man/manlinks.sed

   1 # $Id: manlinks.sed,v 1.15 2021/01/05 20:30:00 tom Exp $
   2 ##############################################################################
   3 # Copyright 2020,2021 Thomas E. Dickey                                       #
   4 # Copyright 2000-2003,2008 Free Software Foundation, Inc.                    #
   5 #                                                                            #
   6 # Permission is hereby granted, free of charge, to any person obtaining a    #
   7 # copy of this software and associated documentation files (the "Software"), #
   8 # to deal in the Software without restriction, including without limitation  #
   9 # the rights to use, copy, modify, merge, publish, distribute, distribute    #
  10 # with modifications, sublicense, and/or sell copies of the Software, and to #
  11 # permit persons to whom the Software is furnished to do so, subject to the  #
  12 # following conditions:                                                      #
  13 #                                                                            #
  14 # The above copyright notice and this permission notice shall be included in #
  15 # all copies or substantial portions of the Software.                        #
  16 #                                                                            #
  17 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR #
  18 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,   #
  19 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL    #
  20 # THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER      #
  21 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING    #
  22 # FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER        #
  23 # DEALINGS IN THE SOFTWARE.                                                  #
  24 #                                                                            #
  25 # Except as contained in this notice, the name(s) of the above copyright     #
  26 # holders shall not be used in advertising or otherwise to promote the sale, #
  27 # use or other dealings in this Software without prior written               #
  28 # authorization.                                                             #
  29 ##############################################################################
  30 # Given a manpage (nroff) as input, writes a list of the names that are
  31 # listed in the "NAME" section, i.e., the names that we would like to use
  32 # as aliases for the manpage -T.Dickey
  33 #
  34 # eliminate formatting controls that get in the way
  35 /^'\\"/d
  36 /\.\\"/d
  37 /^\.br/d
  38 /^\.sp/d
  39 /typedef/d
  40 s/^\.IX//
  41 s/\\f.//g
  42 s/[:,]/ /g
  43 #
  44 # ignore C-style comments
  45 s%/\*.*\*/%%
  46 #
  47 # eliminate unnecessary whitespace, convert multiple blanks to single space
  48 s/^[    ][      ]*//
  49 s/[     ][      ]*$//
  50 s/[     ][      ]*/ /g
  51 /^$/d
  52 #
  53 # convert ".SH" into a more manageable form
  54 s/\.SH[         ][      ]*/.SH_(/
  55 #
  56 # in ".SH NAME"
  57 # change "\-" to "-", eliminate text after "-", and split the remaining lines
  58 # at each space, making a list of names:
  59 /^\.SH_(NAME/,/^\.SH_(SYNOPSIS/{
  60 s/\\-.*/ -/
  61 / -/{
  62 s/ -.*//
  63 s/ /\
  64 /g
  65 }
  66 /^-/{
  67 d
  68 }
  69 s/ /\
  70 /g
  71 }
  72 #
  73 # in ".SH SYNOPSIS"
  74 # remove any line that does not contain a '(', since we only want functions.
  75 # then strip off return-type of each function.
  76 # finally, remove the parameter list, which begins with a '('.
  77 /^\.SH_(SYNOPSIS/,/^\.SH_(DESCRIPTION/{
  78 /^[^(]*$/d
  79 # reduce
  80 #       .B "int add_wch( const cchar_t *\fIwch\fB );"
  81 # to
  82 #       add_wch( const cchar_t *\fIwch\fB );"
  83 s/^\([^ (]* [^ (]* [*]*\)//g
  84 s/^\([^ (]* [*]*\)//g
  85 # trim blanks in case we have
  86 #       void (*) (FORM *) field_init(const FORM *form);
  87 s/) (/)(/g
  88 # reduce stuff like
  89 #       void (*)(FORM *) field_init(const FORM *form);
  90 # to
  91 #       field_init(const FORM *form);
  92 s/^\(([^)]*)\)\(([^)]*)\)*[ ]*//g
  93 # rename marker temporarily
  94 s/\.SH_(/.SH_/
  95 # kill lines with ");", and trim off beginning of argument list.
  96 s/[()].*//
  97 # rename marker back
  98 s/\.SH_/.SH_(/
  99 }
 100 #
 101 # delete ".SH DESCRIPTION" and following lines
 102 /^\.SH_(DESCRIPTION/,${
 103 d
 104 }
 105 #
 106 # delete any remaining directives
 107 /^\./d