ncurses 6.1 - patch 20180908
[ncurses.git] / Ada95 / aclocal.m4
1 dnl***************************************************************************
2 dnl Copyright (c) 2010-2017,2018 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey
30 dnl
31 dnl $Id: aclocal.m4,v 1.136 2018/08/18 20:38:26 tom Exp $
32 dnl Macros used in NCURSES Ada95 auto-configuration script.
33 dnl
34 dnl These macros are maintained separately from NCURSES.  The copyright on
35 dnl this file applies to the aggregation of macros and does not affect use of
36 dnl these macros in other applications.
37 dnl
38 dnl See https://invisible-island.net/autoconf/ for additional information.
39 dnl
40 dnl ---------------------------------------------------------------------------
41 dnl ---------------------------------------------------------------------------
42 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
43 dnl ------------------
44 dnl Conditionally generate script according to whether we're using a given autoconf.
45 dnl
46 dnl $1 = version to compare against
47 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
48 dnl $3 = code to use if AC_ACVERSION is older than $1.
49 define([CF_ACVERSION_CHECK],
50 [
51 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
52 ifdef([m4_version_compare],
53 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
54 [CF_ACVERSION_COMPARE(
55 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
56 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
57 dnl ---------------------------------------------------------------------------
58 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
59 dnl --------------------
60 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
61 dnl                      MAJOR2, MINOR2, TERNARY2,
62 dnl                      PRINTABLE2, not FOUND, FOUND)
63 define([CF_ACVERSION_COMPARE],
64 [ifelse(builtin([eval], [$2 < $5]), 1,
65 [ifelse([$8], , ,[$8])],
66 [ifelse([$9], , ,[$9])])])dnl
67 dnl ---------------------------------------------------------------------------
68 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
69 dnl -------------------
70 dnl Construct the list of include-options for the C programs in the Ada95
71 dnl binding.
72 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
73 [
74 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
75 if test "$srcdir" != "."; then
76         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
77 fi
78 if test "$GCC" != yes; then
79         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
80 elif test "$includedir" != "/usr/include"; then
81         if test "$includedir" = '${prefix}/include' ; then
82                 if test x$prefix != x/usr ; then
83                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
84                 fi
85         else
86                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
87         fi
88 fi
89 AC_SUBST(ACPPFLAGS)
90 ])dnl
91 dnl ---------------------------------------------------------------------------
92 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
93 dnl ---------------
94 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
95 AC_DEFUN([CF_ADD_ADAFLAGS],[
96         ADAFLAGS="$ADAFLAGS $1"
97         AC_SUBST(ADAFLAGS)
98 ])dnl
99 dnl ---------------------------------------------------------------------------
100 dnl CF_ADD_CFLAGS version: 13 updated: 2017/02/25 18:57:40
101 dnl -------------
102 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
103 dnl The second parameter if given makes this macro verbose.
104 dnl
105 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
106 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
107 dnl confused by the quotes (which require backslashes to keep them usable).
108 AC_DEFUN([CF_ADD_CFLAGS],
109 [
110 cf_fix_cppflags=no
111 cf_new_cflags=
112 cf_new_cppflags=
113 cf_new_extra_cppflags=
114
115 for cf_add_cflags in $1
116 do
117 case $cf_fix_cppflags in
118 (no)
119         case $cf_add_cflags in
120         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
121                 case $cf_add_cflags in
122                 (-D*)
123                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
124
125                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
126                                 && test -z "${cf_tst_cflags}" \
127                                 && cf_fix_cppflags=yes
128
129                         if test $cf_fix_cppflags = yes ; then
130                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
131                                 continue
132                         elif test "${cf_tst_cflags}" = "\"'" ; then
133                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
134                                 continue
135                         fi
136                         ;;
137                 esac
138                 case "$CPPFLAGS" in
139                 (*$cf_add_cflags)
140                         ;;
141                 (*)
142                         case $cf_add_cflags in
143                         (-D*)
144                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
145                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
146                                 ;;
147                         esac
148                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
149                         ;;
150                 esac
151                 ;;
152         (*)
153                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
154                 ;;
155         esac
156         ;;
157 (yes)
158         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
159
160         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
161
162         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
163                 && test -z "${cf_tst_cflags}" \
164                 && cf_fix_cppflags=no
165         ;;
166 esac
167 done
168
169 if test -n "$cf_new_cflags" ; then
170         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
171         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
172 fi
173
174 if test -n "$cf_new_cppflags" ; then
175         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
176         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
177 fi
178
179 if test -n "$cf_new_extra_cppflags" ; then
180         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
181         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
182 fi
183
184 AC_SUBST(EXTRA_CPPFLAGS)
185
186 ])dnl
187 dnl ---------------------------------------------------------------------------
188 dnl CF_ADD_INCDIR version: 15 updated: 2018/06/20 20:23:13
189 dnl -------------
190 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
191 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
192 dnl but old versions (and some misinstalled ones) need that.  To make things
193 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
194 dnl the include-path).
195 AC_DEFUN([CF_ADD_INCDIR],
196 [
197 if test -n "$1" ; then
198   for cf_add_incdir in $1
199   do
200         while test $cf_add_incdir != /usr/include
201         do
202           if test -d $cf_add_incdir
203           then
204                 cf_have_incdir=no
205                 if test -n "$CFLAGS$CPPFLAGS" ; then
206                   # a loop is needed to ensure we can add subdirs of existing dirs
207                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
208                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
209                           cf_have_incdir=yes; break
210                         fi
211                   done
212                 fi
213
214                 if test "$cf_have_incdir" = no ; then
215                   if test "$cf_add_incdir" = /usr/local/include ; then
216                         if test "$GCC" = yes
217                         then
218                           cf_save_CPPFLAGS=$CPPFLAGS
219                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
220                           AC_TRY_COMPILE([#include <stdio.h>],
221                                   [printf("Hello")],
222                                   [],
223                                   [cf_have_incdir=yes])
224                           CPPFLAGS=$cf_save_CPPFLAGS
225                         fi
226                   fi
227                 fi
228
229                 if test "$cf_have_incdir" = no ; then
230                   CF_VERBOSE(adding $cf_add_incdir to include-path)
231                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
232
233                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
234                   test "$cf_top_incdir" = "$cf_add_incdir" && break
235                   cf_add_incdir="$cf_top_incdir"
236                 else
237                   break
238                 fi
239           else
240                 break
241           fi
242         done
243   done
244 fi
245 ])dnl
246 dnl ---------------------------------------------------------------------------
247 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
248 dnl ----------
249 dnl Add a library, used to enforce consistency.
250 dnl
251 dnl $1 = library to add, without the "-l"
252 dnl $2 = variable to update (default $LIBS)
253 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
254 dnl ---------------------------------------------------------------------------
255 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
256 dnl -------------
257 dnl     Adds to the library-path
258 dnl
259 dnl     Some machines have trouble with multiple -L options.
260 dnl
261 dnl $1 is the (list of) directory(s) to add
262 dnl $2 is the optional name of the variable to update (default LDFLAGS)
263 dnl
264 AC_DEFUN([CF_ADD_LIBDIR],
265 [
266 if test -n "$1" ; then
267         for cf_add_libdir in $1
268         do
269                 if test $cf_add_libdir = /usr/lib ; then
270                         :
271                 elif test -d $cf_add_libdir
272                 then
273                         cf_have_libdir=no
274                         if test -n "$LDFLAGS$LIBS" ; then
275                                 # a loop is needed to ensure we can add subdirs of existing dirs
276                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
277                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
278                                                 cf_have_libdir=yes; break
279                                         fi
280                                 done
281                         fi
282                         if test "$cf_have_libdir" = no ; then
283                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
284                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
285                         fi
286                 fi
287         done
288 fi
289 ])dnl
290 dnl ---------------------------------------------------------------------------
291 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
292 dnl -----------
293 dnl Add one or more libraries, used to enforce consistency.  Libraries are
294 dnl prepended to an existing list, since their dependencies are assumed to
295 dnl already exist in the list.
296 dnl
297 dnl $1 = libraries to add, with the "-l", etc.
298 dnl $2 = variable to update (default $LIBS)
299 AC_DEFUN([CF_ADD_LIBS],[
300 cf_add_libs="$1"
301 # Filter out duplicates - this happens with badly-designed ".pc" files...
302 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
303 do
304         for cf_add_2lib in $cf_add_libs
305         do
306                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
307                 then
308                         cf_add_1lib=
309                         break
310                 fi
311         done
312         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
313 done
314 ifelse($2,,LIBS,[$2])="$cf_add_libs"
315 ])dnl
316 dnl ---------------------------------------------------------------------------
317 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
318 dnl ------------------
319 dnl Append to a search-list for a nonstandard header/lib-file
320 dnl     $1 = the variable to return as result
321 dnl     $2 = the package name
322 dnl     $3 = the subdirectory, e.g., bin, include or lib
323 dnl $4 = the directory under which we will test for subdirectories
324 dnl $5 = a directory that we do not want $4 to match
325 AC_DEFUN([CF_ADD_SUBDIR_PATH],
326 [
327 test "x$4" != "x$5" && \
328 test -d "$4" && \
329 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
330         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
331         test -d $4/$3 &&          $1="[$]$1 $4/$3"
332         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
333         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
334         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
335         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
336 }
337 ])dnl
338 dnl ---------------------------------------------------------------------------
339 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
340 dnl --------------
341 dnl use this macro for appending text without introducing an extra blank at
342 dnl the beginning
343 define([CF_APPEND_TEXT],
344 [
345         test -n "[$]$1" && $1="[$]$1 "
346         $1="[$]{$1}$2"
347 ])dnl
348 dnl ---------------------------------------------------------------------------
349 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
350 dnl --------------
351 dnl Allow user to disable a normally-on option.
352 AC_DEFUN([CF_ARG_DISABLE],
353 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
354 dnl ---------------------------------------------------------------------------
355 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
356 dnl -------------
357 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
358 dnl values.
359 dnl
360 dnl Parameters:
361 dnl $1 = option name
362 dnl $2 = help-string
363 dnl $3 = action to perform if option is not default
364 dnl $4 = action if perform if option is default
365 dnl $5 = default option value (either 'yes' or 'no')
366 AC_DEFUN([CF_ARG_OPTION],
367 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
368         if test "$enableval" != "$5" ; then
369 ifelse([$3],,[    :]dnl
370 ,[    $3]) ifelse([$4],,,[
371         else
372                 $4])
373         fi],[enableval=$5 ifelse([$4],,,[
374         $4
375 ])dnl
376 ])])dnl
377 dnl ---------------------------------------------------------------------------
378 dnl CF_AR_FLAGS version: 6 updated: 2015/10/10 15:25:05
379 dnl -----------
380 dnl Check for suitable "ar" (archiver) options for updating an archive.
381 dnl
382 dnl In particular, handle some obsolete cases where the "-" might be omitted,
383 dnl as well as a workaround for breakage of make's archive rules by the GNU
384 dnl binutils "ar" program.
385 AC_DEFUN([CF_AR_FLAGS],[
386 AC_REQUIRE([CF_PROG_AR])
387
388 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
389         cf_cv_ar_flags=unknown
390         for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
391         do
392
393                 # check if $ARFLAGS already contains this choice
394                 if test "x$ARFLAGS" != "x" ; then
395                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
396                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
397                                 cf_cv_ar_flags=
398                                 break
399                         fi
400                 fi
401
402                 rm -f conftest.$ac_cv_objext
403                 rm -f conftest.a
404
405                 cat >conftest.$ac_ext <<EOF
406 #line __oline__ "configure"
407 int     testdata[[3]] = { 123, 456, 789 };
408 EOF
409                 if AC_TRY_EVAL(ac_compile) ; then
410                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
411                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
412                         if test -f conftest.a ; then
413                                 cf_cv_ar_flags=$cf_ar_flags
414                                 break
415                         fi
416                 else
417                         CF_VERBOSE(cannot compile test-program)
418                         break
419                 fi
420         done
421         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
422 ])
423
424 if test -n "$ARFLAGS" ; then
425         if test -n "$cf_cv_ar_flags" ; then
426                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
427         fi
428 else
429         ARFLAGS=$cf_cv_ar_flags
430 fi
431
432 AC_SUBST(ARFLAGS)
433 ])
434 dnl ---------------------------------------------------------------------------
435 dnl CF_BUILD_CC version: 8 updated: 2018/01/04 20:31:04
436 dnl -----------
437 dnl If we're cross-compiling, allow the user to override the tools and their
438 dnl options.  The configure script is oriented toward identifying the host
439 dnl compiler, etc., but we need a build compiler to generate parts of the
440 dnl source.
441 dnl
442 dnl $1 = default for $CPPFLAGS
443 dnl $2 = default for $LIBS
444 AC_DEFUN([CF_BUILD_CC],[
445 CF_ACVERSION_CHECK(2.52,,
446         [AC_REQUIRE([CF_PROG_EXT])])
447 if test "$cross_compiling" = yes ; then
448
449         # defaults that we might want to override
450         : ${BUILD_CFLAGS:=''}
451         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
452         : ${BUILD_LDFLAGS:=''}
453         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
454         : ${BUILD_EXEEXT:='$x'}
455         : ${BUILD_OBJEXT:='o'}
456
457         AC_ARG_WITH(build-cc,
458                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
459                 [BUILD_CC="$withval"],
460                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
461         AC_MSG_CHECKING(for native build C compiler)
462         AC_MSG_RESULT($BUILD_CC)
463
464         AC_MSG_CHECKING(for native build C preprocessor)
465         AC_ARG_WITH(build-cpp,
466                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
467                 [BUILD_CPP="$withval"],
468                 [BUILD_CPP='${BUILD_CC} -E'])
469         AC_MSG_RESULT($BUILD_CPP)
470
471         AC_MSG_CHECKING(for native build C flags)
472         AC_ARG_WITH(build-cflags,
473                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
474                 [BUILD_CFLAGS="$withval"])
475         AC_MSG_RESULT($BUILD_CFLAGS)
476
477         AC_MSG_CHECKING(for native build C preprocessor-flags)
478         AC_ARG_WITH(build-cppflags,
479                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
480                 [BUILD_CPPFLAGS="$withval"])
481         AC_MSG_RESULT($BUILD_CPPFLAGS)
482
483         AC_MSG_CHECKING(for native build linker-flags)
484         AC_ARG_WITH(build-ldflags,
485                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
486                 [BUILD_LDFLAGS="$withval"])
487         AC_MSG_RESULT($BUILD_LDFLAGS)
488
489         AC_MSG_CHECKING(for native build linker-libraries)
490         AC_ARG_WITH(build-libs,
491                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
492                 [BUILD_LIBS="$withval"])
493         AC_MSG_RESULT($BUILD_LIBS)
494
495         # this assumes we're on Unix.
496         BUILD_EXEEXT=
497         BUILD_OBJEXT=o
498
499         : ${BUILD_CC:='${CC}'}
500
501         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
502                 AC_MSG_ERROR([Cross-build requires two compilers.
503 Use --with-build-cc to specify the native compiler.])
504         fi
505
506 else
507         : ${BUILD_CC:='${CC}'}
508         : ${BUILD_CPP:='${CPP}'}
509         : ${BUILD_CFLAGS:='${CFLAGS}'}
510         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
511         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
512         : ${BUILD_LIBS:='${LIBS}'}
513         : ${BUILD_EXEEXT:='$x'}
514         : ${BUILD_OBJEXT:='o'}
515 fi
516
517 AC_SUBST(BUILD_CC)
518 AC_SUBST(BUILD_CPP)
519 AC_SUBST(BUILD_CFLAGS)
520 AC_SUBST(BUILD_CPPFLAGS)
521 AC_SUBST(BUILD_LDFLAGS)
522 AC_SUBST(BUILD_LIBS)
523 AC_SUBST(BUILD_EXEEXT)
524 AC_SUBST(BUILD_OBJEXT)
525 ])dnl
526 dnl ---------------------------------------------------------------------------
527 dnl CF_CC_ENV_FLAGS version: 9 updated: 2018/07/29 18:03:26
528 dnl ---------------
529 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
530 dnl into CC.  This will not help with broken scripts that wrap the compiler
531 dnl with options, but eliminates a more common category of user confusion.
532 dnl
533 dnl In particular, it addresses the problem of being able to run the C
534 dnl preprocessor in a consistent manner.
535 dnl
536 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
537 dnl the nuisance of having inconsistent settings for compiler and preprocessor
538 dnl outweighs that limitation.
539 AC_DEFUN([CF_CC_ENV_FLAGS],
540 [
541 # This should have been defined by AC_PROG_CC
542 : ${CC:=cc}
543
544 AC_MSG_CHECKING(\$CFLAGS variable)
545 case "x$CFLAGS" in
546 (*-[[IUD]]*)
547         AC_MSG_RESULT(broken)
548         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
549         cf_flags="$CFLAGS"
550         CFLAGS=
551         for cf_arg in $cf_flags
552         do
553                 CF_ADD_CFLAGS($cf_arg)
554         done
555         ;;
556 (*)
557         AC_MSG_RESULT(ok)
558         ;;
559 esac
560
561 AC_MSG_CHECKING(\$CC variable)
562 case "$CC" in
563 (*[[\ \ ]]-*)
564         AC_MSG_RESULT(broken)
565         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
566         # humor him...
567         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
568         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
569         CC="$cf_prog"
570         for cf_arg in $cf_flags
571         do
572                 case "x$cf_arg" in
573                 (x-[[IUDfgOW]]*)
574                         CF_ADD_CFLAGS($cf_arg)
575                         ;;
576                 (*)
577                         CC="$CC $cf_arg"
578                         ;;
579                 esac
580         done
581         CF_VERBOSE(resulting CC: '$CC')
582         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
583         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
584         ;;
585 (*)
586         AC_MSG_RESULT(ok)
587         ;;
588 esac
589 ])dnl
590 dnl ---------------------------------------------------------------------------
591 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
592 dnl ---------------
593 dnl Determine the default configuration into which we'll install ncurses.  This
594 dnl can be overridden by the user's command-line options.  There's two items to
595 dnl look for:
596 dnl     1. the prefix (e.g., /usr)
597 dnl     2. the header files (e.g., /usr/include/ncurses)
598 dnl We'll look for a previous installation of ncurses and use the same defaults.
599 dnl
600 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
601 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
602 dnl programs from a vendor's.
603 AC_DEFUN([CF_CFG_DEFAULTS],
604 [
605 AC_MSG_CHECKING(for prefix)
606 if test "x$prefix" = "xNONE" ; then
607         case "$cf_cv_system_name" in
608                 # non-vendor systems don't have a conflict
609         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
610                 prefix=/usr
611                 ;;
612         (*)     prefix=$ac_default_prefix
613                 ;;
614         esac
615 fi
616 AC_MSG_RESULT($prefix)
617
618 if test "x$prefix" = "xNONE" ; then
619 AC_MSG_CHECKING(for default include-directory)
620 test -n "$verbose" && echo 1>&AC_FD_MSG
621 for cf_symbol in \
622         $includedir \
623         $includedir/ncurses \
624         $prefix/include \
625         $prefix/include/ncurses \
626         /usr/local/include \
627         /usr/local/include/ncurses \
628         /usr/include \
629         /usr/include/ncurses
630 do
631         cf_dir=`eval echo $cf_symbol`
632         if test -f $cf_dir/curses.h ; then
633         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
634                 includedir="$cf_symbol"
635                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
636                 break
637         fi
638         fi
639         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
640 done
641 AC_MSG_RESULT($includedir)
642 fi
643 ])dnl
644 dnl ---------------------------------------------------------------------------
645 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
646 dnl --------------
647 dnl Check if we're accidentally using a cache from a different machine.
648 dnl Derive the system name, as a check for reusing the autoconf cache.
649 dnl
650 dnl If we've packaged config.guess and config.sub, run that (since it does a
651 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
652 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
653 dnl which is useful in cross-compiles.
654 dnl
655 dnl Note: we would use $ac_config_sub, but that is one of the places where
656 dnl autoconf 2.5x broke compatibility with autoconf 2.13
657 AC_DEFUN([CF_CHECK_CACHE],
658 [
659 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
660         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
661         system_name="$host_os"
662 else
663         system_name="`(uname -s -r) 2>/dev/null`"
664         if test -z "$system_name" ; then
665                 system_name="`(hostname) 2>/dev/null`"
666         fi
667 fi
668 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
669 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
670
671 test -z "$system_name" && system_name="$cf_cv_system_name"
672 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
673
674 if test ".$system_name" != ".$cf_cv_system_name" ; then
675         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
676         AC_MSG_ERROR("Please remove config.cache and try again.")
677 fi
678 ])dnl
679 dnl ---------------------------------------------------------------------------
680 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
681 dnl -----------------
682 dnl Check if the given compiler is really clang.  clang's C driver defines
683 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
684 dnl not ignore some gcc options.
685 dnl
686 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
687 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
688 dnl the wrappers for gcc and g++ warnings.
689 dnl
690 dnl $1 = GCC (default) or GXX
691 dnl $2 = CLANG_COMPILER (default)
692 dnl $3 = CFLAGS (default) or CXXFLAGS
693 AC_DEFUN([CF_CLANG_COMPILER],[
694 ifelse([$2],,CLANG_COMPILER,[$2])=no
695
696 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
697         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
698         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
699         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
700         AC_TRY_COMPILE([],[
701 #ifdef __clang__
702 #else
703 make an error
704 #endif
705 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
706 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
707 ],[])
708         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
709         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
710 fi
711 ])
712 dnl ---------------------------------------------------------------------------
713 dnl CF_CURSES_HEADER version: 5 updated: 2015/04/23 20:35:30
714 dnl ----------------
715 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
716 dnl variations of ncurses' installs.
717 dnl
718 dnl $1 = ncurses when looking for ncurses, or is empty
719 AC_DEFUN([CF_CURSES_HEADER],[
720 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
721 cf_cv_ncurses_header=none
722 for cf_header in \
723         ncurses.h ifelse($1,,,[$1/ncurses.h]) \
724         curses.h ifelse($1,,,[$1/curses.h]) ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
725 do
726 AC_TRY_COMPILE([#include <${cf_header}>],
727         [initscr(); tgoto("?", 0,0)],
728         [cf_cv_ncurses_header=$cf_header; break],[])
729 done
730 ])
731
732 if test "$cf_cv_ncurses_header" = none ; then
733         AC_MSG_ERROR(No curses header-files found)
734 fi
735
736 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
737 AC_CHECK_HEADERS($cf_cv_ncurses_header)
738 ])dnl
739 dnl ---------------------------------------------------------------------------
740 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
741 dnl ----------
742 dnl "dirname" is not portable, so we fake it with a shell script.
743 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
744 dnl ---------------------------------------------------------------------------
745 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
746 dnl ---------------
747 dnl You can always use "make -n" to see the actual options, but it's hard to
748 dnl pick out/analyze warning messages when the compile-line is long.
749 dnl
750 dnl Sets:
751 dnl     ECHO_LT - symbol to control if libtool is verbose
752 dnl     ECHO_LD - symbol to prefix "cc -o" lines
753 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
754 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
755 dnl     ECHO_CC - symbol to put before any "cc" line
756 dnl
757 AC_DEFUN([CF_DISABLE_ECHO],[
758 AC_MSG_CHECKING(if you want to see long compiling messages)
759 CF_ARG_DISABLE(echo,
760         [  --disable-echo          do not display "compiling" commands],
761         [
762         ECHO_LT='--silent'
763         ECHO_LD='@echo linking [$]@;'
764         RULE_CC='@echo compiling [$]<'
765         SHOW_CC='@echo compiling [$]@'
766         ECHO_CC='@'
767 ],[
768         ECHO_LT=''
769         ECHO_LD=''
770         RULE_CC=''
771         SHOW_CC=''
772         ECHO_CC=''
773 ])
774 AC_MSG_RESULT($enableval)
775 AC_SUBST(ECHO_LT)
776 AC_SUBST(ECHO_LD)
777 AC_SUBST(RULE_CC)
778 AC_SUBST(SHOW_CC)
779 AC_SUBST(ECHO_CC)
780 ])dnl
781 dnl ---------------------------------------------------------------------------
782 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
783 dnl ------------------------
784 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
785 AC_MSG_CHECKING(if we want to use GNAT projects)
786 CF_ARG_DISABLE(gnat-projects,
787         [  --disable-gnat-projects test: disable GNAT projects even if usable],
788         [enable_gnat_projects=no],
789         [enable_gnat_projects=yes])
790 AC_MSG_RESULT($enable_gnat_projects)
791 ])dnl
792 dnl ---------------------------------------------------------------------------
793 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
794 dnl ---------------
795 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
796 dnl prefer a standard location, and use -L options only if we do not find the
797 dnl library in the standard library location(s).
798 dnl     $1 = library name
799 dnl     $2 = library class, usually the same as library name
800 dnl     $3 = includes
801 dnl     $4 = code fragment to compile/link
802 dnl     $5 = corresponding function-name
803 dnl     $6 = flag, nonnull if failure should not cause an error-exit
804 dnl
805 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
806 dnl to use a -L option.
807 AC_DEFUN([CF_FIND_LIBRARY],
808 [
809         eval 'cf_cv_have_lib_'$1'=no'
810         cf_libdir=""
811         AC_CHECK_FUNC($5,
812                 eval 'cf_cv_have_lib_'$1'=yes',[
813                 cf_save_LIBS="$LIBS"
814                 AC_MSG_CHECKING(for $5 in -l$1)
815                 LIBS="-l$1 $LIBS"
816                 AC_TRY_LINK([$3],[$4],
817                         [AC_MSG_RESULT(yes)
818                          eval 'cf_cv_have_lib_'$1'=yes'
819                         ],
820                         [AC_MSG_RESULT(no)
821                         CF_LIBRARY_PATH(cf_search,$2)
822                         for cf_libdir in $cf_search
823                         do
824                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
825                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
826                                 AC_TRY_LINK([$3],[$4],
827                                         [AC_MSG_RESULT(yes)
828                                          eval 'cf_cv_have_lib_'$1'=yes'
829                                          break],
830                                         [AC_MSG_RESULT(no)
831                                          LIBS="$cf_save_LIBS"])
832                         done
833                         ])
834                 ])
835 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
836 ifelse($6,,[
837 if test $cf_found_library = no ; then
838         AC_MSG_ERROR(Cannot link $1 library)
839 fi
840 ])
841 ])dnl
842 dnl ---------------------------------------------------------------------------
843 dnl CF_FIND_LINKAGE version: 21 updated: 2018/06/20 20:23:13
844 dnl ---------------
845 dnl Find a library (specifically the linkage used in the code fragment),
846 dnl searching for it if it is not already in the library path.
847 dnl See also CF_ADD_SEARCHPATH.
848 dnl
849 dnl Parameters (4-on are optional):
850 dnl     $1 = headers for library entrypoint
851 dnl     $2 = code fragment for library entrypoint
852 dnl     $3 = the library name without the "-l" option or ".so" suffix.
853 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
854 dnl     $5 = action to perform if not successful
855 dnl     $6 = module name, if not the same as the library name
856 dnl     $7 = extra libraries
857 dnl
858 dnl Sets these variables:
859 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
860 dnl     $cf_cv_header_path_$3 - include-directory if needed
861 dnl     $cf_cv_library_path_$3 - library-directory if needed
862 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
863 AC_DEFUN([CF_FIND_LINKAGE],[
864
865 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
866 # will be set on completion of the AC_TRY_LINK below.
867 cf_cv_header_path_$3=
868 cf_cv_library_path_$3=
869
870 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
871
872 cf_save_LIBS="$LIBS"
873
874 AC_TRY_LINK([$1],[$2],[
875         cf_cv_find_linkage_$3=yes
876         cf_cv_header_path_$3=/usr/include
877         cf_cv_library_path_$3=/usr/lib
878 ],[
879
880 LIBS="-l$3 $7 $cf_save_LIBS"
881
882 AC_TRY_LINK([$1],[$2],[
883         cf_cv_find_linkage_$3=yes
884         cf_cv_header_path_$3=/usr/include
885         cf_cv_library_path_$3=/usr/lib
886         cf_cv_library_file_$3="-l$3"
887 ],[
888         cf_cv_find_linkage_$3=no
889         LIBS="$cf_save_LIBS"
890
891         CF_VERBOSE(find linkage for $3 library)
892         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
893
894         cf_save_CPPFLAGS="$CPPFLAGS"
895         cf_test_CPPFLAGS="$CPPFLAGS"
896
897         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
898         for cf_cv_header_path_$3 in $cf_search
899         do
900                 if test -d $cf_cv_header_path_$3 ; then
901                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
902                         CPPFLAGS="$cf_save_CPPFLAGS"
903                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
904                         AC_TRY_COMPILE([$1],[$2],[
905                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
906                                 cf_cv_find_linkage_$3=maybe
907                                 cf_test_CPPFLAGS="$CPPFLAGS"
908                                 break],[
909                                 CPPFLAGS="$cf_save_CPPFLAGS"
910                                 ])
911                 fi
912         done
913
914         if test "$cf_cv_find_linkage_$3" = maybe ; then
915
916                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
917
918                 cf_save_LIBS="$LIBS"
919                 cf_save_LDFLAGS="$LDFLAGS"
920
921                 ifelse([$6],,,[
922                 CPPFLAGS="$cf_test_CPPFLAGS"
923                 LIBS="-l$3 $7 $cf_save_LIBS"
924                 AC_TRY_LINK([$1],[$2],[
925                         CF_VERBOSE(... found $3 library in system)
926                         cf_cv_find_linkage_$3=yes])
927                         CPPFLAGS="$cf_save_CPPFLAGS"
928                         LIBS="$cf_save_LIBS"
929                         ])
930
931                 if test "$cf_cv_find_linkage_$3" != yes ; then
932                         CF_LIBRARY_PATH(cf_search,$3)
933                         for cf_cv_library_path_$3 in $cf_search
934                         do
935                                 if test -d $cf_cv_library_path_$3 ; then
936                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
937                                         CPPFLAGS="$cf_test_CPPFLAGS"
938                                         LIBS="-l$3 $7 $cf_save_LIBS"
939                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
940                                         AC_TRY_LINK([$1],[$2],[
941                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
942                                         cf_cv_find_linkage_$3=yes
943                                         cf_cv_library_file_$3="-l$3"
944                                         break],[
945                                         CPPFLAGS="$cf_save_CPPFLAGS"
946                                         LIBS="$cf_save_LIBS"
947                                         LDFLAGS="$cf_save_LDFLAGS"
948                                         ])
949                                 fi
950                         done
951                         CPPFLAGS="$cf_save_CPPFLAGS"
952                         LDFLAGS="$cf_save_LDFLAGS"
953                 fi
954
955         else
956                 cf_cv_find_linkage_$3=no
957         fi
958         ],$7)
959 ])
960
961 LIBS="$cf_save_LIBS"
962
963 if test "$cf_cv_find_linkage_$3" = yes ; then
964 ifelse([$4],,[
965         CF_ADD_INCDIR($cf_cv_header_path_$3)
966         CF_ADD_LIBDIR($cf_cv_library_path_$3)
967         CF_ADD_LIB($3)
968 ],[$4])
969 else
970 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
971 fi
972 ])dnl
973 dnl ---------------------------------------------------------------------------
974 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
975 dnl -----------------
976 dnl make ADAFLAGS consistent with CFLAGS
977 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
978         AC_MSG_CHECKING(optimization options for ADAFLAGS)
979         case "$CFLAGS" in
980         (*-g*)
981                 CF_ADD_ADAFLAGS(-g)
982                 ;;
983         esac
984         case "$CFLAGS" in
985         (*-O*)
986                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
987                 CF_ADD_ADAFLAGS($cf_O_flag)
988                 ;;
989         esac
990         AC_MSG_RESULT($ADAFLAGS)
991 ])dnl
992 dnl ---------------------------------------------------------------------------
993 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
994 dnl -----------------
995 dnl Test for availability of useful gcc __attribute__ directives to quiet
996 dnl compiler warnings.  Though useful, not all are supported -- and contrary
997 dnl to documentation, unrecognized directives cause older compilers to barf.
998 AC_DEFUN([CF_GCC_ATTRIBUTES],
999 [
1000 if test "$GCC" = yes
1001 then
1002 cat > conftest.i <<EOF
1003 #ifndef GCC_PRINTF
1004 #define GCC_PRINTF 0
1005 #endif
1006 #ifndef GCC_SCANF
1007 #define GCC_SCANF 0
1008 #endif
1009 #ifndef GCC_NORETURN
1010 #define GCC_NORETURN /* nothing */
1011 #endif
1012 #ifndef GCC_UNUSED
1013 #define GCC_UNUSED /* nothing */
1014 #endif
1015 EOF
1016 if test "$GCC" = yes
1017 then
1018         AC_CHECKING([for $CC __attribute__ directives])
1019 cat > conftest.$ac_ext <<EOF
1020 #line __oline__ "${as_me:-configure}"
1021 #include "confdefs.h"
1022 #include "conftest.h"
1023 #include "conftest.i"
1024 #if     GCC_PRINTF
1025 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1026 #else
1027 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1028 #endif
1029 #if     GCC_SCANF
1030 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1031 #else
1032 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1033 #endif
1034 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1035 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1036 extern void foo(void) GCC_NORETURN;
1037 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1038 EOF
1039         cf_printf_attribute=no
1040         cf_scanf_attribute=no
1041         for cf_attribute in scanf printf unused noreturn
1042         do
1043                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1044                 cf_directive="__attribute__(($cf_attribute))"
1045                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1046
1047                 case $cf_attribute in
1048                 (printf)
1049                         cf_printf_attribute=yes
1050                         cat >conftest.h <<EOF
1051 #define GCC_$cf_ATTRIBUTE 1
1052 EOF
1053                         ;;
1054                 (scanf)
1055                         cf_scanf_attribute=yes
1056                         cat >conftest.h <<EOF
1057 #define GCC_$cf_ATTRIBUTE 1
1058 EOF
1059                         ;;
1060                 (*)
1061                         cat >conftest.h <<EOF
1062 #define GCC_$cf_ATTRIBUTE $cf_directive
1063 EOF
1064                         ;;
1065                 esac
1066
1067                 if AC_TRY_EVAL(ac_compile); then
1068                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1069                         cat conftest.h >>confdefs.h
1070                         case $cf_attribute in
1071                         (noreturn)
1072                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1073                                 ;;
1074                         (printf)
1075                                 cf_value='/* nothing */'
1076                                 if test "$cf_printf_attribute" != no ; then
1077                                         cf_value='__attribute__((format(printf,fmt,var)))'
1078                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1079                                 fi
1080                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1081                                 ;;
1082                         (scanf)
1083                                 cf_value='/* nothing */'
1084                                 if test "$cf_scanf_attribute" != no ; then
1085                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1086                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1087                                 fi
1088                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1089                                 ;;
1090                         (unused)
1091                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1092                                 ;;
1093                         esac
1094                 fi
1095         done
1096 else
1097         fgrep define conftest.i >>confdefs.h
1098 fi
1099 rm -rf conftest*
1100 fi
1101 ])dnl
1102 dnl ---------------------------------------------------------------------------
1103 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
1104 dnl --------------
1105 dnl Find version of gcc
1106 AC_DEFUN([CF_GCC_VERSION],[
1107 AC_REQUIRE([AC_PROG_CC])
1108 GCC_VERSION=none
1109 if test "$GCC" = yes ; then
1110         AC_MSG_CHECKING(version of $CC)
1111         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1112         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1113         AC_MSG_RESULT($GCC_VERSION)
1114 fi
1115 ])dnl
1116 dnl ---------------------------------------------------------------------------
1117 dnl CF_GCC_WARNINGS version: 33 updated: 2018/06/20 20:23:13
1118 dnl ---------------
1119 dnl Check if the compiler supports useful warning options.  There's a few that
1120 dnl we don't use, simply because they're too noisy:
1121 dnl
1122 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1123 dnl     -Wredundant-decls (system headers make this too noisy)
1124 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1125 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1126 dnl             is enabled for ncurses using "--enable-const".
1127 dnl     -pedantic
1128 dnl
1129 dnl Parameter:
1130 dnl     $1 is an optional list of gcc warning flags that a particular
1131 dnl             application might want to use, e.g., "no-unused" for
1132 dnl             -Wno-unused
1133 dnl Special:
1134 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1135 dnl
1136 AC_DEFUN([CF_GCC_WARNINGS],
1137 [
1138 AC_REQUIRE([CF_GCC_VERSION])
1139 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1140 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1141
1142 cat > conftest.$ac_ext <<EOF
1143 #line __oline__ "${as_me:-configure}"
1144 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1145 EOF
1146
1147 if test "$INTEL_COMPILER" = yes
1148 then
1149 # The "-wdXXX" options suppress warnings:
1150 # remark #1419: external declaration in primary source file
1151 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1152 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1153 # remark #193: zero used for undefined preprocessing identifier
1154 # remark #593: variable "curs_sb_left_arrow" was set but never used
1155 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1156 # remark #869: parameter "tw" was never referenced
1157 # remark #981: operands are evaluated in unspecified order
1158 # warning #279: controlling expression is constant
1159
1160         AC_CHECKING([for $CC warning options])
1161         cf_save_CFLAGS="$CFLAGS"
1162         EXTRA_CFLAGS="-Wall"
1163         for cf_opt in \
1164                 wd1419 \
1165                 wd1683 \
1166                 wd1684 \
1167                 wd193 \
1168                 wd593 \
1169                 wd279 \
1170                 wd810 \
1171                 wd869 \
1172                 wd981
1173         do
1174                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1175                 if AC_TRY_EVAL(ac_compile); then
1176                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1177                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1178                 fi
1179         done
1180         CFLAGS="$cf_save_CFLAGS"
1181
1182 elif test "$GCC" = yes
1183 then
1184         AC_CHECKING([for $CC warning options])
1185         cf_save_CFLAGS="$CFLAGS"
1186         EXTRA_CFLAGS=
1187         cf_warn_CONST=""
1188         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1189         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
1190         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
1191         for cf_opt in W Wall \
1192                 Wbad-function-cast \
1193                 Wcast-align \
1194                 Wcast-qual \
1195                 Wdeclaration-after-statement \
1196                 Wextra \
1197                 Winline \
1198                 Wmissing-declarations \
1199                 Wmissing-prototypes \
1200                 Wnested-externs \
1201                 Wpointer-arith \
1202                 Wshadow \
1203                 Wstrict-prototypes \
1204                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
1205         do
1206                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1207                 if AC_TRY_EVAL(ac_compile); then
1208                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1209                         case $cf_opt in
1210                         (Wcast-qual)
1211                                 CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
1212                                 ;;
1213                         (Winline)
1214                                 case $GCC_VERSION in
1215                                 ([[34]].*)
1216                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1217                                         continue;;
1218                                 esac
1219                                 ;;
1220                         (Wpointer-arith)
1221                                 case $GCC_VERSION in
1222                                 ([[12]].*)
1223                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1224                                         continue;;
1225                                 esac
1226                                 ;;
1227                         esac
1228                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1229                 fi
1230         done
1231         CFLAGS="$cf_save_CFLAGS"
1232 fi
1233 rm -rf conftest*
1234
1235 AC_SUBST(EXTRA_CFLAGS)
1236 ])dnl
1237 dnl ---------------------------------------------------------------------------
1238 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
1239 dnl -----------------
1240 AC_DEFUN([CF_GNATPREP_OPT_T],[
1241 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
1242 cf_cv_gnatprep_opt_t=no
1243 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
1244 ])
1245 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
1246 AC_SUBST(GNATPREP_OPTS)
1247 ])dnl
1248 dnl ---------------------------------------------------------------------------
1249 dnl CF_GNAT_GENERICS version: 3 updated: 2015/04/17 21:13:04
1250 dnl ----------------
1251 AC_DEFUN([CF_GNAT_GENERICS],
1252 [
1253 AC_REQUIRE([CF_GNAT_VERSION])
1254
1255 AC_MSG_CHECKING(if GNAT supports generics)
1256 case $cf_gnat_version in
1257 (3.[[1-9]]*|[[4-9]].*)
1258         cf_gnat_generics=yes
1259         ;;
1260 (*)
1261         cf_gnat_generics=no
1262         ;;
1263 esac
1264 AC_MSG_RESULT($cf_gnat_generics)
1265
1266 if test "$cf_gnat_generics" = yes
1267 then
1268         cf_compile_generics=generics
1269         cf_generic_objects="\${GENOBJS}"
1270 else
1271         cf_compile_generics=
1272         cf_generic_objects=
1273 fi
1274
1275 AC_SUBST(cf_compile_generics)
1276 AC_SUBST(cf_generic_objects)
1277 ])dnl
1278 dnl ---------------------------------------------------------------------------
1279 dnl CF_GNAT_PROJECTS version: 9 updated: 2018/01/14 15:46:09
1280 dnl ----------------
1281 dnl GNAT projects are configured with ".gpr" project files.
1282 dnl GNAT libraries are a further development, using the project feature.
1283 AC_DEFUN([CF_GNAT_PROJECTS],
1284 [
1285 AC_REQUIRE([CF_GNAT_VERSION])
1286 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
1287
1288 cf_gnat_libraries=no
1289 cf_gnat_projects=no
1290
1291 if test "$enable_gnat_projects" != no ; then
1292 AC_MSG_CHECKING(if GNAT supports project files)
1293 case $cf_gnat_version in
1294 (3.[[0-9]]*)
1295         ;;
1296 (*)
1297         case $cf_cv_system_name in
1298         (cygwin*|msys*)
1299                 ;;
1300         (*)
1301                 rm -rf conftest* *~conftest*
1302                 if mkdir conftest.src conftest.bin conftest.lib
1303                 then
1304                         cd conftest.src
1305                         rm -rf conftest* *~conftest*
1306                         cat >>library.gpr <<CF_EOF
1307 project Library is
1308   Kind := External ("LIB_KIND");
1309   for Library_Name use "ConfTest";
1310   for Object_Dir use ".";
1311   for Library_ALI_Dir use External("LIBRARY_DIR");
1312   for Library_Version use External ("SONAME");
1313   for Library_Kind use Kind;
1314   for Library_Dir use External("BUILD_DIR");
1315   Source_Dir := External ("SOURCE_DIR");
1316   for Source_Dirs use (Source_Dir);
1317 end Library;
1318 CF_EOF
1319                         cat >>confpackage.ads <<CF_EOF
1320 package ConfPackage is
1321    procedure conftest;
1322 end ConfPackage;
1323 CF_EOF
1324                         cat >>confpackage.adb <<CF_EOF
1325 with Text_IO;
1326 package body ConfPackage is
1327    procedure conftest is
1328    begin
1329       Text_IO.Put ("Hello World");
1330       Text_IO.New_Line;
1331    end conftest;
1332 end ConfPackage;
1333 CF_EOF
1334                         if ( $cf_ada_make $ADAFLAGS \
1335                                         -Plibrary.gpr \
1336                                         -XBUILD_DIR=`cd ../conftest.bin;pwd` \
1337                                         -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
1338                                         -XSOURCE_DIR=`pwd` \
1339                                         -XSONAME=libConfTest.so.1 \
1340                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
1341                                 cf_gnat_projects=yes
1342                         fi
1343                         cd ..
1344                 fi
1345                 if test -f conftest.lib/confpackage.ali
1346                 then
1347                         cf_gnat_libraries=yes
1348                 fi
1349                 rm -rf conftest* *~conftest*
1350                 ;;
1351         esac
1352         ;;
1353 esac
1354 AC_MSG_RESULT($cf_gnat_projects)
1355 fi # enable_gnat_projects
1356
1357 if test $cf_gnat_projects = yes
1358 then
1359         AC_MSG_CHECKING(if GNAT supports libraries)
1360         AC_MSG_RESULT($cf_gnat_libraries)
1361 fi
1362
1363 if test "$cf_gnat_projects" = yes
1364 then
1365         USE_OLD_MAKERULES="#"
1366         USE_GNAT_PROJECTS=""
1367 else
1368         USE_OLD_MAKERULES=""
1369         USE_GNAT_PROJECTS="#"
1370 fi
1371
1372 if test "$cf_gnat_libraries" = yes
1373 then
1374         USE_GNAT_LIBRARIES=""
1375 else
1376         USE_GNAT_LIBRARIES="#"
1377 fi
1378
1379 AC_SUBST(USE_OLD_MAKERULES)
1380 AC_SUBST(USE_GNAT_PROJECTS)
1381 AC_SUBST(USE_GNAT_LIBRARIES)
1382 ])dnl
1383 dnl ---------------------------------------------------------------------------
1384 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
1385 dnl --------------
1386 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
1387 dnl is noted that gnat may compile a tasking unit even for configurations which
1388 dnl fail at runtime.
1389 AC_DEFUN([CF_GNAT_SIGINT],[
1390 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
1391 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
1392
1393 package ConfTest is
1394
1395    pragma Warnings (Off);  --  the next pragma exists since 3.11p
1396    pragma Unreserve_All_Interrupts;
1397    pragma Warnings (On);
1398
1399    protected Process is
1400       procedure Stop;
1401       function Continue return Boolean;
1402       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
1403    private
1404       Done : Boolean := False;
1405    end Process;
1406
1407 end ConfTest;],
1408 [package body ConfTest is
1409    protected body Process is
1410       procedure Stop is
1411       begin
1412          Done := True;
1413       end Stop;
1414       function Continue return Boolean is
1415       begin
1416          return not Done;
1417       end Continue;
1418    end Process;
1419 end ConfTest;],
1420         [cf_cv_gnat_sigint=yes],
1421         [cf_cv_gnat_sigint=no])])
1422
1423 if test $cf_cv_gnat_sigint = yes ; then
1424         USE_GNAT_SIGINT=""
1425 else
1426         USE_GNAT_SIGINT="#"
1427 fi
1428 AC_SUBST(USE_GNAT_SIGINT)
1429 ])dnl
1430 dnl ---------------------------------------------------------------------------
1431 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
1432 dnl ----------------
1433 dnl Verify that a test program compiles/links with GNAT.
1434 dnl $cf_ada_make is set to the program that compiles/links
1435 dnl $ADAFLAGS may be set to the GNAT flags.
1436 dnl
1437 dnl $1 is the text of the spec
1438 dnl $2 is the text of the body
1439 dnl $3 is the shell command to execute if successful
1440 dnl $4 is the shell command to execute if not successful
1441 AC_DEFUN([CF_GNAT_TRY_LINK],
1442 [
1443 rm -rf conftest* *~conftest*
1444 cat >>conftest.ads <<CF_EOF
1445 $1
1446 CF_EOF
1447 cat >>conftest.adb <<CF_EOF
1448 $2
1449 CF_EOF
1450 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1451 ifelse($3,,      :,[      $3])
1452 ifelse($4,,,[else
1453    $4])
1454 fi
1455 rm -rf conftest* *~conftest*
1456 ])dnl
1457 dnl ---------------------------------------------------------------------------
1458 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
1459 dnl ---------------
1460 dnl Verify that a test program compiles and runs with GNAT
1461 dnl $cf_ada_make is set to the program that compiles/links
1462 dnl $ADAFLAGS may be set to the GNAT flags.
1463 dnl
1464 dnl $1 is the text of the spec
1465 dnl $2 is the text of the body
1466 dnl $3 is the shell command to execute if successful
1467 dnl $4 is the shell command to execute if not successful
1468 AC_DEFUN([CF_GNAT_TRY_RUN],
1469 [
1470 rm -rf conftest* *~conftest*
1471 cat >>conftest.ads <<CF_EOF
1472 $1
1473 CF_EOF
1474 cat >>conftest.adb <<CF_EOF
1475 $2
1476 CF_EOF
1477 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1478    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
1479 ifelse($3,,      :,[      $3])
1480 ifelse($4,,,[   else
1481       $4])
1482    fi
1483 ifelse($4,,,[else
1484    $4])
1485 fi
1486 rm -rf conftest* *~conftest*
1487 ])dnl
1488 dnl ---------------------------------------------------------------------------
1489 dnl CF_GNAT_VERSION version: 20 updated: 2015/04/18 08:56:57
1490 dnl ---------------
1491 dnl Verify version of GNAT.
1492 AC_DEFUN([CF_GNAT_VERSION],
1493 [
1494 AC_MSG_CHECKING(for gnat version)
1495 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
1496         grep '[[0-9]].[[0-9]][[0-9]]*' |\
1497         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
1498 AC_MSG_RESULT($cf_gnat_version)
1499
1500 case $cf_gnat_version in
1501 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
1502         cf_cv_prog_gnat_correct=yes
1503         ;;
1504 (*)
1505         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1506         cf_cv_prog_gnat_correct=no
1507         ;;
1508 esac
1509 ])
1510 dnl ---------------------------------------------------------------------------
1511 dnl CF_GNU_SOURCE version: 9 updated: 2018/06/20 20:23:13
1512 dnl -------------
1513 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1514 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1515 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1516 dnl since it is interwoven with GNU extensions.
1517 dnl
1518 dnl Well, yes we could work around it...
1519 dnl
1520 dnl Parameters:
1521 dnl     $1 is the nominal value for _XOPEN_SOURCE
1522 AC_DEFUN([CF_GNU_SOURCE],
1523 [
1524 cf_gnu_xopen_source=ifelse($1,,500,$1)
1525
1526 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
1527 AC_TRY_COMPILE([#include <sys/types.h>],[
1528         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
1529                 return 0;
1530         #else
1531         #       error not GNU C library
1532         #endif],
1533         [cf_cv_gnu_library=yes],
1534         [cf_cv_gnu_library=no])
1535 ])
1536
1537 if test x$cf_cv_gnu_library = xyes; then
1538
1539         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
1540         # was changed to help a little...
1541         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
1542                 cf_save="$CPPFLAGS"
1543                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
1544                 AC_TRY_COMPILE([#include <sys/types.h>],[
1545                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
1546                                 return 0;
1547                         #else
1548                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
1549                         #endif],
1550                         [cf_cv_gnu_library_219=yes],
1551                         [cf_cv_gnu_library_219=no])
1552                 CPPFLAGS="$cf_save"
1553         ])
1554
1555         if test "x$cf_cv_gnu_library_219" = xyes; then
1556                 cf_save="$CPPFLAGS"
1557                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
1558                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
1559                         AC_TRY_COMPILE([
1560                                 #include <limits.h>
1561                                 #include <sys/types.h>
1562                                 ],[
1563                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
1564                                         return 0;
1565                                 #else
1566                                 #       error GNU C library is too old
1567                                 #endif],
1568                                 [cf_cv_gnu_dftsrc_219=yes],
1569                                 [cf_cv_gnu_dftsrc_219=no])
1570                         ])
1571                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
1572         else
1573                 cf_cv_gnu_dftsrc_219=maybe
1574         fi
1575
1576         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
1577
1578                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1579                 AC_TRY_COMPILE([#include <sys/types.h>],[
1580                         #ifndef _XOPEN_SOURCE
1581                         #error  expected _XOPEN_SOURCE to be defined
1582                         #endif],
1583                         [cf_cv_gnu_source=no],
1584                         [cf_save="$CPPFLAGS"
1585                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
1586                          AC_TRY_COMPILE([#include <sys/types.h>],[
1587                                 #ifdef _XOPEN_SOURCE
1588                                 #error  expected _XOPEN_SOURCE to be undefined
1589                                 #endif],
1590                                 [cf_cv_gnu_source=no],
1591                                 [cf_cv_gnu_source=yes])
1592                         CPPFLAGS="$cf_save"
1593                         ])
1594                 ])
1595
1596                 if test "$cf_cv_gnu_source" = yes
1597                 then
1598                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
1599                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
1600                         AC_TRY_COMPILE([#include <sys/types.h>],[
1601                                 #ifdef _DEFAULT_SOURCE
1602                                 #error  expected _DEFAULT_SOURCE to be undefined
1603                                 #endif],
1604                                 [cf_cv_default_source=no],
1605                                 [cf_cv_default_source=yes])
1606                         ])
1607                         if test "$cf_cv_default_source" = yes
1608                         then
1609                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
1610                         fi
1611                 fi
1612         fi
1613
1614 fi
1615 ])dnl
1616 dnl ---------------------------------------------------------------------------
1617 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
1618 dnl --------------
1619 dnl Construct a search-list of directories for a nonstandard header-file
1620 dnl
1621 dnl Parameters
1622 dnl     $1 = the variable to return as result
1623 dnl     $2 = the package name
1624 AC_DEFUN([CF_HEADER_PATH],
1625 [
1626 $1=
1627
1628 # collect the current set of include-directories from compiler flags
1629 cf_header_path_list=""
1630 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1631         for cf_header_path in $CPPFLAGS $CFLAGS
1632         do
1633                 case $cf_header_path in
1634                 (-I*)
1635                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1636                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1637                         cf_header_path_list="$cf_header_path_list [$]$1"
1638                         ;;
1639                 esac
1640         done
1641 fi
1642
1643 # add the variations for the package we are looking for
1644 CF_SUBDIR_PATH($1,$2,include)
1645
1646 test "$includedir" != NONE && \
1647 test "$includedir" != "/usr/include" && \
1648 test -d "$includedir" && {
1649         test -d $includedir &&    $1="[$]$1 $includedir"
1650         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
1651 }
1652
1653 test "$oldincludedir" != NONE && \
1654 test "$oldincludedir" != "/usr/include" && \
1655 test -d "$oldincludedir" && {
1656         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
1657         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
1658 }
1659
1660 $1="[$]$1 $cf_header_path_list"
1661 ])dnl
1662 dnl ---------------------------------------------------------------------------
1663 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
1664 dnl ---------------
1665 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
1666 AC_DEFUN([CF_HELP_MESSAGE],
1667 [AC_DIVERT_HELP([$1])dnl
1668 ])dnl
1669 dnl ---------------------------------------------------------------------------
1670 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
1671 dnl ---------------
1672 dnl Construct the list of include-options according to whether we're building
1673 dnl in the source directory or using '--srcdir=DIR' option.
1674 AC_DEFUN([CF_INCLUDE_DIRS],
1675 [
1676 if test "$srcdir" != "."; then
1677         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
1678 fi
1679 CPPFLAGS="-I../include $CPPFLAGS"
1680 if test "$srcdir" != "."; then
1681         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
1682 fi
1683 CPPFLAGS="-I. $CPPFLAGS"
1684 AC_SUBST(CPPFLAGS)
1685 ])dnl
1686 dnl ---------------------------------------------------------------------------
1687 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
1688 dnl ---------------
1689 dnl prompt for/fill-in useful install-program options
1690 AC_DEFUN([CF_INSTALL_OPTS],
1691 [
1692 CF_INSTALL_OPT_S
1693 CF_INSTALL_OPT_P
1694 CF_INSTALL_OPT_O
1695 ])dnl
1696 dnl ---------------------------------------------------------------------------
1697 dnl CF_INSTALL_OPT_O version: 2 updated: 2015/05/15 19:45:35
1698 dnl ----------------
1699 dnl Almost all "install" programs default to the current user's ownership.
1700 dnl Almost - MINIX is an exception.
1701 AC_DEFUN([CF_INSTALL_OPT_O],
1702 [
1703 AC_MSG_CHECKING(if install needs to be told about ownership)
1704 case `$ac_config_guess` in
1705 (*minix)
1706         with_install_o=yes
1707         ;;
1708 (*)
1709         with_install_o=no
1710         ;;
1711 esac
1712
1713 AC_MSG_RESULT($with_install_o)
1714 if test "x$with_install_o" = xyes
1715 then
1716         INSTALL_OPT_O=`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`
1717 else
1718         INSTALL_OPT_O=
1719 fi
1720
1721 AC_SUBST(INSTALL_OPT_O)
1722 ])dnl
1723 dnl ---------------------------------------------------------------------------
1724 dnl CF_INSTALL_OPT_P version: 1 updated: 2018/08/18 12:19:21
1725 dnl ----------------
1726 dnl Some install-programs accept a "-p" option to preserve file modification
1727 dnl timestamps.  That can be useful as an install option, as well as a way to
1728 dnl avoid the need for ranlib after copying a static archive.
1729 AC_DEFUN([CF_INSTALL_OPT_P],
1730 [
1731 : ${INSTALL:=install}
1732 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
1733         rm -rf conftest*
1734         date >conftest.in
1735         mkdir conftest.out
1736         sleep 3
1737         if $INSTALL -p conftest.in conftest.out 2>/dev/null
1738         then
1739                 if test -f conftest.out/conftest.in
1740                 then
1741                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
1742                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
1743                         if test -s conftest.err
1744                         then
1745                                 cf_cv_install_p=no
1746                         else
1747                                 cf_cv_install_p=yes
1748                         fi
1749                 else
1750                         cf_cv_install_p=no
1751                 fi
1752         else
1753                 cf_cv_install_p=no
1754         fi
1755         rm -rf conftest*
1756 ])
1757 ])dnl
1758 dnl ---------------------------------------------------------------------------
1759 dnl CF_INSTALL_OPT_S version: 2 updated: 2018/08/18 12:19:21
1760 dnl ----------------
1761 dnl By default, we should strip executables which are installed, but leave the
1762 dnl ability to suppress that for unit-testing.
1763 AC_DEFUN([CF_INSTALL_OPT_S],
1764 [
1765 AC_MSG_CHECKING(if you want to install stripped executables)
1766 CF_ARG_DISABLE(stripping,
1767         [  --disable-stripping     do not strip (debug info) installed executables],
1768         [with_stripping=no],
1769         [with_stripping=yes])
1770 AC_MSG_RESULT($with_stripping)
1771
1772 if test "$with_stripping" = yes
1773 then
1774         INSTALL_OPT_S="-s"
1775 else
1776         INSTALL_OPT_S=
1777 fi
1778 AC_SUBST(INSTALL_OPT_S)
1779 ])dnl
1780 dnl ---------------------------------------------------------------------------
1781 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
1782 dnl -----------------
1783 dnl Check if the given compiler is really the Intel compiler for Linux.  It
1784 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
1785 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
1786 dnl
1787 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1788 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1789 dnl the wrappers for gcc and g++ warnings.
1790 dnl
1791 dnl $1 = GCC (default) or GXX
1792 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
1793 dnl $3 = CFLAGS (default) or CXXFLAGS
1794 AC_DEFUN([CF_INTEL_COMPILER],[
1795 AC_REQUIRE([AC_CANONICAL_HOST])
1796 ifelse([$2],,INTEL_COMPILER,[$2])=no
1797
1798 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1799         case $host_os in
1800         (linux*|gnu*)
1801                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
1802                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1803                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
1804                 AC_TRY_COMPILE([],[
1805 #ifdef __INTEL_COMPILER
1806 #else
1807 make an error
1808 #endif
1809 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
1810 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
1811 ],[])
1812                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1813                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
1814                 ;;
1815         esac
1816 fi
1817 ])dnl
1818 dnl ---------------------------------------------------------------------------
1819 dnl CF_LARGEFILE version: 11 updated: 2018/06/20 20:23:13
1820 dnl ------------
1821 dnl Add checks for large file support.
1822 AC_DEFUN([CF_LARGEFILE],[
1823 ifdef([AC_FUNC_FSEEKO],[
1824         AC_SYS_LARGEFILE
1825         if test "$enable_largefile" != no ; then
1826         AC_FUNC_FSEEKO
1827
1828         # Normally we would collect these definitions in the config.h,
1829         # but (like _XOPEN_SOURCE), some environments rely on having these
1830         # defined before any of the system headers are included.  Another
1831         # case comes up with C++, e.g., on AIX the compiler compiles the
1832         # header files by themselves before looking at the body files it is
1833         # told to compile.  For ncurses, those header files do not include
1834         # the config.h
1835         if test "$ac_cv_sys_large_files" != no
1836         then
1837                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
1838         fi
1839         if test "$ac_cv_sys_largefile_source" != no
1840         then
1841                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
1842         fi
1843         if test "$ac_cv_sys_file_offset_bits" != no
1844         then
1845                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
1846         fi
1847
1848         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
1849                 AC_TRY_COMPILE([
1850 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
1851 #include <sys/types.h>
1852 #include <dirent.h>
1853                 ],[
1854                 /* if transitional largefile support is setup, this is true */
1855                 extern struct dirent64 * readdir(DIR *);
1856                 struct dirent64 *x = readdir((DIR *)0);
1857                 struct dirent *y = readdir((DIR *)0);
1858                 int z = x - y;
1859                 ],
1860                 [cf_cv_struct_dirent64=yes],
1861                 [cf_cv_struct_dirent64=no])
1862         ])
1863         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
1864         fi
1865 ])
1866 ])
1867 dnl ---------------------------------------------------------------------------
1868 dnl CF_LD_RPATH_OPT version: 8 updated: 2018/08/18 16:36:35
1869 dnl ---------------
1870 dnl For the given system and compiler, find the compiler flags to pass to the
1871 dnl loader to use the "rpath" feature.
1872 AC_DEFUN([CF_LD_RPATH_OPT],
1873 [
1874 AC_REQUIRE([CF_CHECK_CACHE])
1875
1876 LD_RPATH_OPT=
1877 if test "x$cf_cv_enable_rpath" != xno
1878 then
1879         AC_MSG_CHECKING(for an rpath option)
1880         case $cf_cv_system_name in
1881         (irix*)
1882                 if test "$GCC" = yes; then
1883                         LD_RPATH_OPT="-Wl,-rpath,"
1884                 else
1885                         LD_RPATH_OPT="-rpath "
1886                 fi
1887                 ;;
1888         (linux*|gnu*|k*bsd*-gnu|freebsd*)
1889                 LD_RPATH_OPT="-Wl,-rpath,"
1890                 ;;
1891         (openbsd[[2-9]].*|mirbsd*)
1892                 LD_RPATH_OPT="-Wl,-rpath,"
1893                 ;;
1894         (dragonfly*)
1895                 LD_RPATH_OPT="-rpath "
1896                 ;;
1897         (netbsd*)
1898                 LD_RPATH_OPT="-Wl,-rpath,"
1899                 ;;
1900         (osf*|mls+*)
1901                 LD_RPATH_OPT="-rpath "
1902                 ;;
1903         (solaris2*)
1904                 LD_RPATH_OPT="-R"
1905                 ;;
1906         (*)
1907                 ;;
1908         esac
1909         AC_MSG_RESULT($LD_RPATH_OPT)
1910
1911         case "x$LD_RPATH_OPT" in
1912         (x-R*)
1913                 AC_MSG_CHECKING(if we need a space after rpath option)
1914                 cf_save_LIBS="$LIBS"
1915                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
1916                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
1917                 LIBS="$cf_save_LIBS"
1918                 AC_MSG_RESULT($cf_rpath_space)
1919                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
1920                 ;;
1921         esac
1922 fi
1923 ])dnl
1924 dnl ---------------------------------------------------------------------------
1925 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
1926 dnl ---------------
1927 dnl Construct a search-list of directories for a nonstandard library-file
1928 dnl
1929 dnl Parameters
1930 dnl     $1 = the variable to return as result
1931 dnl     $2 = the package name
1932 AC_DEFUN([CF_LIBRARY_PATH],
1933 [
1934 $1=
1935 cf_library_path_list=""
1936 if test -n "${LDFLAGS}${LIBS}" ; then
1937         for cf_library_path in $LDFLAGS $LIBS
1938         do
1939                 case $cf_library_path in
1940                 (-L*)
1941                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
1942                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
1943                         cf_library_path_list="$cf_library_path_list [$]$1"
1944                         ;;
1945                 esac
1946         done
1947 fi
1948
1949 CF_SUBDIR_PATH($1,$2,lib)
1950
1951 $1="$cf_library_path_list [$]$1"
1952 ])dnl
1953 dnl ---------------------------------------------------------------------------
1954 dnl CF_LIB_PREFIX version: 12 updated: 2015/10/17 19:03:33
1955 dnl -------------
1956 dnl Compute the library-prefix for the given host system
1957 dnl $1 = variable to set
1958 define([CF_LIB_PREFIX],
1959 [
1960         case $cf_cv_system_name in
1961         (OS/2*|os2*)
1962                 if test "$DFT_LWR_MODEL" = libtool; then
1963                         LIB_PREFIX='lib'
1964                 else
1965                         LIB_PREFIX=''
1966                 fi
1967                 ;;
1968         (*)     LIB_PREFIX='lib'
1969                 ;;
1970         esac
1971 ifelse($1,,,[$1=$LIB_PREFIX])
1972         AC_SUBST(LIB_PREFIX)
1973 ])dnl
1974 dnl ---------------------------------------------------------------------------
1975 dnl CF_LIB_SUFFIX version: 25 updated: 2015/04/17 21:13:04
1976 dnl -------------
1977 dnl Compute the library file-suffix from the given model name
1978 dnl $1 = model name
1979 dnl $2 = variable to set (the nominal library suffix)
1980 dnl $3 = dependency variable to set (actual filename)
1981 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1982 AC_DEFUN([CF_LIB_SUFFIX],
1983 [
1984         case X$1 in
1985         (Xlibtool)
1986                 $2='.la'
1987                 $3=[$]$2
1988                 ;;
1989         (Xdebug)
1990                 $2='_g.a'
1991                 $3=[$]$2
1992                 ;;
1993         (Xprofile)
1994                 $2='_p.a'
1995                 $3=[$]$2
1996                 ;;
1997         (Xshared)
1998                 case $cf_cv_system_name in
1999                 (aix[[5-7]]*)
2000                         $2='.so'
2001                         $3=[$]$2
2002                         ;;
2003                 (cygwin*|msys*|mingw*)
2004                         $2='.dll'
2005                         $3='.dll.a'
2006                         ;;
2007                 (darwin*)
2008                         $2='.dylib'
2009                         $3=[$]$2
2010                         ;;
2011                 (hpux*)
2012                         case $target in
2013                         (ia64*)
2014                                 $2='.so'
2015                                 $3=[$]$2
2016                                 ;;
2017                         (*)
2018                                 $2='.sl'
2019                                 $3=[$]$2
2020                                 ;;
2021                         esac
2022                         ;;
2023                 (*)
2024                         $2='.so'
2025                         $3=[$]$2
2026                         ;;
2027                 esac
2028                 ;;
2029         (*)
2030                 $2='.a'
2031                 $3=[$]$2
2032                 ;;
2033         esac
2034         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
2035         then
2036                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
2037                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
2038         fi
2039 ])dnl
2040 dnl ---------------------------------------------------------------------------
2041 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
2042 dnl -----------
2043 dnl Compute the string to append to -library from the given model name
2044 dnl $1 = model name
2045 dnl $2 = variable to set
2046 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
2047 AC_DEFUN([CF_LIB_TYPE],
2048 [
2049         case $1 in
2050         (libtool) $2=''   ;;
2051         (normal)  $2=''   ;;
2052         (debug)   $2='_g' ;;
2053         (profile) $2='_p' ;;
2054         (shared)  $2=''   ;;
2055         esac
2056         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
2057 ])dnl
2058 dnl ---------------------------------------------------------------------------
2059 dnl CF_LINK_DATAONLY version: 12 updated: 2017/07/23 17:46:07
2060 dnl ----------------
2061 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
2062 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
2063 dnl have to provide wrappers for global tables to ensure they're linked
2064 dnl properly.
2065 AC_DEFUN([CF_LINK_DATAONLY],
2066 [
2067 AC_MSG_CHECKING([if data-only library module links])
2068 AC_CACHE_VAL(cf_cv_link_dataonly,[
2069         rm -f conftest.a
2070         cat >conftest.$ac_ext <<EOF
2071 #line __oline__ "configure"
2072 int     testdata[[3]] = { 123, 456, 789 };
2073 EOF
2074         if AC_TRY_EVAL(ac_compile) ; then
2075                 mv conftest.o data.o && \
2076                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
2077         fi
2078         rm -f conftest.$ac_ext data.o
2079         cat >conftest.$ac_ext <<EOF
2080 #line __oline__ "configure"
2081 int     testfunc(void)
2082 {
2083 #if defined(NeXT)
2084         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
2085 #else
2086         extern int testdata[[3]];
2087         return testdata[[0]] == 123
2088            &&  testdata[[1]] == 456
2089            &&  testdata[[2]] == 789;
2090 #endif
2091 }
2092 EOF
2093         if AC_TRY_EVAL(ac_compile); then
2094                 mv conftest.o func.o && \
2095                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
2096         fi
2097         rm -f conftest.$ac_ext func.o
2098         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
2099         cf_saveLIBS="$LIBS"
2100         LIBS="conftest.a $LIBS"
2101         AC_TRY_RUN([
2102         int main(void)
2103         {
2104                 extern int testfunc();
2105                 ${cf_cv_main_return:-return} (!testfunc());
2106         }
2107         ],
2108         [cf_cv_link_dataonly=yes],
2109         [cf_cv_link_dataonly=no],
2110         [cf_cv_link_dataonly=unknown])
2111         LIBS="$cf_saveLIBS"
2112         ])
2113 AC_MSG_RESULT($cf_cv_link_dataonly)
2114
2115 if test "$cf_cv_link_dataonly" = no ; then
2116         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
2117         BROKEN_LINKER=1
2118 fi
2119
2120 ])dnl
2121 dnl ---------------------------------------------------------------------------
2122 dnl CF_MAKEFLAGS version: 18 updated: 2018/02/21 21:26:03
2123 dnl ------------
2124 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
2125 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
2126 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
2127 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
2128 AC_DEFUN([CF_MAKEFLAGS],
2129 [
2130 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
2131         cf_cv_makeflags=''
2132         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
2133         do
2134                 cat >cf_makeflags.tmp <<CF_EOF
2135 SHELL = $SHELL
2136 all :
2137         @ echo '.$cf_option'
2138 CF_EOF
2139                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
2140                 case "$cf_result" in
2141                 (.*k|.*kw)
2142                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
2143                         case "$cf_result" in
2144                         (.*CC=*)        cf_cv_makeflags=
2145                                 ;;
2146                         (*)     cf_cv_makeflags=$cf_option
2147                                 ;;
2148                         esac
2149                         break
2150                         ;;
2151                 (.-)
2152                         ;;
2153                 (*)
2154                         CF_MSG_LOG(given option \"$cf_option\", no match \"$cf_result\")
2155                         ;;
2156                 esac
2157         done
2158         rm -f cf_makeflags.tmp
2159 ])
2160
2161 AC_SUBST(cf_cv_makeflags)
2162 ])dnl
2163 dnl ---------------------------------------------------------------------------
2164 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
2165 dnl ------------
2166 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
2167 dnl a monocase filesystem.
2168 AC_DEFUN([CF_MAKE_TAGS],[
2169 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
2170
2171 AC_CHECK_PROGS(CTAGS, exctags ctags)
2172 AC_CHECK_PROGS(ETAGS, exetags etags)
2173
2174 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
2175
2176 if test "$cf_cv_mixedcase" = yes ; then
2177         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
2178 else
2179         MAKE_UPPER_TAGS=no
2180 fi
2181
2182 if test "$MAKE_UPPER_TAGS" = yes ; then
2183         MAKE_UPPER_TAGS=
2184 else
2185         MAKE_UPPER_TAGS="#"
2186 fi
2187
2188 if test "$MAKE_LOWER_TAGS" = yes ; then
2189         MAKE_LOWER_TAGS=
2190 else
2191         MAKE_LOWER_TAGS="#"
2192 fi
2193
2194 AC_SUBST(CTAGS)
2195 AC_SUBST(ETAGS)
2196
2197 AC_SUBST(MAKE_UPPER_TAGS)
2198 AC_SUBST(MAKE_LOWER_TAGS)
2199 ])dnl
2200 dnl ---------------------------------------------------------------------------
2201 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
2202 dnl ----------------------
2203 dnl Check if the file-system supports mixed-case filenames.  If we're able to
2204 dnl create a lowercase name and see it as uppercase, it doesn't support that.
2205 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
2206 [
2207 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
2208 if test "$cross_compiling" = yes ; then
2209         case $target_alias in
2210         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
2211                 cf_cv_mixedcase=no
2212                 ;;
2213         (*)
2214                 cf_cv_mixedcase=yes
2215                 ;;
2216         esac
2217 else
2218         rm -f conftest CONFTEST
2219         echo test >conftest
2220         if test -f CONFTEST ; then
2221                 cf_cv_mixedcase=no
2222         else
2223                 cf_cv_mixedcase=yes
2224         fi
2225         rm -f conftest CONFTEST
2226 fi
2227 ])
2228 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
2229 ])dnl
2230 dnl ---------------------------------------------------------------------------
2231 dnl CF_MKSTEMP version: 10 updated: 2017/01/21 11:12:16
2232 dnl ----------
2233 dnl Check for a working mkstemp.  This creates two files, checks that they are
2234 dnl successfully created and distinct (AmigaOS apparently fails on the last).
2235 AC_DEFUN([CF_MKSTEMP],[
2236 AC_CHECK_HEADERS( \
2237 unistd.h \
2238 )
2239 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
2240 rm -rf conftest*
2241 AC_TRY_RUN([
2242 #include <sys/types.h>
2243 #ifdef HAVE_UNISTD_H
2244 #include <unistd.h>
2245 #endif
2246 #include <stdlib.h>
2247 #include <stdio.h>
2248 #include <string.h>
2249 #include <sys/stat.h>
2250 int main(void)
2251 {
2252         char *tmpl = "conftestXXXXXX";
2253         char name[2][80];
2254         int n;
2255         int result = 0;
2256         int fd;
2257         struct stat sb;
2258
2259         umask(077);
2260         for (n = 0; n < 2; ++n) {
2261                 strcpy(name[n], tmpl);
2262                 if ((fd = mkstemp(name[n])) >= 0) {
2263                         if (!strcmp(name[n], tmpl)
2264                          || stat(name[n], &sb) != 0
2265                          || (sb.st_mode & S_IFMT) != S_IFREG
2266                          || (sb.st_mode & 077) != 0) {
2267                                 result = 1;
2268                         }
2269                         close(fd);
2270                 }
2271         }
2272         if (result == 0
2273          && !strcmp(name[0], name[1]))
2274                 result = 1;
2275         ${cf_cv_main_return:-return}(result);
2276 }
2277 ],[cf_cv_func_mkstemp=yes
2278 ],[cf_cv_func_mkstemp=no
2279 ],[cf_cv_func_mkstemp=maybe])
2280 ])
2281 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
2282         AC_CHECK_FUNC(mkstemp)
2283 fi
2284 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
2285         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
2286 fi
2287 ])dnl
2288 dnl ---------------------------------------------------------------------------
2289 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2290 dnl ----------
2291 dnl Write a debug message to config.log, along with the line number in the
2292 dnl configure script.
2293 AC_DEFUN([CF_MSG_LOG],[
2294 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2295 ])dnl
2296 dnl ---------------------------------------------------------------------------
2297 dnl CF_NCURSES_ADDON version: 5 updated: 2015/04/26 18:06:58
2298 dnl ----------------
2299 dnl Configure an ncurses add-on, built outside the ncurses tree.
2300 AC_DEFUN([CF_NCURSES_ADDON],[
2301 AC_REQUIRE([CF_NCURSES_CONFIG])
2302
2303 AC_PROVIDE([CF_SUBST_NCURSES_VERSION])
2304
2305 AC_MSG_CHECKING(if you want wide-character code)
2306 AC_ARG_ENABLE(widec,
2307         [  --enable-widec          compile with wide-char/UTF-8 code],
2308         [with_widec=$enableval],
2309         [with_widec=no])
2310 AC_MSG_RESULT($with_widec)
2311 if test "$with_widec" = yes ; then
2312         CF_UTF8_LIB
2313         CF_NCURSES_CONFIG(ncursesw)
2314 else
2315         CF_NCURSES_CONFIG(ncurses)
2316 fi
2317
2318 if test "$NCURSES_CONFIG_PKG" != none ; then
2319         cf_version=`$PKG_CONFIG --modversion $NCURSES_CONFIG_PKG 2>/dev/null`
2320
2321         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2322         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2323         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2324
2325         cf_cv_abi_version=`$PKG_CONFIG --variable=abi_version $NCURSES_CONFIG_PKG 2>/dev/null`
2326         if test -z "$cf_cv_abi_version"
2327         then
2328                 cf_cv_abi_version=`$PKG_CONFIG --variable=major_version $NCURSES_CONFIG_PKG 2>/dev/null`
2329         fi
2330
2331 elif test "$NCURSES_CONFIG" != none ; then
2332
2333         cf_version=`$NCURSES_CONFIG --version 2>/dev/null`
2334
2335         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2336         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2337         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2338
2339         # ABI version is not available from headers
2340         cf_cv_abi_version=`$NCURSES_CONFIG --abi-version 2>/dev/null`
2341
2342 else
2343
2344         for cf_name in MAJOR MINOR PATCH
2345         do
2346         cat >conftest.$ac_ext <<CF_EOF
2347         #include <${cf_cv_ncurses_header:-curses.h}>
2348         AUTOCONF_$cf_name NCURSES_VERSION_$cf_name
2349 CF_EOF
2350                 cf_try="$ac_cpp conftest.$ac_ext 2>&5 | fgrep AUTOCONF_$cf_name >conftest.out"
2351                 AC_TRY_EVAL(cf_try)
2352                 if test -f conftest.out ; then
2353                         cf_result=`cat conftest.out | sed -e "s/^.*AUTOCONF_$cf_name[[  ]][[    ]]*//"`
2354                         eval NCURSES_$cf_name=\"$cf_result\"
2355                         # cat conftest.$ac_ext
2356                         # cat conftest.out
2357                 fi
2358         done
2359
2360         cf_cv_abi_version=${NCURSES_MAJOR}
2361
2362 fi
2363
2364 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
2365
2366 dnl Show the computed version, for logging
2367 cf_cv_timestamp=`date`
2368
2369 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
2370
2371 dnl We need these values in the generated headers
2372 AC_SUBST(NCURSES_MAJOR)
2373 AC_SUBST(NCURSES_MINOR)
2374 AC_SUBST(NCURSES_PATCH)
2375
2376 dnl We need these values in the generated makefiles
2377 AC_SUBST(cf_cv_rel_version)
2378 AC_SUBST(cf_cv_abi_version)
2379
2380 dnl FIXME - not needed for Ada95
2381 AC_SUBST(cf_cv_builtin_bool)
2382 AC_SUBST(cf_cv_header_stdbool_h)
2383 AC_SUBST(cf_cv_type_of_bool)dnl
2384
2385 ])
2386 dnl ---------------------------------------------------------------------------
2387 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
2388 dnl -------------------
2389 dnl Check if we can compile with ncurses' header file
2390 dnl $1 is the cache variable to set
2391 dnl $2 is the header-file to include
2392 dnl $3 is the root name (ncurses or ncursesw)
2393 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2394         AC_TRY_COMPILE([
2395 ]ifelse($3,ncursesw,[
2396 #define _XOPEN_SOURCE_EXTENDED
2397 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2398 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2399 ])[
2400 #include <$2>],[
2401 #ifdef NCURSES_VERSION
2402 ]ifelse($3,ncursesw,[
2403 #ifndef WACS_BSSB
2404         make an error
2405 #endif
2406 ])[
2407 printf("%s\n", NCURSES_VERSION);
2408 #else
2409 #ifdef __NCURSES_H
2410 printf("old\n");
2411 #else
2412         make an error
2413 #endif
2414 #endif
2415         ]
2416         ,[$1=$2]
2417         ,[$1=no])
2418 ])dnl
2419 dnl ---------------------------------------------------------------------------
2420 dnl CF_NCURSES_CONFIG version: 21 updated: 2018/06/20 20:23:13
2421 dnl -----------------
2422 dnl Tie together the configure-script macros for ncurses, preferring these in
2423 dnl order:
2424 dnl a) ".pc" files for pkg-config, using $NCURSES_CONFIG_PKG
2425 dnl b) the "-config" script from ncurses, using $NCURSES_CONFIG
2426 dnl c) just plain libraries
2427 dnl
2428 dnl $1 is the root library name (default: "ncurses")
2429 AC_DEFUN([CF_NCURSES_CONFIG],[
2430 AC_REQUIRE([CF_PKG_CONFIG])
2431 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2432 cf_have_ncuconfig=no
2433
2434 if test "x${PKG_CONFIG:=none}" != xnone; then
2435         AC_MSG_CHECKING(pkg-config for $cf_ncuconfig_root)
2436         if "$PKG_CONFIG" --exists $cf_ncuconfig_root ; then
2437                 AC_MSG_RESULT(yes)
2438
2439                 AC_MSG_CHECKING(if the $cf_ncuconfig_root package files work)
2440                 cf_have_ncuconfig=unknown
2441
2442                 cf_save_CPPFLAGS="$CPPFLAGS"
2443                 cf_save_LIBS="$LIBS"
2444
2445                 CF_ADD_CFLAGS(`$PKG_CONFIG --cflags $cf_ncuconfig_root`)
2446                 CF_ADD_LIBS(`$PKG_CONFIG --libs $cf_ncuconfig_root`)
2447
2448                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2449                         [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2450                         [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2451                                 int main(void)
2452                                 { char *xx = curses_version(); return (xx == 0); }],
2453                                 [cf_have_ncuconfig=yes],
2454                                 [cf_have_ncuconfig=no],
2455                                 [cf_have_ncuconfig=maybe])],
2456                         [cf_have_ncuconfig=no])
2457                 AC_MSG_RESULT($cf_have_ncuconfig)
2458                 test "$cf_have_ncuconfig" = maybe && cf_have_ncuconfig=yes
2459                 if test "$cf_have_ncuconfig" != "yes"
2460                 then
2461                         CPPFLAGS="$cf_save_CPPFLAGS"
2462                         LIBS="$cf_save_LIBS"
2463                         NCURSES_CONFIG_PKG=none
2464                 else
2465                         AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2466                         NCURSES_CONFIG_PKG=$cf_ncuconfig_root
2467                         CF_TERM_HEADER
2468                 fi
2469
2470         else
2471                 AC_MSG_RESULT(no)
2472                 NCURSES_CONFIG_PKG=none
2473         fi
2474 else
2475         NCURSES_CONFIG_PKG=none
2476 fi
2477
2478 if test "x$cf_have_ncuconfig" = "xno"; then
2479         cf_ncurses_config="${cf_ncuconfig_root}${NCURSES_CONFIG_SUFFIX}-config"; echo "Looking for ${cf_ncurses_config}"
2480
2481         CF_ACVERSION_CHECK(2.52,
2482                 [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
2483                 [AC_PATH_PROGS(NCURSES_CONFIG,  ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
2484
2485         if test "$NCURSES_CONFIG" != none ; then
2486
2487                 CF_ADD_CFLAGS(`$NCURSES_CONFIG --cflags`)
2488                 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2489
2490                 # even with config script, some packages use no-override for curses.h
2491                 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2492
2493                 dnl like CF_NCURSES_CPPFLAGS
2494                 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2495
2496                 dnl like CF_NCURSES_LIBS
2497                 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2498                 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2499
2500                 dnl like CF_NCURSES_VERSION
2501                 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
2502
2503         else
2504
2505                 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2506                 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2507
2508         fi
2509 else
2510         NCURSES_CONFIG=none
2511 fi
2512 ])dnl
2513 dnl ---------------------------------------------------------------------------
2514 dnl CF_NCURSES_CPPFLAGS version: 21 updated: 2012/10/06 08:57:51
2515 dnl -------------------
2516 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
2517 dnl the CPPFLAGS variable so we can include its header.
2518 dnl
2519 dnl The header files may be installed as either curses.h, or ncurses.h (would
2520 dnl be obsolete, except that some packagers prefer this name to distinguish it
2521 dnl from a "native" curses implementation).  If not installed for overwrite,
2522 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
2523 dnl /usr/include/ncurses), but someone may have installed overwriting the
2524 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
2525 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
2526 dnl the header.
2527 dnl
2528 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
2529 dnl is already in the include-path, don't even bother with this, since we cannot
2530 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
2531 dnl
2532 dnl The optional parameter gives the root name of the library, in case it is
2533 dnl not installed as the default curses library.  That is how the
2534 dnl wide-character version of ncurses is installed.
2535 AC_DEFUN([CF_NCURSES_CPPFLAGS],
2536 [AC_REQUIRE([CF_WITH_CURSES_DIR])
2537
2538 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
2539 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
2540
2541 test -n "$cf_cv_curses_dir" && \
2542 test "$cf_cv_curses_dir" != "no" && { \
2543   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
2544 }
2545
2546 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
2547         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2548         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
2549         for cf_header in $cf_header_list
2550         do
2551                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2552                 test "$cf_cv_ncurses_h" != no && break
2553         done
2554 ])
2555
2556 CF_NCURSES_HEADER
2557 CF_TERM_HEADER
2558
2559 # some applications need this, but should check for NCURSES_VERSION
2560 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2561
2562 CF_NCURSES_VERSION
2563 ])dnl
2564 dnl ---------------------------------------------------------------------------
2565 dnl CF_NCURSES_HEADER version: 4 updated: 2015/04/15 19:08:48
2566 dnl -----------------
2567 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2568 dnl variations of ncurses' installs.
2569 dnl
2570 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2571 AC_DEFUN([CF_NCURSES_HEADER],[
2572
2573 if test "$cf_cv_ncurses_h" != no ; then
2574         cf_cv_ncurses_header=$cf_cv_ncurses_h
2575 else
2576
2577 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2578         test -n "$verbose" && echo
2579         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2580         test -n "$verbose" && echo search path $cf_search
2581         cf_save2_CPPFLAGS="$CPPFLAGS"
2582         for cf_incdir in $cf_search
2583         do
2584                 CF_ADD_INCDIR($cf_incdir)
2585                 for cf_header in \
2586                         ncurses.h \
2587                         curses.h
2588                 do
2589                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2590                         if test "$cf_cv_ncurses_h2" != no ; then
2591                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2592                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
2593                                 break
2594                         fi
2595                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2596                 done
2597                 CPPFLAGS="$cf_save2_CPPFLAGS"
2598                 test "$cf_cv_ncurses_h2" != no && break
2599         done
2600         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2601         ])
2602
2603         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2604         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
2605         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
2606                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
2607         fi
2608         CF_ADD_INCDIR($cf_1st_incdir)
2609
2610 fi
2611
2612 # Set definitions to allow ifdef'ing for ncurses.h
2613
2614 case $cf_cv_ncurses_header in
2615 (*ncurses.h)
2616         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
2617         ;;
2618 esac
2619
2620 case $cf_cv_ncurses_header in
2621 (ncurses/curses.h|ncurses/ncurses.h)
2622         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
2623         ;;
2624 (ncursesw/curses.h|ncursesw/ncurses.h)
2625         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
2626         ;;
2627 esac
2628
2629 ])dnl
2630 dnl ---------------------------------------------------------------------------
2631 dnl CF_NCURSES_LIBS version: 17 updated: 2015/04/15 19:08:48
2632 dnl ---------------
2633 dnl Look for the ncurses library.  This is a little complicated on Linux,
2634 dnl because it may be linked with the gpm (general purpose mouse) library.
2635 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2636 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2637 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2638 dnl and the linker will record a dependency.
2639 dnl
2640 dnl The optional parameter gives the root name of the library, in case it is
2641 dnl not installed as the default curses library.  That is how the
2642 dnl wide-character version of ncurses is installed.
2643 AC_DEFUN([CF_NCURSES_LIBS],
2644 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2645
2646 cf_nculib_root=ifelse($1,,ncurses,$1)
2647         # This works, except for the special case where we find gpm, but
2648         # ncurses is in a nonstandard location via $LIBS, and we really want
2649         # to link gpm.
2650 cf_ncurses_LIBS=""
2651 cf_ncurses_SAVE="$LIBS"
2652 AC_CHECK_LIB(gpm,Gpm_Open,
2653         [AC_CHECK_LIB(gpm,initscr,
2654                 [LIBS="$cf_ncurses_SAVE"],
2655                 [cf_ncurses_LIBS="-lgpm"])])
2656
2657 case $host_os in
2658 (freebsd*)
2659         # This is only necessary if you are linking against an obsolete
2660         # version of ncurses (but it should do no harm, since it's static).
2661         if test "$cf_nculib_root" = ncurses ; then
2662                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2663         fi
2664         ;;
2665 esac
2666
2667 CF_ADD_LIBS($cf_ncurses_LIBS)
2668
2669 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2670 then
2671         CF_ADD_LIBS(-l$cf_nculib_root)
2672 else
2673         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2674                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2675                 [initscr()],
2676                 initscr)
2677 fi
2678
2679 if test -n "$cf_ncurses_LIBS" ; then
2680         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2681         cf_ncurses_SAVE="$LIBS"
2682         for p in $cf_ncurses_LIBS ; do
2683                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2684                 if test "$q" != "$LIBS" ; then
2685                         LIBS="$q"
2686                 fi
2687         done
2688         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2689                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2690                 [AC_MSG_RESULT(yes)],
2691                 [AC_MSG_RESULT(no)
2692                  LIBS="$cf_ncurses_SAVE"])
2693 fi
2694
2695 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2696 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2697 ])dnl
2698 dnl ---------------------------------------------------------------------------
2699 dnl CF_NCURSES_VERSION version: 15 updated: 2017/05/09 19:26:10
2700 dnl ------------------
2701 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2702 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2703 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2704 AC_DEFUN([CF_NCURSES_VERSION],
2705 [
2706 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2707 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2708         cf_cv_ncurses_version=no
2709         cf_tempfile=out$$
2710         rm -f $cf_tempfile
2711         AC_TRY_RUN([
2712 #include <${cf_cv_ncurses_header:-curses.h}>
2713 #include <stdio.h>
2714 int main(void)
2715 {
2716         FILE *fp = fopen("$cf_tempfile", "w");
2717 #ifdef NCURSES_VERSION
2718 # ifdef NCURSES_VERSION_PATCH
2719         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
2720 # else
2721         fprintf(fp, "%s\n", NCURSES_VERSION);
2722 # endif
2723 #else
2724 # ifdef __NCURSES_H
2725         fprintf(fp, "old\n");
2726 # else
2727         make an error
2728 # endif
2729 #endif
2730         ${cf_cv_main_return:-return}(0);
2731 }],[
2732         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
2733
2734         # This will not work if the preprocessor splits the line after the
2735         # Autoconf token.  The 'unproto' program does that.
2736         cat > conftest.$ac_ext <<EOF
2737 #include <${cf_cv_ncurses_header:-curses.h}>
2738 #undef Autoconf
2739 #ifdef NCURSES_VERSION
2740 Autoconf NCURSES_VERSION
2741 #else
2742 #ifdef __NCURSES_H
2743 Autoconf "old"
2744 #endif
2745 ;
2746 #endif
2747 EOF
2748         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
2749         AC_TRY_EVAL(cf_try)
2750         if test -f conftest.out ; then
2751                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
2752                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
2753                 rm -f conftest.out
2754         fi
2755 ])
2756         rm -f $cf_tempfile
2757 ])
2758 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2759 ])dnl
2760 dnl ---------------------------------------------------------------------------
2761 dnl CF_OBJ_SUBDIR version: 7 updated: 2015/04/17 21:13:04
2762 dnl -------------
2763 dnl Compute the object-directory name from the given model name
2764 AC_DEFUN([CF_OBJ_SUBDIR],
2765 [
2766         case $1 in
2767         (libtool) $2='obj_lo'  ;;
2768         (normal)  $2='objects' ;;
2769         (debug)   $2='obj_g' ;;
2770         (profile) $2='obj_p' ;;
2771         (shared)
2772                 case $cf_cv_system_name in
2773                 (cygwin|msys)
2774                         $2='objects' ;;
2775                 (*)
2776                         $2='obj_s' ;;
2777                 esac
2778         esac
2779 ])dnl
2780 dnl ---------------------------------------------------------------------------
2781 dnl CF_PATHSEP version: 7 updated: 2015/04/12 15:39:00
2782 dnl ----------
2783 dnl Provide a value for the $PATH and similar separator (or amend the value
2784 dnl as provided in autoconf 2.5x).
2785 AC_DEFUN([CF_PATHSEP],
2786 [
2787         AC_MSG_CHECKING(for PATH separator)
2788         case $cf_cv_system_name in
2789         (os2*)  PATH_SEPARATOR=';'  ;;
2790         (*)     ${PATH_SEPARATOR:=':'}  ;;
2791         esac
2792 ifelse([$1],,,[$1=$PATH_SEPARATOR])
2793         AC_SUBST(PATH_SEPARATOR)
2794         AC_MSG_RESULT($PATH_SEPARATOR)
2795 ])dnl
2796 dnl ---------------------------------------------------------------------------
2797 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
2798 dnl --------------
2799 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
2800 dnl begins with one of the prefix/exec_prefix variables, and then again if the
2801 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
2802 dnl delayed evaluation of those symbols.
2803 AC_DEFUN([CF_PATH_SYNTAX],[
2804 if test "x$prefix" != xNONE; then
2805         cf_path_syntax="$prefix"
2806 else
2807         cf_path_syntax="$ac_default_prefix"
2808 fi
2809
2810 case ".[$]$1" in
2811 (.\[$]\(*\)*|.\'*\'*)
2812         ;;
2813 (..|./*|.\\*)
2814         ;;
2815 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
2816         ;;
2817 (.\[$]{*prefix}*|.\[$]{*dir}*)
2818         eval $1="[$]$1"
2819         case ".[$]$1" in
2820         (.NONE/*)
2821                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2822                 ;;
2823         esac
2824         ;;
2825 (.no|.NONE/*)
2826         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2827         ;;
2828 (*)
2829         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
2830         ;;
2831 esac
2832 ])dnl
2833 dnl ---------------------------------------------------------------------------
2834 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
2835 dnl -------------
2836 dnl Check for the package-config program, unless disabled by command-line.
2837 AC_DEFUN([CF_PKG_CONFIG],
2838 [
2839 AC_MSG_CHECKING(if you want to use pkg-config)
2840 AC_ARG_WITH(pkg-config,
2841         [  --with-pkg-config{=path} enable/disable use of pkg-config],
2842         [cf_pkg_config=$withval],
2843         [cf_pkg_config=yes])
2844 AC_MSG_RESULT($cf_pkg_config)
2845
2846 case $cf_pkg_config in
2847 (no)
2848         PKG_CONFIG=none
2849         ;;
2850 (yes)
2851         CF_ACVERSION_CHECK(2.52,
2852                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
2853                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
2854         ;;
2855 (*)
2856         PKG_CONFIG=$withval
2857         ;;
2858 esac
2859
2860 test -z "$PKG_CONFIG" && PKG_CONFIG=none
2861 if test "$PKG_CONFIG" != none ; then
2862         CF_PATH_SYNTAX(PKG_CONFIG)
2863 elif test "x$cf_pkg_config" != xno ; then
2864         AC_MSG_WARN(pkg-config is not installed)
2865 fi
2866
2867 AC_SUBST(PKG_CONFIG)
2868 ])dnl
2869 dnl ---------------------------------------------------------------------------
2870 dnl CF_POSIX_C_SOURCE version: 10 updated: 2018/06/20 20:23:13
2871 dnl -----------------
2872 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
2873 dnl
2874 dnl     POSIX.1-1990                            _POSIX_SOURCE
2875 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
2876 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
2877 dnl             Bindings Option
2878 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
2879 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
2880 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
2881 dnl
2882 dnl Parameters:
2883 dnl     $1 is the nominal value for _POSIX_C_SOURCE
2884 AC_DEFUN([CF_POSIX_C_SOURCE],
2885 [
2886 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
2887
2888 cf_save_CFLAGS="$CFLAGS"
2889 cf_save_CPPFLAGS="$CPPFLAGS"
2890
2891 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
2892 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
2893
2894 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
2895         CF_MSG_LOG(if the symbol is already defined go no further)
2896         AC_TRY_COMPILE([#include <sys/types.h>],[
2897 #ifndef _POSIX_C_SOURCE
2898 make an error
2899 #endif],
2900         [cf_cv_posix_c_source=no],
2901         [cf_want_posix_source=no
2902          case .$cf_POSIX_C_SOURCE in
2903          (.[[12]]??*)
2904                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2905                 ;;
2906          (.2)
2907                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2908                 cf_want_posix_source=yes
2909                 ;;
2910          (.*)
2911                 cf_want_posix_source=yes
2912                 ;;
2913          esac
2914          if test "$cf_want_posix_source" = yes ; then
2915                 AC_TRY_COMPILE([#include <sys/types.h>],[
2916 #ifdef _POSIX_SOURCE
2917 make an error
2918 #endif],[],
2919                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
2920          fi
2921          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
2922          CFLAGS="$cf_trim_CFLAGS"
2923          CPPFLAGS="$cf_trim_CPPFLAGS"
2924          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
2925          CF_MSG_LOG(if the second compile does not leave our definition intact error)
2926          AC_TRY_COMPILE([#include <sys/types.h>],[
2927 #ifndef _POSIX_C_SOURCE
2928 make an error
2929 #endif],,
2930          [cf_cv_posix_c_source=no])
2931          CFLAGS="$cf_save_CFLAGS"
2932          CPPFLAGS="$cf_save_CPPFLAGS"
2933         ])
2934 ])
2935
2936 if test "$cf_cv_posix_c_source" != no ; then
2937         CFLAGS="$cf_trim_CFLAGS"
2938         CPPFLAGS="$cf_trim_CPPFLAGS"
2939         CF_ADD_CFLAGS($cf_cv_posix_c_source)
2940 fi
2941
2942 ])dnl
2943 dnl ---------------------------------------------------------------------------
2944 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
2945 dnl ----------
2946 dnl Check for archiver "ar".
2947 AC_DEFUN([CF_PROG_AR],[
2948 AC_CHECK_TOOL(AR, ar, ar)
2949 ])
2950 dnl ---------------------------------------------------------------------------
2951 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
2952 dnl -----------
2953 dnl Check for awk, ensure that the check found something.
2954 AC_DEFUN([CF_PROG_AWK],
2955 [
2956 AC_PROG_AWK
2957 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
2958 ])dnl
2959 dnl ---------------------------------------------------------------------------
2960 dnl CF_PROG_CC version: 4 updated: 2014/07/12 18:57:58
2961 dnl ----------
2962 dnl standard check for CC, plus followup sanity checks
2963 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
2964 AC_DEFUN([CF_PROG_CC],[
2965 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
2966 CF_GCC_VERSION
2967 CF_ACVERSION_CHECK(2.52,
2968         [AC_PROG_CC_STDC],
2969         [CF_ANSI_CC_REQD])
2970 CF_CC_ENV_FLAGS
2971 ])dnl
2972 dnl ---------------------------------------------------------------------------
2973 dnl CF_PROG_CC_C_O version: 5 updated: 2017/01/21 11:06:25
2974 dnl --------------
2975 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
2976 dnl the output file can be renamed, and allows for a shell variable that can
2977 dnl be used later.  The parameter is either CC or CXX.  The result is the
2978 dnl cache variable:
2979 dnl     $cf_cv_prog_CC_c_o
2980 dnl     $cf_cv_prog_CXX_c_o
2981 dnl
2982 dnl $1 = compiler
2983 dnl $2 = compiler options, if any
2984 AC_DEFUN([CF_PROG_CC_C_O],
2985 [AC_REQUIRE([AC_PROG_CC])dnl
2986 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
2987 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
2988 [
2989 cat > conftest.$ac_ext <<CF_EOF
2990 int main(void)
2991 {
2992         ${cf_cv_main_return:-return}(0);
2993 }
2994 CF_EOF
2995 # We do the test twice because some compilers refuse to overwrite an
2996 # existing .o file with -o, though they will create one.
2997 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
2998 if AC_TRY_EVAL(ac_try) &&
2999   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
3000 then
3001   eval cf_cv_prog_$1_c_o=yes
3002 else
3003   eval cf_cv_prog_$1_c_o=no
3004 fi
3005 rm -rf conftest*
3006 ])dnl
3007 if test $cf_cv_prog_$1_c_o = yes; then
3008   AC_MSG_RESULT([yes])
3009 else
3010   AC_MSG_RESULT([no])
3011 fi
3012 ])dnl
3013 dnl ---------------------------------------------------------------------------
3014 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
3015 dnl -------------
3016 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
3017 dnl This macro adds a check to ensure the script found something.
3018 AC_DEFUN([CF_PROG_EGREP],
3019 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
3020         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
3021                 then ac_cv_prog_egrep='grep -E'
3022                 else ac_cv_prog_egrep='egrep'
3023         fi])
3024         EGREP=$ac_cv_prog_egrep
3025         AC_SUBST([EGREP])
3026         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
3027 ])dnl
3028 dnl ---------------------------------------------------------------------------
3029 dnl CF_PROG_EXT version: 14 updated: 2018/06/20 20:23:13
3030 dnl -----------
3031 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
3032 AC_DEFUN([CF_PROG_EXT],
3033 [
3034 AC_REQUIRE([CF_CHECK_CACHE])
3035 case $cf_cv_system_name in
3036 (os2*)
3037         CFLAGS="$CFLAGS -Zmt"
3038         CF_APPEND_TEXT(CPPFLAGS,-D__ST_MT_ERRNO__)
3039         CXXFLAGS="$CXXFLAGS -Zmt"
3040         # autoconf's macro sets -Zexe and suffix both, which conflict:w
3041         LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
3042         ac_cv_exeext=.exe
3043         ;;
3044 esac
3045
3046 AC_EXEEXT
3047 AC_OBJEXT
3048
3049 PROG_EXT="$EXEEXT"
3050 AC_SUBST(PROG_EXT)
3051 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT",[Define to the program extension (normally blank)])
3052 ])dnl
3053 dnl ---------------------------------------------------------------------------
3054 dnl CF_PROG_INSTALL version: 7 updated: 2015/04/18 08:56:57
3055 dnl ---------------
3056 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
3057 dnl misc/tabset install won't work properly.  Usually this happens only when
3058 dnl using the fallback mkinstalldirs script
3059 AC_DEFUN([CF_PROG_INSTALL],
3060 [AC_PROG_INSTALL
3061 case $INSTALL in
3062 (/*)
3063         ;;
3064 (*)
3065         CF_DIRNAME(cf_dir,$INSTALL)
3066         test -z "$cf_dir" && cf_dir=.
3067         INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
3068         ;;
3069 esac
3070 ])dnl
3071 dnl ---------------------------------------------------------------------------
3072 dnl CF_PROG_GNAT version: 6 updated: 2018/01/16 16:45:49
3073 dnl ------------
3074 dnl Check for gnatmake, ensure that it is complete.
3075 AC_DEFUN([CF_PROG_GNAT],[
3076 cf_ada_make=gnatmake
3077 cf_ada_config="#"
3078 AC_CHECK_PROG(gnatmake_exists, $cf_ada_make, yes, no)
3079 if test "$ac_cv_prog_gnatmake_exists" = no; then
3080         cf_ada_make=
3081         cf_cv_prog_gnat_correct=no
3082 else
3083         AC_CHECK_PROG(gprconfig_exists, gprconfig, yes, no)
3084         if test "$ac_cv_prog_gprconfig_exists" = yes
3085         then
3086                 rm -rf conftest* *~conftest*
3087                 if mkdir conftest.src
3088                 then
3089                         cf_ada_config=""
3090                         cd conftest.src
3091                         for cf_gprconfig in Ada C
3092                         do
3093                                 AC_MSG_CHECKING(for gprconfig name for $cf_gprconfig)
3094                                 cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
3095                                 if test -n "$cf_gprconfig_value"
3096                                 then
3097                                         eval cf_ada_config_[$]cf_gprconfig=[$]cf_gprconfig_value
3098                                         AC_MSG_RESULT($cf_gprconfig_value)
3099                                 else
3100                                         AC_MSG_RESULT(missing)
3101                                         cf_ada_config="#"
3102                                         break
3103                                 fi
3104                         done
3105                         cd ..
3106                         rm -rf conftest* *~conftest*
3107                 fi
3108         else
3109                 # gprconfig is newer than gnatmake; we can continue...
3110                 cf_ada_config="##"
3111         fi
3112         if test "x$cf_ada_config" != "x#"
3113         then
3114                 CF_GNAT_VERSION
3115                 AC_CHECK_PROG(M4_exists, m4, yes, no)
3116                 if test "$ac_cv_prog_M4_exists" = no; then
3117                         cf_cv_prog_gnat_correct=no
3118                         echo Ada95 binding required program m4 not found. Ada95 binding disabled.
3119                 fi
3120                 if test "$cf_cv_prog_gnat_correct" = yes; then
3121                         AC_MSG_CHECKING(if GNAT works)
3122                         CF_GNAT_TRY_RUN([procedure conftest;],
3123 [with Text_IO;
3124 with GNAT.OS_Lib;
3125 procedure conftest is
3126 begin
3127    Text_IO.Put ("Hello World");
3128    Text_IO.New_Line;
3129    GNAT.OS_Lib.OS_Exit (0);
3130 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
3131                         AC_MSG_RESULT($cf_cv_prog_gnat_correct)
3132                 fi
3133         else
3134                 cf_cv_prog_gnat_correct=no
3135         fi
3136 fi
3137
3138 AC_SUBST(cf_ada_make)
3139 AC_SUBST(cf_ada_config)
3140 AC_SUBST(cf_ada_config_Ada)
3141 AC_SUBST(cf_ada_config_C)
3142 ])dnl
3143 dnl ---------------------------------------------------------------------------
3144 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
3145 dnl ------------
3146 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
3147 dnl option if it is supported.
3148 AC_DEFUN([CF_PROG_LN_S],[
3149 AC_PROG_LN_S
3150 AC_MSG_CHECKING(if $LN_S -f options work)
3151
3152 rm -f conf$$.src conf$$dst
3153 echo >conf$$.dst
3154 echo first >conf$$.src
3155 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
3156         cf_prog_ln_sf=yes
3157 else
3158         cf_prog_ln_sf=no
3159 fi
3160 rm -f conf$$.dst conf$$src
3161 AC_MSG_RESULT($cf_prog_ln_sf)
3162
3163 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
3164 ])dnl
3165 dnl ---------------------------------------------------------------------------
3166 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
3167 dnl ----------------
3168 dnl Remove all -U and -D options that refer to the given symbol from a list
3169 dnl of C compiler options.  This works around the problem that not all
3170 dnl compilers process -U and -D options from left-to-right, so a -U option
3171 dnl cannot be used to cancel the effect of a preceding -D option.
3172 dnl
3173 dnl $1 = target (which could be the same as the source variable)
3174 dnl $2 = source (including '$')
3175 dnl $3 = symbol to remove
3176 define([CF_REMOVE_DEFINE],
3177 [
3178 $1=`echo "$2" | \
3179         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
3180                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
3181 ])dnl
3182 dnl ---------------------------------------------------------------------------
3183 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
3184 dnl -------------
3185 dnl Remove the given library from the symbol
3186 dnl
3187 dnl $1 = target (which could be the same as the source variable)
3188 dnl $2 = source (including '$')
3189 dnl $3 = library to remove
3190 define([CF_REMOVE_LIB],
3191 [
3192 # remove $3 library from $2
3193 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
3194 ])dnl
3195 dnl ---------------------------------------------------------------------------
3196 dnl CF_SHARED_OPTS version: 93 updated: 2018/08/18 16:36:35
3197 dnl --------------
3198 dnl --------------
3199 dnl Attempt to determine the appropriate CC/LD options for creating a shared
3200 dnl library.
3201 dnl
3202 dnl Notes:
3203 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
3204 dnl the build-tree, i.e., by making use of the libraries that are compiled in
3205 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
3206 dnl shared library since that can lead to unexpected results at runtime.
3207 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
3208 dnl libraries are compiled in ../../lib
3209 dnl
3210 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
3211 dnl to install symbolic links to the rel/abi versions of shared libraries.
3212 dnl
3213 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
3214 dnl version when making symbolic links.
3215 dnl
3216 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
3217 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
3218 dnl (ex: libncurses.so.<ver>).
3219 dnl
3220 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
3221 AC_DEFUN([CF_SHARED_OPTS],
3222 [
3223         AC_REQUIRE([CF_LD_RPATH_OPT])
3224
3225         RM_SHARED_OPTS=
3226         LOCAL_LDFLAGS=
3227         LOCAL_LDFLAGS2=
3228         LD_SHARED_OPTS=
3229         INSTALL_LIB="-m 644"
3230         : ${rel_builddir:=.}
3231
3232         shlibdir=$libdir
3233         AC_SUBST(shlibdir)
3234
3235         MAKE_DLLS="#"
3236         AC_SUBST(MAKE_DLLS)
3237
3238         cf_cv_do_symlinks=no
3239         cf_ld_rpath_opt=
3240         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
3241
3242         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
3243         AC_ARG_WITH(shlib-version,
3244         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
3245         [test -z "$withval" && withval=auto
3246         case $withval in
3247         (yes)
3248                 cf_cv_shlib_version=auto
3249                 ;;
3250         (rel|abi|auto)
3251                 cf_cv_shlib_version=$withval
3252                 ;;
3253         (*)
3254                 AC_MSG_RESULT($withval)
3255                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
3256                 ;;
3257         esac
3258         ],[cf_cv_shlib_version=auto])
3259         AC_MSG_RESULT($cf_cv_shlib_version)
3260
3261         cf_cv_rm_so_locs=no
3262         cf_try_cflags=
3263
3264         # Some less-capable ports of gcc support only -fpic
3265         CC_SHARED_OPTS=
3266
3267         cf_try_fPIC=no
3268         if test "$GCC" = yes
3269         then
3270                 cf_try_fPIC=yes
3271         else
3272                 case $cf_cv_system_name in
3273                 (*linux*)       # e.g., PGI compiler
3274                         cf_try_fPIC=yes
3275                         ;;
3276                 esac
3277         fi
3278
3279         if test "$cf_try_fPIC" = yes
3280         then
3281                 AC_MSG_CHECKING(which $CC option to use)
3282                 cf_save_CFLAGS="$CFLAGS"
3283                 for CC_SHARED_OPTS in -fPIC -fpic ''
3284                 do
3285                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
3286                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
3287                 done
3288                 AC_MSG_RESULT($CC_SHARED_OPTS)
3289                 CFLAGS="$cf_save_CFLAGS"
3290         fi
3291
3292         cf_cv_shlib_version_infix=no
3293
3294         case $cf_cv_system_name in
3295         (aix4.[3-9]*|aix[[5-7]]*)
3296                 if test "$GCC" = yes; then
3297                         CC_SHARED_OPTS='-Wl,-brtl'
3298                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
3299                 else
3300                         CC_SHARED_OPTS='-brtl'
3301                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
3302                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
3303                 fi
3304                 ;;
3305         (beos*)
3306                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
3307                 ;;
3308         (cygwin*)
3309                 CC_SHARED_OPTS=
3310                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3311                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3312                 cf_cv_shlib_version=cygdll
3313                 cf_cv_shlib_version_infix=cygdll
3314                 shlibdir=$bindir
3315                 MAKE_DLLS=
3316                 cat >mk_shared_lib.sh <<-CF_EOF
3317                 #!$SHELL
3318                 SHARED_LIB=\[$]1
3319                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3320                 shift
3321                 cat <<-EOF
3322                 Linking shared library
3323                 ** SHARED_LIB \[$]SHARED_LIB
3324                 ** IMPORT_LIB \[$]IMPORT_LIB
3325 EOF
3326                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3327 CF_EOF
3328                 chmod +x mk_shared_lib.sh
3329                 ;;
3330         (msys*)
3331                 CC_SHARED_OPTS=
3332                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3333                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3334                 cf_cv_shlib_version=msysdll
3335                 cf_cv_shlib_version_infix=msysdll
3336                 shlibdir=$bindir
3337                 MAKE_DLLS=
3338                 cat >mk_shared_lib.sh <<-CF_EOF
3339                 #!$SHELL
3340                 SHARED_LIB=\[$]1
3341                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3342                 shift
3343                 cat <<-EOF
3344                 Linking shared library
3345                 ** SHARED_LIB \[$]SHARED_LIB
3346                 ** IMPORT_LIB \[$]IMPORT_LIB
3347 EOF
3348                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3349 CF_EOF
3350                 chmod +x mk_shared_lib.sh
3351                 ;;
3352         (darwin*)
3353                 cf_try_cflags="no-cpp-precomp"
3354                 CC_SHARED_OPTS="-dynamic"
3355                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
3356                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
3357                 cf_cv_shlib_version_infix=yes
3358                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
3359                         cf_save_LDFLAGS=$LDFLAGS
3360                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3361                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
3362                                 LDFLAGS=$cf_save_LDFLAGS])
3363                 if test $cf_cv_ldflags_search_paths_first = yes; then
3364                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3365                 fi
3366                 ;;
3367         (hpux[[7-8]]*)
3368                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
3369                 if test "$GCC" != yes; then
3370                         CC_SHARED_OPTS='+Z'
3371                 fi
3372                 MK_SHARED_LIB='${LD} ${LDFLAGS} -b -o $[@]'
3373                 INSTALL_LIB="-m 555"
3374                 ;;
3375         (hpux*)
3376                 # (tested with gcc 2.7.2 -- I don't have c89)
3377                 if test "$GCC" = yes; then
3378                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
3379                 else
3380                         CC_SHARED_OPTS='+Z'
3381                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
3382                 fi
3383                 MK_SHARED_LIB='${LD} ${LDFLAGS} +b ${libdir} -b -o $[@]'
3384                 # HP-UX shared libraries must be executable, and should be
3385                 # readonly to exploit a quirk in the memory manager.
3386                 INSTALL_LIB="-m 555"
3387                 ;;
3388         (interix*)
3389                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3390                 if test "$cf_cv_shlib_version" = rel; then
3391                         cf_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
3392                 else
3393                         cf_shared_soname='`basename $[@]`'
3394                 fi
3395                 CC_SHARED_OPTS=
3396                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $[@]'
3397                 ;;
3398         (irix*)
3399                 if test "$cf_cv_enable_rpath" = yes ; then
3400                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3401                 fi
3402                 # tested with IRIX 5.2 and 'cc'.
3403                 if test "$GCC" != yes; then
3404                         CC_SHARED_OPTS='-KPIC'
3405                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
3406                 else
3407                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,`basename $[@]` -o $[@]'
3408                 fi
3409                 cf_cv_rm_so_locs=yes
3410                 ;;
3411         (linux*|gnu*|k*bsd*-gnu)
3412                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
3413                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3414                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3415                 fi
3416                 if test "$cf_cv_enable_rpath" = yes ; then
3417                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3418                 fi
3419                 CF_SHARED_SONAME
3420                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3421                 ;;
3422         (mingw*)
3423                 cf_cv_shlib_version=mingw
3424                 cf_cv_shlib_version_infix=mingw
3425                 shlibdir=$bindir
3426                 MAKE_DLLS=
3427                 if test "$DFT_LWR_MODEL" = "shared" ; then
3428                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
3429                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3430                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
3431                 fi
3432                 CC_SHARED_OPTS=
3433                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3434                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3435                 cat >mk_shared_lib.sh <<-CF_EOF
3436                 #!$SHELL
3437                 SHARED_LIB=\[$]1
3438                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3439                 shift
3440                 cat <<-EOF
3441                 Linking shared library
3442                 ** SHARED_LIB \[$]SHARED_LIB
3443                 ** IMPORT_LIB \[$]IMPORT_LIB
3444 EOF
3445                 exec \[$]* ${LDFLAGS} -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3446 CF_EOF
3447                 chmod +x mk_shared_lib.sh
3448                 ;;
3449         (openbsd[[2-9]].*|mirbsd*)
3450                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
3451                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3452                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3453                 fi
3454                 if test "$cf_cv_enable_rpath" = yes ; then
3455                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3456                 fi
3457                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3458                 CF_SHARED_SONAME
3459                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3460                 ;;
3461         (nto-qnx*|openbsd*|freebsd[[12]].*)
3462                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3463                 MK_SHARED_LIB='${LD} ${LDFLAGS} -Bshareable -o $[@]'
3464                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3465                 ;;
3466         (dragonfly*|freebsd*)
3467                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3468                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3469                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3470                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
3471                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3472                 fi
3473                 CF_SHARED_SONAME
3474                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3475                 ;;
3476         (netbsd*)
3477                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3478                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3479                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3480                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3481                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3482                         if test "$cf_cv_shlib_version" = auto; then
3483                         if test -f /usr/libexec/ld.elf_so; then
3484                                 cf_cv_shlib_version=abi
3485                         else
3486                                 cf_cv_shlib_version=rel
3487                         fi
3488                         fi
3489                         CF_SHARED_SONAME
3490                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
3491                 else
3492                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -Wl,-shared -Wl,-Bshareable -o $[@]'
3493                 fi
3494                 ;;
3495         (osf*|mls+*)
3496                 # tested with OSF/1 V3.2 and 'cc'
3497                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
3498                 # link with shared libs).
3499                 MK_SHARED_LIB='${LD} ${LDFLAGS} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
3500                 case $host_os in
3501                 (osf4*)
3502                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
3503                         ;;
3504                 esac
3505                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
3506                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
3507                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3508                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3509                 fi
3510                 cf_cv_rm_so_locs=yes
3511                 ;;
3512         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
3513                 # tested with osr5.0.5
3514                 if test "$GCC" != yes; then
3515                         CC_SHARED_OPTS='-belf -KPIC'
3516                 fi
3517                 MK_SHARED_LIB='${LD} ${LDFLAGS} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
3518                 if test "$cf_cv_enable_rpath" = yes ; then
3519                         # only way is to set LD_RUN_PATH but no switch for it
3520                         RUN_PATH=$libdir
3521                 fi
3522                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3523                 LINK_PROGS='LD_RUN_PATH=${libdir}'
3524                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
3525                 ;;
3526         (sunos4*)
3527                 # tested with SunOS 4.1.1 and gcc 2.7.0
3528                 if test "$GCC" != yes; then
3529                         CC_SHARED_OPTS='-KPIC'
3530                 fi
3531                 MK_SHARED_LIB='${LD} ${LDFLAGS} -assert pure-text -o $[@]'
3532                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3533                 ;;
3534         (solaris2*)
3535                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
3536                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
3537                 if test "$DFT_LWR_MODEL" = "shared" ; then
3538                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
3539                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3540                 fi
3541                 if test "$cf_cv_enable_rpath" = yes ; then
3542                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
3543                 fi
3544                 CF_SHARED_SONAME
3545                 if test "$GCC" != yes; then
3546                         cf_save_CFLAGS="$CFLAGS"
3547                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
3548                         do
3549                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
3550                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
3551                         done
3552                         CFLAGS="$cf_save_CFLAGS"
3553                         CC_SHARED_OPTS=$cf_shared_opts
3554                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3555                 else
3556                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3557                 fi
3558                 ;;
3559         (sysv5uw7*|unix_sv*)
3560                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
3561                 if test "$GCC" != yes; then
3562                         CC_SHARED_OPTS='-KPIC'
3563                 fi
3564                 MK_SHARED_LIB='${LD} ${LDFLAGS} -d y -G -o [$]@'
3565                 ;;
3566         (*)
3567                 CC_SHARED_OPTS='unknown'
3568                 MK_SHARED_LIB='echo unknown'
3569                 ;;
3570         esac
3571
3572         # This works if the last tokens in $MK_SHARED_LIB are the -o target.