aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2010,2011 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.563 2011/07/17 18:55:21 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 3 updated: 2002/10/27 23:21:42
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54     [AC_TRY_LINK([#include <langinfo.h>],
  55       [char* cs = nl_langinfo(CODESET);],
  56       am_cv_langinfo_codeset=yes,
  57       am_cv_langinfo_codeset=no)
  58     ])
  59   if test $am_cv_langinfo_codeset = yes; then
  60     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62   fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ACVERSION_CHECK version: 2 updated: 2011/05/08 11:22:03
  66 dnl ------------------
  67 dnl Conditionally generate script according to whether we're using a given autoconf.
  68 dnl
  69 dnl $1 = version to compare against
  70 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  71 dnl $3 = code to use if AC_ACVERSION is older than $1.
  72 define(CF_ACVERSION_CHECK,
  73 [
  74 ifdef([m4_version_compare],
  75 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  76 [CF_ACVERSION_COMPARE(
  77 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  78 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  79 dnl ---------------------------------------------------------------------------
  80 dnl CF_ACVERSION_COMPARE version: 2 updated: 2011/04/14 20:56:50
  81 dnl --------------------
  82 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  83 dnl                      MAJOR2, MINOR2, TERNARY2,
  84 dnl                      PRINTABLE2, not FOUND, FOUND)
  85 define(CF_ACVERSION_COMPARE,
  86 [ifelse(builtin([eval], [$2 < $5]), 1,
  87 [ifelse([$8], , ,[$8])],
  88 [ifelse([$9], , ,[$9])])])dnl
  89 dnl ---------------------------------------------------------------------------
  90 dnl CF_ADA_INCLUDE_DIRS version: 6 updated: 2010/02/26 19:52:07
  91 dnl -------------------
  92 dnl Construct the list of include-options for the C programs in the Ada95
  93 dnl binding.
  94 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  95 [
  96 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  97 if test "$srcdir" != "."; then
  98         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
  99 fi
 100 if test "$GCC" != yes; then
 101         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 102 elif test "$includedir" != "/usr/include"; then
 103         if test "$includedir" = '${prefix}/include' ; then
 104                 if test $prefix != /usr ; then
 105                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 106                 fi
 107         else
 108                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 109         fi
 110 fi
 111 AC_SUBST(ACPPFLAGS)
 112 ])dnl
 113 dnl ---------------------------------------------------------------------------
 114 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 115 dnl ---------------
 116 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 117 AC_DEFUN([CF_ADD_ADAFLAGS],[
 118         ADAFLAGS="$ADAFLAGS $1"
 119         AC_SUBST(ADAFLAGS)
 120 ])dnl
 121 dnl ---------------------------------------------------------------------------
 122 dnl CF_ADD_CFLAGS version: 10 updated: 2010/05/26 05:38:42
 123 dnl -------------
 124 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 125 dnl The second parameter if given makes this macro verbose.
 126 dnl
 127 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 128 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 129 dnl confused by the quotes (which require backslashes to keep them usable).
 130 AC_DEFUN([CF_ADD_CFLAGS],
 131 [
 132 cf_fix_cppflags=no
 133 cf_new_cflags=
 134 cf_new_cppflags=
 135 cf_new_extra_cppflags=
 136
 137 for cf_add_cflags in $1
 138 do
 139 case $cf_fix_cppflags in
 140 no)
 141         case $cf_add_cflags in #(vi
 142         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
 143                 case $cf_add_cflags in
 144                 -D*)
 145                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 146
 147                         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 148                                 && test -z "${cf_tst_cflags}" \
 149                                 && cf_fix_cppflags=yes
 150
 151                         if test $cf_fix_cppflags = yes ; then
 152                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 153                                 continue
 154                         elif test "${cf_tst_cflags}" = "\"'" ; then
 155                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 156                                 continue
 157                         fi
 158                         ;;
 159                 esac
 160                 case "$CPPFLAGS" in
 161                 *$cf_add_cflags) #(vi
 162                         ;;
 163                 *) #(vi
 164                         case $cf_add_cflags in #(vi
 165                         -D*)
 166                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 167                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 168                                 ;;
 169                         esac
 170                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 171                         ;;
 172                 esac
 173                 ;;
 174         *)
 175                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 176                 ;;
 177         esac
 178         ;;
 179 yes)
 180         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 181
 182         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 183
 184         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 185                 && test -z "${cf_tst_cflags}" \
 186                 && cf_fix_cppflags=no
 187         ;;
 188 esac
 189 done
 190
 191 if test -n "$cf_new_cflags" ; then
 192         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 193         CFLAGS="$CFLAGS $cf_new_cflags"
 194 fi
 195
 196 if test -n "$cf_new_cppflags" ; then
 197         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 198         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 199 fi
 200
 201 if test -n "$cf_new_extra_cppflags" ; then
 202         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 203         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 204 fi
 205
 206 AC_SUBST(EXTRA_CPPFLAGS)
 207
 208 ])dnl
 209 dnl ---------------------------------------------------------------------------
 210 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
 211 dnl -------------
 212 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 213 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 214 dnl but old versions (and some misinstalled ones) need that.  To make things
 215 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 216 dnl the include-path).
 217 AC_DEFUN([CF_ADD_INCDIR],
 218 [
 219 if test -n "$1" ; then
 220   for cf_add_incdir in $1
 221   do
 222         while test $cf_add_incdir != /usr/include
 223         do
 224           if test -d $cf_add_incdir
 225           then
 226                 cf_have_incdir=no
 227                 if test -n "$CFLAGS$CPPFLAGS" ; then
 228                   # a loop is needed to ensure we can add subdirs of existing dirs
 229                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 230                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 231                           cf_have_incdir=yes; break
 232                         fi
 233                   done
 234                 fi
 235
 236                 if test "$cf_have_incdir" = no ; then
 237                   if test "$cf_add_incdir" = /usr/local/include ; then
 238                         if test "$GCC" = yes
 239                         then
 240                           cf_save_CPPFLAGS=$CPPFLAGS
 241                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 242                           AC_TRY_COMPILE([#include <stdio.h>],
 243                                   [printf("Hello")],
 244                                   [],
 245                                   [cf_have_incdir=yes])
 246                           CPPFLAGS=$cf_save_CPPFLAGS
 247                         fi
 248                   fi
 249                 fi
 250
 251                 if test "$cf_have_incdir" = no ; then
 252                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 253                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 254
 255                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 256                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 257                   cf_add_incdir="$cf_top_incdir"
 258                 else
 259                   break
 260                 fi
 261           fi
 262         done
 263   done
 264 fi
 265 ])dnl
 266 dnl ---------------------------------------------------------------------------
 267 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 268 dnl ----------
 269 dnl Add a library, used to enforce consistency.
 270 dnl
 271 dnl $1 = library to add, without the "-l"
 272 dnl $2 = variable to update (default $LIBS)
 273 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 274 dnl ---------------------------------------------------------------------------
 275 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
 276 dnl -------------
 277 dnl     Adds to the library-path
 278 dnl
 279 dnl     Some machines have trouble with multiple -L options.
 280 dnl
 281 dnl $1 is the (list of) directory(s) to add
 282 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 283 dnl
 284 AC_DEFUN([CF_ADD_LIBDIR],
 285 [
 286 if test -n "$1" ; then
 287   for cf_add_libdir in $1
 288   do
 289     if test $cf_add_libdir = /usr/lib ; then
 290       :
 291     elif test -d $cf_add_libdir
 292     then
 293       cf_have_libdir=no
 294       if test -n "$LDFLAGS$LIBS" ; then
 295         # a loop is needed to ensure we can add subdirs of existing dirs
 296         for cf_test_libdir in $LDFLAGS $LIBS ; do
 297           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 298             cf_have_libdir=yes; break
 299           fi
 300         done
 301       fi
 302       if test "$cf_have_libdir" = no ; then
 303         CF_VERBOSE(adding $cf_add_libdir to library-path)
 304         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 305       fi
 306     fi
 307   done
 308 fi
 309 ])dnl
 310 dnl ---------------------------------------------------------------------------
 311 dnl CF_ADD_LIBS version: 1 updated: 2010/06/02 05:03:05
 312 dnl -----------
 313 dnl Add one or more libraries, used to enforce consistency.
 314 dnl
 315 dnl $1 = libraries to add, with the "-l", etc.
 316 dnl $2 = variable to update (default $LIBS)
 317 AC_DEFUN([CF_ADD_LIBS],[ifelse($2,,LIBS,[$2])="$1 [$]ifelse($2,,LIBS,[$2])"])dnl
 318 dnl ---------------------------------------------------------------------------
 319 dnl CF_ADD_SUBDIR_PATH version: 3 updated: 2010/07/03 20:58:12
 320 dnl ------------------
 321 dnl Append to a search-list for a nonstandard header/lib-file
 322 dnl     $1 = the variable to return as result
 323 dnl     $2 = the package name
 324 dnl     $3 = the subdirectory, e.g., bin, include or lib
 325 dnl $4 = the directory under which we will test for subdirectories
 326 dnl $5 = a directory that we do not want $4 to match
 327 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 328 [
 329 test "$4" != "$5" && \
 330 test -d "$4" && \
 331 ifelse([$5],NONE,,[(test $5 = NONE || test "$4" != "$5") &&]) {
 332         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 333         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 334         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 335         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 336         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 337         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 338 }
 339 ])dnl
 340 dnl ---------------------------------------------------------------------------
 341 dnl CF_ANSI_CC_CHECK version: 11 updated: 2011/07/01 19:47:45
 342 dnl ----------------
 343 dnl This was originally adapted from the macros 'fp_PROG_CC_STDC' and
 344 dnl 'fp_C_PROTOTYPES' in the sharutils 4.2 distribution.
 345 AC_DEFUN([CF_ANSI_CC_CHECK],
 346 [
 347 # This should have been defined by AC_PROG_CC
 348 : ${CC:=cc}
 349
 350 # Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 351 # into CC.  This will not help with broken scripts that wrap the compiler with
 352 # options, but eliminates a more common category of user confusion.
 353 AC_MSG_CHECKING(\$CC variable)
 354 case "$CC" in #(vi
 355 *[[\ \  ]]-[[IUD]]*)
 356         AC_MSG_RESULT(broken)
 357         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 358         # humor him...
 359         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
 360         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
 361         CF_ADD_CFLAGS($cf_flags)
 362         ;;
 363 *)
 364         AC_MSG_RESULT(ok)
 365         ;;
 366 esac
 367
 368 AC_CACHE_CHECK(for ${CC:-cc} option to accept ANSI C, cf_cv_ansi_cc,[
 369 cf_cv_ansi_cc=no
 370 cf_save_CFLAGS="$CFLAGS"
 371 cf_save_CPPFLAGS="$CPPFLAGS"
 372 # Don't try gcc -ansi; that turns off useful extensions and
 373 # breaks some systems' header files.
 374 # AIX                   -qlanglvl=ansi
 375 # Ultrix and OSF/1      -std1
 376 # HP-UX                 -Aa -D_HPUX_SOURCE
 377 # SVR4                  -Xc
 378 # UnixWare 1.2          (cannot use -Xc, since ANSI/POSIX clashes)
 379 for cf_arg in "-DCC_HAS_PROTOS" \
 380         "" \
 381         -qlanglvl=ansi \
 382         -std1 \
 383         -Ae \
 384         "-Aa -D_HPUX_SOURCE" \
 385         -Xc
 386 do
 387         CF_ADD_CFLAGS($cf_arg)
 388         AC_TRY_COMPILE(
 389 [
 390 #ifndef CC_HAS_PROTOS
 391 #if !defined(__STDC__) || (__STDC__ != 1)
 392 choke me
 393 #endif
 394 #endif
 395 ],[
 396         int test (int i, double x);
 397         struct s1 {int (*f) (int a);};
 398         struct s2 {int (*f) (double a);};],
 399         [cf_cv_ansi_cc="$cf_arg"; break])
 400 done
 401 CFLAGS="$cf_save_CFLAGS"
 402 CPPFLAGS="$cf_save_CPPFLAGS"
 403 ])
 404
 405 if test "$cf_cv_ansi_cc" != "no"; then
 406 if test ".$cf_cv_ansi_cc" != ".-DCC_HAS_PROTOS"; then
 407         CF_ADD_CFLAGS($cf_cv_ansi_cc)
 408 else
 409         AC_DEFINE(CC_HAS_PROTOS)
 410 fi
 411 fi
 412 ])dnl
 413 dnl ---------------------------------------------------------------------------
 414 dnl CF_ANSI_CC_REQD version: 4 updated: 2008/03/23 14:48:54
 415 dnl ---------------
 416 dnl For programs that must use an ANSI compiler, obtain compiler options that
 417 dnl will make it recognize prototypes.  We'll do preprocessor checks in other
 418 dnl macros, since tools such as unproto can fake prototypes, but only part of
 419 dnl the preprocessor.
 420 AC_DEFUN([CF_ANSI_CC_REQD],
 421 [AC_REQUIRE([CF_ANSI_CC_CHECK])
 422 if test "$cf_cv_ansi_cc" = "no"; then
 423         AC_MSG_ERROR(
 424 [Your compiler does not appear to recognize prototypes.
 425 You have the following choices:
 426         a. adjust your compiler options
 427         b. get an up-to-date compiler
 428         c. use a wrapper such as unproto])
 429 fi
 430 ])dnl
 431 dnl ---------------------------------------------------------------------------
 432 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 433 dnl --------------
 434 dnl Allow user to disable a normally-on option.
 435 AC_DEFUN([CF_ARG_DISABLE],
 436 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 437 dnl ---------------------------------------------------------------------------
 438 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
 439 dnl -------------
 440 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 441 dnl values.
 442 dnl
 443 dnl Parameters:
 444 dnl $1 = option name
 445 dnl $2 = help-string
 446 dnl $3 = action to perform if option is not default
 447 dnl $4 = action if perform if option is default
 448 dnl $5 = default option value (either 'yes' or 'no')
 449 AC_DEFUN([CF_ARG_OPTION],
 450 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 451   if test "$enableval" != "$5" ; then
 452 ifelse([$3],,[    :]dnl
 453 ,[    $3]) ifelse([$4],,,[
 454   else
 455     $4])
 456   fi],[enableval=$5 ifelse([$4],,,[
 457   $4
 458 ])dnl
 459   ])])dnl
 460 dnl ---------------------------------------------------------------------------
 461 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
 462 dnl -----------
 463 dnl Check for suitable "ar" (archiver) options for updating an archive.
 464 AC_DEFUN([CF_AR_FLAGS],[
 465 AC_REQUIRE([CF_PROG_AR])
 466
 467 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 468         cf_cv_ar_flags=unknown
 469         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
 470         do
 471
 472                 # check if $ARFLAGS already contains this choice
 473                 if test "x$ARFLAGS" != "x" ; then
 474                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 475                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 476                                 cf_cv_ar_flags=
 477                                 break
 478                         fi
 479                 fi
 480
 481                 rm -f conftest.$ac_cv_objext
 482                 rm -f conftest.a
 483
 484                 cat >conftest.$ac_ext <<EOF
 485 #line __oline__ "configure"
 486 int     testdata[[3]] = { 123, 456, 789 };
 487 EOF
 488                 if AC_TRY_EVAL(ac_compile) ; then
 489                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 490                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 491                         if test -f conftest.a ; then
 492                                 cf_cv_ar_flags=$cf_ar_flags
 493                                 break
 494                         fi
 495                 else
 496                         CF_VERBOSE(cannot compile test-program)
 497                         break
 498                 fi
 499         done
 500         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 501 ])
 502
 503 if test -n "$ARFLAGS" ; then
 504         if test -n "$cf_cv_ar_flags" ; then
 505                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 506         fi
 507 else
 508         ARFLAGS=$cf_cv_ar_flags
 509 fi
 510
 511 AC_SUBST(ARFLAGS)
 512 ])
 513 dnl ---------------------------------------------------------------------------
 514 dnl CF_AWK_BIG_PRINTF version: 3 updated: 2008/12/27 12:30:03
 515 dnl -----------------
 516 dnl Check if awk can handle big strings using printf.  Some older versions of
 517 dnl awk choke on large strings passed via "%s".
 518 dnl
 519 dnl $1 = desired string size
 520 dnl $2 = variable to set with result
 521 AC_DEFUN([CF_AWK_BIG_PRINTF],
 522 [
 523         case x$AWK in #(vi
 524         x)
 525                 eval $2=no
 526                 ;;
 527         *) #(vi
 528                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' \
 529                         | $AWK '{ printf "%d\n", length([$]0); }' | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 530                         eval $2=yes
 531                 else
 532                         eval $2=no
 533                 fi
 534                 ;;
 535         esac
 536 ])dnl
 537 dnl ---------------------------------------------------------------------------
 538 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 539 dnl ------------
 540 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 541 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 542 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 543 dnl
 544 dnl Treat the configuration-variable specially here, since we're directly
 545 dnl substituting its value (i.e., 1/0).
 546 dnl
 547 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 548 AC_DEFUN([CF_BOOL_DECL],
 549 [
 550 AC_MSG_CHECKING(if we should include stdbool.h)
 551
 552 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 553         AC_TRY_COMPILE([],[bool foo = false],
 554                 [cf_cv_header_stdbool_h=0],
 555                 [AC_TRY_COMPILE([
 556 #ifndef __BEOS__
 557 #include <stdbool.h>
 558 #endif
 559 ],[bool foo = false],
 560                         [cf_cv_header_stdbool_h=1],
 561                         [cf_cv_header_stdbool_h=0])])])
 562
 563 if test "$cf_cv_header_stdbool_h" = 1
 564 then    AC_MSG_RESULT(yes)
 565 else    AC_MSG_RESULT(no)
 566 fi
 567
 568 AC_MSG_CHECKING([for builtin bool type])
 569
 570 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 571         AC_TRY_COMPILE([
 572 #include <stdio.h>
 573 #include <sys/types.h>
 574 ],[bool x = false],
 575                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 576                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 577         ])
 578
 579 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 580 then    AC_MSG_RESULT(yes)
 581 else    AC_MSG_RESULT(no)
 582 fi
 583 ])dnl
 584 dnl ---------------------------------------------------------------------------
 585 dnl CF_BOOL_SIZE version: 12 updated: 2006/12/16 12:33:30
 586 dnl ------------
 587 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 588 dnl Don't bother looking for bool.h, since it's been deprecated.
 589 dnl
 590 dnl If the current compiler is C rather than C++, we get the bool definition
 591 dnl from <stdbool.h>.
 592 AC_DEFUN([CF_BOOL_SIZE],
 593 [
 594 AC_MSG_CHECKING([for size of bool])
 595 AC_CACHE_VAL(cf_cv_type_of_bool,[
 596         rm -f cf_test.out
 597         AC_TRY_RUN([
 598 #include <stdlib.h>
 599 #include <stdio.h>
 600
 601 #if defined(__cplusplus)
 602
 603 #ifdef HAVE_GXX_BUILTIN_H
 604 #include <g++/builtin.h>
 605 #elif HAVE_GPP_BUILTIN_H
 606 #include <gpp/builtin.h>
 607 #elif HAVE_BUILTIN_H
 608 #include <builtin.h>
 609 #endif
 610
 611 #else
 612
 613 #if $cf_cv_header_stdbool_h
 614 #include <stdbool.h>
 615 #endif
 616
 617 #endif
 618
 619 main()
 620 {
 621         FILE *fp = fopen("cf_test.out", "w");
 622         if (fp != 0) {
 623                 bool x = true;
 624                 if ((bool)(-x) >= 0)
 625                         fputs("unsigned ", fp);
 626                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 627                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 628                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 629                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 630                 fclose(fp);
 631         }
 632         ${cf_cv_main_return:-return}(0);
 633 }
 634                 ],
 635                 [cf_cv_type_of_bool=`cat cf_test.out`
 636                  if test -z "$cf_cv_type_of_bool"; then
 637                    cf_cv_type_of_bool=unknown
 638                  fi],
 639                 [cf_cv_type_of_bool=unknown],
 640                 [cf_cv_type_of_bool=unknown])
 641         ])
 642         rm -f cf_test.out
 643 AC_MSG_RESULT($cf_cv_type_of_bool)
 644 if test "$cf_cv_type_of_bool" = unknown ; then
 645         case .$NCURSES_BOOL in #(vi
 646         .auto|.) NCURSES_BOOL=unsigned;;
 647         esac
 648         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 649         cf_cv_type_of_bool=$NCURSES_BOOL
 650 fi
 651 ])dnl
 652 dnl ---------------------------------------------------------------------------
 653 dnl CF_BUILD_CC version: 6 updated: 2006/10/14 15:23:15
 654 dnl -----------
 655 dnl If we're cross-compiling, allow the user to override the tools and their
 656 dnl options.  The configure script is oriented toward identifying the host
 657 dnl compiler, etc., but we need a build compiler to generate parts of the
 658 dnl source.
 659 dnl
 660 dnl $1 = default for $CPPFLAGS
 661 dnl $2 = default for $LIBS
 662 AC_DEFUN([CF_BUILD_CC],[
 663 AC_REQUIRE([CF_PROG_EXT])
 664 if test "$cross_compiling" = yes ; then
 665
 666         # defaults that we might want to override
 667         : ${BUILD_CFLAGS:=''}
 668         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 669         : ${BUILD_LDFLAGS:=''}
 670         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 671         : ${BUILD_EXEEXT:='$x'}
 672         : ${BUILD_OBJEXT:='o'}
 673
 674         AC_ARG_WITH(build-cc,
 675                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 676                 [BUILD_CC="$withval"],
 677                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 678         AC_MSG_CHECKING(for native build C compiler)
 679         AC_MSG_RESULT($BUILD_CC)
 680
 681         AC_MSG_CHECKING(for native build C preprocessor)
 682         AC_ARG_WITH(build-cpp,
 683                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 684                 [BUILD_CPP="$withval"],
 685                 [BUILD_CPP='${BUILD_CC} -E'])
 686         AC_MSG_RESULT($BUILD_CPP)
 687
 688         AC_MSG_CHECKING(for native build C flags)
 689         AC_ARG_WITH(build-cflags,
 690                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 691                 [BUILD_CFLAGS="$withval"])
 692         AC_MSG_RESULT($BUILD_CFLAGS)
 693
 694         AC_MSG_CHECKING(for native build C preprocessor-flags)
 695         AC_ARG_WITH(build-cppflags,
 696                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 697                 [BUILD_CPPFLAGS="$withval"])
 698         AC_MSG_RESULT($BUILD_CPPFLAGS)
 699
 700         AC_MSG_CHECKING(for native build linker-flags)
 701         AC_ARG_WITH(build-ldflags,
 702                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 703                 [BUILD_LDFLAGS="$withval"])
 704         AC_MSG_RESULT($BUILD_LDFLAGS)
 705
 706         AC_MSG_CHECKING(for native build linker-libraries)
 707         AC_ARG_WITH(build-libs,
 708                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 709                 [BUILD_LIBS="$withval"])
 710         AC_MSG_RESULT($BUILD_LIBS)
 711
 712         # this assumes we're on Unix.
 713         BUILD_EXEEXT=
 714         BUILD_OBJEXT=o
 715
 716         : ${BUILD_CC:='${CC}'}
 717
 718         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 719                 AC_MSG_ERROR([Cross-build requires two compilers.
 720 Use --with-build-cc to specify the native compiler.])
 721         fi
 722
 723 else
 724         : ${BUILD_CC:='${CC}'}
 725         : ${BUILD_CPP:='${CPP}'}
 726         : ${BUILD_CFLAGS:='${CFLAGS}'}
 727         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 728         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 729         : ${BUILD_LIBS:='${LIBS}'}
 730         : ${BUILD_EXEEXT:='$x'}
 731         : ${BUILD_OBJEXT:='o'}
 732 fi
 733
 734 AC_SUBST(BUILD_CC)
 735 AC_SUBST(BUILD_CPP)
 736 AC_SUBST(BUILD_CFLAGS)
 737 AC_SUBST(BUILD_CPPFLAGS)
 738 AC_SUBST(BUILD_LDFLAGS)
 739 AC_SUBST(BUILD_LIBS)
 740 AC_SUBST(BUILD_EXEEXT)
 741 AC_SUBST(BUILD_OBJEXT)
 742 ])dnl
 743 dnl ---------------------------------------------------------------------------
 744 dnl CF_CFG_DEFAULTS version: 8 updated: 2011/06/04 20:09:13
 745 dnl ---------------
 746 dnl Determine the default configuration into which we'll install ncurses.  This
 747 dnl can be overridden by the user's command-line options.  There's two items to
 748 dnl look for:
 749 dnl     1. the prefix (e.g., /usr)
 750 dnl     2. the header files (e.g., /usr/include/ncurses)
 751 dnl We'll look for a previous installation of ncurses and use the same defaults.
 752 dnl
 753 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 754 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 755 dnl programs from a vendor's.
 756 AC_DEFUN([CF_CFG_DEFAULTS],
 757 [
 758 AC_MSG_CHECKING(for prefix)
 759 if test "x$prefix" = "xNONE" ; then
 760         case "$cf_cv_system_name" in
 761                 # non-vendor systems don't have a conflict
 762         openbsd*|freebsd*|mirbsd*|linux*|cygwin*|k*bsd*-gnu)
 763                 prefix=/usr
 764                 ;;
 765         *)      prefix=$ac_default_prefix
 766                 ;;
 767         esac
 768 fi
 769 AC_MSG_RESULT($prefix)
 770
 771 if test "x$prefix" = "xNONE" ; then
 772 AC_MSG_CHECKING(for default include-directory)
 773 test -n "$verbose" && echo 1>&AC_FD_MSG
 774 for cf_symbol in \
 775         $includedir \
 776         $includedir/ncurses \
 777         $prefix/include \
 778         $prefix/include/ncurses \
 779         /usr/local/include \
 780         /usr/local/include/ncurses \
 781         /usr/include \
 782         /usr/include/ncurses
 783 do
 784         cf_dir=`eval echo $cf_symbol`
 785         if test -f $cf_dir/curses.h ; then
 786         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 787                 includedir="$cf_symbol"
 788                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 789                 break
 790         fi
 791         fi
 792         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 793 done
 794 AC_MSG_RESULT($includedir)
 795 fi
 796 ])dnl
 797 dnl ---------------------------------------------------------------------------
 798 dnl CF_CGETENT version: 3 updated: 2000/08/12 23:18:52
 799 dnl ----------
 800 dnl Check if the terminal-capability database functions are available.  If not,
 801 dnl ncurses has a much-reduced version.
 802 AC_DEFUN([CF_CGETENT],[
 803 AC_MSG_CHECKING(for terminal-capability database functions)
 804 AC_CACHE_VAL(cf_cv_cgetent,[
 805 AC_TRY_LINK([
 806 #include <stdlib.h>],[
 807         char temp[128];
 808         char *buf = temp;
 809         char *db_array = temp;
 810         cgetent(&buf, /* int *, */ &db_array, "vt100");
 811         cgetcap(buf, "tc", '=');
 812         cgetmatch(buf, "tc");
 813         ],
 814         [cf_cv_cgetent=yes],
 815         [cf_cv_cgetent=no])
 816 ])
 817 AC_MSG_RESULT($cf_cv_cgetent)
 818 test "$cf_cv_cgetent" = yes && AC_DEFINE(HAVE_BSD_CGETENT)
 819 ])dnl
 820 dnl ---------------------------------------------------------------------------
 821 dnl CF_CHECK_CACHE version: 11 updated: 2008/03/23 14:45:59
 822 dnl --------------
 823 dnl Check if we're accidentally using a cache from a different machine.
 824 dnl Derive the system name, as a check for reusing the autoconf cache.
 825 dnl
 826 dnl If we've packaged config.guess and config.sub, run that (since it does a
 827 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 828 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 829 dnl which is useful in cross-compiles.
 830 dnl
 831 dnl Note: we would use $ac_config_sub, but that is one of the places where
 832 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 833 AC_DEFUN([CF_CHECK_CACHE],
 834 [
 835 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 836         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 837         system_name="$host_os"
 838 else
 839         system_name="`(uname -s -r) 2>/dev/null`"
 840         if test -z "$system_name" ; then
 841                 system_name="`(hostname) 2>/dev/null`"
 842         fi
 843 fi
 844 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name")
 845 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 846
 847 test -z "$system_name" && system_name="$cf_cv_system_name"
 848 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 849
 850 if test ".$system_name" != ".$cf_cv_system_name" ; then
 851         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 852         AC_MSG_ERROR("Please remove config.cache and try again.")
 853 fi
 854 ])dnl
 855 dnl ---------------------------------------------------------------------------
 856 dnl CF_CHECK_ERRNO version: 11 updated: 2010/05/26 05:38:42
 857 dnl --------------
 858 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 859 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 860 dnl ourselves.
 861 dnl
 862 dnl $1 = the name to check
 863 dnl $2 = the assumed type
 864 AC_DEFUN([CF_CHECK_ERRNO],
 865 [
 866 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 867     AC_TRY_COMPILE([
 868 #ifdef HAVE_STDLIB_H
 869 #include <stdlib.h>
 870 #endif
 871 #include <stdio.h>
 872 #include <sys/types.h>
 873 #include <errno.h> ],
 874     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 875     [cf_cv_dcl_$1=yes],
 876     [cf_cv_dcl_$1=no])
 877 ])
 878
 879 if test "$cf_cv_dcl_$1" = no ; then
 880     CF_UPPER(cf_result,decl_$1)
 881     AC_DEFINE_UNQUOTED($cf_result)
 882 fi
 883
 884 # It's possible (for near-UNIX clones) that the data doesn't exist
 885 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 886 ])dnl
 887 dnl ---------------------------------------------------------------------------
 888 dnl CF_CHECK_EXTERN_DATA version: 3 updated: 2001/12/30 18:03:23
 889 dnl --------------------
 890 dnl Check for existence of external data in the current set of libraries.  If
 891 dnl we can modify it, it's real enough.
 892 dnl $1 = the name to check
 893 dnl $2 = its type
 894 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 895 [
 896 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 897     AC_TRY_LINK([
 898 #undef $1
 899 extern $2 $1;
 900 ],
 901     [$1 = 2],
 902     [cf_cv_have_$1=yes],
 903     [cf_cv_have_$1=no])
 904 ])
 905
 906 if test "$cf_cv_have_$1" = yes ; then
 907     CF_UPPER(cf_result,have_$1)
 908     AC_DEFINE_UNQUOTED($cf_result)
 909 fi
 910
 911 ])dnl
 912 dnl ---------------------------------------------------------------------------
 913 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
 914 dnl -------------------
 915 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 916 dnl is not "weak" - warn about this because it can create problems linking
 917 dnl applications with ncurses.
 918 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 919 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 920
 921 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 922 cf_cv_check_gpm_wgetch=unknown
 923 if test "$cross_compiling" != yes ; then
 924
 925 cat >conftest.$ac_ext <<CF_EOF
 926 #include <gpm.h>
 927 int main()
 928 {
 929         Gpm_Wgetch();
 930         ${cf_cv_main_return:-return}(0);
 931 }
 932 CF_EOF
 933
 934         cf_save_LIBS="$LIBS"
 935         # This only works if we can look at the symbol table.  If a shared
 936         # library is stripped for install, we cannot use that.  So we're forced
 937         # to rely on the static library, noting that some packagers may not
 938         # include it.
 939         LIBS="-static -lgpm -dynamic $LIBS"
 940         if AC_TRY_EVAL(ac_compile) ; then
 941                 if AC_TRY_EVAL(ac_link) ; then
 942                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
 943                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
 944                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
 945                 fi
 946         fi
 947         rm -rf conftest*
 948         LIBS="$cf_save_LIBS"
 949 fi
 950 ])
 951
 952 if test "$cf_cv_check_gpm_wgetch" != yes ; then
 953         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 954 fi
 955 ])])dnl
 956 dnl ---------------------------------------------------------------------------
 957 dnl CF_CPP_PARAM_INIT version: 4 updated: 2001/04/07 22:31:18
 958 dnl -----------------
 959 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
 960 dnl is a late feature for the standard and is not in some recent compilers
 961 dnl (1999/9/11).
 962 AC_DEFUN([CF_CPP_PARAM_INIT],
 963 [
 964 if test -n "$CXX"; then
 965 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
 966         AC_LANG_SAVE
 967         AC_LANG_CPLUSPLUS
 968         AC_TRY_RUN([
 969 class TEST {
 970 private:
 971         int value;
 972 public:
 973         TEST(int x = 1);
 974         ~TEST();
 975 };
 976
 977 TEST::TEST(int x = 1)   // some compilers do not like second initializer
 978 {
 979         value = x;
 980 }
 981 void main() { }
 982 ],
 983         [cf_cv_cpp_param_init=yes],
 984         [cf_cv_cpp_param_init=no],
 985         [cf_cv_cpp_param_init=unknown])
 986         AC_LANG_RESTORE
 987 ])
 988 fi
 989 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT)
 990 ])dnl
 991 dnl ---------------------------------------------------------------------------
 992 dnl CF_CPP_STATIC_CAST version: 1 updated: 2005/07/23 16:52:43
 993 dnl ------------------
 994 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
 995 dnl not be supported in g++ before 3.0
 996 AC_DEFUN([CF_CPP_STATIC_CAST],
 997 [
 998 if test -n "$CXX"; then
 999
1000 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1001         AC_LANG_SAVE
1002         AC_LANG_CPLUSPLUS
1003
1004         AC_TRY_COMPILE([
1005 class NCursesPanel
1006 {
1007 public:
1008   NCursesPanel(int nlines,
1009                int ncols,
1010                int begin_y = 0,
1011                int begin_x = 0)
1012   {
1013   }
1014
1015   ~NCursesPanel();
1016 };
1017
1018 template<class T> class NCursesUserPanel : public NCursesPanel
1019 {
1020 public:
1021   NCursesUserPanel (int nlines,
1022                     int ncols,
1023                     int begin_y = 0,
1024                     int begin_x = 0,
1025                     const T* p_UserData = static_cast<T*>(0))
1026     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1027   {
1028   };
1029   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1030   {
1031   };
1032
1033   virtual ~NCursesUserPanel() {};
1034 };
1035 ],[
1036         const char* p_UserData = static_cast<char*>(0)],
1037         [cf_cv_cpp_static_cast=yes],
1038         [cf_cv_cpp_static_cast=no])
1039
1040         AC_LANG_RESTORE
1041 ])
1042
1043 fi
1044
1045 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST)
1046 ])dnl
1047 dnl ---------------------------------------------------------------------------
1048 dnl CF_C_INLINE version: 3 updated: 2010/05/01 15:14:41
1049 dnl -----------
1050 dnl Check if the C compiler supports "inline".
1051 dnl $1 is the name of a shell variable to set if inline is supported
1052 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1053 AC_DEFUN([CF_C_INLINE],[
1054 AC_C_INLINE
1055 $1=
1056 if test "$ac_cv_c_inline" != no ; then
1057   $1=inline
1058   if test "$INTEL_COMPILER" = yes
1059   then
1060     :
1061   elif test "$GCC" = yes
1062   then
1063     AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1064       cf_save_CFLAGS=$CFLAGS
1065       CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1066       AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1067       [${cf_cv_main_return:-return} foo()],
1068       [cf_cv_gcc_inline=yes],
1069       [cf_cv_gcc_inline=no])
1070       CFLAGS=$cf_save_CFLAGS
1071     ])
1072     if test "$cf_cv_gcc_inline" = yes ; then
1073         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1074     fi
1075   fi
1076 fi
1077 AC_SUBST($1)
1078 ])dnl
1079 dnl ---------------------------------------------------------------------------
1080 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1081 dnl ----------
1082 dnl "dirname" is not portable, so we fake it with a shell script.
1083 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1084 dnl ---------------------------------------------------------------------------
1085 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1086 dnl ---------------
1087 AC_DEFUN([CF_DIRS_TO_MAKE],
1088 [
1089 DIRS_TO_MAKE="lib"
1090 for cf_item in $cf_list_models
1091 do
1092         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1093         for cf_item2 in $DIRS_TO_MAKE
1094         do
1095                 test $cf_item2 = $cf_subdir && break
1096         done
1097         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1098 done
1099 for cf_dir in $DIRS_TO_MAKE
1100 do
1101         test ! -d $cf_dir && mkdir $cf_dir
1102 done
1103 AC_SUBST(DIRS_TO_MAKE)
1104 ])dnl
1105 dnl ---------------------------------------------------------------------------
1106 dnl CF_DISABLE_LEAKS version: 6 updated: 2010/07/23 04:14:32
1107 dnl ----------------
1108 dnl Combine no-leak checks with the libraries or tools that are used for the
1109 dnl checks.
1110 AC_DEFUN([CF_DISABLE_LEAKS],[
1111
1112 AC_REQUIRE([CF_WITH_DMALLOC])
1113 AC_REQUIRE([CF_WITH_DBMALLOC])
1114 AC_REQUIRE([CF_WITH_VALGRIND])
1115
1116 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1117 AC_ARG_ENABLE(leaks,
1118         [  --disable-leaks         test: free permanent memory, analyze leaks],
1119         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1120         : ${with_no_leaks:=no})
1121 AC_MSG_RESULT($with_no_leaks)
1122
1123 if test "$with_no_leaks" = yes ; then
1124         AC_DEFINE(NO_LEAKS)
1125         AC_DEFINE(YY_NO_LEAKS)
1126 fi
1127 ])dnl
1128 dnl ---------------------------------------------------------------------------
1129 dnl CF_DISABLE_LIBTOOL_VERSION version: 1 updated: 2010/05/15 15:45:59
1130 dnl --------------------------
1131 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1132 dnl the older "-version-info" feature.  The newer feature allows us to use
1133 dnl version numbering on shared libraries which make them compatible with
1134 dnl various systems.
1135 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1136 [
1137 AC_MSG_CHECKING(if libtool -version-number should be used)
1138 CF_ARG_DISABLE(libtool-version,
1139         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1140         [cf_libtool_version=no],
1141         [cf_libtool_version=yes])
1142 AC_MSG_RESULT($cf_libtool_version)
1143
1144 if test "$cf_libtool_version" = yes ; then
1145         LIBTOOL_VERSION="-version-number"
1146 else
1147         LIBTOOL_VERSION="-version-info"
1148 fi
1149
1150 AC_SUBST(LIBTOOL_VERSION)
1151 ])dnl
1152 dnl ---------------------------------------------------------------------------
1153 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1154 dnl ---------------------
1155 dnl The rpath-hack makes it simpler to build programs, particularly with the
1156 dnl *BSD ports which may have essential libraries in unusual places.  But it
1157 dnl can interfere with building an executable for the base system.  Use this
1158 dnl option in that case.
1159 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1160 [
1161 AC_MSG_CHECKING(if rpath-hack should be disabled)
1162 CF_ARG_DISABLE(rpath-hack,
1163         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1164         [cf_disable_rpath_hack=yes],
1165         [cf_disable_rpath_hack=no])
1166 AC_MSG_RESULT($cf_disable_rpath_hack)
1167 if test "$cf_disable_rpath_hack" = no ; then
1168         CF_RPATH_HACK
1169 fi
1170 ])
1171 dnl ---------------------------------------------------------------------------
1172 dnl CF_ENABLE_PC_FILES version: 3 updated: 2011/07/16 20:37:23
1173 dnl ------------------
1174 dnl This is the "--enable-pc-files" option, which is available if there is a
1175 dnl pkg-config configuration on the local machine.
1176 dnl
1177 dnl It sets/updates PKG_CONFIG_LIBDIR, which is used by pkg-config as a
1178 dnl special case: overriding PKG_CONFIG_PATH (preferred).
1179 AC_DEFUN([CF_ENABLE_PC_FILES],[
1180 AC_REQUIRE([CF_PATHSEP])
1181 AC_REQUIRE([CF_PKG_CONFIG])
1182
1183 if test "$PKG_CONFIG" != no ; then
1184         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1185
1186         # Leave this as something that can be overridden in the environment.
1187         if test -z "$PKG_CONFIG_LIBDIR" ; then
1188                 if test -n "$PKG_CONFIG_PATH" ; then
1189                         for cf_config in `echo "$PKG_CONFIG_PATH" | sed -e 's/'$PATH_SEPARATOR'/ /g'`
1190                         do
1191                                 if test -n "$cf_config" && test -d "$cf_config"
1192                                 then
1193                                         PKG_CONFIG_LIBDIR=$cf_config
1194                                         break
1195                                 fi
1196                         done
1197                 fi
1198                 if test -z "$PKG_CONFIG_LIBDIR" ; then
1199                         cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
1200                         case x`arch 2>/dev/null` in #(vi
1201                         *64) #(vi
1202                                 for cf_config in $cf_path/lib64 $cf_path/lib32 $cf_path/lib
1203                                 do
1204                                         if test -d $cf_config/pkgconfig
1205                                         then
1206                                                 PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
1207                                                 break
1208                                         fi
1209                                 done
1210                                 ;;
1211                         *)
1212                                 PKG_CONFIG_LIBDIR=$cf_path/lib/pkgconfig
1213                                 ;;
1214                         esac
1215                 fi
1216         else
1217                 PKG_CONFIG_LIBDIR=`echo "$PKG_CONFIG_LIBDIR" | sed -e 's/^://' -e 's/:.*//'`
1218         fi
1219         if test -n "$PKG_CONFIG_LIBDIR" && test -d "$PKG_CONFIG_LIBDIR" ; then
1220                 AC_ARG_ENABLE(pc-files,
1221                         [  --enable-pc-files       generate and install .pc files for pkg-config],
1222                         [enable_pc_files=$enableval],
1223                         [enable_pc_files=no])
1224                 AC_MSG_RESULT($enable_pc_files)
1225                 CF_VERBOSE(found library $PKG_CONFIG_LIBDIR)
1226         else
1227                 AC_MSG_RESULT(no)
1228                 AC_MSG_WARN(did not find library $PKG_CONFIG_LIBDIR)
1229                 enable_pc_files=no
1230         fi
1231 fi
1232 AC_SUBST(PKG_CONFIG_LIBDIR)
1233 ])dnl
1234 dnl ---------------------------------------------------------------------------
1235 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1236 dnl ---------------
1237 dnl Check if the rpath option should be used, setting cache variable
1238 dnl cf_cv_enable_rpath if so.
1239 AC_DEFUN([CF_ENABLE_RPATH],
1240 [
1241 AC_MSG_CHECKING(if rpath option should be used)
1242 AC_ARG_ENABLE(rpath,
1243 [  --enable-rpath          use rpath option when generating shared libraries],
1244 [cf_cv_enable_rpath=$enableval],
1245 [cf_cv_enable_rpath=no])
1246 AC_MSG_RESULT($cf_cv_enable_rpath)
1247 ])dnl
1248 dnl ---------------------------------------------------------------------------
1249 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1250 dnl --------
1251 dnl Check if 'errno' is declared in <errno.h>
1252 AC_DEFUN([CF_ERRNO],
1253 [
1254 CF_CHECK_ERRNO(errno)
1255 ])dnl
1256 dnl ---------------------------------------------------------------------------
1257 dnl CF_ETIP_DEFINES version: 3 updated: 2003/03/22 19:13:43
1258 dnl ---------------
1259 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1260 dnl math.h and builtin.h, only for ncurses
1261 AC_DEFUN([CF_ETIP_DEFINES],
1262 [
1263 AC_MSG_CHECKING(for special defines needed for etip.h)
1264 cf_save_CXXFLAGS="$CXXFLAGS"
1265 cf_result="none"
1266 for cf_math in "" MATH_H
1267 do
1268 for cf_excp in "" MATH_EXCEPTION
1269 do
1270         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -I${srcdir}/include"
1271         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1272         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1273 AC_TRY_COMPILE([
1274 #include <etip.h.in>
1275 ],[],[
1276         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1277         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1278         cf_result="$cf_math $cf_excp"
1279         break
1280 ],[])
1281 done
1282 done
1283 AC_MSG_RESULT($cf_result)
1284 CXXFLAGS="$cf_save_CXXFLAGS"
1285 ])
1286 dnl ---------------------------------------------------------------------------
1287 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
1288 dnl ---------------
1289 dnl Find a library (specifically the linkage used in the code fragment),
1290 dnl searching for it if it is not already in the library path.
1291 dnl See also CF_ADD_SEARCHPATH.
1292 dnl
1293 dnl Parameters (4-on are optional):
1294 dnl     $1 = headers for library entrypoint
1295 dnl     $2 = code fragment for library entrypoint
1296 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1297 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1298 dnl     $5 = action to perform if not successful
1299 dnl     $6 = module name, if not the same as the library name
1300 dnl     $7 = extra libraries
1301 dnl
1302 dnl Sets these variables:
1303 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1304 dnl     $cf_cv_header_path_$3 - include-directory if needed
1305 dnl     $cf_cv_library_path_$3 - library-directory if needed
1306 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1307 AC_DEFUN([CF_FIND_LINKAGE],[
1308
1309 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1310 # will be set on completion of the AC_TRY_LINK below.
1311 cf_cv_header_path_$3=
1312 cf_cv_library_path_$3=
1313
1314 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1315
1316 cf_save_LIBS="$LIBS"
1317
1318 AC_TRY_LINK([$1],[$2],[
1319         cf_cv_find_linkage_$3=yes
1320         cf_cv_header_path_$3=/usr/include
1321         cf_cv_library_path_$3=/usr/lib
1322 ],[
1323
1324 LIBS="-l$3 $7 $cf_save_LIBS"
1325
1326 AC_TRY_LINK([$1],[$2],[
1327         cf_cv_find_linkage_$3=yes
1328         cf_cv_header_path_$3=/usr/include
1329         cf_cv_library_path_$3=/usr/lib
1330         cf_cv_library_file_$3="-l$3"
1331 ],[
1332         cf_cv_find_linkage_$3=no
1333         LIBS="$cf_save_LIBS"
1334
1335     CF_VERBOSE(find linkage for $3 library)
1336     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1337
1338     cf_save_CPPFLAGS="$CPPFLAGS"
1339     cf_test_CPPFLAGS="$CPPFLAGS"
1340
1341     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1342     for cf_cv_header_path_$3 in $cf_search
1343     do
1344       if test -d $cf_cv_header_path_$3 ; then
1345         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1346         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1347         AC_TRY_COMPILE([$1],[$2],[
1348             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1349             cf_cv_find_linkage_$3=maybe
1350             cf_test_CPPFLAGS="$CPPFLAGS"
1351             break],[
1352             CPPFLAGS="$cf_save_CPPFLAGS"
1353             ])
1354       fi
1355     done
1356
1357     if test "$cf_cv_find_linkage_$3" = maybe ; then
1358
1359       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1360
1361       cf_save_LIBS="$LIBS"
1362       cf_save_LDFLAGS="$LDFLAGS"
1363
1364       ifelse([$6],,,[
1365         CPPFLAGS="$cf_test_CPPFLAGS"
1366         LIBS="-l$3 $7 $cf_save_LIBS"
1367         AC_TRY_LINK([$1],[$2],[
1368             CF_VERBOSE(... found $3 library in system)
1369             cf_cv_find_linkage_$3=yes])
1370             CPPFLAGS="$cf_save_CPPFLAGS"
1371             LIBS="$cf_save_LIBS"
1372             ])
1373
1374       if test "$cf_cv_find_linkage_$3" != yes ; then
1375         CF_LIBRARY_PATH(cf_search,$3)
1376         for cf_cv_library_path_$3 in $cf_search
1377         do
1378           if test -d $cf_cv_library_path_$3 ; then
1379             CF_VERBOSE(... testing $cf_cv_library_path_$3)
1380             CPPFLAGS="$cf_test_CPPFLAGS"
1381             LIBS="-l$3 $7 $cf_save_LIBS"
1382             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1383             AC_TRY_LINK([$1],[$2],[
1384                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1385                 cf_cv_find_linkage_$3=yes
1386                 cf_cv_library_file_$3="-l$3"
1387                 break],[
1388                 CPPFLAGS="$cf_save_CPPFLAGS"
1389                 LIBS="$cf_save_LIBS"
1390                 LDFLAGS="$cf_save_LDFLAGS"
1391                 ])
1392           fi
1393         done
1394         CPPFLAGS="$cf_save_CPPFLAGS"
1395         LDFLAGS="$cf_save_LDFLAGS"
1396       fi
1397
1398     else
1399       cf_cv_find_linkage_$3=no
1400     fi
1401     ],$7)
1402 ])
1403
1404 LIBS="$cf_save_LIBS"
1405
1406 if test "$cf_cv_find_linkage_$3" = yes ; then
1407 ifelse([$4],,[
1408         CF_ADD_INCDIR($cf_cv_header_path_$3)
1409         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1410         CF_ADD_LIB($3)
1411 ],[$4])
1412 else
1413 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1414 fi
1415 ])dnl
1416 dnl ---------------------------------------------------------------------------
1417 dnl CF_FUNC_DLSYM version: 2 updated: 2010/05/29 16:31:02
1418 dnl -------------
1419 dnl Test for dlsym() and related functions, as well as libdl.
1420 dnl
1421 dnl Sets
1422 dnl     $cf_have_dlsym
1423 dnl     $cf_have_libdl
1424 AC_DEFUN([CF_FUNC_DLSYM],[
1425 cf_have_dlsym=no
1426 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1427
1428 cf_have_libdl=no
1429 AC_CHECK_LIB(dl,dlsym,[
1430         cf_have_dlsym=yes
1431         cf_have_libdl=yes])])
1432
1433 if test "$cf_have_dlsym" = yes ; then
1434         test "$cf_have_libdl" = yes && CF_ADD_LIB(dl)
1435
1436         AC_MSG_CHECKING(whether able to link to dl*() functions)
1437         AC_TRY_LINK([#include <dlfcn.h>],[
1438                 void *obj;
1439                 if ((obj = dlopen("filename", 0)) != 0) {
1440                         if (dlsym(obj, "symbolname") == 0) {
1441                         dlclose(obj);
1442                         }
1443                 }],[
1444                 AC_DEFINE(HAVE_LIBDL)],[
1445                 AC_MSG_ERROR(Cannot link test program for libdl)])
1446         AC_MSG_RESULT(ok)
1447 else
1448         AC_MSG_ERROR(Cannot find dlsym function)
1449 fi
1450 ])
1451 dnl ---------------------------------------------------------------------------
1452 dnl CF_FUNC_MEMMOVE version: 7 updated: 2006/12/16 12:33:30
1453 dnl ---------------
1454 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1455 dnl is found, add our own version of memmove to the list of objects.
1456 AC_DEFUN([CF_FUNC_MEMMOVE],
1457 [
1458 AC_CHECK_FUNC(memmove,,[
1459 AC_CHECK_FUNC(bcopy,[
1460         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1461                 AC_TRY_RUN([
1462 int main() {
1463         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1464         char temp[40];
1465         bcopy(data, temp, sizeof(data));
1466         bcopy(temp+10, temp, 15);
1467         bcopy(temp+5, temp+15, 10);
1468         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1469 }
1470                 ],
1471                 [cf_cv_good_bcopy=yes],
1472                 [cf_cv_good_bcopy=no],
1473                 [cf_cv_good_bcopy=unknown])
1474                 ])
1475         ],[cf_cv_good_bcopy=no])
1476         if test "$cf_cv_good_bcopy" = yes ; then
1477                 AC_DEFINE(USE_OK_BCOPY)
1478         else
1479                 AC_DEFINE(USE_MY_MEMMOVE)
1480         fi
1481 ])])dnl
1482 dnl ---------------------------------------------------------------------------
1483 dnl CF_FUNC_NANOSLEEP version: 3 updated: 2006/12/16 12:33:30
1484 dnl -----------------
1485 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1486 dnl AIX 4.x, provide a non-working version.
1487 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1488 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1489 AC_TRY_RUN([
1490 #include <stdio.h>
1491 #include <errno.h>
1492 #include <time.h>
1493
1494 #ifdef HAVE_SYS_TIME_H
1495 #include <sys/time.h>
1496 #endif
1497
1498 int main() {
1499         struct timespec ts1, ts2;
1500         int code;
1501         ts1.tv_sec  = 0;
1502         ts1.tv_nsec = 750000000;
1503         ts2.tv_sec  = 0;
1504         ts2.tv_nsec = 0;
1505         errno = 0;
1506         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1507         ${cf_cv_main_return:-return}(code != 0);
1508 }
1509 ],
1510         [cf_cv_func_nanosleep=yes],
1511         [cf_cv_func_nanosleep=no],
1512         [cf_cv_func_nanosleep=unknown])])
1513
1514 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP)
1515 ])
1516 dnl ---------------------------------------------------------------------------
1517 dnl CF_FUNC_OPENPTY version: 3 updated: 2010/05/29 16:31:02
1518 dnl ---------------
1519 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1520 dnl "util" library as well.
1521 AC_DEFUN([CF_FUNC_OPENPTY],
1522 [
1523 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1524 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1525     cf_save_LIBS="$LIBS"
1526     test $cf_cv_lib_util = yes && CF_ADD_LIB(util)
1527     for cf_header in pty.h libutil.h util.h
1528     do
1529     AC_TRY_LINK([
1530 #include <$cf_header>
1531 ],[
1532     int x = openpty((int *)0, (int *)0, (char *)0,
1533                    (struct termios *)0, (struct winsize *)0);
1534 ],[
1535         cf_cv_func_openpty=$cf_header
1536         break
1537 ],[
1538         cf_cv_func_openpty=no
1539 ])
1540     done
1541     LIBS="$cf_save_LIBS"
1542 ])
1543 ])dnl
1544 dnl ---------------------------------------------------------------------------
1545 dnl CF_FUNC_POLL version: 4 updated: 2006/12/16 12:33:30
1546 dnl ------------
1547 dnl See if the poll function really works.  Some platforms have poll(), but
1548 dnl it does not work for terminals or files.
1549 AC_DEFUN([CF_FUNC_POLL],[
1550 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
1551 AC_TRY_RUN([
1552 #include <stdio.h>
1553 #ifdef HAVE_POLL_H
1554 #include <poll.h>
1555 #else
1556 #include <sys/poll.h>
1557 #endif
1558 int main() {
1559         struct pollfd myfds;
1560         int ret;
1561
1562         myfds.fd = 0;
1563         myfds.events = POLLIN;
1564
1565         ret = poll(&myfds, 1, 100);
1566         ${cf_cv_main_return:-return}(ret != 0);
1567 }],
1568         [cf_cv_working_poll=yes],
1569         [cf_cv_working_poll=no],
1570         [cf_cv_working_poll=unknown])])
1571 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL)
1572 ])dnl
1573 dnl ---------------------------------------------------------------------------
1574 dnl CF_FUNC_TERMIOS version: 2 updated: 2000/07/22 23:37:24
1575 dnl ---------------
1576 dnl Some old/broken variations define tcgetattr() only as a macro in
1577 dnl termio(s).h
1578 AC_DEFUN([CF_FUNC_TERMIOS],[
1579 AC_REQUIRE([CF_STRUCT_TERMIOS])
1580 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
1581 AC_TRY_LINK([
1582 #include <sys/types.h>
1583 #ifdef HAVE_UNISTD_H
1584 #include <unistd.h>
1585 #endif
1586 #ifdef HAVE_TERMIOS_H
1587 #include <termios.h>
1588 #define TTY struct termios
1589 #else
1590 #ifdef HAVE_TERMIO_H
1591 #include <termio.h>
1592 #define TTY struct termio
1593 #endif
1594 #endif
1595 ],[
1596 TTY foo;
1597 tcgetattr(1, &foo);],
1598 [cf_cv_have_tcgetattr=yes],
1599 [cf_cv_have_tcgetattr=no])])
1600 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR)
1601 ])dnl
1602 dnl ---------------------------------------------------------------------------
1603 dnl CF_FUNC_VSSCANF version: 3 updated: 2001/12/19 00:50:10
1604 dnl ---------------
1605 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
1606 dnl versions of C.  It is in the GNU C library, and can often be simulated by
1607 dnl other functions.
1608 AC_DEFUN([CF_FUNC_VSSCANF],
1609 [
1610 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
1611 AC_TRY_LINK([
1612 #include <stdarg.h>
1613 #include <stdio.h>],[
1614         va_list ap;
1615         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
1616 AC_TRY_LINK([
1617 #include <stdarg.h>
1618 #include <stdio.h>],[
1619     FILE strbuf;
1620     char *str = "from";
1621
1622     strbuf._flag = _IOREAD;
1623     strbuf._ptr = strbuf._base = (unsigned char *) str;
1624     strbuf._cnt = strlen(str);
1625     strbuf._file = _NFILE;
1626     return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
1627 AC_TRY_LINK([
1628 #include <stdarg.h>
1629 #include <stdio.h>],[
1630     FILE strbuf;
1631     char *str = "from";
1632
1633     strbuf._flag = _IOREAD;
1634     strbuf._ptr = strbuf._base = (unsigned char *) str;
1635     strbuf._cnt = strlen(str);
1636     strbuf._file = _NFILE;
1637     return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
1638 cf_cv_func_vsscanf=no])])])])
1639
1640 case $cf_cv_func_vsscanf in #(vi
1641 vsscanf) AC_DEFINE(HAVE_VSSCANF);; #(vi
1642 vfscanf) AC_DEFINE(HAVE_VFSCANF);; #(vi
1643 _doscan) AC_DEFINE(HAVE__DOSCAN);;
1644 esac
1645
1646 ])dnl
1647 dnl ---------------------------------------------------------------------------
1648 dnl CF_GCC_ATTRIBUTES version: 14 updated: 2010/10/23 15:52:32
1649 dnl -----------------
1650 dnl Test for availability of useful gcc __attribute__ directives to quiet
1651 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1652 dnl to documentation, unrecognized directives cause older compilers to barf.
1653 AC_DEFUN([CF_GCC_ATTRIBUTES],
1654 [
1655 if test "$GCC" = yes
1656 then
1657 cat > conftest.i <<EOF
1658 #ifndef GCC_PRINTF
1659 #define GCC_PRINTF 0
1660 #endif
1661 #ifndef GCC_SCANF
1662 #define GCC_SCANF 0
1663 #endif
1664 #ifndef GCC_NORETURN
1665 #define GCC_NORETURN /* nothing */
1666 #endif
1667 #ifndef GCC_UNUSED
1668 #define GCC_UNUSED /* nothing */
1669 #endif
1670 EOF
1671 if test "$GCC" = yes
1672 then
1673         AC_CHECKING([for $CC __attribute__ directives])
1674 cat > conftest.$ac_ext <<EOF
1675 #line __oline__ "${as_me:-configure}"
1676 #include "confdefs.h"
1677 #include "conftest.h"
1678 #include "conftest.i"
1679 #if     GCC_PRINTF
1680 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1681 #else
1682 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1683 #endif
1684 #if     GCC_SCANF
1685 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1686 #else
1687 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1688 #endif
1689 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1690 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1691 extern void foo(void) GCC_NORETURN;
1692 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1693 EOF
1694         cf_printf_attribute=no
1695         cf_scanf_attribute=no
1696         for cf_attribute in scanf printf unused noreturn
1697         do
1698                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1699                 cf_directive="__attribute__(($cf_attribute))"
1700                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1701
1702                 case $cf_attribute in #(vi
1703                 printf) #(vi
1704                         cf_printf_attribute=yes
1705                         cat >conftest.h <<EOF
1706 #define GCC_$cf_ATTRIBUTE 1
1707 EOF
1708                         ;;
1709                 scanf) #(vi
1710                         cf_scanf_attribute=yes
1711                         cat >conftest.h <<EOF
1712 #define GCC_$cf_ATTRIBUTE 1
1713 EOF
1714                         ;;
1715                 *) #(vi
1716                         cat >conftest.h <<EOF
1717 #define GCC_$cf_ATTRIBUTE $cf_directive
1718 EOF
1719                         ;;
1720                 esac
1721
1722                 if AC_TRY_EVAL(ac_compile); then
1723                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1724                         cat conftest.h >>confdefs.h
1725                         case $cf_attribute in #(vi
1726                         printf) #(vi
1727                                 if test "$cf_printf_attribute" = no ; then
1728                                         cat >>confdefs.h <<EOF
1729 #define GCC_PRINTFLIKE(fmt,var) /* nothing */
1730 EOF
1731                                 else
1732                                         cat >>confdefs.h <<EOF
1733 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1734 EOF
1735                                 fi
1736                                 ;;
1737                         scanf) #(vi
1738                                 if test "$cf_scanf_attribute" = no ; then
1739                                         cat >>confdefs.h <<EOF
1740 #define GCC_SCANFLIKE(fmt,var) /* nothing */
1741 EOF
1742                                 else
1743                                         cat >>confdefs.h <<EOF
1744 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1745 EOF
1746                                 fi
1747                                 ;;
1748                         esac
1749                 fi
1750         done
1751 else
1752         fgrep define conftest.i >>confdefs.h
1753 fi
1754 rm -rf conftest*
1755 fi
1756 ])dnl
1757 dnl ---------------------------------------------------------------------------
1758 dnl CF_GCC_VERSION version: 5 updated: 2010/04/24 11:02:31
1759 dnl --------------
1760 dnl Find version of gcc
1761 AC_DEFUN([CF_GCC_VERSION],[
1762 AC_REQUIRE([AC_PROG_CC])
1763 GCC_VERSION=none
1764 if test "$GCC" = yes ; then
1765         AC_MSG_CHECKING(version of $CC)
1766         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1767         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1768         AC_MSG_RESULT($GCC_VERSION)
1769 fi
1770 ])dnl
1771 dnl ---------------------------------------------------------------------------
1772 dnl CF_GCC_WARNINGS version: 27 updated: 2010/10/23 15:52:32
1773 dnl ---------------
1774 dnl Check if the compiler supports useful warning options.  There's a few that
1775 dnl we don't use, simply because they're too noisy:
1776 dnl
1777 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1778 dnl     -Wredundant-decls (system headers make this too noisy)
1779 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1780 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1781 dnl             is enabled for ncurses using "--enable-const".
1782 dnl     -pedantic
1783 dnl
1784 dnl Parameter:
1785 dnl     $1 is an optional list of gcc warning flags that a particular
1786 dnl             application might want to use, e.g., "no-unused" for
1787 dnl             -Wno-unused
1788 dnl Special:
1789 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1790 dnl
1791 AC_DEFUN([CF_GCC_WARNINGS],
1792 [
1793 AC_REQUIRE([CF_GCC_VERSION])
1794 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1795
1796 cat > conftest.$ac_ext <<EOF
1797 #line __oline__ "${as_me:-configure}"
1798 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1799 EOF
1800
1801 if test "$INTEL_COMPILER" = yes
1802 then
1803 # The "-wdXXX" options suppress warnings:
1804 # remark #1419: external declaration in primary source file
1805 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1806 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1807 # remark #193: zero used for undefined preprocessing identifier
1808 # remark #593: variable "curs_sb_left_arrow" was set but never used
1809 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1810 # remark #869: parameter "tw" was never referenced
1811 # remark #981: operands are evaluated in unspecified order
1812 # warning #279: controlling expression is constant
1813
1814         AC_CHECKING([for $CC warning options])
1815         cf_save_CFLAGS="$CFLAGS"
1816         EXTRA_CFLAGS="-Wall"
1817         for cf_opt in \
1818                 wd1419 \
1819                 wd1683 \
1820                 wd1684 \
1821                 wd193 \
1822                 wd593 \
1823                 wd279 \
1824                 wd810 \
1825                 wd869 \
1826                 wd981
1827         do
1828                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1829                 if AC_TRY_EVAL(ac_compile); then
1830                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1831                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1832                 fi
1833         done
1834         CFLAGS="$cf_save_CFLAGS"
1835
1836 elif test "$GCC" = yes
1837 then
1838         AC_CHECKING([for $CC warning options])
1839         cf_save_CFLAGS="$CFLAGS"
1840         EXTRA_CFLAGS=
1841         cf_warn_CONST=""
1842         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1843         for cf_opt in W Wall \
1844                 Wbad-function-cast \
1845                 Wcast-align \
1846                 Wcast-qual \
1847                 Winline \
1848                 Wmissing-declarations \
1849                 Wmissing-prototypes \
1850                 Wnested-externs \
1851                 Wpointer-arith \
1852                 Wshadow \
1853                 Wstrict-prototypes \
1854                 Wundef $cf_warn_CONST $1
1855         do
1856                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1857                 if AC_TRY_EVAL(ac_compile); then
1858                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1859                         case $cf_opt in #(vi
1860                         Wcast-qual) #(vi
1861                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1862                                 ;;
1863                         Winline) #(vi
1864                                 case $GCC_VERSION in
1865                                 [[34]].*)
1866                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1867                                         continue;;
1868                                 esac
1869                                 ;;
1870                         esac
1871                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1872                 fi
1873         done
1874         CFLAGS="$cf_save_CFLAGS"
1875 fi
1876 rm -rf conftest*
1877
1878 AC_SUBST(EXTRA_CFLAGS)
1879 ])dnl
1880 dnl ---------------------------------------------------------------------------
1881 dnl CF_GETOPT_HEADER version: 4 updated: 2009/08/31 20:07:52
1882 dnl ----------------
1883 dnl Check for getopt's variables which are commonly defined in stdlib.h,
1884 dnl unistd.h or (nonstandard) in getopt.h
1885 AC_DEFUN([CF_GETOPT_HEADER],
1886 [
1887 AC_HAVE_HEADERS(unistd.h getopt.h)
1888 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
1889 cf_cv_getopt_header=none
1890 for cf_header in stdio.h stdlib.h unistd.h getopt.h
1891 do
1892 AC_TRY_COMPILE([
1893 #include <$cf_header>],
1894 [int x = optind; char *y = optarg],
1895 [cf_cv_getopt_header=$cf_header
1896  break])
1897 done
1898 ])
1899 if test $cf_cv_getopt_header != none ; then
1900         AC_DEFINE(HAVE_GETOPT_HEADER)
1901 fi
1902 ])dnl
1903 dnl ---------------------------------------------------------------------------
1904 dnl CF_GNAT_GENERICS version: 2 updated: 2011/03/23 20:24:41
1905 dnl ----------------
1906 AC_DEFUN([CF_GNAT_GENERICS],
1907 [
1908 AC_REQUIRE([CF_GNAT_VERSION])
1909
1910 AC_MSG_CHECKING(if GNAT supports generics)
1911 case $cf_gnat_version in #(vi
1912 3.[[1-9]]*|[[4-9]].*) #(vi
1913         cf_gnat_generics=yes
1914         ;;
1915 *)
1916         cf_gnat_generics=no
1917         ;;
1918 esac
1919 AC_MSG_RESULT($cf_gnat_generics)
1920
1921 if test "$cf_gnat_generics" = yes
1922 then
1923         cf_compile_generics=generics
1924         cf_generic_objects="\${GENOBJS}"
1925 else
1926         cf_compile_generics=
1927         cf_generic_objects=
1928 fi
1929
1930 AC_SUBST(cf_compile_generics)
1931 AC_SUBST(cf_generic_objects)
1932 ])dnl
1933 dnl ---------------------------------------------------------------------------
1934 dnl CF_GNAT_PRAGMA_UNREF version: 1 updated: 2010/06/19 15:22:18
1935 dnl --------------------
1936 dnl Check if the gnat pragma "Unreferenced" works.
1937 AC_DEFUN([CF_GNAT_PRAGMA_UNREF],[
1938 AC_CACHE_CHECK(if GNAT pragma Unreferenced works,cf_cv_pragma_unreferenced,[
1939 CF_GNAT_TRY_LINK([procedure conftest;],
1940 [with Text_IO;
1941 with GNAT.OS_Lib;
1942 procedure conftest is
1943    test : Integer;
1944    pragma Unreferenced (test);
1945 begin
1946    test := 1;
1947    Text_IO.Put ("Hello World");
1948    Text_IO.New_Line;
1949    GNAT.OS_Lib.OS_Exit (0);
1950 end conftest;],
1951         [cf_cv_pragma_unreferenced=yes],
1952         [cf_cv_pragma_unreferenced=no])])
1953
1954 # if the pragma is supported, use it (needed in the Trace code).
1955 if test $cf_cv_pragma_unreferenced = yes ; then
1956         PRAGMA_UNREF=TRUE
1957 else
1958         PRAGMA_UNREF=FALSE
1959 fi
1960 AC_SUBST(PRAGMA_UNREF)
1961 ])dnl
1962 dnl ---------------------------------------------------------------------------
1963 dnl CF_GNAT_PROJECTS version: 2 updated: 2011/03/23 20:24:41
1964 dnl ----------------
1965 dnl GNAT projects are configured with ".gpr" project files.
1966 dnl GNAT libraries are a further development, using the project feature.
1967 AC_DEFUN([CF_GNAT_PROJECTS],
1968 [
1969 AC_REQUIRE([CF_GNAT_VERSION])
1970
1971 cf_gnat_libraries=no
1972 cf_gnat_projects=no
1973
1974 AC_MSG_CHECKING(if GNAT supports project files)
1975 case $cf_gnat_version in #(vi
1976 3.[[0-9]]*) #(vi
1977         ;;
1978 *)
1979         case $cf_cv_system_name in #(vi
1980         cygwin*) #(vi
1981                 ;;
1982         *)
1983                 mkdir conftest.src conftest.bin conftest.lib
1984                 cd conftest.src
1985                 rm -rf conftest* *~conftest*
1986                 cat >>library.gpr <<CF_EOF
1987 project Library is
1988   Kind := External ("LIB_KIND");
1989   for Library_Name use "ConfTest";
1990   for Object_Dir use ".";
1991   for Library_ALI_Dir use External("LIBRARY_DIR");
1992   for Library_Version use External ("SONAME");
1993   for Library_Kind use Kind;
1994   for Library_Dir use External("BUILD_DIR");
1995   Source_Dir := External ("SOURCE_DIR");
1996   for Source_Dirs use (Source_Dir);
1997   package Compiler is
1998      for Default_Switches ("Ada") use
1999        ("-g",
2000         "-O2",
2001         "-gnatafno",
2002         "-gnatVa",   -- All validity checks
2003         "-gnatwa");  -- Activate all optional errors
2004   end Compiler;
2005 end Library;
2006 CF_EOF
2007                 cat >>confpackage.ads <<CF_EOF
2008 package ConfPackage is
2009    procedure conftest;
2010 end ConfPackage;
2011 CF_EOF
2012                 cat >>confpackage.adb <<CF_EOF
2013 with Text_IO;
2014 package body ConfPackage is
2015    procedure conftest is
2016    begin
2017       Text_IO.Put ("Hello World");
2018       Text_IO.New_Line;
2019    end conftest;
2020 end ConfPackage;
2021 CF_EOF
2022                 if ( $cf_ada_make $ADAFLAGS \
2023                                 -Plibrary.gpr \
2024                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2025                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2026                                 -XSOURCE_DIR=`pwd` \
2027                                 -XSONAME=libConfTest.so.1 \
2028                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2029                         cf_gnat_projects=yes
2030                 fi
2031                 cd ..
2032                 if test -f conftest.lib/confpackage.ali
2033                 then
2034                         cf_gnat_libraries=yes
2035                 fi
2036                 rm -rf conftest* *~conftest*
2037                 ;;
2038         esac
2039         ;;
2040 esac
2041 AC_MSG_RESULT($cf_gnat_projects)
2042
2043 if test $cf_gnat_projects = yes
2044 then
2045         AC_MSG_CHECKING(if GNAT supports libraries)
2046         AC_MSG_RESULT($cf_gnat_libraries)
2047 fi
2048
2049 if test "$cf_gnat_projects" = yes
2050 then
2051         USE_OLD_MAKERULES="#"
2052         USE_GNAT_PROJECTS=""
2053 else
2054         USE_OLD_MAKERULES=""
2055         USE_GNAT_PROJECTS="#"
2056 fi
2057
2058 if test "$cf_gnat_libraries" = yes
2059 then
2060         USE_GNAT_LIBRARIES=""
2061 else
2062         USE_GNAT_LIBRARIES="#"
2063 fi
2064
2065 AC_SUBST(USE_OLD_MAKERULES)
2066 AC_SUBST(USE_GNAT_PROJECTS)
2067 AC_SUBST(USE_GNAT_LIBRARIES)
2068 ])dnl
2069 dnl ---------------------------------------------------------------------------
2070 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2071 dnl --------------
2072 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2073 dnl is noted that gnat may compile a tasking unit even for configurations which
2074 dnl fail at runtime.
2075 AC_DEFUN([CF_GNAT_SIGINT],[
2076 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2077 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2078
2079 package ConfTest is
2080
2081    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2082    pragma Unreserve_All_Interrupts;
2083    pragma Warnings (On);
2084
2085    protected Process is
2086       procedure Stop;
2087       function Continue return Boolean;
2088       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2089    private
2090       Done : Boolean := False;
2091    end Process;
2092
2093 end ConfTest;],
2094 [package body ConfTest is
2095    protected body Process is
2096       procedure Stop is
2097       begin
2098          Done := True;
2099       end Stop;
2100       function Continue return Boolean is
2101       begin
2102          return not Done;
2103       end Continue;
2104    end Process;
2105 end ConfTest;],
2106         [cf_cv_gnat_sigint=yes],
2107         [cf_cv_gnat_sigint=no])])
2108
2109 if test $cf_cv_gnat_sigint = yes ; then
2110         USE_GNAT_SIGINT=""
2111 else
2112         USE_GNAT_SIGINT="#"
2113 fi
2114 AC_SUBST(USE_GNAT_SIGINT)
2115 ])dnl
2116 dnl ---------------------------------------------------------------------------
2117 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2118 dnl ----------------
2119 dnl Verify that a test program compiles/links with GNAT.
2120 dnl $cf_ada_make is set to the program that compiles/links
2121 dnl $ADAFLAGS may be set to the GNAT flags.
2122 dnl
2123 dnl $1 is the text of the spec
2124 dnl $2 is the text of the body
2125 dnl $3 is the shell command to execute if successful
2126 dnl $4 is the shell command to execute if not successful
2127 AC_DEFUN([CF_GNAT_TRY_LINK],
2128 [
2129 rm -rf conftest* *~conftest*
2130 cat >>conftest.ads <<CF_EOF
2131 $1
2132 CF_EOF
2133 cat >>conftest.adb <<CF_EOF
2134 $2
2135 CF_EOF
2136 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2137 ifelse($3,,      :,[      $3])
2138 ifelse($4,,,[else
2139    $4])
2140 fi
2141 rm -rf conftest* *~conftest*
2142 ])dnl
2143 dnl ---------------------------------------------------------------------------
2144 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2145 dnl ---------------
2146 dnl Verify that a test program compiles and runs with GNAT
2147 dnl $cf_ada_make is set to the program that compiles/links
2148 dnl $ADAFLAGS may be set to the GNAT flags.
2149 dnl
2150 dnl $1 is the text of the spec
2151 dnl $2 is the text of the body
2152 dnl $3 is the shell command to execute if successful
2153 dnl $4 is the shell command to execute if not successful
2154 AC_DEFUN([CF_GNAT_TRY_RUN],
2155 [
2156 rm -rf conftest* *~conftest*
2157 cat >>conftest.ads <<CF_EOF
2158 $1
2159 CF_EOF
2160 cat >>conftest.adb <<CF_EOF
2161 $2
2162 CF_EOF
2163 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2164    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2165 ifelse($3,,      :,[      $3])
2166 ifelse($4,,,[   else
2167       $4])
2168    fi
2169 ifelse($4,,,[else
2170    $4])
2171 fi
2172 rm -rf conftest* *~conftest*
2173 ])dnl
2174 dnl ---------------------------------------------------------------------------
2175 dnl CF_GNAT_VERSION version: 17 updated: 2011/03/23 20:24:41
2176 dnl ---------------
2177 dnl Verify version of GNAT.
2178 AC_DEFUN([CF_GNAT_VERSION],
2179 [
2180 AC_MSG_CHECKING(for gnat version)
2181 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2182         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2183     sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2184 AC_MSG_RESULT($cf_gnat_version)
2185
2186 case $cf_gnat_version in #(vi
2187 3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*) #(vi
2188         cf_cv_prog_gnat_correct=yes
2189         ;;
2190 *)
2191         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2192         cf_cv_prog_gnat_correct=no
2193         ;;
2194 esac
2195 ])
2196 dnl ---------------------------------------------------------------------------
2197 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
2198 dnl -------------
2199 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2200 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2201 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2202 dnl since it is interwoven with GNU extensions.
2203 dnl
2204 dnl Well, yes we could work around it...
2205 AC_DEFUN([CF_GNU_SOURCE],
2206 [
2207 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2208 AC_TRY_COMPILE([#include <sys/types.h>],[
2209 #ifndef _XOPEN_SOURCE
2210 make an error
2211 #endif],
2212         [cf_cv_gnu_source=no],
2213         [cf_save="$CPPFLAGS"
2214          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2215          AC_TRY_COMPILE([#include <sys/types.h>],[
2216 #ifdef _XOPEN_SOURCE
2217 make an error
2218 #endif],
2219         [cf_cv_gnu_source=no],
2220         [cf_cv_gnu_source=yes])
2221         CPPFLAGS="$cf_save"
2222         ])
2223 ])
2224 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2225 ])dnl
2226 dnl ---------------------------------------------------------------------------
2227 dnl CF_GPP_LIBRARY version: 10 updated: 2010/05/29 16:31:02
2228 dnl --------------
2229 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2230 dnl problem :-).  If we have the compiler but no library, we'll be able to
2231 dnl configure, but won't be able to build the c++ demo program.
2232 AC_DEFUN([CF_GPP_LIBRARY],
2233 [
2234 cf_cxx_library=unknown
2235 case $cf_cv_system_name in #(vi
2236 os2*) #(vi
2237         cf_gpp_libname=gpp
2238         ;;
2239 *)
2240         cf_gpp_libname=g++
2241         ;;
2242 esac
2243 if test "$GXX" = yes; then
2244         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2245         cf_save="$LIBS"
2246         CF_ADD_LIB($cf_gpp_libname)
2247         AC_TRY_LINK([
2248 #include <$cf_gpp_libname/builtin.h>
2249         ],
2250         [two_arg_error_handler_t foo2 = lib_error_handler],
2251         [cf_cxx_library=yes
2252          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2253          if test "$cf_gpp_libname" = cpp ; then
2254             AC_DEFINE(HAVE_GPP_BUILTIN_H)
2255          else
2256             AC_DEFINE(HAVE_GXX_BUILTIN_H)
2257          fi],
2258         [AC_TRY_LINK([
2259 #include <builtin.h>
2260         ],
2261         [two_arg_error_handler_t foo2 = lib_error_handler],
2262         [cf_cxx_library=yes
2263          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2264          AC_DEFINE(HAVE_BUILTIN_H)],
2265         [cf_cxx_library=no])])
2266         LIBS="$cf_save"
2267         AC_MSG_RESULT($cf_cxx_library)
2268 fi
2269 ])dnl
2270 dnl ---------------------------------------------------------------------------
2271 dnl CF_GXX_VERSION version: 6 updated: 2010/10/23 15:44:18
2272 dnl --------------
2273 dnl Check for version of g++
2274 AC_DEFUN([CF_GXX_VERSION],[
2275 AC_REQUIRE([AC_PROG_CPP])
2276 GXX_VERSION=none
2277 if test "$GXX" = yes; then
2278         AC_MSG_CHECKING(version of g++)
2279         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2280         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2281         AC_MSG_RESULT($GXX_VERSION)
2282 fi
2283 ])dnl
2284 dnl ---------------------------------------------------------------------------
2285 dnl CF_GXX_WARNINGS version: 6 updated: 2010/08/14 18:25:37
2286 dnl ---------------
2287 dnl Check if the compiler supports useful warning options.
2288 dnl
2289 dnl Most of gcc's options apply to g++, except:
2290 dnl     -Wbad-function-cast
2291 dnl     -Wmissing-declarations
2292 dnl     -Wnested-externs
2293 dnl
2294 dnl Omit a few (for now):
2295 dnl     -Winline
2296 dnl
2297 dnl Parameter:
2298 dnl     $1 is an optional list of g++ warning flags that a particular
2299 dnl             application might want to use, e.g., "no-unused" for
2300 dnl             -Wno-unused
2301 dnl Special:
2302 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2303 dnl
2304 AC_DEFUN([CF_GXX_WARNINGS],
2305 [
2306
2307 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2308
2309 AC_REQUIRE([CF_GXX_VERSION])
2310
2311 AC_LANG_SAVE
2312 AC_LANG_CPLUSPLUS
2313
2314 cat > conftest.$ac_ext <<EOF
2315 #line __oline__ "configure"
2316 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2317 EOF
2318
2319 if test "$INTEL_CPLUSPLUS" = yes
2320 then
2321 # The "-wdXXX" options suppress warnings:
2322 # remark #1419: external declaration in primary source file
2323 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2324 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2325 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2326 # remark #193: zero used for undefined preprocessing identifier
2327 # remark #593: variable "curs_sb_left_arrow" was set but never used
2328 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2329 # remark #869: parameter "tw" was never referenced
2330 # remark #981: operands are evaluated in unspecified order
2331 # warning #269: invalid format string conversion
2332
2333         AC_CHECKING([for $CC warning options])
2334         cf_save_CXXFLAGS="$CXXFLAGS"
2335         EXTRA_CXXFLAGS="-Wall"
2336         for cf_opt in \
2337                 wd1419 \
2338                 wd1682 \
2339                 wd1683 \
2340                 wd1684 \
2341                 wd193 \
2342                 wd279 \
2343                 wd593 \
2344                 wd810 \
2345                 wd869 \
2346                 wd981
2347         do
2348                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2349                 if AC_TRY_EVAL(ac_compile); then
2350                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2351                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2352                 fi
2353         done
2354         CXXFLAGS="$cf_save_CXXFLAGS"
2355
2356 elif test "$GXX" = yes
2357 then
2358         AC_CHECKING([for $CXX warning options])
2359         cf_save_CXXFLAGS="$CXXFLAGS"
2360         EXTRA_CXXFLAGS="-W -Wall"
2361         cf_gxx_extra_warnings=""
2362         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2363         case "$GCC_VERSION" in
2364         [[1-2]].*)
2365                 ;;
2366         *)
2367                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2368                 ;;
2369         esac
2370         for cf_opt in \
2371                 Wabi \
2372                 fabi-version=0 \
2373                 Woverloaded-virtual \
2374                 Wsign-promo \
2375                 Wsynth \
2376                 Wold-style-cast \
2377                 Wcast-align \
2378                 Wcast-qual \
2379                 Wmissing-prototypes \
2380                 Wpointer-arith \
2381                 Wshadow \
2382                 Wstrict-prototypes \
2383                 Wundef $cf_gxx_extra_warnings $1
2384         do
2385                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2386                 if AC_TRY_EVAL(ac_compile); then
2387                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2388                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2389                 else
2390                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2391                 fi
2392         done
2393         CXXFLAGS="$cf_save_CXXFLAGS"
2394 fi
2395
2396 rm -rf conftest*
2397 AC_LANG_RESTORE
2398 AC_SUBST(EXTRA_CXXFLAGS)
2399 ])dnl
2400 dnl ---------------------------------------------------------------------------
2401 dnl CF_HASHED_DB version: 4 updated: 2010/05/29 16:31:02
2402 dnl ------------
2403 dnl Look for an instance of the Berkeley hashed database.
2404 dnl
2405 dnl $1 = optional parameter, to specify install-prefix for the database.
2406 AC_DEFUN([CF_HASHED_DB],
2407 [
2408 ifelse([$1],,,[
2409 case $1 in #(vi
2410 yes|*able*) #(vi
2411     ;;
2412 *)
2413     if test -d "$1" ; then
2414         CF_ADD_INCDIR($1/include)
2415         CF_ADD_LIBDIR($1/lib)
2416     fi
2417 esac
2418 ])
2419 AC_CHECK_HEADER(db.h,[
2420 CF_HASHED_DB_VERSION
2421 if test "$cf_cv_hashed_db_version" = unknown ; then
2422         AC_MSG_ERROR(Cannot determine version of db)
2423 else
2424         CF_HASHED_DB_LIBS
2425         if test "$cf_cv_hashed_db_libs" = unknown ; then
2426                 AC_MSG_ERROR(Cannot determine library for db)
2427         elif test "$cf_cv_hashed_db_libs" != default ; then
2428                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2429         fi
2430 fi
2431 ],[
2432         AC_MSG_ERROR(Cannot find db.h)
2433 ])
2434 ])dnl
2435 dnl ---------------------------------------------------------------------------
2436 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2437 dnl -----------------
2438 dnl Given that we have the header and version for hashed database, find the
2439 dnl library information.
2440 AC_DEFUN([CF_HASHED_DB_LIBS],
2441 [
2442 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2443 cf_cv_hashed_db_libs=unknown
2444 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2445 do
2446         cf_save_libs="$LIBS"
2447         if test -n "$cf_db_libs"; then
2448                 CF_ADD_LIB($cf_db_libs)
2449         fi
2450         CF_MSG_LOG(checking for library "$cf_db_libs")
2451         AC_TRY_LINK([
2452 $ac_includes_default
2453 #include <db.h>
2454 ],[
2455         char *path = "/tmp/foo";
2456 #ifdef DB_VERSION_MAJOR
2457 #if DB_VERSION_MAJOR >= 4
2458         DB *result = 0;
2459         db_create(&result, NULL, 0);
2460         result->open(result,
2461                 NULL,
2462                 path,
2463                 path,
2464                 DB_HASH,
2465                 DB_CREATE,
2466                 0644);
2467 #elif DB_VERSION_MAJOR >= 3
2468         DB *result = 0;
2469         db_create(&result, NULL, 0);
2470         result->open(result,
2471                 path,
2472                 path,
2473                 DB_HASH,
2474                 DB_CREATE,
2475                 0644);
2476 #elif DB_VERSION_MAJOR >= 2
2477         DB *result = 0;
2478         db_open(path,
2479                 DB_HASH,
2480                 DB_CREATE,
2481                 0644,
2482                 (DB_ENV *) 0,
2483                 (DB_INFO *) 0,
2484                 &result);
2485 #endif /* DB_VERSION_MAJOR */
2486 #else
2487         DB *result = dbopen(path,
2488                      2,
2489                      0644,
2490                      DB_HASH,
2491                      0);
2492 #endif
2493         ${cf_cv_main_return:-return}(result != 0)
2494 ],[
2495         if test -n "$cf_db_libs" ; then
2496                 cf_cv_hashed_db_libs=$cf_db_libs
2497         else
2498                 cf_cv_hashed_db_libs=default
2499         fi
2500         LIBS="$cf_save_libs"
2501         break
2502 ])
2503         LIBS="$cf_save_libs"
2504 done
2505 ])
2506 ])dnl
2507 dnl ---------------------------------------------------------------------------
2508 dnl CF_HASHED_DB_VERSION version: 3 updated: 2007/12/01 15:01:37
2509 dnl --------------------
2510 dnl Given that we have the header file for hashed database, find the version
2511 dnl information.
2512 AC_DEFUN([CF_HASHED_DB_VERSION],
2513 [
2514 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
2515 cf_cv_hashed_db_version=unknown
2516
2517 for cf_db_version in 1 2 3 4 5
2518 do
2519         CF_MSG_LOG(checking for db version $cf_db_version)
2520         AC_TRY_COMPILE([
2521 $ac_includes_default
2522 #include <db.h>
2523
2524 #ifdef DB_VERSION_MAJOR
2525         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
2526 #if $cf_db_version == DB_VERSION_MAJOR
2527         /* ok */
2528 #else
2529         make an error
2530 #endif
2531 #else
2532 #if $cf_db_version == 1
2533         /* ok: assuming this is DB 1.8.5 */
2534 #else
2535         make an error
2536 #endif
2537 #endif
2538 ],[DBT *foo = 0],[
2539         cf_cv_hashed_db_version=$cf_db_version
2540         break
2541         ])
2542 done
2543 ])
2544 ])dnl
2545 dnl ---------------------------------------------------------------------------
2546 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
2547 dnl --------------
2548 dnl Construct a search-list of directories for a nonstandard header-file
2549 dnl
2550 dnl Parameters
2551 dnl     $1 = the variable to return as result
2552 dnl     $2 = the package name
2553 AC_DEFUN([CF_HEADER_PATH],
2554 [
2555 $1=
2556
2557 # collect the current set of include-directories from compiler flags
2558 cf_header_path_list=""
2559 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2560         for cf_header_path in $CPPFLAGS $CFLAGS
2561         do
2562                 case $cf_header_path in #(vi
2563                 -I*)
2564                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2565                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2566                         cf_header_path_list="$cf_header_path_list [$]$1"
2567                         ;;
2568                 esac
2569         done
2570 fi
2571
2572 # add the variations for the package we are looking for
2573 CF_SUBDIR_PATH($1,$2,include)
2574
2575 test "$includedir" != NONE && \
2576 test "$includedir" != "/usr/include" && \
2577 test -d "$includedir" && {
2578         test -d $includedir &&    $1="[$]$1 $includedir"
2579         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
2580 }
2581
2582 test "$oldincludedir" != NONE && \
2583 test "$oldincludedir" != "/usr/include" && \
2584 test -d "$oldincludedir" && {
2585         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
2586         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
2587 }
2588
2589 $1="[$]$1 $cf_header_path_list"
2590 ])dnl
2591 dnl ---------------------------------------------------------------------------
2592 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
2593 dnl ---------------
2594 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2595 AC_DEFUN([CF_HELP_MESSAGE],
2596 [AC_DIVERT_HELP([$1])dnl
2597 ])dnl
2598 dnl ---------------------------------------------------------------------------
2599 dnl CF_INCLUDE_DIRS version: 6 updated: 2009/01/06 19:37:40
2600 dnl ---------------
2601 dnl Construct the list of include-options according to whether we're building
2602 dnl in the source directory or using '--srcdir=DIR' option.  If we're building
2603 dnl with gcc, don't append the includedir if it happens to be /usr/include,
2604 dnl since that usually breaks gcc's shadow-includes.
2605 AC_DEFUN([CF_INCLUDE_DIRS],
2606 [
2607 CPPFLAGS="$CPPFLAGS -I. -I../include"
2608 if test "$srcdir" != "."; then
2609         CPPFLAGS="$CPPFLAGS -I\${srcdir}/../include"
2610 fi
2611 if test "$GCC" != yes; then
2612         CPPFLAGS="$CPPFLAGS -I\${includedir}"
2613 elif test "$includedir" != "/usr/include"; then
2614         if test "$includedir" = '${prefix}/include' ; then
2615                 if test $prefix != /usr ; then
2616                         CPPFLAGS="$CPPFLAGS -I\${includedir}"
2617                 fi
2618         else
2619                 CPPFLAGS="$CPPFLAGS -I\${includedir}"
2620         fi
2621 fi
2622 AC_SUBST(CPPFLAGS)
2623 ])dnl
2624 dnl ---------------------------------------------------------------------------
2625 dnl CF_INTEL_COMPILER version: 4 updated: 2010/05/26 05:38:42
2626 dnl -----------------
2627 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2628 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2629 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2630 dnl
2631 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2632 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2633 dnl the wrappers for gcc and g++ warnings.
2634 dnl
2635 dnl $1 = GCC (default) or GXX
2636 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2637 dnl $3 = CFLAGS (default) or CXXFLAGS
2638 AC_DEFUN([CF_INTEL_COMPILER],[
2639 ifelse([$2],,INTEL_COMPILER,[$2])=no
2640
2641 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2642         case $host_os in
2643         linux*|gnu*)
2644                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2645                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2646                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2647                 AC_TRY_COMPILE([],[
2648 #ifdef __INTEL_COMPILER
2649 #else
2650 make an error
2651 #endif
2652 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2653 cf_save_CFLAGS="$cf_save_CFLAGS -we147 -no-gcc"
2654 ],[])
2655                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2656                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2657                 ;;
2658         esac
2659 fi
2660 ])dnl
2661 dnl ---------------------------------------------------------------------------
2662 dnl CF_ISASCII version: 3 updated: 2000/08/12 23:18:52
2663 dnl ----------
2664 dnl Check if we have either a function or macro for 'isascii()'.
2665 AC_DEFUN([CF_ISASCII],
2666 [
2667 AC_MSG_CHECKING(for isascii)
2668 AC_CACHE_VAL(cf_cv_have_isascii,[
2669         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
2670         [cf_cv_have_isascii=yes],
2671         [cf_cv_have_isascii=no])
2672 ])dnl
2673 AC_MSG_RESULT($cf_cv_have_isascii)
2674 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII)
2675 ])dnl
2676 dnl ---------------------------------------------------------------------------
2677 dnl CF_LARGEFILE version: 7 updated: 2007/06/02 11:58:50
2678 dnl ------------
2679 dnl Add checks for large file support.
2680 AC_DEFUN([CF_LARGEFILE],[
2681 ifdef([AC_FUNC_FSEEKO],[
2682     AC_SYS_LARGEFILE
2683     if test "$enable_largefile" != no ; then
2684         AC_FUNC_FSEEKO
2685
2686         # Normally we would collect these definitions in the config.h,
2687         # but (like _XOPEN_SOURCE), some environments rely on having these
2688         # defined before any of the system headers are included.  Another
2689         # case comes up with C++, e.g., on AIX the compiler compiles the
2690         # header files by themselves before looking at the body files it is
2691         # told to compile.  For ncurses, those header files do not include
2692         # the config.h
2693         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
2694         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
2695         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
2696
2697         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2698                 AC_TRY_COMPILE([
2699 #include <sys/types.h>
2700 #include <dirent.h>
2701                 ],[
2702                 /* if transitional largefile support is setup, this is true */
2703                 extern struct dirent64 * readdir(DIR *);
2704                 struct dirent64 *x = readdir((DIR *)0);
2705                 struct dirent *y = readdir((DIR *)0);
2706                 int z = x - y;
2707                 ],
2708                 [cf_cv_struct_dirent64=yes],
2709                 [cf_cv_struct_dirent64=no])
2710         ])
2711         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64)
2712     fi
2713 ])
2714 ])
2715 dnl ---------------------------------------------------------------------------
2716 dnl CF_LDFLAGS_STATIC version: 9 updated: 2011/07/02 15:36:04
2717 dnl -----------------
2718 dnl Check for compiler/linker flags used to temporarily force usage of static
2719 dnl libraries.  This depends on the compiler and platform.  Use this to help
2720 dnl ensure that the linker picks up a given library based on its position in
2721 dnl the list of linker options and libraries.
2722 AC_DEFUN([CF_LDFLAGS_STATIC],[
2723
2724 if test "$GCC" = yes ; then
2725         case $cf_cv_system_name in #(
2726         OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)         #( vi
2727                 LDFLAGS_STATIC=
2728                 LDFLAGS_SHARED=
2729                 ;;
2730     *)  #( normally, except when broken
2731         LDFLAGS_STATIC=-static
2732         LDFLAGS_SHARED=-dynamic
2733         ;;
2734     esac
2735 else
2736         case $cf_cv_system_name in #(
2737         aix[[4-7]]*)    #( from ld manpage
2738                 LDFLAGS_STATIC=-bstatic
2739                 LDFLAGS_SHARED=-bdynamic
2740                 ;;
2741         hpux*)          #( from ld manpage for hpux10.20, hpux11.11
2742                 # We could also use just "archive" and "shared".
2743                 LDFLAGS_STATIC=-Wl,-a,archive_shared
2744                 LDFLAGS_SHARED=-Wl,-a,shared_archive
2745                 ;;
2746         irix*)          #( from ld manpage IRIX64
2747                 LDFLAGS_STATIC=-Bstatic
2748                 LDFLAGS_SHARED=-Bdynamic
2749                 ;;
2750         osf[[45]]*)     #( from ld manpage osf4.0d, osf5.1
2751                 # alternative "-oldstyle_liblookup" (not in cc manpage)
2752                 LDFLAGS_STATIC=-noso
2753                 LDFLAGS_SHARED=-so_archive
2754                 ;;
2755         solaris2*)
2756                 LDFLAGS_STATIC=-Bstatic
2757                 LDFLAGS_SHARED=-Bdynamic
2758                 ;;
2759         esac
2760 fi
2761
2762 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
2763 then
2764         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
2765
2766         rm -f libconftest.a
2767         cat >conftest.$ac_ext <<EOF
2768 #line __oline__ "configure"
2769 #include <stdio.h>
2770 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
2771 EOF
2772         if AC_TRY_EVAL(ac_compile) ; then
2773                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
2774                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
2775         fi
2776         rm -f conftest.*
2777
2778         cf_save_LIBS="$LIBS"
2779
2780         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
2781         AC_TRY_LINK([
2782 #line __oline__ "configure"
2783 #include <stdio.h>
2784 int cf_ldflags_static(FILE *fp);
2785 ],[
2786         return cf_ldflags_static(stdin);
2787 ],[cf_ldflags_static=yes],[cf_ldflags_static=no])
2788
2789         rm -f libconftest.*
2790         LIBS="$cf_save_LIBS"
2791
2792         AC_MSG_RESULT($cf_ldflags_static)
2793
2794         if test $cf_ldflags_static != yes
2795         then
2796                 LDFLAGS_STATIC=
2797                 LDFLAGS_SHARED=
2798         fi
2799 else
2800         LDFLAGS_STATIC=
2801         LDFLAGS_SHARED=
2802 fi
2803
2804 AC_SUBST(LDFLAGS_STATIC)
2805 AC_SUBST(LDFLAGS_SHARED)
2806 ])
2807 dnl ---------------------------------------------------------------------------
2808 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
2809 dnl ---------------
2810 dnl For the given system and compiler, find the compiler flags to pass to the
2811 dnl loader to use the "rpath" feature.
2812 AC_DEFUN([CF_LD_RPATH_OPT],
2813 [
2814 AC_REQUIRE([CF_CHECK_CACHE])
2815
2816 LD_RPATH_OPT=
2817 AC_MSG_CHECKING(for an rpath option)
2818 case $cf_cv_system_name in #(vi
2819 irix*) #(vi
2820         if test "$GCC" = yes; then
2821                 LD_RPATH_OPT="-Wl,-rpath,"
2822         else
2823                 LD_RPATH_OPT="-rpath "
2824         fi
2825         ;;
2826 linux*|gnu*|k*bsd*-gnu) #(vi
2827         LD_RPATH_OPT="-Wl,-rpath,"
2828         ;;
2829 openbsd[[2-9]].*|mirbsd*) #(vi
2830         LD_RPATH_OPT="-Wl,-rpath,"
2831         ;;
2832 dragonfly*|freebsd*) #(vi
2833         LD_RPATH_OPT="-rpath "
2834         ;;
2835 netbsd*) #(vi
2836         LD_RPATH_OPT="-Wl,-rpath,"
2837         ;;
2838 osf*|mls+*) #(vi
2839         LD_RPATH_OPT="-rpath "
2840         ;;
2841 solaris2*) #(vi
2842         LD_RPATH_OPT="-R"
2843         ;;
2844 *)
2845         ;;
2846 esac
2847 AC_MSG_RESULT($LD_RPATH_OPT)
2848
2849 case "x$LD_RPATH_OPT" in #(vi
2850 x-R*)
2851         AC_MSG_CHECKING(if we need a space after rpath option)
2852         cf_save_LIBS="$LIBS"
2853         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
2854         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
2855         LIBS="$cf_save_LIBS"
2856         AC_MSG_RESULT($cf_rpath_space)
2857         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
2858         ;;
2859 esac
2860 ])dnl
2861 dnl ---------------------------------------------------------------------------
2862 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
2863 dnl ---------------
2864 dnl Construct a search-list of directories for a nonstandard library-file
2865 dnl
2866 dnl Parameters
2867 dnl     $1 = the variable to return as result
2868 dnl     $2 = the package name
2869 AC_DEFUN([CF_LIBRARY_PATH],
2870 [
2871 $1=
2872 cf_library_path_list=""
2873 if test -n "${LDFLAGS}${LIBS}" ; then
2874         for cf_library_path in $LDFLAGS $LIBS
2875         do
2876                 case $cf_library_path in #(vi
2877                 -L*)
2878                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
2879                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
2880                         cf_library_path_list="$cf_library_path_list [$]$1"
2881                         ;;
2882                 esac
2883         done
2884 fi
2885
2886 CF_SUBDIR_PATH($1,$2,lib)
2887
2888 $1="$cf_library_path_list [$]$1"
2889 ])dnl
2890 dnl ---------------------------------------------------------------------------
2891 dnl CF_LIB_PREFIX version: 8 updated: 2008/09/13 11:34:16
2892 dnl -------------
2893 dnl Compute the library-prefix for the given host system
2894 dnl $1 = variable to set
2895 AC_DEFUN([CF_LIB_PREFIX],
2896 [
2897         case $cf_cv_system_name in #(vi
2898         OS/2*|os2*) #(vi
2899         LIB_PREFIX=''
2900         ;;
2901         *)      LIB_PREFIX='lib'
2902         ;;
2903         esac
2904 ifelse($1,,,[$1=$LIB_PREFIX])
2905         AC_SUBST(LIB_PREFIX)
2906 ])dnl
2907 dnl ---------------------------------------------------------------------------
2908 dnl CF_LIB_RULES version: 61 updated: 2010/10/23 16:10:30
2909 dnl ------------
2910 dnl Append definitions and rules for the given models to the subdirectory
2911 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
2912 dnl subdirectory is a library-source directory, modify the LIBS_TO_MAKE list in
2913 dnl the corresponding makefile to list the models that we'll generate.
2914 dnl
2915 dnl For shared libraries, make a list of symbolic links to construct when
2916 dnl generating each library.  The convention used for Linux is the simplest
2917 dnl one:
2918 dnl     lib<name>.so    ->
2919 dnl     lib<name>.so.<major>    ->
2920 dnl     lib<name>.so.<maj>.<minor>
2921 AC_DEFUN([CF_LIB_RULES],
2922 [
2923 CF_LIB_PREFIX(cf_prefix)
2924 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
2925
2926 if test $cf_cv_shlib_version = cygdll ; then
2927         TINFO_NAME=$TINFO_ARG_SUFFIX
2928         TINFO_SUFFIX=.dll
2929 fi
2930
2931 if test -n "$TINFO_SUFFIX" ; then
2932         case $TINFO_SUFFIX in
2933         tw*)
2934                 TINFO_NAME="${TINFO_NAME}tw"
2935                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw//'`
2936                 ;;
2937         t*)
2938                 TINFO_NAME="${TINFO_NAME}t"
2939                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t//'`
2940                 ;;
2941         w*)
2942                 TINFO_NAME="${TINFO_NAME}w"
2943                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w//'`
2944                 ;;
2945         esac
2946 fi
2947
2948 for cf_dir in $SRC_SUBDIRS
2949 do
2950         if test ! -d $srcdir/$cf_dir ; then
2951                 continue
2952         elif test -f $srcdir/$cf_dir/modules; then
2953
2954                 SHARED_LIB=
2955                 LIBS_TO_MAKE=
2956                 for cf_item in $cf_LIST_MODELS
2957                 do
2958                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
2959                         if test $cf_item = shared ; then
2960                         if test "$cf_cv_do_symlinks" = yes ; then
2961                                 case "$cf_cv_shlib_version" in #(vi
2962                                 rel) #(vi
2963                                         case "$cf_cv_system_name" in #(vi
2964                                         darwin*)
2965                                         case .${LIB_SUFFIX} in
2966                                         .tw*)
2967                                                 cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
2968                                                 cf_suffix=tw'.${REL_VERSION}'"$cf_suffix"
2969                                                 ;;
2970                                         .t*)
2971                                                 cf_suffix=`echo $cf_suffix | sed 's/^t//'`
2972                                                 cf_suffix=t'.${REL_VERSION}'"$cf_suffix"
2973                                                 ;;
2974                                         .w*)
2975                                                 cf_suffix=`echo $cf_suffix | sed 's/^w//'`
2976                                                 cf_suffix=w'.${REL_VERSION}'"$cf_suffix"
2977                                                 ;;
2978                                         *)
2979                                                 cf_suffix='.${REL_VERSION}'"$cf_suffix"
2980                                                 ;;
2981                                         esac
2982                                         ;; #(vi
2983                                         *) cf_suffix="$cf_suffix"'.${REL_VERSION}' ;;
2984                                         esac
2985                                         ;;
2986                                 abi)
2987                                         case "$cf_cv_system_name" in #(vi
2988                                         darwin*)
2989                                         case .${LIB_SUFFIX} in
2990                                         .tw*)
2991                                                 cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
2992                                                 cf_suffix=tw'.${ABI_VERSION}'"$cf_suffix"
2993                                                 ;;
2994                                         .t*)
2995                                                 cf_suffix=`echo $cf_suffix | sed 's/^t//'`
2996                                                 cf_suffix=t'.${ABI_VERSION}'"$cf_suffix"
2997                                                 ;;
2998                                         .w*)
2999                                                 cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3000                                                 cf_suffix=w'.${ABI_VERSION}'"$cf_suffix"
3001                                                 ;;
3002                                         *)
3003                                                 cf_suffix='.${ABI_VERSION}'"$cf_suffix"
3004                                                 ;;
3005                                         esac
3006                                         ;; #(vi
3007                                         *) cf_suffix="$cf_suffix"'.${ABI_VERSION}' ;;
3008                                         esac
3009                                         ;;
3010                                 esac
3011                         fi
3012                         # cygwin needs import library, and has unique naming convention
3013                         # use autodetected ${cf_prefix} for import lib and static lib, but
3014                         # use 'cyg' prefix for shared lib.
3015                         if test $cf_cv_shlib_version = cygdll ; then
3016                                 cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3017                                 LIBS_TO_MAKE="$LIBS_TO_MAKE ../lib/cyg${cf_dir}${cf_cygsuf}"
3018                                 continue
3019                         fi
3020                         fi
3021                         LIBS_TO_MAKE="$LIBS_TO_MAKE ../lib/${cf_prefix}${cf_dir}${cf_suffix}"
3022                 done
3023
3024                 if test $cf_dir = ncurses ; then
3025                         cf_subsets="$LIB_SUBSETS"
3026                         cf_r_parts="$cf_subsets"
3027                         cf_liblist="$LIBS_TO_MAKE"
3028
3029                         while test -n "$cf_r_parts"
3030                         do
3031                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3032                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3033                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3034                                         cf_item=
3035                                         case $cf_l_parts in #(vi
3036                                         *termlib*) #(vi
3037                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3038                                                 ;;
3039                                         *ticlib*)
3040                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3041                                                 ;;
3042                                         *)
3043                                                 break
3044                                                 ;;
3045                                         esac
3046                                         if test -n "$cf_item"; then
3047                                                 LIBS_TO_MAKE="$cf_item $LIBS_TO_MAKE"
3048                                         fi
3049                                 else
3050                                         break
3051                                 fi
3052                         done
3053                 else
3054                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3055                 fi
3056
3057                 sed -e "s%@LIBS_TO_MAKE@%$LIBS_TO_MAKE%" \
3058                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3059                         $cf_dir/Makefile >$cf_dir/Makefile.out
3060                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3061
3062                 $AWK -f $srcdir/mk-0th.awk \
3063                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" \
3064                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3065
3066                 for cf_subset in $cf_subsets
3067                 do
3068                         cf_subdirs=
3069                         for cf_item in $cf_LIST_MODELS
3070                         do
3071                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3072                         CF_UPPER(cf_ITEM,$cf_item)
3073                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3074                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3075
3076                         # Test for case where we build libtinfo with a different name.
3077                         cf_libname=$cf_dir
3078                         if test $cf_dir = ncurses ; then
3079                                 case $cf_subset in
3080                                 *base*)
3081                                         cf_libname=${cf_libname}$LIB_SUFFIX
3082                                         ;;
3083                                 *termlib*)
3084                                         cf_libname=$TINFO_LIB_SUFFIX
3085                                         ;;
3086                                 ticlib*)
3087                                         cf_libname=$TICS_LIB_SUFFIX
3088                                         ;;
3089                                 esac
3090                         else
3091                                 cf_libname=${cf_libname}$LIB_SUFFIX
3092                         fi
3093                         if test -n "${DFT_ARG_SUFFIX}" ; then
3094                                 # undo $LIB_SUFFIX add-on in CF_LIB_SUFFIX
3095                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${LIB_SUFFIX}%%"`
3096                         fi
3097
3098                         # These dependencies really are for development, not
3099                         # builds, but they are useful in porting, too.
3100                         cf_depend="../include/ncurses_cfg.h"
3101                         if test "$srcdir" = "."; then
3102                                 cf_reldir="."
3103                         else
3104                                 cf_reldir="\${srcdir}"
3105                         fi
3106
3107                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3108                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3109                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3110                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3111                         fi
3112
3113                         cf_dir_suffix=
3114                         old_cf_suffix="$cf_suffix"
3115                         if test "$cf_cv_shlib_version_infix" = yes ; then
3116                         if test -n "$LIB_SUFFIX" ; then
3117                                 case $LIB_SUFFIX in
3118                                 tw*)
3119                                         cf_libname=`echo $cf_libname | sed 's/tw$//'`
3120                                         cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3121                                         cf_dir_suffix=tw
3122                                         ;;
3123                                 t*)
3124                                         cf_libname=`echo $cf_libname | sed 's/t$//'`
3125                                         cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3126                                         cf_dir_suffix=t
3127                                         ;;
3128                                 w*)
3129                                         cf_libname=`echo $cf_libname | sed 's/w$//'`
3130                                         cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3131                                         cf_dir_suffix=w
3132                                         ;;
3133                                 esac
3134                         fi
3135                         fi
3136
3137                         $AWK -f $srcdir/mk-1st.awk \
3138                                 name=${cf_libname}${cf_dir_suffix} \
3139                                 traces=$LIB_TRACING \
3140                                 MODEL=$cf_ITEM \
3141                                 model=$cf_subdir \
3142                                 prefix=$cf_prefix \
3143                                 suffix=$cf_suffix \
3144                                 subset=$cf_subset \
3145                                 SymLink="$LN_S" \
3146                                 TermlibRoot=$TINFO_NAME \
3147                                 TermlibSuffix=$TINFO_SUFFIX \
3148                                 ShlibVer=$cf_cv_shlib_version \
3149                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3150                                 ReLink=${cf_cv_do_relink:-no} \
3151                                 DoLinks=$cf_cv_do_symlinks \
3152                                 rmSoLocs=$cf_cv_rm_so_locs \
3153                                 ldconfig="$LDCONFIG" \
3154                                 overwrite=$WITH_OVERWRITE \
3155                                 depend="$cf_depend" \
3156                                 host="$host" \
3157                                 libtool_version="$LIBTOOL_VERSION" \
3158                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3159
3160                         cf_suffix="$old_cf_suffix"
3161
3162                         for cf_subdir2 in $cf_subdirs lib
3163                         do
3164                                 test $cf_subdir = $cf_subdir2 && break
3165                         done
3166                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3167                         $AWK -f $srcdir/mk-2nd.awk \
3168                                 name=$cf_dir \
3169                                 traces=$LIB_TRACING \
3170                                 MODEL=$cf_ITEM \
3171                                 model=$cf_subdir \
3172                                 subset=$cf_subset \
3173                                 srcdir=$srcdir \
3174                                 echo=$WITH_ECHO \
3175                                 crenames=$cf_cv_prog_CC_c_o \
3176                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3177                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3178                         cf_subdirs="$cf_subdirs $cf_subdir"
3179                         done
3180                 done
3181         fi
3182
3183         echo '  cd '$cf_dir' && ${MAKE} ${CF_MFLAGS} [$]@' >>Makefile
3184 done
3185
3186 for cf_dir in $SRC_SUBDIRS
3187 do
3188         if test ! -d $srcdir/$cf_dir ; then
3189                 continue
3190         fi
3191
3192         if test -f $cf_dir/Makefile ; then
3193                 case "$cf_dir" in
3194                 Ada95) #(vi
3195                         echo 'libs \' >> Makefile
3196                         echo 'install.libs \' >> Makefile
3197                         echo 'uninstall.libs ::' >> Makefile
3198                         echo '  cd '$cf_dir' && ${MAKE} ${CF_MFLAGS} [$]@' >> Makefile
3199                         ;;
3200                 esac
3201         fi
3202
3203         if test -f $srcdir/$cf_dir/modules; then
3204                 echo >> Makefile
3205                 if test -f $srcdir/$cf_dir/headers; then
3206 cat >> Makefile <<CF_EOF
3207 install.includes \\
3208 uninstall.includes \\
3209 CF_EOF
3210                 fi
3211 if test "$cf_dir" != "c++" ; then
3212 echo 'lint \' >> Makefile
3213 fi
3214 cat >> Makefile <<CF_EOF
3215 libs \\
3216 lintlib \\
3217 install.libs \\
3218 uninstall.libs \\
3219 install.$cf_dir \\
3220 uninstall.$cf_dir ::
3221         cd $cf_dir && \${MAKE} \${CF_MFLAGS} \[$]@
3222 CF_EOF
3223         elif test -f $srcdir/$cf_dir/headers; then
3224 cat >> Makefile <<CF_EOF
3225
3226 libs \\
3227 install.libs \\
3228 uninstall.libs \\
3229 install.includes \\
3230 uninstall.includes ::
3231         cd $cf_dir && \${MAKE} \${CF_MFLAGS} \[$]@
3232 CF_EOF
3233 fi
3234 done
3235
3236 cat >> Makefile <<CF_EOF
3237
3238 install.libs uninstall.libs \\
3239 install.data uninstall.data ::
3240 $MAKE_TERMINFO  cd misc && \${MAKE} \${CF_MFLAGS} \[$]@
3241 CF_EOF
3242
3243 if test "x$cf_with_manpages" = xyes; then
3244 cat >> Makefile <<CF_EOF
3245
3246 install.man \\
3247 uninstall.man ::
3248         cd man && \${MAKE} \${CF_MFLAGS} \[$]@
3249 CF_EOF
3250 fi
3251
3252 cat >> Makefile <<CF_EOF
3253
3254 distclean ::
3255         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3256         rm -f headers.sh headers.sed mk_shared_lib.sh
3257         rm -f edit_man.* man_alias.*
3258         rm -rf \${DIRS_TO_MAKE}
3259 CF_EOF
3260
3261 # Special case: tack's manpage lives in its own directory.
3262 if test "x$cf_with_manpages" = xyes; then
3263 if test -d tack ; then
3264 if test -f $srcdir/$tack.h; then
3265 cat >> Makefile <<CF_EOF
3266
3267 install.man \\
3268 uninstall.man ::
3269         cd tack && \${MAKE} \${CF_MFLAGS} \[$]@
3270 CF_EOF
3271 fi
3272 fi
3273 fi
3274
3275 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3276 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3277 dnl anything, and will make it more standardized.  It's awkward to decide this
3278 dnl at configuration because of quoting, so we'll simply make all headers
3279 dnl installed via a script that can do the right thing.
3280
3281 rm -f headers.sed headers.sh
3282
3283 dnl ( generating this script makes the makefiles a little tidier :-)
3284 echo creating headers.sh
3285 cat >headers.sh <<CF_EOF
3286 #! /bin/sh
3287 # This shell script is generated by the 'configure' script.  It is invoked in a
3288 # subdirectory of the build tree.  It generates a sed-script in the parent
3289 # directory that is used to adjust includes for header files that reside in a
3290 # subdirectory of /usr/include, etc.
3291 PRG=""
3292 while test \[$]# != 3
3293 do
3294 PRG="\$PRG \[$]1"; shift
3295 done
3296 DST=\[$]1
3297 REF=\[$]2
3298 SRC=\[$]3
3299 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3300 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3301 echo installing \$SRC in \$DST
3302 CF_EOF
3303
3304 if test $WITH_CURSES_H = yes; then
3305         cat >>headers.sh <<CF_EOF
3306 case \$DST in
3307 /*/include/*)
3308         END=\`basename \$DST\`
3309         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3310         do
3311                 NAME=\`basename \$i\`
3312                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3313         done
3314         ;;
3315 *)
3316         echo "" >> \$TMPSED
3317         ;;
3318 esac
3319 CF_EOF
3320
3321 else
3322         cat >>headers.sh <<CF_EOF
3323 case \$DST in
3324 /*/include/*)
3325         END=\`basename \$DST\`
3326         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3327         do
3328                 NAME=\`basename \$i\`
3329                 if test "\$NAME" = "curses.h"
3330                 then
3331                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3332                         NAME=ncurses.h
3333                 fi
3334                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3335         done
3336         ;;
3337 *)
3338         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3339         ;;
3340 esac
3341 CF_EOF
3342 fi
3343 cat >>headers.sh <<CF_EOF
3344 rm -f \$TMPSRC
3345 sed -f \$TMPSED \$SRC > \$TMPSRC
3346 NAME=\`basename \$SRC\`
3347 CF_EOF
3348 if test $WITH_CURSES_H != yes; then
3349         cat >>headers.sh <<CF_EOF
3350 test "\$NAME" = "curses.h" && NAME=ncurses.h
3351 CF_EOF
3352 fi
3353 cat >>headers.sh <<CF_EOF
3354 # Just in case someone gzip'd manpages, remove the conflicting copy.
3355 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3356
3357 eval \$PRG \$TMPSRC \$DST/\$NAME
3358 rm -f \$TMPSRC \$TMPSED
3359 CF_EOF
3360
3361 chmod 0755 headers.sh
3362
3363 for cf_dir in $SRC_SUBDIRS
3364 do
3365         if test ! -d $srcdir/$cf_dir ; then
3366                 continue
3367         fi
3368
3369         if test -f $srcdir/$cf_dir/headers; then
3370                 $AWK -f $srcdir/mk-hdr.awk \
3371                         subset="$LIB_SUBSETS" \
3372                         compat="$WITH_CURSES_H" \
3373                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3374         fi
3375
3376         if test -f $srcdir/$cf_dir/modules; then
3377                 if test "$cf_dir" != "c++" ; then
3378                         cat >>$cf_dir/Makefile <<"CF_EOF"
3379 depend : ${AUTO_SRC}
3380         makedepend -- ${CPPFLAGS} -- ${C_SRC}
3381
3382 # DO NOT DELETE THIS LINE -- make depend depends on it.
3383 CF_EOF
3384                 fi
3385         fi
3386 done
3387 AC_SUBST(LIBS_TO_MAKE)
3388 ])dnl
3389 dnl ---------------------------------------------------------------------------
3390 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
3391 dnl -------------
3392 dnl Find the and soname for the given shared library.  Set the cache variable
3393 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
3394 dnl variable to "unknown".
3395 dnl
3396 dnl $1 = headers
3397 dnl $2 = code
3398 dnl $3 = library name
3399 AC_DEFUN([CF_LIB_SONAME],
3400 [
3401 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
3402
3403 cf_cv_$3_soname=unknown
3404 if test "$cross_compiling" != yes ; then
3405 cat >conftest.$ac_ext <<CF_EOF
3406 $1
3407 int main()
3408 {
3409 $2
3410         ${cf_cv_main_return:-return}(0);
3411 }
3412 CF_EOF
3413 cf_save_LIBS="$LIBS"
3414         CF_ADD_LIB($3)
3415         if AC_TRY_EVAL(ac_compile) ; then
3416                 if AC_TRY_EVAL(ac_link) ; then
3417                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
3418                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
3419                 fi
3420         fi
3421 rm -rf conftest*
3422 LIBS="$cf_save_LIBS"
3423 fi
3424 ])
3425 ])
3426 dnl ---------------------------------------------------------------------------
3427 dnl CF_LIB_SUFFIX version: 17 updated: 2011/07/02 15:36:04
3428 dnl -------------
3429 dnl Compute the library file-suffix from the given model name
3430 dnl $1 = model name
3431 dnl $2 = variable to set (the nominal library suffix)
3432 dnl $3 = dependency variable to set (actual filename)
3433 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3434 AC_DEFUN([CF_LIB_SUFFIX],
3435 [
3436         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3437         case $1 in #(vi
3438         libtool) #(vi
3439                 $2='.la'
3440                 $3=[$]$2
3441                 ;;
3442         normal) #(vi
3443                 $2='.a'
3444                 $3=[$]$2
3445                 ;;
3446         debug) #(vi
3447                 $2='_g.a'
3448                 $3=[$]$2
3449                 ;;
3450         profile) #(vi
3451                 $2='_p.a'
3452                 $3=[$]$2
3453                 ;;
3454         shared) #(vi
3455                 case $cf_cv_system_name in
3456                 aix[[5-7]]*) #(vi
3457                         $2='.a'
3458                         $3=[$]$2
3459                         ;;
3460                 cygwin*) #(vi
3461                         $2='.dll'
3462                         $3='.dll.a'
3463                         ;;
3464                 darwin*) #(vi
3465                         $2='.dylib'
3466                         $3=[$]$2
3467                         ;;
3468                 hpux*) #(vi
3469                         case $target in
3470                         ia64*) #(vi
3471                                 $2='.so'
3472                                 $3=[$]$2
3473                                 ;;
3474                         *) #(vi
3475                                 $2='.sl'
3476                                 $3=[$]$2
3477                                 ;;
3478                         esac
3479                         ;;
3480                 *)      $2='.so'
3481                         $3=[$]$2
3482                         ;;
3483                 esac
3484         esac
3485         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3486         test -n "$LIB_SUFFIX" && $3="${LIB_SUFFIX}[$]{$3}"
3487 ])dnl
3488 dnl ---------------------------------------------------------------------------
3489 dnl CF_LIB_TYPE version: 4 updated: 2000/10/20 22:57:49
3490 dnl -----------
3491 dnl Compute the string to append to -library from the given model name
3492 dnl $1 = model name
3493 dnl $2 = variable to set
3494 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3495 AC_DEFUN([CF_LIB_TYPE],
3496 [
3497         case $1 in
3498         libtool) $2=''   ;;
3499         normal)  $2=''   ;;
3500         debug)   $2='_g' ;;
3501         profile) $2='_p' ;;
3502         shared)  $2=''   ;;
3503         esac
3504         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3505 ])dnl
3506 dnl ---------------------------------------------------------------------------
3507 dnl CF_LINK_DATAONLY version: 9 updated: 2009/01/01 20:21:38
3508 dnl ----------------
3509 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
3510 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
3511 dnl have to provide wrappers for global tables to ensure they're linked
3512 dnl properly.
3513 AC_DEFUN([CF_LINK_DATAONLY],
3514 [
3515 AC_MSG_CHECKING([if data-only library module links])
3516 AC_CACHE_VAL(cf_cv_link_dataonly,[
3517         rm -f conftest.a
3518         cat >conftest.$ac_ext <<EOF
3519 #line __oline__ "configure"
3520 int     testdata[[3]] = { 123, 456, 789 };
3521 EOF
3522         if AC_TRY_EVAL(ac_compile) ; then
3523                 mv conftest.o data.o && \
3524                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
3525         fi
3526         rm -f conftest.$ac_ext data.o
3527         cat >conftest.$ac_ext <<EOF
3528 #line __oline__ "configure"
3529 int     testfunc()
3530 {
3531 #if defined(NeXT)
3532         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
3533 #else
3534         extern int testdata[[3]];
3535         return testdata[[0]] == 123
3536            &&  testdata[[1]] == 456
3537            &&  testdata[[2]] == 789;
3538 #endif
3539 }
3540 EOF
3541         if AC_TRY_EVAL(ac_compile); then
3542                 mv conftest.o func.o && \
3543                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
3544         fi
3545         rm -f conftest.$ac_ext func.o
3546         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
3547         cf_saveLIBS="$LIBS"
3548         LIBS="conftest.a $LIBS"
3549         AC_TRY_RUN([
3550         int main()
3551         {
3552                 extern int testfunc();
3553                 ${cf_cv_main_return:-return} (!testfunc());
3554         }
3555         ],
3556         [cf_cv_link_dataonly=yes],
3557         [cf_cv_link_dataonly=no],
3558         [cf_cv_link_dataonly=unknown])
3559         LIBS="$cf_saveLIBS"
3560         ])
3561 AC_MSG_RESULT($cf_cv_link_dataonly)
3562
3563 if test "$cf_cv_link_dataonly" = no ; then
3564         AC_DEFINE(BROKEN_LINKER)
3565         BROKEN_LINKER=1
3566 fi
3567
3568 ])dnl
3569 dnl ---------------------------------------------------------------------------
3570 dnl CF_LINK_FUNCS version: 7 updated: 2006/12/16 12:33:30
3571 dnl -------------
3572 dnl Most Unix systems have both link and symlink, a few don't have symlink.
3573 dnl A few non-Unix systems implement symlink, but not link.
3574 dnl A few non-systems implement neither (or have nonfunctional versions).
3575 AC_DEFUN([CF_LINK_FUNCS],
3576 [
3577 AC_CHECK_FUNCS( \
3578         remove \
3579         unlink )
3580
3581 if test "$cross_compiling" = yes ; then
3582         AC_CHECK_FUNCS( \
3583                 link \
3584                 symlink )
3585 else
3586         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
3587                 cf_cv_link_funcs=
3588                 for cf_func in link symlink ; do
3589                         AC_TRY_RUN([
3590 #include <sys/types.h>
3591 #include <sys/stat.h>
3592 #ifdef HAVE_UNISTD_H
3593 #include <unistd.h>
3594 #endif
3595 int main()
3596 {
3597         int fail = 0;
3598         char *src = "config.log";
3599         char *dst = "conftest.chk";
3600         struct stat src_sb;
3601         struct stat dst_sb;
3602
3603         stat(src, &src_sb);
3604         fail = ($cf_func("config.log", "conftest.chk") < 0)
3605             || (stat(dst, &dst_sb) < 0)
3606             || (dst_sb.st_mtime != src_sb.st_mtime);
3607 #ifdef HAVE_UNLINK
3608         unlink(dst);
3609 #else
3610         remove(dst);
3611 #endif
3612         ${cf_cv_main_return:-return} (fail);
3613 }
3614                         ],[
3615                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
3616                         eval 'ac_cv_func_'$cf_func'=yes'],[
3617                         eval 'ac_cv_func_'$cf_func'=no'],[
3618                         eval 'ac_cv_func_'$cf_func'=error'])
3619                 done
3620                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
3621         ])
3622         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK)
3623         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK)
3624 fi
3625 ])dnl
3626 dnl ---------------------------------------------------------------------------
3627 dnl CF_MAIN_RETURN version: 1 updated: 2006/12/10 09:51:54
3628 dnl --------------
3629 dnl Check if a return from main to the shell actually returns the same exit
3630 dnl code.  This is true for almost any POSIX environment.
3631 dnl
3632 dnl Some very old environments did not flush stdout, etc., on an exit.  That
3633 dnl would be a useful case to test for also.
3634 AC_DEFUN([CF_MAIN_RETURN],
3635 [
3636 cf_cv_main_return=return
3637 ])dnl
3638 dnl ---------------------------------------------------------------------------
3639 dnl CF_MAKEFLAGS version: 14 updated: 2011/03/31 19:29:46
3640 dnl ------------
3641 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
3642 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
3643 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
3644 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
3645 AC_DEFUN([CF_MAKEFLAGS],
3646 [
3647 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
3648         cf_cv_makeflags=''
3649         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
3650         do
3651                 cat >cf_makeflags.tmp <<CF_EOF
3652 SHELL = /bin/sh
3653 all :
3654         @ echo '.$cf_option'
3655 CF_EOF
3656                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
3657                 case "$cf_result" in
3658                 .*k)
3659                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
3660                         case "$cf_result" in
3661                         .*CC=*) cf_cv_makeflags=
3662                                 ;;
3663                         *)      cf_cv_makeflags=$cf_option
3664                                 ;;
3665                         esac
3666                         break
3667                         ;;
3668                 .-)     ;;
3669                 *)      echo "given option \"$cf_option\", no match \"$cf_result\""
3670                         ;;
3671                 esac
3672         done
3673         rm -f cf_makeflags.tmp
3674 ])
3675
3676 AC_SUBST(cf_cv_makeflags)
3677 ])dnl
3678 dnl ---------------------------------------------------------------------------
3679 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
3680 dnl ------------
3681 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
3682 dnl a monocase filesystem.
3683 AC_DEFUN([CF_MAKE_TAGS],[
3684 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
3685
3686 AC_CHECK_PROGS(CTAGS, exctags ctags)
3687 AC_CHECK_PROGS(ETAGS, exetags etags)
3688
3689 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
3690
3691 if test "$cf_cv_mixedcase" = yes ; then
3692         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
3693 else
3694         MAKE_UPPER_TAGS=no
3695 fi
3696
3697 if test "$MAKE_UPPER_TAGS" = yes ; then
3698         MAKE_UPPER_TAGS=
3699 else
3700         MAKE_UPPER_TAGS="#"
3701 fi
3702
3703 if test "$MAKE_LOWER_TAGS" = yes ; then
3704         MAKE_LOWER_TAGS=
3705 else
3706         MAKE_LOWER_TAGS="#"
3707 fi
3708
3709 AC_SUBST(CTAGS)
3710 AC_SUBST(ETAGS)
3711
3712 AC_SUBST(MAKE_UPPER_TAGS)
3713 AC_SUBST(MAKE_LOWER_TAGS)
3714 ])dnl
3715 dnl ---------------------------------------------------------------------------
3716 dnl CF_MANPAGE_FORMAT version: 9 updated: 2010/10/23 16:10:30
3717 dnl -----------------
3718 dnl Option to allow user to override automatic configuration of manpage format.
3719 dnl There are several special cases:
3720 dnl
3721 dnl     gzip - man checks for, can display gzip'd files
3722 dnl     compress - man checks for, can display compressed files
3723 dnl     BSDI - files in the cat-directories are suffixed ".0"
3724 dnl     formatted - installer should format (put files in cat-directory)
3725 dnl     catonly - installer should only format, e.g., for a turnkey system.
3726 dnl
3727 dnl There are other configurations which this macro does not test, e.g., HPUX's
3728 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
3729 dnl convention would not match our use).
3730 AC_DEFUN([CF_MANPAGE_FORMAT],
3731 [
3732 AC_REQUIRE([CF_PATHSEP])
3733 AC_MSG_CHECKING(format of man-pages)
3734
3735 AC_ARG_WITH(manpage-format,
3736         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
3737                           optionally formatted/catonly, e.g., gzip,formatted],
3738         [MANPAGE_FORMAT=$withval],
3739         [MANPAGE_FORMAT=unknown])
3740
3741 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
3742 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
3743
3744 cf_unknown=
3745
3746 case $MANPAGE_FORMAT in
3747 unknown)
3748   if test -z "$MANPATH" ; then
3749     MANPATH="/usr/man:/usr/share/man"
3750   fi
3751
3752   # look for the 'date' man-page (it's most likely to be installed!)
3753   MANPAGE_FORMAT=
3754   cf_preform=no
3755   cf_catonly=yes
3756   cf_example=date
3757
3758   IFS="${IFS:-  }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
3759   for cf_dir in $MANPATH; do
3760     test -z "$cf_dir" && cf_dir=/usr/man
3761     for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
3762     do
3763       cf_test=`echo $cf_name | sed -e 's/*//'`
3764       if test "x$cf_test" = "x$cf_name" ; then
3765
3766         case "$cf_name" in
3767         *.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
3768         *.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
3769         *.0)    MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
3770         *)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
3771         esac
3772
3773         case "$cf_name" in
3774         $cf_dir/man*)
3775           cf_catonly=no
3776           ;;
3777         $cf_dir/cat*)
3778           cf_preform=yes
3779           ;;
3780         esac
3781         break
3782       fi
3783
3784       # if we found a match in either man* or cat*, stop looking
3785       if test -n "$MANPAGE_FORMAT" ; then
3786         cf_found=no
3787         test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
3788         test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
3789         case "$cf_name" in
3790         $cf_dir/cat*)
3791           cf_found=yes
3792           ;;
3793         esac
3794         test $cf_found=yes && break
3795       fi
3796     done
3797     # only check the first directory in $MANPATH where we find manpages
3798     if test -n "$MANPAGE_FORMAT" ; then
3799        break
3800     fi
3801   done
3802   # if we did not find the example, just assume it is normal
3803   test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
3804   IFS="$ac_save_ifs"
3805   ;;
3806 *)
3807   for cf_option in $MANPAGE_FORMAT; do
3808      case $cf_option in #(vi
3809      gzip|compress|BSDI|normal|formatted|catonly)
3810        ;;
3811      *)
3812        cf_unknown="$cf_unknown $cf_option"
3813        ;;
3814      esac
3815   done
3816   ;;
3817 esac
3818
3819 AC_MSG_RESULT($MANPAGE_FORMAT)
3820 if test -n "$cf_unknown" ; then
3821   AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
3822 fi
3823 ])dnl
3824 dnl ---------------------------------------------------------------------------
3825 dnl CF_MANPAGE_RENAMES version: 7 updated: 2005/06/18 18:51:57
3826 dnl ------------------
3827 dnl The Debian people have their own naming convention for manpages.  This
3828 dnl option lets us override the name of the file containing renaming, or
3829 dnl disable it altogether.
3830 AC_DEFUN([CF_MANPAGE_RENAMES],
3831 [
3832 AC_MSG_CHECKING(for manpage renaming)
3833
3834 AC_ARG_WITH(manpage-renames,
3835         [  --with-manpage-renames  specify manpage-renaming],
3836         [MANPAGE_RENAMES=$withval],
3837         [MANPAGE_RENAMES=yes])
3838
3839 case ".$MANPAGE_RENAMES" in #(vi
3840 .no) #(vi
3841   ;;
3842 .|.yes)
3843   # Debian 'man' program?
3844   if test -f /etc/debian_version ; then
3845     MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
3846   else
3847     MANPAGE_RENAMES=no
3848   fi
3849   ;;
3850 esac
3851
3852 if test "$MANPAGE_RENAMES" != no ; then
3853   if test -f $srcdir/man/$MANPAGE_RENAMES ; then
3854     MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
3855   elif test ! -f $MANPAGE_RENAMES ; then
3856     AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
3857   fi
3858
3859   test ! -d man && mkdir man
3860
3861   # Construct a sed-script to perform renaming within man-pages
3862   if test -n "$MANPAGE_RENAMES" ; then
3863     test ! -d man && mkdir man
3864     sh $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
3865   fi
3866 fi
3867
3868 AC_MSG_RESULT($MANPAGE_RENAMES)
3869 AC_SUBST(MANPAGE_RENAMES)
3870 ])dnl
3871 dnl ---------------------------------------------------------------------------
3872 dnl CF_MANPAGE_SYMLINKS version: 5 updated: 2010/07/24 17:12:40
3873 dnl -------------------
3874 dnl Some people expect each tool to make all aliases for manpages in the
3875 dnl man-directory.  This accommodates the older, less-capable implementations
3876 dnl of 'man', and is optional.
3877 AC_DEFUN([CF_MANPAGE_SYMLINKS],
3878 [
3879 AC_MSG_CHECKING(if manpage aliases will be installed)
3880
3881 AC_ARG_WITH(manpage-aliases,
3882         [  --with-manpage-aliases  specify manpage-aliases using .so],
3883         [MANPAGE_ALIASES=$withval],
3884         [MANPAGE_ALIASES=yes])
3885
3886 AC_MSG_RESULT($MANPAGE_ALIASES)
3887
3888 case "x$LN_S" in #(vi
3889 xln*) #(vi
3890         cf_use_symlinks=yes
3891         ;;
3892 *)
3893         cf_use_symlinks=no
3894         ;;
3895 esac
3896
3897 MANPAGE_SYMLINKS=no
3898 if test "$MANPAGE_ALIASES" = yes ; then
3899 AC_MSG_CHECKING(if manpage symlinks should be used)
3900
3901 AC_ARG_WITH(manpage-symlinks,
3902         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
3903         [MANPAGE_SYMLINKS=$withval],
3904         [MANPAGE_SYMLINKS=$cf_use_symlinks])
3905
3906 if test "$$cf_use_symlinks" = no; then
3907 if test "$MANPAGE_SYMLINKS" = yes ; then
3908         AC_MSG_WARN(cannot make symlinks, will use .so files)
3909         MANPAGE_SYMLINKS=no
3910 fi
3911 fi
3912
3913 AC_MSG_RESULT($MANPAGE_SYMLINKS)
3914 fi
3915
3916 ])dnl
3917 dnl ---------------------------------------------------------------------------
3918 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
3919 dnl --------------
3920 dnl This option causes manpages to be run through tbl(1) to generate tables
3921 dnl correctly.
3922 AC_DEFUN([CF_MANPAGE_TBL],
3923 [
3924 AC_MSG_CHECKING(for manpage tbl)
3925
3926 AC_ARG_WITH(manpage-tbl,
3927         [  --with-manpage-tbl      specify manpage processing with tbl],
3928         [MANPAGE_TBL=$withval],
3929         [MANPAGE_TBL=no])
3930
3931 AC_MSG_RESULT($MANPAGE_TBL)
3932 ])dnl
3933 dnl ---------------------------------------------------------------------------
3934 dnl CF_MAN_PAGES version: 39 updated: 2010/10/23 15:44:18
3935 dnl ------------
3936 dnl Try to determine if the man-pages on the system are compressed, and if
3937 dnl so, what format is used.  Use this information to construct a script that
3938 dnl will install man-pages.
3939 AC_DEFUN([CF_MAN_PAGES],
3940 [
3941 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
3942 CF_MANPAGE_FORMAT
3943 CF_MANPAGE_RENAMES
3944 CF_MANPAGE_SYMLINKS
3945 CF_MANPAGE_TBL
3946
3947   if test "$prefix" = "NONE" ; then
3948      cf_prefix="$ac_default_prefix"
3949   else
3950      cf_prefix="$prefix"
3951   fi
3952
3953   case "$MANPAGE_FORMAT" in # (vi
3954   *catonly*) # (vi
3955     cf_format=yes
3956     cf_inboth=no
3957     ;;
3958   *formatted*) # (vi
3959     cf_format=yes
3960     cf_inboth=yes
3961     ;;
3962   *)
3963     cf_format=no
3964     cf_inboth=no
3965     ;;
3966   esac
3967
3968 test ! -d man && mkdir man
3969
3970 cf_so_strip=
3971 cf_compress=
3972 case "$MANPAGE_FORMAT" in #(vi
3973 *compress*) #(vi
3974         cf_so_strip="Z"
3975         cf_compress=compress
3976   ;;
3977 *gzip*)
3978         cf_so_strip="gz"
3979         cf_compress=gzip
3980   ;;
3981 esac
3982
3983 cf_edit_man=./edit_man.sh
3984 cf_man_alias=`pwd`/man_alias.sed
3985
3986 cat >$cf_edit_man <<CF_EOF
3987 #! /bin/sh
3988 # this script is generated by the configure-script CF_MAN_PAGES macro.
3989
3990 prefix="$cf_prefix"
3991 datadir="$datadir"
3992
3993 NCURSES_MAJOR="$NCURSES_MAJOR"
3994 NCURSES_MINOR="$NCURSES_MINOR"
3995 NCURSES_PATCH="$NCURSES_PATCH"
3996
3997 NCURSES_OSPEED="$NCURSES_OSPEED"
3998 TERMINFO="$TERMINFO"
3999
4000 INSTALL="$INSTALL"
4001 INSTALL_DATA="$INSTALL_DATA"
4002
4003 transform="$program_transform_name"
4004
4005 TMP=\${TMPDIR:=/tmp}/man\$\$
4006 trap "rm -f \$TMP" 0 1 2 5 15
4007
4008 form=\[$]1
4009 shift || exit 1
4010
4011 verb=\[$]1
4012 shift || exit 1
4013
4014 mandir=\[$]1
4015 shift || exit 1
4016
4017 srcdir=\[$]1
4018 top_srcdir=\[$]srcdir/..
4019 shift || exit 1
4020
4021 if test "\$form" = normal ; then
4022         if test "$cf_format" = yes ; then
4023         if test "$cf_inboth" = no ; then
4024                 sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4025                 exit $?
4026         fi
4027         fi
4028         cf_subdir=\$mandir/man
4029         cf_tables=$MANPAGE_TBL
4030 else
4031         cf_subdir=\$mandir/cat
4032         cf_tables=yes
4033 fi
4034
4035 # process the list of source-files
4036 for i in \[$]* ; do
4037 case \$i in #(vi
4038 *.orig|*.rej) ;; #(vi
4039 *.[[0-9]]*)
4040         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
4041         if test \$verb = installing ; then
4042         if test ! -d \$cf_subdir\${section} ; then
4043                 mkdir -p \$cf_subdir\$section
4044         fi
4045         fi
4046
4047         # replace variables in man page
4048         if test ! -f $cf_man_alias ; then
4049 cat >>$cf_man_alias <<-CF_EOF2
4050                 s,@DATADIR@,\$datadir,g
4051                 s,@TERMINFO@,\$TERMINFO,g
4052                 s,@NCURSES_MAJOR@,\$NCURSES_MAJOR,g
4053                 s,@NCURSES_MINOR@,\$NCURSES_MINOR,g
4054                 s,@NCURSES_PATCH@,\$NCURSES_PATCH,g
4055                 s,@NCURSES_OSPEED@,\$NCURSES_OSPEED,g
4056 CF_EOF
4057         ifelse($1,,,[
4058         for cf_name in $1
4059         do
4060                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4061                 cf_name=`echo $cf_name|sed "$program_transform_name"`
4062 cat >>$cf_edit_man <<-CF_EOF
4063                 s,@$cf_NAME@,$cf_name,g
4064 CF_EOF
4065         done
4066         ])
4067 cat >>$cf_edit_man <<CF_EOF
4068 CF_EOF2
4069                 echo "...made $cf_man_alias"
4070         fi
4071
4072         aliases=
4073         cf_source=\`basename \$i\`
4074         inalias=\$cf_source
4075         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
4076         if test ! -f \$inalias ; then
4077                 echo .. skipped \$cf_source
4078                 continue
4079         fi
4080 CF_EOF
4081
4082 if test "$MANPAGE_ALIASES" != no ; then
4083 cat >>$cf_edit_man <<CF_EOF
4084         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u\`
4085 CF_EOF
4086 fi
4087
4088 if test "$MANPAGE_RENAMES" = no ; then
4089 cat >>$cf_edit_man <<CF_EOF
4090         # perform program transformations for section 1 man pages
4091         if test \$section = 1 ; then
4092                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
4093         else
4094                 cf_target=\$cf_subdir\${section}/\$cf_source
4095         fi
4096 CF_EOF
4097 else
4098 cat >>$cf_edit_man <<CF_EOF
4099         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
4100         if test -z "\$cf_target" ; then
4101                 echo '? missing rename for '\$cf_source
4102                 cf_target="\$cf_source"
4103         fi
4104         cf_target="\$cf_subdir\${section}/\${cf_target}"
4105
4106 CF_EOF
4107 fi
4108
4109 cat >>$cf_edit_man <<CF_EOF
4110         sed     -f $cf_man_alias \\
4111 CF_EOF
4112
4113 if test -f $MANPAGE_RENAMES ; then
4114 cat >>$cf_edit_man <<CF_EOF
4115                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
4116 CF_EOF
4117 else
4118 cat >>$cf_edit_man <<CF_EOF
4119                 < \$i >\$TMP
4120 CF_EOF
4121 fi
4122
4123 cat >>$cf_edit_man <<CF_EOF
4124 if test \$cf_tables = yes ; then
4125         tbl \$TMP >\$TMP.out
4126         mv \$TMP.out \$TMP
4127 fi
4128 CF_EOF
4129
4130 if test $with_curses_h != yes ; then
4131 cat >>$cf_edit_man <<CF_EOF
4132         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
4133         mv \$TMP.out \$TMP
4134 CF_EOF
4135 fi
4136
4137 cat >>$cf_edit_man <<CF_EOF
4138         if test \$form = format ; then
4139                 nroff -man \$TMP >\$TMP.out
4140                 mv \$TMP.out \$TMP
4141         fi
4142 CF_EOF
4143
4144 if test -n "$cf_compress" ; then
4145 cat >>$cf_edit_man <<CF_EOF
4146         if test \$verb = installing ; then
4147         if ( $cf_compress -f \$TMP )
4148         then
4149                 mv \$TMP.$cf_so_strip \$TMP
4150         fi
4151         fi
4152         cf_target="\$cf_target.$cf_so_strip"
4153 CF_EOF
4154 fi
4155
4156 case "$MANPAGE_FORMAT" in #(vi
4157 *BSDI*)
4158 cat >>$cf_edit_man <<CF_EOF
4159         if test \$form = format ; then
4160                 # BSDI installs only .0 suffixes in the cat directories
4161                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
4162         fi
4163 CF_EOF
4164   ;;
4165 esac
4166
4167 cat >>$cf_edit_man <<CF_EOF
4168         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
4169         if test \$verb = installing ; then
4170                 echo \$verb \$cf_target
4171                 \$INSTALL_DATA \$TMP \$cf_target
4172                 test -d \$cf_subdir\${section} &&
4173                 test -n "\$aliases" && (
4174                         cd \$cf_subdir\${section} && (
4175                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
4176                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
4177                                 cf_target=\`basename \$cf_target\`
4178                                 for cf_alias in \$aliases
4179                                 do
4180                                         if test \$section = 1 ; then
4181                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4182                                         fi
4183
4184                                         if test "$MANPAGE_SYMLINKS" = yes ; then
4185                                                 if test -f \$cf_alias\${suffix} ; then
4186                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
4187                                                         then
4188                                                                 continue
4189                                                         fi
4190                                                 fi
4191                                                 echo .. \$verb alias \$cf_alias\${suffix}
4192 CF_EOF
4193 case "x$LN_S" in #(vi
4194 *-f) #(vi
4195 cat >>$cf_edit_man <<CF_EOF
4196                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4197 CF_EOF
4198         ;;
4199 *)
4200 cat >>$cf_edit_man <<CF_EOF
4201                                                 rm -f \$cf_alias\${suffix}
4202                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4203 CF_EOF
4204         ;;
4205 esac
4206 cat >>$cf_edit_man <<CF_EOF
4207                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
4208                                                 echo ".so \$cf_source" >\$TMP
4209 CF_EOF
4210 if test -n "$cf_compress" ; then
4211 cat >>$cf_edit_man <<CF_EOF
4212                                                 if test -n "$cf_so_strip" ; then
4213                                                         $cf_compress -f \$TMP
4214                                                         mv \$TMP.$cf_so_strip \$TMP
4215                                                 fi
4216 CF_EOF
4217 fi
4218 cat >>$cf_edit_man <<CF_EOF
4219                                                 echo .. \$verb alias \$cf_alias\${suffix}
4220                                                 rm -f \$cf_alias\${suffix}
4221                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
4222                                         fi
4223                                 done
4224                         )
4225                 )
4226         elif test \$verb = removing ; then
4227                 test -f \$cf_target && (
4228                         echo \$verb \$cf_target
4229                         rm -f \$cf_target
4230                 )
4231                 test -d \$cf_subdir\${section} &&
4232                 test -n "\$aliases" && (
4233                         cd \$cf_subdir\${section} && (
4234                                 for cf_alias in \$aliases
4235                                 do
4236                                         if test \$section = 1 ; then
4237                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4238                                         fi
4239
4240                                         echo .. \$verb alias \$cf_alias\${suffix}
4241                                         rm -f \$cf_alias\${suffix}
4242                                 done
4243                         )
4244                 )
4245         else
4246 #               echo ".hy 0"
4247                 cat \$TMP
4248         fi
4249         ;;
4250 esac
4251 done
4252
4253 if test $cf_inboth = yes ; then
4254 if test \$form != format ; then
4255         sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4256 fi
4257 fi
4258
4259 exit 0
4260 CF_EOF
4261 chmod 755 $cf_edit_man
4262
4263 ])dnl
4264 dnl ---------------------------------------------------------------------------
4265 dnl CF_MATH_LIB version: 8 updated: 2010/05/29 16:31:02
4266 dnl -----------
4267 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
4268 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
4269 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
4270 AC_DEFUN([CF_MATH_LIB],
4271 [
4272 AC_CACHE_CHECK(if -lm needed for math functions,
4273         cf_cv_need_libm,[
4274         AC_TRY_LINK([
4275         #include <stdio.h>
4276         #include <math.h>
4277         ],
4278         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
4279         [cf_cv_need_libm=no],
4280         [cf_cv_need_libm=yes])])
4281 if test "$cf_cv_need_libm" = yes
4282 then
4283 ifelse($1,,[
4284         CF_ADD_LIB(m)
4285 ],[$1=-lm])
4286 fi
4287 ])
4288 dnl ---------------------------------------------------------------------------
4289 dnl CF_MIXEDCASE_FILENAMES version: 3 updated: 2003/09/20 17:07:55
4290 dnl ----------------------
4291 dnl Check if the file-system supports mixed-case filenames.  If we're able to
4292 dnl create a lowercase name and see it as uppercase, it doesn't support that.
4293 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
4294 [
4295 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
4296 if test "$cross_compiling" = yes ; then
4297         case $target_alias in #(vi
4298         *-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-mingw32*|*-uwin*) #(vi
4299                 cf_cv_mixedcase=no
4300                 ;;
4301         *)
4302                 cf_cv_mixedcase=yes
4303                 ;;
4304         esac
4305 else
4306         rm -f conftest CONFTEST
4307         echo test >conftest
4308         if test -f CONFTEST ; then
4309                 cf_cv_mixedcase=no
4310         else
4311                 cf_cv_mixedcase=yes
4312         fi
4313         rm -f conftest CONFTEST
4314 fi
4315 ])
4316 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES)
4317 ])dnl
4318 dnl ---------------------------------------------------------------------------
4319 dnl CF_MKSTEMP version: 7 updated: 2010/08/14 18:25:37
4320 dnl ----------
4321 dnl Check for a working mkstemp.  This creates two files, checks that they are
4322 dnl successfully created and distinct (AmigaOS apparently fails on the last).
4323 AC_DEFUN([CF_MKSTEMP],[
4324 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
4325 rm -rf conftest*
4326 AC_TRY_RUN([
4327 #include <sys/types.h>
4328 #include <stdlib.h>
4329 #include <stdio.h>
4330 #include <string.h>
4331 #include <sys/stat.h>
4332 int main()
4333 {
4334         char *tmpl = "conftestXXXXXX";
4335         char name[2][80];
4336         int n;
4337         int result = 0;
4338         int fd;
4339         struct stat sb;
4340
4341         umask(077);
4342         for (n = 0; n < 2; ++n) {
4343                 strcpy(name[n], tmpl);
4344                 if ((fd = mkstemp(name[n])) >= 0) {
4345                         if (!strcmp(name[n], tmpl)
4346                          || stat(name[n], &sb) != 0
4347                          || (sb.st_mode & S_IFMT) != S_IFREG
4348                          || (sb.st_mode & 077) != 0) {
4349                                 result = 1;
4350                         }
4351                         close(fd);
4352                 }
4353         }
4354         if (result == 0
4355          && !strcmp(name[0], name[1]))
4356                 result = 1;
4357         ${cf_cv_main_return:-return}(result);
4358 }
4359 ],[cf_cv_func_mkstemp=yes
4360 ],[cf_cv_func_mkstemp=no
4361 ],[AC_CHECK_FUNC(mkstemp)
4362 ])
4363 ])
4364 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
4365         AC_DEFINE(HAVE_MKSTEMP)
4366 fi
4367 ])dnl
4368 dnl ---------------------------------------------------------------------------
4369 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
4370 dnl ----------
4371 dnl Write a debug message to config.log, along with the line number in the
4372 dnl configure script.
4373 AC_DEFUN([CF_MSG_LOG],[
4374 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
4375 ])dnl
4376 dnl ---------------------------------------------------------------------------
4377 dnl CF_NCURSES_ABI_6 version: 1 updated: 2005/09/17 18:42:49
4378 dnl ----------------
4379 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
4380 dnl warn about this.
4381 AC_DEFUN([CF_NCURSES_ABI_6],[
4382 if test "${with_abi_version+set}" != set; then
4383         case $cf_cv_rel_version in
4384         5.*)
4385                 cf_cv_rel_version=6.0
4386                 cf_cv_abi_version=6
4387                 AC_MSG_WARN(Overriding ABI version to $cf_cv_abi_version)
4388                 ;;
4389         esac
4390 fi
4391 ])dnl
4392 dnl ---------------------------------------------------------------------------
4393 dnl CF_NO_LEAKS_OPTION version: 4 updated: 2006/12/16 14:24:05
4394 dnl ------------------
4395 dnl see CF_WITH_NO_LEAKS
4396 AC_DEFUN([CF_NO_LEAKS_OPTION],[
4397 AC_MSG_CHECKING(if you want to use $1 for testing)
4398 AC_ARG_WITH($1,
4399         [$2],
4400         [AC_DEFINE($3)ifelse([$4],,[
4401          $4
4402 ])
4403         : ${with_cflags:=-g}
4404         : ${with_no_leaks:=yes}
4405          with_$1=yes],
4406         [with_$1=])
4407 AC_MSG_RESULT(${with_$1:-no})
4408
4409 case .$with_cflags in #(vi
4410 .*-g*)
4411         case .$CFLAGS in #(vi
4412         .*-g*) #(vi
4413                 ;;
4414         *)
4415                 CF_ADD_CFLAGS([-g])
4416                 ;;
4417         esac
4418         ;;
4419 esac
4420 ])dnl
4421 dnl ---------------------------------------------------------------------------
4422 dnl CF_NUMBER_SYNTAX version: 1 updated: 2003/09/20 18:12:49
4423 dnl ----------------
4424 dnl Check if the given variable is a number.  If not, report an error.
4425 dnl $1 is the variable
4426 dnl $2 is the message
4427 AC_DEFUN([CF_NUMBER_SYNTAX],[
4428 if test -n "$1" ; then
4429   case $1 in #(vi
4430   [[0-9]]*) #(vi
4431         ;;
4432   *)
4433         AC_MSG_ERROR($2 is not a number: $1)
4434         ;;
4435   esac
4436 else
4437   AC_MSG_ERROR($2 value is empty)
4438 fi
4439 ])dnl
4440 dnl ---------------------------------------------------------------------------
4441 dnl CF_OBJ_SUBDIR version: 4 updated: 2002/02/23 20:38:31
4442 dnl -------------
4443 dnl Compute the object-directory name from the given model name
4444 AC_DEFUN([CF_OBJ_SUBDIR],
4445 [
4446         case $1 in
4447         libtool) $2='obj_lo'  ;;
4448         normal)  $2='objects' ;;
4449         debug)   $2='obj_g' ;;
4450         profile) $2='obj_p' ;;
4451         shared)
4452                 case $cf_cv_system_name in #(vi
4453                 cygwin) #(vi
4454                         $2='objects' ;;
4455                 *)
4456                         $2='obj_s' ;;
4457                 esac
4458         esac
4459 ])dnl
4460 dnl ---------------------------------------------------------------------------
4461 dnl CF_PATHSEP version: 5 updated: 2010/05/26 05:38:42
4462 dnl ----------
4463 dnl Provide a value for the $PATH and similar separator
4464 AC_DEFUN([CF_PATHSEP],
4465 [
4466         case $cf_cv_system_name in
4467         os2*)   PATH_SEPARATOR=';'  ;;
4468         *)      PATH_SEPARATOR=':'  ;;
4469         esac
4470 ifelse([$1],,,[$1=$PATH_SEPARATOR])
4471         AC_SUBST(PATH_SEPARATOR)
4472 ])dnl
4473 dnl ---------------------------------------------------------------------------
4474 dnl CF_PATH_SYNTAX version: 13 updated: 2010/05/26 05:38:42
4475 dnl --------------
4476 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
4477 dnl begins with one of the prefix/exec_prefix variables, and then again if the
4478 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
4479 dnl delayed evaluation of those symbols.
4480 AC_DEFUN([CF_PATH_SYNTAX],[
4481 if test "x$prefix" != xNONE; then
4482   cf_path_syntax="$prefix"
4483 else
4484   cf_path_syntax="$ac_default_prefix"
4485 fi
4486
4487 case ".[$]$1" in #(vi
4488 .\[$]\(*\)*|.\'*\'*) #(vi
4489   ;;
4490 ..|./*|.\\*) #(vi
4491   ;;
4492 .[[a-zA-Z]]:[[\\/]]*) #(vi OS/2 EMX
4493   ;;
4494 .\[$]{*prefix}*) #(vi
4495   eval $1="[$]$1"
4496   case ".[$]$1" in #(vi
4497   .NONE/*)
4498     $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4499     ;;
4500   esac
4501   ;; #(vi
4502 .no|.NONE/*)
4503   $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4504   ;;
4505 *)
4506   ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
4507   ;;
4508 esac
4509 ])dnl
4510 dnl ---------------------------------------------------------------------------
4511 dnl CF_PKG_CONFIG version: 7 updated: 2011/04/29 04:53:22
4512 dnl -------------
4513 dnl Check for the package-config program, unless disabled by command-line.
4514 AC_DEFUN([CF_PKG_CONFIG],
4515 [
4516 AC_MSG_CHECKING(if you want to use pkg-config)
4517 AC_ARG_WITH(pkg-config,
4518         [  --with-pkg-config{=path} enable/disable use of pkg-config],
4519         [cf_pkg_config=$withval],
4520         [cf_pkg_config=yes])
4521 AC_MSG_RESULT($cf_pkg_config)
4522
4523 case $cf_pkg_config in #(vi
4524 no) #(vi
4525         PKG_CONFIG=none
4526         ;;
4527 yes) #(vi
4528         CF_ACVERSION_CHECK(2.52,
4529                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
4530                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
4531         ;;
4532 *)
4533         PKG_CONFIG=$withval
4534         ;;
4535 esac
4536
4537 test -z "$PKG_CONFIG" && PKG_CONFIG=none
4538 if test "$PKG_CONFIG" != none ; then
4539         CF_PATH_SYNTAX(PKG_CONFIG)
4540 fi
4541
4542 AC_SUBST(PKG_CONFIG)
4543 ])dnl
4544 dnl ---------------------------------------------------------------------------
4545 dnl CF_POSIX_C_SOURCE version: 8 updated: 2010/05/26 05:38:42
4546 dnl -----------------
4547 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
4548 dnl
4549 dnl     POSIX.1-1990                            _POSIX_SOURCE
4550 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
4551 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
4552 dnl             Bindings Option
4553 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
4554 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
4555 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
4556 dnl
4557 dnl Parameters:
4558 dnl     $1 is the nominal value for _POSIX_C_SOURCE
4559 AC_DEFUN([CF_POSIX_C_SOURCE],
4560 [
4561 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
4562
4563 cf_save_CFLAGS="$CFLAGS"
4564 cf_save_CPPFLAGS="$CPPFLAGS"
4565
4566 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
4567 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
4568
4569 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
4570         CF_MSG_LOG(if the symbol is already defined go no further)
4571         AC_TRY_COMPILE([#include <sys/types.h>],[
4572 #ifndef _POSIX_C_SOURCE
4573 make an error
4574 #endif],
4575         [cf_cv_posix_c_source=no],
4576         [cf_want_posix_source=no
4577          case .$cf_POSIX_C_SOURCE in #(vi
4578          .[[12]]??*) #(vi
4579                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4580                 ;;
4581          .2) #(vi
4582                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4583                 cf_want_posix_source=yes
4584                 ;;
4585          .*)
4586                 cf_want_posix_source=yes
4587                 ;;
4588          esac
4589          if test "$cf_want_posix_source" = yes ; then
4590                 AC_TRY_COMPILE([#include <sys/types.h>],[
4591 #ifdef _POSIX_SOURCE
4592 make an error
4593 #endif],[],
4594                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
4595          fi
4596          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
4597          CFLAGS="$cf_trim_CFLAGS"
4598          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
4599          CF_MSG_LOG(if the second compile does not leave our definition intact error)
4600          AC_TRY_COMPILE([#include <sys/types.h>],[
4601 #ifndef _POSIX_C_SOURCE
4602 make an error
4603 #endif],,
4604          [cf_cv_posix_c_source=no])
4605          CFLAGS="$cf_save_CFLAGS"
4606          CPPFLAGS="$cf_save_CPPFLAGS"
4607         ])
4608 ])
4609
4610 if test "$cf_cv_posix_c_source" != no ; then
4611         CFLAGS="$cf_trim_CFLAGS"
4612         CPPFLAGS="$cf_trim_CPPFLAGS"
4613         CF_ADD_CFLAGS($cf_cv_posix_c_source)
4614 fi
4615
4616 ])dnl
4617 dnl ---------------------------------------------------------------------------
4618 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
4619 dnl ------------
4620 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
4621 dnl
4622 dnl $1 = symbol to test
4623 dnl $2 = value (if any) to use for a predefinition
4624 AC_DEFUN([CF_PREDEFINE],
4625 [
4626 AC_MSG_CHECKING(if we must define $1)
4627 AC_TRY_COMPILE([#include <sys/types.h>
4628 ],[
4629 #ifndef $1
4630 make an error
4631 #endif],[cf_result=no],[cf_result=yes])
4632 AC_MSG_RESULT($cf_result)
4633
4634 if test "$cf_result" = yes ; then
4635         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
4636 elif test "x$2" != "x" ; then
4637         AC_MSG_CHECKING(checking for compatible value versus $2)
4638         AC_TRY_COMPILE([#include <sys/types.h>
4639 ],[
4640 #if $1-$2 < 0
4641 make an error
4642 #endif],[cf_result=yes],[cf_result=no])
4643         AC_MSG_RESULT($cf_result)
4644         if test "$cf_result" = no ; then
4645                 # perhaps we can override it - try...
4646                 CPPFLAGS="$CPPFLAGS -D$1=$2"
4647         fi
4648 fi
4649 ])dnl
4650 dnl ---------------------------------------------------------------------------
4651 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
4652 dnl ------------
4653 dnl Append definitions and rules for the given programs to the subdirectory
4654 dnl Makefiles, and the recursion rule for the top-level Makefile.
4655 dnl
4656 dnl parameters
4657 dnl     $1 = script to run
4658 dnl     $2 = list of subdirectories
4659 dnl
4660 dnl variables
4661 dnl     $AWK
4662 AC_DEFUN([CF_PRG_RULES],
4663 [
4664 for cf_dir in $2
4665 do
4666         if test ! -d $srcdir/$cf_dir; then
4667                 continue
4668         elif test -f $srcdir/$cf_dir/programs; then
4669                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
4670         fi
4671 done
4672
4673 ])dnl
4674 dnl ---------------------------------------------------------------------------
4675 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
4676 dnl ----------
4677 dnl Check for archiver "ar".
4678 AC_DEFUN([CF_PROG_AR],[
4679 AC_CHECK_TOOL(AR, ar, ar)
4680 ])
4681 dnl ---------------------------------------------------------------------------
4682 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
4683 dnl -----------
4684 dnl Check for awk, ensure that the check found something.
4685 AC_DEFUN([CF_PROG_AWK],
4686 [
4687 AC_PROG_AWK
4688 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
4689 ])dnl
4690 dnl ---------------------------------------------------------------------------
4691 dnl CF_PROG_CC_C_O version: 3 updated: 2010/08/14 18:25:37
4692 dnl --------------
4693 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
4694 dnl the output file can be renamed, and allows for a shell variable that can
4695 dnl be used later.  The parameter is either CC or CXX.  The result is the
4696 dnl cache variable:
4697 dnl     $cf_cv_prog_CC_c_o
4698 dnl     $cf_cv_prog_CXX_c_o
4699 AC_DEFUN([CF_PROG_CC_C_O],
4700 [AC_REQUIRE([AC_PROG_CC])dnl
4701 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
4702 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
4703 [
4704 cat > conftest.$ac_ext <<CF_EOF
4705 #include <stdio.h>
4706 int main()
4707 {
4708         ${cf_cv_main_return:-return}(0);
4709 }
4710 CF_EOF
4711 # We do the test twice because some compilers refuse to overwrite an
4712 # existing .o file with -o, though they will create one.
4713 ac_try='[$]$1 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
4714 if AC_TRY_EVAL(ac_try) &&
4715   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
4716 then
4717   eval cf_cv_prog_$1_c_o=yes
4718 else
4719   eval cf_cv_prog_$1_c_o=no
4720 fi
4721 rm -rf conftest*
4722 ])dnl
4723 if test $cf_cv_prog_$1_c_o = yes; then
4724   AC_MSG_RESULT([yes])
4725 else
4726   AC_MSG_RESULT([no])
4727 fi
4728 ])dnl
4729 dnl ---------------------------------------------------------------------------
4730 dnl CF_PROG_CC_U_D version: 1 updated: 2005/07/14 16:59:30
4731 dnl --------------
4732 dnl Check if C (preprocessor) -U and -D options are processed in the order
4733 dnl given rather than by type of option.  Some compilers insist on apply all
4734 dnl of the -U options after all of the -D options.  Others allow mixing them,
4735 dnl and may predefine symbols that conflict with those we define.
4736 AC_DEFUN([CF_PROG_CC_U_D],
4737 [
4738 AC_CACHE_CHECK(if $CC -U and -D options work together,cf_cv_cc_u_d_options,[
4739         cf_save_CPPFLAGS="$CPPFLAGS"
4740         CPPFLAGS="-UU_D_OPTIONS -DU_D_OPTIONS -DD_U_OPTIONS -UD_U_OPTIONS"
4741         AC_TRY_COMPILE([],[
4742 #ifndef U_D_OPTIONS
4743 make an undefined-error
4744 #endif
4745 #ifdef  D_U_OPTIONS
4746 make a defined-error
4747 #endif
4748         ],[
4749         cf_cv_cc_u_d_options=yes],[
4750         cf_cv_cc_u_d_options=no])
4751         CPPFLAGS="$cf_save_CPPFLAGS"
4752 ])
4753 ])dnl
4754 dnl ---------------------------------------------------------------------------
4755 dnl CF_PROG_EGREP version: 1 updated: 2006/09/16 11:40:59
4756 dnl -------------
4757 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
4758 dnl This macro adds a check to ensure the script found something.
4759 AC_DEFUN([CF_PROG_EGREP],
4760 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
4761    [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
4762     then ac_cv_prog_egrep='grep -E'
4763     else ac_cv_prog_egrep='egrep'
4764     fi])
4765  EGREP=$ac_cv_prog_egrep
4766  AC_SUBST([EGREP])
4767 test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
4768 ])dnl
4769 dnl ---------------------------------------------------------------------------
4770 dnl CF_PROG_EXT version: 10 updated: 2004/01/03 19:28:18
4771 dnl -----------
4772 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
4773 AC_DEFUN([CF_PROG_EXT],
4774 [
4775 AC_REQUIRE([CF_CHECK_CACHE])
4776 case $cf_cv_system_name in
4777 os2*)
4778     CFLAGS="$CFLAGS -Zmt"
4779     CPPFLAGS="$CPPFLAGS -D__ST_MT_ERRNO__"
4780     CXXFLAGS="$CXXFLAGS -Zmt"
4781     # autoconf's macro sets -Zexe and suffix both, which conflict:w
4782     LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
4783     ac_cv_exeext=.exe
4784     ;;
4785 esac
4786
4787 AC_EXEEXT
4788 AC_OBJEXT
4789
4790 PROG_EXT="$EXEEXT"
4791 AC_SUBST(PROG_EXT)
4792 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT")
4793 ])dnl
4794 dnl ---------------------------------------------------------------------------
4795 dnl CF_PROG_GNAT version: 1 updated: 2010/06/19 15:22:18
4796 dnl ------------
4797 dnl Check for gnatmake, ensure that it is complete.
4798 AC_DEFUN([CF_PROG_GNAT],[
4799 cf_ada_make=gnatmake
4800 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
4801 if test "$ac_cv_prog_gnat_exists" = no; then
4802    cf_ada_make=
4803 else
4804    CF_GNAT_VERSION
4805    AC_CHECK_PROG(M4_exists, m4, yes, no)
4806    if test "$ac_cv_prog_M4_exists" = no; then
4807       cf_cv_prog_gnat_correct=no
4808       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
4809    fi
4810    if test "$cf_cv_prog_gnat_correct" = yes; then
4811       AC_MSG_CHECKING(if GNAT works)
4812       CF_GNAT_TRY_RUN([procedure conftest;],
4813 [with Text_IO;
4814 with GNAT.OS_Lib;
4815 procedure conftest is
4816 begin
4817    Text_IO.Put ("Hello World");
4818    Text_IO.New_Line;
4819    GNAT.OS_Lib.OS_Exit (0);
4820 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
4821       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
4822    fi
4823 fi
4824
4825 AC_SUBST(cf_ada_make)
4826 ])dnl
4827 dnl ---------------------------------------------------------------------------
4828 dnl CF_PROG_INSTALL version: 5 updated: 2002/12/21 22:46:07
4829 dnl ---------------
4830 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
4831 dnl misc/tabset install won't work properly.  Usually this happens only when
4832 dnl using the fallback mkinstalldirs script
4833 AC_DEFUN([CF_PROG_INSTALL],
4834 [AC_PROG_INSTALL
4835 case $INSTALL in
4836 /*)
4837   ;;
4838 *)
4839   CF_DIRNAME(cf_dir,$INSTALL)
4840   test -z "$cf_dir" && cf_dir=.
4841   INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
4842   ;;
4843 esac
4844 ])dnl
4845 dnl ---------------------------------------------------------------------------
4846 dnl CF_PROG_LDCONFIG version: 3 updated: 2011/06/04 20:09:13
4847 dnl ----------------
4848 dnl Check for ldconfig, needed to fixup shared libraries that would be built
4849 dnl and then used in the install.
4850 AC_DEFUN([CF_PROG_LDCONFIG],[
4851 if test "$cross_compiling" = yes ; then
4852   LDCONFIG=:
4853 else
4854 case "$cf_cv_system_name" in #(vi
4855 dragonfly*|mirbsd*|freebsd*) #(vi
4856   test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
4857   ;;
4858 *) LDPATH=$PATH:/sbin:/usr/sbin
4859   AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
4860   ;;
4861 esac
4862 fi
4863 AC_SUBST(LDCONFIG)
4864 ])dnl
4865 dnl ---------------------------------------------------------------------------
4866 dnl CF_PROG_LINT version: 2 updated: 2009/08/12 04:43:14
4867 dnl ------------
4868 AC_DEFUN([CF_PROG_LINT],
4869 [
4870 AC_CHECK_PROGS(LINT, tdlint lint alint splint lclint)
4871 AC_SUBST(LINT_OPTS)
4872 ])dnl
4873 dnl ---------------------------------------------------------------------------
4874 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
4875 dnl ------------
4876 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
4877 dnl option if it is supported.
4878 AC_DEFUN([CF_PROG_LN_S],[
4879 AC_PROG_LN_S
4880 AC_MSG_CHECKING(if $LN_S -f options work)
4881
4882 rm -f conf$$.src conf$$dst
4883 echo >conf$$.dst
4884 echo first >conf$$.src
4885 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
4886         cf_prog_ln_sf=yes
4887 else
4888         cf_prog_ln_sf=no
4889 fi
4890 rm -f conf$$.dst conf$$src
4891 AC_MSG_RESULT($cf_prog_ln_sf)
4892
4893 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
4894 ])dnl
4895 dnl ---------------------------------------------------------------------------
4896 dnl CF_REGEX version: 8 updated: 2010/08/07 14:09:44
4897 dnl --------
4898 dnl Attempt to determine if we've got one of the flavors of regular-expression
4899 dnl code that we can support.
4900 AC_DEFUN([CF_REGEX],
4901 [
4902
4903 cf_regex_func=no
4904
4905 cf_regex_libs="regex re"
4906 case $host_os in #(vi
4907 mingw*)
4908         cf_regex_libs="regex.dll $cf_regex_libs"
4909         ;;
4910 esac
4911
4912 AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
4913         for cf_regex_lib in $cf_regex_libs
4914         do
4915                 AC_CHECK_LIB($cf_regex_lib,regcomp,[
4916                                 CF_ADD_LIB($cf_regex_lib)
4917                                 cf_regex_func=regcomp
4918                                 break])
4919         done
4920 ])
4921
4922 if test "$cf_regex_func" = no ; then
4923         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
4924                 AC_CHECK_LIB(gen,compile,[
4925                                 CF_ADD_LIB(gen)
4926                                 cf_regex_func=compile])])
4927 fi
4928
4929 if test "$cf_regex_func" = no ; then
4930         AC_MSG_WARN(cannot find regular expression library)
4931 fi
4932
4933 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
4934
4935 cf_cv_regex_hdrs=no
4936 case $cf_regex_func in #(vi
4937 compile) #(vi
4938         for cf_regex_hdr in regexp.h regexpr.h
4939         do
4940                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
4941                         char *p = compile("", "", "", 0);
4942                         int x = step("", "");
4943                 ],[
4944                         cf_cv_regex_hdrs=$cf_regex_hdr
4945                         break
4946                 ])
4947         done
4948         ;;
4949 *)
4950         for cf_regex_hdr in regex.h
4951         do
4952                 AC_TRY_LINK([#include <sys/types.h>
4953 #include <$cf_regex_hdr>],[
4954                         regex_t *p;
4955                         int x = regcomp(p, "", 0);
4956                         int y = regexec(p, "", 0, 0, 0);
4957                         regfree(p);
4958                 ],[
4959                         cf_cv_regex_hdrs=$cf_regex_hdr
4960                         break
4961                 ])
4962         done
4963         ;;
4964 esac
4965
4966 ])
4967
4968 case $cf_cv_regex_hdrs in #(vi
4969     no)        AC_MSG_WARN(no regular expression header found) ;; #(vi
4970     regex.h)   AC_DEFINE(HAVE_REGEX_H_FUNCS) ;; #(vi
4971     regexp.h)  AC_DEFINE(HAVE_REGEXP_H_FUNCS) ;; #(vi
4972     regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS) ;;
4973 esac
4974 ])dnl
4975 dnl ---------------------------------------------------------------------------
4976 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
4977 dnl ----------------
4978 dnl Remove all -U and -D options that refer to the given symbol from a list
4979 dnl of C compiler options.  This works around the problem that not all
4980 dnl compilers process -U and -D options from left-to-right, so a -U option
4981 dnl cannot be used to cancel the effect of a preceding -D option.
4982 dnl
4983 dnl $1 = target (which could be the same as the source variable)
4984 dnl $2 = source (including '$')
4985 dnl $3 = symbol to remove
4986 define([CF_REMOVE_DEFINE],
4987 [
4988 $1=`echo "$2" | \
4989         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
4990                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
4991 ])dnl
4992 dnl ---------------------------------------------------------------------------
4993 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
4994 dnl -------------
4995 dnl Remove the given library from the symbol
4996 dnl
4997 dnl $1 = target (which could be the same as the source variable)
4998 dnl $2 = source (including '$')
4999 dnl $3 = library to remove
5000 define([CF_REMOVE_LIB],
5001 [
5002 # remove $3 library from $2
5003 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
5004 ])dnl
5005 dnl ---------------------------------------------------------------------------
5006 dnl CF_RPATH_HACK version: 9 updated: 2011/02/13 13:31:33
5007 dnl -------------
5008 AC_DEFUN([CF_RPATH_HACK],
5009 [
5010 AC_REQUIRE([CF_LD_RPATH_OPT])
5011 AC_MSG_CHECKING(for updated LDFLAGS)
5012 if test -n "$LD_RPATH_OPT" ; then
5013         AC_MSG_RESULT(maybe)
5014
5015         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
5016         cf_rpath_list="/usr/lib /lib"
5017         if test "$cf_ldd_prog" != no
5018         then
5019                 cf_rpath_oops=
5020
5021 AC_TRY_LINK([#include <stdio.h>],
5022                 [printf("Hello");],
5023                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort -u`
5024                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort -u`])
5025
5026                 # If we passed the link-test, but get a "not found" on a given library,
5027                 # this could be due to inept reconfiguration of gcc to make it only
5028                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
5029                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
5030                 # /usr/local libraries.
5031                 if test -n "$cf_rpath_oops"
5032                 then
5033                         for cf_rpath_src in $cf_rpath_oops
5034                         do
5035                                 for cf_rpath_dir in \
5036                                         /usr/local \
5037                                         /usr/pkg \
5038                                         /opt/sfw
5039                                 do
5040                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
5041                                         then
5042                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
5043                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
5044                                                 break
5045                                         fi
5046                                 done
5047                         done
5048                 fi
5049         fi
5050
5051         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5052
5053         CF_RPATH_HACK_2(LDFLAGS)
5054         CF_RPATH_HACK_2(LIBS)
5055
5056         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5057 fi
5058 AC_SUBST(EXTRA_LDFLAGS)
5059 ])dnl
5060 dnl ---------------------------------------------------------------------------
5061 dnl CF_RPATH_HACK_2 version: 6 updated: 2010/04/17 16:31:24
5062 dnl ---------------
5063 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
5064 dnl EXTRA_LDFLAGS for each -L option found.
5065 dnl
5066 dnl $cf_rpath_list contains a list of directories to ignore.
5067 dnl
5068 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
5069 dnl      but LIBS often has misplaced -L options.
5070 AC_DEFUN([CF_RPATH_HACK_2],
5071 [
5072 CF_VERBOSE(...checking $1 [$]$1)
5073
5074 cf_rpath_dst=
5075 for cf_rpath_src in [$]$1
5076 do
5077         case $cf_rpath_src in #(vi
5078         -L*) #(vi
5079
5080                 # check if this refers to a directory which we will ignore
5081                 cf_rpath_skip=no
5082                 if test -n "$cf_rpath_list"
5083                 then
5084                         for cf_rpath_item in $cf_rpath_list
5085                         do
5086                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
5087                                 then
5088                                         cf_rpath_skip=yes
5089                                         break
5090                                 fi
5091                         done
5092                 fi
5093
5094                 if test "$cf_rpath_skip" = no
5095                 then
5096                         # transform the option
5097                         if test "$LD_RPATH_OPT" = "-R " ; then
5098                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
5099                         else
5100                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
5101                         fi
5102
5103                         # if we have not already added this, add it now
5104                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
5105                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
5106                         then
5107                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
5108                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
5109                         fi
5110                 fi
5111                 ;;
5112         esac
5113         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
5114 done
5115 $1=$cf_rpath_dst
5116
5117 CF_VERBOSE(...checked $1 [$]$1)
5118 AC_SUBST(EXTRA_LDFLAGS)
5119 ])dnl
5120 dnl ---------------------------------------------------------------------------
5121 dnl CF_SHARED_OPTS version: 68 updated: 2011/07/17 14:48:41
5122 dnl --------------
5123 dnl --------------
5124 dnl Attempt to determine the appropriate CC/LD options for creating a shared
5125 dnl library.
5126 dnl
5127 dnl Note: ${LOCAL_LDFLAGS} is used to link executables that will run within the
5128 dnl build-tree, i.e., by making use of the libraries that are compiled in ../lib
5129 dnl We avoid compiling-in a ../lib path for the shared library since that can
5130 dnl lead to unexpected results at runtime.
5131 dnl ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared libraries
5132 dnl are compiled in ../../lib
5133 dnl
5134 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
5135 dnl to install symbolic links to the rel/abi versions of shared libraries.
5136 dnl
5137 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
5138 dnl version when making symbolic links.
5139 dnl
5140 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
5141 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
5142 dnl (ex: libncurses.so.<ver>).
5143 dnl
5144 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
5145 AC_DEFUN([CF_SHARED_OPTS],
5146 [
5147         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
5148         AC_REQUIRE([CF_LD_RPATH_OPT])
5149         LOCAL_LDFLAGS=
5150         LOCAL_LDFLAGS2=
5151         LD_SHARED_OPTS=
5152         INSTALL_LIB="-m 644"
5153
5154         cf_cv_do_symlinks=no
5155         cf_ld_rpath_opt=
5156         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
5157
5158         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
5159         AC_ARG_WITH(shlib-version,
5160         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
5161         [test -z "$withval" && withval=auto
5162         case $withval in #(vi
5163         yes) #(vi
5164                 cf_cv_shlib_version=auto
5165                 ;;
5166         rel|abi|auto|no) #(vi
5167                 cf_cv_shlib_version=$withval
5168                 ;;
5169         *)
5170                 AC_MSG_ERROR([option value must be one of: rel, abi, auto or no])
5171                 ;;
5172         esac
5173         ],[cf_cv_shlib_version=auto])
5174         AC_MSG_RESULT($cf_cv_shlib_version)
5175
5176         cf_cv_rm_so_locs=no
5177
5178         # Some less-capable ports of gcc support only -fpic
5179         CC_SHARED_OPTS=
5180         if test "$GCC" = yes
5181         then
5182                 AC_MSG_CHECKING(which $CC option to use)
5183                 cf_save_CFLAGS="$CFLAGS"
5184                 for CC_SHARED_OPTS in -fPIC -fpic ''
5185                 do
5186                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
5187                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
5188                 done
5189                 AC_MSG_RESULT($CC_SHARED_OPTS)
5190                 CFLAGS="$cf_save_CFLAGS"
5191         fi
5192
5193         cf_cv_shlib_version_infix=no
5194
5195         case $cf_cv_system_name in #(vi
5196         aix4.[3-9]*|aix[[5-7]]*) #(vi
5197                 if test "$GCC" = yes; then
5198                         CC_SHARED_OPTS=
5199                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${libdir}:/usr/lib -o [$]@'
5200                 else
5201                         # CC_SHARED_OPTS='-qpic=large -G'
5202                         # perhaps "-bM:SRE -bnoentry -bexpall"
5203                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${libdir}:/usr/lib -o [$]@'
5204                 fi
5205                 ;;
5206         beos*) #(vi
5207                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
5208                 ;;
5209         cygwin*) #(vi
5210                 CC_SHARED_OPTS=
5211                 MK_SHARED_LIB='sh ../mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5212                 cf_cv_shlib_version=cygdll
5213                 cf_cv_shlib_version_infix=cygdll
5214                 cat >mk_shared_lib.sh <<-CF_EOF
5215                 #!/bin/sh
5216                 SHARED_LIB=\[$]1
5217                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5218                 shift
5219                 cat <<-EOF
5220                 Linking shared library
5221                 ** SHARED_LIB \[$]SHARED_LIB
5222                 ** IMPORT_LIB \[$]IMPORT_LIB
5223 EOF
5224                 exec \[$]* -shared -Wl,--out-implib=../lib/\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o ../lib/\[$]{SHARED_LIB}
5225 CF_EOF
5226                 chmod +x mk_shared_lib.sh
5227                 ;;
5228         darwin*) #(vi
5229                 EXTRA_CFLAGS="-no-cpp-precomp"
5230                 CC_SHARED_OPTS="-dynamic"
5231                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
5232                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
5233                 cf_cv_shlib_version_infix=yes
5234                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
5235                         cf_save_LDFLAGS=$LDFLAGS
5236                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5237                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
5238                                 LDFLAGS=$cf_save_LDFLAGS])
5239                 if test $cf_cv_ldflags_search_paths_first = yes; then
5240                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5241                 fi
5242                 ;;
5243         hpux*) #(vi
5244                 # (tested with gcc 2.7.2 -- I don't have c89)
5245                 if test "$GCC" = yes; then
5246                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
5247                 else
5248                         CC_SHARED_OPTS='+Z'
5249                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
5250                 fi
5251                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
5252                 # HP-UX shared libraries must be executable, and should be
5253                 # readonly to exploit a quirk in the memory manager.
5254                 INSTALL_LIB="-m 555"
5255                 ;;
5256         interix*)
5257                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5258                 if test "$cf_cv_shlib_version" = rel; then
5259                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
5260                 else
5261                         cf_shared_soname='`basename $@`'
5262                 fi
5263                 CC_SHARED_OPTS=
5264                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${libdir} -Wl,-h,'$cf_shared_soname' -o $@'
5265                 ;;
5266         irix*) #(vi
5267                 if test "$cf_cv_enable_rpath" = yes ; then
5268                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${libdir} $EXTRA_LDFLAGS"
5269                 fi
5270                 # tested with IRIX 5.2 and 'cc'.
5271                 if test "$GCC" != yes; then
5272                         CC_SHARED_OPTS='-KPIC'
5273                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
5274                 else
5275                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
5276                 fi
5277                 cf_cv_rm_so_locs=yes
5278                 ;;
5279         linux*|gnu*|k*bsd*-gnu) #(vi
5280                 if test "$DFT_LWR_MODEL" = "shared" ; then
5281                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5282                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5283                 fi
5284                 if test "$cf_cv_enable_rpath" = yes ; then
5285                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${libdir} $EXTRA_LDFLAGS"
5286                 fi
5287                 CF_SHARED_SONAME
5288                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5289                 ;;
5290         openbsd[[2-9]].*|mirbsd*) #(vi
5291                 if test "$DFT_LWR_MODEL" = "shared" ; then
5292                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5293                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5294                 fi
5295                 if test "$cf_cv_enable_rpath" = yes ; then
5296                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${libdir} $EXTRA_LDFLAGS"
5297                 fi
5298                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5299                 CF_SHARED_SONAME
5300                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5301                 ;;
5302         nto-qnx*|openbsd*|freebsd[[12]].*) #(vi
5303                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5304                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
5305                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5306                 ;;
5307         dragonfly*|freebsd*) #(vi
5308                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5309                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5310                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5311                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${libdir} $LOCAL_LDFLAGS"
5312                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${libdir} $EXTRA_LDFLAGS"
5313                 fi
5314                 CF_SHARED_SONAME
5315                 MK_SHARED_LIB='${LD} -shared -Bshareable -soname=`basename $[@]` -o $[@]'
5316                 ;;
5317         netbsd*) #(vi
5318                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5319                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5320                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5321                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5322                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${libdir} $EXTRA_LDFLAGS"
5323                         if test "$cf_cv_shlib_version" = auto; then
5324                         if test -f /usr/libexec/ld.elf_so; then
5325                                 cf_cv_shlib_version=abi
5326                         else
5327                                 cf_cv_shlib_version=rel
5328                         fi
5329                         fi
5330                         CF_SHARED_SONAME
5331                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
5332                 else
5333                         MK_SHARED_LIB='${LD} -shared -Bshareable -o $[@]'
5334                 fi
5335                 ;;
5336         osf*|mls+*) #(vi
5337                 # tested with OSF/1 V3.2 and 'cc'
5338                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
5339                 # link with shared libs).
5340                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
5341                 case $host_os in #(vi
5342                 osf4*)
5343                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
5344                         ;;
5345                 esac
5346                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
5347                 if test "$DFT_LWR_MODEL" = "shared" ; then
5348                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5349                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5350                 fi
5351                 cf_cv_rm_so_locs=yes
5352                 ;;
5353         sco3.2v5*)  # (also uw2* and UW7: hops 13-Apr-98
5354                 # tested with osr5.0.5
5355                 if test "$GCC" != yes; then
5356                         CC_SHARED_OPTS='-belf -KPIC'
5357                 fi
5358                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
5359                 if test "$cf_cv_enable_rpath" = yes ; then
5360                         # only way is to set LD_RUN_PATH but no switch for it
5361                         RUN_PATH=$libdir
5362                 fi
5363                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5364                 LINK_PROGS='LD_RUN_PATH=${libdir}'
5365                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
5366                 ;;
5367         sunos4*) #(vi
5368                 # tested with SunOS 4.1.1 and gcc 2.7.0
5369                 if test "$GCC" != yes; then
5370                         CC_SHARED_OPTS='-KPIC'
5371                 fi
5372                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
5373                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5374                 ;;
5375         solaris2*) #(vi
5376                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
5377                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
5378                 if test "$DFT_LWR_MODEL" = "shared" ; then
5379                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
5380                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5381                 fi
5382                 if test "$cf_cv_enable_rpath" = yes ; then
5383                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
5384                 fi
5385                 CF_SHARED_SONAME
5386                 if test "$GCC" != yes; then
5387                         cf_save_CFLAGS="$CFLAGS"
5388                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
5389                         do
5390                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
5391                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
5392                         done
5393                         CFLAGS="$cf_save_CFLAGS"
5394                         CC_SHARED_OPTS=$cf_shared_opts
5395                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5396                 else
5397                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5398                 fi
5399                 ;;
5400         sysv5uw7*|unix_sv*) #(vi
5401                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
5402                 if test "$GCC" != yes; then
5403                         CC_SHARED_OPTS='-KPIC'
5404                 fi
5405                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
5406                 ;;
5407         *)
5408                 CC_SHARED_OPTS='unknown'
5409                 MK_SHARED_LIB='echo unknown'
5410                 ;;
5411         esac
5412
5413         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
5414         case "$cf_cv_shlib_version" in #(vi
5415         rel|abi)
5416                 case "$MK_SHARED_LIB" in #(vi
5417                 *'-o $[@]') #(vi
5418                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
5419                         ;;
5420                 *)
5421                         AC_MSG_WARN(ignored --with-shlib-version)
5422                         ;;
5423                 esac
5424                 ;;
5425         esac
5426
5427         if test -n "$cf_ld_rpath_opt" ; then
5428                 MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${libdir}"
5429         fi
5430
5431         AC_SUBST(CC_SHARED_OPTS)
5432         AC_SUBST(LD_RPATH_OPT)
5433         AC_SUBST(LD_SHARED_OPTS)
5434         AC_SUBST(MK_SHARED_LIB)
5435         AC_SUBST(LINK_PROGS)
5436         AC_SUBST(LINK_TESTS)
5437         AC_SUBST(EXTRA_LDFLAGS)
5438         AC_SUBST(LOCAL_LDFLAGS)
5439         AC_SUBST(LOCAL_LDFLAGS2)
5440         AC_SUBST(INSTALL_LIB)
5441 ])dnl
5442 dnl ---------------------------------------------------------------------------
5443 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
5444 dnl ----------------
5445 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
5446 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
5447 dnl option.
5448 dnl
5449 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
5450 dnl If missing, use "rel".
5451 define([CF_SHARED_SONAME],
5452 [
5453         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
5454         if test "$cf_cv_shlib_version" = rel; then
5455                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
5456         else
5457                 cf_cv_shared_soname='`basename $[@]`'
5458         fi
5459 ])
5460 dnl ---------------------------------------------------------------------------
5461 dnl CF_SIGWINCH version: 1 updated: 2006/04/02 16:41:09
5462 dnl -----------
5463 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
5464 dnl programs need this test).
5465 dnl
5466 dnl This is really a MacOS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
5467 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
5468 dnl winsize declaration is left alone - we may revisit this if Apple choose to
5469 dnl break that part of the interface as well.
5470 AC_DEFUN([CF_SIGWINCH],
5471 [
5472 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
5473         AC_TRY_COMPILE([
5474 #include <sys/types.h>
5475 #include <sys/signal.h>
5476 ],[int x = SIGWINCH],
5477         [cf_cv_define_sigwinch=yes],
5478         [AC_TRY_COMPILE([
5479 #undef _XOPEN_SOURCE
5480 #undef _POSIX_SOURCE
5481 #undef _POSIX_C_SOURCE
5482 #include <sys/types.h>
5483 #include <sys/signal.h>
5484 ],[int x = SIGWINCH],
5485         [cf_cv_define_sigwinch=maybe],
5486         [cf_cv_define_sigwinch=no])
5487 ])
5488 ])
5489
5490 if test "$cf_cv_define_sigwinch" = maybe ; then
5491 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
5492 cf_cv_fixup_sigwinch=unknown
5493 cf_sigwinch=32
5494 while test $cf_sigwinch != 1
5495 do
5496         AC_TRY_COMPILE([
5497 #undef _XOPEN_SOURCE
5498 #undef _POSIX_SOURCE
5499 #undef _POSIX_C_SOURCE
5500 #include <sys/types.h>
5501 #include <sys/signal.h>
5502 ],[
5503 #if SIGWINCH != $cf_sigwinch
5504 make an error
5505 #endif
5506 int x = SIGWINCH],
5507         [cf_cv_fixup_sigwinch=$cf_sigwinch
5508          break])
5509
5510 cf_sigwinch=`expr $cf_sigwinch - 1`
5511 done
5512 ])
5513
5514         if test "$cf_cv_fixup_sigwinch" != unknown ; then
5515                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
5516         fi
5517 fi
5518 ])dnl
5519 dnl ---------------------------------------------------------------------------
5520 dnl CF_SIG_ATOMIC_T version: 2 updated: 2005/09/18 17:27:12
5521 dnl ---------------
5522 dnl signal handler, but there are some gcc depedencies in that recommendation.
5523 dnl Try anyway.
5524 AC_DEFUN([CF_SIG_ATOMIC_T],
5525 [
5526 AC_MSG_CHECKING(for signal global datatype)
5527 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
5528         for cf_type in \
5529                 "volatile sig_atomic_t" \
5530                 "sig_atomic_t" \
5531                 "int"
5532         do
5533         AC_TRY_COMPILE([
5534 #include <sys/types.h>
5535 #include <signal.h>
5536 #include <stdio.h>
5537
5538 extern $cf_type x;
5539 $cf_type x;
5540 static void handler(int sig)
5541 {
5542         x = 5;
5543 }],
5544                 [signal(SIGINT, handler);
5545                  x = 1],
5546                 [cf_cv_sig_atomic_t=$cf_type],
5547                 [cf_cv_sig_atomic_t=no])
5548                 test "$cf_cv_sig_atomic_t" != no && break
5549         done
5550         ])
5551 AC_MSG_RESULT($cf_cv_sig_atomic_t)
5552 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t)
5553 ])dnl
5554 dnl ---------------------------------------------------------------------------
5555 dnl CF_SIZECHANGE version: 8 updated: 2000/11/04 12:22:16
5556 dnl -------------
5557 dnl Check for definitions & structures needed for window size-changing
5558 dnl FIXME: check that this works with "snake" (HP-UX 10.x)
5559 AC_DEFUN([CF_SIZECHANGE],
5560 [
5561 AC_REQUIRE([CF_STRUCT_TERMIOS])
5562 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
5563     cf_cv_sizechange=unknown
5564     cf_save_CPPFLAGS="$CPPFLAGS"
5565
5566 for cf_opts in "" "NEED_PTEM_H"
5567 do
5568
5569     CPPFLAGS="$cf_save_CPPFLAGS"
5570     test -n "$cf_opts" && CPPFLAGS="$CPPFLAGS -D$cf_opts"
5571     AC_TRY_COMPILE([#include <sys/types.h>
5572 #ifdef HAVE_TERMIOS_H
5573 #include <termios.h>
5574 #else
5575 #ifdef HAVE_TERMIO_H
5576 #include <termio.h>
5577 #endif
5578 #endif
5579 #ifdef NEED_PTEM_H
5580 /* This is a workaround for SCO:  they neglected to define struct winsize in
5581  * termios.h -- it's only in termio.h and ptem.h
5582  */
5583 #include        <sys/stream.h>
5584 #include        <sys/ptem.h>
5585 #endif
5586 #if !defined(sun) || !defined(HAVE_TERMIOS_H)
5587 #include <sys/ioctl.h>
5588 #endif
5589 ],[
5590 #ifdef TIOCGSIZE
5591         struct ttysize win;     /* FIXME: what system is this? */
5592         int y = win.ts_lines;
5593         int x = win.ts_cols;
5594 #else
5595 #ifdef TIOCGWINSZ
5596         struct winsize win;
5597         int y = win.ws_row;
5598         int x = win.ws_col;
5599 #else
5600         no TIOCGSIZE or TIOCGWINSZ
5601 #endif /* TIOCGWINSZ */
5602 #endif /* TIOCGSIZE */
5603         ],
5604         [cf_cv_sizechange=yes],
5605         [cf_cv_sizechange=no])
5606
5607         CPPFLAGS="$cf_save_CPPFLAGS"
5608         if test "$cf_cv_sizechange" = yes ; then
5609                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
5610                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
5611                 break
5612         fi
5613 done
5614 ])
5615 if test "$cf_cv_sizechange" != no ; then
5616         AC_DEFINE(HAVE_SIZECHANGE)
5617         case $cf_cv_sizechange in #(vi
5618         NEED*)
5619                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
5620                 ;;
5621         esac
5622 fi
5623 ])dnl
5624 dnl ---------------------------------------------------------------------------
5625 dnl CF_SRC_MODULES version: 21 updated: 2010/09/04 17:37:40
5626 dnl --------------
5627 dnl For each parameter, test if the source-directory exists, and if it contains
5628 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
5629 dnl use in CF_LIB_RULES.
5630 dnl
5631 dnl This uses the configured value to make the lists SRC_SUBDIRS and
5632 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
5633 AC_DEFUN([CF_SRC_MODULES],
5634 [
5635 AC_MSG_CHECKING(for src modules)
5636
5637 # dependencies and linker-arguments for test-programs
5638 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
5639 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
5640 if test "$DFT_LWR_MODEL" = "libtool"; then
5641         TEST_ARGS="${TEST_DEPS}"
5642         TEST_ARG2="${TEST_DEP2}"
5643 else
5644         TEST_ARGS="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARGS"
5645         TEST_ARG2="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARG2"
5646 fi
5647
5648 cf_cv_src_modules=
5649 for cf_dir in $1
5650 do
5651         if test -f $srcdir/$cf_dir/modules; then
5652
5653                 # We may/may not have tack in the distribution, though the
5654                 # makefile is.
5655                 if test $cf_dir = tack ; then
5656                         if test ! -f $srcdir/${cf_dir}/${cf_dir}.h; then
5657                                 continue
5658                         fi
5659                 fi
5660
5661                 if test -z "$cf_cv_src_modules"; then
5662                         cf_cv_src_modules=$cf_dir
5663                 else
5664                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
5665                 fi
5666
5667                 # Make the ncurses_cfg.h file record the library interface files as
5668                 # well.  These are header files that are the same name as their
5669                 # directory.  Ncurses is the only library that does not follow
5670                 # that pattern.
5671                 if test $cf_dir = tack ; then
5672                         continue
5673                 elif test -f $srcdir/${cf_dir}/${cf_dir}.h; then
5674                         CF_UPPER(cf_have_include,$cf_dir)
5675                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
5676                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
5677                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEPS"
5678                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEP2"
5679                         if test "$DFT_LWR_MODEL" = "libtool"; then
5680                                 TEST_ARGS="${TEST_DEPS}"
5681                                 TEST_ARG2="${TEST_DEP2}"
5682                         else
5683                                 TEST_ARGS="-l${cf_dir}${DFT_ARG_SUFFIX} $TEST_ARGS"
5684                                 TEST_ARG2="-l${cf_dir}${DFT_ARG_SUFFIX} $TEST_ARG2"
5685                         fi
5686                 fi
5687         fi
5688 done
5689 AC_MSG_RESULT($cf_cv_src_modules)
5690
5691 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
5692 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
5693
5694 AC_SUBST(TEST_ARGS)
5695 AC_SUBST(TEST_DEPS)
5696
5697 AC_SUBST(TEST_ARG2)
5698 AC_SUBST(TEST_DEP2)
5699
5700 SRC_SUBDIRS=
5701 if test "x$cf_with_manpages" != xno ; then
5702         SRC_SUBDIRS="$SRC_SUBDIRS man"
5703 fi
5704 SRC_SUBDIRS="$SRC_SUBDIRS include"
5705 for cf_dir in $cf_cv_src_modules
5706 do
5707         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
5708 done
5709 if test "x$cf_with_tests" != "xno" ; then
5710         SRC_SUBDIRS="$SRC_SUBDIRS test"
5711 fi
5712 test -z "$MAKE_TERMINFO" && SRC_SUBDIRS="$SRC_SUBDIRS misc"
5713 test "$cf_with_cxx_binding" != no && SRC_SUBDIRS="$SRC_SUBDIRS c++"
5714
5715 ADA_SUBDIRS=
5716 if test "$cf_cv_prog_gnat_correct" = yes && test -f $srcdir/Ada95/Makefile.in; then
5717         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
5718         ADA_SUBDIRS="gen src"
5719         if test "x$cf_with_tests" != "xno" ; then
5720                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
5721         fi
5722 fi
5723
5724 SUB_MAKEFILES=
5725 for cf_dir in $SRC_SUBDIRS
5726 do
5727         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
5728 done
5729
5730 if test -n "$ADA_SUBDIRS"; then
5731         for cf_dir in $ADA_SUBDIRS
5732         do
5733                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
5734         done
5735         AC_SUBST(ADA_SUBDIRS)
5736 fi
5737 ])dnl
5738 dnl ---------------------------------------------------------------------------
5739 dnl CF_STDCPP_LIBRARY version: 7 updated: 2010/05/29 16:31:02
5740 dnl -----------------
5741 dnl Check for -lstdc++, which is GNU's standard C++ library.
5742 AC_DEFUN([CF_STDCPP_LIBRARY],
5743 [
5744 if test -n "$GXX" ; then
5745 case $cf_cv_system_name in #(vi
5746 os2*) #(vi
5747         cf_stdcpp_libname=stdcpp
5748         ;;
5749 *)
5750         cf_stdcpp_libname=stdc++
5751         ;;
5752 esac
5753 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
5754         cf_save="$LIBS"
5755         CF_ADD_LIB($cf_stdcpp_libname)
5756 AC_TRY_LINK([
5757 #include <strstream.h>],[
5758 char buf[80];
5759 strstreambuf foo(buf, sizeof(buf))
5760 ],
5761         [cf_cv_libstdcpp=yes],
5762         [cf_cv_libstdcpp=no])
5763         LIBS="$cf_save"
5764 ])
5765 test "$cf_cv_libstdcpp" = yes && CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS)
5766 fi
5767 ])dnl
5768 dnl ---------------------------------------------------------------------------
5769 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
5770 dnl --------------
5771 dnl     Remove "-g" option from the compiler options
5772 AC_DEFUN([CF_STRIP_G_OPT],
5773 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
5774 dnl ---------------------------------------------------------------------------
5775 dnl CF_STRUCT_SIGACTION version: 4 updated: 2011/04/16 11:52:53
5776 dnl -------------------
5777 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
5778 dnl do this if we've found the sigaction function.
5779 AC_DEFUN([CF_STRUCT_SIGACTION],[
5780 AC_REQUIRE([CF_XOPEN_SOURCE])
5781
5782 if test "$ac_cv_func_sigaction" = yes; then
5783 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
5784 AC_TRY_COMPILE([
5785 #include <sys/types.h>
5786 #include <signal.h>],
5787         [struct sigaction act],
5788         [sigact_bad=no],
5789         [
5790 AC_TRY_COMPILE([
5791 #define _POSIX_SOURCE
5792 #include <sys/types.h>
5793 #include <signal.h>],
5794         [struct sigaction act],
5795         [sigact_bad=yes
5796          AC_DEFINE(_POSIX_SOURCE)],
5797          [sigact_bad=unknown])])
5798 AC_MSG_RESULT($sigact_bad)
5799 fi
5800 ])dnl
5801 dnl ---------------------------------------------------------------------------
5802 dnl CF_STRUCT_TERMIOS version: 6 updated: 2011/04/16 11:52:53
5803 dnl -----------------
5804 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
5805 AC_DEFUN([CF_STRUCT_TERMIOS],[
5806 AC_REQUIRE([CF_XOPEN_SOURCE])
5807
5808 AC_CHECK_HEADERS( \
5809 termio.h \
5810 termios.h \
5811 unistd.h \
5812 )
5813
5814 if test "$ISC" = yes ; then
5815         AC_CHECK_HEADERS( sys/termio.h )
5816 fi
5817 if test "$ac_cv_header_termios_h" = yes ; then
5818         case "$CFLAGS $CPPFLAGS" in
5819         *-D_POSIX_SOURCE*)
5820                 termios_bad=dunno ;;
5821         *)      termios_bad=maybe ;;
5822         esac
5823         if test "$termios_bad" = maybe ; then
5824         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
5825         AC_TRY_COMPILE([#include <termios.h>],
5826                 [struct termios foo; int x = foo.c_iflag],
5827                 termios_bad=no, [
5828                 AC_TRY_COMPILE([
5829 #define _POSIX_SOURCE
5830 #include <termios.h>],
5831                         [struct termios foo; int x = foo.c_iflag],
5832                         termios_bad=unknown,
5833                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE))
5834                         ])
5835         AC_MSG_RESULT($termios_bad)
5836         fi
5837 fi
5838 ])dnl
5839 dnl ---------------------------------------------------------------------------
5840 dnl CF_SUBDIR_PATH version: 6 updated: 2010/04/21 06:20:50
5841 dnl --------------
5842 dnl Construct a search-list for a nonstandard header/lib-file
5843 dnl     $1 = the variable to return as result
5844 dnl     $2 = the package name
5845 dnl     $3 = the subdirectory, e.g., bin, include or lib
5846 AC_DEFUN([CF_SUBDIR_PATH],
5847 [
5848 $1=
5849
5850 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr,$prefix)
5851 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
5852 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr/local,$prefix)
5853 CF_ADD_SUBDIR_PATH($1,$2,$3,/opt,$prefix)
5854 CF_ADD_SUBDIR_PATH($1,$2,$3,[$]HOME,$prefix)
5855 ])dnl
5856 dnl ---------------------------------------------------------------------------
5857 dnl CF_SUBST version: 4 updated: 2006/06/17 12:33:03
5858 dnl --------
5859 dnl     Shorthand macro for substituting things that the user may override
5860 dnl     with an environment variable.
5861 dnl
5862 dnl     $1 = long/descriptive name
5863 dnl     $2 = environment variable
5864 dnl     $3 = default value
5865 AC_DEFUN([CF_SUBST],
5866 [AC_CACHE_VAL(cf_cv_subst_$2,[
5867 AC_MSG_CHECKING(for $1 (symbol $2))
5868 CF_SUBST_IF([-z "[$]$2"], [$2], [$3])
5869 cf_cv_subst_$2=[$]$2
5870 AC_MSG_RESULT([$]$2)
5871 ])
5872 ])dnl
5873 dnl ---------------------------------------------------------------------------
5874 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
5875 dnl -----------
5876 dnl     Shorthand macro for substituting things that the user may override
5877 dnl     with an environment variable.
5878 dnl
5879 dnl     $1 = condition to pass to "test"
5880 dnl     $2 = environment variable
5881 dnl     $3 = value if the test succeeds
5882 dnl     $4 = value if the test fails
5883 AC_DEFUN([CF_SUBST_IF],
5884 [
5885 if test $1 ; then
5886         $2=$3
5887 ifelse($4,,,[else
5888         $2=$4])
5889 fi
5890 AC_SUBST($2)
5891 ])dnl
5892 dnl ---------------------------------------------------------------------------
5893 dnl CF_SUBST_NCURSES_VERSION version: 8 updated: 2006/09/16 11:40:59
5894 dnl ------------------------
5895 dnl Get the version-number for use in shared-library naming, etc.
5896 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
5897 [
5898 AC_REQUIRE([CF_PROG_EGREP])
5899 NCURSES_MAJOR="`$ac_cv_prog_egrep '^NCURSES_MAJOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
5900 NCURSES_MINOR="`$ac_cv_prog_egrep '^NCURSES_MINOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
5901 NCURSES_PATCH="`$ac_cv_prog_egrep '^NCURSES_PATCH[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
5902 cf_cv_abi_version=${NCURSES_MAJOR}
5903 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
5904 dnl Show the computed version, for logging
5905 cf_cv_timestamp=`date`
5906 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
5907 dnl We need these values in the generated headers
5908 AC_SUBST(NCURSES_MAJOR)
5909 AC_SUBST(NCURSES_MINOR)
5910 AC_SUBST(NCURSES_PATCH)
5911 dnl We need these values in the generated makefiles
5912 AC_SUBST(cf_cv_rel_version)
5913 AC_SUBST(cf_cv_abi_version)
5914 AC_SUBST(cf_cv_builtin_bool)
5915 AC_SUBST(cf_cv_header_stdbool_h)
5916 AC_SUBST(cf_cv_type_of_bool)dnl
5917 ])dnl
5918 dnl ---------------------------------------------------------------------------
5919 dnl CF_SYS_TIME_SELECT version: 4 updated: 2000/10/04 09:18:40
5920 dnl ------------------
5921 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
5922 dnl older SCO configurations.
5923 AC_DEFUN([CF_SYS_TIME_SELECT],
5924 [
5925 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
5926 AC_CACHE_VAL(cf_cv_sys_time_select,[
5927 AC_TRY_COMPILE([
5928 #include <sys/types.h>
5929 #ifdef HAVE_SYS_TIME_H
5930 #include <sys/time.h>
5931 #endif
5932 #ifdef HAVE_SYS_SELECT_H
5933 #include <sys/select.h>
5934 #endif
5935 ],[],[cf_cv_sys_time_select=yes],
5936      [cf_cv_sys_time_select=no])
5937      ])
5938 AC_MSG_RESULT($cf_cv_sys_time_select)
5939 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT)
5940 ])dnl
5941 dnl ---------------------------------------------------------------------------
5942 dnl CF_TOP_BUILDDIR version: 1 updated: 2006/10/15 16:33:23
5943 dnl ---------------
5944 dnl Define a top_builddir symbol, for applications that need an absolute path.
5945 AC_DEFUN([CF_TOP_BUILDDIR],
5946 [
5947 top_builddir=`pwd`
5948 AC_SUBST(top_builddir)
5949 ])dnl
5950 dnl ---------------------------------------------------------------------------
5951 dnl CF_TYPEOF_CHTYPE version: 8 updated: 2006/12/16 12:33:30
5952 dnl ----------------
5953 dnl Determine the type we should use for chtype (and attr_t, which is treated
5954 dnl as the same thing).  We want around 32 bits, so on most machines want a
5955 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
5956 dnl wide characters, we have to have a type compatible with that, as well.
5957 AC_DEFUN([CF_TYPEOF_CHTYPE],
5958 [
5959 AC_MSG_CHECKING([for type of chtype])
5960 AC_CACHE_VAL(cf_cv_typeof_chtype,[
5961                 AC_TRY_RUN([
5962 #define WANT_BITS 31
5963 #include <stdio.h>
5964 int main()
5965 {
5966         FILE *fp = fopen("cf_test.out", "w");
5967         if (fp != 0) {
5968                 char *result = "long";
5969                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
5970                         int n;
5971                         unsigned int x, y;
5972                         for (n = 0; n < WANT_BITS; n++) {
5973                                 x = (1 << n);
5974                                 y = (x >> n);
5975                                 if (y != 1 || x == 0) {
5976                                         x = 0;
5977                                         break;
5978                                 }
5979                         }
5980                         /*
5981                          * If x is nonzero, an int is big enough for the bits
5982                          * that we want.
5983                          */
5984                         result = (x != 0) ? "int" : "long";
5985                 }
5986                 fputs(result, fp);
5987                 fclose(fp);
5988         }
5989         ${cf_cv_main_return:-return}(0);
5990 }
5991                 ],
5992                 [cf_cv_typeof_chtype=`cat cf_test.out`],
5993                 [cf_cv_typeof_chtype=long],
5994                 [cf_cv_typeof_chtype=long])
5995                 rm -f cf_test.out
5996         ])
5997 AC_MSG_RESULT($cf_cv_typeof_chtype)
5998
5999 AC_SUBST(cf_cv_typeof_chtype)
6000 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype)
6001 ])dnl
6002 dnl ---------------------------------------------------------------------------
6003 dnl CF_TYPE_SIGACTION version: 3 updated: 2000/08/12 23:18:52
6004 dnl -----------------
6005 dnl
6006 AC_DEFUN([CF_TYPE_SIGACTION],
6007 [
6008 AC_MSG_CHECKING([for type sigaction_t])
6009 AC_CACHE_VAL(cf_cv_type_sigaction,[
6010         AC_TRY_COMPILE([
6011 #include <signal.h>],
6012                 [sigaction_t x],
6013                 [cf_cv_type_sigaction=yes],
6014                 [cf_cv_type_sigaction=no])])
6015 AC_MSG_RESULT($cf_cv_type_sigaction)
6016 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION)
6017 ])dnl
6018 dnl ---------------------------------------------------------------------------
6019 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
6020 dnl --------------------
6021 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
6022 dnl won't, but they're still there.
6023 AC_DEFUN([CF_UNSIGNED_LITERALS],
6024 [
6025 AC_MSG_CHECKING([if unsigned literals are legal])
6026 AC_CACHE_VAL(cf_cv_unsigned_literals,[
6027         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
6028                 [cf_cv_unsigned_literals=yes],
6029                 [cf_cv_unsigned_literals=no])
6030         ])
6031 AC_MSG_RESULT($cf_cv_unsigned_literals)
6032 ])dnl
6033 dnl ---------------------------------------------------------------------------
6034 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
6035 dnl --------
6036 dnl Make an uppercase version of a variable
6037 dnl $1=uppercase($2)
6038 AC_DEFUN([CF_UPPER],
6039 [
6040 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
6041 ])dnl
6042 dnl ---------------------------------------------------------------------------
6043 dnl CF_UTF8_LIB version: 7 updated: 2010/06/20 09:24:28
6044 dnl -----------
6045 dnl Check for multibyte support, and if not found, utf8 compatibility library
6046 AC_DEFUN([CF_UTF8_LIB],
6047 [
6048 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
6049         cf_save_LIBS="$LIBS"
6050         AC_TRY_LINK([
6051 #include <stdlib.h>],[putwc(0,0);],
6052         [cf_cv_utf8_lib=yes],
6053         [CF_FIND_LINKAGE([
6054 #include <libutf8.h>],[putwc(0,0);],utf8,
6055                 [cf_cv_utf8_lib=add-on],
6056                 [cf_cv_utf8_lib=no])
6057 ])])
6058
6059 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
6060 # ncurses/ncursesw:
6061 if test "$cf_cv_utf8_lib" = "add-on" ; then
6062         AC_DEFINE(HAVE_LIBUTF8_H)
6063         CF_ADD_INCDIR($cf_cv_header_path_utf8)
6064         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
6065         CF_ADD_LIBS($cf_cv_library_file_utf8)
6066 fi
6067 ])dnl
6068 dnl ---------------------------------------------------------------------------
6069 dnl CF_VA_COPY version: 2 updated: 2010/03/04 05:37:29
6070 dnl ----------
6071 dnl check for va_copy, part of stdarg.h
6072 dnl Also, workaround for glibc's __va_copy, by checking for both.
6073 AC_DEFUN([CF_VA_COPY],[
6074 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
6075 AC_TRY_LINK([
6076 #include <stdarg.h>
6077 ],[
6078         static va_list dst;
6079         static va_list src;
6080         va_copy(dst, src)],
6081         cf_cv_have_va_copy=yes,
6082         cf_cv_have_va_copy=no)])
6083
6084 test "$cf_cv_have_va_copy" = yes && AC_DEFINE(HAVE_VA_COPY)
6085
6086 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
6087 AC_TRY_LINK([
6088 #include <stdarg.h>
6089 ],[
6090         static va_list dst;
6091         static va_list src;
6092         __va_copy(dst, src)],
6093         cf_cv_have___va_copy=yes,
6094         cf_cv_have___va_copy=no)])
6095
6096 test "$cf_cv_have___va_copy" = yes && AC_DEFINE(HAVE___VA_COPY)
6097 ])
6098 dnl ---------------------------------------------------------------------------
6099 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
6100 dnl ----------
6101 dnl Use AC_VERBOSE w/o the warnings
6102 AC_DEFUN([CF_VERBOSE],
6103 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
6104 CF_MSG_LOG([$1])
6105 ])dnl
6106 dnl ---------------------------------------------------------------------------
6107 dnl CF_WCHAR_TYPE version: 3 updated: 2010/05/26 16:44:57
6108 dnl -------------
6109 dnl Check if type wide-character type $1 is declared, and if so, which header
6110 dnl file is needed.  The second parameter is used to set a shell variable when
6111 dnl the type is not found.  The first parameter sets a shell variable for the
6112 dnl opposite sense.
6113 AC_DEFUN([CF_WCHAR_TYPE],
6114 [
6115 # This is needed on Tru64 5.0 to declare $1
6116 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
6117 AC_TRY_COMPILE([
6118 #include <stdlib.h>
6119 #include <stdarg.h>
6120 #include <stdio.h>
6121 #ifdef HAVE_LIBUTF8_H
6122 #include <libutf8.h>
6123 #endif],
6124         [$1 state],
6125         [cf_cv_$1=no],
6126         [AC_TRY_COMPILE([
6127 #include <stdlib.h>
6128 #include <stdarg.h>
6129 #include <stdio.h>
6130 #include <wchar.h>
6131 #ifdef HAVE_LIBUTF8_H
6132 #include <libutf8.h>
6133 #endif],
6134         [$1 value],
6135         [cf_cv_$1=yes],
6136         [cf_cv_$1=unknown])])])
6137
6138 if test "$cf_cv_$1" = yes ; then
6139         AC_DEFINE(NEED_WCHAR_H)
6140         NEED_WCHAR_H=1
6141 fi
6142
6143 ifelse([$2],,,[
6144 # if we do not find $1 in either place, use substitution to provide a fallback.
6145 if test "$cf_cv_$1" = unknown ; then
6146         $2=1
6147 fi
6148 ])
6149 ifelse($3,,,[
6150 # if we find $1 in either place, use substitution to provide a fallback.
6151 if test "$cf_cv_$1" != unknown ; then
6152         $3=1
6153 fi
6154 ])
6155 ])dnl
6156 dnl ---------------------------------------------------------------------------
6157 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
6158 dnl ---------------
6159 dnl Check for compiler-support for weak symbols.
6160 dnl This works with "recent" gcc.
6161 AC_DEFUN([CF_WEAK_SYMBOLS],[
6162 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
6163
6164 AC_TRY_COMPILE([
6165 #include <stdio.h>],
6166 [
6167 #if defined(__GNUC__)
6168 #  if defined __USE_ISOC99
6169 #    define _cat_pragma(exp)    _Pragma(#exp)
6170 #    define _weak_pragma(exp)   _cat_pragma(weak name)
6171 #  else
6172 #    define _weak_pragma(exp)
6173 #  endif
6174 #  define _declare(name)        __extension__ extern __typeof__(name) name
6175 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
6176 #endif
6177
6178 weak_symbol(fopen);
6179 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
6180 ])
6181 ])dnl
6182 dnl ---------------------------------------------------------------------------
6183 dnl CF_WITH_ABI_VERSION version: 1 updated: 2003/09/20 18:12:49
6184 dnl -------------------
6185 dnl Allow library's ABI to be overridden.  Generally this happens when a
6186 dnl packager has incremented the ABI past that used in the original package,
6187 dnl and wishes to keep doing this.
6188 dnl
6189 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
6190 dnl symbol.
6191 AC_DEFUN([CF_WITH_ABI_VERSION],[
6192 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
6193 AC_ARG_WITH(abi-version,
6194 [  --with-abi-version=XXX  override derived ABI version],
6195 [AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
6196  cf_cv_abi_version=$withval])
6197  CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
6198 ifelse($1,,,[
6199 $1_ABI=$cf_cv_abi_version
6200 ])
6201 ])dnl
6202 dnl ---------------------------------------------------------------------------
6203 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
6204 dnl --------------------
6205 dnl Command-line option to specify the Ada95 compiler.
6206 AC_DEFUN([CF_WITH_ADA_COMPILER],[
6207 AC_MSG_CHECKING(for ada-compiler)
6208 AC_ARG_WITH(ada-compiler,
6209         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
6210         [cf_ada_compiler=$withval],
6211         [cf_ada_compiler=gnatmake])
6212 AC_SUBST(cf_ada_compiler)
6213 AC_MSG_RESULT($cf_ada_compiler)
6214 ])dnl
6215 dnl ---------------------------------------------------------------------------
6216 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
6217 dnl -------------------
6218 dnl Command-line option to specify where Ada includes will install.
6219 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
6220 AC_MSG_CHECKING(for ada-include)
6221 CF_WITH_PATH(ada-include,
6222    [  --with-ada-include=DIR  Ada includes are in DIR],
6223    ADA_INCLUDE,
6224    PREFIX/share/ada/adainclude,
6225    [$]prefix/share/ada/adainclude)
6226 AC_SUBST(ADA_INCLUDE)
6227 AC_MSG_RESULT($ADA_INCLUDE)
6228 ])dnl
6229 dnl ---------------------------------------------------------------------------
6230 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
6231 dnl -------------------
6232 dnl Command-line option to specify where Ada objects will install.
6233 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
6234 AC_MSG_CHECKING(for ada-objects)
6235 CF_WITH_PATH(ada-objects,
6236    [  --with-ada-objects=DIR  Ada objects are in DIR],
6237    ADA_OBJECTS,
6238    PREFIX/lib/ada/adalib,
6239    [$]prefix/lib/ada/adalib)
6240 AC_SUBST(ADA_OBJECTS)
6241 AC_MSG_RESULT($ADA_OBJECTS)
6242 ])dnl
6243 dnl ---------------------------------------------------------------------------
6244 dnl CF_WITH_ADA_SHAREDLIB version: 2 updated: 2010/06/26 17:35:58
6245 dnl ---------------------
6246 dnl Command-line option to specify if an Ada95 shared-library should be built,
6247 dnl and optionally what its soname should be.
6248 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
6249 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
6250 AC_ARG_WITH(ada-sharedlib,
6251         [  --with-ada-sharedlib=XX build Ada95 shared-library],
6252         [with_ada_sharedlib=$withval],
6253         [with_ada_sharedlib=no])
6254 AC_MSG_RESULT($with_ada_sharedlib)
6255
6256 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
6257 MAKE_ADA_SHAREDLIB="#"
6258
6259 if test "x$with_ada_sharedlib" != xno
6260 then
6261         MAKE_ADA_SHAREDLIB=
6262         if test "x$with_ada_sharedlib" != xyes
6263         then
6264                 ADA_SHAREDLIB="$with_ada_sharedlib"
6265         fi
6266 fi
6267
6268 AC_SUBST(ADA_SHAREDLIB)
6269 AC_SUBST(MAKE_ADA_SHAREDLIB)
6270 ])dnl
6271 dnl ---------------------------------------------------------------------------
6272 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
6273 dnl ----------------
6274 dnl Configure-option for dbmalloc.  The optional parameter is used to override
6275 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6276 AC_DEFUN([CF_WITH_DBMALLOC],[
6277 CF_NO_LEAKS_OPTION(dbmalloc,
6278         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
6279         [USE_DBMALLOC])
6280
6281 if test "$with_dbmalloc" = yes ; then
6282         AC_CHECK_HEADER(dbmalloc.h,
6283                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
6284 fi
6285 ])dnl
6286 dnl ---------------------------------------------------------------------------
6287 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
6288 dnl ---------------
6289 dnl Configure-option for dmalloc.  The optional parameter is used to override
6290 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6291 AC_DEFUN([CF_WITH_DMALLOC],[
6292 CF_NO_LEAKS_OPTION(dmalloc,
6293         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
6294         [USE_DMALLOC])
6295
6296 if test "$with_dmalloc" = yes ; then
6297         AC_CHECK_HEADER(dmalloc.h,
6298                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
6299 fi
6300 ])dnl
6301 dnl ---------------------------------------------------------------------------
6302 dnl CF_WITH_GPM version: 7 updated: 2008/03/23 14:48:54
6303 dnl -----------
6304 dnl
6305 dnl The option parameter (if neither yes/no) is assumed to be the name of
6306 dnl the gpm library, e.g., for dynamic loading.
6307 AC_DEFUN([CF_WITH_GPM],
6308 [
6309 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
6310 AC_ARG_WITH(gpm,
6311         [  --with-gpm              use Alessandro Rubini's GPM library],
6312         [with_gpm=$withval],
6313         [with_gpm=maybe])
6314 AC_MSG_RESULT($with_gpm)
6315
6316 if test "$with_gpm" != no ; then
6317         AC_CHECK_HEADER(gpm.h,[
6318                 AC_DEFINE(HAVE_GPM_H)
6319                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
6320                         CF_VERBOSE(assuming we really have GPM library)
6321                         AC_DEFINE(HAVE_LIBGPM)
6322                 else
6323                         AC_CHECK_LIB(gpm,Gpm_Open,[:],[
6324                                 AC_MSG_ERROR(Cannot link with GPM library)
6325                 fi
6326                 with_gpm=yes
6327                 ])
6328         ],[
6329                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
6330                 with_gpm=no
6331         ])
6332 fi
6333 ])
6334 dnl ---------------------------------------------------------------------------
6335 dnl CF_WITH_LIBTOOL version: 28 updated: 2011/07/02 15:40:32
6336 dnl ---------------
6337 dnl Provide a configure option to incorporate libtool.  Define several useful
6338 dnl symbols for the makefile rules.
6339 dnl
6340 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
6341 dnl macros from libtool.m4 which is in the aclocal directory of automake.
6342 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
6343 dnl But that still does not work properly since the macro is expanded outside
6344 dnl the CF_WITH_LIBTOOL macro:
6345 dnl
6346 dnl     #!/bin/sh
6347 dnl     ACLOCAL=`aclocal --print-ac-dir`
6348 dnl     if test -z "$ACLOCAL" ; then
6349 dnl             echo cannot find aclocal directory
6350 dnl             exit 1
6351 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
6352 dnl             echo cannot find libtool.m4 file
6353 dnl             exit 1
6354 dnl     fi
6355 dnl
6356 dnl     LOCAL=aclocal.m4
6357 dnl     ORIG=aclocal.m4.orig
6358 dnl
6359 dnl     trap "mv $ORIG $LOCAL" 0 1 2 5 15
6360 dnl     rm -f $ORIG
6361 dnl     mv $LOCAL $ORIG
6362 dnl
6363 dnl     # sed the LIBTOOL= assignment to omit the current directory?
6364 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
6365 dnl     cat $ORIG >>$LOCAL
6366 dnl
6367 dnl     autoconf-257 $*
6368 dnl
6369 AC_DEFUN([CF_WITH_LIBTOOL],
6370 [
6371 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
6372 ifdef([AC_PROG_LIBTOOL],,[
6373 LIBTOOL=
6374 ])
6375 # common library maintenance symbols that are convenient for libtool scripts:
6376 LIB_CREATE='${AR} -cr'
6377 LIB_OBJECT='${OBJECTS}'
6378 LIB_SUFFIX=.a
6379 LIB_PREP="$RANLIB"
6380
6381 # symbols used to prop libtool up to enable it to determine what it should be
6382 # doing:
6383 LIB_CLEAN=
6384 LIB_COMPILE=
6385 LIB_LINK='${CC}'
6386 LIB_INSTALL=
6387 LIB_UNINSTALL=
6388
6389 AC_MSG_CHECKING(if you want to build libraries with libtool)
6390 AC_ARG_WITH(libtool,
6391         [  --with-libtool          generate libraries with libtool],
6392         [with_libtool=$withval],
6393         [with_libtool=no])
6394 AC_MSG_RESULT($with_libtool)
6395 if test "$with_libtool" != "no"; then
6396 ifdef([AC_PROG_LIBTOOL],[
6397         # missing_content_AC_PROG_LIBTOOL{{
6398         AC_PROG_LIBTOOL
6399         # missing_content_AC_PROG_LIBTOOL}}
6400 ],[
6401         if test "$with_libtool" != "yes" ; then
6402                 CF_PATH_SYNTAX(with_libtool)
6403                 LIBTOOL=$with_libtool
6404         else
6405                 AC_PATH_PROG(LIBTOOL,libtool)
6406         fi
6407         if test -z "$LIBTOOL" ; then
6408                 AC_MSG_ERROR(Cannot find libtool)
6409         fi
6410 ])dnl
6411         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${DESTDIR}${libdir} ${LIBTOOL_VERSION} `cut -f1 ${srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
6412         LIB_OBJECT='${OBJECTS:.o=.lo}'
6413         LIB_SUFFIX=.la
6414         LIB_CLEAN='${LIBTOOL} --mode=clean'
6415         LIB_COMPILE='${LIBTOOL} --mode=compile'
6416         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
6417         LIB_INSTALL='${LIBTOOL} --mode=install'
6418         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
6419         LIB_PREP=:
6420
6421         # Show the version of libtool
6422         AC_MSG_CHECKING(version of libtool)
6423
6424         # Save the version in a cache variable - this is not entirely a good
6425         # thing, but the version string from libtool is very ugly, and for
6426         # bug reports it might be useful to have the original string. "("
6427         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
6428         AC_MSG_RESULT($cf_cv_libtool_version)
6429         if test -z "$cf_cv_libtool_version" ; then
6430                 AC_MSG_ERROR(This is not GNU libtool)
6431         fi
6432
6433         # special hack to add -no-undefined (which libtool should do for itself)
6434         LT_UNDEF=
6435         case "$cf_cv_system_name" in #(vi
6436         cygwin*|mingw32*|uwin*|aix[[4-7]]) #(vi
6437                 LT_UNDEF=-no-undefined
6438                 ;;
6439         esac
6440         AC_SUBST([LT_UNDEF])
6441
6442         # special hack to add --tag option for C++ compiler
6443         case $cf_cv_libtool_version in #(vi
6444         1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*) #(vi
6445                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
6446                 LIBTOOL="$LIBTOOL --tag=CC"
6447                 ;;
6448         *)
6449                 LIBTOOL_CXX="$LIBTOOL"
6450                 ;;
6451         esac
6452 else
6453         LIBTOOL=""
6454         LIBTOOL_CXX=""
6455 fi
6456
6457 test -z "$LIBTOOL" && ECHO_LT=
6458
6459 AC_SUBST(LIBTOOL)
6460 AC_SUBST(LIBTOOL_CXX)
6461 AC_SUBST(LIBTOOL_OPTS)
6462
6463 AC_SUBST(LIB_CREATE)
6464 AC_SUBST(LIB_OBJECT)
6465 AC_SUBST(LIB_SUFFIX)
6466 AC_SUBST(LIB_PREP)
6467
6468 AC_SUBST(LIB_CLEAN)
6469 AC_SUBST(LIB_COMPILE)
6470 AC_SUBST(LIB_LINK)
6471 AC_SUBST(LIB_INSTALL)
6472 AC_SUBST(LIB_UNINSTALL)
6473
6474 ])dnl
6475 dnl ---------------------------------------------------------------------------
6476 dnl CF_WITH_PATH version: 10 updated: 2010/10/23 15:44:18
6477 dnl ------------
6478 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
6479 dnl defaulting to yes/no.
6480 dnl
6481 dnl $1 = option name
6482 dnl $2 = help-text
6483 dnl $3 = environment variable to set
6484 dnl $4 = default value, shown in the help-message, must be a constant
6485 dnl $5 = default value, if it's an expression & cannot be in the help-message
6486 dnl
6487 AC_DEFUN([CF_WITH_PATH],
6488 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
6489 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
6490 if ifelse([$5],,true,[test -n "$5"]) ; then
6491 CF_PATH_SYNTAX(withval)
6492 fi
6493 $3="$withval"
6494 AC_SUBST($3)dnl
6495 ])dnl
6496 dnl ---------------------------------------------------------------------------
6497 dnl CF_WITH_PATHLIST version: 7 updated: 2010/10/23 16:10:30
6498 dnl ----------------
6499 dnl Process an option specifying a list of colon-separated paths.
6500 dnl
6501 dnl $1 = option name
6502 dnl $2 = help-text
6503 dnl $3 = environment variable to set
6504 dnl $4 = default value, shown in the help-message, must be a constant
6505 dnl $5 = default value, if it's an expression & cannot be in the help-message
6506 dnl $6 = flag to tell if we want to define or substitute
6507 dnl
6508 AC_DEFUN([CF_WITH_PATHLIST],[
6509 AC_REQUIRE([CF_PATHSEP])
6510 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
6511 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
6512
6513 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
6514 cf_dst_path=
6515 for cf_src_path in $withval
6516 do
6517   CF_PATH_SYNTAX(cf_src_path)
6518   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}:"
6519   cf_dst_path="${cf_dst_path}${cf_src_path}"
6520 done
6521 IFS="$ac_save_ifs"
6522
6523 ifelse($6,define,[
6524 # Strip single quotes from the value, e.g., when it was supplied as a literal
6525 # for $4 or $5.
6526 case $cf_dst_path in #(vi
6527 \'*)
6528   cf_dst_path=`echo $cf_dst_path |sed -e s/\'// -e s/\'\$//`
6529   ;;
6530 esac
6531 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
6532 ])
6533
6534 eval '$3="$cf_dst_path"'
6535 AC_SUBST($3)dnl
6536
6537 ])dnl
6538 dnl ---------------------------------------------------------------------------
6539 dnl CF_WITH_PTHREAD version: 3 updated: 2010/05/29 16:31:02
6540 dnl ---------------
6541 dnl Check for POSIX thread library.
6542 AC_DEFUN([CF_WITH_PTHREAD],
6543 [
6544 AC_MSG_CHECKING(if you want to link with the pthread library)
6545 AC_ARG_WITH(pthread,
6546     [  --with-pthread          use POSIX thread library],
6547     [with_pthread=$withval],
6548     [with_pthread=no])
6549 AC_MSG_RESULT($with_pthread)
6550
6551 if test "$with_pthread" != no ; then
6552     AC_CHECK_HEADER(pthread.h,[
6553         AC_DEFINE(HAVE_PTHREADS_H)
6554
6555         AC_MSG_CHECKING(if we can link with the pthread library)
6556         cf_save_LIBS="$LIBS"
6557         CF_ADD_LIB(pthread)
6558         AC_TRY_LINK([
6559 #include <pthread.h>
6560 ],[
6561         int rc = pthread_create(0,0,0,0);
6562 ],[with_pthread=yes],[with_pthread=no])
6563         LIBS="$cf_save_LIBS"
6564         AC_MSG_RESULT($with_pthread)
6565
6566         if test "$with_pthread" = yes ; then
6567             CF_ADD_LIB(pthread)
6568             AC_DEFINE(HAVE_LIBPTHREADS)
6569         else
6570             AC_MSG_ERROR(Cannot link with pthread library)
6571         fi
6572     ])
6573 fi
6574 ])
6575 dnl ---------------------------------------------------------------------------
6576 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
6577 dnl -------------------
6578 dnl Allow library's release-version to be overridden.  Generally this happens when a
6579 dnl packager has incremented the release-version past that used in the original package,
6580 dnl and wishes to keep doing this.
6581 dnl
6582 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
6583 dnl and {package}_MINOR symbols
6584 dnl symbol.
6585 AC_DEFUN([CF_WITH_REL_VERSION],[
6586 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
6587 AC_ARG_WITH(rel-version,
6588 [  --with-rel-version=XXX  override derived release version],
6589 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
6590  cf_cv_rel_version=$withval])
6591 ifelse($1,,[
6592  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
6593 ],[
6594  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
6595  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
6596  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
6597  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
6598 ])
6599 ])dnl
6600 dnl ---------------------------------------------------------------------------
6601 dnl CF_WITH_SYSMOUSE version: 2 updated: 2003/03/22 19:13:43
6602 dnl ----------------
6603 dnl If we can compile with sysmouse, make it available unless it is not wanted.
6604 AC_DEFUN([CF_WITH_SYSMOUSE],[
6605 # not everyone has "test -c"
6606 if test -c /dev/sysmouse 2>/dev/null ; then
6607 AC_MSG_CHECKING(if you want to use sysmouse)
6608 AC_ARG_WITH(sysmouse,
6609         [  --with-sysmouse         use sysmouse (FreeBSD console)],
6610         [cf_with_sysmouse=$withval],
6611         [cf_with_sysmouse=maybe])
6612         if test "$cf_with_sysmouse" != no ; then
6613         AC_TRY_COMPILE([
6614 #include <osreldate.h>
6615 #if (__FreeBSD_version >= 400017)
6616 #include <sys/consio.h>
6617 #include <sys/fbio.h>
6618 #else
6619 #include <machine/console.h>
6620 #endif
6621 ],[
6622         struct mouse_info the_mouse;
6623         ioctl(0, CONS_MOUSECTL, &the_mouse);
6624 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
6625         fi
6626 AC_MSG_RESULT($cf_with_sysmouse)
6627 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE)
6628 fi
6629 ])dnl
6630 dnl ---------------------------------------------------------------------------
6631 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
6632 dnl ----------------
6633 AC_DEFUN([CF_WITH_VALGRIND],[
6634 CF_NO_LEAKS_OPTION(valgrind,
6635         [  --with-valgrind         test: use valgrind],
6636         [USE_VALGRIND])
6637 ])dnl
6638 dnl ---------------------------------------------------------------------------
6639 dnl CF_XOPEN_SOURCE version: 36 updated: 2011/07/02 15:36:04
6640 dnl ---------------
6641 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
6642 dnl or adapt to the vendor's definitions to get equivalent functionality,
6643 dnl without losing the common non-POSIX features.
6644 dnl
6645 dnl Parameters:
6646 dnl     $1 is the nominal value for _XOPEN_SOURCE
6647 dnl     $2 is the nominal value for _POSIX_C_SOURCE
6648 AC_DEFUN([CF_XOPEN_SOURCE],[
6649
6650 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
6651 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
6652 cf_xopen_source=
6653
6654 case $host_os in #(vi
6655 aix[[4-7]]*) #(vi
6656         cf_xopen_source="-D_ALL_SOURCE"
6657         ;;
6658 cygwin) #(vi
6659         cf_XOPEN_SOURCE=600
6660         ;;
6661 darwin[[0-8]].*) #(vi
6662         cf_xopen_source="-D_APPLE_C_SOURCE"
6663         ;;
6664 darwin*) #(vi
6665         cf_xopen_source="-D_DARWIN_C_SOURCE"
6666         ;;
6667 freebsd*|dragonfly*) #(vi
6668         # 5.x headers associate
6669         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
6670         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
6671         cf_POSIX_C_SOURCE=200112L
6672         cf_XOPEN_SOURCE=600
6673         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
6674         ;;
6675 hpux11*) #(vi
6676         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
6677         ;;
6678 hpux*) #(vi
6679         cf_xopen_source="-D_HPUX_SOURCE"
6680         ;;
6681 irix[[56]].*) #(vi
6682         cf_xopen_source="-D_SGI_SOURCE"
6683         ;;
6684 linux*|gnu*|mint*|k*bsd*-gnu) #(vi
6685         CF_GNU_SOURCE
6686         ;;
6687 mirbsd*) #(vi
6688         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <arpa/inet.h>
6689         ;;
6690 netbsd*) #(vi
6691         # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
6692         ;;
6693 openbsd*) #(vi
6694         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
6695         ;;
6696 osf[[45]]*) #(vi
6697         cf_xopen_source="-D_OSF_SOURCE"
6698         ;;
6699 nto-qnx*) #(vi
6700         cf_xopen_source="-D_QNX_SOURCE"
6701         ;;
6702 sco*) #(vi
6703         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
6704         ;;
6705 solaris2.1[[0-9]]) #(vi
6706         cf_xopen_source="-D__EXTENSIONS__ -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
6707         ;;
6708 solaris2.[[1-9]]) #(vi
6709         cf_xopen_source="-D__EXTENSIONS__"
6710         ;;
6711 *)
6712         AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
6713         AC_TRY_COMPILE([#include <sys/types.h>],[
6714 #ifndef _XOPEN_SOURCE
6715 make an error
6716 #endif],
6717         [cf_cv_xopen_source=no],
6718         [cf_save="$CPPFLAGS"
6719          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
6720          AC_TRY_COMPILE([#include <sys/types.h>],[
6721 #ifdef _XOPEN_SOURCE
6722 make an error
6723 #endif],
6724         [cf_cv_xopen_source=no],
6725         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
6726         CPPFLAGS="$cf_save"
6727         ])
6728 ])
6729         if test "$cf_cv_xopen_source" != no ; then
6730                 CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
6731                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
6732                 cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
6733                 CF_ADD_CFLAGS($cf_temp_xopen_source)
6734         fi
6735         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
6736         ;;
6737 esac
6738
6739 if test -n "$cf_xopen_source" ; then
6740         CF_ADD_CFLAGS($cf_xopen_source)
6741 fi
6742 ])