ncurses 6.2 - patch 20210807
[ncurses.git] / Ada95 / aclocal.m4
1 dnl***************************************************************************
2 dnl Copyright 2018-2020,2021 Thomas E. Dickey                                *
3 dnl Copyright 2010-2017,2018 Free Software Foundation, Inc.                  *
4 dnl                                                                          *
5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
6 dnl copy of this software and associated documentation files (the            *
7 dnl "Software"), to deal in the Software without restriction, including      *
8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
10 dnl copies of the Software, and to permit persons to whom the Software is    *
11 dnl furnished to do so, subject to the following conditions:                 *
12 dnl                                                                          *
13 dnl The above copyright notice and this permission notice shall be included  *
14 dnl in all copies or substantial portions of the Software.                   *
15 dnl                                                                          *
16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
23 dnl                                                                          *
24 dnl Except as contained in this notice, the name(s) of the above copyright   *
25 dnl holders shall not be used in advertising or otherwise to promote the     *
26 dnl sale, use or other dealings in this Software without prior written       *
27 dnl authorization.                                                           *
28 dnl***************************************************************************
29 dnl
30 dnl Author: Thomas E. Dickey
31 dnl
32 dnl $Id: aclocal.m4,v 1.178 2021/08/07 20:59:57 tom Exp $
33 dnl Macros used in NCURSES Ada95 auto-configuration script.
34 dnl
35 dnl These macros are maintained separately from NCURSES.  The copyright on
36 dnl this file applies to the aggregation of macros and does not affect use of
37 dnl these macros in other applications.
38 dnl
39 dnl See these pages for additional information:
40 dnl             https://invisible-island.net/autoconf/
41 dnl             https://invisible-island.net/autoconf/my-autoconf.html
42 dnl
43 dnl ---------------------------------------------------------------------------
44 dnl ---------------------------------------------------------------------------
45 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
46 dnl ------------------
47 dnl Conditionally generate script according to whether we're using a given autoconf.
48 dnl
49 dnl $1 = version to compare against
50 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
51 dnl $3 = code to use if AC_ACVERSION is older than $1.
52 define([CF_ACVERSION_CHECK],
53 [
54 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
55 ifdef([m4_version_compare],
56 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
57 [CF_ACVERSION_COMPARE(
58 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
59 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
60 dnl ---------------------------------------------------------------------------
61 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
62 dnl --------------------
63 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
64 dnl                      MAJOR2, MINOR2, TERNARY2,
65 dnl                      PRINTABLE2, not FOUND, FOUND)
66 define([CF_ACVERSION_COMPARE],
67 [ifelse(builtin([eval], [$2 < $5]), 1,
68 [ifelse([$8], , ,[$8])],
69 [ifelse([$9], , ,[$9])])])dnl
70 dnl ---------------------------------------------------------------------------
71 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
72 dnl -------------------
73 dnl Construct the list of include-options for the C programs in the Ada95
74 dnl binding.
75 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
76 [
77 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
78 if test "$srcdir" != "."; then
79         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
80 fi
81 if test "$GCC" != yes; then
82         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
83 elif test "$includedir" != "/usr/include"; then
84         if test "$includedir" = '${prefix}/include' ; then
85                 if test x$prefix != x/usr ; then
86                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
87                 fi
88         else
89                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
90         fi
91 fi
92 AC_SUBST(ACPPFLAGS)
93 ])dnl
94 dnl ---------------------------------------------------------------------------
95 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
96 dnl ---------------
97 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
98 AC_DEFUN([CF_ADD_ADAFLAGS],[
99         ADAFLAGS="$ADAFLAGS $1"
100         AC_SUBST(ADAFLAGS)
101 ])dnl
102 dnl ---------------------------------------------------------------------------
103 dnl CF_ADD_CFLAGS version: 15 updated: 2020/12/31 10:54:15
104 dnl -------------
105 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
106 dnl $1 = flags to add
107 dnl $2 = if given makes this macro verbose.
108 dnl
109 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
110 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
111 dnl confused by the quotes (which require backslashes to keep them usable).
112 AC_DEFUN([CF_ADD_CFLAGS],
113 [
114 cf_fix_cppflags=no
115 cf_new_cflags=
116 cf_new_cppflags=
117 cf_new_extra_cppflags=
118
119 for cf_add_cflags in $1
120 do
121 case "$cf_fix_cppflags" in
122 (no)
123         case "$cf_add_cflags" in
124         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
125                 case "$cf_add_cflags" in
126                 (-D*)
127                         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
128
129                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
130                                 && test -z "${cf_tst_cflags}" \
131                                 && cf_fix_cppflags=yes
132
133                         if test "$cf_fix_cppflags" = yes ; then
134                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
135                                 continue
136                         elif test "${cf_tst_cflags}" = "\"'" ; then
137                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
138                                 continue
139                         fi
140                         ;;
141                 esac
142                 case "$CPPFLAGS" in
143                 (*$cf_add_cflags)
144                         ;;
145                 (*)
146                         case "$cf_add_cflags" in
147                         (-D*)
148                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
149                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
150                                 ;;
151                         esac
152                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
153                         ;;
154                 esac
155                 ;;
156         (*)
157                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
158                 ;;
159         esac
160         ;;
161 (yes)
162         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
163
164         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^[[^"]]*"'\''//'`
165
166         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
167                 && test -z "${cf_tst_cflags}" \
168                 && cf_fix_cppflags=no
169         ;;
170 esac
171 done
172
173 if test -n "$cf_new_cflags" ; then
174         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
175         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
176 fi
177
178 if test -n "$cf_new_cppflags" ; then
179         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
180         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
181 fi
182
183 if test -n "$cf_new_extra_cppflags" ; then
184         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
185         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
186 fi
187
188 AC_SUBST(EXTRA_CPPFLAGS)
189
190 ])dnl
191 dnl ---------------------------------------------------------------------------
192 dnl CF_ADD_INCDIR version: 16 updated: 2020/12/31 20:19:42
193 dnl -------------
194 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
195 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
196 dnl but old versions (and some misinstalled ones) need that.  To make things
197 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
198 dnl the include-path).
199 AC_DEFUN([CF_ADD_INCDIR],
200 [
201 if test -n "$1" ; then
202   for cf_add_incdir in $1
203   do
204         while test "$cf_add_incdir" != /usr/include
205         do
206           if test -d "$cf_add_incdir"
207           then
208                 cf_have_incdir=no
209                 if test -n "$CFLAGS$CPPFLAGS" ; then
210                   # a loop is needed to ensure we can add subdirs of existing dirs
211                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
212                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
213                           cf_have_incdir=yes; break
214                         fi
215                   done
216                 fi
217
218                 if test "$cf_have_incdir" = no ; then
219                   if test "$cf_add_incdir" = /usr/local/include ; then
220                         if test "$GCC" = yes
221                         then
222                           cf_save_CPPFLAGS=$CPPFLAGS
223                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
224                           AC_TRY_COMPILE([#include <stdio.h>],
225                                   [printf("Hello")],
226                                   [],
227                                   [cf_have_incdir=yes])
228                           CPPFLAGS=$cf_save_CPPFLAGS
229                         fi
230                   fi
231                 fi
232
233                 if test "$cf_have_incdir" = no ; then
234                   CF_VERBOSE(adding $cf_add_incdir to include-path)
235                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
236
237                   cf_top_incdir=`echo "$cf_add_incdir" | sed -e 's%/include/.*$%/include%'`
238                   test "$cf_top_incdir" = "$cf_add_incdir" && break
239                   cf_add_incdir="$cf_top_incdir"
240                 else
241                   break
242                 fi
243           else
244                 break
245           fi
246         done
247   done
248 fi
249 ])dnl
250 dnl ---------------------------------------------------------------------------
251 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
252 dnl ----------
253 dnl Add a library, used to enforce consistency.
254 dnl
255 dnl $1 = library to add, without the "-l"
256 dnl $2 = variable to update (default $LIBS)
257 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
258 dnl ---------------------------------------------------------------------------
259 dnl CF_ADD_LIBDIR version: 11 updated: 2020/12/31 20:19:42
260 dnl -------------
261 dnl     Adds to the library-path
262 dnl
263 dnl     Some machines have trouble with multiple -L options.
264 dnl
265 dnl $1 is the (list of) directory(s) to add
266 dnl $2 is the optional name of the variable to update (default LDFLAGS)
267 dnl
268 AC_DEFUN([CF_ADD_LIBDIR],
269 [
270 if test -n "$1" ; then
271         for cf_add_libdir in $1
272         do
273                 if test "$cf_add_libdir" = /usr/lib ; then
274                         :
275                 elif test -d "$cf_add_libdir"
276                 then
277                         cf_have_libdir=no
278                         if test -n "$LDFLAGS$LIBS" ; then
279                                 # a loop is needed to ensure we can add subdirs of existing dirs
280                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
281                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
282                                                 cf_have_libdir=yes; break
283                                         fi
284                                 done
285                         fi
286                         if test "$cf_have_libdir" = no ; then
287                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
288                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
289                         fi
290                 fi
291         done
292 fi
293 ])dnl
294 dnl ---------------------------------------------------------------------------
295 dnl CF_ADD_LIBS version: 3 updated: 2019/11/02 16:47:33
296 dnl -----------
297 dnl Add one or more libraries, used to enforce consistency.  Libraries are
298 dnl prepended to an existing list, since their dependencies are assumed to
299 dnl already exist in the list.
300 dnl
301 dnl $1 = libraries to add, with the "-l", etc.
302 dnl $2 = variable to update (default $LIBS)
303 AC_DEFUN([CF_ADD_LIBS],[
304 cf_add_libs="[$]ifelse($2,,LIBS,[$2])"
305 # reverse order
306 cf_add_0lib=
307 for cf_add_1lib in $1; do cf_add_0lib="$cf_add_1lib $cf_add_0lib"; done
308 # filter duplicates
309 for cf_add_1lib in $cf_add_0lib; do
310         for cf_add_2lib in $cf_add_libs; do
311                 if test "x$cf_add_1lib" = "x$cf_add_2lib"; then
312                         cf_add_1lib=
313                         break
314                 fi
315         done
316         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_1lib $cf_add_libs"
317 done
318 ifelse($2,,LIBS,[$2])="$cf_add_libs"
319 ])dnl
320 dnl ---------------------------------------------------------------------------
321 dnl CF_ADD_SUBDIR_PATH version: 5 updated: 2020/12/31 20:19:42
322 dnl ------------------
323 dnl Append to a search-list for a nonstandard header/lib-file
324 dnl     $1 = the variable to return as result
325 dnl     $2 = the package name
326 dnl     $3 = the subdirectory, e.g., bin, include or lib
327 dnl $4 = the directory under which we will test for subdirectories
328 dnl $5 = a directory that we do not want $4 to match
329 AC_DEFUN([CF_ADD_SUBDIR_PATH],
330 [
331 test "x$4" != "x$5" && \
332 test -d "$4" && \
333 ifelse([$5],NONE,,[{ test -z "$5" || test "x$5" = xNONE || test "x$4" != "x$5"; } &&]) {
334         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
335         test -d "$4/$3" &&          $1="[$]$1 $4/$3"
336         test -d "$4/$3/$2" &&       $1="[$]$1 $4/$3/$2"
337         test -d "$4/$3/$2/$3" &&    $1="[$]$1 $4/$3/$2/$3"
338         test -d "$4/$2/$3" &&       $1="[$]$1 $4/$2/$3"
339         test -d "$4/$2/$3/$2" &&    $1="[$]$1 $4/$2/$3/$2"
340 }
341 ])dnl
342 dnl ---------------------------------------------------------------------------
343 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
344 dnl --------------
345 dnl use this macro for appending text without introducing an extra blank at
346 dnl the beginning
347 define([CF_APPEND_TEXT],
348 [
349         test -n "[$]$1" && $1="[$]$1 "
350         $1="[$]{$1}$2"
351 ])dnl
352 dnl ---------------------------------------------------------------------------
353 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
354 dnl --------------
355 dnl Allow user to disable a normally-on option.
356 AC_DEFUN([CF_ARG_DISABLE],
357 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
358 dnl ---------------------------------------------------------------------------
359 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
360 dnl -------------
361 dnl Allow user to enable a normally-off option.
362 AC_DEFUN([CF_ARG_ENABLE],
363 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
364 dnl ---------------------------------------------------------------------------
365 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
366 dnl -------------
367 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
368 dnl values.
369 dnl
370 dnl Parameters:
371 dnl $1 = option name
372 dnl $2 = help-string
373 dnl $3 = action to perform if option is not default
374 dnl $4 = action if perform if option is default
375 dnl $5 = default option value (either 'yes' or 'no')
376 AC_DEFUN([CF_ARG_OPTION],
377 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
378         if test "$enableval" != "$5" ; then
379 ifelse([$3],,[    :]dnl
380 ,[    $3]) ifelse([$4],,,[
381         else
382                 $4])
383         fi],[enableval=$5 ifelse([$4],,,[
384         $4
385 ])dnl
386 ])])dnl
387 dnl ---------------------------------------------------------------------------
388 dnl CF_AR_FLAGS version: 9 updated: 2021/01/01 13:31:04
389 dnl -----------
390 dnl Check for suitable "ar" (archiver) options for updating an archive.
391 dnl
392 dnl In particular, handle some obsolete cases where the "-" might be omitted,
393 dnl as well as a workaround for breakage of make's archive rules by the GNU
394 dnl binutils "ar" program.
395 AC_DEFUN([CF_AR_FLAGS],[
396 AC_REQUIRE([CF_PROG_AR])
397
398 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
399         case "$cf_cv_system_name" in
400         (*-msvc*)
401                 cf_cv_ar_flags=''
402                 cat >mk_static_lib.sh <<-EOF
403                 #!$SHELL
404                 MSVC_BIN="[$]AR"
405                 out="\[$]1"
406                 shift
407                 exec \[$]MSVC_BIN -out:"\[$]out" \[$]@
408                 EOF
409                 chmod +x mk_static_lib.sh
410                 AR=`pwd`/mk_static_lib.sh
411                 ;;
412         (*)
413                 cf_cv_ar_flags=unknown
414                 for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
415                 do
416
417                         # check if $ARFLAGS already contains this choice
418                         if test "x$ARFLAGS" != "x" ; then
419                                 cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
420                                 if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
421                                         cf_cv_ar_flags=
422                                         break
423                                 fi
424                         fi
425
426                         rm -f "conftest.$ac_cv_objext"
427                         rm -f conftest.a
428
429                         cat >"conftest.$ac_ext" <<EOF
430 #line __oline__ "configure"
431 int     testdata[[3]] = { 123, 456, 789 };
432 EOF
433                         if AC_TRY_EVAL(ac_compile) ; then
434                                 echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
435                                 $AR $ARFLAGS "$cf_ar_flags" conftest.a "conftest.$ac_cv_objext" 2>&AC_FD_CC 1>/dev/null
436                                 if test -f conftest.a ; then
437                                         cf_cv_ar_flags="$cf_ar_flags"
438                                         break
439                                 fi
440                         else
441                                 CF_VERBOSE(cannot compile test-program)
442                                 break
443                         fi
444                 done
445                 rm -f conftest.a "conftest.$ac_ext" "conftest.$ac_cv_objext"
446                 ;;
447         esac
448 ])
449
450 if test -n "$ARFLAGS" ; then
451         if test -n "$cf_cv_ar_flags" ; then
452                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
453         fi
454 else
455         ARFLAGS=$cf_cv_ar_flags
456 fi
457
458 AC_SUBST(ARFLAGS)
459 ])
460 dnl ---------------------------------------------------------------------------
461 dnl CF_BUILD_CC version: 9 updated: 2021/01/02 09:31:20
462 dnl -----------
463 dnl If we're cross-compiling, allow the user to override the tools and their
464 dnl options.  The configure script is oriented toward identifying the host
465 dnl compiler, etc., but we need a build compiler to generate parts of the
466 dnl source.
467 dnl
468 dnl $1 = default for $CPPFLAGS
469 dnl $2 = default for $LIBS
470 AC_DEFUN([CF_BUILD_CC],[
471 CF_ACVERSION_CHECK(2.52,,
472         [AC_REQUIRE([CF_PROG_EXT])])
473 if test "$cross_compiling" = yes ; then
474
475         # defaults that we might want to override
476         : ${BUILD_CFLAGS:=''}
477         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
478         : ${BUILD_LDFLAGS:=''}
479         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
480         : ${BUILD_EXEEXT:='$x'}
481         : ${BUILD_OBJEXT:='o'}
482
483         AC_ARG_WITH(build-cc,
484                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
485                 [BUILD_CC="$withval"],
486                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
487         AC_MSG_CHECKING(for native build C compiler)
488         AC_MSG_RESULT($BUILD_CC)
489
490         AC_MSG_CHECKING(for native build C preprocessor)
491         AC_ARG_WITH(build-cpp,
492                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
493                 [BUILD_CPP="$withval"],
494                 [BUILD_CPP='${BUILD_CC} -E'])
495         AC_MSG_RESULT($BUILD_CPP)
496
497         AC_MSG_CHECKING(for native build C flags)
498         AC_ARG_WITH(build-cflags,
499                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
500                 [BUILD_CFLAGS="$withval"])
501         AC_MSG_RESULT($BUILD_CFLAGS)
502
503         AC_MSG_CHECKING(for native build C preprocessor-flags)
504         AC_ARG_WITH(build-cppflags,
505                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
506                 [BUILD_CPPFLAGS="$withval"])
507         AC_MSG_RESULT($BUILD_CPPFLAGS)
508
509         AC_MSG_CHECKING(for native build linker-flags)
510         AC_ARG_WITH(build-ldflags,
511                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
512                 [BUILD_LDFLAGS="$withval"])
513         AC_MSG_RESULT($BUILD_LDFLAGS)
514
515         AC_MSG_CHECKING(for native build linker-libraries)
516         AC_ARG_WITH(build-libs,
517                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
518                 [BUILD_LIBS="$withval"])
519         AC_MSG_RESULT($BUILD_LIBS)
520
521         # this assumes we're on Unix.
522         BUILD_EXEEXT=
523         BUILD_OBJEXT=o
524
525         : ${BUILD_CC:='${CC}'}
526
527         if { test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}'; } ; then
528                 AC_MSG_ERROR([Cross-build requires two compilers.
529 Use --with-build-cc to specify the native compiler.])
530         fi
531
532 else
533         : ${BUILD_CC:='${CC}'}
534         : ${BUILD_CPP:='${CPP}'}
535         : ${BUILD_CFLAGS:='${CFLAGS}'}
536         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
537         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
538         : ${BUILD_LIBS:='${LIBS}'}
539         : ${BUILD_EXEEXT:='$x'}
540         : ${BUILD_OBJEXT:='o'}
541 fi
542
543 AC_SUBST(BUILD_CC)
544 AC_SUBST(BUILD_CPP)
545 AC_SUBST(BUILD_CFLAGS)
546 AC_SUBST(BUILD_CPPFLAGS)
547 AC_SUBST(BUILD_LDFLAGS)
548 AC_SUBST(BUILD_LIBS)
549 AC_SUBST(BUILD_EXEEXT)
550 AC_SUBST(BUILD_OBJEXT)
551 ])dnl
552 dnl ---------------------------------------------------------------------------
553 dnl CF_C11_NORETURN version: 3 updated: 2021/03/28 11:36:23
554 dnl ---------------
555 AC_DEFUN([CF_C11_NORETURN],
556 [
557 AC_MSG_CHECKING(if you want to use C11 _Noreturn feature)
558 CF_ARG_ENABLE(stdnoreturn,
559         [  --enable-stdnoreturn    enable C11 _Noreturn feature for diagnostics],
560         [enable_stdnoreturn=yes],
561         [enable_stdnoreturn=no])
562 AC_MSG_RESULT($enable_stdnoreturn)
563
564 if test $enable_stdnoreturn = yes; then
565 AC_CACHE_CHECK([for C11 _Noreturn feature], cf_cv_c11_noreturn,
566         [AC_TRY_COMPILE([
567 #include <stdio.h>
568 #include <stdlib.h>
569 #include <stdnoreturn.h>
570 static _Noreturn void giveup(void) { exit(0); }
571         ],
572         [if (feof(stdin)) giveup()],
573         cf_cv_c11_noreturn=yes,
574         cf_cv_c11_noreturn=no)
575         ])
576 else
577         cf_cv_c11_noreturn=no,
578 fi
579
580 if test "$cf_cv_c11_noreturn" = yes; then
581         AC_DEFINE(HAVE_STDNORETURN_H, 1,[Define if <stdnoreturn.h> header is available and working])
582         AC_DEFINE_UNQUOTED(STDC_NORETURN,_Noreturn,[Define if C11 _Noreturn keyword is supported])
583         HAVE_STDNORETURN_H=1
584 else
585         HAVE_STDNORETURN_H=0
586 fi
587
588 AC_SUBST(HAVE_STDNORETURN_H)
589 AC_SUBST(STDC_NORETURN)
590 ])dnl
591 dnl ---------------------------------------------------------------------------
592 dnl CF_CC_ENV_FLAGS version: 10 updated: 2020/12/31 18:40:20
593 dnl ---------------
594 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
595 dnl into CC.  This will not help with broken scripts that wrap the compiler
596 dnl with options, but eliminates a more common category of user confusion.
597 dnl
598 dnl In particular, it addresses the problem of being able to run the C
599 dnl preprocessor in a consistent manner.
600 dnl
601 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
602 dnl the nuisance of having inconsistent settings for compiler and preprocessor
603 dnl outweighs that limitation.
604 AC_DEFUN([CF_CC_ENV_FLAGS],
605 [
606 # This should have been defined by AC_PROG_CC
607 : "${CC:=cc}"
608
609 AC_MSG_CHECKING(\$CFLAGS variable)
610 case "x$CFLAGS" in
611 (*-[[IUD]]*)
612         AC_MSG_RESULT(broken)
613         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
614         cf_flags="$CFLAGS"
615         CFLAGS=
616         for cf_arg in $cf_flags
617         do
618                 CF_ADD_CFLAGS($cf_arg)
619         done
620         ;;
621 (*)
622         AC_MSG_RESULT(ok)
623         ;;
624 esac
625
626 AC_MSG_CHECKING(\$CC variable)
627 case "$CC" in
628 (*[[\ \ ]]-*)
629         AC_MSG_RESULT(broken)
630         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
631         # humor him...
632         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
633         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
634         CC="$cf_prog"
635         for cf_arg in $cf_flags
636         do
637                 case "x$cf_arg" in
638                 (x-[[IUDfgOW]]*)
639                         CF_ADD_CFLAGS($cf_arg)
640                         ;;
641                 (*)
642                         CC="$CC $cf_arg"
643                         ;;
644                 esac
645         done
646         CF_VERBOSE(resulting CC: '$CC')
647         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
648         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
649         ;;
650 (*)
651         AC_MSG_RESULT(ok)
652         ;;
653 esac
654 ])dnl
655 dnl ---------------------------------------------------------------------------
656 dnl CF_CFG_DEFAULTS version: 16 updated: 2021/01/04 19:33:05
657 dnl ---------------
658 dnl Determine the default configuration into which we'll install ncurses.  This
659 dnl can be overridden by the user's command-line options.  There's two items to
660 dnl look for:
661 dnl     1. the prefix (e.g., /usr)
662 dnl     2. the header files (e.g., /usr/include/ncurses)
663 dnl We'll look for a previous installation of ncurses and use the same defaults.
664 dnl
665 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
666 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
667 dnl programs from a vendor's.
668 AC_DEFUN([CF_CFG_DEFAULTS],
669 [AC_REQUIRE([AC_PROG_FGREP])dnl
670
671 AC_MSG_CHECKING(for prefix)
672 if test "x$prefix" = "xNONE" ; then
673         case "$cf_cv_system_name" in
674                 # non-vendor systems don't have a conflict
675         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
676                 prefix=/usr
677                 ;;
678         (*)     prefix=$ac_default_prefix
679                 ;;
680         esac
681 fi
682 AC_MSG_RESULT($prefix)
683
684 if test "x$prefix" = "xNONE" ; then
685 AC_MSG_CHECKING(for default include-directory)
686 test -n "$verbose" && echo 1>&AC_FD_MSG
687 for cf_symbol in \
688         "$includedir" \
689         "$includedir/ncurses" \
690         "$prefix/include" \
691         "$prefix/include/ncurses" \
692         /usr/local/include \
693         /usr/local/include/ncurses \
694         /usr/include \
695         /usr/include/ncurses
696 do
697         cf_dir=`eval echo "$cf_symbol"`
698         if test -f "$cf_dir/curses.h" ; then
699         if ( ${FGREP-fgrep} NCURSES_VERSION "$cf_dir/curses.h" >/dev/null 2>&1 ) ; then
700                 includedir="$cf_symbol"
701                 test -n "$verbose"  && echo $ECHO_N "   found " 1>&AC_FD_MSG
702                 break
703         fi
704         fi
705         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
706 done
707 AC_MSG_RESULT($includedir)
708 fi
709 ])dnl
710 dnl ---------------------------------------------------------------------------
711 dnl CF_CHECK_CACHE version: 13 updated: 2020/12/31 10:54:15
712 dnl --------------
713 dnl Check if we're accidentally using a cache from a different machine.
714 dnl Derive the system name, as a check for reusing the autoconf cache.
715 dnl
716 dnl If we've packaged config.guess and config.sub, run that (since it does a
717 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
718 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
719 dnl which is useful in cross-compiles.
720 dnl
721 dnl Note: we would use $ac_config_sub, but that is one of the places where
722 dnl autoconf 2.5x broke compatibility with autoconf 2.13
723 AC_DEFUN([CF_CHECK_CACHE],
724 [
725 if test -f "$srcdir/config.guess" || test -f "$ac_aux_dir/config.guess" ; then
726         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
727         system_name="$host_os"
728 else
729         system_name="`(uname -s -r) 2>/dev/null`"
730         if test -z "$system_name" ; then
731                 system_name="`(hostname) 2>/dev/null`"
732         fi
733 fi
734 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
735 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
736
737 test -z "$system_name" && system_name="$cf_cv_system_name"
738 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
739
740 if test ".$system_name" != ".$cf_cv_system_name" ; then
741         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
742         AC_MSG_ERROR("Please remove config.cache and try again.")
743 fi
744 ])dnl
745 dnl ---------------------------------------------------------------------------
746 dnl CF_CHECK_GNAT_VERSION version: 4 updated: 2021/01/01 13:31:04
747 dnl ---------------------
748 AC_DEFUN([CF_CHECK_GNAT_VERSION],
749 [
750 AC_REQUIRE([CF_GNAT_VERSION])
751 case "$cf_cv_gnat_version" in
752 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
753         cf_cv_prog_gnat_correct=yes
754         ;;
755 (*)
756         AC_MSG_WARN(Unsupported GNAT version $cf_cv_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
757         cf_cv_prog_gnat_correct=no
758         ;;
759 esac
760 ])
761 dnl ---------------------------------------------------------------------------
762 dnl CF_CLANG_COMPILER version: 8 updated: 2021/01/01 13:31:04
763 dnl -----------------
764 dnl Check if the given compiler is really clang.  clang's C driver defines
765 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
766 dnl not ignore some gcc options.
767 dnl
768 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
769 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
770 dnl the wrappers for gcc and g++ warnings.
771 dnl
772 dnl $1 = GCC (default) or GXX
773 dnl $2 = CLANG_COMPILER (default)
774 dnl $3 = CFLAGS (default) or CXXFLAGS
775 AC_DEFUN([CF_CLANG_COMPILER],[
776 ifelse([$2],,CLANG_COMPILER,[$2])=no
777
778 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
779         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
780         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
781         AC_TRY_COMPILE([],[
782 #ifdef __clang__
783 #else
784 make an error
785 #endif
786 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
787 ],[])
788         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
789         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
790 fi
791
792 CLANG_VERSION=none
793
794 if test "x$ifelse([$2],,CLANG_COMPILER,[$2])" = "xyes" ; then
795         case "$CC" in
796         (c[[1-9]][[0-9]]|*/c[[1-9]][[0-9]])
797                 AC_MSG_WARN(replacing broken compiler alias $CC)
798                 CFLAGS="$CFLAGS -std=`echo "$CC" | sed -e 's%.*/%%'`"
799                 CC=clang
800                 ;;
801         esac
802
803         AC_MSG_CHECKING(version of $CC)
804         CLANG_VERSION="`$CC --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(CLANG[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
805         test -z "$CLANG_VERSION" && CLANG_VERSION=unknown
806         AC_MSG_RESULT($CLANG_VERSION)
807
808         for cf_clang_opt in \
809                 -Qunused-arguments \
810                 -Wno-error=implicit-function-declaration
811         do
812                 AC_MSG_CHECKING(if option $cf_clang_opt works)
813                 cf_save_CFLAGS="$CFLAGS"
814                 CFLAGS="$CFLAGS $cf_clang_opt"
815                 AC_TRY_LINK([
816                         #include <stdio.h>],[
817                         printf("hello!\\n");],[
818                         cf_clang_optok=yes],[
819                         cf_clang_optok=no])
820                 AC_MSG_RESULT($cf_clang_optok)
821                 CFLAGS="$cf_save_CFLAGS"
822                 if test "$cf_clang_optok" = yes; then
823                         CF_VERBOSE(adding option $cf_clang_opt)
824                         CF_APPEND_TEXT(CFLAGS,$cf_clang_opt)
825                 fi
826         done
827 fi
828 ])
829 dnl ---------------------------------------------------------------------------
830 dnl CF_CONST_X_STRING version: 7 updated: 2021/06/07 17:39:17
831 dnl -----------------
832 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
833 dnl character-strings.
834 dnl
835 dnl It is ambiguous because the specification accommodated the pre-ANSI
836 dnl compilers bundled by more than one vendor in lieu of providing a standard C
837 dnl compiler other than by costly add-ons.  Because of this, the specification
838 dnl did not take into account the use of const for telling the compiler that
839 dnl string literals would be in readonly memory.
840 dnl
841 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
842 dnl let the compiler decide how to represent Xt's strings which were #define'd.
843 dnl That does not solve the problem of using the block of Xt's strings which
844 dnl are compiled into the library (and is less efficient than one might want).
845 dnl
846 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
847 dnl when compiling the library and compiling using the library, to tell the
848 dnl compiler that String is const.
849 AC_DEFUN([CF_CONST_X_STRING],
850 [
851 AC_REQUIRE([AC_PATH_XTRA])
852
853 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
854
855 AC_TRY_COMPILE(
856 [
857 #include <stdlib.h>
858 #include <X11/Intrinsic.h>
859 ],
860 [String foo = malloc(1); free((void*)foo)],[
861
862 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
863         AC_TRY_COMPILE(
864                 [
865 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
866 #undef  XTSTRINGDEFINES /* X11R5 and later */
867 #include <stdlib.h>
868 #include <X11/Intrinsic.h>
869                 ],[String foo = malloc(1); *foo = 0],[
870                         cf_cv_const_x_string=no
871                 ],[
872                         cf_cv_const_x_string=yes
873                 ])
874 ])
875
876 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
877
878 case "$cf_cv_const_x_string" in
879 (no)
880         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
881         ;;
882 (*)
883         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
884         ;;
885 esac
886
887 ])
888 ])dnl
889 dnl ---------------------------------------------------------------------------
890 dnl CF_CONST_X_STRING version: 7 updated: 2021/06/07 17:39:17
891 dnl -----------------
892 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
893 dnl character-strings.
894 dnl
895 dnl It is ambiguous because the specification accommodated the pre-ANSI
896 dnl compilers bundled by more than one vendor in lieu of providing a standard C
897 dnl compiler other than by costly add-ons.  Because of this, the specification
898 dnl did not take into account the use of const for telling the compiler that
899 dnl string literals would be in readonly memory.
900 dnl
901 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
902 dnl let the compiler decide how to represent Xt's strings which were #define'd.
903 dnl That does not solve the problem of using the block of Xt's strings which
904 dnl are compiled into the library (and is less efficient than one might want).
905 dnl
906 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
907 dnl when compiling the library and compiling using the library, to tell the
908 dnl compiler that String is const.
909 AC_DEFUN([CF_CONST_X_STRING],
910 [
911 AC_REQUIRE([AC_PATH_XTRA])
912
913 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
914
915 AC_TRY_COMPILE(
916 [
917 #include <stdlib.h>
918 #include <X11/Intrinsic.h>
919 ],
920 [String foo = malloc(1); free((void*)foo)],[
921
922 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
923         AC_TRY_COMPILE(
924                 [
925 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
926 #undef  XTSTRINGDEFINES /* X11R5 and later */
927 #include <stdlib.h>
928 #include <X11/Intrinsic.h>
929                 ],[String foo = malloc(1); *foo = 0],[
930                         cf_cv_const_x_string=no
931                 ],[
932                         cf_cv_const_x_string=yes
933                 ])
934 ])
935
936 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
937
938 case "$cf_cv_const_x_string" in
939 (no)
940         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
941         ;;
942 (*)
943         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
944         ;;
945 esac
946
947 ])
948 ])dnl
949 dnl ---------------------------------------------------------------------------
950 dnl CF_CURSES_HEADER version: 5 updated: 2015/04/23 20:35:30
951 dnl ----------------
952 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
953 dnl variations of ncurses' installs.
954 dnl
955 dnl $1 = ncurses when looking for ncurses, or is empty
956 AC_DEFUN([CF_CURSES_HEADER],[
957 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
958 cf_cv_ncurses_header=none
959 for cf_header in \
960         ncurses.h ifelse($1,,,[$1/ncurses.h]) \
961         curses.h ifelse($1,,,[$1/curses.h]) ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
962 do
963 AC_TRY_COMPILE([#include <${cf_header}>],
964         [initscr(); tgoto("?", 0,0)],
965         [cf_cv_ncurses_header=$cf_header; break],[])
966 done
967 ])
968
969 if test "$cf_cv_ncurses_header" = none ; then
970         AC_MSG_ERROR(No curses header-files found)
971 fi
972
973 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
974 AC_CHECK_HEADERS($cf_cv_ncurses_header)
975 ])dnl
976 dnl ---------------------------------------------------------------------------
977 dnl CF_DIRNAME version: 5 updated: 2020/12/31 20:19:42
978 dnl ----------
979 dnl "dirname" is not portable, so we fake it with a shell script.
980 AC_DEFUN([CF_DIRNAME],[$1=`echo "$2" | sed -e 's%/[[^/]]*$%%'`])dnl
981 dnl ---------------------------------------------------------------------------
982 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
983 dnl ---------------
984 dnl You can always use "make -n" to see the actual options, but it's hard to
985 dnl pick out/analyze warning messages when the compile-line is long.
986 dnl
987 dnl Sets:
988 dnl     ECHO_LT - symbol to control if libtool is verbose
989 dnl     ECHO_LD - symbol to prefix "cc -o" lines
990 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
991 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
992 dnl     ECHO_CC - symbol to put before any "cc" line
993 dnl
994 AC_DEFUN([CF_DISABLE_ECHO],[
995 AC_MSG_CHECKING(if you want to see long compiling messages)
996 CF_ARG_DISABLE(echo,
997         [  --disable-echo          do not display "compiling" commands],
998         [
999         ECHO_LT='--silent'
1000         ECHO_LD='@echo linking [$]@;'
1001         RULE_CC='@echo compiling [$]<'
1002         SHOW_CC='@echo compiling [$]@'
1003         ECHO_CC='@'
1004 ],[
1005         ECHO_LT=''
1006         ECHO_LD=''
1007         RULE_CC=''
1008         SHOW_CC=''
1009         ECHO_CC=''
1010 ])
1011 AC_MSG_RESULT($enableval)
1012 AC_SUBST(ECHO_LT)
1013 AC_SUBST(ECHO_LD)
1014 AC_SUBST(RULE_CC)
1015 AC_SUBST(SHOW_CC)
1016 AC_SUBST(ECHO_CC)
1017 ])dnl
1018 dnl ---------------------------------------------------------------------------
1019 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1020 dnl ------------------------
1021 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1022 AC_MSG_CHECKING(if we want to use GNAT projects)
1023 CF_ARG_DISABLE(gnat-projects,
1024         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1025         [enable_gnat_projects=no],
1026         [enable_gnat_projects=yes])
1027 AC_MSG_RESULT($enable_gnat_projects)
1028 ])dnl
1029 dnl ---------------------------------------------------------------------------
1030 dnl CF_ENABLE_BROKEN_LINKER version: 2 updated: 2021/01/02 17:09:14
1031 dnl -----------------------
1032 dnl Some linkers cannot reference a data-only object.  Cygwin used to be one.
1033 dnl This usually follows CF_LINK_DATAONLY, but is not required in case we need
1034 dnl an unconditional feature.
1035 AC_DEFUN([CF_ENABLE_BROKEN_LINKER],[
1036
1037 AC_MSG_CHECKING(if you want broken-linker support code)
1038 AC_ARG_ENABLE(broken_linker,
1039         [  --enable-broken_linker  compile with broken-linker support code],
1040         [with_broken_linker=$enableval],
1041         [with_broken_linker=no])
1042 AC_MSG_RESULT($with_broken_linker)
1043
1044 : "${BROKEN_LINKER:=0}"
1045 if test "x$with_broken_linker" = xyes ; then
1046         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
1047         BROKEN_LINKER=1
1048 fi
1049 AC_SUBST(BROKEN_LINKER)
1050 ])dnl
1051 dnl ---------------------------------------------------------------------------
1052 dnl CF_ENABLE_WARNINGS version: 9 updated: 2021/01/05 19:40:50
1053 dnl ------------------
1054 dnl Configure-option to enable gcc warnings
1055 dnl
1056 dnl $1 = extra options to add, if supported
1057 dnl $2 = option for checking attributes.  By default, this is done when
1058 dnl      warnings are enabled.  For other values:
1059 dnl      yes: always do this, e.g., to use in generated library-headers
1060 dnl      no: never do this
1061 AC_DEFUN([CF_ENABLE_WARNINGS],[
1062 if test "$GCC" = yes || test "$GXX" = yes
1063 then
1064 CF_FIX_WARNINGS(CFLAGS)
1065 CF_FIX_WARNINGS(CPPFLAGS)
1066 CF_FIX_WARNINGS(LDFLAGS)
1067 AC_MSG_CHECKING(if you want to turn on gcc warnings)
1068 CF_ARG_ENABLE(warnings,
1069         [  --enable-warnings       test: turn on gcc compiler warnings],
1070         [enable_warnings=yes],
1071         [enable_warnings=no])
1072 AC_MSG_RESULT($enable_warnings)
1073 if test "$enable_warnings" = "yes"
1074 then
1075         ifelse($2,,[CF_GCC_ATTRIBUTES])
1076         CF_GCC_WARNINGS($1)
1077 fi
1078 ifelse($2,yes,[CF_GCC_ATTRIBUTES])
1079 fi
1080 ])dnl
1081 dnl ---------------------------------------------------------------------------
1082 dnl CF_FIND_LIBRARY version: 11 updated: 2021/01/02 09:31:20
1083 dnl ---------------
1084 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
1085 dnl prefer a standard location, and use -L options only if we do not find the
1086 dnl library in the standard library location(s).
1087 dnl     $1 = library name
1088 dnl     $2 = library class, usually the same as library name
1089 dnl     $3 = includes
1090 dnl     $4 = code fragment to compile/link
1091 dnl     $5 = corresponding function-name
1092 dnl     $6 = flag, nonnull if failure should not cause an error-exit
1093 dnl
1094 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
1095 dnl to use a -L option.
1096 AC_DEFUN([CF_FIND_LIBRARY],
1097 [
1098         eval 'cf_cv_have_lib_'"$1"'=no'
1099         cf_libdir=""
1100         AC_CHECK_FUNC($5,
1101                 eval 'cf_cv_have_lib_'"$1"'=yes',[
1102                 cf_save_LIBS="$LIBS"
1103                 AC_MSG_CHECKING(for $5 in -l$1)
1104                 LIBS="-l$1 $LIBS"
1105                 AC_TRY_LINK([$3],[$4],
1106                         [AC_MSG_RESULT(yes)
1107                          eval 'cf_cv_have_lib_'"$1"'=yes'
1108                         ],
1109                         [AC_MSG_RESULT(no)
1110                         CF_LIBRARY_PATH(cf_search,$2)
1111                         for cf_libdir in $cf_search
1112                         do
1113                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
1114                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
1115                                 AC_TRY_LINK([$3],[$4],
1116                                         [AC_MSG_RESULT(yes)
1117                                          eval 'cf_cv_have_lib_'"$1"'=yes'
1118                                          break],
1119                                         [AC_MSG_RESULT(no)
1120                                          LIBS="$cf_save_LIBS"])
1121                         done
1122                         ])
1123                 ])
1124 eval 'cf_found_library="[$]cf_cv_have_lib_'"$1"\"
1125 ifelse($6,,[
1126 if test "$cf_found_library" = no ; then
1127         AC_MSG_ERROR(Cannot link $1 library)
1128 fi
1129 ])
1130 ])dnl
1131 dnl ---------------------------------------------------------------------------
1132 dnl CF_FIND_LINKAGE version: 22 updated: 2020/12/31 20:19:42
1133 dnl ---------------
1134 dnl Find a library (specifically the linkage used in the code fragment),
1135 dnl searching for it if it is not already in the library path.
1136 dnl See also CF_ADD_SEARCHPATH.
1137 dnl
1138 dnl Parameters (4-on are optional):
1139 dnl     $1 = headers for library entrypoint
1140 dnl     $2 = code fragment for library entrypoint
1141 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1142 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1143 dnl     $5 = action to perform if not successful
1144 dnl     $6 = module name, if not the same as the library name
1145 dnl     $7 = extra libraries
1146 dnl
1147 dnl Sets these variables:
1148 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1149 dnl     $cf_cv_header_path_$3 - include-directory if needed
1150 dnl     $cf_cv_library_path_$3 - library-directory if needed
1151 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1152 AC_DEFUN([CF_FIND_LINKAGE],[
1153
1154 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1155 # will be set on completion of the AC_TRY_LINK below.
1156 cf_cv_header_path_$3=
1157 cf_cv_library_path_$3=
1158
1159 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1160
1161 cf_save_LIBS="$LIBS"
1162
1163 AC_TRY_LINK([$1],[$2],[
1164         cf_cv_find_linkage_$3=yes
1165         cf_cv_header_path_$3=/usr/include
1166         cf_cv_library_path_$3=/usr/lib
1167 ],[
1168
1169 LIBS="-l$3 $7 $cf_save_LIBS"
1170
1171 AC_TRY_LINK([$1],[$2],[
1172         cf_cv_find_linkage_$3=yes
1173         cf_cv_header_path_$3=/usr/include
1174         cf_cv_library_path_$3=/usr/lib
1175         cf_cv_library_file_$3="-l$3"
1176 ],[
1177         cf_cv_find_linkage_$3=no
1178         LIBS="$cf_save_LIBS"
1179
1180         CF_VERBOSE(find linkage for $3 library)
1181         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1182
1183         cf_save_CPPFLAGS="$CPPFLAGS"
1184         cf_test_CPPFLAGS="$CPPFLAGS"
1185
1186         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1187         for cf_cv_header_path_$3 in $cf_search
1188         do
1189                 if test -d "$cf_cv_header_path_$3" ; then
1190                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1191                         CPPFLAGS="$cf_save_CPPFLAGS"
1192                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
1193                         AC_TRY_COMPILE([$1],[$2],[
1194                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1195                                 cf_cv_find_linkage_$3=maybe
1196                                 cf_test_CPPFLAGS="$CPPFLAGS"
1197                                 break],[
1198                                 CPPFLAGS="$cf_save_CPPFLAGS"
1199                                 ])
1200                 fi
1201         done
1202
1203         if test "$cf_cv_find_linkage_$3" = maybe ; then
1204
1205                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1206
1207                 cf_save_LIBS="$LIBS"
1208                 cf_save_LDFLAGS="$LDFLAGS"
1209
1210                 ifelse([$6],,,[
1211                 CPPFLAGS="$cf_test_CPPFLAGS"
1212                 LIBS="-l$3 $7 $cf_save_LIBS"
1213                 AC_TRY_LINK([$1],[$2],[
1214                         CF_VERBOSE(... found $3 library in system)
1215                         cf_cv_find_linkage_$3=yes])
1216                         CPPFLAGS="$cf_save_CPPFLAGS"
1217                         LIBS="$cf_save_LIBS"
1218                         ])
1219
1220                 if test "$cf_cv_find_linkage_$3" != yes ; then
1221                         CF_LIBRARY_PATH(cf_search,$3)
1222                         for cf_cv_library_path_$3 in $cf_search
1223                         do
1224                                 if test -d "$cf_cv_library_path_$3" ; then
1225                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1226                                         CPPFLAGS="$cf_test_CPPFLAGS"
1227                                         LIBS="-l$3 $7 $cf_save_LIBS"
1228                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1229                                         AC_TRY_LINK([$1],[$2],[
1230                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1231                                         cf_cv_find_linkage_$3=yes
1232                                         cf_cv_library_file_$3="-l$3"
1233                                         break],[
1234                                         CPPFLAGS="$cf_save_CPPFLAGS"
1235                                         LIBS="$cf_save_LIBS"
1236                                         LDFLAGS="$cf_save_LDFLAGS"
1237                                         ])
1238                                 fi
1239                         done
1240                         CPPFLAGS="$cf_save_CPPFLAGS"
1241                         LDFLAGS="$cf_save_LDFLAGS"
1242                 fi
1243
1244         else
1245                 cf_cv_find_linkage_$3=no
1246         fi
1247         ],$7)
1248 ])
1249
1250 LIBS="$cf_save_LIBS"
1251
1252 if test "$cf_cv_find_linkage_$3" = yes ; then
1253 ifelse([$4],,[
1254         CF_ADD_INCDIR($cf_cv_header_path_$3)
1255         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1256         CF_ADD_LIB($3)
1257 ],[$4])
1258 else
1259 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1260 fi
1261 ])dnl
1262 dnl ---------------------------------------------------------------------------
1263 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
1264 dnl -----------------
1265 dnl make ADAFLAGS consistent with CFLAGS
1266 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1267         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1268         case "$CFLAGS" in
1269         (*-g*)
1270                 CF_ADD_ADAFLAGS(-g)
1271                 ;;
1272         esac
1273         case "$CFLAGS" in
1274         (*-O*)
1275                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1276                 CF_ADD_ADAFLAGS($cf_O_flag)
1277                 ;;
1278         esac
1279         AC_MSG_RESULT($ADAFLAGS)
1280 ])dnl
1281 dnl ---------------------------------------------------------------------------
1282 dnl CF_FIX_WARNINGS version: 3 updated: 2020/12/31 18:40:20
1283 dnl ---------------
1284 dnl Warning flags do not belong in CFLAGS, CPPFLAGS, etc.  Any of gcc's
1285 dnl "-Werror" flags can interfere with configure-checks.  Those go into
1286 dnl EXTRA_CFLAGS.
1287 dnl
1288 dnl $1 = variable name to repair
1289 define([CF_FIX_WARNINGS],[
1290 if test "$GCC" = yes || test "$GXX" = yes
1291 then
1292         case [$]$1 in
1293         (*-Werror=*)
1294                 CF_VERBOSE(repairing $1: [$]$1)
1295                 cf_temp_flags=
1296                 for cf_temp_scan in [$]$1
1297                 do
1298                         case "x$cf_temp_scan" in
1299                         (x-Werror=*)
1300                                 CF_APPEND_TEXT(EXTRA_CFLAGS,$cf_temp_scan)
1301                                 ;;
1302                         (*)
1303                                 CF_APPEND_TEXT(cf_temp_flags,$cf_temp_scan)
1304                                 ;;
1305                         esac
1306                 done
1307                 $1="$cf_temp_flags"
1308                 CF_VERBOSE(... fixed [$]$1)
1309                 CF_VERBOSE(... extra $EXTRA_CFLAGS)
1310                 ;;
1311         esac
1312 fi
1313 AC_SUBST(EXTRA_CFLAGS)
1314 ])dnl
1315 dnl ---------------------------------------------------------------------------
1316 dnl CF_GCC_ATTRIBUTES version: 24 updated: 2021/03/20 12:00:25
1317 dnl -----------------
1318 dnl Test for availability of useful gcc __attribute__ directives to quiet
1319 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1320 dnl to documentation, unrecognized directives cause older compilers to barf.
1321 AC_DEFUN([CF_GCC_ATTRIBUTES],
1322 [AC_REQUIRE([AC_PROG_FGREP])dnl
1323 AC_REQUIRE([CF_C11_NORETURN])dnl
1324
1325 if test "$GCC" = yes || test "$GXX" = yes
1326 then
1327 cat > conftest.i <<EOF
1328 #ifndef GCC_PRINTF
1329 #define GCC_PRINTF 0
1330 #endif
1331 #ifndef GCC_SCANF
1332 #define GCC_SCANF 0
1333 #endif
1334 #ifndef GCC_NORETURN
1335 #define GCC_NORETURN /* nothing */
1336 #endif
1337 #ifndef GCC_UNUSED
1338 #define GCC_UNUSED /* nothing */
1339 #endif
1340 EOF
1341 if test "$GCC" = yes
1342 then
1343         AC_CHECKING([for $CC __attribute__ directives])
1344 cat > "conftest.$ac_ext" <<EOF
1345 #line __oline__ "${as_me:-configure}"
1346 #include "confdefs.h"
1347 #include "conftest.h"
1348 #include "conftest.i"
1349 #if     GCC_PRINTF
1350 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1351 #else
1352 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1353 #endif
1354 #if     GCC_SCANF
1355 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1356 #else
1357 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1358 #endif
1359 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1360 extern GCC_NORETURN void oops(char *,...) GCC_PRINTFLIKE(1,2);
1361 extern GCC_NORETURN void foo(void);
1362 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { (void)argc; (void)argv; return 0; }
1363 EOF
1364         cf_printf_attribute=no
1365         cf_scanf_attribute=no
1366         for cf_attribute in scanf printf unused noreturn
1367         do
1368                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1369                 cf_directive="__attribute__(($cf_attribute))"
1370                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1371
1372                 case "$cf_attribute" in
1373                 (printf)
1374                         cf_printf_attribute=yes
1375                         cat >conftest.h <<EOF
1376 #define GCC_$cf_ATTRIBUTE 1
1377 EOF
1378                         ;;
1379                 (scanf)
1380                         cf_scanf_attribute=yes
1381                         cat >conftest.h <<EOF
1382 #define GCC_$cf_ATTRIBUTE 1
1383 EOF
1384                         ;;
1385                 (*)
1386                         cat >conftest.h <<EOF
1387 #define GCC_$cf_ATTRIBUTE $cf_directive
1388 EOF
1389                         ;;
1390                 esac
1391
1392                 if AC_TRY_EVAL(ac_compile); then
1393                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1394                         cat conftest.h >>confdefs.h
1395                         case "$cf_attribute" in
1396                         (noreturn)
1397                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1398                                 ;;
1399                         (printf)
1400                                 cf_value='/* nothing */'
1401                                 if test "$cf_printf_attribute" != no ; then
1402                                         cf_value='__attribute__((format(printf,fmt,var)))'
1403                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1404                                 fi
1405                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1406                                 ;;
1407                         (scanf)
1408                                 cf_value='/* nothing */'
1409                                 if test "$cf_scanf_attribute" != no ; then
1410                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1411                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1412                                 fi
1413                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1414                                 ;;
1415                         (unused)
1416                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1417                                 ;;
1418                         esac
1419                 fi
1420         done
1421 else
1422         ${FGREP-fgrep} define conftest.i >>confdefs.h
1423 fi
1424 rm -rf ./conftest*
1425 fi
1426 ])dnl
1427 dnl ---------------------------------------------------------------------------
1428 dnl CF_GCC_VERSION version: 8 updated: 2019/09/07 13:38:36
1429 dnl --------------
1430 dnl Find version of gcc, and (because icc/clang pretend to be gcc without being
1431 dnl compatible), attempt to determine if icc/clang is actually used.
1432 AC_DEFUN([CF_GCC_VERSION],[
1433 AC_REQUIRE([AC_PROG_CC])
1434 GCC_VERSION=none
1435 if test "$GCC" = yes ; then
1436         AC_MSG_CHECKING(version of $CC)
1437         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1438         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1439         AC_MSG_RESULT($GCC_VERSION)
1440 fi
1441 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1442 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1443 ])dnl
1444 dnl ---------------------------------------------------------------------------
1445 dnl CF_GCC_WARNINGS version: 41 updated: 2021/01/01 16:53:59
1446 dnl ---------------
1447 dnl Check if the compiler supports useful warning options.  There's a few that
1448 dnl we don't use, simply because they're too noisy:
1449 dnl
1450 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1451 dnl     -Winline (usually not worthwhile)
1452 dnl     -Wredundant-decls (system headers make this too noisy)
1453 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1454 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1455 dnl             is enabled for ncurses using "--enable-const".
1456 dnl     -pedantic
1457 dnl
1458 dnl Parameter:
1459 dnl     $1 is an optional list of gcc warning flags that a particular
1460 dnl             application might want to use, e.g., "no-unused" for
1461 dnl             -Wno-unused
1462 dnl Special:
1463 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1464 dnl
1465 AC_DEFUN([CF_GCC_WARNINGS],
1466 [
1467 AC_REQUIRE([CF_GCC_VERSION])
1468 if test "x$have_x" = xyes; then CF_CONST_X_STRING fi
1469 cat > "conftest.$ac_ext" <<EOF
1470 #line __oline__ "${as_me:-configure}"
1471 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1472 EOF
1473 if test "$INTEL_COMPILER" = yes
1474 then
1475 # The "-wdXXX" options suppress warnings:
1476 # remark #1419: external declaration in primary source file
1477 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1478 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1479 # remark #193: zero used for undefined preprocessing identifier
1480 # remark #593: variable "curs_sb_left_arrow" was set but never used
1481 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1482 # remark #869: parameter "tw" was never referenced
1483 # remark #981: operands are evaluated in unspecified order
1484 # warning #279: controlling expression is constant
1485
1486         AC_CHECKING([for $CC warning options])
1487         cf_save_CFLAGS="$CFLAGS"
1488         EXTRA_CFLAGS="$EXTRA_CFLAGS -Wall"
1489         for cf_opt in \
1490                 wd1419 \
1491                 wd1683 \
1492                 wd1684 \
1493                 wd193 \
1494                 wd593 \
1495                 wd279 \
1496                 wd810 \
1497                 wd869 \
1498                 wd981
1499         do
1500                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1501                 if AC_TRY_EVAL(ac_compile); then
1502                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1503                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1504                 fi
1505         done
1506         CFLAGS="$cf_save_CFLAGS"
1507 elif test "$GCC" = yes && test "$GCC_VERSION" != "unknown"
1508 then
1509         AC_CHECKING([for $CC warning options])
1510         cf_save_CFLAGS="$CFLAGS"
1511         cf_warn_CONST=""
1512         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1513         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
1514         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
1515         for cf_opt in W Wall \
1516                 Wbad-function-cast \
1517                 Wcast-align \
1518                 Wcast-qual \
1519                 Wdeclaration-after-statement \
1520                 Wextra \
1521                 Winline \
1522                 Wmissing-declarations \
1523                 Wmissing-prototypes \
1524                 Wnested-externs \
1525                 Wpointer-arith \
1526                 Wshadow \
1527                 Wstrict-prototypes \
1528                 Wundef Wno-inline $cf_gcc_warnings $cf_warn_CONST $1
1529         do
1530                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1531                 if AC_TRY_EVAL(ac_compile); then
1532                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1533                         case "$cf_opt" in
1534                         (Winline)
1535                                 case "$GCC_VERSION" in
1536                                 ([[34]].*)
1537                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1538                                         continue;;
1539                                 esac
1540                                 ;;
1541                         (Wpointer-arith)
1542                                 case "$GCC_VERSION" in
1543                                 ([[12]].*)
1544                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1545                                         continue;;
1546                                 esac
1547                                 ;;
1548                         esac
1549                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1550                 fi
1551         done
1552         CFLAGS="$cf_save_CFLAGS"
1553 fi
1554 rm -rf ./conftest*
1555
1556 AC_SUBST(EXTRA_CFLAGS)
1557 ])dnl
1558 dnl ---------------------------------------------------------------------------
1559 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
1560 dnl -----------------
1561 AC_DEFUN([CF_GNATPREP_OPT_T],[
1562 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
1563 cf_cv_gnatprep_opt_t=no
1564 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
1565 ])
1566 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
1567 AC_SUBST(GNATPREP_OPTS)
1568 ])dnl
1569 dnl ---------------------------------------------------------------------------
1570 dnl CF_GNAT_GENERICS version: 7 updated: 2021/01/01 13:31:04
1571 dnl ----------------
1572 AC_DEFUN([CF_GNAT_GENERICS],
1573 [
1574 AC_REQUIRE([CF_GNAT_VERSION])
1575
1576 AC_MSG_CHECKING(if GNAT supports generics)
1577 case "$cf_cv_gnat_version" in
1578 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
1579         cf_gnat_generics=yes
1580         ;;
1581 (*)
1582         cf_gnat_generics=no
1583         ;;
1584 esac
1585 AC_MSG_RESULT($cf_gnat_generics)
1586
1587 if test "$cf_gnat_generics" = yes
1588 then
1589         cf_compile_generics=generics
1590         cf_generic_objects="\${GENOBJS}"
1591 else
1592         cf_compile_generics=
1593         cf_generic_objects=
1594 fi
1595
1596 AC_SUBST(cf_compile_generics)
1597 AC_SUBST(cf_generic_objects)
1598 ])dnl
1599 dnl ---------------------------------------------------------------------------
1600 dnl CF_GNAT_PROJECTS version: 13 updated: 2021/01/02 17:09:14
1601 dnl ----------------
1602 dnl GNAT projects are configured with ".gpr" project files.
1603 dnl GNAT libraries are a further development, using the project feature.
1604 AC_DEFUN([CF_GNAT_PROJECTS],
1605 [
1606 AC_REQUIRE([CF_GNAT_VERSION])
1607 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
1608
1609 cf_gnat_libraries=no
1610 cf_gnat_projects=no
1611
1612 if test "$enable_gnat_projects" != no ; then
1613 AC_MSG_CHECKING(if GNAT supports project files)
1614 case "$cf_cv_gnat_version" in
1615 (3.[[0-9]]*)
1616         ;;
1617 (*)
1618         case "$cf_cv_system_name" in
1619         (cygwin*|msys*)
1620                 ;;
1621         (*)
1622                 rm -rf ./conftest* ./*~conftest*
1623                 if mkdir conftest.src conftest.bin conftest.lib
1624                 then
1625                         cd conftest.src
1626                         rm -rf ./conftest* ./*~conftest*
1627                         cat >>library.gpr <<CF_EOF
1628 project Library is
1629   Kind := External ("LIB_KIND");
1630   for Library_Name use "ConfTest";
1631   for Object_Dir use ".";
1632   for Library_ALI_Dir use External("LIBRARY_DIR");
1633   for Library_Version use External ("SONAME");
1634   for Library_Kind use Kind;
1635   for Library_Dir use External("BUILD_DIR");
1636   Source_Dir := External ("SOURCE_DIR");
1637   for Source_Dirs use (Source_Dir);
1638 end Library;
1639 CF_EOF
1640                         cat >>confpackage.ads <<CF_EOF
1641 package ConfPackage is
1642    procedure conftest;
1643 end ConfPackage;
1644 CF_EOF
1645                         cat >>confpackage.adb <<CF_EOF
1646 with Text_IO;
1647 package body ConfPackage is
1648    procedure conftest is
1649    begin
1650       Text_IO.Put ("Hello World");
1651       Text_IO.New_Line;
1652    end conftest;
1653 end ConfPackage;
1654 CF_EOF
1655                         if ( "$cf_ada_make" $ADAFLAGS \
1656                                         -Plibrary.gpr \
1657                                         -XBUILD_DIR="`cd ../conftest.bin;pwd`" \
1658                                         -XLIBRARY_DIR="`cd ../conftest.lib;pwd`" \
1659                                         -XSOURCE_DIR="`pwd`" \
1660                                         -XSONAME=libConfTest.so.1 \
1661                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
1662                                 cf_gnat_projects=yes
1663                         fi
1664                         cd ..
1665                 fi
1666                 if test -f conftest.lib/confpackage.ali
1667                 then
1668                         cf_gnat_libraries=yes
1669                 fi
1670                 rm -rf ./conftest* ./*~conftest*
1671                 ;;
1672         esac
1673         ;;
1674 esac
1675 AC_MSG_RESULT($cf_gnat_projects)
1676 fi # enable_gnat_projects
1677
1678 if test "$cf_gnat_projects" = yes
1679 then
1680         AC_MSG_CHECKING(if GNAT supports libraries)
1681         AC_MSG_RESULT($cf_gnat_libraries)
1682 fi
1683
1684 USE_OLD_MAKERULES=""
1685 USE_GNAT_PROJECTS="#"
1686 USE_GNAT_MAKE_GPR="#"
1687 USE_GNAT_GPRBUILD="#"
1688
1689 if test "$cf_gnat_projects" = yes
1690 then
1691         USE_OLD_MAKERULES="#"
1692         USE_GNAT_PROJECTS=""
1693         if test "$cf_cv_VERSION_GPRBUILD" != no
1694         then
1695                 USE_GNAT_GPRBUILD=""
1696         elif test "$cf_cv_VERSION_GNATMAKE" != no
1697         then
1698                 USE_GNAT_MAKE_GPR=""
1699         else
1700                 AC_MSG_WARN(use old makefile rules since tools are missing)
1701         fi
1702 fi
1703
1704 if test "$cf_gnat_libraries" = yes
1705 then
1706         USE_GNAT_LIBRARIES=""
1707 else
1708         USE_GNAT_LIBRARIES="#"
1709 fi
1710
1711 AC_SUBST(USE_OLD_MAKERULES)
1712 AC_SUBST(USE_GNAT_PROJECTS)
1713 AC_SUBST(USE_GNAT_LIBRARIES)
1714 AC_SUBST(USE_GNAT_MAKE_GPR)
1715 AC_SUBST(USE_GNAT_GPRBUILD)
1716 ])dnl
1717 dnl ---------------------------------------------------------------------------
1718 dnl CF_GNAT_SIGINT version: 2 updated: 2021/01/01 13:31:04
1719 dnl --------------
1720 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
1721 dnl is noted that gnat may compile a tasking unit even for configurations which
1722 dnl fail at runtime.
1723 AC_DEFUN([CF_GNAT_SIGINT],[
1724 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
1725 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
1726
1727 package ConfTest is
1728
1729    pragma Warnings (Off);  --  the next pragma exists since 3.11p
1730    pragma Unreserve_All_Interrupts;
1731    pragma Warnings (On);
1732
1733    protected Process is
1734       procedure Stop;
1735       function Continue return Boolean;
1736       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
1737    private
1738       Done : Boolean := False;
1739    end Process;
1740
1741 end ConfTest;],
1742 [package body ConfTest is
1743    protected body Process is
1744       procedure Stop is
1745       begin
1746          Done := True;
1747       end Stop;
1748       function Continue return Boolean is
1749       begin
1750          return not Done;
1751       end Continue;
1752    end Process;
1753 end ConfTest;],
1754         [cf_cv_gnat_sigint=yes],
1755         [cf_cv_gnat_sigint=no])])
1756
1757 if test "$cf_cv_gnat_sigint" = yes ; then
1758         USE_GNAT_SIGINT=""
1759 else
1760         USE_GNAT_SIGINT="#"
1761 fi
1762 AC_SUBST(USE_GNAT_SIGINT)
1763 ])dnl
1764 dnl ---------------------------------------------------------------------------
1765 dnl CF_GNAT_TRY_LINK version: 4 updated: 2021/01/01 13:31:04
1766 dnl ----------------
1767 dnl Verify that a test program compiles/links with GNAT.
1768 dnl $cf_ada_make is set to the program that compiles/links
1769 dnl $ADAFLAGS may be set to the GNAT flags.
1770 dnl
1771 dnl $1 is the text of the spec
1772 dnl $2 is the text of the body
1773 dnl $3 is the shell command to execute if successful
1774 dnl $4 is the shell command to execute if not successful
1775 AC_DEFUN([CF_GNAT_TRY_LINK],
1776 [
1777 rm -rf ./conftest* ./*~conftest*
1778 cat >>conftest.ads <<CF_EOF
1779 $1
1780 CF_EOF
1781 cat >>conftest.adb <<CF_EOF
1782 $2
1783 CF_EOF
1784 if ( "$cf_ada_make" $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1785 ifelse($3,,      :,[      $3])
1786 ifelse($4,,,[else
1787    $4])
1788 fi
1789 rm -rf ./conftest* ./*~conftest*
1790 ])dnl
1791 dnl ---------------------------------------------------------------------------
1792 dnl CF_GNAT_TRY_RUN version: 6 updated: 2021/01/01 13:31:04
1793 dnl ---------------
1794 dnl Verify that a test program compiles and runs with GNAT
1795 dnl $cf_ada_make is set to the program that compiles/links
1796 dnl $ADAFLAGS may be set to the GNAT flags.
1797 dnl
1798 dnl $1 is the text of the spec
1799 dnl $2 is the text of the body
1800 dnl $3 is the shell command to execute if successful
1801 dnl $4 is the shell command to execute if not successful
1802 AC_DEFUN([CF_GNAT_TRY_RUN],
1803 [
1804 rm -rf ./conftest* ./*~conftest*
1805 cat >>conftest.ads <<CF_EOF
1806 $1
1807 CF_EOF
1808 cat >>conftest.adb <<CF_EOF
1809 $2
1810 CF_EOF
1811 if ( "$cf_ada_make" $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1812    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
1813 ifelse($3,,      :,[      $3])
1814 ifelse($4,,,[   else
1815       $4])
1816    fi
1817 ifelse($4,,,[else
1818    $4])
1819 fi
1820 rm -rf ./conftest* ./*~conftest*
1821 ])dnl
1822 dnl ---------------------------------------------------------------------------
1823 dnl CF_GNAT_VERSION version: 22 updated: 2019/12/31 08:53:54
1824 dnl ---------------
1825 dnl $1 = cache variable to update
1826 dnl $2 = program name
1827 dnl Verify version of GNAT or related tool
1828 AC_DEFUN([CF_GNAT_VERSION],
1829 [
1830 AC_CACHE_CHECK(for ifelse($2,,gnat,$2) version, cf_cv_gnat_version,[
1831 cf_cv_gnat_version=`ifelse($2,,${cf_ada_make:-gnatmake},$2) --version 2>&1 | \
1832         grep '[[0-9]].[[0-9]][[0-9]]*' |\
1833         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
1834 ])
1835 test -z "$cf_cv_gnat_version" && cf_cv_gnat_version=no
1836 ifelse($1,,,[eval $1=$cf_cv_gnat_version; unset cf_cv_gnat_version])
1837 ])dnl
1838 dnl ---------------------------------------------------------------------------
1839 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
1840 dnl -------------
1841 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1842 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1843 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1844 dnl since it is interwoven with GNU extensions.
1845 dnl
1846 dnl Well, yes we could work around it...
1847 dnl
1848 dnl Parameters:
1849 dnl     $1 is the nominal value for _XOPEN_SOURCE
1850 AC_DEFUN([CF_GNU_SOURCE],
1851 [
1852 cf_gnu_xopen_source=ifelse($1,,500,$1)
1853
1854 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
1855 AC_TRY_COMPILE([#include <sys/types.h>],[
1856         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
1857                 return 0;
1858         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
1859                 return 0;
1860         #else
1861         #       error not GNU C library
1862         #endif],
1863         [cf_cv_gnu_library=yes],
1864         [cf_cv_gnu_library=no])
1865 ])
1866
1867 if test x$cf_cv_gnu_library = xyes; then
1868
1869         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
1870         # was changed to help a little.  newlib incorporated the change about 4
1871         # years later.
1872         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
1873                 cf_save="$CPPFLAGS"
1874                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
1875                 AC_TRY_COMPILE([#include <sys/types.h>],[
1876                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
1877                                 return 0;
1878                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
1879                                 return 0;
1880                         #else
1881                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
1882                         #endif],
1883                         [cf_cv_gnu_library_219=yes],
1884                         [cf_cv_gnu_library_219=no])
1885                 CPPFLAGS="$cf_save"
1886         ])
1887
1888         if test "x$cf_cv_gnu_library_219" = xyes; then
1889                 cf_save="$CPPFLAGS"
1890                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
1891                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
1892                         AC_TRY_COMPILE([
1893                                 #include <limits.h>
1894                                 #include <sys/types.h>
1895                                 ],[
1896                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
1897                                         return 0;
1898                                 #else
1899                                 #       error GNU C library is too old
1900                                 #endif],
1901                                 [cf_cv_gnu_dftsrc_219=yes],
1902                                 [cf_cv_gnu_dftsrc_219=no])
1903                         ])
1904                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
1905         else
1906                 cf_cv_gnu_dftsrc_219=maybe
1907         fi
1908
1909         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
1910
1911                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1912                 AC_TRY_COMPILE([#include <sys/types.h>],[
1913                         #ifndef _XOPEN_SOURCE
1914                         #error  expected _XOPEN_SOURCE to be defined
1915                         #endif],
1916                         [cf_cv_gnu_source=no],
1917                         [cf_save="$CPPFLAGS"
1918                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
1919                          AC_TRY_COMPILE([#include <sys/types.h>],[
1920                                 #ifdef _XOPEN_SOURCE
1921                                 #error  expected _XOPEN_SOURCE to be undefined
1922                                 #endif],
1923                                 [cf_cv_gnu_source=no],
1924                                 [cf_cv_gnu_source=yes])
1925                         CPPFLAGS="$cf_save"
1926                         ])
1927                 ])
1928
1929                 if test "$cf_cv_gnu_source" = yes
1930                 then
1931                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
1932                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
1933                         AC_TRY_COMPILE([#include <sys/types.h>],[
1934                                 #ifdef _DEFAULT_SOURCE
1935                                 #error  expected _DEFAULT_SOURCE to be undefined
1936                                 #endif],
1937                                 [cf_cv_default_source=no],
1938                                 [cf_cv_default_source=yes])
1939                         ])
1940                         if test "$cf_cv_default_source" = yes
1941                         then
1942                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
1943                         fi
1944                 fi
1945         fi
1946
1947 fi
1948 ])dnl
1949 dnl ---------------------------------------------------------------------------
1950 dnl CF_HEADER_PATH version: 15 updated: 2021/01/01 13:31:04
1951 dnl --------------
1952 dnl Construct a search-list of directories for a nonstandard header-file
1953 dnl
1954 dnl Parameters
1955 dnl     $1 = the variable to return as result
1956 dnl     $2 = the package name
1957 AC_DEFUN([CF_HEADER_PATH],
1958 [
1959 $1=
1960
1961 # collect the current set of include-directories from compiler flags
1962 cf_header_path_list=""
1963 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1964         for cf_header_path in $CPPFLAGS $CFLAGS
1965         do
1966                 case "$cf_header_path" in
1967                 (-I*)
1968                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1969                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1970                         cf_header_path_list="$cf_header_path_list [$]$1"
1971                         ;;
1972                 esac
1973         done
1974 fi
1975
1976 # add the variations for the package we are looking for
1977 CF_SUBDIR_PATH($1,$2,include)
1978
1979 test "$includedir" != NONE && \
1980 test "$includedir" != "/usr/include" && \
1981 test -d "$includedir" && {
1982         test -d "$includedir" &&    $1="[$]$1 $includedir"
1983         test -d "$includedir/$2" && $1="[$]$1 $includedir/$2"
1984 }
1985
1986 test "$oldincludedir" != NONE && \
1987 test "$oldincludedir" != "/usr/include" && \
1988 test -d "$oldincludedir" && {
1989         test -d "$oldincludedir"    && $1="[$]$1 $oldincludedir"
1990         test -d "$oldincludedir/$2" && $1="[$]$1 $oldincludedir/$2"
1991 }
1992
1993 $1="[$]$1 $cf_header_path_list"
1994 ])dnl
1995 dnl ---------------------------------------------------------------------------
1996 dnl CF_HELP_MESSAGE version: 4 updated: 2019/12/31 08:53:54
1997 dnl ---------------
1998 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
1999 AC_DEFUN([CF_HELP_MESSAGE],
2000 [CF_ACVERSION_CHECK(2.53,[],[
2001 AC_DIVERT_HELP($1)])dnl
2002 ])dnl
2003 dnl ---------------------------------------------------------------------------
2004 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
2005 dnl ---------------
2006 dnl Construct the list of include-options according to whether we're building
2007 dnl in the source directory or using '--srcdir=DIR' option.
2008 AC_DEFUN([CF_INCLUDE_DIRS],
2009 [
2010 if test "$srcdir" != "."; then
2011         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
2012 fi
2013 CPPFLAGS="-I../include $CPPFLAGS"
2014 if test "$srcdir" != "."; then
2015         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
2016 fi
2017 CPPFLAGS="-I. $CPPFLAGS"
2018 AC_SUBST(CPPFLAGS)
2019 ])dnl
2020 dnl ---------------------------------------------------------------------------
2021 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
2022 dnl ---------------
2023 dnl prompt for/fill-in useful install-program options
2024 AC_DEFUN([CF_INSTALL_OPTS],
2025 [
2026 CF_INSTALL_OPT_S
2027 CF_INSTALL_OPT_P
2028 CF_INSTALL_OPT_O
2029 ])dnl
2030 dnl ---------------------------------------------------------------------------
2031 dnl CF_INSTALL_OPT_O version: 3 updated: 2020/12/31 20:19:42
2032 dnl ----------------
2033 dnl Almost all "install" programs default to the current user's ownership.
2034 dnl Almost - MINIX is an exception.
2035 AC_DEFUN([CF_INSTALL_OPT_O],
2036 [
2037 AC_MSG_CHECKING(if install needs to be told about ownership)
2038 case `$ac_config_guess` in
2039 (*minix)
2040         with_install_o=yes
2041         ;;
2042 (*)
2043         with_install_o=no
2044         ;;
2045 esac
2046
2047 AC_MSG_RESULT($with_install_o)
2048 if test "x$with_install_o" = xyes
2049 then
2050         INSTALL_OPT_O="`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`"
2051 else
2052         INSTALL_OPT_O=
2053 fi
2054
2055 AC_SUBST(INSTALL_OPT_O)
2056 ])dnl
2057 dnl ---------------------------------------------------------------------------
2058 dnl CF_INSTALL_OPT_P version: 3 updated: 2021/01/01 13:31:04
2059 dnl ----------------
2060 dnl Some install-programs accept a "-p" option to preserve file modification
2061 dnl timestamps.  That can be useful as an install option, as well as a way to
2062 dnl avoid the need for ranlib after copying a static archive.
2063 AC_DEFUN([CF_INSTALL_OPT_P],
2064 [
2065 : "${INSTALL:=install}"
2066 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
2067         rm -rf ./conftest*
2068         date >conftest.in
2069         mkdir conftest.out
2070         sleep 3
2071         if $INSTALL -p conftest.in conftest.out 2>/dev/null
2072         then
2073                 if test -f conftest.out/conftest.in
2074                 then
2075                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
2076                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
2077                         if test -s conftest.err
2078                         then
2079                                 cf_cv_install_p=no
2080                         else
2081                                 cf_cv_install_p=yes
2082                         fi
2083                 else
2084                         cf_cv_install_p=no
2085                 fi
2086         else
2087                 cf_cv_install_p=no
2088         fi
2089         rm -rf ./conftest*
2090 ])
2091 ])dnl
2092 dnl ---------------------------------------------------------------------------
2093 dnl CF_INSTALL_OPT_S version: 3 updated: 2021/01/05 19:23:48
2094 dnl ----------------
2095 dnl By default, we should strip executables which are installed, but leave the
2096 dnl ability to suppress that for unit-testing.
2097 AC_DEFUN([CF_INSTALL_OPT_S],
2098 [
2099 AC_MSG_CHECKING(if you want to install stripped executables)
2100 CF_ARG_DISABLE(stripping,
2101         [  --disable-stripping     do not strip (debug info) installed executables],
2102         [enable_stripping=no],
2103         [enable_stripping=yes])
2104 AC_MSG_RESULT($enable_stripping)
2105
2106 if test "$enable_stripping" = yes
2107 then
2108         INSTALL_OPT_S="-s"
2109 else
2110         INSTALL_OPT_S=
2111 fi
2112 AC_SUBST(INSTALL_OPT_S)
2113 ])dnl
2114 dnl ---------------------------------------------------------------------------
2115 dnl CF_INTEL_COMPILER version: 8 updated: 2021/01/01 16:53:59
2116 dnl -----------------
2117 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2118 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2119 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2120 dnl
2121 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2122 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2123 dnl the wrappers for gcc and g++ warnings.
2124 dnl
2125 dnl $1 = GCC (default) or GXX
2126 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2127 dnl $3 = CFLAGS (default) or CXXFLAGS
2128 AC_DEFUN([CF_INTEL_COMPILER],[
2129 AC_REQUIRE([AC_CANONICAL_HOST])
2130 ifelse([$2],,INTEL_COMPILER,[$2])=no
2131
2132 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2133         case "$host_os" in
2134         (linux*|gnu*)
2135                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2136                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2137                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2138                 AC_TRY_COMPILE([],[
2139 #ifdef __INTEL_COMPILER
2140 #else
2141 make an error
2142 #endif
2143 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2144 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
2145 ],[])
2146                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2147                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2148                 ;;
2149         esac
2150 fi
2151 ])dnl
2152 dnl ---------------------------------------------------------------------------
2153 dnl CF_LARGEFILE version: 12 updated: 2020/03/19 20:23:48
2154 dnl ------------
2155 dnl Add checks for large file support.
2156 AC_DEFUN([CF_LARGEFILE],[
2157 ifdef([AC_FUNC_FSEEKO],[
2158         AC_SYS_LARGEFILE
2159         if test "$enable_largefile" != no ; then
2160         AC_FUNC_FSEEKO
2161
2162         # Normally we would collect these definitions in the config.h,
2163         # but (like _XOPEN_SOURCE), some environments rely on having these
2164         # defined before any of the system headers are included.  Another
2165         # case comes up with C++, e.g., on AIX the compiler compiles the
2166         # header files by themselves before looking at the body files it is
2167         # told to compile.  For ncurses, those header files do not include
2168         # the config.h
2169         if test "$ac_cv_sys_large_files" != no
2170         then
2171                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
2172         fi
2173         if test "$ac_cv_sys_largefile_source" != no
2174         then
2175                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
2176         fi
2177         if test "$ac_cv_sys_file_offset_bits" != no
2178         then
2179                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
2180         fi
2181
2182         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2183                 AC_TRY_COMPILE([
2184 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
2185 #include <sys/types.h>
2186 #include <dirent.h>
2187                 ],[
2188                 /* if transitional largefile support is setup, this is true */
2189                 extern struct dirent64 * readdir(DIR *);
2190                 struct dirent64 *x = readdir((DIR *)0);
2191                 struct dirent *y = readdir((DIR *)0);
2192                 int z = x - y;
2193                 (void)z;
2194                 ],
2195                 [cf_cv_struct_dirent64=yes],
2196                 [cf_cv_struct_dirent64=no])
2197         ])
2198         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
2199         fi
2200 ])
2201 ])
2202 dnl ---------------------------------------------------------------------------
2203 dnl CF_LD_RPATH_OPT version: 9 updated: 2021/01/01 13:31:04
2204 dnl ---------------
2205 dnl For the given system and compiler, find the compiler flags to pass to the
2206 dnl loader to use the "rpath" feature.
2207 AC_DEFUN([CF_LD_RPATH_OPT],
2208 [
2209 AC_REQUIRE([CF_CHECK_CACHE])
2210
2211 LD_RPATH_OPT=
2212 if test "x$cf_cv_enable_rpath" != xno
2213 then
2214         AC_MSG_CHECKING(for an rpath option)
2215         case "$cf_cv_system_name" in
2216         (irix*)
2217                 if test "$GCC" = yes; then
2218                         LD_RPATH_OPT="-Wl,-rpath,"
2219                 else
2220                         LD_RPATH_OPT="-rpath "
2221                 fi
2222                 ;;
2223         (linux*|gnu*|k*bsd*-gnu|freebsd*)
2224                 LD_RPATH_OPT="-Wl,-rpath,"
2225                 ;;
2226         (openbsd[[2-9]].*|mirbsd*)
2227                 LD_RPATH_OPT="-Wl,-rpath,"
2228                 ;;
2229         (dragonfly*)
2230                 LD_RPATH_OPT="-rpath "
2231                 ;;
2232         (netbsd*)
2233                 LD_RPATH_OPT="-Wl,-rpath,"
2234                 ;;
2235         (osf*|mls+*)
2236                 LD_RPATH_OPT="-rpath "
2237                 ;;
2238         (solaris2*)
2239                 LD_RPATH_OPT="-R"
2240                 ;;
2241         (*)
2242                 ;;
2243         esac
2244         AC_MSG_RESULT($LD_RPATH_OPT)
2245
2246         case "x$LD_RPATH_OPT" in
2247         (x-R*)
2248                 AC_MSG_CHECKING(if we need a space after rpath option)
2249                 cf_save_LIBS="$LIBS"
2250                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
2251                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
2252                 LIBS="$cf_save_LIBS"
2253                 AC_MSG_RESULT($cf_rpath_space)
2254                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
2255                 ;;
2256         esac
2257 fi
2258 ])dnl
2259 dnl ---------------------------------------------------------------------------
2260 dnl CF_LIBRARY_PATH version: 11 updated: 2021/01/01 13:31:04
2261 dnl ---------------
2262 dnl Construct a search-list of directories for a nonstandard library-file
2263 dnl
2264 dnl Parameters
2265 dnl     $1 = the variable to return as result
2266 dnl     $2 = the package name
2267 AC_DEFUN([CF_LIBRARY_PATH],
2268 [
2269 $1=
2270 cf_library_path_list=""
2271 if test -n "${LDFLAGS}${LIBS}" ; then
2272         for cf_library_path in $LDFLAGS $LIBS
2273         do
2274                 case "$cf_library_path" in
2275                 (-L*)
2276                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
2277                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
2278                         cf_library_path_list="$cf_library_path_list [$]$1"
2279                         ;;
2280                 esac
2281         done
2282 fi
2283
2284 CF_SUBDIR_PATH($1,$2,lib)
2285
2286 $1="$cf_library_path_list [$]$1"
2287 ])dnl
2288 dnl ---------------------------------------------------------------------------
2289 dnl CF_LIB_PREFIX version: 14 updated: 2021/01/01 13:31:04
2290 dnl -------------
2291 dnl Compute the library-prefix for the given host system
2292 dnl $1 = variable to set
2293 define([CF_LIB_PREFIX],
2294 [
2295         case "$cf_cv_system_name" in
2296         (OS/2*|os2*)
2297                 if test "$DFT_LWR_MODEL" = libtool; then
2298                         LIB_PREFIX='lib'
2299                 else
2300                         LIB_PREFIX=''
2301                 fi
2302                 ;;
2303         (*-msvc*)
2304                 LIB_PREFIX=''
2305                 ;;
2306         (*)     LIB_PREFIX='lib'
2307                 ;;
2308         esac
2309 ifelse($1,,,[$1=$LIB_PREFIX])
2310         AC_SUBST(LIB_PREFIX)
2311 ])dnl
2312 dnl ---------------------------------------------------------------------------
2313 dnl CF_LIB_SUFFIX version: 28 updated: 2021/01/01 16:53:59
2314 dnl -------------
2315 dnl Compute the library file-suffix from the given model name
2316 dnl $1 = model name
2317 dnl $2 = variable to set (the nominal library suffix)
2318 dnl $3 = dependency variable to set (actual filename)
2319 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
2320 AC_DEFUN([CF_LIB_SUFFIX],
2321 [
2322         case X$1 in
2323         (Xlibtool)
2324                 $2='.la'
2325                 $3=[$]$2
2326                 ;;
2327         (Xdebug)
2328                 case "$cf_cv_system_name" in
2329                 (*-msvc*)
2330                         $2='_g.lib'
2331                         ;;
2332                 (*)
2333                         $2='_g.a'
2334                         ;;
2335                 esac
2336                 $3=[$]$2
2337                 ;;
2338         (Xprofile)
2339                 case "$cf_cv_system_name" in
2340                 (*-msvc*)
2341                         $2='_p.lib'
2342                         ;;
2343                 (*)
2344                         $2='_p.a'
2345                         ;;
2346                 esac
2347                 $3=[$]$2
2348                 ;;
2349         (Xshared)
2350                 case "$cf_cv_system_name" in
2351                 (aix[[5-7]]*)
2352                         $2='.so'
2353                         $3=[$]$2
2354                         ;;
2355                 (*-msvc*)
2356                         $2='.dll'
2357                         $3='.dll.lib'
2358                         ;;
2359                 (cygwin*|msys*|mingw*)
2360                         $2='.dll'
2361                         $3='.dll.a'
2362                         ;;
2363                 (darwin*)
2364                         $2='.dylib'
2365                         $3=[$]$2
2366                         ;;
2367                 (hpux*)
2368                         case "$target" in
2369                         (ia64*)
2370                                 $2='.so'
2371                                 $3=[$]$2
2372                                 ;;
2373                         (*)
2374                                 $2='.sl'
2375                                 $3=[$]$2
2376                                 ;;
2377                         esac
2378                         ;;
2379                 (*)
2380                         $2='.so'
2381                         $3=[$]$2
2382                         ;;
2383                 esac
2384                 ;;
2385         (*)
2386                 case "$target" in
2387                 (*-msvc*)
2388                         $2='.lib'
2389                         ;;
2390                 (*)
2391                         $2='.a'
2392                         ;;
2393                 esac
2394                 $3=[$]$2
2395                 ;;
2396         esac
2397         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
2398         then
2399                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
2400                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
2401         fi
2402 ])dnl
2403 dnl ---------------------------------------------------------------------------
2404 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
2405 dnl -----------
2406 dnl Compute the string to append to -library from the given model name
2407 dnl $1 = model name
2408 dnl $2 = variable to set
2409 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
2410 AC_DEFUN([CF_LIB_TYPE],
2411 [
2412         case $1 in
2413         (libtool) $2=''   ;;
2414         (normal)  $2=''   ;;
2415         (debug)   $2='_g' ;;
2416         (profile) $2='_p' ;;
2417         (shared)  $2=''   ;;
2418         esac
2419         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
2420 ])dnl
2421 dnl ---------------------------------------------------------------------------
2422 dnl CF_LINK_DATAONLY version: 13 updated: 2020/02/08 15:59:30
2423 dnl ----------------
2424 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
2425 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
2426 dnl have to provide wrappers for global tables to ensure they're linked
2427 dnl properly.
2428 AC_DEFUN([CF_LINK_DATAONLY],
2429 [
2430 AC_MSG_CHECKING([if data-only library module links])
2431 AC_CACHE_VAL(cf_cv_link_dataonly,[
2432         rm -f conftest.a
2433         cat >conftest.$ac_ext <<EOF
2434 #line __oline__ "configure"
2435 int     testdata[[3]] = { 123, 456, 789 };
2436 EOF
2437         if AC_TRY_EVAL(ac_compile) ; then
2438                 mv conftest.o data.o && \
2439                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
2440         fi
2441         rm -f conftest.$ac_ext data.o
2442         cat >conftest.$ac_ext <<EOF
2443 #line __oline__ "configure"
2444 int     testfunc(void)
2445 {
2446 #if defined(NeXT)
2447         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
2448 #else
2449         extern int testdata[[3]];
2450         return testdata[[0]] == 123
2451            &&  testdata[[1]] == 456
2452            &&  testdata[[2]] == 789;
2453 #endif
2454 }
2455 EOF
2456         if AC_TRY_EVAL(ac_compile); then
2457                 mv conftest.o func.o && \
2458                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
2459         fi
2460         rm -f conftest.$ac_ext func.o
2461         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
2462         cf_saveLIBS="$LIBS"
2463         LIBS="conftest.a $LIBS"
2464         AC_TRY_RUN([
2465         int main(void)
2466         {
2467                 extern int testfunc();
2468                 ${cf_cv_main_return:-return} (!testfunc());
2469         }
2470         ],
2471         [cf_cv_link_dataonly=yes],
2472         [cf_cv_link_dataonly=no],
2473         [cf_cv_link_dataonly=unknown])
2474         LIBS="$cf_saveLIBS"
2475         ])
2476 AC_MSG_RESULT($cf_cv_link_dataonly)
2477
2478 if test "$cf_cv_link_dataonly" = no ; then
2479         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
2480         BROKEN_LINKER=1
2481 fi
2482 AC_SUBST(BROKEN_LINKER)
2483
2484 ])dnl
2485 dnl ---------------------------------------------------------------------------
2486 dnl CF_MAKEFLAGS version: 20 updated: 2021/01/03 19:29:49
2487 dnl ------------
2488 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
2489 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
2490 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
2491 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
2492 AC_DEFUN([CF_MAKEFLAGS],
2493 [AC_REQUIRE([AC_PROG_FGREP])dnl
2494
2495 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
2496         cf_cv_makeflags=''
2497         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
2498         do
2499                 cat >cf_makeflags.tmp <<CF_EOF
2500 SHELL = $SHELL
2501 all :
2502         @ echo '.$cf_option'
2503 CF_EOF
2504                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | ${FGREP-fgrep} -v "ing directory" | sed -e 's,[[  ]]*$,,'`
2505                 case "$cf_result" in
2506                 (.*k|.*kw)
2507                         cf_result="`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`"
2508                         case "$cf_result" in
2509                         (.*CC=*)        cf_cv_makeflags=
2510                                 ;;
2511                         (*)     cf_cv_makeflags=$cf_option
2512                                 ;;
2513                         esac
2514                         break
2515                         ;;
2516                 (.-)
2517                         ;;
2518                 (*)
2519                         CF_MSG_LOG(given option \"$cf_option\", no match \"$cf_result\")
2520                         ;;
2521                 esac
2522         done
2523         rm -f cf_makeflags.tmp
2524 ])
2525
2526 AC_SUBST(cf_cv_makeflags)
2527 ])dnl
2528 dnl ---------------------------------------------------------------------------
2529 dnl CF_MAKE_PHONY version: 3 updated: 2021/01/08 16:08:21
2530 dnl -------------
2531 dnl Check if the make-program handles a ".PHONY" target, e.g,. a target which
2532 dnl acts as a placeholder.
2533 dnl
2534 dnl The ".PHONY" feature was proposed in 2011 here
2535 dnl     https://www.austingroupbugs.net/view.php?id=523
2536 dnl and is scheduled for release in P1003.1 Issue 8 (late 2022).
2537 dnl
2538 dnl This is not supported by SVr4 make (or SunOS 4, 4.3SD, etc), but works with
2539 dnl a few others (i.e., GNU make and the non-POSIX "BSD" make):
2540 dnl
2541 dnl + This is a GNU make feature (since April 1988, but in turn from binutils,
2542 dnl   date unspecified).
2543 dnl
2544 dnl + It was adopted in NetBSD make in June 1995.
2545 dnl
2546 dnl + The other BSD make programs are derived from the NetBSD make (and for
2547 dnl   that reason are not actually different "implementations").
2548 dnl
2549 dnl + Some features of NetBSD make were actually adapted from pmake, which
2550 dnl   began as a modified GNU make starting in 1993.
2551 dnl
2552 dnl + Version 3.8 of the dmake program in January 1992 also implemented this
2553 dnl   GNU make extension, but is less well known than the BSD make.
2554 AC_DEFUN([CF_MAKE_PHONY],[
2555 AC_CACHE_CHECK(for \".PHONY\" make-support, cf_cv_make_PHONY,[
2556         rm -rf conftest*
2557         (
2558                 mkdir conftest || exit 1
2559                 cd conftest
2560                 cat >makefile <<'CF_EOF'
2561 .PHONY: always
2562 DATA=0
2563 always: always.out
2564         @echo "** making [$]@ [$](DATA)"
2565 once: once.out
2566         @echo "** making [$]@ [$](DATA)"
2567 always.out:
2568         @echo "** making [$]@ [$](DATA)"
2569         echo [$](DATA) > [$]@
2570 once.out:
2571         @echo "** making [$]@ [$](DATA)"
2572         echo [$](DATA) > [$]@
2573 CF_EOF
2574                 for cf_data in 1 2 3
2575                 do
2576                         ${MAKE:-make} always DATA=$cf_data
2577                         ${MAKE:-make} once   DATA=$cf_data
2578                         ${MAKE:-make} -t always once
2579                         if test -f always ; then
2580                                 echo "no (case 1)" > ../conftest.tmp
2581                         elif test ! -f always.out ; then
2582                                 echo "no (case 2)" > ../conftest.tmp
2583                         elif test ! -f once.out ; then
2584                                 echo "no (case 3)" > ../conftest.tmp
2585                         elif ! cmp -s always.out once.out ; then
2586                                 echo "no (case 4)" > ../conftest.tmp
2587                                 diff always.out once.out
2588                         else
2589                                 cf_check="`cat always.out`"
2590                                 if test "x$cf_check" != "x$cf_data" ; then
2591                                         echo "no (case 5)" > ../conftest.tmp
2592                                 else
2593                                         echo yes > ../conftest.tmp
2594                                         rm -f ./*.out
2595                                         continue
2596                                 fi
2597                         fi
2598                         break
2599                 done
2600         ) >&AC_FD_CC 2>&1
2601         cf_cv_make_PHONY="`cat conftest.tmp`"
2602         rm -rf conftest*
2603 ])
2604 MAKE_NO_PHONY="#"
2605 MAKE_PHONY="#"
2606 test "x$cf_cv_make_PHONY" = xyes && MAKE_PHONY=
2607 test "x$cf_cv_make_PHONY" != xyes && MAKE_NO_PHONY=
2608 AC_SUBST(MAKE_NO_PHONY)
2609 AC_SUBST(MAKE_PHONY)
2610 ])dnl
2611 dnl ---------------------------------------------------------------------------
2612 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
2613 dnl ------------
2614 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
2615 dnl a monocase filesystem.
2616 AC_DEFUN([CF_MAKE_TAGS],[
2617 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
2618
2619 AC_CHECK_PROGS(CTAGS, exctags ctags)
2620 AC_CHECK_PROGS(ETAGS, exetags etags)
2621
2622 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
2623
2624 if test "$cf_cv_mixedcase" = yes ; then
2625         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
2626 else
2627         MAKE_UPPER_TAGS=no
2628 fi
2629
2630 if test "$MAKE_UPPER_TAGS" = yes ; then
2631         MAKE_UPPER_TAGS=
2632 else
2633         MAKE_UPPER_TAGS="#"
2634 fi
2635
2636 if test "$MAKE_LOWER_TAGS" = yes ; then
2637         MAKE_LOWER_TAGS=
2638 else
2639         MAKE_LOWER_TAGS="#"
2640 fi
2641
2642 AC_SUBST(CTAGS)
2643 AC_SUBST(ETAGS)
2644
2645 AC_SUBST(MAKE_UPPER_TAGS)
2646 AC_SUBST(MAKE_LOWER_TAGS)
2647 ])dnl
2648 dnl ---------------------------------------------------------------------------
2649 dnl CF_MIXEDCASE_FILENAMES version: 9 updated: 2021/01/01 16:53:59
2650 dnl ----------------------
2651 dnl Check if the file-system supports mixed-case filenames.  If we're able to
2652 dnl create a lowercase name and see it as uppercase, it doesn't support that.
2653 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
2654 [
2655 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
2656 if test "$cross_compiling" = yes ; then
2657         case "$target_alias" in
2658         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*|darwin*)
2659                 cf_cv_mixedcase=no
2660                 ;;
2661         (*)
2662                 cf_cv_mixedcase=yes
2663                 ;;
2664         esac
2665 else
2666         rm -f conftest CONFTEST
2667         echo test >conftest
2668         if test -f CONFTEST ; then
2669                 cf_cv_mixedcase=no
2670         else
2671                 cf_cv_mixedcase=yes
2672         fi
2673         rm -f conftest CONFTEST
2674 fi
2675 ])
2676 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
2677 ])dnl
2678 dnl ---------------------------------------------------------------------------
2679 dnl CF_MKSTEMP version: 11 updated: 2021/01/01 13:31:04
2680 dnl ----------
2681 dnl Check for a working mkstemp.  This creates two files, checks that they are
2682 dnl successfully created and distinct (AmigaOS apparently fails on the last).
2683 AC_DEFUN([CF_MKSTEMP],[
2684 AC_CHECK_HEADERS( \
2685 unistd.h \
2686 )
2687 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
2688 rm -rf ./conftest*
2689 AC_TRY_RUN([
2690 #include <sys/types.h>
2691 #ifdef HAVE_UNISTD_H
2692 #include <unistd.h>
2693 #endif
2694 #include <stdlib.h>
2695 #include <stdio.h>
2696 #include <string.h>
2697 #include <sys/stat.h>
2698 int main(void)
2699 {
2700         char *tmpl = "conftestXXXXXX";
2701         char name[2][80];
2702         int n;
2703         int result = 0;
2704         int fd;
2705         struct stat sb;
2706
2707         umask(077);
2708         for (n = 0; n < 2; ++n) {
2709                 strcpy(name[n], tmpl);
2710                 if ((fd = mkstemp(name[n])) >= 0) {
2711                         if (!strcmp(name[n], tmpl)
2712                          || stat(name[n], &sb) != 0
2713                          || (sb.st_mode & S_IFMT) != S_IFREG
2714                          || (sb.st_mode & 077) != 0) {
2715                                 result = 1;
2716                         }
2717                         close(fd);
2718                 }
2719         }
2720         if (result == 0
2721          && !strcmp(name[0], name[1]))
2722                 result = 1;
2723         ${cf_cv_main_return:-return}(result);
2724 }
2725 ],[cf_cv_func_mkstemp=yes
2726 ],[cf_cv_func_mkstemp=no
2727 ],[cf_cv_func_mkstemp=maybe])
2728 ])
2729 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
2730         AC_CHECK_FUNC(mkstemp)
2731 fi
2732 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
2733         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
2734 fi
2735 ])dnl
2736 dnl ---------------------------------------------------------------------------
2737 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2738 dnl ----------
2739 dnl Write a debug message to config.log, along with the line number in the
2740 dnl configure script.
2741 AC_DEFUN([CF_MSG_LOG],[
2742 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2743 ])dnl
2744 dnl ---------------------------------------------------------------------------
2745 dnl CF_NCURSES_ADDON version: 6 updated: 2021/01/04 19:33:05
2746 dnl ----------------
2747 dnl Configure an ncurses add-on, built outside the ncurses tree.
2748 AC_DEFUN([CF_NCURSES_ADDON],[
2749 AC_REQUIRE([CF_NCURSES_CONFIG])
2750
2751 AC_PROVIDE([CF_SUBST_NCURSES_VERSION])
2752
2753 AC_MSG_CHECKING(if you want wide-character code)
2754 AC_ARG_ENABLE(widec,
2755         [  --enable-widec          compile with wide-char/UTF-8 code],
2756         [with_widec=$enableval],
2757         [with_widec=no])
2758 AC_MSG_RESULT($with_widec)
2759 if test "$with_widec" = yes ; then
2760         CF_UTF8_LIB
2761         CF_NCURSES_CONFIG(ncursesw)
2762 else
2763         CF_NCURSES_CONFIG(ncurses)
2764 fi
2765
2766 if test "$NCURSES_CONFIG_PKG" != none ; then
2767         cf_version=`$PKG_CONFIG --modversion $NCURSES_CONFIG_PKG 2>/dev/null`
2768
2769         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2770         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2771         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2772
2773         cf_cv_abi_version=`$PKG_CONFIG --variable=abi_version $NCURSES_CONFIG_PKG 2>/dev/null`
2774         if test -z "$cf_cv_abi_version"
2775         then
2776                 cf_cv_abi_version=`$PKG_CONFIG --variable=major_version $NCURSES_CONFIG_PKG 2>/dev/null`
2777         fi
2778
2779 elif test "$NCURSES_CONFIG" != none ; then
2780
2781         cf_version=`$NCURSES_CONFIG --version 2>/dev/null`
2782
2783         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2784         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2785         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2786
2787         # ABI version is not available from headers
2788         cf_cv_abi_version=`$NCURSES_CONFIG --abi-version 2>/dev/null`
2789
2790 else
2791
2792         for cf_name in MAJOR MINOR PATCH
2793         do
2794         cat >conftest.$ac_ext <<CF_EOF
2795         #include <${cf_cv_ncurses_header:-curses.h}>
2796         AUTOCONF_$cf_name NCURSES_VERSION_$cf_name
2797 CF_EOF
2798                 cf_try="$ac_cpp conftest.$ac_ext 2>&5 | fgrep AUTOCONF_$cf_name >conftest.out"
2799                 AC_TRY_EVAL(cf_try)
2800                 if test -f conftest.out ; then
2801                         cf_result=`sed -e "s/^.*AUTOCONF_${cf_name}[[   ]][[    ]]*//" conftest.out`
2802                         eval NCURSES_$cf_name=\"$cf_result\"
2803                         # cat conftest.$ac_ext
2804                         # cat conftest.out
2805                 fi
2806         done
2807
2808         cf_cv_abi_version=${NCURSES_MAJOR}
2809
2810 fi
2811
2812 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
2813
2814 dnl Show the computed version, for logging
2815 cf_cv_timestamp=`date`
2816
2817 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
2818
2819 dnl We need these values in the generated headers
2820 AC_SUBST(NCURSES_MAJOR)
2821 AC_SUBST(NCURSES_MINOR)
2822 AC_SUBST(NCURSES_PATCH)
2823
2824 dnl We need these values in the generated makefiles
2825 AC_SUBST(cf_cv_rel_version)
2826 AC_SUBST(cf_cv_abi_version)
2827
2828 dnl FIXME - not needed for Ada95
2829 AC_SUBST(cf_cv_builtin_bool)
2830 AC_SUBST(cf_cv_header_stdbool_h)
2831 AC_SUBST(cf_cv_type_of_bool)dnl
2832
2833 ])
2834 dnl ---------------------------------------------------------------------------
2835 dnl CF_NCURSES_CC_CHECK version: 5 updated: 2020/12/31 20:19:42
2836 dnl -------------------
2837 dnl Check if we can compile with ncurses' header file
2838 dnl $1 is the cache variable to set
2839 dnl $2 is the header-file to include
2840 dnl $3 is the root name (ncurses or ncursesw)
2841 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2842         AC_TRY_COMPILE([
2843 ]ifelse($3,ncursesw,[
2844 #define _XOPEN_SOURCE_EXTENDED
2845 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2846 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2847 ])[
2848 #include <$2>],[
2849 #ifdef NCURSES_VERSION
2850 ]ifelse($3,ncursesw,[
2851 #ifndef WACS_BSSB
2852         make an error
2853 #endif
2854 ])[
2855 printf("%s\\n", NCURSES_VERSION);
2856 #else
2857 #ifdef __NCURSES_H
2858 printf("old\\n");
2859 #else
2860         make an error
2861 #endif
2862 #endif
2863         ]
2864         ,[$1=$2]
2865         ,[$1=no])
2866 ])dnl
2867 dnl ---------------------------------------------------------------------------
2868 dnl CF_NCURSES_CONFIG version: 27 updated: 2021/05/19 19:35:25
2869 dnl -----------------
2870 dnl Tie together the configure-script macros for ncurses, preferring these in
2871 dnl order:
2872 dnl a) ".pc" files for pkg-config, using $NCURSES_CONFIG_PKG
2873 dnl b) the "-config" script from ncurses, using $NCURSES_CONFIG
2874 dnl c) just plain libraries
2875 dnl
2876 dnl $1 is the root library name (default: "ncurses")
2877 AC_DEFUN([CF_NCURSES_CONFIG],[
2878 AC_REQUIRE([CF_PKG_CONFIG])
2879 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2880 cf_have_ncuconfig=no
2881
2882 if test "x${PKG_CONFIG:=none}" != xnone; then
2883         AC_MSG_CHECKING(pkg-config for $cf_ncuconfig_root)
2884         if "$PKG_CONFIG" --exists $cf_ncuconfig_root ; then
2885                 AC_MSG_RESULT(yes)
2886
2887                 AC_MSG_CHECKING(if the $cf_ncuconfig_root package files work)
2888                 cf_have_ncuconfig=unknown
2889
2890                 cf_save_CFLAGS="$CFLAGS"
2891                 cf_save_CPPFLAGS="$CPPFLAGS"
2892                 cf_save_LIBS="$LIBS"
2893
2894                 cf_pkg_cflags="`$PKG_CONFIG --cflags $cf_ncuconfig_root`"
2895                 cf_pkg_libs="`$PKG_CONFIG --libs $cf_ncuconfig_root`"
2896
2897                 # while -W for passing linker flags is prevalent, it is not "standard".
2898                 # At least one wrapper for c89/c99 (in Apple's xcode) has its own
2899                 # incompatible _and_ non-standard -W option which gives an error.  Work
2900                 # around that pitfall.
2901                 case "x${CC}@@${cf_pkg_libs}@${cf_pkg_cflags}" in
2902                 (x*c[[89]]9@@*-W*)
2903                         CF_ADD_CFLAGS($cf_pkg_cflags)
2904                         CF_ADD_LIBS($cf_pkg_libs)
2905
2906                         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2907                                 [initscr(); mousemask(0,0); tigetstr((char *)0);],
2908                                 [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2909                                         int main(void)
2910                                         { const char *xx = curses_version(); return (xx == 0); }],
2911                                         [cf_test_ncuconfig=yes],
2912                                         [cf_test_ncuconfig=no],
2913                                         [cf_test_ncuconfig=maybe])],
2914                                 [cf_test_ncuconfig=no])
2915
2916                         CFLAGS="$cf_save_CFLAGS"
2917                         CPPFLAGS="$cf_save_CPPFLAGS"
2918                         LIBS="$cf_save_LIBS"
2919
2920                         if test "x$cf_test_ncuconfig" != xyes; then
2921                                 cf_temp=`echo "x$cf_pkg_cflags" | sed -e s/^x// -e 's/-W[[^     ]]*//g'`
2922                                 cf_pkg_cflags="$cf_temp"
2923                                 cf_temp=`echo "x$cf_pkg_libs" | sed -e s/^x// -e 's/-W[[^       ]]*//g'`
2924                                 cf_pkg_libs="$cf_temp"
2925                         fi
2926                         ;;
2927                 esac
2928
2929                 CF_ADD_CFLAGS($cf_pkg_cflags)
2930                 CF_ADD_LIBS($cf_pkg_libs)
2931
2932                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2933                         [initscr(); mousemask(0,0); tigetstr((char *)0);],
2934                         [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2935                                 int main(void)
2936                                 { const char *xx = curses_version(); return (xx == 0); }],
2937                                 [cf_have_ncuconfig=yes],
2938                                 [cf_have_ncuconfig=no],
2939                                 [cf_have_ncuconfig=maybe])],
2940                         [cf_have_ncuconfig=no])
2941                 AC_MSG_RESULT($cf_have_ncuconfig)
2942                 test "$cf_have_ncuconfig" = maybe && cf_have_ncuconfig=yes
2943                 if test "$cf_have_ncuconfig" != "yes"
2944                 then
2945                         CPPFLAGS="$cf_save_CPPFLAGS"
2946                         LIBS="$cf_save_LIBS"
2947                         NCURSES_CONFIG_PKG=none
2948                 else
2949                         AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2950                         NCURSES_CONFIG_PKG=$cf_ncuconfig_root
2951                         CF_TERM_HEADER
2952                 fi
2953
2954         else
2955                 AC_MSG_RESULT(no)
2956                 NCURSES_CONFIG_PKG=none
2957         fi
2958 else
2959         NCURSES_CONFIG_PKG=none
2960 fi
2961
2962 if test "x$cf_have_ncuconfig" = "xno"; then
2963         cf_ncurses_config="${cf_ncuconfig_root}${NCURSES_CONFIG_SUFFIX}-config"; echo "Looking for ${cf_ncurses_config}"
2964
2965         CF_ACVERSION_CHECK(2.52,
2966                 [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
2967                 [AC_PATH_PROGS(NCURSES_CONFIG,  ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
2968
2969         if test "$NCURSES_CONFIG" != none ; then
2970
2971                 CF_ADD_CFLAGS(`$NCURSES_CONFIG --cflags`)
2972                 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2973
2974                 # even with config script, some packages use no-override for curses.h
2975                 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2976
2977                 dnl like CF_NCURSES_CPPFLAGS
2978                 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2979
2980                 dnl like CF_NCURSES_LIBS
2981                 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2982                 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2983
2984                 dnl like CF_NCURSES_VERSION
2985                 cf_cv_ncurses_version="`$NCURSES_CONFIG --version`"
2986
2987         else
2988
2989                 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2990                 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2991
2992         fi
2993 else
2994         NCURSES_CONFIG=none
2995 fi
2996 ])dnl
2997 dnl ---------------------------------------------------------------------------
2998 dnl CF_NCURSES_CPPFLAGS version: 22 updated: 2021/01/02 09:31:20
2999 dnl -------------------
3000 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
3001 dnl the CPPFLAGS variable so we can include its header.
3002 dnl
3003 dnl The header files may be installed as either curses.h, or ncurses.h (would
3004 dnl be obsolete, except that some packagers prefer this name to distinguish it
3005 dnl from a "native" curses implementation).  If not installed for overwrite,
3006 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
3007 dnl /usr/include/ncurses), but someone may have installed overwriting the
3008 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
3009 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
3010 dnl the header.
3011 dnl
3012 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
3013 dnl is already in the include-path, don't even bother with this, since we cannot
3014 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
3015 dnl
3016 dnl The optional parameter gives the root name of the library, in case it is
3017 dnl not installed as the default curses library.  That is how the
3018 dnl wide-character version of ncurses is installed.
3019 AC_DEFUN([CF_NCURSES_CPPFLAGS],
3020 [AC_REQUIRE([CF_WITH_CURSES_DIR])
3021
3022 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
3023 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
3024
3025 test -n "$cf_cv_curses_dir" && \
3026 test "$cf_cv_curses_dir" != "no" && { \
3027   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
3028 }
3029
3030 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
3031         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
3032         { test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw; } && cf_header_list="$cf_header_list curses.h ncurses.h"
3033         for cf_header in $cf_header_list
3034         do
3035                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
3036                 test "$cf_cv_ncurses_h" != no && break
3037         done
3038 ])
3039
3040 CF_NCURSES_HEADER
3041 CF_TERM_HEADER
3042
3043 # some applications need this, but should check for NCURSES_VERSION
3044 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
3045
3046 CF_NCURSES_VERSION
3047 ])dnl
3048 dnl ---------------------------------------------------------------------------
3049 dnl CF_NCURSES_HEADER version: 7 updated: 2021/01/04 19:33:05
3050 dnl -----------------
3051 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
3052 dnl variations of ncurses' installs.
3053 dnl
3054 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
3055 AC_DEFUN([CF_NCURSES_HEADER],[
3056
3057 if test "$cf_cv_ncurses_h" != no ; then
3058         cf_cv_ncurses_header=$cf_cv_ncurses_h
3059 else
3060
3061 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
3062         test -n "$verbose" && echo
3063         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
3064         test -n "$verbose" && echo "search path $cf_search"
3065         cf_save2_CPPFLAGS="$CPPFLAGS"
3066         for cf_incdir in $cf_search
3067         do
3068                 CF_ADD_INCDIR($cf_incdir)
3069                 for cf_header in \
3070                         ncurses.h \
3071                         curses.h
3072                 do
3073                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
3074                         if test "$cf_cv_ncurses_h2" != no ; then
3075                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
3076                                 test -n "$verbose" && echo $ECHO_N "    ... found $ECHO_C" 1>&AC_FD_MSG
3077                                 break
3078                         fi
3079                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
3080                 done
3081                 CPPFLAGS="$cf_save2_CPPFLAGS"
3082                 test "$cf_cv_ncurses_h2" != no && break
3083         done
3084         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
3085         ])
3086
3087         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
3088         cf_cv_ncurses_header="`basename "$cf_cv_ncurses_h2"`"
3089         if test "`basename "$cf_1st_incdir"`" = "$cf_ncuhdr_root" ; then
3090                 cf_cv_ncurses_header="$cf_ncuhdr_root/$cf_cv_ncurses_header"
3091         fi
3092         CF_ADD_INCDIR($cf_1st_incdir)
3093
3094 fi
3095
3096 # Set definitions to allow ifdef'ing for ncurses.h
3097
3098 case "$cf_cv_ncurses_header" in
3099 (*ncurses.h)
3100         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
3101         ;;
3102 esac
3103
3104 case "$cf_cv_ncurses_header" in
3105 (ncurses/curses.h|ncurses/ncurses.h)
3106         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
3107         ;;
3108 (ncursesw/curses.h|ncursesw/ncurses.h)
3109         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
3110         ;;
3111 esac
3112
3113 ])dnl
3114 dnl ---------------------------------------------------------------------------
3115 dnl CF_NCURSES_LIBS version: 20 updated: 2021/01/03 08:05:37
3116 dnl ---------------
3117 dnl Look for the ncurses library.  This is a little complicated on Linux,
3118 dnl because it may be linked with the gpm (general purpose mouse) library.
3119 dnl Some distributions have gpm linked with (bsd) curses, which makes it
3120 dnl unusable with ncurses.  However, we don't want to link with gpm unless
3121 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
3122 dnl and the linker will record a dependency.
3123 dnl
3124 dnl The optional parameter gives the root name of the library, in case it is
3125 dnl not installed as the default curses library.  That is how the
3126 dnl wide-character version of ncurses is installed.
3127 AC_DEFUN([CF_NCURSES_LIBS],
3128 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
3129
3130 cf_nculib_root=ifelse($1,,ncurses,$1)
3131         # This works, except for the special case where we find gpm, but
3132         # ncurses is in a nonstandard location via $LIBS, and we really want
3133         # to link gpm.
3134 cf_ncurses_LIBS=""
3135 cf_ncurses_SAVE="$LIBS"
3136 AC_CHECK_LIB(gpm,Gpm_Open,
3137         [AC_CHECK_LIB(gpm,initscr,
3138                 [LIBS="$cf_ncurses_SAVE"],
3139                 [cf_ncurses_LIBS="-lgpm"])])
3140
3141 case "$host_os" in
3142 (freebsd*)
3143         # This is only necessary if you are linking against an obsolete
3144         # version of ncurses (but it should do no harm, since it's static).
3145         if test "$cf_nculib_root" = ncurses ; then
3146                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
3147         fi
3148         ;;
3149 esac
3150
3151 CF_ADD_LIBS($cf_ncurses_LIBS)
3152
3153 if test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no"
3154 then
3155         CF_ADD_LIBS(-l$cf_nculib_root)
3156 else
3157         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
3158                 [#include <${cf_cv_ncurses_header:-curses.h}>],
3159                 [initscr()],
3160                 initscr)
3161 fi
3162
3163 if test -n "$cf_ncurses_LIBS" ; then
3164         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
3165         cf_ncurses_SAVE="$LIBS"
3166         for p in $cf_ncurses_LIBS ; do
3167                 q=`echo "$LIBS" | sed -e "s%$p %%" -e "s%$p$%%"`
3168                 if test "$q" != "$LIBS" ; then
3169                         LIBS="$q"
3170                 fi
3171         done
3172         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
3173                 [initscr(); mousemask(0,0); tigetstr((char *)0);],
3174                 [AC_MSG_RESULT(yes)],
3175                 [AC_MSG_RESULT(no)
3176                  LIBS="$cf_ncurses_SAVE"])
3177 fi
3178
3179 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
3180 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
3181 ])dnl
3182 dnl ---------------------------------------------------------------------------
3183 dnl CF_NCURSES_VERSION version: 16 updated: 2020/12/31 20:19:42
3184 dnl ------------------
3185 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
3186 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
3187 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
3188 AC_DEFUN([CF_NCURSES_VERSION],
3189 [
3190 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
3191 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
3192         cf_cv_ncurses_version=no
3193         cf_tempfile=out$$
3194         rm -f "$cf_tempfile"
3195         AC_TRY_RUN([
3196 #include <${cf_cv_ncurses_header:-curses.h}>
3197 #include <stdio.h>
3198 int main(void)
3199 {
3200         FILE *fp = fopen("$cf_tempfile", "w");
3201 #ifdef NCURSES_VERSION
3202 # ifdef NCURSES_VERSION_PATCH
3203         fprintf(fp, "%s.%d\\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
3204 # else
3205         fprintf(fp, "%s\\n", NCURSES_VERSION);
3206 # endif
3207 #else
3208 # ifdef __NCURSES_H
3209         fprintf(fp, "old\\n");
3210 # else
3211         make an error
3212 # endif
3213 #endif
3214         ${cf_cv_main_return:-return}(0);
3215 }],[
3216         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
3217
3218         # This will not work if the preprocessor splits the line after the
3219         # Autoconf token.  The 'unproto' program does that.
3220         cat > "conftest.$ac_ext" <<EOF
3221 #include <${cf_cv_ncurses_header:-curses.h}>
3222 #undef Autoconf
3223 #ifdef NCURSES_VERSION
3224 Autoconf NCURSES_VERSION
3225 #else
3226 #ifdef __NCURSES_H
3227 Autoconf "old"
3228 #endif
3229 ;
3230 #endif
3231 EOF
3232         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
3233         AC_TRY_EVAL(cf_try)
3234         if test -f conftest.out ; then
3235                 cf_out=`sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%' conftest.out`
3236                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
3237                 rm -f conftest.out
3238         fi
3239 ])
3240         rm -f "$cf_tempfile"
3241 ])
3242 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
3243 ])dnl
3244 dnl ---------------------------------------------------------------------------
3245 dnl CF_OBJ_SUBDIR version: 8 updated: 2021/01/01 13:31:04
3246 dnl -------------
3247 dnl Compute the object-directory name from the given model name
3248 AC_DEFUN([CF_OBJ_SUBDIR],
3249 [
3250         case $1 in
3251         (libtool) $2='obj_lo'  ;;
3252         (normal)  $2='objects' ;;
3253         (debug)   $2='obj_g' ;;
3254         (profile) $2='obj_p' ;;
3255         (shared)
3256                 case "$cf_cv_system_name" in
3257                 (cygwin|msys)
3258                         $2='objects' ;;
3259                 (*)
3260                         $2='obj_s' ;;
3261                 esac
3262         esac
3263 ])dnl
3264 dnl ---------------------------------------------------------------------------
3265 dnl CF_PATHSEP version: 8 updated: 2021/01/01 13:31:04
3266 dnl ----------
3267 dnl Provide a value for the $PATH and similar separator (or amend the value
3268 dnl as provided in autoconf 2.5x).
3269 AC_DEFUN([CF_PATHSEP],
3270 [
3271         AC_MSG_CHECKING(for PATH separator)
3272         case "$cf_cv_system_name" in
3273         (os2*)  PATH_SEPARATOR=';'  ;;
3274         (*)     ${PATH_SEPARATOR:=':'}  ;;
3275         esac
3276 ifelse([$1],,,[$1=$PATH_SEPARATOR])
3277         AC_SUBST(PATH_SEPARATOR)
3278         AC_MSG_RESULT($PATH_SEPARATOR)
3279 ])dnl
3280 dnl ---------------------------------------------------------------------------
3281 dnl CF_PATH_SYNTAX version: 18 updated: 2020/12/31 18:40:20
3282 dnl --------------
3283 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
3284 dnl begins with one of the prefix/exec_prefix variables, and then again if the
3285 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
3286 dnl delayed evaluation of those symbols.
3287 AC_DEFUN([CF_PATH_SYNTAX],[
3288 if test "x$prefix" != xNONE; then
3289         cf_path_syntax="$prefix"
3290 else
3291         cf_path_syntax="$ac_default_prefix"
3292 fi
3293
3294 case ".[$]$1" in
3295 (.\[$]\(*\)*|.\'*\'*)
3296         ;;
3297 (..|./*|.\\*)
3298         ;;
3299 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
3300         ;;
3301 (.\[$]\{*prefix\}*|.\[$]\{*dir\}*)
3302         eval $1="[$]$1"
3303         case ".[$]$1" in
3304         (.NONE/*)
3305                 $1=`echo "[$]$1" | sed -e s%NONE%$cf_path_syntax%`
3306                 ;;
3307         esac
3308         ;;
3309 (.no|.NONE/*)
3310         $1=`echo "[$]$1" | sed -e s%NONE%$cf_path_syntax%`
3311         ;;
3312 (*)
3313         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
3314         ;;
3315 esac
3316 ])dnl
3317 dnl ---------------------------------------------------------------------------
3318 dnl CF_PKG_CONFIG version: 11 updated: 2021/01/01 13:31:04
3319 dnl -------------
3320 dnl Check for the package-config program, unless disabled by command-line.
3321 AC_DEFUN([CF_PKG_CONFIG],
3322 [
3323 AC_MSG_CHECKING(if you want to use pkg-config)
3324 AC_ARG_WITH(pkg-config,
3325         [  --with-pkg-config{=path} enable/disable use of pkg-config],
3326         [cf_pkg_config=$withval],
3327         [cf_pkg_config=yes])
3328 AC_MSG_RESULT($cf_pkg_config)
3329
3330 case "$cf_pkg_config" in
3331 (no)
3332         PKG_CONFIG=none
3333         ;;
3334 (yes)
3335         CF_ACVERSION_CHECK(2.52,
3336                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
3337                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
3338         ;;
3339 (*)
3340         PKG_CONFIG=$withval
3341         ;;
3342 esac
3343
3344 test -z "$PKG_CONFIG" && PKG_CONFIG=none
3345 if test "$PKG_CONFIG" != none ; then
3346         CF_PATH_SYNTAX(PKG_CONFIG)
3347 elif test "x$cf_pkg_config" != xno ; then
3348         AC_MSG_WARN(pkg-config is not installed)
3349 fi
3350
3351 AC_SUBST(PKG_CONFIG)
3352 ])dnl
3353 dnl ---------------------------------------------------------------------------
3354 dnl CF_POSIX_C_SOURCE version: 11 updated: 2018/12/31 20:46:17
3355 dnl -----------------
3356 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
3357 dnl
3358 dnl     POSIX.1-1990                            _POSIX_SOURCE
3359 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
3360 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
3361 dnl             Bindings Option
3362 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
3363 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
3364 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
3365 dnl
3366 dnl Parameters:
3367 dnl     $1 is the nominal value for _POSIX_C_SOURCE
3368 AC_DEFUN([CF_POSIX_C_SOURCE],
3369 [AC_REQUIRE([CF_POSIX_VISIBLE])dnl
3370
3371 if test "$cf_cv_posix_visible" = no; then
3372
3373 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
3374
3375 cf_save_CFLAGS="$CFLAGS"
3376 cf_save_CPPFLAGS="$CPPFLAGS"
3377
3378 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
3379 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
3380
3381 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
3382         CF_MSG_LOG(if the symbol is already defined go no further)
3383         AC_TRY_COMPILE([#include <sys/types.h>],[
3384 #ifndef _POSIX_C_SOURCE
3385 make an error
3386 #endif],
3387         [cf_cv_posix_c_source=no],
3388         [cf_want_posix_source=no
3389          case .$cf_POSIX_C_SOURCE in
3390          (.[[12]]??*)
3391                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
3392                 ;;
3393          (.2)
3394                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
3395                 cf_want_posix_source=yes
3396                 ;;
3397          (.*)
3398                 cf_want_posix_source=yes
3399                 ;;
3400          esac
3401          if test "$cf_want_posix_source" = yes ; then
3402                 AC_TRY_COMPILE([#include <sys/types.h>],[
3403 #ifdef _POSIX_SOURCE
3404 make an error
3405 #endif],[],
3406                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
3407          fi
3408          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
3409          CFLAGS="$cf_trim_CFLAGS"
3410          CPPFLAGS="$cf_trim_CPPFLAGS"
3411          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
3412          CF_MSG_LOG(if the second compile does not leave our definition intact error)
3413          AC_TRY_COMPILE([#include <sys/types.h>],[
3414 #ifndef _POSIX_C_SOURCE
3415 make an error
3416 #endif],,
3417          [cf_cv_posix_c_source=no])
3418          CFLAGS="$cf_save_CFLAGS"
3419          CPPFLAGS="$cf_save_CPPFLAGS"
3420         ])
3421 ])
3422
3423 if test "$cf_cv_posix_c_source" != no ; then
3424         CFLAGS="$cf_trim_CFLAGS"
3425         CPPFLAGS="$cf_trim_CPPFLAGS"
3426         CF_ADD_CFLAGS($cf_cv_posix_c_source)
3427 fi
3428
3429 fi # cf_cv_posix_visible
3430
3431 ])dnl
3432 dnl ---------------------------------------------------------------------------
3433 dnl CF_POSIX_VISIBLE version: 1 updated: 2018/12/31 20:46:17
3434 dnl ----------------
3435 dnl POSIX documents test-macros which an application may set before any system
3436 dnl headers are included to make features available.
3437 dnl
3438 dnl Some BSD platforms (originally FreeBSD, but copied by a few others)
3439 dnl diverged from POSIX in 2002 by setting symbols which make all of the most
3440 dnl recent features visible in the system header files unless the application
3441 dnl overrides the corresponding test-macros.  Doing that introduces portability
3442 dnl problems.
3443 dnl
3444 dnl This macro makes a special check for the symbols used for this, to avoid a
3445 dnl conflicting definition.
3446 AC_DEFUN([CF_POSIX_VISIBLE],
3447 [
3448 AC_CACHE_CHECK(if the POSIX test-macros are already defined,cf_cv_posix_visible,[
3449 AC_TRY_COMPILE([#include <stdio.h>],[
3450 #if defined(__POSIX_VISIBLE) && ((__POSIX_VISIBLE - 0L) > 0) \
3451         && defined(__XSI_VISIBLE) && ((__XSI_VISIBLE - 0L) > 0) \
3452         && defined(__BSD_VISIBLE) && ((__BSD_VISIBLE - 0L) > 0) \
3453         && defined(__ISO_C_VISIBLE) && ((__ISO_C_VISIBLE - 0L) > 0)
3454 #error conflicting symbols found
3455 #endif
3456 ],[cf_cv_posix_visible=no],[cf_cv_posix_visible=yes])
3457 ])
3458 ])dnl
3459 dnl ---------------------------------------------------------------------------
3460 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
3461 dnl ----------
3462 dnl Check for archiver "ar".
3463 AC_DEFUN([CF_PROG_AR],[
3464 AC_CHECK_TOOL(AR, ar, ar)
3465 ])
3466 dnl ---------------------------------------------------------------------------
3467 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
3468 dnl -----------
3469 dnl Check for awk, ensure that the check found something.
3470 AC_DEFUN([CF_PROG_AWK],
3471 [
3472 AC_PROG_AWK
3473 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
3474 ])dnl
3475 dnl ---------------------------------------------------------------------------
3476 dnl CF_PROG_CC version: 5 updated: 2019/12/31 08:53:54
3477 dnl ----------
3478 dnl standard check for CC, plus followup sanity checks
3479 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
3480 AC_DEFUN([CF_PROG_CC],[
3481 CF_ACVERSION_CHECK(2.53,
3482         [AC_MSG_WARN(this will incorrectly handle gnatgcc choice)
3483          AC_REQUIRE([AC_PROG_CC])],
3484         [])
3485 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
3486 CF_GCC_VERSION
3487 CF_ACVERSION_CHECK(2.52,
3488         [AC_PROG_CC_STDC],
3489         [CF_ANSI_CC_REQD])
3490 CF_CC_ENV_FLAGS
3491 ])dnl
3492 dnl ---------------------------------------------------------------------------
3493 dnl CF_PROG_CC_C_O version: 6 updated: 2021/01/01 13:31:04
3494 dnl --------------
3495 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
3496 dnl the output file can be renamed, and allows for a shell variable that can
3497 dnl be used later.  The parameter is either CC or CXX.  The result is the
3498 dnl cache variable:
3499 dnl     $cf_cv_prog_CC_c_o
3500 dnl     $cf_cv_prog_CXX_c_o
3501 dnl
3502 dnl $1 = compiler
3503 dnl $2 = compiler options, if any
3504 AC_DEFUN([CF_PROG_CC_C_O],
3505 [AC_REQUIRE([AC_PROG_CC])dnl
3506 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
3507 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
3508 [
3509 cat > conftest.$ac_ext <<CF_EOF
3510 int main(void)
3511 {
3512         ${cf_cv_main_return:-return}(0);
3513 }
3514 CF_EOF
3515 # We do the test twice because some compilers refuse to overwrite an
3516 # existing .o file with -o, though they will create one.
3517 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
3518 if AC_TRY_EVAL(ac_try) &&
3519   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
3520 then
3521   eval cf_cv_prog_$1_c_o=yes
3522 else
3523   eval cf_cv_prog_$1_c_o=no
3524 fi
3525 rm -rf ./conftest*
3526 ])dnl
3527 if test "$cf_cv_prog_$1_c_o" = yes; then
3528   AC_MSG_RESULT([yes])
3529 else
3530   AC_MSG_RESULT([no])
3531 fi
3532 ])dnl
3533 dnl ---------------------------------------------------------------------------
3534 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
3535 dnl -------------
3536 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
3537 dnl This macro adds a check to ensure the script found something.
3538 AC_DEFUN([CF_PROG_EGREP],
3539 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
3540         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
3541                 then ac_cv_prog_egrep='grep -E'
3542                 else ac_cv_prog_egrep='egrep'
3543         fi])
3544         EGREP=$ac_cv_prog_egrep
3545         AC_SUBST([EGREP])
3546         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
3547 ])dnl
3548 dnl ---------------------------------------------------------------------------
3549 dnl CF_PROG_EXT version: 15 updated: 2021/01/02 09:31:20
3550 dnl -----------
3551 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
3552 AC_DEFUN([CF_PROG_EXT],
3553 [
3554 AC_REQUIRE([CF_CHECK_CACHE])
3555 case "$cf_cv_system_name" in
3556 (os2*)
3557         CFLAGS="$CFLAGS -Zmt"
3558         CF_APPEND_TEXT(CPPFLAGS,-D__ST_MT_ERRNO__)
3559         CXXFLAGS="$CXXFLAGS -Zmt"
3560         # autoconf's macro sets -Zexe and suffix both, which conflict:w
3561         LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
3562         ac_cv_exeext=.exe
3563         ;;
3564 esac
3565
3566 AC_EXEEXT
3567 AC_OBJEXT
3568
3569 PROG_EXT="$EXEEXT"
3570 AC_SUBST(PROG_EXT)
3571 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT",[Define to the program extension (normally blank)])
3572 ])dnl
3573 dnl ---------------------------------------------------------------------------
3574 dnl CF_PROG_GNAT version: 12 updated: 2021/01/02 17:09:14
3575 dnl ------------
3576 dnl Check for gnat/gnatmake/etc, ensure that the toolset is complete.
3577 AC_DEFUN([CF_PROG_GNAT],[
3578 for cf_prog_gnat in gnat gnatmake gprconfig gprbuild
3579 do
3580         CF_UPPER(cf_upper_prog_gnat,${cf_prog_gnat})
3581
3582         unset ac_cv_path_cf_TEMP_gnat
3583         unset cf_TEMP_gnat
3584         AC_PATH_PROG(cf_TEMP_gnat,$cf_prog_gnat,no)
3585         eval "cf_cv_PATH_$cf_upper_prog_gnat=[$]ac_cv_path_cf_TEMP_gnat"
3586
3587         if test "x$cf_TEMP_gnat" != xno; then
3588                 unset cf_cv_gnat_version
3589                 unset cf_TEMP_gnat
3590                 CF_GNAT_VERSION(cf_TEMP_gnat,$cf_prog_gnat)
3591         fi
3592         eval "cf_cv_VERSION_$cf_upper_prog_gnat=[$]cf_TEMP_gnat"
3593
3594         unset cf_TEMP_gnat
3595         unset cf_cv_gnat_version
3596         unset ac_cv_path_cf_TEMP_gnat
3597 done
3598
3599 if test "x$cf_cv_VERSION_GNATMAKE" = "xno"; then
3600         cf_ada_make=
3601         cf_cv_prog_gnat_correct=no
3602 else
3603         cf_ada_make=gnatmake
3604         if test "x$cf_cv_VERSION_GPRCONFIG" = "xno"; then
3605                 # gprconfig is newer than gnatmake; we can continue...
3606                 cf_ada_config="##"
3607         else
3608                 rm -rf ./conftest* ./*~conftest*
3609                 if mkdir conftest.src
3610                 then
3611                         cf_ada_config=""
3612                         cd conftest.src
3613                         for cf_gprconfig in Ada C
3614                         do
3615