test/aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 2003-2011,2012 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl $Id: aclocal.m4,v 1.75 2012/04/01 00:14:58 tom Exp $
  30 dnl
  31 dnl Author: Thomas E. Dickey
  32 dnl
  33 dnl Macros used in NCURSES test programs auto-configuration script.
  34 dnl
  35 dnl These macros are maintained separately from NCURSES.  The copyright on
  36 dnl this file applies to the aggregation of macros and does not affect use of
  37 dnl these macros in other applications.
  38 dnl
  39 dnl See http://invisible-island.net/autoconf/ for additional information.
  40 dnl
  41 dnl ---------------------------------------------------------------------------
  42 dnl ---------------------------------------------------------------------------
  43 dnl CF_ACVERSION_CHECK version: 2 updated: 2011/05/08 11:22:03
  44 dnl ------------------
  45 dnl Conditionally generate script according to whether we're using a given autoconf.
  46 dnl
  47 dnl $1 = version to compare against
  48 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  49 dnl $3 = code to use if AC_ACVERSION is older than $1.
  50 define(CF_ACVERSION_CHECK,
  51 [
  52 ifdef([m4_version_compare],
  53 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  54 [CF_ACVERSION_COMPARE(
  55 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  56 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  57 dnl ---------------------------------------------------------------------------
  58 dnl CF_ACVERSION_COMPARE version: 2 updated: 2011/04/14 20:56:50
  59 dnl --------------------
  60 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  61 dnl                      MAJOR2, MINOR2, TERNARY2,
  62 dnl                      PRINTABLE2, not FOUND, FOUND)
  63 define(CF_ACVERSION_COMPARE,
  64 [ifelse(builtin([eval], [$2 < $5]), 1,
  65 [ifelse([$8], , ,[$8])],
  66 [ifelse([$9], , ,[$9])])])dnl
  67 dnl ---------------------------------------------------------------------------
  68 dnl CF_ADD_CFLAGS version: 10 updated: 2010/05/26 05:38:42
  69 dnl -------------
  70 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
  71 dnl The second parameter if given makes this macro verbose.
  72 dnl
  73 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
  74 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
  75 dnl confused by the quotes (which require backslashes to keep them usable).
  76 AC_DEFUN([CF_ADD_CFLAGS],
  77 [
  78 cf_fix_cppflags=no
  79 cf_new_cflags=
  80 cf_new_cppflags=
  81 cf_new_extra_cppflags=
  82
  83 for cf_add_cflags in $1
  84 do
  85 case $cf_fix_cppflags in
  86 no)
  87         case $cf_add_cflags in #(vi
  88         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
  89                 case $cf_add_cflags in
  90                 -D*)
  91                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
  92
  93                         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
  94                                 && test -z "${cf_tst_cflags}" \
  95                                 && cf_fix_cppflags=yes
  96
  97                         if test $cf_fix_cppflags = yes ; then
  98                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
  99                                 continue
 100                         elif test "${cf_tst_cflags}" = "\"'" ; then
 101                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 102                                 continue
 103                         fi
 104                         ;;
 105                 esac
 106                 case "$CPPFLAGS" in
 107                 *$cf_add_cflags) #(vi
 108                         ;;
 109                 *) #(vi
 110                         case $cf_add_cflags in #(vi
 111                         -D*)
 112                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 113                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 114                                 ;;
 115                         esac
 116                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 117                         ;;
 118                 esac
 119                 ;;
 120         *)
 121                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 122                 ;;
 123         esac
 124         ;;
 125 yes)
 126         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 127
 128         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 129
 130         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 131                 && test -z "${cf_tst_cflags}" \
 132                 && cf_fix_cppflags=no
 133         ;;
 134 esac
 135 done
 136
 137 if test -n "$cf_new_cflags" ; then
 138         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 139         CFLAGS="$CFLAGS $cf_new_cflags"
 140 fi
 141
 142 if test -n "$cf_new_cppflags" ; then
 143         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 144         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 145 fi
 146
 147 if test -n "$cf_new_extra_cppflags" ; then
 148         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 149         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 150 fi
 151
 152 AC_SUBST(EXTRA_CPPFLAGS)
 153
 154 ])dnl
 155 dnl ---------------------------------------------------------------------------
 156 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
 157 dnl -------------
 158 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 159 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 160 dnl but old versions (and some misinstalled ones) need that.  To make things
 161 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 162 dnl the include-path).
 163 AC_DEFUN([CF_ADD_INCDIR],
 164 [
 165 if test -n "$1" ; then
 166   for cf_add_incdir in $1
 167   do
 168         while test $cf_add_incdir != /usr/include
 169         do
 170           if test -d $cf_add_incdir
 171           then
 172                 cf_have_incdir=no
 173                 if test -n "$CFLAGS$CPPFLAGS" ; then
 174                   # a loop is needed to ensure we can add subdirs of existing dirs
 175                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 176                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 177                           cf_have_incdir=yes; break
 178                         fi
 179                   done
 180                 fi
 181
 182                 if test "$cf_have_incdir" = no ; then
 183                   if test "$cf_add_incdir" = /usr/local/include ; then
 184                         if test "$GCC" = yes
 185                         then
 186                           cf_save_CPPFLAGS=$CPPFLAGS
 187                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 188                           AC_TRY_COMPILE([#include <stdio.h>],
 189                                   [printf("Hello")],
 190                                   [],
 191                                   [cf_have_incdir=yes])
 192                           CPPFLAGS=$cf_save_CPPFLAGS
 193                         fi
 194                   fi
 195                 fi
 196
 197                 if test "$cf_have_incdir" = no ; then
 198                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 199                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 200
 201                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 202                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 203                   cf_add_incdir="$cf_top_incdir"
 204                 else
 205                   break
 206                 fi
 207           fi
 208         done
 209   done
 210 fi
 211 ])dnl
 212 dnl ---------------------------------------------------------------------------
 213 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 214 dnl ----------
 215 dnl Add a library, used to enforce consistency.
 216 dnl
 217 dnl $1 = library to add, without the "-l"
 218 dnl $2 = variable to update (default $LIBS)
 219 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 220 dnl ---------------------------------------------------------------------------
 221 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
 222 dnl -------------
 223 dnl     Adds to the library-path
 224 dnl
 225 dnl     Some machines have trouble with multiple -L options.
 226 dnl
 227 dnl $1 is the (list of) directory(s) to add
 228 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 229 dnl
 230 AC_DEFUN([CF_ADD_LIBDIR],
 231 [
 232 if test -n "$1" ; then
 233   for cf_add_libdir in $1
 234   do
 235     if test $cf_add_libdir = /usr/lib ; then
 236       :
 237     elif test -d $cf_add_libdir
 238     then
 239       cf_have_libdir=no
 240       if test -n "$LDFLAGS$LIBS" ; then
 241         # a loop is needed to ensure we can add subdirs of existing dirs
 242         for cf_test_libdir in $LDFLAGS $LIBS ; do
 243           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 244             cf_have_libdir=yes; break
 245           fi
 246         done
 247       fi
 248       if test "$cf_have_libdir" = no ; then
 249         CF_VERBOSE(adding $cf_add_libdir to library-path)
 250         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 251       fi
 252     fi
 253   done
 254 fi
 255 ])dnl
 256 dnl ---------------------------------------------------------------------------
 257 dnl CF_ADD_LIBS version: 1 updated: 2010/06/02 05:03:05
 258 dnl -----------
 259 dnl Add one or more libraries, used to enforce consistency.
 260 dnl
 261 dnl $1 = libraries to add, with the "-l", etc.
 262 dnl $2 = variable to update (default $LIBS)
 263 AC_DEFUN([CF_ADD_LIBS],[ifelse($2,,LIBS,[$2])="$1 [$]ifelse($2,,LIBS,[$2])"])dnl
 264 dnl ---------------------------------------------------------------------------
 265 dnl CF_ADD_LIB_AFTER version: 2 updated: 2010/11/08 20:33:46
 266 dnl ----------------
 267 dnl Add a given library after another, e.g., following the one it satisfies a
 268 dnl dependency for.
 269 dnl
 270 dnl $1 = the first library
 271 dnl $2 = its dependency
 272 AC_DEFUN([CF_ADD_LIB_AFTER],[
 273 CF_VERBOSE(...before $LIBS)
 274 LIBS=`echo "$LIBS" | sed -e "s/[[       ]][[    ]]*/ /g" -e "s,$1 ,$1 $2 ," -e 's/  / /g'`
 275 CF_VERBOSE(...after  $LIBS)
 276 ])dnl
 277 dnl ---------------------------------------------------------------------------
 278 dnl CF_ADD_SUBDIR_PATH version: 3 updated: 2010/07/03 20:58:12
 279 dnl ------------------
 280 dnl Append to a search-list for a nonstandard header/lib-file
 281 dnl     $1 = the variable to return as result
 282 dnl     $2 = the package name
 283 dnl     $3 = the subdirectory, e.g., bin, include or lib
 284 dnl $4 = the directory under which we will test for subdirectories
 285 dnl $5 = a directory that we do not want $4 to match
 286 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 287 [
 288 test "$4" != "$5" && \
 289 test -d "$4" && \
 290 ifelse([$5],NONE,,[(test $5 = NONE || test "$4" != "$5") &&]) {
 291         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 292         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 293         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 294         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 295         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 296         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 297 }
 298 ])dnl
 299 dnl ---------------------------------------------------------------------------
 300 dnl CF_ANSI_CC_CHECK version: 11 updated: 2011/07/01 19:47:45
 301 dnl ----------------
 302 dnl This was originally adapted from the macros 'fp_PROG_CC_STDC' and
 303 dnl 'fp_C_PROTOTYPES' in the sharutils 4.2 distribution.
 304 AC_DEFUN([CF_ANSI_CC_CHECK],
 305 [
 306 # This should have been defined by AC_PROG_CC
 307 : ${CC:=cc}
 308
 309 # Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 310 # into CC.  This will not help with broken scripts that wrap the compiler with
 311 # options, but eliminates a more common category of user confusion.
 312 AC_MSG_CHECKING(\$CC variable)
 313 case "$CC" in #(vi
 314 *[[\ \  ]]-[[IUD]]*)
 315         AC_MSG_RESULT(broken)
 316         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 317         # humor him...
 318         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
 319         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
 320         CF_ADD_CFLAGS($cf_flags)
 321         ;;
 322 *)
 323         AC_MSG_RESULT(ok)
 324         ;;
 325 esac
 326
 327 AC_CACHE_CHECK(for ${CC:-cc} option to accept ANSI C, cf_cv_ansi_cc,[
 328 cf_cv_ansi_cc=no
 329 cf_save_CFLAGS="$CFLAGS"
 330 cf_save_CPPFLAGS="$CPPFLAGS"
 331 # Don't try gcc -ansi; that turns off useful extensions and
 332 # breaks some systems' header files.
 333 # AIX                   -qlanglvl=ansi
 334 # Ultrix and OSF/1      -std1
 335 # HP-UX                 -Aa -D_HPUX_SOURCE
 336 # SVR4                  -Xc
 337 # UnixWare 1.2          (cannot use -Xc, since ANSI/POSIX clashes)
 338 for cf_arg in "-DCC_HAS_PROTOS" \
 339         "" \
 340         -qlanglvl=ansi \
 341         -std1 \
 342         -Ae \
 343         "-Aa -D_HPUX_SOURCE" \
 344         -Xc
 345 do
 346         CF_ADD_CFLAGS($cf_arg)
 347         AC_TRY_COMPILE(
 348 [
 349 #ifndef CC_HAS_PROTOS
 350 #if !defined(__STDC__) || (__STDC__ != 1)
 351 choke me
 352 #endif
 353 #endif
 354 ],[
 355         int test (int i, double x);
 356         struct s1 {int (*f) (int a);};
 357         struct s2 {int (*f) (double a);};],
 358         [cf_cv_ansi_cc="$cf_arg"; break])
 359 done
 360 CFLAGS="$cf_save_CFLAGS"
 361 CPPFLAGS="$cf_save_CPPFLAGS"
 362 ])
 363
 364 if test "$cf_cv_ansi_cc" != "no"; then
 365 if test ".$cf_cv_ansi_cc" != ".-DCC_HAS_PROTOS"; then
 366         CF_ADD_CFLAGS($cf_cv_ansi_cc)
 367 else
 368         AC_DEFINE(CC_HAS_PROTOS)
 369 fi
 370 fi
 371 ])dnl
 372 dnl ---------------------------------------------------------------------------
 373 dnl CF_ANSI_CC_REQD version: 4 updated: 2008/03/23 14:48:54
 374 dnl ---------------
 375 dnl For programs that must use an ANSI compiler, obtain compiler options that
 376 dnl will make it recognize prototypes.  We'll do preprocessor checks in other
 377 dnl macros, since tools such as unproto can fake prototypes, but only part of
 378 dnl the preprocessor.
 379 AC_DEFUN([CF_ANSI_CC_REQD],
 380 [AC_REQUIRE([CF_ANSI_CC_CHECK])
 381 if test "$cf_cv_ansi_cc" = "no"; then
 382         AC_MSG_ERROR(
 383 [Your compiler does not appear to recognize prototypes.
 384 You have the following choices:
 385         a. adjust your compiler options
 386         b. get an up-to-date compiler
 387         c. use a wrapper such as unproto])
 388 fi
 389 ])dnl
 390 dnl ---------------------------------------------------------------------------
 391 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 392 dnl --------------
 393 dnl Allow user to disable a normally-on option.
 394 AC_DEFUN([CF_ARG_DISABLE],
 395 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 396 dnl ---------------------------------------------------------------------------
 397 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 398 dnl -------------
 399 dnl Allow user to enable a normally-off option.
 400 AC_DEFUN([CF_ARG_ENABLE],
 401 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 402 dnl ---------------------------------------------------------------------------
 403 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
 404 dnl -------------
 405 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 406 dnl values.
 407 dnl
 408 dnl Parameters:
 409 dnl $1 = option name
 410 dnl $2 = help-string
 411 dnl $3 = action to perform if option is not default
 412 dnl $4 = action if perform if option is default
 413 dnl $5 = default option value (either 'yes' or 'no')
 414 AC_DEFUN([CF_ARG_OPTION],
 415 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 416   if test "$enableval" != "$5" ; then
 417 ifelse([$3],,[    :]dnl
 418 ,[    $3]) ifelse([$4],,,[
 419   else
 420     $4])
 421   fi],[enableval=$5 ifelse([$4],,,[
 422   $4
 423 ])dnl
 424   ])])dnl
 425 dnl ---------------------------------------------------------------------------
 426 dnl CF_CHECK_CACHE version: 11 updated: 2008/03/23 14:45:59
 427 dnl --------------
 428 dnl Check if we're accidentally using a cache from a different machine.
 429 dnl Derive the system name, as a check for reusing the autoconf cache.
 430 dnl
 431 dnl If we've packaged config.guess and config.sub, run that (since it does a
 432 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 433 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 434 dnl which is useful in cross-compiles.
 435 dnl
 436 dnl Note: we would use $ac_config_sub, but that is one of the places where
 437 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 438 AC_DEFUN([CF_CHECK_CACHE],
 439 [
 440 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 441         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 442         system_name="$host_os"
 443 else
 444         system_name="`(uname -s -r) 2>/dev/null`"
 445         if test -z "$system_name" ; then
 446                 system_name="`(hostname) 2>/dev/null`"
 447         fi
 448 fi
 449 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name")
 450 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 451
 452 test -z "$system_name" && system_name="$cf_cv_system_name"
 453 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 454
 455 if test ".$system_name" != ".$cf_cv_system_name" ; then
 456         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 457         AC_MSG_ERROR("Please remove config.cache and try again.")
 458 fi
 459 ])dnl
 460 dnl ---------------------------------------------------------------------------
 461 dnl CF_CHECK_CFLAGS version: 2 updated: 2001/12/30 19:09:58
 462 dnl ---------------
 463 dnl Conditionally add to $CFLAGS and $CPPFLAGS values which are derived from
 464 dnl a build-configuration such as imake.  These have the pitfall that they
 465 dnl often contain compiler-specific options which we cannot use, mixed with
 466 dnl preprocessor options that we usually can.
 467 AC_DEFUN([CF_CHECK_CFLAGS],
 468 [
 469 CF_VERBOSE(checking additions to CFLAGS)
 470 cf_check_cflags="$CFLAGS"
 471 cf_check_cppflags="$CPPFLAGS"
 472 CF_ADD_CFLAGS($1,yes)
 473 if test "$cf_check_cflags" != "$CFLAGS" ; then
 474 AC_TRY_LINK([#include <stdio.h>],[printf("Hello world");],,
 475         [CF_VERBOSE(test-compile failed.  Undoing change to \$CFLAGS)
 476          if test "$cf_check_cppflags" != "$CPPFLAGS" ; then
 477                  CF_VERBOSE(but keeping change to \$CPPFLAGS)
 478          fi
 479          CFLAGS="$cf_check_flags"])
 480 fi
 481 ])dnl
 482 dnl ---------------------------------------------------------------------------
 483 dnl CF_CURSES_ACS_MAP version: 6 updated: 2010/10/23 15:54:49
 484 dnl -----------------
 485 dnl Check for likely values of acs_map[]:
 486 AC_DEFUN([CF_CURSES_ACS_MAP],
 487 [
 488 AC_REQUIRE([CF_NCURSES_WRAP_PREFIX])dnl
 489 AC_CACHE_CHECK(for alternate character set array, cf_cv_curses_acs_map,[
 490 cf_cv_curses_acs_map=unknown
 491 for name in acs_map _acs_map __acs_map ${NCURSES_WRAP_PREFIX}acs_map
 492 do
 493 AC_TRY_LINK([
 494 #include <${cf_cv_ncurses_header:-curses.h}>
 495 ],[
 496 $name['k'] = ACS_PLUS
 497 ],[cf_cv_curses_acs_map=$name; break])
 498 done
 499 ])
 500
 501 test "$cf_cv_curses_acs_map" != unknown && AC_DEFINE_UNQUOTED(CURSES_ACS_ARRAY,$cf_cv_curses_acs_map)
 502 ])
 503 dnl ---------------------------------------------------------------------------
 504 dnl CF_CURSES_CHECK_DATA version: 4 updated: 2011/01/15 16:39:24
 505 dnl --------------------
 506 dnl Check if curses.h defines the given data/variable.
 507 dnl Use this after CF_NCURSES_CONFIG or CF_CURSES_CONFIG.
 508 AC_DEFUN([CF_CURSES_CHECK_DATA],
 509 [
 510 AC_MSG_CHECKING(for data $1 declaration in ${cf_cv_ncurses_header:-curses.h})
 511
 512 AC_TRY_COMPILE(CF__CURSES_HEAD,[
 513 void *foo = &($1)
 514 ],cf_result=yes,cf_result=no)
 515 AC_MSG_RESULT($cf_result)
 516
 517 if test $cf_result = yes ; then
 518         CF_UPPER(cf_result,have_curses_data_$1)
 519         AC_DEFINE_UNQUOTED($cf_result)
 520 else
 521         AC_MSG_CHECKING(for data $1 in library)
 522         # BSD linkers insist on making weak linkage, but resolve at runtime.
 523         AC_TRY_RUN(CF__CURSES_HEAD
 524 [
 525 extern char $1;
 526 int main(void)
 527 {
 528         void *foo = &($1);
 529         ${cf_cv_main_return:-return}(foo == 0);
 530 }],[cf_result=yes],[cf_result=no],[
 531         # cross-compiling
 532         AC_TRY_LINK(CF__CURSES_HEAD
 533 [extern char $1;],[
 534         do {
 535                 void *foo = &($1);
 536                 ${cf_cv_main_return:-return}(foo == 0);
 537         } while (0)
 538 ],[cf_result=yes],[cf_result=no])
 539 ])
 540         AC_MSG_RESULT($cf_result)
 541         if test $cf_result = yes ; then
 542                 CF_UPPER(cf_result,decl_curses_data_$1)
 543                 AC_DEFINE_UNQUOTED($cf_result)
 544         fi
 545 fi
 546 ])dnl
 547 dnl ---------------------------------------------------------------------------
 548 dnl CF_CURSES_CHECK_TYPE version: 3 updated: 2010/10/23 15:54:49
 549 dnl --------------------
 550 dnl Check if curses.h defines the given type
 551 AC_DEFUN([CF_CURSES_CHECK_TYPE],
 552 [
 553 AC_MSG_CHECKING(for type $1 in ${cf_cv_ncurses_header:-curses.h})
 554 AC_TRY_COMPILE([
 555 #ifndef _XOPEN_SOURCE_EXTENDED
 556 #define _XOPEN_SOURCE_EXTENDED
 557 #endif
 558 #include <${cf_cv_ncurses_header:-curses.h}>],[
 559 $1 foo
 560 ],cf_result=yes,cf_result=no)
 561 AC_MSG_RESULT($cf_result)
 562 if test $cf_result = yes ; then
 563         CF_UPPER(cf_result,have_type_$1)
 564         AC_DEFINE_UNQUOTED($cf_result)
 565 else
 566         AC_DEFINE_UNQUOTED($1,$2)
 567 fi
 568 ])dnl
 569 dnl ---------------------------------------------------------------------------
 570 dnl CF_CURSES_CONFIG version: 2 updated: 2006/10/29 11:06:27
 571 dnl ----------------
 572 dnl Tie together the configure-script macros for curses.  It may be ncurses,
 573 dnl but unless asked, we do not make a special search for ncurses.  However,
 574 dnl still check for the ncurses version number, for use in other macros.
 575 AC_DEFUN([CF_CURSES_CONFIG],
 576 [
 577 CF_CURSES_CPPFLAGS
 578 CF_NCURSES_VERSION
 579 CF_CURSES_LIBS
 580 ])dnl
 581 dnl ---------------------------------------------------------------------------
 582 dnl CF_CURSES_CPPFLAGS version: 11 updated: 2011/04/09 14:51:08
 583 dnl ------------------
 584 dnl Look for the curses headers.
 585 AC_DEFUN([CF_CURSES_CPPFLAGS],[
 586
 587 AC_CACHE_CHECK(for extra include directories,cf_cv_curses_incdir,[
 588 cf_cv_curses_incdir=no
 589 case $host_os in #(vi
 590 hpux10.*) #(vi
 591         if test "x$cf_cv_screen" = "xcurses_colr"
 592         then
 593                 test -d /usr/include/curses_colr && \
 594                 cf_cv_curses_incdir="-I/usr/include/curses_colr"
 595         fi
 596         ;;
 597 sunos3*|sunos4*)
 598         if test "x$cf_cv_screen" = "xcurses_5lib"
 599         then
 600                 test -d /usr/5lib && \
 601                 test -d /usr/5include && \
 602                 cf_cv_curses_incdir="-I/usr/5include"
 603         fi
 604         ;;
 605 esac
 606 ])
 607 test "$cf_cv_curses_incdir" != no && CPPFLAGS="$CPPFLAGS $cf_cv_curses_incdir"
 608
 609 CF_CURSES_HEADER
 610 CF_TERM_HEADER
 611 ])dnl
 612 dnl ---------------------------------------------------------------------------
 613 dnl CF_CURSES_FUNCS version: 17 updated: 2011/05/14 16:07:29
 614 dnl ---------------
 615 dnl Curses-functions are a little complicated, since a lot of them are macros.
 616 AC_DEFUN([CF_CURSES_FUNCS],
 617 [
 618 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
 619 AC_REQUIRE([CF_XOPEN_CURSES])
 620 AC_REQUIRE([CF_CURSES_TERM_H])
 621 AC_REQUIRE([CF_CURSES_UNCTRL_H])
 622 for cf_func in $1
 623 do
 624         CF_UPPER(cf_tr_func,$cf_func)
 625         AC_MSG_CHECKING(for ${cf_func})
 626         CF_MSG_LOG(${cf_func})
 627         AC_CACHE_VAL(cf_cv_func_$cf_func,[
 628                 eval cf_result='$ac_cv_func_'$cf_func
 629                 if test ".$cf_result" != ".no"; then
 630                         AC_TRY_LINK(CF__CURSES_HEAD,
 631                         [
 632 #ifndef ${cf_func}
 633 long foo = (long)(&${cf_func});
 634 if (foo + 1234 > 5678)
 635         ${cf_cv_main_return:-return}(foo);
 636 #endif
 637                         ],
 638                         [cf_result=yes],
 639                         [cf_result=no])
 640                 fi
 641                 eval 'cf_cv_func_'$cf_func'=$cf_result'
 642         ])
 643         # use the computed/retrieved cache-value:
 644         eval 'cf_result=$cf_cv_func_'$cf_func
 645         AC_MSG_RESULT($cf_result)
 646         if test $cf_result != no; then
 647                 AC_DEFINE_UNQUOTED(HAVE_${cf_tr_func})
 648         fi
 649 done
 650 ])dnl
 651 dnl ---------------------------------------------------------------------------
 652 dnl CF_CURSES_HEADER version: 3 updated: 2011/05/01 19:47:45
 653 dnl ----------------
 654 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
 655 dnl variations of ncurses' installs.
 656 dnl
 657 dnl $1 = ncurses when looking for ncurses, or is empty
 658 AC_DEFUN([CF_CURSES_HEADER],[
 659 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
 660 cf_cv_ncurses_header=none
 661 for cf_header in ifelse($1,,,[ \
 662     $1/ncurses.h \
 663         $1/curses.h]) \
 664         ncurses.h \
 665         curses.h ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
 666 do
 667 AC_TRY_COMPILE([#include <${cf_header}>],
 668         [initscr(); tgoto("?", 0,0)],
 669         [cf_cv_ncurses_header=$cf_header; break],[])
 670 done
 671 ])
 672
 673 if test "$cf_cv_ncurses_header" = none ; then
 674         AC_MSG_ERROR(No curses header-files found)
 675 fi
 676
 677 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
 678 AC_CHECK_HEADERS($cf_cv_ncurses_header)
 679 ])dnl
 680 dnl ---------------------------------------------------------------------------
 681 dnl CF_CURSES_LIBS version: 35 updated: 2011/08/09 21:06:37
 682 dnl --------------
 683 dnl Look for the curses libraries.  Older curses implementations may require
 684 dnl termcap/termlib to be linked as well.  Call CF_CURSES_CPPFLAGS first.
 685 AC_DEFUN([CF_CURSES_LIBS],[
 686
 687 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
 688 AC_MSG_CHECKING(if we have identified curses libraries)
 689 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
 690     [initscr(); tgoto("?", 0,0)],
 691     cf_result=yes,
 692     cf_result=no)
 693 AC_MSG_RESULT($cf_result)
 694
 695 if test "$cf_result" = no ; then
 696 case $host_os in #(vi
 697 freebsd*) #(vi
 698     AC_CHECK_LIB(mytinfo,tgoto,[CF_ADD_LIBS(-lmytinfo)])
 699     ;;
 700 hpux10.*) #(vi
 701         # Looking at HPUX 10.20, the Hcurses library is the oldest (1997), cur_colr
 702         # next (1998), and xcurses "newer" (2000).  There is no header file for
 703         # Hcurses; the subdirectory curses_colr has the headers (curses.h and
 704         # term.h) for cur_colr
 705         if test "x$cf_cv_screen" = "xcurses_colr"
 706         then
 707                 AC_CHECK_LIB(cur_colr,initscr,[
 708                         CF_ADD_LIBS(-lcur_colr)
 709                         ac_cv_func_initscr=yes
 710                         ],[
 711                 AC_CHECK_LIB(Hcurses,initscr,[
 712                         # HP's header uses __HP_CURSES, but user claims _HP_CURSES.
 713                         CF_ADD_LIBS(-lHcurses)
 714                         CPPFLAGS="$CPPFLAGS -D__HP_CURSES -D_HP_CURSES"
 715                         ac_cv_func_initscr=yes
 716                         ])])
 717         fi
 718     ;;
 719 linux*)
 720         case `arch 2>/dev/null` in
 721         x86_64)
 722                 if test -d /lib64
 723                 then
 724                         CF_ADD_LIBDIR(/lib64)
 725                 else
 726                         CF_ADD_LIBDIR(/lib)
 727                 fi
 728                 ;;
 729         *)
 730                 CF_ADD_LIBDIR(/lib)
 731                 ;;
 732         esac
 733     ;;
 734 sunos3*|sunos4*)
 735         if test "x$cf_cv_screen" = "xcurses_5lib"
 736         then
 737                 if test -d /usr/5lib ; then
 738                         CF_ADD_LIBDIR(/usr/5lib)
 739                         CF_ADD_LIBS(-lcurses -ltermcap)
 740                 fi
 741     fi
 742     ac_cv_func_initscr=yes
 743     ;;
 744 esac
 745
 746 if test ".$ac_cv_func_initscr" != .yes ; then
 747     cf_save_LIBS="$LIBS"
 748     cf_term_lib=""
 749     cf_curs_lib=""
 750
 751     if test ".${cf_cv_ncurses_version:-no}" != .no
 752     then
 753         cf_check_list="ncurses curses cursesX"
 754     else
 755         cf_check_list="cursesX curses ncurses"
 756     fi
 757
 758     # Check for library containing tgoto.  Do this before curses library
 759     # because it may be needed to link the test-case for initscr.
 760     AC_CHECK_FUNC(tgoto,[cf_term_lib=predefined],[
 761         for cf_term_lib in $cf_check_list otermcap termcap termlib unknown
 762         do
 763             AC_CHECK_LIB($cf_term_lib,tgoto,[break])
 764         done
 765     ])
 766
 767     # Check for library containing initscr
 768     test "$cf_term_lib" != predefined && test "$cf_term_lib" != unknown && LIBS="-l$cf_term_lib $cf_save_LIBS"
 769         for cf_curs_lib in $cf_check_list xcurses jcurses pdcurses unknown
 770     do
 771         AC_CHECK_LIB($cf_curs_lib,initscr,[break])
 772     done
 773     test $cf_curs_lib = unknown && AC_MSG_ERROR(no curses library found)
 774
 775     LIBS="-l$cf_curs_lib $cf_save_LIBS"
 776     if test "$cf_term_lib" = unknown ; then
 777         AC_MSG_CHECKING(if we can link with $cf_curs_lib library)
 778         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
 779             [initscr()],
 780             [cf_result=yes],
 781             [cf_result=no])
 782         AC_MSG_RESULT($cf_result)
 783         test $cf_result = no && AC_MSG_ERROR(Cannot link curses library)
 784     elif test "$cf_curs_lib" = "$cf_term_lib" ; then
 785         :
 786     elif test "$cf_term_lib" != predefined ; then
 787         AC_MSG_CHECKING(if we need both $cf_curs_lib and $cf_term_lib libraries)
 788         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
 789             [initscr(); tgoto((char *)0, 0, 0);],
 790             [cf_result=no],
 791             [
 792             LIBS="-l$cf_curs_lib -l$cf_term_lib $cf_save_LIBS"
 793             AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
 794                 [initscr()],
 795                 [cf_result=yes],
 796                 [cf_result=error])
 797             ])
 798         AC_MSG_RESULT($cf_result)
 799     fi
 800 fi
 801 fi
 802
 803 ])dnl
 804 dnl ---------------------------------------------------------------------------
 805 dnl CF_CURSES_TERM_H version: 9 updated: 2011/04/09 18:19:55
 806 dnl ----------------
 807 dnl SVr4 curses should have term.h as well (where it puts the definitions of
 808 dnl the low-level interface).  This may not be true in old/broken implementations,
 809 dnl as well as in misconfigured systems (e.g., gcc configured for Solaris 2.4
 810 dnl running with Solaris 2.5.1).
 811 AC_DEFUN([CF_CURSES_TERM_H],
 812 [
 813 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
 814
 815 AC_CACHE_CHECK(for term.h, cf_cv_term_header,[
 816
 817 # If we found <ncurses/curses.h>, look for <ncurses/term.h>, but always look
 818 # for <term.h> if we do not find the variant.
 819
 820 cf_header_list="term.h ncurses/term.h ncursesw/term.h"
 821
 822 case ${cf_cv_ncurses_header:-curses.h} in #(vi
 823 */*)
 824         cf_header_item=`echo ${cf_cv_ncurses_header:-curses.h} | sed -e 's%\..*%%' -e 's%/.*%/%'`term.h
 825         cf_header_list="$cf_header_item $cf_header_list"
 826         ;;
 827 esac
 828
 829 for cf_header in $cf_header_list
 830 do
 831         AC_TRY_COMPILE([
 832 #include <${cf_cv_ncurses_header:-curses.h}>
 833 #include <${cf_header}>],
 834         [WINDOW *x],
 835         [cf_cv_term_header=$cf_header
 836          break],
 837         [cf_cv_term_header=no])
 838 done
 839
 840 case $cf_cv_term_header in #(vi
 841 no)
 842         # If curses is ncurses, some packagers still mess it up by trying to make
 843         # us use GNU termcap.  This handles the most common case.
 844         for cf_header in ncurses/term.h ncursesw/term.h
 845         do
 846                 AC_TRY_COMPILE([
 847 #include <${cf_cv_ncurses_header:-curses.h}>
 848 #ifdef NCURSES_VERSION
 849 #include <${cf_header}>
 850 #else
 851 make an error
 852 #endif],
 853                         [WINDOW *x],
 854                         [cf_cv_term_header=$cf_header
 855                          break],
 856                         [cf_cv_term_header=no])
 857         done
 858         ;;
 859 esac
 860 ])
 861
 862 case $cf_cv_term_header in #(vi
 863 term.h) #(vi
 864         AC_DEFINE(HAVE_TERM_H)
 865         ;;
 866 ncurses/term.h) #(vi
 867         AC_DEFINE(HAVE_NCURSES_TERM_H)
 868         ;;
 869 ncursesw/term.h)
 870         AC_DEFINE(HAVE_NCURSESW_TERM_H)
 871         ;;
 872 esac
 873 ])dnl
 874 dnl ---------------------------------------------------------------------------
 875 dnl CF_CURSES_UNCTRL_H version: 1 updated: 2011/04/09 18:19:55
 876 dnl ------------------
 877 dnl Any X/Open curses implementation must have unctrl.h, but ncurses packages
 878 dnl may put it in a subdirectory (along with ncurses' other headers, of
 879 dnl course).  Packages which put the headers in inconsistent locations are
 880 dnl broken).
 881 AC_DEFUN([CF_CURSES_UNCTRL_H],
 882 [
 883 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
 884
 885 AC_CACHE_CHECK(for unctrl.h, cf_cv_unctrl_header,[
 886
 887 # If we found <ncurses/curses.h>, look for <ncurses/unctrl.h>, but always look
 888 # for <unctrl.h> if we do not find the variant.
 889
 890 cf_header_list="unctrl.h ncurses/unctrl.h ncursesw/unctrl.h"
 891
 892 case ${cf_cv_ncurses_header:-curses.h} in #(vi
 893 */*)
 894         cf_header_item=`echo ${cf_cv_ncurses_header:-curses.h} | sed -e 's%\..*%%' -e 's%/.*%/%'`unctrl.h
 895         cf_header_list="$cf_header_item $cf_header_list"
 896         ;;
 897 esac
 898
 899 for cf_header in $cf_header_list
 900 do
 901         AC_TRY_COMPILE([
 902 #include <${cf_cv_ncurses_header:-curses.h}>
 903 #include <${cf_header}>],
 904         [WINDOW *x],
 905         [cf_cv_unctrl_header=$cf_header
 906          break],
 907         [cf_cv_unctrl_header=no])
 908 done
 909
 910 case $cf_cv_unctrl_header in #(vi
 911 no)
 912         AC_MSG_WARN(unctrl.h header not found)
 913         ;;
 914 esac
 915 ])
 916
 917 case $cf_cv_unctrl_header in #(vi
 918 unctrl.h) #(vi
 919         AC_DEFINE(HAVE_UNCTRL_H)
 920         ;;
 921 ncurses/unctrl.h) #(vi
 922         AC_DEFINE(HAVE_NCURSES_UNCTRL_H)
 923         ;;
 924 ncursesw/unctrl.h)
 925         AC_DEFINE(HAVE_NCURSESW_UNCTRL_H)
 926         ;;
 927 esac
 928 ])dnl
 929 dnl ---------------------------------------------------------------------------
 930 dnl CF_CURSES_WACS_MAP version: 5 updated: 2011/01/15 11:28:59
 931 dnl ------------------
 932 dnl Check for likely values of wacs_map[].
 933 AC_DEFUN([CF_CURSES_WACS_MAP],
 934 [
 935 AC_CACHE_CHECK(for wide alternate character set array, cf_cv_curses_wacs_map,[
 936         cf_cv_curses_wacs_map=unknown
 937         for name in wacs_map _wacs_map __wacs_map _nc_wacs _wacs_char
 938         do
 939         AC_TRY_LINK([
 940 #ifndef _XOPEN_SOURCE_EXTENDED
 941 #define _XOPEN_SOURCE_EXTENDED
 942 #endif
 943 #include <${cf_cv_ncurses_header:-curses.h}>],
 944         [void *foo = &($name['k'])],
 945         [cf_cv_curses_wacs_map=$name
 946          break])
 947         done])
 948
 949 test "$cf_cv_curses_wacs_map" != unknown && AC_DEFINE_UNQUOTED(CURSES_WACS_ARRAY,$cf_cv_curses_wacs_map)
 950 ])dnl
 951 dnl ---------------------------------------------------------------------------
 952 dnl CF_CURSES_WACS_SYMBOLS version: 1 updated: 2011/01/15 11:28:59
 953 dnl ----------------------
 954 dnl Do a check to see if the WACS_xxx constants are defined compatibly with
 955 dnl X/Open Curses.  In particular, NetBSD's implementation of the WACS_xxx
 956 dnl constants is broken since those constants do not point to cchar_t's.
 957 AC_DEFUN([CF_CURSES_WACS_SYMBOLS],
 958 [
 959 AC_REQUIRE([CF_CURSES_WACS_MAP])
 960
 961 AC_CACHE_CHECK(for wide alternate character constants, cf_cv_curses_wacs_symbols,[
 962 cf_cv_curses_wacs_symbols=no
 963 if test "$cf_cv_curses_wacs_map" != unknown
 964 then
 965         AC_TRY_LINK([
 966 #ifndef _XOPEN_SOURCE_EXTENDED
 967 #define _XOPEN_SOURCE_EXTENDED
 968 #endif
 969 #include <${cf_cv_ncurses_header:-curses.h}>],
 970         [cchar_t *foo = WACS_PLUS;
 971          $cf_cv_curses_wacs_map['k'] = *WACS_PLUS],
 972         [cf_cv_curses_wacs_symbols=yes])
 973 else
 974         AC_TRY_LINK([
 975 #ifndef _XOPEN_SOURCE_EXTENDED
 976 #define _XOPEN_SOURCE_EXTENDED
 977 #endif
 978 #include <${cf_cv_ncurses_header:-curses.h}>],
 979         [cchar_t *foo = WACS_PLUS],
 980         [cf_cv_curses_wacs_symbols=yes])
 981 fi
 982 ])
 983
 984 test "$cf_cv_curses_wacs_symbols" != no && AC_DEFINE(CURSES_WACS_SYMBOLS)
 985 ])dnl
 986 dnl ---------------------------------------------------------------------------
 987 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
 988 dnl ----------
 989 dnl "dirname" is not portable, so we fake it with a shell script.
 990 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
 991 dnl ---------------------------------------------------------------------------
 992 dnl CF_DISABLE_ECHO version: 11 updated: 2009/12/13 13:16:57
 993 dnl ---------------
 994 dnl You can always use "make -n" to see the actual options, but it's hard to
 995 dnl pick out/analyze warning messages when the compile-line is long.
 996 dnl
 997 dnl Sets:
 998 dnl     ECHO_LT - symbol to control if libtool is verbose
 999 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1000 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1001 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1002 dnl     ECHO_CC - symbol to put before any "cc" line
1003 dnl
1004 AC_DEFUN([CF_DISABLE_ECHO],[
1005 AC_MSG_CHECKING(if you want to see long compiling messages)
1006 CF_ARG_DISABLE(echo,
1007         [  --disable-echo          display "compiling" commands],
1008         [
1009     ECHO_LT='--silent'
1010     ECHO_LD='@echo linking [$]@;'
1011     RULE_CC='@echo compiling [$]<'
1012     SHOW_CC='@echo compiling [$]@'
1013     ECHO_CC='@'
1014 ],[
1015     ECHO_LT=''
1016     ECHO_LD=''
1017     RULE_CC=''
1018     SHOW_CC=''
1019     ECHO_CC=''
1020 ])
1021 AC_MSG_RESULT($enableval)
1022 AC_SUBST(ECHO_LT)
1023 AC_SUBST(ECHO_LD)
1024 AC_SUBST(RULE_CC)
1025 AC_SUBST(SHOW_CC)
1026 AC_SUBST(ECHO_CC)
1027 ])dnl
1028 dnl ---------------------------------------------------------------------------
1029 dnl CF_DISABLE_LEAKS version: 6 updated: 2010/07/23 04:14:32
1030 dnl ----------------
1031 dnl Combine no-leak checks with the libraries or tools that are used for the
1032 dnl checks.
1033 AC_DEFUN([CF_DISABLE_LEAKS],[
1034
1035 AC_REQUIRE([CF_WITH_DMALLOC])
1036 AC_REQUIRE([CF_WITH_DBMALLOC])
1037 AC_REQUIRE([CF_WITH_VALGRIND])
1038
1039 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1040 AC_ARG_ENABLE(leaks,
1041         [  --disable-leaks         test: free permanent memory, analyze leaks],
1042         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1043         : ${with_no_leaks:=no})
1044 AC_MSG_RESULT($with_no_leaks)
1045
1046 if test "$with_no_leaks" = yes ; then
1047         AC_DEFINE(NO_LEAKS)
1048         AC_DEFINE(YY_NO_LEAKS)
1049 fi
1050 ])dnl
1051 dnl ---------------------------------------------------------------------------
1052 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1053 dnl ---------------------
1054 dnl The rpath-hack makes it simpler to build programs, particularly with the
1055 dnl *BSD ports which may have essential libraries in unusual places.  But it
1056 dnl can interfere with building an executable for the base system.  Use this
1057 dnl option in that case.
1058 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1059 [
1060 AC_MSG_CHECKING(if rpath-hack should be disabled)
1061 CF_ARG_DISABLE(rpath-hack,
1062         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1063         [cf_disable_rpath_hack=yes],
1064         [cf_disable_rpath_hack=no])
1065 AC_MSG_RESULT($cf_disable_rpath_hack)
1066 if test "$cf_disable_rpath_hack" = no ; then
1067         CF_RPATH_HACK
1068 fi
1069 ])
1070 dnl ---------------------------------------------------------------------------
1071 dnl CF_ENABLE_WARNINGS version: 4 updated: 2009/07/26 17:53:03
1072 dnl ------------------
1073 dnl Configure-option to enable gcc warnings
1074 AC_DEFUN([CF_ENABLE_WARNINGS],[
1075 if ( test "$GCC" = yes || test "$GXX" = yes )
1076 then
1077 AC_MSG_CHECKING(if you want to turn on gcc warnings)
1078 CF_ARG_ENABLE(warnings,
1079         [  --enable-warnings       test: turn on gcc compiler warnings],
1080         [with_warnings=yes],
1081         [with_warnings=no])
1082 AC_MSG_RESULT($with_warnings)
1083 if test "$with_warnings" = "yes"
1084 then
1085         CF_GCC_ATTRIBUTES
1086         CF_GCC_WARNINGS
1087 fi
1088 fi
1089 ])dnl
1090 dnl ---------------------------------------------------------------------------
1091 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
1092 dnl ---------------
1093 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
1094 dnl prefer a standard location, and use -L options only if we do not find the
1095 dnl library in the standard library location(s).
1096 dnl     $1 = library name
1097 dnl     $2 = library class, usually the same as library name
1098 dnl     $3 = includes
1099 dnl     $4 = code fragment to compile/link
1100 dnl     $5 = corresponding function-name
1101 dnl     $6 = flag, nonnull if failure should not cause an error-exit
1102 dnl
1103 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
1104 dnl to use a -L option.
1105 AC_DEFUN([CF_FIND_LIBRARY],
1106 [
1107         eval 'cf_cv_have_lib_'$1'=no'
1108         cf_libdir=""
1109         AC_CHECK_FUNC($5,
1110                 eval 'cf_cv_have_lib_'$1'=yes',[
1111                 cf_save_LIBS="$LIBS"
1112                 AC_MSG_CHECKING(for $5 in -l$1)
1113                 LIBS="-l$1 $LIBS"
1114                 AC_TRY_LINK([$3],[$4],
1115                         [AC_MSG_RESULT(yes)
1116                          eval 'cf_cv_have_lib_'$1'=yes'
1117                         ],
1118                         [AC_MSG_RESULT(no)
1119                         CF_LIBRARY_PATH(cf_search,$2)
1120                         for cf_libdir in $cf_search
1121                         do
1122                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
1123                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
1124                                 AC_TRY_LINK([$3],[$4],
1125                                         [AC_MSG_RESULT(yes)
1126                                          eval 'cf_cv_have_lib_'$1'=yes'
1127                                          break],
1128                                         [AC_MSG_RESULT(no)
1129                                          LIBS="$cf_save_LIBS"])
1130                         done
1131                         ])
1132                 ])
1133 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
1134 ifelse($6,,[
1135 if test $cf_found_library = no ; then
1136         AC_MSG_ERROR(Cannot link $1 library)
1137 fi
1138 ])
1139 ])dnl
1140 dnl ---------------------------------------------------------------------------
1141 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
1142 dnl ---------------
1143 dnl Find a library (specifically the linkage used in the code fragment),
1144 dnl searching for it if it is not already in the library path.
1145 dnl See also CF_ADD_SEARCHPATH.
1146 dnl
1147 dnl Parameters (4-on are optional):
1148 dnl     $1 = headers for library entrypoint
1149 dnl     $2 = code fragment for library entrypoint
1150 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1151 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1152 dnl     $5 = action to perform if not successful
1153 dnl     $6 = module name, if not the same as the library name
1154 dnl     $7 = extra libraries
1155 dnl
1156 dnl Sets these variables:
1157 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1158 dnl     $cf_cv_header_path_$3 - include-directory if needed
1159 dnl     $cf_cv_library_path_$3 - library-directory if needed
1160 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1161 AC_DEFUN([CF_FIND_LINKAGE],[
1162
1163 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1164 # will be set on completion of the AC_TRY_LINK below.
1165 cf_cv_header_path_$3=
1166 cf_cv_library_path_$3=
1167
1168 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1169
1170 cf_save_LIBS="$LIBS"
1171
1172 AC_TRY_LINK([$1],[$2],[
1173         cf_cv_find_linkage_$3=yes
1174         cf_cv_header_path_$3=/usr/include
1175         cf_cv_library_path_$3=/usr/lib
1176 ],[
1177
1178 LIBS="-l$3 $7 $cf_save_LIBS"
1179
1180 AC_TRY_LINK([$1],[$2],[
1181         cf_cv_find_linkage_$3=yes
1182         cf_cv_header_path_$3=/usr/include
1183         cf_cv_library_path_$3=/usr/lib
1184         cf_cv_library_file_$3="-l$3"
1185 ],[
1186         cf_cv_find_linkage_$3=no
1187         LIBS="$cf_save_LIBS"
1188
1189     CF_VERBOSE(find linkage for $3 library)
1190     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1191
1192     cf_save_CPPFLAGS="$CPPFLAGS"
1193     cf_test_CPPFLAGS="$CPPFLAGS"
1194
1195     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1196     for cf_cv_header_path_$3 in $cf_search
1197     do
1198       if test -d $cf_cv_header_path_$3 ; then
1199         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1200         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1201         AC_TRY_COMPILE([$1],[$2],[
1202             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1203             cf_cv_find_linkage_$3=maybe
1204             cf_test_CPPFLAGS="$CPPFLAGS"
1205             break],[
1206             CPPFLAGS="$cf_save_CPPFLAGS"
1207             ])
1208       fi
1209     done
1210
1211     if test "$cf_cv_find_linkage_$3" = maybe ; then
1212
1213       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1214
1215       cf_save_LIBS="$LIBS"
1216       cf_save_LDFLAGS="$LDFLAGS"
1217
1218       ifelse([$6],,,[
1219         CPPFLAGS="$cf_test_CPPFLAGS"
1220         LIBS="-l$3 $7 $cf_save_LIBS"
1221         AC_TRY_LINK([$1],[$2],[
1222             CF_VERBOSE(... found $3 library in system)
1223             cf_cv_find_linkage_$3=yes])
1224             CPPFLAGS="$cf_save_CPPFLAGS"
1225             LIBS="$cf_save_LIBS"
1226             ])
1227
1228       if test "$cf_cv_find_linkage_$3" != yes ; then
1229         CF_LIBRARY_PATH(cf_search,$3)
1230         for cf_cv_library_path_$3 in $cf_search
1231         do
1232           if test -d $cf_cv_library_path_$3 ; then
1233             CF_VERBOSE(... testing $cf_cv_library_path_$3)
1234             CPPFLAGS="$cf_test_CPPFLAGS"
1235             LIBS="-l$3 $7 $cf_save_LIBS"
1236             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1237             AC_TRY_LINK([$1],[$2],[
1238                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1239                 cf_cv_find_linkage_$3=yes
1240                 cf_cv_library_file_$3="-l$3"
1241                 break],[
1242                 CPPFLAGS="$cf_save_CPPFLAGS"
1243                 LIBS="$cf_save_LIBS"
1244                 LDFLAGS="$cf_save_LDFLAGS"
1245                 ])
1246           fi
1247         done
1248         CPPFLAGS="$cf_save_CPPFLAGS"
1249         LDFLAGS="$cf_save_LDFLAGS"
1250       fi
1251
1252     else
1253       cf_cv_find_linkage_$3=no
1254     fi
1255     ],$7)
1256 ])
1257
1258 LIBS="$cf_save_LIBS"
1259
1260 if test "$cf_cv_find_linkage_$3" = yes ; then
1261 ifelse([$4],,[
1262         CF_ADD_INCDIR($cf_cv_header_path_$3)
1263         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1264         CF_ADD_LIB($3)
1265 ],[$4])
1266 else
1267 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1268 fi
1269 ])dnl
1270 dnl ---------------------------------------------------------------------------
1271 dnl CF_FUNC_CURSES_VERSION version: 5 updated: 2010/10/23 15:54:49
1272 dnl ----------------------
1273 dnl Solaris has a data item 'curses_version', which confuses AC_CHECK_FUNCS.
1274 dnl It's a character string "SVR4", not documented.
1275 AC_DEFUN([CF_FUNC_CURSES_VERSION],
1276 [
1277 AC_CACHE_CHECK(for function curses_version, cf_cv_func_curses_version,[
1278 AC_TRY_RUN([
1279 #include <${cf_cv_ncurses_header:-curses.h}>
1280 int main()
1281 {
1282         char temp[1024];
1283         sprintf(temp, "%s\n", curses_version());
1284         ${cf_cv_main_return:-return}(0);
1285 }]
1286 ,[cf_cv_func_curses_version=yes]
1287 ,[cf_cv_func_curses_version=no]
1288 ,[cf_cv_func_curses_version=unknown])
1289 rm -f core])
1290 test "$cf_cv_func_curses_version" = yes && AC_DEFINE(HAVE_CURSES_VERSION)
1291 ])
1292 dnl ---------------------------------------------------------------------------
1293 dnl CF_GCC_ATTRIBUTES version: 14 updated: 2010/10/23 15:52:32
1294 dnl -----------------
1295 dnl Test for availability of useful gcc __attribute__ directives to quiet
1296 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1297 dnl to documentation, unrecognized directives cause older compilers to barf.
1298 AC_DEFUN([CF_GCC_ATTRIBUTES],
1299 [
1300 if test "$GCC" = yes
1301 then
1302 cat > conftest.i <<EOF
1303 #ifndef GCC_PRINTF
1304 #define GCC_PRINTF 0
1305 #endif
1306 #ifndef GCC_SCANF
1307 #define GCC_SCANF 0
1308 #endif
1309 #ifndef GCC_NORETURN
1310 #define GCC_NORETURN /* nothing */
1311 #endif
1312 #ifndef GCC_UNUSED
1313 #define GCC_UNUSED /* nothing */
1314 #endif
1315 EOF
1316 if test "$GCC" = yes
1317 then
1318         AC_CHECKING([for $CC __attribute__ directives])
1319 cat > conftest.$ac_ext <<EOF
1320 #line __oline__ "${as_me:-configure}"
1321 #include "confdefs.h"
1322 #include "conftest.h"
1323 #include "conftest.i"
1324 #if     GCC_PRINTF
1325 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1326 #else
1327 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1328 #endif
1329 #if     GCC_SCANF
1330 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1331 #else
1332 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1333 #endif
1334 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1335 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1336 extern void foo(void) GCC_NORETURN;
1337 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1338 EOF
1339         cf_printf_attribute=no
1340         cf_scanf_attribute=no
1341         for cf_attribute in scanf printf unused noreturn
1342         do
1343                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1344                 cf_directive="__attribute__(($cf_attribute))"
1345                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1346
1347                 case $cf_attribute in #(vi
1348                 printf) #(vi
1349                         cf_printf_attribute=yes
1350                         cat >conftest.h <<EOF
1351 #define GCC_$cf_ATTRIBUTE 1
1352 EOF
1353                         ;;
1354                 scanf) #(vi
1355                         cf_scanf_attribute=yes
1356                         cat >conftest.h <<EOF
1357 #define GCC_$cf_ATTRIBUTE 1
1358 EOF
1359                         ;;
1360                 *) #(vi
1361                         cat >conftest.h <<EOF
1362 #define GCC_$cf_ATTRIBUTE $cf_directive
1363 EOF
1364                         ;;
1365                 esac
1366
1367                 if AC_TRY_EVAL(ac_compile); then
1368                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1369                         cat conftest.h >>confdefs.h
1370                         case $cf_attribute in #(vi
1371                         printf) #(vi
1372                                 if test "$cf_printf_attribute" = no ; then
1373                                         cat >>confdefs.h <<EOF
1374 #define GCC_PRINTFLIKE(fmt,var) /* nothing */
1375 EOF
1376                                 else
1377                                         cat >>confdefs.h <<EOF
1378 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1379 EOF
1380                                 fi
1381                                 ;;
1382                         scanf) #(vi
1383                                 if test "$cf_scanf_attribute" = no ; then
1384                                         cat >>confdefs.h <<EOF
1385 #define GCC_SCANFLIKE(fmt,var) /* nothing */
1386 EOF
1387                                 else
1388                                         cat >>confdefs.h <<EOF
1389 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1390 EOF
1391                                 fi
1392                                 ;;
1393                         esac
1394                 fi
1395         done
1396 else
1397         fgrep define conftest.i >>confdefs.h
1398 fi
1399 rm -rf conftest*
1400 fi
1401 ])dnl
1402 dnl ---------------------------------------------------------------------------
1403 dnl CF_GCC_VERSION version: 5 updated: 2010/04/24 11:02:31
1404 dnl --------------
1405 dnl Find version of gcc
1406 AC_DEFUN([CF_GCC_VERSION],[
1407 AC_REQUIRE([AC_PROG_CC])
1408 GCC_VERSION=none
1409 if test "$GCC" = yes ; then
1410         AC_MSG_CHECKING(version of $CC)
1411         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1412         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1413         AC_MSG_RESULT($GCC_VERSION)
1414 fi
1415 ])dnl
1416 dnl ---------------------------------------------------------------------------
1417 dnl CF_GCC_WARNINGS version: 28 updated: 2012/03/31 20:10:46
1418 dnl ---------------
1419 dnl Check if the compiler supports useful warning options.  There's a few that
1420 dnl we don't use, simply because they're too noisy:
1421 dnl
1422 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1423 dnl     -Wredundant-decls (system headers make this too noisy)
1424 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1425 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1426 dnl             is enabled for ncurses using "--enable-const".
1427 dnl     -pedantic
1428 dnl
1429 dnl Parameter:
1430 dnl     $1 is an optional list of gcc warning flags that a particular
1431 dnl             application might want to use, e.g., "no-unused" for
1432 dnl             -Wno-unused
1433 dnl Special:
1434 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1435 dnl
1436 AC_DEFUN([CF_GCC_WARNINGS],
1437 [
1438 AC_REQUIRE([CF_GCC_VERSION])
1439 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1440
1441 cat > conftest.$ac_ext <<EOF
1442 #line __oline__ "${as_me:-configure}"
1443 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1444 EOF
1445
1446 if test "$INTEL_COMPILER" = yes
1447 then
1448 # The "-wdXXX" options suppress warnings:
1449 # remark #1419: external declaration in primary source file
1450 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1451 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1452 # remark #193: zero used for undefined preprocessing identifier
1453 # remark #593: variable "curs_sb_left_arrow" was set but never used
1454 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1455 # remark #869: parameter "tw" was never referenced
1456 # remark #981: operands are evaluated in unspecified order
1457 # warning #279: controlling expression is constant
1458
1459         AC_CHECKING([for $CC warning options])
1460         cf_save_CFLAGS="$CFLAGS"
1461         EXTRA_CFLAGS="-Wall"
1462         for cf_opt in \
1463                 wd1419 \
1464                 wd1683 \
1465                 wd1684 \
1466                 wd193 \
1467                 wd593 \
1468                 wd279 \
1469                 wd810 \
1470                 wd869 \
1471                 wd981
1472         do
1473                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1474                 if AC_TRY_EVAL(ac_compile); then
1475                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1476                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1477                 fi
1478         done
1479         CFLAGS="$cf_save_CFLAGS"
1480
1481 elif test "$GCC" = yes
1482 then
1483         AC_CHECKING([for $CC warning options])
1484         cf_save_CFLAGS="$CFLAGS"
1485         EXTRA_CFLAGS=
1486         cf_warn_CONST=""
1487         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1488         for cf_opt in W Wall \
1489                 Wbad-function-cast \
1490                 Wcast-align \
1491                 Wcast-qual \
1492                 Winline \
1493                 Wmissing-declarations \
1494                 Wmissing-prototypes \
1495                 Wnested-externs \
1496                 Wpointer-arith \
1497                 Wshadow \
1498                 Wstrict-prototypes \
1499                 Wundef $cf_warn_CONST $1
1500         do
1501                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1502                 if AC_TRY_EVAL(ac_compile); then
1503                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1504                         case $cf_opt in #(vi
1505                         Wcast-qual) #(vi
1506                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1507                                 ;;
1508                         Winline) #(vi
1509                                 case $GCC_VERSION in
1510                                 [[34]].*)
1511                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1512                                         continue;;
1513                                 esac
1514                                 ;;
1515                         Wpointer-arith) #(vi
1516                                 case $GCC_VERSION in
1517                                 [[12]].*)
1518                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1519                                         continue;;
1520                                 esac
1521                                 ;;
1522                         esac
1523                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1524                 fi
1525         done
1526         CFLAGS="$cf_save_CFLAGS"
1527 fi
1528 rm -rf conftest*
1529
1530 AC_SUBST(EXTRA_CFLAGS)
1531 ])dnl
1532 dnl ---------------------------------------------------------------------------
1533 dnl CF_GETOPT_HEADER version: 4 updated: 2009/08/31 20:07:52
1534 dnl ----------------
1535 dnl Check for getopt's variables which are commonly defined in stdlib.h,
1536 dnl unistd.h or (nonstandard) in getopt.h
1537 AC_DEFUN([CF_GETOPT_HEADER],
1538 [
1539 AC_HAVE_HEADERS(unistd.h getopt.h)
1540 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
1541 cf_cv_getopt_header=none
1542 for cf_header in stdio.h stdlib.h unistd.h getopt.h
1543 do
1544 AC_TRY_COMPILE([
1545 #include <$cf_header>],
1546 [int x = optind; char *y = optarg],
1547 [cf_cv_getopt_header=$cf_header
1548  break])
1549 done
1550 ])
1551 if test $cf_cv_getopt_header != none ; then
1552         AC_DEFINE(HAVE_GETOPT_HEADER)
1553 fi
1554 ])dnl
1555 dnl ---------------------------------------------------------------------------
1556 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
1557 dnl -------------
1558 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1559 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1560 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1561 dnl since it is interwoven with GNU extensions.
1562 dnl
1563 dnl Well, yes we could work around it...
1564 AC_DEFUN([CF_GNU_SOURCE],
1565 [
1566 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1567 AC_TRY_COMPILE([#include <sys/types.h>],[
1568 #ifndef _XOPEN_SOURCE
1569 make an error
1570 #endif],
1571         [cf_cv_gnu_source=no],
1572         [cf_save="$CPPFLAGS"
1573          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1574          AC_TRY_COMPILE([#include <sys/types.h>],[
1575 #ifdef _XOPEN_SOURCE
1576 make an error
1577 #endif],
1578         [cf_cv_gnu_source=no],
1579         [cf_cv_gnu_source=yes])
1580         CPPFLAGS="$cf_save"
1581         ])
1582 ])
1583 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1584 ])dnl
1585 dnl ---------------------------------------------------------------------------
1586 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
1587 dnl --------------
1588 dnl Construct a search-list of directories for a nonstandard header-file
1589 dnl
1590 dnl Parameters
1591 dnl     $1 = the variable to return as result
1592 dnl     $2 = the package name
1593 AC_DEFUN([CF_HEADER_PATH],
1594 [
1595 $1=
1596
1597 # collect the current set of include-directories from compiler flags
1598 cf_header_path_list=""
1599 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1600         for cf_header_path in $CPPFLAGS $CFLAGS
1601         do
1602                 case $cf_header_path in #(vi
1603                 -I*)
1604                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1605                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1606                         cf_header_path_list="$cf_header_path_list [$]$1"
1607                         ;;
1608                 esac
1609         done
1610 fi
1611
1612 # add the variations for the package we are looking for
1613 CF_SUBDIR_PATH($1,$2,include)
1614
1615 test "$includedir" != NONE && \
1616 test "$includedir" != "/usr/include" && \
1617 test -d "$includedir" && {
1618         test -d $includedir &&    $1="[$]$1 $includedir"
1619         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
1620 }
1621
1622 test "$oldincludedir" != NONE && \
1623 test "$oldincludedir" != "/usr/include" && \
1624 test -d "$oldincludedir" && {
1625         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
1626         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
1627 }
1628
1629 $1="[$]$1 $cf_header_path_list"
1630 ])dnl
1631 dnl ---------------------------------------------------------------------------
1632 dnl CF_INHERIT_SCRIPT version: 2 updated: 2003/03/01 23:50:42
1633 dnl -----------------
1634 dnl If we do not have a given script, look for it in the parent directory.
1635 AC_DEFUN([CF_INHERIT_SCRIPT],
1636 [
1637 test -f $1 || ( test -f ../$1 && cp ../$1 ./ )
1638 ])dnl
1639 dnl ---------------------------------------------------------------------------
1640 dnl CF_INTEL_COMPILER version: 4 updated: 2010/05/26 05:38:42
1641 dnl -----------------
1642 dnl Check if the given compiler is really the Intel compiler for Linux.  It
1643 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
1644 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
1645 dnl
1646 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1647 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1648 dnl the wrappers for gcc and g++ warnings.
1649 dnl
1650 dnl $1 = GCC (default) or GXX
1651 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
1652 dnl $3 = CFLAGS (default) or CXXFLAGS
1653 AC_DEFUN([CF_INTEL_COMPILER],[
1654 ifelse([$2],,INTEL_COMPILER,[$2])=no
1655
1656 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1657         case $host_os in
1658         linux*|gnu*)
1659                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
1660                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1661                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
1662                 AC_TRY_COMPILE([],[
1663 #ifdef __INTEL_COMPILER
1664 #else
1665 make an error
1666 #endif
1667 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
1668 cf_save_CFLAGS="$cf_save_CFLAGS -we147 -no-gcc"
1669 ],[])
1670                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1671                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
1672                 ;;
1673         esac
1674 fi
1675 ])dnl
1676 dnl ---------------------------------------------------------------------------
1677 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
1678 dnl ---------------
1679 dnl For the given system and compiler, find the compiler flags to pass to the
1680 dnl loader to use the "rpath" feature.
1681 AC_DEFUN([CF_LD_RPATH_OPT],
1682 [
1683 AC_REQUIRE([CF_CHECK_CACHE])
1684
1685 LD_RPATH_OPT=
1686 AC_MSG_CHECKING(for an rpath option)
1687 case $cf_cv_system_name in #(vi
1688 irix*) #(vi
1689         if test "$GCC" = yes; then
1690                 LD_RPATH_OPT="-Wl,-rpath,"
1691         else
1692                 LD_RPATH_OPT="-rpath "
1693         fi
1694         ;;
1695 linux*|gnu*|k*bsd*-gnu) #(vi
1696         LD_RPATH_OPT="-Wl,-rpath,"
1697         ;;
1698 openbsd[[2-9]].*|mirbsd*) #(vi
1699         LD_RPATH_OPT="-Wl,-rpath,"
1700         ;;
1701 dragonfly*|freebsd*) #(vi
1702         LD_RPATH_OPT="-rpath "
1703         ;;
1704 netbsd*) #(vi
1705         LD_RPATH_OPT="-Wl,-rpath,"
1706         ;;
1707 osf*|mls+*) #(vi
1708         LD_RPATH_OPT="-rpath "
1709         ;;
1710 solaris2*) #(vi
1711         LD_RPATH_OPT="-R"
1712         ;;
1713 *)
1714         ;;
1715 esac
1716 AC_MSG_RESULT($LD_RPATH_OPT)
1717
1718 case "x$LD_RPATH_OPT" in #(vi
1719 x-R*)
1720         AC_MSG_CHECKING(if we need a space after rpath option)
1721         cf_save_LIBS="$LIBS"
1722         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
1723         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
1724         LIBS="$cf_save_LIBS"
1725         AC_MSG_RESULT($cf_rpath_space)
1726         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
1727         ;;
1728 esac
1729 ])dnl
1730 dnl ---------------------------------------------------------------------------
1731 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
1732 dnl ---------------
1733 dnl Construct a search-list of directories for a nonstandard library-file
1734 dnl
1735 dnl Parameters
1736 dnl     $1 = the variable to return as result
1737 dnl     $2 = the package name
1738 AC_DEFUN([CF_LIBRARY_PATH],
1739 [
1740 $1=
1741 cf_library_path_list=""
1742 if test -n "${LDFLAGS}${LIBS}" ; then
1743         for cf_library_path in $LDFLAGS $LIBS
1744         do
1745                 case $cf_library_path in #(vi
1746                 -L*)
1747                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
1748                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
1749                         cf_library_path_list="$cf_library_path_list [$]$1"
1750                         ;;
1751                 esac
1752         done
1753 fi
1754
1755 CF_SUBDIR_PATH($1,$2,lib)
1756
1757 $1="$cf_library_path_list [$]$1"
1758 ])dnl
1759 dnl ---------------------------------------------------------------------------
1760 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
1761 dnl ------------
1762 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
1763 dnl a monocase filesystem.
1764 AC_DEFUN([CF_MAKE_TAGS],[
1765 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
1766
1767 AC_CHECK_PROGS(CTAGS, exctags ctags)
1768 AC_CHECK_PROGS(ETAGS, exetags etags)
1769
1770 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
1771
1772 if test "$cf_cv_mixedcase" = yes ; then
1773         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
1774 else
1775         MAKE_UPPER_TAGS=no
1776 fi
1777
1778 if test "$MAKE_UPPER_TAGS" = yes ; then
1779         MAKE_UPPER_TAGS=
1780 else
1781         MAKE_UPPER_TAGS="#"
1782 fi
1783
1784 if test "$MAKE_LOWER_TAGS" = yes ; then
1785         MAKE_LOWER_TAGS=
1786 else
1787         MAKE_LOWER_TAGS="#"
1788 fi
1789
1790 AC_SUBST(CTAGS)
1791 AC_SUBST(ETAGS)
1792
1793 AC_SUBST(MAKE_UPPER_TAGS)
1794 AC_SUBST(MAKE_LOWER_TAGS)
1795 ])dnl
1796 dnl ---------------------------------------------------------------------------
1797 dnl CF_MATH_LIB version: 8 updated: 2010/05/29 16:31:02
1798 dnl -----------
1799 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
1800 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
1801 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
1802 AC_DEFUN([CF_MATH_LIB],
1803 [
1804 AC_CACHE_CHECK(if -lm needed for math functions,
1805         cf_cv_need_libm,[
1806         AC_TRY_LINK([
1807         #include <stdio.h>
1808         #include <math.h>
1809         ],
1810         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
1811         [cf_cv_need_libm=no],
1812         [cf_cv_need_libm=yes])])
1813 if test "$cf_cv_need_libm" = yes
1814 then
1815 ifelse($1,,[
1816         CF_ADD_LIB(m)
1817 ],[$1=-lm])
1818 fi
1819 ])
1820 dnl ---------------------------------------------------------------------------
1821 dnl CF_MIN_GETCCHAR version: 3 updated: 2010/10/23 15:54:49
1822 dnl ---------------
1823 dnl CF_MIN_GETCCHAR
1824 dnl Check whether getcchar's return value counts the trailing null in a wchar_t
1825 dnl string, or not.  X/Open says it does, but Tru64 and Solaris do not do this.
1826 AC_DEFUN([CF_MIN_GETCCHAR],[
1827 AC_CACHE_CHECK(if getcchar counts trailing null,cf_cv_min_getcchar,[
1828 AC_TRY_RUN([
1829 #include <stdlib.h>
1830 #include <stdarg.h>
1831 #include <${cf_cv_ncurses_header:-curses.h}>
1832
1833 int main()
1834 {
1835         wchar_t data[2];
1836         cchar_t temp[2];
1837         int count;
1838         data[0] = L'\0';
1839     setcchar(temp, data, 0, 0, (void *)0);
1840         count = getcchar(temp, (wchar_t *)0, (attr_t *)0, (short *)0, (void *)0);
1841         ${cf_cv_main_return:-return}(count != 0);
1842 }],
1843         [cf_cv_min_getcchar=no],
1844         [cf_cv_min_getcchar=yes],
1845         [cf_cv_min_getcchar=yes])
1846 ])
1847 if test "$cf_cv_min_getcchar" = yes ; then
1848         AC_DEFINE(MIN_GETCCHAR,1)
1849 fi
1850 ])dnl
1851 dnl ---------------------------------------------------------------------------
1852 dnl CF_MIXEDCASE_FILENAMES version: 3 updated: 2003/09/20 17:07:55
1853 dnl ----------------------
1854 dnl Check if the file-system supports mixed-case filenames.  If we're able to
1855 dnl create a lowercase name and see it as uppercase, it doesn't support that.
1856 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
1857 [
1858 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
1859 if test "$cross_compiling" = yes ; then
1860         case $target_alias in #(vi
1861         *-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-mingw32*|*-uwin*) #(vi
1862                 cf_cv_mixedcase=no
1863                 ;;
1864         *)
1865                 cf_cv_mixedcase=yes
1866                 ;;
1867         esac
1868 else
1869         rm -f conftest CONFTEST
1870         echo test >conftest
1871         if test -f CONFTEST ; then
1872                 cf_cv_mixedcase=no
1873         else
1874                 cf_cv_mixedcase=yes
1875         fi
1876         rm -f conftest CONFTEST
1877 fi
1878 ])
1879 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES)
1880 ])dnl
1881 dnl ---------------------------------------------------------------------------
1882 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
1883 dnl ----------
1884 dnl Write a debug message to config.log, along with the line number in the
1885 dnl configure script.
1886 AC_DEFUN([CF_MSG_LOG],[
1887 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
1888 ])dnl
1889 dnl ---------------------------------------------------------------------------
1890 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
1891 dnl -------------------
1892 dnl Check if we can compile with ncurses' header file
1893 dnl $1 is the cache variable to set
1894 dnl $2 is the header-file to include
1895 dnl $3 is the root name (ncurses or ncursesw)
1896 AC_DEFUN([CF_NCURSES_CC_CHECK],[
1897         AC_TRY_COMPILE([
1898 ]ifelse($3,ncursesw,[
1899 #define _XOPEN_SOURCE_EXTENDED
1900 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
1901 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
1902 ])[
1903 #include <$2>],[
1904 #ifdef NCURSES_VERSION
1905 ]ifelse($3,ncursesw,[
1906 #ifndef WACS_BSSB
1907         make an error
1908 #endif
1909 ])[
1910 printf("%s\n", NCURSES_VERSION);
1911 #else
1912 #ifdef __NCURSES_H
1913 printf("old\n");
1914 #else
1915         make an error
1916 #endif
1917 #endif
1918         ]
1919         ,[$1=$2]
1920         ,[$1=no])
1921 ])dnl
1922 dnl ---------------------------------------------------------------------------
1923 dnl CF_NCURSES_CONFIG version: 9 updated: 2011/11/26 15:42:05
1924 dnl -----------------
1925 dnl Tie together the configure-script macros for ncurses.
1926 dnl Prefer the "-config" script from ncurses 6.x, to simplify analysis.
1927 dnl Allow that to be overridden using the $NCURSES_CONFIG environment variable.
1928 dnl
1929 dnl $1 is the root library name (default: "ncurses")
1930 AC_DEFUN([CF_NCURSES_CONFIG],
1931 [
1932 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
1933
1934 echo "Looking for ${cf_ncuconfig_root}-config"
1935
1936 CF_ACVERSION_CHECK(2.52,
1937         [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
1938         [AC_PATH_PROGS(NCURSES_CONFIG, ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
1939
1940 if test "$NCURSES_CONFIG" != none ; then
1941
1942 CPPFLAGS="$CPPFLAGS `$NCURSES_CONFIG --cflags`"
1943 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
1944
1945 # even with config script, some packages use no-override for curses.h
1946 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
1947
1948 dnl like CF_NCURSES_CPPFLAGS
1949 AC_DEFINE(NCURSES)
1950
1951 dnl like CF_NCURSES_LIBS
1952 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
1953 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
1954
1955 dnl like CF_NCURSES_VERSION
1956 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
1957
1958 else
1959
1960 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
1961 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
1962
1963 fi
1964 ])dnl
1965 dnl ---------------------------------------------------------------------------
1966 dnl CF_NCURSES_CPPFLAGS version: 20 updated: 2010/11/20 17:02:38
1967 dnl -------------------
1968 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
1969 dnl the CPPFLAGS variable so we can include its header.
1970 dnl
1971 dnl The header files may be installed as either curses.h, or ncurses.h (would
1972 dnl be obsolete, except that some packagers prefer this name to distinguish it
1973 dnl from a "native" curses implementation).  If not installed for overwrite,
1974 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
1975 dnl /usr/include/ncurses), but someone may have installed overwriting the
1976 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
1977 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
1978 dnl the header.
1979 dnl
1980 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
1981 dnl is already in the include-path, don't even bother with this, since we cannot
1982 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
1983 dnl
1984 dnl The optional parameter gives the root name of the library, in case it is
1985 dnl not installed as the default curses library.  That is how the
1986 dnl wide-character version of ncurses is installed.
1987 AC_DEFUN([CF_NCURSES_CPPFLAGS],
1988 [AC_REQUIRE([CF_WITH_CURSES_DIR])
1989
1990 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
1991 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
1992
1993 test -n "$cf_cv_curses_dir" && \
1994 test "$cf_cv_curses_dir" != "no" && { \
1995   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
1996 }
1997
1998 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
1999         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2000         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
2001         for cf_header in $cf_header_list
2002         do
2003                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2004                 test "$cf_cv_ncurses_h" != no && break
2005         done
2006 ])
2007
2008 CF_NCURSES_HEADER
2009 CF_TERM_HEADER
2010
2011 # some applications need this, but should check for NCURSES_VERSION
2012 AC_DEFINE(NCURSES)
2013
2014 CF_NCURSES_VERSION
2015 ])dnl
2016 dnl ---------------------------------------------------------------------------
2017 dnl CF_NCURSES_EXT_FUNCS version: 3 updated: 2010/11/13 19:43:23
2018 dnl --------------------
2019 dnl Since 2007/11/17, ncurses has defined NCURSES_EXT_FUNCS; earlier versions
2020 dnl may provide these functions.  Define the symbol if it is not defined, and
2021 dnl if it is valid.
2022 AC_DEFUN([CF_NCURSES_EXT_FUNCS],
2023 [
2024 AC_CACHE_CHECK(for ncurses extended functions,cf_cv_ncurses_ext_funcs,[
2025 AC_TRY_COMPILE([
2026 #include <${cf_cv_ncurses_header:-curses.h}>],
2027 [
2028 int x = NCURSES_EXT_FUNCS
2029 ],[cf_cv_ncurses_ext_funcs=defined],[
2030 AC_TRY_LINK([
2031 #include <${cf_cv_ncurses_header:-curses.h}>],
2032 [
2033         (void) assume_default_colors (0, 0);
2034         (void) curses_version ();
2035         (void) define_key (0, 0);
2036         (void) is_term_resized (0, 0);
2037         (void) key_defined (0);
2038         (void) keybound (0, 0);
2039         (void) keyok (0, 0);
2040         (void) resize_term (0, 0);
2041         (void) resizeterm (0, 0);
2042         (void) use_default_colors ();
2043         (void) use_extended_names (0);
2044         (void) wresize (0, 0, 0);],
2045         [cf_cv_ncurses_ext_funcs=yes],
2046         [cf_cv_ncurses_ext_funcs=no])
2047 ])
2048 ])
2049 test "$cf_cv_ncurses_ext_funcs" = yes && AC_DEFINE(NCURSES_EXT_FUNCS)
2050 ])dnl
2051 dnl ---------------------------------------------------------------------------
2052 dnl CF_NCURSES_HEADER version: 2 updated: 2008/03/23 14:48:54
2053 dnl -----------------
2054 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2055 dnl variations of ncurses' installs.
2056 dnl
2057 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2058 AC_DEFUN([CF_NCURSES_HEADER],[
2059
2060 if test "$cf_cv_ncurses_h" != no ; then
2061         cf_cv_ncurses_header=$cf_cv_ncurses_h
2062 else
2063
2064 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2065         test -n "$verbose" && echo
2066         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2067         test -n "$verbose" && echo search path $cf_search
2068         cf_save2_CPPFLAGS="$CPPFLAGS"
2069         for cf_incdir in $cf_search
2070         do
2071                 CF_ADD_INCDIR($cf_incdir)
2072                 for cf_header in \
2073                         ncurses.h \
2074                         curses.h
2075                 do
2076                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2077                         if test "$cf_cv_ncurses_h2" != no ; then
2078                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2079                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
2080                                 break
2081                         fi
2082                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2083                 done
2084                 CPPFLAGS="$cf_save2_CPPFLAGS"
2085                 test "$cf_cv_ncurses_h2" != no && break
2086         done
2087         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2088         ])
2089
2090         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2091         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
2092         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
2093                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
2094         fi
2095         CF_ADD_INCDIR($cf_1st_incdir)
2096
2097 fi
2098
2099 # Set definitions to allow ifdef'ing for ncurses.h
2100
2101 case $cf_cv_ncurses_header in # (vi
2102 *ncurses.h)
2103         AC_DEFINE(HAVE_NCURSES_H)
2104         ;;
2105 esac
2106
2107 case $cf_cv_ncurses_header in # (vi
2108 ncurses/curses.h|ncurses/ncurses.h)
2109         AC_DEFINE(HAVE_NCURSES_NCURSES_H)
2110         ;;
2111 ncursesw/curses.h|ncursesw/ncurses.h)
2112         AC_DEFINE(HAVE_NCURSESW_NCURSES_H)
2113         ;;
2114 esac
2115
2116 ])dnl
2117 dnl ---------------------------------------------------------------------------
2118 dnl CF_NCURSES_LIBS version: 16 updated: 2010/11/20 17:02:38
2119 dnl ---------------
2120 dnl Look for the ncurses library.  This is a little complicated on Linux,
2121 dnl because it may be linked with the gpm (general purpose mouse) library.
2122 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2123 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2124 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2125 dnl and the linker will record a dependency.
2126 dnl
2127 dnl The optional parameter gives the root name of the library, in case it is
2128 dnl not installed as the default curses library.  That is how the
2129 dnl wide-character version of ncurses is installed.
2130 AC_DEFUN([CF_NCURSES_LIBS],
2131 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2132
2133 cf_nculib_root=ifelse($1,,ncurses,$1)
2134         # This works, except for the special case where we find gpm, but
2135         # ncurses is in a nonstandard location via $LIBS, and we really want
2136         # to link gpm.
2137 cf_ncurses_LIBS=""
2138 cf_ncurses_SAVE="$LIBS"
2139 AC_CHECK_LIB(gpm,Gpm_Open,
2140         [AC_CHECK_LIB(gpm,initscr,
2141                 [LIBS="$cf_ncurses_SAVE"],
2142                 [cf_ncurses_LIBS="-lgpm"])])
2143
2144 case $host_os in #(vi
2145 freebsd*)
2146         # This is only necessary if you are linking against an obsolete
2147         # version of ncurses (but it should do no harm, since it's static).
2148         if test "$cf_nculib_root" = ncurses ; then
2149                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2150         fi
2151         ;;
2152 esac
2153
2154 CF_ADD_LIBS($cf_ncurses_LIBS)
2155
2156 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2157 then
2158         CF_ADD_LIBS(-l$cf_nculib_root)
2159 else
2160         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2161                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2162                 [initscr()],
2163                 initscr)
2164 fi
2165
2166 if test -n "$cf_ncurses_LIBS" ; then
2167         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2168         cf_ncurses_SAVE="$LIBS"
2169         for p in $cf_ncurses_LIBS ; do
2170                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2171                 if test "$q" != "$LIBS" ; then
2172                         LIBS="$q"
2173                 fi
2174         done
2175         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2176                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2177                 [AC_MSG_RESULT(yes)],
2178                 [AC_MSG_RESULT(no)
2179                  LIBS="$cf_ncurses_SAVE"])
2180 fi
2181
2182 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2183 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2184 ])dnl
2185 dnl ---------------------------------------------------------------------------
2186 dnl CF_NCURSES_VERSION version: 13 updated: 2010/10/23 15:54:49
2187 dnl ------------------
2188 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2189 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2190 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2191 AC_DEFUN([CF_NCURSES_VERSION],
2192 [
2193 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2194 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2195         cf_cv_ncurses_version=no
2196         cf_tempfile=out$$
2197         rm -f $cf_tempfile
2198         AC_TRY_RUN([
2199 #include <${cf_cv_ncurses_header:-curses.h}>
2200 #include <stdio.h>
2201 int main()
2202 {
2203         FILE *fp = fopen("$cf_tempfile", "w");
2204 #ifdef NCURSES_VERSION
2205 # ifdef NCURSES_VERSION_PATCH
2206         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
2207 # else
2208         fprintf(fp, "%s\n", NCURSES_VERSION);
2209 # endif
2210 #else
2211 # ifdef __NCURSES_H
2212         fprintf(fp, "old\n");
2213 # else
2214         make an error
2215 # endif
2216 #endif
2217         ${cf_cv_main_return:-return}(0);
2218 }],[
2219         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
2220
2221         # This will not work if the preprocessor splits the line after the
2222         # Autoconf token.  The 'unproto' program does that.
2223         cat > conftest.$ac_ext <<EOF
2224 #include <${cf_cv_ncurses_header:-curses.h}>
2225 #undef Autoconf
2226 #ifdef NCURSES_VERSION
2227 Autoconf NCURSES_VERSION
2228 #else
2229 #ifdef __NCURSES_H
2230 Autoconf "old"
2231 #endif
2232 ;
2233 #endif
2234 EOF
2235         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
2236         AC_TRY_EVAL(cf_try)
2237         if test -f conftest.out ; then
2238                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
2239                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
2240                 rm -f conftest.out
2241         fi
2242 ])
2243         rm -f $cf_tempfile
2244 ])
2245 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES)
2246 ])dnl
2247 dnl ---------------------------------------------------------------------------
2248 dnl CF_NCURSES_WRAP_PREFIX version: 1 updated: 2009/03/28 16:08:10
2249 dnl ----------------------
2250 dnl Check for ncurses "wrap-prefix" used for public variables which have been
2251 dnl wrapped with a function to help with concurrency control.
2252 AC_DEFUN([CF_NCURSES_WRAP_PREFIX],
2253 [
2254 AC_MSG_CHECKING(for ncurses wrap-prefix)
2255 AC_ARG_WITH(ncurses-wrap-prefix,
2256         [  --with-ncurses-wrap-prefix naming-prefix for ncurses wrapped-variables],
2257         [NCURSES_WRAP_PREFIX=$withval],
2258         [NCURSES_WRAP_PREFIX=_nc_])
2259 AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
2260
2261 AC_SUBST(NCURSES_WRAP_PREFIX)
2262 ])
2263 dnl ---------------------------------------------------------------------------
2264 dnl CF_NETBSD_FORM_H version: 1 updated: 2011/01/15 14:59:18
2265 dnl ----------------
2266 dnl Check for NetBSD's form.h, which is incompatible with SVr4 and ncurses.
2267 dnl Some workarounds are needed in client programs to allow them to compile.
2268 AC_DEFUN([CF_NETBSD_FORM_H],[
2269 AC_CACHE_CHECK(for NetBSD form.h,cf_cv_netbsd_form_h,[
2270 AC_TRY_COMPILE([
2271 #include <${cf_cv_ncurses_header:-curses.h}>
2272 #include <form.h>
2273 ],[
2274         FORM *form;
2275         int y = current_field(form)->cursor_ypos;
2276         int x = current_field(form)->cursor_xpos;
2277 ],[cf_cv_netbsd_form_h=yes
2278 ],[cf_cv_netbsd_form_h=no])
2279 ])
2280
2281 test "$cf_cv_netbsd_form_h" = yes && AC_DEFINE(HAVE_NETBSD_FORM_H)
2282 ])dnl
2283 dnl ---------------------------------------------------------------------------
2284 dnl CF_NETBSD_MENU_H version: 1 updated: 2011/01/15 14:59:18
2285 dnl ----------------
2286 dnl Check for NetBSD's menu.h, which is incompatible with SVr4 and ncurses.
2287 dnl Some workarounds are needed in client programs to allow them to compile.
2288 AC_DEFUN([CF_NETBSD_MENU_H],[
2289 AC_CACHE_CHECK(for NetBSD menu.h,cf_cv_netbsd_menu_h,[
2290 AC_TRY_COMPILE([
2291 #include <${cf_cv_ncurses_header:-curses.h}>
2292 #include <menu.h>
2293 ],[
2294         MENU *menu;
2295         int y = menu->max_item_width;
2296 ],[cf_cv_netbsd_menu_h=yes
2297 ],[cf_cv_netbsd_menu_h=no])
2298 ])
2299
2300 test "$cf_cv_netbsd_menu_h" = yes && AC_DEFINE(HAVE_NETBSD_MENU_H)
2301 ])dnl
2302 dnl ---------------------------------------------------------------------------
2303 dnl CF_NO_LEAKS_OPTION version: 4 updated: 2006/12/16 14:24:05
2304 dnl ------------------
2305 dnl see CF_WITH_NO_LEAKS
2306 AC_DEFUN([CF_NO_LEAKS_OPTION],[
2307 AC_MSG_CHECKING(if you want to use $1 for testing)
2308 AC_ARG_WITH($1,
2309         [$2],
2310         [AC_DEFINE($3)ifelse([$4],,[
2311          $4
2312 ])
2313         : ${with_cflags:=-g}
2314         : ${with_no_leaks:=yes}
2315          with_$1=yes],
2316         [with_$1=])
2317 AC_MSG_RESULT(${with_$1:-no})
2318
2319 case .$with_cflags in #(vi
2320 .*-g*)
2321         case .$CFLAGS in #(vi
2322         .*-g*) #(vi
2323                 ;;
2324         *)
2325                 CF_ADD_CFLAGS([-g])
2326                 ;;
2327         esac
2328         ;;
2329 esac
2330 ])dnl
2331 dnl ---------------------------------------------------------------------------
2332 dnl CF_PATH_SYNTAX version: 13 updated: 2010/05/26 05:38:42
2333 dnl --------------
2334 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
2335 dnl begins with one of the prefix/exec_prefix variables, and then again if the
2336 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
2337 dnl delayed evaluation of those symbols.
2338 AC_DEFUN([CF_PATH_SYNTAX],[
2339 if test "x$prefix" != xNONE; then
2340   cf_path_syntax="$prefix"
2341 else
2342   cf_path_syntax="$ac_default_prefix"
2343 fi
2344
2345 case ".[$]$1" in #(vi
2346 .\[$]\(*\)*|.\'*\'*) #(vi
2347   ;;
2348 ..|./*|.\\*) #(vi
2349   ;;
2350 .[[a-zA-Z]]:[[\\/]]*) #(vi OS/2 EMX
2351   ;;
2352 .\[$]{*prefix}*) #(vi
2353   eval $1="[$]$1"
2354   case ".[$]$1" in #(vi
2355   .NONE/*)
2356     $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2357     ;;
2358   esac
2359   ;; #(vi
2360 .no|.NONE/*)
2361   $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2362   ;;
2363 *)
2364   ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
2365   ;;
2366 esac
2367 ])dnl
2368 dnl ---------------------------------------------------------------------------
2369 dnl CF_PDCURSES_X11 version: 12 updated: 2011/11/26 15:42:05
2370 dnl ---------------
2371 dnl Configure for PDCurses' X11 library
2372 AC_DEFUN([CF_PDCURSES_X11],[
2373 AC_REQUIRE([CF_X_ATHENA])
2374
2375 CF_ACVERSION_CHECK(2.52,
2376         [AC_CHECK_TOOLS(XCURSES_CONFIG, xcurses-config, none)],
2377         [AC_PATH_PROGS(XCURSES_CONFIG, xcurses-config, none)])
2378
2379 if test "$XCURSES_CONFIG" != none ; then
2380
2381 CPPFLAGS="$CPPFLAGS `$XCURSES_CONFIG --cflags`"
2382 CF_ADD_LIBS(`$XCURSES_CONFIG --libs`)
2383
2384 cf_cv_lib_XCurses=yes
2385
2386 else
2387
2388 LDFLAGS="$LDFLAGS $X_LIBS"
2389 CF_CHECK_CFLAGS($X_CFLAGS)
2390 AC_CHECK_LIB(X11,XOpenDisplay,
2391         [CF_ADD_LIBS(-lX11)],,
2392         [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])
2393 AC_CACHE_CHECK(for XCurses library,cf_cv_lib_XCurses,[
2394 CF_ADD_LIBS(-lXCurses)
2395 AC_TRY_LINK([
2396 #include <xcurses.h>
2397 char *XCursesProgramName = "test";
2398 ],[XCursesExit();],
2399 [cf_cv_lib_XCurses=yes],
2400 [cf_cv_lib_XCurses=no])
2401 ])
2402
2403 fi
2404
2405 if test $cf_cv_lib_XCurses = yes ; then
2406         AC_DEFINE(UNIX)
2407         AC_DEFINE(XCURSES)
2408         AC_CHECK_HEADER(xcurses.h, AC_DEFINE(HAVE_XCURSES))
2409 else
2410         AC_MSG_ERROR(Cannot link with XCurses)
2411 fi
2412 ])dnl
2413 dnl ---------------------------------------------------------------------------
2414 dnl CF_PKG_CONFIG version: 7 updated: 2011/04/29 04:53:22
2415 dnl -------------
2416 dnl Check for the package-config program, unless disabled by command-line.
2417 AC_DEFUN([CF_PKG_CONFIG],
2418 [
2419 AC_MSG_CHECKING(if you want to use pkg-config)
2420 AC_ARG_WITH(pkg-config,
2421         [  --with-pkg-config{=path} enable/disable use of pkg-config],
2422         [cf_pkg_config=$withval],
2423         [cf_pkg_config=yes])
2424 AC_MSG_RESULT($cf_pkg_config)
2425
2426 case $cf_pkg_config in #(vi
2427 no) #(vi
2428         PKG_CONFIG=none
2429         ;;
2430 yes) #(vi
2431         CF_ACVERSION_CHECK(2.52,
2432                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
2433                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
2434         ;;
2435 *)
2436         PKG_CONFIG=$withval
2437         ;;
2438 esac
2439
2440 test -z "$PKG_CONFIG" && PKG_CONFIG=none
2441 if test "$PKG_CONFIG" != none ; then
2442         CF_PATH_SYNTAX(PKG_CONFIG)
2443 fi
2444
2445 AC_SUBST(PKG_CONFIG)
2446 ])dnl
2447 dnl ---------------------------------------------------------------------------
2448 dnl CF_POSIX_C_SOURCE version: 8 updated: 2010/05/26 05:38:42
2449 dnl -----------------
2450 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
2451 dnl
2452 dnl     POSIX.1-1990                            _POSIX_SOURCE
2453 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
2454 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
2455 dnl             Bindings Option
2456 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
2457 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
2458 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
2459 dnl
2460 dnl Parameters:
2461 dnl     $1 is the nominal value for _POSIX_C_SOURCE
2462 AC_DEFUN([CF_POSIX_C_SOURCE],
2463 [
2464 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
2465
2466 cf_save_CFLAGS="$CFLAGS"
2467 cf_save_CPPFLAGS="$CPPFLAGS"
2468
2469 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
2470 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
2471
2472 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
2473         CF_MSG_LOG(if the symbol is already defined go no further)
2474         AC_TRY_COMPILE([#include <sys/types.h>],[
2475 #ifndef _POSIX_C_SOURCE
2476 make an error
2477 #endif],
2478         [cf_cv_posix_c_source=no],
2479         [cf_want_posix_source=no
2480          case .$cf_POSIX_C_SOURCE in #(vi
2481          .[[12]]??*) #(vi
2482                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2483                 ;;
2484          .2) #(vi
2485                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2486                 cf_want_posix_source=yes
2487                 ;;
2488          .*)
2489                 cf_want_posix_source=yes
2490                 ;;
2491          esac
2492          if test "$cf_want_posix_source" = yes ; then
2493                 AC_TRY_COMPILE([#include <sys/types.h>],[
2494 #ifdef _POSIX_SOURCE
2495 make an error
2496 #endif],[],
2497                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
2498          fi
2499          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
2500          CFLAGS="$cf_trim_CFLAGS"
2501          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
2502          CF_MSG_LOG(if the second compile does not leave our definition intact error)
2503          AC_TRY_COMPILE([#include <sys/types.h>],[
2504 #ifndef _POSIX_C_SOURCE
2505 make an error
2506 #endif],,
2507          [cf_cv_posix_c_source=no])
2508          CFLAGS="$cf_save_CFLAGS"
2509          CPPFLAGS="$cf_save_CPPFLAGS"
2510         ])
2511 ])
2512
2513 if test "$cf_cv_posix_c_source" != no ; then
2514         CFLAGS="$cf_trim_CFLAGS"
2515         CPPFLAGS="$cf_trim_CPPFLAGS"
2516         CF_ADD_CFLAGS($cf_cv_posix_c_source)
2517 fi
2518
2519 ])dnl
2520 dnl ---------------------------------------------------------------------------
2521 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
2522 dnl ------------
2523 dnl Append definitions and rules for the given programs to the subdirectory
2524 dnl Makefiles, and the recursion rule for the top-level Makefile.
2525 dnl
2526 dnl parameters
2527 dnl     $1 = script to run
2528 dnl     $2 = list of subdirectories
2529 dnl
2530 dnl variables
2531 dnl     $AWK
2532 AC_DEFUN([CF_PRG_RULES],
2533 [
2534 for cf_dir in $2
2535 do
2536         if test ! -d $srcdir/$cf_dir; then
2537                 continue
2538         elif test -f $srcdir/$cf_dir/programs; then
2539                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
2540         fi
2541 done
2542
2543 ])dnl
2544 dnl ---------------------------------------------------------------------------
2545 dnl CF_PROG_CC_U_D version: 1 updated: 2005/07/14 16:59:30
2546 dnl --------------
2547 dnl Check if C (preprocessor) -U and -D options are processed in the order
2548 dnl given rather than by type of option.  Some compilers insist on apply all
2549 dnl of the -U options after all of the -D options.  Others allow mixing them,
2550 dnl and may predefine symbols that conflict with those we define.
2551 AC_DEFUN([CF_PROG_CC_U_D],
2552 [
2553 AC_CACHE_CHECK(if $CC -U and -D options work together,cf_cv_cc_u_d_options,[
2554         cf_save_CPPFLAGS="$CPPFLAGS"
2555         CPPFLAGS="-UU_D_OPTIONS -DU_D_OPTIONS -DD_U_OPTIONS -UD_U_OPTIONS"
2556         AC_TRY_COMPILE([],[
2557 #ifndef U_D_OPTIONS
2558 make an undefined-error
2559 #endif
2560 #ifdef  D_U_OPTIONS
2561 make a defined-error
2562 #endif
2563         ],[
2564         cf_cv_cc_u_d_options=yes],[
2565         cf_cv_cc_u_d_options=no])
2566         CPPFLAGS="$cf_save_CPPFLAGS"
2567 ])
2568 ])dnl
2569 dnl ---------------------------------------------------------------------------
2570 dnl CF_PROG_INSTALL version: 5 updated: 2002/12/21 22:46:07
2571 dnl ---------------
2572 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
2573 dnl misc/tabset install won't work properly.  Usually this happens only when
2574 dnl using the fallback mkinstalldirs script
2575 AC_DEFUN([CF_PROG_INSTALL],
2576 [AC_PROG_INSTALL
2577 case $INSTALL in
2578 /*)
2579   ;;
2580 *)
2581   CF_DIRNAME(cf_dir,$INSTALL)
2582   test -z "$cf_dir" && cf_dir=.
2583   INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
2584   ;;
2585 esac
2586 ])dnl
2587 dnl ---------------------------------------------------------------------------
2588 dnl CF_PROG_LINT version: 2 updated: 2009/08/12 04:43:14
2589 dnl ------------
2590 AC_DEFUN([CF_PROG_LINT],
2591 [
2592 AC_CHECK_PROGS(LINT, tdlint lint alint splint lclint)
2593 AC_SUBST(LINT_OPTS)
2594 ])dnl
2595 dnl ---------------------------------------------------------------------------
2596 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
2597 dnl ----------------
2598 dnl Remove all -U and -D options that refer to the given symbol from a list
2599 dnl of C compiler options.  This works around the problem that not all
2600 dnl compilers process -U and -D options from left-to-right, so a -U option
2601 dnl cannot be used to cancel the effect of a preceding -D option.
2602 dnl
2603 dnl $1 = target (which could be the same as the source variable)
2604 dnl $2 = source (including '$')
2605 dnl $3 = symbol to remove
2606 define([CF_REMOVE_DEFINE],
2607 [
2608 $1=`echo "$2" | \
2609         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
2610                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
2611 ])dnl
2612 dnl ---------------------------------------------------------------------------
2613 dnl CF_RPATH_HACK version: 9 updated: 2011/02/13 13:31:33
2614 dnl -------------
2615 AC_DEFUN([CF_RPATH_HACK],
2616 [
2617 AC_REQUIRE([CF_LD_RPATH_OPT])
2618 AC_MSG_CHECKING(for updated LDFLAGS)
2619 if test -n "$LD_RPATH_OPT" ; then
2620         AC_MSG_RESULT(maybe)
2621
2622         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
2623         cf_rpath_list="/usr/lib /lib"
2624         if test "$cf_ldd_prog" != no
2625         then
2626                 cf_rpath_oops=
2627
2628 AC_TRY_LINK([#include <stdio.h>],
2629                 [printf("Hello");],
2630                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort -u`
2631                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort -u`])
2632
2633                 # If we passed the link-test, but get a "not found" on a given library,
2634                 # this could be due to inept reconfiguration of gcc to make it only
2635                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
2636                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
2637                 # /usr/local libraries.
2638                 if test -n "$cf_rpath_oops"
2639                 then
2640                         for cf_rpath_src in $cf_rpath_oops
2641                         do
2642                                 for cf_rpath_dir in \
2643                                         /usr/local \
2644                                         /usr/pkg \
2645                                         /opt/sfw
2646                                 do
2647                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
2648                                         then
2649                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
2650                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
2651                                                 break
2652                                         fi
2653                                 done
2654                         done
2655                 fi
2656         fi
2657
2658         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
2659
2660         CF_RPATH_HACK_2(LDFLAGS)
2661         CF_RPATH_HACK_2(LIBS)
2662
2663         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
2664 fi
2665 AC_SUBST(EXTRA_LDFLAGS)
2666 ])dnl
2667 dnl ---------------------------------------------------------------------------
2668 dnl CF_RPATH_HACK_2 version: 6 updated: 2010/04/17 16:31:24
2669 dnl ---------------
2670 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
2671 dnl EXTRA_LDFLAGS for each -L option found.
2672 dnl
2673 dnl $cf_rpath_list contains a list of directories to ignore.
2674 dnl
2675 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
2676 dnl      but LIBS often has misplaced -L options.
2677 AC_DEFUN([CF_RPATH_HACK_2],
2678 [
2679 CF_VERBOSE(...checking $1 [$]$1)
2680
2681 cf_rpath_dst=
2682 for cf_rpath_src in [$]$1
2683 do
2684         case $cf_rpath_src in #(vi
2685         -L*) #(vi
2686
2687                 # check if this refers to a directory which we will ignore
2688                 cf_rpath_skip=no
2689                 if test -n "$cf_rpath_list"
2690                 then
2691                         for cf_rpath_item in $cf_rpath_list
2692                         do
2693                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
2694                                 then
2695                                         cf_rpath_skip=yes
2696                                         break
2697                                 fi
2698                         done
2699                 fi
2700
2701                 if test "$cf_rpath_skip" = no
2702                 then
2703                         # transform the option
2704                         if test "$LD_RPATH_OPT" = "-R " ; then
2705                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
2706                         else
2707                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
2708                         fi
2709
2710                         # if we have not already added this, add it now
2711                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
2712                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
2713                         then
2714                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
2715                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
2716                         fi
2717                 fi
2718                 ;;
2719         esac
2720         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
2721 done
2722 $1=$cf_rpath_dst
2723
2724 CF_VERBOSE(...checked $1 [$]$1)
2725 AC_SUBST(EXTRA_LDFLAGS)
2726 ])dnl
2727 dnl ---------------------------------------------------------------------------
2728 dnl CF_SIG_ATOMIC_T version: 2 updated: 2005/09/18 17:27:12
2729 dnl ---------------
2730 dnl signal handler, but there are some gcc depedencies in that recommendation.
2731 dnl Try anyway.
2732 AC_DEFUN([CF_SIG_ATOMIC_T],
2733 [
2734 AC_MSG_CHECKING(for signal global datatype)
2735 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
2736         for cf_type in \
2737                 "volatile sig_atomic_t" \
2738                 "sig_atomic_t" \
2739                 "int"
2740         do
2741         AC_TRY_COMPILE([
2742 #include <sys/types.h>
2743 #include <signal.h>
2744 #include <stdio.h>
2745
2746 extern $cf_type x;
2747 $cf_type x;
2748 static void handler(int sig)
2749 {
2750         x = 5;
2751 }],
2752                 [signal(SIGINT, handler);
2753                  x = 1],
2754                 [cf_cv_sig_atomic_t=$cf_type],
2755                 [cf_cv_sig_atomic_t=no])
2756                 test "$cf_cv_sig_atomic_t" != no && break
2757         done
2758         ])
2759 AC_MSG_RESULT($cf_cv_sig_atomic_t)
2760 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t)
2761 ])dnl
2762 dnl ---------------------------------------------------------------------------
2763 dnl CF_SUBDIR_PATH version: 6 updated: 2010/04/21 06:20:50
2764 dnl --------------
2765 dnl Construct a search-list for a nonstandard header/lib-file
2766 dnl     $1 = the variable to return as result
2767 dnl     $2 = the package name
2768 dnl     $3 = the subdirectory, e.g., bin, include or lib
2769 AC_DEFUN([CF_SUBDIR_PATH],
2770 [
2771 $1=
2772
2773 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr,$prefix)
2774 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
2775 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr/local,$prefix)
2776 CF_ADD_SUBDIR_PATH($1,$2,$3,/opt,$prefix)
2777 CF_ADD_SUBDIR_PATH($1,$2,$3,[$]HOME,$prefix)
2778 ])dnl
2779 dnl ---------------------------------------------------------------------------
2780 dnl CF_SYS_TIME_SELECT version: 4 updated: 2000/10/04 09:18:40
2781 dnl ------------------
2782 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
2783 dnl older SCO configurations.
2784 AC_DEFUN([CF_SYS_TIME_SELECT],
2785 [
2786 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
2787 AC_CACHE_VAL(cf_cv_sys_time_select,[
2788 AC_TRY_COMPILE([
2789 #include <sys/types.h>
2790 #ifdef HAVE_SYS_TIME_H
2791 #include <sys/time.h>
2792 #endif
2793 #ifdef HAVE_SYS_SELECT_H
2794 #include <sys/select.h>
2795 #endif
2796 ],[],[cf_cv_sys_time_select=yes],
2797      [cf_cv_sys_time_select=no])
2798      ])
2799 AC_MSG_RESULT($cf_cv_sys_time_select)
2800 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT)
2801 ])dnl
2802 dnl ---------------------------------------------------------------------------
2803 dnl CF_TERM_HEADER version: 2 updated: 2010/10/23 15:54:49
2804 dnl --------------
2805 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
2806 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
2807 dnl but some packagers change this, breaking various applications.
2808 AC_DEFUN([CF_TERM_HEADER],[
2809 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
2810 case ${cf_cv_ncurses_header} in #(vi
2811 */ncurses.h|*/ncursesw.h) #(vi
2812         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
2813         ;;
2814 *)
2815         cf_term_header=term.h
2816         ;;
2817 esac
2818
2819 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
2820 do
2821 AC_TRY_COMPILE([#include <stdio.h>
2822 #include <${cf_cv_ncurses_header:-curses.h}>
2823 #include <$cf_test>
2824 ],[int x = auto_left_margin],[
2825         cf_cv_term_header="$cf_test"],[
2826         cf_cv_term_header=unknown
2827         ])
2828         test "$cf_cv_term_header" != unknown && break
2829 done
2830 ])
2831
2832 # Set definitions to allow ifdef'ing to accommodate subdirectories
2833
2834 case $cf_cv_term_header in # (vi
2835 *term.h)
2836         AC_DEFINE(HAVE_TERM_H)
2837         ;;
2838 esac
2839
2840 case $cf_cv_term_header in # (vi
2841 ncurses/term.h) #(vi
2842         AC_DEFINE(HAVE_NCURSES_TERM_H)
2843         ;;
2844 ncursesw/term.h)
2845         AC_DEFINE(HAVE_NCURSESW_TERM_H)
2846         ;;
2847 esac
2848 ])dnl
2849 dnl ---------------------------------------------------------------------------
2850 dnl CF_TOP_BUILDDIR version: 1 updated: 2006/10/15 16:33:23
2851 dnl ---------------
2852 dnl Define a top_builddir symbol, for applications that need an absolute path.
2853 AC_DEFUN([CF_TOP_BUILDDIR],
2854 [
2855 top_builddir=`pwd`
2856 AC_SUBST(top_builddir)
2857 ])dnl
2858 dnl ---------------------------------------------------------------------------
2859 dnl CF_TPUTS_PROTO version: 2 updated: 2011/04/23 19:25:50
2860 dnl --------------
2861 dnl Check for type of function-pointer passed to tputs.  Some old
2862 dnl implementations used functions that had different prototypes, making it
2863 dnl hard to compile portable programs using tputs.
2864 AC_DEFUN([CF_TPUTS_PROTO],[
2865 CF_CURSES_FUNCS(tputs)
2866 if test x$cf_cv_func_tputs = xyes
2867 then
2868         cf_done=no
2869         for cf_arg in int char
2870         do
2871                 for cf_ret in int void
2872                 do
2873                         if test $cf_ret = void
2874                         then
2875                                 cf_return="/* nothing */"
2876                         else
2877                                 cf_return="return value"
2878                         fi
2879                         AC_TRY_COMPILE([
2880 #include <${cf_cv_ncurses_header:-curses.h}>
2881 #include <$cf_cv_term_header>
2882
2883 static $cf_ret outc($cf_arg value) { $cf_return; }
2884 ],[
2885         tputs("hello", 0, outc);
2886         ${cf_cv_main_return:-return}(0);
2887 ],[
2888                 CF_VERBOSE([prototype $cf_ret func($cf_arg value)])
2889                 cat >>confdefs.h <<EOF
2890 #define TPUTS_ARG               $cf_arg
2891 #define TPUTS_PROTO(func,value) $cf_ret func(TPUTS_ARG value)
2892 #define TPUTS_RETURN(value)     $cf_return
2893 EOF
2894                 cf_done=yes
2895                 break
2896 ])
2897                 done
2898                 test $cf_done = yes && break
2899         done
2900 fi
2901 ])dnl
2902 dnl ---------------------------------------------------------------------------
2903 dnl CF_TRY_PKG_CONFIG version: 4 updated: 2010/06/14 17:42:30
2904 dnl -----------------
2905 dnl This is a simple wrapper to use for pkg-config, for libraries which may be
2906 dnl available in that form.
2907 dnl
2908 dnl $1 = package name
2909 dnl $2 = extra logic to use, if any, after updating CFLAGS and LIBS
2910 dnl $3 = logic to use if pkg-config does not have the package
2911 AC_DEFUN([CF_TRY_PKG_CONFIG],[
2912 AC_REQUIRE([CF_PKG_CONFIG])
2913
2914 if test "$PKG_CONFIG" != none && "$PKG_CONFIG" --exists $1; then
2915         CF_VERBOSE(found package $1)
2916         cf_pkgconfig_incs="`$PKG_CONFIG --cflags $1 2>/dev/null`"
2917         cf_pkgconfig_libs="`$PKG_CONFIG --libs   $1 2>/dev/null`"
2918         CF_VERBOSE(package $1 CFLAGS: $cf_pkgconfig_incs)
2919         CF_VERBOSE(package $1 LIBS: $cf_pkgconfig_libs)
2920         CF_ADD_CFLAGS($cf_pkgconfig_incs)
2921         CF_ADD_LIBS($cf_pkgconfig_libs)
2922         ifelse([$2],,:,[$2])
2923 else
2924         ifelse([$3],,:,[$3])
2925 fi
2926 ])
2927 dnl ---------------------------------------------------------------------------
2928 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
2929 dnl -------------------
2930 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
2931 dnl can define it successfully.
2932 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
2933 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
2934         AC_TRY_COMPILE([
2935 #include <stdlib.h>
2936 #include <string.h>
2937 #include <sys/types.h>
2938 ],[
2939 #ifndef _XOPEN_SOURCE
2940 make an error
2941 #endif],
2942         [cf_cv_xopen_source=no],
2943         [cf_save="$CPPFLAGS"
2944          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
2945          AC_TRY_COMPILE([
2946 #include <stdlib.h>
2947 #include <string.h>
2948 #include <sys/types.h>
2949 ],[
2950 #ifdef _XOPEN_SOURCE
2951 make an error
2952 #endif],
2953         [cf_cv_xopen_source=no],
2954         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
2955         CPPFLAGS="$cf_save"
2956         ])
2957 ])
2958
2959 if test "$cf_cv_xopen_source" != no ; then
2960         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
2961         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
2962         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
2963         CF_ADD_CFLAGS($cf_temp_xopen_source)
2964 fi
2965 ])
2966 dnl ---------------------------------------------------------------------------
2967 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
2968 dnl --------
2969 dnl Make an uppercase version of a variable
2970 dnl $1=uppercase($2)
2971 AC_DEFUN([CF_UPPER],
2972 [
2973 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
2974 ])dnl
2975 dnl ---------------------------------------------------------------------------
2976 dnl CF_UTF8_LIB version: 7 updated: 2010/06/20 09:24:28
2977 dnl -----------
2978 dnl Check for multibyte support, and if not found, utf8 compatibility library
2979 AC_DEFUN([CF_UTF8_LIB],
2980 [
2981 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
2982         cf_save_LIBS="$LIBS"
2983         AC_TRY_LINK([
2984 #include <stdlib.h>],[putwc(0,0);],
2985         [cf_cv_utf8_lib=yes],
2986         [CF_FIND_LINKAGE([
2987 #include <libutf8.h>],[putwc(0,0);],utf8,
2988                 [cf_cv_utf8_lib=add-on],
2989                 [cf_cv_utf8_lib=no])
2990 ])])
2991
2992 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
2993 # ncurses/ncursesw:
2994 if test "$cf_cv_utf8_lib" = "add-on" ; then
2995         AC_DEFINE(HAVE_LIBUTF8_H)
2996         CF_ADD_INCDIR($cf_cv_header_path_utf8)
2997         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
2998         CF_ADD_LIBS($cf_cv_library_file_utf8)
2999 fi
3000 ])dnl
3001 dnl ---------------------------------------------------------------------------
3002 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
3003 dnl ----------
3004 dnl Use AC_VERBOSE w/o the warnings
3005 AC_DEFUN([CF_VERBOSE],
3006 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
3007 CF_MSG_LOG([$1])
3008 ])dnl
3009 dnl ---------------------------------------------------------------------------
3010 dnl CF_WCHAR_TYPE version: 3 updated: 2010/05/26 16:44:57
3011 dnl -------------
3012 dnl Check if type wide-character type $1 is declared, and if so, which header
3013 dnl file is needed.  The second parameter is used to set a shell variable when
3014 dnl the type is not found.  The first parameter sets a shell variable for the
3015 dnl opposite sense.
3016 AC_DEFUN([CF_WCHAR_TYPE],
3017 [
3018 # This is needed on Tru64 5.0 to declare $1
3019 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
3020 AC_TRY_COMPILE([
3021 #include <stdlib.h>
3022 #include <stdarg.h>
3023 #include <stdio.h>
3024 #ifdef HAVE_LIBUTF8_H
3025 #include <libutf8.h>
3026 #endif],
3027         [$1 state],
3028         [cf_cv_$1=no],
3029         [AC_TRY_COMPILE([
3030 #include <stdlib.h>
3031 #include <stdarg.h>
3032 #include <stdio.h>
3033 #include <wchar.h>
3034 #ifdef HAVE_LIBUTF8_H
3035 #include <libutf8.h>
3036 #endif],
3037         [$1 value],
3038         [cf_cv_$1=yes],
3039         [cf_cv_$1=unknown])])])
3040
3041 if test "$cf_cv_$1" = yes ; then
3042         AC_DEFINE(NEED_WCHAR_H)
3043         NEED_WCHAR_H=1
3044 fi
3045
3046 ifelse([$2],,,[
3047 # if we do not find $1 in either place, use substitution to provide a fallback.
3048 if test "$cf_cv_$1" = unknown ; then
3049         $2=1
3050 fi
3051 ])
3052 ifelse($3,,,[
3053 # if we find $1 in either place, use substitution to provide a fallback.
3054 if test "$cf_cv_$1" != unknown ; then
3055         $3=1
3056 fi
3057 ])
3058 ])dnl
3059 dnl ---------------------------------------------------------------------------
3060 dnl CF_WITH_CURSES_DIR version: 3 updated: 2010/11/20 17:02:38
3061 dnl ------------------
3062 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
3063 dnl libraries.
3064 AC_DEFUN([CF_WITH_CURSES_DIR],[
3065
3066 AC_MSG_CHECKING(for specific curses-directory)
3067 AC_ARG_WITH(curses-dir,
3068         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
3069         [cf_cv_curses_dir=$withval],
3070         [cf_cv_curses_dir=no])
3071 AC_MSG_RESULT($cf_cv_curses_dir)
3072
3073 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
3074 then
3075         CF_PATH_SYNTAX(withval)
3076         if test -d "$cf_cv_curses_dir"
3077         then
3078                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
3079                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
3080         fi
3081 fi
3082 ])dnl
3083 dnl ---------------------------------------------------------------------------
3084 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
3085 dnl ----------------
3086 dnl Configure-option for dbmalloc.  The optional parameter is used to override
3087 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
3088 AC_DEFUN([CF_WITH_DBMALLOC],[
3089 CF_NO_LEAKS_OPTION(dbmalloc,
3090         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
3091         [USE_DBMALLOC])
3092
3093 if test "$with_dbmalloc" = yes ; then
3094         AC_CHECK_HEADER(dbmalloc.h,
3095                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
3096 fi
3097 ])dnl
3098 dnl ---------------------------------------------------------------------------
3099 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
3100 dnl ---------------
3101 dnl Configure-option for dmalloc.  The optional parameter is used to override
3102 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
3103 AC_DEFUN([CF_WITH_DMALLOC],[
3104 CF_NO_LEAKS_OPTION(dmalloc,
3105         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
3106         [USE_DMALLOC])
3107
3108 if test "$with_dmalloc" = yes ; then
3109         AC_CHECK_HEADER(dmalloc.h,
3110                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
3111 fi
3112 ])dnl
3113 dnl ---------------------------------------------------------------------------
3114 dnl CF_WITH_NCURSES_ETC version: 2 updated: 2012/01/13 10:49:00
3115 dnl -------------------
3116 dnl Use this macro for programs which use any variant of "curses", e.g.,
3117 dnl "ncurses", and "PDCurses".  Programs that can use curses and some unrelated
3118 dnl library (such as slang) should use a "--with-screen=XXX" option.
3119 dnl
3120 dnl This does not use AC_DEFUN, because that would tell autoconf to run each
3121 dnl of the macros inside this one - before this macro.
3122 define([CF_WITH_NCURSES_ETC],[
3123 CF_WITH_CURSES_DIR
3124
3125 cf_cv_screen=curses
3126
3127 AC_MSG_CHECKING(for specified curses library type)
3128 AC_ARG_WITH(ncursesw,
3129         [  --with-ncursesw         use wide ncurses-libraries],
3130         [cf_cv_screen=ncursesw],[
3131
3132 AC_ARG_WITH(ncurses,
3133         [  --with-ncurses          use ncurses-libraries],
3134         [cf_cv_screen=ncurses],[
3135
3136 AC_ARG_WITH(pdcurses,
3137         [  --with-pdcurses         compile/link with pdcurses X11 library],
3138         [cf_cv_screen=pdcurses],[
3139
3140 AC_ARG_WITH(curses-colr,
3141         [  --with-curses-colr      compile/link with HPUX 10.x color-curses],
3142         [cf_cv_screen=curses_colr],[
3143
3144 AC_ARG_WITH(curses-5lib,
3145         [  --with-curses-5lib      compile/link with SunOS 5lib curses],
3146         [cf_cv_screen=curses_5lib])])])])])
3147
3148 AC_MSG_RESULT($cf_cv_screen)
3149
3150 case $cf_cv_screen in #(vi
3151 curses|curses_*) #(vi
3152         CF_CURSES_CONFIG
3153         ;;
3154 ncurses) #(vi
3155         CF_NCURSES_CONFIG
3156         ;;
3157 ncursesw) #(vi
3158         CF_UTF8_LIB
3159         CF_NCURSES_CONFIG(ncursesw)
3160         ;;
3161 pdcurses)
3162         CF_PDCURSES_X11
3163         ;;
3164 esac
3165
3166 ])dnl
3167 dnl ---------------------------------------------------------------------------
3168 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
3169 dnl ----------------
3170 AC_DEFUN([CF_WITH_VALGRIND],[
3171 CF_NO_LEAKS_OPTION(valgrind,
3172         [  --with-valgrind         test: use valgrind],
3173         [USE_VALGRIND])
3174 ])dnl
3175 dnl ---------------------------------------------------------------------------
3176 dnl CF_XOPEN_CURSES version: 11 updated: 2011/01/18 18:15:30
3177 dnl ---------------
3178 dnl Test if we should define X/Open source for curses, needed on Digital Unix
3179 dnl 4.x, to see the extended functions, but breaks on IRIX 6.x.
3180 dnl
3181 dnl The getbegyx() check is needed for HPUX, which omits legacy macros such
3182 dnl as getbegy().  The latter is better design, but the former is standard.
3183 AC_DEFUN([CF_XOPEN_CURSES],
3184 [
3185 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
3186 AC_CACHE_CHECK(if we must define _XOPEN_SOURCE_EXTENDED,cf_cv_need_xopen_extension,[
3187 AC_TRY_LINK([
3188 #include <stdlib.h>
3189 #include <${cf_cv_ncurses_header:-curses.h}>],[
3190 #if defined(NCURSES_VERSION_PATCH)
3191 #if (NCURSES_VERSION_PATCH < 20100501) && (NCURSES_VERSION_PATCH >= 20100403)
3192         make an error
3193 #endif
3194 #endif
3195         long x = winnstr(stdscr, "", 0);
3196         int x1, y1;
3197         getbegyx(stdscr, y1, x1)],
3198         [cf_cv_need_xopen_extension=no],
3199         [AC_TRY_LINK([
3200 #define _XOPEN_SOURCE_EXTENDED
3201 #include <stdlib.h>
3202 #include <${cf_cv_ncurses_header:-curses.h}>],[
3203 #ifdef NCURSES_VERSION
3204         cchar_t check;
3205         int check2 = curs_set((int)sizeof(check));
3206 #endif
3207         long x = winnstr(stdscr, "", 0);
3208         int x1, y1;
3209         getbegyx(stdscr, y1, x1)],
3210         [cf_cv_need_xopen_extension=yes],
3211         [cf_cv_need_xopen_extension=unknown])])])
3212 test $cf_cv_need_xopen_extension = yes && CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED"
3213 ])dnl
3214 dnl ---------------------------------------------------------------------------
3215 dnl CF_XOPEN_SOURCE version: 42 updated: 2012/01/07 08:26:49
3216 dnl ---------------
3217 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
3218 dnl or adapt to the vendor's definitions to get equivalent functionality,
3219 dnl without losing the common non-POSIX features.
3220 dnl
3221 dnl Parameters:
3222 dnl     $1 is the nominal value for _XOPEN_SOURCE
3223 dnl     $2 is the nominal value for _POSIX_C_SOURCE
3224 AC_DEFUN([CF_XOPEN_SOURCE],[
3225
3226 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
3227 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
3228 cf_xopen_source=
3229
3230 case $host_os in #(vi
3231 aix[[4-7]]*) #(vi
3232         cf_xopen_source="-D_ALL_SOURCE"
3233         ;;
3234 cygwin) #(vi
3235         cf_XOPEN_SOURCE=600
3236         ;;
3237 darwin[[0-8]].*) #(vi
3238         cf_xopen_source="-D_APPLE_C_SOURCE"
3239         ;;
3240 darwin*) #(vi
3241         cf_xopen_source="-D_DARWIN_C_SOURCE"
3242         cf_XOPEN_SOURCE=
3243         ;;
3244 freebsd*|dragonfly*) #(vi
3245         # 5.x headers associate
3246         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
3247         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
3248         cf_POSIX_C_SOURCE=200112L
3249         cf_XOPEN_SOURCE=600
3250         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3251         ;;
3252 hpux11*) #(vi
3253         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
3254         ;;
3255 hpux*) #(vi
3256         cf_xopen_source="-D_HPUX_SOURCE"
3257         ;;
3258 irix[[56]].*) #(vi
3259         cf_xopen_source="-D_SGI_SOURCE"
3260         cf_XOPEN_SOURCE=
3261         ;;
3262 linux*|gnu*|mint*|k*bsd*-gnu) #(vi
3263         CF_GNU_SOURCE
3264         ;;
3265 mirbsd*) #(vi
3266         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
3267         cf_XOPEN_SOURCE=
3268         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3269         ;;
3270 netbsd*) #(vi
3271         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
3272         ;;
3273 openbsd[[4-9]]*) #(vi
3274         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
3275         cf_xopen_source="-D_BSD_SOURCE"
3276         cf_XOPEN_SOURCE=600
3277         ;;
3278 openbsd*) #(vi
3279         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
3280         ;;
3281 osf[[45]]*) #(vi
3282         cf_xopen_source="-D_OSF_SOURCE"
3283         ;;
3284 nto-qnx*) #(vi
3285         cf_xopen_source="-D_QNX_SOURCE"
3286         ;;
3287 sco*) #(vi
3288         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
3289         ;;
3290 solaris2.*) #(vi
3291         cf_xopen_source="-D__EXTENSIONS__"
3292         ;;
3293 *)
3294         CF_TRY_XOPEN_SOURCE
3295         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3296         ;;
3297 esac
3298
3299 if test -n "$cf_xopen_source" ; then
3300         CF_ADD_CFLAGS($cf_xopen_source)
3301 fi
3302
3303 dnl In anything but the default case, we may have system-specific setting
3304 dnl which is still not guaranteed to provide all of the entrypoints that
3305 dnl _XOPEN_SOURCE would yield.
3306 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
3307         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
3308         AC_TRY_COMPILE([#include <stdlib.h>],[
3309 #ifndef _XOPEN_SOURCE
3310 make an error
3311 #endif],
3312         [cf_XOPEN_SOURCE_set=yes],
3313         [cf_XOPEN_SOURCE_set=no])
3314         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
3315         if test $cf_XOPEN_SOURCE_set = yes
3316         then
3317                 AC_TRY_COMPILE([#include <stdlib.h>],[
3318 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
3319 make an error
3320 #endif],
3321                 [cf_XOPEN_SOURCE_set_ok=yes],
3322                 [cf_XOPEN_SOURCE_set_ok=no])
3323                 if test $cf_XOPEN_SOURCE_set_ok = no
3324                 then
3325                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
3326                 fi
3327         else
3328                 CF_TRY_XOPEN_SOURCE
3329         fi
3330 fi
3331 ])
3332 dnl ---------------------------------------------------------------------------
3333 dnl CF_X_ATHENA version: 20 updated: 2010/11/09 05:18:02
3334 dnl -----------
3335 dnl Check for Xaw (Athena) libraries
3336 dnl
3337 dnl Sets $cf_x_athena according to the flavor of Xaw which is used.
3338 AC_DEFUN([CF_X_ATHENA],
3339 [
3340 cf_x_athena=${cf_x_athena:-Xaw}
3341
3342 AC_MSG_CHECKING(if you want to link with Xaw 3d library)
3343 withval=
3344 AC_ARG_WITH(Xaw3d,
3345         [  --with-Xaw3d            link with Xaw 3d library])
3346 if test "$withval" = yes ; then
3347         cf_x_athena=Xaw3d
3348         AC_MSG_RESULT(yes)
3349 else
3350         AC_MSG_RESULT(no)
3351 fi
3352
3353 AC_MSG_CHECKING(if you want to link with neXT Athena library)
3354 withval=
3355 AC_ARG_WITH(neXtaw,
3356         [  --with-neXtaw           link with neXT Athena library])
3357 if test "$withval" = yes ; then
3358         cf_x_athena=neXtaw
3359         AC_MSG_RESULT(yes)
3360 else
3361         AC_MSG_RESULT(no)
3362 fi
3363
3364 AC_MSG_CHECKING(if you want to link with Athena-Plus library)
3365 withval=
3366 AC_ARG_WITH(XawPlus,
3367         [  --with-XawPlus          link with Athena-Plus library])
3368 if test "$withval" = yes ; then
3369         cf_x_athena=XawPlus
3370         AC_MSG_RESULT(yes)
3371 else
3372         AC_MSG_RESULT(no)
3373 fi
3374
3375 cf_x_athena_lib=""
3376
3377 if test "$PKG_CONFIG" != none ; then
3378         cf_athena_list=
3379         test "$cf_x_athena" = Xaw && cf_athena_list="xaw8 xaw7 xaw6"
3380         for cf_athena_pkg in \
3381                 $cf_athena_list \
3382                 ${cf_x_athena} \
3383                 ${cf_x_athena}-devel \
3384                 lib${cf_x_athena} \
3385                 lib${cf_x_athena}-devel
3386         do
3387                 CF_TRY_PKG_CONFIG($cf_athena_pkg,[
3388                         cf_x_athena_lib="$cf_pkgconfig_libs"
3389                         CF_UPPER(cf_x_athena_LIBS,HAVE_LIB_$cf_x_athena)
3390                         AC_DEFINE_UNQUOTED($cf_x_athena_LIBS)
3391
3392 AC_CACHE_CHECK(for usable $cf_x_athena/Xmu package,cf_cv_xaw_compat,[
3393 AC_TRY_LINK([
3394 #include <X11/Xmu/CharSet.h>
3395 ],[
3396 int check = XmuCompareISOLatin1("big", "small")
3397 ],[cf_cv_xaw_compat=yes],[cf_cv_xaw_compat=no])])
3398
3399                         if test "$cf_cv_xaw_compat" = no
3400                         then
3401                                 # workaround for broken ".pc" files...
3402                                 case "$cf_x_athena_lib" in #(vi
3403                                 *-lXmu*) #(vi
3404                                         ;;
3405                                 *)
3406                                         CF_VERBOSE(work around broken package)
3407                                         CF_TRY_PKG_CONFIG(xmu,,[CF_ADD_LIB_AFTER(-lXt,-lXmu)])
3408                                         ;;
3409                                 esac
3410                         fi
3411
3412                         break])
3413         done
3414 fi
3415
3416 if test -z "$cf_x_athena_lib" ; then
3417         CF_X_EXT
3418         CF_X_TOOLKIT
3419         CF_X_ATHENA_CPPFLAGS($cf_x_athena)
3420         CF_X_ATHENA_LIBS($cf_x_athena)
3421 fi
3422 ])dnl
3423 dnl ---------------------------------------------------------------------------
3424 dnl CF_X_ATHENA_CPPFLAGS version: 5 updated: 2010/05/26 17:35:30
3425 dnl --------------------
3426 dnl Normally invoked by CF_X_ATHENA, with $1 set to the appropriate flavor of
3427 dnl the Athena widgets, e.g., Xaw, Xaw3d, neXtaw.
3428 AC_DEFUN([CF_X_ATHENA_CPPFLAGS],
3429 [
3430 cf_x_athena_root=ifelse([$1],,Xaw,[$1])
3431 cf_x_athena_inc=""
3432
3433 for cf_path in default \
3434         /usr/contrib/X11R6 \
3435         /usr/contrib/X11R5 \
3436         /usr/lib/X11R5 \
3437         /usr/local
3438 do
3439         if test -z "$cf_x_athena_inc" ; then
3440                 cf_save="$CPPFLAGS"
3441                 cf_test=X11/$cf_x_athena_root/SimpleMenu.h
3442                 if test $cf_path != default ; then
3443                         CPPFLAGS="$cf_save -I$cf_path/include"
3444                         AC_MSG_CHECKING(for $cf_test in $cf_path)
3445                 else
3446                         AC_MSG_CHECKING(for $cf_test)
3447                 fi
3448                 AC_TRY_COMPILE([
3449 #include <X11/Intrinsic.h>
3450 #include <$cf_test>],[],
3451                         [cf_result=yes],
3452                         [cf_result=no])
3453                 AC_MSG_RESULT($cf_result)
3454                 if test "$cf_result" = yes ; then
3455                         cf_x_athena_inc=$cf_path
3456                         break
3457                 else
3458                         CPPFLAGS="$cf_save"
3459                 fi
3460         fi
3461 done
3462
3463 if test -z "$cf_x_athena_inc" ; then
3464         AC_MSG_WARN(
3465 [Unable to successfully find Athena header files with test program])
3466 elif test "$cf_x_athena_inc" != default ; then
3467         CPPFLAGS="$CPPFLAGS -I$cf_x_athena_inc"
3468 fi
3469 ])
3470 dnl ---------------------------------------------------------------------------
3471 dnl CF_X_ATHENA_LIBS version: 12 updated: 2011/07/17 19:55:02
3472 dnl ----------------
3473 dnl Normally invoked by CF_X_ATHENA, with $1 set to the appropriate flavor of
3474 dnl the Athena widgets, e.g., Xaw, Xaw3d, neXtaw.
3475 AC_DEFUN([CF_X_ATHENA_LIBS],
3476 [AC_REQUIRE([CF_X_TOOLKIT])
3477 cf_x_athena_root=ifelse([$1],,Xaw,[$1])
3478 cf_x_athena_lib=""
3479
3480 for cf_path in default \
3481         /usr/contrib/X11R6 \
3482         /usr/contrib/X11R5 \
3483         /usr/lib/X11R5 \
3484         /usr/local
3485 do
3486         for cf_lib in \
3487                 ${cf_x_athena_root} \
3488                 ${cf_x_athena_root}7 \
3489                 ${cf_x_athena_root}6
3490         do
3491         for cf_libs in \
3492                 "-l$cf_lib -lXmu" \
3493                 "-l$cf_lib -lXpm -lXmu" \
3494                 "-l${cf_lib}_s -lXmu_s"
3495         do
3496                 if test -z "$cf_x_athena_lib" ; then
3497                         cf_save="$LIBS"
3498                         cf_test=XawSimpleMenuAddGlobalActions
3499                         if test $cf_path != default ; then
3500                                 CF_ADD_LIBS(-L$cf_path/lib $cf_libs)
3501                                 AC_MSG_CHECKING(for $cf_libs in $cf_path)
3502                         else
3503                                 CF_ADD_LIBS($cf_libs)
3504                                 AC_MSG_CHECKING(for $cf_test in $cf_libs)
3505                         fi
3506                         AC_TRY_LINK([
3507 #include <X11/Intrinsic.h>
3508 #include <X11/$cf_x_athena_root/SimpleMenu.h>
3509 ],[
3510 $cf_test((XtAppContext) 0)],
3511                                 [cf_result=yes],
3512                                 [cf_result=no])
3513                         AC_MSG_RESULT($cf_result)
3514                         if test "$cf_result" = yes ; then
3515                                 cf_x_athena_lib="$cf_libs"
3516                                 break
3517                         fi
3518                         LIBS="$cf_save"
3519                 fi
3520         done # cf_libs
3521                 test -n "$cf_x_athena_lib" && break
3522         done # cf_lib
3523 done
3524
3525 if test -z "$cf_x_athena_lib" ; then
3526         AC_MSG_ERROR(
3527 [Unable to successfully link Athena library (-l$cf_x_athena_root) with test program])
3528 fi
3529
3530 CF_UPPER(cf_x_athena_LIBS,HAVE_LIB_$cf_x_athena)
3531 AC_DEFINE_UNQUOTED($cf_x_athena_LIBS)
3532 ])
3533 dnl ---------------------------------------------------------------------------
3534 dnl CF_X_EXT version: 3 updated: 2010/06/02 05:03:05
3535 dnl --------
3536 AC_DEFUN([CF_X_EXT],[
3537 CF_TRY_PKG_CONFIG(Xext,,[
3538         AC_CHECK_LIB(Xext,XextCreateExtension,
3539                 [CF_ADD_LIB(Xext)])])
3540 ])dnl
3541 dnl ---------------------------------------------------------------------------
3542 dnl CF_X_TOOLKIT version: 20 updated: 2010/11/19 05:43:04
3543 dnl ------------
3544 dnl Check for X Toolkit libraries
3545 dnl
3546 AC_DEFUN([CF_X_TOOLKIT],
3547 [
3548 AC_REQUIRE([AC_PATH_XTRA])
3549 AC_REQUIRE([CF_CHECK_CACHE])
3550
3551 cf_have_X_LIBS=no
3552
3553 CF_TRY_PKG_CONFIG(xt,[
3554
3555         case "x$LIBS" in #(vi
3556         *-lX11*) #(vi
3557                 ;;
3558         *)
3559 # we have an "xt" package, but it may omit Xt's dependency on X11
3560 AC_CACHE_CHECK(for usable X dependency,cf_cv_xt_x11_compat,[
3561 AC_TRY_LINK([
3562 #include <X11/Xlib.h>
3563 ],[
3564         int rc1 = XDrawLine((Display*) 0, (Drawable) 0, (GC) 0, 0, 0, 0, 0);
3565         int rc2 = XClearWindow((Display*) 0, (Window) 0);
3566         int rc3 = XMoveWindow((Display*) 0, (Window) 0, 0, 0);
3567         int rc4 = XMoveResizeWindow((Display*)0, (Window)0, 0, 0, 0, 0);
3568 ],[cf_cv_xt_x11_compat=yes],[cf_cv_xt_x11_compat=no])])
3569                 if test "$cf_cv_xt_x11_compat" = no
3570                 then
3571                         CF_VERBOSE(work around broken X11 dependency)
3572                         # 2010/11/19 - good enough until a working Xt on Xcb is delivered.
3573                         CF_TRY_PKG_CONFIG(x11,,[CF_ADD_LIB_AFTER(-lXt,-lX11)])
3574                 fi
3575                 ;;
3576         esac
3577
3578 AC_CACHE_CHECK(for usable X Toolkit package,cf_cv_xt_ice_compat,[
3579 AC_TRY_LINK([
3580 #include <X11/Shell.h>
3581 ],[int num = IceConnectionNumber(0)
3582 ],[cf_cv_xt_ice_compat=yes],[cf_cv_xt_ice_compat=no])])
3583
3584         if test "$cf_cv_xt_ice_compat" = no
3585         then
3586                 # workaround for broken ".pc" files used for X Toolkit.
3587                 case "x$X_PRE_LIBS" in #(vi
3588                 *-lICE*)
3589                         case "x$LIBS" in #(vi
3590                         *-lICE*) #(vi
3591                                 ;;
3592                         *)
3593                                 CF_VERBOSE(work around broken ICE dependency)
3594                                 CF_TRY_PKG_CONFIG(ice,
3595                                         [CF_TRY_PKG_CONFIG(sm)],
3596                                         [CF_ADD_LIB_AFTER(-lXt,$X_PRE_LIBS)])
3597                                 ;;
3598                         esac
3599                         ;;
3600                 esac
3601         fi
3602
3603         cf_have_X_LIBS=yes
3604 ],[
3605
3606         LDFLAGS="$X_LIBS $LDFLAGS"
3607         CF_CHECK_CFLAGS($X_CFLAGS)
3608
3609         AC_CHECK_FUNC(XOpenDisplay,,[
3610         AC_CHECK_LIB(X11,XOpenDisplay,
3611                 [CF_ADD_LIB(X11)],,
3612                 [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])])
3613
3614         AC_CHECK_FUNC(XtAppInitialize,,[
3615         AC_CHECK_LIB(Xt, XtAppInitialize,
3616                 [AC_DEFINE(HAVE_LIBXT)
3617                  cf_have_X_LIBS=Xt
3618                  LIBS="-lXt $X_PRE_LIBS $LIBS $X_EXTRA_LIBS"],,
3619                 [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])])
3620 ])
3621
3622 if test $cf_have_X_LIBS = no ; then
3623         AC_MSG_WARN(
3624 [Unable to successfully link X Toolkit library (-lXt) with
3625 test program.  You will have to check and add the proper libraries by hand
3626 to makefile.])
3627 fi
3628 ])dnl
3629 dnl ---------------------------------------------------------------------------
3630 dnl CF__CURSES_HEAD version: 2 updated: 2010/10/23 15:54:49
3631 dnl ---------------
3632 dnl Define a reusable chunk which includes <curses.h> and <term.h> when they
3633 dnl are both available.
3634 define([CF__CURSES_HEAD],[
3635 #ifdef HAVE_XCURSES
3636 #include <xcurses.h>
3637 char * XCursesProgramName = "test";
3638 #else
3639 #include <${cf_cv_ncurses_header:-curses.h}>
3640 #if defined(NCURSES_VERSION) && defined(HAVE_NCURSESW_TERM_H)
3641 #include <ncursesw/term.h>
3642 #elif defined(NCURSES_VERSION) && defined(HAVE_NCURSES_TERM_H)
3643 #include <ncurses/term.h>
3644 #elif defined(HAVE_TERM_H)
3645 #include <term.h>
3646 #endif
3647 #endif
3648 ])