aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2018,2019 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.883 2019/09/21 22:11:35 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See https://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 4 updated: 2015/04/18 08:56:57
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54         [AC_TRY_LINK([#include <langinfo.h>],
  55         [char* cs = nl_langinfo(CODESET);],
  56         am_cv_langinfo_codeset=yes,
  57         am_cv_langinfo_codeset=no)
  58         ])
  59         if test $am_cv_langinfo_codeset = yes; then
  60                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62         fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ABI_DEFAULTS version: 2 updated: 2015/06/06 13:49:58
  66 dnl ---------------
  67 dnl Provide configure-script defaults for different ncurses ABIs.
  68 AC_DEFUN([CF_ABI_DEFAULTS],[
  69 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
  70 case x$cf_cv_abi_version in
  71 (x[[6789]])
  72         cf_dft_ext_colors=yes
  73         cf_dft_ext_const=yes
  74         cf_dft_ext_mouse=yes
  75         cf_dft_ext_putwin=yes
  76         cf_dft_ext_spfuncs=yes
  77         cf_dft_filter_syms=yes
  78         cf_dft_chtype=uint32_t
  79         cf_dft_mmask_t=uint32_t
  80         cf_dft_interop=yes
  81         cf_dft_tparm_arg=intptr_t
  82         cf_dft_with_lp64=yes
  83         ;;
  84 (*)
  85         cf_dft_ext_colors=no
  86         cf_dft_ext_const=no
  87         cf_dft_ext_mouse=no
  88         cf_dft_ext_putwin=no
  89         cf_dft_ext_spfuncs=no
  90         cf_dft_filter_syms=no
  91         cf_dft_chtype=auto
  92         cf_dft_mmask_t=auto
  93         cf_dft_interop=no
  94         cf_dft_tparm_arg=long
  95         cf_dft_with_lp64=no
  96         ;;
  97 esac
  98 ])dnl
  99 dnl ---------------------------------------------------------------------------
 100 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
 101 dnl ------------------
 102 dnl Conditionally generate script according to whether we're using a given autoconf.
 103 dnl
 104 dnl $1 = version to compare against
 105 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
 106 dnl $3 = code to use if AC_ACVERSION is older than $1.
 107 define([CF_ACVERSION_CHECK],
 108 [
 109 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
 110 ifdef([m4_version_compare],
 111 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
 112 [CF_ACVERSION_COMPARE(
 113 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
 114 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
 115 dnl ---------------------------------------------------------------------------
 116 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
 117 dnl --------------------
 118 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
 119 dnl                      MAJOR2, MINOR2, TERNARY2,
 120 dnl                      PRINTABLE2, not FOUND, FOUND)
 121 define([CF_ACVERSION_COMPARE],
 122 [ifelse(builtin([eval], [$2 < $5]), 1,
 123 [ifelse([$8], , ,[$8])],
 124 [ifelse([$9], , ,[$9])])])dnl
 125 dnl ---------------------------------------------------------------------------
 126 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
 127 dnl -------------------
 128 dnl Construct the list of include-options for the C programs in the Ada95
 129 dnl binding.
 130 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
 131 [
 132 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
 133 if test "$srcdir" != "."; then
 134         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 135 fi
 136 if test "$GCC" != yes; then
 137         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 138 elif test "$includedir" != "/usr/include"; then
 139         if test "$includedir" = '${prefix}/include' ; then
 140                 if test x$prefix != x/usr ; then
 141                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 142                 fi
 143         else
 144                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 145         fi
 146 fi
 147 AC_SUBST(ACPPFLAGS)
 148 ])dnl
 149 dnl ---------------------------------------------------------------------------
 150 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 151 dnl ---------------
 152 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 153 AC_DEFUN([CF_ADD_ADAFLAGS],[
 154         ADAFLAGS="$ADAFLAGS $1"
 155         AC_SUBST(ADAFLAGS)
 156 ])dnl
 157 dnl ---------------------------------------------------------------------------
 158 dnl CF_ADD_CFLAGS version: 13 updated: 2017/02/25 18:57:40
 159 dnl -------------
 160 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 161 dnl The second parameter if given makes this macro verbose.
 162 dnl
 163 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 164 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 165 dnl confused by the quotes (which require backslashes to keep them usable).
 166 AC_DEFUN([CF_ADD_CFLAGS],
 167 [
 168 cf_fix_cppflags=no
 169 cf_new_cflags=
 170 cf_new_cppflags=
 171 cf_new_extra_cppflags=
 172
 173 for cf_add_cflags in $1
 174 do
 175 case $cf_fix_cppflags in
 176 (no)
 177         case $cf_add_cflags in
 178         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 179                 case $cf_add_cflags in
 180                 (-D*)
 181                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 182
 183                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 184                                 && test -z "${cf_tst_cflags}" \
 185                                 && cf_fix_cppflags=yes
 186
 187                         if test $cf_fix_cppflags = yes ; then
 188                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 189                                 continue
 190                         elif test "${cf_tst_cflags}" = "\"'" ; then
 191                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 192                                 continue
 193                         fi
 194                         ;;
 195                 esac
 196                 case "$CPPFLAGS" in
 197                 (*$cf_add_cflags)
 198                         ;;
 199                 (*)
 200                         case $cf_add_cflags in
 201                         (-D*)
 202                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 203                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 204                                 ;;
 205                         esac
 206                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 207                         ;;
 208                 esac
 209                 ;;
 210         (*)
 211                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 212                 ;;
 213         esac
 214         ;;
 215 (yes)
 216         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 217
 218         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 219
 220         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 221                 && test -z "${cf_tst_cflags}" \
 222                 && cf_fix_cppflags=no
 223         ;;
 224 esac
 225 done
 226
 227 if test -n "$cf_new_cflags" ; then
 228         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 229         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 230 fi
 231
 232 if test -n "$cf_new_cppflags" ; then
 233         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 234         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 235 fi
 236
 237 if test -n "$cf_new_extra_cppflags" ; then
 238         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 239         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 240 fi
 241
 242 AC_SUBST(EXTRA_CPPFLAGS)
 243
 244 ])dnl
 245 dnl ---------------------------------------------------------------------------
 246 dnl CF_ADD_INCDIR version: 15 updated: 2018/06/20 20:23:13
 247 dnl -------------
 248 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 249 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 250 dnl but old versions (and some misinstalled ones) need that.  To make things
 251 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 252 dnl the include-path).
 253 AC_DEFUN([CF_ADD_INCDIR],
 254 [
 255 if test -n "$1" ; then
 256   for cf_add_incdir in $1
 257   do
 258         while test $cf_add_incdir != /usr/include
 259         do
 260           if test -d $cf_add_incdir
 261           then
 262                 cf_have_incdir=no
 263                 if test -n "$CFLAGS$CPPFLAGS" ; then
 264                   # a loop is needed to ensure we can add subdirs of existing dirs
 265                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 266                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 267                           cf_have_incdir=yes; break
 268                         fi
 269                   done
 270                 fi
 271
 272                 if test "$cf_have_incdir" = no ; then
 273                   if test "$cf_add_incdir" = /usr/local/include ; then
 274                         if test "$GCC" = yes
 275                         then
 276                           cf_save_CPPFLAGS=$CPPFLAGS
 277                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
 278                           AC_TRY_COMPILE([#include <stdio.h>],
 279                                   [printf("Hello")],
 280                                   [],
 281                                   [cf_have_incdir=yes])
 282                           CPPFLAGS=$cf_save_CPPFLAGS
 283                         fi
 284                   fi
 285                 fi
 286
 287                 if test "$cf_have_incdir" = no ; then
 288                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 289                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 290
 291                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 292                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 293                   cf_add_incdir="$cf_top_incdir"
 294                 else
 295                   break
 296                 fi
 297           else
 298                 break
 299           fi
 300         done
 301   done
 302 fi
 303 ])dnl
 304 dnl ---------------------------------------------------------------------------
 305 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 306 dnl ----------
 307 dnl Add a library, used to enforce consistency.
 308 dnl
 309 dnl $1 = library to add, without the "-l"
 310 dnl $2 = variable to update (default $LIBS)
 311 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 312 dnl ---------------------------------------------------------------------------
 313 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 314 dnl -------------
 315 dnl     Adds to the library-path
 316 dnl
 317 dnl     Some machines have trouble with multiple -L options.
 318 dnl
 319 dnl $1 is the (list of) directory(s) to add
 320 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 321 dnl
 322 AC_DEFUN([CF_ADD_LIBDIR],
 323 [
 324 if test -n "$1" ; then
 325         for cf_add_libdir in $1
 326         do
 327                 if test $cf_add_libdir = /usr/lib ; then
 328                         :
 329                 elif test -d $cf_add_libdir
 330                 then
 331                         cf_have_libdir=no
 332                         if test -n "$LDFLAGS$LIBS" ; then
 333                                 # a loop is needed to ensure we can add subdirs of existing dirs
 334                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 335                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 336                                                 cf_have_libdir=yes; break
 337                                         fi
 338                                 done
 339                         fi
 340                         if test "$cf_have_libdir" = no ; then
 341                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 342                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 343                         fi
 344                 fi
 345         done
 346 fi
 347 ])dnl
 348 dnl ---------------------------------------------------------------------------
 349 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
 350 dnl -----------
 351 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 352 dnl prepended to an existing list, since their dependencies are assumed to
 353 dnl already exist in the list.
 354 dnl
 355 dnl $1 = libraries to add, with the "-l", etc.
 356 dnl $2 = variable to update (default $LIBS)
 357 AC_DEFUN([CF_ADD_LIBS],[
 358 cf_add_libs="$1"
 359 # Filter out duplicates - this happens with badly-designed ".pc" files...
 360 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
 361 do
 362         for cf_add_2lib in $cf_add_libs
 363         do
 364                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
 365                 then
 366                         cf_add_1lib=
 367                         break
 368                 fi
 369         done
 370         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
 371 done
 372 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 373 ])dnl
 374 dnl ---------------------------------------------------------------------------
 375 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 376 dnl ------------------
 377 dnl Append to a search-list for a nonstandard header/lib-file
 378 dnl     $1 = the variable to return as result
 379 dnl     $2 = the package name
 380 dnl     $3 = the subdirectory, e.g., bin, include or lib
 381 dnl $4 = the directory under which we will test for subdirectories
 382 dnl $5 = a directory that we do not want $4 to match
 383 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 384 [
 385 test "x$4" != "x$5" && \
 386 test -d "$4" && \
 387 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 388         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 389         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 390         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 391         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 392         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 393         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 394 }
 395 ])dnl
 396 dnl ---------------------------------------------------------------------------
 397 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 398 dnl --------------
 399 dnl use this macro for appending text without introducing an extra blank at
 400 dnl the beginning
 401 define([CF_APPEND_TEXT],
 402 [
 403         test -n "[$]$1" && $1="[$]$1 "
 404         $1="[$]{$1}$2"
 405 ])dnl
 406 dnl ---------------------------------------------------------------------------
 407 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 408 dnl --------------
 409 dnl Allow user to disable a normally-on option.
 410 AC_DEFUN([CF_ARG_DISABLE],
 411 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 412 dnl ---------------------------------------------------------------------------
 413 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 414 dnl -------------
 415 dnl Allow user to enable a normally-off option.
 416 AC_DEFUN([CF_ARG_ENABLE],
 417 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 418 dnl ---------------------------------------------------------------------------
 419 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 420 dnl -------------
 421 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 422 dnl values.
 423 dnl
 424 dnl Parameters:
 425 dnl $1 = option name
 426 dnl $2 = help-string
 427 dnl $3 = action to perform if option is not default
 428 dnl $4 = action if perform if option is default
 429 dnl $5 = default option value (either 'yes' or 'no')
 430 AC_DEFUN([CF_ARG_OPTION],
 431 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 432         if test "$enableval" != "$5" ; then
 433 ifelse([$3],,[    :]dnl
 434 ,[    $3]) ifelse([$4],,,[
 435         else
 436                 $4])
 437         fi],[enableval=$5 ifelse([$4],,,[
 438         $4
 439 ])dnl
 440 ])])dnl
 441 dnl ---------------------------------------------------------------------------
 442 dnl CF_AR_FLAGS version: 6 updated: 2015/10/10 15:25:05
 443 dnl -----------
 444 dnl Check for suitable "ar" (archiver) options for updating an archive.
 445 dnl
 446 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 447 dnl as well as a workaround for breakage of make's archive rules by the GNU
 448 dnl binutils "ar" program.
 449 AC_DEFUN([CF_AR_FLAGS],[
 450 AC_REQUIRE([CF_PROG_AR])
 451
 452 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 453         cf_cv_ar_flags=unknown
 454         for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 455         do
 456
 457                 # check if $ARFLAGS already contains this choice
 458                 if test "x$ARFLAGS" != "x" ; then
 459                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 460                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 461                                 cf_cv_ar_flags=
 462                                 break
 463                         fi
 464                 fi
 465
 466                 rm -f conftest.$ac_cv_objext
 467                 rm -f conftest.a
 468
 469                 cat >conftest.$ac_ext <<EOF
 470 #line __oline__ "configure"
 471 int     testdata[[3]] = { 123, 456, 789 };
 472 EOF
 473                 if AC_TRY_EVAL(ac_compile) ; then
 474                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 475                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 476                         if test -f conftest.a ; then
 477                                 cf_cv_ar_flags=$cf_ar_flags
 478                                 break
 479                         fi
 480                 else
 481                         CF_VERBOSE(cannot compile test-program)
 482                         break
 483                 fi
 484         done
 485         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 486 ])
 487
 488 if test -n "$ARFLAGS" ; then
 489         if test -n "$cf_cv_ar_flags" ; then
 490                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 491         fi
 492 else
 493         ARFLAGS=$cf_cv_ar_flags
 494 fi
 495
 496 AC_SUBST(ARFLAGS)
 497 ])
 498 dnl ---------------------------------------------------------------------------
 499 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
 500 dnl -----------------
 501 dnl Check if awk can handle big strings using printf.  Some older versions of
 502 dnl awk choke on large strings passed via "%s".
 503 dnl
 504 dnl $1 = desired string size
 505 dnl $2 = variable to set with result
 506 AC_DEFUN([CF_AWK_BIG_PRINTF],
 507 [
 508         case x$AWK in
 509         (x)
 510                 eval $2=no
 511                 ;;
 512         (*)
 513                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 514                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 515                         eval $2=yes
 516                 else
 517                         eval $2=no
 518                 fi
 519                 ;;
 520         esac
 521 ])dnl
 522 dnl ---------------------------------------------------------------------------
 523 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 524 dnl ------------
 525 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 526 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 527 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 528 dnl
 529 dnl Treat the configuration-variable specially here, since we're directly
 530 dnl substituting its value (i.e., 1/0).
 531 dnl
 532 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 533 AC_DEFUN([CF_BOOL_DECL],
 534 [
 535 AC_MSG_CHECKING(if we should include stdbool.h)
 536
 537 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 538         AC_TRY_COMPILE([],[bool foo = false],
 539                 [cf_cv_header_stdbool_h=0],
 540                 [AC_TRY_COMPILE([
 541 #ifndef __BEOS__
 542 #include <stdbool.h>
 543 #endif
 544 ],[bool foo = false],
 545                         [cf_cv_header_stdbool_h=1],
 546                         [cf_cv_header_stdbool_h=0])])])
 547
 548 if test "$cf_cv_header_stdbool_h" = 1
 549 then    AC_MSG_RESULT(yes)
 550 else    AC_MSG_RESULT(no)
 551 fi
 552
 553 AC_MSG_CHECKING([for builtin bool type])
 554
 555 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 556         AC_TRY_COMPILE([
 557 #include <stdio.h>
 558 #include <sys/types.h>
 559 ],[bool x = false],
 560                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 561                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 562         ])
 563
 564 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 565 then    AC_MSG_RESULT(yes)
 566 else    AC_MSG_RESULT(no)
 567 fi
 568 ])dnl
 569 dnl ---------------------------------------------------------------------------
 570 dnl CF_BOOL_SIZE version: 15 updated: 2017/01/21 11:06:25
 571 dnl ------------
 572 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 573 dnl Don't bother looking for bool.h, since it's been deprecated.
 574 dnl
 575 dnl If the current compiler is C rather than C++, we get the bool definition
 576 dnl from <stdbool.h>.
 577 AC_DEFUN([CF_BOOL_SIZE],
 578 [
 579 AC_MSG_CHECKING([for size of bool])
 580 AC_CACHE_VAL(cf_cv_type_of_bool,[
 581         rm -f cf_test.out
 582         AC_TRY_RUN([
 583 #include <stdlib.h>
 584 #include <stdio.h>
 585
 586 #if defined(__cplusplus)
 587
 588 #ifdef HAVE_GXX_BUILTIN_H
 589 #include <g++/builtin.h>
 590 #elif HAVE_GPP_BUILTIN_H
 591 #include <gpp/builtin.h>
 592 #elif HAVE_BUILTIN_H
 593 #include <builtin.h>
 594 #endif
 595
 596 #else
 597
 598 #if $cf_cv_header_stdbool_h
 599 #include <stdbool.h>
 600 #endif
 601
 602 #endif
 603
 604 int main(void)
 605 {
 606         FILE *fp = fopen("cf_test.out", "w");
 607         if (fp != 0) {
 608                 bool x = true;
 609                 if ((bool)(-x) >= 0)
 610                         fputs("unsigned ", fp);
 611                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 612                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 613                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 614                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 615                 fclose(fp);
 616         }
 617         ${cf_cv_main_return:-return}(0);
 618 }
 619                 ],
 620                 [cf_cv_type_of_bool=`cat cf_test.out`
 621                  if test -z "$cf_cv_type_of_bool"; then
 622                    cf_cv_type_of_bool=unknown
 623                  fi],
 624                 [cf_cv_type_of_bool=unknown],
 625                 [cf_cv_type_of_bool=unknown])
 626         ])
 627         rm -f cf_test.out
 628 AC_MSG_RESULT($cf_cv_type_of_bool)
 629 if test "$cf_cv_type_of_bool" = unknown ; then
 630         case .$NCURSES_BOOL in
 631         (.auto|.) NCURSES_BOOL=unsigned;;
 632         esac
 633         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 634         cf_cv_type_of_bool=$NCURSES_BOOL
 635 fi
 636 ])dnl
 637 dnl ---------------------------------------------------------------------------
 638 dnl CF_BUILD_CC version: 8 updated: 2018/01/04 20:31:04
 639 dnl -----------
 640 dnl If we're cross-compiling, allow the user to override the tools and their
 641 dnl options.  The configure script is oriented toward identifying the host
 642 dnl compiler, etc., but we need a build compiler to generate parts of the
 643 dnl source.
 644 dnl
 645 dnl $1 = default for $CPPFLAGS
 646 dnl $2 = default for $LIBS
 647 AC_DEFUN([CF_BUILD_CC],[
 648 CF_ACVERSION_CHECK(2.52,,
 649         [AC_REQUIRE([CF_PROG_EXT])])
 650 if test "$cross_compiling" = yes ; then
 651
 652         # defaults that we might want to override
 653         : ${BUILD_CFLAGS:=''}
 654         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 655         : ${BUILD_LDFLAGS:=''}
 656         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 657         : ${BUILD_EXEEXT:='$x'}
 658         : ${BUILD_OBJEXT:='o'}
 659
 660         AC_ARG_WITH(build-cc,
 661                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 662                 [BUILD_CC="$withval"],
 663                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
 664         AC_MSG_CHECKING(for native build C compiler)
 665         AC_MSG_RESULT($BUILD_CC)
 666
 667         AC_MSG_CHECKING(for native build C preprocessor)
 668         AC_ARG_WITH(build-cpp,
 669                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 670                 [BUILD_CPP="$withval"],
 671                 [BUILD_CPP='${BUILD_CC} -E'])
 672         AC_MSG_RESULT($BUILD_CPP)
 673
 674         AC_MSG_CHECKING(for native build C flags)
 675         AC_ARG_WITH(build-cflags,
 676                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 677                 [BUILD_CFLAGS="$withval"])
 678         AC_MSG_RESULT($BUILD_CFLAGS)
 679
 680         AC_MSG_CHECKING(for native build C preprocessor-flags)
 681         AC_ARG_WITH(build-cppflags,
 682                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 683                 [BUILD_CPPFLAGS="$withval"])
 684         AC_MSG_RESULT($BUILD_CPPFLAGS)
 685
 686         AC_MSG_CHECKING(for native build linker-flags)
 687         AC_ARG_WITH(build-ldflags,
 688                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 689                 [BUILD_LDFLAGS="$withval"])
 690         AC_MSG_RESULT($BUILD_LDFLAGS)
 691
 692         AC_MSG_CHECKING(for native build linker-libraries)
 693         AC_ARG_WITH(build-libs,
 694                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 695                 [BUILD_LIBS="$withval"])
 696         AC_MSG_RESULT($BUILD_LIBS)
 697
 698         # this assumes we're on Unix.
 699         BUILD_EXEEXT=
 700         BUILD_OBJEXT=o
 701
 702         : ${BUILD_CC:='${CC}'}
 703
 704         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 705                 AC_MSG_ERROR([Cross-build requires two compilers.
 706 Use --with-build-cc to specify the native compiler.])
 707         fi
 708
 709 else
 710         : ${BUILD_CC:='${CC}'}
 711         : ${BUILD_CPP:='${CPP}'}
 712         : ${BUILD_CFLAGS:='${CFLAGS}'}
 713         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 714         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 715         : ${BUILD_LIBS:='${LIBS}'}
 716         : ${BUILD_EXEEXT:='$x'}
 717         : ${BUILD_OBJEXT:='o'}
 718 fi
 719
 720 AC_SUBST(BUILD_CC)
 721 AC_SUBST(BUILD_CPP)
 722 AC_SUBST(BUILD_CFLAGS)
 723 AC_SUBST(BUILD_CPPFLAGS)
 724 AC_SUBST(BUILD_LDFLAGS)
 725 AC_SUBST(BUILD_LIBS)
 726 AC_SUBST(BUILD_EXEEXT)
 727 AC_SUBST(BUILD_OBJEXT)
 728 ])dnl
 729 dnl ---------------------------------------------------------------------------
 730 dnl CF_CC_ENV_FLAGS version: 9 updated: 2018/07/29 18:03:26
 731 dnl ---------------
 732 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 733 dnl into CC.  This will not help with broken scripts that wrap the compiler
 734 dnl with options, but eliminates a more common category of user confusion.
 735 dnl
 736 dnl In particular, it addresses the problem of being able to run the C
 737 dnl preprocessor in a consistent manner.
 738 dnl
 739 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 740 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 741 dnl outweighs that limitation.
 742 AC_DEFUN([CF_CC_ENV_FLAGS],
 743 [
 744 # This should have been defined by AC_PROG_CC
 745 : ${CC:=cc}
 746
 747 AC_MSG_CHECKING(\$CFLAGS variable)
 748 case "x$CFLAGS" in
 749 (*-[[IUD]]*)
 750         AC_MSG_RESULT(broken)
 751         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
 752         cf_flags="$CFLAGS"
 753         CFLAGS=
 754         for cf_arg in $cf_flags
 755         do
 756                 CF_ADD_CFLAGS($cf_arg)
 757         done
 758         ;;
 759 (*)
 760         AC_MSG_RESULT(ok)
 761         ;;
 762 esac
 763
 764 AC_MSG_CHECKING(\$CC variable)
 765 case "$CC" in
 766 (*[[\ \ ]]-*)
 767         AC_MSG_RESULT(broken)
 768         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
 769         # humor him...
 770         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 771         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
 772         CC="$cf_prog"
 773         for cf_arg in $cf_flags
 774         do
 775                 case "x$cf_arg" in
 776                 (x-[[IUDfgOW]]*)
 777                         CF_ADD_CFLAGS($cf_arg)
 778                         ;;
 779                 (*)
 780                         CC="$CC $cf_arg"
 781                         ;;
 782                 esac
 783         done
 784         CF_VERBOSE(resulting CC: '$CC')
 785         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 786         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 787         ;;
 788 (*)
 789         AC_MSG_RESULT(ok)
 790         ;;
 791 esac
 792 ])dnl
 793 dnl ---------------------------------------------------------------------------
 794 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
 795 dnl ---------------
 796 dnl Determine the default configuration into which we'll install ncurses.  This
 797 dnl can be overridden by the user's command-line options.  There's two items to
 798 dnl look for:
 799 dnl     1. the prefix (e.g., /usr)
 800 dnl     2. the header files (e.g., /usr/include/ncurses)
 801 dnl We'll look for a previous installation of ncurses and use the same defaults.
 802 dnl
 803 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 804 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 805 dnl programs from a vendor's.
 806 AC_DEFUN([CF_CFG_DEFAULTS],
 807 [
 808 AC_MSG_CHECKING(for prefix)
 809 if test "x$prefix" = "xNONE" ; then
 810         case "$cf_cv_system_name" in
 811                 # non-vendor systems don't have a conflict
 812         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 813                 prefix=/usr
 814                 ;;
 815         (*)     prefix=$ac_default_prefix
 816                 ;;
 817         esac
 818 fi
 819 AC_MSG_RESULT($prefix)
 820
 821 if test "x$prefix" = "xNONE" ; then
 822 AC_MSG_CHECKING(for default include-directory)
 823 test -n "$verbose" && echo 1>&AC_FD_MSG
 824 for cf_symbol in \
 825         $includedir \
 826         $includedir/ncurses \
 827         $prefix/include \
 828         $prefix/include/ncurses \
 829         /usr/local/include \
 830         /usr/local/include/ncurses \
 831         /usr/include \
 832         /usr/include/ncurses
 833 do
 834         cf_dir=`eval echo $cf_symbol`
 835         if test -f $cf_dir/curses.h ; then
 836         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 837                 includedir="$cf_symbol"
 838                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 839                 break
 840         fi
 841         fi
 842         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 843 done
 844 AC_MSG_RESULT($includedir)
 845 fi
 846 ])dnl
 847 dnl ---------------------------------------------------------------------------
 848 dnl CF_CGETENT version: 6 updated: 2017/01/21 11:06:25
 849 dnl ----------
 850 dnl Check if the terminal-capability database functions are available.  If not,
 851 dnl ncurses has a much-reduced version.
 852 AC_DEFUN([CF_CGETENT],[
 853 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 854 AC_TRY_LINK([
 855 #include <stdlib.h>],[
 856         char temp[128];
 857         char *buf = temp;
 858         char *db_array = temp;
 859         cgetent(&buf, &db_array, "vt100");
 860         cgetcap(buf, "tc", '=');
 861         cgetmatch(buf, "tc");
 862         ],
 863         [cf_cv_cgetent=yes],
 864         [cf_cv_cgetent=no])
 865 ])
 866
 867 if test "$cf_cv_cgetent" = yes
 868 then
 869         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 870 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 871 AC_TRY_LINK([
 872 #pragma GCC diagnostic error "-Wincompatible-pointer-types-discards-qualifiers"
 873 #include <stdlib.h>],[
 874         char temp[128];
 875         char *buf = temp;
 876 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 877         const char *db_array = temp;
 878         cgetent(&buf, &db_array, "vt100");
 879 #endif
 880         cgetcap(buf, "tc", '=');
 881         cgetmatch(buf, "tc");
 882         ],
 883         [cf_cv_cgetent_const=yes],
 884         [cf_cv_cgetent_const=no])
 885 ])
 886         if test "$cf_cv_cgetent_const" = yes
 887         then
 888                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 889         fi
 890 fi
 891 ])dnl
 892 dnl ---------------------------------------------------------------------------
 893 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 894 dnl --------------
 895 dnl Check if we're accidentally using a cache from a different machine.
 896 dnl Derive the system name, as a check for reusing the autoconf cache.
 897 dnl
 898 dnl If we've packaged config.guess and config.sub, run that (since it does a
 899 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 900 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 901 dnl which is useful in cross-compiles.
 902 dnl
 903 dnl Note: we would use $ac_config_sub, but that is one of the places where
 904 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 905 AC_DEFUN([CF_CHECK_CACHE],
 906 [
 907 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 908         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 909         system_name="$host_os"
 910 else
 911         system_name="`(uname -s -r) 2>/dev/null`"
 912         if test -z "$system_name" ; then
 913                 system_name="`(hostname) 2>/dev/null`"
 914         fi
 915 fi
 916 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 917 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 918
 919 test -z "$system_name" && system_name="$cf_cv_system_name"
 920 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 921
 922 if test ".$system_name" != ".$cf_cv_system_name" ; then
 923         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 924         AC_MSG_ERROR("Please remove config.cache and try again.")
 925 fi
 926 ])dnl
 927 dnl ---------------------------------------------------------------------------
 928 dnl CF_CHECK_ENVIRON version: 3 updated: 2010/05/26 16:44:57
 929 dnl ----------------
 930 dnl Check for data that is usually declared in <unistd.h>, e.g., the 'environ'
 931 dnl variable.  Define a DECL_xxx symbol if we must declare it ourselves.
 932 dnl
 933 dnl $1 = the name to check
 934 dnl $2 = the assumed type
 935 AC_DEFUN([CF_CHECK_ENVIRON],
 936 [
 937 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 938     AC_TRY_COMPILE([
 939 #ifdef HAVE_STDLIB_H
 940 #include <stdlib.h>
 941 #endif
 942 #include <unistd.h> ],
 943     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 944     [cf_cv_dcl_$1=yes],
 945     [cf_cv_dcl_$1=no])
 946 ])
 947
 948 if test "$cf_cv_dcl_$1" = no ; then
 949     CF_UPPER(cf_result,decl_$1)
 950     AC_DEFINE_UNQUOTED($cf_result)
 951 fi
 952
 953 # It's possible (for near-UNIX clones) that the data doesn't exist
 954 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 955 ])dnl
 956 dnl ---------------------------------------------------------------------------
 957 dnl CF_CHECK_ERRNO version: 12 updated: 2015/04/18 08:56:57
 958 dnl --------------
 959 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 960 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 961 dnl ourselves.
 962 dnl
 963 dnl $1 = the name to check
 964 dnl $2 = the assumed type
 965 AC_DEFUN([CF_CHECK_ERRNO],
 966 [
 967 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 968         AC_TRY_COMPILE([
 969 #ifdef HAVE_STDLIB_H
 970 #include <stdlib.h>
 971 #endif
 972 #include <stdio.h>
 973 #include <sys/types.h>
 974 #include <errno.h> ],
 975         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 976         [cf_cv_dcl_$1=yes],
 977         [cf_cv_dcl_$1=no])
 978 ])
 979
 980 if test "$cf_cv_dcl_$1" = no ; then
 981         CF_UPPER(cf_result,decl_$1)
 982         AC_DEFINE_UNQUOTED($cf_result)
 983 fi
 984
 985 # It's possible (for near-UNIX clones) that the data doesn't exist
 986 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 987 ])dnl
 988 dnl ---------------------------------------------------------------------------
 989 dnl CF_CHECK_EXTERN_DATA version: 4 updated: 2015/04/18 08:56:57
 990 dnl --------------------
 991 dnl Check for existence of external data in the current set of libraries.  If
 992 dnl we can modify it, it's real enough.
 993 dnl $1 = the name to check
 994 dnl $2 = its type
 995 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 996 [
 997 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 998         AC_TRY_LINK([
 999 #undef $1
1000 extern $2 $1;
1001 ],
1002         [$1 = 2],
1003         [cf_cv_have_$1=yes],
1004         [cf_cv_have_$1=no])
1005 ])
1006
1007 if test "$cf_cv_have_$1" = yes ; then
1008         CF_UPPER(cf_result,have_$1)
1009         AC_DEFINE_UNQUOTED($cf_result)
1010 fi
1011
1012 ])dnl
1013 dnl ---------------------------------------------------------------------------
1014 dnl CF_CHECK_GETENV version: 1 updated: 2019/06/23 15:28:15
1015 dnl ---------------
1016 dnl Check if repeated getenv calls return the same pointer, e.g., it does not
1017 dnl discard the previous pointer when returning a new one.
1018 AC_DEFUN([CF_CHECK_GETENV],
1019 [
1020 AC_REQUIRE([CF_CHECK_ENVIRON])
1021 AC_CHECK_FUNC( getenv, ,, AC_MSG_ERROR(getenv not found) )
1022 AC_CHECK_FUNCS( putenv setenv strdup )
1023 AC_CACHE_CHECK(if getenv returns consistent values,cf_cv_consistent_getenv,[
1024 AC_TRY_RUN([
1025 #include <stdlib.h>
1026 #include <unistd.h>
1027 #include <stdio.h>
1028 #include <string.h>
1029 #include <sys/types.h>
1030
1031 #if defined(HAVE_ENVIRON) && defined(DECL_ENVIRON) && !defined(environ)
1032 extern char **environ;  /* POSIX, but some systems are not... */
1033 #endif
1034
1035 #if defined(HAVE_STRDUP)
1036 #define str_alloc(s) strdup(s)
1037 #else
1038 #define str_alloc(s) strcpy(malloc(strlen(s) + 1, s))
1039 #endif
1040
1041 static void set_value(const char *name, const char *value)
1042 {
1043 #if defined(HAVE_SETENV)
1044         setenv(name, value, 1);
1045 #elif defined(HAVE_PUTENV)
1046         char buffer[1024];
1047         sprintf(buffer, "%s=%s", name, value);
1048         putenv(str_alloc(buffer));
1049 #else
1050 #error neither putenv/setenv found
1051 #endif
1052 }
1053 int main(void)
1054 {
1055         int pass;
1056         size_t numenv, limit, j;
1057         char **mynames;
1058         char **myvalues;
1059         char **mypointer;
1060         char *equals;
1061         for (numenv = 0; environ[numenv]; ++numenv) ;
1062         limit = numenv + 10;
1063         mynames = (char **) calloc(limit + 1, sizeof(char *));
1064         myvalues = (char **) calloc(limit + 1, sizeof(char *));
1065         mypointer = (char **) calloc(limit + 1, sizeof(char *));
1066 #if defined(HAVE_ENVIRON)
1067         for (j = 0; environ[j]; ++j) {
1068                 mynames[j] = str_alloc(environ[j]);
1069                 equals = strchr(mynames[j], '=');
1070                 if (equals != 0) {
1071                         *equals++ = '\0';
1072                         myvalues[j] = str_alloc(equals);
1073                 } else {
1074                         myvalues[j] = str_alloc("");
1075                 }
1076         }
1077 #endif
1078         for (j = numenv; j < limit; ++j) {
1079                 char name[80];
1080                 char value[80];
1081                 size_t found;
1082                 size_t k = 0;
1083                 do {
1084                         size_t jk;
1085                         found = 0;
1086                         sprintf(name, "TERM%lu", (unsigned long) k);
1087                         for (jk = 0; jk < j; ++jk) {
1088                                 if (!strcmp(name, mynames[jk])) {
1089                                         found = 1;
1090                                         ++k;
1091                                         break;
1092                                 }
1093                         }
1094                 } while (found);
1095                 sprintf(value, "%lu:%p", (unsigned long) k, &mynames[j]);
1096                 set_value(name, value);
1097                 mynames[j] = str_alloc(name);
1098                 myvalues[j] = str_alloc(value);
1099         }
1100         for (pass = 0; pass < 3; ++pass) {
1101                 for (j = 0; j < limit; ++j) {
1102                         char *value = getenv(mynames[j]);
1103                         if (pass) {
1104                                 if (value == 0) {
1105                                         fprintf(stderr, "getenv returned null for %s\n", mynames[j]);
1106                                         ${cf_cv_main_return:-return}(1);
1107                                 } else if (value != mypointer[j]) {
1108                                         fprintf(stderr, "getenv returned different pointer for %s\n", mynames[j]);
1109                                         ${cf_cv_main_return:-return}(1);
1110                                 } else if (strcmp(value, myvalues[j])) {
1111                                         fprintf(stderr, "getenv returned different value for %s\n", mynames[j]);
1112                                         ${cf_cv_main_return:-return}(1);
1113                                 }
1114                         } else {
1115                                 size_t k;
1116                                 mypointer[j] = value;
1117                                 for (k = 0; k < j; ++k) {
1118                                         if (mypointer[j] == mypointer[k]) {
1119                                                 fprintf(stderr, "getenv returned same pointer for %s and %s\n", mynames[j], mynames[k]);
1120                                                 ${cf_cv_main_return:-return}(1);
1121                                         }
1122                                 }
1123                         }
1124                 }
1125         }
1126         ${cf_cv_main_return:-return}(0);
1127 }
1128 ],
1129 [cf_cv_consistent_getenv=yes],
1130 [cf_cv_consistent_getenv=no],
1131 [cf_cv_consistent_getenv=unknown])
1132 ])
1133
1134 if test "x$cf_cv_consistent_getenv" = xno
1135 then
1136         AC_DEFINE(HAVE_CONSISTENT_GETENV,1,[Define to 1 if getenv repeatably returns the same value for a given name])
1137 fi
1138 ])dnl
1139 dnl ---------------------------------------------------------------------------
1140 dnl CF_CHECK_GNAT_VERSION version: 1 updated: 2019/09/21 18:08:42
1141 dnl ---------------------
1142 AC_DEFUN([CF_CHECK_GNAT_VERSION],
1143 [
1144 AC_REQUIRE([CF_GNAT_VERSION])
1145 case $cf_gnat_version in
1146 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
1147         cf_cv_prog_gnat_correct=yes
1148         ;;
1149 (*)
1150         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1151         cf_cv_prog_gnat_correct=no
1152         ;;
1153 esac
1154 ])
1155 dnl ---------------------------------------------------------------------------
1156 dnl CF_CHECK_GPM_WGETCH version: 3 updated: 2017/01/21 11:06:25
1157 dnl -------------------
1158 dnl Check if GPM is already linked with curses.  If so - and if the linkage
1159 dnl is not "weak" - warn about this because it can create problems linking
1160 dnl applications with ncurses.
1161 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
1162 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
1163
1164 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
1165 cf_cv_check_gpm_wgetch=unknown
1166 if test "$cross_compiling" != yes ; then
1167
1168 cat >conftest.$ac_ext <<CF_EOF
1169 #include <gpm.h>
1170 int main(void)
1171 {
1172         Gpm_Wgetch();
1173         ${cf_cv_main_return:-return}(0);
1174 }
1175 CF_EOF
1176
1177         cf_save_LIBS="$LIBS"
1178         # This only works if we can look at the symbol table.  If a shared
1179         # library is stripped for install, we cannot use that.  So we're forced
1180         # to rely on the static library, noting that some packagers may not
1181         # include it.
1182         LIBS="-static -lgpm -dynamic $LIBS"
1183         if AC_TRY_EVAL(ac_compile) ; then
1184                 if AC_TRY_EVAL(ac_link) ; then
1185                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
1186                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
1187                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
1188                 fi
1189         fi
1190         rm -rf conftest*
1191         LIBS="$cf_save_LIBS"
1192 fi
1193 ])
1194
1195 if test "$cf_cv_check_gpm_wgetch" != yes ; then
1196         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
1197 fi
1198 ])])dnl
1199 dnl ---------------------------------------------------------------------------
1200 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
1201 dnl ------------------------
1202 dnl Show the version of libtool
1203 dnl
1204 dnl Save the version in a cache variable - this is not entirely a good thing,
1205 dnl but the version string from libtool is very ugly, and for bug reports it
1206 dnl might be useful to have the original string.
1207 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
1208 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
1209 then
1210         AC_MSG_CHECKING(version of $LIBTOOL)
1211         CF_LIBTOOL_VERSION
1212         AC_MSG_RESULT($cf_cv_libtool_version)
1213         if test -z "$cf_cv_libtool_version" ; then
1214                 AC_MSG_ERROR(This is not GNU libtool)
1215         fi
1216 else
1217         AC_MSG_ERROR(GNU libtool has not been found)
1218 fi
1219 ])dnl
1220 dnl ---------------------------------------------------------------------------
1221 dnl CF_CHECK_WCHAR_H version: 2 updated: 2017/01/21 11:06:25
1222 dnl ----------------
1223 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
1224 AC_DEFUN([CF_CHECK_WCHAR_H],[
1225 AC_CHECK_HEADERS( \
1226 wchar.h \
1227 wctype.h \
1228 )
1229 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1230 AC_TRY_COMPILE(
1231 [
1232 #include <stdlib.h>
1233 #ifdef HAVE_WCHAR_H
1234 #include <wchar.h>
1235 #endif
1236 #ifdef HAVE_WCTYPE_H
1237 #include <wctype.h>
1238 #endif
1239 ],[
1240         wint_t foo = 0;
1241         int bar = iswpunct(foo)],
1242         [cf_cv_wchar_h_okay=yes],
1243         [cf_cv_wchar_h_okay=no])])
1244
1245 if test $cf_cv_wchar_h_okay = no
1246 then
1247         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1248 fi
1249 ])dnl
1250 dnl ---------------------------------------------------------------------------
1251 dnl CF_CHECK_WCWIDTH_GRAPHICS version: 1 updated: 2015/12/19 17:47:56
1252 dnl -------------------------
1253 dnl Most "modern" terminal emulators are based to some degree on VT100, and
1254 dnl should support line-drawing.  Even with Unicode.  There is a problem.
1255 dnl
1256 dnl While most of the VT100 graphics characters were incorporated into Unicode,
1257 dnl all of those were combined into a page of useful graphics characters.
1258 dnl
1259 dnl So far, so good.
1260 dnl
1261 dnl However, while they are useful, there are other considerations.  CJK
1262 dnl is (because of poor device resolution) often rendered as double-width
1263 dnl characters.  So... for these generally-useful characters, what should
1264 dnl be the width (to make them consistent with adjacent characters)?
1265 dnl
1266 dnl The obvious choice would have been to make this locale-dependent, and use
1267 dnl wcwidth() to tell applications what the actual width is.  That was too
1268 dnl obvious.  Instead, we have a slew of "ambiguous-width" characters.
1269 dnl See for example
1270 dnl             http://www.unicode.org/reports/tr11/tr11-29.html
1271 dnl             http://www.cl.cam.ac.uk/~mgk25/ucs/scw-proposal.html
1272 dnl
1273 dnl The EastAsianWidth-6.2.0.txt file from the Unicode organization lists
1274 dnl more than 22,000 characters, with 1281 of those as ambiguous-width.  For
1275 dnl instance, it lists half (44/96) of the Latin-1 characters as
1276 dnl ambiguous-width.  Also, all of the box-characters at 0x2500 are ambiguous.
1277 dnl
1278 dnl What this means for the implementor is that on some systems wcwidth() can
1279 dnl give bad advice.  On Solaris, some of the ambiguous widths are returned as
1280 dnl 1 (the Latin-1 characters), while others are returned as 2 (line-drawing
1281 dnl characters).  These do not necessarily match the behavior of the terminal
1282 dnl emulator.  xterm, for instance, does an optional startup check to find if
1283 dnl this problem (or similar) exists with the system's locale tables, rejecting
1284 dnl them if they are too unreliable.
1285 AC_DEFUN([CF_CHECK_WCWIDTH_GRAPHICS],[
1286 AC_CACHE_CHECK(if wcwidth agrees graphics are single-width, cf_cv_wcwidth_graphics,[
1287 cat >conftest.in <<CF_EOF
1288 -       VT100 symbols
1289 0x250c  upper left corner
1290 0x2514  lower left corner
1291 0x2510  upper right corner
1292 0x2518  lower right corner
1293 0x251c  tee pointing left
1294 0x2524  tee pointing right
1295 0x2534  tee pointing up
1296 0x252c  tee pointing down
1297 0x2500  horizontal line
1298 0x2502  vertical line
1299 0x253c  large plus or crossover
1300 0x23ba  scan line 1
1301 0x23bd  scan line 9
1302 0x25c6  diamond
1303 0x2592  checker board (stipple)
1304 0x00b0  degree symbol
1305 0x00b1  plus/minus
1306 0x00b7  bullet
1307 -       Teletype 5410v1 symbols
1308 0x2190  arrow pointing left
1309 0x2192  arrow pointing right
1310 0x2193  arrow pointing down
1311 0x2191  arrow pointing up
1312 0x2592  board of squares
1313 0x2603  lantern symbol
1314 0x25ae  solid square block
1315 -       these defaults were invented for ncurses
1316 0x23bb  scan line 3
1317 0x23bc  scan line 7
1318 0x2264  less-than-or-equal-to
1319 0x2265  greater-than-or-equal-to
1320 0x03c0  greek pi
1321 0x2260  not-equal
1322 0x00a3  pound-sterling symbol
1323 -       thick-line-drawing
1324 0x250f  upper left corner
1325 0x2517  lower left corner
1326 0x2513  upper right corner
1327 0x251b  lower right corner
1328 0x2523  tee pointing left
1329 0x252b  tee pointing right
1330 0x253b  tee pointing up
1331 0x2533  tee pointing down
1332 0x2501  horizontal line
1333 0x2503  vertical line
1334 0x254b  large plus or crossover
1335 -       double-line-drawing
1336 0x2554  upper left corner
1337 0x255a  lower left corner
1338 0x2557  upper right corner
1339 0x255d  lower right corner
1340 0x2563  tee pointing left
1341 0x2560  tee pointing right
1342 0x2569  tee pointing up
1343 0x2566  tee pointing down
1344 0x2550  horizontal line
1345 0x2551  vertical line
1346 0x256c  large plus or crossover
1347 CF_EOF
1348 AC_TRY_RUN([
1349 #include <locale.h>
1350 #include <stdio.h>
1351 #include <wchar.h>
1352
1353 #define MY_LEN 80
1354
1355 int
1356 main(void)
1357 {
1358         FILE *fp;
1359         int value;
1360         char buffer[MY_LEN + 1];
1361         char notes[MY_LEN + 1];
1362         int totals = 0;
1363         int passed = 0;
1364
1365         if (setlocale(LC_ALL, "en_US.UTF8") ||
1366                 setlocale(LC_ALL, "en_US.UTF-8") ||
1367                 setlocale(LC_ALL, "en_US.utf8") ||
1368                 setlocale(LC_ALL, "en_US.utf-8")) {
1369                 if ((fp = fopen("conftest.in", "r")) != 0) {
1370                         while (fgets(buffer, MY_LEN, fp) != 0) {
1371                                 if (*buffer == '-') {
1372                                         fprintf(stderr, "\t%s", buffer);
1373                                 } else if (sscanf(buffer, "%x %s", &value, notes) == 2) {
1374                                         ++totals;
1375                                         if (wcwidth(value) == 1)
1376                                                 ++passed;
1377                                         fprintf(stderr, "%d\t%s", wcwidth(value), buffer);
1378                                 } else {
1379                                         fprintf(stderr, "?\t%s", buffer);
1380                                 }
1381                         }
1382                 }
1383         }
1384         fprintf(stderr, "%d/%d passed wcwidth/graphics check\n", passed, totals);
1385         return (totals == passed) ? 0 : 1;
1386 }
1387 ],
1388 [cf_cv_wcwidth_graphics=yes],
1389 [cf_cv_wcwidth_graphics=no],
1390 [cf_cv_wcwidth_graphics=unknown])
1391 ])
1392 ])dnl
1393 dnl ---------------------------------------------------------------------------
1394 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
1395 dnl -----------------
1396 dnl Check if the given compiler is really clang.  clang's C driver defines
1397 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1398 dnl not ignore some gcc options.
1399 dnl
1400 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1401 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1402 dnl the wrappers for gcc and g++ warnings.
1403 dnl
1404 dnl $1 = GCC (default) or GXX
1405 dnl $2 = CLANG_COMPILER (default)
1406 dnl $3 = CFLAGS (default) or CXXFLAGS
1407 AC_DEFUN([CF_CLANG_COMPILER],[
1408 ifelse([$2],,CLANG_COMPILER,[$2])=no
1409
1410 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1411         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1412         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1413         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
1414         AC_TRY_COMPILE([],[
1415 #ifdef __clang__
1416 #else
1417 make an error
1418 #endif
1419 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1420 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
1421 ],[])
1422         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1423         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1424 fi
1425 ])
1426 dnl ---------------------------------------------------------------------------
1427 dnl CF_CONST_X_STRING version: 1 updated: 2019/04/08 17:50:29
1428 dnl -----------------
1429 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
1430 dnl character-strings.
1431 dnl
1432 dnl It is ambiguous because the specification accommodated the pre-ANSI
1433 dnl compilers bundled by more than one vendor in lieu of providing a standard C
1434 dnl compiler other than by costly add-ons.  Because of this, the specification
1435 dnl did not take into account the use of const for telling the compiler that
1436 dnl string literals would be in readonly memory.
1437 dnl
1438 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
1439 dnl let the compiler decide how to represent Xt's strings which were #define'd.
1440 dnl That does not solve the problem of using the block of Xt's strings which
1441 dnl are compiled into the library (and is less efficient than one might want).
1442 dnl
1443 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
1444 dnl when compiling the library and compiling using the library, to tell the
1445 dnl compiler that String is const.
1446 AC_DEFUN([CF_CONST_X_STRING],
1447 [
1448 AC_TRY_COMPILE(
1449 [
1450 #include <stdlib.h>
1451 #include <X11/Intrinsic.h>
1452 ],
1453 [String foo = malloc(1)],[
1454
1455 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
1456         AC_TRY_COMPILE(
1457                 [
1458 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
1459 #undef  XTSTRINGDEFINES /* X11R5 and later */
1460 #include <stdlib.h>
1461 #include <X11/Intrinsic.h>
1462                 ],[String foo = malloc(1); *foo = 0],[
1463                         cf_cv_const_x_string=no
1464                 ],[
1465                         cf_cv_const_x_string=yes
1466                 ])
1467 ])
1468
1469 case $cf_cv_const_x_string in
1470 (no)
1471         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
1472         ;;
1473 (*)
1474         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
1475         ;;
1476 esac
1477
1478 ])
1479 ])dnl
1480 dnl ---------------------------------------------------------------------------
1481 dnl CF_CPP_PARAM_INIT version: 7 updated: 2017/01/21 11:06:25
1482 dnl -----------------
1483 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1484 dnl is a late feature for the standard and is not in some recent compilers
1485 dnl (1999/9/11).
1486 AC_DEFUN([CF_CPP_PARAM_INIT],
1487 [
1488 if test -n "$CXX"; then
1489 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1490         AC_LANG_SAVE
1491         AC_LANG_CPLUSPLUS
1492         AC_TRY_RUN([
1493 class TEST {
1494 private:
1495         int value;
1496 public:
1497         TEST(int x = 1);
1498         ~TEST();
1499 };
1500
1501 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1502 {
1503         value = x;
1504 }
1505 int main(void) { }
1506 ],
1507         [cf_cv_cpp_param_init=yes],
1508         [cf_cv_cpp_param_init=no],
1509         [cf_cv_cpp_param_init=unknown])
1510         AC_LANG_RESTORE
1511 ])
1512 fi
1513 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1514 ])dnl
1515 dnl ---------------------------------------------------------------------------
1516 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1517 dnl ------------------
1518 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1519 dnl not be supported in g++ before 3.0
1520 AC_DEFUN([CF_CPP_STATIC_CAST],
1521 [
1522 if test -n "$CXX"; then
1523
1524 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1525         AC_LANG_SAVE
1526         AC_LANG_CPLUSPLUS
1527
1528         AC_TRY_COMPILE([
1529 class NCursesPanel
1530 {
1531 public:
1532   NCursesPanel(int nlines,
1533                int ncols,
1534                int begin_y = 0,
1535                int begin_x = 0)
1536   {
1537   }
1538   NCursesPanel();
1539   ~NCursesPanel();
1540 };
1541
1542 template<class T> class NCursesUserPanel : public NCursesPanel
1543 {
1544 public:
1545   NCursesUserPanel (int nlines,
1546                     int ncols,
1547                     int begin_y = 0,
1548                     int begin_x = 0,
1549                     const T* p_UserData = static_cast<T*>(0))
1550     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1551   {
1552   };
1553   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1554   {
1555   };
1556
1557   virtual ~NCursesUserPanel() {};
1558 };
1559 ],[
1560         const char* p_UserData = static_cast<char*>(0)],
1561         [cf_cv_cpp_static_cast=yes],
1562         [cf_cv_cpp_static_cast=no])
1563
1564         AC_LANG_RESTORE
1565 ])
1566
1567 fi
1568
1569 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1570 ])dnl
1571 dnl ---------------------------------------------------------------------------
1572 dnl CF_CXX_AR_FLAGS version: 2 updated: 2015/04/17 21:13:04
1573 dnl ---------------
1574 dnl Setup special archiver flags for given compilers.
1575 AC_DEFUN([CF_CXX_AR_FLAGS],[
1576         CXX_AR='$(AR)'
1577         CXX_ARFLAGS='$(ARFLAGS)'
1578         case $cf_cv_system_name in
1579         (irix*)
1580             if test "$GXX" != yes ; then
1581                 CXX_AR='$(CXX)'
1582                 CXX_ARFLAGS='-ar -o'
1583             fi
1584             ;;
1585         (sco3.2v5*)
1586             CXXLDFLAGS="-u main"
1587             ;;
1588         (solaris2*)
1589             if test "$GXX" != yes ; then
1590                 CXX_AR='$(CXX)'
1591                 CXX_ARFLAGS='-xar -o'
1592             fi
1593             ;;
1594         esac
1595         AC_SUBST(CXXLDFLAGS)
1596         AC_SUBST(CXX_AR)
1597         AC_SUBST(CXX_ARFLAGS)
1598 ])dnl
1599 dnl ---------------------------------------------------------------------------
1600 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1601 dnl -------------------------
1602 dnl For c++, check if iostream uses "std::" namespace.
1603 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1604 AC_CHECK_HEADERS(iostream)
1605 if test x"$ac_cv_header_iostream" = xyes ; then
1606         AC_MSG_CHECKING(if iostream uses std-namespace)
1607         AC_TRY_COMPILE([
1608 #include <iostream>
1609 using std::endl;
1610 using std::cerr;],[
1611 cerr << "testing" << endl;
1612 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1613         AC_MSG_RESULT($cf_iostream_namespace)
1614         if test "$cf_iostream_namespace" = yes ; then
1615                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1616         fi
1617 fi
1618 ])dnl
1619 dnl ---------------------------------------------------------------------------
1620 dnl CF_C_INLINE version: 6 updated: 2019/09/07 13:38:36
1621 dnl -----------
1622 dnl Check if the C compiler supports "inline".
1623 dnl $1 is the name of a shell variable to set if inline is supported
1624 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1625 AC_DEFUN([CF_C_INLINE],[
1626 AC_REQUIRE([CF_GCC_VERSION])
1627 AC_C_INLINE
1628 $1=
1629 if test "$ac_cv_c_inline" != no ; then
1630         $1=inline
1631         if test "$INTEL_COMPILER" = yes
1632         then
1633                 :
1634         elif test "$CLANG_COMPILER" = yes
1635         then
1636                 :
1637         elif test "$GCC" = yes
1638         then
1639                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1640                 cf_save_CFLAGS=$CFLAGS
1641                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1642                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1643                 [${cf_cv_main_return:-return} foo()],
1644                 [cf_cv_gcc_inline=yes],
1645                 [cf_cv_gcc_inline=no])
1646                 CFLAGS=$cf_save_CFLAGS
1647                 ])
1648                 if test "$cf_cv_gcc_inline" = yes ; then
1649                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1650                 fi
1651         fi
1652 fi
1653 AC_SUBST($1)
1654 ])dnl
1655 dnl ---------------------------------------------------------------------------
1656 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1657 dnl ----------
1658 dnl "dirname" is not portable, so we fake it with a shell script.
1659 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1660 dnl ---------------------------------------------------------------------------
1661 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1662 dnl ---------------
1663 AC_DEFUN([CF_DIRS_TO_MAKE],
1664 [
1665 DIRS_TO_MAKE="lib"
1666 for cf_item in $cf_list_models
1667 do
1668         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1669         for cf_item2 in $DIRS_TO_MAKE
1670         do
1671                 test $cf_item2 = $cf_subdir && break
1672         done
1673         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1674 done
1675 for cf_dir in $DIRS_TO_MAKE
1676 do
1677         test ! -d $cf_dir && mkdir $cf_dir
1678 done
1679 AC_SUBST(DIRS_TO_MAKE)
1680 ])dnl
1681 dnl ---------------------------------------------------------------------------
1682 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1683 dnl ---------------
1684 dnl You can always use "make -n" to see the actual options, but it's hard to
1685 dnl pick out/analyze warning messages when the compile-line is long.
1686 dnl
1687 dnl Sets:
1688 dnl     ECHO_LT - symbol to control if libtool is verbose
1689 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1690 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1691 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1692 dnl     ECHO_CC - symbol to put before any "cc" line
1693 dnl
1694 AC_DEFUN([CF_DISABLE_ECHO],[
1695 AC_MSG_CHECKING(if you want to see long compiling messages)
1696 CF_ARG_DISABLE(echo,
1697         [  --disable-echo          do not display "compiling" commands],
1698         [
1699         ECHO_LT='--silent'
1700         ECHO_LD='@echo linking [$]@;'
1701         RULE_CC='@echo compiling [$]<'
1702         SHOW_CC='@echo compiling [$]@'
1703         ECHO_CC='@'
1704 ],[
1705         ECHO_LT=''
1706         ECHO_LD=''
1707         RULE_CC=''
1708         SHOW_CC=''
1709         ECHO_CC=''
1710 ])
1711 AC_MSG_RESULT($enableval)
1712 AC_SUBST(ECHO_LT)
1713 AC_SUBST(ECHO_LD)
1714 AC_SUBST(RULE_CC)
1715 AC_SUBST(SHOW_CC)
1716 AC_SUBST(ECHO_CC)
1717 ])dnl
1718 dnl ---------------------------------------------------------------------------
1719 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1720 dnl ------------------------
1721 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1722 AC_MSG_CHECKING(if we want to use GNAT projects)
1723 CF_ARG_DISABLE(gnat-projects,
1724         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1725         [enable_gnat_projects=no],
1726         [enable_gnat_projects=yes])
1727 AC_MSG_RESULT($enable_gnat_projects)
1728 ])dnl
1729 dnl ---------------------------------------------------------------------------
1730 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1731 dnl ----------------
1732 dnl Combine no-leak checks with the libraries or tools that are used for the
1733 dnl checks.
1734 AC_DEFUN([CF_DISABLE_LEAKS],[
1735
1736 AC_REQUIRE([CF_WITH_DMALLOC])
1737 AC_REQUIRE([CF_WITH_DBMALLOC])
1738 AC_REQUIRE([CF_WITH_VALGRIND])
1739
1740 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1741 AC_ARG_ENABLE(leaks,
1742         [  --disable-leaks         test: free permanent memory, analyze leaks],
1743         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1744         : ${with_no_leaks:=no})
1745 AC_MSG_RESULT($with_no_leaks)
1746
1747 if test "$with_no_leaks" = yes ; then
1748         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1749         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1750 fi
1751 ])dnl
1752 dnl ---------------------------------------------------------------------------
1753 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
1754 dnl --------------------------
1755 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1756 dnl the older "-version-info" feature.  The newer feature allows us to use
1757 dnl version numbering on shared libraries which make them compatible with
1758 dnl various systems.
1759 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1760 [
1761 AC_MSG_CHECKING(if libtool -version-number should be used)
1762 CF_ARG_DISABLE(libtool-version,
1763         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1764         [cf_libtool_version=no],
1765         [cf_libtool_version=yes])
1766 AC_MSG_RESULT($cf_libtool_version)
1767
1768 if test "$cf_libtool_version" = yes ; then
1769         LIBTOOL_VERSION="-version-number"
1770 else
1771         LIBTOOL_VERSION="-version-info"
1772         case "x$VERSION" in
1773         (x)
1774                 AC_MSG_WARN(VERSION was not set)
1775                 ;;
1776         (x*.*.*)
1777                 ABI_VERSION="$VERSION"
1778                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1779                 ;;
1780         (x*:*:*)
1781                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
1782                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1783                 ;;
1784         (*)
1785                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
1786                 ;;
1787         esac
1788 fi
1789
1790 AC_SUBST(ABI_VERSION)
1791 AC_SUBST(LIBTOOL_VERSION)
1792 ])dnl
1793 dnl ---------------------------------------------------------------------------
1794 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1795 dnl ---------------------
1796 dnl The rpath-hack makes it simpler to build programs, particularly with the
1797 dnl *BSD ports which may have essential libraries in unusual places.  But it
1798 dnl can interfere with building an executable for the base system.  Use this
1799 dnl option in that case.
1800 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1801 [
1802 AC_MSG_CHECKING(if rpath-hack should be disabled)
1803 CF_ARG_DISABLE(rpath-hack,
1804         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1805         [cf_disable_rpath_hack=yes],
1806         [cf_disable_rpath_hack=no])
1807 AC_MSG_RESULT($cf_disable_rpath_hack)
1808 if test "$cf_disable_rpath_hack" = no ; then
1809         CF_RPATH_HACK
1810 fi
1811 ])
1812 dnl ---------------------------------------------------------------------------
1813 dnl CF_ENABLE_PC_FILES version: 13 updated: 2015/11/01 05:27:39
1814 dnl ------------------
1815 dnl This is the "--enable-pc-files" option, which is available if there is a
1816 dnl pkg-config configuration on the local machine.
1817 AC_DEFUN([CF_ENABLE_PC_FILES],[
1818 AC_REQUIRE([CF_PKG_CONFIG])
1819 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1820
1821 if test "x$PKG_CONFIG" != xnone
1822 then
1823         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1824 else
1825         AC_MSG_CHECKING(if we should install .pc files)
1826 fi
1827
1828 AC_ARG_ENABLE(pc-files,
1829         [  --enable-pc-files       generate and install .pc files for pkg-config],
1830         [enable_pc_files=$enableval],
1831         [enable_pc_files=no])
1832 AC_MSG_RESULT($enable_pc_files)
1833
1834 if test "x$enable_pc_files" != xno
1835 then
1836         MAKE_PC_FILES=
1837         case "x$PKG_CONFIG_LIBDIR" in
1838         (xno|xyes)
1839                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
1840                 ;;
1841         (*)
1842                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1843                 ;;
1844         esac
1845 else
1846         MAKE_PC_FILES="#"
1847 fi
1848 AC_SUBST(MAKE_PC_FILES)
1849 ])dnl
1850 dnl ---------------------------------------------------------------------------
1851 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1852 dnl ---------------
1853 dnl Check if the rpath option should be used, setting cache variable
1854 dnl cf_cv_enable_rpath if so.
1855 AC_DEFUN([CF_ENABLE_RPATH],
1856 [
1857 AC_MSG_CHECKING(if rpath option should be used)
1858 AC_ARG_ENABLE(rpath,
1859 [  --enable-rpath          use rpath option when generating shared libraries],
1860 [cf_cv_enable_rpath=$enableval],
1861 [cf_cv_enable_rpath=no])
1862 AC_MSG_RESULT($cf_cv_enable_rpath)
1863 ])dnl
1864 dnl ---------------------------------------------------------------------------
1865 dnl CF_ENABLE_STRING_HACKS version: 5 updated: 2016/10/08 17:34:11
1866 dnl ----------------------
1867 dnl On a few platforms, the compiler and/or loader nags with untruthful
1868 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1869 dnl and implying that most uses of the recommended alternatives are correct.
1870 dnl
1871 dnl Factually speaking, no one has actually counted the number of uses of these
1872 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1873 dnl instances are meaningless compared to the hundreds of millions of lines of
1874 dnl existing C code.
1875 dnl
1876 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1877 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1878 dnl standard - but evolved through phases, and older implementations are likely
1879 dnl to yield surprising results, as documented in manpages on various systems.
1880 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1881 [
1882 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1883 AC_ARG_ENABLE(string-hacks,
1884         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1885         [with_string_hacks=$enableval],
1886         [with_string_hacks=no])
1887 AC_MSG_RESULT($with_string_hacks)
1888
1889 if test "x$with_string_hacks" = "xyes"; then
1890         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1891         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1892         AC_CHECK_FUNC(strlcat,[
1893                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1894                 ],[
1895                 AC_CHECK_LIB(bsd,strlcat,[
1896                         CF_ADD_LIB(bsd)
1897                         AC_CHECK_HEADERS(bsd/string.h)
1898                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1899                         ])
1900                 ])
1901         AC_CHECK_FUNCS( strlcpy snprintf )
1902 fi
1903 ])dnl
1904 dnl ---------------------------------------------------------------------------
1905 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1906 dnl --------
1907 dnl Check if 'errno' is declared in <errno.h>
1908 AC_DEFUN([CF_ERRNO],
1909 [
1910 CF_CHECK_ERRNO(errno)
1911 ])dnl
1912 dnl ---------------------------------------------------------------------------
1913 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1914 dnl ---------------
1915 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1916 dnl math.h and builtin.h, only for ncurses
1917 AC_DEFUN([CF_ETIP_DEFINES],
1918 [
1919 AC_MSG_CHECKING(for special defines needed for etip.h)
1920 cf_save_CXXFLAGS="$CXXFLAGS"
1921 cf_result="none"
1922
1923 # etip.h includes ncurses.h which includes ncurses_dll.h
1924 # But ncurses_dll.h is generated - fix here.
1925 test -d include || mkdir include
1926 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1927
1928 for cf_math in "" MATH_H
1929 do
1930 for cf_excp in "" MATH_EXCEPTION
1931 do
1932         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1933         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1934         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1935 AC_TRY_COMPILE([
1936 #include <etip.h.in>
1937 ],[],[
1938         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1939         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1940         cf_result="$cf_math $cf_excp"
1941         break 2
1942 ],[])
1943 done
1944 done
1945 AC_MSG_RESULT($cf_result)
1946 CXXFLAGS="$cf_save_CXXFLAGS"
1947 ])
1948 dnl ---------------------------------------------------------------------------
1949 dnl CF_FIND_LINKAGE version: 21 updated: 2018/06/20 20:23:13
1950 dnl ---------------
1951 dnl Find a library (specifically the linkage used in the code fragment),
1952 dnl searching for it if it is not already in the library path.
1953 dnl See also CF_ADD_SEARCHPATH.
1954 dnl
1955 dnl Parameters (4-on are optional):
1956 dnl     $1 = headers for library entrypoint
1957 dnl     $2 = code fragment for library entrypoint
1958 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1959 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1960 dnl     $5 = action to perform if not successful
1961 dnl     $6 = module name, if not the same as the library name
1962 dnl     $7 = extra libraries
1963 dnl
1964 dnl Sets these variables:
1965 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1966 dnl     $cf_cv_header_path_$3 - include-directory if needed
1967 dnl     $cf_cv_library_path_$3 - library-directory if needed
1968 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1969 AC_DEFUN([CF_FIND_LINKAGE],[
1970
1971 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1972 # will be set on completion of the AC_TRY_LINK below.
1973 cf_cv_header_path_$3=
1974 cf_cv_library_path_$3=
1975
1976 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1977
1978 cf_save_LIBS="$LIBS"
1979
1980 AC_TRY_LINK([$1],[$2],[
1981         cf_cv_find_linkage_$3=yes
1982         cf_cv_header_path_$3=/usr/include
1983         cf_cv_library_path_$3=/usr/lib
1984 ],[
1985
1986 LIBS="-l$3 $7 $cf_save_LIBS"
1987
1988 AC_TRY_LINK([$1],[$2],[
1989         cf_cv_find_linkage_$3=yes
1990         cf_cv_header_path_$3=/usr/include
1991         cf_cv_library_path_$3=/usr/lib
1992         cf_cv_library_file_$3="-l$3"
1993 ],[
1994         cf_cv_find_linkage_$3=no
1995         LIBS="$cf_save_LIBS"
1996
1997         CF_VERBOSE(find linkage for $3 library)
1998         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1999
2000         cf_save_CPPFLAGS="$CPPFLAGS"
2001         cf_test_CPPFLAGS="$CPPFLAGS"
2002
2003         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
2004         for cf_cv_header_path_$3 in $cf_search
2005         do
2006                 if test -d $cf_cv_header_path_$3 ; then
2007                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
2008                         CPPFLAGS="$cf_save_CPPFLAGS"
2009                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
2010                         AC_TRY_COMPILE([$1],[$2],[
2011                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
2012                                 cf_cv_find_linkage_$3=maybe
2013                                 cf_test_CPPFLAGS="$CPPFLAGS"
2014                                 break],[
2015                                 CPPFLAGS="$cf_save_CPPFLAGS"
2016                                 ])
2017                 fi
2018         done
2019
2020         if test "$cf_cv_find_linkage_$3" = maybe ; then
2021
2022                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
2023
2024                 cf_save_LIBS="$LIBS"
2025                 cf_save_LDFLAGS="$LDFLAGS"
2026
2027                 ifelse([$6],,,[
2028                 CPPFLAGS="$cf_test_CPPFLAGS"
2029                 LIBS="-l$3 $7 $cf_save_LIBS"
2030                 AC_TRY_LINK([$1],[$2],[
2031                         CF_VERBOSE(... found $3 library in system)
2032                         cf_cv_find_linkage_$3=yes])
2033                         CPPFLAGS="$cf_save_CPPFLAGS"
2034                         LIBS="$cf_save_LIBS"
2035                         ])
2036
2037                 if test "$cf_cv_find_linkage_$3" != yes ; then
2038                         CF_LIBRARY_PATH(cf_search,$3)
2039                         for cf_cv_library_path_$3 in $cf_search
2040                         do
2041                                 if test -d $cf_cv_library_path_$3 ; then
2042                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
2043                                         CPPFLAGS="$cf_test_CPPFLAGS"
2044                                         LIBS="-l$3 $7 $cf_save_LIBS"
2045                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
2046                                         AC_TRY_LINK([$1],[$2],[
2047                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
2048                                         cf_cv_find_linkage_$3=yes
2049                                         cf_cv_library_file_$3="-l$3"
2050                                         break],[
2051                                         CPPFLAGS="$cf_save_CPPFLAGS"
2052                                         LIBS="$cf_save_LIBS"
2053                                         LDFLAGS="$cf_save_LDFLAGS"
2054                                         ])
2055                                 fi
2056                         done
2057                         CPPFLAGS="$cf_save_CPPFLAGS"
2058                         LDFLAGS="$cf_save_LDFLAGS"
2059                 fi
2060
2061         else
2062                 cf_cv_find_linkage_$3=no
2063         fi
2064         ],$7)
2065 ])
2066
2067 LIBS="$cf_save_LIBS"
2068
2069 if test "$cf_cv_find_linkage_$3" = yes ; then
2070 ifelse([$4],,[
2071         CF_ADD_INCDIR($cf_cv_header_path_$3)
2072         CF_ADD_LIBDIR($cf_cv_library_path_$3)
2073         CF_ADD_LIB($3)
2074 ],[$4])
2075 else
2076 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
2077 fi
2078 ])dnl
2079 dnl ---------------------------------------------------------------------------
2080 dnl CF_FIND_SUB_INCDIR version: 2 updated: 2015/04/17 21:13:04
2081 dnl ------------------
2082 dnl Find an include-directory with the given leaf-name.  This is useful for
2083 dnl example with FreeBSD ports, which use this convention to distinguish
2084 dnl different versions of the same port.
2085 AC_DEFUN([CF_FIND_SUB_INCDIR],[
2086         CF_SUBDIR_PATH(cf_search,$1,include)
2087         for cf_item in $cf_search
2088         do
2089                 case $cf_item in
2090                 (*/$1)
2091                         CF_ADD_INCDIR($cf_item)
2092                         ;;
2093                 esac
2094         done
2095 ])dnl
2096 dnl ---------------------------------------------------------------------------
2097 dnl CF_FIND_SUB_LIBDIR version: 2 updated: 2015/04/17 21:13:04
2098 dnl ------------------
2099 dnl Find a library-directory with the given leaf-name.  This is useful for
2100 dnl example with FreeBSD ports, which use this convention to distinguish
2101 dnl different versions of the same port.
2102 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
2103         CF_SUBDIR_PATH(cf_search,$1,lib)
2104         for cf_item in $cf_search
2105         do
2106                 case $cf_item in
2107                 (*/$1)
2108                         CF_ADD_LIBDIR($cf_item)
2109                         ;;
2110                 esac
2111         done
2112 ])dnl
2113 dnl ---------------------------------------------------------------------------
2114 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
2115 dnl -----------------
2116 dnl make ADAFLAGS consistent with CFLAGS
2117 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
2118         AC_MSG_CHECKING(optimization options for ADAFLAGS)
2119         case "$CFLAGS" in
2120         (*-g*)
2121                 CF_ADD_ADAFLAGS(-g)
2122                 ;;
2123         esac
2124         case "$CFLAGS" in
2125         (*-O*)
2126                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
2127                 CF_ADD_ADAFLAGS($cf_O_flag)
2128                 ;;
2129         esac
2130         AC_MSG_RESULT($ADAFLAGS)
2131 ])dnl
2132 dnl ---------------------------------------------------------------------------
2133 dnl CF_FOPEN_BIN_R version: 1 updated: 2019/03/30 17:52:21
2134 dnl --------------
2135 dnl Check if fopen works when the "b" (binary) flag is added to the mode
2136 dnl parameter.  POSIX ignores the "b", which c89 specified.  Some very old
2137 dnl systems do not accept it.
2138 AC_DEFUN([CF_FOPEN_BIN_R],[
2139 AC_CACHE_CHECK(if fopen accepts explicit binary mode,cf_cv_fopen_bin_r,[
2140         AC_TRY_RUN([
2141 #include <stdio.h>
2142 int main(void) {
2143         FILE *fp = fopen("conftest.tmp", "wb");
2144         int rc = 0;
2145         if (fp != 0) {
2146                 int p, q;
2147                 for (p = 0; p < 256; ++p) {
2148                         fputc(p, fp);
2149                 }
2150                 fclose(fp);
2151                 fp = fopen("conftest.tmp", "rb");
2152                 if (fp != 0) {
2153                         for (p = 0; p < 256; ++p) {
2154                                 q = fgetc(fp);
2155                                 if (q != p) {
2156                                         rc = 1;
2157                                         break;
2158                                 }
2159                         }
2160                 } else {
2161                         rc = 1;
2162                 }
2163         } else {
2164                 rc = 1;
2165         }
2166         ${cf_cv_main_return:-return} (rc);
2167 }
2168 ],
2169                 [cf_cv_fopen_bin_r=yes],
2170                 [cf_cv_fopen_bin_r=no],
2171                 [cf_cv_fopen_bin_r=unknown])
2172 ])
2173 test "x$cf_cv_fopen_bin_r" != xno && AC_DEFINE(USE_FOPEN_BIN_R)
2174 ])dnl
2175 dnl ---------------------------------------------------------------------------
2176 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
2177 dnl --------------
2178 dnl Forget that we saw the given tool.
2179 AC_DEFUN([CF_FORGET_TOOL],[
2180 unset ac_cv_prog_ac_ct_$1
2181 unset ac_ct_$1
2182 unset $1
2183 ])dnl
2184 dnl ---------------------------------------------------------------------------
2185 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
2186 dnl -------------
2187 dnl Test for dlsym() and related functions, as well as libdl.
2188 dnl
2189 dnl Sets
2190 dnl     $cf_have_dlsym
2191 dnl     $cf_have_libdl
2192 AC_DEFUN([CF_FUNC_DLSYM],[
2193 cf_have_dlsym=no
2194 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
2195
2196 cf_have_libdl=no
2197 AC_CHECK_LIB(dl,dlsym,[
2198         cf_have_dlsym=yes
2199         cf_have_libdl=yes])])
2200
2201 if test "$cf_have_dlsym" = yes ; then
2202         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
2203
2204         AC_MSG_CHECKING(whether able to link to dl*() functions)
2205         AC_TRY_LINK([#include <dlfcn.h>],[
2206                 void *obj;
2207                 if ((obj = dlopen("filename", 0)) != 0) {
2208                         if (dlsym(obj, "symbolname") == 0) {
2209                         dlclose(obj);
2210                         }
2211                 }],[
2212                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
2213                 AC_MSG_ERROR(Cannot link test program for libdl)])
2214         AC_MSG_RESULT(ok)
2215 else
2216         AC_MSG_ERROR(Cannot find dlsym function)
2217 fi
2218 ])
2219 dnl ---------------------------------------------------------------------------
2220 dnl CF_FUNC_MEMMOVE version: 9 updated: 2017/01/21 11:06:25
2221 dnl ---------------
2222 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
2223 dnl is found, add our own version of memmove to the list of objects.
2224 AC_DEFUN([CF_FUNC_MEMMOVE],
2225 [
2226 AC_CHECK_FUNC(memmove,,[
2227 AC_CHECK_FUNC(bcopy,[
2228         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
2229                 AC_TRY_RUN([
2230 int main(void) {
2231         static char data[] = "abcdefghijklmnopqrstuwwxyz";
2232         char temp[40];
2233         bcopy(data, temp, sizeof(data));
2234         bcopy(temp+10, temp, 15);
2235         bcopy(temp+5, temp+15, 10);
2236         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
2237 }
2238                 ],
2239                 [cf_cv_good_bcopy=yes],
2240                 [cf_cv_good_bcopy=no],
2241                 [cf_cv_good_bcopy=unknown])
2242                 ])
2243         ],[cf_cv_good_bcopy=no])
2244         if test "$cf_cv_good_bcopy" = yes ; then
2245                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
2246         else
2247                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
2248         fi
2249 ])])dnl
2250 dnl ---------------------------------------------------------------------------
2251 dnl CF_FUNC_NANOSLEEP version: 5 updated: 2017/01/21 11:06:25
2252 dnl -----------------
2253 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
2254 dnl AIX 4.x, provide a non-working version.
2255 AC_DEFUN([CF_FUNC_NANOSLEEP],[
2256 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
2257 AC_TRY_RUN([
2258 #include <stdio.h>
2259 #include <errno.h>
2260 #include <time.h>
2261
2262 #ifdef HAVE_SYS_TIME_H
2263 #include <sys/time.h>
2264 #endif
2265
2266 int main(void) {
2267         struct timespec ts1, ts2;
2268         int code;
2269         ts1.tv_sec  = 0;
2270         ts1.tv_nsec = 750000000;
2271         ts2.tv_sec  = 0;
2272         ts2.tv_nsec = 0;
2273         errno = 0;
2274         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
2275         ${cf_cv_main_return:-return}(code != 0);
2276 }
2277 ],
2278         [cf_cv_func_nanosleep=yes],
2279         [cf_cv_func_nanosleep=no],
2280         [cf_cv_func_nanosleep=unknown])])
2281
2282 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
2283 ])
2284 dnl ---------------------------------------------------------------------------
2285 dnl CF_FUNC_OPENPTY version: 5 updated: 2015/09/12 14:46:50
2286 dnl ---------------
2287 dnl Check for openpty() function, along with <pty.h> header.  It may need the
2288 dnl "util" library as well.
2289 AC_DEFUN([CF_FUNC_OPENPTY],
2290 [
2291 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
2292 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
2293         cf_save_LIBS="$LIBS"
2294         test $cf_cv_lib_util = yes && { CF_ADD_LIB(util) }
2295         for cf_header in pty.h libutil.h util.h
2296         do
2297         AC_TRY_LINK([
2298 #include <$cf_header>
2299 ],[
2300         int x = openpty((int *)0, (int *)0, (char *)0,
2301                                    (struct termios *)0, (struct winsize *)0);
2302 ],[
2303                 cf_cv_func_openpty=$cf_header
2304                 break
2305 ],[
2306                 cf_cv_func_openpty=no
2307 ])
2308         done
2309         LIBS="$cf_save_LIBS"
2310 ])
2311 ])dnl
2312 dnl ---------------------------------------------------------------------------
2313 dnl CF_FUNC_POLL version: 9 updated: 2015/10/10 13:27:32
2314 dnl ------------
2315 dnl See if the poll function really works.  Some platforms have poll(), but
2316 dnl it does not work for terminals or files.
2317 AC_DEFUN([CF_FUNC_POLL],[
2318 tty 2>&1 >/dev/null || { AC_CHECK_FUNCS(posix_openpt) }
2319 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
2320 AC_TRY_RUN([
2321 #include <stdlib.h>
2322 #include <stdio.h>
2323 #include <unistd.h>
2324 #include <fcntl.h>
2325 #ifdef HAVE_POLL_H
2326 #include <poll.h>
2327 #else
2328 #include <sys/poll.h>
2329 #endif
2330 int main(void) {
2331         struct pollfd myfds;
2332         int ret;
2333
2334         /* check for Darwin bug with respect to "devices" */
2335         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
2336         if (myfds.fd < 0)
2337                 myfds.fd = 0;
2338         myfds.events = POLLIN;
2339         myfds.revents = 0;
2340
2341         ret = poll(&myfds, 1, 100);
2342
2343         if (ret < 0 || (myfds.revents & POLLNVAL)) {
2344                 ret = -1;
2345         } else {
2346                 int fd = 0;
2347                 if (!isatty(fd)) {
2348                         fd = open("/dev/tty", 2);       /* O_RDWR */
2349                 }
2350 #ifdef HAVE_POSIX_OPENPT
2351                 if (fd < 0) {
2352                         fd = posix_openpt(O_RDWR);
2353                 }
2354 #endif
2355
2356                 if (fd >= 0) {
2357                         /* also check with standard input */
2358                         myfds.fd = fd;
2359                         myfds.events = POLLIN;
2360                         myfds.revents = 0;
2361                         ret = poll(&myfds, 1, 100);
2362                 } else {
2363                         ret = -1;
2364                 }
2365         }
2366         ${cf_cv_main_return:-return}(ret < 0);
2367 }],
2368         [cf_cv_working_poll=yes],
2369         [cf_cv_working_poll=no],
2370         [cf_cv_working_poll=unknown])])
2371 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
2372 ])dnl
2373 dnl ---------------------------------------------------------------------------
2374 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
2375 dnl ---------------
2376 dnl Some old/broken variations define tcgetattr() only as a macro in
2377 dnl termio(s).h
2378 AC_DEFUN([CF_FUNC_TERMIOS],[
2379 AC_REQUIRE([CF_STRUCT_TERMIOS])
2380 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
2381 AC_TRY_LINK([
2382 #include <sys/types.h>
2383 #ifdef HAVE_UNISTD_H
2384 #include <unistd.h>
2385 #endif
2386 #ifdef HAVE_TERMIOS_H
2387 #include <termios.h>
2388 #define TTY struct termios
2389 #else
2390 #ifdef HAVE_TERMIO_H
2391 #include <termio.h>
2392 #define TTY struct termio
2393 #endif
2394 #endif
2395 ],[
2396 TTY foo;
2397 tcgetattr(1, &foo);],
2398 [cf_cv_have_tcgetattr=yes],
2399 [cf_cv_have_tcgetattr=no])])
2400 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
2401 ])dnl
2402 dnl ---------------------------------------------------------------------------
2403 dnl CF_FUNC_VSSCANF version: 6 updated: 2015/04/18 08:56:57
2404 dnl ---------------
2405 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
2406 dnl versions of C.  It is in the GNU C library, and can often be simulated by
2407 dnl other functions.
2408 AC_DEFUN([CF_FUNC_VSSCANF],
2409 [
2410 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
2411 AC_TRY_LINK([
2412 #include <stdarg.h>
2413 #include <stdio.h>],[
2414         va_list ap;
2415         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
2416 AC_TRY_LINK([
2417 #include <stdarg.h>
2418 #include <stdio.h>],[
2419         FILE strbuf;
2420         char *str = "from";
2421
2422         strbuf._flag = _IOREAD;
2423         strbuf._ptr = strbuf._base = (unsigned char *) str;
2424         strbuf._cnt = strlen(str);
2425         strbuf._file = _NFILE;
2426         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
2427 AC_TRY_LINK([
2428 #include <stdarg.h>
2429 #include <stdio.h>],[
2430         FILE strbuf;
2431         char *str = "from";
2432
2433         strbuf._flag = _IOREAD;
2434         strbuf._ptr = strbuf._base = (unsigned char *) str;
2435         strbuf._cnt = strlen(str);
2436         strbuf._file = _NFILE;
2437         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
2438 cf_cv_func_vsscanf=no])])])])
2439
2440 case $cf_cv_func_vsscanf in
2441 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
2442 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
2443 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
2444 esac
2445
2446 ])dnl
2447 dnl ---------------------------------------------------------------------------
2448 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
2449 dnl -----------------
2450 dnl Test for availability of useful gcc __attribute__ directives to quiet
2451 dnl compiler warnings.  Though useful, not all are supported -- and contrary
2452 dnl to documentation, unrecognized directives cause older compilers to barf.
2453 AC_DEFUN([CF_GCC_ATTRIBUTES],
2454 [
2455 if test "$GCC" = yes
2456 then
2457 cat > conftest.i <<EOF
2458 #ifndef GCC_PRINTF
2459 #define GCC_PRINTF 0
2460 #endif
2461 #ifndef GCC_SCANF
2462 #define GCC_SCANF 0
2463 #endif
2464 #ifndef GCC_NORETURN
2465 #define GCC_NORETURN /* nothing */
2466 #endif
2467 #ifndef GCC_UNUSED
2468 #define GCC_UNUSED /* nothing */
2469 #endif
2470 EOF
2471 if test "$GCC" = yes
2472 then
2473         AC_CHECKING([for $CC __attribute__ directives])
2474 cat > conftest.$ac_ext <<EOF
2475 #line __oline__ "${as_me:-configure}"
2476 #include "confdefs.h"
2477 #include "conftest.h"
2478 #include "conftest.i"
2479 #if     GCC_PRINTF
2480 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
2481 #else
2482 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
2483 #endif
2484 #if     GCC_SCANF
2485 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2486 #else
2487 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2488 #endif
2489 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2490 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
2491 extern void foo(void) GCC_NORETURN;
2492 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
2493 EOF
2494         cf_printf_attribute=no
2495         cf_scanf_attribute=no
2496         for cf_attribute in scanf printf unused noreturn
2497         do
2498                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2499                 cf_directive="__attribute__(($cf_attribute))"
2500                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2501
2502                 case $cf_attribute in
2503                 (printf)
2504                         cf_printf_attribute=yes
2505                         cat >conftest.h <<EOF
2506 #define GCC_$cf_ATTRIBUTE 1
2507 EOF
2508                         ;;
2509                 (scanf)
2510                         cf_scanf_attribute=yes
2511                         cat >conftest.h <<EOF
2512 #define GCC_$cf_ATTRIBUTE 1
2513 EOF
2514                         ;;
2515                 (*)
2516                         cat >conftest.h <<EOF
2517 #define GCC_$cf_ATTRIBUTE $cf_directive
2518 EOF
2519                         ;;
2520                 esac
2521
2522                 if AC_TRY_EVAL(ac_compile); then
2523                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
2524                         cat conftest.h >>confdefs.h
2525                         case $cf_attribute in
2526                         (noreturn)
2527                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
2528                                 ;;
2529                         (printf)
2530                                 cf_value='/* nothing */'
2531                                 if test "$cf_printf_attribute" != no ; then
2532                                         cf_value='__attribute__((format(printf,fmt,var)))'
2533                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
2534                                 fi
2535                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
2536                                 ;;
2537                         (scanf)
2538                                 cf_value='/* nothing */'
2539                                 if test "$cf_scanf_attribute" != no ; then
2540                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2541                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2542                                 fi
2543                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2544                                 ;;
2545                         (unused)
2546                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2547                                 ;;
2548                         esac
2549                 fi
2550         done
2551 else
2552         fgrep define conftest.i >>confdefs.h
2553 fi
2554 rm -rf conftest*
2555 fi
2556 ])dnl
2557 dnl ---------------------------------------------------------------------------
2558 dnl CF_GCC_VERSION version: 8 updated: 2019/09/07 13:38:36
2559 dnl --------------
2560 dnl Find version of gcc, and (because icc/clang pretend to be gcc without being
2561 dnl compatible), attempt to determine if icc/clang is actually used.
2562 AC_DEFUN([CF_GCC_VERSION],[
2563 AC_REQUIRE([AC_PROG_CC])
2564 GCC_VERSION=none
2565 if test "$GCC" = yes ; then
2566         AC_MSG_CHECKING(version of $CC)
2567         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2568         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2569         AC_MSG_RESULT($GCC_VERSION)
2570 fi
2571 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2572 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2573 ])dnl
2574 dnl ---------------------------------------------------------------------------
2575 dnl CF_GCC_WARNINGS version: 36 updated: 2019/09/07 13:38:36
2576 dnl ---------------
2577 dnl Check if the compiler supports useful warning options.  There's a few that
2578 dnl we don't use, simply because they're too noisy:
2579 dnl
2580 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2581 dnl     -Wredundant-decls (system headers make this too noisy)
2582 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2583 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2584 dnl             is enabled for ncurses using "--enable-const".
2585 dnl     -pedantic
2586 dnl
2587 dnl Parameter:
2588 dnl     $1 is an optional list of gcc warning flags that a particular
2589 dnl             application might want to use, e.g., "no-unused" for
2590 dnl             -Wno-unused
2591 dnl Special:
2592 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2593 dnl
2594 AC_DEFUN([CF_GCC_WARNINGS],
2595 [
2596 AC_REQUIRE([CF_GCC_VERSION])
2597 if test "x$have_x" = xyes; then CF_CONST_X_STRING fi
2598 cat > conftest.$ac_ext <<EOF
2599 #line __oline__ "${as_me:-configure}"
2600 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2601 EOF
2602 if test "$INTEL_COMPILER" = yes
2603 then
2604 # The "-wdXXX" options suppress warnings:
2605 # remark #1419: external declaration in primary source file
2606 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2607 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2608 # remark #193: zero used for undefined preprocessing identifier
2609 # remark #593: variable "curs_sb_left_arrow" was set but never used
2610 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2611 # remark #869: parameter "tw" was never referenced
2612 # remark #981: operands are evaluated in unspecified order
2613 # warning #279: controlling expression is constant
2614
2615         AC_CHECKING([for $CC warning options])
2616         cf_save_CFLAGS="$CFLAGS"
2617         EXTRA_CFLAGS="-Wall"
2618         for cf_opt in \
2619                 wd1419 \
2620                 wd1683 \
2621                 wd1684 \
2622                 wd193 \
2623                 wd593 \
2624                 wd279 \
2625                 wd810 \
2626                 wd869 \
2627                 wd981
2628         do
2629                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2630                 if AC_TRY_EVAL(ac_compile); then
2631                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2632                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2633                 fi
2634         done
2635         CFLAGS="$cf_save_CFLAGS"
2636 elif test "$GCC" = yes
2637 then
2638         AC_CHECKING([for $CC warning options])
2639         cf_save_CFLAGS="$CFLAGS"
2640         EXTRA_CFLAGS=
2641         cf_warn_CONST=""
2642         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2643         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2644         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2645         for cf_opt in W Wall \
2646                 Wbad-function-cast \
2647                 Wcast-align \
2648                 Wcast-qual \
2649                 Wdeclaration-after-statement \
2650                 Wextra \
2651                 Winline \
2652                 Wmissing-declarations \
2653                 Wmissing-prototypes \
2654                 Wnested-externs \
2655                 Wpointer-arith \
2656                 Wshadow \
2657                 Wstrict-prototypes \
2658                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
2659         do
2660                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2661                 if AC_TRY_EVAL(ac_compile); then
2662                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2663                         case $cf_opt in
2664                         (Winline)
2665                                 case $GCC_VERSION in
2666                                 ([[34]].*)
2667                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2668                                         continue;;
2669                                 esac
2670                                 ;;
2671                         (Wpointer-arith)
2672                                 case $GCC_VERSION in
2673                                 ([[12]].*)
2674                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2675                                         continue;;
2676                                 esac
2677                                 ;;
2678                         esac
2679                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2680                 fi
2681         done
2682         CFLAGS="$cf_save_CFLAGS"
2683 fi
2684 rm -rf conftest*
2685
2686 AC_SUBST(EXTRA_CFLAGS)
2687 ])dnl
2688 dnl ---------------------------------------------------------------------------
2689 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
2690 dnl ----------------
2691 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2692 dnl unistd.h or (nonstandard) in getopt.h
2693 AC_DEFUN([CF_GETOPT_HEADER],
2694 [
2695 AC_HAVE_HEADERS(unistd.h getopt.h)
2696 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2697 cf_cv_getopt_header=none
2698 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2699 do
2700 AC_TRY_COMPILE([
2701 #include <$cf_header>],
2702 [int x = optind; char *y = optarg],
2703 [cf_cv_getopt_header=$cf_header
2704  break])
2705 done
2706 ])
2707 if test $cf_cv_getopt_header != none ; then
2708         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2709 fi
2710 if test $cf_cv_getopt_header = getopt.h ; then
2711         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2712 fi
2713 ])dnl
2714 dnl ---------------------------------------------------------------------------
2715 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2716 dnl -----------------
2717 AC_DEFUN([CF_GNATPREP_OPT_T],[
2718 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2719 cf_cv_gnatprep_opt_t=no
2720 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2721 ])
2722 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
2723 AC_SUBST(GNATPREP_OPTS)
2724 ])dnl
2725 dnl ---------------------------------------------------------------------------
2726 dnl CF_GNAT_GENERICS version: 3 updated: 2015/04/17 21:13:04
2727 dnl ----------------
2728 AC_DEFUN([CF_GNAT_GENERICS],
2729 [
2730 AC_REQUIRE([CF_GNAT_VERSION])
2731
2732 AC_MSG_CHECKING(if GNAT supports generics)
2733 case $cf_gnat_version in
2734 (3.[[1-9]]*|[[4-9]].*)
2735         cf_gnat_generics=yes
2736         ;;
2737 (*)
2738         cf_gnat_generics=no
2739         ;;
2740 esac
2741 AC_MSG_RESULT($cf_gnat_generics)
2742
2743 if test "$cf_gnat_generics" = yes
2744 then
2745         cf_compile_generics=generics
2746         cf_generic_objects="\${GENOBJS}"
2747 else
2748         cf_compile_generics=
2749         cf_generic_objects=
2750 fi
2751
2752 AC_SUBST(cf_compile_generics)
2753 AC_SUBST(cf_generic_objects)
2754 ])dnl
2755 dnl ---------------------------------------------------------------------------
2756 dnl CF_GNAT_PROJECTS version: 9 updated: 2018/01/14 15:46:09
2757 dnl ----------------
2758 dnl GNAT projects are configured with ".gpr" project files.
2759 dnl GNAT libraries are a further development, using the project feature.
2760 AC_DEFUN([CF_GNAT_PROJECTS],
2761 [
2762 AC_REQUIRE([CF_GNAT_VERSION])
2763 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
2764
2765 cf_gnat_libraries=no
2766 cf_gnat_projects=no
2767
2768 if test "$enable_gnat_projects" != no ; then
2769 AC_MSG_CHECKING(if GNAT supports project files)
2770 case $cf_gnat_version in
2771 (3.[[0-9]]*)
2772         ;;
2773 (*)
2774         case $cf_cv_system_name in
2775         (cygwin*|msys*)
2776                 ;;
2777         (*)
2778                 rm -rf conftest* *~conftest*
2779                 if mkdir conftest.src conftest.bin conftest.lib
2780                 then
2781                         cd conftest.src
2782                         rm -rf conftest* *~conftest*
2783                         cat >>library.gpr <<CF_EOF
2784 project Library is
2785   Kind := External ("LIB_KIND");
2786   for Library_Name use "ConfTest";
2787   for Object_Dir use ".";
2788   for Library_ALI_Dir use External("LIBRARY_DIR");
2789   for Library_Version use External ("SONAME");
2790   for Library_Kind use Kind;
2791   for Library_Dir use External("BUILD_DIR");
2792   Source_Dir := External ("SOURCE_DIR");
2793   for Source_Dirs use (Source_Dir);
2794 end Library;
2795 CF_EOF
2796                         cat >>confpackage.ads <<CF_EOF
2797 package ConfPackage is
2798    procedure conftest;
2799 end ConfPackage;
2800 CF_EOF
2801                         cat >>confpackage.adb <<CF_EOF
2802 with Text_IO;
2803 package body ConfPackage is
2804    procedure conftest is
2805    begin
2806       Text_IO.Put ("Hello World");
2807       Text_IO.New_Line;
2808    end conftest;
2809 end ConfPackage;
2810 CF_EOF
2811                         if ( $cf_ada_make $ADAFLAGS \
2812                                         -Plibrary.gpr \
2813                                         -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2814                                         -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2815                                         -XSOURCE_DIR=`pwd` \
2816                                         -XSONAME=libConfTest.so.1 \
2817                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2818                                 cf_gnat_projects=yes
2819                         fi
2820                         cd ..
2821                 fi
2822                 if test -f conftest.lib/confpackage.ali
2823                 then
2824                         cf_gnat_libraries=yes
2825                 fi
2826                 rm -rf conftest* *~conftest*
2827                 ;;
2828         esac
2829         ;;
2830 esac
2831 AC_MSG_RESULT($cf_gnat_projects)
2832 fi # enable_gnat_projects
2833
2834 if test $cf_gnat_projects = yes
2835 then
2836         AC_MSG_CHECKING(if GNAT supports libraries)
2837         AC_MSG_RESULT($cf_gnat_libraries)
2838 fi
2839
2840 if test "$cf_gnat_projects" = yes
2841 then
2842         USE_OLD_MAKERULES="#"
2843         USE_GNAT_PROJECTS=""
2844 else
2845         USE_OLD_MAKERULES=""
2846         USE_GNAT_PROJECTS="#"
2847 fi
2848
2849 if test "$cf_gnat_libraries" = yes
2850 then
2851         USE_GNAT_LIBRARIES=""
2852 else
2853         USE_GNAT_LIBRARIES="#"
2854 fi
2855
2856 AC_SUBST(USE_OLD_MAKERULES)
2857 AC_SUBST(USE_GNAT_PROJECTS)
2858 AC_SUBST(USE_GNAT_LIBRARIES)
2859 ])dnl
2860 dnl ---------------------------------------------------------------------------
2861 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2862 dnl --------------
2863 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2864 dnl is noted that gnat may compile a tasking unit even for configurations which
2865 dnl fail at runtime.
2866 AC_DEFUN([CF_GNAT_SIGINT],[
2867 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2868 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2869
2870 package ConfTest is
2871
2872    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2873    pragma Unreserve_All_Interrupts;
2874    pragma Warnings (On);
2875
2876    protected Process is
2877       procedure Stop;
2878       function Continue return Boolean;
2879       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2880    private
2881       Done : Boolean := False;
2882    end Process;
2883
2884 end ConfTest;],
2885 [package body ConfTest is
2886    protected body Process is
2887       procedure Stop is
2888       begin
2889          Done := True;
2890       end Stop;
2891       function Continue return Boolean is
2892       begin
2893          return not Done;
2894       end Continue;
2895    end Process;
2896 end ConfTest;],
2897         [cf_cv_gnat_sigint=yes],
2898         [cf_cv_gnat_sigint=no])])
2899
2900 if test $cf_cv_gnat_sigint = yes ; then
2901         USE_GNAT_SIGINT=""
2902 else
2903         USE_GNAT_SIGINT="#"
2904 fi
2905 AC_SUBST(USE_GNAT_SIGINT)
2906 ])dnl
2907 dnl ---------------------------------------------------------------------------
2908 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2909 dnl ----------------
2910 dnl Verify that a test program compiles/links with GNAT.
2911 dnl $cf_ada_make is set to the program that compiles/links
2912 dnl $ADAFLAGS may be set to the GNAT flags.
2913 dnl
2914 dnl $1 is the text of the spec
2915 dnl $2 is the text of the body
2916 dnl $3 is the shell command to execute if successful
2917 dnl $4 is the shell command to execute if not successful
2918 AC_DEFUN([CF_GNAT_TRY_LINK],
2919 [
2920 rm -rf conftest* *~conftest*
2921 cat >>conftest.ads <<CF_EOF
2922 $1
2923 CF_EOF
2924 cat >>conftest.adb <<CF_EOF
2925 $2
2926 CF_EOF
2927 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2928 ifelse($3,,      :,[      $3])
2929 ifelse($4,,,[else
2930    $4])
2931 fi
2932 rm -rf conftest* *~conftest*
2933 ])dnl
2934 dnl ---------------------------------------------------------------------------
2935 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2936 dnl ---------------
2937 dnl Verify that a test program compiles and runs with GNAT
2938 dnl $cf_ada_make is set to the program that compiles/links
2939 dnl $ADAFLAGS may be set to the GNAT flags.
2940 dnl
2941 dnl $1 is the text of the spec
2942 dnl $2 is the text of the body
2943 dnl $3 is the shell command to execute if successful
2944 dnl $4 is the shell command to execute if not successful
2945 AC_DEFUN([CF_GNAT_TRY_RUN],
2946 [
2947 rm -rf conftest* *~conftest*
2948 cat >>conftest.ads <<CF_EOF
2949 $1
2950 CF_EOF
2951 cat >>conftest.adb <<CF_EOF
2952 $2
2953 CF_EOF
2954 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2955    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2956 ifelse($3,,      :,[      $3])
2957 ifelse($4,,,[   else
2958       $4])
2959    fi
2960 ifelse($4,,,[else
2961    $4])
2962 fi
2963 rm -rf conftest* *~conftest*
2964 ])dnl
2965 dnl ---------------------------------------------------------------------------
2966 dnl CF_GNAT_VERSION version: 21 updated: 2019/09/21 18:08:42
2967 dnl ---------------
2968 dnl $1 = cache variable to update
2969 dnl $2 = program name
2970 dnl Verify version of GNAT or related tool
2971 AC_DEFUN([CF_GNAT_VERSION],
2972 [
2973 AC_CACHE_CHECK(for ifelse($2,,gnat,$2) version, cf_gnat_version,[
2974 cf_gnat_version=`ifelse($2,,${cf_ada_make:-gnatmake},$2) --version 2>&1 | \
2975         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2976         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2977 ])
2978 test -z "$cf_gnat_version" && cf_gnat_version=no
2979 ifelse($1,,,[eval $1=$cf_gnat_version; unset cf_gnat_version])
2980 ])dnl
2981 dnl ---------------------------------------------------------------------------
2982 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
2983 dnl -------------
2984 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2985 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2986 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2987 dnl since it is interwoven with GNU extensions.
2988 dnl
2989 dnl Well, yes we could work around it...
2990 dnl
2991 dnl Parameters:
2992 dnl     $1 is the nominal value for _XOPEN_SOURCE
2993 AC_DEFUN([CF_GNU_SOURCE],
2994 [
2995 cf_gnu_xopen_source=ifelse($1,,500,$1)
2996
2997 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
2998 AC_TRY_COMPILE([#include <sys/types.h>],[
2999         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
3000                 return 0;
3001         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
3002                 return 0;
3003         #else
3004         #       error not GNU C library
3005         #endif],
3006         [cf_cv_gnu_library=yes],
3007         [cf_cv_gnu_library=no])
3008 ])
3009
3010 if test x$cf_cv_gnu_library = xyes; then
3011
3012         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
3013         # was changed to help a little.  newlib incorporated the change about 4
3014         # years later.
3015         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
3016                 cf_save="$CPPFLAGS"
3017                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3018                 AC_TRY_COMPILE([#include <sys/types.h>],[
3019                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
3020                                 return 0;
3021                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
3022                                 return 0;
3023                         #else
3024                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
3025                         #endif],
3026                         [cf_cv_gnu_library_219=yes],
3027                         [cf_cv_gnu_library_219=no])
3028                 CPPFLAGS="$cf_save"
3029         ])
3030
3031         if test "x$cf_cv_gnu_library_219" = xyes; then
3032                 cf_save="$CPPFLAGS"
3033                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
3034                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
3035                         AC_TRY_COMPILE([
3036                                 #include <limits.h>
3037                                 #include <sys/types.h>
3038                                 ],[
3039                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
3040                                         return 0;
3041                                 #else
3042                                 #       error GNU C library is too old
3043                                 #endif],
3044                                 [cf_cv_gnu_dftsrc_219=yes],
3045                                 [cf_cv_gnu_dftsrc_219=no])
3046                         ])
3047                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
3048         else
3049                 cf_cv_gnu_dftsrc_219=maybe
3050         fi
3051
3052         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
3053
3054                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
3055                 AC_TRY_COMPILE([#include <sys/types.h>],[
3056                         #ifndef _XOPEN_SOURCE
3057                         #error  expected _XOPEN_SOURCE to be defined
3058                         #endif],
3059                         [cf_cv_gnu_source=no],
3060                         [cf_save="$CPPFLAGS"
3061                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
3062                          AC_TRY_COMPILE([#include <sys/types.h>],[
3063                                 #ifdef _XOPEN_SOURCE
3064                                 #error  expected _XOPEN_SOURCE to be undefined
3065                                 #endif],
3066                                 [cf_cv_gnu_source=no],
3067                                 [cf_cv_gnu_source=yes])
3068                         CPPFLAGS="$cf_save"
3069                         ])
3070                 ])
3071
3072                 if test "$cf_cv_gnu_source" = yes
3073                 then
3074                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
3075                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
3076                         AC_TRY_COMPILE([#include <sys/types.h>],[
3077                                 #ifdef _DEFAULT_SOURCE
3078                                 #error  expected _DEFAULT_SOURCE to be undefined
3079                                 #endif],
3080                                 [cf_cv_default_source=no],
3081                                 [cf_cv_default_source=yes])
3082                         ])
3083                         if test "$cf_cv_default_source" = yes
3084                         then
3085                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3086                         fi
3087                 fi
3088         fi
3089
3090 fi
3091 ])dnl
3092 dnl ---------------------------------------------------------------------------
3093 dnl CF_GPP_LIBRARY version: 12 updated: 2015/04/17 21:13:04
3094 dnl --------------
3095 dnl If we're trying to use g++, test if libg++ is installed (a rather common
3096 dnl problem :-).  If we have the compiler but no library, we'll be able to
3097 dnl configure, but won't be able to build the c++ demo program.
3098 AC_DEFUN([CF_GPP_LIBRARY],
3099 [
3100 cf_cxx_library=unknown
3101 case $cf_cv_system_name in
3102 (os2*)
3103         cf_gpp_libname=gpp
3104         ;;
3105 (*)
3106         cf_gpp_libname=g++
3107         ;;
3108 esac
3109 if test "$GXX" = yes; then
3110         AC_MSG_CHECKING([for lib$cf_gpp_libname])
3111         cf_save="$LIBS"
3112         CF_ADD_LIB($cf_gpp_libname)
3113         AC_TRY_LINK([
3114 #include <$cf_gpp_libname/builtin.h>
3115         ],
3116         [two_arg_error_handler_t foo2 = lib_error_handler],
3117         [cf_cxx_library=yes
3118          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3119          if test "$cf_gpp_libname" = cpp ; then
3120             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
3121          else
3122             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
3123          fi],
3124         [AC_TRY_LINK([
3125 #include <builtin.h>
3126         ],
3127         [two_arg_error_handler_t foo2 = lib_error_handler],
3128         [cf_cxx_library=yes
3129          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3130          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
3131         [cf_cxx_library=no])])
3132         LIBS="$cf_save"
3133         AC_MSG_RESULT($cf_cxx_library)
3134 fi
3135 ])dnl
3136 dnl ---------------------------------------------------------------------------
3137 dnl CF_GXX_VERSION version: 8 updated: 2017/02/11 14:48:57
3138 dnl --------------
3139 dnl Check for version of g++
3140 AC_DEFUN([CF_GXX_VERSION],[
3141 AC_REQUIRE([AC_PROG_CPP])
3142 GXX_VERSION=none
3143 if test "$GXX" = yes; then
3144         AC_MSG_CHECKING(version of ${CXX:-g++})
3145         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
3146         if test -z "$GXX_VERSION"
3147         then
3148                 GXX_VERSION=unknown
3149                 GXX=no
3150         fi
3151         AC_MSG_RESULT($GXX_VERSION)
3152 fi
3153 ])dnl
3154 dnl ---------------------------------------------------------------------------
3155 dnl CF_GXX_WARNINGS version: 9 updated: 2015/04/17 21:13:04
3156 dnl ---------------
3157 dnl Check if the compiler supports useful warning options.
3158 dnl
3159 dnl Most of gcc's options apply to g++, except:
3160 dnl     -Wbad-function-cast
3161 dnl     -Wmissing-declarations
3162 dnl     -Wnested-externs
3163 dnl
3164 dnl Omit a few (for now):
3165 dnl     -Winline
3166 dnl
3167 dnl Parameter:
3168 dnl     $1 is an optional list of g++ warning flags that a particular
3169 dnl             application might want to use, e.g., "no-unused" for
3170 dnl             -Wno-unused
3171 dnl Special:
3172 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
3173 dnl
3174 AC_DEFUN([CF_GXX_WARNINGS],
3175 [
3176
3177 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
3178 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
3179
3180 AC_REQUIRE([CF_GXX_VERSION])
3181
3182 AC_LANG_SAVE
3183 AC_LANG_CPLUSPLUS
3184
3185 cat > conftest.$ac_ext <<EOF
3186 #line __oline__ "configure"
3187 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
3188 EOF
3189
3190 if test "$INTEL_CPLUSPLUS" = yes
3191 then
3192 # The "-wdXXX" options suppress warnings:
3193 # remark #1419: external declaration in primary source file
3194 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3195 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3196 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
3197 # remark #193: zero used for undefined preprocessing identifier
3198 # remark #593: variable "curs_sb_left_arrow" was set but never used
3199 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
3200 # remark #869: parameter "tw" was never referenced
3201 # remark #981: operands are evaluated in unspecified order
3202 # warning #269: invalid format string conversion
3203
3204         AC_CHECKING([for $CC warning options])
3205         cf_save_CXXFLAGS="$CXXFLAGS"
3206         EXTRA_CXXFLAGS="-Wall"
3207         for cf_opt in \
3208                 wd1419 \
3209                 wd1682 \
3210                 wd1683 \
3211                 wd1684 \
3212                 wd193 \
3213                 wd279 \
3214                 wd593 \
3215                 wd810 \
3216                 wd869 \
3217                 wd981
3218         do
3219                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
3220                 if AC_TRY_EVAL(ac_compile); then
3221                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3222                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3223                 fi
3224         done
3225         CXXFLAGS="$cf_save_CXXFLAGS"
3226
3227 elif test "$GXX" = yes
3228 then
3229         AC_CHECKING([for $CXX warning options])
3230         cf_save_CXXFLAGS="$CXXFLAGS"
3231         EXTRA_CXXFLAGS="-W -Wall"
3232         cf_gxx_extra_warnings=""
3233         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
3234         case "$GCC_VERSION" in
3235         ([[1-2]].*)
3236                 ;;
3237         (*)
3238                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
3239                 ;;
3240         esac
3241         for cf_opt in \
3242                 Wabi \
3243                 fabi-version=0 \
3244                 Wextra \
3245                 Wignored-qualifiers \
3246                 Wlogical-op \
3247                 Woverloaded-virtual \
3248                 Wsign-promo \
3249                 Wsynth \
3250                 Wold-style-cast \
3251                 Wcast-align \
3252                 Wcast-qual \
3253                 Wpointer-arith \
3254                 Wshadow \
3255                 Wundef $cf_gxx_extra_warnings $1
3256         do
3257                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
3258                 if AC_TRY_EVAL(ac_compile); then
3259                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3260                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3261                 else
3262                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
3263                 fi
3264         done
3265         CXXFLAGS="$cf_save_CXXFLAGS"
3266 fi
3267
3268 rm -rf conftest*
3269 AC_LANG_RESTORE
3270 AC_SUBST(EXTRA_CXXFLAGS)
3271 ])dnl
3272 dnl ---------------------------------------------------------------------------
3273 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
3274 dnl ------------
3275 dnl Look for an instance of the Berkeley hashed database.
3276 dnl
3277 dnl $1 = optional parameter, to specify install-prefix for the database.
3278 AC_DEFUN([CF_HASHED_DB],
3279 [
3280 ifelse([$1],,,[
3281 case $1 in
3282 (yes|*able*)
3283         ;;
3284 (*)
3285         if test -d "$1" ; then
3286                 CF_ADD_INCDIR($1/include)
3287                 CF_ADD_LIBDIR($1/lib)
3288         else
3289                 case "$1" in
3290                 (./*|../*|/*)
3291                         AC_MSG_WARN(no such directory $1)
3292                         ;;
3293                 (*)
3294                         CF_FIND_SUB_INCDIR($1)
3295                         CF_FIND_SUB_LIBDIR($1)
3296                         ;;
3297                 esac
3298         fi
3299 esac
3300 ])
3301 AC_CHECK_HEADER(db.h,[
3302 CF_HASHED_DB_VERSION
3303 if test "$cf_cv_hashed_db_version" = unknown ; then
3304         AC_MSG_ERROR(Cannot determine version of db)
3305 else
3306         CF_HASHED_DB_LIBS
3307         if test "$cf_cv_hashed_db_libs" = unknown ; then
3308                 AC_MSG_ERROR(Cannot determine library for db)
3309         elif test "$cf_cv_hashed_db_libs" != default ; then
3310                 CF_ADD_LIB($cf_cv_hashed_db_libs)
3311         fi
3312 fi
3313 ],[
3314         AC_MSG_ERROR(Cannot find db.h)
3315 ])
3316 ])dnl
3317 dnl ---------------------------------------------------------------------------
3318 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
3319 dnl -----------------
3320 dnl Given that we have the header and version for hashed database, find the
3321 dnl library information.
3322 AC_DEFUN([CF_HASHED_DB_LIBS],
3323 [
3324 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
3325 cf_cv_hashed_db_libs=unknown
3326 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
3327 do
3328         cf_save_libs="$LIBS"
3329         if test -n "$cf_db_libs"; then
3330                 CF_ADD_LIB($cf_db_libs)
3331         fi
3332         CF_MSG_LOG(checking for library "$cf_db_libs")
3333         AC_TRY_LINK([
3334 $ac_includes_default
3335 #include <db.h>
3336 ],[
3337         char *path = "/tmp/foo";
3338 #ifdef DB_VERSION_MAJOR
3339 #if DB_VERSION_MAJOR >= 4
3340         DB *result = 0;
3341         db_create(&result, NULL, 0);
3342         result->open(result,
3343                 NULL,
3344                 path,
3345                 path,
3346                 DB_HASH,
3347                 DB_CREATE,
3348                 0644);
3349 #elif DB_VERSION_MAJOR >= 3
3350         DB *result = 0;
3351         db_create(&result, NULL, 0);
3352         result->open(result,
3353                 path,
3354                 path,
3355                 DB_HASH,
3356                 DB_CREATE,
3357                 0644);
3358 #elif DB_VERSION_MAJOR >= 2
3359         DB *result = 0;
3360         db_open(path,
3361                 DB_HASH,
3362                 DB_CREATE,
3363                 0644,
3364                 (DB_ENV *) 0,
3365                 (DB_INFO *) 0,
3366                 &result);
3367 #endif /* DB_VERSION_MAJOR */
3368 #else
3369         DB *result = dbopen(path,
3370                      2,
3371                      0644,
3372                      DB_HASH,
3373                      0);
3374 #endif
3375         ${cf_cv_main_return:-return}(result != 0)
3376 ],[
3377         if test -n "$cf_db_libs" ; then
3378                 cf_cv_hashed_db_libs=$cf_db_libs
3379         else
3380                 cf_cv_hashed_db_libs=default
3381         fi
3382         LIBS="$cf_save_libs"
3383         break
3384 ])
3385         LIBS="$cf_save_libs"
3386 done
3387 ])
3388 ])dnl
3389 dnl ---------------------------------------------------------------------------
3390 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
3391 dnl --------------------
3392 dnl Given that we have the header file for hashed database, find the version
3393 dnl information.
3394 AC_DEFUN([CF_HASHED_DB_VERSION],
3395 [
3396 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
3397 cf_cv_hashed_db_version=unknown
3398
3399 for cf_db_version in 1 2 3 4 5 6
3400 do
3401         CF_MSG_LOG(checking for db version $cf_db_version)
3402         AC_TRY_COMPILE([
3403 $ac_includes_default
3404 #include <db.h>
3405
3406 #ifdef DB_VERSION_MAJOR
3407         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
3408 #if $cf_db_version == DB_VERSION_MAJOR
3409         /* ok */
3410 #else
3411         make an error
3412 #endif
3413 #else
3414 #if $cf_db_version == 1
3415         /* ok: assuming this is DB 1.8.5 */
3416 #else
3417         make an error
3418 #endif
3419 #endif
3420 ],[DBT *foo = 0],[
3421         cf_cv_hashed_db_version=$cf_db_version
3422         break
3423         ])
3424 done
3425 ])
3426 ])dnl
3427 dnl ---------------------------------------------------------------------------
3428 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
3429 dnl --------------
3430 dnl Construct a search-list of directories for a nonstandard header-file
3431 dnl
3432 dnl Parameters
3433 dnl     $1 = the variable to return as result
3434 dnl     $2 = the package name
3435 AC_DEFUN([CF_HEADER_PATH],
3436 [
3437 $1=
3438
3439 # collect the current set of include-directories from compiler flags
3440 cf_header_path_list=""
3441 if test -n "${CFLAGS}${CPPFLAGS}" ; then
3442         for cf_header_path in $CPPFLAGS $CFLAGS
3443         do
3444                 case $cf_header_path in
3445                 (-I*)
3446                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
3447                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
3448                         cf_header_path_list="$cf_header_path_list [$]$1"
3449                         ;;
3450                 esac
3451         done
3452 fi
3453
3454 # add the variations for the package we are looking for
3455 CF_SUBDIR_PATH($1,$2,include)
3456
3457 test "$includedir" != NONE && \
3458 test "$includedir" != "/usr/include" && \
3459 test -d "$includedir" && {
3460         test -d $includedir &&    $1="[$]$1 $includedir"
3461         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
3462 }
3463
3464 test "$oldincludedir" != NONE && \
3465 test "$oldincludedir" != "/usr/include" && \
3466 test -d "$oldincludedir" && {
3467         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
3468         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
3469 }
3470
3471 $1="[$]$1 $cf_header_path_list"
3472 ])dnl
3473 dnl ---------------------------------------------------------------------------
3474 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
3475 dnl ---------------
3476 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
3477 AC_DEFUN([CF_HELP_MESSAGE],
3478 [AC_DIVERT_HELP([$1])dnl
3479 ])dnl
3480 dnl ---------------------------------------------------------------------------
3481 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
3482 dnl ---------------
3483 dnl Construct the list of include-options according to whether we're building
3484 dnl in the source directory or using '--srcdir=DIR' option.
3485 AC_DEFUN([CF_INCLUDE_DIRS],
3486 [
3487 if test "$srcdir" != "."; then
3488         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
3489 fi
3490 CPPFLAGS="-I../include $CPPFLAGS"
3491 if test "$srcdir" != "."; then
3492         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
3493 fi
3494 CPPFLAGS="-I. $CPPFLAGS"
3495 AC_SUBST(CPPFLAGS)
3496 ])dnl
3497 dnl ---------------------------------------------------------------------------
3498 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
3499 dnl ---------------
3500 dnl prompt for/fill-in useful install-program options
3501 AC_DEFUN([CF_INSTALL_OPTS],
3502 [
3503 CF_INSTALL_OPT_S
3504 CF_INSTALL_OPT_P
3505 CF_INSTALL_OPT_O
3506 ])dnl
3507 dnl ---------------------------------------------------------------------------
3508 dnl CF_INSTALL_OPT_O version: 2 updated: 2015/05/15 19:45:35
3509 dnl ----------------
3510 dnl Almost all "install" programs default to the current user's ownership.
3511 dnl Almost - MINIX is an exception.
3512 AC_DEFUN([CF_INSTALL_OPT_O],
3513 [
3514 AC_MSG_CHECKING(if install needs to be told about ownership)
3515 case `$ac_config_guess` in
3516 (*minix)
3517         with_install_o=yes
3518         ;;
3519 (*)
3520         with_install_o=no
3521         ;;
3522 esac
3523
3524 AC_MSG_RESULT($with_install_o)
3525 if test "x$with_install_o" = xyes
3526 then
3527         INSTALL_OPT_O=`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`
3528 else
3529         INSTALL_OPT_O=
3530 fi
3531
3532 AC_SUBST(INSTALL_OPT_O)
3533 ])dnl
3534 dnl ---------------------------------------------------------------------------
3535 dnl CF_INSTALL_OPT_P version: 1 updated: 2018/08/18 12:19:21
3536 dnl ----------------
3537 dnl Some install-programs accept a "-p" option to preserve file modification
3538 dnl timestamps.  That can be useful as an install option, as well as a way to
3539 dnl avoid the need for ranlib after copying a static archive.
3540 AC_DEFUN([CF_INSTALL_OPT_P],
3541 [
3542 : ${INSTALL:=install}
3543 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
3544         rm -rf conftest*
3545         date >conftest.in
3546         mkdir conftest.out
3547         sleep 3
3548         if $INSTALL -p conftest.in conftest.out 2>/dev/null
3549         then
3550                 if test -f conftest.out/conftest.in
3551                 then
3552                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
3553                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
3554                         if test -s conftest.err
3555                         then
3556                                 cf_cv_install_p=no
3557                         else
3558                                 cf_cv_install_p=yes
3559                         fi
3560                 else
3561                         cf_cv_install_p=no
3562                 fi
3563         else
3564                 cf_cv_install_p=no
3565         fi
3566         rm -rf conftest*
3567 ])
3568 ])dnl
3569 dnl ---------------------------------------------------------------------------
3570 dnl CF_INSTALL_OPT_S version: 2 updated: 2018/08/18 12:19:21
3571 dnl ----------------
3572 dnl By default, we should strip executables which are installed, but leave the
3573 dnl ability to suppress that for unit-testing.
3574 AC_DEFUN([CF_INSTALL_OPT_S],
3575 [
3576 AC_MSG_CHECKING(if you want to install stripped executables)
3577 CF_ARG_DISABLE(stripping,
3578         [  --disable-stripping     do not strip (debug info) installed executables],
3579         [with_stripping=no],
3580         [with_stripping=yes])
3581 AC_MSG_RESULT($with_stripping)
3582
3583 if test "$with_stripping" = yes
3584 then
3585         INSTALL_OPT_S="-s"
3586 else
3587         INSTALL_OPT_S=
3588 fi
3589 AC_SUBST(INSTALL_OPT_S)
3590 ])dnl
3591 dnl ---------------------------------------------------------------------------
3592 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
3593 dnl -----------------
3594 dnl Check if the given compiler is really the Intel compiler for Linux.  It
3595 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
3596 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
3597 dnl
3598 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
3599 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
3600 dnl the wrappers for gcc and g++ warnings.
3601 dnl
3602 dnl $1 = GCC (default) or GXX
3603 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
3604 dnl $3 = CFLAGS (default) or CXXFLAGS
3605 AC_DEFUN([CF_INTEL_COMPILER],[
3606 AC_REQUIRE([AC_CANONICAL_HOST])
3607 ifelse([$2],,INTEL_COMPILER,[$2])=no
3608
3609 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
3610         case $host_os in
3611         (linux*|gnu*)
3612                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
3613                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
3614                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
3615                 AC_TRY_COMPILE([],[
3616 #ifdef __INTEL_COMPILER
3617 #else
3618 make an error
3619 #endif
3620 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
3621 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
3622 ],[])
3623                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
3624                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
3625                 ;;
3626         esac
3627 fi
3628 ])dnl
3629 dnl ---------------------------------------------------------------------------
3630 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
3631 dnl ----------
3632 dnl Check if we have either a function or macro for 'isascii()'.
3633 AC_DEFUN([CF_ISASCII],
3634 [
3635 AC_MSG_CHECKING(for isascii)
3636 AC_CACHE_VAL(cf_cv_have_isascii,[
3637         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
3638         [cf_cv_have_isascii=yes],
3639         [cf_cv_have_isascii=no])
3640 ])dnl
3641 AC_MSG_RESULT($cf_cv_have_isascii)
3642 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
3643 ])dnl
3644 dnl ---------------------------------------------------------------------------
3645 dnl CF_LARGEFILE version: 11 updated: 2018/06/20 20:23:13
3646 dnl ------------
3647 dnl Add checks for large file support.
3648 AC_DEFUN([CF_LARGEFILE],[
3649 ifdef([AC_FUNC_FSEEKO],[
3650         AC_SYS_LARGEFILE
3651         if test "$enable_largefile" != no ; then
3652         AC_FUNC_FSEEKO
3653
3654         # Normally we would collect these definitions in the config.h,
3655         # but (like _XOPEN_SOURCE), some environments rely on having these
3656         # defined before any of the system headers are included.  Another
3657         # case comes up with C++, e.g., on AIX the compiler compiles the
3658         # header files by themselves before looking at the body files it is
3659         # told to compile.  For ncurses, those header files do not include
3660         # the config.h
3661         if test "$ac_cv_sys_large_files" != no
3662         then
3663                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
3664         fi
3665         if test "$ac_cv_sys_largefile_source" != no
3666         then
3667                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
3668         fi
3669         if test "$ac_cv_sys_file_offset_bits" != no
3670         then
3671                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
3672         fi
3673
3674         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
3675                 AC_TRY_COMPILE([
3676 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
3677 #include <sys/types.h>
3678 #include <dirent.h>
3679                 ],[
3680                 /* if transitional largefile support is setup, this is true */
3681                 extern struct dirent64 * readdir(DIR *);
3682                 struct dirent64 *x = readdir((DIR *)0);
3683                 struct dirent *y = readdir((DIR *)0);
3684                 int z = x - y;
3685                 ],
3686                 [cf_cv_struct_dirent64=yes],
3687                 [cf_cv_struct_dirent64=no])
3688         ])
3689         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
3690         fi
3691 ])
3692 ])
3693 dnl ---------------------------------------------------------------------------
3694 dnl CF_LDFLAGS_STATIC version: 12 updated: 2015/04/18 08:56:57
3695 dnl -----------------
3696 dnl Check for compiler/linker flags used to temporarily force usage of static
3697 dnl libraries.  This depends on the compiler and platform.  Use this to help
3698 dnl ensure that the linker picks up a given library based on its position in
3699 dnl the list of linker options and libraries.
3700 AC_DEFUN([CF_LDFLAGS_STATIC],[
3701
3702 if test "$GCC" = yes ; then
3703         case $cf_cv_system_name in
3704         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
3705                 LDFLAGS_STATIC=
3706                 LDFLAGS_SHARED=
3707                 ;;
3708         (*)     # normally, except when broken
3709                 LDFLAGS_STATIC=-static
3710                 LDFLAGS_SHARED=-dynamic
3711                 ;;
3712         esac
3713 else
3714         case $cf_cv_system_name in
3715         (aix[[4-7]]*)   # from ld manpage
3716                 LDFLAGS_STATIC=-bstatic
3717                 LDFLAGS_SHARED=-bdynamic
3718                 ;;
3719         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
3720                 # We could also use just "archive" and "shared".
3721                 LDFLAGS_STATIC=-Wl,-a,archive_shared
3722                 LDFLAGS_SHARED=-Wl,-a,shared_archive
3723                 ;;
3724         (irix*)         # from ld manpage IRIX64
3725                 LDFLAGS_STATIC=-Bstatic
3726                 LDFLAGS_SHARED=-Bdynamic
3727                 ;;
3728         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
3729                 # alternative "-oldstyle_liblookup" (not in cc manpage)
3730                 LDFLAGS_STATIC=-noso
3731                 LDFLAGS_SHARED=-so_archive
3732                 ;;
3733         (solaris2*)
3734                 LDFLAGS_STATIC=-Bstatic
3735                 LDFLAGS_SHARED=-Bdynamic
3736                 ;;
3737         esac
3738 fi
3739
3740 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
3741 then
3742         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
3743
3744         rm -f libconftest.a
3745         cat >conftest.$ac_ext <<EOF
3746 #line __oline__ "configure"
3747 #include <stdio.h>
3748 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
3749 EOF
3750         if AC_TRY_EVAL(ac_compile) ; then
3751                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
3752                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
3753         fi
3754         rm -f conftest.*
3755
3756         cf_save_LIBS="$LIBS"
3757
3758         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
3759         AC_TRY_LINK([
3760 #line __oline__ "configure"
3761 #include <stdio.h>
3762 int cf_ldflags_static(FILE *fp);
3763 ],[
3764         return cf_ldflags_static(stdin);
3765 ],[
3766         # some linkers simply ignore the -dynamic
3767         case x`file conftest$ac_exeext 2>/dev/null` in
3768         (*static*)
3769                 cf_ldflags_static=no
3770                 ;;
3771         (*)
3772                 cf_ldflags_static=yes
3773                 ;;
3774         esac
3775 ],[cf_ldflags_static=no])
3776
3777         rm -f libconftest.*
3778         LIBS="$cf_save_LIBS"
3779
3780         AC_MSG_RESULT($cf_ldflags_static)
3781
3782         if test $cf_ldflags_static != yes
3783         then
3784                 LDFLAGS_STATIC=
3785                 LDFLAGS_SHARED=
3786         fi
3787 else
3788         LDFLAGS_STATIC=
3789         LDFLAGS_SHARED=
3790 fi
3791
3792 AC_SUBST(LDFLAGS_STATIC)
3793 AC_SUBST(LDFLAGS_SHARED)
3794 ])
3795 dnl ---------------------------------------------------------------------------
3796 dnl CF_LD_RPATH_OPT version: 8 updated: 2018/08/18 16:36:35
3797 dnl ---------------
3798 dnl For the given system and compiler, find the compiler flags to pass to the
3799 dnl loader to use the "rpath" feature.
3800 AC_DEFUN([CF_LD_RPATH_OPT],
3801 [
3802 AC_REQUIRE([CF_CHECK_CACHE])
3803
3804 LD_RPATH_OPT=
3805 if test "x$cf_cv_enable_rpath" != xno
3806 then
3807         AC_MSG_CHECKING(for an rpath option)
3808         case $cf_cv_system_name in
3809         (irix*)
3810                 if test "$GCC" = yes; then
3811                         LD_RPATH_OPT="-Wl,-rpath,"
3812                 else
3813                         LD_RPATH_OPT="-rpath "
3814                 fi
3815                 ;;
3816         (linux*|gnu*|k*bsd*-gnu|freebsd*)
3817                 LD_RPATH_OPT="-Wl,-rpath,"
3818                 ;;
3819         (openbsd[[2-9]].*|mirbsd*)
3820                 LD_RPATH_OPT="-Wl,-rpath,"
3821                 ;;
3822         (dragonfly*)
3823                 LD_RPATH_OPT="-rpath "
3824                 ;;
3825         (netbsd*)
3826                 LD_RPATH_OPT="-Wl,-rpath,"
3827                 ;;
3828         (osf*|mls+*)
3829                 LD_RPATH_OPT="-rpath "
3830                 ;;
3831         (solaris2*)
3832                 LD_RPATH_OPT="-R"
3833                 ;;
3834         (*)
3835                 ;;
3836         esac
3837         AC_MSG_RESULT($LD_RPATH_OPT)
3838
3839         case "x$LD_RPATH_OPT" in
3840         (x-R*)
3841                 AC_MSG_CHECKING(if we need a space after rpath option)
3842                 cf_save_LIBS="$LIBS"
3843                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3844                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3845                 LIBS="$cf_save_LIBS"
3846                 AC_MSG_RESULT($cf_rpath_space)
3847                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3848                 ;;
3849         esac
3850 fi
3851 ])dnl
3852 dnl ---------------------------------------------------------------------------
3853 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
3854 dnl ---------------
3855 dnl Construct a search-list of directories for a nonstandard library-file
3856 dnl
3857 dnl Parameters
3858 dnl     $1 = the variable to return as result
3859 dnl     $2 = the package name
3860 AC_DEFUN([CF_LIBRARY_PATH],
3861 [
3862 $1=
3863 cf_library_path_list=""
3864 if test -n "${LDFLAGS}${LIBS}" ; then
3865         for cf_library_path in $LDFLAGS $LIBS
3866         do
3867                 case $cf_library_path in
3868                 (-L*)
3869                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3870                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3871                         cf_library_path_list="$cf_library_path_list [$]$1"
3872                         ;;
3873                 esac
3874         done
3875 fi
3876
3877 CF_SUBDIR_PATH($1,$2,lib)
3878
3879 $1="$cf_library_path_list [$]$1"
3880 ])dnl
3881 dnl ---------------------------------------------------------------------------
3882 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
3883 dnl ------------------
3884 AC_DEFUN([CF_LIBTOOL_VERSION],[
3885 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
3886 then
3887         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
3888 else
3889         cf_cv_libtool_version=
3890 fi
3891 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
3892 ])dnl
3893 dnl ---------------------------------------------------------------------------
3894 dnl CF_LIB_PREFIX version: 12 updated: 2015/10/17 19:03:33
3895 dnl -------------
3896 dnl Compute the library-prefix for the given host system
3897 dnl $1 = variable to set
3898 define([CF_LIB_PREFIX],
3899 [
3900         case $cf_cv_system_name in
3901         (OS/2*|os2*)
3902                 if test "$DFT_LWR_MODEL" = libtool; then
3903                         LIB_PREFIX='lib'
3904                 else
3905                         LIB_PREFIX=''
3906                 fi
3907                 ;;
3908         (*)     LIB_PREFIX='lib'
3909                 ;;
3910         esac
3911 ifelse($1,,,[$1=$LIB_PREFIX])
3912         AC_SUBST(LIB_PREFIX)
3913 ])dnl
3914 dnl ---------------------------------------------------------------------------
3915 dnl CF_LIB_RULES version: 88 updated: 2018/08/18 12:19:21
3916 dnl ------------
3917 dnl Append definitions and rules for the given models to the subdirectory
3918 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3919 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
3920 dnl the corresponding makefile to list the models that we'll generate.
3921 dnl
3922 dnl For shared libraries, make a list of symbolic links to construct when
3923 dnl generating each library.  The convention used for Linux is the simplest
3924 dnl one:
3925 dnl     lib<name>.so    ->
3926 dnl     lib<name>.so.<major>    ->
3927 dnl     lib<name>.so.<maj>.<minor>
3928 dnl
3929 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
3930 AC_DEFUN([CF_LIB_RULES],
3931 [
3932 cf_prefix=$LIB_PREFIX
3933 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3934
3935 case $cf_cv_shlib_version in
3936 (cygdll|msysdll|mingw)
3937         TINFO_NAME=$TINFO_ARG_SUFFIX
3938         TINFO_SUFFIX=.dll
3939         ;;
3940 esac
3941
3942 if test -n "$TINFO_SUFFIX" ; then
3943         case $TINFO_SUFFIX in
3944         (tw*)
3945                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
3946                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw'$EXTRA_SUFFIX'//'`
3947                 ;;
3948         (t*)
3949                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
3950                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t'$EXTRA_SUFFIX'//'`
3951                 ;;
3952         (w*)
3953                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
3954                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w'$EXTRA_SUFFIX'//'`
3955                 ;;
3956         esac
3957 fi
3958
3959 for cf_dir in $SRC_SUBDIRS
3960 do
3961         if test ! -d $srcdir/$cf_dir ; then
3962                 continue
3963         elif test -f $srcdir/$cf_dir/modules; then
3964
3965                 SHARED_LIB=
3966                 Libs_To_Make=
3967                 cf_awk_program=
3968                 if test -n "${cf_cv_abi_version}" && test "x${cf_cv_abi_version}" != "x5"
3969                 then
3970                         cf_awk_program="$cf_awk_program\
3971 /deprecated in ABI${cf_cv_abi_version}/ { next; }\
3972 { sub(\"NCURSES([[WT]]+)?\", \"&${cf_cv_abi_version}\"); }\
3973 "
3974                 fi
3975
3976                 if test "x$WILDCARD_SYMS" = xno
3977                 then
3978                         cf_awk_program="$cf_awk_program\
3979 /[[     ]]_\\*;/ { skip=1; next; }\
3980 "
3981                 fi
3982
3983                 if test "x$cf_awk_program" != "x"
3984                 then
3985                         cat >>$cf_dir/Makefile <<CF_EOF
3986
3987 # Generated by CF_LIB_RULES
3988 resulting.map: $UNALTERED_SYMS
3989         $AWK 'BEGIN { skip = 1; last=""; } \
3990 $cf_awk_program \
3991 { if ( last != "" && ( skip == 0 || \[$]\[$]0 !~ /}/ ) ) { print last; }\
3992  skip = 0; last = \[$]\[$]0; } \
3993 END { print last; }' < $UNALTERED_SYMS >\[$]@
3994
3995 distclean::
3996         rm -f resulting.map
3997 CF_EOF
3998                 fi
3999
4000                 for cf_item in $cf_LIST_MODELS
4001                 do
4002                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
4003                         cf_libname=$cf_dir
4004                         test "$cf_dir" = c++ && cf_libname=ncurses++
4005                         if test $cf_item = shared ; then
4006                                 if test -n "${LIB_SUFFIX}"
4007                                 then
4008                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
4009                                 else
4010                                         cf_shared_suffix="$cf_suffix"
4011                                 fi
4012                                 if test "$cf_cv_do_symlinks" = yes ; then
4013                                         cf_version_name=
4014
4015                                         case "$cf_cv_shlib_version" in
4016                                         (rel)
4017                                                 cf_version_name=REL_VERSION
4018                                                 ;;
4019                                         (abi)
4020                                                 cf_version_name=ABI_VERSION
4021                                                 ;;
4022                                         esac
4023
4024                                         if test -n "$cf_version_name"
4025                                         then
4026                                                 case "$cf_cv_system_name" in
4027                                                 (darwin*)
4028                                                         # "w", etc?
4029                                                         cf_suffix="${USE_LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
4030                                                         ;;
4031                                                 (*)
4032                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
4033                                                         ;;
4034                                                 esac
4035                                         fi
4036                                         if test -n "${USE_LIB_SUFFIX}"
4037                                         then
4038                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
4039                                         else
4040                                                 cf_shared_suffix="$cf_suffix"
4041                                         fi
4042                                 fi
4043                                 # cygwin needs import library, and has unique naming convention
4044                                 # use autodetected ${cf_prefix} for import lib and static lib, but
4045                                 # use 'cyg' prefix for shared lib.
4046                                 case $cf_cv_shlib_version in
4047                                 (cygdll)
4048                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4049                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
4050                                         ;;
4051                                 (msysdll)
4052                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4053                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
4054                                         ;;
4055                                 (mingw)
4056                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4057                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
4058                                         ;;
4059                                 (*)
4060                                         cf_add_lib=
4061                                         ;;
4062                                 esac
4063                                 if test -n "$cf_add_lib"
4064                                 then
4065                                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
4066                                         continue
4067                                 fi
4068                         fi
4069                         cf_add_lib="../lib/${cf_prefix}${cf_libname}${cf_suffix}"
4070                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
4071                 done
4072
4073                 if test $cf_dir = ncurses ; then
4074                         cf_subsets="$LIB_SUBSETS"
4075                         cf_r_parts="$cf_subsets"
4076                         cf_liblist="$Libs_To_Make"
4077
4078                         while test -n "$cf_r_parts"
4079                         do
4080                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
4081                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
4082                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
4083                                         cf_add_lib=
4084                                         case $cf_l_parts in
4085                                         (*termlib*)
4086                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
4087                                                 ;;
4088                                         (*ticlib*)
4089                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
4090                                                 ;;
4091                                         (*)
4092                                                 break
4093                                                 ;;
4094                                         esac
4095                                         if test -n "$cf_add_lib"; then
4096                                                 Libs_To_Make="$cf_add_lib $Libs_To_Make"
4097                                         fi
4098                                 else
4099                                         break
4100                                 fi
4101                         done
4102                 else
4103                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
4104                 fi
4105
4106                 if test $cf_dir = c++; then
4107                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
4108                                 cf_list=
4109                                 for cf_item in $Libs_To_Make
4110                                 do
4111                                         case $cf_item in
4112                                         (*.a)
4113                                                 ;;
4114                                         (*)
4115                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
4116                                                 ;;
4117                                         esac
4118                                         for cf_test in $cf_list
4119                                         do
4120                                                 if test "$cf_test" = "$cf_item"
4121                                                 then
4122                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
4123                                                         cf_item=
4124                                                         break
4125                                                 fi
4126                                         done
4127                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
4128                                 done
4129                                 Libs_To_Make="$cf_list"
4130                         fi
4131                 fi
4132
4133                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
4134                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
4135                         $cf_dir/Makefile >$cf_dir/Makefile.out
4136                 mv $cf_dir/Makefile.out $cf_dir/Makefile
4137
4138                 $AWK -f $srcdir/mk-0th.awk \
4139                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
4140                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
4141
4142                 for cf_subset in $cf_subsets
4143                 do
4144                         cf_subdirs=
4145                         for cf_item in $cf_LIST_MODELS
4146                         do
4147
4148                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
4149                         CF_UPPER(cf_ITEM,$cf_item)
4150
4151                         CXX_MODEL=$cf_ITEM
4152                         if test "$CXX_MODEL" = SHARED; then
4153                                 case $cf_cv_shlib_version in
4154                                 (cygdll|msysdll|mingw)
4155                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
4156                                         with_shared_cxx=yes
4157                                         ;;
4158                                 (*)
4159                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
4160                                         ;;
4161                                 esac
4162                         fi
4163
4164                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
4165                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
4166
4167                         # Test for case where we build libtinfo with a different name.
4168                         cf_libname=$cf_dir
4169                         if test $cf_dir = ncurses ; then
4170                                 case $cf_subset in
4171                                 (*base*)
4172                                         cf_libname=${cf_libname}$USE_LIB_SUFFIX
4173                                         ;;
4174                                 (*termlib*)
4175                                         cf_libname=$TINFO_LIB_SUFFIX
4176                                         ;;
4177                                 (ticlib*)
4178                                         cf_libname=$TICS_LIB_SUFFIX
4179                                         ;;
4180                                 esac
4181                         elif test $cf_dir = c++ ; then
4182                                 cf_libname=ncurses++$USE_LIB_SUFFIX
4183                         else
4184                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
4185                         fi
4186                         if test -n "${USE_ARG_SUFFIX}" ; then
4187                                 # undo $USE_LIB_SUFFIX add-on in CF_LIB_SUFFIX
4188                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${USE_LIB_SUFFIX}%%"`
4189                         fi
4190
4191                         # These dependencies really are for development, not
4192                         # builds, but they are useful in porting, too.
4193                         cf_depend="../include/ncurses_cfg.h"
4194                         if test "$srcdir" = "."; then
4195                                 cf_reldir="."
4196                         else
4197                                 cf_reldir="\${srcdir}"
4198                         fi
4199
4200                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
4201                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
4202                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
4203                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
4204                         fi
4205
4206                         cf_dir_suffix=
4207                         old_cf_suffix="$cf_suffix"
4208                         if test "$cf_cv_shlib_version_infix" = yes ; then
4209                         if test -n "$USE_LIB_SUFFIX" ; then
4210                                 case $USE_LIB_SUFFIX in
4211                                 (tw*)
4212                                         cf_libname=`echo $cf_libname | sed 's/tw'$EXTRA_SUFFIX'$//'`
4213                                         cf_suffix=`echo $cf_suffix | sed 's/^tw'$EXTRA_SUFFIX'//'`
4214                                         cf_dir_suffix=tw$EXTRA_SUFFIX
4215                                         ;;
4216                                 (t*)
4217                                         cf_libname=`echo $cf_libname | sed 's/t'$EXTRA_SUFFIX'$//'`
4218                                         cf_suffix=`echo $cf_suffix | sed 's/^t'$EXTRA_SUFFIX'//'`
4219                                         cf_dir_suffix=t$EXTRA_SUFFIX
4220                                         ;;
4221                                 (w*)
4222                                         cf_libname=`echo $cf_libname | sed 's/w'$EXTRA_SUFFIX'$//'`
4223                                         cf_suffix=`echo $cf_suffix | sed 's/^w'$EXTRA_SUFFIX'//'`
4224                                         cf_dir_suffix=w$EXTRA_SUFFIX
4225                                         ;;
4226                                 (*)
4227                                         cf_libname=`echo $cf_libname | sed 's/'$EXTRA_SUFFIX'$//'`
4228                                         cf_suffix=`echo $cf_suffix | sed 's/^'$EXTRA_SUFFIX'//'`
4229                                         cf_dir_suffix=$EXTRA_SUFFIX
4230                                         ;;
4231                                 esac
4232                         fi
4233                         fi
4234
4235                         $AWK -f $srcdir/mk-1st.awk \
4236                                 name=${cf_libname}${cf_dir_suffix} \
4237                                 traces=$LIB_TRACING \
4238                                 MODEL=$cf_ITEM \
4239                                 CXX_MODEL=$CXX_MODEL \
4240                                 model=$cf_subdir \
4241                                 prefix=$cf_prefix \
4242                                 suffix=$cf_suffix \
4243                                 subset=$cf_subset \
4244                                 driver=$cf_cv_term_driver \
4245                                 SymLink="$LN_S" \
4246                                 TermlibRoot=$TINFO_NAME \
4247                                 TermlibSuffix=$TINFO_SUFFIX \
4248                                 ShlibVer=$cf_cv_shlib_version \
4249                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
4250                                 ReLink=${cf_cv_do_relink:-no} \
4251                                 ReRanlib=${cf_cv_do_reranlib:-yes} \
4252                                 DoLinks=$cf_cv_do_symlinks \
4253                                 rmSoLocs=$cf_cv_rm_so_locs \
4254                                 ldconfig="$LDCONFIG" \
4255                                 overwrite=$WITH_OVERWRITE \
4256                                 depend="$cf_depend" \
4257                                 host="$host" \
4258                                 libtool_version="$LIBTOOL_VERSION" \
4259                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
4260
4261                         cf_suffix="$old_cf_suffix"
4262
4263                         for cf_subdir2 in $cf_subdirs lib
4264                         do
4265                                 test $cf_subdir = $cf_subdir2 && break
4266                         done
4267                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
4268                         $AWK -f $srcdir/mk-2nd.awk \
4269                                 name=$cf_dir \
4270                                 traces=$LIB_TRACING \
4271                                 MODEL=$cf_ITEM \
4272                                 model=$cf_subdir \
4273                                 subset=$cf_subset \
4274                                 srcdir=$srcdir \
4275                                 echo=$WITH_ECHO \
4276                                 crenames=$cf_cv_prog_CC_c_o \
4277                                 cxxrenames=$cf_cv_prog_CXX_c_o \
4278                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
4279                         cf_subdirs="$cf_subdirs $cf_subdir"
4280                         done
4281                 done
4282         fi
4283
4284         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
4285 done
4286
4287 for cf_dir in $SRC_SUBDIRS
4288 do
4289         if test ! -d $srcdir/$cf_dir ; then
4290                 continue
4291         fi
4292
4293         if test -f $cf_dir/Makefile ; then
4294                 case "$cf_dir" in
4295                 (Ada95)
4296                         echo 'libs \' >> Makefile
4297                         echo 'install.libs \' >> Makefile
4298                         echo 'uninstall.libs ::' >> Makefile
4299                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
4300                         ;;
4301                 esac
4302         fi
4303
4304         if test -f $srcdir/$cf_dir/modules; then
4305                 echo >> Makefile
4306                 if test -f $srcdir/$cf_dir/headers; then
4307 cat >> Makefile <<CF_EOF
4308 install.includes \\
4309 uninstall.includes \\
4310 CF_EOF
4311                 fi
4312 if test "$cf_dir" != "c++" ; then
4313 echo 'lint \' >> Makefile
4314 fi
4315 cat >> Makefile <<CF_EOF
4316 libs \\
4317 lintlib \\
4318 install.libs \\
4319 uninstall.libs \\
4320 install.$cf_dir \\
4321 uninstall.$cf_dir ::
4322         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
4323 CF_EOF
4324         elif test -f $srcdir/$cf_dir/headers; then
4325 cat >> Makefile <<CF_EOF
4326
4327 libs \\
4328 install.libs \\
4329 uninstall.libs \\
4330 install.includes \\
4331 uninstall.includes ::
4332         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
4333 CF_EOF
4334 fi
4335 done
4336
4337 if test "x$cf_with_db_install" = xyes; then
4338 cat >> Makefile <<CF_EOF
4339
4340 install.libs uninstall.libs \\
4341 install.data uninstall.data ::
4342 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
4343 CF_EOF
4344 else
4345 cat >> Makefile <<CF_EOF
4346
4347 install.libs uninstall.libs ::
4348         cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
4349 CF_EOF
4350 fi
4351
4352 if test "x$cf_with_manpages" = xyes; then
4353 cat >> Makefile <<CF_EOF
4354
4355 install.man \\
4356 uninstall.man ::
4357         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
4358 CF_EOF
4359 fi
4360
4361 cat >> Makefile <<CF_EOF
4362
4363 distclean ::
4364         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
4365         rm -f headers.sh headers.sed mk_shared_lib.sh
4366         rm -f edit_man.* man_alias.*
4367         rm -rf \${DIRS_TO_MAKE}
4368 CF_EOF
4369
4370 # Special case: tack's manpage lives in its own directory.
4371 if test "x$cf_with_manpages" = xyes; then
4372 if test "x$cf_with_tack" = "xyes"; then
4373 cat >> Makefile <<CF_EOF
4374
4375 install.man \\
4376 uninstall.man ::
4377         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
4378 CF_EOF
4379 fi
4380 fi
4381
4382 dnl If we're installing into a subdirectory of /usr/include, etc., we should
4383 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
4384 dnl anything, and will make it more standardized.  It's awkward to decide this
4385 dnl at configuration because of quoting, so we'll simply make all headers
4386 dnl installed via a script that can do the right thing.
4387
4388 rm -f headers.sed headers.sh
4389
4390 dnl ( generating this script makes the makefiles a little tidier :-)
4391 echo creating headers.sh
4392 cat >headers.sh <<CF_EOF
4393 #! $SHELL
4394 # This shell script is generated by the 'configure' script.  It is invoked in a
4395 # subdirectory of the build tree.  It generates a sed-script in the parent
4396 # directory that is used to adjust includes for header files that reside in a
4397 # subdirectory of /usr/include, etc.
4398 PRG=""
4399 while test \[$]# != 3
4400 do
4401 PRG="\$PRG \[$]1"; shift
4402 done
4403 DST=\[$]1
4404 REF=\[$]2
4405 SRC=\[$]3
4406 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
4407 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
4408 echo installing \$SRC in \$DST
4409 CF_EOF
4410
4411 if test $WITH_CURSES_H = yes; then
4412         cat >>headers.sh <<CF_EOF
4413 case \$DST in
4414 (/*/include/*)
4415         END=\`basename \$DST\`
4416         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
4417         do
4418                 NAME=\`basename \$i\`
4419                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
4420         done
4421         ;;
4422 (*)
4423         echo "" >> \$TMPSED
4424         ;;
4425 esac
4426 CF_EOF
4427
4428 else
4429         cat >>headers.sh <<CF_EOF
4430 case \$DST in
4431 (/*/include/*)
4432         END=\`basename \$DST\`
4433         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
4434         do
4435                 NAME=\`basename \$i\`
4436                 if test "\$NAME" = "curses.h"
4437                 then
4438                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
4439                         NAME=ncurses.h
4440                 fi
4441                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
4442         done
4443         ;;
4444 (*)
4445         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
4446         ;;
4447 esac
4448 CF_EOF
4449 fi
4450 cat >>headers.sh <<CF_EOF
4451 rm -f \$TMPSRC
4452 sed -f \$TMPSED \$SRC > \$TMPSRC
4453 NAME=\`basename \$SRC\`
4454 CF_EOF
4455 if test $WITH_CURSES_H != yes; then
4456         cat >>headers.sh <<CF_EOF
4457 test "\$NAME" = "curses.h" && NAME=ncurses.h
4458 CF_EOF
4459 fi
4460 cat >>headers.sh <<CF_EOF
4461 # Just in case someone gzip'd manpages, remove the conflicting copy.
4462 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
4463
4464 eval \$PRG \$TMPSRC \$DST/\$NAME
4465 rm -f \$TMPSRC \$TMPSED
4466 CF_EOF
4467
4468 chmod 0755 headers.sh
4469
4470 for cf_dir in $SRC_SUBDIRS
4471 do
4472         if test ! -d $srcdir/$cf_dir ; then
4473                 continue
4474         fi
4475
4476         if test -f $srcdir/$cf_dir/headers; then
4477                 $AWK -f $srcdir/mk-hdr.awk \
4478                         subset="$LIB_SUBSETS" \
4479                         compat="$WITH_CURSES_H" \
4480                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
4481         fi
4482
4483         if test -f $srcdir/$cf_dir/modules; then
4484                 if test "$cf_dir" != "c++" ; then
4485                         cat >>$cf_dir/Makefile <<"CF_EOF"
4486 depend : ${AUTO_SRC}
4487         makedepend -- ${CPPFLAGS} -- ${C_SRC}
4488
4489 # DO NOT DELETE THIS LINE -- make depend depends on it.
4490 CF_EOF
4491                 fi
4492         fi
4493 done
4494 AC_SUBST(Libs_To_Make)
4495 ])dnl
4496 dnl ---------------------------------------------------------------------------
4497 dnl CF_LIB_SONAME version: 6 updated: 2017/01/21 11:06:25
4498 dnl -------------
4499 dnl Find the and soname for the given shared library.  Set the cache variable
4500 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
4501 dnl variable to "unknown".
4502 dnl
4503 dnl $1 = headers
4504 dnl $2 = code
4505 dnl $3 = library name
4506 AC_DEFUN([CF_LIB_SONAME],
4507 [
4508 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
4509
4510 cf_cv_$3_soname=unknown
4511 if test "$cross_compiling" != yes ; then
4512 cat >conftest.$ac_ext <<CF_EOF
4513 $1
4514 int main(void)
4515 {
4516 $2
4517         ${cf_cv_main_return:-return}(0);
4518 }
4519 CF_EOF
4520 cf_save_LIBS="$LIBS"
4521         CF_ADD_LIB($3)
4522         if AC_TRY_EVAL(ac_compile) ; then
4523                 if AC_TRY_EVAL(ac_link) ; then
4524                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
4525                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
4526                 fi
4527         fi
4528 rm -rf conftest*
4529 LIBS="$cf_save_LIBS"
4530 fi
4531 ])
4532 ])
4533 dnl ---------------------------------------------------------------------------
4534 dnl CF_LIB_SUFFIX version: 25 updated: 2015/04/17 21:13:04
4535 dnl -------------
4536 dnl Compute the library file-suffix from the given model name
4537 dnl $1 = model name
4538 dnl $2 = variable to set (the nominal library suffix)
4539 dnl $3 = dependency variable to set (actual filename)
4540 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4541 AC_DEFUN([CF_LIB_SUFFIX],
4542 [
4543         case X$1 in
4544         (Xlibtool)
4545                 $2='.la'
4546                 $3=[$]$2
4547                 ;;
4548         (Xdebug)
4549                 $2='_g.a'
4550                 $3=[$]$2
4551                 ;;
4552         (Xprofile)
4553                 $2='_p.a'
4554                 $3=[$]$2
4555                 ;;
4556         (Xshared)
4557                 case $cf_cv_system_name in
4558                 (aix[[5-7]]*)
4559                         $2='.so'
4560                         $3=[$]$2
4561                         ;;
4562                 (cygwin*|msys*|mingw*)
4563                         $2='.dll'
4564                         $3='.dll.a'
4565                         ;;
4566                 (darwin*)
4567                         $2='.dylib'
4568                         $3=[$]$2
4569                         ;;
4570                 (hpux*)
4571                         case $target in
4572                         (ia64*)
4573                                 $2='.so'
4574                                 $3=[$]$2
4575                                 ;;
4576                         (*)
4577                                 $2='.sl'
4578                                 $3=[$]$2
4579                                 ;;
4580                         esac
4581                         ;;
4582                 (*)
4583                         $2='.so'
4584                         $3=[$]$2
4585                         ;;
4586                 esac
4587                 ;;
4588         (*)
4589                 $2='.a'
4590                 $3=[$]$2
4591                 ;;
4592         esac
4593         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
4594         then
4595                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
4596                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
4597         fi
4598 ])dnl
4599 dnl ---------------------------------------------------------------------------
4600 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
4601 dnl -----------
4602 dnl Compute the string to append to -library from the given model name
4603 dnl $1 = model name
4604 dnl $2 = variable to set
4605 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4606 AC_DEFUN([CF_LIB_TYPE],
4607 [
4608         case $1 in
4609         (libtool) $2=''   ;;
4610         (normal)  $2=''   ;;
4611         (debug)   $2='_g' ;;
4612         (profile) $2='_p' ;;
4613         (shared)  $2=''   ;;
4614         esac
4615         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
4616 ])dnl
4617 dnl ---------------------------------------------------------------------------
4618 dnl CF_LINK_DATAONLY version: 12 updated: 2017/07/23 17:46:07
4619 dnl ----------------
4620 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
4621 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
4622 dnl have to provide wrappers for global tables to ensure they're linked
4623 dnl properly.
4624 AC_DEFUN([CF_LINK_DATAONLY],
4625 [
4626 AC_MSG_CHECKING([if data-only library module links])
4627 AC_CACHE_VAL(cf_cv_link_dataonly,[
4628         rm -f conftest.a
4629         cat >conftest.$ac_ext <<EOF
4630 #line __oline__ "configure"
4631 int     testdata[[3]] = { 123, 456, 789 };
4632 EOF
4633         if AC_TRY_EVAL(ac_compile) ; then
4634                 mv conftest.o data.o && \
4635                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
4636         fi
4637         rm -f conftest.$ac_ext data.o
4638         cat >conftest.$ac_ext <<EOF
4639 #line __oline__ "configure"
4640 int     testfunc(void)
4641 {
4642 #if defined(NeXT)
4643         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
4644 #else
4645         extern int testdata[[3]];
4646         return testdata[[0]] == 123
4647            &&  testdata[[1]] == 456
4648            &&  testdata[[2]] == 789;
4649 #endif
4650 }
4651 EOF
4652         if AC_TRY_EVAL(ac_compile); then
4653                 mv conftest.o func.o && \
4654                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
4655         fi
4656         rm -f conftest.$ac_ext func.o
4657         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
4658         cf_saveLIBS="$LIBS"
4659         LIBS="conftest.a $LIBS"
4660         AC_TRY_RUN([
4661         int main(void)
4662         {
4663                 extern int testfunc();
4664                 ${cf_cv_main_return:-return} (!testfunc());
4665         }
4666         ],
4667         [cf_cv_link_dataonly=yes],
4668         [cf_cv_link_dataonly=no],
4669         [cf_cv_link_dataonly=unknown])
4670         LIBS="$cf_saveLIBS"
4671         ])
4672 AC_MSG_RESULT($cf_cv_link_dataonly)
4673
4674 if test "$cf_cv_link_dataonly" = no ; then
4675         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
4676         BROKEN_LINKER=1
4677 fi
4678
4679 ])dnl
4680 dnl ---------------------------------------------------------------------------
4681 dnl CF_LINK_FUNCS version: 9 updated: 2017/01/21 11:11:02
4682 dnl -------------
4683 dnl Most Unix systems have both link and symlink, a few don't have symlink.
4684 dnl A few non-Unix systems implement symlink, but not link.
4685 dnl A few non-systems implement neither (or have nonfunctional versions).
4686 AC_DEFUN([CF_LINK_FUNCS],
4687 [
4688 AC_CHECK_HEADERS( \
4689 unistd.h \
4690 )
4691 AC_CHECK_FUNCS( \
4692         remove \
4693         unlink )
4694
4695 if test "$cross_compiling" = yes ; then
4696         AC_CHECK_FUNCS( \
4697                 link \
4698                 symlink )
4699 else
4700         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
4701                 cf_cv_link_funcs=
4702                 for cf_func in link symlink ; do
4703                         AC_TRY_RUN([
4704 #include <sys/types.h>
4705 #include <sys/stat.h>
4706 #ifdef HAVE_UNISTD_H
4707 #include <unistd.h>
4708 #endif
4709 int main(void)
4710 {
4711         int fail = 0;
4712         char *src = "config.log";
4713         char *dst = "conftest.chk";
4714         struct stat src_sb;
4715         struct stat dst_sb;
4716
4717         stat(src, &src_sb);
4718         fail = ($cf_func("config.log", "conftest.chk") < 0)
4719             || (stat(dst, &dst_sb) < 0)
4720             || (dst_sb.st_mtime != src_sb.st_mtime);
4721 #ifdef HAVE_UNLINK
4722         unlink(dst);
4723 #else
4724         remove(dst);
4725 #endif
4726         ${cf_cv_main_return:-return} (fail);
4727 }
4728                         ],[
4729                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
4730                         eval 'ac_cv_func_'$cf_func'=yes'],[
4731                         eval 'ac_cv_func_'$cf_func'=no'],[
4732                         eval 'ac_cv_func_'$cf_func'=error'])
4733                 done
4734                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
4735         ])
4736         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
4737         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
4738 fi
4739 ])dnl
4740 dnl ---------------------------------------------------------------------------
4741 dnl CF_MAKEFLAGS version: 18 updated: 2018/02/21 21:26:03
4742 dnl ------------
4743 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
4744 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
4745 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
4746 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
4747 AC_DEFUN([CF_MAKEFLAGS],
4748 [
4749 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
4750         cf_cv_makeflags=''
4751         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
4752         do
4753                 cat >cf_makeflags.tmp <<CF_EOF
4754 SHELL = $SHELL
4755 all :
4756         @ echo '.$cf_option'
4757 CF_EOF
4758                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
4759                 case "$cf_result" in
4760                 (.*k|.*kw)
4761                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
4762                         case "$cf_result" in
4763                         (.*CC=*)        cf_cv_makeflags=
4764                                 ;;
4765                         (*)     cf_cv_makeflags=$cf_option
4766                                 ;;
4767                         esac
4768                         break
4769                         ;;
4770                 (.-)
4771                         ;;
4772                 (*)
4773                         CF_MSG_LOG(given option \"$cf_option\", no match \"$cf_result\")
4774                         ;;
4775                 esac
4776         done
4777         rm -f cf_makeflags.tmp
4778 ])
4779
4780 AC_SUBST(cf_cv_makeflags)
4781 ])dnl
4782 dnl ---------------------------------------------------------------------------
4783 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
4784 dnl ------------
4785 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
4786 dnl a monocase filesystem.
4787 AC_DEFUN([CF_MAKE_TAGS],[
4788 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
4789
4790 AC_CHECK_PROGS(CTAGS, exctags ctags)
4791 AC_CHECK_PROGS(ETAGS, exetags etags)
4792
4793 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
4794
4795 if test "$cf_cv_mixedcase" = yes ; then
4796         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
4797 else
4798         MAKE_UPPER_TAGS=no
4799 fi
4800
4801 if test "$MAKE_UPPER_TAGS" = yes ; then
4802         MAKE_UPPER_TAGS=
4803 else
4804         MAKE_UPPER_TAGS="#"
4805 fi
4806
4807 if test "$MAKE_LOWER_TAGS" = yes ; then
4808         MAKE_LOWER_TAGS=
4809 else
4810         MAKE_LOWER_TAGS="#"
4811 fi
4812
4813 AC_SUBST(CTAGS)
4814 AC_SUBST(ETAGS)
4815
4816 AC_SUBST(MAKE_UPPER_TAGS)
4817 AC_SUBST(MAKE_LOWER_TAGS)
4818 ])dnl
4819 dnl ---------------------------------------------------------------------------
4820 dnl CF_MANPAGE_FORMAT version: 11 updated: 2015/04/18 08:56:57
4821 dnl -----------------
4822 dnl Option to allow user to override automatic configuration of manpage format.
4823 dnl There are several special cases:
4824 dnl
4825 dnl     gzip - man checks for, can display gzip'd files
4826 dnl     compress - man checks for, can display compressed files
4827 dnl     BSDI - files in the cat-directories are suffixed ".0"
4828 dnl     formatted - installer should format (put files in cat-directory)
4829 dnl     catonly - installer should only format, e.g., for a turnkey system.
4830 dnl
4831 dnl There are other configurations which this macro does not test, e.g., HPUX's
4832 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
4833 dnl convention would not match our use).
4834 AC_DEFUN([CF_MANPAGE_FORMAT],
4835 [
4836 AC_REQUIRE([CF_PATHSEP])
4837 AC_MSG_CHECKING(format of man-pages)
4838
4839 AC_ARG_WITH(manpage-format,
4840         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
4841                           optionally formatted/catonly, e.g., gzip,formatted],
4842         [MANPAGE_FORMAT=$withval],
4843         [MANPAGE_FORMAT=unknown])
4844
4845 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
4846 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
4847
4848 cf_unknown=
4849
4850 case $MANPAGE_FORMAT in
4851 (unknown)
4852         if test -z "$MANPATH" ; then
4853                 MANPATH="/usr/man:/usr/share/man"
4854         fi
4855
4856         # look for the 'date' man-page (it's most likely to be installed!)
4857         MANPAGE_FORMAT=
4858         cf_preform=no
4859         cf_catonly=yes
4860         cf_example=date
4861
4862         IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
4863         for cf_dir in $MANPATH; do
4864                 test -z "$cf_dir" && cf_dir=/usr/man
4865                 for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
4866                 do
4867                         cf_test=`echo $cf_name | sed -e 's/*//'`
4868                         if test "x$cf_test" = "x$cf_name" ; then
4869
4870                                 case "$cf_name" in
4871                                 (*.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
4872                                 (*.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
4873                                 (*.0)  MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
4874                                 (*)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
4875                                 esac
4876
4877                                 case "$cf_name" in
4878                                 ($cf_dir/man*)
4879                                         cf_catonly=no
4880                                         ;;
4881                                 ($cf_dir/cat*)
4882                                         cf_preform=yes
4883                                         ;;
4884                                 esac
4885                                 break
4886                         fi
4887
4888                         # if we found a match in either man* or cat*, stop looking
4889                         if test -n "$MANPAGE_FORMAT" ; then
4890                                 cf_found=no
4891                                 test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
4892                                 test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
4893                                 case "$cf_name" in
4894                                 ($cf_dir/cat*)
4895                                         cf_found=yes
4896                                         ;;
4897                                 esac
4898                                 test $cf_found=yes && break
4899                         fi
4900                 done
4901                 # only check the first directory in $MANPATH where we find manpages
4902                 if test -n "$MANPAGE_FORMAT" ; then
4903                         break
4904                 fi
4905         done
4906         # if we did not find the example, just assume it is normal
4907         test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
4908         IFS="$ac_save_ifs"
4909         ;;
4910 (*)
4911         for cf_option in $MANPAGE_FORMAT; do
4912         case $cf_option in
4913         (gzip|compress|BSDI|normal|formatted|catonly)
4914                 ;;
4915         (*)
4916                 cf_unknown="$cf_unknown $cf_option"
4917                 ;;
4918         esac
4919         done
4920         ;;
4921 esac
4922
4923 AC_MSG_RESULT($MANPAGE_FORMAT)
4924 if test -n "$cf_unknown" ; then
4925         AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
4926 fi
4927 ])dnl
4928 dnl ---------------------------------------------------------------------------
4929 dnl CF_MANPAGE_RENAMES version: 10 updated: 2015/08/05 20:44:28
4930 dnl ------------------
4931 dnl The Debian people have their own naming convention for manpages.  This
4932 dnl option lets us override the name of the file containing renaming, or
4933 dnl disable it altogether.
4934 AC_DEFUN([CF_MANPAGE_RENAMES],
4935 [
4936 AC_MSG_CHECKING(for manpage renaming)
4937
4938 AC_ARG_WITH(manpage-renames,
4939         [  --with-manpage-renames  specify manpage-renaming],
4940         [MANPAGE_RENAMES=$withval],
4941         [MANPAGE_RENAMES=yes])
4942
4943 case ".$MANPAGE_RENAMES" in
4944 (.no)
4945         ;;
4946 (.|.yes)
4947         # Debian 'man' program?
4948         if test -f /etc/debian_version ; then
4949                 MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
4950         else
4951                 MANPAGE_RENAMES=no
4952         fi
4953         ;;
4954 esac
4955
4956 if test "$MANPAGE_RENAMES" != no ; then
4957         if test -f $srcdir/man/$MANPAGE_RENAMES ; then
4958                 MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
4959         elif test ! -f $MANPAGE_RENAMES ; then
4960                 AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
4961         fi
4962
4963         test ! -d man && mkdir man
4964
4965         # Construct a sed-script to perform renaming within man-pages
4966         if test -n "$MANPAGE_RENAMES" ; then
4967                 test ! -d man && mkdir man
4968                 $SHELL $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
4969         fi
4970 fi
4971
4972 AC_MSG_RESULT($MANPAGE_RENAMES)
4973 AC_SUBST(MANPAGE_RENAMES)
4974 ])dnl
4975 dnl ---------------------------------------------------------------------------
4976 dnl CF_MANPAGE_SYMLINKS version: 6 updated: 2015/04/17 21:13:04
4977 dnl -------------------
4978 dnl Some people expect each tool to make all aliases for manpages in the
4979 dnl man-directory.  This accommodates the older, less-capable implementations
4980 dnl of 'man', and is optional.
4981 AC_DEFUN([CF_MANPAGE_SYMLINKS],
4982 [
4983 AC_MSG_CHECKING(if manpage aliases will be installed)
4984
4985 AC_ARG_WITH(manpage-aliases,
4986         [  --with-manpage-aliases  specify manpage-aliases using .so],
4987         [MANPAGE_ALIASES=$withval],
4988         [MANPAGE_ALIASES=yes])
4989
4990 AC_MSG_RESULT($MANPAGE_ALIASES)
4991
4992 case "x$LN_S" in
4993 (xln*)
4994         cf_use_symlinks=yes
4995         ;;
4996 (*)
4997         cf_use_symlinks=no
4998         ;;
4999 esac
5000
5001 MANPAGE_SYMLINKS=no
5002 if test "$MANPAGE_ALIASES" = yes ; then
5003 AC_MSG_CHECKING(if manpage symlinks should be used)
5004
5005 AC_ARG_WITH(manpage-symlinks,
5006         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
5007         [MANPAGE_SYMLINKS=$withval],
5008         [MANPAGE_SYMLINKS=$cf_use_symlinks])
5009
5010 if test "$$cf_use_symlinks" = no; then
5011 if test "$MANPAGE_SYMLINKS" = yes ; then
5012         AC_MSG_WARN(cannot make symlinks, will use .so files)
5013         MANPAGE_SYMLINKS=no
5014 fi
5015 fi
5016
5017 AC_MSG_RESULT($MANPAGE_SYMLINKS)
5018 fi
5019
5020 ])dnl
5021 dnl ---------------------------------------------------------------------------
5022 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
5023 dnl --------------
5024 dnl This option causes manpages to be run through tbl(1) to generate tables
5025 dnl correctly.
5026 AC_DEFUN([CF_MANPAGE_TBL],
5027 [
5028 AC_MSG_CHECKING(for manpage tbl)
5029
5030 AC_ARG_WITH(manpage-tbl,
5031         [  --with-manpage-tbl      specify manpage processing with tbl],
5032         [MANPAGE_TBL=$withval],
5033         [MANPAGE_TBL=no])
5034
5035 AC_MSG_RESULT($MANPAGE_TBL)
5036 ])dnl
5037 dnl ---------------------------------------------------------------------------
5038 dnl CF_MAN_PAGES version: 47 updated: 2017/08/12 07:58:51
5039 dnl ------------
5040 dnl Try to determine if the man-pages on the system are compressed, and if
5041 dnl so, what format is used.  Use this information to construct a script that
5042 dnl will install man-pages.
5043 AC_DEFUN([CF_MAN_PAGES],
5044 [
5045 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
5046 CF_MANPAGE_FORMAT
5047 CF_MANPAGE_RENAMES
5048 CF_MANPAGE_SYMLINKS
5049 CF_MANPAGE_TBL
5050
5051 if test "$prefix" = "NONE" ; then
5052         cf_prefix="$ac_default_prefix"
5053 else
5054         cf_prefix="$prefix"
5055 fi
5056
5057 case "$MANPAGE_FORMAT" in
5058 (*catonly*)
5059         cf_format=yes
5060         cf_inboth=no
5061         ;;
5062 (*formatted*)
5063         cf_format=yes
5064         cf_inboth=yes
5065         ;;
5066 (*)
5067         cf_format=no
5068         cf_inboth=no
5069         ;;
5070 esac
5071
5072 test ! -d man && mkdir man
5073
5074 cf_so_strip=
5075 cf_compress=
5076 case "$MANPAGE_FORMAT" in
5077 (*compress*)
5078         cf_so_strip="Z"
5079         cf_compress=compress
5080         ;;
5081 (*gzip*)
5082         cf_so_strip="gz"
5083         cf_compress=gzip
5084         ;;
5085 esac
5086
5087 cf_edit_man=./edit_man.sh
5088 cf_man_alias=`pwd`/man_alias.sed
5089
5090 cat >$cf_edit_man <<CF_EOF
5091 #! $SHELL
5092 # this script is generated by the configure-script CF_MAN_PAGES macro.
5093
5094 prefix="$cf_prefix"
5095 datarootdir="$datarootdir"
5096 datadir="$datadir"
5097
5098 NCURSES_MAJOR="$NCURSES_MAJOR"
5099 NCURSES_MINOR="$NCURSES_MINOR"
5100 NCURSES_PATCH="$NCURSES_PATCH"
5101
5102 NCURSES_OSPEED="$NCURSES_OSPEED"
5103 TERMINFO="$TERMINFO"
5104
5105 INSTALL="$INSTALL"
5106 INSTALL_DATA="$INSTALL_DATA"
5107
5108 transform="$program_transform_name"
5109
5110 TMP=\${TMPDIR:=/tmp}/man\$\$
5111 trap "rm -f \$TMP" 0 1 2 3 15
5112
5113 form=\[$]1
5114 shift || exit 1
5115
5116 verb=\[$]1
5117 shift || exit 1
5118
5119 mandir=\[$]1
5120 shift || exit 1
5121
5122 srcdir=\[$]1
5123 top_srcdir=\[$]srcdir/..
5124 shift || exit 1
5125
5126 if test "\$form" = normal ; then
5127         if test "$cf_format" = yes ; then
5128         if test "$cf_inboth" = no ; then
5129                 $SHELL \[$]0 format \$verb \$mandir \$srcdir \[$]*
5130                 exit $?
5131         fi
5132         fi
5133         cf_subdir=\$mandir/man
5134         cf_tables=$MANPAGE_TBL
5135 else
5136         cf_subdir=\$mandir/cat
5137         cf_tables=yes
5138 fi
5139
5140 # process the list of source-files
5141 for i in \[$]* ; do
5142 case \$i in
5143 (*.orig|*.rej) ;;
5144 (*.[[0-9]]*)
5145         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
5146         if test \$verb = installing ; then
5147         if test ! -d \$cf_subdir\${section} ; then
5148                 mkdir -p \$cf_subdir\$section
5149         fi
5150         fi
5151
5152         # replace variables in man page
5153         if test ! -f $cf_man_alias ; then
5154 cat >>$cf_man_alias <<-CF_EOF2
5155                 s,@DATADIR@,\$datadir,g
5156                 s,@TERMINFO@,\${TERMINFO:="no default value"},g
5157                 s,@TERMINFO_DIRS@,\${TERMINFO_DIRS:="no default value"},g
5158                 s,@NCURSES_MAJOR@,\${NCURSES_MAJOR:="no default value"},g
5159                 s,@NCURSES_MINOR@,\${NCURSES_MINOR:="no default value"},g
5160                 s,@NCURSES_PATCH@,\${NCURSES_PATCH:="no default value"},g
5161                 s,@NCURSES_OSPEED@,\${NCURSES_OSPEED:="no default value"},g
5162 CF_EOF
5163         ifelse($1,,,[
5164         for cf_name in $1
5165         do
5166                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
5167                 cf_name=`echo $cf_name|sed "$program_transform_name"`
5168 cat >>$cf_edit_man <<-CF_EOF
5169                 s,@$cf_NAME@,$cf_name,g
5170 CF_EOF
5171         done
5172         ])
5173 cat >>$cf_edit_man <<CF_EOF
5174 CF_EOF2
5175                 echo "...made $cf_man_alias"
5176         fi
5177
5178         aliases=
5179         cf_source=\`basename \$i\`
5180         inalias=\$cf_source
5181         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
5182         if test ! -f \$inalias ; then
5183                 echo .. skipped \$cf_source
5184                 continue
5185         fi
5186 CF_EOF
5187
5188 if test "$MANPAGE_ALIASES" != no ; then
5189 cat >>$cf_edit_man <<CF_EOF
5190         nCurses=ignore.3x
5191         test $with_curses_h = yes && nCurses=ncurses.3x
5192         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
5193 CF_EOF
5194 fi
5195
5196 if test "$MANPAGE_RENAMES" = no ; then
5197 cat >>$cf_edit_man <<CF_EOF
5198         # perform program transformations for section 1 man pages
5199         if test \$section = 1 ; then
5200                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
5201         else
5202                 cf_target=\$cf_subdir\${section}/\$cf_source
5203         fi
5204 CF_EOF
5205 else
5206 cat >>$cf_edit_man <<CF_EOF
5207         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
5208         if test -z "\$cf_target" ; then
5209                 echo '? missing rename for '\$cf_source
5210                 cf_target="\$cf_source"
5211         fi
5212         cf_target="\$cf_subdir\${section}/\${cf_target}"
5213
5214 CF_EOF
5215 fi
5216
5217 cat >>$cf_edit_man <<CF_EOF
5218         sed     -f $cf_man_alias \\
5219 CF_EOF
5220
5221 if test -f $MANPAGE_RENAMES ; then
5222 cat >>$cf_edit_man <<CF_EOF
5223                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
5224 CF_EOF
5225 else
5226 cat >>$cf_edit_man <<CF_EOF
5227                 < \$i >\$TMP
5228 CF_EOF
5229 fi
5230
5231 cat >>$cf_edit_man <<CF_EOF
5232 if test \$cf_tables = yes ; then
5233         tbl \$TMP >\$TMP.out
5234         mv \$TMP.out \$TMP
5235 fi
5236 CF_EOF
5237
5238 if test $with_overwrite != yes ; then
5239 cat >>$cf_edit_man <<CF_EOF
5240         sed -e "/\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
5241         mv \$TMP.out \$TMP
5242 CF_EOF
5243 fi
5244
5245 if test $with_curses_h != yes ; then
5246 cat >>$cf_edit_man <<CF_EOF
5247         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
5248         mv \$TMP.out \$TMP
5249 CF_EOF
5250 fi
5251
5252 cat >>$cf_edit_man <<CF_EOF
5253         if test \$form = format ; then
5254                 nroff -man \$TMP >\$TMP.out
5255                 mv \$TMP.out \$TMP
5256         fi
5257 CF_EOF
5258
5259 if test -n "$cf_compress" ; then
5260 cat >>$cf_edit_man <<CF_EOF
5261         if test \$verb = installing ; then
5262         if ( $cf_compress -f \$TMP )
5263         then
5264                 mv \$TMP.$cf_so_strip \$TMP
5265         fi
5266         fi
5267         cf_target="\$cf_target.$cf_so_strip"
5268 CF_EOF
5269 fi
5270
5271 case "$MANPAGE_FORMAT" in
5272 (*BSDI*)
5273 cat >>$cf_edit_man <<CF_EOF
5274         if test \$form = format ; then
5275                 # BSDI installs only .0 suffixes in the cat directories
5276                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
5277         fi
5278 CF_EOF
5279   ;;
5280 esac
5281
5282 cat >>$cf_edit_man <<CF_EOF
5283         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
5284         if test \$verb = installing ; then
5285                 echo \$verb \$cf_target
5286                 \$INSTALL_DATA \$TMP \$cf_target
5287                 test -d \$cf_subdir\${section} &&
5288                 test -n "\$aliases" && (
5289                         cd \$cf_subdir\${section} && (
5290                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
5291                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
5292                                 cf_target=\`basename \$cf_target\`
5293                                 for cf_alias in \$aliases
5294                                 do
5295                                         if test \$section = 1 ; then
5296                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
5297                                         fi
5298
5299                                         if test "$MANPAGE_SYMLINKS" = yes ; then
5300                                                 if test -f \$cf_alias\${suffix} ; then
5301                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
5302                                                         then
5303                                                                 continue
5304                                                         fi
5305                                                 fi
5306                                                 echo .. \$verb alias \$cf_alias\${suffix}
5307 CF_EOF
5308 case "x$LN_S" in
5309 (*-f)
5310 cat >>$cf_edit_man <<CF_EOF
5311                                                 $LN_S \$cf_target \$cf_alias\${suffix}
5312 CF_EOF
5313         ;;
5314 (*)
5315 cat >>$cf_edit_man <<CF_EOF
5316                                                 rm -f \$cf_alias\${suffix}
5317                                                 $LN_S \$cf_target \$cf_alias\${suffix}
5318 CF_EOF
5319         ;;
5320 esac
5321 cat >>$cf_edit_man <<CF_EOF
5322                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
5323                                                 echo ".so \$cf_source" >\$TMP
5324 CF_EOF
5325 if test -n "$cf_compress" ; then
5326 cat >>$cf_edit_man <<CF_EOF
5327                                                 if test -n "$cf_so_strip" ; then
5328                                                         $cf_compress -f \$TMP
5329                                                         mv \$TMP.$cf_so_strip \$TMP
5330                                                 fi
5331 CF_EOF
5332 fi
5333 cat >>$cf_edit_man <<CF_EOF
5334                                                 echo .. \$verb alias \$cf_alias\${suffix}
5335                                                 rm -f \$cf_alias\${suffix}
5336                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
5337                                         fi
5338                                 done
5339                         )
5340                 )
5341         elif test \$verb = removing ; then
5342                 test -f \$cf_target && (
5343                         echo \$verb \$cf_target
5344                         rm -f \$cf_target
5345                 )
5346                 test -d \$cf_subdir\${section} &&
5347                 test -n "\$aliases" && (
5348                         cd \$cf_subdir\${section} && (
5349                                 for cf_alias in \$aliases
5350                                 do
5351                                         if test \$section = 1 ; then
5352                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
5353                                         fi
5354
5355                                         echo .. \$verb alias \$cf_alias\${suffix}
5356                                         rm -f \$cf_alias\${suffix}
5357                                 done
5358                         )
5359                 )
5360         else
5361 #               echo ".hy 0"
5362                 cat \$TMP
5363         fi
5364         ;;
5365 esac
5366 done
5367
5368 if test $cf_inboth = yes ; then
5369 if test \$form != format ; then
5370         $SHELL \[$]0 format \$verb \$mandir \$srcdir \[$]*
5371 fi
5372 fi
5373
5374 exit 0
5375 CF_EOF
5376 chmod 755 $cf_edit_man
5377
5378 ])dnl
5379 dnl ---------------------------------------------------------------------------
5380 dnl CF_MATH_LIB version: 9 updated: 2017/01/21 11:06:25
5381 dnl -----------
5382 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
5383 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
5384 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
5385 AC_DEFUN([CF_MATH_LIB],
5386 [
5387 AC_CACHE_CHECK(if -lm needed for math functions,
5388         cf_cv_need_libm,[
5389         AC_TRY_LINK([
5390         #include <stdio.h>
5391         #include <stdlib.h>
5392         #include <math.h>
5393         ],
5394         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
5395         [cf_cv_need_libm=no],
5396         [cf_cv_need_libm=yes])])
5397 if test "$cf_cv_need_libm" = yes
5398 then
5399 ifelse($1,,[
5400         CF_ADD_LIB(m)
5401 ],[$1=-lm])
5402 fi
5403 ])
5404 dnl ---------------------------------------------------------------------------
5405 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
5406 dnl ----------------------
5407 dnl Check if the file-system supports mixed-case filenames.  If we're able to
5408 dnl create a lowercase name and see it as uppercase, it doesn't support that.
5409 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
5410 [
5411 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
5412 if test "$cross_compiling" = yes ; then
5413         case $target_alias in
5414         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
5415                 cf_cv_mixedcase=no
5416                 ;;
5417         (*)
5418                 cf_cv_mixedcase=yes
5419                 ;;
5420         esac
5421 else
5422         rm -f conftest CONFTEST
5423         echo test >conftest
5424         if test -f CONFTEST ; then
5425                 cf_cv_mixedcase=no
5426         else
5427                 cf_cv_mixedcase=yes
5428         fi
5429         rm -f conftest CONFTEST
5430 fi
5431 ])
5432 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
5433 ])dnl
5434 dnl ---------------------------------------------------------------------------
5435 dnl CF_MKSTEMP version: 10 updated: 2017/01/21 11:12:16
5436 dnl ----------
5437 dnl Check for a working mkstemp.  This creates two files, checks that they are
5438 dnl successfully created and distinct (AmigaOS apparently fails on the last).
5439 AC_DEFUN([CF_MKSTEMP],[
5440 AC_CHECK_HEADERS( \
5441 unistd.h \
5442 )
5443 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
5444 rm -rf conftest*
5445 AC_TRY_RUN([
5446 #include <sys/types.h>
5447 #ifdef HAVE_UNISTD_H
5448 #include <unistd.h>
5449 #endif
5450 #include <stdlib.h>
5451 #include <stdio.h>
5452 #include <string.h>
5453 #include <sys/stat.h>
5454 int main(void)
5455 {
5456         char *tmpl = "conftestXXXXXX";
5457         char name[2][80];
5458         int n;
5459         int result = 0;
5460         int fd;
5461         struct stat sb;
5462
5463         umask(077);
5464         for (n = 0; n < 2; ++n) {
5465                 strcpy(name[n], tmpl);
5466                 if ((fd = mkstemp(name[n])) >= 0) {
5467                         if (!strcmp(name[n], tmpl)
5468                          || stat(name[n], &sb) != 0
5469                          || (sb.st_mode & S_IFMT) != S_IFREG
5470                          || (sb.st_mode & 077) != 0) {
5471                                 result = 1;
5472                         }
5473                         close(fd);
5474                 }
5475         }
5476         if (result == 0
5477          && !strcmp(name[0], name[1]))
5478                 result = 1;
5479         ${cf_cv_main_return:-return}(result);
5480 }
5481 ],[cf_cv_func_mkstemp=yes
5482 ],[cf_cv_func_mkstemp=no
5483 ],[cf_cv_func_mkstemp=maybe])
5484 ])
5485 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
5486         AC_CHECK_FUNC(mkstemp)
5487 fi
5488 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
5489         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
5490 fi
5491 ])dnl
5492 dnl ---------------------------------------------------------------------------
5493 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
5494 dnl ----------
5495 dnl Write a debug message to config.log, along with the line number in the
5496 dnl configure script.
5497 AC_DEFUN([CF_MSG_LOG],[
5498 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
5499 ])dnl
5500 dnl ---------------------------------------------------------------------------
5501 dnl CF_NCURSES_ABI_6 version: 3 updated: 2015/06/06 16:10:11
5502 dnl ----------------
5503 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
5504 dnl warn about this.
5505 AC_DEFUN([CF_NCURSES_ABI_6],[
5506 if test "${with_abi_version+set}" != set; then
5507         case $cf_cv_rel_version in
5508         (5.*)
5509                 cf_cv_rel_version=6.0
5510                 cf_cv_abi_version=6
5511                 AC_MSG_WARN(overriding ABI version to $cf_cv_abi_version)
5512                 ;;
5513         esac
5514 fi
5515 ])dnl
5516 dnl ---------------------------------------------------------------------------
5517 dnl CF_NCURSES_WITH_ABI_VERSION version: 2 updated: 2015/12/19 17:51:52
5518 dnl ---------------------------
5519 dnl Allow ncurses's ABI to be overridden.  Generally this happens when a
5520 dnl packager has incremented the ABI past that used in the original package,
5521 dnl and wishes to keep doing this.
5522 dnl
5523 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
5524 dnl symbol.
5525 AC_DEFUN([CF_NCURSES_WITH_ABI_VERSION],[
5526 CF_WITH_ABI_VERSION($1)
5527 if test "x$cf_cv_abi_version" != "x$with_abi_version"
5528 then
5529         case $cf_cv_rel_version in
5530         (5.*)
5531                 cf_cv_rel_version=$with_abi_version.0
5532                 ;;
5533         esac
5534 fi
5535 ])dnl
5536 dnl ---------------------------------------------------------------------------
5537 dnl CF_NO_LEAKS_OPTION version: 6 updated: 2015/04/12 15:39:00
5538 dnl ------------------
5539 dnl see CF_WITH_NO_LEAKS
5540 AC_DEFUN([CF_NO_LEAKS_OPTION],[
5541 AC_MSG_CHECKING(if you want to use $1 for testing)
5542 AC_ARG_WITH($1,
5543         [$2],
5544         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
5545          $4
5546 ])
5547         : ${with_cflags:=-g}
5548         : ${with_no_leaks:=yes}
5549          with_$1=yes],
5550         [with_$1=])
5551 AC_MSG_RESULT(${with_$1:-no})
5552
5553 case .$with_cflags in
5554 (.*-g*)
5555         case .$CFLAGS in
5556         (.*-g*)
5557                 ;;
5558         (*)
5559                 CF_ADD_CFLAGS([-g])
5560                 ;;
5561         esac
5562         ;;
5563 esac
5564 ])dnl
5565 dnl ---------------------------------------------------------------------------
5566 dnl CF_NUMBER_SYNTAX version: 2 updated: 2015/04/17 21:13:04
5567 dnl ----------------
5568 dnl Check if the given variable is a number.  If not, report an error.
5569 dnl $1 is the variable
5570 dnl $2 is the message
5571 AC_DEFUN([CF_NUMBER_SYNTAX],[
5572 if test -n "$1" ; then
5573   case $1 in
5574   ([[0-9]]*)
5575         ;;
5576   (*)
5577         AC_MSG_ERROR($2 is not a number: $1)
5578         ;;
5579   esac
5580 else
5581   AC_MSG_ERROR($2 value is empty)
5582 fi
5583 ])dnl
5584 dnl ---------------------------------------------------------------------------
5585 dnl CF_OBJ_SUBDIR version: 7 updated: 2015/04/17 21:13:04
5586 dnl -------------
5587 dnl Compute the object-directory name from the given model name
5588 AC_DEFUN([CF_OBJ_SUBDIR],
5589 [
5590         case $1 in
5591         (libtool) $2='obj_lo'  ;;
5592         (normal)  $2='objects' ;;
5593         (debug)   $2='obj_g' ;;
5594         (profile) $2='obj_p' ;;
5595         (shared)
5596                 case $cf_cv_system_name in
5597                 (cygwin|msys)
5598                         $2='objects' ;;
5599                 (*)
5600                         $2='obj_s' ;;
5601                 esac
5602         esac
5603 ])dnl
5604 dnl ---------------------------------------------------------------------------
5605 dnl CF_PATHSEP version: 7 updated: 2015/04/12 15:39:00
5606 dnl ----------
5607 dnl Provide a value for the $PATH and similar separator (or amend the value
5608 dnl as provided in autoconf 2.5x).
5609 AC_DEFUN([CF_PATHSEP],
5610 [
5611         AC_MSG_CHECKING(for PATH separator)
5612         case $cf_cv_system_name in
5613         (os2*)  PATH_SEPARATOR=';'  ;;
5614         (*)     ${PATH_SEPARATOR:=':'}  ;;
5615         esac
5616 ifelse([$1],,,[$1=$PATH_SEPARATOR])
5617         AC_SUBST(PATH_SEPARATOR)
5618         AC_MSG_RESULT($PATH_SEPARATOR)
5619 ])dnl
5620 dnl ---------------------------------------------------------------------------
5621 dnl CF_PATH_PROG version: 10 updated: 2019/06/30 19:44:43
5622 dnl ------------
5623 dnl Check for a given program, defining corresponding symbol.
5624 dnl     $1 = environment variable, which is suffixed by "_PATH" in the #define.
5625 dnl     $2 = program name to find.
5626 dnl     $3 = optional list of additional program names to test.
5627 dnl $4 = $PATH
5628 dnl
5629 dnl If there is more than one token in the result, #define the remaining tokens
5630 dnl to $1_ARGS.  We need this for 'install' in particular.
5631 dnl
5632 dnl FIXME: we should allow this to be overridden by environment variables
5633 dnl
5634 AC_DEFUN([CF_PATH_PROG],[
5635 AC_REQUIRE([CF_PATHSEP])
5636 test -z "[$]$1" && $1=$2
5637 AC_PATH_PROGS($1,[$]$1 $2 ifelse($3,,,$3),[$]$1, ifelse($4,,,$4))
5638
5639 cf_path_prog=""
5640 cf_path_args=""
5641 IFS="${IFS:-    }"; cf_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR"
5642 for cf_temp in $ac_cv_path_$1
5643 do
5644         if test -z "$cf_path_prog" ; then
5645                 if test "$with_full_paths" = yes ; then
5646                         CF_PATH_SYNTAX(cf_temp,break)
5647                         cf_path_prog="$cf_temp"
5648                 else
5649                         cf_path_prog="`basename $cf_temp`"
5650                 fi
5651         elif test -z "$cf_path_args" ; then
5652                 cf_path_args="$cf_temp"
5653         else
5654                 cf_path_args="$cf_path_args $cf_temp"
5655         fi
5656 done
5657 IFS="$cf_save_ifs"
5658
5659 if test -n "$cf_path_prog" ; then
5660         CF_MSG_LOG(defining path for ${cf_path_prog})
5661         AC_DEFINE_UNQUOTED($1_PATH,"$cf_path_prog",Define to pathname $1)
5662         test -n "$cf_path_args" && AC_DEFINE_UNQUOTED($1_ARGS,"$cf_path_args",Define to provide args for $1)
5663 fi
5664 ])dnl
5665 dnl ---------------------------------------------------------------------------
5666 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
5667 dnl --------------
5668 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
5669 dnl begins with one of the prefix/exec_prefix variables, and then again if the
5670 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
5671 dnl delayed evaluation of those symbols.
5672 AC_DEFUN([CF_PATH_SYNTAX],[
5673 if test "x$prefix" != xNONE; then
5674         cf_path_syntax="$prefix"
5675 else
5676         cf_path_syntax="$ac_default_prefix"
5677 fi
5678
5679 case ".[$]$1" in
5680 (.\[$]\(*\)*|.\'*\'*)
5681         ;;
5682 (..|./*|.\\*)
5683         ;;
5684 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
5685         ;;
5686 (.\[$]{*prefix}*|.\[$]{*dir}*)
5687         eval $1="[$]$1"
5688         case ".[$]$1" in
5689         (.NONE/*)
5690                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
5691                 ;;
5692         esac
5693         ;;
5694 (.no|.NONE/*)
5695         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
5696         ;;
5697 (*)
5698         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
5699         ;;
5700 esac
5701 ])dnl
5702 dnl ---------------------------------------------------------------------------
5703 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
5704 dnl -------------
5705 dnl Check for the package-config program, unless disabled by command-line.
5706 AC_DEFUN([CF_PKG_CONFIG],
5707 [
5708 AC_MSG_CHECKING(if you want to use pkg-config)
5709 AC_ARG_WITH(pkg-config,
5710         [  --with-pkg-config{=path} enable/disable use of pkg-config],
5711         [cf_pkg_config=$withval],
5712         [cf_pkg_config=yes])
5713 AC_MSG_RESULT($cf_pkg_config)
5714
5715 case $cf_pkg_config in
5716 (no)
5717         PKG_CONFIG=none
5718         ;;
5719 (yes)
5720         CF_ACVERSION_CHECK(2.52,
5721                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
5722                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
5723         ;;
5724 (*)
5725         PKG_CONFIG=$withval
5726         ;;
5727 esac
5728
5729 test -z "$PKG_CONFIG" && PKG_CONFIG=none
5730 if test "$PKG_CONFIG" != none ; then
5731         CF_PATH_SYNTAX(PKG_CONFIG)
5732 elif test "x$cf_pkg_config" != xno ; then
5733         AC_MSG_WARN(pkg-config is not installed)
5734 fi
5735
5736 AC_SUBST(PKG_CONFIG)
5737 ])dnl
5738 dnl ---------------------------------------------------------------------------
5739 dnl CF_POSIX_C_SOURCE version: 11 updated: 2018/12/31 20:46:17
5740 dnl -----------------
5741 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
5742 dnl
5743 dnl     POSIX.1-1990                            _POSIX_SOURCE
5744 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
5745 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
5746 dnl             Bindings Option
5747 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
5748 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
5749 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
5750 dnl
5751 dnl Parameters:
5752 dnl     $1 is the nominal value for _POSIX_C_SOURCE
5753 AC_DEFUN([CF_POSIX_C_SOURCE],
5754 [AC_REQUIRE([CF_POSIX_VISIBLE])dnl
5755
5756 if test "$cf_cv_posix_visible" = no; then
5757
5758 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
5759
5760 cf_save_CFLAGS="$CFLAGS"
5761 cf_save_CPPFLAGS="$CPPFLAGS"
5762
5763 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
5764 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
5765
5766 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
5767         CF_MSG_LOG(if the symbol is already defined go no further)
5768         AC_TRY_COMPILE([#include <sys/types.h>],[
5769 #ifndef _POSIX_C_SOURCE
5770 make an error
5771 #endif],
5772         [cf_cv_posix_c_source=no],
5773         [cf_want_posix_source=no
5774          case .$cf_POSIX_C_SOURCE in
5775          (.[[12]]??*)
5776                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
5777                 ;;
5778          (.2)
5779                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
5780                 cf_want_posix_source=yes
5781                 ;;
5782          (.*)
5783                 cf_want_posix_source=yes
5784                 ;;
5785          esac
5786          if test "$cf_want_posix_source" = yes ; then
5787                 AC_TRY_COMPILE([#include <sys/types.h>],[
5788 #ifdef _POSIX_SOURCE
5789 make an error
5790 #endif],[],
5791                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
5792          fi
5793          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
5794          CFLAGS="$cf_trim_CFLAGS"
5795          CPPFLAGS="$cf_trim_CPPFLAGS"
5796          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
5797          CF_MSG_LOG(if the second compile does not leave our definition intact error)
5798          AC_TRY_COMPILE([#include <sys/types.h>],[
5799 #ifndef _POSIX_C_SOURCE
5800 make an error
5801 #endif],,
5802          [cf_cv_posix_c_source=no])
5803          CFLAGS="$cf_save_CFLAGS"
5804          CPPFLAGS="$cf_save_CPPFLAGS"
5805         ])
5806 ])
5807
5808 if test "$cf_cv_posix_c_source" != no ; then
5809         CFLAGS="$cf_trim_CFLAGS"
5810         CPPFLAGS="$cf_trim_CPPFLAGS"
5811         CF_ADD_CFLAGS($cf_cv_posix_c_source)
5812 fi
5813
5814 fi # cf_cv_posix_visible
5815
5816 ])dnl
5817 dnl ---------------------------------------------------------------------------
5818 dnl CF_POSIX_VISIBLE version: 1 updated: 2018/12/31 20:46:17
5819 dnl ----------------
5820 dnl POSIX documents test-macros which an application may set before any system
5821 dnl headers are included to make features available.
5822 dnl
5823 dnl Some BSD platforms (originally FreeBSD, but copied by a few others)
5824 dnl diverged from POSIX in 2002 by setting symbols which make all of the most
5825 dnl recent features visible in the system header files unless the application
5826 dnl overrides the corresponding test-macros.  Doing that introduces portability
5827 dnl problems.
5828 dnl
5829 dnl This macro makes a special check for the symbols used for this, to avoid a
5830 dnl conflicting definition.
5831 AC_DEFUN([CF_POSIX_VISIBLE],
5832 [
5833 AC_CACHE_CHECK(if the POSIX test-macros are already defined,cf_cv_posix_visible,[
5834 AC_TRY_COMPILE([#include <stdio.h>],[
5835 #if defined(__POSIX_VISIBLE) && ((__POSIX_VISIBLE - 0L) > 0) \
5836         && defined(__XSI_VISIBLE) && ((__XSI_VISIBLE - 0L) > 0) \
5837         && defined(__BSD_VISIBLE) && ((__BSD_VISIBLE - 0L) > 0) \
5838         && defined(__ISO_C_VISIBLE) && ((__ISO_C_VISIBLE - 0L) > 0)
5839 #error conflicting symbols found
5840 #endif
5841 ],[cf_cv_posix_visible=no],[cf_cv_posix_visible=yes])
5842 ])
5843 ])dnl
5844 dnl ---------------------------------------------------------------------------
5845 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
5846 dnl ------------
5847 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
5848 dnl
5849 dnl $1 = symbol to test
5850 dnl $2 = value (if any) to use for a predefinition
5851 AC_DEFUN([CF_PREDEFINE],
5852 [
5853 AC_MSG_CHECKING(if we must define $1)
5854 AC_TRY_COMPILE([#include <sys/types.h>
5855 ],[
5856 #ifndef $1
5857 make an error
5858 #endif],[cf_result=no],[cf_result=yes])
5859 AC_MSG_RESULT($cf_result)
5860
5861 if test "$cf_result" = yes ; then
5862         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
5863 elif test "x$2" != "x" ; then
5864         AC_MSG_CHECKING(checking for compatible value versus $2)
5865         AC_TRY_COMPILE([#include <sys/types.h>
5866 ],[
5867 #if $1-$2 < 0
5868 make an error
5869 #endif],[cf_result=yes],[cf_result=no])
5870         AC_MSG_RESULT($cf_result)
5871         if test "$cf_result" = no ; then
5872                 # perhaps we can override it - try...
5873                 CPPFLAGS="$CPPFLAGS -D$1=$2"
5874         fi
5875 fi
5876 ])dnl
5877 dnl ---------------------------------------------------------------------------
5878 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
5879 dnl ------------
5880 dnl Append definitions and rules for the given programs to the subdirectory
5881 dnl Makefiles, and the recursion rule for the top-level Makefile.
5882 dnl
5883 dnl parameters
5884 dnl     $1 = script to run
5885 dnl     $2 = list of subdirectories
5886 dnl
5887 dnl variables
5888 dnl     $AWK
5889 AC_DEFUN([CF_PRG_RULES],
5890 [
5891 for cf_dir in $2
5892 do
5893         if test ! -d $srcdir/$cf_dir; then
5894                 continue
5895         elif test -f $srcdir/$cf_dir/programs; then
5896                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
5897         fi
5898 done
5899
5900 ])dnl
5901 dnl ---------------------------------------------------------------------------
5902 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
5903 dnl ----------
5904 dnl Check for archiver "ar".
5905 AC_DEFUN([CF_PROG_AR],[
5906 AC_CHECK_TOOL(AR, ar, ar)
5907 ])
5908 dnl ---------------------------------------------------------------------------
5909 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
5910 dnl -----------
5911 dnl Check for awk, ensure that the check found something.
5912 AC_DEFUN([CF_PROG_AWK],
5913 [
5914 AC_PROG_AWK
5915 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
5916 ])dnl
5917 dnl ---------------------------------------------------------------------------
5918 dnl CF_PROG_CC version: 4 updated: 2014/07/12 18:57:58
5919 dnl ----------
5920 dnl standard check for CC, plus followup sanity checks
5921 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
5922 AC_DEFUN([CF_PROG_CC],[
5923 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
5924 CF_GCC_VERSION
5925 CF_ACVERSION_CHECK(2.52,
5926         [AC_PROG_CC_STDC],
5927         [CF_ANSI_CC_REQD])
5928 CF_CC_ENV_FLAGS
5929 ])dnl
5930 dnl ---------------------------------------------------------------------------
5931 dnl CF_PROG_CC_C_O version: 5 updated: 2017/01/21 11:06:25
5932 dnl --------------
5933 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
5934 dnl the output file can be renamed, and allows for a shell variable that can
5935 dnl be used later.  The parameter is either CC or CXX.  The result is the
5936 dnl cache variable:
5937 dnl     $cf_cv_prog_CC_c_o
5938 dnl     $cf_cv_prog_CXX_c_o
5939 dnl
5940 dnl $1 = compiler
5941 dnl $2 = compiler options, if any
5942 AC_DEFUN([CF_PROG_CC_C_O],
5943 [AC_REQUIRE([AC_PROG_CC])dnl
5944 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
5945 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
5946 [
5947 cat > conftest.$ac_ext <<CF_EOF
5948 int main(void)
5949 {
5950         ${cf_cv_main_return:-return}(0);
5951 }
5952 CF_EOF
5953 # We do the test twice because some compilers refuse to overwrite an
5954 # existing .o file with -o, though they will create one.
5955 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
5956 if AC_TRY_EVAL(ac_try) &&
5957   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
5958 then
5959   eval cf_cv_prog_$1_c_o=yes
5960 else
5961   eval cf_cv_prog_$1_c_o=no
5962 fi
5963 rm -rf conftest*
5964 ])dnl
5965 if test $cf_cv_prog_$1_c_o = yes; then
5966   AC_MSG_RESULT([yes])
5967 else
5968   AC_MSG_RESULT([no])
5969 fi
5970 ])dnl
5971 dnl ---------------------------------------------------------------------------
5972 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
5973 dnl -------------
5974 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
5975 dnl This macro adds a check to ensure the script found something.
5976 AC_DEFUN([CF_PROG_EGREP],
5977 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
5978         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
5979                 then ac_cv_prog_egrep='grep -E'
5980                 else ac_cv_prog_egrep='egrep'
5981         fi])
5982         EGREP=$ac_cv_prog_egrep
5983         AC_SUBST([EGREP])
5984         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
5985 ])dnl
5986 dnl ---------------------------------------------------------------------------
5987 dnl CF_PROG_GNAT version: 9 updated: 2019/09/21 18:08:42
5988 dnl ------------
5989 dnl Check for gnat/gnatmake/etc, ensure that the toolset is complete.
5990 AC_DEFUN([CF_PROG_GNAT],[
5991 for cf_prog_gnat in gnat gnatmake gprconfig gprbuild
5992 do
5993         CF_UPPER(cf_upper_prog_gnat,${cf_prog_gnat})
5994
5995         unset ac_cv_path_cf_TEMP_gnat
5996         unset cf_TEMP_gnat
5997         AC_PATH_PROG(cf_TEMP_gnat,$cf_prog_gnat,no)
5998         eval cf_cv_PATH_$cf_upper_prog_gnat=[$]ac_cv_path_cf_TEMP_gnat
5999
6000         if test "x$cf_TEMP_gnat" != xno; then
6001                 unset cf_gnat_version
6002                 unset cf_TEMP_gnat
6003                 CF_GNAT_VERSION(cf_TEMP_gnat,$cf_prog_gnat)
6004         fi
6005         eval cf_cv_VERSION_$cf_upper_prog_gnat=[$]cf_TEMP_gnat
6006
6007         unset cf_TEMP_gnat
6008         unset cf_gnat_version
6009         unset ac_cv_path_cf_TEMP_gnat
6010 done
6011
6012 if test "x$cf_cv_VERSION_GNATMAKE" = "xno"; then
6013         cf_ada_make=
6014         cf_cv_prog_gnat_correct=no
6015 else
6016         cf_ada_make=gnatmake
6017         if test "x$cf_cv_VERSION_GPRCONFIG" = "xno"; then
6018                 # gprconfig is newer than gnatmake; we can continue...
6019                 cf_ada_config="##"
6020         else
6021                 rm -rf conftest* *~conftest*
6022                 if mkdir conftest.src
6023                 then
6024                         cf_ada_config=""
6025                         cd conftest.src
6026                         for cf_gprconfig in Ada C
6027                         do
6028                                 AC_MSG_CHECKING(for gprconfig name for $cf_gprconfig)
6029                                 if test $cf_gprconfig = C
6030                                 then
6031                                         for cf_gprconfig_param in \
6032                                                 $cf_gprconfig,,,,GNATGCC \
6033                                                 $cf_gprconfig,,,,GCC \
6034                                                 $cf_gprconfig
6035                                         do
6036                                                 cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
6037                                                 test -n "$cf_gprconfig_value" && break
6038                                         done
6039                                 else
6040                                         cf_gprconfig_param=$cf_gprconfig
6041                                         cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
6042                                 fi
6043                                 if test -n "$cf_gprconfig_value"
6044                                 then
6045                                         eval cf_ada_config_[$]cf_gprconfig=[$]cf_gprconfig_value
6046                                         AC_MSG_RESULT($cf_gprconfig_value)
6047                                 else
6048                                         AC_MSG_RESULT(missing)
6049                                         cf_ada_config="#"
6050                                         break
6051                                 fi
6052                         done
6053                         cd ..
6054                         rm -rf conftest* *~conftest*
6055                 fi
6056         fi
6057         if test "x$cf_ada_config" != "x#"
6058         then
6059                 CF_GNAT_VERSION
6060                 CF_CHECK_GNAT_VERSION
6061                 AC_CHECK_PROG(M4_exists, m4, yes, no)
6062                 if test "$ac_cv_prog_M4_exists" = no; then
6063                         cf_cv_prog_gnat_correct=no
6064                         AC_MSG_WARN(Ada95 binding required program m4 not found. Ada95 binding disabled)
6065                 fi
6066                 if test "$cf_cv_prog_gnat_correct" = yes; then
6067                         AC_MSG_CHECKING(if GNAT works)
6068                         CF_GNAT_TRY_RUN([procedure conftest;],
6069 [with Text_IO;
6070 with GNAT.OS_Lib;
6071 procedure conftest is
6072 begin
6073    Text_IO.Put ("Hello World");
6074    Text_IO.New_Line;
6075    GNAT.OS_Lib.OS_Exit (0);
6076 end conftest;],
6077 [cf_cv_prog_gnat_correct=yes],
6078 [cf_cv_prog_gnat_correct=no])
6079                         AC_MSG_RESULT($cf_cv_prog_gnat_correct)
6080                 fi
6081         else
6082                 cf_cv_prog_gnat_correct=no
6083         fi
6084 fi
6085
6086 AC_SUBST(cf_ada_make)
6087 AC_SUBST(cf_ada_config)
6088 AC_SUBST(cf_ada_config_Ada)
6089 AC_SUBST(cf_ada_config_C)
6090 ])dnl
6091 dnl ---------------------------------------------------------------------------
6092 dnl CF_PROG_INSTALL version: 7 updated: 2015/04/18 08:56:57
6093 dnl ---------------
6094 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
6095 dnl misc/tabset install won't work properly.  Usually this happens only when
6096 dnl using the fallback mkinstalldirs script
6097 AC_DEFUN([CF_PROG_INSTALL],
6098 [AC_PROG_INSTALL
6099 case $INSTALL in
6100 (/*)
6101         ;;
6102 (*)
6103         CF_DIRNAME(cf_dir,$INSTALL)
6104         test -z "$cf_dir" && cf_dir=.
6105         INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
6106         ;;
6107 esac
6108 ])dnl
6109 dnl ---------------------------------------------------------------------------
6110 dnl CF_PROG_LDCONFIG version: 5 updated: 2015/04/18 08:56:57
6111 dnl ----------------
6112 dnl Check for ldconfig, needed to fixup shared libraries that would be built
6113 dnl and then used in the install.
6114 AC_DEFUN([CF_PROG_LDCONFIG],[
6115 if test "$cross_compiling" = yes ; then
6116         LDCONFIG=:
6117 else
6118         case "$cf_cv_system_name" in
6119         (dragonfly*|mirbsd*|freebsd*)
6120                 test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
6121                 ;;
6122         (*) LDPATH=$PATH:/sbin:/usr/sbin
6123                 AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
6124                 ;;
6125         esac
6126 fi
6127 AC_SUBST(LDCONFIG)
6128 ])dnl
6129 dnl ---------------------------------------------------------------------------
6130 dnl CF_PROG_LINT version: 3 updated: 2016/05/22 15:25:54
6131 dnl ------------
6132 AC_DEFUN([CF_PROG_LINT],
6133 [
6134 AC_CHECK_PROGS(LINT, lint cppcheck splint)
6135 AC_SUBST(LINT_OPTS)
6136 ])dnl
6137 dnl ---------------------------------------------------------------------------
6138 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
6139 dnl ------------
6140 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
6141 dnl option if it is supported.
6142 AC_DEFUN([CF_PROG_LN_S],[
6143 AC_PROG_LN_S
6144 AC_MSG_CHECKING(if $LN_S -f options work)
6145
6146 rm -f conf$$.src conf$$dst
6147 echo >conf$$.dst
6148 echo first >conf$$.src
6149 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
6150         cf_prog_ln_sf=yes
6151 else
6152         cf_prog_ln_sf=no
6153 fi
6154 rm -f conf$$.dst conf$$src
6155 AC_MSG_RESULT($cf_prog_ln_sf)
6156
6157 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
6158 ])dnl
6159 dnl ---------------------------------------------------------------------------
6160 dnl CF_REGEX version: 12 updated: 2015/04/18 08:56:57
6161 dnl --------
6162 dnl Attempt to determine if we've got one of the flavors of regular-expression
6163 dnl code that we can support.
6164 AC_DEFUN([CF_REGEX],
6165 [
6166
6167 cf_regex_func=no
6168
6169 cf_regex_libs="regex re"
6170 case $host_os in
6171 (mingw*)
6172         cf_regex_libs="gnurx $cf_regex_libs"
6173         ;;
6174 esac
6175
6176 AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
6177         for cf_regex_lib in $cf_regex_libs
6178         do
6179                 AC_CHECK_LIB($cf_regex_lib,regcomp,[
6180                                 CF_ADD_LIB($cf_regex_lib)
6181                                 cf_regex_func=regcomp
6182                                 break])
6183         done
6184 ])
6185
6186 if test "$cf_regex_func" = no ; then
6187         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
6188                 AC_CHECK_LIB(gen,compile,[
6189                                 CF_ADD_LIB(gen)
6190                                 cf_regex_func=compile])])
6191 fi
6192
6193 if test "$cf_regex_func" = no ; then
6194         AC_MSG_WARN(cannot find regular expression library)
6195 fi
6196
6197 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
6198
6199 cf_cv_regex_hdrs=no
6200 case $cf_regex_func in
6201 (compile)
6202         for cf_regex_hdr in regexp.h regexpr.h
6203         do
6204                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
6205                         char *p = compile("", "", "", 0);
6206                         int x = step("", "");
6207                 ],[
6208                         cf_cv_regex_hdrs=$cf_regex_hdr
6209                         break
6210                 ])
6211         done
6212         ;;
6213 (*)
6214         for cf_regex_hdr in regex.h
6215         do
6216                 AC_TRY_LINK([#include <sys/types.h>
6217 #include <$cf_regex_hdr>],[
6218                         regex_t *p;
6219                         int x = regcomp(p, "", 0);
6220                         int y = regexec(p, "", 0, 0, 0);
6221                         regfree(p);
6222                 ],[
6223                         cf_cv_regex_hdrs=$cf_regex_hdr
6224                         break
6225                 ])
6226         done
6227         ;;
6228 esac
6229
6230 ])
6231
6232 case $cf_cv_regex_hdrs in
6233         (no)            AC_MSG_WARN(no regular expression header found) ;;
6234         (regex.h)       AC_DEFINE(HAVE_REGEX_H_FUNCS,1,[Define to 1 to include regex.h for regular expressions]) ;;
6235         (regexp.h)      AC_DEFINE(HAVE_REGEXP_H_FUNCS,1,[Define to 1 to include regexp.h for regular expressions]) ;;
6236         (regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS,1,[Define to 1 to include regexpr.h for regular expressions]) ;;
6237 esac
6238 ])dnl
6239 dnl ---------------------------------------------------------------------------
6240 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
6241 dnl ----------------
6242 dnl Remove all -U and -D options that refer to the given symbol from a list
6243 dnl of C compiler options.  This works around the problem that not all
6244 dnl compilers process -U and -D options from left-to-right, so a -U option
6245 dnl cannot be used to cancel the effect of a preceding -D option.
6246 dnl
6247 dnl $1 = target (which could be the same as the source variable)
6248 dnl $2 = source (including '$')
6249 dnl $3 = symbol to remove
6250 define([CF_REMOVE_DEFINE],
6251 [
6252 $1=`echo "$2" | \
6253         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
6254                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
6255 ])dnl
6256 dnl ---------------------------------------------------------------------------
6257 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
6258 dnl -------------
6259 dnl Remove the given library from the symbol
6260 dnl
6261 dnl $1 = target (which could be the same as the source variable)
6262 dnl $2 = source (including '$')
6263 dnl $3 = library to remove
6264 define([CF_REMOVE_LIB],
6265 [
6266 # remove $3 library from $2
6267 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
6268 ])dnl
6269 dnl ---------------------------------------------------------------------------
6270 dnl CF_RPATH_HACK version: 11 updated: 2013/09/01 13:02:00
6271 dnl -------------
6272 AC_DEFUN([CF_RPATH_HACK],
6273 [
6274 AC_REQUIRE([CF_LD_RPATH_OPT])
6275 AC_MSG_CHECKING(for updated LDFLAGS)
6276 if test -n "$LD_RPATH_OPT" ; then
6277         AC_MSG_RESULT(maybe)
6278
6279         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
6280         cf_rpath_list="/usr/lib /lib"
6281         if test "$cf_ldd_prog" != no
6282         then
6283                 cf_rpath_oops=
6284
6285 AC_TRY_LINK([#include <stdio.h>],
6286                 [printf("Hello");],
6287                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
6288                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
6289
6290                 # If we passed the link-test, but get a "not found" on a given library,
6291                 # this could be due to inept reconfiguration of gcc to make it only
6292                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
6293                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
6294                 # /usr/local libraries.
6295                 if test -n "$cf_rpath_oops"
6296                 then
6297                         for cf_rpath_src in $cf_rpath_oops
6298                         do
6299                                 for cf_rpath_dir in \
6300                                         /usr/local \
6301                                         /usr/pkg \
6302                                         /opt/sfw
6303                                 do
6304                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
6305                                         then
6306                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
6307                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
6308                                                 break
6309                                         fi
6310                                 done
6311                         done
6312                 fi
6313         fi
6314
6315         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
6316
6317         CF_RPATH_HACK_2(LDFLAGS)
6318         CF_RPATH_HACK_2(LIBS)
6319
6320         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
6321 else
6322         AC_MSG_RESULT(no)
6323 fi
6324 AC_SUBST(EXTRA_LDFLAGS)
6325 ])dnl
6326 dnl ---------------------------------------------------------------------------
6327 dnl CF_RPATH_HACK_2 version: 7 updated: 2015/04/12 15:39:00
6328 dnl ---------------
6329 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
6330 dnl EXTRA_LDFLAGS for each -L option found.
6331 dnl
6332 dnl $cf_rpath_list contains a list of directories to ignore.
6333 dnl
6334 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
6335 dnl      but LIBS often has misplaced -L options.
6336 AC_DEFUN([CF_RPATH_HACK_2],
6337 [
6338 CF_VERBOSE(...checking $1 [$]$1)
6339
6340 cf_rpath_dst=
6341 for cf_rpath_src in [$]$1
6342 do
6343         case $cf_rpath_src in
6344         (-L*)
6345
6346                 # check if this refers to a directory which we will ignore
6347                 cf_rpath_skip=no
6348                 if test -n "$cf_rpath_list"
6349                 then
6350                         for cf_rpath_item in $cf_rpath_list
6351                         do
6352                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
6353                                 then
6354                                         cf_rpath_skip=yes
6355                                         break
6356                                 fi
6357                         done
6358                 fi
6359
6360                 if test "$cf_rpath_skip" = no
6361                 then
6362                         # transform the option
6363                         if test "$LD_RPATH_OPT" = "-R " ; then
6364                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
6365                         else
6366                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
6367                         fi
6368
6369                         # if we have not already added this, add it now
6370                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
6371                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
6372                         then
6373                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
6374                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
6375                         fi
6376                 fi
6377                 ;;
6378         esac
6379         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
6380 done
6381 $1=$cf_rpath_dst
6382
6383 CF_VERBOSE(...checked $1 [$]$1)
6384 AC_SUBST(EXTRA_LDFLAGS)
6385 ])dnl
6386 dnl ---------------------------------------------------------------------------
6387 dnl CF_SHARED_OPTS version: 93 updated: 2018/08/18 16:36:35
6388 dnl --------------
6389 dnl --------------
6390 dnl Attempt to determine the appropriate CC/LD options for creating a shared
6391 dnl library.
6392 dnl
6393 dnl Notes:
6394 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
6395 dnl the build-tree, i.e., by making use of the libraries that are compiled in
6396 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
6397 dnl shared library since that can lead to unexpected results at runtime.
6398 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
6399 dnl libraries are compiled in ../../lib
6400 dnl
6401 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
6402 dnl to install symbolic links to the rel/abi versions of shared libraries.
6403 dnl
6404 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
6405 dnl version when making symbolic links.
6406 dnl
6407 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
6408 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
6409 dnl (ex: libncurses.so.<ver>).
6410 dnl
6411 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
6412 AC_DEFUN([CF_SHARED_OPTS],
6413 [
6414         AC_REQUIRE([CF_LD_RPATH_OPT])
6415
6416         RM_SHARED_OPTS=
6417         LOCAL_LDFLAGS=
6418         LOCAL_LDFLAGS2=
6419         LD_SHARED_OPTS=
6420         INSTALL_LIB="-m 644"
6421         : ${rel_builddir:=.}
6422
6423         shlibdir=$libdir
6424         AC_SUBST(shlibdir)
6425
6426         MAKE_DLLS="#"
6427         AC_SUBST(MAKE_DLLS)
6428
6429         cf_cv_do_symlinks=no
6430         cf_ld_rpath_opt=
6431         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
6432
6433         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
6434         AC_ARG_WITH(shlib-version,
6435         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
6436         [test -z "$withval" && withval=auto
6437         case $withval in
6438         (yes)
6439                 cf_cv_shlib_version=auto
6440                 ;;
6441         (rel|abi|auto)
6442                 cf_cv_shlib_version=$withval
6443                 ;;
6444         (*)
6445                 AC_MSG_RESULT($withval)
6446                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
6447                 ;;
6448         esac
6449         ],[cf_cv_shlib_version=auto])
6450         AC_MSG_RESULT($cf_cv_shlib_version)
6451
6452         cf_cv_rm_so_locs=no
6453         cf_try_cflags=
6454
6455         # Some less-capable ports of gcc support only -fpic
6456         CC_SHARED_OPTS=
6457
6458         cf_try_fPIC=no
6459         if test "$GCC" = yes
6460         then
6461                 cf_try_fPIC=yes
6462         else
6463                 case $cf_cv_system_name in
6464                 (*linux*)       # e.g., PGI compiler
6465                         cf_try_fPIC=yes
6466                         ;;
6467                 esac
6468         fi
6469
6470         if test "$cf_try_fPIC" = yes
6471         then
6472                 AC_MSG_CHECKING(which $CC option to use)
6473                 cf_save_CFLAGS="$CFLAGS"
6474                 for CC_SHARED_OPTS in -fPIC -fpic ''
6475                 do
6476                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
6477                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
6478                 done
6479                 AC_MSG_RESULT($CC_SHARED_OPTS)
6480                 CFLAGS="$cf_save_CFLAGS"
6481         fi
6482
6483         cf_cv_shlib_version_infix=no
6484
6485         case $cf_cv_system_name in
6486         (aix4.[3-9]*|aix[[5-7]]*)
6487                 if test "$GCC" = yes; then
6488                         CC_SHARED_OPTS='-Wl,-brtl'
6489                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
6490                 else
6491                         CC_SHARED_OPTS='-brtl'
6492                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
6493                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
6494                 fi
6495                 ;;
6496         (beos*)
6497                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
6498                 ;;
6499         (cygwin*)
6500                 CC_SHARED_OPTS=
6501                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
6502                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
6503                 cf_cv_shlib_version=cygdll
6504                 cf_cv_shlib_version_infix=cygdll
6505                 shlibdir=$bindir
6506                 MAKE_DLLS=
6507                 cat >mk_shared_lib.sh <<-CF_EOF
6508                 #!$SHELL
6509                 SHARED_LIB=\[$]1
6510                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
6511                 shift
6512                 cat <<-EOF
6513                 Linking shared library
6514                 ** SHARED_LIB \[$]SHARED_LIB
6515                 ** IMPORT_LIB \[$]IMPORT_LIB
6516 EOF
6517                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
6518 CF_EOF
6519                 chmod +x mk_shared_lib.sh
6520                 ;;
6521         (msys*)
6522                 CC_SHARED_OPTS=
6523                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
6524                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
6525                 cf_cv_shlib_version=msysdll
6526                 cf_cv_shlib_version_infix=msysdll
6527                 shlibdir=$bindir
6528                 MAKE_DLLS=
6529                 cat >mk_shared_lib.sh <<-CF_EOF
6530                 #!$SHELL
6531                 SHARED_LIB=\[$]1
6532                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
6533                 shift
6534                 cat <<-EOF
6535                 Linking shared library
6536                 ** SHARED_LIB \[$]SHARED_LIB
6537                 ** IMPORT_LIB \[$]IMPORT_LIB
6538 EOF
6539                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
6540 CF_EOF
6541                 chmod +x mk_shared_lib.sh
6542                 ;;
6543         (darwin*)
6544                 cf_try_cflags="no-cpp-precomp"
6545                 CC_SHARED_OPTS="-dynamic"
6546                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
6547                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
6548                 cf_cv_shlib_version_infix=yes
6549                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
6550                         cf_save_LDFLAGS=$LDFLAGS
6551                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
6552                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
6553                                 LDFLAGS=$cf_save_LDFLAGS])
6554                 if test $cf_cv_ldflags_search_paths_first = yes; then
6555                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
6556                 fi
6557                 ;;
6558         (hpux[[7-8]]*)
6559                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
6560                 if test "$GCC" != yes; then
6561                         CC_SHARED_OPTS='+Z'
6562                 fi
6563                 MK_SHARED_LIB='${LD} ${LDFLAGS} -b -o $[@]'
6564                 INSTALL_LIB="-m 555"
6565                 ;;
6566         (hpux*)
6567                 # (tested with gcc 2.7.2 -- I don't have c89)
6568                 if test "$GCC" = yes; then
6569                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
6570                 else
6571                         CC_SHARED_OPTS='+Z'
6572                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
6573                 fi
6574                 MK_SHARED_LIB='${LD} ${LDFLAGS} +b ${libdir} -b -o $[@]'
6575                 # HP-UX shared libraries must be executable, and should be
6576                 # readonly to exploit a quirk in the memory manager.
6577                 INSTALL_LIB="-m 555"
6578                 ;;
6579         (interix*)
6580                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6581                 if test "$cf_cv_shlib_version" = rel; then
6582                         cf_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
6583                 else
6584                         cf_shared_soname='`basename $[@]`'
6585                 fi
6586                 CC_SHARED_OPTS=
6587                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $[@]'
6588                 ;;
6589         (irix*)
6590                 if test "$cf_cv_enable_rpath" = yes ; then
6591                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6592                 fi
6593                 # tested with IRIX 5.2 and 'cc'.
6594                 if test "$GCC" != yes; then
6595                         CC_SHARED_OPTS='-KPIC'
6596                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
6597                 else
6598                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,`basename $[@]` -o $[@]'
6599                 fi
6600                 cf_cv_rm_so_locs=yes
6601                 ;;
6602         (linux*|gnu*|k*bsd*-gnu)
6603                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
6604                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
6605                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6606                 fi
6607                 if test "$cf_cv_enable_rpath" = yes ; then
6608                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6609                 fi
6610                 CF_SHARED_SONAME
6611                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
6612                 ;;
6613         (mingw*)
6614                 cf_cv_shlib_version=mingw
6615                 cf_cv_shlib_version_infix=mingw
6616                 shlibdir=$bindir
6617                 MAKE_DLLS=
6618                 if test "$DFT_LWR_MODEL" = "shared" ; then
6619                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
6620                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6621                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
6622                 fi
6623                 CC_SHARED_OPTS=
6624                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
6625                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
6626                 cat >mk_shared_lib.sh <<-CF_EOF
6627                 #!$SHELL
6628                 SHARED_LIB=\[$]1
6629                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
6630                 shift
6631                 cat <<-EOF
6632                 Linking shared library
6633                 ** SHARED_LIB \[$]SHARED_LIB
6634                 ** IMPORT_LIB \[$]IMPORT_LIB
6635 EOF
6636                 exec \[$]* ${LDFLAGS} -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
6637 CF_EOF
6638                 chmod +x mk_shared_lib.sh
6639                 ;;
6640         (openbsd[[2-9]].*|mirbsd*)
6641                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
6642                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
6643                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6644                 fi
6645                 if test "$cf_cv_enable_rpath" = yes ; then
6646                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6647                 fi
6648                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
6649                 CF_SHARED_SONAME
6650                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
6651                 ;;
6652         (nto-qnx*|openbsd*|freebsd[[12]].*)
6653                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
6654                 MK_SHARED_LIB='${LD} ${LDFLAGS} -Bshareable -o $[@]'
6655                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6656                 ;;
6657         (dragonfly*|freebsd*)
6658                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
6659                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
6660                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
6661                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
6662                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6663                 fi
6664                 CF_SHARED_SONAME
6665                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
6666                 ;;
6667         (netbsd*)
6668                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
6669                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
6670                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
6671                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6672                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6673                         if test "$cf_cv_shlib_version" = auto; then
6674                         if test -f /usr/libexec/ld.elf_so; then
6675                                 cf_cv_shlib_version=abi
6676                         else
6677                                 cf_cv_shlib_version=rel
6678                         fi
6679                         fi
6680                         CF_SHARED_SONAME
6681                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
6682                 else
6683                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -Wl,-shared -Wl,-Bshareable -o $[@]'
6684                 fi
6685                 ;;
6686         (osf*|mls+*)
6687                 # tested with OSF/1 V3.2 and 'cc'
6688                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
6689                 # link with shared libs).
6690                 MK_SHARED_LIB='${LD} ${LDFLAGS} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
6691                 case $host_os in
6692                 (osf4*)
6693                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
6694                         ;;
6695                 esac
6696                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
6697                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
6698                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
6699                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6700                 fi
6701                 cf_cv_rm_so_locs=yes
6702                 ;;
6703         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
6704                 # tested with osr5.0.5
6705                 if test "$GCC" != yes; then
6706                         CC_SHARED_OPTS='-belf -KPIC'
6707                 fi
6708                 MK_SHARED_LIB='${LD} ${LDFLAGS} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
6709                 if test "$cf_cv_enable_rpath" = yes ; then
6710                         # only way is to set LD_RUN_PATH but no switch for it
6711                         RUN_PATH=$libdir
6712                 fi
6713                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6714                 LINK_PROGS='LD_RUN_PATH=${libdir}'
6715                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
6716                 ;;
6717         (sunos4*)
6718                 # tested with SunOS 4.1.1 and gcc 2.7.0
6719                 if test "$GCC" != yes; then
6720                         CC_SHARED_OPTS='-KPIC'
6721                 fi
6722                 MK_SHARED_LIB='${LD} ${LDFLAGS} -assert pure-text -o $[@]'
6723                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6724                 ;;
6725         (solaris2*)
6726                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
6727                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
6728                 if test "$DFT_LWR_MODEL" = "shared" ; then
6729                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
6730                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6731                 fi
6732                 if test "$cf_cv_enable_rpath" = yes ; then
6733                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
6734                 fi
6735                 CF_SHARED_SONAME
6736                 if test "$GCC" != yes; then
6737                         cf_save_CFLAGS="$CFLAGS"
6738                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
6739                         do
6740                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
6741                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
6742                         done
6743                         CFLAGS="$cf_save_CFLAGS"
6744                         CC_SHARED_OPTS=$cf_shared_opts
6745                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
6746                 else
6747                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
6748                 fi
6749                 ;;
6750         (sysv5uw7*|unix_sv*)
6751                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
6752                 if test "$GCC" != yes; then
6753                         CC_SHARED_OPTS='-KPIC'
6754                 fi
6755                 MK_SHARED_LIB='${LD} ${LDFLAGS} -d y -G -o [$]@'
6756                 ;;
6757         (*)
6758                 CC_SHARED_OPTS='unknown'
6759                 MK_SHARED_LIB='echo unknown'
6760                 ;;
6761         esac
6762
6763         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
6764         case "$cf_cv_shlib_version" in
6765         (rel|abi)
6766                 case "$MK_SHARED_LIB" in
6767                 (*'-o $[@]')
6768                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
6769                         ;;
6770                 (*)
6771                         AC_MSG_WARN(ignored --with-shlib-version)
6772                         ;;
6773                 esac
6774                 ;;
6775         esac
6776
6777         if test -n "$cf_try_cflags"
6778         then
6779 cat > conftest.$ac_ext <<EOF
6780 #line __oline__ "${as_me:-configure}"
6781 #include <stdio.h>
6782 int main(int argc, char *argv[[]])
6783 {
6784         printf("hello\n");
6785         return (argv[[argc-1]] == 0) ;
6786 }
6787 EOF
6788                 cf_save_CFLAGS="$CFLAGS"
6789                 for cf_opt in $cf_try_cflags
6790                 do
6791                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
6792                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
6793                         if AC_TRY_EVAL(ac_compile); then
6794                                 AC_MSG_RESULT(yes)
6795                                 cf_save_CFLAGS="$CFLAGS"
6796                         else
6797                                 AC_MSG_RESULT(no)
6798                         fi
6799                 done
6800                 CFLAGS="$cf_save_CFLAGS"
6801         fi
6802
6803
6804         # RPATH_LIST is a colon-separated list of directories
6805         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
6806         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
6807
6808         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
6809
6810         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
6811         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
6812
6813         AC_SUBST(CC_SHARED_OPTS)
6814         AC_SUBST(LD_RPATH_OPT)
6815         AC_SUBST(LD_SHARED_OPTS)
6816         AC_SUBST(MK_SHARED_LIB)
6817         AC_SUBST(RM_SHARED_OPTS)
6818
6819         AC_SUBST(LINK_PROGS)
6820         AC_SUBST(LINK_TESTS)
6821
6822         AC_SUBST(EXTRA_LDFLAGS)
6823         AC_SUBST(LOCAL_LDFLAGS)
6824         AC_SUBST(LOCAL_LDFLAGS2)
6825
6826         AC_SUBST(INSTALL_LIB)
6827         AC_SUBST(RPATH_LIST)
6828 ])dnl
6829 dnl ---------------------------------------------------------------------------
6830 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
6831 dnl ----------------
6832 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
6833 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
6834 dnl option.
6835 dnl
6836 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
6837 dnl If missing, use "rel".
6838 define([CF_SHARED_SONAME],
6839 [
6840         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
6841         if test "$cf_cv_shlib_version" = rel; then
6842                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
6843         else
6844                 cf_cv_shared_soname='`basename $[@]`'
6845         fi
6846 ])
6847 dnl ---------------------------------------------------------------------------
6848 dnl CF_SIGWINCH version: 2 updated: 2019/03/23 19:54:44
6849 dnl -----------
6850 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
6851 dnl programs need this test).
6852 dnl
6853 dnl This is really a Mac OS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
6854 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
6855 dnl winsize declaration is left alone - we may revisit this if Apple choose to
6856 dnl break that part of the interface as well.
6857 AC_DEFUN([CF_SIGWINCH],
6858 [
6859 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
6860         AC_TRY_COMPILE([
6861 #include <sys/types.h>
6862 #include <sys/signal.h>
6863 ],[int x = SIGWINCH],
6864         [cf_cv_define_sigwinch=yes],
6865         [AC_TRY_COMPILE([
6866 #undef _XOPEN_SOURCE
6867 #undef _POSIX_SOURCE
6868 #undef _POSIX_C_SOURCE
6869 #include <sys/types.h>
6870 #include <sys/signal.h>
6871 ],[int x = SIGWINCH],
6872         [cf_cv_define_sigwinch=maybe],
6873         [cf_cv_define_sigwinch=no])
6874 ])
6875 ])
6876
6877 if test "$cf_cv_define_sigwinch" = maybe ; then
6878 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
6879 cf_cv_fixup_sigwinch=unknown
6880 cf_sigwinch=32
6881 while test $cf_sigwinch != 1
6882 do
6883         AC_TRY_COMPILE([
6884 #undef _XOPEN_SOURCE
6885 #undef _POSIX_SOURCE
6886 #undef _POSIX_C_SOURCE
6887 #include <sys/types.h>
6888 #include <sys/signal.h>
6889 ],[
6890 #if SIGWINCH != $cf_sigwinch
6891 make an error
6892 #endif
6893 int x = SIGWINCH],
6894         [cf_cv_fixup_sigwinch=$cf_sigwinch
6895          break])
6896
6897 cf_sigwinch=`expr $cf_sigwinch - 1`
6898 done
6899 ])
6900
6901         if test "$cf_cv_fixup_sigwinch" != unknown ; then
6902                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
6903         fi
6904 fi
6905 ])dnl
6906 dnl ---------------------------------------------------------------------------
6907 dnl CF_SIG_ATOMIC_T version: 3 updated: 2012/10/04 20:12:20
6908 dnl ---------------
6909 dnl signal handler, but there are some gcc depedencies in that recommendation.
6910 dnl Try anyway.
6911 AC_DEFUN([CF_SIG_ATOMIC_T],
6912 [
6913 AC_MSG_CHECKING(for signal global datatype)
6914 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
6915         for cf_type in \
6916                 "volatile sig_atomic_t" \
6917                 "sig_atomic_t" \
6918                 "int"
6919         do
6920         AC_TRY_COMPILE([
6921 #include <sys/types.h>
6922 #include <signal.h>
6923 #include <stdio.h>
6924
6925 extern $cf_type x;
6926 $cf_type x;
6927 static void handler(int sig)
6928 {
6929         x = 5;
6930 }],
6931                 [signal(SIGINT, handler);
6932                  x = 1],
6933                 [cf_cv_sig_atomic_t=$cf_type],
6934                 [cf_cv_sig_atomic_t=no])
6935                 test "$cf_cv_sig_atomic_t" != no && break
6936         done
6937         ])
6938 AC_MSG_RESULT($cf_cv_sig_atomic_t)
6939 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
6940 ])dnl
6941 dnl ---------------------------------------------------------------------------
6942 dnl CF_SIZECHANGE version: 14 updated: 2018/06/20 20:23:13
6943 dnl -------------
6944 dnl Check for definitions & structures needed for window size-changing
6945 dnl
6946 dnl https://stackoverflow.com/questions/18878141/difference-between-structures-ttysize-and-winsize/50769952#50769952
6947 AC_DEFUN([CF_SIZECHANGE],
6948 [
6949 AC_REQUIRE([CF_STRUCT_TERMIOS])
6950 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
6951         cf_cv_sizechange=unknown
6952         cf_save_CPPFLAGS="$CPPFLAGS"
6953
6954 for cf_opts in "" "NEED_PTEM_H"
6955 do
6956
6957         CPPFLAGS="$cf_save_CPPFLAGS"
6958         if test -n "$cf_opts"
6959         then
6960                 CF_APPEND_TEXT(CPPFLAGS,-D$cf_opts)
6961         fi
6962         AC_TRY_COMPILE([#include <sys/types.h>
6963 #ifdef HAVE_TERMIOS_H
6964 #include <termios.h>
6965 #else
6966 #ifdef HAVE_TERMIO_H
6967 #include <termio.h>
6968 #endif
6969 #endif
6970
6971 #ifdef NEED_PTEM_H
6972 /* This is a workaround for SCO:  they neglected to define struct winsize in
6973  * termios.h -- it's only in termio.h and ptem.h
6974  */
6975 #include <sys/stream.h>
6976 #include <sys/ptem.h>
6977 #endif
6978
6979 #ifdef HAVE_SYS_IOCTL_H
6980 #include <sys/ioctl.h>
6981 #endif
6982 ],[
6983 #ifdef TIOCGSIZE
6984         struct ttysize win;     /* SunOS 3.0... */
6985         int y = win.ts_lines;
6986         int x = win.ts_cols;
6987 #else
6988 #ifdef TIOCGWINSZ
6989         struct winsize win;     /* everything else */
6990         int y = win.ws_row;
6991         int x = win.ws_col;
6992 #else
6993         no TIOCGSIZE or TIOCGWINSZ
6994 #endif /* TIOCGWINSZ */
6995 #endif /* TIOCGSIZE */
6996         ],
6997         [cf_cv_sizechange=yes],
6998         [cf_cv_sizechange=no])
6999
7000         CPPFLAGS="$cf_save_CPPFLAGS"
7001         if test "$cf_cv_sizechange" = yes ; then
7002                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
7003                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
7004                 break
7005         fi
7006 done
7007 ])
7008 if test "$cf_cv_sizechange" != no ; then
7009         AC_DEFINE(HAVE_SIZECHANGE,1,[Define to 1 if sizechange declarations are provided])
7010         case $cf_cv_sizechange in
7011         (NEED*)
7012                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
7013                 ;;
7014         esac
7015 fi
7016 ])dnl
7017 dnl ---------------------------------------------------------------------------
7018 dnl CF_SRC_MODULES version: 31 updated: 2019/09/21 18:08:42
7019 dnl --------------
7020 dnl For each parameter, test if the source-directory exists, and if it contains
7021 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
7022 dnl use in CF_LIB_RULES.
7023 dnl
7024 dnl This uses the configured value to make the lists SRC_SUBDIRS and
7025 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
7026 AC_DEFUN([CF_SRC_MODULES],
7027 [
7028 AC_REQUIRE([CF_CHECK_GNAT_VERSION])
7029 AC_MSG_CHECKING(for src modules)
7030
7031 # dependencies and linker-arguments for test-programs
7032 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
7033 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
7034 if test "$DFT_LWR_MODEL" = "libtool"; then
7035         TEST_ARGS="${TEST_DEPS}"
7036         TEST_ARG2="${TEST_DEP2}"
7037 else
7038         TEST_ARGS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
7039         TEST_ARG2="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARG2"
7040 fi
7041
7042 PC_MODULES_TO_MAKE="ncurses${USE_ARG_SUFFIX}"
7043 cf_cv_src_modules=
7044 for cf_dir in $1
7045 do
7046         if test -f $srcdir/$cf_dir/modules; then
7047
7048                 # We may/may not have tack in the distribution, though the
7049                 # makefile is.
7050                 if test $cf_dir = tack ; then
7051                         if test "x$cf_with_tack" != "xyes"; then
7052                                 continue
7053                         fi
7054                 fi
7055
7056                 if test -z "$cf_cv_src_modules"; then
7057                         cf_cv_src_modules=$cf_dir
7058                 else
7059                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
7060                 fi
7061
7062                 # Make the ncurses_cfg.h file record the library interface files as
7063                 # well.  These are header files that are the same name as their
7064                 # directory.  Ncurses is the only library that does not follow
7065                 # that pattern.
7066                 if test $cf_dir = tack ; then
7067                         continue
7068                 elif test -f $srcdir/${cf_dir}/${cf_dir}.h; then
7069                         CF_UPPER(cf_have_include,$cf_dir)
7070                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
7071                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
7072                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEPS"
7073                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEP2"
7074                         if test "$DFT_LWR_MODEL" = "libtool"; then
7075                                 TEST_ARGS="${TEST_DEPS}"
7076                                 TEST_ARG2="${TEST_DEP2}"
7077                         else
7078                                 TEST_ARGS="-l${cf_dir}${USE_ARG_SUFFIX} $TEST_ARGS"
7079                                 TEST_ARG2="-l${cf_dir}${USE_ARG_SUFFIX} $TEST_ARG2"
7080                         fi
7081                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${USE_ARG_SUFFIX}"
7082                 fi
7083         fi
7084 done
7085 AC_MSG_RESULT($cf_cv_src_modules)
7086
7087 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
7088 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
7089
7090 AC_SUBST(TEST_ARGS)
7091 AC_SUBST(TEST_DEPS)
7092
7093 AC_SUBST(TEST_ARG2)
7094 AC_SUBST(TEST_DEP2)
7095
7096 SRC_SUBDIRS=
7097 if test "x$cf_with_manpages" != xno ; then
7098         SRC_SUBDIRS="$SRC_SUBDIRS man"
7099 fi
7100 SRC_SUBDIRS="$SRC_SUBDIRS include"
7101 for cf_dir in $cf_cv_src_modules
7102 do
7103         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
7104 done
7105 if test "x$cf_with_tests" != "xno" ; then
7106         SRC_SUBDIRS="$SRC_SUBDIRS test"
7107 fi
7108 # always make this, to install the ncurses-config script
7109 SRC_SUBDIRS="$SRC_SUBDIRS misc"
7110 if test "$cf_with_cxx_binding" != no; then
7111         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${USE_ARG_SUFFIX}"
7112         SRC_SUBDIRS="$SRC_SUBDIRS c++"
7113 fi
7114
7115 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
7116 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
7117
7118 AC_SUBST(PC_MODULES_TO_MAKE)
7119
7120 ADA_SUBDIRS=
7121 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f $srcdir/Ada95/Makefile.in; then
7122         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
7123         ADA_SUBDIRS="gen src"
7124         if test "x$cf_with_tests" != "xno" ; then
7125                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
7126         fi
7127 fi
7128
7129 SUB_MAKEFILES=
7130 for cf_dir in $SRC_SUBDIRS
7131 do
7132         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
7133 done
7134
7135 if test -n "$ADA_SUBDIRS"; then
7136         for cf_dir in $ADA_SUBDIRS
7137         do
7138                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
7139         done
7140         AC_SUBST(ADA_SUBDIRS)
7141 fi
7142 ])dnl
7143 dnl ---------------------------------------------------------------------------
7144 dnl CF_STDCPP_LIBRARY version: 11 updated: 2015/10/17 19:03:33
7145 dnl -----------------
7146 dnl Check for -lstdc++, which is GNU's standard C++ library.
7147 dnl If $CXXLIBS is set, add that to the libraries used for test-linking.
7148 dnl If -lstdc++ was not already added to $LIBS or $CXXLIBS, and is needed,
7149 dnl add it to $CXXLIBS.
7150 AC_DEFUN([CF_STDCPP_LIBRARY],
7151 [
7152 if test -n "$GXX" ; then
7153
7154         cf_save="$LIBS"
7155         LIBS="$LIBS $CXXLIBS"
7156         AC_MSG_CHECKING(if we already have C++ library)
7157         AC_TRY_LINK([
7158                         #include <iostream>],[
7159                         std::cout << "Hello World!" << std::endl;],
7160                 [cf_have_libstdcpp=yes],
7161                 [cf_have_libstdcpp=no])
7162         AC_MSG_RESULT($cf_have_libstdcpp)
7163         LIBS="$cf_save"
7164
7165         if test $cf_have_libstdcpp != yes
7166         then
7167                 case $cf_cv_system_name in
7168                 (os2*)
7169                         if test -z "`g++ -dM -E - < /dev/null | grep __KLIBC__`"; then
7170                                 cf_stdcpp_libname=stdcpp
7171                         else
7172                                 cf_stdcpp_libname=stdc++
7173                         fi
7174                         ;;
7175                 (*)
7176                         cf_stdcpp_libname=stdc++
7177                         ;;
7178                 esac
7179
7180                 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
7181                         cf_save="$LIBS"
7182                         LIBS="$LIBS $CXXLIBS"
7183                         CF_ADD_LIB($cf_stdcpp_libname)
7184                 AC_TRY_LINK([
7185                                 #include <iostream>],[
7186                                 std::cout << "Hello World!" << std::endl;],
7187                         [cf_cv_libstdcpp=yes],
7188                         [cf_cv_libstdcpp=no])
7189                         LIBS="$cf_save"
7190                 ])
7191                 test "$cf_cv_libstdcpp" = yes && { CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS) }
7192         fi
7193 fi
7194 ])dnl
7195 dnl ---------------------------------------------------------------------------
7196 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
7197 dnl --------------
7198 dnl     Remove "-g" option from the compiler options
7199 AC_DEFUN([CF_STRIP_G_OPT],
7200 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
7201 dnl ---------------------------------------------------------------------------
7202 dnl CF_STRUCT_SIGACTION version: 5 updated: 2012/10/06 17:56:13
7203 dnl -------------------
7204 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
7205 dnl do this if we've found the sigaction function.
7206 AC_DEFUN([CF_STRUCT_SIGACTION],[
7207 AC_REQUIRE([CF_XOPEN_SOURCE])
7208
7209 if test "$ac_cv_func_sigaction" = yes; then
7210 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
7211 AC_TRY_COMPILE([
7212 #include <sys/types.h>
7213 #include <signal.h>],
7214         [struct sigaction act],
7215         [sigact_bad=no],
7216         [
7217 AC_TRY_COMPILE([
7218 #define _POSIX_SOURCE
7219 #include <sys/types.h>
7220 #include <signal.h>],
7221         [struct sigaction act],
7222         [sigact_bad=yes
7223          AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE])],
7224          [sigact_bad=unknown])])
7225 AC_MSG_RESULT($sigact_bad)
7226 fi
7227 ])dnl
7228 dnl ---------------------------------------------------------------------------
7229 dnl CF_STRUCT_TERMIOS version: 9 updated: 2018/06/08 21:57:23
7230 dnl -----------------
7231 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
7232 AC_DEFUN([CF_STRUCT_TERMIOS],[
7233 AC_REQUIRE([CF_XOPEN_SOURCE])
7234
7235 AC_CHECK_HEADERS( \
7236 termio.h \
7237 termios.h \
7238 unistd.h \
7239 sys/ioctl.h \
7240 sys/termio.h \
7241 )
7242
7243 if test "$ac_cv_header_termios_h" = yes ; then
7244         case "$CFLAGS $CPPFLAGS" in
7245         (*-D_POSIX_SOURCE*)
7246                 termios_bad=dunno ;;
7247         (*)     termios_bad=maybe ;;
7248         esac
7249         if test "$termios_bad" = maybe ; then
7250         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
7251         AC_TRY_COMPILE([#include <termios.h>],
7252                 [struct termios foo; int x = foo.c_iflag],
7253                 termios_bad=no, [
7254                 AC_TRY_COMPILE([
7255 #define _POSIX_SOURCE
7256 #include <termios.h>],
7257                         [struct termios foo; int x = foo.c_iflag],
7258                         termios_bad=unknown,
7259                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE]))
7260                         ])
7261         AC_MSG_RESULT($termios_bad)
7262         fi
7263 fi
7264 ])dnl
7265 dnl ---------------------------------------------------------------------------
7266 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
7267 dnl --------------
7268 dnl Construct a search-list for a nonstandard header/lib-file
7269 dnl     $1 = the variable to return as result
7270 dnl     $2 = the package name
7271 dnl     $3 = the subdirectory, e.g., bin, include or lib
7272 AC_DEFUN([CF_SUBDIR_PATH],
7273 [
7274 $1=
7275
7276 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
7277
7278 for cf_subdir_prefix in \
7279         /usr \
7280         /usr/local \
7281         /usr/pkg \
7282         /opt \
7283         /opt/local \
7284         [$]HOME
7285 do
7286         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
7287 done
7288 ])dnl
7289 dnl ---------------------------------------------------------------------------
7290 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
7291 dnl -----------
7292 dnl     Shorthand macro for substituting things that the user may override
7293 dnl     with an environment variable.
7294 dnl
7295 dnl     $1 = condition to pass to "test"
7296 dnl     $2 = environment variable
7297 dnl     $3 = value if the test succeeds
7298 dnl     $4 = value if the test fails
7299 AC_DEFUN([CF_SUBST_IF],
7300 [
7301 if test $1 ; then
7302         $2=$3
7303 ifelse($4,,,[else
7304         $2=$4])
7305 fi
7306 AC_SUBST($2)
7307 ])dnl
7308 dnl ---------------------------------------------------------------------------
7309 dnl CF_SUBST_NCURSES_VERSION version: 8 updated: 2006/09/16 11:40:59
7310 dnl ------------------------
7311 dnl Get the version-number for use in shared-library naming, etc.
7312 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
7313 [
7314 AC_REQUIRE([CF_PROG_EGREP])
7315 NCURSES_MAJOR="`$ac_cv_prog_egrep '^NCURSES_MAJOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
7316 NCURSES_MINOR="`$ac_cv_prog_egrep '^NCURSES_MINOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
7317 NCURSES_PATCH="`$ac_cv_prog_egrep '^NCURSES_PATCH[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
7318 cf_cv_abi_version=${NCURSES_MAJOR}
7319 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
7320 dnl Show the computed version, for logging
7321 cf_cv_timestamp=`date`
7322 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
7323 dnl We need these values in the generated headers
7324 AC_SUBST(NCURSES_MAJOR)
7325 AC_SUBST(NCURSES_MINOR)
7326 AC_SUBST(NCURSES_PATCH)
7327 dnl We need these values in the generated makefiles
7328 AC_SUBST(cf_cv_rel_version)
7329 AC_SUBST(cf_cv_abi_version)
7330 AC_SUBST(cf_cv_builtin_bool)
7331 AC_SUBST(cf_cv_header_stdbool_h)
7332 AC_SUBST(cf_cv_type_of_bool)dnl
7333 ])dnl
7334 dnl ---------------------------------------------------------------------------
7335 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
7336 dnl ------------------
7337 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
7338 dnl older SCO configurations.
7339 AC_DEFUN([CF_SYS_TIME_SELECT],
7340 [
7341 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
7342 AC_CACHE_VAL(cf_cv_sys_time_select,[
7343 AC_TRY_COMPILE([
7344 #include <sys/types.h>
7345 #ifdef HAVE_SYS_TIME_H
7346 #include <sys/time.h>
7347 #endif
7348 #ifdef HAVE_SYS_SELECT_H
7349 #include <sys/select.h>
7350 #endif
7351 ],[],[cf_cv_sys_time_select=yes],
7352          [cf_cv_sys_time_select=no])
7353          ])
7354 AC_MSG_RESULT($cf_cv_sys_time_select)
7355 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
7356 ])dnl
7357 dnl ---------------------------------------------------------------------------
7358 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
7359 dnl ---------------
7360 dnl Define a top_builddir symbol, for applications that need an absolute path.
7361 AC_DEFUN([CF_TOP_BUILDDIR],
7362 [
7363 top_builddir=ifelse($1,,`pwd`,$1)
7364 AC_SUBST(top_builddir)
7365 ])dnl
7366 dnl ---------------------------------------------------------------------------
7367 dnl CF_TRY_PKG_CONFIG version: 5 updated: 2013/07/06 21:27:06
7368 dnl -----------------
7369 dnl This is a simple wrapper to use for pkg-config, for libraries which may be
7370 dnl available in that form.
7371 dnl
7372 dnl $1 = package name
7373 dnl $2 = extra logic to use, if any, after updating CFLAGS and LIBS
7374 dnl $3 = logic to use if pkg-config does not have the package
7375 AC_DEFUN([CF_TRY_PKG_CONFIG],[
7376 AC_REQUIRE([CF_PKG_CONFIG])
7377
7378 if test "$PKG_CONFIG" != none && "$PKG_CONFIG" --exists $1; then
7379         CF_VERBOSE(found package $1)
7380         cf_pkgconfig_incs="`$PKG_CONFIG --cflags $1 2>/dev/null`"
7381         cf_pkgconfig_libs="`$PKG_CONFIG --libs   $1 2>/dev/null`"
7382         CF_VERBOSE(package $1 CFLAGS: $cf_pkgconfig_incs)
7383         CF_VERBOSE(package $1 LIBS: $cf_pkgconfig_libs)
7384         CF_ADD_CFLAGS($cf_pkgconfig_incs)
7385         CF_ADD_LIBS($cf_pkgconfig_libs)
7386         ifelse([$2],,:,[$2])
7387 else
7388         cf_pkgconfig_incs=
7389         cf_pkgconfig_libs=
7390         ifelse([$3],,:,[$3])
7391 fi
7392 ])
7393 dnl ---------------------------------------------------------------------------
7394 dnl CF_TRY_XOPEN_SOURCE version: 2 updated: 2018/06/20 20:23:13
7395 dnl -------------------
7396 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
7397 dnl can define it successfully.
7398 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
7399 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
7400         AC_TRY_COMPILE([
7401 #include <stdlib.h>
7402 #include <string.h>
7403 #include <sys/types.h>
7404 ],[
7405 #ifndef _XOPEN_SOURCE
7406 make an error
7407 #endif],
7408         [cf_cv_xopen_source=no],
7409         [cf_save="$CPPFLAGS"
7410          CF_APPEND_TEXT(CPPFLAGS,-D_XOPEN_SOURCE=$cf_XOPEN_SOURCE)
7411          AC_TRY_COMPILE([
7412 #include <stdlib.h>
7413 #include <string.h>
7414 #include <sys/types.h>
7415 ],[
7416 #ifdef _XOPEN_SOURCE
7417 make an error
7418 #endif],
7419         [cf_cv_xopen_source=no],
7420         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
7421         CPPFLAGS="$cf_save"
7422         ])
7423 ])
7424
7425 if test "$cf_cv_xopen_source" != no ; then
7426         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
7427         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
7428         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
7429         CF_ADD_CFLAGS($cf_temp_xopen_source)
7430 fi
7431 ])
7432 dnl ---------------------------------------------------------------------------
7433 dnl CF_TYPEOF_CHTYPE version: 10 updated: 2017/01/21 11:06:25
7434 dnl ----------------
7435 dnl Determine the type we should use for chtype (and attr_t, which is treated
7436 dnl as the same thing).  We want around 32 bits, so on most machines want a
7437 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
7438 dnl wide characters, we have to have a type compatible with that, as well.
7439 AC_DEFUN([CF_TYPEOF_CHTYPE],
7440 [
7441 AC_MSG_CHECKING([for type of chtype])
7442 AC_CACHE_VAL(cf_cv_typeof_chtype,[
7443                 AC_TRY_RUN([
7444 #define WANT_BITS 31
7445 #include <stdio.h>
7446 int main(void)
7447 {
7448         FILE *fp = fopen("cf_test.out", "w");
7449         if (fp != 0) {
7450                 char *result = "long";
7451                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
7452                         int n;
7453                         unsigned int x, y;
7454                         for (n = 0; n < WANT_BITS; n++) {
7455                                 x = (1 << n);
7456                                 y = (x >> n);
7457                                 if (y != 1 || x == 0) {
7458                                         x = 0;
7459                                         break;
7460                                 }
7461                         }
7462                         /*
7463                          * If x is nonzero, an int is big enough for the bits
7464                          * that we want.
7465                          */
7466                         result = (x != 0) ? "int" : "long";
7467                 }
7468                 fputs(result, fp);
7469                 fclose(fp);
7470         }
7471         ${cf_cv_main_return:-return}(0);
7472 }
7473                 ],
7474                 [cf_cv_typeof_chtype=`cat cf_test.out`],
7475                 [cf_cv_typeof_chtype=long],
7476                 [cf_cv_typeof_chtype=long])
7477                 rm -f cf_test.out
7478         ])
7479 AC_MSG_RESULT($cf_cv_typeof_chtype)
7480
7481 AC_SUBST(cf_cv_typeof_chtype)
7482 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype,[Define to actual type if needed for chtype])
7483 ])dnl
7484 dnl ---------------------------------------------------------------------------
7485 dnl CF_TYPE_SIGACTION version: 4 updated: 2012/10/06 17:56:13
7486 dnl -----------------
7487 dnl
7488 AC_DEFUN([CF_TYPE_SIGACTION],
7489 [
7490 AC_MSG_CHECKING([for type sigaction_t])
7491 AC_CACHE_VAL(cf_cv_type_sigaction,[
7492         AC_TRY_COMPILE([
7493 #include <signal.h>],
7494                 [sigaction_t x],
7495                 [cf_cv_type_sigaction=yes],
7496                 [cf_cv_type_sigaction=no])])
7497 AC_MSG_RESULT($cf_cv_type_sigaction)
7498 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION,1,[Define to 1 if we have the sigaction_t type])
7499 ])dnl
7500 dnl ---------------------------------------------------------------------------
7501 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
7502 dnl --------------------
7503 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
7504 dnl won't, but they're still there.
7505 AC_DEFUN([CF_UNSIGNED_LITERALS],
7506 [
7507 AC_MSG_CHECKING([if unsigned literals are legal])
7508 AC_CACHE_VAL(cf_cv_unsigned_literals,[
7509         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
7510                 [cf_cv_unsigned_literals=yes],
7511                 [cf_cv_unsigned_literals=no])
7512         ])
7513 AC_MSG_RESULT($cf_cv_unsigned_literals)
7514 ])dnl
7515 dnl ---------------------------------------------------------------------------
7516 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
7517 dnl --------
7518 dnl Make an uppercase version of a variable
7519 dnl $1=uppercase($2)
7520 AC_DEFUN([CF_UPPER],
7521 [
7522 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
7523 ])dnl
7524 dnl ---------------------------------------------------------------------------
7525 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
7526 dnl -----------
7527 dnl Check for multibyte support, and if not found, utf8 compatibility library
7528 AC_DEFUN([CF_UTF8_LIB],
7529 [
7530 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
7531         cf_save_LIBS="$LIBS"
7532         AC_TRY_LINK([
7533 #include <stdlib.h>],[putwc(0,0);],
7534         [cf_cv_utf8_lib=yes],
7535         [CF_FIND_LINKAGE([
7536 #include <libutf8.h>],[putwc(0,0);],utf8,
7537                 [cf_cv_utf8_lib=add-on],
7538                 [cf_cv_utf8_lib=no])
7539 ])])
7540
7541 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
7542 # ncurses/ncursesw:
7543 if test "$cf_cv_utf8_lib" = "add-on" ; then
7544         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
7545         CF_ADD_INCDIR($cf_cv_header_path_utf8)
7546         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
7547         CF_ADD_LIBS($cf_cv_library_file_utf8)
7548 fi
7549 ])dnl
7550 dnl ---------------------------------------------------------------------------
7551 dnl CF_VA_COPY version: 6 updated: 2018/12/04 18:14:25
7552 dnl ----------
7553 dnl check for va_copy, part of stdarg.h starting with ISO C 1999.
7554 dnl Also, workaround for glibc's __va_copy, by checking for both.
7555 dnl Finally, try to accommodate pre-ISO C 1999 headers.
7556 AC_DEFUN([CF_VA_COPY],[
7557 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
7558 AC_TRY_LINK([
7559 #include <stdarg.h>
7560 ],[
7561         static va_list dst;
7562         static va_list src;
7563         va_copy(dst, src)],
7564         cf_cv_have_va_copy=yes,
7565         cf_cv_have_va_copy=no)])
7566
7567 if test "$cf_cv_have_va_copy" = yes;
7568 then
7569         AC_DEFINE(HAVE_VA_COPY,1,[Define to 1 if we have va_copy])
7570 else # !cf_cv_have_va_copy
7571
7572 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
7573 AC_TRY_LINK([
7574 #include <stdarg.h>
7575 ],[
7576         static va_list dst;
7577         static va_list src;
7578         __va_copy(dst, src)],
7579         cf_cv_have___va_copy=yes,
7580         cf_cv_have___va_copy=no)])
7581
7582 if test "$cf_cv_have___va_copy" = yes
7583 then
7584         AC_DEFINE(HAVE___VA_COPY,1,[Define to 1 if we have __va_copy])
7585 else # !cf_cv_have___va_copy
7586
7587 AC_CACHE_CHECK(for __builtin_va_copy, cf_cv_have___builtin_va_copy,[
7588 AC_TRY_LINK([
7589 #include <stdarg.h>
7590 ],[
7591         static va_list dst;
7592         static va_list src;
7593         __builtin_va_copy(dst, src)],
7594         cf_cv_have___builtin_va_copy=yes,
7595         cf_cv_have___builtin_va_copy=no)])
7596
7597 test "$cf_cv_have___builtin_va_copy" = yes &&
7598         AC_DEFINE(HAVE___BUILTIN_VA_COPY,1,[Define to 1 if we have __builtin_va_copy])
7599
7600 fi # cf_cv_have___va_copy
7601
7602 fi # cf_cv_have_va_copy
7603
7604 case "${cf_cv_have_va_copy}${cf_cv_have___va_copy}${cf_cv_have___builtin_va_copy}" in
7605 (*yes*)
7606         ;;
7607
7608 (*)
7609         AC_CACHE_CHECK(if we can simply copy va_list, cf_cv_pointer_va_list,[
7610 AC_TRY_LINK([
7611 #include <stdarg.h>
7612 ],[
7613         va_list dst;
7614         va_list src;
7615         dst = src],
7616         cf_cv_pointer_va_list=yes,
7617         cf_cv_pointer_va_list=no)])
7618
7619         if test "$cf_cv_pointer_va_list" = no
7620         then
7621                 AC_CACHE_CHECK(if we can copy va_list indirectly, cf_cv_array_va_list,[
7622 AC_TRY_LINK([
7623 #include <stdarg.h>
7624 ],[
7625         va_list dst;
7626         va_list src;
7627         *dst = *src],
7628                         cf_cv_array_va_list=yes,
7629                         cf_cv_array_va_list=no)])
7630                 test "$cf_cv_array_va_list" = yes && AC_DEFINE(ARRAY_VA_LIST,1,[Define to 1 if we can copy va_list indirectly])
7631         fi
7632         ;;
7633 esac
7634 ])
7635 dnl ---------------------------------------------------------------------------
7636 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
7637 dnl ----------
7638 dnl Use AC_VERBOSE w/o the warnings
7639 AC_DEFUN([CF_VERBOSE],
7640 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
7641 CF_MSG_LOG([$1])
7642 ])dnl
7643 dnl ---------------------------------------------------------------------------
7644 dnl CF_VERSION_INFO version: 7 updated: 2015/04/17 21:13:04
7645 dnl ---------------
7646 dnl Define several useful symbols derived from the VERSION file.  A separate
7647 dnl file is preferred to embedding the version numbers in various scripts.
7648 dnl (automake is a textbook-example of why the latter is a bad idea, but there
7649 dnl are others).
7650 dnl
7651 dnl The file contents are:
7652 dnl     libtool-version release-version patch-version
7653 dnl or
7654 dnl     release-version
7655 dnl where
7656 dnl     libtool-version (see ?) consists of 3 integers separated by '.'
7657 dnl     release-version consists of a major version and minor version
7658 dnl             separated by '.', optionally followed by a patch-version
7659 dnl             separated by '-'.  The minor version need not be an
7660 dnl             integer (but it is preferred).
7661 dnl     patch-version is an integer in the form yyyymmdd, so ifdef's and
7662 dnl             scripts can easily compare versions.
7663 dnl
7664 dnl If libtool is used, the first form is required, since CF_WITH_LIBTOOL
7665 dnl simply extracts the first field using 'cut -f1'.
7666 dnl
7667 dnl Optional parameters:
7668 dnl $1 = internal name for package
7669 dnl $2 = external name for package
7670 AC_DEFUN([CF_VERSION_INFO],
7671 [
7672 if test -f $srcdir/VERSION ; then
7673         AC_MSG_CHECKING(for package version)
7674
7675         # if there are not enough fields, cut returns the last one...
7676         cf_field1=`sed -e '2,$d' $srcdir/VERSION|cut -f1`
7677         cf_field2=`sed -e '2,$d' $srcdir/VERSION|cut -f2`
7678         cf_field3=`sed -e '2,$d' $srcdir/VERSION|cut -f3`
7679
7680         # this is how CF_BUNDLED_INTL uses $VERSION:
7681         VERSION="$cf_field1"
7682
7683         VERSION_MAJOR=`echo "$cf_field2" | sed -e 's/\..*//'`
7684         test -z "$VERSION_MAJOR" && AC_MSG_ERROR(missing major-version)
7685
7686         VERSION_MINOR=`echo "$cf_field2" | sed -e 's/^[[^.]]*\.//' -e 's/-.*//'`
7687         test -z "$VERSION_MINOR" && AC_MSG_ERROR(missing minor-version)
7688
7689         AC_MSG_RESULT(${VERSION_MAJOR}.${VERSION_MINOR})
7690
7691         AC_MSG_CHECKING(for package patch date)
7692         VERSION_PATCH=`echo "$cf_field3" | sed -e 's/^[[^-]]*-//'`
7693         case .$VERSION_PATCH in
7694         (.)
7695                 AC_MSG_ERROR(missing patch-date $VERSION_PATCH)
7696                 ;;
7697         (.[[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]])
7698                 ;;
7699         (*)
7700                 AC_MSG_ERROR(illegal patch-date $VERSION_PATCH)
7701                 ;;
7702         esac
7703         AC_MSG_RESULT($VERSION_PATCH)
7704 else
7705         AC_MSG_ERROR(did not find $srcdir/VERSION)
7706 fi
7707
7708 # show the actual data that we have for versions:
7709 CF_VERBOSE(ABI VERSION $VERSION)
7710 CF_VERBOSE(VERSION_MAJOR $VERSION_MAJOR)
7711 CF_VERBOSE(VERSION_MINOR $VERSION_MINOR)
7712 CF_VERBOSE(VERSION_PATCH $VERSION_PATCH)
7713
7714 AC_SUBST(VERSION)
7715 AC_SUBST(VERSION_MAJOR)
7716 AC_SUBST(VERSION_MINOR)
7717 AC_SUBST(VERSION_PATCH)
7718
7719 dnl if a package name is given, define its corresponding version info.  We
7720 dnl need the package name to ensure that the defined symbols are unique.
7721 ifelse($1,,,[
7722         cf_PACKAGE=$1
7723         PACKAGE=ifelse($2,,$1,$2)
7724         AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",[Define to the package-name])
7725         AC_SUBST(PACKAGE)
7726         CF_UPPER(cf_PACKAGE,$cf_PACKAGE)
7727         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_VERSION,"${VERSION_MAJOR}.${VERSION_MINOR}")
7728         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_PATCHDATE,${VERSION_PATCH})
7729 ])
7730 ])dnl
7731 dnl ---------------------------------------------------------------------------
7732 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
7733 dnl -------------
7734 dnl Check if type wide-character type $1 is declared, and if so, which header
7735 dnl file is needed.  The second parameter is used to set a shell variable when
7736 dnl the type is not found.  The first parameter sets a shell variable for the
7737 dnl opposite sense.
7738 AC_DEFUN([CF_WCHAR_TYPE],
7739 [
7740 # This is needed on Tru64 5.0 to declare $1
7741 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
7742 AC_TRY_COMPILE([
7743 #include <stdlib.h>
7744 #include <stdarg.h>
7745 #include <stdio.h>
7746 #ifdef HAVE_LIBUTF8_H
7747 #include <libutf8.h>
7748 #endif],
7749         [$1 state],
7750         [cf_cv_$1=no],
7751         [AC_TRY_COMPILE([
7752 #include <stdlib.h>
7753 #include <stdarg.h>
7754 #include <stdio.h>
7755 #include <wchar.h>
7756 #ifdef HAVE_LIBUTF8_H
7757 #include <libutf8.h>
7758 #endif],
7759         [$1 value],
7760         [cf_cv_$1=yes],
7761         [cf_cv_$1=unknown])])])
7762
7763 if test "$cf_cv_$1" = yes ; then
7764         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
7765         NEED_WCHAR_H=1
7766 fi
7767
7768 ifelse([$2],,,[
7769 # if we do not find $1 in either place, use substitution to provide a fallback.
7770 if test "$cf_cv_$1" = unknown ; then
7771         $2=1
7772 fi
7773 ])
7774 ifelse($3,,,[
7775 # if we find $1 in either place, use substitution to provide a fallback.
7776 if test "$cf_cv_$1" != unknown ; then
7777         $3=1
7778 fi
7779 ])
7780 ])dnl
7781 dnl ---------------------------------------------------------------------------
7782 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
7783 dnl ---------------
7784 dnl Check for compiler-support for weak symbols.
7785 dnl This works with "recent" gcc.
7786 AC_DEFUN([CF_WEAK_SYMBOLS],[
7787 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
7788
7789 AC_TRY_COMPILE([
7790 #include <stdio.h>],
7791 [
7792 #if defined(__GNUC__)
7793 #  if defined __USE_ISOC99
7794 #    define _cat_pragma(exp)    _Pragma(#exp)
7795 #    define _weak_pragma(exp)   _cat_pragma(weak name)
7796 #  else
7797 #    define _weak_pragma(exp)
7798 #  endif
7799 #  define _declare(name)        __extension__ extern __typeof__(name) name
7800 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
7801 #endif
7802
7803 weak_symbol(fopen);
7804 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
7805 ])
7806 ])dnl
7807 dnl ---------------------------------------------------------------------------
7808 dnl CF_WITH_ABI_VERSION version: 3 updated: 2015/06/06 16:10:11
7809 dnl -------------------
7810 dnl Allow library's ABI to be overridden.  Generally this happens when a
7811 dnl packager has incremented the ABI past that used in the original package,
7812 dnl and wishes to keep doing this.
7813 dnl
7814 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
7815 dnl symbol.
7816 AC_DEFUN([CF_WITH_ABI_VERSION],[
7817 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
7818 AC_ARG_WITH(abi-version,
7819 [  --with-abi-version=XXX  override derived ABI version],[
7820         if test "x$cf_cv_abi_version" != "x$withval"
7821         then
7822                 AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
7823                 case $cf_cv_rel_version in
7824                 (5.*)
7825                         cf_cv_rel_version=$withval.0
7826                         ;;
7827                 (6.*)
7828                         cf_cv_rel_version=$withval.9    # FIXME: should be 10 as of 6.0 release
7829                         ;;
7830                 esac
7831         fi
7832         cf_cv_abi_version=$withval])
7833         CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
7834 ifelse($1,,,[
7835 $1_ABI=$cf_cv_abi_version
7836 ])
7837 ])dnl
7838 dnl ---------------------------------------------------------------------------
7839 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
7840 dnl --------------------
7841 dnl Command-line option to specify the Ada95 compiler.
7842 AC_DEFUN([CF_WITH_ADA_COMPILER],[
7843 AC_MSG_CHECKING(for ada-compiler)
7844 AC_ARG_WITH(ada-compiler,
7845         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
7846         [cf_ada_compiler=$withval],
7847         [cf_ada_compiler=gnatmake])
7848 AC_SUBST(cf_ada_compiler)
7849 AC_MSG_RESULT($cf_ada_compiler)
7850 ])dnl
7851 dnl ---------------------------------------------------------------------------
7852 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
7853 dnl -------------------
7854 dnl Command-line option to specify where Ada includes will install.
7855 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
7856 AC_MSG_CHECKING(for ada-include)
7857 CF_WITH_PATH(ada-include,
7858    [  --with-ada-include=DIR  Ada includes are in DIR],
7859    ADA_INCLUDE,
7860    PREFIX/share/ada/adainclude,
7861    [$]prefix/share/ada/adainclude)
7862 AC_SUBST(ADA_INCLUDE)
7863 AC_MSG_RESULT($ADA_INCLUDE)
7864 ])dnl
7865 dnl ---------------------------------------------------------------------------
7866 dnl CF_WITH_ADA_LIBNAME version: 1 updated: 2019/09/07 18:59:41
7867 dnl -------------------
7868 dnl CF_WITH_ADA_LIBNAME
7869 dnl -------------------
7870 dnl Command-line option to specify how to name the resulting Ada library.
7871 dnl $1 = default value
7872 AC_DEFUN([CF_WITH_ADA_LIBNAME],[
7873 AC_MSG_CHECKING(for ada-libname)
7874 AC_ARG_WITH(ada-libname,
7875    [  --with-ada-libname=XXX  override default Ada library-name],
7876    ADA_LIBNAME=[$]withval,
7877    ADA_LIBNAME=$1)
7878 case "x$ADA_LIBNAME" in
7879 (x|xyes|xno)
7880         ADA_LIBNAME=$1
7881         ;;
7882 esac
7883 AC_SUBST(ADA_LIBNAME)
7884 AC_MSG_RESULT($ADA_LIBNAME)
7885 ])dnl
7886 dnl ---------------------------------------------------------------------------
7887 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
7888 dnl -------------------
7889 dnl Command-line option to specify where Ada objects will install.
7890 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
7891 AC_MSG_CHECKING(for ada-objects)
7892 CF_WITH_PATH(ada-objects,
7893    [  --with-ada-objects=DIR  Ada objects are in DIR],
7894    ADA_OBJECTS,
7895    PREFIX/lib/ada/adalib,
7896    [$]prefix/lib/ada/adalib)
7897 AC_SUBST(ADA_OBJECTS)
7898 AC_MSG_RESULT($ADA_OBJECTS)
7899 ])dnl
7900 dnl ---------------------------------------------------------------------------
7901 dnl CF_WITH_ADA_SHAREDLIB version: 5 updated: 2018/07/21 19:10:35
7902 dnl ---------------------
7903 dnl Command-line option to specify if an Ada95 shared-library should be built,
7904 dnl and optionally what its soname should be.
7905 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
7906 AC_REQUIRE([CF_GNAT_PROJECTS])
7907 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
7908 AC_ARG_WITH(ada-sharedlib,
7909         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
7910         [with_ada_sharedlib=$withval],
7911         [with_ada_sharedlib=no])
7912 AC_MSG_RESULT($with_ada_sharedlib)
7913
7914 if test "x$with_ada_sharedlib" != xno
7915 then
7916         if test "x$cf_gnat_projects" != xyes
7917         then
7918                 AC_MSG_WARN(disabling shared-library since GNAT projects are not supported)
7919                 with_ada_sharedlib=no
7920         fi
7921 fi
7922
7923 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
7924 MAKE_ADA_SHAREDLIB="#"
7925
7926 if test "x$with_ada_sharedlib" != xno
7927 then
7928         MAKE_ADA_SHAREDLIB=
7929         if test "x$with_ada_sharedlib" != xyes
7930         then
7931                 ADA_SHAREDLIB="$with_ada_sharedlib"
7932         fi
7933 fi
7934
7935 AC_SUBST(ADA_SHAREDLIB)
7936 AC_SUBST(MAKE_ADA_SHAREDLIB)
7937 ])dnl
7938 dnl ---------------------------------------------------------------------------
7939 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
7940 dnl ----------------
7941 dnl Configure-option for dbmalloc.  The optional parameter is used to override
7942 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
7943 AC_DEFUN([CF_WITH_DBMALLOC],[
7944 CF_NO_LEAKS_OPTION(dbmalloc,
7945         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
7946         [USE_DBMALLOC])
7947
7948 if test "$with_dbmalloc" = yes ; then
7949         AC_CHECK_HEADER(dbmalloc.h,
7950                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
7951 fi
7952 ])dnl
7953 dnl ---------------------------------------------------------------------------
7954 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
7955 dnl ---------------
7956 dnl Configure-option for dmalloc.  The optional parameter is used to override
7957 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
7958 AC_DEFUN([CF_WITH_DMALLOC],[
7959 CF_NO_LEAKS_OPTION(dmalloc,
7960         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
7961         [USE_DMALLOC])
7962
7963 if test "$with_dmalloc" = yes ; then
7964         AC_CHECK_HEADER(dmalloc.h,
7965                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
7966 fi
7967 ])dnl
7968 dnl ---------------------------------------------------------------------------
7969 dnl CF_WITH_EXPORT_SYMS version: 3 updated: 2014/12/20 19:16:08
7970 dnl -------------------
7971 dnl Use this with libtool to specify the list of symbols that may be exported.
7972 dnl The input file contains one symbol per line; comments work with "#".
7973 dnl
7974 dnl $1 = basename of the ".sym" file (default $PACKAGE)
7975 AC_DEFUN([CF_WITH_EXPORT_SYMS],
7976 [
7977 AC_MSG_CHECKING(if exported-symbols file should be used)
7978 AC_ARG_WITH(export-syms,
7979         [  --with-export-syms=XXX  limit exported symbols using libtool],
7980         [with_export_syms=$withval],
7981         [with_export_syms=no])
7982 if test "x$with_export_syms" = xyes
7983 then
7984         with_export_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).sym'
7985         AC_SUBST(PACKAGE)
7986 fi
7987 AC_MSG_RESULT($with_export_syms)
7988 if test "x$with_export_syms" != xno
7989 then
7990         EXPORT_SYMS="-export-symbols $with_export_syms"
7991         AC_SUBST(EXPORT_SYMS)
7992 fi
7993 ])dnl
7994 dnl ---------------------------------------------------------------------------
7995 dnl CF_WITH_GPM version: 10 updated: 2017/04/29 18:32:18
7996 dnl -----------
7997 dnl
7998 dnl The option parameter (if neither yes/no) is assumed to be the name of
7999 dnl the gpm library, e.g., for dynamic loading.
8000 AC_DEFUN([CF_WITH_GPM],
8001 [
8002 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
8003 AC_ARG_WITH(gpm,
8004         [  --with-gpm              use Alessandro Rubini's GPM library],
8005         [with_gpm=$withval],
8006         [with_gpm=maybe])
8007 AC_MSG_RESULT($with_gpm)
8008
8009 if test "$with_gpm" != no ; then
8010         AC_CHECK_HEADER(gpm.h,[
8011                 AC_DEFINE(HAVE_GPM_H,1,[Define to 1 if we have gpm.h header])
8012                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
8013                         CF_VERBOSE(assuming we really have GPM library)
8014                         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
8015                         with_gpm=yes
8016                 else
8017                         AC_CHECK_LIB(gpm,Gpm_Open,[with_gpm=yes],[
8018                                 if test "$with_gpm" = maybe; then
8019                                         AC_MSG_WARN(Cannot link with GPM library)
8020                                         with_gpm=no
8021                                 else
8022                                         AC_MSG_ERROR(Cannot link with GPM library)
8023                                 fi
8024                         ])
8025                 fi
8026         ],[
8027                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
8028                 with_gpm=no
8029         ])
8030 fi
8031 ])
8032 dnl ---------------------------------------------------------------------------
8033 dnl CF_WITH_LIBTOOL version: 35 updated: 2017/08/12 07:58:51
8034 dnl ---------------
8035 dnl Provide a configure option to incorporate libtool.  Define several useful
8036 dnl symbols for the makefile rules.
8037 dnl
8038 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
8039 dnl macros from libtool.m4 which is in the aclocal directory of automake.
8040 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
8041 dnl But that still does not work properly since the macro is expanded outside
8042 dnl the CF_WITH_LIBTOOL macro:
8043 dnl
8044 dnl     #!/bin/sh
8045 dnl     ACLOCAL=`aclocal --print-ac-dir`
8046 dnl     if test -z "$ACLOCAL" ; then
8047 dnl             echo cannot find aclocal directory
8048 dnl             exit 1
8049 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
8050 dnl             echo cannot find libtool.m4 file
8051 dnl             exit 1
8052 dnl     fi
8053 dnl
8054 dnl     LOCAL=aclocal.m4
8055 dnl     ORIG=aclocal.m4.orig
8056 dnl
8057 dnl     trap "mv $ORIG $LOCAL" 0 1 2 3 15
8058 dnl     rm -f $ORIG
8059 dnl     mv $LOCAL $ORIG
8060 dnl
8061 dnl     # sed the LIBTOOL= assignment to omit the current directory?
8062 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
8063 dnl     cat $ORIG >>$LOCAL
8064 dnl
8065 dnl     autoconf-257 $*
8066 dnl
8067 AC_DEFUN([CF_WITH_LIBTOOL],
8068 [
8069 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
8070 ifdef([AC_PROG_LIBTOOL],,[
8071 LIBTOOL=
8072 ])
8073 # common library maintenance symbols that are convenient for libtool scripts:
8074 LIB_CREATE='${AR} -cr'
8075 LIB_OBJECT='${OBJECTS}'
8076 LIB_SUFFIX=.a
8077 LIB_PREP="$RANLIB"
8078
8079 # symbols used to prop libtool up to enable it to determine what it should be
8080 # doing:
8081 LIB_CLEAN=
8082 LIB_COMPILE=
8083 LIB_LINK='${CC}'
8084 LIB_INSTALL=
8085 LIB_UNINSTALL=
8086
8087 AC_MSG_CHECKING(if you want to build libraries with libtool)
8088 AC_ARG_WITH(libtool,
8089         [  --with-libtool          generate libraries with libtool],
8090         [with_libtool=$withval],
8091         [with_libtool=no])
8092 AC_MSG_RESULT($with_libtool)
8093 if test "$with_libtool" != "no"; then
8094 ifdef([AC_PROG_LIBTOOL],[
8095         # missing_content_AC_PROG_LIBTOOL{{
8096         AC_PROG_LIBTOOL
8097         # missing_content_AC_PROG_LIBTOOL}}
8098 ],[
8099         if test "$with_libtool" != "yes" ; then
8100                 CF_PATH_SYNTAX(with_libtool)
8101                 LIBTOOL=$with_libtool
8102         else
8103                 AC_CHECK_TOOLS(LIBTOOL,[libtool glibtool],none)
8104                 CF_LIBTOOL_VERSION
8105                 if test -z "$cf_cv_libtool_version" && test "$LIBTOOL" = libtool
8106                 then
8107                         CF_FORGET_TOOL(LIBTOOL)
8108                         AC_CHECK_TOOLS(LIBTOOL,[glibtool],none)
8109                         CF_LIBTOOL_VERSION
8110                 fi
8111         fi
8112         if test -z "$LIBTOOL" ; then
8113                 AC_MSG_ERROR(Cannot find libtool)
8114         fi
8115 ])dnl
8116         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${libdir} ${LIBTOOL_VERSION} `cut -f1 ${top_srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
8117         LIB_OBJECT='${OBJECTS:.o=.lo}'
8118         LIB_SUFFIX=.la
8119         LIB_CLEAN='${LIBTOOL} --mode=clean'
8120         LIB_COMPILE='${LIBTOOL} --mode=compile'
8121         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
8122         LIB_INSTALL='${LIBTOOL} --mode=install'
8123         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
8124         LIB_PREP=:
8125
8126         CF_CHECK_LIBTOOL_VERSION
8127
8128         # special hack to add -no-undefined (which libtool should do for itself)
8129         LT_UNDEF=
8130         case "$cf_cv_system_name" in
8131         (cygwin*|msys*|mingw32*|os2*|uwin*|aix[[4-7]])
8132                 LT_UNDEF=-no-undefined
8133                 ;;
8134         esac
8135         AC_SUBST([LT_UNDEF])
8136
8137         # special hack to add --tag option for C++ compiler
8138         case $cf_cv_libtool_version in
8139         (1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*)
8140                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
8141                 LIBTOOL="$LIBTOOL --tag=CC"
8142                 ;;
8143         (*)
8144                 LIBTOOL_CXX="$LIBTOOL"
8145                 ;;
8146         esac
8147 else
8148         LIBTOOL=""
8149         LIBTOOL_CXX=""
8150 fi
8151
8152 test -z "$LIBTOOL" && ECHO_LT=
8153
8154 AC_SUBST(LIBTOOL)
8155 AC_SUBST(LIBTOOL_CXX)
8156 AC_SUBST(LIBTOOL_OPTS)
8157
8158 AC_SUBST(LIB_CREATE)
8159 AC_SUBST(LIB_OBJECT)
8160 AC_SUBST(LIB_SUFFIX)
8161 AC_SUBST(LIB_PREP)
8162
8163 AC_SUBST(LIB_CLEAN)
8164 AC_SUBST(LIB_COMPILE)
8165 AC_SUBST(LIB_LINK)
8166 AC_SUBST(LIB_INSTALL)
8167 AC_SUBST(LIB_UNINSTALL)
8168
8169 ])dnl
8170 dnl ---------------------------------------------------------------------------
8171 dnl CF_WITH_LIBTOOL_OPTS version: 4 updated: 2015/04/17 21:13:04
8172 dnl --------------------
8173 dnl Allow user to pass additional libtool options into the library creation
8174 dnl and link steps.  The main use for this is to do something like
8175 dnl     ./configure --with-libtool-opts=-static
8176 dnl to get the same behavior as automake-flavored
8177 dnl     ./configure --enable-static
8178 AC_DEFUN([CF_WITH_LIBTOOL_OPTS],[
8179 AC_MSG_CHECKING(for additional libtool options)
8180 AC_ARG_WITH(libtool-opts,
8181         [  --with-libtool-opts=XXX specify additional libtool options],
8182         [with_libtool_opts=$withval],
8183         [with_libtool_opts=no])
8184 AC_MSG_RESULT($with_libtool_opts)
8185
8186 case .$with_libtool_opts in
8187 (.yes|.no|.)
8188         ;;
8189 (*)
8190         LIBTOOL_OPTS="$LIBTOOL_OPTS $with_libtool_opts"
8191         ;;
8192 esac
8193
8194 AC_SUBST(LIBTOOL_OPTS)
8195 ])dnl
8196 dnl ---------------------------------------------------------------------------
8197 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
8198 dnl ------------------
8199 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
8200 dnl "lib" prefix, e.g., because it used the dll naming convention.
8201 dnl
8202 dnl $1 = variable to set
8203 AC_DEFUN([CF_WITH_LIB_PREFIX],
8204 [
8205 AC_MSG_CHECKING(if you want to have a library-prefix)
8206 AC_ARG_WITH(lib-prefix,
8207         [  --with-lib-prefix       override library-prefix],
8208         [with_lib_prefix=$withval],
8209         [with_lib_prefix=auto])
8210 AC_MSG_RESULT($with_lib_prefix)
8211
8212 if test $with_lib_prefix = auto
8213 then
8214         CF_LIB_PREFIX($1)
8215 elif test $with_lib_prefix = no
8216 then
8217         LIB_PREFIX=
8218 else
8219         LIB_PREFIX=$with_lib_prefix
8220 fi
8221 ])dnl
8222 dnl ---------------------------------------------------------------------------
8223 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
8224 dnl ------------
8225 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
8226 dnl defaulting to yes/no.
8227 dnl
8228 dnl $1 = option name
8229 dnl $2 = help-text
8230 dnl $3 = environment variable to set
8231 dnl $4 = default value, shown in the help-message, must be a constant
8232 dnl $5 = default value, if it's an expression & cannot be in the help-message
8233 dnl
8234 AC_DEFUN([CF_WITH_PATH],
8235 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
8236 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
8237 if ifelse([$5],,true,[test -n "$5"]) ; then
8238 CF_PATH_SYNTAX(withval)
8239 fi
8240 eval $3="$withval"
8241 AC_SUBST($3)dnl
8242 ])dnl
8243 dnl ---------------------------------------------------------------------------
8244 dnl CF_WITH_PATHLIST version: 10 updated: 2015/04/17 21:13:04
8245 dnl ----------------
8246 dnl Process an option specifying a list of colon-separated paths.
8247 dnl
8248 dnl $1 = option name
8249 dnl $2 = help-text
8250 dnl $3 = environment variable to set
8251 dnl $4 = default value, shown in the help-message, must be a constant
8252 dnl $5 = default value, if it's an expression & cannot be in the help-message
8253 dnl $6 = flag to tell if we want to define or substitute
8254 dnl
8255 AC_DEFUN([CF_WITH_PATHLIST],[
8256 AC_REQUIRE([CF_PATHSEP])
8257 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
8258 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
8259
8260 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
8261 cf_dst_path=
8262 for cf_src_path in $withval
8263 do
8264   CF_PATH_SYNTAX(cf_src_path)
8265   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}$PATH_SEPARATOR"
8266   cf_dst_path="${cf_dst_path}${cf_src_path}"
8267 done
8268 IFS="$ac_save_ifs"
8269
8270 ifelse($6,define,[
8271 # Strip single quotes from the value, e.g., when it was supplied as a literal
8272 # for $4 or $5.
8273 case $cf_dst_path in
8274 (\'*)
8275   cf_dst_path=`echo $cf_dst_path |sed -e s/\'// -e s/\'\$//`
8276   ;;
8277 esac
8278 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
8279 ])
8280
8281 # This may use the prefix/exec_prefix symbols which will only yield "NONE"
8282 # so we have to check/work around.  We do prefer the result of "eval"...
8283 eval cf_dst_eval="$cf_dst_path"
8284 case "x$cf_dst_eval" in
8285 (xNONE*)
8286         $3=$cf_dst_path
8287         ;;
8288 (*)
8289         $3="$cf_dst_eval"
8290         ;;
8291 esac
8292 AC_SUBST($3)dnl
8293
8294 ])dnl
8295 dnl ---------------------------------------------------------------------------
8296 dnl CF_WITH_PATH_PROG version: 1 updated: 2019/06/30 19:44:43
8297 dnl -----------------
8298 dnl Check for a given program, like CF_PATH_PROG, but allow override using a
8299 dnl "--with-xxx" option.
8300 dnl
8301 dnl Parameters:
8302 dnl             $1 = environment variable to set/update
8303 dnl             $2 = program name
8304 dnl             $3 = help-text
8305 dnl             $4 = $PATH
8306 AC_DEFUN([CF_WITH_PATH_PROG],[
8307 AC_ARG_WITH($2-path,
8308         [  --with-$2-path=XXX     specify path of $2 ifelse($3,,,$3)],
8309         [AC_MSG_CHECKING(for $2 program ifelse($3,,,$3))
8310                 $1=$withval
8311                 AC_MSG_RESULT([$]$1)
8312                 CF_PATH_SYNTAX($1)
8313         ],
8314         [CF_PATH_PROG($1,$2,,ifelse($4,,,$4))
8315                 if test -z "[$]$1"
8316                 then
8317                         AC_MSG_WARN(no $2 program found ifelse($3,,,$3))
8318                 fi
8319         ])
8320 ])
8321 dnl ---------------------------------------------------------------------------
8322 dnl CF_WITH_PCRE2 version: 2 updated: 2018/07/14 16:47:56
8323 dnl -------------
8324 dnl Add PCRE2 (Perl-compatible regular expressions v2) to the build if it is
8325 dnl available and the user requests it.  Assume the application will otherwise
8326 dnl use the POSIX interface.
8327 dnl
8328 dnl TODO allow $withval to specify package location
8329 AC_DEFUN([CF_WITH_PCRE2],
8330 [
8331 AC_REQUIRE([CF_PKG_CONFIG])
8332
8333 AC_MSG_CHECKING(if you want to use PCRE2 for regular-expressions)
8334 AC_ARG_WITH(pcre2,
8335         [  --with-pcre2            use PCRE2 for regular-expressions])
8336 test -z "$with_pcre2" && with_pcre2=no
8337 AC_MSG_RESULT($with_pcre2)
8338
8339 if test "x$with_pcre2" != xno ; then
8340         CF_TRY_PKG_CONFIG(libpcre2,,[
8341         CF_TRY_PKG_CONFIG(libpcre,,[
8342                         AC_MSG_ERROR(Cannot find PCRE2 library)])])
8343
8344         AC_DEFINE(HAVE_LIB_PCRE2,1,[Define to 1 if we can/should compile with the PCRE2 library])
8345
8346         # if pkgconfig gave no results, look for the libraries directly
8347         case $LIBS in
8348         (*pcre2-posix*|*pcreposix*)
8349                 ;;
8350         (*)
8351                 AC_CHECK_LIB(pcre2-posix,regcomp,[
8352                         CF_ADD_LIB(pcre2-posix)],
8353                         [AC_CHECK_LIB(pcreposix,regcomp,[
8354                          CF_ADD_LIB(pcreposix)
8355                         ],[AC_MSG_ERROR(Cannot find PCRE2 POSIX library)])])
8356                 ;;
8357         esac
8358
8359         # either way, check for the library header files
8360         AC_CHECK_HEADERS(pcre2-posix.h pcreposix.h)
8361 fi
8362 ])dnl
8363 dnl ---------------------------------------------------------------------------
8364 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 10 updated: 2015/08/22 17:10:56
8365 dnl -------------------------
8366 dnl Allow the choice of the pkg-config library directory to be overridden.
8367 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
8368
8369 case $PKG_CONFIG in
8370 (no|none|yes)
8371         AC_MSG_CHECKING(for pkg-config library directory)
8372         ;;
8373 (*)
8374         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
8375         ;;
8376 esac
8377
8378 PKG_CONFIG_LIBDIR=no
8379 AC_ARG_WITH(pkg-config-libdir,
8380         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
8381         [PKG_CONFIG_LIBDIR=$withval],
8382         [test "x$PKG_CONFIG" != xnone && PKG_CONFIG_LIBDIR=yes])
8383
8384 case x$PKG_CONFIG_LIBDIR in
8385 (x/*)
8386         ;;
8387 (xyes)
8388         # Look for the library directory using the same prefix as the executable
8389         if test "x$PKG_CONFIG" = xnone
8390         then
8391                 cf_path=$prefix
8392         else
8393                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
8394         fi
8395
8396         # If you don't like using the default architecture, you have to specify the
8397         # intended library directory and corresponding compiler/linker options.
8398         #
8399         # This case allows for Debian's 2014-flavor of multiarch, along with the
8400         # most common variations before that point.  Some other variants spell the
8401         # directory differently, e.g., "pkg-config", and put it in unusual places.
8402         # pkg-config has always been poorly standardized, which is ironic...
8403         case x`(arch) 2>/dev/null` in
8404         (*64)
8405                 cf_search_path="\
8406                         $cf_path/lib/*64-linux-gnu \
8407                         $cf_path/share \
8408                         $cf_path/lib64 \
8409                         $cf_path/lib32 \
8410                         $cf_path/lib"
8411                 ;;
8412         (*)
8413                 cf_search_path="\
8414                         $cf_path/lib/*-linux-gnu \
8415                         $cf_path/share \
8416                         $cf_path/lib32 \
8417                         $cf_path/lib \
8418                         $cf_path/libdata"
8419                 ;;
8420         esac
8421
8422         CF_VERBOSE(list...)
8423         for cf_config in $cf_search_path
8424         do
8425                 CF_VERBOSE(checking $cf_config/pkgconfig)
8426                 if test -d $cf_config/pkgconfig
8427                 then
8428                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
8429                         AC_MSG_CHECKING(done)
8430                         break
8431                 fi
8432         done
8433         ;;
8434 (*)
8435         ;;
8436 esac
8437
8438 if test "x$PKG_CONFIG_LIBDIR" != xno ; then
8439         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
8440 fi
8441
8442 AC_SUBST(PKG_CONFIG_LIBDIR)
8443 ])dnl
8444 dnl ---------------------------------------------------------------------------
8445 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
8446 dnl ---------------
8447 dnl Check for POSIX thread library.
8448 AC_DEFUN([CF_WITH_PTHREAD],
8449 [
8450 AC_MSG_CHECKING(if you want to link with the pthread library)
8451 AC_ARG_WITH(pthread,
8452         [  --with-pthread          use POSIX thread library],
8453         [with_pthread=$withval],
8454         [with_pthread=no])
8455 AC_MSG_RESULT($with_pthread)
8456
8457 if test "$with_pthread" != no ; then
8458         AC_CHECK_HEADER(pthread.h,[
8459         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
8460
8461         for cf_lib_pthread in pthread c_r
8462         do
8463             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
8464             cf_save_LIBS="$LIBS"
8465             CF_ADD_LIB($cf_lib_pthread)
8466             AC_TRY_LINK([
8467 #include <pthread.h>
8468 ],[
8469                 int rc = pthread_create(0,0,0,0);
8470                 int r2 = pthread_mutexattr_settype(0, 0);
8471 ],[with_pthread=yes],[with_pthread=no])
8472             LIBS="$cf_save_LIBS"
8473             AC_MSG_RESULT($with_pthread)
8474             test "$with_pthread" = yes && break
8475         done
8476
8477         if test "$with_pthread" = yes ; then
8478             CF_ADD_LIB($cf_lib_pthread)
8479             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
8480         else
8481             AC_MSG_ERROR(Cannot link with pthread library)
8482         fi
8483         ])
8484 fi
8485 ])
8486 dnl ---------------------------------------------------------------------------
8487 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
8488 dnl -------------------
8489 dnl Allow library's release-version to be overridden.  Generally this happens when a
8490 dnl packager has incremented the release-version past that used in the original package,
8491 dnl and wishes to keep doing this.
8492 dnl
8493 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
8494 dnl and {package}_MINOR symbols
8495 dnl symbol.
8496 AC_DEFUN([CF_WITH_REL_VERSION],[
8497 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
8498 AC_ARG_WITH(rel-version,
8499 [  --with-rel-version=XXX  override derived release version],
8500 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
8501  cf_cv_rel_version=$withval])
8502 ifelse($1,,[
8503  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
8504 ],[
8505  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
8506  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
8507  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
8508  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
8509 ])
8510 ])dnl
8511 dnl ---------------------------------------------------------------------------
8512 dnl CF_WITH_SYSMOUSE version: 3 updated: 2012/10/06 17:56:13
8513 dnl ----------------
8514 dnl If we can compile with sysmouse, make it available unless it is not wanted.
8515 AC_DEFUN([CF_WITH_SYSMOUSE],[
8516 # not everyone has "test -c"
8517 if test -c /dev/sysmouse 2>/dev/null ; then
8518 AC_MSG_CHECKING(if you want to use sysmouse)
8519 AC_ARG_WITH(sysmouse,
8520         [  --with-sysmouse         use sysmouse (FreeBSD console)],
8521         [cf_with_sysmouse=$withval],
8522         [cf_with_sysmouse=maybe])
8523         if test "$cf_with_sysmouse" != no ; then
8524         AC_TRY_COMPILE([
8525 #include <osreldate.h>
8526 #if (__FreeBSD_version >= 400017)
8527 #include <sys/consio.h>
8528 #include <sys/fbio.h>
8529 #else
8530 #include <machine/console.h>
8531 #endif
8532 ],[
8533         struct mouse_info the_mouse;
8534         ioctl(0, CONS_MOUSECTL, &the_mouse);
8535 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
8536         fi
8537 AC_MSG_RESULT($cf_with_sysmouse)
8538 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE,1,[Define to 1 if we can/should use the sysmouse interface])
8539 fi
8540 ])dnl
8541 dnl ---------------------------------------------------------------------------
8542 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
8543 dnl ---------------
8544 dnl For testing, override the derived host system-type which is used to decide
8545 dnl things such as the linker commands used to build shared libraries.  This is
8546 dnl normally chosen automatically based on the type of system which you are
8547 dnl building on.  We use it for testing the configure script.
8548 dnl
8549 dnl This is different from the --host option: it is used only for testing parts
8550 dnl of the configure script which would not be reachable with --host since that
8551 dnl relies on the build environment being real, rather than mocked up.
8552 AC_DEFUN([CF_WITH_SYSTYPE],[
8553 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
8554 AC_ARG_WITH(system-type,
8555         [  --with-system-type=XXX  test: override derived host system-type],
8556 [AC_MSG_WARN(overriding system type to $withval)
8557         cf_cv_system_name=$withval
8558         host_os=$withval
8559 ])
8560 ])dnl
8561 dnl ---------------------------------------------------------------------------
8562 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
8563 dnl ----------------
8564 AC_DEFUN([CF_WITH_VALGRIND],[
8565 CF_NO_LEAKS_OPTION(valgrind,
8566         [  --with-valgrind         test: use valgrind],
8567         [USE_VALGRIND])
8568 ])dnl
8569 dnl ---------------------------------------------------------------------------
8570 dnl CF_WITH_VERSIONED_SYMS version: 8 updated: 2018/10/20 20:24:34
8571 dnl ----------------------
8572 dnl Use this when building shared library with ELF, to markup symbols with the
8573 dnl version identifier from the given input file.  Generally that identifier is
8574 dnl the same as the SONAME at which the symbol was first introduced.
8575 dnl
8576 dnl $1 = basename of the ".map" file (default $PACKAGE)
8577 AC_DEFUN([CF_WITH_VERSIONED_SYMS],
8578 [
8579 AC_MSG_CHECKING(if versioned-symbols file should be used)
8580 AC_ARG_WITH(versioned-syms,
8581         [  --with-versioned-syms=X markup versioned symbols using ld],
8582         [with_versioned_syms=$withval],
8583         [with_versioned_syms=no])
8584 case "x$with_versioned_syms" in
8585 (xyes)
8586         with_versioned_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).map'
8587         AC_SUBST(PACKAGE)
8588         ;;
8589 (xno)
8590         ;;
8591 (x/*)
8592         test -f "$with_versioned_syms" || AC_MSG_ERROR(expected a filename: $with_versioned_syms)
8593         ;;
8594 (*)
8595         test -f "$with_versioned_syms" || AC_MSG_ERROR(expected a filename: $with_versioned_syms)
8596         with_versioned_syms=`pwd`/"$with_versioned_syms"
8597         ;;
8598 esac
8599 AC_MSG_RESULT($with_versioned_syms)
8600
8601 RESULTING_SYMS=
8602 VERSIONED_SYMS=
8603 WILDCARD_SYMS=
8604
8605 if test "x$with_versioned_syms" != xno
8606 then
8607         RESULTING_SYMS=$with_versioned_syms
8608         case "x$MK_SHARED_LIB" in
8609         (*-Wl,*)
8610                 VERSIONED_SYMS="-Wl,--version-script,\${RESULTING_SYMS}"
8611                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-Wl,%\\[$]{VERSIONED_SYMS} -Wl,%"`
8612                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
8613                 ;;
8614         (*-dy\ *)
8615                 VERSIONED_SYMS="-Wl,-M,\${RESULTING_SYMS}"
8616                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-dy%\\[$]{VERSIONED_SYMS} -dy%"`
8617                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
8618                 ;;
8619         (*)
8620                 AC_MSG_WARN(this system does not support versioned-symbols)
8621                 ;;
8622         esac
8623
8624         # Linux ld can selectively override scope, e.g., of symbols beginning with
8625         # "_" by first declaring some as global, and then using a wildcard to
8626         # declare the others as local.  Some other loaders cannot do this.  Check
8627         # by constructing a (very) simple shared library and inspecting its
8628         # symbols.
8629         if test "x$VERSIONED_SYMS" != "x"
8630         then
8631                 AC_MSG_CHECKING(if wildcards can be used to selectively omit symbols)
8632                 WILDCARD_SYMS=no
8633
8634                 # make sources
8635                 rm -f conftest.*
8636
8637                 cat >conftest.ver <<EOF
8638 module_1.0 {
8639 global:
8640         globalf1;
8641 local:
8642         localf1;
8643 };
8644 module_2.0 {
8645 global:
8646         globalf2;
8647 local:
8648         localf2;
8649         _*;
8650 } module_1.0;
8651 submodule_1.0 {
8652 global:
8653         subglobalf1;
8654         _ismissing;
8655 local:
8656         sublocalf1;
8657 };
8658 submodule_2.0 {
8659 global:
8660         subglobalf2;
8661 local:
8662         sublocalf2;
8663         _*;
8664 } submodule_1.0;
8665 EOF
8666                 cat >conftest.$ac_ext <<EOF
8667 #line __oline__ "configure"
8668 int     _ismissing(void) { return 1; }
8669 int     _localf1(void) { return 1; }
8670 int     _localf2(void) { return 2; }
8671 int     globalf1(void) { return 1; }
8672 int     globalf2(void) { return 2; }
8673 int     _sublocalf1(void) { return 1; }
8674 int     _sublocalf2(void) { return 2; }
8675 int     subglobalf1(void) { return 1; }
8676 int     subglobalf2(void) { return 2; }
8677 EOF
8678                 cat >conftest.mk <<EOF
8679 CC=${CC}
8680 CFLAGS=${CFLAGS}
8681 CPPFLAGS=${CPPFLAGS}
8682 LDFLAGS=${LDFLAGS}
8683 LIBS=${LIBS}
8684 VERSIONED_SYMS=${VERSIONED_SYMS}
8685 RESULTING_SYMS=conftest.ver
8686 MK_SHARED_LIB=${MK_SHARED_LIB}
8687 conftest.so: conftest.$ac_cv_objext
8688                 \$(MK_SHARED_LIB) conftest.$ac_cv_objext
8689 EOF
8690
8691                 # compile source, make library
8692                 if make -f conftest.mk 2>&AC_FD_CC >/dev/null
8693                 then
8694                         # test for missing symbol in either Data or Text section
8695                         cf_missing=`nm -P conftest.so 2>&AC_FD_CC |fgrep _ismissing | egrep '[[         ]][[DT]][[      ]]'`
8696                         test -n "$cf_missing" && WILDCARD_SYMS=yes
8697                 fi
8698                 AC_MSG_RESULT($WILDCARD_SYMS)
8699                 rm -f conftest.*
8700         fi
8701 fi
8702 AC_SUBST(RESULTING_SYMS)
8703 AC_SUBST(VERSIONED_SYMS)
8704 AC_SUBST(WILDCARD_SYMS)
8705 ])dnl
8706 dnl ---------------------------------------------------------------------------
8707 dnl CF_WITH_X11_RGB version: 1 updated: 2017/11/25 17:32:16
8708 dnl ---------------
8709 dnl Handle configure option "--with-x11-rgb", setting these shell
8710 dnl variables:
8711 dnl
8712 dnl $RGB_PATH is the option value, used for finding the X11 rgb file.
8713 dnl $no_x11_rgb is a "#" (comment) if "--without-x11-rgb" is given.
8714 dnl
8715 dnl Most Linux's use this:
8716 dnl     /usr/share/X11/rgb.txt
8717 dnl Debian uses this:
8718 dnl     /etc/X11/rgb.txt
8719 dnl DragonFlyBSD ports uses this:
8720 dnl     /usr/pkg/lib/X11/rgb.txt
8721 dnl FreeBSD ports use these:
8722 dnl     /usr/local/lib/X11/rgb.txt
8723 dnl     /usr/local/share/X11/rgb.txt
8724 dnl Mandriva has these:
8725 dnl     /usr/lib/X11/rgb.txt
8726 dnl     /usr/lib64/X11/rgb.txt
8727 dnl NetBSD has these
8728 dnl     /usr/X11R7/lib/X11/rgb.txt
8729 dnl OpenSolaris uses
8730 dnl     32-bit:
8731 dnl     /usr/X11/etc/X11/rgb.txt
8732 dnl     /usr/X11/share/X11/rgb.txt
8733 dnl     /usr/X11/lib/X11/rgb.txt
8734 dnl OSX uses
8735 dnl             /opt/local/share/X11/rgb.txt (MacPorts)
8736 dnl             /opt/X11/share/X11/rgb.txt (non-ports)
8737 dnl     64-bit:
8738 dnl     /usr/X11/etc/X11/rgb.txt
8739 dnl     /usr/X11/share/X11/rgb.txt (perhaps)
8740 dnl     /usr/X11/lib/amd64/X11/rgb.txt
8741 dnl Solaris10 uses (in this order):
8742 dnl     /usr/openwin/lib/X11/rgb.txt
8743 dnl     /usr/X11/lib/X11/rgb.txt
8744 AC_DEFUN([CF_WITH_X11_RGB],[
8745 AC_MSG_CHECKING(for X11 rgb file)
8746 AC_ARG_WITH(x11-rgb,
8747         [  --with-x11-rgb=FILE   file containing X11 rgb information (EPREFIX/lib/X11/rgb.txt)],
8748         [RGB_PATH=$withval],
8749         [RGB_PATH=auto])
8750
8751 if test "x[$]RGB_PATH" = xauto
8752 then
8753         RGB_PATH='${exec_prefix}/lib/X11/rgb.txt'
8754         for cf_path in \
8755                 /opt/local/share/X11/rgb.txt \
8756                 /opt/X11/share/X11/rgb.txt \
8757                 /usr/share/X11/rgb.txt \
8758                 /usr/X11/share/X11/rgb.txt \
8759                 /usr/X11/lib/X11/rgb.txt \
8760                 /usr/lib/X11/rgb.txt \
8761                 /etc/X11/rgb.txt \
8762                 /usr/pkg/lib/X11/rgb.txt \
8763                 /usr/X11R7/lib/X11/rgb.txt \
8764                 /usr/X11R6/lib/X11/rgb.txt \
8765                 /usr/X11R5/lib/X11/rgb.txt \
8766                 /usr/X11R4/lib/X11/rgb.txt \
8767                 /usr/local/lib/X11/rgb.txt \
8768                 /usr/local/share/X11/rgb.txt \
8769                 /usr/lib64/X11/rgb.txt
8770         do
8771                 if test -f "$cf_path" ; then
8772                         RGB_PATH="$cf_path"
8773                         break
8774                 fi
8775         done
8776 else
8777         cf_path=$RGB_PATH
8778         CF_PATH_SYNTAX(cf_path)
8779 fi
8780
8781 AC_MSG_RESULT($RGB_PATH)
8782 AC_SUBST(RGB_PATH)
8783 AC_DEFINE_UNQUOTED(RGB_PATH,"$cf_path")
8784
8785 no_x11_rgb=
8786 if test "$RGB_PATH" = no
8787 then
8788         no_x11_rgb="#"
8789 fi
8790 AC_SUBST(no_x11_rgb)
8791 ])dnl
8792 dnl ---------------------------------------------------------------------------
8793 dnl CF_XOPEN_SOURCE version: 55 updated: 2018/12/31 20:46:17
8794 dnl ---------------
8795 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
8796 dnl or adapt to the vendor's definitions to get equivalent functionality,
8797 dnl without losing the common non-POSIX features.
8798 dnl
8799 dnl Parameters:
8800 dnl     $1 is the nominal value for _XOPEN_SOURCE
8801 dnl     $2 is the nominal value for _POSIX_C_SOURCE
8802 AC_DEFUN([CF_XOPEN_SOURCE],[
8803 AC_REQUIRE([AC_CANONICAL_HOST])
8804 AC_REQUIRE([CF_POSIX_VISIBLE])
8805
8806 if test "$cf_cv_posix_visible" = no; then
8807
8808 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
8809 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
8810 cf_xopen_source=
8811
8812 case $host_os in
8813 (aix[[4-7]]*)
8814         cf_xopen_source="-D_ALL_SOURCE"
8815         ;;
8816 (msys)
8817         cf_XOPEN_SOURCE=600
8818         ;;
8819 (darwin[[0-8]].*)
8820         cf_xopen_source="-D_APPLE_C_SOURCE"
8821         ;;
8822 (darwin*)
8823         cf_xopen_source="-D_DARWIN_C_SOURCE"
8824         cf_XOPEN_SOURCE=
8825         ;;
8826 (freebsd*|dragonfly*|midnightbsd*)
8827         # 5.x headers associate
8828         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
8829         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
8830         cf_POSIX_C_SOURCE=200112L
8831         cf_XOPEN_SOURCE=600
8832         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
8833         ;;
8834 (hpux11*)
8835         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
8836         ;;
8837 (hpux*)
8838         cf_xopen_source="-D_HPUX_SOURCE"
8839         ;;
8840 (irix[[56]].*)
8841         cf_xopen_source="-D_SGI_SOURCE"
8842         cf_XOPEN_SOURCE=
8843         ;;
8844 (linux*|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin)
8845         CF_GNU_SOURCE($cf_XOPEN_SOURCE)
8846         ;;
8847 (minix*)
8848         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
8849         ;;
8850 (mirbsd*)
8851         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
8852         cf_XOPEN_SOURCE=
8853         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
8854         ;;
8855 (netbsd*)
8856         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
8857         ;;
8858 (openbsd[[4-9]]*)
8859         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
8860         cf_xopen_source="-D_BSD_SOURCE"
8861         cf_XOPEN_SOURCE=600
8862         ;;
8863 (openbsd*)
8864         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
8865         ;;
8866 (osf[[45]]*)
8867         cf_xopen_source="-D_OSF_SOURCE"
8868         ;;
8869 (nto-qnx*)
8870         cf_xopen_source="-D_QNX_SOURCE"
8871         ;;
8872 (sco*)
8873         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
8874         ;;
8875 (solaris2.*)
8876         cf_xopen_source="-D__EXTENSIONS__"
8877         cf_cv_xopen_source=broken
8878         ;;
8879 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
8880         cf_XOPEN_SOURCE=
8881         cf_POSIX_C_SOURCE=
8882         ;;
8883 (*)
8884         CF_TRY_XOPEN_SOURCE
8885         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
8886         ;;
8887 esac
8888
8889 if test -n "$cf_xopen_source" ; then
8890         CF_ADD_CFLAGS($cf_xopen_source,true)
8891 fi
8892
8893 dnl In anything but the default case, we may have system-specific setting
8894 dnl which is still not guaranteed to provide all of the entrypoints that
8895 dnl _XOPEN_SOURCE would yield.
8896 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
8897         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
8898         AC_TRY_COMPILE([#include <stdlib.h>],[
8899 #ifndef _XOPEN_SOURCE
8900 make an error
8901 #endif],
8902         [cf_XOPEN_SOURCE_set=yes],
8903         [cf_XOPEN_SOURCE_set=no])
8904         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
8905         if test $cf_XOPEN_SOURCE_set = yes
8906         then
8907                 AC_TRY_COMPILE([#include <stdlib.h>],[
8908 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
8909 make an error
8910 #endif],
8911                 [cf_XOPEN_SOURCE_set_ok=yes],
8912                 [cf_XOPEN_SOURCE_set_ok=no])
8913                 if test $cf_XOPEN_SOURCE_set_ok = no
8914                 then
8915                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
8916                 fi
8917         else
8918                 CF_TRY_XOPEN_SOURCE
8919         fi
8920 fi
8921 fi # cf_cv_posix_visible
8922 ])