test/aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 2003-2017,2018 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl $Id: aclocal.m4,v 1.155 2018/01/05 01:37:04 tom Exp $
  30 dnl
  31 dnl Author: Thomas E. Dickey
  32 dnl
  33 dnl Macros used in NCURSES test programs auto-configuration script.
  34 dnl
  35 dnl These macros are maintained separately from NCURSES.  The copyright on
  36 dnl this file applies to the aggregation of macros and does not affect use of
  37 dnl these macros in other applications.
  38 dnl
  39 dnl See http://invisible-island.net/autoconf/ for additional information.
  40 dnl
  41 dnl ---------------------------------------------------------------------------
  42 dnl ---------------------------------------------------------------------------
  43 dnl AM_LANGINFO_CODESET version: 4 updated: 2015/04/18 08:56:57
  44 dnl -------------------
  45 dnl Inserted as requested by gettext 0.10.40
  46 dnl File from /usr/share/aclocal
  47 dnl codeset.m4
  48 dnl ====================
  49 dnl serial AM1
  50 dnl
  51 dnl From Bruno Haible.
  52 AC_DEFUN([AM_LANGINFO_CODESET],
  53 [
  54 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  55         [AC_TRY_LINK([#include <langinfo.h>],
  56         [char* cs = nl_langinfo(CODESET);],
  57         am_cv_langinfo_codeset=yes,
  58         am_cv_langinfo_codeset=no)
  59         ])
  60         if test $am_cv_langinfo_codeset = yes; then
  61                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  62                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  63         fi
  64 ])dnl
  65 dnl ---------------------------------------------------------------------------
  66 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
  67 dnl ------------------
  68 dnl Conditionally generate script according to whether we're using a given autoconf.
  69 dnl
  70 dnl $1 = version to compare against
  71 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  72 dnl $3 = code to use if AC_ACVERSION is older than $1.
  73 define([CF_ACVERSION_CHECK],
  74 [
  75 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
  76 ifdef([m4_version_compare],
  77 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  78 [CF_ACVERSION_COMPARE(
  79 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  80 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  81 dnl ---------------------------------------------------------------------------
  82 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
  83 dnl --------------------
  84 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  85 dnl                      MAJOR2, MINOR2, TERNARY2,
  86 dnl                      PRINTABLE2, not FOUND, FOUND)
  87 define([CF_ACVERSION_COMPARE],
  88 [ifelse(builtin([eval], [$2 < $5]), 1,
  89 [ifelse([$8], , ,[$8])],
  90 [ifelse([$9], , ,[$9])])])dnl
  91 dnl ---------------------------------------------------------------------------
  92 dnl CF_ADD_CFLAGS version: 13 updated: 2017/02/25 18:57:40
  93 dnl -------------
  94 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
  95 dnl The second parameter if given makes this macro verbose.
  96 dnl
  97 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
  98 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
  99 dnl confused by the quotes (which require backslashes to keep them usable).
 100 AC_DEFUN([CF_ADD_CFLAGS],
 101 [
 102 cf_fix_cppflags=no
 103 cf_new_cflags=
 104 cf_new_cppflags=
 105 cf_new_extra_cppflags=
 106
 107 for cf_add_cflags in $1
 108 do
 109 case $cf_fix_cppflags in
 110 (no)
 111         case $cf_add_cflags in
 112         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 113                 case $cf_add_cflags in
 114                 (-D*)
 115                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 116
 117                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 118                                 && test -z "${cf_tst_cflags}" \
 119                                 && cf_fix_cppflags=yes
 120
 121                         if test $cf_fix_cppflags = yes ; then
 122                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 123                                 continue
 124                         elif test "${cf_tst_cflags}" = "\"'" ; then
 125                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 126                                 continue
 127                         fi
 128                         ;;
 129                 esac
 130                 case "$CPPFLAGS" in
 131                 (*$cf_add_cflags)
 132                         ;;
 133                 (*)
 134                         case $cf_add_cflags in
 135                         (-D*)
 136                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 137                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 138                                 ;;
 139                         esac
 140                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 141                         ;;
 142                 esac
 143                 ;;
 144         (*)
 145                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 146                 ;;
 147         esac
 148         ;;
 149 (yes)
 150         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 151
 152         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 153
 154         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 155                 && test -z "${cf_tst_cflags}" \
 156                 && cf_fix_cppflags=no
 157         ;;
 158 esac
 159 done
 160
 161 if test -n "$cf_new_cflags" ; then
 162         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 163         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 164 fi
 165
 166 if test -n "$cf_new_cppflags" ; then
 167         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 168         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 169 fi
 170
 171 if test -n "$cf_new_extra_cppflags" ; then
 172         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 173         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 174 fi
 175
 176 AC_SUBST(EXTRA_CPPFLAGS)
 177
 178 ])dnl
 179 dnl ---------------------------------------------------------------------------
 180 dnl CF_ADD_INCDIR version: 14 updated: 2015/05/25 20:53:04
 181 dnl -------------
 182 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 183 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 184 dnl but old versions (and some misinstalled ones) need that.  To make things
 185 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 186 dnl the include-path).
 187 AC_DEFUN([CF_ADD_INCDIR],
 188 [
 189 if test -n "$1" ; then
 190   for cf_add_incdir in $1
 191   do
 192         while test $cf_add_incdir != /usr/include
 193         do
 194           if test -d $cf_add_incdir
 195           then
 196                 cf_have_incdir=no
 197                 if test -n "$CFLAGS$CPPFLAGS" ; then
 198                   # a loop is needed to ensure we can add subdirs of existing dirs
 199                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 200                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 201                           cf_have_incdir=yes; break
 202                         fi
 203                   done
 204                 fi
 205
 206                 if test "$cf_have_incdir" = no ; then
 207                   if test "$cf_add_incdir" = /usr/local/include ; then
 208                         if test "$GCC" = yes
 209                         then
 210                           cf_save_CPPFLAGS=$CPPFLAGS
 211                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 212                           AC_TRY_COMPILE([#include <stdio.h>],
 213                                   [printf("Hello")],
 214                                   [],
 215                                   [cf_have_incdir=yes])
 216                           CPPFLAGS=$cf_save_CPPFLAGS
 217                         fi
 218                   fi
 219                 fi
 220
 221                 if test "$cf_have_incdir" = no ; then
 222                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 223                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 224
 225                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 226                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 227                   cf_add_incdir="$cf_top_incdir"
 228                 else
 229                   break
 230                 fi
 231           else
 232                 break
 233           fi
 234         done
 235   done
 236 fi
 237 ])dnl
 238 dnl ---------------------------------------------------------------------------
 239 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 240 dnl ----------
 241 dnl Add a library, used to enforce consistency.
 242 dnl
 243 dnl $1 = library to add, without the "-l"
 244 dnl $2 = variable to update (default $LIBS)
 245 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 246 dnl ---------------------------------------------------------------------------
 247 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 248 dnl -------------
 249 dnl     Adds to the library-path
 250 dnl
 251 dnl     Some machines have trouble with multiple -L options.
 252 dnl
 253 dnl $1 is the (list of) directory(s) to add
 254 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 255 dnl
 256 AC_DEFUN([CF_ADD_LIBDIR],
 257 [
 258 if test -n "$1" ; then
 259         for cf_add_libdir in $1
 260         do
 261                 if test $cf_add_libdir = /usr/lib ; then
 262                         :
 263                 elif test -d $cf_add_libdir
 264                 then
 265                         cf_have_libdir=no
 266                         if test -n "$LDFLAGS$LIBS" ; then
 267                                 # a loop is needed to ensure we can add subdirs of existing dirs
 268                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 269                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 270                                                 cf_have_libdir=yes; break
 271                                         fi
 272                                 done
 273                         fi
 274                         if test "$cf_have_libdir" = no ; then
 275                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 276                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 277                         fi
 278                 fi
 279         done
 280 fi
 281 ])dnl
 282 dnl ---------------------------------------------------------------------------
 283 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
 284 dnl -----------
 285 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 286 dnl prepended to an existing list, since their dependencies are assumed to
 287 dnl already exist in the list.
 288 dnl
 289 dnl $1 = libraries to add, with the "-l", etc.
 290 dnl $2 = variable to update (default $LIBS)
 291 AC_DEFUN([CF_ADD_LIBS],[
 292 cf_add_libs="$1"
 293 # Filter out duplicates - this happens with badly-designed ".pc" files...
 294 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
 295 do
 296         for cf_add_2lib in $cf_add_libs
 297         do
 298                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
 299                 then
 300                         cf_add_1lib=
 301                         break
 302                 fi
 303         done
 304         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
 305 done
 306 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 307 ])dnl
 308 dnl ---------------------------------------------------------------------------
 309 dnl CF_ADD_LIB_AFTER version: 3 updated: 2013/07/09 21:27:22
 310 dnl ----------------
 311 dnl Add a given library after another, e.g., following the one it satisfies a
 312 dnl dependency for.
 313 dnl
 314 dnl $1 = the first library
 315 dnl $2 = its dependency
 316 AC_DEFUN([CF_ADD_LIB_AFTER],[
 317 CF_VERBOSE(...before $LIBS)
 318 LIBS=`echo "$LIBS" | sed -e "s/[[       ]][[    ]]*/ /g" -e "s%$1 %$1 $2 %" -e 's%  % %g'`
 319 CF_VERBOSE(...after  $LIBS)
 320 ])dnl
 321 dnl ---------------------------------------------------------------------------
 322 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 323 dnl ------------------
 324 dnl Append to a search-list for a nonstandard header/lib-file
 325 dnl     $1 = the variable to return as result
 326 dnl     $2 = the package name
 327 dnl     $3 = the subdirectory, e.g., bin, include or lib
 328 dnl $4 = the directory under which we will test for subdirectories
 329 dnl $5 = a directory that we do not want $4 to match
 330 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 331 [
 332 test "x$4" != "x$5" && \
 333 test -d "$4" && \
 334 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 335         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 336         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 337         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 338         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 339         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 340         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 341 }
 342 ])dnl
 343 dnl ---------------------------------------------------------------------------
 344 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 345 dnl --------------
 346 dnl use this macro for appending text without introducing an extra blank at
 347 dnl the beginning
 348 define([CF_APPEND_TEXT],
 349 [
 350         test -n "[$]$1" && $1="[$]$1 "
 351         $1="[$]{$1}$2"
 352 ])dnl
 353 dnl ---------------------------------------------------------------------------
 354 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 355 dnl --------------
 356 dnl Allow user to disable a normally-on option.
 357 AC_DEFUN([CF_ARG_DISABLE],
 358 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 359 dnl ---------------------------------------------------------------------------
 360 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 361 dnl -------------
 362 dnl Allow user to enable a normally-off option.
 363 AC_DEFUN([CF_ARG_ENABLE],
 364 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 365 dnl ---------------------------------------------------------------------------
 366 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 367 dnl -------------
 368 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 369 dnl values.
 370 dnl
 371 dnl Parameters:
 372 dnl $1 = option name
 373 dnl $2 = help-string
 374 dnl $3 = action to perform if option is not default
 375 dnl $4 = action if perform if option is default
 376 dnl $5 = default option value (either 'yes' or 'no')
 377 AC_DEFUN([CF_ARG_OPTION],
 378 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 379         if test "$enableval" != "$5" ; then
 380 ifelse([$3],,[    :]dnl
 381 ,[    $3]) ifelse([$4],,,[
 382         else
 383                 $4])
 384         fi],[enableval=$5 ifelse([$4],,,[
 385         $4
 386 ])dnl
 387 ])])dnl
 388 dnl ---------------------------------------------------------------------------
 389 dnl CF_CC_ENV_FLAGS version: 8 updated: 2017/09/23 08:50:24
 390 dnl ---------------
 391 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 392 dnl into CC.  This will not help with broken scripts that wrap the compiler
 393 dnl with options, but eliminates a more common category of user confusion.
 394 dnl
 395 dnl In particular, it addresses the problem of being able to run the C
 396 dnl preprocessor in a consistent manner.
 397 dnl
 398 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 399 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 400 dnl outweighs that limitation.
 401 AC_DEFUN([CF_CC_ENV_FLAGS],
 402 [
 403 # This should have been defined by AC_PROG_CC
 404 : ${CC:=cc}
 405
 406 AC_MSG_CHECKING(\$CC variable)
 407 case "$CC" in
 408 (*[[\ \ ]]-*)
 409         AC_MSG_RESULT(broken)
 410         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 411         # humor him...
 412         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 413         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
 414         CC="$cf_prog"
 415         for cf_arg in $cf_flags
 416         do
 417                 case "x$cf_arg" in
 418                 (x-[[IUDfgOW]]*)
 419                         CF_ADD_CFLAGS($cf_arg)
 420                         ;;
 421                 (*)
 422                         CC="$CC $cf_arg"
 423                         ;;
 424                 esac
 425         done
 426         CF_VERBOSE(resulting CC: '$CC')
 427         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 428         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 429         ;;
 430 (*)
 431         AC_MSG_RESULT(ok)
 432         ;;
 433 esac
 434 ])dnl
 435 dnl ---------------------------------------------------------------------------
 436 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 437 dnl --------------
 438 dnl Check if we're accidentally using a cache from a different machine.
 439 dnl Derive the system name, as a check for reusing the autoconf cache.
 440 dnl
 441 dnl If we've packaged config.guess and config.sub, run that (since it does a
 442 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 443 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 444 dnl which is useful in cross-compiles.
 445 dnl
 446 dnl Note: we would use $ac_config_sub, but that is one of the places where
 447 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 448 AC_DEFUN([CF_CHECK_CACHE],
 449 [
 450 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 451         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 452         system_name="$host_os"
 453 else
 454         system_name="`(uname -s -r) 2>/dev/null`"
 455         if test -z "$system_name" ; then
 456                 system_name="`(hostname) 2>/dev/null`"
 457         fi
 458 fi
 459 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 460 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 461
 462 test -z "$system_name" && system_name="$cf_cv_system_name"
 463 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 464
 465 if test ".$system_name" != ".$cf_cv_system_name" ; then
 466         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 467         AC_MSG_ERROR("Please remove config.cache and try again.")
 468 fi
 469 ])dnl
 470 dnl ---------------------------------------------------------------------------
 471 dnl CF_CHECK_CFLAGS version: 3 updated: 2014/07/22 05:32:57
 472 dnl ---------------
 473 dnl Conditionally add to $CFLAGS and $CPPFLAGS values which are derived from
 474 dnl a build-configuration such as imake.  These have the pitfall that they
 475 dnl often contain compiler-specific options which we cannot use, mixed with
 476 dnl preprocessor options that we usually can.
 477 AC_DEFUN([CF_CHECK_CFLAGS],
 478 [
 479 CF_VERBOSE(checking additions to CFLAGS)
 480 cf_check_cflags="$CFLAGS"
 481 cf_check_cppflags="$CPPFLAGS"
 482 CF_ADD_CFLAGS($1,yes)
 483 if test "x$cf_check_cflags" != "x$CFLAGS" ; then
 484 AC_TRY_LINK([#include <stdio.h>],[printf("Hello world");],,
 485         [CF_VERBOSE(test-compile failed.  Undoing change to \$CFLAGS)
 486          if test "x$cf_check_cppflags" != "x$CPPFLAGS" ; then
 487                  CF_VERBOSE(but keeping change to \$CPPFLAGS)
 488          fi
 489          CFLAGS="$cf_check_flags"])
 490 fi
 491 ])dnl
 492 dnl ---------------------------------------------------------------------------
 493 dnl CF_CHECK_CURSES_LIB version: 2 updated: 2018/01/03 04:47:33
 494 dnl -------------------
 495 dnl $1 = nominal library name, used also for header lookup
 496 dnl $2 = suffix to append to library name
 497 dnl $3 = function to check for using AC_CHECK_LIB
 498 dnl $4 = optional parameter list for $3
 499 AC_DEFUN([CF_CHECK_CURSES_LIB],
 500 [
 501 AC_REQUIRE([CF_PKG_CONFIG])
 502
 503 cf_have_curses_lib=no
 504
 505 : ${NCURSES_CONFIG_PKG:=none}
 506 if test "x${NCURSES_CONFIG_PKG}" = xnone; then
 507         :
 508 elif test "x${PKG_CONFIG:=none}" != xnone; then
 509         AC_MSG_CHECKING(pkg-config for $1$2)
 510         if "$PKG_CONFIG" --exists $1$2 ; then
 511                 AC_MSG_RESULT(yes)
 512
 513                 AC_MSG_CHECKING(if the $1$2 package files work)
 514
 515                 cf_save_CPPFLAGS="$CPPFLAGS"
 516                 cf_save_LIBS="$LIBS"
 517
 518                 CF_ADD_CFLAGS(`$PKG_CONFIG --cflags $1$2`)
 519                 CF_ADD_LIBS(`$PKG_CONFIG --libs $1$2`)
 520
 521                 AC_TRY_LINK([#include <$1.h>],
 522                         [(void) $3 ( ]ifelse([$4],,,[[$4]])[ );],
 523                         [AC_TRY_RUN([#include <$1.h>
 524                                 int main(void)
 525                                 { (void) $3 ( ]ifelse([$4],,,[[$4]])[ ); return 0; }],
 526                                 [cf_have_curses_lib=yes],
 527                                 [cf_have_curses_lib=no],
 528                                 [cf_have_curses_lib=maybe])],
 529                         [cf_have_curses_lib=no])
 530                 AC_MSG_RESULT($cf_have_curses_lib)
 531                 test "$cf_have_curses_lib" = maybe && cf_have_curses_lib=yes
 532                 if test "$cf_have_curses_lib" != "yes"
 533                 then
 534                         CPPFLAGS="$cf_save_CPPFLAGS"
 535                         LIBS="$cf_save_LIBS"
 536                 else
 537                         CF_UPPER(cf_upper,have_lib$1)
 538                         AC_DEFINE_UNQUOTED($cf_upper,1)
 539                 fi
 540         fi
 541 fi
 542 if test "$cf_have_curses_lib" = no; then
 543         AC_CHECK_LIB($1$2,$3,[
 544                 CF_UPPER(cf_upper,have_lib$1)
 545                 CF_ADD_LIBS(-l$1$2)
 546                 AC_DEFINE_UNQUOTED($cf_upper,1)])
 547 fi
 548 ])dnl
 549 dnl ---------------------------------------------------------------------------
 550 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
 551 dnl -----------------
 552 dnl Check if the given compiler is really clang.  clang's C driver defines
 553 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
 554 dnl not ignore some gcc options.
 555 dnl
 556 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
 557 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
 558 dnl the wrappers for gcc and g++ warnings.
 559 dnl
 560 dnl $1 = GCC (default) or GXX
 561 dnl $2 = CLANG_COMPILER (default)
 562 dnl $3 = CFLAGS (default) or CXXFLAGS
 563 AC_DEFUN([CF_CLANG_COMPILER],[
 564 ifelse([$2],,CLANG_COMPILER,[$2])=no
 565
 566 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
 567         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
 568         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
 569         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
 570         AC_TRY_COMPILE([],[
 571 #ifdef __clang__
 572 #else
 573 make an error
 574 #endif
 575 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
 576 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
 577 ],[])
 578         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
 579         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
 580 fi
 581 ])
 582 dnl ---------------------------------------------------------------------------
 583 dnl CF_CURSES_ACS_MAP version: 7 updated: 2012/10/06 16:39:58
 584 dnl -----------------
 585 dnl Check for likely values of acs_map[]:
 586 AC_DEFUN([CF_CURSES_ACS_MAP],
 587 [
 588 AC_REQUIRE([CF_NCURSES_WRAP_PREFIX])dnl
 589 AC_CACHE_CHECK(for alternate character set array, cf_cv_curses_acs_map,[
 590 cf_cv_curses_acs_map=unknown
 591 for name in acs_map _acs_map __acs_map ${NCURSES_WRAP_PREFIX}acs_map
 592 do
 593 AC_TRY_LINK([
 594 #include <${cf_cv_ncurses_header:-curses.h}>
 595 ],[
 596 $name['k'] = ACS_PLUS
 597 ],[cf_cv_curses_acs_map=$name; break])
 598 done
 599 ])
 600
 601 test "$cf_cv_curses_acs_map" != unknown && AC_DEFINE_UNQUOTED(CURSES_ACS_ARRAY,$cf_cv_curses_acs_map,[Define as needed to override ncurses prefix _nc_])
 602 ])
 603 dnl ---------------------------------------------------------------------------
 604 dnl CF_CURSES_CHECK_DATA version: 7 updated: 2018/01/03 04:47:33
 605 dnl --------------------
 606 dnl Check if curses.h defines the given data/variable.
 607 dnl Use this after CF_NCURSES_CONFIG or CF_CURSES_CONFIG.
 608 dnl
 609 dnl $1 = data item(s) to check for
 610 dnl $2 = action on success, e.g., "break" to quit checking a series of choices
 611 AC_DEFUN([CF_CURSES_CHECK_DATA],
 612 [
 613 for cf_data in $1
 614 do
 615 AC_MSG_CHECKING(for data $cf_data declaration in ${cf_cv_ncurses_header:-curses.h})
 616
 617 AC_TRY_COMPILE(CF__CURSES_HEAD,[
 618 void *foo = &($cf_data)
 619 ],[cf_result=yes
 620 ],[cf_result=no])
 621 AC_MSG_RESULT($cf_result)
 622
 623 if test $cf_result = yes ; then
 624         CF_UPPER(cf_result,have_curses_data_$cf_data)
 625         AC_DEFINE_UNQUOTED($cf_result)
 626         ifelse($2,,,[$2])
 627 else
 628         AC_MSG_CHECKING(for data $cf_data in library)
 629         # BSD linkers insist on making weak linkage, but resolve at runtime.
 630         AC_TRY_RUN(CF__CURSES_HEAD
 631 [
 632 extern char $cf_data;
 633 int main(void)
 634 {
 635         void *foo = &($cf_data);
 636         fprintf(stderr, "testing linkage of $cf_data:%p\n", (void *)foo);
 637         ${cf_cv_main_return:-return}(foo == 0);
 638 }],[cf_result=yes
 639 ],[cf_result=no],[
 640         # cross-compiling
 641         AC_TRY_LINK(CF__CURSES_HEAD
 642 [extern char $cf_data;],[
 643         do {
 644                 void *foo = &($cf_data);
 645                 fprintf(stderr, "testing linkage of $cf_data:%p\n", (void *)foo);
 646                 ${cf_cv_main_return:-return}(foo == 0);
 647         } while (0)
 648 ],[cf_result=yes],[cf_result=no])
 649 ])
 650         AC_MSG_RESULT($cf_result)
 651         if test $cf_result = yes ; then
 652                 CF_UPPER(cf_result,decl_curses_data_$cf_data)
 653                 AC_DEFINE_UNQUOTED($cf_result)
 654                 # do not exit loop here, since we prefer system's declarations
 655         fi
 656 fi
 657 done
 658 ])dnl
 659 dnl ---------------------------------------------------------------------------
 660 dnl CF_CURSES_CHECK_TYPE version: 4 updated: 2012/10/06 16:39:58
 661 dnl --------------------
 662 dnl Check if curses.h defines the given type
 663 AC_DEFUN([CF_CURSES_CHECK_TYPE],
 664 [
 665 AC_MSG_CHECKING(for type $1 in ${cf_cv_ncurses_header:-curses.h})
 666 AC_TRY_COMPILE([
 667 #ifndef _XOPEN_SOURCE_EXTENDED
 668 #define _XOPEN_SOURCE_EXTENDED
 669 #endif
 670 #include <${cf_cv_ncurses_header:-curses.h}>],[
 671 $1 foo
 672 ],cf_result=yes,cf_result=no)
 673 AC_MSG_RESULT($cf_result)
 674 if test $cf_result = yes ; then
 675         CF_UPPER(cf_result,have_type_$1)
 676         AC_DEFINE_UNQUOTED($cf_result,1,[Define to 1 if we have type $1])
 677 else
 678         AC_DEFINE_UNQUOTED($1,$2,[Define to appropriate type if $1 is not declared])
 679 fi
 680 ])dnl
 681 dnl ---------------------------------------------------------------------------
 682 dnl CF_CURSES_CONFIG version: 2 updated: 2006/10/29 11:06:27
 683 dnl ----------------
 684 dnl Tie together the configure-script macros for curses.  It may be ncurses,
 685 dnl but unless asked, we do not make a special search for ncurses.  However,
 686 dnl still check for the ncurses version number, for use in other macros.
 687 AC_DEFUN([CF_CURSES_CONFIG],
 688 [
 689 CF_CURSES_CPPFLAGS
 690 CF_NCURSES_VERSION
 691 CF_CURSES_LIBS
 692 ])dnl
 693 dnl ---------------------------------------------------------------------------
 694 dnl CF_CURSES_CPPFLAGS version: 12 updated: 2015/04/15 19:08:48
 695 dnl ------------------
 696 dnl Look for the curses headers.
 697 AC_DEFUN([CF_CURSES_CPPFLAGS],[
 698
 699 AC_CACHE_CHECK(for extra include directories,cf_cv_curses_incdir,[
 700 cf_cv_curses_incdir=no
 701 case $host_os in
 702 (hpux10.*)
 703         if test "x$cf_cv_screen" = "xcurses_colr"
 704         then
 705                 test -d /usr/include/curses_colr && \
 706                 cf_cv_curses_incdir="-I/usr/include/curses_colr"
 707         fi
 708         ;;
 709 (sunos3*|sunos4*)
 710         if test "x$cf_cv_screen" = "xcurses_5lib"
 711         then
 712                 test -d /usr/5lib && \
 713                 test -d /usr/5include && \
 714                 cf_cv_curses_incdir="-I/usr/5include"
 715         fi
 716         ;;
 717 esac
 718 ])
 719 test "$cf_cv_curses_incdir" != no && CPPFLAGS="$CPPFLAGS $cf_cv_curses_incdir"
 720
 721 CF_CURSES_HEADER
 722 CF_TERM_HEADER
 723 ])dnl
 724 dnl ---------------------------------------------------------------------------
 725 dnl CF_CURSES_FUNCS version: 19 updated: 2018/01/03 04:47:33
 726 dnl ---------------
 727 dnl Curses-functions are a little complicated, since a lot of them are macros.
 728 AC_DEFUN([CF_CURSES_FUNCS],
 729 [
 730 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
 731 AC_REQUIRE([CF_XOPEN_CURSES])
 732 AC_REQUIRE([CF_CURSES_TERM_H])
 733 AC_REQUIRE([CF_CURSES_UNCTRL_H])
 734 for cf_func in $1
 735 do
 736         CF_UPPER(cf_tr_func,$cf_func)
 737         AC_MSG_CHECKING(for ${cf_func})
 738         CF_MSG_LOG(${cf_func})
 739         AC_CACHE_VAL(cf_cv_func_$cf_func,[
 740                 eval cf_result='$ac_cv_func_'$cf_func
 741                 if test ".$cf_result" != ".no"; then
 742                         AC_TRY_LINK(CF__CURSES_HEAD,
 743                         [
 744 #ifndef ${cf_func}
 745 long foo = (long)(&${cf_func});
 746 fprintf(stderr, "testing linkage of $cf_func:%p\n", (void *)foo);
 747 if (foo + 1234L > 5678L)
 748         ${cf_cv_main_return:-return}(foo != 0);
 749 #endif
 750                         ],
 751                         [cf_result=yes],
 752                         [cf_result=no])
 753                 fi
 754                 eval 'cf_cv_func_'$cf_func'=$cf_result'
 755         ])
 756         # use the computed/retrieved cache-value:
 757         eval 'cf_result=$cf_cv_func_'$cf_func
 758         AC_MSG_RESULT($cf_result)
 759         if test $cf_result != no; then
 760                 AC_DEFINE_UNQUOTED(HAVE_${cf_tr_func})
 761         fi
 762 done
 763 ])dnl
 764 dnl ---------------------------------------------------------------------------
 765 dnl CF_CURSES_HEADER version: 5 updated: 2015/04/23 20:35:30
 766 dnl ----------------
 767 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
 768 dnl variations of ncurses' installs.
 769 dnl
 770 dnl $1 = ncurses when looking for ncurses, or is empty
 771 AC_DEFUN([CF_CURSES_HEADER],[
 772 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
 773 cf_cv_ncurses_header=none
 774 for cf_header in \
 775         ncurses.h ifelse($1,,,[$1/ncurses.h]) \
 776         curses.h ifelse($1,,,[$1/curses.h]) ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
 777 do
 778 AC_TRY_COMPILE([#include <${cf_header}>],
 779         [initscr(); tgoto("?", 0,0)],
 780         [cf_cv_ncurses_header=$cf_header; break],[])
 781 done
 782 ])
 783
 784 if test "$cf_cv_ncurses_header" = none ; then
 785         AC_MSG_ERROR(No curses header-files found)
 786 fi
 787
 788 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
 789 AC_CHECK_HEADERS($cf_cv_ncurses_header)
 790 ])dnl
 791 dnl ---------------------------------------------------------------------------
 792 dnl CF_CURSES_LIBS version: 41 updated: 2017/12/31 19:23:43
 793 dnl --------------
 794 dnl Look for the curses libraries.  Older curses implementations may require
 795 dnl termcap/termlib to be linked as well.  Call CF_CURSES_CPPFLAGS first.
 796 AC_DEFUN([CF_CURSES_LIBS],[
 797
 798 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
 799 AC_MSG_CHECKING(if we have identified curses libraries)
 800 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
 801         [initscr(); tgoto("?", 0,0)],
 802         cf_result=yes,
 803         cf_result=no)
 804 AC_MSG_RESULT($cf_result)
 805
 806 if test "$cf_result" = no ; then
 807 case $host_os in
 808 (freebsd*)
 809         AC_CHECK_LIB(mytinfo,tgoto,[CF_ADD_LIBS(-lmytinfo)])
 810         ;;
 811 (hpux10.*)
 812         # Looking at HPUX 10.20, the Hcurses library is the oldest (1997), cur_colr
 813         # next (1998), and xcurses "newer" (2000).  There is no header file for
 814         # Hcurses; the subdirectory curses_colr has the headers (curses.h and
 815         # term.h) for cur_colr
 816         if test "x$cf_cv_screen" = "xcurses_colr"
 817         then
 818                 AC_CHECK_LIB(cur_colr,initscr,[
 819                         CF_ADD_LIBS(-lcur_colr)
 820                         ac_cv_func_initscr=yes
 821                         ],[
 822                 AC_CHECK_LIB(Hcurses,initscr,[
 823                         # HP's header uses __HP_CURSES, but user claims _HP_CURSES.
 824                         CF_ADD_LIBS(-lHcurses)
 825                         CPPFLAGS="$CPPFLAGS -D__HP_CURSES -D_HP_CURSES"
 826                         ac_cv_func_initscr=yes
 827                         ])])
 828         fi
 829         ;;
 830 (linux*)
 831         case `arch 2>/dev/null` in
 832         (x86_64)
 833                 if test -d /lib64
 834                 then
 835                         CF_ADD_LIBDIR(/lib64)
 836                 else
 837                         CF_ADD_LIBDIR(/lib)
 838                 fi
 839                 ;;
 840         (*)
 841                 CF_ADD_LIBDIR(/lib)
 842                 ;;
 843         esac
 844         ;;
 845 (sunos3*|sunos4*)
 846         if test "x$cf_cv_screen" = "xcurses_5lib"
 847         then
 848                 if test -d /usr/5lib ; then
 849                         CF_ADD_LIBDIR(/usr/5lib)
 850                         CF_ADD_LIBS(-lcurses -ltermcap)
 851                 fi
 852         fi
 853         ac_cv_func_initscr=yes
 854         ;;
 855 esac
 856
 857 if test ".$ac_cv_func_initscr" != .yes ; then
 858         cf_save_LIBS="$LIBS"
 859
 860         if test ".${cf_cv_ncurses_version:-no}" != .no
 861         then
 862                 cf_check_list="ncurses curses cursesX"
 863         else
 864                 cf_check_list="cursesX curses ncurses"
 865         fi
 866
 867         # Check for library containing tgoto.  Do this before curses library
 868         # because it may be needed to link the test-case for initscr.
 869         if test "x$cf_term_lib" = x
 870         then
 871                 AC_CHECK_FUNC(tgoto,[cf_term_lib=predefined],[
 872                         for cf_term_lib in $cf_check_list otermcap termcap tinfo termlib unknown
 873                         do
 874                                 AC_CHECK_LIB($cf_term_lib,tgoto,[
 875                                         : ${cf_nculib_root:=$cf_term_lib}
 876                                         break
 877                                 ])
 878                         done
 879                 ])
 880         fi
 881
 882         # Check for library containing initscr
 883         test "$cf_term_lib" != predefined && test "$cf_term_lib" != unknown && LIBS="-l$cf_term_lib $cf_save_LIBS"
 884         if test "x$cf_curs_lib" = x
 885         then
 886                 for cf_curs_lib in $cf_check_list xcurses jcurses pdcurses unknown
 887                 do
 888                         LIBS="-l$cf_curs_lib $cf_save_LIBS"
 889                         if test "$cf_term_lib" = unknown || test "$cf_term_lib" = "$cf_curs_lib" ; then
 890                                 AC_MSG_CHECKING(if we can link with $cf_curs_lib library)
 891                                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
 892                                         [initscr()],
 893                                         [cf_result=yes],
 894                                         [cf_result=no])
 895                                 AC_MSG_RESULT($cf_result)
 896                                 test $cf_result = yes && break
 897                         elif test "$cf_curs_lib" = "$cf_term_lib" ; then
 898                                 cf_result=no
 899                         elif test "$cf_term_lib" != predefined ; then
 900                                 AC_MSG_CHECKING(if we need both $cf_curs_lib and $cf_term_lib libraries)
 901                                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
 902                                         [initscr(); tgoto((char *)0, 0, 0);],
 903                                         [cf_result=no],
 904                                         [
 905                                         LIBS="-l$cf_curs_lib -l$cf_term_lib $cf_save_LIBS"
 906                                         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
 907                                                 [initscr()],
 908                                                 [cf_result=yes],
 909                                                 [cf_result=error])
 910                                         ])
 911                                 AC_MSG_RESULT($cf_result)
 912                                 test $cf_result != error && break
 913                         fi
 914                 done
 915         fi
 916         test $cf_curs_lib = unknown && AC_MSG_ERROR(no curses library found)
 917 fi
 918 fi
 919
 920 ])dnl
 921 dnl ---------------------------------------------------------------------------
 922 dnl CF_CURSES_TERM_H version: 11 updated: 2015/04/15 19:08:48
 923 dnl ----------------
 924 dnl SVr4 curses should have term.h as well (where it puts the definitions of
 925 dnl the low-level interface).  This may not be true in old/broken implementations,
 926 dnl as well as in misconfigured systems (e.g., gcc configured for Solaris 2.4
 927 dnl running with Solaris 2.5.1).
 928 AC_DEFUN([CF_CURSES_TERM_H],
 929 [
 930 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
 931
 932 AC_CACHE_CHECK(for term.h, cf_cv_term_header,[
 933
 934 # If we found <ncurses/curses.h>, look for <ncurses/term.h>, but always look
 935 # for <term.h> if we do not find the variant.
 936
 937 cf_header_list="term.h ncurses/term.h ncursesw/term.h"
 938
 939 case ${cf_cv_ncurses_header:-curses.h} in
 940 (*/*)
 941         cf_header_item=`echo ${cf_cv_ncurses_header:-curses.h} | sed -e 's%\..*%%' -e 's%/.*%/%'`term.h
 942         cf_header_list="$cf_header_item $cf_header_list"
 943         ;;
 944 esac
 945
 946 for cf_header in $cf_header_list
 947 do
 948         AC_TRY_COMPILE([
 949 #include <${cf_cv_ncurses_header:-curses.h}>
 950 #include <${cf_header}>],
 951         [WINDOW *x],
 952         [cf_cv_term_header=$cf_header
 953          break],
 954         [cf_cv_term_header=no])
 955 done
 956
 957 case $cf_cv_term_header in
 958 (no)
 959         # If curses is ncurses, some packagers still mess it up by trying to make
 960         # us use GNU termcap.  This handles the most common case.
 961         for cf_header in ncurses/term.h ncursesw/term.h
 962         do
 963                 AC_TRY_COMPILE([
 964 #include <${cf_cv_ncurses_header:-curses.h}>
 965 #ifdef NCURSES_VERSION
 966 #include <${cf_header}>
 967 #else
 968 make an error
 969 #endif],
 970                         [WINDOW *x],
 971                         [cf_cv_term_header=$cf_header
 972                          break],
 973                         [cf_cv_term_header=no])
 974         done
 975         ;;
 976 esac
 977 ])
 978
 979 case $cf_cv_term_header in
 980 (term.h)
 981         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
 982         ;;
 983 (ncurses/term.h)
 984         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
 985         ;;
 986 (ncursesw/term.h)
 987         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
 988         ;;
 989 esac
 990 ])dnl
 991 dnl ---------------------------------------------------------------------------
 992 dnl CF_CURSES_UNCTRL_H version: 4 updated: 2015/04/15 19:08:48
 993 dnl ------------------
 994 dnl Any X/Open curses implementation must have unctrl.h, but ncurses packages
 995 dnl may put it in a subdirectory (along with ncurses' other headers, of
 996 dnl course).  Packages which put the headers in inconsistent locations are
 997 dnl broken).
 998 AC_DEFUN([CF_CURSES_UNCTRL_H],
 999 [
1000 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
1001
1002 AC_CACHE_CHECK(for unctrl.h, cf_cv_unctrl_header,[
1003
1004 # If we found <ncurses/curses.h>, look for <ncurses/unctrl.h>, but always look
1005 # for <unctrl.h> if we do not find the variant.
1006
1007 cf_header_list="unctrl.h ncurses/unctrl.h ncursesw/unctrl.h"
1008
1009 case ${cf_cv_ncurses_header:-curses.h} in
1010 (*/*)
1011         cf_header_item=`echo ${cf_cv_ncurses_header:-curses.h} | sed -e 's%\..*%%' -e 's%/.*%/%'`unctrl.h
1012         cf_header_list="$cf_header_item $cf_header_list"
1013         ;;
1014 esac
1015
1016 for cf_header in $cf_header_list
1017 do
1018         AC_TRY_COMPILE([
1019 #include <${cf_cv_ncurses_header:-curses.h}>
1020 #include <${cf_header}>],
1021         [WINDOW *x],
1022         [cf_cv_unctrl_header=$cf_header
1023          break],
1024         [cf_cv_unctrl_header=no])
1025 done
1026 ])
1027
1028 case $cf_cv_unctrl_header in
1029 (no)
1030         AC_MSG_WARN(unctrl.h header not found)
1031         ;;
1032 esac
1033
1034 case $cf_cv_unctrl_header in
1035 (unctrl.h)
1036         AC_DEFINE(HAVE_UNCTRL_H,1,[Define to 1 if we have unctrl.h])
1037         ;;
1038 (ncurses/unctrl.h)
1039         AC_DEFINE(HAVE_NCURSES_UNCTRL_H,1,[Define to 1 if we have ncurses/unctrl.h])
1040         ;;
1041 (ncursesw/unctrl.h)
1042         AC_DEFINE(HAVE_NCURSESW_UNCTRL_H,1,[Define to 1 if we have ncursesw/unctrl.h])
1043         ;;
1044 esac
1045 ])dnl
1046 dnl ---------------------------------------------------------------------------
1047 dnl CF_CURSES_WACS_MAP version: 6 updated: 2012/10/06 08:57:51
1048 dnl ------------------
1049 dnl Check for likely values of wacs_map[].
1050 AC_DEFUN([CF_CURSES_WACS_MAP],
1051 [
1052 AC_CACHE_CHECK(for wide alternate character set array, cf_cv_curses_wacs_map,[
1053         cf_cv_curses_wacs_map=unknown
1054         for name in wacs_map _wacs_map __wacs_map _nc_wacs _wacs_char
1055         do
1056         AC_TRY_LINK([
1057 #ifndef _XOPEN_SOURCE_EXTENDED
1058 #define _XOPEN_SOURCE_EXTENDED
1059 #endif
1060 #include <${cf_cv_ncurses_header:-curses.h}>],
1061         [void *foo = &($name['k'])],
1062         [cf_cv_curses_wacs_map=$name
1063          break])
1064         done])
1065
1066 test "$cf_cv_curses_wacs_map" != unknown && AC_DEFINE_UNQUOTED(CURSES_WACS_ARRAY,$cf_cv_curses_wacs_map,[Define to name of (n)curses wide-character array])
1067 ])dnl
1068 dnl ---------------------------------------------------------------------------
1069 dnl CF_CURSES_WACS_SYMBOLS version: 2 updated: 2012/10/06 08:57:51
1070 dnl ----------------------
1071 dnl Do a check to see if the WACS_xxx constants are defined compatibly with
1072 dnl X/Open Curses.  In particular, NetBSD's implementation of the WACS_xxx
1073 dnl constants is broken since those constants do not point to cchar_t's.
1074 AC_DEFUN([CF_CURSES_WACS_SYMBOLS],
1075 [
1076 AC_REQUIRE([CF_CURSES_WACS_MAP])
1077
1078 AC_CACHE_CHECK(for wide alternate character constants, cf_cv_curses_wacs_symbols,[
1079 cf_cv_curses_wacs_symbols=no
1080 if test "$cf_cv_curses_wacs_map" != unknown
1081 then
1082         AC_TRY_LINK([
1083 #ifndef _XOPEN_SOURCE_EXTENDED
1084 #define _XOPEN_SOURCE_EXTENDED
1085 #endif
1086 #include <${cf_cv_ncurses_header:-curses.h}>],
1087         [cchar_t *foo = WACS_PLUS;
1088          $cf_cv_curses_wacs_map['k'] = *WACS_PLUS],
1089         [cf_cv_curses_wacs_symbols=yes])
1090 else
1091         AC_TRY_LINK([
1092 #ifndef _XOPEN_SOURCE_EXTENDED
1093 #define _XOPEN_SOURCE_EXTENDED
1094 #endif
1095 #include <${cf_cv_ncurses_header:-curses.h}>],
1096         [cchar_t *foo = WACS_PLUS],
1097         [cf_cv_curses_wacs_symbols=yes])
1098 fi
1099 ])
1100
1101 test "$cf_cv_curses_wacs_symbols" != no && AC_DEFINE(CURSES_WACS_SYMBOLS,1,[Define to 1 if (n)curses supports wide-character WACS_ symbols])
1102 ])dnl
1103 dnl ---------------------------------------------------------------------------
1104 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1105 dnl ----------
1106 dnl "dirname" is not portable, so we fake it with a shell script.
1107 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1108 dnl ---------------------------------------------------------------------------
1109 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1110 dnl ---------------
1111 dnl You can always use "make -n" to see the actual options, but it's hard to
1112 dnl pick out/analyze warning messages when the compile-line is long.
1113 dnl
1114 dnl Sets:
1115 dnl     ECHO_LT - symbol to control if libtool is verbose
1116 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1117 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1118 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1119 dnl     ECHO_CC - symbol to put before any "cc" line
1120 dnl
1121 AC_DEFUN([CF_DISABLE_ECHO],[
1122 AC_MSG_CHECKING(if you want to see long compiling messages)
1123 CF_ARG_DISABLE(echo,
1124         [  --disable-echo          do not display "compiling" commands],
1125         [
1126         ECHO_LT='--silent'
1127         ECHO_LD='@echo linking [$]@;'
1128         RULE_CC='@echo compiling [$]<'
1129         SHOW_CC='@echo compiling [$]@'
1130         ECHO_CC='@'
1131 ],[
1132         ECHO_LT=''
1133         ECHO_LD=''
1134         RULE_CC=''
1135         SHOW_CC=''
1136         ECHO_CC=''
1137 ])
1138 AC_MSG_RESULT($enableval)
1139 AC_SUBST(ECHO_LT)
1140 AC_SUBST(ECHO_LD)
1141 AC_SUBST(RULE_CC)
1142 AC_SUBST(SHOW_CC)
1143 AC_SUBST(ECHO_CC)
1144 ])dnl
1145 dnl ---------------------------------------------------------------------------
1146 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1147 dnl ----------------
1148 dnl Combine no-leak checks with the libraries or tools that are used for the
1149 dnl checks.
1150 AC_DEFUN([CF_DISABLE_LEAKS],[
1151
1152 AC_REQUIRE([CF_WITH_DMALLOC])
1153 AC_REQUIRE([CF_WITH_DBMALLOC])
1154 AC_REQUIRE([CF_WITH_VALGRIND])
1155
1156 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1157 AC_ARG_ENABLE(leaks,
1158         [  --disable-leaks         test: free permanent memory, analyze leaks],
1159         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1160         : ${with_no_leaks:=no})
1161 AC_MSG_RESULT($with_no_leaks)
1162
1163 if test "$with_no_leaks" = yes ; then
1164         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1165         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1166 fi
1167 ])dnl
1168 dnl ---------------------------------------------------------------------------
1169 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1170 dnl ---------------------
1171 dnl The rpath-hack makes it simpler to build programs, particularly with the
1172 dnl *BSD ports which may have essential libraries in unusual places.  But it
1173 dnl can interfere with building an executable for the base system.  Use this
1174 dnl option in that case.
1175 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1176 [
1177 AC_MSG_CHECKING(if rpath-hack should be disabled)
1178 CF_ARG_DISABLE(rpath-hack,
1179         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1180         [cf_disable_rpath_hack=yes],
1181         [cf_disable_rpath_hack=no])
1182 AC_MSG_RESULT($cf_disable_rpath_hack)
1183 if test "$cf_disable_rpath_hack" = no ; then
1184         CF_RPATH_HACK
1185 fi
1186 ])
1187 dnl ---------------------------------------------------------------------------
1188 dnl CF_ENABLE_STRING_HACKS version: 5 updated: 2016/10/08 17:34:11
1189 dnl ----------------------
1190 dnl On a few platforms, the compiler and/or loader nags with untruthful
1191 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1192 dnl and implying that most uses of the recommended alternatives are correct.
1193 dnl
1194 dnl Factually speaking, no one has actually counted the number of uses of these
1195 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1196 dnl instances are meaningless compared to the hundreds of millions of lines of
1197 dnl existing C code.
1198 dnl
1199 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1200 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1201 dnl standard - but evolved through phases, and older implementations are likely
1202 dnl to yield surprising results, as documented in manpages on various systems.
1203 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1204 [
1205 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1206 AC_ARG_ENABLE(string-hacks,
1207         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1208         [with_string_hacks=$enableval],
1209         [with_string_hacks=no])
1210 AC_MSG_RESULT($with_string_hacks)
1211
1212 if test "x$with_string_hacks" = "xyes"; then
1213         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1214         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1215         AC_CHECK_FUNC(strlcat,[
1216                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1217                 ],[
1218                 AC_CHECK_LIB(bsd,strlcat,[
1219                         CF_ADD_LIB(bsd)
1220                         AC_CHECK_HEADERS(bsd/string.h)
1221                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1222                         ])
1223                 ])
1224         AC_CHECK_FUNCS( strlcpy snprintf )
1225 fi
1226 ])dnl
1227 dnl ---------------------------------------------------------------------------
1228 dnl CF_ENABLE_WARNINGS version: 5 updated: 2017/09/29 20:01:16
1229 dnl ------------------
1230 dnl Configure-option to enable gcc warnings
1231 AC_DEFUN([CF_ENABLE_WARNINGS],[
1232 if ( test "$GCC" = yes || test "$GXX" = yes )
1233 then
1234 AC_MSG_CHECKING(if you want to turn on gcc warnings)
1235 CF_ARG_ENABLE(warnings,
1236         [  --enable-warnings       test: turn on gcc compiler warnings],
1237         [with_warnings=yes],
1238         [with_warnings=no])
1239 AC_MSG_RESULT($with_warnings)
1240 if test "$with_warnings" = "yes"
1241 then
1242         CF_GCC_ATTRIBUTES
1243         CF_GCC_WARNINGS($1)
1244 fi
1245 fi
1246 ])dnl
1247 dnl ---------------------------------------------------------------------------
1248 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
1249 dnl ---------------
1250 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
1251 dnl prefer a standard location, and use -L options only if we do not find the
1252 dnl library in the standard library location(s).
1253 dnl     $1 = library name
1254 dnl     $2 = library class, usually the same as library name
1255 dnl     $3 = includes
1256 dnl     $4 = code fragment to compile/link
1257 dnl     $5 = corresponding function-name
1258 dnl     $6 = flag, nonnull if failure should not cause an error-exit
1259 dnl
1260 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
1261 dnl to use a -L option.
1262 AC_DEFUN([CF_FIND_LIBRARY],
1263 [
1264         eval 'cf_cv_have_lib_'$1'=no'
1265         cf_libdir=""
1266         AC_CHECK_FUNC($5,
1267                 eval 'cf_cv_have_lib_'$1'=yes',[
1268                 cf_save_LIBS="$LIBS"
1269                 AC_MSG_CHECKING(for $5 in -l$1)
1270                 LIBS="-l$1 $LIBS"
1271                 AC_TRY_LINK([$3],[$4],
1272                         [AC_MSG_RESULT(yes)
1273                          eval 'cf_cv_have_lib_'$1'=yes'
1274                         ],
1275                         [AC_MSG_RESULT(no)
1276                         CF_LIBRARY_PATH(cf_search,$2)
1277                         for cf_libdir in $cf_search
1278                         do
1279                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
1280                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
1281                                 AC_TRY_LINK([$3],[$4],
1282                                         [AC_MSG_RESULT(yes)
1283                                          eval 'cf_cv_have_lib_'$1'=yes'
1284                                          break],
1285                                         [AC_MSG_RESULT(no)
1286                                          LIBS="$cf_save_LIBS"])
1287                         done
1288                         ])
1289                 ])
1290 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
1291 ifelse($6,,[
1292 if test $cf_found_library = no ; then
1293         AC_MSG_ERROR(Cannot link $1 library)
1294 fi
1295 ])
1296 ])dnl
1297 dnl ---------------------------------------------------------------------------
1298 dnl CF_FIND_LINKAGE version: 20 updated: 2015/04/18 08:56:57
1299 dnl ---------------
1300 dnl Find a library (specifically the linkage used in the code fragment),
1301 dnl searching for it if it is not already in the library path.
1302 dnl See also CF_ADD_SEARCHPATH.
1303 dnl
1304 dnl Parameters (4-on are optional):
1305 dnl     $1 = headers for library entrypoint
1306 dnl     $2 = code fragment for library entrypoint
1307 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1308 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1309 dnl     $5 = action to perform if not successful
1310 dnl     $6 = module name, if not the same as the library name
1311 dnl     $7 = extra libraries
1312 dnl
1313 dnl Sets these variables:
1314 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1315 dnl     $cf_cv_header_path_$3 - include-directory if needed
1316 dnl     $cf_cv_library_path_$3 - library-directory if needed
1317 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1318 AC_DEFUN([CF_FIND_LINKAGE],[
1319
1320 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1321 # will be set on completion of the AC_TRY_LINK below.
1322 cf_cv_header_path_$3=
1323 cf_cv_library_path_$3=
1324
1325 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1326
1327 cf_save_LIBS="$LIBS"
1328
1329 AC_TRY_LINK([$1],[$2],[
1330         cf_cv_find_linkage_$3=yes
1331         cf_cv_header_path_$3=/usr/include
1332         cf_cv_library_path_$3=/usr/lib
1333 ],[
1334
1335 LIBS="-l$3 $7 $cf_save_LIBS"
1336
1337 AC_TRY_LINK([$1],[$2],[
1338         cf_cv_find_linkage_$3=yes
1339         cf_cv_header_path_$3=/usr/include
1340         cf_cv_library_path_$3=/usr/lib
1341         cf_cv_library_file_$3="-l$3"
1342 ],[
1343         cf_cv_find_linkage_$3=no
1344         LIBS="$cf_save_LIBS"
1345
1346         CF_VERBOSE(find linkage for $3 library)
1347         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1348
1349         cf_save_CPPFLAGS="$CPPFLAGS"
1350         cf_test_CPPFLAGS="$CPPFLAGS"
1351
1352         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1353         for cf_cv_header_path_$3 in $cf_search
1354         do
1355                 if test -d $cf_cv_header_path_$3 ; then
1356                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1357                         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1358                         AC_TRY_COMPILE([$1],[$2],[
1359                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1360                                 cf_cv_find_linkage_$3=maybe
1361                                 cf_test_CPPFLAGS="$CPPFLAGS"
1362                                 break],[
1363                                 CPPFLAGS="$cf_save_CPPFLAGS"
1364                                 ])
1365                 fi
1366         done
1367
1368         if test "$cf_cv_find_linkage_$3" = maybe ; then
1369
1370                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1371
1372                 cf_save_LIBS="$LIBS"
1373                 cf_save_LDFLAGS="$LDFLAGS"
1374
1375                 ifelse([$6],,,[
1376                 CPPFLAGS="$cf_test_CPPFLAGS"
1377                 LIBS="-l$3 $7 $cf_save_LIBS"
1378                 AC_TRY_LINK([$1],[$2],[
1379                         CF_VERBOSE(... found $3 library in system)
1380                         cf_cv_find_linkage_$3=yes])
1381                         CPPFLAGS="$cf_save_CPPFLAGS"
1382                         LIBS="$cf_save_LIBS"
1383                         ])
1384
1385                 if test "$cf_cv_find_linkage_$3" != yes ; then
1386                         CF_LIBRARY_PATH(cf_search,$3)
1387                         for cf_cv_library_path_$3 in $cf_search
1388                         do
1389                                 if test -d $cf_cv_library_path_$3 ; then
1390                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1391                                         CPPFLAGS="$cf_test_CPPFLAGS"
1392                                         LIBS="-l$3 $7 $cf_save_LIBS"
1393                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1394                                         AC_TRY_LINK([$1],[$2],[
1395                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1396                                         cf_cv_find_linkage_$3=yes
1397                                         cf_cv_library_file_$3="-l$3"
1398                                         break],[
1399                                         CPPFLAGS="$cf_save_CPPFLAGS"
1400                                         LIBS="$cf_save_LIBS"
1401                                         LDFLAGS="$cf_save_LDFLAGS"
1402                                         ])
1403                                 fi
1404                         done
1405                         CPPFLAGS="$cf_save_CPPFLAGS"
1406                         LDFLAGS="$cf_save_LDFLAGS"
1407                 fi
1408
1409         else
1410                 cf_cv_find_linkage_$3=no
1411         fi
1412         ],$7)
1413 ])
1414
1415 LIBS="$cf_save_LIBS"
1416
1417 if test "$cf_cv_find_linkage_$3" = yes ; then
1418 ifelse([$4],,[
1419         CF_ADD_INCDIR($cf_cv_header_path_$3)
1420         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1421         CF_ADD_LIB($3)
1422 ],[$4])
1423 else
1424 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1425 fi
1426 ])dnl
1427 dnl ---------------------------------------------------------------------------
1428 dnl CF_FUNC_CURSES_VERSION version: 7 updated: 2017/05/10 18:31:29
1429 dnl ----------------------
1430 dnl Solaris has a data item 'curses_version', which confuses AC_CHECK_FUNCS.
1431 dnl It's a character string "SVR4", not documented.
1432 AC_DEFUN([CF_FUNC_CURSES_VERSION],
1433 [
1434 AC_CACHE_CHECK(for function curses_version, cf_cv_func_curses_version,[
1435 AC_TRY_RUN([
1436 #include <${cf_cv_ncurses_header:-curses.h}>
1437 int main(void)
1438 {
1439         char temp[1024];
1440         sprintf(temp, "%s\n", curses_version());
1441         ${cf_cv_main_return:-return}(0);
1442 }]
1443 ,[cf_cv_func_curses_version=yes]
1444 ,[cf_cv_func_curses_version=no]
1445 ,[cf_cv_func_curses_version=unknown])
1446 rm -f core])
1447 test "$cf_cv_func_curses_version" = yes && AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 if we have curses_version function])
1448 ])
1449 dnl ---------------------------------------------------------------------------
1450 dnl CF_FUNC_OPENPTY version: 5 updated: 2015/09/12 14:46:50
1451 dnl ---------------
1452 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1453 dnl "util" library as well.
1454 AC_DEFUN([CF_FUNC_OPENPTY],
1455 [
1456 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1457 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1458         cf_save_LIBS="$LIBS"
1459         test $cf_cv_lib_util = yes && { CF_ADD_LIB(util) }
1460         for cf_header in pty.h libutil.h util.h
1461         do
1462         AC_TRY_LINK([
1463 #include <$cf_header>
1464 ],[
1465         int x = openpty((int *)0, (int *)0, (char *)0,
1466                                    (struct termios *)0, (struct winsize *)0);
1467 ],[
1468                 cf_cv_func_openpty=$cf_header
1469                 break
1470 ],[
1471                 cf_cv_func_openpty=no
1472 ])
1473         done
1474         LIBS="$cf_save_LIBS"
1475 ])
1476 ])dnl
1477 dnl ---------------------------------------------------------------------------
1478 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
1479 dnl -----------------
1480 dnl Test for availability of useful gcc __attribute__ directives to quiet
1481 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1482 dnl to documentation, unrecognized directives cause older compilers to barf.
1483 AC_DEFUN([CF_GCC_ATTRIBUTES],
1484 [
1485 if test "$GCC" = yes
1486 then
1487 cat > conftest.i <<EOF
1488 #ifndef GCC_PRINTF
1489 #define GCC_PRINTF 0
1490 #endif
1491 #ifndef GCC_SCANF
1492 #define GCC_SCANF 0
1493 #endif
1494 #ifndef GCC_NORETURN
1495 #define GCC_NORETURN /* nothing */
1496 #endif
1497 #ifndef GCC_UNUSED
1498 #define GCC_UNUSED /* nothing */
1499 #endif
1500 EOF
1501 if test "$GCC" = yes
1502 then
1503         AC_CHECKING([for $CC __attribute__ directives])
1504 cat > conftest.$ac_ext <<EOF
1505 #line __oline__ "${as_me:-configure}"
1506 #include "confdefs.h"
1507 #include "conftest.h"
1508 #include "conftest.i"
1509 #if     GCC_PRINTF
1510 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1511 #else
1512 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1513 #endif
1514 #if     GCC_SCANF
1515 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1516 #else
1517 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1518 #endif
1519 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1520 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1521 extern void foo(void) GCC_NORETURN;
1522 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1523 EOF
1524         cf_printf_attribute=no
1525         cf_scanf_attribute=no
1526         for cf_attribute in scanf printf unused noreturn
1527         do
1528                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1529                 cf_directive="__attribute__(($cf_attribute))"
1530                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1531
1532                 case $cf_attribute in
1533                 (printf)
1534                         cf_printf_attribute=yes
1535                         cat >conftest.h <<EOF
1536 #define GCC_$cf_ATTRIBUTE 1
1537 EOF
1538                         ;;
1539                 (scanf)
1540                         cf_scanf_attribute=yes
1541                         cat >conftest.h <<EOF
1542 #define GCC_$cf_ATTRIBUTE 1
1543 EOF
1544                         ;;
1545                 (*)
1546                         cat >conftest.h <<EOF
1547 #define GCC_$cf_ATTRIBUTE $cf_directive
1548 EOF
1549                         ;;
1550                 esac
1551
1552                 if AC_TRY_EVAL(ac_compile); then
1553                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1554                         cat conftest.h >>confdefs.h
1555                         case $cf_attribute in
1556                         (noreturn)
1557                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1558                                 ;;
1559                         (printf)
1560                                 cf_value='/* nothing */'
1561                                 if test "$cf_printf_attribute" != no ; then
1562                                         cf_value='__attribute__((format(printf,fmt,var)))'
1563                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1564                                 fi
1565                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1566                                 ;;
1567                         (scanf)
1568                                 cf_value='/* nothing */'
1569                                 if test "$cf_scanf_attribute" != no ; then
1570                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1571                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1572                                 fi
1573                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1574                                 ;;
1575                         (unused)
1576                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1577                                 ;;
1578                         esac
1579                 fi
1580         done
1581 else
1582         fgrep define conftest.i >>confdefs.h
1583 fi
1584 rm -rf conftest*
1585 fi
1586 ])dnl
1587 dnl ---------------------------------------------------------------------------
1588 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
1589 dnl --------------
1590 dnl Find version of gcc
1591 AC_DEFUN([CF_GCC_VERSION],[
1592 AC_REQUIRE([AC_PROG_CC])
1593 GCC_VERSION=none
1594 if test "$GCC" = yes ; then
1595         AC_MSG_CHECKING(version of $CC)
1596         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1597         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1598         AC_MSG_RESULT($GCC_VERSION)
1599 fi
1600 ])dnl
1601 dnl ---------------------------------------------------------------------------
1602 dnl CF_GCC_WARNINGS version: 32 updated: 2015/04/12 15:39:00
1603 dnl ---------------
1604 dnl Check if the compiler supports useful warning options.  There's a few that
1605 dnl we don't use, simply because they're too noisy:
1606 dnl
1607 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1608 dnl     -Wredundant-decls (system headers make this too noisy)
1609 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1610 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1611 dnl             is enabled for ncurses using "--enable-const".
1612 dnl     -pedantic
1613 dnl
1614 dnl Parameter:
1615 dnl     $1 is an optional list of gcc warning flags that a particular
1616 dnl             application might want to use, e.g., "no-unused" for
1617 dnl             -Wno-unused
1618 dnl Special:
1619 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1620 dnl
1621 AC_DEFUN([CF_GCC_WARNINGS],
1622 [
1623 AC_REQUIRE([CF_GCC_VERSION])
1624 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1625 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1626
1627 cat > conftest.$ac_ext <<EOF
1628 #line __oline__ "${as_me:-configure}"
1629 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1630 EOF
1631
1632 if test "$INTEL_COMPILER" = yes
1633 then
1634 # The "-wdXXX" options suppress warnings:
1635 # remark #1419: external declaration in primary source file
1636 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1637 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1638 # remark #193: zero used for undefined preprocessing identifier
1639 # remark #593: variable "curs_sb_left_arrow" was set but never used
1640 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1641 # remark #869: parameter "tw" was never referenced
1642 # remark #981: operands are evaluated in unspecified order
1643 # warning #279: controlling expression is constant
1644
1645         AC_CHECKING([for $CC warning options])
1646         cf_save_CFLAGS="$CFLAGS"
1647         EXTRA_CFLAGS="-Wall"
1648         for cf_opt in \
1649                 wd1419 \
1650                 wd1683 \
1651                 wd1684 \
1652                 wd193 \
1653                 wd593 \
1654                 wd279 \
1655                 wd810 \
1656                 wd869 \
1657                 wd981
1658         do
1659                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1660                 if AC_TRY_EVAL(ac_compile); then
1661                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1662                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1663                 fi
1664         done
1665         CFLAGS="$cf_save_CFLAGS"
1666
1667 elif test "$GCC" = yes
1668 then
1669         AC_CHECKING([for $CC warning options])
1670         cf_save_CFLAGS="$CFLAGS"
1671         EXTRA_CFLAGS=
1672         cf_warn_CONST=""
1673         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1674         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
1675         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
1676         for cf_opt in W Wall \
1677                 Wbad-function-cast \
1678                 Wcast-align \
1679                 Wcast-qual \
1680                 Wdeclaration-after-statement \
1681                 Wextra \
1682                 Winline \
1683                 Wmissing-declarations \
1684                 Wmissing-prototypes \
1685                 Wnested-externs \
1686                 Wpointer-arith \
1687                 Wshadow \
1688                 Wstrict-prototypes \
1689                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
1690         do
1691                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1692                 if AC_TRY_EVAL(ac_compile); then
1693                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1694                         case $cf_opt in
1695                         (Wcast-qual)
1696                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1697                                 ;;
1698                         (Winline)
1699                                 case $GCC_VERSION in
1700                                 ([[34]].*)
1701                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1702                                         continue;;
1703                                 esac
1704                                 ;;
1705                         (Wpointer-arith)
1706                                 case $GCC_VERSION in
1707                                 ([[12]].*)
1708                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1709                                         continue;;
1710                                 esac
1711                                 ;;
1712                         esac
1713                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1714                 fi
1715         done
1716         CFLAGS="$cf_save_CFLAGS"
1717 fi
1718 rm -rf conftest*
1719
1720 AC_SUBST(EXTRA_CFLAGS)
1721 ])dnl
1722 dnl ---------------------------------------------------------------------------
1723 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
1724 dnl ----------------
1725 dnl Check for getopt's variables which are commonly defined in stdlib.h,
1726 dnl unistd.h or (nonstandard) in getopt.h
1727 AC_DEFUN([CF_GETOPT_HEADER],
1728 [
1729 AC_HAVE_HEADERS(unistd.h getopt.h)
1730 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
1731 cf_cv_getopt_header=none
1732 for cf_header in stdio.h stdlib.h unistd.h getopt.h
1733 do
1734 AC_TRY_COMPILE([
1735 #include <$cf_header>],
1736 [int x = optind; char *y = optarg],
1737 [cf_cv_getopt_header=$cf_header
1738  break])
1739 done
1740 ])
1741 if test $cf_cv_getopt_header != none ; then
1742         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
1743 fi
1744 if test $cf_cv_getopt_header = getopt.h ; then
1745         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
1746 fi
1747 ])dnl
1748 dnl ---------------------------------------------------------------------------
1749 dnl CF_GNU_SOURCE version: 7 updated: 2016/08/05 05:15:37
1750 dnl -------------
1751 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1752 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1753 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1754 dnl since it is interwoven with GNU extensions.
1755 dnl
1756 dnl Well, yes we could work around it...
1757 AC_DEFUN([CF_GNU_SOURCE],
1758 [
1759 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1760 AC_TRY_COMPILE([#include <sys/types.h>],[
1761 #ifndef _XOPEN_SOURCE
1762 make an error
1763 #endif],
1764         [cf_cv_gnu_source=no],
1765         [cf_save="$CPPFLAGS"
1766          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1767          AC_TRY_COMPILE([#include <sys/types.h>],[
1768 #ifdef _XOPEN_SOURCE
1769 make an error
1770 #endif],
1771         [cf_cv_gnu_source=no],
1772         [cf_cv_gnu_source=yes])
1773         CPPFLAGS="$cf_save"
1774         ])
1775 ])
1776
1777 if test "$cf_cv_gnu_source" = yes
1778 then
1779 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
1780 CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1781         AC_TRY_COMPILE([#include <sys/types.h>],[
1782 #ifdef _DEFAULT_SOURCE
1783 make an error
1784 #endif],
1785                 [cf_cv_default_source=no],
1786                 [cf_cv_default_source=yes])
1787         ])
1788 test "$cf_cv_default_source" = yes && CPPFLAGS="$CPPFLAGS -D_DEFAULT_SOURCE"
1789 fi
1790 ])dnl
1791 dnl ---------------------------------------------------------------------------
1792 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
1793 dnl --------------
1794 dnl Construct a search-list of directories for a nonstandard header-file
1795 dnl
1796 dnl Parameters
1797 dnl     $1 = the variable to return as result
1798 dnl     $2 = the package name
1799 AC_DEFUN([CF_HEADER_PATH],
1800 [
1801 $1=
1802
1803 # collect the current set of include-directories from compiler flags
1804 cf_header_path_list=""
1805 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1806         for cf_header_path in $CPPFLAGS $CFLAGS
1807         do
1808                 case $cf_header_path in
1809                 (-I*)
1810                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1811                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1812                         cf_header_path_list="$cf_header_path_list [$]$1"
1813                         ;;
1814                 esac
1815         done
1816 fi
1817
1818 # add the variations for the package we are looking for
1819 CF_SUBDIR_PATH($1,$2,include)
1820
1821 test "$includedir" != NONE && \
1822 test "$includedir" != "/usr/include" && \
1823 test -d "$includedir" && {
1824         test -d $includedir &&    $1="[$]$1 $includedir"
1825         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
1826 }
1827
1828 test "$oldincludedir" != NONE && \
1829 test "$oldincludedir" != "/usr/include" && \
1830 test -d "$oldincludedir" && {
1831         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
1832         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
1833 }
1834
1835 $1="[$]$1 $cf_header_path_list"
1836 ])dnl
1837 dnl ---------------------------------------------------------------------------
1838 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
1839 dnl ---------------
1840 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
1841 AC_DEFUN([CF_HELP_MESSAGE],
1842 [AC_DIVERT_HELP([$1])dnl
1843 ])dnl
1844 dnl ---------------------------------------------------------------------------
1845 dnl CF_INHERIT_SCRIPT version: 2 updated: 2003/03/01 23:50:42
1846 dnl -----------------
1847 dnl If we do not have a given script, look for it in the parent directory.
1848 AC_DEFUN([CF_INHERIT_SCRIPT],
1849 [
1850 test -f $1 || ( test -f ../$1 && cp ../$1 ./ )
1851 ])dnl
1852 dnl ---------------------------------------------------------------------------
1853 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
1854 dnl -----------------
1855 dnl Check if the given compiler is really the Intel compiler for Linux.  It
1856 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
1857 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
1858 dnl
1859 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1860 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1861 dnl the wrappers for gcc and g++ warnings.
1862 dnl
1863 dnl $1 = GCC (default) or GXX
1864 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
1865 dnl $3 = CFLAGS (default) or CXXFLAGS
1866 AC_DEFUN([CF_INTEL_COMPILER],[
1867 AC_REQUIRE([AC_CANONICAL_HOST])
1868 ifelse([$2],,INTEL_COMPILER,[$2])=no
1869
1870 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1871         case $host_os in
1872         (linux*|gnu*)
1873                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
1874                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1875                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
1876                 AC_TRY_COMPILE([],[
1877 #ifdef __INTEL_COMPILER
1878 #else
1879 make an error
1880 #endif
1881 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
1882 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
1883 ],[])
1884                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1885                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
1886                 ;;
1887         esac
1888 fi
1889 ])dnl
1890 dnl ---------------------------------------------------------------------------
1891 dnl CF_LD_RPATH_OPT version: 7 updated: 2016/02/20 18:01:19
1892 dnl ---------------
1893 dnl For the given system and compiler, find the compiler flags to pass to the
1894 dnl loader to use the "rpath" feature.
1895 AC_DEFUN([CF_LD_RPATH_OPT],
1896 [
1897 AC_REQUIRE([CF_CHECK_CACHE])
1898
1899 LD_RPATH_OPT=
1900 AC_MSG_CHECKING(for an rpath option)
1901 case $cf_cv_system_name in
1902 (irix*)
1903         if test "$GCC" = yes; then
1904                 LD_RPATH_OPT="-Wl,-rpath,"
1905         else
1906                 LD_RPATH_OPT="-rpath "
1907         fi
1908         ;;
1909 (linux*|gnu*|k*bsd*-gnu|freebsd*)
1910         LD_RPATH_OPT="-Wl,-rpath,"
1911         ;;
1912 (openbsd[[2-9]].*|mirbsd*)
1913         LD_RPATH_OPT="-Wl,-rpath,"
1914         ;;
1915 (dragonfly*)
1916         LD_RPATH_OPT="-rpath "
1917         ;;
1918 (netbsd*)
1919         LD_RPATH_OPT="-Wl,-rpath,"
1920         ;;
1921 (osf*|mls+*)
1922         LD_RPATH_OPT="-rpath "
1923         ;;
1924 (solaris2*)
1925         LD_RPATH_OPT="-R"
1926         ;;
1927 (*)
1928         ;;
1929 esac
1930 AC_MSG_RESULT($LD_RPATH_OPT)
1931
1932 case "x$LD_RPATH_OPT" in
1933 (x-R*)
1934         AC_MSG_CHECKING(if we need a space after rpath option)
1935         cf_save_LIBS="$LIBS"
1936         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
1937         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
1938         LIBS="$cf_save_LIBS"
1939         AC_MSG_RESULT($cf_rpath_space)
1940         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
1941         ;;
1942 esac
1943 ])dnl
1944 dnl ---------------------------------------------------------------------------
1945 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
1946 dnl ---------------
1947 dnl Construct a search-list of directories for a nonstandard library-file
1948 dnl
1949 dnl Parameters
1950 dnl     $1 = the variable to return as result
1951 dnl     $2 = the package name
1952 AC_DEFUN([CF_LIBRARY_PATH],
1953 [
1954 $1=
1955 cf_library_path_list=""
1956 if test -n "${LDFLAGS}${LIBS}" ; then
1957         for cf_library_path in $LDFLAGS $LIBS
1958         do
1959                 case $cf_library_path in
1960                 (-L*)
1961                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
1962                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
1963                         cf_library_path_list="$cf_library_path_list [$]$1"
1964                         ;;
1965                 esac
1966         done
1967 fi
1968
1969 CF_SUBDIR_PATH($1,$2,lib)
1970
1971 $1="$cf_library_path_list [$]$1"
1972 ])dnl
1973 dnl ---------------------------------------------------------------------------
1974 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
1975 dnl ------------
1976 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
1977 dnl a monocase filesystem.
1978 AC_DEFUN([CF_MAKE_TAGS],[
1979 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
1980
1981 AC_CHECK_PROGS(CTAGS, exctags ctags)
1982 AC_CHECK_PROGS(ETAGS, exetags etags)
1983
1984 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
1985
1986 if test "$cf_cv_mixedcase" = yes ; then
1987         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
1988 else
1989         MAKE_UPPER_TAGS=no
1990 fi
1991
1992 if test "$MAKE_UPPER_TAGS" = yes ; then
1993         MAKE_UPPER_TAGS=
1994 else
1995         MAKE_UPPER_TAGS="#"
1996 fi
1997
1998 if test "$MAKE_LOWER_TAGS" = yes ; then
1999         MAKE_LOWER_TAGS=
2000 else
2001         MAKE_LOWER_TAGS="#"
2002 fi
2003
2004 AC_SUBST(CTAGS)
2005 AC_SUBST(ETAGS)
2006
2007 AC_SUBST(MAKE_UPPER_TAGS)
2008 AC_SUBST(MAKE_LOWER_TAGS)
2009 ])dnl
2010 dnl ---------------------------------------------------------------------------
2011 dnl CF_MATH_LIB version: 9 updated: 2017/01/21 11:06:25
2012 dnl -----------
2013 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
2014 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
2015 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
2016 AC_DEFUN([CF_MATH_LIB],
2017 [
2018 AC_CACHE_CHECK(if -lm needed for math functions,
2019         cf_cv_need_libm,[
2020         AC_TRY_LINK([
2021         #include <stdio.h>
2022         #include <stdlib.h>
2023         #include <math.h>
2024         ],
2025         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
2026         [cf_cv_need_libm=no],
2027         [cf_cv_need_libm=yes])])
2028 if test "$cf_cv_need_libm" = yes
2029 then
2030 ifelse($1,,[
2031         CF_ADD_LIB(m)
2032 ],[$1=-lm])
2033 fi
2034 ])
2035 dnl ---------------------------------------------------------------------------
2036 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
2037 dnl ----------------------
2038 dnl Check if the file-system supports mixed-case filenames.  If we're able to
2039 dnl create a lowercase name and see it as uppercase, it doesn't support that.
2040 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
2041 [
2042 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
2043 if test "$cross_compiling" = yes ; then
2044         case $target_alias in
2045         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
2046                 cf_cv_mixedcase=no
2047                 ;;
2048         (*)
2049                 cf_cv_mixedcase=yes
2050                 ;;
2051         esac
2052 else
2053         rm -f conftest CONFTEST
2054         echo test >conftest
2055         if test -f CONFTEST ; then
2056                 cf_cv_mixedcase=no
2057         else
2058                 cf_cv_mixedcase=yes
2059         fi
2060         rm -f conftest CONFTEST
2061 fi
2062 ])
2063 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
2064 ])dnl
2065 dnl ---------------------------------------------------------------------------
2066 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2067 dnl ----------
2068 dnl Write a debug message to config.log, along with the line number in the
2069 dnl configure script.
2070 AC_DEFUN([CF_MSG_LOG],[
2071 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2072 ])dnl
2073 dnl ---------------------------------------------------------------------------
2074 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
2075 dnl -------------------
2076 dnl Check if we can compile with ncurses' header file
2077 dnl $1 is the cache variable to set
2078 dnl $2 is the header-file to include
2079 dnl $3 is the root name (ncurses or ncursesw)
2080 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2081         AC_TRY_COMPILE([
2082 ]ifelse($3,ncursesw,[
2083 #define _XOPEN_SOURCE_EXTENDED
2084 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2085 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2086 ])[
2087 #include <$2>],[
2088 #ifdef NCURSES_VERSION
2089 ]ifelse($3,ncursesw,[
2090 #ifndef WACS_BSSB
2091         make an error
2092 #endif
2093 ])[
2094 printf("%s\n", NCURSES_VERSION);
2095 #else
2096 #ifdef __NCURSES_H
2097 printf("old\n");
2098 #else
2099         make an error
2100 #endif
2101 #endif
2102         ]
2103         ,[$1=$2]
2104         ,[$1=no])
2105 ])dnl
2106 dnl ---------------------------------------------------------------------------
2107 dnl CF_NCURSES_CONFIG version: 20 updated: 2018/01/03 04:47:33
2108 dnl -----------------
2109 dnl Tie together the configure-script macros for ncurses, preferring these in
2110 dnl order:
2111 dnl a) ".pc" files for pkg-config, using $NCURSES_CONFIG_PKG
2112 dnl b) the "-config" script from ncurses, using $NCURSES_CONFIG
2113 dnl c) just plain libraries
2114 dnl
2115 dnl $1 is the root library name (default: "ncurses")
2116 AC_DEFUN([CF_NCURSES_CONFIG],[
2117 AC_REQUIRE([CF_PKG_CONFIG])
2118 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2119 cf_have_ncuconfig=no
2120
2121 if test "x${PKG_CONFIG:=none}" != xnone; then
2122         AC_MSG_CHECKING(pkg-config for $cf_ncuconfig_root)
2123         if "$PKG_CONFIG" --exists $cf_ncuconfig_root ; then
2124                 AC_MSG_RESULT(yes)
2125
2126                 AC_MSG_CHECKING(if the $cf_ncuconfig_root package files work)
2127                 cf_have_ncuconfig=unknown
2128
2129                 cf_save_CPPFLAGS="$CPPFLAGS"
2130                 cf_save_LIBS="$LIBS"
2131
2132                 CPPFLAGS="$CPPFLAGS `$PKG_CONFIG --cflags $cf_ncuconfig_root`"
2133                 CF_ADD_LIBS(`$PKG_CONFIG --libs $cf_ncuconfig_root`)
2134
2135                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2136                         [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2137                         [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2138                                 int main(void)
2139                                 { char *xx = curses_version(); return (xx == 0); }],
2140                                 [cf_have_ncuconfig=yes],
2141                                 [cf_have_ncuconfig=no],
2142                                 [cf_have_ncuconfig=maybe])],
2143                         [cf_have_ncuconfig=no])
2144                 AC_MSG_RESULT($cf_have_ncuconfig)
2145                 test "$cf_have_ncuconfig" = maybe && cf_have_ncuconfig=yes
2146                 if test "$cf_have_ncuconfig" != "yes"
2147                 then
2148                         CPPFLAGS="$cf_save_CPPFLAGS"
2149                         LIBS="$cf_save_LIBS"
2150                         NCURSES_CONFIG_PKG=none
2151                 else
2152                         AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2153                         NCURSES_CONFIG_PKG=$cf_ncuconfig_root
2154                         CF_TERM_HEADER
2155                 fi
2156
2157         else
2158                 AC_MSG_RESULT(no)
2159                 NCURSES_CONFIG_PKG=none
2160         fi
2161 else
2162         NCURSES_CONFIG_PKG=none
2163 fi
2164
2165 if test "x$cf_have_ncuconfig" = "xno"; then
2166         cf_ncurses_config="${cf_ncuconfig_root}${NCURSES_CONFIG_SUFFIX}-config"; echo "Looking for ${cf_ncurses_config}"
2167
2168         CF_ACVERSION_CHECK(2.52,
2169                 [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
2170                 [AC_PATH_PROGS(NCURSES_CONFIG,  ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
2171
2172         if test "$NCURSES_CONFIG" != none ; then
2173
2174                 CPPFLAGS="$CPPFLAGS `$NCURSES_CONFIG --cflags`"
2175                 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2176
2177                 # even with config script, some packages use no-override for curses.h
2178                 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2179
2180                 dnl like CF_NCURSES_CPPFLAGS
2181                 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2182
2183                 dnl like CF_NCURSES_LIBS
2184                 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2185                 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2186
2187                 dnl like CF_NCURSES_VERSION
2188                 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
2189
2190         else
2191
2192                 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2193                 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2194
2195         fi
2196 else
2197         NCURSES_CONFIG=none
2198 fi
2199 ])dnl
2200 dnl ---------------------------------------------------------------------------
2201 dnl CF_NCURSES_CPPFLAGS version: 21 updated: 2012/10/06 08:57:51
2202 dnl -------------------
2203 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
2204 dnl the CPPFLAGS variable so we can include its header.
2205 dnl
2206 dnl The header files may be installed as either curses.h, or ncurses.h (would
2207 dnl be obsolete, except that some packagers prefer this name to distinguish it
2208 dnl from a "native" curses implementation).  If not installed for overwrite,
2209 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
2210 dnl /usr/include/ncurses), but someone may have installed overwriting the
2211 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
2212 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
2213 dnl the header.
2214 dnl
2215 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
2216 dnl is already in the include-path, don't even bother with this, since we cannot
2217 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
2218 dnl
2219 dnl The optional parameter gives the root name of the library, in case it is
2220 dnl not installed as the default curses library.  That is how the
2221 dnl wide-character version of ncurses is installed.
2222 AC_DEFUN([CF_NCURSES_CPPFLAGS],
2223 [AC_REQUIRE([CF_WITH_CURSES_DIR])
2224
2225 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
2226 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
2227
2228 test -n "$cf_cv_curses_dir" && \
2229 test "$cf_cv_curses_dir" != "no" && { \
2230   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
2231 }
2232
2233 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
2234         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2235         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
2236         for cf_header in $cf_header_list
2237         do
2238                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2239                 test "$cf_cv_ncurses_h" != no && break
2240         done
2241 ])
2242
2243 CF_NCURSES_HEADER
2244 CF_TERM_HEADER
2245
2246 # some applications need this, but should check for NCURSES_VERSION
2247 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2248
2249 CF_NCURSES_VERSION
2250 ])dnl
2251 dnl ---------------------------------------------------------------------------
2252 dnl CF_NCURSES_EXT_FUNCS version: 4 updated: 2012/10/06 16:39:58
2253 dnl --------------------
2254 dnl Since 2007/11/17, ncurses has defined NCURSES_EXT_FUNCS; earlier versions
2255 dnl may provide these functions.  Define the symbol if it is not defined, and
2256 dnl if it is valid.
2257 AC_DEFUN([CF_NCURSES_EXT_FUNCS],
2258 [
2259 AC_CACHE_CHECK(for ncurses extended functions,cf_cv_ncurses_ext_funcs,[
2260 AC_TRY_COMPILE([
2261 #include <${cf_cv_ncurses_header:-curses.h}>],
2262 [
2263 int x = NCURSES_EXT_FUNCS
2264 ],[cf_cv_ncurses_ext_funcs=defined],[
2265 AC_TRY_LINK([
2266 #include <${cf_cv_ncurses_header:-curses.h}>],
2267 [
2268         (void) assume_default_colors (0, 0);
2269         (void) curses_version ();
2270         (void) define_key (0, 0);
2271         (void) is_term_resized (0, 0);
2272         (void) key_defined (0);
2273         (void) keybound (0, 0);
2274         (void) keyok (0, 0);
2275         (void) resize_term (0, 0);
2276         (void) resizeterm (0, 0);
2277         (void) use_default_colors ();
2278         (void) use_extended_names (0);
2279         (void) wresize (0, 0, 0);],
2280         [cf_cv_ncurses_ext_funcs=yes],
2281         [cf_cv_ncurses_ext_funcs=no])
2282 ])
2283 ])
2284 test "$cf_cv_ncurses_ext_funcs" = yes && AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 if we have ncurses extensions])
2285 ])dnl
2286 dnl ---------------------------------------------------------------------------
2287 dnl CF_NCURSES_HEADER version: 4 updated: 2015/04/15 19:08:48
2288 dnl -----------------
2289 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2290 dnl variations of ncurses' installs.
2291 dnl
2292 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2293 AC_DEFUN([CF_NCURSES_HEADER],[
2294
2295 if test "$cf_cv_ncurses_h" != no ; then
2296         cf_cv_ncurses_header=$cf_cv_ncurses_h
2297 else
2298
2299 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2300         test -n "$verbose" && echo
2301         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2302         test -n "$verbose" && echo search path $cf_search
2303         cf_save2_CPPFLAGS="$CPPFLAGS"
2304         for cf_incdir in $cf_search
2305         do
2306                 CF_ADD_INCDIR($cf_incdir)
2307                 for cf_header in \
2308                         ncurses.h \
2309                         curses.h
2310                 do
2311                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2312                         if test "$cf_cv_ncurses_h2" != no ; then
2313                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2314                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
2315                                 break
2316                         fi
2317                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2318                 done
2319                 CPPFLAGS="$cf_save2_CPPFLAGS"
2320                 test "$cf_cv_ncurses_h2" != no && break
2321         done
2322         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2323         ])
2324
2325         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2326         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
2327         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
2328                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
2329         fi
2330         CF_ADD_INCDIR($cf_1st_incdir)
2331
2332 fi
2333
2334 # Set definitions to allow ifdef'ing for ncurses.h
2335
2336 case $cf_cv_ncurses_header in
2337 (*ncurses.h)
2338         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
2339         ;;
2340 esac
2341
2342 case $cf_cv_ncurses_header in
2343 (ncurses/curses.h|ncurses/ncurses.h)
2344         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
2345         ;;
2346 (ncursesw/curses.h|ncursesw/ncurses.h)
2347         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
2348         ;;
2349 esac
2350
2351 ])dnl
2352 dnl ---------------------------------------------------------------------------
2353 dnl CF_NCURSES_LIBS version: 17 updated: 2015/04/15 19:08:48
2354 dnl ---------------
2355 dnl Look for the ncurses library.  This is a little complicated on Linux,
2356 dnl because it may be linked with the gpm (general purpose mouse) library.
2357 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2358 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2359 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2360 dnl and the linker will record a dependency.
2361 dnl
2362 dnl The optional parameter gives the root name of the library, in case it is
2363 dnl not installed as the default curses library.  That is how the
2364 dnl wide-character version of ncurses is installed.
2365 AC_DEFUN([CF_NCURSES_LIBS],
2366 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2367
2368 cf_nculib_root=ifelse($1,,ncurses,$1)
2369         # This works, except for the special case where we find gpm, but
2370         # ncurses is in a nonstandard location via $LIBS, and we really want
2371         # to link gpm.
2372 cf_ncurses_LIBS=""
2373 cf_ncurses_SAVE="$LIBS"
2374 AC_CHECK_LIB(gpm,Gpm_Open,
2375         [AC_CHECK_LIB(gpm,initscr,
2376                 [LIBS="$cf_ncurses_SAVE"],
2377                 [cf_ncurses_LIBS="-lgpm"])])
2378
2379 case $host_os in
2380 (freebsd*)
2381         # This is only necessary if you are linking against an obsolete
2382         # version of ncurses (but it should do no harm, since it's static).
2383         if test "$cf_nculib_root" = ncurses ; then
2384                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2385         fi
2386         ;;
2387 esac
2388
2389 CF_ADD_LIBS($cf_ncurses_LIBS)
2390
2391 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2392 then
2393         CF_ADD_LIBS(-l$cf_nculib_root)
2394 else
2395         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2396                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2397                 [initscr()],
2398                 initscr)
2399 fi
2400
2401 if test -n "$cf_ncurses_LIBS" ; then
2402         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2403         cf_ncurses_SAVE="$LIBS"
2404         for p in $cf_ncurses_LIBS ; do
2405                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2406                 if test "$q" != "$LIBS" ; then
2407                         LIBS="$q"
2408                 fi
2409         done
2410         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2411                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2412                 [AC_MSG_RESULT(yes)],
2413                 [AC_MSG_RESULT(no)
2414                  LIBS="$cf_ncurses_SAVE"])
2415 fi
2416
2417 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2418 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2419 ])dnl
2420 dnl ---------------------------------------------------------------------------
2421 dnl CF_NCURSES_PTHREADS version: 2 updated: 2016/04/22 05:07:41
2422 dnl -------------------
2423 dnl Use this followup check to ensure that we link with pthreads if ncurses
2424 dnl uses it.
2425 AC_DEFUN([CF_NCURSES_PTHREADS],[
2426 : ${cf_nculib_root:=ifelse($1,,ncurses,$1)}
2427 AC_CHECK_LIB($cf_nculib_root,_nc_init_pthreads,
2428         cf_cv_ncurses_pthreads=yes,
2429         cf_cv_ncurses_pthreads=no)
2430 if test "$cf_cv_ncurses_pthreads" = yes
2431 then
2432         CF_ADD_LIBS(-lpthread)
2433 fi
2434 ])dnl
2435 dnl ---------------------------------------------------------------------------
2436 dnl CF_NCURSES_VERSION version: 15 updated: 2017/05/09 19:26:10
2437 dnl ------------------
2438 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2439 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2440 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2441 AC_DEFUN([CF_NCURSES_VERSION],
2442 [
2443 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2444 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2445         cf_cv_ncurses_version=no
2446         cf_tempfile=out$$
2447         rm -f $cf_tempfile
2448         AC_TRY_RUN([
2449 #include <${cf_cv_ncurses_header:-curses.h}>
2450 #include <stdio.h>
2451 int main(void)
2452 {
2453         FILE *fp = fopen("$cf_tempfile", "w");
2454 #ifdef NCURSES_VERSION
2455 # ifdef NCURSES_VERSION_PATCH
2456         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
2457 # else
2458         fprintf(fp, "%s\n", NCURSES_VERSION);
2459 # endif
2460 #else
2461 # ifdef __NCURSES_H
2462         fprintf(fp, "old\n");
2463 # else
2464         make an error
2465 # endif
2466 #endif
2467         ${cf_cv_main_return:-return}(0);
2468 }],[
2469         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
2470
2471         # This will not work if the preprocessor splits the line after the
2472         # Autoconf token.  The 'unproto' program does that.
2473         cat > conftest.$ac_ext <<EOF
2474 #include <${cf_cv_ncurses_header:-curses.h}>
2475 #undef Autoconf
2476 #ifdef NCURSES_VERSION
2477 Autoconf NCURSES_VERSION
2478 #else
2479 #ifdef __NCURSES_H
2480 Autoconf "old"
2481 #endif
2482 ;
2483 #endif
2484 EOF
2485         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
2486         AC_TRY_EVAL(cf_try)
2487         if test -f conftest.out ; then
2488                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
2489                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
2490                 rm -f conftest.out
2491         fi
2492 ])
2493         rm -f $cf_tempfile
2494 ])
2495 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2496 ])dnl
2497 dnl ---------------------------------------------------------------------------
2498 dnl CF_NCURSES_WRAP_PREFIX version: 1 updated: 2009/03/28 16:08:10
2499 dnl ----------------------
2500 dnl Check for ncurses "wrap-prefix" used for public variables which have been
2501 dnl wrapped with a function to help with concurrency control.
2502 AC_DEFUN([CF_NCURSES_WRAP_PREFIX],
2503 [
2504 AC_MSG_CHECKING(for ncurses wrap-prefix)
2505 AC_ARG_WITH(ncurses-wrap-prefix,
2506         [  --with-ncurses-wrap-prefix naming-prefix for ncurses wrapped-variables],
2507         [NCURSES_WRAP_PREFIX=$withval],
2508         [NCURSES_WRAP_PREFIX=_nc_])
2509 AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
2510
2511 AC_SUBST(NCURSES_WRAP_PREFIX)
2512 ])
2513 dnl ---------------------------------------------------------------------------
2514 dnl CF_NETBSD_FORM_H version: 2 updated: 2012/10/06 16:39:58
2515 dnl ----------------
2516 dnl Check for NetBSD's form.h, which is incompatible with SVr4 and ncurses.
2517 dnl Some workarounds are needed in client programs to allow them to compile.
2518 AC_DEFUN([CF_NETBSD_FORM_H],[
2519 AC_CACHE_CHECK(for NetBSD form.h,cf_cv_netbsd_form_h,[
2520 AC_TRY_COMPILE([
2521 #include <${cf_cv_ncurses_header:-curses.h}>
2522 #include <form.h>
2523 ],[
2524         FORM *form;
2525         int y = current_field(form)->cursor_ypos;
2526         int x = current_field(form)->cursor_xpos;
2527 ],[cf_cv_netbsd_form_h=yes
2528 ],[cf_cv_netbsd_form_h=no])
2529 ])
2530
2531 test "$cf_cv_netbsd_form_h" = yes && AC_DEFINE(HAVE_NETBSD_FORM_H,1,[Define to 1 if we appear to be using NetBSD form.h])
2532 ])dnl
2533 dnl ---------------------------------------------------------------------------
2534 dnl CF_NETBSD_MENU_H version: 2 updated: 2012/10/06 16:39:58
2535 dnl ----------------
2536 dnl Check for NetBSD's menu.h, which is incompatible with SVr4 and ncurses.
2537 dnl Some workarounds are needed in client programs to allow them to compile.
2538 AC_DEFUN([CF_NETBSD_MENU_H],[
2539 AC_CACHE_CHECK(for NetBSD menu.h,cf_cv_netbsd_menu_h,[
2540 AC_TRY_COMPILE([
2541 #include <${cf_cv_ncurses_header:-curses.h}>
2542 #include <menu.h>
2543 ],[
2544         MENU *menu;
2545         int y = menu->max_item_width;
2546 ],[cf_cv_netbsd_menu_h=yes
2547 ],[cf_cv_netbsd_menu_h=no])
2548 ])
2549
2550 test "$cf_cv_netbsd_menu_h" = yes && AC_DEFINE(HAVE_NETBSD_MENU_H,1,[Define to 1 if we appear to be using NetBSD menu.h])
2551 ])dnl
2552 dnl ---------------------------------------------------------------------------
2553 dnl CF_NO_LEAKS_OPTION version: 6 updated: 2015/04/12 15:39:00
2554 dnl ------------------
2555 dnl see CF_WITH_NO_LEAKS
2556 AC_DEFUN([CF_NO_LEAKS_OPTION],[
2557 AC_MSG_CHECKING(if you want to use $1 for testing)
2558 AC_ARG_WITH($1,
2559         [$2],
2560         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
2561          $4
2562 ])
2563         : ${with_cflags:=-g}
2564         : ${with_no_leaks:=yes}
2565          with_$1=yes],
2566         [with_$1=])
2567 AC_MSG_RESULT(${with_$1:-no})
2568
2569 case .$with_cflags in
2570 (.*-g*)
2571         case .$CFLAGS in
2572         (.*-g*)
2573                 ;;
2574         (*)
2575                 CF_ADD_CFLAGS([-g])
2576                 ;;
2577         esac
2578         ;;
2579 esac
2580 ])dnl
2581 dnl ---------------------------------------------------------------------------
2582 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
2583 dnl --------------
2584 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
2585 dnl begins with one of the prefix/exec_prefix variables, and then again if the
2586 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
2587 dnl delayed evaluation of those symbols.
2588 AC_DEFUN([CF_PATH_SYNTAX],[
2589 if test "x$prefix" != xNONE; then
2590         cf_path_syntax="$prefix"
2591 else
2592         cf_path_syntax="$ac_default_prefix"
2593 fi
2594
2595 case ".[$]$1" in
2596 (.\[$]\(*\)*|.\'*\'*)
2597         ;;
2598 (..|./*|.\\*)
2599         ;;
2600 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
2601         ;;
2602 (.\[$]{*prefix}*|.\[$]{*dir}*)
2603         eval $1="[$]$1"
2604         case ".[$]$1" in
2605         (.NONE/*)
2606                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2607                 ;;
2608         esac
2609         ;;
2610 (.no|.NONE/*)
2611         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2612         ;;
2613 (*)
2614         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
2615         ;;
2616 esac
2617 ])dnl
2618 dnl ---------------------------------------------------------------------------
2619 dnl CF_PDCURSES_X11 version: 13 updated: 2012/10/06 16:39:58
2620 dnl ---------------
2621 dnl Configure for PDCurses' X11 library
2622 AC_DEFUN([CF_PDCURSES_X11],[
2623 AC_REQUIRE([CF_X_ATHENA])
2624
2625 CF_ACVERSION_CHECK(2.52,
2626         [AC_CHECK_TOOLS(XCURSES_CONFIG, xcurses-config, none)],
2627         [AC_PATH_PROGS(XCURSES_CONFIG, xcurses-config, none)])
2628
2629 if test "$XCURSES_CONFIG" != none ; then
2630
2631 CPPFLAGS="$CPPFLAGS `$XCURSES_CONFIG --cflags`"
2632 CF_ADD_LIBS(`$XCURSES_CONFIG --libs`)
2633
2634 cf_cv_lib_XCurses=yes
2635
2636 else
2637
2638 LDFLAGS="$LDFLAGS $X_LIBS"
2639 CF_CHECK_CFLAGS($X_CFLAGS)
2640 AC_CHECK_LIB(X11,XOpenDisplay,
2641         [CF_ADD_LIBS(-lX11)],,
2642         [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])
2643 AC_CACHE_CHECK(for XCurses library,cf_cv_lib_XCurses,[
2644 CF_ADD_LIBS(-lXCurses)
2645 AC_TRY_LINK([
2646 #include <xcurses.h>
2647 char *XCursesProgramName = "test";
2648 ],[XCursesExit();],
2649 [cf_cv_lib_XCurses=yes],
2650 [cf_cv_lib_XCurses=no])
2651 ])
2652
2653 fi
2654
2655 if test $cf_cv_lib_XCurses = yes ; then
2656         AC_DEFINE(UNIX,1,[Define to 1 if using PDCurses on Unix])
2657         AC_DEFINE(XCURSES,1,[Define to 1 if using PDCurses on Unix])
2658         AC_CHECK_HEADER(xcurses.h, AC_DEFINE(HAVE_XCURSES,1,[Define to 1 if using PDCurses on Unix]))
2659 else
2660         AC_MSG_ERROR(Cannot link with XCurses)
2661 fi
2662 ])dnl
2663 dnl ---------------------------------------------------------------------------
2664 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
2665 dnl -------------
2666 dnl Check for the package-config program, unless disabled by command-line.
2667 AC_DEFUN([CF_PKG_CONFIG],
2668 [
2669 AC_MSG_CHECKING(if you want to use pkg-config)
2670 AC_ARG_WITH(pkg-config,
2671         [  --with-pkg-config{=path} enable/disable use of pkg-config],
2672         [cf_pkg_config=$withval],
2673         [cf_pkg_config=yes])
2674 AC_MSG_RESULT($cf_pkg_config)
2675
2676 case $cf_pkg_config in
2677 (no)
2678         PKG_CONFIG=none
2679         ;;
2680 (yes)
2681         CF_ACVERSION_CHECK(2.52,
2682                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
2683                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
2684         ;;
2685 (*)
2686         PKG_CONFIG=$withval
2687         ;;
2688 esac
2689
2690 test -z "$PKG_CONFIG" && PKG_CONFIG=none
2691 if test "$PKG_CONFIG" != none ; then
2692         CF_PATH_SYNTAX(PKG_CONFIG)
2693 elif test "x$cf_pkg_config" != xno ; then
2694         AC_MSG_WARN(pkg-config is not installed)
2695 fi
2696
2697 AC_SUBST(PKG_CONFIG)
2698 ])dnl
2699 dnl ---------------------------------------------------------------------------
2700 dnl CF_POSIX_C_SOURCE version: 9 updated: 2015/04/12 15:39:00
2701 dnl -----------------
2702 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
2703 dnl
2704 dnl     POSIX.1-1990                            _POSIX_SOURCE
2705 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
2706 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
2707 dnl             Bindings Option
2708 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
2709 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
2710 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
2711 dnl
2712 dnl Parameters:
2713 dnl     $1 is the nominal value for _POSIX_C_SOURCE
2714 AC_DEFUN([CF_POSIX_C_SOURCE],
2715 [
2716 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
2717
2718 cf_save_CFLAGS="$CFLAGS"
2719 cf_save_CPPFLAGS="$CPPFLAGS"
2720
2721 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
2722 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
2723
2724 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
2725         CF_MSG_LOG(if the symbol is already defined go no further)
2726         AC_TRY_COMPILE([#include <sys/types.h>],[
2727 #ifndef _POSIX_C_SOURCE
2728 make an error
2729 #endif],
2730         [cf_cv_posix_c_source=no],
2731         [cf_want_posix_source=no
2732          case .$cf_POSIX_C_SOURCE in
2733          (.[[12]]??*)
2734                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2735                 ;;
2736          (.2)
2737                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2738                 cf_want_posix_source=yes
2739                 ;;
2740          (.*)
2741                 cf_want_posix_source=yes
2742                 ;;
2743          esac
2744          if test "$cf_want_posix_source" = yes ; then
2745                 AC_TRY_COMPILE([#include <sys/types.h>],[
2746 #ifdef _POSIX_SOURCE
2747 make an error
2748 #endif],[],
2749                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
2750          fi
2751          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
2752          CFLAGS="$cf_trim_CFLAGS"
2753          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
2754          CF_MSG_LOG(if the second compile does not leave our definition intact error)
2755          AC_TRY_COMPILE([#include <sys/types.h>],[
2756 #ifndef _POSIX_C_SOURCE
2757 make an error
2758 #endif],,
2759          [cf_cv_posix_c_source=no])
2760          CFLAGS="$cf_save_CFLAGS"
2761          CPPFLAGS="$cf_save_CPPFLAGS"
2762         ])
2763 ])
2764
2765 if test "$cf_cv_posix_c_source" != no ; then
2766         CFLAGS="$cf_trim_CFLAGS"
2767         CPPFLAGS="$cf_trim_CPPFLAGS"
2768         CF_ADD_CFLAGS($cf_cv_posix_c_source)
2769 fi
2770
2771 ])dnl
2772 dnl ---------------------------------------------------------------------------
2773 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
2774 dnl ------------
2775 dnl Append definitions and rules for the given programs to the subdirectory
2776 dnl Makefiles, and the recursion rule for the top-level Makefile.
2777 dnl
2778 dnl parameters
2779 dnl     $1 = script to run
2780 dnl     $2 = list of subdirectories
2781 dnl
2782 dnl variables
2783 dnl     $AWK
2784 AC_DEFUN([CF_PRG_RULES],
2785 [
2786 for cf_dir in $2
2787 do
2788         if test ! -d $srcdir/$cf_dir; then
2789                 continue
2790         elif test -f $srcdir/$cf_dir/programs; then
2791                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
2792         fi
2793 done
2794
2795 ])dnl
2796 dnl ---------------------------------------------------------------------------
2797 dnl CF_PROG_CC version: 4 updated: 2014/07/12 18:57:58
2798 dnl ----------
2799 dnl standard check for CC, plus followup sanity checks
2800 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
2801 AC_DEFUN([CF_PROG_CC],[
2802 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
2803 CF_GCC_VERSION
2804 CF_ACVERSION_CHECK(2.52,
2805         [AC_PROG_CC_STDC],
2806         [CF_ANSI_CC_REQD])
2807 CF_CC_ENV_FLAGS
2808 ])dnl
2809 dnl ---------------------------------------------------------------------------
2810 dnl CF_PROG_INSTALL version: 7 updated: 2015/04/18 08:56:57
2811 dnl ---------------
2812 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
2813 dnl misc/tabset install won't work properly.  Usually this happens only when
2814 dnl using the fallback mkinstalldirs script
2815 AC_DEFUN([CF_PROG_INSTALL],
2816 [AC_PROG_INSTALL
2817 case $INSTALL in
2818 (/*)
2819         ;;
2820 (*)
2821         CF_DIRNAME(cf_dir,$INSTALL)
2822         test -z "$cf_dir" && cf_dir=.
2823         INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
2824         ;;
2825 esac
2826 ])dnl
2827 dnl ---------------------------------------------------------------------------
2828 dnl CF_PROG_LINT version: 3 updated: 2016/05/22 15:25:54
2829 dnl ------------
2830 AC_DEFUN([CF_PROG_LINT],
2831 [
2832 AC_CHECK_PROGS(LINT, lint cppcheck splint)
2833 AC_SUBST(LINT_OPTS)
2834 ])dnl
2835 dnl ---------------------------------------------------------------------------
2836 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
2837 dnl ----------------
2838 dnl Remove all -U and -D options that refer to the given symbol from a list
2839 dnl of C compiler options.  This works around the problem that not all
2840 dnl compilers process -U and -D options from left-to-right, so a -U option
2841 dnl cannot be used to cancel the effect of a preceding -D option.
2842 dnl
2843 dnl $1 = target (which could be the same as the source variable)
2844 dnl $2 = source (including '$')
2845 dnl $3 = symbol to remove
2846 define([CF_REMOVE_DEFINE],
2847 [
2848 $1=`echo "$2" | \
2849         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
2850                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
2851 ])dnl
2852 dnl ---------------------------------------------------------------------------
2853 dnl CF_RPATH_HACK version: 11 updated: 2013/09/01 13:02:00
2854 dnl -------------
2855 AC_DEFUN([CF_RPATH_HACK],
2856 [
2857 AC_REQUIRE([CF_LD_RPATH_OPT])
2858 AC_MSG_CHECKING(for updated LDFLAGS)
2859 if test -n "$LD_RPATH_OPT" ; then
2860         AC_MSG_RESULT(maybe)
2861
2862         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
2863         cf_rpath_list="/usr/lib /lib"
2864         if test "$cf_ldd_prog" != no
2865         then
2866                 cf_rpath_oops=
2867
2868 AC_TRY_LINK([#include <stdio.h>],
2869                 [printf("Hello");],
2870                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
2871                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
2872
2873                 # If we passed the link-test, but get a "not found" on a given library,
2874                 # this could be due to inept reconfiguration of gcc to make it only
2875                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
2876                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
2877                 # /usr/local libraries.
2878                 if test -n "$cf_rpath_oops"
2879                 then
2880                         for cf_rpath_src in $cf_rpath_oops
2881                         do
2882                                 for cf_rpath_dir in \
2883                                         /usr/local \
2884                                         /usr/pkg \
2885                                         /opt/sfw
2886                                 do
2887                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
2888                                         then
2889                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
2890                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
2891                                                 break
2892                                         fi
2893                                 done
2894                         done
2895                 fi
2896         fi
2897
2898         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
2899
2900         CF_RPATH_HACK_2(LDFLAGS)
2901         CF_RPATH_HACK_2(LIBS)
2902
2903         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
2904 else
2905         AC_MSG_RESULT(no)
2906 fi
2907 AC_SUBST(EXTRA_LDFLAGS)
2908 ])dnl
2909 dnl ---------------------------------------------------------------------------
2910 dnl CF_RPATH_HACK_2 version: 7 updated: 2015/04/12 15:39:00
2911 dnl ---------------
2912 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
2913 dnl EXTRA_LDFLAGS for each -L option found.
2914 dnl
2915 dnl $cf_rpath_list contains a list of directories to ignore.
2916 dnl
2917 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
2918 dnl      but LIBS often has misplaced -L options.
2919 AC_DEFUN([CF_RPATH_HACK_2],
2920 [
2921 CF_VERBOSE(...checking $1 [$]$1)
2922
2923 cf_rpath_dst=
2924 for cf_rpath_src in [$]$1
2925 do
2926         case $cf_rpath_src in
2927         (-L*)
2928
2929                 # check if this refers to a directory which we will ignore
2930                 cf_rpath_skip=no
2931                 if test -n "$cf_rpath_list"
2932                 then
2933                         for cf_rpath_item in $cf_rpath_list
2934                         do
2935                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
2936                                 then
2937                                         cf_rpath_skip=yes
2938                                         break
2939                                 fi
2940                         done
2941                 fi
2942
2943                 if test "$cf_rpath_skip" = no
2944                 then
2945                         # transform the option
2946                         if test "$LD_RPATH_OPT" = "-R " ; then
2947                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
2948                         else
2949                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
2950                         fi
2951
2952                         # if we have not already added this, add it now
2953                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
2954                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
2955                         then
2956                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
2957                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
2958                         fi
2959                 fi
2960                 ;;
2961         esac
2962         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
2963 done
2964 $1=$cf_rpath_dst
2965
2966 CF_VERBOSE(...checked $1 [$]$1)
2967 AC_SUBST(EXTRA_LDFLAGS)
2968 ])dnl
2969 dnl ---------------------------------------------------------------------------
2970 dnl CF_SIGWINCH version: 1 updated: 2006/04/02 16:41:09
2971 dnl -----------
2972 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
2973 dnl programs need this test).
2974 dnl
2975 dnl This is really a MacOS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
2976 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
2977 dnl winsize declaration is left alone - we may revisit this if Apple choose to
2978 dnl break that part of the interface as well.
2979 AC_DEFUN([CF_SIGWINCH],
2980 [
2981 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
2982         AC_TRY_COMPILE([
2983 #include <sys/types.h>
2984 #include <sys/signal.h>
2985 ],[int x = SIGWINCH],
2986         [cf_cv_define_sigwinch=yes],
2987         [AC_TRY_COMPILE([
2988 #undef _XOPEN_SOURCE
2989 #undef _POSIX_SOURCE
2990 #undef _POSIX_C_SOURCE
2991 #include <sys/types.h>
2992 #include <sys/signal.h>
2993 ],[int x = SIGWINCH],
2994         [cf_cv_define_sigwinch=maybe],
2995         [cf_cv_define_sigwinch=no])
2996 ])
2997 ])
2998
2999 if test "$cf_cv_define_sigwinch" = maybe ; then
3000 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
3001 cf_cv_fixup_sigwinch=unknown
3002 cf_sigwinch=32
3003 while test $cf_sigwinch != 1
3004 do
3005         AC_TRY_COMPILE([
3006 #undef _XOPEN_SOURCE
3007 #undef _POSIX_SOURCE
3008 #undef _POSIX_C_SOURCE
3009 #include <sys/types.h>
3010 #include <sys/signal.h>
3011 ],[
3012 #if SIGWINCH != $cf_sigwinch
3013 make an error
3014 #endif
3015 int x = SIGWINCH],
3016         [cf_cv_fixup_sigwinch=$cf_sigwinch
3017          break])
3018
3019 cf_sigwinch=`expr $cf_sigwinch - 1`
3020 done
3021 ])
3022
3023         if test "$cf_cv_fixup_sigwinch" != unknown ; then
3024                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
3025         fi
3026 fi
3027 ])dnl
3028 dnl ---------------------------------------------------------------------------
3029 dnl CF_SIG_ATOMIC_T version: 3 updated: 2012/10/04 20:12:20
3030 dnl ---------------
3031 dnl signal handler, but there are some gcc depedencies in that recommendation.
3032 dnl Try anyway.
3033 AC_DEFUN([CF_SIG_ATOMIC_T],
3034 [
3035 AC_MSG_CHECKING(for signal global datatype)
3036 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
3037         for cf_type in \
3038                 "volatile sig_atomic_t" \
3039                 "sig_atomic_t" \
3040                 "int"
3041         do
3042         AC_TRY_COMPILE([
3043 #include <sys/types.h>
3044 #include <signal.h>
3045 #include <stdio.h>
3046
3047 extern $cf_type x;
3048 $cf_type x;
3049 static void handler(int sig)
3050 {
3051         x = 5;
3052 }],
3053                 [signal(SIGINT, handler);
3054                  x = 1],
3055                 [cf_cv_sig_atomic_t=$cf_type],
3056                 [cf_cv_sig_atomic_t=no])
3057                 test "$cf_cv_sig_atomic_t" != no && break
3058         done
3059         ])
3060 AC_MSG_RESULT($cf_cv_sig_atomic_t)
3061 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
3062 ])dnl
3063 dnl ---------------------------------------------------------------------------
3064 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
3065 dnl --------------
3066 dnl Construct a search-list for a nonstandard header/lib-file
3067 dnl     $1 = the variable to return as result
3068 dnl     $2 = the package name
3069 dnl     $3 = the subdirectory, e.g., bin, include or lib
3070 AC_DEFUN([CF_SUBDIR_PATH],
3071 [
3072 $1=
3073
3074 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
3075
3076 for cf_subdir_prefix in \
3077         /usr \
3078         /usr/local \
3079         /usr/pkg \
3080         /opt \
3081         /opt/local \
3082         [$]HOME
3083 do
3084         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
3085 done
3086 ])dnl
3087 dnl ---------------------------------------------------------------------------
3088 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
3089 dnl ------------------
3090 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
3091 dnl older SCO configurations.
3092 AC_DEFUN([CF_SYS_TIME_SELECT],
3093 [
3094 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
3095 AC_CACHE_VAL(cf_cv_sys_time_select,[
3096 AC_TRY_COMPILE([
3097 #include <sys/types.h>
3098 #ifdef HAVE_SYS_TIME_H
3099 #include <sys/time.h>
3100 #endif
3101 #ifdef HAVE_SYS_SELECT_H
3102 #include <sys/select.h>
3103 #endif
3104 ],[],[cf_cv_sys_time_select=yes],
3105          [cf_cv_sys_time_select=no])
3106          ])
3107 AC_MSG_RESULT($cf_cv_sys_time_select)
3108 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
3109 ])dnl
3110 dnl ---------------------------------------------------------------------------
3111 dnl CF_TERM_HEADER version: 4 updated: 2015/04/15 19:08:48
3112 dnl --------------
3113 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
3114 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
3115 dnl but some packagers change this, breaking various applications.
3116 AC_DEFUN([CF_TERM_HEADER],[
3117 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
3118 case ${cf_cv_ncurses_header} in
3119 (*/ncurses.h|*/ncursesw.h)
3120         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
3121         ;;
3122 (*)
3123         cf_term_header=term.h
3124         ;;
3125 esac
3126
3127 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
3128 do
3129 AC_TRY_COMPILE([#include <stdio.h>
3130 #include <${cf_cv_ncurses_header:-curses.h}>
3131 #include <$cf_test>
3132 ],[int x = auto_left_margin],[
3133         cf_cv_term_header="$cf_test"],[
3134         cf_cv_term_header=unknown
3135         ])
3136         test "$cf_cv_term_header" != unknown && break
3137 done
3138 ])
3139
3140 # Set definitions to allow ifdef'ing to accommodate subdirectories
3141
3142 case $cf_cv_term_header in
3143 (*term.h)
3144         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
3145         ;;
3146 esac
3147
3148 case $cf_cv_term_header in
3149 (ncurses/term.h)
3150         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
3151         ;;
3152 (ncursesw/term.h)
3153         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
3154         ;;
3155 esac
3156 ])dnl
3157 dnl ---------------------------------------------------------------------------
3158 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
3159 dnl ---------------
3160 dnl Define a top_builddir symbol, for applications that need an absolute path.
3161 AC_DEFUN([CF_TOP_BUILDDIR],
3162 [
3163 top_builddir=ifelse($1,,`pwd`,$1)
3164 AC_SUBST(top_builddir)
3165 ])dnl
3166 dnl ---------------------------------------------------------------------------
3167 dnl CF_TPUTS_PROTO version: 3 updated: 2015/04/17 21:26:14
3168 dnl --------------
3169 dnl Check for type of function-pointer passed to tputs.  Some old
3170 dnl implementations used functions that had different prototypes, making it
3171 dnl hard to compile portable programs using tputs.
3172 AC_DEFUN([CF_TPUTS_PROTO],[
3173 CF_CURSES_FUNCS(tputs)
3174 if test x$cf_cv_func_tputs = xyes
3175 then
3176         cf_done=no
3177         for cf_arg in int char
3178         do
3179                 for cf_ret in int void
3180                 do
3181                         if test $cf_ret = void
3182                         then
3183                                 cf_return="/* nothing */"
3184                         else
3185                                 cf_return="return value"
3186                         fi
3187                         AC_TRY_COMPILE([
3188 #include <${cf_cv_ncurses_header:-curses.h}>
3189 #include <$cf_cv_term_header>
3190
3191 static $cf_ret outc($cf_arg value) { $cf_return; }
3192 ],[
3193         tputs("hello", 0, outc);
3194         ${cf_cv_main_return:-return}(0);
3195 ],[
3196                 CF_VERBOSE([prototype $cf_ret func($cf_arg value)])
3197                 cat >>confdefs.h <<EOF
3198 #define TPUTS_ARG               $cf_arg
3199 #define TPUTS_PROTO(func,value) $cf_ret func(TPUTS_ARG value)
3200 #define TPUTS_RETURN(value)     $cf_return
3201 EOF
3202                 cf_done=yes
3203                 break
3204 ])
3205                 done
3206                 test $cf_done = yes && break
3207         done
3208 fi
3209 ])dnl
3210 dnl ---------------------------------------------------------------------------
3211 dnl CF_TRIM_X_LIBS version: 3 updated: 2015/04/12 15:39:00
3212 dnl --------------
3213 dnl Trim extra base X libraries added as a workaround for inconsistent library
3214 dnl dependencies returned by "new" pkg-config files.
3215 AC_DEFUN([CF_TRIM_X_LIBS],[
3216         for cf_trim_lib in Xmu Xt X11
3217         do
3218                 case "$LIBS" in
3219                 (*-l$cf_trim_lib\ *-l$cf_trim_lib*)
3220                         LIBS=`echo "$LIBS " | sed -e 's/  / /g' -e 's%-l'"$cf_trim_lib"' %%' -e 's/ $//'`
3221                         CF_VERBOSE(..trimmed $LIBS)
3222                         ;;
3223                 esac
3224         done
3225 ])
3226 dnl ---------------------------------------------------------------------------
3227 dnl CF_TRY_PKG_CONFIG version: 5 updated: 2013/07/06 21:27:06
3228 dnl -----------------
3229 dnl This is a simple wrapper to use for pkg-config, for libraries which may be
3230 dnl available in that form.
3231 dnl
3232 dnl $1 = package name
3233 dnl $2 = extra logic to use, if any, after updating CFLAGS and LIBS
3234 dnl $3 = logic to use if pkg-config does not have the package
3235 AC_DEFUN([CF_TRY_PKG_CONFIG],[
3236 AC_REQUIRE([CF_PKG_CONFIG])
3237
3238 if test "$PKG_CONFIG" != none && "$PKG_CONFIG" --exists $1; then
3239         CF_VERBOSE(found package $1)
3240         cf_pkgconfig_incs="`$PKG_CONFIG --cflags $1 2>/dev/null`"
3241         cf_pkgconfig_libs="`$PKG_CONFIG --libs   $1 2>/dev/null`"
3242         CF_VERBOSE(package $1 CFLAGS: $cf_pkgconfig_incs)
3243         CF_VERBOSE(package $1 LIBS: $cf_pkgconfig_libs)
3244         CF_ADD_CFLAGS($cf_pkgconfig_incs)
3245         CF_ADD_LIBS($cf_pkgconfig_libs)
3246         ifelse([$2],,:,[$2])
3247 else
3248         cf_pkgconfig_incs=
3249         cf_pkgconfig_libs=
3250         ifelse([$3],,:,[$3])
3251 fi
3252 ])
3253 dnl ---------------------------------------------------------------------------
3254 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
3255 dnl -------------------
3256 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
3257 dnl can define it successfully.
3258 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
3259 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
3260         AC_TRY_COMPILE([
3261 #include <stdlib.h>
3262 #include <string.h>
3263 #include <sys/types.h>
3264 ],[
3265 #ifndef _XOPEN_SOURCE
3266 make an error
3267 #endif],
3268         [cf_cv_xopen_source=no],
3269         [cf_save="$CPPFLAGS"
3270          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3271          AC_TRY_COMPILE([
3272 #include <stdlib.h>
3273 #include <string.h>
3274 #include <sys/types.h>
3275 ],[
3276 #ifdef _XOPEN_SOURCE
3277 make an error
3278 #endif],
3279         [cf_cv_xopen_source=no],
3280         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
3281         CPPFLAGS="$cf_save"
3282         ])
3283 ])
3284
3285 if test "$cf_cv_xopen_source" != no ; then
3286         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
3287         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
3288         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
3289         CF_ADD_CFLAGS($cf_temp_xopen_source)
3290 fi
3291 ])
3292 dnl ---------------------------------------------------------------------------
3293 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
3294 dnl --------
3295 dnl Make an uppercase version of a variable
3296 dnl $1=uppercase($2)
3297 AC_DEFUN([CF_UPPER],
3298 [
3299 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
3300 ])dnl
3301 dnl ---------------------------------------------------------------------------
3302 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
3303 dnl -----------
3304 dnl Check for multibyte support, and if not found, utf8 compatibility library
3305 AC_DEFUN([CF_UTF8_LIB],
3306 [
3307 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
3308         cf_save_LIBS="$LIBS"
3309         AC_TRY_LINK([
3310 #include <stdlib.h>],[putwc(0,0);],
3311         [cf_cv_utf8_lib=yes],
3312         [CF_FIND_LINKAGE([
3313 #include <libutf8.h>],[putwc(0,0);],utf8,
3314                 [cf_cv_utf8_lib=add-on],
3315                 [cf_cv_utf8_lib=no])
3316 ])])
3317
3318 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
3319 # ncurses/ncursesw:
3320 if test "$cf_cv_utf8_lib" = "add-on" ; then
3321         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
3322         CF_ADD_INCDIR($cf_cv_header_path_utf8)
3323         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
3324         CF_ADD_LIBS($cf_cv_library_file_utf8)
3325 fi
3326 ])dnl
3327 dnl ---------------------------------------------------------------------------
3328 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
3329 dnl ----------
3330 dnl Use AC_VERBOSE w/o the warnings
3331 AC_DEFUN([CF_VERBOSE],
3332 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
3333 CF_MSG_LOG([$1])
3334 ])dnl
3335 dnl ---------------------------------------------------------------------------
3336 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
3337 dnl -------------
3338 dnl Check if type wide-character type $1 is declared, and if so, which header
3339 dnl file is needed.  The second parameter is used to set a shell variable when
3340 dnl the type is not found.  The first parameter sets a shell variable for the
3341 dnl opposite sense.
3342 AC_DEFUN([CF_WCHAR_TYPE],
3343 [
3344 # This is needed on Tru64 5.0 to declare $1
3345 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
3346 AC_TRY_COMPILE([
3347 #include <stdlib.h>
3348 #include <stdarg.h>
3349 #include <stdio.h>
3350 #ifdef HAVE_LIBUTF8_H
3351 #include <libutf8.h>
3352 #endif],
3353         [$1 state],
3354         [cf_cv_$1=no],
3355         [AC_TRY_COMPILE([
3356 #include <stdlib.h>
3357 #include <stdarg.h>
3358 #include <stdio.h>
3359 #include <wchar.h>
3360 #ifdef HAVE_LIBUTF8_H
3361 #include <libutf8.h>
3362 #endif],
3363         [$1 value],
3364         [cf_cv_$1=yes],
3365         [cf_cv_$1=unknown])])])
3366
3367 if test "$cf_cv_$1" = yes ; then
3368         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
3369         NEED_WCHAR_H=1
3370 fi
3371
3372 ifelse([$2],,,[
3373 # if we do not find $1 in either place, use substitution to provide a fallback.
3374 if test "$cf_cv_$1" = unknown ; then
3375         $2=1
3376 fi
3377 ])
3378 ifelse($3,,,[
3379 # if we find $1 in either place, use substitution to provide a fallback.
3380 if test "$cf_cv_$1" != unknown ; then
3381         $3=1
3382 fi
3383 ])
3384 ])dnl
3385 dnl ---------------------------------------------------------------------------
3386 dnl CF_WITH_CURSES_DIR version: 3 updated: 2010/11/20 17:02:38
3387 dnl ------------------
3388 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
3389 dnl libraries.
3390 AC_DEFUN([CF_WITH_CURSES_DIR],[
3391
3392 AC_MSG_CHECKING(for specific curses-directory)
3393 AC_ARG_WITH(curses-dir,
3394         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
3395         [cf_cv_curses_dir=$withval],
3396         [cf_cv_curses_dir=no])
3397 AC_MSG_RESULT($cf_cv_curses_dir)
3398
3399 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
3400 then
3401         CF_PATH_SYNTAX(withval)
3402         if test -d "$cf_cv_curses_dir"
3403         then
3404                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
3405                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
3406         fi
3407 fi
3408 ])dnl
3409 dnl ---------------------------------------------------------------------------
3410 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
3411 dnl ----------------
3412 dnl Configure-option for dbmalloc.  The optional parameter is used to override
3413 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
3414 AC_DEFUN([CF_WITH_DBMALLOC],[
3415 CF_NO_LEAKS_OPTION(dbmalloc,
3416         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
3417         [USE_DBMALLOC])
3418
3419 if test "$with_dbmalloc" = yes ; then
3420         AC_CHECK_HEADER(dbmalloc.h,
3421                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
3422 fi
3423 ])dnl
3424 dnl ---------------------------------------------------------------------------
3425 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
3426 dnl ---------------
3427 dnl Configure-option for dmalloc.  The optional parameter is used to override
3428 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
3429 AC_DEFUN([CF_WITH_DMALLOC],[
3430 CF_NO_LEAKS_OPTION(dmalloc,
3431         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
3432         [USE_DMALLOC])
3433
3434 if test "$with_dmalloc" = yes ; then
3435         AC_CHECK_HEADER(dmalloc.h,
3436                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
3437 fi
3438 ])dnl
3439 dnl ---------------------------------------------------------------------------
3440 dnl CF_WITH_NCURSES_ETC version: 5 updated: 2016/02/20 19:23:20
3441 dnl -------------------
3442 dnl Use this macro for programs which use any variant of "curses", e.g.,
3443 dnl "ncurses", and "PDCurses".  Programs that can use curses and some unrelated
3444 dnl library (such as slang) should use a "--with-screen=XXX" option.
3445 dnl
3446 dnl This does not use AC_DEFUN, because that would tell autoconf to run each
3447 dnl of the macros inside this one - before this macro.
3448 define([CF_WITH_NCURSES_ETC],[
3449 CF_WITH_CURSES_DIR
3450
3451 cf_cv_screen=curses
3452
3453 AC_MSG_CHECKING(for specified curses library type)
3454 AC_ARG_WITH(screen,
3455         [  --with-screen=XXX       use specified curses-libraries],
3456         [cf_cv_screen=$withval],[
3457
3458 AC_ARG_WITH(ncursesw,
3459         [  --with-ncursesw         use wide ncurses-libraries],
3460         [cf_cv_screen=ncursesw],[
3461
3462 AC_ARG_WITH(ncurses,
3463         [  --with-ncurses          use ncurses-libraries],
3464         [cf_cv_screen=ncurses],[
3465
3466 AC_ARG_WITH(pdcurses,
3467         [  --with-pdcurses         compile/link with pdcurses X11 library],
3468         [cf_cv_screen=pdcurses],[
3469
3470 AC_ARG_WITH(curses-colr,
3471         [  --with-curses-colr      compile/link with HPUX 10.x color-curses],
3472         [cf_cv_screen=curses_colr],[
3473
3474 AC_ARG_WITH(curses-5lib,
3475         [  --with-curses-5lib      compile/link with SunOS 5lib curses],
3476         [cf_cv_screen=curses_5lib])])])])])])
3477
3478 AC_MSG_RESULT($cf_cv_screen)
3479
3480 case $cf_cv_screen in
3481 (curses|curses_*)
3482         CF_CURSES_CONFIG
3483         ;;
3484 (ncursesw*)
3485         CF_UTF8_LIB
3486         CF_NCURSES_CONFIG($cf_cv_screen)
3487         ;;
3488 (ncurses*)
3489         CF_NCURSES_CONFIG($cf_cv_screen)
3490         ;;
3491 (pdcurses)
3492         CF_PDCURSES_X11
3493         ;;
3494 (*)
3495         AC_MSG_ERROR(unexpected screen-value: $cf_cv_screen)
3496         ;;
3497 esac
3498
3499 CF_NCURSES_PTHREADS($cf_cv_screen)
3500
3501 ])dnl
3502 dnl ---------------------------------------------------------------------------
3503 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
3504 dnl ----------------
3505 AC_DEFUN([CF_WITH_VALGRIND],[
3506 CF_NO_LEAKS_OPTION(valgrind,
3507         [  --with-valgrind         test: use valgrind],
3508         [USE_VALGRIND])
3509 ])dnl
3510 dnl ---------------------------------------------------------------------------
3511 dnl CF_WITH_X11_RGB version: 1 updated: 2017/11/25 17:32:16
3512 dnl ---------------
3513 dnl Handle configure option "--with-x11-rgb", setting these shell
3514 dnl variables:
3515 dnl
3516 dnl $RGB_PATH is the option value, used for finding the X11 rgb file.
3517 dnl $no_x11_rgb is a "#" (comment) if "--without-x11-rgb" is given.
3518 dnl
3519 dnl Most Linux's use this:
3520 dnl     /usr/share/X11/rgb.txt
3521 dnl Debian uses this:
3522 dnl     /etc/X11/rgb.txt
3523 dnl DragonFlyBSD ports uses this:
3524 dnl     /usr/pkg/lib/X11/rgb.txt
3525 dnl FreeBSD ports use these:
3526 dnl     /usr/local/lib/X11/rgb.txt
3527 dnl     /usr/local/share/X11/rgb.txt
3528 dnl Mandriva has these:
3529 dnl     /usr/lib/X11/rgb.txt
3530 dnl     /usr/lib64/X11/rgb.txt
3531 dnl NetBSD has these
3532 dnl     /usr/X11R7/lib/X11/rgb.txt
3533 dnl OpenSolaris uses
3534 dnl     32-bit:
3535 dnl     /usr/X11/etc/X11/rgb.txt
3536 dnl     /usr/X11/share/X11/rgb.txt
3537 dnl     /usr/X11/lib/X11/rgb.txt
3538 dnl OSX uses
3539 dnl             /opt/local/share/X11/rgb.txt (MacPorts)
3540 dnl             /opt/X11/share/X11/rgb.txt (non-ports)
3541 dnl     64-bit:
3542 dnl     /usr/X11/etc/X11/rgb.txt
3543 dnl     /usr/X11/share/X11/rgb.txt (perhaps)
3544 dnl     /usr/X11/lib/amd64/X11/rgb.txt
3545 dnl Solaris10 uses (in this order):
3546 dnl     /usr/openwin/lib/X11/rgb.txt
3547 dnl     /usr/X11/lib/X11/rgb.txt
3548 AC_DEFUN([CF_WITH_X11_RGB],[
3549 AC_MSG_CHECKING(for X11 rgb file)
3550 AC_ARG_WITH(x11-rgb,
3551         [  --with-x11-rgb=FILE   file containing X11 rgb information (EPREFIX/lib/X11/rgb.txt)],
3552         [RGB_PATH=$withval],
3553         [RGB_PATH=auto])
3554
3555 if test "x[$]RGB_PATH" = xauto
3556 then
3557         RGB_PATH='${exec_prefix}/lib/X11/rgb.txt'
3558         for cf_path in \
3559                 /opt/local/share/X11/rgb.txt \
3560                 /opt/X11/share/X11/rgb.txt \
3561                 /usr/share/X11/rgb.txt \
3562                 /usr/X11/share/X11/rgb.txt \
3563                 /usr/X11/lib/X11/rgb.txt \
3564                 /usr/lib/X11/rgb.txt \
3565                 /etc/X11/rgb.txt \
3566                 /usr/pkg/lib/X11/rgb.txt \
3567                 /usr/X11R7/lib/X11/rgb.txt \
3568                 /usr/X11R6/lib/X11/rgb.txt \
3569                 /usr/X11R5/lib/X11/rgb.txt \
3570                 /usr/X11R4/lib/X11/rgb.txt \
3571                 /usr/local/lib/X11/rgb.txt \
3572                 /usr/local/share/X11/rgb.txt \
3573                 /usr/lib64/X11/rgb.txt
3574         do
3575                 if test -f "$cf_path" ; then
3576                         RGB_PATH="$cf_path"
3577                         break
3578                 fi
3579         done
3580 else
3581         cf_path=$RGB_PATH
3582         CF_PATH_SYNTAX(cf_path)
3583 fi
3584
3585 AC_MSG_RESULT($RGB_PATH)
3586 AC_SUBST(RGB_PATH)
3587 AC_DEFINE_UNQUOTED(RGB_PATH,"$cf_path")
3588
3589 no_x11_rgb=
3590 if test "$RGB_PATH" = no
3591 then
3592         no_x11_rgb="#"
3593 fi
3594 AC_SUBST(no_x11_rgb)
3595 ])dnl
3596 dnl ---------------------------------------------------------------------------
3597 dnl CF_XOPEN_CURSES version: 13 updated: 2015/12/12 20:59:52
3598 dnl ---------------
3599 dnl Test if we should define X/Open source for curses, needed on Digital Unix
3600 dnl 4.x, to see the extended functions, but breaks on IRIX 6.x.
3601 dnl
3602 dnl The getbegyx() check is needed for HPUX, which omits legacy macros such
3603 dnl as getbegy().  The latter is better design, but the former is standard.
3604 AC_DEFUN([CF_XOPEN_CURSES],
3605 [
3606 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
3607 AC_CACHE_CHECK(definition to turn on extended curses functions,cf_cv_need_xopen_extension,[
3608 cf_cv_need_xopen_extension=unknown
3609 AC_TRY_LINK([
3610 #include <stdlib.h>
3611 #include <${cf_cv_ncurses_header:-curses.h}>],[
3612 #if defined(NCURSES_VERSION_PATCH)
3613 #if (NCURSES_VERSION_PATCH < 20100501) && (NCURSES_VERSION_PATCH >= 20100403)
3614         make an error
3615 #endif
3616 #endif
3617 #ifdef NCURSES_VERSION
3618         cchar_t check;
3619         int check2 = curs_set((int)sizeof(check));
3620 #endif
3621         long x = winnstr(stdscr, "", 0);
3622         int x1, y1;
3623         getbegyx(stdscr, y1, x1)],
3624         [cf_cv_need_xopen_extension=none],
3625         [
3626         for cf_try_xopen_extension in _XOPEN_SOURCE_EXTENDED NCURSES_WIDECHAR
3627         do
3628                 AC_TRY_LINK([
3629 #define $cf_try_xopen_extension 1
3630 #include <stdlib.h>
3631 #include <${cf_cv_ncurses_header:-curses.h}>],[
3632 #ifdef NCURSES_VERSION
3633                 cchar_t check;
3634                 int check2 = curs_set((int)sizeof(check));
3635 #endif
3636                 long x = winnstr(stdscr, "", 0);
3637                 int x1, y1;
3638                 getbegyx(stdscr, y1, x1)],
3639                 [cf_cv_need_xopen_extension=$cf_try_xopen_extension; break])
3640         done
3641         ])
3642 ])
3643
3644 case $cf_cv_need_xopen_extension in
3645 (*_*)
3646         CPPFLAGS="$CPPFLAGS -D$cf_cv_need_xopen_extension"
3647         ;;
3648 esac
3649
3650 ])dnl
3651 dnl ---------------------------------------------------------------------------
3652 dnl CF_XOPEN_SOURCE version: 52 updated: 2016/08/27 12:21:42
3653 dnl ---------------
3654 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
3655 dnl or adapt to the vendor's definitions to get equivalent functionality,
3656 dnl without losing the common non-POSIX features.
3657 dnl
3658 dnl Parameters:
3659 dnl     $1 is the nominal value for _XOPEN_SOURCE
3660 dnl     $2 is the nominal value for _POSIX_C_SOURCE
3661 AC_DEFUN([CF_XOPEN_SOURCE],[
3662 AC_REQUIRE([AC_CANONICAL_HOST])
3663
3664 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
3665 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
3666 cf_xopen_source=
3667
3668 case $host_os in
3669 (aix[[4-7]]*)
3670         cf_xopen_source="-D_ALL_SOURCE"
3671         ;;
3672 (msys)
3673         cf_XOPEN_SOURCE=600
3674         ;;
3675 (darwin[[0-8]].*)
3676         cf_xopen_source="-D_APPLE_C_SOURCE"
3677         ;;
3678 (darwin*)
3679         cf_xopen_source="-D_DARWIN_C_SOURCE"
3680         cf_XOPEN_SOURCE=
3681         ;;
3682 (freebsd*|dragonfly*)
3683         # 5.x headers associate
3684         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
3685         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
3686         cf_POSIX_C_SOURCE=200112L
3687         cf_XOPEN_SOURCE=600
3688         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3689         ;;
3690 (hpux11*)
3691         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
3692         ;;
3693 (hpux*)
3694         cf_xopen_source="-D_HPUX_SOURCE"
3695         ;;
3696 (irix[[56]].*)
3697         cf_xopen_source="-D_SGI_SOURCE"
3698         cf_XOPEN_SOURCE=
3699         ;;
3700 (linux*|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin)
3701         CF_GNU_SOURCE
3702         ;;
3703 (minix*)
3704         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
3705         ;;
3706 (mirbsd*)
3707         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
3708         cf_XOPEN_SOURCE=
3709         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3710         ;;
3711 (netbsd*)
3712         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
3713         ;;
3714 (openbsd[[4-9]]*)
3715         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
3716         cf_xopen_source="-D_BSD_SOURCE"
3717         cf_XOPEN_SOURCE=600
3718         ;;
3719 (openbsd*)
3720         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
3721         ;;
3722 (osf[[45]]*)
3723         cf_xopen_source="-D_OSF_SOURCE"
3724         ;;
3725 (nto-qnx*)
3726         cf_xopen_source="-D_QNX_SOURCE"
3727         ;;
3728 (sco*)
3729         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
3730         ;;
3731 (solaris2.*)
3732         cf_xopen_source="-D__EXTENSIONS__"
3733         cf_cv_xopen_source=broken
3734         ;;
3735 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
3736         cf_XOPEN_SOURCE=
3737         cf_POSIX_C_SOURCE=
3738         ;;
3739 (*)
3740         CF_TRY_XOPEN_SOURCE
3741         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3742         ;;
3743 esac
3744
3745 if test -n "$cf_xopen_source" ; then
3746         CF_ADD_CFLAGS($cf_xopen_source,true)
3747 fi
3748
3749 dnl In anything but the default case, we may have system-specific setting
3750 dnl which is still not guaranteed to provide all of the entrypoints that
3751 dnl _XOPEN_SOURCE would yield.
3752 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
3753         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
3754         AC_TRY_COMPILE([#include <stdlib.h>],[
3755 #ifndef _XOPEN_SOURCE
3756 make an error
3757 #endif],
3758         [cf_XOPEN_SOURCE_set=yes],
3759         [cf_XOPEN_SOURCE_set=no])
3760         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
3761         if test $cf_XOPEN_SOURCE_set = yes
3762         then
3763                 AC_TRY_COMPILE([#include <stdlib.h>],[
3764 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
3765 make an error
3766 #endif],
3767                 [cf_XOPEN_SOURCE_set_ok=yes],
3768                 [cf_XOPEN_SOURCE_set_ok=no])
3769                 if test $cf_XOPEN_SOURCE_set_ok = no
3770                 then
3771                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
3772                 fi
3773         else
3774                 CF_TRY_XOPEN_SOURCE
3775         fi
3776 fi
3777 ])
3778 dnl ---------------------------------------------------------------------------
3779 dnl CF_X_ATHENA version: 23 updated: 2015/04/12 15:39:00
3780 dnl -----------
3781 dnl Check for Xaw (Athena) libraries
3782 dnl
3783 dnl Sets $cf_x_athena according to the flavor of Xaw which is used.
3784 AC_DEFUN([CF_X_ATHENA],
3785 [
3786 cf_x_athena=${cf_x_athena:-Xaw}
3787
3788 AC_MSG_CHECKING(if you want to link with Xaw 3d library)
3789 withval=
3790 AC_ARG_WITH(Xaw3d,
3791         [  --with-Xaw3d            link with Xaw 3d library])
3792 if test "$withval" = yes ; then
3793         cf_x_athena=Xaw3d
3794         AC_MSG_RESULT(yes)
3795 else
3796         AC_MSG_RESULT(no)
3797 fi
3798
3799 AC_MSG_CHECKING(if you want to link with Xaw 3d xft library)
3800 withval=
3801 AC_ARG_WITH(Xaw3dxft,
3802         [  --with-Xaw3dxft         link with Xaw 3d xft library])
3803 if test "$withval" = yes ; then
3804         cf_x_athena=Xaw3dxft
3805         AC_MSG_RESULT(yes)
3806 else
3807         AC_MSG_RESULT(no)
3808 fi
3809
3810 AC_MSG_CHECKING(if you want to link with neXT Athena library)
3811 withval=
3812 AC_ARG_WITH(neXtaw,
3813         [  --with-neXtaw           link with neXT Athena library])
3814 if test "$withval" = yes ; then
3815         cf_x_athena=neXtaw
3816         AC_MSG_RESULT(yes)
3817 else
3818         AC_MSG_RESULT(no)
3819 fi
3820
3821 AC_MSG_CHECKING(if you want to link with Athena-Plus library)
3822 withval=
3823 AC_ARG_WITH(XawPlus,
3824         [  --with-XawPlus          link with Athena-Plus library])
3825 if test "$withval" = yes ; then
3826         cf_x_athena=XawPlus
3827         AC_MSG_RESULT(yes)
3828 else
3829         AC_MSG_RESULT(no)
3830 fi
3831
3832 cf_x_athena_lib=""
3833
3834 if test "$PKG_CONFIG" != none ; then
3835         cf_athena_list=
3836         test "$cf_x_athena" = Xaw && cf_athena_list="xaw8 xaw7 xaw6"
3837         for cf_athena_pkg in \
3838                 $cf_athena_list \
3839                 ${cf_x_athena} \
3840                 ${cf_x_athena}-devel \
3841                 lib${cf_x_athena} \
3842                 lib${cf_x_athena}-devel
3843         do
3844                 CF_TRY_PKG_CONFIG($cf_athena_pkg,[
3845                         cf_x_athena_lib="$cf_pkgconfig_libs"
3846                         CF_UPPER(cf_x_athena_LIBS,HAVE_LIB_$cf_x_athena)
3847                         AC_DEFINE_UNQUOTED($cf_x_athena_LIBS)
3848
3849                         CF_TRIM_X_LIBS
3850
3851 AC_CACHE_CHECK(for usable $cf_x_athena/Xmu package,cf_cv_xaw_compat,[
3852 AC_TRY_LINK([
3853 #include <X11/Xmu/CharSet.h>
3854 ],[
3855 int check = XmuCompareISOLatin1("big", "small")
3856 ],[cf_cv_xaw_compat=yes],[cf_cv_xaw_compat=no])])
3857
3858                         if test "$cf_cv_xaw_compat" = no
3859                         then
3860                                 # workaround for broken ".pc" files...
3861                                 case "$cf_x_athena_lib" in
3862                                 (*-lXmu*)
3863                                         ;;
3864                                 (*)
3865                                         CF_VERBOSE(work around broken package)
3866                                         cf_save_xmu="$LIBS"
3867                                         cf_first_lib=`echo "$cf_save_xmu" | sed -e 's/^[ ][ ]*//' -e 's/ .*//'`
3868                                         CF_TRY_PKG_CONFIG(xmu,[
3869                                                         LIBS="$cf_save_xmu"
3870                                                         CF_ADD_LIB_AFTER($cf_first_lib,$cf_pkgconfig_libs)
3871                                                 ],[
3872                                                         CF_ADD_LIB_AFTER($cf_first_lib,-lXmu)
3873                                                 ])
3874                                         CF_TRIM_X_LIBS
3875                                         ;;
3876                                 esac
3877                         fi
3878
3879                         break])
3880         done
3881 fi
3882
3883 if test -z "$cf_x_athena_lib" ; then
3884         CF_X_EXT
3885         CF_X_TOOLKIT
3886         CF_X_ATHENA_CPPFLAGS($cf_x_athena)
3887         CF_X_ATHENA_LIBS($cf_x_athena)
3888 fi
3889 ])dnl
3890 dnl ---------------------------------------------------------------------------
3891 dnl CF_X_ATHENA_CPPFLAGS version: 5 updated: 2010/05/26 17:35:30
3892 dnl --------------------
3893 dnl Normally invoked by CF_X_ATHENA, with $1 set to the appropriate flavor of
3894 dnl the Athena widgets, e.g., Xaw, Xaw3d, neXtaw.
3895 AC_DEFUN([CF_X_ATHENA_CPPFLAGS],
3896 [
3897 cf_x_athena_root=ifelse([$1],,Xaw,[$1])
3898 cf_x_athena_inc=""
3899
3900 for cf_path in default \
3901         /usr/contrib/X11R6 \
3902         /usr/contrib/X11R5 \
3903         /usr/lib/X11R5 \
3904         /usr/local
3905 do
3906         if test -z "$cf_x_athena_inc" ; then
3907                 cf_save="$CPPFLAGS"
3908                 cf_test=X11/$cf_x_athena_root/SimpleMenu.h
3909                 if test $cf_path != default ; then
3910                         CPPFLAGS="$cf_save -I$cf_path/include"
3911                         AC_MSG_CHECKING(for $cf_test in $cf_path)
3912                 else
3913                         AC_MSG_CHECKING(for $cf_test)
3914                 fi
3915                 AC_TRY_COMPILE([
3916 #include <X11/Intrinsic.h>
3917 #include <$cf_test>],[],
3918                         [cf_result=yes],
3919                         [cf_result=no])
3920                 AC_MSG_RESULT($cf_result)
3921                 if test "$cf_result" = yes ; then
3922                         cf_x_athena_inc=$cf_path
3923                         break
3924                 else
3925                         CPPFLAGS="$cf_save"
3926                 fi
3927         fi
3928 done
3929
3930 if test -z "$cf_x_athena_inc" ; then
3931         AC_MSG_WARN(
3932 [Unable to successfully find Athena header files with test program])
3933 elif test "$cf_x_athena_inc" != default ; then
3934         CPPFLAGS="$CPPFLAGS -I$cf_x_athena_inc"
3935 fi
3936 ])
3937 dnl ---------------------------------------------------------------------------
3938 dnl CF_X_ATHENA_LIBS version: 12 updated: 2011/07/17 19:55:02
3939 dnl ----------------
3940 dnl Normally invoked by CF_X_ATHENA, with $1 set to the appropriate flavor of
3941 dnl the Athena widgets, e.g., Xaw, Xaw3d, neXtaw.
3942 AC_DEFUN([CF_X_ATHENA_LIBS],
3943 [AC_REQUIRE([CF_X_TOOLKIT])
3944 cf_x_athena_root=ifelse([$1],,Xaw,[$1])
3945 cf_x_athena_lib=""
3946
3947 for cf_path in default \
3948         /usr/contrib/X11R6 \
3949         /usr/contrib/X11R5 \
3950         /usr/lib/X11R5 \
3951         /usr/local
3952 do
3953         for cf_lib in \
3954                 ${cf_x_athena_root} \
3955                 ${cf_x_athena_root}7 \
3956                 ${cf_x_athena_root}6
3957         do
3958         for cf_libs in \
3959                 "-l$cf_lib -lXmu" \
3960                 "-l$cf_lib -lXpm -lXmu" \
3961                 "-l${cf_lib}_s -lXmu_s"
3962         do
3963                 if test -z "$cf_x_athena_lib" ; then
3964                         cf_save="$LIBS"
3965                         cf_test=XawSimpleMenuAddGlobalActions
3966                         if test $cf_path != default ; then
3967                                 CF_ADD_LIBS(-L$cf_path/lib $cf_libs)
3968                                 AC_MSG_CHECKING(for $cf_libs in $cf_path)
3969                         else
3970                                 CF_ADD_LIBS($cf_libs)
3971                                 AC_MSG_CHECKING(for $cf_test in $cf_libs)
3972                         fi
3973                         AC_TRY_LINK([
3974 #include <X11/Intrinsic.h>
3975 #include <X11/$cf_x_athena_root/SimpleMenu.h>
3976 ],[
3977 $cf_test((XtAppContext) 0)],
3978                                 [cf_result=yes],
3979                                 [cf_result=no])
3980                         AC_MSG_RESULT($cf_result)
3981                         if test "$cf_result" = yes ; then
3982                                 cf_x_athena_lib="$cf_libs"
3983                                 break
3984                         fi
3985                         LIBS="$cf_save"
3986                 fi
3987         done # cf_libs
3988                 test -n "$cf_x_athena_lib" && break
3989         done # cf_lib
3990 done
3991
3992 if test -z "$cf_x_athena_lib" ; then
3993         AC_MSG_ERROR(
3994 [Unable to successfully link Athena library (-l$cf_x_athena_root) with test program])
3995 fi
3996
3997 CF_UPPER(cf_x_athena_LIBS,HAVE_LIB_$cf_x_athena)
3998 AC_DEFINE_UNQUOTED($cf_x_athena_LIBS)
3999 ])
4000 dnl ---------------------------------------------------------------------------
4001 dnl CF_X_EXT version: 3 updated: 2010/06/02 05:03:05
4002 dnl --------
4003 AC_DEFUN([CF_X_EXT],[
4004 CF_TRY_PKG_CONFIG(Xext,,[
4005         AC_CHECK_LIB(Xext,XextCreateExtension,
4006                 [CF_ADD_LIB(Xext)])])
4007 ])dnl
4008 dnl ---------------------------------------------------------------------------
4009 dnl CF_X_TOOLKIT version: 23 updated: 2015/04/12 15:39:00
4010 dnl ------------
4011 dnl Check for X Toolkit libraries
4012 AC_DEFUN([CF_X_TOOLKIT],
4013 [
4014 AC_REQUIRE([AC_PATH_XTRA])
4015 AC_REQUIRE([CF_CHECK_CACHE])
4016
4017 # OSX is schizoid about who owns /usr/X11 (old) versus /opt/X11 (new), and (and
4018 # in some cases has installed dummy files in the former, other cases replaced
4019 # it with a link to the new location).  This complicates the configure script.
4020 # Check for that pitfall, and recover using pkg-config
4021 #
4022 # If none of these are set, the configuration is almost certainly broken.
4023 if test -z "${X_CFLAGS}${X_PRE_LIBS}${X_LIBS}${X_EXTRA_LIBS}"
4024 then
4025         CF_TRY_PKG_CONFIG(x11,,[AC_MSG_WARN(unable to find X11 library)])
4026         CF_TRY_PKG_CONFIG(ice,,[AC_MSG_WARN(unable to find ICE library)])
4027         CF_TRY_PKG_CONFIG(sm,,[AC_MSG_WARN(unable to find SM library)])
4028         CF_TRY_PKG_CONFIG(xt,,[AC_MSG_WARN(unable to find Xt library)])
4029 fi
4030
4031 cf_have_X_LIBS=no
4032
4033 CF_TRY_PKG_CONFIG(xt,[
4034
4035         case "x$LIBS" in
4036         (*-lX11*)
4037                 ;;
4038         (*)
4039 # we have an "xt" package, but it may omit Xt's dependency on X11
4040 AC_CACHE_CHECK(for usable X dependency,cf_cv_xt_x11_compat,[
4041 AC_TRY_LINK([
4042 #include <X11/Xlib.h>
4043 ],[
4044         int rc1 = XDrawLine((Display*) 0, (Drawable) 0, (GC) 0, 0, 0, 0, 0);
4045         int rc2 = XClearWindow((Display*) 0, (Window) 0);
4046         int rc3 = XMoveWindow((Display*) 0, (Window) 0, 0, 0);
4047         int rc4 = XMoveResizeWindow((Display*)0, (Window)0, 0, 0, 0, 0);
4048 ],[cf_cv_xt_x11_compat=yes],[cf_cv_xt_x11_compat=no])])
4049                 if test "$cf_cv_xt_x11_compat" = no
4050                 then
4051                         CF_VERBOSE(work around broken X11 dependency)
4052                         # 2010/11/19 - good enough until a working Xt on Xcb is delivered.
4053                         CF_TRY_PKG_CONFIG(x11,,[CF_ADD_LIB_AFTER(-lXt,-lX11)])
4054                 fi
4055                 ;;
4056         esac
4057
4058 AC_CACHE_CHECK(for usable X Toolkit package,cf_cv_xt_ice_compat,[
4059 AC_TRY_LINK([
4060 #include <X11/Shell.h>
4061 ],[int num = IceConnectionNumber(0)
4062 ],[cf_cv_xt_ice_compat=yes],[cf_cv_xt_ice_compat=no])])
4063
4064         if test "$cf_cv_xt_ice_compat" = no
4065         then
4066                 # workaround for broken ".pc" files used for X Toolkit.
4067                 case "x$X_PRE_LIBS" in
4068                 (*-lICE*)
4069                         case "x$LIBS" in
4070                         (*-lICE*)
4071                                 ;;
4072                         (*)
4073                                 CF_VERBOSE(work around broken ICE dependency)
4074                                 CF_TRY_PKG_CONFIG(ice,
4075                                         [CF_TRY_PKG_CONFIG(sm)],
4076                                         [CF_ADD_LIB_AFTER(-lXt,$X_PRE_LIBS)])
4077                                 ;;
4078                         esac
4079                         ;;
4080                 esac
4081         fi
4082
4083         cf_have_X_LIBS=yes
4084 ],[
4085
4086         LDFLAGS="$X_LIBS $LDFLAGS"
4087         CF_CHECK_CFLAGS($X_CFLAGS)
4088
4089         AC_CHECK_FUNC(XOpenDisplay,,[
4090         AC_CHECK_LIB(X11,XOpenDisplay,
4091                 [CF_ADD_LIB(X11)],,
4092                 [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])])
4093
4094         AC_CHECK_FUNC(XtAppInitialize,,[
4095         AC_CHECK_LIB(Xt, XtAppInitialize,
4096                 [AC_DEFINE(HAVE_LIBXT,1,[Define to 1 if we can compile with the Xt library])
4097                  cf_have_X_LIBS=Xt
4098                  LIBS="-lXt $X_PRE_LIBS $LIBS $X_EXTRA_LIBS"],,
4099                 [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])])
4100 ])
4101
4102 if test $cf_have_X_LIBS = no ; then
4103         AC_MSG_WARN(
4104 [Unable to successfully link X Toolkit library (-lXt) with
4105 test program.  You will have to check and add the proper libraries by hand
4106 to makefile.])
4107 fi
4108 ])dnl
4109 dnl ---------------------------------------------------------------------------
4110 dnl CF__CURSES_HEAD version: 2 updated: 2010/10/23 15:54:49
4111 dnl ---------------
4112 dnl Define a reusable chunk which includes <curses.h> and <term.h> when they
4113 dnl are both available.
4114 define([CF__CURSES_HEAD],[
4115 #ifdef HAVE_XCURSES
4116 #include <xcurses.h>
4117 char * XCursesProgramName = "test";
4118 #else
4119 #include <${cf_cv_ncurses_header:-curses.h}>
4120 #if defined(NCURSES_VERSION) && defined(HAVE_NCURSESW_TERM_H)
4121 #include <ncursesw/term.h>
4122 #elif defined(NCURSES_VERSION) && defined(HAVE_NCURSES_TERM_H)
4123 #include <ncurses/term.h>
4124 #elif defined(HAVE_TERM_H)
4125 #include <term.h>
4126 #endif
4127 #endif
4128 ])