aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2013,2014 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.704 2014/07/26 22:56:21 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 3 updated: 2002/10/27 23:21:42
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54     [AC_TRY_LINK([#include <langinfo.h>],
  55       [char* cs = nl_langinfo(CODESET);],
  56       am_cv_langinfo_codeset=yes,
  57       am_cv_langinfo_codeset=no)
  58     ])
  59   if test $am_cv_langinfo_codeset = yes; then
  60     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62   fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
  66 dnl ------------------
  67 dnl Conditionally generate script according to whether we're using a given autoconf.
  68 dnl
  69 dnl $1 = version to compare against
  70 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  71 dnl $3 = code to use if AC_ACVERSION is older than $1.
  72 define([CF_ACVERSION_CHECK],
  73 [
  74 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
  75 ifdef([m4_version_compare],
  76 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  77 [CF_ACVERSION_COMPARE(
  78 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  79 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  80 dnl ---------------------------------------------------------------------------
  81 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
  82 dnl --------------------
  83 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  84 dnl                      MAJOR2, MINOR2, TERNARY2,
  85 dnl                      PRINTABLE2, not FOUND, FOUND)
  86 define([CF_ACVERSION_COMPARE],
  87 [ifelse(builtin([eval], [$2 < $5]), 1,
  88 [ifelse([$8], , ,[$8])],
  89 [ifelse([$9], , ,[$9])])])dnl
  90 dnl ---------------------------------------------------------------------------
  91 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
  92 dnl -------------------
  93 dnl Construct the list of include-options for the C programs in the Ada95
  94 dnl binding.
  95 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  96 [
  97 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  98 if test "$srcdir" != "."; then
  99         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 100 fi
 101 if test "$GCC" != yes; then
 102         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 103 elif test "$includedir" != "/usr/include"; then
 104         if test "$includedir" = '${prefix}/include' ; then
 105                 if test x$prefix != x/usr ; then
 106                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 107                 fi
 108         else
 109                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 110         fi
 111 fi
 112 AC_SUBST(ACPPFLAGS)
 113 ])dnl
 114 dnl ---------------------------------------------------------------------------
 115 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 116 dnl ---------------
 117 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 118 AC_DEFUN([CF_ADD_ADAFLAGS],[
 119         ADAFLAGS="$ADAFLAGS $1"
 120         AC_SUBST(ADAFLAGS)
 121 ])dnl
 122 dnl ---------------------------------------------------------------------------
 123 dnl CF_ADD_CFLAGS version: 11 updated: 2014/07/22 05:32:57
 124 dnl -------------
 125 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 126 dnl The second parameter if given makes this macro verbose.
 127 dnl
 128 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 129 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 130 dnl confused by the quotes (which require backslashes to keep them usable).
 131 AC_DEFUN([CF_ADD_CFLAGS],
 132 [
 133 cf_fix_cppflags=no
 134 cf_new_cflags=
 135 cf_new_cppflags=
 136 cf_new_extra_cppflags=
 137
 138 for cf_add_cflags in $1
 139 do
 140 case $cf_fix_cppflags in
 141 no)
 142         case $cf_add_cflags in #(vi
 143         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
 144                 case $cf_add_cflags in
 145                 -D*)
 146                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 147
 148                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 149                                 && test -z "${cf_tst_cflags}" \
 150                                 && cf_fix_cppflags=yes
 151
 152                         if test $cf_fix_cppflags = yes ; then
 153                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 154                                 continue
 155                         elif test "${cf_tst_cflags}" = "\"'" ; then
 156                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 157                                 continue
 158                         fi
 159                         ;;
 160                 esac
 161                 case "$CPPFLAGS" in
 162                 *$cf_add_cflags) #(vi
 163                         ;;
 164                 *) #(vi
 165                         case $cf_add_cflags in #(vi
 166                         -D*)
 167                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 168                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 169                                 ;;
 170                         esac
 171                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 172                         ;;
 173                 esac
 174                 ;;
 175         *)
 176                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 177                 ;;
 178         esac
 179         ;;
 180 yes)
 181         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 182
 183         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 184
 185         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 186                 && test -z "${cf_tst_cflags}" \
 187                 && cf_fix_cppflags=no
 188         ;;
 189 esac
 190 done
 191
 192 if test -n "$cf_new_cflags" ; then
 193         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 194         CFLAGS="$CFLAGS $cf_new_cflags"
 195 fi
 196
 197 if test -n "$cf_new_cppflags" ; then
 198         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 199         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 200 fi
 201
 202 if test -n "$cf_new_extra_cppflags" ; then
 203         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 204         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 205 fi
 206
 207 AC_SUBST(EXTRA_CPPFLAGS)
 208
 209 ])dnl
 210 dnl ---------------------------------------------------------------------------
 211 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
 212 dnl -------------
 213 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 214 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 215 dnl but old versions (and some misinstalled ones) need that.  To make things
 216 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 217 dnl the include-path).
 218 AC_DEFUN([CF_ADD_INCDIR],
 219 [
 220 if test -n "$1" ; then
 221   for cf_add_incdir in $1
 222   do
 223         while test $cf_add_incdir != /usr/include
 224         do
 225           if test -d $cf_add_incdir
 226           then
 227                 cf_have_incdir=no
 228                 if test -n "$CFLAGS$CPPFLAGS" ; then
 229                   # a loop is needed to ensure we can add subdirs of existing dirs
 230                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 231                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 232                           cf_have_incdir=yes; break
 233                         fi
 234                   done
 235                 fi
 236
 237                 if test "$cf_have_incdir" = no ; then
 238                   if test "$cf_add_incdir" = /usr/local/include ; then
 239                         if test "$GCC" = yes
 240                         then
 241                           cf_save_CPPFLAGS=$CPPFLAGS
 242                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 243                           AC_TRY_COMPILE([#include <stdio.h>],
 244                                   [printf("Hello")],
 245                                   [],
 246                                   [cf_have_incdir=yes])
 247                           CPPFLAGS=$cf_save_CPPFLAGS
 248                         fi
 249                   fi
 250                 fi
 251
 252                 if test "$cf_have_incdir" = no ; then
 253                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 254                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 255
 256                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 257                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 258                   cf_add_incdir="$cf_top_incdir"
 259                 else
 260                   break
 261                 fi
 262           fi
 263         done
 264   done
 265 fi
 266 ])dnl
 267 dnl ---------------------------------------------------------------------------
 268 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 269 dnl ----------
 270 dnl Add a library, used to enforce consistency.
 271 dnl
 272 dnl $1 = library to add, without the "-l"
 273 dnl $2 = variable to update (default $LIBS)
 274 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 275 dnl ---------------------------------------------------------------------------
 276 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
 277 dnl -------------
 278 dnl     Adds to the library-path
 279 dnl
 280 dnl     Some machines have trouble with multiple -L options.
 281 dnl
 282 dnl $1 is the (list of) directory(s) to add
 283 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 284 dnl
 285 AC_DEFUN([CF_ADD_LIBDIR],
 286 [
 287 if test -n "$1" ; then
 288   for cf_add_libdir in $1
 289   do
 290     if test $cf_add_libdir = /usr/lib ; then
 291       :
 292     elif test -d $cf_add_libdir
 293     then
 294       cf_have_libdir=no
 295       if test -n "$LDFLAGS$LIBS" ; then
 296         # a loop is needed to ensure we can add subdirs of existing dirs
 297         for cf_test_libdir in $LDFLAGS $LIBS ; do
 298           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 299             cf_have_libdir=yes; break
 300           fi
 301         done
 302       fi
 303       if test "$cf_have_libdir" = no ; then
 304         CF_VERBOSE(adding $cf_add_libdir to library-path)
 305         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 306       fi
 307     fi
 308   done
 309 fi
 310 ])dnl
 311 dnl ---------------------------------------------------------------------------
 312 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
 313 dnl -----------
 314 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 315 dnl prepended to an existing list, since their dependencies are assumed to
 316 dnl already exist in the list.
 317 dnl
 318 dnl $1 = libraries to add, with the "-l", etc.
 319 dnl $2 = variable to update (default $LIBS)
 320 AC_DEFUN([CF_ADD_LIBS],[
 321 cf_add_libs="$1"
 322 # Filter out duplicates - this happens with badly-designed ".pc" files...
 323 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
 324 do
 325         for cf_add_2lib in $cf_add_libs
 326         do
 327                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
 328                 then
 329                         cf_add_1lib=
 330                         break
 331                 fi
 332         done
 333         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
 334 done
 335 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 336 ])dnl
 337 dnl ---------------------------------------------------------------------------
 338 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 339 dnl ------------------
 340 dnl Append to a search-list for a nonstandard header/lib-file
 341 dnl     $1 = the variable to return as result
 342 dnl     $2 = the package name
 343 dnl     $3 = the subdirectory, e.g., bin, include or lib
 344 dnl $4 = the directory under which we will test for subdirectories
 345 dnl $5 = a directory that we do not want $4 to match
 346 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 347 [
 348 test "x$4" != "x$5" && \
 349 test -d "$4" && \
 350 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 351         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 352         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 353         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 354         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 355         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 356         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 357 }
 358 ])dnl
 359 dnl ---------------------------------------------------------------------------
 360 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 361 dnl --------------
 362 dnl Allow user to disable a normally-on option.
 363 AC_DEFUN([CF_ARG_DISABLE],
 364 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 365 dnl ---------------------------------------------------------------------------
 366 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
 367 dnl -------------
 368 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 369 dnl values.
 370 dnl
 371 dnl Parameters:
 372 dnl $1 = option name
 373 dnl $2 = help-string
 374 dnl $3 = action to perform if option is not default
 375 dnl $4 = action if perform if option is default
 376 dnl $5 = default option value (either 'yes' or 'no')
 377 AC_DEFUN([CF_ARG_OPTION],
 378 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 379   if test "$enableval" != "$5" ; then
 380 ifelse([$3],,[    :]dnl
 381 ,[    $3]) ifelse([$4],,,[
 382   else
 383     $4])
 384   fi],[enableval=$5 ifelse([$4],,,[
 385   $4
 386 ])dnl
 387   ])])dnl
 388 dnl ---------------------------------------------------------------------------
 389 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
 390 dnl -----------
 391 dnl Check for suitable "ar" (archiver) options for updating an archive.
 392 AC_DEFUN([CF_AR_FLAGS],[
 393 AC_REQUIRE([CF_PROG_AR])
 394
 395 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 396         cf_cv_ar_flags=unknown
 397         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
 398         do
 399
 400                 # check if $ARFLAGS already contains this choice
 401                 if test "x$ARFLAGS" != "x" ; then
 402                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 403                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 404                                 cf_cv_ar_flags=
 405                                 break
 406                         fi
 407                 fi
 408
 409                 rm -f conftest.$ac_cv_objext
 410                 rm -f conftest.a
 411
 412                 cat >conftest.$ac_ext <<EOF
 413 #line __oline__ "configure"
 414 int     testdata[[3]] = { 123, 456, 789 };
 415 EOF
 416                 if AC_TRY_EVAL(ac_compile) ; then
 417                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 418                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 419                         if test -f conftest.a ; then
 420                                 cf_cv_ar_flags=$cf_ar_flags
 421                                 break
 422                         fi
 423                 else
 424                         CF_VERBOSE(cannot compile test-program)
 425                         break
 426                 fi
 427         done
 428         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 429 ])
 430
 431 if test -n "$ARFLAGS" ; then
 432         if test -n "$cf_cv_ar_flags" ; then
 433                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 434         fi
 435 else
 436         ARFLAGS=$cf_cv_ar_flags
 437 fi
 438
 439 AC_SUBST(ARFLAGS)
 440 ])
 441 dnl ---------------------------------------------------------------------------
 442 dnl CF_AWK_BIG_PRINTF version: 4 updated: 2011/10/30 17:09:50
 443 dnl -----------------
 444 dnl Check if awk can handle big strings using printf.  Some older versions of
 445 dnl awk choke on large strings passed via "%s".
 446 dnl
 447 dnl $1 = desired string size
 448 dnl $2 = variable to set with result
 449 AC_DEFUN([CF_AWK_BIG_PRINTF],
 450 [
 451         case x$AWK in #(vi
 452         x)
 453                 eval $2=no
 454                 ;;
 455         *) #(vi
 456                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 457                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 458                         eval $2=yes
 459                 else
 460                         eval $2=no
 461                 fi
 462                 ;;
 463         esac
 464 ])dnl
 465 dnl ---------------------------------------------------------------------------
 466 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 467 dnl ------------
 468 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 469 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 470 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 471 dnl
 472 dnl Treat the configuration-variable specially here, since we're directly
 473 dnl substituting its value (i.e., 1/0).
 474 dnl
 475 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 476 AC_DEFUN([CF_BOOL_DECL],
 477 [
 478 AC_MSG_CHECKING(if we should include stdbool.h)
 479
 480 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 481         AC_TRY_COMPILE([],[bool foo = false],
 482                 [cf_cv_header_stdbool_h=0],
 483                 [AC_TRY_COMPILE([
 484 #ifndef __BEOS__
 485 #include <stdbool.h>
 486 #endif
 487 ],[bool foo = false],
 488                         [cf_cv_header_stdbool_h=1],
 489                         [cf_cv_header_stdbool_h=0])])])
 490
 491 if test "$cf_cv_header_stdbool_h" = 1
 492 then    AC_MSG_RESULT(yes)
 493 else    AC_MSG_RESULT(no)
 494 fi
 495
 496 AC_MSG_CHECKING([for builtin bool type])
 497
 498 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 499         AC_TRY_COMPILE([
 500 #include <stdio.h>
 501 #include <sys/types.h>
 502 ],[bool x = false],
 503                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 504                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 505         ])
 506
 507 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 508 then    AC_MSG_RESULT(yes)
 509 else    AC_MSG_RESULT(no)
 510 fi
 511 ])dnl
 512 dnl ---------------------------------------------------------------------------
 513 dnl CF_BOOL_SIZE version: 13 updated: 2013/04/13 18:03:21
 514 dnl ------------
 515 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 516 dnl Don't bother looking for bool.h, since it's been deprecated.
 517 dnl
 518 dnl If the current compiler is C rather than C++, we get the bool definition
 519 dnl from <stdbool.h>.
 520 AC_DEFUN([CF_BOOL_SIZE],
 521 [
 522 AC_MSG_CHECKING([for size of bool])
 523 AC_CACHE_VAL(cf_cv_type_of_bool,[
 524         rm -f cf_test.out
 525         AC_TRY_RUN([
 526 #include <stdlib.h>
 527 #include <stdio.h>
 528
 529 #if defined(__cplusplus)
 530
 531 #ifdef HAVE_GXX_BUILTIN_H
 532 #include <g++/builtin.h>
 533 #elif HAVE_GPP_BUILTIN_H
 534 #include <gpp/builtin.h>
 535 #elif HAVE_BUILTIN_H
 536 #include <builtin.h>
 537 #endif
 538
 539 #else
 540
 541 #if $cf_cv_header_stdbool_h
 542 #include <stdbool.h>
 543 #endif
 544
 545 #endif
 546
 547 int main()
 548 {
 549         FILE *fp = fopen("cf_test.out", "w");
 550         if (fp != 0) {
 551                 bool x = true;
 552                 if ((bool)(-x) >= 0)
 553                         fputs("unsigned ", fp);
 554                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 555                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 556                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 557                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 558                 fclose(fp);
 559         }
 560         ${cf_cv_main_return:-return}(0);
 561 }
 562                 ],
 563                 [cf_cv_type_of_bool=`cat cf_test.out`
 564                  if test -z "$cf_cv_type_of_bool"; then
 565                    cf_cv_type_of_bool=unknown
 566                  fi],
 567                 [cf_cv_type_of_bool=unknown],
 568                 [cf_cv_type_of_bool=unknown])
 569         ])
 570         rm -f cf_test.out
 571 AC_MSG_RESULT($cf_cv_type_of_bool)
 572 if test "$cf_cv_type_of_bool" = unknown ; then
 573         case .$NCURSES_BOOL in #(vi
 574         .auto|.) NCURSES_BOOL=unsigned;;
 575         esac
 576         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 577         cf_cv_type_of_bool=$NCURSES_BOOL
 578 fi
 579 ])dnl
 580 dnl ---------------------------------------------------------------------------
 581 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
 582 dnl -----------
 583 dnl If we're cross-compiling, allow the user to override the tools and their
 584 dnl options.  The configure script is oriented toward identifying the host
 585 dnl compiler, etc., but we need a build compiler to generate parts of the
 586 dnl source.
 587 dnl
 588 dnl $1 = default for $CPPFLAGS
 589 dnl $2 = default for $LIBS
 590 AC_DEFUN([CF_BUILD_CC],[
 591 CF_ACVERSION_CHECK(2.52,,
 592         [AC_REQUIRE([CF_PROG_EXT])])
 593 if test "$cross_compiling" = yes ; then
 594
 595         # defaults that we might want to override
 596         : ${BUILD_CFLAGS:=''}
 597         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 598         : ${BUILD_LDFLAGS:=''}
 599         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 600         : ${BUILD_EXEEXT:='$x'}
 601         : ${BUILD_OBJEXT:='o'}
 602
 603         AC_ARG_WITH(build-cc,
 604                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 605                 [BUILD_CC="$withval"],
 606                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 607         AC_MSG_CHECKING(for native build C compiler)
 608         AC_MSG_RESULT($BUILD_CC)
 609
 610         AC_MSG_CHECKING(for native build C preprocessor)
 611         AC_ARG_WITH(build-cpp,
 612                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 613                 [BUILD_CPP="$withval"],
 614                 [BUILD_CPP='${BUILD_CC} -E'])
 615         AC_MSG_RESULT($BUILD_CPP)
 616
 617         AC_MSG_CHECKING(for native build C flags)
 618         AC_ARG_WITH(build-cflags,
 619                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 620                 [BUILD_CFLAGS="$withval"])
 621         AC_MSG_RESULT($BUILD_CFLAGS)
 622
 623         AC_MSG_CHECKING(for native build C preprocessor-flags)
 624         AC_ARG_WITH(build-cppflags,
 625                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 626                 [BUILD_CPPFLAGS="$withval"])
 627         AC_MSG_RESULT($BUILD_CPPFLAGS)
 628
 629         AC_MSG_CHECKING(for native build linker-flags)
 630         AC_ARG_WITH(build-ldflags,
 631                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 632                 [BUILD_LDFLAGS="$withval"])
 633         AC_MSG_RESULT($BUILD_LDFLAGS)
 634
 635         AC_MSG_CHECKING(for native build linker-libraries)
 636         AC_ARG_WITH(build-libs,
 637                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 638                 [BUILD_LIBS="$withval"])
 639         AC_MSG_RESULT($BUILD_LIBS)
 640
 641         # this assumes we're on Unix.
 642         BUILD_EXEEXT=
 643         BUILD_OBJEXT=o
 644
 645         : ${BUILD_CC:='${CC}'}
 646
 647         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 648                 AC_MSG_ERROR([Cross-build requires two compilers.
 649 Use --with-build-cc to specify the native compiler.])
 650         fi
 651
 652 else
 653         : ${BUILD_CC:='${CC}'}
 654         : ${BUILD_CPP:='${CPP}'}
 655         : ${BUILD_CFLAGS:='${CFLAGS}'}
 656         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 657         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 658         : ${BUILD_LIBS:='${LIBS}'}
 659         : ${BUILD_EXEEXT:='$x'}
 660         : ${BUILD_OBJEXT:='o'}
 661 fi
 662
 663 AC_SUBST(BUILD_CC)
 664 AC_SUBST(BUILD_CPP)
 665 AC_SUBST(BUILD_CFLAGS)
 666 AC_SUBST(BUILD_CPPFLAGS)
 667 AC_SUBST(BUILD_LDFLAGS)
 668 AC_SUBST(BUILD_LIBS)
 669 AC_SUBST(BUILD_EXEEXT)
 670 AC_SUBST(BUILD_OBJEXT)
 671 ])dnl
 672 dnl ---------------------------------------------------------------------------
 673 dnl CF_CC_ENV_FLAGS version: 1 updated: 2012/10/03 05:25:49
 674 dnl ---------------
 675 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 676 dnl into CC.  This will not help with broken scripts that wrap the compiler with
 677 dnl options, but eliminates a more common category of user confusion.
 678 AC_DEFUN([CF_CC_ENV_FLAGS],
 679 [
 680 # This should have been defined by AC_PROG_CC
 681 : ${CC:=cc}
 682
 683 AC_MSG_CHECKING(\$CC variable)
 684 case "$CC" in #(vi
 685 *[[\ \  ]]-[[IUD]]*)
 686         AC_MSG_RESULT(broken)
 687         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 688         # humor him...
 689         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
 690         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
 691         CF_ADD_CFLAGS($cf_flags)
 692         ;;
 693 *)
 694         AC_MSG_RESULT(ok)
 695         ;;
 696 esac
 697 ])dnl
 698 dnl ---------------------------------------------------------------------------
 699 dnl CF_CFG_DEFAULTS version: 10 updated: 2013/09/07 13:54:05
 700 dnl ---------------
 701 dnl Determine the default configuration into which we'll install ncurses.  This
 702 dnl can be overridden by the user's command-line options.  There's two items to
 703 dnl look for:
 704 dnl     1. the prefix (e.g., /usr)
 705 dnl     2. the header files (e.g., /usr/include/ncurses)
 706 dnl We'll look for a previous installation of ncurses and use the same defaults.
 707 dnl
 708 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 709 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 710 dnl programs from a vendor's.
 711 AC_DEFUN([CF_CFG_DEFAULTS],
 712 [
 713 AC_MSG_CHECKING(for prefix)
 714 if test "x$prefix" = "xNONE" ; then
 715         case "$cf_cv_system_name" in
 716                 # non-vendor systems don't have a conflict
 717         openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 718                 prefix=/usr
 719                 ;;
 720         *)      prefix=$ac_default_prefix
 721                 ;;
 722         esac
 723 fi
 724 AC_MSG_RESULT($prefix)
 725
 726 if test "x$prefix" = "xNONE" ; then
 727 AC_MSG_CHECKING(for default include-directory)
 728 test -n "$verbose" && echo 1>&AC_FD_MSG
 729 for cf_symbol in \
 730         $includedir \
 731         $includedir/ncurses \
 732         $prefix/include \
 733         $prefix/include/ncurses \
 734         /usr/local/include \
 735         /usr/local/include/ncurses \
 736         /usr/include \
 737         /usr/include/ncurses
 738 do
 739         cf_dir=`eval echo $cf_symbol`
 740         if test -f $cf_dir/curses.h ; then
 741         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 742                 includedir="$cf_symbol"
 743                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 744                 break
 745         fi
 746         fi
 747         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 748 done
 749 AC_MSG_RESULT($includedir)
 750 fi
 751 ])dnl
 752 dnl ---------------------------------------------------------------------------
 753 dnl CF_CGETENT version: 5 updated: 2012/10/06 17:56:13
 754 dnl ----------
 755 dnl Check if the terminal-capability database functions are available.  If not,
 756 dnl ncurses has a much-reduced version.
 757 AC_DEFUN([CF_CGETENT],[
 758 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 759 AC_TRY_LINK([
 760 #include <stdlib.h>],[
 761         char temp[128];
 762         char *buf = temp;
 763         char *db_array = temp;
 764         cgetent(&buf, &db_array, "vt100");
 765         cgetcap(buf, "tc", '=');
 766         cgetmatch(buf, "tc");
 767         ],
 768         [cf_cv_cgetent=yes],
 769         [cf_cv_cgetent=no])
 770 ])
 771
 772 if test "$cf_cv_cgetent" = yes
 773 then
 774         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 775 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 776 AC_TRY_LINK([
 777 #include <stdlib.h>],[
 778         char temp[128];
 779         char *buf = temp;
 780 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 781         const char *db_array = temp;
 782         cgetent(&buf, &db_array, "vt100");
 783 #endif
 784         cgetcap(buf, "tc", '=');
 785         cgetmatch(buf, "tc");
 786         ],
 787         [cf_cv_cgetent_const=yes],
 788         [cf_cv_cgetent_const=no])
 789 ])
 790         if test "$cf_cv_cgetent_const" = yes
 791         then
 792                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 793         fi
 794 fi
 795 ])dnl
 796 dnl ---------------------------------------------------------------------------
 797 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 798 dnl --------------
 799 dnl Check if we're accidentally using a cache from a different machine.
 800 dnl Derive the system name, as a check for reusing the autoconf cache.
 801 dnl
 802 dnl If we've packaged config.guess and config.sub, run that (since it does a
 803 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 804 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 805 dnl which is useful in cross-compiles.
 806 dnl
 807 dnl Note: we would use $ac_config_sub, but that is one of the places where
 808 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 809 AC_DEFUN([CF_CHECK_CACHE],
 810 [
 811 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 812         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 813         system_name="$host_os"
 814 else
 815         system_name="`(uname -s -r) 2>/dev/null`"
 816         if test -z "$system_name" ; then
 817                 system_name="`(hostname) 2>/dev/null`"
 818         fi
 819 fi
 820 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 821 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 822
 823 test -z "$system_name" && system_name="$cf_cv_system_name"
 824 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 825
 826 if test ".$system_name" != ".$cf_cv_system_name" ; then
 827         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 828         AC_MSG_ERROR("Please remove config.cache and try again.")
 829 fi
 830 ])dnl
 831 dnl ---------------------------------------------------------------------------
 832 dnl CF_CHECK_ERRNO version: 11 updated: 2010/05/26 05:38:42
 833 dnl --------------
 834 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 835 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 836 dnl ourselves.
 837 dnl
 838 dnl $1 = the name to check
 839 dnl $2 = the assumed type
 840 AC_DEFUN([CF_CHECK_ERRNO],
 841 [
 842 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 843     AC_TRY_COMPILE([
 844 #ifdef HAVE_STDLIB_H
 845 #include <stdlib.h>
 846 #endif
 847 #include <stdio.h>
 848 #include <sys/types.h>
 849 #include <errno.h> ],
 850     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 851     [cf_cv_dcl_$1=yes],
 852     [cf_cv_dcl_$1=no])
 853 ])
 854
 855 if test "$cf_cv_dcl_$1" = no ; then
 856     CF_UPPER(cf_result,decl_$1)
 857     AC_DEFINE_UNQUOTED($cf_result)
 858 fi
 859
 860 # It's possible (for near-UNIX clones) that the data doesn't exist
 861 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 862 ])dnl
 863 dnl ---------------------------------------------------------------------------
 864 dnl CF_CHECK_EXTERN_DATA version: 3 updated: 2001/12/30 18:03:23
 865 dnl --------------------
 866 dnl Check for existence of external data in the current set of libraries.  If
 867 dnl we can modify it, it's real enough.
 868 dnl $1 = the name to check
 869 dnl $2 = its type
 870 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 871 [
 872 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 873     AC_TRY_LINK([
 874 #undef $1
 875 extern $2 $1;
 876 ],
 877     [$1 = 2],
 878     [cf_cv_have_$1=yes],
 879     [cf_cv_have_$1=no])
 880 ])
 881
 882 if test "$cf_cv_have_$1" = yes ; then
 883     CF_UPPER(cf_result,have_$1)
 884     AC_DEFINE_UNQUOTED($cf_result)
 885 fi
 886
 887 ])dnl
 888 dnl ---------------------------------------------------------------------------
 889 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
 890 dnl -------------------
 891 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 892 dnl is not "weak" - warn about this because it can create problems linking
 893 dnl applications with ncurses.
 894 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 895 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 896
 897 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 898 cf_cv_check_gpm_wgetch=unknown
 899 if test "$cross_compiling" != yes ; then
 900
 901 cat >conftest.$ac_ext <<CF_EOF
 902 #include <gpm.h>
 903 int main()
 904 {
 905         Gpm_Wgetch();
 906         ${cf_cv_main_return:-return}(0);
 907 }
 908 CF_EOF
 909
 910         cf_save_LIBS="$LIBS"
 911         # This only works if we can look at the symbol table.  If a shared
 912         # library is stripped for install, we cannot use that.  So we're forced
 913         # to rely on the static library, noting that some packagers may not
 914         # include it.
 915         LIBS="-static -lgpm -dynamic $LIBS"
 916         if AC_TRY_EVAL(ac_compile) ; then
 917                 if AC_TRY_EVAL(ac_link) ; then
 918                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
 919                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
 920                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
 921                 fi
 922         fi
 923         rm -rf conftest*
 924         LIBS="$cf_save_LIBS"
 925 fi
 926 ])
 927
 928 if test "$cf_cv_check_gpm_wgetch" != yes ; then
 929         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 930 fi
 931 ])])dnl
 932 dnl ---------------------------------------------------------------------------
 933 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
 934 dnl ------------------------
 935 dnl Show the version of libtool
 936 dnl
 937 dnl Save the version in a cache variable - this is not entirely a good thing,
 938 dnl but the version string from libtool is very ugly, and for bug reports it
 939 dnl might be useful to have the original string.
 940 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
 941 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
 942 then
 943         AC_MSG_CHECKING(version of $LIBTOOL)
 944         CF_LIBTOOL_VERSION
 945         AC_MSG_RESULT($cf_cv_libtool_version)
 946         if test -z "$cf_cv_libtool_version" ; then
 947                 AC_MSG_ERROR(This is not GNU libtool)
 948         fi
 949 else
 950         AC_MSG_ERROR(GNU libtool has not been found)
 951 fi
 952 ])dnl
 953 dnl ---------------------------------------------------------------------------
 954 dnl CF_CHECK_WCHAR_H version: 1 updated: 2011/10/29 15:01:05
 955 dnl ----------------
 956 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
 957 AC_DEFUN([CF_CHECK_WCHAR_H],[
 958 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
 959 AC_TRY_COMPILE(
 960 [
 961 #include <stdlib.h>
 962 #include <wchar.h>
 963 ],[
 964         wint_t foo = 0;
 965         int bar = iswpunct(foo)],
 966         [cf_cv_wchar_h_okay=yes],
 967         [cf_cv_wchar_h_okay=no])])
 968
 969 if test $cf_cv_wchar_h_okay = no
 970 then
 971         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 972 fi
 973 ])dnl
 974 dnl ---------------------------------------------------------------------------
 975 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
 976 dnl -----------------
 977 dnl Check if the given compiler is really clang.  clang's C driver defines
 978 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
 979 dnl not ignore some gcc options.
 980 dnl
 981 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
 982 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
 983 dnl the wrappers for gcc and g++ warnings.
 984 dnl
 985 dnl $1 = GCC (default) or GXX
 986 dnl $2 = CLANG_COMPILER (default)
 987 dnl $3 = CFLAGS (default) or CXXFLAGS
 988 AC_DEFUN([CF_CLANG_COMPILER],[
 989 ifelse([$2],,CLANG_COMPILER,[$2])=no
 990
 991 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
 992         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
 993         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
 994         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
 995         AC_TRY_COMPILE([],[
 996 #ifdef __clang__
 997 #else
 998 make an error
 999 #endif
1000 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1001 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
1002 ],[])
1003         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1004         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1005 fi
1006 ])
1007 dnl ---------------------------------------------------------------------------
1008 dnl CF_CPP_PARAM_INIT version: 6 updated: 2012/10/06 17:56:13
1009 dnl -----------------
1010 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1011 dnl is a late feature for the standard and is not in some recent compilers
1012 dnl (1999/9/11).
1013 AC_DEFUN([CF_CPP_PARAM_INIT],
1014 [
1015 if test -n "$CXX"; then
1016 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1017         AC_LANG_SAVE
1018         AC_LANG_CPLUSPLUS
1019         AC_TRY_RUN([
1020 class TEST {
1021 private:
1022         int value;
1023 public:
1024         TEST(int x = 1);
1025         ~TEST();
1026 };
1027
1028 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1029 {
1030         value = x;
1031 }
1032 int main() { }
1033 ],
1034         [cf_cv_cpp_param_init=yes],
1035         [cf_cv_cpp_param_init=no],
1036         [cf_cv_cpp_param_init=unknown])
1037         AC_LANG_RESTORE
1038 ])
1039 fi
1040 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1041 ])dnl
1042 dnl ---------------------------------------------------------------------------
1043 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1044 dnl ------------------
1045 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1046 dnl not be supported in g++ before 3.0
1047 AC_DEFUN([CF_CPP_STATIC_CAST],
1048 [
1049 if test -n "$CXX"; then
1050
1051 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1052         AC_LANG_SAVE
1053         AC_LANG_CPLUSPLUS
1054
1055         AC_TRY_COMPILE([
1056 class NCursesPanel
1057 {
1058 public:
1059   NCursesPanel(int nlines,
1060                int ncols,
1061                int begin_y = 0,
1062                int begin_x = 0)
1063   {
1064   }
1065   NCursesPanel();
1066   ~NCursesPanel();
1067 };
1068
1069 template<class T> class NCursesUserPanel : public NCursesPanel
1070 {
1071 public:
1072   NCursesUserPanel (int nlines,
1073                     int ncols,
1074                     int begin_y = 0,
1075                     int begin_x = 0,
1076                     const T* p_UserData = static_cast<T*>(0))
1077     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1078   {
1079   };
1080   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1081   {
1082   };
1083
1084   virtual ~NCursesUserPanel() {};
1085 };
1086 ],[
1087         const char* p_UserData = static_cast<char*>(0)],
1088         [cf_cv_cpp_static_cast=yes],
1089         [cf_cv_cpp_static_cast=no])
1090
1091         AC_LANG_RESTORE
1092 ])
1093
1094 fi
1095
1096 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1097 ])dnl
1098 dnl ---------------------------------------------------------------------------
1099 dnl CF_CXX_AR_FLAGS version: 1 updated: 2011/10/29 08:35:34
1100 dnl ---------------
1101 dnl Setup special archiver flags for given compilers.
1102 AC_DEFUN([CF_CXX_AR_FLAGS],[
1103         CXX_AR='$(AR)'
1104         CXX_ARFLAGS='$(ARFLAGS)'
1105         case $cf_cv_system_name in #(vi
1106         irix*) #(vi
1107             if test "$GXX" != yes ; then
1108                 CXX_AR='$(CXX)'
1109                 CXX_ARFLAGS='-ar -o'
1110             fi
1111             ;;
1112         sco3.2v5*) #(vi
1113             CXXLDFLAGS="-u main"
1114             ;;
1115         solaris2*)
1116             if test "$GXX" != yes ; then
1117                 CXX_AR='$(CXX)'
1118                 CXX_ARFLAGS='-xar -o'
1119             fi
1120             ;;
1121         esac
1122         AC_SUBST(CXXLDFLAGS)
1123         AC_SUBST(CXX_AR)
1124         AC_SUBST(CXX_ARFLAGS)
1125 ])dnl
1126 dnl ---------------------------------------------------------------------------
1127 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1128 dnl -------------------------
1129 dnl For c++, check if iostream uses "std::" namespace.
1130 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1131 AC_CHECK_HEADERS(iostream)
1132 if test x"$ac_cv_header_iostream" = xyes ; then
1133         AC_MSG_CHECKING(if iostream uses std-namespace)
1134         AC_TRY_COMPILE([
1135 #include <iostream>
1136 using std::endl;
1137 using std::cerr;],[
1138 cerr << "testing" << endl;
1139 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1140         AC_MSG_RESULT($cf_iostream_namespace)
1141         if test "$cf_iostream_namespace" = yes ; then
1142                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1143         fi
1144 fi
1145 ])dnl
1146 dnl ---------------------------------------------------------------------------
1147 dnl CF_C_INLINE version: 4 updated: 2012/06/16 14:55:39
1148 dnl -----------
1149 dnl Check if the C compiler supports "inline".
1150 dnl $1 is the name of a shell variable to set if inline is supported
1151 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1152 AC_DEFUN([CF_C_INLINE],[
1153 AC_C_INLINE
1154 $1=
1155 if test "$ac_cv_c_inline" != no ; then
1156   $1=inline
1157   if test "$INTEL_COMPILER" = yes
1158   then
1159     :
1160   elif test "$CLANG_COMPILER" = yes
1161   then
1162     :
1163   elif test "$GCC" = yes
1164   then
1165     AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1166       cf_save_CFLAGS=$CFLAGS
1167       CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1168       AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1169       [${cf_cv_main_return:-return} foo()],
1170       [cf_cv_gcc_inline=yes],
1171       [cf_cv_gcc_inline=no])
1172       CFLAGS=$cf_save_CFLAGS
1173     ])
1174     if test "$cf_cv_gcc_inline" = yes ; then
1175         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1176     fi
1177   fi
1178 fi
1179 AC_SUBST($1)
1180 ])dnl
1181 dnl ---------------------------------------------------------------------------
1182 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1183 dnl ----------
1184 dnl "dirname" is not portable, so we fake it with a shell script.
1185 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1186 dnl ---------------------------------------------------------------------------
1187 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1188 dnl ---------------
1189 AC_DEFUN([CF_DIRS_TO_MAKE],
1190 [
1191 DIRS_TO_MAKE="lib"
1192 for cf_item in $cf_list_models
1193 do
1194         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1195         for cf_item2 in $DIRS_TO_MAKE
1196         do
1197                 test $cf_item2 = $cf_subdir && break
1198         done
1199         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1200 done
1201 for cf_dir in $DIRS_TO_MAKE
1202 do
1203         test ! -d $cf_dir && mkdir $cf_dir
1204 done
1205 AC_SUBST(DIRS_TO_MAKE)
1206 ])dnl
1207 dnl ---------------------------------------------------------------------------
1208 dnl CF_DISABLE_ECHO version: 12 updated: 2012/10/06 16:30:28
1209 dnl ---------------
1210 dnl You can always use "make -n" to see the actual options, but it's hard to
1211 dnl pick out/analyze warning messages when the compile-line is long.
1212 dnl
1213 dnl Sets:
1214 dnl     ECHO_LT - symbol to control if libtool is verbose
1215 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1216 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1217 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1218 dnl     ECHO_CC - symbol to put before any "cc" line
1219 dnl
1220 AC_DEFUN([CF_DISABLE_ECHO],[
1221 AC_MSG_CHECKING(if you want to see long compiling messages)
1222 CF_ARG_DISABLE(echo,
1223         [  --disable-echo          do not display "compiling" commands],
1224         [
1225     ECHO_LT='--silent'
1226     ECHO_LD='@echo linking [$]@;'
1227     RULE_CC='@echo compiling [$]<'
1228     SHOW_CC='@echo compiling [$]@'
1229     ECHO_CC='@'
1230 ],[
1231     ECHO_LT=''
1232     ECHO_LD=''
1233     RULE_CC=''
1234     SHOW_CC=''
1235     ECHO_CC=''
1236 ])
1237 AC_MSG_RESULT($enableval)
1238 AC_SUBST(ECHO_LT)
1239 AC_SUBST(ECHO_LD)
1240 AC_SUBST(RULE_CC)
1241 AC_SUBST(SHOW_CC)
1242 AC_SUBST(ECHO_CC)
1243 ])dnl
1244 dnl ---------------------------------------------------------------------------
1245 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1246 dnl ------------------------
1247 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1248 AC_MSG_CHECKING(if we want to use GNAT projects)
1249 CF_ARG_DISABLE(gnat-projects,
1250         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1251         [enable_gnat_projects=no],
1252         [enable_gnat_projects=yes])
1253 AC_MSG_RESULT($enable_gnat_projects)
1254 ])dnl
1255 dnl ---------------------------------------------------------------------------
1256 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1257 dnl ----------------
1258 dnl Combine no-leak checks with the libraries or tools that are used for the
1259 dnl checks.
1260 AC_DEFUN([CF_DISABLE_LEAKS],[
1261
1262 AC_REQUIRE([CF_WITH_DMALLOC])
1263 AC_REQUIRE([CF_WITH_DBMALLOC])
1264 AC_REQUIRE([CF_WITH_VALGRIND])
1265
1266 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1267 AC_ARG_ENABLE(leaks,
1268         [  --disable-leaks         test: free permanent memory, analyze leaks],
1269         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1270         : ${with_no_leaks:=no})
1271 AC_MSG_RESULT($with_no_leaks)
1272
1273 if test "$with_no_leaks" = yes ; then
1274         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1275         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1276 fi
1277 ])dnl
1278 dnl ---------------------------------------------------------------------------
1279 dnl CF_DISABLE_LIBTOOL_VERSION version: 1 updated: 2010/05/15 15:45:59
1280 dnl --------------------------
1281 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1282 dnl the older "-version-info" feature.  The newer feature allows us to use
1283 dnl version numbering on shared libraries which make them compatible with
1284 dnl various systems.
1285 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1286 [
1287 AC_MSG_CHECKING(if libtool -version-number should be used)
1288 CF_ARG_DISABLE(libtool-version,
1289         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1290         [cf_libtool_version=no],
1291         [cf_libtool_version=yes])
1292 AC_MSG_RESULT($cf_libtool_version)
1293
1294 if test "$cf_libtool_version" = yes ; then
1295         LIBTOOL_VERSION="-version-number"
1296 else
1297         LIBTOOL_VERSION="-version-info"
1298 fi
1299
1300 AC_SUBST(LIBTOOL_VERSION)
1301 ])dnl
1302 dnl ---------------------------------------------------------------------------
1303 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1304 dnl ---------------------
1305 dnl The rpath-hack makes it simpler to build programs, particularly with the
1306 dnl *BSD ports which may have essential libraries in unusual places.  But it
1307 dnl can interfere with building an executable for the base system.  Use this
1308 dnl option in that case.
1309 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1310 [
1311 AC_MSG_CHECKING(if rpath-hack should be disabled)
1312 CF_ARG_DISABLE(rpath-hack,
1313         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1314         [cf_disable_rpath_hack=yes],
1315         [cf_disable_rpath_hack=no])
1316 AC_MSG_RESULT($cf_disable_rpath_hack)
1317 if test "$cf_disable_rpath_hack" = no ; then
1318         CF_RPATH_HACK
1319 fi
1320 ])
1321 dnl ---------------------------------------------------------------------------
1322 dnl CF_ENABLE_PC_FILES version: 9 updated: 2012/08/04 13:59:54
1323 dnl ------------------
1324 dnl This is the "--enable-pc-files" option, which is available if there is a
1325 dnl pkg-config configuration on the local machine.
1326 AC_DEFUN([CF_ENABLE_PC_FILES],[
1327 AC_REQUIRE([CF_PKG_CONFIG])
1328 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1329
1330 if test "$PKG_CONFIG" != none ; then
1331         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1332         AC_ARG_ENABLE(pc-files,
1333                 [  --enable-pc-files       generate and install .pc files for pkg-config],
1334                 [enable_pc_files=$enableval],
1335                 [enable_pc_files=no])
1336         AC_MSG_RESULT($enable_pc_files)
1337         if test "$enable_pc_files" != no
1338         then
1339                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1340         fi
1341 else
1342         enable_pc_files=no
1343 fi
1344 ])dnl
1345 dnl ---------------------------------------------------------------------------
1346 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1347 dnl ---------------
1348 dnl Check if the rpath option should be used, setting cache variable
1349 dnl cf_cv_enable_rpath if so.
1350 AC_DEFUN([CF_ENABLE_RPATH],
1351 [
1352 AC_MSG_CHECKING(if rpath option should be used)
1353 AC_ARG_ENABLE(rpath,
1354 [  --enable-rpath          use rpath option when generating shared libraries],
1355 [cf_cv_enable_rpath=$enableval],
1356 [cf_cv_enable_rpath=no])
1357 AC_MSG_RESULT($cf_cv_enable_rpath)
1358 ])dnl
1359 dnl ---------------------------------------------------------------------------
1360 dnl CF_ENABLE_STRING_HACKS version: 3 updated: 2013/01/26 16:26:12
1361 dnl ----------------------
1362 dnl On a few platforms, the compiler and/or loader nags with untruthful
1363 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1364 dnl and implying that most uses of the recommended alternatives are correct.
1365 dnl
1366 dnl Factually speaking, no one has actually counted the number of uses of these
1367 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1368 dnl instances are meaningless compared to the hundreds of millions of lines of
1369 dnl existing C code.
1370 dnl
1371 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1372 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1373 dnl standard - but evolved through phases, and older implementations are likely
1374 dnl to yield surprising results, as documented in manpages on various systems.
1375 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1376 [
1377 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1378 AC_ARG_ENABLE(string-hacks,
1379         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1380         [with_string_hacks=$enableval],
1381         [with_string_hacks=no])
1382 AC_MSG_RESULT($with_string_hacks)
1383
1384 if test "x$with_string_hacks" = "xyes"; then
1385         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1386         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1387         AC_CHECK_FUNCS( strlcat strlcpy snprintf )
1388 fi
1389 ])dnl
1390 dnl ---------------------------------------------------------------------------
1391 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1392 dnl --------
1393 dnl Check if 'errno' is declared in <errno.h>
1394 AC_DEFUN([CF_ERRNO],
1395 [
1396 CF_CHECK_ERRNO(errno)
1397 ])dnl
1398 dnl ---------------------------------------------------------------------------
1399 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1400 dnl ---------------
1401 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1402 dnl math.h and builtin.h, only for ncurses
1403 AC_DEFUN([CF_ETIP_DEFINES],
1404 [
1405 AC_MSG_CHECKING(for special defines needed for etip.h)
1406 cf_save_CXXFLAGS="$CXXFLAGS"
1407 cf_result="none"
1408
1409 # etip.h includes ncurses.h which includes ncurses_dll.h
1410 # But ncurses_dll.h is generated - fix here.
1411 test -d include || mkdir include
1412 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1413
1414 for cf_math in "" MATH_H
1415 do
1416 for cf_excp in "" MATH_EXCEPTION
1417 do
1418         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1419         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1420         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1421 AC_TRY_COMPILE([
1422 #include <etip.h.in>
1423 ],[],[
1424         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1425         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1426         cf_result="$cf_math $cf_excp"
1427         break 2
1428 ],[])
1429 done
1430 done
1431 AC_MSG_RESULT($cf_result)
1432 CXXFLAGS="$cf_save_CXXFLAGS"
1433 ])
1434 dnl ---------------------------------------------------------------------------
1435 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
1436 dnl ---------------
1437 dnl Find a library (specifically the linkage used in the code fragment),
1438 dnl searching for it if it is not already in the library path.
1439 dnl See also CF_ADD_SEARCHPATH.
1440 dnl
1441 dnl Parameters (4-on are optional):
1442 dnl     $1 = headers for library entrypoint
1443 dnl     $2 = code fragment for library entrypoint
1444 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1445 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1446 dnl     $5 = action to perform if not successful
1447 dnl     $6 = module name, if not the same as the library name
1448 dnl     $7 = extra libraries
1449 dnl
1450 dnl Sets these variables:
1451 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1452 dnl     $cf_cv_header_path_$3 - include-directory if needed
1453 dnl     $cf_cv_library_path_$3 - library-directory if needed
1454 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1455 AC_DEFUN([CF_FIND_LINKAGE],[
1456
1457 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1458 # will be set on completion of the AC_TRY_LINK below.
1459 cf_cv_header_path_$3=
1460 cf_cv_library_path_$3=
1461
1462 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1463
1464 cf_save_LIBS="$LIBS"
1465
1466 AC_TRY_LINK([$1],[$2],[
1467         cf_cv_find_linkage_$3=yes
1468         cf_cv_header_path_$3=/usr/include
1469         cf_cv_library_path_$3=/usr/lib
1470 ],[
1471
1472 LIBS="-l$3 $7 $cf_save_LIBS"
1473
1474 AC_TRY_LINK([$1],[$2],[
1475         cf_cv_find_linkage_$3=yes
1476         cf_cv_header_path_$3=/usr/include
1477         cf_cv_library_path_$3=/usr/lib
1478         cf_cv_library_file_$3="-l$3"
1479 ],[
1480         cf_cv_find_linkage_$3=no
1481         LIBS="$cf_save_LIBS"
1482
1483     CF_VERBOSE(find linkage for $3 library)
1484     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1485
1486     cf_save_CPPFLAGS="$CPPFLAGS"
1487     cf_test_CPPFLAGS="$CPPFLAGS"
1488
1489     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1490     for cf_cv_header_path_$3 in $cf_search
1491     do
1492       if test -d $cf_cv_header_path_$3 ; then
1493         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1494         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1495         AC_TRY_COMPILE([$1],[$2],[
1496             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1497             cf_cv_find_linkage_$3=maybe
1498             cf_test_CPPFLAGS="$CPPFLAGS"
1499             break],[
1500             CPPFLAGS="$cf_save_CPPFLAGS"
1501             ])
1502       fi
1503     done
1504
1505     if test "$cf_cv_find_linkage_$3" = maybe ; then
1506
1507       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1508
1509       cf_save_LIBS="$LIBS"
1510       cf_save_LDFLAGS="$LDFLAGS"
1511
1512       ifelse([$6],,,[
1513         CPPFLAGS="$cf_test_CPPFLAGS"
1514         LIBS="-l$3 $7 $cf_save_LIBS"
1515         AC_TRY_LINK([$1],[$2],[
1516             CF_VERBOSE(... found $3 library in system)
1517             cf_cv_find_linkage_$3=yes])
1518             CPPFLAGS="$cf_save_CPPFLAGS"
1519             LIBS="$cf_save_LIBS"
1520             ])
1521
1522       if test "$cf_cv_find_linkage_$3" != yes ; then
1523         CF_LIBRARY_PATH(cf_search,$3)
1524         for cf_cv_library_path_$3 in $cf_search
1525         do
1526           if test -d $cf_cv_library_path_$3 ; then
1527             CF_VERBOSE(... testing $cf_cv_library_path_$3)
1528             CPPFLAGS="$cf_test_CPPFLAGS"
1529             LIBS="-l$3 $7 $cf_save_LIBS"
1530             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1531             AC_TRY_LINK([$1],[$2],[
1532                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1533                 cf_cv_find_linkage_$3=yes
1534                 cf_cv_library_file_$3="-l$3"
1535                 break],[
1536                 CPPFLAGS="$cf_save_CPPFLAGS"
1537                 LIBS="$cf_save_LIBS"
1538                 LDFLAGS="$cf_save_LDFLAGS"
1539                 ])
1540           fi
1541         done
1542         CPPFLAGS="$cf_save_CPPFLAGS"
1543         LDFLAGS="$cf_save_LDFLAGS"
1544       fi
1545
1546     else
1547       cf_cv_find_linkage_$3=no
1548     fi
1549     ],$7)
1550 ])
1551
1552 LIBS="$cf_save_LIBS"
1553
1554 if test "$cf_cv_find_linkage_$3" = yes ; then
1555 ifelse([$4],,[
1556         CF_ADD_INCDIR($cf_cv_header_path_$3)
1557         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1558         CF_ADD_LIB($3)
1559 ],[$4])
1560 else
1561 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1562 fi
1563 ])dnl
1564 dnl ---------------------------------------------------------------------------
1565 dnl CF_FIND_SUB_INCDIR version: 1 updated: 2014/04/12 16:47:01
1566 dnl ------------------
1567 dnl Find an include-directory with the given leaf-name.  This is useful for
1568 dnl example with FreeBSD ports, which use this convention to distinguish
1569 dnl different versions of the same port.
1570 AC_DEFUN([CF_FIND_SUB_INCDIR],[
1571         CF_SUBDIR_PATH(cf_search,$1,include)
1572         for cf_item in $cf_search
1573         do
1574                 case $cf_item in #(vi
1575                 */$1)
1576                         CF_ADD_INCDIR($cf_item)
1577                         ;;
1578                 esac
1579         done
1580 ])dnl
1581 dnl ---------------------------------------------------------------------------
1582 dnl CF_FIND_SUB_LIBDIR version: 1 updated: 2014/04/12 16:47:01
1583 dnl ------------------
1584 dnl Find a library-directory with the given leaf-name.  This is useful for
1585 dnl example with FreeBSD ports, which use this convention to distinguish
1586 dnl different versions of the same port.
1587 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
1588         CF_SUBDIR_PATH(cf_search,$1,lib)
1589         for cf_item in $cf_search
1590         do
1591                 case $cf_item in #(vi
1592                 */$1)
1593                         CF_ADD_LIBDIR($cf_item)
1594                         ;;
1595                 esac
1596         done
1597 ])dnl
1598 dnl ---------------------------------------------------------------------------
1599 dnl CF_FIXUP_ADAFLAGS version: 1 updated: 2012/03/31 18:48:10
1600 dnl -----------------
1601 dnl make ADAFLAGS consistent with CFLAGS
1602 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1603         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1604         case "$CFLAGS" in
1605         *-g*)
1606                 CF_ADD_ADAFLAGS(-g)
1607                 ;;
1608         esac
1609         case "$CFLAGS" in
1610         *-O*)
1611                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1612                 CF_ADD_ADAFLAGS($cf_O_flag)
1613                 ;;
1614         esac
1615         AC_MSG_RESULT($ADAFLAGS)
1616 ])dnl
1617 dnl ---------------------------------------------------------------------------
1618 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
1619 dnl --------------
1620 dnl Forget that we saw the given tool.
1621 AC_DEFUN([CF_FORGET_TOOL],[
1622 unset ac_cv_prog_ac_ct_$1
1623 unset ac_ct_$1
1624 unset $1
1625 ])dnl
1626 dnl ---------------------------------------------------------------------------
1627 dnl CF_FUNC_DLSYM version: 3 updated: 2012/10/06 11:17:15
1628 dnl -------------
1629 dnl Test for dlsym() and related functions, as well as libdl.
1630 dnl
1631 dnl Sets
1632 dnl     $cf_have_dlsym
1633 dnl     $cf_have_libdl
1634 AC_DEFUN([CF_FUNC_DLSYM],[
1635 cf_have_dlsym=no
1636 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1637
1638 cf_have_libdl=no
1639 AC_CHECK_LIB(dl,dlsym,[
1640         cf_have_dlsym=yes
1641         cf_have_libdl=yes])])
1642
1643 if test "$cf_have_dlsym" = yes ; then
1644         test "$cf_have_libdl" = yes && CF_ADD_LIB(dl)
1645
1646         AC_MSG_CHECKING(whether able to link to dl*() functions)
1647         AC_TRY_LINK([#include <dlfcn.h>],[
1648                 void *obj;
1649                 if ((obj = dlopen("filename", 0)) != 0) {
1650                         if (dlsym(obj, "symbolname") == 0) {
1651                         dlclose(obj);
1652                         }
1653                 }],[
1654                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
1655                 AC_MSG_ERROR(Cannot link test program for libdl)])
1656         AC_MSG_RESULT(ok)
1657 else
1658         AC_MSG_ERROR(Cannot find dlsym function)
1659 fi
1660 ])
1661 dnl ---------------------------------------------------------------------------
1662 dnl CF_FUNC_MEMMOVE version: 8 updated: 2012/10/04 20:12:20
1663 dnl ---------------
1664 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1665 dnl is found, add our own version of memmove to the list of objects.
1666 AC_DEFUN([CF_FUNC_MEMMOVE],
1667 [
1668 AC_CHECK_FUNC(memmove,,[
1669 AC_CHECK_FUNC(bcopy,[
1670         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1671                 AC_TRY_RUN([
1672 int main() {
1673         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1674         char temp[40];
1675         bcopy(data, temp, sizeof(data));
1676         bcopy(temp+10, temp, 15);
1677         bcopy(temp+5, temp+15, 10);
1678         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1679 }
1680                 ],
1681                 [cf_cv_good_bcopy=yes],
1682                 [cf_cv_good_bcopy=no],
1683                 [cf_cv_good_bcopy=unknown])
1684                 ])
1685         ],[cf_cv_good_bcopy=no])
1686         if test "$cf_cv_good_bcopy" = yes ; then
1687                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
1688         else
1689                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
1690         fi
1691 ])])dnl
1692 dnl ---------------------------------------------------------------------------
1693 dnl CF_FUNC_NANOSLEEP version: 4 updated: 2012/10/06 17:56:13
1694 dnl -----------------
1695 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1696 dnl AIX 4.x, provide a non-working version.
1697 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1698 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1699 AC_TRY_RUN([
1700 #include <stdio.h>
1701 #include <errno.h>
1702 #include <time.h>
1703
1704 #ifdef HAVE_SYS_TIME_H
1705 #include <sys/time.h>
1706 #endif
1707
1708 int main() {
1709         struct timespec ts1, ts2;
1710         int code;
1711         ts1.tv_sec  = 0;
1712         ts1.tv_nsec = 750000000;
1713         ts2.tv_sec  = 0;
1714         ts2.tv_nsec = 0;
1715         errno = 0;
1716         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1717         ${cf_cv_main_return:-return}(code != 0);
1718 }
1719 ],
1720         [cf_cv_func_nanosleep=yes],
1721         [cf_cv_func_nanosleep=no],
1722         [cf_cv_func_nanosleep=unknown])])
1723
1724 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
1725 ])
1726 dnl ---------------------------------------------------------------------------
1727 dnl CF_FUNC_OPENPTY version: 3 updated: 2010/05/29 16:31:02
1728 dnl ---------------
1729 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1730 dnl "util" library as well.
1731 AC_DEFUN([CF_FUNC_OPENPTY],
1732 [
1733 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1734 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1735     cf_save_LIBS="$LIBS"
1736     test $cf_cv_lib_util = yes && CF_ADD_LIB(util)
1737     for cf_header in pty.h libutil.h util.h
1738     do
1739     AC_TRY_LINK([
1740 #include <$cf_header>
1741 ],[
1742     int x = openpty((int *)0, (int *)0, (char *)0,
1743                    (struct termios *)0, (struct winsize *)0);
1744 ],[
1745         cf_cv_func_openpty=$cf_header
1746         break
1747 ],[
1748         cf_cv_func_openpty=no
1749 ])
1750     done
1751     LIBS="$cf_save_LIBS"
1752 ])
1753 ])dnl
1754 dnl ---------------------------------------------------------------------------
1755 dnl CF_FUNC_POLL version: 8 updated: 2012/10/04 05:24:07
1756 dnl ------------
1757 dnl See if the poll function really works.  Some platforms have poll(), but
1758 dnl it does not work for terminals or files.
1759 AC_DEFUN([CF_FUNC_POLL],[
1760 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
1761 AC_TRY_RUN([
1762 #include <stdlib.h>
1763 #include <stdio.h>
1764 #include <unistd.h>
1765 #include <fcntl.h>
1766 #ifdef HAVE_POLL_H
1767 #include <poll.h>
1768 #else
1769 #include <sys/poll.h>
1770 #endif
1771 int main() {
1772         struct pollfd myfds;
1773         int ret;
1774
1775         /* check for Darwin bug with respect to "devices" */
1776         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
1777         if (myfds.fd < 0)
1778                 myfds.fd = 0;
1779         myfds.events = POLLIN;
1780         myfds.revents = 0;
1781
1782         ret = poll(&myfds, 1, 100);
1783
1784         if (ret < 0 || (myfds.revents & POLLNVAL)) {
1785                 ret = -1;
1786         } else {
1787                 int fd = 0;
1788                 if (!isatty(fd)) {
1789                         fd = open("/dev/tty", 2);       /* O_RDWR */
1790                 }
1791
1792                 if (fd >= 0) {
1793                         /* also check with standard input */
1794                         myfds.fd = fd;
1795                         myfds.events = POLLIN;
1796                         myfds.revents = 0;
1797                         ret = poll(&myfds, 1, 100);
1798                 } else {
1799                         ret = -1;
1800                 }
1801         }
1802         ${cf_cv_main_return:-return}(ret < 0);
1803 }],
1804         [cf_cv_working_poll=yes],
1805         [cf_cv_working_poll=no],
1806         [cf_cv_working_poll=unknown])])
1807 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
1808 ])dnl
1809 dnl ---------------------------------------------------------------------------
1810 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
1811 dnl ---------------
1812 dnl Some old/broken variations define tcgetattr() only as a macro in
1813 dnl termio(s).h
1814 AC_DEFUN([CF_FUNC_TERMIOS],[
1815 AC_REQUIRE([CF_STRUCT_TERMIOS])
1816 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
1817 AC_TRY_LINK([
1818 #include <sys/types.h>
1819 #ifdef HAVE_UNISTD_H
1820 #include <unistd.h>
1821 #endif
1822 #ifdef HAVE_TERMIOS_H
1823 #include <termios.h>
1824 #define TTY struct termios
1825 #else
1826 #ifdef HAVE_TERMIO_H
1827 #include <termio.h>
1828 #define TTY struct termio
1829 #endif
1830 #endif
1831 ],[
1832 TTY foo;
1833 tcgetattr(1, &foo);],
1834 [cf_cv_have_tcgetattr=yes],
1835 [cf_cv_have_tcgetattr=no])])
1836 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
1837 ])dnl
1838 dnl ---------------------------------------------------------------------------
1839 dnl CF_FUNC_VSSCANF version: 4 updated: 2012/10/06 17:56:13
1840 dnl ---------------
1841 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
1842 dnl versions of C.  It is in the GNU C library, and can often be simulated by
1843 dnl other functions.
1844 AC_DEFUN([CF_FUNC_VSSCANF],
1845 [
1846 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
1847 AC_TRY_LINK([
1848 #include <stdarg.h>
1849 #include <stdio.h>],[
1850         va_list ap;
1851         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
1852 AC_TRY_LINK([
1853 #include <stdarg.h>
1854 #include <stdio.h>],[
1855     FILE strbuf;
1856     char *str = "from";
1857
1858     strbuf._flag = _IOREAD;
1859     strbuf._ptr = strbuf._base = (unsigned char *) str;
1860     strbuf._cnt = strlen(str);
1861     strbuf._file = _NFILE;
1862     return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
1863 AC_TRY_LINK([
1864 #include <stdarg.h>
1865 #include <stdio.h>],[
1866     FILE strbuf;
1867     char *str = "from";
1868
1869     strbuf._flag = _IOREAD;
1870     strbuf._ptr = strbuf._base = (unsigned char *) str;
1871     strbuf._cnt = strlen(str);
1872     strbuf._file = _NFILE;
1873     return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
1874 cf_cv_func_vsscanf=no])])])])
1875
1876 case $cf_cv_func_vsscanf in #(vi
1877 vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);; #(vi
1878 vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);; #(vi
1879 _doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
1880 esac
1881
1882 ])dnl
1883 dnl ---------------------------------------------------------------------------
1884 dnl CF_GCC_ATTRIBUTES version: 16 updated: 2012/10/02 20:55:03
1885 dnl -----------------
1886 dnl Test for availability of useful gcc __attribute__ directives to quiet
1887 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1888 dnl to documentation, unrecognized directives cause older compilers to barf.
1889 AC_DEFUN([CF_GCC_ATTRIBUTES],
1890 [
1891 if test "$GCC" = yes
1892 then
1893 cat > conftest.i <<EOF
1894 #ifndef GCC_PRINTF
1895 #define GCC_PRINTF 0
1896 #endif
1897 #ifndef GCC_SCANF
1898 #define GCC_SCANF 0
1899 #endif
1900 #ifndef GCC_NORETURN
1901 #define GCC_NORETURN /* nothing */
1902 #endif
1903 #ifndef GCC_UNUSED
1904 #define GCC_UNUSED /* nothing */
1905 #endif
1906 EOF
1907 if test "$GCC" = yes
1908 then
1909         AC_CHECKING([for $CC __attribute__ directives])
1910 cat > conftest.$ac_ext <<EOF
1911 #line __oline__ "${as_me:-configure}"
1912 #include "confdefs.h"
1913 #include "conftest.h"
1914 #include "conftest.i"
1915 #if     GCC_PRINTF
1916 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1917 #else
1918 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1919 #endif
1920 #if     GCC_SCANF
1921 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1922 #else
1923 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1924 #endif
1925 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1926 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1927 extern void foo(void) GCC_NORETURN;
1928 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1929 EOF
1930         cf_printf_attribute=no
1931         cf_scanf_attribute=no
1932         for cf_attribute in scanf printf unused noreturn
1933         do
1934                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1935                 cf_directive="__attribute__(($cf_attribute))"
1936                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1937
1938                 case $cf_attribute in #(vi
1939                 printf) #(vi
1940                         cf_printf_attribute=yes
1941                         cat >conftest.h <<EOF
1942 #define GCC_$cf_ATTRIBUTE 1
1943 EOF
1944                         ;;
1945                 scanf) #(vi
1946                         cf_scanf_attribute=yes
1947                         cat >conftest.h <<EOF
1948 #define GCC_$cf_ATTRIBUTE 1
1949 EOF
1950                         ;;
1951                 *) #(vi
1952                         cat >conftest.h <<EOF
1953 #define GCC_$cf_ATTRIBUTE $cf_directive
1954 EOF
1955                         ;;
1956                 esac
1957
1958                 if AC_TRY_EVAL(ac_compile); then
1959                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1960                         cat conftest.h >>confdefs.h
1961                         case $cf_attribute in #(vi
1962                         noreturn) #(vi
1963                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1964                                 ;;
1965                         printf) #(vi
1966                                 cf_value='/* nothing */'
1967                                 if test "$cf_printf_attribute" != no ; then
1968                                         cf_value='__attribute__((format(printf,fmt,var)))'
1969                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1970                                 fi
1971                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1972                                 ;;
1973                         scanf) #(vi
1974                                 cf_value='/* nothing */'
1975                                 if test "$cf_scanf_attribute" != no ; then
1976                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1977                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1978                                 fi
1979                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1980                                 ;;
1981                         unused) #(vi
1982                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1983                                 ;;
1984                         esac
1985                 fi
1986         done
1987 else
1988         fgrep define conftest.i >>confdefs.h
1989 fi
1990 rm -rf conftest*
1991 fi
1992 ])dnl
1993 dnl ---------------------------------------------------------------------------
1994 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
1995 dnl --------------
1996 dnl Find version of gcc
1997 AC_DEFUN([CF_GCC_VERSION],[
1998 AC_REQUIRE([AC_PROG_CC])
1999 GCC_VERSION=none
2000 if test "$GCC" = yes ; then
2001         AC_MSG_CHECKING(version of $CC)
2002         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2003         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2004         AC_MSG_RESULT($GCC_VERSION)
2005 fi
2006 ])dnl
2007 dnl ---------------------------------------------------------------------------
2008 dnl CF_GCC_WARNINGS version: 31 updated: 2013/11/19 19:23:35
2009 dnl ---------------
2010 dnl Check if the compiler supports useful warning options.  There's a few that
2011 dnl we don't use, simply because they're too noisy:
2012 dnl
2013 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2014 dnl     -Wredundant-decls (system headers make this too noisy)
2015 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2016 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2017 dnl             is enabled for ncurses using "--enable-const".
2018 dnl     -pedantic
2019 dnl
2020 dnl Parameter:
2021 dnl     $1 is an optional list of gcc warning flags that a particular
2022 dnl             application might want to use, e.g., "no-unused" for
2023 dnl             -Wno-unused
2024 dnl Special:
2025 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2026 dnl
2027 AC_DEFUN([CF_GCC_WARNINGS],
2028 [
2029 AC_REQUIRE([CF_GCC_VERSION])
2030 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2031 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2032
2033 cat > conftest.$ac_ext <<EOF
2034 #line __oline__ "${as_me:-configure}"
2035 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2036 EOF
2037
2038 if test "$INTEL_COMPILER" = yes
2039 then
2040 # The "-wdXXX" options suppress warnings:
2041 # remark #1419: external declaration in primary source file
2042 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2043 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2044 # remark #193: zero used for undefined preprocessing identifier
2045 # remark #593: variable "curs_sb_left_arrow" was set but never used
2046 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2047 # remark #869: parameter "tw" was never referenced
2048 # remark #981: operands are evaluated in unspecified order
2049 # warning #279: controlling expression is constant
2050
2051         AC_CHECKING([for $CC warning options])
2052         cf_save_CFLAGS="$CFLAGS"
2053         EXTRA_CFLAGS="-Wall"
2054         for cf_opt in \
2055                 wd1419 \
2056                 wd1683 \
2057                 wd1684 \
2058                 wd193 \
2059                 wd593 \
2060                 wd279 \
2061                 wd810 \
2062                 wd869 \
2063                 wd981
2064         do
2065                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2066                 if AC_TRY_EVAL(ac_compile); then
2067                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2068                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2069                 fi
2070         done
2071         CFLAGS="$cf_save_CFLAGS"
2072
2073 elif test "$GCC" = yes
2074 then
2075         AC_CHECKING([for $CC warning options])
2076         cf_save_CFLAGS="$CFLAGS"
2077         EXTRA_CFLAGS=
2078         cf_warn_CONST=""
2079         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2080         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2081         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2082         for cf_opt in W Wall \
2083                 Wbad-function-cast \
2084                 Wcast-align \
2085                 Wcast-qual \
2086                 Wdeclaration-after-statement \
2087                 Wextra \
2088                 Winline \
2089                 Wmissing-declarations \
2090                 Wmissing-prototypes \
2091                 Wnested-externs \
2092                 Wpointer-arith \
2093                 Wshadow \
2094                 Wstrict-prototypes \
2095                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
2096         do
2097                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2098                 if AC_TRY_EVAL(ac_compile); then
2099                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2100                         case $cf_opt in #(vi
2101                         Wcast-qual) #(vi
2102                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
2103                                 ;;
2104                         Winline) #(vi
2105                                 case $GCC_VERSION in
2106                                 [[34]].*)
2107                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2108                                         continue;;
2109                                 esac
2110                                 ;;
2111                         Wpointer-arith) #(vi
2112                                 case $GCC_VERSION in
2113                                 [[12]].*)
2114                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2115                                         continue;;
2116                                 esac
2117                                 ;;
2118                         esac
2119                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2120                 fi
2121         done
2122         CFLAGS="$cf_save_CFLAGS"
2123 fi
2124 rm -rf conftest*
2125
2126 AC_SUBST(EXTRA_CFLAGS)
2127 ])dnl
2128 dnl ---------------------------------------------------------------------------
2129 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
2130 dnl ----------------
2131 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2132 dnl unistd.h or (nonstandard) in getopt.h
2133 AC_DEFUN([CF_GETOPT_HEADER],
2134 [
2135 AC_HAVE_HEADERS(unistd.h getopt.h)
2136 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2137 cf_cv_getopt_header=none
2138 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2139 do
2140 AC_TRY_COMPILE([
2141 #include <$cf_header>],
2142 [int x = optind; char *y = optarg],
2143 [cf_cv_getopt_header=$cf_header
2144  break])
2145 done
2146 ])
2147 if test $cf_cv_getopt_header != none ; then
2148         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2149 fi
2150 if test $cf_cv_getopt_header = getopt.h ; then
2151         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2152 fi
2153 ])dnl
2154 dnl ---------------------------------------------------------------------------
2155 dnl CF_GNAT_GENERICS version: 2 updated: 2011/03/23 20:24:41
2156 dnl ----------------
2157 AC_DEFUN([CF_GNAT_GENERICS],
2158 [
2159 AC_REQUIRE([CF_GNAT_VERSION])
2160
2161 AC_MSG_CHECKING(if GNAT supports generics)
2162 case $cf_gnat_version in #(vi
2163 3.[[1-9]]*|[[4-9]].*) #(vi
2164         cf_gnat_generics=yes
2165         ;;
2166 *)
2167         cf_gnat_generics=no
2168         ;;
2169 esac
2170 AC_MSG_RESULT($cf_gnat_generics)
2171
2172 if test "$cf_gnat_generics" = yes
2173 then
2174         cf_compile_generics=generics
2175         cf_generic_objects="\${GENOBJS}"
2176 else
2177         cf_compile_generics=
2178         cf_generic_objects=
2179 fi
2180
2181 AC_SUBST(cf_compile_generics)
2182 AC_SUBST(cf_generic_objects)
2183 ])dnl
2184 dnl ---------------------------------------------------------------------------
2185 dnl CF_GNAT_PROJECTS version: 7 updated: 2014/06/01 10:46:34
2186 dnl ----------------
2187 dnl GNAT projects are configured with ".gpr" project files.
2188 dnl GNAT libraries are a further development, using the project feature.
2189 AC_DEFUN([CF_GNAT_PROJECTS],
2190 [
2191 AC_REQUIRE([CF_GNAT_VERSION])
2192 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
2193
2194 cf_gnat_libraries=no
2195 cf_gnat_projects=no
2196
2197 if test "$enable_gnat_projects" != no ; then
2198 AC_MSG_CHECKING(if GNAT supports project files)
2199 case $cf_gnat_version in #(vi
2200 3.[[0-9]]*) #(vi
2201         ;;
2202 *)
2203         case $cf_cv_system_name in #(vi
2204         cygwin*|msys*) #(vi
2205                 ;;
2206         *)
2207                 mkdir conftest.src conftest.bin conftest.lib
2208                 cd conftest.src
2209                 rm -rf conftest* *~conftest*
2210                 cat >>library.gpr <<CF_EOF
2211 project Library is
2212   Kind := External ("LIB_KIND");
2213   for Library_Name use "ConfTest";
2214   for Object_Dir use ".";
2215   for Library_ALI_Dir use External("LIBRARY_DIR");
2216   for Library_Version use External ("SONAME");
2217   for Library_Kind use Kind;
2218   for Library_Dir use External("BUILD_DIR");
2219   Source_Dir := External ("SOURCE_DIR");
2220   for Source_Dirs use (Source_Dir);
2221 end Library;
2222 CF_EOF
2223                 cat >>confpackage.ads <<CF_EOF
2224 package ConfPackage is
2225    procedure conftest;
2226 end ConfPackage;
2227 CF_EOF
2228                 cat >>confpackage.adb <<CF_EOF
2229 with Text_IO;
2230 package body ConfPackage is
2231    procedure conftest is
2232    begin
2233       Text_IO.Put ("Hello World");
2234       Text_IO.New_Line;
2235    end conftest;
2236 end ConfPackage;
2237 CF_EOF
2238                 if ( $cf_ada_make $ADAFLAGS \
2239                                 -Plibrary.gpr \
2240                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2241                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2242                                 -XSOURCE_DIR=`pwd` \
2243                                 -XSONAME=libConfTest.so.1 \
2244                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2245                         cf_gnat_projects=yes
2246                 fi
2247                 cd ..
2248                 if test -f conftest.lib/confpackage.ali
2249                 then
2250                         cf_gnat_libraries=yes
2251                 fi
2252                 rm -rf conftest* *~conftest*
2253                 ;;
2254         esac
2255         ;;
2256 esac
2257 AC_MSG_RESULT($cf_gnat_projects)
2258 fi # enable_gnat_projects
2259
2260 if test $cf_gnat_projects = yes
2261 then
2262         AC_MSG_CHECKING(if GNAT supports libraries)
2263         AC_MSG_RESULT($cf_gnat_libraries)
2264 fi
2265
2266 if test "$cf_gnat_projects" = yes
2267 then
2268         USE_OLD_MAKERULES="#"
2269         USE_GNAT_PROJECTS=""
2270 else
2271         USE_OLD_MAKERULES=""
2272         USE_GNAT_PROJECTS="#"
2273 fi
2274
2275 if test "$cf_gnat_libraries" = yes
2276 then
2277         USE_GNAT_LIBRARIES=""
2278 else
2279         USE_GNAT_LIBRARIES="#"
2280 fi
2281
2282 AC_SUBST(USE_OLD_MAKERULES)
2283 AC_SUBST(USE_GNAT_PROJECTS)
2284 AC_SUBST(USE_GNAT_LIBRARIES)
2285 ])dnl
2286 dnl ---------------------------------------------------------------------------
2287 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2288 dnl --------------
2289 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2290 dnl is noted that gnat may compile a tasking unit even for configurations which
2291 dnl fail at runtime.
2292 AC_DEFUN([CF_GNAT_SIGINT],[
2293 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2294 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2295
2296 package ConfTest is
2297
2298    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2299    pragma Unreserve_All_Interrupts;
2300    pragma Warnings (On);
2301
2302    protected Process is
2303       procedure Stop;
2304       function Continue return Boolean;
2305       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2306    private
2307       Done : Boolean := False;
2308    end Process;
2309
2310 end ConfTest;],
2311 [package body ConfTest is
2312    protected body Process is
2313       procedure Stop is
2314       begin
2315          Done := True;
2316       end Stop;
2317       function Continue return Boolean is
2318       begin
2319          return not Done;
2320       end Continue;
2321    end Process;
2322 end ConfTest;],
2323         [cf_cv_gnat_sigint=yes],
2324         [cf_cv_gnat_sigint=no])])
2325
2326 if test $cf_cv_gnat_sigint = yes ; then
2327         USE_GNAT_SIGINT=""
2328 else
2329         USE_GNAT_SIGINT="#"
2330 fi
2331 AC_SUBST(USE_GNAT_SIGINT)
2332 ])dnl
2333 dnl ---------------------------------------------------------------------------
2334 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2335 dnl ----------------
2336 dnl Verify that a test program compiles/links with GNAT.
2337 dnl $cf_ada_make is set to the program that compiles/links
2338 dnl $ADAFLAGS may be set to the GNAT flags.
2339 dnl
2340 dnl $1 is the text of the spec
2341 dnl $2 is the text of the body
2342 dnl $3 is the shell command to execute if successful
2343 dnl $4 is the shell command to execute if not successful
2344 AC_DEFUN([CF_GNAT_TRY_LINK],
2345 [
2346 rm -rf conftest* *~conftest*
2347 cat >>conftest.ads <<CF_EOF
2348 $1
2349 CF_EOF
2350 cat >>conftest.adb <<CF_EOF
2351 $2
2352 CF_EOF
2353 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2354 ifelse($3,,      :,[      $3])
2355 ifelse($4,,,[else
2356    $4])
2357 fi
2358 rm -rf conftest* *~conftest*
2359 ])dnl
2360 dnl ---------------------------------------------------------------------------
2361 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2362 dnl ---------------
2363 dnl Verify that a test program compiles and runs with GNAT
2364 dnl $cf_ada_make is set to the program that compiles/links
2365 dnl $ADAFLAGS may be set to the GNAT flags.
2366 dnl
2367 dnl $1 is the text of the spec
2368 dnl $2 is the text of the body
2369 dnl $3 is the shell command to execute if successful
2370 dnl $4 is the shell command to execute if not successful
2371 AC_DEFUN([CF_GNAT_TRY_RUN],
2372 [
2373 rm -rf conftest* *~conftest*
2374 cat >>conftest.ads <<CF_EOF
2375 $1
2376 CF_EOF
2377 cat >>conftest.adb <<CF_EOF
2378 $2
2379 CF_EOF
2380 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2381    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2382 ifelse($3,,      :,[      $3])
2383 ifelse($4,,,[   else
2384       $4])
2385    fi
2386 ifelse($4,,,[else
2387    $4])
2388 fi
2389 rm -rf conftest* *~conftest*
2390 ])dnl
2391 dnl ---------------------------------------------------------------------------
2392 dnl CF_GNAT_VERSION version: 18 updated: 2012/01/21 19:28:10
2393 dnl ---------------
2394 dnl Verify version of GNAT.
2395 AC_DEFUN([CF_GNAT_VERSION],
2396 [
2397 AC_MSG_CHECKING(for gnat version)
2398 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2399         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2400     sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2401 AC_MSG_RESULT($cf_gnat_version)
2402
2403 case $cf_gnat_version in #(vi
2404 3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]]) #(vi
2405         cf_cv_prog_gnat_correct=yes
2406         ;;
2407 *)
2408         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2409         cf_cv_prog_gnat_correct=no
2410         ;;
2411 esac
2412 ])
2413 dnl ---------------------------------------------------------------------------
2414 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
2415 dnl -------------
2416 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2417 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2418 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2419 dnl since it is interwoven with GNU extensions.
2420 dnl
2421 dnl Well, yes we could work around it...
2422 AC_DEFUN([CF_GNU_SOURCE],
2423 [
2424 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2425 AC_TRY_COMPILE([#include <sys/types.h>],[
2426 #ifndef _XOPEN_SOURCE
2427 make an error
2428 #endif],
2429         [cf_cv_gnu_source=no],
2430         [cf_save="$CPPFLAGS"
2431          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2432          AC_TRY_COMPILE([#include <sys/types.h>],[
2433 #ifdef _XOPEN_SOURCE
2434 make an error
2435 #endif],
2436         [cf_cv_gnu_source=no],
2437         [cf_cv_gnu_source=yes])
2438         CPPFLAGS="$cf_save"
2439         ])
2440 ])
2441 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2442 ])dnl
2443 dnl ---------------------------------------------------------------------------
2444 dnl CF_GPP_LIBRARY version: 11 updated: 2012/10/06 17:56:13
2445 dnl --------------
2446 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2447 dnl problem :-).  If we have the compiler but no library, we'll be able to
2448 dnl configure, but won't be able to build the c++ demo program.
2449 AC_DEFUN([CF_GPP_LIBRARY],
2450 [
2451 cf_cxx_library=unknown
2452 case $cf_cv_system_name in #(vi
2453 os2*) #(vi
2454         cf_gpp_libname=gpp
2455         ;;
2456 *)
2457         cf_gpp_libname=g++
2458         ;;
2459 esac
2460 if test "$GXX" = yes; then
2461         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2462         cf_save="$LIBS"
2463         CF_ADD_LIB($cf_gpp_libname)
2464         AC_TRY_LINK([
2465 #include <$cf_gpp_libname/builtin.h>
2466         ],
2467         [two_arg_error_handler_t foo2 = lib_error_handler],
2468         [cf_cxx_library=yes
2469          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2470          if test "$cf_gpp_libname" = cpp ; then
2471             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
2472          else
2473             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
2474          fi],
2475         [AC_TRY_LINK([
2476 #include <builtin.h>
2477         ],
2478         [two_arg_error_handler_t foo2 = lib_error_handler],
2479         [cf_cxx_library=yes
2480          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2481          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
2482         [cf_cxx_library=no])])
2483         LIBS="$cf_save"
2484         AC_MSG_RESULT($cf_cxx_library)
2485 fi
2486 ])dnl
2487 dnl ---------------------------------------------------------------------------
2488 dnl CF_GXX_VERSION version: 7 updated: 2012/06/16 14:55:39
2489 dnl --------------
2490 dnl Check for version of g++
2491 AC_DEFUN([CF_GXX_VERSION],[
2492 AC_REQUIRE([AC_PROG_CPP])
2493 GXX_VERSION=none
2494 if test "$GXX" = yes; then
2495         AC_MSG_CHECKING(version of ${CXX:-g++})
2496         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2497         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2498         AC_MSG_RESULT($GXX_VERSION)
2499 fi
2500 ])dnl
2501 dnl ---------------------------------------------------------------------------
2502 dnl CF_GXX_WARNINGS version: 8 updated: 2013/11/16 14:27:53
2503 dnl ---------------
2504 dnl Check if the compiler supports useful warning options.
2505 dnl
2506 dnl Most of gcc's options apply to g++, except:
2507 dnl     -Wbad-function-cast
2508 dnl     -Wmissing-declarations
2509 dnl     -Wnested-externs
2510 dnl
2511 dnl Omit a few (for now):
2512 dnl     -Winline
2513 dnl
2514 dnl Parameter:
2515 dnl     $1 is an optional list of g++ warning flags that a particular
2516 dnl             application might want to use, e.g., "no-unused" for
2517 dnl             -Wno-unused
2518 dnl Special:
2519 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2520 dnl
2521 AC_DEFUN([CF_GXX_WARNINGS],
2522 [
2523
2524 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2525 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
2526
2527 AC_REQUIRE([CF_GXX_VERSION])
2528
2529 AC_LANG_SAVE
2530 AC_LANG_CPLUSPLUS
2531
2532 cat > conftest.$ac_ext <<EOF
2533 #line __oline__ "configure"
2534 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2535 EOF
2536
2537 if test "$INTEL_CPLUSPLUS" = yes
2538 then
2539 # The "-wdXXX" options suppress warnings:
2540 # remark #1419: external declaration in primary source file
2541 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2542 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2543 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2544 # remark #193: zero used for undefined preprocessing identifier
2545 # remark #593: variable "curs_sb_left_arrow" was set but never used
2546 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2547 # remark #869: parameter "tw" was never referenced
2548 # remark #981: operands are evaluated in unspecified order
2549 # warning #269: invalid format string conversion
2550
2551         AC_CHECKING([for $CC warning options])
2552         cf_save_CXXFLAGS="$CXXFLAGS"
2553         EXTRA_CXXFLAGS="-Wall"
2554         for cf_opt in \
2555                 wd1419 \
2556                 wd1682 \
2557                 wd1683 \
2558                 wd1684 \
2559                 wd193 \
2560                 wd279 \
2561                 wd593 \
2562                 wd810 \
2563                 wd869 \
2564                 wd981
2565         do
2566                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2567                 if AC_TRY_EVAL(ac_compile); then
2568                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2569                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2570                 fi
2571         done
2572         CXXFLAGS="$cf_save_CXXFLAGS"
2573
2574 elif test "$GXX" = yes
2575 then
2576         AC_CHECKING([for $CXX warning options])
2577         cf_save_CXXFLAGS="$CXXFLAGS"
2578         EXTRA_CXXFLAGS="-W -Wall"
2579         cf_gxx_extra_warnings=""
2580         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2581         case "$GCC_VERSION" in
2582         [[1-2]].*)
2583                 ;;
2584         *)
2585                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2586                 ;;
2587         esac
2588         for cf_opt in \
2589                 Wabi \
2590                 fabi-version=0 \
2591                 Wextra \
2592                 Wignored-qualifiers \
2593                 Wlogical-op \
2594                 Woverloaded-virtual \
2595                 Wsign-promo \
2596                 Wsynth \
2597                 Wold-style-cast \
2598                 Wcast-align \
2599                 Wcast-qual \
2600                 Wpointer-arith \
2601                 Wshadow \
2602                 Wundef $cf_gxx_extra_warnings $1
2603         do
2604                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2605                 if AC_TRY_EVAL(ac_compile); then
2606                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2607                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2608                 else
2609                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2610                 fi
2611         done
2612         CXXFLAGS="$cf_save_CXXFLAGS"
2613 fi
2614
2615 rm -rf conftest*
2616 AC_LANG_RESTORE
2617 AC_SUBST(EXTRA_CXXFLAGS)
2618 ])dnl
2619 dnl ---------------------------------------------------------------------------
2620 dnl CF_HASHED_DB version: 5 updated: 2014/04/12 16:47:01
2621 dnl ------------
2622 dnl Look for an instance of the Berkeley hashed database.
2623 dnl
2624 dnl $1 = optional parameter, to specify install-prefix for the database.
2625 AC_DEFUN([CF_HASHED_DB],
2626 [
2627 ifelse([$1],,,[
2628 case $1 in #(vi
2629 yes|*able*) #(vi
2630     ;;
2631 *)
2632     if test -d "$1" ; then
2633         CF_ADD_INCDIR($1/include)
2634         CF_ADD_LIBDIR($1/lib)
2635         else
2636                 case "$1" in #(vi
2637                 ./*|../*|/*)
2638                         AC_MSG_WARN(no such directory $1)
2639                         ;; #(vi
2640                 *)
2641                         CF_FIND_SUB_INCDIR($1)
2642                         CF_FIND_SUB_LIBDIR($1)
2643                         ;;
2644                 esac
2645     fi
2646 esac
2647 ])
2648 AC_CHECK_HEADER(db.h,[
2649 CF_HASHED_DB_VERSION
2650 if test "$cf_cv_hashed_db_version" = unknown ; then
2651         AC_MSG_ERROR(Cannot determine version of db)
2652 else
2653         CF_HASHED_DB_LIBS
2654         if test "$cf_cv_hashed_db_libs" = unknown ; then
2655                 AC_MSG_ERROR(Cannot determine library for db)
2656         elif test "$cf_cv_hashed_db_libs" != default ; then
2657                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2658         fi
2659 fi
2660 ],[
2661         AC_MSG_ERROR(Cannot find db.h)
2662 ])
2663 ])dnl
2664 dnl ---------------------------------------------------------------------------
2665 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2666 dnl -----------------
2667 dnl Given that we have the header and version for hashed database, find the
2668 dnl library information.
2669 AC_DEFUN([CF_HASHED_DB_LIBS],
2670 [
2671 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2672 cf_cv_hashed_db_libs=unknown
2673 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2674 do
2675         cf_save_libs="$LIBS"
2676         if test -n "$cf_db_libs"; then
2677                 CF_ADD_LIB($cf_db_libs)
2678         fi
2679         CF_MSG_LOG(checking for library "$cf_db_libs")
2680         AC_TRY_LINK([
2681 $ac_includes_default
2682 #include <db.h>
2683 ],[
2684         char *path = "/tmp/foo";
2685 #ifdef DB_VERSION_MAJOR
2686 #if DB_VERSION_MAJOR >= 4
2687         DB *result = 0;
2688         db_create(&result, NULL, 0);
2689         result->open(result,
2690                 NULL,
2691                 path,
2692                 path,
2693                 DB_HASH,
2694                 DB_CREATE,
2695                 0644);
2696 #elif DB_VERSION_MAJOR >= 3
2697         DB *result = 0;
2698         db_create(&result, NULL, 0);
2699         result->open(result,
2700                 path,
2701                 path,
2702                 DB_HASH,
2703                 DB_CREATE,
2704                 0644);
2705 #elif DB_VERSION_MAJOR >= 2
2706         DB *result = 0;
2707         db_open(path,
2708                 DB_HASH,
2709                 DB_CREATE,
2710                 0644,
2711                 (DB_ENV *) 0,
2712                 (DB_INFO *) 0,
2713                 &result);
2714 #endif /* DB_VERSION_MAJOR */
2715 #else
2716         DB *result = dbopen(path,
2717                      2,
2718                      0644,
2719                      DB_HASH,
2720                      0);
2721 #endif
2722         ${cf_cv_main_return:-return}(result != 0)
2723 ],[
2724         if test -n "$cf_db_libs" ; then
2725                 cf_cv_hashed_db_libs=$cf_db_libs
2726         else
2727                 cf_cv_hashed_db_libs=default
2728         fi
2729         LIBS="$cf_save_libs"
2730         break
2731 ])
2732         LIBS="$cf_save_libs"
2733 done
2734 ])
2735 ])dnl
2736 dnl ---------------------------------------------------------------------------
2737 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
2738 dnl --------------------
2739 dnl Given that we have the header file for hashed database, find the version
2740 dnl information.
2741 AC_DEFUN([CF_HASHED_DB_VERSION],
2742 [
2743 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
2744 cf_cv_hashed_db_version=unknown
2745
2746 for cf_db_version in 1 2 3 4 5 6
2747 do
2748         CF_MSG_LOG(checking for db version $cf_db_version)
2749         AC_TRY_COMPILE([
2750 $ac_includes_default
2751 #include <db.h>
2752
2753 #ifdef DB_VERSION_MAJOR
2754         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
2755 #if $cf_db_version == DB_VERSION_MAJOR
2756         /* ok */
2757 #else
2758         make an error
2759 #endif
2760 #else
2761 #if $cf_db_version == 1
2762         /* ok: assuming this is DB 1.8.5 */
2763 #else
2764         make an error
2765 #endif
2766 #endif
2767 ],[DBT *foo = 0],[
2768         cf_cv_hashed_db_version=$cf_db_version
2769         break
2770         ])
2771 done
2772 ])
2773 ])dnl
2774 dnl ---------------------------------------------------------------------------
2775 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
2776 dnl --------------
2777 dnl Construct a search-list of directories for a nonstandard header-file
2778 dnl
2779 dnl Parameters
2780 dnl     $1 = the variable to return as result
2781 dnl     $2 = the package name
2782 AC_DEFUN([CF_HEADER_PATH],
2783 [
2784 $1=
2785
2786 # collect the current set of include-directories from compiler flags
2787 cf_header_path_list=""
2788 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2789         for cf_header_path in $CPPFLAGS $CFLAGS
2790         do
2791                 case $cf_header_path in #(vi
2792                 -I*)
2793                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2794                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2795                         cf_header_path_list="$cf_header_path_list [$]$1"
2796                         ;;
2797                 esac
2798         done
2799 fi
2800
2801 # add the variations for the package we are looking for
2802 CF_SUBDIR_PATH($1,$2,include)
2803
2804 test "$includedir" != NONE && \
2805 test "$includedir" != "/usr/include" && \
2806 test -d "$includedir" && {
2807         test -d $includedir &&    $1="[$]$1 $includedir"
2808         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
2809 }
2810
2811 test "$oldincludedir" != NONE && \
2812 test "$oldincludedir" != "/usr/include" && \
2813 test -d "$oldincludedir" && {
2814         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
2815         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
2816 }
2817
2818 $1="[$]$1 $cf_header_path_list"
2819 ])dnl
2820 dnl ---------------------------------------------------------------------------
2821 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
2822 dnl ---------------
2823 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2824 AC_DEFUN([CF_HELP_MESSAGE],
2825 [AC_DIVERT_HELP([$1])dnl
2826 ])dnl
2827 dnl ---------------------------------------------------------------------------
2828 dnl CF_INCLUDE_DIRS version: 9 updated: 2014/07/26 18:54:28
2829 dnl ---------------
2830 dnl Construct the list of include-options according to whether we're building
2831 dnl in the source directory or using '--srcdir=DIR' option.  If we're building
2832 dnl with gcc, don't append the includedir if it happens to be /usr/include,
2833 dnl since that usually breaks gcc's shadow-includes.
2834 AC_DEFUN([CF_INCLUDE_DIRS],
2835 [
2836 if test "$GCC" != yes; then
2837         CPPFLAGS="-I\${includedir} $CPPFLAGS"
2838 elif test "$includedir" != "/usr/include"; then
2839         if test "$includedir" = '${prefix}/include' ; then
2840                 if test x$prefix != x/usr ; then
2841                         CPPFLAGS="-I\${includedir} $CPPFLAGS"
2842                 fi
2843         else
2844                 CPPFLAGS="-I\${includedir} $CPPFLAGS"
2845         fi
2846 fi
2847 if test "$srcdir" != "."; then
2848         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
2849 fi
2850 CPPFLAGS="-I../include $CPPFLAGS"
2851 if test "$srcdir" != "."; then
2852         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
2853 fi
2854 CPPFLAGS="-I. $CPPFLAGS"
2855 AC_SUBST(CPPFLAGS)
2856 ])dnl
2857 dnl ---------------------------------------------------------------------------
2858 dnl CF_INTEL_COMPILER version: 6 updated: 2014/03/17 13:13:07
2859 dnl -----------------
2860 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2861 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2862 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2863 dnl
2864 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2865 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2866 dnl the wrappers for gcc and g++ warnings.
2867 dnl
2868 dnl $1 = GCC (default) or GXX
2869 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2870 dnl $3 = CFLAGS (default) or CXXFLAGS
2871 AC_DEFUN([CF_INTEL_COMPILER],[
2872 AC_REQUIRE([AC_CANONICAL_HOST])
2873 ifelse([$2],,INTEL_COMPILER,[$2])=no
2874
2875 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2876         case $host_os in
2877         linux*|gnu*)
2878                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2879                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2880                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2881                 AC_TRY_COMPILE([],[
2882 #ifdef __INTEL_COMPILER
2883 #else
2884 make an error
2885 #endif
2886 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2887 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
2888 ],[])
2889                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2890                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2891                 ;;
2892         esac
2893 fi
2894 ])dnl
2895 dnl ---------------------------------------------------------------------------
2896 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
2897 dnl ----------
2898 dnl Check if we have either a function or macro for 'isascii()'.
2899 AC_DEFUN([CF_ISASCII],
2900 [
2901 AC_MSG_CHECKING(for isascii)
2902 AC_CACHE_VAL(cf_cv_have_isascii,[
2903         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
2904         [cf_cv_have_isascii=yes],
2905         [cf_cv_have_isascii=no])
2906 ])dnl
2907 AC_MSG_RESULT($cf_cv_have_isascii)
2908 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
2909 ])dnl
2910 dnl ---------------------------------------------------------------------------
2911 dnl CF_LARGEFILE version: 8 updated: 2012/10/06 08:57:51
2912 dnl ------------
2913 dnl Add checks for large file support.
2914 AC_DEFUN([CF_LARGEFILE],[
2915 ifdef([AC_FUNC_FSEEKO],[
2916     AC_SYS_LARGEFILE
2917     if test "$enable_largefile" != no ; then
2918         AC_FUNC_FSEEKO
2919
2920         # Normally we would collect these definitions in the config.h,
2921         # but (like _XOPEN_SOURCE), some environments rely on having these
2922         # defined before any of the system headers are included.  Another
2923         # case comes up with C++, e.g., on AIX the compiler compiles the
2924         # header files by themselves before looking at the body files it is
2925         # told to compile.  For ncurses, those header files do not include
2926         # the config.h
2927         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
2928         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
2929         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
2930
2931         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2932                 AC_TRY_COMPILE([
2933 #include <sys/types.h>
2934 #include <dirent.h>
2935                 ],[
2936                 /* if transitional largefile support is setup, this is true */
2937                 extern struct dirent64 * readdir(DIR *);
2938                 struct dirent64 *x = readdir((DIR *)0);
2939                 struct dirent *y = readdir((DIR *)0);
2940                 int z = x - y;
2941                 ],
2942                 [cf_cv_struct_dirent64=yes],
2943                 [cf_cv_struct_dirent64=no])
2944         ])
2945         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
2946     fi
2947 ])
2948 ])
2949 dnl ---------------------------------------------------------------------------
2950 dnl CF_LDFLAGS_STATIC version: 10 updated: 2011/09/24 12:51:48
2951 dnl -----------------
2952 dnl Check for compiler/linker flags used to temporarily force usage of static
2953 dnl libraries.  This depends on the compiler and platform.  Use this to help
2954 dnl ensure that the linker picks up a given library based on its position in
2955 dnl the list of linker options and libraries.
2956 AC_DEFUN([CF_LDFLAGS_STATIC],[
2957
2958 if test "$GCC" = yes ; then
2959         case $cf_cv_system_name in #(
2960         OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)         #( vi
2961                 LDFLAGS_STATIC=
2962                 LDFLAGS_SHARED=
2963                 ;;
2964     *)  #( normally, except when broken
2965         LDFLAGS_STATIC=-static
2966         LDFLAGS_SHARED=-dynamic
2967         ;;
2968     esac
2969 else
2970         case $cf_cv_system_name in #(
2971         aix[[4-7]]*)    #( from ld manpage
2972                 LDFLAGS_STATIC=-bstatic
2973                 LDFLAGS_SHARED=-bdynamic
2974                 ;;
2975         hpux*)          #( from ld manpage for hpux10.20, hpux11.11
2976                 # We could also use just "archive" and "shared".
2977                 LDFLAGS_STATIC=-Wl,-a,archive_shared
2978                 LDFLAGS_SHARED=-Wl,-a,shared_archive
2979                 ;;
2980         irix*)          #( from ld manpage IRIX64
2981                 LDFLAGS_STATIC=-Bstatic
2982                 LDFLAGS_SHARED=-Bdynamic
2983                 ;;
2984         osf[[45]]*)     #( from ld manpage osf4.0d, osf5.1
2985                 # alternative "-oldstyle_liblookup" (not in cc manpage)
2986                 LDFLAGS_STATIC=-noso
2987                 LDFLAGS_SHARED=-so_archive
2988                 ;;
2989         solaris2*)
2990                 LDFLAGS_STATIC=-Bstatic
2991                 LDFLAGS_SHARED=-Bdynamic
2992                 ;;
2993         esac
2994 fi
2995
2996 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
2997 then
2998         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
2999
3000         rm -f libconftest.a
3001         cat >conftest.$ac_ext <<EOF
3002 #line __oline__ "configure"
3003 #include <stdio.h>
3004 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
3005 EOF
3006         if AC_TRY_EVAL(ac_compile) ; then
3007                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
3008                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
3009         fi
3010         rm -f conftest.*
3011
3012         cf_save_LIBS="$LIBS"
3013
3014         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
3015         AC_TRY_LINK([
3016 #line __oline__ "configure"
3017 #include <stdio.h>
3018 int cf_ldflags_static(FILE *fp);
3019 ],[
3020         return cf_ldflags_static(stdin);
3021 ],[
3022         # some linkers simply ignore the -dynamic
3023         case x`file conftest$ac_exeext 2>/dev/null` in #(vi
3024         *static*) # (vi
3025                 cf_ldflags_static=no
3026                 ;;
3027         *)
3028                 cf_ldflags_static=yes
3029                 ;;
3030         esac
3031 ],[cf_ldflags_static=no])
3032
3033         rm -f libconftest.*
3034         LIBS="$cf_save_LIBS"
3035
3036         AC_MSG_RESULT($cf_ldflags_static)
3037
3038         if test $cf_ldflags_static != yes
3039         then
3040                 LDFLAGS_STATIC=
3041                 LDFLAGS_SHARED=
3042         fi
3043 else
3044         LDFLAGS_STATIC=
3045         LDFLAGS_SHARED=
3046 fi
3047
3048 AC_SUBST(LDFLAGS_STATIC)
3049 AC_SUBST(LDFLAGS_SHARED)
3050 ])
3051 dnl ---------------------------------------------------------------------------
3052 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
3053 dnl ---------------
3054 dnl For the given system and compiler, find the compiler flags to pass to the
3055 dnl loader to use the "rpath" feature.
3056 AC_DEFUN([CF_LD_RPATH_OPT],
3057 [
3058 AC_REQUIRE([CF_CHECK_CACHE])
3059
3060 LD_RPATH_OPT=
3061 AC_MSG_CHECKING(for an rpath option)
3062 case $cf_cv_system_name in #(vi
3063 irix*) #(vi
3064         if test "$GCC" = yes; then
3065                 LD_RPATH_OPT="-Wl,-rpath,"
3066         else
3067                 LD_RPATH_OPT="-rpath "
3068         fi
3069         ;;
3070 linux*|gnu*|k*bsd*-gnu) #(vi
3071         LD_RPATH_OPT="-Wl,-rpath,"
3072         ;;
3073 openbsd[[2-9]].*|mirbsd*) #(vi
3074         LD_RPATH_OPT="-Wl,-rpath,"
3075         ;;
3076 dragonfly*|freebsd*) #(vi
3077         LD_RPATH_OPT="-rpath "
3078         ;;
3079 netbsd*) #(vi
3080         LD_RPATH_OPT="-Wl,-rpath,"
3081         ;;
3082 osf*|mls+*) #(vi
3083         LD_RPATH_OPT="-rpath "
3084         ;;
3085 solaris2*) #(vi
3086         LD_RPATH_OPT="-R"
3087         ;;
3088 *)
3089         ;;
3090 esac
3091 AC_MSG_RESULT($LD_RPATH_OPT)
3092
3093 case "x$LD_RPATH_OPT" in #(vi
3094 x-R*)
3095         AC_MSG_CHECKING(if we need a space after rpath option)
3096         cf_save_LIBS="$LIBS"
3097         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3098         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3099         LIBS="$cf_save_LIBS"
3100         AC_MSG_RESULT($cf_rpath_space)
3101         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3102         ;;
3103 esac
3104 ])dnl
3105 dnl ---------------------------------------------------------------------------
3106 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
3107 dnl ---------------
3108 dnl Construct a search-list of directories for a nonstandard library-file
3109 dnl
3110 dnl Parameters
3111 dnl     $1 = the variable to return as result
3112 dnl     $2 = the package name
3113 AC_DEFUN([CF_LIBRARY_PATH],
3114 [
3115 $1=
3116 cf_library_path_list=""
3117 if test -n "${LDFLAGS}${LIBS}" ; then
3118         for cf_library_path in $LDFLAGS $LIBS
3119         do
3120                 case $cf_library_path in #(vi
3121                 -L*)
3122                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3123                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3124                         cf_library_path_list="$cf_library_path_list [$]$1"
3125                         ;;
3126                 esac
3127         done
3128 fi
3129
3130 CF_SUBDIR_PATH($1,$2,lib)
3131
3132 $1="$cf_library_path_list [$]$1"
3133 ])dnl
3134 dnl ---------------------------------------------------------------------------
3135 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
3136 dnl ------------------
3137 AC_DEFUN([CF_LIBTOOL_VERSION],[
3138 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
3139 then
3140         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
3141 else
3142         cf_cv_libtool_version=
3143 fi
3144 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
3145 ])dnl
3146 dnl ---------------------------------------------------------------------------
3147 dnl CF_LIB_PREFIX version: 9 updated: 2012/01/21 19:28:10
3148 dnl -------------
3149 dnl Compute the library-prefix for the given host system
3150 dnl $1 = variable to set
3151 define([CF_LIB_PREFIX],
3152 [
3153         case $cf_cv_system_name in #(vi
3154         OS/2*|os2*) #(vi
3155         LIB_PREFIX=''
3156         ;;
3157         *)      LIB_PREFIX='lib'
3158         ;;
3159         esac
3160 ifelse($1,,,[$1=$LIB_PREFIX])
3161         AC_SUBST(LIB_PREFIX)
3162 ])dnl
3163 dnl ---------------------------------------------------------------------------
3164 dnl CF_LIB_RULES version: 74 updated: 2013/09/07 13:54:05
3165 dnl ------------
3166 dnl Append definitions and rules for the given models to the subdirectory
3167 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3168 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
3169 dnl the corresponding makefile to list the models that we'll generate.
3170 dnl
3171 dnl For shared libraries, make a list of symbolic links to construct when
3172 dnl generating each library.  The convention used for Linux is the simplest
3173 dnl one:
3174 dnl     lib<name>.so    ->
3175 dnl     lib<name>.so.<major>    ->
3176 dnl     lib<name>.so.<maj>.<minor>
3177 dnl
3178 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
3179 AC_DEFUN([CF_LIB_RULES],
3180 [
3181 cf_prefix=$LIB_PREFIX
3182 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3183
3184 case $cf_cv_shlib_version in #(vi
3185 cygdll|msysdll|mingw)
3186         TINFO_NAME=$TINFO_ARG_SUFFIX
3187         TINFO_SUFFIX=.dll
3188         ;;
3189 esac
3190
3191 if test -n "$TINFO_SUFFIX" ; then
3192         case $TINFO_SUFFIX in
3193         tw*)
3194                 TINFO_NAME="${TINFO_NAME}tw"
3195                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw//'`
3196                 ;;
3197         t*)
3198                 TINFO_NAME="${TINFO_NAME}t"
3199                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t//'`
3200                 ;;
3201         w*)
3202                 TINFO_NAME="${TINFO_NAME}w"
3203                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w//'`
3204                 ;;
3205         esac
3206 fi
3207
3208 for cf_dir in $SRC_SUBDIRS
3209 do
3210         if test ! -d $srcdir/$cf_dir ; then
3211                 continue
3212         elif test -f $srcdir/$cf_dir/modules; then
3213
3214                 SHARED_LIB=
3215                 Libs_To_Make=
3216                 for cf_item in $cf_LIST_MODELS
3217                 do
3218                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3219                         cf_libname=$cf_dir
3220                         test "$cf_dir" = c++ && cf_libname=ncurses++
3221                         if test $cf_item = shared ; then
3222                                 if test -n "${LIB_SUFFIX}"
3223                                 then
3224                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${LIB_SUFFIX}"'//'`
3225                                 else
3226                                         cf_shared_suffix="$cf_suffix"
3227                                 fi
3228                                 if test "$cf_cv_do_symlinks" = yes ; then
3229                                         cf_version_name=
3230
3231                                         case "$cf_cv_shlib_version" in #(vi
3232                                         rel) #(vi
3233                                                 cf_version_name=REL_VERSION
3234                                                 ;;
3235                                         abi)
3236                                                 cf_version_name=ABI_VERSION
3237                                                 ;;
3238                                         esac
3239
3240                                         if test -n "$cf_version_name"
3241                                         then
3242                                                 case "$cf_cv_system_name" in #(vi
3243                                                 darwin*)
3244                                                         # "w", etc?
3245                                                         cf_suffix="${LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
3246                                                         ;; #(vi
3247                                                 *)
3248                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
3249                                                         ;;
3250                                                 esac
3251                                         fi
3252                                         if test -n "${LIB_SUFFIX}"
3253                                         then
3254                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${LIB_SUFFIX}"'//'`
3255                                         else
3256                                                 cf_shared_suffix="$cf_suffix"
3257                                         fi
3258                                 fi
3259                                 # cygwin needs import library, and has unique naming convention
3260                                 # use autodetected ${cf_prefix} for import lib and static lib, but
3261                                 # use 'cyg' prefix for shared lib.
3262                                 case $cf_cv_shlib_version in #(vi
3263                                 cygdll) #(vi
3264                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3265                                         Libs_To_Make="$Libs_To_Make ../lib/cyg${cf_libname}${cf_cygsuf}"
3266                                         continue
3267                                         ;;
3268                                 msysdll) #(vi
3269                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3270                                         Libs_To_Make="$Libs_To_Make ../lib/msys-${cf_libname}${cf_cygsuf}"
3271                                         continue
3272                                         ;;
3273                                 mingw)
3274                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3275                                         Libs_To_Make="$Libs_To_Make ../lib/lib${cf_libname}${cf_cygsuf}"
3276                                         continue
3277                                         ;;
3278                                 esac
3279                         fi
3280                         Libs_To_Make="$Libs_To_Make ../lib/${cf_prefix}${cf_libname}${cf_suffix}"
3281                 done
3282
3283                 if test $cf_dir = ncurses ; then
3284                         cf_subsets="$LIB_SUBSETS"
3285                         cf_r_parts="$cf_subsets"
3286                         cf_liblist="$Libs_To_Make"
3287
3288                         while test -n "$cf_r_parts"
3289                         do
3290                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3291                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3292                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3293                                         cf_item=
3294                                         case $cf_l_parts in #(vi
3295                                         *termlib*) #(vi
3296                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3297                                                 ;;
3298                                         *ticlib*)
3299                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3300                                                 ;;
3301                                         *)
3302                                                 break
3303                                                 ;;
3304                                         esac
3305                                         if test -n "$cf_item"; then
3306                                                 Libs_To_Make="$cf_item $Libs_To_Make"
3307                                         fi
3308                                 else
3309                                         break
3310                                 fi
3311                         done
3312                 else
3313                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3314                 fi
3315
3316                 if test $cf_dir = c++; then
3317                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
3318                                 cf_list=
3319                                 for cf_item in $Libs_To_Make
3320                                 do
3321                                         case $cf_item in
3322                                         *.a)
3323                                                 ;;
3324                                         *)
3325                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
3326                                                 ;;
3327                                         esac
3328                                         for cf_test in $cf_list
3329                                         do
3330                                                 if test "$cf_test" = "$cf_item"
3331                                                 then
3332                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
3333                                                         cf_item=
3334                                                         break
3335                                                 fi
3336                                         done
3337                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
3338                                 done
3339                                 Libs_To_Make="$cf_list"
3340                         fi
3341                 fi
3342
3343                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
3344                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3345                         $cf_dir/Makefile >$cf_dir/Makefile.out
3346                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3347
3348                 $AWK -f $srcdir/mk-0th.awk \
3349                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
3350                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3351
3352                 for cf_subset in $cf_subsets
3353                 do
3354                         cf_subdirs=
3355                         for cf_item in $cf_LIST_MODELS
3356                         do
3357
3358                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3359                         CF_UPPER(cf_ITEM,$cf_item)
3360
3361                         CXX_MODEL=$cf_ITEM
3362                         if test "$CXX_MODEL" = SHARED; then
3363                                 case $cf_cv_shlib_version in #(vi
3364                                 cygdll|msysdll|mingw) #(vi
3365                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
3366                                         with_shared_cxx=yes
3367                                         ;;
3368                                 *)
3369                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
3370                                         ;;
3371                                 esac
3372                         fi
3373
3374                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3375                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3376
3377                         # Test for case where we build libtinfo with a different name.
3378                         cf_libname=$cf_dir
3379                         if test $cf_dir = ncurses ; then
3380                                 case $cf_subset in
3381                                 *base*)
3382                                         cf_libname=${cf_libname}$LIB_SUFFIX
3383                                         ;;
3384                                 *termlib*)
3385                                         cf_libname=$TINFO_LIB_SUFFIX
3386                                         ;;
3387                                 ticlib*)
3388                                         cf_libname=$TICS_LIB_SUFFIX
3389                                         ;;
3390                                 esac
3391                         elif test $cf_dir = c++ ; then
3392                                 cf_libname=ncurses++$LIB_SUFFIX
3393                         else
3394                                 cf_libname=${cf_libname}$LIB_SUFFIX
3395                         fi
3396                         if test -n "${DFT_ARG_SUFFIX}" ; then
3397                                 # undo $LIB_SUFFIX add-on in CF_LIB_SUFFIX
3398                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${LIB_SUFFIX}%%"`
3399                         fi
3400
3401                         # These dependencies really are for development, not
3402                         # builds, but they are useful in porting, too.
3403                         cf_depend="../include/ncurses_cfg.h"
3404                         if test "$srcdir" = "."; then
3405                                 cf_reldir="."
3406                         else
3407                                 cf_reldir="\${srcdir}"
3408                         fi
3409
3410                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3411                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3412                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3413                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3414                         fi
3415
3416                         cf_dir_suffix=
3417                         old_cf_suffix="$cf_suffix"
3418                         if test "$cf_cv_shlib_version_infix" = yes ; then
3419                         if test -n "$LIB_SUFFIX" ; then
3420                                 case $LIB_SUFFIX in
3421                                 tw*)
3422                                         cf_libname=`echo $cf_libname | sed 's/tw$//'`
3423                                         cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3424                                         cf_dir_suffix=tw
3425                                         ;;
3426                                 t*)
3427                                         cf_libname=`echo $cf_libname | sed 's/t$//'`
3428                                         cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3429                                         cf_dir_suffix=t
3430                                         ;;
3431                                 w*)
3432                                         cf_libname=`echo $cf_libname | sed 's/w$//'`
3433                                         cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3434                                         cf_dir_suffix=w
3435                                         ;;
3436                                 esac
3437                         fi
3438                         fi
3439
3440                         $AWK -f $srcdir/mk-1st.awk \
3441                                 name=${cf_libname}${cf_dir_suffix} \
3442                                 traces=$LIB_TRACING \
3443                                 MODEL=$cf_ITEM \
3444                                 CXX_MODEL=$CXX_MODEL \
3445                                 model=$cf_subdir \
3446                                 prefix=$cf_prefix \
3447                                 suffix=$cf_suffix \
3448                                 subset=$cf_subset \
3449                                 driver=$cf_cv_term_driver \
3450                                 SymLink="$LN_S" \
3451                                 TermlibRoot=$TINFO_NAME \
3452                                 TermlibSuffix=$TINFO_SUFFIX \
3453                                 ShlibVer=$cf_cv_shlib_version \
3454                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3455                                 ReLink=${cf_cv_do_relink:-no} \
3456                                 DoLinks=$cf_cv_do_symlinks \
3457                                 rmSoLocs=$cf_cv_rm_so_locs \
3458                                 ldconfig="$LDCONFIG" \
3459                                 overwrite=$WITH_OVERWRITE \
3460                                 depend="$cf_depend" \
3461                                 host="$host" \
3462                                 libtool_version="$LIBTOOL_VERSION" \
3463                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3464
3465                         cf_suffix="$old_cf_suffix"
3466
3467                         for cf_subdir2 in $cf_subdirs lib
3468                         do
3469                                 test $cf_subdir = $cf_subdir2 && break
3470                         done
3471                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3472                         $AWK -f $srcdir/mk-2nd.awk \
3473                                 name=$cf_dir \
3474                                 traces=$LIB_TRACING \
3475                                 MODEL=$cf_ITEM \
3476                                 model=$cf_subdir \
3477                                 subset=$cf_subset \
3478                                 srcdir=$srcdir \
3479                                 echo=$WITH_ECHO \
3480                                 crenames=$cf_cv_prog_CC_c_o \
3481                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3482                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3483                         cf_subdirs="$cf_subdirs $cf_subdir"
3484                         done
3485                 done
3486         fi
3487
3488         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
3489 done
3490
3491 for cf_dir in $SRC_SUBDIRS
3492 do
3493         if test ! -d $srcdir/$cf_dir ; then
3494                 continue
3495         fi
3496
3497         if test -f $cf_dir/Makefile ; then
3498                 case "$cf_dir" in
3499                 Ada95) #(vi
3500                         echo 'libs \' >> Makefile
3501                         echo 'install.libs \' >> Makefile
3502                         echo 'uninstall.libs ::' >> Makefile
3503                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
3504                         ;;
3505                 esac
3506         fi
3507
3508         if test -f $srcdir/$cf_dir/modules; then
3509                 echo >> Makefile
3510                 if test -f $srcdir/$cf_dir/headers; then
3511 cat >> Makefile <<CF_EOF
3512 install.includes \\
3513 uninstall.includes \\
3514 CF_EOF
3515                 fi
3516 if test "$cf_dir" != "c++" ; then
3517 echo 'lint \' >> Makefile
3518 fi
3519 cat >> Makefile <<CF_EOF
3520 libs \\
3521 lintlib \\
3522 install.libs \\
3523 uninstall.libs \\
3524 install.$cf_dir \\
3525 uninstall.$cf_dir ::
3526         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3527 CF_EOF
3528         elif test -f $srcdir/$cf_dir/headers; then
3529 cat >> Makefile <<CF_EOF
3530
3531 libs \\
3532 install.libs \\
3533 uninstall.libs \\
3534 install.includes \\
3535 uninstall.includes ::
3536         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3537 CF_EOF
3538 fi
3539 done
3540
3541 if test "x$cf_with_db_install" = xyes; then
3542 cat >> Makefile <<CF_EOF
3543
3544 install.libs uninstall.libs \\
3545 install.data uninstall.data ::
3546 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3547 CF_EOF
3548 fi
3549
3550 if test "x$cf_with_manpages" = xyes; then
3551 cat >> Makefile <<CF_EOF
3552
3553 install.man \\
3554 uninstall.man ::
3555         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
3556 CF_EOF
3557 fi
3558
3559 cat >> Makefile <<CF_EOF
3560
3561 distclean ::
3562         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3563         rm -f headers.sh headers.sed mk_shared_lib.sh
3564         rm -f edit_man.* man_alias.*
3565         rm -rf \${DIRS_TO_MAKE}
3566 CF_EOF
3567
3568 # Special case: tack's manpage lives in its own directory.
3569 if test "x$cf_with_manpages" = xyes; then
3570 if test -d tack ; then
3571 if test -f $srcdir/$tack.h; then
3572 cat >> Makefile <<CF_EOF
3573
3574 install.man \\
3575 uninstall.man ::
3576         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
3577 CF_EOF
3578 fi
3579 fi
3580 fi
3581
3582 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3583 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3584 dnl anything, and will make it more standardized.  It's awkward to decide this
3585 dnl at configuration because of quoting, so we'll simply make all headers
3586 dnl installed via a script that can do the right thing.
3587
3588 rm -f headers.sed headers.sh
3589
3590 dnl ( generating this script makes the makefiles a little tidier :-)
3591 echo creating headers.sh
3592 cat >headers.sh <<CF_EOF
3593 #! /bin/sh
3594 # This shell script is generated by the 'configure' script.  It is invoked in a
3595 # subdirectory of the build tree.  It generates a sed-script in the parent
3596 # directory that is used to adjust includes for header files that reside in a
3597 # subdirectory of /usr/include, etc.
3598 PRG=""
3599 while test \[$]# != 3
3600 do
3601 PRG="\$PRG \[$]1"; shift
3602 done
3603 DST=\[$]1
3604 REF=\[$]2
3605 SRC=\[$]3
3606 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3607 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3608 echo installing \$SRC in \$DST
3609 CF_EOF
3610
3611 if test $WITH_CURSES_H = yes; then
3612         cat >>headers.sh <<CF_EOF
3613 case \$DST in
3614 /*/include/*)
3615         END=\`basename \$DST\`
3616         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3617         do
3618                 NAME=\`basename \$i\`
3619                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3620         done
3621         ;;
3622 *)
3623         echo "" >> \$TMPSED
3624         ;;
3625 esac
3626 CF_EOF
3627
3628 else
3629         cat >>headers.sh <<CF_EOF
3630 case \$DST in
3631 /*/include/*)
3632         END=\`basename \$DST\`
3633         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3634         do
3635                 NAME=\`basename \$i\`
3636                 if test "\$NAME" = "curses.h"
3637                 then
3638                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3639                         NAME=ncurses.h
3640                 fi
3641                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3642         done
3643         ;;
3644 *)
3645         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3646         ;;
3647 esac
3648 CF_EOF
3649 fi
3650 cat >>headers.sh <<CF_EOF
3651 rm -f \$TMPSRC
3652 sed -f \$TMPSED \$SRC > \$TMPSRC
3653 NAME=\`basename \$SRC\`
3654 CF_EOF
3655 if test $WITH_CURSES_H != yes; then
3656         cat >>headers.sh <<CF_EOF
3657 test "\$NAME" = "curses.h" && NAME=ncurses.h
3658 CF_EOF
3659 fi
3660 cat >>headers.sh <<CF_EOF
3661 # Just in case someone gzip'd manpages, remove the conflicting copy.
3662 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3663
3664 eval \$PRG \$TMPSRC \$DST/\$NAME
3665 rm -f \$TMPSRC \$TMPSED
3666 CF_EOF
3667
3668 chmod 0755 headers.sh
3669
3670 for cf_dir in $SRC_SUBDIRS
3671 do
3672         if test ! -d $srcdir/$cf_dir ; then
3673                 continue
3674         fi
3675
3676         if test -f $srcdir/$cf_dir/headers; then
3677                 $AWK -f $srcdir/mk-hdr.awk \
3678                         subset="$LIB_SUBSETS" \
3679                         compat="$WITH_CURSES_H" \
3680                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3681         fi
3682
3683         if test -f $srcdir/$cf_dir/modules; then
3684                 if test "$cf_dir" != "c++" ; then
3685                         cat >>$cf_dir/Makefile <<"CF_EOF"
3686 depend : ${AUTO_SRC}
3687         makedepend -- ${CPPFLAGS} -- ${C_SRC}
3688
3689 # DO NOT DELETE THIS LINE -- make depend depends on it.
3690 CF_EOF
3691                 fi
3692         fi
3693 done
3694 AC_SUBST(Libs_To_Make)
3695 ])dnl
3696 dnl ---------------------------------------------------------------------------
3697 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
3698 dnl -------------
3699 dnl Find the and soname for the given shared library.  Set the cache variable
3700 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
3701 dnl variable to "unknown".
3702 dnl
3703 dnl $1 = headers
3704 dnl $2 = code
3705 dnl $3 = library name
3706 AC_DEFUN([CF_LIB_SONAME],
3707 [
3708 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
3709
3710 cf_cv_$3_soname=unknown
3711 if test "$cross_compiling" != yes ; then
3712 cat >conftest.$ac_ext <<CF_EOF
3713 $1
3714 int main()
3715 {
3716 $2
3717         ${cf_cv_main_return:-return}(0);
3718 }
3719 CF_EOF
3720 cf_save_LIBS="$LIBS"
3721         CF_ADD_LIB($3)
3722         if AC_TRY_EVAL(ac_compile) ; then
3723                 if AC_TRY_EVAL(ac_link) ; then
3724                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
3725                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
3726                 fi
3727         fi
3728 rm -rf conftest*
3729 LIBS="$cf_save_LIBS"
3730 fi
3731 ])
3732 ])
3733 dnl ---------------------------------------------------------------------------
3734 dnl CF_LIB_SUFFIX version: 23 updated: 2014/06/21 17:47:12
3735 dnl -------------
3736 dnl Compute the library file-suffix from the given model name
3737 dnl $1 = model name
3738 dnl $2 = variable to set (the nominal library suffix)
3739 dnl $3 = dependency variable to set (actual filename)
3740 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3741 AC_DEFUN([CF_LIB_SUFFIX],
3742 [
3743         case X$1 in #(vi
3744         Xlibtool) #(vi
3745                 $2='.la'
3746                 $3=[$]$2
3747                 ;;
3748         Xdebug) #(vi
3749                 $2='_g.a'
3750                 $3=[$]$2
3751                 ;;
3752         Xprofile) #(vi
3753                 $2='_p.a'
3754                 $3=[$]$2
3755                 ;;
3756         Xshared) #(vi
3757                 case $cf_cv_system_name in
3758                 aix[[5-7]]*) #(vi
3759                         $2='.so'
3760                         $3=[$]$2
3761                         ;;
3762                 cygwin*|msys*|mingw*) #(vi
3763                         $2='.dll'
3764                         $3='.dll.a'
3765                         ;;
3766                 darwin*) #(vi
3767                         $2='.dylib'
3768                         $3=[$]$2
3769                         ;;
3770                 hpux*) #(vi
3771                         case $target in
3772                         ia64*) #(vi
3773                                 $2='.so'
3774                                 $3=[$]$2
3775                                 ;;
3776                         *) #(vi
3777                                 $2='.sl'
3778                                 $3=[$]$2
3779                                 ;;
3780                         esac
3781                         ;;
3782                 *) #(vi
3783                         $2='.so'
3784                         $3=[$]$2
3785                         ;;
3786                 esac
3787                 ;;
3788         *)
3789                 $2='.a'
3790                 $3=[$]$2
3791                 ;;
3792         esac
3793         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3794         test -n "$LIB_SUFFIX" && $3="${LIB_SUFFIX}[$]{$3}"
3795 ])dnl
3796 dnl ---------------------------------------------------------------------------
3797 dnl CF_LIB_TYPE version: 4 updated: 2000/10/20 22:57:49
3798 dnl -----------
3799 dnl Compute the string to append to -library from the given model name
3800 dnl $1 = model name
3801 dnl $2 = variable to set
3802 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3803 AC_DEFUN([CF_LIB_TYPE],
3804 [
3805         case $1 in
3806         libtool) $2=''   ;;
3807         normal)  $2=''   ;;
3808         debug)   $2='_g' ;;
3809         profile) $2='_p' ;;
3810         shared)  $2=''   ;;
3811         esac
3812         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3813 ])dnl
3814 dnl ---------------------------------------------------------------------------
3815 dnl CF_LINK_DATAONLY version: 10 updated: 2012/10/06 17:41:51
3816 dnl ----------------
3817 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
3818 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
3819 dnl have to provide wrappers for global tables to ensure they're linked
3820 dnl properly.
3821 AC_DEFUN([CF_LINK_DATAONLY],
3822 [
3823 AC_MSG_CHECKING([if data-only library module links])
3824 AC_CACHE_VAL(cf_cv_link_dataonly,[
3825         rm -f conftest.a
3826         cat >conftest.$ac_ext <<EOF
3827 #line __oline__ "configure"
3828 int     testdata[[3]] = { 123, 456, 789 };
3829 EOF
3830         if AC_TRY_EVAL(ac_compile) ; then
3831                 mv conftest.o data.o && \
3832                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
3833         fi
3834         rm -f conftest.$ac_ext data.o
3835         cat >conftest.$ac_ext <<EOF
3836 #line __oline__ "configure"
3837 int     testfunc()
3838 {
3839 #if defined(NeXT)
3840         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
3841 #else
3842         extern int testdata[[3]];
3843         return testdata[[0]] == 123
3844            &&  testdata[[1]] == 456
3845            &&  testdata[[2]] == 789;
3846 #endif
3847 }
3848 EOF
3849         if AC_TRY_EVAL(ac_compile); then
3850                 mv conftest.o func.o && \
3851                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
3852         fi
3853         rm -f conftest.$ac_ext func.o
3854         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
3855         cf_saveLIBS="$LIBS"
3856         LIBS="conftest.a $LIBS"
3857         AC_TRY_RUN([
3858         int main()
3859         {
3860                 extern int testfunc();
3861                 ${cf_cv_main_return:-return} (!testfunc());
3862         }
3863         ],
3864         [cf_cv_link_dataonly=yes],
3865         [cf_cv_link_dataonly=no],
3866         [cf_cv_link_dataonly=unknown])
3867         LIBS="$cf_saveLIBS"
3868         ])
3869 AC_MSG_RESULT($cf_cv_link_dataonly)
3870
3871 if test "$cf_cv_link_dataonly" = no ; then
3872         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
3873         BROKEN_LINKER=1
3874 fi
3875
3876 ])dnl
3877 dnl ---------------------------------------------------------------------------
3878 dnl CF_LINK_FUNCS version: 8 updated: 2012/10/06 17:56:13
3879 dnl -------------
3880 dnl Most Unix systems have both link and symlink, a few don't have symlink.
3881 dnl A few non-Unix systems implement symlink, but not link.
3882 dnl A few non-systems implement neither (or have nonfunctional versions).
3883 AC_DEFUN([CF_LINK_FUNCS],
3884 [
3885 AC_CHECK_FUNCS( \
3886         remove \
3887         unlink )
3888
3889 if test "$cross_compiling" = yes ; then
3890         AC_CHECK_FUNCS( \
3891                 link \
3892                 symlink )
3893 else
3894         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
3895                 cf_cv_link_funcs=
3896                 for cf_func in link symlink ; do
3897                         AC_TRY_RUN([
3898 #include <sys/types.h>
3899 #include <sys/stat.h>
3900 #ifdef HAVE_UNISTD_H
3901 #include <unistd.h>
3902 #endif
3903 int main()
3904 {
3905         int fail = 0;
3906         char *src = "config.log";
3907         char *dst = "conftest.chk";
3908         struct stat src_sb;
3909         struct stat dst_sb;
3910
3911         stat(src, &src_sb);
3912         fail = ($cf_func("config.log", "conftest.chk") < 0)
3913             || (stat(dst, &dst_sb) < 0)
3914             || (dst_sb.st_mtime != src_sb.st_mtime);
3915 #ifdef HAVE_UNLINK
3916         unlink(dst);
3917 #else
3918         remove(dst);
3919 #endif
3920         ${cf_cv_main_return:-return} (fail);
3921 }
3922                         ],[
3923                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
3924                         eval 'ac_cv_func_'$cf_func'=yes'],[
3925                         eval 'ac_cv_func_'$cf_func'=no'],[
3926                         eval 'ac_cv_func_'$cf_func'=error'])
3927                 done
3928                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
3929         ])
3930         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
3931         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
3932 fi
3933 ])dnl
3934 dnl ---------------------------------------------------------------------------
3935 dnl CF_MAKEFLAGS version: 15 updated: 2014/05/10 16:43:23
3936 dnl ------------
3937 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
3938 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
3939 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
3940 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
3941 AC_DEFUN([CF_MAKEFLAGS],
3942 [
3943 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
3944         cf_cv_makeflags=''
3945         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
3946         do
3947                 cat >cf_makeflags.tmp <<CF_EOF
3948 SHELL = /bin/sh
3949 all :
3950         @ echo '.$cf_option'
3951 CF_EOF
3952                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
3953                 case "$cf_result" in
3954                 .*k|.*kw)
3955                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
3956                         case "$cf_result" in
3957                         .*CC=*) cf_cv_makeflags=
3958                                 ;;
3959                         *)      cf_cv_makeflags=$cf_option
3960                                 ;;
3961                         esac
3962                         break
3963                         ;;
3964                 .-)     ;;
3965                 *)      echo "given option \"$cf_option\", no match \"$cf_result\""
3966                         ;;
3967                 esac
3968         done
3969         rm -f cf_makeflags.tmp
3970 ])
3971
3972 AC_SUBST(cf_cv_makeflags)
3973 ])dnl
3974 dnl ---------------------------------------------------------------------------
3975 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
3976 dnl ------------
3977 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
3978 dnl a monocase filesystem.
3979 AC_DEFUN([CF_MAKE_TAGS],[
3980 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
3981
3982 AC_CHECK_PROGS(CTAGS, exctags ctags)
3983 AC_CHECK_PROGS(ETAGS, exetags etags)
3984
3985 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
3986
3987 if test "$cf_cv_mixedcase" = yes ; then
3988         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
3989 else
3990         MAKE_UPPER_TAGS=no
3991 fi
3992
3993 if test "$MAKE_UPPER_TAGS" = yes ; then
3994         MAKE_UPPER_TAGS=
3995 else
3996         MAKE_UPPER_TAGS="#"
3997 fi
3998
3999 if test "$MAKE_LOWER_TAGS" = yes ; then
4000         MAKE_LOWER_TAGS=
4001 else
4002         MAKE_LOWER_TAGS="#"
4003 fi
4004
4005 AC_SUBST(CTAGS)
4006 AC_SUBST(ETAGS)
4007
4008 AC_SUBST(MAKE_UPPER_TAGS)
4009 AC_SUBST(MAKE_LOWER_TAGS)
4010 ])dnl
4011 dnl ---------------------------------------------------------------------------
4012 dnl CF_MANPAGE_FORMAT version: 9 updated: 2010/10/23 16:10:30
4013 dnl -----------------
4014 dnl Option to allow user to override automatic configuration of manpage format.
4015 dnl There are several special cases:
4016 dnl
4017 dnl     gzip - man checks for, can display gzip'd files
4018 dnl     compress - man checks for, can display compressed files
4019 dnl     BSDI - files in the cat-directories are suffixed ".0"
4020 dnl     formatted - installer should format (put files in cat-directory)
4021 dnl     catonly - installer should only format, e.g., for a turnkey system.
4022 dnl
4023 dnl There are other configurations which this macro does not test, e.g., HPUX's
4024 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
4025 dnl convention would not match our use).
4026 AC_DEFUN([CF_MANPAGE_FORMAT],
4027 [
4028 AC_REQUIRE([CF_PATHSEP])
4029 AC_MSG_CHECKING(format of man-pages)
4030
4031 AC_ARG_WITH(manpage-format,
4032         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
4033                           optionally formatted/catonly, e.g., gzip,formatted],
4034         [MANPAGE_FORMAT=$withval],
4035         [MANPAGE_FORMAT=unknown])
4036
4037 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
4038 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
4039
4040 cf_unknown=
4041
4042 case $MANPAGE_FORMAT in
4043 unknown)
4044   if test -z "$MANPATH" ; then
4045     MANPATH="/usr/man:/usr/share/man"
4046   fi
4047
4048   # look for the 'date' man-page (it's most likely to be installed!)
4049   MANPAGE_FORMAT=
4050   cf_preform=no
4051   cf_catonly=yes
4052   cf_example=date
4053
4054   IFS="${IFS:-  }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
4055   for cf_dir in $MANPATH; do
4056     test -z "$cf_dir" && cf_dir=/usr/man
4057     for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
4058     do
4059       cf_test=`echo $cf_name | sed -e 's/*//'`
4060       if test "x$cf_test" = "x$cf_name" ; then
4061
4062         case "$cf_name" in
4063         *.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
4064         *.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
4065         *.0)    MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
4066         *)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
4067         esac
4068
4069         case "$cf_name" in
4070         $cf_dir/man*)
4071           cf_catonly=no
4072           ;;
4073         $cf_dir/cat*)
4074           cf_preform=yes
4075           ;;
4076         esac
4077         break
4078       fi
4079
4080       # if we found a match in either man* or cat*, stop looking
4081       if test -n "$MANPAGE_FORMAT" ; then
4082         cf_found=no
4083         test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
4084         test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
4085         case "$cf_name" in
4086         $cf_dir/cat*)
4087           cf_found=yes
4088           ;;
4089         esac
4090         test $cf_found=yes && break
4091       fi
4092     done
4093     # only check the first directory in $MANPATH where we find manpages
4094     if test -n "$MANPAGE_FORMAT" ; then
4095        break
4096     fi
4097   done
4098   # if we did not find the example, just assume it is normal
4099   test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
4100   IFS="$ac_save_ifs"
4101   ;;
4102 *)
4103   for cf_option in $MANPAGE_FORMAT; do
4104      case $cf_option in #(vi
4105      gzip|compress|BSDI|normal|formatted|catonly)
4106        ;;
4107      *)
4108        cf_unknown="$cf_unknown $cf_option"
4109        ;;
4110      esac
4111   done
4112   ;;
4113 esac
4114
4115 AC_MSG_RESULT($MANPAGE_FORMAT)
4116 if test -n "$cf_unknown" ; then
4117   AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
4118 fi
4119 ])dnl
4120 dnl ---------------------------------------------------------------------------
4121 dnl CF_MANPAGE_RENAMES version: 7 updated: 2005/06/18 18:51:57
4122 dnl ------------------
4123 dnl The Debian people have their own naming convention for manpages.  This
4124 dnl option lets us override the name of the file containing renaming, or
4125 dnl disable it altogether.
4126 AC_DEFUN([CF_MANPAGE_RENAMES],
4127 [
4128 AC_MSG_CHECKING(for manpage renaming)
4129
4130 AC_ARG_WITH(manpage-renames,
4131         [  --with-manpage-renames  specify manpage-renaming],
4132         [MANPAGE_RENAMES=$withval],
4133         [MANPAGE_RENAMES=yes])
4134
4135 case ".$MANPAGE_RENAMES" in #(vi
4136 .no) #(vi
4137   ;;
4138 .|.yes)
4139   # Debian 'man' program?
4140   if test -f /etc/debian_version ; then
4141     MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
4142   else
4143     MANPAGE_RENAMES=no
4144   fi
4145   ;;
4146 esac
4147
4148 if test "$MANPAGE_RENAMES" != no ; then
4149   if test -f $srcdir/man/$MANPAGE_RENAMES ; then
4150     MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
4151   elif test ! -f $MANPAGE_RENAMES ; then
4152     AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
4153   fi
4154
4155   test ! -d man && mkdir man
4156
4157   # Construct a sed-script to perform renaming within man-pages
4158   if test -n "$MANPAGE_RENAMES" ; then
4159     test ! -d man && mkdir man
4160     sh $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
4161   fi
4162 fi
4163
4164 AC_MSG_RESULT($MANPAGE_RENAMES)
4165 AC_SUBST(MANPAGE_RENAMES)
4166 ])dnl
4167 dnl ---------------------------------------------------------------------------
4168 dnl CF_MANPAGE_SYMLINKS version: 5 updated: 2010/07/24 17:12:40
4169 dnl -------------------
4170 dnl Some people expect each tool to make all aliases for manpages in the
4171 dnl man-directory.  This accommodates the older, less-capable implementations
4172 dnl of 'man', and is optional.
4173 AC_DEFUN([CF_MANPAGE_SYMLINKS],
4174 [
4175 AC_MSG_CHECKING(if manpage aliases will be installed)
4176
4177 AC_ARG_WITH(manpage-aliases,
4178         [  --with-manpage-aliases  specify manpage-aliases using .so],
4179         [MANPAGE_ALIASES=$withval],
4180         [MANPAGE_ALIASES=yes])
4181
4182 AC_MSG_RESULT($MANPAGE_ALIASES)
4183
4184 case "x$LN_S" in #(vi
4185 xln*) #(vi
4186         cf_use_symlinks=yes
4187         ;;
4188 *)
4189         cf_use_symlinks=no
4190         ;;
4191 esac
4192
4193 MANPAGE_SYMLINKS=no
4194 if test "$MANPAGE_ALIASES" = yes ; then
4195 AC_MSG_CHECKING(if manpage symlinks should be used)
4196
4197 AC_ARG_WITH(manpage-symlinks,
4198         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
4199         [MANPAGE_SYMLINKS=$withval],
4200         [MANPAGE_SYMLINKS=$cf_use_symlinks])
4201
4202 if test "$$cf_use_symlinks" = no; then
4203 if test "$MANPAGE_SYMLINKS" = yes ; then
4204         AC_MSG_WARN(cannot make symlinks, will use .so files)
4205         MANPAGE_SYMLINKS=no
4206 fi
4207 fi
4208
4209 AC_MSG_RESULT($MANPAGE_SYMLINKS)
4210 fi
4211
4212 ])dnl
4213 dnl ---------------------------------------------------------------------------
4214 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
4215 dnl --------------
4216 dnl This option causes manpages to be run through tbl(1) to generate tables
4217 dnl correctly.
4218 AC_DEFUN([CF_MANPAGE_TBL],
4219 [
4220 AC_MSG_CHECKING(for manpage tbl)
4221
4222 AC_ARG_WITH(manpage-tbl,
4223         [  --with-manpage-tbl      specify manpage processing with tbl],
4224         [MANPAGE_TBL=$withval],
4225         [MANPAGE_TBL=no])
4226
4227 AC_MSG_RESULT($MANPAGE_TBL)
4228 ])dnl
4229 dnl ---------------------------------------------------------------------------
4230 dnl CF_MAN_PAGES version: 43 updated: 2013/02/09 12:53:45
4231 dnl ------------
4232 dnl Try to determine if the man-pages on the system are compressed, and if
4233 dnl so, what format is used.  Use this information to construct a script that
4234 dnl will install man-pages.
4235 AC_DEFUN([CF_MAN_PAGES],
4236 [
4237 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
4238 CF_MANPAGE_FORMAT
4239 CF_MANPAGE_RENAMES
4240 CF_MANPAGE_SYMLINKS
4241 CF_MANPAGE_TBL
4242
4243   if test "$prefix" = "NONE" ; then
4244      cf_prefix="$ac_default_prefix"
4245   else
4246      cf_prefix="$prefix"
4247   fi
4248
4249   case "$MANPAGE_FORMAT" in # (vi
4250   *catonly*) # (vi
4251     cf_format=yes
4252     cf_inboth=no
4253     ;;
4254   *formatted*) # (vi
4255     cf_format=yes
4256     cf_inboth=yes
4257     ;;
4258   *)
4259     cf_format=no
4260     cf_inboth=no
4261     ;;
4262   esac
4263
4264 test ! -d man && mkdir man
4265
4266 cf_so_strip=
4267 cf_compress=
4268 case "$MANPAGE_FORMAT" in #(vi
4269 *compress*) #(vi
4270         cf_so_strip="Z"
4271         cf_compress=compress
4272   ;;
4273 *gzip*)
4274         cf_so_strip="gz"
4275         cf_compress=gzip
4276   ;;
4277 esac
4278
4279 cf_edit_man=./edit_man.sh
4280 cf_man_alias=`pwd`/man_alias.sed
4281
4282 cat >$cf_edit_man <<CF_EOF
4283 #! /bin/sh
4284 # this script is generated by the configure-script CF_MAN_PAGES macro.
4285
4286 prefix="$cf_prefix"
4287 datarootdir="$datarootdir"
4288 datadir="$datadir"
4289
4290 NCURSES_MAJOR="$NCURSES_MAJOR"
4291 NCURSES_MINOR="$NCURSES_MINOR"
4292 NCURSES_PATCH="$NCURSES_PATCH"
4293
4294 NCURSES_OSPEED="$NCURSES_OSPEED"
4295 TERMINFO="$TERMINFO"
4296
4297 INSTALL="$INSTALL"
4298 INSTALL_DATA="$INSTALL_DATA"
4299
4300 transform="$program_transform_name"
4301
4302 TMP=\${TMPDIR:=/tmp}/man\$\$
4303 trap "rm -f \$TMP" 0 1 2 5 15
4304
4305 form=\[$]1
4306 shift || exit 1
4307
4308 verb=\[$]1
4309 shift || exit 1
4310
4311 mandir=\[$]1
4312 shift || exit 1
4313
4314 srcdir=\[$]1
4315 top_srcdir=\[$]srcdir/..
4316 shift || exit 1
4317
4318 if test "\$form" = normal ; then
4319         if test "$cf_format" = yes ; then
4320         if test "$cf_inboth" = no ; then
4321                 sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4322                 exit $?
4323         fi
4324         fi
4325         cf_subdir=\$mandir/man
4326         cf_tables=$MANPAGE_TBL
4327 else
4328         cf_subdir=\$mandir/cat
4329         cf_tables=yes
4330 fi
4331
4332 # process the list of source-files
4333 for i in \[$]* ; do
4334 case \$i in #(vi
4335 *.orig|*.rej) ;; #(vi
4336 *.[[0-9]]*)
4337         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
4338         if test \$verb = installing ; then
4339         if test ! -d \$cf_subdir\${section} ; then
4340                 mkdir -p \$cf_subdir\$section
4341         fi
4342         fi
4343
4344         # replace variables in man page
4345         if test ! -f $cf_man_alias ; then
4346 cat >>$cf_man_alias <<-CF_EOF2
4347                 s,@DATADIR@,\$datadir,g
4348                 s,@TERMINFO@,\${TERMINFO:="no default value"},g
4349                 s,@TERMINFO_DIRS@,\${TERMINFO_DIRS:="no default value"},g
4350                 s,@NCURSES_MAJOR@,\${NCURSES_MAJOR:="no default value"},g
4351                 s,@NCURSES_MINOR@,\${NCURSES_MINOR:="no default value"},g
4352                 s,@NCURSES_PATCH@,\${NCURSES_PATCH:="no default value"},g
4353                 s,@NCURSES_OSPEED@,\${NCURSES_OSPEED:="no default value"},g
4354 CF_EOF
4355         ifelse($1,,,[
4356         for cf_name in $1
4357         do
4358                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4359                 cf_name=`echo $cf_name|sed "$program_transform_name"`
4360 cat >>$cf_edit_man <<-CF_EOF
4361                 s,@$cf_NAME@,$cf_name,g
4362 CF_EOF
4363         done
4364         ])
4365 cat >>$cf_edit_man <<CF_EOF
4366 CF_EOF2
4367                 echo "...made $cf_man_alias"
4368         fi
4369
4370         aliases=
4371         cf_source=\`basename \$i\`
4372         inalias=\$cf_source
4373         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
4374         if test ! -f \$inalias ; then
4375                 echo .. skipped \$cf_source
4376                 continue
4377         fi
4378 CF_EOF
4379
4380 if test "$MANPAGE_ALIASES" != no ; then
4381 cat >>$cf_edit_man <<CF_EOF
4382         nCurses=ignore.3x
4383         test $with_curses_h = yes && nCurses=ncurses.3x
4384         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
4385 CF_EOF
4386 fi
4387
4388 if test "$MANPAGE_RENAMES" = no ; then
4389 cat >>$cf_edit_man <<CF_EOF
4390         # perform program transformations for section 1 man pages
4391         if test \$section = 1 ; then
4392                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
4393         else
4394                 cf_target=\$cf_subdir\${section}/\$cf_source
4395         fi
4396 CF_EOF
4397 else
4398 cat >>$cf_edit_man <<CF_EOF
4399         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
4400         if test -z "\$cf_target" ; then
4401                 echo '? missing rename for '\$cf_source
4402                 cf_target="\$cf_source"
4403         fi
4404         cf_target="\$cf_subdir\${section}/\${cf_target}"
4405
4406 CF_EOF
4407 fi
4408
4409 cat >>$cf_edit_man <<CF_EOF
4410         sed     -f $cf_man_alias \\
4411 CF_EOF
4412
4413 if test -f $MANPAGE_RENAMES ; then
4414 cat >>$cf_edit_man <<CF_EOF
4415                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
4416 CF_EOF
4417 else
4418 cat >>$cf_edit_man <<CF_EOF
4419                 < \$i >\$TMP
4420 CF_EOF
4421 fi
4422
4423 cat >>$cf_edit_man <<CF_EOF
4424 if test \$cf_tables = yes ; then
4425         tbl \$TMP >\$TMP.out
4426         mv \$TMP.out \$TMP
4427 fi
4428 CF_EOF
4429
4430 if test $with_overwrite != yes ; then
4431 cat >>$cf_edit_man <<CF_EOF
4432         sed -e "/\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
4433         mv \$TMP.out \$TMP
4434 CF_EOF
4435 fi
4436
4437 if test $with_curses_h != yes ; then
4438 cat >>$cf_edit_man <<CF_EOF
4439         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
4440         mv \$TMP.out \$TMP
4441 CF_EOF
4442 fi
4443
4444 cat >>$cf_edit_man <<CF_EOF
4445         if test \$form = format ; then
4446                 nroff -man \$TMP >\$TMP.out
4447                 mv \$TMP.out \$TMP
4448         fi
4449 CF_EOF
4450
4451 if test -n "$cf_compress" ; then
4452 cat >>$cf_edit_man <<CF_EOF
4453         if test \$verb = installing ; then
4454         if ( $cf_compress -f \$TMP )
4455         then
4456                 mv \$TMP.$cf_so_strip \$TMP
4457         fi
4458         fi
4459         cf_target="\$cf_target.$cf_so_strip"
4460 CF_EOF
4461 fi
4462
4463 case "$MANPAGE_FORMAT" in #(vi
4464 *BSDI*)
4465 cat >>$cf_edit_man <<CF_EOF
4466         if test \$form = format ; then
4467                 # BSDI installs only .0 suffixes in the cat directories
4468                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
4469         fi
4470 CF_EOF
4471   ;;
4472 esac
4473
4474 cat >>$cf_edit_man <<CF_EOF
4475         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
4476         if test \$verb = installing ; then
4477                 echo \$verb \$cf_target
4478                 \$INSTALL_DATA \$TMP \$cf_target
4479                 test -d \$cf_subdir\${section} &&
4480                 test -n "\$aliases" && (
4481                         cd \$cf_subdir\${section} && (
4482                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
4483                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
4484                                 cf_target=\`basename \$cf_target\`
4485                                 for cf_alias in \$aliases
4486                                 do
4487                                         if test \$section = 1 ; then
4488                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4489                                         fi
4490
4491                                         if test "$MANPAGE_SYMLINKS" = yes ; then
4492                                                 if test -f \$cf_alias\${suffix} ; then
4493                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
4494                                                         then
4495                                                                 continue
4496                                                         fi
4497                                                 fi
4498                                                 echo .. \$verb alias \$cf_alias\${suffix}
4499 CF_EOF
4500 case "x$LN_S" in #(vi
4501 *-f) #(vi
4502 cat >>$cf_edit_man <<CF_EOF
4503                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4504 CF_EOF
4505         ;;
4506 *)
4507 cat >>$cf_edit_man <<CF_EOF
4508                                                 rm -f \$cf_alias\${suffix}
4509                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4510 CF_EOF
4511         ;;
4512 esac
4513 cat >>$cf_edit_man <<CF_EOF
4514                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
4515                                                 echo ".so \$cf_source" >\$TMP
4516 CF_EOF
4517 if test -n "$cf_compress" ; then
4518 cat >>$cf_edit_man <<CF_EOF
4519                                                 if test -n "$cf_so_strip" ; then
4520                                                         $cf_compress -f \$TMP
4521                                                         mv \$TMP.$cf_so_strip \$TMP
4522                                                 fi
4523 CF_EOF
4524 fi
4525 cat >>$cf_edit_man <<CF_EOF
4526                                                 echo .. \$verb alias \$cf_alias\${suffix}
4527                                                 rm -f \$cf_alias\${suffix}
4528                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
4529                                         fi
4530                                 done
4531                         )
4532                 )
4533         elif test \$verb = removing ; then
4534                 test -f \$cf_target && (
4535                         echo \$verb \$cf_target
4536                         rm -f \$cf_target
4537                 )
4538                 test -d \$cf_subdir\${section} &&
4539                 test -n "\$aliases" && (
4540                         cd \$cf_subdir\${section} && (
4541                                 for cf_alias in \$aliases
4542                                 do
4543                                         if test \$section = 1 ; then
4544                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4545                                         fi
4546
4547                                         echo .. \$verb alias \$cf_alias\${suffix}
4548                                         rm -f \$cf_alias\${suffix}
4549                                 done
4550                         )
4551                 )
4552         else
4553 #               echo ".hy 0"
4554                 cat \$TMP
4555         fi
4556         ;;
4557 esac
4558 done
4559
4560 if test $cf_inboth = yes ; then
4561 if test \$form != format ; then
4562         sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4563 fi
4564 fi
4565
4566 exit 0
4567 CF_EOF
4568 chmod 755 $cf_edit_man
4569
4570 ])dnl
4571 dnl ---------------------------------------------------------------------------
4572 dnl CF_MATH_LIB version: 8 updated: 2010/05/29 16:31:02
4573 dnl -----------
4574 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
4575 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
4576 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
4577 AC_DEFUN([CF_MATH_LIB],
4578 [
4579 AC_CACHE_CHECK(if -lm needed for math functions,
4580         cf_cv_need_libm,[
4581         AC_TRY_LINK([
4582         #include <stdio.h>
4583         #include <math.h>
4584         ],
4585         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
4586         [cf_cv_need_libm=no],
4587         [cf_cv_need_libm=yes])])
4588 if test "$cf_cv_need_libm" = yes
4589 then
4590 ifelse($1,,[
4591         CF_ADD_LIB(m)
4592 ],[$1=-lm])
4593 fi
4594 ])
4595 dnl ---------------------------------------------------------------------------
4596 dnl CF_MIXEDCASE_FILENAMES version: 6 updated: 2013/10/08 17:47:05
4597 dnl ----------------------
4598 dnl Check if the file-system supports mixed-case filenames.  If we're able to
4599 dnl create a lowercase name and see it as uppercase, it doesn't support that.
4600 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
4601 [
4602 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
4603 if test "$cross_compiling" = yes ; then
4604         case $target_alias in #(vi
4605         *-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*) #(vi
4606                 cf_cv_mixedcase=no
4607                 ;;
4608         *)
4609                 cf_cv_mixedcase=yes
4610                 ;;
4611         esac
4612 else
4613         rm -f conftest CONFTEST
4614         echo test >conftest
4615         if test -f CONFTEST ; then
4616                 cf_cv_mixedcase=no
4617         else
4618                 cf_cv_mixedcase=yes
4619         fi
4620         rm -f conftest CONFTEST
4621 fi
4622 ])
4623 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
4624 ])dnl
4625 dnl ---------------------------------------------------------------------------
4626 dnl CF_MKSTEMP version: 9 updated: 2012/10/03 04:34:49
4627 dnl ----------
4628 dnl Check for a working mkstemp.  This creates two files, checks that they are
4629 dnl successfully created and distinct (AmigaOS apparently fails on the last).
4630 AC_DEFUN([CF_MKSTEMP],[
4631 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
4632 rm -rf conftest*
4633 AC_TRY_RUN([
4634 #include <sys/types.h>
4635 #include <stdlib.h>
4636 #include <stdio.h>
4637 #include <string.h>
4638 #include <sys/stat.h>
4639 int main()
4640 {
4641         char *tmpl = "conftestXXXXXX";
4642         char name[2][80];
4643         int n;
4644         int result = 0;
4645         int fd;
4646         struct stat sb;
4647
4648         umask(077);
4649         for (n = 0; n < 2; ++n) {
4650                 strcpy(name[n], tmpl);
4651                 if ((fd = mkstemp(name[n])) >= 0) {
4652                         if (!strcmp(name[n], tmpl)
4653                          || stat(name[n], &sb) != 0
4654                          || (sb.st_mode & S_IFMT) != S_IFREG
4655                          || (sb.st_mode & 077) != 0) {
4656                                 result = 1;
4657                         }
4658                         close(fd);
4659                 }
4660         }
4661         if (result == 0
4662          && !strcmp(name[0], name[1]))
4663                 result = 1;
4664         ${cf_cv_main_return:-return}(result);
4665 }
4666 ],[cf_cv_func_mkstemp=yes
4667 ],[cf_cv_func_mkstemp=no
4668 ],[cf_cv_func_mkstemp=maybe])
4669 ])
4670 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
4671         AC_CHECK_FUNC(mkstemp)
4672 fi
4673 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
4674         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
4675 fi
4676 ])dnl
4677 dnl ---------------------------------------------------------------------------
4678 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
4679 dnl ----------
4680 dnl Write a debug message to config.log, along with the line number in the
4681 dnl configure script.
4682 AC_DEFUN([CF_MSG_LOG],[
4683 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
4684 ])dnl
4685 dnl ---------------------------------------------------------------------------
4686 dnl CF_NCURSES_ABI_6 version: 1 updated: 2005/09/17 18:42:49
4687 dnl ----------------
4688 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
4689 dnl warn about this.
4690 AC_DEFUN([CF_NCURSES_ABI_6],[
4691 if test "${with_abi_version+set}" != set; then
4692         case $cf_cv_rel_version in
4693         5.*)
4694                 cf_cv_rel_version=6.0
4695                 cf_cv_abi_version=6
4696                 AC_MSG_WARN(Overriding ABI version to $cf_cv_abi_version)
4697                 ;;
4698         esac
4699 fi
4700 ])dnl
4701 dnl ---------------------------------------------------------------------------
4702 dnl CF_NO_LEAKS_OPTION version: 5 updated: 2012/10/02 20:55:03
4703 dnl ------------------
4704 dnl see CF_WITH_NO_LEAKS
4705 AC_DEFUN([CF_NO_LEAKS_OPTION],[
4706 AC_MSG_CHECKING(if you want to use $1 for testing)
4707 AC_ARG_WITH($1,
4708         [$2],
4709         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
4710          $4
4711 ])
4712         : ${with_cflags:=-g}
4713         : ${with_no_leaks:=yes}
4714          with_$1=yes],
4715         [with_$1=])
4716 AC_MSG_RESULT(${with_$1:-no})
4717
4718 case .$with_cflags in #(vi
4719 .*-g*)
4720         case .$CFLAGS in #(vi
4721         .*-g*) #(vi
4722                 ;;
4723         *)
4724                 CF_ADD_CFLAGS([-g])
4725                 ;;
4726         esac
4727         ;;
4728 esac
4729 ])dnl
4730 dnl ---------------------------------------------------------------------------
4731 dnl CF_NUMBER_SYNTAX version: 1 updated: 2003/09/20 18:12:49
4732 dnl ----------------
4733 dnl Check if the given variable is a number.  If not, report an error.
4734 dnl $1 is the variable
4735 dnl $2 is the message
4736 AC_DEFUN([CF_NUMBER_SYNTAX],[
4737 if test -n "$1" ; then
4738   case $1 in #(vi
4739   [[0-9]]*) #(vi
4740         ;;
4741   *)
4742         AC_MSG_ERROR($2 is not a number: $1)
4743         ;;
4744   esac
4745 else
4746   AC_MSG_ERROR($2 value is empty)
4747 fi
4748 ])dnl
4749 dnl ---------------------------------------------------------------------------
4750 dnl CF_OBJ_SUBDIR version: 6 updated: 2013/09/07 14:06:10
4751 dnl -------------
4752 dnl Compute the object-directory name from the given model name
4753 AC_DEFUN([CF_OBJ_SUBDIR],
4754 [
4755         case $1 in
4756         libtool) $2='obj_lo'  ;;
4757         normal)  $2='objects' ;;
4758         debug)   $2='obj_g' ;;
4759         profile) $2='obj_p' ;;
4760         shared)
4761                 case $cf_cv_system_name in #(vi
4762                 cygwin|msys) #(vi
4763                         $2='objects' ;;
4764                 *)
4765                         $2='obj_s' ;;
4766                 esac
4767         esac
4768 ])dnl
4769 dnl ---------------------------------------------------------------------------
4770 dnl CF_PATHSEP version: 6 updated: 2012/09/29 18:38:12
4771 dnl ----------
4772 dnl Provide a value for the $PATH and similar separator (or amend the value
4773 dnl as provided in autoconf 2.5x).
4774 AC_DEFUN([CF_PATHSEP],
4775 [
4776         AC_MSG_CHECKING(for PATH separator)
4777         case $cf_cv_system_name in
4778         os2*)   PATH_SEPARATOR=';'  ;;
4779         *)      ${PATH_SEPARATOR:=':'}  ;;
4780         esac
4781 ifelse([$1],,,[$1=$PATH_SEPARATOR])
4782         AC_SUBST(PATH_SEPARATOR)
4783         AC_MSG_RESULT($PATH_SEPARATOR)
4784 ])dnl
4785 dnl ---------------------------------------------------------------------------
4786 dnl CF_PATH_SYNTAX version: 14 updated: 2012/06/19 20:58:54
4787 dnl --------------
4788 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
4789 dnl begins with one of the prefix/exec_prefix variables, and then again if the
4790 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
4791 dnl delayed evaluation of those symbols.
4792 AC_DEFUN([CF_PATH_SYNTAX],[
4793 if test "x$prefix" != xNONE; then
4794   cf_path_syntax="$prefix"
4795 else
4796   cf_path_syntax="$ac_default_prefix"
4797 fi
4798
4799 case ".[$]$1" in #(vi
4800 .\[$]\(*\)*|.\'*\'*) #(vi
4801   ;;
4802 ..|./*|.\\*) #(vi
4803   ;;
4804 .[[a-zA-Z]]:[[\\/]]*) #(vi OS/2 EMX
4805   ;;
4806 .\[$]{*prefix}*|.\[$]{*dir}*) #(vi
4807   eval $1="[$]$1"
4808   case ".[$]$1" in #(vi
4809   .NONE/*)
4810     $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4811     ;;
4812   esac
4813   ;; #(vi
4814 .no|.NONE/*)
4815   $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4816   ;;
4817 *)
4818   ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
4819   ;;
4820 esac
4821 ])dnl
4822 dnl ---------------------------------------------------------------------------
4823 dnl CF_PKG_CONFIG version: 7 updated: 2011/04/29 04:53:22
4824 dnl -------------
4825 dnl Check for the package-config program, unless disabled by command-line.
4826 AC_DEFUN([CF_PKG_CONFIG],
4827 [
4828 AC_MSG_CHECKING(if you want to use pkg-config)
4829 AC_ARG_WITH(pkg-config,
4830         [  --with-pkg-config{=path} enable/disable use of pkg-config],
4831         [cf_pkg_config=$withval],
4832         [cf_pkg_config=yes])
4833 AC_MSG_RESULT($cf_pkg_config)
4834
4835 case $cf_pkg_config in #(vi
4836 no) #(vi
4837         PKG_CONFIG=none
4838         ;;
4839 yes) #(vi
4840         CF_ACVERSION_CHECK(2.52,
4841                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
4842                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
4843         ;;
4844 *)
4845         PKG_CONFIG=$withval
4846         ;;
4847 esac
4848
4849 test -z "$PKG_CONFIG" && PKG_CONFIG=none
4850 if test "$PKG_CONFIG" != none ; then
4851         CF_PATH_SYNTAX(PKG_CONFIG)
4852 fi
4853
4854 AC_SUBST(PKG_CONFIG)
4855 ])dnl
4856 dnl ---------------------------------------------------------------------------
4857 dnl CF_POSIX_C_SOURCE version: 8 updated: 2010/05/26 05:38:42
4858 dnl -----------------
4859 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
4860 dnl
4861 dnl     POSIX.1-1990                            _POSIX_SOURCE
4862 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
4863 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
4864 dnl             Bindings Option
4865 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
4866 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
4867 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
4868 dnl
4869 dnl Parameters:
4870 dnl     $1 is the nominal value for _POSIX_C_SOURCE
4871 AC_DEFUN([CF_POSIX_C_SOURCE],
4872 [
4873 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
4874
4875 cf_save_CFLAGS="$CFLAGS"
4876 cf_save_CPPFLAGS="$CPPFLAGS"
4877
4878 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
4879 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
4880
4881 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
4882         CF_MSG_LOG(if the symbol is already defined go no further)
4883         AC_TRY_COMPILE([#include <sys/types.h>],[
4884 #ifndef _POSIX_C_SOURCE
4885 make an error
4886 #endif],
4887         [cf_cv_posix_c_source=no],
4888         [cf_want_posix_source=no
4889          case .$cf_POSIX_C_SOURCE in #(vi
4890          .[[12]]??*) #(vi
4891                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4892                 ;;
4893          .2) #(vi
4894                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4895                 cf_want_posix_source=yes
4896                 ;;
4897          .*)
4898                 cf_want_posix_source=yes
4899                 ;;
4900          esac
4901          if test "$cf_want_posix_source" = yes ; then
4902                 AC_TRY_COMPILE([#include <sys/types.h>],[
4903 #ifdef _POSIX_SOURCE
4904 make an error
4905 #endif],[],
4906                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
4907          fi
4908          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
4909          CFLAGS="$cf_trim_CFLAGS"
4910          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
4911          CF_MSG_LOG(if the second compile does not leave our definition intact error)
4912          AC_TRY_COMPILE([#include <sys/types.h>],[
4913 #ifndef _POSIX_C_SOURCE
4914 make an error
4915 #endif],,
4916          [cf_cv_posix_c_source=no])
4917          CFLAGS="$cf_save_CFLAGS"
4918          CPPFLAGS="$cf_save_CPPFLAGS"
4919         ])
4920 ])
4921
4922 if test "$cf_cv_posix_c_source" != no ; then
4923         CFLAGS="$cf_trim_CFLAGS"
4924         CPPFLAGS="$cf_trim_CPPFLAGS"
4925         CF_ADD_CFLAGS($cf_cv_posix_c_source)
4926 fi
4927
4928 ])dnl
4929 dnl ---------------------------------------------------------------------------
4930 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
4931 dnl ------------
4932 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
4933 dnl
4934 dnl $1 = symbol to test
4935 dnl $2 = value (if any) to use for a predefinition
4936 AC_DEFUN([CF_PREDEFINE],
4937 [
4938 AC_MSG_CHECKING(if we must define $1)
4939 AC_TRY_COMPILE([#include <sys/types.h>
4940 ],[
4941 #ifndef $1
4942 make an error
4943 #endif],[cf_result=no],[cf_result=yes])
4944 AC_MSG_RESULT($cf_result)
4945
4946 if test "$cf_result" = yes ; then
4947         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
4948 elif test "x$2" != "x" ; then
4949         AC_MSG_CHECKING(checking for compatible value versus $2)
4950         AC_TRY_COMPILE([#include <sys/types.h>
4951 ],[
4952 #if $1-$2 < 0
4953 make an error
4954 #endif],[cf_result=yes],[cf_result=no])
4955         AC_MSG_RESULT($cf_result)
4956         if test "$cf_result" = no ; then
4957                 # perhaps we can override it - try...
4958                 CPPFLAGS="$CPPFLAGS -D$1=$2"
4959         fi
4960 fi
4961 ])dnl
4962 dnl ---------------------------------------------------------------------------
4963 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
4964 dnl ------------
4965 dnl Append definitions and rules for the given programs to the subdirectory
4966 dnl Makefiles, and the recursion rule for the top-level Makefile.
4967 dnl
4968 dnl parameters
4969 dnl     $1 = script to run
4970 dnl     $2 = list of subdirectories
4971 dnl
4972 dnl variables
4973 dnl     $AWK
4974 AC_DEFUN([CF_PRG_RULES],
4975 [
4976 for cf_dir in $2
4977 do
4978         if test ! -d $srcdir/$cf_dir; then
4979                 continue
4980         elif test -f $srcdir/$cf_dir/programs; then
4981                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
4982         fi
4983 done
4984
4985 ])dnl
4986 dnl ---------------------------------------------------------------------------
4987 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
4988 dnl ----------
4989 dnl Check for archiver "ar".
4990 AC_DEFUN([CF_PROG_AR],[
4991 AC_CHECK_TOOL(AR, ar, ar)
4992 ])
4993 dnl ---------------------------------------------------------------------------
4994 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
4995 dnl -----------
4996 dnl Check for awk, ensure that the check found something.
4997 AC_DEFUN([CF_PROG_AWK],
4998 [
4999 AC_PROG_AWK
5000 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
5001 ])dnl
5002 dnl ---------------------------------------------------------------------------
5003 dnl CF_PROG_CC version: 4 updated: 2014/07/12 18:57:58
5004 dnl ----------
5005 dnl standard check for CC, plus followup sanity checks
5006 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
5007 AC_DEFUN([CF_PROG_CC],[
5008 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
5009 CF_GCC_VERSION
5010 CF_ACVERSION_CHECK(2.52,
5011         [AC_PROG_CC_STDC],
5012         [CF_ANSI_CC_REQD])
5013 CF_CC_ENV_FLAGS
5014 ])dnl
5015 dnl ---------------------------------------------------------------------------
5016 dnl CF_PROG_CC_C_O version: 3 updated: 2010/08/14 18:25:37
5017 dnl --------------
5018 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
5019 dnl the output file can be renamed, and allows for a shell variable that can
5020 dnl be used later.  The parameter is either CC or CXX.  The result is the
5021 dnl cache variable:
5022 dnl     $cf_cv_prog_CC_c_o
5023 dnl     $cf_cv_prog_CXX_c_o
5024 AC_DEFUN([CF_PROG_CC_C_O],
5025 [AC_REQUIRE([AC_PROG_CC])dnl
5026 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
5027 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
5028 [
5029 cat > conftest.$ac_ext <<CF_EOF
5030 #include <stdio.h>
5031 int main()
5032 {
5033         ${cf_cv_main_return:-return}(0);
5034 }
5035 CF_EOF
5036 # We do the test twice because some compilers refuse to overwrite an
5037 # existing .o file with -o, though they will create one.
5038 ac_try='[$]$1 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
5039 if AC_TRY_EVAL(ac_try) &&
5040   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
5041 then
5042   eval cf_cv_prog_$1_c_o=yes
5043 else
5044   eval cf_cv_prog_$1_c_o=no
5045 fi
5046 rm -rf conftest*
5047 ])dnl
5048 if test $cf_cv_prog_$1_c_o = yes; then
5049   AC_MSG_RESULT([yes])
5050 else
5051   AC_MSG_RESULT([no])
5052 fi
5053 ])dnl
5054 dnl ---------------------------------------------------------------------------
5055 dnl CF_PROG_EGREP version: 1 updated: 2006/09/16 11:40:59
5056 dnl -------------
5057 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
5058 dnl This macro adds a check to ensure the script found something.
5059 AC_DEFUN([CF_PROG_EGREP],
5060 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
5061    [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
5062     then ac_cv_prog_egrep='grep -E'
5063     else ac_cv_prog_egrep='egrep'
5064     fi])
5065  EGREP=$ac_cv_prog_egrep
5066  AC_SUBST([EGREP])
5067 test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
5068 ])dnl
5069 dnl ---------------------------------------------------------------------------
5070 dnl CF_PROG_GNAT version: 2 updated: 2011/10/22 14:01:47
5071 dnl ------------
5072 dnl Check for gnatmake, ensure that it is complete.
5073 AC_DEFUN([CF_PROG_GNAT],[
5074 cf_ada_make=gnatmake
5075 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
5076 if test "$ac_cv_prog_gnat_exists" = no; then
5077    cf_ada_make=
5078    cf_cv_prog_gnat_correct=no
5079 else
5080    CF_GNAT_VERSION
5081    AC_CHECK_PROG(M4_exists, m4, yes, no)
5082    if test "$ac_cv_prog_M4_exists" = no; then
5083       cf_cv_prog_gnat_correct=no
5084       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
5085    fi
5086    if test "$cf_cv_prog_gnat_correct" = yes; then
5087       AC_MSG_CHECKING(if GNAT works)
5088       CF_GNAT_TRY_RUN([procedure conftest;],
5089 [with Text_IO;
5090 with GNAT.OS_Lib;
5091 procedure conftest is
5092 begin
5093    Text_IO.Put ("Hello World");
5094    Text_IO.New_Line;
5095    GNAT.OS_Lib.OS_Exit (0);
5096 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
5097       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
5098    fi
5099 fi
5100
5101 AC_SUBST(cf_ada_make)
5102 ])dnl
5103 dnl ---------------------------------------------------------------------------
5104 dnl CF_PROG_INSTALL version: 5 updated: 2002/12/21 22:46:07
5105 dnl ---------------
5106 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
5107 dnl misc/tabset install won't work properly.  Usually this happens only when
5108 dnl using the fallback mkinstalldirs script
5109 AC_DEFUN([CF_PROG_INSTALL],
5110 [AC_PROG_INSTALL
5111 case $INSTALL in
5112 /*)
5113   ;;
5114 *)
5115   CF_DIRNAME(cf_dir,$INSTALL)
5116   test -z "$cf_dir" && cf_dir=.
5117   INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
5118   ;;
5119 esac
5120 ])dnl
5121 dnl ---------------------------------------------------------------------------
5122 dnl CF_PROG_LDCONFIG version: 3 updated: 2011/06/04 20:09:13
5123 dnl ----------------
5124 dnl Check for ldconfig, needed to fixup shared libraries that would be built
5125 dnl and then used in the install.
5126 AC_DEFUN([CF_PROG_LDCONFIG],[
5127 if test "$cross_compiling" = yes ; then
5128   LDCONFIG=:
5129 else
5130 case "$cf_cv_system_name" in #(vi
5131 dragonfly*|mirbsd*|freebsd*) #(vi
5132   test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
5133   ;;
5134 *) LDPATH=$PATH:/sbin:/usr/sbin
5135   AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
5136   ;;
5137 esac
5138 fi
5139 AC_SUBST(LDCONFIG)
5140 ])dnl
5141 dnl ---------------------------------------------------------------------------
5142 dnl CF_PROG_LINT version: 2 updated: 2009/08/12 04:43:14
5143 dnl ------------
5144 AC_DEFUN([CF_PROG_LINT],
5145 [
5146 AC_CHECK_PROGS(LINT, tdlint lint alint splint lclint)
5147 AC_SUBST(LINT_OPTS)
5148 ])dnl
5149 dnl ---------------------------------------------------------------------------
5150 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
5151 dnl ------------
5152 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
5153 dnl option if it is supported.
5154 AC_DEFUN([CF_PROG_LN_S],[
5155 AC_PROG_LN_S
5156 AC_MSG_CHECKING(if $LN_S -f options work)
5157
5158 rm -f conf$$.src conf$$dst
5159 echo >conf$$.dst
5160 echo first >conf$$.src
5161 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
5162         cf_prog_ln_sf=yes
5163 else
5164         cf_prog_ln_sf=no
5165 fi
5166 rm -f conf$$.dst conf$$src
5167 AC_MSG_RESULT($cf_prog_ln_sf)
5168
5169 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
5170 ])dnl
5171 dnl ---------------------------------------------------------------------------
5172 dnl CF_REGEX version: 10 updated: 2012/10/04 20:12:20
5173 dnl --------
5174 dnl Attempt to determine if we've got one of the flavors of regular-expression
5175 dnl code that we can support.
5176 AC_DEFUN([CF_REGEX],
5177 [
5178
5179 cf_regex_func=no
5180
5181 cf_regex_libs="regex re"
5182 case $host_os in #(vi
5183 mingw*)
5184         cf_regex_libs="gnurx $cf_regex_libs"
5185         ;;
5186 esac
5187
5188 AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
5189         for cf_regex_lib in $cf_regex_libs
5190         do
5191                 AC_CHECK_LIB($cf_regex_lib,regcomp,[
5192                                 CF_ADD_LIB($cf_regex_lib)
5193                                 cf_regex_func=regcomp
5194                                 break])
5195         done
5196 ])
5197
5198 if test "$cf_regex_func" = no ; then
5199         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
5200                 AC_CHECK_LIB(gen,compile,[
5201                                 CF_ADD_LIB(gen)
5202                                 cf_regex_func=compile])])
5203 fi
5204
5205 if test "$cf_regex_func" = no ; then
5206         AC_MSG_WARN(cannot find regular expression library)
5207 fi
5208
5209 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
5210
5211 cf_cv_regex_hdrs=no
5212 case $cf_regex_func in #(vi
5213 compile) #(vi
5214         for cf_regex_hdr in regexp.h regexpr.h
5215         do
5216                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
5217                         char *p = compile("", "", "", 0);
5218                         int x = step("", "");
5219                 ],[
5220                         cf_cv_regex_hdrs=$cf_regex_hdr
5221                         break
5222                 ])
5223         done
5224         ;;
5225 *)
5226         for cf_regex_hdr in regex.h
5227         do
5228                 AC_TRY_LINK([#include <sys/types.h>
5229 #include <$cf_regex_hdr>],[
5230                         regex_t *p;
5231                         int x = regcomp(p, "", 0);
5232                         int y = regexec(p, "", 0, 0, 0);
5233                         regfree(p);
5234                 ],[
5235                         cf_cv_regex_hdrs=$cf_regex_hdr
5236                         break
5237                 ])
5238         done
5239         ;;
5240 esac
5241
5242 ])
5243
5244 case $cf_cv_regex_hdrs in #(vi
5245     no)        AC_MSG_WARN(no regular expression header found) ;; #(vi
5246     regex.h)   AC_DEFINE(HAVE_REGEX_H_FUNCS,1,[Define to 1 to include regex.h for regular expressions]) ;; #(vi
5247     regexp.h)  AC_DEFINE(HAVE_REGEXP_H_FUNCS,1,[Define to 1 to include regexp.h for regular expressions]) ;; #(vi
5248     regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS,1,[Define to 1 to include regexpr.h for regular expressions]) ;;
5249 esac
5250 ])dnl
5251 dnl ---------------------------------------------------------------------------
5252 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
5253 dnl ----------------
5254 dnl Remove all -U and -D options that refer to the given symbol from a list
5255 dnl of C compiler options.  This works around the problem that not all
5256 dnl compilers process -U and -D options from left-to-right, so a -U option
5257 dnl cannot be used to cancel the effect of a preceding -D option.
5258 dnl
5259 dnl $1 = target (which could be the same as the source variable)
5260 dnl $2 = source (including '$')
5261 dnl $3 = symbol to remove
5262 define([CF_REMOVE_DEFINE],
5263 [
5264 $1=`echo "$2" | \
5265         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
5266                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
5267 ])dnl
5268 dnl ---------------------------------------------------------------------------
5269 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
5270 dnl -------------
5271 dnl Remove the given library from the symbol
5272 dnl
5273 dnl $1 = target (which could be the same as the source variable)
5274 dnl $2 = source (including '$')
5275 dnl $3 = library to remove
5276 define([CF_REMOVE_LIB],
5277 [
5278 # remove $3 library from $2
5279 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
5280 ])dnl
5281 dnl ---------------------------------------------------------------------------
5282 dnl CF_RPATH_HACK version: 11 updated: 2013/09/01 13:02:00
5283 dnl -------------
5284 AC_DEFUN([CF_RPATH_HACK],
5285 [
5286 AC_REQUIRE([CF_LD_RPATH_OPT])
5287 AC_MSG_CHECKING(for updated LDFLAGS)
5288 if test -n "$LD_RPATH_OPT" ; then
5289         AC_MSG_RESULT(maybe)
5290
5291         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
5292         cf_rpath_list="/usr/lib /lib"
5293         if test "$cf_ldd_prog" != no
5294         then
5295                 cf_rpath_oops=
5296
5297 AC_TRY_LINK([#include <stdio.h>],
5298                 [printf("Hello");],
5299                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
5300                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
5301
5302                 # If we passed the link-test, but get a "not found" on a given library,
5303                 # this could be due to inept reconfiguration of gcc to make it only
5304                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
5305                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
5306                 # /usr/local libraries.
5307                 if test -n "$cf_rpath_oops"
5308                 then
5309                         for cf_rpath_src in $cf_rpath_oops
5310                         do
5311                                 for cf_rpath_dir in \
5312                                         /usr/local \
5313                                         /usr/pkg \
5314                                         /opt/sfw
5315                                 do
5316                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
5317                                         then
5318                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
5319                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
5320                                                 break
5321                                         fi
5322                                 done
5323                         done
5324                 fi
5325         fi
5326
5327         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5328
5329         CF_RPATH_HACK_2(LDFLAGS)
5330         CF_RPATH_HACK_2(LIBS)
5331
5332         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5333 else
5334         AC_MSG_RESULT(no)
5335 fi
5336 AC_SUBST(EXTRA_LDFLAGS)
5337 ])dnl
5338 dnl ---------------------------------------------------------------------------
5339 dnl CF_RPATH_HACK_2 version: 6 updated: 2010/04/17 16:31:24
5340 dnl ---------------
5341 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
5342 dnl EXTRA_LDFLAGS for each -L option found.
5343 dnl
5344 dnl $cf_rpath_list contains a list of directories to ignore.
5345 dnl
5346 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
5347 dnl      but LIBS often has misplaced -L options.
5348 AC_DEFUN([CF_RPATH_HACK_2],
5349 [
5350 CF_VERBOSE(...checking $1 [$]$1)
5351
5352 cf_rpath_dst=
5353 for cf_rpath_src in [$]$1
5354 do
5355         case $cf_rpath_src in #(vi
5356         -L*) #(vi
5357
5358                 # check if this refers to a directory which we will ignore
5359                 cf_rpath_skip=no
5360                 if test -n "$cf_rpath_list"
5361                 then
5362                         for cf_rpath_item in $cf_rpath_list
5363                         do
5364                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
5365                                 then
5366                                         cf_rpath_skip=yes
5367                                         break
5368                                 fi
5369                         done
5370                 fi
5371
5372                 if test "$cf_rpath_skip" = no
5373                 then
5374                         # transform the option
5375                         if test "$LD_RPATH_OPT" = "-R " ; then
5376                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
5377                         else
5378                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
5379                         fi
5380
5381                         # if we have not already added this, add it now
5382                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
5383                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
5384                         then
5385                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
5386                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
5387                         fi
5388                 fi
5389                 ;;
5390         esac
5391         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
5392 done
5393 $1=$cf_rpath_dst
5394
5395 CF_VERBOSE(...checked $1 [$]$1)
5396 AC_SUBST(EXTRA_LDFLAGS)
5397 ])dnl
5398 dnl ---------------------------------------------------------------------------
5399 dnl CF_SHARED_OPTS version: 84 updated: 2013/11/03 06:26:10
5400 dnl --------------
5401 dnl --------------
5402 dnl Attempt to determine the appropriate CC/LD options for creating a shared
5403 dnl library.
5404 dnl
5405 dnl Notes:
5406 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
5407 dnl the build-tree, i.e., by making use of the libraries that are compiled in
5408 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
5409 dnl shared library since that can lead to unexpected results at runtime.
5410 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
5411 dnl libraries are compiled in ../../lib
5412 dnl
5413 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
5414 dnl to install symbolic links to the rel/abi versions of shared libraries.
5415 dnl
5416 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
5417 dnl version when making symbolic links.
5418 dnl
5419 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
5420 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
5421 dnl (ex: libncurses.so.<ver>).
5422 dnl
5423 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
5424 AC_DEFUN([CF_SHARED_OPTS],
5425 [
5426         AC_REQUIRE([CF_LD_RPATH_OPT])
5427         RM_SHARED_OPTS=
5428         LOCAL_LDFLAGS=
5429         LOCAL_LDFLAGS2=
5430         LD_SHARED_OPTS=
5431         INSTALL_LIB="-m 644"
5432         : ${rel_builddir:=.}
5433
5434         shlibdir=$libdir
5435         AC_SUBST(shlibdir)
5436
5437         MAKE_DLLS="#"
5438         AC_SUBST(MAKE_DLLS)
5439
5440         cf_cv_do_symlinks=no
5441         cf_ld_rpath_opt=
5442         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
5443
5444         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
5445         AC_ARG_WITH(shlib-version,
5446         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
5447         [test -z "$withval" && withval=auto
5448         case $withval in #(vi
5449         yes) #(vi
5450                 cf_cv_shlib_version=auto
5451                 ;;
5452         rel|abi|auto|no) #(vi
5453                 cf_cv_shlib_version=$withval
5454                 ;;
5455         *)
5456                 AC_MSG_ERROR([option value must be one of: rel, abi, auto or no])
5457                 ;;
5458         esac
5459         ],[cf_cv_shlib_version=auto])
5460         AC_MSG_RESULT($cf_cv_shlib_version)
5461
5462         cf_cv_rm_so_locs=no
5463         cf_try_cflags=
5464
5465         # Some less-capable ports of gcc support only -fpic
5466         CC_SHARED_OPTS=
5467         if test "$GCC" = yes
5468         then
5469                 AC_MSG_CHECKING(which $CC option to use)
5470                 cf_save_CFLAGS="$CFLAGS"
5471                 for CC_SHARED_OPTS in -fPIC -fpic ''
5472                 do
5473                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
5474                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
5475                 done
5476                 AC_MSG_RESULT($CC_SHARED_OPTS)
5477                 CFLAGS="$cf_save_CFLAGS"
5478         fi
5479
5480         cf_cv_shlib_version_infix=no
5481
5482         case $cf_cv_system_name in #(vi
5483         aix4.[3-9]*|aix[[5-7]]*) #(vi
5484                 if test "$GCC" = yes; then
5485                         CC_SHARED_OPTS=
5486                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5487                 else
5488                         # CC_SHARED_OPTS='-qpic=large -G'
5489                         # perhaps "-bM:SRE -bnoentry -bexpall"
5490                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5491                 fi
5492                 ;;
5493         beos*) #(vi
5494                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
5495                 ;;
5496         cygwin*) #(vi
5497                 CC_SHARED_OPTS=
5498                 MK_SHARED_LIB='sh '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5499                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5500                 cf_cv_shlib_version=cygdll
5501                 cf_cv_shlib_version_infix=cygdll
5502                 shlibdir=$bindir
5503                 MAKE_DLLS=
5504                 cat >mk_shared_lib.sh <<-CF_EOF
5505                 #!/bin/sh
5506                 SHARED_LIB=\[$]1
5507                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5508                 shift
5509                 cat <<-EOF
5510                 Linking shared library
5511                 ** SHARED_LIB \[$]SHARED_LIB
5512                 ** IMPORT_LIB \[$]IMPORT_LIB
5513 EOF
5514                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5515 CF_EOF
5516                 chmod +x mk_shared_lib.sh
5517                 ;;
5518         msys*) #(vi
5519                 CC_SHARED_OPTS=
5520                 MK_SHARED_LIB='sh '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5521                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5522                 cf_cv_shlib_version=msysdll
5523                 cf_cv_shlib_version_infix=msysdll
5524                 shlibdir=$bindir
5525                 MAKE_DLLS=
5526                 cat >mk_shared_lib.sh <<-CF_EOF
5527                 #!/bin/sh
5528                 SHARED_LIB=\[$]1
5529                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5530                 shift
5531                 cat <<-EOF
5532                 Linking shared library
5533                 ** SHARED_LIB \[$]SHARED_LIB
5534                 ** IMPORT_LIB \[$]IMPORT_LIB
5535 EOF
5536                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5537 CF_EOF
5538                 chmod +x mk_shared_lib.sh
5539                 ;;
5540         darwin*) #(vi
5541                 cf_try_cflags="no-cpp-precomp"
5542                 CC_SHARED_OPTS="-dynamic"
5543                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
5544                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
5545                 cf_cv_shlib_version_infix=yes
5546                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
5547                         cf_save_LDFLAGS=$LDFLAGS
5548                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5549                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
5550                                 LDFLAGS=$cf_save_LDFLAGS])
5551                 if test $cf_cv_ldflags_search_paths_first = yes; then
5552                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5553                 fi
5554                 ;;
5555         hpux[[7-8]]*) #(vi
5556                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
5557                 if test "$GCC" != yes; then
5558                         CC_SHARED_OPTS='+Z'
5559                 fi
5560                 MK_SHARED_LIB='${LD} -b -o $[@]'
5561                 INSTALL_LIB="-m 555"
5562                 ;;
5563         hpux*) #(vi
5564                 # (tested with gcc 2.7.2 -- I don't have c89)
5565                 if test "$GCC" = yes; then
5566                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
5567                 else
5568                         CC_SHARED_OPTS='+Z'
5569                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
5570                 fi
5571                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
5572                 # HP-UX shared libraries must be executable, and should be
5573                 # readonly to exploit a quirk in the memory manager.
5574                 INSTALL_LIB="-m 555"
5575                 ;;
5576         interix*)
5577                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5578                 if test "$cf_cv_shlib_version" = rel; then
5579                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
5580                 else
5581                         cf_shared_soname='`basename $@`'
5582                 fi
5583                 CC_SHARED_OPTS=
5584                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
5585                 ;;
5586         irix*) #(vi
5587                 if test "$cf_cv_enable_rpath" = yes ; then
5588                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5589                 fi
5590                 # tested with IRIX 5.2 and 'cc'.
5591                 if test "$GCC" != yes; then
5592                         CC_SHARED_OPTS='-KPIC'
5593                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
5594                 else
5595                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
5596                 fi
5597                 cf_cv_rm_so_locs=yes
5598                 ;;
5599         linux*|gnu*|k*bsd*-gnu) #(vi
5600                 if test "$DFT_LWR_MODEL" = "shared" ; then
5601                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5602                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5603                 fi
5604                 if test "$cf_cv_enable_rpath" = yes ; then
5605                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5606                 fi
5607                 CF_SHARED_SONAME
5608                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5609                 ;;
5610         mingw*) #(vi
5611                 cf_cv_shlib_version=mingw
5612                 cf_cv_shlib_version_infix=mingw
5613                 shlibdir=$bindir
5614                 MAKE_DLLS=
5615                 if test "$DFT_LWR_MODEL" = "shared" ; then
5616                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
5617                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5618                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
5619                 fi
5620                 CC_SHARED_OPTS=
5621                 MK_SHARED_LIB='sh '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5622                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5623                 cat >mk_shared_lib.sh <<-CF_EOF
5624                 #!/bin/sh
5625                 SHARED_LIB=\[$]1
5626                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5627                 shift
5628                 cat <<-EOF
5629                 Linking shared library
5630                 ** SHARED_LIB \[$]SHARED_LIB
5631                 ** IMPORT_LIB \[$]IMPORT_LIB
5632 EOF
5633                 exec \[$]* -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5634 CF_EOF
5635                 chmod +x mk_shared_lib.sh
5636                 ;;
5637         openbsd[[2-9]].*|mirbsd*) #(vi
5638                 if test "$DFT_LWR_MODEL" = "shared" ; then
5639                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5640                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5641                 fi
5642                 if test "$cf_cv_enable_rpath" = yes ; then
5643                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5644                 fi
5645                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5646                 CF_SHARED_SONAME
5647                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5648                 ;;
5649         nto-qnx*|openbsd*|freebsd[[12]].*) #(vi
5650                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5651                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
5652                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5653                 ;;
5654         dragonfly*|freebsd*) #(vi
5655                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5656                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5657                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5658                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
5659                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5660                 fi
5661                 CF_SHARED_SONAME
5662                 MK_SHARED_LIB='${LD} -shared -Bshareable -soname=`basename $[@]` -o $[@]'
5663                 ;;
5664         netbsd*) #(vi
5665                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5666                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5667                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5668                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5669                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5670                         if test "$cf_cv_shlib_version" = auto; then
5671                         if test -f /usr/libexec/ld.elf_so; then
5672                                 cf_cv_shlib_version=abi
5673                         else
5674                                 cf_cv_shlib_version=rel
5675                         fi
5676                         fi
5677                         CF_SHARED_SONAME
5678                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
5679                 else
5680                         MK_SHARED_LIB='${CC} -Wl,-shared -Wl,-Bshareable -o $[@]'
5681                 fi
5682                 ;;
5683         osf*|mls+*) #(vi
5684                 # tested with OSF/1 V3.2 and 'cc'
5685                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
5686                 # link with shared libs).
5687                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
5688                 case $host_os in #(vi
5689                 osf4*)
5690                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
5691                         ;;
5692                 esac
5693                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
5694                 if test "$DFT_LWR_MODEL" = "shared" ; then
5695                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5696                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5697                 fi
5698                 cf_cv_rm_so_locs=yes
5699                 ;;
5700         sco3.2v5*)  # (also uw2* and UW7: hops 13-Apr-98
5701                 # tested with osr5.0.5
5702                 if test "$GCC" != yes; then
5703                         CC_SHARED_OPTS='-belf -KPIC'
5704                 fi
5705                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
5706                 if test "$cf_cv_enable_rpath" = yes ; then
5707                         # only way is to set LD_RUN_PATH but no switch for it
5708                         RUN_PATH=$libdir
5709                 fi
5710                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5711                 LINK_PROGS='LD_RUN_PATH=${libdir}'
5712                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
5713                 ;;
5714         sunos4*) #(vi
5715                 # tested with SunOS 4.1.1 and gcc 2.7.0
5716                 if test "$GCC" != yes; then
5717                         CC_SHARED_OPTS='-KPIC'
5718                 fi
5719                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
5720                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5721                 ;;
5722         solaris2*) #(vi
5723                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
5724                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
5725                 if test "$DFT_LWR_MODEL" = "shared" ; then
5726                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
5727                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5728                 fi
5729                 if test "$cf_cv_enable_rpath" = yes ; then
5730                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
5731                 fi
5732                 CF_SHARED_SONAME
5733                 if test "$GCC" != yes; then
5734                         cf_save_CFLAGS="$CFLAGS"
5735                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
5736                         do
5737                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
5738                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
5739                         done
5740                         CFLAGS="$cf_save_CFLAGS"
5741                         CC_SHARED_OPTS=$cf_shared_opts
5742                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5743                 else
5744                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5745                 fi
5746                 ;;
5747         sysv5uw7*|unix_sv*) #(vi
5748                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
5749                 if test "$GCC" != yes; then
5750                         CC_SHARED_OPTS='-KPIC'
5751                 fi
5752                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
5753                 ;;
5754         *)
5755                 CC_SHARED_OPTS='unknown'
5756                 MK_SHARED_LIB='echo unknown'
5757                 ;;
5758         esac
5759
5760         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
5761         case "$cf_cv_shlib_version" in #(vi
5762         rel|abi)
5763                 case "$MK_SHARED_LIB" in #(vi
5764                 *'-o $[@]') #(vi
5765                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
5766                         ;;
5767                 *)
5768                         AC_MSG_WARN(ignored --with-shlib-version)
5769                         ;;
5770                 esac
5771                 ;;
5772         esac
5773
5774         if test -n "$cf_try_cflags"
5775         then
5776 cat > conftest.$ac_ext <<EOF
5777 #line __oline__ "${as_me:-configure}"
5778 #include <stdio.h>
5779 int main(int argc, char *argv[[]])
5780 {
5781         printf("hello\n");
5782         return (argv[[argc-1]] == 0) ;
5783 }
5784 EOF
5785                 cf_save_CFLAGS="$CFLAGS"
5786                 for cf_opt in $cf_try_cflags
5787                 do
5788                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
5789                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
5790                         if AC_TRY_EVAL(ac_compile); then
5791                                 AC_MSG_RESULT(yes)
5792                                 cf_save_CFLAGS="$CFLAGS"
5793                         else
5794                                 AC_MSG_RESULT(no)
5795                         fi
5796                 done
5797                 CFLAGS="$cf_save_CFLAGS"
5798         fi
5799
5800
5801         # RPATH_LIST is a colon-separated list of directories
5802         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
5803         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
5804
5805         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
5806
5807         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
5808         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
5809
5810         AC_SUBST(CC_SHARED_OPTS)
5811         AC_SUBST(LD_RPATH_OPT)
5812         AC_SUBST(LD_SHARED_OPTS)
5813         AC_SUBST(MK_SHARED_LIB)
5814         AC_SUBST(RM_SHARED_OPTS)
5815
5816         AC_SUBST(LINK_PROGS)
5817         AC_SUBST(LINK_TESTS)
5818
5819         AC_SUBST(EXTRA_LDFLAGS)
5820         AC_SUBST(LOCAL_LDFLAGS)
5821         AC_SUBST(LOCAL_LDFLAGS2)
5822
5823         AC_SUBST(INSTALL_LIB)
5824         AC_SUBST(RPATH_LIST)
5825 ])dnl
5826 dnl ---------------------------------------------------------------------------
5827 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
5828 dnl ----------------
5829 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
5830 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
5831 dnl option.
5832 dnl
5833 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
5834 dnl If missing, use "rel".
5835 define([CF_SHARED_SONAME],
5836 [
5837         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
5838         if test "$cf_cv_shlib_version" = rel; then
5839                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
5840         else
5841                 cf_cv_shared_soname='`basename $[@]`'
5842         fi
5843 ])
5844 dnl ---------------------------------------------------------------------------
5845 dnl CF_SIGWINCH version: 1 updated: 2006/04/02 16:41:09
5846 dnl -----------
5847 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
5848 dnl programs need this test).
5849 dnl
5850 dnl This is really a MacOS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
5851 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
5852 dnl winsize declaration is left alone - we may revisit this if Apple choose to
5853 dnl break that part of the interface as well.
5854 AC_DEFUN([CF_SIGWINCH],
5855 [
5856 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
5857         AC_TRY_COMPILE([
5858 #include <sys/types.h>
5859 #include <sys/signal.h>
5860 ],[int x = SIGWINCH],
5861         [cf_cv_define_sigwinch=yes],
5862         [AC_TRY_COMPILE([
5863 #undef _XOPEN_SOURCE
5864 #undef _POSIX_SOURCE
5865 #undef _POSIX_C_SOURCE
5866 #include <sys/types.h>
5867 #include <sys/signal.h>
5868 ],[int x = SIGWINCH],
5869         [cf_cv_define_sigwinch=maybe],
5870         [cf_cv_define_sigwinch=no])
5871 ])
5872 ])
5873
5874 if test "$cf_cv_define_sigwinch" = maybe ; then
5875 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
5876 cf_cv_fixup_sigwinch=unknown
5877 cf_sigwinch=32
5878 while test $cf_sigwinch != 1
5879 do
5880         AC_TRY_COMPILE([
5881 #undef _XOPEN_SOURCE
5882 #undef _POSIX_SOURCE
5883 #undef _POSIX_C_SOURCE
5884 #include <sys/types.h>
5885 #include <sys/signal.h>
5886 ],[
5887 #if SIGWINCH != $cf_sigwinch
5888 make an error
5889 #endif
5890 int x = SIGWINCH],
5891         [cf_cv_fixup_sigwinch=$cf_sigwinch
5892          break])
5893
5894 cf_sigwinch=`expr $cf_sigwinch - 1`
5895 done
5896 ])
5897
5898         if test "$cf_cv_fixup_sigwinch" != unknown ; then
5899                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
5900         fi
5901 fi
5902 ])dnl
5903 dnl ---------------------------------------------------------------------------
5904 dnl CF_SIG_ATOMIC_T version: 3 updated: 2012/10/04 20:12:20
5905 dnl ---------------
5906 dnl signal handler, but there are some gcc depedencies in that recommendation.
5907 dnl Try anyway.
5908 AC_DEFUN([CF_SIG_ATOMIC_T],
5909 [
5910 AC_MSG_CHECKING(for signal global datatype)
5911 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
5912         for cf_type in \
5913                 "volatile sig_atomic_t" \
5914                 "sig_atomic_t" \
5915                 "int"
5916         do
5917         AC_TRY_COMPILE([
5918 #include <sys/types.h>
5919 #include <signal.h>
5920 #include <stdio.h>
5921
5922 extern $cf_type x;
5923 $cf_type x;
5924 static void handler(int sig)
5925 {
5926         x = 5;
5927 }],
5928                 [signal(SIGINT, handler);
5929                  x = 1],
5930                 [cf_cv_sig_atomic_t=$cf_type],
5931                 [cf_cv_sig_atomic_t=no])
5932                 test "$cf_cv_sig_atomic_t" != no && break
5933         done
5934         ])
5935 AC_MSG_RESULT($cf_cv_sig_atomic_t)
5936 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
5937 ])dnl
5938 dnl ---------------------------------------------------------------------------
5939 dnl CF_SIZECHANGE version: 9 updated: 2012/10/06 11:17:15
5940 dnl -------------
5941 dnl Check for definitions & structures needed for window size-changing
5942 dnl FIXME: check that this works with "snake" (HP-UX 10.x)
5943 AC_DEFUN([CF_SIZECHANGE],
5944 [
5945 AC_REQUIRE([CF_STRUCT_TERMIOS])
5946 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
5947     cf_cv_sizechange=unknown
5948     cf_save_CPPFLAGS="$CPPFLAGS"
5949
5950 for cf_opts in "" "NEED_PTEM_H"
5951 do
5952
5953     CPPFLAGS="$cf_save_CPPFLAGS"
5954     test -n "$cf_opts" && CPPFLAGS="$CPPFLAGS -D$cf_opts"
5955     AC_TRY_COMPILE([#include <sys/types.h>
5956 #ifdef HAVE_TERMIOS_H
5957 #include <termios.h>
5958 #else
5959 #ifdef HAVE_TERMIO_H
5960 #include <termio.h>
5961 #endif
5962 #endif
5963 #ifdef NEED_PTEM_H
5964 /* This is a workaround for SCO:  they neglected to define struct winsize in
5965  * termios.h -- it's only in termio.h and ptem.h
5966  */
5967 #include        <sys/stream.h>
5968 #include        <sys/ptem.h>
5969 #endif
5970 #if !defined(sun) || !defined(HAVE_TERMIOS_H)
5971 #include <sys/ioctl.h>
5972 #endif
5973 ],[
5974 #ifdef TIOCGSIZE
5975         struct ttysize win;     /* FIXME: what system is this? */
5976         int y = win.ts_lines;
5977         int x = win.ts_cols;
5978 #else
5979 #ifdef TIOCGWINSZ
5980         struct winsize win;
5981         int y = win.ws_row;
5982         int x = win.ws_col;
5983 #else
5984         no TIOCGSIZE or TIOCGWINSZ
5985 #endif /* TIOCGWINSZ */
5986 #endif /* TIOCGSIZE */
5987         ],
5988         [cf_cv_sizechange=yes],
5989         [cf_cv_sizechange=no])
5990
5991         CPPFLAGS="$cf_save_CPPFLAGS"
5992         if test "$cf_cv_sizechange" = yes ; then
5993                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
5994                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
5995                 break
5996         fi
5997 done
5998 ])
5999 if test "$cf_cv_sizechange" != no ; then
6000         AC_DEFINE(HAVE_SIZECHANGE,1,[Define to 1 if sizechar declarations are provided])
6001         case $cf_cv_sizechange in #(vi
6002         NEED*)
6003                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
6004                 ;;
6005         esac
6006 fi
6007 ])dnl
6008 dnl ---------------------------------------------------------------------------
6009 dnl CF_SRC_MODULES version: 27 updated: 2013/08/03 18:18:08
6010 dnl --------------
6011 dnl For each parameter, test if the source-directory exists, and if it contains
6012 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
6013 dnl use in CF_LIB_RULES.
6014 dnl
6015 dnl This uses the configured value to make the lists SRC_SUBDIRS and
6016 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
6017 AC_DEFUN([CF_SRC_MODULES],
6018 [
6019 AC_MSG_CHECKING(for src modules)
6020
6021 # dependencies and linker-arguments for test-programs
6022 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
6023 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
6024 if test "$DFT_LWR_MODEL" = "libtool"; then
6025         TEST_ARGS="${TEST_DEPS}"
6026         TEST_ARG2="${TEST_DEP2}"
6027 else
6028         TEST_ARGS="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARGS"
6029         TEST_ARG2="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARG2"
6030 fi
6031
6032 PC_MODULES_TO_MAKE="ncurses${DFT_ARG_SUFFIX}"
6033 cf_cv_src_modules=
6034 for cf_dir in $1
6035 do
6036         if test -f $srcdir/$cf_dir/modules; then
6037
6038                 # We may/may not have tack in the distribution, though the
6039                 # makefile is.
6040                 if test $cf_dir = tack ; then
6041                         if test ! -f $srcdir/${cf_dir}/${cf_dir}.h; then
6042                                 continue
6043                         fi
6044                 fi
6045
6046                 if test -z "$cf_cv_src_modules"; then
6047                         cf_cv_src_modules=$cf_dir
6048                 else
6049                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
6050                 fi
6051
6052                 # Make the ncurses_cfg.h file record the library interface files as
6053                 # well.  These are header files that are the same name as their
6054                 # directory.  Ncurses is the only library that does not follow
6055                 # that pattern.
6056                 if test $cf_dir = tack ; then
6057                         continue
6058                 elif test -f $srcdir/${cf_dir}/${cf_dir}.h; then
6059                         CF_UPPER(cf_have_include,$cf_dir)
6060                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
6061                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
6062                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEPS"
6063                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEP2"
6064                         if test "$DFT_LWR_MODEL" = "libtool"; then
6065                                 TEST_ARGS="${TEST_DEPS}"
6066                                 TEST_ARG2="${TEST_DEP2}"
6067                         else
6068                                 TEST_ARGS="-l${cf_dir}${DFT_ARG_SUFFIX} $TEST_ARGS"
6069                                 TEST_ARG2="-l${cf_dir}${DFT_ARG_SUFFIX} $TEST_ARG2"
6070                         fi
6071                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${DFT_ARG_SUFFIX}"
6072                 fi
6073         fi
6074 done
6075 AC_MSG_RESULT($cf_cv_src_modules)
6076
6077 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
6078 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
6079
6080 AC_SUBST(TEST_ARGS)
6081 AC_SUBST(TEST_DEPS)
6082
6083 AC_SUBST(TEST_ARG2)
6084 AC_SUBST(TEST_DEP2)
6085
6086 SRC_SUBDIRS=
6087 if test "x$cf_with_manpages" != xno ; then
6088         SRC_SUBDIRS="$SRC_SUBDIRS man"
6089 fi
6090 SRC_SUBDIRS="$SRC_SUBDIRS include"
6091 for cf_dir in $cf_cv_src_modules
6092 do
6093         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
6094 done
6095 if test "x$cf_with_tests" != "xno" ; then
6096         SRC_SUBDIRS="$SRC_SUBDIRS test"
6097 fi
6098 if test "x$cf_with_db_install" = xyes; then
6099         test -z "$MAKE_TERMINFO" && SRC_SUBDIRS="$SRC_SUBDIRS misc"
6100 fi
6101 if test "$cf_with_cxx_binding" != no; then
6102         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${DFT_ARG_SUFFIX}"
6103         SRC_SUBDIRS="$SRC_SUBDIRS c++"
6104 fi
6105
6106 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
6107 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
6108
6109 AC_SUBST(PC_MODULES_TO_MAKE)
6110
6111 ADA_SUBDIRS=
6112 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f $srcdir/Ada95/Makefile.in; then
6113         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
6114         ADA_SUBDIRS="gen src"
6115         if test "x$cf_with_tests" != "xno" ; then
6116                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
6117         fi
6118 fi
6119
6120 SUB_MAKEFILES=
6121 for cf_dir in $SRC_SUBDIRS
6122 do
6123         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
6124 done
6125
6126 if test -n "$ADA_SUBDIRS"; then
6127         for cf_dir in $ADA_SUBDIRS
6128         do
6129                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
6130         done
6131         AC_SUBST(ADA_SUBDIRS)
6132 fi
6133 ])dnl
6134 dnl ---------------------------------------------------------------------------
6135 dnl CF_STDCPP_LIBRARY version: 7 updated: 2010/05/29 16:31:02
6136 dnl -----------------
6137 dnl Check for -lstdc++, which is GNU's standard C++ library.
6138 AC_DEFUN([CF_STDCPP_LIBRARY],
6139 [
6140 if test -n "$GXX" ; then
6141 case $cf_cv_system_name in #(vi
6142 os2*) #(vi
6143         cf_stdcpp_libname=stdcpp
6144         ;;
6145 *)
6146         cf_stdcpp_libname=stdc++
6147         ;;
6148 esac
6149 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
6150         cf_save="$LIBS"
6151         CF_ADD_LIB($cf_stdcpp_libname)
6152 AC_TRY_LINK([
6153 #include <strstream.h>],[
6154 char buf[80];
6155 strstreambuf foo(buf, sizeof(buf))
6156 ],
6157         [cf_cv_libstdcpp=yes],
6158         [cf_cv_libstdcpp=no])
6159         LIBS="$cf_save"
6160 ])
6161 test "$cf_cv_libstdcpp" = yes && CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS)
6162 fi
6163 ])dnl
6164 dnl ---------------------------------------------------------------------------
6165 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
6166 dnl --------------
6167 dnl     Remove "-g" option from the compiler options
6168 AC_DEFUN([CF_STRIP_G_OPT],
6169 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
6170 dnl ---------------------------------------------------------------------------
6171 dnl CF_STRUCT_SIGACTION version: 5 updated: 2012/10/06 17:56:13
6172 dnl -------------------
6173 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
6174 dnl do this if we've found the sigaction function.
6175 AC_DEFUN([CF_STRUCT_SIGACTION],[
6176 AC_REQUIRE([CF_XOPEN_SOURCE])
6177
6178 if test "$ac_cv_func_sigaction" = yes; then
6179 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
6180 AC_TRY_COMPILE([
6181 #include <sys/types.h>
6182 #include <signal.h>],
6183         [struct sigaction act],
6184         [sigact_bad=no],
6185         [
6186 AC_TRY_COMPILE([
6187 #define _POSIX_SOURCE
6188 #include <sys/types.h>
6189 #include <signal.h>],
6190         [struct sigaction act],
6191         [sigact_bad=yes
6192          AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE])],
6193          [sigact_bad=unknown])])
6194 AC_MSG_RESULT($sigact_bad)
6195 fi
6196 ])dnl
6197 dnl ---------------------------------------------------------------------------
6198 dnl CF_STRUCT_TERMIOS version: 7 updated: 2012/10/06 17:56:13
6199 dnl -----------------
6200 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
6201 AC_DEFUN([CF_STRUCT_TERMIOS],[
6202 AC_REQUIRE([CF_XOPEN_SOURCE])
6203
6204 AC_CHECK_HEADERS( \
6205 termio.h \
6206 termios.h \
6207 unistd.h \
6208 )
6209
6210 if test "$ISC" = yes ; then
6211         AC_CHECK_HEADERS( sys/termio.h )
6212 fi
6213 if test "$ac_cv_header_termios_h" = yes ; then
6214         case "$CFLAGS $CPPFLAGS" in
6215         *-D_POSIX_SOURCE*)
6216                 termios_bad=dunno ;;
6217         *)      termios_bad=maybe ;;
6218         esac
6219         if test "$termios_bad" = maybe ; then
6220         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
6221         AC_TRY_COMPILE([#include <termios.h>],
6222                 [struct termios foo; int x = foo.c_iflag],
6223                 termios_bad=no, [
6224                 AC_TRY_COMPILE([
6225 #define _POSIX_SOURCE
6226 #include <termios.h>],
6227                         [struct termios foo; int x = foo.c_iflag],
6228                         termios_bad=unknown,
6229                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE]))
6230                         ])
6231         AC_MSG_RESULT($termios_bad)
6232         fi
6233 fi
6234 ])dnl
6235 dnl ---------------------------------------------------------------------------
6236 dnl CF_SUBDIR_PATH version: 6 updated: 2010/04/21 06:20:50
6237 dnl --------------
6238 dnl Construct a search-list for a nonstandard header/lib-file
6239 dnl     $1 = the variable to return as result
6240 dnl     $2 = the package name
6241 dnl     $3 = the subdirectory, e.g., bin, include or lib
6242 AC_DEFUN([CF_SUBDIR_PATH],
6243 [
6244 $1=
6245
6246 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr,$prefix)
6247 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
6248 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr/local,$prefix)
6249 CF_ADD_SUBDIR_PATH($1,$2,$3,/opt,$prefix)
6250 CF_ADD_SUBDIR_PATH($1,$2,$3,[$]HOME,$prefix)
6251 ])dnl
6252 dnl ---------------------------------------------------------------------------
6253 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
6254 dnl -----------
6255 dnl     Shorthand macro for substituting things that the user may override
6256 dnl     with an environment variable.
6257 dnl
6258 dnl     $1 = condition to pass to "test"
6259 dnl     $2 = environment variable
6260 dnl     $3 = value if the test succeeds
6261 dnl     $4 = value if the test fails
6262 AC_DEFUN([CF_SUBST_IF],
6263 [
6264 if test $1 ; then
6265         $2=$3
6266 ifelse($4,,,[else
6267         $2=$4])
6268 fi
6269 AC_SUBST($2)
6270 ])dnl
6271 dnl ---------------------------------------------------------------------------
6272 dnl CF_SUBST_NCURSES_VERSION version: 8 updated: 2006/09/16 11:40:59
6273 dnl ------------------------
6274 dnl Get the version-number for use in shared-library naming, etc.
6275 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
6276 [
6277 AC_REQUIRE([CF_PROG_EGREP])
6278 NCURSES_MAJOR="`$ac_cv_prog_egrep '^NCURSES_MAJOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6279 NCURSES_MINOR="`$ac_cv_prog_egrep '^NCURSES_MINOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6280 NCURSES_PATCH="`$ac_cv_prog_egrep '^NCURSES_PATCH[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6281 cf_cv_abi_version=${NCURSES_MAJOR}
6282 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
6283 dnl Show the computed version, for logging
6284 cf_cv_timestamp=`date`
6285 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
6286 dnl We need these values in the generated headers
6287 AC_SUBST(NCURSES_MAJOR)
6288 AC_SUBST(NCURSES_MINOR)
6289 AC_SUBST(NCURSES_PATCH)
6290 dnl We need these values in the generated makefiles
6291 AC_SUBST(cf_cv_rel_version)
6292 AC_SUBST(cf_cv_abi_version)
6293 AC_SUBST(cf_cv_builtin_bool)
6294 AC_SUBST(cf_cv_header_stdbool_h)
6295 AC_SUBST(cf_cv_type_of_bool)dnl
6296 ])dnl
6297 dnl ---------------------------------------------------------------------------
6298 dnl CF_SYS_TIME_SELECT version: 5 updated: 2012/10/04 05:24:07
6299 dnl ------------------
6300 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
6301 dnl older SCO configurations.
6302 AC_DEFUN([CF_SYS_TIME_SELECT],
6303 [
6304 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
6305 AC_CACHE_VAL(cf_cv_sys_time_select,[
6306 AC_TRY_COMPILE([
6307 #include <sys/types.h>
6308 #ifdef HAVE_SYS_TIME_H
6309 #include <sys/time.h>
6310 #endif
6311 #ifdef HAVE_SYS_SELECT_H
6312 #include <sys/select.h>
6313 #endif
6314 ],[],[cf_cv_sys_time_select=yes],
6315      [cf_cv_sys_time_select=no])
6316      ])
6317 AC_MSG_RESULT($cf_cv_sys_time_select)
6318 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
6319 ])dnl
6320 dnl ---------------------------------------------------------------------------
6321 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
6322 dnl ---------------
6323 dnl Define a top_builddir symbol, for applications that need an absolute path.
6324 AC_DEFUN([CF_TOP_BUILDDIR],
6325 [
6326 top_builddir=ifelse($1,,`pwd`,$1)
6327 AC_SUBST(top_builddir)
6328 ])dnl
6329 dnl ---------------------------------------------------------------------------
6330 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
6331 dnl -------------------
6332 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
6333 dnl can define it successfully.
6334 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
6335 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
6336         AC_TRY_COMPILE([
6337 #include <stdlib.h>
6338 #include <string.h>
6339 #include <sys/types.h>
6340 ],[
6341 #ifndef _XOPEN_SOURCE
6342 make an error
6343 #endif],
6344         [cf_cv_xopen_source=no],
6345         [cf_save="$CPPFLAGS"
6346          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
6347          AC_TRY_COMPILE([
6348 #include <stdlib.h>
6349 #include <string.h>
6350 #include <sys/types.h>
6351 ],[
6352 #ifdef _XOPEN_SOURCE
6353 make an error
6354 #endif],
6355         [cf_cv_xopen_source=no],
6356         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
6357         CPPFLAGS="$cf_save"
6358         ])
6359 ])
6360
6361 if test "$cf_cv_xopen_source" != no ; then
6362         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
6363         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
6364         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
6365         CF_ADD_CFLAGS($cf_temp_xopen_source)
6366 fi
6367 ])
6368 dnl ---------------------------------------------------------------------------
6369 dnl CF_TYPEOF_CHTYPE version: 9 updated: 2012/10/06 17:56:13
6370 dnl ----------------
6371 dnl Determine the type we should use for chtype (and attr_t, which is treated
6372 dnl as the same thing).  We want around 32 bits, so on most machines want a
6373 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
6374 dnl wide characters, we have to have a type compatible with that, as well.
6375 AC_DEFUN([CF_TYPEOF_CHTYPE],
6376 [
6377 AC_MSG_CHECKING([for type of chtype])
6378 AC_CACHE_VAL(cf_cv_typeof_chtype,[
6379                 AC_TRY_RUN([
6380 #define WANT_BITS 31
6381 #include <stdio.h>
6382 int main()
6383 {
6384         FILE *fp = fopen("cf_test.out", "w");
6385         if (fp != 0) {
6386                 char *result = "long";
6387                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
6388                         int n;
6389                         unsigned int x, y;
6390                         for (n = 0; n < WANT_BITS; n++) {
6391                                 x = (1 << n);
6392                                 y = (x >> n);
6393                                 if (y != 1 || x == 0) {
6394                                         x = 0;
6395                                         break;
6396                                 }
6397                         }
6398                         /*
6399                          * If x is nonzero, an int is big enough for the bits
6400                          * that we want.
6401                          */
6402                         result = (x != 0) ? "int" : "long";
6403                 }
6404                 fputs(result, fp);
6405                 fclose(fp);
6406         }
6407         ${cf_cv_main_return:-return}(0);
6408 }
6409                 ],
6410                 [cf_cv_typeof_chtype=`cat cf_test.out`],
6411                 [cf_cv_typeof_chtype=long],
6412                 [cf_cv_typeof_chtype=long])
6413                 rm -f cf_test.out
6414         ])
6415 AC_MSG_RESULT($cf_cv_typeof_chtype)
6416
6417 AC_SUBST(cf_cv_typeof_chtype)
6418 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype,[Define to actual type if needed for chtype])
6419 ])dnl
6420 dnl ---------------------------------------------------------------------------
6421 dnl CF_TYPE_SIGACTION version: 4 updated: 2012/10/06 17:56:13
6422 dnl -----------------
6423 dnl
6424 AC_DEFUN([CF_TYPE_SIGACTION],
6425 [
6426 AC_MSG_CHECKING([for type sigaction_t])
6427 AC_CACHE_VAL(cf_cv_type_sigaction,[
6428         AC_TRY_COMPILE([
6429 #include <signal.h>],
6430                 [sigaction_t x],
6431                 [cf_cv_type_sigaction=yes],
6432                 [cf_cv_type_sigaction=no])])
6433 AC_MSG_RESULT($cf_cv_type_sigaction)
6434 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION,1,[Define to 1 if we have the sigaction_t type])
6435 ])dnl
6436 dnl ---------------------------------------------------------------------------
6437 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
6438 dnl --------------------
6439 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
6440 dnl won't, but they're still there.
6441 AC_DEFUN([CF_UNSIGNED_LITERALS],
6442 [
6443 AC_MSG_CHECKING([if unsigned literals are legal])
6444 AC_CACHE_VAL(cf_cv_unsigned_literals,[
6445         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
6446                 [cf_cv_unsigned_literals=yes],
6447                 [cf_cv_unsigned_literals=no])
6448         ])
6449 AC_MSG_RESULT($cf_cv_unsigned_literals)
6450 ])dnl
6451 dnl ---------------------------------------------------------------------------
6452 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
6453 dnl --------
6454 dnl Make an uppercase version of a variable
6455 dnl $1=uppercase($2)
6456 AC_DEFUN([CF_UPPER],
6457 [
6458 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
6459 ])dnl
6460 dnl ---------------------------------------------------------------------------
6461 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
6462 dnl -----------
6463 dnl Check for multibyte support, and if not found, utf8 compatibility library
6464 AC_DEFUN([CF_UTF8_LIB],
6465 [
6466 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
6467         cf_save_LIBS="$LIBS"
6468         AC_TRY_LINK([
6469 #include <stdlib.h>],[putwc(0,0);],
6470         [cf_cv_utf8_lib=yes],
6471         [CF_FIND_LINKAGE([
6472 #include <libutf8.h>],[putwc(0,0);],utf8,
6473                 [cf_cv_utf8_lib=add-on],
6474                 [cf_cv_utf8_lib=no])
6475 ])])
6476
6477 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
6478 # ncurses/ncursesw:
6479 if test "$cf_cv_utf8_lib" = "add-on" ; then
6480         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
6481         CF_ADD_INCDIR($cf_cv_header_path_utf8)
6482         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
6483         CF_ADD_LIBS($cf_cv_library_file_utf8)
6484 fi
6485 ])dnl
6486 dnl ---------------------------------------------------------------------------
6487 dnl CF_VA_COPY version: 3 updated: 2012/10/06 11:17:15
6488 dnl ----------
6489 dnl check for va_copy, part of stdarg.h
6490 dnl Also, workaround for glibc's __va_copy, by checking for both.
6491 AC_DEFUN([CF_VA_COPY],[
6492 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
6493 AC_TRY_LINK([
6494 #include <stdarg.h>
6495 ],[
6496         static va_list dst;
6497         static va_list src;
6498         va_copy(dst, src)],
6499         cf_cv_have_va_copy=yes,
6500         cf_cv_have_va_copy=no)])
6501
6502 test "$cf_cv_have_va_copy" = yes && AC_DEFINE(HAVE_VA_COPY,1,[Define to 1 if we have va_copy])
6503
6504 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
6505 AC_TRY_LINK([
6506 #include <stdarg.h>
6507 ],[
6508         static va_list dst;
6509         static va_list src;
6510         __va_copy(dst, src)],
6511         cf_cv_have___va_copy=yes,
6512         cf_cv_have___va_copy=no)])
6513
6514 test "$cf_cv_have___va_copy" = yes && AC_DEFINE(HAVE___VA_COPY,1,[Define to 1 if we have __va_copy])
6515 ])
6516 dnl ---------------------------------------------------------------------------
6517 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
6518 dnl ----------
6519 dnl Use AC_VERBOSE w/o the warnings
6520 AC_DEFUN([CF_VERBOSE],
6521 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
6522 CF_MSG_LOG([$1])
6523 ])dnl
6524 dnl ---------------------------------------------------------------------------
6525 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
6526 dnl -------------
6527 dnl Check if type wide-character type $1 is declared, and if so, which header
6528 dnl file is needed.  The second parameter is used to set a shell variable when
6529 dnl the type is not found.  The first parameter sets a shell variable for the
6530 dnl opposite sense.
6531 AC_DEFUN([CF_WCHAR_TYPE],
6532 [
6533 # This is needed on Tru64 5.0 to declare $1
6534 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
6535 AC_TRY_COMPILE([
6536 #include <stdlib.h>
6537 #include <stdarg.h>
6538 #include <stdio.h>
6539 #ifdef HAVE_LIBUTF8_H
6540 #include <libutf8.h>
6541 #endif],
6542         [$1 state],
6543         [cf_cv_$1=no],
6544         [AC_TRY_COMPILE([
6545 #include <stdlib.h>
6546 #include <stdarg.h>
6547 #include <stdio.h>
6548 #include <wchar.h>
6549 #ifdef HAVE_LIBUTF8_H
6550 #include <libutf8.h>
6551 #endif],
6552         [$1 value],
6553         [cf_cv_$1=yes],
6554         [cf_cv_$1=unknown])])])
6555
6556 if test "$cf_cv_$1" = yes ; then
6557         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
6558         NEED_WCHAR_H=1
6559 fi
6560
6561 ifelse([$2],,,[
6562 # if we do not find $1 in either place, use substitution to provide a fallback.
6563 if test "$cf_cv_$1" = unknown ; then
6564         $2=1
6565 fi
6566 ])
6567 ifelse($3,,,[
6568 # if we find $1 in either place, use substitution to provide a fallback.
6569 if test "$cf_cv_$1" != unknown ; then
6570         $3=1
6571 fi
6572 ])
6573 ])dnl
6574 dnl ---------------------------------------------------------------------------
6575 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
6576 dnl ---------------
6577 dnl Check for compiler-support for weak symbols.
6578 dnl This works with "recent" gcc.
6579 AC_DEFUN([CF_WEAK_SYMBOLS],[
6580 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
6581
6582 AC_TRY_COMPILE([
6583 #include <stdio.h>],
6584 [
6585 #if defined(__GNUC__)
6586 #  if defined __USE_ISOC99
6587 #    define _cat_pragma(exp)    _Pragma(#exp)
6588 #    define _weak_pragma(exp)   _cat_pragma(weak name)
6589 #  else
6590 #    define _weak_pragma(exp)
6591 #  endif
6592 #  define _declare(name)        __extension__ extern __typeof__(name) name
6593 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
6594 #endif
6595
6596 weak_symbol(fopen);
6597 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
6598 ])
6599 ])dnl
6600 dnl ---------------------------------------------------------------------------
6601 dnl CF_WITH_ABI_VERSION version: 1 updated: 2003/09/20 18:12:49
6602 dnl -------------------
6603 dnl Allow library's ABI to be overridden.  Generally this happens when a
6604 dnl packager has incremented the ABI past that used in the original package,
6605 dnl and wishes to keep doing this.
6606 dnl
6607 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
6608 dnl symbol.
6609 AC_DEFUN([CF_WITH_ABI_VERSION],[
6610 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
6611 AC_ARG_WITH(abi-version,
6612 [  --with-abi-version=XXX  override derived ABI version],
6613 [AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
6614  cf_cv_abi_version=$withval])
6615  CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
6616 ifelse($1,,,[
6617 $1_ABI=$cf_cv_abi_version
6618 ])
6619 ])dnl
6620 dnl ---------------------------------------------------------------------------
6621 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
6622 dnl --------------------
6623 dnl Command-line option to specify the Ada95 compiler.
6624 AC_DEFUN([CF_WITH_ADA_COMPILER],[
6625 AC_MSG_CHECKING(for ada-compiler)
6626 AC_ARG_WITH(ada-compiler,
6627         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
6628         [cf_ada_compiler=$withval],
6629         [cf_ada_compiler=gnatmake])
6630 AC_SUBST(cf_ada_compiler)
6631 AC_MSG_RESULT($cf_ada_compiler)
6632 ])dnl
6633 dnl ---------------------------------------------------------------------------
6634 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
6635 dnl -------------------
6636 dnl Command-line option to specify where Ada includes will install.
6637 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
6638 AC_MSG_CHECKING(for ada-include)
6639 CF_WITH_PATH(ada-include,
6640    [  --with-ada-include=DIR  Ada includes are in DIR],
6641    ADA_INCLUDE,
6642    PREFIX/share/ada/adainclude,
6643    [$]prefix/share/ada/adainclude)
6644 AC_SUBST(ADA_INCLUDE)
6645 AC_MSG_RESULT($ADA_INCLUDE)
6646 ])dnl
6647 dnl ---------------------------------------------------------------------------
6648 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
6649 dnl -------------------
6650 dnl Command-line option to specify where Ada objects will install.
6651 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
6652 AC_MSG_CHECKING(for ada-objects)
6653 CF_WITH_PATH(ada-objects,
6654    [  --with-ada-objects=DIR  Ada objects are in DIR],
6655    ADA_OBJECTS,
6656    PREFIX/lib/ada/adalib,
6657    [$]prefix/lib/ada/adalib)
6658 AC_SUBST(ADA_OBJECTS)
6659 AC_MSG_RESULT($ADA_OBJECTS)
6660 ])dnl
6661 dnl ---------------------------------------------------------------------------
6662 dnl CF_WITH_ADA_SHAREDLIB version: 4 updated: 2014/05/31 21:08:37
6663 dnl ---------------------
6664 dnl Command-line option to specify if an Ada95 shared-library should be built,
6665 dnl and optionally what its soname should be.
6666 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
6667 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
6668 AC_ARG_WITH(ada-sharedlib,
6669         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
6670         [with_ada_sharedlib=$withval],
6671         [with_ada_sharedlib=no])
6672 AC_MSG_RESULT($with_ada_sharedlib)
6673
6674 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
6675 MAKE_ADA_SHAREDLIB="#"
6676
6677 if test "x$with_ada_sharedlib" != xno
6678 then
6679         MAKE_ADA_SHAREDLIB=
6680         if test "x$with_ada_sharedlib" != xyes
6681         then
6682                 ADA_SHAREDLIB="$with_ada_sharedlib"
6683         fi
6684 fi
6685
6686 AC_SUBST(ADA_SHAREDLIB)
6687 AC_SUBST(MAKE_ADA_SHAREDLIB)
6688 ])dnl
6689 dnl ---------------------------------------------------------------------------
6690 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
6691 dnl ----------------
6692 dnl Configure-option for dbmalloc.  The optional parameter is used to override
6693 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6694 AC_DEFUN([CF_WITH_DBMALLOC],[
6695 CF_NO_LEAKS_OPTION(dbmalloc,
6696         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
6697         [USE_DBMALLOC])
6698
6699 if test "$with_dbmalloc" = yes ; then
6700         AC_CHECK_HEADER(dbmalloc.h,
6701                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
6702 fi
6703 ])dnl
6704 dnl ---------------------------------------------------------------------------
6705 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
6706 dnl ---------------
6707 dnl Configure-option for dmalloc.  The optional parameter is used to override
6708 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6709 AC_DEFUN([CF_WITH_DMALLOC],[
6710 CF_NO_LEAKS_OPTION(dmalloc,
6711         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
6712         [USE_DMALLOC])
6713
6714 if test "$with_dmalloc" = yes ; then
6715         AC_CHECK_HEADER(dmalloc.h,
6716                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
6717 fi
6718 ])dnl
6719 dnl ---------------------------------------------------------------------------
6720 dnl CF_WITH_GPM version: 8 updated: 2012/10/06 17:56:13
6721 dnl -----------
6722 dnl
6723 dnl The option parameter (if neither yes/no) is assumed to be the name of
6724 dnl the gpm library, e.g., for dynamic loading.
6725 AC_DEFUN([CF_WITH_GPM],
6726 [
6727 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
6728 AC_ARG_WITH(gpm,
6729         [  --with-gpm              use Alessandro Rubini's GPM library],
6730         [with_gpm=$withval],
6731         [with_gpm=maybe])
6732 AC_MSG_RESULT($with_gpm)
6733
6734 if test "$with_gpm" != no ; then
6735         AC_CHECK_HEADER(gpm.h,[
6736                 AC_DEFINE(HAVE_GPM_H,1,[Define to 1 if we have gpm.h header])
6737                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
6738                         CF_VERBOSE(assuming we really have GPM library)
6739                         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
6740                 else
6741                         AC_CHECK_LIB(gpm,Gpm_Open,[:],[
6742                                 AC_MSG_ERROR(Cannot link with GPM library)
6743                 fi
6744                 with_gpm=yes
6745                 ])
6746         ],[
6747                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
6748                 with_gpm=no
6749         ])
6750 fi
6751 ])
6752 dnl ---------------------------------------------------------------------------
6753 dnl CF_WITH_LIBTOOL version: 30 updated: 2013/09/07 13:54:05
6754 dnl ---------------
6755 dnl Provide a configure option to incorporate libtool.  Define several useful
6756 dnl symbols for the makefile rules.
6757 dnl
6758 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
6759 dnl macros from libtool.m4 which is in the aclocal directory of automake.
6760 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
6761 dnl But that still does not work properly since the macro is expanded outside
6762 dnl the CF_WITH_LIBTOOL macro:
6763 dnl
6764 dnl     #!/bin/sh
6765 dnl     ACLOCAL=`aclocal --print-ac-dir`
6766 dnl     if test -z "$ACLOCAL" ; then
6767 dnl             echo cannot find aclocal directory
6768 dnl             exit 1
6769 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
6770 dnl             echo cannot find libtool.m4 file
6771 dnl             exit 1
6772 dnl     fi
6773 dnl
6774 dnl     LOCAL=aclocal.m4
6775 dnl     ORIG=aclocal.m4.orig
6776 dnl
6777 dnl     trap "mv $ORIG $LOCAL" 0 1 2 5 15
6778 dnl     rm -f $ORIG
6779 dnl     mv $LOCAL $ORIG
6780 dnl
6781 dnl     # sed the LIBTOOL= assignment to omit the current directory?
6782 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
6783 dnl     cat $ORIG >>$LOCAL
6784 dnl
6785 dnl     autoconf-257 $*
6786 dnl
6787 AC_DEFUN([CF_WITH_LIBTOOL],
6788 [
6789 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
6790 ifdef([AC_PROG_LIBTOOL],,[
6791 LIBTOOL=
6792 ])
6793 # common library maintenance symbols that are convenient for libtool scripts:
6794 LIB_CREATE='${AR} -cr'
6795 LIB_OBJECT='${OBJECTS}'
6796 LIB_SUFFIX=.a
6797 LIB_PREP="$RANLIB"
6798
6799 # symbols used to prop libtool up to enable it to determine what it should be
6800 # doing:
6801 LIB_CLEAN=
6802 LIB_COMPILE=
6803 LIB_LINK='${CC}'
6804 LIB_INSTALL=
6805 LIB_UNINSTALL=
6806
6807 AC_MSG_CHECKING(if you want to build libraries with libtool)
6808 AC_ARG_WITH(libtool,
6809         [  --with-libtool          generate libraries with libtool],
6810         [with_libtool=$withval],
6811         [with_libtool=no])
6812 AC_MSG_RESULT($with_libtool)
6813 if test "$with_libtool" != "no"; then
6814 ifdef([AC_PROG_LIBTOOL],[
6815         # missing_content_AC_PROG_LIBTOOL{{
6816         AC_PROG_LIBTOOL
6817         # missing_content_AC_PROG_LIBTOOL}}
6818 ],[
6819         if test "$with_libtool" != "yes" ; then
6820                 CF_PATH_SYNTAX(with_libtool)
6821                 LIBTOOL=$with_libtool
6822         else
6823                 AC_CHECK_TOOLS(LIBTOOL,[libtool glibtool],none)
6824                 CF_LIBTOOL_VERSION
6825                 if test -z "$cf_cv_libtool_version" && test "$LIBTOOL" = libtool
6826                 then
6827                         CF_FORGET_TOOL(LIBTOOL)
6828                         AC_CHECK_TOOLS(LIBTOOL,[glibtool],none)
6829                         CF_LIBTOOL_VERSION
6830                 fi
6831         fi
6832         if test -z "$LIBTOOL" ; then
6833                 AC_MSG_ERROR(Cannot find libtool)
6834         fi
6835 ])dnl
6836         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${DESTDIR}${libdir} ${LIBTOOL_VERSION} `cut -f1 ${srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
6837         LIB_OBJECT='${OBJECTS:.o=.lo}'
6838         LIB_SUFFIX=.la
6839         LIB_CLEAN='${LIBTOOL} --mode=clean'
6840         LIB_COMPILE='${LIBTOOL} --mode=compile'
6841         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
6842         LIB_INSTALL='${LIBTOOL} --mode=install'
6843         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
6844         LIB_PREP=:
6845
6846         CF_CHECK_LIBTOOL_VERSION
6847
6848         # special hack to add -no-undefined (which libtool should do for itself)
6849         LT_UNDEF=
6850         case "$cf_cv_system_name" in #(vi
6851         cygwin*|msys*|mingw32*|uwin*|aix[[4-7]]) #(vi
6852                 LT_UNDEF=-no-undefined
6853                 ;;
6854         esac
6855         AC_SUBST([LT_UNDEF])
6856
6857         # special hack to add --tag option for C++ compiler
6858         case $cf_cv_libtool_version in #(vi
6859         1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*) #(vi
6860                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
6861                 LIBTOOL="$LIBTOOL --tag=CC"
6862                 ;;
6863         *)
6864                 LIBTOOL_CXX="$LIBTOOL"
6865                 ;;
6866         esac
6867 else
6868         LIBTOOL=""
6869         LIBTOOL_CXX=""
6870 fi
6871
6872 test -z "$LIBTOOL" && ECHO_LT=
6873
6874 AC_SUBST(LIBTOOL)
6875 AC_SUBST(LIBTOOL_CXX)
6876 AC_SUBST(LIBTOOL_OPTS)
6877
6878 AC_SUBST(LIB_CREATE)
6879 AC_SUBST(LIB_OBJECT)
6880 AC_SUBST(LIB_SUFFIX)
6881 AC_SUBST(LIB_PREP)
6882
6883 AC_SUBST(LIB_CLEAN)
6884 AC_SUBST(LIB_COMPILE)
6885 AC_SUBST(LIB_LINK)
6886 AC_SUBST(LIB_INSTALL)
6887 AC_SUBST(LIB_UNINSTALL)
6888
6889 ])dnl
6890 dnl ---------------------------------------------------------------------------
6891 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
6892 dnl ------------------
6893 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
6894 dnl "lib" prefix, e.g., because it used the dll naming convention.
6895 dnl
6896 dnl $1 = variable to set
6897 AC_DEFUN([CF_WITH_LIB_PREFIX],
6898 [
6899 AC_MSG_CHECKING(if you want to have a library-prefix)
6900 AC_ARG_WITH(lib-prefix,
6901         [  --with-lib-prefix       override library-prefix],
6902         [with_lib_prefix=$withval],
6903         [with_lib_prefix=auto])
6904 AC_MSG_RESULT($with_lib_prefix)
6905
6906 if test $with_lib_prefix = auto
6907 then
6908         CF_LIB_PREFIX($1)
6909 elif test $with_lib_prefix = no
6910 then
6911         LIB_PREFIX=
6912 else
6913         LIB_PREFIX=$with_lib_prefix
6914 fi
6915 ])dnl
6916 dnl ---------------------------------------------------------------------------
6917 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
6918 dnl ------------
6919 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
6920 dnl defaulting to yes/no.
6921 dnl
6922 dnl $1 = option name
6923 dnl $2 = help-text
6924 dnl $3 = environment variable to set
6925 dnl $4 = default value, shown in the help-message, must be a constant
6926 dnl $5 = default value, if it's an expression & cannot be in the help-message
6927 dnl
6928 AC_DEFUN([CF_WITH_PATH],
6929 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
6930 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
6931 if ifelse([$5],,true,[test -n "$5"]) ; then
6932 CF_PATH_SYNTAX(withval)
6933 fi
6934 eval $3="$withval"
6935 AC_SUBST($3)dnl
6936 ])dnl
6937 dnl ---------------------------------------------------------------------------
6938 dnl CF_WITH_PATHLIST version: 9 updated: 2012/10/18 05:05:24
6939 dnl ----------------
6940 dnl Process an option specifying a list of colon-separated paths.
6941 dnl
6942 dnl $1 = option name
6943 dnl $2 = help-text
6944 dnl $3 = environment variable to set
6945 dnl $4 = default value, shown in the help-message, must be a constant
6946 dnl $5 = default value, if it's an expression & cannot be in the help-message
6947 dnl $6 = flag to tell if we want to define or substitute
6948 dnl
6949 AC_DEFUN([CF_WITH_PATHLIST],[
6950 AC_REQUIRE([CF_PATHSEP])
6951 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
6952 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
6953
6954 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
6955 cf_dst_path=
6956 for cf_src_path in $withval
6957 do
6958   CF_PATH_SYNTAX(cf_src_path)
6959   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}$PATH_SEPARATOR"
6960   cf_dst_path="${cf_dst_path}${cf_src_path}"
6961 done
6962 IFS="$ac_save_ifs"
6963
6964 ifelse($6,define,[
6965 # Strip single quotes from the value, e.g., when it was supplied as a literal
6966 # for $4 or $5.
6967 case $cf_dst_path in #(vi
6968 \'*)
6969   cf_dst_path=`echo $cf_dst_path |sed -e s/\'// -e s/\'\$//`
6970   ;;
6971 esac
6972 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
6973 ])
6974
6975 # This may use the prefix/exec_prefix symbols which will only yield "NONE"
6976 # so we have to check/work around.  We do prefer the result of "eval"...
6977 eval cf_dst_eval="$cf_dst_path"
6978 case "x$cf_dst_eval" in #(vi
6979 xNONE*) #(vi
6980         $3=$cf_dst_path
6981         ;;
6982 *)
6983         $3="$cf_dst_eval"
6984         ;;
6985 esac
6986 AC_SUBST($3)dnl
6987
6988 ])dnl
6989 dnl ---------------------------------------------------------------------------
6990 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 2 updated: 2011/12/10 18:58:47
6991 dnl -------------------------
6992 dnl Allow the choice of the pkg-config library directory to be overridden.
6993 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
6994 if test "$PKG_CONFIG" != none ; then
6995         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
6996         AC_ARG_WITH(pkg-config-libdir,
6997                 [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
6998                 [PKG_CONFIG_LIBDIR=$withval],
6999                 [PKG_CONFIG_LIBDIR=yes])
7000
7001         case x$PKG_CONFIG_LIBDIR in #(vi
7002         x/*) #(vi
7003                 ;;
7004         xyes) #(vi
7005                 # look for the library directory using the same prefix as the executable
7006                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
7007                 case x`(arch) 2>/dev/null` in #(vi
7008                 *64) #(vi
7009                         for cf_config in $cf_path/share $cf_path/lib64 $cf_path/lib32 $cf_path/lib
7010                         do
7011                                 if test -d $cf_config/pkgconfig
7012                                 then
7013                                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
7014                                         break
7015                                 fi
7016                         done
7017                         ;;
7018                 *)
7019                         PKG_CONFIG_LIBDIR=$cf_path/lib/pkgconfig
7020                         ;;
7021                 esac
7022                 ;;
7023         *)
7024                 ;;
7025         esac
7026
7027         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
7028 fi
7029
7030 AC_SUBST(PKG_CONFIG_LIBDIR)
7031 ])dnl
7032 dnl ---------------------------------------------------------------------------
7033 dnl CF_WITH_PTHREAD version: 6 updated: 2012/10/06 17:41:51
7034 dnl ---------------
7035 dnl Check for POSIX thread library.
7036 AC_DEFUN([CF_WITH_PTHREAD],
7037 [
7038 AC_MSG_CHECKING(if you want to link with the pthread library)
7039 AC_ARG_WITH(pthread,
7040     [  --with-pthread          use POSIX thread library],
7041     [with_pthread=$withval],
7042     [with_pthread=no])
7043 AC_MSG_RESULT($with_pthread)
7044
7045 if test "$with_pthread" != no ; then
7046     AC_CHECK_HEADER(pthread.h,[
7047         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
7048
7049         for cf_lib_pthread in pthread c_r
7050         do
7051             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
7052             cf_save_LIBS="$LIBS"
7053             CF_ADD_LIB($cf_lib_pthread)
7054             AC_TRY_LINK([
7055 #include <pthread.h>
7056 ],[
7057                 int rc = pthread_create(0,0,0,0);
7058                 int r2 = pthread_mutexattr_settype(0, 0);
7059 ],[with_pthread=yes],[with_pthread=no])
7060             LIBS="$cf_save_LIBS"
7061             AC_MSG_RESULT($with_pthread)
7062             test "$with_pthread" = yes && break
7063         done
7064
7065         if test "$with_pthread" = yes ; then
7066             CF_ADD_LIB($cf_lib_pthread)
7067             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
7068         else
7069             AC_MSG_ERROR(Cannot link with pthread library)
7070         fi
7071     ])
7072 fi
7073 ])
7074 dnl ---------------------------------------------------------------------------
7075 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
7076 dnl -------------------
7077 dnl Allow library's release-version to be overridden.  Generally this happens when a
7078 dnl packager has incremented the release-version past that used in the original package,
7079 dnl and wishes to keep doing this.
7080 dnl
7081 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
7082 dnl and {package}_MINOR symbols
7083 dnl symbol.
7084 AC_DEFUN([CF_WITH_REL_VERSION],[
7085 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
7086 AC_ARG_WITH(rel-version,
7087 [  --with-rel-version=XXX  override derived release version],
7088 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
7089  cf_cv_rel_version=$withval])
7090 ifelse($1,,[
7091  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
7092 ],[
7093  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
7094  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
7095  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
7096  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
7097 ])
7098 ])dnl
7099 dnl ---------------------------------------------------------------------------
7100 dnl CF_WITH_SYSMOUSE version: 3 updated: 2012/10/06 17:56:13
7101 dnl ----------------
7102 dnl If we can compile with sysmouse, make it available unless it is not wanted.
7103 AC_DEFUN([CF_WITH_SYSMOUSE],[
7104 # not everyone has "test -c"
7105 if test -c /dev/sysmouse 2>/dev/null ; then
7106 AC_MSG_CHECKING(if you want to use sysmouse)
7107 AC_ARG_WITH(sysmouse,
7108         [  --with-sysmouse         use sysmouse (FreeBSD console)],
7109         [cf_with_sysmouse=$withval],
7110         [cf_with_sysmouse=maybe])
7111         if test "$cf_with_sysmouse" != no ; then
7112         AC_TRY_COMPILE([
7113 #include <osreldate.h>
7114 #if (__FreeBSD_version >= 400017)
7115 #include <sys/consio.h>
7116 #include <sys/fbio.h>
7117 #else
7118 #include <machine/console.h>
7119 #endif
7120 ],[
7121         struct mouse_info the_mouse;
7122         ioctl(0, CONS_MOUSECTL, &the_mouse);
7123 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
7124         fi
7125 AC_MSG_RESULT($cf_with_sysmouse)
7126 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE,1,[Define to 1 if we can/should use the sysmouse interface])
7127 fi
7128 ])dnl
7129 dnl ---------------------------------------------------------------------------
7130 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
7131 dnl ---------------
7132 dnl For testing, override the derived host system-type which is used to decide
7133 dnl things such as the linker commands used to build shared libraries.  This is
7134 dnl normally chosen automatically based on the type of system which you are
7135 dnl building on.  We use it for testing the configure script.
7136 dnl
7137 dnl This is different from the --host option: it is used only for testing parts
7138 dnl of the configure script which would not be reachable with --host since that
7139 dnl relies on the build environment being real, rather than mocked up.
7140 AC_DEFUN([CF_WITH_SYSTYPE],[
7141 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
7142 AC_ARG_WITH(system-type,
7143         [  --with-system-type=XXX  test: override derived host system-type],
7144 [AC_MSG_WARN(overriding system type to $withval)
7145         cf_cv_system_name=$withval
7146         host_os=$withval
7147 ])
7148 ])dnl
7149 dnl ---------------------------------------------------------------------------
7150 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
7151 dnl ----------------
7152 AC_DEFUN([CF_WITH_VALGRIND],[
7153 CF_NO_LEAKS_OPTION(valgrind,
7154         [  --with-valgrind         test: use valgrind],
7155         [USE_VALGRIND])
7156 ])dnl
7157 dnl ---------------------------------------------------------------------------
7158 dnl CF_XOPEN_SOURCE version: 47 updated: 2014/07/23 17:11:49
7159 dnl ---------------
7160 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
7161 dnl or adapt to the vendor's definitions to get equivalent functionality,
7162 dnl without losing the common non-POSIX features.
7163 dnl
7164 dnl Parameters:
7165 dnl     $1 is the nominal value for _XOPEN_SOURCE
7166 dnl     $2 is the nominal value for _POSIX_C_SOURCE
7167 AC_DEFUN([CF_XOPEN_SOURCE],[
7168 AC_REQUIRE([AC_CANONICAL_HOST])
7169
7170 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
7171 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
7172 cf_xopen_source=
7173
7174 case $host_os in #(vi
7175 aix[[4-7]]*) #(vi
7176         cf_xopen_source="-D_ALL_SOURCE"
7177         ;;
7178 cygwin|msys) #(vi
7179         cf_XOPEN_SOURCE=600
7180         ;;
7181 darwin[[0-8]].*) #(vi
7182         cf_xopen_source="-D_APPLE_C_SOURCE"
7183         ;;
7184 darwin*) #(vi
7185         cf_xopen_source="-D_DARWIN_C_SOURCE"
7186         cf_XOPEN_SOURCE=
7187         ;;
7188 freebsd*|dragonfly*) #(vi
7189         # 5.x headers associate
7190         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
7191         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
7192         cf_POSIX_C_SOURCE=200112L
7193         cf_XOPEN_SOURCE=600
7194         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
7195         ;;
7196 hpux11*) #(vi
7197         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
7198         ;;
7199 hpux*) #(vi
7200         cf_xopen_source="-D_HPUX_SOURCE"
7201         ;;
7202 irix[[56]].*) #(vi
7203         cf_xopen_source="-D_SGI_SOURCE"
7204         cf_XOPEN_SOURCE=
7205         ;;
7206 linux*|gnu*|mint*|k*bsd*-gnu) #(vi
7207         CF_GNU_SOURCE
7208         ;;
7209 minix*) #(vi
7210         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
7211         ;;
7212 mirbsd*) #(vi
7213         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
7214         cf_XOPEN_SOURCE=
7215         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
7216         ;;
7217 netbsd*) #(vi
7218         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
7219         ;;
7220 openbsd[[4-9]]*) #(vi
7221         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
7222         cf_xopen_source="-D_BSD_SOURCE"
7223         cf_XOPEN_SOURCE=600
7224         ;;
7225 openbsd*) #(vi
7226         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
7227         ;;
7228 osf[[45]]*) #(vi
7229         cf_xopen_source="-D_OSF_SOURCE"
7230         ;;
7231 nto-qnx*) #(vi
7232         cf_xopen_source="-D_QNX_SOURCE"
7233         ;;
7234 sco*) #(vi
7235         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
7236         ;;
7237 solaris2.*) #(vi
7238         cf_xopen_source="-D__EXTENSIONS__"
7239         cf_cv_xopen_source=broken
7240         ;;
7241 *)
7242         CF_TRY_XOPEN_SOURCE
7243         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
7244         ;;
7245 esac
7246
7247 if test -n "$cf_xopen_source" ; then
7248         CF_ADD_CFLAGS($cf_xopen_source,true)
7249 fi
7250
7251 dnl In anything but the default case, we may have system-specific setting
7252 dnl which is still not guaranteed to provide all of the entrypoints that
7253 dnl _XOPEN_SOURCE would yield.
7254 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
7255         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
7256         AC_TRY_COMPILE([#include <stdlib.h>],[
7257 #ifndef _XOPEN_SOURCE
7258 make an error
7259 #endif],
7260         [cf_XOPEN_SOURCE_set=yes],
7261         [cf_XOPEN_SOURCE_set=no])
7262         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
7263         if test $cf_XOPEN_SOURCE_set = yes
7264         then
7265                 AC_TRY_COMPILE([#include <stdlib.h>],[
7266 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
7267 make an error
7268 #endif],
7269                 [cf_XOPEN_SOURCE_set_ok=yes],
7270                 [cf_XOPEN_SOURCE_set_ok=no])
7271                 if test $cf_XOPEN_SOURCE_set_ok = no
7272                 then
7273                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
7274                 fi
7275         else
7276                 CF_TRY_XOPEN_SOURCE
7277         fi
7278 fi
7279 ])