aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2010,2011 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.588 2011/11/26 21:41:37 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 3 updated: 2002/10/27 23:21:42
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54     [AC_TRY_LINK([#include <langinfo.h>],
  55       [char* cs = nl_langinfo(CODESET);],
  56       am_cv_langinfo_codeset=yes,
  57       am_cv_langinfo_codeset=no)
  58     ])
  59   if test $am_cv_langinfo_codeset = yes; then
  60     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62   fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ACVERSION_CHECK version: 2 updated: 2011/05/08 11:22:03
  66 dnl ------------------
  67 dnl Conditionally generate script according to whether we're using a given autoconf.
  68 dnl
  69 dnl $1 = version to compare against
  70 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  71 dnl $3 = code to use if AC_ACVERSION is older than $1.
  72 define(CF_ACVERSION_CHECK,
  73 [
  74 ifdef([m4_version_compare],
  75 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  76 [CF_ACVERSION_COMPARE(
  77 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  78 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  79 dnl ---------------------------------------------------------------------------
  80 dnl CF_ACVERSION_COMPARE version: 2 updated: 2011/04/14 20:56:50
  81 dnl --------------------
  82 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  83 dnl                      MAJOR2, MINOR2, TERNARY2,
  84 dnl                      PRINTABLE2, not FOUND, FOUND)
  85 define(CF_ACVERSION_COMPARE,
  86 [ifelse(builtin([eval], [$2 < $5]), 1,
  87 [ifelse([$8], , ,[$8])],
  88 [ifelse([$9], , ,[$9])])])dnl
  89 dnl ---------------------------------------------------------------------------
  90 dnl CF_ADA_INCLUDE_DIRS version: 6 updated: 2010/02/26 19:52:07
  91 dnl -------------------
  92 dnl Construct the list of include-options for the C programs in the Ada95
  93 dnl binding.
  94 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  95 [
  96 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  97 if test "$srcdir" != "."; then
  98         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
  99 fi
 100 if test "$GCC" != yes; then
 101         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 102 elif test "$includedir" != "/usr/include"; then
 103         if test "$includedir" = '${prefix}/include' ; then
 104                 if test $prefix != /usr ; then
 105                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 106                 fi
 107         else
 108                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 109         fi
 110 fi
 111 AC_SUBST(ACPPFLAGS)
 112 ])dnl
 113 dnl ---------------------------------------------------------------------------
 114 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 115 dnl ---------------
 116 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 117 AC_DEFUN([CF_ADD_ADAFLAGS],[
 118         ADAFLAGS="$ADAFLAGS $1"
 119         AC_SUBST(ADAFLAGS)
 120 ])dnl
 121 dnl ---------------------------------------------------------------------------
 122 dnl CF_ADD_CFLAGS version: 10 updated: 2010/05/26 05:38:42
 123 dnl -------------
 124 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 125 dnl The second parameter if given makes this macro verbose.
 126 dnl
 127 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 128 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 129 dnl confused by the quotes (which require backslashes to keep them usable).
 130 AC_DEFUN([CF_ADD_CFLAGS],
 131 [
 132 cf_fix_cppflags=no
 133 cf_new_cflags=
 134 cf_new_cppflags=
 135 cf_new_extra_cppflags=
 136
 137 for cf_add_cflags in $1
 138 do
 139 case $cf_fix_cppflags in
 140 no)
 141         case $cf_add_cflags in #(vi
 142         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
 143                 case $cf_add_cflags in
 144                 -D*)
 145                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 146
 147                         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 148                                 && test -z "${cf_tst_cflags}" \
 149                                 && cf_fix_cppflags=yes
 150
 151                         if test $cf_fix_cppflags = yes ; then
 152                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 153                                 continue
 154                         elif test "${cf_tst_cflags}" = "\"'" ; then
 155                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 156                                 continue
 157                         fi
 158                         ;;
 159                 esac
 160                 case "$CPPFLAGS" in
 161                 *$cf_add_cflags) #(vi
 162                         ;;
 163                 *) #(vi
 164                         case $cf_add_cflags in #(vi
 165                         -D*)
 166                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 167                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 168                                 ;;
 169                         esac
 170                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 171                         ;;
 172                 esac
 173                 ;;
 174         *)
 175                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 176                 ;;
 177         esac
 178         ;;
 179 yes)
 180         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 181
 182         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 183
 184         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 185                 && test -z "${cf_tst_cflags}" \
 186                 && cf_fix_cppflags=no
 187         ;;
 188 esac
 189 done
 190
 191 if test -n "$cf_new_cflags" ; then
 192         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 193         CFLAGS="$CFLAGS $cf_new_cflags"
 194 fi
 195
 196 if test -n "$cf_new_cppflags" ; then
 197         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 198         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 199 fi
 200
 201 if test -n "$cf_new_extra_cppflags" ; then
 202         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 203         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 204 fi
 205
 206 AC_SUBST(EXTRA_CPPFLAGS)
 207
 208 ])dnl
 209 dnl ---------------------------------------------------------------------------
 210 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
 211 dnl -------------
 212 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 213 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 214 dnl but old versions (and some misinstalled ones) need that.  To make things
 215 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 216 dnl the include-path).
 217 AC_DEFUN([CF_ADD_INCDIR],
 218 [
 219 if test -n "$1" ; then
 220   for cf_add_incdir in $1
 221   do
 222         while test $cf_add_incdir != /usr/include
 223         do
 224           if test -d $cf_add_incdir
 225           then
 226                 cf_have_incdir=no
 227                 if test -n "$CFLAGS$CPPFLAGS" ; then
 228                   # a loop is needed to ensure we can add subdirs of existing dirs
 229                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 230                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 231                           cf_have_incdir=yes; break
 232                         fi
 233                   done
 234                 fi
 235
 236                 if test "$cf_have_incdir" = no ; then
 237                   if test "$cf_add_incdir" = /usr/local/include ; then
 238                         if test "$GCC" = yes
 239                         then
 240                           cf_save_CPPFLAGS=$CPPFLAGS
 241                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 242                           AC_TRY_COMPILE([#include <stdio.h>],
 243                                   [printf("Hello")],
 244                                   [],
 245                                   [cf_have_incdir=yes])
 246                           CPPFLAGS=$cf_save_CPPFLAGS
 247                         fi
 248                   fi
 249                 fi
 250
 251                 if test "$cf_have_incdir" = no ; then
 252                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 253                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 254
 255                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 256                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 257                   cf_add_incdir="$cf_top_incdir"
 258                 else
 259                   break
 260                 fi
 261           fi
 262         done
 263   done
 264 fi
 265 ])dnl
 266 dnl ---------------------------------------------------------------------------
 267 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 268 dnl ----------
 269 dnl Add a library, used to enforce consistency.
 270 dnl
 271 dnl $1 = library to add, without the "-l"
 272 dnl $2 = variable to update (default $LIBS)
 273 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 274 dnl ---------------------------------------------------------------------------
 275 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
 276 dnl -------------
 277 dnl     Adds to the library-path
 278 dnl
 279 dnl     Some machines have trouble with multiple -L options.
 280 dnl
 281 dnl $1 is the (list of) directory(s) to add
 282 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 283 dnl
 284 AC_DEFUN([CF_ADD_LIBDIR],
 285 [
 286 if test -n "$1" ; then
 287   for cf_add_libdir in $1
 288   do
 289     if test $cf_add_libdir = /usr/lib ; then
 290       :
 291     elif test -d $cf_add_libdir
 292     then
 293       cf_have_libdir=no
 294       if test -n "$LDFLAGS$LIBS" ; then
 295         # a loop is needed to ensure we can add subdirs of existing dirs
 296         for cf_test_libdir in $LDFLAGS $LIBS ; do
 297           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 298             cf_have_libdir=yes; break
 299           fi
 300         done
 301       fi
 302       if test "$cf_have_libdir" = no ; then
 303         CF_VERBOSE(adding $cf_add_libdir to library-path)
 304         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 305       fi
 306     fi
 307   done
 308 fi
 309 ])dnl
 310 dnl ---------------------------------------------------------------------------
 311 dnl CF_ADD_LIBS version: 1 updated: 2010/06/02 05:03:05
 312 dnl -----------
 313 dnl Add one or more libraries, used to enforce consistency.
 314 dnl
 315 dnl $1 = libraries to add, with the "-l", etc.
 316 dnl $2 = variable to update (default $LIBS)
 317 AC_DEFUN([CF_ADD_LIBS],[ifelse($2,,LIBS,[$2])="$1 [$]ifelse($2,,LIBS,[$2])"])dnl
 318 dnl ---------------------------------------------------------------------------
 319 dnl CF_ADD_SUBDIR_PATH version: 3 updated: 2010/07/03 20:58:12
 320 dnl ------------------
 321 dnl Append to a search-list for a nonstandard header/lib-file
 322 dnl     $1 = the variable to return as result
 323 dnl     $2 = the package name
 324 dnl     $3 = the subdirectory, e.g., bin, include or lib
 325 dnl $4 = the directory under which we will test for subdirectories
 326 dnl $5 = a directory that we do not want $4 to match
 327 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 328 [
 329 test "$4" != "$5" && \
 330 test -d "$4" && \
 331 ifelse([$5],NONE,,[(test $5 = NONE || test "$4" != "$5") &&]) {
 332         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 333         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 334         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 335         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 336         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 337         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 338 }
 339 ])dnl
 340 dnl ---------------------------------------------------------------------------
 341 dnl CF_ANSI_CC_CHECK version: 11 updated: 2011/07/01 19:47:45
 342 dnl ----------------
 343 dnl This was originally adapted from the macros 'fp_PROG_CC_STDC' and
 344 dnl 'fp_C_PROTOTYPES' in the sharutils 4.2 distribution.
 345 AC_DEFUN([CF_ANSI_CC_CHECK],
 346 [
 347 # This should have been defined by AC_PROG_CC
 348 : ${CC:=cc}
 349
 350 # Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 351 # into CC.  This will not help with broken scripts that wrap the compiler with
 352 # options, but eliminates a more common category of user confusion.
 353 AC_MSG_CHECKING(\$CC variable)
 354 case "$CC" in #(vi
 355 *[[\ \  ]]-[[IUD]]*)
 356         AC_MSG_RESULT(broken)
 357         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 358         # humor him...
 359         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
 360         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
 361         CF_ADD_CFLAGS($cf_flags)
 362         ;;
 363 *)
 364         AC_MSG_RESULT(ok)
 365         ;;
 366 esac
 367
 368 AC_CACHE_CHECK(for ${CC:-cc} option to accept ANSI C, cf_cv_ansi_cc,[
 369 cf_cv_ansi_cc=no
 370 cf_save_CFLAGS="$CFLAGS"
 371 cf_save_CPPFLAGS="$CPPFLAGS"
 372 # Don't try gcc -ansi; that turns off useful extensions and
 373 # breaks some systems' header files.
 374 # AIX                   -qlanglvl=ansi
 375 # Ultrix and OSF/1      -std1
 376 # HP-UX                 -Aa -D_HPUX_SOURCE
 377 # SVR4                  -Xc
 378 # UnixWare 1.2          (cannot use -Xc, since ANSI/POSIX clashes)
 379 for cf_arg in "-DCC_HAS_PROTOS" \
 380         "" \
 381         -qlanglvl=ansi \
 382         -std1 \
 383         -Ae \
 384         "-Aa -D_HPUX_SOURCE" \
 385         -Xc
 386 do
 387         CF_ADD_CFLAGS($cf_arg)
 388         AC_TRY_COMPILE(
 389 [
 390 #ifndef CC_HAS_PROTOS
 391 #if !defined(__STDC__) || (__STDC__ != 1)
 392 choke me
 393 #endif
 394 #endif
 395 ],[
 396         int test (int i, double x);
 397         struct s1 {int (*f) (int a);};
 398         struct s2 {int (*f) (double a);};],
 399         [cf_cv_ansi_cc="$cf_arg"; break])
 400 done
 401 CFLAGS="$cf_save_CFLAGS"
 402 CPPFLAGS="$cf_save_CPPFLAGS"
 403 ])
 404
 405 if test "$cf_cv_ansi_cc" != "no"; then
 406 if test ".$cf_cv_ansi_cc" != ".-DCC_HAS_PROTOS"; then
 407         CF_ADD_CFLAGS($cf_cv_ansi_cc)
 408 else
 409         AC_DEFINE(CC_HAS_PROTOS)
 410 fi
 411 fi
 412 ])dnl
 413 dnl ---------------------------------------------------------------------------
 414 dnl CF_ANSI_CC_REQD version: 4 updated: 2008/03/23 14:48:54
 415 dnl ---------------
 416 dnl For programs that must use an ANSI compiler, obtain compiler options that
 417 dnl will make it recognize prototypes.  We'll do preprocessor checks in other
 418 dnl macros, since tools such as unproto can fake prototypes, but only part of
 419 dnl the preprocessor.
 420 AC_DEFUN([CF_ANSI_CC_REQD],
 421 [AC_REQUIRE([CF_ANSI_CC_CHECK])
 422 if test "$cf_cv_ansi_cc" = "no"; then
 423         AC_MSG_ERROR(
 424 [Your compiler does not appear to recognize prototypes.
 425 You have the following choices:
 426         a. adjust your compiler options
 427         b. get an up-to-date compiler
 428         c. use a wrapper such as unproto])
 429 fi
 430 ])dnl
 431 dnl ---------------------------------------------------------------------------
 432 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 433 dnl --------------
 434 dnl Allow user to disable a normally-on option.
 435 AC_DEFUN([CF_ARG_DISABLE],
 436 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 437 dnl ---------------------------------------------------------------------------
 438 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
 439 dnl -------------
 440 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 441 dnl values.
 442 dnl
 443 dnl Parameters:
 444 dnl $1 = option name
 445 dnl $2 = help-string
 446 dnl $3 = action to perform if option is not default
 447 dnl $4 = action if perform if option is default
 448 dnl $5 = default option value (either 'yes' or 'no')
 449 AC_DEFUN([CF_ARG_OPTION],
 450 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 451   if test "$enableval" != "$5" ; then
 452 ifelse([$3],,[    :]dnl
 453 ,[    $3]) ifelse([$4],,,[
 454   else
 455     $4])
 456   fi],[enableval=$5 ifelse([$4],,,[
 457   $4
 458 ])dnl
 459   ])])dnl
 460 dnl ---------------------------------------------------------------------------
 461 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
 462 dnl -----------
 463 dnl Check for suitable "ar" (archiver) options for updating an archive.
 464 AC_DEFUN([CF_AR_FLAGS],[
 465 AC_REQUIRE([CF_PROG_AR])
 466
 467 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 468         cf_cv_ar_flags=unknown
 469         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
 470         do
 471
 472                 # check if $ARFLAGS already contains this choice
 473                 if test "x$ARFLAGS" != "x" ; then
 474                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 475                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 476                                 cf_cv_ar_flags=
 477                                 break
 478                         fi
 479                 fi
 480
 481                 rm -f conftest.$ac_cv_objext
 482                 rm -f conftest.a
 483
 484                 cat >conftest.$ac_ext <<EOF
 485 #line __oline__ "configure"
 486 int     testdata[[3]] = { 123, 456, 789 };
 487 EOF
 488                 if AC_TRY_EVAL(ac_compile) ; then
 489                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 490                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 491                         if test -f conftest.a ; then
 492                                 cf_cv_ar_flags=$cf_ar_flags
 493                                 break
 494                         fi
 495                 else
 496                         CF_VERBOSE(cannot compile test-program)
 497                         break
 498                 fi
 499         done
 500         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 501 ])
 502
 503 if test -n "$ARFLAGS" ; then
 504         if test -n "$cf_cv_ar_flags" ; then
 505                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 506         fi
 507 else
 508         ARFLAGS=$cf_cv_ar_flags
 509 fi
 510
 511 AC_SUBST(ARFLAGS)
 512 ])
 513 dnl ---------------------------------------------------------------------------
 514 dnl CF_AWK_BIG_PRINTF version: 4 updated: 2011/10/30 17:09:50
 515 dnl -----------------
 516 dnl Check if awk can handle big strings using printf.  Some older versions of
 517 dnl awk choke on large strings passed via "%s".
 518 dnl
 519 dnl $1 = desired string size
 520 dnl $2 = variable to set with result
 521 AC_DEFUN([CF_AWK_BIG_PRINTF],
 522 [
 523         case x$AWK in #(vi
 524         x)
 525                 eval $2=no
 526                 ;;
 527         *) #(vi
 528                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 529                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 530                         eval $2=yes
 531                 else
 532                         eval $2=no
 533                 fi
 534                 ;;
 535         esac
 536 ])dnl
 537 dnl ---------------------------------------------------------------------------
 538 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 539 dnl ------------
 540 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 541 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 542 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 543 dnl
 544 dnl Treat the configuration-variable specially here, since we're directly
 545 dnl substituting its value (i.e., 1/0).
 546 dnl
 547 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 548 AC_DEFUN([CF_BOOL_DECL],
 549 [
 550 AC_MSG_CHECKING(if we should include stdbool.h)
 551
 552 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 553         AC_TRY_COMPILE([],[bool foo = false],
 554                 [cf_cv_header_stdbool_h=0],
 555                 [AC_TRY_COMPILE([
 556 #ifndef __BEOS__
 557 #include <stdbool.h>
 558 #endif
 559 ],[bool foo = false],
 560                         [cf_cv_header_stdbool_h=1],
 561                         [cf_cv_header_stdbool_h=0])])])
 562
 563 if test "$cf_cv_header_stdbool_h" = 1
 564 then    AC_MSG_RESULT(yes)
 565 else    AC_MSG_RESULT(no)
 566 fi
 567
 568 AC_MSG_CHECKING([for builtin bool type])
 569
 570 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 571         AC_TRY_COMPILE([
 572 #include <stdio.h>
 573 #include <sys/types.h>
 574 ],[bool x = false],
 575                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 576                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 577         ])
 578
 579 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 580 then    AC_MSG_RESULT(yes)
 581 else    AC_MSG_RESULT(no)
 582 fi
 583 ])dnl
 584 dnl ---------------------------------------------------------------------------
 585 dnl CF_BOOL_SIZE version: 12 updated: 2006/12/16 12:33:30
 586 dnl ------------
 587 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 588 dnl Don't bother looking for bool.h, since it's been deprecated.
 589 dnl
 590 dnl If the current compiler is C rather than C++, we get the bool definition
 591 dnl from <stdbool.h>.
 592 AC_DEFUN([CF_BOOL_SIZE],
 593 [
 594 AC_MSG_CHECKING([for size of bool])
 595 AC_CACHE_VAL(cf_cv_type_of_bool,[
 596         rm -f cf_test.out
 597         AC_TRY_RUN([
 598 #include <stdlib.h>
 599 #include <stdio.h>
 600
 601 #if defined(__cplusplus)
 602
 603 #ifdef HAVE_GXX_BUILTIN_H
 604 #include <g++/builtin.h>
 605 #elif HAVE_GPP_BUILTIN_H
 606 #include <gpp/builtin.h>
 607 #elif HAVE_BUILTIN_H
 608 #include <builtin.h>
 609 #endif
 610
 611 #else
 612
 613 #if $cf_cv_header_stdbool_h
 614 #include <stdbool.h>
 615 #endif
 616
 617 #endif
 618
 619 main()
 620 {
 621         FILE *fp = fopen("cf_test.out", "w");
 622         if (fp != 0) {
 623                 bool x = true;
 624                 if ((bool)(-x) >= 0)
 625                         fputs("unsigned ", fp);
 626                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 627                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 628                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 629                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 630                 fclose(fp);
 631         }
 632         ${cf_cv_main_return:-return}(0);
 633 }
 634                 ],
 635                 [cf_cv_type_of_bool=`cat cf_test.out`
 636                  if test -z "$cf_cv_type_of_bool"; then
 637                    cf_cv_type_of_bool=unknown
 638                  fi],
 639                 [cf_cv_type_of_bool=unknown],
 640                 [cf_cv_type_of_bool=unknown])
 641         ])
 642         rm -f cf_test.out
 643 AC_MSG_RESULT($cf_cv_type_of_bool)
 644 if test "$cf_cv_type_of_bool" = unknown ; then
 645         case .$NCURSES_BOOL in #(vi
 646         .auto|.) NCURSES_BOOL=unsigned;;
 647         esac
 648         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 649         cf_cv_type_of_bool=$NCURSES_BOOL
 650 fi
 651 ])dnl
 652 dnl ---------------------------------------------------------------------------
 653 dnl CF_BUILD_CC version: 6 updated: 2006/10/14 15:23:15
 654 dnl -----------
 655 dnl If we're cross-compiling, allow the user to override the tools and their
 656 dnl options.  The configure script is oriented toward identifying the host
 657 dnl compiler, etc., but we need a build compiler to generate parts of the
 658 dnl source.
 659 dnl
 660 dnl $1 = default for $CPPFLAGS
 661 dnl $2 = default for $LIBS
 662 AC_DEFUN([CF_BUILD_CC],[
 663 AC_REQUIRE([CF_PROG_EXT])
 664 if test "$cross_compiling" = yes ; then
 665
 666         # defaults that we might want to override
 667         : ${BUILD_CFLAGS:=''}
 668         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 669         : ${BUILD_LDFLAGS:=''}
 670         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 671         : ${BUILD_EXEEXT:='$x'}
 672         : ${BUILD_OBJEXT:='o'}
 673
 674         AC_ARG_WITH(build-cc,
 675                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 676                 [BUILD_CC="$withval"],
 677                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 678         AC_MSG_CHECKING(for native build C compiler)
 679         AC_MSG_RESULT($BUILD_CC)
 680
 681         AC_MSG_CHECKING(for native build C preprocessor)
 682         AC_ARG_WITH(build-cpp,
 683                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 684                 [BUILD_CPP="$withval"],
 685                 [BUILD_CPP='${BUILD_CC} -E'])
 686         AC_MSG_RESULT($BUILD_CPP)
 687
 688         AC_MSG_CHECKING(for native build C flags)
 689         AC_ARG_WITH(build-cflags,
 690                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 691                 [BUILD_CFLAGS="$withval"])
 692         AC_MSG_RESULT($BUILD_CFLAGS)
 693
 694         AC_MSG_CHECKING(for native build C preprocessor-flags)
 695         AC_ARG_WITH(build-cppflags,
 696                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 697                 [BUILD_CPPFLAGS="$withval"])
 698         AC_MSG_RESULT($BUILD_CPPFLAGS)
 699
 700         AC_MSG_CHECKING(for native build linker-flags)
 701         AC_ARG_WITH(build-ldflags,
 702                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 703                 [BUILD_LDFLAGS="$withval"])
 704         AC_MSG_RESULT($BUILD_LDFLAGS)
 705
 706         AC_MSG_CHECKING(for native build linker-libraries)
 707         AC_ARG_WITH(build-libs,
 708                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 709                 [BUILD_LIBS="$withval"])
 710         AC_MSG_RESULT($BUILD_LIBS)
 711
 712         # this assumes we're on Unix.
 713         BUILD_EXEEXT=
 714         BUILD_OBJEXT=o
 715
 716         : ${BUILD_CC:='${CC}'}
 717
 718         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 719                 AC_MSG_ERROR([Cross-build requires two compilers.
 720 Use --with-build-cc to specify the native compiler.])
 721         fi
 722
 723 else
 724         : ${BUILD_CC:='${CC}'}
 725         : ${BUILD_CPP:='${CPP}'}
 726         : ${BUILD_CFLAGS:='${CFLAGS}'}
 727         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 728         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 729         : ${BUILD_LIBS:='${LIBS}'}
 730         : ${BUILD_EXEEXT:='$x'}
 731         : ${BUILD_OBJEXT:='o'}
 732 fi
 733
 734 AC_SUBST(BUILD_CC)
 735 AC_SUBST(BUILD_CPP)
 736 AC_SUBST(BUILD_CFLAGS)
 737 AC_SUBST(BUILD_CPPFLAGS)
 738 AC_SUBST(BUILD_LDFLAGS)
 739 AC_SUBST(BUILD_LIBS)
 740 AC_SUBST(BUILD_EXEEXT)
 741 AC_SUBST(BUILD_OBJEXT)
 742 ])dnl
 743 dnl ---------------------------------------------------------------------------
 744 dnl CF_CFG_DEFAULTS version: 8 updated: 2011/06/04 20:09:13
 745 dnl ---------------
 746 dnl Determine the default configuration into which we'll install ncurses.  This
 747 dnl can be overridden by the user's command-line options.  There's two items to
 748 dnl look for:
 749 dnl     1. the prefix (e.g., /usr)
 750 dnl     2. the header files (e.g., /usr/include/ncurses)
 751 dnl We'll look for a previous installation of ncurses and use the same defaults.
 752 dnl
 753 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 754 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 755 dnl programs from a vendor's.
 756 AC_DEFUN([CF_CFG_DEFAULTS],
 757 [
 758 AC_MSG_CHECKING(for prefix)
 759 if test "x$prefix" = "xNONE" ; then
 760         case "$cf_cv_system_name" in
 761                 # non-vendor systems don't have a conflict
 762         openbsd*|freebsd*|mirbsd*|linux*|cygwin*|k*bsd*-gnu)
 763                 prefix=/usr
 764                 ;;
 765         *)      prefix=$ac_default_prefix
 766                 ;;
 767         esac
 768 fi
 769 AC_MSG_RESULT($prefix)
 770
 771 if test "x$prefix" = "xNONE" ; then
 772 AC_MSG_CHECKING(for default include-directory)
 773 test -n "$verbose" && echo 1>&AC_FD_MSG
 774 for cf_symbol in \
 775         $includedir \
 776         $includedir/ncurses \
 777         $prefix/include \
 778         $prefix/include/ncurses \
 779         /usr/local/include \
 780         /usr/local/include/ncurses \
 781         /usr/include \
 782         /usr/include/ncurses
 783 do
 784         cf_dir=`eval echo $cf_symbol`
 785         if test -f $cf_dir/curses.h ; then
 786         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 787                 includedir="$cf_symbol"
 788                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 789                 break
 790         fi
 791         fi
 792         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 793 done
 794 AC_MSG_RESULT($includedir)
 795 fi
 796 ])dnl
 797 dnl ---------------------------------------------------------------------------
 798 dnl CF_CGETENT version: 4 updated: 2011/08/07 14:54:41
 799 dnl ----------
 800 dnl Check if the terminal-capability database functions are available.  If not,
 801 dnl ncurses has a much-reduced version.
 802 AC_DEFUN([CF_CGETENT],[
 803 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 804 AC_TRY_LINK([
 805 #include <stdlib.h>],[
 806         char temp[128];
 807         char *buf = temp;
 808         char *db_array = temp;
 809         cgetent(&buf, &db_array, "vt100");
 810         cgetcap(buf, "tc", '=');
 811         cgetmatch(buf, "tc");
 812         ],
 813         [cf_cv_cgetent=yes],
 814         [cf_cv_cgetent=no])
 815 ])
 816
 817 if test "$cf_cv_cgetent" = yes
 818 then
 819         AC_DEFINE(HAVE_BSD_CGETENT)
 820 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 821 AC_TRY_LINK([
 822 #include <stdlib.h>],[
 823         char temp[128];
 824         char *buf = temp;
 825 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 826         const char *db_array = temp;
 827         cgetent(&buf, &db_array, "vt100");
 828 #endif
 829         cgetcap(buf, "tc", '=');
 830         cgetmatch(buf, "tc");
 831         ],
 832         [cf_cv_cgetent_const=yes],
 833         [cf_cv_cgetent_const=no])
 834 ])
 835         if test "$cf_cv_cgetent_const" = yes
 836         then
 837                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const)
 838         fi
 839 fi
 840 ])dnl
 841 dnl ---------------------------------------------------------------------------
 842 dnl CF_CHECK_CACHE version: 11 updated: 2008/03/23 14:45:59
 843 dnl --------------
 844 dnl Check if we're accidentally using a cache from a different machine.
 845 dnl Derive the system name, as a check for reusing the autoconf cache.
 846 dnl
 847 dnl If we've packaged config.guess and config.sub, run that (since it does a
 848 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 849 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 850 dnl which is useful in cross-compiles.
 851 dnl
 852 dnl Note: we would use $ac_config_sub, but that is one of the places where
 853 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 854 AC_DEFUN([CF_CHECK_CACHE],
 855 [
 856 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 857         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 858         system_name="$host_os"
 859 else
 860         system_name="`(uname -s -r) 2>/dev/null`"
 861         if test -z "$system_name" ; then
 862                 system_name="`(hostname) 2>/dev/null`"
 863         fi
 864 fi
 865 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name")
 866 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 867
 868 test -z "$system_name" && system_name="$cf_cv_system_name"
 869 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 870
 871 if test ".$system_name" != ".$cf_cv_system_name" ; then
 872         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 873         AC_MSG_ERROR("Please remove config.cache and try again.")
 874 fi
 875 ])dnl
 876 dnl ---------------------------------------------------------------------------
 877 dnl CF_CHECK_ERRNO version: 11 updated: 2010/05/26 05:38:42
 878 dnl --------------
 879 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 880 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 881 dnl ourselves.
 882 dnl
 883 dnl $1 = the name to check
 884 dnl $2 = the assumed type
 885 AC_DEFUN([CF_CHECK_ERRNO],
 886 [
 887 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 888     AC_TRY_COMPILE([
 889 #ifdef HAVE_STDLIB_H
 890 #include <stdlib.h>
 891 #endif
 892 #include <stdio.h>
 893 #include <sys/types.h>
 894 #include <errno.h> ],
 895     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 896     [cf_cv_dcl_$1=yes],
 897     [cf_cv_dcl_$1=no])
 898 ])
 899
 900 if test "$cf_cv_dcl_$1" = no ; then
 901     CF_UPPER(cf_result,decl_$1)
 902     AC_DEFINE_UNQUOTED($cf_result)
 903 fi
 904
 905 # It's possible (for near-UNIX clones) that the data doesn't exist
 906 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 907 ])dnl
 908 dnl ---------------------------------------------------------------------------
 909 dnl CF_CHECK_EXTERN_DATA version: 3 updated: 2001/12/30 18:03:23
 910 dnl --------------------
 911 dnl Check for existence of external data in the current set of libraries.  If
 912 dnl we can modify it, it's real enough.
 913 dnl $1 = the name to check
 914 dnl $2 = its type
 915 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 916 [
 917 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 918     AC_TRY_LINK([
 919 #undef $1
 920 extern $2 $1;
 921 ],
 922     [$1 = 2],
 923     [cf_cv_have_$1=yes],
 924     [cf_cv_have_$1=no])
 925 ])
 926
 927 if test "$cf_cv_have_$1" = yes ; then
 928     CF_UPPER(cf_result,have_$1)
 929     AC_DEFINE_UNQUOTED($cf_result)
 930 fi
 931
 932 ])dnl
 933 dnl ---------------------------------------------------------------------------
 934 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
 935 dnl -------------------
 936 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 937 dnl is not "weak" - warn about this because it can create problems linking
 938 dnl applications with ncurses.
 939 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 940 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 941
 942 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 943 cf_cv_check_gpm_wgetch=unknown
 944 if test "$cross_compiling" != yes ; then
 945
 946 cat >conftest.$ac_ext <<CF_EOF
 947 #include <gpm.h>
 948 int main()
 949 {
 950         Gpm_Wgetch();
 951         ${cf_cv_main_return:-return}(0);
 952 }
 953 CF_EOF
 954
 955         cf_save_LIBS="$LIBS"
 956         # This only works if we can look at the symbol table.  If a shared
 957         # library is stripped for install, we cannot use that.  So we're forced
 958         # to rely on the static library, noting that some packagers may not
 959         # include it.
 960         LIBS="-static -lgpm -dynamic $LIBS"
 961         if AC_TRY_EVAL(ac_compile) ; then
 962                 if AC_TRY_EVAL(ac_link) ; then
 963                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
 964                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
 965                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
 966                 fi
 967         fi
 968         rm -rf conftest*
 969         LIBS="$cf_save_LIBS"
 970 fi
 971 ])
 972
 973 if test "$cf_cv_check_gpm_wgetch" != yes ; then
 974         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 975 fi
 976 ])])dnl
 977 dnl ---------------------------------------------------------------------------
 978 dnl CF_CHECK_WCHAR_H version: 1 updated: 2011/10/29 15:01:05
 979 dnl ----------------
 980 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
 981 AC_DEFUN([CF_CHECK_WCHAR_H],[
 982 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
 983 AC_TRY_COMPILE(
 984 [
 985 #include <stdlib.h>
 986 #include <wchar.h>
 987 ],[
 988         wint_t foo = 0;
 989         int bar = iswpunct(foo)],
 990         [cf_cv_wchar_h_okay=yes],
 991         [cf_cv_wchar_h_okay=no])])
 992
 993 if test $cf_cv_wchar_h_okay = no
 994 then
 995         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 996 fi
 997 ])dnl
 998 dnl ---------------------------------------------------------------------------
 999 dnl CF_CPP_PARAM_INIT version: 4 updated: 2001/04/07 22:31:18
