Ada95/samples/sample-header_handler.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                       GNAT ncurses Binding Samples                       --
   4 --                                                                          --
   5 --                            Sample.Header_Handler                         --
   6 --                                                                          --
   7 --                                 B O D Y                                  --
   8 --                                                                          --
   9 ------------------------------------------------------------------------------
  10 -- Copyright (c) 1998-2009,2011 Free Software Foundation, Inc.              --
  11 --                                                                          --
  12 -- Permission is hereby granted, free of charge, to any person obtaining a  --
  13 -- copy of this software and associated documentation files (the            --
  14 -- "Software"), to deal in the Software without restriction, including      --
  15 -- without limitation the rights to use, copy, modify, merge, publish,      --
  16 -- distribute, distribute with modifications, sublicense, and/or sell       --
  17 -- copies of the Software, and to permit persons to whom the Software is    --
  18 -- furnished to do so, subject to the following conditions:                 --
  19 --                                                                          --
  20 -- The above copyright notice and this permission notice shall be included  --
  21 -- in all copies or substantial portions of the Software.                   --
  22 --                                                                          --
  23 -- THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  --
  24 -- OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               --
  25 -- MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   --
  26 -- IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   --
  27 -- DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    --
  28 -- OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    --
  29 -- THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               --
  30 --                                                                          --
  31 -- Except as contained in this notice, the name(s) of the above copyright   --
  32 -- holders shall not be used in advertising or otherwise to promote the     --
  33 -- sale, use or other dealings in this Software without prior written       --
  34 -- authorization.                                                           --
  35 ------------------------------------------------------------------------------
  36 --  Author:  Juergen Pfeifer, 1996
  37 --  Version Control
  38 --  $Revision: 1.19 $
  39 --  $Date: 2011/03/22 23:54:38 $
  40 --  Binding Version 01.00
  41 ------------------------------------------------------------------------------
  42 with Ada.Calendar; use Ada.Calendar;
  43 with Terminal_Interface.Curses.Text_IO.Integer_IO;
  44 with Sample.Manifest; use Sample.Manifest;
  45
  46 pragma Elaborate_All (Terminal_Interface.Curses.Text_Io.Integer_IO);
  47
  48 --  This package handles the painting of the header line of the screen.
  49 --
  50 package body Sample.Header_Handler is
  51
  52    package Int_IO is new
  53      Terminal_Interface.Curses.Text_IO.Integer_IO (Integer);
  54    use Int_IO;
  55
  56    Header_Window : Window := Null_Window;
  57
  58    Display_Hour  : Integer := -1; -- hour last displayed
  59    Display_Min   : Integer := -1; -- minute last displayed
  60    Display_Day   : Integer := -1; -- day last displayed
  61    Display_Month : Integer := -1; -- month last displayed
  62
  63    --  This is the routine handed over to the curses library to be called
  64    --  as initialization routine when ripping of the header lines from
  65    --  the screen. This routine must follow C conventions.
  66    function Init_Header_Window (Win     : Window;
  67                                 Columns : Column_Count) return Integer;
  68    pragma Convention (C, Init_Header_Window);
  69
  70    procedure Internal_Update_Header_Window (Do_Update : Boolean);
  71
  72    --  The initialization must be called before Init_Screen. It steals two
  73    --  lines from the top of the screen.
  74    procedure Init_Header_Handler
  75    is
  76    begin
  77       Rip_Off_Lines (2, Init_Header_Window'Access);
  78    end Init_Header_Handler;
  79
  80    procedure N_Out (N : Integer);
  81
  82    --  Emit a two digit number and ensure that a leading zero is generated if
  83    --  necessary.
  84    procedure N_Out (N : Integer)
  85    is
  86    begin
  87       if N < 10 then
  88          Add (Header_Window, '0');
  89          Put (Header_Window, N, 1);
  90       else
  91          Put (Header_Window, N, 2);
  92       end if;
  93    end N_Out;
  94
  95    --  Paint the header window. The input parameter is a flag indicating
  96    --  whether or not the screen should be updated physically after painting.
  97    procedure Internal_Update_Header_Window (Do_Update : Boolean)
  98    is
  99       type Month_Name_Array is
 100          array (Month_Number'First .. Month_Number'Last) of String (1 .. 9);
 101
 102       Month_Names : constant Month_Name_Array :=
 103         ("January  ",
 104          "February ",
 105          "March    ",
 106          "April    ",
 107          "May      ",
 108          "June     ",
 109          "July     ",
 110          "August   ",
 111          "September",
 112          "October  ",
 113          "November ",
 114          "December ");
 115
 116       Now    : constant Time         := Clock;
 117       Sec    : constant Integer      := Integer (Seconds (Now));
 118       Hour   : constant Integer      := Sec / 3600;
 119       Minute : constant Integer      := (Sec - Hour * 3600) / 60;
 120       Mon    : constant Month_Number := Month (Now);
 121       D      : constant Day_Number   := Day (Now);
 122    begin
 123       if Header_Window /= Null_Window then
 124          if Minute /= Display_Min or else Hour /= Display_Hour
 125            or else Display_Day /= D or else Display_Month /= Mon then
 126             Move_Cursor (Header_Window, 0, 0);
 127             N_Out (D); Add (Header_Window, '.');
 128             Add (Header_Window, Month_Names (Mon));
 129             Move_Cursor (Header_Window, 1, 0);
 130             N_Out (Hour); Add (Header_Window, ':');
 131             N_Out (Minute);
 132             Display_Min   := Minute;
 133             Display_Hour  := Hour;
 134             Display_Month := Mon;
 135             Display_Day   := D;
 136             Refresh_Without_Update (Header_Window);
 137             if Do_Update then
 138                Update_Screen;
 139             end if;
 140          end if;
 141       end if;
 142    end Internal_Update_Header_Window;
 143
 144    --  This routine is called in the keyboard input timeout handler. So it will
 145    --  periodically update the header line of the screen.
 146    procedure Update_Header_Window
 147    is
 148    begin
 149       Internal_Update_Header_Window (True);
 150    end Update_Header_Window;
 151
 152    function Init_Header_Window (Win     : Window;
 153                                 Columns : Column_Count) return Integer
 154    is
 155       Title  : constant String := "Ada 95 ncurses Binding Sample";
 156       Pos    : Column_Position;
 157    begin
 158       Header_Window := Win;
 159       if Win /= Null_Window then
 160          if Has_Colors then
 161             Set_Background (Win => Win,
 162                             Ch  => (Ch    => ' ',
 163                                     Color => Header_Color,
 164                                     Attr  => Normal_Video));
 165             Set_Character_Attributes (Win   => Win,
 166                                       Attr  => Normal_Video,
 167                                       Color => Header_Color);
 168             Erase (Win);
 169          end if;
 170          Leave_Cursor_After_Update (Win, True);
 171          Pos := Columns - Column_Position (Title'Length);
 172          Add (Win, 0, Pos / 2, Title);
 173          --  In this phase we must not allow a physical update, because
 174          --  ncurses is not properly initialized at this point.
 175          Internal_Update_Header_Window (False);
 176          return 0;
 177       else
 178          return -1;
 179       end if;
 180    end Init_Header_Window;
 181
 182 end Sample.Header_Handler;