test/configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2016,2017 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1996-on
  30 dnl
  31 dnl $Id: configure.in,v 1.129 2017/03/06 09:48:09 tom Exp $
  32 dnl This is a simple configuration-script for the ncurses test programs that
  33 dnl allows the test-directory to be separately configured against a reference
  34 dnl system (i.e., sysvr4 curses)
  35 dnl
  36 dnl If you're configuring ncurses, you shouldn't need to use this script.
  37 dnl It's only for testing purposes.
  38 dnl
  39 dnl For additional information, see
  40 dnl             http://invisible-island.net/autoconf/
  41 dnl             http://invisible-island.net/ncurses/ncurses-examples.html
  42 dnl ---------------------------------------------------------------------------
  43 AC_PREREQ(2.52.20030208)
  44 AC_INIT(ncurses.c)
  45 AC_CONFIG_HEADER(ncurses_cfg.h:ncurses_tst.hin)
  46
  47 CF_INHERIT_SCRIPT(config.guess)
  48 CF_INHERIT_SCRIPT(config.sub)
  49 CF_CHECK_CACHE
  50
  51 AC_ARG_PROGRAM
  52
  53 AC_PROG_MAKE_SET
  54 CF_PROG_CC
  55 AC_PROG_CPP
  56 AC_PROG_AWK
  57 CF_PROG_INSTALL
  58 CF_PROG_LINT
  59 CF_MAKE_TAGS
  60
  61 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
  62 AC_SUBST(MATH_LIB)
  63
  64 dnl Things that we don't need (or must override) if we're not building ncurses
  65 CF_TOP_BUILDDIR
  66 CC_G_OPT="-g"                                   AC_SUBST(CC_G_OPT)
  67 CC_SHARED_OPTS=unknown                  AC_SUBST(CC_SHARED_OPTS)
  68 CPPFLAGS="$CPPFLAGS"                    AC_SUBST(CPPFLAGS)
  69 DFT_DEP_SUFFIX=""                               AC_SUBST(DFT_DEP_SUFFIX)
  70 DFT_OBJ_SUBDIR=`pwd|sed -e's:.*/::'`    AC_SUBST(DFT_OBJ_SUBDIR)
  71 DFT_UPR_MODEL="NORMAL"                  AC_SUBST(DFT_UPR_MODEL)
  72 LD="ld"                                                 AC_SUBST(LD)
  73 LDFLAGS_SHARED=""                               AC_SUBST(LDFLAGS_SHARED)
  74 LDFLAGS_STATIC=""                               AC_SUBST(LDFLAGS_STATIC)
  75 LD_MODEL=""                                             AC_SUBST(LD_MODEL)
  76 LD_SHARED_OPTS=""                               AC_SUBST(LD_SHARED_OPTS)
  77 LIBTOOL=""                                              AC_SUBST(LIBTOOL)
  78 LIBTOOL_OPTS=""                                 AC_SUBST(LIBTOOL_OPTS)
  79 LIB_CLEAN=""                                    AC_SUBST(LIB_CLEAN)
  80 LIB_COMPILE=""                                  AC_SUBST(LIB_COMPILE)
  81 LIB_LINK='${CC}'                                AC_SUBST(LIB_LINK)
  82 LINK_TESTS=""                                   AC_SUBST(LINK_TESTS)
  83 LOCAL_LDFLAGS=""                                AC_SUBST(LOCAL_LDFLAGS)
  84 PACKAGE="ncurses-examples"              AC_SUBST(PACKAGE)
  85 PTHREAD="-lm"                                   AC_SUBST(PTHREAD)
  86 TEST_ARGS=""                                    AC_SUBST(TEST_ARGS)
  87 TEST_DEPS=""                                    AC_SUBST(TEST_DEPS)
  88 TEST_LIBS=""                                    AC_SUBST(TEST_LIBS)
  89 TINFO_LDFLAGS=''                                AC_SUBST(TINFO_LDFLAGS)
  90 TINFO_LIBS='$(LIBS_CURSES)'             AC_SUBST(TINFO_LIBS)
  91 cf_cv_abi_version=""                    AC_SUBST(cf_cv_abi_version)
  92 cf_cv_rel_version=""                    AC_SUBST(cf_cv_rel_version)
  93 includesubdir=""                                AC_SUBST(includesubdir)
  94
  95 cf_cv_screen=curses
  96 cf_cv_libtype=
  97
  98 AC_EXEEXT
  99 AC_OBJEXT
 100
 101 CF_GCC_ATTRIBUTES
 102 CF_ENABLE_STRING_HACKS
 103 CF_XOPEN_SOURCE
 104 CF_SIG_ATOMIC_T
 105
 106 # Work around breakage on OS X
 107 CF_SIGWINCH
 108
 109 # Checks for CODESET support.
 110 AM_LANGINFO_CODESET
 111
 112 dnl ---------------------------------------------------------------------------
 113 CF_HELP_MESSAGE(General Options:)
 114 CF_PKG_CONFIG
 115 CF_DISABLE_ECHO
 116
 117 dnl ---------------------------------------------------------------------------
 118 CF_HELP_MESSAGE(Curses Version-dependent Options:)
 119 CF_NCURSES_WRAP_PREFIX
 120
 121 AC_MSG_CHECKING(if you want to check for wide-character functions)
 122 CF_ARG_DISABLE(widec,
 123         [  --disable-widec         disable checks for wide-character functions],
 124         cf_enable_widec=no,
 125         cf_enable_widec=yes,
 126         yes)
 127 AC_MSG_RESULT($cf_enable_widec)
 128
 129 dnl ---------------------------------------------------------------------------
 130 CF_HELP_MESSAGE(Curses Version-dependent Options:)
 131 CF_WITH_NCURSES_ETC
 132
 133 case $cf_cv_screen in
 134 (ncurses*)
 135         cf_cv_libtype=`echo "$cf_cv_screen" | sed -e 's/^ncurses//'`
 136         ;;
 137 (curses|curses_*)
 138         CF_NETBSD_FORM_H
 139         CF_NETBSD_MENU_H
 140         ;;
 141 esac
 142
 143 dnl If we've not specified a library, assume we're using sysvr4 libraries
 144 dnl installed conventionally (e.g., SunOS 5.x - solaris).
 145
 146 dnl Autoconf builds up the $LIBS in reverse order
 147
 148 case $cf_cv_screen in
 149 (pdcurses)
 150         ;;
 151 (*)
 152         # look for curses-related libraries
 153         CF_CHECK_CURSES_LIB(panel,$cf_cv_libtype,new_panel)
 154         CF_CHECK_CURSES_LIB(menu,$cf_cv_libtype,menu_driver)
 155         CF_CHECK_CURSES_LIB(form,$cf_cv_libtype,form_driver)
 156
 157         # look for curses-related headers
 158         AC_CHECK_HEADERS( \
 159                 nc_alloc.h \
 160                 nomacros.h \
 161                 form.h \
 162                 menu.h \
 163                 panel.h \
 164                 term_entry.h \
 165                 )
 166         ;;
 167 esac
 168
 169 AC_STDC_HEADERS
 170 AC_HEADER_TIME
 171 AC_CHECK_HEADERS( \
 172 getopt.h \
 173 locale.h \
 174 math.h \
 175 stdarg.h \
 176 sys/ioctl.h \
 177 sys/select.h \
 178 sys/time.h \
 179 termios.h \
 180 unistd.h \
 181 )
 182
 183 CF_GETOPT_HEADER
 184
 185 AC_CHECK_FUNCS( \
 186 getopt \
 187 gettimeofday \
 188 )
 189
 190 if test "x$ac_cv_func_getopt" = xno; then
 191         AC_MSG_ERROR(getopt is required for building programs)
 192 fi
 193
 194 if test "$cf_enable_widec" = yes; then
 195 AC_CHECK_FUNCS( \
 196 mblen \
 197 mbrlen \
 198 mbrtowc \
 199 mbsrtowcs \
 200 mbstowcs \
 201 mbtowc \
 202 wcsrtombs \
 203 wcstombs \
 204 )
 205 fi
 206
 207 CF_CURSES_FUNCS( \
 208 alloc_pair \
 209 assume_default_colors \
 210 chgat \
 211 color_set \
 212 filter \
 213 getbegx \
 214 getcurx \
 215 getmaxx \
 216 getnstr \
 217 getparx \
 218 getwin \
 219 mvvline \
 220 mvwvline \
 221 napms \
 222 putwin \
 223 resize_term \
 224 resizeterm \
 225 restartterm \
 226 ripoffline \
 227 scr_dump \
 228 setupterm \
 229 slk_color \
 230 slk_init \
 231 termattrs \
 232 tgetent \
 233 tigetnum \
 234 tigetstr \
 235 typeahead \
 236 use_default_colors \
 237 use_env \
 238 use_extended_names \
 239 use_screen \
 240 use_window \
 241 vid_puts \
 242 vidputs \
 243 vsscanf \
 244 vw_printw \
 245 wchgat \
 246 winsstr \
 247 wresize \
 248 wsyncdown \
 249 )
 250
 251 CF_TPUTS_PROTO
 252 CF_NCURSES_EXT_FUNCS
 253
 254 if test "$cf_enable_widec" = yes
 255 then
 256         # workaround for systems with ncurses before 20111029, due to change of
 257         # feature test macro from _XPG5 to _XOPEN_SOURCE
 258         if test -n "$cf_cv_ncurses_version" && test "x$cf_cv_ncurses_version" != xno
 259         then
 260                 cf_define_xpg5=no
 261                 AC_MSG_CHECKING(if _XPG5 should be defined to enable wide-characters)
 262
 263                 AC_TRY_COMPILE([
 264 #include <${cf_cv_ncurses_header:-curses.h}>],
 265                         [int x = _XPG5],,
 266                         [cf_save_cppflags="$CPPFLAGS"
 267                          CPPFLAGS="$CPPFLAGS -D_XPG5"
 268                          AC_TRY_COMPILE([
 269 #include <${cf_cv_ncurses_header:-curses.h}>],
 270                                 [int x = _XPG5],
 271                                 [cf_define_xpg5=yes])
 272                          CPPFLAGS="$cf_save_cppflags"])
 273                 AC_MSG_RESULT($cf_define_xpg5)
 274
 275                 if test "$cf_define_xpg5" = yes
 276                 then
 277                         CPPFLAGS="$CPPFLAGS -D_XPG5"
 278                 fi
 279         fi
 280
 281         AC_CACHE_CHECK(for wide-character functions,cf_cv_widechar_funcs,[
 282         AC_TRY_LINK([
 283 #include <${cf_cv_ncurses_header:-curses.h}>],
 284         [
 285                 static wchar_t src_wchar[2];
 286                 static cchar_t dst_cchar;
 287                 setcchar(&dst_cchar, src_wchar, A_NORMAL, 0, (void *) 0);
 288                 ],
 289                 [cf_cv_widechar_funcs=yes],
 290                 [cf_cv_widechar_funcs=no])
 291         ])
 292         if test "$cf_cv_widechar_funcs" != no ; then
 293                 AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to enable wide-character support in (n)curses])
 294         else
 295                 AC_DEFINE(USE_WIDEC_SUPPORT,0)
 296         fi
 297 else
 298         AC_DEFINE(USE_WIDEC_SUPPORT,0)
 299 fi
 300
 301 AC_CACHE_CHECK(if $cf_cv_screen library uses pthreads,cf_cv_use_pthreads,[
 302 AC_TRY_LINK([
 303 #include <${cf_cv_ncurses_header:-curses.h}>
 304 extern void _nc_init_pthreads(void);
 305 ],
 306 [
 307         initscr();
 308         _nc_init_pthreads();
 309         ],
 310         [cf_cv_use_pthreads=yes],
 311         [cf_cv_use_pthreads=no])
 312 ])
 313 test $cf_cv_use_pthreads = yes && AC_DEFINE(USE_PTHREADS)
 314
 315 CF_SYS_TIME_SELECT
 316
 317 # special check for test/ditto.c
 318 CF_FUNC_OPENPTY
 319 if test "$cf_cv_func_openpty" != no ; then
 320         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
 321         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
 322         if test "x$cf_cv_lib_util" = xyes ; then
 323                 CF_ADD_LIB(util,TEST_LIBS)
 324         fi
 325 fi
 326
 327 CF_FUNC_CURSES_VERSION
 328
 329 CF_CURSES_ACS_MAP
 330 if test "$cf_enable_widec" = yes; then
 331         CF_CURSES_WACS_MAP
 332         CF_CURSES_WACS_SYMBOLS
 333 fi
 334
 335 CF_CURSES_CHECK_TYPE(attr_t,long)
 336
 337 if test "$cf_enable_widec" = yes; then
 338         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T, NCURSES_OK_MBSTATE_T)
 339         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 340         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 341
 342         if test "$NCURSES_OK_MBSTATE_T" = 0 ; then
 343                 CF_CURSES_CHECK_TYPE(mbstate_t,long)
 344         fi
 345
 346         if test "$NCURSES_OK_WCHAR_T" = 0 ; then
 347                 CF_CURSES_CHECK_TYPE(wchar_t,long)
 348         fi
 349
 350         if test "$NCURSES_OK_WINT_T" = 0 ; then
 351                 CF_CURSES_CHECK_TYPE(wint_t,long)
 352         fi
 353 fi
 354
 355 CF_CURSES_CHECK_DATA(ospeed)
 356 CF_CURSES_CHECK_DATA(boolnames)
 357 CF_CURSES_CHECK_DATA(boolfnames)
 358 CF_CURSES_CHECK_DATA(ttytype)
 359
 360 dnl ---------------------------------------------------------------------------
 361 CF_HELP_MESSAGE(Testing/development Options:)
 362 CF_ENABLE_WARNINGS
 363 CF_DISABLE_LEAKS
 364 CF_DISABLE_RPATH_HACK
 365
 366 TEST_ARGS="$LIBS"
 367 LIBS=
 368
 369 dnl ---------------------------------------------------------------------------
 370
 371 AC_OUTPUT(Makefile,[
 372 CF_PRG_RULES([$srcdir/mk-test.awk INSTALL=yes ECHO_LINK="$ECHO_LD"], .)
 373         cat >>Makefile <<TEST_EOF
 374
 375 # These rules are generated so we do not rely on suffix rules, which do not
 376 # work consistently for different make-programs (the '\$(MODEL)/' confuses
 377 # some, and the '\$x' confuses others).
 378 TEST_EOF
 379
 380 LIST=`sed -e 's/[[      ]].*//' -e '/^[[#@]]/d' $srcdir/modules`
 381 for N in $LIST
 382 do
 383         cat >>Makefile <<TEST_EOF
 384
 385 \$(MODEL)/$N.o : \$(srcdir)/$N.c \\
 386         \$(srcdir)/test.priv.h \\
 387         ncurses_cfg.h
 388         $SHOW_CC
 389         $ECHO_CC\$(CC) -c \$(CFLAGS_DEFAULT) \$(srcdir)/$N.c
 390 TEST_EOF
 391 done
 392
 393 if test -f ../config.guess && test -f ../config.sub
 394 then
 395         cat >>Makefile <<TEST_EOF
 396
 397 # if we used CF_INHERIT for getting these files, we can remove them
 398 distclean::
 399         rm -f config.guess config.sub
 400 TEST_EOF
 401 fi
 402 ],[
 403 AWK="$AWK"
 404 ECHO_CC="$ECHO_CC"
 405 ECHO_LD="$ECHO_LD"
 406 SHOW_CC="$SHOW_LD"
 407 ],cat)