test/configure.in

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2020,2021 Thomas E. Dickey                                *
   3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey 1996-on
  31 dnl
  32 dnl $Id: configure.in,v 1.163 2021/07/03 20:21:07 tom Exp $
  33 dnl This is a simple configuration-script for the ncurses test programs that
  34 dnl allows the test-directory to be separately configured against a reference
  35 dnl system (i.e., sysvr4 curses)
  36 dnl
  37 dnl If you're configuring ncurses, you shouldn't need to use this script.
  38 dnl It's only for testing purposes.
  39 dnl
  40 dnl For additional information, see
  41 dnl             https://invisible-island.net/autoconf/
  42 dnl             https://invisible-island.net/autoconf/my-autoconf.html
  43 dnl             https://invisible-island.net/ncurses/ncurses-examples.html
  44 dnl ---------------------------------------------------------------------------
  45 AC_PREREQ(2.52.20210509)
  46 AC_INIT(ncurses.c)
  47 AC_CONFIG_HEADER(ncurses_cfg.h:ncurses_tst.hin)
  48
  49 CF_INHERIT_SCRIPT(config.guess)
  50 CF_INHERIT_SCRIPT(config.sub)
  51 CF_CHECK_CACHE
  52
  53 AC_ARG_PROGRAM
  54
  55 CF_HELP_MESSAGE(General Options:)
  56
  57 AC_PROG_MAKE_SET
  58 CF_PROG_CC
  59 AC_C_INLINE
  60 AC_PROG_CPP
  61 AC_PROG_AWK
  62 CF_PROG_INSTALL
  63 CF_INSTALL_OPTS
  64 CF_PROG_LINT
  65 CF_MAKE_PHONY
  66 CF_MAKE_TAGS
  67
  68 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
  69 AC_SUBST(MATH_LIB)
  70
  71 dnl Things that we don't need (or must override) if we're not building ncurses
  72 CF_TOP_BUILDDIR
  73 CC_G_OPT="-g"                                   AC_SUBST(CC_G_OPT)
  74 CC_SHARED_OPTS=unknown                  AC_SUBST(CC_SHARED_OPTS)
  75 CPPFLAGS="$CPPFLAGS"                    AC_SUBST(CPPFLAGS)
  76 DFT_DEP_SUFFIX=""                               AC_SUBST(DFT_DEP_SUFFIX)
  77 DFT_OBJ_SUBDIR=`pwd|sed -e's:.*/::'`    AC_SUBST(DFT_OBJ_SUBDIR)
  78 DFT_UPR_MODEL="NORMAL"                  AC_SUBST(DFT_UPR_MODEL)
  79 LD="ld"                                                 AC_SUBST(LD)
  80 LDFLAGS_SHARED=""                               AC_SUBST(LDFLAGS_SHARED)
  81 LDFLAGS_STATIC=""                               AC_SUBST(LDFLAGS_STATIC)
  82 LD_MODEL=""                                             AC_SUBST(LD_MODEL)
  83 LD_SHARED_OPTS=""                               AC_SUBST(LD_SHARED_OPTS)
  84 LIBTOOL=""                                              AC_SUBST(LIBTOOL)
  85 LIBTOOL_OPTS=""                                 AC_SUBST(LIBTOOL_OPTS)
  86 LIB_CLEAN=""                                    AC_SUBST(LIB_CLEAN)
  87 LIB_COMPILE=""                                  AC_SUBST(LIB_COMPILE)
  88 LIB_LINK='${CC}'                                AC_SUBST(LIB_LINK)
  89 LINK_TESTS=""                                   AC_SUBST(LINK_TESTS)
  90 LOCAL_LDFLAGS=""                                AC_SUBST(LOCAL_LDFLAGS)
  91 PACKAGE="ncurses-examples"              AC_SUBST(PACKAGE)
  92 PTHREAD="-lm"                                   AC_SUBST(PTHREAD)
  93 TEST_ARGS=""                                    AC_SUBST(TEST_ARGS)
  94 TEST_DEPS=""                                    AC_SUBST(TEST_DEPS)
  95 TEST_LIBS=""                                    AC_SUBST(TEST_LIBS)
  96 TINFO_LDFLAGS=''                                AC_SUBST(TINFO_LDFLAGS)
  97 TINFO_LIBS='$(LIBS_CURSES)'             AC_SUBST(TINFO_LIBS)
  98 cf_cv_abi_version=""                    AC_SUBST(cf_cv_abi_version)
  99 cf_cv_rel_version=""                    AC_SUBST(cf_cv_rel_version)
 100 includesubdir=""                                AC_SUBST(includesubdir)
 101
 102 cf_cv_screen=curses
 103 cf_cv_libtype=
 104
 105 AC_EXEEXT
 106 AC_OBJEXT
 107
 108 CF_GCC_ATTRIBUTES
 109 CF_ENABLE_STRING_HACKS
 110 CF_XOPEN_SOURCE(600)
 111 CF_SIG_ATOMIC_T
 112
 113 # Work around breakage on OS X
 114 CF_SIGWINCH
 115
 116 # Checks for CODESET support.
 117 AM_LANGINFO_CODESET
 118
 119 dnl ---------------------------------------------------------------------------
 120 CF_PKG_CONFIG
 121 CF_DISABLE_ECHO
 122
 123 dnl ---------------------------------------------------------------------------
 124 CF_HELP_MESSAGE(Curses Version-dependent Options:)
 125 CF_NCURSES_WRAP_PREFIX
 126
 127 AC_MSG_CHECKING(if you want to check for wide-character functions)
 128 CF_ARG_DISABLE(widec,
 129         [  --disable-widec         disable checks for wide-character functions],
 130         cf_enable_widec=no,
 131         cf_enable_widec=yes,
 132         yes)
 133 AC_MSG_RESULT($cf_enable_widec)
 134
 135 dnl ---------------------------------------------------------------------------
 136 CF_HELP_MESSAGE(Curses Version-dependent Options:)
 137 CF_WITH_NCURSES_ETC
 138
 139 case $cf_cv_screen in
 140 (ncurses*)
 141         cf_cv_libtype=`echo "$cf_cv_screen" | sed -e 's/^ncurses//'`
 142         ;;
 143 esac
 144
 145 CF_WITH_X11_RGB
 146
 147 dnl If we've not specified a library, assume we're using sysvr4 libraries
 148 dnl installed conventionally (e.g., SunOS 5.x - solaris).
 149
 150 dnl Autoconf builds up the $LIBS in reverse order
 151
 152 cf_curses_headers=
 153
 154 case $cf_cv_screen in
 155 (pdcurses)
 156         cf_default_panel=no
 157         cf_default_form=no
 158         cf_default_menu=no
 159         cf_default_tinfo=no
 160         ;;
 161 (xcurses|bsdcurses)
 162         cf_default_panel=no
 163         cf_default_form=no
 164         cf_default_menu=no
 165         cf_default_tinfo=yes
 166         ;;
 167 (*)
 168         cf_default_panel=yes
 169         cf_default_form=yes
 170         cf_default_menu=yes
 171         cf_default_tinfo=yes
 172         case $cf_cv_screen in
 173         (ncurses*)
 174                 cf_curses_headers="nc_alloc.h nomacros.h term_entry.h"
 175                 ;;
 176         esac
 177         ;;
 178 esac
 179
 180 CF_WITH_LIB_BASENAME(FORM_NAME,form)
 181 CF_WITH_LIB_BASENAME(MENU_NAME,menu)
 182 CF_WITH_LIB_BASENAME(PANEL_NAME,panel)
 183
 184 AC_MSG_CHECKING(if you want to check for panel functions)
 185 CF_ARG_DISABLE(panel,
 186         [  --disable-panel         disable checks for panel functions],
 187         cf_enable_panel=no,
 188         cf_enable_panel=$cf_default_panel,
 189         yes)
 190 AC_MSG_RESULT($cf_enable_panel)
 191 if test $cf_enable_panel = yes
 192 then
 193         CF_CHECK_CURSES_LIB($PANEL_NAME,$cf_cv_libtype,new_panel,0)
 194         cf_curses_headers="$cf_curses_headers panel.h"
 195 fi
 196
 197 AC_MSG_CHECKING(if you want to check for menu functions)
 198 CF_ARG_DISABLE(menu,
 199         [  --disable-menu          disable checks for menu functions],
 200         cf_enable_menu=no,
 201         cf_enable_menu=$cf_default_menu,
 202         yes)
 203 AC_MSG_RESULT($cf_enable_menu)
 204 if test $cf_enable_menu = yes
 205 then
 206         case $cf_cv_screen in
 207         (ncurses*)
 208                 ;;
 209         (curses*)
 210                 CF_NETBSD_MENU_H
 211                 ;;
 212         esac
 213         CF_CHECK_CURSES_LIB($MENU_NAME,$cf_cv_libtype,menu_driver,[0,0])
 214         cf_curses_headers="$cf_curses_headers menu.h"
 215 fi
 216
 217 AC_MSG_CHECKING(if you want to check for form functions)
 218 CF_ARG_DISABLE(form,
 219         [  --disable-form          disable checks for form functions],
 220         cf_enable_form=no,
 221         cf_enable_form=$cf_default_form,
 222         yes)
 223 AC_MSG_RESULT($cf_enable_form)
 224 if test $cf_enable_form = yes
 225 then
 226         case $cf_cv_screen in
 227         (ncurses*)
 228                 ;;
 229         (curses*)
 230                 CF_NETBSD_FORM_H
 231                 ;;
 232         esac
 233         CF_CHECK_CURSES_LIB($FORM_NAME,$cf_cv_libtype,form_driver,[0,0])
 234         cf_curses_headers="$cf_curses_headers form.h"
 235 fi
 236
 237 # look for curses-related headers
 238 AC_CHECK_HEADERS( $cf_curses_headers )
 239
 240 AC_STDC_HEADERS
 241 AC_HEADER_TIME
 242 AC_CHECK_HEADERS( \
 243 getopt.h \
 244 locale.h \
 245 math.h \
 246 stdarg.h \
 247 stdint.h \
 248 sys/ioctl.h \
 249 sys/select.h \
 250 sys/time.h \
 251 termios.h \
 252 unistd.h \
 253 )
 254
 255 CF_GETOPT_HEADER
 256
 257 AC_CHECK_FUNCS( \
 258 getopt \
 259 gettimeofday \
 260 snprintf \
 261 strdup \
 262 strstr \
 263 tsearch \
 264 )
 265
 266 # use a compile-check to work with ncurses*-config and subdirectory includes
 267 AC_CACHE_CHECK(if we can use termcap.h,cf_cv_have_termcap_h,[
 268         AC_TRY_COMPILE([
 269 #include <curses.h>
 270 #ifdef NCURSES_VERSION
 271 #undef NCURSES_VERSION
 272 #endif
 273 #include <termcap.h>
 274 #ifndef NCURSES_VERSION
 275 #error wrong header
 276 #endif
 277 ],
 278         [return 0;],
 279         [cf_cv_have_termcap_h=yes],
 280         [cf_cv_have_termcap_h=no])])
 281 if test "x$cf_cv_have_termcap_h" = xyes
 282 then
 283         AC_DEFINE(HAVE_TERMCAP_H,1,[Define to 1 if we can use termcap.h])
 284 else
 285 AC_CACHE_CHECK(if we can use ncurses/termcap.h,cf_cv_have_ncurses_termcap_h,[
 286         AC_TRY_COMPILE([
 287 #include <ncurses/curses.h>
 288 #ifdef NCURSES_VERSION
 289 #undef NCURSES_VERSION
 290 #endif
 291 #include <ncurses/termcap.h>
 292 #ifndef NCURSES_VERSION
 293 #error wrong header
 294 #endif
 295 ],
 296         [return 0;],
 297         [cf_cv_have_ncurses_termcap_h=yes],
 298         [cf_cv_have_ncurses_termcap_h=no])])
 299 test "x$cf_cv_have_ncurses_termcap_h" = xyes && AC_DEFINE(HAVE_NCURSES_TERMCAP_H,1,[Define to 1 if we can use ncurses/termcap.h])
 300 fi
 301
 302 if test "x$ac_cv_func_getopt" = xno; then
 303         AC_MSG_ERROR(getopt is required for building programs)
 304 fi
 305
 306 if test "$cf_enable_widec" = yes; then
 307 AC_CHECK_FUNCS( \
 308 mblen \
 309 mbrlen \
 310 mbrtowc \
 311 mbsrtowcs \
 312 mbstowcs \
 313 mbtowc \
 314 wcsrtombs \
 315 wcstombs \
 316 )
 317 fi
 318
 319 CF_CURSES_FUNCS( \
 320 alloc_pair \
 321 assume_default_colors \
 322 chgat \
 323 color_content \
 324 color_set \
 325 copywin \
 326 delscreen \
 327 dupwin \
 328 exit_curses \
 329 exit_terminfo \
 330 filter \
 331 getbegx \
 332 getcurx \
 333 getmaxx \
 334 getnstr \
 335 getparx \
 336 getwin \
 337 halfdelay \
 338 init_extended_color \
 339 mvderwin \
 340 mvvline \
 341 mvwin \
 342 mvwvline \
 343 napms \
 344 newpad \
 345 putwin \
 346 reset_color_pairs \
 347 resize_term \
 348 resizeterm \
 349 restartterm \
 350 ripoffline \
 351 scr_dump \
 352 setupterm \
 353 slk_color \
 354 slk_init \
 355 termattrs \
 356 termname \
 357 tgetent \
 358 tigetnum \
 359 tigetstr \
 360 tputs_sp \
 361 typeahead \
 362 use_default_colors \
 363 use_env \
 364 use_extended_names \
 365 use_screen \
 366 use_window \
 367 vid_puts \
 368 vidputs \
 369 vsscanf \
 370 vw_printw \
 371 wchgat \
 372 winsdelln \
 373 winsstr \
 374 wresize \
 375 wsyncdown \
 376 _tracef \
 377 )
 378
 379 CF_TPUTS_PROTO
 380 CF_NCURSES_EXT_FUNCS
 381
 382 if test "$cf_enable_widec" = yes
 383 then
 384         # workaround for systems with ncurses before 20111029, due to change of
 385         # feature test macro from _XPG5 to _XOPEN_SOURCE
 386         if test -n "$cf_cv_ncurses_version" && test "x$cf_cv_ncurses_version" != xno
 387         then
 388                 cf_define_xpg5=no
 389                 AC_MSG_CHECKING(if _XPG5 should be defined to enable wide-characters)
 390
 391                 AC_TRY_COMPILE([
 392 #include <${cf_cv_ncurses_header:-curses.h}>],
 393                         [int x = _XPG5],,
 394                         [cf_save_cppflags="$CPPFLAGS"
 395                          CPPFLAGS="$CPPFLAGS -D_XPG5"
 396                          AC_TRY_COMPILE([
 397 #include <${cf_cv_ncurses_header:-curses.h}>],
 398                                 [int x = _XPG5],
 399                                 [cf_define_xpg5=yes])
 400                          CPPFLAGS="$cf_save_cppflags"])
 401                 AC_MSG_RESULT($cf_define_xpg5)
 402
 403                 if test "$cf_define_xpg5" = yes
 404                 then
 405                         CPPFLAGS="$CPPFLAGS -D_XPG5"
 406                 fi
 407         fi
 408
 409         AC_CACHE_CHECK(for wide-character functions,cf_cv_widechar_funcs,[
 410         AC_TRY_LINK([
 411 #include <${cf_cv_ncurses_header:-curses.h}>],
 412         [
 413                 static wchar_t src_wchar[2];
 414                 static cchar_t dst_cchar;
 415                 setcchar(&dst_cchar, src_wchar, A_NORMAL, 0, (void *) 0);
 416                 ],
 417                 [cf_cv_widechar_funcs=yes],
 418                 [cf_cv_widechar_funcs=no])
 419         ])
 420         if test "$cf_cv_widechar_funcs" != no ; then
 421                 AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to enable wide-character support in (n)curses])
 422         else
 423                 AC_DEFINE(USE_WIDEC_SUPPORT,0)
 424         fi
 425 else
 426         AC_DEFINE(USE_WIDEC_SUPPORT,0)
 427 fi
 428
 429 AC_CACHE_CHECK(if $cf_cv_screen library uses pthreads,cf_cv_use_pthreads,[
 430 AC_TRY_LINK([
 431 #include <${cf_cv_ncurses_header:-curses.h}>
 432 extern void _nc_init_pthreads(void);
 433 ],
 434 [
 435         initscr();
 436         _nc_init_pthreads();
 437         ],
 438         [cf_cv_use_pthreads=yes],
 439         [cf_cv_use_pthreads=no])
 440 ])
 441 test $cf_cv_use_pthreads = yes && AC_DEFINE(USE_PTHREADS,1,[Define to 1 if $cf_cv_screen library uses pthreads])
 442
 443 CF_SYS_TIME_SELECT
 444
 445 # special check for test/ditto.c
 446 CF_FUNC_OPENPTY
 447 if test "$cf_cv_func_openpty" != no ; then
 448         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
 449         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
 450         if test "x$cf_cv_lib_util" = xyes ; then
 451                 CF_ADD_LIB(util,TEST_LIBS)
 452         fi
 453 fi
 454
 455 CF_FUNC_CURSES_VERSION
 456
 457 CF_CURSES_ACS_MAP
 458 if test "$cf_enable_widec" = yes; then
 459         CF_CURSES_WACS_MAP
 460         CF_CURSES_WACS_SYMBOLS
 461 fi
 462
 463 CF_CURSES_CHECK_TYPE(attr_t,long)
 464
 465 if test "$cf_enable_widec" = yes; then
 466         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T, NCURSES_OK_MBSTATE_T)
 467         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 468         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 469
 470         if test "$NCURSES_OK_MBSTATE_T" = 0 ; then
 471                 CF_CURSES_CHECK_TYPE(mbstate_t,long)
 472         fi
 473
 474         if test "$NCURSES_OK_WCHAR_T" = 0 ; then
 475                 CF_CURSES_CHECK_TYPE(wchar_t,long)
 476         fi
 477
 478         if test "$NCURSES_OK_WINT_T" = 0 ; then
 479                 CF_CURSES_CHECK_TYPE(wint_t,long)
 480         fi
 481 fi
 482
 483 CF_CURSES_CHECK_DATA(\
 484 TABSIZE \
 485 curscr \
 486 ospeed \
 487 boolnames \
 488 boolfnames \
 489 ttytype)
 490
 491 dnl ---------------------------------------------------------------------------
 492 CF_HELP_MESSAGE(Testing/development Options:)
 493 CF_WITH_SCREEN_PDCURSES
 494 CF_ENABLE_WARNINGS(Wno-unknown-pragmas)
 495 CF_DISABLE_LEAKS
 496 CF_DISABLE_RPATH_HACK
 497
 498 TEST_ARGS="$LIBS"
 499 LIBS=
 500
 501 dnl ---------------------------------------------------------------------------
 502
 503 AC_OUTPUT(Makefile,[
 504 CF_PRG_RULES([$srcdir/mk-test.awk INSTALL=yes ECHO_LINK="$ECHO_LD"], .)
 505         cat >>Makefile <<TEST_EOF
 506
 507 # These rules are generated so we do not rely on suffix rules, which do not
 508 # work consistently for different make-programs (the '\$(MODEL)/' confuses
 509 # some, and the '\$x' confuses others).
 510 TEST_EOF
 511
 512 LIST=`sed -e 's/[[      ]].*//' -e '/^[[#@]]/d' $srcdir/modules`
 513 for N in $LIST
 514 do
 515         cat >>Makefile <<TEST_EOF
 516
 517 \$(MODEL)/$N.o : \$(srcdir)/$N.c \\
 518         \$(srcdir)/test.priv.h \\
 519         ncurses_cfg.h
 520         $SHOW_CC
 521         $ECHO_CC\$(CC) -c \$(CFLAGS_DEFAULT) -DMODULE_NAME="$N" \$(srcdir)/$N.c
 522 TEST_EOF
 523 done
 524
 525 if test -f ../config.guess && test -f ../config.sub
 526 then
 527         cat >>Makefile <<TEST_EOF
 528
 529 # if we used CF_INHERIT for getting these files, we can remove them
 530 distclean::
 531         rm -f config.guess config.sub
 532 TEST_EOF
 533 fi
 534 ],[
 535 AWK="$AWK"
 536 ECHO_CC="$ECHO_CC"
 537 ECHO_LD="$ECHO_LD"
 538 SHOW_CC="$SHOW_LD"
 539 ],cat)