test/configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2016,2017 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1996-on
  30 dnl
  31 dnl $Id: configure.in,v 1.133 2017/08/07 23:30:23 tom Exp $
  32 dnl This is a simple configuration-script for the ncurses test programs that
  33 dnl allows the test-directory to be separately configured against a reference
  34 dnl system (i.e., sysvr4 curses)
  35 dnl
  36 dnl If you're configuring ncurses, you shouldn't need to use this script.
  37 dnl It's only for testing purposes.
  38 dnl
  39 dnl For additional information, see
  40 dnl             http://invisible-island.net/autoconf/
  41 dnl             http://invisible-island.net/ncurses/ncurses-examples.html
  42 dnl ---------------------------------------------------------------------------
  43 AC_PREREQ(2.52.20170501)
  44 AC_INIT(ncurses.c)
  45 AC_CONFIG_HEADER(ncurses_cfg.h:ncurses_tst.hin)
  46
  47 CF_INHERIT_SCRIPT(config.guess)
  48 CF_INHERIT_SCRIPT(config.sub)
  49 CF_CHECK_CACHE
  50
  51 AC_ARG_PROGRAM
  52
  53 AC_PROG_MAKE_SET
  54 CF_PROG_CC
  55 AC_PROG_CPP
  56 AC_PROG_AWK
  57 CF_PROG_INSTALL
  58 CF_PROG_LINT
  59 CF_MAKE_TAGS
  60
  61 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
  62 AC_SUBST(MATH_LIB)
  63
  64 dnl Things that we don't need (or must override) if we're not building ncurses
  65 CF_TOP_BUILDDIR
  66 CC_G_OPT="-g"                                   AC_SUBST(CC_G_OPT)
  67 CC_SHARED_OPTS=unknown                  AC_SUBST(CC_SHARED_OPTS)
  68 CPPFLAGS="$CPPFLAGS"                    AC_SUBST(CPPFLAGS)
  69 DFT_DEP_SUFFIX=""                               AC_SUBST(DFT_DEP_SUFFIX)
  70 DFT_OBJ_SUBDIR=`pwd|sed -e's:.*/::'`    AC_SUBST(DFT_OBJ_SUBDIR)
  71 DFT_UPR_MODEL="NORMAL"                  AC_SUBST(DFT_UPR_MODEL)
  72 LD="ld"                                                 AC_SUBST(LD)
  73 LDFLAGS_SHARED=""                               AC_SUBST(LDFLAGS_SHARED)
  74 LDFLAGS_STATIC=""                               AC_SUBST(LDFLAGS_STATIC)
  75 LD_MODEL=""                                             AC_SUBST(LD_MODEL)
  76 LD_SHARED_OPTS=""                               AC_SUBST(LD_SHARED_OPTS)
  77 LIBTOOL=""                                              AC_SUBST(LIBTOOL)
  78 LIBTOOL_OPTS=""                                 AC_SUBST(LIBTOOL_OPTS)
  79 LIB_CLEAN=""                                    AC_SUBST(LIB_CLEAN)
  80 LIB_COMPILE=""                                  AC_SUBST(LIB_COMPILE)
  81 LIB_LINK='${CC}'                                AC_SUBST(LIB_LINK)
  82 LINK_TESTS=""                                   AC_SUBST(LINK_TESTS)
  83 LOCAL_LDFLAGS=""                                AC_SUBST(LOCAL_LDFLAGS)
  84 PACKAGE="ncurses-examples"              AC_SUBST(PACKAGE)
  85 PTHREAD="-lm"                                   AC_SUBST(PTHREAD)
  86 TEST_ARGS=""                                    AC_SUBST(TEST_ARGS)
  87 TEST_DEPS=""                                    AC_SUBST(TEST_DEPS)
  88 TEST_LIBS=""                                    AC_SUBST(TEST_LIBS)
  89 TINFO_LDFLAGS=''                                AC_SUBST(TINFO_LDFLAGS)
  90 TINFO_LIBS='$(LIBS_CURSES)'             AC_SUBST(TINFO_LIBS)
  91 cf_cv_abi_version=""                    AC_SUBST(cf_cv_abi_version)
  92 cf_cv_rel_version=""                    AC_SUBST(cf_cv_rel_version)
  93 includesubdir=""                                AC_SUBST(includesubdir)
  94
  95 cf_cv_screen=curses
  96 cf_cv_libtype=
  97
  98 AC_EXEEXT
  99 AC_OBJEXT
 100
 101 CF_GCC_ATTRIBUTES
 102 CF_ENABLE_STRING_HACKS
 103 CF_XOPEN_SOURCE
 104 CF_SIG_ATOMIC_T
 105
 106 # Work around breakage on OS X
 107 CF_SIGWINCH
 108
 109 # Checks for CODESET support.
 110 AM_LANGINFO_CODESET
 111
 112 dnl ---------------------------------------------------------------------------
 113 CF_HELP_MESSAGE(General Options:)
 114 CF_PKG_CONFIG
 115 CF_DISABLE_ECHO
 116
 117 dnl ---------------------------------------------------------------------------
 118 CF_HELP_MESSAGE(Curses Version-dependent Options:)
 119 CF_NCURSES_WRAP_PREFIX
 120
 121 AC_MSG_CHECKING(if you want to check for wide-character functions)
 122 CF_ARG_DISABLE(widec,
 123         [  --disable-widec         disable checks for wide-character functions],
 124         cf_enable_widec=no,
 125         cf_enable_widec=yes,
 126         yes)
 127 AC_MSG_RESULT($cf_enable_widec)
 128
 129 dnl ---------------------------------------------------------------------------
 130 CF_HELP_MESSAGE(Curses Version-dependent Options:)
 131 CF_WITH_NCURSES_ETC
 132
 133 case $cf_cv_screen in
 134 (ncurses*)
 135         cf_cv_libtype=`echo "$cf_cv_screen" | sed -e 's/^ncurses//'`
 136         ;;
 137 (curses|curses_*)
 138         CF_NETBSD_FORM_H
 139         CF_NETBSD_MENU_H
 140         ;;
 141 esac
 142
 143 dnl If we've not specified a library, assume we're using sysvr4 libraries
 144 dnl installed conventionally (e.g., SunOS 5.x - solaris).
 145
 146 dnl Autoconf builds up the $LIBS in reverse order
 147
 148 case $cf_cv_screen in
 149 (pdcurses)
 150         ;;
 151 (*)
 152         # look for curses-related libraries
 153         CF_CHECK_CURSES_LIB(panel,$cf_cv_libtype,new_panel)
 154         CF_CHECK_CURSES_LIB(menu,$cf_cv_libtype,menu_driver)
 155         CF_CHECK_CURSES_LIB(form,$cf_cv_libtype,form_driver)
 156
 157         # look for curses-related headers
 158         AC_CHECK_HEADERS( \
 159                 nc_alloc.h \
 160                 nomacros.h \
 161                 form.h \
 162                 menu.h \
 163                 panel.h \
 164                 term_entry.h \
 165                 )
 166         ;;
 167 esac
 168
 169 AC_STDC_HEADERS
 170 AC_HEADER_TIME
 171 AC_CHECK_HEADERS( \
 172 getopt.h \
 173 locale.h \
 174 math.h \
 175 stdarg.h \
 176 sys/ioctl.h \
 177 sys/select.h \
 178 sys/time.h \
 179 termios.h \
 180 unistd.h \
 181 )
 182
 183 CF_GETOPT_HEADER
 184
 185 AC_CHECK_FUNCS( \
 186 getopt \
 187 gettimeofday \
 188 tdestroy \
 189 tsearch \
 190 )
 191
 192 if test "x$ac_cv_func_getopt" = xno; then
 193         AC_MSG_ERROR(getopt is required for building programs)
 194 fi
 195
 196 if test "$cf_enable_widec" = yes; then
 197 AC_CHECK_FUNCS( \
 198 mblen \
 199 mbrlen \
 200 mbrtowc \
 201 mbsrtowcs \
 202 mbstowcs \
 203 mbtowc \
 204 wcsrtombs \
 205 wcstombs \
 206 )
 207 fi
 208
 209 CF_CURSES_FUNCS( \
 210 alloc_pair \
 211 assume_default_colors \
 212 chgat \
 213 color_set \
 214 filter \
 215 getbegx \
 216 getcurx \
 217 getmaxx \
 218 getnstr \
 219 getparx \
 220 getwin \
 221 init_extended_color \
 222 mvvline \
 223 mvwvline \
 224 napms \
 225 putwin \
 226 resize_term \
 227 resizeterm \
 228 restartterm \
 229 ripoffline \
 230 scr_dump \
 231 setupterm \
 232 slk_color \
 233 slk_init \
 234 termattrs \
 235 tgetent \
 236 tigetnum \
 237 tigetstr \
 238 tputs_sp \
 239 typeahead \
 240 use_default_colors \
 241 use_env \
 242 use_extended_names \
 243 use_screen \
 244 use_window \
 245 vid_puts \
 246 vidputs \
 247 vsscanf \
 248 vw_printw \
 249 wchgat \
 250 winsstr \
 251 wresize \
 252 wsyncdown \
 253 _tracef \
 254 )
 255
 256 CF_TPUTS_PROTO
 257 CF_NCURSES_EXT_FUNCS
 258
 259 if test "$cf_enable_widec" = yes
 260 then
 261         # workaround for systems with ncurses before 20111029, due to change of
 262         # feature test macro from _XPG5 to _XOPEN_SOURCE
 263         if test -n "$cf_cv_ncurses_version" && test "x$cf_cv_ncurses_version" != xno
 264         then
 265                 cf_define_xpg5=no
 266                 AC_MSG_CHECKING(if _XPG5 should be defined to enable wide-characters)
 267
 268                 AC_TRY_COMPILE([
 269 #include <${cf_cv_ncurses_header:-curses.h}>],
 270                         [int x = _XPG5],,
 271                         [cf_save_cppflags="$CPPFLAGS"
 272                          CPPFLAGS="$CPPFLAGS -D_XPG5"
 273                          AC_TRY_COMPILE([
 274 #include <${cf_cv_ncurses_header:-curses.h}>],
 275                                 [int x = _XPG5],
 276                                 [cf_define_xpg5=yes])
 277                          CPPFLAGS="$cf_save_cppflags"])
 278                 AC_MSG_RESULT($cf_define_xpg5)
 279
 280                 if test "$cf_define_xpg5" = yes
 281                 then
 282                         CPPFLAGS="$CPPFLAGS -D_XPG5"
 283                 fi
 284         fi
 285
 286         AC_CACHE_CHECK(for wide-character functions,cf_cv_widechar_funcs,[
 287         AC_TRY_LINK([
 288 #include <${cf_cv_ncurses_header:-curses.h}>],
 289         [
 290                 static wchar_t src_wchar[2];
 291                 static cchar_t dst_cchar;
 292                 setcchar(&dst_cchar, src_wchar, A_NORMAL, 0, (void *) 0);
 293                 ],
 294                 [cf_cv_widechar_funcs=yes],
 295                 [cf_cv_widechar_funcs=no])
 296         ])
 297         if test "$cf_cv_widechar_funcs" != no ; then
 298                 AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to enable wide-character support in (n)curses])
 299         else
 300                 AC_DEFINE(USE_WIDEC_SUPPORT,0)
 301         fi
 302 else
 303         AC_DEFINE(USE_WIDEC_SUPPORT,0)
 304 fi
 305
 306 AC_CACHE_CHECK(if $cf_cv_screen library uses pthreads,cf_cv_use_pthreads,[
 307 AC_TRY_LINK([
 308 #include <${cf_cv_ncurses_header:-curses.h}>
 309 extern void _nc_init_pthreads(void);
 310 ],
 311 [
 312         initscr();
 313         _nc_init_pthreads();
 314         ],
 315         [cf_cv_use_pthreads=yes],
 316         [cf_cv_use_pthreads=no])
 317 ])
 318 test $cf_cv_use_pthreads = yes && AC_DEFINE(USE_PTHREADS)
 319
 320 CF_SYS_TIME_SELECT
 321
 322 # special check for test/ditto.c
 323 CF_FUNC_OPENPTY
 324 if test "$cf_cv_func_openpty" != no ; then
 325         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
 326         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
 327         if test "x$cf_cv_lib_util" = xyes ; then
 328                 CF_ADD_LIB(util,TEST_LIBS)
 329         fi
 330 fi
 331
 332 CF_FUNC_CURSES_VERSION
 333
 334 CF_CURSES_ACS_MAP
 335 if test "$cf_enable_widec" = yes; then
 336         CF_CURSES_WACS_MAP
 337         CF_CURSES_WACS_SYMBOLS
 338 fi
 339
 340 CF_CURSES_CHECK_TYPE(attr_t,long)
 341
 342 if test "$cf_enable_widec" = yes; then
 343         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T, NCURSES_OK_MBSTATE_T)
 344         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 345         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 346
 347         if test "$NCURSES_OK_MBSTATE_T" = 0 ; then
 348                 CF_CURSES_CHECK_TYPE(mbstate_t,long)
 349         fi
 350
 351         if test "$NCURSES_OK_WCHAR_T" = 0 ; then
 352                 CF_CURSES_CHECK_TYPE(wchar_t,long)
 353         fi
 354
 355         if test "$NCURSES_OK_WINT_T" = 0 ; then
 356                 CF_CURSES_CHECK_TYPE(wint_t,long)
 357         fi
 358 fi
 359
 360 CF_CURSES_CHECK_DATA(ospeed)
 361 CF_CURSES_CHECK_DATA(boolnames)
 362 CF_CURSES_CHECK_DATA(boolfnames)
 363 CF_CURSES_CHECK_DATA(ttytype)
 364
 365 dnl ---------------------------------------------------------------------------
 366 CF_HELP_MESSAGE(Testing/development Options:)
 367 CF_ENABLE_WARNINGS
 368 CF_DISABLE_LEAKS
 369 CF_DISABLE_RPATH_HACK
 370
 371 TEST_ARGS="$LIBS"
 372 LIBS=
 373
 374 dnl ---------------------------------------------------------------------------
 375
 376 AC_OUTPUT(Makefile,[
 377 CF_PRG_RULES([$srcdir/mk-test.awk INSTALL=yes ECHO_LINK="$ECHO_LD"], .)
 378         cat >>Makefile <<TEST_EOF
 379
 380 # These rules are generated so we do not rely on suffix rules, which do not
 381 # work consistently for different make-programs (the '\$(MODEL)/' confuses
 382 # some, and the '\$x' confuses others).
 383 TEST_EOF
 384
 385 LIST=`sed -e 's/[[      ]].*//' -e '/^[[#@]]/d' $srcdir/modules`
 386 for N in $LIST
 387 do
 388         cat >>Makefile <<TEST_EOF
 389
 390 \$(MODEL)/$N.o : \$(srcdir)/$N.c \\
 391         \$(srcdir)/test.priv.h \\
 392         ncurses_cfg.h
 393         $SHOW_CC
 394         $ECHO_CC\$(CC) -c \$(CFLAGS_DEFAULT) \$(srcdir)/$N.c
 395 TEST_EOF
 396 done
 397
 398 if test -f ../config.guess && test -f ../config.sub
 399 then
 400         cat >>Makefile <<TEST_EOF
 401
 402 # if we used CF_INHERIT for getting these files, we can remove them
 403 distclean::
 404         rm -f config.guess config.sub
 405 TEST_EOF
 406 fi
 407 ],[
 408 AWK="$AWK"
 409 ECHO_CC="$ECHO_CC"
 410 ECHO_LD="$ECHO_LD"
 411 SHOW_CC="$SHOW_LD"
 412 ],cat)