aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2019,2020 Thomas E. Dickey                                *
   3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey 1995-on
  31 dnl
  32 dnl $Id: aclocal.m4,v 1.903 2020/03/08 01:05:14 tom Exp $
  33 dnl Macros used in NCURSES auto-configuration script.
  34 dnl
  35 dnl These macros are maintained separately from NCURSES.  The copyright on
  36 dnl this file applies to the aggregation of macros and does not affect use of
  37 dnl these macros in other applications.
  38 dnl
  39 dnl See these pages for additional information:
  40 dnl             https://invisible-island.net/autoconf/
  41 dnl             https://invisible-island.net/autoconf/my-autoconf.html
  42 dnl
  43 dnl ---------------------------------------------------------------------------
  44 dnl ---------------------------------------------------------------------------
  45 dnl AM_LANGINFO_CODESET version: 4 updated: 2015/04/18 08:56:57
  46 dnl -------------------
  47 dnl Inserted as requested by gettext 0.10.40
  48 dnl File from /usr/share/aclocal
  49 dnl codeset.m4
  50 dnl ====================
  51 dnl serial AM1
  52 dnl
  53 dnl From Bruno Haible.
  54 AC_DEFUN([AM_LANGINFO_CODESET],
  55 [
  56 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  57         [AC_TRY_LINK([#include <langinfo.h>],
  58         [char* cs = nl_langinfo(CODESET);],
  59         am_cv_langinfo_codeset=yes,
  60         am_cv_langinfo_codeset=no)
  61         ])
  62         if test $am_cv_langinfo_codeset = yes; then
  63                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  64                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  65         fi
  66 ])dnl
  67 dnl ---------------------------------------------------------------------------
  68 dnl CF_ABI_DEFAULTS version: 2 updated: 2015/06/06 13:49:58
  69 dnl ---------------
  70 dnl Provide configure-script defaults for different ncurses ABIs.
  71 AC_DEFUN([CF_ABI_DEFAULTS],[
  72 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
  73 case x$cf_cv_abi_version in
  74 (x[[6789]])
  75         cf_dft_ext_colors=yes
  76         cf_dft_ext_const=yes
  77         cf_dft_ext_mouse=yes
  78         cf_dft_ext_putwin=yes
  79         cf_dft_ext_spfuncs=yes
  80         cf_dft_filter_syms=yes
  81         cf_dft_chtype=uint32_t
  82         cf_dft_mmask_t=uint32_t
  83         cf_dft_interop=yes
  84         cf_dft_tparm_arg=intptr_t
  85         cf_dft_with_lp64=yes
  86         ;;
  87 (*)
  88         cf_dft_ext_colors=no
  89         cf_dft_ext_const=no
  90         cf_dft_ext_mouse=no
  91         cf_dft_ext_putwin=no
  92         cf_dft_ext_spfuncs=no
  93         cf_dft_filter_syms=no
  94         cf_dft_chtype=auto
  95         cf_dft_mmask_t=auto
  96         cf_dft_interop=no
  97         cf_dft_tparm_arg=long
  98         cf_dft_with_lp64=no
  99         ;;
 100 esac
 101 ])dnl
 102 dnl ---------------------------------------------------------------------------
 103 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
 104 dnl ------------------
 105 dnl Conditionally generate script according to whether we're using a given autoconf.
 106 dnl
 107 dnl $1 = version to compare against
 108 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
 109 dnl $3 = code to use if AC_ACVERSION is older than $1.
 110 define([CF_ACVERSION_CHECK],
 111 [
 112 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
 113 ifdef([m4_version_compare],
 114 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
 115 [CF_ACVERSION_COMPARE(
 116 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
 117 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
 118 dnl ---------------------------------------------------------------------------
 119 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
 120 dnl --------------------
 121 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
 122 dnl                      MAJOR2, MINOR2, TERNARY2,
 123 dnl                      PRINTABLE2, not FOUND, FOUND)
 124 define([CF_ACVERSION_COMPARE],
 125 [ifelse(builtin([eval], [$2 < $5]), 1,
 126 [ifelse([$8], , ,[$8])],
 127 [ifelse([$9], , ,[$9])])])dnl
 128 dnl ---------------------------------------------------------------------------
 129 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
 130 dnl -------------------
 131 dnl Construct the list of include-options for the C programs in the Ada95
 132 dnl binding.
 133 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
 134 [
 135 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
 136 if test "$srcdir" != "."; then
 137         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 138 fi
 139 if test "$GCC" != yes; then
 140         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 141 elif test "$includedir" != "/usr/include"; then
 142         if test "$includedir" = '${prefix}/include' ; then
 143                 if test x$prefix != x/usr ; then
 144                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 145                 fi
 146         else
 147                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 148         fi
 149 fi
 150 AC_SUBST(ACPPFLAGS)
 151 ])dnl
 152 dnl ---------------------------------------------------------------------------
 153 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 154 dnl ---------------
 155 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 156 AC_DEFUN([CF_ADD_ADAFLAGS],[
 157         ADAFLAGS="$ADAFLAGS $1"
 158         AC_SUBST(ADAFLAGS)
 159 ])dnl
 160 dnl ---------------------------------------------------------------------------
 161 dnl CF_ADD_CFLAGS version: 13 updated: 2017/02/25 18:57:40
 162 dnl -------------
 163 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 164 dnl The second parameter if given makes this macro verbose.
 165 dnl
 166 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 167 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 168 dnl confused by the quotes (which require backslashes to keep them usable).
 169 AC_DEFUN([CF_ADD_CFLAGS],
 170 [
 171 cf_fix_cppflags=no
 172 cf_new_cflags=
 173 cf_new_cppflags=
 174 cf_new_extra_cppflags=
 175
 176 for cf_add_cflags in $1
 177 do
 178 case $cf_fix_cppflags in
 179 (no)
 180         case $cf_add_cflags in
 181         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 182                 case $cf_add_cflags in
 183                 (-D*)
 184                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 185
 186                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 187                                 && test -z "${cf_tst_cflags}" \
 188                                 && cf_fix_cppflags=yes
 189
 190                         if test $cf_fix_cppflags = yes ; then
 191                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 192                                 continue
 193                         elif test "${cf_tst_cflags}" = "\"'" ; then
 194                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 195                                 continue
 196                         fi
 197                         ;;
 198                 esac
 199                 case "$CPPFLAGS" in
 200                 (*$cf_add_cflags)
 201                         ;;
 202                 (*)
 203                         case $cf_add_cflags in
 204                         (-D*)
 205                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 206                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 207                                 ;;
 208                         esac
 209                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 210                         ;;
 211                 esac
 212                 ;;
 213         (*)
 214                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 215                 ;;
 216         esac
 217         ;;
 218 (yes)
 219         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 220
 221         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 222
 223         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 224                 && test -z "${cf_tst_cflags}" \
 225                 && cf_fix_cppflags=no
 226         ;;
 227 esac
 228 done
 229
 230 if test -n "$cf_new_cflags" ; then
 231         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 232         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 233 fi
 234
 235 if test -n "$cf_new_cppflags" ; then
 236         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 237         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 238 fi
 239
 240 if test -n "$cf_new_extra_cppflags" ; then
 241         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 242         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 243 fi
 244
 245 AC_SUBST(EXTRA_CPPFLAGS)
 246
 247 ])dnl
 248 dnl ---------------------------------------------------------------------------
 249 dnl CF_ADD_INCDIR version: 15 updated: 2018/06/20 20:23:13
 250 dnl -------------
 251 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 252 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 253 dnl but old versions (and some misinstalled ones) need that.  To make things
 254 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 255 dnl the include-path).
 256 AC_DEFUN([CF_ADD_INCDIR],
 257 [
 258 if test -n "$1" ; then
 259   for cf_add_incdir in $1
 260   do
 261         while test $cf_add_incdir != /usr/include
 262         do
 263           if test -d $cf_add_incdir
 264           then
 265                 cf_have_incdir=no
 266                 if test -n "$CFLAGS$CPPFLAGS" ; then
 267                   # a loop is needed to ensure we can add subdirs of existing dirs
 268                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 269                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 270                           cf_have_incdir=yes; break
 271                         fi
 272                   done
 273                 fi
 274
 275                 if test "$cf_have_incdir" = no ; then
 276                   if test "$cf_add_incdir" = /usr/local/include ; then
 277                         if test "$GCC" = yes
 278                         then
 279                           cf_save_CPPFLAGS=$CPPFLAGS
 280                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
 281                           AC_TRY_COMPILE([#include <stdio.h>],
 282                                   [printf("Hello")],
 283                                   [],
 284                                   [cf_have_incdir=yes])
 285                           CPPFLAGS=$cf_save_CPPFLAGS
 286                         fi
 287                   fi
 288                 fi
 289
 290                 if test "$cf_have_incdir" = no ; then
 291                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 292                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 293
 294                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 295                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 296                   cf_add_incdir="$cf_top_incdir"
 297                 else
 298                   break
 299                 fi
 300           else
 301                 break
 302           fi
 303         done
 304   done
 305 fi
 306 ])dnl
 307 dnl ---------------------------------------------------------------------------
 308 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 309 dnl ----------
 310 dnl Add a library, used to enforce consistency.
 311 dnl
 312 dnl $1 = library to add, without the "-l"
 313 dnl $2 = variable to update (default $LIBS)
 314 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 315 dnl ---------------------------------------------------------------------------
 316 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 317 dnl -------------
 318 dnl     Adds to the library-path
 319 dnl
 320 dnl     Some machines have trouble with multiple -L options.
 321 dnl
 322 dnl $1 is the (list of) directory(s) to add
 323 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 324 dnl
 325 AC_DEFUN([CF_ADD_LIBDIR],
 326 [
 327 if test -n "$1" ; then
 328         for cf_add_libdir in $1
 329         do
 330                 if test $cf_add_libdir = /usr/lib ; then
 331                         :
 332                 elif test -d $cf_add_libdir
 333                 then
 334                         cf_have_libdir=no
 335                         if test -n "$LDFLAGS$LIBS" ; then
 336                                 # a loop is needed to ensure we can add subdirs of existing dirs
 337                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 338                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 339                                                 cf_have_libdir=yes; break
 340                                         fi
 341                                 done
 342                         fi
 343                         if test "$cf_have_libdir" = no ; then
 344                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 345                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 346                         fi
 347                 fi
 348         done
 349 fi
 350 ])dnl
 351 dnl ---------------------------------------------------------------------------
 352 dnl CF_ADD_LIBS version: 3 updated: 2019/11/02 16:47:33
 353 dnl -----------
 354 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 355 dnl prepended to an existing list, since their dependencies are assumed to
 356 dnl already exist in the list.
 357 dnl
 358 dnl $1 = libraries to add, with the "-l", etc.
 359 dnl $2 = variable to update (default $LIBS)
 360 AC_DEFUN([CF_ADD_LIBS],[
 361 cf_add_libs="[$]ifelse($2,,LIBS,[$2])"
 362 # reverse order
 363 cf_add_0lib=
 364 for cf_add_1lib in $1; do cf_add_0lib="$cf_add_1lib $cf_add_0lib"; done
 365 # filter duplicates
 366 for cf_add_1lib in $cf_add_0lib; do
 367         for cf_add_2lib in $cf_add_libs; do
 368                 if test "x$cf_add_1lib" = "x$cf_add_2lib"; then
 369                         cf_add_1lib=
 370                         break
 371                 fi
 372         done
 373         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_1lib $cf_add_libs"
 374 done
 375 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 376 ])dnl
 377 dnl ---------------------------------------------------------------------------
 378 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 379 dnl ------------------
 380 dnl Append to a search-list for a nonstandard header/lib-file
 381 dnl     $1 = the variable to return as result
 382 dnl     $2 = the package name
 383 dnl     $3 = the subdirectory, e.g., bin, include or lib
 384 dnl $4 = the directory under which we will test for subdirectories
 385 dnl $5 = a directory that we do not want $4 to match
 386 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 387 [
 388 test "x$4" != "x$5" && \
 389 test -d "$4" && \
 390 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 391         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 392         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 393         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 394         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 395         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 396         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 397 }
 398 ])dnl
 399 dnl ---------------------------------------------------------------------------
 400 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 401 dnl --------------
 402 dnl use this macro for appending text without introducing an extra blank at
 403 dnl the beginning
 404 define([CF_APPEND_TEXT],
 405 [
 406         test -n "[$]$1" && $1="[$]$1 "
 407         $1="[$]{$1}$2"
 408 ])dnl
 409 dnl ---------------------------------------------------------------------------
 410 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 411 dnl --------------
 412 dnl Allow user to disable a normally-on option.
 413 AC_DEFUN([CF_ARG_DISABLE],
 414 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 415 dnl ---------------------------------------------------------------------------
 416 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 417 dnl -------------
 418 dnl Allow user to enable a normally-off option.
 419 AC_DEFUN([CF_ARG_ENABLE],
 420 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 421 dnl ---------------------------------------------------------------------------
 422 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 423 dnl -------------
 424 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 425 dnl values.
 426 dnl
 427 dnl Parameters:
 428 dnl $1 = option name
 429 dnl $2 = help-string
 430 dnl $3 = action to perform if option is not default
 431 dnl $4 = action if perform if option is default
 432 dnl $5 = default option value (either 'yes' or 'no')
 433 AC_DEFUN([CF_ARG_OPTION],
 434 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 435         if test "$enableval" != "$5" ; then
 436 ifelse([$3],,[    :]dnl
 437 ,[    $3]) ifelse([$4],,,[
 438         else
 439                 $4])
 440         fi],[enableval=$5 ifelse([$4],,,[
 441         $4
 442 ])dnl
 443 ])])dnl
 444 dnl ---------------------------------------------------------------------------
 445 dnl CF_AR_FLAGS version: 6 updated: 2015/10/10 15:25:05
 446 dnl -----------
 447 dnl Check for suitable "ar" (archiver) options for updating an archive.
 448 dnl
 449 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 450 dnl as well as a workaround for breakage of make's archive rules by the GNU
 451 dnl binutils "ar" program.
 452 AC_DEFUN([CF_AR_FLAGS],[
 453 AC_REQUIRE([CF_PROG_AR])
 454
 455 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 456         cf_cv_ar_flags=unknown
 457         for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 458         do
 459
 460                 # check if $ARFLAGS already contains this choice
 461                 if test "x$ARFLAGS" != "x" ; then
 462                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 463                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 464                                 cf_cv_ar_flags=
 465                                 break
 466                         fi
 467                 fi
 468
 469                 rm -f conftest.$ac_cv_objext
 470                 rm -f conftest.a
 471
 472                 cat >conftest.$ac_ext <<EOF
 473 #line __oline__ "configure"
 474 int     testdata[[3]] = { 123, 456, 789 };
 475 EOF
 476                 if AC_TRY_EVAL(ac_compile) ; then
 477                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 478                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 479                         if test -f conftest.a ; then
 480                                 cf_cv_ar_flags=$cf_ar_flags
 481                                 break
 482                         fi
 483                 else
 484                         CF_VERBOSE(cannot compile test-program)
 485                         break
 486                 fi
 487         done
 488         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 489 ])
 490
 491 if test -n "$ARFLAGS" ; then
 492         if test -n "$cf_cv_ar_flags" ; then
 493                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 494         fi
 495 else
 496         ARFLAGS=$cf_cv_ar_flags
 497 fi
 498
 499 AC_SUBST(ARFLAGS)
 500 ])
 501 dnl ---------------------------------------------------------------------------
 502 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
 503 dnl -----------------
 504 dnl Check if awk can handle big strings using printf.  Some older versions of
 505 dnl awk choke on large strings passed via "%s".
 506 dnl
 507 dnl $1 = desired string size
 508 dnl $2 = variable to set with result
 509 AC_DEFUN([CF_AWK_BIG_PRINTF],
 510 [
 511         case x$AWK in
 512         (x)
 513                 eval $2=no
 514                 ;;
 515         (*)
 516                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 517                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 518                         eval $2=yes
 519                 else
 520                         eval $2=no
 521                 fi
 522                 ;;
 523         esac
 524 ])dnl
 525 dnl ---------------------------------------------------------------------------
 526 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 527 dnl ------------
 528 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 529 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 530 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 531 dnl
 532 dnl Treat the configuration-variable specially here, since we're directly
 533 dnl substituting its value (i.e., 1/0).
 534 dnl
 535 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 536 AC_DEFUN([CF_BOOL_DECL],
 537 [
 538 AC_MSG_CHECKING(if we should include stdbool.h)
 539
 540 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 541         AC_TRY_COMPILE([],[bool foo = false],
 542                 [cf_cv_header_stdbool_h=0],
 543                 [AC_TRY_COMPILE([
 544 #ifndef __BEOS__
 545 #include <stdbool.h>
 546 #endif
 547 ],[bool foo = false],
 548                         [cf_cv_header_stdbool_h=1],
 549                         [cf_cv_header_stdbool_h=0])])])
 550
 551 if test "$cf_cv_header_stdbool_h" = 1
 552 then    AC_MSG_RESULT(yes)
 553 else    AC_MSG_RESULT(no)
 554 fi
 555
 556 AC_MSG_CHECKING([for builtin bool type])
 557
 558 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 559         AC_TRY_COMPILE([
 560 #include <stdio.h>
 561 #include <sys/types.h>
 562 ],[bool x = false],
 563                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 564                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 565         ])
 566
 567 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 568 then    AC_MSG_RESULT(yes)
 569 else    AC_MSG_RESULT(no)
 570 fi
 571 ])dnl
 572 dnl ---------------------------------------------------------------------------
 573 dnl CF_BOOL_SIZE version: 15 updated: 2017/01/21 11:06:25
 574 dnl ------------
 575 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 576 dnl Don't bother looking for bool.h, since it's been deprecated.
 577 dnl
 578 dnl If the current compiler is C rather than C++, we get the bool definition
 579 dnl from <stdbool.h>.
 580 AC_DEFUN([CF_BOOL_SIZE],
 581 [
 582 AC_MSG_CHECKING([for size of bool])
 583 AC_CACHE_VAL(cf_cv_type_of_bool,[
 584         rm -f cf_test.out
 585         AC_TRY_RUN([
 586 #include <stdlib.h>
 587 #include <stdio.h>
 588
 589 #if defined(__cplusplus)
 590
 591 #ifdef HAVE_GXX_BUILTIN_H
 592 #include <g++/builtin.h>
 593 #elif HAVE_GPP_BUILTIN_H
 594 #include <gpp/builtin.h>
 595 #elif HAVE_BUILTIN_H
 596 #include <builtin.h>
 597 #endif
 598
 599 #else
 600
 601 #if $cf_cv_header_stdbool_h
 602 #include <stdbool.h>
 603 #endif
 604
 605 #endif
 606
 607 int main(void)
 608 {
 609         FILE *fp = fopen("cf_test.out", "w");
 610         if (fp != 0) {
 611                 bool x = true;
 612                 if ((bool)(-x) >= 0)
 613                         fputs("unsigned ", fp);
 614                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 615                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 616                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 617                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 618                 fclose(fp);
 619         }
 620         ${cf_cv_main_return:-return}(0);
 621 }
 622                 ],
 623                 [cf_cv_type_of_bool=`cat cf_test.out`
 624                  if test -z "$cf_cv_type_of_bool"; then
 625                    cf_cv_type_of_bool=unknown
 626                  fi],
 627                 [cf_cv_type_of_bool=unknown],
 628                 [cf_cv_type_of_bool=unknown])
 629         ])
 630         rm -f cf_test.out
 631 AC_MSG_RESULT($cf_cv_type_of_bool)
 632 if test "$cf_cv_type_of_bool" = unknown ; then
 633         case .$NCURSES_BOOL in
 634         (.auto|.) NCURSES_BOOL=unsigned;;
 635         esac
 636         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 637         cf_cv_type_of_bool=$NCURSES_BOOL
 638 fi
 639 ])dnl
 640 dnl ---------------------------------------------------------------------------
 641 dnl CF_BUILD_CC version: 8 updated: 2018/01/04 20:31:04
 642 dnl -----------
 643 dnl If we're cross-compiling, allow the user to override the tools and their
 644 dnl options.  The configure script is oriented toward identifying the host
 645 dnl compiler, etc., but we need a build compiler to generate parts of the
 646 dnl source.
 647 dnl
 648 dnl $1 = default for $CPPFLAGS
 649 dnl $2 = default for $LIBS
 650 AC_DEFUN([CF_BUILD_CC],[
 651 CF_ACVERSION_CHECK(2.52,,
 652         [AC_REQUIRE([CF_PROG_EXT])])
 653 if test "$cross_compiling" = yes ; then
 654
 655         # defaults that we might want to override
 656         : ${BUILD_CFLAGS:=''}
 657         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 658         : ${BUILD_LDFLAGS:=''}
 659         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 660         : ${BUILD_EXEEXT:='$x'}
 661         : ${BUILD_OBJEXT:='o'}
 662
 663         AC_ARG_WITH(build-cc,
 664                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 665                 [BUILD_CC="$withval"],
 666                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
 667         AC_MSG_CHECKING(for native build C compiler)
 668         AC_MSG_RESULT($BUILD_CC)
 669
 670         AC_MSG_CHECKING(for native build C preprocessor)
 671         AC_ARG_WITH(build-cpp,
 672                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 673                 [BUILD_CPP="$withval"],
 674                 [BUILD_CPP='${BUILD_CC} -E'])
 675         AC_MSG_RESULT($BUILD_CPP)
 676
 677         AC_MSG_CHECKING(for native build C flags)
 678         AC_ARG_WITH(build-cflags,
 679                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 680                 [BUILD_CFLAGS="$withval"])
 681         AC_MSG_RESULT($BUILD_CFLAGS)
 682
 683         AC_MSG_CHECKING(for native build C preprocessor-flags)
 684         AC_ARG_WITH(build-cppflags,
 685                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 686                 [BUILD_CPPFLAGS="$withval"])
 687         AC_MSG_RESULT($BUILD_CPPFLAGS)
 688
 689         AC_MSG_CHECKING(for native build linker-flags)
 690         AC_ARG_WITH(build-ldflags,
 691                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 692                 [BUILD_LDFLAGS="$withval"])
 693         AC_MSG_RESULT($BUILD_LDFLAGS)
 694
 695         AC_MSG_CHECKING(for native build linker-libraries)
 696         AC_ARG_WITH(build-libs,
 697                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 698                 [BUILD_LIBS="$withval"])
 699         AC_MSG_RESULT($BUILD_LIBS)
 700
 701         # this assumes we're on Unix.
 702         BUILD_EXEEXT=
 703         BUILD_OBJEXT=o
 704
 705         : ${BUILD_CC:='${CC}'}
 706
 707         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 708                 AC_MSG_ERROR([Cross-build requires two compilers.
 709 Use --with-build-cc to specify the native compiler.])
 710         fi
 711
 712 else
 713         : ${BUILD_CC:='${CC}'}
 714         : ${BUILD_CPP:='${CPP}'}
 715         : ${BUILD_CFLAGS:='${CFLAGS}'}
 716         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 717         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 718         : ${BUILD_LIBS:='${LIBS}'}
 719         : ${BUILD_EXEEXT:='$x'}
 720         : ${BUILD_OBJEXT:='o'}
 721 fi
 722
 723 AC_SUBST(BUILD_CC)
 724 AC_SUBST(BUILD_CPP)
 725 AC_SUBST(BUILD_CFLAGS)
 726 AC_SUBST(BUILD_CPPFLAGS)
 727 AC_SUBST(BUILD_LDFLAGS)
 728 AC_SUBST(BUILD_LIBS)
 729 AC_SUBST(BUILD_EXEEXT)
 730 AC_SUBST(BUILD_OBJEXT)
 731 ])dnl
 732 dnl ---------------------------------------------------------------------------
 733 dnl CF_CC_ENV_FLAGS version: 9 updated: 2018/07/29 18:03:26
 734 dnl ---------------
 735 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 736 dnl into CC.  This will not help with broken scripts that wrap the compiler
 737 dnl with options, but eliminates a more common category of user confusion.
 738 dnl
 739 dnl In particular, it addresses the problem of being able to run the C
 740 dnl preprocessor in a consistent manner.
 741 dnl
 742 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 743 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 744 dnl outweighs that limitation.
 745 AC_DEFUN([CF_CC_ENV_FLAGS],
 746 [
 747 # This should have been defined by AC_PROG_CC
 748 : ${CC:=cc}
 749
 750 AC_MSG_CHECKING(\$CFLAGS variable)
 751 case "x$CFLAGS" in
 752 (*-[[IUD]]*)
 753         AC_MSG_RESULT(broken)
 754         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
 755         cf_flags="$CFLAGS"
 756         CFLAGS=
 757         for cf_arg in $cf_flags
 758         do
 759                 CF_ADD_CFLAGS($cf_arg)
 760         done
 761         ;;
 762 (*)
 763         AC_MSG_RESULT(ok)
 764         ;;
 765 esac
 766
 767 AC_MSG_CHECKING(\$CC variable)
 768 case "$CC" in
 769 (*[[\ \ ]]-*)
 770         AC_MSG_RESULT(broken)
 771         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
 772         # humor him...
 773         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 774         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
 775         CC="$cf_prog"
 776         for cf_arg in $cf_flags
 777         do
 778                 case "x$cf_arg" in
 779                 (x-[[IUDfgOW]]*)
 780                         CF_ADD_CFLAGS($cf_arg)
 781                         ;;
 782                 (*)
 783                         CC="$CC $cf_arg"
 784                         ;;
 785                 esac
 786         done
 787         CF_VERBOSE(resulting CC: '$CC')
 788         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 789         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 790         ;;
 791 (*)
 792         AC_MSG_RESULT(ok)
 793         ;;
 794 esac
 795 ])dnl
 796 dnl ---------------------------------------------------------------------------
 797 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
 798 dnl ---------------
 799 dnl Determine the default configuration into which we'll install ncurses.  This
 800 dnl can be overridden by the user's command-line options.  There's two items to
 801 dnl look for:
 802 dnl     1. the prefix (e.g., /usr)
 803 dnl     2. the header files (e.g., /usr/include/ncurses)
 804 dnl We'll look for a previous installation of ncurses and use the same defaults.
 805 dnl
 806 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 807 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 808 dnl programs from a vendor's.
 809 AC_DEFUN([CF_CFG_DEFAULTS],
 810 [
 811 AC_MSG_CHECKING(for prefix)
 812 if test "x$prefix" = "xNONE" ; then
 813         case "$cf_cv_system_name" in
 814                 # non-vendor systems don't have a conflict
 815         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 816                 prefix=/usr
 817                 ;;
 818         (*)     prefix=$ac_default_prefix
 819                 ;;
 820         esac
 821 fi
 822 AC_MSG_RESULT($prefix)
 823
 824 if test "x$prefix" = "xNONE" ; then
 825 AC_MSG_CHECKING(for default include-directory)
 826 test -n "$verbose" && echo 1>&AC_FD_MSG
 827 for cf_symbol in \
 828         $includedir \
 829         $includedir/ncurses \
 830         $prefix/include \
 831         $prefix/include/ncurses \
 832         /usr/local/include \
 833         /usr/local/include/ncurses \
 834         /usr/include \
 835         /usr/include/ncurses
 836 do
 837         cf_dir=`eval echo $cf_symbol`
 838         if test -f $cf_dir/curses.h ; then
 839         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 840                 includedir="$cf_symbol"
 841                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 842                 break
 843         fi
 844         fi
 845         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 846 done
 847 AC_MSG_RESULT($includedir)
 848 fi
 849 ])dnl
 850 dnl ---------------------------------------------------------------------------
 851 dnl CF_CGETENT version: 6 updated: 2017/01/21 11:06:25
 852 dnl ----------
 853 dnl Check if the terminal-capability database functions are available.  If not,
 854 dnl ncurses has a much-reduced version.
 855 AC_DEFUN([CF_CGETENT],[
 856 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 857 AC_TRY_LINK([
 858 #include <stdlib.h>],[
 859         char temp[128];
 860         char *buf = temp;
 861         char *db_array = temp;
 862         cgetent(&buf, &db_array, "vt100");
 863         cgetcap(buf, "tc", '=');
 864         cgetmatch(buf, "tc");
 865         ],
 866         [cf_cv_cgetent=yes],
 867         [cf_cv_cgetent=no])
 868 ])
 869
 870 if test "$cf_cv_cgetent" = yes
 871 then
 872         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 873 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 874 AC_TRY_LINK([
 875 #pragma GCC diagnostic error "-Wincompatible-pointer-types-discards-qualifiers"
 876 #include <stdlib.h>],[
 877         char temp[128];
 878         char *buf = temp;
 879 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 880         const char *db_array = temp;
 881         cgetent(&buf, &db_array, "vt100");
 882 #endif
 883         cgetcap(buf, "tc", '=');
 884         cgetmatch(buf, "tc");
 885         ],
 886         [cf_cv_cgetent_const=yes],
 887         [cf_cv_cgetent_const=no])
 888 ])
 889         if test "$cf_cv_cgetent_const" = yes
 890         then
 891                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 892         fi
 893 fi
 894 ])dnl
 895 dnl ---------------------------------------------------------------------------
 896 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 897 dnl --------------
 898 dnl Check if we're accidentally using a cache from a different machine.
 899 dnl Derive the system name, as a check for reusing the autoconf cache.
 900 dnl
 901 dnl If we've packaged config.guess and config.sub, run that (since it does a
 902 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 903 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 904 dnl which is useful in cross-compiles.
 905 dnl
 906 dnl Note: we would use $ac_config_sub, but that is one of the places where
 907 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 908 AC_DEFUN([CF_CHECK_CACHE],
 909 [
 910 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 911         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 912         system_name="$host_os"
 913 else
 914         system_name="`(uname -s -r) 2>/dev/null`"
 915         if test -z "$system_name" ; then
 916                 system_name="`(hostname) 2>/dev/null`"
 917         fi
 918 fi
 919 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 920 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 921
 922 test -z "$system_name" && system_name="$cf_cv_system_name"
 923 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 924
 925 if test ".$system_name" != ".$cf_cv_system_name" ; then
 926         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 927         AC_MSG_ERROR("Please remove config.cache and try again.")
 928 fi
 929 ])dnl
 930 dnl ---------------------------------------------------------------------------
 931 dnl CF_CHECK_ENVIRON version: 3 updated: 2010/05/26 16:44:57
 932 dnl ----------------
 933 dnl Check for data that is usually declared in <unistd.h>, e.g., the 'environ'
 934 dnl variable.  Define a DECL_xxx symbol if we must declare it ourselves.
 935 dnl
 936 dnl $1 = the name to check
 937 dnl $2 = the assumed type
 938 AC_DEFUN([CF_CHECK_ENVIRON],
 939 [
 940 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 941     AC_TRY_COMPILE([
 942 #ifdef HAVE_STDLIB_H
 943 #include <stdlib.h>
 944 #endif
 945 #include <unistd.h> ],
 946     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 947     [cf_cv_dcl_$1=yes],
 948     [cf_cv_dcl_$1=no])
 949 ])
 950
 951 if test "$cf_cv_dcl_$1" = no ; then
 952     CF_UPPER(cf_result,decl_$1)
 953     AC_DEFINE_UNQUOTED($cf_result)
 954 fi
 955
 956 # It's possible (for near-UNIX clones) that the data doesn't exist
 957 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 958 ])dnl
 959 dnl ---------------------------------------------------------------------------
 960 dnl CF_CHECK_ERRNO version: 12 updated: 2015/04/18 08:56:57
 961 dnl --------------
 962 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 963 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 964 dnl ourselves.
 965 dnl
 966 dnl $1 = the name to check
 967 dnl $2 = the assumed type
 968 AC_DEFUN([CF_CHECK_ERRNO],
 969 [
 970 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 971         AC_TRY_COMPILE([
 972 #ifdef HAVE_STDLIB_H
 973 #include <stdlib.h>
 974 #endif
 975 #include <stdio.h>
 976 #include <sys/types.h>
 977 #include <errno.h> ],
 978         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 979         [cf_cv_dcl_$1=yes],
 980         [cf_cv_dcl_$1=no])
 981 ])
 982
 983 if test "$cf_cv_dcl_$1" = no ; then
 984         CF_UPPER(cf_result,decl_$1)
 985         AC_DEFINE_UNQUOTED($cf_result)
 986 fi
 987
 988 # It's possible (for near-UNIX clones) that the data doesn't exist
 989 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 990 ])dnl
 991 dnl ---------------------------------------------------------------------------
 992 dnl CF_CHECK_EXTERN_DATA version: 4 updated: 2015/04/18 08:56:57
 993 dnl --------------------
 994 dnl Check for existence of external data in the current set of libraries.  If
 995 dnl we can modify it, it's real enough.
 996 dnl $1 = the name to check
 997 dnl $2 = its type
 998 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 999 [
1000 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
1001         AC_TRY_LINK([
1002 #undef $1
1003 extern $2 $1;
1004 ],
1005         [$1 = 2],
1006         [cf_cv_have_$1=yes],
1007         [cf_cv_have_$1=no])
1008 ])
1009
1010 if test "$cf_cv_have_$1" = yes ; then
1011         CF_UPPER(cf_result,have_$1)
1012         AC_DEFINE_UNQUOTED($cf_result)
1013 fi
1014
1015 ])dnl
1016 dnl ---------------------------------------------------------------------------
1017 dnl CF_CHECK_GETENV version: 1 updated: 2019/06/23 15:28:15
1018 dnl ---------------
1019 dnl Check if repeated getenv calls return the same pointer, e.g., it does not
1020 dnl discard the previous pointer when returning a new one.
1021 AC_DEFUN([CF_CHECK_GETENV],
1022 [
1023 AC_REQUIRE([CF_CHECK_ENVIRON])
1024 AC_CHECK_FUNC( getenv, ,, AC_MSG_ERROR(getenv not found) )
1025 AC_CHECK_FUNCS( putenv setenv strdup )
1026 AC_CACHE_CHECK(if getenv returns consistent values,cf_cv_consistent_getenv,[
1027 AC_TRY_RUN([
1028 #include <stdlib.h>
1029 #include <unistd.h>
1030 #include <stdio.h>
1031 #include <string.h>
1032 #include <sys/types.h>
1033
1034 #if defined(HAVE_ENVIRON) && defined(DECL_ENVIRON) && !defined(environ)
1035 extern char **environ;  /* POSIX, but some systems are not... */
1036 #endif
1037
1038 #if defined(HAVE_STRDUP)
1039 #define str_alloc(s) strdup(s)
1040 #else
1041 #define str_alloc(s) strcpy(malloc(strlen(s) + 1, s))
1042 #endif
1043
1044 static void set_value(const char *name, const char *value)
1045 {
1046 #if defined(HAVE_SETENV)
1047         setenv(name, value, 1);
1048 #elif defined(HAVE_PUTENV)
1049         char buffer[1024];
1050         sprintf(buffer, "%s=%s", name, value);
1051         putenv(str_alloc(buffer));
1052 #else
1053 #error neither putenv/setenv found
1054 #endif
1055 }
1056 int main(void)
1057 {
1058         int pass;
1059         size_t numenv, limit, j;
1060         char **mynames;
1061         char **myvalues;
1062         char **mypointer;
1063         char *equals;
1064         for (numenv = 0; environ[numenv]; ++numenv) ;
1065         limit = numenv + 10;
1066         mynames = (char **) calloc(limit + 1, sizeof(char *));
1067         myvalues = (char **) calloc(limit + 1, sizeof(char *));
1068         mypointer = (char **) calloc(limit + 1, sizeof(char *));
1069 #if defined(HAVE_ENVIRON)
1070         for (j = 0; environ[j]; ++j) {
1071                 mynames[j] = str_alloc(environ[j]);
1072                 equals = strchr(mynames[j], '=');
1073                 if (equals != 0) {
1074                         *equals++ = '\0';
1075                         myvalues[j] = str_alloc(equals);
1076                 } else {
1077                         myvalues[j] = str_alloc("");
1078                 }
1079         }
1080 #endif
1081         for (j = numenv; j < limit; ++j) {
1082                 char name[80];
1083                 char value[80];
1084                 size_t found;
1085                 size_t k = 0;
1086                 do {
1087                         size_t jk;
1088                         found = 0;
1089                         sprintf(name, "TERM%lu", (unsigned long) k);
1090                         for (jk = 0; jk < j; ++jk) {
1091                                 if (!strcmp(name, mynames[jk])) {
1092                                         found = 1;
1093                                         ++k;
1094                                         break;
1095                                 }
1096                         }
1097                 } while (found);
1098                 sprintf(value, "%lu:%p", (unsigned long) k, &mynames[j]);
1099                 set_value(name, value);
1100                 mynames[j] = str_alloc(name);
1101                 myvalues[j] = str_alloc(value);
1102         }
1103         for (pass = 0; pass < 3; ++pass) {
1104                 for (j = 0; j < limit; ++j) {
1105                         char *value = getenv(mynames[j]);
1106                         if (pass) {
1107                                 if (value == 0) {
1108                                         fprintf(stderr, "getenv returned null for %s\n", mynames[j]);
1109                                         ${cf_cv_main_return:-return}(1);
1110                                 } else if (value != mypointer[j]) {
1111                                         fprintf(stderr, "getenv returned different pointer for %s\n", mynames[j]);
1112                                         ${cf_cv_main_return:-return}(1);
1113                                 } else if (strcmp(value, myvalues[j])) {
1114                                         fprintf(stderr, "getenv returned different value for %s\n", mynames[j]);
1115                                         ${cf_cv_main_return:-return}(1);
1116                                 }
1117                         } else {
1118                                 size_t k;
1119                                 mypointer[j] = value;
1120                                 for (k = 0; k < j; ++k) {
1121                                         if (mypointer[j] == mypointer[k]) {
1122                                                 fprintf(stderr, "getenv returned same pointer for %s and %s\n", mynames[j], mynames[k]);
1123                                                 ${cf_cv_main_return:-return}(1);
1124                                         }
1125                                 }
1126                         }
1127                 }
1128         }
1129         ${cf_cv_main_return:-return}(0);
1130 }
1131 ],
1132 [cf_cv_consistent_getenv=yes],
1133 [cf_cv_consistent_getenv=no],
1134 [cf_cv_consistent_getenv=unknown])
1135 ])
1136
1137 if test "x$cf_cv_consistent_getenv" = xno
1138 then
1139         AC_DEFINE(HAVE_CONSISTENT_GETENV,1,[Define to 1 if getenv repeatably returns the same value for a given name])
1140 fi
1141 ])dnl
1142 dnl ---------------------------------------------------------------------------
1143 dnl CF_CHECK_GNAT_VERSION version: 2 updated: 2019/12/31 08:53:54
1144 dnl ---------------------
1145 AC_DEFUN([CF_CHECK_GNAT_VERSION],
1146 [
1147 AC_REQUIRE([CF_GNAT_VERSION])
1148 case $cf_cv_gnat_version in
1149 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
1150         cf_cv_prog_gnat_correct=yes
1151         ;;
1152 (*)
1153         AC_MSG_WARN(Unsupported GNAT version $cf_cv_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1154         cf_cv_prog_gnat_correct=no
1155         ;;
1156 esac
1157 ])
1158 dnl ---------------------------------------------------------------------------
1159 dnl CF_CHECK_GPM_WGETCH version: 3 updated: 2017/01/21 11:06:25
1160 dnl -------------------
1161 dnl Check if GPM is already linked with curses.  If so - and if the linkage
1162 dnl is not "weak" - warn about this because it can create problems linking
1163 dnl applications with ncurses.
1164 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
1165 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
1166
1167 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
1168 cf_cv_check_gpm_wgetch=unknown
1169 if test "$cross_compiling" != yes ; then
1170
1171 cat >conftest.$ac_ext <<CF_EOF
1172 #include <gpm.h>
1173 int main(void)
1174 {
1175         Gpm_Wgetch();
1176         ${cf_cv_main_return:-return}(0);
1177 }
1178 CF_EOF
1179
1180         cf_save_LIBS="$LIBS"
1181         # This only works if we can look at the symbol table.  If a shared
1182         # library is stripped for install, we cannot use that.  So we're forced
1183         # to rely on the static library, noting that some packagers may not
1184         # include it.
1185         LIBS="-static -lgpm -dynamic $LIBS"
1186         if AC_TRY_EVAL(ac_compile) ; then
1187                 if AC_TRY_EVAL(ac_link) ; then
1188                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
1189                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
1190                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
1191                 fi
1192         fi
1193         rm -rf conftest*
1194         LIBS="$cf_save_LIBS"
1195 fi
1196 ])
1197
1198 if test "$cf_cv_check_gpm_wgetch" != yes ; then
1199         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
1200 fi
1201 ])])dnl
1202 dnl ---------------------------------------------------------------------------
1203 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
1204 dnl ------------------------
1205 dnl Show the version of libtool
1206 dnl
1207 dnl Save the version in a cache variable - this is not entirely a good thing,
1208 dnl but the version string from libtool is very ugly, and for bug reports it
1209 dnl might be useful to have the original string.
1210 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
1211 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
1212 then
1213         AC_MSG_CHECKING(version of $LIBTOOL)
1214         CF_LIBTOOL_VERSION
1215         AC_MSG_RESULT($cf_cv_libtool_version)
1216         if test -z "$cf_cv_libtool_version" ; then
1217                 AC_MSG_ERROR(This is not GNU libtool)
1218         fi
1219 else
1220         AC_MSG_ERROR(GNU libtool has not been found)
1221 fi
1222 ])dnl
1223 dnl ---------------------------------------------------------------------------
1224 dnl CF_CHECK_WCHAR_H version: 2 updated: 2017/01/21 11:06:25
1225 dnl ----------------
1226 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
1227 AC_DEFUN([CF_CHECK_WCHAR_H],[
1228 AC_CHECK_HEADERS( \
1229 wchar.h \
1230 wctype.h \
1231 )
1232 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1233 AC_TRY_COMPILE(
1234 [
1235 #include <stdlib.h>
1236 #ifdef HAVE_WCHAR_H
1237 #include <wchar.h>
1238 #endif
1239 #ifdef HAVE_WCTYPE_H
1240 #include <wctype.h>
1241 #endif
1242 ],[
1243         wint_t foo = 0;
1244         int bar = iswpunct(foo)],
1245         [cf_cv_wchar_h_okay=yes],
1246         [cf_cv_wchar_h_okay=no])])
1247
1248 if test $cf_cv_wchar_h_okay = no
1249 then
1250         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1251 fi
1252 ])dnl
1253 dnl ---------------------------------------------------------------------------
1254 dnl CF_CHECK_WCWIDTH_GRAPHICS version: 1 updated: 2015/12/19 17:47:56
1255 dnl -------------------------
1256 dnl Most "modern" terminal emulators are based to some degree on VT100, and
1257 dnl should support line-drawing.  Even with Unicode.  There is a problem.
1258 dnl
1259 dnl While most of the VT100 graphics characters were incorporated into Unicode,
1260 dnl all of those were combined into a page of useful graphics characters.
1261 dnl
1262 dnl So far, so good.
1263 dnl
1264 dnl However, while they are useful, there are other considerations.  CJK
1265 dnl is (because of poor device resolution) often rendered as double-width
1266 dnl characters.  So... for these generally-useful characters, what should
1267 dnl be the width (to make them consistent with adjacent characters)?
1268 dnl
1269 dnl The obvious choice would have been to make this locale-dependent, and use
1270 dnl wcwidth() to tell applications what the actual width is.  That was too
1271 dnl obvious.  Instead, we have a slew of "ambiguous-width" characters.
1272 dnl See for example
1273 dnl             http://www.unicode.org/reports/tr11/tr11-29.html
1274 dnl             http://www.cl.cam.ac.uk/~mgk25/ucs/scw-proposal.html
1275 dnl
1276 dnl The EastAsianWidth-6.2.0.txt file from the Unicode organization lists
1277 dnl more than 22,000 characters, with 1281 of those as ambiguous-width.  For
1278 dnl instance, it lists half (44/96) of the Latin-1 characters as
1279 dnl ambiguous-width.  Also, all of the box-characters at 0x2500 are ambiguous.
1280 dnl
1281 dnl What this means for the implementor is that on some systems wcwidth() can
1282 dnl give bad advice.  On Solaris, some of the ambiguous widths are returned as
1283 dnl 1 (the Latin-1 characters), while others are returned as 2 (line-drawing
1284 dnl characters).  These do not necessarily match the behavior of the terminal
1285 dnl emulator.  xterm, for instance, does an optional startup check to find if
1286 dnl this problem (or similar) exists with the system's locale tables, rejecting
1287 dnl them if they are too unreliable.
1288 AC_DEFUN([CF_CHECK_WCWIDTH_GRAPHICS],[
1289 AC_CACHE_CHECK(if wcwidth agrees graphics are single-width, cf_cv_wcwidth_graphics,[
1290 cat >conftest.in <<CF_EOF
1291 -       VT100 symbols
1292 0x250c  upper left corner
1293 0x2514  lower left corner
1294 0x2510  upper right corner
1295 0x2518  lower right corner
1296 0x251c  tee pointing left
1297 0x2524  tee pointing right
1298 0x2534  tee pointing up
1299 0x252c  tee pointing down
1300 0x2500  horizontal line
1301 0x2502  vertical line
1302 0x253c  large plus or crossover
1303 0x23ba  scan line 1
1304 0x23bd  scan line 9
1305 0x25c6  diamond
1306 0x2592  checker board (stipple)
1307 0x00b0  degree symbol
1308 0x00b1  plus/minus
1309 0x00b7  bullet
1310 -       Teletype 5410v1 symbols
1311 0x2190  arrow pointing left
1312 0x2192  arrow pointing right
1313 0x2193  arrow pointing down
1314 0x2191  arrow pointing up
1315 0x2592  board of squares
1316 0x2603  lantern symbol
1317 0x25ae  solid square block
1318 -       these defaults were invented for ncurses
1319 0x23bb  scan line 3
1320 0x23bc  scan line 7
1321 0x2264  less-than-or-equal-to
1322 0x2265  greater-than-or-equal-to
1323 0x03c0  greek pi
1324 0x2260  not-equal
1325 0x00a3  pound-sterling symbol
1326 -       thick-line-drawing
1327 0x250f  upper left corner
1328 0x2517  lower left corner
1329 0x2513  upper right corner
1330 0x251b  lower right corner
1331 0x2523  tee pointing left
1332 0x252b  tee pointing right
1333 0x253b  tee pointing up
1334 0x2533  tee pointing down
1335 0x2501  horizontal line
1336 0x2503  vertical line
1337 0x254b  large plus or crossover
1338 -       double-line-drawing
1339 0x2554  upper left corner
1340 0x255a  lower left corner
1341 0x2557  upper right corner
1342 0x255d  lower right corner
1343 0x2563  tee pointing left
1344 0x2560  tee pointing right
1345 0x2569  tee pointing up
1346 0x2566  tee pointing down
1347 0x2550  horizontal line
1348 0x2551  vertical line
1349 0x256c  large plus or crossover
1350 CF_EOF
1351 AC_TRY_RUN([
1352 #include <locale.h>
1353 #include <stdio.h>
1354 #include <wchar.h>
1355
1356 #define MY_LEN 80
1357
1358 int
1359 main(void)
1360 {
1361         FILE *fp;
1362         int value;
1363         char buffer[MY_LEN + 1];
1364         char notes[MY_LEN + 1];
1365         int totals = 0;
1366         int passed = 0;
1367
1368         if (setlocale(LC_ALL, "en_US.UTF8") ||
1369                 setlocale(LC_ALL, "en_US.UTF-8") ||
1370                 setlocale(LC_ALL, "en_US.utf8") ||
1371                 setlocale(LC_ALL, "en_US.utf-8")) {
1372                 if ((fp = fopen("conftest.in", "r")) != 0) {
1373                         while (fgets(buffer, MY_LEN, fp) != 0) {
1374                                 if (*buffer == '-') {
1375                                         fprintf(stderr, "\t%s", buffer);
1376                                 } else if (sscanf(buffer, "%x %s", &value, notes) == 2) {
1377                                         ++totals;
1378                                         if (wcwidth(value) == 1)
1379                                                 ++passed;
1380                                         fprintf(stderr, "%d\t%s", wcwidth(value), buffer);
1381                                 } else {
1382                                         fprintf(stderr, "?\t%s", buffer);
1383                                 }
1384                         }
1385                 }
1386         }
1387         fprintf(stderr, "%d/%d passed wcwidth/graphics check\n", passed, totals);
1388         return (totals == passed) ? 0 : 1;
1389 }
1390 ],
1391 [cf_cv_wcwidth_graphics=yes],
1392 [cf_cv_wcwidth_graphics=no],
1393 [cf_cv_wcwidth_graphics=unknown])
1394 ])
1395 ])dnl
1396 dnl ---------------------------------------------------------------------------
1397 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
1398 dnl -----------------
1399 dnl Check if the given compiler is really clang.  clang's C driver defines
1400 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1401 dnl not ignore some gcc options.
1402 dnl
1403 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1404 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1405 dnl the wrappers for gcc and g++ warnings.
1406 dnl
1407 dnl $1 = GCC (default) or GXX
1408 dnl $2 = CLANG_COMPILER (default)
1409 dnl $3 = CFLAGS (default) or CXXFLAGS
1410 AC_DEFUN([CF_CLANG_COMPILER],[
1411 ifelse([$2],,CLANG_COMPILER,[$2])=no
1412
1413 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1414         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1415         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1416         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
1417         AC_TRY_COMPILE([],[
1418 #ifdef __clang__
1419 #else
1420 make an error
1421 #endif
1422 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1423 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
1424 ],[])
1425         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1426         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1427 fi
1428 ])
1429 dnl ---------------------------------------------------------------------------
1430 dnl CF_CONST_X_STRING version: 3 updated: 2020/01/11 18:39:22
1431 dnl -----------------
1432 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
1433 dnl character-strings.
1434 dnl
1435 dnl It is ambiguous because the specification accommodated the pre-ANSI
1436 dnl compilers bundled by more than one vendor in lieu of providing a standard C
1437 dnl compiler other than by costly add-ons.  Because of this, the specification
1438 dnl did not take into account the use of const for telling the compiler that
1439 dnl string literals would be in readonly memory.
1440 dnl
1441 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
1442 dnl let the compiler decide how to represent Xt's strings which were #define'd.
1443 dnl That does not solve the problem of using the block of Xt's strings which
1444 dnl are compiled into the library (and is less efficient than one might want).
1445 dnl
1446 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
1447 dnl when compiling the library and compiling using the library, to tell the
1448 dnl compiler that String is const.
1449 AC_DEFUN([CF_CONST_X_STRING],
1450 [
1451 AC_REQUIRE([AC_PATH_XTRA])
1452
1453 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
1454
1455 AC_TRY_COMPILE(
1456 [
1457 #include <stdlib.h>
1458 #include <X11/Intrinsic.h>
1459 ],
1460 [String foo = malloc(1)],[
1461
1462 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
1463         AC_TRY_COMPILE(
1464                 [
1465 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
1466 #undef  XTSTRINGDEFINES /* X11R5 and later */
1467 #include <stdlib.h>
1468 #include <X11/Intrinsic.h>
1469                 ],[String foo = malloc(1); *foo = 0],[
1470                         cf_cv_const_x_string=no
1471                 ],[
1472                         cf_cv_const_x_string=yes
1473                 ])
1474 ])
1475
1476 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
1477
1478 case $cf_cv_const_x_string in
1479 (no)
1480         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
1481         ;;
1482 (*)
1483         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
1484         ;;
1485 esac
1486
1487 ])
1488 ])dnl
1489 dnl ---------------------------------------------------------------------------
1490 dnl CF_CPP_PARAM_INIT version: 7 updated: 2017/01/21 11:06:25
1491 dnl -----------------
1492 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1493 dnl is a late feature for the standard and is not in some recent compilers
1494 dnl (1999/9/11).
1495 AC_DEFUN([CF_CPP_PARAM_INIT],
1496 [
1497 if test -n "$CXX"; then
1498 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1499         AC_LANG_SAVE
1500         AC_LANG_CPLUSPLUS
1501         AC_TRY_RUN([
1502 class TEST {
1503 private:
1504         int value;
1505 public:
1506         TEST(int x = 1);
1507         ~TEST();
1508 };
1509
1510 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1511 {
1512         value = x;
1513 }
1514 int main(void) { }
1515 ],
1516         [cf_cv_cpp_param_init=yes],
1517         [cf_cv_cpp_param_init=no],
1518         [cf_cv_cpp_param_init=unknown])
1519         AC_LANG_RESTORE
1520 ])
1521 fi
1522 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1523 ])dnl
1524 dnl ---------------------------------------------------------------------------
1525 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1526 dnl ------------------
1527 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1528 dnl not be supported in g++ before 3.0
1529 AC_DEFUN([CF_CPP_STATIC_CAST],
1530 [
1531 if test -n "$CXX"; then
1532
1533 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1534         AC_LANG_SAVE
1535         AC_LANG_CPLUSPLUS
1536
1537         AC_TRY_COMPILE([
1538 class NCursesPanel
1539 {
1540 public:
1541   NCursesPanel(int nlines,
1542                int ncols,
1543                int begin_y = 0,
1544                int begin_x = 0)
1545   {
1546   }
1547   NCursesPanel();
1548   ~NCursesPanel();
1549 };
1550
1551 template<class T> class NCursesUserPanel : public NCursesPanel
1552 {
1553 public:
1554   NCursesUserPanel (int nlines,
1555                     int ncols,
1556                     int begin_y = 0,
1557                     int begin_x = 0,
1558                     const T* p_UserData = static_cast<T*>(0))
1559     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1560   {
1561   };
1562   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1563   {
1564   };
1565
1566   virtual ~NCursesUserPanel() {};
1567 };
1568 ],[
1569         const char* p_UserData = static_cast<char*>(0)],
1570         [cf_cv_cpp_static_cast=yes],
1571         [cf_cv_cpp_static_cast=no])
1572
1573         AC_LANG_RESTORE
1574 ])
1575
1576 fi
1577
1578 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1579 ])dnl
1580 dnl ---------------------------------------------------------------------------
1581 dnl CF_CXX_AR_FLAGS version: 2 updated: 2015/04/17 21:13:04
1582 dnl ---------------
1583 dnl Setup special archiver flags for given compilers.
1584 AC_DEFUN([CF_CXX_AR_FLAGS],[
1585         CXX_AR='$(AR)'
1586         CXX_ARFLAGS='$(ARFLAGS)'
1587         case $cf_cv_system_name in
1588         (irix*)
1589             if test "$GXX" != yes ; then
1590                 CXX_AR='$(CXX)'
1591                 CXX_ARFLAGS='-ar -o'
1592             fi
1593             ;;
1594         (sco3.2v5*)
1595             CXXLDFLAGS="-u main"
1596             ;;
1597         (solaris2*)
1598             if test "$GXX" != yes ; then
1599                 CXX_AR='$(CXX)'
1600                 CXX_ARFLAGS='-xar -o'
1601             fi
1602             ;;
1603         esac
1604         AC_SUBST(CXXLDFLAGS)
1605         AC_SUBST(CXX_AR)
1606         AC_SUBST(CXX_ARFLAGS)
1607 ])dnl
1608 dnl ---------------------------------------------------------------------------
1609 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1610 dnl -------------------------
1611 dnl For c++, check if iostream uses "std::" namespace.
1612 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1613 AC_CHECK_HEADERS(iostream)
1614 if test x"$ac_cv_header_iostream" = xyes ; then
1615         AC_MSG_CHECKING(if iostream uses std-namespace)
1616         AC_TRY_COMPILE([
1617 #include <iostream>
1618 using std::endl;
1619 using std::cerr;],[
1620 cerr << "testing" << endl;
1621 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1622         AC_MSG_RESULT($cf_iostream_namespace)
1623         if test "$cf_iostream_namespace" = yes ; then
1624                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1625         fi
1626 fi
1627 ])dnl
1628 dnl ---------------------------------------------------------------------------
1629 dnl CF_C_INLINE version: 6 updated: 2019/09/07 13:38:36
1630 dnl -----------
1631 dnl Check if the C compiler supports "inline".
1632 dnl $1 is the name of a shell variable to set if inline is supported
1633 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1634 AC_DEFUN([CF_C_INLINE],[
1635 AC_REQUIRE([CF_GCC_VERSION])
1636 AC_C_INLINE
1637 $1=
1638 if test "$ac_cv_c_inline" != no ; then
1639         $1=inline
1640         if test "$INTEL_COMPILER" = yes
1641         then
1642                 :
1643         elif test "$CLANG_COMPILER" = yes
1644         then
1645                 :
1646         elif test "$GCC" = yes
1647         then
1648                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1649                 cf_save_CFLAGS=$CFLAGS
1650                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1651                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1652                 [${cf_cv_main_return:-return} foo()],
1653                 [cf_cv_gcc_inline=yes],
1654                 [cf_cv_gcc_inline=no])
1655                 CFLAGS=$cf_save_CFLAGS
1656                 ])
1657                 if test "$cf_cv_gcc_inline" = yes ; then
1658                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1659                 fi
1660         fi
1661 fi
1662 AC_SUBST($1)
1663 ])dnl
1664 dnl ---------------------------------------------------------------------------
1665 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1666 dnl ----------
1667 dnl "dirname" is not portable, so we fake it with a shell script.
1668 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1669 dnl ---------------------------------------------------------------------------
1670 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1671 dnl ---------------
1672 AC_DEFUN([CF_DIRS_TO_MAKE],
1673 [
1674 DIRS_TO_MAKE="lib"
1675 for cf_item in $cf_list_models
1676 do
1677         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1678         for cf_item2 in $DIRS_TO_MAKE
1679         do
1680                 test $cf_item2 = $cf_subdir && break
1681         done
1682         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1683 done
1684 for cf_dir in $DIRS_TO_MAKE
1685 do
1686         test ! -d $cf_dir && mkdir $cf_dir
1687 done
1688 AC_SUBST(DIRS_TO_MAKE)
1689 ])dnl
1690 dnl ---------------------------------------------------------------------------
1691 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1692 dnl ---------------
1693 dnl You can always use "make -n" to see the actual options, but it's hard to
1694 dnl pick out/analyze warning messages when the compile-line is long.
1695 dnl
1696 dnl Sets:
1697 dnl     ECHO_LT - symbol to control if libtool is verbose
1698 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1699 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1700 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1701 dnl     ECHO_CC - symbol to put before any "cc" line
1702 dnl
1703 AC_DEFUN([CF_DISABLE_ECHO],[
1704 AC_MSG_CHECKING(if you want to see long compiling messages)
1705 CF_ARG_DISABLE(echo,
1706         [  --disable-echo          do not display "compiling" commands],
1707         [
1708         ECHO_LT='--silent'
1709         ECHO_LD='@echo linking [$]@;'
1710         RULE_CC='@echo compiling [$]<'
1711         SHOW_CC='@echo compiling [$]@'
1712         ECHO_CC='@'
1713 ],[
1714         ECHO_LT=''
1715         ECHO_LD=''
1716         RULE_CC=''
1717         SHOW_CC=''
1718         ECHO_CC=''
1719 ])
1720 AC_MSG_RESULT($enableval)
1721 AC_SUBST(ECHO_LT)
1722 AC_SUBST(ECHO_LD)
1723 AC_SUBST(RULE_CC)
1724 AC_SUBST(SHOW_CC)
1725 AC_SUBST(ECHO_CC)
1726 ])dnl
1727 dnl ---------------------------------------------------------------------------
1728 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1729 dnl ------------------------
1730 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1731 AC_MSG_CHECKING(if we want to use GNAT projects)
1732 CF_ARG_DISABLE(gnat-projects,
1733         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1734         [enable_gnat_projects=no],
1735         [enable_gnat_projects=yes])
1736 AC_MSG_RESULT($enable_gnat_projects)
1737 ])dnl
1738 dnl ---------------------------------------------------------------------------
1739 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1740 dnl ----------------
1741 dnl Combine no-leak checks with the libraries or tools that are used for the
1742 dnl checks.
1743 AC_DEFUN([CF_DISABLE_LEAKS],[
1744
1745 AC_REQUIRE([CF_WITH_DMALLOC])
1746 AC_REQUIRE([CF_WITH_DBMALLOC])
1747 AC_REQUIRE([CF_WITH_VALGRIND])
1748
1749 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1750 AC_ARG_ENABLE(leaks,
1751         [  --disable-leaks         test: free permanent memory, analyze leaks],
1752         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1753         : ${with_no_leaks:=no})
1754 AC_MSG_RESULT($with_no_leaks)
1755
1756 if test "$with_no_leaks" = yes ; then
1757         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1758         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1759 fi
1760 ])dnl
1761 dnl ---------------------------------------------------------------------------
1762 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
1763 dnl --------------------------
1764 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1765 dnl the older "-version-info" feature.  The newer feature allows us to use
1766 dnl version numbering on shared libraries which make them compatible with
1767 dnl various systems.
1768 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1769 [
1770 AC_MSG_CHECKING(if libtool -version-number should be used)
1771 CF_ARG_DISABLE(libtool-version,
1772         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1773         [cf_libtool_version=no],
1774         [cf_libtool_version=yes])
1775 AC_MSG_RESULT($cf_libtool_version)
1776
1777 if test "$cf_libtool_version" = yes ; then
1778         LIBTOOL_VERSION="-version-number"
1779 else
1780         LIBTOOL_VERSION="-version-info"
1781         case "x$VERSION" in
1782         (x)
1783                 AC_MSG_WARN(VERSION was not set)
1784                 ;;
1785         (x*.*.*)
1786                 ABI_VERSION="$VERSION"
1787                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1788                 ;;
1789         (x*:*:*)
1790                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
1791                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1792                 ;;
1793         (*)
1794                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
1795                 ;;
1796         esac
1797 fi
1798
1799 AC_SUBST(ABI_VERSION)
1800 AC_SUBST(LIBTOOL_VERSION)
1801 ])dnl
1802 dnl ---------------------------------------------------------------------------
1803 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1804 dnl ---------------------
1805 dnl The rpath-hack makes it simpler to build programs, particularly with the
1806 dnl *BSD ports which may have essential libraries in unusual places.  But it
1807 dnl can interfere with building an executable for the base system.  Use this
1808 dnl option in that case.
1809 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1810 [
1811 AC_MSG_CHECKING(if rpath-hack should be disabled)
1812 CF_ARG_DISABLE(rpath-hack,
1813         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1814         [cf_disable_rpath_hack=yes],
1815         [cf_disable_rpath_hack=no])
1816 AC_MSG_RESULT($cf_disable_rpath_hack)
1817 if test "$cf_disable_rpath_hack" = no ; then
1818         CF_RPATH_HACK
1819 fi
1820 ])
1821 dnl ---------------------------------------------------------------------------
1822 dnl CF_ENABLE_BROKEN_LINKER version: 1 updated: 2020/02/08 15:59:30
1823 dnl -----------------------
1824 dnl Some linkers cannot reference a data-only object.  Cygwin used to be one.
1825 dnl This usually follows CF_LINK_DATAONLY, but is not required in case we need
1826 dnl an unconditional feature.
1827 AC_DEFUN([CF_ENABLE_BROKEN_LINKER],[
1828
1829 AC_MSG_CHECKING(if you want broken-linker support code)
1830 AC_ARG_ENABLE(broken_linker,
1831         [  --enable-broken_linker  compile with broken-linker support code],
1832         [with_broken_linker=$enableval],
1833         [with_broken_linker=no])
1834 AC_MSG_RESULT($with_broken_linker)
1835
1836 : ${BROKEN_LINKER:=0}
1837 if test "x$with_broken_linker" = xyes ; then
1838         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
1839         BROKEN_LINKER=1
1840 fi
1841 AC_SUBST(BROKEN_LINKER)
1842 ])dnl
1843 dnl ---------------------------------------------------------------------------
1844 dnl CF_ENABLE_PC_FILES version: 13 updated: 2015/11/01 05:27:39
1845 dnl ------------------
1846 dnl This is the "--enable-pc-files" option, which is available if there is a
1847 dnl pkg-config configuration on the local machine.
1848 AC_DEFUN([CF_ENABLE_PC_FILES],[
1849 AC_REQUIRE([CF_PKG_CONFIG])
1850 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1851
1852 if test "x$PKG_CONFIG" != xnone
1853 then
1854         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1855 else
1856         AC_MSG_CHECKING(if we should install .pc files)
1857 fi
1858
1859 AC_ARG_ENABLE(pc-files,
1860         [  --enable-pc-files       generate and install .pc files for pkg-config],
1861         [enable_pc_files=$enableval],
1862         [enable_pc_files=no])
1863 AC_MSG_RESULT($enable_pc_files)
1864
1865 if test "x$enable_pc_files" != xno
1866 then
1867         MAKE_PC_FILES=
1868         case "x$PKG_CONFIG_LIBDIR" in
1869         (xno|xyes)
1870                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
1871                 ;;
1872         (*)
1873                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1874                 ;;
1875         esac
1876 else
1877         MAKE_PC_FILES="#"
1878 fi
1879 AC_SUBST(MAKE_PC_FILES)
1880 ])dnl
1881 dnl ---------------------------------------------------------------------------
1882 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1883 dnl ---------------
1884 dnl Check if the rpath option should be used, setting cache variable
1885 dnl cf_cv_enable_rpath if so.
1886 AC_DEFUN([CF_ENABLE_RPATH],
1887 [
1888 AC_MSG_CHECKING(if rpath option should be used)
1889 AC_ARG_ENABLE(rpath,
1890 [  --enable-rpath          use rpath option when generating shared libraries],
1891 [cf_cv_enable_rpath=$enableval],
1892 [cf_cv_enable_rpath=no])
1893 AC_MSG_RESULT($cf_cv_enable_rpath)
1894 ])dnl
1895 dnl ---------------------------------------------------------------------------
1896 dnl CF_ENABLE_STRING_HACKS version: 5 updated: 2016/10/08 17:34:11
1897 dnl ----------------------
1898 dnl On a few platforms, the compiler and/or loader nags with untruthful
1899 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1900 dnl and implying that most uses of the recommended alternatives are correct.
1901 dnl
1902 dnl Factually speaking, no one has actually counted the number of uses of these
1903 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1904 dnl instances are meaningless compared to the hundreds of millions of lines of
1905 dnl existing C code.
1906 dnl
1907 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1908 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1909 dnl standard - but evolved through phases, and older implementations are likely
1910 dnl to yield surprising results, as documented in manpages on various systems.
1911 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1912 [
1913 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1914 AC_ARG_ENABLE(string-hacks,
1915         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1916         [with_string_hacks=$enableval],
1917         [with_string_hacks=no])
1918 AC_MSG_RESULT($with_string_hacks)
1919
1920 if test "x$with_string_hacks" = "xyes"; then
1921         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1922         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1923         AC_CHECK_FUNC(strlcat,[
1924                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1925                 ],[
1926                 AC_CHECK_LIB(bsd,strlcat,[
1927                         CF_ADD_LIB(bsd)
1928                         AC_CHECK_HEADERS(bsd/string.h)
1929                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1930                         ])
1931                 ])
1932         AC_CHECK_FUNCS( strlcpy snprintf )
1933 fi
1934 ])dnl
1935 dnl ---------------------------------------------------------------------------
1936 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1937 dnl --------
1938 dnl Check if 'errno' is declared in <errno.h>
1939 AC_DEFUN([CF_ERRNO],
1940 [
1941 CF_CHECK_ERRNO(errno)
1942 ])dnl
1943 dnl ---------------------------------------------------------------------------
1944 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1945 dnl ---------------
1946 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1947 dnl math.h and builtin.h, only for ncurses
1948 AC_DEFUN([CF_ETIP_DEFINES],
1949 [
1950 AC_MSG_CHECKING(for special defines needed for etip.h)
1951 cf_save_CXXFLAGS="$CXXFLAGS"
1952 cf_result="none"
1953
1954 # etip.h includes ncurses.h which includes ncurses_dll.h
1955 # But ncurses_dll.h is generated - fix here.
1956 test -d include || mkdir include
1957 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1958
1959 for cf_math in "" MATH_H
1960 do
1961 for cf_excp in "" MATH_EXCEPTION
1962 do
1963         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1964         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1965         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1966 AC_TRY_COMPILE([
1967 #include <etip.h.in>
1968 ],[],[
1969         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1970         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1971         cf_result="$cf_math $cf_excp"
1972         break 2
1973 ],[])
1974 done
1975 done
1976 AC_MSG_RESULT($cf_result)
1977 CXXFLAGS="$cf_save_CXXFLAGS"
1978 ])
1979 dnl ---------------------------------------------------------------------------
1980 dnl CF_FIND_LINKAGE version: 21 updated: 2018/06/20 20:23:13
1981 dnl ---------------
1982 dnl Find a library (specifically the linkage used in the code fragment),
1983 dnl searching for it if it is not already in the library path.
1984 dnl See also CF_ADD_SEARCHPATH.
1985 dnl
1986 dnl Parameters (4-on are optional):
1987 dnl     $1 = headers for library entrypoint
1988 dnl     $2 = code fragment for library entrypoint
1989 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1990 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1991 dnl     $5 = action to perform if not successful
1992 dnl     $6 = module name, if not the same as the library name
1993 dnl     $7 = extra libraries
1994 dnl
1995 dnl Sets these variables:
1996 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1997 dnl     $cf_cv_header_path_$3 - include-directory if needed
1998 dnl     $cf_cv_library_path_$3 - library-directory if needed
1999 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
2000 AC_DEFUN([CF_FIND_LINKAGE],[
2001
2002 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
2003 # will be set on completion of the AC_TRY_LINK below.
2004 cf_cv_header_path_$3=
2005 cf_cv_library_path_$3=
2006
2007 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
2008
2009 cf_save_LIBS="$LIBS"
2010
2011 AC_TRY_LINK([$1],[$2],[
2012         cf_cv_find_linkage_$3=yes
2013         cf_cv_header_path_$3=/usr/include
2014         cf_cv_library_path_$3=/usr/lib
2015 ],[
2016
2017 LIBS="-l$3 $7 $cf_save_LIBS"
2018
2019 AC_TRY_LINK([$1],[$2],[
2020         cf_cv_find_linkage_$3=yes
2021         cf_cv_header_path_$3=/usr/include
2022         cf_cv_library_path_$3=/usr/lib
2023         cf_cv_library_file_$3="-l$3"
2024 ],[
2025         cf_cv_find_linkage_$3=no
2026         LIBS="$cf_save_LIBS"
2027
2028         CF_VERBOSE(find linkage for $3 library)
2029         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
2030
2031         cf_save_CPPFLAGS="$CPPFLAGS"
2032         cf_test_CPPFLAGS="$CPPFLAGS"
2033
2034         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
2035         for cf_cv_header_path_$3 in $cf_search
2036         do
2037                 if test -d $cf_cv_header_path_$3 ; then
2038                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
2039                         CPPFLAGS="$cf_save_CPPFLAGS"
2040                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
2041                         AC_TRY_COMPILE([$1],[$2],[
2042                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
2043                                 cf_cv_find_linkage_$3=maybe
2044                                 cf_test_CPPFLAGS="$CPPFLAGS"
2045                                 break],[
2046                                 CPPFLAGS="$cf_save_CPPFLAGS"
2047                                 ])
2048                 fi
2049         done
2050
2051         if test "$cf_cv_find_linkage_$3" = maybe ; then
2052
2053                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
2054
2055                 cf_save_LIBS="$LIBS"
2056                 cf_save_LDFLAGS="$LDFLAGS"
2057
2058                 ifelse([$6],,,[
2059                 CPPFLAGS="$cf_test_CPPFLAGS"
2060                 LIBS="-l$3 $7 $cf_save_LIBS"
2061                 AC_TRY_LINK([$1],[$2],[
2062                         CF_VERBOSE(... found $3 library in system)
2063                         cf_cv_find_linkage_$3=yes])
2064                         CPPFLAGS="$cf_save_CPPFLAGS"
2065                         LIBS="$cf_save_LIBS"
2066                         ])
2067
2068                 if test "$cf_cv_find_linkage_$3" != yes ; then
2069                         CF_LIBRARY_PATH(cf_search,$3)
2070                         for cf_cv_library_path_$3 in $cf_search
2071                         do
2072                                 if test -d $cf_cv_library_path_$3 ; then
2073                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
2074                                         CPPFLAGS="$cf_test_CPPFLAGS"
2075                                         LIBS="-l$3 $7 $cf_save_LIBS"
2076                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
2077                                         AC_TRY_LINK([$1],[$2],[
2078                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
2079                                         cf_cv_find_linkage_$3=yes
2080                                         cf_cv_library_file_$3="-l$3"
2081                                         break],[
2082                                         CPPFLAGS="$cf_save_CPPFLAGS"
2083                                         LIBS="$cf_save_LIBS"
2084                                         LDFLAGS="$cf_save_LDFLAGS"
2085                                         ])
2086                                 fi
2087                         done
2088                         CPPFLAGS="$cf_save_CPPFLAGS"
2089                         LDFLAGS="$cf_save_LDFLAGS"
2090                 fi
2091
2092         else
2093                 cf_cv_find_linkage_$3=no
2094         fi
2095         ],$7)
2096 ])
2097
2098 LIBS="$cf_save_LIBS"
2099
2100 if test "$cf_cv_find_linkage_$3" = yes ; then
2101 ifelse([$4],,[
2102         CF_ADD_INCDIR($cf_cv_header_path_$3)
2103         CF_ADD_LIBDIR($cf_cv_library_path_$3)
2104         CF_ADD_LIB($3)
2105 ],[$4])
2106 else
2107 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
2108 fi
2109 ])dnl
2110 dnl ---------------------------------------------------------------------------
2111 dnl CF_FIND_SUB_INCDIR version: 2 updated: 2015/04/17 21:13:04
2112 dnl ------------------
2113 dnl Find an include-directory with the given leaf-name.  This is useful for
2114 dnl example with FreeBSD ports, which use this convention to distinguish
2115 dnl different versions of the same port.
2116 AC_DEFUN([CF_FIND_SUB_INCDIR],[
2117         CF_SUBDIR_PATH(cf_search,$1,include)
2118         for cf_item in $cf_search
2119         do
2120                 case $cf_item in
2121                 (*/$1)
2122                         CF_ADD_INCDIR($cf_item)
2123                         ;;
2124                 esac
2125         done
2126 ])dnl
2127 dnl ---------------------------------------------------------------------------
2128 dnl CF_FIND_SUB_LIBDIR version: 2 updated: 2015/04/17 21:13:04
2129 dnl ------------------
2130 dnl Find a library-directory with the given leaf-name.  This is useful for
2131 dnl example with FreeBSD ports, which use this convention to distinguish
2132 dnl different versions of the same port.
2133 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
2134         CF_SUBDIR_PATH(cf_search,$1,lib)
2135         for cf_item in $cf_search
2136         do
2137                 case $cf_item in
2138                 (*/$1)
2139                         CF_ADD_LIBDIR($cf_item)
2140                         ;;
2141                 esac
2142         done
2143 ])dnl
2144 dnl ---------------------------------------------------------------------------
2145 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
2146 dnl -----------------
2147 dnl make ADAFLAGS consistent with CFLAGS
2148 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
2149         AC_MSG_CHECKING(optimization options for ADAFLAGS)
2150         case "$CFLAGS" in
2151         (*-g*)
2152                 CF_ADD_ADAFLAGS(-g)
2153                 ;;
2154         esac
2155         case "$CFLAGS" in
2156         (*-O*)
2157                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
2158                 CF_ADD_ADAFLAGS($cf_O_flag)
2159                 ;;
2160         esac
2161         AC_MSG_RESULT($ADAFLAGS)
2162 ])dnl
2163 dnl ---------------------------------------------------------------------------
2164 dnl CF_FOPEN_BIN_R version: 2 updated: 2019/12/31 08:53:54
2165 dnl --------------
2166 dnl Check if fopen works when the "b" (binary) flag is added to the mode
2167 dnl parameter.  POSIX ignores the "b", which c89 specified.  Some very old
2168 dnl systems do not accept it.
2169 AC_DEFUN([CF_FOPEN_BIN_R],[
2170 AC_CACHE_CHECK(if fopen accepts explicit binary mode,cf_cv_fopen_bin_r,[
2171         AC_TRY_RUN([
2172 #include <stdio.h>
2173 int main(void) {
2174         FILE *fp = fopen("conftest.tmp", "wb");
2175         int rc = 0;
2176         if (fp != 0) {
2177                 int p, q;
2178                 for (p = 0; p < 256; ++p) {
2179                         fputc(p, fp);
2180                 }
2181                 fclose(fp);
2182                 fp = fopen("conftest.tmp", "rb");
2183                 if (fp != 0) {
2184                         for (p = 0; p < 256; ++p) {
2185                                 q = fgetc(fp);
2186                                 if (q != p) {
2187                                         rc = 1;
2188                                         break;
2189                                 }
2190                         }
2191                 } else {
2192                         rc = 1;
2193                 }
2194         } else {
2195                 rc = 1;
2196         }
2197         ${cf_cv_main_return:-return} (rc);
2198 }
2199 ],
2200                 [cf_cv_fopen_bin_r=yes],
2201                 [cf_cv_fopen_bin_r=no],
2202                 [cf_cv_fopen_bin_r=unknown])
2203 ])
2204 test "x$cf_cv_fopen_bin_r" != xno && AC_DEFINE(USE_FOPEN_BIN_R,1,[Define to 1 if fopen accepts explicit binary mode])
2205 ])dnl
2206 dnl ---------------------------------------------------------------------------
2207 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
2208 dnl --------------
2209 dnl Forget that we saw the given tool.
2210 AC_DEFUN([CF_FORGET_TOOL],[
2211 unset ac_cv_prog_ac_ct_$1
2212 unset ac_ct_$1
2213 unset $1
2214 ])dnl
2215 dnl ---------------------------------------------------------------------------
2216 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
2217 dnl -------------
2218 dnl Test for dlsym() and related functions, as well as libdl.
2219 dnl
2220 dnl Sets
2221 dnl     $cf_have_dlsym
2222 dnl     $cf_have_libdl
2223 AC_DEFUN([CF_FUNC_DLSYM],[
2224 cf_have_dlsym=no
2225 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
2226
2227 cf_have_libdl=no
2228 AC_CHECK_LIB(dl,dlsym,[
2229         cf_have_dlsym=yes
2230         cf_have_libdl=yes])])
2231
2232 if test "$cf_have_dlsym" = yes ; then
2233         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
2234
2235         AC_MSG_CHECKING(whether able to link to dl*() functions)
2236         AC_TRY_LINK([#include <dlfcn.h>],[
2237                 void *obj;
2238                 if ((obj = dlopen("filename", 0)) != 0) {
2239                         if (dlsym(obj, "symbolname") == 0) {
2240                         dlclose(obj);
2241                         }
2242                 }],[
2243                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
2244                 AC_MSG_ERROR(Cannot link test program for libdl)])
2245         AC_MSG_RESULT(ok)
2246 else
2247         AC_MSG_ERROR(Cannot find dlsym function)
2248 fi
2249 ])
2250 dnl ---------------------------------------------------------------------------
2251 dnl CF_FUNC_MEMMOVE version: 9 updated: 2017/01/21 11:06:25
2252 dnl ---------------
2253 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
2254 dnl is found, add our own version of memmove to the list of objects.
2255 AC_DEFUN([CF_FUNC_MEMMOVE],
2256 [
2257 AC_CHECK_FUNC(memmove,,[
2258 AC_CHECK_FUNC(bcopy,[
2259         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
2260                 AC_TRY_RUN([
2261 int main(void) {
2262         static char data[] = "abcdefghijklmnopqrstuwwxyz";
2263         char temp[40];
2264         bcopy(data, temp, sizeof(data));
2265         bcopy(temp+10, temp, 15);
2266         bcopy(temp+5, temp+15, 10);
2267         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
2268 }
2269                 ],
2270                 [cf_cv_good_bcopy=yes],
2271                 [cf_cv_good_bcopy=no],
2272                 [cf_cv_good_bcopy=unknown])
2273                 ])
2274         ],[cf_cv_good_bcopy=no])
2275         if test "$cf_cv_good_bcopy" = yes ; then
2276                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
2277         else
2278                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
2279         fi
2280 ])])dnl
2281 dnl ---------------------------------------------------------------------------
2282 dnl CF_FUNC_NANOSLEEP version: 5 updated: 2017/01/21 11:06:25
2283 dnl -----------------
2284 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
2285 dnl AIX 4.x, provide a non-working version.
2286 AC_DEFUN([CF_FUNC_NANOSLEEP],[
2287 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
2288 AC_TRY_RUN([
2289 #include <stdio.h>
2290 #include <errno.h>
2291 #include <time.h>
2292
2293 #ifdef HAVE_SYS_TIME_H
2294 #include <sys/time.h>
2295 #endif
2296
2297 int main(void) {
2298         struct timespec ts1, ts2;
2299         int code;
2300         ts1.tv_sec  = 0;
2301         ts1.tv_nsec = 750000000;
2302         ts2.tv_sec  = 0;
2303         ts2.tv_nsec = 0;
2304         errno = 0;
2305         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
2306         ${cf_cv_main_return:-return}(code != 0);
2307 }
2308 ],
2309         [cf_cv_func_nanosleep=yes],
2310         [cf_cv_func_nanosleep=no],
2311         [cf_cv_func_nanosleep=unknown])])
2312
2313 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
2314 ])
2315 dnl ---------------------------------------------------------------------------
2316 dnl CF_FUNC_OPENPTY version: 5 updated: 2015/09/12 14:46:50
2317 dnl ---------------
2318 dnl Check for openpty() function, along with <pty.h> header.  It may need the
2319 dnl "util" library as well.
2320 AC_DEFUN([CF_FUNC_OPENPTY],
2321 [
2322 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
2323 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
2324         cf_save_LIBS="$LIBS"
2325         test $cf_cv_lib_util = yes && { CF_ADD_LIB(util) }
2326         for cf_header in pty.h libutil.h util.h
2327         do
2328         AC_TRY_LINK([
2329 #include <$cf_header>
2330 ],[
2331         int x = openpty((int *)0, (int *)0, (char *)0,
2332                                    (struct termios *)0, (struct winsize *)0);
2333 ],[
2334                 cf_cv_func_openpty=$cf_header
2335                 break
2336 ],[
2337                 cf_cv_func_openpty=no
2338 ])
2339         done
2340         LIBS="$cf_save_LIBS"
2341 ])
2342 ])dnl
2343 dnl ---------------------------------------------------------------------------
2344 dnl CF_FUNC_POLL version: 9 updated: 2015/10/10 13:27:32
2345 dnl ------------
2346 dnl See if the poll function really works.  Some platforms have poll(), but
2347 dnl it does not work for terminals or files.
2348 AC_DEFUN([CF_FUNC_POLL],[
2349 tty 2>&1 >/dev/null || { AC_CHECK_FUNCS(posix_openpt) }
2350 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
2351 AC_TRY_RUN([
2352 #include <stdlib.h>
2353 #include <stdio.h>
2354 #include <unistd.h>
2355 #include <fcntl.h>
2356 #ifdef HAVE_POLL_H
2357 #include <poll.h>
2358 #else
2359 #include <sys/poll.h>
2360 #endif
2361 int main(void) {
2362         struct pollfd myfds;
2363         int ret;
2364
2365         /* check for Darwin bug with respect to "devices" */
2366         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
2367         if (myfds.fd < 0)
2368                 myfds.fd = 0;
2369         myfds.events = POLLIN;
2370         myfds.revents = 0;
2371
2372         ret = poll(&myfds, 1, 100);
2373
2374         if (ret < 0 || (myfds.revents & POLLNVAL)) {
2375                 ret = -1;
2376         } else {
2377                 int fd = 0;
2378                 if (!isatty(fd)) {
2379                         fd = open("/dev/tty", 2);       /* O_RDWR */
2380                 }
2381 #ifdef HAVE_POSIX_OPENPT
2382                 if (fd < 0) {
2383                         fd = posix_openpt(O_RDWR);
2384                 }
2385 #endif
2386
2387                 if (fd >= 0) {
2388                         /* also check with standard input */
2389                         myfds.fd = fd;
2390                         myfds.events = POLLIN;
2391                         myfds.revents = 0;
2392                         ret = poll(&myfds, 1, 100);
2393                 } else {
2394                         ret = -1;
2395                 }
2396         }
2397         ${cf_cv_main_return:-return}(ret < 0);
2398 }],
2399         [cf_cv_working_poll=yes],
2400         [cf_cv_working_poll=no],
2401         [cf_cv_working_poll=unknown])])
2402 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
2403 ])dnl
2404 dnl ---------------------------------------------------------------------------
2405 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
2406 dnl ---------------
2407 dnl Some old/broken variations define tcgetattr() only as a macro in
2408 dnl termio(s).h
2409 AC_DEFUN([CF_FUNC_TERMIOS],[
2410 AC_REQUIRE([CF_STRUCT_TERMIOS])
2411 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
2412 AC_TRY_LINK([
2413 #include <sys/types.h>
2414 #ifdef HAVE_UNISTD_H
2415 #include <unistd.h>
2416 #endif
2417 #ifdef HAVE_TERMIOS_H
2418 #include <termios.h>
2419 #define TTY struct termios
2420 #else
2421 #ifdef HAVE_TERMIO_H
2422 #include <termio.h>
2423 #define TTY struct termio
2424 #endif
2425 #endif
2426 ],[
2427 TTY foo;
2428 tcgetattr(1, &foo);],
2429 [cf_cv_have_tcgetattr=yes],
2430 [cf_cv_have_tcgetattr=no])])
2431 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
2432 ])dnl
2433 dnl ---------------------------------------------------------------------------
2434 dnl CF_FUNC_VSSCANF version: 6 updated: 2015/04/18 08:56:57
2435 dnl ---------------
2436 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
2437 dnl versions of C.  It is in the GNU C library, and can often be simulated by
2438 dnl other functions.
2439 AC_DEFUN([CF_FUNC_VSSCANF],
2440 [
2441 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
2442 AC_TRY_LINK([
2443 #include <stdarg.h>
2444 #include <stdio.h>],[
2445         va_list ap;
2446         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
2447 AC_TRY_LINK([
2448 #include <stdarg.h>
2449 #include <stdio.h>],[
2450         FILE strbuf;
2451         char *str = "from";
2452
2453         strbuf._flag = _IOREAD;
2454         strbuf._ptr = strbuf._base = (unsigned char *) str;
2455         strbuf._cnt = strlen(str);
2456         strbuf._file = _NFILE;
2457         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
2458 AC_TRY_LINK([
2459 #include <stdarg.h>
2460 #include <stdio.h>],[
2461         FILE strbuf;
2462         char *str = "from";
2463
2464         strbuf._flag = _IOREAD;
2465         strbuf._ptr = strbuf._base = (unsigned char *) str;
2466         strbuf._cnt = strlen(str);
2467         strbuf._file = _NFILE;
2468         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
2469 cf_cv_func_vsscanf=no])])])])
2470
2471 case $cf_cv_func_vsscanf in
2472 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
2473 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
2474 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
2475 esac
2476
2477 ])dnl
2478 dnl ---------------------------------------------------------------------------
2479 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
2480 dnl -----------------
2481 dnl Test for availability of useful gcc __attribute__ directives to quiet
2482 dnl compiler warnings.  Though useful, not all are supported -- and contrary
2483 dnl to documentation, unrecognized directives cause older compilers to barf.
2484 AC_DEFUN([CF_GCC_ATTRIBUTES],
2485 [
2486 if test "$GCC" = yes
2487 then
2488 cat > conftest.i <<EOF
2489 #ifndef GCC_PRINTF
2490 #define GCC_PRINTF 0
2491 #endif
2492 #ifndef GCC_SCANF
2493 #define GCC_SCANF 0
2494 #endif
2495 #ifndef GCC_NORETURN
2496 #define GCC_NORETURN /* nothing */
2497 #endif
2498 #ifndef GCC_UNUSED
2499 #define GCC_UNUSED /* nothing */
2500 #endif
2501 EOF
2502 if test "$GCC" = yes
2503 then
2504         AC_CHECKING([for $CC __attribute__ directives])
2505 cat > conftest.$ac_ext <<EOF
2506 #line __oline__ "${as_me:-configure}"
2507 #include "confdefs.h"
2508 #include "conftest.h"
2509 #include "conftest.i"
2510 #if     GCC_PRINTF
2511 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
2512 #else
2513 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
2514 #endif
2515 #if     GCC_SCANF
2516 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2517 #else
2518 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2519 #endif
2520 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2521 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
2522 extern void foo(void) GCC_NORETURN;
2523 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
2524 EOF
2525         cf_printf_attribute=no
2526         cf_scanf_attribute=no
2527         for cf_attribute in scanf printf unused noreturn
2528         do
2529                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2530                 cf_directive="__attribute__(($cf_attribute))"
2531                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2532
2533                 case $cf_attribute in
2534                 (printf)
2535                         cf_printf_attribute=yes
2536                         cat >conftest.h <<EOF
2537 #define GCC_$cf_ATTRIBUTE 1
2538 EOF
2539                         ;;
2540                 (scanf)
2541                         cf_scanf_attribute=yes
2542                         cat >conftest.h <<EOF
2543 #define GCC_$cf_ATTRIBUTE 1
2544 EOF
2545                         ;;
2546                 (*)
2547                         cat >conftest.h <<EOF
2548 #define GCC_$cf_ATTRIBUTE $cf_directive
2549 EOF
2550                         ;;
2551                 esac
2552
2553                 if AC_TRY_EVAL(ac_compile); then
2554                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
2555                         cat conftest.h >>confdefs.h
2556                         case $cf_attribute in
2557                         (noreturn)
2558                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
2559                                 ;;
2560                         (printf)
2561                                 cf_value='/* nothing */'
2562                                 if test "$cf_printf_attribute" != no ; then
2563                                         cf_value='__attribute__((format(printf,fmt,var)))'
2564                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
2565                                 fi
2566                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
2567                                 ;;
2568                         (scanf)
2569                                 cf_value='/* nothing */'
2570                                 if test "$cf_scanf_attribute" != no ; then
2571                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2572                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2573                                 fi
2574                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2575                                 ;;
2576                         (unused)
2577                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2578                                 ;;
2579                         esac
2580                 fi
2581         done
2582 else
2583         fgrep define conftest.i >>confdefs.h
2584 fi
2585 rm -rf conftest*
2586 fi
2587 ])dnl
2588 dnl ---------------------------------------------------------------------------
2589 dnl CF_GCC_VERSION version: 8 updated: 2019/09/07 13:38:36
2590 dnl --------------
2591 dnl Find version of gcc, and (because icc/clang pretend to be gcc without being
2592 dnl compatible), attempt to determine if icc/clang is actually used.
2593 AC_DEFUN([CF_GCC_VERSION],[
2594 AC_REQUIRE([AC_PROG_CC])
2595 GCC_VERSION=none
2596 if test "$GCC" = yes ; then
2597         AC_MSG_CHECKING(version of $CC)
2598         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2599         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2600         AC_MSG_RESULT($GCC_VERSION)
2601 fi
2602 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2603 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2604 ])dnl
2605 dnl ---------------------------------------------------------------------------
2606 dnl CF_GCC_WARNINGS version: 37 updated: 2020/01/05 20:04:12
2607 dnl ---------------
2608 dnl Check if the compiler supports useful warning options.  There's a few that
2609 dnl we don't use, simply because they're too noisy:
2610 dnl
2611 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2612 dnl     -Winline (usually not worthwhile)
2613 dnl     -Wredundant-decls (system headers make this too noisy)
2614 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2615 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2616 dnl             is enabled for ncurses using "--enable-const".
2617 dnl     -pedantic
2618 dnl
2619 dnl Parameter:
2620 dnl     $1 is an optional list of gcc warning flags that a particular
2621 dnl             application might want to use, e.g., "no-unused" for
2622 dnl             -Wno-unused
2623 dnl Special:
2624 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2625 dnl
2626 AC_DEFUN([CF_GCC_WARNINGS],
2627 [
2628 AC_REQUIRE([CF_GCC_VERSION])
2629 if test "x$have_x" = xyes; then CF_CONST_X_STRING fi
2630 cat > conftest.$ac_ext <<EOF
2631 #line __oline__ "${as_me:-configure}"
2632 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2633 EOF
2634 if test "$INTEL_COMPILER" = yes
2635 then
2636 # The "-wdXXX" options suppress warnings:
2637 # remark #1419: external declaration in primary source file
2638 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2639 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2640 # remark #193: zero used for undefined preprocessing identifier
2641 # remark #593: variable "curs_sb_left_arrow" was set but never used
2642 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2643 # remark #869: parameter "tw" was never referenced
2644 # remark #981: operands are evaluated in unspecified order
2645 # warning #279: controlling expression is constant
2646
2647         AC_CHECKING([for $CC warning options])
2648         cf_save_CFLAGS="$CFLAGS"
2649         EXTRA_CFLAGS="-Wall"
2650         for cf_opt in \
2651                 wd1419 \
2652                 wd1683 \
2653                 wd1684 \
2654                 wd193 \
2655                 wd593 \
2656                 wd279 \
2657                 wd810 \
2658                 wd869 \
2659                 wd981
2660         do
2661                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2662                 if AC_TRY_EVAL(ac_compile); then
2663                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2664                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2665                 fi
2666         done
2667         CFLAGS="$cf_save_CFLAGS"
2668 elif test "$GCC" = yes && test "$GCC_VERSION" != "unknown"
2669 then
2670         AC_CHECKING([for $CC warning options])
2671         cf_save_CFLAGS="$CFLAGS"
2672         EXTRA_CFLAGS=
2673         cf_warn_CONST=""
2674         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2675         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2676         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2677         for cf_opt in W Wall \
2678                 Wbad-function-cast \
2679                 Wcast-align \
2680                 Wcast-qual \
2681                 Wdeclaration-after-statement \
2682                 Wextra \
2683                 Winline \
2684                 Wmissing-declarations \
2685                 Wmissing-prototypes \
2686                 Wnested-externs \
2687                 Wpointer-arith \
2688                 Wshadow \
2689                 Wstrict-prototypes \
2690                 Wundef Wno-inline $cf_gcc_warnings $cf_warn_CONST $1
2691         do
2692                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2693                 if AC_TRY_EVAL(ac_compile); then
2694                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2695                         case $cf_opt in
2696                         (Winline)
2697                                 case $GCC_VERSION in
2698                                 ([[34]].*)
2699                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2700                                         continue;;
2701                                 esac
2702                                 ;;
2703                         (Wpointer-arith)
2704                                 case $GCC_VERSION in
2705                                 ([[12]].*)
2706                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2707                                         continue;;
2708                                 esac
2709                                 ;;
2710                         esac
2711                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2712                 fi
2713         done
2714         CFLAGS="$cf_save_CFLAGS"
2715 fi
2716 rm -rf conftest*
2717
2718 AC_SUBST(EXTRA_CFLAGS)
2719 ])dnl
2720 dnl ---------------------------------------------------------------------------
2721 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
2722 dnl ----------------
2723 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2724 dnl unistd.h or (nonstandard) in getopt.h
2725 AC_DEFUN([CF_GETOPT_HEADER],
2726 [
2727 AC_HAVE_HEADERS(unistd.h getopt.h)
2728 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2729 cf_cv_getopt_header=none
2730 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2731 do
2732 AC_TRY_COMPILE([
2733 #include <$cf_header>],
2734 [int x = optind; char *y = optarg],
2735 [cf_cv_getopt_header=$cf_header
2736  break])
2737 done
2738 ])
2739 if test $cf_cv_getopt_header != none ; then
2740         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2741 fi
2742 if test $cf_cv_getopt_header = getopt.h ; then
2743         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2744 fi
2745 ])dnl
2746 dnl ---------------------------------------------------------------------------
2747 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2748 dnl -----------------
2749 AC_DEFUN([CF_GNATPREP_OPT_T],[
2750 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2751 cf_cv_gnatprep_opt_t=no
2752 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2753 ])
2754 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
2755 AC_SUBST(GNATPREP_OPTS)
2756 ])dnl
2757 dnl ---------------------------------------------------------------------------
2758 dnl CF_GNAT_GENERICS version: 4 updated: 2019/12/31 08:53:54
2759 dnl ----------------
2760 AC_DEFUN([CF_GNAT_GENERICS],
2761 [
2762 AC_REQUIRE([CF_GNAT_VERSION])
2763
2764 AC_MSG_CHECKING(if GNAT supports generics)
2765 case $cf_cv_gnat_version in
2766 (3.[[1-9]]*|[[4-9]].*)
2767         cf_gnat_generics=yes
2768         ;;
2769 (*)
2770         cf_gnat_generics=no
2771         ;;
2772 esac
2773 AC_MSG_RESULT($cf_gnat_generics)
2774
2775 if test "$cf_gnat_generics" = yes
2776 then
2777         cf_compile_generics=generics
2778         cf_generic_objects="\${GENOBJS}"
2779 else
2780         cf_compile_generics=
2781         cf_generic_objects=
2782 fi
2783
2784 AC_SUBST(cf_compile_generics)
2785 AC_SUBST(cf_generic_objects)
2786 ])dnl
2787 dnl ---------------------------------------------------------------------------
2788 dnl CF_GNAT_PROJECTS version: 10 updated: 2019/12/31 08:53:54
2789 dnl ----------------
2790 dnl GNAT projects are configured with ".gpr" project files.
2791 dnl GNAT libraries are a further development, using the project feature.
2792 AC_DEFUN([CF_GNAT_PROJECTS],
2793 [
2794 AC_REQUIRE([CF_GNAT_VERSION])
2795 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
2796
2797 cf_gnat_libraries=no
2798 cf_gnat_projects=no
2799
2800 if test "$enable_gnat_projects" != no ; then
2801 AC_MSG_CHECKING(if GNAT supports project files)
2802 case $cf_cv_gnat_version in
2803 (3.[[0-9]]*)
2804         ;;
2805 (*)
2806         case $cf_cv_system_name in
2807         (cygwin*|msys*)
2808                 ;;
2809         (*)
2810                 rm -rf conftest* *~conftest*
2811                 if mkdir conftest.src conftest.bin conftest.lib
2812                 then
2813                         cd conftest.src
2814                         rm -rf conftest* *~conftest*
2815                         cat >>library.gpr <<CF_EOF
2816 project Library is
2817   Kind := External ("LIB_KIND");
2818   for Library_Name use "ConfTest";
2819   for Object_Dir use ".";
2820   for Library_ALI_Dir use External("LIBRARY_DIR");
2821   for Library_Version use External ("SONAME");
2822   for Library_Kind use Kind;
2823   for Library_Dir use External("BUILD_DIR");
2824   Source_Dir := External ("SOURCE_DIR");
2825   for Source_Dirs use (Source_Dir);
2826 end Library;
2827 CF_EOF
2828                         cat >>confpackage.ads <<CF_EOF
2829 package ConfPackage is
2830    procedure conftest;
2831 end ConfPackage;
2832 CF_EOF
2833                         cat >>confpackage.adb <<CF_EOF
2834 with Text_IO;
2835 package body ConfPackage is
2836    procedure conftest is
2837    begin
2838       Text_IO.Put ("Hello World");
2839       Text_IO.New_Line;
2840    end conftest;
2841 end ConfPackage;
2842 CF_EOF
2843                         if ( $cf_ada_make $ADAFLAGS \
2844                                         -Plibrary.gpr \
2845                                         -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2846                                         -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2847                                         -XSOURCE_DIR=`pwd` \
2848                                         -XSONAME=libConfTest.so.1 \
2849                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2850                                 cf_gnat_projects=yes
2851                         fi
2852                         cd ..
2853                 fi
2854                 if test -f conftest.lib/confpackage.ali
2855                 then
2856                         cf_gnat_libraries=yes
2857                 fi
2858                 rm -rf conftest* *~conftest*
2859                 ;;
2860         esac
2861         ;;
2862 esac
2863 AC_MSG_RESULT($cf_gnat_projects)
2864 fi # enable_gnat_projects
2865
2866 if test $cf_gnat_projects = yes
2867 then
2868         AC_MSG_CHECKING(if GNAT supports libraries)
2869         AC_MSG_RESULT($cf_gnat_libraries)
2870 fi
2871
2872 if test "$cf_gnat_projects" = yes
2873 then
2874         USE_OLD_MAKERULES="#"
2875         USE_GNAT_PROJECTS=""
2876 else
2877         USE_OLD_MAKERULES=""
2878         USE_GNAT_PROJECTS="#"
2879 fi
2880
2881 if test "$cf_gnat_libraries" = yes
2882 then
2883         USE_GNAT_LIBRARIES=""
2884 else
2885         USE_GNAT_LIBRARIES="#"
2886 fi
2887
2888 AC_SUBST(USE_OLD_MAKERULES)
2889 AC_SUBST(USE_GNAT_PROJECTS)
2890 AC_SUBST(USE_GNAT_LIBRARIES)
2891 ])dnl
2892 dnl ---------------------------------------------------------------------------
2893 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2894 dnl --------------
2895 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2896 dnl is noted that gnat may compile a tasking unit even for configurations which
2897 dnl fail at runtime.
2898 AC_DEFUN([CF_GNAT_SIGINT],[
2899 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2900 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2901
2902 package ConfTest is
2903
2904    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2905    pragma Unreserve_All_Interrupts;
2906    pragma Warnings (On);
2907
2908    protected Process is
2909       procedure Stop;
2910       function Continue return Boolean;
2911       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2912    private
2913       Done : Boolean := False;
2914    end Process;
2915
2916 end ConfTest;],
2917 [package body ConfTest is
2918    protected body Process is
2919       procedure Stop is
2920       begin
2921          Done := True;
2922       end Stop;
2923       function Continue return Boolean is
2924       begin
2925          return not Done;
2926       end Continue;
2927    end Process;
2928 end ConfTest;],
2929         [cf_cv_gnat_sigint=yes],
2930         [cf_cv_gnat_sigint=no])])
2931
2932 if test $cf_cv_gnat_sigint = yes ; then
2933         USE_GNAT_SIGINT=""
2934 else
2935         USE_GNAT_SIGINT="#"
2936 fi
2937 AC_SUBST(USE_GNAT_SIGINT)
2938 ])dnl
2939 dnl ---------------------------------------------------------------------------
2940 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2941 dnl ----------------
2942 dnl Verify that a test program compiles/links with GNAT.
2943 dnl $cf_ada_make is set to the program that compiles/links
2944 dnl $ADAFLAGS may be set to the GNAT flags.
2945 dnl
2946 dnl $1 is the text of the spec
2947 dnl $2 is the text of the body
2948 dnl $3 is the shell command to execute if successful
2949 dnl $4 is the shell command to execute if not successful
2950 AC_DEFUN([CF_GNAT_TRY_LINK],
2951 [
2952 rm -rf conftest* *~conftest*
2953 cat >>conftest.ads <<CF_EOF
2954 $1
2955 CF_EOF
2956 cat >>conftest.adb <<CF_EOF
2957 $2
2958 CF_EOF
2959 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2960 ifelse($3,,      :,[      $3])
2961 ifelse($4,,,[else
2962    $4])
2963 fi
2964 rm -rf conftest* *~conftest*
2965 ])dnl
2966 dnl ---------------------------------------------------------------------------
2967 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2968 dnl ---------------
2969 dnl Verify that a test program compiles and runs with GNAT
2970 dnl $cf_ada_make is set to the program that compiles/links
2971 dnl $ADAFLAGS may be set to the GNAT flags.
2972 dnl
2973 dnl $1 is the text of the spec
2974 dnl $2 is the text of the body
2975 dnl $3 is the shell command to execute if successful
2976 dnl $4 is the shell command to execute if not successful
2977 AC_DEFUN([CF_GNAT_TRY_RUN],
2978 [
2979 rm -rf conftest* *~conftest*
2980 cat >>conftest.ads <<CF_EOF
2981 $1
2982 CF_EOF
2983 cat >>conftest.adb <<CF_EOF
2984 $2
2985 CF_EOF
2986 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2987    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2988 ifelse($3,,      :,[      $3])
2989 ifelse($4,,,[   else
2990       $4])
2991    fi
2992 ifelse($4,,,[else
2993    $4])
2994 fi
2995 rm -rf conftest* *~conftest*
2996 ])dnl
2997 dnl ---------------------------------------------------------------------------
2998 dnl CF_GNAT_VERSION version: 22 updated: 2019/12/31 08:53:54
2999 dnl ---------------
3000 dnl $1 = cache variable to update
3001 dnl $2 = program name
3002 dnl Verify version of GNAT or related tool
3003 AC_DEFUN([CF_GNAT_VERSION],
3004 [
3005 AC_CACHE_CHECK(for ifelse($2,,gnat,$2) version, cf_cv_gnat_version,[
3006 cf_cv_gnat_version=`ifelse($2,,${cf_ada_make:-gnatmake},$2) --version 2>&1 | \
3007         grep '[[0-9]].[[0-9]][[0-9]]*' |\
3008         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
3009 ])
3010 test -z "$cf_cv_gnat_version" && cf_cv_gnat_version=no
3011 ifelse($1,,,[eval $1=$cf_cv_gnat_version; unset cf_cv_gnat_version])
3012 ])dnl
3013 dnl ---------------------------------------------------------------------------
3014 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
3015 dnl -------------
3016 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
3017 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
3018 dnl (or misfeature) of glibc2, which breaks portability of many applications,
3019 dnl since it is interwoven with GNU extensions.
3020 dnl
3021 dnl Well, yes we could work around it...
3022 dnl
3023 dnl Parameters:
3024 dnl     $1 is the nominal value for _XOPEN_SOURCE
3025 AC_DEFUN([CF_GNU_SOURCE],
3026 [
3027 cf_gnu_xopen_source=ifelse($1,,500,$1)
3028
3029 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
3030 AC_TRY_COMPILE([#include <sys/types.h>],[
3031         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
3032                 return 0;
3033         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
3034                 return 0;
3035         #else
3036         #       error not GNU C library
3037         #endif],
3038         [cf_cv_gnu_library=yes],
3039         [cf_cv_gnu_library=no])
3040 ])
3041
3042 if test x$cf_cv_gnu_library = xyes; then
3043
3044         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
3045         # was changed to help a little.  newlib incorporated the change about 4
3046         # years later.
3047         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
3048                 cf_save="$CPPFLAGS"
3049                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3050                 AC_TRY_COMPILE([#include <sys/types.h>],[
3051                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
3052                                 return 0;
3053                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
3054                                 return 0;
3055                         #else
3056                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
3057                         #endif],
3058                         [cf_cv_gnu_library_219=yes],
3059                         [cf_cv_gnu_library_219=no])
3060                 CPPFLAGS="$cf_save"
3061         ])
3062
3063         if test "x$cf_cv_gnu_library_219" = xyes; then
3064                 cf_save="$CPPFLAGS"
3065                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
3066                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
3067                         AC_TRY_COMPILE([
3068                                 #include <limits.h>
3069                                 #include <sys/types.h>
3070                                 ],[
3071                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
3072                                         return 0;
3073                                 #else
3074                                 #       error GNU C library is too old
3075                                 #endif],
3076                                 [cf_cv_gnu_dftsrc_219=yes],
3077                                 [cf_cv_gnu_dftsrc_219=no])
3078                         ])
3079                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
3080         else
3081                 cf_cv_gnu_dftsrc_219=maybe
3082         fi
3083
3084         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
3085
3086                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
3087                 AC_TRY_COMPILE([#include <sys/types.h>],[
3088                         #ifndef _XOPEN_SOURCE
3089                         #error  expected _XOPEN_SOURCE to be defined
3090                         #endif],
3091                         [cf_cv_gnu_source=no],
3092                         [cf_save="$CPPFLAGS"
3093                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
3094                          AC_TRY_COMPILE([#include <sys/types.h>],[
3095                                 #ifdef _XOPEN_SOURCE
3096                                 #error  expected _XOPEN_SOURCE to be undefined
3097                                 #endif],
3098                                 [cf_cv_gnu_source=no],
3099                                 [cf_cv_gnu_source=yes])
3100                         CPPFLAGS="$cf_save"
3101                         ])
3102                 ])
3103
3104                 if test "$cf_cv_gnu_source" = yes
3105                 then
3106                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
3107                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
3108                         AC_TRY_COMPILE([#include <sys/types.h>],[
3109                                 #ifdef _DEFAULT_SOURCE
3110                                 #error  expected _DEFAULT_SOURCE to be undefined
3111                                 #endif],
3112                                 [cf_cv_default_source=no],
3113                                 [cf_cv_default_source=yes])
3114                         ])
3115                         if test "$cf_cv_default_source" = yes
3116                         then
3117                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3118                         fi
3119                 fi
3120         fi
3121
3122 fi
3123 ])dnl
3124 dnl ---------------------------------------------------------------------------
3125 dnl CF_GPP_LIBRARY version: 12 updated: 2015/04/17 21:13:04
3126 dnl --------------
3127 dnl If we're trying to use g++, test if libg++ is installed (a rather common
3128 dnl problem :-).  If we have the compiler but no library, we'll be able to
3129 dnl configure, but won't be able to build the c++ demo program.
3130 AC_DEFUN([CF_GPP_LIBRARY],
3131 [
3132 cf_cxx_library=unknown
3133 case $cf_cv_system_name in
3134 (os2*)
3135         cf_gpp_libname=gpp
3136         ;;
3137 (*)
3138         cf_gpp_libname=g++
3139         ;;
3140 esac
3141 if test "$GXX" = yes; then
3142         AC_MSG_CHECKING([for lib$cf_gpp_libname])
3143         cf_save="$LIBS"
3144         CF_ADD_LIB($cf_gpp_libname)
3145         AC_TRY_LINK([
3146 #include <$cf_gpp_libname/builtin.h>
3147         ],
3148         [two_arg_error_handler_t foo2 = lib_error_handler],
3149         [cf_cxx_library=yes
3150          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3151          if test "$cf_gpp_libname" = cpp ; then
3152             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
3153          else
3154             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
3155          fi],
3156         [AC_TRY_LINK([
3157 #include <builtin.h>
3158         ],
3159         [two_arg_error_handler_t foo2 = lib_error_handler],
3160         [cf_cxx_library=yes
3161          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3162          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
3163         [cf_cxx_library=no])])
3164         LIBS="$cf_save"
3165         AC_MSG_RESULT($cf_cxx_library)
3166 fi
3167 ])dnl
3168 dnl ---------------------------------------------------------------------------
3169 dnl CF_GXX_VERSION version: 8 updated: 2017/02/11 14:48:57
3170 dnl --------------
3171 dnl Check for version of g++
3172 AC_DEFUN([CF_GXX_VERSION],[
3173 AC_REQUIRE([AC_PROG_CPP])
3174 GXX_VERSION=none
3175 if test "$GXX" = yes; then
3176         AC_MSG_CHECKING(version of ${CXX:-g++})
3177         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
3178         if test -z "$GXX_VERSION"
3179         then
3180                 GXX_VERSION=unknown
3181                 GXX=no
3182         fi
3183         AC_MSG_RESULT($GXX_VERSION)
3184 fi
3185 ])dnl
3186 dnl ---------------------------------------------------------------------------
3187 dnl CF_GXX_WARNINGS version: 9 updated: 2015/04/17 21:13:04
3188 dnl ---------------
3189 dnl Check if the compiler supports useful warning options.
3190 dnl
3191 dnl Most of gcc's options apply to g++, except:
3192 dnl     -Wbad-function-cast
3193 dnl     -Wmissing-declarations
3194 dnl     -Wnested-externs
3195 dnl
3196 dnl Omit a few (for now):
3197 dnl     -Winline
3198 dnl
3199 dnl Parameter:
3200 dnl     $1 is an optional list of g++ warning flags that a particular
3201 dnl             application might want to use, e.g., "no-unused" for
3202 dnl             -Wno-unused
3203 dnl Special:
3204 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
3205 dnl
3206 AC_DEFUN([CF_GXX_WARNINGS],
3207 [
3208
3209 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
3210 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
3211
3212 AC_REQUIRE([CF_GXX_VERSION])
3213
3214 AC_LANG_SAVE
3215 AC_LANG_CPLUSPLUS
3216
3217 cat > conftest.$ac_ext <<EOF
3218 #line __oline__ "configure"
3219 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
3220 EOF
3221
3222 if test "$INTEL_CPLUSPLUS" = yes
3223 then
3224 # The "-wdXXX" options suppress warnings:
3225 # remark #1419: external declaration in primary source file
3226 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3227 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3228 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
3229 # remark #193: zero used for undefined preprocessing identifier
3230 # remark #593: variable "curs_sb_left_arrow" was set but never used
3231 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
3232 # remark #869: parameter "tw" was never referenced
3233 # remark #981: operands are evaluated in unspecified order
3234 # warning #269: invalid format string conversion
3235
3236         AC_CHECKING([for $CC warning options])
3237         cf_save_CXXFLAGS="$CXXFLAGS"
3238         EXTRA_CXXFLAGS="-Wall"
3239         for cf_opt in \
3240                 wd1419 \
3241                 wd1682 \
3242                 wd1683 \
3243                 wd1684 \
3244                 wd193 \
3245                 wd279 \
3246                 wd593 \
3247                 wd810 \
3248                 wd869 \
3249                 wd981
3250         do
3251                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
3252                 if AC_TRY_EVAL(ac_compile); then
3253                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3254                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3255                 fi
3256         done
3257         CXXFLAGS="$cf_save_CXXFLAGS"
3258
3259 elif test "$GXX" = yes
3260 then
3261         AC_CHECKING([for $CXX warning options])
3262         cf_save_CXXFLAGS="$CXXFLAGS"
3263         EXTRA_CXXFLAGS="-W -Wall"
3264         cf_gxx_extra_warnings=""
3265         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
3266         case "$GCC_VERSION" in
3267         ([[1-2]].*)
3268                 ;;
3269         (*)
3270                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
3271                 ;;
3272         esac
3273         for cf_opt in \
3274                 Wabi \
3275                 fabi-version=0 \
3276                 Wextra \
3277                 Wignored-qualifiers \
3278                 Wlogical-op \
3279                 Woverloaded-virtual \
3280                 Wsign-promo \
3281                 Wsynth \
3282                 Wold-style-cast \
3283                 Wcast-align \
3284                 Wcast-qual \
3285                 Wpointer-arith \
3286                 Wshadow \
3287                 Wundef $cf_gxx_extra_warnings $1
3288         do
3289                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
3290                 if AC_TRY_EVAL(ac_compile); then
3291                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3292                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3293                 else
3294                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
3295                 fi
3296         done
3297         CXXFLAGS="$cf_save_CXXFLAGS"
3298 fi
3299
3300 rm -rf conftest*
3301 AC_LANG_RESTORE
3302 AC_SUBST(EXTRA_CXXFLAGS)
3303 ])dnl
3304 dnl ---------------------------------------------------------------------------
3305 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
3306 dnl ------------
3307 dnl Look for an instance of the Berkeley hashed database.
3308 dnl
3309 dnl $1 = optional parameter, to specify install-prefix for the database.
3310 AC_DEFUN([CF_HASHED_DB],
3311 [
3312 ifelse([$1],,,[
3313 case $1 in
3314 (yes|*able*)
3315         ;;
3316 (*)
3317         if test -d "$1" ; then
3318                 CF_ADD_INCDIR($1/include)
3319                 CF_ADD_LIBDIR($1/lib)
3320         else
3321                 case "$1" in
3322                 (./*|../*|/*)
3323                         AC_MSG_WARN(no such directory $1)
3324                         ;;
3325                 (*)
3326                         CF_FIND_SUB_INCDIR($1)
3327                         CF_FIND_SUB_LIBDIR($1)
3328                         ;;
3329                 esac
3330         fi
3331 esac
3332 ])
3333 AC_CHECK_HEADER(db.h,[
3334 CF_HASHED_DB_VERSION
3335 if test "$cf_cv_hashed_db_version" = unknown ; then
3336         AC_MSG_ERROR(Cannot determine version of db)
3337 else
3338         CF_HASHED_DB_LIBS
3339         if test "$cf_cv_hashed_db_libs" = unknown ; then
3340                 AC_MSG_ERROR(Cannot determine library for db)
3341         elif test "$cf_cv_hashed_db_libs" != default ; then
3342                 CF_ADD_LIB($cf_cv_hashed_db_libs)
3343         fi
3344 fi
3345 ],[
3346         AC_MSG_ERROR(Cannot find db.h)
3347 ])
3348 ])dnl
3349 dnl ---------------------------------------------------------------------------
3350 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
3351 dnl -----------------
3352 dnl Given that we have the header and version for hashed database, find the
3353 dnl library information.
3354 AC_DEFUN([CF_HASHED_DB_LIBS],
3355 [
3356 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
3357 cf_cv_hashed_db_libs=unknown
3358 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
3359 do
3360         cf_save_libs="$LIBS"
3361         if test -n "$cf_db_libs"; then
3362                 CF_ADD_LIB($cf_db_libs)
3363         fi
3364         CF_MSG_LOG(checking for library "$cf_db_libs")
3365         AC_TRY_LINK([
3366 $ac_includes_default
3367 #include <db.h>
3368 ],[
3369         char *path = "/tmp/foo";
3370 #ifdef DB_VERSION_MAJOR
3371 #if DB_VERSION_MAJOR >= 4
3372         DB *result = 0;
3373         db_create(&result, NULL, 0);
3374         result->open(result,
3375                 NULL,
3376                 path,
3377                 path,
3378                 DB_HASH,
3379                 DB_CREATE,
3380                 0644);
3381 #elif DB_VERSION_MAJOR >= 3
3382         DB *result = 0;
3383         db_create(&result, NULL, 0);
3384         result->open(result,
3385                 path,
3386                 path,
3387                 DB_HASH,
3388                 DB_CREATE,
3389                 0644);
3390 #elif DB_VERSION_MAJOR >= 2
3391         DB *result = 0;
3392         db_open(path,
3393                 DB_HASH,
3394                 DB_CREATE,
3395                 0644,
3396                 (DB_ENV *) 0,
3397                 (DB_INFO *) 0,
3398                 &result);
3399 #endif /* DB_VERSION_MAJOR */
3400 #else
3401         DB *result = dbopen(path,
3402                      2,
3403                      0644,
3404                      DB_HASH,
3405                      0);
3406 #endif
3407         ${cf_cv_main_return:-return}(result != 0)
3408 ],[
3409         if test -n "$cf_db_libs" ; then
3410                 cf_cv_hashed_db_libs=$cf_db_libs
3411         else
3412                 cf_cv_hashed_db_libs=default
3413         fi
3414         LIBS="$cf_save_libs"
3415         break
3416 ])
3417         LIBS="$cf_save_libs"
3418 done
3419 ])
3420 ])dnl
3421 dnl ---------------------------------------------------------------------------
3422 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
3423 dnl --------------------
3424 dnl Given that we have the header file for hashed database, find the version
3425 dnl information.
3426 AC_DEFUN([CF_HASHED_DB_VERSION],
3427 [
3428 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
3429 cf_cv_hashed_db_version=unknown
3430
3431 for cf_db_version in 1 2 3 4 5 6
3432 do
3433         CF_MSG_LOG(checking for db version $cf_db_version)
3434         AC_TRY_COMPILE([
3435 $ac_includes_default
3436 #include <db.h>
3437
3438 #ifdef DB_VERSION_MAJOR
3439         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
3440 #if $cf_db_version == DB_VERSION_MAJOR
3441         /* ok */
3442 #else
3443         make an error
3444 #endif
3445 #else
3446 #if $cf_db_version == 1
3447         /* ok: assuming this is DB 1.8.5 */
3448 #else
3449         make an error
3450 #endif
3451 #endif
3452 ],[DBT *foo = 0],[
3453         cf_cv_hashed_db_version=$cf_db_version
3454         break
3455         ])
3456 done
3457 ])
3458 ])dnl
3459 dnl ---------------------------------------------------------------------------
3460 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
3461 dnl --------------
3462 dnl Construct a search-list of directories for a nonstandard header-file
3463 dnl
3464 dnl Parameters
3465 dnl     $1 = the variable to return as result
3466 dnl     $2 = the package name
3467 AC_DEFUN([CF_HEADER_PATH],
3468 [
3469 $1=
3470
3471 # collect the current set of include-directories from compiler flags
3472 cf_header_path_list=""
3473 if test -n "${CFLAGS}${CPPFLAGS}" ; then
3474         for cf_header_path in $CPPFLAGS $CFLAGS
3475         do
3476                 case $cf_header_path in
3477                 (-I*)
3478                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
3479                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
3480                         cf_header_path_list="$cf_header_path_list [$]$1"
3481                         ;;
3482                 esac
3483         done
3484 fi
3485
3486 # add the variations for the package we are looking for
3487 CF_SUBDIR_PATH($1,$2,include)
3488
3489 test "$includedir" != NONE && \
3490 test "$includedir" != "/usr/include" && \
3491 test -d "$includedir" && {
3492         test -d $includedir &&    $1="[$]$1 $includedir"
3493         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
3494 }
3495
3496 test "$oldincludedir" != NONE && \
3497 test "$oldincludedir" != "/usr/include" && \
3498 test -d "$oldincludedir" && {
3499         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
3500         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
3501 }
3502
3503 $1="[$]$1 $cf_header_path_list"
3504 ])dnl
3505 dnl ---------------------------------------------------------------------------
3506 dnl CF_HELP_MESSAGE version: 4 updated: 2019/12/31 08:53:54
3507 dnl ---------------
3508 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
3509 AC_DEFUN([CF_HELP_MESSAGE],
3510 [CF_ACVERSION_CHECK(2.53,[],[
3511 AC_DIVERT_HELP($1)])dnl
3512 ])dnl
3513 dnl ---------------------------------------------------------------------------
3514 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
3515 dnl ---------------
3516 dnl Construct the list of include-options according to whether we're building
3517 dnl in the source directory or using '--srcdir=DIR' option.
3518 AC_DEFUN([CF_INCLUDE_DIRS],
3519 [
3520 if test "$srcdir" != "."; then
3521         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
3522 fi
3523 CPPFLAGS="-I../include $CPPFLAGS"
3524 if test "$srcdir" != "."; then
3525         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
3526 fi
3527 CPPFLAGS="-I. $CPPFLAGS"
3528 AC_SUBST(CPPFLAGS)
3529 ])dnl
3530 dnl ---------------------------------------------------------------------------
3531 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
3532 dnl ---------------
3533 dnl prompt for/fill-in useful install-program options
3534 AC_DEFUN([CF_INSTALL_OPTS],
3535 [
3536 CF_INSTALL_OPT_S
3537 CF_INSTALL_OPT_P
3538 CF_INSTALL_OPT_O
3539 ])dnl
3540 dnl ---------------------------------------------------------------------------
3541 dnl CF_INSTALL_OPT_O version: 2 updated: 2015/05/15 19:45:35
3542 dnl ----------------
3543 dnl Almost all "install" programs default to the current user's ownership.
3544 dnl Almost - MINIX is an exception.
3545 AC_DEFUN([CF_INSTALL_OPT_O],
3546 [
3547 AC_MSG_CHECKING(if install needs to be told about ownership)
3548 case `$ac_config_guess` in
3549 (*minix)
3550         with_install_o=yes
3551         ;;
3552 (*)
3553         with_install_o=no
3554         ;;
3555 esac
3556
3557 AC_MSG_RESULT($with_install_o)
3558 if test "x$with_install_o" = xyes
3559 then
3560         INSTALL_OPT_O=`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`
3561 else
3562         INSTALL_OPT_O=
3563 fi
3564
3565 AC_SUBST(INSTALL_OPT_O)
3566 ])dnl
3567 dnl ---------------------------------------------------------------------------
3568 dnl CF_INSTALL_OPT_P version: 1 updated: 2018/08/18 12:19:21
3569 dnl ----------------
3570 dnl Some install-programs accept a "-p" option to preserve file modification
3571 dnl timestamps.  That can be useful as an install option, as well as a way to
3572 dnl avoid the need for ranlib after copying a static archive.
3573 AC_DEFUN([CF_INSTALL_OPT_P],
3574 [
3575 : ${INSTALL:=install}
3576 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
3577         rm -rf conftest*
3578         date >conftest.in
3579         mkdir conftest.out
3580         sleep 3
3581         if $INSTALL -p conftest.in conftest.out 2>/dev/null
3582         then
3583                 if test -f conftest.out/conftest.in
3584                 then
3585                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
3586                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
3587                         if test -s conftest.err
3588                         then
3589                                 cf_cv_install_p=no
3590                         else
3591                                 cf_cv_install_p=yes
3592                         fi
3593                 else
3594                         cf_cv_install_p=no
3595                 fi
3596         else
3597                 cf_cv_install_p=no
3598         fi
3599         rm -rf conftest*
3600 ])
3601 ])dnl
3602 dnl ---------------------------------------------------------------------------
3603 dnl CF_INSTALL_OPT_S version: 2 updated: 2018/08/18 12:19:21
3604 dnl ----------------
3605 dnl By default, we should strip executables which are installed, but leave the
3606 dnl ability to suppress that for unit-testing.
3607 AC_DEFUN([CF_INSTALL_OPT_S],
3608 [
3609 AC_MSG_CHECKING(if you want to install stripped executables)
3610 CF_ARG_DISABLE(stripping,
3611         [  --disable-stripping     do not strip (debug info) installed executables],
3612         [with_stripping=no],
3613         [with_stripping=yes])
3614 AC_MSG_RESULT($with_stripping)
3615
3616 if test "$with_stripping" = yes
3617 then
3618         INSTALL_OPT_S="-s"
3619 else
3620         INSTALL_OPT_S=
3621 fi
3622 AC_SUBST(INSTALL_OPT_S)
3623 ])dnl
3624 dnl ---------------------------------------------------------------------------
3625 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
3626 dnl -----------------
3627 dnl Check if the given compiler is really the Intel compiler for Linux.  It
3628 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
3629 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
3630 dnl
3631 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
3632 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
3633 dnl the wrappers for gcc and g++ warnings.
3634 dnl
3635 dnl $1 = GCC (default) or GXX
3636 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
3637 dnl $3 = CFLAGS (default) or CXXFLAGS
3638 AC_DEFUN([CF_INTEL_COMPILER],[
3639 AC_REQUIRE([AC_CANONICAL_HOST])
3640 ifelse([$2],,INTEL_COMPILER,[$2])=no
3641
3642 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
3643         case $host_os in
3644         (linux*|gnu*)
3645                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
3646                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
3647                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
3648                 AC_TRY_COMPILE([],[
3649 #ifdef __INTEL_COMPILER
3650 #else
3651 make an error
3652 #endif
3653 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
3654 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
3655 ],[])
3656                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
3657                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
3658                 ;;
3659         esac
3660 fi
3661 ])dnl
3662 dnl ---------------------------------------------------------------------------
3663 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
3664 dnl ----------
3665 dnl Check if we have either a function or macro for 'isascii()'.
3666 AC_DEFUN([CF_ISASCII],
3667 [
3668 AC_MSG_CHECKING(for isascii)
3669 AC_CACHE_VAL(cf_cv_have_isascii,[
3670         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
3671         [cf_cv_have_isascii=yes],
3672         [cf_cv_have_isascii=no])
3673 ])dnl
3674 AC_MSG_RESULT($cf_cv_have_isascii)
3675 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
3676 ])dnl
3677 dnl ---------------------------------------------------------------------------
3678 dnl CF_LARGEFILE version: 11 updated: 2018/06/20 20:23:13
3679 dnl ------------
3680 dnl Add checks for large file support.
3681 AC_DEFUN([CF_LARGEFILE],[
3682 ifdef([AC_FUNC_FSEEKO],[
3683         AC_SYS_LARGEFILE
3684         if test "$enable_largefile" != no ; then
3685         AC_FUNC_FSEEKO
3686
3687         # Normally we would collect these definitions in the config.h,
3688         # but (like _XOPEN_SOURCE), some environments rely on having these
3689         # defined before any of the system headers are included.  Another
3690         # case comes up with C++, e.g., on AIX the compiler compiles the
3691         # header files by themselves before looking at the body files it is
3692         # told to compile.  For ncurses, those header files do not include
3693         # the config.h
3694         if test "$ac_cv_sys_large_files" != no
3695         then
3696                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
3697         fi
3698         if test "$ac_cv_sys_largefile_source" != no
3699         then
3700                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
3701         fi
3702         if test "$ac_cv_sys_file_offset_bits" != no
3703         then
3704                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
3705         fi
3706
3707         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
3708                 AC_TRY_COMPILE([
3709 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
3710 #include <sys/types.h>
3711 #include <dirent.h>
3712                 ],[
3713                 /* if transitional largefile support is setup, this is true */
3714                 extern struct dirent64 * readdir(DIR *);
3715                 struct dirent64 *x = readdir((DIR *)0);
3716                 struct dirent *y = readdir((DIR *)0);
3717                 int z = x - y;
3718                 ],
3719                 [cf_cv_struct_dirent64=yes],
3720                 [cf_cv_struct_dirent64=no])
3721         ])
3722         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
3723         fi
3724 ])
3725 ])
3726 dnl ---------------------------------------------------------------------------
3727 dnl CF_LDFLAGS_STATIC version: 12 updated: 2015/04/18 08:56:57
3728 dnl -----------------
3729 dnl Check for compiler/linker flags used to temporarily force usage of static
3730 dnl libraries.  This depends on the compiler and platform.  Use this to help
3731 dnl ensure that the linker picks up a given library based on its position in
3732 dnl the list of linker options and libraries.
3733 AC_DEFUN([CF_LDFLAGS_STATIC],[
3734
3735 if test "$GCC" = yes ; then
3736         case $cf_cv_system_name in
3737         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
3738                 LDFLAGS_STATIC=
3739                 LDFLAGS_SHARED=
3740                 ;;
3741         (*)     # normally, except when broken
3742                 LDFLAGS_STATIC=-static
3743                 LDFLAGS_SHARED=-dynamic
3744                 ;;
3745         esac
3746 else
3747         case $cf_cv_system_name in
3748         (aix[[4-7]]*)   # from ld manpage
3749                 LDFLAGS_STATIC=-bstatic
3750                 LDFLAGS_SHARED=-bdynamic
3751                 ;;
3752         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
3753                 # We could also use just "archive" and "shared".
3754                 LDFLAGS_STATIC=-Wl,-a,archive_shared
3755                 LDFLAGS_SHARED=-Wl,-a,shared_archive
3756                 ;;
3757         (irix*)         # from ld manpage IRIX64
3758                 LDFLAGS_STATIC=-Bstatic
3759                 LDFLAGS_SHARED=-Bdynamic
3760                 ;;
3761         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
3762                 # alternative "-oldstyle_liblookup" (not in cc manpage)
3763                 LDFLAGS_STATIC=-noso
3764                 LDFLAGS_SHARED=-so_archive
3765                 ;;
3766         (solaris2*)
3767                 LDFLAGS_STATIC=-Bstatic
3768                 LDFLAGS_SHARED=-Bdynamic
3769                 ;;
3770         esac
3771 fi
3772
3773 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
3774 then
3775         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
3776
3777         rm -f libconftest.a
3778         cat >conftest.$ac_ext <<EOF
3779 #line __oline__ "configure"
3780 #include <stdio.h>
3781 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
3782 EOF
3783         if AC_TRY_EVAL(ac_compile) ; then
3784                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
3785                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
3786         fi
3787         rm -f conftest.*
3788
3789         cf_save_LIBS="$LIBS"
3790
3791         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
3792         AC_TRY_LINK([
3793 #line __oline__ "configure"
3794 #include <stdio.h>
3795 int cf_ldflags_static(FILE *fp);
3796 ],[
3797         return cf_ldflags_static(stdin);
3798 ],[
3799         # some linkers simply ignore the -dynamic
3800         case x`file conftest$ac_exeext 2>/dev/null` in
3801         (*static*)
3802                 cf_ldflags_static=no
3803                 ;;
3804         (*)
3805                 cf_ldflags_static=yes
3806                 ;;
3807         esac
3808 ],[cf_ldflags_static=no])
3809
3810         rm -f libconftest.*
3811         LIBS="$cf_save_LIBS"
3812
3813         AC_MSG_RESULT($cf_ldflags_static)
3814
3815         if test $cf_ldflags_static != yes
3816         then
3817                 LDFLAGS_STATIC=
3818                 LDFLAGS_SHARED=
3819         fi
3820 else
3821         LDFLAGS_STATIC=
3822         LDFLAGS_SHARED=
3823 fi
3824
3825 AC_SUBST(LDFLAGS_STATIC)
3826 AC_SUBST(LDFLAGS_SHARED)
3827 ])
3828 dnl ---------------------------------------------------------------------------
3829 dnl CF_LD_RPATH_OPT version: 8 updated: 2018/08/18 16:36:35
3830 dnl ---------------
3831 dnl For the given system and compiler, find the compiler flags to pass to the
3832 dnl loader to use the "rpath" feature.
3833 AC_DEFUN([CF_LD_RPATH_OPT],
3834 [
3835 AC_REQUIRE([CF_CHECK_CACHE])
3836
3837 LD_RPATH_OPT=
3838 if test "x$cf_cv_enable_rpath" != xno
3839 then
3840         AC_MSG_CHECKING(for an rpath option)
3841         case $cf_cv_system_name in
3842         (irix*)
3843                 if test "$GCC" = yes; then
3844                         LD_RPATH_OPT="-Wl,-rpath,"
3845                 else
3846                         LD_RPATH_OPT="-rpath "
3847                 fi
3848                 ;;
3849         (linux*|gnu*|k*bsd*-gnu|freebsd*)
3850                 LD_RPATH_OPT="-Wl,-rpath,"
3851                 ;;
3852         (openbsd[[2-9]].*|mirbsd*)
3853                 LD_RPATH_OPT="-Wl,-rpath,"
3854                 ;;
3855         (dragonfly*)
3856                 LD_RPATH_OPT="-rpath "
3857                 ;;
3858         (netbsd*)
3859                 LD_RPATH_OPT="-Wl,-rpath,"
3860                 ;;
3861         (osf*|mls+*)
3862                 LD_RPATH_OPT="-rpath "
3863                 ;;
3864         (solaris2*)
3865                 LD_RPATH_OPT="-R"
3866                 ;;
3867         (*)
3868                 ;;
3869         esac
3870         AC_MSG_RESULT($LD_RPATH_OPT)
3871
3872         case "x$LD_RPATH_OPT" in
3873         (x-R*)
3874                 AC_MSG_CHECKING(if we need a space after rpath option)
3875                 cf_save_LIBS="$LIBS"
3876                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3877                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3878                 LIBS="$cf_save_LIBS"
3879                 AC_MSG_RESULT($cf_rpath_space)
3880                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3881                 ;;
3882         esac
3883 fi
3884 ])dnl
3885 dnl ---------------------------------------------------------------------------
3886 dnl CF_LD_SEARCHPATH version: 2 updated: 2019/09/26 20:34:14
3887 dnl ----------------
3888 dnl Try to obtain the linker's search-path, for use in scripts.
3889 dnl
3890 dnl Ignore LD_LIBRARY_PATH, etc.
3891 AC_DEFUN([CF_LD_SEARCHPATH],[
3892 AC_CACHE_CHECK(for linker search path,cf_cv_ld_searchpath,[
3893
3894 if test "$cross_compiling" != yes ; then
3895
3896 # GNU binutils' ld does not involve permissions which may stop ldconfig.
3897 cf_pathlist=`ld --verbose 2>/dev/null | grep SEARCH_DIR | sed -e 's,SEARCH_DIR[[("=]][[("=]]*,,g' -e 's/"[[)]];//gp' | sort -u`
3898
3899 # The -NX options tell newer versions of Linux ldconfig to not attempt to
3900 # update the cache, which makes it run faster.
3901 test -z "$cf_pathlist" && \
3902         cf_pathlist=`ldconfig -NX -v 2>/dev/null | sed -e '/^[[         ]]/d' -e 's/:$//' | sort -u`
3903
3904 test -z "$cf_pathlist" &&
3905         cf_pathlist=`ldconfig -v 2>/dev/null | sed -n -e '/^[[  ]]/d' -e 's/:$//p' | sort -u`
3906
3907 # This works with OpenBSD 6.5, which lists only filenames
3908 test -z "$cf_pathlist" &&
3909         cf_pathlist=`ldconfig -v 2>/dev/null | sed -n -e 's,^Adding \(.*\)/.*[$],\1,p' | sort -u`
3910
3911 if test -z "$cf_pathlist"
3912 then
3913         # dyld default path with MacOS
3914         if test -f /usr/bin/otool && test "x`uname -s`" = xDarwin
3915         then
3916                 # do this to bypass check
3917                 cf_cv_ld_searchpath='$HOME/lib'
3918                 cf_pathlist="/usr/local/lib /lib /usr/lib"
3919         fi
3920 fi
3921
3922 if test -z "$cf_pathlist"
3923 then
3924         # Solaris is hardcoded
3925         if test -d /opt/SUNWspro/lib
3926         then
3927                 cf_pathlist="/opt/SUNWspro/lib /usr/ccs/lib /usr/lib"
3928         elif test -d /usr/ccs/lib
3929         then
3930                 cf_pathlist="/usr/ccs/lib /usr/lib"
3931         fi
3932 fi
3933
3934 fi
3935
3936 # If nothing else, assume it is conventional
3937 test -z "$cf_pathlist" && cf_pathlist="/usr/lib /lib"
3938
3939 # Finally, check that this is only directories
3940 for cf_path in [$]0 $cf_pathlist
3941 do
3942         if test -d "$cf_path"; then
3943                 test -n "$cf_cv_ld_searchpath" && cf_cv_ld_searchpath="${cf_cv_ld_searchpath} "
3944                 cf_cv_ld_searchpath="${cf_cv_ld_searchpath}${cf_path}"
3945         fi
3946 done
3947
3948 # Ensure that it is nonempty
3949 test -z "$cf_cv_ld_searchpath" && cf_cv_ld_searchpath=/usr/lib
3950 ])
3951
3952 LD_SEARCHPATH=`echo "$cf_cv_ld_searchpath"|sed -e 's/ /|/g'`
3953 AC_SUBST(LD_SEARCHPATH)
3954 ])dnl
3955 dnl ---------------------------------------------------------------------------
3956 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
3957 dnl ---------------
3958 dnl Construct a search-list of directories for a nonstandard library-file
3959 dnl
3960 dnl Parameters
3961 dnl     $1 = the variable to return as result
3962 dnl     $2 = the package name
3963 AC_DEFUN([CF_LIBRARY_PATH],
3964 [
3965 $1=
3966 cf_library_path_list=""
3967 if test -n "${LDFLAGS}${LIBS}" ; then
3968         for cf_library_path in $LDFLAGS $LIBS
3969         do
3970                 case $cf_library_path in
3971                 (-L*)
3972                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3973                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3974                         cf_library_path_list="$cf_library_path_list [$]$1"
3975                         ;;
3976                 esac
3977         done
3978 fi
3979
3980 CF_SUBDIR_PATH($1,$2,lib)
3981
3982 $1="$cf_library_path_list [$]$1"
3983 ])dnl
3984 dnl ---------------------------------------------------------------------------
3985 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
3986 dnl ------------------
3987 AC_DEFUN([CF_LIBTOOL_VERSION],[
3988 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
3989 then
3990         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
3991 else
3992         cf_cv_libtool_version=
3993 fi
3994 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
3995 ])dnl
3996 dnl ---------------------------------------------------------------------------
3997 dnl CF_LIB_PREFIX version: 12 updated: 2015/10/17 19:03:33
3998 dnl -------------
3999 dnl Compute the library-prefix for the given host system
4000 dnl $1 = variable to set
4001 define([CF_LIB_PREFIX],
4002 [
4003         case $cf_cv_system_name in
4004         (OS/2*|os2*)
4005                 if test "$DFT_LWR_MODEL" = libtool; then
4006                         LIB_PREFIX='lib'
4007                 else
4008                         LIB_PREFIX=''
4009                 fi
4010                 ;;
4011         (*)     LIB_PREFIX='lib'
4012                 ;;
4013         esac
4014 ifelse($1,,,[$1=$LIB_PREFIX])
4015         AC_SUBST(LIB_PREFIX)
4016 ])dnl
4017 dnl ---------------------------------------------------------------------------
4018 dnl CF_LIB_RULES version: 89 updated: 2020/03/07 20:05:14
4019 dnl ------------
4020 dnl Append definitions and rules for the given models to the subdirectory
4021 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
4022 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
4023 dnl the corresponding makefile to list the models that we'll generate.
4024 dnl
4025 dnl For shared libraries, make a list of symbolic links to construct when
4026 dnl generating each library.  The convention used for Linux is the simplest
4027 dnl one:
4028 dnl     lib<name>.so    ->
4029 dnl     lib<name>.so.<major>    ->
4030 dnl     lib<name>.so.<maj>.<minor>
4031 dnl
4032 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
4033 AC_DEFUN([CF_LIB_RULES],
4034 [
4035 cf_prefix=$LIB_PREFIX
4036 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
4037
4038 case $cf_cv_shlib_version in
4039 (cygdll|msysdll|mingw)
4040         TINFO_NAME=$TINFO_ARG_SUFFIX
4041         TINFO_SUFFIX=.dll
4042         ;;
4043 esac
4044
4045 if test -n "$TINFO_SUFFIX" ; then
4046         case $TINFO_SUFFIX in
4047         (tw*)
4048                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
4049                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw'$EXTRA_SUFFIX'//'`
4050                 ;;
4051         (t*)
4052                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
4053                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t'$EXTRA_SUFFIX'//'`
4054                 ;;
4055         (w*)
4056                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
4057                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w'$EXTRA_SUFFIX'//'`
4058                 ;;
4059         esac
4060 fi
4061
4062 for cf_dir in $SRC_SUBDIRS
4063 do
4064         if test ! -d $srcdir/$cf_dir ; then
4065                 continue
4066         elif test -f $srcdir/$cf_dir/modules; then
4067
4068                 SHARED_LIB=
4069                 Libs_To_Make=
4070                 cf_awk_program=
4071                 if test -n "${cf_cv_abi_version}" && test "x${cf_cv_abi_version}" != "x5"
4072                 then
4073                         cf_awk_program="$cf_awk_program\
4074 /deprecated in ABI${cf_cv_abi_version}/ { next; }\
4075 { sub(\"NCURSES([[WT]]+)?\", \"&${cf_cv_abi_version}\"); }\
4076 "
4077                 fi
4078
4079                 if test "x$WILDCARD_SYMS" = xno
4080                 then
4081                         cf_awk_program="$cf_awk_program\
4082 /[[     ]]_\\*;/ { skip=1; next; }\
4083 "
4084                 fi
4085
4086                 if test "x$cf_awk_program" != "x"
4087                 then
4088                         cat >>$cf_dir/Makefile <<CF_EOF
4089
4090 # Generated by CF_LIB_RULES
4091 resulting.map: $UNALTERED_SYMS
4092         $AWK 'BEGIN { skip = 1; last=""; } \
4093 $cf_awk_program \
4094 { if ( last != "" && ( skip == 0 || \[$]\[$]0 !~ /}/ ) ) { print last; }\
4095  skip = 0; last = \[$]\[$]0; } \
4096 END { print last; }' < $UNALTERED_SYMS >\[$]@
4097
4098 distclean::
4099         rm -f resulting.map
4100 CF_EOF
4101                 fi
4102
4103                 for cf_item in $cf_LIST_MODELS
4104                 do
4105                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
4106                         if test "$cf_dir" = "c++"
4107                         then
4108                                 CF_MAP_LIB_BASENAME(cf_libname,cxx)
4109                         else
4110                                 CF_MAP_LIB_BASENAME(cf_libname,$cf_dir)
4111                         fi
4112                         test -z "$cf_libname" && cf_libname="$cf_dir"
4113                         if test $cf_item = shared ; then
4114                                 if test -n "${LIB_SUFFIX}"
4115                                 then
4116                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
4117                                 else
4118                                         cf_shared_suffix="$cf_suffix"
4119                                 fi
4120                                 if test "$cf_cv_do_symlinks" = yes ; then
4121                                         cf_version_name=
4122
4123                                         case "$cf_cv_shlib_version" in
4124                                         (rel)
4125                                                 cf_version_name=REL_VERSION
4126                                                 ;;
4127                                         (abi)
4128                                                 cf_version_name=ABI_VERSION
4129                                                 ;;
4130                                         esac
4131
4132                                         if test -n "$cf_version_name"
4133                                         then
4134                                                 case "$cf_cv_system_name" in
4135                                                 (darwin*)
4136                                                         # "w", etc?
4137                                                         cf_suffix="${USE_LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
4138                                                         ;;
4139                                                 (*)
4140                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
4141                                                         ;;
4142                                                 esac
4143                                         fi
4144                                         if test -n "${USE_LIB_SUFFIX}"
4145                                         then
4146                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
4147                                         else
4148                                                 cf_shared_suffix="$cf_suffix"
4149                                         fi
4150                                 fi
4151                                 # cygwin needs import library, and has unique naming convention
4152                                 # use autodetected ${cf_prefix} for import lib and static lib, but
4153                                 # use 'cyg' prefix for shared lib.
4154                                 case $cf_cv_shlib_version in
4155                                 (cygdll)
4156                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4157                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
4158                                         ;;
4159                                 (msysdll)
4160                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4161                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
4162                                         ;;
4163                                 (mingw)
4164                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4165                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
4166                                         ;;
4167                                 (*)
4168                                         cf_add_lib=
4169                                         ;;
4170                                 esac
4171                                 if test -n "$cf_add_lib"
4172                                 then
4173                                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
4174                                         continue
4175                                 fi
4176                         fi
4177                         cf_add_lib="../lib/${cf_prefix}${cf_libname}${cf_suffix}"
4178                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
4179                 done
4180
4181                 if test $cf_dir = ncurses ; then
4182                         cf_subsets="$LIB_SUBSETS"
4183                         cf_r_parts="$cf_subsets"
4184                         cf_liblist="$Libs_To_Make"
4185
4186                         while test -n "$cf_r_parts"
4187                         do
4188                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
4189                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
4190                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
4191                                         cf_add_lib=
4192                                         case $cf_l_parts in
4193                                         (*termlib*)
4194                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
4195                                                 ;;
4196                                         (*ticlib*)
4197                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
4198                                                 ;;
4199                                         (*)
4200                                                 break
4201                                                 ;;
4202                                         esac
4203                                         if test -n "$cf_add_lib"; then
4204                                                 Libs_To_Make="$cf_add_lib $Libs_To_Make"
4205                                         fi
4206                                 else
4207                                         break
4208                                 fi
4209                         done
4210                 else
4211                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
4212                 fi
4213
4214                 if test $cf_dir = c++; then
4215                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
4216                                 cf_list=
4217                                 for cf_item in $Libs_To_Make
4218                                 do
4219                                         case $cf_item in
4220                                         (*.a)
4221                                                 ;;
4222                                         (*)
4223                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
4224                                                 ;;
4225                                         esac
4226                                         for cf_test in $cf_list
4227                                         do
4228                                                 if test "$cf_test" = "$cf_item"
4229                                                 then
4230                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
4231                                                         cf_item=
4232                                                         break
4233                                                 fi
4234                                         done
4235                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
4236                                 done
4237                                 Libs_To_Make="$cf_list"
4238                         fi
4239                 fi
4240
4241                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
4242                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
4243                         $cf_dir/Makefile >$cf_dir/Makefile.out
4244                 mv $cf_dir/Makefile.out $cf_dir/Makefile
4245
4246                 $AWK -f $srcdir/mk-0th.awk \
4247                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
4248                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
4249
4250                 for cf_subset in $cf_subsets
4251                 do
4252                         cf_subdirs=
4253                         for cf_item in $cf_LIST_MODELS
4254                         do
4255
4256                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
4257                         CF_UPPER(cf_ITEM,$cf_item)
4258
4259                         CXX_MODEL=$cf_ITEM
4260                         if test "$CXX_MODEL" = SHARED; then
4261                                 case $cf_cv_shlib_version in
4262                                 (cygdll|msysdll|mingw)
4263                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
4264                                         with_shared_cxx=yes
4265                                         ;;
4266                                 (*)
4267                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
4268                                         ;;
4269                                 esac
4270                         fi
4271
4272                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
4273                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
4274
4275                         # Test for case where we build libtinfo with a different name.
4276                         cf_libname=$cf_dir
4277                         if test $cf_dir = ncurses ; then
4278                                 case $cf_subset in
4279                                 (*base*)
4280                                         cf_libname=${cf_libname}$USE_LIB_SUFFIX
4281                                         ;;
4282                                 (*termlib*)
4283                                         cf_libname=$TINFO_LIB_SUFFIX
4284                                         ;;
4285                                 (ticlib*)
4286                                         cf_libname=$TICS_LIB_SUFFIX
4287                                         ;;
4288                                 esac
4289                         elif test $cf_dir = c++ ; then
4290                                 CF_MAP_LIB_BASENAME(cf_libname,cxx)
4291                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
4292                         else
4293                                 CF_MAP_LIB_BASENAME(cf_libname,$cf_dir)
4294                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
4295                         fi
4296                         if test -n "${USE_ARG_SUFFIX}" ; then
4297                                 # undo $USE_LIB_SUFFIX add-on in CF_LIB_SUFFIX
4298                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${USE_LIB_SUFFIX}%%"`
4299                         fi
4300
4301                         # These dependencies really are for development, not
4302                         # builds, but they are useful in porting, too.
4303                         cf_depend="../include/ncurses_cfg.h"
4304                         if test "$srcdir" = "."; then
4305                                 cf_reldir="."
4306                         else
4307                                 cf_reldir="\${srcdir}"
4308                         fi
4309
4310                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
4311                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
4312                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
4313                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
4314                         fi
4315
4316                         cf_dir_suffix=
4317                         old_cf_suffix="$cf_suffix"
4318                         if test "$cf_cv_shlib_version_infix" = yes ; then
4319                         if test -n "$USE_LIB_SUFFIX" ; then
4320                                 case $USE_LIB_SUFFIX in
4321                                 (tw*)
4322                                         cf_libname=`echo $cf_libname | sed 's/tw'$EXTRA_SUFFIX'$//'`
4323                                         cf_suffix=`echo $cf_suffix | sed 's/^tw'$EXTRA_SUFFIX'//'`
4324                                         cf_dir_suffix=tw$EXTRA_SUFFIX
4325                                         ;;
4326                                 (t*)
4327                                         cf_libname=`echo $cf_libname | sed 's/t'$EXTRA_SUFFIX'$//'`
4328                                         cf_suffix=`echo $cf_suffix | sed 's/^t'$EXTRA_SUFFIX'//'`
4329                                         cf_dir_suffix=t$EXTRA_SUFFIX
4330                                         ;;
4331                                 (w*)
4332                                         cf_libname=`echo $cf_libname | sed 's/w'$EXTRA_SUFFIX'$//'`
4333                                         cf_suffix=`echo $cf_suffix | sed 's/^w'$EXTRA_SUFFIX'//'`
4334                                         cf_dir_suffix=w$EXTRA_SUFFIX
4335                                         ;;
4336                                 (*)
4337                                         cf_libname=`echo $cf_libname | sed 's/'$EXTRA_SUFFIX'$//'`
4338                                         cf_suffix=`echo $cf_suffix | sed 's/^'$EXTRA_SUFFIX'//'`
4339                                         cf_dir_suffix=$EXTRA_SUFFIX
4340                                         ;;
4341                                 esac
4342                         fi
4343                         fi
4344
4345                         $AWK -f $srcdir/mk-1st.awk \
4346                                 name=${cf_libname}${cf_dir_suffix} \
4347                                 traces=$LIB_TRACING \
4348                                 MODEL=$cf_ITEM \
4349                                 CXX_MODEL=$CXX_MODEL \
4350                                 model=$cf_subdir \
4351                                 prefix=$cf_prefix \
4352                                 suffix=$cf_suffix \
4353                                 subset=$cf_subset \
4354                                 driver=$cf_cv_term_driver \
4355                                 SymLink="$LN_S" \
4356                                 TermlibRoot=$TINFO_NAME \
4357                                 TermlibSuffix=$TINFO_SUFFIX \
4358                                 ShlibVer=$cf_cv_shlib_version \
4359                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
4360                                 ReLink=${cf_cv_do_relink:-no} \
4361                                 ReRanlib=${cf_cv_do_reranlib:-yes} \
4362                                 DoLinks=$cf_cv_do_symlinks \
4363                                 rmSoLocs=$cf_cv_rm_so_locs \
4364                                 ldconfig="$LDCONFIG" \
4365                                 overwrite=$WITH_OVERWRITE \
4366                                 depend="$cf_depend" \
4367                                 host="$host" \
4368                                 libtool_version="$LIBTOOL_VERSION" \
4369                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
4370
4371                         cf_suffix="$old_cf_suffix"
4372
4373                         for cf_subdir2 in $cf_subdirs lib
4374                         do
4375                                 test $cf_subdir = $cf_subdir2 && break
4376                         done
4377                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
4378                         $AWK -f $srcdir/mk-2nd.awk \
4379                                 name=$cf_dir \
4380                                 traces=$LIB_TRACING \
4381                                 MODEL=$cf_ITEM \
4382                                 model=$cf_subdir \
4383                                 subset=$cf_subset \
4384                                 srcdir=$srcdir \
4385                                 echo=$WITH_ECHO \
4386                                 crenames=$cf_cv_prog_CC_c_o \
4387                                 cxxrenames=$cf_cv_prog_CXX_c_o \
4388                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
4389                         cf_subdirs="$cf_subdirs $cf_subdir"
4390                         done
4391                 done
4392         fi
4393
4394         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
4395 done
4396
4397 for cf_dir in $SRC_SUBDIRS
4398 do
4399         if test ! -d $srcdir/$cf_dir ; then
4400                 continue
4401         fi
4402
4403         if test -f $cf_dir/Makefile ; then
4404                 case "$cf_dir" in
4405                 (Ada95)
4406                         echo 'libs \' >> Makefile
4407                         echo 'install.libs \' >> Makefile
4408                         echo 'uninstall.libs ::' >> Makefile
4409                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
4410                         ;;
4411                 esac
4412         fi
4413
4414         if test -f $srcdir/$cf_dir/modules; then
4415                 echo >> Makefile
4416                 if test -f $srcdir/$cf_dir/headers; then
4417 cat >> Makefile <<CF_EOF
4418 install.includes \\
4419 uninstall.includes \\
4420 CF_EOF
4421                 fi
4422 if test "$cf_dir" != "c++" ; then
4423 echo 'lint \' >> Makefile
4424 fi
4425 cat >> Makefile <<CF_EOF
4426 libs \\
4427 lintlib \\
4428 install.libs \\
4429 uninstall.libs \\
4430 install.$cf_dir \\
4431 uninstall.$cf_dir ::
4432         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
4433 CF_EOF
4434         elif test -f $srcdir/$cf_dir/headers; then
4435 cat >> Makefile <<CF_EOF
4436
4437 libs \\
4438 install.libs \\
4439 uninstall.libs \\
4440 install.includes \\
4441 uninstall.includes ::
4442         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
4443 CF_EOF
4444 fi
4445 done
4446
4447 if test "x$cf_with_db_install" = xyes; then
4448 cat >> Makefile <<CF_EOF
4449
4450 install.libs uninstall.libs \\
4451 install.data uninstall.data ::
4452 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
4453 CF_EOF
4454 else
4455 cat >> Makefile <<CF_EOF
4456
4457 install.libs uninstall.libs ::
4458         cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
4459 CF_EOF
4460 fi
4461
4462 if test "x$cf_with_manpages" = xyes; then
4463 cat >> Makefile <<CF_EOF
4464
4465 install.man \\
4466 uninstall.man ::
4467         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
4468 CF_EOF
4469 fi
4470
4471 cat >> Makefile <<CF_EOF
4472
4473 distclean ::
4474         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
4475         rm -f headers.sh headers.sed mk_shared_lib.sh
4476         rm -f edit_man.* man_alias.*
4477         rm -rf \${DIRS_TO_MAKE}
4478 CF_EOF
4479
4480 # Special case: tack's manpage lives in its own directory.
4481 if test "x$cf_with_manpages" = xyes; then
4482 if test "x$cf_with_tack" = "xyes"; then
4483 cat >> Makefile <<CF_EOF
4484
4485 install.man \\
4486 uninstall.man ::
4487         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
4488 CF_EOF
4489 fi
4490 fi
4491
4492 dnl If we're installing into a subdirectory of /usr/include, etc., we should
4493 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
4494 dnl anything, and will make it more standardized.  It's awkward to decide this
4495 dnl at configuration because of quoting, so we'll simply make all headers
4496 dnl installed via a script that can do the right thing.
4497
4498 rm -f headers.sed headers.sh
4499
4500 dnl ( generating this script makes the makefiles a little tidier :-)
4501 echo creating headers.sh
4502 cat >headers.sh <<CF_EOF
4503 #! $SHELL
4504 # This shell script is generated by the 'configure' script.  It is invoked in a
4505 # subdirectory of the build tree.  It generates a sed-script in the parent
4506 # directory that is used to adjust includes for header files that reside in a
4507 # subdirectory of /usr/include, etc.
4508 PRG=""
4509 while test \[$]# != 3
4510 do
4511 PRG="\$PRG \[$]1"; shift
4512 done
4513 DST=\[$]1
4514 REF=\[$]2
4515 SRC=\[$]3
4516 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
4517 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
4518 echo installing \$SRC in \$DST
4519 CF_EOF
4520
4521 if test $WITH_CURSES_H = yes; then
4522         cat >>headers.sh <<CF_EOF
4523 case \$DST in
4524 (/*/include/*)
4525         END=\`basename \$DST\`
4526         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
4527         do
4528                 NAME=\`basename \$i\`
4529                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
4530         done
4531         ;;
4532 (*)
4533         echo "" >> \$TMPSED
4534         ;;
4535 esac
4536 CF_EOF
4537
4538 else
4539         cat >>headers.sh <<CF_EOF
4540 case \$DST in
4541 (/*/include/*)
4542         END=\`basename \$DST\`
4543         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
4544         do
4545                 NAME=\`basename \$i\`
4546                 if test "\$NAME" = "curses.h"
4547                 then
4548                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
4549                         NAME=ncurses.h
4550                 fi
4551                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
4552         done
4553         ;;
4554 (*)
4555         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
4556         ;;
4557 esac
4558 CF_EOF
4559 fi
4560 cat >>headers.sh <<CF_EOF
4561 rm -f \$TMPSRC
4562 sed -f \$TMPSED \$SRC > \$TMPSRC
4563 NAME=\`basename \$SRC\`
4564 CF_EOF
4565 if test $WITH_CURSES_H != yes; then
4566         cat >>headers.sh <<CF_EOF
4567 test "\$NAME" = "curses.h" && NAME=ncurses.h
4568 CF_EOF
4569 fi
4570 cat >>headers.sh <<CF_EOF
4571 # Just in case someone gzip'd manpages, remove the conflicting copy.
4572 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
4573
4574 eval \$PRG \$TMPSRC \$DST/\$NAME
4575 rm -f \$TMPSRC \$TMPSED
4576 CF_EOF
4577
4578 chmod 0755 headers.sh
4579
4580 for cf_dir in $SRC_SUBDIRS
4581 do
4582         if test ! -d $srcdir/$cf_dir ; then
4583                 continue
4584         fi
4585
4586         if test -f $srcdir/$cf_dir/headers; then
4587                 $AWK -f $srcdir/mk-hdr.awk \
4588                         subset="$LIB_SUBSETS" \
4589                         compat="$WITH_CURSES_H" \
4590                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
4591         fi
4592
4593         if test -f $srcdir/$cf_dir/modules; then
4594                 if test "$cf_dir" != "c++" ; then
4595                         cat >>$cf_dir/Makefile <<"CF_EOF"
4596 depend : ${AUTO_SRC}
4597         makedepend -- ${CPPFLAGS} -- ${C_SRC}
4598
4599 # DO NOT DELETE THIS LINE -- make depend depends on it.
4600 CF_EOF
4601                 fi
4602         fi
4603 done
4604 AC_SUBST(Libs_To_Make)
4605 ])dnl
4606 dnl ---------------------------------------------------------------------------
4607 dnl CF_LIB_SONAME version: 6 updated: 2017/01/21 11:06:25
4608 dnl -------------
4609 dnl Find the and soname for the given shared library.  Set the cache variable
4610 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
4611 dnl variable to "unknown".
4612 dnl
4613 dnl $1 = headers
4614 dnl $2 = code
4615 dnl $3 = library name
4616 AC_DEFUN([CF_LIB_SONAME],
4617 [
4618 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
4619
4620 cf_cv_$3_soname=unknown
4621 if test "$cross_compiling" != yes ; then
4622 cat >conftest.$ac_ext <<CF_EOF
4623 $1
4624 int main(void)
4625 {
4626 $2
4627         ${cf_cv_main_return:-return}(0);
4628 }
4629 CF_EOF
4630 cf_save_LIBS="$LIBS"
4631         CF_ADD_LIB($3)
4632         if AC_TRY_EVAL(ac_compile) ; then
4633                 if AC_TRY_EVAL(ac_link) ; then
4634                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
4635                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
4636                 fi
4637         fi
4638 rm -rf conftest*
4639 LIBS="$cf_save_LIBS"
4640 fi
4641 ])
4642 ])
4643 dnl ---------------------------------------------------------------------------
4644 dnl CF_LIB_SUFFIX version: 25 updated: 2015/04/17 21:13:04
4645 dnl -------------
4646 dnl Compute the library file-suffix from the given model name
4647 dnl $1 = model name
4648 dnl $2 = variable to set (the nominal library suffix)
4649 dnl $3 = dependency variable to set (actual filename)
4650 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4651 AC_DEFUN([CF_LIB_SUFFIX],
4652 [
4653         case X$1 in
4654         (Xlibtool)
4655                 $2='.la'
4656                 $3=[$]$2
4657                 ;;
4658         (Xdebug)
4659                 $2='_g.a'
4660                 $3=[$]$2
4661                 ;;
4662         (Xprofile)
4663                 $2='_p.a'
4664                 $3=[$]$2
4665                 ;;
4666         (Xshared)
4667                 case $cf_cv_system_name in
4668                 (aix[[5-7]]*)
4669                         $2='.so'
4670                         $3=[$]$2
4671                         ;;
4672                 (cygwin*|msys*|mingw*)
4673                         $2='.dll'
4674                         $3='.dll.a'
4675                         ;;
4676                 (darwin*)
4677                         $2='.dylib'
4678                         $3=[$]$2
4679                         ;;
4680                 (hpux*)
4681                         case $target in
4682                         (ia64*)
4683                                 $2='.so'
4684                                 $3=[$]$2
4685                                 ;;
4686                         (*)
4687                                 $2='.sl'
4688                                 $3=[$]$2
4689                                 ;;
4690                         esac
4691                         ;;
4692                 (*)
4693                         $2='.so'
4694                         $3=[$]$2
4695                         ;;
4696                 esac
4697                 ;;
4698         (*)
4699                 $2='.a'
4700                 $3=[$]$2
4701                 ;;
4702         esac
4703         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
4704         then
4705                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
4706                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
4707         fi
4708 ])dnl
4709 dnl ---------------------------------------------------------------------------
4710 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
4711 dnl -----------
4712 dnl Compute the string to append to -library from the given model name
4713 dnl $1 = model name
4714 dnl $2 = variable to set
4715 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4716 AC_DEFUN([CF_LIB_TYPE],
4717 [
4718         case $1 in
4719         (libtool) $2=''   ;;
4720         (normal)  $2=''   ;;
4721         (debug)   $2='_g' ;;
4722         (profile) $2='_p' ;;
4723         (shared)  $2=''   ;;
4724         esac
4725         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
4726 ])dnl
4727 dnl ---------------------------------------------------------------------------
4728 dnl CF_LINK_DATAONLY version: 13 updated: 2020/02/08 15:59:30
4729 dnl ----------------
4730 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
4731 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
4732 dnl have to provide wrappers for global tables to ensure they're linked
4733 dnl properly.
4734 AC_DEFUN([CF_LINK_DATAONLY],
4735 [
4736 AC_MSG_CHECKING([if data-only library module links])
4737 AC_CACHE_VAL(cf_cv_link_dataonly,[
4738         rm -f conftest.a
4739         cat >conftest.$ac_ext <<EOF
4740 #line __oline__ "configure"
4741 int     testdata[[3]] = { 123, 456, 789 };
4742 EOF
4743         if AC_TRY_EVAL(ac_compile) ; then
4744                 mv conftest.o data.o && \
4745                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
4746         fi
4747         rm -f conftest.$ac_ext data.o
4748         cat >conftest.$ac_ext <<EOF
4749 #line __oline__ "configure"
4750 int     testfunc(void)
4751 {
4752 #if defined(NeXT)
4753         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
4754 #else
4755         extern int testdata[[3]];
4756         return testdata[[0]] == 123
4757            &&  testdata[[1]] == 456
4758            &&  testdata[[2]] == 789;
4759 #endif
4760 }
4761 EOF
4762         if AC_TRY_EVAL(ac_compile); then
4763                 mv conftest.o func.o && \
4764                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
4765         fi
4766         rm -f conftest.$ac_ext func.o
4767         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
4768         cf_saveLIBS="$LIBS"
4769         LIBS="conftest.a $LIBS"
4770         AC_TRY_RUN([
4771         int main(void)
4772         {
4773                 extern int testfunc();
4774                 ${cf_cv_main_return:-return} (!testfunc());
4775         }
4776         ],
4777         [cf_cv_link_dataonly=yes],
4778         [cf_cv_link_dataonly=no],
4779         [cf_cv_link_dataonly=unknown])
4780         LIBS="$cf_saveLIBS"
4781         ])
4782 AC_MSG_RESULT($cf_cv_link_dataonly)
4783
4784 if test "$cf_cv_link_dataonly" = no ; then
4785         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
4786         BROKEN_LINKER=1
4787 fi
4788 AC_SUBST(BROKEN_LINKER)
4789
4790 ])dnl
4791 dnl ---------------------------------------------------------------------------
4792 dnl CF_LINK_FUNCS version: 9 updated: 2017/01/21 11:11:02
4793 dnl -------------
4794 dnl Most Unix systems have both link and symlink, a few don't have symlink.
4795 dnl A few non-Unix systems implement symlink, but not link.
4796 dnl A few non-systems implement neither (or have nonfunctional versions).
4797 AC_DEFUN([CF_LINK_FUNCS],
4798 [
4799 AC_CHECK_HEADERS( \
4800 unistd.h \
4801 )
4802 AC_CHECK_FUNCS( \
4803         remove \
4804         unlink )
4805
4806 if test "$cross_compiling" = yes ; then
4807         AC_CHECK_FUNCS( \
4808                 link \
4809                 symlink )
4810 else
4811         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
4812                 cf_cv_link_funcs=
4813                 for cf_func in link symlink ; do
4814                         AC_TRY_RUN([
4815 #include <sys/types.h>
4816 #include <sys/stat.h>
4817 #ifdef HAVE_UNISTD_H
4818 #include <unistd.h>
4819 #endif
4820 int main(void)
4821 {
4822         int fail = 0;
4823         char *src = "config.log";
4824         char *dst = "conftest.chk";
4825         struct stat src_sb;
4826         struct stat dst_sb;
4827
4828         stat(src, &src_sb);
4829         fail = ($cf_func("config.log", "conftest.chk") < 0)
4830             || (stat(dst, &dst_sb) < 0)
4831             || (dst_sb.st_mtime != src_sb.st_mtime);
4832 #ifdef HAVE_UNLINK
4833         unlink(dst);
4834 #else
4835         remove(dst);
4836 #endif
4837         ${cf_cv_main_return:-return} (fail);
4838 }
4839                         ],[
4840                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
4841                         eval 'ac_cv_func_'$cf_func'=yes'],[
4842                         eval 'ac_cv_func_'$cf_func'=no'],[
4843                         eval 'ac_cv_func_'$cf_func'=error'])
4844                 done
4845                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
4846         ])
4847         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
4848         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
4849 fi
4850 ])dnl
4851 dnl ---------------------------------------------------------------------------
4852 dnl CF_MAKEFLAGS version: 18 updated: 2018/02/21 21:26:03
4853 dnl ------------
4854 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
4855 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
4856 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
4857 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
4858 AC_DEFUN([CF_MAKEFLAGS],
4859 [
4860 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
4861         cf_cv_makeflags=''
4862         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
4863         do
4864                 cat >cf_makeflags.tmp <<CF_EOF
4865 SHELL = $SHELL
4866 all :
4867         @ echo '.$cf_option'
4868 CF_EOF
4869                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
4870                 case "$cf_result" in
4871                 (.*k|.*kw)
4872                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
4873                         case "$cf_result" in
4874                         (.*CC=*)        cf_cv_makeflags=
4875                                 ;;
4876                         (*)     cf_cv_makeflags=$cf_option
4877                                 ;;
4878                         esac
4879                         break
4880                         ;;
4881                 (.-)
4882                         ;;
4883                 (*)
4884                         CF_MSG_LOG(given option \"$cf_option\", no match \"$cf_result\")
4885                         ;;
4886                 esac
4887         done
4888         rm -f cf_makeflags.tmp
4889 ])
4890
4891 AC_SUBST(cf_cv_makeflags)
4892 ])dnl
4893 dnl ---------------------------------------------------------------------------
4894 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
4895 dnl ------------
4896 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
4897 dnl a monocase filesystem.
4898 AC_DEFUN([CF_MAKE_TAGS],[
4899 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
4900
4901 AC_CHECK_PROGS(CTAGS, exctags ctags)
4902 AC_CHECK_PROGS(ETAGS, exetags etags)
4903
4904 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
4905
4906 if test "$cf_cv_mixedcase" = yes ; then
4907         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
4908 else
4909         MAKE_UPPER_TAGS=no
4910 fi
4911
4912 if test "$MAKE_UPPER_TAGS" = yes ; then
4913         MAKE_UPPER_TAGS=
4914 else
4915         MAKE_UPPER_TAGS="#"
4916 fi
4917
4918 if test "$MAKE_LOWER_TAGS" = yes ; then
4919         MAKE_LOWER_TAGS=
4920 else
4921         MAKE_LOWER_TAGS="#"
4922 fi
4923
4924 AC_SUBST(CTAGS)
4925 AC_SUBST(ETAGS)
4926
4927 AC_SUBST(MAKE_UPPER_TAGS)
4928 AC_SUBST(MAKE_LOWER_TAGS)
4929 ])dnl
4930 dnl ---------------------------------------------------------------------------
4931 dnl CF_MANPAGE_FORMAT version: 11 updated: 2015/04/18 08:56:57
4932 dnl -----------------
4933 dnl Option to allow user to override automatic configuration of manpage format.
4934 dnl There are several special cases:
4935 dnl
4936 dnl     gzip - man checks for, can display gzip'd files
4937 dnl     compress - man checks for, can display compressed files
4938 dnl     BSDI - files in the cat-directories are suffixed ".0"
4939 dnl     formatted - installer should format (put files in cat-directory)
4940 dnl     catonly - installer should only format, e.g., for a turnkey system.
4941 dnl
4942 dnl There are other configurations which this macro does not test, e.g., HPUX's
4943 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
4944 dnl convention would not match our use).
4945 AC_DEFUN([CF_MANPAGE_FORMAT],
4946 [
4947 AC_REQUIRE([CF_PATHSEP])
4948 AC_MSG_CHECKING(format of man-pages)
4949
4950 AC_ARG_WITH(manpage-format,
4951         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
4952                           optionally formatted/catonly, e.g., gzip,formatted],
4953         [MANPAGE_FORMAT=$withval],
4954         [MANPAGE_FORMAT=unknown])
4955
4956 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
4957 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
4958
4959 cf_unknown=
4960
4961 case $MANPAGE_FORMAT in
4962 (unknown)
4963         if test -z "$MANPATH" ; then
4964                 MANPATH="/usr/man:/usr/share/man"
4965         fi
4966
4967         # look for the 'date' man-page (it's most likely to be installed!)
4968         MANPAGE_FORMAT=
4969         cf_preform=no
4970         cf_catonly=yes
4971         cf_example=date
4972
4973         IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
4974         for cf_dir in $MANPATH; do
4975                 test -z "$cf_dir" && cf_dir=/usr/man
4976                 for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
4977                 do
4978                         cf_test=`echo $cf_name | sed -e 's/*//'`
4979                         if test "x$cf_test" = "x$cf_name" ; then
4980
4981                                 case "$cf_name" in
4982                                 (*.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
4983                                 (*.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
4984                                 (*.0)  MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
4985                                 (*)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
4986                                 esac
4987
4988                                 case "$cf_name" in
4989                                 ($cf_dir/man*)
4990                                         cf_catonly=no
4991                                         ;;
4992                                 ($cf_dir/cat*)
4993                                         cf_preform=yes
4994                                         ;;
4995                                 esac
4996                                 break
4997                         fi
4998
4999                         # if we found a match in either man* or cat*, stop looking
5000                         if test -n "$MANPAGE_FORMAT" ; then
5001                                 cf_found=no
5002                                 test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
5003                                 test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
5004                                 case "$cf_name" in
5005                                 ($cf_dir/cat*)
5006                                         cf_found=yes
5007                                         ;;
5008                                 esac
5009                                 test $cf_found=yes && break
5010                         fi
5011                 done
5012                 # only check the first directory in $MANPATH where we find manpages
5013                 if test -n "$MANPAGE_FORMAT" ; then
5014                         break
5015                 fi
5016         done
5017         # if we did not find the example, just assume it is normal
5018         test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
5019         IFS="$ac_save_ifs"
5020         ;;
5021 (*)
5022         for cf_option in $MANPAGE_FORMAT; do
5023         case $cf_option in
5024         (gzip|compress|BSDI|normal|formatted|catonly)
5025                 ;;
5026         (*)
5027                 cf_unknown="$cf_unknown $cf_option"
5028                 ;;
5029         esac
5030         done
5031         ;;
5032 esac
5033
5034 AC_MSG_RESULT($MANPAGE_FORMAT)
5035 if test -n "$cf_unknown" ; then
5036         AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
5037 fi
5038 ])dnl
5039 dnl ---------------------------------------------------------------------------
5040 dnl CF_MANPAGE_RENAMES version: 10 updated: 2015/08/05 20:44:28
5041 dnl ------------------
5042 dnl The Debian people have their own naming convention for manpages.  This
5043 dnl option lets us override the name of the file containing renaming, or
5044 dnl disable it altogether.
5045 AC_DEFUN([CF_MANPAGE_RENAMES],
5046 [
5047 AC_MSG_CHECKING(for manpage renaming)
5048
5049 AC_ARG_WITH(manpage-renames,
5050         [  --with-manpage-renames  specify manpage-renaming],
5051         [MANPAGE_RENAMES=$withval],
5052         [MANPAGE_RENAMES=yes])
5053
5054 case ".$MANPAGE_RENAMES" in
5055 (.no)
5056         ;;
5057 (.|.yes)
5058         # Debian 'man' program?
5059         if test -f /etc/debian_version ; then
5060                 MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
5061         else
5062                 MANPAGE_RENAMES=no
5063         fi
5064         ;;
5065 esac
5066
5067 if test "$MANPAGE_RENAMES" != no ; then
5068         if test -f $srcdir/man/$MANPAGE_RENAMES ; then
5069                 MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
5070         elif test ! -f $MANPAGE_RENAMES ; then
5071                 AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
5072         fi
5073
5074         test ! -d man && mkdir man
5075
5076         # Construct a sed-script to perform renaming within man-pages
5077         if test -n "$MANPAGE_RENAMES" ; then
5078                 test ! -d man && mkdir man
5079                 $SHELL $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
5080         fi
5081 fi
5082
5083 AC_MSG_RESULT($MANPAGE_RENAMES)
5084 AC_SUBST(MANPAGE_RENAMES)
5085 ])dnl
5086 dnl ---------------------------------------------------------------------------
5087 dnl CF_MANPAGE_SYMLINKS version: 6 updated: 2015/04/17 21:13:04
5088 dnl -------------------
5089 dnl Some people expect each tool to make all aliases for manpages in the
5090 dnl man-directory.  This accommodates the older, less-capable implementations
5091 dnl of 'man', and is optional.
5092 AC_DEFUN([CF_MANPAGE_SYMLINKS],
5093 [
5094 AC_MSG_CHECKING(if manpage aliases will be installed)
5095
5096 AC_ARG_WITH(manpage-aliases,
5097         [  --with-manpage-aliases  specify manpage-aliases using .so],
5098         [MANPAGE_ALIASES=$withval],
5099         [MANPAGE_ALIASES=yes])
5100
5101 AC_MSG_RESULT($MANPAGE_ALIASES)
5102
5103 case "x$LN_S" in
5104 (xln*)
5105         cf_use_symlinks=yes
5106         ;;
5107 (*)
5108         cf_use_symlinks=no
5109         ;;
5110 esac
5111
5112 MANPAGE_SYMLINKS=no
5113 if test "$MANPAGE_ALIASES" = yes ; then
5114 AC_MSG_CHECKING(if manpage symlinks should be used)
5115
5116 AC_ARG_WITH(manpage-symlinks,
5117         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
5118         [MANPAGE_SYMLINKS=$withval],
5119         [MANPAGE_SYMLINKS=$cf_use_symlinks])
5120
5121 if test "$$cf_use_symlinks" = no; then
5122 if test "$MANPAGE_SYMLINKS" = yes ; then
5123         AC_MSG_WARN(cannot make symlinks, will use .so files)
5124         MANPAGE_SYMLINKS=no
5125 fi
5126 fi
5127
5128 AC_MSG_RESULT($MANPAGE_SYMLINKS)
5129 fi
5130
5131 ])dnl
5132 dnl ---------------------------------------------------------------------------
5133 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
5134 dnl --------------
5135 dnl This option causes manpages to be run through tbl(1) to generate tables
5136 dnl correctly.
5137 AC_DEFUN([CF_MANPAGE_TBL],
5138 [
5139 AC_MSG_CHECKING(for manpage tbl)
5140
5141 AC_ARG_WITH(manpage-tbl,
5142         [  --with-manpage-tbl      specify manpage processing with tbl],
5143         [MANPAGE_TBL=$withval],
5144         [MANPAGE_TBL=no])
5145
5146 AC_MSG_RESULT($MANPAGE_TBL)
5147 ])dnl
5148 dnl ---------------------------------------------------------------------------
5149 dnl CF_MAN_PAGES version: 47 updated: 2017/08/12 07:58:51
5150 dnl ------------
5151 dnl Try to determine if the man-pages on the system are compressed, and if
5152 dnl so, what format is used.  Use this information to construct a script that
5153 dnl will install man-pages.
5154 AC_DEFUN([CF_MAN_PAGES],
5155 [
5156 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
5157 CF_MANPAGE_FORMAT
5158 CF_MANPAGE_RENAMES
5159 CF_MANPAGE_SYMLINKS
5160 CF_MANPAGE_TBL
5161
5162 if test "$prefix" = "NONE" ; then
5163         cf_prefix="$ac_default_prefix"
5164 else
5165         cf_prefix="$prefix"
5166 fi
5167
5168 case "$MANPAGE_FORMAT" in
5169 (*catonly*)
5170         cf_format=yes
5171         cf_inboth=no
5172         ;;
5173 (*formatted*)
5174         cf_format=yes
5175         cf_inboth=yes
5176         ;;
5177 (*)
5178         cf_format=no
5179         cf_inboth=no
5180         ;;
5181 esac
5182
5183 test ! -d man && mkdir man
5184
5185 cf_so_strip=
5186 cf_compress=
5187 case "$MANPAGE_FORMAT" in
5188 (*compress*)
5189         cf_so_strip="Z"
5190         cf_compress=compress
5191         ;;
5192 (*gzip*)
5193         cf_so_strip="gz"
5194         cf_compress=gzip
5195         ;;
5196 esac
5197
5198 cf_edit_man=./edit_man.sh
5199 cf_man_alias=`pwd`/man_alias.sed
5200
5201 cat >$cf_edit_man <<CF_EOF
5202 #! $SHELL
5203 # this script is generated by the configure-script CF_MAN_PAGES macro.
5204
5205 prefix="$cf_prefix"
5206 datarootdir="$datarootdir"
5207 datadir="$datadir"
5208
5209 NCURSES_MAJOR="$NCURSES_MAJOR"
5210 NCURSES_MINOR="$NCURSES_MINOR"
5211 NCURSES_PATCH="$NCURSES_PATCH"
5212
5213 NCURSES_OSPEED="$NCURSES_OSPEED"
5214 TERMINFO="$TERMINFO"
5215
5216 INSTALL="$INSTALL"
5217 INSTALL_DATA="$INSTALL_DATA"
5218
5219 transform="$program_transform_name"
5220
5221 TMP=\${TMPDIR:=/tmp}/man\$\$
5222 trap "rm -f \$TMP" 0 1 2 3 15
5223
5224 form=\[$]1
5225 shift || exit 1
5226
5227 verb=\[$]1
5228 shift || exit 1
5229
5230 mandir=\[$]1
5231 shift || exit 1
5232
5233 srcdir=\[$]1
5234 top_srcdir=\[$]srcdir/..
5235 shift || exit 1
5236
5237 if test "\$form" = normal ; then
5238         if test "$cf_format" = yes ; then
5239         if test "$cf_inboth" = no ; then
5240                 $SHELL \[$]0 format \$verb \$mandir \$srcdir \[$]*
5241                 exit $?
5242         fi
5243         fi
5244         cf_subdir=\$mandir/man
5245         cf_tables=$MANPAGE_TBL
5246 else
5247         cf_subdir=\$mandir/cat
5248         cf_tables=yes
5249 fi
5250
5251 # process the list of source-files
5252 for i in \[$]* ; do
5253 case \$i in
5254 (*.orig|*.rej) ;;
5255 (*.[[0-9]]*)
5256         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
5257         if test \$verb = installing ; then
5258         if test ! -d \$cf_subdir\${section} ; then
5259                 mkdir -p \$cf_subdir\$section
5260         fi
5261         fi
5262
5263         # replace variables in man page
5264         if test ! -f $cf_man_alias ; then
5265 cat >>$cf_man_alias <<-CF_EOF2
5266                 s,@DATADIR@,\$datadir,g
5267                 s,@TERMINFO@,\${TERMINFO:="no default value"},g
5268                 s,@TERMINFO_DIRS@,\${TERMINFO_DIRS:="no default value"},g
5269                 s,@NCURSES_MAJOR@,\${NCURSES_MAJOR:="no default value"},g
5270                 s,@NCURSES_MINOR@,\${NCURSES_MINOR:="no default value"},g
5271                 s,@NCURSES_PATCH@,\${NCURSES_PATCH:="no default value"},g
5272                 s,@NCURSES_OSPEED@,\${NCURSES_OSPEED:="no default value"},g
5273 CF_EOF
5274         ifelse($1,,,[
5275         for cf_name in $1
5276         do
5277                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
5278                 cf_name=`echo $cf_name|sed "$program_transform_name"`
5279 cat >>$cf_edit_man <<-CF_EOF
5280                 s,@$cf_NAME@,$cf_name,g
5281 CF_EOF
5282         done
5283         ])
5284 cat >>$cf_edit_man <<CF_EOF
5285 CF_EOF2
5286                 echo "...made $cf_man_alias"
5287         fi
5288
5289         aliases=
5290         cf_source=\`basename \$i\`
5291         inalias=\$cf_source
5292         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
5293         if test ! -f \$inalias ; then
5294                 echo .. skipped \$cf_source
5295                 continue
5296         fi
5297 CF_EOF
5298
5299 if test "$MANPAGE_ALIASES" != no ; then
5300 cat >>$cf_edit_man <<CF_EOF
5301         nCurses=ignore.3x
5302         test $with_curses_h = yes && nCurses=ncurses.3x
5303         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
5304 CF_EOF
5305 fi
5306
5307 if test "$MANPAGE_RENAMES" = no ; then
5308 cat >>$cf_edit_man <<CF_EOF
5309         # perform program transformations for section 1 man pages
5310         if test \$section = 1 ; then
5311                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
5312         else
5313                 cf_target=\$cf_subdir\${section}/\$cf_source
5314         fi
5315 CF_EOF
5316 else
5317 cat >>$cf_edit_man <<CF_EOF
5318         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
5319         if test -z "\$cf_target" ; then
5320                 echo '? missing rename for '\$cf_source
5321                 cf_target="\$cf_source"
5322         fi
5323         cf_target="\$cf_subdir\${section}/\${cf_target}"
5324
5325 CF_EOF
5326 fi
5327
5328 cat >>$cf_edit_man <<CF_EOF
5329         sed     -f $cf_man_alias \\
5330 CF_EOF
5331
5332 if test -f $MANPAGE_RENAMES ; then
5333 cat >>$cf_edit_man <<CF_EOF
5334                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
5335 CF_EOF
5336 else
5337 cat >>$cf_edit_man <<CF_EOF
5338                 < \$i >\$TMP
5339 CF_EOF
5340 fi
5341
5342 cat >>$cf_edit_man <<CF_EOF
5343 if test \$cf_tables = yes ; then
5344         tbl \$TMP >\$TMP.out
5345         mv \$TMP.out \$TMP
5346 fi
5347 CF_EOF
5348
5349 if test $with_overwrite != yes ; then
5350 cat >>$cf_edit_man <<CF_EOF
5351         sed -e "/\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
5352         mv \$TMP.out \$TMP
5353 CF_EOF
5354 fi
5355
5356 if test $with_curses_h != yes ; then
5357 cat >>$cf_edit_man <<CF_EOF
5358         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
5359         mv \$TMP.out \$TMP
5360 CF_EOF
5361 fi
5362
5363 cat >>$cf_edit_man <<CF_EOF
5364         if test \$form = format ; then
5365                 nroff -man \$TMP >\$TMP.out
5366                 mv \$TMP.out \$TMP
5367         fi
5368 CF_EOF
5369
5370 if test -n "$cf_compress" ; then
5371 cat >>$cf_edit_man <<CF_EOF
5372         if test \$verb = installing ; then
5373         if ( $cf_compress -f \$TMP )
5374         then
5375                 mv \$TMP.$cf_so_strip \$TMP
5376         fi
5377         fi
5378         cf_target="\$cf_target.$cf_so_strip"
5379 CF_EOF
5380 fi
5381
5382 case "$MANPAGE_FORMAT" in
5383 (*BSDI*)
5384 cat >>$cf_edit_man <<CF_EOF
5385         if test \$form = format ; then
5386                 # BSDI installs only .0 suffixes in the cat directories
5387                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
5388         fi
5389 CF_EOF
5390   ;;
5391 esac
5392
5393 cat >>$cf_edit_man <<CF_EOF
5394         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
5395         if test \$verb = installing ; then
5396                 echo \$verb \$cf_target
5397                 \$INSTALL_DATA \$TMP \$cf_target
5398                 test -d \$cf_subdir\${section} &&
5399                 test -n "\$aliases" && (
5400                         cd \$cf_subdir\${section} && (
5401                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
5402                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
5403                                 cf_target=\`basename \$cf_target\`
5404                                 for cf_alias in \$aliases
5405                                 do
5406                                         if test \$section = 1 ; then
5407                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
5408                                         fi
5409
5410                                         if test "$MANPAGE_SYMLINKS" = yes ; then
5411                                                 if test -f \$cf_alias\${suffix} ; then
5412                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
5413                                                         then
5414                                                                 continue
5415                                                         fi
5416                                                 fi
5417                                                 echo .. \$verb alias \$cf_alias\${suffix}
5418 CF_EOF
5419 case "x$LN_S" in
5420 (*-f)
5421 cat >>$cf_edit_man <<CF_EOF
5422                                                 $LN_S \$cf_target \$cf_alias\${suffix}
5423 CF_EOF
5424         ;;
5425 (*)
5426 cat >>$cf_edit_man <<CF_EOF
5427                                                 rm -f \$cf_alias\${suffix}
5428                                                 $LN_S \$cf_target \$cf_alias\${suffix}
5429 CF_EOF
5430         ;;
5431 esac
5432 cat >>$cf_edit_man <<CF_EOF
5433                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
5434                                                 echo ".so \$cf_source" >\$TMP
5435 CF_EOF
5436 if test -n "$cf_compress" ; then
5437 cat >>$cf_edit_man <<CF_EOF
5438                                                 if test -n "$cf_so_strip" ; then
5439                                                         $cf_compress -f \$TMP
5440                                                         mv \$TMP.$cf_so_strip \$TMP
5441                                                 fi
5442 CF_EOF
5443 fi
5444 cat >>$cf_edit_man <<CF_EOF
5445                                                 echo .. \$verb alias \$cf_alias\${suffix}
5446                                                 rm -f \$cf_alias\${suffix}
5447                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
5448                                         fi
5449                                 done
5450                         )
5451                 )
5452         elif test \$verb = removing ; then
5453                 test -f \$cf_target && (
5454                         echo \$verb \$cf_target
5455                         rm -f \$cf_target
5456                 )
5457                 test -d \$cf_subdir\${section} &&
5458                 test -n "\$aliases" && (
5459                         cd \$cf_subdir\${section} && (
5460                                 for cf_alias in \$aliases
5461                                 do
5462                                         if test \$section = 1 ; then
5463                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
5464                                         fi
5465
5466                                         echo .. \$verb alias \$cf_alias\${suffix}
5467                                         rm -f \$cf_alias\${suffix}
5468                                 done
5469                         )
5470                 )
5471         else
5472 #               echo ".hy 0"
5473                 cat \$TMP
5474         fi
5475         ;;
5476 esac
5477 done
5478
5479 if test $cf_inboth = yes ; then
5480 if test \$form != format ; then
5481         $SHELL \[$]0 format \$verb \$mandir \$srcdir \[$]*
5482 fi
5483 fi
5484
5485 exit 0
5486 CF_EOF
5487 chmod 755 $cf_edit_man
5488
5489 ])dnl
5490 dnl ---------------------------------------------------------------------------
5491 dnl CF_MAP_LIB_BASENAME version: 1 updated: 2020/03/07 20:05:14
5492 dnl -------------------
5493 dnl Convert a default-libname to the actual one used via CF_WITH_LIB_BASENAME.
5494 dnl
5495 dnl $1 = variable to set
5496 dnl $2 = default-libname
5497 AC_DEFUN([CF_MAP_LIB_BASENAME],[
5498 CF_UPPER(cf_map_lib_basename,$2)
5499 eval $1=\$${cf_map_lib_basename}_NAME
5500 ])dnl
5501 dnl ---------------------------------------------------------------------------
5502 dnl CF_MATH_LIB version: 9 updated: 2017/01/21 11:06:25
5503 dnl -----------
5504 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
5505 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
5506 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
5507 AC_DEFUN([CF_MATH_LIB],
5508 [
5509 AC_CACHE_CHECK(if -lm needed for math functions,
5510         cf_cv_need_libm,[
5511         AC_TRY_LINK([
5512         #include <stdio.h>
5513         #include <stdlib.h>
5514         #include <math.h>
5515         ],
5516         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
5517         [cf_cv_need_libm=no],
5518         [cf_cv_need_libm=yes])])
5519 if test "$cf_cv_need_libm" = yes
5520 then
5521 ifelse($1,,[
5522         CF_ADD_LIB(m)
5523 ],[$1=-lm])
5524 fi
5525 ])
5526 dnl ---------------------------------------------------------------------------
5527 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
5528 dnl ----------------------
5529 dnl Check if the file-system supports mixed-case filenames.  If we're able to
5530 dnl create a lowercase name and see it as uppercase, it doesn't support that.
5531 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
5532 [
5533 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
5534 if test "$cross_compiling" = yes ; then
5535         case $target_alias in
5536         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
5537                 cf_cv_mixedcase=no
5538                 ;;
5539         (*)
5540                 cf_cv_mixedcase=yes
5541                 ;;
5542         esac
5543 else
5544         rm -f conftest CONFTEST
5545         echo test >conftest
5546         if test -f CONFTEST ; then
5547                 cf_cv_mixedcase=no
5548         else
5549                 cf_cv_mixedcase=yes
5550         fi
5551         rm -f conftest CONFTEST
5552 fi
5553 ])
5554 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
5555 ])dnl
5556 dnl ---------------------------------------------------------------------------
5557 dnl CF_MKSTEMP version: 10 updated: 2017/01/21 11:12:16
5558 dnl ----------
5559 dnl Check for a working mkstemp.  This creates two files, checks that they are
5560 dnl successfully created and distinct (AmigaOS apparently fails on the last).
5561 AC_DEFUN([CF_MKSTEMP],[
5562 AC_CHECK_HEADERS( \
5563 unistd.h \
5564 )
5565 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
5566 rm -rf conftest*
5567 AC_TRY_RUN([
5568 #include <sys/types.h>
5569 #ifdef HAVE_UNISTD_H
5570 #include <unistd.h>
5571 #endif
5572 #include <stdlib.h>
5573 #include <stdio.h>
5574 #include <string.h>
5575 #include <sys/stat.h>
5576 int main(void)
5577 {
5578         char *tmpl = "conftestXXXXXX";
5579         char name[2][80];
5580         int n;
5581         int result = 0;
5582         int fd;
5583         struct stat sb;
5584
5585         umask(077);
5586         for (n = 0; n < 2; ++n) {
5587                 strcpy(name[n], tmpl);
5588                 if ((fd = mkstemp(name[n])) >= 0) {
5589                         if (!strcmp(name[n], tmpl)
5590                          || stat(name[n], &sb) != 0
5591                          || (sb.st_mode & S_IFMT) != S_IFREG
5592                          || (sb.st_mode & 077) != 0) {
5593                                 result = 1;
5594                         }
5595                         close(fd);
5596                 }
5597         }
5598         if (result == 0
5599          && !strcmp(name[0], name[1]))
5600                 result = 1;
5601         ${cf_cv_main_return:-return}(result);
5602 }
5603 ],[cf_cv_func_mkstemp=yes
5604 ],[cf_cv_func_mkstemp=no
5605 ],[cf_cv_func_mkstemp=maybe])
5606 ])
5607 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
5608         AC_CHECK_FUNC(mkstemp)
5609 fi
5610 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
5611         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
5612 fi
5613 ])dnl
5614 dnl ---------------------------------------------------------------------------
5615 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
5616 dnl ----------
5617 dnl Write a debug message to config.log, along with the line number in the
5618 dnl configure script.
5619 AC_DEFUN([CF_MSG_LOG],[
5620 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
5621 ])dnl
5622 dnl ---------------------------------------------------------------------------
5623 dnl CF_NCURSES_ABI_6 version: 3 updated: 2015/06/06 16:10:11
5624 dnl ----------------
5625 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
5626 dnl warn about this.
5627 AC_DEFUN([CF_NCURSES_ABI_6],[
5628 if test "${with_abi_version+set}" != set; then
5629         case $cf_cv_rel_version in
5630         (5.*)
5631                 cf_cv_rel_version=6.0
5632                 cf_cv_abi_version=6
5633                 AC_MSG_WARN(overriding ABI version to $cf_cv_abi_version)
5634                 ;;
5635         esac
5636 fi
5637 ])dnl
5638 dnl ---------------------------------------------------------------------------
5639 dnl CF_NCURSES_WITH_ABI_VERSION version: 2 updated: 2015/12/19 17:51:52
5640 dnl ---------------------------
5641 dnl Allow ncurses's ABI to be overridden.  Generally this happens when a
5642 dnl packager has incremented the ABI past that used in the original package,
5643 dnl and wishes to keep doing this.
5644 dnl
5645 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
5646 dnl symbol.
5647 AC_DEFUN([CF_NCURSES_WITH_ABI_VERSION],[
5648 CF_WITH_ABI_VERSION($1)
5649 if test "x$cf_cv_abi_version" != "x$with_abi_version"
5650 then
5651         case $cf_cv_rel_version in
5652         (5.*)
5653                 cf_cv_rel_version=$with_abi_version.0
5654                 ;;
5655         esac
5656 fi
5657 ])dnl
5658 dnl ---------------------------------------------------------------------------
5659 dnl CF_NO_LEAKS_OPTION version: 6 updated: 2015/04/12 15:39:00
5660 dnl ------------------
5661 dnl see CF_WITH_NO_LEAKS
5662 AC_DEFUN([CF_NO_LEAKS_OPTION],[
5663 AC_MSG_CHECKING(if you want to use $1 for testing)
5664 AC_ARG_WITH($1,
5665         [$2],
5666         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
5667          $4
5668 ])
5669         : ${with_cflags:=-g}
5670         : ${with_no_leaks:=yes}
5671          with_$1=yes],
5672         [with_$1=])
5673 AC_MSG_RESULT(${with_$1:-no})
5674
5675 case .$with_cflags in
5676 (.*-g*)
5677         case .$CFLAGS in
5678         (.*-g*)
5679                 ;;
5680         (*)
5681                 CF_ADD_CFLAGS([-g])
5682                 ;;
5683         esac
5684         ;;
5685 esac
5686 ])dnl
5687 dnl ---------------------------------------------------------------------------
5688 dnl CF_NUMBER_SYNTAX version: 2 updated: 2015/04/17 21:13:04
5689 dnl ----------------
5690 dnl Check if the given variable is a number.  If not, report an error.
5691 dnl $1 is the variable
5692 dnl $2 is the message
5693 AC_DEFUN([CF_NUMBER_SYNTAX],[
5694 if test -n "$1" ; then
5695   case $1 in
5696   ([[0-9]]*)
5697         ;;
5698   (*)
5699         AC_MSG_ERROR($2 is not a number: $1)
5700         ;;
5701   esac
5702 else
5703   AC_MSG_ERROR($2 value is empty)
5704 fi
5705 ])dnl
5706 dnl ---------------------------------------------------------------------------
5707 dnl CF_OBJ_SUBDIR version: 7 updated: 2015/04/17 21:13:04
5708 dnl -------------
5709 dnl Compute the object-directory name from the given model name
5710 AC_DEFUN([CF_OBJ_SUBDIR],
5711 [
5712         case $1 in
5713         (libtool) $2='obj_lo'  ;;
5714         (normal)  $2='objects' ;;
5715         (debug)   $2='obj_g' ;;
5716         (profile) $2='obj_p' ;;
5717         (shared)
5718                 case $cf_cv_system_name in
5719                 (cygwin|msys)
5720                         $2='objects' ;;
5721                 (*)
5722                         $2='obj_s' ;;
5723                 esac
5724         esac
5725 ])dnl
5726 dnl ---------------------------------------------------------------------------
5727 dnl CF_PATHSEP version: 7 updated: 2015/04/12 15:39:00
5728 dnl ----------
5729 dnl Provide a value for the $PATH and similar separator (or amend the value
5730 dnl as provided in autoconf 2.5x).
5731 AC_DEFUN([CF_PATHSEP],
5732 [
5733         AC_MSG_CHECKING(for PATH separator)
5734         case $cf_cv_system_name in
5735         (os2*)  PATH_SEPARATOR=';'  ;;
5736         (*)     ${PATH_SEPARATOR:=':'}  ;;
5737         esac
5738 ifelse([$1],,,[$1=$PATH_SEPARATOR])
5739         AC_SUBST(PATH_SEPARATOR)
5740         AC_MSG_RESULT($PATH_SEPARATOR)
5741 ])dnl
5742 dnl ---------------------------------------------------------------------------
5743 dnl CF_PATH_PROG version: 10 updated: 2019/06/30 19:44:43
5744 dnl ------------
5745 dnl Check for a given program, defining corresponding symbol.
5746 dnl     $1 = environment variable, which is suffixed by "_PATH" in the #define.
5747 dnl     $2 = program name to find.
5748 dnl     $3 = optional list of additional program names to test.
5749 dnl $4 = $PATH
5750 dnl
5751 dnl If there is more than one token in the result, #define the remaining tokens
5752 dnl to $1_ARGS.  We need this for 'install' in particular.
5753 dnl
5754 dnl FIXME: we should allow this to be overridden by environment variables
5755 dnl
5756 AC_DEFUN([CF_PATH_PROG],[
5757 AC_REQUIRE([CF_PATHSEP])
5758 test -z "[$]$1" && $1=$2
5759 AC_PATH_PROGS($1,[$]$1 $2 ifelse($3,,,$3),[$]$1, ifelse($4,,,$4))
5760
5761 cf_path_prog=""
5762 cf_path_args=""
5763 IFS="${IFS:-    }"; cf_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR"
5764 for cf_temp in $ac_cv_path_$1
5765 do
5766         if test -z "$cf_path_prog" ; then
5767                 if test "$with_full_paths" = yes ; then
5768                         CF_PATH_SYNTAX(cf_temp,break)
5769                         cf_path_prog="$cf_temp"
5770                 else
5771                         cf_path_prog="`basename $cf_temp`"
5772                 fi
5773         elif test -z "$cf_path_args" ; then
5774                 cf_path_args="$cf_temp"
5775         else
5776                 cf_path_args="$cf_path_args $cf_temp"
5777         fi
5778 done
5779 IFS="$cf_save_ifs"
5780
5781 if test -n "$cf_path_prog" ; then
5782         CF_MSG_LOG(defining path for ${cf_path_prog})
5783         AC_DEFINE_UNQUOTED($1_PATH,"$cf_path_prog",Define to pathname $1)
5784         test -n "$cf_path_args" && AC_DEFINE_UNQUOTED($1_ARGS,"$cf_path_args",Define to provide args for $1)
5785 fi
5786 ])dnl
5787 dnl ---------------------------------------------------------------------------
5788 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
5789 dnl --------------
5790 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
5791 dnl begins with one of the prefix/exec_prefix variables, and then again if the
5792 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
5793 dnl delayed evaluation of those symbols.
5794 AC_DEFUN([CF_PATH_SYNTAX],[
5795 if test "x$prefix" != xNONE; then
5796         cf_path_syntax="$prefix"
5797 else
5798         cf_path_syntax="$ac_default_prefix"
5799 fi
5800
5801 case ".[$]$1" in
5802 (.\[$]\(*\)*|.\'*\'*)
5803         ;;
5804 (..|./*|.\\*)
5805         ;;
5806 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
5807         ;;
5808 (.\[$]{*prefix}*|.\[$]{*dir}*)
5809         eval $1="[$]$1"
5810         case ".[$]$1" in
5811         (.NONE/*)
5812                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
5813                 ;;
5814         esac
5815         ;;
5816 (.no|.NONE/*)
5817         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
5818         ;;
5819 (*)
5820         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
5821         ;;
5822 esac
5823 ])dnl
5824 dnl ---------------------------------------------------------------------------
5825 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
5826 dnl -------------
5827 dnl Check for the package-config program, unless disabled by command-line.
5828 AC_DEFUN([CF_PKG_CONFIG],
5829 [
5830 AC_MSG_CHECKING(if you want to use pkg-config)
5831 AC_ARG_WITH(pkg-config,
5832         [  --with-pkg-config{=path} enable/disable use of pkg-config],
5833         [cf_pkg_config=$withval],
5834         [cf_pkg_config=yes])
5835 AC_MSG_RESULT($cf_pkg_config)
5836
5837 case $cf_pkg_config in
5838 (no)
5839         PKG_CONFIG=none
5840         ;;
5841 (yes)
5842         CF_ACVERSION_CHECK(2.52,
5843                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
5844                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
5845         ;;
5846 (*)
5847         PKG_CONFIG=$withval
5848         ;;
5849 esac
5850
5851 test -z "$PKG_CONFIG" && PKG_CONFIG=none
5852 if test "$PKG_CONFIG" != none ; then
5853         CF_PATH_SYNTAX(PKG_CONFIG)
5854 elif test "x$cf_pkg_config" != xno ; then
5855         AC_MSG_WARN(pkg-config is not installed)
5856 fi
5857
5858 AC_SUBST(PKG_CONFIG)
5859 ])dnl
5860 dnl ---------------------------------------------------------------------------
5861 dnl CF_POSIX_C_SOURCE version: 11 updated: 2018/12/31 20:46:17
5862 dnl -----------------
5863 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
5864 dnl
5865 dnl     POSIX.1-1990                            _POSIX_SOURCE
5866 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
5867 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
5868 dnl             Bindings Option
5869 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
5870 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
5871 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
5872 dnl
5873 dnl Parameters:
5874 dnl     $1 is the nominal value for _POSIX_C_SOURCE
5875 AC_DEFUN([CF_POSIX_C_SOURCE],
5876 [AC_REQUIRE([CF_POSIX_VISIBLE])dnl
5877
5878 if test "$cf_cv_posix_visible" = no; then
5879
5880 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
5881
5882 cf_save_CFLAGS="$CFLAGS"
5883 cf_save_CPPFLAGS="$CPPFLAGS"
5884
5885 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
5886 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
5887
5888 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
5889         CF_MSG_LOG(if the symbol is already defined go no further)
5890         AC_TRY_COMPILE([#include <sys/types.h>],[
5891 #ifndef _POSIX_C_SOURCE
5892 make an error
5893 #endif],
5894         [cf_cv_posix_c_source=no],
5895         [cf_want_posix_source=no
5896          case .$cf_POSIX_C_SOURCE in
5897          (.[[12]]??*)
5898                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
5899                 ;;
5900          (.2)
5901                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
5902                 cf_want_posix_source=yes
5903                 ;;
5904          (.*)
5905                 cf_want_posix_source=yes
5906                 ;;
5907          esac
5908          if test "$cf_want_posix_source" = yes ; then
5909                 AC_TRY_COMPILE([#include <sys/types.h>],[
5910 #ifdef _POSIX_SOURCE
5911 make an error
5912 #endif],[],
5913                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
5914          fi
5915          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
5916          CFLAGS="$cf_trim_CFLAGS"
5917          CPPFLAGS="$cf_trim_CPPFLAGS"
5918          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
5919          CF_MSG_LOG(if the second compile does not leave our definition intact error)
5920          AC_TRY_COMPILE([#include <sys/types.h>],[
5921 #ifndef _POSIX_C_SOURCE
5922 make an error
5923 #endif],,
5924          [cf_cv_posix_c_source=no])
5925          CFLAGS="$cf_save_CFLAGS"
5926          CPPFLAGS="$cf_save_CPPFLAGS"
5927         ])
5928 ])
5929
5930 if test "$cf_cv_posix_c_source" != no ; then
5931         CFLAGS="$cf_trim_CFLAGS"
5932         CPPFLAGS="$cf_trim_CPPFLAGS"
5933         CF_ADD_CFLAGS($cf_cv_posix_c_source)
5934 fi
5935
5936 fi # cf_cv_posix_visible
5937
5938 ])dnl
5939 dnl ---------------------------------------------------------------------------
5940 dnl CF_POSIX_VISIBLE version: 1 updated: 2018/12/31 20:46:17
5941 dnl ----------------
5942 dnl POSIX documents test-macros which an application may set before any system
5943 dnl headers are included to make features available.
5944 dnl
5945 dnl Some BSD platforms (originally FreeBSD, but copied by a few others)
5946 dnl diverged from POSIX in 2002 by setting symbols which make all of the most
5947 dnl recent features visible in the system header files unless the application
5948 dnl overrides the corresponding test-macros.  Doing that introduces portability
5949 dnl problems.
5950 dnl
5951 dnl This macro makes a special check for the symbols used for this, to avoid a
5952 dnl conflicting definition.
5953 AC_DEFUN([CF_POSIX_VISIBLE],
5954 [
5955 AC_CACHE_CHECK(if the POSIX test-macros are already defined,cf_cv_posix_visible,[
5956 AC_TRY_COMPILE([#include <stdio.h>],[
5957 #if defined(__POSIX_VISIBLE) && ((__POSIX_VISIBLE - 0L) > 0) \
5958         && defined(__XSI_VISIBLE) && ((__XSI_VISIBLE - 0L) > 0) \
5959         && defined(__BSD_VISIBLE) && ((__BSD_VISIBLE - 0L) > 0) \
5960         && defined(__ISO_C_VISIBLE) && ((__ISO_C_VISIBLE - 0L) > 0)
5961 #error conflicting symbols found
5962 #endif
5963 ],[cf_cv_posix_visible=no],[cf_cv_posix_visible=yes])
5964 ])
5965 ])dnl
5966 dnl ---------------------------------------------------------------------------
5967 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
5968 dnl ------------
5969 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
5970 dnl
5971 dnl $1 = symbol to test
5972 dnl $2 = value (if any) to use for a predefinition
5973 AC_DEFUN([CF_PREDEFINE],
5974 [
5975 AC_MSG_CHECKING(if we must define $1)
5976 AC_TRY_COMPILE([#include <sys/types.h>
5977 ],[
5978 #ifndef $1
5979 make an error
5980 #endif],[cf_result=no],[cf_result=yes])
5981 AC_MSG_RESULT($cf_result)
5982
5983 if test "$cf_result" = yes ; then
5984         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
5985 elif test "x$2" != "x" ; then
5986         AC_MSG_CHECKING(checking for compatible value versus $2)
5987         AC_TRY_COMPILE([#include <sys/types.h>
5988 ],[
5989 #if $1-$2 < 0
5990 make an error
5991 #endif],[cf_result=yes],[cf_result=no])
5992         AC_MSG_RESULT($cf_result)
5993         if test "$cf_result" = no ; then
5994                 # perhaps we can override it - try...
5995                 CPPFLAGS="$CPPFLAGS -D$1=$2"
5996         fi
5997 fi
5998 ])dnl
5999 dnl ---------------------------------------------------------------------------
6000 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
6001 dnl ------------
6002 dnl Append definitions and rules for the given programs to the subdirectory
6003 dnl Makefiles, and the recursion rule for the top-level Makefile.
6004 dnl
6005 dnl parameters
6006 dnl     $1 = script to run
6007 dnl     $2 = list of subdirectories
6008 dnl
6009 dnl variables
6010 dnl     $AWK
6011 AC_DEFUN([CF_PRG_RULES],
6012 [
6013 for cf_dir in $2
6014 do
6015         if test ! -d $srcdir/$cf_dir; then
6016                 continue
6017         elif test -f $srcdir/$cf_dir/programs; then
6018                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
6019         fi
6020 done
6021
6022 ])dnl
6023 dnl ---------------------------------------------------------------------------
6024 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
6025 dnl ----------
6026 dnl Check for archiver "ar".
6027 AC_DEFUN([CF_PROG_AR],[
6028 AC_CHECK_TOOL(AR, ar, ar)
6029 ])
6030 dnl ---------------------------------------------------------------------------
6031 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
6032 dnl -----------
6033 dnl Check for awk, ensure that the check found something.
6034 AC_DEFUN([CF_PROG_AWK],
6035 [
6036 AC_PROG_AWK
6037 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
6038 ])dnl
6039 dnl ---------------------------------------------------------------------------
6040 dnl CF_PROG_CC version: 5 updated: 2019/12/31 08:53:54
6041 dnl ----------
6042 dnl standard check for CC, plus followup sanity checks
6043 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
6044 AC_DEFUN([CF_PROG_CC],[
6045 CF_ACVERSION_CHECK(2.53,
6046         [AC_MSG_WARN(this will incorrectly handle gnatgcc choice)
6047          AC_REQUIRE([AC_PROG_CC])],
6048         [])
6049 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
6050 CF_GCC_VERSION
6051 CF_ACVERSION_CHECK(2.52,
6052         [AC_PROG_CC_STDC],
6053         [CF_ANSI_CC_REQD])
6054 CF_CC_ENV_FLAGS
6055 ])dnl
6056 dnl ---------------------------------------------------------------------------
6057 dnl CF_PROG_CC_C_O version: 5 updated: 2017/01/21 11:06:25
6058 dnl --------------
6059 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
6060 dnl the output file can be renamed, and allows for a shell variable that can
6061 dnl be used later.  The parameter is either CC or CXX.  The result is the
6062 dnl cache variable:
6063 dnl     $cf_cv_prog_CC_c_o
6064 dnl     $cf_cv_prog_CXX_c_o
6065 dnl
6066 dnl $1 = compiler
6067 dnl $2 = compiler options, if any
6068 AC_DEFUN([CF_PROG_CC_C_O],
6069 [AC_REQUIRE([AC_PROG_CC])dnl
6070 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
6071 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
6072 [
6073 cat > conftest.$ac_ext <<CF_EOF
6074 int main(void)
6075 {
6076         ${cf_cv_main_return:-return}(0);
6077 }
6078 CF_EOF
6079 # We do the test twice because some compilers refuse to overwrite an
6080 # existing .o file with -o, though they will create one.
6081 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
6082 if AC_TRY_EVAL(ac_try) &&
6083   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
6084 then
6085   eval cf_cv_prog_$1_c_o=yes
6086 else
6087   eval cf_cv_prog_$1_c_o=no
6088 fi
6089 rm -rf conftest*
6090 ])dnl
6091 if test $cf_cv_prog_$1_c_o = yes; then
6092   AC_MSG_RESULT([yes])
6093 else
6094   AC_MSG_RESULT([no])
6095 fi
6096 ])dnl
6097 dnl ---------------------------------------------------------------------------
6098 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
6099 dnl -------------
6100 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
6101 dnl This macro adds a check to ensure the script found something.
6102 AC_DEFUN([CF_PROG_EGREP],
6103 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
6104         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
6105                 then ac_cv_prog_egrep='grep -E'
6106                 else ac_cv_prog_egrep='egrep'
6107         fi])
6108         EGREP=$ac_cv_prog_egrep
6109         AC_SUBST([EGREP])
6110         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
6111 ])dnl
6112 dnl ---------------------------------------------------------------------------
6113 dnl CF_PROG_GNAT version: 10 updated: 2019/12/31 08:53:54
6114 dnl ------------
6115 dnl Check for gnat/gnatmake/etc, ensure that the toolset is complete.
6116 AC_DEFUN([CF_PROG_GNAT],[
6117 for cf_prog_gnat in gnat gnatmake gprconfig gprbuild
6118 do
6119         CF_UPPER(cf_upper_prog_gnat,${cf_prog_gnat})
6120
6121         unset ac_cv_path_cf_TEMP_gnat
6122         unset cf_TEMP_gnat
6123         AC_PATH_PROG(cf_TEMP_gnat,$cf_prog_gnat,no)
6124         eval cf_cv_PATH_$cf_upper_prog_gnat=[$]ac_cv_path_cf_TEMP_gnat
6125
6126         if test "x$cf_TEMP_gnat" != xno; then
6127                 unset cf_cv_gnat_version
6128                 unset cf_TEMP_gnat
6129                 CF_GNAT_VERSION(cf_TEMP_gnat,$cf_prog_gnat)
6130         fi
6131         eval cf_cv_VERSION_$cf_upper_prog_gnat=[$]cf_TEMP_gnat
6132
6133         unset cf_TEMP_gnat
6134         unset cf_cv_gnat_version
6135         unset ac_cv_path_cf_TEMP_gnat
6136 done
6137
6138 if test "x$cf_cv_VERSION_GNATMAKE" = "xno"; then
6139         cf_ada_make=
6140         cf_cv_prog_gnat_correct=no
6141 else
6142         cf_ada_make=gnatmake
6143         if test "x$cf_cv_VERSION_GPRCONFIG" = "xno"; then
6144                 # gprconfig is newer than gnatmake; we can continue...
6145                 cf_ada_config="##"
6146         else
6147                 rm -rf conftest* *~conftest*
6148                 if mkdir conftest.src
6149                 then
6150                         cf_ada_config=""
6151                         cd conftest.src
6152                         for cf_gprconfig in Ada C
6153                         do
6154                                 AC_MSG_CHECKING(for gprconfig name for $cf_gprconfig)
6155                                 if test $cf_gprconfig = C
6156                                 then
6157                                         for cf_gprconfig_param in \
6158                                                 $cf_gprconfig,,,,GNATGCC \
6159                                                 $cf_gprconfig,,,,GCC \
6160                                                 $cf_gprconfig
6161                                         do
6162                                                 cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
6163                                                 test -n "$cf_gprconfig_value" && break
6164                                         done
6165                                 else
6166                                         cf_gprconfig_param=$cf_gprconfig
6167                                         cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
6168                                 fi
6169                                 if test -n "$cf_gprconfig_value"
6170                                 then
6171                                         eval cf_ada_config_[$]cf_gprconfig=[$]cf_gprconfig_value
6172                                         AC_MSG_RESULT($cf_gprconfig_value)
6173                                 else
6174                                         AC_MSG_RESULT(missing)
6175                                         cf_ada_config="#"
6176                                         break
6177                                 fi
6178                         done
6179                         cd ..
6180                         rm -rf conftest* *~conftest*
6181                 fi
6182         fi
6183         if test "x$cf_ada_config" != "x#"
6184         then
6185                 CF_GNAT_VERSION
6186                 CF_CHECK_GNAT_VERSION
6187                 AC_CHECK_PROG(M4_exists, m4, yes, no)
6188                 if test "$ac_cv_prog_M4_exists" = no; then
6189                         cf_cv_prog_gnat_correct=no
6190                         AC_MSG_WARN(Ada95 binding required program m4 not found. Ada95 binding disabled)
6191                 fi
6192                 if test "$cf_cv_prog_gnat_correct" = yes; then
6193                         AC_MSG_CHECKING(if GNAT works)
6194                         CF_GNAT_TRY_RUN([procedure conftest;],
6195 [with Text_IO;
6196 with GNAT.OS_Lib;
6197 procedure conftest is
6198 begin
6199    Text_IO.Put ("Hello World");
6200    Text_IO.New_Line;
6201    GNAT.OS_Lib.OS_Exit (0);
6202 end conftest;],
6203 [cf_cv_prog_gnat_correct=yes],
6204 [cf_cv_prog_gnat_correct=no])
6205                         AC_MSG_RESULT($cf_cv_prog_gnat_correct)
6206                 fi
6207         else
6208                 cf_cv_prog_gnat_correct=no
6209         fi
6210 fi
6211
6212 AC_SUBST(cf_ada_make)
6213 AC_SUBST(cf_ada_config)
6214 AC_SUBST(cf_ada_config_Ada)
6215 AC_SUBST(cf_ada_config_C)
6216 ])dnl
6217 dnl ---------------------------------------------------------------------------
6218 dnl CF_PROG_INSTALL version: 7 updated: 2015/04/18 08:56:57
6219 dnl ---------------
6220 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
6221 dnl misc/tabset install won't work properly.  Usually this happens only when
6222 dnl using the fallback mkinstalldirs script
6223 AC_DEFUN([CF_PROG_INSTALL],
6224 [AC_PROG_INSTALL
6225 case $INSTALL in
6226 (/*)
6227         ;;
6228 (*)
6229         CF_DIRNAME(cf_dir,$INSTALL)
6230         test -z "$cf_dir" && cf_dir=.
6231         INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
6232         ;;
6233 esac
6234 ])dnl
6235 dnl ---------------------------------------------------------------------------
6236 dnl CF_PROG_LDCONFIG version: 5 updated: 2015/04/18 08:56:57
6237 dnl ----------------
6238 dnl Check for ldconfig, needed to fixup shared libraries that would be built
6239 dnl and then used in the install.
6240 AC_DEFUN([CF_PROG_LDCONFIG],[
6241 if test "$cross_compiling" = yes ; then
6242         LDCONFIG=:
6243 else
6244         case "$cf_cv_system_name" in
6245         (dragonfly*|mirbsd*|freebsd*)
6246                 test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
6247                 ;;
6248         (*) LDPATH=$PATH:/sbin:/usr/sbin
6249                 AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
6250                 ;;
6251         esac
6252 fi
6253 AC_SUBST(LDCONFIG)
6254 ])dnl
6255 dnl ---------------------------------------------------------------------------
6256 dnl CF_PROG_LINT version: 4 updated: 2019/11/20 18:55:37
6257 dnl ------------
6258 AC_DEFUN([CF_PROG_LINT],
6259 [
6260 AC_CHECK_PROGS(LINT, lint cppcheck splint)
6261 case "x$LINT" in
6262 (xcppcheck|x*/cppcheck)
6263         test -z "$LINT_OPTS" && LINT_OPTS="--enable=all"
6264         ;;
6265 esac
6266 AC_SUBST(LINT_OPTS)
6267 ])dnl
6268 dnl ---------------------------------------------------------------------------
6269 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
6270 dnl ------------
6271 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
6272 dnl option if it is supported.
6273 AC_DEFUN([CF_PROG_LN_S],[
6274 AC_PROG_LN_S
6275 AC_MSG_CHECKING(if $LN_S -f options work)
6276
6277 rm -f conf$$.src conf$$dst
6278 echo >conf$$.dst
6279 echo first >conf$$.src
6280 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
6281         cf_prog_ln_sf=yes
6282 else
6283         cf_prog_ln_sf=no
6284 fi
6285 rm -f conf$$.dst conf$$src
6286 AC_MSG_RESULT($cf_prog_ln_sf)
6287
6288 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
6289 ])dnl
6290 dnl ---------------------------------------------------------------------------
6291 dnl CF_REGEX version: 12 updated: 2015/04/18 08:56:57
6292 dnl --------
6293 dnl Attempt to determine if we've got one of the flavors of regular-expression
6294 dnl code that we can support.
6295 AC_DEFUN([CF_REGEX],
6296 [
6297
6298 cf_regex_func=no
6299
6300 cf_regex_libs="regex re"
6301 case $host_os in
6302 (mingw*)
6303         cf_regex_libs="gnurx $cf_regex_libs"
6304         ;;
6305 esac
6306
6307 AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
6308         for cf_regex_lib in $cf_regex_libs
6309         do
6310                 AC_CHECK_LIB($cf_regex_lib,regcomp,[
6311                                 CF_ADD_LIB($cf_regex_lib)
6312                                 cf_regex_func=regcomp
6313                                 break])
6314         done
6315 ])
6316
6317 if test "$cf_regex_func" = no ; then
6318         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
6319                 AC_CHECK_LIB(gen,compile,[
6320                                 CF_ADD_LIB(gen)
6321                                 cf_regex_func=compile])])
6322 fi
6323
6324 if test "$cf_regex_func" = no ; then
6325         AC_MSG_WARN(cannot find regular expression library)
6326 fi
6327
6328 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
6329
6330 cf_cv_regex_hdrs=no
6331 case $cf_regex_func in
6332 (compile)
6333         for cf_regex_hdr in regexp.h regexpr.h
6334         do
6335                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
6336                         char *p = compile("", "", "", 0);
6337                         int x = step("", "");
6338                 ],[
6339                         cf_cv_regex_hdrs=$cf_regex_hdr
6340                         break
6341                 ])
6342         done
6343         ;;
6344 (*)
6345         for cf_regex_hdr in regex.h
6346         do
6347                 AC_TRY_LINK([#include <sys/types.h>
6348 #include <$cf_regex_hdr>],[
6349                         regex_t *p;
6350                         int x = regcomp(p, "", 0);
6351                         int y = regexec(p, "", 0, 0, 0);
6352                         regfree(p);
6353                 ],[
6354                         cf_cv_regex_hdrs=$cf_regex_hdr
6355                         break
6356                 ])
6357         done
6358         ;;
6359 esac
6360
6361 ])
6362
6363 case $cf_cv_regex_hdrs in
6364         (no)            AC_MSG_WARN(no regular expression header found) ;;
6365         (regex.h)       AC_DEFINE(HAVE_REGEX_H_FUNCS,1,[Define to 1 to include regex.h for regular expressions]) ;;
6366         (regexp.h)      AC_DEFINE(HAVE_REGEXP_H_FUNCS,1,[Define to 1 to include regexp.h for regular expressions]) ;;
6367         (regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS,1,[Define to 1 to include regexpr.h for regular expressions]) ;;
6368 esac
6369 ])dnl
6370 dnl ---------------------------------------------------------------------------
6371 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
6372 dnl ----------------
6373 dnl Remove all -U and -D options that refer to the given symbol from a list
6374 dnl of C compiler options.  This works around the problem that not all
6375 dnl compilers process -U and -D options from left-to-right, so a -U option
6376 dnl cannot be used to cancel the effect of a preceding -D option.
6377 dnl
6378 dnl $1 = target (which could be the same as the source variable)
6379 dnl $2 = source (including '$')
6380 dnl $3 = symbol to remove
6381 define([CF_REMOVE_DEFINE],
6382 [
6383 $1=`echo "$2" | \
6384         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
6385                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
6386 ])dnl
6387 dnl ---------------------------------------------------------------------------
6388 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
6389 dnl -------------
6390 dnl Remove the given library from the symbol
6391 dnl
6392 dnl $1 = target (which could be the same as the source variable)
6393 dnl $2 = source (including '$')
6394 dnl $3 = library to remove
6395 define([CF_REMOVE_LIB],
6396 [
6397 # remove $3 library from $2
6398 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
6399 ])dnl
6400 dnl ---------------------------------------------------------------------------
6401 dnl CF_RESTORE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:47:45
6402 dnl ---------------------
6403 dnl Restore flags saved in CF_SAVE_XTRA_FLAGS
6404 dnl $1 = name of current macro
6405 define([CF_RESTORE_XTRA_FLAGS],
6406 [
6407 LIBS="$cf_save_LIBS_$1"
6408 CFLAGS="$cf_save_CFLAGS_$1"
6409 CPPFLAGS="$cf_save_CPPFLAGS_$1"
6410 ])dnl
6411 dnl ---------------------------------------------------------------------------
6412 dnl CF_RPATH_HACK version: 11 updated: 2013/09/01 13:02:00
6413 dnl -------------
6414 AC_DEFUN([CF_RPATH_HACK],
6415 [
6416 AC_REQUIRE([CF_LD_RPATH_OPT])
6417 AC_MSG_CHECKING(for updated LDFLAGS)
6418 if test -n "$LD_RPATH_OPT" ; then
6419         AC_MSG_RESULT(maybe)
6420
6421         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
6422         cf_rpath_list="/usr/lib /lib"
6423         if test "$cf_ldd_prog" != no
6424         then
6425                 cf_rpath_oops=
6426
6427 AC_TRY_LINK([#include <stdio.h>],
6428                 [printf("Hello");],
6429                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
6430                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
6431
6432                 # If we passed the link-test, but get a "not found" on a given library,
6433                 # this could be due to inept reconfiguration of gcc to make it only
6434                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
6435                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
6436                 # /usr/local libraries.
6437                 if test -n "$cf_rpath_oops"
6438                 then
6439                         for cf_rpath_src in $cf_rpath_oops
6440                         do
6441                                 for cf_rpath_dir in \
6442                                         /usr/local \
6443                                         /usr/pkg \
6444                                         /opt/sfw
6445                                 do
6446                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
6447                                         then
6448                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
6449                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
6450                                                 break
6451                                         fi
6452                                 done
6453                         done
6454                 fi
6455         fi
6456
6457         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
6458
6459         CF_RPATH_HACK_2(LDFLAGS)
6460         CF_RPATH_HACK_2(LIBS)
6461
6462         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
6463 else
6464         AC_MSG_RESULT(no)
6465 fi
6466 AC_SUBST(EXTRA_LDFLAGS)
6467 ])dnl
6468 dnl ---------------------------------------------------------------------------
6469 dnl CF_RPATH_HACK_2 version: 7 updated: 2015/04/12 15:39:00
6470 dnl ---------------
6471 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
6472 dnl EXTRA_LDFLAGS for each -L option found.
6473 dnl
6474 dnl $cf_rpath_list contains a list of directories to ignore.
6475 dnl
6476 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
6477 dnl      but LIBS often has misplaced -L options.
6478 AC_DEFUN([CF_RPATH_HACK_2],
6479 [
6480 CF_VERBOSE(...checking $1 [$]$1)
6481
6482 cf_rpath_dst=
6483 for cf_rpath_src in [$]$1
6484 do
6485         case $cf_rpath_src in
6486         (-L*)
6487
6488                 # check if this refers to a directory which we will ignore
6489                 cf_rpath_skip=no
6490                 if test -n "$cf_rpath_list"
6491                 then
6492                         for cf_rpath_item in $cf_rpath_list
6493                         do
6494                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
6495                                 then
6496                                         cf_rpath_skip=yes
6497                                         break
6498                                 fi
6499                         done
6500                 fi
6501
6502                 if test "$cf_rpath_skip" = no
6503                 then
6504                         # transform the option
6505                         if test "$LD_RPATH_OPT" = "-R " ; then
6506                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
6507                         else
6508                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
6509                         fi
6510
6511                         # if we have not already added this, add it now
6512                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
6513                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
6514                         then
6515                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
6516                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
6517                         fi
6518                 fi
6519                 ;;
6520         esac
6521         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
6522 done
6523 $1=$cf_rpath_dst
6524
6525 CF_VERBOSE(...checked $1 [$]$1)
6526 AC_SUBST(EXTRA_LDFLAGS)
6527 ])dnl
6528 dnl ---------------------------------------------------------------------------
6529 dnl CF_SAVE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:46:44
6530 dnl ------------------
6531 dnl Use this macro to save CFLAGS/CPPFLAGS/LIBS before checks against X headers
6532 dnl and libraries which do not update those variables.
6533 dnl
6534 dnl $1 = name of current macro
6535 define([CF_SAVE_XTRA_FLAGS],
6536 [
6537 cf_save_LIBS_$1="$LIBS"
6538 cf_save_CFLAGS_$1="$CFLAGS"
6539 cf_save_CPPFLAGS_$1="$CPPFLAGS"
6540 LIBS="$LIBS ${X_PRE_LIBS} ${X_LIBS} ${X_EXTRA_LIBS}"
6541 for cf_X_CFLAGS in $X_CFLAGS
6542 do
6543         case "x$cf_X_CFLAGS" in
6544         x-[[IUD]]*)
6545                 CPPFLAGS="$CPPFLAGS $cf_X_CFLAGS"
6546                 ;;
6547         *)
6548                 CFLAGS="$CFLAGS $cf_X_CFLAGS"
6549                 ;;
6550         esac
6551 done
6552 ])dnl
6553 dnl ---------------------------------------------------------------------------
6554 dnl CF_SHARED_OPTS version: 94 updated: 2020/02/29 16:09:19
6555 dnl --------------
6556 dnl --------------
6557 dnl Attempt to determine the appropriate CC/LD options for creating a shared
6558 dnl library.
6559 dnl
6560 dnl Notes:
6561 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
6562 dnl the build-tree, i.e., by making use of the libraries that are compiled in
6563 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
6564 dnl shared library since that can lead to unexpected results at runtime.
6565 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
6566 dnl libraries are compiled in ../../lib
6567 dnl
6568 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
6569 dnl to install symbolic links to the rel/abi versions of shared libraries.
6570 dnl
6571 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
6572 dnl version when making symbolic links.
6573 dnl
6574 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
6575 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
6576 dnl (ex: libncurses.so.<ver>).
6577 dnl
6578 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
6579 AC_DEFUN([CF_SHARED_OPTS],
6580 [
6581         AC_REQUIRE([CF_LD_RPATH_OPT])
6582
6583         RM_SHARED_OPTS=
6584         LOCAL_LDFLAGS=
6585         LOCAL_LDFLAGS2=
6586         LD_SHARED_OPTS=
6587         INSTALL_LIB="-m 644"
6588         : ${rel_builddir:=.}
6589
6590         shlibdir=$libdir
6591         AC_SUBST(shlibdir)
6592
6593         MAKE_DLLS="#"
6594         AC_SUBST(MAKE_DLLS)
6595
6596         cf_cv_do_symlinks=no
6597         cf_ld_rpath_opt=
6598         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
6599
6600         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
6601         AC_ARG_WITH(shlib-version,
6602         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
6603         [test -z "$withval" && withval=auto
6604         case $withval in
6605         (yes)
6606                 cf_cv_shlib_version=auto
6607                 ;;
6608         (rel|abi|auto)
6609                 cf_cv_shlib_version=$withval
6610                 ;;
6611         (*)
6612                 AC_MSG_RESULT($withval)
6613                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
6614                 ;;
6615         esac
6616         ],[cf_cv_shlib_version=auto])
6617         AC_MSG_RESULT($cf_cv_shlib_version)
6618
6619         cf_cv_rm_so_locs=no
6620         cf_try_cflags=
6621
6622         # Some less-capable ports of gcc support only -fpic
6623         CC_SHARED_OPTS=
6624
6625         cf_try_fPIC=no
6626         if test "$GCC" = yes
6627         then
6628                 cf_try_fPIC=yes
6629         else
6630                 case $cf_cv_system_name in
6631                 (*linux*)       # e.g., PGI compiler
6632                         cf_try_fPIC=yes
6633                         ;;
6634                 esac
6635         fi
6636
6637         if test "$cf_try_fPIC" = yes
6638         then
6639                 AC_MSG_CHECKING(which $CC option to use)
6640                 cf_save_CFLAGS="$CFLAGS"
6641                 for CC_SHARED_OPTS in -fPIC -fpic ''
6642                 do
6643                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
6644                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
6645                 done
6646                 AC_MSG_RESULT($CC_SHARED_OPTS)
6647                 CFLAGS="$cf_save_CFLAGS"
6648         fi
6649
6650         cf_cv_shlib_version_infix=no
6651
6652         case $cf_cv_system_name in
6653         (aix4.[3-9]*|aix[[5-7]]*)
6654                 if test "$GCC" = yes; then
6655                         CC_SHARED_OPTS='-Wl,-brtl'
6656                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
6657                 else
6658                         CC_SHARED_OPTS='-brtl'
6659                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
6660                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
6661                 fi
6662                 ;;
6663         (beos*)
6664                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
6665                 ;;
6666         (cygwin*)
6667                 CC_SHARED_OPTS=
6668                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
6669                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
6670                 cf_cv_shlib_version=cygdll
6671                 cf_cv_shlib_version_infix=cygdll
6672                 shlibdir=$bindir
6673                 MAKE_DLLS=
6674                 cat >mk_shared_lib.sh <<-CF_EOF
6675                 #!$SHELL
6676                 SHARED_LIB=\[$]1
6677                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
6678                 shift
6679                 cat <<-EOF
6680                 Linking shared library
6681                 ** SHARED_LIB \[$]SHARED_LIB
6682                 ** IMPORT_LIB \[$]IMPORT_LIB
6683 EOF
6684                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
6685 CF_EOF
6686                 chmod +x mk_shared_lib.sh
6687                 ;;
6688         (msys*)
6689                 CC_SHARED_OPTS=
6690                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
6691                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
6692                 cf_cv_shlib_version=msysdll
6693                 cf_cv_shlib_version_infix=msysdll
6694                 shlibdir=$bindir
6695                 MAKE_DLLS=
6696                 cat >mk_shared_lib.sh <<-CF_EOF
6697                 #!$SHELL
6698                 SHARED_LIB=\[$]1
6699                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
6700                 shift
6701                 cat <<-EOF
6702                 Linking shared library
6703                 ** SHARED_LIB \[$]SHARED_LIB
6704                 ** IMPORT_LIB \[$]IMPORT_LIB
6705 EOF
6706                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
6707 CF_EOF
6708                 chmod +x mk_shared_lib.sh
6709                 ;;
6710         (darwin*)
6711                 cf_try_cflags="no-cpp-precomp"
6712                 CC_SHARED_OPTS="-dynamic"
6713                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
6714                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
6715                 cf_cv_shlib_version_infix=yes
6716                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
6717                         cf_save_LDFLAGS=$LDFLAGS
6718                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
6719                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
6720                                 LDFLAGS=$cf_save_LDFLAGS])
6721                 if test $cf_cv_ldflags_search_paths_first = yes; then
6722                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
6723                 fi
6724                 ;;
6725         (hpux[[7-8]]*)
6726                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
6727                 if test "$GCC" != yes; then
6728                         CC_SHARED_OPTS='+Z'
6729                 fi
6730                 MK_SHARED_LIB='${LD} ${LDFLAGS} -b -o $[@]'
6731                 INSTALL_LIB="-m 555"
6732                 ;;
6733         (hpux*)
6734                 # (tested with gcc 2.7.2 -- I don't have c89)
6735                 if test "$GCC" = yes; then
6736                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
6737                 else
6738                         CC_SHARED_OPTS='+Z'
6739                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
6740                 fi
6741                 MK_SHARED_LIB='${LD} ${LDFLAGS} +b ${libdir} -b -o $[@]'
6742                 # HP-UX shared libraries must be executable, and should be
6743                 # readonly to exploit a quirk in the memory manager.
6744                 INSTALL_LIB="-m 555"
6745                 ;;
6746         (interix*)
6747                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6748                 if test "$cf_cv_shlib_version" = rel; then
6749                         cf_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
6750                 else
6751                         cf_shared_soname='`basename $[@]`'
6752                 fi
6753                 CC_SHARED_OPTS=
6754                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $[@]'
6755                 ;;
6756         (irix*)
6757                 if test "$cf_cv_enable_rpath" = yes ; then
6758                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6759                 fi
6760                 # tested with IRIX 5.2 and 'cc'.
6761                 if test "$GCC" != yes; then
6762                         CC_SHARED_OPTS='-KPIC'
6763                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
6764                 else
6765                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,`basename $[@]` -o $[@]'
6766                 fi
6767                 cf_cv_rm_so_locs=yes
6768                 ;;
6769         (linux*|gnu*|k*bsd*-gnu)
6770                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
6771                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
6772                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6773                 fi
6774                 if test "$cf_cv_enable_rpath" = yes ; then
6775                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6776                 fi
6777                 CF_SHARED_SONAME
6778                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
6779                 ;;
6780         (mingw*msvc*)
6781                 cf_cv_shlib_version=mingw
6782                 cf_cv_shlib_version_infix=mingw
6783                 shlibdir=$bindir
6784                 MAKE_DLLS=
6785                 if test "$DFT_LWR_MODEL" = "shared" ; then
6786                         LOCAL_LDFLAGS="-link -dll"
6787                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6788                         EXTRA_LDFLAGS="-link -dll $EXTRA_LDFLAGS"
6789                 fi
6790                 CC_SHARED_OPTS=
6791                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh $@ ${LD} ${CFLAGS}'
6792                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
6793                 cat >mk_shared_lib.sh <<-CF_EOF
6794                 #!$SHELL
6795                 SHARED_LIB=\$1
6796                 IMPORT_LIB=\`echo "\$1" | sed -e 's/[0-9]*\.dll$\.dll.a/'\`
6797                 shift
6798                 my_ld=\$1
6799                 shift
6800                 cat <<-EOF
6801                 Linking shared library
6802                 ** SHARED LIB \$SHARED_LIB
6803                 ** IMPORT_LIB \$IMPORT_LIB
6804 EOF
6805                 args=\$(echo \$* | sed -E "s#-l(\w*)#lib\1.a#g" | sed -E "s#-L(\w*)#-LIBPATH:\1#g")
6806                 exec \$my_ld -DLL -IMPLIB:"\${IMPORT_LIB}" -OUT:"\${SHARED_LIB}" ${LDFLAGS} \$args
6807                 mv "\${IMPORT_LIB}" "\${IMPORT_LIB}"
6808 CF_EOF
6809                 chmod +x mk_shared_lib.sh
6810                 ;;
6811         (mingw*)
6812                 cf_cv_shlib_version=mingw
6813                 cf_cv_shlib_version_infix=mingw
6814                 shlibdir=$bindir
6815                 MAKE_DLLS=
6816                 if test "$DFT_LWR_MODEL" = "shared" ; then
6817                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
6818                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6819                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
6820                 fi
6821                 CC_SHARED_OPTS=
6822                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
6823                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
6824                 cat >mk_shared_lib.sh <<-CF_EOF
6825                 #!$SHELL
6826                 SHARED_LIB=\[$]1
6827                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
6828                 shift
6829                 cat <<-EOF
6830                 Linking shared library
6831                 ** SHARED_LIB \[$]SHARED_LIB
6832                 ** IMPORT_LIB \[$]IMPORT_LIB
6833 EOF
6834                 exec \[$]* ${LDFLAGS} -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
6835 CF_EOF
6836                 chmod +x mk_shared_lib.sh
6837                 ;;
6838         (openbsd[[2-9]].*|mirbsd*)
6839                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
6840                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
6841                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6842                 fi
6843                 if test "$cf_cv_enable_rpath" = yes ; then
6844                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6845                 fi
6846                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
6847                 CF_SHARED_SONAME
6848                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
6849                 ;;
6850         (nto-qnx*|openbsd*|freebsd[[12]].*)
6851                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
6852                 MK_SHARED_LIB='${LD} ${LDFLAGS} -Bshareable -o $[@]'
6853                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6854                 ;;
6855         (dragonfly*|freebsd*)
6856                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
6857                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
6858                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
6859                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
6860                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6861                 fi
6862                 CF_SHARED_SONAME
6863                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
6864                 ;;
6865         (netbsd*)
6866                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
6867                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
6868                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
6869                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6870                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6871                         if test "$cf_cv_shlib_version" = auto; then
6872                         if test -f /usr/libexec/ld.elf_so; then
6873                                 cf_cv_shlib_version=abi
6874                         else
6875                                 cf_cv_shlib_version=rel
6876                         fi
6877                         fi
6878                         CF_SHARED_SONAME
6879                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
6880                 else
6881                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -Wl,-shared -Wl,-Bshareable -o $[@]'
6882                 fi
6883                 ;;
6884         (osf*|mls+*)
6885                 # tested with OSF/1 V3.2 and 'cc'
6886                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
6887                 # link with shared libs).
6888                 MK_SHARED_LIB='${LD} ${LDFLAGS} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
6889                 case $host_os in
6890                 (osf4*)
6891                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
6892                         ;;
6893                 esac
6894                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
6895                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
6896                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
6897                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6898                 fi
6899                 cf_cv_rm_so_locs=yes
6900                 ;;
6901         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
6902                 # tested with osr5.0.5
6903                 if test "$GCC" != yes; then
6904                         CC_SHARED_OPTS='-belf -KPIC'
6905                 fi
6906                 MK_SHARED_LIB='${LD} ${LDFLAGS} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
6907                 if test "$cf_cv_enable_rpath" = yes ; then
6908                         # only way is to set LD_RUN_PATH but no switch for it
6909                         RUN_PATH=$libdir
6910                 fi
6911                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6912                 LINK_PROGS='LD_RUN_PATH=${libdir}'
6913                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
6914                 ;;
6915         (sunos4*)
6916                 # tested with SunOS 4.1.1 and gcc 2.7.0
6917                 if test "$GCC" != yes; then
6918                         CC_SHARED_OPTS='-KPIC'
6919                 fi
6920                 MK_SHARED_LIB='${LD} ${LDFLAGS} -assert pure-text -o $[@]'
6921                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6922                 ;;
6923         (solaris2*)
6924                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
6925                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
6926                 if test "$DFT_LWR_MODEL" = "shared" ; then
6927                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
6928                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6929                 fi
6930                 if test "$cf_cv_enable_rpath" = yes ; then
6931                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
6932                 fi
6933                 CF_SHARED_SONAME
6934                 if test "$GCC" != yes; then
6935                         cf_save_CFLAGS="$CFLAGS"
6936                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
6937                         do
6938                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
6939                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
6940                         done
6941                         CFLAGS="$cf_save_CFLAGS"
6942                         CC_SHARED_OPTS=$cf_shared_opts
6943                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
6944                 else
6945                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
6946                 fi
6947                 ;;
6948         (sysv5uw7*|unix_sv*)
6949                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
6950                 if test "$GCC" != yes; then
6951                         CC_SHARED_OPTS='-KPIC'
6952                 fi
6953                 MK_SHARED_LIB='${LD} ${LDFLAGS} -d y -G -o [$]@'
6954                 ;;
6955         (*)
6956                 CC_SHARED_OPTS='unknown'
6957                 MK_SHARED_LIB='echo unknown'
6958                 ;;
6959         esac
6960
6961         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
6962         case "$cf_cv_shlib_version" in
6963         (rel|abi)
6964                 case "$MK_SHARED_LIB" in
6965                 (*'-o $[@]')
6966                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
6967                         ;;
6968                 (*)
6969                         AC_MSG_WARN(ignored --with-shlib-version)
6970                         ;;
6971                 esac
6972                 ;;
6973         esac
6974
6975         if test -n "$cf_try_cflags"
6976         then
6977 cat > conftest.$ac_ext <<EOF
6978 #line __oline__ "${as_me:-configure}"
6979 #include <stdio.h>
6980 int main(int argc, char *argv[[]])
6981 {
6982         printf("hello\n");
6983         return (argv[[argc-1]] == 0) ;
6984 }
6985 EOF
6986                 cf_save_CFLAGS="$CFLAGS"
6987                 for cf_opt in $cf_try_cflags
6988                 do
6989                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
6990                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
6991                         if AC_TRY_EVAL(ac_compile); then
6992                                 AC_MSG_RESULT(yes)
6993                                 cf_save_CFLAGS="$CFLAGS"
6994                         else
6995                                 AC_MSG_RESULT(no)
6996                         fi
6997                 done
6998                 CFLAGS="$cf_save_CFLAGS"
6999         fi
7000
7001
7002         # RPATH_LIST is a colon-separated list of directories
7003         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
7004         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
7005
7006         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
7007
7008         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
7009         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
7010
7011         AC_SUBST(CC_SHARED_OPTS)
7012         AC_SUBST(LD_RPATH_OPT)
7013         AC_SUBST(LD_SHARED_OPTS)
7014         AC_SUBST(MK_SHARED_LIB)
7015         AC_SUBST(RM_SHARED_OPTS)
7016
7017         AC_SUBST(LINK_PROGS)
7018         AC_SUBST(LINK_TESTS)
7019
7020         AC_SUBST(EXTRA_LDFLAGS)
7021         AC_SUBST(LOCAL_LDFLAGS)
7022         AC_SUBST(LOCAL_LDFLAGS2)
7023
7024         AC_SUBST(INSTALL_LIB)
7025         AC_SUBST(RPATH_LIST)
7026 ])dnl
7027 dnl ---------------------------------------------------------------------------
7028 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
7029 dnl ----------------
7030 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
7031 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
7032 dnl option.
7033 dnl
7034 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
7035 dnl If missing, use "rel".
7036 define([CF_SHARED_SONAME],
7037 [
7038         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
7039         if test "$cf_cv_shlib_version" = rel; then
7040                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
7041         else
7042                 cf_cv_shared_soname='`basename $[@]`'
7043         fi
7044 ])
7045 dnl ---------------------------------------------------------------------------
7046 dnl CF_SIGWINCH version: 2 updated: 2019/03/23 19:54:44
7047 dnl -----------
7048 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
7049 dnl programs need this test).
7050 dnl
7051 dnl This is really a Mac OS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
7052 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
7053 dnl winsize declaration is left alone - we may revisit this if Apple choose to
7054 dnl break that part of the interface as well.
7055 AC_DEFUN([CF_SIGWINCH],
7056 [
7057 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
7058         AC_TRY_COMPILE([
7059 #include <sys/types.h>
7060 #include <sys/signal.h>
7061 ],[int x = SIGWINCH],
7062         [cf_cv_define_sigwinch=yes],
7063         [AC_TRY_COMPILE([
7064 #undef _XOPEN_SOURCE
7065 #undef _POSIX_SOURCE
7066 #undef _POSIX_C_SOURCE
7067 #include <sys/types.h>
7068 #include <sys/signal.h>
7069 ],[int x = SIGWINCH],
7070         [cf_cv_define_sigwinch=maybe],
7071         [cf_cv_define_sigwinch=no])
7072 ])
7073 ])
7074
7075 if test "$cf_cv_define_sigwinch" = maybe ; then
7076 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
7077 cf_cv_fixup_sigwinch=unknown
7078 cf_sigwinch=32
7079 while test $cf_sigwinch != 1
7080 do
7081         AC_TRY_COMPILE([
7082 #undef _XOPEN_SOURCE
7083 #undef _POSIX_SOURCE
7084 #undef _POSIX_C_SOURCE
7085 #include <sys/types.h>
7086 #include <sys/signal.h>
7087 ],[
7088 #if SIGWINCH != $cf_sigwinch
7089 make an error
7090 #endif
7091 int x = SIGWINCH],
7092         [cf_cv_fixup_sigwinch=$cf_sigwinch
7093          break])
7094
7095 cf_sigwinch=`expr $cf_sigwinch - 1`
7096 done
7097 ])
7098
7099         if test "$cf_cv_fixup_sigwinch" != unknown ; then
7100                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
7101         fi
7102 fi
7103 ])dnl
7104 dnl ---------------------------------------------------------------------------
7105 dnl CF_SIG_ATOMIC_T version: 4 updated: 2020/01/18 12:30:44
7106 dnl ---------------
7107 dnl signal handler, but there are some gcc dependencies in that recommendation.
7108 dnl Try anyway.
7109 AC_DEFUN([CF_SIG_ATOMIC_T],
7110 [
7111 AC_MSG_CHECKING(for signal global datatype)
7112 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
7113         for cf_type in \
7114                 "volatile sig_atomic_t" \
7115                 "sig_atomic_t" \
7116                 "int"
7117         do
7118         AC_TRY_COMPILE([
7119 #include <sys/types.h>
7120 #include <signal.h>
7121 #include <stdio.h>
7122
7123 extern $cf_type x;
7124 $cf_type x;
7125 static void handler(int sig)
7126 {
7127         x = 5;
7128 }],
7129                 [signal(SIGINT, handler);
7130                  x = 1],
7131                 [cf_cv_sig_atomic_t=$cf_type],
7132                 [cf_cv_sig_atomic_t=no])
7133                 test "$cf_cv_sig_atomic_t" != no && break
7134         done
7135         ])
7136 AC_MSG_RESULT($cf_cv_sig_atomic_t)
7137 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
7138 ])dnl
7139 dnl ---------------------------------------------------------------------------
7140 dnl CF_SIZECHANGE version: 14 updated: 2018/06/20 20:23:13
7141 dnl -------------
7142 dnl Check for definitions & structures needed for window size-changing
7143 dnl
7144 dnl https://stackoverflow.com/questions/18878141/difference-between-structures-ttysize-and-winsize/50769952#50769952
7145 AC_DEFUN([CF_SIZECHANGE],
7146 [
7147 AC_REQUIRE([CF_STRUCT_TERMIOS])
7148 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
7149         cf_cv_sizechange=unknown
7150         cf_save_CPPFLAGS="$CPPFLAGS"
7151
7152 for cf_opts in "" "NEED_PTEM_H"
7153 do
7154
7155         CPPFLAGS="$cf_save_CPPFLAGS"
7156         if test -n "$cf_opts"
7157         then
7158                 CF_APPEND_TEXT(CPPFLAGS,-D$cf_opts)
7159         fi
7160         AC_TRY_COMPILE([#include <sys/types.h>
7161 #ifdef HAVE_TERMIOS_H
7162 #include <termios.h>
7163 #else
7164 #ifdef HAVE_TERMIO_H
7165 #include <termio.h>
7166 #endif
7167 #endif
7168
7169 #ifdef NEED_PTEM_H
7170 /* This is a workaround for SCO:  they neglected to define struct winsize in
7171  * termios.h -- it's only in termio.h and ptem.h
7172  */
7173 #include <sys/stream.h>
7174 #include <sys/ptem.h>
7175 #endif
7176
7177 #ifdef HAVE_SYS_IOCTL_H
7178 #include <sys/ioctl.h>
7179 #endif
7180 ],[
7181 #ifdef TIOCGSIZE
7182         struct ttysize win;     /* SunOS 3.0... */
7183         int y = win.ts_lines;
7184         int x = win.ts_cols;
7185 #else
7186 #ifdef TIOCGWINSZ
7187         struct winsize win;     /* everything else */
7188         int y = win.ws_row;
7189         int x = win.ws_col;
7190 #else
7191         no TIOCGSIZE or TIOCGWINSZ
7192 #endif /* TIOCGWINSZ */
7193 #endif /* TIOCGSIZE */
7194         ],
7195         [cf_cv_sizechange=yes],
7196         [cf_cv_sizechange=no])
7197
7198         CPPFLAGS="$cf_save_CPPFLAGS"
7199         if test "$cf_cv_sizechange" = yes ; then
7200                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
7201                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
7202                 break
7203         fi
7204 done
7205 ])
7206 if test "$cf_cv_sizechange" != no ; then
7207         AC_DEFINE(HAVE_SIZECHANGE,1,[Define to 1 if sizechange declarations are provided])
7208         case $cf_cv_sizechange in
7209         (NEED*)
7210                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
7211                 ;;
7212         esac
7213 fi
7214 ])dnl
7215 dnl ---------------------------------------------------------------------------
7216 dnl CF_SRC_MODULES version: 32 updated: 2020/03/07 20:05:14
7217 dnl --------------
7218 dnl For each parameter, test if the source-directory exists, and if it contains
7219 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
7220 dnl use in CF_LIB_RULES.
7221 dnl
7222 dnl This uses the configured value to make the lists SRC_SUBDIRS and
7223 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
7224 AC_DEFUN([CF_SRC_MODULES],
7225 [
7226 AC_REQUIRE([CF_CHECK_GNAT_VERSION])
7227 AC_MSG_CHECKING(for src modules)
7228
7229 # dependencies and linker-arguments for test-programs
7230 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
7231 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
7232 if test "$DFT_LWR_MODEL" = "libtool"; then
7233         TEST_ARGS="${TEST_DEPS}"
7234         TEST_ARG2="${TEST_DEP2}"
7235 else
7236         TEST_ARGS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
7237         TEST_ARG2="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARG2"
7238 fi
7239
7240 PC_MODULES_TO_MAKE="ncurses${USE_ARG_SUFFIX}"
7241 cf_cv_src_modules=
7242 for cf_dir in $1
7243 do
7244         if test -f $srcdir/$cf_dir/modules; then
7245
7246                 # We may/may not have tack in the distribution, though the
7247                 # makefile is.
7248                 if test $cf_dir = tack ; then
7249                         if test "x$cf_with_tack" != "xyes"; then
7250                                 continue
7251                         fi
7252                 fi
7253
7254                 if test -z "$cf_cv_src_modules"; then
7255                         cf_cv_src_modules=$cf_dir
7256                 else
7257                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
7258                 fi
7259
7260                 # Make the ncurses_cfg.h file record the library interface files as
7261                 # well.  These are header files that are the same name as their
7262                 # directory.  Ncurses is the only library that does not follow
7263                 # that pattern.
7264                 if test $cf_dir = tack ; then
7265                         continue
7266                 elif test -f $srcdir/${cf_dir}/${cf_dir}.h; then
7267                         CF_UPPER(cf_have_include,$cf_dir)
7268                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
7269                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
7270                         CF_MAP_LIB_BASENAME(TEST_ROOT,$cf_dir)
7271                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TEST_ROOT}${DFT_DEP_SUFFIX} $TEST_DEPS"
7272                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TEST_ROOT}${DFT_DEP_SUFFIX} $TEST_DEP2"
7273                         if test "$DFT_LWR_MODEL" = "libtool"; then
7274                                 TEST_ARGS="${TEST_DEPS}"
7275                                 TEST_ARG2="${TEST_DEP2}"
7276                         else
7277                                 TEST_ARGS="-l${TEST_ROOT}${USE_ARG_SUFFIX} $TEST_ARGS"
7278                                 TEST_ARG2="-l${TEST_ROOT}${USE_ARG_SUFFIX} $TEST_ARG2"
7279                         fi
7280                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${USE_ARG_SUFFIX}"
7281                 fi
7282         fi
7283 done
7284 AC_MSG_RESULT($cf_cv_src_modules)
7285
7286 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
7287 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
7288
7289 AC_SUBST(TEST_ARGS)
7290 AC_SUBST(TEST_DEPS)
7291
7292 AC_SUBST(TEST_ARG2)
7293 AC_SUBST(TEST_DEP2)
7294
7295 SRC_SUBDIRS=
7296 if test "x$cf_with_manpages" != xno ; then
7297         SRC_SUBDIRS="$SRC_SUBDIRS man"
7298 fi
7299 SRC_SUBDIRS="$SRC_SUBDIRS include"
7300 for cf_dir in $cf_cv_src_modules
7301 do
7302         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
7303 done
7304 if test "x$cf_with_tests" != "xno" ; then
7305         SRC_SUBDIRS="$SRC_SUBDIRS test"
7306 fi
7307 # always make this, to install the ncurses-config script
7308 SRC_SUBDIRS="$SRC_SUBDIRS misc"
7309 if test "$cf_with_cxx_binding" != no; then
7310         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${USE_ARG_SUFFIX}"
7311         SRC_SUBDIRS="$SRC_SUBDIRS c++"
7312 fi
7313
7314 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
7315 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
7316
7317 AC_SUBST(PC_MODULES_TO_MAKE)
7318
7319 ADA_SUBDIRS=
7320 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f $srcdir/Ada95/Makefile.in; then
7321         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
7322         ADA_SUBDIRS="gen src"
7323         if test "x$cf_with_tests" != "xno" ; then
7324                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
7325         fi
7326 fi
7327
7328 SUB_MAKEFILES=
7329 for cf_dir in $SRC_SUBDIRS
7330 do
7331         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
7332 done
7333
7334 if test -n "$ADA_SUBDIRS"; then
7335         for cf_dir in $ADA_SUBDIRS
7336         do
7337                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
7338         done
7339         AC_SUBST(ADA_SUBDIRS)
7340 fi
7341 ])dnl
7342 dnl ---------------------------------------------------------------------------
7343 dnl CF_STDCPP_LIBRARY version: 11 updated: 2015/10/17 19:03:33
7344 dnl -----------------
7345 dnl Check for -lstdc++, which is GNU's standard C++ library.
7346 dnl If $CXXLIBS is set, add that to the libraries used for test-linking.
7347 dnl If -lstdc++ was not already added to $LIBS or $CXXLIBS, and is needed,
7348 dnl add it to $CXXLIBS.
7349 AC_DEFUN([CF_STDCPP_LIBRARY],
7350 [
7351 if test -n "$GXX" ; then
7352
7353         cf_save="$LIBS"
7354         LIBS="$LIBS $CXXLIBS"
7355         AC_MSG_CHECKING(if we already have C++ library)
7356         AC_TRY_LINK([
7357                         #include <iostream>],[
7358                         std::cout << "Hello World!" << std::endl;],
7359                 [cf_have_libstdcpp=yes],
7360                 [cf_have_libstdcpp=no])
7361         AC_MSG_RESULT($cf_have_libstdcpp)
7362         LIBS="$cf_save"
7363
7364         if test $cf_have_libstdcpp != yes
7365         then
7366                 case $cf_cv_system_name in
7367                 (os2*)
7368                         if test -z "`g++ -dM -E - < /dev/null | grep __KLIBC__`"; then
7369                                 cf_stdcpp_libname=stdcpp
7370                         else
7371                                 cf_stdcpp_libname=stdc++
7372                         fi
7373                         ;;
7374                 (*)
7375                         cf_stdcpp_libname=stdc++
7376                         ;;
7377                 esac
7378
7379                 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
7380                         cf_save="$LIBS"
7381                         LIBS="$LIBS $CXXLIBS"
7382                         CF_ADD_LIB($cf_stdcpp_libname)
7383                 AC_TRY_LINK([
7384                                 #include <iostream>],[
7385                                 std::cout << "Hello World!" << std::endl;],
7386                         [cf_cv_libstdcpp=yes],
7387                         [cf_cv_libstdcpp=no])
7388                         LIBS="$cf_save"
7389                 ])
7390                 test "$cf_cv_libstdcpp" = yes && { CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS) }
7391         fi
7392 fi
7393 ])dnl
7394 dnl ---------------------------------------------------------------------------
7395 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
7396 dnl --------------
7397 dnl     Remove "-g" option from the compiler options
7398 AC_DEFUN([CF_STRIP_G_OPT],
7399 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
7400 dnl ---------------------------------------------------------------------------
7401 dnl CF_STRUCT_SIGACTION version: 5 updated: 2012/10/06 17:56:13
7402 dnl -------------------
7403 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
7404 dnl do this if we've found the sigaction function.
7405 AC_DEFUN([CF_STRUCT_SIGACTION],[
7406 AC_REQUIRE([CF_XOPEN_SOURCE])
7407
7408 if test "$ac_cv_func_sigaction" = yes; then
7409 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
7410 AC_TRY_COMPILE([
7411 #include <sys/types.h>
7412 #include <signal.h>],
7413         [struct sigaction act],
7414         [sigact_bad=no],
7415         [
7416 AC_TRY_COMPILE([
7417 #define _POSIX_SOURCE
7418 #include <sys/types.h>
7419 #include <signal.h>],
7420         [struct sigaction act],
7421         [sigact_bad=yes
7422          AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE])],
7423          [sigact_bad=unknown])])
7424 AC_MSG_RESULT($sigact_bad)
7425 fi
7426 ])dnl
7427 dnl ---------------------------------------------------------------------------
7428 dnl CF_STRUCT_TERMIOS version: 9 updated: 2018/06/08 21:57:23
7429 dnl -----------------
7430 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
7431 AC_DEFUN([CF_STRUCT_TERMIOS],[
7432 AC_REQUIRE([CF_XOPEN_SOURCE])
7433
7434 AC_CHECK_HEADERS( \
7435 termio.h \
7436 termios.h \
7437 unistd.h \
7438 sys/ioctl.h \
7439 sys/termio.h \
7440 )
7441
7442 if test "$ac_cv_header_termios_h" = yes ; then
7443         case "$CFLAGS $CPPFLAGS" in
7444         (*-D_POSIX_SOURCE*)
7445                 termios_bad=dunno ;;
7446         (*)     termios_bad=maybe ;;
7447         esac
7448         if test "$termios_bad" = maybe ; then
7449         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
7450         AC_TRY_COMPILE([#include <termios.h>],
7451                 [struct termios foo; int x = foo.c_iflag],
7452                 termios_bad=no, [
7453                 AC_TRY_COMPILE([
7454 #define _POSIX_SOURCE
7455 #include <termios.h>],
7456                         [struct termios foo; int x = foo.c_iflag],
7457                         termios_bad=unknown,
7458                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE]))
7459                         ])
7460         AC_MSG_RESULT($termios_bad)
7461         fi
7462 fi
7463 ])dnl
7464 dnl ---------------------------------------------------------------------------
7465 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
7466 dnl --------------
7467 dnl Construct a search-list for a nonstandard header/lib-file
7468 dnl     $1 = the variable to return as result
7469 dnl     $2 = the package name
7470 dnl     $3 = the subdirectory, e.g., bin, include or lib
7471 AC_DEFUN([CF_SUBDIR_PATH],
7472 [
7473 $1=
7474
7475 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
7476
7477 for cf_subdir_prefix in \
7478         /usr \
7479         /usr/local \
7480         /usr/pkg \
7481         /opt \
7482         /opt/local \
7483         [$]HOME
7484 do
7485         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
7486 done
7487 ])dnl
7488 dnl ---------------------------------------------------------------------------
7489 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
7490 dnl -----------
7491 dnl     Shorthand macro for substituting things that the user may override
7492 dnl     with an environment variable.
7493 dnl
7494 dnl     $1 = condition to pass to "test"
7495 dnl     $2 = environment variable
7496 dnl     $3 = value if the test succeeds
7497 dnl     $4 = value if the test fails
7498 AC_DEFUN([CF_SUBST_IF],
7499 [
7500 if test $1 ; then
7501         $2=$3
7502 ifelse($4,,,[else
7503         $2=$4])
7504 fi
7505 AC_SUBST($2)
7506 ])dnl
7507 dnl ---------------------------------------------------------------------------
7508 dnl CF_SUBST_NCURSES_VERSION version: 8 updated: 2006/09/16 11:40:59
7509 dnl ------------------------
7510 dnl Get the version-number for use in shared-library naming, etc.
7511 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
7512 [
7513 AC_REQUIRE([CF_PROG_EGREP])
7514 NCURSES_MAJOR="`$ac_cv_prog_egrep '^NCURSES_MAJOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
7515 NCURSES_MINOR="`$ac_cv_prog_egrep '^NCURSES_MINOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
7516 NCURSES_PATCH="`$ac_cv_prog_egrep '^NCURSES_PATCH[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
7517 cf_cv_abi_version=${NCURSES_MAJOR}
7518 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
7519 dnl Show the computed version, for logging
7520 cf_cv_timestamp=`date`
7521 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
7522 dnl We need these values in the generated headers
7523 AC_SUBST(NCURSES_MAJOR)
7524 AC_SUBST(NCURSES_MINOR)
7525 AC_SUBST(NCURSES_PATCH)
7526 dnl We need these values in the generated makefiles
7527 AC_SUBST(cf_cv_rel_version)
7528 AC_SUBST(cf_cv_abi_version)
7529 AC_SUBST(cf_cv_builtin_bool)
7530 AC_SUBST(cf_cv_header_stdbool_h)
7531 AC_SUBST(cf_cv_type_of_bool)dnl
7532 ])dnl
7533 dnl ---------------------------------------------------------------------------
7534 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
7535 dnl ------------------
7536 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
7537 dnl older SCO configurations.
7538 AC_DEFUN([CF_SYS_TIME_SELECT],
7539 [
7540 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
7541 AC_CACHE_VAL(cf_cv_sys_time_select,[
7542 AC_TRY_COMPILE([
7543 #include <sys/types.h>
7544 #ifdef HAVE_SYS_TIME_H
7545 #include <sys/time.h>
7546 #endif
7547 #ifdef HAVE_SYS_SELECT_H
7548 #include <sys/select.h>
7549 #endif
7550 ],[],[cf_cv_sys_time_select=yes],
7551          [cf_cv_sys_time_select=no])
7552          ])
7553 AC_MSG_RESULT($cf_cv_sys_time_select)
7554 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
7555 ])dnl
7556 dnl ---------------------------------------------------------------------------
7557 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
7558 dnl ---------------
7559 dnl Define a top_builddir symbol, for applications that need an absolute path.
7560 AC_DEFUN([CF_TOP_BUILDDIR],
7561 [
7562 top_builddir=ifelse($1,,`pwd`,$1)
7563 AC_SUBST(top_builddir)
7564 ])dnl
7565 dnl ---------------------------------------------------------------------------
7566 dnl CF_TRY_PKG_CONFIG version: 5 updated: 2013/07/06 21:27:06
7567 dnl -----------------
7568 dnl This is a simple wrapper to use for pkg-config, for libraries which may be
7569 dnl available in that form.
7570 dnl
7571 dnl $1 = package name
7572 dnl $2 = extra logic to use, if any, after updating CFLAGS and LIBS
7573 dnl $3 = logic to use if pkg-config does not have the package
7574 AC_DEFUN([CF_TRY_PKG_CONFIG],[
7575 AC_REQUIRE([CF_PKG_CONFIG])
7576
7577 if test "$PKG_CONFIG" != none && "$PKG_CONFIG" --exists $1; then
7578         CF_VERBOSE(found package $1)
7579         cf_pkgconfig_incs="`$PKG_CONFIG --cflags $1 2>/dev/null`"
7580         cf_pkgconfig_libs="`$PKG_CONFIG --libs   $1 2>/dev/null`"
7581         CF_VERBOSE(package $1 CFLAGS: $cf_pkgconfig_incs)
7582         CF_VERBOSE(package $1 LIBS: $cf_pkgconfig_libs)
7583         CF_ADD_CFLAGS($cf_pkgconfig_incs)
7584         CF_ADD_LIBS($cf_pkgconfig_libs)
7585         ifelse([$2],,:,[$2])
7586 else
7587         cf_pkgconfig_incs=
7588         cf_pkgconfig_libs=
7589         ifelse([$3],,:,[$3])
7590 fi
7591 ])
7592 dnl ---------------------------------------------------------------------------
7593 dnl CF_TRY_XOPEN_SOURCE version: 2 updated: 2018/06/20 20:23:13
7594 dnl -------------------
7595 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
7596 dnl can define it successfully.
7597 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
7598 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
7599         AC_TRY_COMPILE([
7600 #include <stdlib.h>
7601 #include <string.h>
7602 #include <sys/types.h>
7603 ],[
7604 #ifndef _XOPEN_SOURCE
7605 make an error
7606 #endif],
7607         [cf_cv_xopen_source=no],
7608         [cf_save="$CPPFLAGS"
7609          CF_APPEND_TEXT(CPPFLAGS,-D_XOPEN_SOURCE=$cf_XOPEN_SOURCE)
7610          AC_TRY_COMPILE([
7611 #include <stdlib.h>
7612 #include <string.h>
7613 #include <sys/types.h>
7614 ],[
7615 #ifdef _XOPEN_SOURCE
7616 make an error
7617 #endif],
7618         [cf_cv_xopen_source=no],
7619         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
7620         CPPFLAGS="$cf_save"
7621         ])
7622 ])
7623
7624 if test "$cf_cv_xopen_source" != no ; then
7625         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
7626         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
7627         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
7628         CF_ADD_CFLAGS($cf_temp_xopen_source)
7629 fi
7630 ])
7631 dnl ---------------------------------------------------------------------------
7632 dnl CF_TYPEOF_CHTYPE version: 10 updated: 2017/01/21 11:06:25
7633 dnl ----------------
7634 dnl Determine the type we should use for chtype (and attr_t, which is treated
7635 dnl as the same thing).  We want around 32 bits, so on most machines want a
7636 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
7637 dnl wide characters, we have to have a type compatible with that, as well.
7638 AC_DEFUN([CF_TYPEOF_CHTYPE],
7639 [
7640 AC_MSG_CHECKING([for type of chtype])
7641 AC_CACHE_VAL(cf_cv_typeof_chtype,[
7642                 AC_TRY_RUN([
7643 #define WANT_BITS 31
7644 #include <stdio.h>
7645 int main(void)
7646 {
7647         FILE *fp = fopen("cf_test.out", "w");
7648         if (fp != 0) {
7649                 char *result = "long";
7650                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
7651                         int n;
7652                         unsigned int x, y;
7653                         for (n = 0; n < WANT_BITS; n++) {
7654                                 x = (1 << n);
7655                                 y = (x >> n);
7656                                 if (y != 1 || x == 0) {
7657                                         x = 0;
7658                                         break;
7659                                 }
7660                         }
7661                         /*
7662                          * If x is nonzero, an int is big enough for the bits
7663                          * that we want.
7664                          */
7665                         result = (x != 0) ? "int" : "long";
7666                 }
7667                 fputs(result, fp);
7668                 fclose(fp);
7669         }
7670         ${cf_cv_main_return:-return}(0);
7671 }
7672                 ],
7673                 [cf_cv_typeof_chtype=`cat cf_test.out`],
7674                 [cf_cv_typeof_chtype=long],
7675                 [cf_cv_typeof_chtype=long])
7676                 rm -f cf_test.out
7677         ])
7678 AC_MSG_RESULT($cf_cv_typeof_chtype)
7679
7680 AC_SUBST(cf_cv_typeof_chtype)
7681 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype,[Define to actual type if needed for chtype])
7682 ])dnl
7683 dnl ---------------------------------------------------------------------------
7684 dnl CF_TYPE_SIGACTION version: 4 updated: 2012/10/06 17:56:13
7685 dnl -----------------
7686 dnl
7687 AC_DEFUN([CF_TYPE_SIGACTION],
7688 [
7689 AC_MSG_CHECKING([for type sigaction_t])
7690 AC_CACHE_VAL(cf_cv_type_sigaction,[
7691         AC_TRY_COMPILE([
7692 #include <signal.h>],
7693                 [sigaction_t x],
7694                 [cf_cv_type_sigaction=yes],
7695                 [cf_cv_type_sigaction=no])])
7696 AC_MSG_RESULT($cf_cv_type_sigaction)
7697 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION,1,[Define to 1 if we have the sigaction_t type])
7698 ])dnl
7699 dnl ---------------------------------------------------------------------------
7700 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
7701 dnl --------------------
7702 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
7703 dnl won't, but they're still there.
7704 AC_DEFUN([CF_UNSIGNED_LITERALS],
7705 [
7706 AC_MSG_CHECKING([if unsigned literals are legal])
7707 AC_CACHE_VAL(cf_cv_unsigned_literals,[
7708         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
7709                 [cf_cv_unsigned_literals=yes],
7710                 [cf_cv_unsigned_literals=no])
7711         ])
7712 AC_MSG_RESULT($cf_cv_unsigned_literals)
7713 ])dnl
7714 dnl ---------------------------------------------------------------------------
7715 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
7716 dnl --------
7717 dnl Make an uppercase version of a variable
7718 dnl $1=uppercase($2)
7719 AC_DEFUN([CF_UPPER],
7720 [
7721 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
7722 ])dnl
7723 dnl ---------------------------------------------------------------------------
7724 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
7725 dnl -----------
7726 dnl Check for multibyte support, and if not found, utf8 compatibility library
7727 AC_DEFUN([CF_UTF8_LIB],
7728 [
7729 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
7730         cf_save_LIBS="$LIBS"
7731         AC_TRY_LINK([
7732 #include <stdlib.h>],[putwc(0,0);],
7733         [cf_cv_utf8_lib=yes],
7734         [CF_FIND_LINKAGE([
7735 #include <libutf8.h>],[putwc(0,0);],utf8,
7736                 [cf_cv_utf8_lib=add-on],
7737                 [cf_cv_utf8_lib=no])
7738 ])])
7739
7740 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
7741 # ncurses/ncursesw:
7742 if test "$cf_cv_utf8_lib" = "add-on" ; then
7743         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
7744         CF_ADD_INCDIR($cf_cv_header_path_utf8)
7745         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
7746         CF_ADD_LIBS($cf_cv_library_file_utf8)
7747 fi
7748 ])dnl
7749 dnl ---------------------------------------------------------------------------
7750 dnl CF_VA_COPY version: 6 updated: 2018/12/04 18:14:25
7751 dnl ----------
7752 dnl check for va_copy, part of stdarg.h starting with ISO C 1999.
7753 dnl Also, workaround for glibc's __va_copy, by checking for both.
7754 dnl Finally, try to accommodate pre-ISO C 1999 headers.
7755 AC_DEFUN([CF_VA_COPY],[
7756 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
7757 AC_TRY_LINK([
7758 #include <stdarg.h>
7759 ],[
7760         static va_list dst;
7761         static va_list src;
7762         va_copy(dst, src)],
7763         cf_cv_have_va_copy=yes,
7764         cf_cv_have_va_copy=no)])
7765
7766 if test "$cf_cv_have_va_copy" = yes;
7767 then
7768         AC_DEFINE(HAVE_VA_COPY,1,[Define to 1 if we have va_copy])
7769 else # !cf_cv_have_va_copy
7770
7771 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
7772 AC_TRY_LINK([
7773 #include <stdarg.h>
7774 ],[
7775         static va_list dst;
7776         static va_list src;
7777         __va_copy(dst, src)],
7778         cf_cv_have___va_copy=yes,
7779         cf_cv_have___va_copy=no)])
7780
7781 if test "$cf_cv_have___va_copy" = yes
7782 then
7783         AC_DEFINE(HAVE___VA_COPY,1,[Define to 1 if we have __va_copy])
7784 else # !cf_cv_have___va_copy
7785
7786 AC_CACHE_CHECK(for __builtin_va_copy, cf_cv_have___builtin_va_copy,[
7787 AC_TRY_LINK([
7788 #include <stdarg.h>
7789 ],[
7790         static va_list dst;
7791         static va_list src;
7792         __builtin_va_copy(dst, src)],
7793         cf_cv_have___builtin_va_copy=yes,
7794         cf_cv_have___builtin_va_copy=no)])
7795
7796 test "$cf_cv_have___builtin_va_copy" = yes &&
7797         AC_DEFINE(HAVE___BUILTIN_VA_COPY,1,[Define to 1 if we have __builtin_va_copy])
7798
7799 fi # cf_cv_have___va_copy
7800
7801 fi # cf_cv_have_va_copy
7802
7803 case "${cf_cv_have_va_copy}${cf_cv_have___va_copy}${cf_cv_have___builtin_va_copy}" in
7804 (*yes*)
7805         ;;
7806
7807 (*)
7808         AC_CACHE_CHECK(if we can simply copy va_list, cf_cv_pointer_va_list,[
7809 AC_TRY_LINK([
7810 #include <stdarg.h>
7811 ],[
7812         va_list dst;
7813         va_list src;
7814         dst = src],
7815         cf_cv_pointer_va_list=yes,
7816         cf_cv_pointer_va_list=no)])
7817
7818         if test "$cf_cv_pointer_va_list" = no
7819         then
7820                 AC_CACHE_CHECK(if we can copy va_list indirectly, cf_cv_array_va_list,[
7821 AC_TRY_LINK([
7822 #include <stdarg.h>
7823 ],[
7824         va_list dst;
7825         va_list src;
7826         *dst = *src],
7827                         cf_cv_array_va_list=yes,
7828                         cf_cv_array_va_list=no)])
7829                 test "$cf_cv_array_va_list" = yes && AC_DEFINE(ARRAY_VA_LIST,1,[Define to 1 if we can copy va_list indirectly])
7830         fi
7831         ;;
7832 esac
7833 ])
7834 dnl ---------------------------------------------------------------------------
7835 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
7836 dnl ----------
7837 dnl Use AC_VERBOSE w/o the warnings
7838 AC_DEFUN([CF_VERBOSE],
7839 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
7840 CF_MSG_LOG([$1])
7841 ])dnl
7842 dnl ---------------------------------------------------------------------------
7843 dnl CF_VERSION_INFO version: 7 updated: 2015/04/17 21:13:04
7844 dnl ---------------
7845 dnl Define several useful symbols derived from the VERSION file.  A separate
7846 dnl file is preferred to embedding the version numbers in various scripts.
7847 dnl (automake is a textbook-example of why the latter is a bad idea, but there
7848 dnl are others).
7849 dnl
7850 dnl The file contents are:
7851 dnl     libtool-version release-version patch-version
7852 dnl or
7853 dnl     release-version
7854 dnl where
7855 dnl     libtool-version (see ?) consists of 3 integers separated by '.'
7856 dnl     release-version consists of a major version and minor version
7857 dnl             separated by '.', optionally followed by a patch-version
7858 dnl             separated by '-'.  The minor version need not be an
7859 dnl             integer (but it is preferred).
7860 dnl     patch-version is an integer in the form yyyymmdd, so ifdef's and
7861 dnl             scripts can easily compare versions.
7862 dnl
7863 dnl If libtool is used, the first form is required, since CF_WITH_LIBTOOL
7864 dnl simply extracts the first field using 'cut -f1'.
7865 dnl
7866 dnl Optional parameters:
7867 dnl $1 = internal name for package
7868 dnl $2 = external name for package
7869 AC_DEFUN([CF_VERSION_INFO],
7870 [
7871 if test -f $srcdir/VERSION ; then
7872         AC_MSG_CHECKING(for package version)
7873
7874         # if there are not enough fields, cut returns the last one...
7875         cf_field1=`sed -e '2,$d' $srcdir/VERSION|cut -f1`
7876         cf_field2=`sed -e '2,$d' $srcdir/VERSION|cut -f2`
7877         cf_field3=`sed -e '2,$d' $srcdir/VERSION|cut -f3`
7878
7879         # this is how CF_BUNDLED_INTL uses $VERSION:
7880         VERSION="$cf_field1"
7881
7882         VERSION_MAJOR=`echo "$cf_field2" | sed -e 's/\..*//'`
7883         test -z "$VERSION_MAJOR" && AC_MSG_ERROR(missing major-version)
7884
7885         VERSION_MINOR=`echo "$cf_field2" | sed -e 's/^[[^.]]*\.//' -e 's/-.*//'`
7886         test -z "$VERSION_MINOR" && AC_MSG_ERROR(missing minor-version)
7887
7888         AC_MSG_RESULT(${VERSION_MAJOR}.${VERSION_MINOR})
7889
7890         AC_MSG_CHECKING(for package patch date)
7891         VERSION_PATCH=`echo "$cf_field3" | sed -e 's/^[[^-]]*-//'`
7892         case .$VERSION_PATCH in
7893         (.)
7894                 AC_MSG_ERROR(missing patch-date $VERSION_PATCH)
7895                 ;;
7896         (.[[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]])
7897                 ;;
7898         (*)
7899                 AC_MSG_ERROR(illegal patch-date $VERSION_PATCH)
7900                 ;;
7901         esac
7902         AC_MSG_RESULT($VERSION_PATCH)
7903 else
7904         AC_MSG_ERROR(did not find $srcdir/VERSION)
7905 fi
7906
7907 # show the actual data that we have for versions:
7908 CF_VERBOSE(ABI VERSION $VERSION)
7909 CF_VERBOSE(VERSION_MAJOR $VERSION_MAJOR)
7910 CF_VERBOSE(VERSION_MINOR $VERSION_MINOR)
7911 CF_VERBOSE(VERSION_PATCH $VERSION_PATCH)
7912
7913 AC_SUBST(VERSION)
7914 AC_SUBST(VERSION_MAJOR)
7915 AC_SUBST(VERSION_MINOR)
7916 AC_SUBST(VERSION_PATCH)
7917
7918 dnl if a package name is given, define its corresponding version info.  We
7919 dnl need the package name to ensure that the defined symbols are unique.
7920 ifelse($1,,,[
7921         cf_PACKAGE=$1
7922         PACKAGE=ifelse($2,,$1,$2)
7923         AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",[Define to the package-name])
7924         AC_SUBST(PACKAGE)
7925         CF_UPPER(cf_PACKAGE,$cf_PACKAGE)
7926         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_VERSION,"${VERSION_MAJOR}.${VERSION_MINOR}")
7927         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_PATCHDATE,${VERSION_PATCH})
7928 ])
7929 ])dnl
7930 dnl ---------------------------------------------------------------------------
7931 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
7932 dnl -------------
7933 dnl Check if type wide-character type $1 is declared, and if so, which header
7934 dnl file is needed.  The second parameter is used to set a shell variable when
7935 dnl the type is not found.  The first parameter sets a shell variable for the
7936 dnl opposite sense.
7937 AC_DEFUN([CF_WCHAR_TYPE],
7938 [
7939 # This is needed on Tru64 5.0 to declare $1
7940 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
7941 AC_TRY_COMPILE([
7942 #include <stdlib.h>
7943 #include <stdarg.h>
7944 #include <stdio.h>
7945 #ifdef HAVE_LIBUTF8_H
7946 #include <libutf8.h>
7947 #endif],
7948         [$1 state],
7949         [cf_cv_$1=no],
7950         [AC_TRY_COMPILE([
7951 #include <stdlib.h>
7952 #include <stdarg.h>
7953 #include <stdio.h>
7954 #include <wchar.h>
7955 #ifdef HAVE_LIBUTF8_H
7956 #include <libutf8.h>
7957 #endif],
7958         [$1 value],
7959         [cf_cv_$1=yes],
7960         [cf_cv_$1=unknown])])])
7961
7962 if test "$cf_cv_$1" = yes ; then
7963         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
7964         NEED_WCHAR_H=1
7965 fi
7966
7967 ifelse([$2],,,[
7968 # if we do not find $1 in either place, use substitution to provide a fallback.
7969 if test "$cf_cv_$1" = unknown ; then
7970         $2=1
7971 fi
7972 ])
7973 ifelse($3,,,[
7974 # if we find $1 in either place, use substitution to provide a fallback.
7975 if test "$cf_cv_$1" != unknown ; then
7976         $3=1
7977 fi
7978 ])
7979 ])dnl
7980 dnl ---------------------------------------------------------------------------
7981 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
7982 dnl ---------------
7983 dnl Check for compiler-support for weak symbols.
7984 dnl This works with "recent" gcc.
7985 AC_DEFUN([CF_WEAK_SYMBOLS],[
7986 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
7987
7988 AC_TRY_COMPILE([
7989 #include <stdio.h>],
7990 [
7991 #if defined(__GNUC__)
7992 #  if defined __USE_ISOC99
7993 #    define _cat_pragma(exp)    _Pragma(#exp)
7994 #    define _weak_pragma(exp)   _cat_pragma(weak name)
7995 #  else
7996 #    define _weak_pragma(exp)
7997 #  endif
7998 #  define _declare(name)        __extension__ extern __typeof__(name) name
7999 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
8000 #endif
8001
8002 weak_symbol(fopen);
8003 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
8004 ])
8005 ])dnl
8006 dnl ---------------------------------------------------------------------------
8007 dnl CF_WITH_ABI_VERSION version: 3 updated: 2015/06/06 16:10:11
8008 dnl -------------------
8009 dnl Allow library's ABI to be overridden.  Generally this happens when a
8010 dnl packager has incremented the ABI past that used in the original package,
8011 dnl and wishes to keep doing this.
8012 dnl
8013 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
8014 dnl symbol.
8015 AC_DEFUN([CF_WITH_ABI_VERSION],[
8016 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
8017 AC_ARG_WITH(abi-version,
8018 [  --with-abi-version=XXX  override derived ABI version],[
8019         if test "x$cf_cv_abi_version" != "x$withval"
8020         then
8021                 AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
8022                 case $cf_cv_rel_version in
8023                 (5.*)
8024                         cf_cv_rel_version=$withval.0
8025                         ;;
8026                 (6.*)
8027                         cf_cv_rel_version=$withval.9    # FIXME: should be 10 as of 6.0 release
8028                         ;;
8029                 esac
8030         fi
8031         cf_cv_abi_version=$withval])
8032         CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
8033 ifelse($1,,,[
8034 $1_ABI=$cf_cv_abi_version
8035 ])
8036 ])dnl
8037 dnl ---------------------------------------------------------------------------
8038 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
8039 dnl --------------------
8040 dnl Command-line option to specify the Ada95 compiler.
8041 AC_DEFUN([CF_WITH_ADA_COMPILER],[
8042 AC_MSG_CHECKING(for ada-compiler)
8043 AC_ARG_WITH(ada-compiler,
8044         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
8045         [cf_ada_compiler=$withval],
8046         [cf_ada_compiler=gnatmake])
8047 AC_SUBST(cf_ada_compiler)
8048 AC_MSG_RESULT($cf_ada_compiler)
8049 ])dnl
8050 dnl ---------------------------------------------------------------------------
8051 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
8052 dnl -------------------
8053 dnl Command-line option to specify where Ada includes will install.
8054 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
8055 AC_MSG_CHECKING(for ada-include)
8056 CF_WITH_PATH(ada-include,
8057    [  --with-ada-include=DIR  Ada includes are in DIR],
8058    ADA_INCLUDE,
8059    PREFIX/share/ada/adainclude,
8060    [$]prefix/share/ada/adainclude)
8061 AC_SUBST(ADA_INCLUDE)
8062 AC_MSG_RESULT($ADA_INCLUDE)
8063 ])dnl
8064 dnl ---------------------------------------------------------------------------
8065 dnl CF_WITH_ADA_LIBNAME version: 1 updated: 2019/09/07 18:59:41
8066 dnl -------------------
8067 dnl CF_WITH_ADA_LIBNAME
8068 dnl -------------------
8069 dnl Command-line option to specify how to name the resulting Ada library.
8070 dnl $1 = default value
8071 AC_DEFUN([CF_WITH_ADA_LIBNAME],[
8072 AC_MSG_CHECKING(for ada-libname)
8073 AC_ARG_WITH(ada-libname,
8074    [  --with-ada-libname=XXX  override default Ada library-name],
8075    ADA_LIBNAME=[$]withval,
8076    ADA_LIBNAME=$1)
8077 case "x$ADA_LIBNAME" in
8078 (x|xyes|xno)
8079         ADA_LIBNAME=$1
8080         ;;
8081 esac
8082 AC_SUBST(ADA_LIBNAME)
8083 AC_MSG_RESULT($ADA_LIBNAME)
8084 ])dnl
8085 dnl ---------------------------------------------------------------------------
8086 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
8087 dnl -------------------
8088 dnl Command-line option to specify where Ada objects will install.
8089 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
8090 AC_MSG_CHECKING(for ada-objects)
8091 CF_WITH_PATH(ada-objects,
8092    [  --with-ada-objects=DIR  Ada objects are in DIR],
8093    ADA_OBJECTS,
8094    PREFIX/lib/ada/adalib,
8095    [$]prefix/lib/ada/adalib)
8096 AC_SUBST(ADA_OBJECTS)
8097 AC_MSG_RESULT($ADA_OBJECTS)
8098 ])dnl
8099 dnl ---------------------------------------------------------------------------
8100 dnl CF_WITH_ADA_SHAREDLIB version: 5 updated: 2018/07/21 19:10:35
8101 dnl ---------------------
8102 dnl Command-line option to specify if an Ada95 shared-library should be built,
8103 dnl and optionally what its soname should be.
8104 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
8105 AC_REQUIRE([CF_GNAT_PROJECTS])
8106 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
8107 AC_ARG_WITH(ada-sharedlib,
8108         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
8109         [with_ada_sharedlib=$withval],
8110         [with_ada_sharedlib=no])
8111 AC_MSG_RESULT($with_ada_sharedlib)
8112
8113 if test "x$with_ada_sharedlib" != xno
8114 then
8115         if test "x$cf_gnat_projects" != xyes
8116         then
8117                 AC_MSG_WARN(disabling shared-library since GNAT projects are not supported)
8118                 with_ada_sharedlib=no
8119         fi
8120 fi
8121
8122 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
8123 MAKE_ADA_SHAREDLIB="#"
8124
8125 if test "x$with_ada_sharedlib" != xno
8126 then
8127         MAKE_ADA_SHAREDLIB=
8128         if test "x$with_ada_sharedlib" != xyes
8129         then
8130                 ADA_SHAREDLIB="$with_ada_sharedlib"
8131         fi
8132 fi
8133
8134 AC_SUBST(ADA_SHAREDLIB)
8135 AC_SUBST(MAKE_ADA_SHAREDLIB)
8136 ])dnl
8137 dnl ---------------------------------------------------------------------------
8138 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
8139 dnl ----------------
8140 dnl Configure-option for dbmalloc.  The optional parameter is used to override
8141 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
8142 AC_DEFUN([CF_WITH_DBMALLOC],[
8143 CF_NO_LEAKS_OPTION(dbmalloc,
8144         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
8145         [USE_DBMALLOC])
8146
8147 if test "$with_dbmalloc" = yes ; then
8148         AC_CHECK_HEADER(dbmalloc.h,
8149                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
8150 fi
8151 ])dnl
8152 dnl ---------------------------------------------------------------------------
8153 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
8154 dnl ---------------
8155 dnl Configure-option for dmalloc.  The optional parameter is used to override
8156 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
8157 AC_DEFUN([CF_WITH_DMALLOC],[
8158 CF_NO_LEAKS_OPTION(dmalloc,
8159         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
8160         [USE_DMALLOC])
8161
8162 if test "$with_dmalloc" = yes ; then
8163         AC_CHECK_HEADER(dmalloc.h,
8164                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
8165 fi
8166 ])dnl
8167 dnl ---------------------------------------------------------------------------
8168 dnl CF_WITH_EXPORT_SYMS version: 3 updated: 2014/12/20 19:16:08
8169 dnl -------------------
8170 dnl Use this with libtool to specify the list of symbols that may be exported.
8171 dnl The input file contains one symbol per line; comments work with "#".
8172 dnl
8173 dnl $1 = basename of the ".sym" file (default $PACKAGE)
8174 AC_DEFUN([CF_WITH_EXPORT_SYMS],
8175 [
8176 AC_MSG_CHECKING(if exported-symbols file should be used)
8177 AC_ARG_WITH(export-syms,
8178         [  --with-export-syms=XXX  limit exported symbols using libtool],
8179         [with_export_syms=$withval],
8180         [with_export_syms=no])
8181 if test "x$with_export_syms" = xyes
8182 then
8183         with_export_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).sym'
8184         AC_SUBST(PACKAGE)
8185 fi
8186 AC_MSG_RESULT($with_export_syms)
8187 if test "x$with_export_syms" != xno
8188 then
8189         EXPORT_SYMS="-export-symbols $with_export_syms"
8190         AC_SUBST(EXPORT_SYMS)
8191 fi
8192 ])dnl
8193 dnl ---------------------------------------------------------------------------
8194 dnl CF_WITH_GPM version: 10 updated: 2017/04/29 18:32:18
8195 dnl -----------
8196 dnl
8197 dnl The option parameter (if neither yes/no) is assumed to be the name of
8198 dnl the gpm library, e.g., for dynamic loading.
8199 AC_DEFUN([CF_WITH_GPM],
8200 [
8201 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
8202 AC_ARG_WITH(gpm,
8203         [  --with-gpm              use Alessandro Rubini's GPM library],
8204         [with_gpm=$withval],
8205         [with_gpm=maybe])
8206 AC_MSG_RESULT($with_gpm)
8207
8208 if test "$with_gpm" != no ; then
8209         AC_CHECK_HEADER(gpm.h,[
8210                 AC_DEFINE(HAVE_GPM_H,1,[Define to 1 if we have gpm.h header])
8211                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
8212                         CF_VERBOSE(assuming we really have GPM library)
8213                         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
8214                         with_gpm=yes
8215                 else
8216                         AC_CHECK_LIB(gpm,Gpm_Open,[with_gpm=yes],[
8217                                 if test "$with_gpm" = maybe; then
8218                                         AC_MSG_WARN(Cannot link with GPM library)
8219                                         with_gpm=no
8220                                 else
8221                                         AC_MSG_ERROR(Cannot link with GPM library)
8222                                 fi
8223                         ])
8224                 fi
8225         ],[
8226                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
8227                 with_gpm=no
8228         ])
8229 fi
8230 ])
8231 dnl ---------------------------------------------------------------------------
8232 dnl CF_WITH_LIBTOOL version: 35 updated: 2017/08/12 07:58:51
8233 dnl ---------------
8234 dnl Provide a configure option to incorporate libtool.  Define several useful
8235 dnl symbols for the makefile rules.
8236 dnl
8237 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
8238 dnl macros from libtool.m4 which is in the aclocal directory of automake.
8239 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
8240 dnl But that still does not work properly since the macro is expanded outside
8241 dnl the CF_WITH_LIBTOOL macro:
8242 dnl
8243 dnl     #!/bin/sh
8244 dnl     ACLOCAL=`aclocal --print-ac-dir`
8245 dnl     if test -z "$ACLOCAL" ; then
8246 dnl             echo cannot find aclocal directory
8247 dnl             exit 1
8248 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
8249 dnl             echo cannot find libtool.m4 file
8250 dnl             exit 1
8251 dnl     fi
8252 dnl
8253 dnl     LOCAL=aclocal.m4
8254 dnl     ORIG=aclocal.m4.orig
8255 dnl
8256 dnl     trap "mv $ORIG $LOCAL" 0 1 2 3 15
8257 dnl     rm -f $ORIG
8258 dnl     mv $LOCAL $ORIG
8259 dnl
8260 dnl     # sed the LIBTOOL= assignment to omit the current directory?
8261 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
8262 dnl     cat $ORIG >>$LOCAL
8263 dnl
8264 dnl     autoconf-257 $*
8265 dnl
8266 AC_DEFUN([CF_WITH_LIBTOOL],
8267 [
8268 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
8269 ifdef([AC_PROG_LIBTOOL],,[
8270 LIBTOOL=
8271 ])
8272 # common library maintenance symbols that are convenient for libtool scripts:
8273 LIB_CREATE='${AR} -cr'
8274 LIB_OBJECT='${OBJECTS}'
8275 LIB_SUFFIX=.a
8276 LIB_PREP="$RANLIB"
8277
8278 # symbols used to prop libtool up to enable it to determine what it should be
8279 # doing:
8280 LIB_CLEAN=
8281 LIB_COMPILE=
8282 LIB_LINK='${CC}'
8283 LIB_INSTALL=
8284 LIB_UNINSTALL=
8285
8286 AC_MSG_CHECKING(if you want to build libraries with libtool)
8287 AC_ARG_WITH(libtool,
8288         [  --with-libtool          generate libraries with libtool],
8289         [with_libtool=$withval],
8290         [with_libtool=no])
8291 AC_MSG_RESULT($with_libtool)
8292 if test "$with_libtool" != "no"; then
8293 ifdef([AC_PROG_LIBTOOL],[
8294         # missing_content_AC_PROG_LIBTOOL{{
8295         AC_PROG_LIBTOOL
8296         # missing_content_AC_PROG_LIBTOOL}}
8297 ],[
8298         if test "$with_libtool" != "yes" ; then
8299                 CF_PATH_SYNTAX(with_libtool)
8300                 LIBTOOL=$with_libtool
8301         else
8302                 AC_CHECK_TOOLS(LIBTOOL,[libtool glibtool],none)
8303                 CF_LIBTOOL_VERSION
8304                 if test -z "$cf_cv_libtool_version" && test "$LIBTOOL" = libtool
8305                 then
8306                         CF_FORGET_TOOL(LIBTOOL)
8307                         AC_CHECK_TOOLS(LIBTOOL,[glibtool],none)
8308                         CF_LIBTOOL_VERSION
8309                 fi
8310         fi
8311         if test -z "$LIBTOOL" ; then
8312                 AC_MSG_ERROR(Cannot find libtool)
8313         fi
8314 ])dnl
8315         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${libdir} ${LIBTOOL_VERSION} `cut -f1 ${top_srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
8316         LIB_OBJECT='${OBJECTS:.o=.lo}'
8317         LIB_SUFFIX=.la
8318         LIB_CLEAN='${LIBTOOL} --mode=clean'
8319         LIB_COMPILE='${LIBTOOL} --mode=compile'
8320         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
8321         LIB_INSTALL='${LIBTOOL} --mode=install'
8322         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
8323         LIB_PREP=:
8324
8325         CF_CHECK_LIBTOOL_VERSION
8326
8327         # special hack to add -no-undefined (which libtool should do for itself)
8328         LT_UNDEF=
8329         case "$cf_cv_system_name" in
8330         (cygwin*|msys*|mingw32*|os2*|uwin*|aix[[4-7]])
8331                 LT_UNDEF=-no-undefined
8332                 ;;
8333         esac
8334         AC_SUBST([LT_UNDEF])
8335
8336         # special hack to add --tag option for C++ compiler
8337         case $cf_cv_libtool_version in
8338         (1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*)
8339                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
8340                 LIBTOOL="$LIBTOOL --tag=CC"
8341                 ;;
8342         (*)
8343                 LIBTOOL_CXX="$LIBTOOL"
8344                 ;;
8345         esac
8346 else
8347         LIBTOOL=""
8348         LIBTOOL_CXX=""
8349 fi
8350
8351 test -z "$LIBTOOL" && ECHO_LT=
8352
8353 AC_SUBST(LIBTOOL)
8354 AC_SUBST(LIBTOOL_CXX)
8355 AC_SUBST(LIBTOOL_OPTS)
8356
8357 AC_SUBST(LIB_CREATE)
8358 AC_SUBST(LIB_OBJECT)
8359 AC_SUBST(LIB_SUFFIX)
8360 AC_SUBST(LIB_PREP)
8361
8362 AC_SUBST(LIB_CLEAN)
8363 AC_SUBST(LIB_COMPILE)
8364 AC_SUBST(LIB_LINK)
8365 AC_SUBST(LIB_INSTALL)
8366 AC_SUBST(LIB_UNINSTALL)
8367
8368 ])dnl
8369 dnl ---------------------------------------------------------------------------
8370 dnl CF_WITH_LIBTOOL_OPTS version: 4 updated: 2015/04/17 21:13:04
8371 dnl --------------------
8372 dnl Allow user to pass additional libtool options into the library creation
8373 dnl and link steps.  The main use for this is to do something like
8374 dnl     ./configure --with-libtool-opts=-static
8375 dnl to get the same behavior as automake-flavored
8376 dnl     ./configure --enable-static
8377 AC_DEFUN([CF_WITH_LIBTOOL_OPTS],[
8378 AC_MSG_CHECKING(for additional libtool options)
8379 AC_ARG_WITH(libtool-opts,
8380         [  --with-libtool-opts=XXX specify additional libtool options],
8381         [with_libtool_opts=$withval],
8382         [with_libtool_opts=no])
8383 AC_MSG_RESULT($with_libtool_opts)
8384
8385 case .$with_libtool_opts in
8386 (.yes|.no|.)
8387         ;;
8388 (*)
8389         LIBTOOL_OPTS="$LIBTOOL_OPTS $with_libtool_opts"
8390         ;;
8391 esac
8392
8393 AC_SUBST(LIBTOOL_OPTS)
8394 ])dnl
8395 dnl ---------------------------------------------------------------------------
8396 dnl CF_WITH_LIB_BASENAME version: 1 updated: 2020/03/07 20:05:14
8397 dnl --------------------
8398 dnl Allow for overriding the basename of a library, i.e., the part to which
8399 dnl prefixes/suffixes are attached.
8400 dnl
8401 dnl $1 = variable to set
8402 dnl $2 = option name
8403 dnl $3 = default basename for library, if omitted use $2
8404 AC_DEFUN([CF_WITH_LIB_BASENAME],
8405 [
8406 AC_MSG_CHECKING(for desired basename for $2 library)
8407 AC_ARG_WITH($2-libname,
8408         [  --with-$2-libname=XXX override ifelse($3,,$2,$3) basename of library],
8409         [with_lib_basename=$withval],
8410         [with_lib_basename=ifelse($3,,$2,$3)])
8411 $1="$with_lib_basename"
8412
8413 case "x[$]$1" in
8414 (x|xno|xnone|xyes)
8415         $1=ifelse($3,,$2,$3)
8416         ;;
8417 (*)
8418         ;;
8419 esac
8420
8421 AC_MSG_RESULT([$]$1)
8422 AC_SUBST($1)
8423 ])dnl
8424 dnl ---------------------------------------------------------------------------
8425 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
8426 dnl ------------------
8427 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
8428 dnl "lib" prefix, e.g., because it used the dll naming convention.
8429 dnl
8430 dnl $1 = variable to set
8431 AC_DEFUN([CF_WITH_LIB_PREFIX],
8432 [
8433 AC_MSG_CHECKING(if you want to have a library-prefix)
8434 AC_ARG_WITH(lib-prefix,
8435         [  --with-lib-prefix       override library-prefix],
8436         [with_lib_prefix=$withval],
8437         [with_lib_prefix=auto])
8438 AC_MSG_RESULT($with_lib_prefix)
8439
8440 if test $with_lib_prefix = auto
8441 then
8442         CF_LIB_PREFIX($1)
8443 elif test $with_lib_prefix = no
8444 then
8445         LIB_PREFIX=
8446 else
8447         LIB_PREFIX=$with_lib_prefix
8448 fi
8449 ])dnl
8450 dnl ---------------------------------------------------------------------------
8451 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
8452 dnl ------------
8453 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
8454 dnl defaulting to yes/no.
8455 dnl
8456 dnl $1 = option name
8457 dnl $2 = help-text
8458 dnl $3 = environment variable to set
8459 dnl $4 = default value, shown in the help-message, must be a constant
8460 dnl $5 = default value, if it's an expression & cannot be in the help-message
8461 dnl
8462 AC_DEFUN([CF_WITH_PATH],
8463 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
8464 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
8465 if ifelse([$5],,true,[test -n "$5"]) ; then
8466 CF_PATH_SYNTAX(withval)
8467 fi
8468 eval $3="$withval"
8469 AC_SUBST($3)dnl
8470 ])dnl
8471 dnl ---------------------------------------------------------------------------
8472 dnl CF_WITH_PATHLIST version: 10 updated: 2015/04/17 21:13:04
8473 dnl ----------------
8474 dnl Process an option specifying a list of colon-separated paths.
8475 dnl
8476 dnl $1 = option name
8477 dnl $2 = help-text
8478 dnl $3 = environment variable to set
8479 dnl $4 = default value, shown in the help-message, must be a constant
8480 dnl $5 = default value, if it's an expression & cannot be in the help-message
8481 dnl $6 = flag to tell if we want to define or substitute
8482 dnl
8483 AC_DEFUN([CF_WITH_PATHLIST],[
8484 AC_REQUIRE([CF_PATHSEP])
8485 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
8486 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
8487
8488 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
8489 cf_dst_path=
8490 for cf_src_path in $withval
8491 do
8492   CF_PATH_SYNTAX(cf_src_path)
8493   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}$PATH_SEPARATOR"
8494   cf_dst_path="${cf_dst_path}${cf_src_path}"
8495 done
8496 IFS="$ac_save_ifs"
8497
8498 ifelse($6,define,[
8499 # Strip single quotes from the value, e.g., when it was supplied as a literal
8500 # for $4 or $5.
8501 case $cf_dst_path in
8502 (\'*)
8503   cf_dst_path=`echo $cf_dst_path |sed -e s/\'// -e s/\'\$//`
8504   ;;
8505 esac
8506 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
8507 ])
8508
8509 # This may use the prefix/exec_prefix symbols which will only yield "NONE"
8510 # so we have to check/work around.  We do prefer the result of "eval"...
8511 eval cf_dst_eval="$cf_dst_path"
8512 case "x$cf_dst_eval" in
8513 (xNONE*)
8514         $3=$cf_dst_path
8515         ;;
8516 (*)
8517         $3="$cf_dst_eval"
8518         ;;
8519 esac
8520 AC_SUBST($3)dnl
8521
8522 ])dnl
8523 dnl ---------------------------------------------------------------------------
8524 dnl CF_WITH_PATH_PROG version: 1 updated: 2019/06/30 19:44:43
8525 dnl -----------------
8526 dnl Check for a given program, like CF_PATH_PROG, but allow override using a
8527 dnl "--with-xxx" option.
8528 dnl
8529 dnl Parameters:
8530 dnl             $1 = environment variable to set/update
8531 dnl             $2 = program name
8532 dnl             $3 = help-text
8533 dnl             $4 = $PATH
8534 AC_DEFUN([CF_WITH_PATH_PROG],[
8535 AC_ARG_WITH($2-path,
8536         [  --with-$2-path=XXX     specify path of $2 ifelse($3,,,$3)],
8537         [AC_MSG_CHECKING(for $2 program ifelse($3,,,$3))
8538                 $1=$withval
8539                 AC_MSG_RESULT([$]$1)
8540                 CF_PATH_SYNTAX($1)
8541         ],
8542         [CF_PATH_PROG($1,$2,,ifelse($4,,,$4))
8543                 if test -z "[$]$1"
8544                 then
8545                         AC_MSG_WARN(no $2 program found ifelse($3,,,$3))
8546                 fi
8547         ])
8548 ])
8549 dnl ---------------------------------------------------------------------------
8550 dnl CF_WITH_PCRE2 version: 3 updated: 2020/02/29 16:09:19
8551 dnl -------------
8552 dnl Add PCRE2 (Perl-compatible regular expressions v2) to the build if it is
8553 dnl available and the user requests it.  Assume the application will otherwise
8554 dnl use the POSIX interface.
8555 dnl
8556 dnl TODO allow $withval to specify package location
8557 AC_DEFUN([CF_WITH_PCRE2],
8558 [
8559 AC_REQUIRE([CF_PKG_CONFIG])
8560
8561 AC_MSG_CHECKING(if you want to use PCRE2 for regular-expressions)
8562 AC_ARG_WITH(pcre2,
8563         [  --with-pcre2            use PCRE2 for regular-expressions])
8564 test -z "$with_pcre2" && with_pcre2=no
8565 AC_MSG_RESULT($with_pcre2)
8566
8567 if test "x$with_pcre2" != xno ; then
8568         CF_TRY_PKG_CONFIG(libpcre2,,[
8569         CF_TRY_PKG_CONFIG(libpcre,,[
8570                         AC_MSG_ERROR(Cannot find PCRE2 library)])])
8571
8572         AC_DEFINE(HAVE_LIB_PCRE2,1,[Define to 1 if we can/should compile with the PCRE2 library])
8573
8574         # if pkgconfig gave no results, look for the libraries directly
8575         case $LIBS in
8576         (*pcre2-posix*|*pcreposix*)
8577                 ;;
8578         (*)
8579                 AC_CHECK_LIB(pcre2-posix,regcomp,[
8580                         CF_ADD_LIB(pcre2-posix)],
8581                         [AC_CHECK_LIB(pcreposix,regcomp,[
8582                          CF_ADD_LIB(pcreposix)
8583                         ],[AC_MSG_ERROR(Cannot find PCRE2 POSIX library)])])
8584                 ;;
8585         esac
8586
8587         # either way, check for the library header files
8588         AC_CHECK_HEADERS(pcre2posix.h pcreposix.h)
8589 fi
8590 ])dnl
8591 dnl ---------------------------------------------------------------------------
8592 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 10 updated: 2015/08/22 17:10:56
8593 dnl -------------------------
8594 dnl Allow the choice of the pkg-config library directory to be overridden.
8595 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
8596
8597 case $PKG_CONFIG in
8598 (no|none|yes)
8599         AC_MSG_CHECKING(for pkg-config library directory)
8600         ;;
8601 (*)
8602         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
8603         ;;
8604 esac
8605
8606 PKG_CONFIG_LIBDIR=no
8607 AC_ARG_WITH(pkg-config-libdir,
8608         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
8609         [PKG_CONFIG_LIBDIR=$withval],
8610         [test "x$PKG_CONFIG" != xnone && PKG_CONFIG_LIBDIR=yes])
8611
8612 case x$PKG_CONFIG_LIBDIR in
8613 (x/*)
8614         ;;
8615 (xyes)
8616         # Look for the library directory using the same prefix as the executable
8617         if test "x$PKG_CONFIG" = xnone
8618         then
8619                 cf_path=$prefix
8620         else
8621                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
8622         fi
8623
8624         # If you don't like using the default architecture, you have to specify the
8625         # intended library directory and corresponding compiler/linker options.
8626         #
8627         # This case allows for Debian's 2014-flavor of multiarch, along with the
8628         # most common variations before that point.  Some other variants spell the
8629         # directory differently, e.g., "pkg-config", and put it in unusual places.
8630         # pkg-config has always been poorly standardized, which is ironic...
8631         case x`(arch) 2>/dev/null` in
8632         (*64)
8633                 cf_search_path="\
8634                         $cf_path/lib/*64-linux-gnu \
8635                         $cf_path/share \
8636                         $cf_path/lib64 \
8637                         $cf_path/lib32 \
8638                         $cf_path/lib"
8639                 ;;
8640         (*)
8641                 cf_search_path="\
8642                         $cf_path/lib/*-linux-gnu \
8643                         $cf_path/share \
8644                         $cf_path/lib32 \
8645                         $cf_path/lib \
8646                         $cf_path/libdata"
8647                 ;;
8648         esac
8649
8650         CF_VERBOSE(list...)
8651         for cf_config in $cf_search_path
8652         do
8653                 CF_VERBOSE(checking $cf_config/pkgconfig)
8654                 if test -d $cf_config/pkgconfig
8655                 then
8656                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
8657                         AC_MSG_CHECKING(done)
8658                         break
8659                 fi
8660         done
8661         ;;
8662 (*)
8663         ;;
8664 esac
8665
8666 if test "x$PKG_CONFIG_LIBDIR" != xno ; then
8667         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
8668 fi
8669
8670 AC_SUBST(PKG_CONFIG_LIBDIR)
8671 ])dnl
8672 dnl ---------------------------------------------------------------------------
8673 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
8674 dnl ---------------
8675 dnl Check for POSIX thread library.
8676 AC_DEFUN([CF_WITH_PTHREAD],
8677 [
8678 AC_MSG_CHECKING(if you want to link with the pthread library)
8679 AC_ARG_WITH(pthread,
8680         [  --with-pthread          use POSIX thread library],
8681         [with_pthread=$withval],
8682         [with_pthread=no])
8683 AC_MSG_RESULT($with_pthread)
8684
8685 if test "$with_pthread" != no ; then
8686         AC_CHECK_HEADER(pthread.h,[
8687         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
8688
8689         for cf_lib_pthread in pthread c_r
8690         do
8691             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
8692             cf_save_LIBS="$LIBS"
8693             CF_ADD_LIB($cf_lib_pthread)
8694             AC_TRY_LINK([
8695 #include <pthread.h>
8696 ],[
8697                 int rc = pthread_create(0,0,0,0);
8698                 int r2 = pthread_mutexattr_settype(0, 0);
8699 ],[with_pthread=yes],[with_pthread=no])
8700             LIBS="$cf_save_LIBS"
8701             AC_MSG_RESULT($with_pthread)
8702             test "$with_pthread" = yes && break
8703         done
8704
8705         if test "$with_pthread" = yes ; then
8706             CF_ADD_LIB($cf_lib_pthread)
8707             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
8708         else
8709             AC_MSG_ERROR(Cannot link with pthread library)
8710         fi
8711         ])
8712 fi
8713 ])
8714 dnl ---------------------------------------------------------------------------
8715 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
8716 dnl -------------------
8717 dnl Allow library's release-version to be overridden.  Generally this happens when a
8718 dnl packager has incremented the release-version past that used in the original package,
8719 dnl and wishes to keep doing this.
8720 dnl
8721 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
8722 dnl and {package}_MINOR symbols
8723 dnl symbol.
8724 AC_DEFUN([CF_WITH_REL_VERSION],[
8725 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
8726 AC_ARG_WITH(rel-version,
8727 [  --with-rel-version=XXX  override derived release version],
8728 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
8729  cf_cv_rel_version=$withval])
8730 ifelse($1,,[
8731  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
8732 ],[
8733  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
8734  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
8735  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
8736  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
8737 ])
8738 ])dnl
8739 dnl ---------------------------------------------------------------------------
8740 dnl CF_WITH_SYSMOUSE version: 3 updated: 2012/10/06 17:56:13
8741 dnl ----------------
8742 dnl If we can compile with sysmouse, make it available unless it is not wanted.
8743 AC_DEFUN([CF_WITH_SYSMOUSE],[
8744 # not everyone has "test -c"
8745 if test -c /dev/sysmouse 2>/dev/null ; then
8746 AC_MSG_CHECKING(if you want to use sysmouse)
8747 AC_ARG_WITH(sysmouse,
8748         [  --with-sysmouse         use sysmouse (FreeBSD console)],
8749         [cf_with_sysmouse=$withval],
8750         [cf_with_sysmouse=maybe])
8751         if test "$cf_with_sysmouse" != no ; then
8752         AC_TRY_COMPILE([
8753 #include <osreldate.h>
8754 #if (__FreeBSD_version >= 400017)
8755 #include <sys/consio.h>
8756 #include <sys/fbio.h>
8757 #else
8758 #include <machine/console.h>
8759 #endif
8760 ],[
8761         struct mouse_info the_mouse;
8762         ioctl(0, CONS_MOUSECTL, &the_mouse);
8763 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
8764         fi
8765 AC_MSG_RESULT($cf_with_sysmouse)
8766 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE,1,[Define to 1 if we can/should use the sysmouse interface])
8767 fi
8768 ])dnl
8769 dnl ---------------------------------------------------------------------------
8770 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
8771 dnl ---------------
8772 dnl For testing, override the derived host system-type which is used to decide
8773 dnl things such as the linker commands used to build shared libraries.  This is
8774 dnl normally chosen automatically based on the type of system which you are
8775 dnl building on.  We use it for testing the configure script.
8776 dnl
8777 dnl This is different from the --host option: it is used only for testing parts
8778 dnl of the configure script which would not be reachable with --host since that
8779 dnl relies on the build environment being real, rather than mocked up.
8780 AC_DEFUN([CF_WITH_SYSTYPE],[
8781 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
8782 AC_ARG_WITH(system-type,
8783         [  --with-system-type=XXX  test: override derived host system-type],
8784 [AC_MSG_WARN(overriding system type to $withval)
8785         cf_cv_system_name=$withval
8786         host_os=$withval
8787 ])
8788 ])dnl
8789 dnl ---------------------------------------------------------------------------
8790 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
8791 dnl ----------------
8792 AC_DEFUN([CF_WITH_VALGRIND],[
8793 CF_NO_LEAKS_OPTION(valgrind,
8794         [  --with-valgrind         test: use valgrind],
8795         [USE_VALGRIND])
8796 ])dnl
8797 dnl ---------------------------------------------------------------------------
8798 dnl CF_WITH_VERSIONED_SYMS version: 8 updated: 2018/10/20 20:24:34
8799 dnl ----------------------
8800 dnl Use this when building shared library with ELF, to markup symbols with the
8801 dnl version identifier from the given input file.  Generally that identifier is
8802 dnl the same as the SONAME at which the symbol was first introduced.
8803 dnl
8804 dnl $1 = basename of the ".map" file (default $PACKAGE)
8805 AC_DEFUN([CF_WITH_VERSIONED_SYMS],
8806 [
8807 AC_MSG_CHECKING(if versioned-symbols file should be used)
8808 AC_ARG_WITH(versioned-syms,
8809         [  --with-versioned-syms=X markup versioned symbols using ld],
8810         [with_versioned_syms=$withval],
8811         [with_versioned_syms=no])
8812 case "x$with_versioned_syms" in
8813 (xyes)
8814         with_versioned_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).map'
8815         AC_SUBST(PACKAGE)
8816         ;;
8817 (xno)
8818         ;;
8819 (x/*)
8820         test -f "$with_versioned_syms" || AC_MSG_ERROR(expected a filename: $with_versioned_syms)
8821         ;;
8822 (*)
8823         test -f "$with_versioned_syms" || AC_MSG_ERROR(expected a filename: $with_versioned_syms)
8824         with_versioned_syms=`pwd`/"$with_versioned_syms"
8825         ;;
8826 esac
8827 AC_MSG_RESULT($with_versioned_syms)
8828
8829 RESULTING_SYMS=
8830 VERSIONED_SYMS=
8831 WILDCARD_SYMS=
8832
8833 if test "x$with_versioned_syms" != xno
8834 then
8835         RESULTING_SYMS=$with_versioned_syms
8836         case "x$MK_SHARED_LIB" in
8837         (*-Wl,*)
8838                 VERSIONED_SYMS="-Wl,--version-script,\${RESULTING_SYMS}"
8839                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-Wl,%\\[$]{VERSIONED_SYMS} -Wl,%"`
8840                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
8841                 ;;
8842         (*-dy\ *)
8843                 VERSIONED_SYMS="-Wl,-M,\${RESULTING_SYMS}"
8844                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-dy%\\[$]{VERSIONED_SYMS} -dy%"`
8845                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
8846                 ;;
8847         (*)
8848                 AC_MSG_WARN(this system does not support versioned-symbols)
8849                 ;;
8850         esac
8851
8852         # Linux ld can selectively override scope, e.g., of symbols beginning with
8853         # "_" by first declaring some as global, and then using a wildcard to
8854         # declare the others as local.  Some other loaders cannot do this.  Check
8855         # by constructing a (very) simple shared library and inspecting its
8856         # symbols.
8857         if test "x$VERSIONED_SYMS" != "x"
8858         then
8859                 AC_MSG_CHECKING(if wildcards can be used to selectively omit symbols)
8860                 WILDCARD_SYMS=no
8861
8862                 # make sources
8863                 rm -f conftest.*
8864
8865                 cat >conftest.ver <<EOF
8866 module_1.0 {
8867 global:
8868         globalf1;
8869 local:
8870         localf1;
8871 };
8872 module_2.0 {
8873 global:
8874         globalf2;
8875 local:
8876         localf2;
8877         _*;
8878 } module_1.0;
8879 submodule_1.0 {
8880 global:
8881         subglobalf1;
8882         _ismissing;
8883 local:
8884         sublocalf1;
8885 };
8886 submodule_2.0 {
8887 global:
8888         subglobalf2;
8889 local:
8890         sublocalf2;
8891         _*;
8892 } submodule_1.0;
8893 EOF
8894                 cat >conftest.$ac_ext <<EOF
8895 #line __oline__ "configure"
8896 int     _ismissing(void) { return 1; }
8897 int     _localf1(void) { return 1; }
8898 int     _localf2(void) { return 2; }
8899 int     globalf1(void) { return 1; }
8900 int     globalf2(void) { return 2; }
8901 int     _sublocalf1(void) { return 1; }
8902 int     _sublocalf2(void) { return 2; }
8903 int     subglobalf1(void) { return 1; }
8904 int     subglobalf2(void) { return 2; }
8905 EOF
8906                 cat >conftest.mk <<EOF
8907 CC=${CC}
8908 CFLAGS=${CFLAGS}
8909 CPPFLAGS=${CPPFLAGS}
8910 LDFLAGS=${LDFLAGS}
8911 LIBS=${LIBS}
8912 VERSIONED_SYMS=${VERSIONED_SYMS}
8913 RESULTING_SYMS=conftest.ver
8914 MK_SHARED_LIB=${MK_SHARED_LIB}
8915 conftest.so: conftest.$ac_cv_objext
8916                 \$(MK_SHARED_LIB) conftest.$ac_cv_objext
8917 EOF
8918
8919                 # compile source, make library
8920                 if make -f conftest.mk 2>&AC_FD_CC >/dev/null
8921                 then
8922                         # test for missing symbol in either Data or Text section
8923                         cf_missing=`nm -P conftest.so 2>&AC_FD_CC |fgrep _ismissing | egrep '[[         ]][[DT]][[      ]]'`
8924                         test -n "$cf_missing" && WILDCARD_SYMS=yes
8925                 fi
8926                 AC_MSG_RESULT($WILDCARD_SYMS)
8927                 rm -f conftest.*
8928         fi
8929 fi
8930 AC_SUBST(RESULTING_SYMS)
8931 AC_SUBST(VERSIONED_SYMS)
8932 AC_SUBST(WILDCARD_SYMS)
8933 ])dnl
8934 dnl ---------------------------------------------------------------------------
8935 dnl CF_WITH_X11_RGB version: 2 updated: 2019/12/31 08:53:54
8936 dnl ---------------
8937 dnl Handle configure option "--with-x11-rgb", setting these shell
8938 dnl variables:
8939 dnl
8940 dnl $RGB_PATH is the option value, used for finding the X11 rgb file.
8941 dnl $no_x11_rgb is a "#" (comment) if "--without-x11-rgb" is given.
8942 dnl
8943 dnl Most Linux's use this:
8944 dnl     /usr/share/X11/rgb.txt
8945 dnl Debian uses this:
8946 dnl     /etc/X11/rgb.txt
8947 dnl DragonFlyBSD ports uses this:
8948 dnl     /usr/pkg/lib/X11/rgb.txt
8949 dnl FreeBSD ports use these:
8950 dnl     /usr/local/lib/X11/rgb.txt
8951 dnl     /usr/local/share/X11/rgb.txt
8952 dnl Mandriva has these:
8953 dnl     /usr/lib/X11/rgb.txt
8954 dnl     /usr/lib64/X11/rgb.txt
8955 dnl NetBSD has these
8956 dnl     /usr/X11R7/lib/X11/rgb.txt
8957 dnl OpenSolaris uses
8958 dnl     32-bit:
8959 dnl     /usr/X11/etc/X11/rgb.txt
8960 dnl     /usr/X11/share/X11/rgb.txt
8961 dnl     /usr/X11/lib/X11/rgb.txt
8962 dnl OSX uses
8963 dnl             /opt/local/share/X11/rgb.txt (MacPorts)
8964 dnl             /opt/X11/share/X11/rgb.txt (non-ports)
8965 dnl     64-bit:
8966 dnl     /usr/X11/etc/X11/rgb.txt
8967 dnl     /usr/X11/share/X11/rgb.txt (perhaps)
8968 dnl     /usr/X11/lib/amd64/X11/rgb.txt
8969 dnl Solaris10 uses (in this order):
8970 dnl     /usr/openwin/lib/X11/rgb.txt
8971 dnl     /usr/X11/lib/X11/rgb.txt
8972 AC_DEFUN([CF_WITH_X11_RGB],[
8973 AC_MSG_CHECKING(for X11 rgb file)
8974 AC_ARG_WITH(x11-rgb,
8975         [  --with-x11-rgb=FILE   file containing X11 rgb information (EPREFIX/lib/X11/rgb.txt)],
8976         [RGB_PATH=$withval],
8977         [RGB_PATH=auto])
8978
8979 if test "x[$]RGB_PATH" = xauto
8980 then
8981         RGB_PATH='${exec_prefix}/lib/X11/rgb.txt'
8982         for cf_path in \
8983                 /opt/local/share/X11/rgb.txt \
8984                 /opt/X11/share/X11/rgb.txt \
8985                 /usr/share/X11/rgb.txt \
8986                 /usr/X11/share/X11/rgb.txt \
8987                 /usr/X11/lib/X11/rgb.txt \
8988                 /usr/lib/X11/rgb.txt \
8989                 /etc/X11/rgb.txt \
8990                 /usr/pkg/lib/X11/rgb.txt \
8991                 /usr/X11R7/lib/X11/rgb.txt \
8992                 /usr/X11R6/lib/X11/rgb.txt \
8993                 /usr/X11R5/lib/X11/rgb.txt \
8994                 /usr/X11R4/lib/X11/rgb.txt \
8995                 /usr/local/lib/X11/rgb.txt \
8996                 /usr/local/share/X11/rgb.txt \
8997                 /usr/lib64/X11/rgb.txt
8998         do
8999                 if test -f "$cf_path" ; then
9000                         RGB_PATH="$cf_path"
9001                         break
9002                 fi
9003         done
9004 else
9005         cf_path=$RGB_PATH
9006         CF_PATH_SYNTAX(cf_path)
9007 fi
9008
9009 AC_MSG_RESULT($RGB_PATH)
9010 AC_SUBST(RGB_PATH)
9011 AC_DEFINE_UNQUOTED(RGB_PATH,"$cf_path",[Define to the full pathname of rgb.txt])
9012
9013 no_x11_rgb=
9014 if test "$RGB_PATH" = no
9015 then
9016         no_x11_rgb="#"
9017 fi
9018 AC_SUBST(no_x11_rgb)
9019 ])dnl
9020 dnl ---------------------------------------------------------------------------
9021 dnl CF_XOPEN_SOURCE version: 55 updated: 2018/12/31 20:46:17
9022 dnl ---------------
9023 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
9024 dnl or adapt to the vendor's definitions to get equivalent functionality,
9025 dnl without losing the common non-POSIX features.
9026 dnl
9027 dnl Parameters:
9028 dnl     $1 is the nominal value for _XOPEN_SOURCE
9029 dnl     $2 is the nominal value for _POSIX_C_SOURCE
9030 AC_DEFUN([CF_XOPEN_SOURCE],[
9031 AC_REQUIRE([AC_CANONICAL_HOST])
9032 AC_REQUIRE([CF_POSIX_VISIBLE])
9033
9034 if test "$cf_cv_posix_visible" = no; then
9035
9036 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
9037 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
9038 cf_xopen_source=
9039
9040 case $host_os in
9041 (aix[[4-7]]*)
9042         cf_xopen_source="-D_ALL_SOURCE"
9043         ;;
9044 (msys)
9045         cf_XOPEN_SOURCE=600
9046         ;;
9047 (darwin[[0-8]].*)
9048         cf_xopen_source="-D_APPLE_C_SOURCE"
9049         ;;
9050 (darwin*)
9051         cf_xopen_source="-D_DARWIN_C_SOURCE"
9052         cf_XOPEN_SOURCE=
9053         ;;
9054 (freebsd*|dragonfly*|midnightbsd*)
9055         # 5.x headers associate
9056         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
9057         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
9058         cf_POSIX_C_SOURCE=200112L
9059         cf_XOPEN_SOURCE=600
9060         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
9061         ;;
9062 (hpux11*)
9063         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
9064         ;;
9065 (hpux*)
9066         cf_xopen_source="-D_HPUX_SOURCE"
9067         ;;
9068 (irix[[56]].*)
9069         cf_xopen_source="-D_SGI_SOURCE"
9070         cf_XOPEN_SOURCE=
9071         ;;
9072 (linux*|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin)
9073         CF_GNU_SOURCE($cf_XOPEN_SOURCE)
9074         ;;
9075 (minix*)
9076         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
9077         ;;
9078 (mirbsd*)
9079         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
9080         cf_XOPEN_SOURCE=
9081         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
9082         ;;
9083 (netbsd*)
9084         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
9085         ;;
9086 (openbsd[[4-9]]*)
9087         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
9088         cf_xopen_source="-D_BSD_SOURCE"
9089         cf_XOPEN_SOURCE=600
9090         ;;
9091 (openbsd*)
9092         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
9093         ;;
9094 (osf[[45]]*)
9095         cf_xopen_source="-D_OSF_SOURCE"
9096         ;;
9097 (nto-qnx*)
9098         cf_xopen_source="-D_QNX_SOURCE"
9099         ;;
9100 (sco*)
9101         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
9102         ;;
9103 (solaris2.*)
9104         cf_xopen_source="-D__EXTENSIONS__"
9105         cf_cv_xopen_source=broken
9106         ;;
9107 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
9108         cf_XOPEN_SOURCE=
9109         cf_POSIX_C_SOURCE=
9110         ;;
9111 (*)
9112         CF_TRY_XOPEN_SOURCE
9113         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
9114         ;;
9115 esac
9116
9117 if test -n "$cf_xopen_source" ; then
9118         CF_ADD_CFLAGS($cf_xopen_source,true)
9119 fi
9120
9121 dnl In anything but the default case, we may have system-specific setting
9122 dnl which is still not guaranteed to provide all of the entrypoints that
9123 dnl _XOPEN_SOURCE would yield.
9124 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
9125         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
9126         AC_TRY_COMPILE([#include <stdlib.h>],[
9127 #ifndef _XOPEN_SOURCE
9128 make an error
9129 #endif],
9130         [cf_XOPEN_SOURCE_set=yes],
9131         [cf_XOPEN_SOURCE_set=no])
9132         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
9133         if test $cf_XOPEN_SOURCE_set = yes
9134         then
9135                 AC_TRY_COMPILE([#include <stdlib.h>],[
9136 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
9137 make an error
9138 #endif],
9139                 [cf_XOPEN_SOURCE_set_ok=yes],
9140                 [cf_XOPEN_SOURCE_set_ok=no])
9141                 if test $cf_XOPEN_SOURCE_set_ok = no
9142                 then
9143                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
9144                 fi
9145         else
9146                 CF_TRY_XOPEN_SOURCE
9147         fi
9148 fi
9149 fi # cf_cv_posix_visible
9150 ])