ncurses 6.2 - patch 20200222
[ncurses.git] / Ada95 / aclocal.m4
1 dnl***************************************************************************
2 dnl Copyright 2018-2019,2020 Thomas E. Dickey                                *
3 dnl Copyright 2010-2017,2018 Free Software Foundation, Inc.                  *
4 dnl                                                                          *
5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
6 dnl copy of this software and associated documentation files (the            *
7 dnl "Software"), to deal in the Software without restriction, including      *
8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
10 dnl copies of the Software, and to permit persons to whom the Software is    *
11 dnl furnished to do so, subject to the following conditions:                 *
12 dnl                                                                          *
13 dnl The above copyright notice and this permission notice shall be included  *
14 dnl in all copies or substantial portions of the Software.                   *
15 dnl                                                                          *
16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
23 dnl                                                                          *
24 dnl Except as contained in this notice, the name(s) of the above copyright   *
25 dnl holders shall not be used in advertising or otherwise to promote the     *
26 dnl sale, use or other dealings in this Software without prior written       *
27 dnl authorization.                                                           *
28 dnl***************************************************************************
29 dnl
30 dnl Author: Thomas E. Dickey
31 dnl
32 dnl $Id: aclocal.m4,v 1.153 2020/02/08 21:04:00 tom Exp $
33 dnl Macros used in NCURSES Ada95 auto-configuration script.
34 dnl
35 dnl These macros are maintained separately from NCURSES.  The copyright on
36 dnl this file applies to the aggregation of macros and does not affect use of
37 dnl these macros in other applications.
38 dnl
39 dnl See these pages for additional information:
40 dnl             https://invisible-island.net/autoconf/
41 dnl             https://invisible-island.net/autoconf/my-autoconf.html
42 dnl
43 dnl ---------------------------------------------------------------------------
44 dnl ---------------------------------------------------------------------------
45 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
46 dnl ------------------
47 dnl Conditionally generate script according to whether we're using a given autoconf.
48 dnl
49 dnl $1 = version to compare against
50 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
51 dnl $3 = code to use if AC_ACVERSION is older than $1.
52 define([CF_ACVERSION_CHECK],
53 [
54 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
55 ifdef([m4_version_compare],
56 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
57 [CF_ACVERSION_COMPARE(
58 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
59 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
60 dnl ---------------------------------------------------------------------------
61 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
62 dnl --------------------
63 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
64 dnl                      MAJOR2, MINOR2, TERNARY2,
65 dnl                      PRINTABLE2, not FOUND, FOUND)
66 define([CF_ACVERSION_COMPARE],
67 [ifelse(builtin([eval], [$2 < $5]), 1,
68 [ifelse([$8], , ,[$8])],
69 [ifelse([$9], , ,[$9])])])dnl
70 dnl ---------------------------------------------------------------------------
71 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
72 dnl -------------------
73 dnl Construct the list of include-options for the C programs in the Ada95
74 dnl binding.
75 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
76 [
77 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
78 if test "$srcdir" != "."; then
79         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
80 fi
81 if test "$GCC" != yes; then
82         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
83 elif test "$includedir" != "/usr/include"; then
84         if test "$includedir" = '${prefix}/include' ; then
85                 if test x$prefix != x/usr ; then
86                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
87                 fi
88         else
89                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
90         fi
91 fi
92 AC_SUBST(ACPPFLAGS)
93 ])dnl
94 dnl ---------------------------------------------------------------------------
95 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
96 dnl ---------------
97 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
98 AC_DEFUN([CF_ADD_ADAFLAGS],[
99         ADAFLAGS="$ADAFLAGS $1"
100         AC_SUBST(ADAFLAGS)
101 ])dnl
102 dnl ---------------------------------------------------------------------------
103 dnl CF_ADD_CFLAGS version: 13 updated: 2017/02/25 18:57:40
104 dnl -------------
105 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
106 dnl The second parameter if given makes this macro verbose.
107 dnl
108 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
109 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
110 dnl confused by the quotes (which require backslashes to keep them usable).
111 AC_DEFUN([CF_ADD_CFLAGS],
112 [
113 cf_fix_cppflags=no
114 cf_new_cflags=
115 cf_new_cppflags=
116 cf_new_extra_cppflags=
117
118 for cf_add_cflags in $1
119 do
120 case $cf_fix_cppflags in
121 (no)
122         case $cf_add_cflags in
123         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
124                 case $cf_add_cflags in
125                 (-D*)
126                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
127
128                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
129                                 && test -z "${cf_tst_cflags}" \
130                                 && cf_fix_cppflags=yes
131
132                         if test $cf_fix_cppflags = yes ; then
133                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
134                                 continue
135                         elif test "${cf_tst_cflags}" = "\"'" ; then
136                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
137                                 continue
138                         fi
139                         ;;
140                 esac
141                 case "$CPPFLAGS" in
142                 (*$cf_add_cflags)
143                         ;;
144                 (*)
145                         case $cf_add_cflags in
146                         (-D*)
147                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
148                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
149                                 ;;
150                         esac
151                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
152                         ;;
153                 esac
154                 ;;
155         (*)
156                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
157                 ;;
158         esac
159         ;;
160 (yes)
161         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
162
163         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
164
165         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
166                 && test -z "${cf_tst_cflags}" \
167                 && cf_fix_cppflags=no
168         ;;
169 esac
170 done
171
172 if test -n "$cf_new_cflags" ; then
173         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
174         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
175 fi
176
177 if test -n "$cf_new_cppflags" ; then
178         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
179         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
180 fi
181
182 if test -n "$cf_new_extra_cppflags" ; then
183         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
184         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
185 fi
186
187 AC_SUBST(EXTRA_CPPFLAGS)
188
189 ])dnl
190 dnl ---------------------------------------------------------------------------
191 dnl CF_ADD_INCDIR version: 15 updated: 2018/06/20 20:23:13
192 dnl -------------
193 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
194 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
195 dnl but old versions (and some misinstalled ones) need that.  To make things
196 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
197 dnl the include-path).
198 AC_DEFUN([CF_ADD_INCDIR],
199 [
200 if test -n "$1" ; then
201   for cf_add_incdir in $1
202   do
203         while test $cf_add_incdir != /usr/include
204         do
205           if test -d $cf_add_incdir
206           then
207                 cf_have_incdir=no
208                 if test -n "$CFLAGS$CPPFLAGS" ; then
209                   # a loop is needed to ensure we can add subdirs of existing dirs
210                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
211                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
212                           cf_have_incdir=yes; break
213                         fi
214                   done
215                 fi
216
217                 if test "$cf_have_incdir" = no ; then
218                   if test "$cf_add_incdir" = /usr/local/include ; then
219                         if test "$GCC" = yes
220                         then
221                           cf_save_CPPFLAGS=$CPPFLAGS
222                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
223                           AC_TRY_COMPILE([#include <stdio.h>],
224                                   [printf("Hello")],
225                                   [],
226                                   [cf_have_incdir=yes])
227                           CPPFLAGS=$cf_save_CPPFLAGS
228                         fi
229                   fi
230                 fi
231
232                 if test "$cf_have_incdir" = no ; then
233                   CF_VERBOSE(adding $cf_add_incdir to include-path)
234                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
235
236                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
237                   test "$cf_top_incdir" = "$cf_add_incdir" && break
238                   cf_add_incdir="$cf_top_incdir"
239                 else
240                   break
241                 fi
242           else
243                 break
244           fi
245         done
246   done
247 fi
248 ])dnl
249 dnl ---------------------------------------------------------------------------
250 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
251 dnl ----------
252 dnl Add a library, used to enforce consistency.
253 dnl
254 dnl $1 = library to add, without the "-l"
255 dnl $2 = variable to update (default $LIBS)
256 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
257 dnl ---------------------------------------------------------------------------
258 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
259 dnl -------------
260 dnl     Adds to the library-path
261 dnl
262 dnl     Some machines have trouble with multiple -L options.
263 dnl
264 dnl $1 is the (list of) directory(s) to add
265 dnl $2 is the optional name of the variable to update (default LDFLAGS)
266 dnl
267 AC_DEFUN([CF_ADD_LIBDIR],
268 [
269 if test -n "$1" ; then
270         for cf_add_libdir in $1
271         do
272                 if test $cf_add_libdir = /usr/lib ; then
273                         :
274                 elif test -d $cf_add_libdir
275                 then
276                         cf_have_libdir=no
277                         if test -n "$LDFLAGS$LIBS" ; then
278                                 # a loop is needed to ensure we can add subdirs of existing dirs
279                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
280                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
281                                                 cf_have_libdir=yes; break
282                                         fi
283                                 done
284                         fi
285                         if test "$cf_have_libdir" = no ; then
286                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
287                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
288                         fi
289                 fi
290         done
291 fi
292 ])dnl
293 dnl ---------------------------------------------------------------------------
294 dnl CF_ADD_LIBS version: 3 updated: 2019/11/02 16:47:33
295 dnl -----------
296 dnl Add one or more libraries, used to enforce consistency.  Libraries are
297 dnl prepended to an existing list, since their dependencies are assumed to
298 dnl already exist in the list.
299 dnl
300 dnl $1 = libraries to add, with the "-l", etc.
301 dnl $2 = variable to update (default $LIBS)
302 AC_DEFUN([CF_ADD_LIBS],[
303 cf_add_libs="[$]ifelse($2,,LIBS,[$2])"
304 # reverse order
305 cf_add_0lib=
306 for cf_add_1lib in $1; do cf_add_0lib="$cf_add_1lib $cf_add_0lib"; done
307 # filter duplicates
308 for cf_add_1lib in $cf_add_0lib; do
309         for cf_add_2lib in $cf_add_libs; do
310                 if test "x$cf_add_1lib" = "x$cf_add_2lib"; then
311                         cf_add_1lib=
312                         break
313                 fi
314         done
315         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_1lib $cf_add_libs"
316 done
317 ifelse($2,,LIBS,[$2])="$cf_add_libs"
318 ])dnl
319 dnl ---------------------------------------------------------------------------
320 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
321 dnl ------------------
322 dnl Append to a search-list for a nonstandard header/lib-file
323 dnl     $1 = the variable to return as result
324 dnl     $2 = the package name
325 dnl     $3 = the subdirectory, e.g., bin, include or lib
326 dnl $4 = the directory under which we will test for subdirectories
327 dnl $5 = a directory that we do not want $4 to match
328 AC_DEFUN([CF_ADD_SUBDIR_PATH],
329 [
330 test "x$4" != "x$5" && \
331 test -d "$4" && \
332 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
333         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
334         test -d $4/$3 &&          $1="[$]$1 $4/$3"
335         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
336         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
337         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
338         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
339 }
340 ])dnl
341 dnl ---------------------------------------------------------------------------
342 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
343 dnl --------------
344 dnl use this macro for appending text without introducing an extra blank at
345 dnl the beginning
346 define([CF_APPEND_TEXT],
347 [
348         test -n "[$]$1" && $1="[$]$1 "
349         $1="[$]{$1}$2"
350 ])dnl
351 dnl ---------------------------------------------------------------------------
352 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
353 dnl --------------
354 dnl Allow user to disable a normally-on option.
355 AC_DEFUN([CF_ARG_DISABLE],
356 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
357 dnl ---------------------------------------------------------------------------
358 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
359 dnl -------------
360 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
361 dnl values.
362 dnl
363 dnl Parameters:
364 dnl $1 = option name
365 dnl $2 = help-string
366 dnl $3 = action to perform if option is not default
367 dnl $4 = action if perform if option is default
368 dnl $5 = default option value (either 'yes' or 'no')
369 AC_DEFUN([CF_ARG_OPTION],
370 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
371         if test "$enableval" != "$5" ; then
372 ifelse([$3],,[    :]dnl
373 ,[    $3]) ifelse([$4],,,[
374         else
375                 $4])
376         fi],[enableval=$5 ifelse([$4],,,[
377         $4
378 ])dnl
379 ])])dnl
380 dnl ---------------------------------------------------------------------------
381 dnl CF_AR_FLAGS version: 6 updated: 2015/10/10 15:25:05
382 dnl -----------
383 dnl Check for suitable "ar" (archiver) options for updating an archive.
384 dnl
385 dnl In particular, handle some obsolete cases where the "-" might be omitted,
386 dnl as well as a workaround for breakage of make's archive rules by the GNU
387 dnl binutils "ar" program.
388 AC_DEFUN([CF_AR_FLAGS],[
389 AC_REQUIRE([CF_PROG_AR])
390
391 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
392         cf_cv_ar_flags=unknown
393         for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
394         do
395
396                 # check if $ARFLAGS already contains this choice
397                 if test "x$ARFLAGS" != "x" ; then
398                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
399                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
400                                 cf_cv_ar_flags=
401                                 break
402                         fi
403                 fi
404
405                 rm -f conftest.$ac_cv_objext
406                 rm -f conftest.a
407
408                 cat >conftest.$ac_ext <<EOF
409 #line __oline__ "configure"
410 int     testdata[[3]] = { 123, 456, 789 };
411 EOF
412                 if AC_TRY_EVAL(ac_compile) ; then
413                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
414                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
415                         if test -f conftest.a ; then
416                                 cf_cv_ar_flags=$cf_ar_flags
417                                 break
418                         fi
419                 else
420                         CF_VERBOSE(cannot compile test-program)
421                         break
422                 fi
423         done
424         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
425 ])
426
427 if test -n "$ARFLAGS" ; then
428         if test -n "$cf_cv_ar_flags" ; then
429                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
430         fi
431 else
432         ARFLAGS=$cf_cv_ar_flags
433 fi
434
435 AC_SUBST(ARFLAGS)
436 ])
437 dnl ---------------------------------------------------------------------------
438 dnl CF_BUILD_CC version: 8 updated: 2018/01/04 20:31:04
439 dnl -----------
440 dnl If we're cross-compiling, allow the user to override the tools and their
441 dnl options.  The configure script is oriented toward identifying the host
442 dnl compiler, etc., but we need a build compiler to generate parts of the
443 dnl source.
444 dnl
445 dnl $1 = default for $CPPFLAGS
446 dnl $2 = default for $LIBS
447 AC_DEFUN([CF_BUILD_CC],[
448 CF_ACVERSION_CHECK(2.52,,
449         [AC_REQUIRE([CF_PROG_EXT])])
450 if test "$cross_compiling" = yes ; then
451
452         # defaults that we might want to override
453         : ${BUILD_CFLAGS:=''}
454         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
455         : ${BUILD_LDFLAGS:=''}
456         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
457         : ${BUILD_EXEEXT:='$x'}
458         : ${BUILD_OBJEXT:='o'}
459
460         AC_ARG_WITH(build-cc,
461                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
462                 [BUILD_CC="$withval"],
463                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
464         AC_MSG_CHECKING(for native build C compiler)
465         AC_MSG_RESULT($BUILD_CC)
466
467         AC_MSG_CHECKING(for native build C preprocessor)
468         AC_ARG_WITH(build-cpp,
469                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
470                 [BUILD_CPP="$withval"],
471                 [BUILD_CPP='${BUILD_CC} -E'])
472         AC_MSG_RESULT($BUILD_CPP)
473
474         AC_MSG_CHECKING(for native build C flags)
475         AC_ARG_WITH(build-cflags,
476                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
477                 [BUILD_CFLAGS="$withval"])
478         AC_MSG_RESULT($BUILD_CFLAGS)
479
480         AC_MSG_CHECKING(for native build C preprocessor-flags)
481         AC_ARG_WITH(build-cppflags,
482                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
483                 [BUILD_CPPFLAGS="$withval"])
484         AC_MSG_RESULT($BUILD_CPPFLAGS)
485
486         AC_MSG_CHECKING(for native build linker-flags)
487         AC_ARG_WITH(build-ldflags,
488                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
489                 [BUILD_LDFLAGS="$withval"])
490         AC_MSG_RESULT($BUILD_LDFLAGS)
491
492         AC_MSG_CHECKING(for native build linker-libraries)
493         AC_ARG_WITH(build-libs,
494                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
495                 [BUILD_LIBS="$withval"])
496         AC_MSG_RESULT($BUILD_LIBS)
497
498         # this assumes we're on Unix.
499         BUILD_EXEEXT=
500         BUILD_OBJEXT=o
501
502         : ${BUILD_CC:='${CC}'}
503
504         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
505                 AC_MSG_ERROR([Cross-build requires two compilers.
506 Use --with-build-cc to specify the native compiler.])
507         fi
508
509 else
510         : ${BUILD_CC:='${CC}'}
511         : ${BUILD_CPP:='${CPP}'}
512         : ${BUILD_CFLAGS:='${CFLAGS}'}
513         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
514         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
515         : ${BUILD_LIBS:='${LIBS}'}
516         : ${BUILD_EXEEXT:='$x'}
517         : ${BUILD_OBJEXT:='o'}
518 fi
519
520 AC_SUBST(BUILD_CC)
521 AC_SUBST(BUILD_CPP)
522 AC_SUBST(BUILD_CFLAGS)
523 AC_SUBST(BUILD_CPPFLAGS)
524 AC_SUBST(BUILD_LDFLAGS)
525 AC_SUBST(BUILD_LIBS)
526 AC_SUBST(BUILD_EXEEXT)
527 AC_SUBST(BUILD_OBJEXT)
528 ])dnl
529 dnl ---------------------------------------------------------------------------
530 dnl CF_CC_ENV_FLAGS version: 9 updated: 2018/07/29 18:03:26
531 dnl ---------------
532 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
533 dnl into CC.  This will not help with broken scripts that wrap the compiler
534 dnl with options, but eliminates a more common category of user confusion.
535 dnl
536 dnl In particular, it addresses the problem of being able to run the C
537 dnl preprocessor in a consistent manner.
538 dnl
539 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
540 dnl the nuisance of having inconsistent settings for compiler and preprocessor
541 dnl outweighs that limitation.
542 AC_DEFUN([CF_CC_ENV_FLAGS],
543 [
544 # This should have been defined by AC_PROG_CC
545 : ${CC:=cc}
546
547 AC_MSG_CHECKING(\$CFLAGS variable)
548 case "x$CFLAGS" in
549 (*-[[IUD]]*)
550         AC_MSG_RESULT(broken)
551         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
552         cf_flags="$CFLAGS"
553         CFLAGS=
554         for cf_arg in $cf_flags
555         do
556                 CF_ADD_CFLAGS($cf_arg)
557         done
558         ;;
559 (*)
560         AC_MSG_RESULT(ok)
561         ;;
562 esac
563
564 AC_MSG_CHECKING(\$CC variable)
565 case "$CC" in
566 (*[[\ \ ]]-*)
567         AC_MSG_RESULT(broken)
568         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
569         # humor him...
570         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
571         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
572         CC="$cf_prog"
573         for cf_arg in $cf_flags
574         do
575                 case "x$cf_arg" in
576                 (x-[[IUDfgOW]]*)
577                         CF_ADD_CFLAGS($cf_arg)
578                         ;;
579                 (*)
580                         CC="$CC $cf_arg"
581                         ;;
582                 esac
583         done
584         CF_VERBOSE(resulting CC: '$CC')
585         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
586         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
587         ;;
588 (*)
589         AC_MSG_RESULT(ok)
590         ;;
591 esac
592 ])dnl
593 dnl ---------------------------------------------------------------------------
594 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
595 dnl ---------------
596 dnl Determine the default configuration into which we'll install ncurses.  This
597 dnl can be overridden by the user's command-line options.  There's two items to
598 dnl look for:
599 dnl     1. the prefix (e.g., /usr)
600 dnl     2. the header files (e.g., /usr/include/ncurses)
601 dnl We'll look for a previous installation of ncurses and use the same defaults.
602 dnl
603 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
604 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
605 dnl programs from a vendor's.
606 AC_DEFUN([CF_CFG_DEFAULTS],
607 [
608 AC_MSG_CHECKING(for prefix)
609 if test "x$prefix" = "xNONE" ; then
610         case "$cf_cv_system_name" in
611                 # non-vendor systems don't have a conflict
612         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
613                 prefix=/usr
614                 ;;
615         (*)     prefix=$ac_default_prefix
616                 ;;
617         esac
618 fi
619 AC_MSG_RESULT($prefix)
620
621 if test "x$prefix" = "xNONE" ; then
622 AC_MSG_CHECKING(for default include-directory)
623 test -n "$verbose" && echo 1>&AC_FD_MSG
624 for cf_symbol in \
625         $includedir \
626         $includedir/ncurses \
627         $prefix/include \
628         $prefix/include/ncurses \
629         /usr/local/include \
630         /usr/local/include/ncurses \
631         /usr/include \
632         /usr/include/ncurses
633 do
634         cf_dir=`eval echo $cf_symbol`
635         if test -f $cf_dir/curses.h ; then
636         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
637                 includedir="$cf_symbol"
638                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
639                 break
640         fi
641         fi
642         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
643 done
644 AC_MSG_RESULT($includedir)
645 fi
646 ])dnl
647 dnl ---------------------------------------------------------------------------
648 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
649 dnl --------------
650 dnl Check if we're accidentally using a cache from a different machine.
651 dnl Derive the system name, as a check for reusing the autoconf cache.
652 dnl
653 dnl If we've packaged config.guess and config.sub, run that (since it does a
654 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
655 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
656 dnl which is useful in cross-compiles.
657 dnl
658 dnl Note: we would use $ac_config_sub, but that is one of the places where
659 dnl autoconf 2.5x broke compatibility with autoconf 2.13
660 AC_DEFUN([CF_CHECK_CACHE],
661 [
662 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
663         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
664         system_name="$host_os"
665 else
666         system_name="`(uname -s -r) 2>/dev/null`"
667         if test -z "$system_name" ; then
668                 system_name="`(hostname) 2>/dev/null`"
669         fi
670 fi
671 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
672 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
673
674 test -z "$system_name" && system_name="$cf_cv_system_name"
675 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
676
677 if test ".$system_name" != ".$cf_cv_system_name" ; then
678         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
679         AC_MSG_ERROR("Please remove config.cache and try again.")
680 fi
681 ])dnl
682 dnl ---------------------------------------------------------------------------
683 dnl CF_CHECK_GNAT_VERSION version: 2 updated: 2019/12/31 08:53:54
684 dnl ---------------------
685 AC_DEFUN([CF_CHECK_GNAT_VERSION],
686 [
687 AC_REQUIRE([CF_GNAT_VERSION])
688 case $cf_cv_gnat_version in
689 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
690         cf_cv_prog_gnat_correct=yes
691         ;;
692 (*)
693         AC_MSG_WARN(Unsupported GNAT version $cf_cv_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
694         cf_cv_prog_gnat_correct=no
695         ;;
696 esac
697 ])
698 dnl ---------------------------------------------------------------------------
699 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
700 dnl -----------------
701 dnl Check if the given compiler is really clang.  clang's C driver defines
702 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
703 dnl not ignore some gcc options.
704 dnl
705 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
706 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
707 dnl the wrappers for gcc and g++ warnings.
708 dnl
709 dnl $1 = GCC (default) or GXX
710 dnl $2 = CLANG_COMPILER (default)
711 dnl $3 = CFLAGS (default) or CXXFLAGS
712 AC_DEFUN([CF_CLANG_COMPILER],[
713 ifelse([$2],,CLANG_COMPILER,[$2])=no
714
715 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
716         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
717         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
718         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
719         AC_TRY_COMPILE([],[
720 #ifdef __clang__
721 #else
722 make an error
723 #endif
724 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
725 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
726 ],[])
727         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
728         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
729 fi
730 ])
731 dnl ---------------------------------------------------------------------------
732 dnl CF_CONST_X_STRING version: 3 updated: 2020/01/11 18:39:22
733 dnl -----------------
734 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
735 dnl character-strings.
736 dnl
737 dnl It is ambiguous because the specification accommodated the pre-ANSI
738 dnl compilers bundled by more than one vendor in lieu of providing a standard C
739 dnl compiler other than by costly add-ons.  Because of this, the specification
740 dnl did not take into account the use of const for telling the compiler that
741 dnl string literals would be in readonly memory.
742 dnl
743 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
744 dnl let the compiler decide how to represent Xt's strings which were #define'd. 
745 dnl That does not solve the problem of using the block of Xt's strings which
746 dnl are compiled into the library (and is less efficient than one might want).
747 dnl
748 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
749 dnl when compiling the library and compiling using the library, to tell the
750 dnl compiler that String is const.
751 AC_DEFUN([CF_CONST_X_STRING],
752 [
753 AC_REQUIRE([AC_PATH_XTRA])
754
755 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
756
757 AC_TRY_COMPILE(
758 [
759 #include <stdlib.h>
760 #include <X11/Intrinsic.h>
761 ],
762 [String foo = malloc(1)],[
763
764 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
765         AC_TRY_COMPILE(
766                 [
767 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
768 #undef  XTSTRINGDEFINES /* X11R5 and later */
769 #include <stdlib.h>
770 #include <X11/Intrinsic.h>
771                 ],[String foo = malloc(1); *foo = 0],[
772                         cf_cv_const_x_string=no
773                 ],[
774                         cf_cv_const_x_string=yes
775                 ])
776 ])
777
778 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
779
780 case $cf_cv_const_x_string in
781 (no)
782         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
783         ;;
784 (*)
785         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
786         ;;
787 esac
788
789 ])
790 ])dnl
791 dnl ---------------------------------------------------------------------------
792 dnl CF_CONST_X_STRING version: 3 updated: 2020/01/11 18:39:22
793 dnl -----------------
794 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
795 dnl character-strings.
796 dnl
797 dnl It is ambiguous because the specification accommodated the pre-ANSI
798 dnl compilers bundled by more than one vendor in lieu of providing a standard C
799 dnl compiler other than by costly add-ons.  Because of this, the specification
800 dnl did not take into account the use of const for telling the compiler that
801 dnl string literals would be in readonly memory.
802 dnl
803 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
804 dnl let the compiler decide how to represent Xt's strings which were #define'd. 
805 dnl That does not solve the problem of using the block of Xt's strings which
806 dnl are compiled into the library (and is less efficient than one might want).
807 dnl
808 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
809 dnl when compiling the library and compiling using the library, to tell the
810 dnl compiler that String is const.
811 AC_DEFUN([CF_CONST_X_STRING],
812 [
813 AC_REQUIRE([AC_PATH_XTRA])
814
815 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
816
817 AC_TRY_COMPILE(
818 [
819 #include <stdlib.h>
820 #include <X11/Intrinsic.h>
821 ],
822 [String foo = malloc(1)],[
823
824 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
825         AC_TRY_COMPILE(
826                 [
827 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
828 #undef  XTSTRINGDEFINES /* X11R5 and later */
829 #include <stdlib.h>
830 #include <X11/Intrinsic.h>
831                 ],[String foo = malloc(1); *foo = 0],[
832                         cf_cv_const_x_string=no
833                 ],[
834                         cf_cv_const_x_string=yes
835                 ])
836 ])
837
838 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
839
840 case $cf_cv_const_x_string in
841 (no)
842         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
843         ;;
844 (*)
845         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
846         ;;
847 esac
848
849 ])
850 ])dnl
851 dnl ---------------------------------------------------------------------------
852 dnl CF_CURSES_HEADER version: 5 updated: 2015/04/23 20:35:30
853 dnl ----------------
854 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
855 dnl variations of ncurses' installs.
856 dnl
857 dnl $1 = ncurses when looking for ncurses, or is empty
858 AC_DEFUN([CF_CURSES_HEADER],[
859 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
860 cf_cv_ncurses_header=none
861 for cf_header in \
862         ncurses.h ifelse($1,,,[$1/ncurses.h]) \
863         curses.h ifelse($1,,,[$1/curses.h]) ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
864 do
865 AC_TRY_COMPILE([#include <${cf_header}>],
866         [initscr(); tgoto("?", 0,0)],
867         [cf_cv_ncurses_header=$cf_header; break],[])
868 done
869 ])
870
871 if test "$cf_cv_ncurses_header" = none ; then
872         AC_MSG_ERROR(No curses header-files found)
873 fi
874
875 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
876 AC_CHECK_HEADERS($cf_cv_ncurses_header)
877 ])dnl
878 dnl ---------------------------------------------------------------------------
879 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
880 dnl ----------
881 dnl "dirname" is not portable, so we fake it with a shell script.
882 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
883 dnl ---------------------------------------------------------------------------
884 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
885 dnl ---------------
886 dnl You can always use "make -n" to see the actual options, but it's hard to
887 dnl pick out/analyze warning messages when the compile-line is long.
888 dnl
889 dnl Sets:
890 dnl     ECHO_LT - symbol to control if libtool is verbose
891 dnl     ECHO_LD - symbol to prefix "cc -o" lines
892 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
893 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
894 dnl     ECHO_CC - symbol to put before any "cc" line
895 dnl
896 AC_DEFUN([CF_DISABLE_ECHO],[
897 AC_MSG_CHECKING(if you want to see long compiling messages)
898 CF_ARG_DISABLE(echo,
899         [  --disable-echo          do not display "compiling" commands],
900         [
901         ECHO_LT='--silent'
902         ECHO_LD='@echo linking [$]@;'
903         RULE_CC='@echo compiling [$]<'
904         SHOW_CC='@echo compiling [$]@'
905         ECHO_CC='@'
906 ],[
907         ECHO_LT=''
908         ECHO_LD=''
909         RULE_CC=''
910         SHOW_CC=''
911         ECHO_CC=''
912 ])
913 AC_MSG_RESULT($enableval)
914 AC_SUBST(ECHO_LT)
915 AC_SUBST(ECHO_LD)
916 AC_SUBST(RULE_CC)
917 AC_SUBST(SHOW_CC)
918 AC_SUBST(ECHO_CC)
919 ])dnl
920 dnl ---------------------------------------------------------------------------
921 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
922 dnl ------------------------
923 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
924 AC_MSG_CHECKING(if we want to use GNAT projects)
925 CF_ARG_DISABLE(gnat-projects,
926         [  --disable-gnat-projects test: disable GNAT projects even if usable],
927         [enable_gnat_projects=no],
928         [enable_gnat_projects=yes])
929 AC_MSG_RESULT($enable_gnat_projects)
930 ])dnl
931 dnl ---------------------------------------------------------------------------
932 dnl CF_ENABLE_BROKEN_LINKER version: 1 updated: 2020/02/08 15:59:30
933 dnl -----------------------
934 dnl Some linkers cannot reference a data-only object.  Cygwin used to be one.
935 dnl This usually follows CF_LINK_DATAONLY, but is not required in case we need
936 dnl an unconditional feature.
937 AC_DEFUN([CF_ENABLE_BROKEN_LINKER],[
938
939 AC_MSG_CHECKING(if you want broken-linker support code)
940 AC_ARG_ENABLE(broken_linker,
941         [  --enable-broken_linker  compile with broken-linker support code],
942         [with_broken_linker=$enableval],
943         [with_broken_linker=no])
944 AC_MSG_RESULT($with_broken_linker)
945
946 : ${BROKEN_LINKER:=0}
947 if test "x$with_broken_linker" = xyes ; then
948         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
949         BROKEN_LINKER=1
950 fi
951 AC_SUBST(BROKEN_LINKER)
952 ])dnl
953 dnl ---------------------------------------------------------------------------
954 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
955 dnl ---------------
956 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
957 dnl prefer a standard location, and use -L options only if we do not find the
958 dnl library in the standard library location(s).
959 dnl     $1 = library name
960 dnl     $2 = library class, usually the same as library name
961 dnl     $3 = includes
962 dnl     $4 = code fragment to compile/link
963 dnl     $5 = corresponding function-name
964 dnl     $6 = flag, nonnull if failure should not cause an error-exit
965 dnl
966 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
967 dnl to use a -L option.
968 AC_DEFUN([CF_FIND_LIBRARY],
969 [
970         eval 'cf_cv_have_lib_'$1'=no'
971         cf_libdir=""
972         AC_CHECK_FUNC($5,
973                 eval 'cf_cv_have_lib_'$1'=yes',[
974                 cf_save_LIBS="$LIBS"
975                 AC_MSG_CHECKING(for $5 in -l$1)
976                 LIBS="-l$1 $LIBS"
977                 AC_TRY_LINK([$3],[$4],
978                         [AC_MSG_RESULT(yes)
979                          eval 'cf_cv_have_lib_'$1'=yes'
980                         ],
981                         [AC_MSG_RESULT(no)
982                         CF_LIBRARY_PATH(cf_search,$2)
983                         for cf_libdir in $cf_search
984                         do
985                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
986                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
987                                 AC_TRY_LINK([$3],[$4],
988                                         [AC_MSG_RESULT(yes)
989                                          eval 'cf_cv_have_lib_'$1'=yes'
990                                          break],
991                                         [AC_MSG_RESULT(no)
992                                          LIBS="$cf_save_LIBS"])
993                         done
994                         ])
995                 ])
996 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
997 ifelse($6,,[
998 if test $cf_found_library = no ; then
999         AC_MSG_ERROR(Cannot link $1 library)
1000 fi
1001 ])
1002 ])dnl
1003 dnl ---------------------------------------------------------------------------
1004 dnl CF_FIND_LINKAGE version: 21 updated: 2018/06/20 20:23:13
1005 dnl ---------------
1006 dnl Find a library (specifically the linkage used in the code fragment),
1007 dnl searching for it if it is not already in the library path.
1008 dnl See also CF_ADD_SEARCHPATH.
1009 dnl
1010 dnl Parameters (4-on are optional):
1011 dnl     $1 = headers for library entrypoint
1012 dnl     $2 = code fragment for library entrypoint
1013 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1014 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1015 dnl     $5 = action to perform if not successful
1016 dnl     $6 = module name, if not the same as the library name
1017 dnl     $7 = extra libraries
1018 dnl
1019 dnl Sets these variables:
1020 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1021 dnl     $cf_cv_header_path_$3 - include-directory if needed
1022 dnl     $cf_cv_library_path_$3 - library-directory if needed
1023 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1024 AC_DEFUN([CF_FIND_LINKAGE],[
1025
1026 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1027 # will be set on completion of the AC_TRY_LINK below.
1028 cf_cv_header_path_$3=
1029 cf_cv_library_path_$3=
1030
1031 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1032
1033 cf_save_LIBS="$LIBS"
1034
1035 AC_TRY_LINK([$1],[$2],[
1036         cf_cv_find_linkage_$3=yes
1037         cf_cv_header_path_$3=/usr/include
1038         cf_cv_library_path_$3=/usr/lib
1039 ],[
1040
1041 LIBS="-l$3 $7 $cf_save_LIBS"
1042
1043 AC_TRY_LINK([$1],[$2],[
1044         cf_cv_find_linkage_$3=yes
1045         cf_cv_header_path_$3=/usr/include
1046         cf_cv_library_path_$3=/usr/lib
1047         cf_cv_library_file_$3="-l$3"
1048 ],[
1049         cf_cv_find_linkage_$3=no
1050         LIBS="$cf_save_LIBS"
1051
1052         CF_VERBOSE(find linkage for $3 library)
1053         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1054
1055         cf_save_CPPFLAGS="$CPPFLAGS"
1056         cf_test_CPPFLAGS="$CPPFLAGS"
1057
1058         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1059         for cf_cv_header_path_$3 in $cf_search
1060         do
1061                 if test -d $cf_cv_header_path_$3 ; then
1062                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1063                         CPPFLAGS="$cf_save_CPPFLAGS"
1064                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
1065                         AC_TRY_COMPILE([$1],[$2],[
1066                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1067                                 cf_cv_find_linkage_$3=maybe
1068                                 cf_test_CPPFLAGS="$CPPFLAGS"
1069                                 break],[
1070                                 CPPFLAGS="$cf_save_CPPFLAGS"
1071                                 ])
1072                 fi
1073         done
1074
1075         if test "$cf_cv_find_linkage_$3" = maybe ; then
1076
1077                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1078
1079                 cf_save_LIBS="$LIBS"
1080                 cf_save_LDFLAGS="$LDFLAGS"
1081
1082                 ifelse([$6],,,[
1083                 CPPFLAGS="$cf_test_CPPFLAGS"
1084                 LIBS="-l$3 $7 $cf_save_LIBS"
1085                 AC_TRY_LINK([$1],[$2],[
1086                         CF_VERBOSE(... found $3 library in system)
1087                         cf_cv_find_linkage_$3=yes])
1088                         CPPFLAGS="$cf_save_CPPFLAGS"
1089                         LIBS="$cf_save_LIBS"
1090                         ])
1091
1092                 if test "$cf_cv_find_linkage_$3" != yes ; then
1093                         CF_LIBRARY_PATH(cf_search,$3)
1094                         for cf_cv_library_path_$3 in $cf_search
1095                         do
1096                                 if test -d $cf_cv_library_path_$3 ; then
1097                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1098                                         CPPFLAGS="$cf_test_CPPFLAGS"
1099                                         LIBS="-l$3 $7 $cf_save_LIBS"
1100                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1101                                         AC_TRY_LINK([$1],[$2],[
1102                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1103                                         cf_cv_find_linkage_$3=yes
1104                                         cf_cv_library_file_$3="-l$3"
1105                                         break],[
1106                                         CPPFLAGS="$cf_save_CPPFLAGS"
1107                                         LIBS="$cf_save_LIBS"
1108                                         LDFLAGS="$cf_save_LDFLAGS"
1109                                         ])
1110                                 fi
1111                         done
1112                         CPPFLAGS="$cf_save_CPPFLAGS"
1113                         LDFLAGS="$cf_save_LDFLAGS"
1114                 fi
1115
1116         else
1117                 cf_cv_find_linkage_$3=no
1118         fi
1119         ],$7)
1120 ])
1121
1122 LIBS="$cf_save_LIBS"
1123
1124 if test "$cf_cv_find_linkage_$3" = yes ; then
1125 ifelse([$4],,[
1126         CF_ADD_INCDIR($cf_cv_header_path_$3)
1127         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1128         CF_ADD_LIB($3)
1129 ],[$4])
1130 else
1131 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1132 fi
1133 ])dnl
1134 dnl ---------------------------------------------------------------------------
1135 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
1136 dnl -----------------
1137 dnl make ADAFLAGS consistent with CFLAGS
1138 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1139         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1140         case "$CFLAGS" in
1141         (*-g*)
1142                 CF_ADD_ADAFLAGS(-g)
1143                 ;;
1144         esac
1145         case "$CFLAGS" in
1146         (*-O*)
1147                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1148                 CF_ADD_ADAFLAGS($cf_O_flag)
1149                 ;;
1150         esac
1151         AC_MSG_RESULT($ADAFLAGS)
1152 ])dnl
1153 dnl ---------------------------------------------------------------------------
1154 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
1155 dnl -----------------
1156 dnl Test for availability of useful gcc __attribute__ directives to quiet
1157 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1158 dnl to documentation, unrecognized directives cause older compilers to barf.
1159 AC_DEFUN([CF_GCC_ATTRIBUTES],
1160 [
1161 if test "$GCC" = yes
1162 then
1163 cat > conftest.i <<EOF
1164 #ifndef GCC_PRINTF
1165 #define GCC_PRINTF 0
1166 #endif
1167 #ifndef GCC_SCANF
1168 #define GCC_SCANF 0
1169 #endif
1170 #ifndef GCC_NORETURN
1171 #define GCC_NORETURN /* nothing */
1172 #endif
1173 #ifndef GCC_UNUSED
1174 #define GCC_UNUSED /* nothing */
1175 #endif
1176 EOF
1177 if test "$GCC" = yes
1178 then
1179         AC_CHECKING([for $CC __attribute__ directives])
1180 cat > conftest.$ac_ext <<EOF
1181 #line __oline__ "${as_me:-configure}"
1182 #include "confdefs.h"
1183 #include "conftest.h"
1184 #include "conftest.i"
1185 #if     GCC_PRINTF
1186 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1187 #else
1188 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1189 #endif
1190 #if     GCC_SCANF
1191 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1192 #else
1193 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1194 #endif
1195 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1196 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1197 extern void foo(void) GCC_NORETURN;
1198 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1199 EOF
1200         cf_printf_attribute=no
1201         cf_scanf_attribute=no
1202         for cf_attribute in scanf printf unused noreturn
1203         do
1204                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1205                 cf_directive="__attribute__(($cf_attribute))"
1206                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1207
1208                 case $cf_attribute in
1209                 (printf)
1210                         cf_printf_attribute=yes
1211                         cat >conftest.h <<EOF
1212 #define GCC_$cf_ATTRIBUTE 1
1213 EOF
1214                         ;;
1215                 (scanf)
1216                         cf_scanf_attribute=yes
1217                         cat >conftest.h <<EOF
1218 #define GCC_$cf_ATTRIBUTE 1
1219 EOF
1220                         ;;
1221                 (*)
1222                         cat >conftest.h <<EOF
1223 #define GCC_$cf_ATTRIBUTE $cf_directive
1224 EOF
1225                         ;;
1226                 esac
1227
1228                 if AC_TRY_EVAL(ac_compile); then
1229                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1230                         cat conftest.h >>confdefs.h
1231                         case $cf_attribute in
1232                         (noreturn)
1233                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1234                                 ;;
1235                         (printf)
1236                                 cf_value='/* nothing */'
1237                                 if test "$cf_printf_attribute" != no ; then
1238                                         cf_value='__attribute__((format(printf,fmt,var)))'
1239                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1240                                 fi
1241                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1242                                 ;;
1243                         (scanf)
1244                                 cf_value='/* nothing */'
1245                                 if test "$cf_scanf_attribute" != no ; then
1246                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1247                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1248                                 fi
1249                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1250                                 ;;
1251                         (unused)
1252                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1253                                 ;;
1254                         esac
1255                 fi
1256         done
1257 else
1258         fgrep define conftest.i >>confdefs.h
1259 fi
1260 rm -rf conftest*
1261 fi
1262 ])dnl
1263 dnl ---------------------------------------------------------------------------
1264 dnl CF_GCC_VERSION version: 8 updated: 2019/09/07 13:38:36
1265 dnl --------------
1266 dnl Find version of gcc, and (because icc/clang pretend to be gcc without being
1267 dnl compatible), attempt to determine if icc/clang is actually used.
1268 AC_DEFUN([CF_GCC_VERSION],[
1269 AC_REQUIRE([AC_PROG_CC])
1270 GCC_VERSION=none
1271 if test "$GCC" = yes ; then
1272         AC_MSG_CHECKING(version of $CC)
1273         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1274         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1275         AC_MSG_RESULT($GCC_VERSION)
1276 fi
1277 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1278 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1279 ])dnl
1280 dnl ---------------------------------------------------------------------------
1281 dnl CF_GCC_WARNINGS version: 37 updated: 2020/01/05 20:04:12
1282 dnl ---------------
1283 dnl Check if the compiler supports useful warning options.  There's a few that
1284 dnl we don't use, simply because they're too noisy:
1285 dnl
1286 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1287 dnl     -Winline (usually not worthwhile)
1288 dnl     -Wredundant-decls (system headers make this too noisy)
1289 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1290 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1291 dnl             is enabled for ncurses using "--enable-const".
1292 dnl     -pedantic
1293 dnl
1294 dnl Parameter:
1295 dnl     $1 is an optional list of gcc warning flags that a particular
1296 dnl             application might want to use, e.g., "no-unused" for
1297 dnl             -Wno-unused
1298 dnl Special:
1299 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1300 dnl
1301 AC_DEFUN([CF_GCC_WARNINGS],
1302 [
1303 AC_REQUIRE([CF_GCC_VERSION])
1304 if test "x$have_x" = xyes; then CF_CONST_X_STRING fi
1305 cat > conftest.$ac_ext <<EOF
1306 #line __oline__ "${as_me:-configure}"
1307 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1308 EOF
1309 if test "$INTEL_COMPILER" = yes
1310 then
1311 # The "-wdXXX" options suppress warnings:
1312 # remark #1419: external declaration in primary source file
1313 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1314 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1315 # remark #193: zero used for undefined preprocessing identifier
1316 # remark #593: variable "curs_sb_left_arrow" was set but never used
1317 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1318 # remark #869: parameter "tw" was never referenced
1319 # remark #981: operands are evaluated in unspecified order
1320 # warning #279: controlling expression is constant
1321
1322         AC_CHECKING([for $CC warning options])
1323         cf_save_CFLAGS="$CFLAGS"
1324         EXTRA_CFLAGS="-Wall"
1325         for cf_opt in \
1326                 wd1419 \
1327                 wd1683 \
1328                 wd1684 \
1329                 wd193 \
1330                 wd593 \
1331                 wd279 \
1332                 wd810 \
1333                 wd869 \
1334                 wd981
1335         do
1336                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1337                 if AC_TRY_EVAL(ac_compile); then
1338                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1339                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1340                 fi
1341         done
1342         CFLAGS="$cf_save_CFLAGS"
1343 elif test "$GCC" = yes && test "$GCC_VERSION" != "unknown"
1344 then
1345         AC_CHECKING([for $CC warning options])
1346         cf_save_CFLAGS="$CFLAGS"
1347         EXTRA_CFLAGS=
1348         cf_warn_CONST=""
1349         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1350         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
1351         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
1352         for cf_opt in W Wall \
1353                 Wbad-function-cast \
1354                 Wcast-align \
1355                 Wcast-qual \
1356                 Wdeclaration-after-statement \
1357                 Wextra \
1358                 Winline \
1359                 Wmissing-declarations \
1360                 Wmissing-prototypes \
1361                 Wnested-externs \
1362                 Wpointer-arith \
1363                 Wshadow \
1364                 Wstrict-prototypes \
1365                 Wundef Wno-inline $cf_gcc_warnings $cf_warn_CONST $1
1366         do
1367                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1368                 if AC_TRY_EVAL(ac_compile); then
1369                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1370                         case $cf_opt in
1371                         (Winline)
1372                                 case $GCC_VERSION in
1373                                 ([[34]].*)
1374                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1375                                         continue;;
1376                                 esac
1377                                 ;;
1378                         (Wpointer-arith)
1379                                 case $GCC_VERSION in
1380                                 ([[12]].*)
1381                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1382                                         continue;;
1383                                 esac
1384                                 ;;
1385                         esac
1386                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1387                 fi
1388         done
1389         CFLAGS="$cf_save_CFLAGS"
1390 fi
1391 rm -rf conftest*
1392
1393 AC_SUBST(EXTRA_CFLAGS)
1394 ])dnl
1395 dnl ---------------------------------------------------------------------------
1396 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
1397 dnl -----------------
1398 AC_DEFUN([CF_GNATPREP_OPT_T],[
1399 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
1400 cf_cv_gnatprep_opt_t=no
1401 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
1402 ])
1403 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
1404 AC_SUBST(GNATPREP_OPTS)
1405 ])dnl
1406 dnl ---------------------------------------------------------------------------
1407 dnl CF_GNAT_GENERICS version: 4 updated: 2019/12/31 08:53:54
1408 dnl ----------------
1409 AC_DEFUN([CF_GNAT_GENERICS],
1410 [
1411 AC_REQUIRE([CF_GNAT_VERSION])
1412
1413 AC_MSG_CHECKING(if GNAT supports generics)
1414 case $cf_cv_gnat_version in
1415 (3.[[1-9]]*|[[4-9]].*)
1416         cf_gnat_generics=yes
1417         ;;
1418 (*)
1419         cf_gnat_generics=no
1420         ;;
1421 esac
1422 AC_MSG_RESULT($cf_gnat_generics)
1423
1424 if test "$cf_gnat_generics" = yes
1425 then
1426         cf_compile_generics=generics
1427         cf_generic_objects="\${GENOBJS}"
1428 else
1429         cf_compile_generics=
1430         cf_generic_objects=
1431 fi
1432
1433 AC_SUBST(cf_compile_generics)
1434 AC_SUBST(cf_generic_objects)
1435 ])dnl
1436 dnl ---------------------------------------------------------------------------
1437 dnl CF_GNAT_PROJECTS version: 10 updated: 2019/12/31 08:53:54
1438 dnl ----------------
1439 dnl GNAT projects are configured with ".gpr" project files.
1440 dnl GNAT libraries are a further development, using the project feature.
1441 AC_DEFUN([CF_GNAT_PROJECTS],
1442 [
1443 AC_REQUIRE([CF_GNAT_VERSION])
1444 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
1445
1446 cf_gnat_libraries=no
1447 cf_gnat_projects=no
1448
1449 if test "$enable_gnat_projects" != no ; then
1450 AC_MSG_CHECKING(if GNAT supports project files)
1451 case $cf_cv_gnat_version in
1452 (3.[[0-9]]*)
1453         ;;
1454 (*)
1455         case $cf_cv_system_name in
1456         (cygwin*|msys*)
1457                 ;;
1458         (*)
1459                 rm -rf conftest* *~conftest*
1460                 if mkdir conftest.src conftest.bin conftest.lib
1461                 then
1462                         cd conftest.src
1463                         rm -rf conftest* *~conftest*
1464                         cat >>library.gpr <<CF_EOF
1465 project Library is
1466   Kind := External ("LIB_KIND");
1467   for Library_Name use "ConfTest";
1468   for Object_Dir use ".";
1469   for Library_ALI_Dir use External("LIBRARY_DIR");
1470   for Library_Version use External ("SONAME");
1471   for Library_Kind use Kind;
1472   for Library_Dir use External("BUILD_DIR");
1473   Source_Dir := External ("SOURCE_DIR");
1474   for Source_Dirs use (Source_Dir);
1475 end Library;
1476 CF_EOF
1477                         cat >>confpackage.ads <<CF_EOF
1478 package ConfPackage is
1479    procedure conftest;
1480 end ConfPackage;
1481 CF_EOF
1482                         cat >>confpackage.adb <<CF_EOF
1483 with Text_IO;
1484 package body ConfPackage is
1485    procedure conftest is
1486    begin
1487       Text_IO.Put ("Hello World");
1488       Text_IO.New_Line;
1489    end conftest;
1490 end ConfPackage;
1491 CF_EOF
1492                         if ( $cf_ada_make $ADAFLAGS \
1493                                         -Plibrary.gpr \
1494                                         -XBUILD_DIR=`cd ../conftest.bin;pwd` \
1495                                         -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
1496                                         -XSOURCE_DIR=`pwd` \
1497                                         -XSONAME=libConfTest.so.1 \
1498                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
1499                                 cf_gnat_projects=yes
1500                         fi
1501                         cd ..
1502                 fi
1503                 if test -f conftest.lib/confpackage.ali
1504                 then
1505                         cf_gnat_libraries=yes
1506                 fi
1507                 rm -rf conftest* *~conftest*
1508                 ;;
1509         esac
1510         ;;
1511 esac
1512 AC_MSG_RESULT($cf_gnat_projects)
1513 fi # enable_gnat_projects
1514
1515 if test $cf_gnat_projects = yes
1516 then
1517         AC_MSG_CHECKING(if GNAT supports libraries)
1518         AC_MSG_RESULT($cf_gnat_libraries)
1519 fi
1520
1521 if test "$cf_gnat_projects" = yes
1522 then
1523         USE_OLD_MAKERULES="#"
1524         USE_GNAT_PROJECTS=""
1525 else
1526         USE_OLD_MAKERULES=""
1527         USE_GNAT_PROJECTS="#"
1528 fi
1529
1530 if test "$cf_gnat_libraries" = yes
1531 then
1532         USE_GNAT_LIBRARIES=""
1533 else
1534         USE_GNAT_LIBRARIES="#"
1535 fi
1536
1537 AC_SUBST(USE_OLD_MAKERULES)
1538 AC_SUBST(USE_GNAT_PROJECTS)
1539 AC_SUBST(USE_GNAT_LIBRARIES)
1540 ])dnl
1541 dnl ---------------------------------------------------------------------------
1542 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
1543 dnl --------------
1544 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
1545 dnl is noted that gnat may compile a tasking unit even for configurations which
1546 dnl fail at runtime.
1547 AC_DEFUN([CF_GNAT_SIGINT],[
1548 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
1549 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
1550
1551 package ConfTest is
1552
1553    pragma Warnings (Off);  --  the next pragma exists since 3.11p
1554    pragma Unreserve_All_Interrupts;
1555    pragma Warnings (On);
1556
1557    protected Process is
1558       procedure Stop;
1559       function Continue return Boolean;
1560       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
1561    private
1562       Done : Boolean := False;
1563    end Process;
1564
1565 end ConfTest;],
1566 [package body ConfTest is
1567    protected body Process is
1568       procedure Stop is
1569       begin
1570          Done := True;
1571       end Stop;
1572       function Continue return Boolean is
1573       begin
1574          return not Done;
1575       end Continue;
1576    end Process;
1577 end ConfTest;],
1578         [cf_cv_gnat_sigint=yes],
1579         [cf_cv_gnat_sigint=no])])
1580
1581 if test $cf_cv_gnat_sigint = yes ; then
1582         USE_GNAT_SIGINT=""
1583 else
1584         USE_GNAT_SIGINT="#"
1585 fi
1586 AC_SUBST(USE_GNAT_SIGINT)
1587 ])dnl
1588 dnl ---------------------------------------------------------------------------
1589 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
1590 dnl ----------------
1591 dnl Verify that a test program compiles/links with GNAT.
1592 dnl $cf_ada_make is set to the program that compiles/links
1593 dnl $ADAFLAGS may be set to the GNAT flags.
1594 dnl
1595 dnl $1 is the text of the spec
1596 dnl $2 is the text of the body
1597 dnl $3 is the shell command to execute if successful
1598 dnl $4 is the shell command to execute if not successful
1599 AC_DEFUN([CF_GNAT_TRY_LINK],
1600 [
1601 rm -rf conftest* *~conftest*
1602 cat >>conftest.ads <<CF_EOF
1603 $1
1604 CF_EOF
1605 cat >>conftest.adb <<CF_EOF
1606 $2
1607 CF_EOF
1608 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1609 ifelse($3,,      :,[      $3])
1610 ifelse($4,,,[else
1611    $4])
1612 fi
1613 rm -rf conftest* *~conftest*
1614 ])dnl
1615 dnl ---------------------------------------------------------------------------
1616 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
1617 dnl ---------------
1618 dnl Verify that a test program compiles and runs with GNAT
1619 dnl $cf_ada_make is set to the program that compiles/links
1620 dnl $ADAFLAGS may be set to the GNAT flags.
1621 dnl
1622 dnl $1 is the text of the spec
1623 dnl $2 is the text of the body
1624 dnl $3 is the shell command to execute if successful
1625 dnl $4 is the shell command to execute if not successful
1626 AC_DEFUN([CF_GNAT_TRY_RUN],
1627 [
1628 rm -rf conftest* *~conftest*
1629 cat >>conftest.ads <<CF_EOF
1630 $1
1631 CF_EOF
1632 cat >>conftest.adb <<CF_EOF
1633 $2
1634 CF_EOF
1635 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1636    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
1637 ifelse($3,,      :,[      $3])
1638 ifelse($4,,,[   else
1639       $4])
1640    fi
1641 ifelse($4,,,[else
1642    $4])
1643 fi
1644 rm -rf conftest* *~conftest*
1645 ])dnl
1646 dnl ---------------------------------------------------------------------------
1647 dnl CF_GNAT_VERSION version: 22 updated: 2019/12/31 08:53:54
1648 dnl ---------------
1649 dnl $1 = cache variable to update
1650 dnl $2 = program name
1651 dnl Verify version of GNAT or related tool
1652 AC_DEFUN([CF_GNAT_VERSION],
1653 [
1654 AC_CACHE_CHECK(for ifelse($2,,gnat,$2) version, cf_cv_gnat_version,[
1655 cf_cv_gnat_version=`ifelse($2,,${cf_ada_make:-gnatmake},$2) --version 2>&1 | \
1656         grep '[[0-9]].[[0-9]][[0-9]]*' |\
1657         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
1658 ])
1659 test -z "$cf_cv_gnat_version" && cf_cv_gnat_version=no
1660 ifelse($1,,,[eval $1=$cf_cv_gnat_version; unset cf_cv_gnat_version])
1661 ])dnl
1662 dnl ---------------------------------------------------------------------------
1663 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
1664 dnl -------------
1665 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1666 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1667 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1668 dnl since it is interwoven with GNU extensions.
1669 dnl
1670 dnl Well, yes we could work around it...
1671 dnl
1672 dnl Parameters:
1673 dnl     $1 is the nominal value for _XOPEN_SOURCE
1674 AC_DEFUN([CF_GNU_SOURCE],
1675 [
1676 cf_gnu_xopen_source=ifelse($1,,500,$1)
1677
1678 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
1679 AC_TRY_COMPILE([#include <sys/types.h>],[
1680         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
1681                 return 0;
1682         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
1683                 return 0;
1684         #else
1685         #       error not GNU C library
1686         #endif],
1687         [cf_cv_gnu_library=yes],
1688         [cf_cv_gnu_library=no])
1689 ])
1690
1691 if test x$cf_cv_gnu_library = xyes; then
1692
1693         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
1694         # was changed to help a little.  newlib incorporated the change about 4
1695         # years later.
1696         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
1697                 cf_save="$CPPFLAGS"
1698                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
1699                 AC_TRY_COMPILE([#include <sys/types.h>],[
1700                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
1701                                 return 0;
1702                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
1703                                 return 0;
1704                         #else
1705                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
1706                         #endif],
1707                         [cf_cv_gnu_library_219=yes],
1708                         [cf_cv_gnu_library_219=no])
1709                 CPPFLAGS="$cf_save"
1710         ])
1711
1712         if test "x$cf_cv_gnu_library_219" = xyes; then
1713                 cf_save="$CPPFLAGS"
1714                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
1715                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
1716                         AC_TRY_COMPILE([
1717                                 #include <limits.h>
1718                                 #include <sys/types.h>
1719                                 ],[
1720                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
1721                                         return 0;
1722                                 #else
1723                                 #       error GNU C library is too old
1724                                 #endif],
1725                                 [cf_cv_gnu_dftsrc_219=yes],
1726                                 [cf_cv_gnu_dftsrc_219=no])
1727                         ])
1728                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
1729         else
1730                 cf_cv_gnu_dftsrc_219=maybe
1731         fi
1732
1733         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
1734
1735                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1736                 AC_TRY_COMPILE([#include <sys/types.h>],[
1737                         #ifndef _XOPEN_SOURCE
1738                         #error  expected _XOPEN_SOURCE to be defined
1739                         #endif],
1740                         [cf_cv_gnu_source=no],
1741                         [cf_save="$CPPFLAGS"
1742                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
1743                          AC_TRY_COMPILE([#include <sys/types.h>],[
1744                                 #ifdef _XOPEN_SOURCE
1745                                 #error  expected _XOPEN_SOURCE to be undefined
1746                                 #endif],
1747                                 [cf_cv_gnu_source=no],
1748                                 [cf_cv_gnu_source=yes])
1749                         CPPFLAGS="$cf_save"
1750                         ])
1751                 ])
1752
1753                 if test "$cf_cv_gnu_source" = yes
1754                 then
1755                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
1756                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
1757                         AC_TRY_COMPILE([#include <sys/types.h>],[
1758                                 #ifdef _DEFAULT_SOURCE
1759                                 #error  expected _DEFAULT_SOURCE to be undefined
1760                                 #endif],
1761                                 [cf_cv_default_source=no],
1762                                 [cf_cv_default_source=yes])
1763                         ])
1764                         if test "$cf_cv_default_source" = yes
1765                         then
1766                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
1767                         fi
1768                 fi
1769         fi
1770
1771 fi
1772 ])dnl
1773 dnl ---------------------------------------------------------------------------
1774 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
1775 dnl --------------
1776 dnl Construct a search-list of directories for a nonstandard header-file
1777 dnl
1778 dnl Parameters
1779 dnl     $1 = the variable to return as result
1780 dnl     $2 = the package name
1781 AC_DEFUN([CF_HEADER_PATH],
1782 [
1783 $1=
1784
1785 # collect the current set of include-directories from compiler flags
1786 cf_header_path_list=""
1787 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1788         for cf_header_path in $CPPFLAGS $CFLAGS
1789         do
1790                 case $cf_header_path in
1791                 (-I*)
1792                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1793                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1794                         cf_header_path_list="$cf_header_path_list [$]$1"
1795                         ;;
1796                 esac
1797         done
1798 fi
1799
1800 # add the variations for the package we are looking for
1801 CF_SUBDIR_PATH($1,$2,include)
1802
1803 test "$includedir" != NONE && \
1804 test "$includedir" != "/usr/include" && \
1805 test -d "$includedir" && {
1806         test -d $includedir &&    $1="[$]$1 $includedir"
1807         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
1808 }
1809
1810 test "$oldincludedir" != NONE && \
1811 test "$oldincludedir" != "/usr/include" && \
1812 test -d "$oldincludedir" && {
1813         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
1814         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
1815 }
1816
1817 $1="[$]$1 $cf_header_path_list"
1818 ])dnl
1819 dnl ---------------------------------------------------------------------------
1820 dnl CF_HELP_MESSAGE version: 4 updated: 2019/12/31 08:53:54
1821 dnl ---------------
1822 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
1823 AC_DEFUN([CF_HELP_MESSAGE],
1824 [CF_ACVERSION_CHECK(2.53,[],[
1825 AC_DIVERT_HELP($1)])dnl
1826 ])dnl
1827 dnl ---------------------------------------------------------------------------
1828 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
1829 dnl ---------------
1830 dnl Construct the list of include-options according to whether we're building
1831 dnl in the source directory or using '--srcdir=DIR' option.
1832 AC_DEFUN([CF_INCLUDE_DIRS],
1833 [
1834 if test "$srcdir" != "."; then
1835         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
1836 fi
1837 CPPFLAGS="-I../include $CPPFLAGS"
1838 if test "$srcdir" != "."; then
1839         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
1840 fi
1841 CPPFLAGS="-I. $CPPFLAGS"
1842 AC_SUBST(CPPFLAGS)
1843 ])dnl
1844 dnl ---------------------------------------------------------------------------
1845 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
1846 dnl ---------------
1847 dnl prompt for/fill-in useful install-program options
1848 AC_DEFUN([CF_INSTALL_OPTS],
1849 [
1850 CF_INSTALL_OPT_S
1851 CF_INSTALL_OPT_P
1852 CF_INSTALL_OPT_O
1853 ])dnl
1854 dnl ---------------------------------------------------------------------------
1855 dnl CF_INSTALL_OPT_O version: 2 updated: 2015/05/15 19:45:35
1856 dnl ----------------
1857 dnl Almost all "install" programs default to the current user's ownership.
1858 dnl Almost - MINIX is an exception.
1859 AC_DEFUN([CF_INSTALL_OPT_O],
1860 [
1861 AC_MSG_CHECKING(if install needs to be told about ownership)
1862 case `$ac_config_guess` in
1863 (*minix)
1864         with_install_o=yes
1865         ;;
1866 (*)
1867         with_install_o=no
1868         ;;
1869 esac
1870
1871 AC_MSG_RESULT($with_install_o)
1872 if test "x$with_install_o" = xyes
1873 then
1874         INSTALL_OPT_O=`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`
1875 else
1876         INSTALL_OPT_O=
1877 fi
1878
1879 AC_SUBST(INSTALL_OPT_O)
1880 ])dnl
1881 dnl ---------------------------------------------------------------------------
1882 dnl CF_INSTALL_OPT_P version: 1 updated: 2018/08/18 12:19:21
1883 dnl ----------------
1884 dnl Some install-programs accept a "-p" option to preserve file modification
1885 dnl timestamps.  That can be useful as an install option, as well as a way to
1886 dnl avoid the need for ranlib after copying a static archive.
1887 AC_DEFUN([CF_INSTALL_OPT_P],
1888 [
1889 : ${INSTALL:=install}
1890 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
1891         rm -rf conftest*
1892         date >conftest.in
1893         mkdir conftest.out
1894         sleep 3
1895         if $INSTALL -p conftest.in conftest.out 2>/dev/null
1896         then
1897                 if test -f conftest.out/conftest.in
1898                 then
1899                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
1900                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
1901                         if test -s conftest.err
1902                         then
1903                                 cf_cv_install_p=no
1904                         else
1905                                 cf_cv_install_p=yes
1906                         fi
1907                 else
1908                         cf_cv_install_p=no
1909                 fi
1910         else
1911                 cf_cv_install_p=no
1912         fi
1913         rm -rf conftest*
1914 ])
1915 ])dnl
1916 dnl ---------------------------------------------------------------------------
1917 dnl CF_INSTALL_OPT_S version: 2 updated: 2018/08/18 12:19:21
1918 dnl ----------------
1919 dnl By default, we should strip executables which are installed, but leave the
1920 dnl ability to suppress that for unit-testing.
1921 AC_DEFUN([CF_INSTALL_OPT_S],
1922 [
1923 AC_MSG_CHECKING(if you want to install stripped executables)
1924 CF_ARG_DISABLE(stripping,
1925         [  --disable-stripping     do not strip (debug info) installed executables],
1926         [with_stripping=no],
1927         [with_stripping=yes])
1928 AC_MSG_RESULT($with_stripping)
1929
1930 if test "$with_stripping" = yes
1931 then
1932         INSTALL_OPT_S="-s"
1933 else
1934         INSTALL_OPT_S=
1935 fi
1936 AC_SUBST(INSTALL_OPT_S)
1937 ])dnl
1938 dnl ---------------------------------------------------------------------------
1939 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
1940 dnl -----------------
1941 dnl Check if the given compiler is really the Intel compiler for Linux.  It
1942 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
1943 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
1944 dnl
1945 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1946 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1947 dnl the wrappers for gcc and g++ warnings.
1948 dnl
1949 dnl $1 = GCC (default) or GXX
1950 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
1951 dnl $3 = CFLAGS (default) or CXXFLAGS
1952 AC_DEFUN([CF_INTEL_COMPILER],[
1953 AC_REQUIRE([AC_CANONICAL_HOST])
1954 ifelse([$2],,INTEL_COMPILER,[$2])=no
1955
1956 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1957         case $host_os in
1958         (linux*|gnu*)
1959                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
1960                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1961                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
1962                 AC_TRY_COMPILE([],[
1963 #ifdef __INTEL_COMPILER
1964 #else
1965 make an error
1966 #endif
1967 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
1968 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
1969 ],[])
1970                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1971                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
1972                 ;;
1973         esac
1974 fi
1975 ])dnl
1976 dnl ---------------------------------------------------------------------------
1977 dnl CF_LARGEFILE version: 11 updated: 2018/06/20 20:23:13
1978 dnl ------------
1979 dnl Add checks for large file support.
1980 AC_DEFUN([CF_LARGEFILE],[
1981 ifdef([AC_FUNC_FSEEKO],[
1982         AC_SYS_LARGEFILE
1983         if test "$enable_largefile" != no ; then
1984         AC_FUNC_FSEEKO
1985
1986         # Normally we would collect these definitions in the config.h,
1987         # but (like _XOPEN_SOURCE), some environments rely on having these
1988         # defined before any of the system headers are included.  Another
1989         # case comes up with C++, e.g., on AIX the compiler compiles the
1990         # header files by themselves before looking at the body files it is
1991         # told to compile.  For ncurses, those header files do not include
1992         # the config.h
1993         if test "$ac_cv_sys_large_files" != no
1994         then
1995                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
1996         fi
1997         if test "$ac_cv_sys_largefile_source" != no
1998         then
1999                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
2000         fi
2001         if test "$ac_cv_sys_file_offset_bits" != no
2002         then
2003                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
2004         fi
2005
2006         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2007                 AC_TRY_COMPILE([
2008 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
2009 #include <sys/types.h>
2010 #include <dirent.h>
2011                 ],[
2012                 /* if transitional largefile support is setup, this is true */
2013                 extern struct dirent64 * readdir(DIR *);
2014                 struct dirent64 *x = readdir((DIR *)0);
2015                 struct dirent *y = readdir((DIR *)0);
2016                 int z = x - y;
2017                 ],
2018                 [cf_cv_struct_dirent64=yes],
2019                 [cf_cv_struct_dirent64=no])
2020         ])
2021         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
2022         fi
2023 ])
2024 ])
2025 dnl ---------------------------------------------------------------------------
2026 dnl CF_LD_RPATH_OPT version: 8 updated: 2018/08/18 16:36:35
2027 dnl ---------------
2028 dnl For the given system and compiler, find the compiler flags to pass to the
2029 dnl loader to use the "rpath" feature.
2030 AC_DEFUN([CF_LD_RPATH_OPT],
2031 [
2032 AC_REQUIRE([CF_CHECK_CACHE])
2033
2034 LD_RPATH_OPT=
2035 if test "x$cf_cv_enable_rpath" != xno
2036 then
2037         AC_MSG_CHECKING(for an rpath option)
2038         case $cf_cv_system_name in
2039         (irix*)
2040                 if test "$GCC" = yes; then
2041                         LD_RPATH_OPT="-Wl,-rpath,"
2042                 else
2043                         LD_RPATH_OPT="-rpath "
2044                 fi
2045                 ;;
2046         (linux*|gnu*|k*bsd*-gnu|freebsd*)
2047                 LD_RPATH_OPT="-Wl,-rpath,"
2048                 ;;
2049         (openbsd[[2-9]].*|mirbsd*)
2050                 LD_RPATH_OPT="-Wl,-rpath,"
2051                 ;;
2052         (dragonfly*)
2053                 LD_RPATH_OPT="-rpath "
2054                 ;;
2055         (netbsd*)
2056                 LD_RPATH_OPT="-Wl,-rpath,"
2057                 ;;
2058         (osf*|mls+*)
2059                 LD_RPATH_OPT="-rpath "
2060                 ;;
2061         (solaris2*)
2062                 LD_RPATH_OPT="-R"
2063                 ;;
2064         (*)
2065                 ;;
2066         esac
2067         AC_MSG_RESULT($LD_RPATH_OPT)
2068
2069         case "x$LD_RPATH_OPT" in
2070         (x-R*)
2071                 AC_MSG_CHECKING(if we need a space after rpath option)
2072                 cf_save_LIBS="$LIBS"
2073                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
2074                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
2075                 LIBS="$cf_save_LIBS"
2076                 AC_MSG_RESULT($cf_rpath_space)
2077                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
2078                 ;;
2079         esac
2080 fi
2081 ])dnl
2082 dnl ---------------------------------------------------------------------------
2083 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
2084 dnl ---------------
2085 dnl Construct a search-list of directories for a nonstandard library-file
2086 dnl
2087 dnl Parameters
2088 dnl     $1 = the variable to return as result
2089 dnl     $2 = the package name
2090 AC_DEFUN([CF_LIBRARY_PATH],
2091 [
2092 $1=
2093 cf_library_path_list=""
2094 if test -n "${LDFLAGS}${LIBS}" ; then
2095         for cf_library_path in $LDFLAGS $LIBS
2096         do
2097                 case $cf_library_path in
2098                 (-L*)
2099                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
2100                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
2101                         cf_library_path_list="$cf_library_path_list [$]$1"
2102                         ;;
2103                 esac
2104         done
2105 fi
2106
2107 CF_SUBDIR_PATH($1,$2,lib)
2108
2109 $1="$cf_library_path_list [$]$1"
2110 ])dnl
2111 dnl ---------------------------------------------------------------------------
2112 dnl CF_LIB_PREFIX version: 12 updated: 2015/10/17 19:03:33
2113 dnl -------------
2114 dnl Compute the library-prefix for the given host system
2115 dnl $1 = variable to set
2116 define([CF_LIB_PREFIX],
2117 [
2118         case $cf_cv_system_name in
2119         (OS/2*|os2*)
2120                 if test "$DFT_LWR_MODEL" = libtool; then
2121                         LIB_PREFIX='lib'
2122                 else
2123                         LIB_PREFIX=''
2124                 fi
2125                 ;;
2126         (*)     LIB_PREFIX='lib'
2127                 ;;
2128         esac
2129 ifelse($1,,,[$1=$LIB_PREFIX])
2130         AC_SUBST(LIB_PREFIX)
2131 ])dnl
2132 dnl ---------------------------------------------------------------------------
2133 dnl CF_LIB_SUFFIX version: 25 updated: 2015/04/17 21:13:04
2134 dnl -------------
2135 dnl Compute the library file-suffix from the given model name
2136 dnl $1 = model name
2137 dnl $2 = variable to set (the nominal library suffix)
2138 dnl $3 = dependency variable to set (actual filename)
2139 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
2140 AC_DEFUN([CF_LIB_SUFFIX],
2141 [
2142         case X$1 in
2143         (Xlibtool)
2144                 $2='.la'
2145                 $3=[$]$2
2146                 ;;
2147         (Xdebug)
2148                 $2='_g.a'
2149                 $3=[$]$2
2150                 ;;
2151         (Xprofile)
2152                 $2='_p.a'
2153                 $3=[$]$2
2154                 ;;
2155         (Xshared)
2156                 case $cf_cv_system_name in
2157                 (aix[[5-7]]*)
2158                         $2='.so'
2159                         $3=[$]$2
2160                         ;;
2161                 (cygwin*|msys*|mingw*)
2162                         $2='.dll'
2163                         $3='.dll.a'
2164                         ;;
2165                 (darwin*)
2166                         $2='.dylib'
2167                         $3=[$]$2
2168                         ;;
2169                 (hpux*)
2170                         case $target in
2171                         (ia64*)
2172                                 $2='.so'
2173                                 $3=[$]$2
2174                                 ;;
2175                         (*)
2176                                 $2='.sl'
2177                                 $3=[$]$2
2178                                 ;;
2179                         esac
2180                         ;;
2181                 (*)
2182                         $2='.so'
2183                         $3=[$]$2
2184                         ;;
2185                 esac
2186                 ;;
2187         (*)
2188                 $2='.a'
2189                 $3=[$]$2
2190                 ;;
2191         esac
2192         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
2193         then
2194                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
2195                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
2196         fi
2197 ])dnl
2198 dnl ---------------------------------------------------------------------------
2199 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
2200 dnl -----------
2201 dnl Compute the string to append to -library from the given model name
2202 dnl $1 = model name
2203 dnl $2 = variable to set
2204 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
2205 AC_DEFUN([CF_LIB_TYPE],
2206 [
2207         case $1 in
2208         (libtool) $2=''   ;;
2209         (normal)  $2=''   ;;
2210         (debug)   $2='_g' ;;
2211         (profile) $2='_p' ;;
2212         (shared)  $2=''   ;;
2213         esac
2214         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
2215 ])dnl
2216 dnl ---------------------------------------------------------------------------
2217 dnl CF_LINK_DATAONLY version: 13 updated: 2020/02/08 15:59:30
2218 dnl ----------------
2219 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
2220 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
2221 dnl have to provide wrappers for global tables to ensure they're linked
2222 dnl properly.
2223 AC_DEFUN([CF_LINK_DATAONLY],
2224 [
2225 AC_MSG_CHECKING([if data-only library module links])
2226 AC_CACHE_VAL(cf_cv_link_dataonly,[
2227         rm -f conftest.a
2228         cat >conftest.$ac_ext <<EOF
2229 #line __oline__ "configure"
2230 int     testdata[[3]] = { 123, 456, 789 };
2231 EOF
2232         if AC_TRY_EVAL(ac_compile) ; then
2233                 mv conftest.o data.o && \
2234                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
2235         fi
2236         rm -f conftest.$ac_ext data.o
2237         cat >conftest.$ac_ext <<EOF
2238 #line __oline__ "configure"
2239 int     testfunc(void)
2240 {
2241 #if defined(NeXT)
2242         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
2243 #else
2244         extern int testdata[[3]];
2245         return testdata[[0]] == 123
2246            &&  testdata[[1]] == 456
2247            &&  testdata[[2]] == 789;
2248 #endif
2249 }
2250 EOF
2251         if AC_TRY_EVAL(ac_compile); then
2252                 mv conftest.o func.o && \
2253                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
2254         fi
2255         rm -f conftest.$ac_ext func.o
2256         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
2257         cf_saveLIBS="$LIBS"
2258         LIBS="conftest.a $LIBS"
2259         AC_TRY_RUN([
2260         int main(void)
2261         {
2262                 extern int testfunc();
2263                 ${cf_cv_main_return:-return} (!testfunc());
2264         }
2265         ],
2266         [cf_cv_link_dataonly=yes],
2267         [cf_cv_link_dataonly=no],
2268         [cf_cv_link_dataonly=unknown])
2269         LIBS="$cf_saveLIBS"
2270         ])
2271 AC_MSG_RESULT($cf_cv_link_dataonly)
2272
2273 if test "$cf_cv_link_dataonly" = no ; then
2274         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
2275         BROKEN_LINKER=1
2276 fi
2277 AC_SUBST(BROKEN_LINKER)
2278
2279 ])dnl
2280 dnl ---------------------------------------------------------------------------
2281 dnl CF_MAKEFLAGS version: 18 updated: 2018/02/21 21:26:03
2282 dnl ------------
2283 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
2284 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
2285 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
2286 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
2287 AC_DEFUN([CF_MAKEFLAGS],
2288 [
2289 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
2290         cf_cv_makeflags=''
2291         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
2292         do
2293                 cat >cf_makeflags.tmp <<CF_EOF
2294 SHELL = $SHELL
2295 all :
2296         @ echo '.$cf_option'
2297 CF_EOF
2298                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
2299                 case "$cf_result" in
2300                 (.*k|.*kw)
2301                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
2302                         case "$cf_result" in
2303                         (.*CC=*)        cf_cv_makeflags=
2304                                 ;;
2305                         (*)     cf_cv_makeflags=$cf_option
2306                                 ;;
2307                         esac
2308                         break
2309                         ;;
2310                 (.-)
2311                         ;;
2312                 (*)
2313                         CF_MSG_LOG(given option \"$cf_option\", no match \"$cf_result\")
2314                         ;;
2315                 esac
2316         done
2317         rm -f cf_makeflags.tmp
2318 ])
2319
2320 AC_SUBST(cf_cv_makeflags)
2321 ])dnl
2322 dnl ---------------------------------------------------------------------------
2323 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
2324 dnl ------------
2325 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
2326 dnl a monocase filesystem.
2327 AC_DEFUN([CF_MAKE_TAGS],[
2328 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
2329
2330 AC_CHECK_PROGS(CTAGS, exctags ctags)
2331 AC_CHECK_PROGS(ETAGS, exetags etags)
2332
2333 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
2334
2335 if test "$cf_cv_mixedcase" = yes ; then
2336         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
2337 else
2338         MAKE_UPPER_TAGS=no
2339 fi
2340
2341 if test "$MAKE_UPPER_TAGS" = yes ; then
2342         MAKE_UPPER_TAGS=
2343 else
2344         MAKE_UPPER_TAGS="#"
2345 fi
2346
2347 if test "$MAKE_LOWER_TAGS" = yes ; then
2348         MAKE_LOWER_TAGS=
2349 else
2350         MAKE_LOWER_TAGS="#"
2351 fi
2352
2353 AC_SUBST(CTAGS)
2354 AC_SUBST(ETAGS)
2355
2356 AC_SUBST(MAKE_UPPER_TAGS)
2357 AC_SUBST(MAKE_LOWER_TAGS)
2358 ])dnl
2359 dnl ---------------------------------------------------------------------------
2360 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
2361 dnl ----------------------
2362 dnl Check if the file-system supports mixed-case filenames.  If we're able to
2363 dnl create a lowercase name and see it as uppercase, it doesn't support that.
2364 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
2365 [
2366 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
2367 if test "$cross_compiling" = yes ; then
2368         case $target_alias in
2369         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
2370                 cf_cv_mixedcase=no
2371                 ;;
2372         (*)
2373                 cf_cv_mixedcase=yes
2374                 ;;
2375         esac
2376 else
2377         rm -f conftest CONFTEST
2378         echo test >conftest
2379         if test -f CONFTEST ; then
2380                 cf_cv_mixedcase=no
2381         else
2382                 cf_cv_mixedcase=yes
2383         fi
2384         rm -f conftest CONFTEST
2385 fi
2386 ])
2387 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
2388 ])dnl
2389 dnl ---------------------------------------------------------------------------
2390 dnl CF_MKSTEMP version: 10 updated: 2017/01/21 11:12:16
2391 dnl ----------
2392 dnl Check for a working mkstemp.  This creates two files, checks that they are
2393 dnl successfully created and distinct (AmigaOS apparently fails on the last).
2394 AC_DEFUN([CF_MKSTEMP],[
2395 AC_CHECK_HEADERS( \
2396 unistd.h \
2397 )
2398 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
2399 rm -rf conftest*
2400 AC_TRY_RUN([
2401 #include <sys/types.h>
2402 #ifdef HAVE_UNISTD_H
2403 #include <unistd.h>
2404 #endif
2405 #include <stdlib.h>
2406 #include <stdio.h>
2407 #include <string.h>
2408 #include <sys/stat.h>
2409 int main(void)
2410 {
2411         char *tmpl = "conftestXXXXXX";
2412         char name[2][80];
2413         int n;
2414         int result = 0;
2415         int fd;
2416         struct stat sb;
2417
2418         umask(077);
2419         for (n = 0; n < 2; ++n) {
2420                 strcpy(name[n], tmpl);
2421                 if ((fd = mkstemp(name[n])) >= 0) {
2422                         if (!strcmp(name[n], tmpl)
2423                          || stat(name[n], &sb) != 0
2424                          || (sb.st_mode & S_IFMT) != S_IFREG
2425                          || (sb.st_mode & 077) != 0) {
2426                                 result = 1;
2427                         }
2428                         close(fd);
2429                 }
2430         }
2431         if (result == 0
2432          && !strcmp(name[0], name[1]))
2433                 result = 1;
2434         ${cf_cv_main_return:-return}(result);
2435 }
2436 ],[cf_cv_func_mkstemp=yes
2437 ],[cf_cv_func_mkstemp=no
2438 ],[cf_cv_func_mkstemp=maybe])
2439 ])
2440 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
2441         AC_CHECK_FUNC(mkstemp)
2442 fi
2443 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
2444         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
2445 fi
2446 ])dnl
2447 dnl ---------------------------------------------------------------------------
2448 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2449 dnl ----------
2450 dnl Write a debug message to config.log, along with the line number in the
2451 dnl configure script.
2452 AC_DEFUN([CF_MSG_LOG],[
2453 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2454 ])dnl
2455 dnl ---------------------------------------------------------------------------
2456 dnl CF_NCURSES_ADDON version: 5 updated: 2015/04/26 18:06:58
2457 dnl ----------------
2458 dnl Configure an ncurses add-on, built outside the ncurses tree.
2459 AC_DEFUN([CF_NCURSES_ADDON],[
2460 AC_REQUIRE([CF_NCURSES_CONFIG])
2461
2462 AC_PROVIDE([CF_SUBST_NCURSES_VERSION])
2463
2464 AC_MSG_CHECKING(if you want wide-character code)
2465 AC_ARG_ENABLE(widec,
2466         [  --enable-widec          compile with wide-char/UTF-8 code],
2467         [with_widec=$enableval],
2468         [with_widec=no])
2469 AC_MSG_RESULT($with_widec)
2470 if test "$with_widec" = yes ; then
2471         CF_UTF8_LIB
2472         CF_NCURSES_CONFIG(ncursesw)
2473 else
2474         CF_NCURSES_CONFIG(ncurses)
2475 fi
2476
2477 if test "$NCURSES_CONFIG_PKG" != none ; then
2478         cf_version=`$PKG_CONFIG --modversion $NCURSES_CONFIG_PKG 2>/dev/null`
2479
2480         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2481         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2482         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2483
2484         cf_cv_abi_version=`$PKG_CONFIG --variable=abi_version $NCURSES_CONFIG_PKG 2>/dev/null`
2485         if test -z "$cf_cv_abi_version"
2486         then
2487                 cf_cv_abi_version=`$PKG_CONFIG --variable=major_version $NCURSES_CONFIG_PKG 2>/dev/null`
2488         fi
2489
2490 elif test "$NCURSES_CONFIG" != none ; then
2491
2492         cf_version=`$NCURSES_CONFIG --version 2>/dev/null`
2493
2494         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2495         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2496         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2497
2498         # ABI version is not available from headers
2499         cf_cv_abi_version=`$NCURSES_CONFIG --abi-version 2>/dev/null`
2500
2501 else
2502
2503         for cf_name in MAJOR MINOR PATCH
2504         do
2505         cat >conftest.$ac_ext <<CF_EOF
2506         #include <${cf_cv_ncurses_header:-curses.h}>
2507         AUTOCONF_$cf_name NCURSES_VERSION_$cf_name
2508 CF_EOF
2509                 cf_try="$ac_cpp conftest.$ac_ext 2>&5 | fgrep AUTOCONF_$cf_name >conftest.out"
2510                 AC_TRY_EVAL(cf_try)
2511                 if test -f conftest.out ; then
2512                         cf_result=`cat conftest.out | sed -e "s/^.*AUTOCONF_$cf_name[[  ]][[    ]]*//"`
2513                         eval NCURSES_$cf_name=\"$cf_result\"
2514                         # cat conftest.$ac_ext
2515                         # cat conftest.out
2516                 fi
2517         done
2518
2519         cf_cv_abi_version=${NCURSES_MAJOR}
2520
2521 fi
2522
2523 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
2524
2525 dnl Show the computed version, for logging
2526 cf_cv_timestamp=`date`
2527
2528 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
2529
2530 dnl We need these values in the generated headers
2531 AC_SUBST(NCURSES_MAJOR)
2532 AC_SUBST(NCURSES_MINOR)
2533 AC_SUBST(NCURSES_PATCH)
2534
2535 dnl We need these values in the generated makefiles
2536 AC_SUBST(cf_cv_rel_version)
2537 AC_SUBST(cf_cv_abi_version)
2538
2539 dnl FIXME - not needed for Ada95
2540 AC_SUBST(cf_cv_builtin_bool)
2541 AC_SUBST(cf_cv_header_stdbool_h)
2542 AC_SUBST(cf_cv_type_of_bool)dnl
2543
2544 ])
2545 dnl ---------------------------------------------------------------------------
2546 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
2547 dnl -------------------
2548 dnl Check if we can compile with ncurses' header file
2549 dnl $1 is the cache variable to set
2550 dnl $2 is the header-file to include
2551 dnl $3 is the root name (ncurses or ncursesw)
2552 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2553         AC_TRY_COMPILE([
2554 ]ifelse($3,ncursesw,[
2555 #define _XOPEN_SOURCE_EXTENDED
2556 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2557 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2558 ])[
2559 #include <$2>],[
2560 #ifdef NCURSES_VERSION
2561 ]ifelse($3,ncursesw,[
2562 #ifndef WACS_BSSB
2563         make an error
2564 #endif
2565 ])[
2566 printf("%s\n", NCURSES_VERSION);
2567 #else
2568 #ifdef __NCURSES_H
2569 printf("old\n");
2570 #else
2571         make an error
2572 #endif
2573 #endif
2574         ]
2575         ,[$1=$2]
2576         ,[$1=no])
2577 ])dnl
2578 dnl ---------------------------------------------------------------------------
2579 dnl CF_NCURSES_CONFIG version: 21 updated: 2018/06/20 20:23:13
2580 dnl -----------------
2581 dnl Tie together the configure-script macros for ncurses, preferring these in
2582 dnl order:
2583 dnl a) ".pc" files for pkg-config, using $NCURSES_CONFIG_PKG
2584 dnl b) the "-config" script from ncurses, using $NCURSES_CONFIG
2585 dnl c) just plain libraries
2586 dnl
2587 dnl $1 is the root library name (default: "ncurses")
2588 AC_DEFUN([CF_NCURSES_CONFIG],[
2589 AC_REQUIRE([CF_PKG_CONFIG])
2590 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2591 cf_have_ncuconfig=no
2592
2593 if test "x${PKG_CONFIG:=none}" != xnone; then
2594         AC_MSG_CHECKING(pkg-config for $cf_ncuconfig_root)
2595         if "$PKG_CONFIG" --exists $cf_ncuconfig_root ; then
2596                 AC_MSG_RESULT(yes)
2597
2598                 AC_MSG_CHECKING(if the $cf_ncuconfig_root package files work)
2599                 cf_have_ncuconfig=unknown
2600
2601                 cf_save_CPPFLAGS="$CPPFLAGS"
2602                 cf_save_LIBS="$LIBS"
2603
2604                 CF_ADD_CFLAGS(`$PKG_CONFIG --cflags $cf_ncuconfig_root`)
2605                 CF_ADD_LIBS(`$PKG_CONFIG --libs $cf_ncuconfig_root`)
2606
2607                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2608                         [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2609                         [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2610                                 int main(void)
2611                                 { char *xx = curses_version(); return (xx == 0); }],
2612                                 [cf_have_ncuconfig=yes],
2613                                 [cf_have_ncuconfig=no],
2614                                 [cf_have_ncuconfig=maybe])],
2615                         [cf_have_ncuconfig=no])
2616                 AC_MSG_RESULT($cf_have_ncuconfig)
2617                 test "$cf_have_ncuconfig" = maybe && cf_have_ncuconfig=yes
2618                 if test "$cf_have_ncuconfig" != "yes"
2619                 then
2620                         CPPFLAGS="$cf_save_CPPFLAGS"
2621                         LIBS="$cf_save_LIBS"
2622                         NCURSES_CONFIG_PKG=none
2623                 else
2624                         AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2625                         NCURSES_CONFIG_PKG=$cf_ncuconfig_root
2626                         CF_TERM_HEADER
2627                 fi
2628
2629         else
2630                 AC_MSG_RESULT(no)
2631                 NCURSES_CONFIG_PKG=none
2632         fi
2633 else
2634         NCURSES_CONFIG_PKG=none
2635 fi
2636
2637 if test "x$cf_have_ncuconfig" = "xno"; then
2638         cf_ncurses_config="${cf_ncuconfig_root}${NCURSES_CONFIG_SUFFIX}-config"; echo "Looking for ${cf_ncurses_config}"
2639
2640         CF_ACVERSION_CHECK(2.52,
2641                 [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
2642                 [AC_PATH_PROGS(NCURSES_CONFIG,  ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
2643
2644         if test "$NCURSES_CONFIG" != none ; then
2645
2646                 CF_ADD_CFLAGS(`$NCURSES_CONFIG --cflags`)
2647                 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2648
2649                 # even with config script, some packages use no-override for curses.h
2650                 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2651
2652                 dnl like CF_NCURSES_CPPFLAGS
2653                 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2654
2655                 dnl like CF_NCURSES_LIBS
2656                 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2657                 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2658
2659                 dnl like CF_NCURSES_VERSION
2660                 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
2661
2662         else
2663
2664                 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2665                 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2666
2667         fi
2668 else
2669         NCURSES_CONFIG=none
2670 fi
2671 ])dnl
2672 dnl ---------------------------------------------------------------------------
2673 dnl CF_NCURSES_CPPFLAGS version: 21 updated: 2012/10/06 08:57:51
2674 dnl -------------------
2675 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
2676 dnl the CPPFLAGS variable so we can include its header.
2677 dnl
2678 dnl The header files may be installed as either curses.h, or ncurses.h (would
2679 dnl be obsolete, except that some packagers prefer this name to distinguish it
2680 dnl from a "native" curses implementation).  If not installed for overwrite,
2681 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
2682 dnl /usr/include/ncurses), but someone may have installed overwriting the
2683 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
2684 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
2685 dnl the header.
2686 dnl
2687 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
2688 dnl is already in the include-path, don't even bother with this, since we cannot
2689 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
2690 dnl
2691 dnl The optional parameter gives the root name of the library, in case it is
2692 dnl not installed as the default curses library.  That is how the
2693 dnl wide-character version of ncurses is installed.
2694 AC_DEFUN([CF_NCURSES_CPPFLAGS],
2695 [AC_REQUIRE([CF_WITH_CURSES_DIR])
2696
2697 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
2698 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
2699
2700 test -n "$cf_cv_curses_dir" && \
2701 test "$cf_cv_curses_dir" != "no" && { \
2702   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
2703 }
2704
2705 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
2706         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2707         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
2708         for cf_header in $cf_header_list
2709         do
2710                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2711                 test "$cf_cv_ncurses_h" != no && break
2712         done
2713 ])
2714
2715 CF_NCURSES_HEADER
2716 CF_TERM_HEADER
2717
2718 # some applications need this, but should check for NCURSES_VERSION
2719 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2720
2721 CF_NCURSES_VERSION
2722 ])dnl
2723 dnl ---------------------------------------------------------------------------
2724 dnl CF_NCURSES_HEADER version: 4 updated: 2015/04/15 19:08:48
2725 dnl -----------------
2726 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2727 dnl variations of ncurses' installs.
2728 dnl
2729 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2730 AC_DEFUN([CF_NCURSES_HEADER],[
2731
2732 if test "$cf_cv_ncurses_h" != no ; then
2733         cf_cv_ncurses_header=$cf_cv_ncurses_h
2734 else
2735
2736 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2737         test -n "$verbose" && echo
2738         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2739         test -n "$verbose" && echo search path $cf_search
2740         cf_save2_CPPFLAGS="$CPPFLAGS"
2741         for cf_incdir in $cf_search
2742         do
2743                 CF_ADD_INCDIR($cf_incdir)
2744                 for cf_header in \
2745                         ncurses.h \
2746                         curses.h
2747                 do
2748                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2749                         if test "$cf_cv_ncurses_h2" != no ; then
2750                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2751                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
2752                                 break
2753                         fi
2754                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2755                 done
2756                 CPPFLAGS="$cf_save2_CPPFLAGS"
2757                 test "$cf_cv_ncurses_h2" != no && break
2758         done
2759         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2760         ])
2761
2762         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2763         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
2764         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
2765                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
2766         fi
2767         CF_ADD_INCDIR($cf_1st_incdir)
2768
2769 fi
2770
2771 # Set definitions to allow ifdef'ing for ncurses.h
2772
2773 case $cf_cv_ncurses_header in
2774 (*ncurses.h)
2775         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
2776         ;;
2777 esac
2778
2779 case $cf_cv_ncurses_header in
2780 (ncurses/curses.h|ncurses/ncurses.h)
2781         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
2782         ;;
2783 (ncursesw/curses.h|ncursesw/ncurses.h)
2784         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
2785         ;;
2786 esac
2787
2788 ])dnl
2789 dnl ---------------------------------------------------------------------------
2790 dnl CF_NCURSES_LIBS version: 17 updated: 2015/04/15 19:08:48
2791 dnl ---------------
2792 dnl Look for the ncurses library.  This is a little complicated on Linux,
2793 dnl because it may be linked with the gpm (general purpose mouse) library.
2794 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2795 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2796 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2797 dnl and the linker will record a dependency.
2798 dnl
2799 dnl The optional parameter gives the root name of the library, in case it is
2800 dnl not installed as the default curses library.  That is how the
2801 dnl wide-character version of ncurses is installed.
2802 AC_DEFUN([CF_NCURSES_LIBS],
2803 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2804
2805 cf_nculib_root=ifelse($1,,ncurses,$1)
2806         # This works, except for the special case where we find gpm, but
2807         # ncurses is in a nonstandard location via $LIBS, and we really want
2808         # to link gpm.
2809 cf_ncurses_LIBS=""
2810 cf_ncurses_SAVE="$LIBS"
2811 AC_CHECK_LIB(gpm,Gpm_Open,
2812         [AC_CHECK_LIB(gpm,initscr,
2813                 [LIBS="$cf_ncurses_SAVE"],
2814                 [cf_ncurses_LIBS="-lgpm"])])
2815
2816 case $host_os in
2817 (freebsd*)
2818         # This is only necessary if you are linking against an obsolete
2819         # version of ncurses (but it should do no harm, since it's static).
2820         if test "$cf_nculib_root" = ncurses ; then
2821                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2822         fi
2823         ;;
2824 esac
2825
2826 CF_ADD_LIBS($cf_ncurses_LIBS)
2827
2828 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2829 then
2830         CF_ADD_LIBS(-l$cf_nculib_root)
2831 else
2832         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2833                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2834                 [initscr()],
2835                 initscr)
2836 fi
2837
2838 if test -n "$cf_ncurses_LIBS" ; then
2839         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2840         cf_ncurses_SAVE="$LIBS"
2841         for p in $cf_ncurses_LIBS ; do
2842                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2843                 if test "$q" != "$LIBS" ; then
2844                         LIBS="$q"
2845                 fi
2846         done
2847         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2848                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2849                 [AC_MSG_RESULT(yes)],
2850                 [AC_MSG_RESULT(no)
2851                  LIBS="$cf_ncurses_SAVE"])
2852 fi
2853
2854 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2855 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2856 ])dnl
2857 dnl ---------------------------------------------------------------------------
2858 dnl CF_NCURSES_VERSION version: 15 updated: 2017/05/09 19:26:10
2859 dnl ------------------
2860 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2861 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2862 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2863 AC_DEFUN([CF_NCURSES_VERSION],
2864 [
2865 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2866 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2867         cf_cv_ncurses_version=no
2868         cf_tempfile=out$$
2869         rm -f $cf_tempfile
2870         AC_TRY_RUN([
2871 #include <${cf_cv_ncurses_header:-curses.h}>
2872 #include <stdio.h>
2873 int main(void)
2874 {
2875         FILE *fp = fopen("$cf_tempfile", "w");
2876 #ifdef NCURSES_VERSION
2877 # ifdef NCURSES_VERSION_PATCH
2878         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
2879 # else
2880         fprintf(fp, "%s\n", NCURSES_VERSION);
2881 # endif
2882 #else
2883 # ifdef __NCURSES_H
2884         fprintf(fp, "old\n");
2885 # else
2886         make an error
2887 # endif
2888 #endif
2889         ${cf_cv_main_return:-return}(0);
2890 }],[
2891         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
2892
2893         # This will not work if the preprocessor splits the line after the
2894         # Autoconf token.  The 'unproto' program does that.
2895         cat > conftest.$ac_ext <<EOF
2896 #include <${cf_cv_ncurses_header:-curses.h}>
2897 #undef Autoconf
2898 #ifdef NCURSES_VERSION
2899 Autoconf NCURSES_VERSION
2900 #else
2901 #ifdef __NCURSES_H
2902 Autoconf "old"
2903 #endif
2904 ;
2905 #endif
2906 EOF
2907         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
2908         AC_TRY_EVAL(cf_try)
2909         if test -f conftest.out ; then
2910                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
2911                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
2912                 rm -f conftest.out
2913         fi
2914 ])
2915         rm -f $cf_tempfile
2916 ])
2917 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2918 ])dnl
2919 dnl ---------------------------------------------------------------------------
2920 dnl CF_OBJ_SUBDIR version: 7 updated: 2015/04/17 21:13:04
2921 dnl -------------
2922 dnl Compute the object-directory name from the given model name
2923 AC_DEFUN([CF_OBJ_SUBDIR],
2924 [
2925         case $1 in
2926         (libtool) $2='obj_lo'  ;;
2927         (normal)  $2='objects' ;;
2928         (debug)   $2='obj_g' ;;
2929         (profile) $2='obj_p' ;;
2930         (shared)
2931                 case $cf_cv_system_name in
2932                 (cygwin|msys)
2933                         $2='objects' ;;
2934                 (*)
2935                         $2='obj_s' ;;
2936                 esac
2937         esac
2938 ])dnl
2939 dnl ---------------------------------------------------------------------------
2940 dnl CF_PATHSEP version: 7 updated: 2015/04/12 15:39:00
2941 dnl ----------
2942 dnl Provide a value for the $PATH and similar separator (or amend the value
2943 dnl as provided in autoconf 2.5x).
2944 AC_DEFUN([CF_PATHSEP],
2945 [
2946         AC_MSG_CHECKING(for PATH separator)
2947         case $cf_cv_system_name in
2948         (os2*)  PATH_SEPARATOR=';'  ;;
2949         (*)     ${PATH_SEPARATOR:=':'}  ;;
2950         esac
2951 ifelse([$1],,,[$1=$PATH_SEPARATOR])
2952         AC_SUBST(PATH_SEPARATOR)
2953         AC_MSG_RESULT($PATH_SEPARATOR)
2954 ])dnl
2955 dnl ---------------------------------------------------------------------------
2956 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
2957 dnl --------------
2958 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
2959 dnl begins with one of the prefix/exec_prefix variables, and then again if the
2960 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
2961 dnl delayed evaluation of those symbols.
2962 AC_DEFUN([CF_PATH_SYNTAX],[
2963 if test "x$prefix" != xNONE; then
2964         cf_path_syntax="$prefix"
2965 else
2966         cf_path_syntax="$ac_default_prefix"
2967 fi
2968
2969 case ".[$]$1" in
2970 (.\[$]\(*\)*|.\'*\'*)
2971         ;;
2972 (..|./*|.\\*)
2973         ;;
2974 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
2975         ;;
2976 (.\[$]{*prefix}*|.\[$]{*dir}*)
2977         eval $1="[$]$1"
2978         case ".[$]$1" in
2979         (.NONE/*)
2980                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2981                 ;;
2982         esac
2983         ;;
2984 (.no|.NONE/*)
2985         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2986         ;;
2987 (*)
2988         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
2989         ;;
2990 esac
2991 ])dnl
2992 dnl ---------------------------------------------------------------------------
2993 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
2994 dnl -------------
2995 dnl Check for the package-config program, unless disabled by command-line.
2996 AC_DEFUN([CF_PKG_CONFIG],
2997 [
2998 AC_MSG_CHECKING(if you want to use pkg-config)
2999 AC_ARG_WITH(pkg-config,
3000         [  --with-pkg-config{=path} enable/disable use of pkg-config],
3001         [cf_pkg_config=$withval],
3002         [cf_pkg_config=yes])
3003 AC_MSG_RESULT($cf_pkg_config)
3004
3005 case $cf_pkg_config in
3006 (no)
3007         PKG_CONFIG=none
3008         ;;
3009 (yes)
3010         CF_ACVERSION_CHECK(2.52,
3011                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
3012                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
3013         ;;
3014 (*)
3015         PKG_CONFIG=$withval
3016         ;;
3017 esac
3018
3019 test -z "$PKG_CONFIG" && PKG_CONFIG=none
3020 if test "$PKG_CONFIG" != none ; then
3021         CF_PATH_SYNTAX(PKG_CONFIG)
3022 elif test "x$cf_pkg_config" != xno ; then
3023         AC_MSG_WARN(pkg-config is not installed)
3024 fi
3025
3026 AC_SUBST(PKG_CONFIG)
3027 ])dnl
3028 dnl ---------------------------------------------------------------------------
3029 dnl CF_POSIX_C_SOURCE version: 11 updated: 2018/12/31 20:46:17
3030 dnl -----------------
3031 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
3032 dnl
3033 dnl     POSIX.1-1990                            _POSIX_SOURCE
3034 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
3035 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
3036 dnl             Bindings Option
3037 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
3038 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
3039 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
3040 dnl
3041 dnl Parameters:
3042 dnl     $1 is the nominal value for _POSIX_C_SOURCE
3043 AC_DEFUN([CF_POSIX_C_SOURCE],
3044 [AC_REQUIRE([CF_POSIX_VISIBLE])dnl
3045
3046 if test "$cf_cv_posix_visible" = no; then
3047
3048 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
3049
3050 cf_save_CFLAGS="$CFLAGS"
3051 cf_save_CPPFLAGS="$CPPFLAGS"
3052
3053 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
3054 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
3055
3056 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
3057         CF_MSG_LOG(if the symbol is already defined go no further)
3058         AC_TRY_COMPILE([#include <sys/types.h>],[
3059 #ifndef _POSIX_C_SOURCE
3060 make an error
3061 #endif],
3062         [cf_cv_posix_c_source=no],
3063         [cf_want_posix_source=no
3064          case .$cf_POSIX_C_SOURCE in
3065          (.[[12]]??*)
3066                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
3067                 ;;
3068          (.2)
3069                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
3070                 cf_want_posix_source=yes
3071                 ;;
3072          (.*)
3073                 cf_want_posix_source=yes
3074                 ;;
3075          esac
3076          if test "$cf_want_posix_source" = yes ; then
3077                 AC_TRY_COMPILE([#include <sys/types.h>],[
3078 #ifdef _POSIX_SOURCE
3079 make an error
3080 #endif],[],
3081                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
3082          fi
3083          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
3084          CFLAGS="$cf_trim_CFLAGS"
3085          CPPFLAGS="$cf_trim_CPPFLAGS"
3086          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
3087          CF_MSG_LOG(if the second compile does not leave our definition intact error)
3088          AC_TRY_COMPILE([#include <sys/types.h>],[
3089 #ifndef _POSIX_C_SOURCE
3090 make an error
3091 #endif],,
3092          [cf_cv_posix_c_source=no])
3093          CFLAGS="$cf_save_CFLAGS"
3094          CPPFLAGS="$cf_save_CPPFLAGS"
3095         ])
3096 ])
3097
3098 if test "$cf_cv_posix_c_source" != no ; then
3099         CFLAGS="$cf_trim_CFLAGS"
3100         CPPFLAGS="$cf_trim_CPPFLAGS"
3101         CF_ADD_CFLAGS($cf_cv_posix_c_source)
3102 fi
3103
3104 fi # cf_cv_posix_visible
3105
3106 ])dnl
3107 dnl ---------------------------------------------------------------------------
3108 dnl CF_POSIX_VISIBLE version: 1 updated: 2018/12/31 20:46:17
3109 dnl ----------------
3110 dnl POSIX documents test-macros which an application may set before any system
3111 dnl headers are included to make features available.
3112 dnl
3113 dnl Some BSD platforms (originally FreeBSD, but copied by a few others)
3114 dnl diverged from POSIX in 2002 by setting symbols which make all of the most
3115 dnl recent features visible in the system header files unless the application
3116 dnl overrides the corresponding test-macros.  Doing that introduces portability
3117 dnl problems.
3118 dnl
3119 dnl This macro makes a special check for the symbols used for this, to avoid a
3120 dnl conflicting definition.
3121 AC_DEFUN([CF_POSIX_VISIBLE],
3122 [
3123 AC_CACHE_CHECK(if the POSIX test-macros are already defined,cf_cv_posix_visible,[
3124 AC_TRY_COMPILE([#include <stdio.h>],[
3125 #if defined(__POSIX_VISIBLE) && ((__POSIX_VISIBLE - 0L) > 0) \
3126         && defined(__XSI_VISIBLE) && ((__XSI_VISIBLE - 0L) > 0) \
3127         && defined(__BSD_VISIBLE) && ((__BSD_VISIBLE - 0L) > 0) \
3128         && defined(__ISO_C_VISIBLE) && ((__ISO_C_VISIBLE - 0L) > 0)
3129 #error conflicting symbols found
3130 #endif
3131 ],[cf_cv_posix_visible=no],[cf_cv_posix_visible=yes])
3132 ])
3133 ])dnl
3134 dnl ---------------------------------------------------------------------------
3135 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
3136 dnl ----------
3137 dnl Check for archiver "ar".
3138 AC_DEFUN([CF_PROG_AR],[
3139 AC_CHECK_TOOL(AR, ar, ar)
3140 ])
3141 dnl ---------------------------------------------------------------------------
3142 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
3143 dnl -----------
3144 dnl Check for awk, ensure that the check found something.
3145 AC_DEFUN([CF_PROG_AWK],
3146 [
3147 AC_PROG_AWK
3148 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
3149 ])dnl
3150 dnl ---------------------------------------------------------------------------
3151 dnl CF_PROG_CC version: 5 updated: 2019/12/31 08:53:54
3152 dnl ----------
3153 dnl standard check for CC, plus followup sanity checks
3154 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
3155 AC_DEFUN([CF_PROG_CC],[
3156 CF_ACVERSION_CHECK(2.53,
3157         [AC_MSG_WARN(this will incorrectly handle gnatgcc choice)
3158          AC_REQUIRE([AC_PROG_CC])],
3159         [])
3160 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
3161 CF_GCC_VERSION
3162 CF_ACVERSION_CHECK(2.52,
3163         [AC_PROG_CC_STDC],
3164         [CF_ANSI_CC_REQD])
3165 CF_CC_ENV_FLAGS
3166 ])dnl
3167 dnl ---------------------------------------------------------------------------
3168 dnl CF_PROG_CC_C_O version: 5 updated: 2017/01/21 11:06:25
3169 dnl --------------
3170 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
3171 dnl the output file can be renamed, and allows for a shell variable that can
3172 dnl be used later.  The parameter is either CC or CXX.  The result is the
3173 dnl cache variable:
3174 dnl     $cf_cv_prog_CC_c_o
3175 dnl     $cf_cv_prog_CXX_c_o
3176 dnl
3177 dnl $1 = compiler
3178 dnl $2 = compiler options, if any
3179 AC_DEFUN([CF_PROG_CC_C_O],
3180 [AC_REQUIRE([AC_PROG_CC])dnl
3181 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
3182 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
3183 [
3184 cat > conftest.$ac_ext <<CF_EOF
3185 int main(void)
3186 {
3187         ${cf_cv_main_return:-return}(0);
3188 }
3189 CF_EOF
3190 # We do the test twice because some compilers refuse to overwrite an
3191 # existing .o file with -o, though they will create one.
3192 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
3193 if AC_TRY_EVAL(ac_try) &&
3194   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
3195 then
3196   eval cf_cv_prog_$1_c_o=yes
3197 else
3198   eval cf_cv_prog_$1_c_o=no
3199 fi
3200 rm -rf conftest*
3201 ])dnl
3202 if test $cf_cv_prog_$1_c_o = yes; then
3203   AC_MSG_RESULT([yes])
3204 else
3205   AC_MSG_RESULT([no])
3206 fi
3207 ])dnl
3208 dnl ---------------------------------------------------------------------------
3209 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
3210 dnl -------------
3211 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
3212 dnl This macro adds a check to ensure the script found something.
3213 AC_DEFUN([CF_PROG_EGREP],
3214 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
3215         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
3216                 then ac_cv_prog_egrep='grep -E'
3217                 else ac_cv_prog_egrep='egrep'
3218         fi])
3219         EGREP=$ac_cv_prog_egrep
3220         AC_SUBST([EGREP])
3221         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
3222 ])dnl
3223 dnl ---------------------------------------------------------------------------
3224 dnl CF_PROG_EXT version: 14 updated: 2018/06/20 20:23:13
3225 dnl -----------
3226 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
3227 AC_DEFUN([CF_PROG_EXT],
3228 [
3229 AC_REQUIRE([CF_CHECK_CACHE])
3230 case $cf_cv_system_name in
3231 (os2*)
3232         CFLAGS="$CFLAGS -Zmt"
3233         CF_APPEND_TEXT(CPPFLAGS,-D__ST_MT_ERRNO__)
3234         CXXFLAGS="$CXXFLAGS -Zmt"
3235         # autoconf's macro sets -Zexe and suffix both, which conflict:w
3236         LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
3237         ac_cv_exeext=.exe
3238         ;;
3239 esac
3240
3241 AC_EXEEXT
3242 AC_OBJEXT
3243
3244 PROG_EXT="$EXEEXT"
3245 AC_SUBST(PROG_EXT)
3246 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT",[Define to the program extension (normally blank)])
3247 ])dnl
3248 dnl ---------------------------------------------------------------------------
3249 dnl CF_PROG_GNAT version: 10 updated: 2019/12/31 08:53:54
3250 dnl ------------
3251 dnl Check for gnat/gnatmake/etc, ensure that the toolset is complete.
3252 AC_DEFUN([CF_PROG_GNAT],[
3253 for cf_prog_gnat in gnat gnatmake gprconfig gprbuild
3254 do
3255         CF_UPPER(cf_upper_prog_gnat,${cf_prog_gnat})
3256
3257         unset ac_cv_path_cf_TEMP_gnat
3258         unset cf_TEMP_gnat
3259         AC_PATH_PROG(cf_TEMP_gnat,$cf_prog_gnat,no)
3260         eval cf_cv_PATH_$cf_upper_prog_gnat=[$]ac_cv_path_cf_TEMP_gnat
3261
3262         if test "x$cf_TEMP_gnat" != xno; then
3263                 unset cf_cv_gnat_version
3264                 unset cf_TEMP_gnat
3265                 CF_GNAT_VERSION(cf_TEMP_gnat,$cf_prog_gnat)
3266         fi
3267         eval cf_cv_VERSION_$cf_upper_prog_gnat=[$]cf_TEMP_gnat
3268
3269         unset cf_TEMP_gnat
3270         unset cf_cv_gnat_version
3271         unset ac_cv_path_cf_TEMP_gnat
3272 done
3273
3274 if test "x$cf_cv_VERSION_GNATMAKE" = "xno"; then
3275         cf_ada_make=
3276         cf_cv_prog_gnat_correct=no
3277 else
3278         cf_ada_make=gnatmake
3279         if test "x$cf_cv_VERSION_GPRCONFIG" = "xno"; then
3280                 # gprconfig is newer than gnatmake; we can continue...
3281                 cf_ada_config="##"
3282         else
3283                 rm -rf conftest* *~conftest*
3284                 if mkdir conftest.src
3285                 then
3286                         cf_ada_config=""
3287                         cd conftest.src
3288                         for cf_gprconfig in Ada C
3289                         do
3290                                 AC_MSG_CHECKING(for gprconfig name for $cf_gprconfig)
3291                                 if test $cf_gprconfig = C
3292                                 then
3293                                         for cf_gprconfig_param in \
3294                                                 $cf_gprconfig,,,,GNATGCC \
3295                                                 $cf_gprconfig,,,,GCC \
3296                                                 $cf_gprconfig
3297                                         do
3298                                                 cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
3299                                                 test -n "$cf_gprconfig_value" && break
3300                                         done
3301                                 else
3302                                         cf_gprconfig_param=$cf_gprconfig
3303                                         cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
3304                                 fi
3305                                 if test -n "$cf_gprconfig_value"
3306                                 then
3307                                         eval cf_ada_config_[$]cf_gprconfig=[$]cf_gprconfig_value
3308                                         AC_MSG_RESULT($cf_gprconfig_value)
3309                                 else
3310                                         AC_MSG_RESULT(missing)
3311                                         cf_ada_config="#"
3312                                         break
3313                                 fi
3314                         done
3315                         cd ..
3316                         rm -rf conftest* *~conftest*
3317                 fi
3318         fi
3319         if test "x$cf_ada_config" != "x#"
3320         then
3321                 CF_GNAT_VERSION
3322                 CF_CHECK_GNAT_VERSION
3323                 AC_CHECK_PROG(M4_exists, m4, yes, no)
3324                 if test "$ac_cv_prog_M4_exists" = no; then
3325                         cf_cv_prog_gnat_correct=no
3326                         AC_MSG_WARN(Ada95 binding required program m4 not found. Ada95 binding disabled)
3327                 fi
3328                 if test "$cf_cv_prog_gnat_correct" = yes; then
3329                         AC_MSG_CHECKING(if GNAT works)
3330                         CF_GNAT_TRY_RUN([procedure conftest;],
3331 [with Text_IO;
3332 with GNAT.OS_Lib;
3333 procedure conftest is
3334 begin
3335    Text_IO.Put ("Hello World");
3336    Text_IO.New_Line;
3337    GNAT.OS_Lib.OS_Exit (0);
3338 end conftest;],
3339 [cf_cv_prog_gnat_correct=yes],
3340 [cf_cv_prog_gnat_correct=no])
3341                         AC_MSG_RESULT($cf_cv_prog_gnat_correct)
3342                 fi
3343         else
3344                 cf_cv_prog_gnat_correct=no
3345         fi
3346 fi
3347
3348 AC_SUBST(cf_ada_make)
3349 AC_SUBST(cf_ada_config)
3350 AC_SUBST(cf_ada_config_Ada)
3351 AC_SUBST(cf_ada_config_C)
3352 ])dnl
3353 dnl ---------------------------------------------------------------------------
3354 dnl CF_PROG_INSTALL version: 7 updated: 2015/04/18 08:56:57
3355 dnl ---------------
3356 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
3357 dnl misc/tabset install won't work properly.  Usually this happens only when
3358 dnl using the fallback mkinstalldirs script
3359 AC_DEFUN([CF_PROG_INSTALL],
3360 [AC_PROG_INSTALL
3361 case $INSTALL in
3362 (/*)
3363         ;;
3364 (*)
3365         CF_DIRNAME(cf_dir,$INSTALL)
3366         test -z "$cf_dir" && cf_dir=.
3367         INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
3368         ;;
3369 esac
3370 ])dnl
3371 dnl ---------------------------------------------------------------------------
3372 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
3373 dnl ------------
3374 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
3375 dnl option if it is supported.
3376 AC_DEFUN([CF_PROG_LN_S],[
3377 AC_PROG_LN_S
3378 AC_MSG_CHECKING(if $LN_S -f options work)
3379
3380 rm -f conf$$.src conf$$dst
3381 echo >conf$$.dst
3382 echo first >conf$$.src
3383 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
3384         cf_prog_ln_sf=yes
3385 else
3386         cf_prog_ln_sf=no
3387 fi
3388 rm -f conf$$.dst conf$$src
3389 AC_MSG_RESULT($cf_prog_ln_sf)
3390
3391 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
3392 ])dnl
3393 dnl ---------------------------------------------------------------------------
3394 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
3395 dnl ----------------
3396 dnl Remove all -U and -D options that refer to the given symbol from a list
3397 dnl of C compiler options.  This works around the problem that not all
3398 dnl compilers process -U and -D options from left-to-right, so a -U option
3399 dnl cannot be used to cancel the effect of a preceding -D option.
3400 dnl
3401 dnl $1 = target (which could be the same as the source variable)
3402 dnl $2 = source (including '$')
3403 dnl $3 = symbol to remove
3404 define([CF_REMOVE_DEFINE],
3405 [
3406 $1=`echo "$2" | \
3407         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
3408                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
3409 ])dnl
3410 dnl ---------------------------------------------------------------------------
3411 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
3412 dnl -------------
3413 dnl Remove the given library from the symbol
3414 dnl
3415 dnl $1 = target (which could be the same as the source variable)
3416 dnl $2 = source (including '$')
3417 dnl $3 = library to remove
3418 define([CF_REMOVE_LIB],
3419 [
3420 # remove $3 library from $2
3421 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
3422 ])dnl
3423 dnl ---------------------------------------------------------------------------
3424 dnl CF_RESTORE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:47:45
3425 dnl ---------------------
3426 dnl Restore flags saved in CF_SAVE_XTRA_FLAGS
3427 dnl $1 = name of current macro
3428 define([CF_RESTORE_XTRA_FLAGS],
3429 [
3430 LIBS="$cf_save_LIBS_$1"
3431 CFLAGS="$cf_save_CFLAGS_$1"
3432 CPPFLAGS="$cf_save_CPPFLAGS_$1"
3433 ])dnl
3434 dnl ---------------------------------------------------------------------------
3435 dnl CF_SAVE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:46:44
3436 dnl ------------------
3437 dnl Use this macro to save CFLAGS/CPPFLAGS/LIBS before checks against X headers
3438 dnl and libraries which do not update those variables.
3439 dnl
3440 dnl $1 = name of current macro
3441 define([CF_SAVE_XTRA_FLAGS],
3442 [
3443 cf_save_LIBS_$1="$LIBS"
3444 cf_save_CFLAGS_$1="$CFLAGS"
3445 cf_save_CPPFLAGS_$1="$CPPFLAGS"
3446 LIBS="$LIBS ${X_PRE_LIBS} ${X_LIBS} ${X_EXTRA_LIBS}"
3447 for cf_X_CFLAGS in $X_CFLAGS
3448 do
3449         case "x$cf_X_CFLAGS" in
3450         x-[[IUD]]*)
3451                 CPPFLAGS="$CPPFLAGS $cf_X_CFLAGS"
3452                 ;;
3453         *)
3454                 CFLAGS="$CFLAGS $cf_X_CFLAGS"
3455                 ;;
3456         esac
3457 done
3458 ])dnl
3459 dnl ---------------------------------------------------------------------------
3460 dnl CF_SHARED_OPTS version: 93 updated: 2018/08/18 16:36:35
3461 dnl --------------
3462 dnl --------------
3463 dnl Attempt to determine the appropriate CC/LD options for creating a shared
3464 dnl library.
3465 dnl
3466 dnl Notes:
3467 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
3468 dnl the build-tree, i.e., by making use of the libraries that are compiled in
3469 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
3470 dnl shared library since that can lead to unexpected results at runtime.
3471 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
3472 dnl libraries are compiled in ../../lib
3473 dnl
3474 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
3475 dnl to install symbolic links to the rel/abi versions of shared libraries.
3476 dnl
3477 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
3478 dnl version when making symbolic links.
3479 dnl
3480 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
3481 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
3482 dnl (ex: libncurses.so.<ver>).
3483 dnl
3484 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
3485 AC_DEFUN([CF_SHARED_OPTS],
3486 [
3487         AC_REQUIRE([CF_LD_RPATH_OPT])
3488
3489         RM_SHARED_OPTS=
3490         LOCAL_LDFLAGS=
3491         LOCAL_LDFLAGS2=
3492         LD_SHARED_OPTS=
3493         INSTALL_LIB="-m 644"
3494         : ${rel_builddir:=.}
3495
3496         shlibdir=$libdir
3497         AC_SUBST(shlibdir)
3498
3499         MAKE_DLLS="#"
3500         AC_SUBST(MAKE_DLLS)
3501
3502         cf_cv_do_symlinks=no
3503         cf_ld_rpath_opt=
3504         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
3505
3506         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
3507         AC_ARG_WITH(shlib-version,
3508         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
3509         [test -z "$withval" && withval=auto
3510         case $withval in
3511         (yes)
3512                 cf_cv_shlib_version=auto
3513                 ;;
3514         (rel|abi|auto)
3515                 cf_cv_shlib_version=$withval
3516                 ;;
3517         (*)
3518                 AC_MSG_RESULT($withval)
3519                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
3520                 ;;
3521         esac
3522         ],[cf_cv_shlib_version=auto])
3523         AC_MSG_RESULT($cf_cv_shlib_version)
3524
3525         cf_cv_rm_so_locs=no
3526         cf_try_cflags=
3527
3528         # Some less-capable ports of gcc support only -fpic
3529         CC_SHARED_OPTS=
3530
3531         cf_try_fPIC=no
3532         if test "$GCC" = yes
3533         then
3534                 cf_try_fPIC=yes
3535         else
3536                 case $cf_cv_system_name in
3537                 (*linux*)       # e.g., PGI compiler
3538                         cf_try_fPIC=yes
3539                         ;;
3540                 esac
3541         fi
3542
3543         if test "$cf_try_fPIC" = yes
3544         then
3545                 AC_MSG_CHECKING(which $CC option to use)
3546                 cf_save_CFLAGS="$CFLAGS"
3547                 for CC_SHARED_OPTS in -fPIC -fpic ''
3548                 do
3549                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
3550                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
3551                 done
3552                 AC_MSG_RESULT($CC_SHARED_OPTS)
3553                 CFLAGS="$cf_save_CFLAGS"
3554         fi
3555
3556         cf_cv_shlib_version_infix=no
3557
3558         case $cf_cv_system_name in
3559         (aix4.[3-9]*|aix[[5-7]]*)
3560                 if test "$GCC" = yes; then
3561                         CC_SHARED_OPTS='-Wl,-brtl'
3562                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
3563                 else
3564                         CC_SHARED_OPTS='-brtl'
3565                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
3566                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
3567                 fi
3568                 ;;
3569         (beos*)
3570                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
3571                 ;;
3572         (cygwin*)
3573                 CC_SHARED_OPTS=
3574                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3575                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3576                 cf_cv_shlib_version=cygdll
3577                 cf_cv_shlib_version_infix=cygdll
3578                 shlibdir=$bindir
3579                 MAKE_DLLS=
3580                 cat >mk_shared_lib.sh <<-CF_EOF
3581                 #!$SHELL
3582                 SHARED_LIB=\[$]1
3583                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3584                 shift
3585                 cat <<-EOF
3586                 Linking shared library
3587                 ** SHARED_LIB \[$]SHARED_LIB
3588                 ** IMPORT_LIB \[$]IMPORT_LIB
3589 EOF
3590                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3591 CF_EOF
3592                 chmod +x mk_shared_lib.sh
3593                 ;;
3594         (msys*)
3595                 CC_SHARED_OPTS=
3596                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3597                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3598                 cf_cv_shlib_version=msysdll
3599                 cf_cv_shlib_version_infix=msysdll
3600                 shlibdir=$bindir
3601                 MAKE_DLLS=
3602                 cat >mk_shared_lib.sh <<-CF_EOF
3603                 #!$SHELL
3604                 SHARED_LIB=\[$]1
3605                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3606                 shift
3607                 cat <<-EOF
3608                 Linking shared library
3609                 ** SHARED_LIB \[$]SHARED_LIB
3610                 ** IMPORT_LIB \[$]IMPORT_LIB
3611 EOF
3612                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3613 CF_EOF
3614                 chmod +x mk_shared_lib.sh
3615                 ;;
3616         (darwin*)
3617                 cf_try_cflags="no-cpp-precomp"
3618                 CC_SHARED_OPTS="-dynamic"
3619                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
3620                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
3621                 cf_cv_shlib_version_infix=yes
3622                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
3623                         cf_save_LDFLAGS=$LDFLAGS
3624                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3625                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
3626                                 LDFLAGS=$cf_save_LDFLAGS])
3627                 if test $cf_cv_ldflags_search_paths_first = yes; then
3628                         LDFL