ncurses/tinfo/MKcaptab.awk

   1 ##############################################################################
   2 # Copyright (c) 1998-2006,2007 Free Software Foundation, Inc.                #
   3 #                                                                            #
   4 # Permission is hereby granted, free of charge, to any person obtaining a    #
   5 # copy of this software and associated documentation files (the "Software"), #
   6 # to deal in the Software without restriction, including without limitation  #
   7 # the rights to use, copy, modify, merge, publish, distribute, distribute    #
   8 # with modifications, sublicense, and/or sell copies of the Software, and to #
   9 # permit persons to whom the Software is furnished to do so, subject to the  #
  10 # following conditions:                                                      #
  11 #                                                                            #
  12 # The above copyright notice and this permission notice shall be included in #
  13 # all copies or substantial portions of the Software.                        #
  14 #                                                                            #
  15 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR #
  16 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,   #
  17 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL    #
  18 # THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER      #
  19 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING    #
  20 # FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER        #
  21 # DEALINGS IN THE SOFTWARE.                                                  #
  22 #                                                                            #
  23 # Except as contained in this notice, the name(s) of the above copyright     #
  24 # holders shall not be used in advertising or otherwise to promote the sale, #
  25 # use or other dealings in this Software without prior written               #
  26 # authorization.                                                             #
  27 ##############################################################################
  28 # $Id: MKcaptab.awk,v 1.20 2007/08/12 00:26:15 tom Exp $
  29 function add_string(text) {
  30     if (text != "IGNORE") {
  31         offsets[num_strings] = offset;
  32         offset = offset + length(text) + 1;
  33         printf "%s\\0", text;
  34     } else {
  35         offsets[num_strings] = -1;
  36     }
  37     num_strings = num_strings + 1;
  38     if ((num_strings % 3) == 0) {
  39         printf "\\\n";
  40     }
  41     return offsets[num_strings - 1];
  42 }
  43 BEGIN {
  44         first = 1;
  45         num_aliases = 0;
  46         num_strings = 0;
  47         offset = 0;
  48 }
  49
  50 /^[^#]/ {
  51             if (first) {
  52                 printf "/* generated by MKcaptab.awk %s(%d) */\n", tablename, bigstrings;
  53                 print ""
  54                 if (bigstrings) {
  55                     printf "static struct alias *_nc_%s_table = 0;\n", tablename;
  56                     print "";
  57                     printf "static const char %s_text[] = \"\\\n", tablename;
  58                 } else {
  59                     printf "static const struct alias _nc_%s_table[] =\n", tablename;
  60                     printf "{\n";
  61                 }
  62                 first = 0;
  63             }
  64             if ($1 == tablename) {
  65                 if ($3 == "IGNORE") {
  66                     to = "(char *)NULL";
  67                 } else {
  68                     to = "\"" $3 "\"";
  69                 }
  70                 if (bigstrings) {
  71                     c1 = add_string($2);
  72                     c2 = add_string($3);
  73                     c3 = add_string($4);
  74                     aliases[num_aliases] = sprintf("\t{%5d, %5d, %5d},\t /* %s */", c1, c2, c3, $5);
  75                     num_aliases = num_aliases + 1;
  76                 } else {
  77                     printf "\t{\"%s\", %s, \"%s\"},\t /* %s */\n", $2, to, $4, $5;
  78                 }
  79             }
  80         }
  81 END     {
  82             if (bigstrings) {
  83                 printf "\";\n\n";
  84                 printf "static const alias_table_data %s_data[] = {\n", tablename;
  85                 for (n = 0; n < num_aliases; ++n) {
  86                     printf "%s\n", aliases[n];
  87                 }
  88                 printf "};\n\n";
  89             } else {
  90                 printf "\t{(char *)NULL, (char *)NULL, (char *)NULL}\n";
  91                 printf "};\n\n";
  92             }
  93         }
  94 # vile:sw=4: