6913e9d2c650738f0a56ca4d4cbf22bf3ffc2346
[ncurses.git] / aclocal.m4
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2018,2019 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1995-on
30 dnl
31 dnl $Id: aclocal.m4,v 1.880 2019/09/07 23:00:39 tom Exp $
32 dnl Macros used in NCURSES auto-configuration script.
33 dnl
34 dnl These macros are maintained separately from NCURSES.  The copyright on
35 dnl this file applies to the aggregation of macros and does not affect use of
36 dnl these macros in other applications.
37 dnl
38 dnl See https://invisible-island.net/autoconf/ for additional information.
39 dnl
40 dnl ---------------------------------------------------------------------------
41 dnl ---------------------------------------------------------------------------
42 dnl AM_LANGINFO_CODESET version: 4 updated: 2015/04/18 08:56:57
43 dnl -------------------
44 dnl Inserted as requested by gettext 0.10.40
45 dnl File from /usr/share/aclocal
46 dnl codeset.m4
47 dnl ====================
48 dnl serial AM1
49 dnl
50 dnl From Bruno Haible.
51 AC_DEFUN([AM_LANGINFO_CODESET],
52 [
53 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
54         [AC_TRY_LINK([#include <langinfo.h>],
55         [char* cs = nl_langinfo(CODESET);],
56         am_cv_langinfo_codeset=yes,
57         am_cv_langinfo_codeset=no)
58         ])
59         if test $am_cv_langinfo_codeset = yes; then
60                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
61                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
62         fi
63 ])dnl
64 dnl ---------------------------------------------------------------------------
65 dnl CF_ABI_DEFAULTS version: 2 updated: 2015/06/06 13:49:58
66 dnl ---------------
67 dnl Provide configure-script defaults for different ncurses ABIs.
68 AC_DEFUN([CF_ABI_DEFAULTS],[
69 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
70 case x$cf_cv_abi_version in
71 (x[[6789]])
72         cf_dft_ext_colors=yes
73         cf_dft_ext_const=yes
74         cf_dft_ext_mouse=yes
75         cf_dft_ext_putwin=yes
76         cf_dft_ext_spfuncs=yes
77         cf_dft_filter_syms=yes
78         cf_dft_chtype=uint32_t
79         cf_dft_mmask_t=uint32_t
80         cf_dft_interop=yes
81         cf_dft_tparm_arg=intptr_t
82         cf_dft_with_lp64=yes
83         ;;
84 (*)
85         cf_dft_ext_colors=no
86         cf_dft_ext_const=no
87         cf_dft_ext_mouse=no
88         cf_dft_ext_putwin=no
89         cf_dft_ext_spfuncs=no
90         cf_dft_filter_syms=no
91         cf_dft_chtype=auto
92         cf_dft_mmask_t=auto
93         cf_dft_interop=no
94         cf_dft_tparm_arg=long
95         cf_dft_with_lp64=no
96         ;;
97 esac
98 ])dnl
99 dnl ---------------------------------------------------------------------------
100 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
101 dnl ------------------
102 dnl Conditionally generate script according to whether we're using a given autoconf.
103 dnl
104 dnl $1 = version to compare against
105 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
106 dnl $3 = code to use if AC_ACVERSION is older than $1.
107 define([CF_ACVERSION_CHECK],
108 [
109 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
110 ifdef([m4_version_compare],
111 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
112 [CF_ACVERSION_COMPARE(
113 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
114 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
115 dnl ---------------------------------------------------------------------------
116 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
117 dnl --------------------
118 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
119 dnl                      MAJOR2, MINOR2, TERNARY2,
120 dnl                      PRINTABLE2, not FOUND, FOUND)
121 define([CF_ACVERSION_COMPARE],
122 [ifelse(builtin([eval], [$2 < $5]), 1,
123 [ifelse([$8], , ,[$8])],
124 [ifelse([$9], , ,[$9])])])dnl
125 dnl ---------------------------------------------------------------------------
126 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
127 dnl -------------------
128 dnl Construct the list of include-options for the C programs in the Ada95
129 dnl binding.
130 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
131 [
132 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
133 if test "$srcdir" != "."; then
134         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
135 fi
136 if test "$GCC" != yes; then
137         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
138 elif test "$includedir" != "/usr/include"; then
139         if test "$includedir" = '${prefix}/include' ; then
140                 if test x$prefix != x/usr ; then
141                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
142                 fi
143         else
144                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
145         fi
146 fi
147 AC_SUBST(ACPPFLAGS)
148 ])dnl
149 dnl ---------------------------------------------------------------------------
150 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
151 dnl ---------------
152 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
153 AC_DEFUN([CF_ADD_ADAFLAGS],[
154         ADAFLAGS="$ADAFLAGS $1"
155         AC_SUBST(ADAFLAGS)
156 ])dnl
157 dnl ---------------------------------------------------------------------------
158 dnl CF_ADD_CFLAGS version: 13 updated: 2017/02/25 18:57:40
159 dnl -------------
160 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
161 dnl The second parameter if given makes this macro verbose.
162 dnl
163 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
164 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
165 dnl confused by the quotes (which require backslashes to keep them usable).
166 AC_DEFUN([CF_ADD_CFLAGS],
167 [
168 cf_fix_cppflags=no
169 cf_new_cflags=
170 cf_new_cppflags=
171 cf_new_extra_cppflags=
172
173 for cf_add_cflags in $1
174 do
175 case $cf_fix_cppflags in
176 (no)
177         case $cf_add_cflags in
178         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
179                 case $cf_add_cflags in
180                 (-D*)
181                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
182
183                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
184                                 && test -z "${cf_tst_cflags}" \
185                                 && cf_fix_cppflags=yes
186
187                         if test $cf_fix_cppflags = yes ; then
188                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
189                                 continue
190                         elif test "${cf_tst_cflags}" = "\"'" ; then
191                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
192                                 continue
193                         fi
194                         ;;
195                 esac
196                 case "$CPPFLAGS" in
197                 (*$cf_add_cflags)
198                         ;;
199                 (*)
200                         case $cf_add_cflags in
201                         (-D*)
202                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
203                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
204                                 ;;
205                         esac
206                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
207                         ;;
208                 esac
209                 ;;
210         (*)
211                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
212                 ;;
213         esac
214         ;;
215 (yes)
216         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
217
218         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
219
220         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
221                 && test -z "${cf_tst_cflags}" \
222                 && cf_fix_cppflags=no
223         ;;
224 esac
225 done
226
227 if test -n "$cf_new_cflags" ; then
228         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
229         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
230 fi
231
232 if test -n "$cf_new_cppflags" ; then
233         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
234         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
235 fi
236
237 if test -n "$cf_new_extra_cppflags" ; then
238         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
239         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
240 fi
241
242 AC_SUBST(EXTRA_CPPFLAGS)
243
244 ])dnl
245 dnl ---------------------------------------------------------------------------
246 dnl CF_ADD_INCDIR version: 15 updated: 2018/06/20 20:23:13
247 dnl -------------
248 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
249 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
250 dnl but old versions (and some misinstalled ones) need that.  To make things
251 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
252 dnl the include-path).
253 AC_DEFUN([CF_ADD_INCDIR],
254 [
255 if test -n "$1" ; then
256   for cf_add_incdir in $1
257   do
258         while test $cf_add_incdir != /usr/include
259         do
260           if test -d $cf_add_incdir
261           then
262                 cf_have_incdir=no
263                 if test -n "$CFLAGS$CPPFLAGS" ; then
264                   # a loop is needed to ensure we can add subdirs of existing dirs
265                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
266                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
267                           cf_have_incdir=yes; break
268                         fi
269                   done
270                 fi
271
272                 if test "$cf_have_incdir" = no ; then
273                   if test "$cf_add_incdir" = /usr/local/include ; then
274                         if test "$GCC" = yes
275                         then
276                           cf_save_CPPFLAGS=$CPPFLAGS
277                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
278                           AC_TRY_COMPILE([#include <stdio.h>],
279                                   [printf("Hello")],
280                                   [],
281                                   [cf_have_incdir=yes])
282                           CPPFLAGS=$cf_save_CPPFLAGS
283                         fi
284                   fi
285                 fi
286
287                 if test "$cf_have_incdir" = no ; then
288                   CF_VERBOSE(adding $cf_add_incdir to include-path)
289                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
290
291                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
292                   test "$cf_top_incdir" = "$cf_add_incdir" && break
293                   cf_add_incdir="$cf_top_incdir"
294                 else
295                   break
296                 fi
297           else
298                 break
299           fi
300         done
301   done
302 fi
303 ])dnl
304 dnl ---------------------------------------------------------------------------
305 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
306 dnl ----------
307 dnl Add a library, used to enforce consistency.
308 dnl
309 dnl $1 = library to add, without the "-l"
310 dnl $2 = variable to update (default $LIBS)
311 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
312 dnl ---------------------------------------------------------------------------
313 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
314 dnl -------------
315 dnl     Adds to the library-path
316 dnl
317 dnl     Some machines have trouble with multiple -L options.
318 dnl
319 dnl $1 is the (list of) directory(s) to add
320 dnl $2 is the optional name of the variable to update (default LDFLAGS)
321 dnl
322 AC_DEFUN([CF_ADD_LIBDIR],
323 [
324 if test -n "$1" ; then
325         for cf_add_libdir in $1
326         do
327                 if test $cf_add_libdir = /usr/lib ; then
328                         :
329                 elif test -d $cf_add_libdir
330                 then
331                         cf_have_libdir=no
332                         if test -n "$LDFLAGS$LIBS" ; then
333                                 # a loop is needed to ensure we can add subdirs of existing dirs
334                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
335                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
336                                                 cf_have_libdir=yes; break
337                                         fi
338                                 done
339                         fi
340                         if test "$cf_have_libdir" = no ; then
341                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
342                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
343                         fi
344                 fi
345         done
346 fi
347 ])dnl
348 dnl ---------------------------------------------------------------------------
349 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
350 dnl -----------
351 dnl Add one or more libraries, used to enforce consistency.  Libraries are
352 dnl prepended to an existing list, since their dependencies are assumed to
353 dnl already exist in the list.
354 dnl
355 dnl $1 = libraries to add, with the "-l", etc.
356 dnl $2 = variable to update (default $LIBS)
357 AC_DEFUN([CF_ADD_LIBS],[
358 cf_add_libs="$1"
359 # Filter out duplicates - this happens with badly-designed ".pc" files...
360 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
361 do
362         for cf_add_2lib in $cf_add_libs
363         do
364                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
365                 then
366                         cf_add_1lib=
367                         break
368                 fi
369         done
370         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
371 done
372 ifelse($2,,LIBS,[$2])="$cf_add_libs"
373 ])dnl
374 dnl ---------------------------------------------------------------------------
375 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
376 dnl ------------------
377 dnl Append to a search-list for a nonstandard header/lib-file
378 dnl     $1 = the variable to return as result
379 dnl     $2 = the package name
380 dnl     $3 = the subdirectory, e.g., bin, include or lib
381 dnl $4 = the directory under which we will test for subdirectories
382 dnl $5 = a directory that we do not want $4 to match
383 AC_DEFUN([CF_ADD_SUBDIR_PATH],
384 [
385 test "x$4" != "x$5" && \
386 test -d "$4" && \
387 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
388         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
389         test -d $4/$3 &&          $1="[$]$1 $4/$3"
390         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
391         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
392         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
393         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
394 }
395 ])dnl
396 dnl ---------------------------------------------------------------------------
397 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
398 dnl --------------
399 dnl use this macro for appending text without introducing an extra blank at
400 dnl the beginning
401 define([CF_APPEND_TEXT],
402 [
403         test -n "[$]$1" && $1="[$]$1 "
404         $1="[$]{$1}$2"
405 ])dnl
406 dnl ---------------------------------------------------------------------------
407 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
408 dnl --------------
409 dnl Allow user to disable a normally-on option.
410 AC_DEFUN([CF_ARG_DISABLE],
411 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
412 dnl ---------------------------------------------------------------------------
413 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
414 dnl -------------
415 dnl Allow user to enable a normally-off option.
416 AC_DEFUN([CF_ARG_ENABLE],
417 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
418 dnl ---------------------------------------------------------------------------
419 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
420 dnl -------------
421 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
422 dnl values.
423 dnl
424 dnl Parameters:
425 dnl $1 = option name
426 dnl $2 = help-string
427 dnl $3 = action to perform if option is not default
428 dnl $4 = action if perform if option is default
429 dnl $5 = default option value (either 'yes' or 'no')
430 AC_DEFUN([CF_ARG_OPTION],
431 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
432         if test "$enableval" != "$5" ; then
433 ifelse([$3],,[    :]dnl
434 ,[    $3]) ifelse([$4],,,[
435         else
436                 $4])
437         fi],[enableval=$5 ifelse([$4],,,[
438         $4
439 ])dnl
440 ])])dnl
441 dnl ---------------------------------------------------------------------------
442 dnl CF_AR_FLAGS version: 6 updated: 2015/10/10 15:25:05
443 dnl -----------
444 dnl Check for suitable "ar" (archiver) options for updating an archive.
445 dnl
446 dnl In particular, handle some obsolete cases where the "-" might be omitted,
447 dnl as well as a workaround for breakage of make's archive rules by the GNU
448 dnl binutils "ar" program.
449 AC_DEFUN([CF_AR_FLAGS],[
450 AC_REQUIRE([CF_PROG_AR])
451
452 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
453         cf_cv_ar_flags=unknown
454         for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
455         do
456
457                 # check if $ARFLAGS already contains this choice
458                 if test "x$ARFLAGS" != "x" ; then
459                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
460                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
461                                 cf_cv_ar_flags=
462                                 break
463                         fi
464                 fi
465
466                 rm -f conftest.$ac_cv_objext
467                 rm -f conftest.a
468
469                 cat >conftest.$ac_ext <<EOF
470 #line __oline__ "configure"
471 int     testdata[[3]] = { 123, 456, 789 };
472 EOF
473                 if AC_TRY_EVAL(ac_compile) ; then
474                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
475                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
476                         if test -f conftest.a ; then
477                                 cf_cv_ar_flags=$cf_ar_flags
478                                 break
479                         fi
480                 else
481                         CF_VERBOSE(cannot compile test-program)
482                         break
483                 fi
484         done
485         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
486 ])
487
488 if test -n "$ARFLAGS" ; then
489         if test -n "$cf_cv_ar_flags" ; then
490                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
491         fi
492 else
493         ARFLAGS=$cf_cv_ar_flags
494 fi
495
496 AC_SUBST(ARFLAGS)
497 ])
498 dnl ---------------------------------------------------------------------------
499 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
500 dnl -----------------
501 dnl Check if awk can handle big strings using printf.  Some older versions of
502 dnl awk choke on large strings passed via "%s".
503 dnl
504 dnl $1 = desired string size
505 dnl $2 = variable to set with result
506 AC_DEFUN([CF_AWK_BIG_PRINTF],
507 [
508         case x$AWK in
509         (x)
510                 eval $2=no
511                 ;;
512         (*)
513                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
514                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
515                         eval $2=yes
516                 else
517                         eval $2=no
518                 fi
519                 ;;
520         esac
521 ])dnl
522 dnl ---------------------------------------------------------------------------
523 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
524 dnl ------------
525 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
526 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
527 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
528 dnl
529 dnl Treat the configuration-variable specially here, since we're directly
530 dnl substituting its value (i.e., 1/0).
531 dnl
532 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
533 AC_DEFUN([CF_BOOL_DECL],
534 [
535 AC_MSG_CHECKING(if we should include stdbool.h)
536
537 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
538         AC_TRY_COMPILE([],[bool foo = false],
539                 [cf_cv_header_stdbool_h=0],
540                 [AC_TRY_COMPILE([
541 #ifndef __BEOS__
542 #include <stdbool.h>
543 #endif
544 ],[bool foo = false],
545                         [cf_cv_header_stdbool_h=1],
546                         [cf_cv_header_stdbool_h=0])])])
547
548 if test "$cf_cv_header_stdbool_h" = 1
549 then    AC_MSG_RESULT(yes)
550 else    AC_MSG_RESULT(no)
551 fi
552
553 AC_MSG_CHECKING([for builtin bool type])
554
555 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
556         AC_TRY_COMPILE([
557 #include <stdio.h>
558 #include <sys/types.h>
559 ],[bool x = false],
560                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
561                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
562         ])
563
564 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
565 then    AC_MSG_RESULT(yes)
566 else    AC_MSG_RESULT(no)
567 fi
568 ])dnl
569 dnl ---------------------------------------------------------------------------
570 dnl CF_BOOL_SIZE version: 15 updated: 2017/01/21 11:06:25
571 dnl ------------
572 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
573 dnl Don't bother looking for bool.h, since it's been deprecated.
574 dnl
575 dnl If the current compiler is C rather than C++, we get the bool definition
576 dnl from <stdbool.h>.
577 AC_DEFUN([CF_BOOL_SIZE],
578 [
579 AC_MSG_CHECKING([for size of bool])
580 AC_CACHE_VAL(cf_cv_type_of_bool,[
581         rm -f cf_test.out
582         AC_TRY_RUN([
583 #include <stdlib.h>
584 #include <stdio.h>
585
586 #if defined(__cplusplus)
587
588 #ifdef HAVE_GXX_BUILTIN_H
589 #include <g++/builtin.h>
590 #elif HAVE_GPP_BUILTIN_H
591 #include <gpp/builtin.h>
592 #elif HAVE_BUILTIN_H
593 #include <builtin.h>
594 #endif
595
596 #else
597
598 #if $cf_cv_header_stdbool_h
599 #include <stdbool.h>
600 #endif
601
602 #endif
603
604 int main(void)
605 {
606         FILE *fp = fopen("cf_test.out", "w");
607         if (fp != 0) {
608                 bool x = true;
609                 if ((bool)(-x) >= 0)
610                         fputs("unsigned ", fp);
611                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
612                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
613                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
614                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
615                 fclose(fp);
616         }
617         ${cf_cv_main_return:-return}(0);
618 }
619                 ],
620                 [cf_cv_type_of_bool=`cat cf_test.out`
621                  if test -z "$cf_cv_type_of_bool"; then
622                    cf_cv_type_of_bool=unknown
623                  fi],
624                 [cf_cv_type_of_bool=unknown],
625                 [cf_cv_type_of_bool=unknown])
626         ])
627         rm -f cf_test.out
628 AC_MSG_RESULT($cf_cv_type_of_bool)
629 if test "$cf_cv_type_of_bool" = unknown ; then
630         case .$NCURSES_BOOL in
631         (.auto|.) NCURSES_BOOL=unsigned;;
632         esac
633         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
634         cf_cv_type_of_bool=$NCURSES_BOOL
635 fi
636 ])dnl
637 dnl ---------------------------------------------------------------------------
638 dnl CF_BUILD_CC version: 8 updated: 2018/01/04 20:31:04
639 dnl -----------
640 dnl If we're cross-compiling, allow the user to override the tools and their
641 dnl options.  The configure script is oriented toward identifying the host
642 dnl compiler, etc., but we need a build compiler to generate parts of the
643 dnl source.
644 dnl
645 dnl $1 = default for $CPPFLAGS
646 dnl $2 = default for $LIBS
647 AC_DEFUN([CF_BUILD_CC],[
648 CF_ACVERSION_CHECK(2.52,,
649         [AC_REQUIRE([CF_PROG_EXT])])
650 if test "$cross_compiling" = yes ; then
651
652         # defaults that we might want to override
653         : ${BUILD_CFLAGS:=''}
654         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
655         : ${BUILD_LDFLAGS:=''}
656         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
657         : ${BUILD_EXEEXT:='$x'}
658         : ${BUILD_OBJEXT:='o'}
659
660         AC_ARG_WITH(build-cc,
661                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
662                 [BUILD_CC="$withval"],
663                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
664         AC_MSG_CHECKING(for native build C compiler)
665         AC_MSG_RESULT($BUILD_CC)
666
667         AC_MSG_CHECKING(for native build C preprocessor)
668         AC_ARG_WITH(build-cpp,
669                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
670                 [BUILD_CPP="$withval"],
671                 [BUILD_CPP='${BUILD_CC} -E'])
672         AC_MSG_RESULT($BUILD_CPP)
673
674         AC_MSG_CHECKING(for native build C flags)
675         AC_ARG_WITH(build-cflags,
676                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
677                 [BUILD_CFLAGS="$withval"])
678         AC_MSG_RESULT($BUILD_CFLAGS)
679
680         AC_MSG_CHECKING(for native build C preprocessor-flags)
681         AC_ARG_WITH(build-cppflags,
682                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
683                 [BUILD_CPPFLAGS="$withval"])
684         AC_MSG_RESULT($BUILD_CPPFLAGS)
685
686         AC_MSG_CHECKING(for native build linker-flags)
687         AC_ARG_WITH(build-ldflags,
688                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
689                 [BUILD_LDFLAGS="$withval"])
690         AC_MSG_RESULT($BUILD_LDFLAGS)
691
692         AC_MSG_CHECKING(for native build linker-libraries)
693         AC_ARG_WITH(build-libs,
694                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
695                 [BUILD_LIBS="$withval"])
696         AC_MSG_RESULT($BUILD_LIBS)
697
698         # this assumes we're on Unix.
699         BUILD_EXEEXT=
700         BUILD_OBJEXT=o
701
702         : ${BUILD_CC:='${CC}'}
703
704         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
705                 AC_MSG_ERROR([Cross-build requires two compilers.
706 Use --with-build-cc to specify the native compiler.])
707         fi
708
709 else
710         : ${BUILD_CC:='${CC}'}
711         : ${BUILD_CPP:='${CPP}'}
712         : ${BUILD_CFLAGS:='${CFLAGS}'}
713         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
714         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
715         : ${BUILD_LIBS:='${LIBS}'}
716         : ${BUILD_EXEEXT:='$x'}
717         : ${BUILD_OBJEXT:='o'}
718 fi
719
720 AC_SUBST(BUILD_CC)
721 AC_SUBST(BUILD_CPP)
722 AC_SUBST(BUILD_CFLAGS)
723 AC_SUBST(BUILD_CPPFLAGS)
724 AC_SUBST(BUILD_LDFLAGS)
725 AC_SUBST(BUILD_LIBS)
726 AC_SUBST(BUILD_EXEEXT)
727 AC_SUBST(BUILD_OBJEXT)
728 ])dnl
729 dnl ---------------------------------------------------------------------------
730 dnl CF_CC_ENV_FLAGS version: 9 updated: 2018/07/29 18:03:26
731 dnl ---------------
732 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
733 dnl into CC.  This will not help with broken scripts that wrap the compiler
734 dnl with options, but eliminates a more common category of user confusion.
735 dnl
736 dnl In particular, it addresses the problem of being able to run the C
737 dnl preprocessor in a consistent manner.
738 dnl
739 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
740 dnl the nuisance of having inconsistent settings for compiler and preprocessor
741 dnl outweighs that limitation.
742 AC_DEFUN([CF_CC_ENV_FLAGS],
743 [
744 # This should have been defined by AC_PROG_CC
745 : ${CC:=cc}
746
747 AC_MSG_CHECKING(\$CFLAGS variable)
748 case "x$CFLAGS" in
749 (*-[[IUD]]*)
750         AC_MSG_RESULT(broken)
751         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
752         cf_flags="$CFLAGS"
753         CFLAGS=
754         for cf_arg in $cf_flags
755         do
756                 CF_ADD_CFLAGS($cf_arg)
757         done
758         ;;
759 (*)
760         AC_MSG_RESULT(ok)
761         ;;
762 esac
763
764 AC_MSG_CHECKING(\$CC variable)
765 case "$CC" in
766 (*[[\ \ ]]-*)
767         AC_MSG_RESULT(broken)
768         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
769         # humor him...
770         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
771         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
772         CC="$cf_prog"
773         for cf_arg in $cf_flags
774         do
775                 case "x$cf_arg" in
776                 (x-[[IUDfgOW]]*)
777                         CF_ADD_CFLAGS($cf_arg)
778                         ;;
779                 (*)
780                         CC="$CC $cf_arg"
781                         ;;
782                 esac
783         done
784         CF_VERBOSE(resulting CC: '$CC')
785         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
786         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
787         ;;
788 (*)
789         AC_MSG_RESULT(ok)
790         ;;
791 esac
792 ])dnl
793 dnl ---------------------------------------------------------------------------
794 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
795 dnl ---------------
796 dnl Determine the default configuration into which we'll install ncurses.  This
797 dnl can be overridden by the user's command-line options.  There's two items to
798 dnl look for:
799 dnl     1. the prefix (e.g., /usr)
800 dnl     2. the header files (e.g., /usr/include/ncurses)
801 dnl We'll look for a previous installation of ncurses and use the same defaults.
802 dnl
803 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
804 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
805 dnl programs from a vendor's.
806 AC_DEFUN([CF_CFG_DEFAULTS],
807 [
808 AC_MSG_CHECKING(for prefix)
809 if test "x$prefix" = "xNONE" ; then
810         case "$cf_cv_system_name" in
811                 # non-vendor systems don't have a conflict
812         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
813                 prefix=/usr
814                 ;;
815         (*)     prefix=$ac_default_prefix
816                 ;;
817         esac
818 fi
819 AC_MSG_RESULT($prefix)
820
821 if test "x$prefix" = "xNONE" ; then
822 AC_MSG_CHECKING(for default include-directory)
823 test -n "$verbose" && echo 1>&AC_FD_MSG
824 for cf_symbol in \
825         $includedir \
826         $includedir/ncurses \
827         $prefix/include \
828         $prefix/include/ncurses \
829         /usr/local/include \
830         /usr/local/include/ncurses \
831         /usr/include \
832         /usr/include/ncurses
833 do
834         cf_dir=`eval echo $cf_symbol`
835         if test -f $cf_dir/curses.h ; then
836         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
837                 includedir="$cf_symbol"
838                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
839                 break
840         fi
841         fi
842         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
843 done
844 AC_MSG_RESULT($includedir)
845 fi
846 ])dnl
847 dnl ---------------------------------------------------------------------------
848 dnl CF_CGETENT version: 6 updated: 2017/01/21 11:06:25
849 dnl ----------
850 dnl Check if the terminal-capability database functions are available.  If not,
851 dnl ncurses has a much-reduced version.
852 AC_DEFUN([CF_CGETENT],[
853 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
854 AC_TRY_LINK([
855 #include <stdlib.h>],[
856         char temp[128];
857         char *buf = temp;
858         char *db_array = temp;
859         cgetent(&buf, &db_array, "vt100");
860         cgetcap(buf, "tc", '=');
861         cgetmatch(buf, "tc");
862         ],
863         [cf_cv_cgetent=yes],
864         [cf_cv_cgetent=no])
865 ])
866
867 if test "$cf_cv_cgetent" = yes
868 then
869         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
870 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
871 AC_TRY_LINK([
872 #pragma GCC diagnostic error "-Wincompatible-pointer-types-discards-qualifiers"
873 #include <stdlib.h>],[
874         char temp[128];
875         char *buf = temp;
876 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
877         const char *db_array = temp;
878         cgetent(&buf, &db_array, "vt100");
879 #endif
880         cgetcap(buf, "tc", '=');
881         cgetmatch(buf, "tc");
882         ],
883         [cf_cv_cgetent_const=yes],
884         [cf_cv_cgetent_const=no])
885 ])
886         if test "$cf_cv_cgetent_const" = yes
887         then
888                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
889         fi
890 fi
891 ])dnl
892 dnl ---------------------------------------------------------------------------
893 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
894 dnl --------------
895 dnl Check if we're accidentally using a cache from a different machine.
896 dnl Derive the system name, as a check for reusing the autoconf cache.
897 dnl
898 dnl If we've packaged config.guess and config.sub, run that (since it does a
899 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
900 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
901 dnl which is useful in cross-compiles.
902 dnl
903 dnl Note: we would use $ac_config_sub, but that is one of the places where
904 dnl autoconf 2.5x broke compatibility with autoconf 2.13
905 AC_DEFUN([CF_CHECK_CACHE],
906 [
907 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
908         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
909         system_name="$host_os"
910 else
911         system_name="`(uname -s -r) 2>/dev/null`"
912         if test -z "$system_name" ; then
913                 system_name="`(hostname) 2>/dev/null`"
914         fi
915 fi
916 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
917 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
918
919 test -z "$system_name" && system_name="$cf_cv_system_name"
920 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
921
922 if test ".$system_name" != ".$cf_cv_system_name" ; then
923         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
924         AC_MSG_ERROR("Please remove config.cache and try again.")
925 fi
926 ])dnl
927 dnl ---------------------------------------------------------------------------
928 dnl CF_CHECK_ENVIRON version: 3 updated: 2010/05/26 16:44:57
929 dnl ----------------
930 dnl Check for data that is usually declared in <unistd.h>, e.g., the 'environ'
931 dnl variable.  Define a DECL_xxx symbol if we must declare it ourselves.
932 dnl
933 dnl $1 = the name to check
934 dnl $2 = the assumed type
935 AC_DEFUN([CF_CHECK_ENVIRON],
936 [
937 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
938     AC_TRY_COMPILE([
939 #ifdef HAVE_STDLIB_H
940 #include <stdlib.h>
941 #endif
942 #include <unistd.h> ],
943     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
944     [cf_cv_dcl_$1=yes],
945     [cf_cv_dcl_$1=no])
946 ])
947
948 if test "$cf_cv_dcl_$1" = no ; then
949     CF_UPPER(cf_result,decl_$1)
950     AC_DEFINE_UNQUOTED($cf_result)
951 fi
952
953 # It's possible (for near-UNIX clones) that the data doesn't exist
954 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
955 ])dnl
956 dnl ---------------------------------------------------------------------------
957 dnl CF_CHECK_ERRNO version: 12 updated: 2015/04/18 08:56:57
958 dnl --------------
959 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
960 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
961 dnl ourselves.
962 dnl
963 dnl $1 = the name to check
964 dnl $2 = the assumed type
965 AC_DEFUN([CF_CHECK_ERRNO],
966 [
967 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
968         AC_TRY_COMPILE([
969 #ifdef HAVE_STDLIB_H
970 #include <stdlib.h>
971 #endif
972 #include <stdio.h>
973 #include <sys/types.h>
974 #include <errno.h> ],
975         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
976         [cf_cv_dcl_$1=yes],
977         [cf_cv_dcl_$1=no])
978 ])
979
980 if test "$cf_cv_dcl_$1" = no ; then
981         CF_UPPER(cf_result,decl_$1)
982         AC_DEFINE_UNQUOTED($cf_result)
983 fi
984
985 # It's possible (for near-UNIX clones) that the data doesn't exist
986 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
987 ])dnl
988 dnl ---------------------------------------------------------------------------
989 dnl CF_CHECK_EXTERN_DATA version: 4 updated: 2015/04/18 08:56:57
990 dnl --------------------
991 dnl Check for existence of external data in the current set of libraries.  If
992 dnl we can modify it, it's real enough.
993 dnl $1 = the name to check
994 dnl $2 = its type
995 AC_DEFUN([CF_CHECK_EXTERN_DATA],
996 [
997 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
998         AC_TRY_LINK([
999 #undef $1
1000 extern $2 $1;
1001 ],
1002         [$1 = 2],
1003         [cf_cv_have_$1=yes],
1004         [cf_cv_have_$1=no])
1005 ])
1006
1007 if test "$cf_cv_have_$1" = yes ; then
1008         CF_UPPER(cf_result,have_$1)
1009         AC_DEFINE_UNQUOTED($cf_result)
1010 fi
1011
1012 ])dnl
1013 dnl ---------------------------------------------------------------------------
1014 dnl CF_CHECK_GETENV version: 1 updated: 2019/06/23 15:28:15
1015 dnl ---------------
1016 dnl Check if repeated getenv calls return the same pointer, e.g., it does not
1017 dnl discard the previous pointer when returning a new one.
1018 AC_DEFUN([CF_CHECK_GETENV],
1019 [
1020 AC_REQUIRE([CF_CHECK_ENVIRON])
1021 AC_CHECK_FUNC( getenv, ,, AC_MSG_ERROR(getenv not found) )
1022 AC_CHECK_FUNCS( putenv setenv strdup )
1023 AC_CACHE_CHECK(if getenv returns consistent values,cf_cv_consistent_getenv,[
1024 AC_TRY_RUN([
1025 #include <stdlib.h>
1026 #include <unistd.h>
1027 #include <stdio.h>
1028 #include <string.h>
1029 #include <sys/types.h>
1030
1031 #if defined(HAVE_ENVIRON) && defined(DECL_ENVIRON) && !defined(environ)
1032 extern char **environ;  /* POSIX, but some systems are not... */
1033 #endif
1034
1035 #if defined(HAVE_STRDUP)
1036 #define str_alloc(s) strdup(s)
1037 #else
1038 #define str_alloc(s) strcpy(malloc(strlen(s) + 1, s))
1039 #endif
1040
1041 static void set_value(const char *name, const char *value)
1042 {
1043 #if defined(HAVE_SETENV)
1044         setenv(name, value, 1);
1045 #elif defined(HAVE_PUTENV)
1046         char buffer[1024];
1047         sprintf(buffer, "%s=%s", name, value);
1048         putenv(str_alloc(buffer));
1049 #else
1050 #error neither putenv/setenv found
1051 #endif
1052 }
1053 int main(void)
1054 {
1055         int pass;
1056         size_t numenv, limit, j;
1057         char **mynames;
1058         char **myvalues;
1059         char **mypointer;
1060         char *equals;
1061         for (numenv = 0; environ[numenv]; ++numenv) ;
1062         limit = numenv + 10;
1063         mynames = (char **) calloc(limit + 1, sizeof(char *));
1064         myvalues = (char **) calloc(limit + 1, sizeof(char *));
1065         mypointer = (char **) calloc(limit + 1, sizeof(char *));
1066 #if defined(HAVE_ENVIRON)
1067         for (j = 0; environ[j]; ++j) {
1068                 mynames[j] = str_alloc(environ[j]);
1069                 equals = strchr(mynames[j], '=');
1070                 if (equals != 0) {
1071                         *equals++ = '\0';
1072                         myvalues[j] = str_alloc(equals);
1073                 } else {
1074                         myvalues[j] = str_alloc("");
1075                 }
1076         }
1077 #endif
1078         for (j = numenv; j < limit; ++j) {
1079                 char name[80];
1080                 char value[80];
1081                 size_t found;
1082                 size_t k = 0;
1083                 do {
1084                         size_t jk;
1085                         found = 0;
1086                         sprintf(name, "TERM%lu", (unsigned long) k);
1087                         for (jk = 0; jk < j; ++jk) {
1088                                 if (!strcmp(name, mynames[jk])) {
1089                                         found = 1;
1090                                         ++k;
1091                                         break;
1092                                 }
1093                         }
1094                 } while (found);
1095                 sprintf(value, "%lu:%p", (unsigned long) k, &mynames[j]);
1096                 set_value(name, value);
1097                 mynames[j] = str_alloc(name);
1098                 myvalues[j] = str_alloc(value);
1099         }
1100         for (pass = 0; pass < 3; ++pass) {
1101                 for (j = 0; j < limit; ++j) {
1102                         char *value = getenv(mynames[j]);
1103                         if (pass) {
1104                                 if (value == 0) {
1105                                         fprintf(stderr, "getenv returned null for %s\n", mynames[j]);
1106                                         ${cf_cv_main_return:-return}(1);
1107                                 } else if (value != mypointer[j]) {
1108                                         fprintf(stderr, "getenv returned different pointer for %s\n", mynames[j]);
1109                                         ${cf_cv_main_return:-return}(1);
1110                                 } else if (strcmp(value, myvalues[j])) {
1111                                         fprintf(stderr, "getenv returned different value for %s\n", mynames[j]);
1112                                         ${cf_cv_main_return:-return}(1);
1113                                 }
1114                         } else {
1115                                 size_t k;
1116                                 mypointer[j] = value;
1117                                 for (k = 0; k < j; ++k) {
1118                                         if (mypointer[j] == mypointer[k]) {
1119                                                 fprintf(stderr, "getenv returned same pointer for %s and %s\n", mynames[j], mynames[k]);
1120                                                 ${cf_cv_main_return:-return}(1);
1121                                         }
1122                                 }
1123                         }
1124                 }
1125         }
1126         ${cf_cv_main_return:-return}(0);
1127 }
1128 ],
1129 [cf_cv_consistent_getenv=yes],
1130 [cf_cv_consistent_getenv=no],
1131 [cf_cv_consistent_getenv=unknown])
1132 ])
1133
1134 if test "x$cf_cv_consistent_getenv" = xno
1135 then
1136         AC_DEFINE(HAVE_CONSISTENT_GETENV,1,[Define to 1 if getenv repeatably returns the same value for a given name])
1137 fi
1138 ])dnl
1139 dnl ---------------------------------------------------------------------------
1140 dnl CF_CHECK_GPM_WGETCH version: 3 updated: 2017/01/21 11:06:25
1141 dnl -------------------
1142 dnl Check if GPM is already linked with curses.  If so - and if the linkage
1143 dnl is not "weak" - warn about this because it can create problems linking
1144 dnl applications with ncurses.
1145 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
1146 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
1147
1148 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
1149 cf_cv_check_gpm_wgetch=unknown
1150 if test "$cross_compiling" != yes ; then
1151
1152 cat >conftest.$ac_ext <<CF_EOF
1153 #include <gpm.h>
1154 int main(void)
1155 {
1156         Gpm_Wgetch();
1157         ${cf_cv_main_return:-return}(0);
1158 }
1159 CF_EOF
1160
1161         cf_save_LIBS="$LIBS"
1162         # This only works if we can look at the symbol table.  If a shared
1163         # library is stripped for install, we cannot use that.  So we're forced
1164         # to rely on the static library, noting that some packagers may not
1165         # include it.
1166         LIBS="-static -lgpm -dynamic $LIBS"
1167         if AC_TRY_EVAL(ac_compile) ; then
1168                 if AC_TRY_EVAL(ac_link) ; then
1169                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
1170                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
1171                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
1172                 fi
1173         fi
1174         rm -rf conftest*
1175         LIBS="$cf_save_LIBS"
1176 fi
1177 ])
1178
1179 if test "$cf_cv_check_gpm_wgetch" != yes ; then
1180         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
1181 fi
1182 ])])dnl
1183 dnl ---------------------------------------------------------------------------
1184 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
1185 dnl ------------------------
1186 dnl Show the version of libtool
1187 dnl
1188 dnl Save the version in a cache variable - this is not entirely a good thing,
1189 dnl but the version string from libtool is very ugly, and for bug reports it
1190 dnl might be useful to have the original string.
1191 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
1192 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
1193 then
1194         AC_MSG_CHECKING(version of $LIBTOOL)
1195         CF_LIBTOOL_VERSION
1196         AC_MSG_RESULT($cf_cv_libtool_version)
1197         if test -z "$cf_cv_libtool_version" ; then
1198                 AC_MSG_ERROR(This is not GNU libtool)
1199         fi
1200 else
1201         AC_MSG_ERROR(GNU libtool has not been found)
1202 fi
1203 ])dnl
1204 dnl ---------------------------------------------------------------------------
1205 dnl CF_CHECK_WCHAR_H version: 2 updated: 2017/01/21 11:06:25
1206 dnl ----------------
1207 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
1208 AC_DEFUN([CF_CHECK_WCHAR_H],[
1209 AC_CHECK_HEADERS( \
1210 wchar.h \
1211 wctype.h \
1212 )
1213 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1214 AC_TRY_COMPILE(
1215 [
1216 #include <stdlib.h>
1217 #ifdef HAVE_WCHAR_H
1218 #include <wchar.h>
1219 #endif
1220 #ifdef HAVE_WCTYPE_H
1221 #include <wctype.h>
1222 #endif
1223 ],[
1224         wint_t foo = 0;
1225         int bar = iswpunct(foo)],
1226         [cf_cv_wchar_h_okay=yes],
1227         [cf_cv_wchar_h_okay=no])])
1228
1229 if test $cf_cv_wchar_h_okay = no
1230 then
1231         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1232 fi
1233 ])dnl
1234 dnl ---------------------------------------------------------------------------
1235 dnl CF_CHECK_WCWIDTH_GRAPHICS version: 1 updated: 2015/12/19 17:47:56
1236 dnl -------------------------
1237 dnl Most "modern" terminal emulators are based to some degree on VT100, and
1238 dnl should support line-drawing.  Even with Unicode.  There is a problem.
1239 dnl
1240 dnl While most of the VT100 graphics characters were incorporated into Unicode,
1241 dnl all of those were combined into a page of useful graphics characters.
1242 dnl
1243 dnl So far, so good.
1244 dnl
1245 dnl However, while they are useful, there are other considerations.  CJK
1246 dnl is (because of poor device resolution) often rendered as double-width
1247 dnl characters.  So... for these generally-useful characters, what should
1248 dnl be the width (to make them consistent with adjacent characters)?
1249 dnl
1250 dnl The obvious choice would have been to make this locale-dependent, and use
1251 dnl wcwidth() to tell applications what the actual width is.  That was too
1252 dnl obvious.  Instead, we have a slew of "ambiguous-width" characters.
1253 dnl See for example
1254 dnl             http://www.unicode.org/reports/tr11/tr11-29.html
1255 dnl             http://www.cl.cam.ac.uk/~mgk25/ucs/scw-proposal.html
1256 dnl
1257 dnl The EastAsianWidth-6.2.0.txt file from the Unicode organization lists
1258 dnl more than 22,000 characters, with 1281 of those as ambiguous-width.  For
1259 dnl instance, it lists half (44/96) of the Latin-1 characters as
1260 dnl ambiguous-width.  Also, all of the box-characters at 0x2500 are ambiguous.
1261 dnl
1262 dnl What this means for the implementor is that on some systems wcwidth() can
1263 dnl give bad advice.  On Solaris, some of the ambiguous widths are returned as
1264 dnl 1 (the Latin-1 characters), while others are returned as 2 (line-drawing
1265 dnl characters).  These do not necessarily match the behavior of the terminal
1266 dnl emulator.  xterm, for instance, does an optional startup check to find if
1267 dnl this problem (or similar) exists with the system's locale tables, rejecting
1268 dnl them if they are too unreliable.
1269 AC_DEFUN([CF_CHECK_WCWIDTH_GRAPHICS],[
1270 AC_CACHE_CHECK(if wcwidth agrees graphics are single-width, cf_cv_wcwidth_graphics,[
1271 cat >conftest.in <<CF_EOF
1272 -       VT100 symbols
1273 0x250c  upper left corner
1274 0x2514  lower left corner
1275 0x2510  upper right corner
1276 0x2518  lower right corner
1277 0x251c  tee pointing left
1278 0x2524  tee pointing right
1279 0x2534  tee pointing up
1280 0x252c  tee pointing down
1281 0x2500  horizontal line
1282 0x2502  vertical line
1283 0x253c  large plus or crossover
1284 0x23ba  scan line 1
1285 0x23bd  scan line 9
1286 0x25c6  diamond
1287 0x2592  checker board (stipple)
1288 0x00b0  degree symbol
1289 0x00b1  plus/minus
1290 0x00b7  bullet
1291 -       Teletype 5410v1 symbols
1292 0x2190  arrow pointing left
1293 0x2192  arrow pointing right
1294 0x2193  arrow pointing down
1295 0x2191  arrow pointing up
1296 0x2592  board of squares
1297 0x2603  lantern symbol
1298 0x25ae  solid square block
1299 -       these defaults were invented for ncurses
1300 0x23bb  scan line 3
1301 0x23bc  scan line 7
1302 0x2264  less-than-or-equal-to
1303 0x2265  greater-than-or-equal-to
1304 0x03c0  greek pi
1305 0x2260  not-equal
1306 0x00a3  pound-sterling symbol
1307 -       thick-line-drawing
1308 0x250f  upper left corner
1309 0x2517  lower left corner
1310 0x2513  upper right corner
1311 0x251b  lower right corner
1312 0x2523  tee pointing left
1313 0x252b  tee pointing right
1314 0x253b  tee pointing up
1315 0x2533  tee pointing down
1316 0x2501  horizontal line
1317 0x2503  vertical line
1318 0x254b  large plus or crossover
1319 -       double-line-drawing
1320 0x2554  upper left corner
1321 0x255a  lower left corner
1322 0x2557  upper right corner
1323 0x255d  lower right corner
1324 0x2563  tee pointing left
1325 0x2560  tee pointing right
1326 0x2569  tee pointing up
1327 0x2566  tee pointing down
1328 0x2550  horizontal line
1329 0x2551  vertical line
1330 0x256c  large plus or crossover
1331 CF_EOF
1332 AC_TRY_RUN([
1333 #include <locale.h>
1334 #include <stdio.h>
1335 #include <wchar.h>
1336
1337 #define MY_LEN 80
1338
1339 int
1340 main(void)
1341 {
1342         FILE *fp;
1343         int value;
1344         char buffer[MY_LEN + 1];
1345         char notes[MY_LEN + 1];
1346         int totals = 0;
1347         int passed = 0;
1348
1349         if (setlocale(LC_ALL, "en_US.UTF8") ||
1350                 setlocale(LC_ALL, "en_US.UTF-8") ||
1351                 setlocale(LC_ALL, "en_US.utf8") ||
1352                 setlocale(LC_ALL, "en_US.utf-8")) {
1353                 if ((fp = fopen("conftest.in", "r")) != 0) {
1354                         while (fgets(buffer, MY_LEN, fp) != 0) {
1355                                 if (*buffer == '-') {
1356                                         fprintf(stderr, "\t%s", buffer);
1357                                 } else if (sscanf(buffer, "%x %s", &value, notes) == 2) {
1358                                         ++totals;
1359                                         if (wcwidth(value) == 1)
1360                                                 ++passed;
1361                                         fprintf(stderr, "%d\t%s", wcwidth(value), buffer);
1362                                 } else {
1363                                         fprintf(stderr, "?\t%s", buffer);
1364                                 }
1365                         }
1366                 }
1367         }
1368         fprintf(stderr, "%d/%d passed wcwidth/graphics check\n", passed, totals);
1369         return (totals == passed) ? 0 : 1;
1370 }
1371 ],
1372 [cf_cv_wcwidth_graphics=yes],
1373 [cf_cv_wcwidth_graphics=no],
1374 [cf_cv_wcwidth_graphics=unknown])
1375 ])
1376 ])dnl
1377 dnl ---------------------------------------------------------------------------
1378 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
1379 dnl -----------------
1380 dnl Check if the given compiler is really clang.  clang's C driver defines
1381 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1382 dnl not ignore some gcc options.
1383 dnl
1384 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1385 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1386 dnl the wrappers for gcc and g++ warnings.
1387 dnl
1388 dnl $1 = GCC (default) or GXX
1389 dnl $2 = CLANG_COMPILER (default)
1390 dnl $3 = CFLAGS (default) or CXXFLAGS
1391 AC_DEFUN([CF_CLANG_COMPILER],[
1392 ifelse([$2],,CLANG_COMPILER,[$2])=no
1393
1394 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1395         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1396         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1397         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
1398         AC_TRY_COMPILE([],[
1399 #ifdef __clang__
1400 #else
1401 make an error
1402 #endif
1403 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1404 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
1405 ],[])
1406         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1407         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1408 fi
1409 ])
1410 dnl ---------------------------------------------------------------------------
1411 dnl CF_CONST_X_STRING version: 1 updated: 2019/04/08 17:50:29
1412 dnl -----------------
1413 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
1414 dnl character-strings.
1415 dnl
1416 dnl It is ambiguous because the specification accommodated the pre-ANSI
1417 dnl compilers bundled by more than one vendor in lieu of providing a standard C
1418 dnl compiler other than by costly add-ons.  Because of this, the specification
1419 dnl did not take into account the use of const for telling the compiler that
1420 dnl string literals would be in readonly memory.
1421 dnl
1422 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
1423 dnl let the compiler decide how to represent Xt's strings which were #define'd. 
1424 dnl That does not solve the problem of using the block of Xt's strings which
1425 dnl are compiled into the library (and is less efficient than one might want).
1426 dnl
1427 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
1428 dnl when compiling the library and compiling using the library, to tell the
1429 dnl compiler that String is const.
1430 AC_DEFUN([CF_CONST_X_STRING],
1431 [
1432 AC_TRY_COMPILE(
1433 [
1434 #include <stdlib.h>
1435 #include <X11/Intrinsic.h>
1436 ],
1437 [String foo = malloc(1)],[
1438
1439 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
1440         AC_TRY_COMPILE(
1441                 [
1442 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
1443 #undef  XTSTRINGDEFINES /* X11R5 and later */
1444 #include <stdlib.h>
1445 #include <X11/Intrinsic.h>
1446                 ],[String foo = malloc(1); *foo = 0],[
1447                         cf_cv_const_x_string=no
1448                 ],[
1449                         cf_cv_const_x_string=yes
1450                 ])
1451 ])
1452
1453 case $cf_cv_const_x_string in
1454 (no)
1455         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
1456         ;;
1457 (*)
1458         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
1459         ;;
1460 esac
1461
1462 ])
1463 ])dnl
1464 dnl ---------------------------------------------------------------------------
1465 dnl CF_CPP_PARAM_INIT version: 7 updated: 2017/01/21 11:06:25
1466 dnl -----------------
1467 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1468 dnl is a late feature for the standard and is not in some recent compilers
1469 dnl (1999/9/11).
1470 AC_DEFUN([CF_CPP_PARAM_INIT],
1471 [
1472 if test -n "$CXX"; then
1473 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1474         AC_LANG_SAVE
1475         AC_LANG_CPLUSPLUS
1476         AC_TRY_RUN([
1477 class TEST {
1478 private:
1479         int value;
1480 public:
1481         TEST(int x = 1);
1482         ~TEST();
1483 };
1484
1485 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1486 {
1487         value = x;
1488 }
1489 int main(void) { }
1490 ],
1491         [cf_cv_cpp_param_init=yes],
1492         [cf_cv_cpp_param_init=no],
1493         [cf_cv_cpp_param_init=unknown])
1494         AC_LANG_RESTORE
1495 ])
1496 fi
1497 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1498 ])dnl
1499 dnl ---------------------------------------------------------------------------
1500 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1501 dnl ------------------
1502 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1503 dnl not be supported in g++ before 3.0
1504 AC_DEFUN([CF_CPP_STATIC_CAST],
1505 [
1506 if test -n "$CXX"; then
1507
1508 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1509         AC_LANG_SAVE
1510         AC_LANG_CPLUSPLUS
1511
1512         AC_TRY_COMPILE([
1513 class NCursesPanel
1514 {
1515 public:
1516   NCursesPanel(int nlines,
1517                int ncols,
1518                int begin_y = 0,
1519                int begin_x = 0)
1520   {
1521   }
1522   NCursesPanel();
1523   ~NCursesPanel();
1524 };
1525
1526 template<class T> class NCursesUserPanel : public NCursesPanel
1527 {
1528 public:
1529   NCursesUserPanel (int nlines,
1530                     int ncols,
1531                     int begin_y = 0,
1532                     int begin_x = 0,
1533                     const T* p_UserData = static_cast<T*>(0))
1534     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1535   {
1536   };
1537   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1538   {
1539   };
1540
1541   virtual ~NCursesUserPanel() {};
1542 };
1543 ],[
1544         const char* p_UserData = static_cast<char*>(0)],
1545         [cf_cv_cpp_static_cast=yes],
1546         [cf_cv_cpp_static_cast=no])
1547
1548         AC_LANG_RESTORE
1549 ])
1550
1551 fi
1552
1553 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1554 ])dnl
1555 dnl ---------------------------------------------------------------------------
1556 dnl CF_CXX_AR_FLAGS version: 2 updated: 2015/04/17 21:13:04
1557 dnl ---------------
1558 dnl Setup special archiver flags for given compilers.
1559 AC_DEFUN([CF_CXX_AR_FLAGS],[
1560         CXX_AR='$(AR)'
1561         CXX_ARFLAGS='$(ARFLAGS)'
1562         case $cf_cv_system_name in
1563         (irix*)
1564             if test "$GXX" != yes ; then
1565                 CXX_AR='$(CXX)'
1566                 CXX_ARFLAGS='-ar -o'
1567             fi
1568             ;;
1569         (sco3.2v5*)
1570             CXXLDFLAGS="-u main"
1571             ;;
1572         (solaris2*)
1573             if test "$GXX" != yes ; then
1574                 CXX_AR='$(CXX)'
1575                 CXX_ARFLAGS='-xar -o'
1576             fi
1577             ;;
1578         esac
1579         AC_SUBST(CXXLDFLAGS)
1580         AC_SUBST(CXX_AR)
1581         AC_SUBST(CXX_ARFLAGS)
1582 ])dnl
1583 dnl ---------------------------------------------------------------------------
1584 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1585 dnl -------------------------
1586 dnl For c++, check if iostream uses "std::" namespace.
1587 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1588 AC_CHECK_HEADERS(iostream)
1589 if test x"$ac_cv_header_iostream" = xyes ; then
1590         AC_MSG_CHECKING(if iostream uses std-namespace)
1591         AC_TRY_COMPILE([
1592 #include <iostream>
1593 using std::endl;
1594 using std::cerr;],[
1595 cerr << "testing" << endl;
1596 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1597         AC_MSG_RESULT($cf_iostream_namespace)
1598         if test "$cf_iostream_namespace" = yes ; then
1599                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1600         fi
1601 fi
1602 ])dnl
1603 dnl ---------------------------------------------------------------------------
1604 dnl CF_C_INLINE version: 6 updated: 2019/09/07 13:38:36
1605 dnl -----------
1606 dnl Check if the C compiler supports "inline".
1607 dnl $1 is the name of a shell variable to set if inline is supported
1608 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1609 AC_DEFUN([CF_C_INLINE],[
1610 AC_REQUIRE([CF_GCC_VERSION])
1611 AC_C_INLINE
1612 $1=
1613 if test "$ac_cv_c_inline" != no ; then
1614         $1=inline
1615         if test "$INTEL_COMPILER" = yes
1616         then
1617                 :
1618         elif test "$CLANG_COMPILER" = yes
1619         then
1620                 :
1621         elif test "$GCC" = yes
1622         then
1623                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1624                 cf_save_CFLAGS=$CFLAGS
1625                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1626                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1627                 [${cf_cv_main_return:-return} foo()],
1628                 [cf_cv_gcc_inline=yes],
1629                 [cf_cv_gcc_inline=no])
1630                 CFLAGS=$cf_save_CFLAGS
1631                 ])
1632                 if test "$cf_cv_gcc_inline" = yes ; then
1633                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1634                 fi
1635         fi
1636 fi
1637 AC_SUBST($1)
1638 ])dnl
1639 dnl ---------------------------------------------------------------------------
1640 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1641 dnl ----------
1642 dnl "dirname" is not portable, so we fake it with a shell script.
1643 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1644 dnl ---------------------------------------------------------------------------
1645 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1646 dnl ---------------
1647 AC_DEFUN([CF_DIRS_TO_MAKE],
1648 [
1649 DIRS_TO_MAKE="lib"
1650 for cf_item in $cf_list_models
1651 do
1652         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1653         for cf_item2 in $DIRS_TO_MAKE
1654         do
1655                 test $cf_item2 = $cf_subdir && break
1656         done
1657         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1658 done
1659 for cf_dir in $DIRS_TO_MAKE
1660 do
1661         test ! -d $cf_dir && mkdir $cf_dir
1662 done
1663 AC_SUBST(DIRS_TO_MAKE)
1664 ])dnl
1665 dnl ---------------------------------------------------------------------------
1666 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1667 dnl ---------------
1668 dnl You can always use "make -n" to see the actual options, but it's hard to
1669 dnl pick out/analyze warning messages when the compile-line is long.
1670 dnl
1671 dnl Sets:
1672 dnl     ECHO_LT - symbol to control if libtool is verbose
1673 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1674 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1675 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1676 dnl     ECHO_CC - symbol to put before any "cc" line
1677 dnl
1678 AC_DEFUN([CF_DISABLE_ECHO],[
1679 AC_MSG_CHECKING(if you want to see long compiling messages)
1680 CF_ARG_DISABLE(echo,
1681         [  --disable-echo          do not display "compiling" commands],
1682         [
1683         ECHO_LT='--silent'
1684         ECHO_LD='@echo linking [$]@;'
1685         RULE_CC='@echo compiling [$]<'
1686         SHOW_CC='@echo compiling [$]@'
1687         ECHO_CC='@'
1688 ],[
1689         ECHO_LT=''
1690         ECHO_LD=''
1691         RULE_CC=''
1692         SHOW_CC=''
1693         ECHO_CC=''
1694 ])
1695 AC_MSG_RESULT($enableval)
1696 AC_SUBST(ECHO_LT)
1697 AC_SUBST(ECHO_LD)
1698 AC_SUBST(RULE_CC)
1699 AC_SUBST(SHOW_CC)
1700 AC_SUBST(ECHO_CC)
1701 ])dnl
1702 dnl ---------------------------------------------------------------------------
1703 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1704 dnl ------------------------
1705 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1706 AC_MSG_CHECKING(if we want to use GNAT projects)
1707 CF_ARG_DISABLE(gnat-projects,
1708         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1709         [enable_gnat_projects=no],
1710         [enable_gnat_projects=yes])
1711 AC_MSG_RESULT($enable_gnat_projects)
1712 ])dnl
1713 dnl ---------------------------------------------------------------------------
1714 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1715 dnl ----------------
1716 dnl Combine no-leak checks with the libraries or tools that are used for the
1717 dnl checks.
1718 AC_DEFUN([CF_DISABLE_LEAKS],[
1719
1720 AC_REQUIRE([CF_WITH_DMALLOC])
1721 AC_REQUIRE([CF_WITH_DBMALLOC])
1722 AC_REQUIRE([CF_WITH_VALGRIND])
1723
1724 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1725 AC_ARG_ENABLE(leaks,
1726         [  --disable-leaks         test: free permanent memory, analyze leaks],
1727         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1728         : ${with_no_leaks:=no})
1729 AC_MSG_RESULT($with_no_leaks)
1730
1731 if test "$with_no_leaks" = yes ; then
1732         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1733         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1734 fi
1735 ])dnl
1736 dnl ---------------------------------------------------------------------------
1737 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
1738 dnl --------------------------
1739 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1740 dnl the older "-version-info" feature.  The newer feature allows us to use
1741 dnl version numbering on shared libraries which make them compatible with
1742 dnl various systems.
1743 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1744 [
1745 AC_MSG_CHECKING(if libtool -version-number should be used)
1746 CF_ARG_DISABLE(libtool-version,
1747         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1748         [cf_libtool_version=no],
1749         [cf_libtool_version=yes])
1750 AC_MSG_RESULT($cf_libtool_version)
1751
1752 if test "$cf_libtool_version" = yes ; then
1753         LIBTOOL_VERSION="-version-number"
1754 else
1755         LIBTOOL_VERSION="-version-info"
1756         case "x$VERSION" in
1757         (x)
1758                 AC_MSG_WARN(VERSION was not set)
1759                 ;;
1760         (x*.*.*)
1761                 ABI_VERSION="$VERSION"
1762                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1763                 ;;
1764         (x*:*:*)
1765                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
1766                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1767                 ;;
1768         (*)
1769                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
1770                 ;;
1771         esac
1772 fi
1773
1774 AC_SUBST(ABI_VERSION)
1775 AC_SUBST(LIBTOOL_VERSION)
1776 ])dnl
1777 dnl ---------------------------------------------------------------------------
1778 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1779 dnl ---------------------
1780 dnl The rpath-hack makes it simpler to build programs, particularly with the
1781 dnl *BSD ports which may have essential libraries in unusual places.  But it
1782 dnl can interfere with building an executable for the base system.  Use this
1783 dnl option in that case.
1784 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1785 [
1786 AC_MSG_CHECKING(if rpath-hack should be disabled)
1787 CF_ARG_DISABLE(rpath-hack,
1788         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1789         [cf_disable_rpath_hack=yes],
1790         [cf_disable_rpath_hack=no])
1791 AC_MSG_RESULT($cf_disable_rpath_hack)
1792 if test "$cf_disable_rpath_hack" = no ; then
1793         CF_RPATH_HACK
1794 fi
1795 ])
1796 dnl ---------------------------------------------------------------------------
1797 dnl CF_ENABLE_PC_FILES version: 13 updated: 2015/11/01 05:27:39
1798 dnl ------------------
1799 dnl This is the "--enable-pc-files" option, which is available if there is a
1800 dnl pkg-config configuration on the local machine.
1801 AC_DEFUN([CF_ENABLE_PC_FILES],[
1802 AC_REQUIRE([CF_PKG_CONFIG])
1803 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1804
1805 if test "x$PKG_CONFIG" != xnone
1806 then
1807         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1808 else
1809         AC_MSG_CHECKING(if we should install .pc files)
1810 fi
1811
1812 AC_ARG_ENABLE(pc-files,
1813         [  --enable-pc-files       generate and install .pc files for pkg-config],
1814         [enable_pc_files=$enableval],
1815         [enable_pc_files=no])
1816 AC_MSG_RESULT($enable_pc_files)
1817
1818 if test "x$enable_pc_files" != xno
1819 then
1820         MAKE_PC_FILES=
1821         case "x$PKG_CONFIG_LIBDIR" in
1822         (xno|xyes)
1823                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
1824                 ;;
1825         (*)
1826                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1827                 ;;
1828         esac
1829 else
1830         MAKE_PC_FILES="#"
1831 fi
1832 AC_SUBST(MAKE_PC_FILES)
1833 ])dnl
1834 dnl ---------------------------------------------------------------------------
1835 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1836 dnl ---------------
1837 dnl Check if the rpath option should be used, setting cache variable
1838 dnl cf_cv_enable_rpath if so.
1839 AC_DEFUN([CF_ENABLE_RPATH],
1840 [
1841 AC_MSG_CHECKING(if rpath option should be used)
1842 AC_ARG_ENABLE(rpath,
1843 [  --enable-rpath          use rpath option when generating shared libraries],
1844 [cf_cv_enable_rpath=$enableval],
1845 [cf_cv_enable_rpath=no])
1846 AC_MSG_RESULT($cf_cv_enable_rpath)
1847 ])dnl
1848 dnl ---------------------------------------------------------------------------
1849 dnl CF_ENABLE_STRING_HACKS version: 5 updated: 2016/10/08 17:34:11
1850 dnl ----------------------
1851 dnl On a few platforms, the compiler and/or loader nags with untruthful
1852 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1853 dnl and implying that most uses of the recommended alternatives are correct.
1854 dnl
1855 dnl Factually speaking, no one has actually counted the number of uses of these
1856 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1857 dnl instances are meaningless compared to the hundreds of millions of lines of
1858 dnl existing C code.
1859 dnl
1860 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1861 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1862 dnl standard - but evolved through phases, and older implementations are likely
1863 dnl to yield surprising results, as documented in manpages on various systems.
1864 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1865 [
1866 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1867 AC_ARG_ENABLE(string-hacks,
1868         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1869         [with_string_hacks=$enableval],
1870         [with_string_hacks=no])
1871 AC_MSG_RESULT($with_string_hacks)
1872
1873 if test "x$with_string_hacks" = "xyes"; then
1874         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1875         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1876         AC_CHECK_FUNC(strlcat,[
1877                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1878                 ],[
1879                 AC_CHECK_LIB(bsd,strlcat,[
1880                         CF_ADD_LIB(bsd)
1881                         AC_CHECK_HEADERS(bsd/string.h)
1882                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1883                         ])
1884                 ])
1885         AC_CHECK_FUNCS( strlcpy snprintf )
1886 fi
1887 ])dnl
1888 dnl ---------------------------------------------------------------------------
1889 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1890 dnl --------
1891 dnl Check if 'errno' is declared in <errno.h>
1892 AC_DEFUN([CF_ERRNO],
1893 [
1894 CF_CHECK_ERRNO(errno)
1895 ])dnl
1896 dnl ---------------------------------------------------------------------------
1897 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1898 dnl ---------------
1899 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1900 dnl math.h and builtin.h, only for ncurses
1901 AC_DEFUN([CF_ETIP_DEFINES],
1902 [
1903 AC_MSG_CHECKING(for special defines needed for etip.h)
1904 cf_save_CXXFLAGS="$CXXFLAGS"
1905 cf_result="none"
1906
1907 # etip.h includes ncurses.h which includes ncurses_dll.h
1908 # But ncurses_dll.h is generated - fix here.
1909 test -d include || mkdir include
1910 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1911
1912 for cf_math in "" MATH_H
1913 do
1914 for cf_excp in "" MATH_EXCEPTION
1915 do
1916         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1917         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1918         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1919 AC_TRY_COMPILE([
1920 #include <etip.h.in>
1921 ],[],[
1922         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1923         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1924         cf_result="$cf_math $cf_excp"
1925         break 2
1926 ],[])
1927 done
1928 done
1929 AC_MSG_RESULT($cf_result)
1930 CXXFLAGS="$cf_save_CXXFLAGS"
1931 ])
1932 dnl ---------------------------------------------------------------------------
1933 dnl CF_FIND_LINKAGE version: 21 updated: 2018/06/20 20:23:13
1934 dnl ---------------
1935 dnl Find a library (specifically the linkage used in the code fragment),
1936 dnl searching for it if it is not already in the library path.
1937 dnl See also CF_ADD_SEARCHPATH.
1938 dnl
1939 dnl Parameters (4-on are optional):
1940 dnl     $1 = headers for library entrypoint
1941 dnl     $2 = code fragment for library entrypoint
1942 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1943 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1944 dnl     $5 = action to perform if not successful
1945 dnl     $6 = module name, if not the same as the library name
1946 dnl     $7 = extra libraries
1947 dnl
1948 dnl Sets these variables:
1949 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1950 dnl     $cf_cv_header_path_$3 - include-directory if needed
1951 dnl     $cf_cv_library_path_$3 - library-directory if needed
1952 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1953 AC_DEFUN([CF_FIND_LINKAGE],[
1954
1955 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1956 # will be set on completion of the AC_TRY_LINK below.
1957 cf_cv_header_path_$3=
1958 cf_cv_library_path_$3=
1959
1960 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1961
1962 cf_save_LIBS="$LIBS"
1963
1964 AC_TRY_LINK([$1],[$2],[
1965         cf_cv_find_linkage_$3=yes
1966         cf_cv_header_path_$3=/usr/include
1967         cf_cv_library_path_$3=/usr/lib
1968 ],[
1969
1970 LIBS="-l$3 $7 $cf_save_LIBS"
1971
1972 AC_TRY_LINK([$1],[$2],[
1973         cf_cv_find_linkage_$3=yes
1974         cf_cv_header_path_$3=/usr/include
1975         cf_cv_library_path_$3=/usr/lib
1976         cf_cv_library_file_$3="-l$3"
1977 ],[
1978         cf_cv_find_linkage_$3=no
1979         LIBS="$cf_save_LIBS"
1980
1981         CF_VERBOSE(find linkage for $3 library)
1982         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1983
1984         cf_save_CPPFLAGS="$CPPFLAGS"
1985         cf_test_CPPFLAGS="$CPPFLAGS"
1986
1987         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1988         for cf_cv_header_path_$3 in $cf_search
1989         do
1990                 if test -d $cf_cv_header_path_$3 ; then
1991                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1992                         CPPFLAGS="$cf_save_CPPFLAGS"
1993                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
1994                         AC_TRY_COMPILE([$1],[$2],[
1995                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1996                                 cf_cv_find_linkage_$3=maybe
1997                                 cf_test_CPPFLAGS="$CPPFLAGS"
1998                                 break],[
1999                                 CPPFLAGS="$cf_save_CPPFLAGS"
2000                                 ])
2001                 fi
2002         done
2003
2004         if test "$cf_cv_find_linkage_$3" = maybe ; then
2005
2006                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
2007
2008                 cf_save_LIBS="$LIBS"
2009                 cf_save_LDFLAGS="$LDFLAGS"
2010
2011                 ifelse([$6],,,[
2012                 CPPFLAGS="$cf_test_CPPFLAGS"
2013                 LIBS="-l$3 $7 $cf_save_LIBS"
2014                 AC_TRY_LINK([$1],[$2],[
2015                         CF_VERBOSE(... found $3 library in system)
2016                         cf_cv_find_linkage_$3=yes])
2017                         CPPFLAGS="$cf_save_CPPFLAGS"
2018                         LIBS="$cf_save_LIBS"
2019                         ])
2020
2021                 if test "$cf_cv_find_linkage_$3" != yes ; then
2022                         CF_LIBRARY_PATH(cf_search,$3)
2023                         for cf_cv_library_path_$3 in $cf_search
2024                         do
2025                                 if test -d $cf_cv_library_path_$3 ; then
2026                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
2027                                         CPPFLAGS="$cf_test_CPPFLAGS"
2028                                         LIBS="-l$3 $7 $cf_save_LIBS"
2029                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
2030                                         AC_TRY_LINK([$1],[$2],[
2031                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
2032                                         cf_cv_find_linkage_$3=yes
2033                                         cf_cv_library_file_$3="-l$3"
2034                                         break],[
2035                                         CPPFLAGS="$cf_save_CPPFLAGS"
2036                                         LIBS="$cf_save_LIBS"
2037                                         LDFLAGS="$cf_save_LDFLAGS"
2038                                         ])
2039                                 fi
2040                         done
2041                         CPPFLAGS="$cf_save_CPPFLAGS"
2042                         LDFLAGS="$cf_save_LDFLAGS"
2043                 fi
2044
2045         else
2046                 cf_cv_find_linkage_$3=no
2047         fi
2048         ],$7)
2049 ])
2050
2051 LIBS="$cf_save_LIBS"
2052
2053 if test "$cf_cv_find_linkage_$3" = yes ; then
2054 ifelse([$4],,[
2055         CF_ADD_INCDIR($cf_cv_header_path_$3)
2056         CF_ADD_LIBDIR($cf_cv_library_path_$3)
2057         CF_ADD_LIB($3)
2058 ],[$4])
2059 else
2060 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
2061 fi
2062 ])dnl
2063 dnl ---------------------------------------------------------------------------
2064 dnl CF_FIND_SUB_INCDIR version: 2 updated: 2015/04/17 21:13:04
2065 dnl ------------------
2066 dnl Find an include-directory with the given leaf-name.  This is useful for
2067 dnl example with FreeBSD ports, which use this convention to distinguish
2068 dnl different versions of the same port.
2069 AC_DEFUN([CF_FIND_SUB_INCDIR],[
2070         CF_SUBDIR_PATH(cf_search,$1,include)
2071         for cf_item in $cf_search
2072         do
2073                 case $cf_item in
2074                 (*/$1)
2075                         CF_ADD_INCDIR($cf_item)
2076                         ;;
2077                 esac
2078         done
2079 ])dnl
2080 dnl ---------------------------------------------------------------------------
2081 dnl CF_FIND_SUB_LIBDIR version: 2 updated: 2015/04/17 21:13:04
2082 dnl ------------------
2083 dnl Find a library-directory with the given leaf-name.  This is useful for
2084 dnl example with FreeBSD ports, which use this convention to distinguish
2085 dnl different versions of the same port.
2086 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
2087         CF_SUBDIR_PATH(cf_search,$1,lib)
2088         for cf_item in $cf_search
2089         do
2090                 case $cf_item in
2091                 (*/$1)
2092                         CF_ADD_LIBDIR($cf_item)
2093                         ;;
2094                 esac
2095         done
2096 ])dnl
2097 dnl ---------------------------------------------------------------------------
2098 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
2099 dnl -----------------
2100 dnl make ADAFLAGS consistent with CFLAGS
2101 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
2102         AC_MSG_CHECKING(optimization options for ADAFLAGS)
2103         case "$CFLAGS" in
2104         (*-g*)
2105                 CF_ADD_ADAFLAGS(-g)
2106                 ;;
2107         esac
2108         case "$CFLAGS" in
2109         (*-O*)
2110                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
2111                 CF_ADD_ADAFLAGS($cf_O_flag)
2112                 ;;
2113         esac
2114         AC_MSG_RESULT($ADAFLAGS)
2115 ])dnl
2116 dnl ---------------------------------------------------------------------------
2117 dnl CF_FOPEN_BIN_R version: 1 updated: 2019/03/30 17:52:21
2118 dnl --------------
2119 dnl Check if fopen works when the "b" (binary) flag is added to the mode
2120 dnl parameter.  POSIX ignores the "b", which c89 specified.  Some very old
2121 dnl systems do not accept it.
2122 AC_DEFUN([CF_FOPEN_BIN_R],[
2123 AC_CACHE_CHECK(if fopen accepts explicit binary mode,cf_cv_fopen_bin_r,[
2124         AC_TRY_RUN([
2125 #include <stdio.h>
2126 int main(void) {
2127         FILE *fp = fopen("conftest.tmp", "wb");
2128         int rc = 0;
2129         if (fp != 0) {
2130                 int p, q;
2131                 for (p = 0; p < 256; ++p) {
2132                         fputc(p, fp);
2133                 }
2134                 fclose(fp);
2135                 fp = fopen("conftest.tmp", "rb");
2136                 if (fp != 0) {
2137                         for (p = 0; p < 256; ++p) {
2138                                 q = fgetc(fp);
2139                                 if (q != p) {
2140                                         rc = 1;
2141                                         break;
2142                                 }
2143                         }
2144                 } else {
2145                         rc = 1;
2146                 }
2147         } else {
2148                 rc = 1;
2149         }
2150         ${cf_cv_main_return:-return} (rc);
2151 }
2152 ],
2153                 [cf_cv_fopen_bin_r=yes],
2154                 [cf_cv_fopen_bin_r=no],
2155                 [cf_cv_fopen_bin_r=unknown])
2156 ])
2157 test "x$cf_cv_fopen_bin_r" != xno && AC_DEFINE(USE_FOPEN_BIN_R)
2158 ])dnl
2159 dnl ---------------------------------------------------------------------------
2160 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
2161 dnl --------------
2162 dnl Forget that we saw the given tool.
2163 AC_DEFUN([CF_FORGET_TOOL],[
2164 unset ac_cv_prog_ac_ct_$1
2165 unset ac_ct_$1
2166 unset $1
2167 ])dnl
2168 dnl ---------------------------------------------------------------------------
2169 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
2170 dnl -------------
2171 dnl Test for dlsym() and related functions, as well as libdl.
2172 dnl
2173 dnl Sets
2174 dnl     $cf_have_dlsym
2175 dnl     $cf_have_libdl
2176 AC_DEFUN([CF_FUNC_DLSYM],[
2177 cf_have_dlsym=no
2178 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
2179
2180 cf_have_libdl=no
2181 AC_CHECK_LIB(dl,dlsym,[
2182         cf_have_dlsym=yes
2183         cf_have_libdl=yes])])
2184
2185 if test "$cf_have_dlsym" = yes ; then
2186         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
2187
2188         AC_MSG_CHECKING(whether able to link to dl*() functions)
2189         AC_TRY_LINK([#include <dlfcn.h>],[
2190                 void *obj;
2191                 if ((obj = dlopen("filename", 0)) != 0) {
2192                         if (dlsym(obj, "symbolname") == 0) {
2193                         dlclose(obj);
2194                         }
2195                 }],[
2196                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
2197                 AC_MSG_ERROR(Cannot link test program for libdl)])
2198         AC_MSG_RESULT(ok)
2199 else
2200         AC_MSG_ERROR(Cannot find dlsym function)
2201 fi
2202 ])
2203 dnl ---------------------------------------------------------------------------
2204 dnl CF_FUNC_MEMMOVE version: 9 updated: 2017/01/21 11:06:25
2205 dnl ---------------
2206 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
2207 dnl is found, add our own version of memmove to the list of objects.
2208 AC_DEFUN([CF_FUNC_MEMMOVE],
2209 [
2210 AC_CHECK_FUNC(memmove,,[
2211 AC_CHECK_FUNC(bcopy,[
2212         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
2213                 AC_TRY_RUN([
2214 int main(void) {
2215         static char data[] = "abcdefghijklmnopqrstuwwxyz";
2216         char temp[40];
2217         bcopy(data, temp, sizeof(data));
2218         bcopy(temp+10, temp, 15);
2219         bcopy(temp+5, temp+15, 10);
2220         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
2221 }
2222                 ],
2223                 [cf_cv_good_bcopy=yes],
2224                 [cf_cv_good_bcopy=no],
2225                 [cf_cv_good_bcopy=unknown])
2226                 ])
2227         ],[cf_cv_good_bcopy=no])
2228         if test "$cf_cv_good_bcopy" = yes ; then
2229                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
2230         else
2231                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
2232         fi
2233 ])])dnl
2234 dnl ---------------------------------------------------------------------------
2235 dnl CF_FUNC_NANOSLEEP version: 5 updated: 2017/01/21 11:06:25
2236 dnl -----------------
2237 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
2238 dnl AIX 4.x, provide a non-working version.
2239 AC_DEFUN([CF_FUNC_NANOSLEEP],[
2240 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
2241 AC_TRY_RUN([
2242 #include <stdio.h>
2243 #include <errno.h>
2244 #include <time.h>
2245
2246 #ifdef HAVE_SYS_TIME_H
2247 #include <sys/time.h>
2248 #endif
2249
2250 int main(void) {
2251         struct timespec ts1, ts2;
2252         int code;
2253         ts1.tv_sec  = 0;
2254         ts1.tv_nsec = 750000000;
2255         ts2.tv_sec  = 0;
2256         ts2.tv_nsec = 0;
2257         errno = 0;
2258         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
2259         ${cf_cv_main_return:-return}(code != 0);
2260 }
2261 ],
2262         [cf_cv_func_nanosleep=yes],
2263         [cf_cv_func_nanosleep=no],
2264         [cf_cv_func_nanosleep=unknown])])
2265
2266 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
2267 ])
2268 dnl ---------------------------------------------------------------------------
2269 dnl CF_FUNC_OPENPTY version: 5 updated: 2015/09/12 14:46:50
2270 dnl ---------------
2271 dnl Check for openpty() function, along with <pty.h> header.  It may need the
2272 dnl "util" library as well.
2273 AC_DEFUN([CF_FUNC_OPENPTY],
2274 [
2275 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
2276 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
2277         cf_save_LIBS="$LIBS"
2278         test $cf_cv_lib_util = yes && { CF_ADD_LIB(util) }
2279         for cf_header in pty.h libutil.h util.h
2280         do
2281         AC_TRY_LINK([
2282 #include <$cf_header>
2283 ],[
2284         int x = openpty((int *)0, (int *)0, (char *)0,
2285                                    (struct termios *)0, (struct winsize *)0);
2286 ],[
2287                 cf_cv_func_openpty=$cf_header
2288                 break
2289 ],[
2290                 cf_cv_func_openpty=no
2291 ])
2292         done
2293         LIBS="$cf_save_LIBS"
2294 ])
2295 ])dnl
2296 dnl ---------------------------------------------------------------------------
2297 dnl CF_FUNC_POLL version: 9 updated: 2015/10/10 13:27:32
2298 dnl ------------
2299 dnl See if the poll function really works.  Some platforms have poll(), but
2300 dnl it does not work for terminals or files.
2301 AC_DEFUN([CF_FUNC_POLL],[
2302 tty 2>&1 >/dev/null || { AC_CHECK_FUNCS(posix_openpt) }
2303 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
2304 AC_TRY_RUN([
2305 #include <stdlib.h>
2306 #include <stdio.h>
2307 #include <unistd.h>
2308 #include <fcntl.h>
2309 #ifdef HAVE_POLL_H
2310 #include <poll.h>
2311 #else
2312 #include <sys/poll.h>
2313 #endif
2314 int main(void) {
2315         struct pollfd myfds;
2316         int ret;
2317
2318         /* check for Darwin bug with respect to "devices" */
2319         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
2320         if (myfds.fd < 0)
2321                 myfds.fd = 0;
2322         myfds.events = POLLIN;
2323         myfds.revents = 0;
2324
2325         ret = poll(&myfds, 1, 100);
2326
2327         if (ret < 0 || (myfds.revents & POLLNVAL)) {
2328                 ret = -1;
2329         } else {
2330                 int fd = 0;
2331                 if (!isatty(fd)) {
2332                         fd = open("/dev/tty", 2);       /* O_RDWR */
2333                 }
2334 #ifdef HAVE_POSIX_OPENPT
2335                 if (fd < 0) {
2336                         fd = posix_openpt(O_RDWR);
2337                 }
2338 #endif
2339
2340                 if (fd >= 0) {
2341                         /* also check with standard input */
2342                         myfds.fd = fd;
2343                         myfds.events = POLLIN;
2344                         myfds.revents = 0;
2345                         ret = poll(&myfds, 1, 100);
2346                 } else {
2347                         ret = -1;
2348                 }
2349         }
2350         ${cf_cv_main_return:-return}(ret < 0);
2351 }],
2352         [cf_cv_working_poll=yes],
2353         [cf_cv_working_poll=no],
2354         [cf_cv_working_poll=unknown])])
2355 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
2356 ])dnl
2357 dnl ---------------------------------------------------------------------------
2358 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
2359 dnl ---------------
2360 dnl Some old/broken variations define tcgetattr() only as a macro in
2361 dnl termio(s).h
2362 AC_DEFUN([CF_FUNC_TERMIOS],[
2363 AC_REQUIRE([CF_STRUCT_TERMIOS])
2364 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
2365 AC_TRY_LINK([
2366 #include <sys/types.h>
2367 #ifdef HAVE_UNISTD_H
2368 #include <unistd.h>
2369 #endif
2370 #ifdef HAVE_TERMIOS_H
2371 #include <termios.h>
2372 #define TTY struct termios
2373 #else
2374 #ifdef HAVE_TERMIO_H
2375 #include <termio.h>
2376 #define TTY struct termio
2377 #endif
2378 #endif
2379 ],[
2380 TTY foo;
2381 tcgetattr(1, &foo);],
2382 [cf_cv_have_tcgetattr=yes],
2383 [cf_cv_have_tcgetattr=no])])
2384 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
2385 ])dnl
2386 dnl ---------------------------------------------------------------------------
2387 dnl CF_FUNC_VSSCANF version: 6 updated: 2015/04/18 08:56:57
2388 dnl ---------------
2389 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
2390 dnl versions of C.  It is in the GNU C library, and can often be simulated by
2391 dnl other functions.
2392 AC_DEFUN([CF_FUNC_VSSCANF],
2393 [
2394 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
2395 AC_TRY_LINK([
2396 #include <stdarg.h>
2397 #include <stdio.h>],[
2398         va_list ap;
2399         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
2400 AC_TRY_LINK([
2401 #include <stdarg.h>
2402 #include <stdio.h>],[
2403         FILE strbuf;
2404         char *str = "from";
2405
2406         strbuf._flag = _IOREAD;
2407         strbuf._ptr = strbuf._base = (unsigned char *) str;
2408         strbuf._cnt = strlen(str);
2409         strbuf._file = _NFILE;
2410         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
2411 AC_TRY_LINK([
2412 #include <stdarg.h>
2413 #include <stdio.h>],[
2414         FILE strbuf;
2415         char *str = "from";
2416
2417         strbuf._flag = _IOREAD;
2418         strbuf._ptr = strbuf._base = (unsigned char *) str;
2419         strbuf._cnt = strlen(str);
2420         strbuf._file = _NFILE;
2421         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
2422 cf_cv_func_vsscanf=no])])])])
2423
2424 case $cf_cv_func_vsscanf in
2425 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
2426 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
2427 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
2428 esac
2429
2430 ])dnl
2431 dnl ---------------------------------------------------------------------------
2432 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
2433 dnl -----------------
2434 dnl Test for availability of useful gcc __attribute__ directives to quiet
2435 dnl compiler warnings.  Though useful, not all are supported -- and contrary
2436 dnl to documentation, unrecognized directives cause older compilers to barf.
2437 AC_DEFUN([CF_GCC_ATTRIBUTES],
2438 [
2439 if test "$GCC" = yes
2440 then
2441 cat > conftest.i <<EOF
2442 #ifndef GCC_PRINTF
2443 #define GCC_PRINTF 0
2444 #endif
2445 #ifndef GCC_SCANF
2446 #define GCC_SCANF 0
2447 #endif
2448 #ifndef GCC_NORETURN
2449 #define GCC_NORETURN /* nothing */
2450 #endif
2451 #ifndef GCC_UNUSED
2452 #define GCC_UNUSED /* nothing */
2453 #endif
2454 EOF
2455 if test "$GCC" = yes
2456 then
2457         AC_CHECKING([for $CC __attribute__ directives])
2458 cat > conftest.$ac_ext <<EOF
2459 #line __oline__ "${as_me:-configure}"
2460 #include "confdefs.h"
2461 #include "conftest.h"
2462 #include "conftest.i"
2463 #if     GCC_PRINTF
2464 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
2465 #else
2466 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
2467 #endif
2468 #if     GCC_SCANF
2469 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2470 #else
2471 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2472 #endif
2473 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2474 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
2475 extern void foo(void) GCC_NORETURN;
2476 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
2477 EOF
2478         cf_printf_attribute=no
2479         cf_scanf_attribute=no
2480         for cf_attribute in scanf printf unused noreturn
2481         do
2482                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2483                 cf_directive="__attribute__(($cf_attribute))"
2484                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2485
2486                 case $cf_attribute in
2487                 (printf)
2488                         cf_printf_attribute=yes
2489                         cat >conftest.h <<EOF
2490 #define GCC_$cf_ATTRIBUTE 1
2491 EOF
2492                         ;;
2493                 (scanf)
2494                         cf_scanf_attribute=yes
2495                         cat >conftest.h <<EOF
2496 #define GCC_$cf_ATTRIBUTE 1
2497 EOF
2498                         ;;
2499                 (*)
2500                         cat >conftest.h <<EOF
2501 #define GCC_$cf_ATTRIBUTE $cf_directive
2502 EOF
2503                         ;;
2504                 esac
2505
2506                 if AC_TRY_EVAL(ac_compile); then
2507                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
2508                         cat conftest.h >>confdefs.h
2509                         case $cf_attribute in
2510                         (noreturn)
2511                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
2512                                 ;;
2513                         (printf)
2514                                 cf_value='/* nothing */'
2515                                 if test "$cf_printf_attribute" != no ; then
2516                                         cf_value='__attribute__((format(printf,fmt,var)))'
2517                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
2518                                 fi
2519                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
2520                                 ;;
2521                         (scanf)
2522                                 cf_value='/* nothing */'
2523                                 if test "$cf_scanf_attribute" != no ; then
2524                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2525                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2526                                 fi
2527                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2528                                 ;;
2529                         (unused)
2530                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2531                                 ;;
2532                         esac
2533                 fi
2534         done
2535 else
2536         fgrep define conftest.i >>confdefs.h
2537 fi
2538 rm -rf conftest*
2539 fi
2540 ])dnl
2541 dnl ---------------------------------------------------------------------------
2542 dnl CF_GCC_VERSION version: 8 updated: 2019/09/07 13:38:36
2543 dnl --------------
2544 dnl Find version of gcc, and (because icc/clang pretend to be gcc without being
2545 dnl compatible), attempt to determine if icc/clang is actually used.
2546 AC_DEFUN([CF_GCC_VERSION],[
2547 AC_REQUIRE([AC_PROG_CC])
2548 GCC_VERSION=none
2549 if test "$GCC" = yes ; then
2550         AC_MSG_CHECKING(version of $CC)
2551         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2552         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2553         AC_MSG_RESULT($GCC_VERSION)
2554 fi
2555 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2556 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2557 ])dnl
2558 dnl ---------------------------------------------------------------------------
2559 dnl CF_GCC_WARNINGS version: 36 updated: 2019/09/07 13:38:36
2560 dnl ---------------
2561 dnl Check if the compiler supports useful warning options.  There's a few that
2562 dnl we don't use, simply because they're too noisy:
2563 dnl
2564 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2565 dnl     -Wredundant-decls (system headers make this too noisy)
2566 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2567 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2568 dnl             is enabled for ncurses using "--enable-const".
2569 dnl     -pedantic
2570 dnl
2571 dnl Parameter:
2572 dnl     $1 is an optional list of gcc warning flags that a particular
2573 dnl             application might want to use, e.g., "no-unused" for
2574 dnl             -Wno-unused
2575 dnl Special:
2576 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2577 dnl
2578 AC_DEFUN([CF_GCC_WARNINGS],
2579 [
2580 AC_REQUIRE([CF_GCC_VERSION])
2581 if test "x$have_x" = xyes; then CF_CONST_X_STRING fi
2582 cat > conftest.$ac_ext <<EOF
2583 #line __oline__ "${as_me:-configure}"
2584 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2585 EOF
2586 if test "$INTEL_COMPILER" = yes
2587 then
2588 # The "-wdXXX" options suppress warnings:
2589 # remark #1419: external declaration in primary source file
2590 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2591 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2592 # remark #193: zero used for undefined preprocessing identifier
2593 # remark #593: variable "curs_sb_left_arrow" was set but never used
2594 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2595 # remark #869: parameter "tw" was never referenced
2596 # remark #981: operands are evaluated in unspecified order
2597 # warning #279: controlling expression is constant
2598
2599         AC_CHECKING([for $CC warning options])
2600         cf_save_CFLAGS="$CFLAGS"
2601         EXTRA_CFLAGS="-Wall"
2602         for cf_opt in \
2603                 wd1419 \
2604                 wd1683 \
2605                 wd1684 \
2606                 wd193 \
2607                 wd593 \
2608                 wd279 \
2609                 wd810 \
2610                 wd869 \
2611                 wd981
2612         do
2613                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2614                 if AC_TRY_EVAL(ac_compile); then
2615                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2616                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2617                 fi
2618         done
2619         CFLAGS="$cf_save_CFLAGS"
2620 elif test "$GCC" = yes
2621 then
2622         AC_CHECKING([for $CC warning options])
2623         cf_save_CFLAGS="$CFLAGS"
2624         EXTRA_CFLAGS=
2625         cf_warn_CONST=""
2626         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2627         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2628         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2629         for cf_opt in W Wall \
2630                 Wbad-function-cast \
2631                 Wcast-align \
2632                 Wcast-qual \
2633                 Wdeclaration-after-statement \
2634                 Wextra \
2635                 Winline \
2636                 Wmissing-declarations \
2637                 Wmissing-prototypes \
2638                 Wnested-externs \
2639                 Wpointer-arith \
2640                 Wshadow \
2641                 Wstrict-prototypes \
2642                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
2643         do
2644                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2645                 if AC_TRY_EVAL(ac_compile); then
2646                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2647                         case $cf_opt in
2648                         (Winline)
2649                                 case $GCC_VERSION in
2650                                 ([[34]].*)
2651                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2652                                         continue;;
2653                                 esac
2654                                 ;;
2655                         (Wpointer-arith)
2656                                 case $GCC_VERSION in
2657                                 ([[12]].*)
2658                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2659                                         continue;;
2660                                 esac
2661                                 ;;
2662                         esac
2663                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2664                 fi
2665         done
2666         CFLAGS="$cf_save_CFLAGS"
2667 fi
2668 rm -rf conftest*
2669
2670 AC_SUBST(EXTRA_CFLAGS)
2671 ])dnl
2672 dnl ---------------------------------------------------------------------------
2673 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
2674 dnl ----------------
2675 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2676 dnl unistd.h or (nonstandard) in getopt.h
2677 AC_DEFUN([CF_GETOPT_HEADER],
2678 [
2679 AC_HAVE_HEADERS(unistd.h getopt.h)
2680 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2681 cf_cv_getopt_header=none
2682 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2683 do
2684 AC_TRY_COMPILE([
2685 #include <$cf_header>],
2686 [int x = optind; char *y = optarg],
2687 [cf_cv_getopt_header=$cf_header
2688  break])
2689 done
2690 ])
2691 if test $cf_cv_getopt_header != none ; then
2692         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2693 fi
2694 if test $cf_cv_getopt_header = getopt.h ; then
2695         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2696 fi
2697 ])dnl
2698 dnl ---------------------------------------------------------------------------
2699 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2700 dnl -----------------
2701 AC_DEFUN([CF_GNATPREP_OPT_T],[
2702 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2703 cf_cv_gnatprep_opt_t=no
2704 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2705 ])
2706 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
2707 AC_SUBST(GNATPREP_OPTS)
2708 ])dnl
2709 dnl ---------------------------------------------------------------------------
2710 dnl CF_GNAT_GENERICS version: 3 updated: 2015/04/17 21:13:04
2711 dnl ----------------
2712 AC_DEFUN([CF_GNAT_GENERICS],
2713 [
2714 AC_REQUIRE([CF_GNAT_VERSION])
2715
2716 AC_MSG_CHECKING(if GNAT supports generics)
2717 case $cf_gnat_version in
2718 (3.[[1-9]]*|[[4-9]].*)
2719         cf_gnat_generics=yes
2720         ;;
2721 (*)
2722         cf_gnat_generics=no
2723         ;;
2724 esac
2725 AC_MSG_RESULT($cf_gnat_generics)
2726
2727 if test "$cf_gnat_generics" = yes
2728 then
2729         cf_compile_generics=generics
2730         cf_generic_objects="\${GENOBJS}"
2731 else
2732         cf_compile_generics=
2733         cf_generic_objects=
2734 fi
2735
2736 AC_SUBST(cf_compile_generics)
2737 AC_SUBST(cf_generic_objects)
2738 ])dnl
2739 dnl ---------------------------------------------------------------------------
2740 dnl CF_GNAT_PROJECTS version: 9 updated: 2018/01/14 15:46:09
2741 dnl ----------------
2742 dnl GNAT projects are configured with ".gpr" project files.
2743 dnl GNAT libraries are a further development, using the project feature.
2744 AC_DEFUN([CF_GNAT_PROJECTS],
2745 [
2746 AC_REQUIRE([CF_GNAT_VERSION])
2747 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
2748
2749 cf_gnat_libraries=no
2750 cf_gnat_projects=no
2751
2752 if test "$enable_gnat_projects" != no ; then
2753 AC_MSG_CHECKING(if GNAT supports project files)
2754 case $cf_gnat_version in
2755 (3.[[0-9]]*)
2756         ;;
2757 (*)
2758         case $cf_cv_system_name in
2759         (cygwin*|msys*)
2760                 ;;
2761         (*)
2762                 rm -rf conftest* *~conftest*
2763                 if mkdir conftest.src conftest.bin conftest.lib
2764                 then
2765                         cd conftest.src
2766                         rm -rf conftest* *~conftest*
2767                         cat >>library.gpr <<CF_EOF
2768 project Library is
2769   Kind := External ("LIB_KIND");
2770   for Library_Name use "ConfTest";
2771   for Object_Dir use ".";
2772   for Library_ALI_Dir use External("LIBRARY_DIR");
2773   for Library_Version use External ("SONAME");
2774   for Library_Kind use Kind;
2775   for Library_Dir use External("BUILD_DIR");
2776   Source_Dir := External ("SOURCE_DIR");
2777   for Source_Dirs use (Source_Dir);
2778 end Library;
2779 CF_EOF
2780                         cat >>confpackage.ads <<CF_EOF
2781 package ConfPackage is
2782    procedure conftest;
2783 end ConfPackage;
2784 CF_EOF
2785                         cat >>confpackage.adb <<CF_EOF
2786 with Text_IO;
2787 package body ConfPackage is
2788    procedure conftest is
2789    begin
2790       Text_IO.Put ("Hello World");
2791       Text_IO.New_Line;
2792    end conftest;
2793 end ConfPackage;
2794 CF_EOF
2795                         if ( $cf_ada_make $ADAFLAGS \
2796                                         -Plibrary.gpr \
2797                                         -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2798                                         -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2799                                         -XSOURCE_DIR=`pwd` \
2800                                         -XSONAME=libConfTest.so.1 \
2801                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2802                                 cf_gnat_projects=yes
2803                         fi
2804                         cd ..
2805                 fi
2806                 if test -f conftest.lib/confpackage.ali
2807                 then
2808                         cf_gnat_libraries=yes
2809                 fi
2810                 rm -rf conftest* *~conftest*
2811                 ;;
2812         esac
2813         ;;
2814 esac
2815 AC_MSG_RESULT($cf_gnat_projects)
2816 fi # enable_gnat_projects
2817
2818 if test $cf_gnat_projects = yes
2819 then
2820         AC_MSG_CHECKING(if GNAT supports libraries)
2821         AC_MSG_RESULT($cf_gnat_libraries)
2822 fi
2823
2824 if test "$cf_gnat_projects" = yes
2825 then
2826         USE_OLD_MAKERULES="#"
2827         USE_GNAT_PROJECTS=""
2828 else
2829         USE_OLD_MAKERULES=""
2830         USE_GNAT_PROJECTS="#"
2831 fi
2832
2833 if test "$cf_gnat_libraries" = yes
2834 then
2835         USE_GNAT_LIBRARIES=""
2836 else
2837         USE_GNAT_LIBRARIES="#"
2838 fi
2839
2840 AC_SUBST(USE_OLD_MAKERULES)
2841 AC_SUBST(USE_GNAT_PROJECTS)
2842 AC_SUBST(USE_GNAT_LIBRARIES)
2843 ])dnl
2844 dnl ---------------------------------------------------------------------------
2845 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2846 dnl --------------
2847 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2848 dnl is noted that gnat may compile a tasking unit even for configurations which
2849 dnl fail at runtime.
2850 AC_DEFUN([CF_GNAT_SIGINT],[
2851 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2852 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2853
2854 package ConfTest is
2855
2856    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2857    pragma Unreserve_All_Interrupts;
2858    pragma Warnings (On);
2859
2860    protected Process is
2861       procedure Stop;
2862       function Continue return Boolean;
2863       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2864    private
2865       Done : Boolean := False;
2866    end Process;
2867
2868 end ConfTest;],
2869 [package body ConfTest is
2870    protected body Process is
2871       procedure Stop is
2872       begin
2873          Done := True;
2874       end Stop;
2875       function Continue return Boolean is
2876       begin
2877          return not Done;
2878       end Continue;
2879    end Process;
2880 end ConfTest;],
2881         [cf_cv_gnat_sigint=yes],
2882         [cf_cv_gnat_sigint=no])])
2883
2884 if test $cf_cv_gnat_sigint = yes ; then
2885         USE_GNAT_SIGINT=""
2886 else
2887         USE_GNAT_SIGINT="#"
2888 fi
2889 AC_SUBST(USE_GNAT_SIGINT)
2890 ])dnl
2891 dnl ---------------------------------------------------------------------------
2892 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2893 dnl ----------------
2894 dnl Verify that a test program compiles/links with GNAT.
2895 dnl $cf_ada_make is set to the program that compiles/links
2896 dnl $ADAFLAGS may be set to the GNAT flags.
2897 dnl
2898 dnl $1 is the text of the spec
2899 dnl $2 is the text of the body
2900 dnl $3 is the shell command to execute if successful
2901 dnl $4 is the shell command to execute if not successful
2902 AC_DEFUN([CF_GNAT_TRY_LINK],
2903 [
2904 rm -rf conftest* *~conftest*
2905 cat >>conftest.ads <<CF_EOF
2906 $1
2907 CF_EOF
2908 cat >>conftest.adb <<CF_EOF
2909 $2
2910 CF_EOF
2911 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2912 ifelse($3,,      :,[      $3])
2913 ifelse($4,,,[else
2914    $4])
2915 fi
2916 rm -rf conftest* *~conftest*
2917 ])dnl
2918 dnl ---------------------------------------------------------------------------
2919 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2920 dnl ---------------
2921 dnl Verify that a test program compiles and runs with GNAT
2922 dnl $cf_ada_make is set to the program that compiles/links
2923 dnl $ADAFLAGS may be set to the GNAT flags.
2924 dnl
2925 dnl $1 is the text of the spec
2926 dnl $2 is the text of the body
2927 dnl $3 is the shell command to execute if successful
2928 dnl $4 is the shell command to execute if not successful
2929 AC_DEFUN([CF_GNAT_TRY_RUN],
2930 [
2931 rm -rf conftest* *~conftest*
2932 cat >>conftest.ads <<CF_EOF
2933 $1
2934 CF_EOF
2935 cat >>conftest.adb <<CF_EOF
2936 $2
2937 CF_EOF
2938 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2939    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2940 ifelse($3,,      :,[      $3])
2941 ifelse($4,,,[   else
2942       $4])
2943    fi
2944 ifelse($4,,,[else
2945    $4])
2946 fi
2947 rm -rf conftest* *~conftest*
2948 ])dnl
2949 dnl ---------------------------------------------------------------------------
2950 dnl CF_GNAT_VERSION version: 20 updated: 2015/04/18 08:56:57
2951 dnl ---------------
2952 dnl Verify version of GNAT.
2953 AC_DEFUN([CF_GNAT_VERSION],
2954 [
2955 AC_MSG_CHECKING(for gnat version)
2956 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2957         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2958         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2959 AC_MSG_RESULT($cf_gnat_version)
2960
2961 case $cf_gnat_version in
2962 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
2963         cf_cv_prog_gnat_correct=yes
2964         ;;
2965 (*)
2966         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2967         cf_cv_prog_gnat_correct=no
2968         ;;
2969 esac
2970 ])
2971 dnl ---------------------------------------------------------------------------
2972 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
2973 dnl -------------
2974 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2975 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2976 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2977 dnl since it is interwoven with GNU extensions.
2978 dnl
2979 dnl Well, yes we could work around it...
2980 dnl
2981 dnl Parameters:
2982 dnl     $1 is the nominal value for _XOPEN_SOURCE
2983 AC_DEFUN([CF_GNU_SOURCE],
2984 [
2985 cf_gnu_xopen_source=ifelse($1,,500,$1)
2986
2987 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
2988 AC_TRY_COMPILE([#include <sys/types.h>],[
2989         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
2990                 return 0;
2991         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
2992                 return 0;
2993         #else
2994         #       error not GNU C library
2995         #endif],
2996         [cf_cv_gnu_library=yes],
2997         [cf_cv_gnu_library=no])
2998 ])
2999
3000 if test x$cf_cv_gnu_library = xyes; then
3001
3002         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
3003         # was changed to help a little.  newlib incorporated the change about 4
3004         # years later.
3005         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
3006                 cf_save="$CPPFLAGS"
3007                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3008                 AC_TRY_COMPILE([#include <sys/types.h>],[
3009                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
3010                                 return 0;
3011                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
3012                                 return 0;
3013                         #else
3014                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
3015                         #endif],
3016                         [cf_cv_gnu_library_219=yes],
3017                         [cf_cv_gnu_library_219=no])
3018                 CPPFLAGS="$cf_save"
3019         ])
3020
3021         if test "x$cf_cv_gnu_library_219" = xyes; then
3022                 cf_save="$CPPFLAGS"
3023                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
3024                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
3025                         AC_TRY_COMPILE([
3026                                 #include <limits.h>
3027                                 #include <sys/types.h>
3028                                 ],[
3029                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
3030                                         return 0;
3031                                 #else
3032                                 #       error GNU C library is too old
3033                                 #endif],
3034                                 [cf_cv_gnu_dftsrc_219=yes],
3035                                 [cf_cv_gnu_dftsrc_219=no])
3036                         ])
3037                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
3038         else
3039                 cf_cv_gnu_dftsrc_219=maybe
3040         fi
3041
3042         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
3043
3044                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
3045                 AC_TRY_COMPILE([#include <sys/types.h>],[
3046                         #ifndef _XOPEN_SOURCE
3047                         #error  expected _XOPEN_SOURCE to be defined
3048                         #endif],
3049                         [cf_cv_gnu_source=no],
3050                         [cf_save="$CPPFLAGS"
3051                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
3052                          AC_TRY_COMPILE([#include <sys/types.h>],[
3053                                 #ifdef _XOPEN_SOURCE
3054                                 #error  expected _XOPEN_SOURCE to be undefined
3055                                 #endif],
3056                                 [cf_cv_gnu_source=no],
3057                                 [cf_cv_gnu_source=yes])
3058                         CPPFLAGS="$cf_save"
3059                         ])
3060                 ])
3061
3062                 if test "$cf_cv_gnu_source" = yes
3063                 then
3064                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
3065                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
3066                         AC_TRY_COMPILE([#include <sys/types.h>],[
3067                                 #ifdef _DEFAULT_SOURCE
3068                                 #error  expected _DEFAULT_SOURCE to be undefined
3069                                 #endif],
3070                                 [cf_cv_default_source=no],
3071                                 [cf_cv_default_source=yes])
3072                         ])
3073                         if test "$cf_cv_default_source" = yes
3074                         then
3075                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3076                         fi
3077                 fi
3078         fi
3079
3080 fi
3081 ])dnl
3082 dnl ---------------------------------------------------------------------------
3083 dnl CF_GPP_LIBRARY version: 12 updated: 2015/04/17 21:13:04
3084 dnl --------------
3085 dnl If we're trying to use g++, test if libg++ is installed (a rather common
3086 dnl problem :-).  If we have the compiler but no library, we'll be able to
3087 dnl configure, but won't be able to build the c++ demo program.
3088 AC_DEFUN([CF_GPP_LIBRARY],
3089 [
3090 cf_cxx_library=unknown
3091 case $cf_cv_system_name in
3092 (os2*)
3093         cf_gpp_libname=gpp
3094         ;;
3095 (*)
3096         cf_gpp_libname=g++
3097         ;;
3098 esac
3099 if test "$GXX" = yes; then
3100         AC_MSG_CHECKING([for lib$cf_gpp_libname])
3101         cf_save="$LIBS"
3102         CF_ADD_LIB($cf_gpp_libname)
3103         AC_TRY_LINK([
3104 #include <$cf_gpp_libname/builtin.h>
3105         ],
3106         [two_arg_error_handler_t foo2 = lib_error_handler],
3107         [cf_cxx_library=yes
3108          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3109          if test "$cf_gpp_libname" = cpp ; then
3110             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
3111          else
3112             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
3113          fi],
3114         [AC_TRY_LINK([
3115 #include <builtin.h>
3116         ],
3117         [two_arg_error_handler_t foo2 = lib_error_handler],
3118         [cf_cxx_library=yes
3119          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3120          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
3121         [cf_cxx_library=no])])
3122         LIBS="$cf_save"
3123         AC_MSG_RESULT($cf_cxx_library)
3124 fi
3125 ])dnl
3126 dnl ---------------------------------------------------------------------------
3127 dnl CF_GXX_VERSION version: 8 updated: 2017/02/11 14:48:57
3128 dnl --------------
3129 dnl Check for version of g++
3130 AC_DEFUN([CF_GXX_VERSION],[
3131 AC_REQUIRE([AC_PROG_CPP])
3132 GXX_VERSION=none
3133 if test "$GXX" = yes; then
3134         AC_MSG_CHECKING(version of ${CXX:-g++})
3135         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
3136         if test -z "$GXX_VERSION"
3137         then
3138                 GXX_VERSION=unknown
3139                 GXX=no
3140         fi
3141         AC_MSG_RESULT($GXX_VERSION)
3142 fi
3143 ])dnl
3144 dnl ---------------------------------------------------------------------------
3145 dnl CF_GXX_WARNINGS version: 9 updated: 2015/04/17 21:13:04
3146 dnl ---------------
3147 dnl Check if the compiler supports useful warning options.
3148 dnl
3149 dnl Most of gcc's options apply to g++, except:
3150 dnl     -Wbad-function-cast
3151 dnl     -Wmissing-declarations
3152 dnl     -Wnested-externs
3153 dnl
3154 dnl Omit a few (for now):
3155 dnl     -Winline
3156 dnl
3157 dnl Parameter:
3158 dnl     $1 is an optional list of g++ warning flags that a particular
3159 dnl             application might want to use, e.g., "no-unused" for
3160 dnl             -Wno-unused
3161 dnl Special:
3162 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
3163 dnl
3164 AC_DEFUN([CF_GXX_WARNINGS],
3165 [
3166
3167 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
3168 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
3169
3170 AC_REQUIRE([CF_GXX_VERSION])
3171
3172 AC_LANG_SAVE
3173 AC_LANG_CPLUSPLUS
3174
3175 cat > conftest.$ac_ext <<EOF
3176 #line __oline__ "configure"
3177 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
3178 EOF
3179
3180 if test "$INTEL_CPLUSPLUS" = yes
3181 then
3182 # The "-wdXXX" options suppress warnings:
3183 # remark #1419: external declaration in primary source file
3184 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3185 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3186 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
3187 # remark #193: zero used for undefined preprocessing identifier
3188 # remark #593: variable "curs_sb_left_arrow" was set but never used
3189 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
3190 # remark #869: parameter "tw" was never referenced
3191 # remark #981: operands are evaluated in unspecified order
3192 # warning #269: invalid format string conversion
3193
3194         AC_CHECKING([for $CC warning options])
3195         cf_save_CXXFLAGS="$CXXFLAGS"
3196         EXTRA_CXXFLAGS="-Wall"
3197         for cf_opt in \
3198                 wd1419 \
3199                 wd1682 \
3200                 wd1683 \
3201                 wd1684 \
3202                 wd193 \
3203                 wd279 \
3204                 wd593 \
3205                 wd810 \
3206                 wd869 \
3207                 wd981
3208         do
3209                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
3210                 if AC_TRY_EVAL(ac_compile); then
3211                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3212                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3213                 fi
3214         done
3215         CXXFLAGS="$cf_save_CXXFLAGS"
3216
3217 elif test "$GXX" = yes
3218 then
3219         AC_CHECKING([for $CXX warning options])
3220         cf_save_CXXFLAGS="$CXXFLAGS"
3221         EXTRA_CXXFLAGS="-W -Wall"
3222         cf_gxx_extra_warnings=""
3223         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
3224         case "$GCC_VERSION" in
3225         ([[1-2]].*)
3226                 ;;
3227         (*)
3228                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
3229                 ;;
3230         esac
3231         for cf_opt in \
3232                 Wabi \
3233                 fabi-version=0 \
3234                 Wextra \
3235                 Wignored-qualifiers \
3236                 Wlogical-op \
3237                 Woverloaded-virtual \
3238                 Wsign-promo \
3239                 Wsynth \
3240                 Wold-style-cast \
3241                 Wcast-align \
3242                 Wcast-qual \
3243                 Wpointer-arith \
3244                 Wshadow \
3245                 Wundef $cf_gxx_extra_warnings $1
3246         do
3247                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
3248                 if AC_TRY_EVAL(ac_compile); then
3249                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3250                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3251                 else
3252                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
3253                 fi
3254         done
3255         CXXFLAGS="$cf_save_CXXFLAGS"
3256 fi
3257
3258 rm -rf conftest*
3259 AC_LANG_RESTORE
3260 AC_SUBST(EXTRA_CXXFLAGS)
3261 ])dnl
3262 dnl ---------------------------------------------------------------------------
3263 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
3264 dnl ------------
3265 dnl Look for an instance of the Berkeley hashed database.
3266 dnl
3267 dnl $1 = optional parameter, to specify install-prefix for the database.
3268 AC_DEFUN([CF_HASHED_DB],
3269 [
3270 ifelse([$1],,,[
3271 case $1 in
3272 (yes|*able*)
3273         ;;
3274 (*)
3275         if test -d "$1" ; then
3276                 CF_ADD_INCDIR($1/include)
3277                 CF_ADD_LIBDIR($1/lib)
3278         else
3279                 case "$1" in
3280                 (./*|../*|/*)
3281                         AC_MSG_WARN(no such directory $1)
3282                         ;;
3283                 (*)
3284                         CF_FIND_SUB_INCDIR($1)
3285                         CF_FIND_SUB_LIBDIR($1)
3286                         ;;
3287                 esac
3288         fi
3289 esac
3290 ])
3291 AC_CHECK_HEADER(db.h,[
3292 CF_HASHED_DB_VERSION
3293 if test "$cf_cv_hashed_db_version" = unknown ; then
3294         AC_MSG_ERROR(Cannot determine version of db)
3295 else
3296         CF_HASHED_DB_LIBS
3297         if test "$cf_cv_hashed_db_libs" = unknown ; then
3298                 AC_MSG_ERROR(Cannot determine library for db)
3299         elif test "$cf_cv_hashed_db_libs" != default ; then
3300                 CF_ADD_LIB($cf_cv_hashed_db_libs)
3301         fi
3302 fi
3303 ],[
3304         AC_MSG_ERROR(Cannot find db.h)
3305 ])
3306 ])dnl
3307 dnl ---------------------------------------------------------------------------
3308 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
3309 dnl -----------------
3310 dnl Given that we have the header and version for hashed database, find the
3311 dnl library information.
3312 AC_DEFUN([CF_HASHED_DB_LIBS],
3313 [
3314 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
3315 cf_cv_hashed_db_libs=unknown
3316 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
3317 do
3318         cf_save_libs="$LIBS"
3319         if test -n "$cf_db_libs"; then
3320                 CF_ADD_LIB($cf_db_libs)
3321         fi
3322         CF_MSG_LOG(checking for library "$cf_db_libs")
3323         AC_TRY_LINK([
3324 $ac_includes_default
3325 #include <db.h>
3326 ],[
3327         char *path = "/tmp/foo";
3328 #ifdef DB_VERSION_MAJOR
3329 #if DB_VERSION_MAJOR >= 4
3330         DB *result = 0;
3331         db_create(&result, NULL, 0);
3332         result->open(result,
3333                 NULL,
3334                 path,
3335                 path,
3336                 DB_HASH,
3337                 DB_CREATE,
3338                 0644);
3339 #elif DB_VERSION_MAJOR >= 3
3340         DB *result = 0;
3341         db_create(&result, NULL, 0);
3342         result->open(result,
3343                 path,
3344                 path,
3345                 DB_HASH,
3346                 DB_CREATE,
3347                 0644);
3348 #elif DB_VERSION_MAJOR >= 2
3349         DB *result = 0;
3350         db_open(path,
3351                 DB_HASH,
3352                 DB_CREATE,
3353                 0644,
3354                 (DB_ENV *) 0,
3355                 (DB_INFO *) 0,
3356                 &result);
3357 #endif /* DB_VERSION_MAJOR */
3358 #else
3359         DB *result = dbopen(path,
3360                      2,
3361                      0644,
3362                      DB_HASH,
3363                      0);
3364 #endif
3365         ${cf_cv_main_return:-return}(result != 0)
3366 ],[
3367         if test -n "$cf_db_libs" ; then
3368                 cf_cv_hashed_db_libs=$cf_db_libs
3369         else
3370                 cf_cv_hashed_db_libs=default
3371         fi
3372         LIBS="$cf_save_libs"
3373         break
3374 ])
3375         LIBS="$cf_save_libs"
3376 done
3377 ])
3378 ])dnl
3379 dnl ---------------------------------------------------------------------------
3380 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
3381 dnl --------------------
3382 dnl Given that we have the header file for hashed database, find the version
3383 dnl information.
3384 AC_DEFUN([CF_HASHED_DB_VERSION],
3385 [
3386 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
3387 cf_cv_hashed_db_version=unknown
3388
3389 for cf_db_version in 1 2 3 4 5 6
3390 do
3391         CF_MSG_LOG(checking for db version $cf_db_version)
3392         AC_TRY_COMPILE([
3393 $ac_includes_default
3394 #include <db.h>
3395
3396 #ifdef DB_VERSION_MAJOR
3397         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
3398 #if $cf_db_version == DB_VERSION_MAJOR
3399         /* ok */
3400 #else
3401         make an error
3402 #endif
3403 #else
3404 #if $cf_db_version == 1
3405         /* ok: assuming this is DB 1.8.5 */
3406 #else
3407         make an error
3408 #endif
3409 #endif
3410 ],[DBT *foo = 0],[
3411         cf_cv_hashed_db_version=$cf_db_version
3412         break
3413         ])
3414 done
3415 ])
3416 ])dnl
3417 dnl ---------------------------------------------------------------------------
3418 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
3419 dnl --------------
3420 dnl Construct a search-list of directories for a nonstandard header-file
3421 dnl
3422 dnl Parameters
3423 dnl     $1 = the variable to return as result
3424 dnl     $2 = the package name
3425 AC_DEFUN([CF_HEADER_PATH],
3426 [
3427 $1=
3428
3429 # collect the current set of include-directories from compiler flags
3430 cf_header_path_list=""
3431 if test -n "${CFLAGS}${CPPFLAGS}" ; then
3432         for cf_header_path in $CPPFLAGS $CFLAGS
3433         do
3434                 case $cf_header_path in
3435                 (-I*)
3436                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
3437                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
3438                         cf_header_path_list="$cf_header_path_list [$]$1"
3439                         ;;
3440                 esac
3441         done
3442 fi
3443
3444 # add the variations for the package we are looking for
3445 CF_SUBDIR_PATH($1,$2,include)
3446
3447 test "$includedir" != NONE && \
3448 test "$includedir" != "/usr/include" && \
3449 test -d "$includedir" && {
3450         test -d $includedir &&    $1="[$]$1 $includedir"
3451         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
3452 }
3453
3454 test "$oldincludedir" != NONE && \
3455 test "$oldincludedir" != "/usr/include" && \
3456 test -d "$oldincludedir" && {
3457         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
3458         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
3459 }
3460
3461 $1="[$]$1 $cf_header_path_list"
3462 ])dnl
3463 dnl ---------------------------------------------------------------------------
3464 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
3465 dnl ---------------
3466 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
3467 AC_DEFUN([CF_HELP_MESSAGE],
3468 [AC_DIVERT_HELP([$1])dnl
3469 ])dnl
3470 dnl ---------------------------------------------------------------------------
3471 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
3472 dnl ---------------
3473 dnl Construct the list of include-options according to whether we're building
3474 dnl in the source directory or using '--srcdir=DIR' option.
3475 AC_DEFUN([CF_INCLUDE_DIRS],
3476 [
3477 if test "$srcdir" != "."; then
3478         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
3479 fi
3480 CPPFLAGS="-I../include $CPPFLAGS"
3481 if test "$srcdir" != "."; then
3482         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
3483 fi
3484 CPPFLAGS="-I. $CPPFLAGS"
3485 AC_SUBST(CPPFLAGS)
3486 ])dnl
3487 dnl ---------------------------------------------------------------------------
3488 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
3489 dnl ---------------
3490 dnl prompt for/fill-in useful install-program options
3491 AC_DEFUN([CF_INSTALL_OPTS],
3492 [
3493 CF_INSTALL_OPT_S
3494 CF_INSTALL_OPT_P
3495 CF_INSTALL_OPT_O
3496 ])dnl
3497 dnl ---------------------------------------------------------------------------
3498 dnl CF_INSTALL_OPT_O version: 2 updated: 2015/05/15 19:45:35
3499 dnl ----------------
3500 dnl Almost all "install" programs default to the current user's ownership.
3501 dnl Almost - MINIX is an exception.
3502 AC_DEFUN([CF_INSTALL_OPT_O],
3503 [
3504 AC_MSG_CHECKING(if install needs to be told about ownership)
3505 case `$ac_config_guess` in
3506 (*minix)
3507         with_install_o=yes
3508         ;;
3509 (*)
3510         with_install_o=no
3511         ;;
3512 esac
3513
3514 AC_MSG_RESULT($with_install_o)
3515 if test "x$with_install_o" = xyes
3516 then
3517         INSTALL_OPT_O=`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`
3518 else
3519         INSTALL_OPT_O=
3520 fi
3521
3522 AC_SUBST(INSTALL_OPT_O)
3523 ])dnl
3524 dnl ---------------------------------------------------------------------------
3525 dnl CF_INSTALL_OPT_P version: 1 updated: 2018/08/18 12:19:21
3526 dnl ----------------
3527 dnl Some install-programs accept a "-p" option to preserve file modification
3528 dnl timestamps.  That can be useful as an install option, as well as a way to
3529 dnl avoid the need for ranlib after copying a static archive.
3530 AC_DEFUN([CF_INSTALL_OPT_P],
3531 [
3532 : ${INSTALL:=install}
3533 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
3534         rm -rf conftest*
3535         date >conftest.in
3536         mkdir conftest.out
3537         sleep 3
3538         if $INSTALL -p conftest.in conftest.out 2>/dev/null
3539         then
3540                 if test -f conftest.out/conftest.in
3541                 then
3542                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
3543                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
3544                         if test -s conftest.err
3545                         then
3546                                 cf_cv_install_p=no
3547                         else
3548                                 cf_cv_install_p=yes
3549                         fi
3550                 else
3551                         cf_cv_install_p=no
3552                 fi
3553         else
3554                 cf_cv_install_p=no
3555         fi
3556         rm -rf conftest*
3557 ])
3558 ])dnl
3559 dnl ---------------------------------------------------------------------------
3560 dnl CF_INSTALL_OPT_S version: 2 updated: 2018/08/18 12:19:21
3561 dnl ----------------
3562 dnl By default, we should strip executables which are installed, but leave the
3563 dnl ability to suppress that for unit-testing.
3564 AC_DEFUN([CF_INSTALL_OPT_S],
3565 [
3566 AC_MSG_CHECKING(if you want to install stripped executables)
3567 CF_ARG_DISABLE(stripping,
3568         [  --disable-stripping     do not strip (debug info) installed executables],
3569         [with_stripping=no],
3570         [with_stripping=yes])
3571 AC_MSG_RESULT($with_stripping)
3572
3573 if test "$with_stripping" = yes
3574 then
3575         INSTALL_OPT_S="-s"
3576 else
3577         INSTALL_OPT_S=
3578 fi
3579 AC_SUBST(INSTALL_OPT_S)
3580 ])dnl
3581 dnl ---------------------------------------------------------------------------
3582 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
3583 dnl -----------------
3584 dnl Check if the given compiler is really the Intel compiler for Linux.  It
3585 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
3586 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
3587 dnl
3588 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
3589 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
3590 dnl the wrappers for gcc and g++ warnings.
3591 dnl
3592 dnl $1 = GCC (default) or GXX
3593 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
3594 dnl $3 = CFLAGS (default) or CXXFLAGS
3595 AC_DEFUN([CF_INTEL_COMPILER],[
3596 AC_REQUIRE([AC_CANONICAL_HOST])
3597 ifelse([$2],,INTEL_COMPILER,[$2])=no
3598
3599 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
3600         case $host_os in
3601         (linux*|gnu*)
3602                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
3603                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
3604                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
3605                 AC_TRY_COMPILE([],[
3606 #ifdef __INTEL_COMPILER
3607 #else
3608 make an error
3609 #endif
3610 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
3611 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
3612 ],[])
3613                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
3614                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
3615                 ;;
3616         esac
3617 fi
3618 ])dnl
3619 dnl ---------------------------------------------------------------------------
3620 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
3621 dnl ----------
3622 dnl Check if we have either a function or macro for 'isascii()'.
3623 AC_DEFUN([CF_ISASCII],
3624 [
3625 AC_MSG_CHECKING(for isascii)
3626 AC_CACHE_VAL(cf_cv_have_isascii,[
3627         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
3628         [cf_cv_have_isascii=yes],
3629         [cf_cv_have_isascii=no])
3630 ])dnl
3631 AC_MSG_RESULT($cf_cv_have_isascii)
3632 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
3633 ])dnl
3634 dnl ---------------------------------------------------------------------------
3635 dnl CF_LARGEFILE version: 11 updated: 2018/06/20 20:23:13
3636 dnl ------------
3637 dnl Add checks for large file support.
3638 AC_DEFUN([CF_LARGEFILE],[
3639 ifdef([AC_FUNC_FSEEKO],[
3640         AC_SYS_LARGEFILE
3641         if test "$enable_largefile" != no ; then
3642         AC_FUNC_FSEEKO
3643
3644         # Normally we would collect these definitions in the config.h,
3645         # but (like _XOPEN_SOURCE), some environments rely on having these
3646         # defined before any of the system headers are included.  Another
3647         # case comes up with C++, e.g., on AIX the compiler compiles the
3648         # header files by themselves before looking at the body files it is
3649         # told to compile.  For ncurses, those header files do not include
3650         # the config.h
3651         if test "$ac_cv_sys_large_files" != no
3652         then
3653                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
3654         fi
3655         if test "$ac_cv_sys_largefile_source" != no
3656         then
3657                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
3658         fi
3659         if test "$ac_cv_sys_file_offset_bits" != no
3660         then
3661                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
3662         fi
3663
3664         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
3665                 AC_TRY_COMPILE([
3666 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
3667 #include <sys/types.h>
3668 #include <dirent.h>
3669                 ],[
3670                 /* if transitional largefile support is setup, this is true */
3671                 extern struct dirent64 * readdir(DIR *);
3672                 struct dirent64 *x = readdir((DIR *)0);
3673                 struct dirent *y = readdir((DIR *)0);
3674                 int z = x - y;
3675                 ],
3676                 [cf_cv_struct_dirent64=yes],
3677                 [cf_cv_struct_dirent64=no])
3678         ])
3679         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
3680         fi
3681 ])
3682 ])
3683 dnl ---------------------------------------------------------------------------
3684 dnl CF_LDFLAGS_STATIC version: 12 updated: 2015/04/18 08:56:57
3685 dnl -----------------
3686 dnl Check for compiler/linker flags used to temporarily force usage of static
3687 dnl libraries.  This depends on the compiler and platform.  Use this to help
3688 dnl ensure that the linker picks up a given library based on its position in
3689 dnl the list of linker options and libraries.
3690 AC_DEFUN([CF_LDFLAGS_STATIC],[
3691
3692 if test "$GCC" = yes ; then
3693         case $cf_cv_system_name in
3694         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
3695                 LDFLAGS_STATIC=
3696                 LDFLAGS_SHARED=
3697                 ;;
3698         (*)     # normally, except when broken
3699                 LDFLAGS_STATIC=-static
3700                 LDFLAGS_SHARED=-dynamic
3701                 ;;
3702         esac
3703 else
3704         case $cf_cv_system_name in
3705         (aix[[4-7]]*)   # from ld manpage
3706                 LDFLAGS_STATIC=-bstatic
3707                 LDFLAGS_SHARED=-bdynamic
3708                 ;;
3709         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
3710                 # We could also use just "archive" and "shared".
3711                 LDFLAGS_STATIC=-Wl,-a,archive_shared
3712                 LDFLAGS_SHARED=-Wl,-a,shared_archive
3713                 ;;
3714         (irix*)         # from ld manpage IRIX64
3715                 LDFLAGS_STATIC=-Bstatic
3716                 LDFLAGS_SHARED=-Bdynamic
3717                 ;;
3718         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
3719                 # alternative "-oldstyle_liblookup" (not in cc manpage)
3720                 LDFLAGS_STATIC=-noso
3721                 LDFLAGS_SHARED=-so_archive
3722                 ;;
3723         (solaris2*)
3724                 LDFLAGS_STATIC=-Bstatic
3725                 LDFLAGS_SHARED=-Bdynamic
3726                 ;;
3727         esac
3728 fi
3729
3730 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
3731 then
3732         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
3733
3734         rm -f libconftest.a
3735         cat >conftest.$ac_ext <<EOF
3736 #line __oline__ "configure"
3737 #include <stdio.h>
3738 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
3739 EOF
3740         if AC_TRY_EVAL(ac_compile) ; then
3741                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
3742                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
3743         fi
3744         rm -f conftest.*
3745
3746         cf_save_LIBS="$LIBS"
3747
3748         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
3749         AC_TRY_LINK([
3750 #line __oline__ "configure"
3751 #include <stdio.h>
3752 int cf_ldflags_static(FILE *fp);
3753 ],[
3754         return cf_ldflags_static(stdin);
3755 ],[
3756         # some linkers simply ignore the -dynamic
3757         case x`file conftest$ac_exeext 2>/dev/null` in
3758         (*static*)
3759                 cf_ldflags_static=no
3760                 ;;
3761         (*)