aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2017,2018 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.847 2018/08/18 20:21:21 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See https://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 4 updated: 2015/04/18 08:56:57
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54         [AC_TRY_LINK([#include <langinfo.h>],
  55         [char* cs = nl_langinfo(CODESET);],
  56         am_cv_langinfo_codeset=yes,
  57         am_cv_langinfo_codeset=no)
  58         ])
  59         if test $am_cv_langinfo_codeset = yes; then
  60                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62         fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ABI_DEFAULTS version: 2 updated: 2015/06/06 13:49:58
  66 dnl ---------------
  67 dnl Provide configure-script defaults for different ncurses ABIs.
  68 AC_DEFUN([CF_ABI_DEFAULTS],[
  69 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
  70 case x$cf_cv_abi_version in
  71 (x[[6789]])
  72         cf_dft_ext_colors=yes
  73         cf_dft_ext_const=yes
  74         cf_dft_ext_mouse=yes
  75         cf_dft_ext_putwin=yes
  76         cf_dft_ext_spfuncs=yes
  77         cf_dft_filter_syms=yes
  78         cf_dft_chtype=uint32_t
  79         cf_dft_mmask_t=uint32_t
  80         cf_dft_interop=yes
  81         cf_dft_tparm_arg=intptr_t
  82         cf_dft_with_lp64=yes
  83         ;;
  84 (*)
  85         cf_dft_ext_colors=no
  86         cf_dft_ext_const=no
  87         cf_dft_ext_mouse=no
  88         cf_dft_ext_putwin=no
  89         cf_dft_ext_spfuncs=no
  90         cf_dft_filter_syms=no
  91         cf_dft_chtype=auto
  92         cf_dft_mmask_t=auto
  93         cf_dft_interop=no
  94         cf_dft_tparm_arg=long
  95         cf_dft_with_lp64=no
  96         ;;
  97 esac
  98 ])dnl
  99 dnl ---------------------------------------------------------------------------
 100 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
 101 dnl ------------------
 102 dnl Conditionally generate script according to whether we're using a given autoconf.
 103 dnl
 104 dnl $1 = version to compare against
 105 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
 106 dnl $3 = code to use if AC_ACVERSION is older than $1.
 107 define([CF_ACVERSION_CHECK],
 108 [
 109 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
 110 ifdef([m4_version_compare],
 111 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
 112 [CF_ACVERSION_COMPARE(
 113 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
 114 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
 115 dnl ---------------------------------------------------------------------------
 116 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
 117 dnl --------------------
 118 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
 119 dnl                      MAJOR2, MINOR2, TERNARY2,
 120 dnl                      PRINTABLE2, not FOUND, FOUND)
 121 define([CF_ACVERSION_COMPARE],
 122 [ifelse(builtin([eval], [$2 < $5]), 1,
 123 [ifelse([$8], , ,[$8])],
 124 [ifelse([$9], , ,[$9])])])dnl
 125 dnl ---------------------------------------------------------------------------
 126 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
 127 dnl -------------------
 128 dnl Construct the list of include-options for the C programs in the Ada95
 129 dnl binding.
 130 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
 131 [
 132 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
 133 if test "$srcdir" != "."; then
 134         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 135 fi
 136 if test "$GCC" != yes; then
 137         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 138 elif test "$includedir" != "/usr/include"; then
 139         if test "$includedir" = '${prefix}/include' ; then
 140                 if test x$prefix != x/usr ; then
 141                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 142                 fi
 143         else
 144                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 145         fi
 146 fi
 147 AC_SUBST(ACPPFLAGS)
 148 ])dnl
 149 dnl ---------------------------------------------------------------------------
 150 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 151 dnl ---------------
 152 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 153 AC_DEFUN([CF_ADD_ADAFLAGS],[
 154         ADAFLAGS="$ADAFLAGS $1"
 155         AC_SUBST(ADAFLAGS)
 156 ])dnl
 157 dnl ---------------------------------------------------------------------------
 158 dnl CF_ADD_CFLAGS version: 13 updated: 2017/02/25 18:57:40
 159 dnl -------------
 160 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 161 dnl The second parameter if given makes this macro verbose.
 162 dnl
 163 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 164 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 165 dnl confused by the quotes (which require backslashes to keep them usable).
 166 AC_DEFUN([CF_ADD_CFLAGS],
 167 [
 168 cf_fix_cppflags=no
 169 cf_new_cflags=
 170 cf_new_cppflags=
 171 cf_new_extra_cppflags=
 172
 173 for cf_add_cflags in $1
 174 do
 175 case $cf_fix_cppflags in
 176 (no)
 177         case $cf_add_cflags in
 178         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 179                 case $cf_add_cflags in
 180                 (-D*)
 181                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 182
 183                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 184                                 && test -z "${cf_tst_cflags}" \
 185                                 && cf_fix_cppflags=yes
 186
 187                         if test $cf_fix_cppflags = yes ; then
 188                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 189                                 continue
 190                         elif test "${cf_tst_cflags}" = "\"'" ; then
 191                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 192                                 continue
 193                         fi
 194                         ;;
 195                 esac
 196                 case "$CPPFLAGS" in
 197                 (*$cf_add_cflags)
 198                         ;;
 199                 (*)
 200                         case $cf_add_cflags in
 201                         (-D*)
 202                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 203                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 204                                 ;;
 205                         esac
 206                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 207                         ;;
 208                 esac
 209                 ;;
 210         (*)
 211                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 212                 ;;
 213         esac
 214         ;;
 215 (yes)
 216         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 217
 218         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 219
 220         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 221                 && test -z "${cf_tst_cflags}" \
 222                 && cf_fix_cppflags=no
 223         ;;
 224 esac
 225 done
 226
 227 if test -n "$cf_new_cflags" ; then
 228         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 229         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 230 fi
 231
 232 if test -n "$cf_new_cppflags" ; then
 233         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 234         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 235 fi
 236
 237 if test -n "$cf_new_extra_cppflags" ; then
 238         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 239         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 240 fi
 241
 242 AC_SUBST(EXTRA_CPPFLAGS)
 243
 244 ])dnl
 245 dnl ---------------------------------------------------------------------------
 246 dnl CF_ADD_INCDIR version: 15 updated: 2018/06/20 20:23:13
 247 dnl -------------
 248 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 249 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 250 dnl but old versions (and some misinstalled ones) need that.  To make things
 251 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 252 dnl the include-path).
 253 AC_DEFUN([CF_ADD_INCDIR],
 254 [
 255 if test -n "$1" ; then
 256   for cf_add_incdir in $1
 257   do
 258         while test $cf_add_incdir != /usr/include
 259         do
 260           if test -d $cf_add_incdir
 261           then
 262                 cf_have_incdir=no
 263                 if test -n "$CFLAGS$CPPFLAGS" ; then
 264                   # a loop is needed to ensure we can add subdirs of existing dirs
 265                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 266                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 267                           cf_have_incdir=yes; break
 268                         fi
 269                   done
 270                 fi
 271
 272                 if test "$cf_have_incdir" = no ; then
 273                   if test "$cf_add_incdir" = /usr/local/include ; then
 274                         if test "$GCC" = yes
 275                         then
 276                           cf_save_CPPFLAGS=$CPPFLAGS
 277                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
 278                           AC_TRY_COMPILE([#include <stdio.h>],
 279                                   [printf("Hello")],
 280                                   [],
 281                                   [cf_have_incdir=yes])
 282                           CPPFLAGS=$cf_save_CPPFLAGS
 283                         fi
 284                   fi
 285                 fi
 286
 287                 if test "$cf_have_incdir" = no ; then
 288                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 289                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 290
 291                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 292                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 293                   cf_add_incdir="$cf_top_incdir"
 294                 else
 295                   break
 296                 fi
 297           else
 298                 break
 299           fi
 300         done
 301   done
 302 fi
 303 ])dnl
 304 dnl ---------------------------------------------------------------------------
 305 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 306 dnl ----------
 307 dnl Add a library, used to enforce consistency.
 308 dnl
 309 dnl $1 = library to add, without the "-l"
 310 dnl $2 = variable to update (default $LIBS)
 311 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 312 dnl ---------------------------------------------------------------------------
 313 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 314 dnl -------------
 315 dnl     Adds to the library-path
 316 dnl
 317 dnl     Some machines have trouble with multiple -L options.
 318 dnl
 319 dnl $1 is the (list of) directory(s) to add
 320 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 321 dnl
 322 AC_DEFUN([CF_ADD_LIBDIR],
 323 [
 324 if test -n "$1" ; then
 325         for cf_add_libdir in $1
 326         do
 327                 if test $cf_add_libdir = /usr/lib ; then
 328                         :
 329                 elif test -d $cf_add_libdir
 330                 then
 331                         cf_have_libdir=no
 332                         if test -n "$LDFLAGS$LIBS" ; then
 333                                 # a loop is needed to ensure we can add subdirs of existing dirs
 334                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 335                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 336                                                 cf_have_libdir=yes; break
 337                                         fi
 338                                 done
 339                         fi
 340                         if test "$cf_have_libdir" = no ; then
 341                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 342                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 343                         fi
 344                 fi
 345         done
 346 fi
 347 ])dnl
 348 dnl ---------------------------------------------------------------------------
 349 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
 350 dnl -----------
 351 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 352 dnl prepended to an existing list, since their dependencies are assumed to
 353 dnl already exist in the list.
 354 dnl
 355 dnl $1 = libraries to add, with the "-l", etc.
 356 dnl $2 = variable to update (default $LIBS)
 357 AC_DEFUN([CF_ADD_LIBS],[
 358 cf_add_libs="$1"
 359 # Filter out duplicates - this happens with badly-designed ".pc" files...
 360 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
 361 do
 362         for cf_add_2lib in $cf_add_libs
 363         do
 364                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
 365                 then
 366                         cf_add_1lib=
 367                         break
 368                 fi
 369         done
 370         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
 371 done
 372 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 373 ])dnl
 374 dnl ---------------------------------------------------------------------------
 375 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 376 dnl ------------------
 377 dnl Append to a search-list for a nonstandard header/lib-file
 378 dnl     $1 = the variable to return as result
 379 dnl     $2 = the package name
 380 dnl     $3 = the subdirectory, e.g., bin, include or lib
 381 dnl $4 = the directory under which we will test for subdirectories
 382 dnl $5 = a directory that we do not want $4 to match
 383 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 384 [
 385 test "x$4" != "x$5" && \
 386 test -d "$4" && \
 387 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 388         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 389         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 390         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 391         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 392         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 393         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 394 }
 395 ])dnl
 396 dnl ---------------------------------------------------------------------------
 397 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 398 dnl --------------
 399 dnl use this macro for appending text without introducing an extra blank at
 400 dnl the beginning
 401 define([CF_APPEND_TEXT],
 402 [
 403         test -n "[$]$1" && $1="[$]$1 "
 404         $1="[$]{$1}$2"
 405 ])dnl
 406 dnl ---------------------------------------------------------------------------
 407 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 408 dnl --------------
 409 dnl Allow user to disable a normally-on option.
 410 AC_DEFUN([CF_ARG_DISABLE],
 411 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 412 dnl ---------------------------------------------------------------------------
 413 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 414 dnl -------------
 415 dnl Allow user to enable a normally-off option.
 416 AC_DEFUN([CF_ARG_ENABLE],
 417 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 418 dnl ---------------------------------------------------------------------------
 419 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 420 dnl -------------
 421 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 422 dnl values.
 423 dnl
 424 dnl Parameters:
 425 dnl $1 = option name
 426 dnl $2 = help-string
 427 dnl $3 = action to perform if option is not default
 428 dnl $4 = action if perform if option is default
 429 dnl $5 = default option value (either 'yes' or 'no')
 430 AC_DEFUN([CF_ARG_OPTION],
 431 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 432         if test "$enableval" != "$5" ; then
 433 ifelse([$3],,[    :]dnl
 434 ,[    $3]) ifelse([$4],,,[
 435         else
 436                 $4])
 437         fi],[enableval=$5 ifelse([$4],,,[
 438         $4
 439 ])dnl
 440 ])])dnl
 441 dnl ---------------------------------------------------------------------------
 442 dnl CF_AR_FLAGS version: 6 updated: 2015/10/10 15:25:05
 443 dnl -----------
 444 dnl Check for suitable "ar" (archiver) options for updating an archive.
 445 dnl
 446 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 447 dnl as well as a workaround for breakage of make's archive rules by the GNU
 448 dnl binutils "ar" program.
 449 AC_DEFUN([CF_AR_FLAGS],[
 450 AC_REQUIRE([CF_PROG_AR])
 451
 452 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 453         cf_cv_ar_flags=unknown
 454         for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 455         do
 456
 457                 # check if $ARFLAGS already contains this choice
 458                 if test "x$ARFLAGS" != "x" ; then
 459                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 460                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 461                                 cf_cv_ar_flags=
 462                                 break
 463                         fi
 464                 fi
 465
 466                 rm -f conftest.$ac_cv_objext
 467                 rm -f conftest.a
 468
 469                 cat >conftest.$ac_ext <<EOF
 470 #line __oline__ "configure"
 471 int     testdata[[3]] = { 123, 456, 789 };
 472 EOF
 473                 if AC_TRY_EVAL(ac_compile) ; then
 474                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 475                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 476                         if test -f conftest.a ; then
 477                                 cf_cv_ar_flags=$cf_ar_flags
 478                                 break
 479                         fi
 480                 else
 481                         CF_VERBOSE(cannot compile test-program)
 482                         break
 483                 fi
 484         done
 485         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 486 ])
 487
 488 if test -n "$ARFLAGS" ; then
 489         if test -n "$cf_cv_ar_flags" ; then
 490                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 491         fi
 492 else
 493         ARFLAGS=$cf_cv_ar_flags
 494 fi
 495
 496 AC_SUBST(ARFLAGS)
 497 ])
 498 dnl ---------------------------------------------------------------------------
 499 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
 500 dnl -----------------
 501 dnl Check if awk can handle big strings using printf.  Some older versions of
 502 dnl awk choke on large strings passed via "%s".
 503 dnl
 504 dnl $1 = desired string size
 505 dnl $2 = variable to set with result
 506 AC_DEFUN([CF_AWK_BIG_PRINTF],
 507 [
 508         case x$AWK in
 509         (x)
 510                 eval $2=no
 511                 ;;
 512         (*)
 513                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 514                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 515                         eval $2=yes
 516                 else
 517                         eval $2=no
 518                 fi
 519                 ;;
 520         esac
 521 ])dnl
 522 dnl ---------------------------------------------------------------------------
 523 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 524 dnl ------------
 525 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 526 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 527 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 528 dnl
 529 dnl Treat the configuration-variable specially here, since we're directly
 530 dnl substituting its value (i.e., 1/0).
 531 dnl
 532 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 533 AC_DEFUN([CF_BOOL_DECL],
 534 [
 535 AC_MSG_CHECKING(if we should include stdbool.h)
 536
 537 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 538         AC_TRY_COMPILE([],[bool foo = false],
 539                 [cf_cv_header_stdbool_h=0],
 540                 [AC_TRY_COMPILE([
 541 #ifndef __BEOS__
 542 #include <stdbool.h>
 543 #endif
 544 ],[bool foo = false],
 545                         [cf_cv_header_stdbool_h=1],
 546                         [cf_cv_header_stdbool_h=0])])])
 547
 548 if test "$cf_cv_header_stdbool_h" = 1
 549 then    AC_MSG_RESULT(yes)
 550 else    AC_MSG_RESULT(no)
 551 fi
 552
 553 AC_MSG_CHECKING([for builtin bool type])
 554
 555 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 556         AC_TRY_COMPILE([
 557 #include <stdio.h>
 558 #include <sys/types.h>
 559 ],[bool x = false],
 560                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 561                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 562         ])
 563
 564 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 565 then    AC_MSG_RESULT(yes)
 566 else    AC_MSG_RESULT(no)
 567 fi
 568 ])dnl
 569 dnl ---------------------------------------------------------------------------
 570 dnl CF_BOOL_SIZE version: 15 updated: 2017/01/21 11:06:25
 571 dnl ------------
 572 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 573 dnl Don't bother looking for bool.h, since it's been deprecated.
 574 dnl
 575 dnl If the current compiler is C rather than C++, we get the bool definition
 576 dnl from <stdbool.h>.
 577 AC_DEFUN([CF_BOOL_SIZE],
 578 [
 579 AC_MSG_CHECKING([for size of bool])
 580 AC_CACHE_VAL(cf_cv_type_of_bool,[
 581         rm -f cf_test.out
 582         AC_TRY_RUN([
 583 #include <stdlib.h>
 584 #include <stdio.h>
 585
 586 #if defined(__cplusplus)
 587
 588 #ifdef HAVE_GXX_BUILTIN_H
 589 #include <g++/builtin.h>
 590 #elif HAVE_GPP_BUILTIN_H
 591 #include <gpp/builtin.h>
 592 #elif HAVE_BUILTIN_H
 593 #include <builtin.h>
 594 #endif
 595
 596 #else
 597
 598 #if $cf_cv_header_stdbool_h
 599 #include <stdbool.h>
 600 #endif
 601
 602 #endif
 603
 604 int main(void)
 605 {
 606         FILE *fp = fopen("cf_test.out", "w");
 607         if (fp != 0) {
 608                 bool x = true;
 609                 if ((bool)(-x) >= 0)
 610                         fputs("unsigned ", fp);
 611                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 612                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 613                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 614                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 615                 fclose(fp);
 616         }
 617         ${cf_cv_main_return:-return}(0);
 618 }
 619                 ],
 620                 [cf_cv_type_of_bool=`cat cf_test.out`
 621                  if test -z "$cf_cv_type_of_bool"; then
 622                    cf_cv_type_of_bool=unknown
 623                  fi],
 624                 [cf_cv_type_of_bool=unknown],
 625                 [cf_cv_type_of_bool=unknown])
 626         ])
 627         rm -f cf_test.out
 628 AC_MSG_RESULT($cf_cv_type_of_bool)
 629 if test "$cf_cv_type_of_bool" = unknown ; then
 630         case .$NCURSES_BOOL in
 631         (.auto|.) NCURSES_BOOL=unsigned;;
 632         esac
 633         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 634         cf_cv_type_of_bool=$NCURSES_BOOL
 635 fi
 636 ])dnl
 637 dnl ---------------------------------------------------------------------------
 638 dnl CF_BUILD_CC version: 8 updated: 2018/01/04 20:31:04
 639 dnl -----------
 640 dnl If we're cross-compiling, allow the user to override the tools and their
 641 dnl options.  The configure script is oriented toward identifying the host
 642 dnl compiler, etc., but we need a build compiler to generate parts of the
 643 dnl source.
 644 dnl
 645 dnl $1 = default for $CPPFLAGS
 646 dnl $2 = default for $LIBS
 647 AC_DEFUN([CF_BUILD_CC],[
 648 CF_ACVERSION_CHECK(2.52,,
 649         [AC_REQUIRE([CF_PROG_EXT])])
 650 if test "$cross_compiling" = yes ; then
 651
 652         # defaults that we might want to override
 653         : ${BUILD_CFLAGS:=''}
 654         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 655         : ${BUILD_LDFLAGS:=''}
 656         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 657         : ${BUILD_EXEEXT:='$x'}
 658         : ${BUILD_OBJEXT:='o'}
 659
 660         AC_ARG_WITH(build-cc,
 661                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 662                 [BUILD_CC="$withval"],
 663                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
 664         AC_MSG_CHECKING(for native build C compiler)
 665         AC_MSG_RESULT($BUILD_CC)
 666
 667         AC_MSG_CHECKING(for native build C preprocessor)
 668         AC_ARG_WITH(build-cpp,
 669                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 670                 [BUILD_CPP="$withval"],
 671                 [BUILD_CPP='${BUILD_CC} -E'])
 672         AC_MSG_RESULT($BUILD_CPP)
 673
 674         AC_MSG_CHECKING(for native build C flags)
 675         AC_ARG_WITH(build-cflags,
 676                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 677                 [BUILD_CFLAGS="$withval"])
 678         AC_MSG_RESULT($BUILD_CFLAGS)
 679
 680         AC_MSG_CHECKING(for native build C preprocessor-flags)
 681         AC_ARG_WITH(build-cppflags,
 682                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 683                 [BUILD_CPPFLAGS="$withval"])
 684         AC_MSG_RESULT($BUILD_CPPFLAGS)
 685
 686         AC_MSG_CHECKING(for native build linker-flags)
 687         AC_ARG_WITH(build-ldflags,
 688                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 689                 [BUILD_LDFLAGS="$withval"])
 690         AC_MSG_RESULT($BUILD_LDFLAGS)
 691
 692         AC_MSG_CHECKING(for native build linker-libraries)
 693         AC_ARG_WITH(build-libs,
 694                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 695                 [BUILD_LIBS="$withval"])
 696         AC_MSG_RESULT($BUILD_LIBS)
 697
 698         # this assumes we're on Unix.
 699         BUILD_EXEEXT=
 700         BUILD_OBJEXT=o
 701
 702         : ${BUILD_CC:='${CC}'}
 703
 704         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 705                 AC_MSG_ERROR([Cross-build requires two compilers.
 706 Use --with-build-cc to specify the native compiler.])
 707         fi
 708
 709 else
 710         : ${BUILD_CC:='${CC}'}
 711         : ${BUILD_CPP:='${CPP}'}
 712         : ${BUILD_CFLAGS:='${CFLAGS}'}
 713         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 714         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 715         : ${BUILD_LIBS:='${LIBS}'}
 716         : ${BUILD_EXEEXT:='$x'}
 717         : ${BUILD_OBJEXT:='o'}
 718 fi
 719
 720 AC_SUBST(BUILD_CC)
 721 AC_SUBST(BUILD_CPP)
 722 AC_SUBST(BUILD_CFLAGS)
 723 AC_SUBST(BUILD_CPPFLAGS)
 724 AC_SUBST(BUILD_LDFLAGS)
 725 AC_SUBST(BUILD_LIBS)
 726 AC_SUBST(BUILD_EXEEXT)
 727 AC_SUBST(BUILD_OBJEXT)
 728 ])dnl
 729 dnl ---------------------------------------------------------------------------
 730 dnl CF_CC_ENV_FLAGS version: 9 updated: 2018/07/29 18:03:26
 731 dnl ---------------
 732 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 733 dnl into CC.  This will not help with broken scripts that wrap the compiler
 734 dnl with options, but eliminates a more common category of user confusion.
 735 dnl
 736 dnl In particular, it addresses the problem of being able to run the C
 737 dnl preprocessor in a consistent manner.
 738 dnl
 739 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 740 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 741 dnl outweighs that limitation.
 742 AC_DEFUN([CF_CC_ENV_FLAGS],
 743 [
 744 # This should have been defined by AC_PROG_CC
 745 : ${CC:=cc}
 746
 747 AC_MSG_CHECKING(\$CFLAGS variable)
 748 case "x$CFLAGS" in
 749 (*-[[IUD]]*)
 750         AC_MSG_RESULT(broken)
 751         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
 752         cf_flags="$CFLAGS"
 753         CFLAGS=
 754         for cf_arg in $cf_flags
 755         do
 756                 CF_ADD_CFLAGS($cf_arg)
 757         done
 758         ;;
 759 (*)
 760         AC_MSG_RESULT(ok)
 761         ;;
 762 esac
 763
 764 AC_MSG_CHECKING(\$CC variable)
 765 case "$CC" in
 766 (*[[\ \ ]]-*)
 767         AC_MSG_RESULT(broken)
 768         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
 769         # humor him...
 770         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 771         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
 772         CC="$cf_prog"
 773         for cf_arg in $cf_flags
 774         do
 775                 case "x$cf_arg" in
 776                 (x-[[IUDfgOW]]*)
 777                         CF_ADD_CFLAGS($cf_arg)
 778                         ;;
 779                 (*)
 780                         CC="$CC $cf_arg"
 781                         ;;
 782                 esac
 783         done
 784         CF_VERBOSE(resulting CC: '$CC')
 785         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 786         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 787         ;;
 788 (*)
 789         AC_MSG_RESULT(ok)
 790         ;;
 791 esac
 792 ])dnl
 793 dnl ---------------------------------------------------------------------------
 794 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
 795 dnl ---------------
 796 dnl Determine the default configuration into which we'll install ncurses.  This
 797 dnl can be overridden by the user's command-line options.  There's two items to
 798 dnl look for:
 799 dnl     1. the prefix (e.g., /usr)
 800 dnl     2. the header files (e.g., /usr/include/ncurses)
 801 dnl We'll look for a previous installation of ncurses and use the same defaults.
 802 dnl
 803 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 804 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 805 dnl programs from a vendor's.
 806 AC_DEFUN([CF_CFG_DEFAULTS],
 807 [
 808 AC_MSG_CHECKING(for prefix)
 809 if test "x$prefix" = "xNONE" ; then
 810         case "$cf_cv_system_name" in
 811                 # non-vendor systems don't have a conflict
 812         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 813                 prefix=/usr
 814                 ;;
 815         (*)     prefix=$ac_default_prefix
 816                 ;;
 817         esac
 818 fi
 819 AC_MSG_RESULT($prefix)
 820
 821 if test "x$prefix" = "xNONE" ; then
 822 AC_MSG_CHECKING(for default include-directory)
 823 test -n "$verbose" && echo 1>&AC_FD_MSG
 824 for cf_symbol in \
 825         $includedir \
 826         $includedir/ncurses \
 827         $prefix/include \
 828         $prefix/include/ncurses \
 829         /usr/local/include \
 830         /usr/local/include/ncurses \
 831         /usr/include \
 832         /usr/include/ncurses
 833 do
 834         cf_dir=`eval echo $cf_symbol`
 835         if test -f $cf_dir/curses.h ; then
 836         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 837                 includedir="$cf_symbol"
 838                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 839                 break
 840         fi
 841         fi
 842         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 843 done
 844 AC_MSG_RESULT($includedir)
 845 fi
 846 ])dnl
 847 dnl ---------------------------------------------------------------------------
 848 dnl CF_CGETENT version: 6 updated: 2017/01/21 11:06:25
 849 dnl ----------
 850 dnl Check if the terminal-capability database functions are available.  If not,
 851 dnl ncurses has a much-reduced version.
 852 AC_DEFUN([CF_CGETENT],[
 853 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 854 AC_TRY_LINK([
 855 #include <stdlib.h>],[
 856         char temp[128];
 857         char *buf = temp;
 858         char *db_array = temp;
 859         cgetent(&buf, &db_array, "vt100");
 860         cgetcap(buf, "tc", '=');
 861         cgetmatch(buf, "tc");
 862         ],
 863         [cf_cv_cgetent=yes],
 864         [cf_cv_cgetent=no])
 865 ])
 866
 867 if test "$cf_cv_cgetent" = yes
 868 then
 869         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 870 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 871 AC_TRY_LINK([
 872 #pragma GCC diagnostic error "-Wincompatible-pointer-types-discards-qualifiers"
 873 #include <stdlib.h>],[
 874         char temp[128];
 875         char *buf = temp;
 876 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 877         const char *db_array = temp;
 878         cgetent(&buf, &db_array, "vt100");
 879 #endif
 880         cgetcap(buf, "tc", '=');
 881         cgetmatch(buf, "tc");
 882         ],
 883         [cf_cv_cgetent_const=yes],
 884         [cf_cv_cgetent_const=no])
 885 ])
 886         if test "$cf_cv_cgetent_const" = yes
 887         then
 888                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 889         fi
 890 fi
 891 ])dnl
 892 dnl ---------------------------------------------------------------------------
 893 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 894 dnl --------------
 895 dnl Check if we're accidentally using a cache from a different machine.
 896 dnl Derive the system name, as a check for reusing the autoconf cache.
 897 dnl
 898 dnl If we've packaged config.guess and config.sub, run that (since it does a
 899 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 900 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 901 dnl which is useful in cross-compiles.
 902 dnl
 903 dnl Note: we would use $ac_config_sub, but that is one of the places where
 904 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 905 AC_DEFUN([CF_CHECK_CACHE],
 906 [
 907 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 908         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 909         system_name="$host_os"
 910 else
 911         system_name="`(uname -s -r) 2>/dev/null`"
 912         if test -z "$system_name" ; then
 913                 system_name="`(hostname) 2>/dev/null`"
 914         fi
 915 fi
 916 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 917 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 918
 919 test -z "$system_name" && system_name="$cf_cv_system_name"
 920 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 921
 922 if test ".$system_name" != ".$cf_cv_system_name" ; then
 923         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 924         AC_MSG_ERROR("Please remove config.cache and try again.")
 925 fi
 926 ])dnl
 927 dnl ---------------------------------------------------------------------------
 928 dnl CF_CHECK_ERRNO version: 12 updated: 2015/04/18 08:56:57
 929 dnl --------------
 930 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 931 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 932 dnl ourselves.
 933 dnl
 934 dnl $1 = the name to check
 935 dnl $2 = the assumed type
 936 AC_DEFUN([CF_CHECK_ERRNO],
 937 [
 938 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 939         AC_TRY_COMPILE([
 940 #ifdef HAVE_STDLIB_H
 941 #include <stdlib.h>
 942 #endif
 943 #include <stdio.h>
 944 #include <sys/types.h>
 945 #include <errno.h> ],
 946         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 947         [cf_cv_dcl_$1=yes],
 948         [cf_cv_dcl_$1=no])
 949 ])
 950
 951 if test "$cf_cv_dcl_$1" = no ; then
 952         CF_UPPER(cf_result,decl_$1)
 953         AC_DEFINE_UNQUOTED($cf_result)
 954 fi
 955
 956 # It's possible (for near-UNIX clones) that the data doesn't exist
 957 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 958 ])dnl
 959 dnl ---------------------------------------------------------------------------
 960 dnl CF_CHECK_EXTERN_DATA version: 4 updated: 2015/04/18 08:56:57
 961 dnl --------------------
 962 dnl Check for existence of external data in the current set of libraries.  If
 963 dnl we can modify it, it's real enough.
 964 dnl $1 = the name to check
 965 dnl $2 = its type
 966 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 967 [
 968 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 969         AC_TRY_LINK([
 970 #undef $1
 971 extern $2 $1;
 972 ],
 973         [$1 = 2],
 974         [cf_cv_have_$1=yes],
 975         [cf_cv_have_$1=no])
 976 ])
 977
 978 if test "$cf_cv_have_$1" = yes ; then
 979         CF_UPPER(cf_result,have_$1)
 980         AC_DEFINE_UNQUOTED($cf_result)
 981 fi
 982
 983 ])dnl
 984 dnl ---------------------------------------------------------------------------
 985 dnl CF_CHECK_GPM_WGETCH version: 3 updated: 2017/01/21 11:06:25
 986 dnl -------------------
 987 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 988 dnl is not "weak" - warn about this because it can create problems linking
 989 dnl applications with ncurses.
 990 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 991 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 992
 993 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 994 cf_cv_check_gpm_wgetch=unknown
 995 if test "$cross_compiling" != yes ; then
 996
 997 cat >conftest.$ac_ext <<CF_EOF
 998 #include <gpm.h>
 999 int main(void)
1000 {
1001         Gpm_Wgetch();
1002         ${cf_cv_main_return:-return}(0);
1003 }
1004 CF_EOF
1005
1006         cf_save_LIBS="$LIBS"
1007         # This only works if we can look at the symbol table.  If a shared
1008         # library is stripped for install, we cannot use that.  So we're forced
1009         # to rely on the static library, noting that some packagers may not
1010         # include it.
1011         LIBS="-static -lgpm -dynamic $LIBS"
1012         if AC_TRY_EVAL(ac_compile) ; then
1013                 if AC_TRY_EVAL(ac_link) ; then
1014                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
1015                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
1016                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
1017                 fi
1018         fi
1019         rm -rf conftest*
1020         LIBS="$cf_save_LIBS"
1021 fi
1022 ])
1023
1024 if test "$cf_cv_check_gpm_wgetch" != yes ; then
1025         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
1026 fi
1027 ])])dnl
1028 dnl ---------------------------------------------------------------------------
1029 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
1030 dnl ------------------------
1031 dnl Show the version of libtool
1032 dnl
1033 dnl Save the version in a cache variable - this is not entirely a good thing,
1034 dnl but the version string from libtool is very ugly, and for bug reports it
1035 dnl might be useful to have the original string.
1036 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
1037 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
1038 then
1039         AC_MSG_CHECKING(version of $LIBTOOL)
1040         CF_LIBTOOL_VERSION
1041         AC_MSG_RESULT($cf_cv_libtool_version)
1042         if test -z "$cf_cv_libtool_version" ; then
1043                 AC_MSG_ERROR(This is not GNU libtool)
1044         fi
1045 else
1046         AC_MSG_ERROR(GNU libtool has not been found)
1047 fi
1048 ])dnl
1049 dnl ---------------------------------------------------------------------------
1050 dnl CF_CHECK_WCHAR_H version: 2 updated: 2017/01/21 11:06:25
1051 dnl ----------------
1052 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
1053 AC_DEFUN([CF_CHECK_WCHAR_H],[
1054 AC_CHECK_HEADERS( \
1055 wchar.h \
1056 wctype.h \
1057 )
1058 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1059 AC_TRY_COMPILE(
1060 [
1061 #include <stdlib.h>
1062 #ifdef HAVE_WCHAR_H
1063 #include <wchar.h>
1064 #endif
1065 #ifdef HAVE_WCTYPE_H
1066 #include <wctype.h>
1067 #endif
1068 ],[
1069         wint_t foo = 0;
1070         int bar = iswpunct(foo)],
1071         [cf_cv_wchar_h_okay=yes],
1072         [cf_cv_wchar_h_okay=no])])
1073
1074 if test $cf_cv_wchar_h_okay = no
1075 then
1076         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1077 fi
1078 ])dnl
1079 dnl ---------------------------------------------------------------------------
1080 dnl CF_CHECK_WCWIDTH_GRAPHICS version: 1 updated: 2015/12/19 17:47:56
1081 dnl -------------------------
1082 dnl Most "modern" terminal emulators are based to some degree on VT100, and
1083 dnl should support line-drawing.  Even with Unicode.  There is a problem.
1084 dnl
1085 dnl While most of the VT100 graphics characters were incorporated into Unicode,
1086 dnl all of those were combined into a page of useful graphics characters.
1087 dnl
1088 dnl So far, so good.
1089 dnl
1090 dnl However, while they are useful, there are other considerations.  CJK
1091 dnl is (because of poor device resolution) often rendered as double-width
1092 dnl characters.  So... for these generally-useful characters, what should
1093 dnl be the width (to make them consistent with adjacent characters)?
1094 dnl
1095 dnl The obvious choice would have been to make this locale-dependent, and use
1096 dnl wcwidth() to tell applications what the actual width is.  That was too
1097 dnl obvious.  Instead, we have a slew of "ambiguous-width" characters.
1098 dnl See for example
1099 dnl             http://www.unicode.org/reports/tr11/tr11-29.html
1100 dnl             http://www.cl.cam.ac.uk/~mgk25/ucs/scw-proposal.html
1101 dnl
1102 dnl The EastAsianWidth-6.2.0.txt file from the Unicode organization lists
1103 dnl more than 22,000 characters, with 1281 of those as ambiguous-width.  For
1104 dnl instance, it lists half (44/96) of the Latin-1 characters as
1105 dnl ambiguous-width.  Also, all of the box-characters at 0x2500 are ambiguous.
1106 dnl
1107 dnl What this means for the implementor is that on some systems wcwidth() can
1108 dnl give bad advice.  On Solaris, some of the ambiguous widths are returned as
1109 dnl 1 (the Latin-1 characters), while others are returned as 2 (line-drawing
1110 dnl characters).  These do not necessarily match the behavior of the terminal
1111 dnl emulator.  xterm, for instance, does an optional startup check to find if
1112 dnl this problem (or similar) exists with the system's locale tables, rejecting
1113 dnl them if they are too unreliable.
1114 AC_DEFUN([CF_CHECK_WCWIDTH_GRAPHICS],[
1115 AC_CACHE_CHECK(if wcwidth agrees graphics are single-width, cf_cv_wcwidth_graphics,[
1116 cat >conftest.in <<CF_EOF
1117 -       VT100 symbols
1118 0x250c  upper left corner
1119 0x2514  lower left corner
1120 0x2510  upper right corner
1121 0x2518  lower right corner
1122 0x251c  tee pointing left
1123 0x2524  tee pointing right
1124 0x2534  tee pointing up
1125 0x252c  tee pointing down
1126 0x2500  horizontal line
1127 0x2502  vertical line
1128 0x253c  large plus or crossover
1129 0x23ba  scan line 1
1130 0x23bd  scan line 9
1131 0x25c6  diamond
1132 0x2592  checker board (stipple)
1133 0x00b0  degree symbol
1134 0x00b1  plus/minus
1135 0x00b7  bullet
1136 -       Teletype 5410v1 symbols
1137 0x2190  arrow pointing left
1138 0x2192  arrow pointing right
1139 0x2193  arrow pointing down
1140 0x2191  arrow pointing up
1141 0x2592  board of squares
1142 0x2603  lantern symbol
1143 0x25ae  solid square block
1144 -       these defaults were invented for ncurses
1145 0x23bb  scan line 3
1146 0x23bc  scan line 7
1147 0x2264  less-than-or-equal-to
1148 0x2265  greater-than-or-equal-to
1149 0x03c0  greek pi
1150 0x2260  not-equal
1151 0x00a3  pound-sterling symbol
1152 -       thick-line-drawing
1153 0x250f  upper left corner
1154 0x2517  lower left corner
1155 0x2513  upper right corner
1156 0x251b  lower right corner
1157 0x2523  tee pointing left
1158 0x252b  tee pointing right
1159 0x253b  tee pointing up
1160 0x2533  tee pointing down
1161 0x2501  horizontal line
1162 0x2503  vertical line
1163 0x254b  large plus or crossover
1164 -       double-line-drawing
1165 0x2554  upper left corner
1166 0x255a  lower left corner
1167 0x2557  upper right corner
1168 0x255d  lower right corner
1169 0x2563  tee pointing left
1170 0x2560  tee pointing right
1171 0x2569  tee pointing up
1172 0x2566  tee pointing down
1173 0x2550  horizontal line
1174 0x2551  vertical line
1175 0x256c  large plus or crossover
1176 CF_EOF
1177 AC_TRY_RUN([
1178 #include <locale.h>
1179 #include <stdio.h>
1180 #include <wchar.h>
1181
1182 #define MY_LEN 80
1183
1184 int
1185 main(void)
1186 {
1187         FILE *fp;
1188         int value;
1189         char buffer[MY_LEN + 1];
1190         char notes[MY_LEN + 1];
1191         int totals = 0;
1192         int passed = 0;
1193
1194         if (setlocale(LC_ALL, "en_US.UTF8") ||
1195                 setlocale(LC_ALL, "en_US.UTF-8") ||
1196                 setlocale(LC_ALL, "en_US.utf8") ||
1197                 setlocale(LC_ALL, "en_US.utf-8")) {
1198                 if ((fp = fopen("conftest.in", "r")) != 0) {
1199                         while (fgets(buffer, MY_LEN, fp) != 0) {
1200                                 if (*buffer == '-') {
1201                                         fprintf(stderr, "\t%s", buffer);
1202                                 } else if (sscanf(buffer, "%x %s", &value, notes) == 2) {
1203                                         ++totals;
1204                                         if (wcwidth(value) == 1)
1205                                                 ++passed;
1206                                         fprintf(stderr, "%d\t%s", wcwidth(value), buffer);
1207                                 } else {
1208                                         fprintf(stderr, "?\t%s", buffer);
1209                                 }
1210                         }
1211                 }
1212         }
1213         fprintf(stderr, "%d/%d passed wcwidth/graphics check\n", passed, totals);
1214         return (totals == passed) ? 0 : 1;
1215 }
1216 ],
1217 [cf_cv_wcwidth_graphics=yes],
1218 [cf_cv_wcwidth_graphics=no],
1219 [cf_cv_wcwidth_graphics=unknown])
1220 ])
1221 ])dnl
1222 dnl ---------------------------------------------------------------------------
1223 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
1224 dnl -----------------
1225 dnl Check if the given compiler is really clang.  clang's C driver defines
1226 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1227 dnl not ignore some gcc options.
1228 dnl
1229 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1230 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1231 dnl the wrappers for gcc and g++ warnings.
1232 dnl
1233 dnl $1 = GCC (default) or GXX
1234 dnl $2 = CLANG_COMPILER (default)
1235 dnl $3 = CFLAGS (default) or CXXFLAGS
1236 AC_DEFUN([CF_CLANG_COMPILER],[
1237 ifelse([$2],,CLANG_COMPILER,[$2])=no
1238
1239 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1240         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1241         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1242         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
1243         AC_TRY_COMPILE([],[
1244 #ifdef __clang__
1245 #else
1246 make an error
1247 #endif
1248 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1249 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
1250 ],[])
1251         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1252         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1253 fi
1254 ])
1255 dnl ---------------------------------------------------------------------------
1256 dnl CF_CPP_PARAM_INIT version: 7 updated: 2017/01/21 11:06:25
1257 dnl -----------------
1258 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1259 dnl is a late feature for the standard and is not in some recent compilers
1260 dnl (1999/9/11).
1261 AC_DEFUN([CF_CPP_PARAM_INIT],
1262 [
1263 if test -n "$CXX"; then
1264 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1265         AC_LANG_SAVE
1266         AC_LANG_CPLUSPLUS
1267         AC_TRY_RUN([
1268 class TEST {
1269 private:
1270         int value;
1271 public:
1272         TEST(int x = 1);
1273         ~TEST();
1274 };
1275
1276 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1277 {
1278         value = x;
1279 }
1280 int main(void) { }
1281 ],
1282         [cf_cv_cpp_param_init=yes],
1283         [cf_cv_cpp_param_init=no],
1284         [cf_cv_cpp_param_init=unknown])
1285         AC_LANG_RESTORE
1286 ])
1287 fi
1288 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1289 ])dnl
1290 dnl ---------------------------------------------------------------------------
1291 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1292 dnl ------------------
1293 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1294 dnl not be supported in g++ before 3.0
1295 AC_DEFUN([CF_CPP_STATIC_CAST],
1296 [
1297 if test -n "$CXX"; then
1298
1299 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1300         AC_LANG_SAVE
1301         AC_LANG_CPLUSPLUS
1302
1303         AC_TRY_COMPILE([
1304 class NCursesPanel
1305 {
1306 public:
1307   NCursesPanel(int nlines,
1308                int ncols,
1309                int begin_y = 0,
1310                int begin_x = 0)
1311   {
1312   }
1313   NCursesPanel();
1314   ~NCursesPanel();
1315 };
1316
1317 template<class T> class NCursesUserPanel : public NCursesPanel
1318 {
1319 public:
1320   NCursesUserPanel (int nlines,
1321                     int ncols,
1322                     int begin_y = 0,
1323                     int begin_x = 0,
1324                     const T* p_UserData = static_cast<T*>(0))
1325     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1326   {
1327   };
1328   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1329   {
1330   };
1331
1332   virtual ~NCursesUserPanel() {};
1333 };
1334 ],[
1335         const char* p_UserData = static_cast<char*>(0)],
1336         [cf_cv_cpp_static_cast=yes],
1337         [cf_cv_cpp_static_cast=no])
1338
1339         AC_LANG_RESTORE
1340 ])
1341
1342 fi
1343
1344 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1345 ])dnl
1346 dnl ---------------------------------------------------------------------------
1347 dnl CF_CXX_AR_FLAGS version: 2 updated: 2015/04/17 21:13:04
1348 dnl ---------------
1349 dnl Setup special archiver flags for given compilers.
1350 AC_DEFUN([CF_CXX_AR_FLAGS],[
1351         CXX_AR='$(AR)'
1352         CXX_ARFLAGS='$(ARFLAGS)'
1353         case $cf_cv_system_name in
1354         (irix*)
1355             if test "$GXX" != yes ; then
1356                 CXX_AR='$(CXX)'
1357                 CXX_ARFLAGS='-ar -o'
1358             fi
1359             ;;
1360         (sco3.2v5*)
1361             CXXLDFLAGS="-u main"
1362             ;;
1363         (solaris2*)
1364             if test "$GXX" != yes ; then
1365                 CXX_AR='$(CXX)'
1366                 CXX_ARFLAGS='-xar -o'
1367             fi
1368             ;;
1369         esac
1370         AC_SUBST(CXXLDFLAGS)
1371         AC_SUBST(CXX_AR)
1372         AC_SUBST(CXX_ARFLAGS)
1373 ])dnl
1374 dnl ---------------------------------------------------------------------------
1375 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1376 dnl -------------------------
1377 dnl For c++, check if iostream uses "std::" namespace.
1378 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1379 AC_CHECK_HEADERS(iostream)
1380 if test x"$ac_cv_header_iostream" = xyes ; then
1381         AC_MSG_CHECKING(if iostream uses std-namespace)
1382         AC_TRY_COMPILE([
1383 #include <iostream>
1384 using std::endl;
1385 using std::cerr;],[
1386 cerr << "testing" << endl;
1387 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1388         AC_MSG_RESULT($cf_iostream_namespace)
1389         if test "$cf_iostream_namespace" = yes ; then
1390                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1391         fi
1392 fi
1393 ])dnl
1394 dnl ---------------------------------------------------------------------------
1395 dnl CF_C_INLINE version: 5 updated: 2015/04/18 08:56:57
1396 dnl -----------
1397 dnl Check if the C compiler supports "inline".
1398 dnl $1 is the name of a shell variable to set if inline is supported
1399 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1400 AC_DEFUN([CF_C_INLINE],[
1401 AC_C_INLINE
1402 $1=
1403 if test "$ac_cv_c_inline" != no ; then
1404         $1=inline
1405         if test "$INTEL_COMPILER" = yes
1406         then
1407                 :
1408         elif test "$CLANG_COMPILER" = yes
1409         then
1410                 :
1411         elif test "$GCC" = yes
1412         then
1413                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1414                 cf_save_CFLAGS=$CFLAGS
1415                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1416                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1417                 [${cf_cv_main_return:-return} foo()],
1418                 [cf_cv_gcc_inline=yes],
1419                 [cf_cv_gcc_inline=no])
1420                 CFLAGS=$cf_save_CFLAGS
1421                 ])
1422                 if test "$cf_cv_gcc_inline" = yes ; then
1423                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1424                 fi
1425         fi
1426 fi
1427 AC_SUBST($1)
1428 ])dnl
1429 dnl ---------------------------------------------------------------------------
1430 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1431 dnl ---------------
1432 AC_DEFUN([CF_DIRS_TO_MAKE],
1433 [
1434 DIRS_TO_MAKE="lib"
1435 for cf_item in $cf_list_models
1436 do
1437         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1438         for cf_item2 in $DIRS_TO_MAKE
1439         do
1440                 test $cf_item2 = $cf_subdir && break
1441         done
1442         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1443 done
1444 for cf_dir in $DIRS_TO_MAKE
1445 do
1446         test ! -d $cf_dir && mkdir $cf_dir
1447 done
1448 AC_SUBST(DIRS_TO_MAKE)
1449 ])dnl
1450 dnl ---------------------------------------------------------------------------
1451 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1452 dnl ---------------
1453 dnl You can always use "make -n" to see the actual options, but it's hard to
1454 dnl pick out/analyze warning messages when the compile-line is long.
1455 dnl
1456 dnl Sets:
1457 dnl     ECHO_LT - symbol to control if libtool is verbose
1458 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1459 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1460 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1461 dnl     ECHO_CC - symbol to put before any "cc" line
1462 dnl
1463 AC_DEFUN([CF_DISABLE_ECHO],[
1464 AC_MSG_CHECKING(if you want to see long compiling messages)
1465 CF_ARG_DISABLE(echo,
1466         [  --disable-echo          do not display "compiling" commands],
1467         [
1468         ECHO_LT='--silent'
1469         ECHO_LD='@echo linking [$]@;'
1470         RULE_CC='@echo compiling [$]<'
1471         SHOW_CC='@echo compiling [$]@'
1472         ECHO_CC='@'
1473 ],[
1474         ECHO_LT=''
1475         ECHO_LD=''
1476         RULE_CC=''
1477         SHOW_CC=''
1478         ECHO_CC=''
1479 ])
1480 AC_MSG_RESULT($enableval)
1481 AC_SUBST(ECHO_LT)
1482 AC_SUBST(ECHO_LD)
1483 AC_SUBST(RULE_CC)
1484 AC_SUBST(SHOW_CC)
1485 AC_SUBST(ECHO_CC)
1486 ])dnl
1487 dnl ---------------------------------------------------------------------------
1488 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1489 dnl ------------------------
1490 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1491 AC_MSG_CHECKING(if we want to use GNAT projects)
1492 CF_ARG_DISABLE(gnat-projects,
1493         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1494         [enable_gnat_projects=no],
1495         [enable_gnat_projects=yes])
1496 AC_MSG_RESULT($enable_gnat_projects)
1497 ])dnl
1498 dnl ---------------------------------------------------------------------------
1499 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1500 dnl ----------------
1501 dnl Combine no-leak checks with the libraries or tools that are used for the
1502 dnl checks.
1503 AC_DEFUN([CF_DISABLE_LEAKS],[
1504
1505 AC_REQUIRE([CF_WITH_DMALLOC])
1506 AC_REQUIRE([CF_WITH_DBMALLOC])
1507 AC_REQUIRE([CF_WITH_VALGRIND])
1508
1509 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1510 AC_ARG_ENABLE(leaks,
1511         [  --disable-leaks         test: free permanent memory, analyze leaks],
1512         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1513         : ${with_no_leaks:=no})
1514 AC_MSG_RESULT($with_no_leaks)
1515
1516 if test "$with_no_leaks" = yes ; then
1517         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1518         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1519 fi
1520 ])dnl
1521 dnl ---------------------------------------------------------------------------
1522 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
1523 dnl --------------------------
1524 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1525 dnl the older "-version-info" feature.  The newer feature allows us to use
1526 dnl version numbering on shared libraries which make them compatible with
1527 dnl various systems.
1528 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1529 [
1530 AC_MSG_CHECKING(if libtool -version-number should be used)
1531 CF_ARG_DISABLE(libtool-version,
1532         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1533         [cf_libtool_version=no],
1534         [cf_libtool_version=yes])
1535 AC_MSG_RESULT($cf_libtool_version)
1536
1537 if test "$cf_libtool_version" = yes ; then
1538         LIBTOOL_VERSION="-version-number"
1539 else
1540         LIBTOOL_VERSION="-version-info"
1541         case "x$VERSION" in
1542         (x)
1543                 AC_MSG_WARN(VERSION was not set)
1544                 ;;
1545         (x*.*.*)
1546                 ABI_VERSION="$VERSION"
1547                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1548                 ;;
1549         (x*:*:*)
1550                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
1551                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1552                 ;;
1553         (*)
1554                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
1555                 ;;
1556         esac
1557 fi
1558
1559 AC_SUBST(ABI_VERSION)
1560 AC_SUBST(LIBTOOL_VERSION)
1561 ])dnl
1562 dnl ---------------------------------------------------------------------------
1563 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1564 dnl ---------------------
1565 dnl The rpath-hack makes it simpler to build programs, particularly with the
1566 dnl *BSD ports which may have essential libraries in unusual places.  But it
1567 dnl can interfere with building an executable for the base system.  Use this
1568 dnl option in that case.
1569 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1570 [
1571 AC_MSG_CHECKING(if rpath-hack should be disabled)
1572 CF_ARG_DISABLE(rpath-hack,
1573         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1574         [cf_disable_rpath_hack=yes],
1575         [cf_disable_rpath_hack=no])
1576 AC_MSG_RESULT($cf_disable_rpath_hack)
1577 if test "$cf_disable_rpath_hack" = no ; then
1578         CF_RPATH_HACK
1579 fi
1580 ])
1581 dnl ---------------------------------------------------------------------------
1582 dnl CF_ENABLE_PC_FILES version: 13 updated: 2015/11/01 05:27:39
1583 dnl ------------------
1584 dnl This is the "--enable-pc-files" option, which is available if there is a
1585 dnl pkg-config configuration on the local machine.
1586 AC_DEFUN([CF_ENABLE_PC_FILES],[
1587 AC_REQUIRE([CF_PKG_CONFIG])
1588 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1589
1590 if test "x$PKG_CONFIG" != xnone
1591 then
1592         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1593 else
1594         AC_MSG_CHECKING(if we should install .pc files)
1595 fi
1596
1597 AC_ARG_ENABLE(pc-files,
1598         [  --enable-pc-files       generate and install .pc files for pkg-config],
1599         [enable_pc_files=$enableval],
1600         [enable_pc_files=no])
1601 AC_MSG_RESULT($enable_pc_files)
1602
1603 if test "x$enable_pc_files" != xno
1604 then
1605         MAKE_PC_FILES=
1606         case "x$PKG_CONFIG_LIBDIR" in
1607         (xno|xyes)
1608                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
1609                 ;;
1610         (*)
1611                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1612                 ;;
1613         esac
1614 else
1615         MAKE_PC_FILES="#"
1616 fi
1617 AC_SUBST(MAKE_PC_FILES)
1618 ])dnl
1619 dnl ---------------------------------------------------------------------------
1620 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1621 dnl ---------------
1622 dnl Check if the rpath option should be used, setting cache variable
1623 dnl cf_cv_enable_rpath if so.
1624 AC_DEFUN([CF_ENABLE_RPATH],
1625 [
1626 AC_MSG_CHECKING(if rpath option should be used)
1627 AC_ARG_ENABLE(rpath,
1628 [  --enable-rpath          use rpath option when generating shared libraries],
1629 [cf_cv_enable_rpath=$enableval],
1630 [cf_cv_enable_rpath=no])
1631 AC_MSG_RESULT($cf_cv_enable_rpath)
1632 ])dnl
1633 dnl ---------------------------------------------------------------------------
1634 dnl CF_ENABLE_STRING_HACKS version: 5 updated: 2016/10/08 17:34:11
1635 dnl ----------------------
1636 dnl On a few platforms, the compiler and/or loader nags with untruthful
1637 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1638 dnl and implying that most uses of the recommended alternatives are correct.
1639 dnl
1640 dnl Factually speaking, no one has actually counted the number of uses of these
1641 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1642 dnl instances are meaningless compared to the hundreds of millions of lines of
1643 dnl existing C code.
1644 dnl
1645 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1646 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1647 dnl standard - but evolved through phases, and older implementations are likely
1648 dnl to yield surprising results, as documented in manpages on various systems.
1649 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1650 [
1651 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1652 AC_ARG_ENABLE(string-hacks,
1653         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1654         [with_string_hacks=$enableval],
1655         [with_string_hacks=no])
1656 AC_MSG_RESULT($with_string_hacks)
1657
1658 if test "x$with_string_hacks" = "xyes"; then
1659         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1660         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1661         AC_CHECK_FUNC(strlcat,[
1662                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1663                 ],[
1664                 AC_CHECK_LIB(bsd,strlcat,[
1665                         CF_ADD_LIB(bsd)
1666                         AC_CHECK_HEADERS(bsd/string.h)
1667                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1668                         ])
1669                 ])
1670         AC_CHECK_FUNCS( strlcpy snprintf )
1671 fi
1672 ])dnl
1673 dnl ---------------------------------------------------------------------------
1674 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1675 dnl --------
1676 dnl Check if 'errno' is declared in <errno.h>
1677 AC_DEFUN([CF_ERRNO],
1678 [
1679 CF_CHECK_ERRNO(errno)
1680 ])dnl
1681 dnl ---------------------------------------------------------------------------
1682 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1683 dnl ---------------
1684 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1685 dnl math.h and builtin.h, only for ncurses
1686 AC_DEFUN([CF_ETIP_DEFINES],
1687 [
1688 AC_MSG_CHECKING(for special defines needed for etip.h)
1689 cf_save_CXXFLAGS="$CXXFLAGS"
1690 cf_result="none"
1691
1692 # etip.h includes ncurses.h which includes ncurses_dll.h
1693 # But ncurses_dll.h is generated - fix here.
1694 test -d include || mkdir include
1695 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1696
1697 for cf_math in "" MATH_H
1698 do
1699 for cf_excp in "" MATH_EXCEPTION
1700 do
1701         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1702         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1703         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1704 AC_TRY_COMPILE([
1705 #include <etip.h.in>
1706 ],[],[
1707         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1708         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1709         cf_result="$cf_math $cf_excp"
1710         break 2
1711 ],[])
1712 done
1713 done
1714 AC_MSG_RESULT($cf_result)
1715 CXXFLAGS="$cf_save_CXXFLAGS"
1716 ])
1717 dnl ---------------------------------------------------------------------------
1718 dnl CF_FIND_LINKAGE version: 21 updated: 2018/06/20 20:23:13
1719 dnl ---------------
1720 dnl Find a library (specifically the linkage used in the code fragment),
1721 dnl searching for it if it is not already in the library path.
1722 dnl See also CF_ADD_SEARCHPATH.
1723 dnl
1724 dnl Parameters (4-on are optional):
1725 dnl     $1 = headers for library entrypoint
1726 dnl     $2 = code fragment for library entrypoint
1727 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1728 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1729 dnl     $5 = action to perform if not successful
1730 dnl     $6 = module name, if not the same as the library name
1731 dnl     $7 = extra libraries
1732 dnl
1733 dnl Sets these variables:
1734 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1735 dnl     $cf_cv_header_path_$3 - include-directory if needed
1736 dnl     $cf_cv_library_path_$3 - library-directory if needed
1737 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1738 AC_DEFUN([CF_FIND_LINKAGE],[
1739
1740 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1741 # will be set on completion of the AC_TRY_LINK below.
1742 cf_cv_header_path_$3=
1743 cf_cv_library_path_$3=
1744
1745 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1746
1747 cf_save_LIBS="$LIBS"
1748
1749 AC_TRY_LINK([$1],[$2],[
1750         cf_cv_find_linkage_$3=yes
1751         cf_cv_header_path_$3=/usr/include
1752         cf_cv_library_path_$3=/usr/lib
1753 ],[
1754
1755 LIBS="-l$3 $7 $cf_save_LIBS"
1756
1757 AC_TRY_LINK([$1],[$2],[
1758         cf_cv_find_linkage_$3=yes
1759         cf_cv_header_path_$3=/usr/include
1760         cf_cv_library_path_$3=/usr/lib
1761         cf_cv_library_file_$3="-l$3"
1762 ],[
1763         cf_cv_find_linkage_$3=no
1764         LIBS="$cf_save_LIBS"
1765
1766         CF_VERBOSE(find linkage for $3 library)
1767         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1768
1769         cf_save_CPPFLAGS="$CPPFLAGS"
1770         cf_test_CPPFLAGS="$CPPFLAGS"
1771
1772         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1773         for cf_cv_header_path_$3 in $cf_search
1774         do
1775                 if test -d $cf_cv_header_path_$3 ; then
1776                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1777                         CPPFLAGS="$cf_save_CPPFLAGS"
1778                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
1779                         AC_TRY_COMPILE([$1],[$2],[
1780                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1781                                 cf_cv_find_linkage_$3=maybe
1782                                 cf_test_CPPFLAGS="$CPPFLAGS"
1783                                 break],[
1784                                 CPPFLAGS="$cf_save_CPPFLAGS"
1785                                 ])
1786                 fi
1787         done
1788
1789         if test "$cf_cv_find_linkage_$3" = maybe ; then
1790
1791                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1792
1793                 cf_save_LIBS="$LIBS"
1794                 cf_save_LDFLAGS="$LDFLAGS"
1795
1796                 ifelse([$6],,,[
1797                 CPPFLAGS="$cf_test_CPPFLAGS"
1798                 LIBS="-l$3 $7 $cf_save_LIBS"
1799                 AC_TRY_LINK([$1],[$2],[
1800                         CF_VERBOSE(... found $3 library in system)
1801                         cf_cv_find_linkage_$3=yes])
1802                         CPPFLAGS="$cf_save_CPPFLAGS"
1803                         LIBS="$cf_save_LIBS"
1804                         ])
1805
1806                 if test "$cf_cv_find_linkage_$3" != yes ; then
1807                         CF_LIBRARY_PATH(cf_search,$3)
1808                         for cf_cv_library_path_$3 in $cf_search
1809                         do
1810                                 if test -d $cf_cv_library_path_$3 ; then
1811                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1812                                         CPPFLAGS="$cf_test_CPPFLAGS"
1813                                         LIBS="-l$3 $7 $cf_save_LIBS"
1814                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1815                                         AC_TRY_LINK([$1],[$2],[
1816                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1817                                         cf_cv_find_linkage_$3=yes
1818                                         cf_cv_library_file_$3="-l$3"
1819                                         break],[
1820                                         CPPFLAGS="$cf_save_CPPFLAGS"
1821                                         LIBS="$cf_save_LIBS"
1822                                         LDFLAGS="$cf_save_LDFLAGS"
1823                                         ])
1824                                 fi
1825                         done
1826                         CPPFLAGS="$cf_save_CPPFLAGS"
1827                         LDFLAGS="$cf_save_LDFLAGS"
1828                 fi
1829
1830         else
1831                 cf_cv_find_linkage_$3=no
1832         fi
1833         ],$7)
1834 ])
1835
1836 LIBS="$cf_save_LIBS"
1837
1838 if test "$cf_cv_find_linkage_$3" = yes ; then
1839 ifelse([$4],,[
1840         CF_ADD_INCDIR($cf_cv_header_path_$3)
1841         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1842         CF_ADD_LIB($3)
1843 ],[$4])
1844 else
1845 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1846 fi
1847 ])dnl
1848 dnl ---------------------------------------------------------------------------
1849 dnl CF_FIND_SUB_INCDIR version: 2 updated: 2015/04/17 21:13:04
1850 dnl ------------------
1851 dnl Find an include-directory with the given leaf-name.  This is useful for
1852 dnl example with FreeBSD ports, which use this convention to distinguish
1853 dnl different versions of the same port.
1854 AC_DEFUN([CF_FIND_SUB_INCDIR],[
1855         CF_SUBDIR_PATH(cf_search,$1,include)
1856         for cf_item in $cf_search
1857         do
1858                 case $cf_item in
1859                 (*/$1)
1860                         CF_ADD_INCDIR($cf_item)
1861                         ;;
1862                 esac
1863         done
1864 ])dnl
1865 dnl ---------------------------------------------------------------------------
1866 dnl CF_FIND_SUB_LIBDIR version: 2 updated: 2015/04/17 21:13:04
1867 dnl ------------------
1868 dnl Find a library-directory with the given leaf-name.  This is useful for
1869 dnl example with FreeBSD ports, which use this convention to distinguish
1870 dnl different versions of the same port.
1871 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
1872         CF_SUBDIR_PATH(cf_search,$1,lib)
1873         for cf_item in $cf_search
1874         do
1875                 case $cf_item in
1876                 (*/$1)
1877                         CF_ADD_LIBDIR($cf_item)
1878                         ;;
1879                 esac
1880         done
1881 ])dnl
1882 dnl ---------------------------------------------------------------------------
1883 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
1884 dnl -----------------
1885 dnl make ADAFLAGS consistent with CFLAGS
1886 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1887         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1888         case "$CFLAGS" in
1889         (*-g*)
1890                 CF_ADD_ADAFLAGS(-g)
1891                 ;;
1892         esac
1893         case "$CFLAGS" in
1894         (*-O*)
1895                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1896                 CF_ADD_ADAFLAGS($cf_O_flag)
1897                 ;;
1898         esac
1899         AC_MSG_RESULT($ADAFLAGS)
1900 ])dnl
1901 dnl ---------------------------------------------------------------------------
1902 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
1903 dnl --------------
1904 dnl Forget that we saw the given tool.
1905 AC_DEFUN([CF_FORGET_TOOL],[
1906 unset ac_cv_prog_ac_ct_$1
1907 unset ac_ct_$1
1908 unset $1
1909 ])dnl
1910 dnl ---------------------------------------------------------------------------
1911 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
1912 dnl -------------
1913 dnl Test for dlsym() and related functions, as well as libdl.
1914 dnl
1915 dnl Sets
1916 dnl     $cf_have_dlsym
1917 dnl     $cf_have_libdl
1918 AC_DEFUN([CF_FUNC_DLSYM],[
1919 cf_have_dlsym=no
1920 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1921
1922 cf_have_libdl=no
1923 AC_CHECK_LIB(dl,dlsym,[
1924         cf_have_dlsym=yes
1925         cf_have_libdl=yes])])
1926
1927 if test "$cf_have_dlsym" = yes ; then
1928         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
1929
1930         AC_MSG_CHECKING(whether able to link to dl*() functions)
1931         AC_TRY_LINK([#include <dlfcn.h>],[
1932                 void *obj;
1933                 if ((obj = dlopen("filename", 0)) != 0) {
1934                         if (dlsym(obj, "symbolname") == 0) {
1935                         dlclose(obj);
1936                         }
1937                 }],[
1938                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
1939                 AC_MSG_ERROR(Cannot link test program for libdl)])
1940         AC_MSG_RESULT(ok)
1941 else
1942         AC_MSG_ERROR(Cannot find dlsym function)
1943 fi
1944 ])
1945 dnl ---------------------------------------------------------------------------
1946 dnl CF_FUNC_MEMMOVE version: 9 updated: 2017/01/21 11:06:25
1947 dnl ---------------
1948 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1949 dnl is found, add our own version of memmove to the list of objects.
1950 AC_DEFUN([CF_FUNC_MEMMOVE],
1951 [
1952 AC_CHECK_FUNC(memmove,,[
1953 AC_CHECK_FUNC(bcopy,[
1954         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1955                 AC_TRY_RUN([
1956 int main(void) {
1957         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1958         char temp[40];
1959         bcopy(data, temp, sizeof(data));
1960         bcopy(temp+10, temp, 15);
1961         bcopy(temp+5, temp+15, 10);
1962         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1963 }
1964                 ],
1965                 [cf_cv_good_bcopy=yes],
1966                 [cf_cv_good_bcopy=no],
1967                 [cf_cv_good_bcopy=unknown])
1968                 ])
1969         ],[cf_cv_good_bcopy=no])
1970         if test "$cf_cv_good_bcopy" = yes ; then
1971                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
1972         else
1973                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
1974         fi
1975 ])])dnl
1976 dnl ---------------------------------------------------------------------------
1977 dnl CF_FUNC_NANOSLEEP version: 5 updated: 2017/01/21 11:06:25
1978 dnl -----------------
1979 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1980 dnl AIX 4.x, provide a non-working version.
1981 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1982 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1983 AC_TRY_RUN([
1984 #include <stdio.h>
1985 #include <errno.h>
1986 #include <time.h>
1987
1988 #ifdef HAVE_SYS_TIME_H
1989 #include <sys/time.h>
1990 #endif
1991
1992 int main(void) {
1993         struct timespec ts1, ts2;
1994         int code;
1995         ts1.tv_sec  = 0;
1996         ts1.tv_nsec = 750000000;
1997         ts2.tv_sec  = 0;
1998         ts2.tv_nsec = 0;
1999         errno = 0;
2000         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
2001         ${cf_cv_main_return:-return}(code != 0);
2002 }
2003 ],
2004         [cf_cv_func_nanosleep=yes],
2005         [cf_cv_func_nanosleep=no],
2006         [cf_cv_func_nanosleep=unknown])])
2007
2008 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
2009 ])
2010 dnl ---------------------------------------------------------------------------
2011 dnl CF_FUNC_OPENPTY version: 5 updated: 2015/09/12 14:46:50
2012 dnl ---------------
2013 dnl Check for openpty() function, along with <pty.h> header.  It may need the
2014 dnl "util" library as well.
2015 AC_DEFUN([CF_FUNC_OPENPTY],
2016 [
2017 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
2018 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
2019         cf_save_LIBS="$LIBS"
2020         test $cf_cv_lib_util = yes && { CF_ADD_LIB(util) }
2021         for cf_header in pty.h libutil.h util.h
2022         do
2023         AC_TRY_LINK([
2024 #include <$cf_header>
2025 ],[
2026         int x = openpty((int *)0, (int *)0, (char *)0,
2027                                    (struct termios *)0, (struct winsize *)0);
2028 ],[
2029                 cf_cv_func_openpty=$cf_header
2030                 break
2031 ],[
2032                 cf_cv_func_openpty=no
2033 ])
2034         done
2035         LIBS="$cf_save_LIBS"
2036 ])
2037 ])dnl
2038 dnl ---------------------------------------------------------------------------
2039 dnl CF_FUNC_POLL version: 9 updated: 2015/10/10 13:27:32
2040 dnl ------------
2041 dnl See if the poll function really works.  Some platforms have poll(), but
2042 dnl it does not work for terminals or files.
2043 AC_DEFUN([CF_FUNC_POLL],[
2044 tty 2>&1 >/dev/null || { AC_CHECK_FUNCS(posix_openpt) }
2045 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
2046 AC_TRY_RUN([
2047 #include <stdlib.h>
2048 #include <stdio.h>
2049 #include <unistd.h>
2050 #include <fcntl.h>
2051 #ifdef HAVE_POLL_H
2052 #include <poll.h>
2053 #else
2054 #include <sys/poll.h>
2055 #endif
2056 int main(void) {
2057         struct pollfd myfds;
2058         int ret;
2059
2060         /* check for Darwin bug with respect to "devices" */
2061         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
2062         if (myfds.fd < 0)
2063                 myfds.fd = 0;
2064         myfds.events = POLLIN;
2065         myfds.revents = 0;
2066
2067         ret = poll(&myfds, 1, 100);
2068
2069         if (ret < 0 || (myfds.revents & POLLNVAL)) {
2070                 ret = -1;
2071         } else {
2072                 int fd = 0;
2073                 if (!isatty(fd)) {
2074                         fd = open("/dev/tty", 2);       /* O_RDWR */
2075                 }
2076 #ifdef HAVE_POSIX_OPENPT
2077                 if (fd < 0) {
2078                         fd = posix_openpt(O_RDWR);
2079                 }
2080 #endif
2081
2082                 if (fd >= 0) {
2083                         /* also check with standard input */
2084                         myfds.fd = fd;
2085                         myfds.events = POLLIN;
2086                         myfds.revents = 0;
2087                         ret = poll(&myfds, 1, 100);
2088                 } else {
2089                         ret = -1;
2090                 }
2091         }
2092         ${cf_cv_main_return:-return}(ret < 0);
2093 }],
2094         [cf_cv_working_poll=yes],
2095         [cf_cv_working_poll=no],
2096         [cf_cv_working_poll=unknown])])
2097 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
2098 ])dnl
2099 dnl ---------------------------------------------------------------------------
2100 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
2101 dnl ---------------
2102 dnl Some old/broken variations define tcgetattr() only as a macro in
2103 dnl termio(s).h
2104 AC_DEFUN([CF_FUNC_TERMIOS],[
2105 AC_REQUIRE([CF_STRUCT_TERMIOS])
2106 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
2107 AC_TRY_LINK([
2108 #include <sys/types.h>
2109 #ifdef HAVE_UNISTD_H
2110 #include <unistd.h>
2111 #endif
2112 #ifdef HAVE_TERMIOS_H
2113 #include <termios.h>
2114 #define TTY struct termios
2115 #else
2116 #ifdef HAVE_TERMIO_H
2117 #include <termio.h>
2118 #define TTY struct termio
2119 #endif
2120 #endif
2121 ],[
2122 TTY foo;
2123 tcgetattr(1, &foo);],
2124 [cf_cv_have_tcgetattr=yes],
2125 [cf_cv_have_tcgetattr=no])])
2126 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
2127 ])dnl
2128 dnl ---------------------------------------------------------------------------
2129 dnl CF_FUNC_VSSCANF version: 6 updated: 2015/04/18 08:56:57
2130 dnl ---------------
2131 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
2132 dnl versions of C.  It is in the GNU C library, and can often be simulated by
2133 dnl other functions.
2134 AC_DEFUN([CF_FUNC_VSSCANF],
2135 [
2136 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
2137 AC_TRY_LINK([
2138 #include <stdarg.h>
2139 #include <stdio.h>],[
2140         va_list ap;
2141         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
2142 AC_TRY_LINK([
2143 #include <stdarg.h>
2144 #include <stdio.h>],[
2145         FILE strbuf;
2146         char *str = "from";
2147
2148         strbuf._flag = _IOREAD;
2149         strbuf._ptr = strbuf._base = (unsigned char *) str;
2150         strbuf._cnt = strlen(str);
2151         strbuf._file = _NFILE;
2152         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
2153 AC_TRY_LINK([
2154 #include <stdarg.h>
2155 #include <stdio.h>],[
2156         FILE strbuf;
2157         char *str = "from";
2158
2159         strbuf._flag = _IOREAD;
2160         strbuf._ptr = strbuf._base = (unsigned char *) str;
2161         strbuf._cnt = strlen(str);
2162         strbuf._file = _NFILE;
2163         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
2164 cf_cv_func_vsscanf=no])])])])
2165
2166 case $cf_cv_func_vsscanf in
2167 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
2168 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
2169 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
2170 esac
2171
2172 ])dnl
2173 dnl ---------------------------------------------------------------------------
2174 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
2175 dnl -----------------
2176 dnl Test for availability of useful gcc __attribute__ directives to quiet
2177 dnl compiler warnings.  Though useful, not all are supported -- and contrary
2178 dnl to documentation, unrecognized directives cause older compilers to barf.
2179 AC_DEFUN([CF_GCC_ATTRIBUTES],
2180 [
2181 if test "$GCC" = yes
2182 then
2183 cat > conftest.i <<EOF
2184 #ifndef GCC_PRINTF
2185 #define GCC_PRINTF 0
2186 #endif
2187 #ifndef GCC_SCANF
2188 #define GCC_SCANF 0
2189 #endif
2190 #ifndef GCC_NORETURN
2191 #define GCC_NORETURN /* nothing */
2192 #endif
2193 #ifndef GCC_UNUSED
2194 #define GCC_UNUSED /* nothing */
2195 #endif
2196 EOF
2197 if test "$GCC" = yes
2198 then
2199         AC_CHECKING([for $CC __attribute__ directives])
2200 cat > conftest.$ac_ext <<EOF
2201 #line __oline__ "${as_me:-configure}"
2202 #include "confdefs.h"
2203 #include "conftest.h"
2204 #include "conftest.i"
2205 #if     GCC_PRINTF
2206 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
2207 #else
2208 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
2209 #endif
2210 #if     GCC_SCANF
2211 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2212 #else
2213 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2214 #endif
2215 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2216 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
2217 extern void foo(void) GCC_NORETURN;
2218 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
2219 EOF
2220         cf_printf_attribute=no
2221         cf_scanf_attribute=no
2222         for cf_attribute in scanf printf unused noreturn
2223         do
2224                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2225                 cf_directive="__attribute__(($cf_attribute))"
2226                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2227
2228                 case $cf_attribute in
2229                 (printf)
2230                         cf_printf_attribute=yes
2231                         cat >conftest.h <<EOF
2232 #define GCC_$cf_ATTRIBUTE 1
2233 EOF
2234                         ;;
2235                 (scanf)
2236                         cf_scanf_attribute=yes
2237                         cat >conftest.h <<EOF
2238 #define GCC_$cf_ATTRIBUTE 1
2239 EOF
2240                         ;;
2241                 (*)
2242                         cat >conftest.h <<EOF
2243 #define GCC_$cf_ATTRIBUTE $cf_directive
2244 EOF
2245                         ;;
2246                 esac
2247
2248                 if AC_TRY_EVAL(ac_compile); then
2249                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
2250                         cat conftest.h >>confdefs.h
2251                         case $cf_attribute in
2252                         (noreturn)
2253                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
2254                                 ;;
2255                         (printf)
2256                                 cf_value='/* nothing */'
2257                                 if test "$cf_printf_attribute" != no ; then
2258                                         cf_value='__attribute__((format(printf,fmt,var)))'
2259                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
2260                                 fi
2261                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
2262                                 ;;
2263                         (scanf)
2264                                 cf_value='/* nothing */'
2265                                 if test "$cf_scanf_attribute" != no ; then
2266                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2267                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2268                                 fi
2269                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2270                                 ;;
2271                         (unused)
2272                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2273                                 ;;
2274                         esac
2275                 fi
2276         done
2277 else
2278         fgrep define conftest.i >>confdefs.h
2279 fi
2280 rm -rf conftest*
2281 fi
2282 ])dnl
2283 dnl ---------------------------------------------------------------------------
2284 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
2285 dnl --------------
2286 dnl Find version of gcc
2287 AC_DEFUN([CF_GCC_VERSION],[
2288 AC_REQUIRE([AC_PROG_CC])
2289 GCC_VERSION=none
2290 if test "$GCC" = yes ; then
2291         AC_MSG_CHECKING(version of $CC)
2292         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2293         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2294         AC_MSG_RESULT($GCC_VERSION)
2295 fi
2296 ])dnl
2297 dnl ---------------------------------------------------------------------------
2298 dnl CF_GCC_WARNINGS version: 33 updated: 2018/06/20 20:23:13
2299 dnl ---------------
2300 dnl Check if the compiler supports useful warning options.  There's a few that
2301 dnl we don't use, simply because they're too noisy:
2302 dnl
2303 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2304 dnl     -Wredundant-decls (system headers make this too noisy)
2305 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2306 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2307 dnl             is enabled for ncurses using "--enable-const".
2308 dnl     -pedantic
2309 dnl
2310 dnl Parameter:
2311 dnl     $1 is an optional list of gcc warning flags that a particular
2312 dnl             application might want to use, e.g., "no-unused" for
2313 dnl             -Wno-unused
2314 dnl Special:
2315 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2316 dnl
2317 AC_DEFUN([CF_GCC_WARNINGS],
2318 [
2319 AC_REQUIRE([CF_GCC_VERSION])
2320 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2321 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2322
2323 cat > conftest.$ac_ext <<EOF
2324 #line __oline__ "${as_me:-configure}"
2325 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2326 EOF
2327
2328 if test "$INTEL_COMPILER" = yes
2329 then
2330 # The "-wdXXX" options suppress warnings:
2331 # remark #1419: external declaration in primary source file
2332 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2333 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2334 # remark #193: zero used for undefined preprocessing identifier
2335 # remark #593: variable "curs_sb_left_arrow" was set but never used
2336 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2337 # remark #869: parameter "tw" was never referenced
2338 # remark #981: operands are evaluated in unspecified order
2339 # warning #279: controlling expression is constant
2340
2341         AC_CHECKING([for $CC warning options])
2342         cf_save_CFLAGS="$CFLAGS"
2343         EXTRA_CFLAGS="-Wall"
2344         for cf_opt in \
2345                 wd1419 \
2346                 wd1683 \
2347                 wd1684 \
2348                 wd193 \
2349                 wd593 \
2350                 wd279 \
2351                 wd810 \
2352                 wd869 \
2353                 wd981
2354         do
2355                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2356                 if AC_TRY_EVAL(ac_compile); then
2357                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2358                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2359                 fi
2360         done
2361         CFLAGS="$cf_save_CFLAGS"
2362
2363 elif test "$GCC" = yes
2364 then
2365         AC_CHECKING([for $CC warning options])
2366         cf_save_CFLAGS="$CFLAGS"
2367         EXTRA_CFLAGS=
2368         cf_warn_CONST=""
2369         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2370         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2371         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2372         for cf_opt in W Wall \
2373                 Wbad-function-cast \
2374                 Wcast-align \
2375                 Wcast-qual \
2376                 Wdeclaration-after-statement \
2377                 Wextra \
2378                 Winline \
2379                 Wmissing-declarations \
2380                 Wmissing-prototypes \
2381                 Wnested-externs \
2382                 Wpointer-arith \
2383                 Wshadow \
2384                 Wstrict-prototypes \
2385                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
2386         do
2387                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2388                 if AC_TRY_EVAL(ac_compile); then
2389                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2390                         case $cf_opt in
2391                         (Wcast-qual)
2392                                 CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
2393                                 ;;
2394                         (Winline)
2395                                 case $GCC_VERSION in
2396                                 ([[34]].*)
2397                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2398                                         continue;;
2399                                 esac
2400                                 ;;
2401                         (Wpointer-arith)
2402                                 case $GCC_VERSION in
2403                                 ([[12]].*)
2404                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2405                                         continue;;
2406                                 esac
2407                                 ;;
2408                         esac
2409                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2410                 fi
2411         done
2412         CFLAGS="$cf_save_CFLAGS"
2413 fi
2414 rm -rf conftest*
2415
2416 AC_SUBST(EXTRA_CFLAGS)
2417 ])dnl
2418 dnl ---------------------------------------------------------------------------
2419 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
2420 dnl ----------------
2421 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2422 dnl unistd.h or (nonstandard) in getopt.h
2423 AC_DEFUN([CF_GETOPT_HEADER],
2424 [
2425 AC_HAVE_HEADERS(unistd.h getopt.h)
2426 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2427 cf_cv_getopt_header=none
2428 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2429 do
2430 AC_TRY_COMPILE([
2431 #include <$cf_header>],
2432 [int x = optind; char *y = optarg],
2433 [cf_cv_getopt_header=$cf_header
2434  break])
2435 done
2436 ])
2437 if test $cf_cv_getopt_header != none ; then
2438         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2439 fi
2440 if test $cf_cv_getopt_header = getopt.h ; then
2441         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2442 fi
2443 ])dnl
2444 dnl ---------------------------------------------------------------------------
2445 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2446 dnl -----------------
2447 AC_DEFUN([CF_GNATPREP_OPT_T],[
2448 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2449 cf_cv_gnatprep_opt_t=no
2450 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2451 ])
2452 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
2453 AC_SUBST(GNATPREP_OPTS)
2454 ])dnl
2455 dnl ---------------------------------------------------------------------------
2456 dnl CF_GNAT_GENERICS version: 3 updated: 2015/04/17 21:13:04
2457 dnl ----------------
2458 AC_DEFUN([CF_GNAT_GENERICS],
2459 [
2460 AC_REQUIRE([CF_GNAT_VERSION])
2461
2462 AC_MSG_CHECKING(if GNAT supports generics)
2463 case $cf_gnat_version in
2464 (3.[[1-9]]*|[[4-9]].*)
2465         cf_gnat_generics=yes
2466         ;;
2467 (*)
2468         cf_gnat_generics=no
2469         ;;
2470 esac
2471 AC_MSG_RESULT($cf_gnat_generics)
2472
2473 if test "$cf_gnat_generics" = yes
2474 then
2475         cf_compile_generics=generics
2476         cf_generic_objects="\${GENOBJS}"
2477 else
2478         cf_compile_generics=
2479         cf_generic_objects=
2480 fi
2481
2482 AC_SUBST(cf_compile_generics)
2483 AC_SUBST(cf_generic_objects)
2484 ])dnl
2485 dnl ---------------------------------------------------------------------------
2486 dnl CF_GNAT_PROJECTS version: 9 updated: 2018/01/14 15:46:09
2487 dnl ----------------
2488 dnl GNAT projects are configured with ".gpr" project files.
2489 dnl GNAT libraries are a further development, using the project feature.
2490 AC_DEFUN([CF_GNAT_PROJECTS],
2491 [
2492 AC_REQUIRE([CF_GNAT_VERSION])
2493 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
2494
2495 cf_gnat_libraries=no
2496 cf_gnat_projects=no
2497
2498 if test "$enable_gnat_projects" != no ; then
2499 AC_MSG_CHECKING(if GNAT supports project files)
2500 case $cf_gnat_version in
2501 (3.[[0-9]]*)
2502         ;;
2503 (*)
2504         case $cf_cv_system_name in
2505         (cygwin*|msys*)
2506                 ;;
2507         (*)
2508                 rm -rf conftest* *~conftest*
2509                 if mkdir conftest.src conftest.bin conftest.lib
2510                 then
2511                         cd conftest.src
2512                         rm -rf conftest* *~conftest*
2513                         cat >>library.gpr <<CF_EOF
2514 project Library is
2515   Kind := External ("LIB_KIND");
2516   for Library_Name use "ConfTest";
2517   for Object_Dir use ".";
2518   for Library_ALI_Dir use External("LIBRARY_DIR");
2519   for Library_Version use External ("SONAME");
2520   for Library_Kind use Kind;
2521   for Library_Dir use External("BUILD_DIR");
2522   Source_Dir := External ("SOURCE_DIR");
2523   for Source_Dirs use (Source_Dir);
2524 end Library;
2525 CF_EOF
2526                         cat >>confpackage.ads <<CF_EOF
2527 package ConfPackage is
2528    procedure conftest;
2529 end ConfPackage;
2530 CF_EOF
2531                         cat >>confpackage.adb <<CF_EOF
2532 with Text_IO;
2533 package body ConfPackage is
2534    procedure conftest is
2535    begin
2536       Text_IO.Put ("Hello World");
2537       Text_IO.New_Line;
2538    end conftest;
2539 end ConfPackage;
2540 CF_EOF
2541                         if ( $cf_ada_make $ADAFLAGS \
2542                                         -Plibrary.gpr \
2543                                         -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2544                                         -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2545                                         -XSOURCE_DIR=`pwd` \
2546                                         -XSONAME=libConfTest.so.1 \
2547                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2548                                 cf_gnat_projects=yes
2549                         fi
2550                         cd ..
2551                 fi
2552                 if test -f conftest.lib/confpackage.ali
2553                 then
2554                         cf_gnat_libraries=yes
2555                 fi
2556                 rm -rf conftest* *~conftest*
2557                 ;;
2558         esac
2559         ;;
2560 esac
2561 AC_MSG_RESULT($cf_gnat_projects)
2562 fi # enable_gnat_projects
2563
2564 if test $cf_gnat_projects = yes
2565 then
2566         AC_MSG_CHECKING(if GNAT supports libraries)
2567         AC_MSG_RESULT($cf_gnat_libraries)
2568 fi
2569
2570 if test "$cf_gnat_projects" = yes
2571 then
2572         USE_OLD_MAKERULES="#"
2573         USE_GNAT_PROJECTS=""
2574 else
2575         USE_OLD_MAKERULES=""
2576         USE_GNAT_PROJECTS="#"
2577 fi
2578
2579 if test "$cf_gnat_libraries" = yes
2580 then
2581         USE_GNAT_LIBRARIES=""
2582 else
2583         USE_GNAT_LIBRARIES="#"
2584 fi
2585
2586 AC_SUBST(USE_OLD_MAKERULES)
2587 AC_SUBST(USE_GNAT_PROJECTS)
2588 AC_SUBST(USE_GNAT_LIBRARIES)
2589 ])dnl
2590 dnl ---------------------------------------------------------------------------
2591 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2592 dnl --------------
2593 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2594 dnl is noted that gnat may compile a tasking unit even for configurations which
2595 dnl fail at runtime.
2596 AC_DEFUN([CF_GNAT_SIGINT],[
2597 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2598 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2599
2600 package ConfTest is
2601
2602    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2603    pragma Unreserve_All_Interrupts;
2604    pragma Warnings (On);
2605
2606    protected Process is
2607       procedure Stop;
2608       function Continue return Boolean;
2609       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2610    private
2611       Done : Boolean := False;
2612    end Process;
2613
2614 end ConfTest;],
2615 [package body ConfTest is
2616    protected body Process is
2617       procedure Stop is
2618       begin
2619          Done := True;
2620       end Stop;
2621       function Continue return Boolean is
2622       begin
2623          return not Done;
2624       end Continue;
2625    end Process;
2626 end ConfTest;],
2627         [cf_cv_gnat_sigint=yes],
2628         [cf_cv_gnat_sigint=no])])
2629
2630 if test $cf_cv_gnat_sigint = yes ; then
2631         USE_GNAT_SIGINT=""
2632 else
2633         USE_GNAT_SIGINT="#"
2634 fi
2635 AC_SUBST(USE_GNAT_SIGINT)
2636 ])dnl
2637 dnl ---------------------------------------------------------------------------
2638 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2639 dnl ----------------
2640 dnl Verify that a test program compiles/links with GNAT.
2641 dnl $cf_ada_make is set to the program that compiles/links
2642 dnl $ADAFLAGS may be set to the GNAT flags.
2643 dnl
2644 dnl $1 is the text of the spec
2645 dnl $2 is the text of the body
2646 dnl $3 is the shell command to execute if successful
2647 dnl $4 is the shell command to execute if not successful
2648 AC_DEFUN([CF_GNAT_TRY_LINK],
2649 [
2650 rm -rf conftest* *~conftest*
2651 cat >>conftest.ads <<CF_EOF
2652 $1
2653 CF_EOF
2654 cat >>conftest.adb <<CF_EOF
2655 $2
2656 CF_EOF
2657 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2658 ifelse($3,,      :,[      $3])
2659 ifelse($4,,,[else
2660    $4])
2661 fi
2662 rm -rf conftest* *~conftest*
2663 ])dnl
2664 dnl ---------------------------------------------------------------------------
2665 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2666 dnl ---------------
2667 dnl Verify that a test program compiles and runs with GNAT
2668 dnl $cf_ada_make is set to the program that compiles/links
2669 dnl $ADAFLAGS may be set to the GNAT flags.
2670 dnl
2671 dnl $1 is the text of the spec
2672 dnl $2 is the text of the body
2673 dnl $3 is the shell command to execute if successful
2674 dnl $4 is the shell command to execute if not successful
2675 AC_DEFUN([CF_GNAT_TRY_RUN],
2676 [
2677 rm -rf conftest* *~conftest*
2678 cat >>conftest.ads <<CF_EOF
2679 $1
2680 CF_EOF
2681 cat >>conftest.adb <<CF_EOF
2682 $2
2683 CF_EOF
2684 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2685    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2686 ifelse($3,,      :,[      $3])
2687 ifelse($4,,,[   else
2688       $4])
2689    fi
2690 ifelse($4,,,[else
2691    $4])
2692 fi
2693 rm -rf conftest* *~conftest*
2694 ])dnl
2695 dnl ---------------------------------------------------------------------------
2696 dnl CF_GNAT_VERSION version: 20 updated: 2015/04/18 08:56:57
2697 dnl ---------------
2698 dnl Verify version of GNAT.
2699 AC_DEFUN([CF_GNAT_VERSION],
2700 [
2701 AC_MSG_CHECKING(for gnat version)
2702 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2703         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2704         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2705 AC_MSG_RESULT($cf_gnat_version)
2706
2707 case $cf_gnat_version in
2708 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
2709         cf_cv_prog_gnat_correct=yes
2710         ;;
2711 (*)
2712         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2713         cf_cv_prog_gnat_correct=no
2714         ;;
2715 esac
2716 ])
2717 dnl ---------------------------------------------------------------------------
2718 dnl CF_GNU_SOURCE version: 9 updated: 2018/06/20 20:23:13
2719 dnl -------------
2720 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2721 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2722 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2723 dnl since it is interwoven with GNU extensions.
2724 dnl
2725 dnl Well, yes we could work around it...
2726 dnl
2727 dnl Parameters:
2728 dnl     $1 is the nominal value for _XOPEN_SOURCE
2729 AC_DEFUN([CF_GNU_SOURCE],
2730 [
2731 cf_gnu_xopen_source=ifelse($1,,500,$1)
2732
2733 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
2734 AC_TRY_COMPILE([#include <sys/types.h>],[
2735         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
2736                 return 0;
2737         #else
2738         #       error not GNU C library
2739         #endif],
2740         [cf_cv_gnu_library=yes],
2741         [cf_cv_gnu_library=no])
2742 ])
2743
2744 if test x$cf_cv_gnu_library = xyes; then
2745
2746         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
2747         # was changed to help a little...
2748         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
2749                 cf_save="$CPPFLAGS"
2750                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
2751                 AC_TRY_COMPILE([#include <sys/types.h>],[
2752                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
2753                                 return 0;
2754                         #else
2755                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
2756                         #endif],
2757                         [cf_cv_gnu_library_219=yes],
2758                         [cf_cv_gnu_library_219=no])
2759                 CPPFLAGS="$cf_save"
2760         ])
2761
2762         if test "x$cf_cv_gnu_library_219" = xyes; then
2763                 cf_save="$CPPFLAGS"
2764                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
2765                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
2766                         AC_TRY_COMPILE([
2767                                 #include <limits.h>
2768                                 #include <sys/types.h>
2769                                 ],[
2770                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
2771                                         return 0;
2772                                 #else
2773                                 #       error GNU C library is too old
2774                                 #endif],
2775                                 [cf_cv_gnu_dftsrc_219=yes],
2776                                 [cf_cv_gnu_dftsrc_219=no])
2777                         ])
2778                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
2779         else
2780                 cf_cv_gnu_dftsrc_219=maybe
2781         fi
2782
2783         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
2784
2785                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2786                 AC_TRY_COMPILE([#include <sys/types.h>],[
2787                         #ifndef _XOPEN_SOURCE
2788                         #error  expected _XOPEN_SOURCE to be defined
2789                         #endif],
2790                         [cf_cv_gnu_source=no],
2791                         [cf_save="$CPPFLAGS"
2792                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
2793                          AC_TRY_COMPILE([#include <sys/types.h>],[
2794                                 #ifdef _XOPEN_SOURCE
2795                                 #error  expected _XOPEN_SOURCE to be undefined
2796                                 #endif],
2797                                 [cf_cv_gnu_source=no],
2798                                 [cf_cv_gnu_source=yes])
2799                         CPPFLAGS="$cf_save"
2800                         ])
2801                 ])
2802
2803                 if test "$cf_cv_gnu_source" = yes
2804                 then
2805                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
2806                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
2807                         AC_TRY_COMPILE([#include <sys/types.h>],[
2808                                 #ifdef _DEFAULT_SOURCE
2809                                 #error  expected _DEFAULT_SOURCE to be undefined
2810                                 #endif],
2811                                 [cf_cv_default_source=no],
2812                                 [cf_cv_default_source=yes])
2813                         ])
2814                         if test "$cf_cv_default_source" = yes
2815                         then
2816                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
2817                         fi
2818                 fi
2819         fi
2820
2821 fi
2822 ])dnl
2823 dnl ---------------------------------------------------------------------------
2824 dnl CF_GPP_LIBRARY version: 12 updated: 2015/04/17 21:13:04
2825 dnl --------------
2826 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2827 dnl problem :-).  If we have the compiler but no library, we'll be able to
2828 dnl configure, but won't be able to build the c++ demo program.
2829 AC_DEFUN([CF_GPP_LIBRARY],
2830 [
2831 cf_cxx_library=unknown
2832 case $cf_cv_system_name in
2833 (os2*)
2834         cf_gpp_libname=gpp
2835         ;;
2836 (*)
2837         cf_gpp_libname=g++
2838         ;;
2839 esac
2840 if test "$GXX" = yes; then
2841         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2842         cf_save="$LIBS"
2843         CF_ADD_LIB($cf_gpp_libname)
2844         AC_TRY_LINK([
2845 #include <$cf_gpp_libname/builtin.h>
2846         ],
2847         [two_arg_error_handler_t foo2 = lib_error_handler],
2848         [cf_cxx_library=yes
2849          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2850          if test "$cf_gpp_libname" = cpp ; then
2851             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
2852          else
2853             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
2854          fi],
2855         [AC_TRY_LINK([
2856 #include <builtin.h>
2857         ],
2858         [two_arg_error_handler_t foo2 = lib_error_handler],
2859         [cf_cxx_library=yes
2860          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2861          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
2862         [cf_cxx_library=no])])
2863         LIBS="$cf_save"
2864         AC_MSG_RESULT($cf_cxx_library)
2865 fi
2866 ])dnl
2867 dnl ---------------------------------------------------------------------------
2868 dnl CF_GXX_VERSION version: 8 updated: 2017/02/11 14:48:57
2869 dnl --------------
2870 dnl Check for version of g++
2871 AC_DEFUN([CF_GXX_VERSION],[
2872 AC_REQUIRE([AC_PROG_CPP])
2873 GXX_VERSION=none
2874 if test "$GXX" = yes; then
2875         AC_MSG_CHECKING(version of ${CXX:-g++})
2876         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2877         if test -z "$GXX_VERSION"
2878         then
2879                 GXX_VERSION=unknown
2880                 GXX=no
2881         fi
2882         AC_MSG_RESULT($GXX_VERSION)
2883 fi
2884 ])dnl
2885 dnl ---------------------------------------------------------------------------
2886 dnl CF_GXX_WARNINGS version: 9 updated: 2015/04/17 21:13:04
2887 dnl ---------------
2888 dnl Check if the compiler supports useful warning options.
2889 dnl
2890 dnl Most of gcc's options apply to g++, except:
2891 dnl     -Wbad-function-cast
2892 dnl     -Wmissing-declarations
2893 dnl     -Wnested-externs
2894 dnl
2895 dnl Omit a few (for now):
2896 dnl     -Winline
2897 dnl
2898 dnl Parameter:
2899 dnl     $1 is an optional list of g++ warning flags that a particular
2900 dnl             application might want to use, e.g., "no-unused" for
2901 dnl             -Wno-unused
2902 dnl Special:
2903 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2904 dnl
2905 AC_DEFUN([CF_GXX_WARNINGS],
2906 [
2907
2908 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2909 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
2910
2911 AC_REQUIRE([CF_GXX_VERSION])
2912
2913 AC_LANG_SAVE
2914 AC_LANG_CPLUSPLUS
2915
2916 cat > conftest.$ac_ext <<EOF
2917 #line __oline__ "configure"
2918 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2919 EOF
2920
2921 if test "$INTEL_CPLUSPLUS" = yes
2922 then
2923 # The "-wdXXX" options suppress warnings:
2924 # remark #1419: external declaration in primary source file
2925 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2926 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2927 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2928 # remark #193: zero used for undefined preprocessing identifier
2929 # remark #593: variable "curs_sb_left_arrow" was set but never used
2930 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2931 # remark #869: parameter "tw" was never referenced
2932 # remark #981: operands are evaluated in unspecified order
2933 # warning #269: invalid format string conversion
2934
2935         AC_CHECKING([for $CC warning options])
2936         cf_save_CXXFLAGS="$CXXFLAGS"
2937         EXTRA_CXXFLAGS="-Wall"
2938         for cf_opt in \
2939                 wd1419 \
2940                 wd1682 \
2941                 wd1683 \
2942                 wd1684 \
2943                 wd193 \
2944                 wd279 \
2945                 wd593 \
2946                 wd810 \
2947                 wd869 \
2948                 wd981
2949         do
2950                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2951                 if AC_TRY_EVAL(ac_compile); then
2952                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2953                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2954                 fi
2955         done
2956         CXXFLAGS="$cf_save_CXXFLAGS"
2957
2958 elif test "$GXX" = yes
2959 then
2960         AC_CHECKING([for $CXX warning options])
2961         cf_save_CXXFLAGS="$CXXFLAGS"
2962         EXTRA_CXXFLAGS="-W -Wall"
2963         cf_gxx_extra_warnings=""
2964         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2965         case "$GCC_VERSION" in
2966         ([[1-2]].*)
2967                 ;;
2968         (*)
2969                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2970                 ;;
2971         esac
2972         for cf_opt in \
2973                 Wabi \
2974                 fabi-version=0 \
2975                 Wextra \
2976                 Wignored-qualifiers \
2977                 Wlogical-op \
2978                 Woverloaded-virtual \
2979                 Wsign-promo \
2980                 Wsynth \
2981                 Wold-style-cast \
2982                 Wcast-align \
2983                 Wcast-qual \
2984                 Wpointer-arith \
2985                 Wshadow \
2986                 Wundef $cf_gxx_extra_warnings $1
2987         do
2988                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2989                 if AC_TRY_EVAL(ac_compile); then
2990                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2991                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2992                 else
2993                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2994                 fi
2995         done
2996         CXXFLAGS="$cf_save_CXXFLAGS"
2997 fi
2998
2999 rm -rf conftest*
3000 AC_LANG_RESTORE
3001 AC_SUBST(EXTRA_CXXFLAGS)
3002 ])dnl
3003 dnl ---------------------------------------------------------------------------
3004 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
3005 dnl ------------
3006 dnl Look for an instance of the Berkeley hashed database.
3007 dnl
3008 dnl $1 = optional parameter, to specify install-prefix for the database.
3009 AC_DEFUN([CF_HASHED_DB],
3010 [
3011 ifelse([$1],,,[
3012 case $1 in
3013 (yes|*able*)
3014         ;;
3015 (*)
3016         if test -d "$1" ; then
3017                 CF_ADD_INCDIR($1/include)
3018                 CF_ADD_LIBDIR($1/lib)
3019         else
3020                 case "$1" in
3021                 (./*|../*|/*)
3022                         AC_MSG_WARN(no such directory $1)
3023                         ;;
3024                 (*)
3025                         CF_FIND_SUB_INCDIR($1)
3026                         CF_FIND_SUB_LIBDIR($1)
3027                         ;;
3028                 esac
3029         fi
3030 esac
3031 ])
3032 AC_CHECK_HEADER(db.h,[
3033 CF_HASHED_DB_VERSION
3034 if test "$cf_cv_hashed_db_version" = unknown ; then
3035         AC_MSG_ERROR(Cannot determine version of db)
3036 else
3037         CF_HASHED_DB_LIBS
3038         if test "$cf_cv_hashed_db_libs" = unknown ; then
3039                 AC_MSG_ERROR(Cannot determine library for db)
3040         elif test "$cf_cv_hashed_db_libs" != default ; then
3041                 CF_ADD_LIB($cf_cv_hashed_db_libs)
3042         fi
3043 fi
3044 ],[
3045         AC_MSG_ERROR(Cannot find db.h)
3046 ])
3047 ])dnl
3048 dnl ---------------------------------------------------------------------------
3049 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
3050 dnl -----------------
3051 dnl Given that we have the header and version for hashed database, find the
3052 dnl library information.
3053 AC_DEFUN([CF_HASHED_DB_LIBS],
3054 [
3055 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
3056 cf_cv_hashed_db_libs=unknown
3057 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
3058 do
3059         cf_save_libs="$LIBS"
3060         if test -n "$cf_db_libs"; then
3061                 CF_ADD_LIB($cf_db_libs)
3062         fi
3063         CF_MSG_LOG(checking for library "$cf_db_libs")
3064         AC_TRY_LINK([
3065 $ac_includes_default
3066 #include <db.h>
3067 ],[
3068         char *path = "/tmp/foo";
3069 #ifdef DB_VERSION_MAJOR
3070 #if DB_VERSION_MAJOR >= 4
3071         DB *result = 0;
3072         db_create(&result, NULL, 0);
3073         result->open(result,
3074                 NULL,
3075                 path,
3076                 path,
3077                 DB_HASH,
3078                 DB_CREATE,
3079                 0644);
3080 #elif DB_VERSION_MAJOR >= 3
3081         DB *result = 0;
3082         db_create(&result, NULL, 0);
3083         result->open(result,
3084                 path,
3085                 path,
3086                 DB_HASH,
3087                 DB_CREATE,
3088                 0644);
3089 #elif DB_VERSION_MAJOR >= 2
3090         DB *result = 0;
3091         db_open(path,
3092                 DB_HASH,
3093                 DB_CREATE,
3094                 0644,
3095                 (DB_ENV *) 0,
3096                 (DB_INFO *) 0,
3097                 &result);
3098 #endif /* DB_VERSION_MAJOR */
3099 #else
3100         DB *result = dbopen(path,
3101                      2,
3102                      0644,
3103                      DB_HASH,
3104                      0);
3105 #endif
3106         ${cf_cv_main_return:-return}(result != 0)
3107 ],[
3108         if test -n "$cf_db_libs" ; then
3109                 cf_cv_hashed_db_libs=$cf_db_libs
3110         else
3111                 cf_cv_hashed_db_libs=default
3112         fi
3113         LIBS="$cf_save_libs"
3114         break
3115 ])
3116         LIBS="$cf_save_libs"
3117 done
3118 ])
3119 ])dnl
3120 dnl ---------------------------------------------------------------------------
3121 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
3122 dnl --------------------
3123 dnl Given that we have the header file for hashed database, find the version
3124 dnl information.
3125 AC_DEFUN([CF_HASHED_DB_VERSION],
3126 [
3127 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
3128 cf_cv_hashed_db_version=unknown
3129
3130 for cf_db_version in 1 2 3 4 5 6
3131 do
3132         CF_MSG_LOG(checking for db version $cf_db_version)
3133         AC_TRY_COMPILE([
3134 $ac_includes_default
3135 #include <db.h>
3136
3137 #ifdef DB_VERSION_MAJOR
3138         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
3139 #if $cf_db_version == DB_VERSION_MAJOR
3140         /* ok */
3141 #else
3142         make an error
3143 #endif
3144 #else
3145 #if $cf_db_version == 1
3146         /* ok: assuming this is DB 1.8.5 */
3147 #else
3148         make an error
3149 #endif
3150 #endif
3151 ],[DBT *foo = 0],[
3152         cf_cv_hashed_db_version=$cf_db_version
3153         break
3154         ])
3155 done
3156 ])
3157 ])dnl
3158 dnl ---------------------------------------------------------------------------
3159 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
3160 dnl --------------
3161 dnl Construct a search-list of directories for a nonstandard header-file
3162 dnl
3163 dnl Parameters
3164 dnl     $1 = the variable to return as result
3165 dnl     $2 = the package name
3166 AC_DEFUN([CF_HEADER_PATH],
3167 [
3168 $1=
3169
3170 # collect the current set of include-directories from compiler flags
3171 cf_header_path_list=""
3172 if test -n "${CFLAGS}${CPPFLAGS}" ; then
3173         for cf_header_path in $CPPFLAGS $CFLAGS
3174         do
3175                 case $cf_header_path in
3176                 (-I*)
3177                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
3178                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
3179                         cf_header_path_list="$cf_header_path_list [$]$1"
3180                         ;;
3181                 esac
3182         done
3183 fi
3184
3185 # add the variations for the package we are looking for
3186 CF_SUBDIR_PATH($1,$2,include)
3187
3188 test "$includedir" != NONE && \
3189 test "$includedir" != "/usr/include" && \
3190 test -d "$includedir" && {
3191         test -d $includedir &&    $1="[$]$1 $includedir"
3192         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
3193 }
3194
3195 test "$oldincludedir" != NONE && \
3196 test "$oldincludedir" != "/usr/include" && \
3197 test -d "$oldincludedir" && {
3198         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
3199         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
3200 }
3201
3202 $1="[$]$1 $cf_header_path_list"
3203 ])dnl
3204 dnl ---------------------------------------------------------------------------
3205 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
3206 dnl ---------------
3207 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
3208 AC_DEFUN([CF_HELP_MESSAGE],
3209 [AC_DIVERT_HELP([$1])dnl
3210 ])dnl
3211 dnl ---------------------------------------------------------------------------
3212 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
3213 dnl ---------------
3214 dnl Construct the list of include-options according to whether we're building
3215 dnl in the source directory or using '--srcdir=DIR' option.
3216 AC_DEFUN([CF_INCLUDE_DIRS],
3217 [
3218 if test "$srcdir" != "."; then
3219         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
3220 fi
3221 CPPFLAGS="-I../include $CPPFLAGS"
3222 if test "$srcdir" != "."; then
3223         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
3224 fi
3225 CPPFLAGS="-I. $CPPFLAGS"
3226 AC_SUBST(CPPFLAGS)
3227 ])dnl
3228 dnl ---------------------------------------------------------------------------
3229 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
3230 dnl ---------------
3231 dnl prompt for/fill-in useful install-program options
3232 AC_DEFUN([CF_INSTALL_OPTS],
3233 [
3234 CF_INSTALL_OPT_S
3235 CF_INSTALL_OPT_P
3236 CF_INSTALL_OPT_O
3237 ])dnl
3238 dnl ---------------------------------------------------------------------------
3239 dnl CF_INSTALL_OPT_O version: 2 updated: 2015/05/15 19:45:35
3240 dnl ----------------
3241 dnl Almost all "install" programs default to the current user's ownership.
3242 dnl Almost - MINIX is an exception.
3243 AC_DEFUN([CF_INSTALL_OPT_O],
3244 [
3245 AC_MSG_CHECKING(if install needs to be told about ownership)
3246 case `$ac_config_guess` in
3247 (*minix)
3248         with_install_o=yes
3249         ;;
3250 (*)
3251         with_install_o=no
3252         ;;
3253 esac
3254
3255 AC_MSG_RESULT($with_install_o)
3256 if test "x$with_install_o" = xyes
3257 then
3258         INSTALL_OPT_O=`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`
3259 else
3260         INSTALL_OPT_O=
3261 fi
3262
3263 AC_SUBST(INSTALL_OPT_O)
3264 ])dnl
3265 dnl ---------------------------------------------------------------------------
3266 dnl CF_INSTALL_OPT_P version: 1 updated: 2018/08/18 12:19:21
3267 dnl ----------------
3268 dnl Some install-programs accept a "-p" option to preserve file modification
3269 dnl timestamps.  That can be useful as an install option, as well as a way to
3270 dnl avoid the need for ranlib after copying a static archive.
3271 AC_DEFUN([CF_INSTALL_OPT_P],
3272 [
3273 : ${INSTALL:=install}
3274 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
3275         rm -rf conftest*
3276         date >conftest.in
3277         mkdir conftest.out
3278         sleep 3
3279         if $INSTALL -p conftest.in conftest.out 2>/dev/null
3280         then
3281                 if test -f conftest.out/conftest.in
3282                 then
3283                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
3284                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
3285                         if test -s conftest.err
3286                         then
3287                                 cf_cv_install_p=no
3288                         else
3289                                 cf_cv_install_p=yes
3290                         fi
3291                 else
3292                         cf_cv_install_p=no
3293                 fi
3294         else
3295                 cf_cv_install_p=no
3296         fi
3297         rm -rf conftest*
3298 ])
3299 ])dnl
3300 dnl ---------------------------------------------------------------------------
3301 dnl CF_INSTALL_OPT_S version: 2 updated: 2018/08/18 12:19:21
3302 dnl ----------------
3303 dnl By default, we should strip executables which are installed, but leave the
3304 dnl ability to suppress that for unit-testing.
3305 AC_DEFUN([CF_INSTALL_OPT_S],
3306 [
3307 AC_MSG_CHECKING(if you want to install stripped executables)
3308 CF_ARG_DISABLE(stripping,
3309         [  --disable-stripping     do not strip (debug info) installed executables],
3310         [with_stripping=no],
3311         [with_stripping=yes])
3312 AC_MSG_RESULT($with_stripping)
3313
3314 if test "$with_stripping" = yes
3315 then
3316         INSTALL_OPT_S="-s"
3317 else
3318         INSTALL_OPT_S=
3319 fi
3320 AC_SUBST(INSTALL_OPT_S)
3321 ])dnl
3322 dnl ---------------------------------------------------------------------------
3323 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
3324 dnl -----------------
3325 dnl Check if the given compiler is really the Intel compiler for Linux.  It
3326 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
3327 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
3328 dnl
3329 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
3330 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
3331 dnl the wrappers for gcc and g++ warnings.
3332 dnl
3333 dnl $1 = GCC (default) or GXX
3334 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
3335 dnl $3 = CFLAGS (default) or CXXFLAGS
3336 AC_DEFUN([CF_INTEL_COMPILER],[
3337 AC_REQUIRE([AC_CANONICAL_HOST])
3338 ifelse([$2],,INTEL_COMPILER,[$2])=no
3339
3340 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
3341         case $host_os in
3342         (linux*|gnu*)
3343                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
3344                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
3345                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
3346                 AC_TRY_COMPILE([],[
3347 #ifdef __INTEL_COMPILER
3348 #else
3349 make an error
3350 #endif
3351 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
3352 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
3353 ],[])
3354                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
3355                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
3356                 ;;
3357         esac
3358 fi
3359 ])dnl
3360 dnl ---------------------------------------------------------------------------
3361 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
3362 dnl ----------
3363 dnl Check if we have either a function or macro for 'isascii()'.
3364 AC_DEFUN([CF_ISASCII],
3365 [
3366 AC_MSG_CHECKING(for isascii)
3367 AC_CACHE_VAL(cf_cv_have_isascii,[
3368         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
3369         [cf_cv_have_isascii=yes],
3370         [cf_cv_have_isascii=no])
3371 ])dnl
3372 AC_MSG_RESULT($cf_cv_have_isascii)
3373 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
3374 ])dnl
3375 dnl ---------------------------------------------------------------------------
3376 dnl CF_LARGEFILE version: 11 updated: 2018/06/20 20:23:13
3377 dnl ------------
3378 dnl Add checks for large file support.
3379 AC_DEFUN([CF_LARGEFILE],[
3380 ifdef([AC_FUNC_FSEEKO],[
3381         AC_SYS_LARGEFILE
3382         if test "$enable_largefile" != no ; then
3383         AC_FUNC_FSEEKO
3384
3385         # Normally we would collect these definitions in the config.h,
3386         # but (like _XOPEN_SOURCE), some environments rely on having these
3387         # defined before any of the system headers are included.  Another
3388         # case comes up with C++, e.g., on AIX the compiler compiles the
3389         # header files by themselves before looking at the body files it is
3390         # told to compile.  For ncurses, those header files do not include
3391         # the config.h
3392         if test "$ac_cv_sys_large_files" != no
3393         then
3394                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
3395         fi
3396         if test "$ac_cv_sys_largefile_source" != no
3397         then
3398                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
3399         fi
3400         if test "$ac_cv_sys_file_offset_bits" != no
3401         then
3402                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
3403         fi
3404
3405         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
3406                 AC_TRY_COMPILE([
3407 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
3408 #include <sys/types.h>
3409 #include <dirent.h>
3410                 ],[
3411                 /* if transitional largefile support is setup, this is true */
3412                 extern struct dirent64 * readdir(DIR *);
3413                 struct dirent64 *x = readdir((DIR *)0);
3414                 struct dirent *y = readdir((DIR *)0);
3415                 int z = x - y;
3416                 ],
3417                 [cf_cv_struct_dirent64=yes],
3418                 [cf_cv_struct_dirent64=no])
3419         ])
3420         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
3421         fi
3422 ])
3423 ])
3424 dnl ---------------------------------------------------------------------------
3425 dnl CF_LDFLAGS_STATIC version: 12 updated: 2015/04/18 08:56:57
3426 dnl -----------------
3427 dnl Check for compiler/linker flags used to temporarily force usage of static
3428 dnl libraries.  This depends on the compiler and platform.  Use this to help
3429 dnl ensure that the linker picks up a given library based on its position in
3430 dnl the list of linker options and libraries.
3431 AC_DEFUN([CF_LDFLAGS_STATIC],[
3432
3433 if test "$GCC" = yes ; then
3434         case $cf_cv_system_name in
3435         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
3436                 LDFLAGS_STATIC=
3437                 LDFLAGS_SHARED=
3438                 ;;
3439         (*)     # normally, except when broken
3440                 LDFLAGS_STATIC=-static
3441                 LDFLAGS_SHARED=-dynamic
3442                 ;;
3443         esac
3444 else
3445         case $cf_cv_system_name in
3446         (aix[[4-7]]*)   # from ld manpage
3447                 LDFLAGS_STATIC=-bstatic
3448                 LDFLAGS_SHARED=-bdynamic
3449                 ;;
3450         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
3451                 # We could also use just "archive" and "shared".
3452                 LDFLAGS_STATIC=-Wl,-a,archive_shared
3453                 LDFLAGS_SHARED=-Wl,-a,shared_archive
3454                 ;;
3455         (irix*)         # from ld manpage IRIX64
3456                 LDFLAGS_STATIC=-Bstatic
3457                 LDFLAGS_SHARED=-Bdynamic
3458                 ;;
3459         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
3460                 # alternative "-oldstyle_liblookup" (not in cc manpage)
3461                 LDFLAGS_STATIC=-noso
3462                 LDFLAGS_SHARED=-so_archive
3463                 ;;
3464         (solaris2*)
3465                 LDFLAGS_STATIC=-Bstatic
3466                 LDFLAGS_SHARED=-Bdynamic
3467                 ;;
3468         esac
3469 fi
3470
3471 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
3472 then
3473         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
3474
3475         rm -f libconftest.a
3476         cat >conftest.$ac_ext <<EOF
3477 #line __oline__ "configure"
3478 #include <stdio.h>
3479 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
3480 EOF
3481         if AC_TRY_EVAL(ac_compile) ; then
3482                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
3483                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
3484         fi
3485         rm -f conftest.*
3486
3487         cf_save_LIBS="$LIBS"
3488
3489         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
3490         AC_TRY_LINK([
3491 #line __oline__ "configure"
3492 #include <stdio.h>
3493 int cf_ldflags_static(FILE *fp);
3494 ],[
3495         return cf_ldflags_static(stdin);
3496 ],[
3497         # some linkers simply ignore the -dynamic
3498         case x`file conftest$ac_exeext 2>/dev/null` in
3499         (*static*)
3500                 cf_ldflags_static=no
3501                 ;;
3502         (*)
3503                 cf_ldflags_static=yes
3504                 ;;
3505         esac
3506 ],[cf_ldflags_static=no])
3507
3508         rm -f libconftest.*
3509         LIBS="$cf_save_LIBS"
3510
3511         AC_MSG_RESULT($cf_ldflags_static)
3512
3513         if test $cf_ldflags_static != yes
3514         then
3515                 LDFLAGS_STATIC=
3516                 LDFLAGS_SHARED=
3517         fi
3518 else
3519         LDFLAGS_STATIC=
3520         LDFLAGS_SHARED=
3521 fi
3522
3523 AC_SUBST(LDFLAGS_STATIC)
3524 AC_SUBST(LDFLAGS_SHARED)
3525 ])
3526 dnl ---------------------------------------------------------------------------
3527 dnl CF_LD_RPATH_OPT version: 7 updated: 2016/02/20 18:01:19
3528 dnl ---------------
3529 dnl For the given system and compiler, find the compiler flags to pass to the
3530 dnl loader to use the "rpath" feature.
3531 AC_DEFUN([CF_LD_RPATH_OPT],
3532 [
3533 AC_REQUIRE([CF_CHECK_CACHE])
3534
3535 LD_RPATH_OPT=
3536 if test "x$cf_cv_enable_rpath" != xno
3537 then
3538         AC_MSG_CHECKING(for an rpath option)
3539         case $cf_cv_system_name in
3540         (irix*)
3541                 if test "$GCC" = yes; then
3542                         LD_RPATH_OPT="-Wl,-rpath,"
3543                 else
3544                         LD_RPATH_OPT="-rpath "
3545                 fi
3546                 ;;
3547         (linux*|gnu*|k*bsd*-gnu|freebsd*)
3548                 LD_RPATH_OPT="-Wl,-rpath,"
3549                 ;;
3550         (openbsd[[2-9]].*|mirbsd*)
3551                 LD_RPATH_OPT="-Wl,-rpath,"
3552                 ;;
3553         (dragonfly*)
3554                 LD_RPATH_OPT="-rpath "
3555                 ;;
3556         (netbsd*)
3557                 LD_RPATH_OPT="-Wl,-rpath,"
3558                 ;;
3559         (osf*|mls+*)
3560                 LD_RPATH_OPT="-rpath "
3561                 ;;
3562         (solaris2*)
3563                 LD_RPATH_OPT="-R"
3564                 ;;
3565         (*)
3566                 ;;
3567         esac
3568         AC_MSG_RESULT($LD_RPATH_OPT)
3569
3570         case "x$LD_RPATH_OPT" in
3571         (x-R*)
3572                 AC_MSG_CHECKING(if we need a space after rpath option)
3573                 cf_save_LIBS="$LIBS"
3574                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3575                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3576                 LIBS="$cf_save_LIBS"
3577                 AC_MSG_RESULT($cf_rpath_space)
3578                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3579                 ;;
3580         esac
3581 fi
3582 ])dnl
3583 dnl ---------------------------------------------------------------------------
3584 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
3585 dnl ---------------
3586 dnl Construct a search-list of directories for a nonstandard library-file
3587 dnl
3588 dnl Parameters
3589 dnl     $1 = the variable to return as result
3590 dnl     $2 = the package name
3591 AC_DEFUN([CF_LIBRARY_PATH],
3592 [
3593 $1=
3594 cf_library_path_list=""
3595 if test -n "${LDFLAGS}${LIBS}" ; then
3596         for cf_library_path in $LDFLAGS $LIBS
3597         do
3598                 case $cf_library_path in
3599                 (-L*)
3600                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3601                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3602                         cf_library_path_list="$cf_library_path_list [$]$1"
3603                         ;;
3604                 esac
3605         done
3606 fi
3607
3608 CF_SUBDIR_PATH($1,$2,lib)
3609
3610 $1="$cf_library_path_list [$]$1"
3611 ])dnl
3612 dnl ---------------------------------------------------------------------------
3613 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
3614 dnl ------------------
3615 AC_DEFUN([CF_LIBTOOL_VERSION],[
3616 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
3617 then
3618         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
3619 else
3620         cf_cv_libtool_version=
3621 fi
3622 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
3623 ])dnl
3624 dnl ---------------------------------------------------------------------------
3625 dnl CF_LIB_PREFIX version: 12 updated: 2015/10/17 19:03:33
3626 dnl -------------
3627 dnl Compute the library-prefix for the given host system
3628 dnl $1 = variable to set
3629 define([CF_LIB_PREFIX],
3630 [
3631         case $cf_cv_system_name in
3632         (OS/2*|os2*)
3633                 if test "$DFT_LWR_MODEL" = libtool; then
3634                         LIB_PREFIX='lib'
3635                 else
3636                         LIB_PREFIX=''
3637                 fi
3638                 ;;
3639         (*)     LIB_PREFIX='lib'
3640                 ;;
3641         esac
3642 ifelse($1,,,[$1=$LIB_PREFIX])
3643         AC_SUBST(LIB_PREFIX)
3644 ])dnl
3645 dnl ---------------------------------------------------------------------------
3646 dnl CF_LIB_RULES version: 88 updated: 2018/08/18 12:19:21
3647 dnl ------------
3648 dnl Append definitions and rules for the given models to the subdirectory
3649 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3650 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
3651 dnl the corresponding makefile to list the models that we'll generate.
3652 dnl
3653 dnl For shared libraries, make a list of symbolic links to construct when
3654 dnl generating each library.  The convention used for Linux is the simplest
3655 dnl one:
3656 dnl     lib<name>.so    ->
3657 dnl     lib<name>.so.<major>    ->
3658 dnl     lib<name>.so.<maj>.<minor>
3659 dnl
3660 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
3661 AC_DEFUN([CF_LIB_RULES],
3662 [
3663 cf_prefix=$LIB_PREFIX
3664 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3665
3666 case $cf_cv_shlib_version in
3667 (cygdll|msysdll|mingw)
3668         TINFO_NAME=$TINFO_ARG_SUFFIX
3669         TINFO_SUFFIX=.dll
3670         ;;
3671 esac
3672
3673 if test -n "$TINFO_SUFFIX" ; then
3674         case $TINFO_SUFFIX in
3675         (tw*)
3676                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
3677                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw'$EXTRA_SUFFIX'//'`
3678                 ;;
3679         (t*)
3680                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
3681                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t'$EXTRA_SUFFIX'//'`
3682                 ;;
3683         (w*)
3684                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
3685                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w'$EXTRA_SUFFIX'//'`
3686                 ;;
3687         esac
3688 fi
3689
3690 for cf_dir in $SRC_SUBDIRS
3691 do
3692         if test ! -d $srcdir/$cf_dir ; then
3693                 continue
3694         elif test -f $srcdir/$cf_dir/modules; then
3695
3696                 SHARED_LIB=
3697                 Libs_To_Make=
3698                 cf_awk_program=
3699                 if test -n "${cf_cv_abi_version}" && test "x${cf_cv_abi_version}" != "x5"
3700                 then
3701                         cf_awk_program="$cf_awk_program\
3702 /deprecated in ABI${cf_cv_abi_version}/ { next; }\
3703 { sub(\"NCURSES([[WT]]+)?\", \"&${cf_cv_abi_version}\"); }\
3704 "
3705                 fi
3706
3707                 if test "x$WILDCARD_SYMS" = xno
3708                 then
3709                         cf_awk_program="$cf_awk_program\
3710 /[[     ]]_\\*;/ { skip=1; next; }\
3711 "
3712                 fi
3713
3714                 if test "x$cf_awk_program" != "x"
3715                 then
3716                         cat >>$cf_dir/Makefile <<CF_EOF
3717
3718 # Generated by CF_LIB_RULES
3719 resulting.map: $UNALTERED_SYMS
3720         $AWK 'BEGIN { skip = 1; last=""; } \
3721 $cf_awk_program \
3722 { if ( last != "" && ( skip == 0 || \[$]\[$]0 !~ /}/ ) ) { print last; }\
3723  skip = 0; last = \[$]\[$]0; } \
3724 END { print last; }' < $UNALTERED_SYMS >\[$]@
3725
3726 distclean::
3727         rm -f resulting.map
3728 CF_EOF
3729                 fi
3730
3731                 for cf_item in $cf_LIST_MODELS
3732                 do
3733                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3734                         cf_libname=$cf_dir
3735                         test "$cf_dir" = c++ && cf_libname=ncurses++
3736                         if test $cf_item = shared ; then
3737                                 if test -n "${LIB_SUFFIX}"
3738                                 then
3739                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3740                                 else
3741                                         cf_shared_suffix="$cf_suffix"
3742                                 fi
3743                                 if test "$cf_cv_do_symlinks" = yes ; then
3744                                         cf_version_name=
3745
3746                                         case "$cf_cv_shlib_version" in
3747                                         (rel)
3748                                                 cf_version_name=REL_VERSION
3749                                                 ;;
3750                                         (abi)
3751                                                 cf_version_name=ABI_VERSION
3752                                                 ;;
3753                                         esac
3754
3755                                         if test -n "$cf_version_name"
3756                                         then
3757                                                 case "$cf_cv_system_name" in
3758                                                 (darwin*)
3759                                                         # "w", etc?
3760                                                         cf_suffix="${USE_LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
3761                                                         ;;
3762                                                 (*)
3763                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
3764                                                         ;;
3765                                                 esac
3766                                         fi
3767                                         if test -n "${USE_LIB_SUFFIX}"
3768                                         then
3769                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3770                                         else
3771                                                 cf_shared_suffix="$cf_suffix"
3772                                         fi
3773                                 fi
3774                                 # cygwin needs import library, and has unique naming convention
3775                                 # use autodetected ${cf_prefix} for import lib and static lib, but
3776                                 # use 'cyg' prefix for shared lib.
3777                                 case $cf_cv_shlib_version in
3778                                 (cygdll)
3779                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3780                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
3781                                         ;;
3782                                 (msysdll)
3783                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3784                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
3785                                         ;;
3786                                 (mingw)
3787                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3788                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
3789                                         ;;
3790                                 (*)
3791                                         cf_add_lib=
3792                                         ;;
3793                                 esac
3794                                 if test -n "$cf_add_lib"
3795                                 then
3796                                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3797                                         continue
3798                                 fi
3799                         fi
3800                         cf_add_lib="../lib/${cf_prefix}${cf_libname}${cf_suffix}"
3801                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3802                 done
3803
3804                 if test $cf_dir = ncurses ; then
3805                         cf_subsets="$LIB_SUBSETS"
3806                         cf_r_parts="$cf_subsets"
3807                         cf_liblist="$Libs_To_Make"
3808
3809                         while test -n "$cf_r_parts"
3810                         do
3811                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3812                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3813                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3814                                         cf_add_lib=
3815                                         case $cf_l_parts in
3816                                         (*termlib*)
3817                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3818                                                 ;;
3819                                         (*ticlib*)
3820                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3821                                                 ;;
3822                                         (*)
3823                                                 break
3824                                                 ;;
3825                                         esac
3826                                         if test -n "$cf_add_lib"; then
3827                                                 Libs_To_Make="$cf_add_lib $Libs_To_Make"
3828                                         fi
3829                                 else
3830                                         break
3831                                 fi
3832                         done
3833                 else
3834                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3835                 fi
3836
3837                 if test $cf_dir = c++; then
3838                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
3839                                 cf_list=
3840                                 for cf_item in $Libs_To_Make
3841                                 do
3842                                         case $cf_item in
3843                                         (*.a)
3844                                                 ;;
3845                                         (*)
3846                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
3847                                                 ;;
3848                                         esac
3849                                         for cf_test in $cf_list
3850                                         do
3851                                                 if test "$cf_test" = "$cf_item"
3852                                                 then
3853                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
3854                                                         cf_item=
3855                                                         break
3856                                                 fi
3857                                         done
3858                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
3859                                 done
3860                                 Libs_To_Make="$cf_list"
3861                         fi
3862                 fi
3863
3864                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
3865                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3866                         $cf_dir/Makefile >$cf_dir/Makefile.out
3867                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3868
3869                 $AWK -f $srcdir/mk-0th.awk \
3870                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
3871                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3872
3873                 for cf_subset in $cf_subsets
3874                 do
3875                         cf_subdirs=
3876                         for cf_item in $cf_LIST_MODELS
3877                         do
3878
3879                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3880                         CF_UPPER(cf_ITEM,$cf_item)
3881
3882                         CXX_MODEL=$cf_ITEM
3883                         if test "$CXX_MODEL" = SHARED; then
3884                                 case $cf_cv_shlib_version in
3885                                 (cygdll|msysdll|mingw)
3886                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
3887                                         with_shared_cxx=yes
3888                                         ;;
3889                                 (*)
3890                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
3891                                         ;;
3892                                 esac
3893                         fi
3894
3895                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3896                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3897
3898                         # Test for case where we build libtinfo with a different name.
3899                         cf_libname=$cf_dir
3900                         if test $cf_dir = ncurses ; then
3901                                 case $cf_subset in
3902                                 (*base*)
3903                                         cf_libname=${cf_libname}$USE_LIB_SUFFIX
3904                                         ;;
3905                                 (*termlib*)
3906                                         cf_libname=$TINFO_LIB_SUFFIX
3907                                         ;;
3908                                 (ticlib*)
3909                                         cf_libname=$TICS_LIB_SUFFIX
3910                                         ;;
3911                                 esac
3912                         elif test $cf_dir = c++ ; then
3913                                 cf_libname=ncurses++$USE_LIB_SUFFIX
3914                         else
3915                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
3916                         fi
3917                         if test -n "${USE_ARG_SUFFIX}" ; then
3918                                 # undo $USE_LIB_SUFFIX add-on in CF_LIB_SUFFIX
3919                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${USE_LIB_SUFFIX}%%"`
3920                         fi
3921
3922                         # These dependencies really are for development, not
3923                         # builds, but they are useful in porting, too.
3924                         cf_depend="../include/ncurses_cfg.h"
3925                         if test "$srcdir" = "."; then
3926                                 cf_reldir="."
3927                         else
3928                                 cf_reldir="\${srcdir}"
3929                         fi
3930
3931                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3932                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3933                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3934                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3935                         fi
3936
3937                         cf_dir_suffix=
3938                         old_cf_suffix="$cf_suffix"
3939                         if test "$cf_cv_shlib_version_infix" = yes ; then
3940                         if test -n "$USE_LIB_SUFFIX" ; then
3941                                 case $USE_LIB_SUFFIX in
3942                                 (tw*)
3943                                         cf_libname=`echo $cf_libname | sed 's/tw'$EXTRA_SUFFIX'$//'`
3944                                         cf_suffix=`echo $cf_suffix | sed 's/^tw'$EXTRA_SUFFIX'//'`
3945                                         cf_dir_suffix=tw$EXTRA_SUFFIX
3946                                         ;;
3947                                 (t*)
3948                                         cf_libname=`echo $cf_libname | sed 's/t'$EXTRA_SUFFIX'$//'`
3949                                         cf_suffix=`echo $cf_suffix | sed 's/^t'$EXTRA_SUFFIX'//'`
3950                                         cf_dir_suffix=t$EXTRA_SUFFIX
3951                                         ;;
3952                                 (w*)
3953                                         cf_libname=`echo $cf_libname | sed 's/w'$EXTRA_SUFFIX'$//'`
3954                                         cf_suffix=`echo $cf_suffix | sed 's/^w'$EXTRA_SUFFIX'//'`
3955                                         cf_dir_suffix=w$EXTRA_SUFFIX
3956                                         ;;
3957                                 (*)
3958                                         cf_libname=`echo $cf_libname | sed 's/'$EXTRA_SUFFIX'$//'`
3959                                         cf_suffix=`echo $cf_suffix | sed 's/^'$EXTRA_SUFFIX'//'`
3960                                         cf_dir_suffix=$EXTRA_SUFFIX
3961                                         ;;
3962                                 esac
3963                         fi
3964                         fi
3965
3966                         $AWK -f $srcdir/mk-1st.awk \
3967                                 name=${cf_libname}${cf_dir_suffix} \
3968                                 traces=$LIB_TRACING \
3969                                 MODEL=$cf_ITEM \
3970                                 CXX_MODEL=$CXX_MODEL \
3971                                 model=$cf_subdir \
3972                                 prefix=$cf_prefix \
3973                                 suffix=$cf_suffix \
3974                                 subset=$cf_subset \
3975                                 driver=$cf_cv_term_driver \
3976                                 SymLink="$LN_S" \
3977                                 TermlibRoot=$TINFO_NAME \
3978                                 TermlibSuffix=$TINFO_SUFFIX \
3979                                 ShlibVer=$cf_cv_shlib_version \
3980                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3981                                 ReLink=${cf_cv_do_relink:-no} \
3982                                 ReRanlib=${cf_cv_do_reranlib:-yes} \
3983                                 DoLinks=$cf_cv_do_symlinks \
3984                                 rmSoLocs=$cf_cv_rm_so_locs \
3985                                 ldconfig="$LDCONFIG" \
3986                                 overwrite=$WITH_OVERWRITE \
3987                                 depend="$cf_depend" \
3988                                 host="$host" \
3989                                 libtool_version="$LIBTOOL_VERSION" \
3990                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3991
3992                         cf_suffix="$old_cf_suffix"
3993
3994                         for cf_subdir2 in $cf_subdirs lib
3995                         do
3996                                 test $cf_subdir = $cf_subdir2 && break
3997                         done
3998                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3999                         $AWK -f $srcdir/mk-2nd.awk \
4000                                 name=$cf_dir \
4001                                 traces=$LIB_TRACING \
4002                                 MODEL=$cf_ITEM \
4003                                 model=$cf_subdir \
4004                                 subset=$cf_subset \
4005                                 srcdir=$srcdir \
4006                                 echo=$WITH_ECHO \
4007                                 crenames=$cf_cv_prog_CC_c_o \
4008                                 cxxrenames=$cf_cv_prog_CXX_c_o \
4009                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
4010                         cf_subdirs="$cf_subdirs $cf_subdir"
4011                         done
4012                 done
4013         fi
4014
4015         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
4016 done
4017
4018 for cf_dir in $SRC_SUBDIRS
4019 do
4020         if test ! -d $srcdir/$cf_dir ; then
4021                 continue
4022         fi
4023
4024         if test -f $cf_dir/Makefile ; then
4025                 case "$cf_dir" in
4026                 (Ada95)
4027                         echo 'libs \' >> Makefile
4028                         echo 'install.libs \' >> Makefile
4029                         echo 'uninstall.libs ::' >> Makefile
4030                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
4031                         ;;
4032                 esac
4033         fi
4034
4035         if test -f $srcdir/$cf_dir/modules; then
4036                 echo >> Makefile
4037                 if test -f $srcdir/$cf_dir/headers; then
4038 cat >> Makefile <<CF_EOF
4039 install.includes \\
4040 uninstall.includes \\
4041 CF_EOF
4042                 fi
4043 if test "$cf_dir" != "c++" ; then
4044 echo 'lint \' >> Makefile
4045 fi
4046 cat >> Makefile <<CF_EOF
4047 libs \\
4048 lintlib \\
4049 install.libs \\
4050 uninstall.libs \\
4051 install.$cf_dir \\
4052 uninstall.$cf_dir ::
4053         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
4054 CF_EOF
4055         elif test -f $srcdir/$cf_dir/headers; then
4056 cat >> Makefile <<CF_EOF
4057
4058 libs \\
4059 install.libs \\
4060 uninstall.libs \\
4061 install.includes \\
4062 uninstall.includes ::
4063         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
4064 CF_EOF
4065 fi
4066 done
4067
4068 if test "x$cf_with_db_install" = xyes; then
4069 cat >> Makefile <<CF_EOF
4070
4071 install.libs uninstall.libs \\
4072 install.data uninstall.data ::
4073 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
4074 CF_EOF
4075 else
4076 cat >> Makefile <<CF_EOF
4077
4078 install.libs uninstall.libs ::
4079         cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
4080 CF_EOF
4081 fi
4082
4083 if test "x$cf_with_manpages" = xyes; then
4084 cat >> Makefile <<CF_EOF
4085
4086 install.man \\
4087 uninstall.man ::
4088         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
4089 CF_EOF
4090 fi
4091
4092 cat >> Makefile <<CF_EOF
4093
4094 distclean ::
4095         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
4096         rm -f headers.sh headers.sed mk_shared_lib.sh
4097         rm -f edit_man.* man_alias.*
4098         rm -rf \${DIRS_TO_MAKE}
4099 CF_EOF
4100
4101 # Special case: tack's manpage lives in its own directory.
4102 if test "x$cf_with_manpages" = xyes; then
4103 if test "x$cf_with_tack" = "xyes"; then
4104 cat >> Makefile <<CF_EOF
4105
4106 install.man \\
4107 uninstall.man ::
4108         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
4109 CF_EOF
4110 fi
4111 fi
4112
4113 dnl If we're installing into a subdirectory of /usr/include, etc., we should
4114 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
4115 dnl anything, and will make it more standardized.  It's awkward to decide this
4116 dnl at configuration because of quoting, so we'll simply make all headers
4117 dnl installed via a script that can do the right thing.
4118
4119 rm -f headers.sed headers.sh
4120
4121 dnl ( generating this script makes the makefiles a little tidier :-)
4122 echo creating headers.sh
4123 cat >headers.sh <<CF_EOF
4124 #! $SHELL
4125 # This shell script is generated by the 'configure' script.  It is invoked in a
4126 # subdirectory of the build tree.  It generates a sed-script in the parent
4127 # directory that is used to adjust includes for header files that reside in a
4128 # subdirectory of /usr/include, etc.
4129 PRG=""
4130 while test \[$]# != 3
4131 do
4132 PRG="\$PRG \[$]1"; shift
4133 done
4134 DST=\[$]1
4135 REF=\[$]2
4136 SRC=\[$]3
4137 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
4138 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
4139 echo installing \$SRC in \$DST
4140 CF_EOF
4141
4142 if test $WITH_CURSES_H = yes; then
4143         cat >>headers.sh <<CF_EOF
4144 case \$DST in
4145 (/*/include/*)
4146         END=\`basename \$DST\`
4147         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
4148         do
4149                 NAME=\`basename \$i\`
4150                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
4151         done
4152         ;;
4153 (*)
4154         echo "" >> \$TMPSED
4155         ;;
4156 esac
4157 CF_EOF
4158
4159 else
4160         cat >>headers.sh <<CF_EOF
4161 case \$DST in
4162 (/*/include/*)
4163         END=\`basename \$DST\`
4164         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
4165         do
4166                 NAME=\`basename \$i\`
4167                 if test "\$NAME" = "curses.h"
4168                 then
4169                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
4170                         NAME=ncurses.h
4171                 fi
4172                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
4173         done
4174         ;;
4175 (*)
4176         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
4177         ;;
4178 esac
4179 CF_EOF
4180 fi
4181 cat >>headers.sh <<CF_EOF
4182 rm -f \$TMPSRC
4183 sed -f \$TMPSED \$SRC > \$TMPSRC
4184 NAME=\`basename \$SRC\`
4185 CF_EOF
4186 if test $WITH_CURSES_H != yes; then
4187         cat >>headers.sh <<CF_EOF
4188 test "\$NAME" = "curses.h" && NAME=ncurses.h
4189 CF_EOF
4190 fi
4191 cat >>headers.sh <<CF_EOF
4192 # Just in case someone gzip'd manpages, remove the conflicting copy.
4193 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
4194
4195 eval \$PRG \$TMPSRC \$DST/\$NAME
4196 rm -f \$TMPSRC \$TMPSED
4197 CF_EOF
4198
4199 chmod 0755 headers.sh
4200
4201 for cf_dir in $SRC_SUBDIRS
4202 do
4203         if test ! -d $srcdir/$cf_dir ; then
4204                 continue
4205         fi
4206
4207         if test -f $srcdir/$cf_dir/headers; then
4208                 $AWK -f $srcdir/mk-hdr.awk \
4209                         subset="$LIB_SUBSETS" \
4210                         compat="$WITH_CURSES_H" \
4211                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
4212         fi
4213
4214         if test -f $srcdir/$cf_dir/modules; then
4215                 if test "$cf_dir" != "c++" ; then
4216                         cat >>$cf_dir/Makefile <<"CF_EOF"
4217 depend : ${AUTO_SRC}
4218         makedepend -- ${CPPFLAGS} -- ${C_SRC}
4219
4220 # DO NOT DELETE THIS LINE -- make depend depends on it.
4221 CF_EOF
4222                 fi
4223         fi
4224 done
4225 AC_SUBST(Libs_To_Make)
4226 ])dnl
4227 dnl ---------------------------------------------------------------------------
4228 dnl CF_LIB_SONAME version: 6 updated: 2017/01/21 11:06:25
4229 dnl -------------
4230 dnl Find the and soname for the given shared library.  Set the cache variable
4231 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
4232 dnl variable to "unknown".
4233 dnl
4234 dnl $1 = headers
4235 dnl $2 = code
4236 dnl $3 = library name
4237 AC_DEFUN([CF_LIB_SONAME],
4238 [
4239 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
4240
4241 cf_cv_$3_soname=unknown
4242 if test "$cross_compiling" != yes ; then
4243 cat >conftest.$ac_ext <<CF_EOF
4244 $1
4245 int main(void)
4246 {
4247 $2
4248         ${cf_cv_main_return:-return}(0);
4249 }
4250 CF_EOF
4251 cf_save_LIBS="$LIBS"
4252         CF_ADD_LIB($3)
4253         if AC_TRY_EVAL(ac_compile) ; then
4254                 if AC_TRY_EVAL(ac_link) ; then
4255                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
4256                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
4257                 fi
4258         fi
4259 rm -rf conftest*
4260 LIBS="$cf_save_LIBS"
4261 fi
4262 ])
4263 ])
4264 dnl ---------------------------------------------------------------------------
4265 dnl CF_LIB_SUFFIX version: 25 updated: 2015/04/17 21:13:04
4266 dnl -------------
4267 dnl Compute the library file-suffix from the given model name
4268 dnl $1 = model name
4269 dnl $2 = variable to set (the nominal library suffix)
4270 dnl $3 = dependency variable to set (actual filename)
4271 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4272 AC_DEFUN([CF_LIB_SUFFIX],
4273 [
4274         case X$1 in
4275         (Xlibtool)
4276                 $2='.la'
4277                 $3=[$]$2
4278                 ;;
4279         (Xdebug)
4280                 $2='_g.a'
4281                 $3=[$]$2
4282                 ;;
4283         (Xprofile)
4284                 $2='_p.a'
4285                 $3=[$]$2
4286                 ;;
4287         (Xshared)
4288                 case $cf_cv_system_name in
4289                 (aix[[5-7]]*)
4290                         $2='.so'
4291                         $3=[$]$2
4292                         ;;
4293                 (cygwin*|msys*|mingw*)
4294                         $2='.dll'
4295                         $3='.dll.a'
4296                         ;;
4297                 (darwin*)
4298                         $2='.dylib'
4299                         $3=[$]$2
4300                         ;;
4301                 (hpux*)
4302                         case $target in
4303                         (ia64*)
4304                                 $2='.so'
4305                                 $3=[$]$2
4306                                 ;;
4307                         (*)
4308                                 $2='.sl'
4309                                 $3=[$]$2
4310                                 ;;
4311                         esac
4312                         ;;
4313                 (*)
4314                         $2='.so'
4315                         $3=[$]$2
4316                         ;;
4317                 esac
4318                 ;;
4319         (*)
4320                 $2='.a'
4321                 $3=[$]$2
4322                 ;;
4323         esac
4324         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
4325         then
4326                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
4327                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
4328         fi
4329 ])dnl
4330 dnl ---------------------------------------------------------------------------
4331 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
4332 dnl -----------
4333 dnl Compute the string to append to -library from the given model name
4334 dnl $1 = model name
4335 dnl $2 = variable to set
4336 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4337 AC_DEFUN([CF_LIB_TYPE],
4338 [
4339         case $1 in
4340         (libtool) $2=''   ;;
4341         (normal)  $2=''   ;;
4342         (debug)   $2='_g' ;;
4343         (profile) $2='_p' ;;
4344         (shared)  $2=''   ;;
4345         esac
4346         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
4347 ])dnl
4348 dnl ---------------------------------------------------------------------------
4349 dnl CF_LINK_DATAONLY version: 12 updated: 2017/07/23 17:46:07
4350 dnl ----------------
4351 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
4352 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
4353 dnl have to provide wrappers for global tables to ensure they're linked
4354 dnl properly.
4355 AC_DEFUN([CF_LINK_DATAONLY],
4356 [
4357 AC_MSG_CHECKING([if data-only library module links])
4358 AC_CACHE_VAL(cf_cv_link_dataonly,[
4359         rm -f conftest.a
4360         cat >conftest.$ac_ext <<EOF
4361 #line __oline__ "configure"
4362 int     testdata[[3]] = { 123, 456, 789 };
4363 EOF
4364         if AC_TRY_EVAL(ac_compile) ; then
4365                 mv conftest.o data.o && \
4366                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
4367         fi
4368         rm -f conftest.$ac_ext data.o
4369         cat >conftest.$ac_ext <<EOF
4370 #line __oline__ "configure"
4371 int     testfunc(void)
4372 {
4373 #if defined(NeXT)
4374         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
4375 #else
4376         extern int testdata[[3]];
4377         return testdata[[0]] == 123
4378            &&  testdata[[1]] == 456
4379            &&  testdata[[2]] == 789;
4380 #endif
4381 }
4382 EOF
4383         if AC_TRY_EVAL(ac_compile); then
4384                 mv conftest.o func.o && \
4385                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
4386         fi
4387         rm -f conftest.$ac_ext func.o
4388         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
4389         cf_saveLIBS="$LIBS"
4390         LIBS="conftest.a $LIBS"
4391         AC_TRY_RUN([
4392         int main(void)
4393         {
4394                 extern int testfunc();
4395                 ${cf_cv_main_return:-return} (!testfunc());
4396         }
4397         ],
4398         [cf_cv_link_dataonly=yes],
4399         [cf_cv_link_dataonly=no],
4400         [cf_cv_link_dataonly=unknown])
4401         LIBS="$cf_saveLIBS"
4402         ])
4403 AC_MSG_RESULT($cf_cv_link_dataonly)
4404
4405 if test "$cf_cv_link_dataonly" = no ; then
4406         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
4407         BROKEN_LINKER=1
4408 fi
4409
4410 ])dnl
4411 dnl ---------------------------------------------------------------------------
4412 dnl CF_LINK_FUNCS version: 9 updated: 2017/01/21 11:11:02
4413 dnl -------------
4414 dnl Most Unix systems have both link and symlink, a few don't have symlink.
4415 dnl A few non-Unix systems implement symlink, but not link.
4416 dnl A few non-systems implement neither (or have nonfunctional versions).
4417 AC_DEFUN([CF_LINK_FUNCS],
4418 [
4419 AC_CHECK_HEADERS( \
4420 unistd.h \
4421 )
4422 AC_CHECK_FUNCS( \
4423         remove \
4424         unlink )
4425
4426 if test "$cross_compiling" = yes ; then
4427         AC_CHECK_FUNCS( \
4428                 link \
4429                 symlink )
4430 else
4431         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
4432                 cf_cv_link_funcs=
4433                 for cf_func in link symlink ; do
4434                         AC_TRY_RUN([
4435 #include <sys/types.h>
4436 #include <sys/stat.h>
4437 #ifdef HAVE_UNISTD_H
4438 #include <unistd.h>
4439 #endif
4440 int main(void)
4441 {
4442         int fail = 0;
4443         char *src = "config.log";
4444         char *dst = "conftest.chk";
4445         struct stat src_sb;
4446         struct stat dst_sb;
4447
4448         stat(src, &src_sb);
4449         fail = ($cf_func("config.log", "conftest.chk") < 0)
4450             || (stat(dst, &dst_sb) < 0)
4451             || (dst_sb.st_mtime != src_sb.st_mtime);
4452 #ifdef HAVE_UNLINK
4453         unlink(dst);
4454 #else
4455         remove(dst);
4456 #endif
4457         ${cf_cv_main_return:-return} (fail);
4458 }
4459                         ],[
4460                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
4461                         eval 'ac_cv_func_'$cf_func'=yes'],[
4462                         eval 'ac_cv_func_'$cf_func'=no'],[
4463                         eval 'ac_cv_func_'$cf_func'=error'])
4464                 done
4465                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
4466         ])
4467         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
4468         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
4469 fi
4470 ])dnl
4471 dnl ---------------------------------------------------------------------------
4472 dnl CF_MAKEFLAGS version: 18 updated: 2018/02/21 21:26:03
4473 dnl ------------
4474 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
4475 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
4476 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
4477 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
4478 AC_DEFUN([CF_MAKEFLAGS],
4479 [
4480 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
4481         cf_cv_makeflags=''
4482         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
4483         do
4484                 cat >cf_makeflags.tmp <<CF_EOF
4485 SHELL = $SHELL
4486 all :
4487         @ echo '.$cf_option'
4488 CF_EOF
4489                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
4490                 case "$cf_result" in
4491                 (.*k|.*kw)
4492                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
4493                         case "$cf_result" in
4494                         (.*CC=*)        cf_cv_makeflags=
4495                                 ;;
4496                         (*)     cf_cv_makeflags=$cf_option
4497                                 ;;
4498                         esac
4499                         break
4500                         ;;
4501                 (.-)
4502                         ;;
4503                 (*)
4504                         CF_MSG_LOG(given option \"$cf_option\", no match \"$cf_result\")
4505                         ;;
4506                 esac
4507         done
4508         rm -f cf_makeflags.tmp
4509 ])
4510
4511 AC_SUBST(cf_cv_makeflags)
4512 ])dnl
4513 dnl ---------------------------------------------------------------------------
4514 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
4515 dnl ------------
4516 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
4517 dnl a monocase filesystem.
4518 AC_DEFUN([CF_MAKE_TAGS],[
4519 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
4520
4521 AC_CHECK_PROGS(CTAGS, exctags ctags)
4522 AC_CHECK_PROGS(ETAGS, exetags etags)
4523
4524 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
4525
4526 if test "$cf_cv_mixedcase" = yes ; then
4527         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
4528 else
4529         MAKE_UPPER_TAGS=no
4530 fi
4531
4532 if test "$MAKE_UPPER_TAGS" = yes ; then
4533         MAKE_UPPER_TAGS=
4534 else
4535         MAKE_UPPER_TAGS="#"
4536 fi
4537
4538 if test "$MAKE_LOWER_TAGS" = yes ; then
4539         MAKE_LOWER_TAGS=
4540 else
4541         MAKE_LOWER_TAGS="#"
4542 fi
4543
4544 AC_SUBST(CTAGS)
4545 AC_SUBST(ETAGS)
4546
4547 AC_SUBST(MAKE_UPPER_TAGS)
4548 AC_SUBST(MAKE_LOWER_TAGS)
4549 ])dnl
4550 dnl ---------------------------------------------------------------------------
4551 dnl CF_MANPAGE_FORMAT version: 11 updated: 2015/04/18 08:56:57
4552 dnl -----------------
4553 dnl Option to allow user to override automatic configuration of manpage format.
4554 dnl There are several special cases:
4555 dnl
4556 dnl     gzip - man checks for, can display gzip'd files
4557 dnl     compress - man checks for, can display compressed files
4558 dnl     BSDI - files in the cat-directories are suffixed ".0"
4559 dnl     formatted - installer should format (put files in cat-directory)
4560 dnl     catonly - installer should only format, e.g., for a turnkey system.
4561 dnl
4562 dnl There are other configurations which this macro does not test, e.g., HPUX's
4563 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
4564 dnl convention would not match our use).
4565 AC_DEFUN([CF_MANPAGE_FORMAT],
4566 [
4567 AC_REQUIRE([CF_PATHSEP])
4568 AC_MSG_CHECKING(format of man-pages)
4569
4570 AC_ARG_WITH(manpage-format,
4571         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
4572                           optionally formatted/catonly, e.g., gzip,formatted],
4573         [MANPAGE_FORMAT=$withval],
4574         [MANPAGE_FORMAT=unknown])
4575
4576 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
4577 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
4578
4579 cf_unknown=
4580
4581 case $MANPAGE_FORMAT in
4582 (unknown)
4583         if test -z "$MANPATH" ; then
4584                 MANPATH="/usr/man:/usr/share/man"
4585         fi
4586
4587         # look for the 'date' man-page (it's most likely to be installed!)
4588         MANPAGE_FORMAT=
4589         cf_preform=no
4590         cf_catonly=yes
4591         cf_example=date
4592
4593         IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
4594         for cf_dir in $MANPATH; do
4595                 test -z "$cf_dir" && cf_dir=/usr/man
4596                 for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
4597                 do
4598                         cf_test=`echo $cf_name | sed -e 's/*//'`
4599                         if test "x$cf_test" = "x$cf_name" ; then
4600
4601                                 case "$cf_name" in
4602                                 (*.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
4603                                 (*.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
4604                                 (*.0)  MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
4605                                 (*)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
4606                                 esac
4607
4608                                 case "$cf_name" in
4609                                 ($cf_dir/man*)
4610                                         cf_catonly=no
4611                                         ;;
4612                                 ($cf_dir/cat*)
4613                                         cf_preform=yes
4614                                         ;;
4615                                 esac
4616                                 break
4617                         fi
4618
4619                         # if we found a match in either man* or cat*, stop looking
4620                         if test -n "$MANPAGE_FORMAT" ; then
4621                                 cf_found=no
4622                                 test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
4623                                 test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
4624                                 case "$cf_name" in
4625                                 ($cf_dir/cat*)
4626                                         cf_found=yes
4627                                         ;;
4628                                 esac
4629                                 test $cf_found=yes && break
4630                         fi
4631                 done
4632                 # only check the first directory in $MANPATH where we find manpages
4633                 if test -n "$MANPAGE_FORMAT" ; then
4634                         break
4635                 fi
4636         done
4637         # if we did not find the example, just assume it is normal
4638         test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
4639         IFS="$ac_save_ifs"
4640         ;;
4641 (*)
4642         for cf_option in $MANPAGE_FORMAT; do
4643         case $cf_option in
4644         (gzip|compress|BSDI|normal|formatted|catonly)
4645                 ;;
4646         (*)
4647                 cf_unknown="$cf_unknown $cf_option"
4648                 ;;
4649         esac
4650         done
4651         ;;
4652 esac
4653
4654 AC_MSG_RESULT($MANPAGE_FORMAT)
4655 if test -n "$cf_unknown" ; then
4656         AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
4657 fi
4658 ])dnl
4659 dnl ---------------------------------------------------------------------------
4660 dnl CF_MANPAGE_RENAMES version: 10 updated: 2015/08/05 20:44:28
4661 dnl ------------------
4662 dnl The Debian people have their own naming convention for manpages.  This
4663 dnl option lets us override the name of the file containing renaming, or
4664 dnl disable it altogether.
4665 AC_DEFUN([CF_MANPAGE_RENAMES],
4666 [
4667 AC_MSG_CHECKING(for manpage renaming)
4668
4669 AC_ARG_WITH(manpage-renames,
4670         [  --with-manpage-renames  specify manpage-renaming],
4671         [MANPAGE_RENAMES=$withval],
4672         [MANPAGE_RENAMES=yes])
4673
4674 case ".$MANPAGE_RENAMES" in
4675 (.no)
4676         ;;
4677 (.|.yes)
4678         # Debian 'man' program?
4679         if test -f /etc/debian_version ; then
4680                 MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
4681         else
4682                 MANPAGE_RENAMES=no
4683         fi
4684         ;;
4685 esac
4686
4687 if test "$MANPAGE_RENAMES" != no ; then
4688         if test -f $srcdir/man/$MANPAGE_RENAMES ; then
4689                 MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
4690         elif test ! -f $MANPAGE_RENAMES ; then
4691                 AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
4692         fi
4693
4694         test ! -d man && mkdir man
4695
4696         # Construct a sed-script to perform renaming within man-pages
4697         if test -n "$MANPAGE_RENAMES" ; then
4698                 test ! -d man && mkdir man
4699                 $SHELL $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
4700         fi
4701 fi
4702
4703 AC_MSG_RESULT($MANPAGE_RENAMES)
4704 AC_SUBST(MANPAGE_RENAMES)
4705 ])dnl
4706 dnl ---------------------------------------------------------------------------
4707 dnl CF_MANPAGE_SYMLINKS version: 6 updated: 2015/04/17 21:13:04
4708 dnl -------------------
4709 dnl Some people expect each tool to make all aliases for manpages in the
4710 dnl man-directory.  This accommodates the older, less-capable implementations
4711 dnl of 'man', and is optional.
4712 AC_DEFUN([CF_MANPAGE_SYMLINKS],
4713 [
4714 AC_MSG_CHECKING(if manpage aliases will be installed)
4715
4716 AC_ARG_WITH(manpage-aliases,
4717         [  --with-manpage-aliases  specify manpage-aliases using .so],
4718         [MANPAGE_ALIASES=$withval],
4719         [MANPAGE_ALIASES=yes])
4720
4721 AC_MSG_RESULT($MANPAGE_ALIASES)
4722
4723 case "x$LN_S" in
4724 (xln*)
4725         cf_use_symlinks=yes
4726         ;;
4727 (*)
4728         cf_use_symlinks=no
4729         ;;
4730 esac
4731
4732 MANPAGE_SYMLINKS=no
4733 if test "$MANPAGE_ALIASES" = yes ; then
4734 AC_MSG_CHECKING(if manpage symlinks should be used)
4735
4736 AC_ARG_WITH(manpage-symlinks,
4737         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
4738         [MANPAGE_SYMLINKS=$withval],
4739         [MANPAGE_SYMLINKS=$cf_use_symlinks])
4740
4741 if test "$$cf_use_symlinks" = no; then
4742 if test "$MANPAGE_SYMLINKS" = yes ; then
4743         AC_MSG_WARN(cannot make symlinks, will use .so files)
4744         MANPAGE_SYMLINKS=no
4745 fi
4746 fi
4747
4748 AC_MSG_RESULT($MANPAGE_SYMLINKS)
4749 fi
4750
4751 ])dnl
4752 dnl ---------------------------------------------------------------------------
4753 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
4754 dnl --------------
4755 dnl This option causes manpages to be run through tbl(1) to generate tables
4756 dnl correctly.
4757 AC_DEFUN([CF_MANPAGE_TBL],
4758 [
4759 AC_MSG_CHECKING(for manpage tbl)
4760
4761 AC_ARG_WITH(manpage-tbl,
4762         [  --with-manpage-tbl      specify manpage processing with tbl],
4763         [MANPAGE_TBL=$withval],
4764         [MANPAGE_TBL=no])
4765
4766 AC_MSG_RESULT($MANPAGE_TBL)
4767 ])dnl
4768 dnl ---------------------------------------------------------------------------
4769 dnl CF_MAN_PAGES version: 47 updated: 2017/08/12 07:58:51
4770 dnl ------------
4771 dnl Try to determine if the man-pages on the system are compressed, and if
4772 dnl so, what format is used.  Use this information to construct a script that
4773 dnl will install man-pages.
4774 AC_DEFUN([CF_MAN_PAGES],
4775 [
4776 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
4777 CF_MANPAGE_FORMAT
4778 CF_MANPAGE_RENAMES
4779 CF_MANPAGE_SYMLINKS
4780 CF_MANPAGE_TBL
4781
4782 if test "$prefix" = "NONE" ; then
4783         cf_prefix="$ac_default_prefix"
4784 else
4785         cf_prefix="$prefix"
4786 fi
4787
4788 case "$MANPAGE_FORMAT" in
4789 (*catonly*)
4790         cf_format=yes
4791         cf_inboth=no
4792         ;;
4793 (*formatted*)
4794         cf_format=yes
4795         cf_inboth=yes
4796         ;;
4797 (*)
4798         cf_format=no
4799         cf_inboth=no
4800         ;;
4801 esac
4802
4803 test ! -d man && mkdir man
4804
4805 cf_so_strip=
4806 cf_compress=
4807 case "$MANPAGE_FORMAT" in
4808 (*compress*)
4809         cf_so_strip="Z"
4810         cf_compress=compress
4811         ;;
4812 (*gzip*)
4813         cf_so_strip="gz"
4814         cf_compress=gzip
4815         ;;
4816 esac
4817
4818 cf_edit_man=./edit_man.sh
4819 cf_man_alias=`pwd`/man_alias.sed
4820
4821 cat >$cf_edit_man <<CF_EOF
4822 #! $SHELL
4823 # this script is generated by the configure-script CF_MAN_PAGES macro.
4824
4825 prefix="$cf_prefix"
4826 datarootdir="$datarootdir"
4827 datadir="$datadir"
4828
4829 NCURSES_MAJOR="$NCURSES_MAJOR"
4830 NCURSES_MINOR="$NCURSES_MINOR"
4831 NCURSES_PATCH="$NCURSES_PATCH"
4832
4833 NCURSES_OSPEED="$NCURSES_OSPEED"
4834 TERMINFO="$TERMINFO"
4835
4836 INSTALL="$INSTALL"
4837 INSTALL_DATA="$INSTALL_DATA"
4838
4839 transform="$program_transform_name"
4840
4841 TMP=\${TMPDIR:=/tmp}/man\$\$
4842 trap "rm -f \$TMP" 0 1 2 3 15
4843
4844 form=\[$]1
4845 shift || exit 1
4846
4847 verb=\[$]1
4848 shift || exit 1
4849
4850 mandir=\[$]1
4851 shift || exit 1
4852
4853 srcdir=\[$]1
4854 top_srcdir=\[$]srcdir/..
4855 shift || exit 1
4856
4857 if test "\$form" = normal ; then
4858         if test "$cf_format" = yes ; then
4859         if test "$cf_inboth" = no ; then
4860                 $SHELL \[$]0 format \$verb \$mandir \$srcdir \[$]*
4861                 exit $?
4862         fi
4863         fi
4864         cf_subdir=\$mandir/man
4865         cf_tables=$MANPAGE_TBL
4866 else
4867         cf_subdir=\$mandir/cat
4868         cf_tables=yes
4869 fi
4870
4871 # process the list of source-files
4872 for i in \[$]* ; do
4873 case \$i in
4874 (*.orig|*.rej) ;;
4875 (*.[[0-9]]*)
4876         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
4877         if test \$verb = installing ; then
4878         if test ! -d \$cf_subdir\${section} ; then
4879                 mkdir -p \$cf_subdir\$section
4880         fi
4881         fi
4882
4883         # replace variables in man page
4884         if test ! -f $cf_man_alias ; then
4885 cat >>$cf_man_alias <<-CF_EOF2
4886                 s,@DATADIR@,\$datadir,g
4887                 s,@TERMINFO@,\${TERMINFO:="no default value"},g
4888                 s,@TERMINFO_DIRS@,\${TERMINFO_DIRS:="no default value"},g
4889                 s,@NCURSES_MAJOR@,\${NCURSES_MAJOR:="no default value"},g
4890                 s,@NCURSES_MINOR@,\${NCURSES_MINOR:="no default value"},g
4891                 s,@NCURSES_PATCH@,\${NCURSES_PATCH:="no default value"},g
4892                 s,@NCURSES_OSPEED@,\${NCURSES_OSPEED:="no default value"},g
4893 CF_EOF
4894         ifelse($1,,,[
4895         for cf_name in $1
4896         do
4897                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4898                 cf_name=`echo $cf_name|sed "$program_transform_name"`
4899 cat >>$cf_edit_man <<-CF_EOF
4900                 s,@$cf_NAME@,$cf_name,g
4901 CF_EOF
4902         done
4903         ])
4904 cat >>$cf_edit_man <<CF_EOF
4905 CF_EOF2
4906                 echo "...made $cf_man_alias"
4907         fi
4908
4909         aliases=
4910         cf_source=\`basename \$i\`
4911         inalias=\$cf_source
4912         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
4913         if test ! -f \$inalias ; then
4914                 echo .. skipped \$cf_source
4915                 continue
4916         fi
4917 CF_EOF
4918
4919 if test "$MANPAGE_ALIASES" != no ; then
4920 cat >>$cf_edit_man <<CF_EOF
4921         nCurses=ignore.3x
4922         test $with_curses_h = yes && nCurses=ncurses.3x
4923         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
4924 CF_EOF
4925 fi
4926
4927 if test "$MANPAGE_RENAMES" = no ; then
4928 cat >>$cf_edit_man <<CF_EOF
4929         # perform program transformations for section 1 man pages
4930         if test \$section = 1 ; then
4931                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
4932         else
4933                 cf_target=\$cf_subdir\${section}/\$cf_source
4934         fi
4935 CF_EOF
4936 else
4937 cat >>$cf_edit_man <<CF_EOF
4938         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
4939         if test -z "\$cf_target" ; then
4940                 echo '? missing rename for '\$cf_source
4941                 cf_target="\$cf_source"
4942         fi
4943         cf_target="\$cf_subdir\${section}/\${cf_target}"
4944
4945 CF_EOF
4946 fi
4947
4948 cat >>$cf_edit_man <<CF_EOF
4949         sed     -f $cf_man_alias \\
4950 CF_EOF
4951
4952 if test -f $MANPAGE_RENAMES ; then
4953 cat >>$cf_edit_man <<CF_EOF
4954                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
4955 CF_EOF
4956 else
4957 cat >>$cf_edit_man <<CF_EOF
4958                 < \$i >\$TMP
4959 CF_EOF
4960 fi
4961
4962 cat >>$cf_edit_man <<CF_EOF
4963 if test \$cf_tables = yes ; then
4964         tbl \$TMP >\$TMP.out
4965         mv \$TMP.out \$TMP
4966 fi
4967 CF_EOF
4968
4969 if test $with_overwrite != yes ; then
4970 cat >>$cf_edit_man <<CF_EOF
4971         sed -e "/\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
4972         mv \$TMP.out \$TMP
4973 CF_EOF
4974 fi
4975
4976 if test $with_curses_h != yes ; then
4977 cat >>$cf_edit_man <<CF_EOF
4978         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
4979         mv \$TMP.out \$TMP
4980 CF_EOF
4981 fi
4982
4983 cat >>$cf_edit_man <<CF_EOF
4984         if test \$form = format ; then
4985                 nroff -man \$TMP >\$TMP.out
4986                 mv \$TMP.out \$TMP
4987         fi
4988 CF_EOF
4989
4990 if test -n "$cf_compress" ; then
4991 cat >>$cf_edit_man <<CF_EOF
4992         if test \$verb = installing ; then
4993         if ( $cf_compress -f \$TMP )
4994         then
4995                 mv \$TMP.$cf_so_strip \$TMP
4996         fi
4997         fi
4998         cf_target="\$cf_target.$cf_so_strip"
4999 CF_EOF
5000 fi
5001
5002 case "$MANPAGE_FORMAT" in
5003 (*BSDI*)
5004 cat >>$cf_edit_man <<CF_EOF
5005         if test \$form = format ; then
5006                 # BSDI installs only .0 suffixes in the cat directories
5007                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
5008         fi
5009 CF_EOF
5010   ;;
5011 esac
5012
5013 cat >>$cf_edit_man <<CF_EOF
5014         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
5015         if test \$verb = installing ; then
5016                 echo \$verb \$cf_target
5017                 \$INSTALL_DATA \$TMP \$cf_target
5018                 test -d \$cf_subdir\${section} &&
5019                 test -n "\$aliases" && (
5020                         cd \$cf_subdir\${section} && (
5021                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
5022                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
5023                                 cf_target=\`basename \$cf_target\`
5024                                 for cf_alias in \$aliases
5025                                 do
5026                                         if test \$section = 1 ; then
5027                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
5028                                         fi
5029
5030                                         if test "$MANPAGE_SYMLINKS" = yes ; then
5031                                                 if test -f \$cf_alias\${suffix} ; then
5032                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
5033                                                         then
5034                                                                 continue
5035                                                         fi
5036                                                 fi
5037                                                 echo .. \$verb alias \$cf_alias\${suffix}
5038 CF_EOF
5039 case "x$LN_S" in
5040 (*-f)
5041 cat >>$cf_edit_man <<CF_EOF
5042                                                 $LN_S \$cf_target \$cf_alias\${suffix}
5043 CF_EOF
5044         ;;
5045 (*)
5046 cat >>$cf_edit_man <<CF_EOF
5047                                                 rm -f \$cf_alias\${suffix}
5048                                                 $LN_S \$cf_target \$cf_alias\${suffix}
5049 CF_EOF
5050         ;;
5051 esac
5052 cat >>$cf_edit_man <<CF_EOF
5053                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
5054                                                 echo ".so \$cf_source" >\$TMP
5055 CF_EOF
5056 if test -n "$cf_compress" ; then
5057 cat >>$cf_edit_man <<CF_EOF
5058                                                 if test -n "$cf_so_strip" ; then
5059                                                         $cf_compress -f \$TMP
5060                                                         mv \$TMP.$cf_so_strip \$TMP
5061                                                 fi
5062 CF_EOF
5063 fi
5064 cat >>$cf_edit_man <<CF_EOF
5065                                                 echo .. \$verb alias \$cf_alias\${suffix}
5066                                                 rm -f \$cf_alias\${suffix}
5067                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
5068                                         fi
5069                                 done
5070                         )
5071                 )
5072         elif test \$verb = removing ; then
5073                 test -f \$cf_target && (
5074                         echo \$verb \$cf_target
5075                         rm -f \$cf_target
5076                 )
5077                 test -d \$cf_subdir\${section} &&
5078                 test -n "\$aliases" && (
5079                         cd \$cf_subdir\${section} && (
5080                                 for cf_alias in \$aliases
5081                                 do
5082                                         if test \$section = 1 ; then
5083                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
5084                                         fi
5085
5086                                         echo .. \$verb alias \$cf_alias\${suffix}
5087                                         rm -f \$cf_alias\${suffix}
5088                                 done
5089                         )
5090                 )
5091         else
5092 #               echo ".hy 0"
5093                 cat \$TMP
5094         fi
5095         ;;
5096 esac
5097 done
5098
5099 if test $cf_inboth = yes ; then
5100 if test \$form != format ; then
5101         $SHELL \[$]0 format \$verb \$mandir \$srcdir \[$]*
5102 fi
5103 fi
5104
5105 exit 0
5106 CF_EOF
5107 chmod 755 $cf_edit_man
5108
5109 ])dnl
5110 dnl ---------------------------------------------------------------------------
5111 dnl CF_MATH_LIB version: 9 updated: 2017/01/21 11:06:25
5112 dnl -----------
5113 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
5114 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
5115 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
5116 AC_DEFUN([CF_MATH_LIB],
5117 [
5118 AC_CACHE_CHECK(if -lm needed for math functions,
5119         cf_cv_need_libm,[
5120         AC_TRY_LINK([
5121         #include <stdio.h>
5122         #include <stdlib.h>
5123         #include <math.h>
5124         ],
5125         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
5126         [cf_cv_need_libm=no],
5127         [cf_cv_need_libm=yes])])
5128 if test "$cf_cv_need_libm" = yes
5129 then
5130 ifelse($1,,[
5131         CF_ADD_LIB(m)
5132 ],[$1=-lm])
5133 fi
5134 ])
5135 dnl ---------------------------------------------------------------------------
5136 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
5137 dnl ----------------------
5138 dnl Check if the file-system supports mixed-case filenames.  If we're able to
5139 dnl create a lowercase name and see it as uppercase, it doesn't support that.
5140 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
5141 [
5142 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
5143 if test "$cross_compiling" = yes ; then
5144         case $target_alias in
5145         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
5146                 cf_cv_mixedcase=no
5147                 ;;
5148         (*)
5149                 cf_cv_mixedcase=yes
5150                 ;;
5151         esac
5152 else
5153         rm -f conftest CONFTEST
5154         echo test >conftest
5155         if test -f CONFTEST ; then
5156                 cf_cv_mixedcase=no
5157         else
5158                 cf_cv_mixedcase=yes
5159         fi
5160         rm -f conftest CONFTEST
5161 fi
5162 ])
5163 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
5164 ])dnl
5165 dnl ---------------------------------------------------------------------------
5166 dnl CF_MKSTEMP version: 10 updated: 2017/01/21 11:12:16
5167 dnl ----------
5168 dnl Check for a working mkstemp.  This creates two files, checks that they are
5169 dnl successfully created and distinct (AmigaOS apparently fails on the last).
5170 AC_DEFUN([CF_MKSTEMP],[
5171 AC_CHECK_HEADERS( \
5172 unistd.h \
5173 )
5174 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
5175 rm -rf conftest*
5176 AC_TRY_RUN([
5177 #include <sys/types.h>
5178 #ifdef HAVE_UNISTD_H
5179 #include <unistd.h>
5180 #endif
5181 #include <stdlib.h>
5182 #include <stdio.h>
5183 #include <string.h>
5184 #include <sys/stat.h>
5185 int main(void)
5186 {
5187         char *tmpl = "conftestXXXXXX";
5188         char name[2][80];
5189         int n;
5190         int result = 0;
5191         int fd;
5192         struct stat sb;
5193
5194         umask(077);
5195         for (n = 0; n < 2; ++n) {
5196                 strcpy(name[n], tmpl);
5197                 if ((fd = mkstemp(name[n])) >= 0) {
5198                         if (!strcmp(name[n], tmpl)
5199                          || stat(name[n], &sb) != 0
5200                          || (sb.st_mode & S_IFMT) != S_IFREG
5201                          || (sb.st_mode & 077) != 0) {
5202                                 result = 1;
5203                         }
5204                         close(fd);
5205                 }
5206         }
5207         if (result == 0
5208          && !strcmp(name[0], name[1]))
5209                 result = 1;
5210         ${cf_cv_main_return:-return}(result);
5211 }
5212 ],[cf_cv_func_mkstemp=yes
5213 ],[cf_cv_func_mkstemp=no
5214 ],[cf_cv_func_mkstemp=maybe])
5215 ])
5216 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
5217         AC_CHECK_FUNC(mkstemp)
5218 fi
5219 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
5220         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
5221 fi
5222 ])dnl
5223 dnl ---------------------------------------------------------------------------
5224 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
5225 dnl ----------
5226 dnl Write a debug message to config.log, along with the line number in the
5227 dnl configure script.
5228 AC_DEFUN([CF_MSG_LOG],[
5229 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
5230 ])dnl
5231 dnl ---------------------------------------------------------------------------
5232 dnl CF_NCURSES_ABI_6 version: 3 updated: 2015/06/06 16:10:11
5233 dnl ----------------
5234 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
5235 dnl warn about this.
5236 AC_DEFUN([CF_NCURSES_ABI_6],[
5237 if test "${with_abi_version+set}" != set; then
5238         case $cf_cv_rel_version in
5239         (5.*)
5240                 cf_cv_rel_version=6.0
5241                 cf_cv_abi_version=6
5242                 AC_MSG_WARN(overriding ABI version to $cf_cv_abi_version)
5243                 ;;
5244         esac
5245 fi
5246 ])dnl
5247 dnl ---------------------------------------------------------------------------
5248 dnl CF_NCURSES_WITH_ABI_VERSION version: 2 updated: 2015/12/19 17:51:52
5249 dnl ---------------------------
5250 dnl Allow ncurses's ABI to be overridden.  Generally this happens when a
5251 dnl packager has incremented the ABI past that used in the original package,
5252 dnl and wishes to keep doing this.
5253 dnl
5254 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
5255 dnl symbol.
5256 AC_DEFUN([CF_NCURSES_WITH_ABI_VERSION],[
5257 CF_WITH_ABI_VERSION($1)
5258 if test "x$cf_cv_abi_version" != "x$with_abi_version"
5259 then
5260         case $cf_cv_rel_version in
5261         (5.*)
5262                 cf_cv_rel_version=$with_abi_version.0
5263                 ;;
5264         esac
5265 fi
5266 ])dnl
5267 dnl ---------------------------------------------------------------------------
5268 dnl CF_NO_LEAKS_OPTION version: 6 updated: 2015/04/12 15:39:00
5269 dnl ------------------
5270 dnl see CF_WITH_NO_LEAKS
5271 AC_DEFUN([CF_NO_LEAKS_OPTION],[
5272 AC_MSG_CHECKING(if you want to use $1 for testing)
5273 AC_ARG_WITH($1,
5274         [$2],
5275         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
5276          $4
5277 ])
5278         : ${with_cflags:=-g}
5279         : ${with_no_leaks:=yes}
5280          with_$1=yes],
5281         [with_$1=])
5282 AC_MSG_RESULT(${with_$1:-no})
5283
5284 case .$with_cflags in
5285 (.*-g*)
5286         case .$CFLAGS in
5287         (.*-g*)
5288                 ;;
5289         (*)
5290                 CF_ADD_CFLAGS([-g])
5291                 ;;
5292         esac
5293         ;;
5294 esac
5295 ])dnl
5296 dnl ---------------------------------------------------------------------------
5297 dnl CF_NUMBER_SYNTAX version: 2 updated: 2015/04/17 21:13:04
5298 dnl ----------------
5299 dnl Check if the given variable is a number.  If not, report an error.
5300 dnl $1 is the variable
5301 dnl $2 is the message
5302 AC_DEFUN([CF_NUMBER_SYNTAX],[
5303 if test -n "$1" ; then
5304   case $1 in
5305   ([[0-9]]*)
5306         ;;
5307   (*)
5308         AC_MSG_ERROR($2 is not a number: $1)
5309         ;;
5310   esac
5311 else
5312   AC_MSG_ERROR($2 value is empty)
5313 fi
5314 ])dnl
5315 dnl ---------------------------------------------------------------------------
5316 dnl CF_OBJ_SUBDIR version: 7 updated: 2015/04/17 21:13:04
5317 dnl -------------
5318 dnl Compute the object-directory name from the given model name
5319 AC_DEFUN([CF_OBJ_SUBDIR],
5320 [
5321         case $1 in
5322         (libtool) $2='obj_lo'  ;;
5323         (normal)  $2='objects' ;;
5324         (debug)   $2='obj_g' ;;
5325         (profile) $2='obj_p' ;;
5326         (shared)
5327                 case $cf_cv_system_name in
5328                 (cygwin|msys)
5329                         $2='objects' ;;
5330                 (*)
5331                         $2='obj_s' ;;
5332                 esac
5333         esac
5334 ])dnl
5335 dnl ---------------------------------------------------------------------------
5336 dnl CF_PATHSEP version: 7 updated: 2015/04/12 15:39:00
5337 dnl ----------
5338 dnl Provide a value for the $PATH and similar separator (or amend the value
5339 dnl as provided in autoconf 2.5x).
5340 AC_DEFUN([CF_PATHSEP],
5341 [
5342         AC_MSG_CHECKING(for PATH separator)
5343         case $cf_cv_system_name in
5344         (os2*)  PATH_SEPARATOR=';'  ;;
5345         (*)     ${PATH_SEPARATOR:=':'}  ;;
5346         esac
5347 ifelse([$1],,,[$1=$PATH_SEPARATOR])
5348         AC_SUBST(PATH_SEPARATOR)
5349         AC_MSG_RESULT($PATH_SEPARATOR)
5350 ])dnl
5351 dnl ---------------------------------------------------------------------------
5352 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
5353 dnl --------------
5354 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
5355 dnl begins with one of the prefix/exec_prefix variables, and then again if the
5356 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
5357 dnl delayed evaluation of those symbols.
5358 AC_DEFUN([CF_PATH_SYNTAX],[
5359 if test "x$prefix" != xNONE; then
5360         cf_path_syntax="$prefix"
5361 else
5362         cf_path_syntax="$ac_default_prefix"
5363 fi
5364
5365 case ".[$]$1" in
5366 (.\[$]\(*\)*|.\'*\'*)
5367         ;;
5368 (..|./*|.\\*)
5369         ;;
5370 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
5371         ;;
5372 (.\[$]{*prefix}*|.\[$]{*dir}*)
5373         eval $1="[$]$1"
5374         case ".[$]$1" in
5375         (.NONE/*)
5376                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
5377                 ;;
5378         esac
5379         ;;
5380 (.no|.NONE/*)
5381         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
5382         ;;
5383 (*)
5384         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
5385         ;;
5386 esac
5387 ])dnl
5388 dnl ---------------------------------------------------------------------------
5389 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
5390 dnl -------------
5391 dnl Check for the package-config program, unless disabled by command-line.
5392 AC_DEFUN([CF_PKG_CONFIG],
5393 [
5394 AC_MSG_CHECKING(if you want to use pkg-config)
5395 AC_ARG_WITH(pkg-config,
5396         [  --with-pkg-config{=path} enable/disable use of pkg-config],
5397         [cf_pkg_config=$withval],
5398         [cf_pkg_config=yes])
5399 AC_MSG_RESULT($cf_pkg_config)
5400
5401 case $cf_pkg_config in
5402 (no)
5403         PKG_CONFIG=none
5404         ;;
5405 (yes)
5406         CF_ACVERSION_CHECK(2.52,
5407                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
5408                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
5409         ;;
5410 (*)
5411         PKG_CONFIG=$withval
5412         ;;
5413 esac
5414
5415 test -z "$PKG_CONFIG" && PKG_CONFIG=none
5416 if test "$PKG_CONFIG" != none ; then
5417         CF_PATH_SYNTAX(PKG_CONFIG)
5418 elif test "x$cf_pkg_config" != xno ; then
5419         AC_MSG_WARN(pkg-config is not installed)
5420 fi
5421
5422 AC_SUBST(PKG_CONFIG)
5423 ])dnl
5424 dnl ---------------------------------------------------------------------------
5425 dnl CF_POSIX_C_SOURCE version: 10 updated: 2018/06/20 20:23:13
5426 dnl -----------------
5427 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
5428 dnl
5429 dnl     POSIX.1-1990                            _POSIX_SOURCE
5430 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
5431 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
5432 dnl             Bindings Option
5433 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
5434 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
5435 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
5436 dnl
5437 dnl Parameters:
5438 dnl     $1 is the nominal value for _POSIX_C_SOURCE
5439 AC_DEFUN([CF_POSIX_C_SOURCE],
5440 [
5441 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
5442
5443 cf_save_CFLAGS="$CFLAGS"
5444 cf_save_CPPFLAGS="$CPPFLAGS"
5445
5446 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
5447 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
5448
5449 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
5450         CF_MSG_LOG(if the symbol is already defined go no further)
5451         AC_TRY_COMPILE([#include <sys/types.h>],[
5452 #ifndef _POSIX_C_SOURCE
5453 make an error
5454 #endif],
5455         [cf_cv_posix_c_source=no],
5456         [cf_want_posix_source=no
5457          case .$cf_POSIX_C_SOURCE in
5458          (.[[12]]??*)
5459                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
5460                 ;;
5461          (.2)
5462                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
5463                 cf_want_posix_source=yes
5464                 ;;
5465          (.*)
5466                 cf_want_posix_source=yes
5467                 ;;
5468          esac
5469          if test "$cf_want_posix_source" = yes ; then
5470                 AC_TRY_COMPILE([#include <sys/types.h>],[
5471 #ifdef _POSIX_SOURCE
5472 make an error
5473 #endif],[],
5474                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
5475          fi
5476          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
5477          CFLAGS="$cf_trim_CFLAGS"
5478          CPPFLAGS="$cf_trim_CPPFLAGS"
5479          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
5480          CF_MSG_LOG(if the second compile does not leave our definition intact error)
5481          AC_TRY_COMPILE([#include <sys/types.h>],[
5482 #ifndef _POSIX_C_SOURCE
5483 make an error
5484 #endif],,
5485          [cf_cv_posix_c_source=no])
5486          CFLAGS="$cf_save_CFLAGS"
5487          CPPFLAGS="$cf_save_CPPFLAGS"
5488         ])
5489 ])
5490
5491 if test "$cf_cv_posix_c_source" != no ; then
5492         CFLAGS="$cf_trim_CFLAGS"
5493         CPPFLAGS="$cf_trim_CPPFLAGS"
5494         CF_ADD_CFLAGS($cf_cv_posix_c_source)
5495 fi
5496
5497 ])dnl
5498 dnl ---------------------------------------------------------------------------
5499 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
5500 dnl ------------
5501 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
5502 dnl
5503 dnl $1 = symbol to test
5504 dnl $2 = value (if any) to use for a predefinition
5505 AC_DEFUN([CF_PREDEFINE],
5506 [
5507 AC_MSG_CHECKING(if we must define $1)
5508 AC_TRY_COMPILE([#include <sys/types.h>
5509 ],[
5510 #ifndef $1
5511 make an error
5512 #endif],[cf_result=no],[cf_result=yes])
5513 AC_MSG_RESULT($cf_result)
5514
5515 if test "$cf_result" = yes ; then
5516         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
5517 elif test "x$2" != "x" ; then
5518         AC_MSG_CHECKING(checking for compatible value versus $2)
5519         AC_TRY_COMPILE([#include <sys/types.h>
5520 ],[
5521 #if $1-$2 < 0
5522 make an error
5523 #endif],[cf_result=yes],[cf_result=no])
5524         AC_MSG_RESULT($cf_result)
5525         if test "$cf_result" = no ; then
5526                 # perhaps we can override it - try...
5527                 CPPFLAGS="$CPPFLAGS -D$1=$2"
5528         fi
5529 fi
5530 ])dnl
5531 dnl ---------------------------------------------------------------------------
5532 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
5533 dnl ------------
5534 dnl Append definitions and rules for the given programs to the subdirectory
5535 dnl Makefiles, and the recursion rule for the top-level Makefile.
5536 dnl
5537 dnl parameters
5538 dnl     $1 = script to run
5539 dnl     $2 = list of subdirectories
5540 dnl
5541 dnl variables
5542 dnl     $AWK
5543 AC_DEFUN([CF_PRG_RULES],
5544 [
5545 for cf_dir in $2
5546 do
5547         if test ! -d $srcdir/$cf_dir; then
5548                 continue
5549         elif test -f $srcdir/$cf_dir/programs; then
5550                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
5551         fi
5552 done
5553
5554 ])dnl
5555 dnl ---------------------------------------------------------------------------
5556 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
5557 dnl ----------
5558 dnl Check for archiver "ar".
5559 AC_DEFUN([CF_PROG_AR],[
5560 AC_CHECK_TOOL(AR, ar, ar)
5561 ])
5562 dnl ---------------------------------------------------------------------------
5563 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
5564 dnl -----------
5565 dnl Check for awk, ensure that the check found something.
5566 AC_DEFUN([CF_PROG_AWK],
5567 [
5568 AC_PROG_AWK
5569 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
5570 ])dnl
5571 dnl ---------------------------------------------------------------------------
5572 dnl CF_PROG_CC version: 4 updated: 2014/07/12 18:57:58
5573 dnl ----------
5574 dnl standard check for CC, plus followup sanity checks
5575 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
5576 AC_DEFUN([CF_PROG_CC],[
5577 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
5578 CF_GCC_VERSION
5579 CF_ACVERSION_CHECK(2.52,
5580         [AC_PROG_CC_STDC],
5581         [CF_ANSI_CC_REQD])
5582 CF_CC_ENV_FLAGS
5583 ])dnl
5584 dnl ---------------------------------------------------------------------------
5585 dnl CF_PROG_CC_C_O version: 5 updated: 2017/01/21 11:06:25
5586 dnl --------------
5587 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
5588 dnl the output file can be renamed, and allows for a shell variable that can
5589 dnl be used later.  The parameter is either CC or CXX.  The result is the
5590 dnl cache variable:
5591 dnl     $cf_cv_prog_CC_c_o
5592 dnl     $cf_cv_prog_CXX_c_o
5593 dnl
5594 dnl $1 = compiler
5595 dnl $2 = compiler options, if any
5596 AC_DEFUN([CF_PROG_CC_C_O],
5597 [AC_REQUIRE([AC_PROG_CC])dnl
5598 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
5599 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
5600 [
5601 cat > conftest.$ac_ext <<CF_EOF
5602 int main(void)
5603 {
5604         ${cf_cv_main_return:-return}(0);
5605 }
5606 CF_EOF
5607 # We do the test twice because some compilers refuse to overwrite an
5608 # existing .o file with -o, though they will create one.
5609 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
5610 if AC_TRY_EVAL(ac_try) &&
5611   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
5612 then
5613   eval cf_cv_prog_$1_c_o=yes
5614 else
5615   eval cf_cv_prog_$1_c_o=no
5616 fi
5617 rm -rf conftest*
5618 ])dnl
5619 if test $cf_cv_prog_$1_c_o = yes; then
5620   AC_MSG_RESULT([yes])
5621 else
5622   AC_MSG_RESULT([no])
5623 fi
5624 ])dnl
5625 dnl ---------------------------------------------------------------------------
5626 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
5627 dnl -------------
5628 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
5629 dnl This macro adds a check to ensure the script found something.
5630 AC_DEFUN([CF_PROG_EGREP],
5631 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
5632         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
5633                 then ac_cv_prog_egrep='grep -E'
5634                 else ac_cv_prog_egrep='egrep'
5635         fi])
5636         EGREP=$ac_cv_prog_egrep
5637         AC_SUBST([EGREP])
5638         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
5639 ])dnl
5640 dnl ---------------------------------------------------------------------------
5641 dnl CF_PROG_GNAT version: 6 updated: 2018/01/16 16:45:49
5642 dnl ------------
5643 dnl Check for gnatmake, ensure that it is complete.
5644 AC_DEFUN([CF_PROG_GNAT],[
5645 cf_ada_make=gnatmake
5646 cf_ada_config="#"
5647 AC_CHECK_PROG(gnatmake_exists, $cf_ada_make, yes, no)
5648 if test "$ac_cv_prog_gnatmake_exists" = no; then
5649         cf_ada_make=
5650         cf_cv_prog_gnat_correct=no
5651 else
5652         AC_CHECK_PROG(gprconfig_exists, gprconfig, yes, no)
5653         if test "$ac_cv_prog_gprconfig_exists" = yes
5654         then
5655                 rm -rf conftest* *~conftest*
5656                 if mkdir conftest.src
5657                 then
5658                         cf_ada_config=""
5659                         cd conftest.src
5660                         for cf_gprconfig in Ada C
5661                         do
5662                                 AC_MSG_CHECKING(for gprconfig name for $cf_gprconfig)
5663                                 cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
5664                                 if test -n "$cf_gprconfig_value"
5665                                 then
5666                                         eval cf_ada_config_[$]cf_gprconfig=[$]cf_gprconfig_value
5667                                         AC_MSG_RESULT($cf_gprconfig_value)
5668                                 else
5669                                         AC_MSG_RESULT(missing)
5670                                         cf_ada_config="#"
5671                                         break
5672                                 fi
5673                         done
5674                         cd ..
5675                         rm -rf conftest* *~conftest*
5676                 fi
5677         else
5678                 # gprconfig is newer than gnatmake; we can continue...
5679                 cf_ada_config="##"
5680         fi
5681         if test "x$cf_ada_config" != "x#"
5682         then
5683                 CF_GNAT_VERSION
5684                 AC_CHECK_PROG(M4_exists, m4, yes, no)
5685                 if test "$ac_cv_prog_M4_exists" = no; then
5686                         cf_cv_prog_gnat_correct=no
5687                         echo Ada95 binding required program m4 not found. Ada95 binding disabled.
5688                 fi
5689                 if test "$cf_cv_prog_gnat_correct" = yes; then
5690                         AC_MSG_CHECKING(if GNAT works)
5691                         CF_GNAT_TRY_RUN([procedure conftest;],
5692 [with Text_IO;
5693 with GNAT.OS_Lib;
5694 procedure conftest is
5695 begin
5696    Text_IO.Put ("Hello World");
5697    Text_IO.New_Line;
5698    GNAT.OS_Lib.OS_Exit (0);
5699 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
5700                         AC_MSG_RESULT($cf_cv_prog_gnat_correct)
5701                 fi
5702         else
5703                 cf_cv_prog_gnat_correct=no
5704         fi
5705 fi
5706
5707 AC_SUBST(cf_ada_make)
5708 AC_SUBST(cf_ada_config)
5709 AC_SUBST(cf_ada_config_Ada)
5710 AC_SUBST(cf_ada_config_C)
5711 ])dnl
5712 dnl ---------------------------------------------------------------------------
5713 dnl CF_PROG_LDCONFIG version: 5 updated: 2015/04/18 08:56:57
5714 dnl ----------------
5715 dnl Check for ldconfig, needed to fixup shared libraries that would be built
5716 dnl and then used in the install.
5717 AC_DEFUN([CF_PROG_LDCONFIG],[
5718 if test "$cross_compiling" = yes ; then
5719         LDCONFIG=:
5720 else
5721         case "$cf_cv_system_name" in
5722         (dragonfly*|mirbsd*|freebsd*)
5723                 test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
5724                 ;;
5725         (*) LDPATH=$PATH:/sbin:/usr/sbin
5726                 AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
5727                 ;;
5728         esac
5729 fi
5730 AC_SUBST(LDCONFIG)
5731 ])dnl
5732 dnl ---------------------------------------------------------------------------
5733 dnl CF_PROG_LINT version: 3 updated: 2016/05/22 15:25:54
5734 dnl ------------
5735 AC_DEFUN([CF_PROG_LINT],
5736 [
5737 AC_CHECK_PROGS(LINT, lint cppcheck splint)
5738 AC_SUBST(LINT_OPTS)
5739 ])dnl
5740 dnl ---------------------------------------------------------------------------
5741 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
5742 dnl ------------
5743 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
5744 dnl option if it is supported.
5745 AC_DEFUN([CF_PROG_LN_S],[
5746 AC_PROG_LN_S
5747 AC_MSG_CHECKING(if $LN_S -f options work)
5748
5749 rm -f conf$$.src conf$$dst
5750 echo >conf$$.dst
5751 echo first >conf$$.src
5752 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
5753         cf_prog_ln_sf=yes
5754 else
5755         cf_prog_ln_sf=no
5756 fi
5757 rm -f conf$$.dst conf$$src
5758 AC_MSG_RESULT($cf_prog_ln_sf)
5759
5760 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
5761 ])dnl
5762 dnl ---------------------------------------------------------------------------
5763 dnl CF_REGEX version: 12 updated: 2015/04/18 08:56:57
5764 dnl --------
5765 dnl Attempt to determine if we've got one of the flavors of regular-expression
5766 dnl code that we can support.
5767 AC_DEFUN([CF_REGEX],
5768 [
5769
5770 cf_regex_func=no
5771
5772 cf_regex_libs="regex re"
5773 case $host_os in
5774 (mingw*)
5775         cf_regex_libs="gnurx $cf_regex_libs"
5776         ;;
5777 esac
5778
5779 AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
5780         for cf_regex_lib in $cf_regex_libs
5781         do
5782                 AC_CHECK_LIB($cf_regex_lib,regcomp,[
5783                                 CF_ADD_LIB($cf_regex_lib)
5784                                 cf_regex_func=regcomp
5785                                 break])
5786         done
5787 ])
5788
5789 if test "$cf_regex_func" = no ; then
5790         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
5791                 AC_CHECK_LIB(gen,compile,[
5792                                 CF_ADD_LIB(gen)
5793                                 cf_regex_func=compile])])
5794 fi
5795
5796 if test "$cf_regex_func" = no ; then
5797         AC_MSG_WARN(cannot find regular expression library)
5798 fi
5799
5800 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
5801
5802 cf_cv_regex_hdrs=no
5803 case $cf_regex_func in
5804 (compile)
5805         for cf_regex_hdr in regexp.h regexpr.h
5806         do
5807                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
5808                         char *p = compile("", "", "", 0);
5809                         int x = step("", "");
5810                 ],[
5811                         cf_cv_regex_hdrs=$cf_regex_hdr
5812                         break
5813                 ])
5814         done
5815         ;;
5816 (*)
5817         for cf_regex_hdr in regex.h
5818         do
5819                 AC_TRY_LINK([#include <sys/types.h>
5820 #include <$cf_regex_hdr>],[
5821                         regex_t *p;
5822                         int x = regcomp(p, "", 0);
5823                         int y = regexec(p, "", 0, 0, 0);
5824                         regfree(p);
5825                 ],[
5826                         cf_cv_regex_hdrs=$cf_regex_hdr
5827                         break
5828                 ])
5829         done
5830         ;;
5831 esac
5832
5833 ])
5834
5835 case $cf_cv_regex_hdrs in
5836         (no)            AC_MSG_WARN(no regular expression header found) ;;
5837         (regex.h)       AC_DEFINE(HAVE_REGEX_H_FUNCS,1,[Define to 1 to include regex.h for regular expressions]) ;;
5838         (regexp.h)      AC_DEFINE(HAVE_REGEXP_H_FUNCS,1,[Define to 1 to include regexp.h for regular expressions]) ;;
5839         (regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS,1,[Define to 1 to include regexpr.h for regular expressions]) ;;
5840 esac
5841 ])dnl
5842 dnl ---------------------------------------------------------------------------
5843 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
5844 dnl ----------------
5845 dnl Remove all -U and -D options that refer to the given symbol from a list
5846 dnl of C compiler options.  This works around the problem that not all
5847 dnl compilers process -U and -D options from left-to-right, so a -U option
5848 dnl cannot be used to cancel the effect of a preceding -D option.
5849 dnl
5850 dnl $1 = target (which could be the same as the source variable)
5851 dnl $2 = source (including '$')
5852 dnl $3 = symbol to remove
5853 define([CF_REMOVE_DEFINE],
5854 [
5855 $1=`echo "$2" | \
5856         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
5857                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
5858 ])dnl
5859 dnl ---------------------------------------------------------------------------
5860 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
5861 dnl -------------
5862 dnl Remove the given library from the symbol
5863 dnl
5864 dnl $1 = target (which could be the same as the source variable)
5865 dnl $2 = source (including '$')
5866 dnl $3 = library to remove
5867 define([CF_REMOVE_LIB],
5868 [
5869 # remove $3 library from $2
5870 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
5871 ])dnl
5872 dnl ---------------------------------------------------------------------------
5873 dnl CF_RPATH_HACK version: 11 updated: 2013/09/01 13:02:00
5874 dnl -------------
5875 AC_DEFUN([CF_RPATH_HACK],
5876 [
5877 AC_REQUIRE([CF_LD_RPATH_OPT])
5878 AC_MSG_CHECKING(for updated LDFLAGS)
5879 if test -n "$LD_RPATH_OPT" ; then
5880         AC_MSG_RESULT(maybe)
5881
5882         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
5883         cf_rpath_list="/usr/lib /lib"
5884         if test "$cf_ldd_prog" != no
5885         then
5886                 cf_rpath_oops=
5887
5888 AC_TRY_LINK([#include <stdio.h>],
5889                 [printf("Hello");],
5890                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
5891                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
5892
5893                 # If we passed the link-test, but get a "not found" on a given library,
5894                 # this could be due to inept reconfiguration of gcc to make it only
5895                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
5896                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
5897                 # /usr/local libraries.
5898                 if test -n "$cf_rpath_oops"
5899                 then
5900                         for cf_rpath_src in $cf_rpath_oops
5901                         do
5902                                 for cf_rpath_dir in \
5903                                         /usr/local \
5904                                         /usr/pkg \
5905                                         /opt/sfw
5906                                 do
5907                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
5908                                         then
5909                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
5910                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
5911                                                 break
5912                                         fi
5913                                 done
5914                         done
5915                 fi
5916         fi
5917
5918         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5919
5920         CF_RPATH_HACK_2(LDFLAGS)
5921         CF_RPATH_HACK_2(LIBS)
5922
5923         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5924 else
5925         AC_MSG_RESULT(no)
5926 fi
5927 AC_SUBST(EXTRA_LDFLAGS)
5928 ])dnl
5929 dnl ---------------------------------------------------------------------------
5930 dnl CF_RPATH_HACK_2 version: 7 updated: 2015/04/12 15:39:00
5931 dnl ---------------
5932 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
5933 dnl EXTRA_LDFLAGS for each -L option found.
5934 dnl
5935 dnl $cf_rpath_list contains a list of directories to ignore.
5936 dnl
5937 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
5938 dnl      but LIBS often has misplaced -L options.
5939 AC_DEFUN([CF_RPATH_HACK_2],
5940 [
5941 CF_VERBOSE(...checking $1 [$]$1)
5942
5943 cf_rpath_dst=
5944 for cf_rpath_src in [$]$1
5945 do
5946         case $cf_rpath_src in
5947         (-L*)
5948
5949                 # check if this refers to a directory which we will ignore
5950                 cf_rpath_skip=no
5951                 if test -n "$cf_rpath_list"
5952                 then
5953                         for cf_rpath_item in $cf_rpath_list
5954                         do
5955                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
5956                                 then
5957                                         cf_rpath_skip=yes
5958                                         break
5959                                 fi
5960                         done
5961                 fi
5962
5963                 if test "$cf_rpath_skip" = no
5964                 then
5965                         # transform the option
5966                         if test "$LD_RPATH_OPT" = "-R " ; then
5967                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
5968                         else
5969                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
5970                         fi
5971
5972                         # if we have not already added this, add it now
5973                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
5974                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
5975                         then
5976                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
5977                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
5978                         fi
5979                 fi
5980                 ;;
5981         esac
5982         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
5983 done
5984 $1=$cf_rpath_dst
5985
5986 CF_VERBOSE(...checked $1 [$]$1)
5987 AC_SUBST(EXTRA_LDFLAGS)
5988 ])dnl
5989 dnl ---------------------------------------------------------------------------
5990 dnl CF_SHARED_OPTS version: 92 updated: 2017/12/30 17:26:05
5991 dnl --------------
5992 dnl --------------
5993 dnl Attempt to determine the appropriate CC/LD options for creating a shared
5994 dnl library.
5995 dnl
5996 dnl Notes:
5997 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
5998 dnl the build-tree, i.e., by making use of the libraries that are compiled in
5999 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
6000 dnl shared library since that can lead to unexpected results at runtime.
6001 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
6002 dnl libraries are compiled in ../../lib
6003 dnl
6004 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
6005 dnl to install symbolic links to the rel/abi versions of shared libraries.
6006 dnl
6007 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
6008 dnl version when making symbolic links.
6009 dnl
6010 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
6011 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
6012 dnl (ex: libncurses.so.<ver>).
6013 dnl
6014 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
6015 AC_DEFUN([CF_SHARED_OPTS],
6016 [
6017         AC_REQUIRE([CF_LD_RPATH_OPT])
6018
6019         RM_SHARED_OPTS=
6020         LOCAL_LDFLAGS=
6021         LOCAL_LDFLAGS2=
6022         LD_SHARED_OPTS=
6023         INSTALL_LIB="-m 644"
6024         : ${rel_builddir:=.}
6025
6026         shlibdir=$libdir
6027         AC_SUBST(shlibdir)
6028
6029         MAKE_DLLS="#"
6030         AC_SUBST(MAKE_DLLS)
6031
6032         cf_cv_do_symlinks=no
6033         cf_ld_rpath_opt=
6034         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
6035
6036         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
6037         AC_ARG_WITH(shlib-version,
6038         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
6039         [test -z "$withval" && withval=auto
6040         case $withval in
6041         (yes)
6042                 cf_cv_shlib_version=auto
6043                 ;;
6044         (rel|abi|auto)
6045                 cf_cv_shlib_version=$withval
6046                 ;;
6047         (*)
6048                 AC_MSG_RESULT($withval)
6049                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
6050                 ;;
6051         esac
6052         ],[cf_cv_shlib_version=auto])
6053         AC_MSG_RESULT($cf_cv_shlib_version)
6054
6055         cf_cv_rm_so_locs=no
6056         cf_try_cflags=
6057
6058         # Some less-capable ports of gcc support only -fpic
6059         CC_SHARED_OPTS=
6060
6061         cf_try_fPIC=no
6062         if test "$GCC" = yes
6063         then
6064                 cf_try_fPIC=yes
6065         else
6066                 case $cf_cv_system_name in
6067                 (*linux*)       # e.g., PGI compiler
6068                         cf_try_fPIC=yes
6069                         ;;
6070                 esac
6071         fi
6072
6073         if test "$cf_try_fPIC" = yes
6074         then
6075                 AC_MSG_CHECKING(which $CC option to use)
6076                 cf_save_CFLAGS="$CFLAGS"
6077                 for CC_SHARED_OPTS in -fPIC -fpic ''
6078                 do
6079                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
6080                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
6081                 done
6082                 AC_MSG_RESULT($CC_SHARED_OPTS)
6083                 CFLAGS="$cf_save_CFLAGS"
6084         fi
6085
6086         cf_cv_shlib_version_infix=no
6087
6088         case $cf_cv_system_name in
6089         (aix4.[3-9]*|aix[[5-7]]*)
6090                 if test "$GCC" = yes; then
6091                         CC_SHARED_OPTS='-Wl,-brtl'
6092                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
6093                 else
6094                         CC_SHARED_OPTS='-brtl'
6095                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
6096                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
6097                 fi
6098                 ;;
6099         (beos*)
6100                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
6101                 ;;
6102         (cygwin*)
6103                 CC_SHARED_OPTS=
6104                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
6105                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
6106                 cf_cv_shlib_version=cygdll
6107                 cf_cv_shlib_version_infix=cygdll
6108                 shlibdir=$bindir
6109                 MAKE_DLLS=
6110                 cat >mk_shared_lib.sh <<-CF_EOF
6111                 #!$SHELL
6112                 SHARED_LIB=\[$]1
6113                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
6114                 shift
6115                 cat <<-EOF
6116                 Linking shared library
6117                 ** SHARED_LIB \[$]SHARED_LIB
6118                 ** IMPORT_LIB \[$]IMPORT_LIB
6119 EOF
6120                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
6121 CF_EOF
6122                 chmod +x mk_shared_lib.sh
6123                 ;;
6124         (msys*)
6125                 CC_SHARED_OPTS=
6126                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
6127                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
6128                 cf_cv_shlib_version=msysdll
6129                 cf_cv_shlib_version_infix=msysdll
6130                 shlibdir=$bindir
6131                 MAKE_DLLS=
6132                 cat >mk_shared_lib.sh <<-CF_EOF
6133                 #!$SHELL
6134                 SHARED_LIB=\[$]1
6135                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
6136                 shift
6137                 cat <<-EOF
6138                 Linking shared library
6139                 ** SHARED_LIB \[$]SHARED_LIB
6140                 ** IMPORT_LIB \[$]IMPORT_LIB
6141 EOF
6142                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
6143 CF_EOF
6144                 chmod +x mk_shared_lib.sh
6145                 ;;
6146         (darwin*)
6147                 cf_try_cflags="no-cpp-precomp"
6148                 CC_SHARED_OPTS="-dynamic"
6149                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
6150                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
6151                 cf_cv_shlib_version_infix=yes
6152                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
6153                         cf_save_LDFLAGS=$LDFLAGS
6154                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
6155                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
6156                                 LDFLAGS=$cf_save_LDFLAGS])
6157                 if test $cf_cv_ldflags_search_paths_first = yes; then
6158                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
6159                 fi
6160                 ;;
6161         (hpux[[7-8]]*)
6162                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
6163                 if test "$GCC" != yes; then
6164                         CC_SHARED_OPTS='+Z'
6165                 fi
6166                 MK_SHARED_LIB='${LD} ${LDFLAGS} -b -o $[@]'
6167                 INSTALL_LIB="-m 555"
6168                 ;;
6169         (hpux*)
6170                 # (tested with gcc 2.7.2 -- I don't have c89)
6171                 if test "$GCC" = yes; then
6172                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
6173                 else
6174                         CC_SHARED_OPTS='+Z'
6175                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
6176                 fi
6177                 MK_SHARED_LIB='${LD} ${LDFLAGS} +b ${libdir} -b -o $[@]'
6178                 # HP-UX shared libraries must be executable, and should be
6179                 # readonly to exploit a quirk in the memory manager.
6180                 INSTALL_LIB="-m 555"
6181                 ;;
6182         (interix*)
6183                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6184                 if test "$cf_cv_shlib_version" = rel; then
6185                         cf_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
6186                 else
6187                         cf_shared_soname='`basename $[@]`'
6188                 fi
6189                 CC_SHARED_OPTS=
6190                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $[@]'
6191                 ;;
6192         (irix*)
6193                 if test "$cf_cv_enable_rpath" = yes ; then
6194                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6195                 fi
6196                 # tested with IRIX 5.2 and 'cc'.
6197                 if test "$GCC" != yes; then
6198                         CC_SHARED_OPTS='-KPIC'
6199                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
6200                 else
6201                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,`basename $[@]` -o $[@]'
6202                 fi
6203                 cf_cv_rm_so_locs=yes
6204                 ;;
6205         (linux*|gnu*|k*bsd*-gnu)
6206                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
6207                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
6208                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6209                 fi
6210                 if test "$cf_cv_enable_rpath" = yes ; then
6211                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6212                 fi
6213                 CF_SHARED_SONAME
6214                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
6215                 ;;
6216         (mingw*)
6217                 cf_cv_shlib_version=mingw
6218                 cf_cv_shlib_version_infix=mingw
6219                 shlibdir=$bindir
6220                 MAKE_DLLS=
6221                 if test "$DFT_LWR_MODEL" = "shared" ; then
6222                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
6223                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6224                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
6225                 fi
6226                 CC_SHARED_OPTS=
6227                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
6228                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
6229                 cat >mk_shared_lib.sh <<-CF_EOF
6230                 #!$SHELL
6231                 SHARED_LIB=\[$]1
6232                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
6233                 shift
6234                 cat <<-EOF
6235                 Linking shared library
6236                 ** SHARED_LIB \[$]SHARED_LIB
6237                 ** IMPORT_LIB \[$]IMPORT_LIB
6238 EOF
6239                 exec \[$]* ${LDFLAGS} -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
6240 CF_EOF
6241                 chmod +x mk_shared_lib.sh
6242                 ;;
6243         (openbsd[[2-9]].*|mirbsd*)
6244                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
6245                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
6246                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6247                 fi
6248                 if test "$cf_cv_enable_rpath" = yes ; then
6249                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6250                 fi
6251                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
6252                 CF_SHARED_SONAME
6253                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
6254                 ;;
6255         (nto-qnx*|openbsd*|freebsd[[12]].*)
6256                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
6257                 MK_SHARED_LIB='${LD} ${LDFLAGS} -Bshareable -o $[@]'
6258                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6259                 ;;
6260         (dragonfly*|freebsd*)
6261                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
6262                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
6263                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
6264                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
6265                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6266                 fi
6267                 CF_SHARED_SONAME
6268                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
6269                 ;;
6270         (netbsd*)
6271                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
6272                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
6273                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
6274                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6275                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6276                         if test "$cf_cv_shlib_version" = auto; then
6277                         if test -f /usr/libexec/ld.elf_so; then
6278                                 cf_cv_shlib_version=abi
6279                         else
6280                                 cf_cv_shlib_version=rel
6281                         fi
6282                         fi
6283                         CF_SHARED_SONAME
6284                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
6285                 else
6286                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -Wl,-shared -Wl,-Bshareable -o $[@]'
6287                 fi
6288                 ;;
6289         (osf*|mls+*)
6290                 # tested with OSF/1 V3.2 and 'cc'
6291                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
6292                 # link with shared libs).
6293                 MK_SHARED_LIB='${LD} ${LDFLAGS} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
6294                 case $host_os in
6295                 (osf4*)
6296                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
6297                         ;;
6298                 esac
6299                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
6300                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
6301                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
6302                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6303                 fi
6304                 cf_cv_rm_so_locs=yes
6305                 ;;
6306         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
6307                 # tested with osr5.0.5
6308                 if test "$GCC" != yes; then
6309                         CC_SHARED_OPTS='-belf -KPIC'
6310                 fi
6311                 MK_SHARED_LIB='${LD} ${LDFLAGS} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
6312                 if test "$cf_cv_enable_rpath" = yes ; then
6313                         # only way is to set LD_RUN_PATH but no switch for it
6314                         RUN_PATH=$libdir
6315                 fi
6316                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6317                 LINK_PROGS='LD_RUN_PATH=${libdir}'
6318                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
6319                 ;;
6320         (sunos4*)
6321                 # tested with SunOS 4.1.1 and gcc 2.7.0
6322                 if test "$GCC" != yes; then
6323                         CC_SHARED_OPTS='-KPIC'
6324                 fi
6325                 MK_SHARED_LIB='${LD} ${LDFLAGS} -assert pure-text -o $[@]'
6326                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6327                 ;;
6328         (solaris2*)
6329                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
6330                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
6331                 if test "$DFT_LWR_MODEL" = "shared" ; then
6332                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
6333                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6334                 fi
6335                 if test "$cf_cv_enable_rpath" = yes ; then
6336                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
6337                 fi
6338                 CF_SHARED_SONAME
6339                 if test "$GCC" != yes; then
6340                         cf_save_CFLAGS="$CFLAGS"
6341                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
6342                         do
6343                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
6344                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
6345                         done
6346                         CFLAGS="$cf_save_CFLAGS"
6347                         CC_SHARED_OPTS=$cf_shared_opts
6348                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
6349                 else
6350                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
6351                 fi
6352                 ;;
6353         (sysv5uw7*|unix_sv*)
6354                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
6355                 if test "$GCC" != yes; then
6356                         CC_SHARED_OPTS='-KPIC'
6357                 fi
6358                 MK_SHARED_LIB='${LD} ${LDFLAGS} -d y -G -o [$]@'
6359                 ;;
6360         (*)
6361                 CC_SHARED_OPTS='unknown'
6362                 MK_SHARED_LIB='echo unknown'
6363                 ;;
6364         esac
6365
6366         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
6367         case "$cf_cv_shlib_version" in
6368         (rel|abi)
6369                 case "$MK_SHARED_LIB" in
6370                 (*'-o $[@]')
6371                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
6372                         ;;
6373                 (*)
6374                         AC_MSG_WARN(ignored --with-shlib-version)
6375                         ;;
6376                 esac
6377                 ;;
6378         esac
6379
6380         if test -n "$cf_try_cflags"
6381         then
6382 cat > conftest.$ac_ext <<EOF
6383 #line __oline__ "${as_me:-configure}"
6384 #include <stdio.h>
6385 int main(int argc, char *argv[[]])
6386 {
6387         printf("hello\n");
6388         return (argv[[argc-1]] == 0) ;
6389 }
6390 EOF
6391                 cf_save_CFLAGS="$CFLAGS"
6392                 for cf_opt in $cf_try_cflags
6393                 do
6394                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
6395                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
6396                         if AC_TRY_EVAL(ac_compile); then
6397                                 AC_MSG_RESULT(yes)
6398                                 cf_save_CFLAGS="$CFLAGS"
6399                         else
6400                                 AC_MSG_RESULT(no)
6401                         fi
6402                 done
6403                 CFLAGS="$cf_save_CFLAGS"
6404         fi
6405
6406
6407         # RPATH_LIST is a colon-separated list of directories
6408         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
6409         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
6410
6411         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
6412
6413         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
6414         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
6415
6416         AC_SUBST(CC_SHARED_OPTS)
6417         AC_SUBST(LD_RPATH_OPT)
6418         AC_SUBST(LD_SHARED_OPTS)
6419         AC_SUBST(MK_SHARED_LIB)
6420         AC_SUBST(RM_SHARED_OPTS)
6421
6422         AC_SUBST(LINK_PROGS)
6423         AC_SUBST(LINK_TESTS)
6424
6425         AC_SUBST(EXTRA_LDFLAGS)
6426         AC_SUBST(LOCAL_LDFLAGS)
6427         AC_SUBST(LOCAL_LDFLAGS2)
6428
6429         AC_SUBST(INSTALL_LIB)
6430         AC_SUBST(RPATH_LIST)
6431 ])dnl
6432 dnl ---------------------------------------------------------------------------
6433 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
6434 dnl ----------------
6435 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
6436 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
6437 dnl option.
6438 dnl
6439 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
6440 dnl If missing, use "rel".
6441 define([CF_SHARED_SONAME],
6442 [
6443         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
6444         if test "$cf_cv_shlib_version" = rel; then
6445                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
6446         else
6447                 cf_cv_shared_soname='`basename $[@]`'
6448         fi
6449 ])
6450 dnl ---------------------------------------------------------------------------
6451 dnl CF_SIGWINCH version: 1 updated: 2006/04/02 16:41:09
6452 dnl -----------
6453 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
6454 dnl programs need this test).
6455 dnl
6456 dnl This is really a MacOS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
6457 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
6458 dnl winsize declaration is left alone - we may revisit this if Apple choose to
6459 dnl break that part of the interface as well.
6460 AC_DEFUN([CF_SIGWINCH],
6461 [
6462 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
6463         AC_TRY_COMPILE([
6464 #include <sys/types.h>
6465 #include <sys/signal.h>
6466 ],[int x = SIGWINCH],
6467         [cf_cv_define_sigwinch=yes],
6468         [AC_TRY_COMPILE([
6469 #undef _XOPEN_SOURCE
6470 #undef _POSIX_SOURCE
6471 #undef _POSIX_C_SOURCE
6472 #include <sys/types.h>
6473 #include <sys/signal.h>
6474 ],[int x = SIGWINCH],
6475         [cf_cv_define_sigwinch=maybe],
6476         [cf_cv_define_sigwinch=no])
6477 ])
6478 ])
6479
6480 if test "$cf_cv_define_sigwinch" = maybe ; then
6481 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
6482 cf_cv_fixup_sigwinch=unknown
6483 cf_sigwinch=32
6484 while test $cf_sigwinch != 1
6485 do
6486         AC_TRY_COMPILE([
6487 #undef _XOPEN_SOURCE
6488 #undef _POSIX_SOURCE
6489 #undef _POSIX_C_SOURCE
6490 #include <sys/types.h>
6491 #include <sys/signal.h>
6492 ],[
6493 #if SIGWINCH != $cf_sigwinch
6494 make an error
6495 #endif
6496 int x = SIGWINCH],
6497         [cf_cv_fixup_sigwinch=$cf_sigwinch
6498          break])
6499
6500 cf_sigwinch=`expr $cf_sigwinch - 1`
6501 done
6502 ])
6503
6504         if test "$cf_cv_fixup_sigwinch" != unknown ; then
6505                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
6506         fi
6507 fi
6508 ])dnl
6509 dnl ---------------------------------------------------------------------------
6510 dnl CF_SIG_ATOMIC_T version: 3 updated: 2012/10/04 20:12:20
6511 dnl ---------------
6512 dnl signal handler, but there are some gcc depedencies in that recommendation.
6513 dnl Try anyway.
6514 AC_DEFUN([CF_SIG_ATOMIC_T],
6515 [
6516 AC_MSG_CHECKING(for signal global datatype)
6517 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
6518         for cf_type in \
6519                 "volatile sig_atomic_t" \
6520                 "sig_atomic_t" \
6521                 "int"
6522         do
6523         AC_TRY_COMPILE([
6524 #include <sys/types.h>
6525 #include <signal.h>
6526 #include <stdio.h>
6527
6528 extern $cf_type x;
6529 $cf_type x;
6530 static void handler(int sig)
6531 {
6532         x = 5;
6533 }],
6534                 [signal(SIGINT, handler);
6535                  x = 1],
6536                 [cf_cv_sig_atomic_t=$cf_type],
6537                 [cf_cv_sig_atomic_t=no])
6538                 test "$cf_cv_sig_atomic_t" != no && break
6539         done
6540         ])
6541 AC_MSG_RESULT($cf_cv_sig_atomic_t)
6542 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
6543 ])dnl
6544 dnl ---------------------------------------------------------------------------
6545 dnl CF_SIZECHANGE version: 14 updated: 2018/06/20 20:23:13
6546 dnl -------------
6547 dnl Check for definitions & structures needed for window size-changing
6548 dnl
6549 dnl https://stackoverflow.com/questions/18878141/difference-between-structures-ttysize-and-winsize/50769952#50769952
6550 AC_DEFUN([CF_SIZECHANGE],
6551 [
6552 AC_REQUIRE([CF_STRUCT_TERMIOS])
6553 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
6554         cf_cv_sizechange=unknown
6555         cf_save_CPPFLAGS="$CPPFLAGS"
6556
6557 for cf_opts in "" "NEED_PTEM_H"
6558 do
6559
6560         CPPFLAGS="$cf_save_CPPFLAGS"
6561         if test -n "$cf_opts"
6562         then
6563                 CF_APPEND_TEXT(CPPFLAGS,-D$cf_opts)
6564         fi
6565         AC_TRY_COMPILE([#include <sys/types.h>
6566 #ifdef HAVE_TERMIOS_H
6567 #include <termios.h>
6568 #else
6569 #ifdef HAVE_TERMIO_H
6570 #include <termio.h>
6571 #endif
6572 #endif
6573
6574 #ifdef NEED_PTEM_H
6575 /* This is a workaround for SCO:  they neglected to define struct winsize in
6576  * termios.h -- it's only in termio.h and ptem.h
6577  */
6578 #include <sys/stream.h>
6579 #include <sys/ptem.h>
6580 #endif
6581
6582 #ifdef HAVE_SYS_IOCTL_H
6583 #include <sys/ioctl.h>
6584 #endif
6585 ],[
6586 #ifdef TIOCGSIZE
6587         struct ttysize win;     /* SunOS 3.0... */
6588         int y = win.ts_lines;
6589         int x = win.ts_cols;
6590 #else
6591 #ifdef TIOCGWINSZ
6592         struct winsize win;     /* everything else */
6593         int y = win.ws_row;
6594         int x = win.ws_col;
6595 #else
6596         no TIOCGSIZE or TIOCGWINSZ
6597 #endif /* TIOCGWINSZ */
6598 #endif /* TIOCGSIZE */
6599         ],
6600         [cf_cv_sizechange=yes],
6601         [cf_cv_sizechange=no])
6602
6603         CPPFLAGS="$cf_save_CPPFLAGS"
6604         if test "$cf_cv_sizechange" = yes ; then
6605                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
6606                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
6607                 break
6608         fi
6609 done
6610 ])
6611 if test "$cf_cv_sizechange" != no ; then
6612         AC_DEFINE(HAVE_SIZECHANGE,1,[Define to 1 if sizechange declarations are provided])
6613         case $cf_cv_sizechange in
6614         (NEED*)
6615                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
6616                 ;;
6617         esac
6618 fi
6619 ])dnl
6620 dnl ---------------------------------------------------------------------------
6621 dnl CF_SRC_MODULES version: 30 updated: 2017/07/26 17:08:35
6622 dnl --------------
6623 dnl For each parameter, test if the source-directory exists, and if it contains
6624 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
6625 dnl use in CF_LIB_RULES.
6626 dnl
6627 dnl This uses the configured value to make the lists SRC_SUBDIRS and
6628 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
6629 AC_DEFUN([CF_SRC_MODULES],
6630 [
6631 AC_MSG_CHECKING(for src modules)
6632
6633 # dependencies and linker-arguments for test-programs
6634 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
6635 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
6636 if test "$DFT_LWR_MODEL" = "libtool"; then
6637         TEST_ARGS="${TEST_DEPS}"
6638         TEST_ARG2="${TEST_DEP2}"
6639 else
6640         TEST_ARGS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
6641         TEST_ARG2="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARG2"
6642 fi
6643
6644 PC_MODULES_TO_MAKE="ncurses${USE_ARG_SUFFIX}"
6645 cf_cv_src_modules=
6646 for cf_dir in $1
6647 do
6648         if test -f $srcdir/$cf_dir/modules; then
6649
6650                 # We may/may not have tack in the distribution, though the
6651                 # makefile is.
6652                 if test $cf_dir = tack ; then
6653                         if test "x$cf_with_tack" != "xyes"; then
6654                                 continue
6655                         fi
6656                 fi
6657
6658                 if test -z "$cf_cv_src_modules"; then
6659                         cf_cv_src_modules=$cf_dir
6660                 else
6661                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
6662                 fi
6663
6664                 # Make the ncurses_cfg.h file record the library interface files as
6665                 # well.  These are header files that are the same name as their
6666                 # directory.  Ncurses is the only library that does not follow
6667                 # that pattern.
6668                 if test $cf_dir = tack ; then
6669                         continue
6670                 elif test -f $srcdir/${cf_dir}/${cf_dir}.h; then
6671                         CF_UPPER(cf_have_include,$cf_dir)
6672                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
6673                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
6674                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEPS"
6675                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEP2"
6676                         if test "$DFT_LWR_MODEL" = "libtool"; then
6677                                 TEST_ARGS="${TEST_DEPS}"
6678                                 TEST_ARG2="${TEST_DEP2}"
6679                         else
6680                                 TEST_ARGS="-l${cf_dir}${USE_ARG_SUFFIX} $TEST_ARGS"
6681                                 TEST_ARG2="-l${cf_dir}${USE_ARG_SUFFIX} $TEST_ARG2"
6682                         fi
6683                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${USE_ARG_SUFFIX}"
6684                 fi
6685         fi
6686 done
6687 AC_MSG_RESULT($cf_cv_src_modules)
6688
6689 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
6690 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
6691
6692 AC_SUBST(TEST_ARGS)
6693 AC_SUBST(TEST_DEPS)
6694
6695 AC_SUBST(TEST_ARG2)
6696 AC_SUBST(TEST_DEP2)
6697
6698 SRC_SUBDIRS=
6699 if test "x$cf_with_manpages" != xno ; then
6700         SRC_SUBDIRS="$SRC_SUBDIRS man"
6701 fi
6702 SRC_SUBDIRS="$SRC_SUBDIRS include"
6703 for cf_dir in $cf_cv_src_modules
6704 do
6705         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
6706 done
6707 if test "x$cf_with_tests" != "xno" ; then
6708         SRC_SUBDIRS="$SRC_SUBDIRS test"
6709 fi
6710 # always make this, to install the ncurses-config script
6711 SRC_SUBDIRS="$SRC_SUBDIRS misc"
6712 if test "$cf_with_cxx_binding" != no; then
6713         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${USE_ARG_SUFFIX}"
6714         SRC_SUBDIRS="$SRC_SUBDIRS c++"
6715 fi
6716
6717 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
6718 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
6719
6720 AC_SUBST(PC_MODULES_TO_MAKE)
6721
6722 ADA_SUBDIRS=
6723 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f $srcdir/Ada95/Makefile.in; then
6724         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
6725         ADA_SUBDIRS="gen src"
6726         if test "x$cf_with_tests" != "xno" ; then
6727                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
6728         fi
6729 fi
6730
6731 SUB_MAKEFILES=
6732 for cf_dir in $SRC_SUBDIRS
6733 do
6734         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
6735 done
6736
6737 if test -n "$ADA_SUBDIRS"; then
6738         for cf_dir in $ADA_SUBDIRS
6739         do
6740                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
6741         done
6742         AC_SUBST(ADA_SUBDIRS)
6743 fi
6744 ])dnl
6745 dnl ---------------------------------------------------------------------------
6746 dnl CF_STDCPP_LIBRARY version: 11 updated: 2015/10/17 19:03:33
6747 dnl -----------------
6748 dnl Check for -lstdc++, which is GNU's standard C++ library.
6749 dnl If $CXXLIBS is set, add that to the libraries used for test-linking.
6750 dnl If -lstdc++ was not already added to $LIBS or $CXXLIBS, and is needed,
6751 dnl add it to $CXXLIBS.
6752 AC_DEFUN([CF_STDCPP_LIBRARY],
6753 [
6754 if test -n "$GXX" ; then
6755
6756         cf_save="$LIBS"
6757         LIBS="$LIBS $CXXLIBS"
6758         AC_MSG_CHECKING(if we already have C++ library)
6759         AC_TRY_LINK([
6760                         #include <iostream>],[
6761                         std::cout << "Hello World!" << std::endl;],
6762                 [cf_have_libstdcpp=yes],
6763                 [cf_have_libstdcpp=no])
6764         AC_MSG_RESULT($cf_have_libstdcpp)
6765         LIBS="$cf_save"
6766
6767         if test $cf_have_libstdcpp != yes
6768         then
6769                 case $cf_cv_system_name in
6770                 (os2*)
6771                         if test -z "`g++ -dM -E - < /dev/null | grep __KLIBC__`"; then
6772                                 cf_stdcpp_libname=stdcpp
6773                         else
6774                                 cf_stdcpp_libname=stdc++
6775                         fi
6776                         ;;
6777                 (*)
6778                         cf_stdcpp_libname=stdc++
6779                         ;;
6780                 esac
6781
6782                 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
6783                         cf_save="$LIBS"
6784                         LIBS="$LIBS $CXXLIBS"
6785                         CF_ADD_LIB($cf_stdcpp_libname)
6786                 AC_TRY_LINK([
6787                                 #include <iostream>],[
6788                                 std::cout << "Hello World!" << std::endl;],
6789                         [cf_cv_libstdcpp=yes],
6790                         [cf_cv_libstdcpp=no])
6791                         LIBS="$cf_save"
6792                 ])
6793                 test "$cf_cv_libstdcpp" = yes && { CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS) }
6794         fi
6795 fi
6796 ])dnl
6797 dnl ---------------------------------------------------------------------------
6798 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
6799 dnl --------------
6800 dnl     Remove "-g" option from the compiler options
6801 AC_DEFUN([CF_STRIP_G_OPT],
6802 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
6803 dnl ---------------------------------------------------------------------------
6804 dnl CF_STRUCT_SIGACTION version: 5 updated: 2012/10/06 17:56:13
6805 dnl -------------------
6806 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
6807 dnl do this if we've found the sigaction function.
6808 AC_DEFUN([CF_STRUCT_SIGACTION],[
6809 AC_REQUIRE([CF_XOPEN_SOURCE])
6810
6811 if test "$ac_cv_func_sigaction" = yes; then
6812 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
6813 AC_TRY_COMPILE([
6814 #include <sys/types.h>
6815 #include <signal.h>],
6816         [struct sigaction act],
6817         [sigact_bad=no],
6818         [
6819 AC_TRY_COMPILE([
6820 #define _POSIX_SOURCE
6821 #include <sys/types.h>
6822 #include <signal.h>],
6823         [struct sigaction act],
6824         [sigact_bad=yes
6825          AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE])],
6826          [sigact_bad=unknown])])
6827 AC_MSG_RESULT($sigact_bad)
6828 fi
6829 ])dnl
6830 dnl ---------------------------------------------------------------------------
6831 dnl CF_STRUCT_TERMIOS version: 9 updated: 2018/06/08 21:57:23
6832 dnl -----------------
6833 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
6834 AC_DEFUN([CF_STRUCT_TERMIOS],[
6835 AC_REQUIRE([CF_XOPEN_SOURCE])
6836
6837 AC_CHECK_HEADERS( \
6838 termio.h \
6839 termios.h \
6840 unistd.h \
6841 sys/ioctl.h \
6842 sys/termio.h \
6843 )
6844
6845 if test "$ac_cv_header_termios_h" = yes ; then
6846         case "$CFLAGS $CPPFLAGS" in
6847         (*-D_POSIX_SOURCE*)
6848                 termios_bad=dunno ;;
6849         (*)     termios_bad=maybe ;;
6850         esac
6851         if test "$termios_bad" = maybe ; then
6852         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
6853         AC_TRY_COMPILE([#include <termios.h>],
6854                 [struct termios foo; int x = foo.c_iflag],
6855                 termios_bad=no, [
6856                 AC_TRY_COMPILE([
6857 #define _POSIX_SOURCE
6858 #include <termios.h>],
6859                         [struct termios foo; int x = foo.c_iflag],
6860                         termios_bad=unknown,
6861                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE]))
6862                         ])
6863         AC_MSG_RESULT($termios_bad)
6864         fi
6865 fi
6866 ])dnl
6867 dnl ---------------------------------------------------------------------------
6868 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
6869 dnl --------------
6870 dnl Construct a search-list for a nonstandard header/lib-file
6871 dnl     $1 = the variable to return as result
6872 dnl     $2 = the package name
6873 dnl     $3 = the subdirectory, e.g., bin, include or lib
6874 AC_DEFUN([CF_SUBDIR_PATH],
6875 [
6876 $1=
6877
6878 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
6879
6880 for cf_subdir_prefix in \
6881         /usr \
6882         /usr/local \
6883         /usr/pkg \
6884         /opt \
6885         /opt/local \
6886         [$]HOME
6887 do
6888         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
6889 done
6890 ])dnl
6891 dnl ---------------------------------------------------------------------------
6892 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
6893 dnl -----------
6894 dnl     Shorthand macro for substituting things that the user may override
6895 dnl     with an environment variable.
6896 dnl
6897 dnl     $1 = condition to pass to "test"
6898 dnl     $2 = environment variable
6899 dnl     $3 = value if the test succeeds
6900 dnl     $4 = value if the test fails
6901 AC_DEFUN([CF_SUBST_IF],
6902 [
6903 if test $1 ; then
6904         $2=$3
6905 ifelse($4,,,[else
6906         $2=$4])
6907 fi
6908 AC_SUBST($2)
6909 ])dnl
6910 dnl ---------------------------------------------------------------------------
6911 dnl CF_SUBST_NCURSES_VERSION version: 8 updated: 2006/09/16 11:40:59
6912 dnl ------------------------
6913 dnl Get the version-number for use in shared-library naming, etc.
6914 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
6915 [
6916 AC_REQUIRE([CF_PROG_EGREP])
6917 NCURSES_MAJOR="`$ac_cv_prog_egrep '^NCURSES_MAJOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6918 NCURSES_MINOR="`$ac_cv_prog_egrep '^NCURSES_MINOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6919 NCURSES_PATCH="`$ac_cv_prog_egrep '^NCURSES_PATCH[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6920 cf_cv_abi_version=${NCURSES_MAJOR}
6921 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
6922 dnl Show the computed version, for logging
6923 cf_cv_timestamp=`date`
6924 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
6925 dnl We need these values in the generated headers
6926 AC_SUBST(NCURSES_MAJOR)
6927 AC_SUBST(NCURSES_MINOR)
6928 AC_SUBST(NCURSES_PATCH)
6929 dnl We need these values in the generated makefiles
6930 AC_SUBST(cf_cv_rel_version)
6931 AC_SUBST(cf_cv_abi_version)
6932 AC_SUBST(cf_cv_builtin_bool)
6933 AC_SUBST(cf_cv_header_stdbool_h)
6934 AC_SUBST(cf_cv_type_of_bool)dnl
6935 ])dnl
6936 dnl ---------------------------------------------------------------------------
6937 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
6938 dnl ------------------
6939 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
6940 dnl older SCO configurations.
6941 AC_DEFUN([CF_SYS_TIME_SELECT],
6942 [
6943 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
6944 AC_CACHE_VAL(cf_cv_sys_time_select,[
6945 AC_TRY_COMPILE([
6946 #include <sys/types.h>
6947 #ifdef HAVE_SYS_TIME_H
6948 #include <sys/time.h>
6949 #endif
6950 #ifdef HAVE_SYS_SELECT_H
6951 #include <sys/select.h>
6952 #endif
6953 ],[],[cf_cv_sys_time_select=yes],
6954          [cf_cv_sys_time_select=no])
6955          ])
6956 AC_MSG_RESULT($cf_cv_sys_time_select)
6957 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
6958 ])dnl
6959 dnl ---------------------------------------------------------------------------
6960 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
6961 dnl ---------------
6962 dnl Define a top_builddir symbol, for applications that need an absolute path.
6963 AC_DEFUN([CF_TOP_BUILDDIR],
6964 [
6965 top_builddir=ifelse($1,,`pwd`,$1)
6966 AC_SUBST(top_builddir)
6967 ])dnl
6968 dnl ---------------------------------------------------------------------------
6969 dnl CF_TRY_PKG_CONFIG version: 5 updated: 2013/07/06 21:27:06
6970 dnl -----------------
6971 dnl This is a simple wrapper to use for pkg-config, for libraries which may be
6972 dnl available in that form.
6973 dnl
6974 dnl $1 = package name
6975 dnl $2 = extra logic to use, if any, after updating CFLAGS and LIBS
6976 dnl $3 = logic to use if pkg-config does not have the package
6977 AC_DEFUN([CF_TRY_PKG_CONFIG],[
6978 AC_REQUIRE([CF_PKG_CONFIG])
6979
6980 if test "$PKG_CONFIG" != none && "$PKG_CONFIG" --exists $1; then
6981         CF_VERBOSE(found package $1)
6982         cf_pkgconfig_incs="`$PKG_CONFIG --cflags $1 2>/dev/null`"
6983         cf_pkgconfig_libs="`$PKG_CONFIG --libs   $1 2>/dev/null`"
6984         CF_VERBOSE(package $1 CFLAGS: $cf_pkgconfig_incs)
6985         CF_VERBOSE(package $1 LIBS: $cf_pkgconfig_libs)
6986         CF_ADD_CFLAGS($cf_pkgconfig_incs)
6987         CF_ADD_LIBS($cf_pkgconfig_libs)
6988         ifelse([$2],,:,[$2])
6989 else
6990         cf_pkgconfig_incs=
6991         cf_pkgconfig_libs=
6992         ifelse([$3],,:,[$3])
6993 fi
6994 ])
6995 dnl ---------------------------------------------------------------------------
6996 dnl CF_TRY_XOPEN_SOURCE version: 2 updated: 2018/06/20 20:23:13
6997 dnl -------------------
6998 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
6999 dnl can define it successfully.
7000 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
7001 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
7002         AC_TRY_COMPILE([
7003 #include <stdlib.h>
7004 #include <string.h>
7005 #include <sys/types.h>
7006 ],[
7007 #ifndef _XOPEN_SOURCE
7008 make an error
7009 #endif],
7010         [cf_cv_xopen_source=no],
7011         [cf_save="$CPPFLAGS"
7012          CF_APPEND_TEXT(CPPFLAGS,-D_XOPEN_SOURCE=$cf_XOPEN_SOURCE)
7013          AC_TRY_COMPILE([
7014 #include <stdlib.h>
7015 #include <string.h>
7016 #include <sys/types.h>
7017 ],[
7018 #ifdef _XOPEN_SOURCE
7019 make an error
7020 #endif],
7021         [cf_cv_xopen_source=no],
7022         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
7023         CPPFLAGS="$cf_save"
7024         ])
7025 ])
7026
7027 if test "$cf_cv_xopen_source" != no ; then
7028         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
7029         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
7030         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
7031         CF_ADD_CFLAGS($cf_temp_xopen_source)
7032 fi
7033 ])
7034 dnl ---------------------------------------------------------------------------
7035 dnl CF_TYPEOF_CHTYPE version: 10 updated: 2017/01/21 11:06:25
7036 dnl ----------------
7037 dnl Determine the type we should use for chtype (and attr_t, which is treated
7038 dnl as the same thing).  We want around 32 bits, so on most machines want a
7039 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
7040 dnl wide characters, we have to have a type compatible with that, as well.
7041 AC_DEFUN([CF_TYPEOF_CHTYPE],
7042 [
7043 AC_MSG_CHECKING([for type of chtype])
7044 AC_CACHE_VAL(cf_cv_typeof_chtype,[
7045                 AC_TRY_RUN([
7046 #define WANT_BITS 31
7047 #include <stdio.h>
7048 int main(void)
7049 {
7050         FILE *fp = fopen("cf_test.out", "w");
7051         if (fp != 0) {
7052                 char *result = "long";
7053                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
7054                         int n;
7055                         unsigned int x, y;
7056                         for (n = 0; n < WANT_BITS; n++) {
7057                                 x = (1 << n);
7058                                 y = (x >> n);
7059                                 if (y != 1 || x == 0) {
7060                                         x = 0;
7061                                         break;
7062                                 }
7063                         }
7064                         /*
7065                          * If x is nonzero, an int is big enough for the bits
7066                          * that we want.
7067                          */
7068                         result = (x != 0) ? "int" : "long";
7069                 }
7070                 fputs(result, fp);
7071                 fclose(fp);
7072         }
7073         ${cf_cv_main_return:-return}(0);
7074 }
7075                 ],
7076                 [cf_cv_typeof_chtype=`cat cf_test.out`],
7077                 [cf_cv_typeof_chtype=long],
7078                 [cf_cv_typeof_chtype=long])
7079                 rm -f cf_test.out
7080         ])
7081 AC_MSG_RESULT($cf_cv_typeof_chtype)
7082
7083 AC_SUBST(cf_cv_typeof_chtype)
7084 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype,[Define to actual type if needed for chtype])
7085 ])dnl
7086 dnl ---------------------------------------------------------------------------
7087 dnl CF_TYPE_SIGACTION version: 4 updated: 2012/10/06 17:56:13
7088 dnl -----------------
7089 dnl
7090 AC_DEFUN([CF_TYPE_SIGACTION],
7091 [
7092 AC_MSG_CHECKING([for type sigaction_t])
7093 AC_CACHE_VAL(cf_cv_type_sigaction,[
7094         AC_TRY_COMPILE([
7095 #include <signal.h>],
7096                 [sigaction_t x],
7097                 [cf_cv_type_sigaction=yes],
7098                 [cf_cv_type_sigaction=no])])
7099 AC_MSG_RESULT($cf_cv_type_sigaction)
7100 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION,1,[Define to 1 if we have the sigaction_t type])
7101 ])dnl
7102 dnl ---------------------------------------------------------------------------
7103 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
7104 dnl --------------------
7105 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
7106 dnl won't, but they're still there.
7107 AC_DEFUN([CF_UNSIGNED_LITERALS],
7108 [
7109 AC_MSG_CHECKING([if unsigned literals are legal])
7110 AC_CACHE_VAL(cf_cv_unsigned_literals,[
7111         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
7112                 [cf_cv_unsigned_literals=yes],
7113                 [cf_cv_unsigned_literals=no])
7114         ])
7115 AC_MSG_RESULT($cf_cv_unsigned_literals)
7116 ])dnl
7117 dnl ---------------------------------------------------------------------------
7118 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
7119 dnl --------
7120 dnl Make an uppercase version of a variable
7121 dnl $1=uppercase($2)
7122 AC_DEFUN([CF_UPPER],
7123 [
7124 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
7125 ])dnl
7126 dnl ---------------------------------------------------------------------------
7127 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
7128 dnl -----------
7129 dnl Check for multibyte support, and if not found, utf8 compatibility library
7130 AC_DEFUN([CF_UTF8_LIB],
7131 [
7132 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
7133         cf_save_LIBS="$LIBS"
7134         AC_TRY_LINK([
7135 #include <stdlib.h>],[putwc(0,0);],
7136         [cf_cv_utf8_lib=yes],
7137         [CF_FIND_LINKAGE([
7138 #include <libutf8.h>],[putwc(0,0);],utf8,
7139                 [cf_cv_utf8_lib=add-on],
7140                 [cf_cv_utf8_lib=no])
7141 ])])
7142
7143 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
7144 # ncurses/ncursesw:
7145 if test "$cf_cv_utf8_lib" = "add-on" ; then
7146         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
7147         CF_ADD_INCDIR($cf_cv_header_path_utf8)
7148         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
7149         CF_ADD_LIBS($cf_cv_library_file_utf8)
7150 fi
7151 ])dnl
7152 dnl ---------------------------------------------------------------------------
7153 dnl CF_VA_COPY version: 3 updated: 2012/10/06 11:17:15
7154 dnl ----------
7155 dnl check for va_copy, part of stdarg.h
7156 dnl Also, workaround for glibc's __va_copy, by checking for both.
7157 AC_DEFUN([CF_VA_COPY],[
7158 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
7159 AC_TRY_LINK([
7160 #include <stdarg.h>
7161 ],[
7162         static va_list dst;
7163         static va_list src;
7164         va_copy(dst, src)],
7165         cf_cv_have_va_copy=yes,
7166         cf_cv_have_va_copy=no)])
7167
7168 test "$cf_cv_have_va_copy" = yes && AC_DEFINE(HAVE_VA_COPY,1,[Define to 1 if we have va_copy])
7169
7170 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
7171 AC_TRY_LINK([
7172 #include <stdarg.h>
7173 ],[
7174         static va_list dst;
7175         static va_list src;
7176         __va_copy(dst, src)],
7177         cf_cv_have___va_copy=yes,
7178         cf_cv_have___va_copy=no)])
7179
7180 test "$cf_cv_have___va_copy" = yes && AC_DEFINE(HAVE___VA_COPY,1,[Define to 1 if we have __va_copy])
7181 ])
7182 dnl ---------------------------------------------------------------------------
7183 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
7184 dnl ----------
7185 dnl Use AC_VERBOSE w/o the warnings
7186 AC_DEFUN([CF_VERBOSE],
7187 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
7188 CF_MSG_LOG([$1])
7189 ])dnl
7190 dnl ---------------------------------------------------------------------------
7191 dnl CF_VERSION_INFO version: 7 updated: 2015/04/17 21:13:04
7192 dnl ---------------
7193 dnl Define several useful symbols derived from the VERSION file.  A separate
7194 dnl file is preferred to embedding the version numbers in various scripts.
7195 dnl (automake is a textbook-example of why the latter is a bad idea, but there
7196 dnl are others).
7197 dnl
7198 dnl The file contents are:
7199 dnl     libtool-version release-version patch-version
7200 dnl or
7201 dnl     release-version
7202 dnl where
7203 dnl     libtool-version (see ?) consists of 3 integers separated by '.'
7204 dnl     release-version consists of a major version and minor version
7205 dnl             separated by '.', optionally followed by a patch-version
7206 dnl             separated by '-'.  The minor version need not be an
7207 dnl             integer (but it is preferred).
7208 dnl     patch-version is an integer in the form yyyymmdd, so ifdef's and
7209 dnl             scripts can easily compare versions.
7210 dnl
7211 dnl If libtool is used, the first form is required, since CF_WITH_LIBTOOL
7212 dnl simply extracts the first field using 'cut -f1'.
7213 dnl
7214 dnl Optional parameters:
7215 dnl $1 = internal name for package
7216 dnl $2 = external name for package
7217 AC_DEFUN([CF_VERSION_INFO],
7218 [
7219 if test -f $srcdir/VERSION ; then
7220         AC_MSG_CHECKING(for package version)
7221
7222         # if there are not enough fields, cut returns the last one...
7223         cf_field1=`sed -e '2,$d' $srcdir/VERSION|cut -f1`
7224         cf_field2=`sed -e '2,$d' $srcdir/VERSION|cut -f2`
7225         cf_field3=`sed -e '2,$d' $srcdir/VERSION|cut -f3`
7226
7227         # this is how CF_BUNDLED_INTL uses $VERSION:
7228         VERSION="$cf_field1"
7229
7230         VERSION_MAJOR=`echo "$cf_field2" | sed -e 's/\..*//'`
7231         test -z "$VERSION_MAJOR" && AC_MSG_ERROR(missing major-version)
7232
7233         VERSION_MINOR=`echo "$cf_field2" | sed -e 's/^[[^.]]*\.//' -e 's/-.*//'`
7234         test -z "$VERSION_MINOR" && AC_MSG_ERROR(missing minor-version)
7235
7236         AC_MSG_RESULT(${VERSION_MAJOR}.${VERSION_MINOR})
7237
7238         AC_MSG_CHECKING(for package patch date)
7239         VERSION_PATCH=`echo "$cf_field3" | sed -e 's/^[[^-]]*-//'`
7240         case .$VERSION_PATCH in
7241         (.)
7242                 AC_MSG_ERROR(missing patch-date $VERSION_PATCH)
7243                 ;;
7244         (.[[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]])
7245                 ;;
7246         (*)
7247                 AC_MSG_ERROR(illegal patch-date $VERSION_PATCH)
7248                 ;;
7249         esac
7250         AC_MSG_RESULT($VERSION_PATCH)
7251 else
7252         AC_MSG_ERROR(did not find $srcdir/VERSION)
7253 fi
7254
7255 # show the actual data that we have for versions:
7256 CF_VERBOSE(ABI VERSION $VERSION)
7257 CF_VERBOSE(VERSION_MAJOR $VERSION_MAJOR)
7258 CF_VERBOSE(VERSION_MINOR $VERSION_MINOR)
7259 CF_VERBOSE(VERSION_PATCH $VERSION_PATCH)
7260
7261 AC_SUBST(VERSION)
7262 AC_SUBST(VERSION_MAJOR)
7263 AC_SUBST(VERSION_MINOR)
7264 AC_SUBST(VERSION_PATCH)
7265
7266 dnl if a package name is given, define its corresponding version info.  We
7267 dnl need the package name to ensure that the defined symbols are unique.
7268 ifelse($1,,,[
7269         cf_PACKAGE=$1
7270         PACKAGE=ifelse($2,,$1,$2)
7271         AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",[Define to the package-name])
7272         AC_SUBST(PACKAGE)
7273         CF_UPPER(cf_PACKAGE,$cf_PACKAGE)
7274         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_VERSION,"${VERSION_MAJOR}.${VERSION_MINOR}")
7275         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_PATCHDATE,${VERSION_PATCH})
7276 ])
7277 ])dnl
7278 dnl ---------------------------------------------------------------------------
7279 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
7280 dnl -------------
7281 dnl Check if type wide-character type $1 is declared, and if so, which header
7282 dnl file is needed.  The second parameter is used to set a shell variable when
7283 dnl the type is not found.  The first parameter sets a shell variable for the
7284 dnl opposite sense.
7285 AC_DEFUN([CF_WCHAR_TYPE],
7286 [
7287 # This is needed on Tru64 5.0 to declare $1
7288 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
7289 AC_TRY_COMPILE([
7290 #include <stdlib.h>
7291 #include <stdarg.h>
7292 #include <stdio.h>
7293 #ifdef HAVE_LIBUTF8_H
7294 #include <libutf8.h>
7295 #endif],
7296         [$1 state],
7297         [cf_cv_$1=no],
7298         [AC_TRY_COMPILE([
7299 #include <stdlib.h>
7300 #include <stdarg.h>
7301 #include <stdio.h>
7302 #include <wchar.h>
7303 #ifdef HAVE_LIBUTF8_H
7304 #include <libutf8.h>
7305 #endif],
7306         [$1 value],
7307         [cf_cv_$1=yes],
7308         [cf_cv_$1=unknown])])])
7309
7310 if test "$cf_cv_$1" = yes ; then
7311         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
7312         NEED_WCHAR_H=1
7313 fi
7314
7315 ifelse([$2],,,[
7316 # if we do not find $1 in either place, use substitution to provide a fallback.
7317 if test "$cf_cv_$1" = unknown ; then
7318         $2=1
7319 fi
7320 ])
7321 ifelse($3,,,[
7322 # if we find $1 in either place, use substitution to provide a fallback.
7323 if test "$cf_cv_$1" != unknown ; then
7324         $3=1
7325 fi
7326 ])
7327 ])dnl
7328 dnl ---------------------------------------------------------------------------
7329 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
7330 dnl ---------------
7331 dnl Check for compiler-support for weak symbols.
7332 dnl This works with "recent" gcc.
7333 AC_DEFUN([CF_WEAK_SYMBOLS],[
7334 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
7335
7336 AC_TRY_COMPILE([
7337 #include <stdio.h>],
7338 [
7339 #if defined(__GNUC__)
7340 #  if defined __USE_ISOC99
7341 #    define _cat_pragma(exp)    _Pragma(#exp)
7342 #    define _weak_pragma(exp)   _cat_pragma(weak name)
7343 #  else
7344 #    define _weak_pragma(exp)
7345 #  endif
7346 #  define _declare(name)        __extension__ extern __typeof__(name) name
7347 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
7348 #endif
7349
7350 weak_symbol(fopen);
7351 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
7352 ])
7353 ])dnl
7354 dnl ---------------------------------------------------------------------------
7355 dnl CF_WITH_ABI_VERSION version: 3 updated: 2015/06/06 16:10:11
7356 dnl -------------------
7357 dnl Allow library's ABI to be overridden.  Generally this happens when a
7358 dnl packager has incremented the ABI past that used in the original package,
7359 dnl and wishes to keep doing this.
7360 dnl
7361 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
7362 dnl symbol.
7363 AC_DEFUN([CF_WITH_ABI_VERSION],[
7364 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
7365 AC_ARG_WITH(abi-version,
7366 [  --with-abi-version=XXX  override derived ABI version],[
7367         if test "x$cf_cv_abi_version" != "x$withval"
7368         then
7369                 AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
7370                 case $cf_cv_rel_version in
7371                 (5.*)
7372                         cf_cv_rel_version=$withval.0
7373                         ;;
7374                 (6.*)
7375                         cf_cv_rel_version=$withval.9    # FIXME: should be 10 as of 6.0 release
7376                         ;;
7377                 esac
7378         fi
7379         cf_cv_abi_version=$withval])
7380         CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
7381 ifelse($1,,,[
7382 $1_ABI=$cf_cv_abi_version
7383 ])
7384 ])dnl
7385 dnl ---------------------------------------------------------------------------
7386 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
7387 dnl --------------------
7388 dnl Command-line option to specify the Ada95 compiler.
7389 AC_DEFUN([CF_WITH_ADA_COMPILER],[
7390 AC_MSG_CHECKING(for ada-compiler)
7391 AC_ARG_WITH(ada-compiler,
7392         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
7393         [cf_ada_compiler=$withval],
7394         [cf_ada_compiler=gnatmake])
7395 AC_SUBST(cf_ada_compiler)
7396 AC_MSG_RESULT($cf_ada_compiler)
7397 ])dnl
7398 dnl ---------------------------------------------------------------------------
7399 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
7400 dnl -------------------
7401 dnl Command-line option to specify where Ada includes will install.
7402 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
7403 AC_MSG_CHECKING(for ada-include)
7404 CF_WITH_PATH(ada-include,
7405    [  --with-ada-include=DIR  Ada includes are in DIR],
7406    ADA_INCLUDE,
7407    PREFIX/share/ada/adainclude,
7408    [$]prefix/share/ada/adainclude)
7409 AC_SUBST(ADA_INCLUDE)
7410 AC_MSG_RESULT($ADA_INCLUDE)
7411 ])dnl
7412 dnl ---------------------------------------------------------------------------
7413 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
7414 dnl -------------------
7415 dnl Command-line option to specify where Ada objects will install.
7416 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
7417 AC_MSG_CHECKING(for ada-objects)
7418 CF_WITH_PATH(ada-objects,
7419    [  --with-ada-objects=DIR  Ada objects are in DIR],
7420    ADA_OBJECTS,
7421    PREFIX/lib/ada/adalib,
7422    [$]prefix/lib/ada/adalib)
7423 AC_SUBST(ADA_OBJECTS)
7424 AC_MSG_RESULT($ADA_OBJECTS)
7425 ])dnl
7426 dnl ---------------------------------------------------------------------------
7427 dnl CF_WITH_ADA_SHAREDLIB version: 5 updated: 2018/07/21 19:10:35
7428 dnl ---------------------
7429 dnl Command-line option to specify if an Ada95 shared-library should be built,
7430 dnl and optionally what its soname should be.
7431 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
7432 AC_REQUIRE([CF_GNAT_PROJECTS])
7433 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
7434 AC_ARG_WITH(ada-sharedlib,
7435         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
7436         [with_ada_sharedlib=$withval],
7437         [with_ada_sharedlib=no])
7438 AC_MSG_RESULT($with_ada_sharedlib)
7439
7440 if test "x$with_ada_sharedlib" != xno
7441 then
7442         if test "x$cf_gnat_projects" != xyes
7443         then
7444                 AC_MSG_WARN(disabling shared-library since GNAT projects are not supported)
7445                 with_ada_sharedlib=no
7446         fi
7447 fi
7448
7449 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
7450 MAKE_ADA_SHAREDLIB="#"
7451
7452 if test "x$with_ada_sharedlib" != xno
7453 then
7454         MAKE_ADA_SHAREDLIB=
7455         if test "x$with_ada_sharedlib" != xyes
7456         then
7457                 ADA_SHAREDLIB="$with_ada_sharedlib"
7458         fi
7459 fi
7460
7461 AC_SUBST(ADA_SHAREDLIB)
7462 AC_SUBST(MAKE_ADA_SHAREDLIB)
7463 ])dnl
7464 dnl ---------------------------------------------------------------------------
7465 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
7466 dnl ----------------
7467 dnl Configure-option for dbmalloc.  The optional parameter is used to override
7468 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
7469 AC_DEFUN([CF_WITH_DBMALLOC],[
7470 CF_NO_LEAKS_OPTION(dbmalloc,
7471         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
7472         [USE_DBMALLOC])
7473
7474 if test "$with_dbmalloc" = yes ; then
7475         AC_CHECK_HEADER(dbmalloc.h,
7476                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
7477 fi
7478 ])dnl
7479 dnl ---------------------------------------------------------------------------
7480 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
7481 dnl ---------------
7482 dnl Configure-option for dmalloc.  The optional parameter is used to override
7483 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
7484 AC_DEFUN([CF_WITH_DMALLOC],[
7485 CF_NO_LEAKS_OPTION(dmalloc,
7486         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
7487         [USE_DMALLOC])
7488
7489 if test "$with_dmalloc" = yes ; then
7490         AC_CHECK_HEADER(dmalloc.h,
7491                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
7492 fi
7493 ])dnl
7494 dnl ---------------------------------------------------------------------------
7495 dnl CF_WITH_EXPORT_SYMS version: 3 updated: 2014/12/20 19:16:08
7496 dnl -------------------
7497 dnl Use this with libtool to specify the list of symbols that may be exported.
7498 dnl The input file contains one symbol per line; comments work with "#".
7499 dnl
7500 dnl $1 = basename of the ".sym" file (default $PACKAGE)
7501 AC_DEFUN([CF_WITH_EXPORT_SYMS],
7502 [
7503 AC_MSG_CHECKING(if exported-symbols file should be used)
7504 AC_ARG_WITH(export-syms,
7505         [  --with-export-syms=XXX  limit exported symbols using libtool],
7506         [with_export_syms=$withval],
7507         [with_export_syms=no])
7508 if test "x$with_export_syms" = xyes
7509 then
7510         with_export_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).sym'
7511         AC_SUBST(PACKAGE)
7512 fi
7513 AC_MSG_RESULT($with_export_syms)
7514 if test "x$with_export_syms" != xno
7515 then
7516         EXPORT_SYMS="-export-symbols $with_export_syms"
7517         AC_SUBST(EXPORT_SYMS)
7518 fi
7519 ])dnl
7520 dnl ---------------------------------------------------------------------------
7521 dnl CF_WITH_GPM version: 10 updated: 2017/04/29 18:32:18
7522 dnl -----------
7523 dnl
7524 dnl The option parameter (if neither yes/no) is assumed to be the name of
7525 dnl the gpm library, e.g., for dynamic loading.
7526 AC_DEFUN([CF_WITH_GPM],
7527 [
7528 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
7529 AC_ARG_WITH(gpm,
7530         [  --with-gpm              use Alessandro Rubini's GPM library],
7531         [with_gpm=$withval],
7532         [with_gpm=maybe])
7533 AC_MSG_RESULT($with_gpm)
7534
7535 if test "$with_gpm" != no ; then
7536         AC_CHECK_HEADER(gpm.h,[
7537                 AC_DEFINE(HAVE_GPM_H,1,[Define to 1 if we have gpm.h header])
7538                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
7539                         CF_VERBOSE(assuming we really have GPM library)
7540                         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
7541                         with_gpm=yes
7542                 else
7543                         AC_CHECK_LIB(gpm,Gpm_Open,[with_gpm=yes],[
7544                                 if test "$with_gpm" = maybe; then
7545                                         AC_MSG_WARN(Cannot link with GPM library)
7546                                         with_gpm=no
7547                                 else
7548                                         AC_MSG_ERROR(Cannot link with GPM library)
7549                                 fi
7550                         ])
7551                 fi
7552         ],[
7553                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
7554                 with_gpm=no
7555         ])
7556 fi
7557 ])
7558 dnl ---------------------------------------------------------------------------
7559 dnl CF_WITH_LIBTOOL version: 35 updated: 2017/08/12 07:58:51
7560 dnl ---------------
7561 dnl Provide a configure option to incorporate libtool.  Define several useful
7562 dnl symbols for the makefile rules.
7563 dnl
7564 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
7565 dnl macros from libtool.m4 which is in the aclocal directory of automake.
7566 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
7567 dnl But that still does not work properly since the macro is expanded outside
7568 dnl the CF_WITH_LIBTOOL macro:
7569 dnl
7570 dnl     #!/bin/sh
7571 dnl     ACLOCAL=`aclocal --print-ac-dir`
7572 dnl     if test -z "$ACLOCAL" ; then
7573 dnl             echo cannot find aclocal directory
7574 dnl             exit 1
7575 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
7576 dnl             echo cannot find libtool.m4 file
7577 dnl             exit 1
7578 dnl     fi
7579 dnl
7580 dnl     LOCAL=aclocal.m4
7581 dnl     ORIG=aclocal.m4.orig
7582 dnl
7583 dnl     trap "mv $ORIG $LOCAL" 0 1 2 3 15
7584 dnl     rm -f $ORIG
7585 dnl     mv $LOCAL $ORIG
7586 dnl
7587 dnl     # sed the LIBTOOL= assignment to omit the current directory?
7588 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
7589 dnl     cat $ORIG >>$LOCAL
7590 dnl
7591 dnl     autoconf-257 $*
7592 dnl
7593 AC_DEFUN([CF_WITH_LIBTOOL],
7594 [
7595 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
7596 ifdef([AC_PROG_LIBTOOL],,[
7597 LIBTOOL=
7598 ])
7599 # common library maintenance symbols that are convenient for libtool scripts:
7600 LIB_CREATE='${AR} -cr'
7601 LIB_OBJECT='${OBJECTS}'
7602 LIB_SUFFIX=.a
7603 LIB_PREP="$RANLIB"
7604
7605 # symbols used to prop libtool up to enable it to determine what it should be
7606 # doing:
7607 LIB_CLEAN=
7608 LIB_COMPILE=
7609 LIB_LINK='${CC}'
7610 LIB_INSTALL=
7611 LIB_UNINSTALL=
7612
7613 AC_MSG_CHECKING(if you want to build libraries with libtool)
7614 AC_ARG_WITH(libtool,
7615         [  --with-libtool          generate libraries with libtool],
7616         [with_libtool=$withval],
7617         [with_libtool=no])
7618 AC_MSG_RESULT($with_libtool)
7619 if test "$with_libtool" != "no"; then
7620 ifdef([AC_PROG_LIBTOOL],[
7621         # missing_content_AC_PROG_LIBTOOL{{
7622         AC_PROG_LIBTOOL
7623         # missing_content_AC_PROG_LIBTOOL}}
7624 ],[
7625         if test "$with_libtool" != "yes" ; then
7626                 CF_PATH_SYNTAX(with_libtool)
7627                 LIBTOOL=$with_libtool
7628         else
7629                 AC_CHECK_TOOLS(LIBTOOL,[libtool glibtool],none)
7630                 CF_LIBTOOL_VERSION
7631                 if test -z "$cf_cv_libtool_version" && test "$LIBTOOL" = libtool
7632                 then
7633                         CF_FORGET_TOOL(LIBTOOL)
7634                         AC_CHECK_TOOLS(LIBTOOL,[glibtool],none)
7635                         CF_LIBTOOL_VERSION
7636                 fi
7637         fi
7638         if test -z "$LIBTOOL" ; then
7639                 AC_MSG_ERROR(Cannot find libtool)
7640         fi
7641 ])dnl
7642         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${libdir} ${LIBTOOL_VERSION} `cut -f1 ${top_srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
7643         LIB_OBJECT='${OBJECTS:.o=.lo}'
7644         LIB_SUFFIX=.la
7645         LIB_CLEAN='${LIBTOOL} --mode=clean'
7646         LIB_COMPILE='${LIBTOOL} --mode=compile'
7647         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
7648         LIB_INSTALL='${LIBTOOL} --mode=install'
7649         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
7650         LIB_PREP=:
7651
7652         CF_CHECK_LIBTOOL_VERSION
7653
7654         # special hack to add -no-undefined (which libtool should do for itself)
7655         LT_UNDEF=
7656         case "$cf_cv_system_name" in
7657         (cygwin*|msys*|mingw32*|os2*|uwin*|aix[[4-7]])
7658                 LT_UNDEF=-no-undefined
7659                 ;;
7660         esac
7661         AC_SUBST([LT_UNDEF])
7662
7663         # special hack to add --tag option for C++ compiler
7664         case $cf_cv_libtool_version in
7665         (1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*)
7666                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
7667                 LIBTOOL="$LIBTOOL --tag=CC"
7668                 ;;
7669         (*)
7670                 LIBTOOL_CXX="$LIBTOOL"
7671                 ;;
7672         esac
7673 else
7674         LIBTOOL=""
7675         LIBTOOL_CXX=""
7676 fi
7677
7678 test -z "$LIBTOOL" && ECHO_LT=
7679
7680 AC_SUBST(LIBTOOL)
7681 AC_SUBST(LIBTOOL_CXX)
7682 AC_SUBST(LIBTOOL_OPTS)
7683
7684 AC_SUBST(LIB_CREATE)
7685 AC_SUBST(LIB_OBJECT)
7686 AC_SUBST(LIB_SUFFIX)
7687 AC_SUBST(LIB_PREP)
7688
7689 AC_SUBST(LIB_CLEAN)
7690 AC_SUBST(LIB_COMPILE)
7691 AC_SUBST(LIB_LINK)
7692 AC_SUBST(LIB_INSTALL)
7693 AC_SUBST(LIB_UNINSTALL)
7694
7695 ])dnl
7696 dnl ---------------------------------------------------------------------------
7697 dnl CF_WITH_LIBTOOL_OPTS version: 4 updated: 2015/04/17 21:13:04
7698 dnl --------------------
7699 dnl Allow user to pass additional libtool options into the library creation
7700 dnl and link steps.  The main use for this is to do something like
7701 dnl     ./configure --with-libtool-opts=-static
7702 dnl to get the same behavior as automake-flavored
7703 dnl     ./configure --enable-static
7704 AC_DEFUN([CF_WITH_LIBTOOL_OPTS],[
7705 AC_MSG_CHECKING(for additional libtool options)
7706 AC_ARG_WITH(libtool-opts,
7707         [  --with-libtool-opts=XXX specify additional libtool options],
7708         [with_libtool_opts=$withval],
7709         [with_libtool_opts=no])
7710 AC_MSG_RESULT($with_libtool_opts)
7711
7712 case .$with_libtool_opts in
7713 (.yes|.no|.)
7714         ;;
7715 (*)
7716         LIBTOOL_OPTS="$LIBTOOL_OPTS $with_libtool_opts"
7717         ;;
7718 esac
7719
7720 AC_SUBST(LIBTOOL_OPTS)
7721 ])dnl
7722 dnl ---------------------------------------------------------------------------
7723 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
7724 dnl ------------------
7725 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
7726 dnl "lib" prefix, e.g., because it used the dll naming convention.
7727 dnl
7728 dnl $1 = variable to set
7729 AC_DEFUN([CF_WITH_LIB_PREFIX],
7730 [
7731 AC_MSG_CHECKING(if you want to have a library-prefix)
7732 AC_ARG_WITH(lib-prefix,
7733         [  --with-lib-prefix       override library-prefix],
7734         [with_lib_prefix=$withval],
7735         [with_lib_prefix=auto])
7736 AC_MSG_RESULT($with_lib_prefix)
7737
7738 if test $with_lib_prefix = auto
7739 then
7740         CF_LIB_PREFIX($1)
7741 elif test $with_lib_prefix = no
7742 then
7743         LIB_PREFIX=
7744 else
7745         LIB_PREFIX=$with_lib_prefix
7746 fi
7747 ])dnl
7748 dnl ---------------------------------------------------------------------------
7749 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
7750 dnl ------------
7751 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
7752 dnl defaulting to yes/no.
7753 dnl
7754 dnl $1 = option name
7755 dnl $2 = help-text
7756 dnl $3 = environment variable to set
7757 dnl $4 = default value, shown in the help-message, must be a constant
7758 dnl $5 = default value, if it's an expression & cannot be in the help-message
7759 dnl
7760 AC_DEFUN([CF_WITH_PATH],
7761 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
7762 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
7763 if ifelse([$5],,true,[test -n "$5"]) ; then
7764 CF_PATH_SYNTAX(withval)
7765 fi
7766 eval $3="$withval"
7767 AC_SUBST($3)dnl
7768 ])dnl
7769 dnl ---------------------------------------------------------------------------
7770 dnl CF_WITH_PATHLIST version: 10 updated: 2015/04/17 21:13:04
7771 dnl ----------------
7772 dnl Process an option specifying a list of colon-separated paths.
7773 dnl
7774 dnl $1 = option name
7775 dnl $2 = help-text
7776 dnl $3 = environment variable to set
7777 dnl $4 = default value, shown in the help-message, must be a constant
7778 dnl $5 = default value, if it's an expression & cannot be in the help-message
7779 dnl $6 = flag to tell if we want to define or substitute
7780 dnl
7781 AC_DEFUN([CF_WITH_PATHLIST],[
7782 AC_REQUIRE([CF_PATHSEP])
7783 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
7784 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
7785
7786 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
7787 cf_dst_path=
7788 for cf_src_path in $withval
7789 do
7790   CF_PATH_SYNTAX(cf_src_path)
7791   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}$PATH_SEPARATOR"
7792   cf_dst_path="${cf_dst_path}${cf_src_path}"
7793 done
7794 IFS="$ac_save_ifs"
7795
7796 ifelse($6,define,[
7797 # Strip single quotes from the value, e.g., when it was supplied as a literal
7798 # for $4 or $5.
7799 case $cf_dst_path in
7800 (\'*)
7801   cf_dst_path=`echo $cf_dst_path |sed -e s/\'// -e s/\'\$//`
7802   ;;
7803 esac
7804 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
7805 ])
7806
7807 # This may use the prefix/exec_prefix symbols which will only yield "NONE"
7808 # so we have to check/work around.  We do prefer the result of "eval"...
7809 eval cf_dst_eval="$cf_dst_path"
7810 case "x$cf_dst_eval" in
7811 (xNONE*)
7812         $3=$cf_dst_path
7813         ;;
7814 (*)
7815         $3="$cf_dst_eval"
7816         ;;
7817 esac
7818 AC_SUBST($3)dnl
7819
7820 ])dnl
7821 dnl ---------------------------------------------------------------------------
7822 dnl CF_WITH_PCRE2 version: 2 updated: 2018/07/14 16:47:56
7823 dnl -------------
7824 dnl Add PCRE2 (Perl-compatible regular expressions v2) to the build if it is
7825 dnl available and the user requests it.  Assume the application will otherwise
7826 dnl use the POSIX interface.
7827 dnl
7828 dnl TODO allow $withval to specify package location
7829 AC_DEFUN([CF_WITH_PCRE2],
7830 [
7831 AC_REQUIRE([CF_PKG_CONFIG])
7832
7833 AC_MSG_CHECKING(if you want to use PCRE2 for regular-expressions)
7834 AC_ARG_WITH(pcre2,
7835         [  --with-pcre2            use PCRE2 for regular-expressions])
7836 test -z "$with_pcre2" && with_pcre2=no
7837 AC_MSG_RESULT($with_pcre2)
7838
7839 if test "x$with_pcre2" != xno ; then
7840         CF_TRY_PKG_CONFIG(libpcre2,,[
7841         CF_TRY_PKG_CONFIG(libpcre,,[
7842                         AC_MSG_ERROR(Cannot find PCRE2 library)])])
7843
7844         AC_DEFINE(HAVE_LIB_PCRE2,1,[Define to 1 if we can/should compile with the PCRE2 library])
7845
7846         # if pkgconfig gave no results, look for the libraries directly
7847         case $LIBS in
7848         (*pcre2-posix*|*pcreposix*)
7849                 ;;
7850         (*)
7851                 AC_CHECK_LIB(pcre2-posix,regcomp,[
7852                         CF_ADD_LIB(pcre2-posix)],
7853                         [AC_CHECK_LIB(pcreposix,regcomp,[
7854                          CF_ADD_LIB(pcreposix)
7855                         ],[AC_MSG_ERROR(Cannot find PCRE2 POSIX library)])])
7856                 ;;
7857         esac
7858
7859         # either way, check for the library header files
7860         AC_CHECK_HEADERS(pcre2-posix.h pcreposix.h)
7861 fi
7862 ])dnl
7863 dnl ---------------------------------------------------------------------------
7864 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 10 updated: 2015/08/22 17:10:56
7865 dnl -------------------------
7866 dnl Allow the choice of the pkg-config library directory to be overridden.
7867 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
7868
7869 case $PKG_CONFIG in
7870 (no|none|yes)
7871         AC_MSG_CHECKING(for pkg-config library directory)
7872         ;;
7873 (*)
7874         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
7875         ;;
7876 esac
7877
7878 PKG_CONFIG_LIBDIR=no
7879 AC_ARG_WITH(pkg-config-libdir,
7880         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
7881         [PKG_CONFIG_LIBDIR=$withval],
7882         [test "x$PKG_CONFIG" != xnone && PKG_CONFIG_LIBDIR=yes])
7883
7884 case x$PKG_CONFIG_LIBDIR in
7885 (x/*)
7886         ;;
7887 (xyes)
7888         # Look for the library directory using the same prefix as the executable
7889         if test "x$PKG_CONFIG" = xnone
7890         then
7891                 cf_path=$prefix
7892         else
7893                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
7894         fi
7895
7896         # If you don't like using the default architecture, you have to specify the
7897         # intended library directory and corresponding compiler/linker options.
7898         #
7899         # This case allows for Debian's 2014-flavor of multiarch, along with the
7900         # most common variations before that point.  Some other variants spell the
7901         # directory differently, e.g., "pkg-config", and put it in unusual places.
7902         # pkg-config has always been poorly standardized, which is ironic...
7903         case x`(arch) 2>/dev/null` in
7904         (*64)
7905                 cf_search_path="\
7906                         $cf_path/lib/*64-linux-gnu \
7907                         $cf_path/share \
7908                         $cf_path/lib64 \
7909                         $cf_path/lib32 \
7910                         $cf_path/lib"
7911                 ;;
7912         (*)
7913                 cf_search_path="\
7914                         $cf_path/lib/*-linux-gnu \
7915                         $cf_path/share \
7916                         $cf_path/lib32 \
7917                         $cf_path/lib \
7918                         $cf_path/libdata"
7919                 ;;
7920         esac
7921
7922         CF_VERBOSE(list...)
7923         for cf_config in $cf_search_path
7924         do
7925                 CF_VERBOSE(checking $cf_config/pkgconfig)
7926                 if test -d $cf_config/pkgconfig
7927                 then
7928                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
7929                         AC_MSG_CHECKING(done)
7930                         break
7931                 fi
7932         done
7933         ;;
7934 (*)
7935         ;;
7936 esac
7937
7938 if test "x$PKG_CONFIG_LIBDIR" != xno ; then
7939         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
7940 fi
7941
7942 AC_SUBST(PKG_CONFIG_LIBDIR)
7943 ])dnl
7944 dnl ---------------------------------------------------------------------------
7945 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
7946 dnl ---------------
7947 dnl Check for POSIX thread library.
7948 AC_DEFUN([CF_WITH_PTHREAD],
7949 [
7950 AC_MSG_CHECKING(if you want to link with the pthread library)
7951 AC_ARG_WITH(pthread,
7952         [  --with-pthread          use POSIX thread library],
7953         [with_pthread=$withval],
7954         [with_pthread=no])
7955 AC_MSG_RESULT($with_pthread)
7956
7957 if test "$with_pthread" != no ; then
7958         AC_CHECK_HEADER(pthread.h,[
7959         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
7960
7961         for cf_lib_pthread in pthread c_r
7962         do
7963             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
7964             cf_save_LIBS="$LIBS"
7965             CF_ADD_LIB($cf_lib_pthread)
7966             AC_TRY_LINK([
7967 #include <pthread.h>
7968 ],[
7969                 int rc = pthread_create(0,0,0,0);
7970                 int r2 = pthread_mutexattr_settype(0, 0);
7971 ],[with_pthread=yes],[with_pthread=no])
7972             LIBS="$cf_save_LIBS"
7973             AC_MSG_RESULT($with_pthread)
7974             test "$with_pthread" = yes && break
7975         done
7976
7977         if test "$with_pthread" = yes ; then
7978             CF_ADD_LIB($cf_lib_pthread)
7979             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
7980         else
7981             AC_MSG_ERROR(Cannot link with pthread library)
7982         fi
7983         ])
7984 fi
7985 ])
7986 dnl ---------------------------------------------------------------------------
7987 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
7988 dnl -------------------
7989 dnl Allow library's release-version to be overridden.  Generally this happens when a
7990 dnl packager has incremented the release-version past that used in the original package,
7991 dnl and wishes to keep doing this.
7992 dnl
7993 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
7994 dnl and {package}_MINOR symbols
7995 dnl symbol.
7996 AC_DEFUN([CF_WITH_REL_VERSION],[
7997 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
7998 AC_ARG_WITH(rel-version,
7999 [  --with-rel-version=XXX  override derived release version],
8000 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
8001  cf_cv_rel_version=$withval])
8002 ifelse($1,,[
8003  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
8004 ],[
8005  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
8006  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
8007  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
8008  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
8009 ])
8010 ])dnl
8011 dnl ---------------------------------------------------------------------------
8012 dnl CF_WITH_SYSMOUSE version: 3 updated: 2012/10/06 17:56:13
8013 dnl ----------------
8014 dnl If we can compile with sysmouse, make it available unless it is not wanted.
8015 AC_DEFUN([CF_WITH_SYSMOUSE],[
8016 # not everyone has "test -c"
8017 if test -c /dev/sysmouse 2>/dev/null ; then
8018 AC_MSG_CHECKING(if you want to use sysmouse)
8019 AC_ARG_WITH(sysmouse,
8020         [  --with-sysmouse         use sysmouse (FreeBSD console)],
8021         [cf_with_sysmouse=$withval],
8022         [cf_with_sysmouse=maybe])
8023         if test "$cf_with_sysmouse" != no ; then
8024         AC_TRY_COMPILE([
8025 #include <osreldate.h>
8026 #if (__FreeBSD_version >= 400017)
8027 #include <sys/consio.h>
8028 #include <sys/fbio.h>
8029 #else
8030 #include <machine/console.h>
8031 #endif
8032 ],[
8033         struct mouse_info the_mouse;
8034         ioctl(0, CONS_MOUSECTL, &the_mouse);
8035 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
8036         fi
8037 AC_MSG_RESULT($cf_with_sysmouse)
8038 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE,1,[Define to 1 if we can/should use the sysmouse interface])
8039 fi
8040 ])dnl
8041 dnl ---------------------------------------------------------------------------
8042 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
8043 dnl ---------------
8044 dnl For testing, override the derived host system-type which is used to decide
8045 dnl things such as the linker commands used to build shared libraries.  This is
8046 dnl normally chosen automatically based on the type of system which you are
8047 dnl building on.  We use it for testing the configure script.
8048 dnl
8049 dnl This is different from the --host option: it is used only for testing parts
8050 dnl of the configure script which would not be reachable with --host since that
8051 dnl relies on the build environment being real, rather than mocked up.
8052 AC_DEFUN([CF_WITH_SYSTYPE],[
8053 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
8054 AC_ARG_WITH(system-type,
8055         [  --with-system-type=XXX  test: override derived host system-type],
8056 [AC_MSG_WARN(overriding system type to $withval)
8057         cf_cv_system_name=$withval
8058         host_os=$withval
8059 ])
8060 ])dnl
8061 dnl ---------------------------------------------------------------------------
8062 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
8063 dnl ----------------
8064 AC_DEFUN([CF_WITH_VALGRIND],[
8065 CF_NO_LEAKS_OPTION(valgrind,
8066         [  --with-valgrind         test: use valgrind],
8067         [USE_VALGRIND])
8068 ])dnl
8069 dnl ---------------------------------------------------------------------------
8070 dnl CF_WITH_VERSIONED_SYMS version: 7 updated: 2015/10/24 20:50:26
8071 dnl ----------------------
8072 dnl Use this when building shared library with ELF, to markup symbols with the
8073 dnl version identifier from the given input file.  Generally that identifier is
8074 dnl the same as the SONAME at which the symbol was first introduced.
8075 dnl
8076 dnl $1 = basename of the ".map" file (default $PACKAGE)
8077 AC_DEFUN([CF_WITH_VERSIONED_SYMS],
8078 [
8079 AC_MSG_CHECKING(if versioned-symbols file should be used)
8080 AC_ARG_WITH(versioned-syms,
8081         [  --with-versioned-syms=X markup versioned symbols using ld],
8082         [with_versioned_syms=$withval],
8083         [with_versioned_syms=no])
8084 if test "x$with_versioned_syms" = xyes
8085 then
8086         with_versioned_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).map'
8087         AC_SUBST(PACKAGE)
8088 fi
8089 AC_MSG_RESULT($with_versioned_syms)
8090
8091 RESULTING_SYMS=
8092 VERSIONED_SYMS=
8093 WILDCARD_SYMS=
8094
8095 if test "x$with_versioned_syms" != xno
8096 then
8097         RESULTING_SYMS=$with_versioned_syms
8098         case "x$MK_SHARED_LIB" in
8099         (*-Wl,*)
8100                 VERSIONED_SYMS="-Wl,--version-script,\${RESULTING_SYMS}"
8101                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-Wl,%\\[$]{VERSIONED_SYMS} -Wl,%"`
8102                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
8103                 ;;
8104         (*-dy\ *)
8105                 VERSIONED_SYMS="-Wl,-M,\${RESULTING_SYMS}"
8106                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-dy%\\[$]{VERSIONED_SYMS} -dy%"`
8107                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
8108                 ;;
8109         (*)
8110                 AC_MSG_WARN(this system does not support versioned-symbols)
8111                 ;;
8112         esac
8113
8114         # Linux ld can selectively override scope, e.g., of symbols beginning with
8115         # "_" by first declaring some as global, and then using a wildcard to
8116         # declare the others as local.  Some other loaders cannot do this.  Check
8117         # by constructing a (very) simple shared library and inspecting its
8118         # symbols.
8119         if test "x$VERSIONED_SYMS" != "x"
8120         then
8121                 AC_MSG_CHECKING(if wildcards can be used to selectively omit symbols)
8122                 WILDCARD_SYMS=no
8123
8124                 # make sources
8125                 rm -f conftest.*
8126
8127                 cat >conftest.ver <<EOF
8128 module_1.0 {
8129 global:
8130         globalf1;
8131 local:
8132         localf1;
8133 };
8134 module_2.0 {
8135 global:
8136         globalf2;
8137 local:
8138         localf2;
8139         _*;
8140 } module_1.0;
8141 submodule_1.0 {
8142 global:
8143         subglobalf1;
8144         _ismissing;
8145 local:
8146         sublocalf1;
8147 };
8148 submodule_2.0 {
8149 global:
8150         subglobalf2;
8151 local:
8152         sublocalf2;
8153         _*;
8154 } submodule_1.0;
8155 EOF
8156                 cat >conftest.$ac_ext <<EOF
8157 #line __oline__ "configure"
8158 int     _ismissing(void) { return 1; }
8159 int     _localf1(void) { return 1; }
8160 int     _localf2(void) { return 2; }
8161 int     globalf1(void) { return 1; }
8162 int     globalf2(void) { return 2; }
8163 int     _sublocalf1(void) { return 1; }
8164 int     _sublocalf2(void) { return 2; }
8165 int     subglobalf1(void) { return 1; }
8166 int     subglobalf2(void) { return 2; }
8167 EOF
8168                 cat >conftest.mk <<EOF
8169 CC=${CC}
8170 CFLAGS=${CFLAGS}
8171 CPPFLAGS=${CPPFLAGS}
8172 LDFLAGS=${LDFLAGS}
8173 LIBS=${LIBS}
8174 VERSIONED_SYMS=${VERSIONED_SYMS}
8175 RESULTING_SYMS=conftest.ver
8176 MK_SHARED_LIB=${MK_SHARED_LIB}
8177 conftest.so: conftest.$ac_cv_objext
8178                 \$(MK_SHARED_LIB) conftest.$ac_cv_objext
8179 EOF
8180
8181                 # compile source, make library
8182                 if make -f conftest.mk 2>&AC_FD_CC >/dev/null
8183                 then
8184                         # test for missing symbol in either Data or Text section
8185                         cf_missing=`nm -P conftest.so 2>&AC_FD_CC |fgrep _ismissing | egrep '[[         ]][[DT]][[      ]]'`
8186                         test -n "$cf_missing" && WILDCARD_SYMS=yes
8187                 fi
8188                 AC_MSG_RESULT($WILDCARD_SYMS)
8189                 rm -f conftest.*
8190         fi
8191 fi
8192 AC_SUBST(RESULTING_SYMS)
8193 AC_SUBST(VERSIONED_SYMS)
8194 AC_SUBST(WILDCARD_SYMS)
8195 ])dnl
8196 dnl ---------------------------------------------------------------------------
8197 dnl CF_WITH_X11_RGB version: 1 updated: 2017/11/25 17:32:16
8198 dnl ---------------
8199 dnl Handle configure option "--with-x11-rgb", setting these shell
8200 dnl variables:
8201 dnl
8202 dnl $RGB_PATH is the option value, used for finding the X11 rgb file.
8203 dnl $no_x11_rgb is a "#" (comment) if "--without-x11-rgb" is given.
8204 dnl
8205 dnl Most Linux's use this:
8206 dnl     /usr/share/X11/rgb.txt
8207 dnl Debian uses this:
8208 dnl     /etc/X11/rgb.txt
8209 dnl DragonFlyBSD ports uses this:
8210 dnl     /usr/pkg/lib/X11/rgb.txt
8211 dnl FreeBSD ports use these:
8212 dnl     /usr/local/lib/X11/rgb.txt
8213 dnl     /usr/local/share/X11/rgb.txt
8214 dnl Mandriva has these:
8215 dnl     /usr/lib/X11/rgb.txt
8216 dnl     /usr/lib64/X11/rgb.txt
8217 dnl NetBSD has these
8218 dnl     /usr/X11R7/lib/X11/rgb.txt
8219 dnl OpenSolaris uses
8220 dnl     32-bit:
8221 dnl     /usr/X11/etc/X11/rgb.txt
8222 dnl     /usr/X11/share/X11/rgb.txt
8223 dnl     /usr/X11/lib/X11/rgb.txt
8224 dnl OSX uses
8225 dnl             /opt/local/share/X11/rgb.txt (MacPorts)
8226 dnl             /opt/X11/share/X11/rgb.txt (non-ports)
8227 dnl     64-bit:
8228 dnl     /usr/X11/etc/X11/rgb.txt
8229 dnl     /usr/X11/share/X11/rgb.txt (perhaps)
8230 dnl     /usr/X11/lib/amd64/X11/rgb.txt
8231 dnl Solaris10 uses (in this order):
8232 dnl     /usr/openwin/lib/X11/rgb.txt
8233 dnl     /usr/X11/lib/X11/rgb.txt
8234 AC_DEFUN([CF_WITH_X11_RGB],[
8235 AC_MSG_CHECKING(for X11 rgb file)
8236 AC_ARG_WITH(x11-rgb,
8237         [  --with-x11-rgb=FILE   file containing X11 rgb information (EPREFIX/lib/X11/rgb.txt)],
8238         [RGB_PATH=$withval],
8239         [RGB_PATH=auto])
8240
8241 if test "x[$]RGB_PATH" = xauto
8242 then
8243         RGB_PATH='${exec_prefix}/lib/X11/rgb.txt'
8244         for cf_path in \
8245                 /opt/local/share/X11/rgb.txt \
8246                 /opt/X11/share/X11/rgb.txt \
8247                 /usr/share/X11/rgb.txt \
8248                 /usr/X11/share/X11/rgb.txt \
8249                 /usr/X11/lib/X11/rgb.txt \
8250                 /usr/lib/X11/rgb.txt \
8251                 /etc/X11/rgb.txt \
8252                 /usr/pkg/lib/X11/rgb.txt \
8253                 /usr/X11R7/lib/X11/rgb.txt \
8254                 /usr/X11R6/lib/X11/rgb.txt \
8255                 /usr/X11R5/lib/X11/rgb.txt \
8256                 /usr/X11R4/lib/X11/rgb.txt \
8257                 /usr/local/lib/X11/rgb.txt \
8258                 /usr/local/share/X11/rgb.txt \
8259                 /usr/lib64/X11/rgb.txt
8260         do
8261                 if test -f "$cf_path" ; then
8262                         RGB_PATH="$cf_path"
8263                         break
8264                 fi
8265         done
8266 else
8267         cf_path=$RGB_PATH
8268         CF_PATH_SYNTAX(cf_path)
8269 fi
8270
8271 AC_MSG_RESULT($RGB_PATH)
8272 AC_SUBST(RGB_PATH)
8273 AC_DEFINE_UNQUOTED(RGB_PATH,"$cf_path")
8274
8275 no_x11_rgb=
8276 if test "$RGB_PATH" = no
8277 then
8278         no_x11_rgb="#"
8279 fi
8280 AC_SUBST(no_x11_rgb)
8281 ])dnl
8282 dnl ---------------------------------------------------------------------------
8283 dnl CF_XOPEN_SOURCE version: 53 updated: 2018/06/16 18:58:58
8284 dnl ---------------
8285 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
8286 dnl or adapt to the vendor's definitions to get equivalent functionality,
8287 dnl without losing the common non-POSIX features.
8288 dnl
8289 dnl Parameters:
8290 dnl     $1 is the nominal value for _XOPEN_SOURCE
8291 dnl     $2 is the nominal value for _POSIX_C_SOURCE
8292 AC_DEFUN([CF_XOPEN_SOURCE],[
8293 AC_REQUIRE([AC_CANONICAL_HOST])
8294
8295 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
8296 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
8297 cf_xopen_source=
8298
8299 case $host_os in
8300 (aix[[4-7]]*)
8301         cf_xopen_source="-D_ALL_SOURCE"
8302         ;;
8303 (msys)
8304         cf_XOPEN_SOURCE=600
8305         ;;
8306 (darwin[[0-8]].*)
8307         cf_xopen_source="-D_APPLE_C_SOURCE"
8308         ;;
8309 (darwin*)
8310         cf_xopen_source="-D_DARWIN_C_SOURCE"
8311         cf_XOPEN_SOURCE=
8312         ;;
8313 (freebsd*|dragonfly*)
8314         # 5.x headers associate
8315         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
8316         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
8317         cf_POSIX_C_SOURCE=200112L
8318         cf_XOPEN_SOURCE=600
8319         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
8320         ;;
8321 (hpux11*)
8322         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
8323         ;;
8324 (hpux*)
8325         cf_xopen_source="-D_HPUX_SOURCE"
8326         ;;
8327 (irix[[56]].*)
8328         cf_xopen_source="-D_SGI_SOURCE"
8329         cf_XOPEN_SOURCE=
8330         ;;
8331 (linux*|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin)
8332         CF_GNU_SOURCE($cf_XOPEN_SOURCE)
8333         ;;
8334 (minix*)
8335         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
8336         ;;
8337 (mirbsd*)
8338         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
8339         cf_XOPEN_SOURCE=
8340         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
8341         ;;
8342 (netbsd*)
8343         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
8344         ;;
8345 (openbsd[[4-9]]*)
8346         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
8347         cf_xopen_source="-D_BSD_SOURCE"
8348         cf_XOPEN_SOURCE=600
8349         ;;
8350 (openbsd*)
8351         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
8352         ;;
8353 (osf[[45]]*)
8354         cf_xopen_source="-D_OSF_SOURCE"
8355         ;;
8356 (nto-qnx*)
8357         cf_xopen_source="-D_QNX_SOURCE"
8358         ;;
8359 (sco*)
8360         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
8361         ;;
8362 (solaris2.*)
8363         cf_xopen_source="-D__EXTENSIONS__"
8364         cf_cv_xopen_source=broken
8365         ;;
8366 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
8367         cf_XOPEN_SOURCE=
8368         cf_POSIX_C_SOURCE=
8369         ;;
8370 (*)
8371         CF_TRY_XOPEN_SOURCE
8372         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
8373         ;;
8374 esac
8375
8376 if test -n "$cf_xopen_source" ; then
8377         CF_ADD_CFLAGS($cf_xopen_source,true)
8378 fi
8379
8380 dnl In anything but the default case, we may have system-specific setting
8381 dnl which is still not guaranteed to provide all of the entrypoints that
8382 dnl _XOPEN_SOURCE would yield.
8383 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
8384         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
8385         AC_TRY_COMPILE([#include <stdlib.h>],[
8386 #ifndef _XOPEN_SOURCE
8387 make an error
8388 #endif],
8389         [cf_XOPEN_SOURCE_set=yes],
8390         [cf_XOPEN_SOURCE_set=no])
8391         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
8392         if test $cf_XOPEN_SOURCE_set = yes
8393         then
8394                 AC_TRY_COMPILE([#include <stdlib.h>],[
8395 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
8396 make an error
8397 #endif],
8398                 [cf_XOPEN_SOURCE_set_ok=yes],
8399                 [cf_XOPEN_SOURCE_set_ok=no])
8400                 if test $cf_XOPEN_SOURCE_set_ok = no
8401                 then
8402                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
8403                 fi
8404         else
8405                 CF_TRY_XOPEN_SOURCE
8406         fi
8407 fi
8408 ])