configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2016,2017 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: configure.in,v 1.649 2017/12/26 22:23:59 tom Exp $
  32 dnl Process this file with autoconf to produce a configure script.
  33 dnl
  34 dnl See http://invisible-island.net/autoconf/ for additional information.
  35 dnl
  36 dnl ---------------------------------------------------------------------------
  37 AC_PREREQ(2.52.20170501)
  38 AC_REVISION($Revision: 1.649 $)
  39 AC_INIT(ncurses/base/lib_initscr.c)
  40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  41
  42 CF_TOP_BUILDDIR
  43 CF_SUBST_NCURSES_VERSION
  44 CF_VERSION_INFO(NCURSES,ncurses)
  45
  46 CF_WITH_REL_VERSION(NCURSES)
  47 CF_NCURSES_WITH_ABI_VERSION
  48
  49 CF_WITH_SYSTYPE
  50
  51 ###     Save the given $CFLAGS to allow user-override.
  52 cf_user_CFLAGS="$CFLAGS"
  53
  54 ###     Default install-location
  55 CF_CFG_DEFAULTS
  56 ### Defaults for ncurses ABI
  57 CF_ABI_DEFAULTS
  58
  59 ###     Checks for programs.
  60 AC_ARG_WITH(ada,
  61         [  --without-ada           suppress check for Ada95, don't build demo],
  62         [cf_with_ada=$withval],
  63         [cf_with_ada=yes])
  64 if test "x$cf_with_ada" = xyes
  65 then
  66         cf_PROG_CC="gnatgcc gcc cc"
  67 else
  68         cf_PROG_CC="gcc cc"
  69 fi
  70
  71 CF_PROG_CC($cf_PROG_CC)
  72
  73 AC_PROG_CPP
  74 AC_PROG_GCC_TRADITIONAL
  75 CF_PROG_CC_C_O(CC,[$CFLAGS $CPPFLAGS])
  76 CF_PROG_LDCONFIG
  77
  78 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  79 dnl                             configure script by not letting us test if C++
  80 dnl                             is present, making this option necessary.
  81 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  82 AC_ARG_WITH(cxx,
  83         [  --without-cxx           do not adjust ncurses bool to match C++],
  84         [cf_with_cxx=$withval],
  85         [cf_with_cxx=yes])
  86 AC_MSG_RESULT($cf_with_cxx)
  87 if test "X$cf_with_cxx" = Xno ; then
  88         CXX=""
  89         GXX=""
  90 else
  91         # with autoconf 2.13, we can change the error to a warning:
  92         pushdef([AC_MSG_ERROR],
  93                 [AC_MSG_RESULT(no)
  94                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
  95                 cf_with_cxx=no; CXX=""; GXX="";])dnl
  96         AC_PROG_CXX
  97         popdef([AC_MSG_ERROR])dnl
  98
  99         AC_LANG_PUSH(C++)
 100         if test "x$cf_with_cxx" != xno
 101         then
 102                 # Several of the C++ configurations do not work, particularly when
 103                 # cross-compiling (20140913 -TD)
 104                 AC_MSG_CHECKING(if $CXX works)
 105
 106                 save_CPPFLAGS="$CPPFLAGS"
 107                 eval cf_includedir=${includedir}
 108                 CPPFLAGS="$CPPFLAGS -I${cf_includedir}"
 109                 AC_TRY_COMPILE([
 110 #include <stdlib.h>
 111 #include <stdio.h>
 112 ],
 113                 [
 114                 printf("Hello world!\n")
 115                 ],
 116                 [cf_cxx_works=yes],
 117                 [cf_cxx_works=no])
 118                 CPPFLAGS="$save_CPPFLAGS"
 119
 120                 AC_MSG_RESULT($cf_cxx_works)
 121                 if test "x$cf_cxx_works" = xno
 122                 then
 123                         AC_MSG_WARN([Ignore $CXX, since it cannot compile hello-world.])
 124                         cf_with_cxx=no; CXX=""; GXX="";
 125                 fi
 126         fi
 127         AC_LANG_POP
 128
 129         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
 130         if test "$CXX" = "g++" ; then
 131                 AC_PATH_PROG(CXX,g++)
 132         fi
 133         case "x$CXX" in
 134         (x|xg++)
 135                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
 136                 cf_with_cxx=no; CXX=""; GXX="";
 137                 ;;
 138         esac
 139 fi
 140
 141 CF_GXX_VERSION
 142 case $GXX_VERSION in
 143 (1*|2.[[0-6]]*)
 144         # GXX=""; CXX=""; ac_cv_prog_gxx=no
 145         # cf_cxx_library=no
 146         AC_MSG_WARN(templates do not work)
 147         ;;
 148 esac
 149
 150 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 151 AC_ARG_WITH(cxx-binding,
 152         [  --without-cxx-binding   do not build C++ binding and demo],
 153         [cf_with_cxx_binding=$withval],
 154         [cf_with_cxx_binding=$cf_with_cxx])
 155 AC_MSG_RESULT($cf_with_cxx_binding)
 156
 157 AC_MSG_CHECKING(if you want to build with Ada95)
 158 AC_MSG_RESULT($cf_with_ada)
 159
 160 AC_MSG_CHECKING(if you want to install terminal database)
 161 AC_ARG_ENABLE(db-install,
 162         [  --disable-db-install    suppress install of terminal database],
 163         [cf_with_db_install=$enableval],
 164         [cf_with_db_install=yes])
 165 AC_MSG_RESULT($cf_with_db_install)
 166
 167 AC_MSG_CHECKING(if you want to install manpages)
 168 AC_ARG_WITH(manpages,
 169         [  --without-manpages      suppress install of manpages],
 170         [cf_with_manpages=$withval],
 171         [cf_with_manpages=yes])
 172 AC_MSG_RESULT($cf_with_manpages)
 173
 174 AC_MSG_CHECKING(if you want to build programs such as tic)
 175 AC_ARG_WITH(progs,
 176         [  --without-progs         suppress build/install with programs (e.g., tic)],
 177         [cf_with_progs=$withval],
 178         [cf_with_progs=yes])
 179 AC_MSG_RESULT($cf_with_progs)
 180
 181 if test -f $srcdir/tack/tack.h; then
 182         if test "x$cross_compiling" = xyes ; then
 183                 CF_VERBOSE(ignoring tack because we are cross-compiling)
 184                 cf_with_tack=no
 185         else
 186                 AC_MSG_CHECKING(if you want to build the tack program)
 187                 AC_ARG_WITH(tack,
 188                         [  --without-tack          suppress build/install with tack program],
 189                         [cf_with_tack=$withval],
 190                         [cf_with_tack=$cf_with_progs])
 191                 AC_MSG_RESULT($cf_with_tack)
 192         fi
 193 else
 194         cf_with_tack=no
 195 fi
 196
 197 AC_MSG_CHECKING(if you want to build test-programs)
 198 AC_ARG_WITH(tests,
 199         [  --without-tests         suppress build/install with test-programs],
 200         [cf_with_tests=$withval],
 201         [cf_with_tests=yes])
 202 AC_MSG_RESULT($cf_with_tests)
 203
 204 AC_MSG_CHECKING(if you wish to install curses.h)
 205 AC_ARG_WITH(curses-h,
 206         [  --without-curses-h      install curses.h as ncurses.h only],
 207         [with_curses_h=$withval],
 208         [with_curses_h=yes])
 209 AC_MSG_RESULT($with_curses_h)
 210
 211 modules_to_build="ncurses"
 212 test "X$cf_with_progs" != Xno && modules_to_build="$modules_to_build progs"
 213 test "X$cf_with_tack"  != Xno && modules_to_build="$modules_to_build tack"
 214 modules_to_build="$modules_to_build panel menu form"
 215
 216 AC_ARG_PROGRAM
 217
 218 CF_PROG_AWK
 219 CF_PROG_EGREP
 220 CF_PROG_INSTALL
 221 CF_PROG_LINT
 222 CF_PROG_LN_S
 223
 224 AC_SYS_LONG_FILE_NAMES
 225
 226 # Provide for renaming "ncurses5-config" to "ncurses5X-config", etc., in case
 227 # of package conflict.
 228 cf_config_suffix=
 229 AC_ARG_WITH(config-suffix,
 230         [  --with-config-suffix=X  suffixes pc-files],
 231         [case "x$withval" in
 232         (xyes|xno)
 233                 AC_MSG_WARN(expected a value for config-suffix option)
 234                 ;;
 235         (*)     cf_config_suffix="$withval"
 236                 ;;
 237         esac])
 238 AC_SUBST(cf_config_suffix)
 239
 240 # If we find pkg-config, check if we should install the ".pc" files.
 241 CF_PKG_CONFIG
 242 CF_WITH_PKG_CONFIG_LIBDIR
 243 CF_ENABLE_PC_FILES
 244 if test -z "$MAKE_PC_FILES"
 245 then
 246         AC_MSG_CHECKING(for suffix to add to pc-files)
 247 AC_ARG_WITH(pc-suffix,
 248         [  --with-pc-suffix        suffixes pc-files],
 249         [case "x$withval" in
 250         (xyes|xno)
 251                 PC_MODULE_SUFFIX=
 252                 ;;
 253         (*)     PC_MODULE_SUFFIX="$withval"
 254                 ;;
 255         esac])
 256         test -z "$PC_MODULE_SUFFIX" && PC_MODULE_SUFFIX=none
 257         AC_MSG_RESULT($PC_MODULE_SUFFIX)
 258         test "$PC_MODULE_SUFFIX" = none && PC_MODULE_SUFFIX=
 259         AC_SUBST(PC_MODULE_SUFFIX)
 260 fi
 261
 262 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 263 AC_ARG_ENABLE(mixed-case,
 264         [  --enable-mixed-case     tic should assume mixed-case filenames],
 265         [enable_mixedcase=$enableval],
 266         [enable_mixedcase=auto])
 267 AC_MSG_RESULT($enable_mixedcase)
 268 if test "$enable_mixedcase" = "auto" ; then
 269         CF_MIXEDCASE_FILENAMES
 270 else
 271         cf_cv_mixedcase=$enable_mixedcase
 272         if test "x$enable_mixedcase" = "xyes" ; then
 273                 AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
 274         fi
 275 fi
 276
 277 # do this after mixed-case option (tags/TAGS is not as important as tic).
 278 AC_PROG_MAKE_SET
 279 CF_MAKE_TAGS
 280 CF_MAKEFLAGS
 281
 282 dnl These are standard among *NIX systems, but not when cross-compiling
 283 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 284 AC_CHECK_TOOL(LD, ld, ld)
 285 AC_CHECK_TOOL(AR, ar, ar)
 286 AC_CHECK_TOOL(NM, nm, nm)
 287 CF_AR_FLAGS
 288
 289 dnl Special option for use by system-builders: the install-prefix is used to
 290 dnl adjust the location into which the actual install is done, so that an
 291 dnl archive can be built without modifying the host system's configuration.
 292 AC_MSG_CHECKING(if you have specified an install-prefix)
 293 AC_ARG_WITH(install-prefix,
 294         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 295         [case "x$withval" in
 296         (xyes|xno)
 297                 ;;
 298         (*)     DESTDIR="$withval"
 299                 ;;
 300         esac])
 301 AC_MSG_RESULT($DESTDIR)
 302 AC_SUBST(DESTDIR)
 303
 304 ###############################################################################
 305 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 306 # If we're cross-compiling, allow the user to override the tools and their
 307 # options.  The configure script is oriented toward identifying the host
 308 # compiler, etc., but we need a build compiler to generate parts of the source.
 309 CF_BUILD_CC
 310
 311 ###############################################################################
 312 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 313
 314 ### Options to allow the user to specify the set of libraries which are used.
 315 ### Use "--without-normal --with-shared" to allow the default model to be
 316 ### shared, for example.
 317 cf_list_models=""
 318 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 319
 320 CF_WITH_LIBTOOL
 321 if test "$with_libtool" != "no" ; then
 322
 323 cf_list_models="$cf_list_models libtool"
 324
 325 else
 326
 327 AC_MSG_CHECKING(if you want to build shared libraries)
 328 AC_ARG_WITH(shared,
 329         [  --with-shared           generate shared-libraries],
 330         [with_shared=$withval],
 331         [with_shared=no])
 332 AC_MSG_RESULT($with_shared)
 333 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
 334
 335 AC_MSG_CHECKING(if you want to build static libraries)
 336 AC_ARG_WITH(normal,
 337         [  --with-normal           generate normal-libraries (default)],
 338         [with_normal=$withval],
 339         [with_normal=yes])
 340 AC_MSG_RESULT($with_normal)
 341 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
 342
 343 AC_MSG_CHECKING(if you want to build debug libraries)
 344 AC_ARG_WITH(debug,
 345         [  --with-debug            generate debug-libraries (default)],
 346         [with_debug=$withval],
 347         [with_debug=yes])
 348 AC_MSG_RESULT($with_debug)
 349 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
 350
 351 AC_MSG_CHECKING(if you want to build profiling libraries)
 352 AC_ARG_WITH(profile,
 353         [  --with-profile          generate profile-libraries],
 354         [with_profile=$withval],
 355         [with_profile=no])
 356 AC_MSG_RESULT($with_profile)
 357 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
 358
 359 fi
 360
 361 if test "X$cf_with_cxx_binding" != Xno; then
 362 if test "x$with_shared" = "xyes"; then
 363 AC_MSG_CHECKING(if you want to build C++ shared libraries)
 364 AC_ARG_WITH(cxx-shared,
 365         [  --with-cxx-shared       generate C++ shared-libraries],
 366         [with_shared_cxx=$withval],
 367         [with_shared_cxx=no])
 368 AC_MSG_RESULT($with_shared_cxx)
 369 fi
 370 fi
 371
 372 ###############################################################################
 373
 374 AC_MSG_CHECKING(for specified models)
 375 test -z "$cf_list_models" && cf_list_models=normal
 376 dnl If we use libtool to generate libraries, then it must be the only
 377 dnl specified model.
 378 test "$with_libtool" != "no" && cf_list_models=libtool
 379 AC_MSG_RESULT($cf_list_models)
 380
 381 ### Use the first model as the default, and save its suffix for use in building
 382 ### up test-applications.
 383 AC_MSG_CHECKING(for default model)
 384 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 385 AC_MSG_RESULT($DFT_LWR_MODEL)
 386
 387 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 388
 389 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 390 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 391
 392 TICS_NAME=tic
 393 AC_SUBST(TICS_NAME)
 394
 395 TINFO_NAME=tinfo
 396 AC_SUBST(TINFO_NAME)
 397
 398 LIB_NAME=ncurses
 399 AC_SUBST(LIB_NAME)
 400
 401 LIB_DIR=../lib
 402 LIB_2ND=../../lib
 403
 404 CF_WITH_LIB_PREFIX(cf_prefix)
 405
 406 LIB_SUFFIX=
 407 AC_SUBST(LIB_SUFFIX)
 408 CF_PATHSEP
 409
 410 ###############################################################################
 411
 412 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 413 AC_ARG_WITH(termlib,
 414         [  --with-termlib          generate separate terminfo library],
 415         [with_termlib=$withval],
 416         [with_termlib=no])
 417 AC_MSG_RESULT($with_termlib)
 418
 419 AC_MSG_CHECKING(if you want to build a separate tic library)
 420 AC_ARG_WITH(ticlib,
 421         [  --with-ticlib           generate separate tic library],
 422         [with_ticlib=$withval],
 423         [with_ticlib=no])
 424 AC_MSG_RESULT($with_ticlib)
 425
 426 ### Checks for special libraries, must be done up-front.
 427 SHLIB_LIST=""
 428 CF_WITH_GPM
 429 if test "$with_gpm" != no ; then
 430         AC_MSG_CHECKING(if you want to load GPM dynamically)
 431         AC_ARG_WITH(dlsym,
 432                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 433                 [with_dlsym=$withval],
 434                 [with_dlsym=yes])
 435         AC_MSG_RESULT($with_dlsym)
 436         if test "x$with_dlsym" = xyes ; then
 437                 CF_FUNC_DLSYM
 438                 if test "x$with_gpm" != xyes ; then
 439                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 440                         cf_cv_gpm_soname="$with_gpm"
 441                 else
 442                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 443                 fi
 444                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
 445                 SHLIB_LIST="-ldl $SHLIB_LIST"
 446         else
 447                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 448                 CF_ADD_LIB(gpm,TEST_LIBS)
 449         fi
 450         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
 451         CF_CHECK_GPM_WGETCH
 452 fi
 453
 454 CF_WITH_SYSMOUSE
 455
 456 dnl Not all ports of gcc support the -g option
 457
 458 if test X"$CC_G_OPT" = X"" ; then
 459         CC_G_OPT='-g'
 460         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
 461 fi
 462 AC_SUBST(CC_G_OPT)
 463
 464 if test X"$CXX_G_OPT" = X"" ; then
 465         CXX_G_OPT='-g'
 466         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
 467 fi
 468 AC_SUBST(CXX_G_OPT)
 469
 470 AC_MSG_CHECKING(for default loader flags)
 471 case $DFT_LWR_MODEL in
 472 (libtool) LD_MODEL=''   ;;
 473 (normal)  LD_MODEL=''   ;;
 474 (debug)   LD_MODEL=$CC_G_OPT ;;
 475 (profile) LD_MODEL='-pg';;
 476 (shared)  LD_MODEL=''   ;;
 477 esac
 478 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 479 AC_MSG_RESULT($LD_MODEL)
 480
 481 case $DFT_LWR_MODEL in
 482 (shared)
 483 CF_ENABLE_RPATH
 484 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 485 AC_ARG_ENABLE(relink,
 486 [  --disable-relink        relink shared libraries during install],
 487 [cf_cv_do_relink=$enableval],
 488 [cf_cv_do_relink=yes])
 489 AC_MSG_RESULT($cf_cv_do_relink)
 490         ;;
 491 esac
 492
 493 # we will build libraries one-level down.
 494 rel_builddir=..
 495 CF_SHARED_OPTS
 496 for model in $cf_list_models; do
 497         case $model in
 498         (libtool)
 499                 CF_WITH_LIBTOOL_OPTS
 500                 CF_WITH_EXPORT_SYMS
 501                 ;;
 502         (shared)
 503                 if test "$CC_SHARED_OPTS" = "unknown"; then
 504                         AC_ERROR(Shared libraries are not supported in this version)
 505                 fi
 506                 # workaround for inept transition to PIE vs PIC...
 507                 AC_MSG_CHECKING(if current CFLAGS link properly)
 508                 AC_TRY_LINK(
 509                         [#include <stdio.h>],
 510                         [printf("Hello work\n");],
 511                         [cf_cflags_work=yes],
 512                         [cf_cflags_work=no])
 513                 AC_MSG_RESULT($cf_cflags_work)
 514                 if test "$cf_cflags_work" = no
 515                 then
 516                         CF_VERBOSE(try to work around by appending shared-options)
 517                         CFLAGS="$CFLAGS $CC_SHARED_OPTS"
 518                 fi
 519                 CF_WITH_VERSIONED_SYMS
 520                 ;;
 521         esac
 522 done
 523
 524 # pretend that ncurses==ncursesw==ncursest
 525 AC_MSG_CHECKING(if you want to disable library suffixes)
 526 CF_ARG_DISABLE(lib-suffixes,
 527         [  --disable-lib-suffixes  disable library suffixes],
 528         [disable_lib_suffixes=yes],
 529         [disable_lib_suffixes=no],
 530         no)
 531 AC_MSG_RESULT($disable_lib_suffixes)
 532
 533 ### If we're building with rpath, try to link non-standard libs that way too.
 534 if test "$DFT_LWR_MODEL" = "shared"; then
 535         CF_DISABLE_RPATH_HACK
 536 fi
 537
 538 ###############################################################################
 539 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 540
 541 ###     use option --with-extra-suffix to append suffix to headers and libraries
 542 AC_MSG_CHECKING(if you wish to append extra suffix to header/library paths)
 543 EXTRA_SUFFIX=
 544 AC_ARG_WITH(extra-suffix,
 545         [  --with-extra-suffix=X   append extra suffix to header/library paths],
 546         [case x$withval in
 547         (no)
 548                 ;;
 549         (xyes|x)
 550                 EXTRA_SUFFIX=$cf_cv_abi_version
 551                 ;;
 552         (*)
 553                 EXTRA_SUFFIX=$withval
 554                 ;;
 555         esac
 556         ])
 557 AC_MSG_RESULT($EXTRA_SUFFIX)
 558 AC_SUBST(EXTRA_SUFFIX)
 559
 560 ###     use option --disable-overwrite to leave out the link to -lcurses
 561 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 562 AC_ARG_ENABLE(overwrite,
 563         [  --disable-overwrite     put headers in subdir, omit link to -lcurses],
 564         [with_overwrite=$enableval],
 565         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 566 AC_MSG_RESULT($with_overwrite)
 567
 568 AC_MSG_CHECKING(if external terminfo-database is used)
 569 AC_ARG_ENABLE(database,
 570         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 571         [use_database=$enableval],
 572         [use_database=yes])
 573 AC_MSG_RESULT($use_database)
 574
 575 case $host_os in
 576 (os2*)
 577         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 578         ;;
 579 (*)
 580         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 581         ;;
 582 esac
 583 AC_SUBST(TERMINFO_SRC)
 584
 585 NCURSES_USE_DATABASE=0
 586 if test "$use_database" != no ; then
 587         NCURSES_USE_DATABASE=1
 588
 589         AC_MSG_CHECKING(which terminfo source-file will be installed)
 590         AC_ARG_WITH(database,
 591                 [  --with-database=XXX     specify terminfo source to install],
 592                 [TERMINFO_SRC=$withval])
 593         AC_MSG_RESULT($TERMINFO_SRC)
 594
 595         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 596         AC_ARG_WITH(hashed-db,
 597                 [  --with-hashed-db        specify hashed-database library],,
 598                 [with_hashed_db=no])
 599         AC_MSG_RESULT($with_hashed_db)
 600 else
 601         with_hashed_db=no
 602 fi
 603 AC_SUBST(NCURSES_USE_DATABASE)
 604
 605 AC_MSG_CHECKING(for list of fallback descriptions)
 606 AC_ARG_WITH(fallbacks,
 607         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 608         [with_fallback=$withval],
 609         [with_fallback=])
 610 AC_MSG_RESULT($with_fallback)
 611 FALLBACK_LIST=`test "$with_fallback" != no && echo "$with_fallback" | sed -e 's/,/ /g'`
 612 AC_SUBST(FALLBACK_LIST)
 613
 614 AC_MSG_CHECKING(if you want modern xterm or antique)
 615 AC_ARG_WITH(xterm-new,
 616         [  --without-xterm-new     specify if xterm terminfo should be old version],
 617         [with_xterm_new=$withval],
 618         [with_xterm_new=yes])
 619 case $with_xterm_new in
 620 (no) with_xterm_new=xterm-old;;
 621 (*)      with_xterm_new=xterm-new;;
 622 esac
 623 AC_MSG_RESULT($with_xterm_new)
 624 WHICH_XTERM=$with_xterm_new
 625 AC_SUBST(WHICH_XTERM)
 626
 627 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
 628 AC_ARG_WITH(xterm-kbs,
 629         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
 630         [with_xterm_kbs=$withval],
 631         [with_xterm_kbs=BS])
 632 case x$with_xterm_kbs in
 633 (xyes|xno|xBS|xbs|x8)
 634         with_xterm_kbs=BS
 635         ;;
 636 (xDEL|xdel|x127)
 637         with_xterm_kbs=DEL
 638         ;;
 639 (*)
 640         with_xterm_kbs=$withval
 641         ;;
 642 esac
 643 AC_MSG_RESULT($with_xterm_kbs)
 644 XTERM_KBS=$with_xterm_kbs
 645 AC_SUBST(XTERM_KBS)
 646
 647 MAKE_TERMINFO=
 648 if test "$use_database" = no ; then
 649         TERMINFO="${datadir}/terminfo"
 650         MAKE_TERMINFO="#"
 651 else
 652
 653 AC_MSG_CHECKING(for list of terminfo directories)
 654 CF_WITH_PATHLIST(terminfo-dirs,
 655         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 656         TERMINFO_DIRS,
 657         DATADIR/terminfo,
 658         ${datadir}/terminfo)
 659 AC_MSG_RESULT($TERMINFO_DIRS)
 660 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
 661
 662 AC_MSG_CHECKING(for default terminfo directory)
 663 CF_WITH_PATH(default-terminfo-dir,
 664         [  --with-default-terminfo-dir=DIR default terminfo directory],
 665         TERMINFO,
 666         DATADIR/terminfo,
 667         ${datadir}/terminfo)
 668 AC_MSG_RESULT($TERMINFO)
 669 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
 670
 671 fi
 672
 673 AC_SUBST(TERMINFO)
 674 AC_SUBST(MAKE_TERMINFO)
 675
 676 ###     use option --disable-big-core to make tic run on small machines
 677 ###     We need 4Mb, check if we can allocate 50% more than that.
 678 AC_MSG_CHECKING(if big-core option selected)
 679 AC_ARG_ENABLE(big-core,
 680         [  --disable-big-core      assume machine has little memory],
 681         [with_big_core=$enableval],
 682         [AC_TRY_RUN([
 683 #include <stdlib.h>
 684 #include <string.h>
 685 int main() {
 686         unsigned long n = 6000000L;
 687         char *s = malloc(n);
 688         if (s != 0)
 689                 s[0] = s[n-1] = 0;
 690         ${cf_cv_main_return:-return}(s == 0);
 691 }],
 692         [with_big_core=yes],
 693         [with_big_core=no],
 694         [with_big_core=no])])
 695 AC_MSG_RESULT($with_big_core)
 696 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
 697
 698 ### ISO C only guarantees 512-char strings, we have tables which load faster
 699 ### when constructed using "big" strings.  More than the C compiler, the awk
 700 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 701 AC_MSG_CHECKING(if big-strings option selected)
 702 AC_ARG_ENABLE(big-strings,
 703         [  --disable-big-strings   assume compiler has only standard-size strings],
 704         [with_big_strings=$enableval],
 705         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 706 AC_MSG_RESULT($with_big_strings)
 707
 708 USE_BIG_STRINGS=0
 709 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
 710 AC_SUBST(USE_BIG_STRINGS)
 711
 712 ###     use option --enable-termcap to compile in the termcap fallback support
 713 AC_MSG_CHECKING(if you want termcap-fallback support)
 714 AC_ARG_ENABLE(termcap,
 715         [  --enable-termcap        compile in termcap fallback support],
 716         [with_termcap=$enableval],
 717         [with_termcap=no])
 718 AC_MSG_RESULT($with_termcap)
 719
 720 NCURSES_USE_TERMCAP=0
 721 if test "x$with_termcap" != "xyes" ; then
 722         if test "$use_database" = no ; then
 723                 if test -z "$with_fallback" ; then
 724                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 725                 fi
 726         fi
 727         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
 728 else
 729
 730         if test "$with_ticlib" != no ; then
 731                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 732         fi
 733
 734         NCURSES_USE_TERMCAP=1
 735         AC_MSG_CHECKING(for list of termcap files)
 736         CF_WITH_PATHLIST(termpath,
 737                 [  --with-termpath=XXX     specify list of termcap files],
 738                 TERMPATH,
 739                 /etc/termcap:/usr/share/misc/termcap)
 740         AC_MSG_RESULT($TERMPATH)
 741         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
 742
 743         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 744         AC_MSG_CHECKING(if fast termcap-loader is needed)
 745         AC_ARG_ENABLE(getcap,
 746                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 747                 [with_getcap=$enableval],
 748                 [with_getcap=no])
 749         AC_MSG_RESULT($with_getcap)
 750         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
 751
 752         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 753         AC_ARG_ENABLE(getcap-cache,
 754                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 755                 [with_getcap_cache=$enableval],
 756                 [with_getcap_cache=no])
 757         AC_MSG_RESULT($with_getcap_cache)
 758         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
 759
 760 fi
 761 AC_SUBST(NCURSES_USE_TERMCAP)
 762
 763 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 764 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 765 AC_ARG_ENABLE(home-terminfo,
 766         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 767         [with_home_terminfo=$enableval],
 768         [with_home_terminfo=yes])
 769 AC_MSG_RESULT($with_home_terminfo)
 770 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
 771
 772 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 773 AC_ARG_ENABLE(root-environ,
 774         [  --disable-root-environ  restrict environment when running as root],
 775         [with_root_environ=$enableval],
 776         [with_root_environ=yes])
 777 AC_MSG_RESULT($with_root_environ)
 778 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if environment should be restricted for root user])
 779
 780 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 781 ###   to reduce storage requirements for the terminfo database.
 782 CF_LINK_FUNCS
 783
 784 with_links=no
 785 with_symlinks=no
 786
 787 # soft links (symbolic links) are useful for some systems where hard links do
 788 # not work, or to make it simpler to copy terminfo trees around.
 789 if test "x$ac_cv_func_symlink" = xyes ; then
 790         AC_MSG_CHECKING(if tic should use symbolic links)
 791         AC_ARG_ENABLE(symlinks,
 792         [  --enable-symlinks       make tic use symbolic links not hard links],
 793         [with_symlinks=$enableval],
 794         [with_symlinks=no])
 795         AC_MSG_RESULT($with_symlinks)
 796 fi
 797
 798 # If we have hard links and did not choose to use soft links instead, there is
 799 # no reason to make this choice optional - use the hard links.
 800 if test "$with_symlinks" = no ; then
 801         AC_MSG_CHECKING(if tic should use hard links)
 802         if test "x$ac_cv_func_link" = xyes ; then
 803                 with_links=yes
 804         else
 805                 with_links=no
 806         fi
 807         AC_MSG_RESULT($with_links)
 808 fi
 809
 810 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
 811 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
 812
 813 ###   use option --enable-broken-linker to force on use of broken-linker support
 814 AC_MSG_CHECKING(if you want broken-linker support code)
 815 AC_ARG_ENABLE(broken_linker,
 816         [  --enable-broken_linker  compile with broken-linker support code],
 817         [with_broken_linker=$enableval],
 818         [with_broken_linker=${BROKEN_LINKER:-no}])
 819 AC_MSG_RESULT($with_broken_linker)
 820
 821 BROKEN_LINKER=0
 822 if test "x$with_broken_linker" = xyes ; then
 823         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
 824         BROKEN_LINKER=1
 825 elif test "$DFT_LWR_MODEL" = shared ; then
 826         case $cf_cv_system_name in
 827         (cygwin*)
 828                 AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
 829                 BROKEN_LINKER=1
 830                 CF_VERBOSE(cygwin linker is broken anyway)
 831                 ;;
 832         esac
 833 fi
 834 AC_SUBST(BROKEN_LINKER)
 835
 836 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 837 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 838 AC_ARG_ENABLE(bsdpad,
 839         [  --enable-bsdpad         recognize BSD-style prefix padding],
 840         [with_bsdpad=$enableval],
 841         [with_bsdpad=no])
 842 AC_MSG_RESULT($with_bsdpad)
 843 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
 844
 845 ###   use option --enable-widec to turn on use of wide-character support
 846 NCURSES_CH_T=chtype
 847 NCURSES_LIBUTF8=0
 848
 849 NEED_WCHAR_H=0
 850 NCURSES_MBSTATE_T=0
 851 NCURSES_WCHAR_T=0
 852 NCURSES_WINT_T=0
 853
 854 # Check to define _XOPEN_SOURCE "automatically"
 855 CPPFLAGS_before_XOPEN="$CPPFLAGS"
 856 CF_XOPEN_SOURCE(500)
 857 CPPFLAGS_after_XOPEN="$CPPFLAGS"
 858
 859 # Work around breakage on OS X
 860 CF_SIGWINCH
 861
 862 # Checks for CODESET support.
 863 AM_LANGINFO_CODESET
 864
 865 # use these variables to work around a defect in gcc's fixincludes.
 866 NCURSES_OK_WCHAR_T=
 867 NCURSES_OK_WINT_T=
 868
 869 AC_MSG_CHECKING(if you want wide-character code)
 870 AC_ARG_ENABLE(widec,
 871         [  --enable-widec          compile with wide-char/UTF-8 code],
 872         [with_widec=$enableval],
 873         [with_widec=no])
 874 AC_MSG_RESULT($with_widec)
 875
 876 NCURSES_WCWIDTH_GRAPHICS=1
 877 AC_SUBST(NCURSES_WCWIDTH_GRAPHICS)
 878
 879 if test "x$with_widec" = xyes ; then
 880         if test "x$disable_lib_suffixes" = xno ; then
 881                 LIB_SUFFIX="w${LIB_SUFFIX}"
 882         fi
 883         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
 884         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
 885
 886         CF_CHECK_WCHAR_H
 887         CF_CHECK_WCWIDTH_GRAPHICS
 888         test "$cf_cv_wcwidth_graphics" = no && NCURSES_WCWIDTH_GRAPHICS=0
 889
 890         # with_overwrite=no
 891         NCURSES_CH_T=cchar_t
 892         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 893         if test "x$ac_cv_func_putwc" != xyes ; then
 894                 CF_UTF8_LIB
 895                 if test "$cf_cv_utf8_lib" != no ; then
 896                         NCURSES_LIBUTF8=1
 897                 fi
 898         fi
 899         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 900         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 901         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 902
 903         if test "$NCURSES_MBSTATE_T" != 0; then
 904                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
 905         fi
 906 fi
 907 AC_SUBST(NCURSES_CH_T)
 908 AC_SUBST(NCURSES_LIBUTF8)
 909
 910 AC_SUBST(NEED_WCHAR_H)
 911 AC_SUBST(NCURSES_MBSTATE_T)
 912 AC_SUBST(NCURSES_WCHAR_T)
 913 AC_SUBST(NCURSES_WINT_T)
 914
 915 AC_SUBST(NCURSES_OK_WCHAR_T)
 916 AC_SUBST(NCURSES_OK_WINT_T)
 917
 918 ###   use option --disable-lp64 to allow long chtype
 919 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 920 AC_ARG_ENABLE(lp64,
 921         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 922         [with_lp64=$enableval],
 923         [with_lp64=$cf_dft_with_lp64])
 924 AC_MSG_RESULT($with_lp64)
 925
 926 if test "x$with_lp64" = xyes ; then
 927         cf_cv_enable_lp64=1
 928 else
 929         cf_cv_enable_lp64=0
 930 fi
 931 AC_SUBST(cf_cv_enable_lp64)
 932
 933 CF_LARGEFILE
 934
 935 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 936 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 937 AC_ARG_ENABLE(tparm-varargs,
 938         [  --disable-tparm-varargs compile tparm() without varargs interface],
 939         [with_tparm_varargs=$enableval],
 940         [with_tparm_varargs=yes])
 941 AC_MSG_RESULT($with_tparm_varargs)
 942 NCURSES_TPARM_VARARGS=0
 943 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
 944 AC_SUBST(NCURSES_TPARM_VARARGS)
 945
 946 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
 947 if test "$with_ticlib" != no ; then
 948 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
 949 AC_ARG_ENABLE(tic-depends,
 950         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
 951         [with_tic_depends=$enableval],
 952         [with_tic_depends=yes])
 953 AC_MSG_RESULT($with_tic_depends)
 954 else
 955         with_tic_depends=no
 956 fi
 957
 958 ###   use option --disable-wattr-macros to suppress wattr* macros from curses.h
 959 AC_MSG_CHECKING(if you want to suppress wattr* macros to help with ncurses5/ncurses6 transition)
 960 AC_ARG_ENABLE(wattr-macros,
 961         [  --disable-wattr-macros  suppress wattr* macros to help with ncurses5/ncurses6 transition],
 962         [with_wattr_macros=$enableval],
 963         [with_wattr_macros=yes])
 964 if [[ "x$with_wattr_macros" != xyes ]]; then
 965         NCURSES_WATTR_MACROS=0
 966         AC_MSG_RESULT(yes)
 967 else
 968         NCURSES_WATTR_MACROS=1
 969         AC_MSG_RESULT(no)
 970 fi
 971 AC_SUBST(NCURSES_WATTR_MACROS)
 972
 973 CF_WITH_X11_RGB
 974
 975 ###   use option --with-bool to override bool's type
 976 AC_MSG_CHECKING(for type of bool)
 977 AC_ARG_WITH(bool,
 978         [  --with-bool=TYPE        override fallback type of bool variable],
 979         [NCURSES_BOOL="$withval"],
 980         [NCURSES_BOOL=auto])
 981 AC_MSG_RESULT($NCURSES_BOOL)
 982 AC_SUBST(NCURSES_BOOL)
 983
 984 AC_MSG_CHECKING(for alternate terminal capabilities file)
 985 AC_ARG_WITH(caps,
 986         [  --with-caps=alt         compile with alternate Caps file],
 987         [TERMINFO_CAPS=Caps.$withval],
 988         [TERMINFO_CAPS=Caps])
 989 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
 990 AC_MSG_RESULT($TERMINFO_CAPS)
 991 AC_SUBST(TERMINFO_CAPS)
 992
 993 ###   use option --with-chtype to override chtype's type
 994 AC_MSG_CHECKING(for type of chtype)
 995 AC_ARG_WITH(chtype,
 996         [  --with-chtype=TYPE      override type of chtype],
 997         [NCURSES_CHTYPE="$withval"],
 998         [NCURSES_CHTYPE=$cf_dft_chtype])
 999 AC_MSG_RESULT($NCURSES_CHTYPE)
1000
1001 ###   use option --with-ospeed to override ospeed's type
1002 AC_MSG_CHECKING(for type of ospeed)
1003 AC_ARG_WITH(ospeed,
1004         [  --with-ospeed=TYPE      override type of ospeed variable],
1005         [NCURSES_OSPEED="$withval"],
1006         [NCURSES_OSPEED=short])
1007 AC_MSG_RESULT($NCURSES_OSPEED)
1008 AC_SUBST(NCURSES_OSPEED)
1009
1010 ###   use option --with-mmask-t to override mmask_t's type
1011 AC_MSG_CHECKING(for type of mmask_t)
1012 AC_ARG_WITH(mmask-t,
1013         [  --with-mmask-t=TYPE     override type of mmask_t],
1014         [NCURSES_MMASK_T="$withval"],
1015         [NCURSES_MMASK_T=$cf_dft_mmask_t])
1016 AC_MSG_RESULT($NCURSES_MMASK_T)
1017
1018 ###   use option --with-ccharw-max to override CCHARW_MAX size
1019 AC_MSG_CHECKING(for size CCHARW_MAX)
1020 AC_ARG_WITH(ccharw-max,
1021         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
1022         [NCURSES_CCHARW_MAX="$withval"],
1023         [NCURSES_CCHARW_MAX=5])
1024 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
1025 AC_SUBST(NCURSES_CCHARW_MAX)
1026
1027 ###   use option --with-tparm-arg to override tparm's argument type
1028 AC_MSG_CHECKING(for type of tparm args)
1029 AC_ARG_WITH(tparm-arg,
1030         [  --with-tparm-arg=TYPE   override parameter type of tparm],
1031         [NCURSES_TPARM_ARG="$withval"],
1032         [NCURSES_TPARM_ARG=$cf_dft_tparm_arg])
1033 AC_MSG_RESULT($NCURSES_TPARM_ARG)
1034 AC_SUBST(NCURSES_TPARM_ARG)
1035
1036 ### Enable compiling-in rcs id's
1037 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
1038 AC_ARG_WITH(rcs-ids,
1039         [  --with-rcs-ids          compile-in RCS identifiers],
1040         [with_rcs_ids=$withval],
1041         [with_rcs_ids=no])
1042 AC_MSG_RESULT($with_rcs_ids)
1043 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
1044
1045 ###############################################################################
1046 CF_MAN_PAGES([ captoinfo clear infocmp infotocap reset tabs tic toe tput tset ])
1047
1048 ###############################################################################
1049 CF_HELP_MESSAGE(Extensions:)
1050
1051 ### Note that some functions (such as const) are normally disabled anyway.
1052 AC_MSG_CHECKING(if you want to build with function extensions)
1053 AC_ARG_ENABLE(ext-funcs,
1054         [  --disable-ext-funcs     disable function-extensions],
1055         [with_ext_funcs=$enableval],
1056         [with_ext_funcs=yes])
1057 AC_MSG_RESULT($with_ext_funcs)
1058 if test "x$with_ext_funcs" = xyes ; then
1059         NCURSES_EXT_FUNCS=1
1060         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
1061         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function in test-programs])
1062         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function in test-programs])
1063         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function in test-programs])
1064         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function in test-programs])
1065         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function in test-programs])
1066         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function in test-programs])
1067         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function in test-programs])
1068         AC_DEFINE(HAVE_USE_EXTENDED_NAMES,1,[Define to 1 to enable use_extended_names() function in test-programs])
1069         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function in test-programs])
1070         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function in test-programs])
1071         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function in test-programs])
1072         GENERATED_EXT_FUNCS=generated
1073         test "x$with_ext_funcs" = xyes || cf_dft_ext_spfuncs=no
1074 else
1075         NCURSES_EXT_FUNCS=0
1076         GENERATED_EXT_FUNCS=
1077 fi
1078 AC_SUBST(NCURSES_EXT_FUNCS)
1079 AC_SUBST(GENERATED_EXT_FUNCS)
1080
1081 AC_MSG_CHECKING(if you want to build with SCREEN extensions)
1082 AC_ARG_ENABLE(sp-funcs,
1083         [  --enable-sp-funcs       enable SCREEN-extensions],
1084         [with_sp_funcs=$enableval],
1085         [with_sp_funcs=$cf_dft_ext_spfuncs])
1086 AC_MSG_RESULT($with_sp_funcs)
1087 if test "x$with_sp_funcs" = xyes ; then
1088         NCURSES_SP_FUNCS=1
1089         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable SCREEN-extensions])
1090         AC_DEFINE(HAVE_TPUTS_SP,1,[Define to 1 to enable tputs_sp() function in test-programs])
1091         GENERATED_SP_FUNCS=generated
1092 else
1093         NCURSES_SP_FUNCS=0
1094         GENERATED_SP_FUNCS=
1095 fi
1096 AC_SUBST(NCURSES_SP_FUNCS)
1097 AC_SUBST(GENERATED_SP_FUNCS)
1098
1099 AC_MSG_CHECKING(if you want to build with terminal-driver)
1100 AC_ARG_ENABLE(term-driver,
1101         [  --enable-term-driver    enable terminal-driver],
1102         [with_term_driver=$enableval],
1103         [with_term_driver=no])
1104 AC_MSG_RESULT($with_term_driver)
1105 if test "x$with_term_driver" = xyes ; then
1106         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable terminal-driver])
1107         if test "x$with_termlib" != xno ; then
1108                 AC_MSG_ERROR(The term-driver option conflicts with the termlib option)
1109         fi
1110         if test "x$with_sp_funcs" != xyes ; then
1111                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
1112         fi
1113 fi
1114
1115 ###   use option --enable-const to turn on use of const beyond that in XSI.
1116 AC_MSG_CHECKING(for extended use of const keyword)
1117 AC_ARG_ENABLE(const,
1118         [  --enable-const          compile with extra/non-standard const],
1119         [with_ext_const=$enableval],
1120         [with_ext_const=$cf_dft_ext_const])
1121 AC_MSG_RESULT($with_ext_const)
1122 NCURSES_CONST='/*nothing*/'
1123 if test "x$with_ext_const" = xyes ; then
1124         NCURSES_CONST=const
1125 fi
1126 AC_SUBST(NCURSES_CONST)
1127
1128 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
1129 AC_MSG_CHECKING(if you want to use extended colors)
1130 AC_ARG_ENABLE(ext-colors,
1131         [  --enable-ext-colors     compile for 256-color support],
1132         [with_ext_colors=$enableval],
1133         [with_ext_colors=$cf_dft_ext_colors])
1134 AC_MSG_RESULT($with_ext_colors)
1135 NCURSES_EXT_COLORS=0
1136 if test "x$with_ext_colors" = xyes ; then
1137         if test "x$with_widec" != xyes ; then
1138                 AC_MSG_WARN(This option applies only to wide-character library)
1139         else
1140                 # cannot be ABI 5 since it changes sizeof(cchar_t)
1141                 CF_NCURSES_ABI_6
1142                 NCURSES_EXT_COLORS=1
1143                 AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1144                 AC_DEFINE(HAVE_ALLOC_PAIR,1,[Define to 1 to enable alloc_pair() function])
1145                 AC_DEFINE(HAVE_INIT_EXTENDED_COLOR,1,[Define to 1 to enable init_extended_color() function in test-programs])
1146                 AC_DEFINE(HAVE_RESET_COLOR_PAIRS,1,[Define to 1 to enable reset_color_pairs() function in test-programs])
1147         fi
1148 fi
1149 AC_SUBST(NCURSES_EXT_COLORS)
1150
1151 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1152 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1153 AC_ARG_ENABLE(ext-mouse,
1154         [  --enable-ext-mouse      compile for extended mouse-encoding],
1155         [with_ext_mouse=$enableval],
1156         [with_ext_mouse=$cf_dft_ext_mouse])
1157 AC_MSG_RESULT($with_ext_mouse)
1158 NCURSES_MOUSE_VERSION=1
1159 if test "x$with_ext_mouse" = xyes ; then
1160         NCURSES_MOUSE_VERSION=2
1161         CF_NCURSES_ABI_6
1162 fi
1163 AC_SUBST(NCURSES_MOUSE_VERSION)
1164
1165 ###   use option --enable-ext-putwin to turn on extended screendumps
1166 AC_MSG_CHECKING(if you want to use extended putwin/screendump)
1167 AC_ARG_ENABLE(ext-putwin,
1168         [  --enable-ext-putwin     compile with extended putwin/screendump],
1169         [with_ext_putwin=$enableval],
1170         [with_ext_putwin=$cf_dft_ext_putwin])
1171 AC_MSG_RESULT($with_ext_putwin)
1172 if test "x$with_ext_putwin" = xyes ; then
1173         AC_DEFINE(NCURSES_EXT_PUTWIN,1,[Define to 1 to compile with extended putwin/screendump])
1174 fi
1175
1176 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1177 AC_ARG_ENABLE(no-padding,
1178         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1179         [with_no_padding=$enableval],
1180         [with_no_padding=$with_ext_funcs])
1181 AC_MSG_RESULT($with_no_padding)
1182 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1183
1184 AC_CHECK_SIZEOF([signed char], 0)
1185 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1186         NCURSES_SBOOL="signed char"
1187 else
1188         NCURSES_SBOOL="char"
1189 fi
1190 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1191 AC_ARG_ENABLE(signed-char,
1192         [  --enable-signed-char    compile using signed Boolean's in term.h],
1193         [with_signed_char=$enableval],
1194         [with_signed_char=no])
1195 AC_MSG_RESULT($with_signed_char)
1196 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1197 AC_SUBST(NCURSES_SBOOL)
1198
1199 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1200 AC_MSG_CHECKING(if you want SIGWINCH handler)
1201 AC_ARG_ENABLE(sigwinch,
1202         [  --enable-sigwinch       compile with SIGWINCH handler],
1203         [with_sigwinch=$enableval],
1204         [with_sigwinch=$with_ext_funcs])
1205 AC_MSG_RESULT($with_sigwinch)
1206 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1207
1208 ###   use option --enable-tcap-names to allow user to define new capabilities
1209 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1210 AC_ARG_ENABLE(tcap-names,
1211         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1212         [with_tcap_names=$enableval],
1213         [with_tcap_names=$with_ext_funcs])
1214 AC_MSG_RESULT($with_tcap_names)
1215 NCURSES_XNAMES=0
1216 test "x$with_tcap_names" = xyes && NCURSES_XNAMES=1
1217 AC_SUBST(NCURSES_XNAMES)
1218
1219 ##############################################################################
1220 CF_WITH_PTHREAD
1221
1222 if test "x$with_pthread" != xno; then
1223         AC_CHECK_FUNC(pthread_kill,[
1224                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1225                 AC_ARG_ENABLE(pthreads-eintr,
1226                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1227                         [use_pthreads_eintr=$enableval],
1228                         [use_pthreads_eintr=no])
1229                 AC_MSG_RESULT($use_pthreads_eintr)
1230                 if test "x$use_pthreads_eintr" = xyes ; then
1231                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1232                 fi])
1233
1234         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1235         AC_ARG_ENABLE(weak-symbols,
1236                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1237                 [use_weak_symbols=$enableval],
1238                 [use_weak_symbols=no])
1239         AC_MSG_RESULT($use_weak_symbols)
1240         if test "x$use_weak_symbols" = xyes ; then
1241                 CF_WEAK_SYMBOLS
1242         else
1243                 cf_cv_weak_symbols=no
1244         fi
1245
1246         if test "x$cf_cv_weak_symbols" = xyes ; then
1247                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1248         fi
1249 fi
1250
1251 PTHREAD=
1252 if test "x$with_pthread" = "xyes" ; then
1253         AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1254         enable_reentrant=yes
1255         if test "x$cf_cv_weak_symbols" = xyes ; then
1256                 PTHREAD=-lpthread
1257         fi
1258 fi
1259 AC_SUBST(PTHREAD)
1260
1261 # Reentrant code has to be opaque; there's little advantage to making ncurses
1262 # opaque outside of that, so there is no --enable-opaque option.  We can use
1263 # this option without --with-pthreads, but this will be always set for
1264 # pthreads.
1265 AC_MSG_CHECKING(if you want reentrant code)
1266 AC_ARG_ENABLE(reentrant,
1267         [  --enable-reentrant      compile with reentrant code],
1268         [with_reentrant=$enableval],
1269         [with_reentrant=no])
1270 AC_MSG_RESULT($with_reentrant)
1271 if test "x$with_reentrant" = xyes ; then
1272         cf_cv_enable_reentrant=1
1273         cf_cv_enable_opaque="NCURSES_INTERNALS"
1274         NCURSES_SIZE_T=int
1275         if test "x$cf_cv_weak_symbols" = xyes ; then
1276                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1277                 CF_ADD_LIB(pthread,TEST_LIBS)
1278                 CF_ADD_LIB(pthread,TEST_LIBS2)
1279         else
1280                 # when not using weak symbols but with_reentrant,
1281                 # add 't' to the library suffix on all platforms
1282                 # except cygwin, where we only do that if ALSO
1283                 # compiling with full thread support.
1284                 case "$host" in
1285                 (*cygwin* | *msys*)
1286                         if test "$with_pthread" = "yes" ; then
1287                                 if test "x$disable_lib_suffixes" = "xno" ; then
1288                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1289                                 fi
1290                         fi ;;
1291                 (*)
1292                         if test "x$disable_lib_suffixes" = "xno" ; then
1293                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1294                         fi
1295                         ;;
1296                 esac
1297         fi
1298         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use reentrant feature])
1299         CF_NCURSES_ABI_6
1300 else
1301         cf_cv_enable_reentrant=0
1302         cf_cv_enable_opaque="NCURSES_OPAQUE"
1303         NCURSES_SIZE_T=short
1304 fi
1305 AC_SUBST(cf_cv_enable_reentrant)
1306 AC_SUBST(cf_cv_enable_opaque)
1307
1308 AC_SUBST(NCURSES_SIZE_T)
1309
1310 AC_MSG_CHECKING(if you want opaque curses-library structures)
1311 CF_ARG_ENABLE(opaque-curses,
1312         [  --enable-opaque-curses  make curses WINDOW, etc., "opaque"],
1313         [enable_opaque_curses=yes],[
1314          test "$cf_cv_enable_reentrant" = 1 && enable_opaque_curses=yes
1315          test "$cf_cv_enable_reentrant" = 1 || enable_opaque_curses=no
1316         ])
1317 AC_MSG_RESULT($enable_opaque_curses)
1318
1319 test "$cf_cv_enable_reentrant" = 1 && \
1320 test "$enable_opaque_curses" = no && \
1321 AC_MSG_ERROR(reentrant configuration requires opaque library)
1322
1323 AC_MSG_CHECKING(if you want opaque form-library structures)
1324 AC_ARG_ENABLE(opaque-form,
1325         [  --enable-opaque-form    make form-library structures "opaque"],
1326         [enable_opaque_form=yes],[enable_opaque_form=no])
1327 AC_MSG_RESULT($enable_opaque_form)
1328
1329 AC_MSG_CHECKING(if you want opaque menu-library structures)
1330 AC_ARG_ENABLE(opaque-menu,
1331         [  --enable-opaque-menu    make menu-library structures "opaque"],
1332         [enable_opaque_menu=yes],[enable_opaque_menu=no])
1333 AC_MSG_RESULT($enable_opaque_menu)
1334
1335 AC_MSG_CHECKING(if you want opaque panel-library structures)
1336 AC_ARG_ENABLE(opaque-panel,
1337         [  --enable-opaque-panel   make panel-library structures "opaque"],
1338         [enable_opaque_panel=yes],[enable_opaque_panel=no])
1339 AC_MSG_RESULT($enable_opaque_panel)
1340
1341 NCURSES_OPAQUE=0;               test "$enable_opaque_curses" = yes && NCURSES_OPAQUE=1
1342 NCURSES_OPAQUE_FORM=0;  test "$enable_opaque_form"   = yes && NCURSES_OPAQUE_FORM=1
1343 NCURSES_OPAQUE_MENU=0;  test "$enable_opaque_menu"   = yes && NCURSES_OPAQUE_MENU=1
1344 NCURSES_OPAQUE_PANEL=0; test "$enable_opaque_panel"  = yes && NCURSES_OPAQUE_PANEL=1
1345
1346 AC_SUBST(NCURSES_OPAQUE)
1347 AC_SUBST(NCURSES_OPAQUE_FORM)
1348 AC_SUBST(NCURSES_OPAQUE_MENU)
1349 AC_SUBST(NCURSES_OPAQUE_PANEL)
1350
1351 ### Allow using a different wrap-prefix
1352 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1353         AC_MSG_CHECKING(for prefix used to wrap public variables)
1354         AC_ARG_WITH(wrap-prefix,
1355                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1356                 [NCURSES_WRAP_PREFIX=$withval],
1357                 [NCURSES_WRAP_PREFIX=_nc_])
1358         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1359 else
1360         NCURSES_WRAP_PREFIX=_nc_
1361 fi
1362 AC_SUBST(NCURSES_WRAP_PREFIX)
1363 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1364
1365 ###############################################################################
1366 # These options are relatively safe to experiment with.
1367 CF_HELP_MESSAGE(Development Code:)
1368 AC_MSG_CHECKING(if you want all development code)
1369 AC_ARG_WITH(develop,
1370         [  --without-develop       disable development options],
1371         [with_develop=$withval],
1372         [with_develop=no])
1373 AC_MSG_RESULT($with_develop)
1374
1375 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1376 AC_MSG_CHECKING(if you want hard-tabs code)
1377 AC_ARG_ENABLE(hard-tabs,
1378         [  --enable-hard-tabs      compile with hard-tabs code],,
1379         [enable_hard_tabs=$with_develop])
1380 AC_MSG_RESULT($enable_hard_tabs)
1381 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1382
1383 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1384 AC_MSG_CHECKING(if you want limited support for xmc)
1385 AC_ARG_ENABLE(xmc-glitch,
1386         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1387         [enable_xmc_glitch=$with_develop])
1388 AC_MSG_RESULT($enable_xmc_glitch)
1389 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1390
1391 ###############################################################################
1392 # These are just experimental, probably should not be in a package:
1393 CF_HELP_MESSAGE(Experimental Code:)
1394
1395 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1396 AC_ARG_ENABLE(assumed-color,
1397         [  --disable-assumed-color do not assume anything about default-colors],
1398         [with_assumed_color=$enableval],
1399         [with_assumed_color=yes])
1400 AC_MSG_RESULT($with_assumed_color)
1401 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1402
1403 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1404 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1405 AC_ARG_ENABLE(hashmap,
1406         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1407         [with_hashmap=$enableval],
1408         [with_hashmap=yes])
1409 AC_MSG_RESULT($with_hashmap)
1410 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1411
1412 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1413 AC_MSG_CHECKING(if you want colorfgbg code)
1414 AC_ARG_ENABLE(colorfgbg,
1415         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1416         [with_colorfgbg=$enableval],
1417         [with_colorfgbg=no])
1418 AC_MSG_RESULT($with_colorfgbg)
1419 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1420
1421 ###   use option --enable-interop to turn on use of bindings used for interop
1422 AC_MSG_CHECKING(if you want interop bindings)
1423 AC_ARG_ENABLE(interop,
1424         [  --enable-interop        compile-in interop bindings],
1425         [with_exp_interop=$enableval],
1426         [with_exp_interop=$cf_dft_interop])
1427 AC_MSG_RESULT($with_exp_interop)
1428
1429 NCURSES_INTEROP_FUNCS=0
1430 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1431 AC_SUBST(NCURSES_INTEROP_FUNCS)
1432
1433
1434 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1435 AC_ARG_ENABLE(safe-sprintf,
1436         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1437         [with_safe_sprintf=$enableval],
1438         [with_safe_sprintf=no])
1439 AC_MSG_RESULT($with_safe_sprintf)
1440 test "x$with_safe_sprintf" = xyes && AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1441
1442 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1443 # when hashmap is used scroll hints are useless
1444 if test "$with_hashmap" = no ; then
1445 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1446 AC_ARG_ENABLE(scroll-hints,
1447         [  --disable-scroll-hints  compile without scroll-hints code],
1448         [with_scroll_hints=$enableval],
1449         [with_scroll_hints=yes])
1450 AC_MSG_RESULT($with_scroll_hints)
1451 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1452 fi
1453
1454 AC_MSG_CHECKING(if you want wgetch-events code)
1455 AC_ARG_ENABLE(wgetch-events,
1456         [  --enable-wgetch-events  compile with wgetch-events code],
1457         [with_wgetch_events=$enableval],
1458         [with_wgetch_events=no])
1459 AC_MSG_RESULT($with_wgetch_events)
1460 test "x$with_wgetch_events" = xyes && AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with wgetch-events code])
1461
1462 ###############################################################################
1463 CF_HELP_MESSAGE(Testing/development Options:)
1464
1465 ###     use option --disable-echo to suppress full display compiling commands
1466 CF_DISABLE_ECHO
1467 if test "x$enable_echo" = xyes; then
1468         ECHO_LINK=
1469 else
1470         ECHO_LINK='@ echo linking $@ ... ;'
1471         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1472         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1473 fi
1474 AC_SUBST(ECHO_LINK)
1475
1476 ###     use option --enable-warnings to turn on all gcc warnings
1477 AC_MSG_CHECKING(if you want to see compiler warnings)
1478 AC_ARG_ENABLE(warnings,
1479         [  --enable-warnings       build: turn on GCC compiler warnings],
1480         [with_warnings=$enableval])
1481 AC_MSG_RESULT($with_warnings)
1482
1483 if test "x$with_warnings" = "xyes"; then
1484         CF_ADD_ADAFLAGS(-gnatg)
1485         CF_GCC_WARNINGS(Wno-unknown-pragmas Wswitch-enum)
1486         if test "x$cf_with_cxx" = xyes ; then
1487                 CF_GXX_WARNINGS(Wno-unused)
1488         fi
1489 fi
1490 CF_GCC_ATTRIBUTES
1491 CF_ENABLE_STRING_HACKS
1492
1493 ###     use option --enable-assertions to turn on generation of assertion code
1494 AC_MSG_CHECKING(if you want to enable runtime assertions)
1495 AC_ARG_ENABLE(assertions,
1496         [  --enable-assertions     test: turn on generation of assertion code],
1497         [with_assertions=$enableval],
1498         [with_assertions=no])
1499 AC_MSG_RESULT($with_assertions)
1500 if test -n "$GCC"
1501 then
1502         if test "$with_assertions" = no
1503         then
1504                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1505         else
1506                 CF_ADD_ADAFLAGS(-gnata)
1507         fi
1508 fi
1509
1510 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1511 CF_DISABLE_LEAKS
1512 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1513
1514 ###     use option --enable-expanded to generate certain macros as functions
1515 AC_ARG_ENABLE(expanded,
1516         [  --enable-expanded       test: generate functions for certain macros],
1517         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1518
1519 ###     use option --disable-macros to suppress macros in favor of functions
1520 AC_ARG_ENABLE(macros,
1521         [  --disable-macros        test: use functions rather than macros],
1522         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1523
1524 # Normally we only add trace() to the debug-library.  Allow this to be
1525 # extended to all models of the ncurses library:
1526 cf_all_traces=no
1527 case "$CFLAGS $CPPFLAGS" in
1528 (*-DTRACE*)
1529         cf_all_traces=yes
1530         ;;
1531 esac
1532
1533 AC_MSG_CHECKING(whether to add trace feature to all models)
1534 AC_ARG_WITH(trace,
1535 [  --with-trace            test: add trace() function to all models of ncurses],
1536 [cf_with_trace=$withval],
1537 [cf_with_trace=$cf_all_traces])
1538 AC_MSG_RESULT($cf_with_trace)
1539
1540 if test "x$cf_with_trace" = xyes ; then
1541         LIB_TRACING=all
1542         ADA_TRACE=TRUE
1543         CF_ADD_CFLAGS(-DTRACE)
1544         AC_DEFINE(HAVE__TRACEF,1,[Define to 1 if we have _tracef function])
1545 else
1546         LIB_TRACING=DEBUG
1547         ADA_TRACE=FALSE
1548 fi
1549
1550 AC_SUBST(ADA_TRACE)
1551
1552 CF_DISABLE_GNAT_PROJECTS
1553
1554 ###     Checks for libraries.
1555 case $cf_cv_system_name in
1556 (*mingw32*|*mingw64*)
1557         CPPFLAGS="$CPPFLAGS -DWINVER=0x0501 -DWIN32_LEAN_AND_MEAN"
1558         LIBS=" -lpsapi $LIBS"
1559         ;;
1560 (*)
1561 AC_CHECK_FUNC(gettimeofday,
1562         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1563
1564 AC_CHECK_LIB(bsd, gettimeofday,
1565         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1566         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1567         ;;
1568 esac
1569
1570 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1571 AC_SUBST(MATH_LIB)
1572
1573 ###     Checks for header files.
1574 AC_STDC_HEADERS
1575 AC_HEADER_DIRENT
1576 AC_HEADER_TIME
1577 CF_REGEX
1578
1579 dnl These are some other potentially nonportable headers.
1580 AC_CHECK_HEADERS( \
1581 fcntl.h \
1582 getopt.h \
1583 limits.h \
1584 locale.h \
1585 math.h \
1586 poll.h \
1587 sys/bsdtypes.h \
1588 sys/ioctl.h \
1589 sys/param.h \
1590 sys/poll.h \
1591 sys/select.h \
1592 sys/time.h \
1593 sys/times.h \
1594 ttyent.h \
1595 unistd.h \
1596 wctype.h \
1597 )
1598
1599 CF_GETOPT_HEADER
1600
1601 # check for ISC (this may also define _POSIX_SOURCE)
1602 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1603 if test "x$ISC" = xyes ; then
1604         AC_CHECK_LIB(cposix,main)
1605         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1606 fi
1607
1608 CF_SYS_TIME_SELECT
1609
1610 ###     checks for compiler characteristics
1611 AC_LANG_C
1612 AC_C_CONST
1613 CF_C_INLINE(NCURSES_INLINE,1200)
1614 CF_SIG_ATOMIC_T
1615
1616 if test $NCURSES_CHTYPE = auto ; then
1617         CF_TYPEOF_CHTYPE
1618 else
1619         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1620 fi
1621 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1622 AC_SUBST(cf_cv_typeof_chtype)
1623
1624 CF_UNSIGNED_LITERALS
1625 cf_cv_1UL="1"
1626 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1627 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1628 AC_SUBST(cf_cv_1UL)
1629
1630 if test $NCURSES_MMASK_T = auto ; then
1631         cf_cv_typeof_mmask_t=long
1632 else
1633         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1634 fi
1635 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1636 AC_SUBST(cf_cv_typeof_mmask_t)
1637
1638 ###     Checks for external-data
1639 CF_ERRNO
1640 CF_LINK_DATAONLY
1641
1642 ###     Checks for library functions.
1643 AC_CHECK_FUNCS( \
1644 getcwd \
1645 getegid \
1646 geteuid \
1647 getopt \
1648 getttynam \
1649 issetugid \
1650 poll \
1651 putenv \
1652 remove \
1653 select \
1654 setbuf \
1655 setbuffer \
1656 setenv \
1657 setvbuf \
1658 sigaction \
1659 sigvec \
1660 strdup \
1661 strstr \
1662 tcgetpgrp \
1663 tdestroy \
1664 times \
1665 tsearch \
1666 vsnprintf \
1667 )
1668
1669 if test "x$ac_cv_func_getopt" = xno && \
1670    test "x$cf_with_progs$cf_with_tests" != xnono; then
1671         AC_MSG_ERROR(getopt is required for building programs)
1672 fi
1673
1674 if test "x$with_getcap" = "xyes" ; then
1675         CF_CGETENT
1676 fi
1677
1678 CF_ISASCII
1679 CF_STRUCT_SIGACTION
1680 CF_FUNC_NANOSLEEP
1681 CF_FUNC_TERMIOS
1682 CF_FUNC_VSSCANF
1683 CF_MKSTEMP
1684
1685 # setup for prototype of fallback for vsscanf()
1686 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1687
1688 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1689 if test "x$cross_compiling" = xyes ; then
1690         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1691 else
1692         AC_FUNC_SETVBUF_REVERSED
1693 fi
1694 AC_CHECK_TYPE(intptr_t, long)
1695 AC_CHECK_TYPE(ssize_t, int)
1696 CF_TYPE_SIGACTION
1697 CF_SIZECHANGE
1698 CF_FUNC_MEMMOVE
1699 CF_FUNC_POLL
1700 CF_VA_COPY
1701 AC_FUNC_VFORK
1702
1703 # special check for test/ditto.c
1704 CF_FUNC_OPENPTY
1705 if test "$cf_cv_func_openpty" != no ; then
1706         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1707         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1708         if test "x$cf_cv_lib_util" = xyes ; then
1709                 CF_ADD_LIB(util,TEST_LIBS)
1710         fi
1711 fi
1712 AC_SUBST(TEST_LIBS)
1713 AC_SUBST(TEST_LIBS2)
1714
1715 if test "$with_hashed_db" != no ; then
1716         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1717         CF_HASHED_DB($with_hashed_db)
1718 fi
1719
1720 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1721 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1722         CF_STRIP_G_OPT(CFLAGS)
1723         CF_STRIP_G_OPT(CXXFLAGS)
1724 fi
1725
1726 # Just in case, check if the C compiler has a bool type.
1727 CF_BOOL_DECL(cf_cv_cc_bool_type)
1728
1729 # Check for C++ compiler characteristics (and ensure that it's there!)
1730 if test -n "$CXX" ; then
1731         AC_LANG_CPLUSPLUS
1732         CF_STDCPP_LIBRARY
1733         CF_PROG_CC_C_O(CXX,[$CXXFLAGS $CPPFLAGS])
1734
1735         case $GXX_VERSION in
1736         (1*|2.[0-6]*)
1737                 cf_cxx_library=yes
1738                 ;;
1739         (*-2.7*|2.7*)
1740                 CF_GPP_LIBRARY
1741                 ;;
1742         (*)
1743                 cf_cxx_library=no
1744                 ;;
1745         esac
1746
1747         AC_CHECK_HEADERS(typeinfo)
1748         CF_CXX_IOSTREAM_NAMESPACE
1749         CF_BOOL_DECL
1750         CF_BOOL_SIZE
1751         CF_ETIP_DEFINES
1752         CF_CPP_PARAM_INIT
1753         CF_CPP_STATIC_CAST
1754         CF_CXX_AR_FLAGS
1755 else
1756         cf_cxx_library=no
1757         cf_cv_builtin_bool=1
1758
1759         # Just because we are not configuring against C++ right now does not
1760         # mean that a user will not want to use C++.  Some distributors disable
1761         # the C++ portion of this configuration as a shortcut (or just to avoid
1762         # compiling the demo in the c++ directory).  So we need a reasonable
1763         # default for the 'bool' type.
1764         #
1765         # Caveat: since the storage of the bool type is not standardized, it
1766         # may change.
1767
1768         if test "$NCURSES_BOOL" != auto ; then
1769                 cf_cv_type_of_bool=$NCURSES_BOOL
1770                 cf_cv_header_stdbool_h=0
1771         else
1772                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1773                         CF_BOOL_SIZE
1774                 else
1775                         AC_MSG_CHECKING(for fallback type of bool)
1776                         case "$host_cpu" in
1777                         (i?86)  cf_cv_type_of_bool=char ;;
1778                         (*)     cf_cv_type_of_bool=int  ;;
1779                         esac
1780                         AC_MSG_RESULT($cf_cv_type_of_bool)
1781                 fi
1782         fi
1783 fi
1784 AC_SUBST(CXXLIBS)
1785
1786 # If the C compiler did not declare bool, and we did not determine that the C++
1787 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1788 # ncurses library use the same type as C++ bool.  Note that this allows one to
1789 # specify the type of bool in a configure-script option and postpone
1790 # integration with the C++ compiler provided that the types are compatible.
1791 USE_CXX_BOOL=1
1792 if test $cf_cv_cc_bool_type = 1
1793 then
1794         # oops: C has a bool.  Unlikely, but C++ could differ.
1795         USE_CXX_BOOL=0
1796 elif test $cf_cv_builtin_bool = 0
1797 then
1798         # C++ has no bool
1799         USE_CXX_BOOL=0
1800 else
1801         # this is the normal case
1802         USE_CXX_BOOL='defined(__cplusplus)'
1803 fi
1804 AC_SUBST(USE_CXX_BOOL)
1805
1806 CF_HELP_MESSAGE(Ada95 Binding Options:)
1807
1808 dnl If the Ada95 source-tree is present, add that to the build unless it will
1809 dnl not work, or was not requested.
1810 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1811
1812 dnl libtool does not know anything about GNAT, though a change made in 1998
1813 dnl provided for it "someday".  Disable the ada subtree if we are using
1814 dnl libtool -TD 20070714
1815         if test "$cf_with_ada" != "no" ; then
1816                 if test "$with_libtool" != "no"; then
1817                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1818                         cf_with_ada=no
1819                 fi
1820         fi
1821
1822 dnl Check for availability of GNU Ada Translator (GNAT).
1823 dnl At the moment we support no other Ada95 compiler.
1824         if test "$cf_with_ada" != "no" ; then
1825                 CF_PROG_GNAT
1826                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
1827                         CF_ADD_ADAFLAGS(-gnatpn)
1828                         CF_FIXUP_ADAFLAGS
1829
1830                         CF_GNATPREP_OPT_T
1831
1832                         CF_GNAT_GENERICS
1833                         CF_GNAT_SIGINT
1834                         CF_GNAT_PROJECTS
1835
1836                         CF_WITH_ADA_COMPILER
1837
1838                         cf_ada_package=terminal_interface
1839                         AC_SUBST(cf_ada_package)
1840
1841                         CF_WITH_ADA_INCLUDE
1842                         CF_WITH_ADA_OBJECTS
1843                         CF_WITH_ADA_SHAREDLIB
1844                 fi
1845         fi
1846 else
1847         cf_with_ada=no
1848 fi
1849
1850 # do this "late" to avoid conflict with header-checks
1851 if test "x$with_widec" = xyes ; then
1852         AC_CHECK_SIZEOF(wchar_t)
1853 fi
1854
1855 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1856 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1857 ###
1858 ### ticlib modules may be a separate library, otherwise contained in termlib.
1859 ### termlib modules may be a separate library, otherwise contained in ncurses.
1860 ###
1861 ### The of "+" or " " between the tokens controls the way the script
1862 ### chooses to split module lists into libraries.
1863 ###
1864 ### (see CF_LIB_RULES).
1865 AC_MSG_CHECKING(for library subsets)
1866 LIB_SUBSETS=
1867
1868 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1869         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1870         if test "$with_ticlib" != no ; then
1871                 LIB_SUBSETS="${LIB_SUBSETS} "
1872         else
1873                 LIB_SUBSETS="${LIB_SUBSETS}+"
1874         fi
1875 fi
1876
1877 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1878 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1879
1880 if test "$with_termlib" != no ; then
1881         LIB_SUBSETS="${LIB_SUBSETS} "
1882 else
1883         LIB_SUBSETS="${LIB_SUBSETS}+"
1884 fi
1885
1886 LIB_SUBSETS="${LIB_SUBSETS}base"
1887
1888 # Most term-driver calls are to tinfo, but some like init_pair are to the
1889 # base library (so it resides in base).
1890 if test "$with_term_driver" != no ; then
1891         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1892         case $cf_cv_system_name in
1893         (*mingw32*|*mingw64*)
1894                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1895                 CPPFLAGS="$CPPFLAGS -DUSE_WIN32CON_DRIVER"
1896                 ;;
1897         (*)
1898                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1899                 ;;
1900         esac
1901 fi
1902
1903 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1904 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1905
1906 AC_MSG_RESULT($LIB_SUBSETS)
1907
1908 ### Construct the list of include-directories to be generated
1909 CF_INCLUDE_DIRS
1910 CF_ADA_INCLUDE_DIRS
1911
1912 ### Build up pieces for makefile rules
1913 AC_MSG_CHECKING(default library suffix)
1914 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1915 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1916 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1917
1918 AC_MSG_CHECKING(default library-dependency suffix)
1919 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1920 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1921 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1922
1923 AC_MSG_CHECKING(default object directory)
1924 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1925 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1926 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1927
1928 if test "x$cf_with_cxx" = xyes ; then
1929 AC_MSG_CHECKING(c++ library-dependency suffix)
1930 if test "$with_libtool" != "no"; then
1931         # libtool thinks it can make c++ shared libraries (perhaps only g++)
1932         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1933 elif test "$with_shared_cxx" != "no"; then
1934         # also for g++ users...
1935         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1936 else
1937         # we normally make a static library because C/C++ library rules differ
1938         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
1939 fi
1940 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1941 AC_SUBST(CXX_LIB_SUFFIX)
1942 fi
1943
1944 # do not want -ldl in build except as needed for -lncurses dependency
1945 if test "x$with_dlsym" = xyes ; then
1946 if test $DFT_LWR_MODEL = shared || \
1947    test $DFT_LWR_MODEL = libtool ; then
1948         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1949 fi
1950 fi
1951 ### Set up low-level terminfo dependencies for makefiles.
1952
1953 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1954 # do not need libdl
1955 TICS_LIST=
1956 if test "x$with_dlsym" = xyes ; then
1957         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1958 fi
1959
1960 USE_ARG_SUFFIX="${DFT_ARG_SUFFIX}${EXTRA_SUFFIX}"
1961 USE_LIB_SUFFIX="${LIB_SUFFIX}${EXTRA_SUFFIX}"
1962 USE_CFG_SUFFIX=${DFT_ARG_SUFFIX}${cf_cv_abi_version}
1963 if test -n "$EXTRA_SUFFIX" && test "x$EXTRA_SUFFIX" != "x${cf_cv_abi_version}"
1964 then
1965         USE_CFG_SUFFIX="${USE_CFG_SUFFIX}${EXTRA_SUFFIX}"
1966 fi
1967 AC_SUBST(USE_ARG_SUFFIX)
1968 AC_SUBST(USE_CFG_SUFFIX)
1969 AC_SUBST(USE_LIB_SUFFIX)
1970
1971 if test "$with_ticlib" != no ; then
1972
1973         if test "x$with_ticlib" != xyes ; then
1974                 TICS_NAME=$with_ticlib
1975                 TICS_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
1976                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1977                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1978                 TICS_LIB_SUFFIX="${with_ticlib}"
1979         else
1980                 TICS_SUFFIX=${DFT_LIB_SUFFIX}
1981                 TICS_ARG_SUFFIX="${TICS_NAME}${USE_ARG_SUFFIX}"
1982                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1983                 TICS_LIB_SUFFIX="${TICS_NAME}${USE_LIB_SUFFIX}"
1984         fi
1985         TICS_LDFLAGS="-L${LIB_DIR}"
1986         TICS_LIBS="-l${TICS_ARG_SUFFIX}"
1987 else
1988         TICS_SUFFIX=${DFT_LIB_SUFFIX}
1989         TICS_LDFLAGS="-L${LIB_DIR}"
1990         TICS_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
1991 fi
1992 AC_SUBST(TICS_ARG_SUFFIX)
1993 AC_SUBST(TICS_DEP_SUFFIX)
1994 AC_SUBST(TICS_LIB_SUFFIX)
1995 AC_SUBST(TICS_LDFLAGS)
1996 AC_SUBST(TICS_LIBS)
1997
1998 if test "$with_termlib" != no ; then
1999
2000         if test "x$with_termlib" != xyes ; then
2001                 TINFO_NAME=$with_termlib
2002                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
2003                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2004                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2005                 TINFO_LIB_SUFFIX="${with_termlib}"
2006         else
2007                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2008                 TINFO_ARG_SUFFIX="${TINFO_NAME}${USE_ARG_SUFFIX}"
2009                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
2010                 TINFO_LIB_SUFFIX="${TINFO_NAME}${USE_LIB_SUFFIX}"
2011         fi
2012
2013         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2014         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2015         if test "$DFT_LWR_MODEL" = "libtool"; then
2016                 TEST_ARGS="${TEST_DEPS}"
2017                 TEST_ARG2="${TEST_DEP2}"
2018                 TINFO_LDFLAGS="-L${LIB_DIR}"
2019                 TINFO_LIBS="$TEST_ARGS"
2020                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
2021                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
2022         else
2023                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
2024                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
2025                 if test "x$with_term_driver" != xno ; then
2026                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2027                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${USE_ARG_SUFFIX}"
2028                         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
2029                 else
2030                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2031                         TINFO_LIBS="$TEST_ARGS"
2032                 fi
2033                 TINFO_LDFLAGS="-L${LIB_DIR}"
2034                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2035         fi
2036 else
2037         # the next lines are needed for linking libtic over libncurses
2038         TINFO_NAME=${LIB_NAME}
2039         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2040         TINFO_ARG_SUFFIX=${LIB_NAME}${USE_ARG_SUFFIX}
2041         if test "x$with_tic_depends" = xyes ; then
2042                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2043         else
2044                 TICS_LIST="$SHLIB_LIST"
2045         fi
2046
2047         TINFO_LDFLAGS="-L${LIB_DIR}"
2048         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2049 fi
2050
2051 if test "$DFT_LWR_MODEL" = shared ; then
2052         case $cf_cv_system_name in
2053         (cygwin*|msys*)
2054                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
2055                 TINFO_SUFFIX=.dll
2056                 ;;
2057         esac
2058 fi
2059
2060 AC_SUBST(TINFO_ARG_SUFFIX)
2061 AC_SUBST(TINFO_DEP_SUFFIX)
2062 AC_SUBST(TINFO_LIB_SUFFIX)
2063 AC_SUBST(TINFO_LDFLAGS)
2064 AC_SUBST(TINFO_LIBS)
2065
2066 if test "x$with_dlsym" = xyes ; then
2067         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
2068 fi
2069
2070 if test "$DFT_LWR_MODEL" = "libtool"; then
2071         OBJEXT=lo
2072 fi
2073
2074 # needed for Ada95
2075 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
2076 AC_SUBST(TINFO_LDFLAGS2)
2077
2078 case $DFT_LWR_MODEL in
2079 (normal|debug|profile)
2080         CF_LDFLAGS_STATIC
2081         ;;
2082 esac
2083
2084 AC_MSG_CHECKING(where we will install curses.h)
2085 AC_SUBST(includesubdir)
2086 includesubdir=
2087 if test "$with_overwrite" = no && \
2088  ( test "x$includedir" = 'x${prefix}/include' || \
2089    test "x$includedir" = "x${prefix}/include" )
2090 then
2091         includesubdir="/ncurses${USE_LIB_SUFFIX}"
2092 fi
2093 AC_MSG_RESULT(${includedir}${includesubdir})
2094
2095 ### Resolve a conflict between normal and wide-curses by forcing applications
2096 ### that will need libutf8 to add it to their configure script.
2097 if test "$with_overwrite" != no ; then
2098 if test "$NCURSES_LIBUTF8" = 1 ; then
2099         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
2100         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
2101 fi
2102 fi
2103 WITH_OVERWRITE=$with_overwrite
2104
2105 AC_SUBST(WITH_OVERWRITE)
2106 AC_SUBST(TICS_LIST)
2107 AC_SUBST(TINFO_LIST)
2108 AC_SUBST(SHLIB_LIST)
2109
2110 # used to separate tack out of the tree
2111 NCURSES_TREE=
2112 AC_SUBST(NCURSES_TREE)
2113
2114 ### predefined stuff for the test programs
2115 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
2116
2117 ### Construct the list of subdirectories for which we'll customize makefiles
2118 ### with the appropriate compile-rules.
2119
2120 CF_SRC_MODULES($modules_to_build)
2121
2122 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2123    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${USE_CFG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
2124    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${USE_CFG_SUFFIX}-config.1:man/MKada_config.in"
2125 fi
2126
2127 CF_DIRS_TO_MAKE
2128
2129 # symbols that differ when compiling Ada95 by itself.
2130 NCURSES_SHLIB2=$SHELL' $(top_srcdir)/misc/shlib'
2131 AC_SUBST(NCURSES_SHLIB2)
2132
2133 # values to use as strings
2134 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
2135
2136 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
2137
2138 ### Now that we're done running tests, add the compiler-warnings, if any
2139 CF_ADD_CFLAGS($EXTRA_CFLAGS)
2140
2141 ### Define substitutions for header files to avoid name-pollution
2142 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
2143 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
2144 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
2145 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
2146
2147 ################################################################################
2148 test "x$use_database" = xyes && \
2149 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
2150
2151 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
2152 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${USE_CFG_SUFFIX}-config.1:man/MKncu_config.in"
2153
2154 if test "x$enable_pc_files" = xyes && test -z "$MAKE_PC_FILES" ; then
2155 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
2156 fi
2157 AC_SUBST(cross_compiling)
2158
2159 AC_PATH_PROG(TIC_PATH,tic,unknown,$PATH:/usr/local/ncurses/bin)
2160 if test -n "$FALLBACK_LIST"
2161 then
2162         if test "$TIC_PATH" = unknown
2163         then
2164                 AC_MSG_WARN(no tic program found for fallbacks)
2165         fi
2166 fi
2167 AC_SUBST(TIC_PATH)
2168
2169 if test "x$cf_with_tests" != xno ; then
2170         MAKE_TESTS=
2171 else
2172         MAKE_TESTS="#"
2173 fi
2174 AC_SUBST(MAKE_TESTS)
2175
2176 ADAHTML_DIR=../../doc/html/ada
2177 AC_SUBST(ADAHTML_DIR)
2178
2179 # these could be configurable, but are not currently
2180 PANEL_NAME=panel
2181 MENU_NAME=menu
2182 FORM_NAME=form
2183 CXX_NAME=ncurses++
2184
2185 AC_SUBST(PANEL_NAME)
2186 AC_SUBST(MENU_NAME)
2187 AC_SUBST(FORM_NAME)
2188 AC_SUBST(CXX_NAME)
2189
2190 # workaround for OS/2 (20151017)
2191 case $cf_cv_system_name in
2192 (os2*)
2193         LIBTOOL_OPTS_CXX="-os2dllname ncurs++"
2194         ;;
2195 (*)
2196         LIBTOOL_OPTS_CXX=
2197         ;;
2198 esac
2199 AC_SUBST(LIBTOOL_OPTS_CXX)
2200
2201 # workaround for g++ versus Solaris (20131116)
2202 case $cf_cv_system_name in
2203 (solaris2*)
2204         case "x$CPPFLAGS" in
2205         (*-D_XOPEN_SOURCE_EXTENDED*)
2206                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
2207                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
2208                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
2209                 ;;
2210         esac
2211         ;;
2212 esac
2213
2214 # Help to automatically enable the extended curses features when using either
2215 # the *-config or the ".pc" files by adding defines.
2216 AC_MSG_CHECKING(for defines to add to ncurses${USE_CFG_SUFFIX}-config script)
2217 PKG_CFLAGS=
2218 for cf_loop1 in $CPPFLAGS_after_XOPEN
2219 do
2220         cf_found=no
2221         for cf_loop2 in $CPPFLAGS_before_XOPEN
2222         do
2223                 if test "x$cf_loop1" = "x$cf_loop2"
2224                 then
2225                         cf_found=yes
2226                         break
2227                 fi
2228         done
2229         test "$cf_found" = no && PKG_CFLAGS="$PKG_CFLAGS $cf_loop1"
2230 done
2231 AC_MSG_RESULT($PKG_CFLAGS)
2232 AC_SUBST(PKG_CFLAGS)
2233
2234 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
2235 case "x$NCURSES_OSPEED" in
2236 (*short*)
2237         cf_compatible=1
2238         ;;
2239 (*)
2240         cf_compatible=0
2241         ;;
2242 esac
2243 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
2244
2245 case "x$cf_cv_typeof_chtype" in
2246 (xshort|xint|xlong)
2247         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
2248         ;;
2249 esac
2250
2251 case "x$cf_cv_typeof_mmask_t" in
2252 (xshort|xint|xlong)
2253         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2254         ;;
2255 esac
2256
2257 # substitute into misc/Makefile to suppress
2258 # (un)install.data from the
2259 # (un)install rules.
2260 if test "x$cf_with_db_install" = "xno"; then
2261         MISC_INSTALL_DATA=
2262         MISC_UNINSTALL_DATA=
2263 else
2264         MISC_INSTALL_DATA=install.data
2265         MISC_UNINSTALL_DATA=uninstall.data
2266 fi
2267 AC_SUBST(MISC_INSTALL_DATA)
2268 AC_SUBST(MISC_UNINSTALL_DATA)
2269
2270 SUB_SCRIPTS=
2271
2272 dnl Override the package used for exported symbols
2273 if test -n "$PACKAGE"
2274 then
2275         PACKAGE="${PACKAGE}${DFT_ARG_SUFFIX}"
2276         export PACKAGE
2277         echo "package: $PACKAGE"
2278 fi
2279
2280 UNALTERED_SYMS=
2281 cf_filter_syms=no
2282
2283 if test -n "$RESULTING_SYMS"
2284 then
2285         cf_filter_syms=$cf_dft_filter_syms
2286         CF_VERBOSE(will map symbols to ABI=$cf_cv_abi_version)
2287 fi
2288
2289 if test "x$WILDCARD_SYMS" = xno
2290 then
2291         cf_filter_syms=yes
2292 fi
2293
2294 test "x$cf_with_trace" = xyes && NCURSES_INLINE=
2295
2296 UNALTERED_SYMS=`echo "$RESULTING_SYMS" | sed -e 's/\\$/\\\\$/g'`
2297 if test $cf_filter_syms = yes
2298 then
2299         RESULTING_SYMS=resulting.map
2300 fi
2301 AC_SUBST(UNALTERED_SYMS)
2302
2303 if test "x$cross_compiling" = xyes ; then
2304         ADAGEN_LDFLAGS='$(CROSS_LDFLAGS)'
2305         CHECK_BUILD="#"
2306 else
2307         ADAGEN_LDFLAGS='$(NATIVE_LDFLAGS)'
2308         CHECK_BUILD=
2309 fi
2310 AC_SUBST(ADAGEN_LDFLAGS)
2311 AC_SUBST(CHECK_BUILD)
2312
2313 AC_DEFINE(HAVE_CURSES_DATA_BOOLNAMES,1,[definition needed for in-tree build of tack])
2314
2315 AC_OUTPUT( \
2316         include/MKterm.h.awk \
2317         include/curses.head:include/curses.h.in \
2318         include/ncurses_dll.h \
2319         include/termcap.h \
2320         include/unctrl.h \
2321         $SUB_SCRIPTS \
2322         $SUB_MAKEFILES \
2323         Makefile,[
2324 if test "x$cf_with_tests" != xno ; then
2325         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2326 fi
2327 CF_LIB_RULES($SRC_SUBDIRS)
2328
2329 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2330 if test -z "$USE_OLD_MAKERULES" ; then
2331         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
2332 fi
2333 fi
2334 ],[
2335 ### Special initialization commands, used to pass information from the
2336 ### configuration-run into config.status
2337
2338 AWK="$AWK"
2339 ALTERNATE_SYMS="$ALTERNATE_SYMS"
2340 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2341 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2342 ECHO_LD="$ECHO_LD"
2343 EXTRA_SUFFIX="$EXTRA_SUFFIX"
2344 LDCONFIG="$LDCONFIG"
2345 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2346 LIB_NAME="$LIB_NAME"
2347 LIB_PREFIX="$LIB_PREFIX"
2348 LIB_SUBSETS="$LIB_SUBSETS"
2349 LIB_SUFFIX="$LIB_SUFFIX"
2350 LIB_TRACING="$LIB_TRACING"
2351 LN_S="$LN_S"
2352 MAKE_TERMINFO="$MAKE_TERMINFO"
2353 NCURSES_MAJOR="$NCURSES_MAJOR"
2354 NCURSES_MINOR="$NCURSES_MINOR"
2355 NCURSES_OSPEED="$NCURSES_OSPEED"
2356 NCURSES_PATCH="$NCURSES_PATCH"
2357 SRC_SUBDIRS="$SRC_SUBDIRS"
2358 TERMINFO="$TERMINFO"
2359 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2360 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2361 TICS_NAME="$TICS_NAME"
2362 TICS_SUFFIX="$TICS_SUFFIX"
2363 TIC_PATH="$TIC_PATH"
2364 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2365 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2366 TINFO_NAME="$TINFO_NAME"
2367 TINFO_SUFFIX="$TINFO_SUFFIX"
2368 UNALTERED_SYMS="$UNALTERED_SYMS"
2369 USE_ARG_SUFFIX="$USE_ARG_SUFFIX"
2370 USE_CFG_SUFFIX="$USE_CFG_SUFFIX"
2371 USE_LIB_SUFFIX="$USE_LIB_SUFFIX"
2372 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2373 WILDCARD_SYMS="$WILDCARD_SYMS"
2374 WITH_CURSES_H="$with_curses_h"
2375 WITH_ECHO="${enable_echo:=yes}"
2376 WITH_OVERWRITE="$with_overwrite"
2377 cf_LIST_MODELS="$cf_list_models"
2378 cf_cv_abi_version="$cf_cv_abi_version"
2379 cf_cv_do_relink="$cf_cv_do_relink"
2380 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2381 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2382 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2383 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2384 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2385 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2386 cf_cv_rel_version="$cf_cv_rel_version"
2387 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2388 cf_cv_shared_soname='$cf_cv_shared_soname'
2389 cf_cv_shlib_version="$cf_cv_shlib_version"
2390 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2391 cf_cv_system_name="$cf_cv_system_name"
2392 cf_cv_term_driver="$with_term_driver"
2393 cf_with_ada="$cf_with_ada"
2394 cf_with_cxx_binding="$cf_with_cxx_binding"
2395 cf_with_db_install="$cf_with_db_install"
2396 cf_with_manpages="$cf_with_manpages"
2397 cf_with_tests="$cf_with_tests"
2398 host="$host"
2399 target="$target"
2400 with_shared_cxx="$with_shared_cxx"
2401
2402 ],cat)dnl
2403 ${MAKE:-make} preinstall