test/configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2012,2013 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1996, etc.
  30 dnl
  31 dnl $Id: configure.in,v 1.112 2013/05/18 21:53:54 tom Exp $
  32 dnl This is a simple configuration-script for the ncurses test programs that
  33 dnl allows the test-directory to be separately configured against a reference
  34 dnl system (i.e., sysvr4 curses)
  35 dnl
  36 dnl If you're configuring ncurses, you shouldn't need to use this script.
  37 dnl It's only for testing purposes.
  38 dnl
  39 dnl See http://invisible-island.net/autoconf/ for additional information.
  40 dnl ---------------------------------------------------------------------------
  41 AC_PREREQ(2.52.20030208)
  42 AC_INIT(ncurses.c)
  43 AC_CONFIG_HEADER(ncurses_cfg.h:ncurses_tst.hin)
  44
  45 CF_INHERIT_SCRIPT(config.guess)
  46 CF_INHERIT_SCRIPT(config.sub)
  47 CF_CHECK_CACHE
  48
  49 AC_ARG_PROGRAM
  50
  51 AC_PROG_MAKE_SET
  52 CF_PROG_CC
  53 AC_PROG_CPP
  54 AC_PROG_AWK
  55 CF_PROG_INSTALL
  56 CF_PROG_LINT
  57 CF_MAKE_TAGS
  58
  59 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
  60 AC_SUBST(MATH_LIB)
  61
  62 dnl Things that we don't need (or must override) if we're not building ncurses
  63 CF_TOP_BUILDDIR
  64 CC_G_OPT="-g"                                   AC_SUBST(CC_G_OPT)
  65 CC_SHARED_OPTS=unknown                  AC_SUBST(CC_SHARED_OPTS)
  66 CPPFLAGS="$CPPFLAGS"                    AC_SUBST(CPPFLAGS)
  67 DFT_DEP_SUFFIX=""                               AC_SUBST(DFT_DEP_SUFFIX)
  68 DFT_OBJ_SUBDIR=`pwd|sed -e's:.*/::'`    AC_SUBST(DFT_OBJ_SUBDIR)
  69 DFT_UPR_MODEL="NORMAL"                  AC_SUBST(DFT_UPR_MODEL)
  70 LD="ld"                                                 AC_SUBST(LD)
  71 LDFLAGS_SHARED=""                               AC_SUBST(LDFLAGS_SHARED)
  72 LDFLAGS_STATIC=""                               AC_SUBST(LDFLAGS_STATIC)
  73 LD_MODEL=""                                             AC_SUBST(LD_MODEL)
  74 LD_SHARED_OPTS=""                               AC_SUBST(LD_SHARED_OPTS)
  75 LIBTOOL=""                                              AC_SUBST(LIBTOOL)
  76 LIB_CLEAN=""                                    AC_SUBST(LIB_CLEAN)
  77 LIB_COMPILE=""                                  AC_SUBST(LIB_COMPILE)
  78 LIB_LINK='${CC}'                                AC_SUBST(LIB_LINK)
  79 LINK_TESTS=""                                   AC_SUBST(LINK_TESTS)
  80 LOCAL_LDFLAGS=""                                AC_SUBST(LOCAL_LDFLAGS)
  81 PTHREAD="-lm"                                   AC_SUBST(PTHREAD)
  82 TEST_ARGS=""                                    AC_SUBST(TEST_ARGS)
  83 TEST_DEPS=""                                    AC_SUBST(TEST_DEPS)
  84 TEST_LIBS=""                                    AC_SUBST(TEST_LIBS)
  85 TINFO_LDFLAGS=''                                AC_SUBST(TINFO_LDFLAGS)
  86 TINFO_LIBS='$(LIBS_CURSES)'             AC_SUBST(TINFO_LIBS)
  87 cf_cv_abi_version=""                    AC_SUBST(cf_cv_abi_version)
  88 cf_cv_rel_version=""                    AC_SUBST(cf_cv_rel_version)
  89
  90 cf_cv_screen=curses
  91 cf_cv_libtype=
  92
  93 AC_EXEEXT
  94 AC_OBJEXT
  95
  96 CF_GCC_ATTRIBUTES
  97 CF_XOPEN_SOURCE
  98 CF_SIG_ATOMIC_T
  99
 100 dnl ---------------------------------------------------------------------------
 101 CF_HELP_MESSAGE(General Options:)
 102 CF_PKG_CONFIG
 103 CF_DISABLE_ECHO
 104
 105 dnl ---------------------------------------------------------------------------
 106 CF_HELP_MESSAGE(Curses Version-dependent Options:)
 107 CF_NCURSES_WRAP_PREFIX
 108
 109 AC_MSG_CHECKING(if you want to check for wide-character functions)
 110 CF_ARG_DISABLE(widec,
 111         [  --disable-widec         disable checks for wide-character functions],
 112         cf_enable_widec=no,
 113         cf_enable_widec=yes,
 114         yes)
 115 AC_MSG_RESULT($cf_enable_widec)
 116
 117 dnl ---------------------------------------------------------------------------
 118 CF_HELP_MESSAGE(Curses Version-dependent Options:)
 119 CF_WITH_NCURSES_ETC
 120
 121 case $cf_cv_screen in
 122 curses|curses_*)
 123         CF_NETBSD_FORM_H
 124         CF_NETBSD_MENU_H
 125         ;;
 126 ncursesw)
 127         cf_cv_libtype=w
 128         ;;
 129 esac
 130
 131 dnl If we've not specified a library, assume we're using sysvr4 libraries
 132 dnl installed conventionally (e.g., SunOS 5.x - solaris).
 133
 134 dnl Autoconf builds up the $LIBS in reverse order
 135
 136 case $cf_cv_screen in #(vi
 137 pdcurses) #(vi
 138         ;;
 139 *)
 140         # look for curses-related libraries
 141         : ${cf_panel_lib:=panel}
 142         : ${cf_menu_lib:=menu}
 143         : ${cf_form_lib:=form}
 144         AC_CHECK_LIB($cf_panel_lib$cf_cv_libtype,new_panel)
 145         AC_CHECK_LIB($cf_menu_lib$cf_cv_libtype,menu_driver)
 146         AC_CHECK_LIB($cf_form_lib$cf_cv_libtype,form_driver)
 147
 148         # look for curses-related headers
 149         AC_CHECK_HEADERS( \
 150                 nc_alloc.h \
 151                 nomacros.h \
 152                 form.h \
 153                 menu.h \
 154                 panel.h \
 155                 term_entry.h \
 156                 )
 157         ;;
 158 esac
 159
 160 AC_STDC_HEADERS
 161 AC_HEADER_TIME
 162 AC_CHECK_HEADERS( \
 163 getopt.h \
 164 locale.h \
 165 math.h \
 166 stdarg.h \
 167 sys/ioctl.h \
 168 sys/select.h \
 169 sys/time.h \
 170 termios.h \
 171 unistd.h \
 172 )
 173
 174 CF_GETOPT_HEADER
 175
 176 AC_CHECK_FUNCS( \
 177 gettimeofday \
 178 )
 179
 180 if test "$cf_enable_widec" = yes; then
 181 AC_CHECK_FUNCS( \
 182 mblen \
 183 mbrlen \
 184 mbrtowc \
 185 mbsrtowcs \
 186 mbstowcs \
 187 mbtowc \
 188 wcsrtombs \
 189 wcstombs \
 190 )
 191 fi
 192
 193 CF_CURSES_FUNCS( \
 194 assume_default_colors \
 195 chgat \
 196 color_set \
 197 filter \
 198 getbegx \
 199 getcurx \
 200 getmaxx \
 201 getnstr \
 202 getparx \
 203 getwin \
 204 mvvline \
 205 mvwvline \
 206 napms \
 207 putwin \
 208 resize_term \
 209 resizeterm \
 210 ripoffline \
 211 scr_dump \
 212 setupterm \
 213 slk_color \
 214 slk_init \
 215 termattrs \
 216 tgetent \
 217 tigetnum \
 218 tigetstr \
 219 typeahead \
 220 use_default_colors \
 221 use_screen \
 222 use_window \
 223 vsscanf \
 224 vw_printw \
 225 wchgat \
 226 winsstr \
 227 wresize \
 228 wsyncdown \
 229 )
 230
 231 CF_TPUTS_PROTO
 232 CF_NCURSES_EXT_FUNCS
 233
 234 if test "$cf_enable_widec" = yes
 235 then
 236         # workaround for systems with ncurses before 20111029, due to change of
 237         # feature test macro from _XPG5 to _XOPEN_SOURCE
 238         if test -n "$cf_cv_ncurses_version" && test "x$cf_cv_ncurses_version" != xno
 239         then
 240                 cf_define_xpg5=no
 241                 AC_MSG_CHECKING(if _XPG5 should be defined to enable wide-characters)
 242
 243                 AC_TRY_COMPILE([
 244 #include <${cf_cv_ncurses_header:-curses.h}>],
 245                         [int x = _XPG5],,
 246                         [cf_save_cppflags="$CPPFLAGS"
 247                          CPPFLAGS="$CPPFLAGS -D_XPG5"
 248                          AC_TRY_COMPILE([
 249 #include <${cf_cv_ncurses_header:-curses.h}>],
 250                                 [int x = _XPG5],
 251                                 [cf_define_xpg5=yes])
 252                          CPPFLAGS="$cf_save_cppflags"])
 253                 AC_MSG_RESULT($cf_define_xpg5)
 254
 255                 if test "$cf_define_xpg5" = yes
 256                 then
 257                         CPPFLAGS="$CPPFLAGS -D_XPG5"
 258                 fi
 259         fi
 260
 261         AC_CACHE_CHECK(for wide-character functions,cf_cv_widechar_funcs,[
 262         AC_TRY_LINK([
 263 #include <${cf_cv_ncurses_header:-curses.h}>],
 264         [
 265                 static wchar_t src_wchar[2];
 266                 static cchar_t dst_cchar;
 267                 setcchar(&dst_cchar, src_wchar, A_NORMAL, 0, (void *) 0);
 268                 ],
 269                 [cf_cv_widechar_funcs=yes],
 270                 [cf_cv_widechar_funcs=no])
 271         ])
 272         if test "$cf_cv_widechar_funcs" != no ; then
 273                 AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to enable wide-character support in (n)curses])
 274         else
 275                 AC_DEFINE(USE_WIDEC_SUPPORT,0)
 276         fi
 277 else
 278         AC_DEFINE(USE_WIDEC_SUPPORT,0)
 279 fi
 280
 281 CF_SYS_TIME_SELECT
 282 CF_FUNC_CURSES_VERSION
 283
 284 CF_CURSES_ACS_MAP
 285 if test "$cf_enable_widec" = yes; then
 286         CF_CURSES_WACS_MAP
 287         CF_CURSES_WACS_SYMBOLS
 288 fi
 289
 290 CF_CURSES_CHECK_TYPE(attr_t,long)
 291
 292 if test "$cf_enable_widec" = yes; then
 293         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T, NCURSES_OK_MBSTATE_T)
 294         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 295         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 296
 297         if test "$NCURSES_OK_MBSTATE_T" = 0 ; then
 298                 CF_CURSES_CHECK_TYPE(mbstate_t,long)
 299         fi
 300
 301         if test "$NCURSES_OK_WCHAR_T" = 0 ; then
 302                 CF_CURSES_CHECK_TYPE(wchar_t,long)
 303         fi
 304
 305         if test "$NCURSES_OK_WINT_T" = 0 ; then
 306                 CF_CURSES_CHECK_TYPE(wint_t,long)
 307         fi
 308 fi
 309
 310 CF_CURSES_CHECK_DATA(boolnames)
 311 CF_CURSES_CHECK_DATA(boolfnames)
 312
 313 dnl ---------------------------------------------------------------------------
 314 CF_HELP_MESSAGE(Testing/development Options:)
 315 CF_ENABLE_WARNINGS
 316 CF_DISABLE_LEAKS
 317 CF_DISABLE_RPATH_HACK
 318
 319 TEST_ARGS="$LIBS"
 320 LIBS=
 321
 322 dnl ---------------------------------------------------------------------------
 323
 324 AC_OUTPUT(Makefile,[
 325 CF_PRG_RULES([$srcdir/mk-test.awk INSTALL=yes ECHO_LINK="$ECHO_LD"], .)
 326         cat >>Makefile <<TEST_EOF
 327
 328 # These rules are generated so we do not rely on suffix rules, which do not
 329 # work consistently for different make-programs (the '\$(MODEL)/' confuses
 330 # some, and the '\$x' confuses others).
 331 TEST_EOF
 332
 333 LIST=`sed -e 's/[[      ]].*//' -e '/^[[#@]]/d' $srcdir/modules`
 334 for N in $LIST
 335 do
 336         cat >>Makefile <<TEST_EOF
 337
 338 \$(MODEL)/$N.o : \$(srcdir)/$N.c \\
 339         \$(srcdir)/test.priv.h \\
 340         ncurses_cfg.h
 341         $SHOW_CC
 342         $ECHO_CC\$(CC) -c \$(CFLAGS_DEFAULT) \$(srcdir)/$N.c
 343 TEST_EOF
 344 done
 345
 346 if test -f ../config.guess && test -f ../config.sub
 347 then
 348         cat >>Makefile <<TEST_EOF
 349
 350 # if we used CF_INHERIT for getting these files, we can remove them
 351 distclean::
 352         rm -f config.guess config.sub
 353 TEST_EOF
 354 fi
 355 ],[
 356 AWK="$AWK"
 357 ECHO_CC="$ECHO_CC"
 358 ECHO_LD="$ECHO_LD"
 359 SHOW_CC="$SHOW_LD"
 360 ],cat)