mk-2nd.awk

   1 # $Id: mk-2nd.awk,v 1.21 2020/08/29 22:05:45 tom Exp $
   2 ##############################################################################
   3 # Copyright 2020 Thomas E. Dickey                                            #
   4 # Copyright 1998-2004,2005 Free Software Foundation, Inc.                    #
   5 #                                                                            #
   6 # Permission is hereby granted, free of charge, to any person obtaining a    #
   7 # copy of this software and associated documentation files (the "Software"), #
   8 # to deal in the Software without restriction, including without limitation  #
   9 # the rights to use, copy, modify, merge, publish, distribute, distribute    #
  10 # with modifications, sublicense, and/or sell copies of the Software, and to #
  11 # permit persons to whom the Software is furnished to do so, subject to the  #
  12 # following conditions:                                                      #
  13 #                                                                            #
  14 # The above copyright notice and this permission notice shall be included in #
  15 # all copies or substantial portions of the Software.                        #
  16 #                                                                            #
  17 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR #
  18 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,   #
  19 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL    #
  20 # THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER      #
  21 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING    #
  22 # FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER        #
  23 # DEALINGS IN THE SOFTWARE.                                                  #
  24 #                                                                            #
  25 # Except as contained in this notice, the name(s) of the above copyright     #
  26 # holders shall not be used in advertising or otherwise to promote the sale, #
  27 # use or other dealings in this Software without prior written               #
  28 # authorization.                                                             #
  29 ##############################################################################
  30 #
  31 # Author: Thomas E. Dickey
  32 #
  33 # Generate compile-rules for the modules that we are using in libraries or
  34 # programs.  We are listing them explicitly because we have turned off the
  35 # suffix rules (to force compilation with the appropriate flags).  We could use
  36 # make-recursion but that would result in makefiles that are useless for
  37 # development.
  38 #
  39 # Variables:
  40 #       model directory into which objects are compiled.
  41 #       MODEL (uppercase version of "model"; toupper is not portable)
  42 #       echo (yes iff we will show the $(CC) lines)
  43 #       subset ("none", "base", "base+ext_funcs" or "termlib")
  44 #       crenames ("yes" or "no", flag to control whether -c & -o options are used)
  45 #       cxxrenames ("yes" or "no", flag to control whether -c & -o options are used)
  46 #       traces ("all" or "DEBUG", to control whether tracing is compiled in)
  47 #       srcdir is expanded when "configure --srcdir" was used
  48 #
  49 # Fields in src/modules:
  50 #       $1 = module name
  51 #       $2 = progs|lib|c++
  52 #       $3 = source-directory
  53 #
  54 # Fields in src/modules past $3 are dependencies
  55 #
  56 function in_subset(value) {
  57                 value = " " value " ";
  58                 check = subset;
  59                 sub(" .*$", "", check);
  60                 gsub("[+]", " ", check);
  61                 check = " " check " ";
  62                 return index(check,value);
  63         }
  64 BEGIN   {
  65                 found = 0
  66                 using = 0
  67         }
  68         /^@/ {
  69                 using = 0
  70                 if (subset == "none") {
  71                         using = 1
  72                 } else if (in_subset($2) > 0) {
  73                         if (using == 0) {
  74                                 if (found == 0) {
  75                                         print  ""
  76                                         print  "# generated by mk-2nd.awk"
  77                                         printf "#   model:      %s\n", model
  78                                         printf "#   MODEL:      %s\n", MODEL
  79                                         printf "#   echo:       %s\n", echo
  80                                         printf "#   subset:     %s\n", subset
  81                                         printf "#   crenames:   %s\n", crenames
  82                                         printf "#   cxxrenames: %s\n", cxxrenames
  83                                         printf "#   traces:     %s\n", traces
  84                                         printf "#   srcdir:     %s\n", srcdir
  85                                 }
  86                                 using = 1
  87                         }
  88                 }
  89         }
  90         /^[@#]/ {
  91                 next
  92         }
  93         $1 ~ /trace/ {
  94                 if (traces != "all" && traces != MODEL && $1 != "lib_trace")
  95                         next
  96         }
  97         {
  98                 if ($0 != "" \
  99                  && using != 0) {
 100                         found = 1
 101                         if ( $1 != "" ) {
 102                                 print  ""
 103                                 if ( $2 == "c++" ) {
 104                                         compile="CXX"
 105                                         suffix=".cc"
 106                                         use_c_o=cxxrenames
 107                                 } else {
 108                                         compile="CC"
 109                                         suffix=".c"
 110                                         use_c_o=crenames
 111                                 }
 112                                 printf "../%s/%s$o :\t%s/%s%s", model, $1, $3, $1, suffix
 113                                 for (n = 4; n <= NF; n++) printf " \\\n\t\t\t%s", $n
 114                                 print  ""
 115                                 if ( echo == "yes" )
 116                                         atsign=""
 117                                 else {
 118                                         atsign="@"
 119                                         printf "\t@echo 'compiling %s (%s)'\n", $1, model
 120                                 }
 121                                 printf "\t%s", atsign;
 122                                 if ( use_c_o != "yes" ) {
 123                                         printf "cd ../%s; ", model;
 124                                 }
 125                                 # The choice here is between
 126                                 #       base+ext_funcs and
 127                                 #       termlib+ext_tinfo
 128                                 # but they may appear in the same value.
 129                                 if ( subset ~ /base/ ) {
 130                                         mycflags=""
 131                                 } else if ( subset ~ /termlib/ ) {
 132                                         mycflags=" -DUSE_TERMLIB"
 133                                 }
 134                                 printf "$(LIBTOOL_COMPILE) $(%s) $(CFLAGS_%s)%s -c ", compile, MODEL, mycflags
 135                                 if ( $3 == "." || srcdir == "." ) {
 136                                         dir = $3 "/"
 137                                         sub("^\\$\\(srcdir\\)/","",dir);
 138                                         sub("^\\./","",dir);
 139                                         printf "../%s/%s%s%s", name, dir, $1, suffix
 140                                 } else {
 141                                         printf "%s/%s%s", $3, $1, suffix
 142                                 }
 143                                 if ( use_c_o == "yes" ) {
 144                                         printf " -o ../%s/%s$o", model, $1
 145                                 }
 146                         } else {
 147                                 printf "%s", $1
 148                                 for (n = 2; n <= NF; n++) printf " %s", $n
 149                         }
 150                         print  ""
 151                 }
 152         }
 153 END     {
 154                 print  ""
 155         }