test/configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2014,2015 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1996, etc.
  30 dnl
  31 dnl $Id: configure.in,v 1.124 2015/08/08 20:24:49 tom Exp $
  32 dnl This is a simple configuration-script for the ncurses test programs that
  33 dnl allows the test-directory to be separately configured against a reference
  34 dnl system (i.e., sysvr4 curses)
  35 dnl
  36 dnl If you're configuring ncurses, you shouldn't need to use this script.
  37 dnl It's only for testing purposes.
  38 dnl
  39 dnl See http://invisible-island.net/autoconf/ for additional information.
  40 dnl ---------------------------------------------------------------------------
  41 AC_PREREQ(2.52.20030208)
  42 AC_INIT(ncurses.c)
  43 AC_CONFIG_HEADER(ncurses_cfg.h:ncurses_tst.hin)
  44
  45 CF_INHERIT_SCRIPT(config.guess)
  46 CF_INHERIT_SCRIPT(config.sub)
  47 CF_CHECK_CACHE
  48
  49 AC_ARG_PROGRAM
  50
  51 AC_PROG_MAKE_SET
  52 CF_PROG_CC
  53 AC_PROG_CPP
  54 AC_PROG_AWK
  55 CF_PROG_INSTALL
  56 CF_PROG_LINT
  57 CF_MAKE_TAGS
  58
  59 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
  60 AC_SUBST(MATH_LIB)
  61
  62 dnl Things that we don't need (or must override) if we're not building ncurses
  63 CF_TOP_BUILDDIR
  64 CC_G_OPT="-g"                                   AC_SUBST(CC_G_OPT)
  65 CC_SHARED_OPTS=unknown                  AC_SUBST(CC_SHARED_OPTS)
  66 CPPFLAGS="$CPPFLAGS"                    AC_SUBST(CPPFLAGS)
  67 DFT_DEP_SUFFIX=""                               AC_SUBST(DFT_DEP_SUFFIX)
  68 DFT_OBJ_SUBDIR=`pwd|sed -e's:.*/::'`    AC_SUBST(DFT_OBJ_SUBDIR)
  69 DFT_UPR_MODEL="NORMAL"                  AC_SUBST(DFT_UPR_MODEL)
  70 LD="ld"                                                 AC_SUBST(LD)
  71 LDFLAGS_SHARED=""                               AC_SUBST(LDFLAGS_SHARED)
  72 LDFLAGS_STATIC=""                               AC_SUBST(LDFLAGS_STATIC)
  73 LD_MODEL=""                                             AC_SUBST(LD_MODEL)
  74 LD_SHARED_OPTS=""                               AC_SUBST(LD_SHARED_OPTS)
  75 LIBTOOL=""                                              AC_SUBST(LIBTOOL)
  76 LIBTOOL_OPTS=""                                 AC_SUBST(LIBTOOL_OPTS)
  77 LIB_CLEAN=""                                    AC_SUBST(LIB_CLEAN)
  78 LIB_COMPILE=""                                  AC_SUBST(LIB_COMPILE)
  79 LIB_LINK='${CC}'                                AC_SUBST(LIB_LINK)
  80 LINK_TESTS=""                                   AC_SUBST(LINK_TESTS)
  81 LOCAL_LDFLAGS=""                                AC_SUBST(LOCAL_LDFLAGS)
  82 PACKAGE="ncurses-examples"              AC_SUBST(PACKAGE)
  83 PTHREAD="-lm"                                   AC_SUBST(PTHREAD)
  84 TEST_ARGS=""                                    AC_SUBST(TEST_ARGS)
  85 TEST_DEPS=""                                    AC_SUBST(TEST_DEPS)
  86 TEST_LIBS=""                                    AC_SUBST(TEST_LIBS)
  87 TINFO_LDFLAGS=''                                AC_SUBST(TINFO_LDFLAGS)
  88 TINFO_LIBS='$(LIBS_CURSES)'             AC_SUBST(TINFO_LIBS)
  89 cf_cv_abi_version=""                    AC_SUBST(cf_cv_abi_version)
  90 cf_cv_rel_version=""                    AC_SUBST(cf_cv_rel_version)
  91 includesubdir=""                                AC_SUBST(includesubdir)
  92
  93 cf_cv_screen=curses
  94 cf_cv_libtype=
  95
  96 AC_EXEEXT
  97 AC_OBJEXT
  98
  99 CF_GCC_ATTRIBUTES
 100 CF_XOPEN_SOURCE
 101 CF_SIG_ATOMIC_T
 102
 103 dnl ---------------------------------------------------------------------------
 104 CF_HELP_MESSAGE(General Options:)
 105 CF_PKG_CONFIG
 106 CF_DISABLE_ECHO
 107
 108 dnl ---------------------------------------------------------------------------
 109 CF_HELP_MESSAGE(Curses Version-dependent Options:)
 110 CF_NCURSES_WRAP_PREFIX
 111
 112 AC_MSG_CHECKING(if you want to check for wide-character functions)
 113 CF_ARG_DISABLE(widec,
 114         [  --disable-widec         disable checks for wide-character functions],
 115         cf_enable_widec=no,
 116         cf_enable_widec=yes,
 117         yes)
 118 AC_MSG_RESULT($cf_enable_widec)
 119
 120 dnl ---------------------------------------------------------------------------
 121 CF_HELP_MESSAGE(Curses Version-dependent Options:)
 122 CF_WITH_NCURSES_ETC
 123
 124 case $cf_cv_screen in
 125 (ncurses*)
 126         cf_cv_libtype=`echo "$cf_cv_screen" | sed -e 's/^ncurses//'`
 127         ;;
 128 (curses|curses_*)
 129         CF_NETBSD_FORM_H
 130         CF_NETBSD_MENU_H
 131         ;;
 132 esac
 133
 134 dnl If we've not specified a library, assume we're using sysvr4 libraries
 135 dnl installed conventionally (e.g., SunOS 5.x - solaris).
 136
 137 dnl Autoconf builds up the $LIBS in reverse order
 138
 139 case $cf_cv_screen in
 140 (pdcurses)
 141         ;;
 142 (*)
 143         # look for curses-related libraries
 144         CF_CHECK_CURSES_LIB(panel,$cf_cv_libtype,new_panel)
 145         CF_CHECK_CURSES_LIB(menu,$cf_cv_libtype,menu_driver)
 146         CF_CHECK_CURSES_LIB(form,$cf_cv_libtype,form_driver)
 147
 148         # look for curses-related headers
 149         AC_CHECK_HEADERS( \
 150                 nc_alloc.h \
 151                 nomacros.h \
 152                 form.h \
 153                 menu.h \
 154                 panel.h \
 155                 term_entry.h \
 156                 )
 157         ;;
 158 esac
 159
 160 AC_STDC_HEADERS
 161 AC_HEADER_TIME
 162 AC_CHECK_HEADERS( \
 163 getopt.h \
 164 locale.h \
 165 math.h \
 166 stdarg.h \
 167 sys/ioctl.h \
 168 sys/select.h \
 169 sys/time.h \
 170 termios.h \
 171 unistd.h \
 172 )
 173
 174 CF_GETOPT_HEADER
 175
 176 AC_CHECK_FUNCS( \
 177 getopt \
 178 gettimeofday \
 179 )
 180
 181 if test "x$ac_cv_func_getopt" = xno; then
 182         AC_MSG_ERROR(getopt is required for building programs)
 183 fi
 184
 185 if test "$cf_enable_widec" = yes; then
 186 AC_CHECK_FUNCS( \
 187 mblen \
 188 mbrlen \
 189 mbrtowc \
 190 mbsrtowcs \
 191 mbstowcs \
 192 mbtowc \
 193 wcsrtombs \
 194 wcstombs \
 195 )
 196 fi
 197
 198 CF_CURSES_FUNCS( \
 199 assume_default_colors \
 200 chgat \
 201 color_set \
 202 filter \
 203 getbegx \
 204 getcurx \
 205 getmaxx \
 206 getnstr \
 207 getparx \
 208 getwin \
 209 mvvline \
 210 mvwvline \
 211 napms \
 212 putwin \
 213 resize_term \
 214 resizeterm \
 215 ripoffline \
 216 scr_dump \
 217 setupterm \
 218 slk_color \
 219 slk_init \
 220 termattrs \
 221 tgetent \
 222 tigetnum \
 223 tigetstr \
 224 typeahead \
 225 use_default_colors \
 226 use_env \
 227 use_extended_names \
 228 use_screen \
 229 use_window \
 230 vid_puts \
 231 vidputs \
 232 vsscanf \
 233 vw_printw \
 234 wchgat \
 235 winsstr \
 236 wresize \
 237 wsyncdown \
 238 )
 239
 240 CF_TPUTS_PROTO
 241 CF_NCURSES_EXT_FUNCS
 242
 243 if test "$cf_enable_widec" = yes
 244 then
 245         # workaround for systems with ncurses before 20111029, due to change of
 246         # feature test macro from _XPG5 to _XOPEN_SOURCE
 247         if test -n "$cf_cv_ncurses_version" && test "x$cf_cv_ncurses_version" != xno
 248         then
 249                 cf_define_xpg5=no
 250                 AC_MSG_CHECKING(if _XPG5 should be defined to enable wide-characters)
 251
 252                 AC_TRY_COMPILE([
 253 #include <${cf_cv_ncurses_header:-curses.h}>],
 254                         [int x = _XPG5],,
 255                         [cf_save_cppflags="$CPPFLAGS"
 256                          CPPFLAGS="$CPPFLAGS -D_XPG5"
 257                          AC_TRY_COMPILE([
 258 #include <${cf_cv_ncurses_header:-curses.h}>],
 259                                 [int x = _XPG5],
 260                                 [cf_define_xpg5=yes])
 261                          CPPFLAGS="$cf_save_cppflags"])
 262                 AC_MSG_RESULT($cf_define_xpg5)
 263
 264                 if test "$cf_define_xpg5" = yes
 265                 then
 266                         CPPFLAGS="$CPPFLAGS -D_XPG5"
 267                 fi
 268         fi
 269
 270         AC_CACHE_CHECK(for wide-character functions,cf_cv_widechar_funcs,[
 271         AC_TRY_LINK([
 272 #include <${cf_cv_ncurses_header:-curses.h}>],
 273         [
 274                 static wchar_t src_wchar[2];
 275                 static cchar_t dst_cchar;
 276                 setcchar(&dst_cchar, src_wchar, A_NORMAL, 0, (void *) 0);
 277                 ],
 278                 [cf_cv_widechar_funcs=yes],
 279                 [cf_cv_widechar_funcs=no])
 280         ])
 281         if test "$cf_cv_widechar_funcs" != no ; then
 282                 AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to enable wide-character support in (n)curses])
 283         else
 284                 AC_DEFINE(USE_WIDEC_SUPPORT,0)
 285         fi
 286 else
 287         AC_DEFINE(USE_WIDEC_SUPPORT,0)
 288 fi
 289
 290 AC_CACHE_CHECK(if $cf_cv_screen library uses pthreads,cf_cv_use_pthreads,[
 291 AC_TRY_LINK([
 292 #include <${cf_cv_ncurses_header:-curses.h}>
 293 extern void _nc_init_pthreads(void);
 294 ],
 295 [
 296         initscr();
 297         _nc_init_pthreads();
 298         ],
 299         [cf_cv_use_pthreads=yes],
 300         [cf_cv_use_pthreads=no])
 301 ])
 302 test $cf_cv_use_pthreads = yes && AC_DEFINE(USE_PTHREADS)
 303
 304 CF_SYS_TIME_SELECT
 305 CF_FUNC_CURSES_VERSION
 306
 307 CF_CURSES_ACS_MAP
 308 if test "$cf_enable_widec" = yes; then
 309         CF_CURSES_WACS_MAP
 310         CF_CURSES_WACS_SYMBOLS
 311 fi
 312
 313 CF_CURSES_CHECK_TYPE(attr_t,long)
 314
 315 if test "$cf_enable_widec" = yes; then
 316         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T, NCURSES_OK_MBSTATE_T)
 317         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 318         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 319
 320         if test "$NCURSES_OK_MBSTATE_T" = 0 ; then
 321                 CF_CURSES_CHECK_TYPE(mbstate_t,long)
 322         fi
 323
 324         if test "$NCURSES_OK_WCHAR_T" = 0 ; then
 325                 CF_CURSES_CHECK_TYPE(wchar_t,long)
 326         fi
 327
 328         if test "$NCURSES_OK_WINT_T" = 0 ; then
 329                 CF_CURSES_CHECK_TYPE(wint_t,long)
 330         fi
 331 fi
 332
 333 CF_CURSES_CHECK_DATA(ospeed)
 334 CF_CURSES_CHECK_DATA(boolnames)
 335 CF_CURSES_CHECK_DATA(boolfnames)
 336
 337 dnl ---------------------------------------------------------------------------
 338 CF_HELP_MESSAGE(Testing/development Options:)
 339 CF_ENABLE_WARNINGS
 340 CF_DISABLE_LEAKS
 341 CF_DISABLE_RPATH_HACK
 342
 343 TEST_ARGS="$LIBS"
 344 LIBS=
 345
 346 dnl ---------------------------------------------------------------------------
 347
 348 AC_OUTPUT(Makefile,[
 349 CF_PRG_RULES([$srcdir/mk-test.awk INSTALL=yes ECHO_LINK="$ECHO_LD"], .)
 350         cat >>Makefile <<TEST_EOF
 351
 352 # These rules are generated so we do not rely on suffix rules, which do not
 353 # work consistently for different make-programs (the '\$(MODEL)/' confuses
 354 # some, and the '\$x' confuses others).
 355 TEST_EOF
 356
 357 LIST=`sed -e 's/[[      ]].*//' -e '/^[[#@]]/d' $srcdir/modules`
 358 for N in $LIST
 359 do
 360         cat >>Makefile <<TEST_EOF
 361
 362 \$(MODEL)/$N.o : \$(srcdir)/$N.c \\
 363         \$(srcdir)/test.priv.h \\
 364         ncurses_cfg.h
 365         $SHOW_CC
 366         $ECHO_CC\$(CC) -c \$(CFLAGS_DEFAULT) \$(srcdir)/$N.c
 367 TEST_EOF
 368 done
 369
 370 if test -f ../config.guess && test -f ../config.sub
 371 then
 372         cat >>Makefile <<TEST_EOF
 373
 374 # if we used CF_INHERIT for getting these files, we can remove them
 375 distclean::
 376         rm -f config.guess config.sub
 377 TEST_EOF
 378 fi
 379 ],[
 380 AWK="$AWK"
 381 ECHO_CC="$ECHO_CC"
 382 ECHO_LD="$ECHO_LD"
 383 SHOW_CC="$SHOW_LD"
 384 ],cat)