aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2011,2012 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.611 2012/04/01 00:13:31 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 3 updated: 2002/10/27 23:21:42
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54     [AC_TRY_LINK([#include <langinfo.h>],
  55       [char* cs = nl_langinfo(CODESET);],
  56       am_cv_langinfo_codeset=yes,
  57       am_cv_langinfo_codeset=no)
  58     ])
  59   if test $am_cv_langinfo_codeset = yes; then
  60     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62   fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ACVERSION_CHECK version: 2 updated: 2011/05/08 11:22:03
  66 dnl ------------------
  67 dnl Conditionally generate script according to whether we're using a given autoconf.
  68 dnl
  69 dnl $1 = version to compare against
  70 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  71 dnl $3 = code to use if AC_ACVERSION is older than $1.
  72 define(CF_ACVERSION_CHECK,
  73 [
  74 ifdef([m4_version_compare],
  75 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  76 [CF_ACVERSION_COMPARE(
  77 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  78 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  79 dnl ---------------------------------------------------------------------------
  80 dnl CF_ACVERSION_COMPARE version: 2 updated: 2011/04/14 20:56:50
  81 dnl --------------------
  82 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  83 dnl                      MAJOR2, MINOR2, TERNARY2,
  84 dnl                      PRINTABLE2, not FOUND, FOUND)
  85 define(CF_ACVERSION_COMPARE,
  86 [ifelse(builtin([eval], [$2 < $5]), 1,
  87 [ifelse([$8], , ,[$8])],
  88 [ifelse([$9], , ,[$9])])])dnl
  89 dnl ---------------------------------------------------------------------------
  90 dnl CF_ADA_INCLUDE_DIRS version: 6 updated: 2010/02/26 19:52:07
  91 dnl -------------------
  92 dnl Construct the list of include-options for the C programs in the Ada95
  93 dnl binding.
  94 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  95 [
  96 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  97 if test "$srcdir" != "."; then
  98         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
  99 fi
 100 if test "$GCC" != yes; then
 101         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 102 elif test "$includedir" != "/usr/include"; then
 103         if test "$includedir" = '${prefix}/include' ; then
 104                 if test $prefix != /usr ; then
 105                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 106                 fi
 107         else
 108                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 109         fi
 110 fi
 111 AC_SUBST(ACPPFLAGS)
 112 ])dnl
 113 dnl ---------------------------------------------------------------------------
 114 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 115 dnl ---------------
 116 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 117 AC_DEFUN([CF_ADD_ADAFLAGS],[
 118         ADAFLAGS="$ADAFLAGS $1"
 119         AC_SUBST(ADAFLAGS)
 120 ])dnl
 121 dnl ---------------------------------------------------------------------------
 122 dnl CF_ADD_CFLAGS version: 10 updated: 2010/05/26 05:38:42
 123 dnl -------------
 124 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 125 dnl The second parameter if given makes this macro verbose.
 126 dnl
 127 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 128 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 129 dnl confused by the quotes (which require backslashes to keep them usable).
 130 AC_DEFUN([CF_ADD_CFLAGS],
 131 [
 132 cf_fix_cppflags=no
 133 cf_new_cflags=
 134 cf_new_cppflags=
 135 cf_new_extra_cppflags=
 136
 137 for cf_add_cflags in $1
 138 do
 139 case $cf_fix_cppflags in
 140 no)
 141         case $cf_add_cflags in #(vi
 142         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
 143                 case $cf_add_cflags in
 144                 -D*)
 145                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 146
 147                         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 148                                 && test -z "${cf_tst_cflags}" \
 149                                 && cf_fix_cppflags=yes
 150
 151                         if test $cf_fix_cppflags = yes ; then
 152                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 153                                 continue
 154                         elif test "${cf_tst_cflags}" = "\"'" ; then
 155                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 156                                 continue
 157                         fi
 158                         ;;
 159                 esac
 160                 case "$CPPFLAGS" in
 161                 *$cf_add_cflags) #(vi
 162                         ;;
 163                 *) #(vi
 164                         case $cf_add_cflags in #(vi
 165                         -D*)
 166                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 167                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 168                                 ;;
 169                         esac
 170                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 171                         ;;
 172                 esac
 173                 ;;
 174         *)
 175                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 176                 ;;
 177         esac
 178         ;;
 179 yes)
 180         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 181
 182         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 183
 184         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 185                 && test -z "${cf_tst_cflags}" \
 186                 && cf_fix_cppflags=no
 187         ;;
 188 esac
 189 done
 190
 191 if test -n "$cf_new_cflags" ; then
 192         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 193         CFLAGS="$CFLAGS $cf_new_cflags"
 194 fi
 195
 196 if test -n "$cf_new_cppflags" ; then
 197         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 198         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 199 fi
 200
 201 if test -n "$cf_new_extra_cppflags" ; then
 202         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 203         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 204 fi
 205
 206 AC_SUBST(EXTRA_CPPFLAGS)
 207
 208 ])dnl
 209 dnl ---------------------------------------------------------------------------
 210 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
 211 dnl -------------
 212 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 213 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 214 dnl but old versions (and some misinstalled ones) need that.  To make things
 215 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 216 dnl the include-path).
 217 AC_DEFUN([CF_ADD_INCDIR],
 218 [
 219 if test -n "$1" ; then
 220   for cf_add_incdir in $1
 221   do
 222         while test $cf_add_incdir != /usr/include
 223         do
 224           if test -d $cf_add_incdir
 225           then
 226                 cf_have_incdir=no
 227                 if test -n "$CFLAGS$CPPFLAGS" ; then
 228                   # a loop is needed to ensure we can add subdirs of existing dirs
 229                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 230                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 231                           cf_have_incdir=yes; break
 232                         fi
 233                   done
 234                 fi
 235
 236                 if test "$cf_have_incdir" = no ; then
 237                   if test "$cf_add_incdir" = /usr/local/include ; then
 238                         if test "$GCC" = yes
 239                         then
 240                           cf_save_CPPFLAGS=$CPPFLAGS
 241                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 242                           AC_TRY_COMPILE([#include <stdio.h>],
 243                                   [printf("Hello")],
 244                                   [],
 245                                   [cf_have_incdir=yes])
 246                           CPPFLAGS=$cf_save_CPPFLAGS
 247                         fi
 248                   fi
 249                 fi
 250
 251                 if test "$cf_have_incdir" = no ; then
 252                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 253                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 254
 255                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 256                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 257                   cf_add_incdir="$cf_top_incdir"
 258                 else
 259                   break
 260                 fi
 261           fi
 262         done
 263   done
 264 fi
 265 ])dnl
 266 dnl ---------------------------------------------------------------------------
 267 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 268 dnl ----------
 269 dnl Add a library, used to enforce consistency.
 270 dnl
 271 dnl $1 = library to add, without the "-l"
 272 dnl $2 = variable to update (default $LIBS)
 273 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 274 dnl ---------------------------------------------------------------------------
 275 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
 276 dnl -------------
 277 dnl     Adds to the library-path
 278 dnl
 279 dnl     Some machines have trouble with multiple -L options.
 280 dnl
 281 dnl $1 is the (list of) directory(s) to add
 282 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 283 dnl
 284 AC_DEFUN([CF_ADD_LIBDIR],
 285 [
 286 if test -n "$1" ; then
 287   for cf_add_libdir in $1
 288   do
 289     if test $cf_add_libdir = /usr/lib ; then
 290       :
 291     elif test -d $cf_add_libdir
 292     then
 293       cf_have_libdir=no
 294       if test -n "$LDFLAGS$LIBS" ; then
 295         # a loop is needed to ensure we can add subdirs of existing dirs
 296         for cf_test_libdir in $LDFLAGS $LIBS ; do
 297           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 298             cf_have_libdir=yes; break
 299           fi
 300         done
 301       fi
 302       if test "$cf_have_libdir" = no ; then
 303         CF_VERBOSE(adding $cf_add_libdir to library-path)
 304         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 305       fi
 306     fi
 307   done
 308 fi
 309 ])dnl
 310 dnl ---------------------------------------------------------------------------
 311 dnl CF_ADD_LIBS version: 1 updated: 2010/06/02 05:03:05
 312 dnl -----------
 313 dnl Add one or more libraries, used to enforce consistency.
 314 dnl
 315 dnl $1 = libraries to add, with the "-l", etc.
 316 dnl $2 = variable to update (default $LIBS)
 317 AC_DEFUN([CF_ADD_LIBS],[ifelse($2,,LIBS,[$2])="$1 [$]ifelse($2,,LIBS,[$2])"])dnl
 318 dnl ---------------------------------------------------------------------------
 319 dnl CF_ADD_SUBDIR_PATH version: 3 updated: 2010/07/03 20:58:12
 320 dnl ------------------
 321 dnl Append to a search-list for a nonstandard header/lib-file
 322 dnl     $1 = the variable to return as result
 323 dnl     $2 = the package name
 324 dnl     $3 = the subdirectory, e.g., bin, include or lib
 325 dnl $4 = the directory under which we will test for subdirectories
 326 dnl $5 = a directory that we do not want $4 to match
 327 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 328 [
 329 test "$4" != "$5" && \
 330 test -d "$4" && \
 331 ifelse([$5],NONE,,[(test $5 = NONE || test "$4" != "$5") &&]) {
 332         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 333         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 334         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 335         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 336         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 337         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 338 }
 339 ])dnl
 340 dnl ---------------------------------------------------------------------------
 341 dnl CF_ANSI_CC_CHECK version: 11 updated: 2011/07/01 19:47:45
 342 dnl ----------------
 343 dnl This was originally adapted from the macros 'fp_PROG_CC_STDC' and
 344 dnl 'fp_C_PROTOTYPES' in the sharutils 4.2 distribution.
 345 AC_DEFUN([CF_ANSI_CC_CHECK],
 346 [
 347 # This should have been defined by AC_PROG_CC
 348 : ${CC:=cc}
 349
 350 # Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 351 # into CC.  This will not help with broken scripts that wrap the compiler with
 352 # options, but eliminates a more common category of user confusion.
 353 AC_MSG_CHECKING(\$CC variable)
 354 case "$CC" in #(vi
 355 *[[\ \  ]]-[[IUD]]*)
 356         AC_MSG_RESULT(broken)
 357         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 358         # humor him...
 359         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
 360         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
 361         CF_ADD_CFLAGS($cf_flags)
 362         ;;
 363 *)
 364         AC_MSG_RESULT(ok)
 365         ;;
 366 esac
 367
 368 AC_CACHE_CHECK(for ${CC:-cc} option to accept ANSI C, cf_cv_ansi_cc,[
 369 cf_cv_ansi_cc=no
 370 cf_save_CFLAGS="$CFLAGS"
 371 cf_save_CPPFLAGS="$CPPFLAGS"
 372 # Don't try gcc -ansi; that turns off useful extensions and
 373 # breaks some systems' header files.
 374 # AIX                   -qlanglvl=ansi
 375 # Ultrix and OSF/1      -std1
 376 # HP-UX                 -Aa -D_HPUX_SOURCE
 377 # SVR4                  -Xc
 378 # UnixWare 1.2          (cannot use -Xc, since ANSI/POSIX clashes)
 379 for cf_arg in "-DCC_HAS_PROTOS" \
 380         "" \
 381         -qlanglvl=ansi \
 382         -std1 \
 383         -Ae \
 384         "-Aa -D_HPUX_SOURCE" \
 385         -Xc
 386 do
 387         CF_ADD_CFLAGS($cf_arg)
 388         AC_TRY_COMPILE(
 389 [
 390 #ifndef CC_HAS_PROTOS
 391 #if !defined(__STDC__) || (__STDC__ != 1)
 392 choke me
 393 #endif
 394 #endif
 395 ],[
 396         int test (int i, double x);
 397         struct s1 {int (*f) (int a);};
 398         struct s2 {int (*f) (double a);};],
 399         [cf_cv_ansi_cc="$cf_arg"; break])
 400 done
 401 CFLAGS="$cf_save_CFLAGS"
 402 CPPFLAGS="$cf_save_CPPFLAGS"
 403 ])
 404
 405 if test "$cf_cv_ansi_cc" != "no"; then
 406 if test ".$cf_cv_ansi_cc" != ".-DCC_HAS_PROTOS"; then
 407         CF_ADD_CFLAGS($cf_cv_ansi_cc)
 408 else
 409         AC_DEFINE(CC_HAS_PROTOS)
 410 fi
 411 fi
 412 ])dnl
 413 dnl ---------------------------------------------------------------------------
 414 dnl CF_ANSI_CC_REQD version: 4 updated: 2008/03/23 14:48:54
 415 dnl ---------------
 416 dnl For programs that must use an ANSI compiler, obtain compiler options that
 417 dnl will make it recognize prototypes.  We'll do preprocessor checks in other
 418 dnl macros, since tools such as unproto can fake prototypes, but only part of
 419 dnl the preprocessor.
 420 AC_DEFUN([CF_ANSI_CC_REQD],
 421 [AC_REQUIRE([CF_ANSI_CC_CHECK])
 422 if test "$cf_cv_ansi_cc" = "no"; then
 423         AC_MSG_ERROR(
 424 [Your compiler does not appear to recognize prototypes.
 425 You have the following choices:
 426         a. adjust your compiler options
 427         b. get an up-to-date compiler
 428         c. use a wrapper such as unproto])
 429 fi
 430 ])dnl
 431 dnl ---------------------------------------------------------------------------
 432 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 433 dnl --------------
 434 dnl Allow user to disable a normally-on option.
 435 AC_DEFUN([CF_ARG_DISABLE],
 436 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 437 dnl ---------------------------------------------------------------------------
 438 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
 439 dnl -------------
 440 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 441 dnl values.
 442 dnl
 443 dnl Parameters:
 444 dnl $1 = option name
 445 dnl $2 = help-string
 446 dnl $3 = action to perform if option is not default
 447 dnl $4 = action if perform if option is default
 448 dnl $5 = default option value (either 'yes' or 'no')
 449 AC_DEFUN([CF_ARG_OPTION],
 450 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 451   if test "$enableval" != "$5" ; then
 452 ifelse([$3],,[    :]dnl
 453 ,[    $3]) ifelse([$4],,,[
 454   else
 455     $4])
 456   fi],[enableval=$5 ifelse([$4],,,[
 457   $4
 458 ])dnl
 459   ])])dnl
 460 dnl ---------------------------------------------------------------------------
 461 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
 462 dnl -----------
 463 dnl Check for suitable "ar" (archiver) options for updating an archive.
 464 AC_DEFUN([CF_AR_FLAGS],[
 465 AC_REQUIRE([CF_PROG_AR])
 466
 467 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 468         cf_cv_ar_flags=unknown
 469         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
 470         do
 471
 472                 # check if $ARFLAGS already contains this choice
 473                 if test "x$ARFLAGS" != "x" ; then
 474                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 475                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 476                                 cf_cv_ar_flags=
 477                                 break
 478                         fi
 479                 fi
 480
 481                 rm -f conftest.$ac_cv_objext
 482                 rm -f conftest.a
 483
 484                 cat >conftest.$ac_ext <<EOF
 485 #line __oline__ "configure"
 486 int     testdata[[3]] = { 123, 456, 789 };
 487 EOF
 488                 if AC_TRY_EVAL(ac_compile) ; then
 489                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 490                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 491                         if test -f conftest.a ; then
 492                                 cf_cv_ar_flags=$cf_ar_flags
 493                                 break
 494                         fi
 495                 else
 496                         CF_VERBOSE(cannot compile test-program)
 497                         break
 498                 fi
 499         done
 500         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 501 ])
 502
 503 if test -n "$ARFLAGS" ; then
 504         if test -n "$cf_cv_ar_flags" ; then
 505                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 506         fi
 507 else
 508         ARFLAGS=$cf_cv_ar_flags
 509 fi
 510
 511 AC_SUBST(ARFLAGS)
 512 ])
 513 dnl ---------------------------------------------------------------------------
 514 dnl CF_AWK_BIG_PRINTF version: 4 updated: 2011/10/30 17:09:50
 515 dnl -----------------
 516 dnl Check if awk can handle big strings using printf.  Some older versions of
 517 dnl awk choke on large strings passed via "%s".
 518 dnl
 519 dnl $1 = desired string size
 520 dnl $2 = variable to set with result
 521 AC_DEFUN([CF_AWK_BIG_PRINTF],
 522 [
 523         case x$AWK in #(vi
 524         x)
 525                 eval $2=no
 526                 ;;
 527         *) #(vi
 528                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 529                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 530                         eval $2=yes
 531                 else
 532                         eval $2=no
 533                 fi
 534                 ;;
 535         esac
 536 ])dnl
 537 dnl ---------------------------------------------------------------------------
 538 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 539 dnl ------------
 540 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 541 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 542 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 543 dnl
 544 dnl Treat the configuration-variable specially here, since we're directly
 545 dnl substituting its value (i.e., 1/0).
 546 dnl
 547 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 548 AC_DEFUN([CF_BOOL_DECL],
 549 [
 550 AC_MSG_CHECKING(if we should include stdbool.h)
 551
 552 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 553         AC_TRY_COMPILE([],[bool foo = false],
 554                 [cf_cv_header_stdbool_h=0],
 555                 [AC_TRY_COMPILE([
 556 #ifndef __BEOS__
 557 #include <stdbool.h>
 558 #endif
 559 ],[bool foo = false],
 560                         [cf_cv_header_stdbool_h=1],
 561                         [cf_cv_header_stdbool_h=0])])])
 562
 563 if test "$cf_cv_header_stdbool_h" = 1
 564 then    AC_MSG_RESULT(yes)
 565 else    AC_MSG_RESULT(no)
 566 fi
 567
 568 AC_MSG_CHECKING([for builtin bool type])
 569
 570 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 571         AC_TRY_COMPILE([
 572 #include <stdio.h>
 573 #include <sys/types.h>
 574 ],[bool x = false],
 575                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 576                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 577         ])
 578
 579 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 580 then    AC_MSG_RESULT(yes)
 581 else    AC_MSG_RESULT(no)
 582 fi
 583 ])dnl
 584 dnl ---------------------------------------------------------------------------
 585 dnl CF_BOOL_SIZE version: 12 updated: 2006/12/16 12:33:30
 586 dnl ------------
 587 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 588 dnl Don't bother looking for bool.h, since it's been deprecated.
 589 dnl
 590 dnl If the current compiler is C rather than C++, we get the bool definition
 591 dnl from <stdbool.h>.
 592 AC_DEFUN([CF_BOOL_SIZE],
 593 [
 594 AC_MSG_CHECKING([for size of bool])
 595 AC_CACHE_VAL(cf_cv_type_of_bool,[
 596         rm -f cf_test.out
 597         AC_TRY_RUN([
 598 #include <stdlib.h>
 599 #include <stdio.h>
 600
 601 #if defined(__cplusplus)
 602
 603 #ifdef HAVE_GXX_BUILTIN_H
 604 #include <g++/builtin.h>
 605 #elif HAVE_GPP_BUILTIN_H
 606 #include <gpp/builtin.h>
 607 #elif HAVE_BUILTIN_H
 608 #include <builtin.h>
 609 #endif
 610
 611 #else
 612
 613 #if $cf_cv_header_stdbool_h
 614 #include <stdbool.h>
 615 #endif
 616
 617 #endif
 618
 619 main()
 620 {
 621         FILE *fp = fopen("cf_test.out", "w");
 622         if (fp != 0) {
 623                 bool x = true;
 624                 if ((bool)(-x) >= 0)
 625                         fputs("unsigned ", fp);
 626                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 627                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 628                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 629                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 630                 fclose(fp);
 631         }
 632         ${cf_cv_main_return:-return}(0);
 633 }
 634                 ],
 635                 [cf_cv_type_of_bool=`cat cf_test.out`
 636                  if test -z "$cf_cv_type_of_bool"; then
 637                    cf_cv_type_of_bool=unknown
 638                  fi],
 639                 [cf_cv_type_of_bool=unknown],
 640                 [cf_cv_type_of_bool=unknown])
 641         ])
 642         rm -f cf_test.out
 643 AC_MSG_RESULT($cf_cv_type_of_bool)
 644 if test "$cf_cv_type_of_bool" = unknown ; then
 645         case .$NCURSES_BOOL in #(vi
 646         .auto|.) NCURSES_BOOL=unsigned;;
 647         esac
 648         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 649         cf_cv_type_of_bool=$NCURSES_BOOL
 650 fi
 651 ])dnl
 652 dnl ---------------------------------------------------------------------------
 653 dnl CF_BUILD_CC version: 6 updated: 2006/10/14 15:23:15
 654 dnl -----------
 655 dnl If we're cross-compiling, allow the user to override the tools and their
 656 dnl options.  The configure script is oriented toward identifying the host
 657 dnl compiler, etc., but we need a build compiler to generate parts of the
 658 dnl source.
 659 dnl
 660 dnl $1 = default for $CPPFLAGS
 661 dnl $2 = default for $LIBS
 662 AC_DEFUN([CF_BUILD_CC],[
 663 AC_REQUIRE([CF_PROG_EXT])
 664 if test "$cross_compiling" = yes ; then
 665
 666         # defaults that we might want to override
 667         : ${BUILD_CFLAGS:=''}
 668         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 669         : ${BUILD_LDFLAGS:=''}
 670         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 671         : ${BUILD_EXEEXT:='$x'}
 672         : ${BUILD_OBJEXT:='o'}
 673
 674         AC_ARG_WITH(build-cc,
 675                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 676                 [BUILD_CC="$withval"],
 677                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 678         AC_MSG_CHECKING(for native build C compiler)
 679         AC_MSG_RESULT($BUILD_CC)
 680
 681         AC_MSG_CHECKING(for native build C preprocessor)
 682         AC_ARG_WITH(build-cpp,
 683                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 684                 [BUILD_CPP="$withval"],
 685                 [BUILD_CPP='${BUILD_CC} -E'])
 686         AC_MSG_RESULT($BUILD_CPP)
 687
 688         AC_MSG_CHECKING(for native build C flags)
 689         AC_ARG_WITH(build-cflags,
 690                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 691                 [BUILD_CFLAGS="$withval"])
 692         AC_MSG_RESULT($BUILD_CFLAGS)
 693
 694         AC_MSG_CHECKING(for native build C preprocessor-flags)
 695         AC_ARG_WITH(build-cppflags,
 696                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 697                 [BUILD_CPPFLAGS="$withval"])
 698         AC_MSG_RESULT($BUILD_CPPFLAGS)
 699
 700         AC_MSG_CHECKING(for native build linker-flags)
 701         AC_ARG_WITH(build-ldflags,
 702                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 703                 [BUILD_LDFLAGS="$withval"])
 704         AC_MSG_RESULT($BUILD_LDFLAGS)
 705
 706         AC_MSG_CHECKING(for native build linker-libraries)
 707         AC_ARG_WITH(build-libs,
 708                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 709                 [BUILD_LIBS="$withval"])
 710         AC_MSG_RESULT($BUILD_LIBS)
 711
 712         # this assumes we're on Unix.
 713         BUILD_EXEEXT=
 714         BUILD_OBJEXT=o
 715
 716         : ${BUILD_CC:='${CC}'}
 717
 718         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 719                 AC_MSG_ERROR([Cross-build requires two compilers.
 720 Use --with-build-cc to specify the native compiler.])
 721         fi
 722
 723 else
 724         : ${BUILD_CC:='${CC}'}
 725         : ${BUILD_CPP:='${CPP}'}
 726         : ${BUILD_CFLAGS:='${CFLAGS}'}
 727         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 728         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 729         : ${BUILD_LIBS:='${LIBS}'}
 730         : ${BUILD_EXEEXT:='$x'}
 731         : ${BUILD_OBJEXT:='o'}
 732 fi
 733
 734 AC_SUBST(BUILD_CC)
 735 AC_SUBST(BUILD_CPP)
 736 AC_SUBST(BUILD_CFLAGS)
 737 AC_SUBST(BUILD_CPPFLAGS)
 738 AC_SUBST(BUILD_LDFLAGS)
 739 AC_SUBST(BUILD_LIBS)
 740 AC_SUBST(BUILD_EXEEXT)
 741 AC_SUBST(BUILD_OBJEXT)
 742 ])dnl
 743 dnl ---------------------------------------------------------------------------
 744 dnl CF_CFG_DEFAULTS version: 8 updated: 2011/06/04 20:09:13
 745 dnl ---------------
 746 dnl Determine the default configuration into which we'll install ncurses.  This
 747 dnl can be overridden by the user's command-line options.  There's two items to
 748 dnl look for:
 749 dnl     1. the prefix (e.g., /usr)
 750 dnl     2. the header files (e.g., /usr/include/ncurses)
 751 dnl We'll look for a previous installation of ncurses and use the same defaults.
 752 dnl
 753 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 754 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 755 dnl programs from a vendor's.
 756 AC_DEFUN([CF_CFG_DEFAULTS],
 757 [
 758 AC_MSG_CHECKING(for prefix)
 759 if test "x$prefix" = "xNONE" ; then
 760         case "$cf_cv_system_name" in
 761                 # non-vendor systems don't have a conflict
 762         openbsd*|freebsd*|mirbsd*|linux*|cygwin*|k*bsd*-gnu)
 763                 prefix=/usr
 764                 ;;
 765         *)      prefix=$ac_default_prefix
 766                 ;;
 767         esac
 768 fi
 769 AC_MSG_RESULT($prefix)
 770
 771 if test "x$prefix" = "xNONE" ; then
 772 AC_MSG_CHECKING(for default include-directory)
 773 test -n "$verbose" && echo 1>&AC_FD_MSG
 774 for cf_symbol in \
 775         $includedir \
 776         $includedir/ncurses \
 777         $prefix/include \
 778         $prefix/include/ncurses \
 779         /usr/local/include \
 780         /usr/local/include/ncurses \
 781         /usr/include \
 782         /usr/include/ncurses
 783 do
 784         cf_dir=`eval echo $cf_symbol`
 785         if test -f $cf_dir/curses.h ; then
 786         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 787                 includedir="$cf_symbol"
 788                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 789                 break
 790         fi
 791         fi
 792         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 793 done
 794 AC_MSG_RESULT($includedir)
 795 fi
 796 ])dnl
 797 dnl ---------------------------------------------------------------------------
 798 dnl CF_CGETENT version: 4 updated: 2011/08/07 14:54:41
 799 dnl ----------
 800 dnl Check if the terminal-capability database functions are available.  If not,
 801 dnl ncurses has a much-reduced version.
 802 AC_DEFUN([CF_CGETENT],[
 803 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 804 AC_TRY_LINK([
 805 #include <stdlib.h>],[
 806         char temp[128];
 807         char *buf = temp;
 808         char *db_array = temp;
 809         cgetent(&buf, &db_array, "vt100");
 810         cgetcap(buf, "tc", '=');
 811         cgetmatch(buf, "tc");
 812         ],
 813         [cf_cv_cgetent=yes],
 814         [cf_cv_cgetent=no])
 815 ])
 816
 817 if test "$cf_cv_cgetent" = yes
 818 then
 819         AC_DEFINE(HAVE_BSD_CGETENT)
 820 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 821 AC_TRY_LINK([
 822 #include <stdlib.h>],[
 823         char temp[128];
 824         char *buf = temp;
 825 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 826         const char *db_array = temp;
 827         cgetent(&buf, &db_array, "vt100");
 828 #endif
 829         cgetcap(buf, "tc", '=');
 830         cgetmatch(buf, "tc");
 831         ],
 832         [cf_cv_cgetent_const=yes],
 833         [cf_cv_cgetent_const=no])
 834 ])
 835         if test "$cf_cv_cgetent_const" = yes
 836         then
 837                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const)
 838         fi
 839 fi
 840 ])dnl
 841 dnl ---------------------------------------------------------------------------
 842 dnl CF_CHECK_CACHE version: 11 updated: 2008/03/23 14:45:59
 843 dnl --------------
 844 dnl Check if we're accidentally using a cache from a different machine.
 845 dnl Derive the system name, as a check for reusing the autoconf cache.
 846 dnl
 847 dnl If we've packaged config.guess and config.sub, run that (since it does a
 848 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 849 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 850 dnl which is useful in cross-compiles.
 851 dnl
 852 dnl Note: we would use $ac_config_sub, but that is one of the places where
 853 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 854 AC_DEFUN([CF_CHECK_CACHE],
 855 [
 856 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 857         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 858         system_name="$host_os"
 859 else
 860         system_name="`(uname -s -r) 2>/dev/null`"
 861         if test -z "$system_name" ; then
 862                 system_name="`(hostname) 2>/dev/null`"
 863         fi
 864 fi
 865 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name")
 866 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 867
 868 test -z "$system_name" && system_name="$cf_cv_system_name"
 869 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 870
 871 if test ".$system_name" != ".$cf_cv_system_name" ; then
 872         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 873         AC_MSG_ERROR("Please remove config.cache and try again.")
 874 fi
 875 ])dnl
 876 dnl ---------------------------------------------------------------------------
 877 dnl CF_CHECK_ERRNO version: 11 updated: 2010/05/26 05:38:42
 878 dnl --------------
 879 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 880 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 881 dnl ourselves.
 882 dnl
 883 dnl $1 = the name to check
 884 dnl $2 = the assumed type
 885 AC_DEFUN([CF_CHECK_ERRNO],
 886 [
 887 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 888     AC_TRY_COMPILE([
 889 #ifdef HAVE_STDLIB_H
 890 #include <stdlib.h>
 891 #endif
 892 #include <stdio.h>
 893 #include <sys/types.h>
 894 #include <errno.h> ],
 895     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 896     [cf_cv_dcl_$1=yes],
 897     [cf_cv_dcl_$1=no])
 898 ])
 899
 900 if test "$cf_cv_dcl_$1" = no ; then
 901     CF_UPPER(cf_result,decl_$1)
 902     AC_DEFINE_UNQUOTED($cf_result)
 903 fi
 904
 905 # It's possible (for near-UNIX clones) that the data doesn't exist
 906 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 907 ])dnl
 908 dnl ---------------------------------------------------------------------------
 909 dnl CF_CHECK_EXTERN_DATA version: 3 updated: 2001/12/30 18:03:23
 910 dnl --------------------
 911 dnl Check for existence of external data in the current set of libraries.  If
 912 dnl we can modify it, it's real enough.
 913 dnl $1 = the name to check
 914 dnl $2 = its type
 915 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 916 [
 917 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 918     AC_TRY_LINK([
 919 #undef $1
 920 extern $2 $1;
 921 ],
 922     [$1 = 2],
 923     [cf_cv_have_$1=yes],
 924     [cf_cv_have_$1=no])
 925 ])
 926
 927 if test "$cf_cv_have_$1" = yes ; then
 928     CF_UPPER(cf_result,have_$1)
 929     AC_DEFINE_UNQUOTED($cf_result)
 930 fi
 931
 932 ])dnl
 933 dnl ---------------------------------------------------------------------------
 934 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
 935 dnl -------------------
 936 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 937 dnl is not "weak" - warn about this because it can create problems linking
 938 dnl applications with ncurses.
 939 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 940 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 941
 942 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 943 cf_cv_check_gpm_wgetch=unknown
 944 if test "$cross_compiling" != yes ; then
 945
 946 cat >conftest.$ac_ext <<CF_EOF
 947 #include <gpm.h>
 948 int main()
 949 {
 950         Gpm_Wgetch();
 951         ${cf_cv_main_return:-return}(0);
 952 }
 953 CF_EOF
 954
 955         cf_save_LIBS="$LIBS"
 956         # This only works if we can look at the symbol table.  If a shared
 957         # library is stripped for install, we cannot use that.  So we're forced
 958         # to rely on the static library, noting that some packagers may not
 959         # include it.
 960         LIBS="-static -lgpm -dynamic $LIBS"
 961         if AC_TRY_EVAL(ac_compile) ; then
 962                 if AC_TRY_EVAL(ac_link) ; then
 963                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
 964                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
 965                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
 966                 fi
 967         fi
 968         rm -rf conftest*
 969         LIBS="$cf_save_LIBS"
 970 fi
 971 ])
 972
 973 if test "$cf_cv_check_gpm_wgetch" != yes ; then
 974         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 975 fi
 976 ])])dnl
 977 dnl ---------------------------------------------------------------------------
 978 dnl CF_CHECK_WCHAR_H version: 1 updated: 2011/10/29 15:01:05
 979 dnl ----------------
 980 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
 981 AC_DEFUN([CF_CHECK_WCHAR_H],[
 982 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
 983 AC_TRY_COMPILE(
 984 [
 985 #include <stdlib.h>
 986 #include <wchar.h>
 987 ],[
 988         wint_t foo = 0;
 989         int bar = iswpunct(foo)],
 990         [cf_cv_wchar_h_okay=yes],
 991         [cf_cv_wchar_h_okay=no])])
 992
 993 if test $cf_cv_wchar_h_okay = no
 994 then
 995         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 996 fi
 997 ])dnl
 998 dnl ---------------------------------------------------------------------------
 999 dnl CF_CPP_PARAM_INIT version: 5 updated: 2011/12/03 16:54:03
