Ada95/aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 2010-2017,2018 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.141 2018/12/15 19:54:31 tom Exp $
  32 dnl Macros used in NCURSES Ada95 auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See https://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
  43 dnl ------------------
  44 dnl Conditionally generate script according to whether we're using a given autoconf.
  45 dnl
  46 dnl $1 = version to compare against
  47 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  48 dnl $3 = code to use if AC_ACVERSION is older than $1.
  49 define([CF_ACVERSION_CHECK],
  50 [
  51 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
  52 ifdef([m4_version_compare],
  53 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  54 [CF_ACVERSION_COMPARE(
  55 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  56 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  57 dnl ---------------------------------------------------------------------------
  58 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
  59 dnl --------------------
  60 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  61 dnl                      MAJOR2, MINOR2, TERNARY2,
  62 dnl                      PRINTABLE2, not FOUND, FOUND)
  63 define([CF_ACVERSION_COMPARE],
  64 [ifelse(builtin([eval], [$2 < $5]), 1,
  65 [ifelse([$8], , ,[$8])],
  66 [ifelse([$9], , ,[$9])])])dnl
  67 dnl ---------------------------------------------------------------------------
  68 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
  69 dnl -------------------
  70 dnl Construct the list of include-options for the C programs in the Ada95
  71 dnl binding.
  72 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  73 [
  74 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  75 if test "$srcdir" != "."; then
  76         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
  77 fi
  78 if test "$GCC" != yes; then
  79         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  80 elif test "$includedir" != "/usr/include"; then
  81         if test "$includedir" = '${prefix}/include' ; then
  82                 if test x$prefix != x/usr ; then
  83                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  84                 fi
  85         else
  86                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
  87         fi
  88 fi
  89 AC_SUBST(ACPPFLAGS)
  90 ])dnl
  91 dnl ---------------------------------------------------------------------------
  92 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
  93 dnl ---------------
  94 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
  95 AC_DEFUN([CF_ADD_ADAFLAGS],[
  96         ADAFLAGS="$ADAFLAGS $1"
  97         AC_SUBST(ADAFLAGS)
  98 ])dnl
  99 dnl ---------------------------------------------------------------------------
 100 dnl CF_ADD_CFLAGS version: 13 updated: 2017/02/25 18:57:40
 101 dnl -------------
 102 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 103 dnl The second parameter if given makes this macro verbose.
 104 dnl
 105 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 106 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 107 dnl confused by the quotes (which require backslashes to keep them usable).
 108 AC_DEFUN([CF_ADD_CFLAGS],
 109 [
 110 cf_fix_cppflags=no
 111 cf_new_cflags=
 112 cf_new_cppflags=
 113 cf_new_extra_cppflags=
 114
 115 for cf_add_cflags in $1
 116 do
 117 case $cf_fix_cppflags in
 118 (no)
 119         case $cf_add_cflags in
 120         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 121                 case $cf_add_cflags in
 122                 (-D*)
 123                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 124
 125                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 126                                 && test -z "${cf_tst_cflags}" \
 127                                 && cf_fix_cppflags=yes
 128
 129                         if test $cf_fix_cppflags = yes ; then
 130                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 131                                 continue
 132                         elif test "${cf_tst_cflags}" = "\"'" ; then
 133                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 134                                 continue
 135                         fi
 136                         ;;
 137                 esac
 138                 case "$CPPFLAGS" in
 139                 (*$cf_add_cflags)
 140                         ;;
 141                 (*)
 142                         case $cf_add_cflags in
 143                         (-D*)
 144                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 145                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 146                                 ;;
 147                         esac
 148                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 149                         ;;
 150                 esac
 151                 ;;
 152         (*)
 153                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 154                 ;;
 155         esac
 156         ;;
 157 (yes)
 158         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 159
 160         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 161
 162         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 163                 && test -z "${cf_tst_cflags}" \
 164                 && cf_fix_cppflags=no
 165         ;;
 166 esac
 167 done
 168
 169 if test -n "$cf_new_cflags" ; then
 170         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 171         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 172 fi
 173
 174 if test -n "$cf_new_cppflags" ; then
 175         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 176         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 177 fi
 178
 179 if test -n "$cf_new_extra_cppflags" ; then
 180         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 181         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 182 fi
 183
 184 AC_SUBST(EXTRA_CPPFLAGS)
 185
 186 ])dnl
 187 dnl ---------------------------------------------------------------------------
 188 dnl CF_ADD_INCDIR version: 15 updated: 2018/06/20 20:23:13
 189 dnl -------------
 190 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 191 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 192 dnl but old versions (and some misinstalled ones) need that.  To make things
 193 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 194 dnl the include-path).
 195 AC_DEFUN([CF_ADD_INCDIR],
 196 [
 197 if test -n "$1" ; then
 198   for cf_add_incdir in $1
 199   do
 200         while test $cf_add_incdir != /usr/include
 201         do
 202           if test -d $cf_add_incdir
 203           then
 204                 cf_have_incdir=no
 205                 if test -n "$CFLAGS$CPPFLAGS" ; then
 206                   # a loop is needed to ensure we can add subdirs of existing dirs
 207                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 208                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 209                           cf_have_incdir=yes; break
 210                         fi
 211                   done
 212                 fi
 213
 214                 if test "$cf_have_incdir" = no ; then
 215                   if test "$cf_add_incdir" = /usr/local/include ; then
 216                         if test "$GCC" = yes
 217                         then
 218                           cf_save_CPPFLAGS=$CPPFLAGS
 219                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
 220                           AC_TRY_COMPILE([#include <stdio.h>],
 221                                   [printf("Hello")],
 222                                   [],
 223                                   [cf_have_incdir=yes])
 224                           CPPFLAGS=$cf_save_CPPFLAGS
 225                         fi
 226                   fi
 227                 fi
 228
 229                 if test "$cf_have_incdir" = no ; then
 230                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 231                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 232
 233                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 234                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 235                   cf_add_incdir="$cf_top_incdir"
 236                 else
 237                   break
 238                 fi
 239           else
 240                 break
 241           fi
 242         done
 243   done
 244 fi
 245 ])dnl
 246 dnl ---------------------------------------------------------------------------
 247 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 248 dnl ----------
 249 dnl Add a library, used to enforce consistency.
 250 dnl
 251 dnl $1 = library to add, without the "-l"
 252 dnl $2 = variable to update (default $LIBS)
 253 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 254 dnl ---------------------------------------------------------------------------
 255 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 256 dnl -------------
 257 dnl     Adds to the library-path
 258 dnl
 259 dnl     Some machines have trouble with multiple -L options.
 260 dnl
 261 dnl $1 is the (list of) directory(s) to add
 262 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 263 dnl
 264 AC_DEFUN([CF_ADD_LIBDIR],
 265 [
 266 if test -n "$1" ; then
 267         for cf_add_libdir in $1
 268         do
 269                 if test $cf_add_libdir = /usr/lib ; then
 270                         :
 271                 elif test -d $cf_add_libdir
 272                 then
 273                         cf_have_libdir=no
 274                         if test -n "$LDFLAGS$LIBS" ; then
 275                                 # a loop is needed to ensure we can add subdirs of existing dirs
 276                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 277                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 278                                                 cf_have_libdir=yes; break
 279                                         fi
 280                                 done
 281                         fi
 282                         if test "$cf_have_libdir" = no ; then
 283                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 284                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 285                         fi
 286                 fi
 287         done
 288 fi
 289 ])dnl
 290 dnl ---------------------------------------------------------------------------
 291 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
 292 dnl -----------
 293 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 294 dnl prepended to an existing list, since their dependencies are assumed to
 295 dnl already exist in the list.
 296 dnl
 297 dnl $1 = libraries to add, with the "-l", etc.
 298 dnl $2 = variable to update (default $LIBS)
 299 AC_DEFUN([CF_ADD_LIBS],[
 300 cf_add_libs="$1"
 301 # Filter out duplicates - this happens with badly-designed ".pc" files...
 302 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
 303 do
 304         for cf_add_2lib in $cf_add_libs
 305         do
 306                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
 307                 then
 308                         cf_add_1lib=
 309                         break
 310                 fi
 311         done
 312         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
 313 done
 314 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 315 ])dnl
 316 dnl ---------------------------------------------------------------------------
 317 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 318 dnl ------------------
 319 dnl Append to a search-list for a nonstandard header/lib-file
 320 dnl     $1 = the variable to return as result
 321 dnl     $2 = the package name
 322 dnl     $3 = the subdirectory, e.g., bin, include or lib
 323 dnl $4 = the directory under which we will test for subdirectories
 324 dnl $5 = a directory that we do not want $4 to match
 325 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 326 [
 327 test "x$4" != "x$5" && \
 328 test -d "$4" && \
 329 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 330         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 331         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 332         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 333         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 334         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 335         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 336 }
 337 ])dnl
 338 dnl ---------------------------------------------------------------------------
 339 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 340 dnl --------------
 341 dnl use this macro for appending text without introducing an extra blank at
 342 dnl the beginning
 343 define([CF_APPEND_TEXT],
 344 [
 345         test -n "[$]$1" && $1="[$]$1 "
 346         $1="[$]{$1}$2"
 347 ])dnl
 348 dnl ---------------------------------------------------------------------------
 349 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 350 dnl --------------
 351 dnl Allow user to disable a normally-on option.
 352 AC_DEFUN([CF_ARG_DISABLE],
 353 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 354 dnl ---------------------------------------------------------------------------
 355 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 356 dnl -------------
 357 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 358 dnl values.
 359 dnl
 360 dnl Parameters:
 361 dnl $1 = option name
 362 dnl $2 = help-string
 363 dnl $3 = action to perform if option is not default
 364 dnl $4 = action if perform if option is default
 365 dnl $5 = default option value (either 'yes' or 'no')
 366 AC_DEFUN([CF_ARG_OPTION],
 367 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 368         if test "$enableval" != "$5" ; then
 369 ifelse([$3],,[    :]dnl
 370 ,[    $3]) ifelse([$4],,,[
 371         else
 372                 $4])
 373         fi],[enableval=$5 ifelse([$4],,,[
 374         $4
 375 ])dnl
 376 ])])dnl
 377 dnl ---------------------------------------------------------------------------
 378 dnl CF_AR_FLAGS version: 6 updated: 2015/10/10 15:25:05
 379 dnl -----------
 380 dnl Check for suitable "ar" (archiver) options for updating an archive.
 381 dnl
 382 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 383 dnl as well as a workaround for breakage of make's archive rules by the GNU
 384 dnl binutils "ar" program.
 385 AC_DEFUN([CF_AR_FLAGS],[
 386 AC_REQUIRE([CF_PROG_AR])
 387
 388 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 389         cf_cv_ar_flags=unknown
 390         for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 391         do
 392
 393                 # check if $ARFLAGS already contains this choice
 394                 if test "x$ARFLAGS" != "x" ; then
 395                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 396                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 397                                 cf_cv_ar_flags=
 398                                 break
 399                         fi
 400                 fi
 401
 402                 rm -f conftest.$ac_cv_objext
 403                 rm -f conftest.a
 404
 405                 cat >conftest.$ac_ext <<EOF
 406 #line __oline__ "configure"
 407 int     testdata[[3]] = { 123, 456, 789 };
 408 EOF
 409                 if AC_TRY_EVAL(ac_compile) ; then
 410                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 411                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 412                         if test -f conftest.a ; then
 413                                 cf_cv_ar_flags=$cf_ar_flags
 414                                 break
 415                         fi
 416                 else
 417                         CF_VERBOSE(cannot compile test-program)
 418                         break
 419                 fi
 420         done
 421         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 422 ])
 423
 424 if test -n "$ARFLAGS" ; then
 425         if test -n "$cf_cv_ar_flags" ; then
 426                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 427         fi
 428 else
 429         ARFLAGS=$cf_cv_ar_flags
 430 fi
 431
 432 AC_SUBST(ARFLAGS)
 433 ])
 434 dnl ---------------------------------------------------------------------------
 435 dnl CF_BUILD_CC version: 8 updated: 2018/01/04 20:31:04
 436 dnl -----------
 437 dnl If we're cross-compiling, allow the user to override the tools and their
 438 dnl options.  The configure script is oriented toward identifying the host
 439 dnl compiler, etc., but we need a build compiler to generate parts of the
 440 dnl source.
 441 dnl
 442 dnl $1 = default for $CPPFLAGS
 443 dnl $2 = default for $LIBS
 444 AC_DEFUN([CF_BUILD_CC],[
 445 CF_ACVERSION_CHECK(2.52,,
 446         [AC_REQUIRE([CF_PROG_EXT])])
 447 if test "$cross_compiling" = yes ; then
 448
 449         # defaults that we might want to override
 450         : ${BUILD_CFLAGS:=''}
 451         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 452         : ${BUILD_LDFLAGS:=''}
 453         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 454         : ${BUILD_EXEEXT:='$x'}
 455         : ${BUILD_OBJEXT:='o'}
 456
 457         AC_ARG_WITH(build-cc,
 458                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 459                 [BUILD_CC="$withval"],
 460                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
 461         AC_MSG_CHECKING(for native build C compiler)
 462         AC_MSG_RESULT($BUILD_CC)
 463
 464         AC_MSG_CHECKING(for native build C preprocessor)
 465         AC_ARG_WITH(build-cpp,
 466                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 467                 [BUILD_CPP="$withval"],
 468                 [BUILD_CPP='${BUILD_CC} -E'])
 469         AC_MSG_RESULT($BUILD_CPP)
 470
 471         AC_MSG_CHECKING(for native build C flags)
 472         AC_ARG_WITH(build-cflags,
 473                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 474                 [BUILD_CFLAGS="$withval"])
 475         AC_MSG_RESULT($BUILD_CFLAGS)
 476
 477         AC_MSG_CHECKING(for native build C preprocessor-flags)
 478         AC_ARG_WITH(build-cppflags,
 479                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 480                 [BUILD_CPPFLAGS="$withval"])
 481         AC_MSG_RESULT($BUILD_CPPFLAGS)
 482
 483         AC_MSG_CHECKING(for native build linker-flags)
 484         AC_ARG_WITH(build-ldflags,
 485                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 486                 [BUILD_LDFLAGS="$withval"])
 487         AC_MSG_RESULT($BUILD_LDFLAGS)
 488
 489         AC_MSG_CHECKING(for native build linker-libraries)
 490         AC_ARG_WITH(build-libs,
 491                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 492                 [BUILD_LIBS="$withval"])
 493         AC_MSG_RESULT($BUILD_LIBS)
 494
 495         # this assumes we're on Unix.
 496         BUILD_EXEEXT=
 497         BUILD_OBJEXT=o
 498
 499         : ${BUILD_CC:='${CC}'}
 500
 501         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 502                 AC_MSG_ERROR([Cross-build requires two compilers.
 503 Use --with-build-cc to specify the native compiler.])
 504         fi
 505
 506 else
 507         : ${BUILD_CC:='${CC}'}
 508         : ${BUILD_CPP:='${CPP}'}
 509         : ${BUILD_CFLAGS:='${CFLAGS}'}
 510         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 511         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 512         : ${BUILD_LIBS:='${LIBS}'}
 513         : ${BUILD_EXEEXT:='$x'}
 514         : ${BUILD_OBJEXT:='o'}
 515 fi
 516
 517 AC_SUBST(BUILD_CC)
 518 AC_SUBST(BUILD_CPP)
 519 AC_SUBST(BUILD_CFLAGS)
 520 AC_SUBST(BUILD_CPPFLAGS)
 521 AC_SUBST(BUILD_LDFLAGS)
 522 AC_SUBST(BUILD_LIBS)
 523 AC_SUBST(BUILD_EXEEXT)
 524 AC_SUBST(BUILD_OBJEXT)
 525 ])dnl
 526 dnl ---------------------------------------------------------------------------
 527 dnl CF_CC_ENV_FLAGS version: 9 updated: 2018/07/29 18:03:26
 528 dnl ---------------
 529 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 530 dnl into CC.  This will not help with broken scripts that wrap the compiler
 531 dnl with options, but eliminates a more common category of user confusion.
 532 dnl
 533 dnl In particular, it addresses the problem of being able to run the C
 534 dnl preprocessor in a consistent manner.
 535 dnl
 536 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 537 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 538 dnl outweighs that limitation.
 539 AC_DEFUN([CF_CC_ENV_FLAGS],
 540 [
 541 # This should have been defined by AC_PROG_CC
 542 : ${CC:=cc}
 543
 544 AC_MSG_CHECKING(\$CFLAGS variable)
 545 case "x$CFLAGS" in
 546 (*-[[IUD]]*)
 547         AC_MSG_RESULT(broken)
 548         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
 549         cf_flags="$CFLAGS"
 550         CFLAGS=
 551         for cf_arg in $cf_flags
 552         do
 553                 CF_ADD_CFLAGS($cf_arg)
 554         done
 555         ;;
 556 (*)
 557         AC_MSG_RESULT(ok)
 558         ;;
 559 esac
 560
 561 AC_MSG_CHECKING(\$CC variable)
 562 case "$CC" in
 563 (*[[\ \ ]]-*)
 564         AC_MSG_RESULT(broken)
 565         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
 566         # humor him...
 567         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 568         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
 569         CC="$cf_prog"
 570         for cf_arg in $cf_flags
 571         do
 572                 case "x$cf_arg" in
 573                 (x-[[IUDfgOW]]*)
 574                         CF_ADD_CFLAGS($cf_arg)
 575                         ;;
 576                 (*)
 577                         CC="$CC $cf_arg"
 578                         ;;
 579                 esac
 580         done
 581         CF_VERBOSE(resulting CC: '$CC')
 582         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 583         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 584         ;;
 585 (*)
 586         AC_MSG_RESULT(ok)
 587         ;;
 588 esac
 589 ])dnl
 590 dnl ---------------------------------------------------------------------------
 591 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
 592 dnl ---------------
 593 dnl Determine the default configuration into which we'll install ncurses.  This
 594 dnl can be overridden by the user's command-line options.  There's two items to
 595 dnl look for:
 596 dnl     1. the prefix (e.g., /usr)
 597 dnl     2. the header files (e.g., /usr/include/ncurses)
 598 dnl We'll look for a previous installation of ncurses and use the same defaults.
 599 dnl
 600 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 601 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 602 dnl programs from a vendor's.
 603 AC_DEFUN([CF_CFG_DEFAULTS],
 604 [
 605 AC_MSG_CHECKING(for prefix)
 606 if test "x$prefix" = "xNONE" ; then
 607         case "$cf_cv_system_name" in
 608                 # non-vendor systems don't have a conflict
 609         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 610                 prefix=/usr
 611                 ;;
 612         (*)     prefix=$ac_default_prefix
 613                 ;;
 614         esac
 615 fi
 616 AC_MSG_RESULT($prefix)
 617
 618 if test "x$prefix" = "xNONE" ; then
 619 AC_MSG_CHECKING(for default include-directory)
 620 test -n "$verbose" && echo 1>&AC_FD_MSG
 621 for cf_symbol in \
 622         $includedir \
 623         $includedir/ncurses \
 624         $prefix/include \
 625         $prefix/include/ncurses \
 626         /usr/local/include \
 627         /usr/local/include/ncurses \
 628         /usr/include \
 629         /usr/include/ncurses
 630 do
 631         cf_dir=`eval echo $cf_symbol`
 632         if test -f $cf_dir/curses.h ; then
 633         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 634                 includedir="$cf_symbol"
 635                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 636                 break
 637         fi
 638         fi
 639         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 640 done
 641 AC_MSG_RESULT($includedir)
 642 fi
 643 ])dnl
 644 dnl ---------------------------------------------------------------------------
 645 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 646 dnl --------------
 647 dnl Check if we're accidentally using a cache from a different machine.
 648 dnl Derive the system name, as a check for reusing the autoconf cache.
 649 dnl
 650 dnl If we've packaged config.guess and config.sub, run that (since it does a
 651 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 652 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 653 dnl which is useful in cross-compiles.
 654 dnl
 655 dnl Note: we would use $ac_config_sub, but that is one of the places where
 656 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 657 AC_DEFUN([CF_CHECK_CACHE],
 658 [
 659 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 660         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 661         system_name="$host_os"
 662 else
 663         system_name="`(uname -s -r) 2>/dev/null`"
 664         if test -z "$system_name" ; then
 665                 system_name="`(hostname) 2>/dev/null`"
 666         fi
 667 fi
 668 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 669 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 670
 671 test -z "$system_name" && system_name="$cf_cv_system_name"
 672 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 673
 674 if test ".$system_name" != ".$cf_cv_system_name" ; then
 675         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 676         AC_MSG_ERROR("Please remove config.cache and try again.")
 677 fi
 678 ])dnl
 679 dnl ---------------------------------------------------------------------------
 680 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
 681 dnl -----------------
 682 dnl Check if the given compiler is really clang.  clang's C driver defines
 683 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
 684 dnl not ignore some gcc options.
 685 dnl
 686 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
 687 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
 688 dnl the wrappers for gcc and g++ warnings.
 689 dnl
 690 dnl $1 = GCC (default) or GXX
 691 dnl $2 = CLANG_COMPILER (default)
 692 dnl $3 = CFLAGS (default) or CXXFLAGS
 693 AC_DEFUN([CF_CLANG_COMPILER],[
 694 ifelse([$2],,CLANG_COMPILER,[$2])=no
 695
 696 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
 697         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
 698         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
 699         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
 700         AC_TRY_COMPILE([],[
 701 #ifdef __clang__
 702 #else
 703 make an error
 704 #endif
 705 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
 706 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
 707 ],[])
 708         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
 709         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
 710 fi
 711 ])
 712 dnl ---------------------------------------------------------------------------
 713 dnl CF_CURSES_HEADER version: 5 updated: 2015/04/23 20:35:30
 714 dnl ----------------
 715 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
 716 dnl variations of ncurses' installs.
 717 dnl
 718 dnl $1 = ncurses when looking for ncurses, or is empty
 719 AC_DEFUN([CF_CURSES_HEADER],[
 720 AC_CACHE_CHECK(if we have identified curses headers,cf_cv_ncurses_header,[
 721 cf_cv_ncurses_header=none
 722 for cf_header in \
 723         ncurses.h ifelse($1,,,[$1/ncurses.h]) \
 724         curses.h ifelse($1,,,[$1/curses.h]) ifelse($1,,[ncurses/ncurses.h ncurses/curses.h])
 725 do
 726 AC_TRY_COMPILE([#include <${cf_header}>],
 727         [initscr(); tgoto("?", 0,0)],
 728         [cf_cv_ncurses_header=$cf_header; break],[])
 729 done
 730 ])
 731
 732 if test "$cf_cv_ncurses_header" = none ; then
 733         AC_MSG_ERROR(No curses header-files found)
 734 fi
 735
 736 # cheat, to get the right #define's for HAVE_NCURSES_H, etc.
 737 AC_CHECK_HEADERS($cf_cv_ncurses_header)
 738 ])dnl
 739 dnl ---------------------------------------------------------------------------
 740 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
 741 dnl ----------
 742 dnl "dirname" is not portable, so we fake it with a shell script.
 743 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
 744 dnl ---------------------------------------------------------------------------
 745 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
 746 dnl ---------------
 747 dnl You can always use "make -n" to see the actual options, but it's hard to
 748 dnl pick out/analyze warning messages when the compile-line is long.
 749 dnl
 750 dnl Sets:
 751 dnl     ECHO_LT - symbol to control if libtool is verbose
 752 dnl     ECHO_LD - symbol to prefix "cc -o" lines
 753 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
 754 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
 755 dnl     ECHO_CC - symbol to put before any "cc" line
 756 dnl
 757 AC_DEFUN([CF_DISABLE_ECHO],[
 758 AC_MSG_CHECKING(if you want to see long compiling messages)
 759 CF_ARG_DISABLE(echo,
 760         [  --disable-echo          do not display "compiling" commands],
 761         [
 762         ECHO_LT='--silent'
 763         ECHO_LD='@echo linking [$]@;'
 764         RULE_CC='@echo compiling [$]<'
 765         SHOW_CC='@echo compiling [$]@'
 766         ECHO_CC='@'
 767 ],[
 768         ECHO_LT=''
 769         ECHO_LD=''
 770         RULE_CC=''
 771         SHOW_CC=''
 772         ECHO_CC=''
 773 ])
 774 AC_MSG_RESULT($enableval)
 775 AC_SUBST(ECHO_LT)
 776 AC_SUBST(ECHO_LD)
 777 AC_SUBST(RULE_CC)
 778 AC_SUBST(SHOW_CC)
 779 AC_SUBST(ECHO_CC)
 780 ])dnl
 781 dnl ---------------------------------------------------------------------------
 782 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
 783 dnl ------------------------
 784 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
 785 AC_MSG_CHECKING(if we want to use GNAT projects)
 786 CF_ARG_DISABLE(gnat-projects,
 787         [  --disable-gnat-projects test: disable GNAT projects even if usable],
 788         [enable_gnat_projects=no],
 789         [enable_gnat_projects=yes])
 790 AC_MSG_RESULT($enable_gnat_projects)
 791 ])dnl
 792 dnl ---------------------------------------------------------------------------
 793 dnl CF_FIND_LIBRARY version: 9 updated: 2008/03/23 14:48:54
 794 dnl ---------------
 795 dnl Look for a non-standard library, given parameters for AC_TRY_LINK.  We
 796 dnl prefer a standard location, and use -L options only if we do not find the
 797 dnl library in the standard library location(s).
 798 dnl     $1 = library name
 799 dnl     $2 = library class, usually the same as library name
 800 dnl     $3 = includes
 801 dnl     $4 = code fragment to compile/link
 802 dnl     $5 = corresponding function-name
 803 dnl     $6 = flag, nonnull if failure should not cause an error-exit
 804 dnl
 805 dnl Sets the variable "$cf_libdir" as a side-effect, so we can see if we had
 806 dnl to use a -L option.
 807 AC_DEFUN([CF_FIND_LIBRARY],
 808 [
 809         eval 'cf_cv_have_lib_'$1'=no'
 810         cf_libdir=""
 811         AC_CHECK_FUNC($5,
 812                 eval 'cf_cv_have_lib_'$1'=yes',[
 813                 cf_save_LIBS="$LIBS"
 814                 AC_MSG_CHECKING(for $5 in -l$1)
 815                 LIBS="-l$1 $LIBS"
 816                 AC_TRY_LINK([$3],[$4],
 817                         [AC_MSG_RESULT(yes)
 818                          eval 'cf_cv_have_lib_'$1'=yes'
 819                         ],
 820                         [AC_MSG_RESULT(no)
 821                         CF_LIBRARY_PATH(cf_search,$2)
 822                         for cf_libdir in $cf_search
 823                         do
 824                                 AC_MSG_CHECKING(for -l$1 in $cf_libdir)
 825                                 LIBS="-L$cf_libdir -l$1 $cf_save_LIBS"
 826                                 AC_TRY_LINK([$3],[$4],
 827                                         [AC_MSG_RESULT(yes)
 828                                          eval 'cf_cv_have_lib_'$1'=yes'
 829                                          break],
 830                                         [AC_MSG_RESULT(no)
 831                                          LIBS="$cf_save_LIBS"])
 832                         done
 833                         ])
 834                 ])
 835 eval 'cf_found_library=[$]cf_cv_have_lib_'$1
 836 ifelse($6,,[
 837 if test $cf_found_library = no ; then
 838         AC_MSG_ERROR(Cannot link $1 library)
 839 fi
 840 ])
 841 ])dnl
 842 dnl ---------------------------------------------------------------------------
 843 dnl CF_FIND_LINKAGE version: 21 updated: 2018/06/20 20:23:13
 844 dnl ---------------
 845 dnl Find a library (specifically the linkage used in the code fragment),
 846 dnl searching for it if it is not already in the library path.
 847 dnl See also CF_ADD_SEARCHPATH.
 848 dnl
 849 dnl Parameters (4-on are optional):
 850 dnl     $1 = headers for library entrypoint
 851 dnl     $2 = code fragment for library entrypoint
 852 dnl     $3 = the library name without the "-l" option or ".so" suffix.
 853 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
 854 dnl     $5 = action to perform if not successful
 855 dnl     $6 = module name, if not the same as the library name
 856 dnl     $7 = extra libraries
 857 dnl
 858 dnl Sets these variables:
 859 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
 860 dnl     $cf_cv_header_path_$3 - include-directory if needed
 861 dnl     $cf_cv_library_path_$3 - library-directory if needed
 862 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
 863 AC_DEFUN([CF_FIND_LINKAGE],[
 864
 865 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
 866 # will be set on completion of the AC_TRY_LINK below.
 867 cf_cv_header_path_$3=
 868 cf_cv_library_path_$3=
 869
 870 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
 871
 872 cf_save_LIBS="$LIBS"
 873
 874 AC_TRY_LINK([$1],[$2],[
 875         cf_cv_find_linkage_$3=yes
 876         cf_cv_header_path_$3=/usr/include
 877         cf_cv_library_path_$3=/usr/lib
 878 ],[
 879
 880 LIBS="-l$3 $7 $cf_save_LIBS"
 881
 882 AC_TRY_LINK([$1],[$2],[
 883         cf_cv_find_linkage_$3=yes
 884         cf_cv_header_path_$3=/usr/include
 885         cf_cv_library_path_$3=/usr/lib
 886         cf_cv_library_file_$3="-l$3"
 887 ],[
 888         cf_cv_find_linkage_$3=no
 889         LIBS="$cf_save_LIBS"
 890
 891         CF_VERBOSE(find linkage for $3 library)
 892         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
 893
 894         cf_save_CPPFLAGS="$CPPFLAGS"
 895         cf_test_CPPFLAGS="$CPPFLAGS"
 896
 897         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
 898         for cf_cv_header_path_$3 in $cf_search
 899         do
 900                 if test -d $cf_cv_header_path_$3 ; then
 901                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
 902                         CPPFLAGS="$cf_save_CPPFLAGS"
 903                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
 904                         AC_TRY_COMPILE([$1],[$2],[
 905                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
 906                                 cf_cv_find_linkage_$3=maybe
 907                                 cf_test_CPPFLAGS="$CPPFLAGS"
 908                                 break],[
 909                                 CPPFLAGS="$cf_save_CPPFLAGS"
 910                                 ])
 911                 fi
 912         done
 913
 914         if test "$cf_cv_find_linkage_$3" = maybe ; then
 915
 916                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
 917
 918                 cf_save_LIBS="$LIBS"
 919                 cf_save_LDFLAGS="$LDFLAGS"
 920
 921                 ifelse([$6],,,[
 922                 CPPFLAGS="$cf_test_CPPFLAGS"
 923                 LIBS="-l$3 $7 $cf_save_LIBS"
 924                 AC_TRY_LINK([$1],[$2],[
 925                         CF_VERBOSE(... found $3 library in system)
 926                         cf_cv_find_linkage_$3=yes])
 927                         CPPFLAGS="$cf_save_CPPFLAGS"
 928                         LIBS="$cf_save_LIBS"
 929                         ])
 930
 931                 if test "$cf_cv_find_linkage_$3" != yes ; then
 932                         CF_LIBRARY_PATH(cf_search,$3)
 933                         for cf_cv_library_path_$3 in $cf_search
 934                         do
 935                                 if test -d $cf_cv_library_path_$3 ; then
 936                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
 937                                         CPPFLAGS="$cf_test_CPPFLAGS"
 938                                         LIBS="-l$3 $7 $cf_save_LIBS"
 939                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
 940                                         AC_TRY_LINK([$1],[$2],[
 941                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
 942                                         cf_cv_find_linkage_$3=yes
 943                                         cf_cv_library_file_$3="-l$3"
 944                                         break],[
 945                                         CPPFLAGS="$cf_save_CPPFLAGS"
 946                                         LIBS="$cf_save_LIBS"
 947                                         LDFLAGS="$cf_save_LDFLAGS"
 948                                         ])
 949                                 fi
 950                         done
 951                         CPPFLAGS="$cf_save_CPPFLAGS"
 952                         LDFLAGS="$cf_save_LDFLAGS"
 953                 fi
 954
 955         else
 956                 cf_cv_find_linkage_$3=no
 957         fi
 958         ],$7)
 959 ])
 960
 961 LIBS="$cf_save_LIBS"
 962
 963 if test "$cf_cv_find_linkage_$3" = yes ; then
 964 ifelse([$4],,[
 965         CF_ADD_INCDIR($cf_cv_header_path_$3)
 966         CF_ADD_LIBDIR($cf_cv_library_path_$3)
 967         CF_ADD_LIB($3)
 968 ],[$4])
 969 else
 970 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
 971 fi
 972 ])dnl
 973 dnl ---------------------------------------------------------------------------
 974 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
 975 dnl -----------------
 976 dnl make ADAFLAGS consistent with CFLAGS
 977 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
 978         AC_MSG_CHECKING(optimization options for ADAFLAGS)
 979         case "$CFLAGS" in
 980         (*-g*)
 981                 CF_ADD_ADAFLAGS(-g)
 982                 ;;
 983         esac
 984         case "$CFLAGS" in
 985         (*-O*)
 986                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
 987                 CF_ADD_ADAFLAGS($cf_O_flag)
 988                 ;;
 989         esac
 990         AC_MSG_RESULT($ADAFLAGS)
 991 ])dnl
 992 dnl ---------------------------------------------------------------------------
 993 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
 994 dnl -----------------
 995 dnl Test for availability of useful gcc __attribute__ directives to quiet
 996 dnl compiler warnings.  Though useful, not all are supported -- and contrary
 997 dnl to documentation, unrecognized directives cause older compilers to barf.
 998 AC_DEFUN([CF_GCC_ATTRIBUTES],
 999 [
1000 if test "$GCC" = yes
1001 then
1002 cat > conftest.i <<EOF
1003 #ifndef GCC_PRINTF
1004 #define GCC_PRINTF 0
1005 #endif
1006 #ifndef GCC_SCANF
1007 #define GCC_SCANF 0
1008 #endif
1009 #ifndef GCC_NORETURN
1010 #define GCC_NORETURN /* nothing */
1011 #endif
1012 #ifndef GCC_UNUSED
1013 #define GCC_UNUSED /* nothing */
1014 #endif
1015 EOF
1016 if test "$GCC" = yes
1017 then
1018         AC_CHECKING([for $CC __attribute__ directives])
1019 cat > conftest.$ac_ext <<EOF
1020 #line __oline__ "${as_me:-configure}"
1021 #include "confdefs.h"
1022 #include "conftest.h"
1023 #include "conftest.i"
1024 #if     GCC_PRINTF
1025 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1026 #else
1027 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1028 #endif
1029 #if     GCC_SCANF
1030 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1031 #else
1032 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1033 #endif
1034 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1035 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1036 extern void foo(void) GCC_NORETURN;
1037 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1038 EOF
1039         cf_printf_attribute=no
1040         cf_scanf_attribute=no
1041         for cf_attribute in scanf printf unused noreturn
1042         do
1043                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1044                 cf_directive="__attribute__(($cf_attribute))"
1045                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1046
1047                 case $cf_attribute in
1048                 (printf)
1049                         cf_printf_attribute=yes
1050                         cat >conftest.h <<EOF
1051 #define GCC_$cf_ATTRIBUTE 1
1052 EOF
1053                         ;;
1054                 (scanf)
1055                         cf_scanf_attribute=yes
1056                         cat >conftest.h <<EOF
1057 #define GCC_$cf_ATTRIBUTE 1
1058 EOF
1059                         ;;
1060                 (*)
1061                         cat >conftest.h <<EOF
1062 #define GCC_$cf_ATTRIBUTE $cf_directive
1063 EOF
1064                         ;;
1065                 esac
1066
1067                 if AC_TRY_EVAL(ac_compile); then
1068                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1069                         cat conftest.h >>confdefs.h
1070                         case $cf_attribute in
1071                         (noreturn)
1072                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1073                                 ;;
1074                         (printf)
1075                                 cf_value='/* nothing */'
1076                                 if test "$cf_printf_attribute" != no ; then
1077                                         cf_value='__attribute__((format(printf,fmt,var)))'
1078                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1079                                 fi
1080                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1081                                 ;;
1082                         (scanf)
1083                                 cf_value='/* nothing */'
1084                                 if test "$cf_scanf_attribute" != no ; then
1085                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1086                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1087                                 fi
1088                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1089                                 ;;
1090                         (unused)
1091                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1092                                 ;;
1093                         esac
1094                 fi
1095         done
1096 else
1097         fgrep define conftest.i >>confdefs.h
1098 fi
1099 rm -rf conftest*
1100 fi
1101 ])dnl
1102 dnl ---------------------------------------------------------------------------
1103 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
1104 dnl --------------
1105 dnl Find version of gcc
1106 AC_DEFUN([CF_GCC_VERSION],[
1107 AC_REQUIRE([AC_PROG_CC])
1108 GCC_VERSION=none
1109 if test "$GCC" = yes ; then
1110         AC_MSG_CHECKING(version of $CC)
1111         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1112         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1113         AC_MSG_RESULT($GCC_VERSION)
1114 fi
1115 ])dnl
1116 dnl ---------------------------------------------------------------------------
1117 dnl CF_GCC_WARNINGS version: 33 updated: 2018/06/20 20:23:13
1118 dnl ---------------
1119 dnl Check if the compiler supports useful warning options.  There's a few that
1120 dnl we don't use, simply because they're too noisy:
1121 dnl
1122 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1123 dnl     -Wredundant-decls (system headers make this too noisy)
1124 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1125 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1126 dnl             is enabled for ncurses using "--enable-const".
1127 dnl     -pedantic
1128 dnl
1129 dnl Parameter:
1130 dnl     $1 is an optional list of gcc warning flags that a particular
1131 dnl             application might want to use, e.g., "no-unused" for
1132 dnl             -Wno-unused
1133 dnl Special:
1134 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1135 dnl
1136 AC_DEFUN([CF_GCC_WARNINGS],
1137 [
1138 AC_REQUIRE([CF_GCC_VERSION])
1139 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1140 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1141
1142 cat > conftest.$ac_ext <<EOF
1143 #line __oline__ "${as_me:-configure}"
1144 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1145 EOF
1146
1147 if test "$INTEL_COMPILER" = yes
1148 then
1149 # The "-wdXXX" options suppress warnings:
1150 # remark #1419: external declaration in primary source file
1151 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1152 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1153 # remark #193: zero used for undefined preprocessing identifier
1154 # remark #593: variable "curs_sb_left_arrow" was set but never used
1155 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1156 # remark #869: parameter "tw" was never referenced
1157 # remark #981: operands are evaluated in unspecified order
1158 # warning #279: controlling expression is constant
1159
1160         AC_CHECKING([for $CC warning options])
1161         cf_save_CFLAGS="$CFLAGS"
1162         EXTRA_CFLAGS="-Wall"
1163         for cf_opt in \
1164                 wd1419 \
1165                 wd1683 \
1166                 wd1684 \
1167                 wd193 \
1168                 wd593 \
1169                 wd279 \
1170                 wd810 \
1171                 wd869 \
1172                 wd981
1173         do
1174                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1175                 if AC_TRY_EVAL(ac_compile); then
1176                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1177                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1178                 fi
1179         done
1180         CFLAGS="$cf_save_CFLAGS"
1181
1182 elif test "$GCC" = yes
1183 then
1184         AC_CHECKING([for $CC warning options])
1185         cf_save_CFLAGS="$CFLAGS"
1186         EXTRA_CFLAGS=
1187         cf_warn_CONST=""
1188         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1189         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
1190         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
1191         for cf_opt in W Wall \
1192                 Wbad-function-cast \
1193                 Wcast-align \
1194                 Wcast-qual \
1195                 Wdeclaration-after-statement \
1196                 Wextra \
1197                 Winline \
1198                 Wmissing-declarations \
1199                 Wmissing-prototypes \
1200                 Wnested-externs \
1201                 Wpointer-arith \
1202                 Wshadow \
1203                 Wstrict-prototypes \
1204                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
1205         do
1206                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1207                 if AC_TRY_EVAL(ac_compile); then
1208                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1209                         case $cf_opt in
1210                         (Wcast-qual)
1211                                 CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
1212                                 ;;
1213                         (Winline)
1214                                 case $GCC_VERSION in
1215                                 ([[34]].*)
1216                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1217                                         continue;;
1218                                 esac
1219                                 ;;
1220                         (Wpointer-arith)
1221                                 case $GCC_VERSION in
1222                                 ([[12]].*)
1223                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1224                                         continue;;
1225                                 esac
1226                                 ;;
1227                         esac
1228                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1229                 fi
1230         done
1231         CFLAGS="$cf_save_CFLAGS"
1232 fi
1233 rm -rf conftest*
1234
1235 AC_SUBST(EXTRA_CFLAGS)
1236 ])dnl
1237 dnl ---------------------------------------------------------------------------
1238 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
1239 dnl -----------------
1240 AC_DEFUN([CF_GNATPREP_OPT_T],[
1241 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
1242 cf_cv_gnatprep_opt_t=no
1243 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
1244 ])
1245 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
1246 AC_SUBST(GNATPREP_OPTS)
1247 ])dnl
1248 dnl ---------------------------------------------------------------------------
1249 dnl CF_GNAT_GENERICS version: 3 updated: 2015/04/17 21:13:04
1250 dnl ----------------
1251 AC_DEFUN([CF_GNAT_GENERICS],
1252 [
1253 AC_REQUIRE([CF_GNAT_VERSION])
1254
1255 AC_MSG_CHECKING(if GNAT supports generics)
1256 case $cf_gnat_version in
1257 (3.[[1-9]]*|[[4-9]].*)
1258         cf_gnat_generics=yes
1259         ;;
1260 (*)
1261         cf_gnat_generics=no
1262         ;;
1263 esac
1264 AC_MSG_RESULT($cf_gnat_generics)
1265
1266 if test "$cf_gnat_generics" = yes
1267 then
1268         cf_compile_generics=generics
1269         cf_generic_objects="\${GENOBJS}"
1270 else
1271         cf_compile_generics=
1272         cf_generic_objects=
1273 fi
1274
1275 AC_SUBST(cf_compile_generics)
1276 AC_SUBST(cf_generic_objects)
1277 ])dnl
1278 dnl ---------------------------------------------------------------------------
1279 dnl CF_GNAT_PROJECTS version: 9 updated: 2018/01/14 15:46:09
1280 dnl ----------------
1281 dnl GNAT projects are configured with ".gpr" project files.
1282 dnl GNAT libraries are a further development, using the project feature.
1283 AC_DEFUN([CF_GNAT_PROJECTS],
1284 [
1285 AC_REQUIRE([CF_GNAT_VERSION])
1286 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
1287
1288 cf_gnat_libraries=no
1289 cf_gnat_projects=no
1290
1291 if test "$enable_gnat_projects" != no ; then
1292 AC_MSG_CHECKING(if GNAT supports project files)
1293 case $cf_gnat_version in
1294 (3.[[0-9]]*)
1295         ;;
1296 (*)
1297         case $cf_cv_system_name in
1298         (cygwin*|msys*)
1299                 ;;
1300         (*)
1301                 rm -rf conftest* *~conftest*
1302                 if mkdir conftest.src conftest.bin conftest.lib
1303                 then
1304                         cd conftest.src
1305                         rm -rf conftest* *~conftest*
1306                         cat >>library.gpr <<CF_EOF
1307 project Library is
1308   Kind := External ("LIB_KIND");
1309   for Library_Name use "ConfTest";
1310   for Object_Dir use ".";
1311   for Library_ALI_Dir use External("LIBRARY_DIR");
1312   for Library_Version use External ("SONAME");
1313   for Library_Kind use Kind;
1314   for Library_Dir use External("BUILD_DIR");
1315   Source_Dir := External ("SOURCE_DIR");
1316   for Source_Dirs use (Source_Dir);
1317 end Library;
1318 CF_EOF
1319                         cat >>confpackage.ads <<CF_EOF
1320 package ConfPackage is
1321    procedure conftest;
1322 end ConfPackage;
1323 CF_EOF
1324                         cat >>confpackage.adb <<CF_EOF
1325 with Text_IO;
1326 package body ConfPackage is
1327    procedure conftest is
1328    begin
1329       Text_IO.Put ("Hello World");
1330       Text_IO.New_Line;
1331    end conftest;
1332 end ConfPackage;
1333 CF_EOF
1334                         if ( $cf_ada_make $ADAFLAGS \
1335                                         -Plibrary.gpr \
1336                                         -XBUILD_DIR=`cd ../conftest.bin;pwd` \
1337                                         -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
1338                                         -XSOURCE_DIR=`pwd` \
1339                                         -XSONAME=libConfTest.so.1 \
1340                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
1341                                 cf_gnat_projects=yes
1342                         fi
1343                         cd ..
1344                 fi
1345                 if test -f conftest.lib/confpackage.ali
1346                 then
1347                         cf_gnat_libraries=yes
1348                 fi
1349                 rm -rf conftest* *~conftest*
1350                 ;;
1351         esac
1352         ;;
1353 esac
1354 AC_MSG_RESULT($cf_gnat_projects)
1355 fi # enable_gnat_projects
1356
1357 if test $cf_gnat_projects = yes
1358 then
1359         AC_MSG_CHECKING(if GNAT supports libraries)
1360         AC_MSG_RESULT($cf_gnat_libraries)
1361 fi
1362
1363 if test "$cf_gnat_projects" = yes
1364 then
1365         USE_OLD_MAKERULES="#"
1366         USE_GNAT_PROJECTS=""
1367 else
1368         USE_OLD_MAKERULES=""
1369         USE_GNAT_PROJECTS="#"
1370 fi
1371
1372 if test "$cf_gnat_libraries" = yes
1373 then
1374         USE_GNAT_LIBRARIES=""
1375 else
1376         USE_GNAT_LIBRARIES="#"
1377 fi
1378
1379 AC_SUBST(USE_OLD_MAKERULES)
1380 AC_SUBST(USE_GNAT_PROJECTS)
1381 AC_SUBST(USE_GNAT_LIBRARIES)
1382 ])dnl
1383 dnl ---------------------------------------------------------------------------
1384 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
1385 dnl --------------
1386 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
1387 dnl is noted that gnat may compile a tasking unit even for configurations which
1388 dnl fail at runtime.
1389 AC_DEFUN([CF_GNAT_SIGINT],[
1390 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
1391 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
1392
1393 package ConfTest is
1394
1395    pragma Warnings (Off);  --  the next pragma exists since 3.11p
1396    pragma Unreserve_All_Interrupts;
1397    pragma Warnings (On);
1398
1399    protected Process is
1400       procedure Stop;
1401       function Continue return Boolean;
1402       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
1403    private
1404       Done : Boolean := False;
1405    end Process;
1406
1407 end ConfTest;],
1408 [package body ConfTest is
1409    protected body Process is
1410       procedure Stop is
1411       begin
1412          Done := True;
1413       end Stop;
1414       function Continue return Boolean is
1415       begin
1416          return not Done;
1417       end Continue;
1418    end Process;
1419 end ConfTest;],
1420         [cf_cv_gnat_sigint=yes],
1421         [cf_cv_gnat_sigint=no])])
1422
1423 if test $cf_cv_gnat_sigint = yes ; then
1424         USE_GNAT_SIGINT=""
1425 else
1426         USE_GNAT_SIGINT="#"
1427 fi
1428 AC_SUBST(USE_GNAT_SIGINT)
1429 ])dnl
1430 dnl ---------------------------------------------------------------------------
1431 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
1432 dnl ----------------
1433 dnl Verify that a test program compiles/links with GNAT.
1434 dnl $cf_ada_make is set to the program that compiles/links
1435 dnl $ADAFLAGS may be set to the GNAT flags.
1436 dnl
1437 dnl $1 is the text of the spec
1438 dnl $2 is the text of the body
1439 dnl $3 is the shell command to execute if successful
1440 dnl $4 is the shell command to execute if not successful
1441 AC_DEFUN([CF_GNAT_TRY_LINK],
1442 [
1443 rm -rf conftest* *~conftest*
1444 cat >>conftest.ads <<CF_EOF
1445 $1
1446 CF_EOF
1447 cat >>conftest.adb <<CF_EOF
1448 $2
1449 CF_EOF
1450 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1451 ifelse($3,,      :,[      $3])
1452 ifelse($4,,,[else
1453    $4])
1454 fi
1455 rm -rf conftest* *~conftest*
1456 ])dnl
1457 dnl ---------------------------------------------------------------------------
1458 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
1459 dnl ---------------
1460 dnl Verify that a test program compiles and runs with GNAT
1461 dnl $cf_ada_make is set to the program that compiles/links
1462 dnl $ADAFLAGS may be set to the GNAT flags.
1463 dnl
1464 dnl $1 is the text of the spec
1465 dnl $2 is the text of the body
1466 dnl $3 is the shell command to execute if successful
1467 dnl $4 is the shell command to execute if not successful
1468 AC_DEFUN([CF_GNAT_TRY_RUN],
1469 [
1470 rm -rf conftest* *~conftest*
1471 cat >>conftest.ads <<CF_EOF
1472 $1
1473 CF_EOF
1474 cat >>conftest.adb <<CF_EOF
1475 $2
1476 CF_EOF
1477 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
1478    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
1479 ifelse($3,,      :,[      $3])
1480 ifelse($4,,,[   else
1481       $4])
1482    fi
1483 ifelse($4,,,[else
1484    $4])
1485 fi
1486 rm -rf conftest* *~conftest*
1487 ])dnl
1488 dnl ---------------------------------------------------------------------------
1489 dnl CF_GNAT_VERSION version: 20 updated: 2015/04/18 08:56:57
1490 dnl ---------------
1491 dnl Verify version of GNAT.
1492 AC_DEFUN([CF_GNAT_VERSION],
1493 [
1494 AC_MSG_CHECKING(for gnat version)
1495 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
1496         grep '[[0-9]].[[0-9]][[0-9]]*' |\
1497         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
1498 AC_MSG_RESULT($cf_gnat_version)
1499
1500 case $cf_gnat_version in
1501 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
1502         cf_cv_prog_gnat_correct=yes
1503         ;;
1504 (*)
1505         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1506         cf_cv_prog_gnat_correct=no
1507         ;;
1508 esac
1509 ])
1510 dnl ---------------------------------------------------------------------------
1511 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
1512 dnl -------------
1513 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
1514 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
1515 dnl (or misfeature) of glibc2, which breaks portability of many applications,
1516 dnl since it is interwoven with GNU extensions.
1517 dnl
1518 dnl Well, yes we could work around it...
1519 dnl
1520 dnl Parameters:
1521 dnl     $1 is the nominal value for _XOPEN_SOURCE
1522 AC_DEFUN([CF_GNU_SOURCE],
1523 [
1524 cf_gnu_xopen_source=ifelse($1,,500,$1)
1525
1526 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
1527 AC_TRY_COMPILE([#include <sys/types.h>],[
1528         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
1529                 return 0;
1530         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
1531                 return 0;
1532         #else
1533         #       error not GNU C library
1534         #endif],
1535         [cf_cv_gnu_library=yes],
1536         [cf_cv_gnu_library=no])
1537 ])
1538
1539 if test x$cf_cv_gnu_library = xyes; then
1540
1541         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
1542         # was changed to help a little.  newlib incorporated the change about 4
1543         # years later.
1544         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
1545                 cf_save="$CPPFLAGS"
1546                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
1547                 AC_TRY_COMPILE([#include <sys/types.h>],[
1548                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
1549                                 return 0;
1550                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
1551                                 return 0;
1552                         #else
1553                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
1554                         #endif],
1555                         [cf_cv_gnu_library_219=yes],
1556                         [cf_cv_gnu_library_219=no])
1557                 CPPFLAGS="$cf_save"
1558         ])
1559
1560         if test "x$cf_cv_gnu_library_219" = xyes; then
1561                 cf_save="$CPPFLAGS"
1562                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
1563                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
1564                         AC_TRY_COMPILE([
1565                                 #include <limits.h>
1566                                 #include <sys/types.h>
1567                                 ],[
1568                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
1569                                         return 0;
1570                                 #else
1571                                 #       error GNU C library is too old
1572                                 #endif],
1573                                 [cf_cv_gnu_dftsrc_219=yes],
1574                                 [cf_cv_gnu_dftsrc_219=no])
1575                         ])
1576                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
1577         else
1578                 cf_cv_gnu_dftsrc_219=maybe
1579         fi
1580
1581         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
1582
1583                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
1584                 AC_TRY_COMPILE([#include <sys/types.h>],[
1585                         #ifndef _XOPEN_SOURCE
1586                         #error  expected _XOPEN_SOURCE to be defined
1587                         #endif],
1588                         [cf_cv_gnu_source=no],
1589                         [cf_save="$CPPFLAGS"
1590                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
1591                          AC_TRY_COMPILE([#include <sys/types.h>],[
1592                                 #ifdef _XOPEN_SOURCE
1593                                 #error  expected _XOPEN_SOURCE to be undefined
1594                                 #endif],
1595                                 [cf_cv_gnu_source=no],
1596                                 [cf_cv_gnu_source=yes])
1597                         CPPFLAGS="$cf_save"
1598                         ])
1599                 ])
1600
1601                 if test "$cf_cv_gnu_source" = yes
1602                 then
1603                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
1604                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
1605                         AC_TRY_COMPILE([#include <sys/types.h>],[
1606                                 #ifdef _DEFAULT_SOURCE
1607                                 #error  expected _DEFAULT_SOURCE to be undefined
1608                                 #endif],
1609                                 [cf_cv_default_source=no],
1610                                 [cf_cv_default_source=yes])
1611                         ])
1612                         if test "$cf_cv_default_source" = yes
1613                         then
1614                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
1615                         fi
1616                 fi
1617         fi
1618
1619 fi
1620 ])dnl
1621 dnl ---------------------------------------------------------------------------
1622 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
1623 dnl --------------
1624 dnl Construct a search-list of directories for a nonstandard header-file
1625 dnl
1626 dnl Parameters
1627 dnl     $1 = the variable to return as result
1628 dnl     $2 = the package name
1629 AC_DEFUN([CF_HEADER_PATH],
1630 [
1631 $1=
1632
1633 # collect the current set of include-directories from compiler flags
1634 cf_header_path_list=""
1635 if test -n "${CFLAGS}${CPPFLAGS}" ; then
1636         for cf_header_path in $CPPFLAGS $CFLAGS
1637         do
1638                 case $cf_header_path in
1639                 (-I*)
1640                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
1641                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
1642                         cf_header_path_list="$cf_header_path_list [$]$1"
1643                         ;;
1644                 esac
1645         done
1646 fi
1647
1648 # add the variations for the package we are looking for
1649 CF_SUBDIR_PATH($1,$2,include)
1650
1651 test "$includedir" != NONE && \
1652 test "$includedir" != "/usr/include" && \
1653 test -d "$includedir" && {
1654         test -d $includedir &&    $1="[$]$1 $includedir"
1655         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
1656 }
1657
1658 test "$oldincludedir" != NONE && \
1659 test "$oldincludedir" != "/usr/include" && \
1660 test -d "$oldincludedir" && {
1661         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
1662         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
1663 }
1664
1665 $1="[$]$1 $cf_header_path_list"
1666 ])dnl
1667 dnl ---------------------------------------------------------------------------
1668 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
1669 dnl ---------------
1670 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
1671 AC_DEFUN([CF_HELP_MESSAGE],
1672 [AC_DIVERT_HELP([$1])dnl
1673 ])dnl
1674 dnl ---------------------------------------------------------------------------
1675 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
1676 dnl ---------------
1677 dnl Construct the list of include-options according to whether we're building
1678 dnl in the source directory or using '--srcdir=DIR' option.
1679 AC_DEFUN([CF_INCLUDE_DIRS],
1680 [
1681 if test "$srcdir" != "."; then
1682         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
1683 fi
1684 CPPFLAGS="-I../include $CPPFLAGS"
1685 if test "$srcdir" != "."; then
1686         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
1687 fi
1688 CPPFLAGS="-I. $CPPFLAGS"
1689 AC_SUBST(CPPFLAGS)
1690 ])dnl
1691 dnl ---------------------------------------------------------------------------
1692 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
1693 dnl ---------------
1694 dnl prompt for/fill-in useful install-program options
1695 AC_DEFUN([CF_INSTALL_OPTS],
1696 [
1697 CF_INSTALL_OPT_S
1698 CF_INSTALL_OPT_P
1699 CF_INSTALL_OPT_O
1700 ])dnl
1701 dnl ---------------------------------------------------------------------------
1702 dnl CF_INSTALL_OPT_O version: 2 updated: 2015/05/15 19:45:35
1703 dnl ----------------
1704 dnl Almost all "install" programs default to the current user's ownership.
1705 dnl Almost - MINIX is an exception.
1706 AC_DEFUN([CF_INSTALL_OPT_O],
1707 [
1708 AC_MSG_CHECKING(if install needs to be told about ownership)
1709 case `$ac_config_guess` in
1710 (*minix)
1711         with_install_o=yes
1712         ;;
1713 (*)
1714         with_install_o=no
1715         ;;
1716 esac
1717
1718 AC_MSG_RESULT($with_install_o)
1719 if test "x$with_install_o" = xyes
1720 then
1721         INSTALL_OPT_O=`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`
1722 else
1723         INSTALL_OPT_O=
1724 fi
1725
1726 AC_SUBST(INSTALL_OPT_O)
1727 ])dnl
1728 dnl ---------------------------------------------------------------------------
1729 dnl CF_INSTALL_OPT_P version: 1 updated: 2018/08/18 12:19:21
1730 dnl ----------------
1731 dnl Some install-programs accept a "-p" option to preserve file modification
1732 dnl timestamps.  That can be useful as an install option, as well as a way to
1733 dnl avoid the need for ranlib after copying a static archive.
1734 AC_DEFUN([CF_INSTALL_OPT_P],
1735 [
1736 : ${INSTALL:=install}
1737 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
1738         rm -rf conftest*
1739         date >conftest.in
1740         mkdir conftest.out
1741         sleep 3
1742         if $INSTALL -p conftest.in conftest.out 2>/dev/null
1743         then
1744                 if test -f conftest.out/conftest.in
1745                 then
1746                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
1747                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
1748                         if test -s conftest.err
1749                         then
1750                                 cf_cv_install_p=no
1751                         else
1752                                 cf_cv_install_p=yes
1753                         fi
1754                 else
1755                         cf_cv_install_p=no
1756                 fi
1757         else
1758                 cf_cv_install_p=no
1759         fi
1760         rm -rf conftest*
1761 ])
1762 ])dnl
1763 dnl ---------------------------------------------------------------------------
1764 dnl CF_INSTALL_OPT_S version: 2 updated: 2018/08/18 12:19:21
1765 dnl ----------------
1766 dnl By default, we should strip executables which are installed, but leave the
1767 dnl ability to suppress that for unit-testing.
1768 AC_DEFUN([CF_INSTALL_OPT_S],
1769 [
1770 AC_MSG_CHECKING(if you want to install stripped executables)
1771 CF_ARG_DISABLE(stripping,
1772         [  --disable-stripping     do not strip (debug info) installed executables],
1773         [with_stripping=no],
1774         [with_stripping=yes])
1775 AC_MSG_RESULT($with_stripping)
1776
1777 if test "$with_stripping" = yes
1778 then
1779         INSTALL_OPT_S="-s"
1780 else
1781         INSTALL_OPT_S=
1782 fi
1783 AC_SUBST(INSTALL_OPT_S)
1784 ])dnl
1785 dnl ---------------------------------------------------------------------------
1786 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
1787 dnl -----------------
1788 dnl Check if the given compiler is really the Intel compiler for Linux.  It
1789 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
1790 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
1791 dnl
1792 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1793 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1794 dnl the wrappers for gcc and g++ warnings.
1795 dnl
1796 dnl $1 = GCC (default) or GXX
1797 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
1798 dnl $3 = CFLAGS (default) or CXXFLAGS
1799 AC_DEFUN([CF_INTEL_COMPILER],[
1800 AC_REQUIRE([AC_CANONICAL_HOST])
1801 ifelse([$2],,INTEL_COMPILER,[$2])=no
1802
1803 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1804         case $host_os in
1805         (linux*|gnu*)
1806                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
1807                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1808                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
1809                 AC_TRY_COMPILE([],[
1810 #ifdef __INTEL_COMPILER
1811 #else
1812 make an error
1813 #endif
1814 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
1815 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
1816 ],[])
1817                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1818                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
1819                 ;;
1820         esac
1821 fi
1822 ])dnl
1823 dnl ---------------------------------------------------------------------------
1824 dnl CF_LARGEFILE version: 11 updated: 2018/06/20 20:23:13
1825 dnl ------------
1826 dnl Add checks for large file support.
1827 AC_DEFUN([CF_LARGEFILE],[
1828 ifdef([AC_FUNC_FSEEKO],[
1829         AC_SYS_LARGEFILE
1830         if test "$enable_largefile" != no ; then
1831         AC_FUNC_FSEEKO
1832
1833         # Normally we would collect these definitions in the config.h,
1834         # but (like _XOPEN_SOURCE), some environments rely on having these
1835         # defined before any of the system headers are included.  Another
1836         # case comes up with C++, e.g., on AIX the compiler compiles the
1837         # header files by themselves before looking at the body files it is
1838         # told to compile.  For ncurses, those header files do not include
1839         # the config.h
1840         if test "$ac_cv_sys_large_files" != no
1841         then
1842                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
1843         fi
1844         if test "$ac_cv_sys_largefile_source" != no
1845         then
1846                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
1847         fi
1848         if test "$ac_cv_sys_file_offset_bits" != no
1849         then
1850                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
1851         fi
1852
1853         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
1854                 AC_TRY_COMPILE([
1855 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
1856 #include <sys/types.h>
1857 #include <dirent.h>
1858                 ],[
1859                 /* if transitional largefile support is setup, this is true */
1860                 extern struct dirent64 * readdir(DIR *);
1861                 struct dirent64 *x = readdir((DIR *)0);
1862                 struct dirent *y = readdir((DIR *)0);
1863                 int z = x - y;
1864                 ],
1865                 [cf_cv_struct_dirent64=yes],
1866                 [cf_cv_struct_dirent64=no])
1867         ])
1868         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
1869         fi
1870 ])
1871 ])
1872 dnl ---------------------------------------------------------------------------
1873 dnl CF_LD_RPATH_OPT version: 8 updated: 2018/08/18 16:36:35
1874 dnl ---------------
1875 dnl For the given system and compiler, find the compiler flags to pass to the
1876 dnl loader to use the "rpath" feature.
1877 AC_DEFUN([CF_LD_RPATH_OPT],
1878 [
1879 AC_REQUIRE([CF_CHECK_CACHE])
1880
1881 LD_RPATH_OPT=
1882 if test "x$cf_cv_enable_rpath" != xno
1883 then
1884         AC_MSG_CHECKING(for an rpath option)
1885         case $cf_cv_system_name in
1886         (irix*)
1887                 if test "$GCC" = yes; then
1888                         LD_RPATH_OPT="-Wl,-rpath,"
1889                 else
1890                         LD_RPATH_OPT="-rpath "
1891                 fi
1892                 ;;
1893         (linux*|gnu*|k*bsd*-gnu|freebsd*)
1894                 LD_RPATH_OPT="-Wl,-rpath,"
1895                 ;;
1896         (openbsd[[2-9]].*|mirbsd*)
1897                 LD_RPATH_OPT="-Wl,-rpath,"
1898                 ;;
1899         (dragonfly*)
1900                 LD_RPATH_OPT="-rpath "
1901                 ;;
1902         (netbsd*)
1903                 LD_RPATH_OPT="-Wl,-rpath,"
1904                 ;;
1905         (osf*|mls+*)
1906                 LD_RPATH_OPT="-rpath "
1907                 ;;
1908         (solaris2*)
1909                 LD_RPATH_OPT="-R"
1910                 ;;
1911         (*)
1912                 ;;
1913         esac
1914         AC_MSG_RESULT($LD_RPATH_OPT)
1915
1916         case "x$LD_RPATH_OPT" in
1917         (x-R*)
1918                 AC_MSG_CHECKING(if we need a space after rpath option)
1919                 cf_save_LIBS="$LIBS"
1920                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
1921                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
1922                 LIBS="$cf_save_LIBS"
1923                 AC_MSG_RESULT($cf_rpath_space)
1924                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
1925                 ;;
1926         esac
1927 fi
1928 ])dnl
1929 dnl ---------------------------------------------------------------------------
1930 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
1931 dnl ---------------
1932 dnl Construct a search-list of directories for a nonstandard library-file
1933 dnl
1934 dnl Parameters
1935 dnl     $1 = the variable to return as result
1936 dnl     $2 = the package name
1937 AC_DEFUN([CF_LIBRARY_PATH],
1938 [
1939 $1=
1940 cf_library_path_list=""
1941 if test -n "${LDFLAGS}${LIBS}" ; then
1942         for cf_library_path in $LDFLAGS $LIBS
1943         do
1944                 case $cf_library_path in
1945                 (-L*)
1946                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
1947                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
1948                         cf_library_path_list="$cf_library_path_list [$]$1"
1949                         ;;
1950                 esac
1951         done
1952 fi
1953
1954 CF_SUBDIR_PATH($1,$2,lib)
1955
1956 $1="$cf_library_path_list [$]$1"
1957 ])dnl
1958 dnl ---------------------------------------------------------------------------
1959 dnl CF_LIB_PREFIX version: 12 updated: 2015/10/17 19:03:33
1960 dnl -------------
1961 dnl Compute the library-prefix for the given host system
1962 dnl $1 = variable to set
1963 define([CF_LIB_PREFIX],
1964 [
1965         case $cf_cv_system_name in
1966         (OS/2*|os2*)
1967                 if test "$DFT_LWR_MODEL" = libtool; then
1968                         LIB_PREFIX='lib'
1969                 else
1970                         LIB_PREFIX=''
1971                 fi
1972                 ;;
1973         (*)     LIB_PREFIX='lib'
1974                 ;;
1975         esac
1976 ifelse($1,,,[$1=$LIB_PREFIX])
1977         AC_SUBST(LIB_PREFIX)
1978 ])dnl
1979 dnl ---------------------------------------------------------------------------
1980 dnl CF_LIB_SUFFIX version: 25 updated: 2015/04/17 21:13:04
1981 dnl -------------
1982 dnl Compute the library file-suffix from the given model name
1983 dnl $1 = model name
1984 dnl $2 = variable to set (the nominal library suffix)
1985 dnl $3 = dependency variable to set (actual filename)
1986 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
1987 AC_DEFUN([CF_LIB_SUFFIX],
1988 [
1989         case X$1 in
1990         (Xlibtool)
1991                 $2='.la'
1992                 $3=[$]$2
1993                 ;;
1994         (Xdebug)
1995                 $2='_g.a'
1996                 $3=[$]$2
1997                 ;;
1998         (Xprofile)
1999                 $2='_p.a'
2000                 $3=[$]$2
2001                 ;;
2002         (Xshared)
2003                 case $cf_cv_system_name in
2004                 (aix[[5-7]]*)
2005                         $2='.so'
2006                         $3=[$]$2
2007                         ;;
2008                 (cygwin*|msys*|mingw*)
2009                         $2='.dll'
2010                         $3='.dll.a'
2011                         ;;
2012                 (darwin*)
2013                         $2='.dylib'
2014                         $3=[$]$2
2015                         ;;
2016                 (hpux*)
2017                         case $target in
2018                         (ia64*)
2019                                 $2='.so'
2020                                 $3=[$]$2
2021                                 ;;
2022                         (*)
2023                                 $2='.sl'
2024                                 $3=[$]$2
2025                                 ;;
2026                         esac
2027                         ;;
2028                 (*)
2029                         $2='.so'
2030                         $3=[$]$2
2031                         ;;
2032                 esac
2033                 ;;
2034         (*)
2035                 $2='.a'
2036                 $3=[$]$2
2037                 ;;
2038         esac
2039         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
2040         then
2041                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
2042                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
2043         fi
2044 ])dnl
2045 dnl ---------------------------------------------------------------------------
2046 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
2047 dnl -----------
2048 dnl Compute the string to append to -library from the given model name
2049 dnl $1 = model name
2050 dnl $2 = variable to set
2051 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
2052 AC_DEFUN([CF_LIB_TYPE],
2053 [
2054         case $1 in
2055         (libtool) $2=''   ;;
2056         (normal)  $2=''   ;;
2057         (debug)   $2='_g' ;;
2058         (profile) $2='_p' ;;
2059         (shared)  $2=''   ;;
2060         esac
2061         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
2062 ])dnl
2063 dnl ---------------------------------------------------------------------------
2064 dnl CF_LINK_DATAONLY version: 12 updated: 2017/07/23 17:46:07
2065 dnl ----------------
2066 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
2067 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
2068 dnl have to provide wrappers for global tables to ensure they're linked
2069 dnl properly.
2070 AC_DEFUN([CF_LINK_DATAONLY],
2071 [
2072 AC_MSG_CHECKING([if data-only library module links])
2073 AC_CACHE_VAL(cf_cv_link_dataonly,[
2074         rm -f conftest.a
2075         cat >conftest.$ac_ext <<EOF
2076 #line __oline__ "configure"
2077 int     testdata[[3]] = { 123, 456, 789 };
2078 EOF
2079         if AC_TRY_EVAL(ac_compile) ; then
2080                 mv conftest.o data.o && \
2081                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
2082         fi
2083         rm -f conftest.$ac_ext data.o
2084         cat >conftest.$ac_ext <<EOF
2085 #line __oline__ "configure"
2086 int     testfunc(void)
2087 {
2088 #if defined(NeXT)
2089         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
2090 #else
2091         extern int testdata[[3]];
2092         return testdata[[0]] == 123
2093            &&  testdata[[1]] == 456
2094            &&  testdata[[2]] == 789;
2095 #endif
2096 }
2097 EOF
2098         if AC_TRY_EVAL(ac_compile); then
2099                 mv conftest.o func.o && \
2100                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
2101         fi
2102         rm -f conftest.$ac_ext func.o
2103         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
2104         cf_saveLIBS="$LIBS"
2105         LIBS="conftest.a $LIBS"
2106         AC_TRY_RUN([
2107         int main(void)
2108         {
2109                 extern int testfunc();
2110                 ${cf_cv_main_return:-return} (!testfunc());
2111         }
2112         ],
2113         [cf_cv_link_dataonly=yes],
2114         [cf_cv_link_dataonly=no],
2115         [cf_cv_link_dataonly=unknown])
2116         LIBS="$cf_saveLIBS"
2117         ])
2118 AC_MSG_RESULT($cf_cv_link_dataonly)
2119
2120 if test "$cf_cv_link_dataonly" = no ; then
2121         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
2122         BROKEN_LINKER=1
2123 fi
2124
2125 ])dnl
2126 dnl ---------------------------------------------------------------------------
2127 dnl CF_MAKEFLAGS version: 18 updated: 2018/02/21 21:26:03
2128 dnl ------------
2129 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
2130 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
2131 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
2132 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
2133 AC_DEFUN([CF_MAKEFLAGS],
2134 [
2135 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
2136         cf_cv_makeflags=''
2137         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
2138         do
2139                 cat >cf_makeflags.tmp <<CF_EOF
2140 SHELL = $SHELL
2141 all :
2142         @ echo '.$cf_option'
2143 CF_EOF
2144                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
2145                 case "$cf_result" in
2146                 (.*k|.*kw)
2147                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
2148                         case "$cf_result" in
2149                         (.*CC=*)        cf_cv_makeflags=
2150                                 ;;
2151                         (*)     cf_cv_makeflags=$cf_option
2152                                 ;;
2153                         esac
2154                         break
2155                         ;;
2156                 (.-)
2157                         ;;
2158                 (*)
2159                         CF_MSG_LOG(given option \"$cf_option\", no match \"$cf_result\")
2160                         ;;
2161                 esac
2162         done
2163         rm -f cf_makeflags.tmp
2164 ])
2165
2166 AC_SUBST(cf_cv_makeflags)
2167 ])dnl
2168 dnl ---------------------------------------------------------------------------
2169 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
2170 dnl ------------
2171 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
2172 dnl a monocase filesystem.
2173 AC_DEFUN([CF_MAKE_TAGS],[
2174 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
2175
2176 AC_CHECK_PROGS(CTAGS, exctags ctags)
2177 AC_CHECK_PROGS(ETAGS, exetags etags)
2178
2179 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
2180
2181 if test "$cf_cv_mixedcase" = yes ; then
2182         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
2183 else
2184         MAKE_UPPER_TAGS=no
2185 fi
2186
2187 if test "$MAKE_UPPER_TAGS" = yes ; then
2188         MAKE_UPPER_TAGS=
2189 else
2190         MAKE_UPPER_TAGS="#"
2191 fi
2192
2193 if test "$MAKE_LOWER_TAGS" = yes ; then
2194         MAKE_LOWER_TAGS=
2195 else
2196         MAKE_LOWER_TAGS="#"
2197 fi
2198
2199 AC_SUBST(CTAGS)
2200 AC_SUBST(ETAGS)
2201
2202 AC_SUBST(MAKE_UPPER_TAGS)
2203 AC_SUBST(MAKE_LOWER_TAGS)
2204 ])dnl
2205 dnl ---------------------------------------------------------------------------
2206 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
2207 dnl ----------------------
2208 dnl Check if the file-system supports mixed-case filenames.  If we're able to
2209 dnl create a lowercase name and see it as uppercase, it doesn't support that.
2210 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
2211 [
2212 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
2213 if test "$cross_compiling" = yes ; then
2214         case $target_alias in
2215         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
2216                 cf_cv_mixedcase=no
2217                 ;;
2218         (*)
2219                 cf_cv_mixedcase=yes
2220                 ;;
2221         esac
2222 else
2223         rm -f conftest CONFTEST
2224         echo test >conftest
2225         if test -f CONFTEST ; then
2226                 cf_cv_mixedcase=no
2227         else
2228                 cf_cv_mixedcase=yes
2229         fi
2230         rm -f conftest CONFTEST
2231 fi
2232 ])
2233 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
2234 ])dnl
2235 dnl ---------------------------------------------------------------------------
2236 dnl CF_MKSTEMP version: 10 updated: 2017/01/21 11:12:16
2237 dnl ----------
2238 dnl Check for a working mkstemp.  This creates two files, checks that they are
2239 dnl successfully created and distinct (AmigaOS apparently fails on the last).
2240 AC_DEFUN([CF_MKSTEMP],[
2241 AC_CHECK_HEADERS( \
2242 unistd.h \
2243 )
2244 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
2245 rm -rf conftest*
2246 AC_TRY_RUN([
2247 #include <sys/types.h>
2248 #ifdef HAVE_UNISTD_H
2249 #include <unistd.h>
2250 #endif
2251 #include <stdlib.h>
2252 #include <stdio.h>
2253 #include <string.h>
2254 #include <sys/stat.h>
2255 int main(void)
2256 {
2257         char *tmpl = "conftestXXXXXX";
2258         char name[2][80];
2259         int n;
2260         int result = 0;
2261         int fd;
2262         struct stat sb;
2263
2264         umask(077);
2265         for (n = 0; n < 2; ++n) {
2266                 strcpy(name[n], tmpl);
2267                 if ((fd = mkstemp(name[n])) >= 0) {
2268                         if (!strcmp(name[n], tmpl)
2269                          || stat(name[n], &sb) != 0
2270                          || (sb.st_mode & S_IFMT) != S_IFREG
2271                          || (sb.st_mode & 077) != 0) {
2272                                 result = 1;
2273                         }
2274                         close(fd);
2275                 }
2276         }
2277         if (result == 0
2278          && !strcmp(name[0], name[1]))
2279                 result = 1;
2280         ${cf_cv_main_return:-return}(result);
2281 }
2282 ],[cf_cv_func_mkstemp=yes
2283 ],[cf_cv_func_mkstemp=no
2284 ],[cf_cv_func_mkstemp=maybe])
2285 ])
2286 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
2287         AC_CHECK_FUNC(mkstemp)
2288 fi
2289 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
2290         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
2291 fi
2292 ])dnl
2293 dnl ---------------------------------------------------------------------------
2294 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
2295 dnl ----------
2296 dnl Write a debug message to config.log, along with the line number in the
2297 dnl configure script.
2298 AC_DEFUN([CF_MSG_LOG],[
2299 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
2300 ])dnl
2301 dnl ---------------------------------------------------------------------------
2302 dnl CF_NCURSES_ADDON version: 5 updated: 2015/04/26 18:06:58
2303 dnl ----------------
2304 dnl Configure an ncurses add-on, built outside the ncurses tree.
2305 AC_DEFUN([CF_NCURSES_ADDON],[
2306 AC_REQUIRE([CF_NCURSES_CONFIG])
2307
2308 AC_PROVIDE([CF_SUBST_NCURSES_VERSION])
2309
2310 AC_MSG_CHECKING(if you want wide-character code)
2311 AC_ARG_ENABLE(widec,
2312         [  --enable-widec          compile with wide-char/UTF-8 code],
2313         [with_widec=$enableval],
2314         [with_widec=no])
2315 AC_MSG_RESULT($with_widec)
2316 if test "$with_widec" = yes ; then
2317         CF_UTF8_LIB
2318         CF_NCURSES_CONFIG(ncursesw)
2319 else
2320         CF_NCURSES_CONFIG(ncurses)
2321 fi
2322
2323 if test "$NCURSES_CONFIG_PKG" != none ; then
2324         cf_version=`$PKG_CONFIG --modversion $NCURSES_CONFIG_PKG 2>/dev/null`
2325
2326         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2327         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2328         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2329
2330         cf_cv_abi_version=`$PKG_CONFIG --variable=abi_version $NCURSES_CONFIG_PKG 2>/dev/null`
2331         if test -z "$cf_cv_abi_version"
2332         then
2333                 cf_cv_abi_version=`$PKG_CONFIG --variable=major_version $NCURSES_CONFIG_PKG 2>/dev/null`
2334         fi
2335
2336 elif test "$NCURSES_CONFIG" != none ; then
2337
2338         cf_version=`$NCURSES_CONFIG --version 2>/dev/null`
2339
2340         NCURSES_MAJOR=`echo "$cf_version" | sed -e 's/\..*//'`
2341         NCURSES_MINOR=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.//' -e 's/\..*//'`
2342         NCURSES_PATCH=`echo "$cf_version" | sed -e 's/^[[0-9]][[0-9]]*\.[[0-9]][[0-9]]*\.//'`
2343
2344         # ABI version is not available from headers
2345         cf_cv_abi_version=`$NCURSES_CONFIG --abi-version 2>/dev/null`
2346
2347 else
2348
2349         for cf_name in MAJOR MINOR PATCH
2350         do
2351         cat >conftest.$ac_ext <<CF_EOF
2352         #include <${cf_cv_ncurses_header:-curses.h}>
2353         AUTOCONF_$cf_name NCURSES_VERSION_$cf_name
2354 CF_EOF
2355                 cf_try="$ac_cpp conftest.$ac_ext 2>&5 | fgrep AUTOCONF_$cf_name >conftest.out"
2356                 AC_TRY_EVAL(cf_try)
2357                 if test -f conftest.out ; then
2358                         cf_result=`cat conftest.out | sed -e "s/^.*AUTOCONF_$cf_name[[  ]][[    ]]*//"`
2359                         eval NCURSES_$cf_name=\"$cf_result\"
2360                         # cat conftest.$ac_ext
2361                         # cat conftest.out
2362                 fi
2363         done
2364
2365         cf_cv_abi_version=${NCURSES_MAJOR}
2366
2367 fi
2368
2369 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
2370
2371 dnl Show the computed version, for logging
2372 cf_cv_timestamp=`date`
2373
2374 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
2375
2376 dnl We need these values in the generated headers
2377 AC_SUBST(NCURSES_MAJOR)
2378 AC_SUBST(NCURSES_MINOR)
2379 AC_SUBST(NCURSES_PATCH)
2380
2381 dnl We need these values in the generated makefiles
2382 AC_SUBST(cf_cv_rel_version)
2383 AC_SUBST(cf_cv_abi_version)
2384
2385 dnl FIXME - not needed for Ada95
2386 AC_SUBST(cf_cv_builtin_bool)
2387 AC_SUBST(cf_cv_header_stdbool_h)
2388 AC_SUBST(cf_cv_type_of_bool)dnl
2389
2390 ])
2391 dnl ---------------------------------------------------------------------------
2392 dnl CF_NCURSES_CC_CHECK version: 4 updated: 2007/07/29 10:39:05
2393 dnl -------------------
2394 dnl Check if we can compile with ncurses' header file
2395 dnl $1 is the cache variable to set
2396 dnl $2 is the header-file to include
2397 dnl $3 is the root name (ncurses or ncursesw)
2398 AC_DEFUN([CF_NCURSES_CC_CHECK],[
2399         AC_TRY_COMPILE([
2400 ]ifelse($3,ncursesw,[
2401 #define _XOPEN_SOURCE_EXTENDED
2402 #undef  HAVE_LIBUTF8_H  /* in case we used CF_UTF8_LIB */
2403 #define HAVE_LIBUTF8_H  /* to force ncurses' header file to use cchar_t */
2404 ])[
2405 #include <$2>],[
2406 #ifdef NCURSES_VERSION
2407 ]ifelse($3,ncursesw,[
2408 #ifndef WACS_BSSB
2409         make an error
2410 #endif
2411 ])[
2412 printf("%s\n", NCURSES_VERSION);
2413 #else
2414 #ifdef __NCURSES_H
2415 printf("old\n");
2416 #else
2417         make an error
2418 #endif
2419 #endif
2420         ]
2421         ,[$1=$2]
2422         ,[$1=no])
2423 ])dnl
2424 dnl ---------------------------------------------------------------------------
2425 dnl CF_NCURSES_CONFIG version: 21 updated: 2018/06/20 20:23:13
2426 dnl -----------------
2427 dnl Tie together the configure-script macros for ncurses, preferring these in
2428 dnl order:
2429 dnl a) ".pc" files for pkg-config, using $NCURSES_CONFIG_PKG
2430 dnl b) the "-config" script from ncurses, using $NCURSES_CONFIG
2431 dnl c) just plain libraries
2432 dnl
2433 dnl $1 is the root library name (default: "ncurses")
2434 AC_DEFUN([CF_NCURSES_CONFIG],[
2435 AC_REQUIRE([CF_PKG_CONFIG])
2436 cf_ncuconfig_root=ifelse($1,,ncurses,$1)
2437 cf_have_ncuconfig=no
2438
2439 if test "x${PKG_CONFIG:=none}" != xnone; then
2440         AC_MSG_CHECKING(pkg-config for $cf_ncuconfig_root)
2441         if "$PKG_CONFIG" --exists $cf_ncuconfig_root ; then
2442                 AC_MSG_RESULT(yes)
2443
2444                 AC_MSG_CHECKING(if the $cf_ncuconfig_root package files work)
2445                 cf_have_ncuconfig=unknown
2446
2447                 cf_save_CPPFLAGS="$CPPFLAGS"
2448                 cf_save_LIBS="$LIBS"
2449
2450                 CF_ADD_CFLAGS(`$PKG_CONFIG --cflags $cf_ncuconfig_root`)
2451                 CF_ADD_LIBS(`$PKG_CONFIG --libs $cf_ncuconfig_root`)
2452
2453                 AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2454                         [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2455                         [AC_TRY_RUN([#include <${cf_cv_ncurses_header:-curses.h}>
2456                                 int main(void)
2457                                 { char *xx = curses_version(); return (xx == 0); }],
2458                                 [cf_have_ncuconfig=yes],
2459                                 [cf_have_ncuconfig=no],
2460                                 [cf_have_ncuconfig=maybe])],
2461                         [cf_have_ncuconfig=no])
2462                 AC_MSG_RESULT($cf_have_ncuconfig)
2463                 test "$cf_have_ncuconfig" = maybe && cf_have_ncuconfig=yes
2464                 if test "$cf_have_ncuconfig" != "yes"
2465                 then
2466                         CPPFLAGS="$cf_save_CPPFLAGS"
2467                         LIBS="$cf_save_LIBS"
2468                         NCURSES_CONFIG_PKG=none
2469                 else
2470                         AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2471                         NCURSES_CONFIG_PKG=$cf_ncuconfig_root
2472                         CF_TERM_HEADER
2473                 fi
2474
2475         else
2476                 AC_MSG_RESULT(no)
2477                 NCURSES_CONFIG_PKG=none
2478         fi
2479 else
2480         NCURSES_CONFIG_PKG=none
2481 fi
2482
2483 if test "x$cf_have_ncuconfig" = "xno"; then
2484         cf_ncurses_config="${cf_ncuconfig_root}${NCURSES_CONFIG_SUFFIX}-config"; echo "Looking for ${cf_ncurses_config}"
2485
2486         CF_ACVERSION_CHECK(2.52,
2487                 [AC_CHECK_TOOLS(NCURSES_CONFIG, ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)],
2488                 [AC_PATH_PROGS(NCURSES_CONFIG,  ${cf_ncurses_config} ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}6-config ${cf_ncuconfig_root}5-config, none)])
2489
2490         if test "$NCURSES_CONFIG" != none ; then
2491
2492                 CF_ADD_CFLAGS(`$NCURSES_CONFIG --cflags`)
2493                 CF_ADD_LIBS(`$NCURSES_CONFIG --libs`)
2494
2495                 # even with config script, some packages use no-override for curses.h
2496                 CF_CURSES_HEADER(ifelse($1,,ncurses,$1))
2497
2498                 dnl like CF_NCURSES_CPPFLAGS
2499                 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2500
2501                 dnl like CF_NCURSES_LIBS
2502                 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_ncuconfig_root)
2503                 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2504
2505                 dnl like CF_NCURSES_VERSION
2506                 cf_cv_ncurses_version=`$NCURSES_CONFIG --version`
2507
2508         else
2509
2510                 CF_NCURSES_CPPFLAGS(ifelse($1,,ncurses,$1))
2511                 CF_NCURSES_LIBS(ifelse($1,,ncurses,$1))
2512
2513         fi
2514 else
2515         NCURSES_CONFIG=none
2516 fi
2517 ])dnl
2518 dnl ---------------------------------------------------------------------------
2519 dnl CF_NCURSES_CPPFLAGS version: 21 updated: 2012/10/06 08:57:51
2520 dnl -------------------
2521 dnl Look for the SVr4 curses clone 'ncurses' in the standard places, adjusting
2522 dnl the CPPFLAGS variable so we can include its header.
2523 dnl
2524 dnl The header files may be installed as either curses.h, or ncurses.h (would
2525 dnl be obsolete, except that some packagers prefer this name to distinguish it
2526 dnl from a "native" curses implementation).  If not installed for overwrite,
2527 dnl the curses.h file would be in an ncurses subdirectory (e.g.,
2528 dnl /usr/include/ncurses), but someone may have installed overwriting the
2529 dnl vendor's curses.  Only very old versions (pre-1.9.2d, the first autoconf'd
2530 dnl version) of ncurses don't define either __NCURSES_H or NCURSES_VERSION in
2531 dnl the header.
2532 dnl
2533 dnl If the installer has set $CFLAGS or $CPPFLAGS so that the ncurses header
2534 dnl is already in the include-path, don't even bother with this, since we cannot
2535 dnl easily determine which file it is.  In this case, it has to be <curses.h>.
2536 dnl
2537 dnl The optional parameter gives the root name of the library, in case it is
2538 dnl not installed as the default curses library.  That is how the
2539 dnl wide-character version of ncurses is installed.
2540 AC_DEFUN([CF_NCURSES_CPPFLAGS],
2541 [AC_REQUIRE([CF_WITH_CURSES_DIR])
2542
2543 AC_PROVIDE([CF_CURSES_CPPFLAGS])dnl
2544 cf_ncuhdr_root=ifelse($1,,ncurses,$1)
2545
2546 test -n "$cf_cv_curses_dir" && \
2547 test "$cf_cv_curses_dir" != "no" && { \
2548   CF_ADD_INCDIR($cf_cv_curses_dir/include/$cf_ncuhdr_root)
2549 }
2550
2551 AC_CACHE_CHECK(for $cf_ncuhdr_root header in include-path, cf_cv_ncurses_h,[
2552         cf_header_list="$cf_ncuhdr_root/curses.h $cf_ncuhdr_root/ncurses.h"
2553         ( test "$cf_ncuhdr_root" = ncurses || test "$cf_ncuhdr_root" = ncursesw ) && cf_header_list="$cf_header_list curses.h ncurses.h"
2554         for cf_header in $cf_header_list
2555         do
2556                 CF_NCURSES_CC_CHECK(cf_cv_ncurses_h,$cf_header,$1)
2557                 test "$cf_cv_ncurses_h" != no && break
2558         done
2559 ])
2560
2561 CF_NCURSES_HEADER
2562 CF_TERM_HEADER
2563
2564 # some applications need this, but should check for NCURSES_VERSION
2565 AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2566
2567 CF_NCURSES_VERSION
2568 ])dnl
2569 dnl ---------------------------------------------------------------------------
2570 dnl CF_NCURSES_HEADER version: 4 updated: 2015/04/15 19:08:48
2571 dnl -----------------
2572 dnl Find a "curses" header file, e.g,. "curses.h", or one of the more common
2573 dnl variations of ncurses' installs.
2574 dnl
2575 dnl See also CF_CURSES_HEADER, which sets the same cache variable.
2576 AC_DEFUN([CF_NCURSES_HEADER],[
2577
2578 if test "$cf_cv_ncurses_h" != no ; then
2579         cf_cv_ncurses_header=$cf_cv_ncurses_h
2580 else
2581
2582 AC_CACHE_CHECK(for $cf_ncuhdr_root include-path, cf_cv_ncurses_h2,[
2583         test -n "$verbose" && echo
2584         CF_HEADER_PATH(cf_search,$cf_ncuhdr_root)
2585         test -n "$verbose" && echo search path $cf_search
2586         cf_save2_CPPFLAGS="$CPPFLAGS"
2587         for cf_incdir in $cf_search
2588         do
2589                 CF_ADD_INCDIR($cf_incdir)
2590                 for cf_header in \
2591                         ncurses.h \
2592                         curses.h
2593                 do
2594                         CF_NCURSES_CC_CHECK(cf_cv_ncurses_h2,$cf_header,$1)
2595                         if test "$cf_cv_ncurses_h2" != no ; then
2596                                 cf_cv_ncurses_h2=$cf_incdir/$cf_header
2597                                 test -n "$verbose" && echo $ac_n "      ... found $ac_c" 1>&AC_FD_MSG
2598                                 break
2599                         fi
2600                         test -n "$verbose" && echo "    ... tested $cf_incdir/$cf_header" 1>&AC_FD_MSG
2601                 done
2602                 CPPFLAGS="$cf_save2_CPPFLAGS"
2603                 test "$cf_cv_ncurses_h2" != no && break
2604         done
2605         test "$cf_cv_ncurses_h2" = no && AC_MSG_ERROR(not found)
2606         ])
2607
2608         CF_DIRNAME(cf_1st_incdir,$cf_cv_ncurses_h2)
2609         cf_cv_ncurses_header=`basename $cf_cv_ncurses_h2`
2610         if test `basename $cf_1st_incdir` = $cf_ncuhdr_root ; then
2611                 cf_cv_ncurses_header=$cf_ncuhdr_root/$cf_cv_ncurses_header
2612         fi
2613         CF_ADD_INCDIR($cf_1st_incdir)
2614
2615 fi
2616
2617 # Set definitions to allow ifdef'ing for ncurses.h
2618
2619 case $cf_cv_ncurses_header in
2620 (*ncurses.h)
2621         AC_DEFINE(HAVE_NCURSES_H,1,[Define to 1 if we have ncurses.h])
2622         ;;
2623 esac
2624
2625 case $cf_cv_ncurses_header in
2626 (ncurses/curses.h|ncurses/ncurses.h)
2627         AC_DEFINE(HAVE_NCURSES_NCURSES_H,1,[Define to 1 if we have ncurses/ncurses.h])
2628         ;;
2629 (ncursesw/curses.h|ncursesw/ncurses.h)
2630         AC_DEFINE(HAVE_NCURSESW_NCURSES_H,1,[Define to 1 if we have ncursesw/ncurses.h])
2631         ;;
2632 esac
2633
2634 ])dnl
2635 dnl ---------------------------------------------------------------------------
2636 dnl CF_NCURSES_LIBS version: 17 updated: 2015/04/15 19:08:48
2637 dnl ---------------
2638 dnl Look for the ncurses library.  This is a little complicated on Linux,
2639 dnl because it may be linked with the gpm (general purpose mouse) library.
2640 dnl Some distributions have gpm linked with (bsd) curses, which makes it
2641 dnl unusable with ncurses.  However, we don't want to link with gpm unless
2642 dnl ncurses has a dependency, since gpm is normally set up as a shared library,
2643 dnl and the linker will record a dependency.
2644 dnl
2645 dnl The optional parameter gives the root name of the library, in case it is
2646 dnl not installed as the default curses library.  That is how the
2647 dnl wide-character version of ncurses is installed.
2648 AC_DEFUN([CF_NCURSES_LIBS],
2649 [AC_REQUIRE([CF_NCURSES_CPPFLAGS])
2650
2651 cf_nculib_root=ifelse($1,,ncurses,$1)
2652         # This works, except for the special case where we find gpm, but
2653         # ncurses is in a nonstandard location via $LIBS, and we really want
2654         # to link gpm.
2655 cf_ncurses_LIBS=""
2656 cf_ncurses_SAVE="$LIBS"
2657 AC_CHECK_LIB(gpm,Gpm_Open,
2658         [AC_CHECK_LIB(gpm,initscr,
2659                 [LIBS="$cf_ncurses_SAVE"],
2660                 [cf_ncurses_LIBS="-lgpm"])])
2661
2662 case $host_os in
2663 (freebsd*)
2664         # This is only necessary if you are linking against an obsolete
2665         # version of ncurses (but it should do no harm, since it's static).
2666         if test "$cf_nculib_root" = ncurses ; then
2667                 AC_CHECK_LIB(mytinfo,tgoto,[cf_ncurses_LIBS="-lmytinfo $cf_ncurses_LIBS"])
2668         fi
2669         ;;
2670 esac
2671
2672 CF_ADD_LIBS($cf_ncurses_LIBS)
2673
2674 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
2675 then
2676         CF_ADD_LIBS(-l$cf_nculib_root)
2677 else
2678         CF_FIND_LIBRARY($cf_nculib_root,$cf_nculib_root,
2679                 [#include <${cf_cv_ncurses_header:-curses.h}>],
2680                 [initscr()],
2681                 initscr)
2682 fi
2683
2684 if test -n "$cf_ncurses_LIBS" ; then
2685         AC_MSG_CHECKING(if we can link $cf_nculib_root without $cf_ncurses_LIBS)
2686         cf_ncurses_SAVE="$LIBS"
2687         for p in $cf_ncurses_LIBS ; do
2688                 q=`echo $LIBS | sed -e "s%$p %%" -e "s%$p$%%"`
2689                 if test "$q" != "$LIBS" ; then
2690                         LIBS="$q"
2691                 fi
2692         done
2693         AC_TRY_LINK([#include <${cf_cv_ncurses_header:-curses.h}>],
2694                 [initscr(); mousemask(0,0); tgoto((char *)0, 0, 0);],
2695                 [AC_MSG_RESULT(yes)],
2696                 [AC_MSG_RESULT(no)
2697                  LIBS="$cf_ncurses_SAVE"])
2698 fi
2699
2700 CF_UPPER(cf_nculib_ROOT,HAVE_LIB$cf_nculib_root)
2701 AC_DEFINE_UNQUOTED($cf_nculib_ROOT)
2702 ])dnl
2703 dnl ---------------------------------------------------------------------------
2704 dnl CF_NCURSES_VERSION version: 15 updated: 2017/05/09 19:26:10
2705 dnl ------------------
2706 dnl Check for the version of ncurses, to aid in reporting bugs, etc.
2707 dnl Call CF_CURSES_CPPFLAGS first, or CF_NCURSES_CPPFLAGS.  We don't use
2708 dnl AC_REQUIRE since that does not work with the shell's if/then/else/fi.
2709 AC_DEFUN([CF_NCURSES_VERSION],
2710 [
2711 AC_REQUIRE([CF_CURSES_CPPFLAGS])dnl
2712 AC_CACHE_CHECK(for ncurses version, cf_cv_ncurses_version,[
2713         cf_cv_ncurses_version=no
2714         cf_tempfile=out$$
2715         rm -f $cf_tempfile
2716         AC_TRY_RUN([
2717 #include <${cf_cv_ncurses_header:-curses.h}>
2718 #include <stdio.h>
2719 int main(void)
2720 {
2721         FILE *fp = fopen("$cf_tempfile", "w");
2722 #ifdef NCURSES_VERSION
2723 # ifdef NCURSES_VERSION_PATCH
2724         fprintf(fp, "%s.%d\n", NCURSES_VERSION, NCURSES_VERSION_PATCH);
2725 # else
2726         fprintf(fp, "%s\n", NCURSES_VERSION);
2727 # endif
2728 #else
2729 # ifdef __NCURSES_H
2730         fprintf(fp, "old\n");
2731 # else
2732         make an error
2733 # endif
2734 #endif
2735         ${cf_cv_main_return:-return}(0);
2736 }],[
2737         cf_cv_ncurses_version=`cat $cf_tempfile`],,[
2738
2739         # This will not work if the preprocessor splits the line after the
2740         # Autoconf token.  The 'unproto' program does that.
2741         cat > conftest.$ac_ext <<EOF
2742 #include <${cf_cv_ncurses_header:-curses.h}>
2743 #undef Autoconf
2744 #ifdef NCURSES_VERSION
2745 Autoconf NCURSES_VERSION
2746 #else
2747 #ifdef __NCURSES_H
2748 Autoconf "old"
2749 #endif
2750 ;
2751 #endif
2752 EOF
2753         cf_try="$ac_cpp conftest.$ac_ext 2>&AC_FD_CC | grep '^Autoconf ' >conftest.out"
2754         AC_TRY_EVAL(cf_try)
2755         if test -f conftest.out ; then
2756                 cf_out=`cat conftest.out | sed -e 's%^Autoconf %%' -e 's%^[[^"]]*"%%' -e 's%".*%%'`
2757                 test -n "$cf_out" && cf_cv_ncurses_version="$cf_out"
2758                 rm -f conftest.out
2759         fi
2760 ])
2761         rm -f $cf_tempfile
2762 ])
2763 test "$cf_cv_ncurses_version" = no || AC_DEFINE(NCURSES,1,[Define to 1 if we are using ncurses headers/libraries])
2764 ])dnl
2765 dnl ---------------------------------------------------------------------------
2766 dnl CF_OBJ_SUBDIR version: 7 updated: 2015/04/17 21:13:04
2767 dnl -------------
2768 dnl Compute the object-directory name from the given model name
2769 AC_DEFUN([CF_OBJ_SUBDIR],
2770 [
2771         case $1 in
2772         (libtool) $2='obj_lo'  ;;
2773         (normal)  $2='objects' ;;
2774         (debug)   $2='obj_g' ;;
2775         (profile) $2='obj_p' ;;
2776         (shared)
2777                 case $cf_cv_system_name in
2778                 (cygwin|msys)
2779                         $2='objects' ;;
2780                 (*)
2781                         $2='obj_s' ;;
2782                 esac
2783         esac
2784 ])dnl
2785 dnl ---------------------------------------------------------------------------
2786 dnl CF_PATHSEP version: 7 updated: 2015/04/12 15:39:00
2787 dnl ----------
2788 dnl Provide a value for the $PATH and similar separator (or amend the value
2789 dnl as provided in autoconf 2.5x).
2790 AC_DEFUN([CF_PATHSEP],
2791 [
2792         AC_MSG_CHECKING(for PATH separator)
2793         case $cf_cv_system_name in
2794         (os2*)  PATH_SEPARATOR=';'  ;;
2795         (*)     ${PATH_SEPARATOR:=':'}  ;;
2796         esac
2797 ifelse([$1],,,[$1=$PATH_SEPARATOR])
2798         AC_SUBST(PATH_SEPARATOR)
2799         AC_MSG_RESULT($PATH_SEPARATOR)
2800 ])dnl
2801 dnl ---------------------------------------------------------------------------
2802 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
2803 dnl --------------
2804 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
2805 dnl begins with one of the prefix/exec_prefix variables, and then again if the
2806 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
2807 dnl delayed evaluation of those symbols.
2808 AC_DEFUN([CF_PATH_SYNTAX],[
2809 if test "x$prefix" != xNONE; then
2810         cf_path_syntax="$prefix"
2811 else
2812         cf_path_syntax="$ac_default_prefix"
2813 fi
2814
2815 case ".[$]$1" in
2816 (.\[$]\(*\)*|.\'*\'*)
2817         ;;
2818 (..|./*|.\\*)
2819         ;;
2820 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
2821         ;;
2822 (.\[$]{*prefix}*|.\[$]{*dir}*)
2823         eval $1="[$]$1"
2824         case ".[$]$1" in
2825         (.NONE/*)
2826                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2827                 ;;
2828         esac
2829         ;;
2830 (.no|.NONE/*)
2831         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
2832         ;;
2833 (*)
2834         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
2835         ;;
2836 esac
2837 ])dnl
2838 dnl ---------------------------------------------------------------------------
2839 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
2840 dnl -------------
2841 dnl Check for the package-config program, unless disabled by command-line.
2842 AC_DEFUN([CF_PKG_CONFIG],
2843 [
2844 AC_MSG_CHECKING(if you want to use pkg-config)
2845 AC_ARG_WITH(pkg-config,
2846         [  --with-pkg-config{=path} enable/disable use of pkg-config],
2847         [cf_pkg_config=$withval],
2848         [cf_pkg_config=yes])
2849 AC_MSG_RESULT($cf_pkg_config)
2850
2851 case $cf_pkg_config in
2852 (no)
2853         PKG_CONFIG=none
2854         ;;
2855 (yes)
2856         CF_ACVERSION_CHECK(2.52,
2857                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
2858                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
2859         ;;
2860 (*)
2861         PKG_CONFIG=$withval
2862         ;;
2863 esac
2864
2865 test -z "$PKG_CONFIG" && PKG_CONFIG=none
2866 if test "$PKG_CONFIG" != none ; then
2867         CF_PATH_SYNTAX(PKG_CONFIG)
2868 elif test "x$cf_pkg_config" != xno ; then
2869         AC_MSG_WARN(pkg-config is not installed)
2870 fi
2871
2872 AC_SUBST(PKG_CONFIG)
2873 ])dnl
2874 dnl ---------------------------------------------------------------------------
2875 dnl CF_POSIX_C_SOURCE version: 10 updated: 2018/06/20 20:23:13
2876 dnl -----------------
2877 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
2878 dnl
2879 dnl     POSIX.1-1990                            _POSIX_SOURCE
2880 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
2881 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
2882 dnl             Bindings Option
2883 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
2884 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
2885 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
2886 dnl
2887 dnl Parameters:
2888 dnl     $1 is the nominal value for _POSIX_C_SOURCE
2889 AC_DEFUN([CF_POSIX_C_SOURCE],
2890 [
2891 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
2892
2893 cf_save_CFLAGS="$CFLAGS"
2894 cf_save_CPPFLAGS="$CPPFLAGS"
2895
2896 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
2897 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
2898
2899 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
2900         CF_MSG_LOG(if the symbol is already defined go no further)
2901         AC_TRY_COMPILE([#include <sys/types.h>],[
2902 #ifndef _POSIX_C_SOURCE
2903 make an error
2904 #endif],
2905         [cf_cv_posix_c_source=no],
2906         [cf_want_posix_source=no
2907          case .$cf_POSIX_C_SOURCE in
2908          (.[[12]]??*)
2909                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2910                 ;;
2911          (.2)
2912                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
2913                 cf_want_posix_source=yes
2914                 ;;
2915          (.*)
2916                 cf_want_posix_source=yes
2917                 ;;
2918          esac
2919          if test "$cf_want_posix_source" = yes ; then
2920                 AC_TRY_COMPILE([#include <sys/types.h>],[
2921 #ifdef _POSIX_SOURCE
2922 make an error
2923 #endif],[],
2924                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
2925          fi
2926          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
2927          CFLAGS="$cf_trim_CFLAGS"
2928          CPPFLAGS="$cf_trim_CPPFLAGS"
2929          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
2930          CF_MSG_LOG(if the second compile does not leave our definition intact error)
2931          AC_TRY_COMPILE([#include <sys/types.h>],[
2932 #ifndef _POSIX_C_SOURCE
2933 make an error
2934 #endif],,
2935          [cf_cv_posix_c_source=no])
2936          CFLAGS="$cf_save_CFLAGS"
2937          CPPFLAGS="$cf_save_CPPFLAGS"
2938         ])
2939 ])
2940
2941 if test "$cf_cv_posix_c_source" != no ; then
2942         CFLAGS="$cf_trim_CFLAGS"
2943         CPPFLAGS="$cf_trim_CPPFLAGS"
2944         CF_ADD_CFLAGS($cf_cv_posix_c_source)
2945 fi
2946
2947 ])dnl
2948 dnl ---------------------------------------------------------------------------
2949 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
2950 dnl ----------
2951 dnl Check for archiver "ar".
2952 AC_DEFUN([CF_PROG_AR],[
2953 AC_CHECK_TOOL(AR, ar, ar)
2954 ])
2955 dnl ---------------------------------------------------------------------------
2956 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
2957 dnl -----------
2958 dnl Check for awk, ensure that the check found something.
2959 AC_DEFUN([CF_PROG_AWK],
2960 [
2961 AC_PROG_AWK
2962 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
2963 ])dnl
2964 dnl ---------------------------------------------------------------------------
2965 dnl CF_PROG_CC version: 4 updated: 2014/07/12 18:57:58
2966 dnl ----------
2967 dnl standard check for CC, plus followup sanity checks
2968 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
2969 AC_DEFUN([CF_PROG_CC],[
2970 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
2971 CF_GCC_VERSION
2972 CF_ACVERSION_CHECK(2.52,
2973         [AC_PROG_CC_STDC],
2974         [CF_ANSI_CC_REQD])
2975 CF_CC_ENV_FLAGS
2976 ])dnl
2977 dnl ---------------------------------------------------------------------------
2978 dnl CF_PROG_CC_C_O version: 5 updated: 2017/01/21 11:06:25
2979 dnl --------------
2980 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
2981 dnl the output file can be renamed, and allows for a shell variable that can
2982 dnl be used later.  The parameter is either CC or CXX.  The result is the
2983 dnl cache variable:
2984 dnl     $cf_cv_prog_CC_c_o
2985 dnl     $cf_cv_prog_CXX_c_o
2986 dnl
2987 dnl $1 = compiler
2988 dnl $2 = compiler options, if any
2989 AC_DEFUN([CF_PROG_CC_C_O],
2990 [AC_REQUIRE([AC_PROG_CC])dnl
2991 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
2992 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
2993 [
2994 cat > conftest.$ac_ext <<CF_EOF
2995 int main(void)
2996 {
2997         ${cf_cv_main_return:-return}(0);
2998 }
2999 CF_EOF
3000 # We do the test twice because some compilers refuse to overwrite an
3001 # existing .o file with -o, though they will create one.
3002 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
3003 if AC_TRY_EVAL(ac_try) &&
3004   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
3005 then
3006   eval cf_cv_prog_$1_c_o=yes
3007 else
3008   eval cf_cv_prog_$1_c_o=no
3009 fi
3010 rm -rf conftest*
3011 ])dnl
3012 if test $cf_cv_prog_$1_c_o = yes; then
3013   AC_MSG_RESULT([yes])
3014 else
3015   AC_MSG_RESULT([no])
3016 fi
3017 ])dnl
3018 dnl ---------------------------------------------------------------------------
3019 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
3020 dnl -------------
3021 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
3022 dnl This macro adds a check to ensure the script found something.
3023 AC_DEFUN([CF_PROG_EGREP],
3024 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
3025         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
3026                 then ac_cv_prog_egrep='grep -E'
3027                 else ac_cv_prog_egrep='egrep'
3028         fi])
3029         EGREP=$ac_cv_prog_egrep
3030         AC_SUBST([EGREP])
3031         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
3032 ])dnl
3033 dnl ---------------------------------------------------------------------------
3034 dnl CF_PROG_EXT version: 14 updated: 2018/06/20 20:23:13
3035 dnl -----------
3036 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
3037 AC_DEFUN([CF_PROG_EXT],
3038 [
3039 AC_REQUIRE([CF_CHECK_CACHE])
3040 case $cf_cv_system_name in
3041 (os2*)
3042         CFLAGS="$CFLAGS -Zmt"
3043         CF_APPEND_TEXT(CPPFLAGS,-D__ST_MT_ERRNO__)
3044         CXXFLAGS="$CXXFLAGS -Zmt"
3045         # autoconf's macro sets -Zexe and suffix both, which conflict:w
3046         LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
3047         ac_cv_exeext=.exe
3048         ;;
3049 esac
3050
3051 AC_EXEEXT
3052 AC_OBJEXT
3053
3054 PROG_EXT="$EXEEXT"
3055 AC_SUBST(PROG_EXT)
3056 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT",[Define to the program extension (normally blank)])
3057 ])dnl
3058 dnl ---------------------------------------------------------------------------
3059 dnl CF_PROG_GNAT version: 8 updated: 2018/11/10 19:47:04
3060 dnl ------------
3061 dnl Check for gnatmake, ensure that it is complete.
3062 AC_DEFUN([CF_PROG_GNAT],[
3063 cf_ada_make=gnatmake
3064 cf_ada_config="#"
3065 AC_CHECK_PROG(gnatmake_exists, $cf_ada_make, yes, no)
3066 if test "$ac_cv_prog_gnatmake_exists" = no; then
3067         cf_ada_make=
3068         cf_cv_prog_gnat_correct=no
3069 else
3070         AC_CHECK_PROG(gprconfig_exists, gprconfig, yes, no)
3071         if test "$ac_cv_prog_gprconfig_exists" = yes
3072         then
3073                 rm -rf conftest* *~conftest*
3074                 if mkdir conftest.src
3075                 then
3076                         cf_ada_config=""
3077                         cd conftest.src
3078                         for cf_gprconfig in Ada C
3079                         do
3080                                 AC_MSG_CHECKING(for gprconfig name for $cf_gprconfig)
3081                                 if test $cf_gprconfig = C
3082                                 then
3083                                         for cf_gprconfig_param in \
3084                                                 $cf_gprconfig,,,,GNATGCC \
3085                                                 $cf_gprconfig,,,,GCC \
3086                                                 $cf_gprconfig
3087                                         do
3088                                                 cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
3089                                                 test -n "$cf_gprconfig_value" && break
3090                                         done
3091                                 else
3092                                         cf_gprconfig_param=$cf_gprconfig
3093                                         cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
3094                                 fi
3095                                 if test -n "$cf_gprconfig_value"
3096                                 then
3097                                         eval cf_ada_config_[$]cf_gprconfig=[$]cf_gprconfig_value
3098                                         AC_MSG_RESULT($cf_gprconfig_value)
3099                                 else
3100                                         AC_MSG_RESULT(missing)
3101                                         cf_ada_config="#"
3102                                         break
3103                                 fi
3104                         done
3105                         cd ..
3106                         rm -rf conftest* *~conftest*
3107                 fi
3108         else
3109                 # gprconfig is newer than gnatmake; we can continue...
3110                 cf_ada_config="##"
3111         fi
3112         if test "x$cf_ada_config" != "x#"
3113         then
3114                 CF_GNAT_VERSION
3115                 AC_CHECK_PROG(M4_exists, m4, yes, no)
3116                 if test "$ac_cv_prog_M4_exists" = no; then
3117                         cf_cv_prog_gnat_correct=no
3118                         echo Ada95 binding required program m4 not found. Ada95 binding disabled.
3119                 fi
3120                 if test "$cf_cv_prog_gnat_correct" = yes; then
3121                         AC_MSG_CHECKING(if GNAT works)
3122                         CF_GNAT_TRY_RUN([procedure conftest;],
3123 [with Text_IO;
3124 with GNAT.OS_Lib;
3125 procedure conftest is
3126 begin
3127    Text_IO.Put ("Hello World");
3128    Text_IO.New_Line;
3129    GNAT.OS_Lib.OS_Exit (0);
3130 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
3131                         AC_MSG_RESULT($cf_cv_prog_gnat_correct)
3132                 fi
3133         else
3134                 cf_cv_prog_gnat_correct=no
3135         fi
3136 fi
3137
3138 AC_SUBST(cf_ada_make)
3139 AC_SUBST(cf_ada_config)
3140 AC_SUBST(cf_ada_config_Ada)
3141 AC_SUBST(cf_ada_config_C)
3142 ])dnl
3143 dnl ---------------------------------------------------------------------------
3144 dnl CF_PROG_INSTALL version: 7 updated: 2015/04/18 08:56:57
3145 dnl ---------------
3146 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
3147 dnl misc/tabset install won't work properly.  Usually this happens only when
3148 dnl using the fallback mkinstalldirs script
3149 AC_DEFUN([CF_PROG_INSTALL],
3150 [AC_PROG_INSTALL
3151 case $INSTALL in
3152 (/*)
3153         ;;
3154 (*)
3155         CF_DIRNAME(cf_dir,$INSTALL)
3156         test -z "$cf_dir" && cf_dir=.
3157         INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
3158         ;;
3159 esac
3160 ])dnl
3161 dnl ---------------------------------------------------------------------------
3162 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
3163 dnl ------------
3164 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
3165 dnl option if it is supported.
3166 AC_DEFUN([CF_PROG_LN_S],[
3167 AC_PROG_LN_S
3168 AC_MSG_CHECKING(if $LN_S -f options work)
3169
3170 rm -f conf$$.src conf$$dst
3171 echo >conf$$.dst
3172 echo first >conf$$.src
3173 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
3174         cf_prog_ln_sf=yes
3175 else
3176         cf_prog_ln_sf=no
3177 fi
3178 rm -f conf$$.dst conf$$src
3179 AC_MSG_RESULT($cf_prog_ln_sf)
3180
3181 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
3182 ])dnl
3183 dnl ---------------------------------------------------------------------------
3184 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
3185 dnl ----------------
3186 dnl Remove all -U and -D options that refer to the given symbol from a list
3187 dnl of C compiler options.  This works around the problem that not all
3188 dnl compilers process -U and -D options from left-to-right, so a -U option
3189 dnl cannot be used to cancel the effect of a preceding -D option.
3190 dnl
3191 dnl $1 = target (which could be the same as the source variable)
3192 dnl $2 = source (including '$')
3193 dnl $3 = symbol to remove
3194 define([CF_REMOVE_DEFINE],
3195 [
3196 $1=`echo "$2" | \
3197         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
3198                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
3199 ])dnl
3200 dnl ---------------------------------------------------------------------------
3201 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
3202 dnl -------------
3203 dnl Remove the given library from the symbol
3204 dnl
3205 dnl $1 = target (which could be the same as the source variable)
3206 dnl $2 = source (including '$')
3207 dnl $3 = library to remove
3208 define([CF_REMOVE_LIB],
3209 [
3210 # remove $3 library from $2
3211 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
3212 ])dnl
3213 dnl ---------------------------------------------------------------------------
3214 dnl CF_SHARED_OPTS version: 93 updated: 2018/08/18 16:36:35
3215 dnl --------------
3216 dnl --------------
3217 dnl Attempt to determine the appropriate CC/LD options for creating a shared
3218 dnl library.
3219 dnl
3220 dnl Notes:
3221 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
3222 dnl the build-tree, i.e., by making use of the libraries that are compiled in
3223 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
3224 dnl shared library since that can lead to unexpected results at runtime.
3225 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
3226 dnl libraries are compiled in ../../lib
3227 dnl
3228 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
3229 dnl to install symbolic links to the rel/abi versions of shared libraries.
3230 dnl
3231 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
3232 dnl version when making symbolic links.
3233 dnl
3234 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
3235 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
3236 dnl (ex: libncurses.so.<ver>).
3237 dnl
3238 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
3239 AC_DEFUN([CF_SHARED_OPTS],
3240 [
3241         AC_REQUIRE([CF_LD_RPATH_OPT])
3242
3243         RM_SHARED_OPTS=
3244         LOCAL_LDFLAGS=
3245         LOCAL_LDFLAGS2=
3246         LD_SHARED_OPTS=
3247         INSTALL_LIB="-m 644"
3248         : ${rel_builddir:=.}
3249
3250         shlibdir=$libdir
3251         AC_SUBST(shlibdir)
3252
3253         MAKE_DLLS="#"
3254         AC_SUBST(MAKE_DLLS)
3255
3256         cf_cv_do_symlinks=no
3257         cf_ld_rpath_opt=
3258         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
3259
3260         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
3261         AC_ARG_WITH(shlib-version,
3262         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
3263         [test -z "$withval" && withval=auto
3264         case $withval in
3265         (yes)
3266                 cf_cv_shlib_version=auto
3267                 ;;
3268         (rel|abi|auto)
3269                 cf_cv_shlib_version=$withval
3270                 ;;
3271         (*)
3272                 AC_MSG_RESULT($withval)
3273                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
3274                 ;;
3275         esac
3276         ],[cf_cv_shlib_version=auto])
3277         AC_MSG_RESULT($cf_cv_shlib_version)
3278
3279         cf_cv_rm_so_locs=no
3280         cf_try_cflags=
3281
3282         # Some less-capable ports of gcc support only -fpic
3283         CC_SHARED_OPTS=
3284
3285         cf_try_fPIC=no
3286         if test "$GCC" = yes
3287         then
3288                 cf_try_fPIC=yes
3289         else
3290                 case $cf_cv_system_name in
3291                 (*linux*)       # e.g., PGI compiler
3292                         cf_try_fPIC=yes
3293                         ;;
3294                 esac
3295         fi
3296
3297         if test "$cf_try_fPIC" = yes
3298         then
3299                 AC_MSG_CHECKING(which $CC option to use)
3300                 cf_save_CFLAGS="$CFLAGS"
3301                 for CC_SHARED_OPTS in -fPIC -fpic ''
3302                 do
3303                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
3304                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
3305                 done
3306                 AC_MSG_RESULT($CC_SHARED_OPTS)
3307                 CFLAGS="$cf_save_CFLAGS"
3308         fi
3309
3310         cf_cv_shlib_version_infix=no
3311
3312         case $cf_cv_system_name in
3313         (aix4.[3-9]*|aix[[5-7]]*)
3314                 if test "$GCC" = yes; then
3315                         CC_SHARED_OPTS='-Wl,-brtl'
3316                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
3317                 else
3318                         CC_SHARED_OPTS='-brtl'
3319                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
3320                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
3321                 fi
3322                 ;;
3323         (beos*)
3324                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
3325                 ;;
3326         (cygwin*)
3327                 CC_SHARED_OPTS=
3328                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3329                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3330                 cf_cv_shlib_version=cygdll
3331                 cf_cv_shlib_version_infix=cygdll
3332                 shlibdir=$bindir
3333                 MAKE_DLLS=
3334                 cat >mk_shared_lib.sh <<-CF_EOF
3335                 #!$SHELL
3336                 SHARED_LIB=\[$]1
3337                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3338                 shift
3339                 cat <<-EOF
3340                 Linking shared library
3341                 ** SHARED_LIB \[$]SHARED_LIB
3342                 ** IMPORT_LIB \[$]IMPORT_LIB
3343 EOF
3344                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3345 CF_EOF
3346                 chmod +x mk_shared_lib.sh
3347                 ;;
3348         (msys*)
3349                 CC_SHARED_OPTS=
3350                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3351                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3352                 cf_cv_shlib_version=msysdll
3353                 cf_cv_shlib_version_infix=msysdll
3354                 shlibdir=$bindir
3355                 MAKE_DLLS=
3356                 cat >mk_shared_lib.sh <<-CF_EOF
3357                 #!$SHELL
3358                 SHARED_LIB=\[$]1
3359                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3360                 shift
3361                 cat <<-EOF
3362                 Linking shared library
3363                 ** SHARED_LIB \[$]SHARED_LIB
3364                 ** IMPORT_LIB \[$]IMPORT_LIB
3365 EOF
3366                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3367 CF_EOF
3368                 chmod +x mk_shared_lib.sh
3369                 ;;
3370         (darwin*)
3371                 cf_try_cflags="no-cpp-precomp"
3372                 CC_SHARED_OPTS="-dynamic"
3373                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
3374                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
3375                 cf_cv_shlib_version_infix=yes
3376                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
3377                         cf_save_LDFLAGS=$LDFLAGS
3378                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3379                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
3380                                 LDFLAGS=$cf_save_LDFLAGS])
3381                 if test $cf_cv_ldflags_search_paths_first = yes; then
3382                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
3383                 fi
3384                 ;;
3385         (hpux[[7-8]]*)
3386                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
3387                 if test "$GCC" != yes; then
3388                         CC_SHARED_OPTS='+Z'
3389                 fi
3390                 MK_SHARED_LIB='${LD} ${LDFLAGS} -b -o $[@]'
3391                 INSTALL_LIB="-m 555"
3392                 ;;
3393         (hpux*)
3394                 # (tested with gcc 2.7.2 -- I don't have c89)
3395                 if test "$GCC" = yes; then
3396                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
3397                 else
3398                         CC_SHARED_OPTS='+Z'
3399                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
3400                 fi
3401                 MK_SHARED_LIB='${LD} ${LDFLAGS} +b ${libdir} -b -o $[@]'
3402                 # HP-UX shared libraries must be executable, and should be
3403                 # readonly to exploit a quirk in the memory manager.
3404                 INSTALL_LIB="-m 555"
3405                 ;;
3406         (interix*)
3407                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3408                 if test "$cf_cv_shlib_version" = rel; then
3409                         cf_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
3410                 else
3411                         cf_shared_soname='`basename $[@]`'
3412                 fi
3413                 CC_SHARED_OPTS=
3414                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $[@]'
3415                 ;;
3416         (irix*)
3417                 if test "$cf_cv_enable_rpath" = yes ; then
3418                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3419                 fi
3420                 # tested with IRIX 5.2 and 'cc'.
3421                 if test "$GCC" != yes; then
3422                         CC_SHARED_OPTS='-KPIC'
3423                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
3424                 else
3425                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,`basename $[@]` -o $[@]'
3426                 fi
3427                 cf_cv_rm_so_locs=yes
3428                 ;;
3429         (linux*|gnu*|k*bsd*-gnu)
3430                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
3431                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3432                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3433                 fi
3434                 if test "$cf_cv_enable_rpath" = yes ; then
3435                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3436                 fi
3437                 CF_SHARED_SONAME
3438                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3439                 ;;
3440         (mingw*)
3441                 cf_cv_shlib_version=mingw
3442                 cf_cv_shlib_version_infix=mingw
3443                 shlibdir=$bindir
3444                 MAKE_DLLS=
3445                 if test "$DFT_LWR_MODEL" = "shared" ; then
3446                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
3447                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3448                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
3449                 fi
3450                 CC_SHARED_OPTS=
3451                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
3452                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
3453                 cat >mk_shared_lib.sh <<-CF_EOF
3454                 #!$SHELL
3455                 SHARED_LIB=\[$]1
3456                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
3457                 shift
3458                 cat <<-EOF
3459                 Linking shared library
3460                 ** SHARED_LIB \[$]SHARED_LIB
3461                 ** IMPORT_LIB \[$]IMPORT_LIB
3462 EOF
3463                 exec \[$]* ${LDFLAGS} -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
3464 CF_EOF
3465                 chmod +x mk_shared_lib.sh
3466                 ;;
3467         (openbsd[[2-9]].*|mirbsd*)
3468                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
3469                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3470                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3471                 fi
3472                 if test "$cf_cv_enable_rpath" = yes ; then
3473                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3474                 fi
3475                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3476                 CF_SHARED_SONAME
3477                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3478                 ;;
3479         (nto-qnx*|openbsd*|freebsd[[12]].*)
3480                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3481                 MK_SHARED_LIB='${LD} ${LDFLAGS} -Bshareable -o $[@]'
3482                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3483                 ;;
3484         (dragonfly*|freebsd*)
3485                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3486                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3487                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3488                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
3489                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3490                 fi
3491                 CF_SHARED_SONAME
3492                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
3493                 ;;
3494         (netbsd*)
3495                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
3496                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
3497                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
3498                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3499                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
3500                         if test "$cf_cv_shlib_version" = auto; then
3501                         if test -f /usr/libexec/ld.elf_so; then
3502                                 cf_cv_shlib_version=abi
3503                         else
3504                                 cf_cv_shlib_version=rel
3505                         fi
3506                         fi
3507                         CF_SHARED_SONAME
3508                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
3509                 else
3510                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -Wl,-shared -Wl,-Bshareable -o $[@]'
3511                 fi
3512                 ;;
3513         (osf*|mls+*)
3514                 # tested with OSF/1 V3.2 and 'cc'
3515                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
3516                 # link with shared libs).
3517                 MK_SHARED_LIB='${LD} ${LDFLAGS} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
3518                 case $host_os in
3519                 (osf4*)
3520                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
3521                         ;;
3522                 esac
3523                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
3524                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
3525                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
3526                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3527                 fi
3528                 cf_cv_rm_so_locs=yes
3529                 ;;
3530         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
3531                 # tested with osr5.0.5
3532                 if test "$GCC" != yes; then
3533                         CC_SHARED_OPTS='-belf -KPIC'
3534                 fi
3535                 MK_SHARED_LIB='${LD} ${LDFLAGS} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
3536                 if test "$cf_cv_enable_rpath" = yes ; then
3537                         # only way is to set LD_RUN_PATH but no switch for it
3538                         RUN_PATH=$libdir
3539                 fi
3540                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3541                 LINK_PROGS='LD_RUN_PATH=${libdir}'
3542                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
3543                 ;;
3544         (sunos4*)
3545                 # tested with SunOS 4.1.1 and gcc 2.7.0
3546                 if test "$GCC" != yes; then
3547                         CC_SHARED_OPTS='-KPIC'
3548                 fi
3549                 MK_SHARED_LIB='${LD} ${LDFLAGS} -assert pure-text -o $[@]'
3550                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
3551                 ;;
3552         (solaris2*)
3553                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
3554                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
3555                 if test "$DFT_LWR_MODEL" = "shared" ; then
3556                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
3557                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
3558                 fi
3559                 if test "$cf_cv_enable_rpath" = yes ; then
3560                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
3561                 fi
3562                 CF_SHARED_SONAME
3563                 if test "$GCC" != yes; then
3564                         cf_save_CFLAGS="$CFLAGS"
3565                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
3566                         do
3567                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
3568                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
3569                         done
3570                         CFLAGS="$cf_save_CFLAGS"
3571                         CC_SHARED_OPTS=$cf_shared_opts
3572                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3573                 else
3574                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
3575                 fi
3576                 ;;
3577         (sysv5uw7*|unix_sv*)
3578                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
3579                 if test "$GCC" != yes; then
3580                         CC_SHARED_OPTS='-KPIC'
3581                 fi
3582                 MK_SHARED_LIB='${LD} ${LDFLAGS} -d y -G -o [$]@'
3583                 ;;
3584         (*)
3585                 CC_SHARED_OPTS='unknown'
3586                 MK_SHARED_LIB='echo unknown'
3587                 ;;
3588         esac
3589
3590         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
3591         case "$cf_cv_shlib_version" in
3592         (rel|abi)
3593                 case "$MK_SHARED_LIB" in
3594                 (*'-o $[@]')
3595                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
3596                         ;;
3597                 (*)
3598                         AC_MSG_WARN(ignored --with-shlib-version)
3599                         ;;
3600                 esac
3601                 ;;
3602         esac
3603
3604         if test -n "$cf_try_cflags"
3605         then
3606 cat > conftest.$ac_ext <<EOF
3607 #line __oline__ "${as_me:-configure}"
3608 #include <stdio.h>
3609 int main(int argc, char *argv[[]])
3610 {
3611         printf("hello\n");
3612         return (argv[[argc-1]] == 0) ;
3613 }
3614 EOF
3615                 cf_save_CFLAGS="$CFLAGS"
3616                 for cf_opt in $cf_try_cflags
3617                 do
3618                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
3619                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
3620                         if AC_TRY_EVAL(ac_compile); then
3621                                 AC_MSG_RESULT(yes)
3622                                 cf_save_CFLAGS="$CFLAGS"
3623                         else
3624                                 AC_MSG_RESULT(no)
3625                         fi
3626                 done
3627                 CFLAGS="$cf_save_CFLAGS"
3628         fi
3629
3630
3631         # RPATH_LIST is a colon-separated list of directories
3632         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
3633         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
3634
3635         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
3636
3637         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
3638         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
3639
3640         AC_SUBST(CC_SHARED_OPTS)
3641         AC_SUBST(LD_RPATH_OPT)
3642         AC_SUBST(LD_SHARED_OPTS)
3643         AC_SUBST(MK_SHARED_LIB)
3644         AC_SUBST(RM_SHARED_OPTS)
3645
3646         AC_SUBST(LINK_PROGS)
3647         AC_SUBST(LINK_TESTS)
3648
3649         AC_SUBST(EXTRA_LDFLAGS)
3650         AC_SUBST(LOCAL_LDFLAGS)
3651         AC_SUBST(LOCAL_LDFLAGS2)
3652
3653         AC_SUBST(INSTALL_LIB)
3654         AC_SUBST(RPATH_LIST)
3655 ])dnl
3656 dnl ---------------------------------------------------------------------------
3657 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
3658 dnl ----------------
3659 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
3660 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
3661 dnl option.
3662 dnl
3663 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
3664 dnl If missing, use "rel".
3665 define([CF_SHARED_SONAME],
3666 [
3667         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
3668         if test "$cf_cv_shlib_version" = rel; then
3669                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
3670         else
3671                 cf_cv_shared_soname='`basename $[@]`'
3672         fi
3673 ])
3674 dnl ---------------------------------------------------------------------------
3675 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
3676 dnl --------------
3677 dnl     Remove "-g" option from the compiler options
3678 AC_DEFUN([CF_STRIP_G_OPT],
3679 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
3680 dnl ---------------------------------------------------------------------------
3681 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
3682 dnl --------------
3683 dnl Construct a search-list for a nonstandard header/lib-file
3684 dnl     $1 = the variable to return as result
3685 dnl     $2 = the package name
3686 dnl     $3 = the subdirectory, e.g., bin, include or lib
3687 AC_DEFUN([CF_SUBDIR_PATH],
3688 [
3689 $1=
3690
3691 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
3692
3693 for cf_subdir_prefix in \
3694         /usr \
3695         /usr/local \
3696         /usr/pkg \
3697         /opt \
3698         /opt/local \
3699         [$]HOME
3700 do
3701         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
3702 done
3703 ])dnl
3704 dnl ---------------------------------------------------------------------------
3705 dnl CF_TERM_HEADER version: 4 updated: 2015/04/15 19:08:48
3706 dnl --------------
3707 dnl Look for term.h, which is part of X/Open curses.  It defines the interface
3708 dnl to terminfo database.  Usually it is in the same include-path as curses.h,
3709 dnl but some packagers change this, breaking various applications.
3710 AC_DEFUN([CF_TERM_HEADER],[
3711 AC_CACHE_CHECK(for terminfo header, cf_cv_term_header,[
3712 case ${cf_cv_ncurses_header} in
3713 (*/ncurses.h|*/ncursesw.h)
3714         cf_term_header=`echo "$cf_cv_ncurses_header" | sed -e 's%ncurses[[^.]]*\.h$%term.h%'`
3715         ;;
3716 (*)
3717         cf_term_header=term.h
3718         ;;
3719 esac
3720
3721 for cf_test in $cf_term_header "ncurses/term.h" "ncursesw/term.h"
3722 do
3723 AC_TRY_COMPILE([#include <stdio.h>
3724 #include <${cf_cv_ncurses_header:-curses.h}>
3725 #include <$cf_test>
3726 ],[int x = auto_left_margin],[
3727         cf_cv_term_header="$cf_test"],[
3728         cf_cv_term_header=unknown
3729         ])
3730         test "$cf_cv_term_header" != unknown && break
3731 done
3732 ])
3733
3734 # Set definitions to allow ifdef'ing to accommodate subdirectories
3735
3736 case $cf_cv_term_header in
3737 (*term.h)
3738         AC_DEFINE(HAVE_TERM_H,1,[Define to 1 if we have term.h])
3739         ;;
3740 esac
3741
3742 case $cf_cv_term_header in
3743 (ncurses/term.h)
3744         AC_DEFINE(HAVE_NCURSES_TERM_H,1,[Define to 1 if we have ncurses/term.h])
3745         ;;
3746 (ncursesw/term.h)
3747         AC_DEFINE(HAVE_NCURSESW_TERM_H,1,[Define to 1 if we have ncursesw/term.h])
3748         ;;
3749 esac
3750 ])dnl
3751 dnl ---------------------------------------------------------------------------
3752 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
3753 dnl ---------------
3754 dnl Define a top_builddir symbol, for applications that need an absolute path.
3755 AC_DEFUN([CF_TOP_BUILDDIR],
3756 [
3757 top_builddir=ifelse($1,,`pwd`,$1)
3758 AC_SUBST(top_builddir)
3759 ])dnl
3760 dnl ---------------------------------------------------------------------------
3761 dnl CF_TRY_XOPEN_SOURCE version: 2 updated: 2018/06/20 20:23:13
3762 dnl -------------------
3763 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
3764 dnl can define it successfully.
3765 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
3766 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
3767         AC_TRY_COMPILE([
3768 #include <stdlib.h>
3769 #include <string.h>
3770 #include <sys/types.h>
3771 ],[
3772 #ifndef _XOPEN_SOURCE
3773 make an error
3774 #endif],
3775         [cf_cv_xopen_source=no],
3776         [cf_save="$CPPFLAGS"
3777          CF_APPEND_TEXT(CPPFLAGS,-D_XOPEN_SOURCE=$cf_XOPEN_SOURCE)
3778          AC_TRY_COMPILE([
3779 #include <stdlib.h>
3780 #include <string.h>
3781 #include <sys/types.h>
3782 ],[
3783 #ifdef _XOPEN_SOURCE
3784 make an error
3785 #endif],
3786         [cf_cv_xopen_source=no],
3787         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
3788         CPPFLAGS="$cf_save"
3789         ])
3790 ])
3791
3792 if test "$cf_cv_xopen_source" != no ; then
3793         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
3794         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
3795         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
3796         CF_ADD_CFLAGS($cf_temp_xopen_source)
3797 fi
3798 ])
3799 dnl ---------------------------------------------------------------------------
3800 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
3801 dnl --------
3802 dnl Make an uppercase version of a variable
3803 dnl $1=uppercase($2)
3804 AC_DEFUN([CF_UPPER],
3805 [
3806 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
3807 ])dnl
3808 dnl ---------------------------------------------------------------------------
3809 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
3810 dnl -----------
3811 dnl Check for multibyte support, and if not found, utf8 compatibility library
3812 AC_DEFUN([CF_UTF8_LIB],
3813 [
3814 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
3815         cf_save_LIBS="$LIBS"
3816         AC_TRY_LINK([
3817 #include <stdlib.h>],[putwc(0,0);],
3818         [cf_cv_utf8_lib=yes],
3819         [CF_FIND_LINKAGE([
3820 #include <libutf8.h>],[putwc(0,0);],utf8,
3821                 [cf_cv_utf8_lib=add-on],
3822                 [cf_cv_utf8_lib=no])
3823 ])])
3824
3825 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
3826 # ncurses/ncursesw:
3827 if test "$cf_cv_utf8_lib" = "add-on" ; then
3828         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
3829         CF_ADD_INCDIR($cf_cv_header_path_utf8)
3830         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
3831         CF_ADD_LIBS($cf_cv_library_file_utf8)
3832 fi
3833 ])dnl
3834 dnl ---------------------------------------------------------------------------
3835 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
3836 dnl ----------
3837 dnl Use AC_VERBOSE w/o the warnings
3838 AC_DEFUN([CF_VERBOSE],
3839 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
3840 CF_MSG_LOG([$1])
3841 ])dnl
3842 dnl ---------------------------------------------------------------------------
3843 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
3844 dnl ---------------
3845 dnl Check for compiler-support for weak symbols.
3846 dnl This works with "recent" gcc.
3847 AC_DEFUN([CF_WEAK_SYMBOLS],[
3848 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
3849
3850 AC_TRY_COMPILE([
3851 #include <stdio.h>],
3852 [
3853 #if defined(__GNUC__)
3854 #  if defined __USE_ISOC99
3855 #    define _cat_pragma(exp)    _Pragma(#exp)
3856 #    define _weak_pragma(exp)   _cat_pragma(weak name)
3857 #  else
3858 #    define _weak_pragma(exp)
3859 #  endif
3860 #  define _declare(name)        __extension__ extern __typeof__(name) name
3861 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
3862 #endif
3863
3864 weak_symbol(fopen);
3865 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
3866 ])
3867 ])dnl
3868 dnl ---------------------------------------------------------------------------
3869 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
3870 dnl --------------------
3871 dnl Command-line option to specify the Ada95 compiler.
3872 AC_DEFUN([CF_WITH_ADA_COMPILER],[
3873 AC_MSG_CHECKING(for ada-compiler)
3874 AC_ARG_WITH(ada-compiler,
3875         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
3876         [cf_ada_compiler=$withval],
3877         [cf_ada_compiler=gnatmake])
3878 AC_SUBST(cf_ada_compiler)
3879 AC_MSG_RESULT($cf_ada_compiler)
3880 ])dnl
3881 dnl ---------------------------------------------------------------------------
3882 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
3883 dnl -------------------
3884 dnl Command-line option to specify where Ada includes will install.
3885 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
3886 AC_MSG_CHECKING(for ada-include)
3887 CF_WITH_PATH(ada-include,
3888    [  --with-ada-include=DIR  Ada includes are in DIR],
3889    ADA_INCLUDE,
3890    PREFIX/share/ada/adainclude,
3891    [$]prefix/share/ada/adainclude)
3892 AC_SUBST(ADA_INCLUDE)
3893 AC_MSG_RESULT($ADA_INCLUDE)
3894 ])dnl
3895 dnl ---------------------------------------------------------------------------
3896 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
3897 dnl -------------------
3898 dnl Command-line option to specify where Ada objects will install.
3899 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
3900 AC_MSG_CHECKING(for ada-objects)
3901 CF_WITH_PATH(ada-objects,
3902    [  --with-ada-objects=DIR  Ada objects are in DIR],
3903    ADA_OBJECTS,
3904    PREFIX/lib/ada/adalib,
3905    [$]prefix/lib/ada/adalib)
3906 AC_SUBST(ADA_OBJECTS)
3907 AC_MSG_RESULT($ADA_OBJECTS)
3908 ])dnl
3909 dnl ---------------------------------------------------------------------------
3910 dnl CF_WITH_ADA_SHAREDLIB version: 5 updated: 2018/07/21 19:10:35
3911 dnl ---------------------
3912 dnl Command-line option to specify if an Ada95 shared-library should be built,
3913 dnl and optionally what its soname should be.
3914 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
3915 AC_REQUIRE([CF_GNAT_PROJECTS])
3916 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
3917 AC_ARG_WITH(ada-sharedlib,
3918         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
3919         [with_ada_sharedlib=$withval],
3920         [with_ada_sharedlib=no])
3921 AC_MSG_RESULT($with_ada_sharedlib)
3922
3923 if test "x$with_ada_sharedlib" != xno
3924 then
3925         if test "x$cf_gnat_projects" != xyes
3926         then
3927                 AC_MSG_WARN(disabling shared-library since GNAT projects are not supported)
3928                 with_ada_sharedlib=no
3929         fi
3930 fi
3931
3932 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
3933 MAKE_ADA_SHAREDLIB="#"
3934
3935 if test "x$with_ada_sharedlib" != xno
3936 then
3937         MAKE_ADA_SHAREDLIB=
3938         if test "x$with_ada_sharedlib" != xyes
3939         then
3940                 ADA_SHAREDLIB="$with_ada_sharedlib"
3941         fi
3942 fi
3943
3944 AC_SUBST(ADA_SHAREDLIB)
3945 AC_SUBST(MAKE_ADA_SHAREDLIB)
3946 ])dnl
3947 dnl ---------------------------------------------------------------------------
3948 dnl CF_WITH_CURSES_DIR version: 3 updated: 2010/11/20 17:02:38
3949 dnl ------------------
3950 dnl Wrapper for AC_ARG_WITH to specify directory under which to look for curses
3951 dnl libraries.
3952 AC_DEFUN([CF_WITH_CURSES_DIR],[
3953
3954 AC_MSG_CHECKING(for specific curses-directory)
3955 AC_ARG_WITH(curses-dir,
3956         [  --with-curses-dir=DIR   directory in which (n)curses is installed],
3957         [cf_cv_curses_dir=$withval],
3958         [cf_cv_curses_dir=no])
3959 AC_MSG_RESULT($cf_cv_curses_dir)
3960
3961 if ( test -n "$cf_cv_curses_dir" && test "$cf_cv_curses_dir" != "no" )
3962 then
3963         CF_PATH_SYNTAX(withval)
3964         if test -d "$cf_cv_curses_dir"
3965         then
3966                 CF_ADD_INCDIR($cf_cv_curses_dir/include)
3967                 CF_ADD_LIBDIR($cf_cv_curses_dir/lib)
3968         fi
3969 fi
3970 ])dnl
3971 dnl ---------------------------------------------------------------------------
3972 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
3973 dnl ------------------
3974 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
3975 dnl "lib" prefix, e.g., because it used the dll naming convention.
3976 dnl
3977 dnl $1 = variable to set
3978 AC_DEFUN([CF_WITH_LIB_PREFIX],
3979 [
3980 AC_MSG_CHECKING(if you want to have a library-prefix)
3981 AC_ARG_WITH(lib-prefix,
3982         [  --with-lib-prefix       override library-prefix],
3983         [with_lib_prefix=$withval],
3984         [with_lib_prefix=auto])
3985 AC_MSG_RESULT($with_lib_prefix)
3986
3987 if test $with_lib_prefix = auto
3988 then
3989         CF_LIB_PREFIX($1)
3990 elif test $with_lib_prefix = no
3991 then
3992         LIB_PREFIX=
3993 else
3994         LIB_PREFIX=$with_lib_prefix
3995 fi
3996 ])dnl
3997 dnl ---------------------------------------------------------------------------
3998 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
3999 dnl ------------
4000 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
4001 dnl defaulting to yes/no.
4002 dnl
4003 dnl $1 = option name
4004 dnl $2 = help-text
4005 dnl $3 = environment variable to set
4006 dnl $4 = default value, shown in the help-message, must be a constant
4007 dnl $5 = default value, if it's an expression & cannot be in the help-message
4008 dnl
4009 AC_DEFUN([CF_WITH_PATH],
4010 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
4011 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
4012 if ifelse([$5],,true,[test -n "$5"]) ; then
4013 CF_PATH_SYNTAX(withval)
4014 fi
4015 eval $3="$withval"
4016 AC_SUBST($3)dnl
4017 ])dnl
4018 dnl ---------------------------------------------------------------------------
4019 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 10 updated: 2015/08/22 17:10:56
4020 dnl -------------------------
4021 dnl Allow the choice of the pkg-config library directory to be overridden.
4022 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
4023
4024 case $PKG_CONFIG in
4025 (no|none|yes)
4026         AC_MSG_CHECKING(for pkg-config library directory)
4027         ;;
4028 (*)
4029         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
4030         ;;
4031 esac
4032
4033 PKG_CONFIG_LIBDIR=no
4034 AC_ARG_WITH(pkg-config-libdir,
4035         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
4036         [PKG_CONFIG_LIBDIR=$withval],
4037         [test "x$PKG_CONFIG" != xnone && PKG_CONFIG_LIBDIR=yes])
4038
4039 case x$PKG_CONFIG_LIBDIR in
4040 (x/*)
4041         ;;
4042 (xyes)
4043         # Look for the library directory using the same prefix as the executable
4044         if test "x$PKG_CONFIG" = xnone
4045         then
4046                 cf_path=$prefix
4047         else
4048                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
4049         fi
4050
4051         # If you don't like using the default architecture, you have to specify the
4052         # intended library directory and corresponding compiler/linker options.
4053         #
4054         # This case allows for Debian's 2014-flavor of multiarch, along with the
4055         # most common variations before that point.  Some other variants spell the
4056         # directory differently, e.g., "pkg-config", and put it in unusual places.
4057         # pkg-config has always been poorly standardized, which is ironic...
4058         case x`(arch) 2>/dev/null` in
4059         (*64)
4060                 cf_search_path="\
4061                         $cf_path/lib/*64-linux-gnu \
4062                         $cf_path/share \
4063                         $cf_path/lib64 \
4064                         $cf_path/lib32 \
4065                         $cf_path/lib"
4066                 ;;
4067         (*)
4068                 cf_search_path="\
4069                         $cf_path/lib/*-linux-gnu \
4070                         $cf_path/share \
4071                         $cf_path/lib32 \
4072                         $cf_path/lib \
4073                         $cf_path/libdata"
4074                 ;;
4075         esac
4076
4077         CF_VERBOSE(list...)
4078         for cf_config in $cf_search_path
4079         do
4080                 CF_VERBOSE(checking $cf_config/pkgconfig)
4081                 if test -d $cf_config/pkgconfig
4082                 then
4083                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
4084                         AC_MSG_CHECKING(done)
4085                         break
4086                 fi
4087         done
4088         ;;
4089 (*)
4090         ;;
4091 esac
4092
4093 if test "x$PKG_CONFIG_LIBDIR" != xno ; then
4094         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
4095 fi
4096
4097 AC_SUBST(PKG_CONFIG_LIBDIR)
4098 ])dnl
4099 dnl ---------------------------------------------------------------------------
4100 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
4101 dnl ---------------
4102 dnl Check for POSIX thread library.
4103 AC_DEFUN([CF_WITH_PTHREAD],
4104 [
4105 AC_MSG_CHECKING(if you want to link with the pthread library)
4106 AC_ARG_WITH(pthread,
4107         [  --with-pthread          use POSIX thread library],
4108         [with_pthread=$withval],
4109         [with_pthread=no])
4110 AC_MSG_RESULT($with_pthread)
4111
4112 if test "$with_pthread" != no ; then
4113         AC_CHECK_HEADER(pthread.h,[
4114         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
4115
4116         for cf_lib_pthread in pthread c_r
4117         do
4118             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
4119             cf_save_LIBS="$LIBS"
4120             CF_ADD_LIB($cf_lib_pthread)
4121             AC_TRY_LINK([
4122 #include <pthread.h>
4123 ],[
4124                 int rc = pthread_create(0,0,0,0);
4125                 int r2 = pthread_mutexattr_settype(0, 0);
4126 ],[with_pthread=yes],[with_pthread=no])
4127             LIBS="$cf_save_LIBS"
4128             AC_MSG_RESULT($with_pthread)
4129             test "$with_pthread" = yes && break
4130         done
4131
4132         if test "$with_pthread" = yes ; then
4133             CF_ADD_LIB($cf_lib_pthread)
4134             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
4135         else
4136             AC_MSG_ERROR(Cannot link with pthread library)
4137         fi
4138         ])
4139 fi
4140 ])
4141 dnl ---------------------------------------------------------------------------
4142 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
4143 dnl ---------------
4144 dnl For testing, override the derived host system-type which is used to decide
4145 dnl things such as the linker commands used to build shared libraries.  This is
4146 dnl normally chosen automatically based on the type of system which you are
4147 dnl building on.  We use it for testing the configure script.
4148 dnl
4149 dnl This is different from the --host option: it is used only for testing parts
4150 dnl of the configure script which would not be reachable with --host since that
4151 dnl relies on the build environment being real, rather than mocked up.
4152 AC_DEFUN([CF_WITH_SYSTYPE],[
4153 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
4154 AC_ARG_WITH(system-type,
4155         [  --with-system-type=XXX  test: override derived host system-type],
4156 [AC_MSG_WARN(overriding system type to $withval)
4157         cf_cv_system_name=$withval
4158         host_os=$withval
4159 ])
4160 ])dnl
4161 dnl ---------------------------------------------------------------------------
4162 dnl CF_XOPEN_SOURCE version: 54 updated: 2018/11/07 07:43:44
4163 dnl ---------------
4164 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
4165 dnl or adapt to the vendor's definitions to get equivalent functionality,
4166 dnl without losing the common non-POSIX features.
4167 dnl
4168 dnl Parameters:
4169 dnl     $1 is the nominal value for _XOPEN_SOURCE
4170 dnl     $2 is the nominal value for _POSIX_C_SOURCE
4171 AC_DEFUN([CF_XOPEN_SOURCE],[
4172 AC_REQUIRE([AC_CANONICAL_HOST])
4173
4174 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
4175 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
4176 cf_xopen_source=
4177
4178 case $host_os in
4179 (aix[[4-7]]*)
4180         cf_xopen_source="-D_ALL_SOURCE"
4181         ;;
4182 (msys)
4183         cf_XOPEN_SOURCE=600
4184         ;;
4185 (darwin[[0-8]].*)
4186         cf_xopen_source="-D_APPLE_C_SOURCE"
4187         ;;
4188 (darwin*)
4189         cf_xopen_source="-D_DARWIN_C_SOURCE"
4190         cf_XOPEN_SOURCE=
4191         ;;
4192 (freebsd*|dragonfly*|midnightbsd*)
4193         # 5.x headers associate
4194         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
4195         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
4196         cf_POSIX_C_SOURCE=200112L
4197         cf_XOPEN_SOURCE=600
4198         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
4199         ;;
4200 (hpux11*)
4201         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
4202         ;;
4203 (hpux*)
4204         cf_xopen_source="-D_HPUX_SOURCE"
4205         ;;
4206 (irix[[56]].*)
4207         cf_xopen_source="-D_SGI_SOURCE"
4208         cf_XOPEN_SOURCE=
4209         ;;
4210 (linux*|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin)
4211         CF_GNU_SOURCE($cf_XOPEN_SOURCE)
4212         ;;
4213 (minix*)
4214         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
4215         ;;
4216 (mirbsd*)
4217         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
4218         cf_XOPEN_SOURCE=
4219         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
4220         ;;
4221 (netbsd*)
4222         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
4223         ;;
4224 (openbsd[[4-9]]*)
4225         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
4226         cf_xopen_source="-D_BSD_SOURCE"
4227         cf_XOPEN_SOURCE=600
4228         ;;
4229 (openbsd*)
4230         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
4231         ;;
4232 (osf[[45]]*)
4233         cf_xopen_source="-D_OSF_SOURCE"
4234         ;;
4235 (nto-qnx*)
4236         cf_xopen_source="-D_QNX_SOURCE"
4237         ;;
4238 (sco*)
4239         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
4240         ;;
4241 (solaris2.*)
4242         cf_xopen_source="-D__EXTENSIONS__"
4243         cf_cv_xopen_source=broken
4244         ;;
4245 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
4246         cf_XOPEN_SOURCE=
4247         cf_POSIX_C_SOURCE=
4248         ;;
4249 (*)
4250         CF_TRY_XOPEN_SOURCE
4251         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
4252         ;;
4253 esac
4254
4255 if test -n "$cf_xopen_source" ; then
4256         CF_ADD_CFLAGS($cf_xopen_source,true)
4257 fi
4258
4259 dnl In anything but the default case, we may have system-specific setting
4260 dnl which is still not guaranteed to provide all of the entrypoints that
4261 dnl _XOPEN_SOURCE would yield.
4262 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
4263         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
4264         AC_TRY_COMPILE([#include <stdlib.h>],[
4265 #ifndef _XOPEN_SOURCE
4266 make an error
4267 #endif],
4268         [cf_XOPEN_SOURCE_set=yes],
4269         [cf_XOPEN_SOURCE_set=no])
4270         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
4271         if test $cf_XOPEN_SOURCE_set = yes
4272         then
4273                 AC_TRY_COMPILE([#include <stdlib.h>],[
4274 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
4275 make an error
4276 #endif],
4277                 [cf_XOPEN_SOURCE_set_ok=yes],
4278                 [cf_XOPEN_SOURCE_set_ok=no])
4279                 if test $cf_XOPEN_SOURCE_set_ok = no
4280                 then
4281                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
4282                 fi
4283         else
4284                 CF_TRY_XOPEN_SOURCE
4285         fi
4286 fi
4287 ])