aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2012,2013 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.684 2013/11/16 19:28:35 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 3 updated: 2002/10/27 23:21:42
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54     [AC_TRY_LINK([#include <langinfo.h>],
  55       [char* cs = nl_langinfo(CODESET);],
  56       am_cv_langinfo_codeset=yes,
  57       am_cv_langinfo_codeset=no)
  58     ])
  59   if test $am_cv_langinfo_codeset = yes; then
  60     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62   fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ACVERSION_CHECK version: 4 updated: 2013/03/04 19:52:56
  66 dnl ------------------
  67 dnl Conditionally generate script according to whether we're using a given autoconf.
  68 dnl
  69 dnl $1 = version to compare against
  70 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
  71 dnl $3 = code to use if AC_ACVERSION is older than $1.
  72 define([CF_ACVERSION_CHECK],
  73 [
  74 ifdef([AC_ACVERSION], ,[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])dnl
  75 ifdef([m4_version_compare],
  76 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
  77 [CF_ACVERSION_COMPARE(
  78 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
  79 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
  80 dnl ---------------------------------------------------------------------------
  81 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
  82 dnl --------------------
  83 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
  84 dnl                      MAJOR2, MINOR2, TERNARY2,
  85 dnl                      PRINTABLE2, not FOUND, FOUND)
  86 define([CF_ACVERSION_COMPARE],
  87 [ifelse(builtin([eval], [$2 < $5]), 1,
  88 [ifelse([$8], , ,[$8])],
  89 [ifelse([$9], , ,[$9])])])dnl
  90 dnl ---------------------------------------------------------------------------
  91 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
  92 dnl -------------------
  93 dnl Construct the list of include-options for the C programs in the Ada95
  94 dnl binding.
  95 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
  96 [
  97 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
  98 if test "$srcdir" != "."; then
  99         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 100 fi
 101 if test "$GCC" != yes; then
 102         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 103 elif test "$includedir" != "/usr/include"; then
 104         if test "$includedir" = '${prefix}/include' ; then
 105                 if test x$prefix != x/usr ; then
 106                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 107                 fi
 108         else
 109                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 110         fi
 111 fi
 112 AC_SUBST(ACPPFLAGS)
 113 ])dnl
 114 dnl ---------------------------------------------------------------------------
 115 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 116 dnl ---------------
 117 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 118 AC_DEFUN([CF_ADD_ADAFLAGS],[
 119         ADAFLAGS="$ADAFLAGS $1"
 120         AC_SUBST(ADAFLAGS)
 121 ])dnl
 122 dnl ---------------------------------------------------------------------------
 123 dnl CF_ADD_CFLAGS version: 10 updated: 2010/05/26 05:38:42
 124 dnl -------------
 125 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 126 dnl The second parameter if given makes this macro verbose.
 127 dnl
 128 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 129 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 130 dnl confused by the quotes (which require backslashes to keep them usable).
 131 AC_DEFUN([CF_ADD_CFLAGS],
 132 [
 133 cf_fix_cppflags=no
 134 cf_new_cflags=
 135 cf_new_cppflags=
 136 cf_new_extra_cppflags=
 137
 138 for cf_add_cflags in $1
 139 do
 140 case $cf_fix_cppflags in
 141 no)
 142         case $cf_add_cflags in #(vi
 143         -undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C) #(vi
 144                 case $cf_add_cflags in
 145                 -D*)
 146                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 147
 148                         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 149                                 && test -z "${cf_tst_cflags}" \
 150                                 && cf_fix_cppflags=yes
 151
 152                         if test $cf_fix_cppflags = yes ; then
 153                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 154                                 continue
 155                         elif test "${cf_tst_cflags}" = "\"'" ; then
 156                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 157                                 continue
 158                         fi
 159                         ;;
 160                 esac
 161                 case "$CPPFLAGS" in
 162                 *$cf_add_cflags) #(vi
 163                         ;;
 164                 *) #(vi
 165                         case $cf_add_cflags in #(vi
 166                         -D*)
 167                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 168                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 169                                 ;;
 170                         esac
 171                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 172                         ;;
 173                 esac
 174                 ;;
 175         *)
 176                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 177                 ;;
 178         esac
 179         ;;
 180 yes)
 181         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 182
 183         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 184
 185         test "${cf_add_cflags}" != "${cf_tst_cflags}" \
 186                 && test -z "${cf_tst_cflags}" \
 187                 && cf_fix_cppflags=no
 188         ;;
 189 esac
 190 done
 191
 192 if test -n "$cf_new_cflags" ; then
 193         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 194         CFLAGS="$CFLAGS $cf_new_cflags"
 195 fi
 196
 197 if test -n "$cf_new_cppflags" ; then
 198         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 199         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 200 fi
 201
 202 if test -n "$cf_new_extra_cppflags" ; then
 203         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 204         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 205 fi
 206
 207 AC_SUBST(EXTRA_CPPFLAGS)
 208
 209 ])dnl
 210 dnl ---------------------------------------------------------------------------
 211 dnl CF_ADD_INCDIR version: 13 updated: 2010/05/26 16:44:57
 212 dnl -------------
 213 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 214 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 215 dnl but old versions (and some misinstalled ones) need that.  To make things
 216 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 217 dnl the include-path).
 218 AC_DEFUN([CF_ADD_INCDIR],
 219 [
 220 if test -n "$1" ; then
 221   for cf_add_incdir in $1
 222   do
 223         while test $cf_add_incdir != /usr/include
 224         do
 225           if test -d $cf_add_incdir
 226           then
 227                 cf_have_incdir=no
 228                 if test -n "$CFLAGS$CPPFLAGS" ; then
 229                   # a loop is needed to ensure we can add subdirs of existing dirs
 230                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 231                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 232                           cf_have_incdir=yes; break
 233                         fi
 234                   done
 235                 fi
 236
 237                 if test "$cf_have_incdir" = no ; then
 238                   if test "$cf_add_incdir" = /usr/local/include ; then
 239                         if test "$GCC" = yes
 240                         then
 241                           cf_save_CPPFLAGS=$CPPFLAGS
 242                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 243                           AC_TRY_COMPILE([#include <stdio.h>],
 244                                   [printf("Hello")],
 245                                   [],
 246                                   [cf_have_incdir=yes])
 247                           CPPFLAGS=$cf_save_CPPFLAGS
 248                         fi
 249                   fi
 250                 fi
 251
 252                 if test "$cf_have_incdir" = no ; then
 253                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 254                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 255
 256                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 257                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 258                   cf_add_incdir="$cf_top_incdir"
 259                 else
 260                   break
 261                 fi
 262           fi
 263         done
 264   done
 265 fi
 266 ])dnl
 267 dnl ---------------------------------------------------------------------------
 268 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 269 dnl ----------
 270 dnl Add a library, used to enforce consistency.
 271 dnl
 272 dnl $1 = library to add, without the "-l"
 273 dnl $2 = variable to update (default $LIBS)
 274 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 275 dnl ---------------------------------------------------------------------------
 276 dnl CF_ADD_LIBDIR version: 9 updated: 2010/05/26 16:44:57
 277 dnl -------------
 278 dnl     Adds to the library-path
 279 dnl
 280 dnl     Some machines have trouble with multiple -L options.
 281 dnl
 282 dnl $1 is the (list of) directory(s) to add
 283 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 284 dnl
 285 AC_DEFUN([CF_ADD_LIBDIR],
 286 [
 287 if test -n "$1" ; then
 288   for cf_add_libdir in $1
 289   do
 290     if test $cf_add_libdir = /usr/lib ; then
 291       :
 292     elif test -d $cf_add_libdir
 293     then
 294       cf_have_libdir=no
 295       if test -n "$LDFLAGS$LIBS" ; then
 296         # a loop is needed to ensure we can add subdirs of existing dirs
 297         for cf_test_libdir in $LDFLAGS $LIBS ; do
 298           if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 299             cf_have_libdir=yes; break
 300           fi
 301         done
 302       fi
 303       if test "$cf_have_libdir" = no ; then
 304         CF_VERBOSE(adding $cf_add_libdir to library-path)
 305         ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 306       fi
 307     fi
 308   done
 309 fi
 310 ])dnl
 311 dnl ---------------------------------------------------------------------------
 312 dnl CF_ADD_LIBS version: 1 updated: 2010/06/02 05:03:05
 313 dnl -----------
 314 dnl Add one or more libraries, used to enforce consistency.
 315 dnl
 316 dnl $1 = libraries to add, with the "-l", etc.
 317 dnl $2 = variable to update (default $LIBS)
 318 AC_DEFUN([CF_ADD_LIBS],[ifelse($2,,LIBS,[$2])="$1 [$]ifelse($2,,LIBS,[$2])"])dnl
 319 dnl ---------------------------------------------------------------------------
 320 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 321 dnl ------------------
 322 dnl Append to a search-list for a nonstandard header/lib-file
 323 dnl     $1 = the variable to return as result
 324 dnl     $2 = the package name
 325 dnl     $3 = the subdirectory, e.g., bin, include or lib
 326 dnl $4 = the directory under which we will test for subdirectories
 327 dnl $5 = a directory that we do not want $4 to match
 328 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 329 [
 330 test "x$4" != "x$5" && \
 331 test -d "$4" && \
 332 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 333         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 334         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 335         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 336         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 337         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 338         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 339 }
 340 ])dnl
 341 dnl ---------------------------------------------------------------------------
 342 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 343 dnl --------------
 344 dnl Allow user to disable a normally-on option.
 345 AC_DEFUN([CF_ARG_DISABLE],
 346 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 347 dnl ---------------------------------------------------------------------------
 348 dnl CF_ARG_OPTION version: 4 updated: 2010/05/26 05:38:42
 349 dnl -------------
 350 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 351 dnl values.
 352 dnl
 353 dnl Parameters:
 354 dnl $1 = option name
 355 dnl $2 = help-string
 356 dnl $3 = action to perform if option is not default
 357 dnl $4 = action if perform if option is default
 358 dnl $5 = default option value (either 'yes' or 'no')
 359 AC_DEFUN([CF_ARG_OPTION],
 360 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 361   if test "$enableval" != "$5" ; then
 362 ifelse([$3],,[    :]dnl
 363 ,[    $3]) ifelse([$4],,,[
 364   else
 365     $4])
 366   fi],[enableval=$5 ifelse([$4],,,[
 367   $4
 368 ])dnl
 369   ])])dnl
 370 dnl ---------------------------------------------------------------------------
 371 dnl CF_AR_FLAGS version: 5 updated: 2010/05/20 20:24:29
 372 dnl -----------
 373 dnl Check for suitable "ar" (archiver) options for updating an archive.
 374 AC_DEFUN([CF_AR_FLAGS],[
 375 AC_REQUIRE([CF_PROG_AR])
 376
 377 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 378         cf_cv_ar_flags=unknown
 379         for cf_ar_flags in -curv curv -crv crv -cqv cqv -rv rv
 380         do
 381
 382                 # check if $ARFLAGS already contains this choice
 383                 if test "x$ARFLAGS" != "x" ; then
 384                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 385                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 386                                 cf_cv_ar_flags=
 387                                 break
 388                         fi
 389                 fi
 390
 391                 rm -f conftest.$ac_cv_objext
 392                 rm -f conftest.a
 393
 394                 cat >conftest.$ac_ext <<EOF
 395 #line __oline__ "configure"
 396 int     testdata[[3]] = { 123, 456, 789 };
 397 EOF
 398                 if AC_TRY_EVAL(ac_compile) ; then
 399                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 400                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 401                         if test -f conftest.a ; then
 402                                 cf_cv_ar_flags=$cf_ar_flags
 403                                 break
 404                         fi
 405                 else
 406                         CF_VERBOSE(cannot compile test-program)
 407                         break
 408                 fi
 409         done
 410         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 411 ])
 412
 413 if test -n "$ARFLAGS" ; then
 414         if test -n "$cf_cv_ar_flags" ; then
 415                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 416         fi
 417 else
 418         ARFLAGS=$cf_cv_ar_flags
 419 fi
 420
 421 AC_SUBST(ARFLAGS)
 422 ])
 423 dnl ---------------------------------------------------------------------------
 424 dnl CF_AWK_BIG_PRINTF version: 4 updated: 2011/10/30 17:09:50
 425 dnl -----------------
 426 dnl Check if awk can handle big strings using printf.  Some older versions of
 427 dnl awk choke on large strings passed via "%s".
 428 dnl
 429 dnl $1 = desired string size
 430 dnl $2 = variable to set with result
 431 AC_DEFUN([CF_AWK_BIG_PRINTF],
 432 [
 433         case x$AWK in #(vi
 434         x)
 435                 eval $2=no
 436                 ;;
 437         *) #(vi
 438                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 439                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 440                         eval $2=yes
 441                 else
 442                         eval $2=no
 443                 fi
 444                 ;;
 445         esac
 446 ])dnl
 447 dnl ---------------------------------------------------------------------------
 448 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 449 dnl ------------
 450 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 451 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 452 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 453 dnl
 454 dnl Treat the configuration-variable specially here, since we're directly
 455 dnl substituting its value (i.e., 1/0).
 456 dnl
 457 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 458 AC_DEFUN([CF_BOOL_DECL],
 459 [
 460 AC_MSG_CHECKING(if we should include stdbool.h)
 461
 462 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 463         AC_TRY_COMPILE([],[bool foo = false],
 464                 [cf_cv_header_stdbool_h=0],
 465                 [AC_TRY_COMPILE([
 466 #ifndef __BEOS__
 467 #include <stdbool.h>
 468 #endif
 469 ],[bool foo = false],
 470                         [cf_cv_header_stdbool_h=1],
 471                         [cf_cv_header_stdbool_h=0])])])
 472
 473 if test "$cf_cv_header_stdbool_h" = 1
 474 then    AC_MSG_RESULT(yes)
 475 else    AC_MSG_RESULT(no)
 476 fi
 477
 478 AC_MSG_CHECKING([for builtin bool type])
 479
 480 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 481         AC_TRY_COMPILE([
 482 #include <stdio.h>
 483 #include <sys/types.h>
 484 ],[bool x = false],
 485                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 486                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 487         ])
 488
 489 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 490 then    AC_MSG_RESULT(yes)
 491 else    AC_MSG_RESULT(no)
 492 fi
 493 ])dnl
 494 dnl ---------------------------------------------------------------------------
 495 dnl CF_BOOL_SIZE version: 13 updated: 2013/04/13 18:03:21
 496 dnl ------------
 497 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 498 dnl Don't bother looking for bool.h, since it's been deprecated.
 499 dnl
 500 dnl If the current compiler is C rather than C++, we get the bool definition
 501 dnl from <stdbool.h>.
 502 AC_DEFUN([CF_BOOL_SIZE],
 503 [
 504 AC_MSG_CHECKING([for size of bool])
 505 AC_CACHE_VAL(cf_cv_type_of_bool,[
 506         rm -f cf_test.out
 507         AC_TRY_RUN([
 508 #include <stdlib.h>
 509 #include <stdio.h>
 510
 511 #if defined(__cplusplus)
 512
 513 #ifdef HAVE_GXX_BUILTIN_H
 514 #include <g++/builtin.h>
 515 #elif HAVE_GPP_BUILTIN_H
 516 #include <gpp/builtin.h>
 517 #elif HAVE_BUILTIN_H
 518 #include <builtin.h>
 519 #endif
 520
 521 #else
 522
 523 #if $cf_cv_header_stdbool_h
 524 #include <stdbool.h>
 525 #endif
 526
 527 #endif
 528
 529 int main()
 530 {
 531         FILE *fp = fopen("cf_test.out", "w");
 532         if (fp != 0) {
 533                 bool x = true;
 534                 if ((bool)(-x) >= 0)
 535                         fputs("unsigned ", fp);
 536                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 537                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 538                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 539                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 540                 fclose(fp);
 541         }
 542         ${cf_cv_main_return:-return}(0);
 543 }
 544                 ],
 545                 [cf_cv_type_of_bool=`cat cf_test.out`
 546                  if test -z "$cf_cv_type_of_bool"; then
 547                    cf_cv_type_of_bool=unknown
 548                  fi],
 549                 [cf_cv_type_of_bool=unknown],
 550                 [cf_cv_type_of_bool=unknown])
 551         ])
 552         rm -f cf_test.out
 553 AC_MSG_RESULT($cf_cv_type_of_bool)
 554 if test "$cf_cv_type_of_bool" = unknown ; then
 555         case .$NCURSES_BOOL in #(vi
 556         .auto|.) NCURSES_BOOL=unsigned;;
 557         esac
 558         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 559         cf_cv_type_of_bool=$NCURSES_BOOL
 560 fi
 561 ])dnl
 562 dnl ---------------------------------------------------------------------------
 563 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
 564 dnl -----------
 565 dnl If we're cross-compiling, allow the user to override the tools and their
 566 dnl options.  The configure script is oriented toward identifying the host
 567 dnl compiler, etc., but we need a build compiler to generate parts of the
 568 dnl source.
 569 dnl
 570 dnl $1 = default for $CPPFLAGS
 571 dnl $2 = default for $LIBS
 572 AC_DEFUN([CF_BUILD_CC],[
 573 CF_ACVERSION_CHECK(2.52,,
 574         [AC_REQUIRE([CF_PROG_EXT])])
 575 if test "$cross_compiling" = yes ; then
 576
 577         # defaults that we might want to override
 578         : ${BUILD_CFLAGS:=''}
 579         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 580         : ${BUILD_LDFLAGS:=''}
 581         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 582         : ${BUILD_EXEEXT:='$x'}
 583         : ${BUILD_OBJEXT:='o'}
 584
 585         AC_ARG_WITH(build-cc,
 586                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 587                 [BUILD_CC="$withval"],
 588                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 589         AC_MSG_CHECKING(for native build C compiler)
 590         AC_MSG_RESULT($BUILD_CC)
 591
 592         AC_MSG_CHECKING(for native build C preprocessor)
 593         AC_ARG_WITH(build-cpp,
 594                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 595                 [BUILD_CPP="$withval"],
 596                 [BUILD_CPP='${BUILD_CC} -E'])
 597         AC_MSG_RESULT($BUILD_CPP)
 598
 599         AC_MSG_CHECKING(for native build C flags)
 600         AC_ARG_WITH(build-cflags,
 601                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 602                 [BUILD_CFLAGS="$withval"])
 603         AC_MSG_RESULT($BUILD_CFLAGS)
 604
 605         AC_MSG_CHECKING(for native build C preprocessor-flags)
 606         AC_ARG_WITH(build-cppflags,
 607                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 608                 [BUILD_CPPFLAGS="$withval"])
 609         AC_MSG_RESULT($BUILD_CPPFLAGS)
 610
 611         AC_MSG_CHECKING(for native build linker-flags)
 612         AC_ARG_WITH(build-ldflags,
 613                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 614                 [BUILD_LDFLAGS="$withval"])
 615         AC_MSG_RESULT($BUILD_LDFLAGS)
 616
 617         AC_MSG_CHECKING(for native build linker-libraries)
 618         AC_ARG_WITH(build-libs,
 619                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 620                 [BUILD_LIBS="$withval"])
 621         AC_MSG_RESULT($BUILD_LIBS)
 622
 623         # this assumes we're on Unix.
 624         BUILD_EXEEXT=
 625         BUILD_OBJEXT=o
 626
 627         : ${BUILD_CC:='${CC}'}
 628
 629         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 630                 AC_MSG_ERROR([Cross-build requires two compilers.
 631 Use --with-build-cc to specify the native compiler.])
 632         fi
 633
 634 else
 635         : ${BUILD_CC:='${CC}'}
 636         : ${BUILD_CPP:='${CPP}'}
 637         : ${BUILD_CFLAGS:='${CFLAGS}'}
 638         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 639         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 640         : ${BUILD_LIBS:='${LIBS}'}
 641         : ${BUILD_EXEEXT:='$x'}
 642         : ${BUILD_OBJEXT:='o'}
 643 fi
 644
 645 AC_SUBST(BUILD_CC)
 646 AC_SUBST(BUILD_CPP)
 647 AC_SUBST(BUILD_CFLAGS)
 648 AC_SUBST(BUILD_CPPFLAGS)
 649 AC_SUBST(BUILD_LDFLAGS)
 650 AC_SUBST(BUILD_LIBS)
 651 AC_SUBST(BUILD_EXEEXT)
 652 AC_SUBST(BUILD_OBJEXT)
 653 ])dnl
 654 dnl ---------------------------------------------------------------------------
 655 dnl CF_CC_ENV_FLAGS version: 1 updated: 2012/10/03 05:25:49
 656 dnl ---------------
 657 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 658 dnl into CC.  This will not help with broken scripts that wrap the compiler with
 659 dnl options, but eliminates a more common category of user confusion.
 660 AC_DEFUN([CF_CC_ENV_FLAGS],
 661 [
 662 # This should have been defined by AC_PROG_CC
 663 : ${CC:=cc}
 664
 665 AC_MSG_CHECKING(\$CC variable)
 666 case "$CC" in #(vi
 667 *[[\ \  ]]-[[IUD]]*)
 668         AC_MSG_RESULT(broken)
 669         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 670         # humor him...
 671         cf_flags=`echo "$CC" | sed -e 's/^[[^   ]]*[[   ]]//'`
 672         CC=`echo "$CC" | sed -e 's/[[   ]].*//'`
 673         CF_ADD_CFLAGS($cf_flags)
 674         ;;
 675 *)
 676         AC_MSG_RESULT(ok)
 677         ;;
 678 esac
 679 ])dnl
 680 dnl ---------------------------------------------------------------------------
 681 dnl CF_CFG_DEFAULTS version: 10 updated: 2013/09/07 13:54:05
 682 dnl ---------------
 683 dnl Determine the default configuration into which we'll install ncurses.  This
 684 dnl can be overridden by the user's command-line options.  There's two items to
 685 dnl look for:
 686 dnl     1. the prefix (e.g., /usr)
 687 dnl     2. the header files (e.g., /usr/include/ncurses)
 688 dnl We'll look for a previous installation of ncurses and use the same defaults.
 689 dnl
 690 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 691 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 692 dnl programs from a vendor's.
 693 AC_DEFUN([CF_CFG_DEFAULTS],
 694 [
 695 AC_MSG_CHECKING(for prefix)
 696 if test "x$prefix" = "xNONE" ; then
 697         case "$cf_cv_system_name" in
 698                 # non-vendor systems don't have a conflict
 699         openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 700                 prefix=/usr
 701                 ;;
 702         *)      prefix=$ac_default_prefix
 703                 ;;
 704         esac
 705 fi
 706 AC_MSG_RESULT($prefix)
 707
 708 if test "x$prefix" = "xNONE" ; then
 709 AC_MSG_CHECKING(for default include-directory)
 710 test -n "$verbose" && echo 1>&AC_FD_MSG
 711 for cf_symbol in \
 712         $includedir \
 713         $includedir/ncurses \
 714         $prefix/include \
 715         $prefix/include/ncurses \
 716         /usr/local/include \
 717         /usr/local/include/ncurses \
 718         /usr/include \
 719         /usr/include/ncurses
 720 do
 721         cf_dir=`eval echo $cf_symbol`
 722         if test -f $cf_dir/curses.h ; then
 723         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 724                 includedir="$cf_symbol"
 725                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 726                 break
 727         fi
 728         fi
 729         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 730 done
 731 AC_MSG_RESULT($includedir)
 732 fi
 733 ])dnl
 734 dnl ---------------------------------------------------------------------------
 735 dnl CF_CGETENT version: 5 updated: 2012/10/06 17:56:13
 736 dnl ----------
 737 dnl Check if the terminal-capability database functions are available.  If not,
 738 dnl ncurses has a much-reduced version.
 739 AC_DEFUN([CF_CGETENT],[
 740 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 741 AC_TRY_LINK([
 742 #include <stdlib.h>],[
 743         char temp[128];
 744         char *buf = temp;
 745         char *db_array = temp;
 746         cgetent(&buf, &db_array, "vt100");
 747         cgetcap(buf, "tc", '=');
 748         cgetmatch(buf, "tc");
 749         ],
 750         [cf_cv_cgetent=yes],
 751         [cf_cv_cgetent=no])
 752 ])
 753
 754 if test "$cf_cv_cgetent" = yes
 755 then
 756         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 757 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 758 AC_TRY_LINK([
 759 #include <stdlib.h>],[
 760         char temp[128];
 761         char *buf = temp;
 762 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 763         const char *db_array = temp;
 764         cgetent(&buf, &db_array, "vt100");
 765 #endif
 766         cgetcap(buf, "tc", '=');
 767         cgetmatch(buf, "tc");
 768         ],
 769         [cf_cv_cgetent_const=yes],
 770         [cf_cv_cgetent_const=no])
 771 ])
 772         if test "$cf_cv_cgetent_const" = yes
 773         then
 774                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 775         fi
 776 fi
 777 ])dnl
 778 dnl ---------------------------------------------------------------------------
 779 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 780 dnl --------------
 781 dnl Check if we're accidentally using a cache from a different machine.
 782 dnl Derive the system name, as a check for reusing the autoconf cache.
 783 dnl
 784 dnl If we've packaged config.guess and config.sub, run that (since it does a
 785 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 786 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 787 dnl which is useful in cross-compiles.
 788 dnl
 789 dnl Note: we would use $ac_config_sub, but that is one of the places where
 790 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 791 AC_DEFUN([CF_CHECK_CACHE],
 792 [
 793 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 794         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 795         system_name="$host_os"
 796 else
 797         system_name="`(uname -s -r) 2>/dev/null`"
 798         if test -z "$system_name" ; then
 799                 system_name="`(hostname) 2>/dev/null`"
 800         fi
 801 fi
 802 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 803 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 804
 805 test -z "$system_name" && system_name="$cf_cv_system_name"
 806 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 807
 808 if test ".$system_name" != ".$cf_cv_system_name" ; then
 809         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 810         AC_MSG_ERROR("Please remove config.cache and try again.")
 811 fi
 812 ])dnl
 813 dnl ---------------------------------------------------------------------------
 814 dnl CF_CHECK_ERRNO version: 11 updated: 2010/05/26 05:38:42
 815 dnl --------------
 816 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 817 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 818 dnl ourselves.
 819 dnl
 820 dnl $1 = the name to check
 821 dnl $2 = the assumed type
 822 AC_DEFUN([CF_CHECK_ERRNO],
 823 [
 824 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 825     AC_TRY_COMPILE([
 826 #ifdef HAVE_STDLIB_H
 827 #include <stdlib.h>
 828 #endif
 829 #include <stdio.h>
 830 #include <sys/types.h>
 831 #include <errno.h> ],
 832     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 833     [cf_cv_dcl_$1=yes],
 834     [cf_cv_dcl_$1=no])
 835 ])
 836
 837 if test "$cf_cv_dcl_$1" = no ; then
 838     CF_UPPER(cf_result,decl_$1)
 839     AC_DEFINE_UNQUOTED($cf_result)
 840 fi
 841
 842 # It's possible (for near-UNIX clones) that the data doesn't exist
 843 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 844 ])dnl
 845 dnl ---------------------------------------------------------------------------
 846 dnl CF_CHECK_EXTERN_DATA version: 3 updated: 2001/12/30 18:03:23
 847 dnl --------------------
 848 dnl Check for existence of external data in the current set of libraries.  If
 849 dnl we can modify it, it's real enough.
 850 dnl $1 = the name to check
 851 dnl $2 = its type
 852 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 853 [
 854 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 855     AC_TRY_LINK([
 856 #undef $1
 857 extern $2 $1;
 858 ],
 859     [$1 = 2],
 860     [cf_cv_have_$1=yes],
 861     [cf_cv_have_$1=no])
 862 ])
 863
 864 if test "$cf_cv_have_$1" = yes ; then
 865     CF_UPPER(cf_result,have_$1)
 866     AC_DEFINE_UNQUOTED($cf_result)
 867 fi
 868
 869 ])dnl
 870 dnl ---------------------------------------------------------------------------
 871 dnl CF_CHECK_GPM_WGETCH version: 2 updated: 2010/08/14 18:25:37
 872 dnl -------------------
 873 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 874 dnl is not "weak" - warn about this because it can create problems linking
 875 dnl applications with ncurses.
 876 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 877 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 878
 879 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 880 cf_cv_check_gpm_wgetch=unknown
 881 if test "$cross_compiling" != yes ; then
 882
 883 cat >conftest.$ac_ext <<CF_EOF
 884 #include <gpm.h>
 885 int main()
 886 {
 887         Gpm_Wgetch();
 888         ${cf_cv_main_return:-return}(0);
 889 }
 890 CF_EOF
 891
 892         cf_save_LIBS="$LIBS"
 893         # This only works if we can look at the symbol table.  If a shared
 894         # library is stripped for install, we cannot use that.  So we're forced
 895         # to rely on the static library, noting that some packagers may not
 896         # include it.
 897         LIBS="-static -lgpm -dynamic $LIBS"
 898         if AC_TRY_EVAL(ac_compile) ; then
 899                 if AC_TRY_EVAL(ac_link) ; then
 900                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
 901                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
 902                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
 903                 fi
 904         fi
 905         rm -rf conftest*
 906         LIBS="$cf_save_LIBS"
 907 fi
 908 ])
 909
 910 if test "$cf_cv_check_gpm_wgetch" != yes ; then
 911         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 912 fi
 913 ])])dnl
 914 dnl ---------------------------------------------------------------------------
 915 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
 916 dnl ------------------------
 917 dnl Show the version of libtool
 918 dnl
 919 dnl Save the version in a cache variable - this is not entirely a good thing,
 920 dnl but the version string from libtool is very ugly, and for bug reports it
 921 dnl might be useful to have the original string.
 922 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
 923 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
 924 then
 925         AC_MSG_CHECKING(version of $LIBTOOL)
 926         CF_LIBTOOL_VERSION
 927         AC_MSG_RESULT($cf_cv_libtool_version)
 928         if test -z "$cf_cv_libtool_version" ; then
 929                 AC_MSG_ERROR(This is not GNU libtool)
 930         fi
 931 else
 932         AC_MSG_ERROR(GNU libtool has not been found)
 933 fi
 934 ])dnl
 935 dnl ---------------------------------------------------------------------------
 936 dnl CF_CHECK_WCHAR_H version: 1 updated: 2011/10/29 15:01:05
 937 dnl ----------------
 938 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
 939 AC_DEFUN([CF_CHECK_WCHAR_H],[
 940 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
 941 AC_TRY_COMPILE(
 942 [
 943 #include <stdlib.h>
 944 #include <wchar.h>
 945 ],[
 946         wint_t foo = 0;
 947         int bar = iswpunct(foo)],
 948         [cf_cv_wchar_h_okay=yes],
 949         [cf_cv_wchar_h_okay=no])])
 950
 951 if test $cf_cv_wchar_h_okay = no
 952 then
 953         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 954 fi
 955 ])dnl
 956 dnl ---------------------------------------------------------------------------
 957 dnl CF_CLANG_COMPILER version: 1 updated: 2012/06/16 14:55:39
 958 dnl -----------------
 959 dnl Check if the given compiler is really clang.  clang's C driver defines
 960 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
 961 dnl not ignore some gcc options.
 962 dnl
 963 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
 964 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
 965 dnl the wrappers for gcc and g++ warnings.
 966 dnl
 967 dnl $1 = GCC (default) or GXX
 968 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
 969 dnl $3 = CFLAGS (default) or CXXFLAGS
 970 AC_DEFUN([CF_CLANG_COMPILER],[
 971 ifelse([$2],,CLANG_COMPILER,[$2])=no
 972
 973 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
 974         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
 975         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
 976         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
 977         AC_TRY_COMPILE([],[
 978 #ifdef __clang__
 979 #else
 980 make an error
 981 #endif
 982 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
 983 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
 984 ],[])
 985         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
 986         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
 987 fi
 988 ])
 989 dnl ---------------------------------------------------------------------------
 990 dnl CF_CPP_PARAM_INIT version: 6 updated: 2012/10/06 17:56:13
 991 dnl -----------------
 992 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
 993 dnl is a late feature for the standard and is not in some recent compilers
 994 dnl (1999/9/11).
 995 AC_DEFUN([CF_CPP_PARAM_INIT],
 996 [
 997 if test -n "$CXX"; then
 998 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
 999         AC_LANG_SAVE
1000         AC_LANG_CPLUSPLUS
1001         AC_TRY_RUN([
1002 class TEST {
1003 private:
1004         int value;
1005 public:
1006         TEST(int x = 1);
1007         ~TEST();
1008 };
1009
1010 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1011 {
1012         value = x;
1013 }
1014 int main() { }
1015 ],
1016         [cf_cv_cpp_param_init=yes],
1017         [cf_cv_cpp_param_init=no],
1018         [cf_cv_cpp_param_init=unknown])
1019         AC_LANG_RESTORE
1020 ])
1021 fi
1022 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1023 ])dnl
1024 dnl ---------------------------------------------------------------------------
1025 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1026 dnl ------------------
1027 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1028 dnl not be supported in g++ before 3.0
1029 AC_DEFUN([CF_CPP_STATIC_CAST],
1030 [
1031 if test -n "$CXX"; then
1032
1033 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1034         AC_LANG_SAVE
1035         AC_LANG_CPLUSPLUS
1036
1037         AC_TRY_COMPILE([
1038 class NCursesPanel
1039 {
1040 public:
1041   NCursesPanel(int nlines,
1042                int ncols,
1043                int begin_y = 0,
1044                int begin_x = 0)
1045   {
1046   }
1047   NCursesPanel();
1048   ~NCursesPanel();
1049 };
1050
1051 template<class T> class NCursesUserPanel : public NCursesPanel
1052 {
1053 public:
1054   NCursesUserPanel (int nlines,
1055                     int ncols,
1056                     int begin_y = 0,
1057                     int begin_x = 0,
1058                     const T* p_UserData = static_cast<T*>(0))
1059     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1060   {
1061   };
1062   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1063   {
1064   };
1065
1066   virtual ~NCursesUserPanel() {};
1067 };
1068 ],[
1069         const char* p_UserData = static_cast<char*>(0)],
1070         [cf_cv_cpp_static_cast=yes],
1071         [cf_cv_cpp_static_cast=no])
1072
1073         AC_LANG_RESTORE
1074 ])
1075
1076 fi
1077
1078 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1079 ])dnl
1080 dnl ---------------------------------------------------------------------------
1081 dnl CF_CXX_AR_FLAGS version: 1 updated: 2011/10/29 08:35:34
1082 dnl ---------------
1083 dnl Setup special archiver flags for given compilers.
1084 AC_DEFUN([CF_CXX_AR_FLAGS],[
1085         CXX_AR='$(AR)'
1086         CXX_ARFLAGS='$(ARFLAGS)'
1087         case $cf_cv_system_name in #(vi
1088         irix*) #(vi
1089             if test "$GXX" != yes ; then
1090                 CXX_AR='$(CXX)'
1091                 CXX_ARFLAGS='-ar -o'
1092             fi
1093             ;;
1094         sco3.2v5*) #(vi
1095             CXXLDFLAGS="-u main"
1096             ;;
1097         solaris2*)
1098             if test "$GXX" != yes ; then
1099                 CXX_AR='$(CXX)'
1100                 CXX_ARFLAGS='-xar -o'
1101             fi
1102             ;;
1103         esac
1104         AC_SUBST(CXXLDFLAGS)
1105         AC_SUBST(CXX_AR)
1106         AC_SUBST(CXX_ARFLAGS)
1107 ])dnl
1108 dnl ---------------------------------------------------------------------------
1109 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1110 dnl -------------------------
1111 dnl For c++, check if iostream uses "std::" namespace.
1112 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1113 AC_CHECK_HEADERS(iostream)
1114 if test x"$ac_cv_header_iostream" = xyes ; then
1115         AC_MSG_CHECKING(if iostream uses std-namespace)
1116         AC_TRY_COMPILE([
1117 #include <iostream>
1118 using std::endl;
1119 using std::cerr;],[
1120 cerr << "testing" << endl;
1121 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1122         AC_MSG_RESULT($cf_iostream_namespace)
1123         if test "$cf_iostream_namespace" = yes ; then
1124                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1125         fi
1126 fi
1127 ])dnl
1128 dnl ---------------------------------------------------------------------------
1129 dnl CF_C_INLINE version: 4 updated: 2012/06/16 14:55:39
1130 dnl -----------
1131 dnl Check if the C compiler supports "inline".
1132 dnl $1 is the name of a shell variable to set if inline is supported
1133 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1134 AC_DEFUN([CF_C_INLINE],[
1135 AC_C_INLINE
1136 $1=
1137 if test "$ac_cv_c_inline" != no ; then
1138   $1=inline
1139   if test "$INTEL_COMPILER" = yes
1140   then
1141     :
1142   elif test "$CLANG_COMPILER" = yes
1143   then
1144     :
1145   elif test "$GCC" = yes
1146   then
1147     AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1148       cf_save_CFLAGS=$CFLAGS
1149       CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1150       AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1151       [${cf_cv_main_return:-return} foo()],
1152       [cf_cv_gcc_inline=yes],
1153       [cf_cv_gcc_inline=no])
1154       CFLAGS=$cf_save_CFLAGS
1155     ])
1156     if test "$cf_cv_gcc_inline" = yes ; then
1157         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1158     fi
1159   fi
1160 fi
1161 AC_SUBST($1)
1162 ])dnl
1163 dnl ---------------------------------------------------------------------------
1164 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1165 dnl ----------
1166 dnl "dirname" is not portable, so we fake it with a shell script.
1167 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1168 dnl ---------------------------------------------------------------------------
1169 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1170 dnl ---------------
1171 AC_DEFUN([CF_DIRS_TO_MAKE],
1172 [
1173 DIRS_TO_MAKE="lib"
1174 for cf_item in $cf_list_models
1175 do
1176         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1177         for cf_item2 in $DIRS_TO_MAKE
1178         do
1179                 test $cf_item2 = $cf_subdir && break
1180         done
1181         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1182 done
1183 for cf_dir in $DIRS_TO_MAKE
1184 do
1185         test ! -d $cf_dir && mkdir $cf_dir
1186 done
1187 AC_SUBST(DIRS_TO_MAKE)
1188 ])dnl
1189 dnl ---------------------------------------------------------------------------
1190 dnl CF_DISABLE_ECHO version: 12 updated: 2012/10/06 16:30:28
1191 dnl ---------------
1192 dnl You can always use "make -n" to see the actual options, but it's hard to
1193 dnl pick out/analyze warning messages when the compile-line is long.
1194 dnl
1195 dnl Sets:
1196 dnl     ECHO_LT - symbol to control if libtool is verbose
1197 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1198 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1199 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1200 dnl     ECHO_CC - symbol to put before any "cc" line
1201 dnl
1202 AC_DEFUN([CF_DISABLE_ECHO],[
1203 AC_MSG_CHECKING(if you want to see long compiling messages)
1204 CF_ARG_DISABLE(echo,
1205         [  --disable-echo          do not display "compiling" commands],
1206         [
1207     ECHO_LT='--silent'
1208     ECHO_LD='@echo linking [$]@;'
1209     RULE_CC='@echo compiling [$]<'
1210     SHOW_CC='@echo compiling [$]@'
1211     ECHO_CC='@'
1212 ],[
1213     ECHO_LT=''
1214     ECHO_LD=''
1215     RULE_CC=''
1216     SHOW_CC=''
1217     ECHO_CC=''
1218 ])
1219 AC_MSG_RESULT($enableval)
1220 AC_SUBST(ECHO_LT)
1221 AC_SUBST(ECHO_LD)
1222 AC_SUBST(RULE_CC)
1223 AC_SUBST(SHOW_CC)
1224 AC_SUBST(ECHO_CC)
1225 ])dnl
1226 dnl ---------------------------------------------------------------------------
1227 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1228 dnl ----------------
1229 dnl Combine no-leak checks with the libraries or tools that are used for the
1230 dnl checks.
1231 AC_DEFUN([CF_DISABLE_LEAKS],[
1232
1233 AC_REQUIRE([CF_WITH_DMALLOC])
1234 AC_REQUIRE([CF_WITH_DBMALLOC])
1235 AC_REQUIRE([CF_WITH_VALGRIND])
1236
1237 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1238 AC_ARG_ENABLE(leaks,
1239         [  --disable-leaks         test: free permanent memory, analyze leaks],
1240         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1241         : ${with_no_leaks:=no})
1242 AC_MSG_RESULT($with_no_leaks)
1243
1244 if test "$with_no_leaks" = yes ; then
1245         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1246         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1247 fi
1248 ])dnl
1249 dnl ---------------------------------------------------------------------------
1250 dnl CF_DISABLE_LIBTOOL_VERSION version: 1 updated: 2010/05/15 15:45:59
1251 dnl --------------------------
1252 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1253 dnl the older "-version-info" feature.  The newer feature allows us to use
1254 dnl version numbering on shared libraries which make them compatible with
1255 dnl various systems.
1256 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1257 [
1258 AC_MSG_CHECKING(if libtool -version-number should be used)
1259 CF_ARG_DISABLE(libtool-version,
1260         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1261         [cf_libtool_version=no],
1262         [cf_libtool_version=yes])
1263 AC_MSG_RESULT($cf_libtool_version)
1264
1265 if test "$cf_libtool_version" = yes ; then
1266         LIBTOOL_VERSION="-version-number"
1267 else
1268         LIBTOOL_VERSION="-version-info"
1269 fi
1270
1271 AC_SUBST(LIBTOOL_VERSION)
1272 ])dnl
1273 dnl ---------------------------------------------------------------------------
1274 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1275 dnl ---------------------
1276 dnl The rpath-hack makes it simpler to build programs, particularly with the
1277 dnl *BSD ports which may have essential libraries in unusual places.  But it
1278 dnl can interfere with building an executable for the base system.  Use this
1279 dnl option in that case.
1280 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1281 [
1282 AC_MSG_CHECKING(if rpath-hack should be disabled)
1283 CF_ARG_DISABLE(rpath-hack,
1284         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1285         [cf_disable_rpath_hack=yes],
1286         [cf_disable_rpath_hack=no])
1287 AC_MSG_RESULT($cf_disable_rpath_hack)
1288 if test "$cf_disable_rpath_hack" = no ; then
1289         CF_RPATH_HACK
1290 fi
1291 ])
1292 dnl ---------------------------------------------------------------------------
1293 dnl CF_ENABLE_PC_FILES version: 9 updated: 2012/08/04 13:59:54
1294 dnl ------------------
1295 dnl This is the "--enable-pc-files" option, which is available if there is a
1296 dnl pkg-config configuration on the local machine.
1297 AC_DEFUN([CF_ENABLE_PC_FILES],[
1298 AC_REQUIRE([CF_PKG_CONFIG])
1299 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1300
1301 if test "$PKG_CONFIG" != none ; then
1302         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1303         AC_ARG_ENABLE(pc-files,
1304                 [  --enable-pc-files       generate and install .pc files for pkg-config],
1305                 [enable_pc_files=$enableval],
1306                 [enable_pc_files=no])
1307         AC_MSG_RESULT($enable_pc_files)
1308         if test "$enable_pc_files" != no
1309         then
1310                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1311         fi
1312 else
1313         enable_pc_files=no
1314 fi
1315 ])dnl
1316 dnl ---------------------------------------------------------------------------
1317 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1318 dnl ---------------
1319 dnl Check if the rpath option should be used, setting cache variable
1320 dnl cf_cv_enable_rpath if so.
1321 AC_DEFUN([CF_ENABLE_RPATH],
1322 [
1323 AC_MSG_CHECKING(if rpath option should be used)
1324 AC_ARG_ENABLE(rpath,
1325 [  --enable-rpath          use rpath option when generating shared libraries],
1326 [cf_cv_enable_rpath=$enableval],
1327 [cf_cv_enable_rpath=no])
1328 AC_MSG_RESULT($cf_cv_enable_rpath)
1329 ])dnl
1330 dnl ---------------------------------------------------------------------------
1331 dnl CF_ENABLE_STRING_HACKS version: 3 updated: 2013/01/26 16:26:12
1332 dnl ----------------------
1333 dnl On a few platforms, the compiler and/or loader nags with untruthful
1334 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1335 dnl and implying that most uses of the recommended alternatives are correct.
1336 dnl
1337 dnl Factually speaking, no one has actually counted the number of uses of these
1338 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1339 dnl instances are meaningless compared to the hundreds of millions of lines of
1340 dnl existing C code.
1341 dnl
1342 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1343 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1344 dnl standard - but evolved through phases, and older implementations are likely
1345 dnl to yield surprising results, as documented in manpages on various systems.
1346 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1347 [
1348 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1349 AC_ARG_ENABLE(string-hacks,
1350         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1351         [with_string_hacks=$enableval],
1352         [with_string_hacks=no])
1353 AC_MSG_RESULT($with_string_hacks)
1354
1355 if test "x$with_string_hacks" = "xyes"; then
1356         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1357         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1358         AC_CHECK_FUNCS( strlcat strlcpy snprintf )
1359 fi
1360 ])dnl
1361 dnl ---------------------------------------------------------------------------
1362 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1363 dnl --------
1364 dnl Check if 'errno' is declared in <errno.h>
1365 AC_DEFUN([CF_ERRNO],
1366 [
1367 CF_CHECK_ERRNO(errno)
1368 ])dnl
1369 dnl ---------------------------------------------------------------------------
1370 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1371 dnl ---------------
1372 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1373 dnl math.h and builtin.h, only for ncurses
1374 AC_DEFUN([CF_ETIP_DEFINES],
1375 [
1376 AC_MSG_CHECKING(for special defines needed for etip.h)
1377 cf_save_CXXFLAGS="$CXXFLAGS"
1378 cf_result="none"
1379
1380 # etip.h includes ncurses.h which includes ncurses_dll.h
1381 # But ncurses_dll.h is generated - fix here.
1382 test -d include || mkdir include
1383 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1384
1385 for cf_math in "" MATH_H
1386 do
1387 for cf_excp in "" MATH_EXCEPTION
1388 do
1389         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1390         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1391         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1392 AC_TRY_COMPILE([
1393 #include <etip.h.in>
1394 ],[],[
1395         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1396         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1397         cf_result="$cf_math $cf_excp"
1398         break 2
1399 ],[])
1400 done
1401 done
1402 AC_MSG_RESULT($cf_result)
1403 CXXFLAGS="$cf_save_CXXFLAGS"
1404 ])
1405 dnl ---------------------------------------------------------------------------
1406 dnl CF_FIND_LINKAGE version: 19 updated: 2010/05/29 16:31:02
1407 dnl ---------------
1408 dnl Find a library (specifically the linkage used in the code fragment),
1409 dnl searching for it if it is not already in the library path.
1410 dnl See also CF_ADD_SEARCHPATH.
1411 dnl
1412 dnl Parameters (4-on are optional):
1413 dnl     $1 = headers for library entrypoint
1414 dnl     $2 = code fragment for library entrypoint
1415 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1416 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1417 dnl     $5 = action to perform if not successful
1418 dnl     $6 = module name, if not the same as the library name
1419 dnl     $7 = extra libraries
1420 dnl
1421 dnl Sets these variables:
1422 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1423 dnl     $cf_cv_header_path_$3 - include-directory if needed
1424 dnl     $cf_cv_library_path_$3 - library-directory if needed
1425 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1426 AC_DEFUN([CF_FIND_LINKAGE],[
1427
1428 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1429 # will be set on completion of the AC_TRY_LINK below.
1430 cf_cv_header_path_$3=
1431 cf_cv_library_path_$3=
1432
1433 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1434
1435 cf_save_LIBS="$LIBS"
1436
1437 AC_TRY_LINK([$1],[$2],[
1438         cf_cv_find_linkage_$3=yes
1439         cf_cv_header_path_$3=/usr/include
1440         cf_cv_library_path_$3=/usr/lib
1441 ],[
1442
1443 LIBS="-l$3 $7 $cf_save_LIBS"
1444
1445 AC_TRY_LINK([$1],[$2],[
1446         cf_cv_find_linkage_$3=yes
1447         cf_cv_header_path_$3=/usr/include
1448         cf_cv_library_path_$3=/usr/lib
1449         cf_cv_library_file_$3="-l$3"
1450 ],[
1451         cf_cv_find_linkage_$3=no
1452         LIBS="$cf_save_LIBS"
1453
1454     CF_VERBOSE(find linkage for $3 library)
1455     CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1456
1457     cf_save_CPPFLAGS="$CPPFLAGS"
1458     cf_test_CPPFLAGS="$CPPFLAGS"
1459
1460     CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1461     for cf_cv_header_path_$3 in $cf_search
1462     do
1463       if test -d $cf_cv_header_path_$3 ; then
1464         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1465         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1466         AC_TRY_COMPILE([$1],[$2],[
1467             CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1468             cf_cv_find_linkage_$3=maybe
1469             cf_test_CPPFLAGS="$CPPFLAGS"
1470             break],[
1471             CPPFLAGS="$cf_save_CPPFLAGS"
1472             ])
1473       fi
1474     done
1475
1476     if test "$cf_cv_find_linkage_$3" = maybe ; then
1477
1478       CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1479
1480       cf_save_LIBS="$LIBS"
1481       cf_save_LDFLAGS="$LDFLAGS"
1482
1483       ifelse([$6],,,[
1484         CPPFLAGS="$cf_test_CPPFLAGS"
1485         LIBS="-l$3 $7 $cf_save_LIBS"
1486         AC_TRY_LINK([$1],[$2],[
1487             CF_VERBOSE(... found $3 library in system)
1488             cf_cv_find_linkage_$3=yes])
1489             CPPFLAGS="$cf_save_CPPFLAGS"
1490             LIBS="$cf_save_LIBS"
1491             ])
1492
1493       if test "$cf_cv_find_linkage_$3" != yes ; then
1494         CF_LIBRARY_PATH(cf_search,$3)
1495         for cf_cv_library_path_$3 in $cf_search
1496         do
1497           if test -d $cf_cv_library_path_$3 ; then
1498             CF_VERBOSE(... testing $cf_cv_library_path_$3)
1499             CPPFLAGS="$cf_test_CPPFLAGS"
1500             LIBS="-l$3 $7 $cf_save_LIBS"
1501             LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1502             AC_TRY_LINK([$1],[$2],[
1503                 CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1504                 cf_cv_find_linkage_$3=yes
1505                 cf_cv_library_file_$3="-l$3"
1506                 break],[
1507                 CPPFLAGS="$cf_save_CPPFLAGS"
1508                 LIBS="$cf_save_LIBS"
1509                 LDFLAGS="$cf_save_LDFLAGS"
1510                 ])
1511           fi
1512         done
1513         CPPFLAGS="$cf_save_CPPFLAGS"
1514         LDFLAGS="$cf_save_LDFLAGS"
1515       fi
1516
1517     else
1518       cf_cv_find_linkage_$3=no
1519     fi
1520     ],$7)
1521 ])
1522
1523 LIBS="$cf_save_LIBS"
1524
1525 if test "$cf_cv_find_linkage_$3" = yes ; then
1526 ifelse([$4],,[
1527         CF_ADD_INCDIR($cf_cv_header_path_$3)
1528         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1529         CF_ADD_LIB($3)
1530 ],[$4])
1531 else
1532 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1533 fi
1534 ])dnl
1535 dnl ---------------------------------------------------------------------------
1536 dnl CF_FIXUP_ADAFLAGS version: 1 updated: 2012/03/31 18:48:10
1537 dnl -----------------
1538 dnl make ADAFLAGS consistent with CFLAGS
1539 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1540         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1541         case "$CFLAGS" in
1542         *-g*)
1543                 CF_ADD_ADAFLAGS(-g)
1544                 ;;
1545         esac
1546         case "$CFLAGS" in
1547         *-O*)
1548                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1549                 CF_ADD_ADAFLAGS($cf_O_flag)
1550                 ;;
1551         esac
1552         AC_MSG_RESULT($ADAFLAGS)
1553 ])dnl
1554 dnl ---------------------------------------------------------------------------
1555 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
1556 dnl --------------
1557 dnl Forget that we saw the given tool.
1558 AC_DEFUN([CF_FORGET_TOOL],[
1559 unset ac_cv_prog_ac_ct_$1
1560 unset ac_ct_$1
1561 unset $1
1562 ])dnl
1563 dnl ---------------------------------------------------------------------------
1564 dnl CF_FUNC_DLSYM version: 3 updated: 2012/10/06 11:17:15
1565 dnl -------------
1566 dnl Test for dlsym() and related functions, as well as libdl.
1567 dnl
1568 dnl Sets
1569 dnl     $cf_have_dlsym
1570 dnl     $cf_have_libdl
1571 AC_DEFUN([CF_FUNC_DLSYM],[
1572 cf_have_dlsym=no
1573 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1574
1575 cf_have_libdl=no
1576 AC_CHECK_LIB(dl,dlsym,[
1577         cf_have_dlsym=yes
1578         cf_have_libdl=yes])])
1579
1580 if test "$cf_have_dlsym" = yes ; then
1581         test "$cf_have_libdl" = yes && CF_ADD_LIB(dl)
1582
1583         AC_MSG_CHECKING(whether able to link to dl*() functions)
1584         AC_TRY_LINK([#include <dlfcn.h>],[
1585                 void *obj;
1586                 if ((obj = dlopen("filename", 0)) != 0) {
1587                         if (dlsym(obj, "symbolname") == 0) {
1588                         dlclose(obj);
1589                         }
1590                 }],[
1591                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
1592                 AC_MSG_ERROR(Cannot link test program for libdl)])
1593         AC_MSG_RESULT(ok)
1594 else
1595         AC_MSG_ERROR(Cannot find dlsym function)
1596 fi
1597 ])
1598 dnl ---------------------------------------------------------------------------
1599 dnl CF_FUNC_MEMMOVE version: 8 updated: 2012/10/04 20:12:20
1600 dnl ---------------
1601 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1602 dnl is found, add our own version of memmove to the list of objects.
1603 AC_DEFUN([CF_FUNC_MEMMOVE],
1604 [
1605 AC_CHECK_FUNC(memmove,,[
1606 AC_CHECK_FUNC(bcopy,[
1607         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1608                 AC_TRY_RUN([
1609 int main() {
1610         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1611         char temp[40];
1612         bcopy(data, temp, sizeof(data));
1613         bcopy(temp+10, temp, 15);
1614         bcopy(temp+5, temp+15, 10);
1615         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1616 }
1617                 ],
1618                 [cf_cv_good_bcopy=yes],
1619                 [cf_cv_good_bcopy=no],
1620                 [cf_cv_good_bcopy=unknown])
1621                 ])
1622         ],[cf_cv_good_bcopy=no])
1623         if test "$cf_cv_good_bcopy" = yes ; then
1624                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
1625         else
1626                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
1627         fi
1628 ])])dnl
1629 dnl ---------------------------------------------------------------------------
1630 dnl CF_FUNC_NANOSLEEP version: 4 updated: 2012/10/06 17:56:13
1631 dnl -----------------
1632 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1633 dnl AIX 4.x, provide a non-working version.
1634 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1635 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1636 AC_TRY_RUN([
1637 #include <stdio.h>
1638 #include <errno.h>
1639 #include <time.h>
1640
1641 #ifdef HAVE_SYS_TIME_H
1642 #include <sys/time.h>
1643 #endif
1644
1645 int main() {
1646         struct timespec ts1, ts2;
1647         int code;
1648         ts1.tv_sec  = 0;
1649         ts1.tv_nsec = 750000000;
1650         ts2.tv_sec  = 0;
1651         ts2.tv_nsec = 0;
1652         errno = 0;
1653         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1654         ${cf_cv_main_return:-return}(code != 0);
1655 }
1656 ],
1657         [cf_cv_func_nanosleep=yes],
1658         [cf_cv_func_nanosleep=no],
1659         [cf_cv_func_nanosleep=unknown])])
1660
1661 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
1662 ])
1663 dnl ---------------------------------------------------------------------------
1664 dnl CF_FUNC_OPENPTY version: 3 updated: 2010/05/29 16:31:02
1665 dnl ---------------
1666 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1667 dnl "util" library as well.
1668 AC_DEFUN([CF_FUNC_OPENPTY],
1669 [
1670 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1671 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1672     cf_save_LIBS="$LIBS"
1673     test $cf_cv_lib_util = yes && CF_ADD_LIB(util)
1674     for cf_header in pty.h libutil.h util.h
1675     do
1676     AC_TRY_LINK([
1677 #include <$cf_header>
1678 ],[
1679     int x = openpty((int *)0, (int *)0, (char *)0,
1680                    (struct termios *)0, (struct winsize *)0);
1681 ],[
1682         cf_cv_func_openpty=$cf_header
1683         break
1684 ],[
1685         cf_cv_func_openpty=no
1686 ])
1687     done
1688     LIBS="$cf_save_LIBS"
1689 ])
1690 ])dnl
1691 dnl ---------------------------------------------------------------------------
1692 dnl CF_FUNC_POLL version: 8 updated: 2012/10/04 05:24:07
1693 dnl ------------
1694 dnl See if the poll function really works.  Some platforms have poll(), but
1695 dnl it does not work for terminals or files.
1696 AC_DEFUN([CF_FUNC_POLL],[
1697 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
1698 AC_TRY_RUN([
1699 #include <stdlib.h>
1700 #include <stdio.h>
1701 #include <unistd.h>
1702 #include <fcntl.h>
1703 #ifdef HAVE_POLL_H
1704 #include <poll.h>
1705 #else
1706 #include <sys/poll.h>
1707 #endif
1708 int main() {
1709         struct pollfd myfds;
1710         int ret;
1711
1712         /* check for Darwin bug with respect to "devices" */
1713         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
1714         if (myfds.fd < 0)
1715                 myfds.fd = 0;
1716         myfds.events = POLLIN;
1717         myfds.revents = 0;
1718
1719         ret = poll(&myfds, 1, 100);
1720
1721         if (ret < 0 || (myfds.revents & POLLNVAL)) {
1722                 ret = -1;
1723         } else {
1724                 int fd = 0;
1725                 if (!isatty(fd)) {
1726                         fd = open("/dev/tty", 2);       /* O_RDWR */
1727                 }
1728
1729                 if (fd >= 0) {
1730                         /* also check with standard input */
1731                         myfds.fd = fd;
1732                         myfds.events = POLLIN;
1733                         myfds.revents = 0;
1734                         ret = poll(&myfds, 1, 100);
1735                 } else {
1736                         ret = -1;
1737                 }
1738         }
1739         ${cf_cv_main_return:-return}(ret < 0);
1740 }],
1741         [cf_cv_working_poll=yes],
1742         [cf_cv_working_poll=no],
1743         [cf_cv_working_poll=unknown])])
1744 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
1745 ])dnl
1746 dnl ---------------------------------------------------------------------------
1747 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
1748 dnl ---------------
1749 dnl Some old/broken variations define tcgetattr() only as a macro in
1750 dnl termio(s).h
1751 AC_DEFUN([CF_FUNC_TERMIOS],[
1752 AC_REQUIRE([CF_STRUCT_TERMIOS])
1753 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
1754 AC_TRY_LINK([
1755 #include <sys/types.h>
1756 #ifdef HAVE_UNISTD_H
1757 #include <unistd.h>
1758 #endif
1759 #ifdef HAVE_TERMIOS_H
1760 #include <termios.h>
1761 #define TTY struct termios
1762 #else
1763 #ifdef HAVE_TERMIO_H
1764 #include <termio.h>
1765 #define TTY struct termio
1766 #endif
1767 #endif
1768 ],[
1769 TTY foo;
1770 tcgetattr(1, &foo);],
1771 [cf_cv_have_tcgetattr=yes],
1772 [cf_cv_have_tcgetattr=no])])
1773 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
1774 ])dnl
1775 dnl ---------------------------------------------------------------------------
1776 dnl CF_FUNC_VSSCANF version: 4 updated: 2012/10/06 17:56:13
1777 dnl ---------------
1778 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
1779 dnl versions of C.  It is in the GNU C library, and can often be simulated by
1780 dnl other functions.
1781 AC_DEFUN([CF_FUNC_VSSCANF],
1782 [
1783 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
1784 AC_TRY_LINK([
1785 #include <stdarg.h>
1786 #include <stdio.h>],[
1787         va_list ap;
1788         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
1789 AC_TRY_LINK([
1790 #include <stdarg.h>
1791 #include <stdio.h>],[
1792     FILE strbuf;
1793     char *str = "from";
1794
1795     strbuf._flag = _IOREAD;
1796     strbuf._ptr = strbuf._base = (unsigned char *) str;
1797     strbuf._cnt = strlen(str);
1798     strbuf._file = _NFILE;
1799     return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
1800 AC_TRY_LINK([
1801 #include <stdarg.h>
1802 #include <stdio.h>],[
1803     FILE strbuf;
1804     char *str = "from";
1805
1806     strbuf._flag = _IOREAD;
1807     strbuf._ptr = strbuf._base = (unsigned char *) str;
1808     strbuf._cnt = strlen(str);
1809     strbuf._file = _NFILE;
1810     return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
1811 cf_cv_func_vsscanf=no])])])])
1812
1813 case $cf_cv_func_vsscanf in #(vi
1814 vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);; #(vi
1815 vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);; #(vi
1816 _doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
1817 esac
1818
1819 ])dnl
1820 dnl ---------------------------------------------------------------------------
1821 dnl CF_GCC_ATTRIBUTES version: 16 updated: 2012/10/02 20:55:03
1822 dnl -----------------
1823 dnl Test for availability of useful gcc __attribute__ directives to quiet
1824 dnl compiler warnings.  Though useful, not all are supported -- and contrary
1825 dnl to documentation, unrecognized directives cause older compilers to barf.
1826 AC_DEFUN([CF_GCC_ATTRIBUTES],
1827 [
1828 if test "$GCC" = yes
1829 then
1830 cat > conftest.i <<EOF
1831 #ifndef GCC_PRINTF
1832 #define GCC_PRINTF 0
1833 #endif
1834 #ifndef GCC_SCANF
1835 #define GCC_SCANF 0
1836 #endif
1837 #ifndef GCC_NORETURN
1838 #define GCC_NORETURN /* nothing */
1839 #endif
1840 #ifndef GCC_UNUSED
1841 #define GCC_UNUSED /* nothing */
1842 #endif
1843 EOF
1844 if test "$GCC" = yes
1845 then
1846         AC_CHECKING([for $CC __attribute__ directives])
1847 cat > conftest.$ac_ext <<EOF
1848 #line __oline__ "${as_me:-configure}"
1849 #include "confdefs.h"
1850 #include "conftest.h"
1851 #include "conftest.i"
1852 #if     GCC_PRINTF
1853 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
1854 #else
1855 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
1856 #endif
1857 #if     GCC_SCANF
1858 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
1859 #else
1860 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
1861 #endif
1862 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
1863 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
1864 extern void foo(void) GCC_NORETURN;
1865 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
1866 EOF
1867         cf_printf_attribute=no
1868         cf_scanf_attribute=no
1869         for cf_attribute in scanf printf unused noreturn
1870         do
1871                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
1872                 cf_directive="__attribute__(($cf_attribute))"
1873                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
1874
1875                 case $cf_attribute in #(vi
1876                 printf) #(vi
1877                         cf_printf_attribute=yes
1878                         cat >conftest.h <<EOF
1879 #define GCC_$cf_ATTRIBUTE 1
1880 EOF
1881                         ;;
1882                 scanf) #(vi
1883                         cf_scanf_attribute=yes
1884                         cat >conftest.h <<EOF
1885 #define GCC_$cf_ATTRIBUTE 1
1886 EOF
1887                         ;;
1888                 *) #(vi
1889                         cat >conftest.h <<EOF
1890 #define GCC_$cf_ATTRIBUTE $cf_directive
1891 EOF
1892                         ;;
1893                 esac
1894
1895                 if AC_TRY_EVAL(ac_compile); then
1896                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
1897                         cat conftest.h >>confdefs.h
1898                         case $cf_attribute in #(vi
1899                         noreturn) #(vi
1900                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
1901                                 ;;
1902                         printf) #(vi
1903                                 cf_value='/* nothing */'
1904                                 if test "$cf_printf_attribute" != no ; then
1905                                         cf_value='__attribute__((format(printf,fmt,var)))'
1906                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
1907                                 fi
1908                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
1909                                 ;;
1910                         scanf) #(vi
1911                                 cf_value='/* nothing */'
1912                                 if test "$cf_scanf_attribute" != no ; then
1913                                         cf_value='__attribute__((format(scanf,fmt,var)))'
1914                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
1915                                 fi
1916                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
1917                                 ;;
1918                         unused) #(vi
1919                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
1920                                 ;;
1921                         esac
1922                 fi
1923         done
1924 else
1925         fgrep define conftest.i >>confdefs.h
1926 fi
1927 rm -rf conftest*
1928 fi
1929 ])dnl
1930 dnl ---------------------------------------------------------------------------
1931 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
1932 dnl --------------
1933 dnl Find version of gcc
1934 AC_DEFUN([CF_GCC_VERSION],[
1935 AC_REQUIRE([AC_PROG_CC])
1936 GCC_VERSION=none
1937 if test "$GCC" = yes ; then
1938         AC_MSG_CHECKING(version of $CC)
1939         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1940         test -z "$GCC_VERSION" && GCC_VERSION=unknown
1941         AC_MSG_RESULT($GCC_VERSION)
1942 fi
1943 ])dnl
1944 dnl ---------------------------------------------------------------------------
1945 dnl CF_GCC_WARNINGS version: 30 updated: 2013/11/16 13:56:26
1946 dnl ---------------
1947 dnl Check if the compiler supports useful warning options.  There's a few that
1948 dnl we don't use, simply because they're too noisy:
1949 dnl
1950 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
1951 dnl     -Wredundant-decls (system headers make this too noisy)
1952 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
1953 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
1954 dnl             is enabled for ncurses using "--enable-const".
1955 dnl     -pedantic
1956 dnl
1957 dnl Parameter:
1958 dnl     $1 is an optional list of gcc warning flags that a particular
1959 dnl             application might want to use, e.g., "no-unused" for
1960 dnl             -Wno-unused
1961 dnl Special:
1962 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
1963 dnl
1964 AC_DEFUN([CF_GCC_WARNINGS],
1965 [
1966 AC_REQUIRE([CF_GCC_VERSION])
1967 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
1968 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
1969
1970 cat > conftest.$ac_ext <<EOF
1971 #line __oline__ "${as_me:-configure}"
1972 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
1973 EOF
1974
1975 if test "$INTEL_COMPILER" = yes
1976 then
1977 # The "-wdXXX" options suppress warnings:
1978 # remark #1419: external declaration in primary source file
1979 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
1980 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
1981 # remark #193: zero used for undefined preprocessing identifier
1982 # remark #593: variable "curs_sb_left_arrow" was set but never used
1983 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
1984 # remark #869: parameter "tw" was never referenced
1985 # remark #981: operands are evaluated in unspecified order
1986 # warning #279: controlling expression is constant
1987
1988         AC_CHECKING([for $CC warning options])
1989         cf_save_CFLAGS="$CFLAGS"
1990         EXTRA_CFLAGS="-Wall"
1991         for cf_opt in \
1992                 wd1419 \
1993                 wd1683 \
1994                 wd1684 \
1995                 wd193 \
1996                 wd593 \
1997                 wd279 \
1998                 wd810 \
1999                 wd869 \
2000                 wd981
2001         do
2002                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2003                 if AC_TRY_EVAL(ac_compile); then
2004                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2005                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2006                 fi
2007         done
2008         CFLAGS="$cf_save_CFLAGS"
2009
2010 elif test "$GCC" = yes
2011 then
2012         AC_CHECKING([for $CC warning options])
2013         cf_save_CFLAGS="$CFLAGS"
2014         EXTRA_CFLAGS=
2015         cf_warn_CONST=""
2016         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2017         for cf_opt in W Wall \
2018                 Wbad-function-cast \
2019                 Wcast-align \
2020                 Wcast-qual \
2021                 Wdeclaration-after-statement \
2022                 Wextra \
2023                 Wignored-qualifiers \
2024                 Winline \
2025                 Wlogical-op \
2026                 Wmissing-declarations \
2027                 Wmissing-prototypes \
2028                 Wnested-externs \
2029                 Wpointer-arith \
2030                 Wshadow \
2031                 Wstrict-prototypes \
2032                 Wundef \
2033                 Wvarargs $cf_warn_CONST $1
2034         do
2035                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2036                 if AC_TRY_EVAL(ac_compile); then
2037                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2038                         case $cf_opt in #(vi
2039                         Wcast-qual) #(vi
2040                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
2041                                 ;;
2042                         Winline) #(vi
2043                                 case $GCC_VERSION in
2044                                 [[34]].*)
2045                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2046                                         continue;;
2047                                 esac
2048                                 ;;
2049                         Wpointer-arith) #(vi
2050                                 case $GCC_VERSION in
2051                                 [[12]].*)
2052                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2053                                         continue;;
2054                                 esac
2055                                 ;;
2056                         esac
2057                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2058                 fi
2059         done
2060         CFLAGS="$cf_save_CFLAGS"
2061 fi
2062 rm -rf conftest*
2063
2064 AC_SUBST(EXTRA_CFLAGS)
2065 ])dnl
2066 dnl ---------------------------------------------------------------------------
2067 dnl CF_GETOPT_HEADER version: 5 updated: 2012/10/06 16:39:58
2068 dnl ----------------
2069 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2070 dnl unistd.h or (nonstandard) in getopt.h
2071 AC_DEFUN([CF_GETOPT_HEADER],
2072 [
2073 AC_HAVE_HEADERS(unistd.h getopt.h)
2074 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2075 cf_cv_getopt_header=none
2076 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2077 do
2078 AC_TRY_COMPILE([
2079 #include <$cf_header>],
2080 [int x = optind; char *y = optarg],
2081 [cf_cv_getopt_header=$cf_header
2082  break])
2083 done
2084 ])
2085 if test $cf_cv_getopt_header != none ; then
2086         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if we need to include getopt.h])
2087 fi
2088 ])dnl
2089 dnl ---------------------------------------------------------------------------
2090 dnl CF_GNAT_GENERICS version: 2 updated: 2011/03/23 20:24:41
2091 dnl ----------------
2092 AC_DEFUN([CF_GNAT_GENERICS],
2093 [
2094 AC_REQUIRE([CF_GNAT_VERSION])
2095
2096 AC_MSG_CHECKING(if GNAT supports generics)
2097 case $cf_gnat_version in #(vi
2098 3.[[1-9]]*|[[4-9]].*) #(vi
2099         cf_gnat_generics=yes
2100         ;;
2101 *)
2102         cf_gnat_generics=no
2103         ;;
2104 esac
2105 AC_MSG_RESULT($cf_gnat_generics)
2106
2107 if test "$cf_gnat_generics" = yes
2108 then
2109         cf_compile_generics=generics
2110         cf_generic_objects="\${GENOBJS}"
2111 else
2112         cf_compile_generics=
2113         cf_generic_objects=
2114 fi
2115
2116 AC_SUBST(cf_compile_generics)
2117 AC_SUBST(cf_generic_objects)
2118 ])dnl
2119 dnl ---------------------------------------------------------------------------
2120 dnl CF_GNAT_PRAGMA_UNREF version: 1 updated: 2010/06/19 15:22:18
2121 dnl --------------------
2122 dnl Check if the gnat pragma "Unreferenced" works.
2123 AC_DEFUN([CF_GNAT_PRAGMA_UNREF],[
2124 AC_CACHE_CHECK(if GNAT pragma Unreferenced works,cf_cv_pragma_unreferenced,[
2125 CF_GNAT_TRY_LINK([procedure conftest;],
2126 [with Text_IO;
2127 with GNAT.OS_Lib;
2128 procedure conftest is
2129    test : Integer;
2130    pragma Unreferenced (test);
2131 begin
2132    test := 1;
2133    Text_IO.Put ("Hello World");
2134    Text_IO.New_Line;
2135    GNAT.OS_Lib.OS_Exit (0);
2136 end conftest;],
2137         [cf_cv_pragma_unreferenced=yes],
2138         [cf_cv_pragma_unreferenced=no])])
2139
2140 # if the pragma is supported, use it (needed in the Trace code).
2141 if test $cf_cv_pragma_unreferenced = yes ; then
2142         PRAGMA_UNREF=TRUE
2143 else
2144         PRAGMA_UNREF=FALSE
2145 fi
2146 AC_SUBST(PRAGMA_UNREF)
2147 ])dnl
2148 dnl ---------------------------------------------------------------------------
2149 dnl CF_GNAT_PROJECTS version: 4 updated: 2013/09/07 14:05:46
2150 dnl ----------------
2151 dnl GNAT projects are configured with ".gpr" project files.
2152 dnl GNAT libraries are a further development, using the project feature.
2153 AC_DEFUN([CF_GNAT_PROJECTS],
2154 [
2155 AC_REQUIRE([CF_GNAT_VERSION])
2156
2157 cf_gnat_libraries=no
2158 cf_gnat_projects=no
2159
2160 AC_MSG_CHECKING(if GNAT supports project files)
2161 case $cf_gnat_version in #(vi
2162 3.[[0-9]]*) #(vi
2163         ;;
2164 *)
2165         case $cf_cv_system_name in #(vi
2166         cygwin*|msys*) #(vi
2167                 ;;
2168         *)
2169                 mkdir conftest.src conftest.bin conftest.lib
2170                 cd conftest.src
2171                 rm -rf conftest* *~conftest*
2172                 cat >>library.gpr <<CF_EOF
2173 project Library is
2174   Kind := External ("LIB_KIND");
2175   for Library_Name use "ConfTest";
2176   for Object_Dir use ".";
2177   for Library_ALI_Dir use External("LIBRARY_DIR");
2178   for Library_Version use External ("SONAME");
2179   for Library_Kind use Kind;
2180   for Library_Dir use External("BUILD_DIR");
2181   Source_Dir := External ("SOURCE_DIR");
2182   for Source_Dirs use (Source_Dir);
2183   package Compiler is
2184      for Default_Switches ("Ada") use
2185        ("-g",
2186         "-O2",
2187         "-gnatafno",
2188         "-gnatVa",   -- All validity checks
2189         "-gnatwa");  -- Activate all optional errors
2190   end Compiler;
2191 end Library;
2192 CF_EOF
2193                 cat >>confpackage.ads <<CF_EOF
2194 package ConfPackage is
2195    procedure conftest;
2196 end ConfPackage;
2197 CF_EOF
2198                 cat >>confpackage.adb <<CF_EOF
2199 with Text_IO;
2200 package body ConfPackage is
2201    procedure conftest is
2202    begin
2203       Text_IO.Put ("Hello World");
2204       Text_IO.New_Line;
2205    end conftest;
2206 end ConfPackage;
2207 CF_EOF
2208                 if ( $cf_ada_make $ADAFLAGS \
2209                                 -Plibrary.gpr \
2210                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2211                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2212                                 -XSOURCE_DIR=`pwd` \
2213                                 -XSONAME=libConfTest.so.1 \
2214                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2215                         cf_gnat_projects=yes
2216                 fi
2217                 cd ..
2218                 if test -f conftest.lib/confpackage.ali
2219                 then
2220                         cf_gnat_libraries=yes
2221                 fi
2222                 rm -rf conftest* *~conftest*
2223                 ;;
2224         esac
2225         ;;
2226 esac
2227 AC_MSG_RESULT($cf_gnat_projects)
2228
2229 if test $cf_gnat_projects = yes
2230 then
2231         AC_MSG_CHECKING(if GNAT supports libraries)
2232         AC_MSG_RESULT($cf_gnat_libraries)
2233 fi
2234
2235 if test "$cf_gnat_projects" = yes
2236 then
2237         USE_OLD_MAKERULES="#"
2238         USE_GNAT_PROJECTS=""
2239 else
2240         USE_OLD_MAKERULES=""
2241         USE_GNAT_PROJECTS="#"
2242 fi
2243
2244 if test "$cf_gnat_libraries" = yes
2245 then
2246         USE_GNAT_LIBRARIES=""
2247 else
2248         USE_GNAT_LIBRARIES="#"
2249 fi
2250
2251 AC_SUBST(USE_OLD_MAKERULES)
2252 AC_SUBST(USE_GNAT_PROJECTS)
2253 AC_SUBST(USE_GNAT_LIBRARIES)
2254 ])dnl
2255 dnl ---------------------------------------------------------------------------
2256 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2257 dnl --------------
2258 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2259 dnl is noted that gnat may compile a tasking unit even for configurations which
2260 dnl fail at runtime.
2261 AC_DEFUN([CF_GNAT_SIGINT],[
2262 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2263 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2264
2265 package ConfTest is
2266
2267    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2268    pragma Unreserve_All_Interrupts;
2269    pragma Warnings (On);
2270
2271    protected Process is
2272       procedure Stop;
2273       function Continue return Boolean;
2274       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2275    private
2276       Done : Boolean := False;
2277    end Process;
2278
2279 end ConfTest;],
2280 [package body ConfTest is
2281    protected body Process is
2282       procedure Stop is
2283       begin
2284          Done := True;
2285       end Stop;
2286       function Continue return Boolean is
2287       begin
2288          return not Done;
2289       end Continue;
2290    end Process;
2291 end ConfTest;],
2292         [cf_cv_gnat_sigint=yes],
2293         [cf_cv_gnat_sigint=no])])
2294
2295 if test $cf_cv_gnat_sigint = yes ; then
2296         USE_GNAT_SIGINT=""
2297 else
2298         USE_GNAT_SIGINT="#"
2299 fi
2300 AC_SUBST(USE_GNAT_SIGINT)
2301 ])dnl
2302 dnl ---------------------------------------------------------------------------
2303 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2304 dnl ----------------
2305 dnl Verify that a test program compiles/links with GNAT.
2306 dnl $cf_ada_make is set to the program that compiles/links
2307 dnl $ADAFLAGS may be set to the GNAT flags.
2308 dnl
2309 dnl $1 is the text of the spec
2310 dnl $2 is the text of the body
2311 dnl $3 is the shell command to execute if successful
2312 dnl $4 is the shell command to execute if not successful
2313 AC_DEFUN([CF_GNAT_TRY_LINK],
2314 [
2315 rm -rf conftest* *~conftest*
2316 cat >>conftest.ads <<CF_EOF
2317 $1
2318 CF_EOF
2319 cat >>conftest.adb <<CF_EOF
2320 $2
2321 CF_EOF
2322 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2323 ifelse($3,,      :,[      $3])
2324 ifelse($4,,,[else
2325    $4])
2326 fi
2327 rm -rf conftest* *~conftest*
2328 ])dnl
2329 dnl ---------------------------------------------------------------------------
2330 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2331 dnl ---------------
2332 dnl Verify that a test program compiles and runs with GNAT
2333 dnl $cf_ada_make is set to the program that compiles/links
2334 dnl $ADAFLAGS may be set to the GNAT flags.
2335 dnl
2336 dnl $1 is the text of the spec
2337 dnl $2 is the text of the body
2338 dnl $3 is the shell command to execute if successful
2339 dnl $4 is the shell command to execute if not successful
2340 AC_DEFUN([CF_GNAT_TRY_RUN],
2341 [
2342 rm -rf conftest* *~conftest*
2343 cat >>conftest.ads <<CF_EOF
2344 $1
2345 CF_EOF
2346 cat >>conftest.adb <<CF_EOF
2347 $2
2348 CF_EOF
2349 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2350    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2351 ifelse($3,,      :,[      $3])
2352 ifelse($4,,,[   else
2353       $4])
2354    fi
2355 ifelse($4,,,[else
2356    $4])
2357 fi
2358 rm -rf conftest* *~conftest*
2359 ])dnl
2360 dnl ---------------------------------------------------------------------------
2361 dnl CF_GNAT_VERSION version: 18 updated: 2012/01/21 19:28:10
2362 dnl ---------------
2363 dnl Verify version of GNAT.
2364 AC_DEFUN([CF_GNAT_VERSION],
2365 [
2366 AC_MSG_CHECKING(for gnat version)
2367 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2368         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2369     sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2370 AC_MSG_RESULT($cf_gnat_version)
2371
2372 case $cf_gnat_version in #(vi
2373 3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]]) #(vi
2374         cf_cv_prog_gnat_correct=yes
2375         ;;
2376 *)
2377         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2378         cf_cv_prog_gnat_correct=no
2379         ;;
2380 esac
2381 ])
2382 dnl ---------------------------------------------------------------------------
2383 dnl CF_GNU_SOURCE version: 6 updated: 2005/07/09 13:23:07
2384 dnl -------------
2385 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2386 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2387 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2388 dnl since it is interwoven with GNU extensions.
2389 dnl
2390 dnl Well, yes we could work around it...
2391 AC_DEFUN([CF_GNU_SOURCE],
2392 [
2393 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2394 AC_TRY_COMPILE([#include <sys/types.h>],[
2395 #ifndef _XOPEN_SOURCE
2396 make an error
2397 #endif],
2398         [cf_cv_gnu_source=no],
2399         [cf_save="$CPPFLAGS"
2400          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2401          AC_TRY_COMPILE([#include <sys/types.h>],[
2402 #ifdef _XOPEN_SOURCE
2403 make an error
2404 #endif],
2405         [cf_cv_gnu_source=no],
2406         [cf_cv_gnu_source=yes])
2407         CPPFLAGS="$cf_save"
2408         ])
2409 ])
2410 test "$cf_cv_gnu_source" = yes && CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2411 ])dnl
2412 dnl ---------------------------------------------------------------------------
2413 dnl CF_GPP_LIBRARY version: 11 updated: 2012/10/06 17:56:13
2414 dnl --------------
2415 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2416 dnl problem :-).  If we have the compiler but no library, we'll be able to
2417 dnl configure, but won't be able to build the c++ demo program.
2418 AC_DEFUN([CF_GPP_LIBRARY],
2419 [
2420 cf_cxx_library=unknown
2421 case $cf_cv_system_name in #(vi
2422 os2*) #(vi
2423         cf_gpp_libname=gpp
2424         ;;
2425 *)
2426         cf_gpp_libname=g++
2427         ;;
2428 esac
2429 if test "$GXX" = yes; then
2430         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2431         cf_save="$LIBS"
2432         CF_ADD_LIB($cf_gpp_libname)
2433         AC_TRY_LINK([
2434 #include <$cf_gpp_libname/builtin.h>
2435         ],
2436         [two_arg_error_handler_t foo2 = lib_error_handler],
2437         [cf_cxx_library=yes
2438          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2439          if test "$cf_gpp_libname" = cpp ; then
2440             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
2441          else
2442             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
2443          fi],
2444         [AC_TRY_LINK([
2445 #include <builtin.h>
2446         ],
2447         [two_arg_error_handler_t foo2 = lib_error_handler],
2448         [cf_cxx_library=yes
2449          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2450          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
2451         [cf_cxx_library=no])])
2452         LIBS="$cf_save"
2453         AC_MSG_RESULT($cf_cxx_library)
2454 fi
2455 ])dnl
2456 dnl ---------------------------------------------------------------------------
2457 dnl CF_GXX_VERSION version: 7 updated: 2012/06/16 14:55:39
2458 dnl --------------
2459 dnl Check for version of g++
2460 AC_DEFUN([CF_GXX_VERSION],[
2461 AC_REQUIRE([AC_PROG_CPP])
2462 GXX_VERSION=none
2463 if test "$GXX" = yes; then
2464         AC_MSG_CHECKING(version of ${CXX:-g++})
2465         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2466         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2467         AC_MSG_RESULT($GXX_VERSION)
2468 fi
2469 ])dnl
2470 dnl ---------------------------------------------------------------------------
2471 dnl CF_GXX_WARNINGS version: 8 updated: 2013/11/16 14:27:53
2472 dnl ---------------
2473 dnl Check if the compiler supports useful warning options.
2474 dnl
2475 dnl Most of gcc's options apply to g++, except:
2476 dnl     -Wbad-function-cast
2477 dnl     -Wmissing-declarations
2478 dnl     -Wnested-externs
2479 dnl
2480 dnl Omit a few (for now):
2481 dnl     -Winline
2482 dnl
2483 dnl Parameter:
2484 dnl     $1 is an optional list of g++ warning flags that a particular
2485 dnl             application might want to use, e.g., "no-unused" for
2486 dnl             -Wno-unused
2487 dnl Special:
2488 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2489 dnl
2490 AC_DEFUN([CF_GXX_WARNINGS],
2491 [
2492
2493 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2494 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
2495
2496 AC_REQUIRE([CF_GXX_VERSION])
2497
2498 AC_LANG_SAVE
2499 AC_LANG_CPLUSPLUS
2500
2501 cat > conftest.$ac_ext <<EOF
2502 #line __oline__ "configure"
2503 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2504 EOF
2505
2506 if test "$INTEL_CPLUSPLUS" = yes
2507 then
2508 # The "-wdXXX" options suppress warnings:
2509 # remark #1419: external declaration in primary source file
2510 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2511 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2512 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2513 # remark #193: zero used for undefined preprocessing identifier
2514 # remark #593: variable "curs_sb_left_arrow" was set but never used
2515 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2516 # remark #869: parameter "tw" was never referenced
2517 # remark #981: operands are evaluated in unspecified order
2518 # warning #269: invalid format string conversion
2519
2520         AC_CHECKING([for $CC warning options])
2521         cf_save_CXXFLAGS="$CXXFLAGS"
2522         EXTRA_CXXFLAGS="-Wall"
2523         for cf_opt in \
2524                 wd1419 \
2525                 wd1682 \
2526                 wd1683 \
2527                 wd1684 \
2528                 wd193 \
2529                 wd279 \
2530                 wd593 \
2531                 wd810 \
2532                 wd869 \
2533                 wd981
2534         do
2535                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2536                 if AC_TRY_EVAL(ac_compile); then
2537                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2538                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2539                 fi
2540         done
2541         CXXFLAGS="$cf_save_CXXFLAGS"
2542
2543 elif test "$GXX" = yes
2544 then
2545         AC_CHECKING([for $CXX warning options])
2546         cf_save_CXXFLAGS="$CXXFLAGS"
2547         EXTRA_CXXFLAGS="-W -Wall"
2548         cf_gxx_extra_warnings=""
2549         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2550         case "$GCC_VERSION" in
2551         [[1-2]].*)
2552                 ;;
2553         *)
2554                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2555                 ;;
2556         esac
2557         for cf_opt in \
2558                 Wabi \
2559                 fabi-version=0 \
2560                 Wextra \
2561                 Wignored-qualifiers \
2562                 Wlogical-op \
2563                 Woverloaded-virtual \
2564                 Wsign-promo \
2565                 Wsynth \
2566                 Wold-style-cast \
2567                 Wcast-align \
2568                 Wcast-qual \
2569                 Wpointer-arith \
2570                 Wshadow \
2571                 Wundef $cf_gxx_extra_warnings $1
2572         do
2573                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2574                 if AC_TRY_EVAL(ac_compile); then
2575                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2576                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2577                 else
2578                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2579                 fi
2580         done
2581         CXXFLAGS="$cf_save_CXXFLAGS"
2582 fi
2583
2584 rm -rf conftest*
2585 AC_LANG_RESTORE
2586 AC_SUBST(EXTRA_CXXFLAGS)
2587 ])dnl
2588 dnl ---------------------------------------------------------------------------
2589 dnl CF_HASHED_DB version: 4 updated: 2010/05/29 16:31:02
2590 dnl ------------
2591 dnl Look for an instance of the Berkeley hashed database.
2592 dnl
2593 dnl $1 = optional parameter, to specify install-prefix for the database.
2594 AC_DEFUN([CF_HASHED_DB],
2595 [
2596 ifelse([$1],,,[
2597 case $1 in #(vi
2598 yes|*able*) #(vi
2599     ;;
2600 *)
2601     if test -d "$1" ; then
2602         CF_ADD_INCDIR($1/include)
2603         CF_ADD_LIBDIR($1/lib)
2604     fi
2605 esac
2606 ])
2607 AC_CHECK_HEADER(db.h,[
2608 CF_HASHED_DB_VERSION
2609 if test "$cf_cv_hashed_db_version" = unknown ; then
2610         AC_MSG_ERROR(Cannot determine version of db)
2611 else
2612         CF_HASHED_DB_LIBS
2613         if test "$cf_cv_hashed_db_libs" = unknown ; then
2614                 AC_MSG_ERROR(Cannot determine library for db)
2615         elif test "$cf_cv_hashed_db_libs" != default ; then
2616                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2617         fi
2618 fi
2619 ],[
2620         AC_MSG_ERROR(Cannot find db.h)
2621 ])
2622 ])dnl
2623 dnl ---------------------------------------------------------------------------
2624 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2625 dnl -----------------
2626 dnl Given that we have the header and version for hashed database, find the
2627 dnl library information.
2628 AC_DEFUN([CF_HASHED_DB_LIBS],
2629 [
2630 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2631 cf_cv_hashed_db_libs=unknown
2632 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2633 do
2634         cf_save_libs="$LIBS"
2635         if test -n "$cf_db_libs"; then
2636                 CF_ADD_LIB($cf_db_libs)
2637         fi
2638         CF_MSG_LOG(checking for library "$cf_db_libs")
2639         AC_TRY_LINK([
2640 $ac_includes_default
2641 #include <db.h>
2642 ],[
2643         char *path = "/tmp/foo";
2644 #ifdef DB_VERSION_MAJOR
2645 #if DB_VERSION_MAJOR >= 4
2646         DB *result = 0;
2647         db_create(&result, NULL, 0);
2648         result->open(result,
2649                 NULL,
2650                 path,
2651                 path,
2652                 DB_HASH,
2653                 DB_CREATE,
2654                 0644);
2655 #elif DB_VERSION_MAJOR >= 3
2656         DB *result = 0;
2657         db_create(&result, NULL, 0);
2658         result->open(result,
2659                 path,
2660                 path,
2661                 DB_HASH,
2662                 DB_CREATE,
2663                 0644);
2664 #elif DB_VERSION_MAJOR >= 2
2665         DB *result = 0;
2666         db_open(path,
2667                 DB_HASH,
2668                 DB_CREATE,
2669                 0644,
2670                 (DB_ENV *) 0,
2671                 (DB_INFO *) 0,
2672                 &result);
2673 #endif /* DB_VERSION_MAJOR */
2674 #else
2675         DB *result = dbopen(path,
2676                      2,
2677                      0644,
2678                      DB_HASH,
2679                      0);
2680 #endif
2681         ${cf_cv_main_return:-return}(result != 0)
2682 ],[
2683         if test -n "$cf_db_libs" ; then
2684                 cf_cv_hashed_db_libs=$cf_db_libs
2685         else
2686                 cf_cv_hashed_db_libs=default
2687         fi
2688         LIBS="$cf_save_libs"
2689         break
2690 ])
2691         LIBS="$cf_save_libs"
2692 done
2693 ])
2694 ])dnl
2695 dnl ---------------------------------------------------------------------------
2696 dnl CF_HASHED_DB_VERSION version: 3 updated: 2007/12/01 15:01:37
2697 dnl --------------------
2698 dnl Given that we have the header file for hashed database, find the version
2699 dnl information.
2700 AC_DEFUN([CF_HASHED_DB_VERSION],
2701 [
2702 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
2703 cf_cv_hashed_db_version=unknown
2704
2705 for cf_db_version in 1 2 3 4 5
2706 do
2707         CF_MSG_LOG(checking for db version $cf_db_version)
2708         AC_TRY_COMPILE([
2709 $ac_includes_default
2710 #include <db.h>
2711
2712 #ifdef DB_VERSION_MAJOR
2713         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
2714 #if $cf_db_version == DB_VERSION_MAJOR
2715         /* ok */
2716 #else
2717         make an error
2718 #endif
2719 #else
2720 #if $cf_db_version == 1
2721         /* ok: assuming this is DB 1.8.5 */
2722 #else
2723         make an error
2724 #endif
2725 #endif
2726 ],[DBT *foo = 0],[
2727         cf_cv_hashed_db_version=$cf_db_version
2728         break
2729         ])
2730 done
2731 ])
2732 ])dnl
2733 dnl ---------------------------------------------------------------------------
2734 dnl CF_HEADER_PATH version: 12 updated: 2010/05/05 05:22:40
2735 dnl --------------
2736 dnl Construct a search-list of directories for a nonstandard header-file
2737 dnl
2738 dnl Parameters
2739 dnl     $1 = the variable to return as result
2740 dnl     $2 = the package name
2741 AC_DEFUN([CF_HEADER_PATH],
2742 [
2743 $1=
2744
2745 # collect the current set of include-directories from compiler flags
2746 cf_header_path_list=""
2747 if test -n "${CFLAGS}${CPPFLAGS}" ; then
2748         for cf_header_path in $CPPFLAGS $CFLAGS
2749         do
2750                 case $cf_header_path in #(vi
2751                 -I*)
2752                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
2753                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
2754                         cf_header_path_list="$cf_header_path_list [$]$1"
2755                         ;;
2756                 esac
2757         done
2758 fi
2759
2760 # add the variations for the package we are looking for
2761 CF_SUBDIR_PATH($1,$2,include)
2762
2763 test "$includedir" != NONE && \
2764 test "$includedir" != "/usr/include" && \
2765 test -d "$includedir" && {
2766         test -d $includedir &&    $1="[$]$1 $includedir"
2767         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
2768 }
2769
2770 test "$oldincludedir" != NONE && \
2771 test "$oldincludedir" != "/usr/include" && \
2772 test -d "$oldincludedir" && {
2773         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
2774         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
2775 }
2776
2777 $1="[$]$1 $cf_header_path_list"
2778 ])dnl
2779 dnl ---------------------------------------------------------------------------
2780 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
2781 dnl ---------------
2782 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
2783 AC_DEFUN([CF_HELP_MESSAGE],
2784 [AC_DIVERT_HELP([$1])dnl
2785 ])dnl
2786 dnl ---------------------------------------------------------------------------
2787 dnl CF_INCLUDE_DIRS version: 8 updated: 2013/10/12 16:45:09
2788 dnl ---------------
2789 dnl Construct the list of include-options according to whether we're building
2790 dnl in the source directory or using '--srcdir=DIR' option.  If we're building
2791 dnl with gcc, don't append the includedir if it happens to be /usr/include,
2792 dnl since that usually breaks gcc's shadow-includes.
2793 AC_DEFUN([CF_INCLUDE_DIRS],
2794 [
2795 if test "$GCC" != yes; then
2796         CPPFLAGS="-I\${includedir} $CPPFLAGS"
2797 elif test "$includedir" != "/usr/include"; then
2798         if test "$includedir" = '${prefix}/include' ; then
2799                 if test x$prefix != x/usr ; then
2800                         CPPFLAGS="-I\${includedir} $CPPFLAGS"
2801                 fi
2802         else
2803                 CPPFLAGS="-I\${includedir} $CPPFLAGS"
2804         fi
2805 fi
2806 if test "$srcdir" != "."; then
2807         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
2808 fi
2809 CPPFLAGS="-I. -I../include $CPPFLAGS"
2810 AC_SUBST(CPPFLAGS)
2811 ])dnl
2812 dnl ---------------------------------------------------------------------------
2813 dnl CF_INTEL_COMPILER version: 5 updated: 2013/02/10 10:41:05
2814 dnl -----------------
2815 dnl Check if the given compiler is really the Intel compiler for Linux.  It
2816 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
2817 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
2818 dnl
2819 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
2820 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
2821 dnl the wrappers for gcc and g++ warnings.
2822 dnl
2823 dnl $1 = GCC (default) or GXX
2824 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
2825 dnl $3 = CFLAGS (default) or CXXFLAGS
2826 AC_DEFUN([CF_INTEL_COMPILER],[
2827 AC_REQUIRE([AC_CANONICAL_HOST])
2828 ifelse([$2],,INTEL_COMPILER,[$2])=no
2829
2830 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
2831         case $host_os in
2832         linux*|gnu*)
2833                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
2834                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
2835                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
2836                 AC_TRY_COMPILE([],[
2837 #ifdef __INTEL_COMPILER
2838 #else
2839 make an error
2840 #endif
2841 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
2842 cf_save_CFLAGS="$cf_save_CFLAGS -we147 -no-gcc"
2843 ],[])
2844                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
2845                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
2846                 ;;
2847         esac
2848 fi
2849 ])dnl
2850 dnl ---------------------------------------------------------------------------
2851 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
2852 dnl ----------
2853 dnl Check if we have either a function or macro for 'isascii()'.
2854 AC_DEFUN([CF_ISASCII],
2855 [
2856 AC_MSG_CHECKING(for isascii)
2857 AC_CACHE_VAL(cf_cv_have_isascii,[
2858         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
2859         [cf_cv_have_isascii=yes],
2860         [cf_cv_have_isascii=no])
2861 ])dnl
2862 AC_MSG_RESULT($cf_cv_have_isascii)
2863 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
2864 ])dnl
2865 dnl ---------------------------------------------------------------------------
2866 dnl CF_LARGEFILE version: 8 updated: 2012/10/06 08:57:51
2867 dnl ------------
2868 dnl Add checks for large file support.
2869 AC_DEFUN([CF_LARGEFILE],[
2870 ifdef([AC_FUNC_FSEEKO],[
2871     AC_SYS_LARGEFILE
2872     if test "$enable_largefile" != no ; then
2873         AC_FUNC_FSEEKO
2874
2875         # Normally we would collect these definitions in the config.h,
2876         # but (like _XOPEN_SOURCE), some environments rely on having these
2877         # defined before any of the system headers are included.  Another
2878         # case comes up with C++, e.g., on AIX the compiler compiles the
2879         # header files by themselves before looking at the body files it is
2880         # told to compile.  For ncurses, those header files do not include
2881         # the config.h
2882         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
2883         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
2884         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
2885
2886         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
2887                 AC_TRY_COMPILE([
2888 #include <sys/types.h>
2889 #include <dirent.h>
2890                 ],[
2891                 /* if transitional largefile support is setup, this is true */
2892                 extern struct dirent64 * readdir(DIR *);
2893                 struct dirent64 *x = readdir((DIR *)0);
2894                 struct dirent *y = readdir((DIR *)0);
2895                 int z = x - y;
2896                 ],
2897                 [cf_cv_struct_dirent64=yes],
2898                 [cf_cv_struct_dirent64=no])
2899         ])
2900         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
2901     fi
2902 ])
2903 ])
2904 dnl ---------------------------------------------------------------------------
2905 dnl CF_LDFLAGS_STATIC version: 10 updated: 2011/09/24 12:51:48
2906 dnl -----------------
2907 dnl Check for compiler/linker flags used to temporarily force usage of static
2908 dnl libraries.  This depends on the compiler and platform.  Use this to help
2909 dnl ensure that the linker picks up a given library based on its position in
2910 dnl the list of linker options and libraries.
2911 AC_DEFUN([CF_LDFLAGS_STATIC],[
2912
2913 if test "$GCC" = yes ; then
2914         case $cf_cv_system_name in #(
2915         OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)         #( vi
2916                 LDFLAGS_STATIC=
2917                 LDFLAGS_SHARED=
2918                 ;;
2919     *)  #( normally, except when broken
2920         LDFLAGS_STATIC=-static
2921         LDFLAGS_SHARED=-dynamic
2922         ;;
2923     esac
2924 else
2925         case $cf_cv_system_name in #(
2926         aix[[4-7]]*)    #( from ld manpage
2927                 LDFLAGS_STATIC=-bstatic
2928                 LDFLAGS_SHARED=-bdynamic
2929                 ;;
2930         hpux*)          #( from ld manpage for hpux10.20, hpux11.11
2931                 # We could also use just "archive" and "shared".
2932                 LDFLAGS_STATIC=-Wl,-a,archive_shared
2933                 LDFLAGS_SHARED=-Wl,-a,shared_archive
2934                 ;;
2935         irix*)          #( from ld manpage IRIX64
2936                 LDFLAGS_STATIC=-Bstatic
2937                 LDFLAGS_SHARED=-Bdynamic
2938                 ;;
2939         osf[[45]]*)     #( from ld manpage osf4.0d, osf5.1
2940                 # alternative "-oldstyle_liblookup" (not in cc manpage)
2941                 LDFLAGS_STATIC=-noso
2942                 LDFLAGS_SHARED=-so_archive
2943                 ;;
2944         solaris2*)
2945                 LDFLAGS_STATIC=-Bstatic
2946                 LDFLAGS_SHARED=-Bdynamic
2947                 ;;
2948         esac
2949 fi
2950
2951 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
2952 then
2953         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
2954
2955         rm -f libconftest.a
2956         cat >conftest.$ac_ext <<EOF
2957 #line __oline__ "configure"
2958 #include <stdio.h>
2959 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
2960 EOF
2961         if AC_TRY_EVAL(ac_compile) ; then
2962                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
2963                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
2964         fi
2965         rm -f conftest.*
2966
2967         cf_save_LIBS="$LIBS"
2968
2969         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
2970         AC_TRY_LINK([
2971 #line __oline__ "configure"
2972 #include <stdio.h>
2973 int cf_ldflags_static(FILE *fp);
2974 ],[
2975         return cf_ldflags_static(stdin);
2976 ],[
2977         # some linkers simply ignore the -dynamic
2978         case x`file conftest$ac_exeext 2>/dev/null` in #(vi
2979         *static*) # (vi
2980                 cf_ldflags_static=no
2981                 ;;
2982         *)
2983                 cf_ldflags_static=yes
2984                 ;;
2985         esac
2986 ],[cf_ldflags_static=no])
2987
2988         rm -f libconftest.*
2989         LIBS="$cf_save_LIBS"
2990
2991         AC_MSG_RESULT($cf_ldflags_static)
2992
2993         if test $cf_ldflags_static != yes
2994         then
2995                 LDFLAGS_STATIC=
2996                 LDFLAGS_SHARED=
2997         fi
2998 else
2999         LDFLAGS_STATIC=
3000         LDFLAGS_SHARED=
3001 fi
3002
3003 AC_SUBST(LDFLAGS_STATIC)
3004 AC_SUBST(LDFLAGS_SHARED)
3005 ])
3006 dnl ---------------------------------------------------------------------------
3007 dnl CF_LD_RPATH_OPT version: 5 updated: 2011/07/17 14:48:41
3008 dnl ---------------
3009 dnl For the given system and compiler, find the compiler flags to pass to the
3010 dnl loader to use the "rpath" feature.
3011 AC_DEFUN([CF_LD_RPATH_OPT],
3012 [
3013 AC_REQUIRE([CF_CHECK_CACHE])
3014
3015 LD_RPATH_OPT=
3016 AC_MSG_CHECKING(for an rpath option)
3017 case $cf_cv_system_name in #(vi
3018 irix*) #(vi
3019         if test "$GCC" = yes; then
3020                 LD_RPATH_OPT="-Wl,-rpath,"
3021         else
3022                 LD_RPATH_OPT="-rpath "
3023         fi
3024         ;;
3025 linux*|gnu*|k*bsd*-gnu) #(vi
3026         LD_RPATH_OPT="-Wl,-rpath,"
3027         ;;
3028 openbsd[[2-9]].*|mirbsd*) #(vi
3029         LD_RPATH_OPT="-Wl,-rpath,"
3030         ;;
3031 dragonfly*|freebsd*) #(vi
3032         LD_RPATH_OPT="-rpath "
3033         ;;
3034 netbsd*) #(vi
3035         LD_RPATH_OPT="-Wl,-rpath,"
3036         ;;
3037 osf*|mls+*) #(vi
3038         LD_RPATH_OPT="-rpath "
3039         ;;
3040 solaris2*) #(vi
3041         LD_RPATH_OPT="-R"
3042         ;;
3043 *)
3044         ;;
3045 esac
3046 AC_MSG_RESULT($LD_RPATH_OPT)
3047
3048 case "x$LD_RPATH_OPT" in #(vi
3049 x-R*)
3050         AC_MSG_CHECKING(if we need a space after rpath option)
3051         cf_save_LIBS="$LIBS"
3052         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3053         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3054         LIBS="$cf_save_LIBS"
3055         AC_MSG_RESULT($cf_rpath_space)
3056         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3057         ;;
3058 esac
3059 ])dnl
3060 dnl ---------------------------------------------------------------------------
3061 dnl CF_LIBRARY_PATH version: 9 updated: 2010/03/28 12:52:50
3062 dnl ---------------
3063 dnl Construct a search-list of directories for a nonstandard library-file
3064 dnl
3065 dnl Parameters
3066 dnl     $1 = the variable to return as result
3067 dnl     $2 = the package name
3068 AC_DEFUN([CF_LIBRARY_PATH],
3069 [
3070 $1=
3071 cf_library_path_list=""
3072 if test -n "${LDFLAGS}${LIBS}" ; then
3073         for cf_library_path in $LDFLAGS $LIBS
3074         do
3075                 case $cf_library_path in #(vi
3076                 -L*)
3077                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3078                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3079                         cf_library_path_list="$cf_library_path_list [$]$1"
3080                         ;;
3081                 esac
3082         done
3083 fi
3084
3085 CF_SUBDIR_PATH($1,$2,lib)
3086
3087 $1="$cf_library_path_list [$]$1"
3088 ])dnl
3089 dnl ---------------------------------------------------------------------------
3090 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
3091 dnl ------------------
3092 AC_DEFUN([CF_LIBTOOL_VERSION],[
3093 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
3094 then
3095         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
3096 else
3097         cf_cv_libtool_version=
3098 fi
3099 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
3100 ])dnl
3101 dnl ---------------------------------------------------------------------------
3102 dnl CF_LIB_PREFIX version: 9 updated: 2012/01/21 19:28:10
3103 dnl -------------
3104 dnl Compute the library-prefix for the given host system
3105 dnl $1 = variable to set
3106 define([CF_LIB_PREFIX],
3107 [
3108         case $cf_cv_system_name in #(vi
3109         OS/2*|os2*) #(vi
3110         LIB_PREFIX=''
3111         ;;
3112         *)      LIB_PREFIX='lib'
3113         ;;
3114         esac
3115 ifelse($1,,,[$1=$LIB_PREFIX])
3116         AC_SUBST(LIB_PREFIX)
3117 ])dnl
3118 dnl ---------------------------------------------------------------------------
3119 dnl CF_LIB_RULES version: 74 updated: 2013/09/07 13:54:05
3120 dnl ------------
3121 dnl Append definitions and rules for the given models to the subdirectory
3122 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3123 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
3124 dnl the corresponding makefile to list the models that we'll generate.
3125 dnl
3126 dnl For shared libraries, make a list of symbolic links to construct when
3127 dnl generating each library.  The convention used for Linux is the simplest
3128 dnl one:
3129 dnl     lib<name>.so    ->
3130 dnl     lib<name>.so.<major>    ->
3131 dnl     lib<name>.so.<maj>.<minor>
3132 dnl
3133 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
3134 AC_DEFUN([CF_LIB_RULES],
3135 [
3136 cf_prefix=$LIB_PREFIX
3137 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3138
3139 case $cf_cv_shlib_version in #(vi
3140 cygdll|msysdll|mingw)
3141         TINFO_NAME=$TINFO_ARG_SUFFIX
3142         TINFO_SUFFIX=.dll
3143         ;;
3144 esac
3145
3146 if test -n "$TINFO_SUFFIX" ; then
3147         case $TINFO_SUFFIX in
3148         tw*)
3149                 TINFO_NAME="${TINFO_NAME}tw"
3150                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw//'`
3151                 ;;
3152         t*)
3153                 TINFO_NAME="${TINFO_NAME}t"
3154                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t//'`
3155                 ;;
3156         w*)
3157                 TINFO_NAME="${TINFO_NAME}w"
3158                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w//'`
3159                 ;;
3160         esac
3161 fi
3162
3163 for cf_dir in $SRC_SUBDIRS
3164 do
3165         if test ! -d $srcdir/$cf_dir ; then
3166                 continue
3167         elif test -f $srcdir/$cf_dir/modules; then
3168
3169                 SHARED_LIB=
3170                 Libs_To_Make=
3171                 for cf_item in $cf_LIST_MODELS
3172                 do
3173                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3174                         cf_libname=$cf_dir
3175                         test "$cf_dir" = c++ && cf_libname=ncurses++
3176                         if test $cf_item = shared ; then
3177                                 if test -n "${LIB_SUFFIX}"
3178                                 then
3179                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${LIB_SUFFIX}"'//'`
3180                                 else
3181                                         cf_shared_suffix="$cf_suffix"
3182                                 fi
3183                                 if test "$cf_cv_do_symlinks" = yes ; then
3184                                         cf_version_name=
3185
3186                                         case "$cf_cv_shlib_version" in #(vi
3187                                         rel) #(vi
3188                                                 cf_version_name=REL_VERSION
3189                                                 ;;
3190                                         abi)
3191                                                 cf_version_name=ABI_VERSION
3192                                                 ;;
3193                                         esac
3194
3195                                         if test -n "$cf_version_name"
3196                                         then
3197                                                 case "$cf_cv_system_name" in #(vi
3198                                                 darwin*)
3199                                                         # "w", etc?
3200                                                         cf_suffix="${LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
3201                                                         ;; #(vi
3202                                                 *)
3203                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
3204                                                         ;;
3205                                                 esac
3206                                         fi
3207                                         if test -n "${LIB_SUFFIX}"
3208                                         then
3209                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${LIB_SUFFIX}"'//'`
3210                                         else
3211                                                 cf_shared_suffix="$cf_suffix"
3212                                         fi
3213                                 fi
3214                                 # cygwin needs import library, and has unique naming convention
3215                                 # use autodetected ${cf_prefix} for import lib and static lib, but
3216                                 # use 'cyg' prefix for shared lib.
3217                                 case $cf_cv_shlib_version in #(vi
3218                                 cygdll) #(vi
3219                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3220                                         Libs_To_Make="$Libs_To_Make ../lib/cyg${cf_libname}${cf_cygsuf}"
3221                                         continue
3222                                         ;;
3223                                 msysdll) #(vi
3224                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3225                                         Libs_To_Make="$Libs_To_Make ../lib/msys-${cf_libname}${cf_cygsuf}"
3226                                         continue
3227                                         ;;
3228                                 mingw)
3229                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3230                                         Libs_To_Make="$Libs_To_Make ../lib/lib${cf_libname}${cf_cygsuf}"
3231                                         continue
3232                                         ;;
3233                                 esac
3234                         fi
3235                         Libs_To_Make="$Libs_To_Make ../lib/${cf_prefix}${cf_libname}${cf_suffix}"
3236                 done
3237
3238                 if test $cf_dir = ncurses ; then
3239                         cf_subsets="$LIB_SUBSETS"
3240                         cf_r_parts="$cf_subsets"
3241                         cf_liblist="$Libs_To_Make"
3242
3243                         while test -n "$cf_r_parts"
3244                         do
3245                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3246                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3247                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3248                                         cf_item=
3249                                         case $cf_l_parts in #(vi
3250                                         *termlib*) #(vi
3251                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3252                                                 ;;
3253                                         *ticlib*)
3254                                                 cf_item=`echo $cf_liblist |sed -e s%${LIB_NAME}${LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3255                                                 ;;
3256                                         *)
3257                                                 break
3258                                                 ;;
3259                                         esac
3260                                         if test -n "$cf_item"; then
3261                                                 Libs_To_Make="$cf_item $Libs_To_Make"
3262                                         fi
3263                                 else
3264                                         break
3265                                 fi
3266                         done
3267                 else
3268                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3269                 fi
3270
3271                 if test $cf_dir = c++; then
3272                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
3273                                 cf_list=
3274                                 for cf_item in $Libs_To_Make
3275                                 do
3276                                         case $cf_item in
3277                                         *.a)
3278                                                 ;;
3279                                         *)
3280                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
3281                                                 ;;
3282                                         esac
3283                                         for cf_test in $cf_list
3284                                         do
3285                                                 if test "$cf_test" = "$cf_item"
3286                                                 then
3287                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
3288                                                         cf_item=
3289                                                         break
3290                                                 fi
3291                                         done
3292                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
3293                                 done
3294                                 Libs_To_Make="$cf_list"
3295                         fi
3296                 fi
3297
3298                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
3299                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3300                         $cf_dir/Makefile >$cf_dir/Makefile.out
3301                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3302
3303                 $AWK -f $srcdir/mk-0th.awk \
3304                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
3305                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3306
3307                 for cf_subset in $cf_subsets
3308                 do
3309                         cf_subdirs=
3310                         for cf_item in $cf_LIST_MODELS
3311                         do
3312
3313                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3314                         CF_UPPER(cf_ITEM,$cf_item)
3315
3316                         CXX_MODEL=$cf_ITEM
3317                         if test "$CXX_MODEL" = SHARED; then
3318                                 case $cf_cv_shlib_version in #(vi
3319                                 cygdll|msysdll|mingw) #(vi
3320                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
3321                                         with_shared_cxx=yes
3322                                         ;;
3323                                 *)
3324                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
3325                                         ;;
3326                                 esac
3327                         fi
3328
3329                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3330                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3331
3332                         # Test for case where we build libtinfo with a different name.
3333                         cf_libname=$cf_dir
3334                         if test $cf_dir = ncurses ; then
3335                                 case $cf_subset in
3336                                 *base*)
3337                                         cf_libname=${cf_libname}$LIB_SUFFIX
3338                                         ;;
3339                                 *termlib*)
3340                                         cf_libname=$TINFO_LIB_SUFFIX
3341                                         ;;
3342                                 ticlib*)
3343                                         cf_libname=$TICS_LIB_SUFFIX
3344                                         ;;
3345                                 esac
3346                         elif test $cf_dir = c++ ; then
3347                                 cf_libname=ncurses++$LIB_SUFFIX
3348                         else
3349                                 cf_libname=${cf_libname}$LIB_SUFFIX
3350                         fi
3351                         if test -n "${DFT_ARG_SUFFIX}" ; then
3352                                 # undo $LIB_SUFFIX add-on in CF_LIB_SUFFIX
3353                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${LIB_SUFFIX}%%"`
3354                         fi
3355
3356                         # These dependencies really are for development, not
3357                         # builds, but they are useful in porting, too.
3358                         cf_depend="../include/ncurses_cfg.h"
3359                         if test "$srcdir" = "."; then
3360                                 cf_reldir="."
3361                         else
3362                                 cf_reldir="\${srcdir}"
3363                         fi
3364
3365                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3366                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3367                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3368                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3369                         fi
3370
3371                         cf_dir_suffix=
3372                         old_cf_suffix="$cf_suffix"
3373                         if test "$cf_cv_shlib_version_infix" = yes ; then
3374                         if test -n "$LIB_SUFFIX" ; then
3375                                 case $LIB_SUFFIX in
3376                                 tw*)
3377                                         cf_libname=`echo $cf_libname | sed 's/tw$//'`
3378                                         cf_suffix=`echo $cf_suffix | sed 's/^tw//'`
3379                                         cf_dir_suffix=tw
3380                                         ;;
3381                                 t*)
3382                                         cf_libname=`echo $cf_libname | sed 's/t$//'`
3383                                         cf_suffix=`echo $cf_suffix | sed 's/^t//'`
3384                                         cf_dir_suffix=t
3385                                         ;;
3386                                 w*)
3387                                         cf_libname=`echo $cf_libname | sed 's/w$//'`
3388                                         cf_suffix=`echo $cf_suffix | sed 's/^w//'`
3389                                         cf_dir_suffix=w
3390                                         ;;
3391                                 esac
3392                         fi
3393                         fi
3394
3395                         $AWK -f $srcdir/mk-1st.awk \
3396                                 name=${cf_libname}${cf_dir_suffix} \
3397                                 traces=$LIB_TRACING \
3398                                 MODEL=$cf_ITEM \
3399                                 CXX_MODEL=$CXX_MODEL \
3400                                 model=$cf_subdir \
3401                                 prefix=$cf_prefix \
3402                                 suffix=$cf_suffix \
3403                                 subset=$cf_subset \
3404                                 driver=$cf_cv_term_driver \
3405                                 SymLink="$LN_S" \
3406                                 TermlibRoot=$TINFO_NAME \
3407                                 TermlibSuffix=$TINFO_SUFFIX \
3408                                 ShlibVer=$cf_cv_shlib_version \
3409                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3410                                 ReLink=${cf_cv_do_relink:-no} \
3411                                 DoLinks=$cf_cv_do_symlinks \
3412                                 rmSoLocs=$cf_cv_rm_so_locs \
3413                                 ldconfig="$LDCONFIG" \
3414                                 overwrite=$WITH_OVERWRITE \
3415                                 depend="$cf_depend" \
3416                                 host="$host" \
3417                                 libtool_version="$LIBTOOL_VERSION" \
3418                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3419
3420                         cf_suffix="$old_cf_suffix"
3421
3422                         for cf_subdir2 in $cf_subdirs lib
3423                         do
3424                                 test $cf_subdir = $cf_subdir2 && break
3425                         done
3426                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3427                         $AWK -f $srcdir/mk-2nd.awk \
3428                                 name=$cf_dir \
3429                                 traces=$LIB_TRACING \
3430                                 MODEL=$cf_ITEM \
3431                                 model=$cf_subdir \
3432                                 subset=$cf_subset \
3433                                 srcdir=$srcdir \
3434                                 echo=$WITH_ECHO \
3435                                 crenames=$cf_cv_prog_CC_c_o \
3436                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3437                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3438                         cf_subdirs="$cf_subdirs $cf_subdir"
3439                         done
3440                 done
3441         fi
3442
3443         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
3444 done
3445
3446 for cf_dir in $SRC_SUBDIRS
3447 do
3448         if test ! -d $srcdir/$cf_dir ; then
3449                 continue
3450         fi
3451
3452         if test -f $cf_dir/Makefile ; then
3453                 case "$cf_dir" in
3454                 Ada95) #(vi
3455                         echo 'libs \' >> Makefile
3456                         echo 'install.libs \' >> Makefile
3457                         echo 'uninstall.libs ::' >> Makefile
3458                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
3459                         ;;
3460                 esac
3461         fi
3462
3463         if test -f $srcdir/$cf_dir/modules; then
3464                 echo >> Makefile
3465                 if test -f $srcdir/$cf_dir/headers; then
3466 cat >> Makefile <<CF_EOF
3467 install.includes \\
3468 uninstall.includes \\
3469 CF_EOF
3470                 fi
3471 if test "$cf_dir" != "c++" ; then
3472 echo 'lint \' >> Makefile
3473 fi
3474 cat >> Makefile <<CF_EOF
3475 libs \\
3476 lintlib \\
3477 install.libs \\
3478 uninstall.libs \\
3479 install.$cf_dir \\
3480 uninstall.$cf_dir ::
3481         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3482 CF_EOF
3483         elif test -f $srcdir/$cf_dir/headers; then
3484 cat >> Makefile <<CF_EOF
3485
3486 libs \\
3487 install.libs \\
3488 uninstall.libs \\
3489 install.includes \\
3490 uninstall.includes ::
3491         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3492 CF_EOF
3493 fi
3494 done
3495
3496 if test "x$cf_with_db_install" = xyes; then
3497 cat >> Makefile <<CF_EOF
3498
3499 install.libs uninstall.libs \\
3500 install.data uninstall.data ::
3501 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3502 CF_EOF
3503 fi
3504
3505 if test "x$cf_with_manpages" = xyes; then
3506 cat >> Makefile <<CF_EOF
3507
3508 install.man \\
3509 uninstall.man ::
3510         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
3511 CF_EOF
3512 fi
3513
3514 cat >> Makefile <<CF_EOF
3515
3516 distclean ::
3517         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3518         rm -f headers.sh headers.sed mk_shared_lib.sh
3519         rm -f edit_man.* man_alias.*
3520         rm -rf \${DIRS_TO_MAKE}
3521 CF_EOF
3522
3523 # Special case: tack's manpage lives in its own directory.
3524 if test "x$cf_with_manpages" = xyes; then
3525 if test -d tack ; then
3526 if test -f $srcdir/$tack.h; then
3527 cat >> Makefile <<CF_EOF
3528
3529 install.man \\
3530 uninstall.man ::
3531         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
3532 CF_EOF
3533 fi
3534 fi
3535 fi
3536
3537 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3538 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3539 dnl anything, and will make it more standardized.  It's awkward to decide this
3540 dnl at configuration because of quoting, so we'll simply make all headers
3541 dnl installed via a script that can do the right thing.
3542
3543 rm -f headers.sed headers.sh
3544
3545 dnl ( generating this script makes the makefiles a little tidier :-)
3546 echo creating headers.sh
3547 cat >headers.sh <<CF_EOF
3548 #! /bin/sh
3549 # This shell script is generated by the 'configure' script.  It is invoked in a
3550 # subdirectory of the build tree.  It generates a sed-script in the parent
3551 # directory that is used to adjust includes for header files that reside in a
3552 # subdirectory of /usr/include, etc.
3553 PRG=""
3554 while test \[$]# != 3
3555 do
3556 PRG="\$PRG \[$]1"; shift
3557 done
3558 DST=\[$]1
3559 REF=\[$]2
3560 SRC=\[$]3
3561 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3562 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3563 echo installing \$SRC in \$DST
3564 CF_EOF
3565
3566 if test $WITH_CURSES_H = yes; then
3567         cat >>headers.sh <<CF_EOF
3568 case \$DST in
3569 /*/include/*)
3570         END=\`basename \$DST\`
3571         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3572         do
3573                 NAME=\`basename \$i\`
3574                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3575         done
3576         ;;
3577 *)
3578         echo "" >> \$TMPSED
3579         ;;
3580 esac
3581 CF_EOF
3582
3583 else
3584         cat >>headers.sh <<CF_EOF
3585 case \$DST in
3586 /*/include/*)
3587         END=\`basename \$DST\`
3588         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3589         do
3590                 NAME=\`basename \$i\`
3591                 if test "\$NAME" = "curses.h"
3592                 then
3593                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3594                         NAME=ncurses.h
3595                 fi
3596                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3597         done
3598         ;;
3599 *)
3600         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3601         ;;
3602 esac
3603 CF_EOF
3604 fi
3605 cat >>headers.sh <<CF_EOF
3606 rm -f \$TMPSRC
3607 sed -f \$TMPSED \$SRC > \$TMPSRC
3608 NAME=\`basename \$SRC\`
3609 CF_EOF
3610 if test $WITH_CURSES_H != yes; then
3611         cat >>headers.sh <<CF_EOF
3612 test "\$NAME" = "curses.h" && NAME=ncurses.h
3613 CF_EOF
3614 fi
3615 cat >>headers.sh <<CF_EOF
3616 # Just in case someone gzip'd manpages, remove the conflicting copy.
3617 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
3618
3619 eval \$PRG \$TMPSRC \$DST/\$NAME
3620 rm -f \$TMPSRC \$TMPSED
3621 CF_EOF
3622
3623 chmod 0755 headers.sh
3624
3625 for cf_dir in $SRC_SUBDIRS
3626 do
3627         if test ! -d $srcdir/$cf_dir ; then
3628                 continue
3629         fi
3630
3631         if test -f $srcdir/$cf_dir/headers; then
3632                 $AWK -f $srcdir/mk-hdr.awk \
3633                         subset="$LIB_SUBSETS" \
3634                         compat="$WITH_CURSES_H" \
3635                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
3636         fi
3637
3638         if test -f $srcdir/$cf_dir/modules; then
3639                 if test "$cf_dir" != "c++" ; then
3640                         cat >>$cf_dir/Makefile <<"CF_EOF"
3641 depend : ${AUTO_SRC}
3642         makedepend -- ${CPPFLAGS} -- ${C_SRC}
3643
3644 # DO NOT DELETE THIS LINE -- make depend depends on it.
3645 CF_EOF
3646                 fi
3647         fi
3648 done
3649 AC_SUBST(Libs_To_Make)
3650 ])dnl
3651 dnl ---------------------------------------------------------------------------
3652 dnl CF_LIB_SONAME version: 5 updated: 2010/08/14 18:25:37
3653 dnl -------------
3654 dnl Find the and soname for the given shared library.  Set the cache variable
3655 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
3656 dnl variable to "unknown".
3657 dnl
3658 dnl $1 = headers
3659 dnl $2 = code
3660 dnl $3 = library name
3661 AC_DEFUN([CF_LIB_SONAME],
3662 [
3663 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
3664
3665 cf_cv_$3_soname=unknown
3666 if test "$cross_compiling" != yes ; then
3667 cat >conftest.$ac_ext <<CF_EOF
3668 $1
3669 int main()
3670 {
3671 $2
3672         ${cf_cv_main_return:-return}(0);
3673 }
3674 CF_EOF
3675 cf_save_LIBS="$LIBS"
3676         CF_ADD_LIB($3)
3677         if AC_TRY_EVAL(ac_compile) ; then
3678                 if AC_TRY_EVAL(ac_link) ; then
3679                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
3680                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
3681                 fi
3682         fi
3683 rm -rf conftest*
3684 LIBS="$cf_save_LIBS"
3685 fi
3686 ])
3687 ])
3688 dnl ---------------------------------------------------------------------------
3689 dnl CF_LIB_SUFFIX version: 22 updated: 2013/09/07 13:54:05
3690 dnl -------------
3691 dnl Compute the library file-suffix from the given model name
3692 dnl $1 = model name
3693 dnl $2 = variable to set (the nominal library suffix)
3694 dnl $3 = dependency variable to set (actual filename)
3695 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3696 AC_DEFUN([CF_LIB_SUFFIX],
3697 [
3698         case X$1 in #(vi
3699         Xlibtool) #(vi
3700                 $2='.la'
3701                 $3=[$]$2
3702                 ;;
3703         Xdebug) #(vi
3704                 $2='_g.a'
3705                 $3=[$]$2
3706                 ;;
3707         Xprofile) #(vi
3708                 $2='_p.a'
3709                 $3=[$]$2
3710                 ;;
3711         Xshared) #(vi
3712                 case $cf_cv_system_name in
3713                 aix[[5-7]]*) #(vi
3714                         $2='.a'
3715                         $3=[$]$2
3716                         ;;
3717                 cygwin*|msys*|mingw*) #(vi
3718                         $2='.dll'
3719                         $3='.dll.a'
3720                         ;;
3721                 darwin*) #(vi
3722                         $2='.dylib'
3723                         $3=[$]$2
3724                         ;;
3725                 hpux*) #(vi
3726                         case $target in
3727                         ia64*) #(vi
3728                                 $2='.so'
3729                                 $3=[$]$2
3730                                 ;;
3731                         *) #(vi
3732                                 $2='.sl'
3733                                 $3=[$]$2
3734                                 ;;
3735                         esac
3736                         ;;
3737                 *) #(vi
3738                         $2='.so'
3739                         $3=[$]$2
3740                         ;;
3741                 esac
3742                 ;;
3743         *)
3744                 $2='.a'
3745                 $3=[$]$2
3746                 ;;
3747         esac
3748         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3749         test -n "$LIB_SUFFIX" && $3="${LIB_SUFFIX}[$]{$3}"
3750 ])dnl
3751 dnl ---------------------------------------------------------------------------
3752 dnl CF_LIB_TYPE version: 4 updated: 2000/10/20 22:57:49
3753 dnl -----------
3754 dnl Compute the string to append to -library from the given model name
3755 dnl $1 = model name
3756 dnl $2 = variable to set
3757 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
3758 AC_DEFUN([CF_LIB_TYPE],
3759 [
3760         case $1 in
3761         libtool) $2=''   ;;
3762         normal)  $2=''   ;;
3763         debug)   $2='_g' ;;
3764         profile) $2='_p' ;;
3765         shared)  $2=''   ;;
3766         esac
3767         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
3768 ])dnl
3769 dnl ---------------------------------------------------------------------------
3770 dnl CF_LINK_DATAONLY version: 10 updated: 2012/10/06 17:41:51
3771 dnl ----------------
3772 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
3773 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
3774 dnl have to provide wrappers for global tables to ensure they're linked
3775 dnl properly.
3776 AC_DEFUN([CF_LINK_DATAONLY],
3777 [
3778 AC_MSG_CHECKING([if data-only library module links])
3779 AC_CACHE_VAL(cf_cv_link_dataonly,[
3780         rm -f conftest.a
3781         cat >conftest.$ac_ext <<EOF
3782 #line __oline__ "configure"
3783 int     testdata[[3]] = { 123, 456, 789 };
3784 EOF
3785         if AC_TRY_EVAL(ac_compile) ; then
3786                 mv conftest.o data.o && \
3787                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
3788         fi
3789         rm -f conftest.$ac_ext data.o
3790         cat >conftest.$ac_ext <<EOF
3791 #line __oline__ "configure"
3792 int     testfunc()
3793 {
3794 #if defined(NeXT)
3795         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
3796 #else
3797         extern int testdata[[3]];
3798         return testdata[[0]] == 123
3799            &&  testdata[[1]] == 456
3800            &&  testdata[[2]] == 789;
3801 #endif
3802 }
3803 EOF
3804         if AC_TRY_EVAL(ac_compile); then
3805                 mv conftest.o func.o && \
3806                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
3807         fi
3808         rm -f conftest.$ac_ext func.o
3809         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
3810         cf_saveLIBS="$LIBS"
3811         LIBS="conftest.a $LIBS"
3812         AC_TRY_RUN([
3813         int main()
3814         {
3815                 extern int testfunc();
3816                 ${cf_cv_main_return:-return} (!testfunc());
3817         }
3818         ],
3819         [cf_cv_link_dataonly=yes],
3820         [cf_cv_link_dataonly=no],
3821         [cf_cv_link_dataonly=unknown])
3822         LIBS="$cf_saveLIBS"
3823         ])
3824 AC_MSG_RESULT($cf_cv_link_dataonly)
3825
3826 if test "$cf_cv_link_dataonly" = no ; then
3827         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
3828         BROKEN_LINKER=1
3829 fi
3830
3831 ])dnl
3832 dnl ---------------------------------------------------------------------------
3833 dnl CF_LINK_FUNCS version: 8 updated: 2012/10/06 17:56:13
3834 dnl -------------
3835 dnl Most Unix systems have both link and symlink, a few don't have symlink.
3836 dnl A few non-Unix systems implement symlink, but not link.
3837 dnl A few non-systems implement neither (or have nonfunctional versions).
3838 AC_DEFUN([CF_LINK_FUNCS],
3839 [
3840 AC_CHECK_FUNCS( \
3841         remove \
3842         unlink )
3843
3844 if test "$cross_compiling" = yes ; then
3845         AC_CHECK_FUNCS( \
3846                 link \
3847                 symlink )
3848 else
3849         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
3850                 cf_cv_link_funcs=
3851                 for cf_func in link symlink ; do
3852                         AC_TRY_RUN([
3853 #include <sys/types.h>
3854 #include <sys/stat.h>
3855 #ifdef HAVE_UNISTD_H
3856 #include <unistd.h>
3857 #endif
3858 int main()
3859 {
3860         int fail = 0;
3861         char *src = "config.log";
3862         char *dst = "conftest.chk";
3863         struct stat src_sb;
3864         struct stat dst_sb;
3865
3866         stat(src, &src_sb);
3867         fail = ($cf_func("config.log", "conftest.chk") < 0)
3868             || (stat(dst, &dst_sb) < 0)
3869             || (dst_sb.st_mtime != src_sb.st_mtime);
3870 #ifdef HAVE_UNLINK
3871         unlink(dst);
3872 #else
3873         remove(dst);
3874 #endif
3875         ${cf_cv_main_return:-return} (fail);
3876 }
3877                         ],[
3878                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
3879                         eval 'ac_cv_func_'$cf_func'=yes'],[
3880                         eval 'ac_cv_func_'$cf_func'=no'],[
3881                         eval 'ac_cv_func_'$cf_func'=error'])
3882                 done
3883                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
3884         ])
3885         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
3886         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
3887 fi
3888 ])dnl
3889 dnl ---------------------------------------------------------------------------
3890 dnl CF_MAKEFLAGS version: 14 updated: 2011/03/31 19:29:46
3891 dnl ------------
3892 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
3893 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
3894 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
3895 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
3896 AC_DEFUN([CF_MAKEFLAGS],
3897 [
3898 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
3899         cf_cv_makeflags=''
3900         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
3901         do
3902                 cat >cf_makeflags.tmp <<CF_EOF
3903 SHELL = /bin/sh
3904 all :
3905         @ echo '.$cf_option'
3906 CF_EOF
3907                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
3908                 case "$cf_result" in
3909                 .*k)
3910                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
3911                         case "$cf_result" in
3912                         .*CC=*) cf_cv_makeflags=
3913                                 ;;
3914                         *)      cf_cv_makeflags=$cf_option
3915                                 ;;
3916                         esac
3917                         break
3918                         ;;
3919                 .-)     ;;
3920                 *)      echo "given option \"$cf_option\", no match \"$cf_result\""
3921                         ;;
3922                 esac
3923         done
3924         rm -f cf_makeflags.tmp
3925 ])
3926
3927 AC_SUBST(cf_cv_makeflags)
3928 ])dnl
3929 dnl ---------------------------------------------------------------------------
3930 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
3931 dnl ------------
3932 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
3933 dnl a monocase filesystem.
3934 AC_DEFUN([CF_MAKE_TAGS],[
3935 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
3936
3937 AC_CHECK_PROGS(CTAGS, exctags ctags)
3938 AC_CHECK_PROGS(ETAGS, exetags etags)
3939
3940 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
3941
3942 if test "$cf_cv_mixedcase" = yes ; then
3943         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
3944 else
3945         MAKE_UPPER_TAGS=no
3946 fi
3947
3948 if test "$MAKE_UPPER_TAGS" = yes ; then
3949         MAKE_UPPER_TAGS=
3950 else
3951         MAKE_UPPER_TAGS="#"
3952 fi
3953
3954 if test "$MAKE_LOWER_TAGS" = yes ; then
3955         MAKE_LOWER_TAGS=
3956 else
3957         MAKE_LOWER_TAGS="#"
3958 fi
3959
3960 AC_SUBST(CTAGS)
3961 AC_SUBST(ETAGS)
3962
3963 AC_SUBST(MAKE_UPPER_TAGS)
3964 AC_SUBST(MAKE_LOWER_TAGS)
3965 ])dnl
3966 dnl ---------------------------------------------------------------------------
3967 dnl CF_MANPAGE_FORMAT version: 9 updated: 2010/10/23 16:10:30
3968 dnl -----------------
3969 dnl Option to allow user to override automatic configuration of manpage format.
3970 dnl There are several special cases:
3971 dnl
3972 dnl     gzip - man checks for, can display gzip'd files
3973 dnl     compress - man checks for, can display compressed files
3974 dnl     BSDI - files in the cat-directories are suffixed ".0"
3975 dnl     formatted - installer should format (put files in cat-directory)
3976 dnl     catonly - installer should only format, e.g., for a turnkey system.
3977 dnl
3978 dnl There are other configurations which this macro does not test, e.g., HPUX's
3979 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
3980 dnl convention would not match our use).
3981 AC_DEFUN([CF_MANPAGE_FORMAT],
3982 [
3983 AC_REQUIRE([CF_PATHSEP])
3984 AC_MSG_CHECKING(format of man-pages)
3985
3986 AC_ARG_WITH(manpage-format,
3987         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
3988                           optionally formatted/catonly, e.g., gzip,formatted],
3989         [MANPAGE_FORMAT=$withval],
3990         [MANPAGE_FORMAT=unknown])
3991
3992 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
3993 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
3994
3995 cf_unknown=
3996
3997 case $MANPAGE_FORMAT in
3998 unknown)
3999   if test -z "$MANPATH" ; then
4000     MANPATH="/usr/man:/usr/share/man"
4001   fi
4002
4003   # look for the 'date' man-page (it's most likely to be installed!)
4004   MANPAGE_FORMAT=
4005   cf_preform=no
4006   cf_catonly=yes
4007   cf_example=date
4008
4009   IFS="${IFS:-  }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
4010   for cf_dir in $MANPATH; do
4011     test -z "$cf_dir" && cf_dir=/usr/man
4012     for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
4013     do
4014       cf_test=`echo $cf_name | sed -e 's/*//'`
4015       if test "x$cf_test" = "x$cf_name" ; then
4016
4017         case "$cf_name" in
4018         *.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
4019         *.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
4020         *.0)    MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
4021         *)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
4022         esac
4023
4024         case "$cf_name" in
4025         $cf_dir/man*)
4026           cf_catonly=no
4027           ;;
4028         $cf_dir/cat*)
4029           cf_preform=yes
4030           ;;
4031         esac
4032         break
4033       fi
4034
4035       # if we found a match in either man* or cat*, stop looking
4036       if test -n "$MANPAGE_FORMAT" ; then
4037         cf_found=no
4038         test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
4039         test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
4040         case "$cf_name" in
4041         $cf_dir/cat*)
4042           cf_found=yes
4043           ;;
4044         esac
4045         test $cf_found=yes && break
4046       fi
4047     done
4048     # only check the first directory in $MANPATH where we find manpages
4049     if test -n "$MANPAGE_FORMAT" ; then
4050        break
4051     fi
4052   done
4053   # if we did not find the example, just assume it is normal
4054   test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
4055   IFS="$ac_save_ifs"
4056   ;;
4057 *)
4058   for cf_option in $MANPAGE_FORMAT; do
4059      case $cf_option in #(vi
4060      gzip|compress|BSDI|normal|formatted|catonly)
4061        ;;
4062      *)
4063        cf_unknown="$cf_unknown $cf_option"
4064        ;;
4065      esac
4066   done
4067   ;;
4068 esac
4069
4070 AC_MSG_RESULT($MANPAGE_FORMAT)
4071 if test -n "$cf_unknown" ; then
4072   AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
4073 fi
4074 ])dnl
4075 dnl ---------------------------------------------------------------------------
4076 dnl CF_MANPAGE_RENAMES version: 7 updated: 2005/06/18 18:51:57
4077 dnl ------------------
4078 dnl The Debian people have their own naming convention for manpages.  This
4079 dnl option lets us override the name of the file containing renaming, or
4080 dnl disable it altogether.
4081 AC_DEFUN([CF_MANPAGE_RENAMES],
4082 [
4083 AC_MSG_CHECKING(for manpage renaming)
4084
4085 AC_ARG_WITH(manpage-renames,
4086         [  --with-manpage-renames  specify manpage-renaming],
4087         [MANPAGE_RENAMES=$withval],
4088         [MANPAGE_RENAMES=yes])
4089
4090 case ".$MANPAGE_RENAMES" in #(vi
4091 .no) #(vi
4092   ;;
4093 .|.yes)
4094   # Debian 'man' program?
4095   if test -f /etc/debian_version ; then
4096     MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
4097   else
4098     MANPAGE_RENAMES=no
4099   fi
4100   ;;
4101 esac
4102
4103 if test "$MANPAGE_RENAMES" != no ; then
4104   if test -f $srcdir/man/$MANPAGE_RENAMES ; then
4105     MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
4106   elif test ! -f $MANPAGE_RENAMES ; then
4107     AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
4108   fi
4109
4110   test ! -d man && mkdir man
4111
4112   # Construct a sed-script to perform renaming within man-pages
4113   if test -n "$MANPAGE_RENAMES" ; then
4114     test ! -d man && mkdir man
4115     sh $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
4116   fi
4117 fi
4118
4119 AC_MSG_RESULT($MANPAGE_RENAMES)
4120 AC_SUBST(MANPAGE_RENAMES)
4121 ])dnl
4122 dnl ---------------------------------------------------------------------------
4123 dnl CF_MANPAGE_SYMLINKS version: 5 updated: 2010/07/24 17:12:40
4124 dnl -------------------
4125 dnl Some people expect each tool to make all aliases for manpages in the
4126 dnl man-directory.  This accommodates the older, less-capable implementations
4127 dnl of 'man', and is optional.
4128 AC_DEFUN([CF_MANPAGE_SYMLINKS],
4129 [
4130 AC_MSG_CHECKING(if manpage aliases will be installed)
4131
4132 AC_ARG_WITH(manpage-aliases,
4133         [  --with-manpage-aliases  specify manpage-aliases using .so],
4134         [MANPAGE_ALIASES=$withval],
4135         [MANPAGE_ALIASES=yes])
4136
4137 AC_MSG_RESULT($MANPAGE_ALIASES)
4138
4139 case "x$LN_S" in #(vi
4140 xln*) #(vi
4141         cf_use_symlinks=yes
4142         ;;
4143 *)
4144         cf_use_symlinks=no
4145         ;;
4146 esac
4147
4148 MANPAGE_SYMLINKS=no
4149 if test "$MANPAGE_ALIASES" = yes ; then
4150 AC_MSG_CHECKING(if manpage symlinks should be used)
4151
4152 AC_ARG_WITH(manpage-symlinks,
4153         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
4154         [MANPAGE_SYMLINKS=$withval],
4155         [MANPAGE_SYMLINKS=$cf_use_symlinks])
4156
4157 if test "$$cf_use_symlinks" = no; then
4158 if test "$MANPAGE_SYMLINKS" = yes ; then
4159         AC_MSG_WARN(cannot make symlinks, will use .so files)
4160         MANPAGE_SYMLINKS=no
4161 fi
4162 fi
4163
4164 AC_MSG_RESULT($MANPAGE_SYMLINKS)
4165 fi
4166
4167 ])dnl
4168 dnl ---------------------------------------------------------------------------
4169 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
4170 dnl --------------
4171 dnl This option causes manpages to be run through tbl(1) to generate tables
4172 dnl correctly.
4173 AC_DEFUN([CF_MANPAGE_TBL],
4174 [
4175 AC_MSG_CHECKING(for manpage tbl)
4176
4177 AC_ARG_WITH(manpage-tbl,
4178         [  --with-manpage-tbl      specify manpage processing with tbl],
4179         [MANPAGE_TBL=$withval],
4180         [MANPAGE_TBL=no])
4181
4182 AC_MSG_RESULT($MANPAGE_TBL)
4183 ])dnl
4184 dnl ---------------------------------------------------------------------------
4185 dnl CF_MAN_PAGES version: 43 updated: 2013/02/09 12:53:45
4186 dnl ------------
4187 dnl Try to determine if the man-pages on the system are compressed, and if
4188 dnl so, what format is used.  Use this information to construct a script that
4189 dnl will install man-pages.
4190 AC_DEFUN([CF_MAN_PAGES],
4191 [
4192 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
4193 CF_MANPAGE_FORMAT
4194 CF_MANPAGE_RENAMES
4195 CF_MANPAGE_SYMLINKS
4196 CF_MANPAGE_TBL
4197
4198   if test "$prefix" = "NONE" ; then
4199      cf_prefix="$ac_default_prefix"
4200   else
4201      cf_prefix="$prefix"
4202   fi
4203
4204   case "$MANPAGE_FORMAT" in # (vi
4205   *catonly*) # (vi
4206     cf_format=yes
4207     cf_inboth=no
4208     ;;
4209   *formatted*) # (vi
4210     cf_format=yes
4211     cf_inboth=yes
4212     ;;
4213   *)
4214     cf_format=no
4215     cf_inboth=no
4216     ;;
4217   esac
4218
4219 test ! -d man && mkdir man
4220
4221 cf_so_strip=
4222 cf_compress=
4223 case "$MANPAGE_FORMAT" in #(vi
4224 *compress*) #(vi
4225         cf_so_strip="Z"
4226         cf_compress=compress
4227   ;;
4228 *gzip*)
4229         cf_so_strip="gz"
4230         cf_compress=gzip
4231   ;;
4232 esac
4233
4234 cf_edit_man=./edit_man.sh
4235 cf_man_alias=`pwd`/man_alias.sed
4236
4237 cat >$cf_edit_man <<CF_EOF
4238 #! /bin/sh
4239 # this script is generated by the configure-script CF_MAN_PAGES macro.
4240
4241 prefix="$cf_prefix"
4242 datarootdir="$datarootdir"
4243 datadir="$datadir"
4244
4245 NCURSES_MAJOR="$NCURSES_MAJOR"
4246 NCURSES_MINOR="$NCURSES_MINOR"
4247 NCURSES_PATCH="$NCURSES_PATCH"
4248
4249 NCURSES_OSPEED="$NCURSES_OSPEED"
4250 TERMINFO="$TERMINFO"
4251
4252 INSTALL="$INSTALL"
4253 INSTALL_DATA="$INSTALL_DATA"
4254
4255 transform="$program_transform_name"
4256
4257 TMP=\${TMPDIR:=/tmp}/man\$\$
4258 trap "rm -f \$TMP" 0 1 2 5 15
4259
4260 form=\[$]1
4261 shift || exit 1
4262
4263 verb=\[$]1
4264 shift || exit 1
4265
4266 mandir=\[$]1
4267 shift || exit 1
4268
4269 srcdir=\[$]1
4270 top_srcdir=\[$]srcdir/..
4271 shift || exit 1
4272
4273 if test "\$form" = normal ; then
4274         if test "$cf_format" = yes ; then
4275         if test "$cf_inboth" = no ; then
4276                 sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4277                 exit $?
4278         fi
4279         fi
4280         cf_subdir=\$mandir/man
4281         cf_tables=$MANPAGE_TBL
4282 else
4283         cf_subdir=\$mandir/cat
4284         cf_tables=yes
4285 fi
4286
4287 # process the list of source-files
4288 for i in \[$]* ; do
4289 case \$i in #(vi
4290 *.orig|*.rej) ;; #(vi
4291 *.[[0-9]]*)
4292         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
4293         if test \$verb = installing ; then
4294         if test ! -d \$cf_subdir\${section} ; then
4295                 mkdir -p \$cf_subdir\$section
4296         fi
4297         fi
4298
4299         # replace variables in man page
4300         if test ! -f $cf_man_alias ; then
4301 cat >>$cf_man_alias <<-CF_EOF2
4302                 s,@DATADIR@,\$datadir,g
4303                 s,@TERMINFO@,\${TERMINFO:="no default value"},g
4304                 s,@TERMINFO_DIRS@,\${TERMINFO_DIRS:="no default value"},g
4305                 s,@NCURSES_MAJOR@,\${NCURSES_MAJOR:="no default value"},g
4306                 s,@NCURSES_MINOR@,\${NCURSES_MINOR:="no default value"},g
4307                 s,@NCURSES_PATCH@,\${NCURSES_PATCH:="no default value"},g
4308                 s,@NCURSES_OSPEED@,\${NCURSES_OSPEED:="no default value"},g
4309 CF_EOF
4310         ifelse($1,,,[
4311         for cf_name in $1
4312         do
4313                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4314                 cf_name=`echo $cf_name|sed "$program_transform_name"`
4315 cat >>$cf_edit_man <<-CF_EOF
4316                 s,@$cf_NAME@,$cf_name,g
4317 CF_EOF
4318         done
4319         ])
4320 cat >>$cf_edit_man <<CF_EOF
4321 CF_EOF2
4322                 echo "...made $cf_man_alias"
4323         fi
4324
4325         aliases=
4326         cf_source=\`basename \$i\`
4327         inalias=\$cf_source
4328         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
4329         if test ! -f \$inalias ; then
4330                 echo .. skipped \$cf_source
4331                 continue
4332         fi
4333 CF_EOF
4334
4335 if test "$MANPAGE_ALIASES" != no ; then
4336 cat >>$cf_edit_man <<CF_EOF
4337         nCurses=ignore.3x
4338         test $with_curses_h = yes && nCurses=ncurses.3x
4339         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
4340 CF_EOF
4341 fi
4342
4343 if test "$MANPAGE_RENAMES" = no ; then
4344 cat >>$cf_edit_man <<CF_EOF
4345         # perform program transformations for section 1 man pages
4346         if test \$section = 1 ; then
4347                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
4348         else
4349                 cf_target=\$cf_subdir\${section}/\$cf_source
4350         fi
4351 CF_EOF
4352 else
4353 cat >>$cf_edit_man <<CF_EOF
4354         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
4355         if test -z "\$cf_target" ; then
4356                 echo '? missing rename for '\$cf_source
4357                 cf_target="\$cf_source"
4358         fi
4359         cf_target="\$cf_subdir\${section}/\${cf_target}"
4360
4361 CF_EOF
4362 fi
4363
4364 cat >>$cf_edit_man <<CF_EOF
4365         sed     -f $cf_man_alias \\
4366 CF_EOF
4367
4368 if test -f $MANPAGE_RENAMES ; then
4369 cat >>$cf_edit_man <<CF_EOF
4370                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
4371 CF_EOF
4372 else
4373 cat >>$cf_edit_man <<CF_EOF
4374                 < \$i >\$TMP
4375 CF_EOF
4376 fi
4377
4378 cat >>$cf_edit_man <<CF_EOF
4379 if test \$cf_tables = yes ; then
4380         tbl \$TMP >\$TMP.out
4381         mv \$TMP.out \$TMP
4382 fi
4383 CF_EOF
4384
4385 if test $with_overwrite != yes ; then
4386 cat >>$cf_edit_man <<CF_EOF
4387         sed -e "/\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
4388         mv \$TMP.out \$TMP
4389 CF_EOF
4390 fi
4391
4392 if test $with_curses_h != yes ; then
4393 cat >>$cf_edit_man <<CF_EOF
4394         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
4395         mv \$TMP.out \$TMP
4396 CF_EOF
4397 fi
4398
4399 cat >>$cf_edit_man <<CF_EOF
4400         if test \$form = format ; then
4401                 nroff -man \$TMP >\$TMP.out
4402                 mv \$TMP.out \$TMP
4403         fi
4404 CF_EOF
4405
4406 if test -n "$cf_compress" ; then
4407 cat >>$cf_edit_man <<CF_EOF
4408         if test \$verb = installing ; then
4409         if ( $cf_compress -f \$TMP )
4410         then
4411                 mv \$TMP.$cf_so_strip \$TMP
4412         fi
4413         fi
4414         cf_target="\$cf_target.$cf_so_strip"
4415 CF_EOF
4416 fi
4417
4418 case "$MANPAGE_FORMAT" in #(vi
4419 *BSDI*)
4420 cat >>$cf_edit_man <<CF_EOF
4421         if test \$form = format ; then
4422                 # BSDI installs only .0 suffixes in the cat directories
4423                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
4424         fi
4425 CF_EOF
4426   ;;
4427 esac
4428
4429 cat >>$cf_edit_man <<CF_EOF
4430         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
4431         if test \$verb = installing ; then
4432                 echo \$verb \$cf_target
4433                 \$INSTALL_DATA \$TMP \$cf_target
4434                 test -d \$cf_subdir\${section} &&
4435                 test -n "\$aliases" && (
4436                         cd \$cf_subdir\${section} && (
4437                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
4438                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
4439                                 cf_target=\`basename \$cf_target\`
4440                                 for cf_alias in \$aliases
4441                                 do
4442                                         if test \$section = 1 ; then
4443                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4444                                         fi
4445
4446                                         if test "$MANPAGE_SYMLINKS" = yes ; then
4447                                                 if test -f \$cf_alias\${suffix} ; then
4448                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
4449                                                         then
4450                                                                 continue
4451                                                         fi
4452                                                 fi
4453                                                 echo .. \$verb alias \$cf_alias\${suffix}
4454 CF_EOF
4455 case "x$LN_S" in #(vi
4456 *-f) #(vi
4457 cat >>$cf_edit_man <<CF_EOF
4458                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4459 CF_EOF
4460         ;;
4461 *)
4462 cat >>$cf_edit_man <<CF_EOF
4463                                                 rm -f \$cf_alias\${suffix}
4464                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4465 CF_EOF
4466         ;;
4467 esac
4468 cat >>$cf_edit_man <<CF_EOF
4469                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
4470                                                 echo ".so \$cf_source" >\$TMP
4471 CF_EOF
4472 if test -n "$cf_compress" ; then
4473 cat >>$cf_edit_man <<CF_EOF
4474                                                 if test -n "$cf_so_strip" ; then
4475                                                         $cf_compress -f \$TMP
4476                                                         mv \$TMP.$cf_so_strip \$TMP
4477                                                 fi
4478 CF_EOF
4479 fi
4480 cat >>$cf_edit_man <<CF_EOF
4481                                                 echo .. \$verb alias \$cf_alias\${suffix}
4482                                                 rm -f \$cf_alias\${suffix}
4483                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
4484                                         fi
4485                                 done
4486                         )
4487                 )
4488         elif test \$verb = removing ; then
4489                 test -f \$cf_target && (
4490                         echo \$verb \$cf_target
4491                         rm -f \$cf_target
4492                 )
4493                 test -d \$cf_subdir\${section} &&
4494                 test -n "\$aliases" && (
4495                         cd \$cf_subdir\${section} && (
4496                                 for cf_alias in \$aliases
4497                                 do
4498                                         if test \$section = 1 ; then
4499                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4500                                         fi
4501
4502                                         echo .. \$verb alias \$cf_alias\${suffix}
4503                                         rm -f \$cf_alias\${suffix}
4504                                 done
4505                         )
4506                 )
4507         else
4508 #               echo ".hy 0"
4509                 cat \$TMP
4510         fi
4511         ;;
4512 esac
4513 done
4514
4515 if test $cf_inboth = yes ; then
4516 if test \$form != format ; then
4517         sh \[$]0 format \$verb \$mandir \$srcdir \[$]*
4518 fi
4519 fi
4520
4521 exit 0
4522 CF_EOF
4523 chmod 755 $cf_edit_man
4524
4525 ])dnl
4526 dnl ---------------------------------------------------------------------------
4527 dnl CF_MATH_LIB version: 8 updated: 2010/05/29 16:31:02
4528 dnl -----------
4529 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
4530 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
4531 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
4532 AC_DEFUN([CF_MATH_LIB],
4533 [
4534 AC_CACHE_CHECK(if -lm needed for math functions,
4535         cf_cv_need_libm,[
4536         AC_TRY_LINK([
4537         #include <stdio.h>
4538         #include <math.h>
4539         ],
4540         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
4541         [cf_cv_need_libm=no],
4542         [cf_cv_need_libm=yes])])
4543 if test "$cf_cv_need_libm" = yes
4544 then
4545 ifelse($1,,[
4546         CF_ADD_LIB(m)
4547 ],[$1=-lm])
4548 fi
4549 ])
4550 dnl ---------------------------------------------------------------------------
4551 dnl CF_MIXEDCASE_FILENAMES version: 6 updated: 2013/10/08 17:47:05
4552 dnl ----------------------
4553 dnl Check if the file-system supports mixed-case filenames.  If we're able to
4554 dnl create a lowercase name and see it as uppercase, it doesn't support that.
4555 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
4556 [
4557 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
4558 if test "$cross_compiling" = yes ; then
4559         case $target_alias in #(vi
4560         *-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*) #(vi
4561                 cf_cv_mixedcase=no
4562                 ;;
4563         *)
4564                 cf_cv_mixedcase=yes
4565                 ;;
4566         esac
4567 else
4568         rm -f conftest CONFTEST
4569         echo test >conftest
4570         if test -f CONFTEST ; then
4571                 cf_cv_mixedcase=no
4572         else
4573                 cf_cv_mixedcase=yes
4574         fi
4575         rm -f conftest CONFTEST
4576 fi
4577 ])
4578 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
4579 ])dnl
4580 dnl ---------------------------------------------------------------------------
4581 dnl CF_MKSTEMP version: 9 updated: 2012/10/03 04:34:49
4582 dnl ----------
4583 dnl Check for a working mkstemp.  This creates two files, checks that they are
4584 dnl successfully created and distinct (AmigaOS apparently fails on the last).
4585 AC_DEFUN([CF_MKSTEMP],[
4586 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
4587 rm -rf conftest*
4588 AC_TRY_RUN([
4589 #include <sys/types.h>
4590 #include <stdlib.h>
4591 #include <stdio.h>
4592 #include <string.h>
4593 #include <sys/stat.h>
4594 int main()
4595 {
4596         char *tmpl = "conftestXXXXXX";
4597         char name[2][80];
4598         int n;
4599         int result = 0;
4600         int fd;
4601         struct stat sb;
4602
4603         umask(077);
4604         for (n = 0; n < 2; ++n) {
4605                 strcpy(name[n], tmpl);
4606                 if ((fd = mkstemp(name[n])) >= 0) {
4607                         if (!strcmp(name[n], tmpl)
4608                          || stat(name[n], &sb) != 0
4609                          || (sb.st_mode & S_IFMT) != S_IFREG
4610                          || (sb.st_mode & 077) != 0) {
4611                                 result = 1;
4612                         }
4613                         close(fd);
4614                 }
4615         }
4616         if (result == 0
4617          && !strcmp(name[0], name[1]))
4618                 result = 1;
4619         ${cf_cv_main_return:-return}(result);
4620 }
4621 ],[cf_cv_func_mkstemp=yes
4622 ],[cf_cv_func_mkstemp=no
4623 ],[cf_cv_func_mkstemp=maybe])
4624 ])
4625 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
4626         AC_CHECK_FUNC(mkstemp)
4627 fi
4628 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
4629         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
4630 fi
4631 ])dnl
4632 dnl ---------------------------------------------------------------------------
4633 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
4634 dnl ----------
4635 dnl Write a debug message to config.log, along with the line number in the
4636 dnl configure script.
4637 AC_DEFUN([CF_MSG_LOG],[
4638 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
4639 ])dnl
4640 dnl ---------------------------------------------------------------------------
4641 dnl CF_NCURSES_ABI_6 version: 1 updated: 2005/09/17 18:42:49
4642 dnl ----------------
4643 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
4644 dnl warn about this.
4645 AC_DEFUN([CF_NCURSES_ABI_6],[
4646 if test "${with_abi_version+set}" != set; then
4647         case $cf_cv_rel_version in
4648         5.*)
4649                 cf_cv_rel_version=6.0
4650                 cf_cv_abi_version=6
4651                 AC_MSG_WARN(Overriding ABI version to $cf_cv_abi_version)
4652                 ;;
4653         esac
4654 fi
4655 ])dnl
4656 dnl ---------------------------------------------------------------------------
4657 dnl CF_NO_LEAKS_OPTION version: 5 updated: 2012/10/02 20:55:03
4658 dnl ------------------
4659 dnl see CF_WITH_NO_LEAKS
4660 AC_DEFUN([CF_NO_LEAKS_OPTION],[
4661 AC_MSG_CHECKING(if you want to use $1 for testing)
4662 AC_ARG_WITH($1,
4663         [$2],
4664         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
4665          $4
4666 ])
4667         : ${with_cflags:=-g}
4668         : ${with_no_leaks:=yes}
4669          with_$1=yes],
4670         [with_$1=])
4671 AC_MSG_RESULT(${with_$1:-no})
4672
4673 case .$with_cflags in #(vi
4674 .*-g*)
4675         case .$CFLAGS in #(vi
4676         .*-g*) #(vi
4677                 ;;
4678         *)
4679                 CF_ADD_CFLAGS([-g])
4680                 ;;
4681         esac
4682         ;;
4683 esac
4684 ])dnl
4685 dnl ---------------------------------------------------------------------------
4686 dnl CF_NUMBER_SYNTAX version: 1 updated: 2003/09/20 18:12:49
4687 dnl ----------------
4688 dnl Check if the given variable is a number.  If not, report an error.
4689 dnl $1 is the variable
4690 dnl $2 is the message
4691 AC_DEFUN([CF_NUMBER_SYNTAX],[
4692 if test -n "$1" ; then
4693   case $1 in #(vi
4694   [[0-9]]*) #(vi
4695         ;;
4696   *)
4697         AC_MSG_ERROR($2 is not a number: $1)
4698         ;;
4699   esac
4700 else
4701   AC_MSG_ERROR($2 value is empty)
4702 fi
4703 ])dnl
4704 dnl ---------------------------------------------------------------------------
4705 dnl CF_OBJ_SUBDIR version: 6 updated: 2013/09/07 14:06:10
4706 dnl -------------
4707 dnl Compute the object-directory name from the given model name
4708 AC_DEFUN([CF_OBJ_SUBDIR],
4709 [
4710         case $1 in
4711         libtool) $2='obj_lo'  ;;
4712         normal)  $2='objects' ;;
4713         debug)   $2='obj_g' ;;
4714         profile) $2='obj_p' ;;
4715         shared)
4716                 case $cf_cv_system_name in #(vi
4717                 cygwin|msys) #(vi
4718                         $2='objects' ;;
4719                 *)
4720                         $2='obj_s' ;;
4721                 esac
4722         esac
4723 ])dnl
4724 dnl ---------------------------------------------------------------------------
4725 dnl CF_PATHSEP version: 6 updated: 2012/09/29 18:38:12
4726 dnl ----------
4727 dnl Provide a value for the $PATH and similar separator (or amend the value
4728 dnl as provided in autoconf 2.5x).
4729 AC_DEFUN([CF_PATHSEP],
4730 [
4731         AC_MSG_CHECKING(for PATH separator)
4732         case $cf_cv_system_name in
4733         os2*)   PATH_SEPARATOR=';'  ;;
4734         *)      ${PATH_SEPARATOR:=':'}  ;;
4735         esac
4736 ifelse([$1],,,[$1=$PATH_SEPARATOR])
4737         AC_SUBST(PATH_SEPARATOR)
4738         AC_MSG_RESULT($PATH_SEPARATOR)
4739 ])dnl
4740 dnl ---------------------------------------------------------------------------
4741 dnl CF_PATH_SYNTAX version: 14 updated: 2012/06/19 20:58:54
4742 dnl --------------
4743 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
4744 dnl begins with one of the prefix/exec_prefix variables, and then again if the
4745 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
4746 dnl delayed evaluation of those symbols.
4747 AC_DEFUN([CF_PATH_SYNTAX],[
4748 if test "x$prefix" != xNONE; then
4749   cf_path_syntax="$prefix"
4750 else
4751   cf_path_syntax="$ac_default_prefix"
4752 fi
4753
4754 case ".[$]$1" in #(vi
4755 .\[$]\(*\)*|.\'*\'*) #(vi
4756   ;;
4757 ..|./*|.\\*) #(vi
4758   ;;
4759 .[[a-zA-Z]]:[[\\/]]*) #(vi OS/2 EMX
4760   ;;
4761 .\[$]{*prefix}*|.\[$]{*dir}*) #(vi
4762   eval $1="[$]$1"
4763   case ".[$]$1" in #(vi
4764   .NONE/*)
4765     $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4766     ;;
4767   esac
4768   ;; #(vi
4769 .no|.NONE/*)
4770   $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
4771   ;;
4772 *)
4773   ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
4774   ;;
4775 esac
4776 ])dnl
4777 dnl ---------------------------------------------------------------------------
4778 dnl CF_PKG_CONFIG version: 7 updated: 2011/04/29 04:53:22
4779 dnl -------------
4780 dnl Check for the package-config program, unless disabled by command-line.
4781 AC_DEFUN([CF_PKG_CONFIG],
4782 [
4783 AC_MSG_CHECKING(if you want to use pkg-config)
4784 AC_ARG_WITH(pkg-config,
4785         [  --with-pkg-config{=path} enable/disable use of pkg-config],
4786         [cf_pkg_config=$withval],
4787         [cf_pkg_config=yes])
4788 AC_MSG_RESULT($cf_pkg_config)
4789
4790 case $cf_pkg_config in #(vi
4791 no) #(vi
4792         PKG_CONFIG=none
4793         ;;
4794 yes) #(vi
4795         CF_ACVERSION_CHECK(2.52,
4796                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
4797                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
4798         ;;
4799 *)
4800         PKG_CONFIG=$withval
4801         ;;
4802 esac
4803
4804 test -z "$PKG_CONFIG" && PKG_CONFIG=none
4805 if test "$PKG_CONFIG" != none ; then
4806         CF_PATH_SYNTAX(PKG_CONFIG)
4807 fi
4808
4809 AC_SUBST(PKG_CONFIG)
4810 ])dnl
4811 dnl ---------------------------------------------------------------------------
4812 dnl CF_POSIX_C_SOURCE version: 8 updated: 2010/05/26 05:38:42
4813 dnl -----------------
4814 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
4815 dnl
4816 dnl     POSIX.1-1990                            _POSIX_SOURCE
4817 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
4818 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
4819 dnl             Bindings Option
4820 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
4821 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
4822 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
4823 dnl
4824 dnl Parameters:
4825 dnl     $1 is the nominal value for _POSIX_C_SOURCE
4826 AC_DEFUN([CF_POSIX_C_SOURCE],
4827 [
4828 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
4829
4830 cf_save_CFLAGS="$CFLAGS"
4831 cf_save_CPPFLAGS="$CPPFLAGS"
4832
4833 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
4834 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
4835
4836 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
4837         CF_MSG_LOG(if the symbol is already defined go no further)
4838         AC_TRY_COMPILE([#include <sys/types.h>],[
4839 #ifndef _POSIX_C_SOURCE
4840 make an error
4841 #endif],
4842         [cf_cv_posix_c_source=no],
4843         [cf_want_posix_source=no
4844          case .$cf_POSIX_C_SOURCE in #(vi
4845          .[[12]]??*) #(vi
4846                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4847                 ;;
4848          .2) #(vi
4849                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
4850                 cf_want_posix_source=yes
4851                 ;;
4852          .*)
4853                 cf_want_posix_source=yes
4854                 ;;
4855          esac
4856          if test "$cf_want_posix_source" = yes ; then
4857                 AC_TRY_COMPILE([#include <sys/types.h>],[
4858 #ifdef _POSIX_SOURCE
4859 make an error
4860 #endif],[],
4861                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
4862          fi
4863          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
4864          CFLAGS="$cf_trim_CFLAGS"
4865          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
4866          CF_MSG_LOG(if the second compile does not leave our definition intact error)
4867          AC_TRY_COMPILE([#include <sys/types.h>],[
4868 #ifndef _POSIX_C_SOURCE
4869 make an error
4870 #endif],,
4871          [cf_cv_posix_c_source=no])
4872          CFLAGS="$cf_save_CFLAGS"
4873          CPPFLAGS="$cf_save_CPPFLAGS"
4874         ])
4875 ])
4876
4877 if test "$cf_cv_posix_c_source" != no ; then
4878         CFLAGS="$cf_trim_CFLAGS"
4879         CPPFLAGS="$cf_trim_CPPFLAGS"
4880         CF_ADD_CFLAGS($cf_cv_posix_c_source)
4881 fi
4882
4883 ])dnl
4884 dnl ---------------------------------------------------------------------------
4885 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
4886 dnl ------------
4887 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
4888 dnl
4889 dnl $1 = symbol to test
4890 dnl $2 = value (if any) to use for a predefinition
4891 AC_DEFUN([CF_PREDEFINE],
4892 [
4893 AC_MSG_CHECKING(if we must define $1)
4894 AC_TRY_COMPILE([#include <sys/types.h>
4895 ],[
4896 #ifndef $1
4897 make an error
4898 #endif],[cf_result=no],[cf_result=yes])
4899 AC_MSG_RESULT($cf_result)
4900
4901 if test "$cf_result" = yes ; then
4902         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
4903 elif test "x$2" != "x" ; then
4904         AC_MSG_CHECKING(checking for compatible value versus $2)
4905         AC_TRY_COMPILE([#include <sys/types.h>
4906 ],[
4907 #if $1-$2 < 0
4908 make an error
4909 #endif],[cf_result=yes],[cf_result=no])
4910         AC_MSG_RESULT($cf_result)
4911         if test "$cf_result" = no ; then
4912                 # perhaps we can override it - try...
4913                 CPPFLAGS="$CPPFLAGS -D$1=$2"
4914         fi
4915 fi
4916 ])dnl
4917 dnl ---------------------------------------------------------------------------
4918 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
4919 dnl ------------
4920 dnl Append definitions and rules for the given programs to the subdirectory
4921 dnl Makefiles, and the recursion rule for the top-level Makefile.
4922 dnl
4923 dnl parameters
4924 dnl     $1 = script to run
4925 dnl     $2 = list of subdirectories
4926 dnl
4927 dnl variables
4928 dnl     $AWK
4929 AC_DEFUN([CF_PRG_RULES],
4930 [
4931 for cf_dir in $2
4932 do
4933         if test ! -d $srcdir/$cf_dir; then
4934                 continue
4935         elif test -f $srcdir/$cf_dir/programs; then
4936                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
4937         fi
4938 done
4939
4940 ])dnl
4941 dnl ---------------------------------------------------------------------------
4942 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
4943 dnl ----------
4944 dnl Check for archiver "ar".
4945 AC_DEFUN([CF_PROG_AR],[
4946 AC_CHECK_TOOL(AR, ar, ar)
4947 ])
4948 dnl ---------------------------------------------------------------------------
4949 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
4950 dnl -----------
4951 dnl Check for awk, ensure that the check found something.
4952 AC_DEFUN([CF_PROG_AWK],
4953 [
4954 AC_PROG_AWK
4955 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
4956 ])dnl
4957 dnl ---------------------------------------------------------------------------
4958 dnl CF_PROG_CC version: 3 updated: 2012/10/06 15:31:55
4959 dnl ----------
4960 dnl standard check for CC, plus followup sanity checks
4961 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
4962 AC_DEFUN([CF_PROG_CC],[
4963 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
4964 CF_GCC_VERSION
4965 CF_ACVERSION_CHECK(2.52,
4966         [AC_PROG_CC_STDC],
4967         [CF_ANSI_CC_REQD])
4968 CF_CC_ENV_FLAGS
4969 ])dnl
4970 dnl ---------------------------------------------------------------------------
4971 dnl CF_PROG_CC_C_O version: 3 updated: 2010/08/14 18:25:37
4972 dnl --------------
4973 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
4974 dnl the output file can be renamed, and allows for a shell variable that can
4975 dnl be used later.  The parameter is either CC or CXX.  The result is the
4976 dnl cache variable:
4977 dnl     $cf_cv_prog_CC_c_o
4978 dnl     $cf_cv_prog_CXX_c_o
4979 AC_DEFUN([CF_PROG_CC_C_O],
4980 [AC_REQUIRE([AC_PROG_CC])dnl
4981 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
4982 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
4983 [
4984 cat > conftest.$ac_ext <<CF_EOF
4985 #include <stdio.h>
4986 int main()
4987 {
4988         ${cf_cv_main_return:-return}(0);
4989 }
4990 CF_EOF
4991 # We do the test twice because some compilers refuse to overwrite an
4992 # existing .o file with -o, though they will create one.
4993 ac_try='[$]$1 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
4994 if AC_TRY_EVAL(ac_try) &&
4995   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
4996 then
4997   eval cf_cv_prog_$1_c_o=yes
4998 else
4999   eval cf_cv_prog_$1_c_o=no
5000 fi
5001 rm -rf conftest*
5002 ])dnl
5003 if test $cf_cv_prog_$1_c_o = yes; then
5004   AC_MSG_RESULT([yes])
5005 else
5006   AC_MSG_RESULT([no])
5007 fi
5008 ])dnl
5009 dnl ---------------------------------------------------------------------------
5010 dnl CF_PROG_EGREP version: 1 updated: 2006/09/16 11:40:59
5011 dnl -------------
5012 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
5013 dnl This macro adds a check to ensure the script found something.
5014 AC_DEFUN([CF_PROG_EGREP],
5015 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
5016    [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
5017     then ac_cv_prog_egrep='grep -E'
5018     else ac_cv_prog_egrep='egrep'
5019     fi])
5020  EGREP=$ac_cv_prog_egrep
5021  AC_SUBST([EGREP])
5022 test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
5023 ])dnl
5024 dnl ---------------------------------------------------------------------------
5025 dnl CF_PROG_GNAT version: 2 updated: 2011/10/22 14:01:47
5026 dnl ------------
5027 dnl Check for gnatmake, ensure that it is complete.
5028 AC_DEFUN([CF_PROG_GNAT],[
5029 cf_ada_make=gnatmake
5030 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
5031 if test "$ac_cv_prog_gnat_exists" = no; then
5032    cf_ada_make=
5033    cf_cv_prog_gnat_correct=no
5034 else
5035    CF_GNAT_VERSION
5036    AC_CHECK_PROG(M4_exists, m4, yes, no)
5037    if test "$ac_cv_prog_M4_exists" = no; then
5038       cf_cv_prog_gnat_correct=no
5039       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
5040    fi
5041    if test "$cf_cv_prog_gnat_correct" = yes; then
5042       AC_MSG_CHECKING(if GNAT works)
5043       CF_GNAT_TRY_RUN([procedure conftest;],
5044 [with Text_IO;
5045 with GNAT.OS_Lib;
5046 procedure conftest is
5047 begin
5048    Text_IO.Put ("Hello World");
5049    Text_IO.New_Line;
5050    GNAT.OS_Lib.OS_Exit (0);
5051 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
5052       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
5053    fi
5054 fi
5055
5056 AC_SUBST(cf_ada_make)
5057 ])dnl
5058 dnl ---------------------------------------------------------------------------
5059 dnl CF_PROG_INSTALL version: 5 updated: 2002/12/21 22:46:07
5060 dnl ---------------
5061 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
5062 dnl misc/tabset install won't work properly.  Usually this happens only when
5063 dnl using the fallback mkinstalldirs script
5064 AC_DEFUN([CF_PROG_INSTALL],
5065 [AC_PROG_INSTALL
5066 case $INSTALL in
5067 /*)
5068   ;;
5069 *)
5070   CF_DIRNAME(cf_dir,$INSTALL)
5071   test -z "$cf_dir" && cf_dir=.
5072   INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
5073   ;;
5074 esac
5075 ])dnl
5076 dnl ---------------------------------------------------------------------------
5077 dnl CF_PROG_LDCONFIG version: 3 updated: 2011/06/04 20:09:13
5078 dnl ----------------
5079 dnl Check for ldconfig, needed to fixup shared libraries that would be built
5080 dnl and then used in the install.
5081 AC_DEFUN([CF_PROG_LDCONFIG],[
5082 if test "$cross_compiling" = yes ; then
5083   LDCONFIG=:
5084 else
5085 case "$cf_cv_system_name" in #(vi
5086 dragonfly*|mirbsd*|freebsd*) #(vi
5087   test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
5088   ;;
5089 *) LDPATH=$PATH:/sbin:/usr/sbin
5090   AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
5091   ;;
5092 esac
5093 fi
5094 AC_SUBST(LDCONFIG)
5095 ])dnl
5096 dnl ---------------------------------------------------------------------------
5097 dnl CF_PROG_LINT version: 2 updated: 2009/08/12 04:43:14
5098 dnl ------------
5099 AC_DEFUN([CF_PROG_LINT],
5100 [
5101 AC_CHECK_PROGS(LINT, tdlint lint alint splint lclint)
5102 AC_SUBST(LINT_OPTS)
5103 ])dnl
5104 dnl ---------------------------------------------------------------------------
5105 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
5106 dnl ------------
5107 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
5108 dnl option if it is supported.
5109 AC_DEFUN([CF_PROG_LN_S],[
5110 AC_PROG_LN_S
5111 AC_MSG_CHECKING(if $LN_S -f options work)
5112
5113 rm -f conf$$.src conf$$dst
5114 echo >conf$$.dst
5115 echo first >conf$$.src
5116 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
5117         cf_prog_ln_sf=yes
5118 else
5119         cf_prog_ln_sf=no
5120 fi
5121 rm -f conf$$.dst conf$$src
5122 AC_MSG_RESULT($cf_prog_ln_sf)
5123
5124 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
5125 ])dnl
5126 dnl ---------------------------------------------------------------------------
5127 dnl CF_REGEX version: 10 updated: 2012/10/04 20:12:20
5128 dnl --------
5129 dnl Attempt to determine if we've got one of the flavors of regular-expression
5130 dnl code that we can support.
5131 AC_DEFUN([CF_REGEX],
5132 [
5133
5134 cf_regex_func=no
5135
5136 cf_regex_libs="regex re"
5137 case $host_os in #(vi
5138 mingw*)
5139         cf_regex_libs="gnurx $cf_regex_libs"
5140         ;;
5141 esac
5142
5143 AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
5144         for cf_regex_lib in $cf_regex_libs
5145         do
5146                 AC_CHECK_LIB($cf_regex_lib,regcomp,[
5147                                 CF_ADD_LIB($cf_regex_lib)
5148                                 cf_regex_func=regcomp
5149                                 break])
5150         done
5151 ])
5152
5153 if test "$cf_regex_func" = no ; then
5154         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
5155                 AC_CHECK_LIB(gen,compile,[
5156                                 CF_ADD_LIB(gen)
5157                                 cf_regex_func=compile])])
5158 fi
5159
5160 if test "$cf_regex_func" = no ; then
5161         AC_MSG_WARN(cannot find regular expression library)
5162 fi
5163
5164 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
5165
5166 cf_cv_regex_hdrs=no
5167 case $cf_regex_func in #(vi
5168 compile) #(vi
5169         for cf_regex_hdr in regexp.h regexpr.h
5170         do
5171                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
5172                         char *p = compile("", "", "", 0);
5173                         int x = step("", "");
5174                 ],[
5175                         cf_cv_regex_hdrs=$cf_regex_hdr
5176                         break
5177                 ])
5178         done
5179         ;;
5180 *)
5181         for cf_regex_hdr in regex.h
5182         do
5183                 AC_TRY_LINK([#include <sys/types.h>
5184 #include <$cf_regex_hdr>],[
5185                         regex_t *p;
5186                         int x = regcomp(p, "", 0);
5187                         int y = regexec(p, "", 0, 0, 0);
5188                         regfree(p);
5189                 ],[
5190                         cf_cv_regex_hdrs=$cf_regex_hdr
5191                         break
5192                 ])
5193         done
5194         ;;
5195 esac
5196
5197 ])
5198
5199 case $cf_cv_regex_hdrs in #(vi
5200     no)        AC_MSG_WARN(no regular expression header found) ;; #(vi
5201     regex.h)   AC_DEFINE(HAVE_REGEX_H_FUNCS,1,[Define to 1 to include regex.h for regular expressions]) ;; #(vi
5202     regexp.h)  AC_DEFINE(HAVE_REGEXP_H_FUNCS,1,[Define to 1 to include regexp.h for regular expressions]) ;; #(vi
5203     regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS,1,[Define to 1 to include regexpr.h for regular expressions]) ;;
5204 esac
5205 ])dnl
5206 dnl ---------------------------------------------------------------------------
5207 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
5208 dnl ----------------
5209 dnl Remove all -U and -D options that refer to the given symbol from a list
5210 dnl of C compiler options.  This works around the problem that not all
5211 dnl compilers process -U and -D options from left-to-right, so a -U option
5212 dnl cannot be used to cancel the effect of a preceding -D option.
5213 dnl
5214 dnl $1 = target (which could be the same as the source variable)
5215 dnl $2 = source (including '$')
5216 dnl $3 = symbol to remove
5217 define([CF_REMOVE_DEFINE],
5218 [
5219 $1=`echo "$2" | \
5220         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
5221                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
5222 ])dnl
5223 dnl ---------------------------------------------------------------------------
5224 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
5225 dnl -------------
5226 dnl Remove the given library from the symbol
5227 dnl
5228 dnl $1 = target (which could be the same as the source variable)
5229 dnl $2 = source (including '$')
5230 dnl $3 = library to remove
5231 define([CF_REMOVE_LIB],
5232 [
5233 # remove $3 library from $2
5234 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
5235 ])dnl
5236 dnl ---------------------------------------------------------------------------
5237 dnl CF_RPATH_HACK version: 11 updated: 2013/09/01 13:02:00
5238 dnl -------------
5239 AC_DEFUN([CF_RPATH_HACK],
5240 [
5241 AC_REQUIRE([CF_LD_RPATH_OPT])
5242 AC_MSG_CHECKING(for updated LDFLAGS)
5243 if test -n "$LD_RPATH_OPT" ; then
5244         AC_MSG_RESULT(maybe)
5245
5246         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
5247         cf_rpath_list="/usr/lib /lib"
5248         if test "$cf_ldd_prog" != no
5249         then
5250                 cf_rpath_oops=
5251
5252 AC_TRY_LINK([#include <stdio.h>],
5253                 [printf("Hello");],
5254                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
5255                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
5256
5257                 # If we passed the link-test, but get a "not found" on a given library,
5258                 # this could be due to inept reconfiguration of gcc to make it only
5259                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
5260                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
5261                 # /usr/local libraries.
5262                 if test -n "$cf_rpath_oops"
5263                 then
5264                         for cf_rpath_src in $cf_rpath_oops
5265                         do
5266                                 for cf_rpath_dir in \
5267                                         /usr/local \
5268                                         /usr/pkg \
5269                                         /opt/sfw
5270                                 do
5271                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
5272                                         then
5273                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
5274                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
5275                                                 break
5276                                         fi
5277                                 done
5278                         done
5279                 fi
5280         fi
5281
5282         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5283
5284         CF_RPATH_HACK_2(LDFLAGS)
5285         CF_RPATH_HACK_2(LIBS)
5286
5287         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5288 else
5289         AC_MSG_RESULT(no)
5290 fi
5291 AC_SUBST(EXTRA_LDFLAGS)
5292 ])dnl
5293 dnl ---------------------------------------------------------------------------
5294 dnl CF_RPATH_HACK_2 version: 6 updated: 2010/04/17 16:31:24
5295 dnl ---------------
5296 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
5297 dnl EXTRA_LDFLAGS for each -L option found.
5298 dnl
5299 dnl $cf_rpath_list contains a list of directories to ignore.
5300 dnl
5301 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
5302 dnl      but LIBS often has misplaced -L options.
5303 AC_DEFUN([CF_RPATH_HACK_2],
5304 [
5305 CF_VERBOSE(...checking $1 [$]$1)
5306
5307 cf_rpath_dst=
5308 for cf_rpath_src in [$]$1
5309 do
5310         case $cf_rpath_src in #(vi
5311         -L*) #(vi
5312
5313                 # check if this refers to a directory which we will ignore
5314                 cf_rpath_skip=no
5315                 if test -n "$cf_rpath_list"
5316                 then
5317                         for cf_rpath_item in $cf_rpath_list
5318                         do
5319                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
5320                                 then
5321                                         cf_rpath_skip=yes
5322                                         break
5323                                 fi
5324                         done
5325                 fi
5326
5327                 if test "$cf_rpath_skip" = no
5328                 then
5329                         # transform the option
5330                         if test "$LD_RPATH_OPT" = "-R " ; then
5331                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
5332                         else
5333                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
5334                         fi
5335
5336                         # if we have not already added this, add it now
5337                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
5338                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
5339                         then
5340                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
5341                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
5342                         fi
5343                 fi
5344                 ;;
5345         esac
5346         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
5347 done
5348 $1=$cf_rpath_dst
5349
5350 CF_VERBOSE(...checked $1 [$]$1)
5351 AC_SUBST(EXTRA_LDFLAGS)
5352 ])dnl
5353 dnl ---------------------------------------------------------------------------
5354 dnl CF_SHARED_OPTS version: 84 updated: 2013/11/03 06:26:10
5355 dnl --------------
5356 dnl --------------
5357 dnl Attempt to determine the appropriate CC/LD options for creating a shared
5358 dnl library.
5359 dnl
5360 dnl Notes:
5361 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
5362 dnl the build-tree, i.e., by making use of the libraries that are compiled in
5363 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
5364 dnl shared library since that can lead to unexpected results at runtime.
5365 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
5366 dnl libraries are compiled in ../../lib
5367 dnl
5368 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
5369 dnl to install symbolic links to the rel/abi versions of shared libraries.
5370 dnl
5371 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
5372 dnl version when making symbolic links.
5373 dnl
5374 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
5375 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
5376 dnl (ex: libncurses.so.<ver>).
5377 dnl
5378 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
5379 AC_DEFUN([CF_SHARED_OPTS],
5380 [
5381         AC_REQUIRE([CF_LD_RPATH_OPT])
5382         RM_SHARED_OPTS=
5383         LOCAL_LDFLAGS=
5384         LOCAL_LDFLAGS2=
5385         LD_SHARED_OPTS=
5386         INSTALL_LIB="-m 644"
5387         : ${rel_builddir:=.}
5388
5389         shlibdir=$libdir
5390         AC_SUBST(shlibdir)
5391
5392         MAKE_DLLS="#"
5393         AC_SUBST(MAKE_DLLS)
5394
5395         cf_cv_do_symlinks=no
5396         cf_ld_rpath_opt=
5397         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
5398
5399         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
5400         AC_ARG_WITH(shlib-version,
5401         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
5402         [test -z "$withval" && withval=auto
5403         case $withval in #(vi
5404         yes) #(vi
5405                 cf_cv_shlib_version=auto
5406                 ;;
5407         rel|abi|auto|no) #(vi
5408                 cf_cv_shlib_version=$withval
5409                 ;;
5410         *)
5411                 AC_MSG_ERROR([option value must be one of: rel, abi, auto or no])
5412                 ;;
5413         esac
5414         ],[cf_cv_shlib_version=auto])
5415         AC_MSG_RESULT($cf_cv_shlib_version)
5416
5417         cf_cv_rm_so_locs=no
5418         cf_try_cflags=
5419
5420         # Some less-capable ports of gcc support only -fpic
5421         CC_SHARED_OPTS=
5422         if test "$GCC" = yes
5423         then
5424                 AC_MSG_CHECKING(which $CC option to use)
5425                 cf_save_CFLAGS="$CFLAGS"
5426                 for CC_SHARED_OPTS in -fPIC -fpic ''
5427                 do
5428                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
5429                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
5430                 done
5431                 AC_MSG_RESULT($CC_SHARED_OPTS)
5432                 CFLAGS="$cf_save_CFLAGS"
5433         fi
5434
5435         cf_cv_shlib_version_infix=no
5436
5437         case $cf_cv_system_name in #(vi
5438         aix4.[3-9]*|aix[[5-7]]*) #(vi
5439                 if test "$GCC" = yes; then
5440                         CC_SHARED_OPTS=
5441                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5442                 else
5443                         # CC_SHARED_OPTS='-qpic=large -G'
5444                         # perhaps "-bM:SRE -bnoentry -bexpall"
5445                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5446                 fi
5447                 ;;
5448         beos*) #(vi
5449                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
5450                 ;;
5451         cygwin*) #(vi
5452                 CC_SHARED_OPTS=
5453                 MK_SHARED_LIB='sh '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5454                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5455                 cf_cv_shlib_version=cygdll
5456                 cf_cv_shlib_version_infix=cygdll
5457                 shlibdir=$bindir
5458                 MAKE_DLLS=
5459                 cat >mk_shared_lib.sh <<-CF_EOF
5460                 #!/bin/sh
5461                 SHARED_LIB=\[$]1
5462                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5463                 shift
5464                 cat <<-EOF
5465                 Linking shared library
5466                 ** SHARED_LIB \[$]SHARED_LIB
5467                 ** IMPORT_LIB \[$]IMPORT_LIB
5468 EOF
5469                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5470 CF_EOF
5471                 chmod +x mk_shared_lib.sh
5472                 ;;
5473         msys*) #(vi
5474                 CC_SHARED_OPTS=
5475                 MK_SHARED_LIB='sh '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5476                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5477                 cf_cv_shlib_version=msysdll
5478                 cf_cv_shlib_version_infix=msysdll
5479                 shlibdir=$bindir
5480                 MAKE_DLLS=
5481                 cat >mk_shared_lib.sh <<-CF_EOF
5482                 #!/bin/sh
5483                 SHARED_LIB=\[$]1
5484                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5485                 shift
5486                 cat <<-EOF
5487                 Linking shared library
5488                 ** SHARED_LIB \[$]SHARED_LIB
5489                 ** IMPORT_LIB \[$]IMPORT_LIB
5490 EOF
5491                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5492 CF_EOF
5493                 chmod +x mk_shared_lib.sh
5494                 ;;
5495         darwin*) #(vi
5496                 cf_try_cflags="no-cpp-precomp"
5497                 CC_SHARED_OPTS="-dynamic"
5498                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
5499                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
5500                 cf_cv_shlib_version_infix=yes
5501                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
5502                         cf_save_LDFLAGS=$LDFLAGS
5503                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5504                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
5505                                 LDFLAGS=$cf_save_LDFLAGS])
5506                 if test $cf_cv_ldflags_search_paths_first = yes; then
5507                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5508                 fi
5509                 ;;
5510         hpux[[7-8]]*) #(vi
5511                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
5512                 if test "$GCC" != yes; then
5513                         CC_SHARED_OPTS='+Z'
5514                 fi
5515                 MK_SHARED_LIB='${LD} -b -o $[@]'
5516                 INSTALL_LIB="-m 555"
5517                 ;;
5518         hpux*) #(vi
5519                 # (tested with gcc 2.7.2 -- I don't have c89)
5520                 if test "$GCC" = yes; then
5521                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
5522                 else
5523                         CC_SHARED_OPTS='+Z'
5524                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
5525                 fi
5526                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
5527                 # HP-UX shared libraries must be executable, and should be
5528                 # readonly to exploit a quirk in the memory manager.
5529                 INSTALL_LIB="-m 555"
5530                 ;;
5531         interix*)
5532                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5533                 if test "$cf_cv_shlib_version" = rel; then
5534                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
5535                 else
5536                         cf_shared_soname='`basename $@`'
5537                 fi
5538                 CC_SHARED_OPTS=
5539                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
5540                 ;;
5541         irix*) #(vi
5542                 if test "$cf_cv_enable_rpath" = yes ; then
5543                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5544                 fi
5545                 # tested with IRIX 5.2 and 'cc'.
5546                 if test "$GCC" != yes; then
5547                         CC_SHARED_OPTS='-KPIC'
5548                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
5549                 else
5550                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
5551                 fi
5552                 cf_cv_rm_so_locs=yes
5553                 ;;
5554         linux*|gnu*|k*bsd*-gnu) #(vi
5555                 if test "$DFT_LWR_MODEL" = "shared" ; then
5556                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5557                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5558                 fi
5559                 if test "$cf_cv_enable_rpath" = yes ; then
5560                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5561                 fi
5562                 CF_SHARED_SONAME
5563                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5564                 ;;
5565         mingw*) #(vi
5566                 cf_cv_shlib_version=mingw
5567                 cf_cv_shlib_version_infix=mingw
5568                 shlibdir=$bindir
5569                 MAKE_DLLS=
5570                 if test "$DFT_LWR_MODEL" = "shared" ; then
5571                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
5572                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5573                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
5574                 fi
5575                 CC_SHARED_OPTS=
5576                 MK_SHARED_LIB='sh '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5577                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5578                 cat >mk_shared_lib.sh <<-CF_EOF
5579                 #!/bin/sh
5580                 SHARED_LIB=\[$]1
5581                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5582                 shift
5583                 cat <<-EOF
5584                 Linking shared library
5585                 ** SHARED_LIB \[$]SHARED_LIB
5586                 ** IMPORT_LIB \[$]IMPORT_LIB
5587 EOF
5588                 exec \[$]* -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5589 CF_EOF
5590                 chmod +x mk_shared_lib.sh
5591                 ;;
5592         openbsd[[2-9]].*|mirbsd*) #(vi
5593                 if test "$DFT_LWR_MODEL" = "shared" ; then
5594                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5595                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5596                 fi
5597                 if test "$cf_cv_enable_rpath" = yes ; then
5598                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5599                 fi
5600                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5601                 CF_SHARED_SONAME
5602                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
5603                 ;;
5604         nto-qnx*|openbsd*|freebsd[[12]].*) #(vi
5605                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5606                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
5607                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5608                 ;;
5609         dragonfly*|freebsd*) #(vi
5610                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5611                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5612                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5613                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
5614                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5615                 fi
5616                 CF_SHARED_SONAME
5617                 MK_SHARED_LIB='${LD} -shared -Bshareable -soname=`basename $[@]` -o $[@]'
5618                 ;;
5619         netbsd*) #(vi
5620                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
5621                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
5622                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
5623                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5624                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5625                         if test "$cf_cv_shlib_version" = auto; then
5626                         if test -f /usr/libexec/ld.elf_so; then
5627                                 cf_cv_shlib_version=abi
5628                         else
5629                                 cf_cv_shlib_version=rel
5630                         fi
5631                         fi
5632                         CF_SHARED_SONAME
5633                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
5634                 else
5635                         MK_SHARED_LIB='${CC} -Wl,-shared -Wl,-Bshareable -o $[@]'
5636                 fi
5637                 ;;
5638         osf*|mls+*) #(vi
5639                 # tested with OSF/1 V3.2 and 'cc'
5640                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
5641                 # link with shared libs).
5642                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
5643                 case $host_os in #(vi
5644                 osf4*)
5645                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
5646                         ;;
5647                 esac
5648                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
5649                 if test "$DFT_LWR_MODEL" = "shared" ; then
5650                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5651                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5652                 fi
5653                 cf_cv_rm_so_locs=yes
5654                 ;;
5655         sco3.2v5*)  # (also uw2* and UW7: hops 13-Apr-98
5656                 # tested with osr5.0.5
5657                 if test "$GCC" != yes; then
5658                         CC_SHARED_OPTS='-belf -KPIC'
5659                 fi
5660                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
5661                 if test "$cf_cv_enable_rpath" = yes ; then
5662                         # only way is to set LD_RUN_PATH but no switch for it
5663                         RUN_PATH=$libdir
5664                 fi
5665                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5666                 LINK_PROGS='LD_RUN_PATH=${libdir}'
5667                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
5668                 ;;
5669         sunos4*) #(vi
5670                 # tested with SunOS 4.1.1 and gcc 2.7.0
5671                 if test "$GCC" != yes; then
5672                         CC_SHARED_OPTS='-KPIC'
5673                 fi
5674                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
5675                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5676                 ;;
5677         solaris2*) #(vi
5678                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
5679                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
5680                 if test "$DFT_LWR_MODEL" = "shared" ; then
5681                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
5682                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5683                 fi
5684                 if test "$cf_cv_enable_rpath" = yes ; then
5685                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
5686                 fi
5687                 CF_SHARED_SONAME
5688                 if test "$GCC" != yes; then
5689                         cf_save_CFLAGS="$CFLAGS"
5690                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
5691                         do
5692                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
5693                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
5694                         done
5695                         CFLAGS="$cf_save_CFLAGS"
5696                         CC_SHARED_OPTS=$cf_shared_opts
5697                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5698                 else
5699                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
5700                 fi
5701                 ;;
5702         sysv5uw7*|unix_sv*) #(vi
5703                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
5704                 if test "$GCC" != yes; then
5705                         CC_SHARED_OPTS='-KPIC'
5706                 fi
5707                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
5708                 ;;
5709         *)
5710                 CC_SHARED_OPTS='unknown'
5711                 MK_SHARED_LIB='echo unknown'
5712                 ;;
5713         esac
5714
5715         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
5716         case "$cf_cv_shlib_version" in #(vi
5717         rel|abi)
5718                 case "$MK_SHARED_LIB" in #(vi
5719                 *'-o $[@]') #(vi
5720                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
5721                         ;;
5722                 *)
5723                         AC_MSG_WARN(ignored --with-shlib-version)
5724                         ;;
5725                 esac
5726                 ;;
5727         esac
5728
5729         if test -n "$cf_try_cflags"
5730         then
5731 cat > conftest.$ac_ext <<EOF
5732 #line __oline__ "${as_me:-configure}"
5733 #include <stdio.h>
5734 int main(int argc, char *argv[[]])
5735 {
5736         printf("hello\n");
5737         return (argv[[argc-1]] == 0) ;
5738 }
5739 EOF
5740                 cf_save_CFLAGS="$CFLAGS"
5741                 for cf_opt in $cf_try_cflags
5742                 do
5743                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
5744                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
5745                         if AC_TRY_EVAL(ac_compile); then
5746                                 AC_MSG_RESULT(yes)
5747                                 cf_save_CFLAGS="$CFLAGS"
5748                         else
5749                                 AC_MSG_RESULT(no)
5750                         fi
5751                 done
5752                 CFLAGS="$cf_save_CFLAGS"
5753         fi
5754
5755
5756         # RPATH_LIST is a colon-separated list of directories
5757         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
5758         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
5759
5760         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
5761
5762         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
5763         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
5764
5765         AC_SUBST(CC_SHARED_OPTS)
5766         AC_SUBST(LD_RPATH_OPT)
5767         AC_SUBST(LD_SHARED_OPTS)
5768         AC_SUBST(MK_SHARED_LIB)
5769         AC_SUBST(RM_SHARED_OPTS)
5770
5771         AC_SUBST(LINK_PROGS)
5772         AC_SUBST(LINK_TESTS)
5773
5774         AC_SUBST(EXTRA_LDFLAGS)
5775         AC_SUBST(LOCAL_LDFLAGS)
5776         AC_SUBST(LOCAL_LDFLAGS2)
5777
5778         AC_SUBST(INSTALL_LIB)
5779         AC_SUBST(RPATH_LIST)
5780 ])dnl
5781 dnl ---------------------------------------------------------------------------
5782 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
5783 dnl ----------------
5784 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
5785 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
5786 dnl option.
5787 dnl
5788 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
5789 dnl If missing, use "rel".
5790 define([CF_SHARED_SONAME],
5791 [
5792         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
5793         if test "$cf_cv_shlib_version" = rel; then
5794                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
5795         else
5796                 cf_cv_shared_soname='`basename $[@]`'
5797         fi
5798 ])
5799 dnl ---------------------------------------------------------------------------
5800 dnl CF_SIGWINCH version: 1 updated: 2006/04/02 16:41:09
5801 dnl -----------
5802 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
5803 dnl programs need this test).
5804 dnl
5805 dnl This is really a MacOS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
5806 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
5807 dnl winsize declaration is left alone - we may revisit this if Apple choose to
5808 dnl break that part of the interface as well.
5809 AC_DEFUN([CF_SIGWINCH],
5810 [
5811 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
5812         AC_TRY_COMPILE([
5813 #include <sys/types.h>
5814 #include <sys/signal.h>
5815 ],[int x = SIGWINCH],
5816         [cf_cv_define_sigwinch=yes],
5817         [AC_TRY_COMPILE([
5818 #undef _XOPEN_SOURCE
5819 #undef _POSIX_SOURCE
5820 #undef _POSIX_C_SOURCE
5821 #include <sys/types.h>
5822 #include <sys/signal.h>
5823 ],[int x = SIGWINCH],
5824         [cf_cv_define_sigwinch=maybe],
5825         [cf_cv_define_sigwinch=no])
5826 ])
5827 ])
5828
5829 if test "$cf_cv_define_sigwinch" = maybe ; then
5830 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
5831 cf_cv_fixup_sigwinch=unknown
5832 cf_sigwinch=32
5833 while test $cf_sigwinch != 1
5834 do
5835         AC_TRY_COMPILE([
5836 #undef _XOPEN_SOURCE
5837 #undef _POSIX_SOURCE
5838 #undef _POSIX_C_SOURCE
5839 #include <sys/types.h>
5840 #include <sys/signal.h>
5841 ],[
5842 #if SIGWINCH != $cf_sigwinch
5843 make an error
5844 #endif
5845 int x = SIGWINCH],
5846         [cf_cv_fixup_sigwinch=$cf_sigwinch
5847          break])
5848
5849 cf_sigwinch=`expr $cf_sigwinch - 1`
5850 done
5851 ])
5852
5853         if test "$cf_cv_fixup_sigwinch" != unknown ; then
5854                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
5855         fi
5856 fi
5857 ])dnl
5858 dnl ---------------------------------------------------------------------------
5859 dnl CF_SIG_ATOMIC_T version: 3 updated: 2012/10/04 20:12:20
5860 dnl ---------------
5861 dnl signal handler, but there are some gcc depedencies in that recommendation.
5862 dnl Try anyway.
5863 AC_DEFUN([CF_SIG_ATOMIC_T],
5864 [
5865 AC_MSG_CHECKING(for signal global datatype)
5866 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
5867         for cf_type in \
5868                 "volatile sig_atomic_t" \
5869                 "sig_atomic_t" \
5870                 "int"
5871         do
5872         AC_TRY_COMPILE([
5873 #include <sys/types.h>
5874 #include <signal.h>
5875 #include <stdio.h>
5876
5877 extern $cf_type x;
5878 $cf_type x;
5879 static void handler(int sig)
5880 {
5881         x = 5;
5882 }],
5883                 [signal(SIGINT, handler);
5884                  x = 1],
5885                 [cf_cv_sig_atomic_t=$cf_type],
5886                 [cf_cv_sig_atomic_t=no])
5887                 test "$cf_cv_sig_atomic_t" != no && break
5888         done
5889         ])
5890 AC_MSG_RESULT($cf_cv_sig_atomic_t)
5891 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
5892 ])dnl
5893 dnl ---------------------------------------------------------------------------
5894 dnl CF_SIZECHANGE version: 9 updated: 2012/10/06 11:17:15
5895 dnl -------------
5896 dnl Check for definitions & structures needed for window size-changing
5897 dnl FIXME: check that this works with "snake" (HP-UX 10.x)
5898 AC_DEFUN([CF_SIZECHANGE],
5899 [
5900 AC_REQUIRE([CF_STRUCT_TERMIOS])
5901 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
5902     cf_cv_sizechange=unknown
5903     cf_save_CPPFLAGS="$CPPFLAGS"
5904
5905 for cf_opts in "" "NEED_PTEM_H"
5906 do
5907
5908     CPPFLAGS="$cf_save_CPPFLAGS"
5909     test -n "$cf_opts" && CPPFLAGS="$CPPFLAGS -D$cf_opts"
5910     AC_TRY_COMPILE([#include <sys/types.h>
5911 #ifdef HAVE_TERMIOS_H
5912 #include <termios.h>
5913 #else
5914 #ifdef HAVE_TERMIO_H
5915 #include <termio.h>
5916 #endif
5917 #endif
5918 #ifdef NEED_PTEM_H
5919 /* This is a workaround for SCO:  they neglected to define struct winsize in
5920  * termios.h -- it's only in termio.h and ptem.h
5921  */
5922 #include        <sys/stream.h>
5923 #include        <sys/ptem.h>
5924 #endif
5925 #if !defined(sun) || !defined(HAVE_TERMIOS_H)
5926 #include <sys/ioctl.h>
5927 #endif
5928 ],[
5929 #ifdef TIOCGSIZE
5930         struct ttysize win;     /* FIXME: what system is this? */
5931         int y = win.ts_lines;
5932         int x = win.ts_cols;
5933 #else
5934 #ifdef TIOCGWINSZ
5935         struct winsize win;
5936         int y = win.ws_row;
5937         int x = win.ws_col;
5938 #else
5939         no TIOCGSIZE or TIOCGWINSZ
5940 #endif /* TIOCGWINSZ */
5941 #endif /* TIOCGSIZE */
5942         ],
5943         [cf_cv_sizechange=yes],
5944         [cf_cv_sizechange=no])
5945
5946         CPPFLAGS="$cf_save_CPPFLAGS"
5947         if test "$cf_cv_sizechange" = yes ; then
5948                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
5949                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
5950                 break
5951         fi
5952 done
5953 ])
5954 if test "$cf_cv_sizechange" != no ; then
5955         AC_DEFINE(HAVE_SIZECHANGE,1,[Define to 1 if sizechar declarations are provided])
5956         case $cf_cv_sizechange in #(vi
5957         NEED*)
5958                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
5959                 ;;
5960         esac
5961 fi
5962 ])dnl
5963 dnl ---------------------------------------------------------------------------
5964 dnl CF_SRC_MODULES version: 27 updated: 2013/08/03 18:18:08
5965 dnl --------------
5966 dnl For each parameter, test if the source-directory exists, and if it contains
5967 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
5968 dnl use in CF_LIB_RULES.
5969 dnl
5970 dnl This uses the configured value to make the lists SRC_SUBDIRS and
5971 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
5972 AC_DEFUN([CF_SRC_MODULES],
5973 [
5974 AC_MSG_CHECKING(for src modules)
5975
5976 # dependencies and linker-arguments for test-programs
5977 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
5978 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
5979 if test "$DFT_LWR_MODEL" = "libtool"; then
5980         TEST_ARGS="${TEST_DEPS}"
5981         TEST_ARG2="${TEST_DEP2}"
5982 else
5983         TEST_ARGS="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARGS"
5984         TEST_ARG2="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARG2"
5985 fi
5986
5987 PC_MODULES_TO_MAKE="ncurses${DFT_ARG_SUFFIX}"
5988 cf_cv_src_modules=
5989 for cf_dir in $1
5990 do
5991         if test -f $srcdir/$cf_dir/modules; then
5992
5993                 # We may/may not have tack in the distribution, though the
5994                 # makefile is.
5995                 if test $cf_dir = tack ; then
5996                         if test ! -f $srcdir/${cf_dir}/${cf_dir}.h; then
5997                                 continue
5998                         fi
5999                 fi
6000
6001                 if test -z "$cf_cv_src_modules"; then
6002                         cf_cv_src_modules=$cf_dir
6003                 else
6004                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
6005                 fi
6006
6007                 # Make the ncurses_cfg.h file record the library interface files as
6008                 # well.  These are header files that are the same name as their
6009                 # directory.  Ncurses is the only library that does not follow
6010                 # that pattern.
6011                 if test $cf_dir = tack ; then
6012                         continue
6013                 elif test -f $srcdir/${cf_dir}/${cf_dir}.h; then
6014                         CF_UPPER(cf_have_include,$cf_dir)
6015                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
6016                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
6017                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEPS"
6018                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEP2"
6019                         if test "$DFT_LWR_MODEL" = "libtool"; then
6020                                 TEST_ARGS="${TEST_DEPS}"
6021                                 TEST_ARG2="${TEST_DEP2}"
6022                         else
6023                                 TEST_ARGS="-l${cf_dir}${DFT_ARG_SUFFIX} $TEST_ARGS"
6024                                 TEST_ARG2="-l${cf_dir}${DFT_ARG_SUFFIX} $TEST_ARG2"
6025                         fi
6026                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${DFT_ARG_SUFFIX}"
6027                 fi
6028         fi
6029 done
6030 AC_MSG_RESULT($cf_cv_src_modules)
6031
6032 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
6033 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
6034
6035 AC_SUBST(TEST_ARGS)
6036 AC_SUBST(TEST_DEPS)
6037
6038 AC_SUBST(TEST_ARG2)
6039 AC_SUBST(TEST_DEP2)
6040
6041 SRC_SUBDIRS=
6042 if test "x$cf_with_manpages" != xno ; then
6043         SRC_SUBDIRS="$SRC_SUBDIRS man"
6044 fi
6045 SRC_SUBDIRS="$SRC_SUBDIRS include"
6046 for cf_dir in $cf_cv_src_modules
6047 do
6048         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
6049 done
6050 if test "x$cf_with_tests" != "xno" ; then
6051         SRC_SUBDIRS="$SRC_SUBDIRS test"
6052 fi
6053 if test "x$cf_with_db_install" = xyes; then
6054         test -z "$MAKE_TERMINFO" && SRC_SUBDIRS="$SRC_SUBDIRS misc"
6055 fi
6056 if test "$cf_with_cxx_binding" != no; then
6057         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${DFT_ARG_SUFFIX}"
6058         SRC_SUBDIRS="$SRC_SUBDIRS c++"
6059 fi
6060
6061 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
6062 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
6063
6064 AC_SUBST(PC_MODULES_TO_MAKE)
6065
6066 ADA_SUBDIRS=
6067 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f $srcdir/Ada95/Makefile.in; then
6068         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
6069         ADA_SUBDIRS="gen src"
6070         if test "x$cf_with_tests" != "xno" ; then
6071                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
6072         fi
6073 fi
6074
6075 SUB_MAKEFILES=
6076 for cf_dir in $SRC_SUBDIRS
6077 do
6078         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
6079 done
6080
6081 if test -n "$ADA_SUBDIRS"; then
6082         for cf_dir in $ADA_SUBDIRS
6083         do
6084                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
6085         done
6086         AC_SUBST(ADA_SUBDIRS)
6087 fi
6088 ])dnl
6089 dnl ---------------------------------------------------------------------------
6090 dnl CF_STDCPP_LIBRARY version: 7 updated: 2010/05/29 16:31:02
6091 dnl -----------------
6092 dnl Check for -lstdc++, which is GNU's standard C++ library.
6093 AC_DEFUN([CF_STDCPP_LIBRARY],
6094 [
6095 if test -n "$GXX" ; then
6096 case $cf_cv_system_name in #(vi
6097 os2*) #(vi
6098         cf_stdcpp_libname=stdcpp
6099         ;;
6100 *)
6101         cf_stdcpp_libname=stdc++
6102         ;;
6103 esac
6104 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
6105         cf_save="$LIBS"
6106         CF_ADD_LIB($cf_stdcpp_libname)
6107 AC_TRY_LINK([
6108 #include <strstream.h>],[
6109 char buf[80];
6110 strstreambuf foo(buf, sizeof(buf))
6111 ],
6112         [cf_cv_libstdcpp=yes],
6113         [cf_cv_libstdcpp=no])
6114         LIBS="$cf_save"
6115 ])
6116 test "$cf_cv_libstdcpp" = yes && CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS)
6117 fi
6118 ])dnl
6119 dnl ---------------------------------------------------------------------------
6120 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
6121 dnl --------------
6122 dnl     Remove "-g" option from the compiler options
6123 AC_DEFUN([CF_STRIP_G_OPT],
6124 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
6125 dnl ---------------------------------------------------------------------------
6126 dnl CF_STRUCT_SIGACTION version: 5 updated: 2012/10/06 17:56:13
6127 dnl -------------------
6128 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
6129 dnl do this if we've found the sigaction function.
6130 AC_DEFUN([CF_STRUCT_SIGACTION],[
6131 AC_REQUIRE([CF_XOPEN_SOURCE])
6132
6133 if test "$ac_cv_func_sigaction" = yes; then
6134 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
6135 AC_TRY_COMPILE([
6136 #include <sys/types.h>
6137 #include <signal.h>],
6138         [struct sigaction act],
6139         [sigact_bad=no],
6140         [
6141 AC_TRY_COMPILE([
6142 #define _POSIX_SOURCE
6143 #include <sys/types.h>
6144 #include <signal.h>],
6145         [struct sigaction act],
6146         [sigact_bad=yes
6147          AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE])],
6148          [sigact_bad=unknown])])
6149 AC_MSG_RESULT($sigact_bad)
6150 fi
6151 ])dnl
6152 dnl ---------------------------------------------------------------------------
6153 dnl CF_STRUCT_TERMIOS version: 7 updated: 2012/10/06 17:56:13
6154 dnl -----------------
6155 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
6156 AC_DEFUN([CF_STRUCT_TERMIOS],[
6157 AC_REQUIRE([CF_XOPEN_SOURCE])
6158
6159 AC_CHECK_HEADERS( \
6160 termio.h \
6161 termios.h \
6162 unistd.h \
6163 )
6164
6165 if test "$ISC" = yes ; then
6166         AC_CHECK_HEADERS( sys/termio.h )
6167 fi
6168 if test "$ac_cv_header_termios_h" = yes ; then
6169         case "$CFLAGS $CPPFLAGS" in
6170         *-D_POSIX_SOURCE*)
6171                 termios_bad=dunno ;;
6172         *)      termios_bad=maybe ;;
6173         esac
6174         if test "$termios_bad" = maybe ; then
6175         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
6176         AC_TRY_COMPILE([#include <termios.h>],
6177                 [struct termios foo; int x = foo.c_iflag],
6178                 termios_bad=no, [
6179                 AC_TRY_COMPILE([
6180 #define _POSIX_SOURCE
6181 #include <termios.h>],
6182                         [struct termios foo; int x = foo.c_iflag],
6183                         termios_bad=unknown,
6184                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE]))
6185                         ])
6186         AC_MSG_RESULT($termios_bad)
6187         fi
6188 fi
6189 ])dnl
6190 dnl ---------------------------------------------------------------------------
6191 dnl CF_SUBDIR_PATH version: 6 updated: 2010/04/21 06:20:50
6192 dnl --------------
6193 dnl Construct a search-list for a nonstandard header/lib-file
6194 dnl     $1 = the variable to return as result
6195 dnl     $2 = the package name
6196 dnl     $3 = the subdirectory, e.g., bin, include or lib
6197 AC_DEFUN([CF_SUBDIR_PATH],
6198 [
6199 $1=
6200
6201 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr,$prefix)
6202 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
6203 CF_ADD_SUBDIR_PATH($1,$2,$3,/usr/local,$prefix)
6204 CF_ADD_SUBDIR_PATH($1,$2,$3,/opt,$prefix)
6205 CF_ADD_SUBDIR_PATH($1,$2,$3,[$]HOME,$prefix)
6206 ])dnl
6207 dnl ---------------------------------------------------------------------------
6208 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
6209 dnl -----------
6210 dnl     Shorthand macro for substituting things that the user may override
6211 dnl     with an environment variable.
6212 dnl
6213 dnl     $1 = condition to pass to "test"
6214 dnl     $2 = environment variable
6215 dnl     $3 = value if the test succeeds
6216 dnl     $4 = value if the test fails
6217 AC_DEFUN([CF_SUBST_IF],
6218 [
6219 if test $1 ; then
6220         $2=$3
6221 ifelse($4,,,[else
6222         $2=$4])
6223 fi
6224 AC_SUBST($2)
6225 ])dnl
6226 dnl ---------------------------------------------------------------------------
6227 dnl CF_SUBST_NCURSES_VERSION version: 8 updated: 2006/09/16 11:40:59
6228 dnl ------------------------
6229 dnl Get the version-number for use in shared-library naming, etc.
6230 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
6231 [
6232 AC_REQUIRE([CF_PROG_EGREP])
6233 NCURSES_MAJOR="`$ac_cv_prog_egrep '^NCURSES_MAJOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6234 NCURSES_MINOR="`$ac_cv_prog_egrep '^NCURSES_MINOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6235 NCURSES_PATCH="`$ac_cv_prog_egrep '^NCURSES_PATCH[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6236 cf_cv_abi_version=${NCURSES_MAJOR}
6237 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
6238 dnl Show the computed version, for logging
6239 cf_cv_timestamp=`date`
6240 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
6241 dnl We need these values in the generated headers
6242 AC_SUBST(NCURSES_MAJOR)
6243 AC_SUBST(NCURSES_MINOR)
6244 AC_SUBST(NCURSES_PATCH)
6245 dnl We need these values in the generated makefiles
6246 AC_SUBST(cf_cv_rel_version)
6247 AC_SUBST(cf_cv_abi_version)
6248 AC_SUBST(cf_cv_builtin_bool)
6249 AC_SUBST(cf_cv_header_stdbool_h)
6250 AC_SUBST(cf_cv_type_of_bool)dnl
6251 ])dnl
6252 dnl ---------------------------------------------------------------------------
6253 dnl CF_SYS_TIME_SELECT version: 5 updated: 2012/10/04 05:24:07
6254 dnl ------------------
6255 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
6256 dnl older SCO configurations.
6257 AC_DEFUN([CF_SYS_TIME_SELECT],
6258 [
6259 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
6260 AC_CACHE_VAL(cf_cv_sys_time_select,[
6261 AC_TRY_COMPILE([
6262 #include <sys/types.h>
6263 #ifdef HAVE_SYS_TIME_H
6264 #include <sys/time.h>
6265 #endif
6266 #ifdef HAVE_SYS_SELECT_H
6267 #include <sys/select.h>
6268 #endif
6269 ],[],[cf_cv_sys_time_select=yes],
6270      [cf_cv_sys_time_select=no])
6271      ])
6272 AC_MSG_RESULT($cf_cv_sys_time_select)
6273 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
6274 ])dnl
6275 dnl ---------------------------------------------------------------------------
6276 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
6277 dnl ---------------
6278 dnl Define a top_builddir symbol, for applications that need an absolute path.
6279 AC_DEFUN([CF_TOP_BUILDDIR],
6280 [
6281 top_builddir=ifelse($1,,`pwd`,$1)
6282 AC_SUBST(top_builddir)
6283 ])dnl
6284 dnl ---------------------------------------------------------------------------
6285 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
6286 dnl -------------------
6287 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
6288 dnl can define it successfully.
6289 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
6290 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
6291         AC_TRY_COMPILE([
6292 #include <stdlib.h>
6293 #include <string.h>
6294 #include <sys/types.h>
6295 ],[
6296 #ifndef _XOPEN_SOURCE
6297 make an error
6298 #endif],
6299         [cf_cv_xopen_source=no],
6300         [cf_save="$CPPFLAGS"
6301          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
6302          AC_TRY_COMPILE([
6303 #include <stdlib.h>
6304 #include <string.h>
6305 #include <sys/types.h>
6306 ],[
6307 #ifdef _XOPEN_SOURCE
6308 make an error
6309 #endif],
6310         [cf_cv_xopen_source=no],
6311         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
6312         CPPFLAGS="$cf_save"
6313         ])
6314 ])
6315
6316 if test "$cf_cv_xopen_source" != no ; then
6317         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
6318         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
6319         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
6320         CF_ADD_CFLAGS($cf_temp_xopen_source)
6321 fi
6322 ])
6323 dnl ---------------------------------------------------------------------------
6324 dnl CF_TYPEOF_CHTYPE version: 9 updated: 2012/10/06 17:56:13
6325 dnl ----------------
6326 dnl Determine the type we should use for chtype (and attr_t, which is treated
6327 dnl as the same thing).  We want around 32 bits, so on most machines want a
6328 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
6329 dnl wide characters, we have to have a type compatible with that, as well.
6330 AC_DEFUN([CF_TYPEOF_CHTYPE],
6331 [
6332 AC_MSG_CHECKING([for type of chtype])
6333 AC_CACHE_VAL(cf_cv_typeof_chtype,[
6334                 AC_TRY_RUN([
6335 #define WANT_BITS 31
6336 #include <stdio.h>
6337 int main()
6338 {
6339         FILE *fp = fopen("cf_test.out", "w");
6340         if (fp != 0) {
6341                 char *result = "long";
6342                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
6343                         int n;
6344                         unsigned int x, y;
6345                         for (n = 0; n < WANT_BITS; n++) {
6346                                 x = (1 << n);
6347                                 y = (x >> n);
6348                                 if (y != 1 || x == 0) {
6349                                         x = 0;
6350                                         break;
6351                                 }
6352                         }
6353                         /*
6354                          * If x is nonzero, an int is big enough for the bits
6355                          * that we want.
6356                          */
6357                         result = (x != 0) ? "int" : "long";
6358                 }
6359                 fputs(result, fp);
6360                 fclose(fp);
6361         }
6362         ${cf_cv_main_return:-return}(0);
6363 }
6364                 ],
6365                 [cf_cv_typeof_chtype=`cat cf_test.out`],
6366                 [cf_cv_typeof_chtype=long],
6367                 [cf_cv_typeof_chtype=long])
6368                 rm -f cf_test.out
6369         ])
6370 AC_MSG_RESULT($cf_cv_typeof_chtype)
6371
6372 AC_SUBST(cf_cv_typeof_chtype)
6373 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype,[Define to actual type if needed for chtype])
6374 ])dnl
6375 dnl ---------------------------------------------------------------------------
6376 dnl CF_TYPE_SIGACTION version: 4 updated: 2012/10/06 17:56:13
6377 dnl -----------------
6378 dnl
6379 AC_DEFUN([CF_TYPE_SIGACTION],
6380 [
6381 AC_MSG_CHECKING([for type sigaction_t])
6382 AC_CACHE_VAL(cf_cv_type_sigaction,[
6383         AC_TRY_COMPILE([
6384 #include <signal.h>],
6385                 [sigaction_t x],
6386                 [cf_cv_type_sigaction=yes],
6387                 [cf_cv_type_sigaction=no])])
6388 AC_MSG_RESULT($cf_cv_type_sigaction)
6389 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION,1,[Define to 1 if we have the sigaction_t type])
6390 ])dnl
6391 dnl ---------------------------------------------------------------------------
6392 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
6393 dnl --------------------
6394 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
6395 dnl won't, but they're still there.
6396 AC_DEFUN([CF_UNSIGNED_LITERALS],
6397 [
6398 AC_MSG_CHECKING([if unsigned literals are legal])
6399 AC_CACHE_VAL(cf_cv_unsigned_literals,[
6400         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
6401                 [cf_cv_unsigned_literals=yes],
6402                 [cf_cv_unsigned_literals=no])
6403         ])
6404 AC_MSG_RESULT($cf_cv_unsigned_literals)
6405 ])dnl
6406 dnl ---------------------------------------------------------------------------
6407 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
6408 dnl --------
6409 dnl Make an uppercase version of a variable
6410 dnl $1=uppercase($2)
6411 AC_DEFUN([CF_UPPER],
6412 [
6413 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
6414 ])dnl
6415 dnl ---------------------------------------------------------------------------
6416 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
6417 dnl -----------
6418 dnl Check for multibyte support, and if not found, utf8 compatibility library
6419 AC_DEFUN([CF_UTF8_LIB],
6420 [
6421 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
6422         cf_save_LIBS="$LIBS"
6423         AC_TRY_LINK([
6424 #include <stdlib.h>],[putwc(0,0);],
6425         [cf_cv_utf8_lib=yes],
6426         [CF_FIND_LINKAGE([
6427 #include <libutf8.h>],[putwc(0,0);],utf8,
6428                 [cf_cv_utf8_lib=add-on],
6429                 [cf_cv_utf8_lib=no])
6430 ])])
6431
6432 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
6433 # ncurses/ncursesw:
6434 if test "$cf_cv_utf8_lib" = "add-on" ; then
6435         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
6436         CF_ADD_INCDIR($cf_cv_header_path_utf8)
6437         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
6438         CF_ADD_LIBS($cf_cv_library_file_utf8)
6439 fi
6440 ])dnl
6441 dnl ---------------------------------------------------------------------------
6442 dnl CF_VA_COPY version: 3 updated: 2012/10/06 11:17:15
6443 dnl ----------
6444 dnl check for va_copy, part of stdarg.h
6445 dnl Also, workaround for glibc's __va_copy, by checking for both.
6446 AC_DEFUN([CF_VA_COPY],[
6447 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
6448 AC_TRY_LINK([
6449 #include <stdarg.h>
6450 ],[
6451         static va_list dst;
6452         static va_list src;
6453         va_copy(dst, src)],
6454         cf_cv_have_va_copy=yes,
6455         cf_cv_have_va_copy=no)])
6456
6457 test "$cf_cv_have_va_copy" = yes && AC_DEFINE(HAVE_VA_COPY,1,[Define to 1 if we have va_copy])
6458
6459 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
6460 AC_TRY_LINK([
6461 #include <stdarg.h>
6462 ],[
6463         static va_list dst;
6464         static va_list src;
6465         __va_copy(dst, src)],
6466         cf_cv_have___va_copy=yes,
6467         cf_cv_have___va_copy=no)])
6468
6469 test "$cf_cv_have___va_copy" = yes && AC_DEFINE(HAVE___VA_COPY,1,[Define to 1 if we have __va_copy])
6470 ])
6471 dnl ---------------------------------------------------------------------------
6472 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
6473 dnl ----------
6474 dnl Use AC_VERBOSE w/o the warnings
6475 AC_DEFUN([CF_VERBOSE],
6476 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
6477 CF_MSG_LOG([$1])
6478 ])dnl
6479 dnl ---------------------------------------------------------------------------
6480 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
6481 dnl -------------
6482 dnl Check if type wide-character type $1 is declared, and if so, which header
6483 dnl file is needed.  The second parameter is used to set a shell variable when
6484 dnl the type is not found.  The first parameter sets a shell variable for the
6485 dnl opposite sense.
6486 AC_DEFUN([CF_WCHAR_TYPE],
6487 [
6488 # This is needed on Tru64 5.0 to declare $1
6489 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
6490 AC_TRY_COMPILE([
6491 #include <stdlib.h>
6492 #include <stdarg.h>
6493 #include <stdio.h>
6494 #ifdef HAVE_LIBUTF8_H
6495 #include <libutf8.h>
6496 #endif],
6497         [$1 state],
6498         [cf_cv_$1=no],
6499         [AC_TRY_COMPILE([
6500 #include <stdlib.h>
6501 #include <stdarg.h>
6502 #include <stdio.h>
6503 #include <wchar.h>
6504 #ifdef HAVE_LIBUTF8_H
6505 #include <libutf8.h>
6506 #endif],
6507         [$1 value],
6508         [cf_cv_$1=yes],
6509         [cf_cv_$1=unknown])])])
6510
6511 if test "$cf_cv_$1" = yes ; then
6512         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
6513         NEED_WCHAR_H=1
6514 fi
6515
6516 ifelse([$2],,,[
6517 # if we do not find $1 in either place, use substitution to provide a fallback.
6518 if test "$cf_cv_$1" = unknown ; then
6519         $2=1
6520 fi
6521 ])
6522 ifelse($3,,,[
6523 # if we find $1 in either place, use substitution to provide a fallback.
6524 if test "$cf_cv_$1" != unknown ; then
6525         $3=1
6526 fi
6527 ])
6528 ])dnl
6529 dnl ---------------------------------------------------------------------------
6530 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
6531 dnl ---------------
6532 dnl Check for compiler-support for weak symbols.
6533 dnl This works with "recent" gcc.
6534 AC_DEFUN([CF_WEAK_SYMBOLS],[
6535 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
6536
6537 AC_TRY_COMPILE([
6538 #include <stdio.h>],
6539 [
6540 #if defined(__GNUC__)
6541 #  if defined __USE_ISOC99
6542 #    define _cat_pragma(exp)    _Pragma(#exp)
6543 #    define _weak_pragma(exp)   _cat_pragma(weak name)
6544 #  else
6545 #    define _weak_pragma(exp)
6546 #  endif
6547 #  define _declare(name)        __extension__ extern __typeof__(name) name
6548 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
6549 #endif
6550
6551 weak_symbol(fopen);
6552 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
6553 ])
6554 ])dnl
6555 dnl ---------------------------------------------------------------------------
6556 dnl CF_WITH_ABI_VERSION version: 1 updated: 2003/09/20 18:12:49
6557 dnl -------------------
6558 dnl Allow library's ABI to be overridden.  Generally this happens when a
6559 dnl packager has incremented the ABI past that used in the original package,
6560 dnl and wishes to keep doing this.
6561 dnl
6562 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
6563 dnl symbol.
6564 AC_DEFUN([CF_WITH_ABI_VERSION],[
6565 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
6566 AC_ARG_WITH(abi-version,
6567 [  --with-abi-version=XXX  override derived ABI version],
6568 [AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
6569  cf_cv_abi_version=$withval])
6570  CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
6571 ifelse($1,,,[
6572 $1_ABI=$cf_cv_abi_version
6573 ])
6574 ])dnl
6575 dnl ---------------------------------------------------------------------------
6576 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
6577 dnl --------------------
6578 dnl Command-line option to specify the Ada95 compiler.
6579 AC_DEFUN([CF_WITH_ADA_COMPILER],[
6580 AC_MSG_CHECKING(for ada-compiler)
6581 AC_ARG_WITH(ada-compiler,
6582         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
6583         [cf_ada_compiler=$withval],
6584         [cf_ada_compiler=gnatmake])
6585 AC_SUBST(cf_ada_compiler)
6586 AC_MSG_RESULT($cf_ada_compiler)
6587 ])dnl
6588 dnl ---------------------------------------------------------------------------
6589 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
6590 dnl -------------------
6591 dnl Command-line option to specify where Ada includes will install.
6592 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
6593 AC_MSG_CHECKING(for ada-include)
6594 CF_WITH_PATH(ada-include,
6595    [  --with-ada-include=DIR  Ada includes are in DIR],
6596    ADA_INCLUDE,
6597    PREFIX/share/ada/adainclude,
6598    [$]prefix/share/ada/adainclude)
6599 AC_SUBST(ADA_INCLUDE)
6600 AC_MSG_RESULT($ADA_INCLUDE)
6601 ])dnl
6602 dnl ---------------------------------------------------------------------------
6603 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
6604 dnl -------------------
6605 dnl Command-line option to specify where Ada objects will install.
6606 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
6607 AC_MSG_CHECKING(for ada-objects)
6608 CF_WITH_PATH(ada-objects,
6609    [  --with-ada-objects=DIR  Ada objects are in DIR],
6610    ADA_OBJECTS,
6611    PREFIX/lib/ada/adalib,
6612    [$]prefix/lib/ada/adalib)
6613 AC_SUBST(ADA_OBJECTS)
6614 AC_MSG_RESULT($ADA_OBJECTS)
6615 ])dnl
6616 dnl ---------------------------------------------------------------------------
6617 dnl CF_WITH_ADA_SHAREDLIB version: 2 updated: 2010/06/26 17:35:58
6618 dnl ---------------------
6619 dnl Command-line option to specify if an Ada95 shared-library should be built,
6620 dnl and optionally what its soname should be.
6621 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
6622 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
6623 AC_ARG_WITH(ada-sharedlib,
6624         [  --with-ada-sharedlib=XX build Ada95 shared-library],
6625         [with_ada_sharedlib=$withval],
6626         [with_ada_sharedlib=no])
6627 AC_MSG_RESULT($with_ada_sharedlib)
6628
6629 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
6630 MAKE_ADA_SHAREDLIB="#"
6631
6632 if test "x$with_ada_sharedlib" != xno
6633 then
6634         MAKE_ADA_SHAREDLIB=
6635         if test "x$with_ada_sharedlib" != xyes
6636         then
6637                 ADA_SHAREDLIB="$with_ada_sharedlib"
6638         fi
6639 fi
6640
6641 AC_SUBST(ADA_SHAREDLIB)
6642 AC_SUBST(MAKE_ADA_SHAREDLIB)
6643 ])dnl
6644 dnl ---------------------------------------------------------------------------
6645 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
6646 dnl ----------------
6647 dnl Configure-option for dbmalloc.  The optional parameter is used to override
6648 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6649 AC_DEFUN([CF_WITH_DBMALLOC],[
6650 CF_NO_LEAKS_OPTION(dbmalloc,
6651         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
6652         [USE_DBMALLOC])
6653
6654 if test "$with_dbmalloc" = yes ; then
6655         AC_CHECK_HEADER(dbmalloc.h,
6656                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
6657 fi
6658 ])dnl
6659 dnl ---------------------------------------------------------------------------
6660 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
6661 dnl ---------------
6662 dnl Configure-option for dmalloc.  The optional parameter is used to override
6663 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
6664 AC_DEFUN([CF_WITH_DMALLOC],[
6665 CF_NO_LEAKS_OPTION(dmalloc,
6666         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
6667         [USE_DMALLOC])
6668
6669 if test "$with_dmalloc" = yes ; then
6670         AC_CHECK_HEADER(dmalloc.h,
6671                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
6672 fi
6673 ])dnl
6674 dnl ---------------------------------------------------------------------------
6675 dnl CF_WITH_GPM version: 8 updated: 2012/10/06 17:56:13
6676 dnl -----------
6677 dnl
6678 dnl The option parameter (if neither yes/no) is assumed to be the name of
6679 dnl the gpm library, e.g., for dynamic loading.
6680 AC_DEFUN([CF_WITH_GPM],
6681 [
6682 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
6683 AC_ARG_WITH(gpm,
6684         [  --with-gpm              use Alessandro Rubini's GPM library],
6685         [with_gpm=$withval],
6686         [with_gpm=maybe])
6687 AC_MSG_RESULT($with_gpm)
6688
6689 if test "$with_gpm" != no ; then
6690         AC_CHECK_HEADER(gpm.h,[
6691                 AC_DEFINE(HAVE_GPM_H,1,[Define to 1 if we have gpm.h header])
6692                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
6693                         CF_VERBOSE(assuming we really have GPM library)
6694                         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
6695                 else
6696                         AC_CHECK_LIB(gpm,Gpm_Open,[:],[
6697                                 AC_MSG_ERROR(Cannot link with GPM library)
6698                 fi
6699                 with_gpm=yes
6700                 ])
6701         ],[
6702                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
6703                 with_gpm=no
6704         ])
6705 fi
6706 ])
6707 dnl ---------------------------------------------------------------------------
6708 dnl CF_WITH_LIBTOOL version: 30 updated: 2013/09/07 13:54:05
6709 dnl ---------------
6710 dnl Provide a configure option to incorporate libtool.  Define several useful
6711 dnl symbols for the makefile rules.
6712 dnl
6713 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
6714 dnl macros from libtool.m4 which is in the aclocal directory of automake.
6715 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
6716 dnl But that still does not work properly since the macro is expanded outside
6717 dnl the CF_WITH_LIBTOOL macro:
6718 dnl
6719 dnl     #!/bin/sh
6720 dnl     ACLOCAL=`aclocal --print-ac-dir`
6721 dnl     if test -z "$ACLOCAL" ; then
6722 dnl             echo cannot find aclocal directory
6723 dnl             exit 1
6724 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
6725 dnl             echo cannot find libtool.m4 file
6726 dnl             exit 1
6727 dnl     fi
6728 dnl
6729 dnl     LOCAL=aclocal.m4
6730 dnl     ORIG=aclocal.m4.orig
6731 dnl
6732 dnl     trap "mv $ORIG $LOCAL" 0 1 2 5 15
6733 dnl     rm -f $ORIG
6734 dnl     mv $LOCAL $ORIG
6735 dnl
6736 dnl     # sed the LIBTOOL= assignment to omit the current directory?
6737 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
6738 dnl     cat $ORIG >>$LOCAL
6739 dnl
6740 dnl     autoconf-257 $*
6741 dnl
6742 AC_DEFUN([CF_WITH_LIBTOOL],
6743 [
6744 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
6745 ifdef([AC_PROG_LIBTOOL],,[
6746 LIBTOOL=
6747 ])
6748 # common library maintenance symbols that are convenient for libtool scripts:
6749 LIB_CREATE='${AR} -cr'
6750 LIB_OBJECT='${OBJECTS}'
6751 LIB_SUFFIX=.a
6752 LIB_PREP="$RANLIB"
6753
6754 # symbols used to prop libtool up to enable it to determine what it should be
6755 # doing:
6756 LIB_CLEAN=
6757 LIB_COMPILE=
6758 LIB_LINK='${CC}'
6759 LIB_INSTALL=
6760 LIB_UNINSTALL=
6761
6762 AC_MSG_CHECKING(if you want to build libraries with libtool)
6763 AC_ARG_WITH(libtool,
6764         [  --with-libtool          generate libraries with libtool],
6765         [with_libtool=$withval],
6766         [with_libtool=no])
6767 AC_MSG_RESULT($with_libtool)
6768 if test "$with_libtool" != "no"; then
6769 ifdef([AC_PROG_LIBTOOL],[
6770         # missing_content_AC_PROG_LIBTOOL{{
6771         AC_PROG_LIBTOOL
6772         # missing_content_AC_PROG_LIBTOOL}}
6773 ],[
6774         if test "$with_libtool" != "yes" ; then
6775                 CF_PATH_SYNTAX(with_libtool)
6776                 LIBTOOL=$with_libtool
6777         else
6778                 AC_CHECK_TOOLS(LIBTOOL,[libtool glibtool],none)
6779                 CF_LIBTOOL_VERSION
6780                 if test -z "$cf_cv_libtool_version" && test "$LIBTOOL" = libtool
6781                 then
6782                         CF_FORGET_TOOL(LIBTOOL)
6783                         AC_CHECK_TOOLS(LIBTOOL,[glibtool],none)
6784                         CF_LIBTOOL_VERSION
6785                 fi
6786         fi
6787         if test -z "$LIBTOOL" ; then
6788                 AC_MSG_ERROR(Cannot find libtool)
6789         fi
6790 ])dnl
6791         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${DESTDIR}${libdir} ${LIBTOOL_VERSION} `cut -f1 ${srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
6792         LIB_OBJECT='${OBJECTS:.o=.lo}'
6793         LIB_SUFFIX=.la
6794         LIB_CLEAN='${LIBTOOL} --mode=clean'
6795         LIB_COMPILE='${LIBTOOL} --mode=compile'
6796         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
6797         LIB_INSTALL='${LIBTOOL} --mode=install'
6798         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
6799         LIB_PREP=:
6800
6801         CF_CHECK_LIBTOOL_VERSION
6802
6803         # special hack to add -no-undefined (which libtool should do for itself)
6804         LT_UNDEF=
6805         case "$cf_cv_system_name" in #(vi
6806         cygwin*|msys*|mingw32*|uwin*|aix[[4-7]]) #(vi
6807                 LT_UNDEF=-no-undefined
6808                 ;;
6809         esac
6810         AC_SUBST([LT_UNDEF])
6811
6812         # special hack to add --tag option for C++ compiler
6813         case $cf_cv_libtool_version in #(vi
6814         1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*) #(vi
6815                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
6816                 LIBTOOL="$LIBTOOL --tag=CC"
6817                 ;;
6818         *)
6819                 LIBTOOL_CXX="$LIBTOOL"
6820                 ;;
6821         esac
6822 else
6823         LIBTOOL=""
6824         LIBTOOL_CXX=""
6825 fi
6826
6827 test -z "$LIBTOOL" && ECHO_LT=
6828
6829 AC_SUBST(LIBTOOL)
6830 AC_SUBST(LIBTOOL_CXX)
6831 AC_SUBST(LIBTOOL_OPTS)
6832
6833 AC_SUBST(LIB_CREATE)
6834 AC_SUBST(LIB_OBJECT)
6835 AC_SUBST(LIB_SUFFIX)
6836 AC_SUBST(LIB_PREP)
6837
6838 AC_SUBST(LIB_CLEAN)
6839 AC_SUBST(LIB_COMPILE)
6840 AC_SUBST(LIB_LINK)
6841 AC_SUBST(LIB_INSTALL)
6842 AC_SUBST(LIB_UNINSTALL)
6843
6844 ])dnl
6845 dnl ---------------------------------------------------------------------------
6846 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
6847 dnl ------------------
6848 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
6849 dnl "lib" prefix, e.g., because it used the dll naming convention.
6850 dnl
6851 dnl $1 = variable to set
6852 AC_DEFUN([CF_WITH_LIB_PREFIX],
6853 [
6854 AC_MSG_CHECKING(if you want to have a library-prefix)
6855 AC_ARG_WITH(lib-prefix,
6856         [  --with-lib-prefix       override library-prefix],
6857         [with_lib_prefix=$withval],
6858         [with_lib_prefix=auto])
6859 AC_MSG_RESULT($with_lib_prefix)
6860
6861 if test $with_lib_prefix = auto
6862 then
6863         CF_LIB_PREFIX($1)
6864 elif test $with_lib_prefix = no
6865 then
6866         LIB_PREFIX=
6867 else
6868         LIB_PREFIX=$with_lib_prefix
6869 fi
6870 ])dnl
6871 dnl ---------------------------------------------------------------------------
6872 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
6873 dnl ------------
6874 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
6875 dnl defaulting to yes/no.
6876 dnl
6877 dnl $1 = option name
6878 dnl $2 = help-text
6879 dnl $3 = environment variable to set
6880 dnl $4 = default value, shown in the help-message, must be a constant
6881 dnl $5 = default value, if it's an expression & cannot be in the help-message
6882 dnl
6883 AC_DEFUN([CF_WITH_PATH],
6884 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
6885 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
6886 if ifelse([$5],,true,[test -n "$5"]) ; then
6887 CF_PATH_SYNTAX(withval)
6888 fi
6889 eval $3="$withval"
6890 AC_SUBST($3)dnl
6891 ])dnl
6892 dnl ---------------------------------------------------------------------------
6893 dnl CF_WITH_PATHLIST version: 9 updated: 2012/10/18 05:05:24
6894 dnl ----------------
6895 dnl Process an option specifying a list of colon-separated paths.
6896 dnl
6897 dnl $1 = option name
6898 dnl $2 = help-text
6899 dnl $3 = environment variable to set
6900 dnl $4 = default value, shown in the help-message, must be a constant
6901 dnl $5 = default value, if it's an expression & cannot be in the help-message
6902 dnl $6 = flag to tell if we want to define or substitute
6903 dnl
6904 AC_DEFUN([CF_WITH_PATHLIST],[
6905 AC_REQUIRE([CF_PATHSEP])
6906 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
6907 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
6908
6909 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
6910 cf_dst_path=
6911 for cf_src_path in $withval
6912 do
6913   CF_PATH_SYNTAX(cf_src_path)
6914   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}$PATH_SEPARATOR"
6915   cf_dst_path="${cf_dst_path}${cf_src_path}"
6916 done
6917 IFS="$ac_save_ifs"
6918
6919 ifelse($6,define,[
6920 # Strip single quotes from the value, e.g., when it was supplied as a literal
6921 # for $4 or $5.
6922 case $cf_dst_path in #(vi
6923 \'*)
6924   cf_dst_path=`echo $cf_dst_path |sed -e s/\'// -e s/\'\$//`
6925   ;;
6926 esac
6927 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
6928 ])
6929
6930 # This may use the prefix/exec_prefix symbols which will only yield "NONE"
6931 # so we have to check/work around.  We do prefer the result of "eval"...
6932 eval cf_dst_eval="$cf_dst_path"
6933 case "x$cf_dst_eval" in #(vi
6934 xNONE*) #(vi
6935         $3=$cf_dst_path
6936         ;;
6937 *)
6938         $3="$cf_dst_eval"
6939         ;;
6940 esac
6941 AC_SUBST($3)dnl
6942
6943 ])dnl
6944 dnl ---------------------------------------------------------------------------
6945 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 2 updated: 2011/12/10 18:58:47
6946 dnl -------------------------
6947 dnl Allow the choice of the pkg-config library directory to be overridden.
6948 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
6949 if test "$PKG_CONFIG" != none ; then
6950         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
6951         AC_ARG_WITH(pkg-config-libdir,
6952                 [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
6953                 [PKG_CONFIG_LIBDIR=$withval],
6954                 [PKG_CONFIG_LIBDIR=yes])
6955
6956         case x$PKG_CONFIG_LIBDIR in #(vi
6957         x/*) #(vi
6958                 ;;
6959         xyes) #(vi
6960                 # look for the library directory using the same prefix as the executable
6961                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
6962                 case x`(arch) 2>/dev/null` in #(vi
6963                 *64) #(vi
6964                         for cf_config in $cf_path/share $cf_path/lib64 $cf_path/lib32 $cf_path/lib
6965                         do
6966                                 if test -d $cf_config/pkgconfig
6967                                 then
6968                                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
6969                                         break
6970                                 fi
6971                         done
6972                         ;;
6973                 *)
6974                         PKG_CONFIG_LIBDIR=$cf_path/lib/pkgconfig
6975                         ;;
6976                 esac
6977                 ;;
6978         *)
6979                 ;;
6980         esac
6981
6982         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
6983 fi
6984
6985 AC_SUBST(PKG_CONFIG_LIBDIR)
6986 ])dnl
6987 dnl ---------------------------------------------------------------------------
6988 dnl CF_WITH_PTHREAD version: 6 updated: 2012/10/06 17:41:51
6989 dnl ---------------
6990 dnl Check for POSIX thread library.
6991 AC_DEFUN([CF_WITH_PTHREAD],
6992 [
6993 AC_MSG_CHECKING(if you want to link with the pthread library)
6994 AC_ARG_WITH(pthread,
6995     [  --with-pthread          use POSIX thread library],
6996     [with_pthread=$withval],
6997     [with_pthread=no])
6998 AC_MSG_RESULT($with_pthread)
6999
7000 if test "$with_pthread" != no ; then
7001     AC_CHECK_HEADER(pthread.h,[
7002         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
7003
7004         for cf_lib_pthread in pthread c_r
7005         do
7006             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
7007             cf_save_LIBS="$LIBS"
7008             CF_ADD_LIB($cf_lib_pthread)
7009             AC_TRY_LINK([
7010 #include <pthread.h>
7011 ],[
7012                 int rc = pthread_create(0,0,0,0);
7013                 int r2 = pthread_mutexattr_settype(0, 0);
7014 ],[with_pthread=yes],[with_pthread=no])
7015             LIBS="$cf_save_LIBS"
7016             AC_MSG_RESULT($with_pthread)
7017             test "$with_pthread" = yes && break
7018         done
7019
7020         if test "$with_pthread" = yes ; then
7021             CF_ADD_LIB($cf_lib_pthread)
7022             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
7023         else
7024             AC_MSG_ERROR(Cannot link with pthread library)
7025         fi
7026     ])
7027 fi
7028 ])
7029 dnl ---------------------------------------------------------------------------
7030 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
7031 dnl -------------------
7032 dnl Allow library's release-version to be overridden.  Generally this happens when a
7033 dnl packager has incremented the release-version past that used in the original package,
7034 dnl and wishes to keep doing this.
7035 dnl
7036 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
7037 dnl and {package}_MINOR symbols
7038 dnl symbol.
7039 AC_DEFUN([CF_WITH_REL_VERSION],[
7040 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
7041 AC_ARG_WITH(rel-version,
7042 [  --with-rel-version=XXX  override derived release version],
7043 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
7044  cf_cv_rel_version=$withval])
7045 ifelse($1,,[
7046  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
7047 ],[
7048  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
7049  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
7050  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
7051  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
7052 ])
7053 ])dnl
7054 dnl ---------------------------------------------------------------------------
7055 dnl CF_WITH_SYSMOUSE version: 3 updated: 2012/10/06 17:56:13
7056 dnl ----------------
7057 dnl If we can compile with sysmouse, make it available unless it is not wanted.
7058 AC_DEFUN([CF_WITH_SYSMOUSE],[
7059 # not everyone has "test -c"
7060 if test -c /dev/sysmouse 2>/dev/null ; then
7061 AC_MSG_CHECKING(if you want to use sysmouse)
7062 AC_ARG_WITH(sysmouse,
7063         [  --with-sysmouse         use sysmouse (FreeBSD console)],
7064         [cf_with_sysmouse=$withval],
7065         [cf_with_sysmouse=maybe])
7066         if test "$cf_with_sysmouse" != no ; then
7067         AC_TRY_COMPILE([
7068 #include <osreldate.h>
7069 #if (__FreeBSD_version >= 400017)
7070 #include <sys/consio.h>
7071 #include <sys/fbio.h>
7072 #else
7073 #include <machine/console.h>
7074 #endif
7075 ],[
7076         struct mouse_info the_mouse;
7077         ioctl(0, CONS_MOUSECTL, &the_mouse);
7078 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
7079         fi
7080 AC_MSG_RESULT($cf_with_sysmouse)
7081 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE,1,[Define to 1 if we can/should use the sysmouse interface])
7082 fi
7083 ])dnl
7084 dnl ---------------------------------------------------------------------------
7085 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
7086 dnl ---------------
7087 dnl For testing, override the derived host system-type which is used to decide
7088 dnl things such as the linker commands used to build shared libraries.  This is
7089 dnl normally chosen automatically based on the type of system which you are
7090 dnl building on.  We use it for testing the configure script.
7091 dnl
7092 dnl This is different from the --host option: it is used only for testing parts
7093 dnl of the configure script which would not be reachable with --host since that
7094 dnl relies on the build environment being real, rather than mocked up.
7095 AC_DEFUN([CF_WITH_SYSTYPE],[
7096 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
7097 AC_ARG_WITH(system-type,
7098         [  --with-system-type=XXX  test: override derived host system-type],
7099 [AC_MSG_WARN(overriding system type to $withval)
7100         cf_cv_system_name=$withval
7101         host_os=$withval
7102 ])
7103 ])dnl
7104 dnl ---------------------------------------------------------------------------
7105 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
7106 dnl ----------------
7107 AC_DEFUN([CF_WITH_VALGRIND],[
7108 CF_NO_LEAKS_OPTION(valgrind,
7109         [  --with-valgrind         test: use valgrind],
7110         [USE_VALGRIND])
7111 ])dnl
7112 dnl ---------------------------------------------------------------------------
7113 dnl CF_XOPEN_SOURCE version: 45 updated: 2013/09/07 14:06:25
7114 dnl ---------------
7115 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
7116 dnl or adapt to the vendor's definitions to get equivalent functionality,
7117 dnl without losing the common non-POSIX features.
7118 dnl
7119 dnl Parameters:
7120 dnl     $1 is the nominal value for _XOPEN_SOURCE
7121 dnl     $2 is the nominal value for _POSIX_C_SOURCE
7122 AC_DEFUN([CF_XOPEN_SOURCE],[
7123 AC_REQUIRE([AC_CANONICAL_HOST])
7124
7125 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
7126 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
7127 cf_xopen_source=
7128
7129 case $host_os in #(vi
7130 aix[[4-7]]*) #(vi
7131         cf_xopen_source="-D_ALL_SOURCE"
7132         ;;
7133 cygwin|msys) #(vi
7134         cf_XOPEN_SOURCE=600
7135         ;;
7136 darwin[[0-8]].*) #(vi
7137         cf_xopen_source="-D_APPLE_C_SOURCE"
7138         ;;
7139 darwin*) #(vi
7140         cf_xopen_source="-D_DARWIN_C_SOURCE"
7141         cf_XOPEN_SOURCE=
7142         ;;
7143 freebsd*|dragonfly*) #(vi
7144         # 5.x headers associate
7145         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
7146         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
7147         cf_POSIX_C_SOURCE=200112L
7148         cf_XOPEN_SOURCE=600
7149         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
7150         ;;
7151 hpux11*) #(vi
7152         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
7153         ;;
7154 hpux*) #(vi
7155         cf_xopen_source="-D_HPUX_SOURCE"
7156         ;;
7157 irix[[56]].*) #(vi
7158         cf_xopen_source="-D_SGI_SOURCE"
7159         cf_XOPEN_SOURCE=
7160         ;;
7161 linux*|gnu*|mint*|k*bsd*-gnu) #(vi
7162         CF_GNU_SOURCE
7163         ;;
7164 mirbsd*) #(vi
7165         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
7166         cf_XOPEN_SOURCE=
7167         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
7168         ;;
7169 netbsd*) #(vi
7170         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
7171         ;;
7172 openbsd[[4-9]]*) #(vi
7173         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
7174         cf_xopen_source="-D_BSD_SOURCE"
7175         cf_XOPEN_SOURCE=600
7176         ;;
7177 openbsd*) #(vi
7178         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
7179         ;;
7180 osf[[45]]*) #(vi
7181         cf_xopen_source="-D_OSF_SOURCE"
7182         ;;
7183 nto-qnx*) #(vi
7184         cf_xopen_source="-D_QNX_SOURCE"
7185         ;;
7186 sco*) #(vi
7187         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
7188         ;;
7189 solaris2.*) #(vi
7190         cf_xopen_source="-D__EXTENSIONS__"
7191         ;;
7192 *)
7193         CF_TRY_XOPEN_SOURCE
7194         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
7195         ;;
7196 esac
7197
7198 if test -n "$cf_xopen_source" ; then
7199         CF_ADD_CFLAGS($cf_xopen_source)
7200 fi
7201
7202 dnl In anything but the default case, we may have system-specific setting
7203 dnl which is still not guaranteed to provide all of the entrypoints that
7204 dnl _XOPEN_SOURCE would yield.
7205 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
7206         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
7207         AC_TRY_COMPILE([#include <stdlib.h>],[
7208 #ifndef _XOPEN_SOURCE
7209 make an error
7210 #endif],
7211         [cf_XOPEN_SOURCE_set=yes],
7212         [cf_XOPEN_SOURCE_set=no])
7213         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
7214         if test $cf_XOPEN_SOURCE_set = yes
7215         then
7216                 AC_TRY_COMPILE([#include <stdlib.h>],[
7217 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
7218 make an error
7219 #endif],
7220                 [cf_XOPEN_SOURCE_set_ok=yes],
7221                 [cf_XOPEN_SOURCE_set_ok=no])
7222                 if test $cf_XOPEN_SOURCE_set_ok = no
7223                 then
7224                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
7225                 fi
7226         else
7227                 CF_TRY_XOPEN_SOURCE
7228         fi
7229 fi
7230 ])