ncurses 5.9 - patch 20140831
[ncurses.git] / aclocal.m4
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2013,2014 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1995-on
30 dnl
31 dnl $Id: aclocal.m4,v 1.706 2014/08/02 22:38:39 tom Exp $
32 dnl Macros used in NCURSES auto-configuration script.
33 dnl
34 dnl These macros are maintained separately from NCURSES.  The copyright on
35 dnl this file applies to the aggregation of macros and does not affect use of
36 dnl these macros in other applications.
37 dnl
38 dnl See http://invisible-island.net/autoconf/ for additional information.
39 dnl
40 dnl ---------------------------------------------------------------------------
41 dnl ---------------------------------------------------------------------------
42 dnl AM_LANGINFO_CODESET version: 3 updated: 2002/10/27 23:21:42
43 dnl -------------------
44 dnl Inserted as requested by gettext 0.10.40
45 dnl File from /usr/share/aclocal
46 dnl codeset.m4
47 dnl ====================
48 dnl serial AM1
49 dnl
50 dnl From Bruno Haible.
51 AC_DEFUN([AM_LANGINFO_CODESET],
52 [
53   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
54     [AC_TRY_LINK([#include <langinfo.h>],
55       [char* cs = nl_langinfo(CODESET);],
56       am_cv_langinfo_codeset=yes,
57       am_cv_langinfo_codeset=no)
58     ])
59   if test $am_cv_langinfo_codeset = yes; then
60     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
61       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
62   fi
63 ])dnl
64 dnl ---------------------------------------------------------------------------
65 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
66 dnl ------------------
67 dnl Conditionally generate script according to whether we're using a given autoconf.
68 dnl
69 dnl $1 = version to compare against
70 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
71 dnl $3 = code to use if AC_ACVERSION is older than $1.
72 define([CF_ACVERSION_CHECK],
73 [
74 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
75 ifdef([m4_version_compare],
76 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
77 [CF_ACVERSION_COMPARE(
78 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
79 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
80 dnl ---------------------------------------------------------------------------
81 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
82 dnl --------------------
83 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
84 dnl                      MAJOR2, MINOR2, TERNARY2,
85 dnl                      PRINTABLE2, not FOUND, FOUND)
86 define([CF_ACVERSION_COMPARE],
87 [ifelse(builtin([eval], [$2 < $5]), 1,
88 [ifelse([$8], , ,[$8])],
89 [ifelse([$9], , ,[$9])])])dnl
90 dnl ---------------------------------------------------------------------------
91 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
92 dnl -------------------
93 dnl Construct the list of include-options for the C programs in the Ada95
94 dnl binding.
95 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
96 [
97 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
98 if test "$srcdir" != "."; then
99         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
100 fi
101 if test "$GCC" != yes; then
102         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
103 elif test "$includedir" != "/usr/include"; then
104         if test "$includedir" = '${prefix}/include' ; then
105                 if test x$prefix != x/usr ; then
106                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
107                 fi
108         else
109                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
110         fi
111 fi
112 AC_SUBST(ACPPFLAGS)
113 ])dnl
114 dnl ---------------------------------------------------------------------------
115 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
116 dnl ---------------
117 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
118 AC_DEFUN([CF_ADD_ADAFLAGS],[
119         ADAFLAGS="$ADAFLAGS $1"
120         AC_SUBST(ADAFLAGS)
121 ])dnl
122 dnl ---------------------------------------------------------------------------
123 dnl CF_ADD_CFLAGS version: 11 updated: 2014/07/22 05:32:57
124 dnl -------------
125 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
126 dnl The second parameter if given makes this macro verbose.
127 dnl
128 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
129 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
130 dnl confused by the quotes (which require backslashes to keep them usable).
131 AC_DEFUN([CF_ADD_CFLAGS],
132 [
133 cf_fix_cppflags=no
134 cf_new_cflags=
135 cf_new_cppflags=
136 cf_new_extra_cppflags=
137
138 for cf_add_cflags in $1
139 do
140 case $cf_fix_cppflags in
141 no)
142         case $cf_add_cflags in #(vi
143         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
144                 case $cf_add_cflags in
145                 -D*)
146                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
147
148                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
149                                 && test -z "${cf_tst_cflags}" \
150                                 && cf_fix_cppflags=yes
151
152                         if test $cf_fix_cppflags = yes ; then
153                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
154                                 continue
155                         elif test "${cf_tst_cflags}" = "\"'" ; then
156                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
157                                 continue
158                         fi
159                         ;;
160                 esac
161                 case "$CPPFLAGS" in
162                 *$cf_add_cflags) #(vi
163                         ;;
164                 *) #(vi
165                         case $cf_add_cflags in #(vi
166                         -D*)
167                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
168                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
169                                 ;;
170                         esac
171                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
172                         ;;
173                 esac
174                 ;;
175         *)
176                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
177                 ;;
178         esac
179         ;;
180 yes)
181         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
182
183         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
184
185         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
186                 && test -z "${cf_tst_cflags}" \
187                 && cf_fix_cppflags=no
188         ;;
189 esac
190 done
191
192 if test -n "$cf_new_cflags" ; then
193         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
194         CFLAGS="$CFLAGS $cf_new_cflags"
195 fi
196
197 if test -n "$cf_new_cppflags" ; then
198         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
199         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
200 fi
201
202 if test -n "$cf_new_extra_cppflags" ; then
203         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
204         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
205 fi
206
207 AC_SUBST(EXTRA_CPPFLAGS)
208
209 ])dnl
210 dnl ---------------------------------------------------------------------------
211 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
212 dnl -------------
213 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
214 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
215 dnl but old versions (and some misinstalled ones) need that.  To make things
216 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
217 dnl the include-path).
218 AC_DEFUN([CF_ADD_INCDIR],
219 [
220 if test -n "$1" ; then
221   for cf_add_incdir in $1
222   do
223         while test $cf_add_incdir != /usr/include
224         do
225           if test -d $cf_add_incdir
226           then
227                 cf_have_incdir=no
228                 if test -n "$CFLAGS$CPPFLAGS" ; then
229                   # a loop is needed to ensure we can add subdirs of existing dirs
230                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
231                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
232                           cf_have_incdir=yes; break
233                         fi
234                   done
235                 fi
236
237                 if test "$cf_have_incdir" = no ; then
238                   if test "$cf_add_incdir" = /usr/local/include ; then
239                         if test "$GCC" = yes
240                         then
241                           cf_save_CPPFLAGS=$CPPFLAGS
242                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
243                           AC_TRY_COMPILE([#include <stdio.h>],
244                                   [printf("Hello")],
245                                   [],
246                                   [cf_have_incdir=yes])
247                           CPPFLAGS=$cf_save_CPPFLAGS
248                         fi
249                   fi
250                 fi
251
252                 if test "$cf_have_incdir" = no ; then
253                   CF_VERBOSE(adding $cf_add_incdir to include-path)
254                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
255
256                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
257                   test "$cf_top_incdir" = "$cf_add_incdir" && break
258                   cf_add_incdir="$cf_top_incdir"
259                 else
260                   break
261                 fi
262           fi
263         done
264   done
265 fi
266 ])dnl
267 dnl ---------------------------------------------------------------------------
268 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
269 dnl ----------
270 dnl Add a library, used to enforce consistency.
271 dnl
272 dnl $1 = library to add, without the "-l"
273 dnl $2 = variable to update (default $LIBS)
274 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
275 dnl ---------------------------------------------------------------------------
276 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
277 dnl -------------
278 dnl     Adds to the library-path
279 dnl
280 dnl     Some machines have trouble with multiple -L options.
281 dnl
282 dnl $1 is the (list of) directory(s) to add
283 dnl $2 is the optional name of the variable to update (default LDFLAGS)
284 dnl
285 AC_DEFUN([CF_ADD_LIBDIR],
286 [
287 if test -n "$1" ; then
288   for cf_add_libdir in $1
289   do
290     if test $cf_add_libdir = /usr/lib ; then
291       :
292     elif test -d $cf_add_libdir
293     then
294       cf_have_libdir=no
295       if test -n "$LDFLAGS$LIBS" ; then
296         # a loop is needed to ensure we can add subdirs of existing dirs
297         for cf_test_libdir in $LDFLAGS $LIBS ; do
298           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
299             cf_have_libdir=yes; break
300           fi
301         done
302       fi
303       if test "$cf_have_libdir" = no ; then
304         CF_VERBOSE(adding $cf_add_libdir to library-path)
305         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
306       fi
307     fi
308   done
309 fi
310 ])dnl
311 dnl ---------------------------------------------------------------------------
312 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
313 dnl -----------
314 dnl Add one or more libraries, used to enforce consistency.  Libraries are
315 dnl prepended to an existing list, since their dependencies are assumed to
316 dnl already exist in the list.
317 dnl
318 dnl $1 = libraries to add, with the "-l", etc.
319 dnl $2 = variable to update (default $LIBS)
320 AC_DEFUN([CF_ADD_LIBS],[
321 cf_add_libs="$1"
322 # Filter out duplicates - this happens with badly-designed ".pc" files...
323 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
324 do
325         for cf_add_2lib in $cf_add_libs
326         do
327                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
328                 then
329                         cf_add_1lib=
330                         break
331                 fi
332         done
333         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
334 done
335 ifelse($2,,LIBS,[$2])="$cf_add_libs"
336 ])dnl
337 dnl ---------------------------------------------------------------------------
338 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
339 dnl ------------------
340 dnl Append to a search-list for a nonstandard header/lib-file
341 dnl     $1 = the variable to return as result
342 dnl     $2 = the package name
343 dnl     $3 = the subdirectory, e.g., bin, include or lib
344 dnl $4 = the directory under which we will test for subdirectories
345 dnl $5 = a directory that we do not want $4 to match
346 AC_DEFUN([CF_ADD_SUBDIR_PATH],
347 [
348 test "x$4" != "x$5" && \
349 test -d "$4" && \
350 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
351         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
352         test -d $4/$3 &&          $1="[$]$1 $4/$3"
353         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
354         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
355         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
356         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
357 }
358 ])dnl
359 dnl ---------------------------------------------------------------------------
360 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
361 dnl --------------
362 dnl Allow user to disable a normally-on option.
363 AC_DEFUN([CF_ARG_DISABLE],
364 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
365 dnl ---------------------------------------------------------------------------
366 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
367 dnl -------------
368 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
369 dnl values.
370 dnl
371 dnl Parameters:
372 dnl $1 = option name
373 dnl $2 = help-string
374 dnl $3 = action to perform if option is not default
375 dnl $4 = action if perform if option is default
376 dnl $5 = default option value (either 'yes' or 'no')
377 AC_DEFUN([CF_ARG_OPTION],
378 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
379   if test "$enableval" != "$5" ; then
380 ifelse([$3],,[    :]dnl
381 ,[    $3]) ifelse([$4],,,[
382   else
383     $4])
384   fi],[enableval=$5 ifelse([$4],,,[
385   $4
386 ])dnl
387   ])])dnl
388 dnl ---------------------------------------------------------------------------
389 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
390 dnl -----------
391 dnl Check for suitable "ar" (archiver) options for updating an archive.
392 AC_DEFUN([CF_AR_FLAGS],[
393 AC_REQUIRE([CF_PROG_AR])
394
395 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
396         cf_cv_ar_flags=unknown
397         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
398         do
399
400                 # check if $ARFLAGS already contains this choice
401                 if test "x$ARFLAGS" != "x" ; then
402                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
403                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
404                                 cf_cv_ar_flags=
405                                 break
406                         fi
407                 fi
408
409                 rm -f conftest.$ac_cv_objext
410                 rm -f conftest.a
411
412                 cat >conftest.$ac_ext <<EOF
413 #line __oline__ "configure"
414 int     testdata[[3]] = { 123, 456, 789 };
415 EOF
416                 if AC_TRY_EVAL(ac_compile) ; then
417                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
418                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
419                         if test -f conftest.a ; then
420                                 cf_cv_ar_flags=$cf_ar_flags
421                                 break
422                         fi
423                 else
424                         CF_VERBOSE(cannot compile test-program)
425                         break
426                 fi
427         done
428         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
429 ])
430
431 if test -n "$ARFLAGS" ; then
432         if test -n "$cf_cv_ar_flags" ; then
433                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
434         fi
435 else
436         ARFLAGS=$cf_cv_ar_flags
437 fi
438
439 AC_SUBST(ARFLAGS)
440 ])
441 dnl ---------------------------------------------------------------------------
442 dnl CF_AWK_BIG_PRINTF version: 4 updated: 2011/10/30 17:09:50
443 dnl -----------------
444 dnl Check if awk can handle big strings using printf.  Some older versions of
445 dnl awk choke on large strings passed via "%s".
446 dnl
447 dnl $1 = desired string size
448 dnl $2 = variable to set with result
449 AC_DEFUN([CF_AWK_BIG_PRINTF],
450 [
451         case x$AWK in #(vi
452         x)
453                 eval $2=no
454                 ;;
455         *) #(vi
456                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
457                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
458                         eval $2=yes
459                 else
460                         eval $2=no
461                 fi
462                 ;;
463         esac
464 ])dnl
465 dnl ---------------------------------------------------------------------------
466 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
467 dnl ------------
468 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
469 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
470 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
471 dnl
472 dnl Treat the configuration-variable specially here, since we're directly
473 dnl substituting its value (i.e., 1/0).
474 dnl
475 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
476 AC_DEFUN([CF_BOOL_DECL],
477 [
478 AC_MSG_CHECKING(if we should include stdbool.h)
479
480 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
481         AC_TRY_COMPILE([],[bool foo = false],
482                 [cf_cv_header_stdbool_h=0],
483                 [AC_TRY_COMPILE([
484 #ifndef __BEOS__
485 #include <stdbool.h>
486 #endif
487 ],[bool foo = false],
488                         [cf_cv_header_stdbool_h=1],
489                         [cf_cv_header_stdbool_h=0])])])
490
491 if test "$cf_cv_header_stdbool_h" = 1
492 then    AC_MSG_RESULT(yes)
493 else    AC_MSG_RESULT(no)
494 fi
495
496 AC_MSG_CHECKING([for builtin bool type])
497
498 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
499         AC_TRY_COMPILE([
500 #include <stdio.h>
501 #include <sys/types.h>
502 ],[bool x = false],
503                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
504                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
505         ])
506
507 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
508 then    AC_MSG_RESULT(yes)
509 else    AC_MSG_RESULT(no)
510 fi
511 ])dnl
512 dnl ---------------------------------------------------------------------------
513 dnl CF_BOOL_SIZE version: 13 updated: 2013/04/13 18:03:21
514 dnl ------------
515 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
516 dnl Don't bother looking for bool.h, since it's been deprecated.
517 dnl
518 dnl If the current compiler is C rather than C++, we get the bool definition
519 dnl from <stdbool.h>.
520 AC_DEFUN([CF_BOOL_SIZE],
521 [
522 AC_MSG_CHECKING([for size of bool])
523 AC_CACHE_VAL(cf_cv_type_of_bool,[
524         rm -f cf_test.out
525         AC_TRY_RUN([
526 #include <stdlib.h>
527 #include <stdio.h>
528
529 #if defined(__cplusplus)
530
531 #ifdef HAVE_GXX_BUILTIN_H
532 #include <g++/builtin.h>
533 #elif HAVE_GPP_BUILTIN_H
534 #include <gpp/builtin.h>
535 #elif HAVE_BUILTIN_H
536 #include <builtin.h>
537 #endif
538
539 #else
540
541 #if $cf_cv_header_stdbool_h
542 #include <stdbool.h>
543 #endif
544
545 #endif
546
547 int main()
548 {
549         FILE *fp = fopen("cf_test.out", "w");
550         if (fp != 0) {
551                 bool x = true;
552                 if ((bool)(-x) >= 0)
553                         fputs("unsigned ", fp);
554                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
555                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
556                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
557                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
558                 fclose(fp);
559         }
560         ${cf_cv_main_return:-return}(0);
561 }
562                 ],
563                 [cf_cv_type_of_bool=`cat cf_test.out`
564                  if test -z "$cf_cv_type_of_bool"; then
565                    cf_cv_type_of_bool=unknown
566                  fi],
567                 [cf_cv_type_of_bool=unknown],
568                 [cf_cv_type_of_bool=unknown])
569         ])
570         rm -f cf_test.out
571 AC_MSG_RESULT($cf_cv_type_of_bool)
572 if test "$cf_cv_type_of_bool" = unknown ; then
573         case .$NCURSES_BOOL in #(vi
574         .auto|.) NCURSES_BOOL=unsigned;;
575         esac
576         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
577         cf_cv_type_of_bool=$NCURSES_BOOL
578 fi
579 ])dnl
580 dnl ---------------------------------------------------------------------------
581 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
582 dnl -----------
583 dnl If we're cross-compiling, allow the user to override the tools and their
584 dnl options.  The configure script is oriented toward identifying the host
585 dnl compiler, etc., but we need a build compiler to generate parts of the
586 dnl source.
587 dnl
588 dnl $1 = default for $CPPFLAGS
589 dnl $2 = default for $LIBS
590 AC_DEFUN([CF_BUILD_CC],[
591 CF_ACVERSION_CHECK(2.52,,
592         [AC_REQUIRE([CF_PROG_EXT])])
593 if test "$cross_compiling" = yes ; then
594
595         # defaults that we might want to override
596         : ${BUILD_CFLAGS:=''}
597         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
598         : ${BUILD_LDFLAGS:=''}
599         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
600         : ${BUILD_EXEEXT:='$x'}
601         : ${BUILD_OBJEXT:='o'}
602
603         AC_ARG_WITH(build-cc,
604                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
605                 [BUILD_CC="$withval"],
606                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
607         AC_MSG_CHECKING(for native build C compiler)
608         AC_MSG_RESULT($BUILD_CC)
609
610         AC_MSG_CHECKING(for native build C preprocessor)
611         AC_ARG_WITH(build-cpp,
612                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
613                 [BUILD_CPP="$withval"],
614                 [BUILD_CPP='${BUILD_CC} -E'])
615         AC_MSG_RESULT($BUILD_CPP)
616
617         AC_MSG_CHECKING(for native build C flags)
618         AC_ARG_WITH(build-cflags,
619                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
620                 [BUILD_CFLAGS="$withval"])
621         AC_MSG_RESULT($BUILD_CFLAGS)
622
623         AC_MSG_CHECKING(for native build C preprocessor-flags)
624         AC_ARG_WITH(build-cppflags,
625                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
626                 [BUILD_CPPFLAGS="$withval"])
627         AC_MSG_RESULT($BUILD_CPPFLAGS)
628
629         AC_MSG_CHECKING(for native build linker-flags)
630         AC_ARG_WITH(build-ldflags,
631                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
632                 [BUILD_LDFLAGS="$withval"])
633         AC_MSG_RESULT($BUILD_LDFLAGS)
634
635         AC_MSG_CHECKING(for native build linker-libraries)
636         AC_ARG_WITH(build-libs,
637                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
638                 [BUILD_LIBS="$withval"])
639         AC_MSG_RESULT($BUILD_LIBS)
640
641         # this assumes we're on Unix.
642         BUILD_EXEEXT=
643         BUILD_OBJEXT=o
644
645         : ${BUILD_CC:='${CC}'}
646
647         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
648                 AC_MSG_ERROR([Cross-build requires two compilers.
649 Use --with-build-cc to specify the native compiler.])
650         fi
651
652 else
653         : ${BUILD_CC:='${CC}'}
654         : ${BUILD_CPP:='${CPP}'}
655         : ${BUILD_CFLAGS:='${CFLAGS}'}
656         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
657         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
658         : ${BUILD_LIBS:='${LIBS}'}
659         : ${BUILD_EXEEXT:='$x'}
660         : ${BUILD_OBJEXT:='o'}
661 fi
662
663 AC_SUBST(BUILD_CC)
664 AC_SUBST(BUILD_CPP)
665 AC_SUBST(BUILD_CFLAGS)
666 AC_SUBST(BUILD_CPPFLAGS)
667 AC_SUBST(BUILD_LDFLAGS)
668 AC_SUBST(BUILD_LIBS)
669 AC_SUBST(BUILD_EXEEXT)
670 AC_SUBST(BUILD_OBJEXT)
671 ])dnl
672 dnl ---------------------------------------------------------------------------
673 dnl CF_CC_ENV_FLAGS version: 1 updated: 2012/10/03 05:25:49
674 dnl ---------------
675 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
676 dnl into CC.  This will not help with broken scripts that wrap the compiler with
677 dnl options, but eliminates a more common category of user confusion.
678 AC_DEFUN([CF_CC_ENV_FLAGS],
679 [
680 # This should have been defined by AC_PROG_CC
681 : ${CC:=cc}
682
683 AC_MSG_CHECKING(\$CC variable)
684 case "$CC" in #(vi
685 *[[\ \  ]]-[[IUD]]*)
686         AC_MSG_RESULT(broken)
687         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
688         # humor him...
689         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
690         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
691         CF_ADD_CFLAGS($cf_flags)
692         ;;
693 *)
694         AC_MSG_RESULT(ok)
695         ;;
696 esac
697 ])dnl
698 dnl ---------------------------------------------------------------------------
699 dnl CF_CFG_DEFAULTS version: 10 updated: 2013/09/07 13:54:05
700 dnl ---------------
701 dnl Determine the default configuration into which we'll install ncurses.  This
702 dnl can be overridden by the user's command-line options.  There's two items to
703 dnl look for:
704 dnl     1. the prefix (e.g., /usr)
705 dnl     2. the header files (e.g., /usr/include/ncurses)
706 dnl We'll look for a previous installation of ncurses and use the same defaults.
707 dnl
708 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
709 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
710 dnl programs from a vendor's.
711 AC_DEFUN([CF_CFG_DEFAULTS],
712 [
713 AC_MSG_CHECKING(for prefix)
714 if test "x$prefix" = "xNONE" ; then
715         case "$cf_cv_system_name" in
716                 # non-vendor systems don't have a conflict
717         openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
718                 prefix=/usr
719                 ;;
720         *)      prefix=$ac_default_prefix
721                 ;;
722         esac
723 fi
724 AC_MSG_RESULT($prefix)
725
726 if test "x$prefix" = "xNONE" ; then
727 AC_MSG_CHECKING(for default include-directory)
728 test -n "$verbose" && echo 1>&AC_FD_MSG
729 for cf_symbol in \
730         $includedir \
731         $includedir/ncurses \
732         $prefix/include \
733         $prefix/include/ncurses \
734         /usr/local/include \
735         /usr/local/include/ncurses \
736         /usr/include \
737         /usr/include/ncurses
738 do
739         cf_dir=`eval echo $cf_symbol`
740         if test -f $cf_dir/curses.h ; then
741         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
742                 includedir="$cf_symbol"
743                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
744                 break
745         fi
746         fi
747         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
748 done
749 AC_MSG_RESULT($includedir)
750 fi
751 ])dnl
752 dnl ---------------------------------------------------------------------------
753 dnl CF_CGETENT version: 5 updated: 2012/10/06 17:56:13
754 dnl ----------
755 dnl Check if the terminal-capability database functions are available.  If not,
756 dnl ncurses has a much-reduced version.
757 AC_DEFUN([CF_CGETENT],[
758 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
759 AC_TRY_LINK([
760 #include <stdlib.h>],[
761         char temp[128];
762         char *buf = temp;
763         char *db_array = temp;
764         cgetent(&buf, &db_array, "vt100");
765         cgetcap(buf, "tc", '=');
766         cgetmatch(buf, "tc");
767         ],
768         [cf_cv_cgetent=yes],
769         [cf_cv_cgetent=no])
770 ])
771
772 if test "$cf_cv_cgetent" = yes
773 then
774         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
775 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
776 AC_TRY_LINK([
777 #include <stdlib.h>],[
778         char temp[128];
779         char *buf = temp;
780 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
781         const char *db_array = temp;
782         cgetent(&buf, &db_array, "vt100");
783 #endif
784         cgetcap(buf, "tc", '=');
785         cgetmatch(buf, "tc");
786         ],
787         [cf_cv_cgetent_const=yes],
788         [cf_cv_cgetent_const=no])
789 ])
790         if test "$cf_cv_cgetent_const" = yes
791         then
792                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
793         fi
794 fi
795 ])dnl
796 dnl ---------------------------------------------------------------------------
797 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
798 dnl --------------
799 dnl Check if we're accidentally using a cache from a different machine.
800 dnl Derive the system name, as a check for reusing the autoconf cache.
801 dnl
802 dnl If we've packaged config.guess and config.sub, run that (since it does a
803 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
804 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
805 dnl which is useful in cross-compiles.
806 dnl
807 dnl Note: we would use $ac_config_sub, but that is one of the places where
808 dnl autoconf 2.5x broke compatibility with autoconf 2.13
809 AC_DEFUN([CF_CHECK_CACHE],
810 [
811 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
812         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
813         system_name="$host_os"
814 else
815         system_name="`(uname -s -r) 2>/dev/null`"
816         if test -z "$system_name" ; then
817                 system_name="`(hostname) 2>/dev/null`"
818         fi
819 fi
820 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
821 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
822
823 test -z "$system_name" && system_name="$cf_cv_system_name"
824 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
825
826 if test ".$system_name" != ".$cf_cv_system_name" ; then
827         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
828         AC_MSG_ERROR("Please remove config.cache and try again.")
829 fi
830 ])dnl
831 dnl ---------------------------------------------------------------------------
832 dnl CF_CHECK_ERRNO version: 11 updated: 2010/05/26 05:38:42
833 dnl --------------
834 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
835 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
836 dnl ourselves.
837 dnl
838 dnl $1 = the name to check
839 dnl $2 = the assumed type
840 AC_DEFUN([CF_CHECK_ERRNO],
841 [
842 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
843     AC_TRY_COMPILE([
844 #ifdef HAVE_STDLIB_H
845 #include <stdlib.h>
846 #endif
847 #include <stdio.h>
848 #include <sys/types.h>
849 #include <errno.h> ],
850     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
851     [cf_cv_dcl_$1=yes],
852     [cf_cv_dcl_$1=no])
853 ])
854
855 if test "$cf_cv_dcl_$1" = no ; then
856     CF_UPPER(cf_result,decl_$1)
857     AC_DEFINE_UNQUOTED($cf_result)
858 fi
859
860 # It's possible (for near-UNIX clones) that the data doesn't exist
861 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
862 ])dnl
863 dnl ---------------------------------------------------------------------------
864 dnl CF_CHECK_EXTERN_DATA version: 3 updated: 2001/12/30 18:03:23
865 dnl --------------------
866 dnl Check for existence of external data in the current set of libraries.  If
867 dnl we can modify it, it's real enough.
868 dnl $1 = the name to check
869 dnl $2 = its type
870 AC_DEFUN([CF_CHECK_EXTERN_DATA],
871 [
872 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
873     AC_TRY_LINK([
874 #undef $1
875 extern $2 $1;
876 ],
877     [$1 = 2],
878     [cf_cv_have_$1=yes],
879     [cf_cv_have_$1=no])
880 ])
881
882 if test "$cf_cv_have_$1" = yes ; then
883     CF_UPPER(cf_result,have_$1)
884     AC_DEFINE_UNQUOTED($cf_result)
885 fi
886
887 ])dnl
888 dnl ---------------------------------------------------------------------------
889 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
890 dnl -------------------
891 dnl Check if GPM is already linked with curses.  If so - and if the linkage
892 dnl is not "weak" - warn about this because it can create problems linking
893 dnl applications with ncurses.
894 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
895 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
896
897 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
898 cf_cv_check_gpm_wgetch=unknown
899 if test "$cross_compiling" != yes ; then
900
901 cat >conftest.$ac_ext <<CF_EOF
902 #include <gpm.h>
903 int main()
904 {
905         Gpm_Wgetch();
906         ${cf_cv_main_return:-return}(0);
907 }
908 CF_EOF
909
910         cf_save_LIBS="$LIBS"
911         # This only works if we can look at the symbol table.  If a shared
912         # library is stripped for install, we cannot use that.  So we're forced
913         # to rely on the static library, noting that some packagers may not
914         # include it.
915         LIBS="-static -lgpm -dynamic $LIBS"
916         if AC_TRY_EVAL(ac_compile) ; then
917                 if AC_TRY_EVAL(ac_link) ; then
918                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
919                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
920                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
921                 fi
922         fi
923         rm -rf conftest*
924         LIBS="$cf_save_LIBS"
925 fi
926 ])
927
928 if test "$cf_cv_check_gpm_wgetch" != yes ; then
929         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
930 fi
931 ])])dnl
932 dnl ---------------------------------------------------------------------------
933 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
934 dnl ------------------------
935 dnl Show the version of libtool
936 dnl
937 dnl Save the version in a cache variable - this is not entirely a good thing,
938 dnl but the version string from libtool is very ugly, and for bug reports it
939 dnl might be useful to have the original string.
940 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
941 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
942 then
943         AC_MSG_CHECKING(version of $LIBTOOL)
944         CF_LIBTOOL_VERSION
945         AC_MSG_RESULT($cf_cv_libtool_version)
946         if test -z "$cf_cv_libtool_version" ; then
947                 AC_MSG_ERROR(This is not GNU libtool)
948         fi
949 else
950         AC_MSG_ERROR(GNU libtool has not been found)
951 fi
952 ])dnl
953 dnl ---------------------------------------------------------------------------
954 dnl CF_CHECK_WCHAR_H version: 1 updated: 2011/10/29 15:01:05
955 dnl ----------------
956 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
957 AC_DEFUN([CF_CHECK_WCHAR_H],[
958 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
959 AC_TRY_COMPILE(
960 [
961 #include <stdlib.h>
962 #include <wchar.h>
963 ],[
964         wint_t foo = 0;
965         int bar = iswpunct(foo)],
966         [cf_cv_wchar_h_okay=yes],
967         [cf_cv_wchar_h_okay=no])])
968
969 if test $cf_cv_wchar_h_okay = no
970 then
971         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
972 fi
973 ])dnl
974 dnl ---------------------------------------------------------------------------
975 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
976 dnl -----------------
977 dnl Check if the given compiler is really clang.  clang's C driver defines
978 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
979 dnl not ignore some gcc options.
980 dnl
981 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
982 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
983 dnl the wrappers for gcc and g++ warnings.
984 dnl
985 dnl $1 = GCC (default) or GXX
986 dnl $2 = CLANG_COMPILER (default)
987 dnl $3 = CFLAGS (default) or CXXFLAGS
988 AC_DEFUN([CF_CLANG_COMPILER],[
989 ifelse([$2],,CLANG_COMPILER,[$2])=no
990
991 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
992         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
993         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
994         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
995         AC_TRY_COMPILE([],[
996 #ifdef __clang__
997 #else
998 make an error
999 #endif
1000 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1001 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
1002 ],[])
1003         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1004         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1005 fi
1006 ])
1007 dnl ---------------------------------------------------------------------------
1008 dnl CF_CPP_PARAM_INIT version: 6 updated: 2012/10/06 17:56:13
1009 dnl -----------------
1010 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1011 dnl is a late feature for the standard and is not in some recent compilers
1012 dnl (1999/9/11).
1013 AC_DEFUN([CF_CPP_PARAM_INIT],
1014 [
1015 if test -n "$CXX"; then
1016 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1017         AC_LANG_SAVE
1018         AC_LANG_CPLUSPLUS
1019         AC_TRY_RUN([
1020 class TEST {
1021 private:
1022         int value;
1023 public:
1024         TEST(int x = 1);
1025         ~TEST();
1026 };
1027
1028 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1029 {
1030         value = x;
1031 }
1032 int main() { }
1033 ],
1034         [cf_cv_cpp_param_init=yes],
1035         [cf_cv_cpp_param_init=no],
1036         [cf_cv_cpp_param_init=unknown])
1037         AC_LANG_RESTORE
1038 ])
1039 fi
1040 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1041 ])dnl
1042 dnl ---------------------------------------------------------------------------
1043 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1044 dnl ------------------
1045 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1046 dnl not be supported in g++ before 3.0
1047 AC_DEFUN([CF_CPP_STATIC_CAST],
1048 [
1049 if test -n "$CXX"; then
1050
1051 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1052         AC_LANG_SAVE
1053         AC_LANG_CPLUSPLUS
1054
1055         AC_TRY_COMPILE([
1056 class NCursesPanel
1057 {
1058 public:
1059   NCursesPanel(int nlines,
1060                int ncols,
1061                int begin_y = 0,
1062                int begin_x = 0)
1063   {
1064   }
1065   NCursesPanel();
1066   ~NCursesPanel();
1067 };
1068
1069 template<class T> class NCursesUserPanel : public NCursesPanel
1070 {
1071 public:
1072   NCursesUserPanel (int nlines,
1073                     int ncols,
1074                     int begin_y = 0,
1075                     int begin_x = 0,
1076                     const T* p_UserData = static_cast<T*>(0))
1077     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1078   {
1079   };
1080   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1081   {
1082   };
1083
1084   virtual ~NCursesUserPanel() {};
1085 };
1086 ],[
1087         const char* p_UserData = static_cast<char*>(0)],
1088         [cf_cv_cpp_static_cast=yes],
1089         [cf_cv_cpp_static_cast=no])
1090
1091         AC_LANG_RESTORE
1092 ])
1093
1094 fi
1095
1096 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1097 ])dnl
1098 dnl ---------------------------------------------------------------------------
1099 dnl CF_CXX_AR_FLAGS version: 1 updated: 2011/10/29 08:35:34
1100 dnl ---------------
1101 dnl Setup special archiver flags for given compilers.
1102 AC_DEFUN([CF_CXX_AR_FLAGS],[
1103         CXX_AR='$(AR)'
1104         CXX_ARFLAGS='$(ARFLAGS)'
1105         case $cf_cv_system_name in #(vi
1106         irix*) #(vi
1107             if test "$GXX" != yes ; then
1108                 CXX_AR='$(CXX)'
1109                 CXX_ARFLAGS='-ar -o'
1110             fi
1111             ;;
1112         sco3.2v5*) #(vi
1113             CXXLDFLAGS="-u main"
1114             ;;
1115         solaris2*)
1116             if test "$GXX" != yes ; then
1117                 CXX_AR='$(CXX)'
1118                 CXX_ARFLAGS='-xar -o'
1119             fi
1120             ;;
1121         esac
1122         AC_SUBST(CXXLDFLAGS)
1123         AC_SUBST(CXX_AR)
1124         AC_SUBST(CXX_ARFLAGS)
1125 ])dnl
1126 dnl ---------------------------------------------------------------------------
1127 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1128 dnl -------------------------
1129 dnl For c++, check if iostream uses "std::" namespace.
1130 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1131 AC_CHECK_HEADERS(iostream)
1132 if test x"$ac_cv_header_iostream" = xyes ; then
1133         AC_MSG_CHECKING(if iostream uses std-namespace)
1134         AC_TRY_COMPILE([
1135 #include <iostream>
1136 using std::endl;
1137 using std::cerr;],[
1138 cerr << "testing" << endl;
1139 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1140         AC_MSG_RESULT($cf_iostream_namespace)
1141         if test "$cf_iostream_namespace" = yes ; then
1142                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1143         fi
1144 fi
1145 ])dnl
1146 dnl ---------------------------------------------------------------------------
1147 dnl CF_C_INLINE version: 4 updated: 2012/06/16 14:55:39
1148 dnl -----------
1149 dnl Check if the C compiler supports "inline".
1150 dnl $1 is the name of a shell variable to set if inline is supported
1151 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1152 AC_DEFUN([CF_C_INLINE],[
1153 AC_C_INLINE
1154 $1=
1155 if test "$ac_cv_c_inline" != no ; then
1156   $1=inline
1157   if test "$INTEL_COMPILER" = yes
1158   then
1159     :
1160   elif test "$CLANG_COMPILER" = yes
1161   then
1162     :
1163   elif test "$GCC" = yes
1164   then
1165     AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1166       cf_save_CFLAGS=$CFLAGS
1167       CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1168       AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1169       [${cf_cv_main_return:-return} foo()],
1170       [cf_cv_gcc_inline=yes],
1171       [cf_cv_gcc_inline=no])
1172       CFLAGS=$cf_save_CFLAGS
1173     ])
1174     if test "$cf_cv_gcc_inline" = yes ; then
1175         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1176     fi
1177   fi
1178 fi
1179 AC_SUBST($1)
1180 ])dnl
1181 dnl ---------------------------------------------------------------------------
1182 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1183 dnl ----------
1184 dnl "dirname" is not portable, so we fake it with a shell script.
1185 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1186 dnl ---------------------------------------------------------------------------
1187 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1188 dnl ---------------
1189 AC_DEFUN([CF_DIRS_TO_MAKE],
1190 [
1191 DIRS_TO_MAKE="lib"
1192 for cf_item in $cf_list_models
1193 do
1194         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1195         for cf_item2 in $DIRS_TO_MAKE
1196         do
1197                 test $cf_item2 = $cf_subdir && break
1198         done
1199         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1200 done
1201 for cf_dir in $DIRS_TO_MAKE
1202 do
1203         test ! -d $cf_dir && mkdir $cf_dir
1204 done
1205 AC_SUBST(DIRS_TO_MAKE)
1206 ])dnl
1207 dnl ---------------------------------------------------------------------------
1208 dnl CF_DISABLE_ECHO version: 12 updated: 2012/10/06 16:30:28
1209 dnl ---------------
1210 dnl You can always use "make -n" to see the actual options, but it's hard to
1211 dnl pick out/analyze warning messages when the compile-line is long.
1212 dnl
1213 dnl Sets:
1214 dnl     ECHO_LT - symbol to control if libtool is verbose
1215 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1216 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1217 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1218 dnl     ECHO_CC - symbol to put before any "cc" line
1219 dnl
1220 AC_DEFUN([CF_DISABLE_ECHO],[
1221 AC_MSG_CHECKING(if you want to see long compiling messages)
1222 CF_ARG_DISABLE(echo,
1223         [  --disable-echo          do not display "compiling" commands],
1224         [
1225     ECHO_LT='--silent'
1226     ECHO_LD='@echo linking [$]@;'
1227     RULE_CC='@echo compiling [$]<'
1228     SHOW_CC='@echo compiling [$]@'
1229     ECHO_CC='@'
1230 ],[
1231     ECHO_LT=''
1232     ECHO_LD=''
1233     RULE_CC=''
1234     SHOW_CC=''
1235     ECHO_CC=''
1236 ])
1237 AC_MSG_RESULT($enableval)
1238 AC_SUBST(ECHO_LT)
1239 AC_SUBST(ECHO_LD)
1240 AC_SUBST(RULE_CC)
1241 AC_SUBST(SHOW_CC)
1242 AC_SUBST(ECHO_CC)
1243 ])dnl
1244 dnl ---------------------------------------------------------------------------
1245 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1246 dnl ------------------------
1247 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1248 AC_MSG_CHECKING(if we want to use GNAT projects)
1249 CF_ARG_DISABLE(gnat-projects,
1250         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1251         [enable_gnat_projects=no],
1252         [enable_gnat_projects=yes])
1253 AC_MSG_RESULT($enable_gnat_projects)
1254 ])dnl
1255 dnl ---------------------------------------------------------------------------
1256 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1257 dnl ----------------
1258 dnl Combine no-leak checks with the libraries or tools that are used for the
1259 dnl checks.
1260 AC_DEFUN([CF_DISABLE_LEAKS],[
1261
1262 AC_REQUIRE([CF_WITH_DMALLOC])
1263 AC_REQUIRE([CF_WITH_DBMALLOC])
1264 AC_REQUIRE([CF_WITH_VALGRIND])
1265
1266 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1267 AC_ARG_ENABLE(leaks,
1268         [  --disable-leaks         test: free permanent memory, analyze leaks],
1269         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1270         : ${with_no_leaks:=no})
1271 AC_MSG_RESULT($with_no_leaks)
1272
1273 if test "$with_no_leaks" = yes ; then
1274         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1275         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1276 fi
1277 ])dnl
1278 dnl ---------------------------------------------------------------------------
1279 dnl CF_DISABLE_LIBTOOL_VERSION version: 1 updated: 2010/05/15 15:45:59
1280 dnl --------------------------
1281 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1282 dnl the older "-version-info" feature.  The newer feature allows us to use
1283 dnl version numbering on shared libraries which make them compatible with
1284 dnl various systems.
1285 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1286 [
1287 AC_MSG_CHECKING(if libtool -version-number should be used)
1288 CF_ARG_DISABLE(libtool-version,
1289         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1290         [cf_libtool_version=no],
1291         [cf_libtool_version=yes])
1292 AC_MSG_RESULT($cf_libtool_version)
1293
1294 if test "$cf_libtool_version" = yes ; then
1295         LIBTOOL_VERSION="-version-number"
1296 else
1297         LIBTOOL_VERSION="-version-info"
1298 fi
1299
1300 AC_SUBST(LIBTOOL_VERSION)
1301 ])dnl
1302 dnl ---------------------------------------------------------------------------
1303 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1304 dnl ---------------------
1305 dnl The rpath-hack makes it simpler to build programs, particularly with the
1306 dnl *BSD ports which may have essential libraries in unusual places.  But it
1307 dnl can interfere with building an executable for the base system.  Use this
1308 dnl option in that case.
1309 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1310 [
1311 AC_MSG_CHECKING(if rpath-hack should be disabled)
1312 CF_ARG_DISABLE(rpath-hack,
1313         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1314         [cf_disable_rpath_hack=yes],
1315         [cf_disable_rpath_hack=no])
1316 AC_MSG_RESULT($cf_disable_rpath_hack)
1317 if test "$cf_disable_rpath_hack" = no ; then
1318         CF_RPATH_HACK
1319 fi
1320 ])
1321 dnl ---------------------------------------------------------------------------
1322 dnl CF_ENABLE_PC_FILES version: 9 updated: 2012/08/04 13:59:54
1323 dnl ------------------
1324 dnl This is the "--enable-pc-files" option, which is available if there is a
1325 dnl pkg-config configuration on the local machine.
1326 AC_DEFUN([CF_ENABLE_PC_FILES],[
1327 AC_REQUIRE([CF_PKG_CONFIG])
1328 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1329
1330 if test "$PKG_CONFIG" != none ; then
1331         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1332         AC_ARG_ENABLE(pc-files,
1333                 [  --enable-pc-files       generate and install .pc files for pkg-config],
1334                 [enable_pc_files=$enableval],
1335                 [enable_pc_files=no])
1336         AC_MSG_RESULT($enable_pc_files)
1337         if test "$enable_pc_files" != no
1338         then
1339                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1340         fi
1341 else
1342         enable_pc_files=no
1343 fi
1344 ])dnl
1345 dnl ---------------------------------------------------------------------------
1346 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1347 dnl ---------------
1348 dnl Check if the rpath option should be used, setting cache variable
1349 dnl cf_cv_enable_rpath if so.
1350 AC_DEFUN([CF_ENABLE_RPATH],
1351 [
1352 AC_MSG_CHECKING(if rpath option should be used)
1353 AC_ARG_ENABLE(rpath,
1354 [  --enable-rpath          use rpath option when generating shared libraries],
1355 [cf_cv_enable_rpath=$enableval],
1356 [cf_cv_enable_rpath=no])
1357 AC_MSG_RESULT($cf_cv_enable_rpath)
1358 ])dnl
1359 dnl ---------------------------------------------------------------------------
1360 dnl CF_ENABLE_STRING_HACKS version: 3 updated: 2013/01/26 16:26:12
1361 dnl ----------------------
1362 dnl On a few platforms, the compiler and/or loader nags with untruthful
1363 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1364 dnl and implying that most uses of the recommended alternatives are correct.
1365 dnl
1366 dnl Factually speaking, no one has actually counted the number of uses of these
1367 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1368 dnl instances are meaningless compared to the hundreds of millions of lines of
1369 dnl existing C code.
1370 dnl
1371 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1372 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1373 dnl standard - but evolved through phases, and older implementations are likely
1374 dnl to yield surprising results, as documented in manpages on various systems.
1375 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1376 [
1377 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1378 AC_ARG_ENABLE(string-hacks,
1379         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1380         [with_string_hacks=$enableval],
1381         [with_string_hacks=no])
1382 AC_MSG_RESULT($with_string_hacks)
1383
1384 if test "x$with_string_hacks" = "xyes"; then
1385         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1386         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1387         AC_CHECK_FUNCS( strlcat strlcpy snprintf )
1388 fi
1389 ])dnl
1390 dnl ---------------------------------------------------------------------------
1391 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1392 dnl --------
1393 dnl Check if 'errno' is declared in <errno.h>
1394 AC_DEFUN([CF_ERRNO],
1395 [
1396 CF_CHECK_ERRNO(errno)
1397 ])dnl
1398 dnl ---------------------------------------------------------------------------
1399 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1400 dnl ---------------
1401 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1402 dnl math.h and builtin.h, only for ncurses
1403 AC_DEFUN([CF_ETIP_DEFINES],
1404 [
1405 AC_MSG_CHECKING(for special defines needed for etip.h)
1406 cf_save_CXXFLAGS="$CXXFLAGS"
1407 cf_result="none"
1408
1409 # etip.h includes ncurses.h which includes ncurses_dll.h
1410 # But ncurses_dll.h is generated - fix here.
1411 test -d include || mkdir include
1412 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1413
1414 for cf_math in "" MATH_H
1415 do
1416 for cf_excp in "" MATH_EXCEPTION
1417 do
1418         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1419         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1420         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1421 AC_TRY_COMPILE([
1422 #include <etip.h.in>
1423 ],[],[
1424         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1425         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1426         cf_result="$cf_math $cf_excp"
1427         break 2
1428 ],[])
1429 done
1430 done
1431 AC_MSG_RESULT($cf_result)
1432 CXXFLAGS="$cf_save_CXXFLAGS"
1433 ])
1434 dnl ---------------------------------------------------------------------------
1435 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
1436 dnl ---------------
1437 dnl Find a library (specifically the linkage used in the code fragment),
1438 dnl searching for it if it is not already in the library path.
1439 dnl See also CF_ADD_SEARCHPATH.
1440 dnl
1441 dnl Parameters (4-on are optional):
1442 dnl     $1 = headers for library entrypoint
1443 dnl     $2 = code fragment for library entrypoint
1444 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1445 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1446 dnl     $5 = action to perform if not successful
1447 dnl     $6 = module name, if not the same as the library name
1448 dnl     $7 = extra libraries
1449 dnl
1450 dnl Sets these variables:
1451 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1452 dnl     $cf_cv_header_path_$3 - include-directory if needed
1453 dnl     $cf_cv_library_path_$3 - library-directory if needed
1454 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1455 AC_DEFUN([CF_FIND_LINKAGE],[
1456
1457 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1458 # will be set on completion of the AC_TRY_LINK below.
1459 cf_cv_header_path_$3=
1460 cf_cv_library_path_$3=
1461
1462 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1463
1464 cf_save_LIBS="$LIBS"
1465
1466 AC_TRY_LINK([$1],[$2],[
1467         cf_cv_find_linkage_$3=yes
1468         cf_cv_header_path_$3=/usr/include
1469         cf_cv_library_path_$3=/usr/lib
1470 ],[
1471
1472 LIBS="-l$3 $7 $cf_save_LIBS"
1473
1474 AC_TRY_LINK([$1],[$2],[
1475         cf_cv_find_linkage_$3=yes
1476         cf_cv_header_path_$3=/usr/include
1477         cf_cv_library_path_$3=/usr/lib
1478         cf_cv_library_file_$3="-l$3"
1479 ],[
1480         cf_cv_find_linkage_$3=no
1481         LIBS="$cf_save_LIBS"
1482
1483     CF_VERBOSE(find linkage for $3 library)
1484     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1485
1486     cf_save_CPPFLAGS="$CPPFLAGS"
1487     cf_test_CPPFLAGS="$CPPFLAGS"
1488
1489     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1490     for cf_cv_header_path_$3 in $cf_search
1491     do
1492       if test -d $cf_cv_header_path_$3 ; then
1493         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1494         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1495         AC_TRY_COMPILE([$1],[$2],[
1496             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1497             cf_cv_find_linkage_$3=maybe
1498             cf_test_CPPFLAGS="$CPPFLAGS"
1499             break],[
1500             CPPFLAGS="$cf_save_CPPFLAGS"
1501             ])
1502       fi
1503     done
1504
1505     if test "$cf_cv_find_linkage_$3" = maybe ; then
1506
1507       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1508
1509       cf_save_LIBS="$LIBS"
1510       cf_save_LDFLAGS="$LDFLAGS"
1511
1512       ifelse([$6],,,[
1513         CPPFLAGS="$cf_test_CPPFLAGS"
1514         LIBS="-l$3 $7 $cf_save_LIBS"
1515         AC_TRY_LINK([$1],[$2],[
1516             CF_VERBOSE(... found $3 library in system)
1517             cf_cv_find_linkage_$3=yes])
1518             CPPFLAGS="$cf_save_CPPFLAGS"
1519             LIBS="$cf_save_LIBS"
1520             ])
1521
1522       if test "$cf_cv_find_linkage_$3" != yes ; then
1523         CF_LIBRARY_PATH(cf_search,$3)
1524         for cf_cv_library_path_$3 in $cf_search
1525         do
1526           if test -d $cf_cv_library_path_$3 ; then
1527             CF_VERBOSE(... testing $cf_cv_library_path_$3)
1528             CPPFLAGS="$cf_test_CPPFLAGS"
1529             LIBS="-l$3 $7 $cf_save_LIBS"
1530             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1531             AC_TRY_LINK([$1],[$2],[
1532                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1533                 cf_cv_find_linkage_$3=yes
1534                 cf_cv_library_file_$3="-l$3"
1535                 break],[
1536                 CPPFLAGS="$cf_save_CPPFLAGS"
1537                 LIBS="$cf_save_LIBS"
1538                 LDFLAGS="$cf_save_LDFLAGS"
1539                 ])
1540           fi
1541         done
1542         CPPFLAGS="$cf_save_CPPFLAGS"
1543         LDFLAGS="$cf_save_LDFLAGS"
1544       fi
1545
1546     else
1547       cf_cv_find_linkage_$3=no
1548     fi
1549     ],$7)
1550 ])
1551
1552 LIBS="$cf_save_LIBS"
1553
1554 if test "$cf_cv_find_linkage_$3" = yes ; then
1555 ifelse([$4],,[
1556         CF_ADD_INCDIR($cf_cv_header_path_$3)
1557         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1558         CF_ADD_LIB($3)
1559 ],[$4])
1560 else
1561 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1562 fi
1563 ])dnl
1564 dnl ---------------------------------------------------------------------------
1565 dnl CF_FIND_SUB_INCDIR version: 1 updated: 2014/04/12 16:47:01
1566 dnl ------------------
1567 dnl Find an include-directory with the given leaf-name.  This is useful for
1568 dnl example with FreeBSD ports, which use this convention to distinguish
1569 dnl different versions of the same port.
1570 AC_DEFUN([CF_FIND_SUB_INCDIR],[
1571         CF_SUBDIR_PATH(cf_search,$1,include)
1572         for cf_item in $cf_search
1573         do
1574                 case $cf_item in #(vi
1575                 */$1)
1576                         CF_ADD_INCDIR($cf_item)
1577                         ;;
1578                 esac
1579         done
1580 ])dnl
1581 dnl ---------------------------------------------------------------------------
1582 dnl CF_FIND_SUB_LIBDIR version: 1 updated: 2014/04/12 16:47:01
1583 dnl ------------------
1584 dnl Find a library-directory with the given leaf-name.  This is useful for
1585 dnl example with FreeBSD ports, which use this convention to distinguish
1586 dnl different versions of the same port.
1587 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
1588         CF_SUBDIR_PATH(cf_search,$1,lib)
1589         for cf_item in $cf_search
1590         do
1591                 case $cf_item in #(vi
1592                 */$1)
1593                         CF_ADD_LIBDIR($cf_item)
1594                         ;;
1595                 esac
1596         done
1597 ])dnl
1598 dnl ---------------------------------------------------------------------------
1599 dnl CF_FIXUP_ADAFLAGS version: 1 updated: 2012/03/31 18:48:10
1600 dnl -----------------
1601 dnl make ADAFLAGS consistent with CFLAGS
1602 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1603         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1604         case "$CFLAGS" in
1605         *-g*)
1606                 CF_ADD_ADAFLAGS(-g)
1607                 ;;
1608         esac
1609         case "$CFLAGS" in
1610         *-O*)
1611                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1612                 CF_ADD_ADAFLAGS($cf_O_flag)
1613                 ;;
1614         esac
1615         AC_MSG_RESULT($ADAFLAGS)
1616 ])dnl
1617 dnl ---------------------------------------------------------------------------
1618 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
1619 dnl --------------
1620 dnl Forget that we saw the given tool.
1621 AC_DEFUN([CF_FORGET_TOOL],[
1622 unset ac_cv_prog_ac_ct_$1
1623 unset ac_ct_$1
1624 unset $1
1625 ])dnl
1626 dnl ---------------------------------------------------------------------------
1627 dnl CF_FUNC_DLSYM version: 3 updated: 2012/10/06 11:17:15
1628 dnl -------------
1629 dnl Test for dlsym() and related functions, as well as libdl.
1630 dnl
1631 dnl Sets
1632 dnl     $cf_have_dlsym
1633 dnl     $cf_have_libdl
1634 AC_DEFUN([CF_FUNC_DLSYM],[
1635 cf_have_dlsym=no
1636 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1637
1638 cf_have_libdl=no
1639 AC_CHECK_LIB(dl,dlsym,[
1640         cf_have_dlsym=yes
1641         cf_have_libdl=yes])])
1642
1643 if test "$cf_have_dlsym" = yes ; then
1644         test "$cf_have_libdl" = yes && CF_ADD_LIB(dl)
1645
1646         AC_MSG_CHECKING(whether able to link to dl*() functions)
1647         AC_TRY_LINK([#include <dlfcn.h>],[
1648                 void *obj;
1649                 if ((obj = dlopen("filename", 0)) != 0) {
1650                         if (dlsym(obj, "symbolname") == 0) {
1651                         dlclose(obj);
1652                         }
1653                 }],[
1654                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
1655                 AC_MSG_ERROR(Cannot link test program for libdl)])
1656         AC_MSG_RESULT(ok)
1657 else
1658         AC_MSG_ERROR(Cannot find dlsym function)
1659 fi
1660 ])
1661 dnl ---------------------------------------------------------------------------
1662 dnl CF_FUNC_MEMMOVE version: 8 updated: 2012/10/04 20:12:20
1663 dnl ---------------
1664 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1665 dnl is found, add our own version of memmove to the list of objects.
1666 AC_DEFUN([CF_FUNC_MEMMOVE],
1667 [
1668 AC_CHECK_FUNC(memmove,,[
1669 AC_CHECK_FUNC(bcopy,[
1670         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1671                 AC_TRY_RUN([
1672 int main() {
1673         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1674         char temp[40];
1675         bcopy(data, temp, sizeof(data));
1676         bcopy(temp+10, temp, 15);
1677         bcopy(temp+5, temp+15, 10);
1678         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1679 }
1680                 ],
1681                 [cf_cv_good_bcopy=yes],
1682                 [cf_cv_good_bcopy=no],
1683                 [cf_cv_good_bcopy=unknown])
1684                 ])
1685         ],[cf_cv_good_bcopy=no])
1686         if test "$cf_cv_good_bcopy" = yes ; then
1687                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
1688         else
1689                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
1690         fi
1691 ])])dnl
1692 dnl ---------------------------------------------------------------------------
1693 dnl CF_FUNC_NANOSLEEP version: 4 updated: 2012/10/06 17:56:13
1694 dnl -----------------
1695 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1696 dnl AIX 4.x, provide a non-working version.
1697 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1698 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1699 AC_TRY_RUN([
1700 #include <stdio.h>
1701 #include <errno.h>
1702 #include <time.h>
1703
1704 #ifdef HAVE_SYS_TIME_H
1705 #include <sys/time.h>
1706 #endif
1707
1708 int main() {
1709         struct timespec ts1, ts2;
1710         int code;
1711         ts1.tv_sec  = 0;
1712         ts1.tv_nsec = 750000000;
1713         ts2.tv_sec  = 0;
1714         ts2.tv_nsec = 0;
1715         errno = 0;
1716         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1717         ${cf_cv_main_return:-return}(code != 0);
1718 }
1719 ],
1720         [cf_cv_func_nanosleep=yes],
1721         [cf_cv_func_nanosleep=no],
1722         [cf_cv_func_nanosleep=unknown])])
1723
1724 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
1725 ])
1726 dnl ---------------------------------------------------------------------------
1727 dnl CF_FUNC_OPENPTY version: 3 updated: 2010/05/29 16:31:02
1728 dnl ---------------
1729 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1730 dnl "util" library as well.
1731 AC_DEFUN([CF_FUNC_OPENPTY],
1732 [
1733 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1734 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1735     cf_save_LIBS="$LIBS"
1736     test $cf_cv_lib_util = yes && CF_ADD_LIB(util)
1737     for cf_header in pty.h libutil.h util.h
1738     do
1739     AC_TRY_LINK([
1740 #include <$cf_header>
1741 ],[
1742     int x = openpty((int *)0, (int *)0, (char *)0,
1743                    (struct termios *)0, (struct winsize *)0);
1744 ],[
1745         cf_cv_func_openpty=$cf_header
1746         break
1747 ],[
1748         cf_cv_func_openpty=no
1749 ])
1750     done
1751     LIBS="$cf_save_LIBS"
1752 ])
1753 ])dnl
1754 dnl ---------------------------------------------------------------------------
1755 dnl CF_FUNC_POLL version: 8 updated: 2012/10/04 05:24:07
1756 dnl ------------
1757 dnl See if the poll function really works.  Some platforms have poll(), but
1758 dnl it does not work for terminals or files.
1759 AC_DEFUN([CF_FUNC_POLL],[
1760 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
1761 AC_TRY_RUN([
1762 #include <stdlib.h>
1763 #include <stdio.h>
1764 #include <unistd.h>
1765 #include <fcntl.h>
1766 #ifdef HAVE_POLL_H
1767 #include <poll.h>
1768 #else
1769 #include <sys/poll.h>
1770 #endif
1771 int main() {
1772         struct pollfd myfds;
1773         int ret;
1774
1775         /* check for Darwin bug with respect to "devices" */
1776         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
1777         if (myfds.fd < 0)
1778                 myfds.fd = 0;
1779         myfds.events = POLLIN;
1780         myfds.revents = 0;
1781
1782         ret = poll(&myfds, 1, 100);
1783
1784         if (ret < 0 || (myfds.revents & POLLNVAL)) {
1785                 ret = -1;
1786         } else {
1787                 int fd = 0;
1788                 if (!isatty(fd)) {
1789                         fd = open("/dev/tty", 2);       /* O_RDWR */
1790                 }
1791
1792                 if (fd >= 0) {
1793                         /* also check with standard input */
1794                         myfds.fd = fd;
1795                         myfds.events = POLLIN;
1796                         myfds.revents = 0;
1797                         ret = poll(&myfds, 1, 100);
1798                 } else {
1799                         ret = -1;
1800                 }
1801         }
1802         ${cf_cv_main_return:-return}(ret < 0);
1803 }],
1804         [cf_cv_working_poll=yes],
1805         [cf_cv_working_poll=no],
1806         [cf_cv_working_poll=unknown])])
1807 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
1808 ])dnl
1809 dnl ---------------------------------------------------------------------------
1810 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
1811 dnl ---------------
1812 dnl Some old/broken variations define tcgetattr() only as a macro in
1813 dnl termio(s).h
1814 AC_DEFUN([CF_FUNC_TERMIOS],[
1815 AC_REQUIRE([CF_STRUCT_TERMIOS])
1816 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
1817 AC_TRY_LINK([
1818 #include <sys/types.h>
1819 #ifdef HAVE_UNISTD_H
1820 #include <unistd.h>
1821 #endif
1822 #ifdef HAVE_TERMIOS_H
1823 #include <termios.h>
1824 #define TTY struct termios
1825 #else
1826 #ifdef HAVE_TERMIO_H
1827 #include <termio.h>
1828 #define TTY struct termio
1829 #endif
1830 #endif
1831 ],[
1832 TTY foo;
1833 tcgetattr(1, &foo);],
1834 [cf_cv_have_tcgetattr=yes],
1835 [cf_cv_have_tcgetattr=no])])
1836 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
1837 ])dnl
1838 dnl ---------------------------------------------------------------------------
1839 dnl CF_FUNC_VSSCANF version: 4 updated: 2012/10/06 17:56:13
1840 dnl ---------------
1841 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
1842 dnl versions of C.  It is in the GNU C library, and can often be simulated by
1843 dnl other functions.
1844 AC_DEFUN([CF_FUNC_VSSCANF],
1845 [
1846 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
1847 AC_TRY_LINK([
1848 #include <stdarg.h>
1849 #include <stdio.h>],[
1850         va_list ap;
1851         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
1852 AC_TRY_LINK([
1853 #include <stdarg.h>
1854 #include <stdio.h>],[
1855     FILE strbuf;
1856     char *str = "from";
1857
1858     strbuf._flag = _IOREAD;
1859     strbuf._ptr = strbuf._base = (unsigned char *) str;
1860     strbuf._cnt = strlen(str);
1861     strbuf._file = _NFILE;
1862     return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
1863 AC_TRY_LINK([
1864 #include <stdarg.h>
1865 #include <stdio.h>],[
1866     FILE strbuf;
1867     char *str = "from";
1868
1869     strbuf._flag = _IOREAD;
1870     strbuf._ptr = strbuf._base = (unsigned char *) str;
1871     strbuf._cnt = strlen(str);
1872     strbuf._file = _NFILE;
1873     return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
1874 cf_cv_func_vsscanf=no])])])])
1875
1876 case $cf_cv_func_vsscanf in #(vi
1877 vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);; #(vi
1878 vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);; #(vi
1879 _doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
1880 esac
1881
1882 ])dnl
1883 dnl ---------------------------------------------------------------------------
1884 dnl CF_GCC_ATTRIBUTES version: 16 updated: 2012/10/02 20:55:03
1885 dnl -----------------
1886 dnl Test for availability of useful gcc __attribute__ directives to quiet
1887 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1888 dnl to documentation, unrecognized directives cause older compilers to barf.
1889 AC_DEFUN([CF_GCC_ATTRIBUTES],
1890 [
1891 if test "$GCC" = yes
1892 then
1893 cat > conftest.i <<EOF
1894 #ifndef GCC_PRINTF
1895 #define GCC_PRINTF 0
1896 #endif
1897 #ifndef GCC_SCANF
1898 #define GCC_SCANF 0
1899 #endif
1900 #ifndef GCC_NORETURN
1901 #define GCC_NORETURN /* nothing */
1902 #endif
1903 #ifndef GCC_UNUSED
1904 #define GCC_UNUSED /* nothing */
1905 #endif
1906 EOF
1907 if test "$GCC" = yes
1908 then
1909         AC_CHECKING([for $CC __attribute__ directives])
1910 cat > conftest.$ac_ext <<EOF
1911 #line __oline__ "${as_me:-configure}"
1912 #include "confdefs.h"
1913 #include "conftest.h"
1914 #include "conftest.i"
1915 #if     GCC_PRINTF
1916 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1917 #else
1918 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1919 #endif
1920 #if     GCC_SCANF
1921 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1922 #else
1923 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1924 #endif
1925 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1926 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1927 extern void foo(void) GCC_NORETURN;
1928 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1929 EOF
1930         cf_printf_attribute=no
1931         cf_scanf_attribute=no
1932         for cf_attribute in scanf printf unused noreturn
1933         do
1934                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1935                 cf_directive="__attribute__(($cf_attribute))"
1936                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1937
1938                 case $cf_attribute in #(vi
1939                 printf) #(vi
1940                         cf_printf_attribute=yes
1941                         cat >conftest.h <<EOF
1942 #define GCC_$cf_ATTRIBUTE 1
1943 EOF
1944                         ;;
1945                 scanf) #(vi
1946                         cf_scanf_attribute=yes
1947                         cat >conftest.h <<EOF
1948 #define GCC_$cf_ATTRIBUTE 1
1949 EOF
1950                         ;;
1951                 *) #(vi
1952                         cat >conftest.h <<EOF
1953 #define GCC_$cf_ATTRIBUTE $cf_directive
1954 EOF
1955                         ;;
1956                 esac
1957
1958                 if AC_TRY_EVAL(ac_compile); then
1959                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1960                         cat conftest.h >>confdefs.h
1961                         case $cf_attribute in #(vi
1962                         noreturn) #(vi
1963                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1964                                 ;;
1965                         printf) #(vi
1966                                 cf_value='/* nothing */'
1967                                 if test "$cf_printf_attribute" != no ; then
1968                                         cf_value='__attribute__((format(printf,fmt,var)))'
1969                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1970                                 fi
1971                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1972                                 ;;
1973                         scanf) #(vi
1974                                 cf_value='/* nothing */'
1975                                 if test "$cf_scanf_attribute" != no ; then
1976                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1977                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1978                                 fi
1979                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1980                                 ;;
1981                         unused) #(vi
1982                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1983                                 ;;
1984                         esac
1985                 fi
1986         done
1987 else
1988         fgrep define conftest.i >>confdefs.h
1989 fi
1990 rm -rf conftest*
1991 fi
1992 ])dnl
1993 dnl ---------------------------------------------------------------------------
1994 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
1995 dnl --------------
1996 dnl Find version of gcc
1997 AC_DEFUN([CF_GCC_VERSION],[
1998 AC_REQUIRE([AC_PROG_CC])
1999 GCC_VERSION=none
2000 if test "$GCC" = yes ; then
2001         AC_MSG_CHECKING(version of $CC)
2002         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2003         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2004         AC_MSG_RESULT($GCC_VERSION)
2005 fi
2006 ])dnl
2007 dnl ---------------------------------------------------------------------------
2008 dnl CF_GCC_WARNINGS version: 31 updated: 2013/11/19 19:23:35
2009 dnl ---------------
2010 dnl Check if the compiler supports useful warning options.  There's a few that
2011 dnl we don't use, simply because they're too noisy:
2012 dnl
2013 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2014 dnl     -Wredundant-decls (system headers make this too noisy)
2015 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2016 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2017 dnl             is enabled for ncurses using "--enable-const".
2018 dnl     -pedantic
2019 dnl
2020 dnl Parameter:
2021 dnl     $1 is an optional list of gcc warning flags that a particular
2022 dnl             application might want to use, e.g., "no-unused" for
2023 dnl             -Wno-unused
2024 dnl Special:
2025 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2026 dnl
2027 AC_DEFUN([CF_GCC_WARNINGS],
2028 [
2029 AC_REQUIRE([CF_GCC_VERSION])
2030 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2031 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2032
2033 cat > conftest.$ac_ext <<EOF
2034 #line __oline__ "${as_me:-configure}"
2035 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2036 EOF
2037
2038 if test "$INTEL_COMPILER" = yes
2039 then
2040 # The "-wdXXX" options suppress warnings:
2041 # remark #1419: external declaration in primary source file
2042 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2043 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2044 # remark #193: zero used for undefined preprocessing identifier
2045 # remark #593: variable "curs_sb_left_arrow" was set but never used
2046 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2047 # remark #869: parameter "tw" was never referenced
2048 # remark #981: operands are evaluated in unspecified order
2049 # warning #279: controlling expression is constant
2050
2051         AC_CHECKING([for $CC warning options])
2052         cf_save_CFLAGS="$CFLAGS"
2053         EXTRA_CFLAGS="-Wall"
2054         for cf_opt in \
2055                 wd1419 \
2056                 wd1683 \
2057                 wd1684 \
2058                 wd193 \
2059                 wd593 \
2060                 wd279 \
2061                 wd810 \
2062                 wd869 \
2063                 wd981
2064         do
2065                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2066                 if AC_TRY_EVAL(ac_compile); then
2067                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2068                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2069                 fi
2070         done
2071         CFLAGS="$cf_save_CFLAGS"
2072
2073 elif test "$GCC" = yes
2074 then
2075         AC_CHECKING([for $CC warning options])
2076         cf_save_CFLAGS="$CFLAGS"
2077         EXTRA_CFLAGS=
2078         cf_warn_CONST=""
2079         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2080         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2081         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2082         for cf_opt in W Wall \
2083                 Wbad-function-cast \
2084                 Wcast-align \
2085                 Wcast-qual \
2086                 Wdeclaration-after-statement \
2087                 Wextra \
2088                 Winline \
2089                 Wmissing-declarations \
2090                 Wmissing-prototypes \
2091                 Wnested-externs \
2092                 Wpointer-arith \
2093                 Wshadow \
2094                 Wstrict-prototypes \
2095                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
2096         do
2097                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2098                 if AC_TRY_EVAL(ac_compile); then
2099                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2100                         case $cf_opt in #(vi
2101                         Wcast-qual) #(vi
2102                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
2103                                 ;;
2104                         Winline) #(vi
2105                                 case $GCC_VERSION in
2106                                 [[34]].*)
2107                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2108                                         continue;;
2109                                 esac
2110                                 ;;
2111                         Wpointer-arith) #(vi
2112                                 case $GCC_VERSION in
2113                                 [[12]].*)
2114                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2115                                         continue;;
2116                                 esac
2117                                 ;;
2118                         esac
2119                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2120                 fi
2121         done
2122         CFLAGS="$cf_save_CFLAGS"
2123 fi
2124 rm -rf conftest*
2125
2126 AC_SUBST(EXTRA_CFLAGS)
2127 ])dnl
2128 dnl ---------------------------------------------------------------------------
2129 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
2130 dnl ----------------
2131 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2132 dnl unistd.h or (nonstandard) in getopt.h
2133 AC_DEFUN([CF_GETOPT_HEADER],
2134 [
2135 AC_HAVE_HEADERS(unistd.h getopt.h)
2136 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2137 cf_cv_getopt_header=none
2138 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2139 do
2140 AC_TRY_COMPILE([
2141 #include <$cf_header>],
2142 [int x = optind; char *y = optarg],
2143 [cf_cv_getopt_header=$cf_header
2144  break])
2145 done
2146 ])
2147 if test $cf_cv_getopt_header != none ; then
2148         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2149 fi
2150 if test $cf_cv_getopt_header = getopt.h ; then
2151         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2152 fi
2153 ])dnl
2154 dnl ---------------------------------------------------------------------------
2155 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2156 dnl -----------------
2157 AC_DEFUN([CF_GNATPREP_OPT_T],[
2158 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2159 cf_cv_gnatprep_opt_t=no
2160 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2161 ])
2162 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
2163 AC_SUBST(GNATPREP_OPTS)
2164 ])dnl
2165 dnl ---------------------------------------------------------------------------
2166 dnl CF_GNAT_GENERICS version: 2 updated: 2011/03/23 20:24:41
2167 dnl ----------------
2168 AC_DEFUN([CF_GNAT_GENERICS],
2169 [
2170 AC_REQUIRE([CF_GNAT_VERSION])
2171
2172 AC_MSG_CHECKING(if GNAT supports generics)
2173 case $cf_gnat_version in #(vi
2174 3.[[1-9]]*|[[4-9]].*) #(vi
2175         cf_gnat_generics=yes
2176         ;;
2177 *)
2178         cf_gnat_generics=no
2179         ;;
2180 esac
2181 AC_MSG_RESULT($cf_gnat_generics)
2182
2183 if test "$cf_gnat_generics" = yes
2184 then
2185         cf_compile_generics=generics
2186         cf_generic_objects="\${GENOBJS}"
2187 else
2188         cf_compile_generics=
2189         cf_generic_objects=
2190 fi
2191
2192 AC_SUBST(cf_compile_generics)
2193 AC_SUBST(cf_generic_objects)
2194 ])dnl
2195 dnl ---------------------------------------------------------------------------
2196 dnl CF_GNAT_PROJECTS version: 7 updated: 2014/06/01 10:46:34
2197 dnl ----------------
2198 dnl GNAT projects are configured with ".gpr" project files.
2199 dnl GNAT libraries are a further development, using the project feature.
2200 AC_DEFUN([CF_GNAT_PROJECTS],
2201 [
2202 AC_REQUIRE([CF_GNAT_VERSION])
2203 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
2204
2205 cf_gnat_libraries=no
2206 cf_gnat_projects=no
2207
2208 if test "$enable_gnat_projects" != no ; then
2209 AC_MSG_CHECKING(if GNAT supports project files)
2210 case $cf_gnat_version in #(vi
2211 3.[[0-9]]*) #(vi
2212         ;;
2213 *)
2214         case $cf_cv_system_name in #(vi
2215         cygwin*|msys*) #(vi
2216                 ;;
2217         *)
2218                 mkdir conftest.src conftest.bin conftest.lib
2219                 cd conftest.src
2220                 rm -rf conftest* *~conftest*
2221                 cat >>library.gpr <<CF_EOF
2222 project Library is
2223   Kind := External ("LIB_KIND");
2224   for Library_Name use "ConfTest";
2225   for Object_Dir use ".";
2226   for Library_ALI_Dir use External("LIBRARY_DIR");
2227   for Library_Version use External ("SONAME");
2228   for Library_Kind use Kind;
2229   for Library_Dir use External("BUILD_DIR");
2230   Source_Dir := External ("SOURCE_DIR");
2231   for Source_Dirs use (Source_Dir);
2232 end Library;
2233 CF_EOF
2234                 cat >>confpackage.ads <<CF_EOF
2235 package ConfPackage is
2236    procedure conftest;
2237 end ConfPackage;
2238 CF_EOF
2239                 cat >>confpackage.adb <<CF_EOF
2240 with Text_IO;
2241 package body ConfPackage is
2242    procedure conftest is
2243    begin
2244       Text_IO.Put ("Hello World");
2245       Text_IO.New_Line;
2246    end conftest;
2247 end ConfPackage;
2248 CF_EOF
2249                 if ( $cf_ada_make $ADAFLAGS \
2250                                 -Plibrary.gpr \
2251                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2252                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2253                                 -XSOURCE_DIR=`pwd` \
2254                                 -XSONAME=libConfTest.so.1 \
2255                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2256                         cf_gnat_projects=yes
2257                 fi
2258                 cd ..
2259                 if test -f conftest.lib/confpackage.ali
2260                 then
2261                         cf_gnat_libraries=yes
2262                 fi
2263                 rm -rf conftest* *~conftest*
2264                 ;;
2265         esac
2266         ;;
2267 esac
2268 AC_MSG_RESULT($cf_gnat_projects)
2269 fi # enable_gnat_projects
2270
2271 if test $cf_gnat_projects = yes
2272 then
2273         AC_MSG_CHECKING(if GNAT supports libraries)
2274         AC_MSG_RESULT($cf_gnat_libraries)
2275 fi
2276
2277 if test "$cf_gnat_projects" = yes
2278 then
2279         USE_OLD_MAKERULES="#"
2280         USE_GNAT_PROJECTS=""
2281 else
2282         USE_OLD_MAKERULES=""
2283         USE_GNAT_PROJECTS="#"
2284 fi
2285
2286 if test "$cf_gnat_libraries" = yes
2287 then
2288         USE_GNAT_LIBRARIES=""
2289 else
2290         USE_GNAT_LIBRARIES="#"
2291 fi
2292
2293 AC_SUBST(USE_OLD_MAKERULES)
2294 AC_SUBST(USE_GNAT_PROJECTS)
2295 AC_SUBST(USE_GNAT_LIBRARIES)
2296 ])dnl
2297 dnl ---------------------------------------------------------------------------
2298 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2299 dnl --------------
2300 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2301 dnl is noted that gnat may compile a tasking unit even for configurations which
2302 dnl fail at runtime.
2303 AC_DEFUN([CF_GNAT_SIGINT],[
2304 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2305 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2306
2307 package ConfTest is
2308
2309    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2310    pragma Unreserve_All_Interrupts;
2311    pragma Warnings (On);
2312
2313    protected Process is
2314       procedure Stop;
2315       function Continue return Boolean;
2316       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2317    private
2318       Done : Boolean := False;
2319    end Process;
2320
2321 end ConfTest;],
2322 [package body ConfTest is
2323    protected body Process is
2324       procedure Stop is
2325       begin
2326          Done := True;
2327       end Stop;
2328       function Continue return Boolean is
2329       begin
2330          return not Done;
2331       end Continue;
2332    end Process;
2333 end ConfTest;],
2334         [cf_cv_gnat_sigint=yes],
2335         [cf_cv_gnat_sigint=no])])
2336
2337 if test $cf_cv_gnat_sigint = yes ; then
2338         USE_GNAT_SIGINT=""
2339 else
2340         USE_GNAT_SIGINT="#"
2341 fi
2342 AC_SUBST(USE_GNAT_SIGINT)
2343 ])dnl
2344 dnl ---------------------------------------------------------------------------
2345 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2346 dnl ----------------
2347 dnl Verify that a test program compiles/links with GNAT.
2348 dnl $cf_ada_make is set to the program that compiles/links
2349 dnl $ADAFLAGS may be set to the GNAT flags.
2350 dnl
2351 dnl $1 is the text of the spec
2352 dnl $2 is the text of the body
2353 dnl $3 is the shell command to execute if successful
2354 dnl $4 is the shell command to execute if not successful
2355 AC_DEFUN([CF_GNAT_TRY_LINK],
2356 [
2357 rm -rf conftest* *~conftest*
2358 cat >>conftest.ads <<CF_EOF
2359 $1
2360 CF_EOF
2361 cat >>conftest.adb <<CF_EOF
2362 $2
2363 CF_EOF
2364 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2365 ifelse($3,,      :,[      $3])
2366 ifelse($4,,,[else
2367    $4])
2368 fi
2369 rm -rf conftest* *~conftest*
2370 ])dnl
2371 dnl ---------------------------------------------------------------------------
2372 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2373 dnl ---------------
2374 dnl Verify that a test program compiles and runs with GNAT
2375 dnl $cf_ada_make is set to the program that compiles/links
2376 dnl $ADAFLAGS may be set to the GNAT flags.
2377 dnl
2378 dnl $1 is the text of the spec
2379 dnl $2 is the text of the body
2380 dnl $3 is the shell command to execute if successful
2381 dnl $4 is the shell command to execute if not successful
2382 AC_DEFUN([CF_GNAT_TRY_RUN],
2383 [
2384 rm -rf conftest* *~conftest*
2385 cat >>conftest.ads <<CF_EOF
2386 $1
2387 CF_EOF
2388 cat >>conftest.adb <<CF_EOF
2389 $2
2390 CF_EOF
2391 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2392    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2393 ifelse($3,,      :,[      $3])
2394 ifelse($4,,,[   else
2395       $4])
2396    fi
2397 ifelse($4,,,[else
2398    $4])
2399 fi
2400 rm -rf conftest* *~conftest*
2401 ])dnl
2402 dnl ---------------------------------------------------------------------------
2403 dnl CF_GNAT_VERSION version: 18 updated: 2012/01/21 19:28:10
2404 dnl ---------------
2405 dnl Verify version of GNAT.
2406 AC_DEFUN([CF_GNAT_VERSION],
2407 [
2408 AC_MSG_CHECKING(for gnat version)
2409 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2410         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2411     sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2412 AC_MSG_RESULT($cf_gnat_version)
2413
2414 case $cf_gnat_version in #(vi
2415 3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]]) #(vi
2416         cf_cv_prog_gnat_correct=yes
2417         ;;
2418 *)
2419         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2420         cf_cv_prog_gnat_correct=no
2421         ;;
2422 esac
2423 ])
2424 dnl ---------------------------------------------------------------------------
2425 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
2426 dnl -------------
2427 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2428 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2429 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2430 dnl since it is interwoven with GNU extensions.
2431 dnl
2432 dnl Well, yes we could work around it...
2433 AC_DEFUN([CF_GNU_SOURCE],
2434 [
2435 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2436 AC_TRY_COMPILE([#include <sys/types.h>],[
2437 #ifndef _XOPEN_SOURCE
2438 make an error
2439 #endif],
2440         [cf_cv_gnu_source=no],
2441         [cf_save="$CPPFLAGS"
2442          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2443          AC_TRY_COMPILE([#include <sys/types.h>],[
2444 #ifdef _XOPEN_SOURCE
2445 make an error
2446 #endif],
2447         [cf_cv_gnu_source=no],
2448         [cf_cv_gnu_source=yes])
2449         CPPFLAGS="$cf_save"
2450         ])
2451 ])
2452 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2453 ])dnl
2454 dnl ---------------------------------------------------------------------------
2455 dnl CF_GPP_LIBRARY version: 11 updated: 2012/10/06 17:56:13
2456 dnl --------------
2457 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2458 dnl problem :-).  If we have the compiler but no library, we'll be able to
2459 dnl configure, but won't be able to build the c++ demo program.
2460 AC_DEFUN([CF_GPP_LIBRARY],
2461 [
2462 cf_cxx_library=unknown
2463 case $cf_cv_system_name in #(vi
2464 os2*) #(vi
2465         cf_gpp_libname=gpp
2466         ;;
2467 *)
2468         cf_gpp_libname=g++
2469         ;;
2470 esac
2471 if test "$GXX" = yes; then
2472         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2473         cf_save="$LIBS"
2474         CF_ADD_LIB($cf_gpp_libname)
2475         AC_TRY_LINK([
2476 #include <$cf_gpp_libname/builtin.h>
2477         ],
2478         [two_arg_error_handler_t foo2 = lib_error_handler],
2479         [cf_cxx_library=yes
2480          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2481          if test "$cf_gpp_libname" = cpp ; then
2482             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
2483          else
2484             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
2485          fi],
2486         [AC_TRY_LINK([
2487 #include <builtin.h>
2488         ],
2489         [two_arg_error_handler_t foo2 = lib_error_handler],
2490         [cf_cxx_library=yes
2491          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2492          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
2493         [cf_cxx_library=no])])
2494         LIBS="$cf_save"
2495         AC_MSG_RESULT($cf_cxx_library)
2496 fi
2497 ])dnl
2498 dnl ---------------------------------------------------------------------------
2499 dnl CF_GXX_VERSION version: 7 updated: 2012/06/16 14:55:39
2500 dnl --------------
2501 dnl Check for version of g++
2502 AC_DEFUN([CF_GXX_VERSION],[
2503 AC_REQUIRE([AC_PROG_CPP])
2504 GXX_VERSION=none
2505 if test "$GXX" = yes; then
2506         AC_MSG_CHECKING(version of ${CXX:-g++})
2507         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2508         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2509         AC_MSG_RESULT($GXX_VERSION)
2510 fi
2511 ])dnl
2512 dnl ---------------------------------------------------------------------------
2513 dnl CF_GXX_WARNINGS version: 8 updated: 2013/11/16 14:27:53
2514 dnl ---------------
2515 dnl Check if the compiler supports useful warning options.
2516 dnl
2517 dnl Most of gcc's options apply to g++, except:
2518 dnl     -Wbad-function-cast
2519 dnl     -Wmissing-declarations
2520 dnl     -Wnested-externs
2521 dnl
2522 dnl Omit a few (for now):
2523 dnl     -Winline
2524 dnl
2525 dnl Parameter:
2526 dnl     $1 is an optional list of g++ warning flags that a particular
2527 dnl             application might want to use, e.g., "no-unused" for
2528 dnl             -Wno-unused
2529 dnl Special:
2530 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2531 dnl
2532 AC_DEFUN([CF_GXX_WARNINGS],
2533 [
2534
2535 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2536 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
2537
2538 AC_REQUIRE([CF_GXX_VERSION])
2539
2540 AC_LANG_SAVE
2541 AC_LANG_CPLUSPLUS
2542
2543 cat > conftest.$ac_ext <<EOF
2544 #line __oline__ "configure"
2545 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2546 EOF
2547
2548 if test "$INTEL_CPLUSPLUS" = yes
2549 then
2550 # The "-wdXXX" options suppress warnings:
2551 # remark #1419: external declaration in primary source file
2552 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2553 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2554 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2555 # remark #193: zero used for undefined preprocessing identifier
2556 # remark #593: variable "curs_sb_left_arrow" was set but never used
2557 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2558 # remark #869: parameter "tw" was never referenced
2559 # remark #981: operands are evaluated in unspecified order
2560 # warning #269: invalid format string conversion
2561
2562         AC_CHECKING([for $CC warning options])
2563         cf_save_CXXFLAGS="$CXXFLAGS"
2564         EXTRA_CXXFLAGS="-Wall"
2565         for cf_opt in \
2566                 wd1419 \
2567                 wd1682 \
2568                 wd1683 \
2569                 wd1684 \
2570                 wd193 \
2571                 wd279 \
2572                 wd593 \
2573                 wd810 \
2574                 wd869 \
2575                 wd981
2576         do
2577                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2578                 if AC_TRY_EVAL(ac_compile); then
2579                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2580                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2581                 fi
2582         done
2583         CXXFLAGS="$cf_save_CXXFLAGS"
2584
2585 elif test "$GXX" = yes
2586 then
2587         AC_CHECKING([for $CXX warning options])
2588         cf_save_CXXFLAGS="$CXXFLAGS"
2589         EXTRA_CXXFLAGS="-W -Wall"
2590         cf_gxx_extra_warnings=""
2591         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2592         case "$GCC_VERSION" in
2593         [[1-2]].*)
2594                 ;;
2595         *)
2596                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2597                 ;;
2598         esac
2599         for cf_opt in \
2600                 Wabi \
2601                 fabi-version=0 \
2602                 Wextra \
2603                 Wignored-qualifiers \
2604                 Wlogical-op \
2605                 Woverloaded-virtual \
2606                 Wsign-promo \
2607                 Wsynth \
2608                 Wold-style-cast \
2609                 Wcast-align \
2610                 Wcast-qual \
2611                 Wpointer-arith \
2612                 Wshadow \
2613                 Wundef $cf_gxx_extra_warnings $1
2614         do
2615                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2616                 if AC_TRY_EVAL(ac_compile); then
2617                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2618                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2619                 else
2620                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2621                 fi
2622         done
2623         CXXFLAGS="$cf_save_CXXFLAGS"
2624 fi
2625
2626 rm -rf conftest*
2627 AC_LANG_RESTORE
2628 AC_SUBST(EXTRA_CXXFLAGS)
2629 ])dnl
2630 dnl ---------------------------------------------------------------------------
2631 dnl CF_HASHED_DB version: 5 updated: 2014/04/12 16:47:01
2632 dnl ------------
2633 dnl Look for an instance of the Berkeley hashed database.
2634 dnl
2635 dnl $1 = optional parameter, to specify install-prefix for the database.
2636 AC_DEFUN([CF_HASHED_DB],
2637 [
2638 ifelse([$1],,,[
2639 case $1 in #(vi
2640 yes|*able*) #(vi
2641     ;;
2642 *)
2643     if test -d "$1" ; then
2644         CF_ADD_INCDIR($1/include)
2645         CF_ADD_LIBDIR($1/lib)
2646         else
2647                 case "$1" in #(vi
2648                 ./*|../*|/*)
2649                         AC_MSG_WARN(no such directory $1)
2650                         ;; #(vi
2651                 *)
2652                         CF_FIND_SUB_INCDIR($1)
2653                         CF_FIND_SUB_LIBDIR($1)
2654                         ;;
2655                 esac
2656     fi
2657 esac
2658 ])
2659 AC_CHECK_HEADER(db.h,[
2660 CF_HASHED_DB_VERSION
2661 if test "$cf_cv_hashed_db_version" = unknown ; then
2662         AC_MSG_ERROR(Cannot determine version of db)
2663 else
2664         CF_HASHED_DB_LIBS
2665         if test "$cf_cv_hashed_db_libs" = unknown ; then
2666                 AC_MSG_ERROR(Cannot determine library for db)
2667         elif test "$cf_cv_hashed_db_libs" != default ; then
2668                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2669         fi
2670 fi
2671 ],[
2672         AC_MSG_ERROR(Cannot find db.h)
2673 ])
2674 ])dnl
2675 dnl ---------------------------------------------------------------------------
2676 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2677 dnl -----------------
2678 dnl Given that we have the header and version for hashed database, find the
2679 dnl library information.
2680 AC_DEFUN([CF_HASHED_DB_LIBS],
2681 [
2682 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2683 cf_cv_hashed_db_libs=unknown
2684 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2685 do
2686         cf_save_libs="$LIBS"
2687         if test -n "$cf_db_libs"; then
2688                 CF_ADD_LIB($cf_db_libs)
2689         fi
2690         CF_MSG_LOG(checking for library "$cf_db_libs")
2691         AC_TRY_LINK([
2692 $ac_includes_default
2693 #include <db.h>
2694 ],[
2695         char *path = "/tmp/foo";
2696 #ifdef DB_VERSION_MAJOR
2697 #if DB_VERSION_MAJOR >= 4
2698         DB *result = 0;
2699         db_create(&result, NULL, 0);
2700         result->open(result,
2701                 NULL,
2702                 path,
2703                 path,
2704                 DB_HASH,
2705                 DB_CREATE,
2706                 0644);
2707 #elif DB_VERSION_MAJOR >= 3
2708         DB *result = 0;
2709         db_create(&result, NULL, 0);
2710         result->open(result,
2711                 path,
2712                 path,
2713                 DB_HASH,
2714                 DB_CREATE,
2715                 0644);
2716 #elif DB_VERSION_MAJOR >= 2
2717         DB *result = 0;
2718         db_open(path,
2719                 DB_HASH,
2720                 DB_CREATE,
2721                 0644,
2722                 (DB_ENV *) 0,
2723                 (DB_INFO *) 0,
2724                 &result);
2725 #endif /* DB_VERSION_MAJOR */
2726 #else
2727         DB *result = dbopen(path,
2728                      2,
2729                      0644,
2730                      DB_HASH,
2731                      0);
2732 #endif
2733         ${cf_cv_main_return:-return}(result != 0)
2734 ],[
2735         if test -n "$cf_db_libs" ; then
2736                 cf_cv_hashed_db_libs=$cf_db_libs
2737         else
2738                 cf_cv_hashed_db_libs=default
2739         fi
2740         LIBS="$cf_save_libs"
2741         break
2742 ])
2743         LIBS="$cf_save_libs"
2744 done
2745 ])
2746 ])dnl
2747 dnl ---------------------------------------------------------------------------
2748 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
2749 dnl --------------------
2750 dnl Given that we have the header file for hashed database, find the version
2751 dnl information.
2752 AC_DEFUN([CF_HASHED_DB_VERSION],
2753 [
2754 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
2755 cf_cv_hashed_db_version=unknown
2756
2757 for cf_db_version in 1 2 3 4 5 6
2758 do
2759         CF_MSG_LOG(checking for db version $cf_db_version)
2760         AC_TRY_COMPILE([
2761 $ac_includes_default
2762 #include <db.h>
2763
2764 #ifdef DB_VERSION_MAJOR
2765         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
2766 #if $cf_db_version == DB_VERSION_MAJOR
2767         /* ok */
2768 #else
2769         make an error
2770 #endif
2771 #else
2772 #if $cf_db_version == 1
2773         /* ok: assuming this is DB 1.8.5 */
2774 #else
2775         make an error
2776 #endif
2777 #endif
2778 ],[DBT *foo = 0],[
2779         cf_cv_hashed_db_version=$cf_db_version
2780         break
2781         ])
2782 done
2783 ])
2784 ])dnl
2785 dnl ---------------------------------------------------------------------------
2786 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
2787 dnl --------------
2788 dnl Construct a search-list of directories for a nonstandard header-file
2789 dnl
2790 dnl Parameters
2791 dnl     $1 = the variable to return as result
2792 dnl     $2 = the package name
2793 AC_DEFUN([CF_HEADER_PATH],
2794 [
2795 $1=
2796
2797 # collect the current set of include-directories from compiler flags
2798 cf_header_path_list=""
2799 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2800         for cf_header_path in $CPPFLAGS $CFLAGS
2801         do
2802                 case $cf_header_path in #(vi
2803                 -I*)
2804                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2805                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2806                         cf_header_path_list="$cf_header_path_list [$]$1"
2807                         ;;
2808                 esac
2809         done
2810 fi
2811
2812 # add the variations for the package we are looking for
2813 CF_SUBDIR_PATH($1,$2,include)
2814
2815 test "$includedir" != NONE && \
2816 test "$includedir" != "/usr/include" && \
2817 test -d "$includedir" && {
2818         test -d $includedir &&    $1="[$]$1 $includedir"
2819         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
2820 }
2821
2822 test "$oldincludedir" != NONE && \
2823 test "$oldincludedir" != "/usr/include" && \
2824 test -d "$oldincludedir" && {
2825         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
2826         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
2827 }
2828
2829 $1="[$]$1 $cf_header_path_list"
2830 ])dnl
2831 dnl ---------------------------------------------------------------------------
2832 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
2833 dnl ---------------
2834 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2835 AC_DEFUN([CF_HELP_MESSAGE],
2836 [AC_DIVERT_HELP([$1])dnl
2837 ])dnl
2838 dnl ---------------------------------------------------------------------------
2839 dnl CF_INCLUDE_DIRS version: 9 updated: 2014/07/26 18:54:28
2840 dnl ---------------
2841 dnl Construct the list of include-options according to whether we're building
2842 dnl in the source directory or using '--srcdir=DIR' option.  If we're building
2843 dnl with gcc, don't append the includedir if it happens to be /usr/include,
2844 dnl since that usually breaks gcc's shadow-includes.
2845 AC_DEFUN([CF_INCLUDE_DIRS],
2846 [
2847 if test "$GCC" != yes; then
2848         CPPFLAGS="-I\${includedir} $CPPFLAGS"
2849 elif test "$includedir" != "/usr/include"; then
2850         if test "$includedir" = '${prefix}/include' ; then
2851                 if test x$prefix != x/usr ; then
2852                         CPPFLAGS="-I\${includedir} $CPPFLAGS"
2853                 fi
2854         else
2855                 CPPFLAGS="-I\${includedir} $CPPFLAGS"
2856         fi
2857 fi
2858 if test "$srcdir" != "."; then
2859         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
2860 fi
2861 CPPFLAGS="-I../include $CPPFLAGS"
2862 if test "$srcdir" != "."; then
2863         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
2864 fi
2865 CPPFLAGS="-I. $CPPFLAGS"
2866 AC_SUBST(CPPFLAGS)
2867 ])dnl
2868 dnl ---------------------------------------------------------------------------
2869 dnl CF_INTEL_COMPILER version: 6 updated: 2014/03/17 13:13:07
2870 dnl -----------------
2871 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2872 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2873 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2874 dnl
2875 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2876 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2877 dnl the wrappers for gcc and g++ warnings.
2878 dnl
2879 dnl $1 = GCC (default) or GXX
2880 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2881 dnl $3 = CFLAGS (default) or CXXFLAGS
2882 AC_DEFUN([CF_INTEL_COMPILER],[
2883 AC_REQUIRE([AC_CANONICAL_HOST])
2884 ifelse([$2],,INTEL_COMPILER,[$2])=no
2885
2886 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2887         case $host_os in
2888         linux*|gnu*)
2889                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2890                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2891                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2892                 AC_TRY_COMPILE([],[
2893 #ifdef __INTEL_COMPILER
2894 #else
2895 make an error
2896 #endif
2897 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2898 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
2899 ],[])
2900                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2901                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2902                 ;;
2903         esac
2904 fi
2905 ])dnl
2906 dnl ---------------------------------------------------------------------------
2907 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
2908 dnl ----------
2909 dnl Check if we have either a function or macro for 'isascii()'.
2910 AC_DEFUN([CF_ISASCII],
2911 [
2912 AC_MSG_CHECKING(for isascii)
2913 AC_CACHE_VAL(cf_cv_have_isascii,[
2914         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
2915         [cf_cv_have_isascii=yes],
2916         [cf_cv_have_isascii=no])
2917 ])dnl
2918 AC_MSG_RESULT($cf_cv_have_isascii)
2919 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
2920 ])dnl
2921 dnl ---------------------------------------------------------------------------
2922 dnl CF_LARGEFILE version: 8 updated: 2012/10/06 08:57:51
2923 dnl ------------
2924 dnl Add checks for large file support.
2925 AC_DEFUN([CF_LARGEFILE],[
2926 ifdef([AC_FUNC_FSEEKO],[
2927     AC_SYS_LARGEFILE
2928     if test "$enable_largefile" != no ; then
2929         AC_FUNC_FSEEKO
2930
2931         # Normally we would collect these definitions in the config.h,
2932         # but (like _XOPEN_SOURCE), some environments rely on having these
2933         # defined before any of the system headers are included.  Another
2934         # case comes up with C++, e.g., on AIX the compiler compiles the
2935         # header files by themselves before looking at the body files it is
2936         # told to compile.  For ncurses, those header files do not include
2937         # the config.h
2938         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
2939         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
2940         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
2941
2942         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2943                 AC_TRY_COMPILE([
2944 #include <sys/types.h>
2945 #include <dirent.h>
2946                 ],[
2947                 /* if transitional largefile support is setup, this is true */
2948                 extern struct dirent64 * readdir(DIR *);
2949                 struct dirent64 *x = readdir((DIR *)0);
2950                 struct dirent *y = readdir((DIR *)0);
2951                 int z = x - y;
2952                 ],
2953                 [cf_cv_struct_dirent64=yes],
2954                 [cf_cv_struct_dirent64=no])
2955         ])
2956         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
2957     fi
2958 ])
2959 ])
2960 dnl ---------------------------------------------------------------------------
2961 dnl CF_LDFLAGS_STATIC version: 10 updated: 2011/09/24 12:51:48
2962 dnl -----------------
2963 dnl Check for compiler/linker flags used to temporarily force usage of static
2964 dnl libraries.  This depends on the compiler and platform.  Use this to help
2965 dnl ensure that the linker picks up a given library based on its position in
2966 dnl the list of linker options and libraries.
2967 AC_DEFUN([CF_LDFLAGS_STATIC],[
2968
2969 if test "$GCC" = yes ; then
2970         case $cf_cv_system_name in #(
2971         OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)         #( vi
2972                 LDFLAGS_STATIC=
2973                 LDFLAGS_SHARED=
2974                 ;;
2975     *)  #( normally, except when broken
2976         LDFLAGS_STATIC=-static
2977         LDFLAGS_SHARED=-dynamic
2978         ;;
2979     esac
2980 else
2981         case $cf_cv_system_name in #(
2982         aix[[4-7]]*)    #( from ld manpage
2983                 LDFLAGS_STATIC=-bstatic
2984                 LDFLAGS_SHARED=-bdynamic
2985                 ;;
2986         hpux*)          #( from ld manpage for hpux10.20, hpux11.11
2987                 # We could also use just "archive" and "shared".
2988                 LDFLAGS_STATIC=-Wl,-a,archive_shared
2989                 LDFLAGS_SHARED=-Wl,-a,shared_archive
2990                 ;;
2991         irix*)          #( from ld manpage IRIX64
2992                 LDFLAGS_STATIC=-Bstatic
2993                 LDFLAGS_SHARED=-Bdynamic
2994                 ;;
2995         osf[[45]]*)     #( from ld manpage osf4.0d, osf5.1
2996                 # alternative "-oldstyle_liblookup" (not in cc manpage)
2997                 LDFLAGS_STATIC=-noso
2998                 LDFLAGS_SHARED=-so_archive
2999                 ;;
3000         solaris2*)
3001                 LDFLAGS_STATIC=-Bstatic
3002                 LDFLAGS_SHARED=-Bdynamic
3003                 ;;
3004         esac
3005 fi
3006
3007 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
3008 then
3009         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
3010
3011         rm -f libconftest.a
3012         cat >conftest.$ac_ext <<EOF
3013 #line __oline__ "configure"
3014 #include <stdio.h>
3015 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
3016 EOF
3017         if AC_TRY_EVAL(ac_compile) ; then
3018                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
3019                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
3020         fi
3021         rm -f conftest.*
3022
3023         cf_save_LIBS="$LIBS"
3024
3025         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
3026         AC_TRY_LINK([
3027 #line __oline__ "configure"
3028 #include <stdio.h>
3029 int cf_ldflags_static(FILE *fp);
3030 ],[
3031         return cf_ldflags_static(stdin);
3032 ],[
3033         # some linkers simply ignore the -dynamic
3034         case x`file conftest$ac_exeext 2>/dev/null` in #(vi
3035         *static*) # (vi
3036                 cf_ldflags_static=no
3037                 ;;
3038         *)
3039                 cf_ldflags_static=yes
3040                 ;;
3041         esac
3042 ],[cf_ldflags_static=no])
3043
3044         rm -f libconftest.*
3045         LIBS="$cf_save_LIBS"
3046
3047         AC_MSG_RESULT($cf_ldflags_static)
3048
3049         if test $cf_ldflags_static != yes
3050         then
3051                 LDFLAGS_STATIC=
3052                 LDFLAGS_SHARED=
3053         fi
3054 else
3055         LDFLAGS_STATIC=
3056         LDFLAGS_SHARED=
3057 fi
3058
3059 AC_SUBST(LDFLAGS_STATIC)
3060 AC_SUBST(LDFLAGS_SHARED)
3061 ])
3062 dnl ---------------------------------------------------------------------------
3063 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
3064 dnl ---------------
3065 dnl For the given system and compiler, find the compiler flags to pass to the
3066 dnl loader to use the "rpath" feature.
3067 AC_DEFUN([CF_LD_RPATH_OPT],
3068 [
3069 AC_REQUIRE([CF_CHECK_CACHE])
3070
3071 LD_RPATH_OPT=
3072 AC_MSG_CHECKING(for an rpath option)
3073 case $cf_cv_system_name in #(vi
3074 irix*) #(vi
3075         if test "$GCC" = yes; then
3076                 LD_RPATH_OPT="-Wl,-rpath,"
3077         else
3078                 LD_RPATH_OPT="-rpath "
3079         fi
3080         ;;
3081 linux*|gnu*|k*bsd*-gnu) #(vi
3082         LD_RPATH_OPT="-Wl,-rpath,"
3083         ;;
3084 openbsd[[2-9]].*|mirbsd*) #(vi
3085         LD_RPATH_OPT="-Wl,-rpath,"
3086         ;;
3087 dragonfly*|freebsd*) #(vi
3088         LD_RPATH_OPT="-rpath "
3089         ;;
3090 netbsd*) #(vi
3091         LD_RPATH_OPT="-Wl,-rpath,"
3092         ;;
3093 osf*|mls+*) #(vi
3094         LD_RPATH_OPT="-rpath "
3095         ;;
3096 solaris2*) #(vi
3097         LD_RPATH_OPT="-R"
3098         ;;
3099 *)
3100         ;;
3101 esac
3102 AC_MSG_RESULT($LD_RPATH_OPT)
3103
3104 case "x$LD_RPATH_OPT" in #(vi
3105 x-R*)
3106         AC_MSG_CHECKING(if we need a space after rpath option)
3107         cf_save_LIBS="$LIBS"
3108         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3109         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3110         LIBS="$cf_save_LIBS"
3111         AC_MSG_RESULT($cf_rpath_space)
3112         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3113         ;;
3114 esac
3115 ])dnl
3116 dnl ---------------------------------------------------------------------------
3117 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
3118 dnl ---------------
3119 dnl Construct a search-list of directories for a nonstandard library-file
3120 dnl
3121 dnl Parameters
3122 dnl     $1 = the variable to return as result
3123 dnl     $2 = the package name
3124 AC_DEFUN([CF_LIBRARY_PATH],
3125 [
3126 $1=
3127 cf_library_path_list=""
3128 if test -n "${LDFLAGS}${LIBS}" ; then
3129         for cf_library_path in $LDFLAGS $LIBS
3130         do
3131                 case $cf_library_path in #(vi
3132                 -L*)
3133                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3134                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3135                         cf_library_path_list="$cf_library_path_list [$]$1"
3136                         ;;
3137                 esac
3138         done
3139 fi
3140
3141 CF_SUBDIR_PATH($1,$2,lib)
3142
3143 $1="$cf_library_path_list [$]$1"
3144 ])dnl
3145 dnl ---------------------------------------------------------------------------
3146 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
3147 dnl ------------------
3148 AC_DEFUN([CF_LIBTOOL_VERSION],[
3149 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
3150 then
3151         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
3152 else
3153         cf_cv_libtool_version=
3154 fi
3155 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
3156 ])dnl
3157 dnl ---------------------------------------------------------------------------
3158 dnl CF_LIB_PREFIX version: 9 updated: 2012/01/21 19:28:10
3159 dnl -------------
3160 dnl Compute the library-prefix for the given host system
3161 dnl $1 = variable to set
3162 define([CF_LIB_PREFIX],
3163 [
3164         case $cf_cv_system_name in #(vi
3165         OS/2*|os2*) #(vi
3166         LIB_PREFIX=''
3167         ;;
3168         *)      LIB_PREFIX='lib'
3169         ;;
3170         esac
3171 ifelse($1,,,[$1=$LIB_PREFIX])
3172         AC_SUBST(LIB_PREFIX)
3173 ])dnl
3174 dnl ---------------------------------------------------------------------------
3175 dnl CF_LIB_RULES version: 74 updated: 2013/09/07 13:54:05
3176 dnl ------------
3177 dnl Append definitions and rules for the given models to the subdirectory
3178 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3179 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
3180 dnl the corresponding makefile to list the models that we'll generate.
3181 dnl
3182 dnl For shared libraries, make a list of symbolic links to construct when
3183 dnl generating each library.  The convention used for Linux is the simplest
3184 dnl one:
3185 dnl     lib<name>.so    ->
3186 dnl     lib<name>.so.<major>    ->
3187 dnl     lib<name>.so.<maj>.<minor>
3188 dnl
3189 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
3190 AC_DEFUN([CF_LIB_RULES],
3191 [
3192 cf_prefix=$LIB_PREFIX
3193 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3194
3195 case $cf_cv_shlib_version in #(vi
3196 cygdll|msysdll|mingw)
3197         TINFO_NAME=$TINFO_ARG_SUFFIX
3198         TINFO_SUFFIX=.dll
3199         ;;
3200 esac
3201
3202 if test -n "$TINFO_SUFFIX" ; then
3203         case $TINFO_SUFFIX in
3204         tw*)
3205                 TINFO_NAME="${TINFO_NAME}tw"
3206                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw//'`
3207                 ;;
3208         t*)
3209                 TINFO_NAME="${TINFO_NAME}t"
3210                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t//'`
3211                 ;;
3212         w*)
3213                 TINFO_NAME="${TINFO_NAME}w"
3214                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w//'`
3215                 ;;
3216         esac
3217 fi
3218
3219 for cf_dir in $SRC_SUBDIRS
3220 do
3221         if test ! -d $srcdir/$cf_dir ; then
3222                 continue
3223         elif test -f $srcdir/$cf_dir/modules; then
3224
3225                 SHARED_LIB=
3226                 Libs_To_Make=
3227                 for cf_item in $cf_LIST_MODELS
3228                 do
3229                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3230                         cf_libname=$cf_dir
3231                         test "$cf_dir" = c++ && cf_libname=ncurses++
3232                         if test $cf_item = shared ; then
3233                                 if test -n "${LIB_SUFFIX}"
3234                                 then
3235                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${LIB_SUFFIX}"'//'`
3236                                 else
3237                                         cf_shared_suffix="$cf_suffix"
3238                                 fi
3239                                 if test "$cf_cv_do_symlinks" = yes ; then
3240                                         cf_version_name=
3241
3242                                         case "$cf_cv_shlib_version" in #(vi
3243                                         rel) #(vi
3244                                                 cf_version_name=REL_VERSION
3245                                                 ;;
3246                                         abi)
3247                                                 cf_version_name=ABI_VERSION
3248                                                 ;;
3249                                         esac
3250
3251                                         if test -n "$cf_version_name"
3252                                         then
3253                                                 case "$cf_cv_system_name" in #(vi
3254                                                 darwin*)
3255                                                         # "w", etc?
3256                                                         cf_suffix="${LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
3257                                                         ;; #(vi
3258                                                 *)
3259                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
3260                                                         ;;
3261                                                 esac
3262                                         fi
3263                                         if test -n "${LIB_SUFFIX}"
3264                                         then
3265                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${LIB_SUFFIX}"'//'`
3266                                         else
3267                                                 cf_shared_suffix="$cf_suffix"
3268                                         fi
3269                                 fi
3270                                 # cygwin needs import library, and has unique naming convention
3271                                 # use autodetected ${cf_prefix} for import lib and static lib, but
3272                                 # use 'cyg' prefix for shared lib.
3273                                 case $cf_cv_shlib_version in #(vi
3274                                 cygdll) #(vi
3275                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3276                                         Libs_To_Make="$Libs_To_Make ../lib/cyg${cf_libname}${cf_cygsuf}"
3277                                         continue
3278                                         ;;
3279                                 msysdll) #(vi
3280                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3281                                         Libs_To_Make="$Libs_To_Make ../lib/msys-${cf_libname}${cf_cygsuf}"
3282                                         continue
3283                                         ;;
3284                                 mingw)
3285                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3286                                         Libs_To_Make="$Libs_To_Make ../lib/lib${cf_libname}${cf_cygsuf}"
3287                                         continue
3288                                         ;;
3289                                 esac
3290                         fi
3291                         Libs_To_Make="$Libs_To_Make ../lib/${cf_prefix}${cf_libname}${cf_suffix}"
3292                 done
3293
3294                 if test $cf_dir = ncurses ; then
3295                         cf_subsets="$LIB_SUBSETS"
3296                         cf_r_parts="$cf_subsets"
3297                         cf_liblist="$Libs_To_Make"
3298
3299                         while test -n "$cf_r_parts"
3300                         do
3301                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3302                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3303                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3304                                         cf_item=
3305                                         case $cf_l_parts in #(vi
3306                                         *termlib*) #(vi
3307                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3308                                                 ;;
3309                                         *ticlib*)
3310                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3311                                                 ;;
3312                                         *)
3313                                                 break
3314                                                 ;;
3315                                         esac
3316                                         if test -n "$cf_item"; then
3317                                                 Libs_To_Make="$cf_item $Libs_To_Make"
3318                                         fi
3319                                 else
3320                                         break
3321                                 fi
3322                         done
3323                 else
3324                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3325                 fi
3326
3327                 if test $cf_dir = c++; then
3328                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
3329                                 cf_list=
3330                                 for cf_item in $Libs_To_Make
3331                                 do
3332                                         case $cf_item in
3333                                         *.a)
3334                                                 ;;
3335                                         *)
3336                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
3337                                                 ;;
3338                                         esac
3339                                         for cf_test in $cf_list
3340                                         do
3341                                                 if test "$cf_test" = "$cf_item"
3342                                                 then
3343                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
3344                                                         cf_item=
3345                                                         break
3346                                                 fi
3347                                         done
3348                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
3349                                 done
3350                                 Libs_To_Make="$cf_list"
3351                         fi
3352                 fi
3353
3354                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
3355                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3356                         $cf_dir/Makefile >$cf_dir/Makefile.out
3357                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3358
3359                 $AWK -f $srcdir/mk-0th.awk \
3360                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
3361                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3362
3363                 for cf_subset in $cf_subsets
3364                 do
3365                         cf_subdirs=
3366                         for cf_item in $cf_LIST_MODELS
3367                         do
3368
3369                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3370                         CF_UPPER(cf_ITEM,$cf_item)
3371
3372                         CXX_MODEL=$cf_ITEM
3373                         if test "$CXX_MODEL" = SHARED; then
3374                                 case $cf_cv_shlib_version in #(vi
3375                                 cygdll|msysdll|mingw) #(vi
3376                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
3377                                         with_shared_cxx=yes
3378                                         ;;
3379                                 *)
3380                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
3381                                         ;;
3382                                 esac
3383                         fi
3384
3385                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3386                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3387
3388                         # Test for case where we build libtinfo with a different name.
3389                         cf_libname=$cf_dir
3390                         if test $cf_dir = ncurses ; then
3391                                 case $cf_subset in
3392                                 *base*)
3393                                         cf_libname=${cf_libname}$LIB_SUFFIX
3394                                         ;;
3395                                 *termlib*)
3396                                         cf_libname=$TINFO_LIB_SUFFIX
3397                                         ;;
3398                                 ticlib*)
3399                                         cf_libname=$TICS_LIB_SUFFIX
3400                                         ;;
3401                                 esac
3402                         elif test $cf_dir = c++ ; then
3403                                 cf_libname=ncurses++$LIB_SUFFIX
3404                         else
3405                                 cf_libname=${cf_libname}$LIB_SUFFIX
3406                         fi
3407                         if test -n "${DFT_ARG_SUFFIX}" ; then
3408                                 # undo $LIB_SUFFIX add-on in CF_LIB_SUFFIX
3409                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${LIB_SUFFIX}%%"`
3410                         fi
3411
3412                         # These dependencies really are for development, not
3413                         # builds, but they are useful in porting, too.
3414                         cf_depend="../include/ncurses_cfg.h"
3415                         if test "$srcdir" = "."; then
3416                                 cf_reldir="."
3417                         else
3418                                 cf_reldir="\${srcdir}"
3419                         fi
3420
3421                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3422                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3423                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3424                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3425                         fi
3426
3427                         cf_dir_suffix=
3428                         old_cf_suffix="$cf_suffix"
3429                         if test "$cf_cv_shlib_version_infix" = yes ; then
3430                         if test -n "$LIB_SUFFIX" ; then
3431                                 case $LIB_SUFFIX in
3432                                 tw*)
3433                                         cf_libname=`echo $cf_libname | sed 's/tw$//'`
3434                                         cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3435                                         cf_dir_suffix=tw
3436                                         ;;
3437                                 t*)
3438                                         cf_libname=`echo $cf_libname | sed 's/t$//'`
3439                                         cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3440                                         cf_dir_suffix=t
3441                                         ;;
3442                                 w*)
3443                                         cf_libname=`echo $cf_libname | sed 's/w$//'`
3444                                         cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3445                                         cf_dir_suffix=w
3446                                         ;;
3447                                 esac
3448                         fi
3449                         fi
3450
3451                         $AWK -f $srcdir/mk-1st.awk \
3452                                 name=${cf_libname}${cf_dir_suffix} \
3453                                 traces=$LIB_TRACING \
3454                                 MODEL=$cf_ITEM \
3455                                 CXX_MODEL=$CXX_MODEL \
3456                                 model=$cf_subdir \
3457                                 prefix=$cf_prefix \
3458                                 suffix=$cf_suffix \
3459                                 subset=$cf_subset \
3460                                 driver=$cf_cv_term_driver \
3461                                 SymLink="$LN_S" \
3462                                 TermlibRoot=$TINFO_NAME \
3463                                 TermlibSuffix=$TINFO_SUFFIX \
3464                                 ShlibVer=$cf_cv_shlib_version \
3465                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3466                                 ReLink=${cf_cv_do_relink:-no} \
3467                                 DoLinks=$cf_cv_do_symlinks \
3468                                 rmSoLocs=$cf_cv_rm_so_locs \
3469                                 ldconfig="$LDCONFIG" \
3470                                 overwrite=$WITH_OVERWRITE \
3471                                 depend="$cf_depend" \
3472                                 host="$host" \
3473                                 libtool_version="$LIBTOOL_VERSION" \
3474                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3475
3476                         cf_suffix="$old_cf_suffix"
3477
3478                         for cf_subdir2 in $cf_subdirs lib
3479                         do
3480                                 test $cf_subdir = $cf_subdir2 && break
3481                         done
3482                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3483                         $AWK -f $srcdir/mk-2nd.awk \
3484                                 name=$cf_dir \
3485                                 traces=$LIB_TRACING \
3486                                 MODEL=$cf_ITEM \
3487                                 model=$cf_subdir \
3488                                 subset=$cf_subset \
3489                                 srcdir=$srcdir \
3490                                 echo=$WITH_ECHO \
3491                                 crenames=$cf_cv_prog_CC_c_o \
3492                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3493                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3494                         cf_subdirs="$cf_subdirs $cf_subdir"
3495                         done
3496                 done
3497         fi
3498
3499         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
3500 done
3501
3502 for cf_dir in $SRC_SUBDIRS
3503 do
3504         if test ! -d $srcdir/$cf_dir ; then
3505                 continue
3506         fi
3507
3508         if test -f $cf_dir/Makefile ; then
3509                 case "$cf_dir" in
3510                 Ada95) #(vi
3511                         echo 'libs \' >> Makefile
3512                         echo 'install.libs \' >> Makefile
3513                         echo 'uninstall.libs ::' >> Makefile
3514                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
3515                         ;;
3516                 esac
3517         fi
3518
3519         if test -f $srcdir/$cf_dir/modules; then
3520                 echo >> Makefile
3521                 if test -f $srcdir/$cf_dir/headers; then
3522 cat >> Makefile <<CF_EOF
3523 install.includes \\
3524 uninstall.includes \\
3525 CF_EOF
3526                 fi
3527 if test "$cf_dir" != "c++" ; then
3528 echo 'lint \' >> Makefile
3529 fi
3530 cat >> Makefile <<CF_EOF
3531 libs \\
3532 lintlib \\
3533 install.libs \\
3534 uninstall.libs \\
3535 install.$cf_dir \\
3536 uninstall.$cf_dir ::
3537         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3538 CF_EOF
3539         elif test -f $srcdir/$cf_dir/headers; then
3540 cat >> Makefile <<CF_EOF
3541
3542 libs \\
3543 install.libs \\
3544 uninstall.libs \\
3545 install.includes \\
3546 uninstall.includes ::
3547         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3548 CF_EOF
3549 fi
3550 done
3551
3552 if test "x$cf_with_db_install" = xyes; then
3553 cat >> Makefile <<CF_EOF
3554
3555 install.libs uninstall.libs \\
3556 install.data uninstall.data ::
3557 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3558 CF_EOF
3559 fi
3560
3561 if test "x$cf_with_manpages" = xyes; then
3562 cat >> Makefile <<CF_EOF
3563
3564 install.man \\
3565 uninstall.man ::
3566         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
3567 CF_EOF
3568 fi
3569
3570 cat >> Makefile <<CF_EOF
3571
3572 distclean ::
3573         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3574         rm -f headers.sh headers.sed mk_shared_lib.sh
3575         rm -f edit_man.* man_alias.*
3576         rm -rf \${DIRS_TO_MAKE}
3577 CF_EOF
3578
3579 # Special case: tack's manpage lives in its own directory.
3580 if test "x$cf_with_manpages" = xyes; then
3581 if test -d tack ; then
3582 if test -f $srcdir/$tack.h; then
3583 cat >> Makefile <<CF_EOF
3584
3585 install.man \\
3586 uninstall.man ::
3587         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
3588 CF_EOF
3589 fi
3590 fi
3591 fi
3592
3593 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3594 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3595 dnl anything, and will make it more standardized.  It's awkward to decide this
3596 dnl at configuration because of quoting, so we'll simply make all headers
3597 dnl installed via a script that can do the right thing.
3598
3599 rm -f headers.sed headers.sh
3600
3601 dnl ( generating this script makes the makefiles a little tidier :-)
3602 echo creating headers.sh
3603 cat >headers.sh <<CF_EOF
3604 #! /bin/sh
3605 # This shell script is generated by the 'configure' script.  It is invoked in a
3606 # subdirectory of the build tree.  It generates a sed-script in the parent
3607 # directory that is used to adjust includes for header files that reside in a
3608 # subdirectory of /usr/include, etc.
3609 PRG=""
3610 while test \[$]# != 3
3611 do
3612 PRG="\$PRG \[$]1"; shift
3613 done
3614 DST=\[$]1
3615 REF=\[$]2
3616 SRC=\[$]3
3617 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3618 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3619 echo installing \$SRC in \$DST
3620 CF_EOF
3621
3622 if test $WITH_CURSES_H = yes; then
3623         cat >>headers.sh <<CF_EOF
3624 case \$DST in
3625 /*/include/*)
3626         END=\`basename \$DST\`
3627         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3628         do
3629                 NAME=\`basename \$i\`
3630                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3631         done
3632         ;;
3633 *)
3634         echo "" >> \$TMPSED
3635         ;;
3636 esac
3637 CF_EOF
3638
3639 else
3640         cat >>headers.sh <<CF_EOF
3641 case \$DST in
3642 /*/include/*)
3643         END=\`basename \$DST\`
3644         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3645         do
3646                 NAME=\`basename \$i\`
3647                 if test "\$NAME" = "curses.h"
3648                 then
3649                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3650                         NAME=ncurses.h
3651                 fi
3652                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3653         done
3654         ;;
3655 *)
3656         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3657         ;;
3658 esac
3659 CF_EOF
3660 fi
3661 cat >>headers.sh <<CF_EOF
3662 rm -f \$TMPSRC
3663 sed -f \$TMPSED \$SRC > \$TMPSRC
3664 NAME=\`basename \$SRC\`
3665 CF_EOF
3666 if test $WITH_CURSES_H != yes; then
3667         cat >>headers.sh <<CF_EOF
3668 test "\$NAME" = "curses.h" && NAME=ncurses.h
3669 CF_EOF
3670 fi
3671 cat >>headers.sh <<CF_EOF
3672 # Just in case someone gzip'd manpages, remove the conflicting copy.
3673 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3674
3675 eval \$PRG \$TMPSRC \$DST/\$NAME
3676 rm -f \$TMPSRC \$TMPSED
3677 CF_EOF
3678
3679 chmod 0755 headers.sh
3680
3681 for cf_dir in $SRC_SUBDIRS
3682 do
3683         if test ! -d $srcdir/$cf_dir ; then
3684                 continue
3685         fi
3686
3687         if test -f $srcdir/$cf_dir/headers; then
3688                 $AWK -f $srcdir/mk-hdr.awk \
3689                         subset="$LIB_SUBSETS" \
3690                         compat="$WITH_CURSES_H" \
3691                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3692         fi
3693
3694         if test -f $srcdir/$cf_dir/modules; then
3695                 if test "$cf_dir" != "c++" ; then
3696                         cat >>$cf_dir/Makefile <<"CF_EOF"
3697 depend : ${AUTO_SRC}
3698         makedepend -- ${CPPFLAGS} -- ${C_SRC}
3699
3700 # DO NOT DELETE THIS LINE -- make depend depends on it.
3701 CF_EOF
3702                 fi
3703         fi
3704 done
3705 AC_SUBST(Libs_To_Make)
3706 ])dnl
3707 dnl ---------------------------------------------------------------------------
3708 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
3709 dnl -------------
3710 dnl Find the and soname for the given shared library.  Set the cache variable
3711 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
3712 dnl variable to "unknown".
3713 dnl
3714 dnl $1 = headers
3715 dnl $2 = code
3716 dnl $3 = library name
3717 AC_DEFUN([CF_LIB_SONAME],