configure.in

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2019,2020 Thomas E. Dickey                                *
   3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey 1995-on
  31 dnl
  32 dnl $Id: configure.in,v 1.716 2020/08/16 16:21:37 tom Exp $
  33 dnl Process this file with autoconf to produce a configure script.
  34 dnl
  35 dnl For additional information, see
  36 dnl     https://invisible-island.net/autoconf/
  37 dnl     https://invisible-island.net/autoconf/my-autoconf.html
  38 dnl
  39 dnl ---------------------------------------------------------------------------
  40 AC_PREREQ(2.52.20200111)
  41 AC_REVISION($Revision: 1.716 $)
  42 AC_INIT(ncurses/base/lib_initscr.c)
  43 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  44
  45 AC_DEFUN([AC_PATH_XTRA],[])dnl ignore dependencies on this
  46
  47 CF_TOP_BUILDDIR
  48 CF_SUBST_NCURSES_VERSION
  49 CF_VERSION_INFO(NCURSES,ncurses)
  50
  51 CF_WITH_REL_VERSION(NCURSES)
  52 CF_NCURSES_WITH_ABI_VERSION
  53
  54 CF_WITH_SYSTYPE
  55
  56 ###     Save the given $CFLAGS to allow user-override.
  57 cf_user_CFLAGS="$CFLAGS"
  58
  59 ###     Default install-location
  60 CF_CFG_DEFAULTS
  61 ### Defaults for ncurses ABI
  62 CF_ABI_DEFAULTS
  63
  64 ###     Checks for programs.
  65 AC_ARG_WITH(ada,
  66         [  --without-ada           suppress check for Ada compiler, don't build demo],
  67         [cf_with_ada=$withval],
  68         [cf_with_ada=yes])
  69
  70 if test "x$cf_with_ada" = xyes
  71 then
  72         cf_prog_cc="gnatgcc gcc cc"
  73 else
  74         cf_prog_cc="gcc cc"
  75 fi
  76 CF_PROG_CC($cf_prog_cc)
  77
  78 AC_PROG_CPP
  79 AC_PROG_GCC_TRADITIONAL
  80 CF_PROG_CC_C_O(CC,[$CFLAGS $CPPFLAGS])
  81 CF_PROG_LDCONFIG
  82
  83 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  84 dnl                             configure script by not letting us test if C++
  85 dnl                             is present, making this option necessary.
  86 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  87 AC_ARG_WITH(cxx,
  88         [  --without-cxx           do not adjust ncurses bool to match C++],
  89         [cf_with_cxx=$withval],
  90         [cf_with_cxx=yes])
  91 AC_MSG_RESULT($cf_with_cxx)
  92 if test "X$cf_with_cxx" = Xno ; then
  93         CXX=""
  94         GXX=""
  95 else
  96         # with autoconf 2.13, we can change the error to a warning:
  97         pushdef([AC_MSG_ERROR],
  98                 [AC_MSG_RESULT(no)
  99                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
 100                 cf_with_cxx=no; CXX=""; GXX="";])dnl
 101         AC_PROG_CXX
 102         popdef([AC_MSG_ERROR])dnl
 103
 104         AC_LANG_PUSH(C++)
 105         if test "x$cf_with_cxx" != xno
 106         then
 107                 # Several of the C++ configurations do not work, particularly when
 108                 # cross-compiling (20140913 -TD)
 109                 AC_MSG_CHECKING(if $CXX works)
 110
 111                 save_CPPFLAGS="$CPPFLAGS"
 112                 eval cf_includedir=${includedir}
 113                 CPPFLAGS="$CPPFLAGS -I${cf_includedir}"
 114                 AC_TRY_COMPILE([
 115 #include <stdlib.h>
 116 #include <stdio.h>
 117 ],
 118                 [
 119                 printf("Hello world!\n")
 120                 ],
 121                 [cf_cxx_works=yes],
 122                 [cf_cxx_works=no])
 123                 CPPFLAGS="$save_CPPFLAGS"
 124
 125                 AC_MSG_RESULT($cf_cxx_works)
 126                 if test "x$cf_cxx_works" = xno
 127                 then
 128                         AC_MSG_WARN([Ignore $CXX, since it cannot compile hello-world.])
 129                         cf_with_cxx=no; CXX=""; GXX="";
 130                 fi
 131         fi
 132         AC_LANG_POP
 133
 134         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
 135         if test "$CXX" = "g++" ; then
 136                 AC_PATH_PROG(CXX,g++)
 137         fi
 138         case "x$CXX" in
 139         (x|xg++)
 140                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
 141                 cf_with_cxx=no; CXX=""; GXX="";
 142                 ;;
 143         esac
 144 fi
 145
 146 CF_GXX_VERSION
 147 case $GXX_VERSION in
 148 ([[1-9]][[0-9]].*)
 149         ;;
 150 (1.*|2.[[0-6]]*)
 151         AC_MSG_WARN(templates do not work)
 152         ;;
 153 esac
 154
 155 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 156 AC_ARG_WITH(cxx-binding,
 157         [  --without-cxx-binding   do not build C++ binding and demo],
 158         [cf_with_cxx_binding=$withval],
 159         [cf_with_cxx_binding=$cf_with_cxx])
 160 AC_MSG_RESULT($cf_with_cxx_binding)
 161
 162 AC_MSG_CHECKING(if you want to build with Ada)
 163 AC_MSG_RESULT($cf_with_ada)
 164
 165 AC_MSG_CHECKING(if you want to install terminal database)
 166 AC_ARG_ENABLE(db-install,
 167         [  --disable-db-install    suppress install of terminal database],
 168         [cf_with_db_install=$enableval],
 169         [cf_with_db_install=yes])
 170 AC_MSG_RESULT($cf_with_db_install)
 171
 172 AC_MSG_CHECKING(if you want to install manpages)
 173 AC_ARG_WITH(manpages,
 174         [  --without-manpages      suppress install of manpages],
 175         [cf_with_manpages=$withval],
 176         [cf_with_manpages=yes])
 177 AC_MSG_RESULT($cf_with_manpages)
 178
 179 AC_MSG_CHECKING(if you want to build programs such as tic)
 180 AC_ARG_WITH(progs,
 181         [  --without-progs         suppress build/install with programs (e.g., tic)],
 182         [cf_with_progs=$withval],
 183         [cf_with_progs=yes])
 184 AC_MSG_RESULT($cf_with_progs)
 185
 186 if test -f $srcdir/tack/tack.h; then
 187         if test "x$cross_compiling" = xyes ; then
 188                 CF_VERBOSE(ignoring tack because we are cross-compiling)
 189                 cf_with_tack=no
 190         else
 191                 AC_MSG_CHECKING(if you want to build the tack program)
 192                 AC_ARG_WITH(tack,
 193                         [  --without-tack          suppress build/install with tack program],
 194                         [cf_with_tack=$withval],
 195                         [cf_with_tack=$cf_with_progs])
 196                 AC_MSG_RESULT($cf_with_tack)
 197         fi
 198 else
 199         cf_with_tack=no
 200 fi
 201
 202 AC_MSG_CHECKING(if you want to build test-programs)
 203 AC_ARG_WITH(tests,
 204         [  --without-tests         suppress build/install with test-programs],
 205         [cf_with_tests=$withval],
 206         [cf_with_tests=yes])
 207 AC_MSG_RESULT($cf_with_tests)
 208
 209 AC_MSG_CHECKING(if you wish to install curses.h)
 210 AC_ARG_WITH(curses-h,
 211         [  --without-curses-h      install curses.h as ncurses.h only],
 212         [with_curses_h=$withval],
 213         [with_curses_h=yes])
 214 AC_MSG_RESULT($with_curses_h)
 215
 216 modules_to_build="ncurses"
 217 test "X$cf_with_progs" != Xno && modules_to_build="$modules_to_build progs"
 218 test "X$cf_with_tack"  != Xno && modules_to_build="$modules_to_build tack"
 219 modules_to_build="$modules_to_build panel menu form"
 220
 221 AC_ARG_PROGRAM
 222
 223 CF_PROG_AWK
 224 CF_PROG_EGREP
 225 CF_PROG_INSTALL
 226 CF_PROG_LINT
 227 CF_PROG_LN_S
 228
 229 AC_SYS_LONG_FILE_NAMES
 230
 231 # Provide for renaming "ncurses5-config" to "ncurses5X-config", etc., in case
 232 # of package conflict.
 233 cf_config_suffix=
 234 AC_ARG_WITH(config-suffix,
 235         [  --with-config-suffix=X  suffixes ncursesXX-config file],
 236         [case "x$withval" in
 237         (xyes|xno)
 238                 AC_MSG_WARN(expected a value for config-suffix option)
 239                 ;;
 240         (*)     cf_config_suffix="$withval"
 241                 ;;
 242         esac])
 243 AC_SUBST(cf_config_suffix)
 244
 245 # If we find pkg-config, check if we should install the ".pc" files.
 246 CF_PKG_CONFIG
 247 CF_WITH_PKG_CONFIG_LIBDIR
 248 CF_ENABLE_PC_FILES
 249 if test -z "$MAKE_PC_FILES"
 250 then
 251         AC_MSG_CHECKING(for suffix to add to pc-files)
 252 AC_ARG_WITH(pc-suffix,
 253         [  --with-pc-suffix        suffixes pc-files],
 254         [case "x$withval" in
 255         (xyes|xno)
 256                 PC_MODULE_SUFFIX=
 257                 ;;
 258         (*)     PC_MODULE_SUFFIX="$withval"
 259                 ;;
 260         esac])
 261         test -z "$PC_MODULE_SUFFIX" && PC_MODULE_SUFFIX=none
 262         AC_MSG_RESULT($PC_MODULE_SUFFIX)
 263         test "$PC_MODULE_SUFFIX" = none && PC_MODULE_SUFFIX=
 264         AC_SUBST(PC_MODULE_SUFFIX)
 265 fi
 266
 267 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 268 AC_ARG_ENABLE(mixed-case,
 269         [  --enable-mixed-case     tic should assume mixed-case filenames],
 270         [enable_mixedcase=$enableval],
 271         [enable_mixedcase=auto])
 272 AC_MSG_RESULT($enable_mixedcase)
 273 if test "$enable_mixedcase" = "auto" ; then
 274         CF_MIXEDCASE_FILENAMES
 275 else
 276         cf_cv_mixedcase=$enable_mixedcase
 277         if test "x$enable_mixedcase" = "xyes" ; then
 278                 AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
 279         fi
 280 fi
 281
 282 # do this after mixed-case option (tags/TAGS is not as important as tic).
 283 AC_PROG_MAKE_SET
 284 CF_MAKE_TAGS
 285 CF_MAKEFLAGS
 286
 287 dnl These are standard among *NIX systems, but not when cross-compiling
 288 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 289 AC_CHECK_TOOL(LD, ld, ld)
 290 AC_CHECK_TOOL(AR, ar, ar)
 291 AC_CHECK_TOOL(NM, nm, nm)
 292 CF_AR_FLAGS
 293
 294 dnl Special option for use by system-builders: the install-prefix is used to
 295 dnl adjust the location into which the actual install is done, so that an
 296 dnl archive can be built without modifying the host system's configuration.
 297 AC_MSG_CHECKING(if you have specified an install-prefix)
 298 AC_ARG_WITH(install-prefix,
 299         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 300         [case "x$withval" in
 301         (xyes|xno)
 302                 ;;
 303         (*)     DESTDIR="$withval"
 304                 ;;
 305         esac])
 306 AC_MSG_RESULT($DESTDIR)
 307 AC_SUBST(DESTDIR)
 308
 309 ###############################################################################
 310 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 311 # If we're cross-compiling, allow the user to override the tools and their
 312 # options.  The configure script is oriented toward identifying the host
 313 # compiler, etc., but we need a build compiler to generate parts of the source.
 314
 315 case $cf_cv_system_name in
 316 (*-msvc*)
 317         LDFLAGS="$LDFLAGS user32.lib"
 318         export LDFLAGS
 319         ;;
 320 esac
 321
 322 CF_BUILD_CC
 323
 324 ###############################################################################
 325 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 326
 327 ### Options to allow the user to specify the set of libraries which are used.
 328 ### Use "--without-normal --with-shared" to allow the default model to be
 329 ### shared, for example.
 330 cf_list_models=""
 331 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 332
 333 CF_WITH_LIBTOOL
 334 if test "$with_libtool" != "no" ; then
 335
 336 cf_list_models="$cf_list_models libtool"
 337
 338 else
 339
 340 AC_MSG_CHECKING(if you want to build shared libraries)
 341 AC_ARG_WITH(shared,
 342         [  --with-shared           generate shared-libraries],
 343         [with_shared=$withval],
 344         [with_shared=no])
 345 AC_MSG_RESULT($with_shared)
 346 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
 347
 348 AC_MSG_CHECKING(if you want to build static libraries)
 349 AC_ARG_WITH(normal,
 350         [  --with-normal           generate normal-libraries (default)],
 351         [with_normal=$withval],
 352         [with_normal=yes])
 353 AC_MSG_RESULT($with_normal)
 354 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
 355
 356 AC_MSG_CHECKING(if you want to build debug libraries)
 357 AC_ARG_WITH(debug,
 358         [  --with-debug            generate debug-libraries (default)],
 359         [with_debug=$withval],
 360         [with_debug=yes])
 361 AC_MSG_RESULT($with_debug)
 362 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
 363
 364 AC_MSG_CHECKING(if you want to build profiling libraries)
 365 AC_ARG_WITH(profile,
 366         [  --with-profile          generate profile-libraries],
 367         [with_profile=$withval],
 368         [with_profile=no])
 369 AC_MSG_RESULT($with_profile)
 370 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
 371
 372 fi
 373
 374 if test "X$cf_with_cxx_binding" != Xno; then
 375 if test "x$with_shared" = "xyes"; then
 376 AC_MSG_CHECKING(if you want to build C++ shared libraries)
 377 AC_ARG_WITH(cxx-shared,
 378         [  --with-cxx-shared       generate C++ shared-libraries],
 379         [with_shared_cxx=$withval],
 380         [with_shared_cxx=no])
 381 AC_MSG_RESULT($with_shared_cxx)
 382 fi
 383 fi
 384
 385 ###############################################################################
 386
 387 AC_MSG_CHECKING(for specified models)
 388 test -z "$cf_list_models" && cf_list_models=normal
 389 dnl If we use libtool to generate libraries, then it must be the only
 390 dnl specified model.
 391 test "$with_libtool" != "no" && cf_list_models=libtool
 392 AC_MSG_RESULT($cf_list_models)
 393
 394 ### Use the first model as the default, and save its suffix for use in building
 395 ### up test-applications.
 396 AC_MSG_CHECKING(for default model)
 397 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 398 AC_MSG_RESULT($DFT_LWR_MODEL)
 399
 400 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 401
 402 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 403 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 404
 405 TICS_NAME=tic
 406 AC_SUBST(TICS_NAME)
 407
 408 TINFO_NAME=tinfo
 409 AC_SUBST(TINFO_NAME)
 410
 411 LIB_NAME=ncurses
 412 AC_SUBST(LIB_NAME)
 413
 414 LIB_DIR=../lib
 415 LIB_2ND=../../lib
 416
 417 CF_WITH_LIB_PREFIX(cf_prefix)
 418
 419 LIB_SUFFIX=
 420 AC_SUBST(LIB_SUFFIX)
 421 CF_PATHSEP
 422
 423 ###############################################################################
 424
 425 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 426 AC_ARG_WITH(termlib,
 427         [  --with-termlib          generate separate terminfo library],
 428         [with_termlib=$withval],
 429         [with_termlib=no])
 430 AC_MSG_RESULT($with_termlib)
 431
 432 AC_MSG_CHECKING(if you want to build a separate tic library)
 433 AC_ARG_WITH(ticlib,
 434         [  --with-ticlib           generate separate tic library],
 435         [with_ticlib=$withval],
 436         [with_ticlib=no])
 437 AC_MSG_RESULT($with_ticlib)
 438
 439 dnl Not all ports of gcc support the -g option
 440
 441 if test X"$CC_G_OPT" = X"" ; then
 442         CC_G_OPT='-g'
 443         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
 444 fi
 445 AC_SUBST(CC_G_OPT)
 446
 447 if test X"$CXX_G_OPT" = X"" ; then
 448         CXX_G_OPT='-g'
 449         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
 450 fi
 451 AC_SUBST(CXX_G_OPT)
 452
 453 AC_MSG_CHECKING(for default loader flags)
 454 case $DFT_LWR_MODEL in
 455 (libtool) LD_MODEL=''   ;;
 456 (normal)  LD_MODEL=''   ;;
 457 (debug)   LD_MODEL=$CC_G_OPT ;;
 458 (profile) LD_MODEL='-pg';;
 459 (shared)  LD_MODEL=''   ;;
 460 esac
 461 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 462 AC_MSG_RESULT($LD_MODEL)
 463
 464 case $DFT_LWR_MODEL in
 465 (shared)
 466 CF_ENABLE_RPATH
 467 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 468 AC_ARG_ENABLE(relink,
 469 [  --disable-relink        relink shared libraries during install],
 470 [cf_cv_do_relink=$enableval],
 471 [cf_cv_do_relink=yes])
 472 AC_MSG_RESULT($cf_cv_do_relink)
 473         ;;
 474 esac
 475
 476 # we will build libraries one-level down.
 477 rel_builddir=..
 478 CF_SHARED_OPTS
 479 for model in $cf_list_models; do
 480         case $model in
 481         (libtool)
 482                 CF_WITH_LIBTOOL_OPTS
 483                 CF_WITH_EXPORT_SYMS
 484                 ;;
 485         (shared)
 486                 if test "$CC_SHARED_OPTS" = "unknown"; then
 487                         AC_ERROR(Shared libraries are not supported in this version)
 488                 fi
 489                 # workaround for inept transition to PIE vs PIC...
 490                 AC_MSG_CHECKING(if current CFLAGS link properly)
 491                 AC_TRY_LINK(
 492                         [#include <stdio.h>],
 493                         [printf("Hello work\n");],
 494                         [cf_cflags_work=yes],
 495                         [cf_cflags_work=no])
 496                 AC_MSG_RESULT($cf_cflags_work)
 497                 if test "$cf_cflags_work" = no
 498                 then
 499                         CF_VERBOSE(try to work around by appending shared-options)
 500                         CFLAGS="$CFLAGS $CC_SHARED_OPTS"
 501                 fi
 502                 CF_WITH_VERSIONED_SYMS
 503                 ;;
 504         esac
 505 done
 506
 507 ### Checks for special libraries, must be done up-front.
 508 SHLIB_LIST=""
 509 CF_WITH_GPM
 510 if test "$with_gpm" != no ; then
 511         AC_MSG_CHECKING(if you want to load GPM dynamically)
 512         AC_ARG_WITH(dlsym,
 513                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 514                 [with_dlsym=$withval],
 515                 [with_dlsym=yes])
 516         AC_MSG_RESULT($with_dlsym)
 517         if test "x$with_dlsym" = xyes ; then
 518                 CF_FUNC_DLSYM
 519                 if test "x$with_gpm" != xyes ; then
 520                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 521                         cf_cv_gpm_soname="$with_gpm"
 522                 else
 523                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 524                 fi
 525                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
 526                 SHLIB_LIST="-ldl $SHLIB_LIST"
 527                 CF_ADD_LIB(dl,PRIVATE_LIBS)
 528         else
 529                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 530                 CF_ADD_LIB(gpm,TEST_LIBS)
 531                 CF_ADD_LIB(gpm,PRIVATE_LIBS)
 532         fi
 533         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
 534         CF_CHECK_GPM_WGETCH
 535 fi
 536
 537 CF_WITH_PCRE2
 538 CF_WITH_SYSMOUSE
 539
 540 # pretend that ncurses==ncursesw==ncursest
 541 AC_MSG_CHECKING(if you want to disable library suffixes)
 542 CF_ARG_DISABLE(lib-suffixes,
 543         [  --disable-lib-suffixes  disable library suffixes],
 544         [disable_lib_suffixes=yes],
 545         [disable_lib_suffixes=no],
 546         no)
 547 AC_MSG_RESULT($disable_lib_suffixes)
 548
 549 ### If we're building with rpath, try to link non-standard libs that way too.
 550 if test "$DFT_LWR_MODEL" = "shared" && test "x$cf_cv_enable_rpath" != xno; then
 551         CF_DISABLE_RPATH_HACK
 552 fi
 553
 554 ### Depending on the system, someone may use rpath to build ncurses but not
 555 # want users of the package to rely upon that feature.  Give those people an
 556 # option to suppress that detail from EXTRA_LDFLAGS.
 557 EXTRA_PKG_LDFLAGS="$EXTRA_LDFLAGS"
 558 if test -n "$EXTRA_PKG_LDFLAGS"
 559 then
 560         AC_MSG_CHECKING(if you want to disable extra LDFLAGS for package-scripts)
 561         CF_ARG_DISABLE(pkg-ldflags,
 562                 [  --disable-pkg-ldflags   disable extra LDFLAGS for package-scripts],
 563                 [disable_pkg_ldflags=yes],
 564                 [disable_pkg_ldflags=no],
 565                 no)
 566         AC_MSG_RESULT($disable_pkg_ldflags)
 567         test "$disable_pkg_ldflags" = yes && EXTRA_PKG_LDFLAGS=
 568 fi
 569 AC_SUBST(EXTRA_PKG_LDFLAGS)
 570
 571 ###############################################################################
 572 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 573
 574 ###     use option --with-extra-suffix to append suffix to headers and libraries
 575 AC_MSG_CHECKING(if you wish to append extra suffix to header/library paths)
 576 EXTRA_SUFFIX=
 577 AC_ARG_WITH(extra-suffix,
 578         [  --with-extra-suffix=X   append extra suffix to header/library paths],
 579         [case x$withval in
 580         (no)
 581                 ;;
 582         (xyes|x)
 583                 EXTRA_SUFFIX=$cf_cv_abi_version
 584                 ;;
 585         (*)
 586                 EXTRA_SUFFIX=$withval
 587                 ;;
 588         esac
 589         ])
 590 AC_MSG_RESULT($EXTRA_SUFFIX)
 591 AC_SUBST(EXTRA_SUFFIX)
 592
 593 ###     use option --disable-overwrite to leave out the link to -lcurses
 594 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 595 AC_ARG_ENABLE(overwrite,
 596         [  --disable-overwrite     put headers in subdir, omit link to -lcurses],
 597         [with_overwrite=$enableval],
 598         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 599 AC_MSG_RESULT($with_overwrite)
 600
 601 AC_MSG_CHECKING(if external terminfo-database is used)
 602 AC_ARG_ENABLE(database,
 603         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 604         [use_database=$enableval],
 605         [use_database=yes])
 606 AC_MSG_RESULT($use_database)
 607
 608 case $host_os in
 609 (os2*)
 610         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 611         ;;
 612 (*)
 613         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 614         ;;
 615 esac
 616 AC_SUBST(TERMINFO_SRC)
 617
 618 NCURSES_USE_DATABASE=0
 619 if test "$use_database" != no ; then
 620         NCURSES_USE_DATABASE=1
 621
 622         AC_MSG_CHECKING(which terminfo source-file will be installed)
 623         AC_ARG_WITH(database,
 624                 [  --with-database=XXX     specify terminfo source to install],
 625                 [TERMINFO_SRC=$withval])
 626         AC_MSG_RESULT($TERMINFO_SRC)
 627
 628         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 629         AC_ARG_WITH(hashed-db,
 630                 [  --with-hashed-db        specify hashed-database library],,
 631                 [with_hashed_db=no])
 632         AC_MSG_RESULT($with_hashed_db)
 633 else
 634         with_hashed_db=no
 635 fi
 636 AC_SUBST(NCURSES_USE_DATABASE)
 637
 638 AC_MSG_CHECKING(for list of fallback descriptions)
 639 AC_ARG_WITH(fallbacks,
 640         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 641         [with_fallback=$withval],
 642         [with_fallback=])
 643 AC_MSG_RESULT($with_fallback)
 644
 645 case ".$with_fallback" in
 646 (.|.no)
 647         FALLBACK_LIST=
 648         ;;
 649 (.yes)
 650         AC_MSG_WARN(expected a list of terminal descriptions)
 651         ;;
 652 (*)
 653         FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 654         ;;
 655 esac
 656
 657 # The fallback feature in ncurses relies upon tic/infocmp outside the build
 658 # tree for generating the terminal descriptions that will be compiled into the
 659 # library.  If your toolchain is old, it may not handle current terminal
 660 # databases.  Use configure-options to point to the tools which will be used,
 661 # rather than the first ones found on the $PATH.
 662 AC_CHECK_TOOL(TIC, tic)
 663 AC_CHECK_TOOL(INFOCMP, infocmp)
 664 if test -n "$FALLBACK_LIST"
 665 then
 666         CF_WITH_PATH_PROG(TIC,     tic,     [for fallbacks], $PATH:/usr/local/ncurses/bin)
 667         CF_WITH_PATH_PROG(INFOCMP, infocmp, [for fallbacks], $PATH:/usr/local/ncurses/bin)
 668         test -z "$TIC" && FALLBACK_LIST=
 669         test -z "$INFOCMP" && FALLBACK_LIST=
 670         if test -z "$FALLBACK_LIST"
 671         then
 672                 AC_MSG_WARN(ignoring fallback option because tic/infocmp are not available)
 673         fi
 674 fi
 675 AC_SUBST(TIC)
 676 AC_SUBST(INFOCMP)
 677
 678 USE_FALLBACKS=
 679 test -z "$FALLBACK_LIST" && USE_FALLBACKS="#"
 680 AC_SUBST(FALLBACK_LIST)
 681 AC_SUBST(USE_FALLBACKS)
 682
 683 AC_MSG_CHECKING(if you want modern xterm or antique)
 684 AC_ARG_WITH(xterm-new,
 685         [  --without-xterm-new     specify if xterm terminfo should be old version],
 686         [with_xterm_new=$withval],
 687         [with_xterm_new=yes])
 688 case $with_xterm_new in
 689 (no) with_xterm_new=xterm-old;;
 690 (*)      with_xterm_new=xterm-new;;
 691 esac
 692 AC_MSG_RESULT($with_xterm_new)
 693 WHICH_XTERM=$with_xterm_new
 694 AC_SUBST(WHICH_XTERM)
 695
 696 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
 697 AC_ARG_WITH(xterm-kbs,
 698         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
 699         [with_xterm_kbs=$withval],
 700         [with_xterm_kbs=BS])
 701 case x$with_xterm_kbs in
 702 (xyes|xno|xBS|xbs|x8)
 703         with_xterm_kbs=BS
 704         ;;
 705 (xDEL|xdel|x127)
 706         with_xterm_kbs=DEL
 707         ;;
 708 (*)
 709         with_xterm_kbs=$withval
 710         ;;
 711 esac
 712 AC_MSG_RESULT($with_xterm_kbs)
 713 XTERM_KBS=$with_xterm_kbs
 714 AC_SUBST(XTERM_KBS)
 715
 716 MAKE_TERMINFO=
 717 if test "$use_database" = no ; then
 718         TERMINFO="${datadir}/terminfo"
 719         MAKE_TERMINFO="#"
 720 else
 721
 722 AC_MSG_CHECKING(for list of terminfo directories)
 723 CF_WITH_PATHLIST(terminfo-dirs,
 724         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 725         TERMINFO_DIRS,
 726         DATADIR/terminfo,
 727         ${datadir}/terminfo)
 728 AC_MSG_RESULT($TERMINFO_DIRS)
 729 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
 730
 731 case "x$TERMINFO" in
 732 x???:*)
 733         AC_MSG_WARN(ignoring non-directory/file TERMINFO value)
 734         unset TERMINFO
 735         ;;
 736 esac
 737
 738 AC_MSG_CHECKING(for default terminfo directory)
 739 CF_WITH_PATH(default-terminfo-dir,
 740         [  --with-default-terminfo-dir=DIR default terminfo directory],
 741         TERMINFO,
 742         DATADIR/terminfo,
 743         ${datadir}/terminfo)
 744 AC_MSG_RESULT($TERMINFO)
 745 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
 746
 747 fi
 748
 749 AC_SUBST(TERMINFO)
 750 AC_SUBST(MAKE_TERMINFO)
 751
 752 ###     use option --disable-big-core to make tic run on small machines
 753 ###     We need 4Mb, check if we can allocate 50% more than that.
 754 AC_MSG_CHECKING(if big-core option selected)
 755 AC_ARG_ENABLE(big-core,
 756         [  --disable-big-core      assume machine has little memory],
 757         [with_big_core=$enableval],
 758         [AC_TRY_RUN([
 759 #include <stdlib.h>
 760 #include <string.h>
 761 int main() {
 762         unsigned long n = 6000000L;
 763         char *s = malloc(n);
 764         if (s != 0)
 765                 s[0] = s[n-1] = 0;
 766         ${cf_cv_main_return:-return}(s == 0);
 767 }],
 768         [with_big_core=yes],
 769         [with_big_core=no],
 770         [with_big_core=no])])
 771 AC_MSG_RESULT($with_big_core)
 772 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
 773
 774 ### ISO C only guarantees 512-char strings, we have tables which load faster
 775 ### when constructed using "big" strings.  More than the C compiler, the awk
 776 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 777 AC_MSG_CHECKING(if big-strings option selected)
 778 AC_ARG_ENABLE(big-strings,
 779         [  --disable-big-strings   assume compiler has only standard-size strings],
 780         [with_big_strings=$enableval],
 781         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 782 AC_MSG_RESULT($with_big_strings)
 783
 784 USE_BIG_STRINGS=0
 785 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
 786 AC_SUBST(USE_BIG_STRINGS)
 787
 788 ###     use option --enable-termcap to compile in the termcap fallback support
 789 AC_MSG_CHECKING(if you want termcap-fallback support)
 790 AC_ARG_ENABLE(termcap,
 791         [  --enable-termcap        compile in termcap fallback support],
 792         [with_termcap=$enableval],
 793         [with_termcap=no])
 794 AC_MSG_RESULT($with_termcap)
 795
 796 NCURSES_USE_TERMCAP=0
 797 if test "x$with_termcap" != "xyes" ; then
 798         if test "$use_database" = no ; then
 799                 if test -z "$with_fallback" ; then
 800                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 801                 fi
 802         fi
 803         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
 804 else
 805
 806         if test "$with_ticlib" != no ; then
 807                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 808         fi
 809
 810         NCURSES_USE_TERMCAP=1
 811         AC_MSG_CHECKING(for list of termcap files)
 812         CF_WITH_PATHLIST(termpath,
 813                 [  --with-termpath=XXX     specify list of termcap files],
 814                 TERMPATH,
 815                 /etc/termcap:/usr/share/misc/termcap)
 816         AC_MSG_RESULT($TERMPATH)
 817         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
 818
 819         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 820         AC_MSG_CHECKING(if fast termcap-loader is needed)
 821         AC_ARG_ENABLE(getcap,
 822                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 823                 [with_getcap=$enableval],
 824                 [with_getcap=no])
 825         AC_MSG_RESULT($with_getcap)
 826         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
 827
 828         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 829         AC_ARG_ENABLE(getcap-cache,
 830                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 831                 [with_getcap_cache=$enableval],
 832                 [with_getcap_cache=no])
 833         AC_MSG_RESULT($with_getcap_cache)
 834         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
 835
 836 fi
 837 AC_SUBST(NCURSES_USE_TERMCAP)
 838
 839 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 840 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 841 AC_ARG_ENABLE(home-terminfo,
 842         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 843         [with_home_terminfo=$enableval],
 844         [with_home_terminfo=yes])
 845 AC_MSG_RESULT($with_home_terminfo)
 846 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
 847
 848 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 849 AC_ARG_ENABLE(root-environ,
 850         [  --disable-root-environ  restrict environment when running as root],
 851         [with_root_environ=$enableval],
 852         [with_root_environ=yes])
 853 AC_MSG_RESULT($with_root_environ)
 854 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if environment should be restricted for root user])
 855
 856 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 857 ###   to reduce storage requirements for the terminfo database.
 858 CF_LINK_FUNCS
 859
 860 with_links=no
 861 with_symlinks=no
 862
 863 # soft links (symbolic links) are useful for some systems where hard links do
 864 # not work, or to make it simpler to copy terminfo trees around.
 865 if test "x$ac_cv_func_symlink" = xyes ; then
 866         AC_MSG_CHECKING(if tic should use symbolic links)
 867         AC_ARG_ENABLE(symlinks,
 868         [  --enable-symlinks       make tic use symbolic links not hard links],
 869         [with_symlinks=$enableval],
 870         [with_symlinks=no])
 871         AC_MSG_RESULT($with_symlinks)
 872 fi
 873
 874 # If we have hard links and did not choose to use soft links instead, there is
 875 # no reason to make this choice optional - use the hard links.
 876 if test "$with_symlinks" = no ; then
 877         AC_MSG_CHECKING(if tic should use hard links)
 878         if test "x$ac_cv_func_link" = xyes ; then
 879                 with_links=yes
 880         else
 881                 with_links=no
 882         fi
 883         AC_MSG_RESULT($with_links)
 884 fi
 885
 886 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
 887 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
 888
 889 ###   use option --enable-broken-linker to force on use of broken-linker support
 890 CF_ENABLE_BROKEN_LINKER
 891
 892 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 893 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 894 AC_ARG_ENABLE(bsdpad,
 895         [  --enable-bsdpad         recognize BSD-style prefix padding],
 896         [with_bsdpad=$enableval],
 897         [with_bsdpad=no])
 898 AC_MSG_RESULT($with_bsdpad)
 899 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
 900
 901 ###   use option --enable-widec to turn on use of wide-character support
 902 NCURSES_CH_T=chtype
 903 NCURSES_LIBUTF8=0
 904
 905 NEED_WCHAR_H=0
 906 NCURSES_MBSTATE_T=0
 907 NCURSES_WCHAR_T=0
 908 NCURSES_WINT_T=0
 909
 910 # Check to define _XOPEN_SOURCE "automatically"
 911 CPPFLAGS_before_XOPEN="$CPPFLAGS"
 912 CF_XOPEN_SOURCE(600)
 913 CPPFLAGS_after_XOPEN="$CPPFLAGS"
 914
 915 # Work around breakage on OS X
 916 CF_SIGWINCH
 917
 918 # Checks for CODESET support.
 919 AM_LANGINFO_CODESET
 920
 921 # use these variables to work around a defect in gcc's fixincludes.
 922 NCURSES_OK_WCHAR_T=
 923 NCURSES_OK_WINT_T=
 924
 925 AC_MSG_CHECKING(if you want wide-character code)
 926 AC_ARG_ENABLE(widec,
 927         [  --enable-widec          compile with wide-char/UTF-8 code],
 928         [with_widec=$enableval],
 929         [with_widec=no])
 930 AC_MSG_RESULT($with_widec)
 931
 932 NCURSES_WCWIDTH_GRAPHICS=1
 933 AC_SUBST(NCURSES_WCWIDTH_GRAPHICS)
 934
 935 if test "x$with_widec" = xyes ; then
 936         if test "x$disable_lib_suffixes" = xno ; then
 937                 LIB_SUFFIX="w${LIB_SUFFIX}"
 938         fi
 939         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
 940         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
 941
 942         CF_CHECK_WCHAR_H
 943         CF_CHECK_WCWIDTH_GRAPHICS
 944         test "$cf_cv_wcwidth_graphics" = no && NCURSES_WCWIDTH_GRAPHICS=0
 945
 946         # with_overwrite=no
 947         NCURSES_CH_T=cchar_t
 948         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 949         if test "x$ac_cv_func_putwc" != xyes ; then
 950                 CF_UTF8_LIB
 951                 if test "$cf_cv_utf8_lib" != no ; then
 952                         NCURSES_LIBUTF8=1
 953                 fi
 954         fi
 955         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 956         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 957         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 958
 959         if test "$NCURSES_MBSTATE_T" != 0; then
 960                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
 961         fi
 962 fi
 963 AC_SUBST(NCURSES_CH_T)
 964 AC_SUBST(NCURSES_LIBUTF8)
 965
 966 AC_SUBST(NEED_WCHAR_H)
 967 AC_SUBST(NCURSES_MBSTATE_T)
 968 AC_SUBST(NCURSES_WCHAR_T)
 969 AC_SUBST(NCURSES_WINT_T)
 970
 971 AC_SUBST(NCURSES_OK_WCHAR_T)
 972 AC_SUBST(NCURSES_OK_WINT_T)
 973
 974 ###   use option --disable-lp64 to allow long chtype
 975 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 976 AC_ARG_ENABLE(lp64,
 977         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 978         [with_lp64=$enableval],
 979         [with_lp64=$cf_dft_with_lp64])
 980 AC_MSG_RESULT($with_lp64)
 981
 982 if test "x$with_lp64" = xyes ; then
 983         cf_cv_enable_lp64=1
 984 else
 985         cf_cv_enable_lp64=0
 986 fi
 987 AC_SUBST(cf_cv_enable_lp64)
 988
 989 CF_LARGEFILE
 990
 991 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 992 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 993 AC_ARG_ENABLE(tparm-varargs,
 994         [  --disable-tparm-varargs compile tparm() without varargs interface],
 995         [with_tparm_varargs=$enableval],
 996         [with_tparm_varargs=yes])
 997 AC_MSG_RESULT($with_tparm_varargs)
 998 NCURSES_TPARM_VARARGS=0
 999 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
1000 AC_SUBST(NCURSES_TPARM_VARARGS)
1001
1002 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
1003 if test "$with_ticlib" != no ; then
1004 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
1005 AC_ARG_ENABLE(tic-depends,
1006         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
1007         [with_tic_depends=$enableval],
1008         [with_tic_depends=yes])
1009 AC_MSG_RESULT($with_tic_depends)
1010 else
1011         with_tic_depends=no
1012 fi
1013
1014 ###   use option --disable-wattr-macros to suppress wattr* macros from curses.h
1015 AC_MSG_CHECKING(if you want to suppress wattr* macros to help with ncurses5/ncurses6 transition)
1016 AC_ARG_ENABLE(wattr-macros,
1017         [  --disable-wattr-macros  suppress wattr* macros to help with ncurses5/ncurses6 transition],
1018         [with_wattr_macros=$enableval],
1019         [with_wattr_macros=yes])
1020 if [[ "x$with_wattr_macros" != xyes ]]; then
1021         NCURSES_WATTR_MACROS=0
1022         AC_MSG_RESULT(yes)
1023 else
1024         NCURSES_WATTR_MACROS=1
1025         AC_MSG_RESULT(no)
1026 fi
1027 AC_SUBST(NCURSES_WATTR_MACROS)
1028
1029 CF_WITH_X11_RGB
1030
1031 ###   use option --with-bool to override bool's type
1032 AC_MSG_CHECKING(for type of bool)
1033 AC_ARG_WITH(bool,
1034         [  --with-bool=TYPE        override fallback type of bool variable],
1035         [NCURSES_BOOL="$withval"],
1036         [NCURSES_BOOL=auto])
1037 AC_MSG_RESULT($NCURSES_BOOL)
1038 AC_SUBST(NCURSES_BOOL)
1039
1040 AC_MSG_CHECKING(for alternate terminal capabilities file)
1041 AC_ARG_WITH(caps,
1042         [  --with-caps=alt         compile with alternate Caps file],
1043         [TERMINFO_CAPS=Caps.$withval],
1044         [TERMINFO_CAPS=Caps])
1045 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
1046 AC_MSG_RESULT($TERMINFO_CAPS)
1047 AC_SUBST(TERMINFO_CAPS)
1048
1049 ###   use option --with-chtype to override chtype's type
1050 AC_MSG_CHECKING(for type of chtype)
1051 AC_ARG_WITH(chtype,
1052         [  --with-chtype=TYPE      override type of chtype],
1053         [NCURSES_CHTYPE="$withval"],
1054         [NCURSES_CHTYPE=$cf_dft_chtype])
1055 AC_MSG_RESULT($NCURSES_CHTYPE)
1056
1057 ###   use option --with-ospeed to override ospeed's type
1058 AC_MSG_CHECKING(for type of ospeed)
1059 AC_ARG_WITH(ospeed,
1060         [  --with-ospeed=TYPE      override type of ospeed variable],
1061         [NCURSES_OSPEED="$withval"],
1062         [NCURSES_OSPEED=short])
1063 AC_MSG_RESULT($NCURSES_OSPEED)
1064 AC_SUBST(NCURSES_OSPEED)
1065
1066 ###   use option --with-mmask-t to override mmask_t's type
1067 AC_MSG_CHECKING(for type of mmask_t)
1068 AC_ARG_WITH(mmask-t,
1069         [  --with-mmask-t=TYPE     override type of mmask_t],
1070         [NCURSES_MMASK_T="$withval"],
1071         [NCURSES_MMASK_T=$cf_dft_mmask_t])
1072 AC_MSG_RESULT($NCURSES_MMASK_T)
1073
1074 ###   use option --with-ccharw-max to override CCHARW_MAX size
1075 AC_MSG_CHECKING(for size CCHARW_MAX)
1076 AC_ARG_WITH(ccharw-max,
1077         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
1078         [NCURSES_CCHARW_MAX="$withval"],
1079         [NCURSES_CCHARW_MAX=5])
1080 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
1081 AC_SUBST(NCURSES_CCHARW_MAX)
1082
1083 AC_CHECK_SIZEOF([signed char])
1084 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1085         NCURSES_SBOOL="signed char"
1086 else
1087         NCURSES_SBOOL="char"
1088 fi
1089 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1090 AC_ARG_ENABLE(signed-char,
1091         [  --enable-signed-char    compile using signed Boolean's in term.h],
1092         [with_signed_char=$enableval],
1093         [with_signed_char=no])
1094 AC_MSG_RESULT($with_signed_char)
1095 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1096 AC_SUBST(NCURSES_SBOOL)
1097
1098 ###   use option --with-tparm-arg to override tparm's argument type
1099 AC_MSG_CHECKING(for type of tparm args)
1100 AC_ARG_WITH(tparm-arg,
1101         [  --with-tparm-arg=TYPE   override parameter type of tparm],
1102         [NCURSES_TPARM_ARG="$withval"],
1103         [NCURSES_TPARM_ARG=$cf_dft_tparm_arg])
1104 AC_MSG_RESULT($NCURSES_TPARM_ARG)
1105 AC_SUBST(NCURSES_TPARM_ARG)
1106
1107 ### Enable compiling-in rcs id's
1108 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
1109 AC_ARG_WITH(rcs-ids,
1110         [  --with-rcs-ids          compile-in RCS identifiers],
1111         [with_rcs_ids=$withval],
1112         [with_rcs_ids=no])
1113 AC_MSG_RESULT($with_rcs_ids)
1114 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
1115
1116 ###############################################################################
1117 CF_MAN_PAGES([ captoinfo clear infocmp infotocap reset tabs tic toe tput tset ])
1118
1119 ###############################################################################
1120 CF_HELP_MESSAGE(Extensions:)
1121
1122 ### Note that some functions (such as const) are normally disabled anyway.
1123 AC_MSG_CHECKING(if you want to build with function extensions)
1124 AC_ARG_ENABLE(ext-funcs,
1125         [  --disable-ext-funcs     disable function-extensions],
1126         [with_ext_funcs=$enableval],
1127         [with_ext_funcs=yes])
1128 AC_MSG_RESULT($with_ext_funcs)
1129 if test "x$with_ext_funcs" = xyes ; then
1130         NCURSES_EXT_FUNCS=1
1131         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
1132         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function in test-programs])
1133         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function in test-programs])
1134         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function in test-programs])
1135         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function in test-programs])
1136         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function in test-programs])
1137         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function in test-programs])
1138         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function in test-programs])
1139         AC_DEFINE(HAVE_USE_EXTENDED_NAMES,1,[Define to 1 to enable use_extended_names() function in test-programs])
1140         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function in test-programs])
1141         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function in test-programs])
1142         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function in test-programs])
1143         GENERATED_EXT_FUNCS=generated
1144         test "x$with_ext_funcs" = xyes || cf_dft_ext_spfuncs=no
1145 else
1146         NCURSES_EXT_FUNCS=0
1147         GENERATED_EXT_FUNCS=
1148 fi
1149 AC_SUBST(NCURSES_EXT_FUNCS)
1150 AC_SUBST(GENERATED_EXT_FUNCS)
1151
1152 AC_MSG_CHECKING(if you want to build with SCREEN extensions)
1153 AC_ARG_ENABLE(sp-funcs,
1154         [  --enable-sp-funcs       enable SCREEN-extensions],
1155         [with_sp_funcs=$enableval],
1156         [with_sp_funcs=$cf_dft_ext_spfuncs])
1157 AC_MSG_RESULT($with_sp_funcs)
1158 if test "x$with_sp_funcs" = xyes ; then
1159         NCURSES_SP_FUNCS=1
1160         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable SCREEN-extensions])
1161         AC_DEFINE(HAVE_TPUTS_SP,1,[Define to 1 to enable tputs_sp() function in test-programs])
1162         GENERATED_SP_FUNCS=generated
1163 else
1164         NCURSES_SP_FUNCS=0
1165         GENERATED_SP_FUNCS=
1166 fi
1167 AC_SUBST(NCURSES_SP_FUNCS)
1168 AC_SUBST(GENERATED_SP_FUNCS)
1169
1170 AC_MSG_CHECKING(if you want to build with terminal-driver)
1171 AC_ARG_ENABLE(term-driver,
1172         [  --enable-term-driver    enable terminal-driver],
1173         [with_term_driver=$enableval],
1174         [with_term_driver=no])
1175 AC_MSG_RESULT($with_term_driver)
1176 if test "x$with_term_driver" = xyes ; then
1177         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable terminal-driver])
1178         if test "x$with_termlib" != xno ; then
1179                 AC_MSG_ERROR(The term-driver option conflicts with the termlib option)
1180         fi
1181         if test "x$with_sp_funcs" != xyes ; then
1182                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
1183         fi
1184 fi
1185
1186 ###   use option --enable-const to turn on use of const beyond that in XSI.
1187 AC_MSG_CHECKING(for extended use of const keyword)
1188 AC_ARG_ENABLE(const,
1189         [  --enable-const          compile with extra/non-standard const],
1190         [with_ext_const=$enableval],
1191         [with_ext_const=$cf_dft_ext_const])
1192 AC_MSG_RESULT($with_ext_const)
1193 NCURSES_CONST='/*nothing*/'
1194 if test "x$with_ext_const" = xyes ; then
1195         NCURSES_CONST=const
1196 fi
1197 AC_SUBST(NCURSES_CONST)
1198
1199 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
1200 AC_MSG_CHECKING(if you want to use extended colors)
1201 AC_ARG_ENABLE(ext-colors,
1202         [  --enable-ext-colors     compile for 256-color support],
1203         [with_ext_colors=$enableval],
1204         [with_ext_colors=$cf_dft_ext_colors])
1205 AC_MSG_RESULT($with_ext_colors)
1206 NCURSES_EXT_COLORS=0
1207 if test "x$with_ext_colors" = xyes ; then
1208         if test "x$with_widec" != xyes ; then
1209                 AC_MSG_WARN(This option applies only to wide-character library)
1210         else
1211                 # cannot be ABI 5 since it changes sizeof(cchar_t)
1212                 CF_NCURSES_ABI_6
1213                 NCURSES_EXT_COLORS=1
1214                 AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1215                 AC_DEFINE(HAVE_ALLOC_PAIR,1,[Define to 1 to enable alloc_pair() function])
1216                 AC_DEFINE(HAVE_INIT_EXTENDED_COLOR,1,[Define to 1 to enable init_extended_color() function in test-programs])
1217                 AC_DEFINE(HAVE_RESET_COLOR_PAIRS,1,[Define to 1 to enable reset_color_pairs() function in test-programs])
1218         fi
1219 fi
1220 AC_SUBST(NCURSES_EXT_COLORS)
1221
1222 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1223 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1224 AC_ARG_ENABLE(ext-mouse,
1225         [  --enable-ext-mouse      compile for extended mouse-encoding],
1226         [with_ext_mouse=$enableval],
1227         [with_ext_mouse=$cf_dft_ext_mouse])
1228 AC_MSG_RESULT($with_ext_mouse)
1229 NCURSES_MOUSE_VERSION=1
1230 if test "x$with_ext_mouse" = xyes ; then
1231         NCURSES_MOUSE_VERSION=2
1232         CF_NCURSES_ABI_6
1233 fi
1234 AC_SUBST(NCURSES_MOUSE_VERSION)
1235
1236 ###   use option --enable-ext-putwin to turn on extended screendumps
1237 AC_MSG_CHECKING(if you want to use extended putwin/screendump)
1238 AC_ARG_ENABLE(ext-putwin,
1239         [  --enable-ext-putwin     compile with extended putwin/screendump],
1240         [with_ext_putwin=$enableval],
1241         [with_ext_putwin=$cf_dft_ext_putwin])
1242 AC_MSG_RESULT($with_ext_putwin)
1243 if test "x$with_ext_putwin" = xyes ; then
1244         AC_DEFINE(NCURSES_EXT_PUTWIN,1,[Define to 1 to compile with extended putwin/screendump])
1245 fi
1246
1247 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1248 AC_ARG_ENABLE(no-padding,
1249         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1250         [with_no_padding=$enableval],
1251         [with_no_padding=$with_ext_funcs])
1252 AC_MSG_RESULT($with_no_padding)
1253 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1254
1255 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1256 AC_MSG_CHECKING(if you want SIGWINCH handler)
1257 AC_ARG_ENABLE(sigwinch,
1258         [  --enable-sigwinch       compile with SIGWINCH handler],
1259         [with_sigwinch=$enableval],
1260         [with_sigwinch=$with_ext_funcs])
1261 AC_MSG_RESULT($with_sigwinch)
1262 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1263
1264 ###   use option --enable-tcap-names to allow user to define new capabilities
1265 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1266 AC_ARG_ENABLE(tcap-names,
1267         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1268         [with_tcap_names=$enableval],
1269         [with_tcap_names=$with_ext_funcs])
1270 AC_MSG_RESULT($with_tcap_names)
1271 NCURSES_XNAMES=0
1272 test "x$with_tcap_names" = xyes && NCURSES_XNAMES=1
1273 AC_SUBST(NCURSES_XNAMES)
1274
1275 ##############################################################################
1276 CF_HELP_MESSAGE(Reentrant Code:)
1277 CF_WITH_PTHREAD
1278
1279 if test "x$with_pthread" != xno; then
1280         AC_CHECK_FUNC(pthread_kill,[
1281                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1282                 AC_ARG_ENABLE(pthreads-eintr,
1283                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1284                         [use_pthreads_eintr=$enableval],
1285                         [use_pthreads_eintr=no])
1286                 AC_MSG_RESULT($use_pthreads_eintr)
1287                 if test "x$use_pthreads_eintr" = xyes ; then
1288                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1289                 fi])
1290
1291         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1292         AC_ARG_ENABLE(weak-symbols,
1293                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1294                 [use_weak_symbols=$enableval],
1295                 [use_weak_symbols=no])
1296         AC_MSG_RESULT($use_weak_symbols)
1297         if test "x$use_weak_symbols" = xyes ; then
1298                 CF_WEAK_SYMBOLS
1299         else
1300                 cf_cv_weak_symbols=no
1301         fi
1302
1303         if test "x$cf_cv_weak_symbols" = xyes ; then
1304                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1305         fi
1306 fi
1307
1308 PTHREAD=
1309 if test "x$with_pthread" = "xyes" ; then
1310         AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1311         enable_reentrant=yes
1312         if test "x$cf_cv_weak_symbols" = xyes ; then
1313                 PTHREAD=-lpthread
1314                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1315         fi
1316 fi
1317 AC_SUBST(PTHREAD)
1318
1319 # Reentrant code has to be opaque; there's little advantage to making ncurses
1320 # opaque outside of that, so there is no --enable-opaque option.  We can use
1321 # this option without --with-pthreads, but this will be always set for
1322 # pthreads.
1323 AC_MSG_CHECKING(if you want reentrant code)
1324 AC_ARG_ENABLE(reentrant,
1325         [  --enable-reentrant      compile with reentrant code],
1326         [with_reentrant=$enableval],
1327         [with_reentrant=no])
1328 AC_MSG_RESULT($with_reentrant)
1329 if test "x$with_reentrant" = xyes ; then
1330         cf_cv_enable_reentrant=1
1331         cf_cv_enable_opaque="NCURSES_INTERNALS"
1332         NCURSES_SIZE_T=int
1333         if test "x$cf_cv_weak_symbols" = xyes ; then
1334                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1335                 CF_ADD_LIB(pthread,TEST_LIBS)
1336                 CF_ADD_LIB(pthread,TEST_LIBS2)
1337                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1338         else
1339                 # when not using weak symbols but with_reentrant,
1340                 # add 't' to the library suffix on all platforms
1341                 # except cygwin, where we only do that if ALSO
1342                 # compiling with full thread support.
1343                 case "$host" in
1344                 (*cygwin* | *msys*)
1345                         if test "$with_pthread" = "yes" ; then
1346                                 if test "x$disable_lib_suffixes" = "xno" ; then
1347                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1348                                 fi
1349                         fi ;;
1350                 (*)
1351                         if test "x$disable_lib_suffixes" = "xno" ; then
1352                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1353                         fi
1354                         ;;
1355                 esac
1356         fi
1357         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use reentrant feature])
1358         CF_NCURSES_ABI_6
1359 else
1360         cf_cv_enable_reentrant=0
1361         cf_cv_enable_opaque="NCURSES_OPAQUE"
1362         NCURSES_SIZE_T=short
1363 fi
1364 AC_SUBST(cf_cv_enable_reentrant)
1365 AC_SUBST(cf_cv_enable_opaque)
1366
1367 AC_SUBST(NCURSES_SIZE_T)
1368
1369 AC_MSG_CHECKING(if you want opaque curses-library structures)
1370 CF_ARG_ENABLE(opaque-curses,
1371         [  --enable-opaque-curses  make curses WINDOW, etc., "opaque"],
1372         [enable_opaque_curses=yes],[
1373          test "$cf_cv_enable_reentrant" = 1 && enable_opaque_curses=yes
1374          test "$cf_cv_enable_reentrant" = 1 || enable_opaque_curses=no
1375         ])
1376 AC_MSG_RESULT($enable_opaque_curses)
1377
1378 test "$cf_cv_enable_reentrant" = 1 && \
1379 test "$enable_opaque_curses" = no && \
1380 AC_MSG_ERROR(reentrant configuration requires opaque library)
1381
1382 AC_MSG_CHECKING(if you want opaque form-library structures)
1383 AC_ARG_ENABLE(opaque-form,
1384         [  --enable-opaque-form    make form-library structures "opaque"],
1385         [enable_opaque_form=yes],[enable_opaque_form=no])
1386 AC_MSG_RESULT($enable_opaque_form)
1387
1388 AC_MSG_CHECKING(if you want opaque menu-library structures)
1389 AC_ARG_ENABLE(opaque-menu,
1390         [  --enable-opaque-menu    make menu-library structures "opaque"],
1391         [enable_opaque_menu=yes],[enable_opaque_menu=no])
1392 AC_MSG_RESULT($enable_opaque_menu)
1393
1394 AC_MSG_CHECKING(if you want opaque panel-library structures)
1395 AC_ARG_ENABLE(opaque-panel,
1396         [  --enable-opaque-panel   make panel-library structures "opaque"],
1397         [enable_opaque_panel=yes],[enable_opaque_panel=no])
1398 AC_MSG_RESULT($enable_opaque_panel)
1399
1400 NCURSES_OPAQUE=0;               test "$enable_opaque_curses" = yes && NCURSES_OPAQUE=1
1401 NCURSES_OPAQUE_FORM=0;  test "$enable_opaque_form"   = yes && NCURSES_OPAQUE_FORM=1
1402 NCURSES_OPAQUE_MENU=0;  test "$enable_opaque_menu"   = yes && NCURSES_OPAQUE_MENU=1
1403 NCURSES_OPAQUE_PANEL=0; test "$enable_opaque_panel"  = yes && NCURSES_OPAQUE_PANEL=1
1404
1405 AC_SUBST(NCURSES_OPAQUE)
1406 AC_SUBST(NCURSES_OPAQUE_FORM)
1407 AC_SUBST(NCURSES_OPAQUE_MENU)
1408 AC_SUBST(NCURSES_OPAQUE_PANEL)
1409
1410 ### Allow using a different wrap-prefix
1411 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1412         AC_MSG_CHECKING(for prefix used to wrap public variables)
1413         AC_ARG_WITH(wrap-prefix,
1414                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1415                 [NCURSES_WRAP_PREFIX=$withval],
1416                 [NCURSES_WRAP_PREFIX=_nc_])
1417         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1418 else
1419         NCURSES_WRAP_PREFIX=_nc_
1420 fi
1421 AC_SUBST(NCURSES_WRAP_PREFIX)
1422 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1423
1424 ###############################################################################
1425 # These options are relatively safe to experiment with.
1426 CF_HELP_MESSAGE(Development Code:)
1427 AC_MSG_CHECKING(if you want all development code)
1428 AC_ARG_WITH(develop,
1429         [  --without-develop       disable development options],
1430         [with_develop=$withval],
1431         [with_develop=no])
1432 AC_MSG_RESULT($with_develop)
1433
1434 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1435 AC_MSG_CHECKING(if you want hard-tabs code)
1436 AC_ARG_ENABLE(hard-tabs,
1437         [  --enable-hard-tabs      compile with hard-tabs code],,
1438         [enable_hard_tabs=$with_develop])
1439 AC_MSG_RESULT($enable_hard_tabs)
1440 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1441
1442 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1443 AC_MSG_CHECKING(if you want limited support for xmc)
1444 AC_ARG_ENABLE(xmc-glitch,
1445         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1446         [enable_xmc_glitch=$with_develop])
1447 AC_MSG_RESULT($enable_xmc_glitch)
1448 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1449
1450 ###############################################################################
1451 # These are just experimental, probably should not be in a package:
1452 CF_HELP_MESSAGE(Experimental Code:)
1453
1454 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1455 AC_ARG_ENABLE(assumed-color,
1456         [  --disable-assumed-color do not assume anything about default-colors],
1457         [with_assumed_color=$enableval],
1458         [with_assumed_color=yes])
1459 AC_MSG_RESULT($with_assumed_color)
1460 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1461
1462 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1463 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1464 AC_ARG_ENABLE(hashmap,
1465         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1466         [with_hashmap=$enableval],
1467         [with_hashmap=yes])
1468 AC_MSG_RESULT($with_hashmap)
1469 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1470
1471 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1472 AC_MSG_CHECKING(if you want colorfgbg code)
1473 AC_ARG_ENABLE(colorfgbg,
1474         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1475         [with_colorfgbg=$enableval],
1476         [with_colorfgbg=no])
1477 AC_MSG_RESULT($with_colorfgbg)
1478 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1479
1480 ###   use option --enable-fvisibility to turn on use of gcc-specific feature
1481 AC_MSG_CHECKING(if you want to use gcc -fvisibility option)
1482 AC_ARG_ENABLE(fvisibility,
1483         [  --enable-fvisibility    compile with -fvisibility=hidden],
1484         [cf_with_fvisibility=$enableval],
1485         [cf_with_fvisibility=no])
1486 AC_MSG_RESULT($cf_with_fvisibility)
1487
1488 NCURSES_IMPEXP=
1489 NCURSES_CXX_IMPEXP=
1490 if test "x$cf_with_fvisibility" = xyes; then
1491         CF_CHECK_FVISIBILITY($CC,CFLAGS,cf_cv_fvisibility_hidden)
1492         if test "x$cf_cv_fvisibility_hidden" = xyes
1493         then
1494                 CF_ADD_CFLAGS([-fvisibility=hidden])
1495                 NCURSES_IMPEXP="__attribute__ ((visibility(\"default\")))"
1496         fi
1497         if test -n "$CXX"
1498         then
1499                 AC_LANG_PUSH(C++)
1500                 CF_CHECK_FVISIBILITY($CXX,CXXFLAGS,cf_cv_fvisibility_hidden2)
1501                 if test "x$cf_cv_fvisibility_hidden2" = xyes
1502                 then
1503                         CF_ADD_CXXFLAGS([-fvisibility=hidden])
1504                         NCURSES_CXX_IMPEXP="__attribute__ ((visibility(\"default\")))"
1505                 fi
1506                 AC_LANG_POP
1507         fi
1508 fi
1509 AC_SUBST(NCURSES_IMPEXP)
1510 AC_SUBST(NCURSES_CXX_IMPEXP)
1511
1512 ###   use option --enable-interop to turn on use of bindings used for interop
1513 AC_MSG_CHECKING(if you want interop bindings)
1514 AC_ARG_ENABLE(interop,
1515         [  --enable-interop        compile-in interop bindings],
1516         [with_exp_interop=$enableval],
1517         [with_exp_interop=$cf_dft_interop])
1518 AC_MSG_RESULT($with_exp_interop)
1519
1520 NCURSES_INTEROP_FUNCS=0
1521 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1522 AC_SUBST(NCURSES_INTEROP_FUNCS)
1523
1524
1525 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1526 AC_ARG_ENABLE(safe-sprintf,
1527         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1528         [with_safe_sprintf=$enableval],
1529         [with_safe_sprintf=no])
1530 AC_MSG_RESULT($with_safe_sprintf)
1531
1532 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1533 # when hashmap is used scroll hints are useless
1534 if test "$with_hashmap" = no ; then
1535 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1536 AC_ARG_ENABLE(scroll-hints,
1537         [  --disable-scroll-hints  compile without scroll-hints code],
1538         [with_scroll_hints=$enableval],
1539         [with_scroll_hints=yes])
1540 AC_MSG_RESULT($with_scroll_hints)
1541 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1542 fi
1543
1544 AC_MSG_CHECKING(if you want wgetch-events code)
1545 AC_ARG_ENABLE(wgetch-events,
1546         [  --enable-wgetch-events  compile with wgetch-events code],
1547         [with_wgetch_events=$enableval],
1548         [with_wgetch_events=no])
1549 AC_MSG_RESULT($with_wgetch_events)
1550 test "x$with_wgetch_events" = xyes && AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with wgetch-events code])
1551
1552 ###############################################################################
1553 CF_HELP_MESSAGE(Testing/development Options:)
1554
1555 ###     use option --disable-echo to suppress full display compiling commands
1556 CF_DISABLE_ECHO
1557 if test "x$enable_echo" = xyes; then
1558         ECHO_LINK=
1559 else
1560         ECHO_LINK='@ echo linking $@ ... ;'
1561         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1562         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1563 fi
1564 AC_SUBST(ECHO_LINK)
1565
1566 # --disable-stripping is used for debugging
1567 CF_INSTALL_OPTS
1568
1569 # If we're avoiding relinking of shared libraries during install, that is to
1570 # avoid modifying the build-tree.  For the same reason, avoid doing ranlib if
1571 # the install program has "-p" (for preserving timestamps).
1572 cf_cv_do_reranlib=yes
1573 if test "x$cf_cv_install_p" = xyes
1574 then
1575         if test "x$cf_cv_do_relink" != xyes
1576         then
1577                 cf_cv_do_reranlib=no
1578                 INSTALL_OPT_P="-p"
1579                 INSTALL_LIB="$INSTALL_LIB $INSTALL_OPT_P"
1580         fi
1581 fi
1582 AC_SUBST(INSTALL_OPT_P)
1583
1584 ###     use option --enable-warnings to turn on all gcc warnings
1585 AC_MSG_CHECKING(if you want to see compiler warnings)
1586 AC_ARG_ENABLE(warnings,
1587         [  --enable-warnings       build: turn on GCC compiler warnings],
1588         [with_warnings=$enableval])
1589 AC_MSG_RESULT($with_warnings)
1590
1591 if test "x$with_warnings" = "xyes"; then
1592         CF_ADD_ADAFLAGS(-gnatg)
1593         CF_GCC_WARNINGS(Wno-unknown-pragmas Wswitch-enum)
1594         if test "x$cf_with_cxx" = xyes ; then
1595                 CF_GXX_WARNINGS(Wno-unused)
1596         fi
1597 fi
1598 CF_GCC_ATTRIBUTES
1599 CF_ENABLE_STRING_HACKS
1600
1601 ###     use option --enable-assertions to turn on generation of assertion code
1602 AC_MSG_CHECKING(if you want to enable runtime assertions)
1603 AC_ARG_ENABLE(assertions,
1604         [  --enable-assertions     test: turn on generation of assertion code],
1605         [with_assertions=$enableval],
1606         [with_assertions=no])
1607 AC_MSG_RESULT($with_assertions)
1608 if test -n "$GCC"
1609 then
1610         if test "$with_assertions" = no
1611         then
1612                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1613         else
1614                 CF_ADD_ADAFLAGS(-gnata)
1615         fi
1616 fi
1617
1618 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1619 CF_DISABLE_LEAKS
1620 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1621
1622 ###     use option --enable-expanded to generate certain macros as functions
1623 AC_ARG_ENABLE(expanded,
1624         [  --enable-expanded       test: generate functions for certain macros],
1625         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1626
1627 ###     use option --disable-macros to suppress macros in favor of functions
1628 AC_ARG_ENABLE(macros,
1629         [  --disable-macros        test: use functions rather than macros],
1630         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1631
1632 # Normally we only add trace() to the debug-library.  Allow this to be
1633 # extended to all models of the ncurses library:
1634 cf_all_traces=no
1635 case "$CFLAGS $CPPFLAGS" in
1636 (*-DTRACE*)
1637         cf_all_traces=yes
1638         ;;
1639 esac
1640
1641 AC_MSG_CHECKING(whether to add trace feature to all models)
1642 AC_ARG_WITH(trace,
1643 [  --with-trace            test: add trace() function to all models of ncurses],
1644 [cf_with_trace=$withval],
1645 [cf_with_trace=$cf_all_traces])
1646 AC_MSG_RESULT($cf_with_trace)
1647
1648 if test "x$cf_with_trace" = xyes ; then
1649         LIB_TRACING=all
1650         ADA_TRACE=TRUE
1651         CF_ADD_CFLAGS(-DTRACE)
1652         AC_DEFINE(HAVE__TRACEF,1,[Define to 1 if we have _tracef function])
1653 else
1654         LIB_TRACING=DEBUG
1655         ADA_TRACE=FALSE
1656 fi
1657
1658 AC_SUBST(ADA_TRACE)
1659
1660 CF_DISABLE_GNAT_PROJECTS
1661
1662 ###     Checks for libraries.
1663 case $cf_cv_system_name in
1664 (*mingw32*|*mingw64*)
1665         CPPFLAGS="$CPPFLAGS -DWINVER=0x0501 -DWIN32_LEAN_AND_MEAN"
1666         # Note: WINVER may be a problem with Windows 10
1667         ;;
1668 (*)
1669 AC_CHECK_FUNC(gettimeofday,
1670         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1671
1672 AC_CHECK_LIB(bsd, gettimeofday,
1673         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1674         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1675         ;;
1676 esac
1677
1678 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1679 AC_SUBST(MATH_LIB)
1680
1681 ###     Checks for header files.
1682 AC_STDC_HEADERS
1683 AC_HEADER_DIRENT
1684 AC_HEADER_TIME
1685 CF_REGEX
1686
1687 dnl These are some other potentially nonportable headers.
1688 AC_CHECK_HEADERS( \
1689 fcntl.h \
1690 getopt.h \
1691 limits.h \
1692 locale.h \
1693 math.h \
1694 poll.h \
1695 sys/ioctl.h \
1696 sys/param.h \
1697 sys/poll.h \
1698 sys/select.h \
1699 sys/time.h \
1700 sys/times.h \
1701 ttyent.h \
1702 unistd.h \
1703 wctype.h \
1704 )
1705
1706 CF_GETOPT_HEADER
1707
1708 CF_CHECK_ENVIRON(environ)
1709 CF_CHECK_GETENV
1710 if test "x$cf_cv_consistent_getenv" = xno && \
1711         test "x$cf_with_trace" = xyes
1712 then
1713         AC_MSG_WARN(The NCURSES_TRACE environment variable is not supported with this configuration)
1714 fi
1715
1716 CF_SYS_TIME_SELECT
1717
1718 ###     checks for compiler characteristics
1719 AC_LANG_C
1720 AC_C_CONST
1721 CF_C_INLINE(NCURSES_INLINE,1200)
1722 CF_SIG_ATOMIC_T
1723
1724 if test $NCURSES_CHTYPE = auto ; then
1725         CF_TYPEOF_CHTYPE
1726 else
1727         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1728 fi
1729 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1730 AC_SUBST(cf_cv_typeof_chtype)
1731
1732 CF_UNSIGNED_LITERALS
1733 cf_cv_1UL="1"
1734 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1735 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1736 AC_SUBST(cf_cv_1UL)
1737
1738 if test $NCURSES_MMASK_T = auto ; then
1739         cf_cv_typeof_mmask_t=long
1740 else
1741         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1742 fi
1743 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1744 AC_SUBST(cf_cv_typeof_mmask_t)
1745
1746 ###     Checks for external-data
1747 CF_ERRNO
1748 CF_LINK_DATAONLY
1749
1750 ###     Checks for library functions.
1751 AC_CHECK_FUNCS( \
1752 getcwd \
1753 getegid \
1754 geteuid \
1755 getopt \
1756 getttynam \
1757 issetugid \
1758 localeconv \
1759 poll \
1760 putenv \
1761 remove \
1762 select \
1763 setbuf \
1764 setbuffer \
1765 setenv \
1766 setvbuf \
1767 sigaction \
1768 sigvec \
1769 snprintf \
1770 strdup \
1771 strstr \
1772 sysconf \
1773 tcgetpgrp \
1774 times \
1775 tsearch \
1776 vsnprintf \
1777 )
1778
1779 if test "x$ac_cv_func_getopt" = xno && \
1780    test "x$cf_with_progs$cf_with_tests" != xnono; then
1781         AC_MSG_ERROR(getopt is required for building programs)
1782 fi
1783
1784 if test "x$with_safe_sprintf" = xyes
1785 then
1786         if test "x$ac_cv_func_vsnprintf" = xyes
1787         then
1788                 AC_MSG_WARN(will use vsnprintf instead of safe-sprintf option)
1789         else
1790                 AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1791         fi
1792 fi
1793
1794 if test "x$with_getcap" = "xyes" ; then
1795         CF_CGETENT
1796 fi
1797
1798 CF_ISASCII
1799 CF_STRUCT_SIGACTION
1800 CF_FUNC_NANOSLEEP
1801 CF_FUNC_TERMIOS
1802 CF_FUNC_VSSCANF
1803 CF_MKSTEMP
1804
1805 # setup for prototype of fallback for vsscanf()
1806 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1807
1808 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1809 if test "x$cross_compiling" = xyes ; then
1810         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1811 else
1812         AC_FUNC_SETVBUF_REVERSED
1813 fi
1814 AC_CHECK_TYPE(intptr_t, long)
1815 AC_CHECK_TYPE(ssize_t, int)
1816 CF_TYPE_SIGACTION
1817 CF_SIZECHANGE
1818 CF_FUNC_MEMMOVE
1819 CF_FUNC_POLL
1820 CF_VA_COPY
1821 AC_FUNC_VFORK
1822 CF_FOPEN_BIN_R
1823
1824 # special check for test/ditto.c
1825 CF_FUNC_OPENPTY
1826 if test "$cf_cv_func_openpty" != no ; then
1827         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1828         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1829         if test "x$cf_cv_lib_util" = xyes ; then
1830                 CF_ADD_LIB(util,TEST_LIBS)
1831         fi
1832 fi
1833 AC_SUBST(TEST_LIBS)
1834 AC_SUBST(TEST_LIBS2)
1835
1836 if test "$with_hashed_db" != no ; then
1837         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1838         CF_HASHED_DB($with_hashed_db)
1839 fi
1840
1841 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1842 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1843         CF_STRIP_G_OPT(CFLAGS)
1844         CF_STRIP_G_OPT(CXXFLAGS)
1845 fi
1846
1847 # Just in case, check if the C compiler has a bool type.
1848 CF_BOOL_DECL(cf_cv_cc_bool_type)
1849
1850 # Check for C++ compiler characteristics (and ensure that it's there!)
1851 if test -n "$CXX" ; then
1852         AC_LANG_CPLUSPLUS
1853         CF_STDCPP_LIBRARY
1854         CF_PROG_CC_C_O(CXX,[$CXXFLAGS $CPPFLAGS])
1855
1856         case $GXX_VERSION in
1857         (1.*|2.[[0-6]]*|[[1-9]][[0-9]].*)
1858                 cf_cxx_library=yes
1859                 ;;
1860         (*-2.7*|2.7*)
1861                 CF_GPP_LIBRARY
1862                 ;;
1863         (*)
1864                 cf_cxx_library=no
1865                 ;;
1866         esac
1867
1868         AC_CHECK_HEADERS(typeinfo)
1869         CF_CXX_IOSTREAM_NAMESPACE
1870         CF_BOOL_DECL
1871         CF_BOOL_SIZE
1872         CF_ETIP_DEFINES
1873         CF_CPP_PARAM_INIT
1874         CF_CPP_STATIC_CAST
1875         CF_CXX_AR_FLAGS
1876 else
1877         cf_cxx_library=no
1878         cf_cv_builtin_bool=1
1879
1880         # Just because we are not configuring against C++ right now does not
1881         # mean that a user will not want to use C++.  Some distributors disable
1882         # the C++ portion of this configuration as a shortcut (or just to avoid
1883         # compiling the demo in the c++ directory).  So we need a reasonable
1884         # default for the 'bool' type.
1885         #
1886         # Caveat: since the storage of the bool type is not standardized, it
1887         # may change.
1888
1889         if test "$NCURSES_BOOL" != auto ; then
1890                 cf_cv_type_of_bool=$NCURSES_BOOL
1891                 cf_cv_header_stdbool_h=0
1892         else
1893                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1894                         CF_BOOL_SIZE
1895                 else
1896                         AC_MSG_CHECKING(for fallback type of bool)
1897                         case "$host_cpu" in
1898                         (i?86)  cf_cv_type_of_bool=char ;;
1899                         (*)     cf_cv_type_of_bool=int  ;;
1900                         esac
1901                         AC_MSG_RESULT($cf_cv_type_of_bool)
1902                 fi
1903         fi
1904 fi
1905 AC_SUBST(CXXLIBS)
1906
1907 # If the C compiler did not declare bool, and we did not determine that the C++
1908 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1909 # ncurses library use the same type as C++ bool.  Note that this allows one to
1910 # specify the type of bool in a configure-script option and postpone
1911 # integration with the C++ compiler provided that the types are compatible.
1912 USE_CXX_BOOL=1
1913 if test $cf_cv_cc_bool_type = 1
1914 then
1915         # oops: C has a bool.  Unlikely, but C++ could differ.
1916         USE_CXX_BOOL=0
1917 elif test $cf_cv_builtin_bool = 0
1918 then
1919         # C++ has no bool
1920         USE_CXX_BOOL=0
1921 else
1922         # this is the normal case
1923         USE_CXX_BOOL='defined(__cplusplus)'
1924 fi
1925 AC_SUBST(USE_CXX_BOOL)
1926
1927 CF_HELP_MESSAGE(Ada Binding Options:)
1928
1929 dnl If the Ada95 source-tree is present, add that to the build unless it will
1930 dnl not work, or was not requested.
1931 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1932
1933 dnl libtool does not know anything about GNAT, though a change made in 1998
1934 dnl provided for it "someday".  Disable the ada subtree if we are using
1935 dnl libtool -TD 20070714
1936         if test "$cf_with_ada" != "no" ; then
1937                 if test "$with_libtool" != "no"; then
1938                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1939                         cf_with_ada=no
1940                 fi
1941         fi
1942
1943 dnl Check for availability of GNU Ada Translator (GNAT).
1944 dnl At the moment we support no other Ada compiler.
1945         if test "$cf_with_ada" != "no" ; then
1946                 CF_PROG_GNAT
1947                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
1948                         CF_ADD_ADAFLAGS(-gnatpn)
1949                         CF_FIXUP_ADAFLAGS
1950
1951                         CF_GNATPREP_OPT_T
1952
1953                         CF_GNAT_GENERICS
1954                         CF_GNAT_SIGINT
1955                         CF_GNAT_PROJECTS
1956
1957                         CF_WITH_ADA_COMPILER
1958
1959                         cf_ada_package=terminal_interface
1960                         AC_SUBST(cf_ada_package)
1961
1962                         CF_WITH_ADA_INCLUDE
1963                         CF_WITH_ADA_OBJECTS
1964                         CF_WITH_ADA_SHAREDLIB
1965
1966                         # allow the Ada binding to be renamed
1967                         CF_WITH_ADA_LIBNAME(AdaCurses)
1968                 fi
1969         fi
1970 else
1971         cf_with_ada=no
1972 fi
1973
1974 # do this "late" to avoid conflict with header-checks
1975 if test "x$with_widec" = xyes ; then
1976         AC_CHECK_SIZEOF(wchar_t)
1977         # cross-compiling to mingw can run into the problem that attempting to
1978         # link with the regex library fails, causing the test to not set this to
1979         # a number.  "recent" autoconf does not address this problem either -TD
1980         if test -z "$ac_cv_sizeof_wchar_t"
1981         then
1982                 CF_VERBOSE(test failed (assume 2))
1983                 sed /SIZEOF_WCHAR_T/d confdefs.h >confdefs.tmp
1984                 mv confdefs.tmp confdefs.h
1985                 echo "#define SIZEOF_WCHAR_T 2" >>confdefs.h
1986         fi
1987 fi
1988
1989 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1990 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1991 ###
1992 ### ticlib modules may be a separate library, otherwise contained in termlib.
1993 ### termlib modules may be a separate library, otherwise contained in ncurses.
1994 ###
1995 ### The of "+" or " " between the tokens controls the way the script
1996 ### chooses to split module lists into libraries.
1997 ###
1998 ### (see CF_LIB_RULES).
1999 AC_MSG_CHECKING(for library subsets)
2000 LIB_SUBSETS=
2001
2002 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
2003         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
2004         if test "$with_ticlib" != no ; then
2005                 LIB_SUBSETS="${LIB_SUBSETS} "
2006         else
2007                 LIB_SUBSETS="${LIB_SUBSETS}+"
2008         fi
2009 fi
2010
2011 LIB_SUBSETS="${LIB_SUBSETS}termlib"
2012 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
2013
2014 if test "$with_termlib" != no ; then
2015         LIB_SUBSETS="${LIB_SUBSETS} "
2016 else
2017         LIB_SUBSETS="${LIB_SUBSETS}+"
2018 fi
2019
2020 LIB_SUBSETS="${LIB_SUBSETS}base"
2021
2022 # Most term-driver calls are to tinfo, but some like init_pair are to the
2023 # base library (so it resides in base).
2024 if test "$with_term_driver" != no ; then
2025         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
2026         case $cf_cv_system_name in
2027         (*mingw32*|*mingw64*)
2028                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
2029                 CPPFLAGS="$CPPFLAGS -DUSE_WIN32CON_DRIVER"
2030                 ;;
2031         (*)
2032                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
2033                 ;;
2034         esac
2035 fi
2036
2037 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
2038 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
2039
2040 AC_MSG_RESULT($LIB_SUBSETS)
2041
2042 ### Construct the list of include-directories to be generated
2043 CF_INCLUDE_DIRS
2044 CF_ADA_INCLUDE_DIRS
2045
2046 ### Build up pieces for makefile rules
2047 AC_MSG_CHECKING(default library suffix)
2048 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
2049 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
2050 AC_MSG_RESULT($DFT_ARG_SUFFIX)
2051
2052 AC_MSG_CHECKING(default library-dependency suffix)
2053 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
2054 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
2055 AC_MSG_RESULT($DFT_DEP_SUFFIX)
2056
2057 AC_MSG_CHECKING(default object directory)
2058 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
2059 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
2060 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
2061
2062 if test "x$cf_with_cxx" = xyes ; then
2063 AC_MSG_CHECKING(c++ library-dependency suffix)
2064 if test "$with_libtool" != "no"; then
2065         # libtool thinks it can make c++ shared libraries (perhaps only g++)
2066         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2067 elif test "$with_shared_cxx" != "no"; then
2068         # also for g++ users...
2069         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2070 else
2071         # we normally make a static library because C/C++ library rules differ
2072         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
2073 fi
2074 AC_MSG_RESULT($CXX_LIB_SUFFIX)
2075 AC_SUBST(CXX_LIB_SUFFIX)
2076 fi
2077
2078 # do not want -ldl in build except as needed for -lncurses dependency
2079 if test "x$with_dlsym" = xyes ; then
2080 if test $DFT_LWR_MODEL = shared || \
2081    test $DFT_LWR_MODEL = libtool ; then
2082         CF_REMOVE_LIB(LIBS,$LIBS,dl)
2083 fi
2084 fi
2085 ### Set up low-level terminfo dependencies for makefiles.
2086
2087 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
2088 # do not need libdl
2089 TICS_LIST=
2090 if test "x$with_dlsym" = xyes ; then
2091         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
2092 fi
2093
2094 USE_ARG_SUFFIX="${DFT_ARG_SUFFIX}${EXTRA_SUFFIX}"
2095 USE_LIB_SUFFIX="${LIB_SUFFIX}${EXTRA_SUFFIX}"
2096 USE_CFG_SUFFIX=${DFT_ARG_SUFFIX}${cf_cv_abi_version}
2097 if test -n "$EXTRA_SUFFIX" && test "x$EXTRA_SUFFIX" != "x${cf_cv_abi_version}"
2098 then
2099         USE_CFG_SUFFIX="${USE_CFG_SUFFIX}${EXTRA_SUFFIX}"
2100 fi
2101 AC_SUBST(USE_ARG_SUFFIX)
2102 AC_SUBST(USE_CFG_SUFFIX)
2103 AC_SUBST(USE_LIB_SUFFIX)
2104
2105 if test "$with_ticlib" != no ; then
2106
2107         if test "x$with_ticlib" != xyes ; then
2108                 TICS_NAME=$with_ticlib
2109                 TICS_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
2110                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2111                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2112                 TICS_LIB_SUFFIX="${with_ticlib}"
2113         else
2114                 TICS_SUFFIX=${DFT_LIB_SUFFIX}
2115                 TICS_ARG_SUFFIX="${TICS_NAME}${USE_ARG_SUFFIX}"
2116                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
2117                 TICS_LIB_SUFFIX="${TICS_NAME}${USE_LIB_SUFFIX}"
2118         fi
2119         TICS_LDFLAGS="-L${LIB_DIR}"
2120         TICS_LIBS="-l${TICS_ARG_SUFFIX}"
2121 else
2122         TICS_SUFFIX=${DFT_LIB_SUFFIX}
2123         TICS_LDFLAGS="-L${LIB_DIR}"
2124         TICS_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2125 fi
2126 AC_SUBST(TICS_ARG_SUFFIX)
2127 AC_SUBST(TICS_DEP_SUFFIX)
2128 AC_SUBST(TICS_LIB_SUFFIX)
2129 AC_SUBST(TICS_LDFLAGS)
2130 AC_SUBST(TICS_LIBS)
2131
2132 if test "$with_termlib" != no ; then
2133
2134         if test "x$with_termlib" != xyes ; then
2135                 TINFO_NAME=$with_termlib
2136                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
2137                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2138                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2139                 TINFO_LIB_SUFFIX="${with_termlib}"
2140         else
2141                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2142                 TINFO_ARG_SUFFIX="${TINFO_NAME}${USE_ARG_SUFFIX}"
2143                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
2144                 TINFO_LIB_SUFFIX="${TINFO_NAME}${USE_LIB_SUFFIX}"
2145         fi
2146
2147         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2148         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2149         if test "$DFT_LWR_MODEL" = "libtool"; then
2150                 TEST_ARGS="${TEST_DEPS}"
2151                 TEST_ARG2="${TEST_DEP2}"
2152                 TINFO_LDFLAGS="-L${LIB_DIR}"
2153                 TINFO_LIBS="$TEST_ARGS"
2154                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
2155                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
2156         else
2157                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
2158                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
2159                 if test "x$with_term_driver" != xno ; then
2160                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2161                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${USE_ARG_SUFFIX}"
2162                         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
2163                 else
2164                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2165                         TINFO_LIBS="$TEST_ARGS"
2166                 fi
2167                 TINFO_LDFLAGS="-L${LIB_DIR}"
2168                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2169         fi
2170 else
2171         # the next lines are needed for linking libtic over libncurses
2172         TINFO_NAME=${LIB_NAME}
2173         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2174         TINFO_ARG_SUFFIX=${LIB_NAME}${USE_ARG_SUFFIX}
2175         if test "x$with_tic_depends" = xyes ; then
2176                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2177         else
2178                 TICS_LIST="$SHLIB_LIST"
2179         fi
2180
2181         TINFO_LDFLAGS="-L${LIB_DIR}"
2182         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2183 fi
2184
2185 if test "$DFT_LWR_MODEL" = shared ; then
2186         case $cf_cv_system_name in
2187         (cygwin*|msys*)
2188                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
2189                 TINFO_SUFFIX=.dll
2190                 ;;
2191         esac
2192 fi
2193
2194 AC_SUBST(TINFO_ARG_SUFFIX)
2195 AC_SUBST(TINFO_DEP_SUFFIX)
2196 AC_SUBST(TINFO_LIB_SUFFIX)
2197 AC_SUBST(TINFO_LDFLAGS)
2198 AC_SUBST(TINFO_LIBS)
2199
2200 if test "x$with_dlsym" = xyes ; then
2201         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
2202 fi
2203
2204 if test "$DFT_LWR_MODEL" = "libtool"; then
2205         OBJEXT=lo
2206 fi
2207
2208 # needed for Ada95
2209 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
2210 AC_SUBST(TINFO_LDFLAGS2)
2211
2212 case $DFT_LWR_MODEL in
2213 (normal|debug|profile)
2214         CF_LDFLAGS_STATIC
2215         ;;
2216 esac
2217
2218 AC_MSG_CHECKING(where we will install curses.h)
2219 AC_SUBST(includesubdir)
2220 includesubdir=
2221 if test "$with_overwrite" = no && \
2222  ( test "x$includedir" = 'x${prefix}/include' || \
2223    test "x$includedir" = "x${prefix}/include" )
2224 then
2225         includesubdir="/ncurses${USE_LIB_SUFFIX}"
2226 fi
2227 AC_MSG_RESULT(${includedir}${includesubdir})
2228
2229 ### Resolve a conflict between normal and wide-curses by forcing applications
2230 ### that will need libutf8 to add it to their configure script.
2231 if test "$with_overwrite" != no ; then
2232 if test "$NCURSES_LIBUTF8" = 1 ; then
2233         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
2234         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
2235 fi
2236 fi
2237 WITH_OVERWRITE=$with_overwrite
2238
2239 ### At least on MinGW a shared library build without libtool
2240 ### requires adding the additional libs to the link list.
2241 case $cf_cv_system_name in
2242 (*mingw32*|*mingw64*)
2243         if test "$DFT_LWR_MODEL" != "libtool"; then
2244            SHLIB_LIST="$SHLIB_LIST ${LIBS}"
2245         fi
2246         ;;
2247 *)      ;;
2248 esac
2249
2250 AC_SUBST(WITH_OVERWRITE)
2251 AC_SUBST(TICS_LIST)
2252 AC_SUBST(TINFO_LIST)
2253 AC_SUBST(SHLIB_LIST)
2254
2255 # used to separate tack out of the tree
2256 NCURSES_TREE=
2257 AC_SUBST(NCURSES_TREE)
2258
2259 ### predefined stuff for the test programs
2260 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
2261
2262 # pkgsrc uses these
2263 CF_WITH_LIB_BASENAME(FORM_NAME,form)
2264 CF_WITH_LIB_BASENAME(MENU_NAME,menu)
2265 CF_WITH_LIB_BASENAME(PANEL_NAME,panel)
2266 CF_WITH_LIB_BASENAME(CXX_NAME,cxx,ncurses++)
2267
2268 ### Construct the list of subdirectories for which we'll customize makefiles
2269 ### with the appropriate compile-rules.
2270
2271 CF_SRC_MODULES($modules_to_build)
2272
2273 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2274    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/src/library.gpr:Ada95/src/library.gpr.in"
2275    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${USE_CFG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
2276    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${USE_CFG_SUFFIX}-config.1:man/MKada_config.in"
2277 fi
2278
2279 CF_DIRS_TO_MAKE
2280
2281 # symbols that differ when compiling Ada95 by itself.
2282 NCURSES_SHLIB2=$SHELL' $(top_srcdir)/misc/shlib'
2283 AC_SUBST(NCURSES_SHLIB2)
2284
2285 # values to use as strings
2286 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
2287
2288 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
2289
2290 ### Now that we're done running tests, add the compiler-warnings, if any
2291 CF_ADD_CFLAGS($EXTRA_CFLAGS)
2292
2293 ### Define substitutions for header files to avoid name-pollution
2294 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
2295 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
2296 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
2297 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
2298
2299 ################################################################################
2300 test "x$use_database" = xyes && \
2301 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
2302
2303 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
2304 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${USE_CFG_SUFFIX}-config.1:man/MKncu_config.in"
2305
2306 if test "x$enable_pc_files" = xyes && test -z "$MAKE_PC_FILES" ; then
2307 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
2308 fi
2309 AC_SUBST(cross_compiling)
2310
2311 if test "x$cf_with_tests" != xno ; then
2312         MAKE_TESTS=
2313 else
2314         MAKE_TESTS="#"
2315 fi
2316 AC_SUBST(MAKE_TESTS)
2317
2318 ADAHTML_DIR=../../doc/html/ada
2319 AC_SUBST(ADAHTML_DIR)
2320
2321 # workaround for OS/2 (20151017)
2322 case $cf_cv_system_name in
2323 (os2*)
2324         LIBTOOL_OPTS_CXX="-os2dllname ncurs++"
2325         ;;
2326 (*)
2327         LIBTOOL_OPTS_CXX=
2328         ;;
2329 esac
2330 AC_SUBST(LIBTOOL_OPTS_CXX)
2331
2332 # workaround for g++ versus Solaris (20131116)
2333 case $cf_cv_system_name in
2334 (solaris2*)
2335         case "x$CPPFLAGS" in
2336         (*-D_XOPEN_SOURCE_EXTENDED*)
2337                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
2338                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
2339                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
2340                 ;;
2341         esac
2342         ;;
2343 esac
2344
2345 # Help to automatically enable the extended curses features when using either
2346 # the *-config or the ".pc" files by adding defines.
2347 AC_MSG_CHECKING(for defines to add to ncurses${USE_CFG_SUFFIX}-config script)
2348 PKG_CFLAGS=
2349 for cf_loop1 in $CPPFLAGS_after_XOPEN
2350 do
2351         cf_found=no
2352         for cf_loop2 in $CPPFLAGS_before_XOPEN
2353         do
2354                 if test "x$cf_loop1" = "x$cf_loop2"
2355                 then
2356                         cf_found=yes
2357                         break
2358                 fi
2359         done
2360         test "$cf_found" = no && PKG_CFLAGS="$PKG_CFLAGS $cf_loop1"
2361 done
2362 AC_MSG_RESULT($PKG_CFLAGS)
2363 AC_SUBST(PKG_CFLAGS)
2364
2365 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
2366 case "x$NCURSES_OSPEED" in
2367 (*short*)
2368         cf_compatible=1
2369         ;;
2370 (*)
2371         cf_compatible=0
2372         ;;
2373 esac
2374 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
2375
2376 case "x$cf_cv_typeof_chtype" in
2377 (xshort|xint|xlong)
2378         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
2379         ;;
2380 esac
2381
2382 case "x$cf_cv_typeof_mmask_t" in
2383 (xshort|xint|xlong)
2384         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2385         ;;
2386 esac
2387
2388 # substitute into misc/Makefile to suppress
2389 # (un)install.data from the
2390 # (un)install rules.
2391 if test "x$cf_with_db_install" = "xno"; then
2392         MISC_INSTALL_DATA=
2393         MISC_UNINSTALL_DATA=
2394 else
2395         MISC_INSTALL_DATA=install.data
2396         MISC_UNINSTALL_DATA=uninstall.data
2397 fi
2398 AC_SUBST(MISC_INSTALL_DATA)
2399 AC_SUBST(MISC_UNINSTALL_DATA)
2400
2401 if test "x$cf_with_db_install" = "xno" || test "x$TERMINFO_SRC" = "xno"; then
2402         MAKE_DATABASE="#"
2403 else
2404         MAKE_DATABASE="$MAKE_TERMINFO"
2405 fi
2406 AC_SUBST(MAKE_DATABASE)
2407
2408 dnl Override the package used for exported symbols
2409 if test -n "$PACKAGE"
2410 then
2411         PACKAGE="${PACKAGE}${DFT_ARG_SUFFIX}"
2412         export PACKAGE
2413         echo "package: $PACKAGE"
2414 fi
2415
2416 UNALTERED_SYMS=
2417 cf_filter_syms=no
2418
2419 if test -n "$RESULTING_SYMS"
2420 then
2421         cf_filter_syms=$cf_dft_filter_syms
2422         CF_VERBOSE(will map symbols to ABI=$cf_cv_abi_version)
2423 fi
2424
2425 if test "x$WILDCARD_SYMS" = xno
2426 then
2427         cf_filter_syms=yes
2428 fi
2429
2430 test "x$cf_with_trace" = xyes && NCURSES_INLINE=
2431
2432 UNALTERED_SYMS=`echo "$RESULTING_SYMS" | sed -e 's/\\$/\\\\$/g'`
2433 if test $cf_filter_syms = yes
2434 then
2435         RESULTING_SYMS=resulting.map
2436 fi
2437 AC_SUBST(UNALTERED_SYMS)
2438
2439 if test "x$cross_compiling" = xyes ; then
2440         ADAGEN_LDFLAGS='$(CROSS_LDFLAGS)'
2441         CHECK_BUILD="#"
2442 else
2443         ADAGEN_LDFLAGS='$(NATIVE_LDFLAGS)'
2444         CHECK_BUILD=
2445 fi
2446 AC_SUBST(ADAGEN_LDFLAGS)
2447 AC_SUBST(CHECK_BUILD)
2448 AC_SUBST(PRIVATE_LIBS)
2449
2450 # This is used for the *-config script and *.pc data files.
2451 CF_LD_SEARCHPATH
2452
2453 AC_DEFINE(HAVE_CURSES_DATA_BOOLNAMES,1,[definition needed for in-tree build of tack])
2454
2455 AC_OUTPUT( \
2456         include/MKterm.h.awk \
2457         include/curses.head:include/curses.h.in \
2458         include/ncurses_dll.h \
2459         include/termcap.h \
2460         include/unctrl.h \
2461         $SUB_MAKEFILES \
2462         Makefile,[
2463 if test "x$cf_with_tests" != xno ; then
2464         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2465 fi
2466 CF_LIB_RULES($SRC_SUBDIRS)
2467
2468 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2469 if test -z "$USE_OLD_MAKERULES" ; then
2470         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
2471 fi
2472 fi
2473 ],[
2474 ### Special initialization commands, used to pass information from the
2475 ### configuration-run into config.status
2476
2477 ALTERNATE_SYMS="$ALTERNATE_SYMS"
2478 AWK="$AWK"
2479 CXX_NAME="$CXX_NAME"
2480 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2481 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2482 ECHO_LD="$ECHO_LD"
2483 EXTRA_SUFFIX="$EXTRA_SUFFIX"
2484 FORM_NAME="$FORM_NAME"
2485 LDCONFIG="$LDCONFIG"
2486 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2487 LIB_NAME="$LIB_NAME"
2488 LIB_PREFIX="$LIB_PREFIX"
2489 LIB_SUBSETS="$LIB_SUBSETS"
2490 LIB_SUFFIX="$LIB_SUFFIX"
2491 LIB_TRACING="$LIB_TRACING"
2492 LN_S="$LN_S"
2493 MAKE_TERMINFO="$MAKE_TERMINFO"
2494 MENU_NAME="$MENU_NAME"
2495 NCURSES_MAJOR="$NCURSES_MAJOR"
2496 NCURSES_MINOR="$NCURSES_MINOR"
2497 NCURSES_OSPEED="$NCURSES_OSPEED"
2498 NCURSES_PATCH="$NCURSES_PATCH"
2499 PANEL_NAME="$PANEL_NAME"
2500 SRC_SUBDIRS="$SRC_SUBDIRS"
2501 TERMINFO="$TERMINFO"
2502 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2503 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2504 TICS_NAME="$TICS_NAME"
2505 TICS_SUFFIX="$TICS_SUFFIX"
2506 TIC_PATH="$TIC_PATH"
2507 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2508 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2509 TINFO_NAME="$TINFO_NAME"
2510 TINFO_SUFFIX="$TINFO_SUFFIX"
2511 UNALTERED_SYMS="$UNALTERED_SYMS"
2512 USE_ARG_SUFFIX="$USE_ARG_SUFFIX"
2513 USE_CFG_SUFFIX="$USE_CFG_SUFFIX"
2514 USE_LIB_SUFFIX="$USE_LIB_SUFFIX"
2515 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2516 WILDCARD_SYMS="$WILDCARD_SYMS"
2517 WITH_CURSES_H="$with_curses_h"
2518 WITH_ECHO="${enable_echo:=yes}"
2519 WITH_OVERWRITE="$with_overwrite"
2520 cf_LIST_MODELS="$cf_list_models"
2521 cf_cv_abi_version="$cf_cv_abi_version"
2522 cf_cv_do_relink="$cf_cv_do_relink"
2523 cf_cv_do_reranlib="$cf_cv_do_reranlib"
2524 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2525 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2526 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2527 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2528 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2529 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2530 cf_cv_rel_version="$cf_cv_rel_version"
2531 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2532 cf_cv_shared_soname='$cf_cv_shared_soname'
2533 cf_cv_shlib_version="$cf_cv_shlib_version"
2534 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2535 cf_cv_system_name="$cf_cv_system_name"
2536 cf_cv_term_driver="$with_term_driver"
2537 cf_with_ada="$cf_with_ada"
2538 cf_with_cxx_binding="$cf_with_cxx_binding"
2539 cf_with_db_install="$cf_with_db_install"
2540 cf_with_manpages="$cf_with_manpages"
2541 cf_with_tests="$cf_with_tests"
2542 host="$host"
2543 target="$target"
2544 with_shared_cxx="$with_shared_cxx"
2545
2546 ],cat)dnl
2547 ${MAKE:-make} preinstall