mk-2nd.awk

   1 # $Id: mk-2nd.awk,v 1.22 2020/08/31 23:49:17 tom Exp $
   2 ##############################################################################
   3 # Copyright 2020 Thomas E. Dickey                                            #
   4 # Copyright 1998-2004,2005 Free Software Foundation, Inc.                    #
   5 #                                                                            #
   6 # Permission is hereby granted, free of charge, to any person obtaining a    #
   7 # copy of this software and associated documentation files (the "Software"), #
   8 # to deal in the Software without restriction, including without limitation  #
   9 # the rights to use, copy, modify, merge, publish, distribute, distribute    #
  10 # with modifications, sublicense, and/or sell copies of the Software, and to #
  11 # permit persons to whom the Software is furnished to do so, subject to the  #
  12 # following conditions:                                                      #
  13 #                                                                            #
  14 # The above copyright notice and this permission notice shall be included in #
  15 # all copies or substantial portions of the Software.                        #
  16 #                                                                            #
  17 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR #
  18 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,   #
  19 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL    #
  20 # THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER      #
  21 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING    #
  22 # FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER        #
  23 # DEALINGS IN THE SOFTWARE.                                                  #
  24 #                                                                            #
  25 # Except as contained in this notice, the name(s) of the above copyright     #
  26 # holders shall not be used in advertising or otherwise to promote the sale, #
  27 # use or other dealings in this Software without prior written               #
  28 # authorization.                                                             #
  29 ##############################################################################
  30 #
  31 # Author: Thomas E. Dickey
  32 #
  33 # Generate compile-rules for the modules that we are using in libraries or
  34 # programs.  We are listing them explicitly because we have turned off the
  35 # suffix rules (to force compilation with the appropriate flags).  We could use
  36 # make-recursion but that would result in makefiles that are useless for
  37 # development.
  38 #
  39 # Variables:
  40 #       model directory into which objects are compiled.
  41 #       MODEL (uppercase version of "model"; toupper is not portable)
  42 #       echo (yes iff we will show the $(CC) lines)
  43 #       subset ("none", "base", "base+ext_funcs" or "termlib")
  44 #       crenames ("yes" or "no", flag to control whether -c & -o options are used)
  45 #       cxxrenames ("yes" or "no", flag to control whether -c & -o options are used)
  46 #       traces ("all" or "DEBUG", to control whether tracing is compiled in)
  47 #       srcdir is expanded when "configure --srcdir" was used
  48 #
  49 # Fields in src/modules:
  50 #       $1 = module name
  51 #       $2 = progs|lib|c++
  52 #       $3 = source-directory
  53 #
  54 # Fields in src/modules past $3 are dependencies
  55 #
  56 function in_subset(value) {
  57                 value = " " value " ";
  58                 check = subset;
  59                 gsub("[+]", " ", check);
  60                 check = " " check " ";
  61                 return index(check,value);
  62         }
  63 BEGIN   {
  64                 found = 0
  65                 using = 0
  66         }
  67         /^@/ {
  68                 using = 0
  69                 if (subset == "none") {
  70                         using = 1
  71                 } else if (in_subset($2) > 0) {
  72                         if (using == 0) {
  73                                 if (found == 0) {
  74                                         print  ""
  75                                         print  "# generated by mk-2nd.awk"
  76                                         printf "#   model:      %s\n", model
  77                                         printf "#   MODEL:      %s\n", MODEL
  78                                         printf "#   echo:       %s\n", echo
  79                                         printf "#   subset:     %s\n", subset
  80                                         printf "#   crenames:   %s\n", crenames
  81                                         printf "#   cxxrenames: %s\n", cxxrenames
  82                                         printf "#   traces:     %s\n", traces
  83                                         printf "#   srcdir:     %s\n", srcdir
  84                                 }
  85                                 using = 1
  86                         }
  87                 }
  88         }
  89         /^[@#]/ {
  90                 next
  91         }
  92         $1 ~ /trace/ {
  93                 if (traces != "all" && traces != MODEL && $1 != "lib_trace")
  94                         next
  95         }
  96         {
  97                 if ($0 != "" \
  98                  && using != 0) {
  99                         found = 1
 100                         if ( $1 != "" ) {
 101                                 print  ""
 102                                 if ( $2 == "c++" ) {
 103                                         compile="CXX"
 104                                         suffix=".cc"
 105                                         use_c_o=cxxrenames
 106                                 } else {
 107                                         compile="CC"
 108                                         suffix=".c"
 109                                         use_c_o=crenames
 110                                 }
 111                                 printf "../%s/%s$o :\t%s/%s%s", model, $1, $3, $1, suffix
 112                                 for (n = 4; n <= NF; n++) printf " \\\n\t\t\t%s", $n
 113                                 print  ""
 114                                 if ( echo == "yes" )
 115                                         atsign=""
 116                                 else {
 117                                         atsign="@"
 118                                         printf "\t@echo 'compiling %s (%s)'\n", $1, model
 119                                 }
 120                                 printf "\t%s", atsign;
 121                                 if ( use_c_o != "yes" ) {
 122                                         printf "cd ../%s; ", model;
 123                                 }
 124                                 # The choice here is between
 125                                 #       base+ext_funcs and
 126                                 #       termlib+ext_tinfo
 127                                 # but they may appear in the same value.
 128                                 if ( subset ~ /base/ ) {
 129                                         mycflags=""
 130                                 } else if ( subset ~ /termlib/ ) {
 131                                         mycflags=" -DUSE_TERMLIB"
 132                                 }
 133                                 printf "$(LIBTOOL_COMPILE) $(%s) $(CFLAGS_%s)%s -c ", compile, MODEL, mycflags
 134                                 if ( $3 == "." || srcdir == "." ) {
 135                                         dir = $3 "/"
 136                                         sub("^\\$\\(srcdir\\)/","",dir);
 137                                         sub("^\\./","",dir);
 138                                         printf "../%s/%s%s%s", name, dir, $1, suffix
 139                                 } else {
 140                                         printf "%s/%s%s", $3, $1, suffix
 141                                 }
 142                                 if ( use_c_o == "yes" ) {
 143                                         printf " -o ../%s/%s$o", model, $1
 144                                 }
 145                         } else {
 146                                 printf "%s", $1
 147                                 for (n = 2; n <= NF; n++) printf " %s", $n
 148                         }
 149                         print  ""
 150                 }
 151         }
 152 END     {
 153                 print  ""
 154         }