ncurses 5.7 - patch 20100313
[ncurses.git] / mk-2nd.awk
1 # $Id: mk-2nd.awk,v 1.19 2005/01/22 16:30:04 tom Exp $
2 ##############################################################################
3 # Copyright (c) 1998-2004,2005 Free Software Foundation, Inc.                #
4 #                                                                            #
5 # Permission is hereby granted, free of charge, to any person obtaining a    #
6 # copy of this software and associated documentation files (the "Software"), #
7 # to deal in the Software without restriction, including without limitation  #
8 # the rights to use, copy, modify, merge, publish, distribute, distribute    #
9 # with modifications, sublicense, and/or sell copies of the Software, and to #
10 # permit persons to whom the Software is furnished to do so, subject to the  #
11 # following conditions:                                                      #
12 #                                                                            #
13 # The above copyright notice and this permission notice shall be included in #
14 # all copies or substantial portions of the Software.                        #
15 #                                                                            #
16 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR #
17 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,   #
18 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL    #
19 # THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER      #
20 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING    #
21 # FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER        #
22 # DEALINGS IN THE SOFTWARE.                                                  #
23 #                                                                            #
24 # Except as contained in this notice, the name(s) of the above copyright     #
25 # holders shall not be used in advertising or otherwise to promote the sale, #
26 # use or other dealings in this Software without prior written               #
27 # authorization.                                                             #
28 ##############################################################################
29 #
30 # Author: Thomas E. Dickey
31 #
32 # Generate compile-rules for the modules that we are using in libraries or
33 # programs.  We are listing them explicitly because we have turned off the
34 # suffix rules (to force compilation with the appropriate flags).  We could use
35 # make-recursion but that would result in makefiles that are useless for
36 # development.
37 #
38 # Variables:
39 #       model directory into which objects are compiled.
40 #       MODEL (uppercase version of "model"; toupper is not portable)
41 #       echo (yes iff we will show the $(CC) lines)
42 #       subset ("none", "base", "base+ext_funcs" or "termlib")
43 #       crenames ("yes" or "no", flag to control whether -c & -o options are used)
44 #       cxxrenames ("yes" or "no", flag to control whether -c & -o options are used)
45 #       traces ("all" or "DEBUG", to control whether tracing is compiled in)
46 #       srcdir is expanded when "configure --srcdir" was used
47 #
48 # Fields in src/modules:
49 #       $1 = module name
50 #       $2 = progs|lib|c++
51 #       $3 = source-directory
52 #
53 # Fields in src/modules past $3 are dependencies
54 #
55 BEGIN   {
56                 found = 0
57                 using = 0
58         }
59         /^@/ {
60                 using = 0
61                 if (subset == "none") {
62                         using = 1
63                 } else if (index(subset,$2) > 0) {
64                         if (using == 0) {
65                                 if (found == 0) {
66                                         print  ""
67                                         print  "# generated by mk-2nd.awk"
68                                         printf "#   model:      %s\n", model
69                                         printf "#   MODEL:      %s\n", MODEL
70                                         printf "#   echo:       %s\n", echo 
71                                         printf "#   subset:     %s\n", subset
72                                         printf "#   crenames:   %s\n", crenames
73                                         printf "#   cxxrenames: %s\n", cxxrenames
74                                         printf "#   traces:     %s\n", traces
75                                         printf "#   srcdir:     %s\n", srcdir
76                                 }
77                                 using = 1
78                         }
79                 }
80         }
81         /^[@#]/ {
82                 next
83         }
84         $1 ~ /trace/ {
85                 if (traces != "all" && traces != MODEL && $1 != "lib_trace")
86                         next
87         }
88         {
89                 if ($0 != "" \
90                  && using != 0) {
91                         found = 1
92                         if ( $1 != "" ) {
93                                 print  ""
94                                 if ( $2 == "c++" ) {
95                                         compile="CXX"
96                                         suffix=".cc"
97                                         use_c_o=cxxrenames
98                                 } else {
99                                         compile="CC"
100                                         suffix=".c"
101                                         use_c_o=crenames
102                                 }
103                                 printf "../%s/%s$o :\t%s/%s%s", model, $1, $3, $1, suffix
104                                 for (n = 4; n <= NF; n++) printf " \\\n\t\t\t%s", $n
105                                 print  ""
106                                 if ( echo == "yes" )
107                                         atsign=""
108                                 else {
109                                         atsign="@"
110                                         printf "\t@echo 'compiling %s (%s)'\n", $1, model
111                                 }
112                                 printf "\t%s", atsign;
113                                 if ( use_c_o != "yes" ) {
114                                         printf "cd ../%s; ", model;
115                                 }
116                                 # The choice here is between
117                                 #       base+ext_funcs and
118                                 #       termlib+ext_tinfo
119                                 # but they may appear in the same value.
120                                 if ( subset ~ /base/ ) {
121                                         mycflags=""
122                                 } else if ( subset ~ /termlib/ ) {
123                                         mycflags=" -DUSE_TERMLIB"
124                                 }
125                                 printf "$(LIBTOOL_COMPILE) $(%s) $(CFLAGS_%s)%s -c ", compile, MODEL, mycflags
126                                 if ( $3 == "." || srcdir == "." ) {
127                                         dir = $3 "/"
128                                         sub("^\\$\\(srcdir\\)/","",dir);
129                                         sub("^\\./","",dir);
130                                         printf "../%s/%s%s%s", name, dir, $1, suffix
131                                 } else {
132                                         printf "%s/%s%s", $3, $1, suffix
133                                 }
134                                 if ( use_c_o == "yes" ) {
135                                         printf " -o ../%s/%s$o", model, $1
136                                 }
137                         } else {
138                                 printf "%s", $1
139                                 for (n = 2; n <= NF; n++) printf " %s", $n
140                         }
141                         print  ""
142                 }
143         }
144 END     {
145                 print  ""
146         }