c2b52a05903dece1d9a302ce9cb953e149dbd56a
[ncurses.git] / Ada95 / src / terminal_interface-curses-mouse.adb
1 ------------------------------------------------------------------------------
2 --                                                                          --
3 --                           GNAT ncurses Binding                           --
4 --                                                                          --
5 --                     Terminal_Interface.Curses.Mouse                      --
6 --                                                                          --
7 --                                 B O D Y                                  --
8 --                                                                          --
9 ------------------------------------------------------------------------------
10 -- Copyright (c) 1998 Free Software Foundation, Inc.                        --
11 --                                                                          --
12 -- Permission is hereby granted, free of charge, to any person obtaining a  --
13 -- copy of this software and associated documentation files (the            --
14 -- "Software"), to deal in the Software without restriction, including      --
15 -- without limitation the rights to use, copy, modify, merge, publish,      --
16 -- distribute, distribute with modifications, sublicense, and/or sell       --
17 -- copies of the Software, and to permit persons to whom the Software is    --
18 -- furnished to do so, subject to the following conditions:                 --
19 --                                                                          --
20 -- The above copyright notice and this permission notice shall be included  --
21 -- in all copies or substantial portions of the Software.                   --
22 --                                                                          --
23 -- THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  --
24 -- OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               --
25 -- MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   --
26 -- IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   --
27 -- DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    --
28 -- OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    --
29 -- THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               --
30 --                                                                          --
31 -- Except as contained in this notice, the name(s) of the above copyright   --
32 -- holders shall not be used in advertising or otherwise to promote the     --
33 -- sale, use or other dealings in this Software without prior written       --
34 -- authorization.                                                           --
35 ------------------------------------------------------------------------------
36 --  Author:  Juergen Pfeifer, 1996
37 --  Contact: http://www.familiepfeifer.de/Contact.aspx?Lang=en
38 --  Version Control:
39 --  $Revision: 1.17 $
40 --  Binding Version 01.00
41 ------------------------------------------------------------------------------
42 with System;
43
44 with Terminal_Interface.Curses.Aux; use Terminal_Interface.Curses.Aux;
45 with Interfaces.C; use Interfaces.C;
46 use Interfaces;
47
48 package body Terminal_Interface.Curses.Mouse is
49
50    use type System.Bit_Order;
51    use type Interfaces.C.int;
52
53    function Has_Mouse return Boolean
54    is
55       function Mouse_Avail return C_Int;
56       pragma Import (C, Mouse_Avail, "_nc_has_mouse");
57    begin
58       if Has_Key (Key_Mouse) or else Mouse_Avail /= 0 then
59          return True;
60       else
61          return False;
62       end if;
63    end Has_Mouse;
64
65    function Get_Mouse return Mouse_Event
66    is
67       type Event_Access is access all Mouse_Event;
68
69       function Getmouse (Ev : Event_Access) return C_Int;
70       pragma Import (C, Getmouse, "getmouse");
71
72       Event : aliased Mouse_Event;
73    begin
74       if Getmouse (Event'Access) = Curses_Err then
75          raise Curses_Exception;
76       end if;
77       return Event;
78    end Get_Mouse;
79
80    procedure Register_Reportable_Event (Button : in Mouse_Button;
81                                         State  : in Button_State;
82                                         Mask   : in out Event_Mask)
83    is
84       Button_Nr : constant Natural := Mouse_Button'Pos (Button);
85       State_Nr  : constant Natural := Button_State'Pos (State);
86    begin
87       if Button in Modifier_Keys and then State /= Pressed then
88          raise Curses_Exception;
89       else
90          if Button in Real_Buttons then
91             Mask := Mask or ((2 ** (6 * Button_Nr)) ** State_Nr);
92          else
93             Mask := Mask or (BUTTON_CTRL ** (Button_Nr - 4));
94          end if;
95       end if;
96    end Register_Reportable_Event;
97
98    procedure Register_Reportable_Events (Button : in Mouse_Button;
99                                          State  : in Button_States;
100                                          Mask   : in out Event_Mask)
101    is
102    begin
103       for S in Button_States'Range loop
104          if State (S) then
105             Register_Reportable_Event (Button, S, Mask);
106          end if;
107       end loop;
108    end Register_Reportable_Events;
109
110    function Start_Mouse (Mask : Event_Mask := All_Events)
111                          return Event_Mask
112    is
113       function MMask (M : Event_Mask;
114                       O : access Event_Mask) return Event_Mask;
115       pragma Import (C, MMask, "mousemask");
116       R   : Event_Mask;
117       Old : aliased Event_Mask;
118    begin
119       R := MMask (Mask, Old'Access);
120       return Old;
121    end Start_Mouse;
122
123    procedure End_Mouse (Mask : in Event_Mask := No_Events)
124    is
125    begin
126       null;
127    end End_Mouse;
128
129    procedure Dispatch_Event (Mask   : in  Event_Mask;
130                              Button : out Mouse_Button;
131                              State  : out Button_State);
132
133    procedure Dispatch_Event (Mask   : in  Event_Mask;
134                              Button : out Mouse_Button;
135                              State  : out Button_State) is
136       L : Event_Mask;
137    begin
138       Button := Alt;  --  preset to non real button;
139       if (Mask and BUTTON1_EVENTS) /= 0 then
140          Button := Left;
141       elsif (Mask and BUTTON2_EVENTS) /= 0 then
142          Button := Middle;
143       elsif (Mask and BUTTON3_EVENTS) /= 0 then
144          Button := Right;
145       elsif (Mask and BUTTON4_EVENTS) /= 0 then
146          Button := Button4;
147       end if;
148       if Button in Real_Buttons then
149          L := 2 ** (6 * Mouse_Button'Pos (Button));
150          for I in Button_State'Range loop
151             if (Mask and L) /= 0 then
152                State := I;
153                exit;
154             end if;
155             L := 2 * L;
156          end loop;
157       else
158          State := Pressed;
159          if (Mask and BUTTON_CTRL) /= 0 then
160             Button := Control;
161          elsif (Mask and BUTTON_SHIFT) /= 0 then
162             Button := Shift;
163          elsif (Mask and BUTTON_ALT) /= 0 then
164             Button := Alt;
165          end if;
166       end if;
167    end Dispatch_Event;
168
169    procedure Get_Event (Event  : in  Mouse_Event;
170                         Y      : out Line_Position;
171                         X      : out Column_Position;
172                         Button : out Mouse_Button;
173                         State  : out Button_State)
174    is
175       Mask  : constant Event_Mask := Event.Bstate;
176    begin
177       X := Column_Position (Event.X);
178       Y := Line_Position   (Event.Y);
179       Dispatch_Event (Mask, Button, State);
180    end Get_Event;
181
182    procedure Unget_Mouse (Event : in Mouse_Event)
183    is
184       function Ungetmouse (Ev : Mouse_Event) return C_Int;
185       pragma Import (C, Ungetmouse, "ungetmouse");
186    begin
187       if Ungetmouse (Event) = Curses_Err then
188          raise Curses_Exception;
189       end if;
190    end Unget_Mouse;
191
192    function Enclosed_In_Window (Win    : Window := Standard_Window;
193                                 Event  : Mouse_Event) return Boolean
194    is
195       function Wenclose (Win : Window; Y : C_Int; X : C_Int)
196                          return Curses_Bool;
197       pragma Import (C, Wenclose, "wenclose");
198    begin
199       if Wenclose (Win, C_Int (Event.Y), C_Int (Event.X))
200         = Curses_Bool_False then
201          return False;
202       else
203          return True;
204       end if;
205    end Enclosed_In_Window;
206
207    function Mouse_Interval (Msec : Natural := 200) return Natural
208    is
209       function Mouseinterval (Msec : C_Int) return C_Int;
210       pragma Import (C, Mouseinterval, "mouseinterval");
211    begin
212       return Natural (Mouseinterval (C_Int (Msec)));
213    end Mouse_Interval;
214
215 end Terminal_Interface.Curses.Mouse;