ncurses 5.3
[ncurses.git] / man / manlinks.sed
1 # $Id: manlinks.sed,v 1.10 2002/09/21 19:02:03 tom Exp $
2 ##############################################################################
3 # Copyright (c) 2000,2002 Free Software Foundation, Inc.                     #
4 #                                                                            #
5 # Permission is hereby granted, free of charge, to any person obtaining a    #
6 # copy of this software and associated documentation files (the "Software"), #
7 # to deal in the Software without restriction, including without limitation  #
8 # the rights to use, copy, modify, merge, publish, distribute, distribute    #
9 # with modifications, sublicense, and/or sell copies of the Software, and to #
10 # permit persons to whom the Software is furnished to do so, subject to the  #
11 # following conditions:                                                      #
12 #                                                                            #
13 # The above copyright notice and this permission notice shall be included in #
14 # all copies or substantial portions of the Software.                        #
15 #                                                                            #
16 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR #
17 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,   #
18 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL    #
19 # THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER      #
20 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING    #
21 # FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER        #
22 # DEALINGS IN THE SOFTWARE.                                                  #
23 #                                                                            #
24 # Except as contained in this notice, the name(s) of the above copyright     #
25 # holders shall not be used in advertising or otherwise to promote the sale, #
26 # use or other dealings in this Software without prior written               #
27 # authorization.                                                             #
28 ##############################################################################
29 # Given a manpage (nroff) as input, writes a list of the names that are
30 # listed in the "NAME" section, i.e., the names that we would like to use
31 # as aliases for the manpage -T.Dickey
32 /^'\\"/d
33 /\.\\"/d
34 /^\.br/d
35 /^\.sp/d
36 s/^\.IX//
37 s/\\f.//g
38 s/[:,]/ /g
39 s/^[    ][      ]*//
40 s/[     ][      ]*$//
41 s/[     ][      ]*/ /g
42 s/\.SH[         ][      ]*/.SH_(/
43 #
44 /^\.SH_(NAME/,/^\.SH_(SYNOPSIS/{
45 s/\\-.*/ -/
46 / -/{
47         s/ -.*//
48         s/ /\
49 /g
50 }
51 /^-/{
52         d
53 }
54 s/ /\
55 /g
56 }
57 /^\.SH_(SYNOPSIS/,/^\.SH_(DESCRIPTION/{
58         /^#/d
59         /^[^(]*$/d
60         s/^\([^ (]* [^ (]* [*]*\)//g
61         s/^\([^ (]* [*]*\)//g
62         s/\.SH_(/.SH_/
63         s/(.*//
64         s/\.SH_/.SH_(/
65 }
66 /^\.SH_(DESCRIPTION/,${
67         d
68 }
69 /^\./d