1000 dnl -----------------
1001 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1002 dnl is a late feature for the standard and is not in some recent compilers
1003 dnl (1999/9/11).
1004 AC_DEFUN([CF_CPP_PARAM_INIT],
1005 [
1006 if test -n "$CXX"; then
1007 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1008         AC_LANG_SAVE
1009         AC_LANG_CPLUSPLUS
1010         AC_TRY_RUN([
1011 class TEST {
1012 private:
1013         int value;
1014 public:
1015         TEST(int x = 1);
1016         ~TEST();
1017 };
1018
1019 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1020 {
1021         value = x;
1022 }
1023 int main() { }
1024 ],
1025         [cf_cv_cpp_param_init=yes],
1026         [cf_cv_cpp_param_init=no],
1027         [cf_cv_cpp_param_init=unknown])
1028         AC_LANG_RESTORE
1029 ])
1030 fi
1031 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT)
1032 ])dnl
1033 dnl ---------------------------------------------------------------------------
1034 dnl CF_CPP_STATIC_CAST version: 1 updated: 2005/07/23 16:52:43
1035 dnl ------------------
1036 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1037 dnl not be supported in g++ before 3.0
1038 AC_DEFUN([CF_CPP_STATIC_CAST],
1039 [
1040 if test -n "$CXX"; then
1041
1042 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1043         AC_LANG_SAVE
1044         AC_LANG_CPLUSPLUS
1045
1046         AC_TRY_COMPILE([
1047 class NCursesPanel
1048 {
1049 public:
1050   NCursesPanel(int nlines,
1051                int ncols,
1052                int begin_y = 0,
1053                int begin_x = 0)
1054   {
1055   }
1056
1057   ~NCursesPanel();
1058 };
1059
1060 template<class T> class NCursesUserPanel : public NCursesPanel
1061 {
1062 public:
1063   NCursesUserPanel (int nlines,
1064                     int ncols,
1065                     int begin_y = 0,
1066                     int begin_x = 0,
1067                     const T* p_UserData = static_cast<T*>(0))
1068     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1069   {
1070   };
1071   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1072   {
1073   };
1074
1075   virtual ~NCursesUserPanel() {};
1076 };
1077 ],[
1078         const char* p_UserData = static_cast<char*>(0)],
1079         [cf_cv_cpp_static_cast=yes],
1080         [cf_cv_cpp_static_cast=no])
1081
1082         AC_LANG_RESTORE
1083 ])
1084
1085 fi
1086
1087 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST)
1088 ])dnl
1089 dnl ---------------------------------------------------------------------------
1090 dnl CF_CXX_AR_FLAGS version: 1 updated: 2011/10/29 08:35:34
1091 dnl ---------------
1092 dnl Setup special archiver flags for given compilers.
1093 AC_DEFUN([CF_CXX_AR_FLAGS],[
1094         CXX_AR='$(AR)'
1095         CXX_ARFLAGS='$(ARFLAGS)'
1096         case $cf_cv_system_name in #(vi
1097         irix*) #(vi
1098             if test "$GXX" != yes ; then
1099                 CXX_AR='$(CXX)'
1100                 CXX_ARFLAGS='-ar -o'
1101             fi
1102             ;;
1103         sco3.2v5*) #(vi
1104             CXXLDFLAGS="-u main"
1105             ;;
1106         solaris2*)
1107             if test "$GXX" != yes ; then
1108                 CXX_AR='$(CXX)'
1109                 CXX_ARFLAGS='-xar -o'
1110             fi
1111             ;;
1112         esac
1113         AC_SUBST(CXXLDFLAGS)
1114         AC_SUBST(CXX_AR)
1115         AC_SUBST(CXX_ARFLAGS)
1116 ])dnl
1117 dnl ---------------------------------------------------------------------------
1118 dnl CF_CXX_IOSTREAM_NAMESPACE version: 1 updated: 2011/10/29 08:35:34
1119 dnl -------------------------
1120 dnl For c++, check if iostream uses "std::" namespace.
1121 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1122 AC_CHECK_HEADERS(iostream)
1123 if test x"$ac_cv_header_iostream" = xyes ; then
1124         AC_MSG_CHECKING(if iostream uses std-namespace)
1125         AC_TRY_COMPILE([
1126 #include <iostream>
1127 using std::endl;
1128 using std::cerr;],[
1129 cerr << "testing" << endl;
1130 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1131         AC_MSG_RESULT($cf_iostream_namespace)
1132         if test "$cf_iostream_namespace" = yes ; then
1133                 AC_DEFINE(IOSTREAM_NAMESPACE)
1134         fi
1135 fi
1136 ])dnl
1137 dnl ---------------------------------------------------------------------------
1138 dnl CF_C_INLINE version: 3 updated: 2010/05/01 15:14:41
1139 dnl -----------
1140 dnl Check if the C compiler supports "inline".
1141 dnl $1 is the name of a shell variable to set if inline is supported
1142 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1143 AC_DEFUN([CF_C_INLINE],[
1144 AC_C_INLINE
1145 $1=
1146 if test "$ac_cv_c_inline" != no ; then
1147   $1=inline
1148   if test "$INTEL_COMPILER" = yes
1149   then
1150     :
1151   elif test "$GCC" = yes
1152   then
1153     AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1154       cf_save_CFLAGS=$CFLAGS
1155       CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1156       AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1157       [${cf_cv_main_return:-return} foo()],
1158       [cf_cv_gcc_inline=yes],
1159       [cf_cv_gcc_inline=no])
1160       CFLAGS=$cf_save_CFLAGS
1161     ])
1162     if test "$cf_cv_gcc_inline" = yes ; then
1163         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1164     fi
1165   fi
1166 fi
1167 AC_SUBST($1)
1168 ])dnl
1169 dnl ---------------------------------------------------------------------------
1170 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1171 dnl ----------
1172 dnl "dirname" is not portable, so we fake it with a shell script.
1173 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1174 dnl ---------------------------------------------------------------------------
1175 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1176 dnl ---------------
1177 AC_DEFUN([CF_DIRS_TO_MAKE],
1178 [
1179 DIRS_TO_MAKE="lib"
1180 for cf_item in $cf_list_models
1181 do
1182         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1183         for cf_item2 in $DIRS_TO_MAKE
1184         do
1185                 test $cf_item2 = $cf_subdir && break
1186         done
1187         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1188 done
1189 for cf_dir in $DIRS_TO_MAKE
1190 do
1191         test ! -d $cf_dir && mkdir $cf_dir
1192 done
1193 AC_SUBST(DIRS_TO_MAKE)
1194 ])dnl
1195 dnl ---------------------------------------------------------------------------
1196 dnl CF_DISABLE_ECHO version: 11 updated: 2009/12/13 13:16:57
1197 dnl ---------------
1198 dnl You can always use "make -n" to see the actual options, but it's hard to
1199 dnl pick out/analyze warning messages when the compile-line is long.
1200 dnl
1201 dnl Sets:
1202 dnl     ECHO_LT - symbol to control if libtool is verbose
1203 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1204 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1205 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1206 dnl     ECHO_CC - symbol to put before any "cc" line
1207 dnl
1208 AC_DEFUN([CF_DISABLE_ECHO],[
1209 AC_MSG_CHECKING(if you want to see long compiling messages)
1210 CF_ARG_DISABLE(echo,
1211         [  --disable-echo          display "compiling" commands],
1212         [
1213     ECHO_LT='--silent'
1214     ECHO_LD='@echo linking [$]@;'
1215     RULE_CC='@echo compiling [$]<'
1216     SHOW_CC='@echo compiling [$]@'
1217     ECHO_CC='@'
1218 ],[
1219     ECHO_LT=''
1220     ECHO_LD=''
1221     RULE_CC=''
1222     SHOW_CC=''
1223     ECHO_CC=''
1224 ])
1225 AC_MSG_RESULT($enableval)
1226 AC_SUBST(ECHO_LT)
1227 AC_SUBST(ECHO_LD)
1228 AC_SUBST(RULE_CC)
1229 AC_SUBST(SHOW_CC)
1230 AC_SUBST(ECHO_CC)
1231 ])dnl
1232 dnl ---------------------------------------------------------------------------
1233 dnl CF_DISABLE_LEAKS version: 6 updated: 2010/07/23 04:14:32
1234 dnl ----------------
1235 dnl Combine no-leak checks with the libraries or tools that are used for the
1236 dnl checks.
1237 AC_DEFUN([CF_DISABLE_LEAKS],[
1238
1239 AC_REQUIRE([CF_WITH_DMALLOC])
1240 AC_REQUIRE([CF_WITH_DBMALLOC])
1241 AC_REQUIRE([CF_WITH_VALGRIND])
1242
1243 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1244 AC_ARG_ENABLE(leaks,
1245         [  --disable-leaks         test: free permanent memory, analyze leaks],
1246         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1247         : ${with_no_leaks:=no})
1248 AC_MSG_RESULT($with_no_leaks)
1249
1250 if test "$with_no_leaks" = yes ; then
1251         AC_DEFINE(NO_LEAKS)
1252         AC_DEFINE(YY_NO_LEAKS)
1253 fi
1254 ])dnl
1255 dnl ---------------------------------------------------------------------------
1256 dnl CF_DISABLE_LIBTOOL_VERSION version: 1 updated: 2010/05/15 15:45:59
1257 dnl --------------------------
1258 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1259 dnl the older "-version-info" feature.  The newer feature allows us to use
1260 dnl version numbering on shared libraries which make them compatible with
1261 dnl various systems.
1262 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1263 [
1264 AC_MSG_CHECKING(if libtool -version-number should be used)
1265 CF_ARG_DISABLE(libtool-version,
1266         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1267         [cf_libtool_version=no],
1268         [cf_libtool_version=yes])
1269 AC_MSG_RESULT($cf_libtool_version)
1270
1271 if test "$cf_libtool_version" = yes ; then
1272         LIBTOOL_VERSION="-version-number"
1273 else
1274         LIBTOOL_VERSION="-version-info"
1275 fi
1276
1277 AC_SUBST(LIBTOOL_VERSION)
1278 ])dnl
1279 dnl ---------------------------------------------------------------------------
1280 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1281 dnl ---------------------
1282 dnl The rpath-hack makes it simpler to build programs, particularly with the
1283 dnl *BSD ports which may have essential libraries in unusual places.  But it
1284 dnl can interfere with building an executable for the base system.  Use this
1285 dnl option in that case.
1286 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1287 [
1288 AC_MSG_CHECKING(if rpath-hack should be disabled)
1289 CF_ARG_DISABLE(rpath-hack,
1290         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1291         [cf_disable_rpath_hack=yes],
1292         [cf_disable_rpath_hack=no])
1293 AC_MSG_RESULT($cf_disable_rpath_hack)
1294 if test "$cf_disable_rpath_hack" = no ; then
1295         CF_RPATH_HACK
1296 fi
1297 ])
1298 dnl ---------------------------------------------------------------------------
1299 dnl CF_ENABLE_PC_FILES version: 7 updated: 2011/12/10 18:58:47
1300 dnl ------------------
1301 dnl This is the "--enable-pc-files" option, which is available if there is a
1302 dnl pkg-config configuration on the local machine.
1303 AC_DEFUN([CF_ENABLE_PC_FILES],[
1304 AC_REQUIRE([CF_PKG_CONFIG])
1305 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1306
1307 if test "$PKG_CONFIG" != none ; then
1308         if test -n "$PKG_CONFIG_LIBDIR" && test -d "$PKG_CONFIG_LIBDIR" ; then
1309                 AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1310                 AC_ARG_ENABLE(pc-files,
1311                         [  --enable-pc-files       generate and install .pc files for pkg-config],
1312                         [enable_pc_files=$enableval],
1313                         [enable_pc_files=no])
1314                 AC_MSG_RESULT($enable_pc_files)
1315         elif test -z "$PKG_CONFIG_LIBDIR" || test "$PKG_CONFIG_LIBDIR" != no; then
1316                 enable_pc_files=no
1317                 AC_MSG_WARN(did not find $PKG_CONFIG library)
1318         fi
1319 else
1320         enable_pc_files=no
1321 fi
1322 ])dnl
1323 dnl ---------------------------------------------------------------------------
1324 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1325 dnl ---------------
1326 dnl Check if the rpath option should be used, setting cache variable
1327 dnl cf_cv_enable_rpath if so.
1328 AC_DEFUN([CF_ENABLE_RPATH],
1329 [
1330 AC_MSG_CHECKING(if rpath option should be used)
1331 AC_ARG_ENABLE(rpath,
1332 [  --enable-rpath          use rpath option when generating shared libraries],
1333 [cf_cv_enable_rpath=$enableval],
1334 [cf_cv_enable_rpath=no])
1335 AC_MSG_RESULT($cf_cv_enable_rpath)
1336 ])dnl
1337 dnl ---------------------------------------------------------------------------
1338 dnl CF_ENABLE_STRING_HACKS version: 1 updated: 2012/02/25 06:33:21
1339 dnl ----------------------
1340 dnl On a few platforms, the compiler and/or loader nags with untruthful
1341 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1342 dnl and implying that most uses of the recommended alternatives are correct.
1343 dnl
1344 dnl Factually speaking, no one has actually counted the number of uses of these
1345 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1346 dnl instances are meaningless compared to the hundreds of millions of lines of
1347 dnl existing C code.
1348 dnl
1349 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1350 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1351 dnl standard - but evolved through phases, and older implementations are likely
1352 dnl to yield surprising results, as documented in manpages on various systems.
1353 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1354 [
1355 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1356 AC_ARG_ENABLE(string-hacks,
1357         [  --enable-string-hacks  work around bogus compiler/loader warnings],
1358         [with_string_hacks=$enableval],
1359         [with_string_hacks=no])
1360 AC_MSG_RESULT($with_string_hacks)
1361
1362 if test "x$with_string_hacks" = "xyes"; then
1363         AC_DEFINE(USE_STRING_HACKS)
1364         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1365         AC_CHECK_FUNCS( strlcat strlcpy snprintf )
1366 fi
1367 ])dnl
1368 dnl ---------------------------------------------------------------------------
1369 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1370 dnl --------
1371 dnl Check if 'errno' is declared in <errno.h>
1372 AC_DEFUN([CF_ERRNO],
1373 [
1374 CF_CHECK_ERRNO(errno)
1375 ])dnl
1376 dnl ---------------------------------------------------------------------------
1377 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1378 dnl ---------------
1379 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1380 dnl math.h and builtin.h, only for ncurses
1381 AC_DEFUN([CF_ETIP_DEFINES],
1382 [
1383 AC_MSG_CHECKING(for special defines needed for etip.h)
1384 cf_save_CXXFLAGS="$CXXFLAGS"
1385 cf_result="none"
1386
1387 # etip.h includes ncurses.h which includes ncurses_dll.h
1388 # But ncurses_dll.h is generated - fix here.
1389 test -d include || mkdir include
1390 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1391
1392 for cf_math in "" MATH_H
1393 do
1394 for cf_excp in "" MATH_EXCEPTION
1395 do
1396         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1397         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1398         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1399 AC_TRY_COMPILE([
1400 #include <etip.h.in>
1401 ],[],[
1402         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1403         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1404         cf_result="$cf_math $cf_excp"
1405         break 2
1406 ],[])
1407 done
1408 done
1409 AC_MSG_RESULT($cf_result)
1410 CXXFLAGS="$cf_save_CXXFLAGS"
1411 ])
1412 dnl ---------------------------------------------------------------------------
1413 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
1414 dnl ---------------
1415 dnl Find a library (specifically the linkage used in the code fragment),
1416 dnl searching for it if it is not already in the library path.
1417 dnl See also CF_ADD_SEARCHPATH.
1418 dnl
1419 dnl Parameters (4-on are optional):
1420 dnl     $1 = headers for library entrypoint
1421 dnl     $2 = code fragment for library entrypoint
1422 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1423 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1424 dnl     $5 = action to perform if not successful
1425 dnl     $6 = module name, if not the same as the library name
1426 dnl     $7 = extra libraries
1427 dnl
1428 dnl Sets these variables:
1429 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1430 dnl     $cf_cv_header_path_$3 - include-directory if needed
1431 dnl     $cf_cv_library_path_$3 - library-directory if needed
1432 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1433 AC_DEFUN([CF_FIND_LINKAGE],[
1434
1435 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1436 # will be set on completion of the AC_TRY_LINK below.
1437 cf_cv_header_path_$3=
1438 cf_cv_library_path_$3=
1439
1440 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1441
1442 cf_save_LIBS="$LIBS"
1443
1444 AC_TRY_LINK([$1],[$2],[
1445         cf_cv_find_linkage_$3=yes
1446         cf_cv_header_path_$3=/usr/include
1447         cf_cv_library_path_$3=/usr/lib
1448 ],[
1449
1450 LIBS="-l$3 $7 $cf_save_LIBS"
1451
1452 AC_TRY_LINK([$1],[$2],[
1453         cf_cv_find_linkage_$3=yes
1454         cf_cv_header_path_$3=/usr/include
1455         cf_cv_library_path_$3=/usr/lib
1456         cf_cv_library_file_$3="-l$3"
1457 ],[
1458         cf_cv_find_linkage_$3=no
1459         LIBS="$cf_save_LIBS"
1460
1461     CF_VERBOSE(find linkage for $3 library)
1462     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1463
1464     cf_save_CPPFLAGS="$CPPFLAGS"
1465     cf_test_CPPFLAGS="$CPPFLAGS"
1466
1467     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1468     for cf_cv_header_path_$3 in $cf_search
1469     do
1470       if test -d $cf_cv_header_path_$3 ; then
1471         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1472         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1473         AC_TRY_COMPILE([$1],[$2],[
1474             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1475             cf_cv_find_linkage_$3=maybe
1476             cf_test_CPPFLAGS="$CPPFLAGS"
1477             break],[
1478             CPPFLAGS="$cf_save_CPPFLAGS"
1479             ])
1480       fi
1481     done
1482
1483     if test "$cf_cv_find_linkage_$3" = maybe ; then
1484
1485       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1486
1487       cf_save_LIBS="$LIBS"
1488       cf_save_LDFLAGS="$LDFLAGS"
1489
1490       ifelse([$6],,,[
1491         CPPFLAGS="$cf_test_CPPFLAGS"
1492         LIBS="-l$3 $7 $cf_save_LIBS"
1493         AC_TRY_LINK([$1],[$2],[
1494             CF_VERBOSE(... found $3 library in system)
1495             cf_cv_find_linkage_$3=yes])
1496             CPPFLAGS="$cf_save_CPPFLAGS"
1497             LIBS="$cf_save_LIBS"
1498             ])
1499
1500       if test "$cf_cv_find_linkage_$3" != yes ; then
1501         CF_LIBRARY_PATH(cf_search,$3)
1502         for cf_cv_library_path_$3 in $cf_search
1503         do
1504           if test -d $cf_cv_library_path_$3 ; then
1505             CF_VERBOSE(... testing $cf_cv_library_path_$3)
1506             CPPFLAGS="$cf_test_CPPFLAGS"
1507             LIBS="-l$3 $7 $cf_save_LIBS"
1508             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1509             AC_TRY_LINK([$1],[$2],[
1510                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1511                 cf_cv_find_linkage_$3=yes
1512                 cf_cv_library_file_$3="-l$3"
1513                 break],[
1514                 CPPFLAGS="$cf_save_CPPFLAGS"
1515                 LIBS="$cf_save_LIBS"
1516                 LDFLAGS="$cf_save_LDFLAGS"
1517                 ])
1518           fi
1519         done
1520         CPPFLAGS="$cf_save_CPPFLAGS"
1521         LDFLAGS="$cf_save_LDFLAGS"
1522       fi
1523
1524     else
1525       cf_cv_find_linkage_$3=no
1526     fi
1527     ],$7)
1528 ])
1529
1530 LIBS="$cf_save_LIBS"
1531
1532 if test "$cf_cv_find_linkage_$3" = yes ; then
1533 ifelse([$4],,[
1534         CF_ADD_INCDIR($cf_cv_header_path_$3)
1535         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1536         CF_ADD_LIB($3)
1537 ],[$4])
1538 else
1539 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1540 fi
1541 ])dnl
1542 dnl ---------------------------------------------------------------------------
1543 dnl CF_FIXUP_ADAFLAGS version: 1 updated: 2012/03/31 18:48:10
1544 dnl -----------------
1545 dnl make ADAFLAGS consistent with CFLAGS
1546 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1547         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1548         case "$CFLAGS" in
1549         *-g*)
1550                 CF_ADD_ADAFLAGS(-g)
1551                 ;;
1552         esac
1553         case "$CFLAGS" in
1554         *-O*)
1555                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1556                 CF_ADD_ADAFLAGS($cf_O_flag)
1557                 ;;
1558         esac
1559         AC_MSG_RESULT($ADAFLAGS)
1560 ])dnl
1561 dnl ---------------------------------------------------------------------------
1562 dnl CF_FUNC_DLSYM version: 2 updated: 2010/05/29 16:31:02
1563 dnl -------------
1564 dnl Test for dlsym() and related functions, as well as libdl.
1565 dnl
1566 dnl Sets
1567 dnl     $cf_have_dlsym
1568 dnl     $cf_have_libdl
1569 AC_DEFUN([CF_FUNC_DLSYM],[
1570 cf_have_dlsym=no
1571 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1572
1573 cf_have_libdl=no
1574 AC_CHECK_LIB(dl,dlsym,[
1575         cf_have_dlsym=yes
1576         cf_have_libdl=yes])])
1577
1578 if test "$cf_have_dlsym" = yes ; then
1579         test "$cf_have_libdl" = yes && CF_ADD_LIB(dl)
1580
1581         AC_MSG_CHECKING(whether able to link to dl*() functions)
1582         AC_TRY_LINK([#include <dlfcn.h>],[
1583                 void *obj;
1584                 if ((obj = dlopen("filename", 0)) != 0) {
1585                         if (dlsym(obj, "symbolname") == 0) {
1586                         dlclose(obj);
1587                         }
1588                 }],[
1589                 AC_DEFINE(HAVE_LIBDL)],[
1590                 AC_MSG_ERROR(Cannot link test program for libdl)])
1591         AC_MSG_RESULT(ok)
1592 else
1593         AC_MSG_ERROR(Cannot find dlsym function)
1594 fi
1595 ])
1596 dnl ---------------------------------------------------------------------------
1597 dnl CF_FUNC_MEMMOVE version: 7 updated: 2006/12/16 12:33:30
1598 dnl ---------------
1599 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1600 dnl is found, add our own version of memmove to the list of objects.
1601 AC_DEFUN([CF_FUNC_MEMMOVE],
1602 [
1603 AC_CHECK_FUNC(memmove,,[
1604 AC_CHECK_FUNC(bcopy,[
1605         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1606                 AC_TRY_RUN([
1607 int main() {
1608         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1609         char temp[40];
1610         bcopy(data, temp, sizeof(data));
1611         bcopy(temp+10, temp, 15);
1612         bcopy(temp+5, temp+15, 10);
1613         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1614 }
1615                 ],
1616                 [cf_cv_good_bcopy=yes],
1617                 [cf_cv_good_bcopy=no],
1618                 [cf_cv_good_bcopy=unknown])
1619                 ])
1620         ],[cf_cv_good_bcopy=no])
1621         if test "$cf_cv_good_bcopy" = yes ; then
1622                 AC_DEFINE(USE_OK_BCOPY)
1623         else
1624                 AC_DEFINE(USE_MY_MEMMOVE)
1625         fi
1626 ])])dnl
1627 dnl ---------------------------------------------------------------------------
1628 dnl CF_FUNC_NANOSLEEP version: 3 updated: 2006/12/16 12:33:30
1629 dnl -----------------
1630 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1631 dnl AIX 4.x, provide a non-working version.
1632 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1633 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1634 AC_TRY_RUN([
1635 #include <stdio.h>
1636 #include <errno.h>
1637 #include <time.h>
1638
1639 #ifdef HAVE_SYS_TIME_H
1640 #include <sys/time.h>
1641 #endif
1642
1643 int main() {
1644         struct timespec ts1, ts2;
1645         int code;
1646         ts1.tv_sec  = 0;
1647         ts1.tv_nsec = 750000000;
1648         ts2.tv_sec  = 0;
1649         ts2.tv_nsec = 0;
1650         errno = 0;
1651         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1652         ${cf_cv_main_return:-return}(code != 0);
1653 }
1654 ],
1655         [cf_cv_func_nanosleep=yes],
1656         [cf_cv_func_nanosleep=no],
1657         [cf_cv_func_nanosleep=unknown])])
1658
1659 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP)
1660 ])
1661 dnl ---------------------------------------------------------------------------
1662 dnl CF_FUNC_OPENPTY version: 3 updated: 2010/05/29 16:31:02
1663 dnl ---------------
1664 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1665 dnl "util" library as well.
1666 AC_DEFUN([CF_FUNC_OPENPTY],
1667 [
1668 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1669 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1670     cf_save_LIBS="$LIBS"
1671     test $cf_cv_lib_util = yes && CF_ADD_LIB(util)
1672     for cf_header in pty.h libutil.h util.h
1673     do
1674     AC_TRY_LINK([
1675 #include <$cf_header>
1676 ],[
1677     int x = openpty((int *)0, (int *)0, (char *)0,
1678                    (struct termios *)0, (struct winsize *)0);
1679 ],[
1680         cf_cv_func_openpty=$cf_header
1681         break
1682 ],[
1683         cf_cv_func_openpty=no
1684 ])
1685     done
1686     LIBS="$cf_save_LIBS"
1687 ])
1688 ])dnl
1689 dnl ---------------------------------------------------------------------------
1690 dnl CF_FUNC_POLL version: 5 updated: 2012/01/25 17:55:38
1691 dnl ------------
1692 dnl See if the poll function really works.  Some platforms have poll(), but
1693 dnl it does not work for terminals or files.
1694 AC_DEFUN([CF_FUNC_POLL],[
1695 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
1696 AC_TRY_RUN([
1697 #include <stdio.h>
1698 #ifdef HAVE_POLL_H
1699 #include <poll.h>
1700 #else
1701 #include <sys/poll.h>
1702 #endif
1703 int main() {
1704         struct pollfd myfds;
1705         int ret;
1706
1707         /* check for Darwin bug with respect to "devices" */
1708         myfds.fd = open("/dev/null", 1);
1709         if (myfds.fd < 0)
1710                 myfds.fd = 0;
1711         myfds.events = POLLIN;
1712         myfds.revents = 0;
1713
1714         ret = poll(&myfds, 1, 100);
1715
1716         if (ret < 0 || (myfds.revents & POLLNVAL)) {
1717                 ret = -1;
1718         } else {
1719
1720                 /* also check with standard input */
1721                 myfds.fd = 0;
1722                 myfds.events = POLLIN;
1723                 myfds.revents = 0;
1724
1725                 ret = poll(&myfds, 1, 100);
1726                 if (ret < 0) {
1727                         ret = 0;
1728                 }
1729         }
1730         ${cf_cv_main_return:-return}(ret != 0);
1731 }],
1732         [cf_cv_working_poll=yes],
1733         [cf_cv_working_poll=no],
1734         [cf_cv_working_poll=unknown])])
1735 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL)
1736 ])dnl
1737 dnl ---------------------------------------------------------------------------
1738 dnl CF_FUNC_TERMIOS version: 2 updated: 2000/07/22 23:37:24
1739 dnl ---------------
1740 dnl Some old/broken variations define tcgetattr() only as a macro in
1741 dnl termio(s).h
1742 AC_DEFUN([CF_FUNC_TERMIOS],[
1743 AC_REQUIRE([CF_STRUCT_TERMIOS])
1744 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
1745 AC_TRY_LINK([
1746 #include <sys/types.h>
1747 #ifdef HAVE_UNISTD_H
1748 #include <unistd.h>
1749 #endif
1750 #ifdef HAVE_TERMIOS_H
1751 #include <termios.h>
1752 #define TTY struct termios
1753 #else
1754 #ifdef HAVE_TERMIO_H
1755 #include <termio.h>
1756 #define TTY struct termio
1757 #endif
1758 #endif
1759 ],[
1760 TTY foo;
1761 tcgetattr(1, &foo);],
1762 [cf_cv_have_tcgetattr=yes],
1763 [cf_cv_have_tcgetattr=no])])
1764 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR)
1765 ])dnl
1766 dnl ---------------------------------------------------------------------------
1767 dnl CF_FUNC_VSSCANF version: 3 updated: 2001/12/19 00:50:10
1768 dnl ---------------
1769 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
1770 dnl versions of C.  It is in the GNU C library, and can often be simulated by
1771 dnl other functions.
1772 AC_DEFUN([CF_FUNC_VSSCANF],
1773 [
1774 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
1775 AC_TRY_LINK([
1776 #include <stdarg.h>
1777 #include <stdio.h>],[
1778         va_list ap;
1779         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
1780 AC_TRY_LINK([
1781 #include <stdarg.h>
1782 #include <stdio.h>],[
1783     FILE strbuf;
1784     char *str = "from";
1785
1786     strbuf._flag = _IOREAD;
1787     strbuf._ptr = strbuf._base = (unsigned char *) str;
1788     strbuf._cnt = strlen(str);
1789     strbuf._file = _NFILE;
1790     return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
1791 AC_TRY_LINK([
1792 #include <stdarg.h>
1793 #include <stdio.h>],[
1794     FILE strbuf;
1795     char *str = "from";
1796
1797     strbuf._flag = _IOREAD;
1798     strbuf._ptr = strbuf._base = (unsigned char *) str;
1799     strbuf._cnt = strlen(str);
1800     strbuf._file = _NFILE;
1801     return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
1802 cf_cv_func_vsscanf=no])])])])
1803
1804 case $cf_cv_func_vsscanf in #(vi
1805 vsscanf) AC_DEFINE(HAVE_VSSCANF);; #(vi
1806 vfscanf) AC_DEFINE(HAVE_VFSCANF);; #(vi
1807 _doscan) AC_DEFINE(HAVE__DOSCAN);;
1808 esac
1809
1810 ])dnl
1811 dnl ---------------------------------------------------------------------------
1812 dnl CF_GCC_ATTRIBUTES version: 14 updated: 2010/10/23 15:52:32
1813 dnl -----------------
1814 dnl Test for availability of useful gcc __attribute__ directives to quiet
1815 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1816 dnl to documentation, unrecognized directives cause older compilers to barf.
1817 AC_DEFUN([CF_GCC_ATTRIBUTES],
1818 [
1819 if test "$GCC" = yes
1820 then
1821 cat > conftest.i <<EOF
1822 #ifndef GCC_PRINTF
1823 #define GCC_PRINTF 0
1824 #endif
1825 #ifndef GCC_SCANF
1826 #define GCC_SCANF 0
1827 #endif
1828 #ifndef GCC_NORETURN
1829 #define GCC_NORETURN /* nothing */
1830 #endif
1831 #ifndef GCC_UNUSED
1832 #define GCC_UNUSED /* nothing */
1833 #endif
1834 EOF
1835 if test "$GCC" = yes
1836 then
1837         AC_CHECKING([for $CC __attribute__ directives])
1838 cat > conftest.$ac_ext <<EOF
1839 #line __oline__ "${as_me:-configure}"
1840 #include "confdefs.h"
1841 #include "conftest.h"
1842 #include "conftest.i"
1843 #if     GCC_PRINTF
1844 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1845 #else
1846 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1847 #endif
1848 #if     GCC_SCANF
1849 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1850 #else
1851 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1852 #endif
1853 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1854 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1855 extern void foo(void) GCC_NORETURN;
1856 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1857 EOF
1858         cf_printf_attribute=no
1859         cf_scanf_attribute=no
1860         for cf_attribute in scanf printf unused noreturn
1861         do
1862                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1863                 cf_directive="__attribute__(($cf_attribute))"
1864                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1865
1866                 case $cf_attribute in #(vi
1867                 printf) #(vi
1868                         cf_printf_attribute=yes
1869                         cat >conftest.h <<EOF
1870 #define GCC_$cf_ATTRIBUTE 1
1871 EOF
1872                         ;;
1873                 scanf) #(vi
1874                         cf_scanf_attribute=yes
1875                         cat >conftest.h <<EOF
1876 #define GCC_$cf_ATTRIBUTE 1
1877 EOF
1878                         ;;
1879                 *) #(vi
1880                         cat >conftest.h <<EOF
1881 #define GCC_$cf_ATTRIBUTE $cf_directive
1882 EOF
1883                         ;;
1884                 esac
1885
1886                 if AC_TRY_EVAL(ac_compile); then
1887                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1888                         cat conftest.h >>confdefs.h
1889                         case $cf_attribute in #(vi
1890                         printf) #(vi
1891                                 if test "$cf_printf_attribute" = no ; then
1892                                         cat >>confdefs.h <<EOF
1893 #define GCC_PRINTFLIKE(fmt,var) /* nothing */
1894 EOF
1895                                 else
1896                                         cat >>confdefs.h <<EOF
1897 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1898 EOF
1899                                 fi
1900                                 ;;
1901                         scanf) #(vi
1902                                 if test "$cf_scanf_attribute" = no ; then
1903                                         cat >>confdefs.h <<EOF
1904 #define GCC_SCANFLIKE(fmt,var) /* nothing */
1905 EOF
1906                                 else
1907                                         cat >>confdefs.h <<EOF
1908 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1909 EOF
1910                                 fi
1911                                 ;;
1912                         esac
1913                 fi
1914         done
1915 else
1916         fgrep define conftest.i >>confdefs.h
1917 fi
1918 rm -rf conftest*
1919 fi
1920 ])dnl
1921 dnl ---------------------------------------------------------------------------
1922 dnl CF_GCC_VERSION version: 5 updated: 2010/04/24 11:02:31
1923 dnl --------------
1924 dnl Find version of gcc
1925 AC_DEFUN([CF_GCC_VERSION],[
1926 AC_REQUIRE([AC_PROG_CC])
1927 GCC_VERSION=none
1928 if test "$GCC" = yes ; then
1929         AC_MSG_CHECKING(version of $CC)
1930         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1931         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1932         AC_MSG_RESULT($GCC_VERSION)
1933 fi
1934 ])dnl
1935 dnl ---------------------------------------------------------------------------
1936 dnl CF_GCC_WARNINGS version: 28 updated: 2012/03/31 20:10:46
1937 dnl ---------------
1938 dnl Check if the compiler supports useful warning options.  There's a few that
1939 dnl we don't use, simply because they're too noisy:
1940 dnl
1941 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1942 dnl     -Wredundant-decls (system headers make this too noisy)
1943 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1944 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1945 dnl             is enabled for ncurses using "--enable-const".
1946 dnl     -pedantic
1947 dnl
1948 dnl Parameter:
1949 dnl     $1 is an optional list of gcc warning flags that a particular
1950 dnl             application might want to use, e.g., "no-unused" for
1951 dnl             -Wno-unused
1952 dnl Special:
1953 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1954 dnl
1955 AC_DEFUN([CF_GCC_WARNINGS],
1956 [
1957 AC_REQUIRE([CF_GCC_VERSION])
1958 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1959
1960 cat > conftest.$ac_ext <<EOF
1961 #line __oline__ "${as_me:-configure}"
1962 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1963 EOF
1964
1965 if test "$INTEL_COMPILER" = yes
1966 then
1967 # The "-wdXXX" options suppress warnings:
1968 # remark #1419: external declaration in primary source file
1969 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1970 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1971 # remark #193: zero used for undefined preprocessing identifier
1972 # remark #593: variable "curs_sb_left_arrow" was set but never used
1973 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1974 # remark #869: parameter "tw" was never referenced
1975 # remark #981: operands are evaluated in unspecified order
1976 # warning #279: controlling expression is constant
1977
1978         AC_CHECKING([for $CC warning options])
1979         cf_save_CFLAGS="$CFLAGS"
1980         EXTRA_CFLAGS="-Wall"
1981         for cf_opt in \
1982                 wd1419 \
1983                 wd1683 \
1984                 wd1684 \
1985                 wd193 \
1986                 wd593 \
1987                 wd279 \
1988                 wd810 \
1989                 wd869 \
1990                 wd981
1991         do
1992                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
1993                 if AC_TRY_EVAL(ac_compile); then
1994                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
1995                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
1996                 fi
1997         done
1998         CFLAGS="$cf_save_CFLAGS"
1999
2000 elif test "$GCC" = yes
2001 then
2002         AC_CHECKING([for $CC warning options])
2003         cf_save_CFLAGS="$CFLAGS"
2004         EXTRA_CFLAGS=
2005         cf_warn_CONST=""
2006         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2007         for cf_opt in W Wall \
2008                 Wbad-function-cast \
2009                 Wcast-align \
2010                 Wcast-qual \
2011                 Winline \
2012                 Wmissing-declarations \
2013                 Wmissing-prototypes \
2014                 Wnested-externs \
2015                 Wpointer-arith \
2016                 Wshadow \
2017                 Wstrict-prototypes \
2018                 Wundef $cf_warn_CONST $1
2019         do
2020                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2021                 if AC_TRY_EVAL(ac_compile); then
2022                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2023                         case $cf_opt in #(vi
2024                         Wcast-qual) #(vi
2025                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
2026                                 ;;
2027                         Winline) #(vi
2028                                 case $GCC_VERSION in
2029                                 [[34]].*)
2030                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2031                                         continue;;
2032                                 esac
2033                                 ;;
2034                         Wpointer-arith) #(vi
2035                                 case $GCC_VERSION in
2036                                 [[12]].*)
2037                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2038                                         continue;;
2039                                 esac
2040                                 ;;
2041                         esac
2042                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2043                 fi
2044         done
2045         CFLAGS="$cf_save_CFLAGS"
2046 fi
2047 rm -rf conftest*
2048
2049 AC_SUBST(EXTRA_CFLAGS)
2050 ])dnl
2051 dnl ---------------------------------------------------------------------------
2052 dnl CF_GETOPT_HEADER version: 4 updated: 2009/08/31 20:07:52
2053 dnl ----------------
2054 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2055 dnl unistd.h or (nonstandard) in getopt.h
2056 AC_DEFUN([CF_GETOPT_HEADER],
2057 [
2058 AC_HAVE_HEADERS(unistd.h getopt.h)
2059 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2060 cf_cv_getopt_header=none
2061 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2062 do
2063 AC_TRY_COMPILE([
2064 #include <$cf_header>],
2065 [int x = optind; char *y = optarg],
2066 [cf_cv_getopt_header=$cf_header
2067  break])
2068 done
2069 ])
2070 if test $cf_cv_getopt_header != none ; then
2071         AC_DEFINE(HAVE_GETOPT_HEADER)
2072 fi
2073 ])dnl
2074 dnl ---------------------------------------------------------------------------
2075 dnl CF_GNAT_GENERICS version: 2 updated: 2011/03/23 20:24:41
2076 dnl ----------------
2077 AC_DEFUN([CF_GNAT_GENERICS],
2078 [
2079 AC_REQUIRE([CF_GNAT_VERSION])
2080
2081 AC_MSG_CHECKING(if GNAT supports generics)
2082 case $cf_gnat_version in #(vi
2083 3.[[1-9]]*|[[4-9]].*) #(vi
2084         cf_gnat_generics=yes
2085         ;;
2086 *)
2087         cf_gnat_generics=no
2088         ;;
2089 esac
2090 AC_MSG_RESULT($cf_gnat_generics)
2091
2092 if test "$cf_gnat_generics" = yes
2093 then
2094         cf_compile_generics=generics
2095         cf_generic_objects="\${GENOBJS}"
2096 else
2097         cf_compile_generics=
2098         cf_generic_objects=
2099 fi
2100
2101 AC_SUBST(cf_compile_generics)
2102 AC_SUBST(cf_generic_objects)
2103 ])dnl
2104 dnl ---------------------------------------------------------------------------
2105 dnl CF_GNAT_PRAGMA_UNREF version: 1 updated: 2010/06/19 15:22:18
2106 dnl --------------------
2107 dnl Check if the gnat pragma "Unreferenced" works.
2108 AC_DEFUN([CF_GNAT_PRAGMA_UNREF],[
2109 AC_CACHE_CHECK(if GNAT pragma Unreferenced works,cf_cv_pragma_unreferenced,[
2110 CF_GNAT_TRY_LINK([procedure conftest;],
2111 [with Text_IO;
2112 with GNAT.OS_Lib;
2113 procedure conftest is
2114    test : Integer;
2115    pragma Unreferenced (test);
2116 begin
2117    test := 1;
2118    Text_IO.Put ("Hello World");
2119    Text_IO.New_Line;
2120    GNAT.OS_Lib.OS_Exit (0);
2121 end conftest;],
2122         [cf_cv_pragma_unreferenced=yes],
2123         [cf_cv_pragma_unreferenced=no])])
2124
2125 # if the pragma is supported, use it (needed in the Trace code).
2126 if test $cf_cv_pragma_unreferenced = yes ; then
2127         PRAGMA_UNREF=TRUE
2128 else
2129         PRAGMA_UNREF=FALSE
2130 fi
2131 AC_SUBST(PRAGMA_UNREF)
2132 ])dnl
2133 dnl ---------------------------------------------------------------------------
2134 dnl CF_GNAT_PROJECTS version: 2 updated: 2011/03/23 20:24:41
2135 dnl ----------------
2136 dnl GNAT projects are configured with ".gpr" project files.
2137 dnl GNAT libraries are a further development, using the project feature.
2138 AC_DEFUN([CF_GNAT_PROJECTS],
2139 [
2140 AC_REQUIRE([CF_GNAT_VERSION])
2141
2142 cf_gnat_libraries=no
2143 cf_gnat_projects=no
2144
2145 AC_MSG_CHECKING(if GNAT supports project files)
2146 case $cf_gnat_version in #(vi
2147 3.[[0-9]]*) #(vi
2148         ;;
2149 *)
2150         case $cf_cv_system_name in #(vi
2151         cygwin*) #(vi
2152                 ;;
2153         *)
2154                 mkdir conftest.src conftest.bin conftest.lib
2155                 cd conftest.src
2156                 rm -rf conftest* *~conftest*
2157                 cat >>library.gpr <<CF_EOF
2158 project Library is
2159   Kind := External ("LIB_KIND");
2160   for Library_Name use "ConfTest";
2161   for Object_Dir use ".";
2162   for Library_ALI_Dir use External("LIBRARY_DIR");
2163   for Library_Version use External ("SONAME");
2164   for Library_Kind use Kind;
2165   for Library_Dir use External("BUILD_DIR");
2166   Source_Dir := External ("SOURCE_DIR");
2167   for Source_Dirs use (Source_Dir);
2168   package Compiler is
2169      for Default_Switches ("Ada") use
2170        ("-g",
2171         "-O2",
2172         "-gnatafno",
2173         "-gnatVa",   -- All validity checks
2174         "-gnatwa");  -- Activate all optional errors
2175   end Compiler;
2176 end Library;
2177 CF_EOF
2178                 cat >>confpackage.ads <<CF_EOF
2179 package ConfPackage is
2180    procedure conftest;
2181 end ConfPackage;
2182 CF_EOF
2183                 cat >>confpackage.adb <<CF_EOF
2184 with Text_IO;
2185 package body ConfPackage is
2186    procedure conftest is
2187    begin
2188       Text_IO.Put ("Hello World");
2189       Text_IO.New_Line;
2190    end conftest;
2191 end ConfPackage;
2192 CF_EOF
2193                 if ( $cf_ada_make $ADAFLAGS \
2194                                 -Plibrary.gpr \
2195                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2196                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2197                                 -XSOURCE_DIR=`pwd` \
2198                                 -XSONAME=libConfTest.so.1 \
2199                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2200                         cf_gnat_projects=yes
2201                 fi
2202                 cd ..
2203                 if test -f conftest.lib/confpackage.ali
2204                 then
2205                         cf_gnat_libraries=yes
2206                 fi
2207                 rm -rf conftest* *~conftest*
2208                 ;;
2209         esac
2210         ;;
2211 esac
2212 AC_MSG_RESULT($cf_gnat_projects)
2213
2214 if test $cf_gnat_projects = yes
2215 then
2216         AC_MSG_CHECKING(if GNAT supports libraries)
2217         AC_MSG_RESULT($cf_gnat_libraries)
2218 fi
2219
2220 if test "$cf_gnat_projects" = yes
2221 then
2222         USE_OLD_MAKERULES="#"
2223         USE_GNAT_PROJECTS=""
2224 else
2225         USE_OLD_MAKERULES=""
2226         USE_GNAT_PROJECTS="#"
2227 fi
2228
2229 if test "$cf_gnat_libraries" = yes
2230 then
2231         USE_GNAT_LIBRARIES=""
2232 else
2233         USE_GNAT_LIBRARIES="#"
2234 fi
2235
2236 AC_SUBST(USE_OLD_MAKERULES)
2237 AC_SUBST(USE_GNAT_PROJECTS)
2238 AC_SUBST(USE_GNAT_LIBRARIES)
2239 ])dnl
2240 dnl ---------------------------------------------------------------------------
2241 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2242 dnl --------------
2243 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2244 dnl is noted that gnat may compile a tasking unit even for configurations which
2245 dnl fail at runtime.
2246 AC_DEFUN([CF_GNAT_SIGINT],[
2247 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2248 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2249
2250 package ConfTest is
2251
2252    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2253    pragma Unreserve_All_Interrupts;
2254    pragma Warnings (On);
2255
2256    protected Process is
2257       procedure Stop;
2258       function Continue return Boolean;
2259       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2260    private
2261       Done : Boolean := False;
2262    end Process;
2263
2264 end ConfTest;],
2265 [package body ConfTest is
2266    protected body Process is
2267       procedure Stop is
2268       begin
2269          Done := True;
2270       end Stop;
2271       function Continue return Boolean is
2272       begin
2273          return not Done;
2274       end Continue;
2275    end Process;
2276 end ConfTest;],
2277         [cf_cv_gnat_sigint=yes],
2278         [cf_cv_gnat_sigint=no])])
2279
2280 if test $cf_cv_gnat_sigint = yes ; then
2281         USE_GNAT_SIGINT=""
2282 else
2283         USE_GNAT_SIGINT="#"
2284 fi
2285 AC_SUBST(USE_GNAT_SIGINT)
2286 ])dnl
2287 dnl ---------------------------------------------------------------------------
2288 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2289 dnl ----------------
2290 dnl Verify that a test program compiles/links with GNAT.
2291 dnl $cf_ada_make is set to the program that compiles/links
2292 dnl $ADAFLAGS may be set to the GNAT flags.
2293 dnl
2294 dnl $1 is the text of the spec
2295 dnl $2 is the text of the body
2296 dnl $3 is the shell command to execute if successful
2297 dnl $4 is the shell command to execute if not successful
2298 AC_DEFUN([CF_GNAT_TRY_LINK],
2299 [
2300 rm -rf conftest* *~conftest*
2301 cat >>conftest.ads <<CF_EOF
2302 $1
2303 CF_EOF
2304 cat >>conftest.adb <<CF_EOF
2305 $2
2306 CF_EOF
2307 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2308 ifelse($3,,      :,[      $3])
2309 ifelse($4,,,[else
2310    $4])
2311 fi
2312 rm -rf conftest* *~conftest*
2313 ])dnl
2314 dnl ---------------------------------------------------------------------------
2315 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2316 dnl ---------------
2317 dnl Verify that a test program compiles and runs with GNAT
2318 dnl $cf_ada_make is set to the program that compiles/links
2319 dnl $ADAFLAGS may be set to the GNAT flags.
2320 dnl
2321 dnl $1 is the text of the spec
2322 dnl $2 is the text of the body
2323 dnl $3 is the shell command to execute if successful
2324 dnl $4 is the shell command to execute if not successful
2325 AC_DEFUN([CF_GNAT_TRY_RUN],
2326 [
2327 rm -rf conftest* *~conftest*
2328 cat >>conftest.ads <<CF_EOF
2329 $1
2330 CF_EOF
2331 cat >>conftest.adb <<CF_EOF
2332 $2
2333 CF_EOF
2334 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2335    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2336 ifelse($3,,      :,[      $3])
2337 ifelse($4,,,[   else
2338       $4])
2339    fi
2340 ifelse($4,,,[else
2341    $4])
2342 fi
2343 rm -rf conftest* *~conftest*
2344 ])dnl
2345 dnl ---------------------------------------------------------------------------
2346 dnl CF_GNAT_VERSION version: 18 updated: 2012/01/21 19:28:10
2347 dnl ---------------
2348 dnl Verify version of GNAT.
2349 AC_DEFUN([CF_GNAT_VERSION],
2350 [
2351 AC_MSG_CHECKING(for gnat version)
2352 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2353         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2354     sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2355 AC_MSG_RESULT($cf_gnat_version)
2356
2357 case $cf_gnat_version in #(vi
2358 3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]]) #(vi
2359         cf_cv_prog_gnat_correct=yes
2360         ;;
2361 *)
2362         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2363         cf_cv_prog_gnat_correct=no
2364         ;;
2365 esac
2366 ])
2367 dnl ---------------------------------------------------------------------------
2368 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
2369 dnl -------------
2370 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2371 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2372 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2373 dnl since it is interwoven with GNU extensions.
2374 dnl
2375 dnl Well, yes we could work around it...
2376 AC_DEFUN([CF_GNU_SOURCE],
2377 [
2378 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2379 AC_TRY_COMPILE([#include <sys/types.h>],[
2380 #ifndef _XOPEN_SOURCE
2381 make an error
2382 #endif],
2383         [cf_cv_gnu_source=no],
2384         [cf_save="$CPPFLAGS"
2385          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2386          AC_TRY_COMPILE([#include <sys/types.h>],[
2387 #ifdef _XOPEN_SOURCE
2388 make an error
2389 #endif],
2390         [cf_cv_gnu_source=no],
2391         [cf_cv_gnu_source=yes])
2392         CPPFLAGS="$cf_save"
2393         ])
2394 ])
2395 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2396 ])dnl
2397 dnl ---------------------------------------------------------------------------
2398 dnl CF_GPP_LIBRARY version: 10 updated: 2010/05/29 16:31:02
2399 dnl --------------
2400 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2401 dnl problem :-).  If we have the compiler but no library, we'll be able to
2402 dnl configure, but won't be able to build the c++ demo program.
2403 AC_DEFUN([CF_GPP_LIBRARY],
2404 [
2405 cf_cxx_library=unknown
2406 case $cf_cv_system_name in #(vi
2407 os2*) #(vi
2408         cf_gpp_libname=gpp
2409         ;;
2410 *)
2411         cf_gpp_libname=g++
2412         ;;
2413 esac
2414 if test "$GXX" = yes; then
2415         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2416         cf_save="$LIBS"
2417         CF_ADD_LIB($cf_gpp_libname)
2418         AC_TRY_LINK([
2419 #include <$cf_gpp_libname/builtin.h>
2420         ],
2421         [two_arg_error_handler_t foo2 = lib_error_handler],
2422         [cf_cxx_library=yes
2423          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2424          if test "$cf_gpp_libname" = cpp ; then
2425             AC_DEFINE(HAVE_GPP_BUILTIN_H)
2426          else
2427             AC_DEFINE(HAVE_GXX_BUILTIN_H)
2428          fi],
2429         [AC_TRY_LINK([
2430 #include <builtin.h>
2431         ],
2432         [two_arg_error_handler_t foo2 = lib_error_handler],
2433         [cf_cxx_library=yes
2434          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2435          AC_DEFINE(HAVE_BUILTIN_H)],
2436         [cf_cxx_library=no])])
2437         LIBS="$cf_save"
2438         AC_MSG_RESULT($cf_cxx_library)
2439 fi
2440 ])dnl
2441 dnl ---------------------------------------------------------------------------
2442 dnl CF_GXX_VERSION version: 6 updated: 2010/10/23 15:44:18
2443 dnl --------------
2444 dnl Check for version of g++
2445 AC_DEFUN([CF_GXX_VERSION],[
2446 AC_REQUIRE([AC_PROG_CPP])
2447 GXX_VERSION=none
2448 if test "$GXX" = yes; then
2449         AC_MSG_CHECKING(version of g++)
2450         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2451         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2452         AC_MSG_RESULT($GXX_VERSION)
2453 fi
2454 ])dnl
2455 dnl ---------------------------------------------------------------------------
2456 dnl CF_GXX_WARNINGS version: 6 updated: 2010/08/14 18:25:37
2457 dnl ---------------
2458 dnl Check if the compiler supports useful warning options.
2459 dnl
2460 dnl Most of gcc's options apply to g++, except:
2461 dnl     -Wbad-function-cast
2462 dnl     -Wmissing-declarations
2463 dnl     -Wnested-externs
2464 dnl
2465 dnl Omit a few (for now):
2466 dnl     -Winline
2467 dnl
2468 dnl Parameter:
2469 dnl     $1 is an optional list of g++ warning flags that a particular
2470 dnl             application might want to use, e.g., "no-unused" for
2471 dnl             -Wno-unused
2472 dnl Special:
2473 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2474 dnl
2475 AC_DEFUN([CF_GXX_WARNINGS],
2476 [
2477
2478 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2479
2480 AC_REQUIRE([CF_GXX_VERSION])
2481
2482 AC_LANG_SAVE
2483 AC_LANG_CPLUSPLUS
2484
2485 cat > conftest.$ac_ext <<EOF
2486 #line __oline__ "configure"
2487 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2488 EOF
2489
2490 if test "$INTEL_CPLUSPLUS" = yes
2491 then
2492 # The "-wdXXX" options suppress warnings:
2493 # remark #1419: external declaration in primary source file
2494 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2495 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2496 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2497 # remark #193: zero used for undefined preprocessing identifier
2498 # remark #593: variable "curs_sb_left_arrow" was set but never used
2499 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2500 # remark #869: parameter "tw" was never referenced
2501 # remark #981: operands are evaluated in unspecified order
2502 # warning #269: invalid format string conversion
2503
2504         AC_CHECKING([for $CC warning options])
2505         cf_save_CXXFLAGS="$CXXFLAGS"
2506         EXTRA_CXXFLAGS="-Wall"
2507         for cf_opt in \
2508                 wd1419 \
2509                 wd1682 \
2510                 wd1683 \
2511                 wd1684 \
2512                 wd193 \
2513                 wd279 \
2514                 wd593 \
2515                 wd810 \
2516                 wd869 \
2517                 wd981
2518         do
2519                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2520                 if AC_TRY_EVAL(ac_compile); then
2521                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2522                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2523                 fi
2524         done
2525         CXXFLAGS="$cf_save_CXXFLAGS"
2526
2527 elif test "$GXX" = yes
2528 then
2529         AC_CHECKING([for $CXX warning options])
2530         cf_save_CXXFLAGS="$CXXFLAGS"
2531         EXTRA_CXXFLAGS="-W -Wall"
2532         cf_gxx_extra_warnings=""
2533         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2534         case "$GCC_VERSION" in
2535         [[1-2]].*)
2536                 ;;
2537         *)
2538                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2539                 ;;
2540         esac
2541         for cf_opt in \
2542                 Wabi \
2543                 fabi-version=0 \
2544                 Woverloaded-virtual \
2545                 Wsign-promo \
2546                 Wsynth \
2547                 Wold-style-cast \
2548                 Wcast-align \
2549                 Wcast-qual \
2550                 Wmissing-prototypes \
2551                 Wpointer-arith \
2552                 Wshadow \
2553                 Wstrict-prototypes \
2554                 Wundef $cf_gxx_extra_warnings $1
2555         do
2556                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2557                 if AC_TRY_EVAL(ac_compile); then
2558                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2559                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2560                 else
2561                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2562                 fi
2563         done
2564         CXXFLAGS="$cf_save_CXXFLAGS"
2565 fi
2566
2567 rm -rf conftest*
2568 AC_LANG_RESTORE
2569 AC_SUBST(EXTRA_CXXFLAGS)
2570 ])dnl
2571 dnl ---------------------------------------------------------------------------
2572 dnl CF_HASHED_DB version: 4 updated: 2010/05/29 16:31:02
2573 dnl ------------
2574 dnl Look for an instance of the Berkeley hashed database.
2575 dnl
2576 dnl $1 = optional parameter, to specify install-prefix for the database.
2577 AC_DEFUN([CF_HASHED_DB],
2578 [
2579 ifelse([$1],,,[
2580 case $1 in #(vi
2581 yes|*able*) #(vi
2582     ;;
2583 *)
2584     if test -d "$1" ; then
2585         CF_ADD_INCDIR($1/include)
2586         CF_ADD_LIBDIR($1/lib)
2587     fi
2588 esac
2589 ])
2590 AC_CHECK_HEADER(db.h,[
2591 CF_HASHED_DB_VERSION
2592 if test "$cf_cv_hashed_db_version" = unknown ; then
2593         AC_MSG_ERROR(Cannot determine version of db)
2594 else
2595         CF_HASHED_DB_LIBS
2596         if test "$cf_cv_hashed_db_libs" = unknown ; then
2597                 AC_MSG_ERROR(Cannot determine library for db)
2598         elif test "$cf_cv_hashed_db_libs" != default ; then
2599                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2600         fi
2601 fi
2602 ],[
2603         AC_MSG_ERROR(Cannot find db.h)
2604 ])
2605 ])dnl
2606 dnl ---------------------------------------------------------------------------
2607 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2608 dnl -----------------
2609 dnl Given that we have the header and version for hashed database, find the
2610 dnl library information.
2611 AC_DEFUN([CF_HASHED_DB_LIBS],
2612 [
2613 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2614 cf_cv_hashed_db_libs=unknown
2615 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2616 do
2617         cf_save_libs="$LIBS"
2618         if test -n "$cf_db_libs"; then
2619                 CF_ADD_LIB($cf_db_libs)
2620         fi
2621         CF_MSG_LOG(checking for library "$cf_db_libs")
2622         AC_TRY_LINK([
2623 $ac_includes_default
2624 #include <db.h>
2625 ],[
2626         char *path = "/tmp/foo";
2627 #ifdef DB_VERSION_MAJOR
2628 #if DB_VERSION_MAJOR >= 4
2629         DB *result = 0;
2630         db_create(&result, NULL, 0);
2631         result->open(result,
2632                 NULL,
2633                 path,
2634                 path,
2635                 DB_HASH,
2636                 DB_CREATE,
2637                 0644);
2638 #elif DB_VERSION_MAJOR >= 3
2639         DB *result = 0;
2640         db_create(&result, NULL, 0);
2641         result->open(result,
2642                 path,
2643                 path,
2644                 DB_HASH,
2645                 DB_CREATE,
2646                 0644);
2647 #elif DB_VERSION_MAJOR >= 2
2648         DB *result = 0;
2649         db_open(path,
2650                 DB_HASH,
2651                 DB_CREATE,
2652                 0644,
2653                 (DB_ENV *) 0,
2654                 (DB_INFO *) 0,
2655                 &result);
2656 #endif /* DB_VERSION_MAJOR */
2657 #else
2658         DB *result = dbopen(path,
2659                      2,
2660                      0644,
2661                      DB_HASH,
2662                      0);
2663 #endif
2664         ${cf_cv_main_return:-return}(result != 0)
2665 ],[
2666         if test -n "$cf_db_libs" ; then
2667                 cf_cv_hashed_db_libs=$cf_db_libs
2668         else
2669                 cf_cv_hashed_db_libs=default
2670         fi
2671         LIBS="$cf_save_libs"
2672         break
2673 ])
2674         LIBS="$cf_save_libs"
2675 done
2676 ])
2677 ])dnl
2678 dnl ---------------------------------------------------------------------------
2679 dnl CF_HASHED_DB_VERSION version: 3 updated: 2007/12/01 15:01:37
2680 dnl --------------------
2681 dnl Given that we have the header file for hashed database, find the version
2682 dnl information.
2683 AC_DEFUN([CF_HASHED_DB_VERSION],
2684 [
2685 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
2686 cf_cv_hashed_db_version=unknown
2687
2688 for cf_db_version in 1 2 3 4 5
2689 do
2690         CF_MSG_LOG(checking for db version $cf_db_version)
2691         AC_TRY_COMPILE([
2692 $ac_includes_default
2693 #include <db.h>
2694
2695 #ifdef DB_VERSION_MAJOR
2696         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
2697 #if $cf_db_version == DB_VERSION_MAJOR
2698         /* ok */
2699 #else
2700         make an error
2701 #endif
2702 #else
2703 #if $cf_db_version == 1
2704         /* ok: assuming this is DB 1.8.5 */
2705 #else
2706         make an error
2707 #endif
2708 #endif
2709 ],[DBT *foo = 0],[
2710         cf_cv_hashed_db_version=$cf_db_version
2711         break
2712         ])
2713 done
2714 ])
2715 ])dnl
2716 dnl ---------------------------------------------------------------------------
2717 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
2718 dnl --------------
2719 dnl Construct a search-list of directories for a nonstandard header-file
2720 dnl
2721 dnl Parameters
2722 dnl     $1 = the variable to return as result
2723 dnl     $2 = the package name
2724 AC_DEFUN([CF_HEADER_PATH],
2725 [
2726 $1=
2727
2728 # collect the current set of include-directories from compiler flags
2729 cf_header_path_list=""
2730 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2731         for cf_header_path in $CPPFLAGS $CFLAGS
2732         do
2733                 case $cf_header_path in #(vi
2734                 -I*)
2735                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2736                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2737                         cf_header_path_list="$cf_header_path_list [$]$1"
2738                         ;;
2739                 esac
2740         done
2741 fi
2742
2743 # add the variations for the package we are looking for
2744 CF_SUBDIR_PATH($1,$2,include)
2745
2746 test "$includedir" != NONE && \
2747 test "$includedir" != "/usr/include" && \
2748 test -d "$includedir" && {
2749         test -d $includedir &&    $1="[$]$1 $includedir"
2750         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
2751 }
2752
2753 test "$oldincludedir" != NONE && \
2754 test "$oldincludedir" != "/usr/include" && \
2755 test -d "$oldincludedir" && {
2756         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
2757         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
2758 }
2759
2760 $1="[$]$1 $cf_header_path_list"
2761 ])dnl
2762 dnl ---------------------------------------------------------------------------
2763 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
2764 dnl ---------------
2765 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2766 AC_DEFUN([CF_HELP_MESSAGE],
2767 [AC_DIVERT_HELP([$1])dnl
2768 ])dnl
2769 dnl ---------------------------------------------------------------------------
2770 dnl CF_INCLUDE_DIRS version: 6 updated: 2009/01/06 19:37:40
2771 dnl ---------------
2772 dnl Construct the list of include-options according to whether we're building
2773 dnl in the source directory or using '--srcdir=DIR' option.  If we're building
2774 dnl with gcc, don't append the includedir if it happens to be /usr/include,
2775 dnl since that usually breaks gcc's shadow-includes.
2776 AC_DEFUN([CF_INCLUDE_DIRS],
2777 [
2778 CPPFLAGS="$CPPFLAGS -I. -I../include"
2779 if test "$srcdir" != "."; then
2780         CPPFLAGS="$CPPFLAGS -I\${srcdir}/../include"
2781 fi
2782 if test "$GCC" != yes; then
2783         CPPFLAGS="$CPPFLAGS -I\${includedir}"
2784 elif test "$includedir" != "/usr/include"; then
2785         if test "$includedir" = '${prefix}/include' ; then
2786                 if test $prefix != /usr ; then
2787                         CPPFLAGS="$CPPFLAGS -I\${includedir}"
2788                 fi
2789         else
2790                 CPPFLAGS="$CPPFLAGS -I\${includedir}"
2791         fi
2792 fi
2793 AC_SUBST(CPPFLAGS)
2794 ])dnl
2795 dnl ---------------------------------------------------------------------------
2796 dnl CF_INTEL_COMPILER version: 4 updated: 2010/05/26 05:38:42
2797 dnl -----------------
2798 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2799 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2800 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2801 dnl
2802 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2803 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2804 dnl the wrappers for gcc and g++ warnings.
2805 dnl
2806 dnl $1 = GCC (default) or GXX
2807 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2808 dnl $3 = CFLAGS (default) or CXXFLAGS
2809 AC_DEFUN([CF_INTEL_COMPILER],[
2810 ifelse([$2],,INTEL_COMPILER,[$2])=no
2811
2812 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2813         case $host_os in
2814         linux*|gnu*)
2815                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2816                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2817                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2818                 AC_TRY_COMPILE([],[
2819 #ifdef __INTEL_COMPILER
2820 #else
2821 make an error
2822 #endif
2823 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2824 cf_save_CFLAGS="$cf_save_CFLAGS -we147 -no-gcc"
2825 ],[])
2826                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2827                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2828                 ;;
2829         esac
2830 fi
2831 ])dnl
2832 dnl ---------------------------------------------------------------------------
2833 dnl CF_ISASCII version: 3 updated: 2000/08/12 23:18:52
2834 dnl ----------
2835 dnl Check if we have either a function or macro for 'isascii()'.
2836 AC_DEFUN([CF_ISASCII],
2837 [
2838 AC_MSG_CHECKING(for isascii)
2839 AC_CACHE_VAL(cf_cv_have_isascii,[
2840         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
2841         [cf_cv_have_isascii=yes],
2842         [cf_cv_have_isascii=no])
2843 ])dnl
2844 AC_MSG_RESULT($cf_cv_have_isascii)
2845 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII)
2846 ])dnl
2847 dnl ---------------------------------------------------------------------------
2848 dnl CF_LARGEFILE version: 7 updated: 2007/06/02 11:58:50
2849 dnl ------------
2850 dnl Add checks for large file support.
2851 AC_DEFUN([CF_LARGEFILE],[
2852 ifdef([AC_FUNC_FSEEKO],[
2853     AC_SYS_LARGEFILE
2854     if test "$enable_largefile" != no ; then
2855         AC_FUNC_FSEEKO
2856
2857         # Normally we would collect these definitions in the config.h,
2858         # but (like _XOPEN_SOURCE), some environments rely on having these
2859         # defined before any of the system headers are included.  Another
2860         # case comes up with C++, e.g., on AIX the compiler compiles the
2861         # header files by themselves before looking at the body files it is
2862         # told to compile.  For ncurses, those header files do not include
2863         # the config.h
2864         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
2865         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
2866         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
2867
2868         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2869                 AC_TRY_COMPILE([
2870 #include <sys/types.h>
2871 #include <dirent.h>
2872                 ],[
2873                 /* if transitional largefile support is setup, this is true */
2874                 extern struct dirent64 * readdir(DIR *);
2875                 struct dirent64 *x = readdir((DIR *)0);
2876                 struct dirent *y = readdir((DIR *)0);
2877                 int z = x - y;
2878                 ],
2879                 [cf_cv_struct_dirent64=yes],
2880                 [cf_cv_struct_dirent64=no])
2881         ])
2882         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64)
2883     fi
2884 ])
2885 ])
2886 dnl ---------------------------------------------------------------------------
2887 dnl CF_LDFLAGS_STATIC version: 10 updated: 2011/09/24 12:51:48
2888 dnl -----------------
2889 dnl Check for compiler/linker flags used to temporarily force usage of static
2890 dnl libraries.  This depends on the compiler and platform.  Use this to help
2891 dnl ensure that the linker picks up a given library based on its position in
2892 dnl the list of linker options and libraries.
2893 AC_DEFUN([CF_LDFLAGS_STATIC],[
2894
2895 if test "$GCC" = yes ; then
2896         case $cf_cv_system_name in #(
2897         OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)         #( vi
2898                 LDFLAGS_STATIC=
2899                 LDFLAGS_SHARED=
2900                 ;;
2901     *)  #( normally, except when broken
2902         LDFLAGS_STATIC=-static
2903         LDFLAGS_SHARED=-dynamic
2904         ;;
2905     esac
2906 else
2907         case $cf_cv_system_name in #(
2908         aix[[4-7]]*)    #( from ld manpage
2909                 LDFLAGS_STATIC=-bstatic
2910                 LDFLAGS_SHARED=-bdynamic
2911                 ;;
2912         hpux*)          #( from ld manpage for hpux10.20, hpux11.11
2913                 # We could also use just "archive" and "shared".
2914                 LDFLAGS_STATIC=-Wl,-a,archive_shared
2915                 LDFLAGS_SHARED=-Wl,-a,shared_archive
2916                 ;;
2917         irix*)          #( from ld manpage IRIX64
2918                 LDFLAGS_STATIC=-Bstatic
2919                 LDFLAGS_SHARED=-Bdynamic
2920                 ;;
2921         osf[[45]]*)     #( from ld manpage osf4.0d, osf5.1
2922                 # alternative "-oldstyle_liblookup" (not in cc manpage)
2923                 LDFLAGS_STATIC=-noso
2924                 LDFLAGS_SHARED=-so_archive
2925                 ;;
2926         solaris2*)
2927                 LDFLAGS_STATIC=-Bstatic
2928                 LDFLAGS_SHARED=-Bdynamic
2929                 ;;
2930         esac
2931 fi
2932
2933 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
2934 then
2935         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
2936
2937         rm -f libconftest.a
2938         cat >conftest.$ac_ext <<EOF
2939 #line __oline__ "configure"
2940 #include <stdio.h>
2941 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
2942 EOF
2943         if AC_TRY_EVAL(ac_compile) ; then
2944                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
2945                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
2946         fi
2947         rm -f conftest.*
2948
2949         cf_save_LIBS="$LIBS"
2950
2951         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
2952         AC_TRY_LINK([
2953 #line __oline__ "configure"
2954 #include <stdio.h>
2955 int cf_ldflags_static(FILE *fp);
2956 ],[
2957         return cf_ldflags_static(stdin);
2958 ],[
2959         # some linkers simply ignore the -dynamic
2960         case x`file conftest$ac_exeext 2>/dev/null` in #(vi
2961         *static*) # (vi
2962                 cf_ldflags_static=no
2963                 ;;
2964         *)
2965                 cf_ldflags_static=yes
2966                 ;;
2967         esac
2968 ],[cf_ldflags_static=no])
2969
2970         rm -f libconftest.*
2971         LIBS="$cf_save_LIBS"
2972
2973         AC_MSG_RESULT($cf_ldflags_static)
2974
2975         if test $cf_ldflags_static != yes
2976         then
2977                 LDFLAGS_STATIC=
2978                 LDFLAGS_SHARED=
2979         fi
2980 else
2981         LDFLAGS_STATIC=
2982         LDFLAGS_SHARED=
2983 fi
2984
2985 AC_SUBST(LDFLAGS_STATIC)
2986 AC_SUBST(LDFLAGS_SHARED)
2987 ])
2988 dnl ---------------------------------------------------------------------------
2989 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
2990 dnl ---------------
2991 dnl For the given system and compiler, find the compiler flags to pass to the
2992 dnl loader to use the "rpath" feature.
2993 AC_DEFUN([CF_LD_RPATH_OPT],
2994 [
2995 AC_REQUIRE([CF_CHECK_CACHE])
2996
2997 LD_RPATH_OPT=
2998 AC_MSG_CHECKING(for an rpath option)
2999 case $cf_cv_system_name in #(vi
3000 irix*) #(vi
3001         if test "$GCC" = yes; then
3002                 LD_RPATH_OPT="-Wl,-rpath,"
3003         else
3004                 LD_RPATH_OPT="-rpath "
3005         fi
3006         ;;
3007 linux*|gnu*|k*bsd*-gnu) #(vi
3008         LD_RPATH_OPT="-Wl,-rpath,"
3009         ;;
3010 openbsd[[2-9]].*|mirbsd*) #(vi
3011         LD_RPATH_OPT="-Wl,-rpath,"
3012         ;;
3013 dragonfly*|freebsd*) #(vi
3014         LD_RPATH_OPT="-rpath "
3015         ;;
3016 netbsd*) #(vi
3017         LD_RPATH_OPT="-Wl,-rpath,"
3018         ;;
3019 osf*|mls+*) #(vi
3020         LD_RPATH_OPT="-rpath "
3021         ;;
3022 solaris2*) #(vi
3023         LD_RPATH_OPT="-R"
3024         ;;
3025 *)
3026         ;;
3027 esac
3028 AC_MSG_RESULT($LD_RPATH_OPT)
3029
3030 case "x$LD_RPATH_OPT" in #(vi
3031 x-R*)
3032         AC_MSG_CHECKING(if we need a space after rpath option)
3033         cf_save_LIBS="$LIBS"
3034         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3035         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3036         LIBS="$cf_save_LIBS"
3037         AC_MSG_RESULT($cf_rpath_space)
3038         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3039         ;;
3040 esac
3041 ])dnl
3042 dnl ---------------------------------------------------------------------------
3043 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
3044 dnl ---------------
3045 dnl Construct a search-list of directories for a nonstandard library-file
3046 dnl
3047 dnl Parameters
3048 dnl     $1 = the variable to return as result
3049 dnl     $2 = the package name
3050 AC_DEFUN([CF_LIBRARY_PATH],
3051 [
3052 $1=
3053 cf_library_path_list=""
3054 if test -n "${LDFLAGS}${LIBS}" ; then
3055         for cf_library_path in $LDFLAGS $LIBS
3056         do
3057                 case $cf_library_path in #(vi
3058                 -L*)
3059                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3060                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3061                         cf_library_path_list="$cf_library_path_list [$]$1"
3062                         ;;
3063                 esac
3064         done
3065 fi
3066
3067 CF_SUBDIR_PATH($1,$2,lib)
3068
3069 $1="$cf_library_path_list [$]$1"
3070 ])dnl
3071 dnl ---------------------------------------------------------------------------
3072 dnl CF_LIB_PREFIX version: 9 updated: 2012/01/21 19:28:10
3073 dnl -------------
3074 dnl Compute the library-prefix for the given host system
3075 dnl $1 = variable to set
3076 define([CF_LIB_PREFIX],
3077 [
3078         case $cf_cv_system_name in #(vi
3079         OS/2*|os2*) #(vi
3080         LIB_PREFIX=''
3081         ;;
3082         *)      LIB_PREFIX='lib'
3083         ;;
3084         esac
3085 ifelse($1,,,[$1=$LIB_PREFIX])
3086         AC_SUBST(LIB_PREFIX)
3087 ])dnl
3088 dnl ---------------------------------------------------------------------------
3089 dnl CF_LIB_RULES version: 64 updated: 2012/02/25 15:20:07
3090 dnl ------------
3091 dnl Append definitions and rules for the given models to the subdirectory
3092 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3093 dnl subdirectory is a library-source directory, modify the LIBS_TO_MAKE list in
3094 dnl the corresponding makefile to list the models that we'll generate.
3095 dnl
3096 dnl For shared libraries, make a list of symbolic links to construct when
3097 dnl generating each library.  The convention used for Linux is the simplest
3098 dnl one:
3099 dnl     lib<name>.so    ->
3100 dnl     lib<name>.so.<major>    ->
3101 dnl     lib<name>.so.<maj>.<minor>
3102 AC_DEFUN([CF_LIB_RULES],
3103 [
3104 cf_prefix=$LIB_PREFIX
3105 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3106
3107 case $cf_cv_shlib_version in #(vi
3108 cygdll|mingw)
3109         TINFO_NAME=$TINFO_ARG_SUFFIX
3110         TINFO_SUFFIX=.dll
3111         ;;
3112 esac
3113
3114 if test -n "$TINFO_SUFFIX" ; then
3115         case $TINFO_SUFFIX in
3116         tw*)
3117                 TINFO_NAME="${TINFO_NAME}tw"
3118                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw//'`
3119                 ;;
3120         t*)
3121                 TINFO_NAME="${TINFO_NAME}t"
3122                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t//'`
3123                 ;;
3124         w*)
3125                 TINFO_NAME="${TINFO_NAME}w"
3126                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w//'`
3127                 ;;
3128         esac
3129 fi
3130
3131 for cf_dir in $SRC_SUBDIRS
3132 do
3133         if test ! -d $srcdir/$cf_dir ; then
3134                 continue
3135         elif test -f $srcdir/$cf_dir/modules; then
3136
3137                 SHARED_LIB=
3138                 LIBS_TO_MAKE=
3139                 for cf_item in $cf_LIST_MODELS
3140                 do
3141                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3142                         if test $cf_item = shared ; then
3143                         if test "$cf_cv_do_symlinks" = yes ; then
3144                                 case "$cf_cv_shlib_version" in #(vi
3145                                 rel) #(vi
3146                                         case "$cf_cv_system_name" in #(vi
3147                                         darwin*)
3148                                         case .${LIB_SUFFIX} in
3149                                         .tw*)
3150                                                 cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3151                                                 cf_suffix=tw'.${REL_VERSION}'"$cf_suffix"
3152                                                 ;;
3153                                         .t*)
3154                                                 cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3155                                                 cf_suffix=t'.${REL_VERSION}'"$cf_suffix"
3156                                                 ;;
3157                                         .w*)
3158                                                 cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3159                                                 cf_suffix=w'.${REL_VERSION}'"$cf_suffix"
3160                                                 ;;
3161                                         *)
3162                                                 cf_suffix='.${REL_VERSION}'"$cf_suffix"
3163                                                 ;;
3164                                         esac
3165                                         ;; #(vi
3166                                         *) cf_suffix="$cf_suffix"'.${REL_VERSION}' ;;
3167                                         esac
3168                                         ;;
3169                                 abi)
3170                                         case "$cf_cv_system_name" in #(vi
3171                                         darwin*)
3172                                         case .${LIB_SUFFIX} in
3173                                         .tw*)
3174                                                 cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3175                                                 cf_suffix=tw'.${ABI_VERSION}'"$cf_suffix"
3176                                                 ;;
3177                                         .t*)
3178                                                 cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3179                                                 cf_suffix=t'.${ABI_VERSION}'"$cf_suffix"
3180                                                 ;;
3181                                         .w*)
3182                                                 cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3183                                                 cf_suffix=w'.${ABI_VERSION}'"$cf_suffix"
3184                                                 ;;
3185                                         *)
3186                                                 cf_suffix='.${ABI_VERSION}'"$cf_suffix"
3187                                                 ;;
3188                                         esac
3189                                         ;; #(vi
3190                                         *) cf_suffix="$cf_suffix"'.${ABI_VERSION}' ;;
3191                                         esac
3192                                         ;;
3193                                 esac
3194                         fi
3195                         # cygwin needs import library, and has unique naming convention
3196                         # use autodetected ${cf_prefix} for import lib and static lib, but
3197                         # use 'cyg' prefix for shared lib.
3198                         case $cf_cv_shlib_version in #(vi
3199                         cygdll) #(vi
3200                                 cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3201                                 LIBS_TO_MAKE="$LIBS_TO_MAKE ../lib/cyg${cf_dir}${cf_cygsuf}"
3202                                 continue
3203                                 ;;
3204                         mingw)
3205                                 cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3206                                 LIBS_TO_MAKE="$LIBS_TO_MAKE ../lib/lib${cf_dir}${cf_cygsuf}"
3207                                 continue
3208                                 ;;
3209                         esac
3210                         fi
3211                         LIBS_TO_MAKE="$LIBS_TO_MAKE ../lib/${cf_prefix}${cf_dir}${cf_suffix}"
3212                 done
3213
3214                 if test $cf_dir = ncurses ; then
3215                         cf_subsets="$LIB_SUBSETS"
3216                         cf_r_parts="$cf_subsets"
3217                         cf_liblist="$LIBS_TO_MAKE"
3218
3219                         while test -n "$cf_r_parts"
3220                         do
3221                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3222                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3223                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3224                                         cf_item=
3225                                         case $cf_l_parts in #(vi
3226                                         *termlib*) #(vi
3227                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3228                                                 ;;
3229                                         *ticlib*)
3230                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3231                                                 ;;
3232                                         *)
3233                                                 break
3234                                                 ;;
3235                                         esac
3236                                         if test -n "$cf_item"; then
3237                                                 LIBS_TO_MAKE="$cf_item $LIBS_TO_MAKE"
3238                                         fi
3239                                 else
3240                                         break
3241                                 fi
3242                         done
3243                 else
3244                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3245                 fi
3246
3247                 sed -e "s%@LIBS_TO_MAKE@%$LIBS_TO_MAKE%" \
3248                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3249                         $cf_dir/Makefile >$cf_dir/Makefile.out
3250                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3251
3252                 $AWK -f $srcdir/mk-0th.awk \
3253                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" \
3254                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3255
3256                 for cf_subset in $cf_subsets
3257                 do
3258                         cf_subdirs=
3259                         for cf_item in $cf_LIST_MODELS
3260                         do
3261                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3262                         CF_UPPER(cf_ITEM,$cf_item)
3263                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3264                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3265
3266                         # Test for case where we build libtinfo with a different name.
3267                         cf_libname=$cf_dir
3268                         if test $cf_dir = ncurses ; then
3269                                 case $cf_subset in
3270                                 *base*)
3271                                         cf_libname=${cf_libname}$LIB_SUFFIX
3272                                         ;;
3273                                 *termlib*)
3274                                         cf_libname=$TINFO_LIB_SUFFIX
3275                                         ;;
3276                                 ticlib*)
3277                                         cf_libname=$TICS_LIB_SUFFIX
3278                                         ;;
3279                                 esac
3280                         else
3281                                 cf_libname=${cf_libname}$LIB_SUFFIX
3282                         fi
3283                         if test -n "${DFT_ARG_SUFFIX}" ; then
3284                                 # undo $LIB_SUFFIX add-on in CF_LIB_SUFFIX
3285                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${LIB_SUFFIX}%%"`
3286                         fi
3287
3288                         # These dependencies really are for development, not
3289                         # builds, but they are useful in porting, too.
3290                         cf_depend="../include/ncurses_cfg.h"
3291                         if test "$srcdir" = "."; then
3292                                 cf_reldir="."
3293                         else
3294                                 cf_reldir="\${srcdir}"
3295                         fi
3296
3297                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3298                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3299                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3300                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3301                         fi
3302
3303                         cf_dir_suffix=
3304                         old_cf_suffix="$cf_suffix"
3305                         if test "$cf_cv_shlib_version_infix" = yes ; then
3306                         if test -n "$LIB_SUFFIX" ; then
3307                                 case $LIB_SUFFIX in
3308                                 tw*)
3309                                         cf_libname=`echo $cf_libname | sed 's/tw$//'`
3310                                         cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3311                                         cf_dir_suffix=tw
3312                                         ;;
3313                                 t*)
3314                                         cf_libname=`echo $cf_libname | sed 's/t$//'`
3315                                         cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3316                                         cf_dir_suffix=t
3317                                         ;;
3318                                 w*)
3319                                         cf_libname=`echo $cf_libname | sed 's/w$//'`
3320                                         cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3321                                         cf_dir_suffix=w
3322                                         ;;
3323                                 esac
3324                         fi
3325                         fi
3326
3327                         $AWK -f $srcdir/mk-1st.awk \
3328                                 name=${cf_libname}${cf_dir_suffix} \
3329                                 traces=$LIB_TRACING \
3330                                 MODEL=$cf_ITEM \
3331                                 model=$cf_subdir \
3332                                 prefix=$cf_prefix \
3333                                 suffix=$cf_suffix \
3334                                 subset=$cf_subset \
3335                                 driver=$cf_cv_term_driver \
3336                                 SymLink="$LN_S" \
3337                                 TermlibRoot=$TINFO_NAME \
3338                                 TermlibSuffix=$TINFO_SUFFIX \
3339                                 ShlibVer=$cf_cv_shlib_version \
3340                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3341                                 ReLink=${cf_cv_do_relink:-no} \
3342                                 DoLinks=$cf_cv_do_symlinks \
3343                                 rmSoLocs=$cf_cv_rm_so_locs \
3344                                 ldconfig="$LDCONFIG" \
3345                                 overwrite=$WITH_OVERWRITE \
3346                                 depend="$cf_depend" \
3347                                 host="$host" \
3348                                 libtool_version="$LIBTOOL_VERSION" \
3349                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3350
3351                         cf_suffix="$old_cf_suffix"
3352
3353                         for cf_subdir2 in $cf_subdirs lib
3354                         do
3355                                 test $cf_subdir = $cf_subdir2 && break
3356                         done
3357                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3358                         $AWK -f $srcdir/mk-2nd.awk \
3359                                 name=$cf_dir \
3360                                 traces=$LIB_TRACING \
3361                                 MODEL=$cf_ITEM \
3362                                 model=$cf_subdir \
3363                                 subset=$cf_subset \
3364                                 srcdir=$srcdir \
3365                                 echo=$WITH_ECHO \
3366                                 crenames=$cf_cv_prog_CC_c_o \
3367                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3368                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3369                         cf_subdirs="$cf_subdirs $cf_subdir"
3370                         done
3371                 done
3372         fi
3373
3374         echo '  cd '$cf_dir' && ${MAKE} ${CF_MFLAGS} [$]@' >>Makefile
3375 done
3376
3377 for cf_dir in $SRC_SUBDIRS
3378 do
3379         if test ! -d $srcdir/$cf_dir ; then
3380                 continue
3381         fi
3382
3383         if test -f $cf_dir/Makefile ; then
3384                 case "$cf_dir" in
3385                 Ada95) #(vi
3386                         echo 'libs \' >> Makefile
3387                         echo 'install.libs \' >> Makefile
3388                         echo 'uninstall.libs ::' >> Makefile
3389                         echo '  cd '$cf_dir' && ${MAKE} ${CF_MFLAGS} [$]@' >> Makefile
3390                         ;;
3391                 esac
3392         fi
3393
3394         if test -f $srcdir/$cf_dir/modules; then
3395                 echo >> Makefile
3396                 if test -f $srcdir/$cf_dir/headers; then
3397 cat >> Makefile <<CF_EOF
3398 install.includes \\
3399 uninstall.includes \\
3400 CF_EOF
3401                 fi
3402 if test "$cf_dir" != "c++" ; then
3403 echo 'lint \' >> Makefile
3404 fi
3405 cat >> Makefile <<CF_EOF
3406 libs \\
3407 lintlib \\
3408 install.libs \\
3409 uninstall.libs \\
3410 install.$cf_dir \\
3411 uninstall.$cf_dir ::
3412         cd $cf_dir && \${MAKE} \${CF_MFLAGS} \[$]@
3413 CF_EOF
3414         elif test -f $srcdir/$cf_dir/headers; then
3415 cat >> Makefile <<CF_EOF
3416
3417 libs \\
3418 install.libs \\
3419 uninstall.libs \\
3420 install.includes \\
3421 uninstall.includes ::
3422         cd $cf_dir && \${MAKE} \${CF_MFLAGS} \[$]@
3423 CF_EOF
3424 fi
3425 done
3426
3427 cat >> Makefile <<CF_EOF
3428
3429 install.libs uninstall.libs \\
3430 install.data uninstall.data ::
3431 $MAKE_TERMINFO  cd misc && \${MAKE} \${CF_MFLAGS} \[$]@
3432 CF_EOF
3433
3434 if test "x$cf_with_manpages" = xyes; then
3435 cat >> Makefile <<CF_EOF
3436
3437 install.man \\
3438 uninstall.man ::
3439         cd man && \${MAKE} \${CF_MFLAGS} \[$]@
3440 CF_EOF
3441 fi
3442
3443 cat >> Makefile <<CF_EOF
3444
3445 distclean ::
3446         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3447         rm -f headers.sh headers.sed mk_shared_lib.sh
3448         rm -f edit_man.* man_alias.*
3449         rm -rf \${DIRS_TO_MAKE}
3450 CF_EOF
3451
3452 # Special case: tack's manpage lives in its own directory.
3453 if test "x$cf_with_manpages" = xyes; then
3454 if test -d tack ; then
3455 if test -f $srcdir/$tack.h; then
3456 cat >> Makefile <<CF_EOF
3457
3458 install.man \\
3459 uninstall.man ::
3460         cd tack && \${MAKE} \${CF_MFLAGS} \[$]@
3461 CF_EOF
3462 fi
3463 fi
3464 fi
3465
3466 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3467 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3468 dnl anything, and will make it more standardized.  It's awkward to decide this
3469 dnl at configuration because of quoting, so we'll simply make all headers
3470 dnl installed via a script that can do the right thing.
3471
3472 rm -f headers.sed headers.sh
3473
3474 dnl ( generating this script makes the makefiles a little tidier :-)
3475 echo creating headers.sh
3476 cat >headers.sh <<CF_EOF
3477 #! /bin/sh
3478 # This shell script is generated by the 'configure' script.  It is invoked in a
3479 # subdirectory of the build tree.  It generates a sed-script in the parent
3480 # directory that is used to adjust includes for header files that reside in a
3481 # subdirectory of /usr/include, etc.
3482 PRG=""
3483 while test \[$]# != 3
3484 do
3485 PRG="\$PRG \[$]1"; shift
3486 done
3487 DST=\[$]1
3488 REF=\[$]2
3489 SRC=\[$]3
3490 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3491 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3492 echo installing \$SRC in \$DST
3493 CF_EOF
3494
3495 if test $WITH_CURSES_H = yes; then
3496         cat >>headers.sh <<CF_EOF
3497 case \$DST in
3498 /*/include/*)
3499         END=\`basename \$DST\`
3500         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3501         do
3502                 NAME=\`basename \$i\`
3503                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3504         done
3505         ;;
3506 *)
3507         echo "" >> \$TMPSED
3508         ;;
3509 esac
3510 CF_EOF
3511
3512 else
3513         cat >>headers.sh <<CF_EOF
3514 case \$DST in
3515 /*/include/*)
3516         END=\`basename \$DST\`
3517         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3518         do
3519                 NAME=\`basename \$i\`
3520                 if test "\$NAME" = "curses.h"
3521                 then
3522                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3523                         NAME=ncurses.h
3524                 fi
3525                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3526         done
3527         ;;
3528 *)
3529         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3530         ;;
3531 esac
3532 CF_EOF
3533 fi
3534 cat >>headers.sh <<CF_EOF
3535 rm -f \$TMPSRC
3536 sed -f \$TMPSED \$SRC > \$TMPSRC
3537 NAME=\`basename \$SRC\`
3538 CF_EOF
3539 if test $WITH_CURSES_H != yes; then
3540         cat >>headers.sh <<CF_EOF
3541 test "\$NAME" = "curses.h" && NAME=ncurses.h
3542 CF_EOF
3543 fi
3544 cat >>headers.sh <<CF_EOF
3545 # Just in case someone gzip'd manpages, remove the conflicting copy.
3546 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3547
3548 eval \$PRG \$TMPSRC \$DST/\$NAME
3549 rm -f \$TMPSRC \$TMPSED
3550 CF_EOF
3551
3552 chmod 0755 headers.sh
3553
3554 for cf_dir in $SRC_SUBDIRS
3555 do
3556         if test ! -d $srcdir/$cf_dir ; then
3557                 continue
3558         fi
3559
3560         if test -f $srcdir/$cf_dir/headers; then
3561                 $AWK -f $srcdir/mk-hdr.awk \
3562                         subset="$LIB_SUBSETS" \
3563                         compat="$WITH_CURSES_H" \
3564                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3565         fi
3566
3567         if test -f $srcdir/$cf_dir/modules; then
3568                 if test "$cf_dir" != "c++" ; then
3569                         cat >>$cf_dir/Makefile <<"CF_EOF"
3570 depend : ${AUTO_SRC}
3571         makedepend -- ${CPPFLAGS} -- ${C_SRC}
3572
3573 # DO NOT DELETE THIS LINE -- make depend depends on it.
3574 CF_EOF
3575                 fi
3576         fi
3577 done
3578 AC_SUBST(LIBS_TO_MAKE)
3579 ])dnl
3580 dnl ---------------------------------------------------------------------------
3581 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
3582 dnl -------------
3583 dnl Find the and soname for the given shared library.  Set the cache variable
3584 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
3585 dnl variable to "unknown".
3586 dnl
3587 dnl $1 = headers
3588 dnl $2 = code
3589 dnl $3 = library name
3590 AC_DEFUN([CF_LIB_SONAME],
3591 [
3592 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
3593
3594 cf_cv_$3_soname=unknown
3595 if test "$cross_compiling" != yes ; then
3596 cat >conftest.$ac_ext <<CF_EOF
3597 $1
3598 int main()
3599 {
3600 $2
3601         ${cf_cv_main_return:-return}(0);
3602 }
3603 CF_EOF
3604 cf_save_LIBS="$LIBS"
3605         CF_ADD_LIB($3)
3606         if AC_TRY_EVAL(ac_compile) ; then
3607                 if AC_TRY_EVAL(ac_link) ; then
3608                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
3609                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
3610                 fi
3611         fi
3612 rm -rf conftest*
3613 LIBS="$cf_save_LIBS"
3614 fi
3615 ])
3616 ])
3617 dnl ---------------------------------------------------------------------------
3618 dnl CF_LIB_SUFFIX version: 18 updated: 2012/02/25 15:20:07
3619 dnl -------------
3620 dnl Compute the library file-suffix from the given model name
3621 dnl $1 = model name
3622 dnl $2 = variable to set (the nominal library suffix)
3623 dnl $3 = dependency variable to set (actual filename)
3624 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3625 AC_DEFUN([CF_LIB_SUFFIX],
3626 [
3627         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3628         case $1 in #(vi
3629         libtool) #(vi
3630                 $2='.la'
3631                 $3=[$]$2
3632                 ;;
3633         normal) #(vi
3634                 $2='.a'
3635                 $3=[$]$2
3636                 ;;
3637         debug) #(vi
3638                 $2='_g.a'
3639                 $3=[$]$2
3640                 ;;
3641         profile) #(vi
3642                 $2='_p.a'
3643                 $3=[$]$2
3644                 ;;
3645         shared) #(vi
3646                 case $cf_cv_system_name in
3647                 aix[[5-7]]*) #(vi
3648                         $2='.a'
3649                         $3=[$]$2
3650                         ;;
3651                 cygwin*|mingw*) #(vi
3652                         $2='.dll'
3653                         $3='.dll.a'
3654                         ;;
3655                 darwin*) #(vi
3656                         $2='.dylib'
3657                         $3=[$]$2
3658                         ;;
3659                 hpux*) #(vi
3660                         case $target in
3661                         ia64*) #(vi
3662                                 $2='.so'
3663                                 $3=[$]$2
3664                                 ;;
3665                         *) #(vi
3666                                 $2='.sl'
3667                                 $3=[$]$2
3668                                 ;;
3669                         esac
3670                         ;;
3671                 *)      $2='.so'
3672                         $3=[$]$2
3673                         ;;
3674                 esac
3675         esac
3676         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3677         test -n "$LIB_SUFFIX" && $3="${LIB_SUFFIX}[$]{$3}"
3678 ])dnl
3679 dnl ---------------------------------------------------------------------------
3680 dnl CF_LIB_TYPE version: 4 updated: 2000/10/20 22:57:49
3681 dnl -----------
3682 dnl Compute the string to append to -library from the given model name
3683 dnl $1 = model name
3684 dnl $2 = variable to set
3685 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3686 AC_DEFUN([CF_LIB_TYPE],
3687 [
3688         case $1 in
3689         libtool) $2=''   ;;
3690         normal)  $2=''   ;;
3691         debug)   $2='_g' ;;
3692         profile) $2='_p' ;;
3693         shared)  $2=''   ;;
3694         esac
3695         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3696 ])dnl
3697 dnl ---------------------------------------------------------------------------
3698 dnl CF_LINK_DATAONLY version: 9 updated: 2009/01/01 20:21:38
3699 dnl ----------------
3700 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
3701 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
3702 dnl have to provide wrappers for global tables to ensure they're linked
3703 dnl properly.
3704 AC_DEFUN([CF_LINK_DATAONLY],
3705 [
3706 AC_MSG_CHECKING([if data-only library module links])
3707 AC_CACHE_VAL(cf_cv_link_dataonly,[
3708         rm -f conftest.a
3709         cat >conftest.$ac_ext <<EOF
3710 #line __oline__ "configure"
3711 int     testdata[[3]] = { 123, 456, 789 };
3712 EOF
3713         if AC_TRY_EVAL(ac_compile) ; then
3714                 mv conftest.o data.o && \
3715                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
3716         fi
3717         rm -f conftest.$ac_ext data.o
3718         cat >conftest.$ac_ext <<EOF
3719 #line __oline__ "configure"
3720 int     testfunc()
3721 {
3722 #if defined(NeXT)
3723         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
3724 #else
3725         extern int testdata[[3]];
3726         return testdata[[0]] == 123
3727            &&  testdata[[1]] == 456
3728            &&  testdata[[2]] == 789;
3729 #endif
3730 }
3731 EOF
3732         if AC_TRY_EVAL(ac_compile); then
3733                 mv conftest.o func.o && \
3734                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
3735         fi
3736         rm -f conftest.$ac_ext func.o
3737         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
3738         cf_saveLIBS="$LIBS"
3739         LIBS="conftest.a $LIBS"
3740         AC_TRY_RUN([
3741         int main()
3742         {
3743                 extern int testfunc();
3744                 ${cf_cv_main_return:-return} (!testfunc());
3745         }
3746         ],
3747         [cf_cv_link_dataonly=yes],
3748         [cf_cv_link_dataonly=no],
3749         [cf_cv_link_dataonly=unknown])
3750         LIBS="$cf_saveLIBS"
3751         ])
3752 AC_MSG_RESULT($cf_cv_link_dataonly)
3753
3754 if test "$cf_cv_link_dataonly" = no ; then
3755         AC_DEFINE(BROKEN_LINKER)
3756         BROKEN_LINKER=1
3757 fi
3758
3759 ])dnl
3760 dnl ---------------------------------------------------------------------------
3761 dnl CF_LINK_FUNCS version: 7 updated: 2006/12/16 12:33:30
3762 dnl -------------
3763 dnl Most Unix systems have both link and symlink, a few don't have symlink.
3764 dnl A few non-Unix systems implement symlink, but not link.
3765 dnl A few non-systems implement neither (or have nonfunctional versions).
3766 AC_DEFUN([CF_LINK_FUNCS],
3767 [
3768 AC_CHECK_FUNCS( \
3769         remove \
3770         unlink )
3771
3772 if test "$cross_compiling" = yes ; then
3773         AC_CHECK_FUNCS( \
3774                 link \
3775                 symlink )
3776 else
3777         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
3778                 cf_cv_link_funcs=
3779                 for cf_func in link symlink ; do
3780                         AC_TRY_RUN([
3781 #include <sys/types.h>
3782 #include <sys/stat.h>
3783 #ifdef HAVE_UNISTD_H
3784 #include <unistd.h>
3785 #endif
3786 int main()
3787 {
3788         int fail = 0;
3789         char *src = "config.log";
3790         char *dst = "conftest.chk";
3791         struct stat src_sb;
3792         struct stat dst_sb;
3793
3794         stat(src, &src_sb);
3795         fail = ($cf_func("config.log", "conftest.chk") < 0)
3796             || (stat(dst, &dst_sb) < 0)
3797             || (dst_sb.st_mtime != src_sb.st_mtime);
3798 #ifdef HAVE_UNLINK
3799         unlink(dst);
3800 #else
3801         remove(dst);
3802 #endif
3803         ${cf_cv_main_return:-return} (fail);
3804 }
3805                         ],[
3806                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
3807                         eval 'ac_cv_func_'$cf_func'=yes'],[
3808                         eval 'ac_cv_func_'$cf_func'=no'],[
3809                         eval 'ac_cv_func_'$cf_func'=error'])
3810                 done
3811                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
3812         ])
3813         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK)
3814         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK)
3815 fi
3816 ])dnl
3817 dnl ---------------------------------------------------------------------------
3818 dnl CF_MAIN_RETURN version: 1 updated: 2006/12/10 09:51:54
3819 dnl --------------
3820 dnl Check if a return from main to the shell actually returns the same exit
3821 dnl code.  This is true for almost any POSIX environment.
3822 dnl
3823 dnl Some very old environments did not flush stdout, etc., on an exit.  That
3824 dnl would be a useful case to test for also.
3825 AC_DEFUN([CF_MAIN_RETURN],
3826 [
3827 cf_cv_main_return=return
3828 ])dnl
3829 dnl ---------------------------------------------------------------------------
3830 dnl CF_MAKEFLAGS version: 14 updated: 2011/03/31 19:29:46
3831 dnl ------------
3832 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
3833 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
3834 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
3835 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
3836 AC_DEFUN([CF_MAKEFLAGS],
3837 [
3838 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
3839         cf_cv_makeflags=''
3840         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
3841         do
3842                 cat >cf_makeflags.tmp <<CF_EOF
3843 SHELL = /bin/sh
3844 all :
3845         @ echo '.$cf_option'
3846 CF_EOF
3847                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
3848                 case "$cf_result" in
3849                 .*k)
3850                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
3851                         case "$cf_result" in
3852                         .*CC=*) cf_cv_makeflags=
3853                                 ;;
3854                         *)      cf_cv_makeflags=$cf_option
3855                                 ;;
3856                         esac
3857                         break
3858                         ;;
3859                 .-)     ;;
3860                 *)      echo "given option \"$cf_option\", no match \"$cf_result\""
3861                         ;;
3862                 esac
3863         done
3864         rm -f cf_makeflags.tmp
3865 ])
3866
3867 AC_SUBST(cf_cv_makeflags)
3868 ])dnl
3869 dnl ---------------------------------------------------------------------------
3870 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
3871 dnl ------------
3872 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
3873 dnl a monocase filesystem.
3874 AC_DEFUN([CF_MAKE_TAGS],[
3875 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
3876
3877 AC_CHECK_PROGS(CTAGS, exctags ctags)
3878 AC_CHECK_PROGS(ETAGS, exetags etags)
3879
3880 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
3881
3882 if test "$cf_cv_mixedcase" = yes ; then
3883         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
3884 else
3885         MAKE_UPPER_TAGS=no
3886 fi
3887
3888 if test "$MAKE_UPPER_TAGS" = yes ; then
3889         MAKE_UPPER_TAGS=
3890 else
3891         MAKE_UPPER_TAGS="#"
3892 fi
3893
3894 if test "$MAKE_LOWER_TAGS" = yes ; then
3895         MAKE_LOWER_TAGS=
3896 else
3897         MAKE_LOWER_TAGS="#"
3898 fi
3899
3900 AC_SUBST(CTAGS)
3901 AC_SUBST(ETAGS)
3902
3903 AC_SUBST(MAKE_UPPER_TAGS)
3904 AC_SUBST(MAKE_LOWER_TAGS)
3905 ])dnl
3906 dnl ---------------------------------------------------------------------------
3907 dnl CF_MANPAGE_FORMAT version: 9 updated: 2010/10/23 16:10:30
3908 dnl -----------------
3909 dnl Option to allow user to override automatic configuration of manpage format.
3910 dnl There are several special cases:
3911 dnl
3912 dnl     gzip - man checks for, can display gzip'd files
3913 dnl     compress - man checks for, can display compressed files
3914 dnl     BSDI - files in the cat-directories are suffixed ".0"
3915 dnl     formatted - installer should format (put files in cat-directory)
3916 dnl     catonly - installer should only format, e.g., for a turnkey system.
3917 dnl
3918 dnl There are other configurations which this macro does not test, e.g., HPUX's
3919 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
3920 dnl convention would not match our use).
3921 AC_DEFUN([CF_MANPAGE_FORMAT],
3922 [
3923 AC_REQUIRE([CF_PATHSEP])
3924 AC_MSG_CHECKING(format of man-pages)
3925
3926 AC_ARG_WITH(manpage-format,
3927         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
3928                           optionally formatted/catonly, e.g., gzip,formatted],
3929         [MANPAGE_FORMAT=$withval],
3930         [MANPAGE_FORMAT=unknown])
3931
3932 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
3933 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
3934
3935 cf_unknown=
3936
3937 case $MANPAGE_FORMAT in
3938 unknown)
3939   if test -z "$MANPATH" ; then
3940     MANPATH="/usr/man:/usr/share/man"
3941   fi
3942
3943   # look for the 'date' man-page (it's most likely to be installed!)
3944   MANPAGE_FORMAT=
3945   cf_preform=no
3946   cf_catonly=yes
3947   cf_example=date
3948
3949   IFS="${IFS:-  }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
3950   for cf_dir in $MANPATH; do
3951     test -z "$cf_dir" && cf_dir=/usr/man
3952     for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
3953     do
3954       cf_test=`echo $cf_name | sed -e 's/*//'`
3955       if test "x$cf_test" = "x$cf_name" ; then
3956
3957         case "$cf_name" in
3958         *.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
3959         *.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
3960         *.0)    MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
3961         *)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
3962         esac
3963
3964         case "$cf_name" in
3965         $cf_dir/man*)
3966           cf_catonly=no
3967           ;;
3968         $cf_dir/cat*)
3969           cf_preform=yes
3970           ;;
3971         esac
3972         break
3973       fi
3974
3975       # if we found a match in either man* or cat*, stop looking
3976       if test -n "$MANPAGE_FORMAT" ; then
3977         cf_found=no
3978         test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
3979         test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
3980         case "$cf_name" in
3981         $cf_dir/cat*)
3982           cf_found=yes
3983           ;;
3984         esac
3985         test $cf_found=yes && break
3986       fi
3987     done
3988     # only check the first directory in $MANPATH where we find manpages
3989     if test -n "$MANPAGE_FORMAT" ; then
3990        break
3991     fi
3992   done
3993   # if we did not find the example, just assume it is normal
3994   test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
3995   IFS="$ac_save_ifs"
3996   ;;
3997 *)
3998   for cf_option in $MANPAGE_FORMAT; do
3999      case $cf_option in #(vi
4000      gzip|compress|BSDI|normal|formatted|catonly)
4001        ;;
4002      *)
4003        cf_unknown="$cf_unknown $cf_option"
4004        ;;
4005      esac
4006   done
4007   ;;
4008 esac
4009
4010 AC_MSG_RESULT($MANPAGE_FORMAT)
4011 if test -n "$cf_unknown" ; then
4012   AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
4013 fi
4014 ])dnl
4015 dnl ---------------------------------------------------------------------------
4016 dnl CF_MANPAGE_RENAMES version: 7 updated: 2005/06/18 18:51:57
4017 dnl ------------------
4018 dnl The Debian people have their own naming convention for manpages.  This
4019 dnl option lets us override the name of the file containing renaming, or
4020 dnl disable it altogether.
4021 AC_DEFUN([CF_MANPAGE_RENAMES],
4022 [
4023 AC_MSG_CHECKING(for manpage renaming)
4024
4025 AC_ARG_WITH(manpage-renames,
4026         [  --with-manpage-renames  specify manpage-renaming],
4027         [MANPAGE_RENAMES=$withval],
4028         [MANPAGE_RENAMES=yes])
4029
4030 case ".$MANPAGE_RENAMES" in #(vi
4031 .no) #(vi
4032   ;;
4033 .|.yes)
4034   # Debian 'man' program?
4035   if test -f /etc/debian_version ; then
4036     MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
4037   else
4038     MANPAGE_RENAMES=no
4039   fi
4040   ;;
4041 esac
4042
4043 if test "$MANPAGE_RENAMES" != no ; then
4044   if test -f $srcdir/man/$MANPAGE_RENAMES ; then
4045     MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
4046   elif test ! -f $MANPAGE_RENAMES ; then
4047     AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
4048   fi
4049
4050   test ! -d man && mkdir man
4051
4052   # Construct a sed-script to perform renaming within man-pages
4053   if test -n "$MANPAGE_RENAMES" ; then
4054     test ! -d man && mkdir man
4055     sh $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
4056   fi
4057 fi
4058
4059 AC_MSG_RESULT($MANPAGE_RENAMES)
4060 AC_SUBST(MANPAGE_RENAMES)
4061 ])dnl
4062 dnl ---------------------------------------------------------------------------
4063 dnl CF_MANPAGE_SYMLINKS version: 5 updated: 2010/07/24 17:12:40
4064 dnl -------------------
4065 dnl Some people expect each tool to make all aliases for manpages in the
4066 dnl man-directory.  This accommodates the older, less-capable implementations
4067 dnl of 'man', and is optional.
4068 AC_DEFUN([CF_MANPAGE_SYMLINKS],
4069 [
4070 AC_MSG_CHECKING(if manpage aliases will be installed)
4071
4072 AC_ARG_WITH(manpage-aliases,
4073         [  --with-manpage-aliases  specify manpage-aliases using .so],
4074         [MANPAGE_ALIASES=$withval],
4075         [MANPAGE_ALIASES=yes])
4076
4077 AC_MSG_RESULT($MANPAGE_ALIASES)
4078
4079 case "x$LN_S" in #(vi
4080 xln*) #(vi
4081         cf_use_symlinks=yes
4082         ;;
4083 *)
4084         cf_use_symlinks=no
4085         ;;
4086 esac
4087
4088 MANPAGE_SYMLINKS=no
4089 if test "$MANPAGE_ALIASES" = yes ; then
4090 AC_MSG_CHECKING(if manpage symlinks should be used)
4091
4092 AC_ARG_WITH(manpage-symlinks,
4093         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
4094         [MANPAGE_SYMLINKS=$withval],
4095         [MANPAGE_SYMLINKS=$cf_use_symlinks])
4096
4097 if test "$$cf_use_symlinks" = no; then
4098 if test "$MANPAGE_SYMLINKS" = yes ; then
4099         AC_MSG_WARN(cannot make symlinks, will use .so files)
4100         MANPAGE_SYMLINKS=no
4101 fi
4102 fi
4103
4104 AC_MSG_RESULT($MANPAGE_SYMLINKS)
4105 fi
4106
4107 ])dnl
4108 dnl ---------------------------------------------------------------------------
4109 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
4110 dnl --------------
4111 dnl This option causes manpages to be run through tbl(1) to generate tables
4112 dnl correctly.
4113 AC_DEFUN([CF_MANPAGE_TBL],
4114 [
4115 AC_MSG_CHECKING(for manpage tbl)
4116
4117 AC_ARG_WITH(manpage-tbl,
4118         [  --with-manpage-tbl      specify manpage processing with tbl],
4119         [MANPAGE_TBL=$withval],
4120         [MANPAGE_TBL=no])
4121
4122 AC_MSG_RESULT($MANPAGE_TBL)
4123 ])dnl
4124 dnl ---------------------------------------------------------------------------
4125 dnl CF_MAN_PAGES version: 40 updated: 2011/09/10 16:20:21
4126 dnl ------------
4127 dnl Try to determine if the man-pages on the system are compressed, and if
4128 dnl so, what format is used.  Use this information to construct a script that
4129 dnl will install man-pages.
4130 AC_DEFUN([CF_MAN_PAGES],
4131 [
4132 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
4133 CF_MANPAGE_FORMAT
4134 CF_MANPAGE_RENAMES
4135 CF_MANPAGE_SYMLINKS
4136 CF_MANPAGE_TBL
4137
4138   if test "$prefix" = "NONE" ; then
4139      cf_prefix="$ac_default_prefix"
4140   else
4141      cf_prefix="$prefix"
4142   fi
4143
4144   case "$MANPAGE_FORMAT" in # (vi
4145   *catonly*) # (vi
4146     cf_format=yes
4147     cf_inboth=no
4148     ;;
4149   *formatted*) # (vi
4150     cf_format=yes
4151     cf_inboth=yes
4152     ;;
4153   *)
4154     cf_format=no
4155     cf_inboth=no
4156     ;;
4157   esac
4158
4159 test ! -d man && mkdir man
4160
4161 cf_so_strip=
4162 cf_compress=
4163 case "$MANPAGE_FORMAT" in #(vi
4164 *compress*) #(vi
4165         cf_so_strip="Z"
4166         cf_compress=compress
4167   ;;
4168 *gzip*)
4169         cf_so_strip="gz"
4170         cf_compress=gzip
4171   ;;
4172 esac
4173
4174 cf_edit_man=./edit_man.sh
4175 cf_man_alias=`pwd`/man_alias.sed
4176
4177 cat >$cf_edit_man <<CF_EOF
4178 #! /bin/sh
4179 # this script is generated by the configure-script CF_MAN_PAGES macro.
4180
4181 prefix="$cf_prefix"
4182 datadir="$datadir"
4183
4184 NCURSES_MAJOR="$NCURSES_MAJOR"
4185 NCURSES_MINOR="$NCURSES_MINOR"
4186 NCURSES_PATCH="$NCURSES_PATCH"
4187
4188 NCURSES_OSPEED="$NCURSES_OSPEED"
4189 TERMINFO="$TERMINFO"
4190
4191 INSTALL="$INSTALL"
4192 INSTALL_DATA="$INSTALL_DATA"
4193
4194 transform="$program_transform_name"
4195
4196 TMP=\${TMPDIR:=/tmp}/man\$\$
4197 trap "rm -f \$TMP" 0 1 2 5 15
4198
4199 form=\[$]1
4200 shift || exit 1
4201
4202 verb=\[$]1
4203 shift || exit 1
4204
4205 mandir=\[$]1
4206 shift || exit 1
4207
4208 srcdir=\[$]1
4209 top_srcdir=\[$]srcdir/..
4210 shift || exit 1
4211
4212 if test "\$form" = normal ; then
4213         if test "$cf_format" = yes ; then
4214         if test "$cf_inboth" = no ; then
4215                 sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4216                 exit $?
4217         fi
4218         fi
4219         cf_subdir=\$mandir/man
4220         cf_tables=$MANPAGE_TBL
4221 else
4222         cf_subdir=\$mandir/cat
4223         cf_tables=yes
4224 fi
4225
4226 # process the list of source-files
4227 for i in \[$]* ; do
4228 case \$i in #(vi
4229 *.orig|*.rej) ;; #(vi
4230 *.[[0-9]]*)
4231         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
4232         if test \$verb = installing ; then
4233         if test ! -d \$cf_subdir\${section} ; then
4234                 mkdir -p \$cf_subdir\$section
4235         fi
4236         fi
4237
4238         # replace variables in man page
4239         if test ! -f $cf_man_alias ; then
4240 cat >>$cf_man_alias <<-CF_EOF2
4241                 s,@DATADIR@,\$datadir,g
4242                 s,@TERMINFO@,\$TERMINFO,g
4243                 s,@NCURSES_MAJOR@,\$NCURSES_MAJOR,g
4244                 s,@NCURSES_MINOR@,\$NCURSES_MINOR,g
4245                 s,@NCURSES_PATCH@,\$NCURSES_PATCH,g
4246                 s,@NCURSES_OSPEED@,\$NCURSES_OSPEED,g
4247 CF_EOF
4248         ifelse($1,,,[
4249         for cf_name in $1
4250         do
4251                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4252                 cf_name=`echo $cf_name|sed "$program_transform_name"`
4253 cat >>$cf_edit_man <<-CF_EOF
4254                 s,@$cf_NAME@,$cf_name,g
4255 CF_EOF
4256         done
4257         ])
4258 cat >>$cf_edit_man <<CF_EOF
4259 CF_EOF2
4260                 echo "...made $cf_man_alias"
4261         fi
4262
4263         aliases=
4264         cf_source=\`basename \$i\`
4265         inalias=\$cf_source
4266         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
4267         if test ! -f \$inalias ; then
4268                 echo .. skipped \$cf_source
4269                 continue
4270         fi
4271 CF_EOF
4272
4273 if test "$MANPAGE_ALIASES" != no ; then
4274 cat >>$cf_edit_man <<CF_EOF
4275         nCurses=ignore.3x
4276         test $with_curses_h = yes && nCurses=ncurses.3x
4277         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
4278 CF_EOF
4279 fi
4280
4281 if test "$MANPAGE_RENAMES" = no ; then
4282 cat >>$cf_edit_man <<CF_EOF
4283         # perform program transformations for section 1 man pages
4284         if test \$section = 1 ; then
4285                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
4286         else
4287                 cf_target=\$cf_subdir\${section}/\$cf_source
4288         fi
4289 CF_EOF
4290 else
4291 cat >>$cf_edit_man <<CF_EOF
4292         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
4293         if test -z "\$cf_target" ; then
4294                 echo '? missing rename for '\$cf_source
4295                 cf_target="\$cf_source"
4296         fi
4297         cf_target="\$cf_subdir\${section}/\${cf_target}"
4298
4299 CF_EOF
4300 fi
4301
4302 cat >>$cf_edit_man <<CF_EOF
4303         sed     -f $cf_man_alias \\
4304 CF_EOF
4305
4306 if test -f $MANPAGE_RENAMES ; then
4307 cat >>$cf_edit_man <<CF_EOF
4308                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
4309 CF_EOF
4310 else
4311 cat >>$cf_edit_man <<CF_EOF
4312                 < \$i >\$TMP
4313 CF_EOF
4314 fi
4315
4316 cat >>$cf_edit_man <<CF_EOF
4317 if test \$cf_tables = yes ; then
4318         tbl \$TMP >\$TMP.out
4319         mv \$TMP.out \$TMP
4320 fi
4321 CF_EOF
4322
4323 if test $with_overwrite != yes ; then
4324 cat >>$cf_edit_man <<CF_EOF
4325         sed -e "/\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
4326         mv \$TMP.out \$TMP
4327 CF_EOF
4328 fi
4329
4330 if test $with_curses_h != yes ; then
4331 cat >>$cf_edit_man <<CF_EOF
4332         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
4333         mv \$TMP.out \$TMP
4334 CF_EOF
4335 fi
4336
4337 cat >>$cf_edit_man <<CF_EOF
4338         if test \$form = format ; then
4339                 nroff -man \$TMP >\$TMP.out
4340                 mv \$TMP.out \$TMP
4341         fi
4342 CF_EOF
4343
4344 if test -n "$cf_compress" ; then
4345 cat >>$cf_edit_man <<CF_EOF
4346         if test \$verb = installing ; then
4347         if ( $cf_compress -f \$TMP )
4348         then
4349                 mv \$TMP.$cf_so_strip \$TMP
4350         fi
4351         fi
4352         cf_target="\$cf_target.$cf_so_strip"
4353 CF_EOF
4354 fi
4355
4356 case "$MANPAGE_FORMAT" in #(vi
4357 *BSDI*)
4358 cat >>$cf_edit_man <<CF_EOF
4359         if test \$form = format ; then
4360                 # BSDI installs only .0 suffixes in the cat directories
4361                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
4362         fi
4363 CF_EOF
4364   ;;
4365 esac
4366
4367 cat >>$cf_edit_man <<CF_EOF
4368         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
4369         if test \$verb = installing ; then
4370                 echo \$verb \$cf_target
4371                 \$INSTALL_DATA \$TMP \$cf_target
4372                 test -d \$cf_subdir\${section} &&
4373                 test -n "\$aliases" && (
4374                         cd \$cf_subdir\${section} && (
4375                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
4376                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
4377                                 cf_target=\`basename \$cf_target\`
4378                                 for cf_alias in \$aliases
4379                                 do
4380                                         if test \$section = 1 ; then
4381                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4382                                         fi
4383
4384                                         if test "$MANPAGE_SYMLINKS" = yes ; then
4385                                                 if test -f \$cf_alias\${suffix} ; then
4386                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
4387                                                         then
4388                                                                 continue
4389                                                         fi
4390                                                 fi
4391                                                 echo .. \$verb alias \$cf_alias\${suffix}
4392 CF_EOF
4393 case "x$LN_S" in #(vi
4394 *-f) #(vi
4395 cat >>$cf_edit_man <<CF_EOF
4396                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4397 CF_EOF
4398         ;;
4399 *)
4400 cat >>$cf_edit_man <<CF_EOF
4401                                                 rm -f \$cf_alias\${suffix}
4402                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4403 CF_EOF
4404         ;;
4405 esac
4406 cat >>$cf_edit_man <<CF_EOF
4407                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
4408                                                 echo ".so \$cf_source" >\$TMP
4409 CF_EOF
4410 if test -n "$cf_compress" ; then
4411 cat >>$cf_edit_man <<CF_EOF
4412                                                 if test -n "$cf_so_strip" ; then
4413                                                         $cf_compress -f \$TMP
4414                                                         mv \$TMP.$cf_so_strip \$TMP
4415                                                 fi
4416 CF_EOF
4417 fi
4418 cat >>$cf_edit_man <<CF_EOF
4419                                                 echo .. \$verb alias \$cf_alias\${suffix}
4420                                                 rm -f \$cf_alias\${suffix}
4421                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
4422                                         fi
4423                                 done
4424                         )
4425                 )
4426         elif test \$verb = removing ; then
4427                 test -f \$cf_target && (
4428                         echo \$verb \$cf_target
4429                         rm -f \$cf_target
4430                 )
4431                 test -d \$cf_subdir\${section} &&
4432                 test -n "\$aliases" && (
4433                         cd \$cf_subdir\${section} && (
4434                                 for cf_alias in \$aliases
4435                                 do
4436                                         if test \$section = 1 ; then
4437                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4438                                         fi
4439
4440                                         echo .. \$verb alias \$cf_alias\${suffix}
4441                                         rm -f \$cf_alias\${suffix}
4442                                 done
4443                         )
4444                 )
4445         else
4446 #               echo ".hy 0"
4447                 cat \$TMP
4448         fi
4449         ;;
4450 esac
4451 done
4452
4453 if test $cf_inboth = yes ; then
4454 if test \$form != format ; then
4455         sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4456 fi
4457 fi
4458
4459 exit 0
4460 CF_EOF
4461 chmod 755 $cf_edit_man
4462
4463 ])dnl
4464 dnl ---------------------------------------------------------------------------
4465 dnl CF_MATH_LIB version: 8 updated: 2010/05/29 16:31:02
4466 dnl -----------
4467 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
4468 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
4469 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
4470 AC_DEFUN([CF_MATH_LIB],
4471 [
4472 AC_CACHE_CHECK(if -lm needed for math functions,
4473         cf_cv_need_libm,[
4474         AC_TRY_LINK([
4475         #include <stdio.h>
4476         #include <math.h>
4477         ],
4478         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
4479         [cf_cv_need_libm=no],
4480         [cf_cv_need_libm=yes])])
4481 if test "$cf_cv_need_libm" = yes
4482 then
4483 ifelse($1,,[
4484         CF_ADD_LIB(m)
4485 ],[$1=-lm])
4486 fi
4487 ])
4488 dnl ---------------------------------------------------------------------------
4489 dnl CF_MIXEDCASE_FILENAMES version: 3 updated: 2003/09/20 17:07:55
4490 dnl ----------------------
4491 dnl Check if the file-system supports mixed-case filenames.  If we're able to
4492 dnl create a lowercase name and see it as uppercase, it doesn't support that.
4493 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
4494 [
4495 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
4496 if test "$cross_compiling" = yes ; then
4497         case $target_alias in #(vi
4498         *-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-mingw32*|*-uwin*) #(vi
4499                 cf_cv_mixedcase=no
4500                 ;;
4501         *)
4502                 cf_cv_mixedcase=yes
4503                 ;;
4504         esac
4505 else
4506         rm -f conftest CONFTEST
4507         echo test >conftest
4508         if test -f CONFTEST ; then
4509                 cf_cv_mixedcase=no
4510         else
4511                 cf_cv_mixedcase=yes
4512         fi
4513         rm -f conftest CONFTEST
4514 fi
4515 ])
4516 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES)
4517 ])dnl
4518 dnl ---------------------------------------------------------------------------
4519 dnl CF_MKSTEMP version: 8 updated: 2012/02/13 20:34:56
4520 dnl ----------
4521 dnl Check for a working mkstemp.  This creates two files, checks that they are
4522 dnl successfully created and distinct (AmigaOS apparently fails on the last).
4523 AC_DEFUN([CF_MKSTEMP],[
4524 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
4525 rm -rf conftest*
4526 AC_TRY_RUN([
4527 #include <sys/types.h>
4528 #include <stdlib.h>
4529 #include <stdio.h>
4530 #include <string.h>
4531 #include <sys/stat.h>
4532 int main()
4533 {
4534         char *tmpl = "conftestXXXXXX";
4535         char name[2][80];
4536         int n;
4537         int result = 0;
4538         int fd;
4539         struct stat sb;
4540
4541         umask(077);
4542         for (n = 0; n < 2; ++n) {
4543                 strcpy(name[n], tmpl);
4544                 if ((fd = mkstemp(name[n])) >= 0) {
4545                         if (!strcmp(name[n], tmpl)
4546                          || stat(name[n], &sb) != 0
4547                          || (sb.st_mode & S_IFMT) != S_IFREG
4548                          || (sb.st_mode & 077) != 0) {
4549                                 result = 1;
4550                         }
4551                         close(fd);
4552                 }
4553         }
4554         if (result == 0
4555          && !strcmp(name[0], name[1]))
4556                 result = 1;
4557         ${cf_cv_main_return:-return}(result);
4558 }
4559 ],[cf_cv_func_mkstemp=yes
4560 ],[cf_cv_func_mkstemp=no
4561 ],[cf_cv_func_mkstemp=maybe])
4562 ])
4563 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
4564         AC_CHECK_FUNC(mkstemp)
4565 fi
4566 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
4567         AC_DEFINE(HAVE_MKSTEMP)
4568 fi
4569 ])dnl
4570 dnl ---------------------------------------------------------------------------
4571 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
4572 dnl ----------
4573 dnl Write a debug message to config.log, along with the line number in the
4574 dnl configure script.
4575 AC_DEFUN([CF_MSG_LOG],[
4576 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
4577 ])dnl
4578 dnl ---------------------------------------------------------------------------
4579 dnl CF_NCURSES_ABI_6 version: 1 updated: 2005/09/17 18:42:49
4580 dnl ----------------
4581 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
4582 dnl warn about this.
4583 AC_DEFUN([CF_NCURSES_ABI_6],[
4584 if test "${with_abi_version+set}" != set; then
4585         case $cf_cv_rel_version in
4586         5.*)
4587                 cf_cv_rel_version=6.0
4588                 cf_cv_abi_version=6
4589                 AC_MSG_WARN(Overriding ABI version to $cf_cv_abi_version)
4590                 ;;
4591         esac
4592 fi
4593 ])dnl
4594 dnl ---------------------------------------------------------------------------
4595 dnl CF_NO_LEAKS_OPTION version: 4 updated: 2006/12/16 14:24:05
4596 dnl ------------------
4597 dnl see CF_WITH_NO_LEAKS
4598 AC_DEFUN([CF_NO_LEAKS_OPTION],[
4599 AC_MSG_CHECKING(if you want to use $1 for testing)
4600 AC_ARG_WITH($1,
4601         [$2],
4602         [AC_DEFINE($3)ifelse([$4],,[
4603          $4
4604 ])
4605         : ${with_cflags:=-g}
4606         : ${with_no_leaks:=yes}
4607          with_$1=yes],
4608         [with_$1=])
4609 AC_MSG_RESULT(${with_$1:-no})
4610
4611 case .$with_cflags in #(vi
4612 .*-g*)
4613         case .$CFLAGS in #(vi
4614         .*-g*) #(vi
4615                 ;;
4616         *)
4617                 CF_ADD_CFLAGS([-g])
4618                 ;;
4619         esac
4620         ;;
4621 esac
4622 ])dnl
4623 dnl ---------------------------------------------------------------------------
4624 dnl CF_NUMBER_SYNTAX version: 1 updated: 2003/09/20 18:12:49
4625 dnl ----------------
4626 dnl Check if the given variable is a number.  If not, report an error.
4627 dnl $1 is the variable
4628 dnl $2 is the message
4629 AC_DEFUN([CF_NUMBER_SYNTAX],[
4630 if test -n "$1" ; then
4631   case $1 in #(vi
4632   [[0-9]]*) #(vi
4633         ;;
4634   *)
4635         AC_MSG_ERROR($2 is not a number: $1)
4636         ;;
4637   esac
4638 else
4639   AC_MSG_ERROR($2 value is empty)
4640 fi
4641 ])dnl
4642 dnl ---------------------------------------------------------------------------
4643 dnl CF_OBJ_SUBDIR version: 4 updated: 2002/02/23 20:38:31
4644 dnl -------------
4645 dnl Compute the object-directory name from the given model name
4646 AC_DEFUN([CF_OBJ_SUBDIR],
4647 [
4648         case $1 in
4649         libtool) $2='obj_lo'  ;;
4650         normal)  $2='objects' ;;
4651         debug)   $2='obj_g' ;;
4652         profile) $2='obj_p' ;;
4653         shared)
4654                 case $cf_cv_system_name in #(vi
4655                 cygwin) #(vi
4656                         $2='objects' ;;
4657                 *)
4658                         $2='obj_s' ;;
4659                 esac
4660         esac
4661 ])dnl
4662 dnl ---------------------------------------------------------------------------
4663 dnl CF_PATHSEP version: 5 updated: 2010/05/26 05:38:42
4664 dnl ----------
4665 dnl Provide a value for the $PATH and similar separator
4666 AC_DEFUN([CF_PATHSEP],
4667 [
4668         case $cf_cv_system_name in
4669         os2*)   PATH_SEPARATOR=';'  ;;
4670         *)      PATH_SEPARATOR=':'  ;;
4671         esac
4672 ifelse([$1],,,[$1=$PATH_SEPARATOR])
4673         AC_SUBST(PATH_SEPARATOR)
4674 ])dnl
4675 dnl ---------------------------------------------------------------------------
4676 dnl CF_PATH_SYNTAX version: 13 updated: 2010/05/26 05:38:42
4677 dnl --------------
4678 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
4679 dnl begins with one of the prefix/exec_prefix variables, and then again if the
4680 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
4681 dnl delayed evaluation of those symbols.
4682 AC_DEFUN([CF_PATH_SYNTAX],[
4683 if test "x$prefix" != xNONE; then
4684   cf_path_syntax="$prefix"
4685 else
4686   cf_path_syntax="$ac_default_prefix"
4687 fi
4688
4689 case ".[$]$1" in #(vi
4690 .\[$]\(*\)*|.\'*\'*) #(vi
4691   ;;
4692 ..|./*|.\\*) #(vi
4693   ;;
4694 .[[a-zA-Z]]:[[\\/]]*) #(vi OS/2 EMX
4695   ;;
4696 .\[$]{*prefix}*) #(vi
4697   eval $1="[$]$1"
4698   case ".[$]$1" in #(vi
4699   .NONE/*)
4700     $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4701     ;;
4702   esac
4703   ;; #(vi
4704 .no|.NONE/*)
4705   $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4706   ;;
4707 *)
4708   ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
4709   ;;
4710 esac
4711 ])dnl
4712 dnl ---------------------------------------------------------------------------
4713 dnl CF_PKG_CONFIG version: 7 updated: 2011/04/29 04:53:22
4714 dnl -------------
4715 dnl Check for the package-config program, unless disabled by command-line.
4716 AC_DEFUN([CF_PKG_CONFIG],
4717 [
4718 AC_MSG_CHECKING(if you want to use pkg-config)
4719 AC_ARG_WITH(pkg-config,
4720         [  --with-pkg-config{=path} enable/disable use of pkg-config],
4721         [cf_pkg_config=$withval],
4722         [cf_pkg_config=yes])
4723 AC_MSG_RESULT($cf_pkg_config)
4724
4725 case $cf_pkg_config in #(vi
4726 no) #(vi
4727         PKG_CONFIG=none
4728         ;;
4729 yes) #(vi
4730         CF_ACVERSION_CHECK(2.52,
4731                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
4732                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
4733         ;;
4734 *)
4735         PKG_CONFIG=$withval
4736         ;;
4737 esac
4738
4739 test -z "$PKG_CONFIG" && PKG_CONFIG=none
4740 if test "$PKG_CONFIG" != none ; then
4741         CF_PATH_SYNTAX(PKG_CONFIG)
4742 fi
4743
4744 AC_SUBST(PKG_CONFIG)
4745 ])dnl
4746 dnl ---------------------------------------------------------------------------
4747 dnl CF_POSIX_C_SOURCE version: 8 updated: 2010/05/26 05:38:42
4748 dnl -----------------
4749 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
4750 dnl
4751 dnl     POSIX.1-1990                            _POSIX_SOURCE
4752 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
4753 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
4754 dnl             Bindings Option
4755 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
4756 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
4757 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
4758 dnl
4759 dnl Parameters:
4760 dnl     $1 is the nominal value for _POSIX_C_SOURCE
4761 AC_DEFUN([CF_POSIX_C_SOURCE],
4762 [
4763 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
4764
4765 cf_save_CFLAGS="$CFLAGS"
4766 cf_save_CPPFLAGS="$CPPFLAGS"
4767
4768 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
4769 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
4770
4771 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
4772         CF_MSG_LOG(if the symbol is already defined go no further)
4773         AC_TRY_COMPILE([#include <sys/types.h>],[
4774 #ifndef _POSIX_C_SOURCE
4775 make an error
4776 #endif],
4777         [cf_cv_posix_c_source=no],
4778         [cf_want_posix_source=no
4779          case .$cf_POSIX_C_SOURCE in #(vi
4780          .[[12]]??*) #(vi
4781                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4782                 ;;
4783          .2) #(vi
4784                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4785                 cf_want_posix_source=yes
4786                 ;;
4787          .*)
4788                 cf_want_posix_source=yes
4789                 ;;
4790          esac
4791          if test "$cf_want_posix_source" = yes ; then
4792                 AC_TRY_COMPILE([#include <sys/types.h>],[
4793 #ifdef _POSIX_SOURCE
4794 make an error
4795 #endif],[],
4796                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
4797          fi
4798          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
4799          CFLAGS="$cf_trim_CFLAGS"
4800          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
4801          CF_MSG_LOG(if the second compile does not leave our definition intact error)
4802          AC_TRY_COMPILE([#include <sys/types.h>],[
4803 #ifndef _POSIX_C_SOURCE
4804 make an error
4805 #endif],,
4806          [cf_cv_posix_c_source=no])
4807          CFLAGS="$cf_save_CFLAGS"
4808          CPPFLAGS="$cf_save_CPPFLAGS"
4809         ])
4810 ])
4811
4812 if test "$cf_cv_posix_c_source" != no ; then
4813         CFLAGS="$cf_trim_CFLAGS"
4814         CPPFLAGS="$cf_trim_CPPFLAGS"
4815         CF_ADD_CFLAGS($cf_cv_posix_c_source)
4816 fi
4817
4818 ])dnl
4819 dnl ---------------------------------------------------------------------------
4820 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
4821 dnl ------------
4822 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
4823 dnl
4824 dnl $1 = symbol to test
4825 dnl $2 = value (if any) to use for a predefinition
4826 AC_DEFUN([CF_PREDEFINE],
4827 [
4828 AC_MSG_CHECKING(if we must define $1)
4829 AC_TRY_COMPILE([#include <sys/types.h>
4830 ],[
4831 #ifndef $1
4832 make an error
4833 #endif],[cf_result=no],[cf_result=yes])
4834 AC_MSG_RESULT($cf_result)
4835
4836 if test "$cf_result" = yes ; then
4837         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
4838 elif test "x$2" != "x" ; then
4839         AC_MSG_CHECKING(checking for compatible value versus $2)
4840         AC_TRY_COMPILE([#include <sys/types.h>
4841 ],[
4842 #if $1-$2 < 0
4843 make an error
4844 #endif],[cf_result=yes],[cf_result=no])
4845         AC_MSG_RESULT($cf_result)
4846         if test "$cf_result" = no ; then
4847                 # perhaps we can override it - try...
4848                 CPPFLAGS="$CPPFLAGS -D$1=$2"
4849         fi
4850 fi
4851 ])dnl
4852 dnl ---------------------------------------------------------------------------
4853 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
4854 dnl ------------
4855 dnl Append definitions and rules for the given programs to the subdirectory
4856 dnl Makefiles, and the recursion rule for the top-level Makefile.
4857 dnl
4858 dnl parameters
4859 dnl     $1 = script to run
4860 dnl     $2 = list of subdirectories
4861 dnl
4862 dnl variables
4863 dnl     $AWK
4864 AC_DEFUN([CF_PRG_RULES],
4865 [
4866 for cf_dir in $2
4867 do
4868         if test ! -d $srcdir/$cf_dir; then
4869                 continue
4870         elif test -f $srcdir/$cf_dir/programs; then
4871                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
4872         fi
4873 done
4874
4875 ])dnl
4876 dnl ---------------------------------------------------------------------------
4877 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
4878 dnl ----------
4879 dnl Check for archiver "ar".
4880 AC_DEFUN([CF_PROG_AR],[
4881 AC_CHECK_TOOL(AR, ar, ar)
4882 ])
4883 dnl ---------------------------------------------------------------------------
4884 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
4885 dnl -----------
4886 dnl Check for awk, ensure that the check found something.
4887 AC_DEFUN([CF_PROG_AWK],
4888 [
4889 AC_PROG_AWK
4890 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
4891 ])dnl
4892 dnl ---------------------------------------------------------------------------
4893 dnl CF_PROG_CC_C_O version: 3 updated: 2010/08/14 18:25:37
4894 dnl --------------
4895 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
4896 dnl the output file can be renamed, and allows for a shell variable that can
4897 dnl be used later.  The parameter is either CC or CXX.  The result is the
4898 dnl cache variable:
4899 dnl     $cf_cv_prog_CC_c_o
4900 dnl     $cf_cv_prog_CXX_c_o
4901 AC_DEFUN([CF_PROG_CC_C_O],
4902 [AC_REQUIRE([AC_PROG_CC])dnl
4903 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
4904 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
4905 [
4906 cat > conftest.$ac_ext <<CF_EOF
4907 #include <stdio.h>
4908 int main()
4909 {
4910         ${cf_cv_main_return:-return}(0);
4911 }
4912 CF_EOF
4913 # We do the test twice because some compilers refuse to overwrite an
4914 # existing .o file with -o, though they will create one.
4915 ac_try='[$]$1 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
4916 if AC_TRY_EVAL(ac_try) &&
4917   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
4918 then
4919   eval cf_cv_prog_$1_c_o=yes
4920 else
4921   eval cf_cv_prog_$1_c_o=no
4922 fi
4923 rm -rf conftest*
4924 ])dnl
4925 if test $cf_cv_prog_$1_c_o = yes; then
4926   AC_MSG_RESULT([yes])
4927 else
4928   AC_MSG_RESULT([no])
4929 fi
4930 ])dnl
4931 dnl ---------------------------------------------------------------------------
4932 dnl CF_PROG_CC_U_D version: 1 updated: 2005/07/14 16:59:30
4933 dnl --------------
4934 dnl Check if C (preprocessor) -U and -D options are processed in the order
4935 dnl given rather than by type of option.  Some compilers insist on apply all
4936 dnl of the -U options after all of the -D options.  Others allow mixing them,
4937 dnl and may predefine symbols that conflict with those we define.
4938 AC_DEFUN([CF_PROG_CC_U_D],
4939 [
4940 AC_CACHE_CHECK(if $CC -U and -D options work together,cf_cv_cc_u_d_options,[
4941         cf_save_CPPFLAGS="$CPPFLAGS"
4942         CPPFLAGS="-UU_D_OPTIONS -DU_D_OPTIONS -DD_U_OPTIONS -UD_U_OPTIONS"
4943         AC_TRY_COMPILE([],[
4944 #ifndef U_D_OPTIONS
4945 make an undefined-error
4946 #endif
4947 #ifdef  D_U_OPTIONS
4948 make a defined-error
4949 #endif
4950         ],[
4951         cf_cv_cc_u_d_options=yes],[
4952         cf_cv_cc_u_d_options=no])
4953         CPPFLAGS="$cf_save_CPPFLAGS"
4954 ])
4955 ])dnl
4956 dnl ---------------------------------------------------------------------------
4957 dnl CF_PROG_EGREP version: 1 updated: 2006/09/16 11:40:59
4958 dnl -------------
4959 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
4960 dnl This macro adds a check to ensure the script found something.
4961 AC_DEFUN([CF_PROG_EGREP],
4962 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
4963    [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
4964     then ac_cv_prog_egrep='grep -E'
4965     else ac_cv_prog_egrep='egrep'
4966     fi])
4967  EGREP=$ac_cv_prog_egrep
4968  AC_SUBST([EGREP])
4969 test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
4970 ])dnl
4971 dnl ---------------------------------------------------------------------------
4972 dnl CF_PROG_EXT version: 10 updated: 2004/01/03 19:28:18
4973 dnl -----------
4974 dnl Compute $PROG_EXT, used for non-Unix ports, such as OS/2 EMX.
4975 AC_DEFUN([CF_PROG_EXT],
4976 [
4977 AC_REQUIRE([CF_CHECK_CACHE])
4978 case $cf_cv_system_name in
4979 os2*)
4980     CFLAGS="$CFLAGS -Zmt"
4981     CPPFLAGS="$CPPFLAGS -D__ST_MT_ERRNO__"
4982     CXXFLAGS="$CXXFLAGS -Zmt"
4983     # autoconf's macro sets -Zexe and suffix both, which conflict:w
4984     LDFLAGS="$LDFLAGS -Zmt -Zcrtdll"
4985     ac_cv_exeext=.exe
4986     ;;
4987 esac
4988
4989 AC_EXEEXT
4990 AC_OBJEXT
4991
4992 PROG_EXT="$EXEEXT"
4993 AC_SUBST(PROG_EXT)
4994 test -n "$PROG_EXT" && AC_DEFINE_UNQUOTED(PROG_EXT,"$PROG_EXT")
4995 ])dnl
4996 dnl ---------------------------------------------------------------------------
4997 dnl CF_PROG_GNAT version: 2 updated: 2011/10/22 14:01:47
4998 dnl ------------
4999 dnl Check for gnatmake, ensure that it is complete.
5000 AC_DEFUN([CF_PROG_GNAT],[
5001 cf_ada_make=gnatmake
5002 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
5003 if test "$ac_cv_prog_gnat_exists" = no; then
5004    cf_ada_make=
5005    cf_cv_prog_gnat_correct=no
5006 else
5007    CF_GNAT_VERSION
5008    AC_CHECK_PROG(M4_exists, m4, yes, no)
5009    if test "$ac_cv_prog_M4_exists" = no; then
5010       cf_cv_prog_gnat_correct=no
5011       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
5012    fi
5013    if test "$cf_cv_prog_gnat_correct" = yes; then
5014       AC_MSG_CHECKING(if GNAT works)
5015       CF_GNAT_TRY_RUN([procedure conftest;],
5016 [with Text_IO;
5017 with GNAT.OS_Lib;
5018 procedure conftest is
5019 begin
5020    Text_IO.Put ("Hello World");
5021    Text_IO.New_Line;
5022    GNAT.OS_Lib.OS_Exit (0);
5023 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
5024       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
5025    fi
5026 fi
5027
5028 AC_SUBST(cf_ada_make)
5029 ])dnl
5030 dnl ---------------------------------------------------------------------------
5031 dnl CF_PROG_INSTALL version: 5 updated: 2002/12/21 22:46:07
5032 dnl ---------------
5033 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
5034 dnl misc/tabset install won't work properly.  Usually this happens only when
5035 dnl using the fallback mkinstalldirs script
5036 AC_DEFUN([CF_PROG_INSTALL],
5037 [AC_PROG_INSTALL
5038 case $INSTALL in
5039 /*)
5040   ;;
5041 *)
5042   CF_DIRNAME(cf_dir,$INSTALL)
5043   test -z "$cf_dir" && cf_dir=.
5044   INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
5045   ;;
5046 esac
5047 ])dnl
5048 dnl ---------------------------------------------------------------------------
5049 dnl CF_PROG_LDCONFIG version: 3 updated: 2011/06/04 20:09:13
5050 dnl ----------------
5051 dnl Check for ldconfig, needed to fixup shared libraries that would be built
5052 dnl and then used in the install.
5053 AC_DEFUN([CF_PROG_LDCONFIG],[
5054 if test "$cross_compiling" = yes ; then
5055   LDCONFIG=:
5056 else
5057 case "$cf_cv_system_name" in #(vi
5058 dragonfly*|mirbsd*|freebsd*) #(vi
5059   test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
5060   ;;
5061 *) LDPATH=$PATH:/sbin:/usr/sbin
5062   AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
5063   ;;
5064 esac
5065 fi
5066 AC_SUBST(LDCONFIG)
5067 ])dnl
5068 dnl ---------------------------------------------------------------------------
5069 dnl CF_PROG_LINT version: 2 updated: 2009/08/12 04:43:14
5070 dnl ------------
5071 AC_DEFUN([CF_PROG_LINT],
5072 [
5073 AC_CHECK_PROGS(LINT, tdlint lint alint splint lclint)
5074 AC_SUBST(LINT_OPTS)
5075 ])dnl
5076 dnl ---------------------------------------------------------------------------
5077 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
5078 dnl ------------
5079 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
5080 dnl option if it is supported.
5081 AC_DEFUN([CF_PROG_LN_S],[
5082 AC_PROG_LN_S
5083 AC_MSG_CHECKING(if $LN_S -f options work)
5084
5085 rm -f conf$$.src conf$$dst
5086 echo >conf$$.dst
5087 echo first >conf$$.src
5088 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
5089         cf_prog_ln_sf=yes
5090 else
5091         cf_prog_ln_sf=no
5092 fi
5093 rm -f conf$$.dst conf$$src
5094 AC_MSG_RESULT($cf_prog_ln_sf)
5095
5096 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
5097 ])dnl
5098 dnl ---------------------------------------------------------------------------
5099 dnl CF_REGEX version: 9 updated: 2012/01/07 15:08:24
5100 dnl --------
5101 dnl Attempt to determine if we've got one of the flavors of regular-expression
5102 dnl code that we can support.
5103 AC_DEFUN([CF_REGEX],
5104 [
5105
5106 cf_regex_func=no
5107
5108 cf_regex_libs="regex re"
5109 case $host_os in #(vi
5110 mingw*)
5111         cf_regex_libs="gnurx $cf_regex_libs"
5112         ;;
5113 esac
5114
5115 AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
5116         for cf_regex_lib in $cf_regex_libs
5117         do
5118                 AC_CHECK_LIB($cf_regex_lib,regcomp,[
5119                                 CF_ADD_LIB($cf_regex_lib)
5120                                 cf_regex_func=regcomp
5121                                 break])
5122         done
5123 ])
5124
5125 if test "$cf_regex_func" = no ; then
5126         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
5127                 AC_CHECK_LIB(gen,compile,[
5128                                 CF_ADD_LIB(gen)
5129                                 cf_regex_func=compile])])
5130 fi
5131
5132 if test "$cf_regex_func" = no ; then
5133         AC_MSG_WARN(cannot find regular expression library)
5134 fi
5135
5136 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
5137
5138 cf_cv_regex_hdrs=no
5139 case $cf_regex_func in #(vi
5140 compile) #(vi
5141         for cf_regex_hdr in regexp.h regexpr.h
5142         do
5143                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
5144                         char *p = compile("", "", "", 0);
5145                         int x = step("", "");
5146                 ],[
5147                         cf_cv_regex_hdrs=$cf_regex_hdr
5148                         break
5149                 ])
5150         done
5151         ;;
5152 *)
5153         for cf_regex_hdr in regex.h
5154         do
5155                 AC_TRY_LINK([#include <sys/types.h>
5156 #include <$cf_regex_hdr>],[
5157                         regex_t *p;
5158                         int x = regcomp(p, "", 0);
5159                         int y = regexec(p, "", 0, 0, 0);
5160                         regfree(p);
5161                 ],[
5162                         cf_cv_regex_hdrs=$cf_regex_hdr
5163                         break
5164                 ])
5165         done
5166         ;;
5167 esac
5168
5169 ])
5170
5171 case $cf_cv_regex_hdrs in #(vi
5172     no)        AC_MSG_WARN(no regular expression header found) ;; #(vi
5173     regex.h)   AC_DEFINE(HAVE_REGEX_H_FUNCS) ;; #(vi
5174     regexp.h)  AC_DEFINE(HAVE_REGEXP_H_FUNCS) ;; #(vi
5175     regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS) ;;
5176 esac
5177 ])dnl
5178 dnl ---------------------------------------------------------------------------
5179 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
5180 dnl ----------------
5181 dnl Remove all -U and -D options that refer to the given symbol from a list
5182 dnl of C compiler options.  This works around the problem that not all
5183 dnl compilers process -U and -D options from left-to-right, so a -U option
5184 dnl cannot be used to cancel the effect of a preceding -D option.
5185 dnl
5186 dnl $1 = target (which could be the same as the source variable)
5187 dnl $2 = source (including '$')
5188 dnl $3 = symbol to remove
5189 define([CF_REMOVE_DEFINE],
5190 [
5191 $1=`echo "$2" | \
5192         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
5193                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
5194 ])dnl
5195 dnl ---------------------------------------------------------------------------
5196 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
5197 dnl -------------
5198 dnl Remove the given library from the symbol
5199 dnl
5200 dnl $1 = target (which could be the same as the source variable)
5201 dnl $2 = source (including '$')
5202 dnl $3 = library to remove
5203 define([CF_REMOVE_LIB],
5204 [
5205 # remove $3 library from $2
5206 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
5207 ])dnl
5208 dnl ---------------------------------------------------------------------------
5209 dnl CF_RPATH_HACK version: 9 updated: 2011/02/13 13:31:33
5210 dnl -------------
5211 AC_DEFUN([CF_RPATH_HACK],
5212 [
5213 AC_REQUIRE([CF_LD_RPATH_OPT])
5214 AC_MSG_CHECKING(for updated LDFLAGS)
5215 if test -n "$LD_RPATH_OPT" ; then
5216         AC_MSG_RESULT(maybe)
5217
5218         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
5219         cf_rpath_list="/usr/lib /lib"
5220         if test "$cf_ldd_prog" != no
5221         then
5222                 cf_rpath_oops=
5223
5224 AC_TRY_LINK([#include <stdio.h>],
5225                 [printf("Hello");],
5226                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort -u`
5227                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort -u`])
5228
5229                 # If we passed the link-test, but get a "not found" on a given library,
5230                 # this could be due to inept reconfiguration of gcc to make it only
5231                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
5232                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
5233                 # /usr/local libraries.
5234                 if test -n "$cf_rpath_oops"
5235                 then
5236                         for cf_rpath_src in $cf_rpath_oops
5237                         do
5238                                 for cf_rpath_dir in \
5239                                         /usr/local \
5240                                         /usr/pkg \
5241                                         /opt/sfw
5242                                 do
5243                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
5244                                         then
5245                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
5246                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
5247                                                 break
5248                                         fi
5249                                 done
5250                         done
5251                 fi
5252         fi
5253
5254         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5255
5256         CF_RPATH_HACK_2(LDFLAGS)
5257         CF_RPATH_HACK_2(LIBS)
5258
5259         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5260 fi
5261 AC_SUBST(EXTRA_LDFLAGS)
5262 ])dnl
5263 dnl ---------------------------------------------------------------------------
5264 dnl CF_RPATH_HACK_2 version: 6 updated: 2010/04/17 16:31:24
5265 dnl ---------------
5266 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
5267 dnl EXTRA_LDFLAGS for each -L option found.
5268 dnl
5269 dnl $cf_rpath_list contains a list of directories to ignore.
5270 dnl
5271 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
5272 dnl      but LIBS often has misplaced -L options.
5273 AC_DEFUN([CF_RPATH_HACK_2],
5274 [
5275 CF_VERBOSE(...checking $1 [$]$1)
5276
5277 cf_rpath_dst=
5278 for cf_rpath_src in [$]$1
5279 do
5280         case $cf_rpath_src in #(vi
5281         -L*) #(vi
5282
5283                 # check if this refers to a directory which we will ignore
5284                 cf_rpath_skip=no
5285                 if test -n "$cf_rpath_list"
5286                 then
5287                         for cf_rpath_item in $cf_rpath_list
5288                         do
5289                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
5290                                 then
5291                                         cf_rpath_skip=yes
5292                                         break
5293                                 fi
5294                         done
5295                 fi
5296
5297                 if test "$cf_rpath_skip" = no
5298                 then
5299                         # transform the option
5300                         if test "$LD_RPATH_OPT" = "-R " ; then
5301                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
5302                         else
5303                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
5304                         fi
5305
5306                         # if we have not already added this, add it now
5307                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
5308                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
5309                         then
5310                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
5311                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
5312                         fi
5313                 fi
5314                 ;;
5315         esac
5316         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
5317 done
5318 $1=$cf_rpath_dst
5319
5320 CF_VERBOSE(...checked $1 [$]$1)
5321 AC_SUBST(EXTRA_LDFLAGS)
5322 ])dnl
5323 dnl ---------------------------------------------------------------------------
5324 dnl CF_SHARED_OPTS version: 70 updated: 2012/02/25 15:20:07
5325 dnl --------------
5326 dnl --------------
5327 dnl Attempt to determine the appropriate CC/LD options for creating a shared
5328 dnl library.
5329 dnl
5330 dnl Note: ${LOCAL_LDFLAGS} is used to link executables that will run within the
5331 dnl build-tree, i.e., by making use of the libraries that are compiled in ../lib
5332 dnl We avoid compiling-in a ../lib path for the shared library since that can
5333 dnl lead to unexpected results at runtime.
5334 dnl ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared libraries
5335 dnl are compiled in ../../lib
5336 dnl
5337 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
5338 dnl to install symbolic links to the rel/abi versions of shared libraries.
5339 dnl
5340 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
5341 dnl version when making symbolic links.
5342 dnl
5343 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
5344 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
5345 dnl (ex: libncurses.so.<ver>).
5346 dnl
5347 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
5348 AC_DEFUN([CF_SHARED_OPTS],
5349 [
5350         AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
5351         AC_REQUIRE([CF_LD_RPATH_OPT])
5352         LOCAL_LDFLAGS=
5353         LOCAL_LDFLAGS2=
5354         LD_SHARED_OPTS=
5355         INSTALL_LIB="-m 644"
5356
5357         cf_cv_do_symlinks=no
5358         cf_ld_rpath_opt=
5359         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
5360
5361         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
5362         AC_ARG_WITH(shlib-version,
5363         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
5364         [test -z "$withval" && withval=auto
5365         case $withval in #(vi
5366         yes) #(vi
5367                 cf_cv_shlib_version=auto
5368                 ;;
5369         rel|abi|auto|no) #(vi
5370                 cf_cv_shlib_version=$withval
5371                 ;;
5372         *)
5373                 AC_MSG_ERROR([option value must be one of: rel, abi, auto or no])
5374                 ;;
5375         esac
5376         ],[cf_cv_shlib_version=auto])
5377         AC_MSG_RESULT($cf_cv_shlib_version)
5378
5379         cf_cv_rm_so_locs=no
5380
5381         # Some less-capable ports of gcc support only -fpic
5382         CC_SHARED_OPTS=
5383         if test "$GCC" = yes
5384         then
5385                 AC_MSG_CHECKING(which $CC option to use)
5386                 cf_save_CFLAGS="$CFLAGS"
5387                 for CC_SHARED_OPTS in -fPIC -fpic ''
5388                 do
5389                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
5390                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
5391                 done
5392                 AC_MSG_RESULT($CC_SHARED_OPTS)
5393                 CFLAGS="$cf_save_CFLAGS"
5394         fi
5395
5396         cf_cv_shlib_version_infix=no
5397
5398         case $cf_cv_system_name in #(vi
5399         aix4.[3-9]*|aix[[5-7]]*) #(vi
5400                 if test "$GCC" = yes; then
5401                         CC_SHARED_OPTS=
5402                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5403                 else
5404                         # CC_SHARED_OPTS='-qpic=large -G'
5405                         # perhaps "-bM:SRE -bnoentry -bexpall"
5406                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5407                 fi
5408                 ;;
5409         beos*) #(vi
5410                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
5411                 ;;
5412         cygwin*) #(vi
5413                 CC_SHARED_OPTS=
5414                 MK_SHARED_LIB='sh ../mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5415                 cf_cv_shlib_version=cygdll
5416                 cf_cv_shlib_version_infix=cygdll
5417                 cat >mk_shared_lib.sh <<-CF_EOF
5418                 #!/bin/sh
5419                 SHARED_LIB=\[$]1
5420                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5421                 shift
5422                 cat <<-EOF
5423                 Linking shared library
5424                 ** SHARED_LIB \[$]SHARED_LIB
5425                 ** IMPORT_LIB \[$]IMPORT_LIB
5426 EOF
5427                 exec \[$]* -shared -Wl,--out-implib=../lib/\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o ../lib/\[$]{SHARED_LIB}
5428 CF_EOF
5429                 chmod +x mk_shared_lib.sh
5430                 ;;
5431         darwin*) #(vi
5432                 EXTRA_CFLAGS="-no-cpp-precomp"
5433                 CC_SHARED_OPTS="-dynamic"
5434                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
5435                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
5436                 cf_cv_shlib_version_infix=yes
5437                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
5438                         cf_save_LDFLAGS=$LDFLAGS
5439                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5440                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
5441                                 LDFLAGS=$cf_save_LDFLAGS])
5442                 if test $cf_cv_ldflags_search_paths_first = yes; then
5443                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5444                 fi
5445                 ;;
5446         hpux*) #(vi
5447                 # (tested with gcc 2.7.2 -- I don't have c89)
5448                 if test "$GCC" = yes; then
5449                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
5450                 else
5451                         CC_SHARED_OPTS='+Z'
5452                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
5453                 fi
5454                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
5455                 # HP-UX shared libraries must be executable, and should be
5456                 # readonly to exploit a quirk in the memory manager.
5457                 INSTALL_LIB="-m 555"
5458                 ;;
5459         interix*)
5460                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5461                 if test "$cf_cv_shlib_version" = rel; then
5462                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
5463                 else
5464                         cf_shared_soname='`basename $@`'
5465                 fi
5466                 CC_SHARED_OPTS=
5467                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
5468                 ;;
5469         irix*) #(vi
5470                 if test "$cf_cv_enable_rpath" = yes ; then
5471                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5472                 fi
5473                 # tested with IRIX 5.2 and 'cc'.
5474                 if test "$GCC" != yes; then
5475                         CC_SHARED_OPTS='-KPIC'
5476                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
5477                 else
5478                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
5479                 fi
5480                 cf_cv_rm_so_locs=yes
5481                 ;;
5482         linux*|gnu*|k*bsd*-gnu) #(vi
5483                 if test "$DFT_LWR_MODEL" = "shared" ; then
5484                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5485                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5486                 fi
5487                 if test "$cf_cv_enable_rpath" = yes ; then
5488                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5489                 fi
5490                 CF_SHARED_SONAME
5491                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5492                 ;;
5493         mingw*) #(vi
5494                 cf_cv_shlib_version=mingw
5495                 cf_cv_shlib_version_infix=mingw
5496                 CC_SHARED_OPTS=
5497                 MK_SHARED_LIB='sh ../mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5498                 #MK_SHARED_LIB='${CC} ${CFLAGS} -mdll -Wl,-soname,'$cf_cv_shared_soname',-stats -o $[@]'
5499                 #MK_SHARED_LIB='${DLLTOOL} --export-all-symbols --output-exp --output-lib $[@]'
5500                 cat >mk_shared_lib.sh <<-CF_EOF
5501                 #!/bin/sh
5502                 SHARED_LIB=\[$]1
5503                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5504                 shift
5505                 cat <<-EOF
5506                 Linking shared library
5507                 ** SHARED_LIB \[$]SHARED_LIB
5508                 ** IMPORT_LIB \[$]IMPORT_LIB
5509 EOF
5510                 exec \[$]* -shared -Wl,--out-implib=../lib/\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o ../lib/\[$]{SHARED_LIB}
5511 CF_EOF
5512                 chmod +x mk_shared_lib.sh
5513                 ;;
5514         openbsd[[2-9]].*|mirbsd*) #(vi
5515                 if test "$DFT_LWR_MODEL" = "shared" ; then
5516                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5517                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5518                 fi
5519                 if test "$cf_cv_enable_rpath" = yes ; then
5520                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5521                 fi
5522                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5523                 CF_SHARED_SONAME
5524                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5525                 ;;
5526         nto-qnx*|openbsd*|freebsd[[12]].*) #(vi
5527                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5528                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
5529                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5530                 ;;
5531         dragonfly*|freebsd*) #(vi
5532                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5533                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5534                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5535                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
5536                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5537                 fi
5538                 CF_SHARED_SONAME
5539                 MK_SHARED_LIB='${LD} -shared -Bshareable -soname=`basename $[@]` -o $[@]'
5540                 ;;
5541         netbsd*) #(vi
5542                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5543                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5544                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5545                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5546                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5547                         if test "$cf_cv_shlib_version" = auto; then
5548                         if test -f /usr/libexec/ld.elf_so; then
5549                                 cf_cv_shlib_version=abi
5550                         else
5551                                 cf_cv_shlib_version=rel
5552                         fi
5553                         fi
5554                         CF_SHARED_SONAME
5555                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
5556                 else
5557                         MK_SHARED_LIB='${LD} -shared -Bshareable -o $[@]'
5558                 fi
5559                 ;;
5560         osf*|mls+*) #(vi
5561                 # tested with OSF/1 V3.2 and 'cc'
5562                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
5563                 # link with shared libs).
5564                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
5565                 case $host_os in #(vi
5566                 osf4*)
5567                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
5568                         ;;
5569                 esac
5570                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
5571                 if test "$DFT_LWR_MODEL" = "shared" ; then
5572                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5573                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5574                 fi
5575                 cf_cv_rm_so_locs=yes
5576                 ;;
5577         sco3.2v5*)  # (also uw2* and UW7: hops 13-Apr-98
5578                 # tested with osr5.0.5
5579                 if test "$GCC" != yes; then
5580                         CC_SHARED_OPTS='-belf -KPIC'
5581                 fi
5582                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
5583                 if test "$cf_cv_enable_rpath" = yes ; then
5584                         # only way is to set LD_RUN_PATH but no switch for it
5585                         RUN_PATH=$libdir
5586                 fi
5587                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5588                 LINK_PROGS='LD_RUN_PATH=${libdir}'
5589                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
5590                 ;;
5591         sunos4*) #(vi
5592                 # tested with SunOS 4.1.1 and gcc 2.7.0
5593                 if test "$GCC" != yes; then
5594                         CC_SHARED_OPTS='-KPIC'
5595                 fi
5596                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
5597                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5598                 ;;
5599         solaris2*) #(vi
5600                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
5601                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
5602                 if test "$DFT_LWR_MODEL" = "shared" ; then
5603                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
5604                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5605                 fi
5606                 if test "$cf_cv_enable_rpath" = yes ; then
5607                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
5608                 fi
5609                 CF_SHARED_SONAME
5610                 if test "$GCC" != yes; then
5611                         cf_save_CFLAGS="$CFLAGS"
5612                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
5613                         do
5614                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
5615                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
5616                         done
5617                         CFLAGS="$cf_save_CFLAGS"
5618                         CC_SHARED_OPTS=$cf_shared_opts
5619                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5620                 else
5621                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5622                 fi
5623                 ;;
5624         sysv5uw7*|unix_sv*) #(vi
5625                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
5626                 if test "$GCC" != yes; then
5627                         CC_SHARED_OPTS='-KPIC'
5628                 fi
5629                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
5630                 ;;
5631         *)
5632                 CC_SHARED_OPTS='unknown'
5633                 MK_SHARED_LIB='echo unknown'
5634                 ;;
5635         esac
5636
5637         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
5638         case "$cf_cv_shlib_version" in #(vi
5639         rel|abi)
5640                 case "$MK_SHARED_LIB" in #(vi
5641                 *'-o $[@]') #(vi
5642                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
5643                         ;;
5644                 *)
5645                         AC_MSG_WARN(ignored --with-shlib-version)
5646                         ;;
5647                 esac
5648                 ;;
5649         esac
5650
5651         # RPATH_LIST is a colon-separated list of directories
5652         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
5653         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
5654
5655         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
5656         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
5657
5658         AC_SUBST(CC_SHARED_OPTS)
5659         AC_SUBST(LD_RPATH_OPT)
5660         AC_SUBST(LD_SHARED_OPTS)
5661         AC_SUBST(MK_SHARED_LIB)
5662         AC_SUBST(LINK_PROGS)
5663         AC_SUBST(LINK_TESTS)
5664         AC_SUBST(EXTRA_LDFLAGS)
5665         AC_SUBST(LOCAL_LDFLAGS)
5666         AC_SUBST(LOCAL_LDFLAGS2)
5667         AC_SUBST(INSTALL_LIB)
5668         AC_SUBST(RPATH_LIST)
5669 ])dnl
5670 dnl ---------------------------------------------------------------------------
5671 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
5672 dnl ----------------
5673 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
5674 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
5675 dnl option.
5676 dnl
5677 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
5678 dnl If missing, use "rel".
5679 define([CF_SHARED_SONAME],
5680 [
5681         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
5682         if test "$cf_cv_shlib_version" = rel; then
5683                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
5684         else
5685                 cf_cv_shared_soname='`basename $[@]`'
5686         fi
5687 ])
5688 dnl ---------------------------------------------------------------------------
5689 dnl CF_SIGWINCH version: 1 updated: 2006/04/02 16:41:09
5690 dnl -----------
5691 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
5692 dnl programs need this test).
5693 dnl
5694 dnl This is really a MacOS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
5695 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
5696 dnl winsize declaration is left alone - we may revisit this if Apple choose to
5697 dnl break that part of the interface as well.
5698 AC_DEFUN([CF_SIGWINCH],
5699 [
5700 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
5701         AC_TRY_COMPILE([
5702 #include <sys/types.h>
5703 #include <sys/signal.h>
5704 ],[int x = SIGWINCH],
5705         [cf_cv_define_sigwinch=yes],
5706         [AC_TRY_COMPILE([
5707 #undef _XOPEN_SOURCE
5708 #undef _POSIX_SOURCE
5709 #undef _POSIX_C_SOURCE
5710 #include <sys/types.h>
5711 #include <sys/signal.h>
5712 ],[int x = SIGWINCH],
5713         [cf_cv_define_sigwinch=maybe],
5714         [cf_cv_define_sigwinch=no])
5715 ])
5716 ])
5717
5718 if test "$cf_cv_define_sigwinch" = maybe ; then
5719 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
5720 cf_cv_fixup_sigwinch=unknown
5721 cf_sigwinch=32
5722 while test $cf_sigwinch != 1
5723 do
5724         AC_TRY_COMPILE([
5725 #undef _XOPEN_SOURCE
5726 #undef _POSIX_SOURCE
5727 #undef _POSIX_C_SOURCE
5728 #include <sys/types.h>
5729 #include <sys/signal.h>
5730 ],[
5731 #if SIGWINCH != $cf_sigwinch
5732 make an error
5733 #endif
5734 int x = SIGWINCH],
5735         [cf_cv_fixup_sigwinch=$cf_sigwinch
5736          break])
5737
5738 cf_sigwinch=`expr $cf_sigwinch - 1`
5739 done
5740 ])
5741
5742         if test "$cf_cv_fixup_sigwinch" != unknown ; then
5743                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
5744         fi
5745 fi
5746 ])dnl
5747 dnl ---------------------------------------------------------------------------
5748 dnl CF_SIG_ATOMIC_T version: 2 updated: 2005/09/18 17:27:12
5749 dnl ---------------
5750 dnl signal handler, but there are some gcc depedencies in that recommendation.
5751 dnl Try anyway.
5752 AC_DEFUN([CF_SIG_ATOMIC_T],
5753 [
5754 AC_MSG_CHECKING(for signal global datatype)
5755 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
5756         for cf_type in \
5757                 "volatile sig_atomic_t" \
5758                 "sig_atomic_t" \
5759                 "int"
5760         do
5761         AC_TRY_COMPILE([
5762 #include <sys/types.h>
5763 #include <signal.h>
5764 #include <stdio.h>
5765
5766 extern $cf_type x;
5767 $cf_type x;
5768 static void handler(int sig)
5769 {
5770         x = 5;
5771 }],
5772                 [signal(SIGINT, handler);
5773                  x = 1],
5774                 [cf_cv_sig_atomic_t=$cf_type],
5775                 [cf_cv_sig_atomic_t=no])
5776                 test "$cf_cv_sig_atomic_t" != no && break
5777         done
5778         ])
5779 AC_MSG_RESULT($cf_cv_sig_atomic_t)
5780 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t)
5781 ])dnl
5782 dnl ---------------------------------------------------------------------------
5783 dnl CF_SIZECHANGE version: 8 updated: 2000/11/04 12:22:16
5784 dnl -------------
5785 dnl Check for definitions & structures needed for window size-changing
5786 dnl FIXME: check that this works with "snake" (HP-UX 10.x)
5787 AC_DEFUN([CF_SIZECHANGE],
5788 [
5789 AC_REQUIRE([CF_STRUCT_TERMIOS])
5790 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
5791     cf_cv_sizechange=unknown
5792     cf_save_CPPFLAGS="$CPPFLAGS"
5793
5794 for cf_opts in "" "NEED_PTEM_H"
5795 do
5796
5797     CPPFLAGS="$cf_save_CPPFLAGS"
5798     test -n "$cf_opts" && CPPFLAGS="$CPPFLAGS -D$cf_opts"
5799     AC_TRY_COMPILE([#include <sys/types.h>
5800 #ifdef HAVE_TERMIOS_H
5801 #include <termios.h>
5802 #else
5803 #ifdef HAVE_TERMIO_H
5804 #include <termio.h>
5805 #endif
5806 #endif
5807 #ifdef NEED_PTEM_H
5808 /* This is a workaround for SCO:  they neglected to define struct winsize in
5809  * termios.h -- it's only in termio.h and ptem.h
5810  */
5811 #include        <sys/stream.h>
5812 #include        <sys/ptem.h>
5813 #endif
5814 #if !defined(sun) || !defined(HAVE_TERMIOS_H)
5815 #include <sys/ioctl.h>
5816 #endif
5817 ],[
5818 #ifdef TIOCGSIZE
5819         struct ttysize win;     /* FIXME: what system is this? */
5820         int y = win.ts_lines;
5821         int x = win.ts_cols;
5822 #else
5823 #ifdef TIOCGWINSZ
5824         struct winsize win;
5825         int y = win.ws_row;
5826         int x = win.ws_col;
5827 #else
5828         no TIOCGSIZE or TIOCGWINSZ
5829 #endif /* TIOCGWINSZ */
5830 #endif /* TIOCGSIZE */
5831         ],
5832         [cf_cv_sizechange=yes],
5833         [cf_cv_sizechange=no])
5834
5835         CPPFLAGS="$cf_save_CPPFLAGS"
5836         if test "$cf_cv_sizechange" = yes ; then
5837                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
5838                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
5839                 break
5840         fi
5841 done
5842 ])
5843 if test "$cf_cv_sizechange" != no ; then
5844         AC_DEFINE(HAVE_SIZECHANGE)
5845         case $cf_cv_sizechange in #(vi
5846         NEED*)
5847                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
5848                 ;;
5849         esac
5850 fi
5851 ])dnl
5852 dnl ---------------------------------------------------------------------------
5853 dnl CF_SRC_MODULES version: 26 updated: 2012/01/07 15:08:24
5854 dnl --------------
5855 dnl For each parameter, test if the source-directory exists, and if it contains
5856 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
5857 dnl use in CF_LIB_RULES.
5858 dnl
5859 dnl This uses the configured value to make the lists SRC_SUBDIRS and
5860 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
5861 AC_DEFUN([CF_SRC_MODULES],
5862 [
5863 AC_MSG_CHECKING(for src modules)
5864
5865 # dependencies and linker-arguments for test-programs
5866 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
5867 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
5868 if test "$DFT_LWR_MODEL" = "libtool"; then
5869         TEST_ARGS="${TEST_DEPS}"
5870         TEST_ARG2="${TEST_DEP2}"
5871 else
5872         TEST_ARGS="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARGS"
5873         TEST_ARG2="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARG2"
5874 fi
5875
5876 PC_MODULES_TO_MAKE="ncurses${DFT_ARG_SUFFIX}"
5877 cf_cv_src_modules=
5878 for cf_dir in $1
5879 do
5880         if test -f $srcdir/$cf_dir/modules; then
5881
5882                 # We may/may not have tack in the distribution, though the
5883                 # makefile is.
5884                 if test $cf_dir = tack ; then
5885                         if test ! -f $srcdir/${cf_dir}/${cf_dir}.h; then
5886                                 continue
5887                         fi
5888                 fi
5889
5890                 if test -z "$cf_cv_src_modules"; then
5891                         cf_cv_src_modules=$cf_dir
5892                 else
5893                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
5894                 fi
5895
5896                 # Make the ncurses_cfg.h file record the library interface files as
5897                 # well.  These are header files that are the same name as their
5898                 # directory.  Ncurses is the only library that does not follow
5899                 # that pattern.
5900                 if test $cf_dir = tack ; then
5901                         continue
5902                 elif test -f $srcdir/${cf_dir}/${cf_dir}.h; then
5903                         CF_UPPER(cf_have_include,$cf_dir)
5904                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
5905                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
5906                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEPS"
5907                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEP2"
5908                         if test "$DFT_LWR_MODEL" = "libtool"; then
5909                                 TEST_ARGS="${TEST_DEPS}"
5910                                 TEST_ARG2="${TEST_DEP2}"
5911                         else
5912                                 TEST_ARGS="-l${cf_dir}${DFT_ARG_SUFFIX} $TEST_ARGS"
5913                                 TEST_ARG2="-l${cf_dir}${DFT_ARG_SUFFIX} $TEST_ARG2"
5914                         fi
5915                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${DFT_ARG_SUFFIX}"
5916                 fi
5917         fi
5918 done
5919 AC_MSG_RESULT($cf_cv_src_modules)
5920
5921 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
5922 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
5923
5924 AC_SUBST(TEST_ARGS)
5925 AC_SUBST(TEST_DEPS)
5926
5927 AC_SUBST(TEST_ARG2)
5928 AC_SUBST(TEST_DEP2)
5929
5930 SRC_SUBDIRS=
5931 if test "x$cf_with_manpages" != xno ; then
5932         SRC_SUBDIRS="$SRC_SUBDIRS man"
5933 fi
5934 SRC_SUBDIRS="$SRC_SUBDIRS include"
5935 for cf_dir in $cf_cv_src_modules
5936 do
5937         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
5938 done
5939 if test "x$cf_with_tests" != "xno" ; then
5940         SRC_SUBDIRS="$SRC_SUBDIRS test"
5941 fi
5942 test -z "$MAKE_TERMINFO" && SRC_SUBDIRS="$SRC_SUBDIRS misc"
5943 if test "$cf_with_cxx_binding" != no; then
5944         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${DFT_ARG_SUFFIX}"
5945         SRC_SUBDIRS="$SRC_SUBDIRS c++"
5946 fi
5947
5948 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
5949 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
5950
5951 AC_SUBST(PC_MODULES_TO_MAKE)
5952
5953 ADA_SUBDIRS=
5954 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f $srcdir/Ada95/Makefile.in; then
5955         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
5956         ADA_SUBDIRS="gen src"
5957         if test "x$cf_with_tests" != "xno" ; then
5958                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
5959         fi
5960 fi
5961
5962 SUB_MAKEFILES=
5963 for cf_dir in $SRC_SUBDIRS
5964 do
5965         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
5966 done
5967
5968 if test -n "$ADA_SUBDIRS"; then
5969         for cf_dir in $ADA_SUBDIRS
5970         do
5971                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
5972         done
5973         AC_SUBST(ADA_SUBDIRS)
5974 fi
5975 ])dnl
5976 dnl ---------------------------------------------------------------------------
5977 dnl CF_STDCPP_LIBRARY version: 7 updated: 2010/05/29 16:31:02
5978 dnl -----------------
5979 dnl Check for -lstdc++, which is GNU's standard C++ library.
5980 AC_DEFUN([CF_STDCPP_LIBRARY],
5981 [
5982 if test -n "$GXX" ; then
5983 case $cf_cv_system_name in #(vi
5984 os2*) #(vi
5985         cf_stdcpp_libname=stdcpp
5986         ;;
5987 *)
5988         cf_stdcpp_libname=stdc++
5989         ;;
5990 esac
5991 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
5992         cf_save="$LIBS"
5993         CF_ADD_LIB($cf_stdcpp_libname)
5994 AC_TRY_LINK([
5995 #include <strstream.h>],[
5996 char buf[80];
5997 strstreambuf foo(buf, sizeof(buf))
5998 ],
5999         [cf_cv_libstdcpp=yes],
6000         [cf_cv_libstdcpp=no])
6001         LIBS="$cf_save"
6002 ])
6003 test "$cf_cv_libstdcpp" = yes && CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS)
6004 fi
6005 ])dnl
6006 dnl ---------------------------------------------------------------------------
6007 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
6008 dnl --------------
6009 dnl     Remove "-g" option from the compiler options
6010 AC_DEFUN([CF_STRIP_G_OPT],
6011 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
6012 dnl ---------------------------------------------------------------------------
6013 dnl CF_STRUCT_SIGACTION version: 4 updated: 2011/04/16 11:52:53
6014 dnl -------------------
6015 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
6016 dnl do this if we've found the sigaction function.
6017 AC_DEFUN([CF_STRUCT_SIGACTION],[
6018 AC_REQUIRE([CF_XOPEN_SOURCE])
6019
6020 if test "$ac_cv_func_sigaction" = yes; then
6021 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
6022 AC_TRY_COMPILE([
6023 #include <sys/types.h>
6024 #include <signal.h>],
6025         [struct sigaction act],
6026         [sigact_bad=no],
6027         [
6028 AC_TRY_COMPILE([
6029 #define _POSIX_SOURCE
6030 #include <sys/types.h>
6031 #include <signal.h>],
6032         [struct sigaction act],
6033         [sigact_bad=yes
6034          AC_DEFINE(_POSIX_SOURCE)],
6035          [sigact_bad=unknown])])
6036 AC_MSG_RESULT($sigact_bad)
6037 fi
6038 ])dnl
6039 dnl ---------------------------------------------------------------------------
6040 dnl CF_STRUCT_TERMIOS version: 6 updated: 2011/04/16 11:52:53
6041 dnl -----------------
6042 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
6043 AC_DEFUN([CF_STRUCT_TERMIOS],[
6044 AC_REQUIRE([CF_XOPEN_SOURCE])
6045
6046 AC_CHECK_HEADERS( \
6047 termio.h \
6048 termios.h \
6049 unistd.h \
6050 )
6051
6052 if test "$ISC" = yes ; then
6053         AC_CHECK_HEADERS( sys/termio.h )
6054 fi
6055 if test "$ac_cv_header_termios_h" = yes ; then
6056         case "$CFLAGS $CPPFLAGS" in
6057         *-D_POSIX_SOURCE*)
6058                 termios_bad=dunno ;;
6059         *)      termios_bad=maybe ;;
6060         esac
6061         if test "$termios_bad" = maybe ; then
6062         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
6063         AC_TRY_COMPILE([#include <termios.h>],
6064                 [struct termios foo; int x = foo.c_iflag],
6065                 termios_bad=no, [
6066                 AC_TRY_COMPILE([
6067 #define _POSIX_SOURCE
6068 #include <termios.h>],
6069                         [struct termios foo; int x = foo.c_iflag],
6070                         termios_bad=unknown,
6071                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE))
6072                         ])
6073         AC_MSG_RESULT($termios_bad)
6074         fi
6075 fi
6076 ])dnl
6077 dnl ---------------------------------------------------------------------------
6078 dnl CF_SUBDIR_PATH version: 6 updated: 2010/04/21 06:20:50
6079 dnl --------------
6080 dnl Construct a search-list for a nonstandard header/lib-file
6081 dnl     $1 = the variable to return as result
6082 dnl     $2 = the package name
6083 dnl     $3 = the subdirectory, e.g., bin, include or lib
6084 AC_DEFUN([CF_SUBDIR_PATH],
6085 [
6086 $1=
6087
6088 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr,$prefix)
6089 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
6090 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr/local,$prefix)
6091 CF_ADD_SUBDIR_PATH($1,$2,$3,/opt,$prefix)
6092 CF_ADD_SUBDIR_PATH($1,$2,$3,[$]HOME,$prefix)
6093 ])dnl
6094 dnl ---------------------------------------------------------------------------
6095 dnl CF_SUBST version: 4 updated: 2006/06/17 12:33:03
6096 dnl --------
6097 dnl     Shorthand macro for substituting things that the user may override
6098 dnl     with an environment variable.
6099 dnl
6100 dnl     $1 = long/descriptive name
6101 dnl     $2 = environment variable
6102 dnl     $3 = default value
6103 AC_DEFUN([CF_SUBST],
6104 [AC_CACHE_VAL(cf_cv_subst_$2,[
6105 AC_MSG_CHECKING(for $1 (symbol $2))
6106 CF_SUBST_IF([-z "[$]$2"], [$2], [$3])
6107 cf_cv_subst_$2=[$]$2
6108 AC_MSG_RESULT([$]$2)
6109 ])
6110 ])dnl
6111 dnl ---------------------------------------------------------------------------
6112 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
6113 dnl -----------
6114 dnl     Shorthand macro for substituting things that the user may override
6115 dnl     with an environment variable.
6116 dnl
6117 dnl     $1 = condition to pass to "test"
6118 dnl     $2 = environment variable
6119 dnl     $3 = value if the test succeeds
6120 dnl     $4 = value if the test fails
6121 AC_DEFUN([CF_SUBST_IF],
6122 [
6123 if test $1 ; then
6124         $2=$3
6125 ifelse($4,,,[else
6126         $2=$4])
6127 fi
6128 AC_SUBST($2)
6129 ])dnl
6130 dnl ---------------------------------------------------------------------------
6131 dnl CF_SUBST_NCURSES_VERSION version: 8 updated: 2006/09/16 11:40:59
6132 dnl ------------------------
6133 dnl Get the version-number for use in shared-library naming, etc.
6134 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
6135 [
6136 AC_REQUIRE([CF_PROG_EGREP])
6137 NCURSES_MAJOR="`$ac_cv_prog_egrep '^NCURSES_MAJOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6138 NCURSES_MINOR="`$ac_cv_prog_egrep '^NCURSES_MINOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6139 NCURSES_PATCH="`$ac_cv_prog_egrep '^NCURSES_PATCH[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6140 cf_cv_abi_version=${NCURSES_MAJOR}
6141 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
6142 dnl Show the computed version, for logging
6143 cf_cv_timestamp=`date`
6144 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
6145 dnl We need these values in the generated headers
6146 AC_SUBST(NCURSES_MAJOR)
6147 AC_SUBST(NCURSES_MINOR)
6148 AC_SUBST(NCURSES_PATCH)
6149 dnl We need these values in the generated makefiles
6150 AC_SUBST(cf_cv_rel_version)
6151 AC_SUBST(cf_cv_abi_version)
6152 AC_SUBST(cf_cv_builtin_bool)
6153 AC_SUBST(cf_cv_header_stdbool_h)
6154 AC_SUBST(cf_cv_type_of_bool)dnl
6155 ])dnl
6156 dnl ---------------------------------------------------------------------------
6157 dnl CF_SYS_TIME_SELECT version: 4 updated: 2000/10/04 09:18:40
6158 dnl ------------------
6159 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
6160 dnl older SCO configurations.
6161 AC_DEFUN([CF_SYS_TIME_SELECT],
6162 [
6163 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
6164 AC_CACHE_VAL(cf_cv_sys_time_select,[
6165 AC_TRY_COMPILE([
6166 #include <sys/types.h>
6167 #ifdef HAVE_SYS_TIME_H
6168 #include <sys/time.h>
6169 #endif
6170 #ifdef HAVE_SYS_SELECT_H
6171 #include <sys/select.h>
6172 #endif
6173 ],[],[cf_cv_sys_time_select=yes],
6174      [cf_cv_sys_time_select=no])
6175      ])
6176 AC_MSG_RESULT($cf_cv_sys_time_select)
6177 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT)
6178 ])dnl
6179 dnl ---------------------------------------------------------------------------
6180 dnl CF_TOP_BUILDDIR version: 1 updated: 2006/10/15 16:33:23
6181 dnl ---------------
6182 dnl Define a top_builddir symbol, for applications that need an absolute path.
6183 AC_DEFUN([CF_TOP_BUILDDIR],
6184 [
6185 top_builddir=`pwd`
6186 AC_SUBST(top_builddir)
6187 ])dnl
6188 dnl ---------------------------------------------------------------------------
6189 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
6190 dnl -------------------
6191 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
6192 dnl can define it successfully.
6193 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
6194 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
6195         AC_TRY_COMPILE([
6196 #include <stdlib.h>
6197 #include <string.h>
6198 #include <sys/types.h>
6199 ],[
6200 #ifndef _XOPEN_SOURCE
6201 make an error
6202 #endif],
6203         [cf_cv_xopen_source=no],
6204         [cf_save="$CPPFLAGS"
6205          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
6206          AC_TRY_COMPILE([
6207 #include <stdlib.h>
6208 #include <string.h>
6209 #include <sys/types.h>
6210 ],[
6211 #ifdef _XOPEN_SOURCE
6212 make an error
6213 #endif],
6214         [cf_cv_xopen_source=no],
6215         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
6216         CPPFLAGS="$cf_save"
6217         ])
6218 ])
6219
6220 if test "$cf_cv_xopen_source" != no ; then
6221         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
6222         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
6223         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
6224         CF_ADD_CFLAGS($cf_temp_xopen_source)
6225 fi
6226 ])
6227 dnl ---------------------------------------------------------------------------
6228 dnl CF_TYPEOF_CHTYPE version: 8 updated: 2006/12/16 12:33:30
6229 dnl ----------------
6230 dnl Determine the type we should use for chtype (and attr_t, which is treated
6231 dnl as the same thing).  We want around 32 bits, so on most machines want a
6232 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
6233 dnl wide characters, we have to have a type compatible with that, as well.
6234 AC_DEFUN([CF_TYPEOF_CHTYPE],
6235 [
6236 AC_MSG_CHECKING([for type of chtype])
6237 AC_CACHE_VAL(cf_cv_typeof_chtype,[
6238                 AC_TRY_RUN([
6239 #define WANT_BITS 31
6240 #include <stdio.h>
6241 int main()
6242 {
6243         FILE *fp = fopen("cf_test.out", "w");
6244         if (fp != 0) {
6245                 char *result = "long";
6246                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
6247                         int n;
6248                         unsigned int x, y;
6249                         for (n = 0; n < WANT_BITS; n++) {
6250                                 x = (1 << n);
6251                                 y = (x >> n);
6252                                 if (y != 1 || x == 0) {
6253                                         x = 0;
6254                                         break;
6255                                 }
6256                         }
6257                         /*
6258                          * If x is nonzero, an int is big enough for the bits
6259                          * that we want.
6260                          */
6261                         result = (x != 0) ? "int" : "long";
6262                 }
6263                 fputs(result, fp);
6264                 fclose(fp);
6265         }
6266         ${cf_cv_main_return:-return}(0);
6267 }
6268                 ],
6269                 [cf_cv_typeof_chtype=`cat cf_test.out`],
6270                 [cf_cv_typeof_chtype=long],
6271                 [cf_cv_typeof_chtype=long])
6272                 rm -f cf_test.out
6273         ])
6274 AC_MSG_RESULT($cf_cv_typeof_chtype)
6275
6276 AC_SUBST(cf_cv_typeof_chtype)
6277 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype)
6278 ])dnl
6279 dnl ---------------------------------------------------------------------------
6280 dnl CF_TYPE_SIGACTION version: 3 updated: 2000/08/12 23:18:52
6281 dnl -----------------
6282 dnl
6283 AC_DEFUN([CF_TYPE_SIGACTION],
6284 [
6285 AC_MSG_CHECKING([for type sigaction_t])
6286 AC_CACHE_VAL(cf_cv_type_sigaction,[
6287         AC_TRY_COMPILE([
6288 #include <signal.h>],
6289                 [sigaction_t x],
6290                 [cf_cv_type_sigaction=yes],
6291                 [cf_cv_type_sigaction=no])])
6292 AC_MSG_RESULT($cf_cv_type_sigaction)
6293 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION)
6294 ])dnl
6295 dnl ---------------------------------------------------------------------------
6296 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
6297 dnl --------------------
6298 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
6299 dnl won't, but they're still there.
6300 AC_DEFUN([CF_UNSIGNED_LITERALS],
6301 [
6302 AC_MSG_CHECKING([if unsigned literals are legal])
6303 AC_CACHE_VAL(cf_cv_unsigned_literals,[
6304         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
6305                 [cf_cv_unsigned_literals=yes],
6306                 [cf_cv_unsigned_literals=no])
6307         ])
6308 AC_MSG_RESULT($cf_cv_unsigned_literals)
6309 ])dnl
6310 dnl ---------------------------------------------------------------------------
6311 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
6312 dnl --------
6313 dnl Make an uppercase version of a variable
6314 dnl $1=uppercase($2)
6315 AC_DEFUN([CF_UPPER],
6316 [
6317 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
6318 ])dnl
6319 dnl ---------------------------------------------------------------------------
6320 dnl CF_UTF8_LIB version: 7 updated: 2010/06/20 09:24:28
6321 dnl -----------
6322 dnl Check for multibyte support, and if not found, utf8 compatibility library
6323 AC_DEFUN([CF_UTF8_LIB],
6324 [
6325 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
6326         cf_save_LIBS="$LIBS"
6327         AC_TRY_LINK([
6328 #include <stdlib.h>],[putwc(0,0);],
6329         [cf_cv_utf8_lib=yes],
6330         [CF_FIND_LINKAGE([
6331 #include <libutf8.h>],[putwc(0,0);],utf8,
6332                 [cf_cv_utf8_lib=add-on],
6333                 [cf_cv_utf8_lib=no])
6334 ])])
6335
6336 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
6337 # ncurses/ncursesw:
6338 if test "$cf_cv_utf8_lib" = "add-on" ; then
6339         AC_DEFINE(HAVE_LIBUTF8_H)
6340         CF_ADD_INCDIR($cf_cv_header_path_utf8)
6341         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
6342         CF_ADD_LIBS($cf_cv_library_file_utf8)
6343 fi
6344 ])dnl
6345 dnl ---------------------------------------------------------------------------
6346 dnl CF_VA_COPY version: 2 updated: 2010/03/04 05:37:29
6347 dnl ----------
6348 dnl check for va_copy, part of stdarg.h
6349 dnl Also, workaround for glibc's __va_copy, by checking for both.
6350 AC_DEFUN([CF_VA_COPY],[
6351 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
6352 AC_TRY_LINK([
6353 #include <stdarg.h>
6354 ],[
6355         static va_list dst;
6356         static va_list src;
6357         va_copy(dst, src)],
6358         cf_cv_have_va_copy=yes,
6359         cf_cv_have_va_copy=no)])
6360
6361 test "$cf_cv_have_va_copy" = yes && AC_DEFINE(HAVE_VA_COPY)
6362
6363 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
6364 AC_TRY_LINK([
6365 #include <stdarg.h>
6366 ],[
6367         static va_list dst;
6368         static va_list src;
6369         __va_copy(dst, src)],
6370         cf_cv_have___va_copy=yes,
6371         cf_cv_have___va_copy=no)])
6372
6373 test "$cf_cv_have___va_copy" = yes && AC_DEFINE(HAVE___VA_COPY)
6374 ])
6375 dnl ---------------------------------------------------------------------------
6376 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
6377 dnl ----------
6378 dnl Use AC_VERBOSE w/o the warnings
6379 AC_DEFUN([CF_VERBOSE],
6380 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
6381 CF_MSG_LOG([$1])
6382 ])dnl
6383 dnl ---------------------------------------------------------------------------
6384 dnl CF_WCHAR_TYPE version: 3 updated: 2010/05/26 16:44:57
6385 dnl -------------
6386 dnl Check if type wide-character type $1 is declared, and if so, which header
6387 dnl file is needed.  The second parameter is used to set a shell variable when
6388 dnl the type is not found.  The first parameter sets a shell variable for the
6389 dnl opposite sense.
6390 AC_DEFUN([CF_WCHAR_TYPE],
6391 [
6392 # This is needed on Tru64 5.0 to declare $1
6393 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
6394 AC_TRY_COMPILE([
6395 #include <stdlib.h>
6396 #include <stdarg.h>
6397 #include <stdio.h>
6398 #ifdef HAVE_LIBUTF8_H
6399 #include <libutf8.h>
6400 #endif],
6401         [$1 state],
6402         [cf_cv_$1=no],
6403         [AC_TRY_COMPILE([
6404 #include <stdlib.h>
6405 #include <stdarg.h>
6406 #include <stdio.h>
6407 #include <wchar.h>
6408 #ifdef HAVE_LIBUTF8_H
6409 #include <libutf8.h>
6410 #endif],
6411         [$1 value],
6412         [cf_cv_$1=yes],
6413         [cf_cv_$1=unknown])])])
6414
6415 if test "$cf_cv_$1" = yes ; then
6416         AC_DEFINE(NEED_WCHAR_H)
6417         NEED_WCHAR_H=1
6418 fi
6419
6420 ifelse([$2],,,[
6421 # if we do not find $1 in either place, use substitution to provide a fallback.
6422 if test "$cf_cv_$1" = unknown ; then
6423         $2=1
6424 fi
6425 ])
6426 ifelse($3,,,[
6427 # if we find $1 in either place, use substitution to provide a fallback.
6428 if test "$cf_cv_$1" != unknown ; then
6429         $3=1
6430 fi
6431 ])
6432 ])dnl
6433 dnl ---------------------------------------------------------------------------
6434 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
6435 dnl ---------------
6436 dnl Check for compiler-support for weak symbols.
6437 dnl This works with "recent" gcc.
6438 AC_DEFUN([CF_WEAK_SYMBOLS],[
6439 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
6440
6441 AC_TRY_COMPILE([
6442 #include <stdio.h>],
6443 [
6444 #if defined(__GNUC__)
6445 #  if defined __USE_ISOC99
6446 #    define _cat_pragma(exp)    _Pragma(#exp)
6447 #    define _weak_pragma(exp)   _cat_pragma(weak name)
6448 #  else
6449 #    define _weak_pragma(exp)
6450 #  endif
6451 #  define _declare(name)        __extension__ extern __typeof__(name) name
6452 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
6453 #endif
6454
6455 weak_symbol(fopen);
6456 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
6457 ])
6458 ])dnl
6459 dnl ---------------------------------------------------------------------------
6460 dnl CF_WITH_ABI_VERSION version: 1 updated: 2003/09/20 18:12:49
6461 dnl -------------------
6462 dnl Allow library's ABI to be overridden.  Generally this happens when a
6463 dnl packager has incremented the ABI past that used in the original package,
6464 dnl and wishes to keep doing this.
6465 dnl
6466 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
6467 dnl symbol.
6468 AC_DEFUN([CF_WITH_ABI_VERSION],[
6469 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
6470 AC_ARG_WITH(abi-version,
6471 [  --with-abi-version=XXX  override derived ABI version],
6472 [AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
6473  cf_cv_abi_version=$withval])
6474  CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
6475 ifelse($1,,,[
6476 $1_ABI=$cf_cv_abi_version
6477 ])
6478 ])dnl
6479 dnl ---------------------------------------------------------------------------
6480 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
6481 dnl --------------------
6482 dnl Command-line option to specify the Ada95 compiler.
6483 AC_DEFUN([CF_WITH_ADA_COMPILER],[
6484 AC_MSG_CHECKING(for ada-compiler)
6485 AC_ARG_WITH(ada-compiler,
6486         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
6487         [cf_ada_compiler=$withval],
6488         [cf_ada_compiler=gnatmake])
6489 AC_SUBST(cf_ada_compiler)
6490 AC_MSG_RESULT($cf_ada_compiler)
6491 ])dnl
6492 dnl ---------------------------------------------------------------------------
6493 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
6494 dnl -------------------
6495 dnl Command-line option to specify where Ada includes will install.
6496 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
6497 AC_MSG_CHECKING(for ada-include)
6498 CF_WITH_PATH(ada-include,
6499    [  --with-ada-include=DIR  Ada includes are in DIR],
6500    ADA_INCLUDE,
6501    PREFIX/share/ada/adainclude,
6502    [$]prefix/share/ada/adainclude)
6503 AC_SUBST(ADA_INCLUDE)
6504 AC_MSG_RESULT($ADA_INCLUDE)
6505 ])dnl
6506 dnl ---------------------------------------------------------------------------
6507 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
6508 dnl -------------------
6509 dnl Command-line option to specify where Ada objects will install.
6510 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
6511 AC_MSG_CHECKING(for ada-objects)
6512 CF_WITH_PATH(ada-objects,
6513    [  --with-ada-objects=DIR  Ada objects are in DIR],
6514    ADA_OBJECTS,
6515    PREFIX/lib/ada/adalib,
6516    [$]prefix/lib/ada/adalib)
6517 AC_SUBST(ADA_OBJECTS)
6518 AC_MSG_RESULT($ADA_OBJECTS)
6519 ])dnl
6520 dnl ---------------------------------------------------------------------------
6521 dnl CF_WITH_ADA_SHAREDLIB version: 2 updated: 2010/06/26 17:35:58
6522 dnl ---------------------
6523 dnl Command-line option to specify if an Ada95 shared-library should be built,
6524 dnl and optionally what its soname should be.
6525 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
6526 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
6527 AC_ARG_WITH(ada-sharedlib,
6528         [  --with-ada-sharedlib=XX build Ada95 shared-library],
6529         [with_ada_sharedlib=$withval],
6530         [with_ada_sharedlib=no])
6531 AC_MSG_RESULT($with_ada_sharedlib)
6532
6533 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
6534 MAKE_ADA_SHAREDLIB="#"
6535
6536 if test "x$with_ada_sharedlib" != xno
6537 then
6538         MAKE_ADA_SHAREDLIB=
6539         if test "x$with_ada_sharedlib" != xyes
6540         then
6541                 ADA_SHAREDLIB="$with_ada_sharedlib"
6542         fi
6543 fi
6544
6545 AC_SUBST(ADA_SHAREDLIB)
6546 AC_SUBST(MAKE_ADA_SHAREDLIB)
6547 ])dnl
6548 dnl ---------------------------------------------------------------------------
6549 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
6550 dnl ----------------
6551 dnl Configure-option for dbmalloc.  The optional parameter is used to override
6552 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6553 AC_DEFUN([CF_WITH_DBMALLOC],[
6554 CF_NO_LEAKS_OPTION(dbmalloc,
6555         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
6556         [USE_DBMALLOC])
6557
6558 if test "$with_dbmalloc" = yes ; then
6559         AC_CHECK_HEADER(dbmalloc.h,
6560                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
6561 fi
6562 ])dnl
6563 dnl ---------------------------------------------------------------------------
6564 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
6565 dnl ---------------
6566 dnl Configure-option for dmalloc.  The optional parameter is used to override
6567 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6568 AC_DEFUN([CF_WITH_DMALLOC],[
6569 CF_NO_LEAKS_OPTION(dmalloc,
6570         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
6571         [USE_DMALLOC])
6572
6573 if test "$with_dmalloc" = yes ; then
6574         AC_CHECK_HEADER(dmalloc.h,
6575                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
6576 fi
6577 ])dnl
6578 dnl ---------------------------------------------------------------------------
6579 dnl CF_WITH_GPM version: 7 updated: 2008/03/23 14:48:54
6580 dnl -----------
6581 dnl
6582 dnl The option parameter (if neither yes/no) is assumed to be the name of
6583 dnl the gpm library, e.g., for dynamic loading.
6584 AC_DEFUN([CF_WITH_GPM],
6585 [
6586 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
6587 AC_ARG_WITH(gpm,
6588         [  --with-gpm              use Alessandro Rubini's GPM library],
6589         [with_gpm=$withval],
6590         [with_gpm=maybe])
6591 AC_MSG_RESULT($with_gpm)
6592
6593 if test "$with_gpm" != no ; then
6594         AC_CHECK_HEADER(gpm.h,[
6595                 AC_DEFINE(HAVE_GPM_H)
6596                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
6597                         CF_VERBOSE(assuming we really have GPM library)
6598                         AC_DEFINE(HAVE_LIBGPM)
6599                 else
6600                         AC_CHECK_LIB(gpm,Gpm_Open,[:],[
6601                                 AC_MSG_ERROR(Cannot link with GPM library)
6602                 fi
6603                 with_gpm=yes
6604                 ])
6605         ],[
6606                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
6607                 with_gpm=no
6608         ])
6609 fi
6610 ])
6611 dnl ---------------------------------------------------------------------------
6612 dnl CF_WITH_LIBTOOL version: 28 updated: 2011/07/02 15:40:32
6613 dnl ---------------
6614 dnl Provide a configure option to incorporate libtool.  Define several useful
6615 dnl symbols for the makefile rules.
6616 dnl
6617 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
6618 dnl macros from libtool.m4 which is in the aclocal directory of automake.
6619 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
6620 dnl But that still does not work properly since the macro is expanded outside
6621 dnl the CF_WITH_LIBTOOL macro:
6622 dnl
6623 dnl     #!/bin/sh
6624 dnl     ACLOCAL=`aclocal --print-ac-dir`
6625 dnl     if test -z "$ACLOCAL" ; then
6626 dnl             echo cannot find aclocal directory
6627 dnl             exit 1
6628 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
6629 dnl             echo cannot find libtool.m4 file
6630 dnl             exit 1
6631 dnl     fi
6632 dnl
6633 dnl     LOCAL=aclocal.m4
6634 dnl     ORIG=aclocal.m4.orig
6635 dnl
6636 dnl     trap "mv $ORIG $LOCAL" 0 1 2 5 15
6637 dnl     rm -f $ORIG
6638 dnl     mv $LOCAL $ORIG
6639 dnl
6640 dnl     # sed the LIBTOOL= assignment to omit the current directory?
6641 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
6642 dnl     cat $ORIG >>$LOCAL
6643 dnl
6644 dnl     autoconf-257 $*
6645 dnl
6646 AC_DEFUN([CF_WITH_LIBTOOL],
6647 [
6648 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
6649 ifdef([AC_PROG_LIBTOOL],,[
6650 LIBTOOL=
6651 ])
6652 # common library maintenance symbols that are convenient for libtool scripts:
6653 LIB_CREATE='${AR} -cr'
6654 LIB_OBJECT='${OBJECTS}'
6655 LIB_SUFFIX=.a
6656 LIB_PREP="$RANLIB"
6657
6658 # symbols used to prop libtool up to enable it to determine what it should be
6659 # doing:
6660 LIB_CLEAN=
6661 LIB_COMPILE=
6662 LIB_LINK='${CC}'
6663 LIB_INSTALL=
6664 LIB_UNINSTALL=
6665
6666 AC_MSG_CHECKING(if you want to build libraries with libtool)
6667 AC_ARG_WITH(libtool,
6668         [  --with-libtool          generate libraries with libtool],
6669         [with_libtool=$withval],
6670         [with_libtool=no])
6671 AC_MSG_RESULT($with_libtool)
6672 if test "$with_libtool" != "no"; then
6673 ifdef([AC_PROG_LIBTOOL],[
6674         # missing_content_AC_PROG_LIBTOOL{{
6675         AC_PROG_LIBTOOL
6676         # missing_content_AC_PROG_LIBTOOL}}
6677 ],[
6678         if test "$with_libtool" != "yes" ; then
6679                 CF_PATH_SYNTAX(with_libtool)
6680                 LIBTOOL=$with_libtool
6681         else
6682                 AC_PATH_PROG(LIBTOOL,libtool)
6683         fi
6684         if test -z "$LIBTOOL" ; then
6685                 AC_MSG_ERROR(Cannot find libtool)
6686         fi
6687 ])dnl
6688         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${DESTDIR}${libdir} ${LIBTOOL_VERSION} `cut -f1 ${srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
6689         LIB_OBJECT='${OBJECTS:.o=.lo}'
6690         LIB_SUFFIX=.la
6691         LIB_CLEAN='${LIBTOOL} --mode=clean'
6692         LIB_COMPILE='${LIBTOOL} --mode=compile'
6693         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
6694         LIB_INSTALL='${LIBTOOL} --mode=install'
6695         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
6696         LIB_PREP=:
6697
6698         # Show the version of libtool
6699         AC_MSG_CHECKING(version of libtool)
6700
6701         # Save the version in a cache variable - this is not entirely a good
6702         # thing, but the version string from libtool is very ugly, and for
6703         # bug reports it might be useful to have the original string. "("
6704         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
6705         AC_MSG_RESULT($cf_cv_libtool_version)
6706         if test -z "$cf_cv_libtool_version" ; then
6707                 AC_MSG_ERROR(This is not GNU libtool)
6708         fi
6709
6710         # special hack to add -no-undefined (which libtool should do for itself)
6711         LT_UNDEF=
6712         case "$cf_cv_system_name" in #(vi
6713         cygwin*|mingw32*|uwin*|aix[[4-7]]) #(vi
6714                 LT_UNDEF=-no-undefined
6715                 ;;
6716         esac
6717         AC_SUBST([LT_UNDEF])
6718
6719         # special hack to add --tag option for C++ compiler
6720         case $cf_cv_libtool_version in #(vi
6721         1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*) #(vi
6722                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
6723                 LIBTOOL="$LIBTOOL --tag=CC"
6724                 ;;
6725         *)
6726                 LIBTOOL_CXX="$LIBTOOL"
6727                 ;;
6728         esac
6729 else
6730         LIBTOOL=""
6731         LIBTOOL_CXX=""
6732 fi
6733
6734 test -z "$LIBTOOL" && ECHO_LT=
6735
6736 AC_SUBST(LIBTOOL)
6737 AC_SUBST(LIBTOOL_CXX)
6738 AC_SUBST(LIBTOOL_OPTS)
6739
6740 AC_SUBST(LIB_CREATE)
6741 AC_SUBST(LIB_OBJECT)
6742 AC_SUBST(LIB_SUFFIX)
6743 AC_SUBST(LIB_PREP)
6744
6745 AC_SUBST(LIB_CLEAN)
6746 AC_SUBST(LIB_COMPILE)
6747 AC_SUBST(LIB_LINK)
6748 AC_SUBST(LIB_INSTALL)
6749 AC_SUBST(LIB_UNINSTALL)
6750
6751 ])dnl
6752 dnl ---------------------------------------------------------------------------
6753 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
6754 dnl ------------------
6755 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
6756 dnl "lib" prefix, e.g., because it used the dll naming convention.
6757 dnl
6758 dnl $1 = variable to set
6759 AC_DEFUN([CF_WITH_LIB_PREFIX],
6760 [
6761 AC_MSG_CHECKING(if you want to have a library-prefix)
6762 AC_ARG_WITH(lib-prefix,
6763         [  --with-lib-prefix       override library-prefix],
6764         [with_lib_prefix=$withval],
6765         [with_lib_prefix=auto])
6766 AC_MSG_RESULT($with_lib_prefix)
6767
6768 if test $with_lib_prefix = auto
6769 then
6770         CF_LIB_PREFIX($1)
6771 elif test $with_lib_prefix = no
6772 then
6773         LIB_PREFIX=
6774 else
6775         LIB_PREFIX=$with_lib_prefix
6776 fi
6777 ])dnl
6778 dnl ---------------------------------------------------------------------------
6779 dnl CF_WITH_PATH version: 10 updated: 2010/10/23 15:44:18
6780 dnl ------------
6781 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
6782 dnl defaulting to yes/no.
6783 dnl
6784 dnl $1 = option name
6785 dnl $2 = help-text
6786 dnl $3 = environment variable to set
6787 dnl $4 = default value, shown in the help-message, must be a constant
6788 dnl $5 = default value, if it's an expression & cannot be in the help-message
6789 dnl
6790 AC_DEFUN([CF_WITH_PATH],
6791 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
6792 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
6793 if ifelse([$5],,true,[test -n "$5"]) ; then
6794 CF_PATH_SYNTAX(withval)
6795 fi
6796 $3="$withval"
6797 AC_SUBST($3)dnl
6798 ])dnl
6799 dnl ---------------------------------------------------------------------------
6800 dnl CF_WITH_PATHLIST version: 7 updated: 2010/10/23 16:10:30
6801 dnl ----------------
6802 dnl Process an option specifying a list of colon-separated paths.
6803 dnl
6804 dnl $1 = option name
6805 dnl $2 = help-text
6806 dnl $3 = environment variable to set
6807 dnl $4 = default value, shown in the help-message, must be a constant
6808 dnl $5 = default value, if it's an expression & cannot be in the help-message
6809 dnl $6 = flag to tell if we want to define or substitute
6810 dnl
6811 AC_DEFUN([CF_WITH_PATHLIST],[
6812 AC_REQUIRE([CF_PATHSEP])
6813 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
6814 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
6815
6816 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
6817 cf_dst_path=
6818 for cf_src_path in $withval
6819 do
6820   CF_PATH_SYNTAX(cf_src_path)
6821   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}:"
6822   cf_dst_path="${cf_dst_path}${cf_src_path}"
6823 done
6824 IFS="$ac_save_ifs"
6825
6826 ifelse($6,define,[
6827 # Strip single quotes from the value, e.g., when it was supplied as a literal
6828 # for $4 or $5.
6829 case $cf_dst_path in #(vi
6830 \'*)
6831   cf_dst_path=`echo $cf_dst_path |sed -e s/\'// -e s/\'\$//`
6832   ;;
6833 esac
6834 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
6835 ])
6836
6837 eval '$3="$cf_dst_path"'
6838 AC_SUBST($3)dnl
6839
6840 ])dnl
6841 dnl ---------------------------------------------------------------------------
6842 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 2 updated: 2011/12/10 18:58:47
6843 dnl -------------------------
6844 dnl Allow the choice of the pkg-config library directory to be overridden.
6845 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
6846 if test "$PKG_CONFIG" != none ; then
6847         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
6848         AC_ARG_WITH(pkg-config-libdir,
6849                 [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
6850                 [PKG_CONFIG_LIBDIR=$withval],
6851                 [PKG_CONFIG_LIBDIR=yes])
6852
6853         case x$PKG_CONFIG_LIBDIR in #(vi
6854         x/*) #(vi
6855                 ;;
6856         xyes) #(vi
6857                 # look for the library directory using the same prefix as the executable
6858                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
6859                 case x`(arch) 2>/dev/null` in #(vi
6860                 *64) #(vi
6861                         for cf_config in $cf_path/share $cf_path/lib64 $cf_path/lib32 $cf_path/lib
6862                         do
6863                                 if test -d $cf_config/pkgconfig
6864                                 then
6865                                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
6866                                         break
6867                                 fi
6868                         done
6869                         ;;
6870                 *)
6871                         PKG_CONFIG_LIBDIR=$cf_path/lib/pkgconfig
6872                         ;;
6873                 esac
6874                 ;;
6875         *)
6876                 ;;
6877         esac
6878
6879         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
6880 fi
6881
6882 AC_SUBST(PKG_CONFIG_LIBDIR)
6883 ])dnl
6884 dnl ---------------------------------------------------------------------------
6885 dnl CF_WITH_PTHREAD version: 5 updated: 2011/12/10 19:01:56
6886 dnl ---------------
6887 dnl Check for POSIX thread library.
6888 AC_DEFUN([CF_WITH_PTHREAD],
6889 [
6890 AC_MSG_CHECKING(if you want to link with the pthread library)
6891 AC_ARG_WITH(pthread,
6892     [  --with-pthread          use POSIX thread library],
6893     [with_pthread=$withval],
6894     [with_pthread=no])
6895 AC_MSG_RESULT($with_pthread)
6896
6897 if test "$with_pthread" != no ; then
6898     AC_CHECK_HEADER(pthread.h,[
6899         AC_DEFINE(HAVE_PTHREADS_H)
6900
6901         for cf_lib_pthread in pthread c_r
6902         do
6903             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
6904             cf_save_LIBS="$LIBS"
6905             CF_ADD_LIB($cf_lib_pthread)
6906             AC_TRY_LINK([
6907 #include <pthread.h>
6908 ],[
6909                 int rc = pthread_create(0,0,0,0);
6910                 int r2 = pthread_mutexattr_settype(0, 0);
6911 ],[with_pthread=yes],[with_pthread=no])
6912             LIBS="$cf_save_LIBS"
6913             AC_MSG_RESULT($with_pthread)
6914             test "$with_pthread" = yes && break
6915         done
6916
6917         if test "$with_pthread" = yes ; then
6918             CF_ADD_LIB($cf_lib_pthread)
6919             AC_DEFINE(HAVE_LIBPTHREADS)
6920         else
6921             AC_MSG_ERROR(Cannot link with pthread library)
6922         fi
6923     ])
6924 fi
6925 ])
6926 dnl ---------------------------------------------------------------------------
6927 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
6928 dnl -------------------
6929 dnl Allow library's release-version to be overridden.  Generally this happens when a
6930 dnl packager has incremented the release-version past that used in the original package,
6931 dnl and wishes to keep doing this.
6932 dnl
6933 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
6934 dnl and {package}_MINOR symbols
6935 dnl symbol.
6936 AC_DEFUN([CF_WITH_REL_VERSION],[
6937 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
6938 AC_ARG_WITH(rel-version,
6939 [  --with-rel-version=XXX  override derived release version],
6940 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
6941  cf_cv_rel_version=$withval])
6942 ifelse($1,,[
6943  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
6944 ],[
6945  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
6946  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
6947  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
6948  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
6949 ])
6950 ])dnl
6951 dnl ---------------------------------------------------------------------------
6952 dnl CF_WITH_SYSMOUSE version: 2 updated: 2003/03/22 19:13:43
6953 dnl ----------------
6954 dnl If we can compile with sysmouse, make it available unless it is not wanted.
6955 AC_DEFUN([CF_WITH_SYSMOUSE],[
6956 # not everyone has "test -c"
6957 if test -c /dev/sysmouse 2>/dev/null ; then
6958 AC_MSG_CHECKING(if you want to use sysmouse)
6959 AC_ARG_WITH(sysmouse,
6960         [  --with-sysmouse         use sysmouse (FreeBSD console)],
6961         [cf_with_sysmouse=$withval],
6962         [cf_with_sysmouse=maybe])
6963         if test "$cf_with_sysmouse" != no ; then
6964         AC_TRY_COMPILE([
6965 #include <osreldate.h>
6966 #if (__FreeBSD_version >= 400017)
6967 #include <sys/consio.h>
6968 #include <sys/fbio.h>
6969 #else
6970 #include <machine/console.h>
6971 #endif
6972 ],[
6973         struct mouse_info the_mouse;
6974         ioctl(0, CONS_MOUSECTL, &the_mouse);
6975 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
6976         fi
6977 AC_MSG_RESULT($cf_with_sysmouse)
6978 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE)
6979 fi
6980 ])dnl
6981 dnl ---------------------------------------------------------------------------
6982 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
6983 dnl ----------------
6984 AC_DEFUN([CF_WITH_VALGRIND],[
6985 CF_NO_LEAKS_OPTION(valgrind,
6986         [  --with-valgrind         test: use valgrind],
6987         [USE_VALGRIND])
6988 ])dnl
6989 dnl ---------------------------------------------------------------------------
6990 dnl CF_XOPEN_SOURCE version: 42 updated: 2012/01/07 08:26:49
6991 dnl ---------------
6992 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
6993 dnl or adapt to the vendor's definitions to get equivalent functionality,
6994 dnl without losing the common non-POSIX features.
6995 dnl
6996 dnl Parameters:
6997 dnl     $1 is the nominal value for _XOPEN_SOURCE
6998 dnl     $2 is the nominal value for _POSIX_C_SOURCE
6999 AC_DEFUN([CF_XOPEN_SOURCE],[
7000
7001 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
7002 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
7003 cf_xopen_source=
7004
7005 case $host_os in #(vi
7006 aix[[4-7]]*) #(vi
7007         cf_xopen_source="-D_ALL_SOURCE"
7008         ;;
7009 cygwin) #(vi
7010         cf_XOPEN_SOURCE=600
7011         ;;
7012 darwin[[0-8]].*) #(vi
7013         cf_xopen_source="-D_APPLE_C_SOURCE"
7014         ;;
7015 darwin*) #(vi
7016         cf_xopen_source="-D_DARWIN_C_SOURCE"
7017         cf_XOPEN_SOURCE=
7018         ;;
7019 freebsd*|dragonfly*) #(vi
7020         # 5.x headers associate
7021         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
7022         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
7023         cf_POSIX_C_SOURCE=200112L
7024         cf_XOPEN_SOURCE=600
7025         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
7026         ;;
7027 hpux11*) #(vi
7028         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
7029         ;;
7030 hpux*) #(vi
7031         cf_xopen_source="-D_HPUX_SOURCE"
7032         ;;
7033 irix[[56]].*) #(vi
7034         cf_xopen_source="-D_SGI_SOURCE"
7035         cf_XOPEN_SOURCE=
7036         ;;
7037 linux*|gnu*|mint*|k*bsd*-gnu) #(vi
7038         CF_GNU_SOURCE
7039         ;;
7040 mirbsd*) #(vi
7041         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
7042         cf_XOPEN_SOURCE=
7043         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
7044         ;;
7045 netbsd*) #(vi
7046         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
7047         ;;
7048 openbsd[[4-9]]*) #(vi
7049         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
7050         cf_xopen_source="-D_BSD_SOURCE"
7051         cf_XOPEN_SOURCE=600
7052         ;;
7053 openbsd*) #(vi
7054         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
7055         ;;
7056 osf[[45]]*) #(vi
7057         cf_xopen_source="-D_OSF_SOURCE"
7058         ;;
7059 nto-qnx*) #(vi
7060         cf_xopen_source="-D_QNX_SOURCE"
7061         ;;
7062 sco*) #(vi
7063         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
7064         ;;
7065 solaris2.*) #(vi
7066         cf_xopen_source="-D__EXTENSIONS__"
7067         ;;
7068 *)
7069         CF_TRY_XOPEN_SOURCE
7070         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
7071         ;;
7072 esac
7073
7074 if test -n "$cf_xopen_source" ; then
7075         CF_ADD_CFLAGS($cf_xopen_source)
7076 fi
7077
7078 dnl In anything but the default case, we may have system-specific setting
7079 dnl which is still not guaranteed to provide all of the entrypoints that
7080 dnl _XOPEN_SOURCE would yield.
7081 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
7082         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
7083         AC_TRY_COMPILE([#include <stdlib.h>],[
7084 #ifndef _XOPEN_SOURCE
7085 make an error
7086 #endif],
7087         [cf_XOPEN_SOURCE_set=yes],
7088         [cf_XOPEN_SOURCE_set=no])
7089         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
7090         if test $cf_XOPEN_SOURCE_set = yes
7091         then
7092                 AC_TRY_COMPILE([#include <stdlib.h>],[
7093 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
7094 make an error
7095 #endif],
7096                 [cf_XOPEN_SOURCE_set_ok=yes],
7097                 [cf_XOPEN_SOURCE_set_ok=no])
7098                 if test $cf_XOPEN_SOURCE_set_ok = no
7099                 then
7100                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
7101                 fi
7102         else
7103                 CF_TRY_XOPEN_SOURCE
7104         fi
7105 fi
7106 ])