ncurses 5.6 - patch 20070714
[ncurses.git] / configure.in
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2006,2007 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1995-on
30 dnl
31 dnl $Id: configure.in,v 1.421 2007/07/14 15:45:08 tom Exp $
32 dnl Process this file with autoconf to produce a configure script.
33 dnl
34 dnl See http://invisible-island.net/autoconf/ for additional information.
35 dnl
36 dnl ---------------------------------------------------------------------------
37 AC_PREREQ(2.13.20020210)
38 AC_REVISION($Revision: 1.421 $)
39 AC_INIT(ncurses/base/lib_initscr.c)
40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
41
42 CF_TOP_BUILDDIR
43 CF_SUBST_NCURSES_VERSION
44
45 CF_WITH_REL_VERSION(NCURSES)
46 CF_WITH_ABI_VERSION
47
48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
49 AC_ARG_WITH(system-type,
50 [  --with-system-type=XXX  test: override derived host system-type],
51 [AC_MSG_WARN(overriding system type to $withval)
52  cf_cv_system_name=$withval])
53
54 ###     Save the given $CFLAGS to allow user-override.
55 cf_user_CFLAGS="$CFLAGS"
56
57 ###     Default install-location
58 CF_CFG_DEFAULTS
59
60 ###     Checks for programs.
61 AC_PROG_CC
62 CF_GCC_VERSION
63
64 AC_PROG_CPP
65 AC_PROG_GCC_TRADITIONAL
66 CF_PROG_CC_C_O(CC)
67 AC_ISC_POSIX
68 CF_ANSI_CC_REQD
69 CF_PROG_EXT
70 CF_PROG_LDCONFIG
71
72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
73 dnl                             configure script by not letting us test if C++
74 dnl                             is present, making this option necessary.
75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
76 AC_ARG_WITH(cxx,
77         [  --without-cxx           do not adjust ncurses bool to match C++],
78         [cf_with_cxx=$withval],
79         [cf_with_cxx=yes])
80 AC_MSG_RESULT($cf_with_cxx)
81 if test "X$cf_with_cxx" = Xno ; then
82         CXX=""
83         GXX=""
84 else
85         # with autoconf 2.13, we can change the error to a warning:
86         pushdef([AC_MSG_ERROR],
87                 [AC_MSG_RESULT(no)
88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
90         AC_PROG_CXX
91         popdef([AC_MSG_ERROR])dnl
92         # autoconf 2.5x removed the error - by hardcoding it to g++.
93         if test "$CXX" = "g++" ; then
94                 AC_PATH_PROG(CXX,g++)
95         fi
96         if test "$CXX" = "g++" ; then
97                 AC_MSG_WARN(ignoring hardcoded g++)
98                 cf_with_cxx=no; CXX=""; GXX="";
99         fi
100 fi
101
102 CF_GXX_VERSION
103 case $GXX_VERSION in
104 1*|2.[[0-6]]*)
105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
106         # cf_cxx_library=no
107         AC_MSG_WARN(templates do not work)
108         ;;
109 esac
110
111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
112 AC_ARG_WITH(cxx-binding,
113         [  --without-cxx-binding   do not build C++ binding and demo],
114         [cf_with_cxx_binding=$withval],
115         [cf_with_cxx_binding=$cf_with_cxx])
116 AC_MSG_RESULT($cf_with_cxx_binding)
117
118 AC_MSG_CHECKING(if you want to build with Ada95)
119 AC_ARG_WITH(ada,
120         [  --without-ada           suppress check for Ada95, don't build demo],
121         [cf_with_ada=$withval],
122         [cf_with_ada=yes])
123 AC_MSG_RESULT($cf_with_ada)
124
125 AC_MSG_CHECKING(if you want to build programs such as tic)
126 AC_ARG_WITH(progs,
127         [  --without-progs         suppress build with programs (e.g., tic)],
128         [cf_with_progs=$withval],
129         [cf_with_progs=yes])
130 AC_MSG_RESULT($cf_with_progs)
131
132 AC_MSG_CHECKING(if you wish to install curses.h)
133 AC_ARG_WITH(curses-h,
134         [  --without-curses-h      install curses.h as ncurses.h only],
135         [with_curses_h=$withval],
136         [with_curses_h=yes])
137 AC_MSG_RESULT($with_curses_h)
138
139 modules_to_build="ncurses"
140 if test "X$cf_with_progs" != Xno ; then
141 modules_to_build="$modules_to_build progs tack"
142 fi
143 modules_to_build="$modules_to_build panel menu form"
144
145 AC_ARG_PROGRAM
146
147 CF_PROG_AWK
148 CF_PROG_EGREP
149 CF_PROG_INSTALL
150 CF_PROG_LINT
151 AC_PROG_LN_S
152
153 AC_PROG_MAKE_SET
154 CF_MAKE_TAGS
155 CF_MAKEFLAGS
156
157 AC_SYS_LONG_FILE_NAMES
158 CF_MIXEDCASE_FILENAMES
159
160 dnl These are standard among *NIX systems, but not when cross-compiling
161 AC_CHECK_TOOL(RANLIB, ranlib, ':')
162 AC_CHECK_TOOL(LD, ld, ld)
163 AC_CHECK_TOOL(AR, ar, ar)
164 CF_SUBST(archiver options,AR_OPTS,rv)
165
166 dnl Special option for use by system-builders: the install-prefix is used to
167 dnl adjust the location into which the actual install is done, so that an
168 dnl archive can be built without modifying the host system's configuration.
169 AC_MSG_CHECKING(if you have specified an install-prefix)
170 AC_ARG_WITH(install-prefix,
171         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
172         [case "$withval" in #(vi
173         yes|no) #(vi
174                 ;;
175         *)      DESTDIR="$withval"
176                 ;;
177         esac])
178 AC_MSG_RESULT($DESTDIR)
179 AC_SUBST(DESTDIR)
180
181 ###############################################################################
182 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
183 # If we're cross-compiling, allow the user to override the tools and their
184 # options.  The configure script is oriented toward identifying the host
185 # compiler, etc., but we need a build compiler to generate parts of the source.
186 CF_BUILD_CC
187
188 ###############################################################################
189 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
190
191 ### Options to allow the user to specify the set of libraries which are used.
192 ### Use "--without-normal --with-shared" to allow the default model to be
193 ### shared, for example.
194 cf_list_models=""
195 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
196
197 CF_WITH_LIBTOOL
198 if test "$with_libtool" != "no" ; then
199
200 cf_list_models="$cf_list_models libtool"
201
202 else
203
204 AC_MSG_CHECKING(if you want to build shared libraries)
205 AC_ARG_WITH(shared,
206         [  --with-shared           generate shared-libraries],
207         [with_shared=$withval],
208         [with_shared=no])
209 AC_MSG_RESULT($with_shared)
210 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
211
212 AC_MSG_CHECKING(if you want to build static libraries)
213 AC_ARG_WITH(normal,
214         [  --with-normal           generate normal-libraries (default)],
215         [with_normal=$withval],
216         [with_normal=yes])
217 AC_MSG_RESULT($with_normal)
218 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
219
220 AC_MSG_CHECKING(if you want to build debug libraries)
221 AC_ARG_WITH(debug,
222         [  --with-debug            generate debug-libraries (default)],
223         [with_debug=$withval],
224         [with_debug=yes])
225 AC_MSG_RESULT($with_debug)
226 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
227
228 AC_MSG_CHECKING(if you want to build profiling libraries)
229 AC_ARG_WITH(profile,
230         [  --with-profile          generate profile-libraries],
231         [with_profile=$withval],
232         [with_profile=no])
233 AC_MSG_RESULT($with_profile)
234 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
235
236 fi
237
238 ###############################################################################
239
240 AC_MSG_CHECKING(for specified models)
241 test -z "$cf_list_models" && cf_list_models=normal
242 dnl If we use libtool to generate libraries, then it must be the only
243 dnl specified model.
244 test "$with_libtool" != "no" && cf_list_models=libtool
245 AC_MSG_RESULT($cf_list_models)
246
247 ### Use the first model as the default, and save its suffix for use in building
248 ### up test-applications.
249 AC_MSG_CHECKING(for default model)
250 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
251 AC_MSG_RESULT($DFT_LWR_MODEL)
252
253 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
254
255 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
256 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
257
258 TICS_NAME=tic
259 AC_SUBST(TICS_NAME)
260
261 TINFO_NAME=tinfo
262 AC_SUBST(TINFO_NAME)
263
264 LIB_NAME=ncurses
265 AC_SUBST(LIB_NAME)
266
267 LIB_DIR=../lib
268 LIB_2ND=../../lib
269
270 CF_LIB_PREFIX(cf_prefix)
271 LIB_PREFIX=$cf_prefix
272 AC_SUBST(LIB_PREFIX)
273
274 LIB_SUFFIX=
275 AC_SUBST(LIB_SUFFIX)
276
277 ###############################################################################
278
279 AC_MSG_CHECKING(if you want to build a separate terminfo library)
280 AC_ARG_WITH(termlib,
281         [  --with-termlib          generate separate terminfo library],
282         [with_termlib=$withval],
283         [with_termlib=no])
284 AC_MSG_RESULT($with_termlib)
285
286 AC_MSG_CHECKING(if you want to build a separate tic library)
287 AC_ARG_WITH(ticlib,
288         [  --with-ticlib           generate separate tic library],
289         [with_ticlib=$withval],
290         [with_ticlib=no])
291 AC_MSG_RESULT($with_ticlib)
292
293 ### Checks for special libraries, must be done up-front.
294 SHLIB_LIST=""
295 CF_WITH_GPM
296 if test "$with_gpm" != no ; then
297         AC_MSG_CHECKING(if you want to load GPM dynamically)
298         AC_ARG_WITH(dlsym,
299                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
300                 [with_dlsym=$withval],
301                 [with_dlsym=yes])
302         AC_MSG_RESULT($with_dlsym)
303         if test "$with_dlsym" = yes ; then
304                 CF_FUNC_DLSYM
305                 if test "$with_gpm" != yes ; then
306                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
307                         cf_cv_gpm_soname="$with_gpm"
308                 else
309                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
310                 fi
311                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
312                 SHLIB_LIST="-ldl $SHLIB_LIST"
313         else
314                 SHLIB_LIST="-lgpm $SHLIB_LIST"
315         fi
316         AC_DEFINE(HAVE_LIBGPM)
317         CF_CHECK_GPM_WGETCH
318 fi
319
320 CF_WITH_SYSMOUSE
321
322 dnl Not all ports of gcc support the -g option
323
324 if test X"$CC_G_OPT" = X"" ; then
325         CC_G_OPT='-g'
326         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
327 fi
328 AC_SUBST(CC_G_OPT)
329
330 if test X"$CXX_G_OPT" = X"" ; then
331         CXX_G_OPT='-g'
332         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
333 fi
334 AC_SUBST(CXX_G_OPT)
335
336 AC_MSG_CHECKING(for default loader flags)
337 case $DFT_LWR_MODEL in
338 libtool) LD_MODEL=''   ;;
339 normal)  LD_MODEL=''   ;;
340 debug)   LD_MODEL=$CC_G_OPT ;;
341 profile) LD_MODEL='-pg';;
342 shared)  LD_MODEL=''   ;;
343 esac
344 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
345 AC_MSG_RESULT($LD_MODEL)
346
347 case $DFT_LWR_MODEL in
348 shared)
349 AC_MSG_CHECKING(if rpath option should be used)
350 AC_ARG_ENABLE(rpath,
351 [  --enable-rpath          use rpath option when generating shared libraries],
352 [cf_cv_ld_rpath=$enableval],
353 [cf_cv_ld_rpath=no])
354 AC_MSG_RESULT($cf_cv_ld_rpath)
355 AC_MSG_CHECKING(if shared libraries should be relinked during install)
356 AC_ARG_ENABLE(rpath,
357 [  --disable-relink        relink shared libraries during install],
358 [cf_cv_do_relink=$enableval],
359 [cf_cv_do_relink=yes])
360 AC_MSG_RESULT($cf_cv_do_relink)
361         ;;
362 esac
363
364 CF_SHARED_OPTS
365 if test "$CC_SHARED_OPTS" = "unknown"; then
366         for model in $cf_list_models; do
367                 if test "$model" = "shared"; then
368                         AC_ERROR(Shared libraries are not supported in this version)
369                 fi
370         done
371 fi
372
373 ###############################################################################
374 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
375
376 ###     use option --disable-overwrite to leave out the link to -lcurses
377 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
378 AC_ARG_ENABLE(overwrite,
379         [  --disable-overwrite     leave out the link to -lcurses],
380         [with_overwrite=$enableval],
381         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
382 AC_MSG_RESULT($with_overwrite)
383
384 AC_MSG_CHECKING(if external terminfo-database is used)
385 AC_ARG_ENABLE(database,
386         [  --disable-database      do not use terminfo, only fallbacks/termcap],
387         [use_database=$enableval],
388         [use_database=yes])
389 AC_MSG_RESULT($use_database)
390
391 case $host_os in #(vi
392 os2*) #(vi
393         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
394         ;;
395 *) #(vi
396         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
397         ;;
398 esac
399 AC_SUBST(TERMINFO_SRC)
400
401 CF_PATHSEP
402 if test "$use_database" != no ; then
403         AC_DEFINE(USE_DATABASE)
404
405         AC_MSG_CHECKING(which terminfo source-file will be installed)
406         AC_ARG_ENABLE(database,
407                 [  --with-database=XXX     specify terminfo source to install],
408                 [TERMINFO_SRC=$withval])
409         AC_MSG_RESULT($TERMINFO_SRC)
410
411         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
412         AC_ARG_WITH(hashed-db,
413                 [  --with-hashed-db        specify hashed-database library],,
414                 [with_hashed_db=no])
415         AC_MSG_RESULT($with_hashed_db)
416 fi
417
418 AC_MSG_CHECKING(for list of fallback descriptions)
419 AC_ARG_WITH(fallbacks,
420         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
421         [with_fallback=$withval],
422         [with_fallback=])
423 AC_MSG_RESULT($with_fallback)
424 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
425 AC_SUBST(FALLBACK_LIST)
426
427 AC_MSG_CHECKING(if you want modern xterm or antique)
428 AC_ARG_WITH(xterm-new,
429         [  --without-xterm-new     specify if xterm terminfo should be old version],
430         [with_xterm_new=$withval],
431         [with_xterm_new=yes])
432 case $with_xterm_new in
433 no)     with_xterm_new=xterm-old;;
434 *)      with_xterm_new=xterm-new;;
435 esac
436 AC_MSG_RESULT($with_xterm_new)
437 WHICH_XTERM=$with_xterm_new
438 AC_SUBST(WHICH_XTERM)
439
440 MAKE_TERMINFO=
441 if test "$use_database" = no ; then
442         TERMINFO="${datadir}/terminfo"
443         MAKE_TERMINFO="#"
444 else
445
446 AC_MSG_CHECKING(for list of terminfo directories)
447 CF_WITH_PATHLIST(terminfo-dirs,
448         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
449         TERMINFO_DIRS,
450         DATADIR/terminfo,
451         ${datadir}/terminfo)
452 AC_MSG_RESULT($TERMINFO_DIRS)
453 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
454
455 AC_MSG_CHECKING(for default terminfo directory)
456 CF_WITH_PATH(default-terminfo-dir,
457         [  --with-default-terminfo-dir=DIR default terminfo directory],
458         TERMINFO,
459         DATADIR/terminfo,
460         ${datadir}/terminfo)
461 AC_MSG_RESULT($TERMINFO)
462 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
463
464 fi
465
466 AC_SUBST(TERMINFO)
467 AC_SUBST(MAKE_TERMINFO)
468
469 ###     use option --disable-big-core to make tic run on small machines
470 ###     We need 4Mb, check if we can allocate 50% more than that.
471 AC_MSG_CHECKING(if big-core option selected)
472 AC_ARG_ENABLE(big-core,
473         [  --disable-big-core      assume machine has little memory],
474         [with_big_core=$enableval],
475         [AC_TRY_RUN([
476 #include <stdlib.h>
477 #include <string.h>
478 int main() {
479         unsigned long n = 6000000L;
480         char *s = malloc(n);
481         if (s != 0)
482                 s[0] = s[n-1] = 0;
483         ${cf_cv_main_return:-return}(s == 0);
484 }],
485         [with_big_core=yes],
486         [with_big_core=no],
487         [with_big_core=no])])
488 AC_MSG_RESULT($with_big_core)
489 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
490
491 ###     use option --enable-termcap to compile in the termcap fallback support
492 AC_MSG_CHECKING(if you want termcap-fallback support)
493 AC_ARG_ENABLE(termcap,
494         [  --enable-termcap        compile in termcap fallback support],
495         [with_termcap=$enableval],
496         [with_termcap=no])
497 AC_MSG_RESULT($with_termcap)
498
499 if test "$with_termcap" != "yes" ; then
500         if test "$use_database" = no ; then
501                 if test -z "$with_fallback" ; then
502                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
503                 fi
504         fi
505         AC_DEFINE(PURE_TERMINFO)
506 else
507
508 if test "$with_ticlib" != no ; then
509         AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
510 fi
511
512 AC_DEFINE(USE_TERMCAP)
513 AC_MSG_CHECKING(for list of termcap files)
514 CF_WITH_PATHLIST(termpath,
515         [  --with-termpath=XXX     specify list of termcap files],
516         TERMPATH,
517         /etc/termcap:/usr/share/misc/termcap)
518 AC_MSG_RESULT($TERMPATH)
519 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
520
521 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
522 AC_MSG_CHECKING(if fast termcap-loader is needed)
523 AC_ARG_ENABLE(getcap,
524         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
525         [with_getcap=$enableval],
526         [with_getcap=no])
527 AC_MSG_RESULT($with_getcap)
528 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
529
530 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
531 AC_ARG_ENABLE(getcap-cache,
532         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
533         [with_getcap_cache=$enableval],
534         [with_getcap_cache=no])
535 AC_MSG_RESULT($with_getcap_cache)
536 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
537
538 fi
539
540 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
541 AC_MSG_CHECKING(if ~/.terminfo is wanted)
542 AC_ARG_ENABLE(home-terminfo,
543         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
544         [with_home_terminfo=$enableval],
545         [with_home_terminfo=yes])
546 AC_MSG_RESULT($with_home_terminfo)
547 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
548
549 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
550 AC_ARG_ENABLE(root-environ,
551         [  --disable-root-environ  restrict environment when running as root],
552         [with_root_environ=$enableval],
553         [with_root_environ=yes])
554 AC_MSG_RESULT($with_root_environ)
555 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
556
557 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
558 ###   to reduce storage requirements for the terminfo database.
559 CF_LINK_FUNCS
560
561 with_links=no
562 with_symlinks=no
563
564 # soft links (symbolic links) are useful for some systems where hard links do
565 # not work, or to make it simpler to copy terminfo trees around.
566 if test "$ac_cv_func_symlink" = yes ; then
567     AC_MSG_CHECKING(if tic should use symbolic links)
568     AC_ARG_ENABLE(symlinks,
569         [  --enable-symlinks       make tic use symbolic links not hard links],
570         [with_symlinks=$enableval],
571         [with_symlinks=no])
572     AC_MSG_RESULT($with_symlinks)
573 fi
574
575 # If we have hard links and did not choose to use soft links instead, there is
576 # no reason to make this choice optional - use the hard links.
577 if test "$with_symlinks" = no ; then
578     AC_MSG_CHECKING(if tic should use hard links)
579     if test "$ac_cv_func_link" = yes ; then
580         with_links=yes
581     else
582         with_links=no
583     fi
584     AC_MSG_RESULT($with_links)
585 fi
586
587 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
588 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
589
590 ###   use option --enable-broken-linker to force on use of broken-linker support
591 AC_MSG_CHECKING(if you want broken-linker support code)
592 AC_ARG_ENABLE(broken_linker,
593         [  --enable-broken_linker  compile with broken-linker support code],
594         [with_broken_linker=$enableval],
595         [with_broken_linker=${BROKEN_LINKER-no}])
596 AC_MSG_RESULT($with_broken_linker)
597
598 BROKEN_LINKER=0
599 if test "$with_broken_linker" = yes ; then
600         AC_DEFINE(BROKEN_LINKER)
601         BROKEN_LINKER=1
602 elif test "$DFT_LWR_MODEL" = shared ; then
603         case $cf_cv_system_name in #(vi
604         cygwin*)
605                 AC_DEFINE(BROKEN_LINKER)
606                 BROKEN_LINKER=1
607                 CF_VERBOSE(cygwin linker is broken anyway)
608                 ;;
609         esac
610 fi
611 AC_SUBST(BROKEN_LINKER)
612
613 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
614 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
615 AC_ARG_ENABLE(bsdpad,
616         [  --enable-bsdpad         recognize BSD-style prefix padding],
617         [with_bsdpad=$enableval],
618         [with_bsdpad=no])
619 AC_MSG_RESULT($with_bsdpad)
620 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
621
622 ###   use option --enable-widec to turn on use of wide-character support
623 NCURSES_CH_T=chtype
624 NCURSES_LIBUTF8=0
625
626 NEED_WCHAR_H=0
627 NCURSES_MBSTATE_T=0
628 NCURSES_WCHAR_T=0
629 NCURSES_WINT_T=0
630
631 # Check to define _XOPEN_SOURCE "automatically"
632 CF_XOPEN_SOURCE
633
634 # Work around breakage on OS X
635 CF_SIGWINCH
636
637 # Checks for CODESET support.
638 AM_LANGINFO_CODESET
639
640 # use these variables to work around a defect in gcc's fixincludes.
641 NCURSES_OK_WCHAR_T=
642 NCURSES_OK_WINT_T=
643
644 AC_MSG_CHECKING(if you want wide-character code)
645 AC_ARG_ENABLE(widec,
646         [  --enable-widec          compile with wide-char/UTF-8 code],
647         [with_widec=$enableval],
648         [with_widec=no])
649 AC_MSG_RESULT($with_widec)
650 if test "$with_widec" = yes ; then
651         LIB_SUFFIX="w${LIB_SUFFIX}"
652         AC_DEFINE(USE_WIDEC_SUPPORT)
653         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
654         # with_overwrite=no
655         NCURSES_CH_T=cchar_t
656         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc)
657         if test "$ac_cv_func_putwc" != yes ; then
658                 CF_LIBUTF8
659                 if test "$cf_cv_libutf8" = yes ; then
660                         NCURSES_LIBUTF8=1
661                 fi
662         fi
663         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
664         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
665         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
666
667         if test "$NCURSES_MBSTATE_T" != 0; then
668                 AC_DEFINE(NEED_MBSTATE_T_DEF)
669         fi
670 fi
671 AC_SUBST(NCURSES_CH_T)
672 AC_SUBST(NCURSES_LIBUTF8)
673
674 AC_SUBST(NEED_WCHAR_H)
675 AC_SUBST(NCURSES_MBSTATE_T)
676 AC_SUBST(NCURSES_WCHAR_T)
677 AC_SUBST(NCURSES_WINT_T)
678
679 AC_SUBST(NCURSES_OK_WCHAR_T)
680 AC_SUBST(NCURSES_OK_WINT_T)
681
682 ###   use option --disable-lp64 to allow long chtype
683 case $cf_cv_abi_version in
684 [[345]]*)
685         default_with_lp64=no
686         ;;
687 *)
688         default_with_lp64=yes
689         ;;
690 esac
691
692 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
693 AC_ARG_ENABLE(lp64,
694         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
695         [with_lp64=$enableval],
696         [with_lp64=$default_with_lp64])
697 AC_MSG_RESULT($with_lp64)
698
699 if test "$with_lp64" = yes ; then
700         cf_cv_enable_lp64=1
701 else
702         cf_cv_enable_lp64=0
703 fi
704 AC_SUBST(cf_cv_enable_lp64)
705
706 CF_LARGEFILE
707
708 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
709 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
710 AC_ARG_ENABLE(tparm-varargs,
711         [  --disable-tparm-varargs compile tparm() without varargs interface],
712         [with_tparm_varargs=$enableval],
713         [with_tparm_varargs=yes])
714 AC_MSG_RESULT($with_tparm_varargs)
715 NCURSES_TPARM_VARARGS=0
716 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
717 AC_SUBST(NCURSES_TPARM_VARARGS)
718
719 ###   use option --with-bool to override bool's type
720 AC_MSG_CHECKING(for type of bool)
721 AC_ARG_WITH(bool,
722         [  --with-bool=TYPE        override fallback type of bool variable],
723         [NCURSES_BOOL="$withval"],
724         [NCURSES_BOOL=auto])
725 AC_MSG_RESULT($NCURSES_BOOL)
726 AC_SUBST(NCURSES_BOOL)
727
728 AC_MSG_CHECKING(for alternate terminal capabilities file)
729 AC_ARG_WITH(caps,
730         [  --with-caps=alt         compile with alternate Caps file],
731         [TERMINFO_CAPS=Caps.$withval],
732         [TERMINFO_CAPS=Caps])
733 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
734 AC_MSG_RESULT($TERMINFO_CAPS)
735 AC_SUBST(TERMINFO_CAPS)
736
737 ###   use option --with-chtype to override chtype's type
738 AC_MSG_CHECKING(for type of chtype)
739 AC_ARG_WITH(chtype,
740         [  --with-chtype=TYPE      override type of chtype],
741         [NCURSES_CHTYPE="$withval"],
742         [NCURSES_CHTYPE=auto])
743 AC_MSG_RESULT($NCURSES_CHTYPE)
744
745 ###   use option --with-ospeed to override ospeed's type
746 AC_MSG_CHECKING(for type of ospeed)
747 AC_ARG_WITH(ospeed,
748         [  --with-ospeed=TYPE      override type of ospeed variable],
749         [NCURSES_OSPEED="$withval"],
750         [NCURSES_OSPEED=short])
751 AC_MSG_RESULT($NCURSES_OSPEED)
752 AC_SUBST(NCURSES_OSPEED)
753
754 ###   use option --with-mmask-t to override mmask_t's type
755 AC_MSG_CHECKING(for type of mmask_t)
756 AC_ARG_WITH(mmask-t,
757         [  --with-mmask-t=TYPE     override type of mmask_t],
758         [NCURSES_MMASK_T="$withval"],
759         [NCURSES_MMASK_T=auto])
760 AC_MSG_RESULT($NCURSES_MMASK_T)
761
762 ### Enable compiling-in rcs id's
763 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
764 AC_ARG_WITH(rcs-ids,
765         [  --with-rcs-ids          compile-in RCS identifiers],
766         [with_rcs_ids=$withval],
767         [with_rcs_ids=no])
768 AC_MSG_RESULT($with_rcs_ids)
769 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
770
771 ###############################################################################
772 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tic toe tput ])
773
774 ###############################################################################
775 CF_HELP_MESSAGE(Extensions:)
776
777 ### Note that some functions (such as const) are normally disabled anyway.
778 AC_MSG_CHECKING(if you want to build with function extensions)
779 AC_ARG_ENABLE(ext-funcs,
780         [  --disable-ext-funcs     disable function-extensions],
781         [with_ext_funcs=$enableval],
782         [with_ext_funcs=yes])
783 AC_MSG_RESULT($with_ext_funcs)
784 if test "$with_ext_funcs" = yes ; then
785         NCURSES_EXT_FUNCS=1
786         AC_DEFINE(HAVE_CURSES_VERSION)
787         AC_DEFINE(HAVE_HAS_KEY)
788         AC_DEFINE(HAVE_RESIZETERM)
789         AC_DEFINE(HAVE_RESIZE_TERM)
790         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
791         AC_DEFINE(HAVE_WRESIZE)
792         AC_DEFINE(NCURSES_EXT_FUNCS)
793 else
794         NCURSES_EXT_FUNCS=0
795 fi
796 AC_SUBST(NCURSES_EXT_FUNCS)
797
798 ###   use option --enable-const to turn on use of const beyond that in XSI.
799 AC_MSG_CHECKING(for extended use of const keyword)
800 AC_ARG_ENABLE(const,
801         [  --enable-const          compile with extra/non-standard const],
802         [with_ext_const=$enableval],
803         [with_ext_const=no])
804 AC_MSG_RESULT($with_ext_const)
805 NCURSES_CONST='/*nothing*/'
806 if test "$with_ext_const" = yes ; then
807         NCURSES_CONST=const
808 fi
809 AC_SUBST(NCURSES_CONST)
810
811 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
812 AC_ARG_ENABLE(no-padding,
813         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
814         [with_no_padding=$enableval],
815         [with_no_padding=$with_ext_funcs])
816 AC_MSG_RESULT($with_no_padding)
817 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
818
819 AC_CHECK_SIZEOF([signed char], 0)
820 if test "$ac_cv_sizeof_signed_char" = 1 ; then
821         NCURSES_SBOOL="signed char"
822 else
823         NCURSES_SBOOL="char"
824 fi
825 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
826 AC_ARG_ENABLE(signed-char,
827         [  --enable-signed-char    compile using signed Boolean's in term.h],
828         [with_signed_char=$enableval],
829         [with_signed_char=no])
830 AC_MSG_RESULT($with_signed_char)
831 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
832 AC_SUBST(NCURSES_SBOOL)
833
834 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
835 AC_MSG_CHECKING(if you want SIGWINCH handler)
836 AC_ARG_ENABLE(sigwinch,
837         [  --enable-sigwinch       compile with SIGWINCH handler],
838         [with_sigwinch=$enableval],
839         [with_sigwinch=$with_ext_funcs])
840 AC_MSG_RESULT($with_sigwinch)
841 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
842
843 ###   use option --enable-tcap-names to allow user to define new capabilities
844 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
845 AC_ARG_ENABLE(tcap-names,
846         [  --enable-tcap-names     compile with user-definable terminal capabilities],
847         [with_tcap_names=$enableval],
848         [with_tcap_names=$with_ext_funcs])
849 AC_MSG_RESULT($with_tcap_names)
850 NCURSES_XNAMES=0
851 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
852 AC_SUBST(NCURSES_XNAMES)
853
854 ###############################################################################
855 # These options are relatively safe to experiment with.
856 CF_HELP_MESSAGE(Development Code:)
857 AC_MSG_CHECKING(if you want all development code)
858 AC_ARG_WITH(develop,
859         [  --without-develop       disable development options],
860         [with_develop=$withval],
861         [with_develop=no])
862 AC_MSG_RESULT($with_develop)
863
864 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
865 AC_MSG_CHECKING(if you want hard-tabs code)
866 AC_ARG_ENABLE(hard-tabs,
867         [  --enable-hard-tabs      compile with hard-tabs code],,
868         [enable_hard_tabs=$with_develop])
869 AC_MSG_RESULT($enable_hard_tabs)
870 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
871
872 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
873 AC_MSG_CHECKING(if you want limited support for xmc)
874 AC_ARG_ENABLE(xmc-glitch,
875         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
876         [enable_xmc_glitch=$with_develop])
877 AC_MSG_RESULT($enable_xmc_glitch)
878 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
879
880 ###############################################################################
881 # These are just experimental, probably should not be in a package:
882 CF_HELP_MESSAGE(Experimental Code:)
883
884 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
885 AC_ARG_ENABLE(assumed-color,
886         [  --disable-assumed-color do not assume anything about default-colors],
887         [with_assumed_color=$enableval],
888         [with_assumed_color=yes])
889 AC_MSG_RESULT($with_assumed_color)
890 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
891
892 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
893 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
894 AC_ARG_ENABLE(hashmap,
895         [  --disable-hashmap       compile without hashmap scrolling-optimization],
896         [with_hashmap=$enableval],
897         [with_hashmap=yes])
898 AC_MSG_RESULT($with_hashmap)
899 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
900
901 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
902 AC_MSG_CHECKING(if you want colorfgbg code)
903 AC_ARG_ENABLE(colorfgbg,
904         [  --enable-colorfgbg      compile with $COLORFGBG code],
905         [with_colorfgbg=$enableval],
906         [with_colorfgbg=no])
907 AC_MSG_RESULT($with_colorfgbg)
908 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
909
910 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
911 AC_MSG_CHECKING(if you want to use experimental extended colors)
912 AC_ARG_ENABLE(ext-colors,
913         [  --enable-ext-colors     compile for experimental 256-color support],
914         [with_ext_colors=$enableval],
915         [with_ext_colors=no])
916 AC_MSG_RESULT($with_ext_colors)
917 NCURSES_EXT_COLORS=0
918 if test "$with_ext_colors" = yes ; then
919         if test "$with_widec" != yes ; then
920                 AC_MSG_ERROR(This option applies only to wide-character library)
921         else
922                 # cannot be ABI 5 since it changes sizeof(cchar_t)
923                 CF_NCURSES_ABI_6
924         fi
925         NCURSES_EXT_COLORS=1
926         AC_DEFINE(NCURSES_EXT_COLORS)
927 fi
928 AC_SUBST(NCURSES_EXT_COLORS)
929
930 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
931 AC_MSG_CHECKING(if you want to use experimental extended mouse encoding)
932 AC_ARG_ENABLE(ext-mouse,
933         [  --enable-ext-mouse      compile for experimental mouse-encoding],
934         [with_ext_mouse=$enableval],
935         [with_ext_mouse=no])
936 AC_MSG_RESULT($with_ext_mouse)
937 NCURSES_MOUSE_VERSION=1
938 if test "$with_ext_mouse" = yes ; then
939         NCURSES_MOUSE_VERSION=2
940         CF_NCURSES_ABI_6
941 fi
942 AC_SUBST(NCURSES_MOUSE_VERSION)
943
944 # Reentrant code has to be opaque; there's little advantage to making ncurses
945 # opaque outside of that, so there is no --enable-opaque option.
946 AC_MSG_CHECKING(if you want experimental reentrant code)
947 AC_ARG_ENABLE(reentrant,
948         [  --enable-reentrant      compile with experimental reentrant code],
949         [with_reentrant=$enableval],
950         [with_reentrant=no])
951 AC_MSG_RESULT($with_reentrant)
952 if test "$with_reentrant" = yes ; then
953         cf_cv_enable_reentrant=1
954         cf_cv_enable_opaque="NCURSES_INTERNALS"
955         NCURSES_OPAQUE=1
956         NCURSES_SIZE_T=int
957         LIB_SUFFIX="t${LIB_SUFFIX}"
958         AC_DEFINE(USE_REENTRANT)
959         CF_NCURSES_ABI_6
960 else
961         cf_cv_enable_reentrant=0
962         cf_cv_enable_opaque="NCURSES_OPAQUE"
963         NCURSES_OPAQUE=0
964         NCURSES_SIZE_T=short
965 fi
966 AC_SUBST(cf_cv_enable_reentrant)
967 AC_SUBST(cf_cv_enable_opaque)
968 AC_SUBST(NCURSES_OPAQUE)
969 AC_SUBST(NCURSES_SIZE_T)
970
971 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
972 AC_ARG_ENABLE(safe-sprintf,
973         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
974         [with_safe_sprintf=$enableval],
975         [with_safe_sprintf=no])
976 AC_MSG_RESULT($with_safe_sprintf)
977 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
978
979 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
980 # when hashmap is used scroll hints are useless
981 if test "$with_hashmap" = no ; then
982 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
983 AC_ARG_ENABLE(scroll-hints,
984         [  --disable-scroll-hints  compile without scroll-hints code],
985         [with_scroll_hints=$enableval],
986         [with_scroll_hints=yes])
987 AC_MSG_RESULT($with_scroll_hints)
988 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
989 fi
990
991 AC_MSG_CHECKING(if you want experimental wgetch-events code)
992 AC_ARG_ENABLE(wgetch-events,
993         [  --enable-wgetch-events  compile with experimental wgetch-events code],
994         [with_wgetch_events=$enableval],
995         [with_wgetch_events=no])
996 AC_MSG_RESULT($with_wgetch_events)
997 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
998
999 ###############################################################################
1000 CF_HELP_MESSAGE(Testing/development Options:)
1001
1002 ###     use option --disable-echo to suppress full display compiling commands
1003 AC_MSG_CHECKING(if you want to display full commands during build)
1004 AC_ARG_ENABLE(echo,
1005         [  --enable-echo           build: display "compiling" commands (default)],
1006         [with_echo=$enableval],
1007         [with_echo=yes])
1008 if test "$with_echo" = yes; then
1009         ECHO_LINK=
1010 else
1011         ECHO_LINK='@ echo linking $@ ... ;'
1012         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1013         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1014 fi
1015 AC_MSG_RESULT($with_echo)
1016 AC_SUBST(ECHO_LINK)
1017
1018 ###     use option --enable-warnings to turn on all gcc warnings
1019 AC_MSG_CHECKING(if you want to see compiler warnings)
1020 AC_ARG_ENABLE(warnings,
1021         [  --enable-warnings       build: turn on GCC compiler warnings],
1022         [with_warnings=$enableval])
1023 AC_MSG_RESULT($with_warnings)
1024
1025 if test -n "$with_warnings"; then
1026         ADAFLAGS="$ADAFLAGS -gnatg"
1027         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
1028         if test "$cf_with_cxx" = yes ; then
1029                 CF_GXX_WARNINGS(Wno-unused)
1030         fi
1031 fi
1032 CF_GCC_ATTRIBUTES
1033
1034 ###     use option --enable-assertions to turn on generation of assertion code
1035 AC_MSG_CHECKING(if you want to enable runtime assertions)
1036 AC_ARG_ENABLE(assertions,
1037         [  --enable-assertions     test: turn on generation of assertion code],
1038         [with_assertions=$enableval],
1039         [with_assertions=no])
1040 AC_MSG_RESULT($with_assertions)
1041 if test -n "$GCC"
1042 then
1043         if test "$with_assertions" = no
1044         then
1045                 AC_DEFINE(NDEBUG)
1046                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1047         else
1048                 ADAFLAGS="$ADAFLAGS -gnata"
1049         fi
1050 fi
1051
1052 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1053 CF_DISABLE_LEAKS
1054 AC_DEFINE(HAVE_NC_ALLOC_H)
1055
1056 ###     use option --enable-expanded to generate certain macros as functions
1057 AC_ARG_ENABLE(expanded,
1058         [  --enable-expanded       test: generate functions for certain macros],
1059         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1060
1061 ###     use option --disable-macros to suppress macros in favor of functions
1062 AC_ARG_ENABLE(macros,
1063         [  --disable-macros        test: use functions rather than macros],
1064         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1065
1066 # Normally we only add trace() to the debug-library.  Allow this to be
1067 # extended to all models of the ncurses library:
1068 cf_all_traces=no
1069 case "$CFLAGS $CPPFLAGS" in
1070 *-DTRACE*)
1071         cf_all_traces=yes
1072         ;;
1073 esac
1074
1075 AC_MSG_CHECKING(whether to add trace feature to all models)
1076 AC_ARG_WITH(trace,
1077 [  --with-trace            test: add trace() function to all models of ncurses],
1078 [cf_with_trace=$withval],
1079 [cf_with_trace=$cf_all_traces])
1080 AC_MSG_RESULT($cf_with_trace)
1081
1082 if test "$cf_with_trace" = yes ; then
1083         LIB_TRACING=all
1084         ADA_TRACE=TRUE
1085         CF_ADD_CFLAGS(-DTRACE)
1086 else
1087         LIB_TRACING=DEBUG
1088         ADA_TRACE=FALSE
1089 fi
1090
1091 AC_SUBST(ADA_TRACE)
1092
1093 ###     Checks for libraries.
1094 AC_CHECK_FUNC(gettimeofday,
1095         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1096
1097 AC_CHECK_LIB(bsd, gettimeofday,
1098         AC_DEFINE(HAVE_GETTIMEOFDAY)
1099         LIBS="$LIBS -lbsd")])dnl CLIX: bzero, select, gettimeofday
1100
1101 CF_MATH_LIB(MATH_LIB,sin(x))
1102 AC_SUBST(MATH_LIB)
1103
1104 ###     Checks for header files.
1105 AC_STDC_HEADERS
1106 AC_HEADER_DIRENT
1107 AC_HEADER_TIME
1108 CF_REGEX
1109
1110 dnl These are some other potentially nonportable headers.
1111 AC_CHECK_HEADERS( \
1112 fcntl.h \
1113 getopt.h \
1114 limits.h \
1115 locale.h \
1116 poll.h \
1117 sys/bsdtypes.h \
1118 sys/ioctl.h \
1119 sys/param.h \
1120 sys/poll.h \
1121 sys/select.h \
1122 sys/time.h \
1123 sys/times.h \
1124 ttyent.h \
1125 unistd.h \
1126 wctype.h \
1127 )
1128
1129 # check for ISC (this may also define _POSIX_SOURCE)
1130 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1131 if test "$ISC" = yes ; then
1132         AC_CHECK_LIB(cposix,main)
1133         AC_CHECK_LIB(inet,bzero,LIBS="$LIBS -linet")dnl also 'select()'
1134 fi
1135
1136 CF_SYS_TIME_SELECT
1137
1138 ###     checks for compiler characteristics
1139 AC_LANG_C
1140 AC_C_CONST
1141 CF_C_INLINE(NCURSES_INLINE,1200)
1142 CF_SIG_ATOMIC_T
1143
1144 if test $NCURSES_CHTYPE = auto ; then
1145         CF_TYPEOF_CHTYPE
1146 else
1147         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1148 fi
1149 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1150 AC_SUBST(cf_cv_typeof_chtype)
1151
1152 CF_UNSIGNED_LITERALS
1153 cf_cv_1UL="1"
1154 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1155 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1156 AC_SUBST(cf_cv_1UL)
1157
1158 if test $NCURSES_MMASK_T = auto ; then
1159         cf_cv_typeof_mmask_t=long
1160 else
1161         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1162 fi
1163 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1164 AC_SUBST(cf_cv_typeof_mmask_t)
1165
1166 ###     Checks for external-data
1167 CF_ERRNO
1168 CF_LINK_DATAONLY
1169
1170 ###     Checks for library functions.
1171 AC_CHECK_FUNCS( \
1172 getcwd \
1173 getegid \
1174 geteuid \
1175 getttynam \
1176 issetugid \
1177 poll \
1178 remove \
1179 select \
1180 setbuf \
1181 setbuffer \
1182 setvbuf \
1183 sigaction \
1184 sigvec \
1185 strdup \
1186 strstr \
1187 tcgetpgrp \
1188 times \
1189 vsnprintf \
1190 )
1191 if test "$with_getcap" = "yes" ; then
1192         CF_CGETENT
1193 fi
1194
1195 CF_ISASCII
1196 CF_STRUCT_SIGACTION
1197 CF_FUNC_NANOSLEEP
1198 CF_FUNC_TERMIOS
1199 CF_FUNC_VSSCANF
1200 CF_MKSTEMP
1201
1202 # setup for prototype of fallback for vsscanf()
1203 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1204
1205 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1206 if test "$cross_compiling" = yes ; then
1207         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1208 else
1209         AC_FUNC_SETVBUF_REVERSED
1210 fi
1211 AC_TYPE_SIGNAL
1212 CF_TYPE_SIGACTION
1213 CF_SIZECHANGE
1214 CF_FUNC_MEMMOVE
1215 CF_FUNC_POLL
1216
1217 if test "$with_hashed_db" != no ; then
1218         AC_DEFINE(USE_HASHED_DB)
1219         CF_HASHED_DB
1220 fi
1221
1222 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1223 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1224         CF_STRIP_G_OPT(CFLAGS)
1225         CF_STRIP_G_OPT(CXXFLAGS)
1226 fi
1227
1228 # Just in case, check if the C compiler has a bool type.
1229 CF_BOOL_DECL(cf_cv_cc_bool_type)
1230
1231 # Check for C++ compiler characteristics (and ensure that it's there!)
1232 if test -n "$CXX" ; then
1233         AC_LANG_CPLUSPLUS
1234         CF_STDCPP_LIBRARY
1235         CF_PROG_CC_C_O(CXX)
1236
1237         case $GXX_VERSION in
1238         1*|2.[0-6]*)
1239                 cf_cxx_library=yes
1240                 ;;
1241         *-2.7*|2.7*)
1242                 CF_GPP_LIBRARY
1243                 ;;
1244         *)
1245                 cf_cxx_library=no
1246                 ;;
1247         esac
1248
1249         AC_CHECK_HEADERS(iostream typeinfo)
1250
1251         CF_BOOL_DECL
1252         CF_BOOL_SIZE
1253         CF_ETIP_DEFINES
1254         CF_CPP_PARAM_INIT
1255         CF_CPP_STATIC_CAST
1256
1257         CXX_AR='$(AR)'
1258         CXX_AR_OPTS='$(AR_OPTS)'
1259         case $cf_cv_system_name in #(vi
1260         irix*) #(vi
1261             if test "$GXX" != yes ; then
1262                 CXX_AR='$(CXX)'
1263                 CXX_AR_OPTS='-ar -o'
1264             fi
1265             ;;
1266         sco3.2v5*) #(vi
1267             CXXLDFLAGS="-u main"
1268             ;;
1269         solaris2*)
1270             if test "$GXX" != yes ; then
1271                 CXX_AR='$(CXX)'
1272                 CXX_AR_OPTS='-xar -o'
1273             fi
1274             ;;
1275         esac
1276         AC_SUBST(CXXLDFLAGS)
1277         AC_SUBST(CXX_AR)
1278         AC_SUBST(CXX_AR_OPTS)
1279 else
1280         cf_cxx_library=no
1281         cf_cv_builtin_bool=1
1282
1283         # Just because we are not configuring against C++ right now does not
1284         # mean that a user will not want to use C++.  Some distributors disable
1285         # the C++ portion of this configuration as a shortcut (or just to avoid
1286         # compiling the demo in the c++ directory).  So we need a reasonable
1287         # default for the 'bool' type.
1288         #
1289         # Caveat: since the storage of the bool type is not standardized, it
1290         # may change.
1291
1292         if test "$NCURSES_BOOL" != auto ; then
1293                 cf_cv_type_of_bool=$NCURSES_BOOL
1294                 cf_cv_header_stdbool_h=0
1295         else
1296                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1297                         CF_BOOL_SIZE
1298                 else
1299                         AC_MSG_CHECKING(for fallback type of bool)
1300                         case "$host_cpu" in #(vi
1301                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1302                         *)      cf_cv_type_of_bool=int  ;;
1303                         esac
1304                         AC_MSG_RESULT($cf_cv_type_of_bool)
1305                 fi
1306         fi
1307 fi
1308 AC_SUBST(CXXLIBS)
1309
1310 # If the C compiler did not declare bool, and we did not determine that the C++
1311 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1312 # ncurses library use the same type as C++ bool.  Note that this allows one to
1313 # specify the type of bool in a configure-script option and postpone
1314 # integration with the C++ compiler provided that the types are compatible.
1315 USE_CXX_BOOL=1
1316 if test $cf_cv_cc_bool_type = 1
1317 then
1318         # oops: C has a bool.  Unlikely, but C++ could differ.
1319         USE_CXX_BOOL=0
1320 elif test $cf_cv_builtin_bool = 0
1321 then
1322         # C++ has no bool
1323         USE_CXX_BOOL=0
1324 else
1325         # this is the normal case
1326         USE_CXX_BOOL='defined(__cplusplus)'
1327 fi
1328 AC_SUBST(USE_CXX_BOOL)
1329
1330 CF_HELP_MESSAGE(Ada95 Binding Options:)
1331
1332 dnl If the Ada95 source-tree is present, add that to the build unless it will
1333 dnl not work, or was not requested.
1334 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1335
1336 dnl libtool does not know anything about GNAT, though a change made in 1998
1337 dnl provided for it "someday".  Disable the ada subtree if we are using
1338 dnl libtool -TD 20070714
1339 if test "$cf_with_ada" != "no" ; then
1340     if test "$with_libtool" != "no"; then
1341         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1342         cf_with_ada=no
1343     fi
1344 fi
1345
1346 dnl Check for availability of GNU Ada Translator (GNAT).
1347 dnl At the moment we support no other Ada95 compiler.
1348 if test "$cf_with_ada" != "no" ; then
1349 cf_ada_make=gnatmake
1350 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
1351 if test "$ac_cv_prog_gnat_exists" = no; then
1352    cf_ada_make=
1353 else
1354    CF_GNAT_VERSION
1355    AC_CHECK_PROG(M4_exists, m4, yes, no)
1356    if test "$ac_cv_prog_M4_exists" = no; then
1357       cf_cv_prog_gnat_correct=no
1358       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
1359    fi
1360    if test "$cf_cv_prog_gnat_correct" = yes; then
1361       AC_MSG_CHECKING(if GNAT works)
1362       CF_GNAT_TRY_RUN([procedure conftest;],
1363 [with Text_IO;
1364 with GNAT.OS_Lib;
1365 procedure conftest is
1366 begin
1367    Text_IO.Put ("Hello World");
1368    Text_IO.New_Line;
1369    GNAT.OS_Lib.OS_Exit (0);
1370 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
1371       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
1372    fi
1373 fi
1374 if test "$cf_cv_prog_gnat_correct" = yes; then
1375    ADAFLAGS="-O3 -gnatpn $ADAFLAGS"
1376
1377    AC_MSG_CHECKING(if GNAT pragma Unreferenced works)
1378    CF_GNAT_TRY_LINK([procedure conftest;],
1379 [with Text_IO;
1380 with GNAT.OS_Lib;
1381 procedure conftest is
1382    test : Integer;
1383    pragma Unreferenced (test);
1384 begin
1385    test := 1;
1386    Text_IO.Put ("Hello World");
1387    Text_IO.New_Line;
1388    GNAT.OS_Lib.OS_Exit (0);
1389 end conftest;],[cf_cv_pragma_unreferenced=yes],[cf_cv_pragma_unreferenced=no])
1390    AC_MSG_RESULT($cf_cv_pragma_unreferenced)
1391
1392    # if the pragma is supported, use it (needed in the Trace code).
1393    if test $cf_cv_pragma_unreferenced = yes ; then
1394       PRAGMA_UNREF=TRUE
1395    else
1396       PRAGMA_UNREF=FALSE
1397    fi
1398
1399    AC_ARG_WITH(ada-compiler,
1400         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
1401         [cf_ada_compiler=$withval],
1402         [cf_ada_compiler=gnatmake])
1403
1404    cf_ada_package=terminal_interface
1405
1406    AC_SUBST(cf_ada_make)
1407    AC_SUBST(cf_ada_compiler)
1408    AC_SUBST(cf_ada_package)
1409    AC_SUBST(ADAFLAGS)
1410    AC_SUBST(cf_compile_generics)
1411    AC_SUBST(cf_generic_objects)
1412    AC_SUBST(PRAGMA_UNREF)
1413
1414    CF_WITH_PATH(ada-include,
1415        [  --with-ada-include=DIR  Ada includes are in DIR],
1416        ADA_INCLUDE,
1417        PREFIX/lib/ada/adainclude,
1418        [$]prefix/lib/ada/adainclude)
1419    AC_SUBST(ADA_INCLUDE)
1420
1421    CF_WITH_PATH(ada-objects,
1422        [  --with-ada-objects=DIR  Ada objects are in DIR],
1423        ADA_OBJECTS,
1424        PREFIX/lib/ada/adalib,
1425        [$]prefix/lib/ada/adalib)
1426    AC_SUBST(ADA_OBJECTS)
1427
1428 fi
1429 fi
1430 else
1431    cf_with_ada=no
1432 fi
1433
1434 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1435 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1436 ###
1437 ### ticlib modules may be a separate library, otherwise contained in termlib.
1438 ### termlib modules may be a separate library, otherwise contained in ncurses.
1439 ###
1440 ### The of "+" or " " between the tokens controls the way the script
1441 ### chooses to split module lists into libraries.
1442 ###
1443 ### (see CF_LIB_RULES).
1444 AC_MSG_CHECKING(for library subsets)
1445 LIB_SUBSETS=
1446
1447 if test "$cf_with_progs" = yes || test "$with_ticlib" != no; then
1448         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1449         if test "$with_ticlib" != no ; then
1450                 LIB_SUBSETS="${LIB_SUBSETS} "
1451         else
1452                 LIB_SUBSETS="${LIB_SUBSETS}+"
1453         fi
1454 fi
1455
1456 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1457 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1458 if test "$with_termlib" != no ; then
1459         LIB_SUBSETS="${LIB_SUBSETS} "
1460 else
1461         LIB_SUBSETS="${LIB_SUBSETS}+"
1462 fi
1463
1464 LIB_SUBSETS="${LIB_SUBSETS}base"
1465 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1466 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1467
1468 AC_MSG_RESULT($LIB_SUBSETS)
1469
1470 ### Construct the list of include-directories to be generated
1471 CF_INCLUDE_DIRS
1472 CF_ADA_INCLUDE_DIRS
1473
1474 ### Build up pieces for makefile rules
1475 AC_MSG_CHECKING(default library suffix)
1476 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1477 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1478 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1479
1480 AC_MSG_CHECKING(default library-dependency suffix)
1481 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_DEP_SUFFIX)dnl
1482 DFT_LIB_SUFFIX=$DFT_DEP_SUFFIX
1483 if test $DFT_LWR_MODEL = shared ; then
1484         case $cf_cv_system_name in #(vi
1485         cygwin*)
1486                 DFT_DEP_SUFFIX=".dll.a"
1487                 DFT_LIB_SUFFIX=".dll"
1488                 ;;
1489         esac
1490 fi
1491 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1492 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1493
1494 AC_MSG_CHECKING(default object directory)
1495 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1496 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1497 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1498
1499 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1500 if test "$cf_with_cxx" = yes ; then
1501 AC_MSG_CHECKING(c++ library-dependency suffix)
1502 if test "$with_libtool" != "no"; then
1503         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1504 else
1505         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX)dnl we normally make a static library
1506 fi
1507 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1508 AC_SUBST(CXX_LIB_SUFFIX)
1509 fi
1510
1511 # do not want -ldl in build except as needed for -lncurses dependency
1512 if test "$with_dlsym" = yes ; then
1513 if test $DFT_LWR_MODEL = shared || \
1514    test $DFT_LWR_MODEL = libtool ; then
1515         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1516 fi
1517 fi
1518 ### Set up low-level terminfo dependencies for makefiles.
1519
1520 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1521 # do not need libdl
1522 TICS_LIST=
1523 if test "$with_dlsym" = yes ; then
1524         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1525 fi
1526
1527 if test "$with_ticlib" != no ; then
1528
1529         if test "$with_ticlib" != yes ; then
1530                 TICS_NAME=$with_ticlib
1531                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1532                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1533                 TICS_LIB_SUFFIX="${with_ticlib}"
1534         else
1535                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1536                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1537                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1538         fi
1539         TICS_ARGS="-L${LIB_DIR} -l${TICS_LIB_SUFFIX}"
1540 else
1541         TICS_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1542 fi
1543 AC_SUBST(TICS_ARG_SUFFIX)
1544 AC_SUBST(TICS_DEP_SUFFIX)
1545 AC_SUBST(TICS_LIB_SUFFIX)
1546 AC_SUBST(TICS_ARGS)
1547
1548 if test "$with_termlib" != no ; then
1549
1550         if test "$with_termlib" != yes ; then
1551                 TINFO_NAME=$with_termlib
1552                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1553                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1554                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1555                 TINFO_LIB_SUFFIX="${with_termlib}"
1556         else
1557                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1558                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1559                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1560                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1561         fi
1562
1563         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1564         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1565         if test "$DFT_LWR_MODEL" = "libtool"; then
1566                 TEST_ARGS="${TEST_DEPS}"
1567                 TEST_ARG2="${TEST_DEP2}"
1568                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1569         else
1570                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1571                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1572                 TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1573                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1574                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1575         fi
1576 else
1577         # the next lines are needed for linking libtic over libncurses
1578         TINFO_NAME=${LIB_NAME}
1579         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1580         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1581         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1582
1583         TINFO_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1584 fi
1585
1586 if test "$DFT_LWR_MODEL" = shared ; then
1587         case $cf_cv_system_name in #(vi
1588         cygwin*)
1589                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
1590                 TINFO_SUFFIX=.dll
1591                 ;;
1592         esac
1593 fi
1594
1595 AC_SUBST(TINFO_ARG_SUFFIX)
1596 AC_SUBST(TINFO_DEP_SUFFIX)
1597 AC_SUBST(TINFO_LIB_SUFFIX)
1598 AC_SUBST(TINFO_ARGS)
1599
1600 if test "$with_dlsym" = yes ; then
1601         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1602 fi
1603
1604 # needed for Ada95
1605 TINFO_ARGS2=`echo "$TINFO_ARGS" | sed -e 's,-L\.\./,-L../../,'`
1606 AC_SUBST(TINFO_ARGS2)
1607
1608 case $DFT_LWR_MODEL in
1609 normal|debug|profile)
1610         CF_LDFLAGS_STATIC
1611         ;;
1612 esac
1613
1614 AC_MSG_CHECKING(where we will install curses.h)
1615 test "$with_overwrite" = no && \
1616 test "x$includedir" = 'x${prefix}/include' && \
1617         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1618 AC_MSG_RESULT($includedir)
1619
1620 ### Resolve a conflict between normal and wide-curses by forcing applications
1621 ### that will need libutf8 to add it to their configure script.
1622 if test "$with_overwrite" != no ; then
1623 if test "$NCURSES_LIBUTF8" = 1 ; then
1624         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1625         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1626 fi
1627 fi
1628
1629 AC_SUBST(WITH_OVERWRITE)
1630 AC_SUBST(TICS_LIST)
1631 AC_SUBST(TINFO_LIST)
1632 AC_SUBST(SHLIB_LIST)
1633
1634 # used to separate tack out of the tree
1635 NCURSES_TREE=
1636 AC_SUBST(NCURSES_TREE)
1637
1638 ### predefined stuff for the test programs
1639 AC_DEFINE(HAVE_SLK_COLOR)
1640
1641 ### Construct the list of subdirectories for which we'll customize makefiles
1642 ### with the appropriate compile-rules.
1643
1644 CF_SRC_MODULES($modules_to_build)
1645
1646 if test "$cf_with_ada" != "no" && test "$cf_cv_prog_gnat_correct" != "no"; then
1647    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses-config"
1648 fi
1649
1650 CF_DIRS_TO_MAKE
1651
1652 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATHSEP')
1653
1654 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1655
1656 ### Now that we're done running tests, add the compiler-warnings, if any
1657 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1658
1659 ### Define substitutions for header files to avoid name-pollution
1660 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1661 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1662 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1663
1664 ################################################################################
1665 test "$use_database" = yes && SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1666 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1667 AC_OUTPUT( \
1668         include/MKterm.h.awk \
1669         include/curses.head:include/curses.h.in \
1670         include/termcap.h \
1671         include/unctrl.h \
1672         $SUB_MAKEFILES \
1673         Makefile,[
1674 CF_PRG_RULES([$srcdir/test/mk-test.awk ECHO_LINK="$ECHO_LINK"], test)
1675 CF_LIB_RULES($SRC_SUBDIRS)
1676 ],[
1677 ### Special initialization commands, used to pass information from the
1678 ### configuration-run into config.status
1679
1680 AWK="$AWK"
1681 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1682 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1683 ECHO_LINK="$ECHO_LINK"
1684 LDCONFIG="$LDCONFIG"
1685 LIB_NAME="$LIB_NAME"
1686 LIB_SUBSETS="$LIB_SUBSETS"
1687 LIB_SUFFIX="$LIB_SUFFIX"
1688 LIB_TRACING="$LIB_TRACING"
1689 MAKE_TERMINFO="$MAKE_TERMINFO"
1690 NCURSES_MAJOR="$NCURSES_MAJOR"
1691 NCURSES_MINOR="$NCURSES_MINOR"
1692 NCURSES_OSPEED="$NCURSES_OSPEED"
1693 NCURSES_PATCH="$NCURSES_PATCH"
1694 SRC_SUBDIRS="$SRC_SUBDIRS"
1695 TERMINFO="$TERMINFO"
1696 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1697 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1698 TINFO_NAME="$TINFO_NAME"
1699 TINFO_SUFFIX="$TINFO_SUFFIX"
1700 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1701 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1702 TICS_NAME="$TICS_NAME"
1703 WITH_CURSES_H="$with_curses_h"
1704 WITH_ECHO="$with_echo"
1705 WITH_OVERWRITE="$with_overwrite"
1706 cf_LIST_MODELS="$cf_list_models"
1707 cf_cv_abi_version="$cf_cv_abi_version"
1708 cf_cv_do_relink="$cf_cv_do_relink"
1709 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1710 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1711 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1712 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1713 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1714 cf_cv_rel_version="$cf_cv_rel_version"
1715 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1716 cf_cv_shlib_version="$cf_cv_shlib_version"
1717 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1718 cf_cv_system_name="$cf_cv_system_name"
1719 cf_with_cxx_binding="$cf_with_cxx_binding"
1720 host="$host"
1721 target="$target"
1722
1723 ],cat)dnl
1724 ${MAKE-make} preinstall