ncurses 6.0 - patch 20180106
[ncurses.git] / test / configure.in
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2017,2018 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1996-on
30 dnl
31 dnl $Id: configure.in,v 1.148 2018/01/02 23:39:26 tom Exp $
32 dnl This is a simple configuration-script for the ncurses test programs that
33 dnl allows the test-directory to be separately configured against a reference
34 dnl system (i.e., sysvr4 curses)
35 dnl
36 dnl If you're configuring ncurses, you shouldn't need to use this script.
37 dnl It's only for testing purposes.
38 dnl
39 dnl For additional information, see
40 dnl             https://invisible-island.net/autoconf/
41 dnl             https://invisible-island.net/ncurses/ncurses-examples.html
42 dnl ---------------------------------------------------------------------------
43 AC_PREREQ(2.52.20170501)
44 AC_INIT(ncurses.c)
45 AC_CONFIG_HEADER(ncurses_cfg.h:ncurses_tst.hin)
46
47 CF_INHERIT_SCRIPT(config.guess)
48 CF_INHERIT_SCRIPT(config.sub)
49 CF_CHECK_CACHE
50
51 AC_ARG_PROGRAM
52
53 AC_PROG_MAKE_SET
54 CF_PROG_CC
55 AC_C_INLINE
56 AC_PROG_CPP
57 AC_PROG_AWK
58 CF_PROG_INSTALL
59 CF_PROG_LINT
60 CF_MAKE_TAGS
61
62 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
63 AC_SUBST(MATH_LIB)
64
65 dnl Things that we don't need (or must override) if we're not building ncurses
66 CF_TOP_BUILDDIR
67 CC_G_OPT="-g"                                   AC_SUBST(CC_G_OPT)
68 CC_SHARED_OPTS=unknown                  AC_SUBST(CC_SHARED_OPTS)
69 CPPFLAGS="$CPPFLAGS"                    AC_SUBST(CPPFLAGS)
70 DFT_DEP_SUFFIX=""                               AC_SUBST(DFT_DEP_SUFFIX)
71 DFT_OBJ_SUBDIR=`pwd|sed -e's:.*/::'`    AC_SUBST(DFT_OBJ_SUBDIR)
72 DFT_UPR_MODEL="NORMAL"                  AC_SUBST(DFT_UPR_MODEL)
73 LD="ld"                                                 AC_SUBST(LD)
74 LDFLAGS_SHARED=""                               AC_SUBST(LDFLAGS_SHARED)
75 LDFLAGS_STATIC=""                               AC_SUBST(LDFLAGS_STATIC)
76 LD_MODEL=""                                             AC_SUBST(LD_MODEL)
77 LD_SHARED_OPTS=""                               AC_SUBST(LD_SHARED_OPTS)
78 LIBTOOL=""                                              AC_SUBST(LIBTOOL)
79 LIBTOOL_OPTS=""                                 AC_SUBST(LIBTOOL_OPTS)
80 LIB_CLEAN=""                                    AC_SUBST(LIB_CLEAN)
81 LIB_COMPILE=""                                  AC_SUBST(LIB_COMPILE)
82 LIB_LINK='${CC}'                                AC_SUBST(LIB_LINK)
83 LINK_TESTS=""                                   AC_SUBST(LINK_TESTS)
84 LOCAL_LDFLAGS=""                                AC_SUBST(LOCAL_LDFLAGS)
85 PACKAGE="ncurses-examples"              AC_SUBST(PACKAGE)
86 PTHREAD="-lm"                                   AC_SUBST(PTHREAD)
87 TEST_ARGS=""                                    AC_SUBST(TEST_ARGS)
88 TEST_DEPS=""                                    AC_SUBST(TEST_DEPS)
89 TEST_LIBS=""                                    AC_SUBST(TEST_LIBS)
90 TINFO_LDFLAGS=''                                AC_SUBST(TINFO_LDFLAGS)
91 TINFO_LIBS='$(LIBS_CURSES)'             AC_SUBST(TINFO_LIBS)
92 cf_cv_abi_version=""                    AC_SUBST(cf_cv_abi_version)
93 cf_cv_rel_version=""                    AC_SUBST(cf_cv_rel_version)
94 includesubdir=""                                AC_SUBST(includesubdir)
95
96 cf_cv_screen=curses
97 cf_cv_libtype=
98
99 AC_EXEEXT
100 AC_OBJEXT
101
102 CF_GCC_ATTRIBUTES
103 CF_ENABLE_STRING_HACKS
104 CF_XOPEN_SOURCE
105 CF_SIG_ATOMIC_T
106
107 # Work around breakage on OS X
108 CF_SIGWINCH
109
110 # Checks for CODESET support.
111 AM_LANGINFO_CODESET
112
113 dnl ---------------------------------------------------------------------------
114 CF_HELP_MESSAGE(General Options:)
115 CF_PKG_CONFIG
116 CF_DISABLE_ECHO
117
118 dnl ---------------------------------------------------------------------------
119 CF_HELP_MESSAGE(Curses Version-dependent Options:)
120 CF_NCURSES_WRAP_PREFIX
121
122 AC_MSG_CHECKING(if you want to check for wide-character functions)
123 CF_ARG_DISABLE(widec,
124         [  --disable-widec         disable checks for wide-character functions],
125         cf_enable_widec=no,
126         cf_enable_widec=yes,
127         yes)
128 AC_MSG_RESULT($cf_enable_widec)
129
130 dnl ---------------------------------------------------------------------------
131 CF_HELP_MESSAGE(Curses Version-dependent Options:)
132 CF_WITH_NCURSES_ETC
133
134 case $cf_cv_screen in
135 (ncurses*)
136         cf_cv_libtype=`echo "$cf_cv_screen" | sed -e 's/^ncurses//'`
137         ;;
138 esac
139
140 CF_WITH_X11_RGB
141
142 dnl If we've not specified a library, assume we're using sysvr4 libraries
143 dnl installed conventionally (e.g., SunOS 5.x - solaris).
144
145 dnl Autoconf builds up the $LIBS in reverse order
146
147 cf_curses_headers=
148
149 case $cf_cv_screen in
150 (pdcurses)
151         cf_default_panel=no
152         cf_default_form=no
153         cf_default_menu=no
154         cf_default_tinfo=no
155         ;;
156 (xcurses|bsdcurses)
157         cf_default_panel=no
158         cf_default_form=no
159         cf_default_menu=no
160         cf_default_tinfo=yes
161         ;;
162 (*)
163         cf_default_panel=yes
164         cf_default_form=yes
165         cf_default_menu=yes
166         cf_default_tinfo=yes
167         case $cf_cv_screen in
168         (ncurses*)
169                 cf_curses_headers="nc_alloc.h nomacros.h term_entry.h"
170                 ;;
171         esac
172         ;;
173 esac
174
175 AC_MSG_CHECKING(if you want to check for panel functions)
176 CF_ARG_DISABLE(panel,
177         [  --disable-panel         disable checks for panel functions],
178         cf_enable_panel=no,
179         cf_enable_panel=$cf_default_panel,
180         yes)
181 AC_MSG_RESULT($cf_enable_panel)
182 if test $cf_enable_panel = yes
183 then
184         CF_CHECK_CURSES_LIB(panel,$cf_cv_libtype,new_panel,0)
185         cf_curses_headers="$cf_curses_headers panel.h"
186 fi
187
188 AC_MSG_CHECKING(if you want to check for menu functions)
189 CF_ARG_DISABLE(menu,
190         [  --disable-menu          disable checks for menu functions],
191         cf_enable_menu=no,
192         cf_enable_menu=$cf_default_menu,
193         yes)
194 AC_MSG_RESULT($cf_enable_menu)
195 if test $cf_enable_menu = yes
196 then
197         case $cf_cv_screen in
198         (ncurses*)
199                 ;;
200         (curses*)
201                 CF_NETBSD_MENU_H
202                 ;;
203         esac
204         CF_CHECK_CURSES_LIB(menu,$cf_cv_libtype,menu_driver,[0,0])
205         cf_curses_headers="$cf_curses_headers menu.h"
206 fi
207
208 AC_MSG_CHECKING(if you want to check for form functions)
209 CF_ARG_DISABLE(form,
210         [  --disable-form          disable checks for form functions],
211         cf_enable_form=no,
212         cf_enable_form=$cf_default_form,
213         yes)
214 AC_MSG_RESULT($cf_enable_form)
215 if test $cf_enable_form = yes
216 then
217         case $cf_cv_screen in
218         (ncurses*)
219                 ;;
220         (curses*)
221                 CF_NETBSD_FORM_H
222                 ;;
223         esac
224         CF_CHECK_CURSES_LIB(form,$cf_cv_libtype,form_driver,[0,0])
225         cf_curses_headers="$cf_curses_headers form.h"
226 fi
227
228 # look for curses-related headers
229 AC_CHECK_HEADERS( $cf_curses_headers )
230
231 AC_STDC_HEADERS
232 AC_HEADER_TIME
233 AC_CHECK_HEADERS( \
234 getopt.h \
235 locale.h \
236 math.h \
237 stdarg.h \
238 stdint.h \
239 sys/ioctl.h \
240 sys/select.h \
241 sys/time.h \
242 termios.h \
243 unistd.h \
244 )
245
246 CF_GETOPT_HEADER
247
248 AC_CHECK_FUNCS( \
249 getopt \
250 gettimeofday \
251 tdestroy \
252 tsearch \
253 )
254
255 # use a compile-check to work with ncurses*-config and subdirectory includes
256 AC_CACHE_CHECK(if we can use termcap.h,cf_cv_have_termcap_h,[
257         AC_TRY_COMPILE([
258 #include <curses.h>
259 #include <termcap.h>
260 ],
261         [return 0;],
262         [cf_cv_have_termcap_h=yes],
263         [cf_cv_have_termcap_h=no])])
264 test "x$cf_cv_have_termcap_h" = xyes && AC_DEFINE(HAVE_TERMCAP_H)
265
266 if test "x$ac_cv_func_getopt" = xno; then
267         AC_MSG_ERROR(getopt is required for building programs)
268 fi
269
270 if test "$cf_enable_widec" = yes; then
271 AC_CHECK_FUNCS( \
272 mblen \
273 mbrlen \
274 mbrtowc \
275 mbsrtowcs \
276 mbstowcs \
277 mbtowc \
278 wcsrtombs \
279 wcstombs \
280 )
281 fi
282
283 CF_CURSES_FUNCS( \
284 alloc_pair \
285 assume_default_colors \
286 chgat \
287 color_content \
288 color_set \
289 copywin \
290 delscreen \
291 dupwin \
292 filter \
293 getbegx \
294 getcurx \
295 getmaxx \
296 getnstr \
297 getparx \
298 getwin \
299 halfdelay \
300 init_extended_color \
301 mvderwin \
302 mvvline \
303 mvwin \
304 mvwvline \
305 napms \
306 newpad \
307 putwin \
308 reset_color_pairs \
309 resize_term \
310 resizeterm \
311 restartterm \
312 ripoffline \
313 scr_dump \
314 setupterm \
315 slk_color \
316 slk_init \
317 termattrs \
318 tgetent \
319 tigetnum \
320 tigetstr \
321 tputs_sp \
322 typeahead \
323 use_default_colors \
324 use_env \
325 use_extended_names \
326 use_screen \
327 use_window \
328 vid_puts \
329 vidputs \
330 vsscanf \
331 vw_printw \
332 wchgat \
333 winsdelln \
334 winsstr \
335 wresize \
336 wsyncdown \
337 _tracef \
338 )
339
340 CF_TPUTS_PROTO
341 CF_NCURSES_EXT_FUNCS
342
343 if test "$cf_enable_widec" = yes
344 then
345         # workaround for systems with ncurses before 20111029, due to change of
346         # feature test macro from _XPG5 to _XOPEN_SOURCE
347         if test -n "$cf_cv_ncurses_version" && test "x$cf_cv_ncurses_version" != xno
348         then
349                 cf_define_xpg5=no
350                 AC_MSG_CHECKING(if _XPG5 should be defined to enable wide-characters)
351
352                 AC_TRY_COMPILE([
353 #include <${cf_cv_ncurses_header:-curses.h}>],
354                         [int x = _XPG5],,
355                         [cf_save_cppflags="$CPPFLAGS"
356                          CPPFLAGS="$CPPFLAGS -D_XPG5"
357                          AC_TRY_COMPILE([
358 #include <${cf_cv_ncurses_header:-curses.h}>],
359                                 [int x = _XPG5],
360                                 [cf_define_xpg5=yes])
361                          CPPFLAGS="$cf_save_cppflags"])
362                 AC_MSG_RESULT($cf_define_xpg5)
363
364                 if test "$cf_define_xpg5" = yes
365                 then
366                         CPPFLAGS="$CPPFLAGS -D_XPG5"
367                 fi
368         fi
369
370         AC_CACHE_CHECK(for wide-character functions,cf_cv_widechar_funcs,[
371         AC_TRY_LINK([
372 #include <${cf_cv_ncurses_header:-curses.h}>],
373         [
374                 static wchar_t src_wchar[2];
375                 static cchar_t dst_cchar;
376                 setcchar(&dst_cchar, src_wchar, A_NORMAL, 0, (void *) 0);
377                 ],
378                 [cf_cv_widechar_funcs=yes],
379                 [cf_cv_widechar_funcs=no])
380         ])
381         if test "$cf_cv_widechar_funcs" != no ; then
382                 AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to enable wide-character support in (n)curses])
383         else
384                 AC_DEFINE(USE_WIDEC_SUPPORT,0)
385         fi
386 else
387         AC_DEFINE(USE_WIDEC_SUPPORT,0)
388 fi
389
390 AC_CACHE_CHECK(if $cf_cv_screen library uses pthreads,cf_cv_use_pthreads,[
391 AC_TRY_LINK([
392 #include <${cf_cv_ncurses_header:-curses.h}>
393 extern void _nc_init_pthreads(void);
394 ],
395 [
396         initscr();
397         _nc_init_pthreads();
398         ],
399         [cf_cv_use_pthreads=yes],
400         [cf_cv_use_pthreads=no])
401 ])
402 test $cf_cv_use_pthreads = yes && AC_DEFINE(USE_PTHREADS)
403
404 CF_SYS_TIME_SELECT
405
406 # special check for test/ditto.c
407 CF_FUNC_OPENPTY
408 if test "$cf_cv_func_openpty" != no ; then
409         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
410         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
411         if test "x$cf_cv_lib_util" = xyes ; then
412                 CF_ADD_LIB(util,TEST_LIBS)
413         fi
414 fi
415
416 CF_FUNC_CURSES_VERSION
417
418 CF_CURSES_ACS_MAP
419 if test "$cf_enable_widec" = yes; then
420         CF_CURSES_WACS_MAP
421         CF_CURSES_WACS_SYMBOLS
422 fi
423
424 CF_CURSES_CHECK_TYPE(attr_t,long)
425
426 if test "$cf_enable_widec" = yes; then
427         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T, NCURSES_OK_MBSTATE_T)
428         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
429         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
430
431         if test "$NCURSES_OK_MBSTATE_T" = 0 ; then
432                 CF_CURSES_CHECK_TYPE(mbstate_t,long)
433         fi
434
435         if test "$NCURSES_OK_WCHAR_T" = 0 ; then
436                 CF_CURSES_CHECK_TYPE(wchar_t,long)
437         fi
438
439         if test "$NCURSES_OK_WINT_T" = 0 ; then
440                 CF_CURSES_CHECK_TYPE(wint_t,long)
441         fi
442 fi
443
444 CF_CURSES_CHECK_DATA(\
445 curscr \
446 ospeed \
447 boolnames \
448 boolfnames \
449 ttytype)
450
451 dnl ---------------------------------------------------------------------------
452 CF_HELP_MESSAGE(Testing/development Options:)
453 CF_ENABLE_WARNINGS(Wno-unknown-pragmas)
454 CF_DISABLE_LEAKS
455 CF_DISABLE_RPATH_HACK
456
457 TEST_ARGS="$LIBS"
458 LIBS=
459
460 dnl ---------------------------------------------------------------------------
461
462 AC_OUTPUT(Makefile,[
463 CF_PRG_RULES([$srcdir/mk-test.awk INSTALL=yes ECHO_LINK="$ECHO_LD"], .)
464         cat >>Makefile <<TEST_EOF
465
466 # These rules are generated so we do not rely on suffix rules, which do not
467 # work consistently for different make-programs (the '\$(MODEL)/' confuses
468 # some, and the '\$x' confuses others).
469 TEST_EOF
470
471 LIST=`sed -e 's/[[      ]].*//' -e '/^[[#@]]/d' $srcdir/modules`
472 for N in $LIST
473 do
474         cat >>Makefile <<TEST_EOF
475
476 \$(MODEL)/$N.o : \$(srcdir)/$N.c \\
477         \$(srcdir)/test.priv.h \\
478         ncurses_cfg.h
479         $SHOW_CC
480         $ECHO_CC\$(CC) -c \$(CFLAGS_DEFAULT) -DMODULE_NAME="$N" \$(srcdir)/$N.c
481 TEST_EOF
482 done
483
484 if test -f ../config.guess && test -f ../config.sub
485 then
486         cat >>Makefile <<TEST_EOF
487
488 # if we used CF_INHERIT for getting these files, we can remove them
489 distclean::
490         rm -f config.guess config.sub
491 TEST_EOF
492 fi
493 ],[
494 AWK="$AWK"
495 ECHO_CC="$ECHO_CC"
496 ECHO_LD="$ECHO_LD"
497 SHOW_CC="$SHOW_LD"
498 ],cat)