]> ncurses.scripts.mit.edu Git - ncurses.git/blob - test/aclocal.m4
ncurses 6.2 - patch 20200829
[ncurses.git] / test / aclocal.m4
1 dnl***************************************************************************
2 dnl Copyright 2018-2019,2020 Thomas E. Dickey                                *
3 dnl Copyright 2003-2017,2018 Free Software Foundation, Inc.                  *
4 dnl                                                                          *
5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
6 dnl copy of this software and associated documentation files (the            *
7 dnl "Software"), to deal in the Software without restriction, including      *
8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
10 dnl copies of the Software, and to permit persons to whom the Software is    *
11 dnl furnished to do so, subject to the following conditions:                 *
12 dnl                                                                          *
13 dnl The above copyright notice and this permission notice shall be included  *
14 dnl in all copies or substantial portions of the Software.                   *
15 dnl                                                                          *
16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
23 dnl                                                                          *
24 dnl Except as contained in this notice, the name(s) of the above copyright   *
25 dnl holders shall not be used in advertising or otherwise to promote the     *
26 dnl sale, use or other dealings in this Software without prior written       *
27 dnl authorization.                                                           *
28 dnl***************************************************************************
29 dnl
30 dnl $Id: aclocal.m4,v 1.182 2020/08/29 13:24:15 tom Exp $
31 dnl
32 dnl Author: Thomas E. Dickey
33 dnl
34 dnl Macros used in NCURSES test programs auto-configuration script.
35 dnl
36 dnl These macros are maintained separately from NCURSES.  The copyright on
37 dnl this file applies to the aggregation of macros and does not affect use of
38 dnl these macros in other applications.
39 dnl
40 dnl See these pages for additional information:
41 dnl             https://invisible-island.net/autoconf/
42 dnl             https://invisible-island.net/autoconf/my-autoconf.html
43 dnl
44 dnl ---------------------------------------------------------------------------
45 dnl ---------------------------------------------------------------------------
46 dnl AM_LANGINFO_CODESET version: 5 updated: 2020/03/10 18:53:47
47 dnl -------------------
48 dnl Inserted as requested by gettext 0.10.40
49 dnl File from /usr/share/aclocal
50 dnl codeset.m4
51 dnl ====================
52 dnl serial AM1
53 dnl
54 dnl From Bruno Haible.
55 AC_DEFUN([AM_LANGINFO_CODESET],
56 [
57 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
58         [AC_TRY_LINK([#include <langinfo.h>],
59         [char* cs = nl_langinfo(CODESET); (void)cs],
60         am_cv_langinfo_codeset=yes,
61         am_cv_langinfo_codeset=no)
62         ])
63         if test $am_cv_langinfo_codeset = yes; then
64                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
65                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
66         fi
67 ])dnl
68 dnl ---------------------------------------------------------------------------
69 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
70 dnl ------------------
71 dnl Conditionally generate script according to whether we're using a given autoconf.
72 dnl
73 dnl $1 = version to compare against
74 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
75 dnl $3 = code to use if AC_ACVERSION is older than $1.
76 define([CF_ACVERSION_CHECK],
77 [
78 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
79 ifdef([m4_version_compare],
80 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
81 [CF_ACVERSION_COMPARE(
82 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
83 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
84 dnl ---------------------------------------------------------------------------
85 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
86 dnl --------------------
87 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
88 dnl                      MAJOR2, MINOR2, TERNARY2,
89 dnl                      PRINTABLE2, not FOUND, FOUND)
90 define([CF_ACVERSION_COMPARE],
91 [ifelse(builtin([eval], [$2 < $5]), 1,
92 [ifelse([$8], , ,[$8])],
93 [ifelse([$9], , ,[$9])])])dnl
94 dnl ---------------------------------------------------------------------------
95 dnl CF_ADD_CFLAGS version: 14 updated: 2020/04/04 16:16:13
96 dnl -------------
97 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
98 dnl $1 = flags to add
99 dnl $2 = if given makes this macro verbose.
100 dnl
101 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
102 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
103 dnl confused by the quotes (which require backslashes to keep them usable).
104 AC_DEFUN([CF_ADD_CFLAGS],
105 [
106 cf_fix_cppflags=no
107 cf_new_cflags=
108 cf_new_cppflags=
109 cf_new_extra_cppflags=
110
111 for cf_add_cflags in $1
112 do
113 case $cf_fix_cppflags in
114 (no)
115         case $cf_add_cflags in
116         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
117                 case $cf_add_cflags in
118                 (-D*)
119                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
120
121                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
122                                 && test -z "${cf_tst_cflags}" \
123                                 && cf_fix_cppflags=yes
124
125                         if test $cf_fix_cppflags = yes ; then
126                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
127                                 continue
128                         elif test "${cf_tst_cflags}" = "\"'" ; then
129                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
130                                 continue
131                         fi
132                         ;;
133                 esac
134                 case "$CPPFLAGS" in
135                 (*$cf_add_cflags)
136                         ;;
137                 (*)
138                         case $cf_add_cflags in
139                         (-D*)
140                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
141                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
142                                 ;;
143                         esac
144                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
145                         ;;
146                 esac
147                 ;;
148         (*)
149                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
150                 ;;
151         esac
152         ;;
153 (yes)
154         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
155
156         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
157
158         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
159                 && test -z "${cf_tst_cflags}" \
160                 && cf_fix_cppflags=no
161         ;;
162 esac
163 done
164
165 if test -n "$cf_new_cflags" ; then
166         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
167         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
168 fi
169
170 if test -n "$cf_new_cppflags" ; then
171         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
172         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
173 fi
174
175 if test -n "$cf_new_extra_cppflags" ; then
176         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
177         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
178 fi
179
180 AC_SUBST(EXTRA_CPPFLAGS)
181
182 ])dnl
183 dnl ---------------------------------------------------------------------------
184 dnl CF_ADD_INCDIR version: 15 updated: 2018/06/20 20:23:13
185 dnl -------------
186 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
187 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
188 dnl but old versions (and some misinstalled ones) need that.  To make things
189 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
190 dnl the include-path).
191 AC_DEFUN([CF_ADD_INCDIR],
192 [
193 if test -n "$1" ; then
194   for cf_add_incdir in $1
195   do
196         while test $cf_add_incdir != /usr/include
197         do
198           if test -d $cf_add_incdir
199           then
200                 cf_have_incdir=no
201                 if test -n "$CFLAGS$CPPFLAGS" ; then
202                   # a loop is needed to ensure we can add subdirs of existing dirs
203                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
204                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
205                           cf_have_incdir=yes; break
206                         fi
207                   done
208                 fi
209
210                 if test "$cf_have_incdir" = no ; then
211                   if test "$cf_add_incdir" = /usr/local/include ; then
212                         if test "$GCC" = yes
213                         then
214                           cf_save_CPPFLAGS=$CPPFLAGS
215                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
216                           AC_TRY_COMPILE([#include <stdio.h>],
217                                   [printf("Hello")],
218                                   [],
219                                   [cf_have_incdir=yes])
220                           CPPFLAGS=$cf_save_CPPFLAGS
221                         fi
222                   fi
223                 fi
224
225                 if test "$cf_have_incdir" = no ; then
226                   CF_VERBOSE(adding $cf_add_incdir to include-path)
227                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
228
229                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
230                   test "$cf_top_incdir" = "$cf_add_incdir" && break
231                   cf_add_incdir="$cf_top_incdir"
232                 else
233                   break
234                 fi
235           else
236                 break
237           fi
238         done
239   done
240 fi
241 ])dnl
242 dnl ---------------------------------------------------------------------------
243 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
244 dnl ----------
245 dnl Add a library, used to enforce consistency.
246 dnl
247 dnl $1 = library to add, without the "-l"
248 dnl $2 = variable to update (default $LIBS)
249 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
250 dnl ---------------------------------------------------------------------------
251 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
252 dnl -------------
253 dnl     Adds to the library-path
254 dnl
255 dnl     Some machines have trouble with multiple -L options.
256 dnl
257 dnl $1 is the (list of) directory(s) to add
258 dnl $2 is the optional name of the variable to update (default LDFLAGS)
259 dnl
260 AC_DEFUN([CF_ADD_LIBDIR],
261 [
262 if test -n "$1" ; then
263         for cf_add_libdir in $1
264         do
265                 if test $cf_add_libdir = /usr/lib ; then
266                         :
267                 elif test -d $cf_add_libdir
268                 then
269                         cf_have_libdir=no
270                         if test -n "$LDFLAGS$LIBS" ; then
271                                 # a loop is needed to ensure we can add subdirs of existing dirs
272                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
273                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
274                                                 cf_have_libdir=yes; break
275                                         fi
276                                 done
277                         fi
278                         if test "$cf_have_libdir" = no ; then
279                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
280                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
281                         fi
282                 fi
283         done
284 fi
285 ])dnl
286 dnl ---------------------------------------------------------------------------
287 dnl CF_ADD_LIBS version: 3 updated: 2019/11/02 16:47:33
288 dnl -----------
289 dnl Add one or more libraries, used to enforce consistency.  Libraries are
290 dnl prepended to an existing list, since their dependencies are assumed to
291 dnl already exist in the list.
292 dnl
293 dnl $1 = libraries to add, with the "-l", etc.
294 dnl $2 = variable to update (default $LIBS)
295 AC_DEFUN([CF_ADD_LIBS],[
296 cf_add_libs="[$]ifelse($2,,LIBS,[$2])"
297 # reverse order
298 cf_add_0lib=
299 for cf_add_1lib in $1; do cf_add_0lib="$cf_add_1lib $cf_add_0lib"; done
300 # filter duplicates
301 for cf_add_1lib in $cf_add_0lib; do
302         for cf_add_2lib in $cf_add_libs; do
303                 if test "x$cf_add_1lib" = "x$cf_add_2lib"; then
304                         cf_add_1lib=
305                         break
306                 fi
307         done
308         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_1lib $cf_add_libs"
309 done
310 ifelse($2,,LIBS,[$2])="$cf_add_libs"
311 ])dnl
312 dnl ---------------------------------------------------------------------------
313 dnl CF_ADD_LIB_AFTER version: 3 updated: 2013/07/09 21:27:22
314 dnl ----------------
315 dnl Add a given library after another, e.g., following the one it satisfies a
316 dnl dependency for.
317 dnl
318 dnl $1 = the first library
319 dnl $2 = its dependency
320 AC_DEFUN([CF_ADD_LIB_AFTER],[
321 CF_VERBOSE(...before $LIBS)
322 LIBS=`echo "$LIBS" | sed -e "s/[[       ]][[    ]]*/ /g" -e "s%$1 %$1 $2 %" -e 's%  % %g'`
323 CF_VERBOSE(...after  $LIBS)
324 ])dnl
325 dnl ---------------------------------------------------------------------------
326 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
327 dnl ------------------
328 dnl Append to a search-list for a nonstandard header/lib-file
329 dnl     $1 = the variable to return as result
330 dnl     $2 = the package name
331 dnl     $3 = the subdirectory, e.g., bin, include or lib
332 dnl $4 = the directory under which we will test for subdirectories
333 dnl $5 = a directory that we do not want $4 to match
334 AC_DEFUN([CF_ADD_SUBDIR_PATH],
335 [
336 test "x$4" != "x$5" && \
337 test -d "$4" && \
338 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
339         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
340         test -d $4/$3 &&          $1="[$]$1 $4/$3"
341         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
342         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
343         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
344         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
345 }
346 ])dnl
347 dnl ---------------------------------------------------------------------------
348 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
349 dnl --------------
350 dnl use this macro for appending text without introducing an extra blank at
351 dnl the beginning
352 define([CF_APPEND_TEXT],
353 [
354         test -n "[$]$1" && $1="[$]$1 "
355         $1="[$]{$1}$2"
356 ])dnl
357 dnl ---------------------------------------------------------------------------
358 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
359 dnl --------------
360 dnl Allow user to disable a normally-on option.
361 AC_DEFUN([CF_ARG_DISABLE],
362 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
363 dnl ---------------------------------------------------------------------------
364 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
365 dnl -------------
366 dnl Allow user to enable a normally-off option.
367 AC_DEFUN([CF_ARG_ENABLE],
368 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
369 dnl ---------------------------------------------------------------------------
370 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
371 dnl -------------
372 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
373 dnl values.
374 dnl
375 dnl Parameters:
376 dnl $1 = option name
377 dnl $2 = help-string
378 dnl $3 = action to perform if option is not default
379 dnl $4 = action if perform if option is default
380 dnl $5 = default option value (either 'yes' or 'no')
381 AC_DEFUN([CF_ARG_OPTION],
382 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
383         if test "$enableval" != "$5" ; then
384 ifelse([$3],,[    :]dnl
385 ,[    $3]) ifelse([$4],,,[
386         else
387                 $4])
388         fi],[enableval=$5 ifelse([$4],,,[
389         $4
390 ])dnl
391 ])])dnl
392 dnl ---------------------------------------------------------------------------
393 dnl CF_CC_ENV_FLAGS version: 9 updated: 2018/07/29 18:03:26
394 dnl ---------------
395 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
396 dnl into CC.  This will not help with broken scripts that wrap the compiler
397 dnl with options, but eliminates a more common category of user confusion.
398 dnl
399 dnl In particular, it addresses the problem of being able to run the C
400 dnl preprocessor in a consistent manner.
401 dnl
402 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
403 dnl the nuisance of having inconsistent settings for compiler and preprocessor
404 dnl outweighs that limitation.
405 AC_DEFUN([CF_CC_ENV_FLAGS],
406 [
407 # This should have been defined by AC_PROG_CC
408 : ${CC:=cc}
409
410 AC_MSG_CHECKING(\$CFLAGS variable)
411 case "x$CFLAGS" in
412 (*-[[IUD]]*)
413         AC_MSG_RESULT(broken)
414         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
415         cf_flags="$CFLAGS"
416         CFLAGS=
417         for cf_arg in $cf_flags
418         do
419                 CF_ADD_CFLAGS($cf_arg)
420         done
421         ;;
422 (*)
423         AC_MSG_RESULT(ok)
424         ;;
425 esac
426
427 AC_MSG_CHECKING(\$CC variable)
428 case "$CC" in
429 (*[[\ \ ]]-*)
430         AC_MSG_RESULT(broken)
431         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
432         # humor him...
433         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
434         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
435         CC="$cf_prog"
436         for cf_arg in $cf_flags
437         do
438                 case "x$cf_arg" in
439                 (x-[[IUDfgOW]]*)
440                         CF_ADD_CFLAGS($cf_arg)
441                         ;;
442                 (*)
443                         CC="$CC $cf_arg"
444                         ;;
445                 esac
446         done
447         CF_VERBOSE(resulting CC: '$CC')
448         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
449         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
450         ;;
451 (*)
452         AC_MSG_RESULT(ok)
453         ;;
454 esac
455 ])dnl
456 dnl ---------------------------------------------------------------------------
457 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
458 dnl --------------
459 dnl Check if we're accidentally using a cache from a different machine.
460 dnl Derive the system name, as a check for reusing the autoconf cache.
461 dnl
462 dnl If we've packaged config.guess and config.sub, run that (since it does a
463 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
464 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
465 dnl which is useful in cross-compiles.
466 dnl
467 dnl Note: we would use $ac_config_sub, but that is one of the places where
468 dnl autoconf 2.5x broke compatibility with autoconf 2.13
469 AC_DEFUN([CF_CHECK_CACHE],
470 [
471 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
472         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
473         system_name="$host_os"
474 else
475         system_name="`(uname -s -r) 2>/dev/null`"
476         if test -z "$system_name" ; then
477                 system_name="`(hostname) 2>/dev/null`"
478         fi
479 fi
480 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
481 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
482
483 test -z "$system_name" && system_name="$cf_cv_system_name"
484 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
485
486 if test ".$system_name" != ".$cf_cv_system_name" ; then
487         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
488         AC_MSG_ERROR("Please remove config.cache and try again.")
489 fi
490 ])dnl
491 dnl ---------------------------------------------------------------------------
492 dnl CF_CHECK_CFLAGS version: 3 updated: 2014/07/22 05:32:57
493 dnl ---------------
494 dnl Conditionally add to $CFLAGS and $CPPFLAGS values which are derived from
495 dnl a build-configuration such as imake.  These have the pitfall that they
496 dnl often contain compiler-specific options which we cannot use, mixed with
497 dnl preprocessor options that we usually can.
498 AC_DEFUN([CF_CHECK_CFLAGS],
499 [
500 CF_VERBOSE(checking additions to CFLAGS)
501 cf_check_cflags="$CFLAGS"
502 cf_check_cppflags="$CPPFLAGS"
503 CF_ADD_CFLAGS($1,yes)
504 if test "x$cf_check_cflags" != "x$CFLAGS" ; then
505 AC_TRY_LINK([#include <stdio.h>],[printf("Hello world");],,
506         [CF_VERBOSE(test-compile failed.  Undoing change to \$CFLAGS)
507          if test "x$cf_check_cppflags" != "x$CPPFLAGS" ; then
508                  CF_VERBOSE(but keeping change to \$CPPFLAGS)
509          fi
510          CFLAGS="$cf_check_flags"])
511 fi
512 ])dnl
513 dnl ---------------------------------------------------------------------------
514 dnl CF_CHECK_CURSES_LIB version: 2 updated: 2018/01/03 04:47:33
515 dnl -------------------
516 dnl $1 = nominal library name, used also for header lookup
517 dnl $2 = suffix to append to library name
518 dnl $3 = function to check for using AC_CHECK_LIB
519 dnl $4 = optional parameter list for $3
520 AC_DEFUN([CF_CHECK_CURSES_LIB],
521 [
522 AC_REQUIRE([CF_PKG_CONFIG])
523
524 cf_have_curses_lib=no
525
526 : ${NCURSES_CONFIG_PKG:=none}
527 if test "x${NCURSES_CONFIG_PKG}" = xnone; then
528         :
529 elif test "x${PKG_CONFIG:=none}" != xnone; then
530         AC_MSG_CHECKING(pkg-config for $1$2)
531         if "$PKG_CONFIG" --exists $1$2 ; then
532                 AC_MSG_RESULT(yes)
533
534                 AC_MSG_CHECKING(if the $1$2 package files work)
535
536                 cf_save_CPPFLAGS="$CPPFLAGS"
537                 cf_save_LIBS="$LIBS"
538
539                 CF_ADD_CFLAGS(`$PKG_CONFIG --cflags $1$2`)
540                 CF_ADD_LIBS(`$PKG_CONFIG --libs $1$2`)
541
542                 AC_TRY_LINK([#include <$1.h>],
543                         [(void) $3 ( ]ifelse([$4],,,[[$4]])[ );],
544                         [AC_TRY_RUN([#include <$1.h>
545                                 int main(void)
546                                 { (void) $3 ( ]ifelse([$4],,,[[$4]])[ ); return 0; }],
547                                 [cf_have_curses_lib=yes],
548                                 [cf_have_curses_lib=no],
549                                 [cf_have_curses_lib=maybe])],
550                         [cf_have_curses_lib=no])
551                 AC_MSG_RESULT($cf_have_curses_lib)
552                 test "$cf_have_curses_lib" = maybe && cf_have_curses_lib=yes
553                 if test "$cf_have_curses_lib" != "yes"
554                 then
555                         CPPFLAGS="$cf_save_CPPFLAGS"
556                         LIBS="$cf_save_LIBS"
557                 else
558                         CF_UPPER(cf_upper,have_lib$1)
559                         AC_DEFINE_UNQUOTED($cf_upper,1)
560                 fi
561         fi
562 fi
563 if test "$cf_have_curses_lib" = no; then
564         AC_CHECK_LIB($1$2,$3,[
565                 CF_UPPER(cf_upper,have_lib$1)
566                 CF_ADD_LIBS(-l$1$2)
567                 AC_DEFINE_UNQUOTED($cf_upper,1)])
568 fi
569 ])dnl
570 dnl ---------------------------------------------------------------------------
571 dnl CF_CLANG_COMPILER version: 3 updated: 2020/08/28 04:10:22
572 dnl -----------------
573 dnl Check if the given compiler is really clang.  clang's C driver defines
574 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
575 dnl not ignore some gcc options.
576 dnl
577 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
578 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
579 dnl the wrappers for gcc and g++ warnings.
580 dnl
581 dnl $1 = GCC (default) or GXX
582 dnl $2 = CLANG_COMPILER (default)
583 dnl $3 = CFLAGS (default) or CXXFLAGS
584 AC_DEFUN([CF_CLANG_COMPILER],[
585 ifelse([$2],,CLANG_COMPILER,[$2])=no
586
587 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
588         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
589         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
590         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
591         AC_TRY_COMPILE([],[
592 #ifdef __clang__
593 #else
594 make an error
595 #endif
596 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
597 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
598 ],[])
599         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
600         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
601 fi
602
603 if test "x$CLANG_COMPILER" = "xyes" ; then
604         CF_APPEND_TEXT(CFLAGS,-Wno-error=implicit-function-declaration)
605 fi
606 ])
607 dnl ---------------------------------------------------------------------------
608 dnl CF_CONST_X_STRING version: 4 updated: 2020/03/10 18:53:47
609 dnl -----------------
610 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
611 dnl character-strings.
612 dnl
613 dnl It is ambiguous because the specification accommodated the pre-ANSI
614 dnl compilers bundled by more than one vendor in lieu of providing a standard C
615 dnl compiler other than by costly add-ons.  Because of this, the specification
616 dnl did not take into account the use of const for telling the compiler that
617 dnl string literals would be in readonly memory.
618 dnl
619 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
620 dnl let the compiler decide how to represent Xt's strings which were #define'd. 
621 dnl That does not solve the problem of using the block of Xt's strings which
622 dnl are compiled into the library (and is less efficient than one might want).
623 dnl
624 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
625 dnl when compiling the library and compiling using the library, to tell the
626 dnl compiler that String is const.
627 AC_DEFUN([CF_CONST_X_STRING],
628 [
629 AC_REQUIRE([AC_PATH_XTRA])
630
631 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
632
633 AC_TRY_COMPILE(
634 [
635 #include <stdlib.h>
636 #include <X11/Intrinsic.h>
637 ],
638 [String foo = malloc(1); (void)foo],[
639
640 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
641         AC_TRY_COMPILE(
642                 [
643 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
644 #undef  XTSTRINGDEFINES /* X11R5 and later */
645 #include <stdlib.h>
646 #include <X11/Intrinsic.h>
647                 ],[String foo = malloc(1); *foo = 0],[
648                         cf_cv_const_x_string=no
649                 ],[
650                         cf_cv_const_x_string=yes
651                 ])
652 ])
653
654 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
655
656 case $cf_cv_const_x_string in
657 (no)
658         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
659         ;;
660 (*)
661         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
662         ;;
663 esac
664
665 ])
666 ])dnl
667 dnl ---------------------------------------------------------------------------
668 dnl CF_CURSES_ACS_MAP version: 7 updated: 2012/10/06 16:39:58
669 dnl -----------------
670 dnl Check for likely values of acs_map[]:
671 AC_DEFUN([CF_CURSES_ACS_MAP],
672 [
673 AC_REQUIRE([CF_NCURSES_WRAP_PREFIX])dnl
674 AC_CACHE_CHECK(for alternate character set array, cf_cv_curses_acs_map,[
675 cf_cv_curses_acs_map=unknown
676 for name in acs_map _acs_map __acs_map ${NCURSES_WRAP_PREFIX}acs_map
677 do
678 AC_TRY_LINK([
679 #include <${cf_cv_ncurses_header:-curses.h}>
680 ],[
681 $name['k'] = ACS_PLUS
682 ],[cf_cv_curses_acs_map=$name; break])
683 done
684 ])
685
686 test "$cf_cv_curses_acs_map" != unknown && AC_DEFINE_UNQUOTED(CURSES_ACS_ARRAY,$cf_cv_curses_acs_map,[Define as needed to override ncurses prefix _nc_])
687 ])
688 dnl ---------------------------------------------------------------------------
689 dnl CF_CURSES_CHECK_DATA version: 9 updated: 2020/02/08 21:00:26
690 dnl --------------------
691 dnl Check if curses.h defines the given data/variable.
692 dnl Use this after CF_NCURSES_CONFIG or CF_CURSES_CONFIG.
693 dnl
694 dnl $1 = data item(s) to check for
695 dnl $2 = action on success, e.g., "break" to quit checking a series of choices
696 AC_DEFUN([CF_CURSES_CHECK_DATA],
697 [
698 for cf_data in $1
699 do
700 AC_MSG_CHECKING(for data $cf_data declaration in ${cf_cv_ncurses_header:-curses.h})
701
702 AC_TRY_COMPILE(CF__CURSES_HEAD,
703 CF__CURSES_DATA(foo,$cf_data)
704 ,[cf_result=yes
705 ],[cf_result=no])
706 AC_MSG_RESULT($cf_result)
707
708 if test $cf_result = yes ; then
709         CF_UPPER(cf_result,have_curses_data_$cf_data)
710         AC_DEFINE_UNQUOTED($cf_result)
711         ifelse($2,,,[$2])
712 else
713         AC_MSG_CHECKING(for data $cf_data in library)
714         # BSD linkers insist on making weak linkage, but resolve at runtime.
715         AC_TRY_RUN(CF__CURSES_HEAD
716 [
717 extern char $cf_data;
718 int main(void)
719 {
720         ]CF__CURSES_DATA(foo,$cf_data)[
721         ${cf_cv_main_return:-return}(foo == 0);
722 }],[cf_result=yes
723 ],[cf_result=no],[
724         # cross-compiling
725         AC_TRY_LINK(CF__CURSES_HEAD
726 [extern char $cf_data;],[
727         do {
728                 ]CF__CURSES_DATA(foo,$cf_data)[
729                 ${cf_cv_main_return:-return}(foo == 0);
730         } while (0)
731 ],[cf_result=yes],[cf_result=no])
732 ])
733         AC_MSG_RESULT($cf_result)
734         if test $cf_result = yes ; then
735                 CF_UPPER(cf_result,decl_curses_data_$cf_data)
736                 AC_DEFINE_UNQUOTED($cf_result)
737                 # do not exit loop here, since we prefer system's declarations
738         fi
739 fi
740 done
741 ])dnl
742 dnl ---------------------------------------------------------------------------
743 dnl CF_CURSES_CHECK_TYPE version: 4 updated: 2012/10/06 16:39:58
744 dnl --------------------
745 dnl Check if curses.h defines the given type
746 AC_DEFUN([CF_CURSES_CHECK_TYPE],
747 [
748 AC_MSG_CHECKING(for type $1 in ${cf_cv_ncurses_header:-curses.h})
749 AC_TRY_COMPILE([
750 #ifndef _XOPEN_SOURCE_EXTENDED
751 #define _XOPEN_SOURCE_EXTENDED
752 #endif
753 #include <${cf_cv_ncurses_header:-curses.h}>],[
754 $1 foo
755 ],cf_result=yes,cf_result=no)
756 AC_MSG_RESULT($cf_result)
757 if test $cf_result = yes ; then
758         CF_UPPER(cf_result,have_type_$1)
759         AC_DEFINE_UNQUOTED($cf_result,1,[Define to 1 if we have type $1])
760 else
761         AC_DEFINE_UNQUOTED($1,$2,[Define to appropriate type if $1 is not declared])
762 fi
763 ])dnl
764 dnl ---------------------------------------------------------------------------
765 dnl CF_CURSES_CONFIG version: 2 updated: 2006/10/29 11:06:27
766 dnl ----------------
767 dnl Tie together the configure-script macros for curses.  It may be ncurses,
768 dnl but unless asked, we do not make a special search for ncurses.  However,
769 dnl still check for the ncurses version number, for use in other macros.
770 AC_DEFUN([CF_CURSES_CONFIG],
771 [
772 CF_CURSES_CPPFLAGS
773 CF_NCURSES_VERSION
774 CF_CURSES_LIBS
775 ])dnl
776 dnl ---------------------------------------------------------------------------
777 dnl CF_CURSES_CPPFLAGS version: 13 updated: 2018/06/20 20:23:13
778 dnl ------------------
779 dnl Look for the curses headers.
780 AC_DEFUN([CF_CURSES_CPPFLAGS],[
781
782 AC_CACHE_CHECK(for extra include directories,cf_cv_curses_incdir,[
783 cf_cv_curses_incdir=no
784 case $host_os in
785 (hpux10.*)
786         if test "x$cf_cv_screen" = "xcurses_colr"
787         then
788                 test -d /usr/include/curses_colr && \
789                 cf_cv_curses_incdir="-I/usr/include/curses_colr"
790         fi
791         ;;
792 (sunos3*|sunos4*)
793         if test "x$cf_cv_screen" = "xcurses_5lib"
794         then
795                 test -d /usr/5lib && \
796                 test -d /usr/5include && \
797                 cf_cv_curses_incdir="-I/usr/5include"
798         fi
799         ;;
800 esac
801 ])
802 if test "$cf_cv_curses_incdir" != no
803 then
804         CF_APPEND_TEXT(CPPFLAGS,$cf_cv_curses_incdir)
805 fi
806
807 CF_CURSES_HEADER
808 CF_TERM_HEADER
809 ])dnl
810 dnl ---------------------------------------------------------------------------
811 dnl CF_CURSES_FUNCS version: 19 updated: 2018/01/03 04:47:33
812 dnl ---------------
813 dnl Curses-functions are a little complicated, since a lot of them are macros.
814 AC_DEFUN([CF_CURSES_FUNCS],
815 [
816 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
817 AC_REQUIRE([CF_XOPEN_CURSES])
818 AC_REQUIRE([CF_CURSES_TERM_H])
819 AC_REQUIRE([CF_CURSES_UNCTRL_H])
820 for cf_func in $1
821 do
822         CF_UPPER(cf_tr_func,$cf_func)
823         AC_MSG_CHECKING(for ${cf_func})
824         CF_MSG_LOG(${cf_func})
825         AC_CACHE_VAL(cf_cv_func_$cf_func,[
826                 eval cf_result='$ac_cv_func_'$cf_func
827                 if test ".$cf_result" != ".no"; then
828                         AC_TRY_LINK(CF__CURSES_HEAD,
829                         [
830 #ifndef ${cf_func}
831 long foo = (long)(&${cf_func});
832 fprintf(stderr, "testing linkage of $cf_func:%p\n", (void *)foo);
833 if (foo + 1234L > 5678L)
834         ${cf_cv_main_return:-return}(foo != 0);
835 #endif
836                         ],
837                         [cf_result=yes],
838                         [cf_result=no])
839                 fi
840                 eval 'cf_cv_func_'$cf_func'=$cf_result'
841         ])
842         # use the computed/retrieved cache-value:
843         eval 'cf_result=$cf_cv_func_'$cf_func
844         AC_MSG_RESULT($cf_result)
845         if test $cf_result != no; then
846                 AC_DEFINE_UNQUOTED(HAVE_${cf_tr_func})
847         fi
848 done
849 ])dnl
850 dnl ---------------------------------------------------------------------------
851 dnl CF_CURSES_HEADER version: 5 updated: 2015/04/23 20:35:30
852 dnl ----------------
853 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
854 dnl variations of ncurses' installs.
855 dnl
856 dnl $1 = ncurses when looking for ncurses, or is empty
857 AC_DEFUN([CF_CURSES_HEADER],[
858 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
859 cf_cv_ncurses_header=none
860 for cf_header in \
861         ncurses.h ifelse($1,,,[$1/ncurses.h]) \
862         curses.h ifelse($1,,,[$1/curses.h]) ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
863 do
864 AC_TRY_COMPILE([#include <${cf_header}>],
865         [initscr(); tgoto("?", 0,0)],
866         [cf_cv_ncurses_header=$cf_header; break],[])
867 done
868 ])
869
870 if test "$cf_cv_ncurses_header" = none ; then
871         AC_MSG_ERROR(No curses header-files found)
872 fi
873
874 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
875 AC_CHECK_HEADERS($cf_cv_ncurses_header)
876 ])dnl
877 dnl ---------------------------------------------------------------------------
878 dnl CF_CURSES_LIBS version: 42 updated: 2018/06/20 20:23:13
879 dnl --------------
880 dnl Look for the curses libraries.  Older curses implementations may require
881 dnl termcap/termlib to be linked as well.  Call CF_CURSES_CPPFLAGS first.
882 AC_DEFUN([CF_CURSES_LIBS],[
883
884 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
885 AC_MSG_CHECKING(if we have identified curses libraries)
886 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
887         [initscr(); tgoto("?", 0,0)],
888         cf_result=yes,
889         cf_result=no)
890 AC_MSG_RESULT($cf_result)
891
892 if test "$cf_result" = no ; then
893 case $host_os in
894 (freebsd*)
895         AC_CHECK_LIB(mytinfo,tgoto,[CF_ADD_LIBS(-lmytinfo)])
896         ;;
897 (hpux10.*)
898         # Looking at HPUX 10.20, the Hcurses library is the oldest (1997), cur_colr
899         # next (1998), and xcurses "newer" (2000).  There is no header file for
900         # Hcurses; the subdirectory curses_colr has the headers (curses.h and
901         # term.h) for cur_colr
902         if test "x$cf_cv_screen" = "xcurses_colr"
903         then
904                 AC_CHECK_LIB(cur_colr,initscr,[
905                         CF_ADD_LIBS(-lcur_colr)
906                         ac_cv_func_initscr=yes
907                         ],[
908                 AC_CHECK_LIB(Hcurses,initscr,[
909                         # HP's header uses __HP_CURSES, but user claims _HP_CURSES.
910                         CF_ADD_LIBS(-lHcurses)
911                         CF_APPEND_TEXT(CPPFLAGS,-D__HP_CURSES -D_HP_CURSES)
912                         ac_cv_func_initscr=yes
913                         ])])
914         fi
915         ;;
916 (linux*)
917         case `arch 2>/dev/null` in
918         (x86_64)
919                 if test -d /lib64
920                 then
921                         CF_ADD_LIBDIR(/lib64)
922                 else
923                         CF_ADD_LIBDIR(/lib)
924                 fi
925                 ;;
926         (*)
927                 CF_ADD_LIBDIR(/lib)
928                 ;;
929         esac
930         ;;
931 (sunos3*|sunos4*)
932         if test "x$cf_cv_screen" = "xcurses_5lib"
933         then
934                 if test -d /usr/5lib ; then
935                         CF_ADD_LIBDIR(/usr/5lib)
936                         CF_ADD_LIBS(-lcurses -ltermcap)
937                 fi
938         fi
939         ac_cv_func_initscr=yes
940         ;;
941 esac
942
943 if test ".$ac_cv_func_initscr" != .yes ; then
944         cf_save_LIBS="$LIBS"
945
946         if test ".${cf_cv_ncurses_version:-no}" != .no
947         then
948                 cf_check_list="ncurses curses cursesX"
949         else
950                 cf_check_list="cursesX curses ncurses"
951         fi
952
953         # Check for library containing tgoto.  Do this before curses library
954         # because it may be needed to link the test-case for initscr.
955         if test "x$cf_term_lib" = x
956         then
957                 AC_CHECK_FUNC(tgoto,[cf_term_lib=predefined],[
958                         for cf_term_lib in $cf_check_list otermcap termcap tinfo termlib unknown
959                         do
960                                 AC_CHECK_LIB($cf_term_lib,tgoto,[
961                                         : ${cf_nculib_root:=$cf_term_lib}
962                                         break
963                                 ])
964                         done
965                 ])
966         fi
967
968         # Check for library containing initscr
969         test "$cf_term_lib" != predefined && test "$cf_term_lib" != unknown && LIBS="-l$cf_term_lib $cf_save_LIBS"
970         if test "x$cf_curs_lib" = x
971         then
972                 for cf_curs_lib in $cf_check_list xcurses jcurses pdcurses unknown
973                 do
974                         LIBS="-l$cf_curs_lib $cf_save_LIBS"
975                         if test "$cf_term_lib" = unknown || test "$cf_term_lib" = "$cf_curs_lib" ; then
976                                 AC_MSG_CHECKING(if we can link with $cf_curs_lib library)
977                                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
978                                         [initscr()],
979                                         [cf_result=yes],
980                                         [cf_result=no])
981                                 AC_MSG_RESULT($cf_result)
982                                 test $cf_result = yes && break
983                         elif test "$cf_curs_lib" = "$cf_term_lib" ; then
984                                 cf_result=no
985                         elif test "$cf_term_lib" != predefined ; then
986                                 AC_MSG_CHECKING(if we need both $cf_curs_lib and $cf_term_lib libraries)
987                                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
988                                         [initscr(); tgoto((char *)0, 0, 0);],
989                                         [cf_result=no],
990                                         [
991                                         LIBS="-l$cf_curs_lib -l$cf_term_lib $cf_save_LIBS"
992                                         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
993                                                 [initscr()],
994                                                 [cf_result=yes],
995                                                 [cf_result=error])
996                                         ])
997                                 AC_MSG_RESULT($cf_result)
998                                 test $cf_result != error && break
999                         fi
1000                 done
1001         fi
1002         test $cf_curs_lib = unknown && AC_MSG_ERROR(no curses library found)
1003 fi
1004 fi
1005
1006 ])dnl
1007 dnl ---------------------------------------------------------------------------
1008 dnl CF_CURSES_TERM_H version: 12 updated: 2020/03/19 20:23:48
1009 dnl ----------------
1010 dnl SVr4 curses should have term.h as well (where it puts the definitions of
1011 dnl the low-level interface).  This may not be true in old/broken implementations,
1012 dnl as well as in misconfigured systems (e.g., gcc configured for Solaris 2.4
1013 dnl running with Solaris 2.5.1).
1014 AC_DEFUN([CF_CURSES_TERM_H],
1015 [
1016 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
1017
1018 AC_CACHE_CHECK(for term.h, cf_cv_term_header,[
1019
1020 # If we found <ncurses/curses.h>, look for <ncurses/term.h>, but always look
1021 # for <term.h> if we do not find the variant.
1022
1023 cf_header_list="term.h ncurses/term.h ncursesw/term.h"
1024
1025 case ${cf_cv_ncurses_header:-curses.h} in
1026 (*/*)
1027         cf_header_item=`echo ${cf_cv_ncurses_header:-curses.h} | sed -e 's%\..*%%' -e 's%/.*%/%'`term.h
1028         cf_header_list="$cf_header_item $cf_header_list"
1029         ;;
1030 esac
1031
1032 for cf_header in $cf_header_list
1033 do
1034         AC_TRY_COMPILE([
1035 #include <${cf_cv_ncurses_header:-curses.h}>
1036 #include <${cf_header}>],
1037         [WINDOW *x; (void)x],
1038         [cf_cv_term_header=$cf_header
1039          break],
1040         [cf_cv_term_header=no])
1041 done
1042
1043 case $cf_cv_term_header in
1044 (no)
1045         # If curses is ncurses, some packagers still mess it up by trying to make
1046         # us use GNU termcap.  This handles the most common case.
1047         for cf_header in ncurses/term.h ncursesw/term.h
1048         do
1049                 AC_TRY_COMPILE([
1050 #include <${cf_cv_ncurses_header:-curses.h}>
1051 #ifdef NCURSES_VERSION
1052 #include <${cf_header}>
1053 #else
1054 make an error
1055 #endif],
1056                         [WINDOW *x; (void)x],
1057                         [cf_cv_term_header=$cf_header
1058                          break],
1059                         [cf_cv_term_header=no])
1060         done
1061         ;;
1062 esac
1063 ])
1064
1065 case $cf_cv_term_header in
1066 (term.h)
1067         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
1068         ;;
1069 (ncurses/term.h)
1070         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
1071         ;;
1072 (ncursesw/term.h)
1073         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
1074         ;;
1075 esac
1076 ])dnl
1077 dnl ---------------------------------------------------------------------------
1078 dnl CF_CURSES_UNCTRL_H version: 5 updated: 2020/03/19 20:23:48
1079 dnl ------------------
1080 dnl Any X/Open curses implementation must have unctrl.h, but ncurses packages
1081 dnl may put it in a subdirectory (along with ncurses' other headers, of
1082 dnl course).  Packages which put the headers in inconsistent locations are
1083 dnl broken).
1084 AC_DEFUN([CF_CURSES_UNCTRL_H],
1085 [
1086 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
1087
1088 AC_CACHE_CHECK(for unctrl.h, cf_cv_unctrl_header,[
1089
1090 # If we found <ncurses/curses.h>, look for <ncurses/unctrl.h>, but always look
1091 # for <unctrl.h> if we do not find the variant.
1092
1093 cf_header_list="unctrl.h ncurses/unctrl.h ncursesw/unctrl.h"
1094
1095 case ${cf_cv_ncurses_header:-curses.h} in
1096 (*/*)
1097         cf_header_item=`echo ${cf_cv_ncurses_header:-curses.h} | sed -e 's%\..*%%' -e 's%/.*%/%'`unctrl.h
1098         cf_header_list="$cf_header_item $cf_header_list"
1099         ;;
1100 esac
1101
1102 for cf_header in $cf_header_list
1103 do
1104         AC_TRY_COMPILE([
1105 #include <${cf_cv_ncurses_header:-curses.h}>
1106 #include <${cf_header}>],
1107         [WINDOW *x; (void)x],
1108         [cf_cv_unctrl_header=$cf_header
1109          break],
1110         [cf_cv_unctrl_header=no])
1111 done
1112 ])
1113
1114 case $cf_cv_unctrl_header in
1115 (no)
1116         AC_MSG_WARN(unctrl.h header not found)
1117         ;;
1118 esac
1119
1120 case $cf_cv_unctrl_header in
1121 (unctrl.h)
1122         AC_DEFINE(HAVE_UNCTRL_H,1,[Define to 1 if we have unctrl.h])
1123         ;;
1124 (ncurses/unctrl.h)
1125         AC_DEFINE(HAVE_NCURSES_UNCTRL_H,1,[Define to 1 if we have ncurses/unctrl.h])
1126         ;;
1127 (ncursesw/unctrl.h)
1128         AC_DEFINE(HAVE_NCURSESW_UNCTRL_H,1,[Define to 1 if we have ncursesw/unctrl.h])
1129         ;;
1130 esac
1131 ])dnl
1132 dnl ---------------------------------------------------------------------------
1133 dnl CF_CURSES_WACS_MAP version: 7 updated: 2020/03/19 20:23:48
1134 dnl ------------------
1135 dnl Check for likely values of wacs_map[].
1136 AC_DEFUN([CF_CURSES_WACS_MAP],
1137 [
1138 AC_CACHE_CHECK(for wide alternate character set array, cf_cv_curses_wacs_map,[
1139         cf_cv_curses_wacs_map=unknown
1140         for name in wacs_map _wacs_map __wacs_map _nc_wacs _wacs_char
1141         do
1142         AC_TRY_LINK([
1143 #ifndef _XOPEN_SOURCE_EXTENDED
1144 #define _XOPEN_SOURCE_EXTENDED
1145 #endif
1146 #include <${cf_cv_ncurses_header:-curses.h}>],
1147         [void *foo = &($name['k']); (void)foo],
1148         [cf_cv_curses_wacs_map=$name
1149          break])
1150         done])
1151
1152 test "$cf_cv_curses_wacs_map" != unknown && AC_DEFINE_UNQUOTED(CURSES_WACS_ARRAY,$cf_cv_curses_wacs_map,[Define to name of (n)curses wide-character array])
1153 ])dnl
1154 dnl ---------------------------------------------------------------------------
1155 dnl CF_CURSES_WACS_SYMBOLS version: 3 updated: 2020/03/19 20:23:48
1156 dnl ----------------------
1157 dnl Do a check to see if the WACS_xxx constants are defined compatibly with
1158 dnl X/Open Curses.  In particular, NetBSD's implementation of the WACS_xxx
1159 dnl constants is broken since those constants do not point to cchar_t's.
1160 AC_DEFUN([CF_CURSES_WACS_SYMBOLS],
1161 [
1162 AC_REQUIRE([CF_CURSES_WACS_MAP])
1163
1164 AC_CACHE_CHECK(for wide alternate character constants, cf_cv_curses_wacs_symbols,[
1165 cf_cv_curses_wacs_symbols=no
1166 if test "$cf_cv_curses_wacs_map" != unknown
1167 then
1168         AC_TRY_LINK([
1169 #ifndef _XOPEN_SOURCE_EXTENDED
1170 #define _XOPEN_SOURCE_EXTENDED
1171 #endif
1172 #include <${cf_cv_ncurses_header:-curses.h}>],
1173         [cchar_t *foo = WACS_PLUS;
1174          $cf_cv_curses_wacs_map['k'] = *WACS_PLUS; (void)foo],
1175         [cf_cv_curses_wacs_symbols=yes])
1176 else
1177         AC_TRY_LINK([
1178 #ifndef _XOPEN_SOURCE_EXTENDED
1179 #define _XOPEN_SOURCE_EXTENDED
1180 #endif
1181 #include <${cf_cv_ncurses_header:-curses.h}>],
1182         [cchar_t *foo = WACS_PLUS; (void)foo],
1183         [cf_cv_curses_wacs_symbols=yes])
1184 fi
1185 ])
1186
1187 test "$cf_cv_curses_wacs_symbols" != no && AC_DEFINE(CURSES_WACS_SYMBOLS,1,[Define to 1 if (n)curses supports wide-character WACS_ symbols])
1188 ])dnl
1189 dnl ---------------------------------------------------------------------------
1190 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1191 dnl ----------
1192 dnl "dirname" is not portable, so we fake it with a shell script.
1193 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1194 dnl ---------------------------------------------------------------------------
1195 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1196 dnl ---------------
1197 dnl You can always use "make -n" to see the actual options, but it's hard to
1198 dnl pick out/analyze warning messages when the compile-line is long.
1199 dnl
1200 dnl Sets:
1201 dnl     ECHO_LT - symbol to control if libtool is verbose
1202 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1203 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1204 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1205 dnl     ECHO_CC - symbol to put before any "cc" line
1206 dnl
1207 AC_DEFUN([CF_DISABLE_ECHO],[
1208 AC_MSG_CHECKING(if you want to see long compiling messages)
1209 CF_ARG_DISABLE(echo,
1210         [  --disable-echo          do not display "compiling" commands],
1211         [
1212         ECHO_LT='--silent'
1213         ECHO_LD='@echo linking [$]@;'
1214         RULE_CC='@echo compiling [$]<'
1215         SHOW_CC='@echo compiling [$]@'
1216         ECHO_CC='@'
1217 ],[
1218         ECHO_LT=''
1219         ECHO_LD=''
1220         RULE_CC=''
1221         SHOW_CC=''
1222         ECHO_CC=''
1223 ])
1224 AC_MSG_RESULT($enableval)
1225 AC_SUBST(ECHO_LT)
1226 AC_SUBST(ECHO_LD)
1227 AC_SUBST(RULE_CC)
1228 AC_SUBST(SHOW_CC)
1229 AC_SUBST(ECHO_CC)
1230 ])dnl
1231 dnl ---------------------------------------------------------------------------
1232 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1233 dnl ----------------
1234 dnl Combine no-leak checks with the libraries or tools that are used for the
1235 dnl checks.
1236 AC_DEFUN([CF_DISABLE_LEAKS],[
1237
1238 AC_REQUIRE([CF_WITH_DMALLOC])
1239 AC_REQUIRE([CF_WITH_DBMALLOC])
1240 AC_REQUIRE([CF_WITH_VALGRIND])
1241
1242 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1243 AC_ARG_ENABLE(leaks,
1244         [  --disable-leaks         test: free permanent memory, analyze leaks],
1245         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1246         : ${with_no_leaks:=no})
1247 AC_MSG_RESULT($with_no_leaks)
1248
1249 if test "$with_no_leaks" = yes ; then
1250         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1251         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1252 fi
1253 ])dnl
1254 dnl ---------------------------------------------------------------------------
1255 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1256 dnl ---------------------
1257 dnl The rpath-hack makes it simpler to build programs, particularly with the
1258 dnl *BSD ports which may have essential libraries in unusual places.  But it
1259 dnl can interfere with building an executable for the base system.  Use this
1260 dnl option in that case.
1261 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1262 [
1263 AC_MSG_CHECKING(if rpath-hack should be disabled)
1264 CF_ARG_DISABLE(rpath-hack,
1265         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1266         [cf_disable_rpath_hack=yes],
1267         [cf_disable_rpath_hack=no])
1268 AC_MSG_RESULT($cf_disable_rpath_hack)
1269 if test "$cf_disable_rpath_hack" = no ; then
1270         CF_RPATH_HACK
1271 fi
1272 ])
1273 dnl ---------------------------------------------------------------------------
1274 dnl CF_ENABLE_STRING_HACKS version: 5 updated: 2016/10/08 17:34:11
1275 dnl ----------------------
1276 dnl On a few platforms, the compiler and/or loader nags with untruthful
1277 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1278 dnl and implying that most uses of the recommended alternatives are correct.
1279 dnl
1280 dnl Factually speaking, no one has actually counted the number of uses of these
1281 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1282 dnl instances are meaningless compared to the hundreds of millions of lines of
1283 dnl existing C code.
1284 dnl
1285 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1286 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1287 dnl standard - but evolved through phases, and older implementations are likely
1288 dnl to yield surprising results, as documented in manpages on various systems.
1289 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1290 [
1291 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1292 AC_ARG_ENABLE(string-hacks,
1293         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1294         [with_string_hacks=$enableval],
1295         [with_string_hacks=no])
1296 AC_MSG_RESULT($with_string_hacks)
1297
1298 if test "x$with_string_hacks" = "xyes"; then
1299         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1300         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1301         AC_CHECK_FUNC(strlcat,[
1302                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1303                 ],[
1304                 AC_CHECK_LIB(bsd,strlcat,[
1305                         CF_ADD_LIB(bsd)
1306                         AC_CHECK_HEADERS(bsd/string.h)
1307                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1308                         ])
1309                 ])
1310         AC_CHECK_FUNCS( strlcpy snprintf )
1311 fi
1312 ])dnl
1313 dnl ---------------------------------------------------------------------------
1314 dnl CF_ENABLE_WARNINGS version: 6 updated: 2020/08/28 04:10:22
1315 dnl ------------------
1316 dnl Configure-option to enable gcc warnings
1317 AC_DEFUN([CF_ENABLE_WARNINGS],[
1318 if ( test "$GCC" = yes || test "$GXX" = yes )
1319 then
1320 CF_FIX_WARNINGS(CFLAGS)
1321 CF_FIX_WARNINGS(CPPFLAGS)
1322 CF_FIX_WARNINGS(LDFLAGS)
1323 AC_MSG_CHECKING(if you want to turn on gcc warnings)
1324 CF_ARG_ENABLE(warnings,
1325         [  --enable-warnings       test: turn on gcc compiler warnings],
1326         [with_warnings=yes],
1327         [with_warnings=no])
1328 AC_MSG_RESULT($with_warnings)
1329 if test "$with_warnings" = "yes"
1330 then
1331         CF_GCC_ATTRIBUTES
1332         CF_GCC_WARNINGS($1)
1333 fi
1334 fi
1335 ])dnl
1336 dnl ---------------------------------------------------------------------------
1337 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
1338 dnl ---------------
1339 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
1340 dnl prefer a standard location, and use -L options only if we do not find the
1341 dnl library in the standard library location(s).
1342 dnl     $1 = library name
1343 dnl     $2 = library class, usually the same as library name
1344 dnl     $3 = includes
1345 dnl     $4 = code fragment to compile/link
1346 dnl     $5 = corresponding function-name
1347 dnl     $6 = flag, nonnull if failure should not cause an error-exit
1348 dnl
1349 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
1350 dnl to use a -L option.
1351 AC_DEFUN([CF_FIND_LIBRARY],
1352 [
1353         eval 'cf_cv_have_lib_'$1'=no'
1354         cf_libdir=""
1355         AC_CHECK_FUNC($5,
1356                 eval 'cf_cv_have_lib_'$1'=yes',[
1357                 cf_save_LIBS="$LIBS"
1358                 AC_MSG_CHECKING(for $5 in -l$1)
1359                 LIBS="-l$1 $LIBS"
1360                 AC_TRY_LINK([$3],[$4],
1361                         [AC_MSG_RESULT(yes)
1362                          eval 'cf_cv_have_lib_'$1'=yes'
1363                         ],
1364                         [AC_MSG_RESULT(no)
1365                         CF_LIBRARY_PATH(cf_search,$2)
1366                         for cf_libdir in $cf_search
1367                         do
1368                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
1369                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
1370                                 AC_TRY_LINK([$3],[$4],
1371                                         [AC_MSG_RESULT(yes)
1372                                          eval 'cf_cv_have_lib_'$1'=yes'
1373                                          break],
1374                                         [AC_MSG_RESULT(no)
1375                                          LIBS="$cf_save_LIBS"])
1376                         done
1377                         ])
1378                 ])
1379 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
1380 ifelse($6,,[
1381 if test $cf_found_library = no ; then
1382         AC_MSG_ERROR(Cannot link $1 library)
1383 fi
1384 ])
1385 ])dnl
1386 dnl ---------------------------------------------------------------------------
1387 dnl CF_FIND_LINKAGE version: 21 updated: 2018/06/20 20:23:13
1388 dnl ---------------
1389 dnl Find a library (specifically the linkage used in the code fragment),
1390 dnl searching for it if it is not already in the library path.
1391 dnl See also CF_ADD_SEARCHPATH.
1392 dnl
1393 dnl Parameters (4-on are optional):
1394 dnl     $1 = headers for library entrypoint
1395 dnl     $2 = code fragment for library entrypoint
1396 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1397 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1398 dnl     $5 = action to perform if not successful
1399 dnl     $6 = module name, if not the same as the library name
1400 dnl     $7 = extra libraries
1401 dnl
1402 dnl Sets these variables:
1403 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1404 dnl     $cf_cv_header_path_$3 - include-directory if needed
1405 dnl     $cf_cv_library_path_$3 - library-directory if needed
1406 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1407 AC_DEFUN([CF_FIND_LINKAGE],[
1408
1409 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1410 # will be set on completion of the AC_TRY_LINK below.
1411 cf_cv_header_path_$3=
1412 cf_cv_library_path_$3=
1413
1414 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1415
1416 cf_save_LIBS="$LIBS"
1417
1418 AC_TRY_LINK([$1],[$2],[
1419         cf_cv_find_linkage_$3=yes
1420         cf_cv_header_path_$3=/usr/include
1421         cf_cv_library_path_$3=/usr/lib
1422 ],[
1423
1424 LIBS="-l$3 $7 $cf_save_LIBS"
1425
1426 AC_TRY_LINK([$1],[$2],[
1427         cf_cv_find_linkage_$3=yes
1428         cf_cv_header_path_$3=/usr/include
1429         cf_cv_library_path_$3=/usr/lib
1430         cf_cv_library_file_$3="-l$3"
1431 ],[
1432         cf_cv_find_linkage_$3=no
1433         LIBS="$cf_save_LIBS"
1434
1435         CF_VERBOSE(find linkage for $3 library)
1436         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1437
1438         cf_save_CPPFLAGS="$CPPFLAGS"
1439         cf_test_CPPFLAGS="$CPPFLAGS"
1440
1441         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1442         for cf_cv_header_path_$3 in $cf_search
1443         do
1444                 if test -d $cf_cv_header_path_$3 ; then
1445                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1446                         CPPFLAGS="$cf_save_CPPFLAGS"
1447                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
1448                         AC_TRY_COMPILE([$1],[$2],[
1449                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1450                                 cf_cv_find_linkage_$3=maybe
1451                                 cf_test_CPPFLAGS="$CPPFLAGS"
1452                                 break],[
1453                                 CPPFLAGS="$cf_save_CPPFLAGS"
1454                                 ])
1455                 fi
1456         done
1457
1458         if test "$cf_cv_find_linkage_$3" = maybe ; then
1459
1460                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1461
1462                 cf_save_LIBS="$LIBS"
1463                 cf_save_LDFLAGS="$LDFLAGS"
1464
1465                 ifelse([$6],,,[
1466                 CPPFLAGS="$cf_test_CPPFLAGS"
1467                 LIBS="-l$3 $7 $cf_save_LIBS"
1468                 AC_TRY_LINK([$1],[$2],[
1469                         CF_VERBOSE(... found $3 library in system)
1470                         cf_cv_find_linkage_$3=yes])
1471                         CPPFLAGS="$cf_save_CPPFLAGS"
1472                         LIBS="$cf_save_LIBS"
1473                         ])
1474
1475                 if test "$cf_cv_find_linkage_$3" != yes ; then
1476                         CF_LIBRARY_PATH(cf_search,$3)
1477                         for cf_cv_library_path_$3 in $cf_search
1478                         do
1479                                 if test -d $cf_cv_library_path_$3 ; then
1480                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1481                                         CPPFLAGS="$cf_test_CPPFLAGS"
1482                                         LIBS="-l$3 $7 $cf_save_LIBS"
1483                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1484                                         AC_TRY_LINK([$1],[$2],[
1485                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1486                                         cf_cv_find_linkage_$3=yes
1487                                         cf_cv_library_file_$3="-l$3"
1488                                         break],[
1489                                         CPPFLAGS="$cf_save_CPPFLAGS"
1490                                         LIBS="$cf_save_LIBS"
1491                                         LDFLAGS="$cf_save_LDFLAGS"
1492                                         ])
1493                                 fi
1494                         done
1495                         CPPFLAGS="$cf_save_CPPFLAGS"
1496                         LDFLAGS="$cf_save_LDFLAGS"
1497                 fi
1498
1499         else
1500                 cf_cv_find_linkage_$3=no
1501         fi
1502         ],$7)
1503 ])
1504
1505 LIBS="$cf_save_LIBS"
1506
1507 if test "$cf_cv_find_linkage_$3" = yes ; then
1508 ifelse([$4],,[
1509         CF_ADD_INCDIR($cf_cv_header_path_$3)
1510         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1511         CF_ADD_LIB($3)
1512 ],[$4])
1513 else
1514 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1515 fi
1516 ])dnl
1517 dnl ---------------------------------------------------------------------------
1518 dnl CF_FIX_WARNINGS version: 2 updated: 2020/08/28 15:08:28
1519 dnl ---------------
1520 dnl Warning flags do not belong in CFLAGS, CPPFLAGS, etc.  Any of gcc's
1521 dnl "-Werror" flags can interfere with configure-checks.  Those go into
1522 dnl EXTRA_CFLAGS.
1523 dnl
1524 dnl $1 = variable name to repair
1525 define([CF_FIX_WARNINGS],[
1526 if ( test "$GCC" = yes || test "$GXX" = yes )
1527 then
1528         case [$]$1 in
1529         (*-Werror=*)
1530                 CF_VERBOSE(repairing $1: [$]$1)
1531                 cf_temp_flags=
1532                 for cf_temp_scan in [$]$1
1533                 do
1534                         case "x$cf_temp_scan" in
1535                         (x-Werror=*)
1536                                 CF_APPEND_TEXT(EXTRA_CFLAGS,"$cf_temp_scan")
1537                                 ;;
1538                         (*)
1539                                 CF_APPEND_TEXT(cf_temp_flags,"$cf_temp_scan")
1540                                 ;;
1541                         esac
1542                 done
1543                 $1="$cf_temp_flags"
1544                 CF_VERBOSE(... fixed [$]$1)
1545                 CF_VERBOSE(... extra $EXTRA_CFLAGS)
1546                 ;;
1547         esac
1548 fi
1549 AC_SUBST(EXTRA_CFLAGS)
1550 ])dnl
1551 dnl ---------------------------------------------------------------------------
1552 dnl CF_FUNC_CURSES_VERSION version: 7 updated: 2017/05/10 18:31:29
1553 dnl ----------------------
1554 dnl Solaris has a data item 'curses_version', which confuses AC_CHECK_FUNCS.
1555 dnl It's a character string "SVR4", not documented.
1556 AC_DEFUN([CF_FUNC_CURSES_VERSION],
1557 [
1558 AC_CACHE_CHECK(for function curses_version, cf_cv_func_curses_version,[
1559 AC_TRY_RUN([
1560 #include <${cf_cv_ncurses_header:-curses.h}>
1561 int main(void)
1562 {
1563         char temp[1024];
1564         sprintf(temp, "%s\n", curses_version());
1565         ${cf_cv_main_return:-return}(0);
1566 }]
1567 ,[cf_cv_func_curses_version=yes]
1568 ,[cf_cv_func_curses_version=no]
1569 ,[cf_cv_func_curses_version=unknown])
1570 rm -f core])
1571 test "$cf_cv_func_curses_version" = yes && AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 if we have curses_version function])
1572 ])
1573 dnl ---------------------------------------------------------------------------
1574 dnl CF_FUNC_OPENPTY version: 5 updated: 2015/09/12 14:46:50
1575 dnl ---------------
1576 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1577 dnl "util" library as well.
1578 AC_DEFUN([CF_FUNC_OPENPTY],
1579 [
1580 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1581 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1582         cf_save_LIBS="$LIBS"
1583         test $cf_cv_lib_util = yes && { CF_ADD_LIB(util) }
1584         for cf_header in pty.h libutil.h util.h
1585         do
1586         AC_TRY_LINK([
1587 #include <$cf_header>
1588 ],[
1589         int x = openpty((int *)0, (int *)0, (char *)0,
1590                                    (struct termios *)0, (struct winsize *)0);
1591 ],[
1592                 cf_cv_func_openpty=$cf_header
1593                 break
1594 ],[
1595                 cf_cv_func_openpty=no
1596 ])
1597         done
1598         LIBS="$cf_save_LIBS"
1599 ])
1600 ])dnl
1601 dnl ---------------------------------------------------------------------------
1602 dnl CF_GCC_ATTRIBUTES version: 18 updated: 2020/03/10 18:53:47
1603 dnl -----------------
1604 dnl Test for availability of useful gcc __attribute__ directives to quiet
1605 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1606 dnl to documentation, unrecognized directives cause older compilers to barf.
1607 AC_DEFUN([CF_GCC_ATTRIBUTES],
1608 [
1609 if test "$GCC" = yes
1610 then
1611 cat > conftest.i <<EOF
1612 #ifndef GCC_PRINTF
1613 #define GCC_PRINTF 0
1614 #endif
1615 #ifndef GCC_SCANF
1616 #define GCC_SCANF 0
1617 #endif
1618 #ifndef GCC_NORETURN
1619 #define GCC_NORETURN /* nothing */
1620 #endif
1621 #ifndef GCC_UNUSED
1622 #define GCC_UNUSED /* nothing */
1623 #endif
1624 EOF
1625 if test "$GCC" = yes
1626 then
1627         AC_CHECKING([for $CC __attribute__ directives])
1628 cat > conftest.$ac_ext <<EOF
1629 #line __oline__ "${as_me:-configure}"
1630 #include "confdefs.h"
1631 #include "conftest.h"
1632 #include "conftest.i"
1633 #if     GCC_PRINTF
1634 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1635 #else
1636 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1637 #endif
1638 #if     GCC_SCANF
1639 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1640 #else
1641 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1642 #endif
1643 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1644 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1645 extern void foo(void) GCC_NORETURN;
1646 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { (void)argc; (void)argv; return 0; }
1647 EOF
1648         cf_printf_attribute=no
1649         cf_scanf_attribute=no
1650         for cf_attribute in scanf printf unused noreturn
1651         do
1652                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1653                 cf_directive="__attribute__(($cf_attribute))"
1654                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1655
1656                 case $cf_attribute in
1657                 (printf)
1658                         cf_printf_attribute=yes
1659                         cat >conftest.h <<EOF
1660 #define GCC_$cf_ATTRIBUTE 1
1661 EOF
1662                         ;;
1663                 (scanf)
1664                         cf_scanf_attribute=yes
1665                         cat >conftest.h <<EOF
1666 #define GCC_$cf_ATTRIBUTE 1
1667 EOF
1668                         ;;
1669                 (*)
1670                         cat >conftest.h <<EOF
1671 #define GCC_$cf_ATTRIBUTE $cf_directive
1672 EOF
1673                         ;;
1674                 esac
1675
1676                 if AC_TRY_EVAL(ac_compile); then
1677                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1678                         cat conftest.h >>confdefs.h
1679                         case $cf_attribute in
1680                         (noreturn)
1681                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1682                                 ;;
1683                         (printf)
1684                                 cf_value='/* nothing */'
1685                                 if test "$cf_printf_attribute" != no ; then
1686                                         cf_value='__attribute__((format(printf,fmt,var)))'
1687                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1688                                 fi
1689                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1690                                 ;;
1691                         (scanf)
1692                                 cf_value='/* nothing */'
1693                                 if test "$cf_scanf_attribute" != no ; then
1694                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1695                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1696                                 fi
1697                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1698                                 ;;
1699                         (unused)
1700                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1701                                 ;;
1702                         esac
1703                 fi
1704         done
1705 else
1706         fgrep define conftest.i >>confdefs.h
1707 fi
1708 rm -rf conftest*
1709 fi
1710 ])dnl
1711 dnl ---------------------------------------------------------------------------
1712 dnl CF_GCC_VERSION version: 8 updated: 2019/09/07 13:38:36
1713 dnl --------------
1714 dnl Find version of gcc, and (because icc/clang pretend to be gcc without being
1715 dnl compatible), attempt to determine if icc/clang is actually used.
1716 AC_DEFUN([CF_GCC_VERSION],[
1717 AC_REQUIRE([AC_PROG_CC])
1718 GCC_VERSION=none
1719 if test "$GCC" = yes ; then
1720         AC_MSG_CHECKING(version of $CC)
1721         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1722         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1723         AC_MSG_RESULT($GCC_VERSION)
1724 fi
1725 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1726 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1727 ])dnl
1728 dnl ---------------------------------------------------------------------------
1729 dnl CF_GCC_WARNINGS version: 38 updated: 2020/08/28 15:08:28
1730 dnl ---------------
1731 dnl Check if the compiler supports useful warning options.  There's a few that
1732 dnl we don't use, simply because they're too noisy:
1733 dnl
1734 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1735 dnl     -Winline (usually not worthwhile)
1736 dnl     -Wredundant-decls (system headers make this too noisy)
1737 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1738 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1739 dnl             is enabled for ncurses using "--enable-const".
1740 dnl     -pedantic
1741 dnl
1742 dnl Parameter:
1743 dnl     $1 is an optional list of gcc warning flags that a particular
1744 dnl             application might want to use, e.g., "no-unused" for
1745 dnl             -Wno-unused
1746 dnl Special:
1747 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1748 dnl
1749 AC_DEFUN([CF_GCC_WARNINGS],
1750 [
1751 AC_REQUIRE([CF_GCC_VERSION])
1752 if test "x$have_x" = xyes; then CF_CONST_X_STRING fi
1753 cat > conftest.$ac_ext <<EOF
1754 #line __oline__ "${as_me:-configure}"
1755 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1756 EOF
1757 if test "$INTEL_COMPILER" = yes
1758 then
1759 # The "-wdXXX" options suppress warnings:
1760 # remark #1419: external declaration in primary source file
1761 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1762 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1763 # remark #193: zero used for undefined preprocessing identifier
1764 # remark #593: variable "curs_sb_left_arrow" was set but never used
1765 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1766 # remark #869: parameter "tw" was never referenced
1767 # remark #981: operands are evaluated in unspecified order
1768 # warning #279: controlling expression is constant
1769
1770         AC_CHECKING([for $CC warning options])
1771         cf_save_CFLAGS="$CFLAGS"
1772         EXTRA_CFLAGS="$EXTRA_CFLAGS -Wall"
1773         for cf_opt in \
1774                 wd1419 \
1775                 wd1683 \
1776                 wd1684 \
1777                 wd193 \
1778                 wd593 \
1779                 wd279 \
1780                 wd810 \
1781                 wd869 \
1782                 wd981
1783         do
1784                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1785                 if AC_TRY_EVAL(ac_compile); then
1786                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1787                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1788                 fi
1789         done
1790         CFLAGS="$cf_save_CFLAGS"
1791 elif test "$GCC" = yes && test "$GCC_VERSION" != "unknown"
1792 then
1793         AC_CHECKING([for $CC warning options])
1794         cf_save_CFLAGS="$CFLAGS"
1795         cf_warn_CONST=""
1796         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1797         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
1798         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
1799         for cf_opt in W Wall \
1800                 Wbad-function-cast \
1801                 Wcast-align \
1802                 Wcast-qual \
1803                 Wdeclaration-after-statement \
1804                 Wextra \
1805                 Winline \
1806                 Wmissing-declarations \
1807                 Wmissing-prototypes \
1808                 Wnested-externs \
1809                 Wpointer-arith \
1810                 Wshadow \
1811                 Wstrict-prototypes \
1812                 Wundef Wno-inline $cf_gcc_warnings $cf_warn_CONST $1
1813         do
1814                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1815                 if AC_TRY_EVAL(ac_compile); then
1816                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1817                         case $cf_opt in
1818                         (Winline)
1819                                 case $GCC_VERSION in
1820                                 ([[34]].*)
1821                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1822                                         continue;;
1823                                 esac
1824                                 ;;
1825                         (Wpointer-arith)
1826                                 case $GCC_VERSION in
1827                                 ([[12]].*)
1828                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1829                                         continue;;
1830                                 esac
1831                                 ;;
1832                         esac
1833                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1834                 fi
1835         done
1836         CFLAGS="$cf_save_CFLAGS"
1837 fi
1838 rm -rf conftest*
1839
1840 AC_SUBST(EXTRA_CFLAGS)
1841 ])dnl
1842 dnl ---------------------------------------------------------------------------
1843 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
1844 dnl ----------------
1845 dnl Check for getopt's variables which are commonly defined in stdlib.h,
1846 dnl unistd.h or (nonstandard) in getopt.h
1847 AC_DEFUN([CF_GETOPT_HEADER],
1848 [
1849 AC_HAVE_HEADERS(unistd.h getopt.h)
1850 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
1851 cf_cv_getopt_header=none
1852 for cf_header in stdio.h stdlib.h unistd.h getopt.h
1853 do
1854 AC_TRY_COMPILE([
1855 #include <$cf_header>],
1856 [int x = optind; char *y = optarg],
1857 [cf_cv_getopt_header=$cf_header
1858  break])
1859 done
1860 ])
1861 if test $cf_cv_getopt_header != none ; then
1862         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
1863 fi
1864 if test $cf_cv_getopt_header = getopt.h ; then
1865         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
1866 fi
1867 ])dnl
1868 dnl ---------------------------------------------------------------------------
1869 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
1870 dnl -------------
1871 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1872 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1873 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1874 dnl since it is interwoven with GNU extensions.
1875 dnl
1876 dnl Well, yes we could work around it...
1877 dnl
1878 dnl Parameters:
1879 dnl     $1 is the nominal value for _XOPEN_SOURCE
1880 AC_DEFUN([CF_GNU_SOURCE],
1881 [
1882 cf_gnu_xopen_source=ifelse($1,,500,$1)
1883
1884 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
1885 AC_TRY_COMPILE([#include <sys/types.h>],[
1886         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
1887                 return 0;
1888         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
1889                 return 0;
1890         #else
1891         #       error not GNU C library
1892         #endif],
1893         [cf_cv_gnu_library=yes],
1894         [cf_cv_gnu_library=no])
1895 ])
1896
1897 if test x$cf_cv_gnu_library = xyes; then
1898
1899         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
1900         # was changed to help a little.  newlib incorporated the change about 4
1901         # years later.
1902         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
1903                 cf_save="$CPPFLAGS"
1904                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
1905                 AC_TRY_COMPILE([#include <sys/types.h>],[
1906                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
1907                                 return 0;
1908                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
1909                                 return 0;
1910                         #else
1911                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
1912                         #endif],
1913                         [cf_cv_gnu_library_219=yes],
1914                         [cf_cv_gnu_library_219=no])
1915                 CPPFLAGS="$cf_save"
1916         ])
1917
1918         if test "x$cf_cv_gnu_library_219" = xyes; then
1919                 cf_save="$CPPFLAGS"
1920                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
1921                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
1922                         AC_TRY_COMPILE([
1923                                 #include <limits.h>
1924                                 #include <sys/types.h>
1925                                 ],[
1926                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
1927                                         return 0;
1928                                 #else
1929                                 #       error GNU C library is too old
1930                                 #endif],
1931                                 [cf_cv_gnu_dftsrc_219=yes],
1932                                 [cf_cv_gnu_dftsrc_219=no])
1933                         ])
1934                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
1935         else
1936                 cf_cv_gnu_dftsrc_219=maybe
1937         fi
1938
1939         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
1940
1941                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1942                 AC_TRY_COMPILE([#include <sys/types.h>],[
1943                         #ifndef _XOPEN_SOURCE
1944                         #error  expected _XOPEN_SOURCE to be defined
1945                         #endif],
1946                         [cf_cv_gnu_source=no],
1947                         [cf_save="$CPPFLAGS"
1948                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
1949                          AC_TRY_COMPILE([#include <sys/types.h>],[
1950                                 #ifdef _XOPEN_SOURCE
1951                                 #error  expected _XOPEN_SOURCE to be undefined
1952                                 #endif],
1953                                 [cf_cv_gnu_source=no],
1954                                 [cf_cv_gnu_source=yes])
1955                         CPPFLAGS="$cf_save"
1956                         ])
1957                 ])
1958
1959                 if test "$cf_cv_gnu_source" = yes
1960                 then
1961                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
1962                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
1963                         AC_TRY_COMPILE([#include <sys/types.h>],[
1964                                 #ifdef _DEFAULT_SOURCE
1965                                 #error  expected _DEFAULT_SOURCE to be undefined
1966                                 #endif],
1967                                 [cf_cv_default_source=no],
1968                                 [cf_cv_default_source=yes])
1969                         ])
1970                         if test "$cf_cv_default_source" = yes
1971                         then
1972                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
1973                         fi
1974                 fi
1975         fi
1976
1977 fi
1978 ])dnl
1979 dnl ---------------------------------------------------------------------------
1980 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
1981 dnl --------------
1982 dnl Construct a search-list of directories for a nonstandard header-file
1983 dnl
1984 dnl Parameters
1985 dnl     $1 = the variable to return as result
1986 dnl     $2 = the package name
1987 AC_DEFUN([CF_HEADER_PATH],
1988 [
1989 $1=
1990
1991 # collect the current set of include-directories from compiler flags
1992 cf_header_path_list=""
1993 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1994         for cf_header_path in $CPPFLAGS $CFLAGS
1995         do
1996                 case $cf_header_path in
1997                 (-I*)
1998                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1999                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2000                         cf_header_path_list="$cf_header_path_list [$]$1"
2001                         ;;
2002                 esac
2003         done
2004 fi
2005
2006 # add the variations for the package we are looking for
2007 CF_SUBDIR_PATH($1,$2,include)
2008
2009 test "$includedir" != NONE && \
2010 test "$includedir" != "/usr/include" && \
2011 test -d "$includedir" && {
2012         test -d $includedir &&    $1="[$]$1 $includedir"
2013         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
2014 }
2015
2016 test "$oldincludedir" != NONE && \
2017 test "$oldincludedir" != "/usr/include" && \
2018 test -d "$oldincludedir" && {
2019         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
2020         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
2021 }
2022
2023 $1="[$]$1 $cf_header_path_list"
2024 ])dnl
2025 dnl ---------------------------------------------------------------------------
2026 dnl CF_HELP_MESSAGE version: 4 updated: 2019/12/31 08:53:54
2027 dnl ---------------
2028 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2029 AC_DEFUN([CF_HELP_MESSAGE],
2030 [CF_ACVERSION_CHECK(2.53,[],[
2031 AC_DIVERT_HELP($1)])dnl
2032 ])dnl
2033 dnl ---------------------------------------------------------------------------
2034 dnl CF_INHERIT_SCRIPT version: 2 updated: 2003/03/01 23:50:42
2035 dnl -----------------
2036 dnl If we do not have a given script, look for it in the parent directory.
2037 AC_DEFUN([CF_INHERIT_SCRIPT],
2038 [
2039 test -f $1 || ( test -f ../$1 && cp ../$1 ./ )
2040 ])dnl
2041 dnl ---------------------------------------------------------------------------
2042 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
2043 dnl ---------------
2044 dnl prompt for/fill-in useful install-program options
2045 AC_DEFUN([CF_INSTALL_OPTS],
2046 [
2047 CF_INSTALL_OPT_S
2048 CF_INSTALL_OPT_P
2049 CF_INSTALL_OPT_O
2050 ])dnl
2051 dnl ---------------------------------------------------------------------------
2052 dnl CF_INSTALL_OPT_O version: 2 updated: 2015/05/15 19:45:35
2053 dnl ----------------
2054 dnl Almost all "install" programs default to the current user's ownership.
2055 dnl Almost - MINIX is an exception.
2056 AC_DEFUN([CF_INSTALL_OPT_O],
2057 [
2058 AC_MSG_CHECKING(if install needs to be told about ownership)
2059 case `$ac_config_guess` in
2060 (*minix)
2061         with_install_o=yes
2062         ;;
2063 (*)
2064         with_install_o=no
2065         ;;
2066 esac
2067
2068 AC_MSG_RESULT($with_install_o)
2069 if test "x$with_install_o" = xyes
2070 then
2071         INSTALL_OPT_O=`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`
2072 else
2073         INSTALL_OPT_O=
2074 fi
2075
2076 AC_SUBST(INSTALL_OPT_O)
2077 ])dnl
2078 dnl ---------------------------------------------------------------------------
2079 dnl CF_INSTALL_OPT_P version: 1 updated: 2018/08/18 12:19:21
2080 dnl ----------------
2081 dnl Some install-programs accept a "-p" option to preserve file modification
2082 dnl timestamps.  That can be useful as an install option, as well as a way to
2083 dnl avoid the need for ranlib after copying a static archive.
2084 AC_DEFUN([CF_INSTALL_OPT_P],
2085 [
2086 : ${INSTALL:=install}
2087 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
2088         rm -rf conftest*
2089         date >conftest.in
2090         mkdir conftest.out
2091         sleep 3
2092         if $INSTALL -p conftest.in conftest.out 2>/dev/null
2093         then
2094                 if test -f conftest.out/conftest.in
2095                 then
2096                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
2097                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
2098                         if test -s conftest.err
2099                         then
2100                                 cf_cv_install_p=no
2101                         else
2102                                 cf_cv_install_p=yes
2103                         fi
2104                 else
2105                         cf_cv_install_p=no
2106                 fi
2107         else
2108                 cf_cv_install_p=no
2109         fi
2110         rm -rf conftest*
2111 ])
2112 ])dnl
2113 dnl ---------------------------------------------------------------------------
2114 dnl CF_INSTALL_OPT_S version: 2 updated: 2018/08/18 12:19:21
2115 dnl ----------------
2116 dnl By default, we should strip executables which are installed, but leave the
2117 dnl ability to suppress that for unit-testing.
2118 AC_DEFUN([CF_INSTALL_OPT_S],
2119 [
2120 AC_MSG_CHECKING(if you want to install stripped executables)
2121 CF_ARG_DISABLE(stripping,
2122         [  --disable-stripping     do not strip (debug info) installed executables],
2123         [with_stripping=no],
2124         [with_stripping=yes])
2125 AC_MSG_RESULT($with_stripping)
2126
2127 if test "$with_stripping" = yes
2128 then
2129         INSTALL_OPT_S="-s"
2130 else
2131         INSTALL_OPT_S=
2132 fi
2133 AC_SUBST(INSTALL_OPT_S)
2134 ])dnl
2135 dnl ---------------------------------------------------------------------------
2136 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
2137 dnl -----------------
2138 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2139 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2140 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2141 dnl
2142 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2143 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2144 dnl the wrappers for gcc and g++ warnings.
2145 dnl
2146 dnl $1 = GCC (default) or GXX
2147 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2148 dnl $3 = CFLAGS (default) or CXXFLAGS
2149 AC_DEFUN([CF_INTEL_COMPILER],[
2150 AC_REQUIRE([AC_CANONICAL_HOST])
2151 ifelse([$2],,INTEL_COMPILER,[$2])=no
2152
2153 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2154         case $host_os in
2155         (linux*|gnu*)
2156                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2157                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2158                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2159                 AC_TRY_COMPILE([],[
2160 #ifdef __INTEL_COMPILER
2161 #else
2162 make an error
2163 #endif
2164 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2165 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
2166 ],[])
2167                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2168                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2169                 ;;
2170         esac
2171 fi
2172 ])dnl
2173 dnl ---------------------------------------------------------------------------
2174 dnl CF_LD_RPATH_OPT version: 8 updated: 2018/08/18 16:36:35
2175 dnl ---------------
2176 dnl For the given system and compiler, find the compiler flags to pass to the
2177 dnl loader to use the "rpath" feature.
2178 AC_DEFUN([CF_LD_RPATH_OPT],
2179 [
2180 AC_REQUIRE([CF_CHECK_CACHE])
2181
2182 LD_RPATH_OPT=
2183 if test "x$cf_cv_enable_rpath" != xno
2184 then
2185         AC_MSG_CHECKING(for an rpath option)
2186         case $cf_cv_system_name in
2187         (irix*)
2188                 if test "$GCC" = yes; then
2189                         LD_RPATH_OPT="-Wl,-rpath,"
2190                 else
2191                         LD_RPATH_OPT="-rpath "
2192                 fi
2193                 ;;
2194         (linux*|gnu*|k*bsd*-gnu|freebsd*)
2195                 LD_RPATH_OPT="-Wl,-rpath,"
2196                 ;;
2197         (openbsd[[2-9]].*|mirbsd*)
2198                 LD_RPATH_OPT="-Wl,-rpath,"
2199                 ;;
2200         (dragonfly*)
2201                 LD_RPATH_OPT="-rpath "
2202                 ;;
2203         (netbsd*)
2204                 LD_RPATH_OPT="-Wl,-rpath,"
2205                 ;;
2206         (osf*|mls+*)
2207                 LD_RPATH_OPT="-rpath "
2208                 ;;
2209         (solaris2*)
2210                 LD_RPATH_OPT="-R"
2211                 ;;
2212         (*)
2213                 ;;
2214         esac
2215         AC_MSG_RESULT($LD_RPATH_OPT)
2216
2217         case "x$LD_RPATH_OPT" in
2218         (x-R*)
2219                 AC_MSG_CHECKING(if we need a space after rpath option)
2220                 cf_save_LIBS="$LIBS"
2221                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
2222                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
2223                 LIBS="$cf_save_LIBS"
2224                 AC_MSG_RESULT($cf_rpath_space)
2225                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
2226                 ;;
2227         esac
2228 fi
2229 ])dnl
2230 dnl ---------------------------------------------------------------------------
2231 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
2232 dnl ---------------
2233 dnl Construct a search-list of directories for a nonstandard library-file
2234 dnl
2235 dnl Parameters
2236 dnl     $1 = the variable to return as result
2237 dnl     $2 = the package name
2238 AC_DEFUN([CF_LIBRARY_PATH],
2239 [
2240 $1=
2241 cf_library_path_list=""
2242 if test -n "${LDFLAGS}${LIBS}" ; then
2243         for cf_library_path in $LDFLAGS $LIBS
2244         do
2245                 case $cf_library_path in
2246                 (-L*)
2247                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
2248                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
2249                         cf_library_path_list="$cf_library_path_list [$]$1"
2250                         ;;
2251                 esac
2252         done
2253 fi
2254
2255 CF_SUBDIR_PATH($1,$2,lib)
2256
2257 $1="$cf_library_path_list [$]$1"
2258 ])dnl
2259 dnl ---------------------------------------------------------------------------
2260 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
2261 dnl ------------
2262 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
2263 dnl a monocase filesystem.
2264 AC_DEFUN([CF_MAKE_TAGS],[
2265 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
2266
2267 AC_CHECK_PROGS(CTAGS, exctags ctags)
2268 AC_CHECK_PROGS(ETAGS, exetags etags)
2269
2270 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
2271
2272 if test "$cf_cv_mixedcase" = yes ; then
2273         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
2274 else
2275         MAKE_UPPER_TAGS=no
2276 fi
2277
2278 if test "$MAKE_UPPER_TAGS" = yes ; then
2279         MAKE_UPPER_TAGS=
2280 else
2281         MAKE_UPPER_TAGS="#"
2282 fi
2283
2284 if test "$MAKE_LOWER_TAGS" = yes ; then
2285         MAKE_LOWER_TAGS=
2286 else
2287         MAKE_LOWER_TAGS="#"
2288 fi
2289
2290 AC_SUBST(CTAGS)
2291 AC_SUBST(ETAGS)
2292
2293 AC_SUBST(MAKE_UPPER_TAGS)
2294 AC_SUBST(MAKE_LOWER_TAGS)
2295 ])dnl
2296 dnl ---------------------------------------------------------------------------
2297 dnl CF_MATH_LIB version: 9 updated: 2017/01/21 11:06:25
2298 dnl -----------
2299 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
2300 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
2301 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
2302 AC_DEFUN([CF_MATH_LIB],
2303 [
2304 AC_CACHE_CHECK(if -lm needed for math functions,
2305         cf_cv_need_libm,[
2306         AC_TRY_LINK([
2307         #include <stdio.h>
2308         #include <stdlib.h>
2309         #include <math.h>
2310         ],
2311         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
2312         [cf_cv_need_libm=no],
2313         [cf_cv_need_libm=yes])])
2314 if test "$cf_cv_need_libm" = yes
2315 then
2316 ifelse($1,,[
2317         CF_ADD_LIB(m)
2318 ],[$1=-lm])
2319 fi
2320 ])
2321 dnl ---------------------------------------------------------------------------
2322 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
2323 dnl ----------------------
2324 dnl Check if the file-system supports mixed-case filenames.  If we're able to
2325 dnl create a lowercase name and see it as uppercase, it doesn't support that.
2326 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
2327 [
2328 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
2329 if test "$cross_compiling" = yes ; then
2330         case $target_alias in
2331         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
2332                 cf_cv_mixedcase=no
2333                 ;;
2334         (*)
2335                 cf_cv_mixedcase=yes
2336                 ;;
2337         esac
2338 else
2339         rm -f conftest CONFTEST
2340         echo test >conftest
2341         if test -f CONFTEST ; then
2342                 cf_cv_mixedcase=no
2343         else
2344                 cf_cv_mixedcase=yes
2345         fi
2346         rm -f conftest CONFTEST
2347 fi
2348 ])
2349 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
2350 ])dnl
2351 dnl ---------------------------------------------------------------------------
2352 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2353 dnl ----------
2354 dnl Write a debug message to config.log, along with the line number in the
2355 dnl configure script.
2356 AC_DEFUN([CF_MSG_LOG],[
2357 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2358 ])dnl
2359 dnl ---------------------------------------------------------------------------
2360 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
2361 dnl -------------------
2362 dnl Check if we can compile with ncurses' header file
2363 dnl $1 is the cache variable to set
2364 dnl $2 is the header-file to include
2365 dnl $3 is the root name (ncurses or ncursesw)
2366 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2367         AC_TRY_COMPILE([
2368 ]ifelse($3,ncursesw,[
2369 #define _XOPEN_SOURCE_EXTENDED
2370 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2371 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2372 ])[
2373 #include <$2>],[
2374 #ifdef NCURSES_VERSION
2375 ]ifelse($3,ncursesw,[
2376 #ifndef WACS_BSSB
2377         make an error
2378 #endif
2379 ])[
2380 printf("%s\n", NCURSES_VERSION);
2381 #else
2382 #ifdef __NCURSES_H
2383 printf("old\n");
2384 #else
2385         make an error
2386 #endif
2387 #endif
2388         ]
2389         ,[$1=$2]
2390         ,[$1=no])
2391 ])dnl
2392 dnl ---------------------------------------------------------------------------
2393 dnl CF_NCURSES_CONFIG version: 23 updated: 2020/02/27 05:21:59
2394 dnl -----------------
2395 dnl Tie together the configure-script macros for ncurses, preferring these in
2396 dnl order:
2397 dnl a) ".pc" files for pkg-config, using $NCURSES_CONFIG_PKG
2398 dnl b) the "-config" script from ncurses, using $NCURSES_CONFIG
2399 dnl c) just plain libraries
2400 dnl
2401 dnl $1 is the root library name (default: "ncurses")
2402 AC_DEFUN([CF_NCURSES_CONFIG],[
2403 AC_REQUIRE([CF_PKG_CONFIG])
2404 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2405 cf_have_ncuconfig=no
2406
2407 if test "x${PKG_CONFIG:=none}" != xnone; then
2408         AC_MSG_CHECKING(pkg-config for $cf_ncuconfig_root)
2409         if "$PKG_CONFIG" --exists $cf_ncuconfig_root ; then
2410                 AC_MSG_RESULT(yes)
2411
2412                 AC_MSG_CHECKING(if the $cf_ncuconfig_root package files work)
2413                 cf_have_ncuconfig=unknown
2414
2415                 cf_save_CFLAGS="$CFLAGS"
2416                 cf_save_CPPFLAGS="$CPPFLAGS"
2417                 cf_save_LIBS="$LIBS"
2418
2419                 cf_pkg_cflags=`$PKG_CONFIG --cflags $cf_ncuconfig_root`
2420                 cf_pkg_libs=`$PKG_CONFIG --libs $cf_ncuconfig_root`
2421
2422                 # while -W for passing linker flags is prevalent, it is not "standard". 
2423                 # At least one wrapper for c89/c99 (in Apple's xcode) has its own
2424                 # incompatible _and_ non-standard -W option which gives an error.  Work
2425                 # around that pitfall.
2426                 case "x${CC}@@${cf_pkg_libs}@${cf_pkg_cflags}" in
2427                 (x*c[[89]]9@@*-W*)
2428                         CF_ADD_CFLAGS($cf_pkg_cflags)
2429                         CF_ADD_LIBS($cf_pkg_libs)
2430
2431                         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2432                                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2433                                 [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2434                                         int main(void)
2435                                         { char *xx = curses_version(); return (xx == 0); }],
2436                                         [cf_test_ncuconfig=yes],
2437                                         [cf_test_ncuconfig=no],
2438                                         [cf_test_ncuconfig=maybe])],
2439                                 [cf_test_ncuconfig=no])
2440
2441                         CFLAGS="$cf_save_CFLAGS"
2442                         CPPFLAGS="$cf_save_CPPFLAGS"
2443                         LIBS="$cf_save_LIBS"
2444
2445                         if test "x$cf_test_ncuconfig" != xyes; then
2446                                 cf_temp=`echo "x$cf_pkg_cflags" | sed -e s/^x// -e 's/-W[[^     ]]*//g'`
2447                                 cf_pkg_cflags="$cf_temp"
2448                                 cf_temp=`echo "x$cf_pkg_libs" | sed -e s/^x// -e 's/-W[[^       ]]*//g'`
2449                                 cf_pkg_libs="$cf_temp"
2450                         fi
2451                         ;;
2452                 esac
2453
2454                 CF_ADD_CFLAGS($cf_pkg_cflags)
2455                 CF_ADD_LIBS($cf_pkg_libs)
2456
2457                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2458                         [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2459                         [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2460                                 int main(void)
2461                                 { char *xx = curses_version(); return (xx == 0); }],
2462                                 [cf_have_ncuconfig=yes],
2463                                 [cf_have_ncuconfig=no],
2464                                 [cf_have_ncuconfig=maybe])],
2465                         [cf_have_ncuconfig=no])
2466                 AC_MSG_RESULT($cf_have_ncuconfig)
2467                 test "$cf_have_ncuconfig" = maybe && cf_have_ncuconfig=yes
2468                 if test "$cf_have_ncuconfig" != "yes"
2469                 then
2470                         CPPFLAGS="$cf_save_CPPFLAGS"
2471                         LIBS="$cf_save_LIBS"
2472                         NCURSES_CONFIG_PKG=none
2473                 else
2474                         AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2475                         NCURSES_CONFIG_PKG=$cf_ncuconfig_root
2476                         CF_TERM_HEADER
2477                 fi
2478
2479         else
2480                 AC_MSG_RESULT(no)
2481                 NCURSES_CONFIG_PKG=none
2482         fi
2483 else
2484         NCURSES_CONFIG_PKG=none
2485 fi
2486
2487 if test "x$cf_have_ncuconfig" = "xno"; then
2488         cf_ncurses_config="${cf_ncuconfig_root}${NCURSES_CONFIG_SUFFIX}-config"; echo "Looking for ${cf_ncurses_config}"
2489
2490         CF_ACVERSION_CHECK(2.52,
2491                 [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
2492                 [AC_PATH_PROGS(NCURSES_CONFIG,  ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
2493
2494         if test "$NCURSES_CONFIG" != none ; then
2495
2496                 CF_ADD_CFLAGS(`$NCURSES_CONFIG --cflags`)
2497                 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2498
2499                 # even with config script, some packages use no-override for curses.h
2500                 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2501
2502                 dnl like CF_NCURSES_CPPFLAGS
2503                 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2504
2505                 dnl like CF_NCURSES_LIBS
2506                 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2507                 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2508
2509                 dnl like CF_NCURSES_VERSION
2510                 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
2511
2512         else
2513
2514                 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2515                 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2516
2517         fi
2518 else
2519         NCURSES_CONFIG=none
2520 fi
2521 ])dnl
2522 dnl ---------------------------------------------------------------------------
2523 dnl CF_NCURSES_CPPFLAGS version: 21 updated: 2012/10/06 08:57:51
2524 dnl -------------------
2525 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
2526 dnl the CPPFLAGS variable so we can include its header.
2527 dnl
2528 dnl The header files may be installed as either curses.h, or ncurses.h (would
2529 dnl be obsolete, except that some packagers prefer this name to distinguish it
2530 dnl from a "native" curses implementation).  If not installed for overwrite,
2531 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
2532 dnl /usr/include/ncurses), but someone may have installed overwriting the
2533 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
2534 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
2535 dnl the header.
2536 dnl
2537 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
2538 dnl is already in the include-path, don't even bother with this, since we cannot
2539 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
2540 dnl
2541 dnl The optional parameter gives the root name of the library, in case it is
2542 dnl not installed as the default curses library.  That is how the
2543 dnl wide-character version of ncurses is installed.
2544 AC_DEFUN([CF_NCURSES_CPPFLAGS],
2545 [AC_REQUIRE([CF_WITH_CURSES_DIR])
2546
2547 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
2548 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
2549
2550 test -n "$cf_cv_curses_dir" && \
2551 test "$cf_cv_curses_dir" != "no" && { \
2552   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
2553 }
2554
2555 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
2556         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2557         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
2558         for cf_header in $cf_header_list
2559         do
2560                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2561                 test "$cf_cv_ncurses_h" != no && break
2562         done
2563 ])
2564
2565 CF_NCURSES_HEADER
2566 CF_TERM_HEADER
2567
2568 # some applications need this, but should check for NCURSES_VERSION
2569 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2570
2571 CF_NCURSES_VERSION
2572 ])dnl
2573 dnl ---------------------------------------------------------------------------
2574 dnl CF_NCURSES_EXT_FUNCS version: 4 updated: 2012/10/06 16:39:58
2575 dnl --------------------
2576 dnl Since 2007/11/17, ncurses has defined NCURSES_EXT_FUNCS; earlier versions
2577 dnl may provide these functions.  Define the symbol if it is not defined, and
2578 dnl if it is valid.
2579 AC_DEFUN([CF_NCURSES_EXT_FUNCS],
2580 [
2581 AC_CACHE_CHECK(for ncurses extended functions,cf_cv_ncurses_ext_funcs,[
2582 AC_TRY_COMPILE([
2583 #include <${cf_cv_ncurses_header:-curses.h}>],
2584 [
2585 int x = NCURSES_EXT_FUNCS
2586 ],[cf_cv_ncurses_ext_funcs=defined],[
2587 AC_TRY_LINK([
2588 #include <${cf_cv_ncurses_header:-curses.h}>],
2589 [
2590         (void) assume_default_colors (0, 0);
2591         (void) curses_version ();
2592         (void) define_key (0, 0);
2593         (void) is_term_resized (0, 0);
2594         (void) key_defined (0);
2595         (void) keybound (0, 0);
2596         (void) keyok (0, 0);
2597         (void) resize_term (0, 0);
2598         (void) resizeterm (0, 0);
2599         (void) use_default_colors ();
2600         (void) use_extended_names (0);
2601         (void) wresize (0, 0, 0);],
2602         [cf_cv_ncurses_ext_funcs=yes],
2603         [cf_cv_ncurses_ext_funcs=no])
2604 ])
2605 ])
2606 test "$cf_cv_ncurses_ext_funcs" = yes && AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 if we have ncurses extensions])
2607 ])dnl
2608 dnl ---------------------------------------------------------------------------
2609 dnl CF_NCURSES_HEADER version: 4 updated: 2015/04/15 19:08:48
2610 dnl -----------------
2611 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2612 dnl variations of ncurses' installs.
2613 dnl
2614 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2615 AC_DEFUN([CF_NCURSES_HEADER],[
2616
2617 if test "$cf_cv_ncurses_h" != no ; then
2618         cf_cv_ncurses_header=$cf_cv_ncurses_h
2619 else
2620
2621 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2622         test -n "$verbose" && echo
2623         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2624         test -n "$verbose" && echo search path $cf_search
2625         cf_save2_CPPFLAGS="$CPPFLAGS"
2626         for cf_incdir in $cf_search
2627         do
2628                 CF_ADD_INCDIR($cf_incdir)
2629                 for cf_header in \
2630                         ncurses.h \
2631                         curses.h
2632                 do
2633                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2634                         if test "$cf_cv_ncurses_h2" != no ; then
2635                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2636                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
2637                                 break
2638                         fi
2639                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2640                 done
2641                 CPPFLAGS="$cf_save2_CPPFLAGS"
2642                 test "$cf_cv_ncurses_h2" != no && break
2643         done
2644         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2645         ])
2646
2647         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2648         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
2649         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
2650                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
2651         fi
2652         CF_ADD_INCDIR($cf_1st_incdir)
2653
2654 fi
2655
2656 # Set definitions to allow ifdef'ing for ncurses.h
2657
2658 case $cf_cv_ncurses_header in
2659 (*ncurses.h)
2660         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
2661         ;;
2662 esac
2663
2664 case $cf_cv_ncurses_header in
2665 (ncurses/curses.h|ncurses/ncurses.h)
2666         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
2667         ;;
2668 (ncursesw/curses.h|ncursesw/ncurses.h)
2669         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
2670         ;;
2671 esac
2672
2673 ])dnl
2674 dnl ---------------------------------------------------------------------------
2675 dnl CF_NCURSES_LIBS version: 17 updated: 2015/04/15 19:08:48
2676 dnl ---------------
2677 dnl Look for the ncurses library.  This is a little complicated on Linux,
2678 dnl because it may be linked with the gpm (general purpose mouse) library.
2679 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2680 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2681 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2682 dnl and the linker will record a dependency.
2683 dnl
2684 dnl The optional parameter gives the root name of the library, in case it is
2685 dnl not installed as the default curses library.  That is how the
2686 dnl wide-character version of ncurses is installed.
2687 AC_DEFUN([CF_NCURSES_LIBS],
2688 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2689
2690 cf_nculib_root=ifelse($1,,ncurses,$1)
2691         # This works, except for the special case where we find gpm, but
2692         # ncurses is in a nonstandard location via $LIBS, and we really want
2693         # to link gpm.
2694 cf_ncurses_LIBS=""
2695 cf_ncurses_SAVE="$LIBS"
2696 AC_CHECK_LIB(gpm,Gpm_Open,
2697         [AC_CHECK_LIB(gpm,initscr,
2698                 [LIBS="$cf_ncurses_SAVE"],
2699                 [cf_ncurses_LIBS="-lgpm"])])
2700
2701 case $host_os in
2702 (freebsd*)
2703         # This is only necessary if you are linking against an obsolete
2704         # version of ncurses (but it should do no harm, since it's static).
2705         if test "$cf_nculib_root" = ncurses ; then
2706                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2707         fi
2708         ;;
2709 esac
2710
2711 CF_ADD_LIBS($cf_ncurses_LIBS)
2712
2713 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2714 then
2715         CF_ADD_LIBS(-l$cf_nculib_root)
2716 else
2717         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2718                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2719                 [initscr()],
2720                 initscr)
2721 fi
2722
2723 if test -n "$cf_ncurses_LIBS" ; then
2724         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2725         cf_ncurses_SAVE="$LIBS"
2726         for p in $cf_ncurses_LIBS ; do
2727                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2728                 if test "$q" != "$LIBS" ; then
2729                         LIBS="$q"
2730                 fi
2731         done
2732         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2733                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2734                 [AC_MSG_RESULT(yes)],
2735                 [AC_MSG_RESULT(no)
2736                  LIBS="$cf_ncurses_SAVE"])
2737 fi
2738
2739 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2740 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2741 ])dnl
2742 dnl ---------------------------------------------------------------------------
2743 dnl CF_NCURSES_PTHREADS version: 2 updated: 2016/04/22 05:07:41
2744 dnl -------------------
2745 dnl Use this followup check to ensure that we link with pthreads if ncurses
2746 dnl uses it.
2747 AC_DEFUN([CF_NCURSES_PTHREADS],[
2748 : ${cf_nculib_root:=ifelse($1,,ncurses,$1)}
2749 AC_CHECK_LIB($cf_nculib_root,_nc_init_pthreads,
2750         cf_cv_ncurses_pthreads=yes,
2751         cf_cv_ncurses_pthreads=no)
2752 if test "$cf_cv_ncurses_pthreads" = yes
2753 then
2754         CF_ADD_LIBS(-lpthread)
2755 fi
2756 ])dnl
2757 dnl ---------------------------------------------------------------------------
2758 dnl CF_NCURSES_VERSION version: 15 updated: 2017/05/09 19:26:10
2759 dnl ------------------
2760 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2761 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2762 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2763 AC_DEFUN([CF_NCURSES_VERSION],
2764 [
2765 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2766 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2767         cf_cv_ncurses_version=no
2768         cf_tempfile=out$$
2769         rm -f $cf_tempfile
2770         AC_TRY_RUN([
2771 #include <${cf_cv_ncurses_header:-curses.h}>
2772 #include <stdio.h>
2773 int main(void)
2774 {
2775         FILE *fp = fopen("$cf_tempfile", "w");
2776 #ifdef NCURSES_VERSION
2777 # ifdef NCURSES_VERSION_PATCH
2778         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
2779 # else
2780         fprintf(fp, "%s\n", NCURSES_VERSION);
2781 # endif
2782 #else
2783 # ifdef __NCURSES_H
2784         fprintf(fp, "old\n");
2785 # else
2786         make an error
2787 # endif
2788 #endif
2789         ${cf_cv_main_return:-return}(0);
2790 }],[
2791         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
2792
2793         # This will not work if the preprocessor splits the line after the
2794         # Autoconf token.  The 'unproto' program does that.
2795         cat > conftest.$ac_ext <<EOF
2796 #include <${cf_cv_ncurses_header:-curses.h}>
2797 #undef Autoconf
2798 #ifdef NCURSES_VERSION
2799 Autoconf NCURSES_VERSION
2800 #else
2801 #ifdef __NCURSES_H
2802 Autoconf "old"
2803 #endif
2804 ;
2805 #endif
2806 EOF
2807         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
2808         AC_TRY_EVAL(cf_try)
2809         if test -f conftest.out ; then
2810                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
2811                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
2812                 rm -f conftest.out
2813         fi
2814 ])
2815         rm -f $cf_tempfile
2816 ])
2817 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2818 ])dnl
2819 dnl ---------------------------------------------------------------------------
2820 dnl CF_NCURSES_WRAP_PREFIX version: 1 updated: 2009/03/28 16:08:10
2821 dnl ----------------------
2822 dnl Check for ncurses "wrap-prefix" used for public variables which have been
2823 dnl wrapped with a function to help with concurrency control.
2824 AC_DEFUN([CF_NCURSES_WRAP_PREFIX],
2825 [
2826 AC_MSG_CHECKING(for ncurses wrap-prefix)
2827 AC_ARG_WITH(ncurses-wrap-prefix,
2828         [  --with-ncurses-wrap-prefix naming-prefix for ncurses wrapped-variables],
2829         [NCURSES_WRAP_PREFIX=$withval],
2830         [NCURSES_WRAP_PREFIX=_nc_])
2831 AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
2832
2833 AC_SUBST(NCURSES_WRAP_PREFIX)
2834 ])
2835 dnl ---------------------------------------------------------------------------
2836 dnl CF_NETBSD_FORM_H version: 2 updated: 2012/10/06 16:39:58
2837 dnl ----------------
2838 dnl Check for NetBSD's form.h, which is incompatible with SVr4 and ncurses.
2839 dnl Some workarounds are needed in client programs to allow them to compile.
2840 AC_DEFUN([CF_NETBSD_FORM_H],[
2841 AC_CACHE_CHECK(for NetBSD form.h,cf_cv_netbsd_form_h,[
2842 AC_TRY_COMPILE([
2843 #include <${cf_cv_ncurses_header:-curses.h}>
2844 #include <form.h>
2845 ],[
2846         FORM *form;
2847         int y = current_field(form)->cursor_ypos;
2848         int x = current_field(form)->cursor_xpos;
2849 ],[cf_cv_netbsd_form_h=yes
2850 ],[cf_cv_netbsd_form_h=no])
2851 ])
2852
2853 test "$cf_cv_netbsd_form_h" = yes && AC_DEFINE(HAVE_NETBSD_FORM_H,1,[Define to 1 if we appear to be using NetBSD form.h])
2854 ])dnl
2855 dnl ---------------------------------------------------------------------------
2856 dnl CF_NETBSD_MENU_H version: 2 updated: 2012/10/06 16:39:58
2857 dnl ----------------
2858 dnl Check for NetBSD's menu.h, which is incompatible with SVr4 and ncurses.
2859 dnl Some workarounds are needed in client programs to allow them to compile.
2860 AC_DEFUN([CF_NETBSD_MENU_H],[
2861 AC_CACHE_CHECK(for NetBSD menu.h,cf_cv_netbsd_menu_h,[
2862 AC_TRY_COMPILE([
2863 #include <${cf_cv_ncurses_header:-curses.h}>
2864 #include <menu.h>
2865 ],[
2866         MENU *menu;
2867         int y = menu->max_item_width;
2868 ],[cf_cv_netbsd_menu_h=yes
2869 ],[cf_cv_netbsd_menu_h=no])
2870 ])
2871
2872 test "$cf_cv_netbsd_menu_h" = yes && AC_DEFINE(HAVE_NETBSD_MENU_H,1,[Define to 1 if we appear to be using NetBSD menu.h])
2873 ])dnl
2874 dnl ---------------------------------------------------------------------------
2875 dnl CF_NO_LEAKS_OPTION version: 6 updated: 2015/04/12 15:39:00
2876 dnl ------------------
2877 dnl see CF_WITH_NO_LEAKS
2878 AC_DEFUN([CF_NO_LEAKS_OPTION],[
2879 AC_MSG_CHECKING(if you want to use $1 for testing)
2880 AC_ARG_WITH($1,
2881         [$2],
2882         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
2883          $4
2884 ])
2885         : ${with_cflags:=-g}
2886         : ${with_no_leaks:=yes}
2887          with_$1=yes],
2888         [with_$1=])
2889 AC_MSG_RESULT(${with_$1:-no})
2890
2891 case .$with_cflags in
2892 (.*-g*)
2893         case .$CFLAGS in
2894         (.*-g*)
2895                 ;;
2896         (*)
2897                 CF_ADD_CFLAGS([-g])
2898                 ;;
2899         esac
2900         ;;
2901 esac
2902 ])dnl
2903 dnl ---------------------------------------------------------------------------
2904 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
2905 dnl --------------
2906 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
2907 dnl begins with one of the prefix/exec_prefix variables, and then again if the
2908 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
2909 dnl delayed evaluation of those symbols.
2910 AC_DEFUN([CF_PATH_SYNTAX],[
2911 if test "x$prefix" != xNONE; then
2912         cf_path_syntax="$prefix"
2913 else
2914         cf_path_syntax="$ac_default_prefix"
2915 fi
2916
2917 case ".[$]$1" in
2918 (.\[$]\(*\)*|.\'*\'*)
2919         ;;
2920 (..|./*|.\\*)
2921         ;;
2922 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
2923         ;;
2924 (.\[$]{*prefix}*|.\[$]{*dir}*)
2925         eval $1="[$]$1"
2926         case ".[$]$1" in
2927         (.NONE/*)
2928                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2929                 ;;
2930         esac
2931         ;;
2932 (.no|.NONE/*)
2933         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2934         ;;
2935 (*)
2936         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
2937         ;;
2938 esac
2939 ])dnl
2940 dnl ---------------------------------------------------------------------------
2941 dnl CF_PDCURSES_X11 version: 14 updated: 2018/06/20 20:23:13
2942 dnl ---------------
2943 dnl Configure for PDCurses' X11 library
2944 AC_DEFUN([CF_PDCURSES_X11],[
2945 AC_REQUIRE([CF_X_ATHENA])
2946
2947 CF_ACVERSION_CHECK(2.52,
2948         [AC_CHECK_TOOLS(XCURSES_CONFIG, xcurses-config, none)],
2949         [AC_PATH_PROGS(XCURSES_CONFIG, xcurses-config, none)])
2950
2951 if test "$XCURSES_CONFIG" != none ; then
2952
2953 CF_ADD_CFLAGS(`$XCURSES_CONFIG --cflags`)
2954 CF_ADD_LIBS(`$XCURSES_CONFIG --libs`)
2955
2956 cf_cv_lib_XCurses=yes
2957
2958 else
2959
2960 LDFLAGS="$LDFLAGS $X_LIBS"
2961 CF_CHECK_CFLAGS($X_CFLAGS)
2962 AC_CHECK_LIB(X11,XOpenDisplay,
2963         [CF_ADD_LIBS(-lX11)],,
2964         [$X_PRE_LIBS $LIBS $X_EXTRA_LIBS])
2965 AC_CACHE_CHECK(for XCurses library,cf_cv_lib_XCurses,[
2966 CF_ADD_LIBS(-lXCurses)
2967 AC_TRY_LINK([
2968 #include <xcurses.h>
2969 char *XCursesProgramName = "test";
2970 ],[XCursesExit();],
2971 [cf_cv_lib_XCurses=yes],
2972 [cf_cv_lib_XCurses=no])
2973 ])
2974
2975 fi
2976
2977 if test $cf_cv_lib_XCurses = yes ; then
2978         AC_DEFINE(UNIX,1,[Define to 1 if using PDCurses on Unix])
2979         AC_DEFINE(XCURSES,1,[Define to 1 if using PDCurses on Unix])
2980         AC_CHECK_HEADER(xcurses.h, AC_DEFINE(HAVE_XCURSES,1,[Define to 1 if using PDCurses on Unix]))
2981 else
2982         AC_MSG_ERROR(Cannot link with XCurses)
2983 fi
2984 ])dnl
2985 dnl ---------------------------------------------------------------------------
2986 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
2987 dnl -------------
2988 dnl Check for the package-config program, unless disabled by command-line.
2989 AC_DEFUN([CF_PKG_CONFIG],
2990 [
2991 AC_MSG_CHECKING(if you want to use pkg-config)
2992 AC_ARG_WITH(pkg-config,
2993         [  --with-pkg-config{=path} enable/disable use of pkg-config],
2994         [cf_pkg_config=$withval],
2995         [cf_pkg_config=yes])
2996 AC_MSG_RESULT($cf_pkg_config)
2997
2998 case $cf_pkg_config in
2999 (no)
3000         PKG_CONFIG=none
3001         ;;
3002 (yes)
3003         CF_ACVERSION_CHECK(2.52,
3004                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
3005                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
3006         ;;
3007 (*)
3008         PKG_CONFIG=$withval
3009         ;;
3010 esac
3011
3012 test -z "$PKG_CONFIG" && PKG_CONFIG=none
3013 if test "$PKG_CONFIG" != none ; then
3014         CF_PATH_SYNTAX(PKG_CONFIG)
3015 elif test "x$cf_pkg_config" != xno ; then
3016         AC_MSG_WARN(pkg-config is not installed)
3017 fi
3018
3019 AC_SUBST(PKG_CONFIG)
3020 ])dnl
3021 dnl ---------------------------------------------------------------------------
3022 dnl CF_POSIX_C_SOURCE version: 11 updated: 2018/12/31 20:46:17
3023 dnl -----------------
3024 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
3025 dnl
3026 dnl     POSIX.1-1990                            _POSIX_SOURCE
3027 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
3028 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
3029 dnl             Bindings Option
3030 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
3031 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
3032 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
3033 dnl
3034 dnl Parameters:
3035 dnl     $1 is the nominal value for _POSIX_C_SOURCE
3036 AC_DEFUN([CF_POSIX_C_SOURCE],
3037 [AC_REQUIRE([CF_POSIX_VISIBLE])dnl
3038
3039 if test "$cf_cv_posix_visible" = no; then
3040
3041 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
3042
3043 cf_save_CFLAGS="$CFLAGS"
3044 cf_save_CPPFLAGS="$CPPFLAGS"
3045
3046 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
3047 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
3048
3049 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
3050         CF_MSG_LOG(if the symbol is already defined go no further)
3051         AC_TRY_COMPILE([#include <sys/types.h>],[
3052 #ifndef _POSIX_C_SOURCE
3053 make an error
3054 #endif],
3055         [cf_cv_posix_c_source=no],
3056         [cf_want_posix_source=no
3057          case .$cf_POSIX_C_SOURCE in
3058          (.[[12]]??*)
3059                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
3060                 ;;
3061          (.2)
3062                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
3063                 cf_want_posix_source=yes
3064                 ;;
3065          (.*)
3066                 cf_want_posix_source=yes
3067                 ;;
3068          esac
3069          if test "$cf_want_posix_source" = yes ; then
3070                 AC_TRY_COMPILE([#include <sys/types.h>],[
3071 #ifdef _POSIX_SOURCE
3072 make an error
3073 #endif],[],
3074                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
3075          fi
3076          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
3077          CFLAGS="$cf_trim_CFLAGS"
3078          CPPFLAGS="$cf_trim_CPPFLAGS"
3079          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
3080          CF_MSG_LOG(if the second compile does not leave our definition intact error)
3081          AC_TRY_COMPILE([#include <sys/types.h>],[
3082 #ifndef _POSIX_C_SOURCE
3083 make an error
3084 #endif],,
3085          [cf_cv_posix_c_source=no])
3086          CFLAGS="$cf_save_CFLAGS"
3087          CPPFLAGS="$cf_save_CPPFLAGS"
3088         ])
3089 ])
3090
3091 if test "$cf_cv_posix_c_source" != no ; then
3092         CFLAGS="$cf_trim_CFLAGS"
3093         CPPFLAGS="$cf_trim_CPPFLAGS"
3094         CF_ADD_CFLAGS($cf_cv_posix_c_source)
3095 fi
3096
3097 fi # cf_cv_posix_visible
3098
3099 ])dnl
3100 dnl ---------------------------------------------------------------------------
3101 dnl CF_POSIX_VISIBLE version: 1 updated: 2018/12/31 20:46:17
3102 dnl ----------------
3103 dnl POSIX documents test-macros which an application may set before any system
3104 dnl headers are included to make features available.
3105 dnl
3106 dnl Some BSD platforms (originally FreeBSD, but copied by a few others)
3107 dnl diverged from POSIX in 2002 by setting symbols which make all of the most
3108 dnl recent features visible in the system header files unless the application
3109 dnl overrides the corresponding test-macros.  Doing that introduces portability
3110 dnl problems.
3111 dnl
3112 dnl This macro makes a special check for the symbols used for this, to avoid a
3113 dnl conflicting definition.
3114 AC_DEFUN([CF_POSIX_VISIBLE],
3115 [
3116 AC_CACHE_CHECK(if the POSIX test-macros are already defined,cf_cv_posix_visible,[
3117 AC_TRY_COMPILE([#include <stdio.h>],[
3118 #if defined(__POSIX_VISIBLE) && ((__POSIX_VISIBLE - 0L) > 0) \
3119         && defined(__XSI_VISIBLE) && ((__XSI_VISIBLE - 0L) > 0) \
3120         && defined(__BSD_VISIBLE) && ((__BSD_VISIBLE - 0L) > 0) \
3121         && defined(__ISO_C_VISIBLE) && ((__ISO_C_VISIBLE - 0L) > 0)
3122 #error conflicting symbols found
3123 #endif
3124 ],[cf_cv_posix_visible=no],[cf_cv_posix_visible=yes])
3125 ])
3126 ])dnl
3127 dnl ---------------------------------------------------------------------------
3128 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
3129 dnl ------------
3130 dnl Append definitions and rules for the given programs to the subdirectory
3131 dnl Makefiles, and the recursion rule for the top-level Makefile.
3132 dnl
3133 dnl parameters
3134 dnl     $1 = script to run
3135 dnl     $2 = list of subdirectories
3136 dnl
3137 dnl variables
3138 dnl     $AWK
3139 AC_DEFUN([CF_PRG_RULES],
3140 [
3141 for cf_dir in $2
3142 do
3143         if test ! -d $srcdir/$cf_dir; then
3144                 continue
3145         elif test -f $srcdir/$cf_dir/programs; then
3146                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
3147         fi
3148 done
3149
3150 ])dnl
3151 dnl ---------------------------------------------------------------------------
3152 dnl CF_PROG_CC version: 5 updated: 2019/12/31 08:53:54
3153 dnl ----------
3154 dnl standard check for CC, plus followup sanity checks
3155 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
3156 AC_DEFUN([CF_PROG_CC],[
3157 CF_ACVERSION_CHECK(2.53,
3158         [AC_MSG_WARN(this will incorrectly handle gnatgcc choice)
3159          AC_REQUIRE([AC_PROG_CC])],
3160         [])
3161 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
3162 CF_GCC_VERSION
3163 CF_ACVERSION_CHECK(2.52,
3164         [AC_PROG_CC_STDC],
3165         [CF_ANSI_CC_REQD])
3166 CF_CC_ENV_FLAGS
3167 ])dnl
3168 dnl ---------------------------------------------------------------------------
3169 dnl CF_PROG_INSTALL version: 7 updated: 2015/04/18 08:56:57
3170 dnl ---------------
3171 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
3172 dnl misc/tabset install won't work properly.  Usually this happens only when
3173 dnl using the fallback mkinstalldirs script
3174 AC_DEFUN([CF_PROG_INSTALL],
3175 [AC_PROG_INSTALL
3176 case $INSTALL in
3177 (/*)
3178         ;;
3179 (*)
3180         CF_DIRNAME(cf_dir,$INSTALL)
3181         test -z "$cf_dir" && cf_dir=.
3182         INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
3183         ;;
3184 esac
3185 ])dnl
3186 dnl ---------------------------------------------------------------------------
3187 dnl CF_PROG_LINT version: 4 updated: 2019/11/20 18:55:37
3188 dnl ------------
3189 AC_DEFUN([CF_PROG_LINT],
3190 [
3191 AC_CHECK_PROGS(LINT, lint cppcheck splint)
3192 case "x$LINT" in
3193 (xcppcheck|x*/cppcheck)
3194         test -z "$LINT_OPTS" && LINT_OPTS="--enable=all"
3195         ;;
3196 esac
3197 AC_SUBST(LINT_OPTS)
3198 ])dnl
3199 dnl ---------------------------------------------------------------------------
3200 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
3201 dnl ----------------
3202 dnl Remove all -U and -D options that refer to the given symbol from a list
3203 dnl of C compiler options.  This works around the problem that not all
3204 dnl compilers process -U and -D options from left-to-right, so a -U option
3205 dnl cannot be used to cancel the effect of a preceding -D option.
3206 dnl
3207 dnl $1 = target (which could be the same as the source variable)
3208 dnl $2 = source (including '$')
3209 dnl $3 = symbol to remove
3210 define([CF_REMOVE_DEFINE],
3211 [
3212 $1=`echo "$2" | \
3213         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
3214                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
3215 ])dnl
3216 dnl ---------------------------------------------------------------------------
3217 dnl CF_RESTORE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:47:45
3218 dnl ---------------------
3219 dnl Restore flags saved in CF_SAVE_XTRA_FLAGS
3220 dnl $1 = name of current macro
3221 define([CF_RESTORE_XTRA_FLAGS],
3222 [
3223 LIBS="$cf_save_LIBS_$1"
3224 CFLAGS="$cf_save_CFLAGS_$1"
3225 CPPFLAGS="$cf_save_CPPFLAGS_$1"
3226 ])dnl
3227 dnl ---------------------------------------------------------------------------
3228 dnl CF_RPATH_HACK version: 11 updated: 2013/09/01 13:02:00
3229 dnl -------------
3230 AC_DEFUN([CF_RPATH_HACK],
3231 [
3232 AC_REQUIRE([CF_LD_RPATH_OPT])
3233 AC_MSG_CHECKING(for updated LDFLAGS)
3234 if test -n "$LD_RPATH_OPT" ; then
3235         AC_MSG_RESULT(maybe)
3236
3237         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
3238         cf_rpath_list="/usr/lib /lib"
3239         if test "$cf_ldd_prog" != no
3240         then
3241                 cf_rpath_oops=
3242
3243 AC_TRY_LINK([#include <stdio.h>],
3244                 [printf("Hello");],
3245                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
3246                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
3247
3248                 # If we passed the link-test, but get a "not found" on a given library,
3249                 # this could be due to inept reconfiguration of gcc to make it only
3250                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
3251                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
3252                 # /usr/local libraries.
3253                 if test -n "$cf_rpath_oops"
3254                 then
3255                         for cf_rpath_src in $cf_rpath_oops
3256                         do
3257                                 for cf_rpath_dir in \
3258                                         /usr/local \
3259                                         /usr/pkg \
3260                                         /opt/sfw
3261                                 do
3262                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
3263                                         then
3264                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
3265                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
3266                                                 break
3267                                         fi
3268                                 done
3269                         done
3270                 fi
3271         fi
3272
3273         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
3274
3275         CF_RPATH_HACK_2(LDFLAGS)
3276         CF_RPATH_HACK_2(LIBS)
3277
3278         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
3279 else
3280         AC_MSG_RESULT(no)
3281 fi
3282 AC_SUBST(EXTRA_LDFLAGS)
3283 ])dnl
3284 dnl ---------------------------------------------------------------------------
3285 dnl CF_RPATH_HACK_2 version: 7 updated: 2015/04/12 15:39:00
3286 dnl ---------------
3287 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
3288 dnl EXTRA_LDFLAGS for each -L option found.
3289 dnl
3290 dnl $cf_rpath_list contains a list of directories to ignore.
3291 dnl
3292 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
3293 dnl      but LIBS often has misplaced -L options.
3294 AC_DEFUN([CF_RPATH_HACK_2],
3295 [
3296 CF_VERBOSE(...checking $1 [$]$1)
3297
3298 cf_rpath_dst=
3299 for cf_rpath_src in [$]$1
3300 do
3301         case $cf_rpath_src in
3302         (-L*)
3303
3304                 # check if this refers to a directory which we will ignore
3305                 cf_rpath_skip=no
3306                 if test -n "$cf_rpath_list"
3307                 then
3308                         for cf_rpath_item in $cf_rpath_list
3309                         do
3310                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
3311                                 then
3312                                         cf_rpath_skip=yes
3313                                         break
3314                                 fi
3315                         done
3316                 fi
3317
3318                 if test "$cf_rpath_skip" = no
3319                 then
3320                         # transform the option
3321                         if test "$LD_RPATH_OPT" = "-R " ; then
3322                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
3323                         else
3324                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
3325                         fi
3326
3327                         # if we have not already added this, add it now
3328                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
3329                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
3330                         then
3331                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
3332                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
3333                         fi
3334                 fi
3335                 ;;
3336         esac
3337         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
3338 done
3339 $1=$cf_rpath_dst
3340
3341 CF_VERBOSE(...checked $1 [$]$1)
3342 AC_SUBST(EXTRA_LDFLAGS)
3343 ])dnl
3344 dnl ---------------------------------------------------------------------------
3345 dnl CF_SAVE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:46:44
3346 dnl ------------------
3347 dnl Use this macro to save CFLAGS/CPPFLAGS/LIBS before checks against X headers
3348 dnl and libraries which do not update those variables.
3349 dnl
3350 dnl $1 = name of current macro
3351 define([CF_SAVE_XTRA_FLAGS],
3352 [
3353 cf_save_LIBS_$1="$LIBS"
3354 cf_save_CFLAGS_$1="$CFLAGS"
3355 cf_save_CPPFLAGS_$1="$CPPFLAGS"
3356 LIBS="$LIBS ${X_PRE_LIBS} ${X_LIBS} ${X_EXTRA_LIBS}"
3357 for cf_X_CFLAGS in $X_CFLAGS
3358 do
3359         case "x$cf_X_CFLAGS" in
3360         x-[[IUD]]*)
3361                 CPPFLAGS="$CPPFLAGS $cf_X_CFLAGS"
3362                 ;;
3363         *)
3364                 CFLAGS="$CFLAGS $cf_X_CFLAGS"
3365                 ;;
3366         esac
3367 done
3368 ])dnl
3369 dnl ---------------------------------------------------------------------------
3370 dnl CF_SIGWINCH version: 3 updated: 2020/03/10 18:53:47
3371 dnl -----------
3372 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
3373 dnl programs need this test).
3374 dnl
3375 dnl This is really a Mac OS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
3376 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
3377 dnl winsize declaration is left alone - we may revisit this if Apple choose to
3378 dnl break that part of the interface as well.
3379 AC_DEFUN([CF_SIGWINCH],
3380 [
3381 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
3382         AC_TRY_COMPILE([
3383 #include <sys/types.h>
3384 #include <sys/signal.h>
3385 ],[int x = SIGWINCH; (void)x],
3386         [cf_cv_define_sigwinch=yes],
3387         [AC_TRY_COMPILE([
3388 #undef _XOPEN_SOURCE
3389 #undef _POSIX_SOURCE
3390 #undef _POSIX_C_SOURCE
3391 #include <sys/types.h>
3392 #include <sys/signal.h>
3393 ],[int x = SIGWINCH; (void)x],
3394         [cf_cv_define_sigwinch=maybe],
3395         [cf_cv_define_sigwinch=no])
3396 ])
3397 ])
3398
3399 if test "$cf_cv_define_sigwinch" = maybe ; then
3400 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
3401 cf_cv_fixup_sigwinch=unknown
3402 cf_sigwinch=32
3403 while test $cf_sigwinch != 1
3404 do
3405         AC_TRY_COMPILE([
3406 #undef _XOPEN_SOURCE
3407 #undef _POSIX_SOURCE
3408 #undef _POSIX_C_SOURCE
3409 #include <sys/types.h>
3410 #include <sys/signal.h>
3411 ],[
3412 #if SIGWINCH != $cf_sigwinch
3413 make an error
3414 #endif
3415 int x = SIGWINCH; (void)x],
3416         [cf_cv_fixup_sigwinch=$cf_sigwinch
3417          break])
3418
3419 cf_sigwinch=`expr $cf_sigwinch - 1`
3420 done
3421 ])
3422
3423         if test "$cf_cv_fixup_sigwinch" != unknown ; then
3424                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
3425         fi
3426 fi
3427 ])dnl
3428 dnl ---------------------------------------------------------------------------
3429 dnl CF_SIG_ATOMIC_T version: 5 updated: 2020/03/10 18:53:47
3430 dnl ---------------
3431 dnl signal handler, but there are some gcc dependencies in that recommendation.
3432 dnl Try anyway.
3433 AC_DEFUN([CF_SIG_ATOMIC_T],
3434 [
3435 AC_MSG_CHECKING(for signal global datatype)
3436 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
3437         for cf_type in \
3438                 "volatile sig_atomic_t" \
3439                 "sig_atomic_t" \
3440                 "int"
3441         do
3442         AC_TRY_COMPILE([
3443 #include <sys/types.h>
3444 #include <signal.h>
3445 #include <stdio.h>
3446
3447 extern $cf_type x;
3448 $cf_type x;
3449 static void handler(int sig)
3450 {
3451         (void)sig;
3452         x = 5;
3453 }],
3454                 [signal(SIGINT, handler);
3455                  x = 1],
3456                 [cf_cv_sig_atomic_t=$cf_type],
3457                 [cf_cv_sig_atomic_t=no])
3458                 test "$cf_cv_sig_atomic_t" != no && break
3459         done
3460         ])
3461 AC_MSG_RESULT($cf_cv_sig_atomic_t)
3462 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
3463 ])dnl
3464 dnl ---------------------------------------------------------------------------
3465 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
3466 dnl --------------
3467 dnl Construct a search-list for a nonstandard header/lib-file
3468 dnl     $1 = the variable to return as result
3469 dnl     $2 = the package name
3470 dnl     $3 = the subdirectory, e.g., bin, include or lib
3471 AC_DEFUN([CF_SUBDIR_PATH],
3472 [
3473 $1=
3474
3475 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
3476
3477 for cf_subdir_prefix in \
3478         /usr \
3479         /usr/local \
3480         /usr/pkg \
3481         /opt \
3482         /opt/local \
3483         [$]HOME
3484 do
3485         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
3486 done
3487 ])dnl
3488 dnl ---------------------------------------------------------------------------
3489 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
3490 dnl ------------------
3491 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
3492 dnl older SCO configurations.
3493 AC_DEFUN([CF_SYS_TIME_SELECT],
3494 [
3495 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
3496 AC_CACHE_VAL(cf_cv_sys_time_select,[
3497 AC_TRY_COMPILE([
3498 #include <sys/types.h>
3499 #ifdef HAVE_SYS_TIME_H
3500 #include <sys/time.h>
3501 #endif
3502 #ifdef HAVE_SYS_SELECT_H
3503 #include <sys/select.h>
3504 #endif
3505 ],[],[cf_cv_sys_time_select=yes],
3506          [cf_cv_sys_time_select=no])
3507          ])
3508 AC_MSG_RESULT($cf_cv_sys_time_select)
3509 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
3510 ])dnl
3511 dnl ---------------------------------------------------------------------------
3512 dnl CF_TERM_HEADER version: 5 updated: 2020/03/19 20:23:48
3513 dnl --------------
3514 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
3515 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
3516 dnl but some packagers change this, breaking various applications.
3517 AC_DEFUN([CF_TERM_HEADER],[
3518 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
3519 case ${cf_cv_ncurses_header} in
3520 (*/ncurses.h|*/ncursesw.h)
3521         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
3522         ;;
3523 (*)
3524         cf_term_header=term.h
3525         ;;
3526 esac
3527
3528 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
3529 do
3530 AC_TRY_COMPILE([#include <stdio.h>
3531 #include <${cf_cv_ncurses_header:-curses.h}>
3532 #include <$cf_test>
3533 ],[int x = auto_left_margin; (void)x],[
3534         cf_cv_term_header="$cf_test"],[
3535         cf_cv_term_header=unknown
3536         ])
3537         test "$cf_cv_term_header" != unknown && break
3538 done
3539 ])
3540
3541 # Set definitions to allow ifdef'ing to accommodate subdirectories
3542
3543 case $cf_cv_term_header in
3544 (*term.h)
3545         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
3546         ;;
3547 esac
3548
3549 case $cf_cv_term_header in
3550 (ncurses/term.h)
3551         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
3552         ;;
3553 (ncursesw/term.h)
3554         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
3555         ;;
3556 esac
3557 ])dnl
3558 dnl ---------------------------------------------------------------------------
3559 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
3560 dnl ---------------
3561 dnl Define a top_builddir symbol, for applications that need an absolute path.
3562 AC_DEFUN([CF_TOP_BUILDDIR],
3563 [
3564 top_builddir=ifelse($1,,`pwd`,$1)
3565 AC_SUBST(top_builddir)
3566 ])dnl
3567 dnl ---------------------------------------------------------------------------
3568 dnl CF_TPUTS_PROTO version: 3 updated: 2015/04/17 21:26:14
3569 dnl --------------
3570 dnl Check for type of function-pointer passed to tputs.  Some old
3571 dnl implementations used functions that had different prototypes, making it
3572 dnl hard to compile portable programs using tputs.
3573 AC_DEFUN([CF_TPUTS_PROTO],[
3574 CF_CURSES_FUNCS(tputs)
3575 if test x$cf_cv_func_tputs = xyes
3576 then
3577         cf_done=no
3578         for cf_arg in int char
3579         do
3580                 for cf_ret in int void
3581                 do
3582                         if test $cf_ret = void
3583                         then
3584                                 cf_return="/* nothing */"
3585                         else
3586                                 cf_return="return value"
3587                         fi
3588                         AC_TRY_COMPILE([
3589 #include <${cf_cv_ncurses_header:-curses.h}>
3590 #include <$cf_cv_term_header>
3591
3592 static $cf_ret outc($cf_arg value) { $cf_return; }
3593 ],[
3594         tputs("hello", 0, outc);
3595         ${cf_cv_main_return:-return}(0);
3596 ],[
3597                 CF_VERBOSE([prototype $cf_ret func($cf_arg value)])
3598                 cat >>confdefs.h <<EOF
3599 #define TPUTS_ARG               $cf_arg
3600 #define TPUTS_PROTO(func,value) $cf_ret func(TPUTS_ARG value)
3601 #define TPUTS_RETURN(value)     $cf_return
3602 EOF
3603                 cf_done=yes
3604                 break
3605 ])
3606                 done
3607                 test $cf_done = yes && break
3608         done
3609 fi
3610 ])dnl
3611 dnl ---------------------------------------------------------------------------
3612 dnl CF_TRIM_X_LIBS version: 3 updated: 2015/04/12 15:39:00
3613 dnl --------------
3614 dnl Trim extra base X libraries added as a workaround for inconsistent library
3615 dnl dependencies returned by "new" pkg-config files.
3616 AC_DEFUN([CF_TRIM_X_LIBS],[
3617         for cf_trim_lib in Xmu Xt X11
3618         do
3619                 case "$LIBS" in
3620                 (*-l$cf_trim_lib\ *-l$cf_trim_lib*)
3621                         LIBS=`echo "$LIBS " | sed -e 's/  / /g' -e 's%-l'"$cf_trim_lib"' %%' -e 's/ $//'`
3622                         CF_VERBOSE(..trimmed $LIBS)
3623                         ;;
3624                 esac
3625         done
3626 ])
3627 dnl ---------------------------------------------------------------------------
3628 dnl CF_TRY_PKG_CONFIG version: 5 updated: 2013/07/06 21:27:06
3629 dnl -----------------
3630 dnl This is a simple wrapper to use for pkg-config, for libraries which may be
3631 dnl available in that form.
3632 dnl
3633 dnl $1 = package name
3634 dnl $2 = extra logic to use, if any, after updating CFLAGS and LIBS
3635 dnl $3 = logic to use if pkg-config does not have the package
3636 AC_DEFUN([CF_TRY_PKG_CONFIG],[
3637 AC_REQUIRE([CF_PKG_CONFIG])
3638
3639 if test "$PKG_CONFIG" != none && "$PKG_CONFIG" --exists $1; then
3640         CF_VERBOSE(found package $1)
3641         cf_pkgconfig_incs="`$PKG_CONFIG --cflags $1 2>/dev/null`"
3642         cf_pkgconfig_libs="`$PKG_CONFIG --libs   $1 2>/dev/null`"
3643         CF_VERBOSE(package $1 CFLAGS: $cf_pkgconfig_incs)
3644         CF_VERBOSE(package $1 LIBS: $cf_pkgconfig_libs)
3645         CF_ADD_CFLAGS($cf_pkgconfig_incs)
3646         CF_ADD_LIBS($cf_pkgconfig_libs)
3647         ifelse([$2],,:,[$2])
3648 else
3649         cf_pkgconfig_incs=
3650         cf_pkgconfig_libs=
3651         ifelse([$3],,:,[$3])
3652 fi
3653 ])
3654 dnl ---------------------------------------------------------------------------
3655 dnl CF_TRY_XOPEN_SOURCE version: 2 updated: 2018/06/20 20:23:13
3656 dnl -------------------
3657 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
3658 dnl can define it successfully.
3659 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
3660 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
3661         AC_TRY_COMPILE([
3662 #include <stdlib.h>
3663 #include <string.h>
3664 #include <sys/types.h>
3665 ],[
3666 #ifndef _XOPEN_SOURCE
3667 make an error
3668 #endif],
3669         [cf_cv_xopen_source=no],
3670         [cf_save="$CPPFLAGS"
3671          CF_APPEND_TEXT(CPPFLAGS,-D_XOPEN_SOURCE=$cf_XOPEN_SOURCE)
3672          AC_TRY_COMPILE([
3673 #include <stdlib.h>
3674 #include <string.h>
3675 #include <sys/types.h>
3676 ],[
3677 #ifdef _XOPEN_SOURCE
3678 make an error
3679 #endif],
3680         [cf_cv_xopen_source=no],
3681         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
3682         CPPFLAGS="$cf_save"
3683         ])
3684 ])
3685
3686 if test "$cf_cv_xopen_source" != no ; then
3687         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
3688         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
3689         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
3690         CF_ADD_CFLAGS($cf_temp_xopen_source)
3691 fi
3692 ])
3693 dnl ---------------------------------------------------------------------------
3694 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
3695 dnl --------
3696 dnl Make an uppercase version of a variable
3697 dnl $1=uppercase($2)
3698 AC_DEFUN([CF_UPPER],
3699 [
3700 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
3701 ])dnl
3702 dnl ---------------------------------------------------------------------------
3703 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
3704 dnl -----------
3705 dnl Check for multibyte support, and if not found, utf8 compatibility library
3706 AC_DEFUN([CF_UTF8_LIB],
3707 [
3708 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
3709         cf_save_LIBS="$LIBS"
3710         AC_TRY_LINK([
3711 #include <stdlib.h>],[putwc(0,0);],
3712         [cf_cv_utf8_lib=yes],
3713         [CF_FIND_LINKAGE([
3714 #include <libutf8.h>],[putwc(0,0);],utf8,
3715                 [cf_cv_utf8_lib=add-on],
3716                 [cf_cv_utf8_lib=no])
3717 ])])
3718
3719 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
3720 # ncurses/ncursesw:
3721 if test "$cf_cv_utf8_lib" = "add-on" ; then
3722         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
3723         CF_ADD_INCDIR($cf_cv_header_path_utf8)
3724         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
3725         CF_ADD_LIBS($cf_cv_library_file_utf8)
3726 fi
3727 ])dnl
3728 dnl ---------------------------------------------------------------------------
3729 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
3730 dnl ----------
3731 dnl Use AC_VERBOSE w/o the warnings
3732 AC_DEFUN([CF_VERBOSE],
3733 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
3734 CF_MSG_LOG([$1])
3735 ])dnl
3736 dnl ---------------------------------------------------------------------------
3737 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
3738 dnl -------------
3739 dnl Check if type wide-character type $1 is declared, and if so, which header
3740 dnl file is needed.  The second parameter is used to set a shell variable when
3741 dnl the type is not found.  The first parameter sets a shell variable for the
3742 dnl opposite sense.
3743 AC_DEFUN([CF_WCHAR_TYPE],
3744 [
3745 # This is needed on Tru64 5.0 to declare $1
3746 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
3747 AC_TRY_COMPILE([
3748 #include <stdlib.h>
3749 #include <stdarg.h>
3750 #include <stdio.h>
3751 #ifdef HAVE_LIBUTF8_H
3752 #include <libutf8.h>
3753 #endif],
3754         [$1 state],
3755         [cf_cv_$1=no],
3756         [AC_TRY_COMPILE([
3757 #include <stdlib.h>
3758 #include <stdarg.h>
3759 #include <stdio.h>
3760 #include <wchar.h>
3761 #ifdef HAVE_LIBUTF8_H
3762 #include <libutf8.h>
3763 #endif],
3764         [$1 value],
3765         [cf_cv_$1=yes],
3766         [cf_cv_$1=unknown])])])
3767
3768 if test "$cf_cv_$1" = yes ; then
3769         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
3770         NEED_WCHAR_H=1
3771 fi
3772
3773 ifelse([$2],,,[
3774 # if we do not find $1 in either place, use substitution to provide a fallback.
3775 if test "$cf_cv_$1" = unknown ; then
3776         $2=1
3777 fi
3778 ])
3779 ifelse($3,,,[
3780 # if we find $1 in either place, use substitution to provide a fallback.
3781 if test "$cf_cv_$1" != unknown ; then
3782         $3=1
3783 fi
3784 ])
3785 ])dnl
3786 dnl ---------------------------------------------------------------------------
3787 dnl CF_WITH_CURSES_DIR version: 3 updated: 2010/11/20 17:02:38
3788 dnl ------------------
3789 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
3790 dnl libraries.
3791 AC_DEFUN([CF_WITH_CURSES_DIR],[
3792
3793 AC_MSG_CHECKING(for specific curses-directory)
3794 AC_ARG_WITH(curses-dir,
3795         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
3796         [cf_cv_curses_dir=$withval],
3797         [cf_cv_curses_dir=no])
3798 AC_MSG_RESULT($cf_cv_curses_dir)
3799
3800 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
3801 then
3802         CF_PATH_SYNTAX(withval)
3803         if test -d "$cf_cv_curses_dir"
3804         then
3805                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
3806                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
3807         fi
3808 fi
3809 ])dnl
3810 dnl ---------------------------------------------------------------------------
3811 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
3812 dnl ----------------
3813 dnl Configure-option for dbmalloc.  The optional parameter is used to override
3814 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
3815 AC_DEFUN([CF_WITH_DBMALLOC],[
3816 CF_NO_LEAKS_OPTION(dbmalloc,
3817         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
3818         [USE_DBMALLOC])
3819
3820 if test "$with_dbmalloc" = yes ; then
3821         AC_CHECK_HEADER(dbmalloc.h,
3822                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
3823 fi
3824 ])dnl
3825 dnl ---------------------------------------------------------------------------
3826 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
3827 dnl ---------------
3828 dnl Configure-option for dmalloc.  The optional parameter is used to override
3829 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
3830 AC_DEFUN([CF_WITH_DMALLOC],[
3831 CF_NO_LEAKS_OPTION(dmalloc,
3832         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
3833         [USE_DMALLOC])
3834
3835 if test "$with_dmalloc" = yes ; then
3836         AC_CHECK_HEADER(dmalloc.h,
3837                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
3838 fi
3839 ])dnl
3840 dnl ---------------------------------------------------------------------------
3841 dnl CF_WITH_LIB_BASENAME version: 1 updated: 2020/03/07 20:05:14
3842 dnl --------------------
3843 dnl Allow for overriding the basename of a library, i.e., the part to which
3844 dnl prefixes/suffixes are attached.
3845 dnl
3846 dnl $1 = variable to set
3847 dnl $2 = option name
3848 dnl $3 = default basename for library, if omitted use $2
3849 AC_DEFUN([CF_WITH_LIB_BASENAME],
3850 [
3851 AC_MSG_CHECKING(for desired basename for $2 library)
3852 AC_ARG_WITH($2-libname,
3853         [  --with-$2-libname=XXX override ifelse($3,,$2,$3) basename of library],
3854         [with_lib_basename=$withval],
3855         [with_lib_basename=ifelse($3,,$2,$3)])
3856 $1="$with_lib_basename"
3857
3858 case "x[$]$1" in
3859 (x|xno|xnone|xyes)
3860         $1=ifelse($3,,$2,$3)
3861         ;;
3862 (*)
3863         ;;
3864 esac
3865
3866 AC_MSG_RESULT([$]$1)
3867 AC_SUBST($1)
3868 ])dnl
3869 dnl ---------------------------------------------------------------------------
3870 dnl CF_WITH_NCURSES_ETC version: 5 updated: 2016/02/20 19:23:20
3871 dnl -------------------
3872 dnl Use this macro for programs which use any variant of "curses", e.g.,
3873 dnl "ncurses", and "PDCurses".  Programs that can use curses and some unrelated
3874 dnl library (such as slang) should use a "--with-screen=XXX" option.
3875 dnl
3876 dnl This does not use AC_DEFUN, because that would tell autoconf to run each
3877 dnl of the macros inside this one - before this macro.
3878 define([CF_WITH_NCURSES_ETC],[
3879 CF_WITH_CURSES_DIR
3880
3881 cf_cv_screen=curses
3882
3883 AC_MSG_CHECKING(for specified curses library type)
3884 AC_ARG_WITH(screen,
3885         [  --with-screen=XXX       use specified curses-libraries],
3886         [cf_cv_screen=$withval],[
3887
3888 AC_ARG_WITH(ncursesw,
3889         [  --with-ncursesw         use wide ncurses-libraries],
3890         [cf_cv_screen=ncursesw],[
3891
3892 AC_ARG_WITH(ncurses,
3893         [  --with-ncurses          use ncurses-libraries],
3894         [cf_cv_screen=ncurses],[
3895
3896 AC_ARG_WITH(pdcurses,
3897         [  --with-pdcurses         compile/link with pdcurses X11 library],
3898         [cf_cv_screen=pdcurses],[
3899
3900 AC_ARG_WITH(curses-colr,
3901         [  --with-curses-colr      compile/link with HPUX 10.x color-curses],
3902         [cf_cv_screen=curses_colr],[
3903
3904 AC_ARG_WITH(curses-5lib,
3905         [  --with-curses-5lib      compile/link with SunOS 5lib curses],
3906         [cf_cv_screen=curses_5lib])])])])])])
3907
3908 AC_MSG_RESULT($cf_cv_screen)
3909
3910 case $cf_cv_screen in
3911 (curses|curses_*)
3912         CF_CURSES_CONFIG
3913         ;;
3914 (ncursesw*)
3915         CF_UTF8_LIB
3916         CF_NCURSES_CONFIG($cf_cv_screen)
3917         ;;
3918 (ncurses*)
3919         CF_NCURSES_CONFIG($cf_cv_screen)
3920         ;;
3921 (pdcurses)
3922         CF_PDCURSES_X11
3923         ;;
3924 (*)
3925         AC_MSG_ERROR(unexpected screen-value: $cf_cv_screen)
3926         ;;
3927 esac
3928
3929 CF_NCURSES_PTHREADS($cf_cv_screen)
3930
3931 ])dnl
3932 dnl ---------------------------------------------------------------------------
3933 dnl CF_WITH_SCREEN_PDCURSES version: 1 updated: 2020/08/28 16:56:27
3934 dnl -----------------------
3935 dnl Call this macro before CF_ENABLE_WARNINGS for configure scripts which use
3936 dnl the "--with-screen=pdcurses" selection.  Doing that allows the configure
3937 dnl script to search for the X11/Xt header files to declare (or not) the
3938 dnl symbol needed to enable "const" in those header files.  If that configure
3939 dnl option is not used, then those checks are unnecessary.
3940 AC_DEFUN([CF_WITH_SCREEN_PDCURSES],[
3941 AC_PROVIDE([AC_PATH_XTRA])
3942 AC_PROVIDE([AC_PATH_X])
3943 if test -n "$with_screen" && test "x$with_screen" = "xpdcurses"
3944 then
3945         AC_PATH_X
3946         AC_PATH_XTRA
3947 fi
3948 ])dnl
3949 dnl ---------------------------------------------------------------------------
3950 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
3951 dnl ----------------
3952 AC_DEFUN([CF_WITH_VALGRIND],[
3953 CF_NO_LEAKS_OPTION(valgrind,
3954         [  --with-valgrind         test: use valgrind],
3955         [USE_VALGRIND])
3956 ])dnl
3957 dnl ---------------------------------------------------------------------------
3958 dnl CF_WITH_X11_RGB version: 2 updated: 2019/12/31 08:53:54
3959 dnl ---------------
3960 dnl Handle configure option "--with-x11-rgb", setting these shell
3961 dnl variables:
3962 dnl
3963 dnl $RGB_PATH is the option value, used for finding the X11 rgb file.
3964 dnl $no_x11_rgb is a "#" (comment) if "--without-x11-rgb" is given.
3965 dnl
3966 dnl Most Linux's use this:
3967 dnl     /usr/share/X11/rgb.txt
3968 dnl Debian uses this:
3969 dnl     /etc/X11/rgb.txt
3970 dnl DragonFlyBSD ports uses this:
3971 dnl     /usr/pkg/lib/X11/rgb.txt
3972 dnl FreeBSD ports use these:
3973 dnl     /usr/local/lib/X11/rgb.txt
3974 dnl     /usr/local/share/X11/rgb.txt
3975 dnl Mandriva has these:
3976 dnl     /usr/lib/X11/rgb.txt
3977 dnl     /usr/lib64/X11/rgb.txt
3978 dnl NetBSD has these
3979 dnl     /usr/X11R7/lib/X11/rgb.txt
3980 dnl OpenSolaris uses
3981 dnl     32-bit:
3982 dnl     /usr/X11/etc/X11/rgb.txt
3983 dnl     /usr/X11/share/X11/rgb.txt
3984 dnl     /usr/X11/lib/X11/rgb.txt
3985 dnl OSX uses
3986 dnl             /opt/local/share/X11/rgb.txt (MacPorts)
3987 dnl             /opt/X11/share/X11/rgb.txt (non-ports)
3988 dnl     64-bit:
3989 dnl     /usr/X11/etc/X11/rgb.txt
3990 dnl     /usr/X11/share/X11/rgb.txt (perhaps)
3991 dnl     /usr/X11/lib/amd64/X11/rgb.txt
3992 dnl Solaris10 uses (in this order):
3993 dnl     /usr/openwin/lib/X11/rgb.txt
3994 dnl     /usr/X11/lib/X11/rgb.txt
3995 AC_DEFUN([CF_WITH_X11_RGB],[
3996 AC_MSG_CHECKING(for X11 rgb file)
3997 AC_ARG_WITH(x11-rgb,
3998         [  --with-x11-rgb=FILE   file containing X11 rgb information (EPREFIX/lib/X11/rgb.txt)],
3999         [RGB_PATH=$withval],
4000         [RGB_PATH=auto])
4001
4002 if test "x[$]RGB_PATH" = xauto
4003 then
4004         RGB_PATH='${exec_prefix}/lib/X11/rgb.txt'
4005         for cf_path in \
4006                 /opt/local/share/X11/rgb.txt \
4007                 /opt/X11/share/X11/rgb.txt \
4008                 /usr/share/X11/rgb.txt \
4009                 /usr/X11/share/X11/rgb.txt \
4010                 /usr/X11/lib/X11/rgb.txt \
4011                 /usr/lib/X11/rgb.txt \
4012                 /etc/X11/rgb.txt \
4013                 /usr/pkg/lib/X11/rgb.txt \
4014                 /usr/X11R7/lib/X11/rgb.txt \
4015                 /usr/X11R6/lib/X11/rgb.txt \
4016                 /usr/X11R5/lib/X11/rgb.txt \
4017                 /usr/X11R4/lib/X11/rgb.txt \
4018                 /usr/local/lib/X11/rgb.txt \
4019                 /usr/local/share/X11/rgb.txt \
4020                 /usr/lib64/X11/rgb.txt
4021         do
4022                 if test -f "$cf_path" ; then
4023                         RGB_PATH="$cf_path"
4024                         break
4025                 fi
4026         done
4027 else
4028         cf_path=$RGB_PATH
4029         CF_PATH_SYNTAX(cf_path)
4030 fi
4031
4032 AC_MSG_RESULT($RGB_PATH)
4033 AC_SUBST(RGB_PATH)
4034 AC_DEFINE_UNQUOTED(RGB_PATH,"$cf_path",[Define to the full pathname of rgb.txt])
4035
4036 no_x11_rgb=
4037 if test "$RGB_PATH" = no
4038 then
4039         no_x11_rgb="#"
4040 fi
4041 AC_SUBST(no_x11_rgb)
4042 ])dnl
4043 dnl ---------------------------------------------------------------------------
4044 dnl CF_XOPEN_CURSES version: 15 updated: 2020/03/19 20:23:48
4045 dnl ---------------
4046 dnl Test if we should define X/Open source for curses, needed on Digital Unix
4047 dnl 4.x, to see the extended functions, but breaks on IRIX 6.x.
4048 dnl
4049 dnl The getbegyx() check is needed for HPUX, which omits legacy macros such
4050 dnl as getbegy().  The latter is better design, but the former is standard.
4051 AC_DEFUN([CF_XOPEN_CURSES],
4052 [
4053 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
4054 AC_CACHE_CHECK(definition to turn on extended curses functions,cf_cv_need_xopen_extension,[
4055 cf_cv_need_xopen_extension=unknown
4056 AC_TRY_LINK([
4057 #include <stdlib.h>
4058 #include <${cf_cv_ncurses_header:-curses.h}>],[
4059 #if defined(NCURSES_VERSION_PATCH)
4060 #if (NCURSES_VERSION_PATCH < 20100501) && (NCURSES_VERSION_PATCH >= 20100403)
4061         make an error
4062 #endif
4063 #endif
4064 #ifdef NCURSES_VERSION
4065         cchar_t check;
4066         int check2 = curs_set((int)sizeof(check));
4067 #endif
4068         long x = winnstr(stdscr, "", 0);
4069         int x1, y1;
4070 #ifdef NCURSES_VERSION
4071         (void)check2;
4072 #endif
4073         getbegyx(stdscr, y1, x1);
4074         (void)x;
4075         (void)y1;
4076         (void)x1;
4077         ],
4078         [cf_cv_need_xopen_extension=none],
4079         [
4080         for cf_try_xopen_extension in _XOPEN_SOURCE_EXTENDED NCURSES_WIDECHAR
4081         do
4082                 AC_TRY_LINK([
4083 #define $cf_try_xopen_extension 1
4084 #include <stdlib.h>
4085 #include <${cf_cv_ncurses_header:-curses.h}>],[
4086 #ifdef NCURSES_VERSION
4087                 cchar_t check;
4088                 int check2 = curs_set((int)sizeof(check));
4089 #endif
4090                 long x = winnstr(stdscr, "", 0);
4091                 int x1, y1;
4092                 getbegyx(stdscr, y1, x1);
4093 #ifdef NCURSES_VERSION
4094                 (void)check2;
4095 #endif
4096                 (void)x;
4097                 (void)y1;
4098                 (void)x1;
4099                 ],
4100                 [cf_cv_need_xopen_extension=$cf_try_xopen_extension; break])
4101         done
4102         ])
4103 ])
4104
4105 case $cf_cv_need_xopen_extension in
4106 (*_*)
4107         CF_APPEND_TEXT(CPPFLAGS,-D$cf_cv_need_xopen_extension)
4108         ;;
4109 esac
4110
4111 ])dnl
4112 dnl ---------------------------------------------------------------------------
4113 dnl CF_XOPEN_SOURCE version: 55 updated: 2018/12/31 20:46:17
4114 dnl ---------------
4115 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
4116 dnl or adapt to the vendor's definitions to get equivalent functionality,
4117 dnl without losing the common non-POSIX features.
4118 dnl
4119 dnl Parameters:
4120 dnl     $1 is the nominal value for _XOPEN_SOURCE
4121 dnl     $2 is the nominal value for _POSIX_C_SOURCE
4122 AC_DEFUN([CF_XOPEN_SOURCE],[
4123 AC_REQUIRE([AC_CANONICAL_HOST])
4124 AC_REQUIRE([CF_POSIX_VISIBLE])
4125
4126 if test "$cf_cv_posix_visible" = no; then
4127
4128 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
4129 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
4130 cf_xopen_source=
4131
4132 case $host_os in
4133 (aix[[4-7]]*)
4134         cf_xopen_source="-D_ALL_SOURCE"
4135         ;;
4136 (msys)
4137         cf_XOPEN_SOURCE=600
4138         ;;
4139 (darwin[[0-8]].*)
4140         cf_xopen_source="-D_APPLE_C_SOURCE"
4141         ;;
4142 (darwin*)
4143         cf_xopen_source="-D_DARWIN_C_SOURCE"
4144         cf_XOPEN_SOURCE=
4145         ;;
4146 (freebsd*|dragonfly*|midnightbsd*)
4147         # 5.x headers associate
4148         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
4149         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
4150         cf_POSIX_C_SOURCE=200112L
4151         cf_XOPEN_SOURCE=600
4152         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
4153         ;;
4154 (hpux11*)
4155         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
4156         ;;
4157 (hpux*)
4158         cf_xopen_source="-D_HPUX_SOURCE"
4159         ;;
4160 (irix[[56]].*)
4161         cf_xopen_source="-D_SGI_SOURCE"
4162         cf_XOPEN_SOURCE=
4163         ;;
4164 (linux*|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin)
4165         CF_GNU_SOURCE($cf_XOPEN_SOURCE)
4166         ;;
4167 (minix*)
4168         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
4169         ;;
4170 (mirbsd*)
4171         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
4172         cf_XOPEN_SOURCE=
4173         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
4174         ;;
4175 (netbsd*)
4176         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
4177         ;;
4178 (openbsd[[4-9]]*)
4179         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
4180         cf_xopen_source="-D_BSD_SOURCE"
4181         cf_XOPEN_SOURCE=600
4182         ;;
4183 (openbsd*)
4184         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
4185         ;;
4186 (osf[[45]]*)
4187         cf_xopen_source="-D_OSF_SOURCE"
4188         ;;
4189 (nto-qnx*)
4190         cf_xopen_source="-D_QNX_SOURCE"
4191         ;;
4192 (sco*)
4193         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
4194         ;;
4195 (solaris2.*)
4196         cf_xopen_source="-D__EXTENSIONS__"
4197         cf_cv_xopen_source=broken
4198         ;;
4199 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
4200         cf_XOPEN_SOURCE=
4201         cf_POSIX_C_SOURCE=
4202         ;;
4203 (*)
4204         CF_TRY_XOPEN_SOURCE
4205         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
4206         ;;
4207 esac
4208
4209 if test -n "$cf_xopen_source" ; then
4210         CF_ADD_CFLAGS($cf_xopen_source,true)
4211 fi
4212
4213 dnl In anything but the default case, we may have system-specific setting
4214 dnl which is still not guaranteed to provide all of the entrypoints that
4215 dnl _XOPEN_SOURCE would yield.
4216 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
4217         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
4218         AC_TRY_COMPILE([#include <stdlib.h>],[
4219 #ifndef _XOPEN_SOURCE
4220 make an error
4221 #endif],
4222         [cf_XOPEN_SOURCE_set=yes],
4223         [cf_XOPEN_SOURCE_set=no])
4224         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
4225         if test $cf_XOPEN_SOURCE_set = yes
4226         then
4227                 AC_TRY_COMPILE([#include <stdlib.h>],[
4228 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
4229 make an error
4230 #endif],
4231                 [cf_XOPEN_SOURCE_set_ok=yes],
4232                 [cf_XOPEN_SOURCE_set_ok=no])
4233                 if test $cf_XOPEN_SOURCE_set_ok = no
4234                 then
4235                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
4236                 fi
4237         else
4238                 CF_TRY_XOPEN_SOURCE
4239         fi
4240 fi
4241 fi # cf_cv_posix_visible
4242 ])
4243 dnl ---------------------------------------------------------------------------
4244 dnl CF_X_ATHENA version: 24 updated: 2020/03/10 18:53:47
4245 dnl -----------
4246 dnl Check for Xaw (Athena) libraries
4247 dnl
4248 dnl Sets $cf_x_athena according to the flavor of Xaw which is used.
4249 AC_DEFUN([CF_X_ATHENA],
4250 [
4251 cf_x_athena=${cf_x_athena:-Xaw}
4252
4253 AC_MSG_CHECKING(if you want to link with Xaw 3d library)
4254 withval=
4255 AC_ARG_WITH(Xaw3d,
4256         [  --with-Xaw3d            link with Xaw 3d library])
4257 if test "$withval" = yes ; then
4258         cf_x_athena=Xaw3d
4259         AC_MSG_RESULT(yes)
4260 else
4261         AC_MSG_RESULT(no)
4262 fi
4263
4264 AC_MSG_CHECKING(if you want to link with Xaw 3d xft library)
4265 withval=
4266 AC_ARG_WITH(Xaw3dxft,
4267         [  --with-Xaw3dxft         link with Xaw 3d xft library])
4268 if test "$withval" = yes ; then
4269         cf_x_athena=Xaw3dxft
4270         AC_MSG_RESULT(yes)
4271 else
4272         AC_MSG_RESULT(no)
4273 fi
4274
4275 AC_MSG_CHECKING(if you want to link with neXT Athena library)
4276 withval=
4277 AC_ARG_WITH(neXtaw,
4278         [  --with-neXtaw           link with neXT Athena library])
4279 if test "$withval" = yes ; then
4280         cf_x_athena=neXtaw
4281         AC_MSG_RESULT(yes)
4282 else
4283         AC_MSG_RESULT(no)
4284 fi
4285
4286 AC_MSG_CHECKING(if you want to link with Athena-Plus library)
4287 withval=
4288 AC_ARG_WITH(XawPlus,
4289         [  --with-XawPlus          link with Athena-Plus library])
4290 if test "$withval" = yes ; then
4291         cf_x_athena=XawPlus
4292         AC_MSG_RESULT(yes)
4293 else
4294         AC_MSG_RESULT(no)
4295 fi
4296
4297 cf_x_athena_lib=""
4298
4299 if test "$PKG_CONFIG" != none ; then
4300         cf_athena_list=
4301         test "$cf_x_athena" = Xaw && cf_athena_list="xaw8 xaw7 xaw6"
4302         for cf_athena_pkg in \
4303                 $cf_athena_list \
4304                 ${cf_x_athena} \
4305                 ${cf_x_athena}-devel \
4306                 lib${cf_x_athena} \
4307                 lib${cf_x_athena}-devel
4308         do
4309                 CF_TRY_PKG_CONFIG($cf_athena_pkg,[
4310                         cf_x_athena_lib="$cf_pkgconfig_libs"
4311                         CF_UPPER(cf_x_athena_LIBS,HAVE_LIB_$cf_x_athena)
4312                         AC_DEFINE_UNQUOTED($cf_x_athena_LIBS)
4313
4314                         CF_TRIM_X_LIBS
4315
4316 AC_CACHE_CHECK(for usable $cf_x_athena/Xmu package,cf_cv_xaw_compat,[
4317 AC_TRY_LINK([
4318 #include <X11/Xmu/CharSet.h>
4319 ],[
4320 int check = XmuCompareISOLatin1("big", "small");
4321 (void)check;
4322 ],[cf_cv_xaw_compat=yes],[cf_cv_xaw_compat=no])])
4323
4324                         if test "$cf_cv_xaw_compat" = no
4325                         then
4326                                 # workaround for broken ".pc" files...
4327                                 case "$cf_x_athena_lib" in
4328                                 (*-lXmu*)
4329                                         ;;
4330                                 (*)
4331                                         CF_VERBOSE(work around broken package)
4332                                         cf_save_xmu="$LIBS"
4333                                         cf_first_lib=`echo "$cf_save_xmu" | sed -e 's/^[ ][ ]*//' -e 's/ .*//'`
4334                                         CF_TRY_PKG_CONFIG(xmu,[
4335                                                         LIBS="$cf_save_xmu"
4336                                                         CF_ADD_LIB_AFTER($cf_first_lib,$cf_pkgconfig_libs)
4337                                                 ],[
4338                                                         CF_ADD_LIB_AFTER($cf_first_lib,-lXmu)
4339                                                 ])
4340                                         CF_TRIM_X_LIBS
4341                                         ;;
4342                                 esac
4343                         fi
4344
4345                         break])
4346         done
4347 fi
4348
4349 if test -z "$cf_x_athena_lib" ; then
4350         CF_X_EXT
4351         CF_X_TOOLKIT
4352         CF_X_ATHENA_CPPFLAGS($cf_x_athena)