1000 dnl -----------------
1001 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1002 dnl is a late feature for the standard and is not in some recent compilers
1003 dnl (1999/9/11).
1004 AC_DEFUN([CF_CPP_PARAM_INIT],
1005 [
1006 if test -n "$CXX"; then
1007 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1008         AC_LANG_SAVE
1009         AC_LANG_CPLUSPLUS
1010         AC_TRY_RUN([
1011 class TEST {
1012 private:
1013         int value;
1014 public:
1015         TEST(int x = 1);
1016         ~TEST();
1017 };
1018
1019 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1020 {
1021         value = x;
1022 }
1023 void main() { }
1024 ],
1025         [cf_cv_cpp_param_init=yes],
1026         [cf_cv_cpp_param_init=no],
1027         [cf_cv_cpp_param_init=unknown])
1028         AC_LANG_RESTORE
1029 ])
1030 fi
1031 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT)
1032 ])dnl
1033 dnl ---------------------------------------------------------------------------
1034 dnl CF_CPP_STATIC_CAST version: 1 updated: 2005/07/23 16:52:43
1035 dnl ------------------
1036 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1037 dnl not be supported in g++ before 3.0
1038 AC_DEFUN([CF_CPP_STATIC_CAST],
1039 [
1040 if test -n "$CXX"; then
1041
1042 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1043         AC_LANG_SAVE
1044         AC_LANG_CPLUSPLUS
1045
1046         AC_TRY_COMPILE([
1047 class NCursesPanel
1048 {
1049 public:
1050   NCursesPanel(int nlines,
1051                int ncols,
1052                int begin_y = 0,
1053                int begin_x = 0)
1054   {
1055   }
1056
1057   ~NCursesPanel();
1058 };
1059
1060 template<class T> class NCursesUserPanel : public NCursesPanel
1061 {
1062 public:
1063   NCursesUserPanel (int nlines,
1064                     int ncols,
1065                     int begin_y = 0,
1066                     int begin_x = 0,
1067                     const T* p_UserData = static_cast<T*>(0))
1068     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1069   {
1070   };
1071   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1072   {
1073   };
1074
1075   virtual ~NCursesUserPanel() {};
1076 };
1077 ],[
1078         const char* p_UserData = static_cast<char*>(0)],
1079         [cf_cv_cpp_static_cast=yes],
1080         [cf_cv_cpp_static_cast=no])
1081
1082         AC_LANG_RESTORE
1083 ])
1084
1085 fi
1086
1087 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST)
1088 ])dnl
1089 dnl ---------------------------------------------------------------------------
1090 dnl CF_CXX_AR_FLAGS version: 1 updated: 2011/10/29 08:35:34
1091 dnl ---------------
1092 dnl Setup special archiver flags for given compilers.
1093 AC_DEFUN([CF_CXX_AR_FLAGS],[
1094         CXX_AR='$(AR)'
1095         CXX_ARFLAGS='$(ARFLAGS)'
1096         case $cf_cv_system_name in #(vi
1097         irix*) #(vi
1098             if test "$GXX" != yes ; then
1099                 CXX_AR='$(CXX)'
1100                 CXX_ARFLAGS='-ar -o'
1101             fi
1102             ;;
1103         sco3.2v5*) #(vi
1104             CXXLDFLAGS="-u main"
1105             ;;
1106         solaris2*)
1107             if test "$GXX" != yes ; then
1108                 CXX_AR='$(CXX)'
1109                 CXX_ARFLAGS='-xar -o'
1110             fi
1111             ;;
1112         esac
1113         AC_SUBST(CXXLDFLAGS)
1114         AC_SUBST(CXX_AR)
1115         AC_SUBST(CXX_ARFLAGS)
1116 ])dnl
1117 dnl ---------------------------------------------------------------------------
1118 dnl CF_CXX_IOSTREAM_NAMESPACE version: 1 updated: 2011/10/29 08:35:34
1119 dnl -------------------------
1120 dnl For c++, check if iostream uses "std::" namespace.
1121 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1122 AC_CHECK_HEADERS(iostream)
1123 if test x"$ac_cv_header_iostream" = xyes ; then
1124         AC_MSG_CHECKING(if iostream uses std-namespace)
1125         AC_TRY_COMPILE([
1126 #include <iostream>
1127 using std::endl;
1128 using std::cerr;],[
1129 cerr << "testing" << endl;
1130 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1131         AC_MSG_RESULT($cf_iostream_namespace)
1132         if test "$cf_iostream_namespace" = yes ; then
1133                 AC_DEFINE(IOSTREAM_NAMESPACE)
1134         fi
1135 fi
1136 ])dnl
1137 dnl ---------------------------------------------------------------------------
1138 dnl CF_C_INLINE version: 3 updated: 2010/05/01 15:14:41
1139 dnl -----------
1140 dnl Check if the C compiler supports "inline".
1141 dnl $1 is the name of a shell variable to set if inline is supported
1142 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1143 AC_DEFUN([CF_C_INLINE],[
1144 AC_C_INLINE
1145 $1=
1146 if test "$ac_cv_c_inline" != no ; then
1147   $1=inline
1148   if test "$INTEL_COMPILER" = yes
1149   then
1150     :
1151   elif test "$GCC" = yes
1152   then
1153     AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1154       cf_save_CFLAGS=$CFLAGS
1155       CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1156       AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1157       [${cf_cv_main_return:-return} foo()],
1158       [cf_cv_gcc_inline=yes],
1159       [cf_cv_gcc_inline=no])
1160       CFLAGS=$cf_save_CFLAGS
1161     ])
1162     if test "$cf_cv_gcc_inline" = yes ; then
1163         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1164     fi
1165   fi
1166 fi
1167 AC_SUBST($1)
1168 ])dnl
1169 dnl ---------------------------------------------------------------------------
1170 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1171 dnl ----------
1172 dnl "dirname" is not portable, so we fake it with a shell script.
1173 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1174 dnl ---------------------------------------------------------------------------
1175 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1176 dnl ---------------
1177 AC_DEFUN([CF_DIRS_TO_MAKE],
1178 [
1179 DIRS_TO_MAKE="lib"
1180 for cf_item in $cf_list_models
1181 do
1182         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1183         for cf_item2 in $DIRS_TO_MAKE
1184         do
1185                 test $cf_item2 = $cf_subdir && break
1186         done
1187         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1188 done
1189 for cf_dir in $DIRS_TO_MAKE
1190 do
1191         test ! -d $cf_dir && mkdir $cf_dir
1192 done
1193 AC_SUBST(DIRS_TO_MAKE)
1194 ])dnl
1195 dnl ---------------------------------------------------------------------------
1196 dnl CF_DISABLE_LEAKS version: 6 updated: 2010/07/23 04:14:32
1197 dnl ----------------
1198 dnl Combine no-leak checks with the libraries or tools that are used for the
1199 dnl checks.
1200 AC_DEFUN([CF_DISABLE_LEAKS],[
1201
1202 AC_REQUIRE([CF_WITH_DMALLOC])
1203 AC_REQUIRE([CF_WITH_DBMALLOC])
1204 AC_REQUIRE([CF_WITH_VALGRIND])
1205
1206 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1207 AC_ARG_ENABLE(leaks,
1208         [  --disable-leaks         test: free permanent memory, analyze leaks],
1209         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1210         : ${with_no_leaks:=no})
1211 AC_MSG_RESULT($with_no_leaks)
1212
1213 if test "$with_no_leaks" = yes ; then
1214         AC_DEFINE(NO_LEAKS)
1215         AC_DEFINE(YY_NO_LEAKS)
1216 fi
1217 ])dnl
1218 dnl ---------------------------------------------------------------------------
1219 dnl CF_DISABLE_LIBTOOL_VERSION version: 1 updated: 2010/05/15 15:45:59
1220 dnl --------------------------
1221 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1222 dnl the older "-version-info" feature.  The newer feature allows us to use
1223 dnl version numbering on shared libraries which make them compatible with
1224 dnl various systems.
1225 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1226 [
1227 AC_MSG_CHECKING(if libtool -version-number should be used)
1228 CF_ARG_DISABLE(libtool-version,
1229         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1230         [cf_libtool_version=no],
1231         [cf_libtool_version=yes])
1232 AC_MSG_RESULT($cf_libtool_version)
1233
1234 if test "$cf_libtool_version" = yes ; then
1235         LIBTOOL_VERSION="-version-number"
1236 else
1237         LIBTOOL_VERSION="-version-info"
1238 fi
1239
1240 AC_SUBST(LIBTOOL_VERSION)
1241 ])dnl
1242 dnl ---------------------------------------------------------------------------
1243 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1244 dnl ---------------------
1245 dnl The rpath-hack makes it simpler to build programs, particularly with the
1246 dnl *BSD ports which may have essential libraries in unusual places.  But it
1247 dnl can interfere with building an executable for the base system.  Use this
1248 dnl option in that case.
1249 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1250 [
1251 AC_MSG_CHECKING(if rpath-hack should be disabled)
1252 CF_ARG_DISABLE(rpath-hack,
1253         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1254         [cf_disable_rpath_hack=yes],
1255         [cf_disable_rpath_hack=no])
1256 AC_MSG_RESULT($cf_disable_rpath_hack)
1257 if test "$cf_disable_rpath_hack" = no ; then
1258         CF_RPATH_HACK
1259 fi
1260 ])
1261 dnl ---------------------------------------------------------------------------
1262 dnl CF_ENABLE_PC_FILES version: 6 updated: 2011/09/10 16:31:04
1263 dnl ------------------
1264 dnl This is the "--enable-pc-files" option, which is available if there is a
1265 dnl pkg-config configuration on the local machine.
1266 AC_DEFUN([CF_ENABLE_PC_FILES],[
1267 AC_REQUIRE([CF_PKG_CONFIG])
1268 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1269
1270 if test "$PKG_CONFIG" != no ; then
1271         if test -n "$PKG_CONFIG_LIBDIR" && test -d "$PKG_CONFIG_LIBDIR" ; then
1272                 AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1273                 AC_ARG_ENABLE(pc-files,
1274                         [  --enable-pc-files       generate and install .pc files for pkg-config],
1275                         [enable_pc_files=$enableval],
1276                         [enable_pc_files=no])
1277                 AC_MSG_RESULT($enable_pc_files)
1278         elif test -z "$PKG_CONFIG_LIBDIR" || test "$PKG_CONFIG_LIBDIR" != no; then
1279                 enable_pc_files=no
1280                 AC_MSG_WARN(did not find $PKG_CONFIG library)
1281         fi
1282 else
1283         enable_pc_files=no
1284 fi
1285 ])dnl
1286 dnl ---------------------------------------------------------------------------
1287 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1288 dnl ---------------
1289 dnl Check if the rpath option should be used, setting cache variable
1290 dnl cf_cv_enable_rpath if so.
1291 AC_DEFUN([CF_ENABLE_RPATH],
1292 [
1293 AC_MSG_CHECKING(if rpath option should be used)
1294 AC_ARG_ENABLE(rpath,
1295 [  --enable-rpath          use rpath option when generating shared libraries],
1296 [cf_cv_enable_rpath=$enableval],
1297 [cf_cv_enable_rpath=no])
1298 AC_MSG_RESULT($cf_cv_enable_rpath)
1299 ])dnl
1300 dnl ---------------------------------------------------------------------------
1301 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1302 dnl --------
1303 dnl Check if 'errno' is declared in <errno.h>
1304 AC_DEFUN([CF_ERRNO],
1305 [
1306 CF_CHECK_ERRNO(errno)
1307 ])dnl
1308 dnl ---------------------------------------------------------------------------
1309 dnl CF_ETIP_DEFINES version: 3 updated: 2003/03/22 19:13:43
1310 dnl ---------------
1311 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1312 dnl math.h and builtin.h, only for ncurses
1313 AC_DEFUN([CF_ETIP_DEFINES],
1314 [
1315 AC_MSG_CHECKING(for special defines needed for etip.h)
1316 cf_save_CXXFLAGS="$CXXFLAGS"
1317 cf_result="none"
1318 for cf_math in "" MATH_H
1319 do
1320 for cf_excp in "" MATH_EXCEPTION
1321 do
1322         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -I${srcdir}/include"
1323         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1324         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1325 AC_TRY_COMPILE([
1326 #include <etip.h.in>
1327 ],[],[
1328         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1329         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1330         cf_result="$cf_math $cf_excp"
1331         break
1332 ],[])
1333 done
1334 done
1335 AC_MSG_RESULT($cf_result)
1336 CXXFLAGS="$cf_save_CXXFLAGS"
1337 ])
1338 dnl ---------------------------------------------------------------------------
1339 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
1340 dnl ---------------
1341 dnl Find a library (specifically the linkage used in the code fragment),
1342 dnl searching for it if it is not already in the library path.
1343 dnl See also CF_ADD_SEARCHPATH.
1344 dnl
1345 dnl Parameters (4-on are optional):
1346 dnl     $1 = headers for library entrypoint
1347 dnl     $2 = code fragment for library entrypoint
1348 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1349 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1350 dnl     $5 = action to perform if not successful
1351 dnl     $6 = module name, if not the same as the library name
1352 dnl     $7 = extra libraries
1353 dnl
1354 dnl Sets these variables:
1355 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1356 dnl     $cf_cv_header_path_$3 - include-directory if needed
1357 dnl     $cf_cv_library_path_$3 - library-directory if needed
1358 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1359 AC_DEFUN([CF_FIND_LINKAGE],[
1360
1361 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1362 # will be set on completion of the AC_TRY_LINK below.
1363 cf_cv_header_path_$3=
1364 cf_cv_library_path_$3=
1365
1366 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1367
1368 cf_save_LIBS="$LIBS"
1369
1370 AC_TRY_LINK([$1],[$2],[
1371         cf_cv_find_linkage_$3=yes
1372         cf_cv_header_path_$3=/usr/include
1373         cf_cv_library_path_$3=/usr/lib
1374 ],[
1375
1376 LIBS="-l$3 $7 $cf_save_LIBS"
1377
1378 AC_TRY_LINK([$1],[$2],[
1379         cf_cv_find_linkage_$3=yes
1380         cf_cv_header_path_$3=/usr/include
1381         cf_cv_library_path_$3=/usr/lib
1382         cf_cv_library_file_$3="-l$3"
1383 ],[
1384         cf_cv_find_linkage_$3=no
1385         LIBS="$cf_save_LIBS"
1386
1387     CF_VERBOSE(find linkage for $3 library)
1388     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1389
1390     cf_save_CPPFLAGS="$CPPFLAGS"
1391     cf_test_CPPFLAGS="$CPPFLAGS"
1392
1393     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1394     for cf_cv_header_path_$3 in $cf_search
1395     do
1396       if test -d $cf_cv_header_path_$3 ; then
1397         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1398         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1399         AC_TRY_COMPILE([$1],[$2],[
1400             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1401             cf_cv_find_linkage_$3=maybe
1402             cf_test_CPPFLAGS="$CPPFLAGS"
1403             break],[
1404             CPPFLAGS="$cf_save_CPPFLAGS"
1405             ])
1406       fi
1407     done
1408
1409     if test "$cf_cv_find_linkage_$3" = maybe ; then
1410
1411       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1412
1413       cf_save_LIBS="$LIBS"
1414       cf_save_LDFLAGS="$LDFLAGS"
1415
1416       ifelse([$6],,,[
1417         CPPFLAGS="$cf_test_CPPFLAGS"
1418         LIBS="-l$3 $7 $cf_save_LIBS"
1419         AC_TRY_LINK([$1],[$2],[
1420             CF_VERBOSE(... found $3 library in system)
1421             cf_cv_find_linkage_$3=yes])
1422             CPPFLAGS="$cf_save_CPPFLAGS"
1423             LIBS="$cf_save_LIBS"
1424             ])
1425
1426       if test "$cf_cv_find_linkage_$3" != yes ; then
1427         CF_LIBRARY_PATH(cf_search,$3)
1428         for cf_cv_library_path_$3 in $cf_search
1429         do
1430           if test -d $cf_cv_library_path_$3 ; then
1431             CF_VERBOSE(... testing $cf_cv_library_path_$3)
1432             CPPFLAGS="$cf_test_CPPFLAGS"
1433             LIBS="-l$3 $7 $cf_save_LIBS"
1434             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1435             AC_TRY_LINK([$1],[$2],[
1436                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1437                 cf_cv_find_linkage_$3=yes
1438                 cf_cv_library_file_$3="-l$3"
1439                 break],[
1440                 CPPFLAGS="$cf_save_CPPFLAGS"
1441                 LIBS="$cf_save_LIBS"
1442                 LDFLAGS="$cf_save_LDFLAGS"
1443                 ])
1444           fi
1445         done
1446         CPPFLAGS="$cf_save_CPPFLAGS"
1447         LDFLAGS="$cf_save_LDFLAGS"
1448       fi
1449
1450     else
1451       cf_cv_find_linkage_$3=no
1452     fi
1453     ],$7)
1454 ])
1455
1456 LIBS="$cf_save_LIBS"
1457
1458 if test "$cf_cv_find_linkage_$3" = yes ; then
1459 ifelse([$4],,[
1460         CF_ADD_INCDIR($cf_cv_header_path_$3)
1461         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1462         CF_ADD_LIB($3)
1463 ],[$4])
1464 else
1465 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1466 fi
1467 ])dnl
1468 dnl ---------------------------------------------------------------------------
1469 dnl CF_FUNC_DLSYM version: 2 updated: 2010/05/29 16:31:02
1470 dnl -------------
1471 dnl Test for dlsym() and related functions, as well as libdl.
1472 dnl
1473 dnl Sets
1474 dnl     $cf_have_dlsym
1475 dnl     $cf_have_libdl
1476 AC_DEFUN([CF_FUNC_DLSYM],[
1477 cf_have_dlsym=no
1478 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1479
1480 cf_have_libdl=no
1481 AC_CHECK_LIB(dl,dlsym,[
1482         cf_have_dlsym=yes
1483         cf_have_libdl=yes])])
1484
1485 if test "$cf_have_dlsym" = yes ; then
1486         test "$cf_have_libdl" = yes && CF_ADD_LIB(dl)
1487
1488         AC_MSG_CHECKING(whether able to link to dl*() functions)
1489         AC_TRY_LINK([#include <dlfcn.h>],[
1490                 void *obj;
1491                 if ((obj = dlopen("filename", 0)) != 0) {
1492                         if (dlsym(obj, "symbolname") == 0) {
1493                         dlclose(obj);
1494                         }
1495                 }],[
1496                 AC_DEFINE(HAVE_LIBDL)],[
1497                 AC_MSG_ERROR(Cannot link test program for libdl)])
1498         AC_MSG_RESULT(ok)
1499 else
1500         AC_MSG_ERROR(Cannot find dlsym function)
1501 fi
1502 ])
1503 dnl ---------------------------------------------------------------------------
1504 dnl CF_FUNC_MEMMOVE version: 7 updated: 2006/12/16 12:33:30
1505 dnl ---------------
1506 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1507 dnl is found, add our own version of memmove to the list of objects.
1508 AC_DEFUN([CF_FUNC_MEMMOVE],
1509 [
1510 AC_CHECK_FUNC(memmove,,[
1511 AC_CHECK_FUNC(bcopy,[
1512         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1513                 AC_TRY_RUN([
1514 int main() {
1515         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1516         char temp[40];
1517         bcopy(data, temp, sizeof(data));
1518         bcopy(temp+10, temp, 15);
1519         bcopy(temp+5, temp+15, 10);
1520         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1521 }
1522                 ],
1523                 [cf_cv_good_bcopy=yes],
1524                 [cf_cv_good_bcopy=no],
1525                 [cf_cv_good_bcopy=unknown])
1526                 ])
1527         ],[cf_cv_good_bcopy=no])
1528         if test "$cf_cv_good_bcopy" = yes ; then
1529                 AC_DEFINE(USE_OK_BCOPY)
1530         else
1531                 AC_DEFINE(USE_MY_MEMMOVE)
1532         fi
1533 ])])dnl
1534 dnl ---------------------------------------------------------------------------
1535 dnl CF_FUNC_NANOSLEEP version: 3 updated: 2006/12/16 12:33:30
1536 dnl -----------------
1537 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1538 dnl AIX 4.x, provide a non-working version.
1539 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1540 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1541 AC_TRY_RUN([
1542 #include <stdio.h>
1543 #include <errno.h>
1544 #include <time.h>
1545
1546 #ifdef HAVE_SYS_TIME_H
1547 #include <sys/time.h>
1548 #endif
1549
1550 int main() {
1551         struct timespec ts1, ts2;
1552         int code;
1553         ts1.tv_sec  = 0;
1554         ts1.tv_nsec = 750000000;
1555         ts2.tv_sec  = 0;
1556         ts2.tv_nsec = 0;
1557         errno = 0;
1558         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1559         ${cf_cv_main_return:-return}(code != 0);
1560 }
1561 ],
1562         [cf_cv_func_nanosleep=yes],
1563         [cf_cv_func_nanosleep=no],
1564         [cf_cv_func_nanosleep=unknown])])
1565
1566 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP)
1567 ])
1568 dnl ---------------------------------------------------------------------------
1569 dnl CF_FUNC_OPENPTY version: 3 updated: 2010/05/29 16:31:02
1570 dnl ---------------
1571 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1572 dnl "util" library as well.
1573 AC_DEFUN([CF_FUNC_OPENPTY],
1574 [
1575 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1576 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1577     cf_save_LIBS="$LIBS"
1578     test $cf_cv_lib_util = yes && CF_ADD_LIB(util)
1579     for cf_header in pty.h libutil.h util.h
1580     do
1581     AC_TRY_LINK([
1582 #include <$cf_header>
1583 ],[
1584     int x = openpty((int *)0, (int *)0, (char *)0,
1585                    (struct termios *)0, (struct winsize *)0);
1586 ],[
1587         cf_cv_func_openpty=$cf_header
1588         break
1589 ],[
1590         cf_cv_func_openpty=no
1591 ])
1592     done
1593     LIBS="$cf_save_LIBS"
1594 ])
1595 ])dnl
1596 dnl ---------------------------------------------------------------------------
1597 dnl CF_FUNC_POLL version: 4 updated: 2006/12/16 12:33:30
1598 dnl ------------
1599 dnl See if the poll function really works.  Some platforms have poll(), but
1600 dnl it does not work for terminals or files.
1601 AC_DEFUN([CF_FUNC_POLL],[
1602 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
1603 AC_TRY_RUN([
1604 #include <stdio.h>
1605 #ifdef HAVE_POLL_H
1606 #include <poll.h>
1607 #else
1608 #include <sys/poll.h>
1609 #endif
1610 int main() {
1611         struct pollfd myfds;
1612         int ret;
1613
1614         myfds.fd = 0;
1615         myfds.events = POLLIN;
1616
1617         ret = poll(&myfds, 1, 100);
1618         ${cf_cv_main_return:-return}(ret != 0);
1619 }],
1620         [cf_cv_working_poll=yes],
1621         [cf_cv_working_poll=no],
1622         [cf_cv_working_poll=unknown])])
1623 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL)
1624 ])dnl
1625 dnl ---------------------------------------------------------------------------
1626 dnl CF_FUNC_TERMIOS version: 2 updated: 2000/07/22 23:37:24
1627 dnl ---------------
1628 dnl Some old/broken variations define tcgetattr() only as a macro in
1629 dnl termio(s).h
1630 AC_DEFUN([CF_FUNC_TERMIOS],[
1631 AC_REQUIRE([CF_STRUCT_TERMIOS])
1632 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
1633 AC_TRY_LINK([
1634 #include <sys/types.h>
1635 #ifdef HAVE_UNISTD_H
1636 #include <unistd.h>
1637 #endif
1638 #ifdef HAVE_TERMIOS_H
1639 #include <termios.h>
1640 #define TTY struct termios
1641 #else
1642 #ifdef HAVE_TERMIO_H
1643 #include <termio.h>
1644 #define TTY struct termio
1645 #endif
1646 #endif
1647 ],[
1648 TTY foo;
1649 tcgetattr(1, &foo);],
1650 [cf_cv_have_tcgetattr=yes],
1651 [cf_cv_have_tcgetattr=no])])
1652 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR)
1653 ])dnl
1654 dnl ---------------------------------------------------------------------------
1655 dnl CF_FUNC_VSSCANF version: 3 updated: 2001/12/19 00:50:10
1656 dnl ---------------
1657 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
1658 dnl versions of C.  It is in the GNU C library, and can often be simulated by
1659 dnl other functions.
1660 AC_DEFUN([CF_FUNC_VSSCANF],
1661 [
1662 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
1663 AC_TRY_LINK([
1664 #include <stdarg.h>
1665 #include <stdio.h>],[
1666         va_list ap;
1667         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
1668 AC_TRY_LINK([
1669 #include <stdarg.h>
1670 #include <stdio.h>],[
1671     FILE strbuf;
1672     char *str = "from";
1673
1674     strbuf._flag = _IOREAD;
1675     strbuf._ptr = strbuf._base = (unsigned char *) str;
1676     strbuf._cnt = strlen(str);
1677     strbuf._file = _NFILE;
1678     return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
1679 AC_TRY_LINK([
1680 #include <stdarg.h>
1681 #include <stdio.h>],[
1682     FILE strbuf;
1683     char *str = "from";
1684
1685     strbuf._flag = _IOREAD;
1686     strbuf._ptr = strbuf._base = (unsigned char *) str;
1687     strbuf._cnt = strlen(str);
1688     strbuf._file = _NFILE;
1689     return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
1690 cf_cv_func_vsscanf=no])])])])
1691
1692 case $cf_cv_func_vsscanf in #(vi
1693 vsscanf) AC_DEFINE(HAVE_VSSCANF);; #(vi
1694 vfscanf) AC_DEFINE(HAVE_VFSCANF);; #(vi
1695 _doscan) AC_DEFINE(HAVE__DOSCAN);;
1696 esac
1697
1698 ])dnl
1699 dnl ---------------------------------------------------------------------------
1700 dnl CF_GCC_ATTRIBUTES version: 14 updated: 2010/10/23 15:52:32
1701 dnl -----------------
1702 dnl Test for availability of useful gcc __attribute__ directives to quiet
1703 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1704 dnl to documentation, unrecognized directives cause older compilers to barf.
1705 AC_DEFUN([CF_GCC_ATTRIBUTES],
1706 [
1707 if test "$GCC" = yes
1708 then
1709 cat > conftest.i <<EOF
1710 #ifndef GCC_PRINTF
1711 #define GCC_PRINTF 0
1712 #endif
1713 #ifndef GCC_SCANF
1714 #define GCC_SCANF 0
1715 #endif
1716 #ifndef GCC_NORETURN
1717 #define GCC_NORETURN /* nothing */
1718 #endif
1719 #ifndef GCC_UNUSED
1720 #define GCC_UNUSED /* nothing */
1721 #endif
1722 EOF
1723 if test "$GCC" = yes
1724 then
1725         AC_CHECKING([for $CC __attribute__ directives])
1726 cat > conftest.$ac_ext <<EOF
1727 #line __oline__ "${as_me:-configure}"
1728 #include "confdefs.h"
1729 #include "conftest.h"
1730 #include "conftest.i"
1731 #if     GCC_PRINTF
1732 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1733 #else
1734 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1735 #endif
1736 #if     GCC_SCANF
1737 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1738 #else
1739 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1740 #endif
1741 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1742 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1743 extern void foo(void) GCC_NORETURN;
1744 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1745 EOF
1746         cf_printf_attribute=no
1747         cf_scanf_attribute=no
1748         for cf_attribute in scanf printf unused noreturn
1749         do
1750                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1751                 cf_directive="__attribute__(($cf_attribute))"
1752                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1753
1754                 case $cf_attribute in #(vi
1755                 printf) #(vi
1756                         cf_printf_attribute=yes
1757                         cat >conftest.h <<EOF
1758 #define GCC_$cf_ATTRIBUTE 1
1759 EOF
1760                         ;;
1761                 scanf) #(vi
1762                         cf_scanf_attribute=yes
1763                         cat >conftest.h <<EOF
1764 #define GCC_$cf_ATTRIBUTE 1
1765 EOF
1766                         ;;
1767                 *) #(vi
1768                         cat >conftest.h <<EOF
1769 #define GCC_$cf_ATTRIBUTE $cf_directive
1770 EOF
1771                         ;;
1772                 esac
1773
1774                 if AC_TRY_EVAL(ac_compile); then
1775                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1776                         cat conftest.h >>confdefs.h
1777                         case $cf_attribute in #(vi
1778                         printf) #(vi
1779                                 if test "$cf_printf_attribute" = no ; then
1780                                         cat >>confdefs.h <<EOF
1781 #define GCC_PRINTFLIKE(fmt,var) /* nothing */
1782 EOF
1783                                 else
1784                                         cat >>confdefs.h <<EOF
1785 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1786 EOF
1787                                 fi
1788                                 ;;
1789                         scanf) #(vi
1790                                 if test "$cf_scanf_attribute" = no ; then
1791                                         cat >>confdefs.h <<EOF
1792 #define GCC_SCANFLIKE(fmt,var) /* nothing */
1793 EOF
1794                                 else
1795                                         cat >>confdefs.h <<EOF
1796 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1797 EOF
1798                                 fi
1799                                 ;;
1800                         esac
1801                 fi
1802         done
1803 else
1804         fgrep define conftest.i >>confdefs.h
1805 fi
1806 rm -rf conftest*
1807 fi
1808 ])dnl
1809 dnl ---------------------------------------------------------------------------
1810 dnl CF_GCC_VERSION version: 5 updated: 2010/04/24 11:02:31
1811 dnl --------------
1812 dnl Find version of gcc
1813 AC_DEFUN([CF_GCC_VERSION],[
1814 AC_REQUIRE([AC_PROG_CC])
1815 GCC_VERSION=none
1816 if test "$GCC" = yes ; then
1817         AC_MSG_CHECKING(version of $CC)
1818         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1819         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1820         AC_MSG_RESULT($GCC_VERSION)
1821 fi
1822 ])dnl
1823 dnl ---------------------------------------------------------------------------
1824 dnl CF_GCC_WARNINGS version: 27 updated: 2010/10/23 15:52:32
1825 dnl ---------------
1826 dnl Check if the compiler supports useful warning options.  There's a few that
1827 dnl we don't use, simply because they're too noisy:
1828 dnl
1829 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1830 dnl     -Wredundant-decls (system headers make this too noisy)
1831 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1832 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1833 dnl             is enabled for ncurses using "--enable-const".
1834 dnl     -pedantic
1835 dnl
1836 dnl Parameter:
1837 dnl     $1 is an optional list of gcc warning flags that a particular
1838 dnl             application might want to use, e.g., "no-unused" for
1839 dnl             -Wno-unused
1840 dnl Special:
1841 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1842 dnl
1843 AC_DEFUN([CF_GCC_WARNINGS],
1844 [
1845 AC_REQUIRE([CF_GCC_VERSION])
1846 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1847
1848 cat > conftest.$ac_ext <<EOF
1849 #line __oline__ "${as_me:-configure}"
1850 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1851 EOF
1852
1853 if test "$INTEL_COMPILER" = yes
1854 then
1855 # The "-wdXXX" options suppress warnings:
1856 # remark #1419: external declaration in primary source file
1857 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1858 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1859 # remark #193: zero used for undefined preprocessing identifier
1860 # remark #593: variable "curs_sb_left_arrow" was set but never used
1861 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1862 # remark #869: parameter "tw" was never referenced
1863 # remark #981: operands are evaluated in unspecified order
1864 # warning #279: controlling expression is constant
1865
1866         AC_CHECKING([for $CC warning options])
1867         cf_save_CFLAGS="$CFLAGS"
1868         EXTRA_CFLAGS="-Wall"
1869         for cf_opt in \
1870                 wd1419 \
1871                 wd1683 \
1872                 wd1684 \
1873                 wd193 \
1874                 wd593 \
1875                 wd279 \
1876                 wd810 \
1877                 wd869 \
1878                 wd981
1879         do
1880                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1881                 if AC_TRY_EVAL(ac_compile); then
1882                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1883                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1884                 fi
1885         done
1886         CFLAGS="$cf_save_CFLAGS"
1887
1888 elif test "$GCC" = yes
1889 then
1890         AC_CHECKING([for $CC warning options])
1891         cf_save_CFLAGS="$CFLAGS"
1892         EXTRA_CFLAGS=
1893         cf_warn_CONST=""
1894         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
1895         for cf_opt in W Wall \
1896                 Wbad-function-cast \
1897                 Wcast-align \
1898                 Wcast-qual \
1899                 Winline \
1900                 Wmissing-declarations \
1901                 Wmissing-prototypes \
1902                 Wnested-externs \
1903                 Wpointer-arith \
1904                 Wshadow \
1905                 Wstrict-prototypes \
1906                 Wundef $cf_warn_CONST $1
1907         do
1908                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1909                 if AC_TRY_EVAL(ac_compile); then
1910                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1911                         case $cf_opt in #(vi
1912                         Wcast-qual) #(vi
1913                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
1914                                 ;;
1915                         Winline) #(vi
1916                                 case $GCC_VERSION in
1917                                 [[34]].*)
1918                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
1919                                         continue;;
1920                                 esac
1921                                 ;;
1922                         esac
1923                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1924                 fi
1925         done
1926         CFLAGS="$cf_save_CFLAGS"
1927 fi
1928 rm -rf conftest*
1929
1930 AC_SUBST(EXTRA_CFLAGS)
1931 ])dnl
1932 dnl ---------------------------------------------------------------------------
1933 dnl CF_GETOPT_HEADER version: 4 updated: 2009/08/31 20:07:52
1934 dnl ----------------
1935 dnl Check for getopt's variables which are commonly defined in stdlib.h,
1936 dnl unistd.h or (nonstandard) in getopt.h
1937 AC_DEFUN([CF_GETOPT_HEADER],
1938 [
1939 AC_HAVE_HEADERS(unistd.h getopt.h)
1940 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
1941 cf_cv_getopt_header=none
1942 for cf_header in stdio.h stdlib.h unistd.h getopt.h
1943 do
1944 AC_TRY_COMPILE([
1945 #include <$cf_header>],
1946 [int x = optind; char *y = optarg],
1947 [cf_cv_getopt_header=$cf_header
1948  break])
1949 done
1950 ])
1951 if test $cf_cv_getopt_header != none ; then
1952         AC_DEFINE(HAVE_GETOPT_HEADER)
1953 fi
1954 ])dnl
1955 dnl ---------------------------------------------------------------------------
1956 dnl CF_GNAT_GENERICS version: 2 updated: 2011/03/23 20:24:41
1957 dnl ----------------
1958 AC_DEFUN([CF_GNAT_GENERICS],
1959 [
1960 AC_REQUIRE([CF_GNAT_VERSION])
1961
1962 AC_MSG_CHECKING(if GNAT supports generics)
1963 case $cf_gnat_version in #(vi
1964 3.[[1-9]]*|[[4-9]].*) #(vi
1965         cf_gnat_generics=yes
1966         ;;
1967 *)
1968         cf_gnat_generics=no
1969         ;;
1970 esac
1971 AC_MSG_RESULT($cf_gnat_generics)
1972
1973 if test "$cf_gnat_generics" = yes
1974 then
1975         cf_compile_generics=generics
1976         cf_generic_objects="\${GENOBJS}"
1977 else
1978         cf_compile_generics=
1979         cf_generic_objects=
1980 fi
1981
1982 AC_SUBST(cf_compile_generics)
1983 AC_SUBST(cf_generic_objects)
1984 ])dnl
1985 dnl ---------------------------------------------------------------------------
1986 dnl CF_GNAT_PRAGMA_UNREF version: 1 updated: 2010/06/19 15:22:18
1987 dnl --------------------
1988 dnl Check if the gnat pragma "Unreferenced" works.
1989 AC_DEFUN([CF_GNAT_PRAGMA_UNREF],[
1990 AC_CACHE_CHECK(if GNAT pragma Unreferenced works,cf_cv_pragma_unreferenced,[
1991 CF_GNAT_TRY_LINK([procedure conftest;],
1992 [with Text_IO;
1993 with GNAT.OS_Lib;
1994 procedure conftest is
1995    test : Integer;
1996    pragma Unreferenced (test);
1997 begin
1998    test := 1;
1999    Text_IO.Put ("Hello World");
2000    Text_IO.New_Line;
2001    GNAT.OS_Lib.OS_Exit (0);
2002 end conftest;],
2003         [cf_cv_pragma_unreferenced=yes],
2004         [cf_cv_pragma_unreferenced=no])])
2005
2006 # if the pragma is supported, use it (needed in the Trace code).
2007 if test $cf_cv_pragma_unreferenced = yes ; then
2008         PRAGMA_UNREF=TRUE
2009 else
2010         PRAGMA_UNREF=FALSE
2011 fi
2012 AC_SUBST(PRAGMA_UNREF)
2013 ])dnl
2014 dnl ---------------------------------------------------------------------------
2015 dnl CF_GNAT_PROJECTS version: 2 updated: 2011/03/23 20:24:41
2016 dnl ----------------
2017 dnl GNAT projects are configured with ".gpr" project files.
2018 dnl GNAT libraries are a further development, using the project feature.
2019 AC_DEFUN([CF_GNAT_PROJECTS],
2020 [
2021 AC_REQUIRE([CF_GNAT_VERSION])
2022
2023 cf_gnat_libraries=no
2024 cf_gnat_projects=no
2025
2026 AC_MSG_CHECKING(if GNAT supports project files)
2027 case $cf_gnat_version in #(vi
2028 3.[[0-9]]*) #(vi
2029         ;;
2030 *)
2031         case $cf_cv_system_name in #(vi
2032         cygwin*) #(vi
2033                 ;;
2034         *)
2035                 mkdir conftest.src conftest.bin conftest.lib
2036                 cd conftest.src
2037                 rm -rf conftest* *~conftest*
2038                 cat >>library.gpr <<CF_EOF
2039 project Library is
2040   Kind := External ("LIB_KIND");
2041   for Library_Name use "ConfTest";
2042   for Object_Dir use ".";
2043   for Library_ALI_Dir use External("LIBRARY_DIR");
2044   for Library_Version use External ("SONAME");
2045   for Library_Kind use Kind;
2046   for Library_Dir use External("BUILD_DIR");
2047   Source_Dir := External ("SOURCE_DIR");
2048   for Source_Dirs use (Source_Dir);
2049   package Compiler is
2050      for Default_Switches ("Ada") use
2051        ("-g",
2052         "-O2",
2053         "-gnatafno",
2054         "-gnatVa",   -- All validity checks
2055         "-gnatwa");  -- Activate all optional errors
2056   end Compiler;
2057 end Library;
2058 CF_EOF
2059                 cat >>confpackage.ads <<CF_EOF
2060 package ConfPackage is
2061    procedure conftest;
2062 end ConfPackage;
2063 CF_EOF
2064                 cat >>confpackage.adb <<CF_EOF
2065 with Text_IO;
2066 package body ConfPackage is
2067    procedure conftest is
2068    begin
2069       Text_IO.Put ("Hello World");
2070       Text_IO.New_Line;
2071    end conftest;
2072 end ConfPackage;
2073 CF_EOF
2074                 if ( $cf_ada_make $ADAFLAGS \
2075                                 -Plibrary.gpr \
2076                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2077                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2078                                 -XSOURCE_DIR=`pwd` \
2079                                 -XSONAME=libConfTest.so.1 \
2080                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2081                         cf_gnat_projects=yes
2082                 fi
2083                 cd ..
2084                 if test -f conftest.lib/confpackage.ali
2085                 then
2086                         cf_gnat_libraries=yes
2087                 fi
2088                 rm -rf conftest* *~conftest*
2089                 ;;
2090         esac
2091         ;;
2092 esac
2093 AC_MSG_RESULT($cf_gnat_projects)
2094
2095 if test $cf_gnat_projects = yes
2096 then
2097         AC_MSG_CHECKING(if GNAT supports libraries)
2098         AC_MSG_RESULT($cf_gnat_libraries)
2099 fi
2100
2101 if test "$cf_gnat_projects" = yes
2102 then
2103         USE_OLD_MAKERULES="#"
2104         USE_GNAT_PROJECTS=""
2105 else
2106         USE_OLD_MAKERULES=""
2107         USE_GNAT_PROJECTS="#"
2108 fi
2109
2110 if test "$cf_gnat_libraries" = yes
2111 then
2112         USE_GNAT_LIBRARIES=""
2113 else
2114         USE_GNAT_LIBRARIES="#"
2115 fi
2116
2117 AC_SUBST(USE_OLD_MAKERULES)
2118 AC_SUBST(USE_GNAT_PROJECTS)
2119 AC_SUBST(USE_GNAT_LIBRARIES)
2120 ])dnl
2121 dnl ---------------------------------------------------------------------------
2122 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2123 dnl --------------
2124 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2125 dnl is noted that gnat may compile a tasking unit even for configurations which
2126 dnl fail at runtime.
2127 AC_DEFUN([CF_GNAT_SIGINT],[
2128 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2129 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2130
2131 package ConfTest is
2132
2133    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2134    pragma Unreserve_All_Interrupts;
2135    pragma Warnings (On);
2136
2137    protected Process is
2138       procedure Stop;
2139       function Continue return Boolean;
2140       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2141    private
2142       Done : Boolean := False;
2143    end Process;
2144
2145 end ConfTest;],
2146 [package body ConfTest is
2147    protected body Process is
2148       procedure Stop is
2149       begin
2150          Done := True;
2151       end Stop;
2152       function Continue return Boolean is
2153       begin
2154          return not Done;
2155       end Continue;
2156    end Process;
2157 end ConfTest;],
2158         [cf_cv_gnat_sigint=yes],
2159         [cf_cv_gnat_sigint=no])])
2160
2161 if test $cf_cv_gnat_sigint = yes ; then
2162         USE_GNAT_SIGINT=""
2163 else
2164         USE_GNAT_SIGINT="#"
2165 fi
2166 AC_SUBST(USE_GNAT_SIGINT)
2167 ])dnl
2168 dnl ---------------------------------------------------------------------------
2169 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2170 dnl ----------------
2171 dnl Verify that a test program compiles/links with GNAT.
2172 dnl $cf_ada_make is set to the program that compiles/links
2173 dnl $ADAFLAGS may be set to the GNAT flags.
2174 dnl
2175 dnl $1 is the text of the spec
2176 dnl $2 is the text of the body
2177 dnl $3 is the shell command to execute if successful
2178 dnl $4 is the shell command to execute if not successful
2179 AC_DEFUN([CF_GNAT_TRY_LINK],
2180 [
2181 rm -rf conftest* *~conftest*
2182 cat >>conftest.ads <<CF_EOF
2183 $1
2184 CF_EOF
2185 cat >>conftest.adb <<CF_EOF
2186 $2
2187 CF_EOF
2188 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2189 ifelse($3,,      :,[      $3])
2190 ifelse($4,,,[else
2191    $4])
2192 fi
2193 rm -rf conftest* *~conftest*
2194 ])dnl
2195 dnl ---------------------------------------------------------------------------
2196 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2197 dnl ---------------
2198 dnl Verify that a test program compiles and runs with GNAT
2199 dnl $cf_ada_make is set to the program that compiles/links
2200 dnl $ADAFLAGS may be set to the GNAT flags.
2201 dnl
2202 dnl $1 is the text of the spec
2203 dnl $2 is the text of the body
2204 dnl $3 is the shell command to execute if successful
2205 dnl $4 is the shell command to execute if not successful
2206 AC_DEFUN([CF_GNAT_TRY_RUN],
2207 [
2208 rm -rf conftest* *~conftest*
2209 cat >>conftest.ads <<CF_EOF
2210 $1
2211 CF_EOF
2212 cat >>conftest.adb <<CF_EOF
2213 $2
2214 CF_EOF
2215 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2216    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2217 ifelse($3,,      :,[      $3])
2218 ifelse($4,,,[   else
2219       $4])
2220    fi
2221 ifelse($4,,,[else
2222    $4])
2223 fi
2224 rm -rf conftest* *~conftest*
2225 ])dnl
2226 dnl ---------------------------------------------------------------------------
2227 dnl CF_GNAT_VERSION version: 17 updated: 2011/03/23 20:24:41
2228 dnl ---------------
2229 dnl Verify version of GNAT.
2230 AC_DEFUN([CF_GNAT_VERSION],
2231 [
2232 AC_MSG_CHECKING(for gnat version)
2233 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2234         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2235     sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2236 AC_MSG_RESULT($cf_gnat_version)
2237
2238 case $cf_gnat_version in #(vi
2239 3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*) #(vi
2240         cf_cv_prog_gnat_correct=yes
2241         ;;
2242 *)
2243         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2244         cf_cv_prog_gnat_correct=no
2245         ;;
2246 esac
2247 ])
2248 dnl ---------------------------------------------------------------------------
2249 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
2250 dnl -------------
2251 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2252 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2253 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2254 dnl since it is interwoven with GNU extensions.
2255 dnl
2256 dnl Well, yes we could work around it...
2257 AC_DEFUN([CF_GNU_SOURCE],
2258 [
2259 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2260 AC_TRY_COMPILE([#include <sys/types.h>],[
2261 #ifndef _XOPEN_SOURCE
2262 make an error
2263 #endif],
2264         [cf_cv_gnu_source=no],
2265         [cf_save="$CPPFLAGS"
2266          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2267          AC_TRY_COMPILE([#include <sys/types.h>],[
2268 #ifdef _XOPEN_SOURCE
2269 make an error
2270 #endif],
2271         [cf_cv_gnu_source=no],
2272         [cf_cv_gnu_source=yes])
2273         CPPFLAGS="$cf_save"
2274         ])
2275 ])
2276 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2277 ])dnl
2278 dnl ---------------------------------------------------------------------------
2279 dnl CF_GPP_LIBRARY version: 10 updated: 2010/05/29 16:31:02
2280 dnl --------------
2281 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2282 dnl problem :-).  If we have the compiler but no library, we'll be able to
2283 dnl configure, but won't be able to build the c++ demo program.
2284 AC_DEFUN([CF_GPP_LIBRARY],
2285 [
2286 cf_cxx_library=unknown
2287 case $cf_cv_system_name in #(vi
2288 os2*) #(vi
2289         cf_gpp_libname=gpp
2290         ;;
2291 *)
2292         cf_gpp_libname=g++
2293         ;;
2294 esac
2295 if test "$GXX" = yes; then
2296         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2297         cf_save="$LIBS"
2298         CF_ADD_LIB($cf_gpp_libname)
2299         AC_TRY_LINK([
2300 #include <$cf_gpp_libname/builtin.h>
2301         ],
2302         [two_arg_error_handler_t foo2 = lib_error_handler],
2303         [cf_cxx_library=yes
2304          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2305          if test "$cf_gpp_libname" = cpp ; then
2306             AC_DEFINE(HAVE_GPP_BUILTIN_H)
2307          else
2308             AC_DEFINE(HAVE_GXX_BUILTIN_H)
2309          fi],
2310         [AC_TRY_LINK([
2311 #include <builtin.h>
2312         ],
2313         [two_arg_error_handler_t foo2 = lib_error_handler],
2314         [cf_cxx_library=yes
2315          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2316          AC_DEFINE(HAVE_BUILTIN_H)],
2317         [cf_cxx_library=no])])
2318         LIBS="$cf_save"
2319         AC_MSG_RESULT($cf_cxx_library)
2320 fi
2321 ])dnl
2322 dnl ---------------------------------------------------------------------------
2323 dnl CF_GXX_VERSION version: 6 updated: 2010/10/23 15:44:18
2324 dnl --------------
2325 dnl Check for version of g++
2326 AC_DEFUN([CF_GXX_VERSION],[
2327 AC_REQUIRE([AC_PROG_CPP])
2328 GXX_VERSION=none
2329 if test "$GXX" = yes; then
2330         AC_MSG_CHECKING(version of g++)
2331         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2332         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2333         AC_MSG_RESULT($GXX_VERSION)
2334 fi
2335 ])dnl
2336 dnl ---------------------------------------------------------------------------
2337 dnl CF_GXX_WARNINGS version: 6 updated: 2010/08/14 18:25:37
2338 dnl ---------------
2339 dnl Check if the compiler supports useful warning options.
2340 dnl
2341 dnl Most of gcc's options apply to g++, except:
2342 dnl     -Wbad-function-cast
2343 dnl     -Wmissing-declarations
2344 dnl     -Wnested-externs
2345 dnl
2346 dnl Omit a few (for now):
2347 dnl     -Winline
2348 dnl
2349 dnl Parameter:
2350 dnl     $1 is an optional list of g++ warning flags that a particular
2351 dnl             application might want to use, e.g., "no-unused" for
2352 dnl             -Wno-unused
2353 dnl Special:
2354 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2355 dnl
2356 AC_DEFUN([CF_GXX_WARNINGS],
2357 [
2358
2359 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2360
2361 AC_REQUIRE([CF_GXX_VERSION])
2362
2363 AC_LANG_SAVE
2364 AC_LANG_CPLUSPLUS
2365
2366 cat > conftest.$ac_ext <<EOF
2367 #line __oline__ "configure"
2368 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2369 EOF
2370
2371 if test "$INTEL_CPLUSPLUS" = yes
2372 then
2373 # The "-wdXXX" options suppress warnings:
2374 # remark #1419: external declaration in primary source file
2375 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2376 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2377 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2378 # remark #193: zero used for undefined preprocessing identifier
2379 # remark #593: variable "curs_sb_left_arrow" was set but never used
2380 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2381 # remark #869: parameter "tw" was never referenced
2382 # remark #981: operands are evaluated in unspecified order
2383 # warning #269: invalid format string conversion
2384
2385         AC_CHECKING([for $CC warning options])
2386         cf_save_CXXFLAGS="$CXXFLAGS"
2387         EXTRA_CXXFLAGS="-Wall"
2388         for cf_opt in \
2389                 wd1419 \
2390                 wd1682 \
2391                 wd1683 \
2392                 wd1684 \
2393                 wd193 \
2394                 wd279 \
2395                 wd593 \
2396                 wd810 \
2397                 wd869 \
2398                 wd981
2399         do
2400                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2401                 if AC_TRY_EVAL(ac_compile); then
2402                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2403                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2404                 fi
2405         done
2406         CXXFLAGS="$cf_save_CXXFLAGS"
2407
2408 elif test "$GXX" = yes
2409 then
2410         AC_CHECKING([for $CXX warning options])
2411         cf_save_CXXFLAGS="$CXXFLAGS"
2412         EXTRA_CXXFLAGS="-W -Wall"
2413         cf_gxx_extra_warnings=""
2414         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2415         case "$GCC_VERSION" in
2416         [[1-2]].*)
2417                 ;;
2418         *)
2419                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2420                 ;;
2421         esac
2422         for cf_opt in \
2423                 Wabi \
2424                 fabi-version=0 \
2425                 Woverloaded-virtual \
2426                 Wsign-promo \
2427                 Wsynth \
2428                 Wold-style-cast \
2429                 Wcast-align \
2430                 Wcast-qual \
2431                 Wmissing-prototypes \
2432                 Wpointer-arith \
2433                 Wshadow \
2434                 Wstrict-prototypes \
2435                 Wundef $cf_gxx_extra_warnings $1
2436         do
2437                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2438                 if AC_TRY_EVAL(ac_compile); then
2439                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2440                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2441                 else
2442                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2443                 fi
2444         done
2445         CXXFLAGS="$cf_save_CXXFLAGS"
2446 fi
2447
2448 rm -rf conftest*
2449 AC_LANG_RESTORE
2450 AC_SUBST(EXTRA_CXXFLAGS)
2451 ])dnl
2452 dnl ---------------------------------------------------------------------------
2453 dnl CF_HASHED_DB version: 4 updated: 2010/05/29 16:31:02
2454 dnl ------------
2455 dnl Look for an instance of the Berkeley hashed database.
2456 dnl
2457 dnl $1 = optional parameter, to specify install-prefix for the database.
2458 AC_DEFUN([CF_HASHED_DB],
2459 [
2460 ifelse([$1],,,[
2461 case $1 in #(vi
2462 yes|*able*) #(vi
2463     ;;
2464 *)
2465     if test -d "$1" ; then
2466         CF_ADD_INCDIR($1/include)
2467         CF_ADD_LIBDIR($1/lib)
2468     fi
2469 esac
2470 ])
2471 AC_CHECK_HEADER(db.h,[
2472 CF_HASHED_DB_VERSION
2473 if test "$cf_cv_hashed_db_version" = unknown ; then
2474         AC_MSG_ERROR(Cannot determine version of db)
2475 else
2476         CF_HASHED_DB_LIBS
2477         if test "$cf_cv_hashed_db_libs" = unknown ; then
2478                 AC_MSG_ERROR(Cannot determine library for db)
2479         elif test "$cf_cv_hashed_db_libs" != default ; then
2480                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2481         fi
2482 fi
2483 ],[
2484         AC_MSG_ERROR(Cannot find db.h)
2485 ])
2486 ])dnl
2487 dnl ---------------------------------------------------------------------------
2488 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2489 dnl -----------------
2490 dnl Given that we have the header and version for hashed database, find the
2491 dnl library information.
2492 AC_DEFUN([CF_HASHED_DB_LIBS],
2493 [
2494 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2495 cf_cv_hashed_db_libs=unknown
2496 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2497 do
2498         cf_save_libs="$LIBS"
2499         if test -n "$cf_db_libs"; then
2500                 CF_ADD_LIB($cf_db_libs)
2501         fi
2502         CF_MSG_LOG(checking for library "$cf_db_libs")
2503         AC_TRY_LINK([
2504 $ac_includes_default
2505 #include <db.h>
2506 ],[
2507         char *path = "/tmp/foo";
2508 #ifdef DB_VERSION_MAJOR
2509 #if DB_VERSION_MAJOR >= 4
2510         DB *result = 0;
2511         db_create(&result, NULL, 0);
2512         result->open(result,
2513                 NULL,
2514                 path,
2515                 path,
2516                 DB_HASH,
2517                 DB_CREATE,
2518                 0644);
2519 #elif DB_VERSION_MAJOR >= 3
2520         DB *result = 0;
2521         db_create(&result, NULL, 0);
2522         result->open(result,
2523                 path,
2524                 path,
2525                 DB_HASH,
2526                 DB_CREATE,
2527                 0644);
2528 #elif DB_VERSION_MAJOR >= 2
2529         DB *result = 0;
2530         db_open(path,
2531                 DB_HASH,
2532                 DB_CREATE,
2533                 0644,
2534                 (DB_ENV *) 0,
2535                 (DB_INFO *) 0,
2536                 &result);
2537 #endif /* DB_VERSION_MAJOR */
2538 #else
2539         DB *result = dbopen(path,
2540                      2,
2541                      0644,
2542                      DB_HASH,
2543                      0);
2544 #endif
2545         ${cf_cv_main_return:-return}(result != 0)
2546 ],[
2547         if test -n "$cf_db_libs" ; then
2548                 cf_cv_hashed_db_libs=$cf_db_libs
2549         else
2550                 cf_cv_hashed_db_libs=default
2551         fi
2552         LIBS="$cf_save_libs"
2553         break
2554 ])
2555         LIBS="$cf_save_libs"
2556 done
2557 ])
2558 ])dnl
2559 dnl ---------------------------------------------------------------------------
2560 dnl CF_HASHED_DB_VERSION version: 3 updated: 2007/12/01 15:01:37
2561 dnl --------------------
2562 dnl Given that we have the header file for hashed database, find the version
2563 dnl information.
2564 AC_DEFUN([CF_HASHED_DB_VERSION],
2565 [
2566 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
2567 cf_cv_hashed_db_version=unknown
2568
2569 for cf_db_version in 1 2 3 4 5
2570 do
2571         CF_MSG_LOG(checking for db version $cf_db_version)
2572         AC_TRY_COMPILE([
2573 $ac_includes_default
2574 #include <db.h>
2575
2576 #ifdef DB_VERSION_MAJOR
2577         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
2578 #if $cf_db_version == DB_VERSION_MAJOR
2579         /* ok */
2580 #else
2581         make an error
2582 #endif
2583 #else
2584 #if $cf_db_version == 1
2585         /* ok: assuming this is DB 1.8.5 */
2586 #else
2587         make an error
2588 #endif
2589 #endif
2590 ],[DBT *foo = 0],[
2591         cf_cv_hashed_db_version=$cf_db_version
2592         break
2593         ])
2594 done
2595 ])
2596 ])dnl
2597 dnl ---------------------------------------------------------------------------
2598 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
2599 dnl --------------
2600 dnl Construct a search-list of directories for a nonstandard header-file
2601 dnl
2602 dnl Parameters
2603 dnl     $1 = the variable to return as result
2604 dnl     $2 = the package name
2605 AC_DEFUN([CF_HEADER_PATH],
2606 [
2607 $1=
2608
2609 # collect the current set of include-directories from compiler flags
2610 cf_header_path_list=""
2611 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2612         for cf_header_path in $CPPFLAGS $CFLAGS
2613         do
2614                 case $cf_header_path in #(vi
2615                 -I*)
2616                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2617                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2618                         cf_header_path_list="$cf_header_path_list [$]$1"
2619                         ;;
2620                 esac
2621         done
2622 fi
2623
2624 # add the variations for the package we are looking for
2625 CF_SUBDIR_PATH($1,$2,include)
2626
2627 test "$includedir" != NONE && \
2628 test "$includedir" != "/usr/include" && \
2629 test -d "$includedir" && {
2630         test -d $includedir &&    $1="[$]$1 $includedir"
2631         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
2632 }
2633
2634 test "$oldincludedir" != NONE && \
2635 test "$oldincludedir" != "/usr/include" && \
2636 test -d "$oldincludedir" && {
2637         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
2638         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
2639 }
2640
2641 $1="[$]$1 $cf_header_path_list"
2642 ])dnl
2643 dnl ---------------------------------------------------------------------------
2644 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
2645 dnl ---------------
2646 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2647 AC_DEFUN([CF_HELP_MESSAGE],
2648 [AC_DIVERT_HELP([$1])dnl
2649 ])dnl
2650 dnl ---------------------------------------------------------------------------
2651 dnl CF_INCLUDE_DIRS version: 6 updated: 2009/01/06 19:37:40
2652 dnl ---------------
2653 dnl Construct the list of include-options according to whether we're building
2654 dnl in the source directory or using '--srcdir=DIR' option.  If we're building
2655 dnl with gcc, don't append the includedir if it happens to be /usr/include,
2656 dnl since that usually breaks gcc's shadow-includes.
2657 AC_DEFUN([CF_INCLUDE_DIRS],
2658 [
2659 CPPFLAGS="$CPPFLAGS -I. -I../include"
2660 if test "$srcdir" != "."; then
2661         CPPFLAGS="$CPPFLAGS -I\${srcdir}/../include"
2662 fi
2663 if test "$GCC" != yes; then
2664         CPPFLAGS="$CPPFLAGS -I\${includedir}"
2665 elif test "$includedir" != "/usr/include"; then
2666         if test "$includedir" = '${prefix}/include' ; then
2667                 if test $prefix != /usr ; then
2668                         CPPFLAGS="$CPPFLAGS -I\${includedir}"
2669                 fi
2670         else
2671                 CPPFLAGS="$CPPFLAGS -I\${includedir}"
2672         fi
2673 fi
2674 AC_SUBST(CPPFLAGS)
2675 ])dnl
2676 dnl ---------------------------------------------------------------------------
2677 dnl CF_INTEL_COMPILER version: 4 updated: 2010/05/26 05:38:42
2678 dnl -----------------
2679 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2680 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2681 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2682 dnl
2683 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2684 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2685 dnl the wrappers for gcc and g++ warnings.
2686 dnl
2687 dnl $1 = GCC (default) or GXX
2688 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2689 dnl $3 = CFLAGS (default) or CXXFLAGS
2690 AC_DEFUN([CF_INTEL_COMPILER],[
2691 ifelse([$2],,INTEL_COMPILER,[$2])=no
2692
2693 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2694         case $host_os in
2695         linux*|gnu*)
2696                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2697                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2698                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2699                 AC_TRY_COMPILE([],[
2700 #ifdef __INTEL_COMPILER
2701 #else
2702 make an error
2703 #endif
2704 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2705 cf_save_CFLAGS="$cf_save_CFLAGS -we147 -no-gcc"
2706 ],[])
2707                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2708                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2709                 ;;
2710         esac
2711 fi
2712 ])dnl
2713 dnl ---------------------------------------------------------------------------
2714 dnl CF_ISASCII version: 3 updated: 2000/08/12 23:18:52
2715 dnl ----------
2716 dnl Check if we have either a function or macro for 'isascii()'.
2717 AC_DEFUN([CF_ISASCII],
2718 [
2719 AC_MSG_CHECKING(for isascii)
2720 AC_CACHE_VAL(cf_cv_have_isascii,[
2721         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
2722         [cf_cv_have_isascii=yes],
2723         [cf_cv_have_isascii=no])
2724 ])dnl
2725 AC_MSG_RESULT($cf_cv_have_isascii)
2726 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII)
2727 ])dnl
2728 dnl ---------------------------------------------------------------------------
2729 dnl CF_LARGEFILE version: 7 updated: 2007/06/02 11:58:50
2730 dnl ------------
2731 dnl Add checks for large file support.
2732 AC_DEFUN([CF_LARGEFILE],[
2733 ifdef([AC_FUNC_FSEEKO],[
2734     AC_SYS_LARGEFILE
2735     if test "$enable_largefile" != no ; then
2736         AC_FUNC_FSEEKO
2737
2738         # Normally we would collect these definitions in the config.h,
2739         # but (like _XOPEN_SOURCE), some environments rely on having these
2740         # defined before any of the system headers are included.  Another
2741         # case comes up with C++, e.g., on AIX the compiler compiles the
2742         # header files by themselves before looking at the body files it is
2743         # told to compile.  For ncurses, those header files do not include
2744         # the config.h
2745         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
2746         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
2747         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
2748
2749         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2750                 AC_TRY_COMPILE([
2751 #include <sys/types.h>
2752 #include <dirent.h>
2753                 ],[
2754                 /* if transitional largefile support is setup, this is true */
2755                 extern struct dirent64 * readdir(DIR *);
2756                 struct dirent64 *x = readdir((DIR *)0);
2757                 struct dirent *y = readdir((DIR *)0);
2758                 int z = x - y;
2759                 ],
2760                 [cf_cv_struct_dirent64=yes],
2761                 [cf_cv_struct_dirent64=no])
2762         ])
2763         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64)
2764     fi
2765 ])
2766 ])
2767 dnl ---------------------------------------------------------------------------
2768 dnl CF_LDFLAGS_STATIC version: 10 updated: 2011/09/24 12:51:48
2769 dnl -----------------
2770 dnl Check for compiler/linker flags used to temporarily force usage of static
2771 dnl libraries.  This depends on the compiler and platform.  Use this to help
2772 dnl ensure that the linker picks up a given library based on its position in
2773 dnl the list of linker options and libraries.
2774 AC_DEFUN([CF_LDFLAGS_STATIC],[
2775
2776 if test "$GCC" = yes ; then
2777         case $cf_cv_system_name in #(
2778         OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)         #( vi
2779                 LDFLAGS_STATIC=
2780                 LDFLAGS_SHARED=
2781                 ;;
2782     *)  #( normally, except when broken
2783         LDFLAGS_STATIC=-static
2784         LDFLAGS_SHARED=-dynamic
2785         ;;
2786     esac
2787 else
2788         case $cf_cv_system_name in #(
2789         aix[[4-7]]*)    #( from ld manpage
2790                 LDFLAGS_STATIC=-bstatic
2791                 LDFLAGS_SHARED=-bdynamic
2792                 ;;
2793         hpux*)          #( from ld manpage for hpux10.20, hpux11.11
2794                 # We could also use just "archive" and "shared".
2795                 LDFLAGS_STATIC=-Wl,-a,archive_shared
2796                 LDFLAGS_SHARED=-Wl,-a,shared_archive
2797                 ;;
2798         irix*)          #( from ld manpage IRIX64
2799                 LDFLAGS_STATIC=-Bstatic
2800                 LDFLAGS_SHARED=-Bdynamic
2801                 ;;
2802         osf[[45]]*)     #( from ld manpage osf4.0d, osf5.1
2803                 # alternative "-oldstyle_liblookup" (not in cc manpage)
2804                 LDFLAGS_STATIC=-noso
2805                 LDFLAGS_SHARED=-so_archive
2806                 ;;
2807         solaris2*)
2808                 LDFLAGS_STATIC=-Bstatic
2809                 LDFLAGS_SHARED=-Bdynamic
2810                 ;;
2811         esac
2812 fi
2813
2814 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
2815 then
2816         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
2817
2818         rm -f libconftest.a
2819         cat >conftest.$ac_ext <<EOF
2820 #line __oline__ "configure"
2821 #include <stdio.h>
2822 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
2823 EOF
2824         if AC_TRY_EVAL(ac_compile) ; then
2825                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
2826                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
2827         fi
2828         rm -f conftest.*
2829
2830         cf_save_LIBS="$LIBS"
2831
2832         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
2833         AC_TRY_LINK([
2834 #line __oline__ "configure"
2835 #include <stdio.h>
2836 int cf_ldflags_static(FILE *fp);
2837 ],[
2838         return cf_ldflags_static(stdin);
2839 ],[
2840         # some linkers simply ignore the -dynamic
2841         case x`file conftest$ac_exeext 2>/dev/null` in #(vi
2842         *static*) # (vi
2843                 cf_ldflags_static=no
2844                 ;;
2845         *)
2846                 cf_ldflags_static=yes
2847                 ;;
2848         esac
2849 ],[cf_ldflags_static=no])
2850
2851         rm -f libconftest.*
2852         LIBS="$cf_save_LIBS"
2853
2854         AC_MSG_RESULT($cf_ldflags_static)
2855
2856         if test $cf_ldflags_static != yes
2857         then
2858                 LDFLAGS_STATIC=
2859                 LDFLAGS_SHARED=
2860         fi
2861 else
2862         LDFLAGS_STATIC=
2863         LDFLAGS_SHARED=
2864 fi
2865
2866 AC_SUBST(LDFLAGS_STATIC)
2867 AC_SUBST(LDFLAGS_SHARED)
2868 ])
2869 dnl ---------------------------------------------------------------------------
2870 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
2871 dnl ---------------
2872 dnl For the given system and compiler, find the compiler flags to pass to the
2873 dnl loader to use the "rpath" feature.
2874 AC_DEFUN([CF_LD_RPATH_OPT],
2875 [
2876 AC_REQUIRE([CF_CHECK_CACHE])
2877
2878 LD_RPATH_OPT=
2879 AC_MSG_CHECKING(for an rpath option)
2880 case $cf_cv_system_name in #(vi
2881 irix*) #(vi
2882         if test "$GCC" = yes; then
2883                 LD_RPATH_OPT="-Wl,-rpath,"
2884         else
2885                 LD_RPATH_OPT="-rpath "
2886         fi
2887         ;;
2888 linux*|gnu*|k*bsd*-gnu) #(vi
2889         LD_RPATH_OPT="-Wl,-rpath,"
2890         ;;
2891 openbsd[[2-9]].*|mirbsd*) #(vi
2892         LD_RPATH_OPT="-Wl,-rpath,"
2893         ;;
2894 dragonfly*|freebsd*) #(vi
2895         LD_RPATH_OPT="-rpath "
2896         ;;
2897 netbsd*) #(vi
2898         LD_RPATH_OPT="-Wl,-rpath,"
2899         ;;
2900 osf*|mls+*) #(vi
2901         LD_RPATH_OPT="-rpath "
2902         ;;
2903 solaris2*) #(vi
2904         LD_RPATH_OPT="-R"
2905         ;;
2906 *)
2907         ;;
2908 esac
2909 AC_MSG_RESULT($LD_RPATH_OPT)
2910
2911 case "x$LD_RPATH_OPT" in #(vi
2912 x-R*)
2913         AC_MSG_CHECKING(if we need a space after rpath option)
2914         cf_save_LIBS="$LIBS"
2915         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
2916         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
2917         LIBS="$cf_save_LIBS"
2918         AC_MSG_RESULT($cf_rpath_space)
2919         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
2920         ;;
2921 esac
2922 ])dnl
2923 dnl ---------------------------------------------------------------------------
2924 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
2925 dnl ---------------
2926 dnl Construct a search-list of directories for a nonstandard library-file
2927 dnl
2928 dnl Parameters
2929 dnl     $1 = the variable to return as result
2930 dnl     $2 = the package name
2931 AC_DEFUN([CF_LIBRARY_PATH],
2932 [
2933 $1=
2934 cf_library_path_list=""
2935 if test -n "${LDFLAGS}${LIBS}" ; then
2936         for cf_library_path in $LDFLAGS $LIBS
2937         do
2938                 case $cf_library_path in #(vi
2939                 -L*)
2940                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
2941                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
2942                         cf_library_path_list="$cf_library_path_list [$]$1"
2943                         ;;
2944                 esac
2945         done
2946 fi
2947
2948 CF_SUBDIR_PATH($1,$2,lib)
2949
2950 $1="$cf_library_path_list [$]$1"
2951 ])dnl
2952 dnl ---------------------------------------------------------------------------
2953 dnl CF_LIB_PREFIX version: 8 updated: 2008/09/13 11:34:16
2954 dnl -------------
2955 dnl Compute the library-prefix for the given host system
2956 dnl $1 = variable to set
2957 AC_DEFUN([CF_LIB_PREFIX],
2958 [
2959         case $cf_cv_system_name in #(vi
2960         OS/2*|os2*) #(vi
2961         LIB_PREFIX=''
2962         ;;
2963         *)      LIB_PREFIX='lib'
2964         ;;
2965         esac
2966 ifelse($1,,,[$1=$LIB_PREFIX])
2967         AC_SUBST(LIB_PREFIX)
2968 ])dnl
2969 dnl ---------------------------------------------------------------------------
2970 dnl CF_LIB_RULES version: 61 updated: 2010/10/23 16:10:30
2971 dnl ------------
2972 dnl Append definitions and rules for the given models to the subdirectory
2973 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
2974 dnl subdirectory is a library-source directory, modify the LIBS_TO_MAKE list in
2975 dnl the corresponding makefile to list the models that we'll generate.
2976 dnl
2977 dnl For shared libraries, make a list of symbolic links to construct when
2978 dnl generating each library.  The convention used for Linux is the simplest
2979 dnl one:
2980 dnl     lib<name>.so    ->
2981 dnl     lib<name>.so.<major>    ->
2982 dnl     lib<name>.so.<maj>.<minor>
2983 AC_DEFUN([CF_LIB_RULES],
2984 [
2985 CF_LIB_PREFIX(cf_prefix)
2986 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
2987
2988 if test $cf_cv_shlib_version = cygdll ; then
2989         TINFO_NAME=$TINFO_ARG_SUFFIX
2990         TINFO_SUFFIX=.dll
2991 fi
2992
2993 if test -n "$TINFO_SUFFIX" ; then
2994         case $TINFO_SUFFIX in
2995         tw*)
2996                 TINFO_NAME="${TINFO_NAME}tw"
2997                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw//'`
2998                 ;;
2999         t*)
3000                 TINFO_NAME="${TINFO_NAME}t"
3001                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t//'`
3002                 ;;
3003         w*)
3004                 TINFO_NAME="${TINFO_NAME}w"
3005                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w//'`
3006                 ;;
3007         esac
3008 fi
3009
3010 for cf_dir in $SRC_SUBDIRS
3011 do
3012         if test ! -d $srcdir/$cf_dir ; then
3013                 continue
3014         elif test -f $srcdir/$cf_dir/modules; then
3015
3016                 SHARED_LIB=
3017                 LIBS_TO_MAKE=
3018                 for cf_item in $cf_LIST_MODELS
3019                 do
3020                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3021                         if test $cf_item = shared ; then
3022                         if test "$cf_cv_do_symlinks" = yes ; then
3023                                 case "$cf_cv_shlib_version" in #(vi
3024                                 rel) #(vi
3025                                         case "$cf_cv_system_name" in #(vi
3026                                         darwin*)
3027                                         case .${LIB_SUFFIX} in
3028                                         .tw*)
3029                                                 cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3030                                                 cf_suffix=tw'.${REL_VERSION}'"$cf_suffix"
3031                                                 ;;
3032                                         .t*)
3033                                                 cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3034                                                 cf_suffix=t'.${REL_VERSION}'"$cf_suffix"
3035                                                 ;;
3036                                         .w*)
3037                                                 cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3038                                                 cf_suffix=w'.${REL_VERSION}'"$cf_suffix"
3039                                                 ;;
3040                                         *)
3041                                                 cf_suffix='.${REL_VERSION}'"$cf_suffix"
3042                                                 ;;
3043                                         esac
3044                                         ;; #(vi
3045                                         *) cf_suffix="$cf_suffix"'.${REL_VERSION}' ;;
3046                                         esac
3047                                         ;;
3048                                 abi)
3049                                         case "$cf_cv_system_name" in #(vi
3050                                         darwin*)
3051                                         case .${LIB_SUFFIX} in
3052                                         .tw*)
3053                                                 cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3054                                                 cf_suffix=tw'.${ABI_VERSION}'"$cf_suffix"
3055                                                 ;;
3056                                         .t*)
3057                                                 cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3058                                                 cf_suffix=t'.${ABI_VERSION}'"$cf_suffix"
3059                                                 ;;
3060                                         .w*)
3061                                                 cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3062                                                 cf_suffix=w'.${ABI_VERSION}'"$cf_suffix"
3063                                                 ;;
3064                                         *)
3065                                                 cf_suffix='.${ABI_VERSION}'"$cf_suffix"
3066                                                 ;;
3067                                         esac
3068                                         ;; #(vi
3069                                         *) cf_suffix="$cf_suffix"'.${ABI_VERSION}' ;;
3070                                         esac
3071                                         ;;
3072                                 esac
3073                         fi
3074                         # cygwin needs import library, and has unique naming convention
3075                         # use autodetected ${cf_prefix} for import lib and static lib, but
3076                         # use 'cyg' prefix for shared lib.
3077                         if test $cf_cv_shlib_version = cygdll ; then
3078                                 cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3079                                 LIBS_TO_MAKE="$LIBS_TO_MAKE ../lib/cyg${cf_dir}${cf_cygsuf}"
3080                                 continue
3081                         fi
3082                         fi
3083                         LIBS_TO_MAKE="$LIBS_TO_MAKE ../lib/${cf_prefix}${cf_dir}${cf_suffix}"
3084                 done
3085
3086                 if test $cf_dir = ncurses ; then
3087                         cf_subsets="$LIB_SUBSETS"
3088                         cf_r_parts="$cf_subsets"
3089                         cf_liblist="$LIBS_TO_MAKE"
3090
3091                         while test -n "$cf_r_parts"
3092                         do
3093                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3094                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3095                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3096                                         cf_item=
3097                                         case $cf_l_parts in #(vi
3098                                         *termlib*) #(vi
3099                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3100                                                 ;;
3101                                         *ticlib*)
3102                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3103                                                 ;;
3104                                         *)
3105                                                 break
3106                                                 ;;
3107                                         esac
3108                                         if test -n "$cf_item"; then
3109                                                 LIBS_TO_MAKE="$cf_item $LIBS_TO_MAKE"
3110                                         fi
3111                                 else
3112                                         break
3113                                 fi
3114                         done
3115                 else
3116                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3117                 fi
3118
3119                 sed -e "s%@LIBS_TO_MAKE@%$LIBS_TO_MAKE%" \
3120                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3121                         $cf_dir/Makefile >$cf_dir/Makefile.out
3122                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3123
3124                 $AWK -f $srcdir/mk-0th.awk \
3125                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" \
3126                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3127
3128                 for cf_subset in $cf_subsets
3129                 do
3130                         cf_subdirs=
3131                         for cf_item in $cf_LIST_MODELS
3132                         do
3133                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3134                         CF_UPPER(cf_ITEM,$cf_item)
3135                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3136                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3137
3138                         # Test for case where we build libtinfo with a different name.
3139                         cf_libname=$cf_dir
3140                         if test $cf_dir = ncurses ; then
3141                                 case $cf_subset in
3142                                 *base*)
3143                                         cf_libname=${cf_libname}$LIB_SUFFIX
3144                                         ;;
3145                                 *termlib*)
3146                                         cf_libname=$TINFO_LIB_SUFFIX
3147                                         ;;
3148                                 ticlib*)
3149                                         cf_libname=$TICS_LIB_SUFFIX
3150                                         ;;
3151                                 esac
3152                         else
3153                                 cf_libname=${cf_libname}$LIB_SUFFIX
3154                         fi
3155                         if test -n "${DFT_ARG_SUFFIX}" ; then
3156                                 # undo $LIB_SUFFIX add-on in CF_LIB_SUFFIX
3157                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${LIB_SUFFIX}%%"`
3158                         fi
3159
3160                         # These dependencies really are for development, not
3161                         # builds, but they are useful in porting, too.
3162                         cf_depend="../include/ncurses_cfg.h"
3163                         if test "$srcdir" = "."; then
3164                                 cf_reldir="."
3165                         else
3166                                 cf_reldir="\${srcdir}"
3167                         fi
3168
3169                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3170                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3171                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3172                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3173                         fi
3174
3175                         cf_dir_suffix=
3176                         old_cf_suffix="$cf_suffix"
3177                         if test "$cf_cv_shlib_version_infix" = yes ; then
3178                         if test -n "$LIB_SUFFIX" ; then
3179                                 case $LIB_SUFFIX in
3180                                 tw*)
3181                                         cf_libname=`echo $cf_libname | sed 's/tw$//'`
3182                                         cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3183                                         cf_dir_suffix=tw
3184                                         ;;
3185                                 t*)
3186                                         cf_libname=`echo $cf_libname | sed 's/t$//'`
3187                                         cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3188                                         cf_dir_suffix=t
3189                                         ;;
3190                                 w*)
3191                                         cf_libname=`echo $cf_libname | sed 's/w$//'`
3192                                         cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3193                                         cf_dir_suffix=w
3194                                         ;;
3195                                 esac
3196                         fi
3197                         fi
3198
3199                         $AWK -f $srcdir/mk-1st.awk \
3200                                 name=${cf_libname}${cf_dir_suffix} \
3201                                 traces=$LIB_TRACING \
3202                                 MODEL=$cf_ITEM \
3203                                 model=$cf_subdir \
3204                                 prefix=$cf_prefix \
3205                                 suffix=$cf_suffix \
3206                                 subset=$cf_subset \
3207                                 SymLink="$LN_S" \
3208                                 TermlibRoot=$TINFO_NAME \
3209                                 TermlibSuffix=$TINFO_SUFFIX \
3210                                 ShlibVer=$cf_cv_shlib_version \
3211                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3212                                 ReLink=${cf_cv_do_relink:-no} \
3213                                 DoLinks=$cf_cv_do_symlinks \
3214                                 rmSoLocs=$cf_cv_rm_so_locs \
3215                                 ldconfig="$LDCONFIG" \
3216                                 overwrite=$WITH_OVERWRITE \
3217                                 depend="$cf_depend" \
3218                                 host="$host" \
3219                                 libtool_version="$LIBTOOL_VERSION" \
3220                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3221
3222                         cf_suffix="$old_cf_suffix"
3223
3224                         for cf_subdir2 in $cf_subdirs lib
3225                         do
3226                                 test $cf_subdir = $cf_subdir2 && break
3227                         done
3228                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3229                         $AWK -f $srcdir/mk-2nd.awk \
3230                                 name=$cf_dir \
3231                                 traces=$LIB_TRACING \
3232                                 MODEL=$cf_ITEM \
3233                                 model=$cf_subdir \
3234                                 subset=$cf_subset \
3235                                 srcdir=$srcdir \
3236                                 echo=$WITH_ECHO \
3237                                 crenames=$cf_cv_prog_CC_c_o \
3238                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3239                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3240                         cf_subdirs="$cf_subdirs $cf_subdir"
3241                         done
3242                 done
3243         fi
3244
3245         echo '  cd '$cf_dir' && ${MAKE} ${CF_MFLAGS} [$]@' >>Makefile
3246 done
3247
3248 for cf_dir in $SRC_SUBDIRS
3249 do
3250         if test ! -d $srcdir/$cf_dir ; then
3251                 continue
3252         fi
3253
3254         if test -f $cf_dir/Makefile ; then
3255                 case "$cf_dir" in
3256                 Ada95) #(vi
3257                         echo 'libs \' >> Makefile
3258                         echo 'install.libs \' >> Makefile
3259                         echo 'uninstall.libs ::' >> Makefile
3260                         echo '  cd '$cf_dir' && ${MAKE} ${CF_MFLAGS} [$]@' >> Makefile
3261                         ;;
3262                 esac
3263         fi
3264
3265         if test -f $srcdir/$cf_dir/modules; then
3266                 echo >> Makefile
3267                 if test -f $srcdir/$cf_dir/headers; then
3268 cat >> Makefile <<CF_EOF
3269 install.includes \\
3270 uninstall.includes \\
3271 CF_EOF
3272                 fi
3273 if test "$cf_dir" != "c++" ; then
3274 echo 'lint \' >> Makefile
3275 fi
3276 cat >> Makefile <<CF_EOF
3277 libs \\
3278 lintlib \\
3279 install.libs \\
3280 uninstall.libs \\
3281 install.$cf_dir \\
3282 uninstall.$cf_dir ::
3283         cd $cf_dir && \${MAKE} \${CF_MFLAGS} \[$]@
3284 CF_EOF
3285         elif test -f $srcdir/$cf_dir/headers; then
3286 cat >> Makefile <<CF_EOF
3287
3288 libs \\
3289 install.libs \\
3290 uninstall.libs \\
3291 install.includes \\
3292 uninstall.includes ::
3293         cd $cf_dir && \${MAKE} \${CF_MFLAGS} \[$]@
3294 CF_EOF
3295 fi
3296 done
3297
3298 cat >> Makefile <<CF_EOF
3299
3300 install.libs uninstall.libs \\
3301 install.data uninstall.data ::
3302 $MAKE_TERMINFO  cd misc && \${MAKE} \${CF_MFLAGS} \[$]@
3303 CF_EOF
3304
3305 if test "x$cf_with_manpages" = xyes; then
3306 cat >> Makefile <<CF_EOF
3307
3308 install.man \\
3309 uninstall.man ::
3310         cd man && \${MAKE} \${CF_MFLAGS} \[$]@
3311 CF_EOF
3312 fi
3313
3314 cat >> Makefile <<CF_EOF
3315
3316 distclean ::
3317         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3318         rm -f headers.sh headers.sed mk_shared_lib.sh
3319         rm -f edit_man.* man_alias.*
3320         rm -rf \${DIRS_TO_MAKE}
3321 CF_EOF
3322
3323 # Special case: tack's manpage lives in its own directory.
3324 if test "x$cf_with_manpages" = xyes; then
3325 if test -d tack ; then
3326 if test -f $srcdir/$tack.h; then
3327 cat >> Makefile <<CF_EOF
3328
3329 install.man \\
3330 uninstall.man ::
3331         cd tack && \${MAKE} \${CF_MFLAGS} \[$]@
3332 CF_EOF
3333 fi
3334 fi
3335 fi
3336
3337 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3338 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3339 dnl anything, and will make it more standardized.  It's awkward to decide this
3340 dnl at configuration because of quoting, so we'll simply make all headers
3341 dnl installed via a script that can do the right thing.
3342
3343 rm -f headers.sed headers.sh
3344
3345 dnl ( generating this script makes the makefiles a little tidier :-)
3346 echo creating headers.sh
3347 cat >headers.sh <<CF_EOF
3348 #! /bin/sh
3349 # This shell script is generated by the 'configure' script.  It is invoked in a
3350 # subdirectory of the build tree.  It generates a sed-script in the parent
3351 # directory that is used to adjust includes for header files that reside in a
3352 # subdirectory of /usr/include, etc.
3353 PRG=""
3354 while test \[$]# != 3
3355 do
3356 PRG="\$PRG \[$]1"; shift
3357 done
3358 DST=\[$]1
3359 REF=\[$]2
3360 SRC=\[$]3
3361 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3362 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3363 echo installing \$SRC in \$DST
3364 CF_EOF
3365
3366 if test $WITH_CURSES_H = yes; then
3367         cat >>headers.sh <<CF_EOF
3368 case \$DST in
3369 /*/include/*)
3370         END=\`basename \$DST\`
3371         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3372         do
3373                 NAME=\`basename \$i\`
3374                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3375         done
3376         ;;
3377 *)
3378         echo "" >> \$TMPSED
3379         ;;
3380 esac
3381 CF_EOF
3382
3383 else
3384         cat >>headers.sh <<CF_EOF
3385 case \$DST in
3386 /*/include/*)
3387         END=\`basename \$DST\`
3388         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3389         do
3390                 NAME=\`basename \$i\`
3391                 if test "\$NAME" = "curses.h"
3392                 then
3393                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3394                         NAME=ncurses.h
3395                 fi
3396                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3397         done
3398         ;;
3399 *)
3400         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3401         ;;
3402 esac
3403 CF_EOF
3404 fi
3405 cat >>headers.sh <<CF_EOF
3406 rm -f \$TMPSRC
3407 sed -f \$TMPSED \$SRC > \$TMPSRC
3408 NAME=\`basename \$SRC\`
3409 CF_EOF
3410 if test $WITH_CURSES_H != yes; then
3411         cat >>headers.sh <<CF_EOF
3412 test "\$NAME" = "curses.h" && NAME=ncurses.h
3413 CF_EOF
3414 fi
3415 cat >>headers.sh <<CF_EOF
3416 # Just in case someone gzip'd manpages, remove the conflicting copy.
3417 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3418
3419 eval \$PRG \$TMPSRC \$DST/\$NAME
3420 rm -f \$TMPSRC \$TMPSED
3421 CF_EOF
3422
3423 chmod 0755 headers.sh
3424
3425 for cf_dir in $SRC_SUBDIRS
3426 do
3427         if test ! -d $srcdir/$cf_dir ; then
3428                 continue
3429         fi
3430
3431         if test -f $srcdir/$cf_dir/headers; then
3432                 $AWK -f $srcdir/mk-hdr.awk \
3433                         subset="$LIB_SUBSETS" \
3434                         compat="$WITH_CURSES_H" \
3435                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3436         fi
3437
3438         if test -f $srcdir/$cf_dir/modules; then
3439                 if test "$cf_dir" != "c++" ; then
3440                         cat >>$cf_dir/Makefile <<"CF_EOF"
3441 depend : ${AUTO_SRC}
3442         makedepend -- ${CPPFLAGS} -- ${C_SRC}
3443
3444 # DO NOT DELETE THIS LINE -- make depend depends on it.
3445 CF_EOF
3446                 fi
3447         fi
3448 done
3449 AC_SUBST(LIBS_TO_MAKE)
3450 ])dnl
3451 dnl ---------------------------------------------------------------------------
3452 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
3453 dnl -------------
3454 dnl Find the and soname for the given shared library.  Set the cache variable
3455 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
3456 dnl variable to "unknown".
3457 dnl
3458 dnl $1 = headers
3459 dnl $2 = code
3460 dnl $3 = library name
3461 AC_DEFUN([CF_LIB_SONAME],
3462 [
3463 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
3464
3465 cf_cv_$3_soname=unknown
3466 if test "$cross_compiling" != yes ; then
3467 cat >conftest.$ac_ext <<CF_EOF
3468 $1
3469 int main()
3470 {
3471 $2
3472         ${cf_cv_main_return:-return}(0);
3473 }
3474 CF_EOF
3475 cf_save_LIBS="$LIBS"
3476         CF_ADD_LIB($3)
3477         if AC_TRY_EVAL(ac_compile) ; then
3478                 if AC_TRY_EVAL(ac_link) ; then
3479                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
3480                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
3481                 fi
3482         fi
3483 rm -rf conftest*
3484 LIBS="$cf_save_LIBS"
3485 fi
3486 ])
3487 ])
3488 dnl ---------------------------------------------------------------------------
3489 dnl CF_LIB_SUFFIX version: 17 updated: 2011/07/02 15:36:04
3490 dnl -------------
3491 dnl Compute the library file-suffix from the given model name
3492 dnl $1 = model name
3493 dnl $2 = variable to set (the nominal library suffix)
3494 dnl $3 = dependency variable to set (actual filename)
3495 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3496 AC_DEFUN([CF_LIB_SUFFIX],
3497 [
3498         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3499         case $1 in #(vi
3500         libtool) #(vi
3501                 $2='.la'
3502                 $3=[$]$2
3503                 ;;
3504         normal) #(vi
3505                 $2='.a'
3506                 $3=[$]$2
3507                 ;;
3508         debug) #(vi
3509                 $2='_g.a'
3510                 $3=[$]$2
3511                 ;;
3512         profile) #(vi
3513                 $2='_p.a'
3514                 $3=[$]$2
3515                 ;;
3516         shared) #(vi
3517                 case $cf_cv_system_name in
3518                 aix[[5-7]]*) #(vi
3519                         $2='.a'
3520                         $3=[$]$2
3521                         ;;
3522                 cygwin*) #(vi
3523                         $2='.dll'
3524                         $3='.dll.a'
3525                         ;;
3526                 darwin*) #(vi
3527                         $2='.dylib'
3528                         $3=[$]$2
3529                         ;;
3530                 hpux*) #(vi
3531                         case $target in
3532                         ia64*) #(vi
3533                                 $2='.so'
3534                                 $3=[$]$2
3535                                 ;;
3536                         *) #(vi
3537                                 $2='.sl'
3538                                 $3=[$]$2
3539                                 ;;
3540                         esac
3541                         ;;
3542                 *)      $2='.so'
3543                         $3=[$]$2
3544                         ;;
3545                 esac
3546         esac
3547         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3548         test -n "$LIB_SUFFIX" && $3="${LIB_SUFFIX}[$]{$3}"
3549 ])dnl
3550 dnl ---------------------------------------------------------------------------
3551 dnl CF_LIB_TYPE version: 4 updated: 2000/10/20 22:57:49
3552 dnl -----------
3553 dnl Compute the string to append to -library from the given model name
3554 dnl $1 = model name
3555 dnl $2 = variable to set
3556 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3557 AC_DEFUN([CF_LIB_TYPE],
3558 [
3559         case $1 in
3560         libtool) $2=''   ;;
3561         normal)  $2=''   ;;
3562         debug)   $2='_g' ;;
3563         profile) $2='_p' ;;
3564         shared)  $2=''   ;;
3565         esac
3566         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3567 ])dnl
3568 dnl ---------------------------------------------------------------------------
3569 dnl CF_LINK_DATAONLY version: 9 updated: 2009/01/01 20:21:38
3570 dnl ----------------
3571 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
3572 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
3573 dnl have to provide wrappers for global tables to ensure they're linked
3574 dnl properly.
3575 AC_DEFUN([CF_LINK_DATAONLY],
3576 [
3577 AC_MSG_CHECKING([if data-only library module links])
3578 AC_CACHE_VAL(cf_cv_link_dataonly,[
3579         rm -f conftest.a
3580         cat >conftest.$ac_ext <<EOF
3581 #line __oline__ "configure"
3582 int     testdata[[3]] = { 123, 456, 789 };
3583 EOF
3584         if AC_TRY_EVAL(ac_compile) ; then
3585                 mv conftest.o data.o && \
3586                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
3587         fi
3588         rm -f conftest.$ac_ext data.o
3589         cat >conftest.$ac_ext <<EOF
3590 #line __oline__ "configure"
3591 int     testfunc()
3592 {
3593 #if defined(NeXT)
3594         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
3595 #else
3596         extern int testdata[[3]];
3597         return testdata[[0]] == 123
3598            &&  testdata[[1]] == 456
3599            &&  testdata[[2]] == 789;
3600 #endif
3601 }
3602 EOF
3603         if AC_TRY_EVAL(ac_compile); then
3604                 mv conftest.o func.o && \
3605                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
3606         fi
3607         rm -f conftest.$ac_ext func.o
3608         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
3609         cf_saveLIBS="$LIBS"
3610         LIBS="conftest.a $LIBS"
3611         AC_TRY_RUN([
3612         int main()
3613         {
3614                 extern int testfunc();
3615                 ${cf_cv_main_return:-return} (!testfunc());
3616         }
3617         ],
3618         [cf_cv_link_dataonly=yes],
3619         [cf_cv_link_dataonly=no],
3620         [cf_cv_link_dataonly=unknown])
3621         LIBS="$cf_saveLIBS"
3622         ])
3623 AC_MSG_RESULT($cf_cv_link_dataonly)
3624
3625 if test "$cf_cv_link_dataonly" = no ; then
3626         AC_DEFINE(BROKEN_LINKER)
3627         BROKEN_LINKER=1
3628 fi
3629
3630 ])dnl
3631 dnl ---------------------------------------------------------------------------
3632 dnl CF_LINK_FUNCS version: 7 updated: 2006/12/16 12:33:30
3633 dnl -------------
3634 dnl Most Unix systems have both link and symlink, a few don't have symlink.
3635 dnl A few non-Unix systems implement symlink, but not link.
3636 dnl A few non-systems implement neither (or have nonfunctional versions).
3637 AC_DEFUN([CF_LINK_FUNCS],
3638 [
3639 AC_CHECK_FUNCS( \
3640         remove \
3641         unlink )
3642
3643 if test "$cross_compiling" = yes ; then
3644         AC_CHECK_FUNCS( \
3645                 link \
3646                 symlink )
3647 else
3648         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
3649                 cf_cv_link_funcs=
3650                 for cf_func in link symlink ; do
3651                         AC_TRY_RUN([
3652 #include <sys/types.h>
3653 #include <sys/stat.h>
3654 #ifdef HAVE_UNISTD_H
3655 #include <unistd.h>
3656 #endif
3657 int main()
3658 {
3659         int fail = 0;
3660         char *src = "config.log";
3661         char *dst = "conftest.chk";
3662         struct stat src_sb;
3663         struct stat dst_sb;
3664
3665         stat(src, &src_sb);
3666         fail = ($cf_func("config.log", "conftest.chk") < 0)
3667             || (stat(dst, &dst_sb) < 0)
3668             || (dst_sb.st_mtime != src_sb.st_mtime);
3669 #ifdef HAVE_UNLINK
3670         unlink(dst);
3671 #else
3672         remove(dst);
3673 #endif
3674         ${cf_cv_main_return:-return} (fail);
3675 }
3676                         ],[
3677                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
3678                         eval 'ac_cv_func_'$cf_func'=yes'],[
3679                         eval 'ac_cv_func_'$cf_func'=no'],[
3680                         eval 'ac_cv_func_'$cf_func'=error'])
3681                 done
3682                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
3683         ])
3684         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK)
3685         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK)
3686 fi
3687 ])dnl
3688 dnl ---------------------------------------------------------------------------
3689 dnl CF_MAIN_RETURN version: 1 updated: 2006/12/10 09:51:54
3690 dnl --------------
3691 dnl Check if a return from main to the shell actually returns the same exit
3692 dnl code.  This is true for almost any POSIX environment.
3693 dnl
3694 dnl Some very old environments did not flush stdout, etc., on an exit.  That
3695 dnl would be a useful case to test for also.
3696 AC_DEFUN([CF_MAIN_RETURN],
3697 [
3698 cf_cv_main_return=return
3699 ])dnl
3700 dnl ---------------------------------------------------------------------------
3701 dnl CF_MAKEFLAGS version: 14 updated: 2011/03/31 19:29:46
3702 dnl ------------
3703 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
3704 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
3705 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
3706 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
3707 AC_DEFUN([CF_MAKEFLAGS],
3708 [
3709 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
3710         cf_cv_makeflags=''
3711         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
3712         do
3713                 cat >cf_makeflags.tmp <<CF_EOF
3714 SHELL = /bin/sh
3715 all :
3716         @ echo '.$cf_option'
3717 CF_EOF
3718                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
3719                 case "$cf_result" in
3720                 .*k)
3721                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
3722                         case "$cf_result" in
3723                         .*CC=*) cf_cv_makeflags=
3724                                 ;;
3725                         *)      cf_cv_makeflags=$cf_option
3726                                 ;;
3727                         esac
3728                         break
3729                         ;;
3730                 .-)     ;;
3731                 *)      echo "given option \"$cf_option\", no match \"$cf_result\""
3732                         ;;
3733                 esac
3734         done
3735         rm -f cf_makeflags.tmp
3736 ])
3737
3738 AC_SUBST(cf_cv_makeflags)
3739 ])dnl
3740 dnl ---------------------------------------------------------------------------
3741 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
3742 dnl ------------
3743 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
3744 dnl a monocase filesystem.
3745 AC_DEFUN([CF_MAKE_TAGS],[
3746 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
3747
3748 AC_CHECK_PROGS(CTAGS, exctags ctags)
3749 AC_CHECK_PROGS(ETAGS, exetags etags)
3750
3751 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
3752
3753 if test "$cf_cv_mixedcase" = yes ; then
3754         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
3755 else
3756         MAKE_UPPER_TAGS=no
3757 fi
3758
3759 if test "$MAKE_UPPER_TAGS" = yes ; then
3760         MAKE_UPPER_TAGS=
3761 else
3762         MAKE_UPPER_TAGS="#"
3763 fi
3764
3765 if test "$MAKE_LOWER_TAGS" = yes ; then
3766         MAKE_LOWER_TAGS=
3767 else
3768         MAKE_LOWER_TAGS="#"
3769 fi
3770
3771 AC_SUBST(CTAGS)
3772 AC_SUBST(ETAGS)
3773
3774 AC_SUBST(MAKE_UPPER_TAGS)
3775 AC_SUBST(MAKE_LOWER_TAGS)
3776 ])dnl
3777 dnl ---------------------------------------------------------------------------
3778 dnl CF_MANPAGE_FORMAT version: 9 updated: 2010/10/23 16:10:30
3779 dnl -----------------
3780 dnl Option to allow user to override automatic configuration of manpage format.
3781 dnl There are several special cases:
3782 dnl
3783 dnl     gzip - man checks for, can display gzip'd files
3784 dnl     compress - man checks for, can display compressed files
3785 dnl     BSDI - files in the cat-directories are suffixed ".0"
3786 dnl     formatted - installer should format (put files in cat-directory)
3787 dnl     catonly - installer should only format, e.g., for a turnkey system.
3788 dnl
3789 dnl There are other configurations which this macro does not test, e.g., HPUX's
3790 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
3791 dnl convention would not match our use).
3792 AC_DEFUN([CF_MANPAGE_FORMAT],
3793 [
3794 AC_REQUIRE([CF_PATHSEP])
3795 AC_MSG_CHECKING(format of man-pages)
3796
3797 AC_ARG_WITH(manpage-format,
3798         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
3799                           optionally formatted/catonly, e.g., gzip,formatted],
3800         [MANPAGE_FORMAT=$withval],
3801         [MANPAGE_FORMAT=unknown])
3802
3803 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
3804 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
3805
3806 cf_unknown=
3807
3808 case $MANPAGE_FORMAT in
3809 unknown)
3810   if test -z "$MANPATH" ; then
3811     MANPATH="/usr/man:/usr/share/man"
3812   fi
3813
3814   # look for the 'date' man-page (it's most likely to be installed!)
3815   MANPAGE_FORMAT=
3816   cf_preform=no
3817   cf_catonly=yes
3818   cf_example=date
3819
3820   IFS="${IFS:-  }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
3821   for cf_dir in $MANPATH; do
3822     test -z "$cf_dir" && cf_dir=/usr/man
3823     for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
3824     do
3825       cf_test=`echo $cf_name | sed -e 's/*//'`
3826       if test "x$cf_test" = "x$cf_name" ; then
3827
3828         case "$cf_name" in
3829         *.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
3830         *.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
3831         *.0)    MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
3832         *)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
3833         esac
3834
3835         case "$cf_name" in
3836         $cf_dir/man*)
3837           cf_catonly=no
3838           ;;
3839         $cf_dir/cat*)
3840           cf_preform=yes
3841           ;;
3842         esac
3843         break
3844       fi
3845
3846       # if we found a match in either man* or cat*, stop looking
3847       if test -n "$MANPAGE_FORMAT" ; then
3848         cf_found=no
3849         test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
3850         test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
3851         case "$cf_name" in
3852         $cf_dir/cat*)
3853           cf_found=yes
3854           ;;
3855         esac
3856         test $cf_found=yes && break
3857       fi
3858     done
3859     # only check the first directory in $MANPATH where we find manpages
3860     if test -n "$MANPAGE_FORMAT" ; then
3861        break
3862     fi
3863   done
3864   # if we did not find the example, just assume it is normal
3865   test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
3866   IFS="$ac_save_ifs"
3867   ;;
3868 *)
3869   for cf_option in $MANPAGE_FORMAT; do
3870      case $cf_option in #(vi
3871      gzip|compress|BSDI|normal|formatted|catonly)
3872        ;;
3873      *)
3874        cf_unknown="$cf_unknown $cf_option"
3875        ;;
3876      esac
3877   done
3878   ;;
3879 esac
3880
3881 AC_MSG_RESULT($MANPAGE_FORMAT)
3882 if test -n "$cf_unknown" ; then
3883   AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
3884 fi
3885 ])dnl
3886 dnl ---------------------------------------------------------------------------
3887 dnl CF_MANPAGE_RENAMES version: 7 updated: 2005/06/18 18:51:57
3888 dnl ------------------
3889 dnl The Debian people have their own naming convention for manpages.  This
3890 dnl option lets us override the name of the file containing renaming, or
3891 dnl disable it altogether.
3892 AC_DEFUN([CF_MANPAGE_RENAMES],
3893 [
3894 AC_MSG_CHECKING(for manpage renaming)
3895
3896 AC_ARG_WITH(manpage-renames,
3897         [  --with-manpage-renames  specify manpage-renaming],
3898         [MANPAGE_RENAMES=$withval],
3899         [MANPAGE_RENAMES=yes])
3900
3901 case ".$MANPAGE_RENAMES" in #(vi
3902 .no) #(vi
3903   ;;
3904 .|.yes)
3905   # Debian 'man' program?
3906   if test -f /etc/debian_version ; then
3907     MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
3908   else
3909     MANPAGE_RENAMES=no
3910   fi
3911   ;;
3912 esac
3913
3914 if test "$MANPAGE_RENAMES" != no ; then
3915   if test -f $srcdir/man/$MANPAGE_RENAMES ; then
3916     MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
3917   elif test ! -f $MANPAGE_RENAMES ; then
3918     AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
3919   fi
3920
3921   test ! -d man && mkdir man
3922
3923   # Construct a sed-script to perform renaming within man-pages
3924   if test -n "$MANPAGE_RENAMES" ; then
3925     test ! -d man && mkdir man
3926     sh $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
3927   fi
3928 fi
3929
3930 AC_MSG_RESULT($MANPAGE_RENAMES)
3931 AC_SUBST(MANPAGE_RENAMES)
3932 ])dnl
3933 dnl ---------------------------------------------------------------------------
3934 dnl CF_MANPAGE_SYMLINKS version: 5 updated: 2010/07/24 17:12:40
3935 dnl -------------------
3936 dnl Some people expect each tool to make all aliases for manpages in the
3937 dnl man-directory.  This accommodates the older, less-capable implementations
3938 dnl of 'man', and is optional.
3939 AC_DEFUN([CF_MANPAGE_SYMLINKS],
3940 [
3941 AC_MSG_CHECKING(if manpage aliases will be installed)
3942
3943 AC_ARG_WITH(manpage-aliases,
3944         [  --with-manpage-aliases  specify manpage-aliases using .so],
3945         [MANPAGE_ALIASES=$withval],
3946         [MANPAGE_ALIASES=yes])
3947
3948 AC_MSG_RESULT($MANPAGE_ALIASES)
3949
3950 case "x$LN_S" in #(vi
3951 xln*) #(vi
3952         cf_use_symlinks=yes
3953         ;;
3954 *)
3955         cf_use_symlinks=no
3956         ;;
3957 esac
3958
3959 MANPAGE_SYMLINKS=no
3960 if test "$MANPAGE_ALIASES" = yes ; then
3961 AC_MSG_CHECKING(if manpage symlinks should be used)
3962
3963 AC_ARG_WITH(manpage-symlinks,
3964         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
3965         [MANPAGE_SYMLINKS=$withval],
3966         [MANPAGE_SYMLINKS=$cf_use_symlinks])
3967
3968 if test "$$cf_use_symlinks" = no; then
3969 if test "$MANPAGE_SYMLINKS" = yes ; then
3970         AC_MSG_WARN(cannot make symlinks, will use .so files)
3971         MANPAGE_SYMLINKS=no
3972 fi
3973 fi
3974
3975 AC_MSG_RESULT($MANPAGE_SYMLINKS)
3976 fi
3977
3978 ])dnl
3979 dnl ---------------------------------------------------------------------------
3980 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
3981 dnl --------------
3982 dnl This option causes manpages to be run through tbl(1) to generate tables
3983 dnl correctly.
3984 AC_DEFUN([CF_MANPAGE_TBL],
3985 [
3986 AC_MSG_CHECKING(for manpage tbl)
3987
3988 AC_ARG_WITH(manpage-tbl,
3989         [  --with-manpage-tbl      specify manpage processing with tbl],
3990         [MANPAGE_TBL=$withval],
3991         [MANPAGE_TBL=no])
3992
3993 AC_MSG_RESULT($MANPAGE_TBL)
3994 ])dnl
3995 dnl ---------------------------------------------------------------------------
3996 dnl CF_MAN_PAGES version: 40 updated: 2011/09/10 16:20:21
3997 dnl ------------
3998 dnl Try to determine if the man-pages on the system are compressed, and if
3999 dnl so, what format is used.  Use this information to construct a script that
4000 dnl will install man-pages.
4001 AC_DEFUN([CF_MAN_PAGES],
4002 [
4003 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
4004 CF_MANPAGE_FORMAT
4005 CF_MANPAGE_RENAMES
4006 CF_MANPAGE_SYMLINKS
4007 CF_MANPAGE_TBL
4008
4009   if test "$prefix" = "NONE" ; then
4010      cf_prefix="$ac_default_prefix"
4011   else
4012      cf_prefix="$prefix"
4013   fi
4014
4015   case "$MANPAGE_FORMAT" in # (vi
4016   *catonly*) # (vi
4017     cf_format=yes
4018     cf_inboth=no
4019     ;;
4020   *formatted*) # (vi
4021     cf_format=yes
4022     cf_inboth=yes
4023     ;;
4024   *)
4025     cf_format=no
4026     cf_inboth=no
4027     ;;
4028   esac
4029
4030 test ! -d man && mkdir man
4031
4032 cf_so_strip=
4033 cf_compress=
4034 case "$MANPAGE_FORMAT" in #(vi
4035 *compress*) #(vi
4036         cf_so_strip="Z"
4037         cf_compress=compress
4038   ;;
4039 *gzip*)
4040         cf_so_strip="gz"
4041         cf_compress=gzip
4042   ;;
4043 esac
4044
4045 cf_edit_man=./edit_man.sh
4046 cf_man_alias=`pwd`/man_alias.sed
4047
4048 cat >$cf_edit_man <<CF_EOF
4049 #! /bin/sh
4050 # this script is generated by the configure-script CF_MAN_PAGES macro.
4051
4052 prefix="$cf_prefix"
4053 datadir="$datadir"
4054
4055 NCURSES_MAJOR="$NCURSES_MAJOR"
4056 NCURSES_MINOR="$NCURSES_MINOR"
4057 NCURSES_PATCH="$NCURSES_PATCH"
4058
4059 NCURSES_OSPEED="$NCURSES_OSPEED"
4060 TERMINFO="$TERMINFO"
4061
4062 INSTALL="$INSTALL"
4063 INSTALL_DATA="$INSTALL_DATA"
4064
4065 transform="$program_transform_name"
4066
4067 TMP=\${TMPDIR:=/tmp}/man\$\$
4068 trap "rm -f \$TMP" 0 1 2 5 15
4069
4070 form=\[$]1
4071 shift || exit 1
4072
4073 verb=\[$]1
4074 shift || exit 1
4075
4076 mandir=\[$]1
4077 shift || exit 1
4078
4079 srcdir=\[$]1
4080 top_srcdir=\[$]srcdir/..
4081 shift || exit 1
4082
4083 if test "\$form" = normal ; then
4084         if test "$cf_format" = yes ; then
4085         if test "$cf_inboth" = no ; then
4086                 sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4087                 exit $?
4088         fi
4089         fi
4090         cf_subdir=\$mandir/man
4091         cf_tables=$MANPAGE_TBL
4092 else
4093         cf_subdir=\$mandir/cat
4094         cf_tables=yes
4095 fi
4096
4097 # process the list of source-files
4098 for i in \[$]* ; do
4099 case \$i in #(vi
4100 *.orig|*.rej) ;; #(vi
4101 *.[[0-9]]*)
4102         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
4103         if test \$verb = installing ; then
4104         if test ! -d \$cf_subdir\${section} ; then
4105                 mkdir -p \$cf_subdir\$section
4106         fi
4107         fi
4108
4109         # replace variables in man page
4110         if test ! -f $cf_man_alias ; then
4111 cat >>$cf_man_alias <<-CF_EOF2
4112                 s,@DATADIR@,\$datadir,g
4113                 s,@TERMINFO@,\$TERMINFO,g
4114                 s,@NCURSES_MAJOR@,\$NCURSES_MAJOR,g
4115                 s,@NCURSES_MINOR@,\$NCURSES_MINOR,g
4116                 s,@NCURSES_PATCH@,\$NCURSES_PATCH,g
4117                 s,@NCURSES_OSPEED@,\$NCURSES_OSPEED,g
4118 CF_EOF
4119         ifelse($1,,,[
4120         for cf_name in $1
4121         do
4122                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4123                 cf_name=`echo $cf_name|sed "$program_transform_name"`
4124 cat >>$cf_edit_man <<-CF_EOF
4125                 s,@$cf_NAME@,$cf_name,g
4126 CF_EOF
4127         done
4128         ])
4129 cat >>$cf_edit_man <<CF_EOF
4130 CF_EOF2
4131                 echo "...made $cf_man_alias"
4132         fi
4133
4134         aliases=
4135         cf_source=\`basename \$i\`
4136         inalias=\$cf_source
4137         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
4138         if test ! -f \$inalias ; then
4139                 echo .. skipped \$cf_source
4140                 continue
4141         fi
4142 CF_EOF
4143
4144 if test "$MANPAGE_ALIASES" != no ; then
4145 cat >>$cf_edit_man <<CF_EOF
4146         nCurses=ignore.3x
4147         test $with_curses_h = yes && nCurses=ncurses.3x
4148         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
4149 CF_EOF
4150 fi
4151
4152 if test "$MANPAGE_RENAMES" = no ; then
4153 cat >>$cf_edit_man <<CF_EOF
4154         # perform program transformations for section 1 man pages
4155         if test \$section = 1 ; then
4156                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
4157         else
4158                 cf_target=\$cf_subdir\${section}/\$cf_source
4159         fi
4160 CF_EOF
4161 else
4162 cat >>$cf_edit_man <<CF_EOF
4163         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
4164         if test -z "\$cf_target" ; then
4165                 echo '? missing rename for '\$cf_source
4166                 cf_target="\$cf_source"
4167         fi
4168         cf_target="\$cf_subdir\${section}/\${cf_target}"
4169
4170 CF_EOF
4171 fi
4172
4173 cat >>$cf_edit_man <<CF_EOF
4174         sed     -f $cf_man_alias \\
4175 CF_EOF
4176
4177 if test -f $MANPAGE_RENAMES ; then
4178 cat >>$cf_edit_man <<CF_EOF
4179                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
4180 CF_EOF
4181 else
4182 cat >>$cf_edit_man <<CF_EOF
4183                 < \$i >\$TMP
4184 CF_EOF
4185 fi
4186
4187 cat >>$cf_edit_man <<CF_EOF
4188 if test \$cf_tables = yes ; then
4189         tbl \$TMP >\$TMP.out
4190         mv \$TMP.out \$TMP
4191 fi
4192 CF_EOF
4193
4194 if test $with_overwrite != yes ; then
4195 cat >>$cf_edit_man <<CF_EOF
4196         sed -e "/\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
4197         mv \$TMP.out \$TMP
4198 CF_EOF
4199 fi
4200
4201 if test $with_curses_h != yes ; then
4202 cat >>$cf_edit_man <<CF_EOF
4203         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
4204         mv \$TMP.out \$TMP
4205 CF_EOF
4206 fi
4207
4208 cat >>$cf_edit_man <<CF_EOF
4209         if test \$form = format ; then
4210                 nroff -man \$TMP >\$TMP.out
4211                 mv \$TMP.out \$TMP
4212         fi
4213 CF_EOF
4214
4215 if test -n "$cf_compress" ; then
4216 cat >>$cf_edit_man <<CF_EOF
4217         if test \$verb = installing ; then
4218         if ( $cf_compress -f \$TMP )
4219         then
4220                 mv \$TMP.$cf_so_strip \$TMP
4221         fi
4222         fi
4223         cf_target="\$cf_target.$cf_so_strip"
4224 CF_EOF
4225 fi
4226
4227 case "$MANPAGE_FORMAT" in #(vi
4228 *BSDI*)
4229 cat >>$cf_edit_man <<CF_EOF
4230         if test \$form = format ; then
4231                 # BSDI installs only .0 suffixes in the cat directories
4232                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
4233         fi
4234 CF_EOF
4235   ;;
4236 esac
4237
4238 cat >>$cf_edit_man <<CF_EOF
4239         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
4240         if test \$verb = installing ; then
4241                 echo \$verb \$cf_target
4242                 \$INSTALL_DATA \$TMP \$cf_target
4243                 test -d \$cf_subdir\${section} &&
4244                 test -n "\$aliases" && (
4245                         cd \$cf_subdir\${section} && (
4246                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
4247                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
4248                                 cf_target=\`basename \$cf_target\`
4249                                 for cf_alias in \$aliases
4250                                 do
4251                                         if test \$section = 1 ; then
4252                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4253                                         fi
4254
4255                                         if test "$MANPAGE_SYMLINKS" = yes ; then
4256                                                 if test -f \$cf_alias\${suffix} ; then
4257                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
4258                                                         then
4259                                                                 continue
4260                                                         fi
4261                                                 fi
4262                                                 echo .. \$verb alias \$cf_alias\${suffix}
4263 CF_EOF
4264 case "x$LN_S" in #(vi
4265 *-f) #(vi
4266 cat >>$cf_edit_man <<CF_EOF
4267                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4268 CF_EOF
4269         ;;
4270 *)
4271 cat >>$cf_edit_man <<CF_EOF
4272                                                 rm -f \$cf_alias\${suffix}
4273                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4274 CF_EOF
4275         ;;
4276 esac
4277 cat >>$cf_edit_man <<CF_EOF
4278                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
4279                                                 echo ".so \$cf_source" >\$TMP
4280 CF_EOF
4281 if test -n "$cf_compress" ; then
4282 cat >>$cf_edit_man <<CF_EOF
4283                                                 if test -n "$cf_so_strip" ; then
4284                                                         $cf_compress -f \$TMP
4285                                                         mv \$TMP.$cf_so_strip \$TMP
4286                                                 fi
4287 CF_EOF
4288 fi
4289 cat >>$cf_edit_man <<CF_EOF
4290                                                 echo .. \$verb alias \$cf_alias\${suffix}
4291                                                 rm -f \$cf_alias\${suffix}
4292                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
4293                                         fi
4294                                 done
4295                         )
4296                 )
4297         elif test \$verb = removing ; then
4298                 test -f \$cf_target && (
4299                         echo \$verb \$cf_target
4300                         rm -f \$cf_target
4301                 )
4302                 test -d \$cf_subdir\${section} &&
4303                 test -n "\$aliases" && (
4304                         cd \$cf_subdir\${section} && (
4305                                 for cf_alias in \$aliases
4306                                 do
4307                                         if test \$section = 1 ; then
4308                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4309                                         fi
4310
4311                                         echo .. \$verb alias \$cf_alias\${suffix}
4312                                         rm -f \$cf_alias\${suffix}
4313                                 done
4314                         )
4315                 )
4316         else
4317 #               echo ".hy 0"
4318                 cat \$TMP
4319         fi
4320         ;;
4321 esac
4322 done
4323
4324 if test $cf_inboth = yes ; then
4325 if test \$form != format ; then
4326         sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4327 fi
4328 fi
4329
4330 exit 0
4331 CF_EOF
4332 chmod 755 $cf_edit_man
4333
4334 ])dnl
4335 dnl ---------------------------------------------------------------------------
4336 dnl CF_MATH_LIB version: 8 updated: 2010/05/29 16:31:02
4337 dnl -----------
4338 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
4339 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
4340 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
4341 AC_DEFUN([CF_MATH_LIB],
4342 [
4343 AC_CACHE_CHECK(if -lm needed for math functions,
4344         cf_cv_need_libm,[
4345         AC_TRY_LINK([
4346         #include <stdio.h>
4347         #include <math.h>
4348         ],
4349         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
4350         [cf_cv_need_libm=no],
4351         [cf_cv_need_libm=yes])])
4352 if test "$cf_cv_need_libm" = yes
4353 then
4354 ifelse($1,,[
4355         CF_ADD_LIB(m)
4356 ],[$1=-lm])
4357 fi
4358 ])
4359 dnl ---------------------------------------------------------------------------
4360 dnl CF_MIXEDCASE_FILENAMES version: 3 updated: 2003/09/20 17:07:55
4361 dnl ----------------------
4362 dnl Check if the file-system supports mixed-case filenames.  If we're able to
4363 dnl create a lowercase name and see it as uppercase, it doesn't support that.
4364 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
4365 [
4366 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
4367 if test "$cross_compiling" = yes ; then
4368         case $target_alias in #(vi
4369         *-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-mingw32*|*-uwin*) #(vi
4370                 cf_cv_mixedcase=no
4371                 ;;
4372         *)
4373                 cf_cv_mixedcase=yes
4374                 ;;
4375         esac
4376 else
4377         rm -f conftest CONFTEST
4378         echo test >conftest
4379         if test -f CONFTEST ; then
4380                 cf_cv_mixedcase=no
4381         else
4382                 cf_cv_mixedcase=yes
4383         fi
4384         rm -f conftest CONFTEST
4385 fi
4386 ])
4387 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES)
4388 ])dnl
4389 dnl ---------------------------------------------------------------------------
4390 dnl CF_MKSTEMP version: 7 updated: 2010/08/14 18:25:37
4391 dnl ----------
4392 dnl Check for a working mkstemp.  This creates two files, checks that they are
4393 dnl successfully created and distinct (AmigaOS apparently fails on the last).
4394 AC_DEFUN([CF_MKSTEMP],[
4395 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
4396 rm -rf conftest*
4397 AC_TRY_RUN([
4398 #include <sys/types.h>
4399 #include <stdlib.h>
4400 #include <stdio.h>
4401 #include <string.h>
4402 #include <sys/stat.h>
4403 int main()
4404 {
4405         char *tmpl = "conftestXXXXXX";
4406         char name[2][80];
4407         int n;
4408         int result = 0;
4409         int fd;
4410         struct stat sb;
4411
4412         umask(077);
4413         for (n = 0; n < 2; ++n) {
4414                 strcpy(name[n], tmpl);
4415                 if ((fd = mkstemp(name[n])) >= 0) {
4416                         if (!strcmp(name[n], tmpl)
4417                          || stat(name[n], &sb) != 0
4418                          || (sb.st_mode & S_IFMT) != S_IFREG
4419                          || (sb.st_mode & 077) != 0) {
4420                                 result = 1;
4421                         }
4422                         close(fd);
4423                 }
4424         }
4425         if (result == 0
4426          && !strcmp(name[0], name[1]))
4427                 result = 1;
4428         ${cf_cv_main_return:-return}(result);
4429 }
4430 ],[cf_cv_func_mkstemp=yes
4431 ],[cf_cv_func_mkstemp=no
4432 ],[AC_CHECK_FUNC(mkstemp)
4433 ])
4434 ])
4435 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
4436         AC_DEFINE(HAVE_MKSTEMP)
4437 fi
4438 ])dnl
4439 dnl ---------------------------------------------------------------------------
4440 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
4441 dnl ----------
4442 dnl Write a debug message to config.log, along with the line number in the
4443 dnl configure script.
4444 AC_DEFUN([CF_MSG_LOG],[
4445 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
4446 ])dnl
4447 dnl ---------------------------------------------------------------------------
4448 dnl CF_NCURSES_ABI_6 version: 1 updated: 2005/09/17 18:42:49
4449 dnl ----------------
4450 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
4451 dnl warn about this.
4452 AC_DEFUN([CF_NCURSES_ABI_6],[
4453 if test "${with_abi_version+set}" != set; then
4454         case $cf_cv_rel_version in
4455         5.*)
4456                 cf_cv_rel_version=6.0
4457                 cf_cv_abi_version=6
4458                 AC_MSG_WARN(Overriding ABI version to $cf_cv_abi_version)
4459                 ;;
4460         esac
4461 fi
4462 ])dnl
4463 dnl ---------------------------------------------------------------------------
4464 dnl CF_NO_LEAKS_OPTION version: 4 updated: 2006/12/16 14:24:05
4465 dnl ------------------
4466 dnl see CF_WITH_NO_LEAKS
4467 AC_DEFUN([CF_NO_LEAKS_OPTION],[
4468 AC_MSG_CHECKING(if you want to use $1 for testing)
4469 AC_ARG_WITH($1,
4470         [$2],
4471         [AC_DEFINE($3)ifelse([$4],,[
4472          $4
4473 ])
4474         : ${with_cflags:=-g}
4475         : ${with_no_leaks:=yes}
4476          with_$1=yes],
4477         [with_$1=])
4478 AC_MSG_RESULT(${with_$1:-no})
4479
4480 case .$with_cflags in #(vi
4481 .*-g*)
4482         case .$CFLAGS in #(vi
4483         .*-g*) #(vi
4484                 ;;
4485         *)
4486                 CF_ADD_CFLAGS([-g])
4487                 ;;
4488         esac
4489         ;;
4490 esac
4491 ])dnl
4492 dnl ---------------------------------------------------------------------------
4493 dnl CF_NUMBER_SYNTAX version: 1 updated: 2003/09/20 18:12:49
4494 dnl ----------------
4495 dnl Check if the given variable is a number.  If not, report an error.
4496 dnl $1 is the variable
4497 dnl $2 is the message
4498 AC_DEFUN([CF_NUMBER_SYNTAX],[
4499 if test -n "$1" ; then
4500   case $1 in #(vi
4501   [[0-9]]*) #(vi
4502         ;;
4503   *)
4504         AC_MSG_ERROR($2 is not a number: $1)
4505         ;;
4506   esac
4507 else
4508   AC_MSG_ERROR($2 value is empty)
4509 fi
4510 ])dnl
4511 dnl ---------------------------------------------------------------------------
4512 dnl CF_OBJ_SUBDIR version: 4 updated: 2002/02/23 20:38:31
4513 dnl -------------
4514 dnl Compute the object-directory name from the given model name
4515 AC_DEFUN([CF_OBJ_SUBDIR],
4516 [
4517         case $1 in
4518         libtool) $2='obj_lo'  ;;
4519         normal)  $2='objects' ;;
4520         debug)   $2='obj_g' ;;
4521         profile) $2='obj_p' ;;
4522         shared)
4523                 case $cf_cv_system_name in #(vi
4524                 cygwin) #(vi
4525                         $2='objects' ;;
4526                 *)
4527                         $2='obj_s' ;;
4528                 esac
4529         esac
4530 ])dnl
4531 dnl ---------------------------------------------------------------------------
4532 dnl CF_PATHSEP version: 5 updated: 2010/05/26 05:38:42
4533 dnl ----------
4534 dnl Provide a value for the $PATH and similar separator
4535 AC_DEFUN([CF_PATHSEP],
4536 [
4537         case $cf_cv_system_name in
4538         os2*)   PATH_SEPARATOR=';'  ;;
4539         *)      PATH_SEPARATOR=':'  ;;
4540         esac
4541 ifelse([$1],,,[$1=$PATH_SEPARATOR])
4542         AC_SUBST(PATH_SEPARATOR)
4543 ])dnl
4544 dnl ---------------------------------------------------------------------------
4545 dnl CF_PATH_SYNTAX version: 13 updated: 2010/05/26 05:38:42
4546 dnl --------------
4547 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
4548 dnl begins with one of the prefix/exec_prefix variables, and then again if the
4549 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
4550 dnl delayed evaluation of those symbols.
4551 AC_DEFUN([CF_PATH_SYNTAX],[
4552 if test "x$prefix" != xNONE; then
4553   cf_path_syntax="$prefix"
4554 else
4555   cf_path_syntax="$ac_default_prefix"
4556 fi
4557
4558 case ".[$]$1" in #(vi
4559 .\[$]\(*\)*|.\'*\'*) #(vi
4560   ;;
4561 ..|./*|.\\*) #(vi
4562   ;;
4563 .[[a-zA-Z]]:[[\\/]]*) #(vi OS/2 EMX
4564   ;;
4565 .\[$]{*prefix}*) #(vi
4566   eval $1="[$]$1"
4567   case ".[$]$1" in #(vi
4568   .NONE/*)
4569     $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4570     ;;
4571   esac
4572   ;; #(vi
4573 .no|.NONE/*)
4574   $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4575   ;;
4576 *)
4577   ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
4578   ;;
4579 esac
4580 ])dnl
4581 dnl ---------------------------------------------------------------------------
4582 dnl CF_PKG_CONFIG version: 7 updated: 2011/04/29 04:53:22
4583 dnl -------------
4584 dnl Check for the package-config program, unless disabled by command-line.
4585 AC_DEFUN([CF_PKG_CONFIG],
4586 [
4587 AC_MSG_CHECKING(if you want to use pkg-config)
4588 AC_ARG_WITH(pkg-config,
4589         [  --with-pkg-config{=path} enable/disable use of pkg-config],
4590         [cf_pkg_config=$withval],
4591         [cf_pkg_config=yes])
4592 AC_MSG_RESULT($cf_pkg_config)
4593
4594 case $cf_pkg_config in #(vi
4595 no) #(vi
4596         PKG_CONFIG=none
4597         ;;
4598 yes) #(vi
4599         CF_ACVERSION_CHECK(2.52,
4600                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
4601                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
4602         ;;
4603 *)
4604         PKG_CONFIG=$withval
4605         ;;
4606 esac
4607
4608 test -z "$PKG_CONFIG" && PKG_CONFIG=none
4609 if test "$PKG_CONFIG" != none ; then
4610         CF_PATH_SYNTAX(PKG_CONFIG)
4611 fi
4612
4613 AC_SUBST(PKG_CONFIG)
4614 ])dnl
4615 dnl ---------------------------------------------------------------------------
4616 dnl CF_POSIX_C_SOURCE version: 8 updated: 2010/05/26 05:38:42
4617 dnl -----------------
4618 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
4619 dnl
4620 dnl     POSIX.1-1990                            _POSIX_SOURCE
4621 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
4622 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
4623 dnl             Bindings Option
4624 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
4625 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
4626 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
4627 dnl
4628 dnl Parameters:
4629 dnl     $1 is the nominal value for _POSIX_C_SOURCE
4630 AC_DEFUN([CF_POSIX_C_SOURCE],
4631 [
4632 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
4633
4634 cf_save_CFLAGS="$CFLAGS"
4635 cf_save_CPPFLAGS="$CPPFLAGS"
4636
4637 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
4638 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
4639
4640 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
4641         CF_MSG_LOG(if the symbol is already defined go no further)
4642         AC_TRY_COMPILE([#include <sys/types.h>],[
4643 #ifndef _POSIX_C_SOURCE
4644 make an error
4645 #endif],
4646         [cf_cv_posix_c_source=no],
4647         [cf_want_posix_source=no
4648          case .$cf_POSIX_C_SOURCE in #(vi
4649          .[[12]]??*) #(vi
4650                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4651                 ;;
4652          .2) #(vi
4653                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4654                 cf_want_posix_source=yes
4655                 ;;
4656          .*)
4657                 cf_want_posix_source=yes
4658                 ;;
4659          esac
4660          if test "$cf_want_posix_source" = yes ; then
4661                 AC_TRY_COMPILE([#include <sys/types.h>],[
4662 #ifdef _POSIX_SOURCE
4663 make an error
4664 #endif],[],
4665                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
4666          fi
4667          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
4668          CFLAGS="$cf_trim_CFLAGS"
4669          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
4670          CF_MSG_LOG(if the second compile does not leave our definition intact error)
4671          AC_TRY_COMPILE([#include <sys/types.h>],[
4672 #ifndef _POSIX_C_SOURCE
4673 make an error
4674 #endif],,
4675          [cf_cv_posix_c_source=no])
4676          CFLAGS="$cf_save_CFLAGS"
4677          CPPFLAGS="$cf_save_CPPFLAGS"
4678         ])
4679 ])
4680
4681 if test "$cf_cv_posix_c_source" != no ; then
4682         CFLAGS="$cf_trim_CFLAGS"
4683         CPPFLAGS="$cf_trim_CPPFLAGS"
4684         CF_ADD_CFLAGS($cf_cv_posix_c_source)
4685 fi
4686
4687 ])dnl
4688 dnl ---------------------------------------------------------------------------
4689 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
4690 dnl ------------
4691 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
4692 dnl
4693 dnl $1 = symbol to test
4694 dnl $2 = value (if any) to use for a predefinition
4695 AC_DEFUN([CF_PREDEFINE],
4696 [
4697 AC_MSG_CHECKING(if we must define $1)
4698 AC_TRY_COMPILE([#include <sys/types.h>
4699 ],[
4700 #ifndef $1
4701 make an error
4702 #endif],[cf_result=no],[cf_result=yes])
4703 AC_MSG_RESULT($cf_result)
4704
4705 if test "$cf_result" = yes ; then
4706         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
4707 elif test "x$2" != "x" ; then
4708         AC_MSG_CHECKING(checking for compatible value versus $2)
4709         AC_TRY_COMPILE([#include <sys/types.h>
4710 ],[
4711 #if $1-$2 < 0
4712 make an error
4713 #endif],[cf_result=yes],[cf_result=no])
4714         AC_MSG_RESULT($cf_result)
4715         if test "$cf_result" = no ; then
4716                 # perhaps we can override it - try...
4717                 CPPFLAGS="$CPPFLAGS -D$1=$2"
4718         fi
4719 fi
4720 ])dnl
4721 dnl ---------------------------------------------------------------------------
4722 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
4723 dnl ------------
4724 dnl Append definitions and rules for the given programs to the subdirectory
4725 dnl Makefiles, and the recursion rule for the top-level Makefile.
4726 dnl
4727 dnl parameters
4728 dnl     $1 = script to run
4729 dnl     $2 = list of subdirectories
4730 dnl
4731 dnl variables
4732 dnl     $AWK
4733 AC_DEFUN([CF_PRG_RULES],
4734 [
4735 for cf_dir in $2
4736 do
4737         if test ! -d $srcdir/$cf_dir; then
4738                 continue
4739         elif test -f $srcdir/$cf_dir/programs; then
4740                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
4741         fi
4742 done
4743
4744 ])dnl
4745 dnl ---------------------------------------------------------------------------
4746 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
4747 dnl ----------
4748 dnl Check for archiver "ar".
4749 AC_DEFUN([CF_PROG_AR],[
4750 AC_CHECK_TOOL(AR, ar, ar)
4751 ])
4752 dnl ---------------------------------------------------------------------------
4753 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
4754 dnl -----------
4755 dnl Check for awk, ensure that the check found something.
4756 AC_DEFUN([CF_PROG_AWK],
4757 [
4758 AC_PROG_AWK
4759 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
4760 ])dnl
4761 dnl ---------------------------------------------------------------------------
4762 dnl CF_PROG_CC_C_O version: 3 updated: 2010/08/14 18:25:37
4763 dnl --------------
4764 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
4765 dnl the output file can be renamed, and allows for a shell variable that can
4766 dnl be used later.  The parameter is either CC or CXX.  The result is the
4767 dnl cache variable:
4768 dnl     $cf_cv_prog_CC_c_o
4769 dnl     $cf_cv_prog_CXX_c_o
4770 AC_DEFUN([CF_PROG_CC_C_O],
4771 [AC_REQUIRE([AC_PROG_CC])dnl
4772 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
4773 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
4774 [
4775 cat > conftest.$ac_ext <<CF_EOF
4776 #include <stdio.h>
4777 int main()
4778 {
4779         ${cf_cv_main_return:-return}(0);
4780 }
4781 CF_EOF
4782 # We do the test twice because some compilers refuse to overwrite an
4783 # existing .o file with -o, though they will create one.
4784 ac_try='[$]$1 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
4785 if AC_TRY_EVAL(ac_try) &&
4786   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
4787 then
4788   eval cf_cv_prog_$1_c_o=yes
4789 else
4790   eval cf_cv_prog_$1_c_o=no
4791 fi
4792 rm -rf conftest*
4793 ])dnl
4794 if test $cf_cv_prog_$1_c_o = yes; then
4795   AC_MSG_RESULT([yes])
4796 else
4797   AC_MSG_RESULT([no])
4798 fi
4799 ])dnl
4800 dnl ---------------------------------------------------------------------------
4801 dnl CF_PROG_CC_U_D version: 1 updated: 2005/07/14 16:59:30
4802 dnl --------------
4803 dnl Check if C (preprocessor) -U and -D options are processed in the order
4804 dnl given rather than by type of option.  Some compilers insist on apply all
4805 dnl of the -U options after all of the -D options.  Others allow mixing them,
4806 dnl and may predefine symbols that conflict with those we define.
4807 AC_DEFUN([CF_PROG_CC_U_D],
4808 [
4809 AC_CACHE_CHECK(if $CC -U and -D options work together,cf_cv_cc_u_d_options,[
4810         cf_save_CPPFLAGS="$CPPFLAGS"
4811         CPPFLAGS="-UU_D_OPTIONS -DU_D_OPTIONS -DD_U_OPTIONS -UD_U_OPTIONS"
4812         AC_TRY_COMPILE([],[
4813 #ifndef U_D_OPTIONS
4814 make an undefined-error
4815 #endif
4816 #ifdef  D_U_OPTIONS
4817 make a defined-error
4818 #endif
4819         ],[
4820         cf_cv_cc_u_d_options=yes],[
4821         cf_cv_cc_u_d_options=no])
4822         CPPFLAGS="$cf_save_CPPFLAGS"
4823 ])
4824 ])dnl
4825 dnl ---------------------------------------------------------------------------
4826 dnl CF_PROG_EGREP version: 1 updated: 2006/09/16 11:40:59
4827 dnl -------------
4828 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
4829 dnl This macro adds a check to ensure the script found something.
4830 AC_DEFUN([CF_PROG_EGREP],
4831 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
4832    [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
4833     then ac_cv_prog_egrep='grep -E'
4834     else ac_cv_prog_egrep='egrep'
4835     fi])
4836  EGREP=$ac_cv_prog_egrep
4837  AC_SUBST([EGREP])
4838 test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
4839 ])dnl
4840 dnl ---------------------------------------------------------------------------
4841 dnl CF_PROG_EXT version: 10 updated: 2004/01/03 19:28:18
4842 dnl -----------
4843 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
4844 AC_DEFUN([CF_PROG_EXT],
4845 [
4846 AC_REQUIRE([CF_CHECK_CACHE])
4847 case $cf_cv_system_name in
4848 os2*)
4849     CFLAGS="$CFLAGS -Zmt"
4850     CPPFLAGS="$CPPFLAGS -D__ST_MT_ERRNO__"
4851     CXXFLAGS="$CXXFLAGS -Zmt"
4852     # autoconf's macro sets -Zexe and suffix both, which conflict:w
4853     LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
4854     ac_cv_exeext=.exe
4855     ;;
4856 esac
4857
4858 AC_EXEEXT
4859 AC_OBJEXT
4860
4861 PROG_EXT="$EXEEXT"
4862 AC_SUBST(PROG_EXT)
4863 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT")
4864 ])dnl
4865 dnl ---------------------------------------------------------------------------
4866 dnl CF_PROG_GNAT version: 2 updated: 2011/10/22 14:01:47
4867 dnl ------------
4868 dnl Check for gnatmake, ensure that it is complete.
4869 AC_DEFUN([CF_PROG_GNAT],[
4870 cf_ada_make=gnatmake
4871 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
4872 if test "$ac_cv_prog_gnat_exists" = no; then
4873    cf_ada_make=
4874    cf_cv_prog_gnat_correct=no
4875 else
4876    CF_GNAT_VERSION
4877    AC_CHECK_PROG(M4_exists, m4, yes, no)
4878    if test "$ac_cv_prog_M4_exists" = no; then
4879       cf_cv_prog_gnat_correct=no
4880       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
4881    fi
4882    if test "$cf_cv_prog_gnat_correct" = yes; then
4883       AC_MSG_CHECKING(if GNAT works)
4884       CF_GNAT_TRY_RUN([procedure conftest;],
4885 [with Text_IO;
4886 with GNAT.OS_Lib;
4887 procedure conftest is
4888 begin
4889    Text_IO.Put ("Hello World");
4890    Text_IO.New_Line;
4891    GNAT.OS_Lib.OS_Exit (0);
4892 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
4893       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
4894    fi
4895 fi
4896
4897 AC_SUBST(cf_ada_make)
4898 ])dnl
4899 dnl ---------------------------------------------------------------------------
4900 dnl CF_PROG_INSTALL version: 5 updated: 2002/12/21 22:46:07
4901 dnl ---------------
4902 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
4903 dnl misc/tabset install won't work properly.  Usually this happens only when
4904 dnl using the fallback mkinstalldirs script
4905 AC_DEFUN([CF_PROG_INSTALL],
4906 [AC_PROG_INSTALL
4907 case $INSTALL in
4908 /*)
4909   ;;
4910 *)
4911   CF_DIRNAME(cf_dir,$INSTALL)
4912   test -z "$cf_dir" && cf_dir=.
4913   INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
4914   ;;
4915 esac
4916 ])dnl
4917 dnl ---------------------------------------------------------------------------
4918 dnl CF_PROG_LDCONFIG version: 3 updated: 2011/06/04 20:09:13
4919 dnl ----------------
4920 dnl Check for ldconfig, needed to fixup shared libraries that would be built
4921 dnl and then used in the install.
4922 AC_DEFUN([CF_PROG_LDCONFIG],[
4923 if test "$cross_compiling" = yes ; then
4924   LDCONFIG=:
4925 else
4926 case "$cf_cv_system_name" in #(vi
4927 dragonfly*|mirbsd*|freebsd*) #(vi
4928   test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
4929   ;;
4930 *) LDPATH=$PATH:/sbin:/usr/sbin
4931   AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
4932   ;;
4933 esac
4934 fi
4935 AC_SUBST(LDCONFIG)
4936 ])dnl
4937 dnl ---------------------------------------------------------------------------
4938 dnl CF_PROG_LINT version: 2 updated: 2009/08/12 04:43:14
4939 dnl ------------
4940 AC_DEFUN([CF_PROG_LINT],
4941 [
4942 AC_CHECK_PROGS(LINT, tdlint lint alint splint lclint)
4943 AC_SUBST(LINT_OPTS)
4944 ])dnl
4945 dnl ---------------------------------------------------------------------------
4946 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
4947 dnl ------------
4948 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
4949 dnl option if it is supported.
4950 AC_DEFUN([CF_PROG_LN_S],[
4951 AC_PROG_LN_S
4952 AC_MSG_CHECKING(if $LN_S -f options work)
4953
4954 rm -f conf$$.src conf$$dst
4955 echo >conf$$.dst
4956 echo first >conf$$.src
4957 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
4958         cf_prog_ln_sf=yes
4959 else
4960         cf_prog_ln_sf=no
4961 fi
4962 rm -f conf$$.dst conf$$src
4963 AC_MSG_RESULT($cf_prog_ln_sf)
4964
4965 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
4966 ])dnl
4967 dnl ---------------------------------------------------------------------------
4968 dnl CF_REGEX version: 8 updated: 2010/08/07 14:09:44
4969 dnl --------
4970 dnl Attempt to determine if we've got one of the flavors of regular-expression
4971 dnl code that we can support.
4972 AC_DEFUN([CF_REGEX],
4973 [
4974
4975 cf_regex_func=no
4976
4977 cf_regex_libs="regex re"
4978 case $host_os in #(vi
4979 mingw*)
4980         cf_regex_libs="regex.dll $cf_regex_libs"
4981         ;;
4982 esac
4983
4984 AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
4985         for cf_regex_lib in $cf_regex_libs
4986         do
4987                 AC_CHECK_LIB($cf_regex_lib,regcomp,[
4988                                 CF_ADD_LIB($cf_regex_lib)
4989                                 cf_regex_func=regcomp
4990                                 break])
4991         done
4992 ])
4993
4994 if test "$cf_regex_func" = no ; then
4995         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
4996                 AC_CHECK_LIB(gen,compile,[
4997                                 CF_ADD_LIB(gen)
4998                                 cf_regex_func=compile])])
4999 fi
5000
5001 if test "$cf_regex_func" = no ; then
5002         AC_MSG_WARN(cannot find regular expression library)
5003 fi
5004
5005 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
5006
5007 cf_cv_regex_hdrs=no
5008 case $cf_regex_func in #(vi
5009 compile) #(vi
5010         for cf_regex_hdr in regexp.h regexpr.h
5011         do
5012                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
5013                         char *p = compile("", "", "", 0);
5014                         int x = step("", "");
5015                 ],[
5016                         cf_cv_regex_hdrs=$cf_regex_hdr
5017                         break
5018                 ])
5019         done
5020         ;;
5021 *)
5022         for cf_regex_hdr in regex.h
5023         do
5024                 AC_TRY_LINK([#include <sys/types.h>
5025 #include <$cf_regex_hdr>],[
5026                         regex_t *p;
5027                         int x = regcomp(p, "", 0);
5028                         int y = regexec(p, "", 0, 0, 0);
5029                         regfree(p);
5030                 ],[
5031                         cf_cv_regex_hdrs=$cf_regex_hdr
5032                         break
5033                 ])
5034         done
5035         ;;
5036 esac
5037
5038 ])
5039
5040 case $cf_cv_regex_hdrs in #(vi
5041     no)        AC_MSG_WARN(no regular expression header found) ;; #(vi
5042     regex.h)   AC_DEFINE(HAVE_REGEX_H_FUNCS) ;; #(vi
5043     regexp.h)  AC_DEFINE(HAVE_REGEXP_H_FUNCS) ;; #(vi
5044     regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS) ;;
5045 esac
5046 ])dnl
5047 dnl ---------------------------------------------------------------------------
5048 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
5049 dnl ----------------
5050 dnl Remove all -U and -D options that refer to the given symbol from a list
5051 dnl of C compiler options.  This works around the problem that not all
5052 dnl compilers process -U and -D options from left-to-right, so a -U option
5053 dnl cannot be used to cancel the effect of a preceding -D option.
5054 dnl
5055 dnl $1 = target (which could be the same as the source variable)
5056 dnl $2 = source (including '$')
5057 dnl $3 = symbol to remove
5058 define([CF_REMOVE_DEFINE],
5059 [
5060 $1=`echo "$2" | \
5061         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
5062                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
5063 ])dnl
5064 dnl ---------------------------------------------------------------------------
5065 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
5066 dnl -------------
5067 dnl Remove the given library from the symbol
5068 dnl
5069 dnl $1 = target (which could be the same as the source variable)
5070 dnl $2 = source (including '$')
5071 dnl $3 = library to remove
5072 define([CF_REMOVE_LIB],
5073 [
5074 # remove $3 library from $2
5075 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
5076 ])dnl
5077 dnl ---------------------------------------------------------------------------
5078 dnl CF_RPATH_HACK version: 9 updated: 2011/02/13 13:31:33
5079 dnl -------------
5080 AC_DEFUN([CF_RPATH_HACK],
5081 [
5082 AC_REQUIRE([CF_LD_RPATH_OPT])
5083 AC_MSG_CHECKING(for updated LDFLAGS)
5084 if test -n "$LD_RPATH_OPT" ; then
5085         AC_MSG_RESULT(maybe)
5086
5087         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
5088         cf_rpath_list="/usr/lib /lib"
5089         if test "$cf_ldd_prog" != no
5090         then
5091                 cf_rpath_oops=
5092
5093 AC_TRY_LINK([#include <stdio.h>],
5094                 [printf("Hello");],
5095                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort -u`
5096                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort -u`])
5097
5098                 # If we passed the link-test, but get a "not found" on a given library,
5099                 # this could be due to inept reconfiguration of gcc to make it only
5100                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
5101                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
5102                 # /usr/local libraries.
5103                 if test -n "$cf_rpath_oops"
5104                 then
5105                         for cf_rpath_src in $cf_rpath_oops
5106                         do
5107                                 for cf_rpath_dir in \
5108                                         /usr/local \
5109                                         /usr/pkg \
5110                                         /opt/sfw
5111                                 do
5112                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
5113                                         then
5114                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
5115                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
5116                                                 break
5117                                         fi
5118                                 done
5119                         done
5120                 fi
5121         fi
5122
5123         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5124
5125         CF_RPATH_HACK_2(LDFLAGS)
5126         CF_RPATH_HACK_2(LIBS)
5127
5128         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5129 fi
5130 AC_SUBST(EXTRA_LDFLAGS)
5131 ])dnl
5132 dnl ---------------------------------------------------------------------------
5133 dnl CF_RPATH_HACK_2 version: 6 updated: 2010/04/17 16:31:24
5134 dnl ---------------
5135 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
5136 dnl EXTRA_LDFLAGS for each -L option found.
5137 dnl
5138 dnl $cf_rpath_list contains a list of directories to ignore.
5139 dnl
5140 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
5141 dnl      but LIBS often has misplaced -L options.
5142 AC_DEFUN([CF_RPATH_HACK_2],
5143 [
5144 CF_VERBOSE(...checking $1 [$]$1)
5145
5146 cf_rpath_dst=
5147 for cf_rpath_src in [$]$1
5148 do
5149         case $cf_rpath_src in #(vi
5150         -L*) #(vi
5151
5152                 # check if this refers to a directory which we will ignore
5153                 cf_rpath_skip=no
5154                 if test -n "$cf_rpath_list"
5155                 then
5156                         for cf_rpath_item in $cf_rpath_list
5157                         do
5158                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
5159                                 then
5160                                         cf_rpath_skip=yes
5161                                         break
5162                                 fi
5163                         done
5164                 fi
5165
5166                 if test "$cf_rpath_skip" = no
5167                 then
5168                         # transform the option
5169                         if test "$LD_RPATH_OPT" = "-R " ; then
5170                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
5171                         else
5172                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
5173                         fi
5174
5175                         # if we have not already added this, add it now
5176                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
5177                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
5178                         then
5179                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
5180                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
5181                         fi
5182                 fi
5183                 ;;
5184         esac
5185         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
5186 done
5187 $1=$cf_rpath_dst
5188
5189 CF_VERBOSE(...checked $1 [$]$1)
5190 AC_SUBST(EXTRA_LDFLAGS)
5191 ])dnl
5192 dnl ---------------------------------------------------------------------------
5193 dnl CF_SHARED_OPTS version: 69 updated: 2011/07/30 19:31:39
5194 dnl --------------
5195 dnl --------------
5196 dnl Attempt to determine the appropriate CC/LD options for creating a shared
5197 dnl library.
5198 dnl
5199 dnl Note: ${LOCAL_LDFLAGS} is used to link executables that will run within the
5200 dnl build-tree, i.e., by making use of the libraries that are compiled in ../lib
5201 dnl We avoid compiling-in a ../lib path for the shared library since that can
5202 dnl lead to unexpected results at runtime.
5203 dnl ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared libraries
5204 dnl are compiled in ../../lib
5205 dnl
5206 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
5207 dnl to install symbolic links to the rel/abi versions of shared libraries.
5208 dnl
5209 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
5210 dnl version when making symbolic links.
5211 dnl
5212 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
5213 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
5214 dnl (ex: libncurses.so.<ver>).
5215 dnl
5216 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
5217 AC_DEFUN([CF_SHARED_OPTS],
5218 [
5219         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
5220         AC_REQUIRE([CF_LD_RPATH_OPT])
5221         LOCAL_LDFLAGS=
5222         LOCAL_LDFLAGS2=
5223         LD_SHARED_OPTS=
5224         INSTALL_LIB="-m 644"
5225
5226         cf_cv_do_symlinks=no
5227         cf_ld_rpath_opt=
5228         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
5229
5230         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
5231         AC_ARG_WITH(shlib-version,
5232         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
5233         [test -z "$withval" && withval=auto
5234         case $withval in #(vi
5235         yes) #(vi
5236                 cf_cv_shlib_version=auto
5237                 ;;
5238         rel|abi|auto|no) #(vi
5239                 cf_cv_shlib_version=$withval
5240                 ;;
5241         *)
5242                 AC_MSG_ERROR([option value must be one of: rel, abi, auto or no])
5243                 ;;
5244         esac
5245         ],[cf_cv_shlib_version=auto])
5246         AC_MSG_RESULT($cf_cv_shlib_version)
5247
5248         cf_cv_rm_so_locs=no
5249
5250         # Some less-capable ports of gcc support only -fpic
5251         CC_SHARED_OPTS=
5252         if test "$GCC" = yes
5253         then
5254                 AC_MSG_CHECKING(which $CC option to use)
5255                 cf_save_CFLAGS="$CFLAGS"
5256                 for CC_SHARED_OPTS in -fPIC -fpic ''
5257                 do
5258                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
5259                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
5260                 done
5261                 AC_MSG_RESULT($CC_SHARED_OPTS)
5262                 CFLAGS="$cf_save_CFLAGS"
5263         fi
5264
5265         cf_cv_shlib_version_infix=no
5266
5267         case $cf_cv_system_name in #(vi
5268         aix4.[3-9]*|aix[[5-7]]*) #(vi
5269                 if test "$GCC" = yes; then
5270                         CC_SHARED_OPTS=
5271                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5272                 else
5273                         # CC_SHARED_OPTS='-qpic=large -G'
5274                         # perhaps "-bM:SRE -bnoentry -bexpall"
5275                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5276                 fi
5277                 ;;
5278         beos*) #(vi
5279                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
5280                 ;;
5281         cygwin*) #(vi
5282                 CC_SHARED_OPTS=
5283                 MK_SHARED_LIB='sh ../mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5284                 cf_cv_shlib_version=cygdll
5285                 cf_cv_shlib_version_infix=cygdll
5286                 cat >mk_shared_lib.sh <<-CF_EOF
5287                 #!/bin/sh
5288                 SHARED_LIB=\[$]1
5289                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5290                 shift
5291                 cat <<-EOF
5292                 Linking shared library
5293                 ** SHARED_LIB \[$]SHARED_LIB
5294                 ** IMPORT_LIB \[$]IMPORT_LIB
5295 EOF
5296                 exec \[$]* -shared -Wl,--out-implib=../lib/\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o ../lib/\[$]{SHARED_LIB}
5297 CF_EOF
5298                 chmod +x mk_shared_lib.sh
5299                 ;;
5300         darwin*) #(vi
5301                 EXTRA_CFLAGS="-no-cpp-precomp"
5302                 CC_SHARED_OPTS="-dynamic"
5303                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
5304                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
5305                 cf_cv_shlib_version_infix=yes
5306                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
5307                         cf_save_LDFLAGS=$LDFLAGS
5308                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5309                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
5310                                 LDFLAGS=$cf_save_LDFLAGS])
5311                 if test $cf_cv_ldflags_search_paths_first = yes; then
5312                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5313                 fi
5314                 ;;
5315         hpux*) #(vi
5316                 # (tested with gcc 2.7.2 -- I don't have c89)
5317                 if test "$GCC" = yes; then
5318                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
5319                 else
5320                         CC_SHARED_OPTS='+Z'
5321                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
5322                 fi
5323                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
5324                 # HP-UX shared libraries must be executable, and should be
5325                 # readonly to exploit a quirk in the memory manager.
5326                 INSTALL_LIB="-m 555"
5327                 ;;
5328         interix*)
5329                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5330                 if test "$cf_cv_shlib_version" = rel; then
5331                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
5332                 else
5333                         cf_shared_soname='`basename $@`'
5334                 fi
5335                 CC_SHARED_OPTS=
5336                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
5337                 ;;
5338         irix*) #(vi
5339                 if test "$cf_cv_enable_rpath" = yes ; then
5340                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5341                 fi
5342                 # tested with IRIX 5.2 and 'cc'.
5343                 if test "$GCC" != yes; then
5344                         CC_SHARED_OPTS='-KPIC'
5345                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
5346                 else
5347                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
5348                 fi
5349                 cf_cv_rm_so_locs=yes
5350                 ;;
5351         linux*|gnu*|k*bsd*-gnu) #(vi
5352                 if test "$DFT_LWR_MODEL" = "shared" ; then
5353                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5354                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5355                 fi
5356                 if test "$cf_cv_enable_rpath" = yes ; then
5357                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5358                 fi
5359                 CF_SHARED_SONAME
5360                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5361                 ;;
5362         openbsd[[2-9]].*|mirbsd*) #(vi
5363                 if test "$DFT_LWR_MODEL" = "shared" ; then
5364                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5365                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5366                 fi
5367                 if test "$cf_cv_enable_rpath" = yes ; then
5368                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5369                 fi
5370                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5371                 CF_SHARED_SONAME
5372                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5373                 ;;
5374         nto-qnx*|openbsd*|freebsd[[12]].*) #(vi
5375                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5376                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
5377                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5378                 ;;
5379         dragonfly*|freebsd*) #(vi
5380                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5381                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5382                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5383                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
5384                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5385                 fi
5386                 CF_SHARED_SONAME
5387                 MK_SHARED_LIB='${LD} -shared -Bshareable -soname=`basename $[@]` -o $[@]'
5388                 ;;
5389         netbsd*) #(vi
5390                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5391                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5392                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5393                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5394                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5395                         if test "$cf_cv_shlib_version" = auto; then
5396                         if test -f /usr/libexec/ld.elf_so; then
5397                                 cf_cv_shlib_version=abi
5398                         else
5399                                 cf_cv_shlib_version=rel
5400                         fi
5401                         fi
5402                         CF_SHARED_SONAME
5403                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
5404                 else
5405                         MK_SHARED_LIB='${LD} -shared -Bshareable -o $[@]'
5406                 fi
5407                 ;;
5408         osf*|mls+*) #(vi
5409                 # tested with OSF/1 V3.2 and 'cc'
5410                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
5411                 # link with shared libs).
5412                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
5413                 case $host_os in #(vi
5414                 osf4*)
5415                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
5416                         ;;
5417                 esac
5418                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
5419                 if test "$DFT_LWR_MODEL" = "shared" ; then
5420                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5421                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5422                 fi
5423                 cf_cv_rm_so_locs=yes
5424                 ;;
5425         sco3.2v5*)  # (also uw2* and UW7: hops 13-Apr-98
5426                 # tested with osr5.0.5
5427                 if test "$GCC" != yes; then
5428                         CC_SHARED_OPTS='-belf -KPIC'
5429                 fi
5430                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
5431                 if test "$cf_cv_enable_rpath" = yes ; then
5432                         # only way is to set LD_RUN_PATH but no switch for it
5433                         RUN_PATH=$libdir
5434                 fi
5435                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5436                 LINK_PROGS='LD_RUN_PATH=${libdir}'
5437                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
5438                 ;;
5439         sunos4*) #(vi
5440                 # tested with SunOS 4.1.1 and gcc 2.7.0
5441                 if test "$GCC" != yes; then
5442                         CC_SHARED_OPTS='-KPIC'
5443                 fi
5444                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
5445                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5446                 ;;
5447         solaris2*) #(vi
5448                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
5449                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
5450                 if test "$DFT_LWR_MODEL" = "shared" ; then
5451                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
5452                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5453                 fi
5454                 if test "$cf_cv_enable_rpath" = yes ; then
5455                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
5456                 fi
5457                 CF_SHARED_SONAME
5458                 if test "$GCC" != yes; then
5459                         cf_save_CFLAGS="$CFLAGS"
5460                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
5461                         do
5462                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
5463                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
5464                         done
5465                         CFLAGS="$cf_save_CFLAGS"
5466                         CC_SHARED_OPTS=$cf_shared_opts
5467                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5468                 else
5469                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5470                 fi
5471                 ;;
5472         sysv5uw7*|unix_sv*) #(vi
5473                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
5474                 if test "$GCC" != yes; then
5475                         CC_SHARED_OPTS='-KPIC'
5476                 fi
5477                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
5478                 ;;
5479         *)
5480                 CC_SHARED_OPTS='unknown'
5481                 MK_SHARED_LIB='echo unknown'
5482                 ;;
5483         esac
5484
5485         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
5486         case "$cf_cv_shlib_version" in #(vi
5487         rel|abi)
5488                 case "$MK_SHARED_LIB" in #(vi
5489                 *'-o $[@]') #(vi
5490                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
5491                         ;;
5492                 *)
5493                         AC_MSG_WARN(ignored --with-shlib-version)
5494                         ;;
5495                 esac
5496                 ;;
5497         esac
5498
5499         # RPATH_LIST is a colon-separated list of directories
5500         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
5501         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
5502
5503         AC_SUBST(CC_SHARED_OPTS)
5504         AC_SUBST(LD_RPATH_OPT)
5505         AC_SUBST(LD_SHARED_OPTS)
5506         AC_SUBST(MK_SHARED_LIB)
5507         AC_SUBST(LINK_PROGS)
5508         AC_SUBST(LINK_TESTS)
5509         AC_SUBST(EXTRA_LDFLAGS)
5510         AC_SUBST(LOCAL_LDFLAGS)
5511         AC_SUBST(LOCAL_LDFLAGS2)
5512         AC_SUBST(INSTALL_LIB)
5513         AC_SUBST(RPATH_LIST)
5514 ])dnl
5515 dnl ---------------------------------------------------------------------------
5516 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
5517 dnl ----------------
5518 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
5519 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
5520 dnl option.
5521 dnl
5522 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
5523 dnl If missing, use "rel".
5524 define([CF_SHARED_SONAME],
5525 [
5526         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
5527         if test "$cf_cv_shlib_version" = rel; then
5528                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
5529         else
5530                 cf_cv_shared_soname='`basename $[@]`'
5531         fi
5532 ])
5533 dnl ---------------------------------------------------------------------------
5534 dnl CF_SIGWINCH version: 1 updated: 2006/04/02 16:41:09
5535 dnl -----------
5536 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
5537 dnl programs need this test).
5538 dnl
5539 dnl This is really a MacOS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
5540 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
5541 dnl winsize declaration is left alone - we may revisit this if Apple choose to
5542 dnl break that part of the interface as well.
5543 AC_DEFUN([CF_SIGWINCH],
5544 [
5545 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
5546         AC_TRY_COMPILE([
5547 #include <sys/types.h>
5548 #include <sys/signal.h>
5549 ],[int x = SIGWINCH],
5550         [cf_cv_define_sigwinch=yes],
5551         [AC_TRY_COMPILE([
5552 #undef _XOPEN_SOURCE
5553 #undef _POSIX_SOURCE
5554 #undef _POSIX_C_SOURCE
5555 #include <sys/types.h>
5556 #include <sys/signal.h>
5557 ],[int x = SIGWINCH],
5558         [cf_cv_define_sigwinch=maybe],
5559         [cf_cv_define_sigwinch=no])
5560 ])
5561 ])
5562
5563 if test "$cf_cv_define_sigwinch" = maybe ; then
5564 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
5565 cf_cv_fixup_sigwinch=unknown
5566 cf_sigwinch=32
5567 while test $cf_sigwinch != 1
5568 do
5569         AC_TRY_COMPILE([
5570 #undef _XOPEN_SOURCE
5571 #undef _POSIX_SOURCE
5572 #undef _POSIX_C_SOURCE
5573 #include <sys/types.h>
5574 #include <sys/signal.h>
5575 ],[
5576 #if SIGWINCH != $cf_sigwinch
5577 make an error
5578 #endif
5579 int x = SIGWINCH],
5580         [cf_cv_fixup_sigwinch=$cf_sigwinch
5581          break])
5582
5583 cf_sigwinch=`expr $cf_sigwinch - 1`
5584 done
5585 ])
5586
5587         if test "$cf_cv_fixup_sigwinch" != unknown ; then
5588                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
5589         fi
5590 fi
5591 ])dnl
5592 dnl ---------------------------------------------------------------------------
5593 dnl CF_SIG_ATOMIC_T version: 2 updated: 2005/09/18 17:27:12
5594 dnl ---------------
5595 dnl signal handler, but there are some gcc depedencies in that recommendation.
5596 dnl Try anyway.
5597 AC_DEFUN([CF_SIG_ATOMIC_T],
5598 [
5599 AC_MSG_CHECKING(for signal global datatype)
5600 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
5601         for cf_type in \
5602                 "volatile sig_atomic_t" \
5603                 "sig_atomic_t" \
5604                 "int"
5605         do
5606         AC_TRY_COMPILE([
5607 #include <sys/types.h>
5608 #include <signal.h>
5609 #include <stdio.h>
5610
5611 extern $cf_type x;
5612 $cf_type x;
5613 static void handler(int sig)
5614 {
5615         x = 5;
5616 }],
5617                 [signal(SIGINT, handler);
5618                  x = 1],
5619                 [cf_cv_sig_atomic_t=$cf_type],
5620                 [cf_cv_sig_atomic_t=no])
5621                 test "$cf_cv_sig_atomic_t" != no && break
5622         done
5623         ])
5624 AC_MSG_RESULT($cf_cv_sig_atomic_t)
5625 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t)
5626 ])dnl
5627 dnl ---------------------------------------------------------------------------
5628 dnl CF_SIZECHANGE version: 8 updated: 2000/11/04 12:22:16
5629 dnl -------------
5630 dnl Check for definitions & structures needed for window size-changing
5631 dnl FIXME: check that this works with "snake" (HP-UX 10.x)
5632 AC_DEFUN([CF_SIZECHANGE],
5633 [
5634 AC_REQUIRE([CF_STRUCT_TERMIOS])
5635 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
5636     cf_cv_sizechange=unknown
5637     cf_save_CPPFLAGS="$CPPFLAGS"
5638
5639 for cf_opts in "" "NEED_PTEM_H"
5640 do
5641
5642     CPPFLAGS="$cf_save_CPPFLAGS"
5643     test -n "$cf_opts" && CPPFLAGS="$CPPFLAGS -D$cf_opts"
5644     AC_TRY_COMPILE([#include <sys/types.h>
5645 #ifdef HAVE_TERMIOS_H
5646 #include <termios.h>
5647 #else
5648 #ifdef HAVE_TERMIO_H
5649 #include <termio.h>
5650 #endif
5651 #endif
5652 #ifdef NEED_PTEM_H
5653 /* This is a workaround for SCO:  they neglected to define struct winsize in
5654  * termios.h -- it's only in termio.h and ptem.h
5655  */
5656 #include        <sys/stream.h>
5657 #include        <sys/ptem.h>
5658 #endif
5659 #if !defined(sun) || !defined(HAVE_TERMIOS_H)
5660 #include <sys/ioctl.h>
5661 #endif
5662 ],[
5663 #ifdef TIOCGSIZE
5664         struct ttysize win;     /* FIXME: what system is this? */
5665         int y = win.ts_lines;
5666         int x = win.ts_cols;
5667 #else
5668 #ifdef TIOCGWINSZ
5669         struct winsize win;
5670         int y = win.ws_row;
5671         int x = win.ws_col;
5672 #else
5673         no TIOCGSIZE or TIOCGWINSZ
5674 #endif /* TIOCGWINSZ */
5675 #endif /* TIOCGSIZE */
5676         ],
5677         [cf_cv_sizechange=yes],
5678         [cf_cv_sizechange=no])
5679
5680         CPPFLAGS="$cf_save_CPPFLAGS"
5681         if test "$cf_cv_sizechange" = yes ; then
5682                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
5683                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
5684                 break
5685         fi
5686 done
5687 ])
5688 if test "$cf_cv_sizechange" != no ; then
5689         AC_DEFINE(HAVE_SIZECHANGE)
5690         case $cf_cv_sizechange in #(vi
5691         NEED*)
5692                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
5693                 ;;
5694         esac
5695 fi
5696 ])dnl
5697 dnl ---------------------------------------------------------------------------
5698 dnl CF_SRC_MODULES version: 23 updated: 2011/11/26 16:35:15
5699 dnl --------------
5700 dnl For each parameter, test if the source-directory exists, and if it contains
5701 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
5702 dnl use in CF_LIB_RULES.
5703 dnl
5704 dnl This uses the configured value to make the lists SRC_SUBDIRS and
5705 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
5706 AC_DEFUN([CF_SRC_MODULES],
5707 [
5708 AC_MSG_CHECKING(for src modules)
5709
5710 # dependencies and linker-arguments for test-programs
5711 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
5712 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
5713 if test "$DFT_LWR_MODEL" = "libtool"; then
5714         TEST_ARGS="${TEST_DEPS}"
5715         TEST_ARG2="${TEST_DEP2}"
5716 else
5717         TEST_ARGS="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARGS"
5718         TEST_ARG2="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARG2"
5719 fi
5720
5721 PC_MODULES_TO_MAKE="ncurses"
5722 cf_cv_src_modules=
5723 for cf_dir in $1
5724 do
5725         if test -f $srcdir/$cf_dir/modules; then
5726
5727                 # We may/may not have tack in the distribution, though the
5728                 # makefile is.
5729                 if test $cf_dir = tack ; then
5730                         if test ! -f $srcdir/${cf_dir}/${cf_dir}.h; then
5731                                 continue
5732                         fi
5733                 fi
5734
5735                 if test -z "$cf_cv_src_modules"; then
5736                         cf_cv_src_modules=$cf_dir
5737                 else
5738                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
5739                 fi
5740
5741                 # Make the ncurses_cfg.h file record the library interface files as
5742                 # well.  These are header files that are the same name as their
5743                 # directory.  Ncurses is the only library that does not follow
5744                 # that pattern.
5745                 if test $cf_dir = tack ; then
5746                         continue
5747                 elif test -f $srcdir/${cf_dir}/${cf_dir}.h; then
5748                         CF_UPPER(cf_have_include,$cf_dir)
5749                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
5750                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
5751                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEPS"
5752                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEP2"
5753                         if test "$DFT_LWR_MODEL" = "libtool"; then
5754                                 TEST_ARGS="${TEST_DEPS}"
5755                                 TEST_ARG2="${TEST_DEP2}"
5756                         else
5757                                 TEST_ARGS="-l${cf_dir}${DFT_ARG_SUFFIX} $TEST_ARGS"
5758                                 TEST_ARG2="-l${cf_dir}${DFT_ARG_SUFFIX} $TEST_ARG2"
5759                         fi
5760                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}"
5761                 fi
5762         fi
5763 done
5764 AC_MSG_RESULT($cf_cv_src_modules)
5765
5766 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
5767 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
5768
5769 AC_SUBST(TEST_ARGS)
5770 AC_SUBST(TEST_DEPS)
5771
5772 AC_SUBST(TEST_ARG2)
5773 AC_SUBST(TEST_DEP2)
5774
5775 SRC_SUBDIRS=
5776 if test "x$cf_with_manpages" != xno ; then
5777         SRC_SUBDIRS="$SRC_SUBDIRS man"
5778 fi
5779 SRC_SUBDIRS="$SRC_SUBDIRS include"
5780 for cf_dir in $cf_cv_src_modules
5781 do
5782         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
5783 done
5784 if test "x$cf_with_tests" != "xno" ; then
5785         SRC_SUBDIRS="$SRC_SUBDIRS test"
5786 fi
5787 test -z "$MAKE_TERMINFO" && SRC_SUBDIRS="$SRC_SUBDIRS misc"
5788 if test "$cf_with_cxx_binding" != no; then
5789         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++"
5790         SRC_SUBDIRS="$SRC_SUBDIRS c++"
5791 fi
5792
5793 AC_SUBST(PC_MODULES_TO_MAKE)
5794
5795 ADA_SUBDIRS=
5796 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f $srcdir/Ada95/Makefile.in; then
5797         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
5798         ADA_SUBDIRS="gen src"
5799         if test "x$cf_with_tests" != "xno" ; then
5800                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
5801         fi
5802 fi
5803
5804 SUB_MAKEFILES=
5805 for cf_dir in $SRC_SUBDIRS
5806 do
5807         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
5808 done
5809
5810 if test -n "$ADA_SUBDIRS"; then
5811         for cf_dir in $ADA_SUBDIRS
5812         do
5813                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
5814         done
5815         AC_SUBST(ADA_SUBDIRS)
5816 fi
5817 ])dnl
5818 dnl ---------------------------------------------------------------------------
5819 dnl CF_STDCPP_LIBRARY version: 7 updated: 2010/05/29 16:31:02
5820 dnl -----------------
5821 dnl Check for -lstdc++, which is GNU's standard C++ library.
5822 AC_DEFUN([CF_STDCPP_LIBRARY],
5823 [
5824 if test -n "$GXX" ; then
5825 case $cf_cv_system_name in #(vi
5826 os2*) #(vi
5827         cf_stdcpp_libname=stdcpp
5828         ;;
5829 *)
5830         cf_stdcpp_libname=stdc++
5831         ;;
5832 esac
5833 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
5834         cf_save="$LIBS"
5835         CF_ADD_LIB($cf_stdcpp_libname)
5836 AC_TRY_LINK([
5837 #include <strstream.h>],[
5838 char buf[80];
5839 strstreambuf foo(buf, sizeof(buf))
5840 ],
5841         [cf_cv_libstdcpp=yes],
5842         [cf_cv_libstdcpp=no])
5843         LIBS="$cf_save"
5844 ])
5845 test "$cf_cv_libstdcpp" = yes && CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS)
5846 fi
5847 ])dnl
5848 dnl ---------------------------------------------------------------------------
5849 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
5850 dnl --------------
5851 dnl     Remove "-g" option from the compiler options
5852 AC_DEFUN([CF_STRIP_G_OPT],
5853 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
5854 dnl ---------------------------------------------------------------------------
5855 dnl CF_STRUCT_SIGACTION version: 4 updated: 2011/04/16 11:52:53
5856 dnl -------------------
5857 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
5858 dnl do this if we've found the sigaction function.
5859 AC_DEFUN([CF_STRUCT_SIGACTION],[
5860 AC_REQUIRE([CF_XOPEN_SOURCE])
5861
5862 if test "$ac_cv_func_sigaction" = yes; then
5863 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
5864 AC_TRY_COMPILE([
5865 #include <sys/types.h>
5866 #include <signal.h>],
5867         [struct sigaction act],
5868         [sigact_bad=no],
5869         [
5870 AC_TRY_COMPILE([
5871 #define _POSIX_SOURCE
5872 #include <sys/types.h>
5873 #include <signal.h>],
5874         [struct sigaction act],
5875         [sigact_bad=yes
5876          AC_DEFINE(_POSIX_SOURCE)],
5877          [sigact_bad=unknown])])
5878 AC_MSG_RESULT($sigact_bad)
5879 fi
5880 ])dnl
5881 dnl ---------------------------------------------------------------------------
5882 dnl CF_STRUCT_TERMIOS version: 6 updated: 2011/04/16 11:52:53
5883 dnl -----------------
5884 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
5885 AC_DEFUN([CF_STRUCT_TERMIOS],[
5886 AC_REQUIRE([CF_XOPEN_SOURCE])
5887
5888 AC_CHECK_HEADERS( \
5889 termio.h \
5890 termios.h \
5891 unistd.h \
5892 )
5893
5894 if test "$ISC" = yes ; then
5895         AC_CHECK_HEADERS( sys/termio.h )
5896 fi
5897 if test "$ac_cv_header_termios_h" = yes ; then
5898         case "$CFLAGS $CPPFLAGS" in
5899         *-D_POSIX_SOURCE*)
5900                 termios_bad=dunno ;;
5901         *)      termios_bad=maybe ;;
5902         esac
5903         if test "$termios_bad" = maybe ; then
5904         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
5905         AC_TRY_COMPILE([#include <termios.h>],
5906                 [struct termios foo; int x = foo.c_iflag],
5907                 termios_bad=no, [
5908                 AC_TRY_COMPILE([
5909 #define _POSIX_SOURCE
5910 #include <termios.h>],
5911                         [struct termios foo; int x = foo.c_iflag],
5912                         termios_bad=unknown,
5913                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE))
5914                         ])
5915         AC_MSG_RESULT($termios_bad)
5916         fi
5917 fi
5918 ])dnl
5919 dnl ---------------------------------------------------------------------------
5920 dnl CF_SUBDIR_PATH version: 6 updated: 2010/04/21 06:20:50
5921 dnl --------------
5922 dnl Construct a search-list for a nonstandard header/lib-file
5923 dnl     $1 = the variable to return as result
5924 dnl     $2 = the package name
5925 dnl     $3 = the subdirectory, e.g., bin, include or lib
5926 AC_DEFUN([CF_SUBDIR_PATH],
5927 [
5928 $1=
5929
5930 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr,$prefix)
5931 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
5932 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr/local,$prefix)
5933 CF_ADD_SUBDIR_PATH($1,$2,$3,/opt,$prefix)
5934 CF_ADD_SUBDIR_PATH($1,$2,$3,[$]HOME,$prefix)
5935 ])dnl
5936 dnl ---------------------------------------------------------------------------
5937 dnl CF_SUBST version: 4 updated: 2006/06/17 12:33:03
5938 dnl --------
5939 dnl     Shorthand macro for substituting things that the user may override
5940 dnl     with an environment variable.
5941 dnl
5942 dnl     $1 = long/descriptive name
5943 dnl     $2 = environment variable
5944 dnl     $3 = default value
5945 AC_DEFUN([CF_SUBST],
5946 [AC_CACHE_VAL(cf_cv_subst_$2,[
5947 AC_MSG_CHECKING(for $1 (symbol $2))
5948 CF_SUBST_IF([-z "[$]$2"], [$2], [$3])
5949 cf_cv_subst_$2=[$]$2
5950 AC_MSG_RESULT([$]$2)
5951 ])
5952 ])dnl
5953 dnl ---------------------------------------------------------------------------
5954 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
5955 dnl -----------
5956 dnl     Shorthand macro for substituting things that the user may override
5957 dnl     with an environment variable.
5958 dnl
5959 dnl     $1 = condition to pass to "test"
5960 dnl     $2 = environment variable
5961 dnl     $3 = value if the test succeeds
5962 dnl     $4 = value if the test fails
5963 AC_DEFUN([CF_SUBST_IF],
5964 [
5965 if test $1 ; then
5966         $2=$3
5967 ifelse($4,,,[else
5968         $2=$4])
5969 fi
5970 AC_SUBST($2)
5971 ])dnl
5972 dnl ---------------------------------------------------------------------------
5973 dnl CF_SUBST_NCURSES_VERSION version: 8 updated: 2006/09/16 11:40:59
5974 dnl ------------------------
5975 dnl Get the version-number for use in shared-library naming, etc.
5976 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
5977 [
5978 AC_REQUIRE([CF_PROG_EGREP])
5979 NCURSES_MAJOR="`$ac_cv_prog_egrep '^NCURSES_MAJOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
5980 NCURSES_MINOR="`$ac_cv_prog_egrep '^NCURSES_MINOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
5981 NCURSES_PATCH="`$ac_cv_prog_egrep '^NCURSES_PATCH[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
5982 cf_cv_abi_version=${NCURSES_MAJOR}
5983 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
5984 dnl Show the computed version, for logging
5985 cf_cv_timestamp=`date`
5986 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
5987 dnl We need these values in the generated headers
5988 AC_SUBST(NCURSES_MAJOR)
5989 AC_SUBST(NCURSES_MINOR)
5990 AC_SUBST(NCURSES_PATCH)
5991 dnl We need these values in the generated makefiles
5992 AC_SUBST(cf_cv_rel_version)
5993 AC_SUBST(cf_cv_abi_version)
5994 AC_SUBST(cf_cv_builtin_bool)
5995 AC_SUBST(cf_cv_header_stdbool_h)
5996 AC_SUBST(cf_cv_type_of_bool)dnl
5997 ])dnl
5998 dnl ---------------------------------------------------------------------------
5999 dnl CF_SYS_TIME_SELECT version: 4 updated: 2000/10/04 09:18:40
6000 dnl ------------------
6001 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
6002 dnl older SCO configurations.
6003 AC_DEFUN([CF_SYS_TIME_SELECT],
6004 [
6005 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
6006 AC_CACHE_VAL(cf_cv_sys_time_select,[
6007 AC_TRY_COMPILE([
6008 #include <sys/types.h>
6009 #ifdef HAVE_SYS_TIME_H
6010 #include <sys/time.h>
6011 #endif
6012 #ifdef HAVE_SYS_SELECT_H
6013 #include <sys/select.h>
6014 #endif
6015 ],[],[cf_cv_sys_time_select=yes],
6016      [cf_cv_sys_time_select=no])
6017      ])
6018 AC_MSG_RESULT($cf_cv_sys_time_select)
6019 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT)
6020 ])dnl
6021 dnl ---------------------------------------------------------------------------
6022 dnl CF_TOP_BUILDDIR version: 1 updated: 2006/10/15 16:33:23
6023 dnl ---------------
6024 dnl Define a top_builddir symbol, for applications that need an absolute path.
6025 AC_DEFUN([CF_TOP_BUILDDIR],
6026 [
6027 top_builddir=`pwd`
6028 AC_SUBST(top_builddir)
6029 ])dnl
6030 dnl ---------------------------------------------------------------------------
6031 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
6032 dnl -------------------
6033 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
6034 dnl can define it successfully.
6035 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
6036 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
6037         AC_TRY_COMPILE([
6038 #include <stdlib.h>
6039 #include <string.h>
6040 #include <sys/types.h>
6041 ],[
6042 #ifndef _XOPEN_SOURCE
6043 make an error
6044 #endif],
6045         [cf_cv_xopen_source=no],
6046         [cf_save="$CPPFLAGS"
6047          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
6048          AC_TRY_COMPILE([
6049 #include <stdlib.h>
6050 #include <string.h>
6051 #include <sys/types.h>
6052 ],[
6053 #ifdef _XOPEN_SOURCE
6054 make an error
6055 #endif],
6056         [cf_cv_xopen_source=no],
6057         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
6058         CPPFLAGS="$cf_save"
6059         ])
6060 ])
6061
6062 if test "$cf_cv_xopen_source" != no ; then
6063         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
6064         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
6065         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
6066         CF_ADD_CFLAGS($cf_temp_xopen_source)
6067 fi
6068 ])
6069 dnl ---------------------------------------------------------------------------
6070 dnl CF_TYPEOF_CHTYPE version: 8 updated: 2006/12/16 12:33:30
6071 dnl ----------------
6072 dnl Determine the type we should use for chtype (and attr_t, which is treated
6073 dnl as the same thing).  We want around 32 bits, so on most machines want a
6074 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
6075 dnl wide characters, we have to have a type compatible with that, as well.
6076 AC_DEFUN([CF_TYPEOF_CHTYPE],
6077 [
6078 AC_MSG_CHECKING([for type of chtype])
6079 AC_CACHE_VAL(cf_cv_typeof_chtype,[
6080                 AC_TRY_RUN([
6081 #define WANT_BITS 31
6082 #include <stdio.h>
6083 int main()
6084 {
6085         FILE *fp = fopen("cf_test.out", "w");
6086         if (fp != 0) {
6087                 char *result = "long";
6088                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
6089                         int n;
6090                         unsigned int x, y;
6091                         for (n = 0; n < WANT_BITS; n++) {
6092                                 x = (1 << n);
6093                                 y = (x >> n);
6094                                 if (y != 1 || x == 0) {
6095                                         x = 0;
6096                                         break;
6097                                 }
6098                         }
6099                         /*
6100                          * If x is nonzero, an int is big enough for the bits
6101                          * that we want.
6102                          */
6103                         result = (x != 0) ? "int" : "long";
6104                 }
6105                 fputs(result, fp);
6106                 fclose(fp);
6107         }
6108         ${cf_cv_main_return:-return}(0);
6109 }
6110                 ],
6111                 [cf_cv_typeof_chtype=`cat cf_test.out`],
6112                 [cf_cv_typeof_chtype=long],
6113                 [cf_cv_typeof_chtype=long])
6114                 rm -f cf_test.out
6115         ])
6116 AC_MSG_RESULT($cf_cv_typeof_chtype)
6117
6118 AC_SUBST(cf_cv_typeof_chtype)
6119 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype)
6120 ])dnl
6121 dnl ---------------------------------------------------------------------------
6122 dnl CF_TYPE_SIGACTION version: 3 updated: 2000/08/12 23:18:52
6123 dnl -----------------
6124 dnl
6125 AC_DEFUN([CF_TYPE_SIGACTION],
6126 [
6127 AC_MSG_CHECKING([for type sigaction_t])
6128 AC_CACHE_VAL(cf_cv_type_sigaction,[
6129         AC_TRY_COMPILE([
6130 #include <signal.h>],
6131                 [sigaction_t x],
6132                 [cf_cv_type_sigaction=yes],
6133                 [cf_cv_type_sigaction=no])])
6134 AC_MSG_RESULT($cf_cv_type_sigaction)
6135 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION)
6136 ])dnl
6137 dnl ---------------------------------------------------------------------------
6138 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
6139 dnl --------------------
6140 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
6141 dnl won't, but they're still there.
6142 AC_DEFUN([CF_UNSIGNED_LITERALS],
6143 [
6144 AC_MSG_CHECKING([if unsigned literals are legal])
6145 AC_CACHE_VAL(cf_cv_unsigned_literals,[
6146         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
6147                 [cf_cv_unsigned_literals=yes],
6148                 [cf_cv_unsigned_literals=no])
6149         ])
6150 AC_MSG_RESULT($cf_cv_unsigned_literals)
6151 ])dnl
6152 dnl ---------------------------------------------------------------------------
6153 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
6154 dnl --------
6155 dnl Make an uppercase version of a variable
6156 dnl $1=uppercase($2)
6157 AC_DEFUN([CF_UPPER],
6158 [
6159 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
6160 ])dnl
6161 dnl ---------------------------------------------------------------------------
6162 dnl CF_UTF8_LIB version: 7 updated: 2010/06/20 09:24:28
6163 dnl -----------
6164 dnl Check for multibyte support, and if not found, utf8 compatibility library
6165 AC_DEFUN([CF_UTF8_LIB],
6166 [
6167 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
6168         cf_save_LIBS="$LIBS"
6169         AC_TRY_LINK([
6170 #include <stdlib.h>],[putwc(0,0);],
6171         [cf_cv_utf8_lib=yes],
6172         [CF_FIND_LINKAGE([
6173 #include <libutf8.h>],[putwc(0,0);],utf8,
6174                 [cf_cv_utf8_lib=add-on],
6175                 [cf_cv_utf8_lib=no])
6176 ])])
6177
6178 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
6179 # ncurses/ncursesw:
6180 if test "$cf_cv_utf8_lib" = "add-on" ; then
6181         AC_DEFINE(HAVE_LIBUTF8_H)
6182         CF_ADD_INCDIR($cf_cv_header_path_utf8)
6183         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
6184         CF_ADD_LIBS($cf_cv_library_file_utf8)
6185 fi
6186 ])dnl
6187 dnl ---------------------------------------------------------------------------
6188 dnl CF_VA_COPY version: 2 updated: 2010/03/04 05:37:29
6189 dnl ----------
6190 dnl check for va_copy, part of stdarg.h
6191 dnl Also, workaround for glibc's __va_copy, by checking for both.
6192 AC_DEFUN([CF_VA_COPY],[
6193 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
6194 AC_TRY_LINK([
6195 #include <stdarg.h>
6196 ],[
6197         static va_list dst;
6198         static va_list src;
6199         va_copy(dst, src)],
6200         cf_cv_have_va_copy=yes,
6201         cf_cv_have_va_copy=no)])
6202
6203 test "$cf_cv_have_va_copy" = yes && AC_DEFINE(HAVE_VA_COPY)
6204
6205 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
6206 AC_TRY_LINK([
6207 #include <stdarg.h>
6208 ],[
6209         static va_list dst;
6210         static va_list src;
6211         __va_copy(dst, src)],
6212         cf_cv_have___va_copy=yes,
6213         cf_cv_have___va_copy=no)])
6214
6215 test "$cf_cv_have___va_copy" = yes && AC_DEFINE(HAVE___VA_COPY)
6216 ])
6217 dnl ---------------------------------------------------------------------------
6218 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
6219 dnl ----------
6220 dnl Use AC_VERBOSE w/o the warnings
6221 AC_DEFUN([CF_VERBOSE],
6222 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
6223 CF_MSG_LOG([$1])
6224 ])dnl
6225 dnl ---------------------------------------------------------------------------
6226 dnl CF_WCHAR_TYPE version: 3 updated: 2010/05/26 16:44:57
6227 dnl -------------
6228 dnl Check if type wide-character type $1 is declared, and if so, which header
6229 dnl file is needed.  The second parameter is used to set a shell variable when
6230 dnl the type is not found.  The first parameter sets a shell variable for the
6231 dnl opposite sense.
6232 AC_DEFUN([CF_WCHAR_TYPE],
6233 [
6234 # This is needed on Tru64 5.0 to declare $1
6235 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
6236 AC_TRY_COMPILE([
6237 #include <stdlib.h>
6238 #include <stdarg.h>
6239 #include <stdio.h>
6240 #ifdef HAVE_LIBUTF8_H
6241 #include <libutf8.h>
6242 #endif],
6243         [$1 state],
6244         [cf_cv_$1=no],
6245         [AC_TRY_COMPILE([
6246 #include <stdlib.h>
6247 #include <stdarg.h>
6248 #include <stdio.h>
6249 #include <wchar.h>
6250 #ifdef HAVE_LIBUTF8_H
6251 #include <libutf8.h>
6252 #endif],
6253         [$1 value],
6254         [cf_cv_$1=yes],
6255         [cf_cv_$1=unknown])])])
6256
6257 if test "$cf_cv_$1" = yes ; then
6258         AC_DEFINE(NEED_WCHAR_H)
6259         NEED_WCHAR_H=1
6260 fi
6261
6262 ifelse([$2],,,[
6263 # if we do not find $1 in either place, use substitution to provide a fallback.
6264 if test "$cf_cv_$1" = unknown ; then
6265         $2=1
6266 fi
6267 ])
6268 ifelse($3,,,[
6269 # if we find $1 in either place, use substitution to provide a fallback.
6270 if test "$cf_cv_$1" != unknown ; then
6271         $3=1
6272 fi
6273 ])
6274 ])dnl
6275 dnl ---------------------------------------------------------------------------
6276 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
6277 dnl ---------------
6278 dnl Check for compiler-support for weak symbols.
6279 dnl This works with "recent" gcc.
6280 AC_DEFUN([CF_WEAK_SYMBOLS],[
6281 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
6282
6283 AC_TRY_COMPILE([
6284 #include <stdio.h>],
6285 [
6286 #if defined(__GNUC__)
6287 #  if defined __USE_ISOC99
6288 #    define _cat_pragma(exp)    _Pragma(#exp)
6289 #    define _weak_pragma(exp)   _cat_pragma(weak name)
6290 #  else
6291 #    define _weak_pragma(exp)
6292 #  endif
6293 #  define _declare(name)        __extension__ extern __typeof__(name) name
6294 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
6295 #endif
6296
6297 weak_symbol(fopen);
6298 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
6299 ])
6300 ])dnl
6301 dnl ---------------------------------------------------------------------------
6302 dnl CF_WITH_ABI_VERSION version: 1 updated: 2003/09/20 18:12:49
6303 dnl -------------------
6304 dnl Allow library's ABI to be overridden.  Generally this happens when a
6305 dnl packager has incremented the ABI past that used in the original package,
6306 dnl and wishes to keep doing this.
6307 dnl
6308 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
6309 dnl symbol.
6310 AC_DEFUN([CF_WITH_ABI_VERSION],[
6311 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
6312 AC_ARG_WITH(abi-version,
6313 [  --with-abi-version=XXX  override derived ABI version],
6314 [AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
6315  cf_cv_abi_version=$withval])
6316  CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
6317 ifelse($1,,,[
6318 $1_ABI=$cf_cv_abi_version
6319 ])
6320 ])dnl
6321 dnl ---------------------------------------------------------------------------
6322 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
6323 dnl --------------------
6324 dnl Command-line option to specify the Ada95 compiler.
6325 AC_DEFUN([CF_WITH_ADA_COMPILER],[
6326 AC_MSG_CHECKING(for ada-compiler)
6327 AC_ARG_WITH(ada-compiler,
6328         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
6329         [cf_ada_compiler=$withval],
6330         [cf_ada_compiler=gnatmake])
6331 AC_SUBST(cf_ada_compiler)
6332 AC_MSG_RESULT($cf_ada_compiler)
6333 ])dnl
6334 dnl ---------------------------------------------------------------------------
6335 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
6336 dnl -------------------
6337 dnl Command-line option to specify where Ada includes will install.
6338 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
6339 AC_MSG_CHECKING(for ada-include)
6340 CF_WITH_PATH(ada-include,
6341    [  --with-ada-include=DIR  Ada includes are in DIR],
6342    ADA_INCLUDE,
6343    PREFIX/share/ada/adainclude,
6344    [$]prefix/share/ada/adainclude)
6345 AC_SUBST(ADA_INCLUDE)
6346 AC_MSG_RESULT($ADA_INCLUDE)
6347 ])dnl
6348 dnl ---------------------------------------------------------------------------
6349 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
6350 dnl -------------------
6351 dnl Command-line option to specify where Ada objects will install.
6352 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
6353 AC_MSG_CHECKING(for ada-objects)
6354 CF_WITH_PATH(ada-objects,
6355    [  --with-ada-objects=DIR  Ada objects are in DIR],
6356    ADA_OBJECTS,
6357    PREFIX/lib/ada/adalib,
6358    [$]prefix/lib/ada/adalib)
6359 AC_SUBST(ADA_OBJECTS)
6360 AC_MSG_RESULT($ADA_OBJECTS)
6361 ])dnl
6362 dnl ---------------------------------------------------------------------------
6363 dnl CF_WITH_ADA_SHAREDLIB version: 2 updated: 2010/06/26 17:35:58
6364 dnl ---------------------
6365 dnl Command-line option to specify if an Ada95 shared-library should be built,
6366 dnl and optionally what its soname should be.
6367 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
6368 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
6369 AC_ARG_WITH(ada-sharedlib,
6370         [  --with-ada-sharedlib=XX build Ada95 shared-library],
6371         [with_ada_sharedlib=$withval],
6372         [with_ada_sharedlib=no])
6373 AC_MSG_RESULT($with_ada_sharedlib)
6374
6375 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
6376 MAKE_ADA_SHAREDLIB="#"
6377
6378 if test "x$with_ada_sharedlib" != xno
6379 then
6380         MAKE_ADA_SHAREDLIB=
6381         if test "x$with_ada_sharedlib" != xyes
6382         then
6383                 ADA_SHAREDLIB="$with_ada_sharedlib"
6384         fi
6385 fi
6386
6387 AC_SUBST(ADA_SHAREDLIB)
6388 AC_SUBST(MAKE_ADA_SHAREDLIB)
6389 ])dnl
6390 dnl ---------------------------------------------------------------------------
6391 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
6392 dnl ----------------
6393 dnl Configure-option for dbmalloc.  The optional parameter is used to override
6394 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6395 AC_DEFUN([CF_WITH_DBMALLOC],[
6396 CF_NO_LEAKS_OPTION(dbmalloc,
6397         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
6398         [USE_DBMALLOC])
6399
6400 if test "$with_dbmalloc" = yes ; then
6401         AC_CHECK_HEADER(dbmalloc.h,
6402                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
6403 fi
6404 ])dnl
6405 dnl ---------------------------------------------------------------------------
6406 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
6407 dnl ---------------
6408 dnl Configure-option for dmalloc.  The optional parameter is used to override
6409 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6410 AC_DEFUN([CF_WITH_DMALLOC],[
6411 CF_NO_LEAKS_OPTION(dmalloc,
6412         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
6413         [USE_DMALLOC])
6414
6415 if test "$with_dmalloc" = yes ; then
6416         AC_CHECK_HEADER(dmalloc.h,
6417                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
6418 fi
6419 ])dnl
6420 dnl ---------------------------------------------------------------------------
6421 dnl CF_WITH_GPM version: 7 updated: 2008/03/23 14:48:54
6422 dnl -----------
6423 dnl
6424 dnl The option parameter (if neither yes/no) is assumed to be the name of
6425 dnl the gpm library, e.g., for dynamic loading.
6426 AC_DEFUN([CF_WITH_GPM],
6427 [
6428 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
6429 AC_ARG_WITH(gpm,
6430         [  --with-gpm              use Alessandro Rubini's GPM library],
6431         [with_gpm=$withval],
6432         [with_gpm=maybe])
6433 AC_MSG_RESULT($with_gpm)
6434
6435 if test "$with_gpm" != no ; then
6436         AC_CHECK_HEADER(gpm.h,[
6437                 AC_DEFINE(HAVE_GPM_H)
6438                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
6439                         CF_VERBOSE(assuming we really have GPM library)
6440                         AC_DEFINE(HAVE_LIBGPM)
6441                 else
6442                         AC_CHECK_LIB(gpm,Gpm_Open,[:],[
6443                                 AC_MSG_ERROR(Cannot link with GPM library)
6444                 fi
6445                 with_gpm=yes
6446                 ])
6447         ],[
6448                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
6449                 with_gpm=no
6450         ])
6451 fi
6452 ])
6453 dnl ---------------------------------------------------------------------------
6454 dnl CF_WITH_LIBTOOL version: 28 updated: 2011/07/02 15:40:32
6455 dnl ---------------
6456 dnl Provide a configure option to incorporate libtool.  Define several useful
6457 dnl symbols for the makefile rules.
6458 dnl
6459 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
6460 dnl macros from libtool.m4 which is in the aclocal directory of automake.
6461 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
6462 dnl But that still does not work properly since the macro is expanded outside
6463 dnl the CF_WITH_LIBTOOL macro:
6464 dnl
6465 dnl     #!/bin/sh
6466 dnl     ACLOCAL=`aclocal --print-ac-dir`
6467 dnl     if test -z "$ACLOCAL" ; then
6468 dnl             echo cannot find aclocal directory
6469 dnl             exit 1
6470 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
6471 dnl             echo cannot find libtool.m4 file
6472 dnl             exit 1
6473 dnl     fi
6474 dnl
6475 dnl     LOCAL=aclocal.m4
6476 dnl     ORIG=aclocal.m4.orig
6477 dnl
6478 dnl     trap "mv $ORIG $LOCAL" 0 1 2 5 15
6479 dnl     rm -f $ORIG
6480 dnl     mv $LOCAL $ORIG
6481 dnl
6482 dnl     # sed the LIBTOOL= assignment to omit the current directory?
6483 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
6484 dnl     cat $ORIG >>$LOCAL
6485 dnl
6486 dnl     autoconf-257 $*
6487 dnl
6488 AC_DEFUN([CF_WITH_LIBTOOL],
6489 [
6490 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
6491 ifdef([AC_PROG_LIBTOOL],,[
6492 LIBTOOL=
6493 ])
6494 # common library maintenance symbols that are convenient for libtool scripts:
6495 LIB_CREATE='${AR} -cr'
6496 LIB_OBJECT='${OBJECTS}'
6497 LIB_SUFFIX=.a
6498 LIB_PREP="$RANLIB"
6499
6500 # symbols used to prop libtool up to enable it to determine what it should be
6501 # doing:
6502 LIB_CLEAN=
6503 LIB_COMPILE=
6504 LIB_LINK='${CC}'
6505 LIB_INSTALL=
6506 LIB_UNINSTALL=
6507
6508 AC_MSG_CHECKING(if you want to build libraries with libtool)
6509 AC_ARG_WITH(libtool,
6510         [  --with-libtool          generate libraries with libtool],
6511         [with_libtool=$withval],
6512         [with_libtool=no])
6513 AC_MSG_RESULT($with_libtool)
6514 if test "$with_libtool" != "no"; then
6515 ifdef([AC_PROG_LIBTOOL],[
6516         # missing_content_AC_PROG_LIBTOOL{{
6517         AC_PROG_LIBTOOL
6518         # missing_content_AC_PROG_LIBTOOL}}
6519 ],[
6520         if test "$with_libtool" != "yes" ; then
6521                 CF_PATH_SYNTAX(with_libtool)
6522                 LIBTOOL=$with_libtool
6523         else
6524                 AC_PATH_PROG(LIBTOOL,libtool)
6525         fi
6526         if test -z "$LIBTOOL" ; then
6527                 AC_MSG_ERROR(Cannot find libtool)
6528         fi
6529 ])dnl
6530         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${DESTDIR}${libdir} ${LIBTOOL_VERSION} `cut -f1 ${srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
6531         LIB_OBJECT='${OBJECTS:.o=.lo}'
6532         LIB_SUFFIX=.la
6533         LIB_CLEAN='${LIBTOOL} --mode=clean'
6534         LIB_COMPILE='${LIBTOOL} --mode=compile'
6535         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
6536         LIB_INSTALL='${LIBTOOL} --mode=install'
6537         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
6538         LIB_PREP=:
6539
6540         # Show the version of libtool
6541         AC_MSG_CHECKING(version of libtool)
6542
6543         # Save the version in a cache variable - this is not entirely a good
6544         # thing, but the version string from libtool is very ugly, and for
6545         # bug reports it might be useful to have the original string. "("
6546         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
6547         AC_MSG_RESULT($cf_cv_libtool_version)
6548         if test -z "$cf_cv_libtool_version" ; then
6549                 AC_MSG_ERROR(This is not GNU libtool)
6550         fi
6551
6552         # special hack to add -no-undefined (which libtool should do for itself)
6553         LT_UNDEF=
6554         case "$cf_cv_system_name" in #(vi
6555         cygwin*|mingw32*|uwin*|aix[[4-7]]) #(vi
6556                 LT_UNDEF=-no-undefined
6557                 ;;
6558         esac
6559         AC_SUBST([LT_UNDEF])
6560
6561         # special hack to add --tag option for C++ compiler
6562         case $cf_cv_libtool_version in #(vi
6563         1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*) #(vi
6564                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
6565                 LIBTOOL="$LIBTOOL --tag=CC"
6566                 ;;
6567         *)
6568                 LIBTOOL_CXX="$LIBTOOL"
6569                 ;;
6570         esac
6571 else
6572         LIBTOOL=""
6573         LIBTOOL_CXX=""
6574 fi
6575
6576 test -z "$LIBTOOL" && ECHO_LT=
6577
6578 AC_SUBST(LIBTOOL)
6579 AC_SUBST(LIBTOOL_CXX)
6580 AC_SUBST(LIBTOOL_OPTS)
6581
6582 AC_SUBST(LIB_CREATE)
6583 AC_SUBST(LIB_OBJECT)
6584 AC_SUBST(LIB_SUFFIX)
6585 AC_SUBST(LIB_PREP)
6586
6587 AC_SUBST(LIB_CLEAN)
6588 AC_SUBST(LIB_COMPILE)
6589 AC_SUBST(LIB_LINK)
6590 AC_SUBST(LIB_INSTALL)
6591 AC_SUBST(LIB_UNINSTALL)
6592
6593 ])dnl
6594 dnl ---------------------------------------------------------------------------
6595 dnl CF_WITH_PATH version: 10 updated: 2010/10/23 15:44:18
6596 dnl ------------
6597 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
6598 dnl defaulting to yes/no.
6599 dnl
6600 dnl $1 = option name
6601 dnl $2 = help-text
6602 dnl $3 = environment variable to set
6603 dnl $4 = default value, shown in the help-message, must be a constant
6604 dnl $5 = default value, if it's an expression & cannot be in the help-message
6605 dnl
6606 AC_DEFUN([CF_WITH_PATH],
6607 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
6608 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
6609 if ifelse([$5],,true,[test -n "$5"]) ; then
6610 CF_PATH_SYNTAX(withval)
6611 fi
6612 $3="$withval"
6613 AC_SUBST($3)dnl
6614 ])dnl
6615 dnl ---------------------------------------------------------------------------
6616 dnl CF_WITH_PATHLIST version: 7 updated: 2010/10/23 16:10:30
6617 dnl ----------------
6618 dnl Process an option specifying a list of colon-separated paths.
6619 dnl
6620 dnl $1 = option name
6621 dnl $2 = help-text
6622 dnl $3 = environment variable to set
6623 dnl $4 = default value, shown in the help-message, must be a constant
6624 dnl $5 = default value, if it's an expression & cannot be in the help-message
6625 dnl $6 = flag to tell if we want to define or substitute
6626 dnl
6627 AC_DEFUN([CF_WITH_PATHLIST],[
6628 AC_REQUIRE([CF_PATHSEP])
6629 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
6630 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
6631
6632 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
6633 cf_dst_path=
6634 for cf_src_path in $withval
6635 do
6636   CF_PATH_SYNTAX(cf_src_path)
6637   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}:"
6638   cf_dst_path="${cf_dst_path}${cf_src_path}"
6639 done
6640 IFS="$ac_save_ifs"
6641
6642 ifelse($6,define,[
6643 # Strip single quotes from the value, e.g., when it was supplied as a literal
6644 # for $4 or $5.
6645 case $cf_dst_path in #(vi
6646 \'*)
6647   cf_dst_path=`echo $cf_dst_path |sed -e s/\'// -e s/\'\$//`
6648   ;;
6649 esac
6650 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
6651 ])
6652
6653 eval '$3="$cf_dst_path"'
6654 AC_SUBST($3)dnl
6655
6656 ])dnl
6657 dnl ---------------------------------------------------------------------------
6658 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 1 updated: 2011/09/10 16:20:21
6659 dnl -------------------------
6660 dnl Allow the choice of the pkg-config library directory to be overridden.
6661 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
6662 if test "$PKG_CONFIG" != no ; then
6663         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
6664         AC_ARG_WITH(pkg-config-libdir,
6665                 [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
6666                 [PKG_CONFIG_LIBDIR=$withval],
6667                 [PKG_CONFIG_LIBDIR=yes])
6668
6669         case x$PKG_CONFIG_LIBDIR in #(vi
6670         x/*) #(vi
6671                 ;;
6672         xyes) #(vi
6673                 # look for the library directory using the same prefix as the executable
6674                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
6675                 case x`(arch) 2>/dev/null` in #(vi
6676                 *64) #(vi
6677                         for cf_config in $cf_path/share $cf_path/lib64 $cf_path/lib32 $cf_path/lib
6678                         do
6679                                 if test -d $cf_config/pkgconfig
6680                                 then
6681                                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
6682                                         break
6683                                 fi
6684                         done
6685                         ;;
6686                 *)
6687                         PKG_CONFIG_LIBDIR=$cf_path/lib/pkgconfig
6688                         ;;
6689                 esac
6690                 ;;
6691         *)
6692                 ;;
6693         esac
6694
6695         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
6696 fi
6697
6698 AC_SUBST(PKG_CONFIG_LIBDIR)
6699 ])dnl
6700 dnl ---------------------------------------------------------------------------
6701 dnl CF_WITH_PTHREAD version: 4 updated: 2011/11/12 21:08:44
6702 dnl ---------------
6703 dnl Check for POSIX thread library.
6704 AC_DEFUN([CF_WITH_PTHREAD],
6705 [
6706 AC_MSG_CHECKING(if you want to link with the pthread library)
6707 AC_ARG_WITH(pthread,
6708     [  --with-pthread          use POSIX thread library],
6709     [with_pthread=$withval],
6710     [with_pthread=no])
6711 AC_MSG_RESULT($with_pthread)
6712
6713 if test "$with_pthread" != no ; then
6714     AC_CHECK_HEADER(pthread.h,[
6715         AC_DEFINE(HAVE_PTHREADS_H)
6716
6717         for cf_lib_pthread in pthread c_r
6718         do
6719             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
6720             cf_save_LIBS="$LIBS"
6721             CF_ADD_LIB($cf_lib_pthread)
6722             AC_TRY_LINK([
6723 #include <pthread.h>
6724 ],[
6725             int rc = pthread_create(0,0,0,0);
6726 ],[with_pthread=yes],[with_pthread=no])
6727             LIBS="$cf_save_LIBS"
6728             AC_MSG_RESULT($with_pthread)
6729             test "$with_pthread" = yes && break
6730         done
6731
6732         if test "$with_pthread" = yes ; then
6733             CF_ADD_LIB($cf_lib_pthread)
6734             AC_DEFINE(HAVE_LIBPTHREADS)
6735         else
6736             AC_MSG_ERROR(Cannot link with pthread library)
6737         fi
6738     ])
6739 fi
6740 ])
6741 dnl ---------------------------------------------------------------------------
6742 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
6743 dnl -------------------
6744 dnl Allow library's release-version to be overridden.  Generally this happens when a
6745 dnl packager has incremented the release-version past that used in the original package,
6746 dnl and wishes to keep doing this.
6747 dnl
6748 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
6749 dnl and {package}_MINOR symbols
6750 dnl symbol.
6751 AC_DEFUN([CF_WITH_REL_VERSION],[
6752 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
6753 AC_ARG_WITH(rel-version,
6754 [  --with-rel-version=XXX  override derived release version],
6755 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
6756  cf_cv_rel_version=$withval])
6757 ifelse($1,,[
6758  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
6759 ],[
6760  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
6761  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
6762  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
6763  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
6764 ])
6765 ])dnl
6766 dnl ---------------------------------------------------------------------------
6767 dnl CF_WITH_SYSMOUSE version: 2 updated: 2003/03/22 19:13:43
6768 dnl ----------------
6769 dnl If we can compile with sysmouse, make it available unless it is not wanted.
6770 AC_DEFUN([CF_WITH_SYSMOUSE],[
6771 # not everyone has "test -c"
6772 if test -c /dev/sysmouse 2>/dev/null ; then
6773 AC_MSG_CHECKING(if you want to use sysmouse)
6774 AC_ARG_WITH(sysmouse,
6775         [  --with-sysmouse         use sysmouse (FreeBSD console)],
6776         [cf_with_sysmouse=$withval],
6777         [cf_with_sysmouse=maybe])
6778         if test "$cf_with_sysmouse" != no ; then
6779         AC_TRY_COMPILE([
6780 #include <osreldate.h>
6781 #if (__FreeBSD_version >= 400017)
6782 #include <sys/consio.h>
6783 #include <sys/fbio.h>
6784 #else
6785 #include <machine/console.h>
6786 #endif
6787 ],[
6788         struct mouse_info the_mouse;
6789         ioctl(0, CONS_MOUSECTL, &the_mouse);
6790 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
6791         fi
6792 AC_MSG_RESULT($cf_with_sysmouse)
6793 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE)
6794 fi
6795 ])dnl
6796 dnl ---------------------------------------------------------------------------
6797 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
6798 dnl ----------------
6799 AC_DEFUN([CF_WITH_VALGRIND],[
6800 CF_NO_LEAKS_OPTION(valgrind,
6801         [  --with-valgrind         test: use valgrind],
6802         [USE_VALGRIND])
6803 ])dnl
6804 dnl ---------------------------------------------------------------------------
6805 dnl CF_XOPEN_SOURCE version: 40 updated: 2011/11/12 21:08:44
6806 dnl ---------------
6807 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
6808 dnl or adapt to the vendor's definitions to get equivalent functionality,
6809 dnl without losing the common non-POSIX features.
6810 dnl
6811 dnl Parameters:
6812 dnl     $1 is the nominal value for _XOPEN_SOURCE
6813 dnl     $2 is the nominal value for _POSIX_C_SOURCE
6814 AC_DEFUN([CF_XOPEN_SOURCE],[
6815
6816 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
6817 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
6818 cf_xopen_source=
6819
6820 case $host_os in #(vi
6821 aix[[4-7]]*) #(vi
6822         cf_xopen_source="-D_ALL_SOURCE"
6823         ;;
6824 cygwin) #(vi
6825         cf_XOPEN_SOURCE=600
6826         ;;
6827 darwin[[0-8]].*) #(vi
6828         cf_xopen_source="-D_APPLE_C_SOURCE"
6829         ;;
6830 darwin*) #(vi
6831         cf_xopen_source="-D_DARWIN_C_SOURCE"
6832         ;;
6833 freebsd*|dragonfly*) #(vi
6834         # 5.x headers associate
6835         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
6836         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
6837         cf_POSIX_C_SOURCE=200112L
6838         cf_XOPEN_SOURCE=600
6839         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
6840         ;;
6841 hpux11*) #(vi
6842         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
6843         ;;
6844 hpux*) #(vi
6845         cf_xopen_source="-D_HPUX_SOURCE"
6846         ;;
6847 irix[[56]].*) #(vi
6848         cf_xopen_source="-D_SGI_SOURCE"
6849         ;;
6850 linux*|gnu*|mint*|k*bsd*-gnu) #(vi
6851         CF_GNU_SOURCE
6852         ;;
6853 mirbsd*) #(vi
6854         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
6855         cf_XOPEN_SOURCE=
6856         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
6857         ;;
6858 netbsd*) #(vi
6859         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
6860         ;;
6861 openbsd[[4-9]]*) #(vi
6862         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
6863         cf_XOPEN_SOURCE=600
6864         ;;
6865 openbsd*) #(vi
6866         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
6867         ;;
6868 osf[[45]]*) #(vi
6869         cf_xopen_source="-D_OSF_SOURCE"
6870         ;;
6871 nto-qnx*) #(vi
6872         cf_xopen_source="-D_QNX_SOURCE"
6873         ;;
6874 sco*) #(vi
6875         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
6876         ;;
6877 solaris2.*) #(vi
6878         cf_xopen_source="-D__EXTENSIONS__"
6879         ;;
6880 *)
6881         CF_TRY_XOPEN_SOURCE
6882         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
6883         ;;
6884 esac
6885
6886 if test -n "$cf_xopen_source" ; then
6887         CF_ADD_CFLAGS($cf_xopen_source)
6888 fi
6889
6890 dnl In anything but the default case, we may have system-specific setting
6891 dnl which is still not guaranteed to provide all of the entrypoints that
6892 dnl _XOPEN_SOURCE would yield.
6893 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
6894         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
6895         AC_TRY_COMPILE([#include <stdlib.h>],[
6896 #ifndef _XOPEN_SOURCE
6897 make an error
6898 #endif],
6899         [cf_XOPEN_SOURCE_set=yes],
6900         [cf_XOPEN_SOURCE_set=no])
6901         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
6902         if test $cf_XOPEN_SOURCE_set = yes
6903         then
6904                 AC_TRY_COMPILE([#include <stdlib.h>],[
6905 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
6906 make an error
6907 #endif],
6908                 [cf_XOPEN_SOURCE_set_ok=yes],
6909                 [cf_XOPEN_SOURCE_set_ok=no])
6910                 if test $cf_XOPEN_SOURCE_set_ok = no
6911                 then
6912                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
6913                 fi
6914         else
6915                 CF_TRY_XOPEN_SOURCE
6916         fi
6917 fi
6918 ])