Ada95/aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 2010,2011 Free Software Foundation, Inc.                   *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.20 2011/01/22 19:46:50 tom Exp $
  32 dnl Macros used in NCURSES Ada95 auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl CF_ADA_INCLUDE_DIRS version: 6 updated: 2010/02/26 19:52:07
  43 dnl -------------------
  44 dnl Construct the list of include-options for the C programs in the Ada95
  45 dnl binding.
  46 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  47 [
  48 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  49 if test "$srcdir" != "."; then
  50         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
  51 fi
  52 if test "$GCC" != yes; then
  53         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  54 elif test "$includedir" != "/usr/include"; then
  55         if test "$includedir" = '${prefix}/include' ; then
  56                 if test $prefix != /usr ; then
  57                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  58                 fi
  59         else
  60                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  61         fi
  62 fi
  63 AC_SUBST(ACPPFLAGS)
  64 ])dnl
  65 dnl ---------------------------------------------------------------------------
  66 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
  67 dnl ---------------
  68 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
  69 AC_DEFUN([CF_ADD_ADAFLAGS],[
  70         ADAFLAGS="$ADAFLAGS $1"
  71         AC_SUBST(ADAFLAGS)
  72 ])dnl
  73 dnl ---------------------------------------------------------------------------
  74 dnl CF_ADD_CFLAGS version: 10 updated: 2010/05/26 05:38:42
  75 dnl -------------
  76 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
  77 dnl The second parameter if given makes this macro verbose.
  78 dnl
  79 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
  80 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
  81 dnl confused by the quotes (which require backslashes to keep them usable).
  82 AC_DEFUN([CF_ADD_CFLAGS],
  83 [
  84 cf_fix_cppflags=no
  85 cf_new_cflags=
  86 cf_new_cppflags=
  87 cf_new_extra_cppflags=
  88
  89 for cf_add_cflags in $1
  90 do
  91 case $cf_fix_cppflags in
  92 no)
  93         case $cf_add_cflags in #(vi
  94         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
  95                 case $cf_add_cflags in
  96                 -D*)
  97                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
  98
  99                         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 100                                 && test -z "${cf_tst_cflags}" \
 101                                 && cf_fix_cppflags=yes
 102
 103                         if test $cf_fix_cppflags = yes ; then
 104                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 105                                 continue
 106                         elif test "${cf_tst_cflags}" = "\"'" ; then
 107                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 108                                 continue
 109                         fi
 110                         ;;
 111                 esac
 112                 case "$CPPFLAGS" in
 113                 *$cf_add_cflags) #(vi
 114                         ;;
 115                 *) #(vi
 116                         case $cf_add_cflags in #(vi
 117                         -D*)
 118                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 119                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 120                                 ;;
 121                         esac
 122                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 123                         ;;
 124                 esac
 125                 ;;
 126         *)
 127                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 128                 ;;
 129         esac
 130         ;;
 131 yes)
 132         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 133
 134         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 135
 136         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 137                 && test -z "${cf_tst_cflags}" \
 138                 && cf_fix_cppflags=no
 139         ;;
 140 esac
 141 done
 142
 143 if test -n "$cf_new_cflags" ; then
 144         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 145         CFLAGS="$CFLAGS $cf_new_cflags"
 146 fi
 147
 148 if test -n "$cf_new_cppflags" ; then
 149         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 150         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 151 fi
 152
 153 if test -n "$cf_new_extra_cppflags" ; then
 154         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 155         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 156 fi
 157
 158 AC_SUBST(EXTRA_CPPFLAGS)
 159
 160 ])dnl
 161 dnl ---------------------------------------------------------------------------
 162 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
 163 dnl -------------
 164 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 165 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 166 dnl but old versions (and some misinstalled ones) need that.  To make things
 167 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 168 dnl the include-path).
 169 AC_DEFUN([CF_ADD_INCDIR],
 170 [
 171 if test -n "$1" ; then
 172   for cf_add_incdir in $1
 173   do
 174         while test $cf_add_incdir != /usr/include
 175         do
 176           if test -d $cf_add_incdir
 177           then
 178                 cf_have_incdir=no
 179                 if test -n "$CFLAGS$CPPFLAGS" ; then
 180                   # a loop is needed to ensure we can add subdirs of existing dirs
 181                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 182                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 183                           cf_have_incdir=yes; break
 184                         fi
 185                   done
 186                 fi
 187
 188                 if test "$cf_have_incdir" = no ; then
 189                   if test "$cf_add_incdir" = /usr/local/include ; then
 190                         if test "$GCC" = yes
 191                         then
 192                           cf_save_CPPFLAGS=$CPPFLAGS
 193                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 194                           AC_TRY_COMPILE([#include <stdio.h>],
 195                                   [printf("Hello")],
 196                                   [],
 197                                   [cf_have_incdir=yes])
 198                           CPPFLAGS=$cf_save_CPPFLAGS
 199                         fi
 200                   fi
 201                 fi
 202
 203                 if test "$cf_have_incdir" = no ; then
 204                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 205                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 206
 207                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 208                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 209                   cf_add_incdir="$cf_top_incdir"
 210                 else
 211                   break
 212                 fi
 213           fi
 214         done
 215   done
 216 fi
 217 ])dnl
 218 dnl ---------------------------------------------------------------------------
 219 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 220 dnl ----------
 221 dnl Add a library, used to enforce consistency.
 222 dnl
 223 dnl $1 = library to add, without the "-l"
 224 dnl $2 = variable to update (default $LIBS)
 225 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 226 dnl ---------------------------------------------------------------------------
 227 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
 228 dnl -------------
 229 dnl     Adds to the library-path
 230 dnl
 231 dnl     Some machines have trouble with multiple -L options.
 232 dnl
 233 dnl $1 is the (list of) directory(s) to add
 234 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 235 dnl
 236 AC_DEFUN([CF_ADD_LIBDIR],
 237 [
 238 if test -n "$1" ; then
 239   for cf_add_libdir in $1
 240   do
 241     if test $cf_add_libdir = /usr/lib ; then
 242       :
 243     elif test -d $cf_add_libdir
 244     then
 245       cf_have_libdir=no
 246       if test -n "$LDFLAGS$LIBS" ; then
 247         # a loop is needed to ensure we can add subdirs of existing dirs
 248         for cf_test_libdir in $LDFLAGS $LIBS ; do
 249           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 250             cf_have_libdir=yes; break
 251           fi
 252         done
 253       fi
 254       if test "$cf_have_libdir" = no ; then
 255         CF_VERBOSE(adding $cf_add_libdir to library-path)
 256         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 257       fi
 258     fi
 259   done
 260 fi
 261 ])dnl
 262 dnl ---------------------------------------------------------------------------
 263 dnl CF_ADD_LIBS version: 1 updated: 2010/06/02 05:03:05
 264 dnl -----------
 265 dnl Add one or more libraries, used to enforce consistency.
 266 dnl
 267 dnl $1 = libraries to add, with the "-l", etc.
 268 dnl $2 = variable to update (default $LIBS)
 269 AC_DEFUN([CF_ADD_LIBS],[ifelse($2,,LIBS,[$2])="$1 [$]ifelse($2,,LIBS,[$2])"])dnl
 270 dnl ---------------------------------------------------------------------------
 271 dnl CF_ADD_SUBDIR_PATH version: 3 updated: 2010/07/03 20:58:12
 272 dnl ------------------
 273 dnl Append to a search-list for a nonstandard header/lib-file
 274 dnl     $1 = the variable to return as result
 275 dnl     $2 = the package name
 276 dnl     $3 = the subdirectory, e.g., bin, include or lib
 277 dnl $4 = the directory under which we will test for subdirectories
 278 dnl $5 = a directory that we do not want $4 to match
 279 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 280 [
 281 test "$4" != "$5" && \
 282 test -d "$4" && \
 283 ifelse([$5],NONE,,[(test $5 = NONE || test "$4" != "$5") &&]) {
 284         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 285         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 286         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 287         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 288         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 289         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 290 }
 291 ])dnl
 292 dnl ---------------------------------------------------------------------------
 293 dnl CF_ANSI_CC_CHECK version: 10 updated: 2010/10/23 15:52:32
 294 dnl ----------------
 295 dnl This is adapted from the macros 'fp_PROG_CC_STDC' and 'fp_C_PROTOTYPES'
 296 dnl in the sharutils 4.2 distribution.
 297 AC_DEFUN([CF_ANSI_CC_CHECK],
 298 [
 299 AC_CACHE_CHECK(for ${CC:-cc} option to accept ANSI C, cf_cv_ansi_cc,[
 300 cf_cv_ansi_cc=no
 301 cf_save_CFLAGS="$CFLAGS"
 302 cf_save_CPPFLAGS="$CPPFLAGS"
 303 # Don't try gcc -ansi; that turns off useful extensions and
 304 # breaks some systems' header files.
 305 # AIX                   -qlanglvl=ansi
 306 # Ultrix and OSF/1      -std1
 307 # HP-UX                 -Aa -D_HPUX_SOURCE
 308 # SVR4                  -Xc
 309 # UnixWare 1.2          (cannot use -Xc, since ANSI/POSIX clashes)
 310 for cf_arg in "-DCC_HAS_PROTOS" \
 311         "" \
 312         -qlanglvl=ansi \
 313         -std1 \
 314         -Ae \
 315         "-Aa -D_HPUX_SOURCE" \
 316         -Xc
 317 do
 318         CF_ADD_CFLAGS($cf_arg)
 319         AC_TRY_COMPILE(
 320 [
 321 #ifndef CC_HAS_PROTOS
 322 #if !defined(__STDC__) || (__STDC__ != 1)
 323 choke me
 324 #endif
 325 #endif
 326 ],[
 327         int test (int i, double x);
 328         struct s1 {int (*f) (int a);};
 329         struct s2 {int (*f) (double a);};],
 330         [cf_cv_ansi_cc="$cf_arg"; break])
 331 done
 332 CFLAGS="$cf_save_CFLAGS"
 333 CPPFLAGS="$cf_save_CPPFLAGS"
 334 ])
 335
 336 if test "$cf_cv_ansi_cc" != "no"; then
 337 if test ".$cf_cv_ansi_cc" != ".-DCC_HAS_PROTOS"; then
 338         CF_ADD_CFLAGS($cf_cv_ansi_cc)
 339 else
 340         AC_DEFINE(CC_HAS_PROTOS)
 341 fi
 342 fi
 343 ])dnl
 344 dnl ---------------------------------------------------------------------------
 345 dnl CF_ANSI_CC_REQD version: 4 updated: 2008/03/23 14:48:54
 346 dnl ---------------
 347 dnl For programs that must use an ANSI compiler, obtain compiler options that
 348 dnl will make it recognize prototypes.  We'll do preprocessor checks in other
 349 dnl macros, since tools such as unproto can fake prototypes, but only part of
 350 dnl the preprocessor.
 351 AC_DEFUN([CF_ANSI_CC_REQD],
 352 [AC_REQUIRE([CF_ANSI_CC_CHECK])
 353 if test "$cf_cv_ansi_cc" = "no"; then
 354         AC_MSG_ERROR(
 355 [Your compiler does not appear to recognize prototypes.
 356 You have the following choices:
 357         a. adjust your compiler options
 358         b. get an up-to-date compiler
 359         c. use a wrapper such as unproto])
 360 fi
 361 ])dnl
 362 dnl ---------------------------------------------------------------------------
 363 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
 364 dnl -----------
 365 dnl Check for suitable "ar" (archiver) options for updating an archive.
 366 AC_DEFUN([CF_AR_FLAGS],[
 367 AC_REQUIRE([CF_PROG_AR])
 368
 369 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 370         cf_cv_ar_flags=unknown
 371         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
 372         do
 373
 374                 # check if $ARFLAGS already contains this choice
 375                 if test "x$ARFLAGS" != "x" ; then
 376                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 377                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 378                                 cf_cv_ar_flags=
 379                                 break
 380                         fi
 381                 fi
 382
 383                 rm -f conftest.$ac_cv_objext
 384                 rm -f conftest.a
 385
 386                 cat >conftest.$ac_ext <<EOF
 387 #line __oline__ "configure"
 388 int     testdata[[3]] = { 123, 456, 789 };
 389 EOF
 390                 if AC_TRY_EVAL(ac_compile) ; then
 391                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 392                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 393                         if test -f conftest.a ; then
 394                                 cf_cv_ar_flags=$cf_ar_flags
 395                                 break
 396                         fi
 397                 else
 398                         CF_VERBOSE(cannot compile test-program)
 399                         break
 400                 fi
 401         done
 402         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 403 ])
 404
 405 if test -n "$ARFLAGS" ; then
 406         if test -n "$cf_cv_ar_flags" ; then
 407                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 408         fi
 409 else
 410         ARFLAGS=$cf_cv_ar_flags
 411 fi
 412
 413 AC_SUBST(ARFLAGS)
 414 ])
 415 dnl ---------------------------------------------------------------------------
 416 dnl CF_BUILD_CC version: 6 updated: 2006/10/14 15:23:15
 417 dnl -----------
 418 dnl If we're cross-compiling, allow the user to override the tools and their
 419 dnl options.  The configure script is oriented toward identifying the host
 420 dnl compiler, etc., but we need a build compiler to generate parts of the
 421 dnl source.
 422 dnl
 423 dnl $1 = default for $CPPFLAGS
 424 dnl $2 = default for $LIBS
 425 AC_DEFUN([CF_BUILD_CC],[
 426 AC_REQUIRE([CF_PROG_EXT])
 427 if test "$cross_compiling" = yes ; then
 428
 429         # defaults that we might want to override
 430         : ${BUILD_CFLAGS:=''}
 431         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 432         : ${BUILD_LDFLAGS:=''}
 433         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 434         : ${BUILD_EXEEXT:='$x'}
 435         : ${BUILD_OBJEXT:='o'}
 436
 437         AC_ARG_WITH(build-cc,
 438                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 439                 [BUILD_CC="$withval"],
 440                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 441         AC_MSG_CHECKING(for native build C compiler)
 442         AC_MSG_RESULT($BUILD_CC)
 443
 444         AC_MSG_CHECKING(for native build C preprocessor)
 445         AC_ARG_WITH(build-cpp,
 446                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 447                 [BUILD_CPP="$withval"],
 448                 [BUILD_CPP='${BUILD_CC} -E'])
 449         AC_MSG_RESULT($BUILD_CPP)
 450
 451         AC_MSG_CHECKING(for native build C flags)
 452         AC_ARG_WITH(build-cflags,
 453                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 454                 [BUILD_CFLAGS="$withval"])
 455         AC_MSG_RESULT($BUILD_CFLAGS)
 456
 457         AC_MSG_CHECKING(for native build C preprocessor-flags)
 458         AC_ARG_WITH(build-cppflags,
 459                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 460                 [BUILD_CPPFLAGS="$withval"])
 461         AC_MSG_RESULT($BUILD_CPPFLAGS)
 462
 463         AC_MSG_CHECKING(for native build linker-flags)
 464         AC_ARG_WITH(build-ldflags,
 465                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 466                 [BUILD_LDFLAGS="$withval"])
 467         AC_MSG_RESULT($BUILD_LDFLAGS)
 468
 469         AC_MSG_CHECKING(for native build linker-libraries)
 470         AC_ARG_WITH(build-libs,
 471                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 472                 [BUILD_LIBS="$withval"])
 473         AC_MSG_RESULT($BUILD_LIBS)
 474
 475         # this assumes we're on Unix.
 476         BUILD_EXEEXT=
 477         BUILD_OBJEXT=o
 478
 479         : ${BUILD_CC:='${CC}'}
 480
 481         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 482                 AC_MSG_ERROR([Cross-build requires two compilers.
 483 Use --with-build-cc to specify the native compiler.])
 484         fi
 485
 486 else
 487         : ${BUILD_CC:='${CC}'}
 488         : ${BUILD_CPP:='${CPP}'}
 489         : ${BUILD_CFLAGS:='${CFLAGS}'}
 490         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 491         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 492         : ${BUILD_LIBS:='${LIBS}'}
 493         : ${BUILD_EXEEXT:='$x'}
 494         : ${BUILD_OBJEXT:='o'}
 495 fi
 496
 497 AC_SUBST(BUILD_CC)
 498 AC_SUBST(BUILD_CPP)
 499 AC_SUBST(BUILD_CFLAGS)
 500 AC_SUBST(BUILD_CPPFLAGS)
 501 AC_SUBST(BUILD_LDFLAGS)
 502 AC_SUBST(BUILD_LIBS)
 503 AC_SUBST(BUILD_EXEEXT)
 504 AC_SUBST(BUILD_OBJEXT)
 505 ])dnl
 506 dnl ---------------------------------------------------------------------------
 507 dnl CF_CFG_DEFAULTS version: 7 updated: 2005/09/24 16:15:00
 508 dnl ---------------
 509 dnl Determine the default configuration into which we'll install ncurses.  This
 510 dnl can be overridden by the user's command-line options.  There's two items to
 511 dnl look for:
 512 dnl     1. the prefix (e.g., /usr)
 513 dnl     2. the header files (e.g., /usr/include/ncurses)
 514 dnl We'll look for a previous installation of ncurses and use the same defaults.
 515 dnl
 516 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 517 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 518 dnl programs from a vendor's.
 519 AC_DEFUN([CF_CFG_DEFAULTS],
 520 [
 521 AC_MSG_CHECKING(for prefix)
 522 if test "x$prefix" = "xNONE" ; then
 523         case "$cf_cv_system_name" in
 524                 # non-vendor systems don't have a conflict
 525         openbsd*|freebsd*|linux*|cygwin*|k*bsd*-gnu)
 526                 prefix=/usr
 527                 ;;
 528         *)      prefix=$ac_default_prefix
 529                 ;;
 530         esac
 531 fi
 532 AC_MSG_RESULT($prefix)
 533
 534 if test "x$prefix" = "xNONE" ; then
 535 AC_MSG_CHECKING(for default include-directory)
 536 test -n "$verbose" && echo 1>&AC_FD_MSG
 537 for cf_symbol in \
 538         $includedir \
 539         $includedir/ncurses \
 540         $prefix/include \
 541         $prefix/include/ncurses \
 542         /usr/local/include \
 543         /usr/local/include/ncurses \
 544         /usr/include \
 545         /usr/include/ncurses
 546 do
 547         cf_dir=`eval echo $cf_symbol`
 548         if test -f $cf_dir/curses.h ; then
 549         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 550                 includedir="$cf_symbol"
 551                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 552                 break
 553         fi
 554         fi
 555         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 556 done
 557 AC_MSG_RESULT($includedir)
 558 fi
 559 ])dnl
 560 dnl ---------------------------------------------------------------------------
 561 dnl CF_CHECK_CACHE version: 11 updated: 2008/03/23 14:45:59
 562 dnl --------------
 563 dnl Check if we're accidentally using a cache from a different machine.
 564 dnl Derive the system name, as a check for reusing the autoconf cache.
 565 dnl
 566 dnl If we've packaged config.guess and config.sub, run that (since it does a
 567 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 568 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 569 dnl which is useful in cross-compiles.
 570 dnl
 571 dnl Note: we would use $ac_config_sub, but that is one of the places where
 572 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 573 AC_DEFUN([CF_CHECK_CACHE],
 574 [
 575 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 576         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 577         system_name="$host_os"
 578 else
 579         system_name="`(uname -s -r) 2>/dev/null`"
 580         if test -z "$system_name" ; then
 581                 system_name="`(hostname) 2>/dev/null`"
 582         fi
 583 fi
 584 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name")
 585 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 586
 587 test -z "$system_name" && system_name="$cf_cv_system_name"
 588 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 589
 590 if test ".$system_name" != ".$cf_cv_system_name" ; then
 591         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 592         AC_MSG_ERROR("Please remove config.cache and try again.")
 593 fi
 594 ])dnl
 595 dnl ---------------------------------------------------------------------------
 596 dnl CF_CURSES_HEADER version: 2 updated: 2010/04/28 06:02:16
 597 dnl ----------------
 598 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
 599 dnl variations of ncurses' installs.
 600 dnl
 601 dnl $1 = ncurses when looking for ncurses, or is empty
 602 AC_DEFUN([CF_CURSES_HEADER],[
 603 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
 604 cf_cv_ncurses_header=none
 605 for cf_header in ifelse($1,,,[ \
 606     $1/curses.h \
 607         $1/ncurses.h]) \
 608         curses.h \
 609         ncurses.h ifelse($1,,[ncurses/curses.h ncurses/ncurses.h])
 610 do
 611 AC_TRY_COMPILE([#include <${cf_header}>],
 612         [initscr(); tgoto("?", 0,0)],
 613         [cf_cv_ncurses_header=$cf_header; break],[])
 614 done
 615 ])
 616
 617 if test "$cf_cv_ncurses_header" = none ; then
 618         AC_MSG_ERROR(No curses header-files found)
 619 fi
 620
 621 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
 622 AC_CHECK_HEADERS($cf_cv_ncurses_header)
 623 ])dnl
 624 dnl ---------------------------------------------------------------------------
 625 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
 626 dnl ----------
 627 dnl "dirname" is not portable, so we fake it with a shell script.
 628 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
 629 dnl ---------------------------------------------------------------------------
 630 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
 631 dnl ---------------
 632 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
 633 dnl prefer a standard location, and use -L options only if we do not find the
 634 dnl library in the standard library location(s).
 635 dnl     $1 = library name
 636 dnl     $2 = library class, usually the same as library name
 637 dnl     $3 = includes
 638 dnl     $4 = code fragment to compile/link
 639 dnl     $5 = corresponding function-name
 640 dnl     $6 = flag, nonnull if failure should not cause an error-exit
 641 dnl
 642 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
 643 dnl to use a -L option.
 644 AC_DEFUN([CF_FIND_LIBRARY],
 645 [
 646         eval 'cf_cv_have_lib_'$1'=no'
 647         cf_libdir=""
 648         AC_CHECK_FUNC($5,
 649                 eval 'cf_cv_have_lib_'$1'=yes',[
 650                 cf_save_LIBS="$LIBS"
 651                 AC_MSG_CHECKING(for $5 in -l$1)
 652                 LIBS="-l$1 $LIBS"
 653                 AC_TRY_LINK([$3],[$4],
 654                         [AC_MSG_RESULT(yes)
 655                          eval 'cf_cv_have_lib_'$1'=yes'
 656                         ],
 657                         [AC_MSG_RESULT(no)
 658                         CF_LIBRARY_PATH(cf_search,$2)
 659                         for cf_libdir in $cf_search
 660                         do
 661                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
 662                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
 663                                 AC_TRY_LINK([$3],[$4],
 664                                         [AC_MSG_RESULT(yes)
 665                                          eval 'cf_cv_have_lib_'$1'=yes'
 666                                          break],
 667                                         [AC_MSG_RESULT(no)
 668                                          LIBS="$cf_save_LIBS"])
 669                         done
 670                         ])
 671                 ])
 672 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
 673 ifelse($6,,[
 674 if test $cf_found_library = no ; then
 675         AC_MSG_ERROR(Cannot link $1 library)
 676 fi
 677 ])
 678 ])dnl
 679 dnl ---------------------------------------------------------------------------
 680 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
 681 dnl ---------------
 682 dnl Find a library (specifically the linkage used in the code fragment),
 683 dnl searching for it if it is not already in the library path.
 684 dnl See also CF_ADD_SEARCHPATH.
 685 dnl
 686 dnl Parameters (4-on are optional):
 687 dnl     $1 = headers for library entrypoint
 688 dnl     $2 = code fragment for library entrypoint
 689 dnl     $3 = the library name without the "-l" option or ".so" suffix.
 690 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
 691 dnl     $5 = action to perform if not successful
 692 dnl     $6 = module name, if not the same as the library name
 693 dnl     $7 = extra libraries
 694 dnl
 695 dnl Sets these variables:
 696 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
 697 dnl     $cf_cv_header_path_$3 - include-directory if needed
 698 dnl     $cf_cv_library_path_$3 - library-directory if needed
 699 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
 700 AC_DEFUN([CF_FIND_LINKAGE],[
 701
 702 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
 703 # will be set on completion of the AC_TRY_LINK below.
 704 cf_cv_header_path_$3=
 705 cf_cv_library_path_$3=
 706
 707 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
 708
 709 cf_save_LIBS="$LIBS"
 710
 711 AC_TRY_LINK([$1],[$2],[
 712         cf_cv_find_linkage_$3=yes
 713         cf_cv_header_path_$3=/usr/include
 714         cf_cv_library_path_$3=/usr/lib
 715 ],[
 716
 717 LIBS="-l$3 $7 $cf_save_LIBS"
 718
 719 AC_TRY_LINK([$1],[$2],[
 720         cf_cv_find_linkage_$3=yes
 721         cf_cv_header_path_$3=/usr/include
 722         cf_cv_library_path_$3=/usr/lib
 723         cf_cv_library_file_$3="-l$3"
 724 ],[
 725         cf_cv_find_linkage_$3=no
 726         LIBS="$cf_save_LIBS"
 727
 728     CF_VERBOSE(find linkage for $3 library)
 729     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
 730
 731     cf_save_CPPFLAGS="$CPPFLAGS"
 732     cf_test_CPPFLAGS="$CPPFLAGS"
 733
 734     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
 735     for cf_cv_header_path_$3 in $cf_search
 736     do
 737       if test -d $cf_cv_header_path_$3 ; then
 738         CF_VERBOSE(... testing $cf_cv_header_path_$3)
 739         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
 740         AC_TRY_COMPILE([$1],[$2],[
 741             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
 742             cf_cv_find_linkage_$3=maybe
 743             cf_test_CPPFLAGS="$CPPFLAGS"
 744             break],[
 745             CPPFLAGS="$cf_save_CPPFLAGS"
 746             ])
 747       fi
 748     done
 749
 750     if test "$cf_cv_find_linkage_$3" = maybe ; then
 751
 752       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
 753
 754       cf_save_LIBS="$LIBS"
 755       cf_save_LDFLAGS="$LDFLAGS"
 756
 757       ifelse([$6],,,[
 758         CPPFLAGS="$cf_test_CPPFLAGS"
 759         LIBS="-l$3 $7 $cf_save_LIBS"
 760         AC_TRY_LINK([$1],[$2],[
 761             CF_VERBOSE(... found $3 library in system)
 762             cf_cv_find_linkage_$3=yes])
 763             CPPFLAGS="$cf_save_CPPFLAGS"
 764             LIBS="$cf_save_LIBS"
 765             ])
 766
 767       if test "$cf_cv_find_linkage_$3" != yes ; then
 768         CF_LIBRARY_PATH(cf_search,$3)
 769         for cf_cv_library_path_$3 in $cf_search
 770         do
 771           if test -d $cf_cv_library_path_$3 ; then
 772             CF_VERBOSE(... testing $cf_cv_library_path_$3)
 773             CPPFLAGS="$cf_test_CPPFLAGS"
 774             LIBS="-l$3 $7 $cf_save_LIBS"
 775             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
 776             AC_TRY_LINK([$1],[$2],[
 777                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
 778                 cf_cv_find_linkage_$3=yes
 779                 cf_cv_library_file_$3="-l$3"
 780                 break],[
 781                 CPPFLAGS="$cf_save_CPPFLAGS"
 782                 LIBS="$cf_save_LIBS"
 783                 LDFLAGS="$cf_save_LDFLAGS"
 784                 ])
 785           fi
 786         done
 787         CPPFLAGS="$cf_save_CPPFLAGS"
 788         LDFLAGS="$cf_save_LDFLAGS"
 789       fi
 790
 791     else
 792       cf_cv_find_linkage_$3=no
 793     fi
 794     ],$7)
 795 ])
 796
 797 LIBS="$cf_save_LIBS"
 798
 799 if test "$cf_cv_find_linkage_$3" = yes ; then
 800 ifelse([$4],,[
 801         CF_ADD_INCDIR($cf_cv_header_path_$3)
 802         CF_ADD_LIBDIR($cf_cv_library_path_$3)
 803         CF_ADD_LIB($3)
 804 ],[$4])
 805 else
 806 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
 807 fi
 808 ])dnl
 809 dnl ---------------------------------------------------------------------------
 810 dnl CF_GCC_ATTRIBUTES version: 14 updated: 2010/10/23 15:52:32
 811 dnl -----------------
 812 dnl Test for availability of useful gcc __attribute__ directives to quiet
 813 dnl compiler warnings.  Though useful, not all are supported -- and contrary
 814 dnl to documentation, unrecognized directives cause older compilers to barf.
 815 AC_DEFUN([CF_GCC_ATTRIBUTES],
 816 [
 817 if test "$GCC" = yes
 818 then
 819 cat > conftest.i <<EOF
 820 #ifndef GCC_PRINTF
 821 #define GCC_PRINTF 0
 822 #endif
 823 #ifndef GCC_SCANF
 824 #define GCC_SCANF 0
 825 #endif
 826 #ifndef GCC_NORETURN
 827 #define GCC_NORETURN /* nothing */
 828 #endif
 829 #ifndef GCC_UNUSED
 830 #define GCC_UNUSED /* nothing */
 831 #endif
 832 EOF
 833 if test "$GCC" = yes
 834 then
 835         AC_CHECKING([for $CC __attribute__ directives])
 836 cat > conftest.$ac_ext <<EOF
 837 #line __oline__ "${as_me:-configure}"
 838 #include "confdefs.h"
 839 #include "conftest.h"
 840 #include "conftest.i"
 841 #if     GCC_PRINTF
 842 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
 843 #else
 844 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
 845 #endif
 846 #if     GCC_SCANF
 847 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
 848 #else
 849 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
 850 #endif
 851 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
 852 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
 853 extern void foo(void) GCC_NORETURN;
 854 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
 855 EOF
 856         cf_printf_attribute=no
 857         cf_scanf_attribute=no
 858         for cf_attribute in scanf printf unused noreturn
 859         do
 860                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
 861                 cf_directive="__attribute__(($cf_attribute))"
 862                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
 863
 864                 case $cf_attribute in #(vi
 865                 printf) #(vi
 866                         cf_printf_attribute=yes
 867                         cat >conftest.h <<EOF
 868 #define GCC_$cf_ATTRIBUTE 1
 869 EOF
 870                         ;;
 871                 scanf) #(vi
 872                         cf_scanf_attribute=yes
 873                         cat >conftest.h <<EOF
 874 #define GCC_$cf_ATTRIBUTE 1
 875 EOF
 876                         ;;
 877                 *) #(vi
 878                         cat >conftest.h <<EOF
 879 #define GCC_$cf_ATTRIBUTE $cf_directive
 880 EOF
 881                         ;;
 882                 esac
 883
 884                 if AC_TRY_EVAL(ac_compile); then
 885                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
 886                         cat conftest.h >>confdefs.h
 887                         case $cf_attribute in #(vi
 888                         printf) #(vi
 889                                 if test "$cf_printf_attribute" = no ; then
 890                                         cat >>confdefs.h <<EOF
 891 #define GCC_PRINTFLIKE(fmt,var) /* nothing */
 892 EOF
 893                                 else
 894                                         cat >>confdefs.h <<EOF
 895 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
 896 EOF
 897                                 fi
 898                                 ;;
 899                         scanf) #(vi
 900                                 if test "$cf_scanf_attribute" = no ; then
 901                                         cat >>confdefs.h <<EOF
 902 #define GCC_SCANFLIKE(fmt,var) /* nothing */
 903 EOF
 904                                 else
 905                                         cat >>confdefs.h <<EOF
 906 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
 907 EOF
 908                                 fi
 909                                 ;;
 910                         esac
 911                 fi
 912         done
 913 else
 914         fgrep define conftest.i >>confdefs.h
 915 fi
 916 rm -rf conftest*
 917 fi
 918 ])dnl
 919 dnl ---------------------------------------------------------------------------
 920 dnl CF_GCC_VERSION version: 5 updated: 2010/04/24 11:02:31
 921 dnl --------------
 922 dnl Find version of gcc
 923 AC_DEFUN([CF_GCC_VERSION],[
 924 AC_REQUIRE([AC_PROG_CC])
 925 GCC_VERSION=none
 926 if test "$GCC" = yes ; then
 927         AC_MSG_CHECKING(version of $CC)
 928         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
 929         test -z "$GCC_VERSION" && GCC_VERSION=unknown
 930         AC_MSG_RESULT($GCC_VERSION)
 931 fi
 932 ])dnl
 933 dnl ---------------------------------------------------------------------------
 934 dnl CF_GCC_WARNINGS version: 27 updated: 2010/10/23 15:52:32
 935 dnl ---------------
 936 dnl Check if the compiler supports useful warning options.  There's a few that
 937 dnl we don't use, simply because they're too noisy:
 938 dnl
 939 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
 940 dnl     -Wredundant-decls (system headers make this too noisy)
 941 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
 942 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
 943 dnl             is enabled for ncurses using "--enable-const".
 944 dnl     -pedantic
 945 dnl
 946 dnl Parameter:
 947 dnl     $1 is an optional list of gcc warning flags that a particular
 948 dnl             application might want to use, e.g., "no-unused" for
 949 dnl             -Wno-unused
 950 dnl Special:
 951 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
 952 dnl
 953 AC_DEFUN([CF_GCC_WARNINGS],
 954 [
 955 AC_REQUIRE([CF_GCC_VERSION])
 956 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
 957
 958 cat > conftest.$ac_ext <<EOF
 959 #line __oline__ "${as_me:-configure}"
 960 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
 961 EOF
 962
 963 if test "$INTEL_COMPILER" = yes
 964 then
 965 # The "-wdXXX" options suppress warnings:
 966 # remark #1419: external declaration in primary source file
 967 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
 968 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
 969 # remark #193: zero used for undefined preprocessing identifier
 970 # remark #593: variable "curs_sb_left_arrow" was set but never used
 971 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
 972 # remark #869: parameter "tw" was never referenced
 973 # remark #981: operands are evaluated in unspecified order
 974 # warning #279: controlling expression is constant
 975
 976         AC_CHECKING([for $CC warning options])
 977         cf_save_CFLAGS="$CFLAGS"
 978         EXTRA_CFLAGS="-Wall"
 979         for cf_opt in \
 980                 wd1419 \
 981                 wd1683 \
 982                 wd1684 \
 983                 wd193 \
 984                 wd593 \
 985                 wd279 \
 986                 wd810 \
 987                 wd869 \
 988                 wd981
 989         do
 990                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
 991                 if AC_TRY_EVAL(ac_compile); then
 992                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
 993                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
 994                 fi
 995         done
 996         CFLAGS="$cf_save_CFLAGS"
 997
 998 elif test "$GCC" = yes
 999 then
1000         AC_CHECKING([for $CC warning options])
1001         cf_save_CFLAGS="$CFLAGS"
1002         EXTRA_CFLAGS=
1003         cf_warn_CONST=""
1004         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1005         for cf_opt in W Wall \
1006                 Wbad-function-cast \
1007                 Wcast-align \
1008                 Wcast-qual \
1009                 Winline \
1010                 Wmissing-declarations \
1011                 Wmissing-prototypes \
1012                 Wnested-externs \
1013                 Wpointer-arith \
1014                 Wshadow \
1015                 Wstrict-prototypes \
1016                 Wundef $cf_warn_CONST $1
1017         do
1018                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1019                 if AC_TRY_EVAL(ac_compile); then
1020                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1021                         case $cf_opt in #(vi
1022                         Wcast-qual) #(vi
1023                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1024                                 ;;
1025                         Winline) #(vi
1026                                 case $GCC_VERSION in
1027                                 [[34]].*)
1028                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1029                                         continue;;
1030                                 esac
1031                                 ;;
1032                         esac
1033                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1034                 fi
1035         done
1036         CFLAGS="$cf_save_CFLAGS"
1037 fi
1038 rm -rf conftest*
1039
1040 AC_SUBST(EXTRA_CFLAGS)
1041 ])dnl
1042 dnl ---------------------------------------------------------------------------
1043 dnl CF_GNAT_GENERICS version: 1 updated: 2010/11/13 14:15:18
1044 dnl ----------------
1045 AC_DEFUN([CF_GNAT_GENERICS],
1046 [
1047 AC_MSG_CHECKING(if GNAT supports generics)
1048 case $cf_gnat_version in #(vi
1049 3.[[1-9]]*|[[4-9]].*) #(vi
1050         cf_gnat_generics=yes
1051         ;;
1052 *)
1053         cf_gnat_generics=no
1054         ;;
1055 esac
1056 AC_MSG_RESULT($cf_gnat_generics)
1057
1058 if test "$cf_gnat_generics" = yes
1059 then
1060         cf_compile_generics=generics
1061         cf_generic_objects="\${GENOBJS}"
1062 else
1063         cf_compile_generics=
1064         cf_generic_objects=
1065 fi
1066
1067 AC_SUBST(cf_compile_generics)
1068 AC_SUBST(cf_generic_objects)
1069 ])dnl
1070 dnl ---------------------------------------------------------------------------
1071 dnl CF_GNAT_PRAGMA_UNREF version: 1 updated: 2010/06/19 15:22:18
1072 dnl --------------------
1073 dnl Check if the gnat pragma "Unreferenced" works.
1074 AC_DEFUN([CF_GNAT_PRAGMA_UNREF],[
1075 AC_CACHE_CHECK(if GNAT pragma Unreferenced works,cf_cv_pragma_unreferenced,[
1076 CF_GNAT_TRY_LINK([procedure conftest;],
1077 [with Text_IO;
1078 with GNAT.OS_Lib;
1079 procedure conftest is
1080    test : Integer;
1081    pragma Unreferenced (test);
1082 begin
1083    test := 1;
1084    Text_IO.Put ("Hello World");
1085    Text_IO.New_Line;
1086    GNAT.OS_Lib.OS_Exit (0);
1087 end conftest;],
1088         [cf_cv_pragma_unreferenced=yes],
1089         [cf_cv_pragma_unreferenced=no])])
1090
1091 # if the pragma is supported, use it (needed in the Trace code).
1092 if test $cf_cv_pragma_unreferenced = yes ; then
1093         PRAGMA_UNREF=TRUE
1094 else
1095         PRAGMA_UNREF=FALSE
1096 fi
1097 AC_SUBST(PRAGMA_UNREF)
1098 ])dnl
1099 dnl ---------------------------------------------------------------------------
1100 dnl CF_GNAT_PROJECTS version: 1 updated: 2010/11/13 14:15:18
1101 dnl ----------------
1102 AC_DEFUN([CF_GNAT_PROJECTS],
1103 [
1104 AC_MSG_CHECKING(if GNAT supports project files)
1105 case $cf_gnat_version in #(vi
1106 3.[[0-9]]*) #(vi
1107         cf_gnat_projects=no
1108         ;;
1109 *)
1110         case $cf_cv_system_name in #(vi
1111         cygwin*) #(vi
1112                 cf_gnat_projects=no
1113                 ;;
1114         *)
1115                 cf_gnat_projects=yes
1116                 ;;
1117         esac
1118         ;;
1119 esac
1120 AC_MSG_RESULT($cf_gnat_projects)
1121
1122 if test "$cf_gnat_projects" = yes
1123 then
1124         USE_OLD_MAKERULES="#"
1125         USE_GNAT_PROJECTS=""
1126 else
1127         USE_OLD_MAKERULES=""
1128         USE_GNAT_PROJECTS="#"
1129 fi
1130
1131 AC_SUBST(USE_OLD_MAKERULES)
1132 AC_SUBST(USE_GNAT_PROJECTS)
1133 ])dnl
1134 dnl ---------------------------------------------------------------------------
1135 dnl CF_GNAT_TRY_LINK version: 2 updated: 2010/08/14 18:25:37
1136 dnl ----------------
1137 dnl Verify that a test program compiles/links with GNAT.
1138 dnl $cf_ada_make is set to the program that compiles/links
1139 dnl $ADAFLAGS may be set to the GNAT flags.
1140 dnl
1141 dnl $1 is the text of the spec
1142 dnl $2 is the text of the body
1143 dnl $3 is the shell command to execute if successful
1144 dnl $4 is the shell command to execute if not successful
1145 AC_DEFUN([CF_GNAT_TRY_LINK],
1146 [
1147 rm -rf conftest*
1148 cat >>conftest.ads <<CF_EOF
1149 $1
1150 CF_EOF
1151 cat >>conftest.adb <<CF_EOF
1152 $2
1153 CF_EOF
1154 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1155 ifelse($3,,      :,[      $3])
1156 ifelse($4,,,[else
1157    $4])
1158 fi
1159 rm -rf conftest*
1160 ])dnl
1161 dnl ---------------------------------------------------------------------------
1162 dnl CF_GNAT_TRY_RUN version: 4 updated: 2010/08/14 18:25:37
1163 dnl ---------------
1164 dnl Verify that a test program compiles and runs with GNAT
1165 dnl $cf_ada_make is set to the program that compiles/links
1166 dnl $ADAFLAGS may be set to the GNAT flags.
1167 dnl
1168 dnl $1 is the text of the spec
1169 dnl $2 is the text of the body
1170 dnl $3 is the shell command to execute if successful
1171 dnl $4 is the shell command to execute if not successful
1172 AC_DEFUN([CF_GNAT_TRY_RUN],
1173 [
1174 rm -rf conftest*
1175 cat >>conftest.ads <<CF_EOF
1176 $1
1177 CF_EOF
1178 cat >>conftest.adb <<CF_EOF
1179 $2
1180 CF_EOF
1181 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1182    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
1183 ifelse($3,,      :,[      $3])
1184 ifelse($4,,,[   else
1185       $4])
1186    fi
1187 ifelse($4,,,[else
1188    $4])
1189 fi
1190 rm -rf conftest*
1191 ])dnl
1192 dnl ---------------------------------------------------------------------------
1193 dnl CF_GNAT_VERSION version: 16 updated: 2010/11/13 14:15:18
1194 dnl ---------------
1195 dnl Verify version of GNAT.
1196 AC_DEFUN([CF_GNAT_VERSION],
1197 [
1198 AC_MSG_CHECKING(for gnat version)
1199 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
1200         grep '[[0-9]].[[0-9]][[0-9]]*' |\
1201     sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
1202 AC_MSG_RESULT($cf_gnat_version)
1203
1204 case $cf_gnat_version in #(vi
1205 3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*) #(vi
1206         cf_cv_prog_gnat_correct=yes
1207         ;;
1208 *)
1209         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1210         cf_cv_prog_gnat_correct=no
1211         ;;
1212 esac
1213
1214 CF_GNAT_GENERICS
1215 CF_GNAT_PROJECTS
1216 ])
1217 dnl ---------------------------------------------------------------------------
1218 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
1219 dnl -------------
1220 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1221 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1222 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1223 dnl since it is interwoven with GNU extensions.
1224 dnl
1225 dnl Well, yes we could work around it...
1226 AC_DEFUN([CF_GNU_SOURCE],
1227 [
1228 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1229 AC_TRY_COMPILE([#include <sys/types.h>],[
1230 #ifndef _XOPEN_SOURCE
1231 make an error
1232 #endif],
1233         [cf_cv_gnu_source=no],
1234         [cf_save="$CPPFLAGS"
1235          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1236          AC_TRY_COMPILE([#include <sys/types.h>],[
1237 #ifdef _XOPEN_SOURCE
1238 make an error
1239 #endif],
1240         [cf_cv_gnu_source=no],
1241         [cf_cv_gnu_source=yes])
1242         CPPFLAGS="$cf_save"
1243         ])
1244 ])
1245 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
1246 ])dnl
1247 dnl ---------------------------------------------------------------------------
1248 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
1249 dnl --------------
1250 dnl Construct a search-list of directories for a nonstandard header-file
1251 dnl
1252 dnl Parameters
1253 dnl     $1 = the variable to return as result
1254 dnl     $2 = the package name
1255 AC_DEFUN([CF_HEADER_PATH],
1256 [
1257 $1=
1258
1259 # collect the current set of include-directories from compiler flags
1260 cf_header_path_list=""
1261 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1262         for cf_header_path in $CPPFLAGS $CFLAGS
1263         do
1264                 case $cf_header_path in #(vi
1265                 -I*)
1266                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1267                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1268                         cf_header_path_list="$cf_header_path_list [$]$1"
1269                         ;;
1270                 esac
1271         done
1272 fi
1273
1274 # add the variations for the package we are looking for
1275 CF_SUBDIR_PATH($1,$2,include)
1276
1277 test "$includedir" != NONE && \
1278 test "$includedir" != "/usr/include" && \
1279 test -d "$includedir" && {
1280         test -d $includedir &&    $1="[$]$1 $includedir"
1281         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
1282 }
1283
1284 test "$oldincludedir" != NONE && \
1285 test "$oldincludedir" != "/usr/include" && \
1286 test -d "$oldincludedir" && {
1287         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
1288         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
1289 }
1290
1291 $1="[$]$1 $cf_header_path_list"
1292 ])dnl
1293 dnl ---------------------------------------------------------------------------
1294 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
1295 dnl ---------------
1296 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
1297 AC_DEFUN([CF_HELP_MESSAGE],
1298 [AC_DIVERT_HELP([$1])dnl
1299 ])dnl
1300 dnl ---------------------------------------------------------------------------
1301 dnl CF_INCLUDE_DIRS version: 6 updated: 2009/01/06 19:37:40
1302 dnl ---------------
1303 dnl Construct the list of include-options according to whether we're building
1304 dnl in the source directory or using '--srcdir=DIR' option.  If we're building
1305 dnl with gcc, don't append the includedir if it happens to be /usr/include,
1306 dnl since that usually breaks gcc's shadow-includes.
1307 AC_DEFUN([CF_INCLUDE_DIRS],
1308 [
1309 CPPFLAGS="$CPPFLAGS -I. -I../include"
1310 if test "$srcdir" != "."; then
1311         CPPFLAGS="$CPPFLAGS -I\${srcdir}/../include"
1312 fi
1313 if test "$GCC" != yes; then
1314         CPPFLAGS="$CPPFLAGS -I\${includedir}"
1315 elif test "$includedir" != "/usr/include"; then
1316         if test "$includedir" = '${prefix}/include' ; then
1317                 if test $prefix != /usr ; then
1318                         CPPFLAGS="$CPPFLAGS -I\${includedir}"
1319                 fi
1320         else
1321                 CPPFLAGS="$CPPFLAGS -I\${includedir}"
1322         fi
1323 fi
1324 AC_SUBST(CPPFLAGS)
1325 ])dnl
1326 dnl ---------------------------------------------------------------------------
1327 dnl CF_INTEL_COMPILER version: 4 updated: 2010/05/26 05:38:42
1328 dnl -----------------
1329 dnl Check if the given compiler is really the Intel compiler for Linux.  It
1330 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
1331 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
1332 dnl
1333 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1334 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1335 dnl the wrappers for gcc and g++ warnings.
1336 dnl
1337 dnl $1 = GCC (default) or GXX
1338 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
1339 dnl $3 = CFLAGS (default) or CXXFLAGS
1340 AC_DEFUN([CF_INTEL_COMPILER],[
1341 ifelse([$2],,INTEL_COMPILER,[$2])=no
1342
1343 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1344         case $host_os in
1345         linux*|gnu*)
1346                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
1347                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1348                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
1349                 AC_TRY_COMPILE([],[
1350 #ifdef __INTEL_COMPILER
1351 #else
1352 make an error
1353 #endif
1354 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
1355 cf_save_CFLAGS="$cf_save_CFLAGS -we147 -no-gcc"
1356 ],[])
1357                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1358                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
1359                 ;;
1360         esac
1361 fi
1362 ])dnl
1363 dnl ---------------------------------------------------------------------------
1364 dnl CF_LARGEFILE version: 7 updated: 2007/06/02 11:58:50
1365 dnl ------------
1366 dnl Add checks for large file support.
1367 AC_DEFUN([CF_LARGEFILE],[
1368 ifdef([AC_FUNC_FSEEKO],[
1369     AC_SYS_LARGEFILE
1370     if test "$enable_largefile" != no ; then
1371         AC_FUNC_FSEEKO
1372
1373         # Normally we would collect these definitions in the config.h,
1374         # but (like _XOPEN_SOURCE), some environments rely on having these
1375         # defined before any of the system headers are included.  Another
1376         # case comes up with C++, e.g., on AIX the compiler compiles the
1377         # header files by themselves before looking at the body files it is
1378         # told to compile.  For ncurses, those header files do not include
1379         # the config.h
1380         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
1381         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
1382         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
1383
1384         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
1385                 AC_TRY_COMPILE([
1386 #include <sys/types.h>
1387 #include <dirent.h>
1388                 ],[
1389                 /* if transitional largefile support is setup, this is true */
1390                 extern struct dirent64 * readdir(DIR *);
1391                 struct dirent64 *x = readdir((DIR *)0);
1392                 struct dirent *y = readdir((DIR *)0);
1393                 int z = x - y;
1394                 ],
1395                 [cf_cv_struct_dirent64=yes],
1396                 [cf_cv_struct_dirent64=no])
1397         ])
1398         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64)
1399     fi
1400 ])
1401 ])
1402 dnl ---------------------------------------------------------------------------
1403 dnl CF_LD_RPATH_OPT version: 3 updated: 2010/06/02 05:03:05
1404 dnl ---------------
1405 dnl For the given system and compiler, find the compiler flags to pass to the
1406 dnl loader to use the "rpath" feature.
1407 AC_DEFUN([CF_LD_RPATH_OPT],
1408 [
1409 AC_REQUIRE([CF_CHECK_CACHE])
1410
1411 LD_RPATH_OPT=
1412 AC_MSG_CHECKING(for an rpath option)
1413 case $cf_cv_system_name in #(vi
1414 irix*) #(vi
1415         if test "$GCC" = yes; then
1416                 LD_RPATH_OPT="-Wl,-rpath,"
1417         else
1418                 LD_RPATH_OPT="-rpath "
1419         fi
1420         ;;
1421 linux*|gnu*|k*bsd*-gnu) #(vi
1422         LD_RPATH_OPT="-Wl,-rpath,"
1423         ;;
1424 openbsd[[2-9]].*) #(vi
1425         LD_RPATH_OPT="-Wl,-rpath,"
1426         ;;
1427 freebsd*) #(vi
1428         LD_RPATH_OPT="-rpath "
1429         ;;
1430 netbsd*) #(vi
1431         LD_RPATH_OPT="-Wl,-rpath,"
1432         ;;
1433 osf*|mls+*) #(vi
1434         LD_RPATH_OPT="-rpath "
1435         ;;
1436 solaris2*) #(vi
1437         LD_RPATH_OPT="-R"
1438         ;;
1439 *)
1440         ;;
1441 esac
1442 AC_MSG_RESULT($LD_RPATH_OPT)
1443
1444 case "x$LD_RPATH_OPT" in #(vi
1445 x-R*)
1446         AC_MSG_CHECKING(if we need a space after rpath option)
1447         cf_save_LIBS="$LIBS"
1448         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
1449         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
1450         LIBS="$cf_save_LIBS"
1451         AC_MSG_RESULT($cf_rpath_space)
1452         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
1453         ;;
1454 esac
1455 ])dnl
1456 dnl ---------------------------------------------------------------------------
1457 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
1458 dnl ---------------
1459 dnl Construct a search-list of directories for a nonstandard library-file
1460 dnl
1461 dnl Parameters
1462 dnl     $1 = the variable to return as result
1463 dnl     $2 = the package name
1464 AC_DEFUN([CF_LIBRARY_PATH],
1465 [
1466 $1=
1467 cf_library_path_list=""
1468 if test -n "${LDFLAGS}${LIBS}" ; then
1469         for cf_library_path in $LDFLAGS $LIBS
1470         do
1471                 case $cf_library_path in #(vi
1472                 -L*)
1473                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
1474                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
1475                         cf_library_path_list="$cf_library_path_list [$]$1"
1476                         ;;
1477                 esac
1478         done
1479 fi
1480
1481 CF_SUBDIR_PATH($1,$2,lib)
1482
1483 $1="$cf_library_path_list [$]$1"
1484 ])dnl
1485 dnl ---------------------------------------------------------------------------
1486 dnl CF_LIB_PREFIX version: 8 updated: 2008/09/13 11:34:16
1487 dnl -------------
1488 dnl Compute the library-prefix for the given host system
1489 dnl $1 = variable to set
1490 AC_DEFUN([CF_LIB_PREFIX],
1491 [
1492         case $cf_cv_system_name in #(vi
1493         OS/2*|os2*) #(vi
1494         LIB_PREFIX=''
1495         ;;
1496         *)      LIB_PREFIX='lib'
1497         ;;
1498         esac
1499 ifelse($1,,,[$1=$LIB_PREFIX])
1500         AC_SUBST(LIB_PREFIX)
1501 ])dnl
1502 dnl ---------------------------------------------------------------------------
1503 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
1504 dnl -------------
1505 dnl Find the and soname for the given shared library.  Set the cache variable
1506 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
1507 dnl variable to "unknown".
1508 dnl
1509 dnl $1 = headers
1510 dnl $2 = code
1511 dnl $3 = library name
1512 AC_DEFUN([CF_LIB_SONAME],
1513 [
1514 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
1515
1516 cf_cv_$3_soname=unknown
1517 if test "$cross_compiling" != yes ; then
1518 cat >conftest.$ac_ext <<CF_EOF
1519 $1
1520 int main()
1521 {
1522 $2
1523         ${cf_cv_main_return:-return}(0);
1524 }
1525 CF_EOF
1526 cf_save_LIBS="$LIBS"
1527         CF_ADD_LIB($3)
1528         if AC_TRY_EVAL(ac_compile) ; then
1529                 if AC_TRY_EVAL(ac_link) ; then
1530                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
1531                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
1532                 fi
1533         fi
1534 rm -rf conftest*
1535 LIBS="$cf_save_LIBS"
1536 fi
1537 ])
1538 ])
1539 dnl ---------------------------------------------------------------------------
1540 dnl CF_LIB_SUFFIX version: 16 updated: 2008/12/27 12:30:03
1541 dnl -------------
1542 dnl Compute the library file-suffix from the given model name
1543 dnl $1 = model name
1544 dnl $2 = variable to set (the nominal library suffix)
1545 dnl $3 = dependency variable to set (actual filename)
1546 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1547 AC_DEFUN([CF_LIB_SUFFIX],
1548 [
1549         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
1550         case $1 in #(vi
1551         libtool) #(vi
1552                 $2='.la'
1553                 $3=[$]$2
1554                 ;;
1555         normal) #(vi
1556                 $2='.a'
1557                 $3=[$]$2
1558                 ;;
1559         debug) #(vi
1560                 $2='_g.a'
1561                 $3=[$]$2
1562                 ;;
1563         profile) #(vi
1564                 $2='_p.a'
1565                 $3=[$]$2
1566                 ;;
1567         shared) #(vi
1568                 case $cf_cv_system_name in
1569                 aix[[56]]*) #(vi
1570                         $2='.a'
1571                         $3=[$]$2
1572                         ;;
1573                 cygwin*) #(vi
1574                         $2='.dll'
1575                         $3='.dll.a'
1576                         ;;
1577                 darwin*) #(vi
1578                         $2='.dylib'
1579                         $3=[$]$2
1580                         ;;
1581                 hpux*) #(vi
1582                         case $target in
1583                         ia64*) #(vi
1584                                 $2='.so'
1585                                 $3=[$]$2
1586                                 ;;
1587                         *) #(vi
1588                                 $2='.sl'
1589                                 $3=[$]$2
1590                                 ;;
1591                         esac
1592                         ;;
1593                 *)      $2='.so'
1594                         $3=[$]$2
1595                         ;;
1596                 esac
1597         esac
1598         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
1599         test -n "$LIB_SUFFIX" && $3="${LIB_SUFFIX}[$]{$3}"
1600 ])dnl
1601 dnl ---------------------------------------------------------------------------
1602 dnl CF_LIB_TYPE version: 4 updated: 2000/10/20 22:57:49
1603 dnl -----------
1604 dnl Compute the string to append to -library from the given model name
1605 dnl $1 = model name
1606 dnl $2 = variable to set
1607 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1608 AC_DEFUN([CF_LIB_TYPE],
1609 [
1610         case $1 in
1611         libtool) $2=''   ;;
1612         normal)  $2=''   ;;
1613         debug)   $2='_g' ;;
1614         profile) $2='_p' ;;
1615         shared)  $2=''   ;;
1616         esac
1617         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
1618 ])dnl
1619 dnl ---------------------------------------------------------------------------
1620 dnl CF_LINK_DATAONLY version: 9 updated: 2009/01/01 20:21:38
1621 dnl ----------------
1622 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
1623 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
1624 dnl have to provide wrappers for global tables to ensure they're linked
1625 dnl properly.
1626 AC_DEFUN([CF_LINK_DATAONLY],
1627 [
1628 AC_MSG_CHECKING([if data-only library module links])
1629 AC_CACHE_VAL(cf_cv_link_dataonly,[
1630         rm -f conftest.a
1631         cat >conftest.$ac_ext <<EOF
1632 #line __oline__ "configure"
1633 int     testdata[[3]] = { 123, 456, 789 };
1634 EOF
1635         if AC_TRY_EVAL(ac_compile) ; then
1636                 mv conftest.o data.o && \
1637                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
1638         fi
1639         rm -f conftest.$ac_ext data.o
1640         cat >conftest.$ac_ext <<EOF
1641 #line __oline__ "configure"
1642 int     testfunc()
1643 {
1644 #if defined(NeXT)
1645         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
1646 #else
1647         extern int testdata[[3]];
1648         return testdata[[0]] == 123
1649            &&  testdata[[1]] == 456
1650            &&  testdata[[2]] == 789;
1651 #endif
1652 }
1653 EOF
1654         if AC_TRY_EVAL(ac_compile); then
1655                 mv conftest.o func.o && \
1656                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
1657         fi
1658         rm -f conftest.$ac_ext func.o
1659         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
1660         cf_saveLIBS="$LIBS"
1661         LIBS="conftest.a $LIBS"
1662         AC_TRY_RUN([
1663         int main()
1664         {
1665                 extern int testfunc();
1666                 ${cf_cv_main_return:-return} (!testfunc());
1667         }
1668         ],
1669         [cf_cv_link_dataonly=yes],
1670         [cf_cv_link_dataonly=no],
1671         [cf_cv_link_dataonly=unknown])
1672         LIBS="$cf_saveLIBS"
1673         ])
1674 AC_MSG_RESULT($cf_cv_link_dataonly)
1675
1676 if test "$cf_cv_link_dataonly" = no ; then
1677         AC_DEFINE(BROKEN_LINKER)
1678         BROKEN_LINKER=1
1679 fi
1680
1681 ])dnl
1682 dnl ---------------------------------------------------------------------------
1683 dnl CF_LINK_FUNCS version: 7 updated: 2006/12/16 12:33:30
1684 dnl -------------
1685 dnl Most Unix systems have both link and symlink, a few don't have symlink.
1686 dnl A few non-Unix systems implement symlink, but not link.
1687 dnl A few non-systems implement neither (or have nonfunctional versions).
1688 AC_DEFUN([CF_LINK_FUNCS],
1689 [
1690 AC_CHECK_FUNCS( \
1691         remove \
1692         unlink )
1693
1694 if test "$cross_compiling" = yes ; then
1695         AC_CHECK_FUNCS( \
1696                 link \
1697                 symlink )
1698 else
1699         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
1700                 cf_cv_link_funcs=
1701                 for cf_func in link symlink ; do
1702                         AC_TRY_RUN([
1703 #include <sys/types.h>
1704 #include <sys/stat.h>
1705 #ifdef HAVE_UNISTD_H
1706 #include <unistd.h>
1707 #endif
1708 int main()
1709 {
1710         int fail = 0;
1711         char *src = "config.log";
1712         char *dst = "conftest.chk";
1713         struct stat src_sb;
1714         struct stat dst_sb;
1715
1716         stat(src, &src_sb);
1717         fail = ($cf_func("config.log", "conftest.chk") < 0)
1718             || (stat(dst, &dst_sb) < 0)
1719             || (dst_sb.st_mtime != src_sb.st_mtime);
1720 #ifdef HAVE_UNLINK
1721         unlink(dst);
1722 #else
1723         remove(dst);
1724 #endif
1725         ${cf_cv_main_return:-return} (fail);
1726 }
1727                         ],[
1728                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
1729                         eval 'ac_cv_func_'$cf_func'=yes'],[
1730                         eval 'ac_cv_func_'$cf_func'=no'],[
1731                         eval 'ac_cv_func_'$cf_func'=error'])
1732                 done
1733                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
1734         ])
1735         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK)
1736         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK)
1737 fi
1738 ])dnl
1739 dnl ---------------------------------------------------------------------------
1740 dnl CF_MAIN_RETURN version: 1 updated: 2006/12/10 09:51:54
1741 dnl --------------
1742 dnl Check if a return from main to the shell actually returns the same exit
1743 dnl code.  This is true for almost any POSIX environment.
1744 dnl
1745 dnl Some very old environments did not flush stdout, etc., on an exit.  That
1746 dnl would be a useful case to test for also.
1747 AC_DEFUN([CF_MAIN_RETURN],
1748 [
1749 cf_cv_main_return=return
1750 ])dnl
1751 dnl ---------------------------------------------------------------------------
1752 dnl CF_MAKEFLAGS version: 13 updated: 2010/10/23 15:52:32
1753 dnl ------------
1754 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
1755 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
1756 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
1757 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
1758 AC_DEFUN([CF_MAKEFLAGS],
1759 [
1760 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
1761         cf_cv_makeflags=''
1762         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
1763         do
1764                 cat >cf_makeflags.tmp <<CF_EOF
1765 SHELL = /bin/sh
1766 all :
1767         @ echo '.$cf_option'
1768 CF_EOF
1769                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | sed -e 's,[[      ]]*$,,'`
1770                 case "$cf_result" in
1771                 .*k)
1772                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
1773                         case "$cf_result" in
1774                         .*CC=*) cf_cv_makeflags=
1775                                 ;;
1776                         *)      cf_cv_makeflags=$cf_option
1777                                 ;;
1778                         esac
1779                         break
1780                         ;;
1781                 .-)     ;;
1782                 *)      echo "given option \"$cf_option\", no match \"$cf_result\""
1783                         ;;
1784                 esac
1785         done
1786         rm -f cf_makeflags.tmp
1787 ])
1788
1789 AC_SUBST(cf_cv_makeflags)
1790 ])dnl
1791 dnl ---------------------------------------------------------------------------
1792 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
1793 dnl ------------
1794 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
1795 dnl a monocase filesystem.
1796 AC_DEFUN([CF_MAKE_TAGS],[
1797 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
1798
1799 AC_CHECK_PROGS(CTAGS, exctags ctags)
1800 AC_CHECK_PROGS(ETAGS, exetags etags)
1801
1802 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
1803
1804 if test "$cf_cv_mixedcase" = yes ; then
1805         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
1806 else
1807         MAKE_UPPER_TAGS=no
1808 fi
1809
1810 if test "$MAKE_UPPER_TAGS" = yes ; then
1811         MAKE_UPPER_TAGS=
1812 else
1813         MAKE_UPPER_TAGS="#"
1814 fi
1815
1816 if test "$MAKE_LOWER_TAGS" = yes ; then
1817         MAKE_LOWER_TAGS=
1818 else
1819         MAKE_LOWER_TAGS="#"
1820 fi
1821
1822 AC_SUBST(CTAGS)
1823 AC_SUBST(ETAGS)
1824
1825 AC_SUBST(MAKE_UPPER_TAGS)
1826 AC_SUBST(MAKE_LOWER_TAGS)
1827 ])dnl
1828 dnl ---------------------------------------------------------------------------
1829 dnl CF_MIXEDCASE_FILENAMES version: 3 updated: 2003/09/20 17:07:55
1830 dnl ----------------------
1831 dnl Check if the file-system supports mixed-case filenames.  If we're able to
1832 dnl create a lowercase name and see it as uppercase, it doesn't support that.
1833 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
1834 [
1835 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
1836 if test "$cross_compiling" = yes ; then
1837         case $target_alias in #(vi
1838         *-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-mingw32*|*-uwin*) #(vi
1839                 cf_cv_mixedcase=no
1840                 ;;
1841         *)
1842                 cf_cv_mixedcase=yes
1843                 ;;
1844         esac
1845 else
1846         rm -f conftest CONFTEST
1847         echo test >conftest
1848         if test -f CONFTEST ; then
1849                 cf_cv_mixedcase=no
1850         else
1851                 cf_cv_mixedcase=yes
1852         fi
1853         rm -f conftest CONFTEST
1854 fi
1855 ])
1856 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES)
1857 ])dnl
1858 dnl ---------------------------------------------------------------------------
1859 dnl CF_MKSTEMP version: 7 updated: 2010/08/14 18:25:37
1860 dnl ----------
1861 dnl Check for a working mkstemp.  This creates two files, checks that they are
1862 dnl successfully created and distinct (AmigaOS apparently fails on the last).
1863 AC_DEFUN([CF_MKSTEMP],[
1864 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
1865 rm -rf conftest*
1866 AC_TRY_RUN([
1867 #include <sys/types.h>
1868 #include <stdlib.h>
1869 #include <stdio.h>
1870 #include <string.h>
1871 #include <sys/stat.h>
1872 int main()
1873 {
1874         char *tmpl = "conftestXXXXXX";
1875         char name[2][80];
1876         int n;
1877         int result = 0;
1878         int fd;
1879         struct stat sb;
1880
1881         umask(077);
1882         for (n = 0; n < 2; ++n) {
1883                 strcpy(name[n], tmpl);
1884                 if ((fd = mkstemp(name[n])) >= 0) {
1885                         if (!strcmp(name[n], tmpl)
1886                          || stat(name[n], &sb) != 0
1887                          || (sb.st_mode & S_IFMT) != S_IFREG
1888                          || (sb.st_mode & 077) != 0) {
1889                                 result = 1;
1890                         }
1891                         close(fd);
1892                 }
1893         }
1894         if (result == 0
1895          && !strcmp(name[0], name[1]))
1896                 result = 1;
1897         ${cf_cv_main_return:-return}(result);
1898 }
1899 ],[cf_cv_func_mkstemp=yes
1900 ],[cf_cv_func_mkstemp=no
1901 ],[AC_CHECK_FUNC(mkstemp)
1902 ])
1903 ])
1904 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
1905         AC_DEFINE(HAVE_MKSTEMP)
1906 fi
1907 ])dnl
1908 dnl ---------------------------------------------------------------------------
1909 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
1910 dnl ----------
1911 dnl Write a debug message to config.log, along with the line number in the
1912 dnl configure script.
1913 AC_DEFUN([CF_MSG_LOG],[
1914 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
1915 ])dnl
1916 dnl ---------------------------------------------------------------------------
1917 dnl CF_NCURSES_ADDON version: 3 updated: 2010/10/23 15:54:49
1918 dnl ----------------
1919 dnl Configure an ncurses add-on, built outside the ncurses tree.
1920 AC_DEFUN([CF_NCURSES_ADDON],[
1921
1922 AC_PROVIDE([CF_SUBST_NCURSES_VERSION])
1923
1924 AC_MSG_CHECKING(if you want wide-character code)
1925 AC_ARG_ENABLE(widec,
1926         [  --enable-widec          compile with wide-char/UTF-8 code],
1927         [with_widec=$enableval],
1928         [with_widec=no])
1929 AC_MSG_RESULT($with_widec)
1930 if test "$with_widec" = yes ; then
1931         CF_UTF8_LIB
1932         CF_NCURSES_CONFIG(ncursesw)
1933 else
1934         CF_NCURSES_CONFIG(ncurses)
1935 fi
1936
1937 if test "$NCURSES_CONFIG" != none ; then
1938
1939 cf_version=`$NCURSES_CONFIG --version`
1940
1941 NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
1942 NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]]\+\.//' -e 's/\..*//'`
1943 NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]]\+\.[[0-9]]\+\.//'`
1944
1945 # ABI version is not available from headers
1946 cf_cv_abi_version=`$NCURSES_CONFIG --abi-version`
1947
1948 else
1949
1950 for cf_name in MAJOR MINOR PATCH
1951 do
1952 cat >conftest.$ac_ext <<CF_EOF
1953 #include <${cf_cv_ncurses_header:-curses.h}>
1954 AUTOCONF_$cf_name NCURSES_VERSION_$cf_name
1955 CF_EOF
1956         cf_try="$ac_cpp conftest.$ac_ext 2>&5 | fgrep AUTOCONF_$cf_name >conftest.out"
1957         AC_TRY_EVAL(cf_try)
1958         if test -f conftest.out ; then
1959                 cf_result=`cat conftest.out | sed -e "s/^.*AUTOCONF_$cf_name[[  ]]\+//"`
1960                 eval NCURSES_$cf_name=$cf_result
1961                 cat conftest.$ac_ext
1962                 cat conftest.out
1963         fi
1964 done
1965
1966 cf_cv_abi_version=${NCURSES_MAJOR}
1967
1968 fi
1969
1970 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
1971
1972 dnl Show the computed version, for logging
1973 cf_cv_timestamp=`date`
1974
1975 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
1976
1977 dnl We need these values in the generated headers
1978 AC_SUBST(NCURSES_MAJOR)
1979 AC_SUBST(NCURSES_MINOR)
1980 AC_SUBST(NCURSES_PATCH)
1981
1982 dnl We need these values in the generated makefiles
1983 AC_SUBST(cf_cv_rel_version)
1984 AC_SUBST(cf_cv_abi_version)
1985
1986 dnl FIXME - not needed for Ada95
1987 AC_SUBST(cf_cv_builtin_bool)
1988 AC_SUBST(cf_cv_header_stdbool_h)
1989 AC_SUBST(cf_cv_type_of_bool)dnl
1990
1991 ])
1992 dnl ---------------------------------------------------------------------------
1993 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
1994 dnl -------------------
1995 dnl Check if we can compile with ncurses' header file
1996 dnl $1 is the cache variable to set
1997 dnl $2 is the header-file to include
1998 dnl $3 is the root name (ncurses or ncursesw)
1999 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2000         AC_TRY_COMPILE([
2001 ]ifelse($3,ncursesw,[
2002 #define _XOPEN_SOURCE_EXTENDED
2003 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2004 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2005 ])[
2006 #include <$2>],[
2007 #ifdef NCURSES_VERSION
2008 ]ifelse($3,ncursesw,[
2009 #ifndef WACS_BSSB
2010         make an error
2011 #endif
2012 ])[
2013 printf("%s\n", NCURSES_VERSION);
2014 #else
2015 #ifdef __NCURSES_H
2016 printf("old\n");
2017 #else
2018         make an error
2019 #endif
2020 #endif
2021         ]
2022         ,[$1=$2]
2023         ,[$1=no])
2024 ])dnl
2025 dnl ---------------------------------------------------------------------------
2026 dnl CF_NCURSES_CONFIG version: 8 updated: 2010/07/08 05:17:30
2027 dnl -----------------
2028 dnl Tie together the configure-script macros for ncurses.
2029 dnl Prefer the "-config" script from ncurses 6.x, to simplify analysis.
2030 dnl Allow that to be overridden using the $NCURSES_CONFIG environment variable.
2031 dnl
2032 dnl $1 is the root library name (default: "ncurses")
2033 AC_DEFUN([CF_NCURSES_CONFIG],
2034 [
2035 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2036
2037 echo "Looking for ${cf_ncuconfig_root}-config"
2038 AC_PATH_PROGS(NCURSES_CONFIG,${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config,none)
2039
2040 if test "$NCURSES_CONFIG" != none ; then
2041
2042 CPPFLAGS="$CPPFLAGS `$NCURSES_CONFIG --cflags`"
2043 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2044
2045 # even with config script, some packages use no-override for curses.h
2046 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2047
2048 dnl like CF_NCURSES_CPPFLAGS
2049 AC_DEFINE(NCURSES)
2050
2051 dnl like CF_NCURSES_LIBS
2052 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2053 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2054
2055 dnl like CF_NCURSES_VERSION
2056 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
2057
2058 else
2059
2060 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2061 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2062
2063 fi
2064 ])dnl
2065 dnl ---------------------------------------------------------------------------
2066 dnl CF_NCURSES_CPPFLAGS version: 20 updated: 2010/11/20 17:02:38
2067 dnl -------------------
2068 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
2069 dnl the CPPFLAGS variable so we can include its header.
2070 dnl
2071 dnl The header files may be installed as either curses.h, or ncurses.h (would
2072 dnl be obsolete, except that some packagers prefer this name to distinguish it
2073 dnl from a "native" curses implementation).  If not installed for overwrite,
2074 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
2075 dnl /usr/include/ncurses), but someone may have installed overwriting the
2076 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
2077 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
2078 dnl the header.
2079 dnl
2080 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
2081 dnl is already in the include-path, don't even bother with this, since we cannot
2082 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
2083 dnl
2084 dnl The optional parameter gives the root name of the library, in case it is
2085 dnl not installed as the default curses library.  That is how the
2086 dnl wide-character version of ncurses is installed.
2087 AC_DEFUN([CF_NCURSES_CPPFLAGS],
2088 [AC_REQUIRE([CF_WITH_CURSES_DIR])
2089
2090 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
2091 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
2092
2093 test -n "$cf_cv_curses_dir" && \
2094 test "$cf_cv_curses_dir" != "no" && { \
2095   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
2096 }
2097
2098 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
2099         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2100         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
2101         for cf_header in $cf_header_list
2102         do
2103                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2104                 test "$cf_cv_ncurses_h" != no && break
2105         done
2106 ])
2107
2108 CF_NCURSES_HEADER
2109 CF_TERM_HEADER
2110
2111 # some applications need this, but should check for NCURSES_VERSION
2112 AC_DEFINE(NCURSES)
2113
2114 CF_NCURSES_VERSION
2115 ])dnl
2116 dnl ---------------------------------------------------------------------------
2117 dnl CF_NCURSES_HEADER version: 2 updated: 2008/03/23 14:48:54
2118 dnl -----------------
2119 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2120 dnl variations of ncurses' installs.
2121 dnl
2122 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2123 AC_DEFUN([CF_NCURSES_HEADER],[
2124
2125 if test "$cf_cv_ncurses_h" != no ; then
2126         cf_cv_ncurses_header=$cf_cv_ncurses_h
2127 else
2128
2129 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2130         test -n "$verbose" && echo
2131         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2132         test -n "$verbose" && echo search path $cf_search
2133         cf_save2_CPPFLAGS="$CPPFLAGS"
2134         for cf_incdir in $cf_search
2135         do
2136                 CF_ADD_INCDIR($cf_incdir)
2137                 for cf_header in \
2138                         ncurses.h \
2139                         curses.h
2140                 do
2141                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2142                         if test "$cf_cv_ncurses_h2" != no ; then
2143                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2144                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
2145                                 break
2146                         fi
2147                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2148                 done
2149                 CPPFLAGS="$cf_save2_CPPFLAGS"
2150                 test "$cf_cv_ncurses_h2" != no && break
2151         done
2152         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2153         ])
2154
2155         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2156         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
2157         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
2158                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
2159         fi
2160         CF_ADD_INCDIR($cf_1st_incdir)
2161
2162 fi
2163
2164 # Set definitions to allow ifdef'ing for ncurses.h
2165
2166 case $cf_cv_ncurses_header in # (vi
2167 *ncurses.h)
2168         AC_DEFINE(HAVE_NCURSES_H)
2169         ;;
2170 esac
2171
2172 case $cf_cv_ncurses_header in # (vi
2173 ncurses/curses.h|ncurses/ncurses.h)
2174         AC_DEFINE(HAVE_NCURSES_NCURSES_H)
2175         ;;
2176 ncursesw/curses.h|ncursesw/ncurses.h)
2177         AC_DEFINE(HAVE_NCURSESW_NCURSES_H)
2178         ;;
2179 esac
2180
2181 ])dnl
2182 dnl ---------------------------------------------------------------------------
2183 dnl CF_NCURSES_LIBS version: 16 updated: 2010/11/20 17:02:38
2184 dnl ---------------
2185 dnl Look for the ncurses library.  This is a little complicated on Linux,
2186 dnl because it may be linked with the gpm (general purpose mouse) library.
2187 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2188 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2189 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2190 dnl and the linker will record a dependency.
2191 dnl
2192 dnl The optional parameter gives the root name of the library, in case it is
2193 dnl not installed as the default curses library.  That is how the
2194 dnl wide-character version of ncurses is installed.
2195 AC_DEFUN([CF_NCURSES_LIBS],
2196 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2197
2198 cf_nculib_root=ifelse($1,,ncurses,$1)
2199         # This works, except for the special case where we find gpm, but
2200         # ncurses is in a nonstandard location via $LIBS, and we really want
2201         # to link gpm.
2202 cf_ncurses_LIBS=""
2203 cf_ncurses_SAVE="$LIBS"
2204 AC_CHECK_LIB(gpm,Gpm_Open,
2205         [AC_CHECK_LIB(gpm,initscr,
2206                 [LIBS="$cf_ncurses_SAVE"],
2207                 [cf_ncurses_LIBS="-lgpm"])])
2208
2209 case $host_os in #(vi
2210 freebsd*)
2211         # This is only necessary if you are linking against an obsolete
2212         # version of ncurses (but it should do no harm, since it's static).
2213         if test "$cf_nculib_root" = ncurses ; then
2214                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2215         fi
2216         ;;
2217 esac
2218
2219 CF_ADD_LIBS($cf_ncurses_LIBS)
2220
2221 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2222 then
2223         CF_ADD_LIBS(-l$cf_nculib_root)
2224 else
2225         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2226                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2227                 [initscr()],
2228                 initscr)
2229 fi
2230
2231 if test -n "$cf_ncurses_LIBS" ; then
2232         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2233         cf_ncurses_SAVE="$LIBS"
2234         for p in $cf_ncurses_LIBS ; do
2235                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2236                 if test "$q" != "$LIBS" ; then
2237                         LIBS="$q"
2238                 fi
2239         done
2240         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2241                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2242                 [AC_MSG_RESULT(yes)],
2243                 [AC_MSG_RESULT(no)
2244                  LIBS="$cf_ncurses_SAVE"])
2245 fi
2246
2247 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2248 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2249 ])dnl
2250 dnl ---------------------------------------------------------------------------
2251 dnl CF_NCURSES_VERSION version: 13 updated: 2010/10/23 15:54:49
2252 dnl ------------------
2253 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2254 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2255 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2256 AC_DEFUN([CF_NCURSES_VERSION],
2257 [
2258 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2259 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2260         cf_cv_ncurses_version=no
2261         cf_tempfile=out$$
2262         rm -f $cf_tempfile
2263         AC_TRY_RUN([
2264 #include <${cf_cv_ncurses_header:-curses.h}>
2265 #include <stdio.h>
2266 int main()
2267 {
2268         FILE *fp = fopen("$cf_tempfile", "w");
2269 #ifdef NCURSES_VERSION
2270 # ifdef NCURSES_VERSION_PATCH
2271         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
2272 # else
2273         fprintf(fp, "%s\n", NCURSES_VERSION);
2274 # endif
2275 #else
2276 # ifdef __NCURSES_H
2277         fprintf(fp, "old\n");
2278 # else
2279         make an error
2280 # endif
2281 #endif
2282         ${cf_cv_main_return:-return}(0);
2283 }],[
2284         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
2285
2286         # This will not work if the preprocessor splits the line after the
2287         # Autoconf token.  The 'unproto' program does that.
2288         cat > conftest.$ac_ext <<EOF
2289 #include <${cf_cv_ncurses_header:-curses.h}>
2290 #undef Autoconf
2291 #ifdef NCURSES_VERSION
2292 Autoconf NCURSES_VERSION
2293 #else
2294 #ifdef __NCURSES_H
2295 Autoconf "old"
2296 #endif
2297 ;
2298 #endif
2299 EOF
2300         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
2301         AC_TRY_EVAL(cf_try)
2302         if test -f conftest.out ; then
2303                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
2304                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
2305                 rm -f conftest.out
2306         fi
2307 ])
2308         rm -f $cf_tempfile
2309 ])
2310 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES)
2311 ])dnl
2312 dnl ---------------------------------------------------------------------------
2313 dnl CF_NO_LEAKS_OPTION version: 4 updated: 2006/12/16 14:24:05
2314 dnl ------------------
2315 dnl see CF_WITH_NO_LEAKS
2316 AC_DEFUN([CF_NO_LEAKS_OPTION],[
2317 AC_MSG_CHECKING(if you want to use $1 for testing)
2318 AC_ARG_WITH($1,
2319         [$2],
2320         [AC_DEFINE($3)ifelse([$4],,[
2321          $4
2322 ])
2323         : ${with_cflags:=-g}
2324         : ${with_no_leaks:=yes}
2325          with_$1=yes],
2326         [with_$1=])
2327 AC_MSG_RESULT(${with_$1:-no})
2328
2329 case .$with_cflags in #(vi
2330 .*-g*)
2331         case .$CFLAGS in #(vi
2332         .*-g*) #(vi
2333                 ;;
2334         *)
2335                 CF_ADD_CFLAGS([-g])
2336                 ;;
2337         esac
2338         ;;
2339 esac
2340 ])dnl
2341 dnl ---------------------------------------------------------------------------
2342 dnl CF_NUMBER_SYNTAX version: 1 updated: 2003/09/20 18:12:49
2343 dnl ----------------
2344 dnl Check if the given variable is a number.  If not, report an error.
2345 dnl $1 is the variable
2346 dnl $2 is the message
2347 AC_DEFUN([CF_NUMBER_SYNTAX],[
2348 if test -n "$1" ; then
2349   case $1 in #(vi
2350   [[0-9]]*) #(vi
2351         ;;
2352   *)
2353         AC_MSG_ERROR($2 is not a number: $1)
2354         ;;
2355   esac
2356 else
2357   AC_MSG_ERROR($2 value is empty)
2358 fi
2359 ])dnl
2360 dnl ---------------------------------------------------------------------------
2361 dnl CF_OBJ_SUBDIR version: 4 updated: 2002/02/23 20:38:31
2362 dnl -------------
2363 dnl Compute the object-directory name from the given model name
2364 AC_DEFUN([CF_OBJ_SUBDIR],
2365 [
2366         case $1 in
2367         libtool) $2='obj_lo'  ;;
2368         normal)  $2='objects' ;;
2369         debug)   $2='obj_g' ;;
2370         profile) $2='obj_p' ;;
2371         shared)
2372                 case $cf_cv_system_name in #(vi
2373                 cygwin) #(vi
2374                         $2='objects' ;;
2375                 *)
2376                         $2='obj_s' ;;
2377                 esac
2378         esac
2379 ])dnl
2380 dnl ---------------------------------------------------------------------------
2381 dnl CF_PATHSEP version: 5 updated: 2010/05/26 05:38:42
2382 dnl ----------
2383 dnl Provide a value for the $PATH and similar separator
2384 AC_DEFUN([CF_PATHSEP],
2385 [
2386         case $cf_cv_system_name in
2387         os2*)   PATH_SEPARATOR=';'  ;;
2388         *)      PATH_SEPARATOR=':'  ;;
2389         esac
2390 ifelse([$1],,,[$1=$PATH_SEPARATOR])
2391         AC_SUBST(PATH_SEPARATOR)
2392 ])dnl
2393 dnl ---------------------------------------------------------------------------
2394 dnl CF_PATH_SYNTAX version: 13 updated: 2010/05/26 05:38:42
2395 dnl --------------
2396 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
2397 dnl begins with one of the prefix/exec_prefix variables, and then again if the
2398 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
2399 dnl delayed evaluation of those symbols.
2400 AC_DEFUN([CF_PATH_SYNTAX],[
2401 if test "x$prefix" != xNONE; then
2402   cf_path_syntax="$prefix"
2403 else
2404   cf_path_syntax="$ac_default_prefix"
2405 fi
2406
2407 case ".[$]$1" in #(vi
2408 .\[$]\(*\)*|.\'*\'*) #(vi
2409   ;;
2410 ..|./*|.\\*) #(vi
2411   ;;
2412 .[[a-zA-Z]]:[[\\/]]*) #(vi OS/2 EMX
2413   ;;
2414 .\[$]{*prefix}*) #(vi
2415   eval $1="[$]$1"
2416   case ".[$]$1" in #(vi
2417   .NONE/*)
2418     $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2419     ;;
2420   esac
2421   ;; #(vi
2422 .no|.NONE/*)
2423   $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2424   ;;
2425 *)
2426   ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
2427   ;;
2428 esac
2429 ])dnl
2430 dnl ---------------------------------------------------------------------------
2431 dnl CF_PKG_CONFIG version: 3 updated: 2009/01/25 10:55:09
2432 dnl -------------
2433 dnl Check for the package-config program, unless disabled by command-line.
2434 AC_DEFUN([CF_PKG_CONFIG],
2435 [
2436 AC_MSG_CHECKING(if you want to use pkg-config)
2437 AC_ARG_WITH(pkg-config,
2438         [  --with-pkg-config{=path} enable/disable use of pkg-config],
2439         [cf_pkg_config=$withval],
2440         [cf_pkg_config=yes])
2441 AC_MSG_RESULT($cf_pkg_config)
2442
2443 case $cf_pkg_config in #(vi
2444 no) #(vi
2445         PKG_CONFIG=none
2446         ;;
2447 yes) #(vi
2448         AC_PATH_PROG(PKG_CONFIG, pkg-config, none)
2449         ;;
2450 *)
2451         PKG_CONFIG=$withval
2452         ;;
2453 esac
2454
2455 test -z "$PKG_CONFIG" && PKG_CONFIG=none
2456 if test "$PKG_CONFIG" != none ; then
2457         CF_PATH_SYNTAX(PKG_CONFIG)
2458 fi
2459
2460 AC_SUBST(PKG_CONFIG)
2461 ])dnl
2462 dnl ---------------------------------------------------------------------------
2463 dnl CF_POSIX_C_SOURCE version: 8 updated: 2010/05/26 05:38:42
2464 dnl -----------------
2465 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
2466 dnl
2467 dnl     POSIX.1-1990                            _POSIX_SOURCE
2468 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
2469 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
2470 dnl             Bindings Option
2471 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
2472 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
2473 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
2474 dnl
2475 dnl Parameters:
2476 dnl     $1 is the nominal value for _POSIX_C_SOURCE
2477 AC_DEFUN([CF_POSIX_C_SOURCE],
2478 [
2479 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
2480
2481 cf_save_CFLAGS="$CFLAGS"
2482 cf_save_CPPFLAGS="$CPPFLAGS"
2483
2484 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
2485 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
2486
2487 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
2488         CF_MSG_LOG(if the symbol is already defined go no further)
2489         AC_TRY_COMPILE([#include <sys/types.h>],[
2490 #ifndef _POSIX_C_SOURCE
2491 make an error
2492 #endif],
2493         [cf_cv_posix_c_source=no],
2494         [cf_want_posix_source=no
2495          case .$cf_POSIX_C_SOURCE in #(vi
2496          .[[12]]??*) #(vi
2497                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2498                 ;;
2499          .2) #(vi
2500                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2501                 cf_want_posix_source=yes
2502                 ;;
2503          .*)
2504                 cf_want_posix_source=yes
2505                 ;;
2506          esac
2507          if test "$cf_want_posix_source" = yes ; then
2508                 AC_TRY_COMPILE([#include <sys/types.h>],[
2509 #ifdef _POSIX_SOURCE
2510 make an error
2511 #endif],[],
2512                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
2513          fi
2514          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
2515          CFLAGS="$cf_trim_CFLAGS"
2516          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
2517          CF_MSG_LOG(if the second compile does not leave our definition intact error)
2518          AC_TRY_COMPILE([#include <sys/types.h>],[
2519 #ifndef _POSIX_C_SOURCE
2520 make an error
2521 #endif],,
2522          [cf_cv_posix_c_source=no])
2523          CFLAGS="$cf_save_CFLAGS"
2524          CPPFLAGS="$cf_save_CPPFLAGS"
2525         ])
2526 ])
2527
2528 if test "$cf_cv_posix_c_source" != no ; then
2529         CFLAGS="$cf_trim_CFLAGS"
2530         CPPFLAGS="$cf_trim_CPPFLAGS"
2531         CF_ADD_CFLAGS($cf_cv_posix_c_source)
2532 fi
2533
2534 ])dnl
2535 dnl ---------------------------------------------------------------------------
2536 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
2537 dnl ----------
2538 dnl Check for archiver "ar".
2539 AC_DEFUN([CF_PROG_AR],[
2540 AC_CHECK_TOOL(AR, ar, ar)
2541 ])
2542 dnl ---------------------------------------------------------------------------
2543 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
2544 dnl -----------
2545 dnl Check for awk, ensure that the check found something.
2546 AC_DEFUN([CF_PROG_AWK],
2547 [
2548 AC_PROG_AWK
2549 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
2550 ])dnl
2551 dnl ---------------------------------------------------------------------------
2552 dnl CF_PROG_CC_C_O version: 3 updated: 2010/08/14 18:25:37
2553 dnl --------------
2554 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
2555 dnl the output file can be renamed, and allows for a shell variable that can
2556 dnl be used later.  The parameter is either CC or CXX.  The result is the
2557 dnl cache variable:
2558 dnl     $cf_cv_prog_CC_c_o
2559 dnl     $cf_cv_prog_CXX_c_o
2560 AC_DEFUN([CF_PROG_CC_C_O],
2561 [AC_REQUIRE([AC_PROG_CC])dnl
2562 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
2563 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
2564 [
2565 cat > conftest.$ac_ext <<CF_EOF
2566 #include <stdio.h>
2567 int main()
2568 {
2569         ${cf_cv_main_return:-return}(0);
2570 }
2571 CF_EOF
2572 # We do the test twice because some compilers refuse to overwrite an
2573 # existing .o file with -o, though they will create one.
2574 ac_try='[$]$1 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
2575 if AC_TRY_EVAL(ac_try) &&
2576   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
2577 then
2578   eval cf_cv_prog_$1_c_o=yes
2579 else
2580   eval cf_cv_prog_$1_c_o=no
2581 fi
2582 rm -rf conftest*
2583 ])dnl
2584 if test $cf_cv_prog_$1_c_o = yes; then
2585   AC_MSG_RESULT([yes])
2586 else
2587   AC_MSG_RESULT([no])
2588 fi
2589 ])dnl
2590 dnl ---------------------------------------------------------------------------
2591 dnl CF_PROG_EGREP version: 1 updated: 2006/09/16 11:40:59
2592 dnl -------------
2593 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
2594 dnl This macro adds a check to ensure the script found something.
2595 AC_DEFUN([CF_PROG_EGREP],
2596 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
2597    [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
2598     then ac_cv_prog_egrep='grep -E'
2599     else ac_cv_prog_egrep='egrep'
2600     fi])
2601  EGREP=$ac_cv_prog_egrep
2602  AC_SUBST([EGREP])
2603 test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
2604 ])dnl
2605 dnl ---------------------------------------------------------------------------
2606 dnl CF_PROG_EXT version: 10 updated: 2004/01/03 19:28:18
2607 dnl -----------
2608 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
2609 AC_DEFUN([CF_PROG_EXT],
2610 [
2611 AC_REQUIRE([CF_CHECK_CACHE])
2612 case $cf_cv_system_name in
2613 os2*)
2614     CFLAGS="$CFLAGS -Zmt"
2615     CPPFLAGS="$CPPFLAGS -D__ST_MT_ERRNO__"
2616     CXXFLAGS="$CXXFLAGS -Zmt"
2617     # autoconf's macro sets -Zexe and suffix both, which conflict:w
2618     LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
2619     ac_cv_exeext=.exe
2620     ;;
2621 esac
2622
2623 AC_EXEEXT
2624 AC_OBJEXT
2625
2626 PROG_EXT="$EXEEXT"
2627 AC_SUBST(PROG_EXT)
2628 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT")
2629 ])dnl
2630 dnl ---------------------------------------------------------------------------
2631 dnl CF_PROG_GNAT version: 1 updated: 2010/06/19 15:22:18
2632 dnl ------------
2633 dnl Check for gnatmake, ensure that it is complete.
2634 AC_DEFUN([CF_PROG_GNAT],[
2635 cf_ada_make=gnatmake
2636 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
2637 if test "$ac_cv_prog_gnat_exists" = no; then
2638    cf_ada_make=
2639 else
2640    CF_GNAT_VERSION
2641    AC_CHECK_PROG(M4_exists, m4, yes, no)
2642    if test "$ac_cv_prog_M4_exists" = no; then
2643       cf_cv_prog_gnat_correct=no
2644       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
2645    fi
2646    if test "$cf_cv_prog_gnat_correct" = yes; then
2647       AC_MSG_CHECKING(if GNAT works)
2648       CF_GNAT_TRY_RUN([procedure conftest;],
2649 [with Text_IO;
2650 with GNAT.OS_Lib;
2651 procedure conftest is
2652 begin
2653    Text_IO.Put ("Hello World");
2654    Text_IO.New_Line;
2655    GNAT.OS_Lib.OS_Exit (0);
2656 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
2657       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
2658    fi
2659 fi
2660
2661 AC_SUBST(cf_ada_make)
2662 ])dnl
2663 dnl ---------------------------------------------------------------------------
2664 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
2665 dnl ------------
2666 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
2667 dnl option if it is supported.
2668 AC_DEFUN([CF_PROG_LN_S],[
2669 AC_PROG_LN_S
2670 AC_MSG_CHECKING(if $LN_S -f options work)
2671
2672 rm -f conf$$.src conf$$dst
2673 echo >conf$$.dst
2674 echo first >conf$$.src
2675 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
2676         cf_prog_ln_sf=yes
2677 else
2678         cf_prog_ln_sf=no
2679 fi
2680 rm -f conf$$.dst conf$$src
2681 AC_MSG_RESULT($cf_prog_ln_sf)
2682
2683 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
2684 ])dnl
2685 dnl ---------------------------------------------------------------------------
2686 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
2687 dnl ----------------
2688 dnl Remove all -U and -D options that refer to the given symbol from a list
2689 dnl of C compiler options.  This works around the problem that not all
2690 dnl compilers process -U and -D options from left-to-right, so a -U option
2691 dnl cannot be used to cancel the effect of a preceding -D option.
2692 dnl
2693 dnl $1 = target (which could be the same as the source variable)
2694 dnl $2 = source (including '$')
2695 dnl $3 = symbol to remove
2696 define([CF_REMOVE_DEFINE],
2697 [
2698 $1=`echo "$2" | \
2699         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
2700                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
2701 ])dnl
2702 dnl ---------------------------------------------------------------------------
2703 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
2704 dnl -------------
2705 dnl Remove the given library from the symbol
2706 dnl
2707 dnl $1 = target (which could be the same as the source variable)
2708 dnl $2 = source (including '$')
2709 dnl $3 = library to remove
2710 define([CF_REMOVE_LIB],
2711 [
2712 # remove $3 library from $2
2713 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
2714 ])dnl
2715 dnl ---------------------------------------------------------------------------
2716 dnl CF_SHARED_OPTS version: 64 updated: 2010/06/05 16:51:16
2717 dnl --------------
2718 dnl --------------
2719 dnl Attempt to determine the appropriate CC/LD options for creating a shared
2720 dnl library.
2721 dnl
2722 dnl Note: ${LOCAL_LDFLAGS} is used to link executables that will run within the
2723 dnl build-tree, i.e., by making use of the libraries that are compiled in ../lib
2724 dnl We avoid compiling-in a ../lib path for the shared library since that can
2725 dnl lead to unexpected results at runtime.
2726 dnl ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared libraries
2727 dnl are compiled in ../../lib
2728 dnl
2729 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
2730 dnl to install symbolic links to the rel/abi versions of shared libraries.
2731 dnl
2732 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
2733 dnl version when making symbolic links.
2734 dnl
2735 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
2736 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
2737 dnl (ex: libncurses.so.<ver>).
2738 dnl
2739 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
2740 AC_DEFUN([CF_SHARED_OPTS],
2741 [
2742         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
2743         AC_REQUIRE([CF_LD_RPATH_OPT])
2744         LOCAL_LDFLAGS=
2745         LOCAL_LDFLAGS2=
2746         LD_SHARED_OPTS=
2747         INSTALL_LIB="-m 644"
2748
2749         cf_cv_do_symlinks=no
2750         cf_ld_rpath_opt=
2751         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
2752
2753         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
2754         AC_ARG_WITH(shlib-version,
2755         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
2756         [test -z "$withval" && withval=auto
2757         case $withval in #(vi
2758         yes) #(vi
2759                 cf_cv_shlib_version=auto
2760                 ;;
2761         rel|abi|auto|no) #(vi
2762                 cf_cv_shlib_version=$withval
2763                 ;;
2764         *)
2765                 AC_MSG_ERROR([option value must be one of: rel, abi, auto or no])
2766                 ;;
2767         esac
2768         ],[cf_cv_shlib_version=auto])
2769         AC_MSG_RESULT($cf_cv_shlib_version)
2770
2771         cf_cv_rm_so_locs=no
2772
2773         # Some less-capable ports of gcc support only -fpic
2774         CC_SHARED_OPTS=
2775         if test "$GCC" = yes
2776         then
2777                 AC_MSG_CHECKING(which $CC option to use)
2778                 cf_save_CFLAGS="$CFLAGS"
2779                 for CC_SHARED_OPTS in -fPIC -fpic ''
2780                 do
2781                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
2782                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
2783                 done
2784                 AC_MSG_RESULT($CC_SHARED_OPTS)
2785                 CFLAGS="$cf_save_CFLAGS"
2786         fi
2787
2788         cf_cv_shlib_version_infix=no
2789
2790         case $cf_cv_system_name in #(vi
2791         aix[[56]]*) #(vi
2792                 if test "$GCC" = yes; then
2793                         CC_SHARED_OPTS=
2794                         MK_SHARED_LIB='$(CC) -shared'
2795                 fi
2796                 ;;
2797         beos*) #(vi
2798                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
2799                 ;;
2800         cygwin*) #(vi
2801                 CC_SHARED_OPTS=
2802                 MK_SHARED_LIB='sh ../mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
2803                 cf_cv_shlib_version=cygdll
2804                 cf_cv_shlib_version_infix=cygdll
2805                 cat >mk_shared_lib.sh <<-CF_EOF
2806                 #!/bin/sh
2807                 SHARED_LIB=\[$]1
2808                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
2809                 shift
2810                 cat <<-EOF
2811                 Linking shared library
2812                 ** SHARED_LIB \[$]SHARED_LIB
2813                 ** IMPORT_LIB \[$]IMPORT_LIB
2814 EOF
2815                 exec \[$]* -shared -Wl,--out-implib=../lib/\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o ../lib/\[$]{SHARED_LIB}
2816 CF_EOF
2817                 chmod +x mk_shared_lib.sh
2818                 ;;
2819         darwin*) #(vi
2820                 EXTRA_CFLAGS="-no-cpp-precomp"
2821                 CC_SHARED_OPTS="-dynamic"
2822                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
2823                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
2824                 cf_cv_shlib_version_infix=yes
2825                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
2826                         cf_save_LDFLAGS=$LDFLAGS
2827                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
2828                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
2829                                 LDFLAGS=$cf_save_LDFLAGS])
2830                 if test $cf_cv_ldflags_search_paths_first = yes; then
2831                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
2832                 fi
2833                 ;;
2834         hpux*) #(vi
2835                 # (tested with gcc 2.7.2 -- I don't have c89)
2836                 if test "$GCC" = yes; then
2837                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
2838                 else
2839                         CC_SHARED_OPTS='+Z'
2840                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
2841                 fi
2842                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
2843                 # HP-UX shared libraries must be executable, and should be
2844                 # readonly to exploit a quirk in the memory manager.
2845                 INSTALL_LIB="-m 555"
2846                 ;;
2847         irix*) #(vi
2848                 if test "$cf_cv_enable_rpath" = yes ; then
2849                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${libdir} $EXTRA_LDFLAGS"
2850                 fi
2851                 # tested with IRIX 5.2 and 'cc'.
2852                 if test "$GCC" != yes; then
2853                         CC_SHARED_OPTS='-KPIC'
2854                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
2855                 else
2856                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
2857                 fi
2858                 cf_cv_rm_so_locs=yes
2859                 ;;
2860         linux*|gnu*|k*bsd*-gnu) #(vi
2861                 if test "$DFT_LWR_MODEL" = "shared" ; then
2862                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
2863                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
2864                 fi
2865                 if test "$cf_cv_enable_rpath" = yes ; then
2866                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${libdir} $EXTRA_LDFLAGS"
2867                 fi
2868                 CF_SHARED_SONAME
2869                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
2870                 ;;
2871         openbsd[[2-9]].*) #(vi
2872                 if test "$DFT_LWR_MODEL" = "shared" ; then
2873                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
2874                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
2875                 fi
2876                 if test "$cf_cv_enable_rpath" = yes ; then
2877                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${libdir} $EXTRA_LDFLAGS"
2878                 fi
2879                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
2880                 CF_SHARED_SONAME
2881                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
2882                 ;;
2883         nto-qnx*|openbsd*|freebsd[[12]].*) #(vi
2884                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
2885                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
2886                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
2887                 ;;
2888         freebsd*) #(vi
2889                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
2890                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
2891                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
2892                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${libdir} $LOCAL_LDFLAGS"
2893                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${libdir} $EXTRA_LDFLAGS"
2894                 fi
2895                 CF_SHARED_SONAME
2896                 MK_SHARED_LIB='${LD} -shared -Bshareable -soname=`basename $[@]` -o $[@]'
2897                 ;;
2898         netbsd*) #(vi
2899                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
2900                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
2901                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
2902                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
2903                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${libdir} $EXTRA_LDFLAGS"
2904                         if test "$cf_cv_shlib_version" = auto; then
2905                         if test -f /usr/libexec/ld.elf_so; then
2906                                 cf_cv_shlib_version=abi
2907                         else
2908                                 cf_cv_shlib_version=rel
2909                         fi
2910                         fi
2911                         CF_SHARED_SONAME
2912                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
2913                 else
2914                         MK_SHARED_LIB='${LD} -shared -Bshareable -o $[@]'
2915                 fi
2916                 ;;
2917         osf*|mls+*) #(vi
2918                 # tested with OSF/1 V3.2 and 'cc'
2919                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
2920                 # link with shared libs).
2921                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
2922                 case $host_os in #(vi
2923                 osf4*)
2924                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
2925                         ;;
2926                 esac
2927                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
2928                 if test "$DFT_LWR_MODEL" = "shared" ; then
2929                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
2930                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
2931                 fi
2932                 cf_cv_rm_so_locs=yes
2933                 ;;
2934         sco3.2v5*)  # (also uw2* and UW7: hops 13-Apr-98
2935                 # tested with osr5.0.5
2936                 if test "$GCC" != yes; then
2937                         CC_SHARED_OPTS='-belf -KPIC'
2938                 fi
2939                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
2940                 if test "$cf_cv_enable_rpath" = yes ; then
2941                         # only way is to set LD_RUN_PATH but no switch for it
2942                         RUN_PATH=$libdir
2943                 fi
2944                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
2945                 LINK_PROGS='LD_RUN_PATH=${libdir}'
2946                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
2947                 ;;
2948         sunos4*) #(vi
2949                 # tested with SunOS 4.1.1 and gcc 2.7.0
2950                 if test "$GCC" != yes; then
2951                         CC_SHARED_OPTS='-KPIC'
2952                 fi
2953                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
2954                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
2955                 ;;
2956         solaris2*) #(vi
2957                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
2958                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
2959                 if test "$DFT_LWR_MODEL" = "shared" ; then
2960                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
2961                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
2962                 fi
2963                 if test "$cf_cv_enable_rpath" = yes ; then
2964                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
2965                 fi
2966                 CF_SHARED_SONAME
2967                 if test "$GCC" != yes; then
2968                         cf_save_CFLAGS="$CFLAGS"
2969                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
2970                         do
2971                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
2972                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
2973                         done
2974                         CFLAGS="$cf_save_CFLAGS"
2975                         CC_SHARED_OPTS=$cf_shared_opts
2976                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
2977                 else
2978                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
2979                 fi
2980                 ;;
2981         sysv5uw7*|unix_sv*) #(vi
2982                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
2983                 if test "$GCC" != yes; then
2984                         CC_SHARED_OPTS='-KPIC'
2985                 fi
2986                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
2987                 ;;
2988         *)
2989                 CC_SHARED_OPTS='unknown'
2990                 MK_SHARED_LIB='echo unknown'
2991                 ;;
2992         esac
2993
2994         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
2995         case "$cf_cv_shlib_version" in #(vi
2996         rel|abi)
2997                 case "$MK_SHARED_LIB" in #(vi
2998                 *'-o $[@]') #(vi
2999                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
3000                         ;;
3001                 *)
3002                         AC_MSG_WARN(ignored --with-shlib-version)
3003                         ;;
3004                 esac
3005                 ;;
3006         esac
3007
3008         if test -n "$cf_ld_rpath_opt" ; then
3009                 MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${libdir}"
3010         fi
3011
3012         AC_SUBST(CC_SHARED_OPTS)
3013         AC_SUBST(LD_RPATH_OPT)
3014         AC_SUBST(LD_SHARED_OPTS)
3015         AC_SUBST(MK_SHARED_LIB)
3016         AC_SUBST(LINK_PROGS)
3017         AC_SUBST(LINK_TESTS)
3018         AC_SUBST(EXTRA_LDFLAGS)
3019         AC_SUBST(LOCAL_LDFLAGS)
3020         AC_SUBST(LOCAL_LDFLAGS2)
3021         AC_SUBST(INSTALL_LIB)
3022 ])dnl
3023 dnl ---------------------------------------------------------------------------
3024 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
3025 dnl ----------------
3026 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
3027 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
3028 dnl option.
3029 dnl
3030 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
3031 dnl If missing, use "rel".
3032 define([CF_SHARED_SONAME],
3033 [
3034         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
3035         if test "$cf_cv_shlib_version" = rel; then
3036                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
3037         else
3038                 cf_cv_shared_soname='`basename $[@]`'
3039         fi
3040 ])
3041 dnl ---------------------------------------------------------------------------
3042 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
3043 dnl --------------
3044 dnl     Remove "-g" option from the compiler options
3045 AC_DEFUN([CF_STRIP_G_OPT],
3046 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
3047 dnl ---------------------------------------------------------------------------
3048 dnl CF_SUBDIR_PATH version: 6 updated: 2010/04/21 06:20:50
3049 dnl --------------
3050 dnl Construct a search-list for a nonstandard header/lib-file
3051 dnl     $1 = the variable to return as result
3052 dnl     $2 = the package name
3053 dnl     $3 = the subdirectory, e.g., bin, include or lib
3054 AC_DEFUN([CF_SUBDIR_PATH],
3055 [
3056 $1=
3057
3058 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr,$prefix)
3059 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
3060 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr/local,$prefix)
3061 CF_ADD_SUBDIR_PATH($1,$2,$3,/opt,$prefix)
3062 CF_ADD_SUBDIR_PATH($1,$2,$3,[$]HOME,$prefix)
3063 ])dnl
3064 dnl ---------------------------------------------------------------------------
3065 dnl CF_SUBST version: 4 updated: 2006/06/17 12:33:03
3066 dnl --------
3067 dnl     Shorthand macro for substituting things that the user may override
3068 dnl     with an environment variable.
3069 dnl
3070 dnl     $1 = long/descriptive name
3071 dnl     $2 = environment variable
3072 dnl     $3 = default value
3073 AC_DEFUN([CF_SUBST],
3074 [AC_CACHE_VAL(cf_cv_subst_$2,[
3075 AC_MSG_CHECKING(for $1 (symbol $2))
3076 CF_SUBST_IF([-z "[$]$2"], [$2], [$3])
3077 cf_cv_subst_$2=[$]$2
3078 AC_MSG_RESULT([$]$2)
3079 ])
3080 ])dnl
3081 dnl ---------------------------------------------------------------------------
3082 dnl CF_TERM_HEADER version: 2 updated: 2010/10/23 15:54:49
3083 dnl --------------
3084 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
3085 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
3086 dnl but some packagers change this, breaking various applications.
3087 AC_DEFUN([CF_TERM_HEADER],[
3088 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
3089 case ${cf_cv_ncurses_header} in #(vi
3090 */ncurses.h|*/ncursesw.h) #(vi
3091         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
3092         ;;
3093 *)
3094         cf_term_header=term.h
3095         ;;
3096 esac
3097
3098 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
3099 do
3100 AC_TRY_COMPILE([#include <stdio.h>
3101 #include <${cf_cv_ncurses_header:-curses.h}>
3102 #include <$cf_test>
3103 ],[int x = auto_left_margin],[
3104         cf_cv_term_header="$cf_test"],[
3105         cf_cv_term_header=unknown
3106         ])
3107         test "$cf_cv_term_header" != unknown && break
3108 done
3109 ])
3110
3111 # Set definitions to allow ifdef'ing to accommodate subdirectories
3112
3113 case $cf_cv_term_header in # (vi
3114 *term.h)
3115         AC_DEFINE(HAVE_TERM_H)
3116         ;;
3117 esac
3118
3119 case $cf_cv_term_header in # (vi
3120 ncurses/term.h) #(vi
3121         AC_DEFINE(HAVE_NCURSES_TERM_H)
3122         ;;
3123 ncursesw/term.h)
3124         AC_DEFINE(HAVE_NCURSESW_TERM_H)
3125         ;;
3126 esac
3127 ])dnl
3128 dnl ---------------------------------------------------------------------------
3129 dnl CF_TOP_BUILDDIR version: 1 updated: 2006/10/15 16:33:23
3130 dnl ---------------
3131 dnl Define a top_builddir symbol, for applications that need an absolute path.
3132 AC_DEFUN([CF_TOP_BUILDDIR],
3133 [
3134 top_builddir=`pwd`
3135 AC_SUBST(top_builddir)
3136 ])dnl
3137 dnl ---------------------------------------------------------------------------
3138 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
3139 dnl --------
3140 dnl Make an uppercase version of a variable
3141 dnl $1=uppercase($2)
3142 AC_DEFUN([CF_UPPER],
3143 [
3144 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
3145 ])dnl
3146 dnl ---------------------------------------------------------------------------
3147 dnl CF_UTF8_LIB version: 7 updated: 2010/06/20 09:24:28
3148 dnl -----------
3149 dnl Check for multibyte support, and if not found, utf8 compatibility library
3150 AC_DEFUN([CF_UTF8_LIB],
3151 [
3152 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
3153         cf_save_LIBS="$LIBS"
3154         AC_TRY_LINK([
3155 #include <stdlib.h>],[putwc(0,0);],
3156         [cf_cv_utf8_lib=yes],
3157         [CF_FIND_LINKAGE([
3158 #include <libutf8.h>],[putwc(0,0);],utf8,
3159                 [cf_cv_utf8_lib=add-on],
3160                 [cf_cv_utf8_lib=no])
3161 ])])
3162
3163 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
3164 # ncurses/ncursesw:
3165 if test "$cf_cv_utf8_lib" = "add-on" ; then
3166         AC_DEFINE(HAVE_LIBUTF8_H)
3167         CF_ADD_INCDIR($cf_cv_header_path_utf8)
3168         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
3169         CF_ADD_LIBS($cf_cv_library_file_utf8)
3170 fi
3171 ])dnl
3172 dnl ---------------------------------------------------------------------------
3173 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
3174 dnl ----------
3175 dnl Use AC_VERBOSE w/o the warnings
3176 AC_DEFUN([CF_VERBOSE],
3177 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
3178 CF_MSG_LOG([$1])
3179 ])dnl
3180 dnl ---------------------------------------------------------------------------
3181 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
3182 dnl ---------------
3183 dnl Check for compiler-support for weak symbols.
3184 dnl This works with "recent" gcc.
3185 AC_DEFUN([CF_WEAK_SYMBOLS],[
3186 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
3187
3188 AC_TRY_COMPILE([
3189 #include <stdio.h>],
3190 [
3191 #if defined(__GNUC__)
3192 #  if defined __USE_ISOC99
3193 #    define _cat_pragma(exp)    _Pragma(#exp)
3194 #    define _weak_pragma(exp)   _cat_pragma(weak name)
3195 #  else
3196 #    define _weak_pragma(exp)
3197 #  endif
3198 #  define _declare(name)        __extension__ extern __typeof__(name) name
3199 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
3200 #endif
3201
3202 weak_symbol(fopen);
3203 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
3204 ])
3205 ])dnl
3206 dnl ---------------------------------------------------------------------------
3207 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
3208 dnl --------------------
3209 dnl Command-line option to specify the Ada95 compiler.
3210 AC_DEFUN([CF_WITH_ADA_COMPILER],[
3211 AC_MSG_CHECKING(for ada-compiler)
3212 AC_ARG_WITH(ada-compiler,
3213         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
3214         [cf_ada_compiler=$withval],
3215         [cf_ada_compiler=gnatmake])
3216 AC_SUBST(cf_ada_compiler)
3217 AC_MSG_RESULT($cf_ada_compiler)
3218 ])dnl
3219 dnl ---------------------------------------------------------------------------
3220 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
3221 dnl -------------------
3222 dnl Command-line option to specify where Ada includes will install.
3223 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
3224 AC_MSG_CHECKING(for ada-include)
3225 CF_WITH_PATH(ada-include,
3226    [  --with-ada-include=DIR  Ada includes are in DIR],
3227    ADA_INCLUDE,
3228    PREFIX/share/ada/adainclude,
3229    [$]prefix/share/ada/adainclude)
3230 AC_SUBST(ADA_INCLUDE)
3231 AC_MSG_RESULT($ADA_INCLUDE)
3232 ])dnl
3233 dnl ---------------------------------------------------------------------------
3234 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
3235 dnl -------------------
3236 dnl Command-line option to specify where Ada objects will install.
3237 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
3238 AC_MSG_CHECKING(for ada-objects)
3239 CF_WITH_PATH(ada-objects,
3240    [  --with-ada-objects=DIR  Ada objects are in DIR],
3241    ADA_OBJECTS,
3242    PREFIX/lib/ada/adalib,
3243    [$]prefix/lib/ada/adalib)
3244 AC_SUBST(ADA_OBJECTS)
3245 AC_MSG_RESULT($ADA_OBJECTS)
3246 ])dnl
3247 dnl ---------------------------------------------------------------------------
3248 dnl CF_WITH_ADA_SHAREDLIB version: 2 updated: 2010/06/26 17:35:58
3249 dnl ---------------------
3250 dnl Command-line option to specify if an Ada95 shared-library should be built,
3251 dnl and optionally what its soname should be.
3252 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
3253 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
3254 AC_ARG_WITH(ada-sharedlib,
3255         [  --with-ada-sharedlib=XX build Ada95 shared-library],
3256         [with_ada_sharedlib=$withval],
3257         [with_ada_sharedlib=no])
3258 AC_MSG_RESULT($with_ada_sharedlib)
3259
3260 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
3261 MAKE_ADA_SHAREDLIB="#"
3262
3263 if test "x$with_ada_sharedlib" != xno
3264 then
3265         MAKE_ADA_SHAREDLIB=
3266         if test "x$with_ada_sharedlib" != xyes
3267         then
3268                 ADA_SHAREDLIB="$with_ada_sharedlib"
3269         fi
3270 fi
3271
3272 AC_SUBST(ADA_SHAREDLIB)
3273 AC_SUBST(MAKE_ADA_SHAREDLIB)
3274 ])dnl
3275 dnl ---------------------------------------------------------------------------
3276 dnl CF_WITH_CURSES_DIR version: 3 updated: 2010/11/20 17:02:38
3277 dnl ------------------
3278 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
3279 dnl libraries.
3280 AC_DEFUN([CF_WITH_CURSES_DIR],[
3281
3282 AC_MSG_CHECKING(for specific curses-directory)
3283 AC_ARG_WITH(curses-dir,
3284         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
3285         [cf_cv_curses_dir=$withval],
3286         [cf_cv_curses_dir=no])
3287 AC_MSG_RESULT($cf_cv_curses_dir)
3288
3289 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
3290 then
3291         CF_PATH_SYNTAX(withval)
3292         if test -d "$cf_cv_curses_dir"
3293         then
3294                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
3295                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
3296         fi
3297 fi
3298 ])dnl
3299 dnl ---------------------------------------------------------------------------
3300 dnl CF_WITH_PATH version: 10 updated: 2010/10/23 15:44:18
3301 dnl ------------
3302 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
3303 dnl defaulting to yes/no.
3304 dnl
3305 dnl $1 = option name
3306 dnl $2 = help-text
3307 dnl $3 = environment variable to set
3308 dnl $4 = default value, shown in the help-message, must be a constant
3309 dnl $5 = default value, if it's an expression & cannot be in the help-message
3310 dnl
3311 AC_DEFUN([CF_WITH_PATH],
3312 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
3313 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
3314 if ifelse([$5],,true,[test -n "$5"]) ; then
3315 CF_PATH_SYNTAX(withval)
3316 fi
3317 $3="$withval"
3318 AC_SUBST($3)dnl
3319 ])dnl
3320 dnl ---------------------------------------------------------------------------
3321 dnl CF_WITH_PTHREAD version: 3 updated: 2010/05/29 16:31:02
3322 dnl ---------------
3323 dnl Check for POSIX thread library.
3324 AC_DEFUN([CF_WITH_PTHREAD],
3325 [
3326 AC_MSG_CHECKING(if you want to link with the pthread library)
3327 AC_ARG_WITH(pthread,
3328     [  --with-pthread          use POSIX thread library],
3329     [with_pthread=$withval],
3330     [with_pthread=no])
3331 AC_MSG_RESULT($with_pthread)
3332
3333 if test "$with_pthread" != no ; then
3334     AC_CHECK_HEADER(pthread.h,[
3335         AC_DEFINE(HAVE_PTHREADS_H)
3336
3337         AC_MSG_CHECKING(if we can link with the pthread library)
3338         cf_save_LIBS="$LIBS"
3339         CF_ADD_LIB(pthread)
3340         AC_TRY_LINK([
3341 #include <pthread.h>
3342 ],[
3343         int rc = pthread_create(0,0,0,0);
3344 ],[with_pthread=yes],[with_pthread=no])
3345         LIBS="$cf_save_LIBS"
3346         AC_MSG_RESULT($with_pthread)
3347
3348         if test "$with_pthread" = yes ; then
3349             CF_ADD_LIB(pthread)
3350             AC_DEFINE(HAVE_LIBPTHREADS)
3351         else
3352             AC_MSG_ERROR(Cannot link with pthread library)
3353         fi
3354     ])
3355 fi
3356 ])
3357 dnl ---------------------------------------------------------------------------
3358 dnl CF_XOPEN_SOURCE version: 34 updated: 2010/05/26 05:38:42
3359 dnl ---------------
3360 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
3361 dnl or adapt to the vendor's definitions to get equivalent functionality,
3362 dnl without losing the common non-POSIX features.
3363 dnl
3364 dnl Parameters:
3365 dnl     $1 is the nominal value for _XOPEN_SOURCE
3366 dnl     $2 is the nominal value for _POSIX_C_SOURCE
3367 AC_DEFUN([CF_XOPEN_SOURCE],[
3368
3369 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
3370 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
3371 cf_xopen_source=
3372
3373 case $host_os in #(vi
3374 aix[[456]]*) #(vi
3375         cf_xopen_source="-D_ALL_SOURCE"
3376         ;;
3377 darwin[[0-8]].*) #(vi
3378         cf_xopen_source="-D_APPLE_C_SOURCE"
3379         ;;
3380 darwin*) #(vi
3381         cf_xopen_source="-D_DARWIN_C_SOURCE"
3382         ;;
3383 freebsd*|dragonfly*) #(vi
3384         # 5.x headers associate
3385         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
3386         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
3387         cf_POSIX_C_SOURCE=200112L
3388         cf_XOPEN_SOURCE=600
3389         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3390         ;;
3391 hpux11*) #(vi
3392         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
3393         ;;
3394 hpux*) #(vi
3395         cf_xopen_source="-D_HPUX_SOURCE"
3396         ;;
3397 irix[[56]].*) #(vi
3398         cf_xopen_source="-D_SGI_SOURCE"
3399         ;;
3400 linux*|gnu*|mint*|k*bsd*-gnu) #(vi
3401         CF_GNU_SOURCE
3402         ;;
3403 mirbsd*) #(vi
3404         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <arpa/inet.h>
3405         ;;
3406 netbsd*) #(vi
3407         # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
3408         ;;
3409 openbsd*) #(vi
3410         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
3411         ;;
3412 osf[[45]]*) #(vi
3413         cf_xopen_source="-D_OSF_SOURCE"
3414         ;;
3415 nto-qnx*) #(vi
3416         cf_xopen_source="-D_QNX_SOURCE"
3417         ;;
3418 sco*) #(vi
3419         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
3420         ;;
3421 solaris2.1[[0-9]]) #(vi
3422         cf_xopen_source="-D__EXTENSIONS__ -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3423         ;;
3424 solaris2.[[1-9]]) #(vi
3425         cf_xopen_source="-D__EXTENSIONS__"
3426         ;;
3427 *)
3428         AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
3429         AC_TRY_COMPILE([#include <sys/types.h>],[
3430 #ifndef _XOPEN_SOURCE
3431 make an error
3432 #endif],
3433         [cf_cv_xopen_source=no],
3434         [cf_save="$CPPFLAGS"
3435          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
3436          AC_TRY_COMPILE([#include <sys/types.h>],[
3437 #ifdef _XOPEN_SOURCE
3438 make an error
3439 #endif],
3440         [cf_cv_xopen_source=no],
3441         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
3442         CPPFLAGS="$cf_save"
3443         ])
3444 ])
3445         if test "$cf_cv_xopen_source" != no ; then
3446                 CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
3447                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
3448                 cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
3449                 CF_ADD_CFLAGS($cf_temp_xopen_source)
3450         fi
3451         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
3452         ;;
3453 esac
3454
3455 if test -n "$cf_xopen_source" ; then
3456         CF_ADD_CFLAGS($cf_xopen_source)
3457 fi
3458 ])