aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2018,2019 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.862 2019/03/30 21:53:01 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See https://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 4 updated: 2015/04/18 08:56:57
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54         [AC_TRY_LINK([#include <langinfo.h>],
  55         [char* cs = nl_langinfo(CODESET);],
  56         am_cv_langinfo_codeset=yes,
  57         am_cv_langinfo_codeset=no)
  58         ])
  59         if test $am_cv_langinfo_codeset = yes; then
  60                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62         fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ABI_DEFAULTS version: 2 updated: 2015/06/06 13:49:58
  66 dnl ---------------
  67 dnl Provide configure-script defaults for different ncurses ABIs.
  68 AC_DEFUN([CF_ABI_DEFAULTS],[
  69 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
  70 case x$cf_cv_abi_version in
  71 (x[[6789]])
  72         cf_dft_ext_colors=yes
  73         cf_dft_ext_const=yes
  74         cf_dft_ext_mouse=yes
  75         cf_dft_ext_putwin=yes
  76         cf_dft_ext_spfuncs=yes
  77         cf_dft_filter_syms=yes
  78         cf_dft_chtype=uint32_t
  79         cf_dft_mmask_t=uint32_t
  80         cf_dft_interop=yes
  81         cf_dft_tparm_arg=intptr_t
  82         cf_dft_with_lp64=yes
  83         ;;
  84 (*)
  85         cf_dft_ext_colors=no
  86         cf_dft_ext_const=no
  87         cf_dft_ext_mouse=no
  88         cf_dft_ext_putwin=no
  89         cf_dft_ext_spfuncs=no
  90         cf_dft_filter_syms=no
  91         cf_dft_chtype=auto
  92         cf_dft_mmask_t=auto
  93         cf_dft_interop=no
  94         cf_dft_tparm_arg=long
  95         cf_dft_with_lp64=no
  96         ;;
  97 esac
  98 ])dnl
  99 dnl ---------------------------------------------------------------------------
 100 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
 101 dnl ------------------
 102 dnl Conditionally generate script according to whether we're using a given autoconf.
 103 dnl
 104 dnl $1 = version to compare against
 105 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
 106 dnl $3 = code to use if AC_ACVERSION is older than $1.
 107 define([CF_ACVERSION_CHECK],
 108 [
 109 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
 110 ifdef([m4_version_compare],
 111 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
 112 [CF_ACVERSION_COMPARE(
 113 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
 114 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
 115 dnl ---------------------------------------------------------------------------
 116 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
 117 dnl --------------------
 118 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
 119 dnl                      MAJOR2, MINOR2, TERNARY2,
 120 dnl                      PRINTABLE2, not FOUND, FOUND)
 121 define([CF_ACVERSION_COMPARE],
 122 [ifelse(builtin([eval], [$2 < $5]), 1,
 123 [ifelse([$8], , ,[$8])],
 124 [ifelse([$9], , ,[$9])])])dnl
 125 dnl ---------------------------------------------------------------------------
 126 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
 127 dnl -------------------
 128 dnl Construct the list of include-options for the C programs in the Ada95
 129 dnl binding.
 130 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
 131 [
 132 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
 133 if test "$srcdir" != "."; then
 134         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 135 fi
 136 if test "$GCC" != yes; then
 137         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 138 elif test "$includedir" != "/usr/include"; then
 139         if test "$includedir" = '${prefix}/include' ; then
 140                 if test x$prefix != x/usr ; then
 141                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 142                 fi
 143         else
 144                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 145         fi
 146 fi
 147 AC_SUBST(ACPPFLAGS)
 148 ])dnl
 149 dnl ---------------------------------------------------------------------------
 150 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 151 dnl ---------------
 152 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 153 AC_DEFUN([CF_ADD_ADAFLAGS],[
 154         ADAFLAGS="$ADAFLAGS $1"
 155         AC_SUBST(ADAFLAGS)
 156 ])dnl
 157 dnl ---------------------------------------------------------------------------
 158 dnl CF_ADD_CFLAGS version: 13 updated: 2017/02/25 18:57:40
 159 dnl -------------
 160 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 161 dnl The second parameter if given makes this macro verbose.
 162 dnl
 163 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 164 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 165 dnl confused by the quotes (which require backslashes to keep them usable).
 166 AC_DEFUN([CF_ADD_CFLAGS],
 167 [
 168 cf_fix_cppflags=no
 169 cf_new_cflags=
 170 cf_new_cppflags=
 171 cf_new_extra_cppflags=
 172
 173 for cf_add_cflags in $1
 174 do
 175 case $cf_fix_cppflags in
 176 (no)
 177         case $cf_add_cflags in
 178         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 179                 case $cf_add_cflags in
 180                 (-D*)
 181                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 182
 183                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 184                                 && test -z "${cf_tst_cflags}" \
 185                                 && cf_fix_cppflags=yes
 186
 187                         if test $cf_fix_cppflags = yes ; then
 188                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 189                                 continue
 190                         elif test "${cf_tst_cflags}" = "\"'" ; then
 191                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 192                                 continue
 193                         fi
 194                         ;;
 195                 esac
 196                 case "$CPPFLAGS" in
 197                 (*$cf_add_cflags)
 198                         ;;
 199                 (*)
 200                         case $cf_add_cflags in
 201                         (-D*)
 202                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 203                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 204                                 ;;
 205                         esac
 206                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 207                         ;;
 208                 esac
 209                 ;;
 210         (*)
 211                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 212                 ;;
 213         esac
 214         ;;
 215 (yes)
 216         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 217
 218         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 219
 220         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 221                 && test -z "${cf_tst_cflags}" \
 222                 && cf_fix_cppflags=no
 223         ;;
 224 esac
 225 done
 226
 227 if test -n "$cf_new_cflags" ; then
 228         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 229         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 230 fi
 231
 232 if test -n "$cf_new_cppflags" ; then
 233         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 234         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 235 fi
 236
 237 if test -n "$cf_new_extra_cppflags" ; then
 238         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 239         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 240 fi
 241
 242 AC_SUBST(EXTRA_CPPFLAGS)
 243
 244 ])dnl
 245 dnl ---------------------------------------------------------------------------
 246 dnl CF_ADD_INCDIR version: 15 updated: 2018/06/20 20:23:13
 247 dnl -------------
 248 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 249 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 250 dnl but old versions (and some misinstalled ones) need that.  To make things
 251 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 252 dnl the include-path).
 253 AC_DEFUN([CF_ADD_INCDIR],
 254 [
 255 if test -n "$1" ; then
 256   for cf_add_incdir in $1
 257   do
 258         while test $cf_add_incdir != /usr/include
 259         do
 260           if test -d $cf_add_incdir
 261           then
 262                 cf_have_incdir=no
 263                 if test -n "$CFLAGS$CPPFLAGS" ; then
 264                   # a loop is needed to ensure we can add subdirs of existing dirs
 265                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 266                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 267                           cf_have_incdir=yes; break
 268                         fi
 269                   done
 270                 fi
 271
 272                 if test "$cf_have_incdir" = no ; then
 273                   if test "$cf_add_incdir" = /usr/local/include ; then
 274                         if test "$GCC" = yes
 275                         then
 276                           cf_save_CPPFLAGS=$CPPFLAGS
 277                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
 278                           AC_TRY_COMPILE([#include <stdio.h>],
 279                                   [printf("Hello")],
 280                                   [],
 281                                   [cf_have_incdir=yes])
 282                           CPPFLAGS=$cf_save_CPPFLAGS
 283                         fi
 284                   fi
 285                 fi
 286
 287                 if test "$cf_have_incdir" = no ; then
 288                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 289                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 290
 291                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 292                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 293                   cf_add_incdir="$cf_top_incdir"
 294                 else
 295                   break
 296                 fi
 297           else
 298                 break
 299           fi
 300         done
 301   done
 302 fi
 303 ])dnl
 304 dnl ---------------------------------------------------------------------------
 305 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 306 dnl ----------
 307 dnl Add a library, used to enforce consistency.
 308 dnl
 309 dnl $1 = library to add, without the "-l"
 310 dnl $2 = variable to update (default $LIBS)
 311 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 312 dnl ---------------------------------------------------------------------------
 313 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 314 dnl -------------
 315 dnl     Adds to the library-path
 316 dnl
 317 dnl     Some machines have trouble with multiple -L options.
 318 dnl
 319 dnl $1 is the (list of) directory(s) to add
 320 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 321 dnl
 322 AC_DEFUN([CF_ADD_LIBDIR],
 323 [
 324 if test -n "$1" ; then
 325         for cf_add_libdir in $1
 326         do
 327                 if test $cf_add_libdir = /usr/lib ; then
 328                         :
 329                 elif test -d $cf_add_libdir
 330                 then
 331                         cf_have_libdir=no
 332                         if test -n "$LDFLAGS$LIBS" ; then
 333                                 # a loop is needed to ensure we can add subdirs of existing dirs
 334                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 335                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 336                                                 cf_have_libdir=yes; break
 337                                         fi
 338                                 done
 339                         fi
 340                         if test "$cf_have_libdir" = no ; then
 341                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 342                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 343                         fi
 344                 fi
 345         done
 346 fi
 347 ])dnl
 348 dnl ---------------------------------------------------------------------------
 349 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
 350 dnl -----------
 351 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 352 dnl prepended to an existing list, since their dependencies are assumed to
 353 dnl already exist in the list.
 354 dnl
 355 dnl $1 = libraries to add, with the "-l", etc.
 356 dnl $2 = variable to update (default $LIBS)
 357 AC_DEFUN([CF_ADD_LIBS],[
 358 cf_add_libs="$1"
 359 # Filter out duplicates - this happens with badly-designed ".pc" files...
 360 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
 361 do
 362         for cf_add_2lib in $cf_add_libs
 363         do
 364                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
 365                 then
 366                         cf_add_1lib=
 367                         break
 368                 fi
 369         done
 370         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
 371 done
 372 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 373 ])dnl
 374 dnl ---------------------------------------------------------------------------
 375 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 376 dnl ------------------
 377 dnl Append to a search-list for a nonstandard header/lib-file
 378 dnl     $1 = the variable to return as result
 379 dnl     $2 = the package name
 380 dnl     $3 = the subdirectory, e.g., bin, include or lib
 381 dnl $4 = the directory under which we will test for subdirectories
 382 dnl $5 = a directory that we do not want $4 to match
 383 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 384 [
 385 test "x$4" != "x$5" && \
 386 test -d "$4" && \
 387 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 388         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 389         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 390         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 391         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 392         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 393         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 394 }
 395 ])dnl
 396 dnl ---------------------------------------------------------------------------
 397 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 398 dnl --------------
 399 dnl use this macro for appending text without introducing an extra blank at
 400 dnl the beginning
 401 define([CF_APPEND_TEXT],
 402 [
 403         test -n "[$]$1" && $1="[$]$1 "
 404         $1="[$]{$1}$2"
 405 ])dnl
 406 dnl ---------------------------------------------------------------------------
 407 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 408 dnl --------------
 409 dnl Allow user to disable a normally-on option.
 410 AC_DEFUN([CF_ARG_DISABLE],
 411 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 412 dnl ---------------------------------------------------------------------------
 413 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 414 dnl -------------
 415 dnl Allow user to enable a normally-off option.
 416 AC_DEFUN([CF_ARG_ENABLE],
 417 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 418 dnl ---------------------------------------------------------------------------
 419 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 420 dnl -------------
 421 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 422 dnl values.
 423 dnl
 424 dnl Parameters:
 425 dnl $1 = option name
 426 dnl $2 = help-string
 427 dnl $3 = action to perform if option is not default
 428 dnl $4 = action if perform if option is default
 429 dnl $5 = default option value (either 'yes' or 'no')
 430 AC_DEFUN([CF_ARG_OPTION],
 431 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 432         if test "$enableval" != "$5" ; then
 433 ifelse([$3],,[    :]dnl
 434 ,[    $3]) ifelse([$4],,,[
 435         else
 436                 $4])
 437         fi],[enableval=$5 ifelse([$4],,,[
 438         $4
 439 ])dnl
 440 ])])dnl
 441 dnl ---------------------------------------------------------------------------
 442 dnl CF_AR_FLAGS version: 6 updated: 2015/10/10 15:25:05
 443 dnl -----------
 444 dnl Check for suitable "ar" (archiver) options for updating an archive.
 445 dnl
 446 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 447 dnl as well as a workaround for breakage of make's archive rules by the GNU
 448 dnl binutils "ar" program.
 449 AC_DEFUN([CF_AR_FLAGS],[
 450 AC_REQUIRE([CF_PROG_AR])
 451
 452 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 453         cf_cv_ar_flags=unknown
 454         for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 455         do
 456
 457                 # check if $ARFLAGS already contains this choice
 458                 if test "x$ARFLAGS" != "x" ; then
 459                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 460                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 461                                 cf_cv_ar_flags=
 462                                 break
 463                         fi
 464                 fi
 465
 466                 rm -f conftest.$ac_cv_objext
 467                 rm -f conftest.a
 468
 469                 cat >conftest.$ac_ext <<EOF
 470 #line __oline__ "configure"
 471 int     testdata[[3]] = { 123, 456, 789 };
 472 EOF
 473                 if AC_TRY_EVAL(ac_compile) ; then
 474                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 475                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 476                         if test -f conftest.a ; then
 477                                 cf_cv_ar_flags=$cf_ar_flags
 478                                 break
 479                         fi
 480                 else
 481                         CF_VERBOSE(cannot compile test-program)
 482                         break
 483                 fi
 484         done
 485         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 486 ])
 487
 488 if test -n "$ARFLAGS" ; then
 489         if test -n "$cf_cv_ar_flags" ; then
 490                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 491         fi
 492 else
 493         ARFLAGS=$cf_cv_ar_flags
 494 fi
 495
 496 AC_SUBST(ARFLAGS)
 497 ])
 498 dnl ---------------------------------------------------------------------------
 499 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
 500 dnl -----------------
 501 dnl Check if awk can handle big strings using printf.  Some older versions of
 502 dnl awk choke on large strings passed via "%s".
 503 dnl
 504 dnl $1 = desired string size
 505 dnl $2 = variable to set with result
 506 AC_DEFUN([CF_AWK_BIG_PRINTF],
 507 [
 508         case x$AWK in
 509         (x)
 510                 eval $2=no
 511                 ;;
 512         (*)
 513                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 514                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 515                         eval $2=yes
 516                 else
 517                         eval $2=no
 518                 fi
 519                 ;;
 520         esac
 521 ])dnl
 522 dnl ---------------------------------------------------------------------------
 523 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 524 dnl ------------
 525 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 526 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 527 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 528 dnl
 529 dnl Treat the configuration-variable specially here, since we're directly
 530 dnl substituting its value (i.e., 1/0).
 531 dnl
 532 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 533 AC_DEFUN([CF_BOOL_DECL],
 534 [
 535 AC_MSG_CHECKING(if we should include stdbool.h)
 536
 537 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 538         AC_TRY_COMPILE([],[bool foo = false],
 539                 [cf_cv_header_stdbool_h=0],
 540                 [AC_TRY_COMPILE([
 541 #ifndef __BEOS__
 542 #include <stdbool.h>
 543 #endif
 544 ],[bool foo = false],
 545                         [cf_cv_header_stdbool_h=1],
 546                         [cf_cv_header_stdbool_h=0])])])
 547
 548 if test "$cf_cv_header_stdbool_h" = 1
 549 then    AC_MSG_RESULT(yes)
 550 else    AC_MSG_RESULT(no)
 551 fi
 552
 553 AC_MSG_CHECKING([for builtin bool type])
 554
 555 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 556         AC_TRY_COMPILE([
 557 #include <stdio.h>
 558 #include <sys/types.h>
 559 ],[bool x = false],
 560                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 561                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 562         ])
 563
 564 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 565 then    AC_MSG_RESULT(yes)
 566 else    AC_MSG_RESULT(no)
 567 fi
 568 ])dnl
 569 dnl ---------------------------------------------------------------------------
 570 dnl CF_BOOL_SIZE version: 15 updated: 2017/01/21 11:06:25
 571 dnl ------------
 572 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 573 dnl Don't bother looking for bool.h, since it's been deprecated.
 574 dnl
 575 dnl If the current compiler is C rather than C++, we get the bool definition
 576 dnl from <stdbool.h>.
 577 AC_DEFUN([CF_BOOL_SIZE],
 578 [
 579 AC_MSG_CHECKING([for size of bool])
 580 AC_CACHE_VAL(cf_cv_type_of_bool,[
 581         rm -f cf_test.out
 582         AC_TRY_RUN([
 583 #include <stdlib.h>
 584 #include <stdio.h>
 585
 586 #if defined(__cplusplus)
 587
 588 #ifdef HAVE_GXX_BUILTIN_H
 589 #include <g++/builtin.h>
 590 #elif HAVE_GPP_BUILTIN_H
 591 #include <gpp/builtin.h>
 592 #elif HAVE_BUILTIN_H
 593 #include <builtin.h>
 594 #endif
 595
 596 #else
 597
 598 #if $cf_cv_header_stdbool_h
 599 #include <stdbool.h>
 600 #endif
 601
 602 #endif
 603
 604 int main(void)
 605 {
 606         FILE *fp = fopen("cf_test.out", "w");
 607         if (fp != 0) {
 608                 bool x = true;
 609                 if ((bool)(-x) >= 0)
 610                         fputs("unsigned ", fp);
 611                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 612                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 613                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 614                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 615                 fclose(fp);
 616         }
 617         ${cf_cv_main_return:-return}(0);
 618 }
 619                 ],
 620                 [cf_cv_type_of_bool=`cat cf_test.out`
 621                  if test -z "$cf_cv_type_of_bool"; then
 622                    cf_cv_type_of_bool=unknown
 623                  fi],
 624                 [cf_cv_type_of_bool=unknown],
 625                 [cf_cv_type_of_bool=unknown])
 626         ])
 627         rm -f cf_test.out
 628 AC_MSG_RESULT($cf_cv_type_of_bool)
 629 if test "$cf_cv_type_of_bool" = unknown ; then
 630         case .$NCURSES_BOOL in
 631         (.auto|.) NCURSES_BOOL=unsigned;;
 632         esac
 633         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 634         cf_cv_type_of_bool=$NCURSES_BOOL
 635 fi
 636 ])dnl
 637 dnl ---------------------------------------------------------------------------
 638 dnl CF_BUILD_CC version: 8 updated: 2018/01/04 20:31:04
 639 dnl -----------
 640 dnl If we're cross-compiling, allow the user to override the tools and their
 641 dnl options.  The configure script is oriented toward identifying the host
 642 dnl compiler, etc., but we need a build compiler to generate parts of the
 643 dnl source.
 644 dnl
 645 dnl $1 = default for $CPPFLAGS
 646 dnl $2 = default for $LIBS
 647 AC_DEFUN([CF_BUILD_CC],[
 648 CF_ACVERSION_CHECK(2.52,,
 649         [AC_REQUIRE([CF_PROG_EXT])])
 650 if test "$cross_compiling" = yes ; then
 651
 652         # defaults that we might want to override
 653         : ${BUILD_CFLAGS:=''}
 654         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 655         : ${BUILD_LDFLAGS:=''}
 656         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 657         : ${BUILD_EXEEXT:='$x'}
 658         : ${BUILD_OBJEXT:='o'}
 659
 660         AC_ARG_WITH(build-cc,
 661                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 662                 [BUILD_CC="$withval"],
 663                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
 664         AC_MSG_CHECKING(for native build C compiler)
 665         AC_MSG_RESULT($BUILD_CC)
 666
 667         AC_MSG_CHECKING(for native build C preprocessor)
 668         AC_ARG_WITH(build-cpp,
 669                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 670                 [BUILD_CPP="$withval"],
 671                 [BUILD_CPP='${BUILD_CC} -E'])
 672         AC_MSG_RESULT($BUILD_CPP)
 673
 674         AC_MSG_CHECKING(for native build C flags)
 675         AC_ARG_WITH(build-cflags,
 676                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 677                 [BUILD_CFLAGS="$withval"])
 678         AC_MSG_RESULT($BUILD_CFLAGS)
 679
 680         AC_MSG_CHECKING(for native build C preprocessor-flags)
 681         AC_ARG_WITH(build-cppflags,
 682                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 683                 [BUILD_CPPFLAGS="$withval"])
 684         AC_MSG_RESULT($BUILD_CPPFLAGS)
 685
 686         AC_MSG_CHECKING(for native build linker-flags)
 687         AC_ARG_WITH(build-ldflags,
 688                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 689                 [BUILD_LDFLAGS="$withval"])
 690         AC_MSG_RESULT($BUILD_LDFLAGS)
 691
 692         AC_MSG_CHECKING(for native build linker-libraries)
 693         AC_ARG_WITH(build-libs,
 694                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 695                 [BUILD_LIBS="$withval"])
 696         AC_MSG_RESULT($BUILD_LIBS)
 697
 698         # this assumes we're on Unix.
 699         BUILD_EXEEXT=
 700         BUILD_OBJEXT=o
 701
 702         : ${BUILD_CC:='${CC}'}
 703
 704         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 705                 AC_MSG_ERROR([Cross-build requires two compilers.
 706 Use --with-build-cc to specify the native compiler.])
 707         fi
 708
 709 else
 710         : ${BUILD_CC:='${CC}'}
 711         : ${BUILD_CPP:='${CPP}'}
 712         : ${BUILD_CFLAGS:='${CFLAGS}'}
 713         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 714         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 715         : ${BUILD_LIBS:='${LIBS}'}
 716         : ${BUILD_EXEEXT:='$x'}
 717         : ${BUILD_OBJEXT:='o'}
 718 fi
 719
 720 AC_SUBST(BUILD_CC)
 721 AC_SUBST(BUILD_CPP)
 722 AC_SUBST(BUILD_CFLAGS)
 723 AC_SUBST(BUILD_CPPFLAGS)
 724 AC_SUBST(BUILD_LDFLAGS)
 725 AC_SUBST(BUILD_LIBS)
 726 AC_SUBST(BUILD_EXEEXT)
 727 AC_SUBST(BUILD_OBJEXT)
 728 ])dnl
 729 dnl ---------------------------------------------------------------------------
 730 dnl CF_CC_ENV_FLAGS version: 9 updated: 2018/07/29 18:03:26
 731 dnl ---------------
 732 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 733 dnl into CC.  This will not help with broken scripts that wrap the compiler
 734 dnl with options, but eliminates a more common category of user confusion.
 735 dnl
 736 dnl In particular, it addresses the problem of being able to run the C
 737 dnl preprocessor in a consistent manner.
 738 dnl
 739 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 740 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 741 dnl outweighs that limitation.
 742 AC_DEFUN([CF_CC_ENV_FLAGS],
 743 [
 744 # This should have been defined by AC_PROG_CC
 745 : ${CC:=cc}
 746
 747 AC_MSG_CHECKING(\$CFLAGS variable)
 748 case "x$CFLAGS" in
 749 (*-[[IUD]]*)
 750         AC_MSG_RESULT(broken)
 751         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
 752         cf_flags="$CFLAGS"
 753         CFLAGS=
 754         for cf_arg in $cf_flags
 755         do
 756                 CF_ADD_CFLAGS($cf_arg)
 757         done
 758         ;;
 759 (*)
 760         AC_MSG_RESULT(ok)
 761         ;;
 762 esac
 763
 764 AC_MSG_CHECKING(\$CC variable)
 765 case "$CC" in
 766 (*[[\ \ ]]-*)
 767         AC_MSG_RESULT(broken)
 768         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
 769         # humor him...
 770         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 771         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
 772         CC="$cf_prog"
 773         for cf_arg in $cf_flags
 774         do
 775                 case "x$cf_arg" in
 776                 (x-[[IUDfgOW]]*)
 777                         CF_ADD_CFLAGS($cf_arg)
 778                         ;;
 779                 (*)
 780                         CC="$CC $cf_arg"
 781                         ;;
 782                 esac
 783         done
 784         CF_VERBOSE(resulting CC: '$CC')
 785         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 786         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 787         ;;
 788 (*)
 789         AC_MSG_RESULT(ok)
 790         ;;
 791 esac
 792 ])dnl
 793 dnl ---------------------------------------------------------------------------
 794 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
 795 dnl ---------------
 796 dnl Determine the default configuration into which we'll install ncurses.  This
 797 dnl can be overridden by the user's command-line options.  There's two items to
 798 dnl look for:
 799 dnl     1. the prefix (e.g., /usr)
 800 dnl     2. the header files (e.g., /usr/include/ncurses)
 801 dnl We'll look for a previous installation of ncurses and use the same defaults.
 802 dnl
 803 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 804 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 805 dnl programs from a vendor's.
 806 AC_DEFUN([CF_CFG_DEFAULTS],
 807 [
 808 AC_MSG_CHECKING(for prefix)
 809 if test "x$prefix" = "xNONE" ; then
 810         case "$cf_cv_system_name" in
 811                 # non-vendor systems don't have a conflict
 812         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 813                 prefix=/usr
 814                 ;;
 815         (*)     prefix=$ac_default_prefix
 816                 ;;
 817         esac
 818 fi
 819 AC_MSG_RESULT($prefix)
 820
 821 if test "x$prefix" = "xNONE" ; then
 822 AC_MSG_CHECKING(for default include-directory)
 823 test -n "$verbose" && echo 1>&AC_FD_MSG
 824 for cf_symbol in \
 825         $includedir \
 826         $includedir/ncurses \
 827         $prefix/include \
 828         $prefix/include/ncurses \
 829         /usr/local/include \
 830         /usr/local/include/ncurses \
 831         /usr/include \
 832         /usr/include/ncurses
 833 do
 834         cf_dir=`eval echo $cf_symbol`
 835         if test -f $cf_dir/curses.h ; then
 836         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 837                 includedir="$cf_symbol"
 838                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 839                 break
 840         fi
 841         fi
 842         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 843 done
 844 AC_MSG_RESULT($includedir)
 845 fi
 846 ])dnl
 847 dnl ---------------------------------------------------------------------------
 848 dnl CF_CGETENT version: 6 updated: 2017/01/21 11:06:25
 849 dnl ----------
 850 dnl Check if the terminal-capability database functions are available.  If not,
 851 dnl ncurses has a much-reduced version.
 852 AC_DEFUN([CF_CGETENT],[
 853 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 854 AC_TRY_LINK([
 855 #include <stdlib.h>],[
 856         char temp[128];
 857         char *buf = temp;
 858         char *db_array = temp;
 859         cgetent(&buf, &db_array, "vt100");
 860         cgetcap(buf, "tc", '=');
 861         cgetmatch(buf, "tc");
 862         ],
 863         [cf_cv_cgetent=yes],
 864         [cf_cv_cgetent=no])
 865 ])
 866
 867 if test "$cf_cv_cgetent" = yes
 868 then
 869         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 870 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 871 AC_TRY_LINK([
 872 #pragma GCC diagnostic error "-Wincompatible-pointer-types-discards-qualifiers"
 873 #include <stdlib.h>],[
 874         char temp[128];
 875         char *buf = temp;
 876 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 877         const char *db_array = temp;
 878         cgetent(&buf, &db_array, "vt100");
 879 #endif
 880         cgetcap(buf, "tc", '=');
 881         cgetmatch(buf, "tc");
 882         ],
 883         [cf_cv_cgetent_const=yes],
 884         [cf_cv_cgetent_const=no])
 885 ])
 886         if test "$cf_cv_cgetent_const" = yes
 887         then
 888                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 889         fi
 890 fi
 891 ])dnl
 892 dnl ---------------------------------------------------------------------------
 893 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 894 dnl --------------
 895 dnl Check if we're accidentally using a cache from a different machine.
 896 dnl Derive the system name, as a check for reusing the autoconf cache.
 897 dnl
 898 dnl If we've packaged config.guess and config.sub, run that (since it does a
 899 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 900 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 901 dnl which is useful in cross-compiles.
 902 dnl
 903 dnl Note: we would use $ac_config_sub, but that is one of the places where
 904 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 905 AC_DEFUN([CF_CHECK_CACHE],
 906 [
 907 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 908         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 909         system_name="$host_os"
 910 else
 911         system_name="`(uname -s -r) 2>/dev/null`"
 912         if test -z "$system_name" ; then
 913                 system_name="`(hostname) 2>/dev/null`"
 914         fi
 915 fi
 916 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 917 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 918
 919 test -z "$system_name" && system_name="$cf_cv_system_name"
 920 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 921
 922 if test ".$system_name" != ".$cf_cv_system_name" ; then
 923         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 924         AC_MSG_ERROR("Please remove config.cache and try again.")
 925 fi
 926 ])dnl
 927 dnl ---------------------------------------------------------------------------
 928 dnl CF_CHECK_ERRNO version: 12 updated: 2015/04/18 08:56:57
 929 dnl --------------
 930 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 931 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 932 dnl ourselves.
 933 dnl
 934 dnl $1 = the name to check
 935 dnl $2 = the assumed type
 936 AC_DEFUN([CF_CHECK_ERRNO],
 937 [
 938 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 939         AC_TRY_COMPILE([
 940 #ifdef HAVE_STDLIB_H
 941 #include <stdlib.h>
 942 #endif
 943 #include <stdio.h>
 944 #include <sys/types.h>
 945 #include <errno.h> ],
 946         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 947         [cf_cv_dcl_$1=yes],
 948         [cf_cv_dcl_$1=no])
 949 ])
 950
 951 if test "$cf_cv_dcl_$1" = no ; then
 952         CF_UPPER(cf_result,decl_$1)
 953         AC_DEFINE_UNQUOTED($cf_result)
 954 fi
 955
 956 # It's possible (for near-UNIX clones) that the data doesn't exist
 957 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 958 ])dnl
 959 dnl ---------------------------------------------------------------------------
 960 dnl CF_CHECK_EXTERN_DATA version: 4 updated: 2015/04/18 08:56:57
 961 dnl --------------------
 962 dnl Check for existence of external data in the current set of libraries.  If
 963 dnl we can modify it, it's real enough.
 964 dnl $1 = the name to check
 965 dnl $2 = its type
 966 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 967 [
 968 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 969         AC_TRY_LINK([
 970 #undef $1
 971 extern $2 $1;
 972 ],
 973         [$1 = 2],
 974         [cf_cv_have_$1=yes],
 975         [cf_cv_have_$1=no])
 976 ])
 977
 978 if test "$cf_cv_have_$1" = yes ; then
 979         CF_UPPER(cf_result,have_$1)
 980         AC_DEFINE_UNQUOTED($cf_result)
 981 fi
 982
 983 ])dnl
 984 dnl ---------------------------------------------------------------------------
 985 dnl CF_CHECK_GPM_WGETCH version: 3 updated: 2017/01/21 11:06:25
 986 dnl -------------------
 987 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 988 dnl is not "weak" - warn about this because it can create problems linking
 989 dnl applications with ncurses.
 990 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 991 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 992
 993 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 994 cf_cv_check_gpm_wgetch=unknown
 995 if test "$cross_compiling" != yes ; then
 996
 997 cat >conftest.$ac_ext <<CF_EOF
 998 #include <gpm.h>
 999 int main(void)
1000 {
1001         Gpm_Wgetch();
1002         ${cf_cv_main_return:-return}(0);
1003 }
1004 CF_EOF
1005
1006         cf_save_LIBS="$LIBS"
1007         # This only works if we can look at the symbol table.  If a shared
1008         # library is stripped for install, we cannot use that.  So we're forced
1009         # to rely on the static library, noting that some packagers may not
1010         # include it.
1011         LIBS="-static -lgpm -dynamic $LIBS"
1012         if AC_TRY_EVAL(ac_compile) ; then
1013                 if AC_TRY_EVAL(ac_link) ; then
1014                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
1015                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
1016                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
1017                 fi
1018         fi
1019         rm -rf conftest*
1020         LIBS="$cf_save_LIBS"
1021 fi
1022 ])
1023
1024 if test "$cf_cv_check_gpm_wgetch" != yes ; then
1025         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
1026 fi
1027 ])])dnl
1028 dnl ---------------------------------------------------------------------------
1029 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
1030 dnl ------------------------
1031 dnl Show the version of libtool
1032 dnl
1033 dnl Save the version in a cache variable - this is not entirely a good thing,
1034 dnl but the version string from libtool is very ugly, and for bug reports it
1035 dnl might be useful to have the original string.
1036 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
1037 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
1038 then
1039         AC_MSG_CHECKING(version of $LIBTOOL)
1040         CF_LIBTOOL_VERSION
1041         AC_MSG_RESULT($cf_cv_libtool_version)
1042         if test -z "$cf_cv_libtool_version" ; then
1043                 AC_MSG_ERROR(This is not GNU libtool)
1044         fi
1045 else
1046         AC_MSG_ERROR(GNU libtool has not been found)
1047 fi
1048 ])dnl
1049 dnl ---------------------------------------------------------------------------
1050 dnl CF_CHECK_WCHAR_H version: 2 updated: 2017/01/21 11:06:25
1051 dnl ----------------
1052 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
1053 AC_DEFUN([CF_CHECK_WCHAR_H],[
1054 AC_CHECK_HEADERS( \
1055 wchar.h \
1056 wctype.h \
1057 )
1058 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1059 AC_TRY_COMPILE(
1060 [
1061 #include <stdlib.h>
1062 #ifdef HAVE_WCHAR_H
1063 #include <wchar.h>
1064 #endif
1065 #ifdef HAVE_WCTYPE_H
1066 #include <wctype.h>
1067 #endif
1068 ],[
1069         wint_t foo = 0;
1070         int bar = iswpunct(foo)],
1071         [cf_cv_wchar_h_okay=yes],
1072         [cf_cv_wchar_h_okay=no])])
1073
1074 if test $cf_cv_wchar_h_okay = no
1075 then
1076         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1077 fi
1078 ])dnl
1079 dnl ---------------------------------------------------------------------------
1080 dnl CF_CHECK_WCWIDTH_GRAPHICS version: 1 updated: 2015/12/19 17:47:56
1081 dnl -------------------------
1082 dnl Most "modern" terminal emulators are based to some degree on VT100, and
1083 dnl should support line-drawing.  Even with Unicode.  There is a problem.
1084 dnl
1085 dnl While most of the VT100 graphics characters were incorporated into Unicode,
1086 dnl all of those were combined into a page of useful graphics characters.
1087 dnl
1088 dnl So far, so good.
1089 dnl
1090 dnl However, while they are useful, there are other considerations.  CJK
1091 dnl is (because of poor device resolution) often rendered as double-width
1092 dnl characters.  So... for these generally-useful characters, what should
1093 dnl be the width (to make them consistent with adjacent characters)?
1094 dnl
1095 dnl The obvious choice would have been to make this locale-dependent, and use
1096 dnl wcwidth() to tell applications what the actual width is.  That was too
1097 dnl obvious.  Instead, we have a slew of "ambiguous-width" characters.
1098 dnl See for example
1099 dnl             http://www.unicode.org/reports/tr11/tr11-29.html
1100 dnl             http://www.cl.cam.ac.uk/~mgk25/ucs/scw-proposal.html
1101 dnl
1102 dnl The EastAsianWidth-6.2.0.txt file from the Unicode organization lists
1103 dnl more than 22,000 characters, with 1281 of those as ambiguous-width.  For
1104 dnl instance, it lists half (44/96) of the Latin-1 characters as
1105 dnl ambiguous-width.  Also, all of the box-characters at 0x2500 are ambiguous.
1106 dnl
1107 dnl What this means for the implementor is that on some systems wcwidth() can
1108 dnl give bad advice.  On Solaris, some of the ambiguous widths are returned as
1109 dnl 1 (the Latin-1 characters), while others are returned as 2 (line-drawing
1110 dnl characters).  These do not necessarily match the behavior of the terminal
1111 dnl emulator.  xterm, for instance, does an optional startup check to find if
1112 dnl this problem (or similar) exists with the system's locale tables, rejecting
1113 dnl them if they are too unreliable.
1114 AC_DEFUN([CF_CHECK_WCWIDTH_GRAPHICS],[
1115 AC_CACHE_CHECK(if wcwidth agrees graphics are single-width, cf_cv_wcwidth_graphics,[
1116 cat >conftest.in <<CF_EOF
1117 -       VT100 symbols
1118 0x250c  upper left corner
1119 0x2514  lower left corner
1120 0x2510  upper right corner
1121 0x2518  lower right corner
1122 0x251c  tee pointing left
1123 0x2524  tee pointing right
1124 0x2534  tee pointing up
1125 0x252c  tee pointing down
1126 0x2500  horizontal line
1127 0x2502  vertical line
1128 0x253c  large plus or crossover
1129 0x23ba  scan line 1
1130 0x23bd  scan line 9
1131 0x25c6  diamond
1132 0x2592  checker board (stipple)
1133 0x00b0  degree symbol
1134 0x00b1  plus/minus
1135 0x00b7  bullet
1136 -       Teletype 5410v1 symbols
1137 0x2190  arrow pointing left
1138 0x2192  arrow pointing right
1139 0x2193  arrow pointing down
1140 0x2191  arrow pointing up
1141 0x2592  board of squares
1142 0x2603  lantern symbol
1143 0x25ae  solid square block
1144 -       these defaults were invented for ncurses
1145 0x23bb  scan line 3
1146 0x23bc  scan line 7
1147 0x2264  less-than-or-equal-to
1148 0x2265  greater-than-or-equal-to
1149 0x03c0  greek pi
1150 0x2260  not-equal
1151 0x00a3  pound-sterling symbol
1152 -       thick-line-drawing
1153 0x250f  upper left corner
1154 0x2517  lower left corner
1155 0x2513  upper right corner
1156 0x251b  lower right corner
1157 0x2523  tee pointing left
1158 0x252b  tee pointing right
1159 0x253b  tee pointing up
1160 0x2533  tee pointing down
1161 0x2501  horizontal line
1162 0x2503  vertical line
1163 0x254b  large plus or crossover
1164 -       double-line-drawing
1165 0x2554  upper left corner
1166 0x255a  lower left corner
1167 0x2557  upper right corner
1168 0x255d  lower right corner
1169 0x2563  tee pointing left
1170 0x2560  tee pointing right
1171 0x2569  tee pointing up
1172 0x2566  tee pointing down
1173 0x2550  horizontal line
1174 0x2551  vertical line
1175 0x256c  large plus or crossover
1176 CF_EOF
1177 AC_TRY_RUN([
1178 #include <locale.h>
1179 #include <stdio.h>
1180 #include <wchar.h>
1181
1182 #define MY_LEN 80
1183
1184 int
1185 main(void)
1186 {
1187         FILE *fp;
1188         int value;
1189         char buffer[MY_LEN + 1];
1190         char notes[MY_LEN + 1];
1191         int totals = 0;
1192         int passed = 0;
1193
1194         if (setlocale(LC_ALL, "en_US.UTF8") ||
1195                 setlocale(LC_ALL, "en_US.UTF-8") ||
1196                 setlocale(LC_ALL, "en_US.utf8") ||
1197                 setlocale(LC_ALL, "en_US.utf-8")) {
1198                 if ((fp = fopen("conftest.in", "r")) != 0) {
1199                         while (fgets(buffer, MY_LEN, fp) != 0) {
1200                                 if (*buffer == '-') {
1201                                         fprintf(stderr, "\t%s", buffer);
1202                                 } else if (sscanf(buffer, "%x %s", &value, notes) == 2) {
1203                                         ++totals;
1204                                         if (wcwidth(value) == 1)
1205                                                 ++passed;
1206                                         fprintf(stderr, "%d\t%s", wcwidth(value), buffer);
1207                                 } else {
1208                                         fprintf(stderr, "?\t%s", buffer);
1209                                 }
1210                         }
1211                 }
1212         }
1213         fprintf(stderr, "%d/%d passed wcwidth/graphics check\n", passed, totals);
1214         return (totals == passed) ? 0 : 1;
1215 }
1216 ],
1217 [cf_cv_wcwidth_graphics=yes],
1218 [cf_cv_wcwidth_graphics=no],
1219 [cf_cv_wcwidth_graphics=unknown])
1220 ])
1221 ])dnl
1222 dnl ---------------------------------------------------------------------------
1223 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
1224 dnl -----------------
1225 dnl Check if the given compiler is really clang.  clang's C driver defines
1226 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1227 dnl not ignore some gcc options.
1228 dnl
1229 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1230 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1231 dnl the wrappers for gcc and g++ warnings.
1232 dnl
1233 dnl $1 = GCC (default) or GXX
1234 dnl $2 = CLANG_COMPILER (default)
1235 dnl $3 = CFLAGS (default) or CXXFLAGS
1236 AC_DEFUN([CF_CLANG_COMPILER],[
1237 ifelse([$2],,CLANG_COMPILER,[$2])=no
1238
1239 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1240         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1241         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1242         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
1243         AC_TRY_COMPILE([],[
1244 #ifdef __clang__
1245 #else
1246 make an error
1247 #endif
1248 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1249 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
1250 ],[])
1251         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1252         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1253 fi
1254 ])
1255 dnl ---------------------------------------------------------------------------
1256 dnl CF_CPP_PARAM_INIT version: 7 updated: 2017/01/21 11:06:25
1257 dnl -----------------
1258 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1259 dnl is a late feature for the standard and is not in some recent compilers
1260 dnl (1999/9/11).
1261 AC_DEFUN([CF_CPP_PARAM_INIT],
1262 [
1263 if test -n "$CXX"; then
1264 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1265         AC_LANG_SAVE
1266         AC_LANG_CPLUSPLUS
1267         AC_TRY_RUN([
1268 class TEST {
1269 private:
1270         int value;
1271 public:
1272         TEST(int x = 1);
1273         ~TEST();
1274 };
1275
1276 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1277 {
1278         value = x;
1279 }
1280 int main(void) { }
1281 ],
1282         [cf_cv_cpp_param_init=yes],
1283         [cf_cv_cpp_param_init=no],
1284         [cf_cv_cpp_param_init=unknown])
1285         AC_LANG_RESTORE
1286 ])
1287 fi
1288 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1289 ])dnl
1290 dnl ---------------------------------------------------------------------------
1291 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1292 dnl ------------------
1293 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1294 dnl not be supported in g++ before 3.0
1295 AC_DEFUN([CF_CPP_STATIC_CAST],
1296 [
1297 if test -n "$CXX"; then
1298
1299 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1300         AC_LANG_SAVE
1301         AC_LANG_CPLUSPLUS
1302
1303         AC_TRY_COMPILE([
1304 class NCursesPanel
1305 {
1306 public:
1307   NCursesPanel(int nlines,
1308                int ncols,
1309                int begin_y = 0,
1310                int begin_x = 0)
1311   {
1312   }
1313   NCursesPanel();
1314   ~NCursesPanel();
1315 };
1316
1317 template<class T> class NCursesUserPanel : public NCursesPanel
1318 {
1319 public:
1320   NCursesUserPanel (int nlines,
1321                     int ncols,
1322                     int begin_y = 0,
1323                     int begin_x = 0,
1324                     const T* p_UserData = static_cast<T*>(0))
1325     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1326   {
1327   };
1328   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1329   {
1330   };
1331
1332   virtual ~NCursesUserPanel() {};
1333 };
1334 ],[
1335         const char* p_UserData = static_cast<char*>(0)],
1336         [cf_cv_cpp_static_cast=yes],
1337         [cf_cv_cpp_static_cast=no])
1338
1339         AC_LANG_RESTORE
1340 ])
1341
1342 fi
1343
1344 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1345 ])dnl
1346 dnl ---------------------------------------------------------------------------
1347 dnl CF_CXX_AR_FLAGS version: 2 updated: 2015/04/17 21:13:04
1348 dnl ---------------
1349 dnl Setup special archiver flags for given compilers.
1350 AC_DEFUN([CF_CXX_AR_FLAGS],[
1351         CXX_AR='$(AR)'
1352         CXX_ARFLAGS='$(ARFLAGS)'
1353         case $cf_cv_system_name in
1354         (irix*)
1355             if test "$GXX" != yes ; then
1356                 CXX_AR='$(CXX)'
1357                 CXX_ARFLAGS='-ar -o'
1358             fi
1359             ;;
1360         (sco3.2v5*)
1361             CXXLDFLAGS="-u main"
1362             ;;
1363         (solaris2*)
1364             if test "$GXX" != yes ; then
1365                 CXX_AR='$(CXX)'
1366                 CXX_ARFLAGS='-xar -o'
1367             fi
1368             ;;
1369         esac
1370         AC_SUBST(CXXLDFLAGS)
1371         AC_SUBST(CXX_AR)
1372         AC_SUBST(CXX_ARFLAGS)
1373 ])dnl
1374 dnl ---------------------------------------------------------------------------
1375 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1376 dnl -------------------------
1377 dnl For c++, check if iostream uses "std::" namespace.
1378 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1379 AC_CHECK_HEADERS(iostream)
1380 if test x"$ac_cv_header_iostream" = xyes ; then
1381         AC_MSG_CHECKING(if iostream uses std-namespace)
1382         AC_TRY_COMPILE([
1383 #include <iostream>
1384 using std::endl;
1385 using std::cerr;],[
1386 cerr << "testing" << endl;
1387 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1388         AC_MSG_RESULT($cf_iostream_namespace)
1389         if test "$cf_iostream_namespace" = yes ; then
1390                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1391         fi
1392 fi
1393 ])dnl
1394 dnl ---------------------------------------------------------------------------
1395 dnl CF_C_INLINE version: 5 updated: 2015/04/18 08:56:57
1396 dnl -----------
1397 dnl Check if the C compiler supports "inline".
1398 dnl $1 is the name of a shell variable to set if inline is supported
1399 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1400 AC_DEFUN([CF_C_INLINE],[
1401 AC_C_INLINE
1402 $1=
1403 if test "$ac_cv_c_inline" != no ; then
1404         $1=inline
1405         if test "$INTEL_COMPILER" = yes
1406         then
1407                 :
1408         elif test "$CLANG_COMPILER" = yes
1409         then
1410                 :
1411         elif test "$GCC" = yes
1412         then
1413                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1414                 cf_save_CFLAGS=$CFLAGS
1415                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1416                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1417                 [${cf_cv_main_return:-return} foo()],
1418                 [cf_cv_gcc_inline=yes],
1419                 [cf_cv_gcc_inline=no])
1420                 CFLAGS=$cf_save_CFLAGS
1421                 ])
1422                 if test "$cf_cv_gcc_inline" = yes ; then
1423                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1424                 fi
1425         fi
1426 fi
1427 AC_SUBST($1)
1428 ])dnl
1429 dnl ---------------------------------------------------------------------------
1430 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1431 dnl ----------
1432 dnl "dirname" is not portable, so we fake it with a shell script.
1433 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1434 dnl ---------------------------------------------------------------------------
1435 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1436 dnl ---------------
1437 AC_DEFUN([CF_DIRS_TO_MAKE],
1438 [
1439 DIRS_TO_MAKE="lib"
1440 for cf_item in $cf_list_models
1441 do
1442         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1443         for cf_item2 in $DIRS_TO_MAKE
1444         do
1445                 test $cf_item2 = $cf_subdir && break
1446         done
1447         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1448 done
1449 for cf_dir in $DIRS_TO_MAKE
1450 do
1451         test ! -d $cf_dir && mkdir $cf_dir
1452 done
1453 AC_SUBST(DIRS_TO_MAKE)
1454 ])dnl
1455 dnl ---------------------------------------------------------------------------
1456 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1457 dnl ---------------
1458 dnl You can always use "make -n" to see the actual options, but it's hard to
1459 dnl pick out/analyze warning messages when the compile-line is long.
1460 dnl
1461 dnl Sets:
1462 dnl     ECHO_LT - symbol to control if libtool is verbose
1463 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1464 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1465 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1466 dnl     ECHO_CC - symbol to put before any "cc" line
1467 dnl
1468 AC_DEFUN([CF_DISABLE_ECHO],[
1469 AC_MSG_CHECKING(if you want to see long compiling messages)
1470 CF_ARG_DISABLE(echo,
1471         [  --disable-echo          do not display "compiling" commands],
1472         [
1473         ECHO_LT='--silent'
1474         ECHO_LD='@echo linking [$]@;'
1475         RULE_CC='@echo compiling [$]<'
1476         SHOW_CC='@echo compiling [$]@'
1477         ECHO_CC='@'
1478 ],[
1479         ECHO_LT=''
1480         ECHO_LD=''
1481         RULE_CC=''
1482         SHOW_CC=''
1483         ECHO_CC=''
1484 ])
1485 AC_MSG_RESULT($enableval)
1486 AC_SUBST(ECHO_LT)
1487 AC_SUBST(ECHO_LD)
1488 AC_SUBST(RULE_CC)
1489 AC_SUBST(SHOW_CC)
1490 AC_SUBST(ECHO_CC)
1491 ])dnl
1492 dnl ---------------------------------------------------------------------------
1493 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1494 dnl ------------------------
1495 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1496 AC_MSG_CHECKING(if we want to use GNAT projects)
1497 CF_ARG_DISABLE(gnat-projects,
1498         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1499         [enable_gnat_projects=no],
1500         [enable_gnat_projects=yes])
1501 AC_MSG_RESULT($enable_gnat_projects)
1502 ])dnl
1503 dnl ---------------------------------------------------------------------------
1504 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1505 dnl ----------------
1506 dnl Combine no-leak checks with the libraries or tools that are used for the
1507 dnl checks.
1508 AC_DEFUN([CF_DISABLE_LEAKS],[
1509
1510 AC_REQUIRE([CF_WITH_DMALLOC])
1511 AC_REQUIRE([CF_WITH_DBMALLOC])
1512 AC_REQUIRE([CF_WITH_VALGRIND])
1513
1514 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1515 AC_ARG_ENABLE(leaks,
1516         [  --disable-leaks         test: free permanent memory, analyze leaks],
1517         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1518         : ${with_no_leaks:=no})
1519 AC_MSG_RESULT($with_no_leaks)
1520
1521 if test "$with_no_leaks" = yes ; then
1522         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1523         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1524 fi
1525 ])dnl
1526 dnl ---------------------------------------------------------------------------
1527 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
1528 dnl --------------------------
1529 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1530 dnl the older "-version-info" feature.  The newer feature allows us to use
1531 dnl version numbering on shared libraries which make them compatible with
1532 dnl various systems.
1533 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1534 [
1535 AC_MSG_CHECKING(if libtool -version-number should be used)
1536 CF_ARG_DISABLE(libtool-version,
1537         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1538         [cf_libtool_version=no],
1539         [cf_libtool_version=yes])
1540 AC_MSG_RESULT($cf_libtool_version)
1541
1542 if test "$cf_libtool_version" = yes ; then
1543         LIBTOOL_VERSION="-version-number"
1544 else
1545         LIBTOOL_VERSION="-version-info"
1546         case "x$VERSION" in
1547         (x)
1548                 AC_MSG_WARN(VERSION was not set)
1549                 ;;
1550         (x*.*.*)
1551                 ABI_VERSION="$VERSION"
1552                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1553                 ;;
1554         (x*:*:*)
1555                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
1556                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1557                 ;;
1558         (*)
1559                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
1560                 ;;
1561         esac
1562 fi
1563
1564 AC_SUBST(ABI_VERSION)
1565 AC_SUBST(LIBTOOL_VERSION)
1566 ])dnl
1567 dnl ---------------------------------------------------------------------------
1568 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1569 dnl ---------------------
1570 dnl The rpath-hack makes it simpler to build programs, particularly with the
1571 dnl *BSD ports which may have essential libraries in unusual places.  But it
1572 dnl can interfere with building an executable for the base system.  Use this
1573 dnl option in that case.
1574 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1575 [
1576 AC_MSG_CHECKING(if rpath-hack should be disabled)
1577 CF_ARG_DISABLE(rpath-hack,
1578         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1579         [cf_disable_rpath_hack=yes],
1580         [cf_disable_rpath_hack=no])
1581 AC_MSG_RESULT($cf_disable_rpath_hack)
1582 if test "$cf_disable_rpath_hack" = no ; then
1583         CF_RPATH_HACK
1584 fi
1585 ])
1586 dnl ---------------------------------------------------------------------------
1587 dnl CF_ENABLE_PC_FILES version: 13 updated: 2015/11/01 05:27:39
1588 dnl ------------------
1589 dnl This is the "--enable-pc-files" option, which is available if there is a
1590 dnl pkg-config configuration on the local machine.
1591 AC_DEFUN([CF_ENABLE_PC_FILES],[
1592 AC_REQUIRE([CF_PKG_CONFIG])
1593 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1594
1595 if test "x$PKG_CONFIG" != xnone
1596 then
1597         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1598 else
1599         AC_MSG_CHECKING(if we should install .pc files)
1600 fi
1601
1602 AC_ARG_ENABLE(pc-files,
1603         [  --enable-pc-files       generate and install .pc files for pkg-config],
1604         [enable_pc_files=$enableval],
1605         [enable_pc_files=no])
1606 AC_MSG_RESULT($enable_pc_files)
1607
1608 if test "x$enable_pc_files" != xno
1609 then
1610         MAKE_PC_FILES=
1611         case "x$PKG_CONFIG_LIBDIR" in
1612         (xno|xyes)
1613                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
1614                 ;;
1615         (*)
1616                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1617                 ;;
1618         esac
1619 else
1620         MAKE_PC_FILES="#"
1621 fi
1622 AC_SUBST(MAKE_PC_FILES)
1623 ])dnl
1624 dnl ---------------------------------------------------------------------------
1625 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1626 dnl ---------------
1627 dnl Check if the rpath option should be used, setting cache variable
1628 dnl cf_cv_enable_rpath if so.
1629 AC_DEFUN([CF_ENABLE_RPATH],
1630 [
1631 AC_MSG_CHECKING(if rpath option should be used)
1632 AC_ARG_ENABLE(rpath,
1633 [  --enable-rpath          use rpath option when generating shared libraries],
1634 [cf_cv_enable_rpath=$enableval],
1635 [cf_cv_enable_rpath=no])
1636 AC_MSG_RESULT($cf_cv_enable_rpath)
1637 ])dnl
1638 dnl ---------------------------------------------------------------------------
1639 dnl CF_ENABLE_STRING_HACKS version: 5 updated: 2016/10/08 17:34:11
1640 dnl ----------------------
1641 dnl On a few platforms, the compiler and/or loader nags with untruthful
1642 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1643 dnl and implying that most uses of the recommended alternatives are correct.
1644 dnl
1645 dnl Factually speaking, no one has actually counted the number of uses of these
1646 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1647 dnl instances are meaningless compared to the hundreds of millions of lines of
1648 dnl existing C code.
1649 dnl
1650 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1651 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1652 dnl standard - but evolved through phases, and older implementations are likely
1653 dnl to yield surprising results, as documented in manpages on various systems.
1654 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1655 [
1656 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1657 AC_ARG_ENABLE(string-hacks,
1658         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1659         [with_string_hacks=$enableval],
1660         [with_string_hacks=no])
1661 AC_MSG_RESULT($with_string_hacks)
1662
1663 if test "x$with_string_hacks" = "xyes"; then
1664         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1665         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1666         AC_CHECK_FUNC(strlcat,[
1667                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1668                 ],[
1669                 AC_CHECK_LIB(bsd,strlcat,[
1670                         CF_ADD_LIB(bsd)
1671                         AC_CHECK_HEADERS(bsd/string.h)
1672                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1673                         ])
1674                 ])
1675         AC_CHECK_FUNCS( strlcpy snprintf )
1676 fi
1677 ])dnl
1678 dnl ---------------------------------------------------------------------------
1679 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1680 dnl --------
1681 dnl Check if 'errno' is declared in <errno.h>
1682 AC_DEFUN([CF_ERRNO],
1683 [
1684 CF_CHECK_ERRNO(errno)
1685 ])dnl
1686 dnl ---------------------------------------------------------------------------
1687 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1688 dnl ---------------
1689 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1690 dnl math.h and builtin.h, only for ncurses
1691 AC_DEFUN([CF_ETIP_DEFINES],
1692 [
1693 AC_MSG_CHECKING(for special defines needed for etip.h)
1694 cf_save_CXXFLAGS="$CXXFLAGS"
1695 cf_result="none"
1696
1697 # etip.h includes ncurses.h which includes ncurses_dll.h
1698 # But ncurses_dll.h is generated - fix here.
1699 test -d include || mkdir include
1700 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1701
1702 for cf_math in "" MATH_H
1703 do
1704 for cf_excp in "" MATH_EXCEPTION
1705 do
1706         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1707         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1708         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1709 AC_TRY_COMPILE([
1710 #include <etip.h.in>
1711 ],[],[
1712         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1713         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1714         cf_result="$cf_math $cf_excp"
1715         break 2
1716 ],[])
1717 done
1718 done
1719 AC_MSG_RESULT($cf_result)
1720 CXXFLAGS="$cf_save_CXXFLAGS"
1721 ])
1722 dnl ---------------------------------------------------------------------------
1723 dnl CF_FIND_LINKAGE version: 21 updated: 2018/06/20 20:23:13
1724 dnl ---------------
1725 dnl Find a library (specifically the linkage used in the code fragment),
1726 dnl searching for it if it is not already in the library path.
1727 dnl See also CF_ADD_SEARCHPATH.
1728 dnl
1729 dnl Parameters (4-on are optional):
1730 dnl     $1 = headers for library entrypoint
1731 dnl     $2 = code fragment for library entrypoint
1732 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1733 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1734 dnl     $5 = action to perform if not successful
1735 dnl     $6 = module name, if not the same as the library name
1736 dnl     $7 = extra libraries
1737 dnl
1738 dnl Sets these variables:
1739 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1740 dnl     $cf_cv_header_path_$3 - include-directory if needed
1741 dnl     $cf_cv_library_path_$3 - library-directory if needed
1742 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1743 AC_DEFUN([CF_FIND_LINKAGE],[
1744
1745 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1746 # will be set on completion of the AC_TRY_LINK below.
1747 cf_cv_header_path_$3=
1748 cf_cv_library_path_$3=
1749
1750 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1751
1752 cf_save_LIBS="$LIBS"
1753
1754 AC_TRY_LINK([$1],[$2],[
1755         cf_cv_find_linkage_$3=yes
1756         cf_cv_header_path_$3=/usr/include
1757         cf_cv_library_path_$3=/usr/lib
1758 ],[
1759
1760 LIBS="-l$3 $7 $cf_save_LIBS"
1761
1762 AC_TRY_LINK([$1],[$2],[
1763         cf_cv_find_linkage_$3=yes
1764         cf_cv_header_path_$3=/usr/include
1765         cf_cv_library_path_$3=/usr/lib
1766         cf_cv_library_file_$3="-l$3"
1767 ],[
1768         cf_cv_find_linkage_$3=no
1769         LIBS="$cf_save_LIBS"
1770
1771         CF_VERBOSE(find linkage for $3 library)
1772         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1773
1774         cf_save_CPPFLAGS="$CPPFLAGS"
1775         cf_test_CPPFLAGS="$CPPFLAGS"
1776
1777         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1778         for cf_cv_header_path_$3 in $cf_search
1779         do
1780                 if test -d $cf_cv_header_path_$3 ; then
1781                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1782                         CPPFLAGS="$cf_save_CPPFLAGS"
1783                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
1784                         AC_TRY_COMPILE([$1],[$2],[
1785                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1786                                 cf_cv_find_linkage_$3=maybe
1787                                 cf_test_CPPFLAGS="$CPPFLAGS"
1788                                 break],[
1789                                 CPPFLAGS="$cf_save_CPPFLAGS"
1790                                 ])
1791                 fi
1792         done
1793
1794         if test "$cf_cv_find_linkage_$3" = maybe ; then
1795
1796                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1797
1798                 cf_save_LIBS="$LIBS"
1799                 cf_save_LDFLAGS="$LDFLAGS"
1800
1801                 ifelse([$6],,,[
1802                 CPPFLAGS="$cf_test_CPPFLAGS"
1803                 LIBS="-l$3 $7 $cf_save_LIBS"
1804                 AC_TRY_LINK([$1],[$2],[
1805                         CF_VERBOSE(... found $3 library in system)
1806                         cf_cv_find_linkage_$3=yes])
1807                         CPPFLAGS="$cf_save_CPPFLAGS"
1808                         LIBS="$cf_save_LIBS"
1809                         ])
1810
1811                 if test "$cf_cv_find_linkage_$3" != yes ; then
1812                         CF_LIBRARY_PATH(cf_search,$3)
1813                         for cf_cv_library_path_$3 in $cf_search
1814                         do
1815                                 if test -d $cf_cv_library_path_$3 ; then
1816                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1817                                         CPPFLAGS="$cf_test_CPPFLAGS"
1818                                         LIBS="-l$3 $7 $cf_save_LIBS"
1819                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1820                                         AC_TRY_LINK([$1],[$2],[
1821                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1822                                         cf_cv_find_linkage_$3=yes
1823                                         cf_cv_library_file_$3="-l$3"
1824                                         break],[
1825                                         CPPFLAGS="$cf_save_CPPFLAGS"
1826                                         LIBS="$cf_save_LIBS"
1827                                         LDFLAGS="$cf_save_LDFLAGS"
1828                                         ])
1829                                 fi
1830                         done
1831                         CPPFLAGS="$cf_save_CPPFLAGS"
1832                         LDFLAGS="$cf_save_LDFLAGS"
1833                 fi
1834
1835         else
1836                 cf_cv_find_linkage_$3=no
1837         fi
1838         ],$7)
1839 ])
1840
1841 LIBS="$cf_save_LIBS"
1842
1843 if test "$cf_cv_find_linkage_$3" = yes ; then
1844 ifelse([$4],,[
1845         CF_ADD_INCDIR($cf_cv_header_path_$3)
1846         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1847         CF_ADD_LIB($3)
1848 ],[$4])
1849 else
1850 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1851 fi
1852 ])dnl
1853 dnl ---------------------------------------------------------------------------
1854 dnl CF_FIND_SUB_INCDIR version: 2 updated: 2015/04/17 21:13:04
1855 dnl ------------------
1856 dnl Find an include-directory with the given leaf-name.  This is useful for
1857 dnl example with FreeBSD ports, which use this convention to distinguish
1858 dnl different versions of the same port.
1859 AC_DEFUN([CF_FIND_SUB_INCDIR],[
1860         CF_SUBDIR_PATH(cf_search,$1,include)
1861         for cf_item in $cf_search
1862         do
1863                 case $cf_item in
1864                 (*/$1)
1865                         CF_ADD_INCDIR($cf_item)
1866                         ;;
1867                 esac
1868         done
1869 ])dnl
1870 dnl ---------------------------------------------------------------------------
1871 dnl CF_FIND_SUB_LIBDIR version: 2 updated: 2015/04/17 21:13:04
1872 dnl ------------------
1873 dnl Find a library-directory with the given leaf-name.  This is useful for
1874 dnl example with FreeBSD ports, which use this convention to distinguish
1875 dnl different versions of the same port.
1876 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
1877         CF_SUBDIR_PATH(cf_search,$1,lib)
1878         for cf_item in $cf_search
1879         do
1880                 case $cf_item in
1881                 (*/$1)
1882                         CF_ADD_LIBDIR($cf_item)
1883                         ;;
1884                 esac
1885         done
1886 ])dnl
1887 dnl ---------------------------------------------------------------------------
1888 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
1889 dnl -----------------
1890 dnl make ADAFLAGS consistent with CFLAGS
1891 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1892         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1893         case "$CFLAGS" in
1894         (*-g*)
1895                 CF_ADD_ADAFLAGS(-g)
1896                 ;;
1897         esac
1898         case "$CFLAGS" in
1899         (*-O*)
1900                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1901                 CF_ADD_ADAFLAGS($cf_O_flag)
1902                 ;;
1903         esac
1904         AC_MSG_RESULT($ADAFLAGS)
1905 ])dnl
1906 dnl ---------------------------------------------------------------------------
1907 dnl CF_FOPEN_BIN_R version: 1 updated: 2019/03/30 17:52:21
1908 dnl --------------
1909 dnl Check if fopen works when the "b" (binary) flag is added to the mode
1910 dnl parameter.  POSIX ignores the "b", which c89 specified.  Some very old
1911 dnl systems do not accept it.
1912 AC_DEFUN([CF_FOPEN_BIN_R],[
1913 AC_CACHE_CHECK(if fopen accepts explicit binary mode,cf_cv_fopen_bin_r,[
1914         AC_TRY_RUN([
1915 #include <stdio.h>
1916 int main(void) {
1917         FILE *fp = fopen("conftest.tmp", "wb");
1918         int rc = 0;
1919         if (fp != 0) {
1920                 int p, q;
1921                 for (p = 0; p < 256; ++p) {
1922                         fputc(p, fp);
1923                 }
1924                 fclose(fp);
1925                 fp = fopen("conftest.tmp", "rb");
1926                 if (fp != 0) {
1927                         for (p = 0; p < 256; ++p) {
1928                                 q = fgetc(fp);
1929                                 if (q != p) {
1930                                         rc = 1;
1931                                         break;
1932                                 }
1933                         }
1934                 } else {
1935                         rc = 1;
1936                 }
1937         } else {
1938                 rc = 1;
1939         }
1940         ${cf_cv_main_return:-return} (rc);
1941 }
1942 ],
1943                 [cf_cv_fopen_bin_r=yes],
1944                 [cf_cv_fopen_bin_r=no],
1945                 [cf_cv_fopen_bin_r=unknown])
1946 ])
1947 test "x$cf_cv_fopen_bin_r" != xno && AC_DEFINE(USE_FOPEN_BIN_R)
1948 ])dnl
1949 dnl ---------------------------------------------------------------------------
1950 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
1951 dnl --------------
1952 dnl Forget that we saw the given tool.
1953 AC_DEFUN([CF_FORGET_TOOL],[
1954 unset ac_cv_prog_ac_ct_$1
1955 unset ac_ct_$1
1956 unset $1
1957 ])dnl
1958 dnl ---------------------------------------------------------------------------
1959 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
1960 dnl -------------
1961 dnl Test for dlsym() and related functions, as well as libdl.
1962 dnl
1963 dnl Sets
1964 dnl     $cf_have_dlsym
1965 dnl     $cf_have_libdl
1966 AC_DEFUN([CF_FUNC_DLSYM],[
1967 cf_have_dlsym=no
1968 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1969
1970 cf_have_libdl=no
1971 AC_CHECK_LIB(dl,dlsym,[
1972         cf_have_dlsym=yes
1973         cf_have_libdl=yes])])
1974
1975 if test "$cf_have_dlsym" = yes ; then
1976         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
1977
1978         AC_MSG_CHECKING(whether able to link to dl*() functions)
1979         AC_TRY_LINK([#include <dlfcn.h>],[
1980                 void *obj;
1981                 if ((obj = dlopen("filename", 0)) != 0) {
1982                         if (dlsym(obj, "symbolname") == 0) {
1983                         dlclose(obj);
1984                         }
1985                 }],[
1986                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
1987                 AC_MSG_ERROR(Cannot link test program for libdl)])
1988         AC_MSG_RESULT(ok)
1989 else
1990         AC_MSG_ERROR(Cannot find dlsym function)
1991 fi
1992 ])
1993 dnl ---------------------------------------------------------------------------
1994 dnl CF_FUNC_MEMMOVE version: 9 updated: 2017/01/21 11:06:25
1995 dnl ---------------
1996 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1997 dnl is found, add our own version of memmove to the list of objects.
1998 AC_DEFUN([CF_FUNC_MEMMOVE],
1999 [
2000 AC_CHECK_FUNC(memmove,,[
2001 AC_CHECK_FUNC(bcopy,[
2002         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
2003                 AC_TRY_RUN([
2004 int main(void) {
2005         static char data[] = "abcdefghijklmnopqrstuwwxyz";
2006         char temp[40];
2007         bcopy(data, temp, sizeof(data));
2008         bcopy(temp+10, temp, 15);
2009         bcopy(temp+5, temp+15, 10);
2010         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
2011 }
2012                 ],
2013                 [cf_cv_good_bcopy=yes],
2014                 [cf_cv_good_bcopy=no],
2015                 [cf_cv_good_bcopy=unknown])
2016                 ])
2017         ],[cf_cv_good_bcopy=no])
2018         if test "$cf_cv_good_bcopy" = yes ; then
2019                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
2020         else
2021                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
2022         fi
2023 ])])dnl
2024 dnl ---------------------------------------------------------------------------
2025 dnl CF_FUNC_NANOSLEEP version: 5 updated: 2017/01/21 11:06:25
2026 dnl -----------------
2027 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
2028 dnl AIX 4.x, provide a non-working version.
2029 AC_DEFUN([CF_FUNC_NANOSLEEP],[
2030 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
2031 AC_TRY_RUN([
2032 #include <stdio.h>
2033 #include <errno.h>
2034 #include <time.h>
2035
2036 #ifdef HAVE_SYS_TIME_H
2037 #include <sys/time.h>
2038 #endif
2039
2040 int main(void) {
2041         struct timespec ts1, ts2;
2042         int code;
2043         ts1.tv_sec  = 0;
2044         ts1.tv_nsec = 750000000;
2045         ts2.tv_sec  = 0;
2046         ts2.tv_nsec = 0;
2047         errno = 0;
2048         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
2049         ${cf_cv_main_return:-return}(code != 0);
2050 }
2051 ],
2052         [cf_cv_func_nanosleep=yes],
2053         [cf_cv_func_nanosleep=no],
2054         [cf_cv_func_nanosleep=unknown])])
2055
2056 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
2057 ])
2058 dnl ---------------------------------------------------------------------------
2059 dnl CF_FUNC_OPENPTY version: 5 updated: 2015/09/12 14:46:50
2060 dnl ---------------
2061 dnl Check for openpty() function, along with <pty.h> header.  It may need the
2062 dnl "util" library as well.
2063 AC_DEFUN([CF_FUNC_OPENPTY],
2064 [
2065 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
2066 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
2067         cf_save_LIBS="$LIBS"
2068         test $cf_cv_lib_util = yes && { CF_ADD_LIB(util) }
2069         for cf_header in pty.h libutil.h util.h
2070         do
2071         AC_TRY_LINK([
2072 #include <$cf_header>
2073 ],[
2074         int x = openpty((int *)0, (int *)0, (char *)0,
2075                                    (struct termios *)0, (struct winsize *)0);
2076 ],[
2077                 cf_cv_func_openpty=$cf_header
2078                 break
2079 ],[
2080                 cf_cv_func_openpty=no
2081 ])
2082         done
2083         LIBS="$cf_save_LIBS"
2084 ])
2085 ])dnl
2086 dnl ---------------------------------------------------------------------------
2087 dnl CF_FUNC_POLL version: 9 updated: 2015/10/10 13:27:32
2088 dnl ------------
2089 dnl See if the poll function really works.  Some platforms have poll(), but
2090 dnl it does not work for terminals or files.
2091 AC_DEFUN([CF_FUNC_POLL],[
2092 tty 2>&1 >/dev/null || { AC_CHECK_FUNCS(posix_openpt) }
2093 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
2094 AC_TRY_RUN([
2095 #include <stdlib.h>
2096 #include <stdio.h>
2097 #include <unistd.h>
2098 #include <fcntl.h>
2099 #ifdef HAVE_POLL_H
2100 #include <poll.h>
2101 #else
2102 #include <sys/poll.h>
2103 #endif
2104 int main(void) {
2105         struct pollfd myfds;
2106         int ret;
2107
2108         /* check for Darwin bug with respect to "devices" */
2109         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
2110         if (myfds.fd < 0)
2111                 myfds.fd = 0;
2112         myfds.events = POLLIN;
2113         myfds.revents = 0;
2114
2115         ret = poll(&myfds, 1, 100);
2116
2117         if (ret < 0 || (myfds.revents & POLLNVAL)) {
2118                 ret = -1;
2119         } else {
2120                 int fd = 0;
2121                 if (!isatty(fd)) {
2122                         fd = open("/dev/tty", 2);       /* O_RDWR */
2123                 }
2124 #ifdef HAVE_POSIX_OPENPT
2125                 if (fd < 0) {
2126                         fd = posix_openpt(O_RDWR);
2127                 }
2128 #endif
2129
2130                 if (fd >= 0) {
2131                         /* also check with standard input */
2132                         myfds.fd = fd;
2133                         myfds.events = POLLIN;
2134                         myfds.revents = 0;
2135                         ret = poll(&myfds, 1, 100);
2136                 } else {
2137                         ret = -1;
2138                 }
2139         }
2140         ${cf_cv_main_return:-return}(ret < 0);
2141 }],
2142         [cf_cv_working_poll=yes],
2143         [cf_cv_working_poll=no],
2144         [cf_cv_working_poll=unknown])])
2145 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
2146 ])dnl
2147 dnl ---------------------------------------------------------------------------
2148 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
2149 dnl ---------------
2150 dnl Some old/broken variations define tcgetattr() only as a macro in
2151 dnl termio(s).h
2152 AC_DEFUN([CF_FUNC_TERMIOS],[
2153 AC_REQUIRE([CF_STRUCT_TERMIOS])
2154 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
2155 AC_TRY_LINK([
2156 #include <sys/types.h>
2157 #ifdef HAVE_UNISTD_H
2158 #include <unistd.h>
2159 #endif
2160 #ifdef HAVE_TERMIOS_H
2161 #include <termios.h>
2162 #define TTY struct termios
2163 #else
2164 #ifdef HAVE_TERMIO_H
2165 #include <termio.h>
2166 #define TTY struct termio
2167 #endif
2168 #endif
2169 ],[
2170 TTY foo;
2171 tcgetattr(1, &foo);],
2172 [cf_cv_have_tcgetattr=yes],
2173 [cf_cv_have_tcgetattr=no])])
2174 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
2175 ])dnl
2176 dnl ---------------------------------------------------------------------------
2177 dnl CF_FUNC_VSSCANF version: 6 updated: 2015/04/18 08:56:57
2178 dnl ---------------
2179 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
2180 dnl versions of C.  It is in the GNU C library, and can often be simulated by
2181 dnl other functions.
2182 AC_DEFUN([CF_FUNC_VSSCANF],
2183 [
2184 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
2185 AC_TRY_LINK([
2186 #include <stdarg.h>
2187 #include <stdio.h>],[
2188         va_list ap;
2189         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
2190 AC_TRY_LINK([
2191 #include <stdarg.h>
2192 #include <stdio.h>],[
2193         FILE strbuf;
2194         char *str = "from";
2195
2196         strbuf._flag = _IOREAD;
2197         strbuf._ptr = strbuf._base = (unsigned char *) str;
2198         strbuf._cnt = strlen(str);
2199         strbuf._file = _NFILE;
2200         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
2201 AC_TRY_LINK([
2202 #include <stdarg.h>
2203 #include <stdio.h>],[
2204         FILE strbuf;
2205         char *str = "from";
2206
2207         strbuf._flag = _IOREAD;
2208         strbuf._ptr = strbuf._base = (unsigned char *) str;
2209         strbuf._cnt = strlen(str);
2210         strbuf._file = _NFILE;
2211         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
2212 cf_cv_func_vsscanf=no])])])])
2213
2214 case $cf_cv_func_vsscanf in
2215 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
2216 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
2217 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
2218 esac
2219
2220 ])dnl
2221 dnl ---------------------------------------------------------------------------
2222 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
2223 dnl -----------------
2224 dnl Test for availability of useful gcc __attribute__ directives to quiet
2225 dnl compiler warnings.  Though useful, not all are supported -- and contrary
2226 dnl to documentation, unrecognized directives cause older compilers to barf.
2227 AC_DEFUN([CF_GCC_ATTRIBUTES],
2228 [
2229 if test "$GCC" = yes
2230 then
2231 cat > conftest.i <<EOF
2232 #ifndef GCC_PRINTF
2233 #define GCC_PRINTF 0
2234 #endif
2235 #ifndef GCC_SCANF
2236 #define GCC_SCANF 0
2237 #endif
2238 #ifndef GCC_NORETURN
2239 #define GCC_NORETURN /* nothing */
2240 #endif
2241 #ifndef GCC_UNUSED
2242 #define GCC_UNUSED /* nothing */
2243 #endif
2244 EOF
2245 if test "$GCC" = yes
2246 then
2247         AC_CHECKING([for $CC __attribute__ directives])
2248 cat > conftest.$ac_ext <<EOF
2249 #line __oline__ "${as_me:-configure}"
2250 #include "confdefs.h"
2251 #include "conftest.h"
2252 #include "conftest.i"
2253 #if     GCC_PRINTF
2254 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
2255 #else
2256 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
2257 #endif
2258 #if     GCC_SCANF
2259 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2260 #else
2261 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2262 #endif
2263 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2264 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
2265 extern void foo(void) GCC_NORETURN;
2266 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
2267 EOF
2268         cf_printf_attribute=no
2269         cf_scanf_attribute=no
2270         for cf_attribute in scanf printf unused noreturn
2271         do
2272                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2273                 cf_directive="__attribute__(($cf_attribute))"
2274                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2275
2276                 case $cf_attribute in
2277                 (printf)
2278                         cf_printf_attribute=yes
2279                         cat >conftest.h <<EOF
2280 #define GCC_$cf_ATTRIBUTE 1
2281 EOF
2282                         ;;
2283                 (scanf)
2284                         cf_scanf_attribute=yes
2285                         cat >conftest.h <<EOF
2286 #define GCC_$cf_ATTRIBUTE 1
2287 EOF
2288                         ;;
2289                 (*)
2290                         cat >conftest.h <<EOF
2291 #define GCC_$cf_ATTRIBUTE $cf_directive
2292 EOF
2293                         ;;
2294                 esac
2295
2296                 if AC_TRY_EVAL(ac_compile); then
2297                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
2298                         cat conftest.h >>confdefs.h
2299                         case $cf_attribute in
2300                         (noreturn)
2301                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
2302                                 ;;
2303                         (printf)
2304                                 cf_value='/* nothing */'
2305                                 if test "$cf_printf_attribute" != no ; then
2306                                         cf_value='__attribute__((format(printf,fmt,var)))'
2307                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
2308                                 fi
2309                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
2310                                 ;;
2311                         (scanf)
2312                                 cf_value='/* nothing */'
2313                                 if test "$cf_scanf_attribute" != no ; then
2314                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2315                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2316                                 fi
2317                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2318                                 ;;
2319                         (unused)
2320                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2321                                 ;;
2322                         esac
2323                 fi
2324         done
2325 else
2326         fgrep define conftest.i >>confdefs.h
2327 fi
2328 rm -rf conftest*
2329 fi
2330 ])dnl
2331 dnl ---------------------------------------------------------------------------
2332 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
2333 dnl --------------
2334 dnl Find version of gcc
2335 AC_DEFUN([CF_GCC_VERSION],[
2336 AC_REQUIRE([AC_PROG_CC])
2337 GCC_VERSION=none
2338 if test "$GCC" = yes ; then
2339         AC_MSG_CHECKING(version of $CC)
2340         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2341         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2342         AC_MSG_RESULT($GCC_VERSION)
2343 fi
2344 ])dnl
2345 dnl ---------------------------------------------------------------------------
2346 dnl CF_GCC_WARNINGS version: 33 updated: 2018/06/20 20:23:13
2347 dnl ---------------
2348 dnl Check if the compiler supports useful warning options.  There's a few that
2349 dnl we don't use, simply because they're too noisy:
2350 dnl
2351 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2352 dnl     -Wredundant-decls (system headers make this too noisy)
2353 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2354 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2355 dnl             is enabled for ncurses using "--enable-const".
2356 dnl     -pedantic
2357 dnl
2358 dnl Parameter:
2359 dnl     $1 is an optional list of gcc warning flags that a particular
2360 dnl             application might want to use, e.g., "no-unused" for
2361 dnl             -Wno-unused
2362 dnl Special:
2363 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2364 dnl
2365 AC_DEFUN([CF_GCC_WARNINGS],
2366 [
2367 AC_REQUIRE([CF_GCC_VERSION])
2368 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2369 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2370
2371 cat > conftest.$ac_ext <<EOF
2372 #line __oline__ "${as_me:-configure}"
2373 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2374 EOF
2375
2376 if test "$INTEL_COMPILER" = yes
2377 then
2378 # The "-wdXXX" options suppress warnings:
2379 # remark #1419: external declaration in primary source file
2380 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2381 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2382 # remark #193: zero used for undefined preprocessing identifier
2383 # remark #593: variable "curs_sb_left_arrow" was set but never used
2384 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2385 # remark #869: parameter "tw" was never referenced
2386 # remark #981: operands are evaluated in unspecified order
2387 # warning #279: controlling expression is constant
2388
2389         AC_CHECKING([for $CC warning options])
2390         cf_save_CFLAGS="$CFLAGS"
2391         EXTRA_CFLAGS="-Wall"
2392         for cf_opt in \
2393                 wd1419 \
2394                 wd1683 \
2395                 wd1684 \
2396                 wd193 \
2397                 wd593 \
2398                 wd279 \
2399                 wd810 \
2400                 wd869 \
2401                 wd981
2402         do
2403                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2404                 if AC_TRY_EVAL(ac_compile); then
2405                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2406                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2407                 fi
2408         done
2409         CFLAGS="$cf_save_CFLAGS"
2410
2411 elif test "$GCC" = yes
2412 then
2413         AC_CHECKING([for $CC warning options])
2414         cf_save_CFLAGS="$CFLAGS"
2415         EXTRA_CFLAGS=
2416         cf_warn_CONST=""
2417         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2418         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2419         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2420         for cf_opt in W Wall \
2421                 Wbad-function-cast \
2422                 Wcast-align \
2423                 Wcast-qual \
2424                 Wdeclaration-after-statement \
2425                 Wextra \
2426                 Winline \
2427                 Wmissing-declarations \
2428                 Wmissing-prototypes \
2429                 Wnested-externs \
2430                 Wpointer-arith \
2431                 Wshadow \
2432                 Wstrict-prototypes \
2433                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
2434         do
2435                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2436                 if AC_TRY_EVAL(ac_compile); then
2437                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2438                         case $cf_opt in
2439                         (Wcast-qual)
2440                                 CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
2441                                 ;;
2442                         (Winline)
2443                                 case $GCC_VERSION in
2444                                 ([[34]].*)
2445                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2446                                         continue;;
2447                                 esac
2448                                 ;;
2449                         (Wpointer-arith)
2450                                 case $GCC_VERSION in
2451                                 ([[12]].*)
2452                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2453                                         continue;;
2454                                 esac
2455                                 ;;
2456                         esac
2457                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2458                 fi
2459         done
2460         CFLAGS="$cf_save_CFLAGS"
2461 fi
2462 rm -rf conftest*
2463
2464 AC_SUBST(EXTRA_CFLAGS)
2465 ])dnl
2466 dnl ---------------------------------------------------------------------------
2467 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
2468 dnl ----------------
2469 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2470 dnl unistd.h or (nonstandard) in getopt.h
2471 AC_DEFUN([CF_GETOPT_HEADER],
2472 [
2473 AC_HAVE_HEADERS(unistd.h getopt.h)
2474 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2475 cf_cv_getopt_header=none
2476 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2477 do
2478 AC_TRY_COMPILE([
2479 #include <$cf_header>],
2480 [int x = optind; char *y = optarg],
2481 [cf_cv_getopt_header=$cf_header
2482  break])
2483 done
2484 ])
2485 if test $cf_cv_getopt_header != none ; then
2486         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2487 fi
2488 if test $cf_cv_getopt_header = getopt.h ; then
2489         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2490 fi
2491 ])dnl
2492 dnl ---------------------------------------------------------------------------
2493 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2494 dnl -----------------
2495 AC_DEFUN([CF_GNATPREP_OPT_T],[
2496 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2497 cf_cv_gnatprep_opt_t=no
2498 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2499 ])
2500 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
2501 AC_SUBST(GNATPREP_OPTS)
2502 ])dnl
2503 dnl ---------------------------------------------------------------------------
2504 dnl CF_GNAT_GENERICS version: 3 updated: 2015/04/17 21:13:04
2505 dnl ----------------
2506 AC_DEFUN([CF_GNAT_GENERICS],
2507 [
2508 AC_REQUIRE([CF_GNAT_VERSION])
2509
2510 AC_MSG_CHECKING(if GNAT supports generics)
2511 case $cf_gnat_version in
2512 (3.[[1-9]]*|[[4-9]].*)
2513         cf_gnat_generics=yes
2514         ;;
2515 (*)
2516         cf_gnat_generics=no
2517         ;;
2518 esac
2519 AC_MSG_RESULT($cf_gnat_generics)
2520
2521 if test "$cf_gnat_generics" = yes
2522 then
2523         cf_compile_generics=generics
2524         cf_generic_objects="\${GENOBJS}"
2525 else
2526         cf_compile_generics=
2527         cf_generic_objects=
2528 fi
2529
2530 AC_SUBST(cf_compile_generics)
2531 AC_SUBST(cf_generic_objects)
2532 ])dnl
2533 dnl ---------------------------------------------------------------------------
2534 dnl CF_GNAT_PROJECTS version: 9 updated: 2018/01/14 15:46:09
2535 dnl ----------------
2536 dnl GNAT projects are configured with ".gpr" project files.
2537 dnl GNAT libraries are a further development, using the project feature.
2538 AC_DEFUN([CF_GNAT_PROJECTS],
2539 [
2540 AC_REQUIRE([CF_GNAT_VERSION])
2541 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
2542
2543 cf_gnat_libraries=no
2544 cf_gnat_projects=no
2545
2546 if test "$enable_gnat_projects" != no ; then
2547 AC_MSG_CHECKING(if GNAT supports project files)
2548 case $cf_gnat_version in
2549 (3.[[0-9]]*)
2550         ;;
2551 (*)
2552         case $cf_cv_system_name in
2553         (cygwin*|msys*)
2554                 ;;
2555         (*)
2556                 rm -rf conftest* *~conftest*
2557                 if mkdir conftest.src conftest.bin conftest.lib
2558                 then
2559                         cd conftest.src
2560                         rm -rf conftest* *~conftest*
2561                         cat >>library.gpr <<CF_EOF
2562 project Library is
2563   Kind := External ("LIB_KIND");
2564   for Library_Name use "ConfTest";
2565   for Object_Dir use ".";
2566   for Library_ALI_Dir use External("LIBRARY_DIR");
2567   for Library_Version use External ("SONAME");
2568   for Library_Kind use Kind;
2569   for Library_Dir use External("BUILD_DIR");
2570   Source_Dir := External ("SOURCE_DIR");
2571   for Source_Dirs use (Source_Dir);
2572 end Library;
2573 CF_EOF
2574                         cat >>confpackage.ads <<CF_EOF
2575 package ConfPackage is
2576    procedure conftest;
2577 end ConfPackage;
2578 CF_EOF
2579                         cat >>confpackage.adb <<CF_EOF
2580 with Text_IO;
2581 package body ConfPackage is
2582    procedure conftest is
2583    begin
2584       Text_IO.Put ("Hello World");
2585       Text_IO.New_Line;
2586    end conftest;
2587 end ConfPackage;
2588 CF_EOF
2589                         if ( $cf_ada_make $ADAFLAGS \
2590                                         -Plibrary.gpr \
2591                                         -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2592                                         -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2593                                         -XSOURCE_DIR=`pwd` \
2594                                         -XSONAME=libConfTest.so.1 \
2595                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2596                                 cf_gnat_projects=yes
2597                         fi
2598                         cd ..
2599                 fi
2600                 if test -f conftest.lib/confpackage.ali
2601                 then
2602                         cf_gnat_libraries=yes
2603                 fi
2604                 rm -rf conftest* *~conftest*
2605                 ;;
2606         esac
2607         ;;
2608 esac
2609 AC_MSG_RESULT($cf_gnat_projects)
2610 fi # enable_gnat_projects
2611
2612 if test $cf_gnat_projects = yes
2613 then
2614         AC_MSG_CHECKING(if GNAT supports libraries)
2615         AC_MSG_RESULT($cf_gnat_libraries)
2616 fi
2617
2618 if test "$cf_gnat_projects" = yes
2619 then
2620         USE_OLD_MAKERULES="#"
2621         USE_GNAT_PROJECTS=""
2622 else
2623         USE_OLD_MAKERULES=""
2624         USE_GNAT_PROJECTS="#"
2625 fi
2626
2627 if test "$cf_gnat_libraries" = yes
2628 then
2629         USE_GNAT_LIBRARIES=""
2630 else
2631         USE_GNAT_LIBRARIES="#"
2632 fi
2633
2634 AC_SUBST(USE_OLD_MAKERULES)
2635 AC_SUBST(USE_GNAT_PROJECTS)
2636 AC_SUBST(USE_GNAT_LIBRARIES)
2637 ])dnl
2638 dnl ---------------------------------------------------------------------------
2639 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2640 dnl --------------
2641 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2642 dnl is noted that gnat may compile a tasking unit even for configurations which
2643 dnl fail at runtime.
2644 AC_DEFUN([CF_GNAT_SIGINT],[
2645 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2646 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2647
2648 package ConfTest is
2649
2650    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2651    pragma Unreserve_All_Interrupts;
2652    pragma Warnings (On);
2653
2654    protected Process is
2655       procedure Stop;
2656       function Continue return Boolean;
2657       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2658    private
2659       Done : Boolean := False;
2660    end Process;
2661
2662 end ConfTest;],
2663 [package body ConfTest is
2664    protected body Process is
2665       procedure Stop is
2666       begin
2667          Done := True;
2668       end Stop;
2669       function Continue return Boolean is
2670       begin
2671          return not Done;
2672       end Continue;
2673    end Process;
2674 end ConfTest;],
2675         [cf_cv_gnat_sigint=yes],
2676         [cf_cv_gnat_sigint=no])])
2677
2678 if test $cf_cv_gnat_sigint = yes ; then
2679         USE_GNAT_SIGINT=""
2680 else
2681         USE_GNAT_SIGINT="#"
2682 fi
2683 AC_SUBST(USE_GNAT_SIGINT)
2684 ])dnl
2685 dnl ---------------------------------------------------------------------------
2686 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2687 dnl ----------------
2688 dnl Verify that a test program compiles/links with GNAT.
2689 dnl $cf_ada_make is set to the program that compiles/links
2690 dnl $ADAFLAGS may be set to the GNAT flags.
2691 dnl
2692 dnl $1 is the text of the spec
2693 dnl $2 is the text of the body
2694 dnl $3 is the shell command to execute if successful
2695 dnl $4 is the shell command to execute if not successful
2696 AC_DEFUN([CF_GNAT_TRY_LINK],
2697 [
2698 rm -rf conftest* *~conftest*
2699 cat >>conftest.ads <<CF_EOF
2700 $1
2701 CF_EOF
2702 cat >>conftest.adb <<CF_EOF
2703 $2
2704 CF_EOF
2705 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2706 ifelse($3,,      :,[      $3])
2707 ifelse($4,,,[else
2708    $4])
2709 fi
2710 rm -rf conftest* *~conftest*
2711 ])dnl
2712 dnl ---------------------------------------------------------------------------
2713 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2714 dnl ---------------
2715 dnl Verify that a test program compiles and runs with GNAT
2716 dnl $cf_ada_make is set to the program that compiles/links
2717 dnl $ADAFLAGS may be set to the GNAT flags.
2718 dnl
2719 dnl $1 is the text of the spec
2720 dnl $2 is the text of the body
2721 dnl $3 is the shell command to execute if successful
2722 dnl $4 is the shell command to execute if not successful
2723 AC_DEFUN([CF_GNAT_TRY_RUN],
2724 [
2725 rm -rf conftest* *~conftest*
2726 cat >>conftest.ads <<CF_EOF
2727 $1
2728 CF_EOF
2729 cat >>conftest.adb <<CF_EOF
2730 $2
2731 CF_EOF
2732 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2733    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2734 ifelse($3,,      :,[      $3])
2735 ifelse($4,,,[   else
2736       $4])
2737    fi
2738 ifelse($4,,,[else
2739    $4])
2740 fi
2741 rm -rf conftest* *~conftest*
2742 ])dnl
2743 dnl ---------------------------------------------------------------------------
2744 dnl CF_GNAT_VERSION version: 20 updated: 2015/04/18 08:56:57
2745 dnl ---------------
2746 dnl Verify version of GNAT.
2747 AC_DEFUN([CF_GNAT_VERSION],
2748 [
2749 AC_MSG_CHECKING(for gnat version)
2750 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2751         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2752         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2753 AC_MSG_RESULT($cf_gnat_version)
2754
2755 case $cf_gnat_version in
2756 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
2757         cf_cv_prog_gnat_correct=yes
2758         ;;
2759 (*)
2760         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2761         cf_cv_prog_gnat_correct=no
2762         ;;
2763 esac
2764 ])
2765 dnl ---------------------------------------------------------------------------
2766 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
2767 dnl -------------
2768 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2769 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2770 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2771 dnl since it is interwoven with GNU extensions.
2772 dnl
2773 dnl Well, yes we could work around it...
2774 dnl
2775 dnl Parameters:
2776 dnl     $1 is the nominal value for _XOPEN_SOURCE
2777 AC_DEFUN([CF_GNU_SOURCE],
2778 [
2779 cf_gnu_xopen_source=ifelse($1,,500,$1)
2780
2781 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
2782 AC_TRY_COMPILE([#include <sys/types.h>],[
2783         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
2784                 return 0;
2785         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
2786                 return 0;
2787         #else
2788         #       error not GNU C library
2789         #endif],
2790         [cf_cv_gnu_library=yes],
2791         [cf_cv_gnu_library=no])
2792 ])
2793
2794 if test x$cf_cv_gnu_library = xyes; then
2795
2796         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
2797         # was changed to help a little.  newlib incorporated the change about 4
2798         # years later.
2799         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
2800                 cf_save="$CPPFLAGS"
2801                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
2802                 AC_TRY_COMPILE([#include <sys/types.h>],[
2803                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
2804                                 return 0;
2805                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
2806                                 return 0;
2807                         #else
2808                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
2809                         #endif],
2810                         [cf_cv_gnu_library_219=yes],
2811                         [cf_cv_gnu_library_219=no])
2812                 CPPFLAGS="$cf_save"
2813         ])
2814
2815         if test "x$cf_cv_gnu_library_219" = xyes; then
2816                 cf_save="$CPPFLAGS"
2817                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
2818                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
2819                         AC_TRY_COMPILE([
2820                                 #include <limits.h>
2821                                 #include <sys/types.h>
2822                                 ],[
2823                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
2824                                         return 0;
2825                                 #else
2826                                 #       error GNU C library is too old
2827                                 #endif],
2828                                 [cf_cv_gnu_dftsrc_219=yes],
2829                                 [cf_cv_gnu_dftsrc_219=no])
2830                         ])
2831                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
2832         else
2833                 cf_cv_gnu_dftsrc_219=maybe
2834         fi
2835
2836         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
2837
2838                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2839                 AC_TRY_COMPILE([#include <sys/types.h>],[
2840                         #ifndef _XOPEN_SOURCE
2841                         #error  expected _XOPEN_SOURCE to be defined
2842                         #endif],
2843                         [cf_cv_gnu_source=no],
2844                         [cf_save="$CPPFLAGS"
2845                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
2846                          AC_TRY_COMPILE([#include <sys/types.h>],[
2847                                 #ifdef _XOPEN_SOURCE
2848                                 #error  expected _XOPEN_SOURCE to be undefined
2849                                 #endif],
2850                                 [cf_cv_gnu_source=no],
2851                                 [cf_cv_gnu_source=yes])
2852                         CPPFLAGS="$cf_save"
2853                         ])
2854                 ])
2855
2856                 if test "$cf_cv_gnu_source" = yes
2857                 then
2858                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
2859                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
2860                         AC_TRY_COMPILE([#include <sys/types.h>],[
2861                                 #ifdef _DEFAULT_SOURCE
2862                                 #error  expected _DEFAULT_SOURCE to be undefined
2863                                 #endif],
2864                                 [cf_cv_default_source=no],
2865                                 [cf_cv_default_source=yes])
2866                         ])
2867                         if test "$cf_cv_default_source" = yes
2868                         then
2869                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
2870                         fi
2871                 fi
2872         fi
2873
2874 fi
2875 ])dnl
2876 dnl ---------------------------------------------------------------------------
2877 dnl CF_GPP_LIBRARY version: 12 updated: 2015/04/17 21:13:04
2878 dnl --------------
2879 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2880 dnl problem :-).  If we have the compiler but no library, we'll be able to
2881 dnl configure, but won't be able to build the c++ demo program.
2882 AC_DEFUN([CF_GPP_LIBRARY],
2883 [
2884 cf_cxx_library=unknown
2885 case $cf_cv_system_name in
2886 (os2*)
2887         cf_gpp_libname=gpp
2888         ;;
2889 (*)
2890         cf_gpp_libname=g++
2891         ;;
2892 esac
2893 if test "$GXX" = yes; then
2894         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2895         cf_save="$LIBS"
2896         CF_ADD_LIB($cf_gpp_libname)
2897         AC_TRY_LINK([
2898 #include <$cf_gpp_libname/builtin.h>
2899         ],
2900         [two_arg_error_handler_t foo2 = lib_error_handler],
2901         [cf_cxx_library=yes
2902          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2903          if test "$cf_gpp_libname" = cpp ; then
2904             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
2905          else
2906             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
2907          fi],
2908         [AC_TRY_LINK([
2909 #include <builtin.h>
2910         ],
2911         [two_arg_error_handler_t foo2 = lib_error_handler],
2912         [cf_cxx_library=yes
2913          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2914          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
2915         [cf_cxx_library=no])])
2916         LIBS="$cf_save"
2917         AC_MSG_RESULT($cf_cxx_library)
2918 fi
2919 ])dnl
2920 dnl ---------------------------------------------------------------------------
2921 dnl CF_GXX_VERSION version: 8 updated: 2017/02/11 14:48:57
2922 dnl --------------
2923 dnl Check for version of g++
2924 AC_DEFUN([CF_GXX_VERSION],[
2925 AC_REQUIRE([AC_PROG_CPP])
2926 GXX_VERSION=none
2927 if test "$GXX" = yes; then
2928         AC_MSG_CHECKING(version of ${CXX:-g++})
2929         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2930         if test -z "$GXX_VERSION"
2931         then
2932                 GXX_VERSION=unknown
2933                 GXX=no
2934         fi
2935         AC_MSG_RESULT($GXX_VERSION)
2936 fi
2937 ])dnl
2938 dnl ---------------------------------------------------------------------------
2939 dnl CF_GXX_WARNINGS version: 9 updated: 2015/04/17 21:13:04
2940 dnl ---------------
2941 dnl Check if the compiler supports useful warning options.
2942 dnl
2943 dnl Most of gcc's options apply to g++, except:
2944 dnl     -Wbad-function-cast
2945 dnl     -Wmissing-declarations
2946 dnl     -Wnested-externs
2947 dnl
2948 dnl Omit a few (for now):
2949 dnl     -Winline
2950 dnl
2951 dnl Parameter:
2952 dnl     $1 is an optional list of g++ warning flags that a particular
2953 dnl             application might want to use, e.g., "no-unused" for
2954 dnl             -Wno-unused
2955 dnl Special:
2956 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2957 dnl
2958 AC_DEFUN([CF_GXX_WARNINGS],
2959 [
2960
2961 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2962 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
2963
2964 AC_REQUIRE([CF_GXX_VERSION])
2965
2966 AC_LANG_SAVE
2967 AC_LANG_CPLUSPLUS
2968
2969 cat > conftest.$ac_ext <<EOF
2970 #line __oline__ "configure"
2971 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2972 EOF
2973
2974 if test "$INTEL_CPLUSPLUS" = yes
2975 then
2976 # The "-wdXXX" options suppress warnings:
2977 # remark #1419: external declaration in primary source file
2978 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2979 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2980 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2981 # remark #193: zero used for undefined preprocessing identifier
2982 # remark #593: variable "curs_sb_left_arrow" was set but never used
2983 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2984 # remark #869: parameter "tw" was never referenced
2985 # remark #981: operands are evaluated in unspecified order
2986 # warning #269: invalid format string conversion
2987
2988         AC_CHECKING([for $CC warning options])
2989         cf_save_CXXFLAGS="$CXXFLAGS"
2990         EXTRA_CXXFLAGS="-Wall"
2991         for cf_opt in \
2992                 wd1419 \
2993                 wd1682 \
2994                 wd1683 \
2995                 wd1684 \
2996                 wd193 \
2997                 wd279 \
2998                 wd593 \
2999                 wd810 \
3000                 wd869 \
3001                 wd981
3002         do
3003                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
3004                 if AC_TRY_EVAL(ac_compile); then
3005                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3006                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3007                 fi
3008         done
3009         CXXFLAGS="$cf_save_CXXFLAGS"
3010
3011 elif test "$GXX" = yes
3012 then
3013         AC_CHECKING([for $CXX warning options])
3014         cf_save_CXXFLAGS="$CXXFLAGS"
3015         EXTRA_CXXFLAGS="-W -Wall"
3016         cf_gxx_extra_warnings=""
3017         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
3018         case "$GCC_VERSION" in
3019         ([[1-2]].*)
3020                 ;;
3021         (*)
3022                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
3023                 ;;
3024         esac
3025         for cf_opt in \
3026                 Wabi \
3027                 fabi-version=0 \
3028                 Wextra \
3029                 Wignored-qualifiers \
3030                 Wlogical-op \
3031                 Woverloaded-virtual \
3032                 Wsign-promo \
3033                 Wsynth \
3034                 Wold-style-cast \
3035                 Wcast-align \
3036                 Wcast-qual \
3037                 Wpointer-arith \
3038                 Wshadow \
3039                 Wundef $cf_gxx_extra_warnings $1
3040         do
3041                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
3042                 if AC_TRY_EVAL(ac_compile); then
3043                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3044                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3045                 else
3046                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
3047                 fi
3048         done
3049         CXXFLAGS="$cf_save_CXXFLAGS"
3050 fi
3051
3052 rm -rf conftest*
3053 AC_LANG_RESTORE
3054 AC_SUBST(EXTRA_CXXFLAGS)
3055 ])dnl
3056 dnl ---------------------------------------------------------------------------
3057 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
3058 dnl ------------
3059 dnl Look for an instance of the Berkeley hashed database.
3060 dnl
3061 dnl $1 = optional parameter, to specify install-prefix for the database.
3062 AC_DEFUN([CF_HASHED_DB],
3063 [
3064 ifelse([$1],,,[
3065 case $1 in
3066 (yes|*able*)
3067         ;;
3068 (*)
3069         if test -d "$1" ; then
3070                 CF_ADD_INCDIR($1/include)
3071                 CF_ADD_LIBDIR($1/lib)
3072         else
3073                 case "$1" in
3074                 (./*|../*|/*)
3075                         AC_MSG_WARN(no such directory $1)
3076                         ;;
3077                 (*)
3078                         CF_FIND_SUB_INCDIR($1)
3079                         CF_FIND_SUB_LIBDIR($1)
3080                         ;;
3081                 esac
3082         fi
3083 esac
3084 ])
3085 AC_CHECK_HEADER(db.h,[
3086 CF_HASHED_DB_VERSION
3087 if test "$cf_cv_hashed_db_version" = unknown ; then
3088         AC_MSG_ERROR(Cannot determine version of db)
3089 else
3090         CF_HASHED_DB_LIBS
3091         if test "$cf_cv_hashed_db_libs" = unknown ; then
3092                 AC_MSG_ERROR(Cannot determine library for db)
3093         elif test "$cf_cv_hashed_db_libs" != default ; then
3094                 CF_ADD_LIB($cf_cv_hashed_db_libs)
3095         fi
3096 fi
3097 ],[
3098         AC_MSG_ERROR(Cannot find db.h)
3099 ])
3100 ])dnl
3101 dnl ---------------------------------------------------------------------------
3102 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
3103 dnl -----------------
3104 dnl Given that we have the header and version for hashed database, find the
3105 dnl library information.
3106 AC_DEFUN([CF_HASHED_DB_LIBS],
3107 [
3108 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
3109 cf_cv_hashed_db_libs=unknown
3110 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
3111 do
3112         cf_save_libs="$LIBS"
3113         if test -n "$cf_db_libs"; then
3114                 CF_ADD_LIB($cf_db_libs)
3115         fi
3116         CF_MSG_LOG(checking for library "$cf_db_libs")
3117         AC_TRY_LINK([
3118 $ac_includes_default
3119 #include <db.h>
3120 ],[
3121         char *path = "/tmp/foo";
3122 #ifdef DB_VERSION_MAJOR
3123 #if DB_VERSION_MAJOR >= 4
3124         DB *result = 0;
3125         db_create(&result, NULL, 0);
3126         result->open(result,
3127                 NULL,
3128                 path,
3129                 path,
3130                 DB_HASH,
3131                 DB_CREATE,
3132                 0644);
3133 #elif DB_VERSION_MAJOR >= 3
3134         DB *result = 0;
3135         db_create(&result, NULL, 0);
3136         result->open(result,
3137                 path,
3138                 path,
3139                 DB_HASH,
3140                 DB_CREATE,
3141                 0644);
3142 #elif DB_VERSION_MAJOR >= 2
3143         DB *result = 0;
3144         db_open(path,
3145                 DB_HASH,
3146                 DB_CREATE,
3147                 0644,
3148                 (DB_ENV *) 0,
3149                 (DB_INFO *) 0,
3150                 &result);
3151 #endif /* DB_VERSION_MAJOR */
3152 #else
3153         DB *result = dbopen(path,
3154                      2,
3155                      0644,
3156                      DB_HASH,
3157                      0);
3158 #endif
3159         ${cf_cv_main_return:-return}(result != 0)
3160 ],[
3161         if test -n "$cf_db_libs" ; then
3162                 cf_cv_hashed_db_libs=$cf_db_libs
3163         else
3164                 cf_cv_hashed_db_libs=default
3165         fi
3166         LIBS="$cf_save_libs"
3167         break
3168 ])
3169         LIBS="$cf_save_libs"
3170 done
3171 ])
3172 ])dnl
3173 dnl ---------------------------------------------------------------------------
3174 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
3175 dnl --------------------
3176 dnl Given that we have the header file for hashed database, find the version
3177 dnl information.
3178 AC_DEFUN([CF_HASHED_DB_VERSION],
3179 [
3180 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
3181 cf_cv_hashed_db_version=unknown
3182
3183 for cf_db_version in 1 2 3 4 5 6
3184 do
3185         CF_MSG_LOG(checking for db version $cf_db_version)
3186         AC_TRY_COMPILE([
3187 $ac_includes_default
3188 #include <db.h>
3189
3190 #ifdef DB_VERSION_MAJOR
3191         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
3192 #if $cf_db_version == DB_VERSION_MAJOR
3193         /* ok */
3194 #else
3195         make an error
3196 #endif
3197 #else
3198 #if $cf_db_version == 1
3199         /* ok: assuming this is DB 1.8.5 */
3200 #else
3201         make an error
3202 #endif
3203 #endif
3204 ],[DBT *foo = 0],[
3205         cf_cv_hashed_db_version=$cf_db_version
3206         break
3207         ])
3208 done
3209 ])
3210 ])dnl
3211 dnl ---------------------------------------------------------------------------
3212 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
3213 dnl --------------
3214 dnl Construct a search-list of directories for a nonstandard header-file
3215 dnl
3216 dnl Parameters
3217 dnl     $1 = the variable to return as result
3218 dnl     $2 = the package name
3219 AC_DEFUN([CF_HEADER_PATH],
3220 [
3221 $1=
3222
3223 # collect the current set of include-directories from compiler flags
3224 cf_header_path_list=""
3225 if test -n "${CFLAGS}${CPPFLAGS}" ; then
3226         for cf_header_path in $CPPFLAGS $CFLAGS
3227         do
3228                 case $cf_header_path in
3229                 (-I*)
3230                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
3231                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
3232                         cf_header_path_list="$cf_header_path_list [$]$1"
3233                         ;;
3234                 esac
3235         done
3236 fi
3237
3238 # add the variations for the package we are looking for
3239 CF_SUBDIR_PATH($1,$2,include)
3240
3241 test "$includedir" != NONE && \
3242 test "$includedir" != "/usr/include" && \
3243 test -d "$includedir" && {
3244         test -d $includedir &&    $1="[$]$1 $includedir"
3245         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
3246 }
3247
3248 test "$oldincludedir" != NONE && \
3249 test "$oldincludedir" != "/usr/include" && \
3250 test -d "$oldincludedir" && {
3251         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
3252         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
3253 }
3254
3255 $1="[$]$1 $cf_header_path_list"
3256 ])dnl
3257 dnl ---------------------------------------------------------------------------
3258 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
3259 dnl ---------------
3260 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
3261 AC_DEFUN([CF_HELP_MESSAGE],
3262 [AC_DIVERT_HELP([$1])dnl
3263 ])dnl
3264 dnl ---------------------------------------------------------------------------
3265 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
3266 dnl ---------------
3267 dnl Construct the list of include-options according to whether we're building
3268 dnl in the source directory or using '--srcdir=DIR' option.
3269 AC_DEFUN([CF_INCLUDE_DIRS],
3270 [
3271 if test "$srcdir" != "."; then
3272         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
3273 fi
3274 CPPFLAGS="-I../include $CPPFLAGS"
3275 if test "$srcdir" != "."; then
3276         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
3277 fi
3278 CPPFLAGS="-I. $CPPFLAGS"
3279 AC_SUBST(CPPFLAGS)
3280 ])dnl
3281 dnl ---------------------------------------------------------------------------
3282 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
3283 dnl ---------------
3284 dnl prompt for/fill-in useful install-program options
3285 AC_DEFUN([CF_INSTALL_OPTS],
3286 [
3287 CF_INSTALL_OPT_S
3288 CF_INSTALL_OPT_P
3289 CF_INSTALL_OPT_O
3290 ])dnl
3291 dnl ---------------------------------------------------------------------------
3292 dnl CF_INSTALL_OPT_O version: 2 updated: 2015/05/15 19:45:35
3293 dnl ----------------
3294 dnl Almost all "install" programs default to the current user's ownership.
3295 dnl Almost - MINIX is an exception.
3296 AC_DEFUN([CF_INSTALL_OPT_O],
3297 [
3298 AC_MSG_CHECKING(if install needs to be told about ownership)
3299 case `$ac_config_guess` in
3300 (*minix)
3301         with_install_o=yes
3302         ;;
3303 (*)
3304         with_install_o=no
3305         ;;
3306 esac
3307
3308 AC_MSG_RESULT($with_install_o)
3309 if test "x$with_install_o" = xyes
3310 then
3311         INSTALL_OPT_O=`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`
3312 else
3313         INSTALL_OPT_O=
3314 fi
3315
3316 AC_SUBST(INSTALL_OPT_O)
3317 ])dnl
3318 dnl ---------------------------------------------------------------------------
3319 dnl CF_INSTALL_OPT_P version: 1 updated: 2018/08/18 12:19:21
3320 dnl ----------------
3321 dnl Some install-programs accept a "-p" option to preserve file modification
3322 dnl timestamps.  That can be useful as an install option, as well as a way to
3323 dnl avoid the need for ranlib after copying a static archive.
3324 AC_DEFUN([CF_INSTALL_OPT_P],
3325 [
3326 : ${INSTALL:=install}
3327 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
3328         rm -rf conftest*
3329         date >conftest.in
3330         mkdir conftest.out
3331         sleep 3
3332         if $INSTALL -p conftest.in conftest.out 2>/dev/null
3333         then
3334                 if test -f conftest.out/conftest.in
3335                 then
3336                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
3337                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
3338                         if test -s conftest.err
3339                         then
3340                                 cf_cv_install_p=no
3341                         else
3342                                 cf_cv_install_p=yes
3343                         fi
3344                 else
3345                         cf_cv_install_p=no
3346                 fi
3347         else
3348                 cf_cv_install_p=no
3349         fi
3350         rm -rf conftest*
3351 ])
3352 ])dnl
3353 dnl ---------------------------------------------------------------------------
3354 dnl CF_INSTALL_OPT_S version: 2 updated: 2018/08/18 12:19:21
3355 dnl ----------------
3356 dnl By default, we should strip executables which are installed, but leave the
3357 dnl ability to suppress that for unit-testing.
3358 AC_DEFUN([CF_INSTALL_OPT_S],
3359 [
3360 AC_MSG_CHECKING(if you want to install stripped executables)
3361 CF_ARG_DISABLE(stripping,
3362         [  --disable-stripping     do not strip (debug info) installed executables],
3363         [with_stripping=no],
3364         [with_stripping=yes])
3365 AC_MSG_RESULT($with_stripping)
3366
3367 if test "$with_stripping" = yes
3368 then
3369         INSTALL_OPT_S="-s"
3370 else
3371         INSTALL_OPT_S=
3372 fi
3373 AC_SUBST(INSTALL_OPT_S)
3374 ])dnl
3375 dnl ---------------------------------------------------------------------------
3376 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
3377 dnl -----------------
3378 dnl Check if the given compiler is really the Intel compiler for Linux.  It
3379 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
3380 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
3381 dnl
3382 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
3383 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
3384 dnl the wrappers for gcc and g++ warnings.
3385 dnl
3386 dnl $1 = GCC (default) or GXX
3387 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
3388 dnl $3 = CFLAGS (default) or CXXFLAGS
3389 AC_DEFUN([CF_INTEL_COMPILER],[
3390 AC_REQUIRE([AC_CANONICAL_HOST])
3391 ifelse([$2],,INTEL_COMPILER,[$2])=no
3392
3393 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
3394         case $host_os in
3395         (linux*|gnu*)
3396                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
3397                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
3398                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
3399                 AC_TRY_COMPILE([],[
3400 #ifdef __INTEL_COMPILER
3401 #else
3402 make an error
3403 #endif
3404 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
3405 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
3406 ],[])
3407                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
3408                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
3409                 ;;
3410         esac
3411 fi
3412 ])dnl
3413 dnl ---------------------------------------------------------------------------
3414 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
3415 dnl ----------
3416 dnl Check if we have either a function or macro for 'isascii()'.
3417 AC_DEFUN([CF_ISASCII],
3418 [
3419 AC_MSG_CHECKING(for isascii)
3420 AC_CACHE_VAL(cf_cv_have_isascii,[
3421         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
3422         [cf_cv_have_isascii=yes],
3423         [cf_cv_have_isascii=no])
3424 ])dnl
3425 AC_MSG_RESULT($cf_cv_have_isascii)
3426 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
3427 ])dnl
3428 dnl ---------------------------------------------------------------------------
3429 dnl CF_LARGEFILE version: 11 updated: 2018/06/20 20:23:13
3430 dnl ------------
3431 dnl Add checks for large file support.
3432 AC_DEFUN([CF_LARGEFILE],[
3433 ifdef([AC_FUNC_FSEEKO],[
3434         AC_SYS_LARGEFILE
3435         if test "$enable_largefile" != no ; then
3436         AC_FUNC_FSEEKO
3437
3438         # Normally we would collect these definitions in the config.h,
3439         # but (like _XOPEN_SOURCE), some environments rely on having these
3440         # defined before any of the system headers are included.  Another
3441         # case comes up with C++, e.g., on AIX the compiler compiles the
3442         # header files by themselves before looking at the body files it is
3443         # told to compile.  For ncurses, those header files do not include
3444         # the config.h
3445         if test "$ac_cv_sys_large_files" != no
3446         then
3447                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
3448         fi
3449         if test "$ac_cv_sys_largefile_source" != no
3450         then
3451                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
3452         fi
3453         if test "$ac_cv_sys_file_offset_bits" != no
3454         then
3455                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
3456         fi
3457
3458         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
3459                 AC_TRY_COMPILE([
3460 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
3461 #include <sys/types.h>
3462 #include <dirent.h>
3463                 ],[
3464                 /* if transitional largefile support is setup, this is true */
3465                 extern struct dirent64 * readdir(DIR *);
3466                 struct dirent64 *x = readdir((DIR *)0);
3467                 struct dirent *y = readdir((DIR *)0);
3468                 int z = x - y;
3469                 ],
3470                 [cf_cv_struct_dirent64=yes],
3471                 [cf_cv_struct_dirent64=no])
3472         ])
3473         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
3474         fi
3475 ])
3476 ])
3477 dnl ---------------------------------------------------------------------------
3478 dnl CF_LDFLAGS_STATIC version: 12 updated: 2015/04/18 08:56:57
3479 dnl -----------------
3480 dnl Check for compiler/linker flags used to temporarily force usage of static
3481 dnl libraries.  This depends on the compiler and platform.  Use this to help
3482 dnl ensure that the linker picks up a given library based on its position in
3483 dnl the list of linker options and libraries.
3484 AC_DEFUN([CF_LDFLAGS_STATIC],[
3485
3486 if test "$GCC" = yes ; then
3487         case $cf_cv_system_name in
3488         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
3489                 LDFLAGS_STATIC=
3490                 LDFLAGS_SHARED=
3491                 ;;
3492         (*)     # normally, except when broken
3493                 LDFLAGS_STATIC=-static
3494                 LDFLAGS_SHARED=-dynamic
3495                 ;;
3496         esac
3497 else
3498         case $cf_cv_system_name in
3499         (aix[[4-7]]*)   # from ld manpage
3500                 LDFLAGS_STATIC=-bstatic
3501                 LDFLAGS_SHARED=-bdynamic
3502                 ;;
3503         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
3504                 # We could also use just "archive" and "shared".
3505                 LDFLAGS_STATIC=-Wl,-a,archive_shared
3506                 LDFLAGS_SHARED=-Wl,-a,shared_archive
3507                 ;;
3508         (irix*)         # from ld manpage IRIX64
3509                 LDFLAGS_STATIC=-Bstatic
3510                 LDFLAGS_SHARED=-Bdynamic
3511                 ;;
3512         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
3513                 # alternative "-oldstyle_liblookup" (not in cc manpage)
3514                 LDFLAGS_STATIC=-noso
3515                 LDFLAGS_SHARED=-so_archive
3516                 ;;
3517         (solaris2*)
3518                 LDFLAGS_STATIC=-Bstatic
3519                 LDFLAGS_SHARED=-Bdynamic
3520                 ;;
3521         esac
3522 fi
3523
3524 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
3525 then
3526         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
3527
3528         rm -f libconftest.a
3529         cat >conftest.$ac_ext <<EOF
3530 #line __oline__ "configure"
3531 #include <stdio.h>
3532 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
3533 EOF
3534         if AC_TRY_EVAL(ac_compile) ; then
3535                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
3536                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
3537         fi
3538         rm -f conftest.*
3539
3540         cf_save_LIBS="$LIBS"
3541
3542         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
3543         AC_TRY_LINK([
3544 #line __oline__ "configure"
3545 #include <stdio.h>
3546 int cf_ldflags_static(FILE *fp);
3547 ],[
3548         return cf_ldflags_static(stdin);
3549 ],[
3550         # some linkers simply ignore the -dynamic
3551         case x`file conftest$ac_exeext 2>/dev/null` in
3552         (*static*)
3553                 cf_ldflags_static=no
3554                 ;;
3555         (*)
3556                 cf_ldflags_static=yes
3557                 ;;
3558         esac
3559 ],[cf_ldflags_static=no])
3560
3561         rm -f libconftest.*
3562         LIBS="$cf_save_LIBS"
3563
3564         AC_MSG_RESULT($cf_ldflags_static)
3565
3566         if test $cf_ldflags_static != yes
3567         then
3568                 LDFLAGS_STATIC=
3569                 LDFLAGS_SHARED=
3570         fi
3571 else
3572         LDFLAGS_STATIC=
3573         LDFLAGS_SHARED=
3574 fi
3575
3576 AC_SUBST(LDFLAGS_STATIC)
3577 AC_SUBST(LDFLAGS_SHARED)
3578 ])
3579 dnl ---------------------------------------------------------------------------
3580 dnl CF_LD_RPATH_OPT version: 8 updated: 2018/08/18 16:36:35
3581 dnl ---------------
3582 dnl For the given system and compiler, find the compiler flags to pass to the
3583 dnl loader to use the "rpath" feature.
3584 AC_DEFUN([CF_LD_RPATH_OPT],
3585 [
3586 AC_REQUIRE([CF_CHECK_CACHE])
3587
3588 LD_RPATH_OPT=
3589 if test "x$cf_cv_enable_rpath" != xno
3590 then
3591         AC_MSG_CHECKING(for an rpath option)
3592         case $cf_cv_system_name in
3593         (irix*)
3594                 if test "$GCC" = yes; then
3595                         LD_RPATH_OPT="-Wl,-rpath,"
3596                 else
3597                         LD_RPATH_OPT="-rpath "
3598                 fi
3599                 ;;
3600         (linux*|gnu*|k*bsd*-gnu|freebsd*)
3601                 LD_RPATH_OPT="-Wl,-rpath,"
3602                 ;;
3603         (openbsd[[2-9]].*|mirbsd*)
3604                 LD_RPATH_OPT="-Wl,-rpath,"
3605                 ;;
3606         (dragonfly*)
3607                 LD_RPATH_OPT="-rpath "
3608                 ;;
3609         (netbsd*)
3610                 LD_RPATH_OPT="-Wl,-rpath,"
3611                 ;;
3612         (osf*|mls+*)
3613                 LD_RPATH_OPT="-rpath "
3614                 ;;
3615         (solaris2*)
3616                 LD_RPATH_OPT="-R"
3617                 ;;
3618         (*)
3619                 ;;
3620         esac
3621         AC_MSG_RESULT($LD_RPATH_OPT)
3622
3623         case "x$LD_RPATH_OPT" in
3624         (x-R*)
3625                 AC_MSG_CHECKING(if we need a space after rpath option)
3626                 cf_save_LIBS="$LIBS"
3627                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3628                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3629                 LIBS="$cf_save_LIBS"
3630                 AC_MSG_RESULT($cf_rpath_space)
3631                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3632                 ;;
3633         esac
3634 fi
3635 ])dnl
3636 dnl ---------------------------------------------------------------------------
3637 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
3638 dnl ---------------
3639 dnl Construct a search-list of directories for a nonstandard library-file
3640 dnl
3641 dnl Parameters
3642 dnl     $1 = the variable to return as result
3643 dnl     $2 = the package name
3644 AC_DEFUN([CF_LIBRARY_PATH],
3645 [
3646 $1=
3647 cf_library_path_list=""
3648 if test -n "${LDFLAGS}${LIBS}" ; then
3649         for cf_library_path in $LDFLAGS $LIBS
3650         do
3651                 case $cf_library_path in
3652                 (-L*)
3653                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3654                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3655                         cf_library_path_list="$cf_library_path_list [$]$1"
3656                         ;;
3657                 esac
3658         done
3659 fi
3660
3661 CF_SUBDIR_PATH($1,$2,lib)
3662
3663 $1="$cf_library_path_list [$]$1"
3664 ])dnl
3665 dnl ---------------------------------------------------------------------------
3666 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
3667 dnl ------------------
3668 AC_DEFUN([CF_LIBTOOL_VERSION],[
3669 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
3670 then
3671         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
3672 else
3673         cf_cv_libtool_version=
3674 fi
3675 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
3676 ])dnl
3677 dnl ---------------------------------------------------------------------------
3678 dnl CF_LIB_PREFIX version: 12 updated: 2015/10/17 19:03:33
3679 dnl -------------
3680 dnl Compute the library-prefix for the given host system
3681 dnl $1 = variable to set
3682 define([CF_LIB_PREFIX],
3683 [
3684         case $cf_cv_system_name in
3685         (OS/2*|os2*)
3686                 if test "$DFT_LWR_MODEL" = libtool; then
3687                         LIB_PREFIX='lib'
3688                 else
3689                         LIB_PREFIX=''
3690                 fi
3691                 ;;
3692         (*)     LIB_PREFIX='lib'
3693                 ;;
3694         esac
3695 ifelse($1,,,[$1=$LIB_PREFIX])
3696         AC_SUBST(LIB_PREFIX)
3697 ])dnl
3698 dnl ---------------------------------------------------------------------------
3699 dnl CF_LIB_RULES version: 88 updated: 2018/08/18 12:19:21
3700 dnl ------------
3701 dnl Append definitions and rules for the given models to the subdirectory
3702 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3703 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
3704 dnl the corresponding makefile to list the models that we'll generate.
3705 dnl
3706 dnl For shared libraries, make a list of symbolic links to construct when
3707 dnl generating each library.  The convention used for Linux is the simplest
3708 dnl one:
3709 dnl     lib<name>.so    ->
3710 dnl     lib<name>.so.<major>    ->
3711 dnl     lib<name>.so.<maj>.<minor>
3712 dnl
3713 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
3714 AC_DEFUN([CF_LIB_RULES],
3715 [
3716 cf_prefix=$LIB_PREFIX
3717 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3718
3719 case $cf_cv_shlib_version in
3720 (cygdll|msysdll|mingw)
3721         TINFO_NAME=$TINFO_ARG_SUFFIX
3722         TINFO_SUFFIX=.dll
3723         ;;
3724 esac
3725
3726 if test -n "$TINFO_SUFFIX" ; then
3727         case $TINFO_SUFFIX in
3728         (tw*)
3729                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
3730                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw'$EXTRA_SUFFIX'//'`
3731                 ;;
3732         (t*)
3733                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
3734                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t'$EXTRA_SUFFIX'//'`
3735                 ;;
3736         (w*)
3737                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
3738                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w'$EXTRA_SUFFIX'//'`
3739                 ;;
3740         esac
3741 fi
3742
3743 for cf_dir in $SRC_SUBDIRS
3744 do
3745         if test ! -d $srcdir/$cf_dir ; then
3746                 continue
3747         elif test -f $srcdir/$cf_dir/modules; then
3748
3749                 SHARED_LIB=
3750                 Libs_To_Make=
3751                 cf_awk_program=
3752                 if test -n "${cf_cv_abi_version}" && test "x${cf_cv_abi_version}" != "x5"
3753                 then
3754                         cf_awk_program="$cf_awk_program\
3755 /deprecated in ABI${cf_cv_abi_version}/ { next; }\
3756 { sub(\"NCURSES([[WT]]+)?\", \"&${cf_cv_abi_version}\"); }\
3757 "
3758                 fi
3759
3760                 if test "x$WILDCARD_SYMS" = xno
3761                 then
3762                         cf_awk_program="$cf_awk_program\
3763 /[[     ]]_\\*;/ { skip=1; next; }\
3764 "
3765                 fi
3766
3767                 if test "x$cf_awk_program" != "x"
3768                 then
3769                         cat >>$cf_dir/Makefile <<CF_EOF
3770
3771 # Generated by CF_LIB_RULES
3772 resulting.map: $UNALTERED_SYMS
3773         $AWK 'BEGIN { skip = 1; last=""; } \
3774 $cf_awk_program \
3775 { if ( last != "" && ( skip == 0 || \[$]\[$]0 !~ /}/ ) ) { print last; }\
3776  skip = 0; last = \[$]\[$]0; } \
3777 END { print last; }' < $UNALTERED_SYMS >\[$]@
3778
3779 distclean::
3780         rm -f resulting.map
3781 CF_EOF
3782                 fi
3783
3784                 for cf_item in $cf_LIST_MODELS
3785                 do
3786                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3787                         cf_libname=$cf_dir
3788                         test "$cf_dir" = c++ && cf_libname=ncurses++
3789                         if test $cf_item = shared ; then
3790                                 if test -n "${LIB_SUFFIX}"
3791                                 then
3792                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3793                                 else
3794                                         cf_shared_suffix="$cf_suffix"
3795                                 fi
3796                                 if test "$cf_cv_do_symlinks" = yes ; then
3797                                         cf_version_name=
3798
3799                                         case "$cf_cv_shlib_version" in
3800                                         (rel)
3801                                                 cf_version_name=REL_VERSION
3802                                                 ;;
3803                                         (abi)
3804                                                 cf_version_name=ABI_VERSION
3805                                                 ;;
3806                                         esac
3807
3808                                         if test -n "$cf_version_name"
3809                                         then
3810                                                 case "$cf_cv_system_name" in
3811                                                 (darwin*)
3812                                                         # "w", etc?
3813                                                         cf_suffix="${USE_LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
3814                                                         ;;
3815                                                 (*)
3816                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
3817                                                         ;;
3818                                                 esac
3819                                         fi
3820                                         if test -n "${USE_LIB_SUFFIX}"
3821                                         then
3822                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3823                                         else
3824                                                 cf_shared_suffix="$cf_suffix"
3825                                         fi
3826                                 fi
3827                                 # cygwin needs import library, and has unique naming convention
3828                                 # use autodetected ${cf_prefix} for import lib and static lib, but
3829                                 # use 'cyg' prefix for shared lib.
3830                                 case $cf_cv_shlib_version in
3831                                 (cygdll)
3832                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3833                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
3834                                         ;;
3835                                 (msysdll)
3836                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3837                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
3838                                         ;;
3839                                 (mingw)
3840                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3841                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
3842                                         ;;
3843                                 (*)
3844                                         cf_add_lib=
3845                                         ;;
3846                                 esac
3847                                 if test -n "$cf_add_lib"
3848                                 then
3849                                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3850                                         continue
3851                                 fi
3852                         fi
3853                         cf_add_lib="../lib/${cf_prefix}${cf_libname}${cf_suffix}"
3854                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3855                 done
3856
3857                 if test $cf_dir = ncurses ; then
3858                         cf_subsets="$LIB_SUBSETS"
3859                         cf_r_parts="$cf_subsets"
3860                         cf_liblist="$Libs_To_Make"
3861
3862                         while test -n "$cf_r_parts"
3863                         do
3864                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3865                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3866                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3867                                         cf_add_lib=
3868                                         case $cf_l_parts in
3869                                         (*termlib*)
3870                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3871                                                 ;;
3872                                         (*ticlib*)
3873                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3874                                                 ;;
3875                                         (*)
3876                                                 break
3877                                                 ;;
3878                                         esac
3879                                         if test -n "$cf_add_lib"; then
3880                                                 Libs_To_Make="$cf_add_lib $Libs_To_Make"
3881                                         fi
3882                                 else
3883                                         break
3884                                 fi
3885                         done
3886                 else
3887                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3888                 fi
3889
3890                 if test $cf_dir = c++; then
3891                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
3892                                 cf_list=
3893                                 for cf_item in $Libs_To_Make
3894                                 do
3895                                         case $cf_item in
3896                                         (*.a)
3897                                                 ;;
3898                                         (*)
3899                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
3900                                                 ;;
3901                                         esac
3902                                         for cf_test in $cf_list
3903                                         do
3904                                                 if test "$cf_test" = "$cf_item"
3905                                                 then
3906                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
3907                                                         cf_item=
3908                                                         break
3909                                                 fi
3910                                         done
3911                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
3912                                 done
3913                                 Libs_To_Make="$cf_list"
3914                         fi
3915                 fi
3916
3917                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
3918                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3919                         $cf_dir/Makefile >$cf_dir/Makefile.out
3920                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3921
3922                 $AWK -f $srcdir/mk-0th.awk \
3923                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
3924                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3925
3926                 for cf_subset in $cf_subsets
3927                 do
3928                         cf_subdirs=
3929                         for cf_item in $cf_LIST_MODELS
3930                         do
3931
3932                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3933                         CF_UPPER(cf_ITEM,$cf_item)
3934
3935                         CXX_MODEL=$cf_ITEM
3936                         if test "$CXX_MODEL" = SHARED; then
3937                                 case $cf_cv_shlib_version in
3938                                 (cygdll|msysdll|mingw)
3939                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
3940                                         with_shared_cxx=yes
3941                                         ;;
3942                                 (*)
3943                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
3944                                         ;;
3945                                 esac
3946                         fi
3947
3948                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3949                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3950
3951                         # Test for case where we build libtinfo with a different name.
3952                         cf_libname=$cf_dir
3953                         if test $cf_dir = ncurses ; then
3954                                 case $cf_subset in
3955                                 (*base*)
3956                                         cf_libname=${cf_libname}$USE_LIB_SUFFIX
3957                                         ;;
3958                                 (*termlib*)
3959                                         cf_libname=$TINFO_LIB_SUFFIX
3960                                         ;;
3961                                 (ticlib*)
3962                                         cf_libname=$TICS_LIB_SUFFIX
3963                                         ;;
3964                                 esac
3965                         elif test $cf_dir = c++ ; then
3966                                 cf_libname=ncurses++$USE_LIB_SUFFIX
3967                         else
3968                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
3969                         fi
3970                         if test -n "${USE_ARG_SUFFIX}" ; then
3971                                 # undo $USE_LIB_SUFFIX add-on in CF_LIB_SUFFIX
3972                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${USE_LIB_SUFFIX}%%"`
3973                         fi
3974
3975                         # These dependencies really are for development, not
3976                         # builds, but they are useful in porting, too.
3977                         cf_depend="../include/ncurses_cfg.h"
3978                         if test "$srcdir" = "."; then
3979                                 cf_reldir="."
3980                         else
3981                                 cf_reldir="\${srcdir}"
3982                         fi
3983
3984                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3985                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3986                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3987                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3988                         fi
3989
3990                         cf_dir_suffix=
3991                         old_cf_suffix="$cf_suffix"
3992                         if test "$cf_cv_shlib_version_infix" = yes ; then
3993                         if test -n "$USE_LIB_SUFFIX" ; then
3994                                 case $USE_LIB_SUFFIX in
3995                                 (tw*)
3996                                         cf_libname=`echo $cf_libname | sed 's/tw'$EXTRA_SUFFIX'$//'`
3997                                         cf_suffix=`echo $cf_suffix | sed 's/^tw'$EXTRA_SUFFIX'//'`
3998                                         cf_dir_suffix=tw$EXTRA_SUFFIX
3999                                         ;;
4000                                 (t*)
4001                                         cf_libname=`echo $cf_libname | sed 's/t'$EXTRA_SUFFIX'$//'`
4002                                         cf_suffix=`echo $cf_suffix | sed 's/^t'$EXTRA_SUFFIX'//'`
4003                                         cf_dir_suffix=t$EXTRA_SUFFIX
4004                                         ;;
4005                                 (w*)
4006                                         cf_libname=`echo $cf_libname | sed 's/w'$EXTRA_SUFFIX'$//'`
4007                                         cf_suffix=`echo $cf_suffix | sed 's/^w'$EXTRA_SUFFIX'//'`
4008                                         cf_dir_suffix=w$EXTRA_SUFFIX
4009                                         ;;
4010                                 (*)
4011                                         cf_libname=`echo $cf_libname | sed 's/'$EXTRA_SUFFIX'$//'`
4012                                         cf_suffix=`echo $cf_suffix | sed 's/^'$EXTRA_SUFFIX'//'`
4013                                         cf_dir_suffix=$EXTRA_SUFFIX
4014                                         ;;
4015                                 esac
4016                         fi
4017                         fi
4018
4019                         $AWK -f $srcdir/mk-1st.awk \
4020                                 name=${cf_libname}${cf_dir_suffix} \
4021                                 traces=$LIB_TRACING \
4022                                 MODEL=$cf_ITEM \
4023                                 CXX_MODEL=$CXX_MODEL \
4024                                 model=$cf_subdir \
4025                                 prefix=$cf_prefix \
4026                                 suffix=$cf_suffix \
4027                                 subset=$cf_subset \
4028                                 driver=$cf_cv_term_driver \
4029                                 SymLink="$LN_S" \
4030                                 TermlibRoot=$TINFO_NAME \
4031                                 TermlibSuffix=$TINFO_SUFFIX \
4032                                 ShlibVer=$cf_cv_shlib_version \
4033                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
4034                                 ReLink=${cf_cv_do_relink:-no} \
4035                                 ReRanlib=${cf_cv_do_reranlib:-yes} \
4036                                 DoLinks=$cf_cv_do_symlinks \
4037                                 rmSoLocs=$cf_cv_rm_so_locs \
4038                                 ldconfig="$LDCONFIG" \
4039                                 overwrite=$WITH_OVERWRITE \
4040                                 depend="$cf_depend" \
4041                                 host="$host" \
4042                                 libtool_version="$LIBTOOL_VERSION" \
4043                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
4044
4045                         cf_suffix="$old_cf_suffix"
4046
4047                         for cf_subdir2 in $cf_subdirs lib
4048                         do
4049                                 test $cf_subdir = $cf_subdir2 && break
4050                         done
4051                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
4052                         $AWK -f $srcdir/mk-2nd.awk \
4053                                 name=$cf_dir \
4054                                 traces=$LIB_TRACING \
4055                                 MODEL=$cf_ITEM \
4056                                 model=$cf_subdir \
4057                                 subset=$cf_subset \
4058                                 srcdir=$srcdir \
4059                                 echo=$WITH_ECHO \
4060                                 crenames=$cf_cv_prog_CC_c_o \
4061                                 cxxrenames=$cf_cv_prog_CXX_c_o \
4062                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
4063                         cf_subdirs="$cf_subdirs $cf_subdir"
4064                         done
4065                 done
4066         fi
4067
4068         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
4069 done
4070
4071 for cf_dir in $SRC_SUBDIRS
4072 do
4073         if test ! -d $srcdir/$cf_dir ; then
4074                 continue
4075         fi
4076
4077         if test -f $cf_dir/Makefile ; then
4078                 case "$cf_dir" in
4079                 (Ada95)
4080                         echo 'libs \' >> Makefile
4081                         echo 'install.libs \' >> Makefile
4082                         echo 'uninstall.libs ::' >> Makefile
4083                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
4084                         ;;
4085                 esac
4086         fi
4087
4088         if test -f $srcdir/$cf_dir/modules; then
4089                 echo >> Makefile
4090                 if test -f $srcdir/$cf_dir/headers; then
4091 cat >> Makefile <<CF_EOF
4092 install.includes \\
4093 uninstall.includes \\
4094 CF_EOF
4095                 fi
4096 if test "$cf_dir" != "c++" ; then
4097 echo 'lint \' >> Makefile
4098 fi
4099 cat >> Makefile <<CF_EOF
4100 libs \\
4101 lintlib \\
4102 install.libs \\
4103 uninstall.libs \\
4104 install.$cf_dir \\
4105 uninstall.$cf_dir ::
4106         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
4107 CF_EOF
4108         elif test -f $srcdir/$cf_dir/headers; then
4109 cat >> Makefile <<CF_EOF
4110
4111 libs \\
4112 install.libs \\
4113 uninstall.libs \\
4114 install.includes \\
4115 uninstall.includes ::
4116         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
4117 CF_EOF
4118 fi
4119 done
4120
4121 if test "x$cf_with_db_install" = xyes; then
4122 cat >> Makefile <<CF_EOF
4123
4124 install.libs uninstall.libs \\
4125 install.data uninstall.data ::
4126 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
4127 CF_EOF
4128 else
4129 cat >> Makefile <<CF_EOF
4130
4131 install.libs uninstall.libs ::
4132         cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
4133 CF_EOF
4134 fi
4135
4136 if test "x$cf_with_manpages" = xyes; then
4137 cat >> Makefile <<CF_EOF
4138
4139 install.man \\
4140 uninstall.man ::
4141         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
4142 CF_EOF
4143 fi
4144
4145 cat >> Makefile <<CF_EOF
4146
4147 distclean ::
4148         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
4149         rm -f headers.sh headers.sed mk_shared_lib.sh
4150         rm -f edit_man.* man_alias.*
4151         rm -rf \${DIRS_TO_MAKE}
4152 CF_EOF
4153
4154 # Special case: tack's manpage lives in its own directory.
4155 if test "x$cf_with_manpages" = xyes; then
4156 if test "x$cf_with_tack" = "xyes"; then
4157 cat >> Makefile <<CF_EOF
4158
4159 install.man \\
4160 uninstall.man ::
4161         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
4162 CF_EOF
4163 fi
4164 fi
4165
4166 dnl If we're installing into a subdirectory of /usr/include, etc., we should
4167 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
4168 dnl anything, and will make it more standardized.  It's awkward to decide this
4169 dnl at configuration because of quoting, so we'll simply make all headers
4170 dnl installed via a script that can do the right thing.
4171
4172 rm -f headers.sed headers.sh
4173
4174 dnl ( generating this script makes the makefiles a little tidier :-)
4175 echo creating headers.sh
4176 cat >headers.sh <<CF_EOF
4177 #! $SHELL
4178 # This shell script is generated by the 'configure' script.  It is invoked in a
4179 # subdirectory of the build tree.  It generates a sed-script in the parent
4180 # directory that is used to adjust includes for header files that reside in a
4181 # subdirectory of /usr/include, etc.
4182 PRG=""
4183 while test \[$]# != 3
4184 do
4185 PRG="\$PRG \[$]1"; shift
4186 done
4187 DST=\[$]1
4188 REF=\[$]2
4189 SRC=\[$]3
4190 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
4191 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
4192 echo installing \$SRC in \$DST
4193 CF_EOF
4194
4195 if test $WITH_CURSES_H = yes; then
4196         cat >>headers.sh <<CF_EOF
4197 case \$DST in
4198 (/*/include/*)
4199         END=\`basename \$DST\`
4200         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
4201         do
4202                 NAME=\`basename \$i\`
4203                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
4204         done
4205         ;;
4206 (*)
4207         echo "" >> \$TMPSED
4208         ;;
4209 esac
4210 CF_EOF
4211
4212 else
4213         cat >>headers.sh <<CF_EOF
4214 case \$DST in
4215 (/*/include/*)
4216         END=\`basename \$DST\`
4217         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
4218         do
4219                 NAME=\`basename \$i\`
4220                 if test "\$NAME" = "curses.h"
4221                 then
4222                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
4223                         NAME=ncurses.h
4224                 fi
4225                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
4226         done
4227         ;;
4228 (*)
4229         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
4230         ;;
4231 esac
4232 CF_EOF
4233 fi
4234 cat >>headers.sh <<CF_EOF
4235 rm -f \$TMPSRC
4236 sed -f \$TMPSED \$SRC > \$TMPSRC
4237 NAME=\`basename \$SRC\`
4238 CF_EOF
4239 if test $WITH_CURSES_H != yes; then
4240         cat >>headers.sh <<CF_EOF
4241 test "\$NAME" = "curses.h" && NAME=ncurses.h
4242 CF_EOF
4243 fi
4244 cat >>headers.sh <<CF_EOF
4245 # Just in case someone gzip'd manpages, remove the conflicting copy.
4246 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
4247
4248 eval \$PRG \$TMPSRC \$DST/\$NAME
4249 rm -f \$TMPSRC \$TMPSED
4250 CF_EOF
4251
4252 chmod 0755 headers.sh
4253
4254 for cf_dir in $SRC_SUBDIRS
4255 do
4256         if test ! -d $srcdir/$cf_dir ; then
4257                 continue
4258         fi
4259
4260         if test -f $srcdir/$cf_dir/headers; then
4261                 $AWK -f $srcdir/mk-hdr.awk \
4262                         subset="$LIB_SUBSETS" \
4263                         compat="$WITH_CURSES_H" \
4264                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
4265         fi
4266
4267         if test -f $srcdir/$cf_dir/modules; then
4268                 if test "$cf_dir" != "c++" ; then
4269                         cat >>$cf_dir/Makefile <<"CF_EOF"
4270 depend : ${AUTO_SRC}
4271         makedepend -- ${CPPFLAGS} -- ${C_SRC}
4272
4273 # DO NOT DELETE THIS LINE -- make depend depends on it.
4274 CF_EOF
4275                 fi
4276         fi
4277 done
4278 AC_SUBST(Libs_To_Make)
4279 ])dnl
4280 dnl ---------------------------------------------------------------------------
4281 dnl CF_LIB_SONAME version: 6 updated: 2017/01/21 11:06:25
4282 dnl -------------
4283 dnl Find the and soname for the given shared library.  Set the cache variable
4284 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
4285 dnl variable to "unknown".
4286 dnl
4287 dnl $1 = headers
4288 dnl $2 = code
4289 dnl $3 = library name
4290 AC_DEFUN([CF_LIB_SONAME],
4291 [
4292 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
4293
4294 cf_cv_$3_soname=unknown
4295 if test "$cross_compiling" != yes ; then
4296 cat >conftest.$ac_ext <<CF_EOF
4297 $1
4298 int main(void)
4299 {
4300 $2
4301         ${cf_cv_main_return:-return}(0);
4302 }
4303 CF_EOF
4304 cf_save_LIBS="$LIBS"
4305         CF_ADD_LIB($3)
4306         if AC_TRY_EVAL(ac_compile) ; then
4307                 if AC_TRY_EVAL(ac_link) ; then
4308                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
4309                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
4310                 fi
4311         fi
4312 rm -rf conftest*
4313 LIBS="$cf_save_LIBS"
4314 fi
4315 ])
4316 ])
4317 dnl ---------------------------------------------------------------------------
4318 dnl CF_LIB_SUFFIX version: 25 updated: 2015/04/17 21:13:04
4319 dnl -------------
4320 dnl Compute the library file-suffix from the given model name
4321 dnl $1 = model name
4322 dnl $2 = variable to set (the nominal library suffix)
4323 dnl $3 = dependency variable to set (actual filename)
4324 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4325 AC_DEFUN([CF_LIB_SUFFIX],
4326 [
4327         case X$1 in
4328         (Xlibtool)
4329                 $2='.la'
4330                 $3=[$]$2
4331                 ;;
4332         (Xdebug)
4333                 $2='_g.a'
4334                 $3=[$]$2
4335                 ;;
4336         (Xprofile)
4337                 $2='_p.a'
4338                 $3=[$]$2
4339                 ;;
4340         (Xshared)
4341                 case $cf_cv_system_name in
4342                 (aix[[5-7]]*)
4343                         $2='.so'
4344                         $3=[$]$2
4345                         ;;
4346                 (cygwin*|msys*|mingw*)
4347                         $2='.dll'
4348                         $3='.dll.a'
4349                         ;;
4350                 (darwin*)
4351                         $2='.dylib'
4352                         $3=[$]$2
4353                         ;;
4354                 (hpux*)
4355                         case $target in
4356                         (ia64*)
4357                                 $2='.so'
4358                                 $3=[$]$2
4359                                 ;;
4360                         (*)
4361                                 $2='.sl'
4362                                 $3=[$]$2
4363                                 ;;
4364                         esac
4365                         ;;
4366                 (*)
4367                         $2='.so'
4368                         $3=[$]$2
4369                         ;;
4370                 esac
4371                 ;;
4372         (*)
4373                 $2='.a'
4374                 $3=[$]$2
4375                 ;;
4376         esac
4377         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
4378         then
4379                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
4380                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
4381         fi
4382 ])dnl
4383 dnl ---------------------------------------------------------------------------
4384 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
4385 dnl -----------
4386 dnl Compute the string to append to -library from the given model name
4387 dnl $1 = model name
4388 dnl $2 = variable to set
4389 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4390 AC_DEFUN([CF_LIB_TYPE],
4391 [
4392         case $1 in
4393         (libtool) $2=''   ;;
4394         (normal)  $2=''   ;;
4395         (debug)   $2='_g' ;;
4396         (profile) $2='_p' ;;
4397         (shared)  $2=''   ;;
4398         esac
4399         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
4400 ])dnl
4401 dnl ---------------------------------------------------------------------------
4402 dnl CF_LINK_DATAONLY version: 12 updated: 2017/07/23 17:46:07
4403 dnl ----------------
4404 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
4405 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
4406 dnl have to provide wrappers for global tables to ensure they're linked
4407 dnl properly.
4408 AC_DEFUN([CF_LINK_DATAONLY],
4409 [
4410 AC_MSG_CHECKING([if data-only library module links])
4411 AC_CACHE_VAL(cf_cv_link_dataonly,[
4412         rm -f conftest.a
4413         cat >conftest.$ac_ext <<EOF
4414 #line __oline__ "configure"
4415 int     testdata[[3]] = { 123, 456, 789 };
4416 EOF
4417         if AC_TRY_EVAL(ac_compile) ; then
4418                 mv conftest.o data.o && \
4419                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
4420         fi
4421         rm -f conftest.$ac_ext data.o
4422         cat >conftest.$ac_ext <<EOF
4423 #line __oline__ "configure"
4424 int     testfunc(void)
4425 {
4426 #if defined(NeXT)
4427         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
4428 #else
4429         extern int testdata[[3]];
4430         return testdata[[0]] == 123
4431            &&  testdata[[1]] == 456
4432            &&  testdata[[2]] == 789;
4433 #endif
4434 }
4435 EOF
4436         if AC_TRY_EVAL(ac_compile); then
4437                 mv conftest.o func.o && \
4438                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
4439         fi
4440         rm -f conftest.$ac_ext func.o
4441         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
4442         cf_saveLIBS="$LIBS"
4443         LIBS="conftest.a $LIBS"
4444         AC_TRY_RUN([
4445         int main(void)
4446         {
4447                 extern int testfunc();
4448                 ${cf_cv_main_return:-return} (!testfunc());
4449         }
4450         ],
4451         [cf_cv_link_dataonly=yes],
4452         [cf_cv_link_dataonly=no],
4453         [cf_cv_link_dataonly=unknown])
4454         LIBS="$cf_saveLIBS"
4455         ])
4456 AC_MSG_RESULT($cf_cv_link_dataonly)
4457
4458 if test "$cf_cv_link_dataonly" = no ; then
4459         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
4460         BROKEN_LINKER=1
4461 fi
4462
4463 ])dnl
4464 dnl ---------------------------------------------------------------------------
4465 dnl CF_LINK_FUNCS version: 9 updated: 2017/01/21 11:11:02
4466 dnl -------------
4467 dnl Most Unix systems have both link and symlink, a few don't have symlink.
4468 dnl A few non-Unix systems implement symlink, but not link.
4469 dnl A few non-systems implement neither (or have nonfunctional versions).
4470 AC_DEFUN([CF_LINK_FUNCS],
4471 [
4472 AC_CHECK_HEADERS( \
4473 unistd.h \
4474 )
4475 AC_CHECK_FUNCS( \
4476         remove \
4477         unlink )
4478
4479 if test "$cross_compiling" = yes ; then
4480         AC_CHECK_FUNCS( \
4481                 link \
4482                 symlink )
4483 else
4484         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
4485                 cf_cv_link_funcs=
4486                 for cf_func in link symlink ; do
4487                         AC_TRY_RUN([
4488 #include <sys/types.h>
4489 #include <sys/stat.h>
4490 #ifdef HAVE_UNISTD_H
4491 #include <unistd.h>
4492 #endif
4493 int main(void)
4494 {
4495         int fail = 0;
4496         char *src = "config.log";
4497         char *dst = "conftest.chk";
4498         struct stat src_sb;
4499         struct stat dst_sb;
4500
4501         stat(src, &src_sb);
4502         fail = ($cf_func("config.log", "conftest.chk") < 0)
4503             || (stat(dst, &dst_sb) < 0)
4504             || (dst_sb.st_mtime != src_sb.st_mtime);
4505 #ifdef HAVE_UNLINK
4506         unlink(dst);
4507 #else
4508         remove(dst);
4509 #endif
4510         ${cf_cv_main_return:-return} (fail);
4511 }
4512                         ],[
4513                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
4514                         eval 'ac_cv_func_'$cf_func'=yes'],[
4515                         eval 'ac_cv_func_'$cf_func'=no'],[
4516                         eval 'ac_cv_func_'$cf_func'=error'])
4517                 done
4518                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
4519         ])
4520         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
4521         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
4522 fi
4523 ])dnl
4524 dnl ---------------------------------------------------------------------------
4525 dnl CF_MAKEFLAGS version: 18 updated: 2018/02/21 21:26:03
4526 dnl ------------
4527 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
4528 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
4529 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
4530 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
4531 AC_DEFUN([CF_MAKEFLAGS],
4532 [
4533 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
4534         cf_cv_makeflags=''
4535         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
4536         do
4537                 cat >cf_makeflags.tmp <<CF_EOF
4538 SHELL = $SHELL
4539 all :
4540         @ echo '.$cf_option'
4541 CF_EOF
4542                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
4543                 case "$cf_result" in
4544                 (.*k|.*kw)
4545                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
4546                         case "$cf_result" in
4547                         (.*CC=*)        cf_cv_makeflags=
4548                                 ;;
4549                         (*)     cf_cv_makeflags=$cf_option
4550                                 ;;
4551                         esac
4552                         break
4553                         ;;
4554                 (.-)
4555                         ;;
4556                 (*)
4557                         CF_MSG_LOG(given option \"$cf_option\", no match \"$cf_result\")
4558                         ;;
4559                 esac
4560         done
4561         rm -f cf_makeflags.tmp
4562 ])
4563
4564 AC_SUBST(cf_cv_makeflags)
4565 ])dnl
4566 dnl ---------------------------------------------------------------------------
4567 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
4568 dnl ------------
4569 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
4570 dnl a monocase filesystem.
4571 AC_DEFUN([CF_MAKE_TAGS],[
4572 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
4573
4574 AC_CHECK_PROGS(CTAGS, exctags ctags)
4575 AC_CHECK_PROGS(ETAGS, exetags etags)
4576
4577 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
4578
4579 if test "$cf_cv_mixedcase" = yes ; then
4580         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
4581 else
4582         MAKE_UPPER_TAGS=no
4583 fi
4584
4585 if test "$MAKE_UPPER_TAGS" = yes ; then
4586         MAKE_UPPER_TAGS=
4587 else
4588         MAKE_UPPER_TAGS="#"
4589 fi
4590
4591 if test "$MAKE_LOWER_TAGS" = yes ; then
4592         MAKE_LOWER_TAGS=
4593 else
4594         MAKE_LOWER_TAGS="#"
4595 fi
4596
4597 AC_SUBST(CTAGS)
4598 AC_SUBST(ETAGS)
4599
4600 AC_SUBST(MAKE_UPPER_TAGS)
4601 AC_SUBST(MAKE_LOWER_TAGS)
4602 ])dnl
4603 dnl ---------------------------------------------------------------------------
4604 dnl CF_MANPAGE_FORMAT version: 11 updated: 2015/04/18 08:56:57
4605 dnl -----------------
4606 dnl Option to allow user to override automatic configuration of manpage format.
4607 dnl There are several special cases:
4608 dnl
4609 dnl     gzip - man checks for, can display gzip'd files
4610 dnl     compress - man checks for, can display compressed files
4611 dnl     BSDI - files in the cat-directories are suffixed ".0"
4612 dnl     formatted - installer should format (put files in cat-directory)
4613 dnl     catonly - installer should only format, e.g., for a turnkey system.
4614 dnl
4615 dnl There are other configurations which this macro does not test, e.g., HPUX's
4616 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
4617 dnl convention would not match our use).
4618 AC_DEFUN([CF_MANPAGE_FORMAT],
4619 [
4620 AC_REQUIRE([CF_PATHSEP])
4621 AC_MSG_CHECKING(format of man-pages)
4622
4623 AC_ARG_WITH(manpage-format,
4624         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
4625                           optionally formatted/catonly, e.g., gzip,formatted],
4626         [MANPAGE_FORMAT=$withval],
4627         [MANPAGE_FORMAT=unknown])
4628
4629 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
4630 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
4631
4632 cf_unknown=
4633
4634 case $MANPAGE_FORMAT in
4635 (unknown)
4636         if test -z "$MANPATH" ; then
4637                 MANPATH="/usr/man:/usr/share/man"
4638         fi
4639
4640         # look for the 'date' man-page (it's most likely to be installed!)
4641         MANPAGE_FORMAT=
4642         cf_preform=no
4643         cf_catonly=yes
4644         cf_example=date
4645
4646         IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
4647         for cf_dir in $MANPATH; do
4648                 test -z "$cf_dir" && cf_dir=/usr/man
4649                 for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
4650                 do
4651                         cf_test=`echo $cf_name | sed -e 's/*//'`
4652                         if test "x$cf_test" = "x$cf_name" ; then
4653
4654                                 case "$cf_name" in
4655                                 (*.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
4656                                 (*.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
4657                                 (*.0)  MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
4658                                 (*)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
4659                                 esac
4660
4661                                 case "$cf_name" in
4662                                 ($cf_dir/man*)
4663                                         cf_catonly=no
4664                                         ;;
4665                                 ($cf_dir/cat*)
4666                                         cf_preform=yes
4667                                         ;;
4668                                 esac
4669                                 break
4670                         fi
4671
4672                         # if we found a match in either man* or cat*, stop looking
4673                         if test -n "$MANPAGE_FORMAT" ; then
4674                                 cf_found=no
4675                                 test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
4676                                 test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
4677                                 case "$cf_name" in
4678                                 ($cf_dir/cat*)
4679                                         cf_found=yes
4680                                         ;;
4681                                 esac
4682                                 test $cf_found=yes && break
4683                         fi
4684                 done
4685                 # only check the first directory in $MANPATH where we find manpages
4686                 if test -n "$MANPAGE_FORMAT" ; then
4687                         break
4688                 fi
4689         done
4690         # if we did not find the example, just assume it is normal
4691         test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
4692         IFS="$ac_save_ifs"
4693         ;;
4694 (*)
4695         for cf_option in $MANPAGE_FORMAT; do
4696         case $cf_option in
4697         (gzip|compress|BSDI|normal|formatted|catonly)
4698                 ;;
4699         (*)
4700                 cf_unknown="$cf_unknown $cf_option"
4701                 ;;
4702         esac
4703         done
4704         ;;
4705 esac
4706
4707 AC_MSG_RESULT($MANPAGE_FORMAT)
4708 if test -n "$cf_unknown" ; then
4709         AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
4710 fi
4711 ])dnl
4712 dnl ---------------------------------------------------------------------------
4713 dnl CF_MANPAGE_RENAMES version: 10 updated: 2015/08/05 20:44:28
4714 dnl ------------------
4715 dnl The Debian people have their own naming convention for manpages.  This
4716 dnl option lets us override the name of the file containing renaming, or
4717 dnl disable it altogether.
4718 AC_DEFUN([CF_MANPAGE_RENAMES],
4719 [
4720 AC_MSG_CHECKING(for manpage renaming)
4721
4722 AC_ARG_WITH(manpage-renames,
4723         [  --with-manpage-renames  specify manpage-renaming],
4724         [MANPAGE_RENAMES=$withval],
4725         [MANPAGE_RENAMES=yes])
4726
4727 case ".$MANPAGE_RENAMES" in
4728 (.no)
4729         ;;
4730 (.|.yes)
4731         # Debian 'man' program?
4732         if test -f /etc/debian_version ; then
4733                 MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
4734         else
4735                 MANPAGE_RENAMES=no
4736         fi
4737         ;;
4738 esac
4739
4740 if test "$MANPAGE_RENAMES" != no ; then
4741         if test -f $srcdir/man/$MANPAGE_RENAMES ; then
4742                 MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
4743         elif test ! -f $MANPAGE_RENAMES ; then
4744                 AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
4745         fi
4746
4747         test ! -d man && mkdir man
4748
4749         # Construct a sed-script to perform renaming within man-pages
4750         if test -n "$MANPAGE_RENAMES" ; then
4751                 test ! -d man && mkdir man
4752                 $SHELL $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
4753         fi
4754 fi
4755
4756 AC_MSG_RESULT($MANPAGE_RENAMES)
4757 AC_SUBST(MANPAGE_RENAMES)
4758 ])dnl
4759 dnl ---------------------------------------------------------------------------
4760 dnl CF_MANPAGE_SYMLINKS version: 6 updated: 2015/04/17 21:13:04
4761 dnl -------------------
4762 dnl Some people expect each tool to make all aliases for manpages in the
4763 dnl man-directory.  This accommodates the older, less-capable implementations
4764 dnl of 'man', and is optional.
4765 AC_DEFUN([CF_MANPAGE_SYMLINKS],
4766 [
4767 AC_MSG_CHECKING(if manpage aliases will be installed)
4768
4769 AC_ARG_WITH(manpage-aliases,
4770         [  --with-manpage-aliases  specify manpage-aliases using .so],
4771         [MANPAGE_ALIASES=$withval],
4772         [MANPAGE_ALIASES=yes])
4773
4774 AC_MSG_RESULT($MANPAGE_ALIASES)
4775
4776 case "x$LN_S" in
4777 (xln*)
4778         cf_use_symlinks=yes
4779         ;;
4780 (*)
4781         cf_use_symlinks=no
4782         ;;
4783 esac
4784
4785 MANPAGE_SYMLINKS=no
4786 if test "$MANPAGE_ALIASES" = yes ; then
4787 AC_MSG_CHECKING(if manpage symlinks should be used)
4788
4789 AC_ARG_WITH(manpage-symlinks,
4790         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
4791         [MANPAGE_SYMLINKS=$withval],
4792         [MANPAGE_SYMLINKS=$cf_use_symlinks])
4793
4794 if test "$$cf_use_symlinks" = no; then
4795 if test "$MANPAGE_SYMLINKS" = yes ; then
4796         AC_MSG_WARN(cannot make symlinks, will use .so files)
4797         MANPAGE_SYMLINKS=no
4798 fi
4799 fi
4800
4801 AC_MSG_RESULT($MANPAGE_SYMLINKS)
4802 fi
4803
4804 ])dnl
4805 dnl ---------------------------------------------------------------------------
4806 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
4807 dnl --------------
4808 dnl This option causes manpages to be run through tbl(1) to generate tables
4809 dnl correctly.
4810 AC_DEFUN([CF_MANPAGE_TBL],
4811 [
4812 AC_MSG_CHECKING(for manpage tbl)
4813
4814 AC_ARG_WITH(manpage-tbl,
4815         [  --with-manpage-tbl      specify manpage processing with tbl],
4816         [MANPAGE_TBL=$withval],
4817         [MANPAGE_TBL=no])
4818
4819 AC_MSG_RESULT($MANPAGE_TBL)
4820 ])dnl
4821 dnl ---------------------------------------------------------------------------
4822 dnl CF_MAN_PAGES version: 47 updated: 2017/08/12 07:58:51
4823 dnl ------------
4824 dnl Try to determine if the man-pages on the system are compressed, and if
4825 dnl so, what format is used.  Use this information to construct a script that
4826 dnl will install man-pages.
4827 AC_DEFUN([CF_MAN_PAGES],
4828 [
4829 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
4830 CF_MANPAGE_FORMAT
4831 CF_MANPAGE_RENAMES
4832 CF_MANPAGE_SYMLINKS
4833 CF_MANPAGE_TBL
4834
4835 if test "$prefix" = "NONE" ; then
4836         cf_prefix="$ac_default_prefix"
4837 else
4838         cf_prefix="$prefix"
4839 fi
4840
4841 case "$MANPAGE_FORMAT" in
4842 (*catonly*)
4843         cf_format=yes
4844         cf_inboth=no
4845         ;;
4846 (*formatted*)
4847         cf_format=yes
4848         cf_inboth=yes
4849         ;;
4850 (*)
4851         cf_format=no
4852         cf_inboth=no
4853         ;;
4854 esac
4855
4856 test ! -d man && mkdir man
4857
4858 cf_so_strip=
4859 cf_compress=
4860 case "$MANPAGE_FORMAT" in
4861 (*compress*)
4862         cf_so_strip="Z"
4863         cf_compress=compress
4864         ;;
4865 (*gzip*)
4866         cf_so_strip="gz"
4867         cf_compress=gzip
4868         ;;
4869 esac
4870
4871 cf_edit_man=./edit_man.sh
4872 cf_man_alias=`pwd`/man_alias.sed
4873
4874 cat >$cf_edit_man <<CF_EOF
4875 #! $SHELL
4876 # this script is generated by the configure-script CF_MAN_PAGES macro.
4877
4878 prefix="$cf_prefix"
4879 datarootdir="$datarootdir"
4880 datadir="$datadir"
4881
4882 NCURSES_MAJOR="$NCURSES_MAJOR"
4883 NCURSES_MINOR="$NCURSES_MINOR"
4884 NCURSES_PATCH="$NCURSES_PATCH"
4885
4886 NCURSES_OSPEED="$NCURSES_OSPEED"
4887 TERMINFO="$TERMINFO"
4888
4889 INSTALL="$INSTALL"
4890 INSTALL_DATA="$INSTALL_DATA"
4891
4892 transform="$program_transform_name"
4893
4894 TMP=\${TMPDIR:=/tmp}/man\$\$
4895 trap "rm -f \$TMP" 0 1 2 3 15
4896
4897 form=\[$]1
4898 shift || exit 1
4899
4900 verb=\[$]1
4901 shift || exit 1
4902
4903 mandir=\[$]1
4904 shift || exit 1
4905
4906 srcdir=\[$]1
4907 top_srcdir=\[$]srcdir/..
4908 shift || exit 1
4909
4910 if test "\$form" = normal ; then
4911         if test "$cf_format" = yes ; then
4912         if test "$cf_inboth" = no ; then
4913                 $SHELL \[$]0 format \$verb \$mandir \$srcdir \[$]*
4914                 exit $?
4915         fi
4916         fi
4917         cf_subdir=\$mandir/man
4918         cf_tables=$MANPAGE_TBL
4919 else
4920         cf_subdir=\$mandir/cat
4921         cf_tables=yes
4922 fi
4923
4924 # process the list of source-files
4925 for i in \[$]* ; do
4926 case \$i in
4927 (*.orig|*.rej) ;;
4928 (*.[[0-9]]*)
4929         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
4930         if test \$verb = installing ; then
4931         if test ! -d \$cf_subdir\${section} ; then
4932                 mkdir -p \$cf_subdir\$section
4933         fi
4934         fi
4935
4936         # replace variables in man page
4937         if test ! -f $cf_man_alias ; then
4938 cat >>$cf_man_alias <<-CF_EOF2
4939                 s,@DATADIR@,\$datadir,g
4940                 s,@TERMINFO@,\${TERMINFO:="no default value"},g
4941                 s,@TERMINFO_DIRS@,\${TERMINFO_DIRS:="no default value"},g
4942                 s,@NCURSES_MAJOR@,\${NCURSES_MAJOR:="no default value"},g
4943                 s,@NCURSES_MINOR@,\${NCURSES_MINOR:="no default value"},g
4944                 s,@NCURSES_PATCH@,\${NCURSES_PATCH:="no default value"},g
4945                 s,@NCURSES_OSPEED@,\${NCURSES_OSPEED:="no default value"},g
4946 CF_EOF
4947         ifelse($1,,,[
4948         for cf_name in $1
4949         do
4950                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4951                 cf_name=`echo $cf_name|sed "$program_transform_name"`
4952 cat >>$cf_edit_man <<-CF_EOF
4953                 s,@$cf_NAME@,$cf_name,g
4954 CF_EOF
4955         done
4956         ])
4957 cat >>$cf_edit_man <<CF_EOF
4958 CF_EOF2
4959                 echo "...made $cf_man_alias"
4960         fi
4961
4962         aliases=
4963         cf_source=\`basename \$i\`
4964         inalias=\$cf_source
4965         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
4966         if test ! -f \$inalias ; then
4967                 echo .. skipped \$cf_source
4968                 continue
4969         fi
4970 CF_EOF
4971
4972 if test "$MANPAGE_ALIASES" != no ; then
4973 cat >>$cf_edit_man <<CF_EOF
4974         nCurses=ignore.3x
4975         test $with_curses_h = yes && nCurses=ncurses.3x
4976         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
4977 CF_EOF
4978 fi
4979
4980 if test "$MANPAGE_RENAMES" = no ; then
4981 cat >>$cf_edit_man <<CF_EOF
4982         # perform program transformations for section 1 man pages
4983         if test \$section = 1 ; then
4984                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
4985         else
4986                 cf_target=\$cf_subdir\${section}/\$cf_source
4987         fi
4988 CF_EOF
4989 else
4990 cat >>$cf_edit_man <<CF_EOF
4991         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
4992         if test -z "\$cf_target" ; then
4993                 echo '? missing rename for '\$cf_source
4994                 cf_target="\$cf_source"
4995         fi
4996         cf_target="\$cf_subdir\${section}/\${cf_target}"
4997
4998 CF_EOF
4999 fi
5000
5001 cat >>$cf_edit_man <<CF_EOF
5002         sed     -f $cf_man_alias \\
5003 CF_EOF
5004
5005 if test -f $MANPAGE_RENAMES ; then
5006 cat >>$cf_edit_man <<CF_EOF
5007                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
5008 CF_EOF
5009 else
5010 cat >>$cf_edit_man <<CF_EOF
5011                 < \$i >\$TMP
5012 CF_EOF
5013 fi
5014
5015 cat >>$cf_edit_man <<CF_EOF
5016 if test \$cf_tables = yes ; then
5017         tbl \$TMP >\$TMP.out
5018         mv \$TMP.out \$TMP
5019 fi
5020 CF_EOF
5021
5022 if test $with_overwrite != yes ; then
5023 cat >>$cf_edit_man <<CF_EOF
5024         sed -e "/\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
5025         mv \$TMP.out \$TMP
5026 CF_EOF
5027 fi
5028
5029 if test $with_curses_h != yes ; then
5030 cat >>$cf_edit_man <<CF_EOF
5031         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
5032         mv \$TMP.out \$TMP
5033 CF_EOF
5034 fi
5035
5036 cat >>$cf_edit_man <<CF_EOF
5037         if test \$form = format ; then
5038                 nroff -man \$TMP >\$TMP.out
5039                 mv \$TMP.out \$TMP
5040         fi
5041 CF_EOF
5042
5043 if test -n "$cf_compress" ; then
5044 cat >>$cf_edit_man <<CF_EOF
5045         if test \$verb = installing ; then
5046         if ( $cf_compress -f \$TMP )
5047         then
5048                 mv \$TMP.$cf_so_strip \$TMP
5049         fi
5050         fi
5051         cf_target="\$cf_target.$cf_so_strip"
5052 CF_EOF
5053 fi
5054
5055 case "$MANPAGE_FORMAT" in
5056 (*BSDI*)
5057 cat >>$cf_edit_man <<CF_EOF
5058         if test \$form = format ; then
5059                 # BSDI installs only .0 suffixes in the cat directories
5060                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
5061         fi
5062 CF_EOF
5063   ;;
5064 esac
5065
5066 cat >>$cf_edit_man <<CF_EOF
5067         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
5068         if test \$verb = installing ; then
5069                 echo \$verb \$cf_target
5070                 \$INSTALL_DATA \$TMP \$cf_target
5071                 test -d \$cf_subdir\${section} &&
5072                 test -n "\$aliases" && (
5073                         cd \$cf_subdir\${section} && (
5074                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
5075                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
5076                                 cf_target=\`basename \$cf_target\`
5077                                 for cf_alias in \$aliases
5078                                 do
5079                                         if test \$section = 1 ; then
5080                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
5081                                         fi
5082
5083                                         if test "$MANPAGE_SYMLINKS" = yes ; then
5084                                                 if test -f \$cf_alias\${suffix} ; then
5085                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
5086                                                         then
5087                                                                 continue
5088                                                         fi
5089                                                 fi
5090                                                 echo .. \$verb alias \$cf_alias\${suffix}
5091 CF_EOF
5092 case "x$LN_S" in
5093 (*-f)
5094 cat >>$cf_edit_man <<CF_EOF
5095                                                 $LN_S \$cf_target \$cf_alias\${suffix}
5096 CF_EOF
5097         ;;
5098 (*)
5099 cat >>$cf_edit_man <<CF_EOF
5100                                                 rm -f \$cf_alias\${suffix}
5101                                                 $LN_S \$cf_target \$cf_alias\${suffix}
5102 CF_EOF
5103         ;;
5104 esac
5105 cat >>$cf_edit_man <<CF_EOF
5106                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
5107                                                 echo ".so \$cf_source" >\$TMP
5108 CF_EOF
5109 if test -n "$cf_compress" ; then
5110 cat >>$cf_edit_man <<CF_EOF
5111                                                 if test -n "$cf_so_strip" ; then
5112                                                         $cf_compress -f \$TMP
5113                                                         mv \$TMP.$cf_so_strip \$TMP
5114                                                 fi
5115 CF_EOF
5116 fi
5117 cat >>$cf_edit_man <<CF_EOF
5118                                                 echo .. \$verb alias \$cf_alias\${suffix}
5119                                                 rm -f \$cf_alias\${suffix}
5120                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
5121                                         fi
5122                                 done
5123                         )
5124                 )
5125         elif test \$verb = removing ; then
5126                 test -f \$cf_target && (
5127                         echo \$verb \$cf_target
5128                         rm -f \$cf_target
5129                 )
5130                 test -d \$cf_subdir\${section} &&
5131                 test -n "\$aliases" && (
5132                         cd \$cf_subdir\${section} && (
5133                                 for cf_alias in \$aliases
5134                                 do
5135                                         if test \$section = 1 ; then
5136                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
5137                                         fi
5138
5139                                         echo .. \$verb alias \$cf_alias\${suffix}
5140                                         rm -f \$cf_alias\${suffix}
5141                                 done
5142                         )
5143                 )
5144         else
5145 #               echo ".hy 0"
5146                 cat \$TMP
5147         fi
5148         ;;
5149 esac
5150 done
5151
5152 if test $cf_inboth = yes ; then
5153 if test \$form != format ; then
5154         $SHELL \[$]0 format \$verb \$mandir \$srcdir \[$]*
5155 fi
5156 fi
5157
5158 exit 0
5159 CF_EOF
5160 chmod 755 $cf_edit_man
5161
5162 ])dnl
5163 dnl ---------------------------------------------------------------------------
5164 dnl CF_MATH_LIB version: 9 updated: 2017/01/21 11:06:25
5165 dnl -----------
5166 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
5167 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
5168 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
5169 AC_DEFUN([CF_MATH_LIB],
5170 [
5171 AC_CACHE_CHECK(if -lm needed for math functions,
5172         cf_cv_need_libm,[
5173         AC_TRY_LINK([
5174         #include <stdio.h>
5175         #include <stdlib.h>
5176         #include <math.h>
5177         ],
5178         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
5179         [cf_cv_need_libm=no],
5180         [cf_cv_need_libm=yes])])
5181 if test "$cf_cv_need_libm" = yes
5182 then
5183 ifelse($1,,[
5184         CF_ADD_LIB(m)
5185 ],[$1=-lm])
5186 fi
5187 ])
5188 dnl ---------------------------------------------------------------------------
5189 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
5190 dnl ----------------------
5191 dnl Check if the file-system supports mixed-case filenames.  If we're able to
5192 dnl create a lowercase name and see it as uppercase, it doesn't support that.
5193 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
5194 [
5195 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
5196 if test "$cross_compiling" = yes ; then
5197         case $target_alias in
5198         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
5199                 cf_cv_mixedcase=no
5200                 ;;
5201         (*)
5202                 cf_cv_mixedcase=yes
5203                 ;;
5204         esac
5205 else
5206         rm -f conftest CONFTEST
5207         echo test >conftest
5208         if test -f CONFTEST ; then
5209                 cf_cv_mixedcase=no
5210         else
5211                 cf_cv_mixedcase=yes
5212         fi
5213         rm -f conftest CONFTEST
5214 fi
5215 ])
5216 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
5217 ])dnl
5218 dnl ---------------------------------------------------------------------------
5219 dnl CF_MKSTEMP version: 10 updated: 2017/01/21 11:12:16
5220 dnl ----------
5221 dnl Check for a working mkstemp.  This creates two files, checks that they are
5222 dnl successfully created and distinct (AmigaOS apparently fails on the last).
5223 AC_DEFUN([CF_MKSTEMP],[
5224 AC_CHECK_HEADERS( \
5225 unistd.h \
5226 )
5227 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
5228 rm -rf conftest*
5229 AC_TRY_RUN([
5230 #include <sys/types.h>
5231 #ifdef HAVE_UNISTD_H
5232 #include <unistd.h>
5233 #endif
5234 #include <stdlib.h>
5235 #include <stdio.h>
5236 #include <string.h>
5237 #include <sys/stat.h>
5238 int main(void)
5239 {
5240         char *tmpl = "conftestXXXXXX";
5241         char name[2][80];
5242         int n;
5243         int result = 0;
5244         int fd;
5245         struct stat sb;
5246
5247         umask(077);
5248         for (n = 0; n < 2; ++n) {
5249                 strcpy(name[n], tmpl);
5250                 if ((fd = mkstemp(name[n])) >= 0) {
5251                         if (!strcmp(name[n], tmpl)
5252                          || stat(name[n], &sb) != 0
5253                          || (sb.st_mode & S_IFMT) != S_IFREG
5254                          || (sb.st_mode & 077) != 0) {
5255                                 result = 1;
5256                         }
5257                         close(fd);
5258                 }
5259         }
5260         if (result == 0
5261          && !strcmp(name[0], name[1]))
5262                 result = 1;
5263         ${cf_cv_main_return:-return}(result);
5264 }
5265 ],[cf_cv_func_mkstemp=yes
5266 ],[cf_cv_func_mkstemp=no
5267 ],[cf_cv_func_mkstemp=maybe])
5268 ])
5269 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
5270         AC_CHECK_FUNC(mkstemp)
5271 fi
5272 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
5273         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
5274 fi
5275 ])dnl
5276 dnl ---------------------------------------------------------------------------
5277 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
5278 dnl ----------
5279 dnl Write a debug message to config.log, along with the line number in the
5280 dnl configure script.
5281 AC_DEFUN([CF_MSG_LOG],[
5282 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
5283 ])dnl
5284 dnl ---------------------------------------------------------------------------
5285 dnl CF_NCURSES_ABI_6 version: 3 updated: 2015/06/06 16:10:11
5286 dnl ----------------
5287 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
5288 dnl warn about this.
5289 AC_DEFUN([CF_NCURSES_ABI_6],[
5290 if test "${with_abi_version+set}" != set; then
5291         case $cf_cv_rel_version in
5292         (5.*)
5293                 cf_cv_rel_version=6.0
5294                 cf_cv_abi_version=6
5295                 AC_MSG_WARN(overriding ABI version to $cf_cv_abi_version)
5296                 ;;
5297         esac
5298 fi
5299 ])dnl
5300 dnl ---------------------------------------------------------------------------
5301 dnl CF_NCURSES_WITH_ABI_VERSION version: 2 updated: 2015/12/19 17:51:52
5302 dnl ---------------------------
5303 dnl Allow ncurses's ABI to be overridden.  Generally this happens when a
5304 dnl packager has incremented the ABI past that used in the original package,
5305 dnl and wishes to keep doing this.
5306 dnl
5307 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
5308 dnl symbol.
5309 AC_DEFUN([CF_NCURSES_WITH_ABI_VERSION],[
5310 CF_WITH_ABI_VERSION($1)
5311 if test "x$cf_cv_abi_version" != "x$with_abi_version"
5312 then
5313         case $cf_cv_rel_version in
5314         (5.*)
5315                 cf_cv_rel_version=$with_abi_version.0
5316                 ;;
5317         esac
5318 fi
5319 ])dnl
5320 dnl ---------------------------------------------------------------------------
5321 dnl CF_NO_LEAKS_OPTION version: 6 updated: 2015/04/12 15:39:00
5322 dnl ------------------
5323 dnl see CF_WITH_NO_LEAKS
5324 AC_DEFUN([CF_NO_LEAKS_OPTION],[
5325 AC_MSG_CHECKING(if you want to use $1 for testing)
5326 AC_ARG_WITH($1,
5327         [$2],
5328         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
5329          $4
5330 ])
5331         : ${with_cflags:=-g}
5332         : ${with_no_leaks:=yes}
5333          with_$1=yes],
5334         [with_$1=])
5335 AC_MSG_RESULT(${with_$1:-no})
5336
5337 case .$with_cflags in
5338 (.*-g*)
5339         case .$CFLAGS in
5340         (.*-g*)
5341                 ;;
5342         (*)
5343                 CF_ADD_CFLAGS([-g])
5344                 ;;
5345         esac
5346         ;;
5347 esac
5348 ])dnl
5349 dnl ---------------------------------------------------------------------------
5350 dnl CF_NUMBER_SYNTAX version: 2 updated: 2015/04/17 21:13:04
5351 dnl ----------------
5352 dnl Check if the given variable is a number.  If not, report an error.
5353 dnl $1 is the variable
5354 dnl $2 is the message
5355 AC_DEFUN([CF_NUMBER_SYNTAX],[
5356 if test -n "$1" ; then
5357   case $1 in
5358   ([[0-9]]*)
5359         ;;
5360   (*)
5361         AC_MSG_ERROR($2 is not a number: $1)
5362         ;;
5363   esac
5364 else
5365   AC_MSG_ERROR($2 value is empty)
5366 fi
5367 ])dnl
5368 dnl ---------------------------------------------------------------------------
5369 dnl CF_OBJ_SUBDIR version: 7 updated: 2015/04/17 21:13:04
5370 dnl -------------
5371 dnl Compute the object-directory name from the given model name
5372 AC_DEFUN([CF_OBJ_SUBDIR],
5373 [
5374         case $1 in
5375         (libtool) $2='obj_lo'  ;;
5376         (normal)  $2='objects' ;;
5377         (debug)   $2='obj_g' ;;
5378         (profile) $2='obj_p' ;;
5379         (shared)
5380                 case $cf_cv_system_name in
5381                 (cygwin|msys)
5382                         $2='objects' ;;
5383                 (*)
5384                         $2='obj_s' ;;
5385                 esac
5386         esac
5387 ])dnl
5388 dnl ---------------------------------------------------------------------------
5389 dnl CF_PATHSEP version: 7 updated: 2015/04/12 15:39:00
5390 dnl ----------
5391 dnl Provide a value for the $PATH and similar separator (or amend the value
5392 dnl as provided in autoconf 2.5x).
5393 AC_DEFUN([CF_PATHSEP],
5394 [
5395         AC_MSG_CHECKING(for PATH separator)
5396         case $cf_cv_system_name in
5397         (os2*)  PATH_SEPARATOR=';'  ;;
5398         (*)     ${PATH_SEPARATOR:=':'}  ;;
5399         esac
5400 ifelse([$1],,,[$1=$PATH_SEPARATOR])
5401         AC_SUBST(PATH_SEPARATOR)
5402         AC_MSG_RESULT($PATH_SEPARATOR)
5403 ])dnl
5404 dnl ---------------------------------------------------------------------------
5405 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
5406 dnl --------------
5407 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
5408 dnl begins with one of the prefix/exec_prefix variables, and then again if the
5409 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
5410 dnl delayed evaluation of those symbols.
5411 AC_DEFUN([CF_PATH_SYNTAX],[
5412 if test "x$prefix" != xNONE; then
5413         cf_path_syntax="$prefix"
5414 else
5415         cf_path_syntax="$ac_default_prefix"
5416 fi
5417
5418 case ".[$]$1" in
5419 (.\[$]\(*\)*|.\'*\'*)
5420         ;;
5421 (..|./*|.\\*)
5422         ;;
5423 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
5424         ;;
5425 (.\[$]{*prefix}*|.\[$]{*dir}*)
5426         eval $1="[$]$1"
5427         case ".[$]$1" in
5428         (.NONE/*)
5429                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
5430                 ;;
5431         esac
5432         ;;
5433 (.no|.NONE/*)
5434         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
5435         ;;
5436 (*)
5437         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
5438         ;;
5439 esac
5440 ])dnl
5441 dnl ---------------------------------------------------------------------------
5442 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
5443 dnl -------------
5444 dnl Check for the package-config program, unless disabled by command-line.
5445 AC_DEFUN([CF_PKG_CONFIG],
5446 [
5447 AC_MSG_CHECKING(if you want to use pkg-config)
5448 AC_ARG_WITH(pkg-config,
5449         [  --with-pkg-config{=path} enable/disable use of pkg-config],
5450         [cf_pkg_config=$withval],
5451         [cf_pkg_config=yes])
5452 AC_MSG_RESULT($cf_pkg_config)
5453
5454 case $cf_pkg_config in
5455 (no)
5456         PKG_CONFIG=none
5457         ;;
5458 (yes)
5459         CF_ACVERSION_CHECK(2.52,
5460                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
5461                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
5462         ;;
5463 (*)
5464         PKG_CONFIG=$withval
5465         ;;
5466 esac
5467
5468 test -z "$PKG_CONFIG" && PKG_CONFIG=none
5469 if test "$PKG_CONFIG" != none ; then
5470         CF_PATH_SYNTAX(PKG_CONFIG)
5471 elif test "x$cf_pkg_config" != xno ; then
5472         AC_MSG_WARN(pkg-config is not installed)
5473 fi
5474
5475 AC_SUBST(PKG_CONFIG)
5476 ])dnl
5477 dnl ---------------------------------------------------------------------------
5478 dnl CF_POSIX_C_SOURCE version: 11 updated: 2018/12/31 20:46:17
5479 dnl -----------------
5480 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
5481 dnl
5482 dnl     POSIX.1-1990                            _POSIX_SOURCE
5483 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
5484 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
5485 dnl             Bindings Option
5486 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
5487 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
5488 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
5489 dnl
5490 dnl Parameters:
5491 dnl     $1 is the nominal value for _POSIX_C_SOURCE
5492 AC_DEFUN([CF_POSIX_C_SOURCE],
5493 [AC_REQUIRE([CF_POSIX_VISIBLE])dnl
5494
5495 if test "$cf_cv_posix_visible" = no; then
5496
5497 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
5498
5499 cf_save_CFLAGS="$CFLAGS"
5500 cf_save_CPPFLAGS="$CPPFLAGS"
5501
5502 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
5503 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
5504
5505 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
5506         CF_MSG_LOG(if the symbol is already defined go no further)
5507         AC_TRY_COMPILE([#include <sys/types.h>],[
5508 #ifndef _POSIX_C_SOURCE
5509 make an error
5510 #endif],
5511         [cf_cv_posix_c_source=no],
5512         [cf_want_posix_source=no
5513          case .$cf_POSIX_C_SOURCE in
5514          (.[[12]]??*)
5515                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
5516                 ;;
5517          (.2)
5518                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
5519                 cf_want_posix_source=yes
5520                 ;;
5521          (.*)
5522                 cf_want_posix_source=yes
5523                 ;;
5524          esac
5525          if test "$cf_want_posix_source" = yes ; then
5526                 AC_TRY_COMPILE([#include <sys/types.h>],[
5527 #ifdef _POSIX_SOURCE
5528 make an error
5529 #endif],[],
5530                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
5531          fi
5532          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
5533          CFLAGS="$cf_trim_CFLAGS"
5534          CPPFLAGS="$cf_trim_CPPFLAGS"
5535          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
5536          CF_MSG_LOG(if the second compile does not leave our definition intact error)
5537          AC_TRY_COMPILE([#include <sys/types.h>],[
5538 #ifndef _POSIX_C_SOURCE
5539 make an error
5540 #endif],,
5541          [cf_cv_posix_c_source=no])
5542          CFLAGS="$cf_save_CFLAGS"
5543          CPPFLAGS="$cf_save_CPPFLAGS"
5544         ])
5545 ])
5546
5547 if test "$cf_cv_posix_c_source" != no ; then
5548         CFLAGS="$cf_trim_CFLAGS"
5549         CPPFLAGS="$cf_trim_CPPFLAGS"
5550         CF_ADD_CFLAGS($cf_cv_posix_c_source)
5551 fi
5552
5553 fi # cf_cv_posix_visible
5554
5555 ])dnl
5556 dnl ---------------------------------------------------------------------------
5557 dnl CF_POSIX_VISIBLE version: 1 updated: 2018/12/31 20:46:17
5558 dnl ----------------
5559 dnl POSIX documents test-macros which an application may set before any system
5560 dnl headers are included to make features available.
5561 dnl
5562 dnl Some BSD platforms (originally FreeBSD, but copied by a few others)
5563 dnl diverged from POSIX in 2002 by setting symbols which make all of the most
5564 dnl recent features visible in the system header files unless the application
5565 dnl overrides the corresponding test-macros.  Doing that introduces portability
5566 dnl problems.
5567 dnl
5568 dnl This macro makes a special check for the symbols used for this, to avoid a
5569 dnl conflicting definition.
5570 AC_DEFUN([CF_POSIX_VISIBLE],
5571 [
5572 AC_CACHE_CHECK(if the POSIX test-macros are already defined,cf_cv_posix_visible,[
5573 AC_TRY_COMPILE([#include <stdio.h>],[
5574 #if defined(__POSIX_VISIBLE) && ((__POSIX_VISIBLE - 0L) > 0) \
5575         && defined(__XSI_VISIBLE) && ((__XSI_VISIBLE - 0L) > 0) \
5576         && defined(__BSD_VISIBLE) && ((__BSD_VISIBLE - 0L) > 0) \
5577         && defined(__ISO_C_VISIBLE) && ((__ISO_C_VISIBLE - 0L) > 0)
5578 #error conflicting symbols found
5579 #endif
5580 ],[cf_cv_posix_visible=no],[cf_cv_posix_visible=yes])
5581 ])
5582 ])dnl
5583 dnl ---------------------------------------------------------------------------
5584 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
5585 dnl ------------
5586 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
5587 dnl
5588 dnl $1 = symbol to test
5589 dnl $2 = value (if any) to use for a predefinition
5590 AC_DEFUN([CF_PREDEFINE],
5591 [
5592 AC_MSG_CHECKING(if we must define $1)
5593 AC_TRY_COMPILE([#include <sys/types.h>
5594 ],[
5595 #ifndef $1
5596 make an error
5597 #endif],[cf_result=no],[cf_result=yes])
5598 AC_MSG_RESULT($cf_result)
5599
5600 if test "$cf_result" = yes ; then
5601         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
5602 elif test "x$2" != "x" ; then
5603         AC_MSG_CHECKING(checking for compatible value versus $2)
5604         AC_TRY_COMPILE([#include <sys/types.h>
5605 ],[
5606 #if $1-$2 < 0
5607 make an error
5608 #endif],[cf_result=yes],[cf_result=no])
5609         AC_MSG_RESULT($cf_result)
5610         if test "$cf_result" = no ; then
5611                 # perhaps we can override it - try...
5612                 CPPFLAGS="$CPPFLAGS -D$1=$2"
5613         fi
5614 fi
5615 ])dnl
5616 dnl ---------------------------------------------------------------------------
5617 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
5618 dnl ------------
5619 dnl Append definitions and rules for the given programs to the subdirectory
5620 dnl Makefiles, and the recursion rule for the top-level Makefile.
5621 dnl
5622 dnl parameters
5623 dnl     $1 = script to run
5624 dnl     $2 = list of subdirectories
5625 dnl
5626 dnl variables
5627 dnl     $AWK
5628 AC_DEFUN([CF_PRG_RULES],
5629 [
5630 for cf_dir in $2
5631 do
5632         if test ! -d $srcdir/$cf_dir; then
5633                 continue
5634         elif test -f $srcdir/$cf_dir/programs; then
5635                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
5636         fi
5637 done
5638
5639 ])dnl
5640 dnl ---------------------------------------------------------------------------
5641 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
5642 dnl ----------
5643 dnl Check for archiver "ar".
5644 AC_DEFUN([CF_PROG_AR],[
5645 AC_CHECK_TOOL(AR, ar, ar)
5646 ])
5647 dnl ---------------------------------------------------------------------------
5648 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
5649 dnl -----------
5650 dnl Check for awk, ensure that the check found something.
5651 AC_DEFUN([CF_PROG_AWK],
5652 [
5653 AC_PROG_AWK
5654 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
5655 ])dnl
5656 dnl ---------------------------------------------------------------------------
5657 dnl CF_PROG_CC version: 4 updated: 2014/07/12 18:57:58
5658 dnl ----------
5659 dnl standard check for CC, plus followup sanity checks
5660 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
5661 AC_DEFUN([CF_PROG_CC],[
5662 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
5663 CF_GCC_VERSION
5664 CF_ACVERSION_CHECK(2.52,
5665         [AC_PROG_CC_STDC],
5666         [CF_ANSI_CC_REQD])
5667 CF_CC_ENV_FLAGS
5668 ])dnl
5669 dnl ---------------------------------------------------------------------------
5670 dnl CF_PROG_CC_C_O version: 5 updated: 2017/01/21 11:06:25
5671 dnl --------------
5672 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
5673 dnl the output file can be renamed, and allows for a shell variable that can
5674 dnl be used later.  The parameter is either CC or CXX.  The result is the
5675 dnl cache variable:
5676 dnl     $cf_cv_prog_CC_c_o
5677 dnl     $cf_cv_prog_CXX_c_o
5678 dnl
5679 dnl $1 = compiler
5680 dnl $2 = compiler options, if any
5681 AC_DEFUN([CF_PROG_CC_C_O],
5682 [AC_REQUIRE([AC_PROG_CC])dnl
5683 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
5684 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
5685 [
5686 cat > conftest.$ac_ext <<CF_EOF
5687 int main(void)
5688 {
5689         ${cf_cv_main_return:-return}(0);
5690 }
5691 CF_EOF
5692 # We do the test twice because some compilers refuse to overwrite an
5693 # existing .o file with -o, though they will create one.
5694 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
5695 if AC_TRY_EVAL(ac_try) &&
5696   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
5697 then
5698   eval cf_cv_prog_$1_c_o=yes
5699 else
5700   eval cf_cv_prog_$1_c_o=no
5701 fi
5702 rm -rf conftest*
5703 ])dnl
5704 if test $cf_cv_prog_$1_c_o = yes; then
5705   AC_MSG_RESULT([yes])
5706 else
5707   AC_MSG_RESULT([no])
5708 fi
5709 ])dnl
5710 dnl ---------------------------------------------------------------------------
5711 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
5712 dnl -------------
5713 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
5714 dnl This macro adds a check to ensure the script found something.
5715 AC_DEFUN([CF_PROG_EGREP],
5716 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
5717         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
5718                 then ac_cv_prog_egrep='grep -E'
5719                 else ac_cv_prog_egrep='egrep'
5720         fi])
5721         EGREP=$ac_cv_prog_egrep
5722         AC_SUBST([EGREP])
5723         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
5724 ])dnl
5725 dnl ---------------------------------------------------------------------------
5726 dnl CF_PROG_GNAT version: 8 updated: 2018/11/10 19:47:04
5727 dnl ------------
5728 dnl Check for gnatmake, ensure that it is complete.
5729 AC_DEFUN([CF_PROG_GNAT],[
5730 cf_ada_make=gnatmake
5731 cf_ada_config="#"
5732 AC_CHECK_PROG(gnatmake_exists, $cf_ada_make, yes, no)
5733 if test "$ac_cv_prog_gnatmake_exists" = no; then
5734         cf_ada_make=
5735         cf_cv_prog_gnat_correct=no
5736 else
5737         AC_CHECK_PROG(gprconfig_exists, gprconfig, yes, no)
5738         if test "$ac_cv_prog_gprconfig_exists" = yes
5739         then
5740                 rm -rf conftest* *~conftest*
5741                 if mkdir conftest.src
5742                 then
5743                         cf_ada_config=""
5744                         cd conftest.src
5745                         for cf_gprconfig in Ada C
5746                         do
5747                                 AC_MSG_CHECKING(for gprconfig name for $cf_gprconfig)
5748                                 if test $cf_gprconfig = C
5749                                 then
5750                                         for cf_gprconfig_param in \
5751                                                 $cf_gprconfig,,,,GNATGCC \
5752                                                 $cf_gprconfig,,,,GCC \
5753                                                 $cf_gprconfig
5754                                         do
5755                                                 cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
5756                                                 test -n "$cf_gprconfig_value" && break
5757                                         done
5758                                 else
5759                                         cf_gprconfig_param=$cf_gprconfig
5760                                         cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
5761                                 fi
5762                                 if test -n "$cf_gprconfig_value"
5763                                 then
5764                                         eval cf_ada_config_[$]cf_gprconfig=[$]cf_gprconfig_value
5765                                         AC_MSG_RESULT($cf_gprconfig_value)
5766                                 else
5767                                         AC_MSG_RESULT(missing)
5768                                         cf_ada_config="#"
5769                                         break
5770                                 fi
5771                         done
5772                         cd ..
5773                         rm -rf conftest* *~conftest*
5774                 fi
5775         else
5776                 # gprconfig is newer than gnatmake; we can continue...
5777                 cf_ada_config="##"
5778         fi
5779         if test "x$cf_ada_config" != "x#"
5780         then
5781                 CF_GNAT_VERSION
5782                 AC_CHECK_PROG(M4_exists, m4, yes, no)
5783                 if test "$ac_cv_prog_M4_exists" = no; then
5784                         cf_cv_prog_gnat_correct=no
5785                         echo Ada95 binding required program m4 not found. Ada95 binding disabled.
5786                 fi
5787                 if test "$cf_cv_prog_gnat_correct" = yes; then
5788                         AC_MSG_CHECKING(if GNAT works)
5789                         CF_GNAT_TRY_RUN([procedure conftest;],
5790 [with Text_IO;
5791 with GNAT.OS_Lib;
5792 procedure conftest is
5793 begin
5794    Text_IO.Put ("Hello World");
5795    Text_IO.New_Line;
5796    GNAT.OS_Lib.OS_Exit (0);
5797 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
5798                         AC_MSG_RESULT($cf_cv_prog_gnat_correct)
5799                 fi
5800         else
5801                 cf_cv_prog_gnat_correct=no
5802         fi
5803 fi
5804
5805 AC_SUBST(cf_ada_make)
5806 AC_SUBST(cf_ada_config)
5807 AC_SUBST(cf_ada_config_Ada)
5808 AC_SUBST(cf_ada_config_C)
5809 ])dnl
5810 dnl ---------------------------------------------------------------------------
5811 dnl CF_PROG_INSTALL version: 7 updated: 2015/04/18 08:56:57
5812 dnl ---------------
5813 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
5814 dnl misc/tabset install won't work properly.  Usually this happens only when
5815 dnl using the fallback mkinstalldirs script
5816 AC_DEFUN([CF_PROG_INSTALL],
5817 [AC_PROG_INSTALL
5818 case $INSTALL in
5819 (/*)
5820         ;;
5821 (*)
5822         CF_DIRNAME(cf_dir,$INSTALL)
5823         test -z "$cf_dir" && cf_dir=.
5824         INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
5825         ;;
5826 esac
5827 ])dnl
5828 dnl ---------------------------------------------------------------------------
5829 dnl CF_PROG_LDCONFIG version: 5 updated: 2015/04/18 08:56:57
5830 dnl ----------------
5831 dnl Check for ldconfig, needed to fixup shared libraries that would be built
5832 dnl and then used in the install.
5833 AC_DEFUN([CF_PROG_LDCONFIG],[
5834 if test "$cross_compiling" = yes ; then
5835         LDCONFIG=:
5836 else
5837         case "$cf_cv_system_name" in
5838         (dragonfly*|mirbsd*|freebsd*)
5839                 test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
5840                 ;;
5841         (*) LDPATH=$PATH:/sbin:/usr/sbin
5842                 AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
5843                 ;;
5844         esac
5845 fi
5846 AC_SUBST(LDCONFIG)
5847 ])dnl
5848 dnl ---------------------------------------------------------------------------
5849 dnl CF_PROG_LINT version: 3 updated: 2016/05/22 15:25:54
5850 dnl ------------
5851 AC_DEFUN([CF_PROG_LINT],
5852 [
5853 AC_CHECK_PROGS(LINT, lint cppcheck splint)
5854 AC_SUBST(LINT_OPTS)
5855 ])dnl
5856 dnl ---------------------------------------------------------------------------
5857 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
5858 dnl ------------
5859 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
5860 dnl option if it is supported.
5861 AC_DEFUN([CF_PROG_LN_S],[
5862 AC_PROG_LN_S
5863 AC_MSG_CHECKING(if $LN_S -f options work)
5864
5865 rm -f conf$$.src conf$$dst
5866 echo >conf$$.dst
5867 echo first >conf$$.src
5868 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
5869         cf_prog_ln_sf=yes
5870 else
5871         cf_prog_ln_sf=no
5872 fi
5873 rm -f conf$$.dst conf$$src
5874 AC_MSG_RESULT($cf_prog_ln_sf)
5875
5876 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
5877 ])dnl
5878 dnl ---------------------------------------------------------------------------
5879 dnl CF_REGEX version: 12 updated: 2015/04/18 08:56:57
5880 dnl --------
5881 dnl Attempt to determine if we've got one of the flavors of regular-expression
5882 dnl code that we can support.
5883 AC_DEFUN([CF_REGEX],
5884 [
5885
5886 cf_regex_func=no
5887
5888 cf_regex_libs="regex re"
5889 case $host_os in
5890 (mingw*)
5891         cf_regex_libs="gnurx $cf_regex_libs"
5892         ;;
5893 esac
5894
5895 AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
5896         for cf_regex_lib in $cf_regex_libs
5897         do
5898                 AC_CHECK_LIB($cf_regex_lib,regcomp,[
5899                                 CF_ADD_LIB($cf_regex_lib)
5900                                 cf_regex_func=regcomp
5901                                 break])
5902         done
5903 ])
5904
5905 if test "$cf_regex_func" = no ; then
5906         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
5907                 AC_CHECK_LIB(gen,compile,[
5908                                 CF_ADD_LIB(gen)
5909                                 cf_regex_func=compile])])
5910 fi
5911
5912 if test "$cf_regex_func" = no ; then
5913         AC_MSG_WARN(cannot find regular expression library)
5914 fi
5915
5916 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
5917
5918 cf_cv_regex_hdrs=no
5919 case $cf_regex_func in
5920 (compile)
5921         for cf_regex_hdr in regexp.h regexpr.h
5922         do
5923                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
5924                         char *p = compile("", "", "", 0);
5925                         int x = step("", "");
5926                 ],[
5927                         cf_cv_regex_hdrs=$cf_regex_hdr
5928                         break
5929                 ])
5930         done
5931         ;;
5932 (*)
5933         for cf_regex_hdr in regex.h
5934         do
5935                 AC_TRY_LINK([#include <sys/types.h>
5936 #include <$cf_regex_hdr>],[
5937                         regex_t *p;
5938                         int x = regcomp(p, "", 0);
5939                         int y = regexec(p, "", 0, 0, 0);
5940                         regfree(p);
5941                 ],[
5942                         cf_cv_regex_hdrs=$cf_regex_hdr
5943                         break
5944                 ])
5945         done
5946         ;;
5947 esac
5948
5949 ])
5950
5951 case $cf_cv_regex_hdrs in
5952         (no)            AC_MSG_WARN(no regular expression header found) ;;
5953         (regex.h)       AC_DEFINE(HAVE_REGEX_H_FUNCS,1,[Define to 1 to include regex.h for regular expressions]) ;;
5954         (regexp.h)      AC_DEFINE(HAVE_REGEXP_H_FUNCS,1,[Define to 1 to include regexp.h for regular expressions]) ;;
5955         (regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS,1,[Define to 1 to include regexpr.h for regular expressions]) ;;
5956 esac
5957 ])dnl
5958 dnl ---------------------------------------------------------------------------
5959 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
5960 dnl ----------------
5961 dnl Remove all -U and -D options that refer to the given symbol from a list
5962 dnl of C compiler options.  This works around the problem that not all
5963 dnl compilers process -U and -D options from left-to-right, so a -U option
5964 dnl cannot be used to cancel the effect of a preceding -D option.
5965 dnl
5966 dnl $1 = target (which could be the same as the source variable)
5967 dnl $2 = source (including '$')
5968 dnl $3 = symbol to remove
5969 define([CF_REMOVE_DEFINE],
5970 [
5971 $1=`echo "$2" | \
5972         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
5973                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
5974 ])dnl
5975 dnl ---------------------------------------------------------------------------
5976 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
5977 dnl -------------
5978 dnl Remove the given library from the symbol
5979 dnl
5980 dnl $1 = target (which could be the same as the source variable)
5981 dnl $2 = source (including '$')
5982 dnl $3 = library to remove
5983 define([CF_REMOVE_LIB],
5984 [
5985 # remove $3 library from $2
5986 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
5987 ])dnl
5988 dnl ---------------------------------------------------------------------------
5989 dnl CF_RPATH_HACK version: 11 updated: 2013/09/01 13:02:00
5990 dnl -------------
5991 AC_DEFUN([CF_RPATH_HACK],
5992 [
5993 AC_REQUIRE([CF_LD_RPATH_OPT])
5994 AC_MSG_CHECKING(for updated LDFLAGS)
5995 if test -n "$LD_RPATH_OPT" ; then
5996         AC_MSG_RESULT(maybe)
5997
5998         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
5999         cf_rpath_list="/usr/lib /lib"
6000         if test "$cf_ldd_prog" != no
6001         then
6002                 cf_rpath_oops=
6003
6004 AC_TRY_LINK([#include <stdio.h>],
6005                 [printf("Hello");],
6006                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
6007                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
6008
6009                 # If we passed the link-test, but get a "not found" on a given library,
6010                 # this could be due to inept reconfiguration of gcc to make it only
6011                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
6012                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
6013                 # /usr/local libraries.
6014                 if test -n "$cf_rpath_oops"
6015                 then
6016                         for cf_rpath_src in $cf_rpath_oops
6017                         do
6018                                 for cf_rpath_dir in \
6019                                         /usr/local \
6020                                         /usr/pkg \
6021                                         /opt/sfw
6022                                 do
6023                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
6024                                         then
6025                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
6026                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
6027                                                 break
6028                                         fi
6029                                 done
6030                         done
6031                 fi
6032         fi
6033
6034         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
6035
6036         CF_RPATH_HACK_2(LDFLAGS)
6037         CF_RPATH_HACK_2(LIBS)
6038
6039         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
6040 else
6041         AC_MSG_RESULT(no)
6042 fi
6043 AC_SUBST(EXTRA_LDFLAGS)
6044 ])dnl
6045 dnl ---------------------------------------------------------------------------
6046 dnl CF_RPATH_HACK_2 version: 7 updated: 2015/04/12 15:39:00
6047 dnl ---------------
6048 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
6049 dnl EXTRA_LDFLAGS for each -L option found.
6050 dnl
6051 dnl $cf_rpath_list contains a list of directories to ignore.
6052 dnl
6053 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
6054 dnl      but LIBS often has misplaced -L options.
6055 AC_DEFUN([CF_RPATH_HACK_2],
6056 [
6057 CF_VERBOSE(...checking $1 [$]$1)
6058
6059 cf_rpath_dst=
6060 for cf_rpath_src in [$]$1
6061 do
6062         case $cf_rpath_src in
6063         (-L*)
6064
6065                 # check if this refers to a directory which we will ignore
6066                 cf_rpath_skip=no
6067                 if test -n "$cf_rpath_list"
6068                 then
6069                         for cf_rpath_item in $cf_rpath_list
6070                         do
6071                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
6072                                 then
6073                                         cf_rpath_skip=yes
6074                                         break
6075                                 fi
6076                         done
6077                 fi
6078
6079                 if test "$cf_rpath_skip" = no
6080                 then
6081                         # transform the option
6082                         if test "$LD_RPATH_OPT" = "-R " ; then
6083                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
6084                         else
6085                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
6086                         fi
6087
6088                         # if we have not already added this, add it now
6089                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
6090                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
6091                         then
6092                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
6093                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
6094                         fi
6095                 fi
6096                 ;;
6097         esac
6098         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
6099 done
6100 $1=$cf_rpath_dst
6101
6102 CF_VERBOSE(...checked $1 [$]$1)
6103 AC_SUBST(EXTRA_LDFLAGS)
6104 ])dnl
6105 dnl ---------------------------------------------------------------------------
6106 dnl CF_SHARED_OPTS version: 93 updated: 2018/08/18 16:36:35
6107 dnl --------------
6108 dnl --------------
6109 dnl Attempt to determine the appropriate CC/LD options for creating a shared
6110 dnl library.
6111 dnl
6112 dnl Notes:
6113 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
6114 dnl the build-tree, i.e., by making use of the libraries that are compiled in
6115 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
6116 dnl shared library since that can lead to unexpected results at runtime.
6117 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
6118 dnl libraries are compiled in ../../lib
6119 dnl
6120 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
6121 dnl to install symbolic links to the rel/abi versions of shared libraries.
6122 dnl
6123 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
6124 dnl version when making symbolic links.
6125 dnl
6126 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
6127 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
6128 dnl (ex: libncurses.so.<ver>).
6129 dnl
6130 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
6131 AC_DEFUN([CF_SHARED_OPTS],
6132 [
6133         AC_REQUIRE([CF_LD_RPATH_OPT])
6134
6135         RM_SHARED_OPTS=
6136         LOCAL_LDFLAGS=
6137         LOCAL_LDFLAGS2=
6138         LD_SHARED_OPTS=
6139         INSTALL_LIB="-m 644"
6140         : ${rel_builddir:=.}
6141
6142         shlibdir=$libdir
6143         AC_SUBST(shlibdir)
6144
6145         MAKE_DLLS="#"
6146         AC_SUBST(MAKE_DLLS)
6147
6148         cf_cv_do_symlinks=no
6149         cf_ld_rpath_opt=
6150         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
6151
6152         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
6153         AC_ARG_WITH(shlib-version,
6154         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
6155         [test -z "$withval" && withval=auto
6156         case $withval in
6157         (yes)
6158                 cf_cv_shlib_version=auto
6159                 ;;
6160         (rel|abi|auto)
6161                 cf_cv_shlib_version=$withval
6162                 ;;
6163         (*)
6164                 AC_MSG_RESULT($withval)
6165                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
6166                 ;;
6167         esac
6168         ],[cf_cv_shlib_version=auto])
6169         AC_MSG_RESULT($cf_cv_shlib_version)
6170
6171         cf_cv_rm_so_locs=no
6172         cf_try_cflags=
6173
6174         # Some less-capable ports of gcc support only -fpic
6175         CC_SHARED_OPTS=
6176
6177         cf_try_fPIC=no
6178         if test "$GCC" = yes
6179         then
6180                 cf_try_fPIC=yes
6181         else
6182                 case $cf_cv_system_name in
6183                 (*linux*)       # e.g., PGI compiler
6184                         cf_try_fPIC=yes
6185                         ;;
6186                 esac
6187         fi
6188
6189         if test "$cf_try_fPIC" = yes
6190         then
6191                 AC_MSG_CHECKING(which $CC option to use)
6192                 cf_save_CFLAGS="$CFLAGS"
6193                 for CC_SHARED_OPTS in -fPIC -fpic ''
6194                 do
6195                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
6196                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
6197                 done
6198                 AC_MSG_RESULT($CC_SHARED_OPTS)
6199                 CFLAGS="$cf_save_CFLAGS"
6200         fi
6201
6202         cf_cv_shlib_version_infix=no
6203
6204         case $cf_cv_system_name in
6205         (aix4.[3-9]*|aix[[5-7]]*)
6206                 if test "$GCC" = yes; then
6207                         CC_SHARED_OPTS='-Wl,-brtl'
6208                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
6209                 else
6210                         CC_SHARED_OPTS='-brtl'
6211                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
6212                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
6213                 fi
6214                 ;;
6215         (beos*)
6216                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
6217                 ;;
6218         (cygwin*)
6219                 CC_SHARED_OPTS=
6220                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
6221                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
6222                 cf_cv_shlib_version=cygdll
6223                 cf_cv_shlib_version_infix=cygdll
6224                 shlibdir=$bindir
6225                 MAKE_DLLS=
6226                 cat >mk_shared_lib.sh <<-CF_EOF
6227                 #!$SHELL
6228                 SHARED_LIB=\[$]1
6229                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
6230                 shift
6231                 cat <<-EOF
6232                 Linking shared library
6233                 ** SHARED_LIB \[$]SHARED_LIB
6234                 ** IMPORT_LIB \[$]IMPORT_LIB
6235 EOF
6236                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
6237 CF_EOF
6238                 chmod +x mk_shared_lib.sh
6239                 ;;
6240         (msys*)
6241                 CC_SHARED_OPTS=
6242                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
6243                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
6244                 cf_cv_shlib_version=msysdll
6245                 cf_cv_shlib_version_infix=msysdll
6246                 shlibdir=$bindir
6247                 MAKE_DLLS=
6248                 cat >mk_shared_lib.sh <<-CF_EOF
6249                 #!$SHELL
6250                 SHARED_LIB=\[$]1
6251                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
6252                 shift
6253                 cat <<-EOF
6254                 Linking shared library
6255                 ** SHARED_LIB \[$]SHARED_LIB
6256                 ** IMPORT_LIB \[$]IMPORT_LIB
6257 EOF
6258                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
6259 CF_EOF
6260                 chmod +x mk_shared_lib.sh
6261                 ;;
6262         (darwin*)
6263                 cf_try_cflags="no-cpp-precomp"
6264                 CC_SHARED_OPTS="-dynamic"
6265                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
6266                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
6267                 cf_cv_shlib_version_infix=yes
6268                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
6269                         cf_save_LDFLAGS=$LDFLAGS
6270                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
6271                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
6272                                 LDFLAGS=$cf_save_LDFLAGS])
6273                 if test $cf_cv_ldflags_search_paths_first = yes; then
6274                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
6275                 fi
6276                 ;;
6277         (hpux[[7-8]]*)
6278                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
6279                 if test "$GCC" != yes; then
6280                         CC_SHARED_OPTS='+Z'
6281                 fi
6282                 MK_SHARED_LIB='${LD} ${LDFLAGS} -b -o $[@]'
6283                 INSTALL_LIB="-m 555"
6284                 ;;
6285         (hpux*)
6286                 # (tested with gcc 2.7.2 -- I don't have c89)
6287                 if test "$GCC" = yes; then
6288                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
6289                 else
6290                         CC_SHARED_OPTS='+Z'
6291                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
6292                 fi
6293                 MK_SHARED_LIB='${LD} ${LDFLAGS} +b ${libdir} -b -o $[@]'
6294                 # HP-UX shared libraries must be executable, and should be
6295                 # readonly to exploit a quirk in the memory manager.
6296                 INSTALL_LIB="-m 555"
6297                 ;;
6298         (interix*)
6299                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6300                 if test "$cf_cv_shlib_version" = rel; then
6301                         cf_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
6302                 else
6303                         cf_shared_soname='`basename $[@]`'
6304                 fi
6305                 CC_SHARED_OPTS=
6306                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $[@]'
6307                 ;;
6308         (irix*)
6309                 if test "$cf_cv_enable_rpath" = yes ; then
6310                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6311                 fi
6312                 # tested with IRIX 5.2 and 'cc'.
6313                 if test "$GCC" != yes; then
6314                         CC_SHARED_OPTS='-KPIC'
6315                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
6316                 else
6317                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,`basename $[@]` -o $[@]'
6318                 fi
6319                 cf_cv_rm_so_locs=yes
6320                 ;;
6321         (linux*|gnu*|k*bsd*-gnu)
6322                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
6323                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
6324                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6325                 fi
6326                 if test "$cf_cv_enable_rpath" = yes ; then
6327                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6328                 fi
6329                 CF_SHARED_SONAME
6330                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
6331                 ;;
6332         (mingw*)
6333                 cf_cv_shlib_version=mingw
6334                 cf_cv_shlib_version_infix=mingw
6335                 shlibdir=$bindir
6336                 MAKE_DLLS=
6337                 if test "$DFT_LWR_MODEL" = "shared" ; then
6338                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
6339                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6340                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
6341                 fi
6342                 CC_SHARED_OPTS=
6343                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
6344                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
6345                 cat >mk_shared_lib.sh <<-CF_EOF
6346                 #!$SHELL
6347                 SHARED_LIB=\[$]1
6348                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
6349                 shift
6350                 cat <<-EOF
6351                 Linking shared library
6352                 ** SHARED_LIB \[$]SHARED_LIB
6353                 ** IMPORT_LIB \[$]IMPORT_LIB
6354 EOF
6355                 exec \[$]* ${LDFLAGS} -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
6356 CF_EOF
6357                 chmod +x mk_shared_lib.sh
6358                 ;;
6359         (openbsd[[2-9]].*|mirbsd*)
6360                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
6361                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
6362                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6363                 fi
6364                 if test "$cf_cv_enable_rpath" = yes ; then
6365                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6366                 fi
6367                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
6368                 CF_SHARED_SONAME
6369                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
6370                 ;;
6371         (nto-qnx*|openbsd*|freebsd[[12]].*)
6372                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
6373                 MK_SHARED_LIB='${LD} ${LDFLAGS} -Bshareable -o $[@]'
6374                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6375                 ;;
6376         (dragonfly*|freebsd*)
6377                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
6378                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
6379                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
6380                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
6381                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6382                 fi
6383                 CF_SHARED_SONAME
6384                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
6385                 ;;
6386         (netbsd*)
6387                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
6388                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
6389                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
6390                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6391                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6392                         if test "$cf_cv_shlib_version" = auto; then
6393                         if test -f /usr/libexec/ld.elf_so; then
6394                                 cf_cv_shlib_version=abi
6395                         else
6396                                 cf_cv_shlib_version=rel
6397                         fi
6398                         fi
6399                         CF_SHARED_SONAME
6400                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
6401                 else
6402                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -Wl,-shared -Wl,-Bshareable -o $[@]'
6403                 fi
6404                 ;;
6405         (osf*|mls+*)
6406                 # tested with OSF/1 V3.2 and 'cc'
6407                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
6408                 # link with shared libs).
6409                 MK_SHARED_LIB='${LD} ${LDFLAGS} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
6410                 case $host_os in
6411                 (osf4*)
6412                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
6413                         ;;
6414                 esac
6415                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
6416                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
6417                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
6418                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6419                 fi
6420                 cf_cv_rm_so_locs=yes
6421                 ;;
6422         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
6423                 # tested with osr5.0.5
6424                 if test "$GCC" != yes; then
6425                         CC_SHARED_OPTS='-belf -KPIC'
6426                 fi
6427                 MK_SHARED_LIB='${LD} ${LDFLAGS} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
6428                 if test "$cf_cv_enable_rpath" = yes ; then
6429                         # only way is to set LD_RUN_PATH but no switch for it
6430                         RUN_PATH=$libdir
6431                 fi
6432                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6433                 LINK_PROGS='LD_RUN_PATH=${libdir}'
6434                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
6435                 ;;
6436         (sunos4*)
6437                 # tested with SunOS 4.1.1 and gcc 2.7.0
6438                 if test "$GCC" != yes; then
6439                         CC_SHARED_OPTS='-KPIC'
6440                 fi
6441                 MK_SHARED_LIB='${LD} ${LDFLAGS} -assert pure-text -o $[@]'
6442                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6443                 ;;
6444         (solaris2*)
6445                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
6446                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
6447                 if test "$DFT_LWR_MODEL" = "shared" ; then
6448                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
6449                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6450                 fi
6451                 if test "$cf_cv_enable_rpath" = yes ; then
6452                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
6453                 fi
6454                 CF_SHARED_SONAME
6455                 if test "$GCC" != yes; then
6456                         cf_save_CFLAGS="$CFLAGS"
6457                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
6458                         do
6459                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
6460                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
6461                         done
6462                         CFLAGS="$cf_save_CFLAGS"
6463                         CC_SHARED_OPTS=$cf_shared_opts
6464                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
6465                 else
6466                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
6467                 fi
6468                 ;;
6469         (sysv5uw7*|unix_sv*)
6470                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
6471                 if test "$GCC" != yes; then
6472                         CC_SHARED_OPTS='-KPIC'
6473                 fi
6474                 MK_SHARED_LIB='${LD} ${LDFLAGS} -d y -G -o [$]@'
6475                 ;;
6476         (*)
6477                 CC_SHARED_OPTS='unknown'
6478                 MK_SHARED_LIB='echo unknown'
6479                 ;;
6480         esac
6481
6482         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
6483         case "$cf_cv_shlib_version" in
6484         (rel|abi)
6485                 case "$MK_SHARED_LIB" in
6486                 (*'-o $[@]')
6487                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
6488                         ;;
6489                 (*)
6490                         AC_MSG_WARN(ignored --with-shlib-version)
6491                         ;;
6492                 esac
6493                 ;;
6494         esac
6495
6496         if test -n "$cf_try_cflags"
6497         then
6498 cat > conftest.$ac_ext <<EOF
6499 #line __oline__ "${as_me:-configure}"
6500 #include <stdio.h>
6501 int main(int argc, char *argv[[]])
6502 {
6503         printf("hello\n");
6504         return (argv[[argc-1]] == 0) ;
6505 }
6506 EOF
6507                 cf_save_CFLAGS="$CFLAGS"
6508                 for cf_opt in $cf_try_cflags
6509                 do
6510                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
6511                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
6512                         if AC_TRY_EVAL(ac_compile); then
6513                                 AC_MSG_RESULT(yes)
6514                                 cf_save_CFLAGS="$CFLAGS"
6515                         else
6516                                 AC_MSG_RESULT(no)
6517                         fi
6518                 done
6519                 CFLAGS="$cf_save_CFLAGS"
6520         fi
6521
6522
6523         # RPATH_LIST is a colon-separated list of directories
6524         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
6525         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
6526
6527         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
6528
6529         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
6530         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
6531
6532         AC_SUBST(CC_SHARED_OPTS)
6533         AC_SUBST(LD_RPATH_OPT)
6534         AC_SUBST(LD_SHARED_OPTS)
6535         AC_SUBST(MK_SHARED_LIB)
6536         AC_SUBST(RM_SHARED_OPTS)
6537
6538         AC_SUBST(LINK_PROGS)
6539         AC_SUBST(LINK_TESTS)
6540
6541         AC_SUBST(EXTRA_LDFLAGS)
6542         AC_SUBST(LOCAL_LDFLAGS)
6543         AC_SUBST(LOCAL_LDFLAGS2)
6544
6545         AC_SUBST(INSTALL_LIB)
6546         AC_SUBST(RPATH_LIST)
6547 ])dnl
6548 dnl ---------------------------------------------------------------------------
6549 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
6550 dnl ----------------
6551 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
6552 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
6553 dnl option.
6554 dnl
6555 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
6556 dnl If missing, use "rel".
6557 define([CF_SHARED_SONAME],
6558 [
6559         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
6560         if test "$cf_cv_shlib_version" = rel; then
6561                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
6562         else
6563                 cf_cv_shared_soname='`basename $[@]`'
6564         fi
6565 ])
6566 dnl ---------------------------------------------------------------------------
6567 dnl CF_SIGWINCH version: 1 updated: 2006/04/02 16:41:09
6568 dnl -----------
6569 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
6570 dnl programs need this test).
6571 dnl
6572 dnl This is really a MacOS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
6573 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
6574 dnl winsize declaration is left alone - we may revisit this if Apple choose to
6575 dnl break that part of the interface as well.
6576 AC_DEFUN([CF_SIGWINCH],
6577 [
6578 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
6579         AC_TRY_COMPILE([
6580 #include <sys/types.h>
6581 #include <sys/signal.h>
6582 ],[int x = SIGWINCH],
6583         [cf_cv_define_sigwinch=yes],
6584         [AC_TRY_COMPILE([
6585 #undef _XOPEN_SOURCE
6586 #undef _POSIX_SOURCE
6587 #undef _POSIX_C_SOURCE
6588 #include <sys/types.h>
6589 #include <sys/signal.h>
6590 ],[int x = SIGWINCH],
6591         [cf_cv_define_sigwinch=maybe],
6592         [cf_cv_define_sigwinch=no])
6593 ])
6594 ])
6595
6596 if test "$cf_cv_define_sigwinch" = maybe ; then
6597 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
6598 cf_cv_fixup_sigwinch=unknown
6599 cf_sigwinch=32
6600 while test $cf_sigwinch != 1
6601 do
6602         AC_TRY_COMPILE([
6603 #undef _XOPEN_SOURCE
6604 #undef _POSIX_SOURCE
6605 #undef _POSIX_C_SOURCE
6606 #include <sys/types.h>
6607 #include <sys/signal.h>
6608 ],[
6609 #if SIGWINCH != $cf_sigwinch
6610 make an error
6611 #endif
6612 int x = SIGWINCH],
6613         [cf_cv_fixup_sigwinch=$cf_sigwinch
6614          break])
6615
6616 cf_sigwinch=`expr $cf_sigwinch - 1`
6617 done
6618 ])
6619
6620         if test "$cf_cv_fixup_sigwinch" != unknown ; then
6621                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
6622         fi
6623 fi
6624 ])dnl
6625 dnl ---------------------------------------------------------------------------
6626 dnl CF_SIG_ATOMIC_T version: 3 updated: 2012/10/04 20:12:20
6627 dnl ---------------
6628 dnl signal handler, but there are some gcc depedencies in that recommendation.
6629 dnl Try anyway.
6630 AC_DEFUN([CF_SIG_ATOMIC_T],
6631 [
6632 AC_MSG_CHECKING(for signal global datatype)
6633 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
6634         for cf_type in \
6635                 "volatile sig_atomic_t" \
6636                 "sig_atomic_t" \
6637                 "int"
6638         do
6639         AC_TRY_COMPILE([
6640 #include <sys/types.h>
6641 #include <signal.h>
6642 #include <stdio.h>
6643
6644 extern $cf_type x;
6645 $cf_type x;
6646 static void handler(int sig)
6647 {
6648         x = 5;
6649 }],
6650                 [signal(SIGINT, handler);
6651                  x = 1],
6652                 [cf_cv_sig_atomic_t=$cf_type],
6653                 [cf_cv_sig_atomic_t=no])
6654                 test "$cf_cv_sig_atomic_t" != no && break
6655         done
6656         ])
6657 AC_MSG_RESULT($cf_cv_sig_atomic_t)
6658 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
6659 ])dnl
6660 dnl ---------------------------------------------------------------------------
6661 dnl CF_SIZECHANGE version: 14 updated: 2018/06/20 20:23:13
6662 dnl -------------
6663 dnl Check for definitions & structures needed for window size-changing
6664 dnl
6665 dnl https://stackoverflow.com/questions/18878141/difference-between-structures-ttysize-and-winsize/50769952#50769952
6666 AC_DEFUN([CF_SIZECHANGE],
6667 [
6668 AC_REQUIRE([CF_STRUCT_TERMIOS])
6669 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
6670         cf_cv_sizechange=unknown
6671         cf_save_CPPFLAGS="$CPPFLAGS"
6672
6673 for cf_opts in "" "NEED_PTEM_H"
6674 do
6675
6676         CPPFLAGS="$cf_save_CPPFLAGS"
6677         if test -n "$cf_opts"
6678         then
6679                 CF_APPEND_TEXT(CPPFLAGS,-D$cf_opts)
6680         fi
6681         AC_TRY_COMPILE([#include <sys/types.h>
6682 #ifdef HAVE_TERMIOS_H
6683 #include <termios.h>
6684 #else
6685 #ifdef HAVE_TERMIO_H
6686 #include <termio.h>
6687 #endif
6688 #endif
6689
6690 #ifdef NEED_PTEM_H
6691 /* This is a workaround for SCO:  they neglected to define struct winsize in
6692  * termios.h -- it's only in termio.h and ptem.h
6693  */
6694 #include <sys/stream.h>
6695 #include <sys/ptem.h>
6696 #endif
6697
6698 #ifdef HAVE_SYS_IOCTL_H
6699 #include <sys/ioctl.h>
6700 #endif
6701 ],[
6702 #ifdef TIOCGSIZE
6703         struct ttysize win;     /* SunOS 3.0... */
6704         int y = win.ts_lines;
6705         int x = win.ts_cols;
6706 #else
6707 #ifdef TIOCGWINSZ
6708         struct winsize win;     /* everything else */
6709         int y = win.ws_row;
6710         int x = win.ws_col;
6711 #else
6712         no TIOCGSIZE or TIOCGWINSZ
6713 #endif /* TIOCGWINSZ */
6714 #endif /* TIOCGSIZE */
6715         ],
6716         [cf_cv_sizechange=yes],
6717         [cf_cv_sizechange=no])
6718
6719         CPPFLAGS="$cf_save_CPPFLAGS"
6720         if test "$cf_cv_sizechange" = yes ; then
6721                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
6722                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
6723                 break
6724         fi
6725 done
6726 ])
6727 if test "$cf_cv_sizechange" != no ; then
6728         AC_DEFINE(HAVE_SIZECHANGE,1,[Define to 1 if sizechange declarations are provided])
6729         case $cf_cv_sizechange in
6730         (NEED*)
6731                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
6732                 ;;
6733         esac
6734 fi
6735 ])dnl
6736 dnl ---------------------------------------------------------------------------
6737 dnl CF_SRC_MODULES version: 30 updated: 2017/07/26 17:08:35
6738 dnl --------------
6739 dnl For each parameter, test if the source-directory exists, and if it contains
6740 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
6741 dnl use in CF_LIB_RULES.
6742 dnl
6743 dnl This uses the configured value to make the lists SRC_SUBDIRS and
6744 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
6745 AC_DEFUN([CF_SRC_MODULES],
6746 [
6747 AC_MSG_CHECKING(for src modules)
6748
6749 # dependencies and linker-arguments for test-programs
6750 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
6751 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
6752 if test "$DFT_LWR_MODEL" = "libtool"; then
6753         TEST_ARGS="${TEST_DEPS}"
6754         TEST_ARG2="${TEST_DEP2}"
6755 else
6756         TEST_ARGS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
6757         TEST_ARG2="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARG2"
6758 fi
6759
6760 PC_MODULES_TO_MAKE="ncurses${USE_ARG_SUFFIX}"
6761 cf_cv_src_modules=
6762 for cf_dir in $1
6763 do
6764         if test -f $srcdir/$cf_dir/modules; then
6765
6766                 # We may/may not have tack in the distribution, though the
6767                 # makefile is.
6768                 if test $cf_dir = tack ; then
6769                         if test "x$cf_with_tack" != "xyes"; then
6770                                 continue
6771                         fi
6772                 fi
6773
6774                 if test -z "$cf_cv_src_modules"; then
6775                         cf_cv_src_modules=$cf_dir
6776                 else
6777                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
6778                 fi
6779
6780                 # Make the ncurses_cfg.h file record the library interface files as
6781                 # well.  These are header files that are the same name as their
6782                 # directory.  Ncurses is the only library that does not follow
6783                 # that pattern.
6784                 if test $cf_dir = tack ; then
6785                         continue
6786                 elif test -f $srcdir/${cf_dir}/${cf_dir}.h; then
6787                         CF_UPPER(cf_have_include,$cf_dir)
6788                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
6789                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
6790                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEPS"
6791                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEP2"
6792                         if test "$DFT_LWR_MODEL" = "libtool"; then
6793                                 TEST_ARGS="${TEST_DEPS}"
6794                                 TEST_ARG2="${TEST_DEP2}"
6795                         else
6796                                 TEST_ARGS="-l${cf_dir}${USE_ARG_SUFFIX} $TEST_ARGS"
6797                                 TEST_ARG2="-l${cf_dir}${USE_ARG_SUFFIX} $TEST_ARG2"
6798                         fi
6799                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${USE_ARG_SUFFIX}"
6800                 fi
6801         fi
6802 done
6803 AC_MSG_RESULT($cf_cv_src_modules)
6804
6805 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
6806 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
6807
6808 AC_SUBST(TEST_ARGS)
6809 AC_SUBST(TEST_DEPS)
6810
6811 AC_SUBST(TEST_ARG2)
6812 AC_SUBST(TEST_DEP2)
6813
6814 SRC_SUBDIRS=
6815 if test "x$cf_with_manpages" != xno ; then
6816         SRC_SUBDIRS="$SRC_SUBDIRS man"
6817 fi
6818 SRC_SUBDIRS="$SRC_SUBDIRS include"
6819 for cf_dir in $cf_cv_src_modules
6820 do
6821         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
6822 done
6823 if test "x$cf_with_tests" != "xno" ; then
6824         SRC_SUBDIRS="$SRC_SUBDIRS test"
6825 fi
6826 # always make this, to install the ncurses-config script
6827 SRC_SUBDIRS="$SRC_SUBDIRS misc"
6828 if test "$cf_with_cxx_binding" != no; then
6829         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${USE_ARG_SUFFIX}"
6830         SRC_SUBDIRS="$SRC_SUBDIRS c++"
6831 fi
6832
6833 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
6834 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
6835
6836 AC_SUBST(PC_MODULES_TO_MAKE)
6837
6838 ADA_SUBDIRS=
6839 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f $srcdir/Ada95/Makefile.in; then
6840         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
6841         ADA_SUBDIRS="gen src"
6842         if test "x$cf_with_tests" != "xno" ; then
6843                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
6844         fi
6845 fi
6846
6847 SUB_MAKEFILES=
6848 for cf_dir in $SRC_SUBDIRS
6849 do
6850         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
6851 done
6852
6853 if test -n "$ADA_SUBDIRS"; then
6854         for cf_dir in $ADA_SUBDIRS
6855         do
6856                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
6857         done
6858         AC_SUBST(ADA_SUBDIRS)
6859 fi
6860 ])dnl
6861 dnl ---------------------------------------------------------------------------
6862 dnl CF_STDCPP_LIBRARY version: 11 updated: 2015/10/17 19:03:33
6863 dnl -----------------
6864 dnl Check for -lstdc++, which is GNU's standard C++ library.
6865 dnl If $CXXLIBS is set, add that to the libraries used for test-linking.
6866 dnl If -lstdc++ was not already added to $LIBS or $CXXLIBS, and is needed,
6867 dnl add it to $CXXLIBS.
6868 AC_DEFUN([CF_STDCPP_LIBRARY],
6869 [
6870 if test -n "$GXX" ; then
6871
6872         cf_save="$LIBS"
6873         LIBS="$LIBS $CXXLIBS"
6874         AC_MSG_CHECKING(if we already have C++ library)
6875         AC_TRY_LINK([
6876                         #include <iostream>],[
6877                         std::cout << "Hello World!" << std::endl;],
6878                 [cf_have_libstdcpp=yes],
6879                 [cf_have_libstdcpp=no])
6880         AC_MSG_RESULT($cf_have_libstdcpp)
6881         LIBS="$cf_save"
6882
6883         if test $cf_have_libstdcpp != yes
6884         then
6885                 case $cf_cv_system_name in
6886                 (os2*)
6887                         if test -z "`g++ -dM -E - < /dev/null | grep __KLIBC__`"; then
6888                                 cf_stdcpp_libname=stdcpp
6889                         else
6890                                 cf_stdcpp_libname=stdc++
6891                         fi
6892                         ;;
6893                 (*)
6894                         cf_stdcpp_libname=stdc++
6895                         ;;
6896                 esac
6897
6898                 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
6899                         cf_save="$LIBS"
6900                         LIBS="$LIBS $CXXLIBS"
6901                         CF_ADD_LIB($cf_stdcpp_libname)
6902                 AC_TRY_LINK([
6903                                 #include <iostream>],[
6904                                 std::cout << "Hello World!" << std::endl;],
6905                         [cf_cv_libstdcpp=yes],
6906                         [cf_cv_libstdcpp=no])
6907                         LIBS="$cf_save"
6908                 ])
6909                 test "$cf_cv_libstdcpp" = yes && { CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS) }
6910         fi
6911 fi
6912 ])dnl
6913 dnl ---------------------------------------------------------------------------
6914 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
6915 dnl --------------
6916 dnl     Remove "-g" option from the compiler options
6917 AC_DEFUN([CF_STRIP_G_OPT],
6918 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
6919 dnl ---------------------------------------------------------------------------
6920 dnl CF_STRUCT_SIGACTION version: 5 updated: 2012/10/06 17:56:13
6921 dnl -------------------
6922 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
6923 dnl do this if we've found the sigaction function.
6924 AC_DEFUN([CF_STRUCT_SIGACTION],[
6925 AC_REQUIRE([CF_XOPEN_SOURCE])
6926
6927 if test "$ac_cv_func_sigaction" = yes; then
6928 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
6929 AC_TRY_COMPILE([
6930 #include <sys/types.h>
6931 #include <signal.h>],
6932         [struct sigaction act],
6933         [sigact_bad=no],
6934         [
6935 AC_TRY_COMPILE([
6936 #define _POSIX_SOURCE
6937 #include <sys/types.h>
6938 #include <signal.h>],
6939         [struct sigaction act],
6940         [sigact_bad=yes
6941          AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE])],
6942          [sigact_bad=unknown])])
6943 AC_MSG_RESULT($sigact_bad)
6944 fi
6945 ])dnl
6946 dnl ---------------------------------------------------------------------------
6947 dnl CF_STRUCT_TERMIOS version: 9 updated: 2018/06/08 21:57:23
6948 dnl -----------------
6949 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
6950 AC_DEFUN([CF_STRUCT_TERMIOS],[
6951 AC_REQUIRE([CF_XOPEN_SOURCE])
6952
6953 AC_CHECK_HEADERS( \
6954 termio.h \
6955 termios.h \
6956 unistd.h \
6957 sys/ioctl.h \
6958 sys/termio.h \
6959 )
6960
6961 if test "$ac_cv_header_termios_h" = yes ; then
6962         case "$CFLAGS $CPPFLAGS" in
6963         (*-D_POSIX_SOURCE*)
6964                 termios_bad=dunno ;;
6965         (*)     termios_bad=maybe ;;
6966         esac
6967         if test "$termios_bad" = maybe ; then
6968         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
6969         AC_TRY_COMPILE([#include <termios.h>],
6970                 [struct termios foo; int x = foo.c_iflag],
6971                 termios_bad=no, [
6972                 AC_TRY_COMPILE([
6973 #define _POSIX_SOURCE
6974 #include <termios.h>],
6975                         [struct termios foo; int x = foo.c_iflag],
6976                         termios_bad=unknown,
6977                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE]))
6978                         ])
6979         AC_MSG_RESULT($termios_bad)
6980         fi
6981 fi
6982 ])dnl
6983 dnl ---------------------------------------------------------------------------
6984 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
6985 dnl --------------
6986 dnl Construct a search-list for a nonstandard header/lib-file
6987 dnl     $1 = the variable to return as result
6988 dnl     $2 = the package name
6989 dnl     $3 = the subdirectory, e.g., bin, include or lib
6990 AC_DEFUN([CF_SUBDIR_PATH],
6991 [
6992 $1=
6993
6994 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
6995
6996 for cf_subdir_prefix in \
6997         /usr \
6998         /usr/local \
6999         /usr/pkg \
7000         /opt \
7001         /opt/local \
7002         [$]HOME
7003 do
7004         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
7005 done
7006 ])dnl
7007 dnl ---------------------------------------------------------------------------
7008 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
7009 dnl -----------
7010 dnl     Shorthand macro for substituting things that the user may override
7011 dnl     with an environment variable.
7012 dnl
7013 dnl     $1 = condition to pass to "test"
7014 dnl     $2 = environment variable
7015 dnl     $3 = value if the test succeeds
7016 dnl     $4 = value if the test fails
7017 AC_DEFUN([CF_SUBST_IF],
7018 [
7019 if test $1 ; then
7020         $2=$3
7021 ifelse($4,,,[else
7022         $2=$4])
7023 fi
7024 AC_SUBST($2)
7025 ])dnl
7026 dnl ---------------------------------------------------------------------------
7027 dnl CF_SUBST_NCURSES_VERSION version: 8 updated: 2006/09/16 11:40:59
7028 dnl ------------------------
7029 dnl Get the version-number for use in shared-library naming, etc.
7030 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
7031 [
7032 AC_REQUIRE([CF_PROG_EGREP])
7033 NCURSES_MAJOR="`$ac_cv_prog_egrep '^NCURSES_MAJOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
7034 NCURSES_MINOR="`$ac_cv_prog_egrep '^NCURSES_MINOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
7035 NCURSES_PATCH="`$ac_cv_prog_egrep '^NCURSES_PATCH[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
7036 cf_cv_abi_version=${NCURSES_MAJOR}
7037 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
7038 dnl Show the computed version, for logging
7039 cf_cv_timestamp=`date`
7040 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
7041 dnl We need these values in the generated headers
7042 AC_SUBST(NCURSES_MAJOR)
7043 AC_SUBST(NCURSES_MINOR)
7044 AC_SUBST(NCURSES_PATCH)
7045 dnl We need these values in the generated makefiles
7046 AC_SUBST(cf_cv_rel_version)
7047 AC_SUBST(cf_cv_abi_version)
7048 AC_SUBST(cf_cv_builtin_bool)
7049 AC_SUBST(cf_cv_header_stdbool_h)
7050 AC_SUBST(cf_cv_type_of_bool)dnl
7051 ])dnl
7052 dnl ---------------------------------------------------------------------------
7053 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
7054 dnl ------------------
7055 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
7056 dnl older SCO configurations.
7057 AC_DEFUN([CF_SYS_TIME_SELECT],
7058 [
7059 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
7060 AC_CACHE_VAL(cf_cv_sys_time_select,[
7061 AC_TRY_COMPILE([
7062 #include <sys/types.h>
7063 #ifdef HAVE_SYS_TIME_H
7064 #include <sys/time.h>
7065 #endif
7066 #ifdef HAVE_SYS_SELECT_H
7067 #include <sys/select.h>
7068 #endif
7069 ],[],[cf_cv_sys_time_select=yes],
7070          [cf_cv_sys_time_select=no])
7071          ])
7072 AC_MSG_RESULT($cf_cv_sys_time_select)
7073 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
7074 ])dnl
7075 dnl ---------------------------------------------------------------------------
7076 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
7077 dnl ---------------
7078 dnl Define a top_builddir symbol, for applications that need an absolute path.
7079 AC_DEFUN([CF_TOP_BUILDDIR],
7080 [
7081 top_builddir=ifelse($1,,`pwd`,$1)
7082 AC_SUBST(top_builddir)
7083 ])dnl
7084 dnl ---------------------------------------------------------------------------
7085 dnl CF_TRY_PKG_CONFIG version: 5 updated: 2013/07/06 21:27:06
7086 dnl -----------------
7087 dnl This is a simple wrapper to use for pkg-config, for libraries which may be
7088 dnl available in that form.
7089 dnl
7090 dnl $1 = package name
7091 dnl $2 = extra logic to use, if any, after updating CFLAGS and LIBS
7092 dnl $3 = logic to use if pkg-config does not have the package
7093 AC_DEFUN([CF_TRY_PKG_CONFIG],[
7094 AC_REQUIRE([CF_PKG_CONFIG])
7095
7096 if test "$PKG_CONFIG" != none && "$PKG_CONFIG" --exists $1; then
7097         CF_VERBOSE(found package $1)
7098         cf_pkgconfig_incs="`$PKG_CONFIG --cflags $1 2>/dev/null`"
7099         cf_pkgconfig_libs="`$PKG_CONFIG --libs   $1 2>/dev/null`"
7100         CF_VERBOSE(package $1 CFLAGS: $cf_pkgconfig_incs)
7101         CF_VERBOSE(package $1 LIBS: $cf_pkgconfig_libs)
7102         CF_ADD_CFLAGS($cf_pkgconfig_incs)
7103         CF_ADD_LIBS($cf_pkgconfig_libs)
7104         ifelse([$2],,:,[$2])
7105 else
7106         cf_pkgconfig_incs=
7107         cf_pkgconfig_libs=
7108         ifelse([$3],,:,[$3])
7109 fi
7110 ])
7111 dnl ---------------------------------------------------------------------------
7112 dnl CF_TRY_XOPEN_SOURCE version: 2 updated: 2018/06/20 20:23:13
7113 dnl -------------------
7114 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
7115 dnl can define it successfully.
7116 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
7117 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
7118         AC_TRY_COMPILE([
7119 #include <stdlib.h>
7120 #include <string.h>
7121 #include <sys/types.h>
7122 ],[
7123 #ifndef _XOPEN_SOURCE
7124 make an error
7125 #endif],
7126         [cf_cv_xopen_source=no],
7127         [cf_save="$CPPFLAGS"
7128          CF_APPEND_TEXT(CPPFLAGS,-D_XOPEN_SOURCE=$cf_XOPEN_SOURCE)
7129          AC_TRY_COMPILE([
7130 #include <stdlib.h>
7131 #include <string.h>
7132 #include <sys/types.h>
7133 ],[
7134 #ifdef _XOPEN_SOURCE
7135 make an error
7136 #endif],
7137         [cf_cv_xopen_source=no],
7138         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
7139         CPPFLAGS="$cf_save"
7140         ])
7141 ])
7142
7143 if test "$cf_cv_xopen_source" != no ; then
7144         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
7145         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
7146         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
7147         CF_ADD_CFLAGS($cf_temp_xopen_source)
7148 fi
7149 ])
7150 dnl ---------------------------------------------------------------------------
7151 dnl CF_TYPEOF_CHTYPE version: 10 updated: 2017/01/21 11:06:25
7152 dnl ----------------
7153 dnl Determine the type we should use for chtype (and attr_t, which is treated
7154 dnl as the same thing).  We want around 32 bits, so on most machines want a
7155 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
7156 dnl wide characters, we have to have a type compatible with that, as well.
7157 AC_DEFUN([CF_TYPEOF_CHTYPE],
7158 [
7159 AC_MSG_CHECKING([for type of chtype])
7160 AC_CACHE_VAL(cf_cv_typeof_chtype,[
7161                 AC_TRY_RUN([
7162 #define WANT_BITS 31
7163 #include <stdio.h>
7164 int main(void)
7165 {
7166         FILE *fp = fopen("cf_test.out", "w");
7167         if (fp != 0) {
7168                 char *result = "long";
7169                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
7170                         int n;
7171                         unsigned int x, y;
7172                         for (n = 0; n < WANT_BITS; n++) {
7173                                 x = (1 << n);
7174                                 y = (x >> n);
7175                                 if (y != 1 || x == 0) {
7176                                         x = 0;
7177                                         break;
7178                                 }
7179                         }
7180                         /*
7181                          * If x is nonzero, an int is big enough for the bits
7182                          * that we want.
7183                          */
7184                         result = (x != 0) ? "int" : "long";
7185                 }
7186                 fputs(result, fp);
7187                 fclose(fp);
7188         }
7189         ${cf_cv_main_return:-return}(0);
7190 }
7191                 ],
7192                 [cf_cv_typeof_chtype=`cat cf_test.out`],
7193                 [cf_cv_typeof_chtype=long],
7194                 [cf_cv_typeof_chtype=long])
7195                 rm -f cf_test.out
7196         ])
7197 AC_MSG_RESULT($cf_cv_typeof_chtype)
7198
7199 AC_SUBST(cf_cv_typeof_chtype)
7200 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype,[Define to actual type if needed for chtype])
7201 ])dnl
7202 dnl ---------------------------------------------------------------------------
7203 dnl CF_TYPE_SIGACTION version: 4 updated: 2012/10/06 17:56:13
7204 dnl -----------------
7205 dnl
7206 AC_DEFUN([CF_TYPE_SIGACTION],
7207 [
7208 AC_MSG_CHECKING([for type sigaction_t])
7209 AC_CACHE_VAL(cf_cv_type_sigaction,[
7210         AC_TRY_COMPILE([
7211 #include <signal.h>],
7212                 [sigaction_t x],
7213                 [cf_cv_type_sigaction=yes],
7214                 [cf_cv_type_sigaction=no])])
7215 AC_MSG_RESULT($cf_cv_type_sigaction)
7216 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION,1,[Define to 1 if we have the sigaction_t type])
7217 ])dnl
7218 dnl ---------------------------------------------------------------------------
7219 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
7220 dnl --------------------
7221 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
7222 dnl won't, but they're still there.
7223 AC_DEFUN([CF_UNSIGNED_LITERALS],
7224 [
7225 AC_MSG_CHECKING([if unsigned literals are legal])
7226 AC_CACHE_VAL(cf_cv_unsigned_literals,[
7227         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
7228                 [cf_cv_unsigned_literals=yes],
7229                 [cf_cv_unsigned_literals=no])
7230         ])
7231 AC_MSG_RESULT($cf_cv_unsigned_literals)
7232 ])dnl
7233 dnl ---------------------------------------------------------------------------
7234 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
7235 dnl --------
7236 dnl Make an uppercase version of a variable
7237 dnl $1=uppercase($2)
7238 AC_DEFUN([CF_UPPER],
7239 [
7240 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
7241 ])dnl
7242 dnl ---------------------------------------------------------------------------
7243 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
7244 dnl -----------
7245 dnl Check for multibyte support, and if not found, utf8 compatibility library
7246 AC_DEFUN([CF_UTF8_LIB],
7247 [
7248 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
7249         cf_save_LIBS="$LIBS"
7250         AC_TRY_LINK([
7251 #include <stdlib.h>],[putwc(0,0);],
7252         [cf_cv_utf8_lib=yes],
7253         [CF_FIND_LINKAGE([
7254 #include <libutf8.h>],[putwc(0,0);],utf8,
7255                 [cf_cv_utf8_lib=add-on],
7256                 [cf_cv_utf8_lib=no])
7257 ])])
7258
7259 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
7260 # ncurses/ncursesw:
7261 if test "$cf_cv_utf8_lib" = "add-on" ; then
7262         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
7263         CF_ADD_INCDIR($cf_cv_header_path_utf8)
7264         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
7265         CF_ADD_LIBS($cf_cv_library_file_utf8)
7266 fi
7267 ])dnl
7268 dnl ---------------------------------------------------------------------------
7269 dnl CF_VA_COPY version: 6 updated: 2018/12/04 18:14:25
7270 dnl ----------
7271 dnl check for va_copy, part of stdarg.h starting with ISO C 1999.
7272 dnl Also, workaround for glibc's __va_copy, by checking for both.
7273 dnl Finally, try to accommodate pre-ISO C 1999 headers.
7274 AC_DEFUN([CF_VA_COPY],[
7275 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
7276 AC_TRY_LINK([
7277 #include <stdarg.h>
7278 ],[
7279         static va_list dst;
7280         static va_list src;
7281         va_copy(dst, src)],
7282         cf_cv_have_va_copy=yes,
7283         cf_cv_have_va_copy=no)])
7284
7285 if test "$cf_cv_have_va_copy" = yes;
7286 then
7287         AC_DEFINE(HAVE_VA_COPY,1,[Define to 1 if we have va_copy])
7288 else # !cf_cv_have_va_copy
7289
7290 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
7291 AC_TRY_LINK([
7292 #include <stdarg.h>
7293 ],[
7294         static va_list dst;
7295         static va_list src;
7296         __va_copy(dst, src)],
7297         cf_cv_have___va_copy=yes,
7298         cf_cv_have___va_copy=no)])
7299
7300 if test "$cf_cv_have___va_copy" = yes
7301 then
7302         AC_DEFINE(HAVE___VA_COPY,1,[Define to 1 if we have __va_copy])
7303 else # !cf_cv_have___va_copy
7304
7305 AC_CACHE_CHECK(for __builtin_va_copy, cf_cv_have___builtin_va_copy,[
7306 AC_TRY_LINK([
7307 #include <stdarg.h>
7308 ],[
7309         static va_list dst;
7310         static va_list src;
7311         __builtin_va_copy(dst, src)],
7312         cf_cv_have___builtin_va_copy=yes,
7313         cf_cv_have___builtin_va_copy=no)])
7314
7315 test "$cf_cv_have___builtin_va_copy" = yes &&
7316         AC_DEFINE(HAVE___BUILTIN_VA_COPY,1,[Define to 1 if we have __builtin_va_copy])
7317
7318 fi # cf_cv_have___va_copy
7319
7320 fi # cf_cv_have_va_copy
7321
7322 case "${cf_cv_have_va_copy}${cf_cv_have___va_copy}${cf_cv_have___builtin_va_copy}" in
7323 (*yes*)
7324         ;;
7325
7326 (*)
7327         AC_CACHE_CHECK(if we can simply copy va_list, cf_cv_pointer_va_list,[
7328 AC_TRY_LINK([
7329 #include <stdarg.h>
7330 ],[
7331         va_list dst;
7332         va_list src;
7333         dst = src],
7334         cf_cv_pointer_va_list=yes,
7335         cf_cv_pointer_va_list=no)])
7336
7337         if test "$cf_cv_pointer_va_list" = no
7338         then
7339                 AC_CACHE_CHECK(if we can copy va_list indirectly, cf_cv_array_va_list,[
7340 AC_TRY_LINK([
7341 #include <stdarg.h>
7342 ],[
7343         va_list dst;
7344         va_list src;
7345         *dst = *src],
7346                         cf_cv_array_va_list=yes,
7347                         cf_cv_array_va_list=no)])
7348                 test "$cf_cv_array_va_list" = yes && AC_DEFINE(ARRAY_VA_LIST,1,[Define to 1 if we can copy va_list indirectly])
7349         fi
7350         ;;
7351 esac
7352 ])
7353 dnl ---------------------------------------------------------------------------
7354 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
7355 dnl ----------
7356 dnl Use AC_VERBOSE w/o the warnings
7357 AC_DEFUN([CF_VERBOSE],
7358 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
7359 CF_MSG_LOG([$1])
7360 ])dnl
7361 dnl ---------------------------------------------------------------------------
7362 dnl CF_VERSION_INFO version: 7 updated: 2015/04/17 21:13:04
7363 dnl ---------------
7364 dnl Define several useful symbols derived from the VERSION file.  A separate
7365 dnl file is preferred to embedding the version numbers in various scripts.
7366 dnl (automake is a textbook-example of why the latter is a bad idea, but there
7367 dnl are others).
7368 dnl
7369 dnl The file contents are:
7370 dnl     libtool-version release-version patch-version
7371 dnl or
7372 dnl     release-version
7373 dnl where
7374 dnl     libtool-version (see ?) consists of 3 integers separated by '.'
7375 dnl     release-version consists of a major version and minor version
7376 dnl             separated by '.', optionally followed by a patch-version
7377 dnl             separated by '-'.  The minor version need not be an
7378 dnl             integer (but it is preferred).
7379 dnl     patch-version is an integer in the form yyyymmdd, so ifdef's and
7380 dnl             scripts can easily compare versions.
7381 dnl
7382 dnl If libtool is used, the first form is required, since CF_WITH_LIBTOOL
7383 dnl simply extracts the first field using 'cut -f1'.
7384 dnl
7385 dnl Optional parameters:
7386 dnl $1 = internal name for package
7387 dnl $2 = external name for package
7388 AC_DEFUN([CF_VERSION_INFO],
7389 [
7390 if test -f $srcdir/VERSION ; then
7391         AC_MSG_CHECKING(for package version)
7392
7393         # if there are not enough fields, cut returns the last one...
7394         cf_field1=`sed -e '2,$d' $srcdir/VERSION|cut -f1`
7395         cf_field2=`sed -e '2,$d' $srcdir/VERSION|cut -f2`
7396         cf_field3=`sed -e '2,$d' $srcdir/VERSION|cut -f3`
7397
7398         # this is how CF_BUNDLED_INTL uses $VERSION:
7399         VERSION="$cf_field1"
7400
7401         VERSION_MAJOR=`echo "$cf_field2" | sed -e 's/\..*//'`
7402         test -z "$VERSION_MAJOR" && AC_MSG_ERROR(missing major-version)
7403
7404         VERSION_MINOR=`echo "$cf_field2" | sed -e 's/^[[^.]]*\.//' -e 's/-.*//'`
7405         test -z "$VERSION_MINOR" && AC_MSG_ERROR(missing minor-version)
7406
7407         AC_MSG_RESULT(${VERSION_MAJOR}.${VERSION_MINOR})
7408
7409         AC_MSG_CHECKING(for package patch date)
7410         VERSION_PATCH=`echo "$cf_field3" | sed -e 's/^[[^-]]*-//'`
7411         case .$VERSION_PATCH in
7412         (.)
7413                 AC_MSG_ERROR(missing patch-date $VERSION_PATCH)
7414                 ;;
7415         (.[[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]])
7416                 ;;
7417         (*)
7418                 AC_MSG_ERROR(illegal patch-date $VERSION_PATCH)
7419                 ;;
7420         esac
7421         AC_MSG_RESULT($VERSION_PATCH)
7422 else
7423         AC_MSG_ERROR(did not find $srcdir/VERSION)
7424 fi
7425
7426 # show the actual data that we have for versions:
7427 CF_VERBOSE(ABI VERSION $VERSION)
7428 CF_VERBOSE(VERSION_MAJOR $VERSION_MAJOR)
7429 CF_VERBOSE(VERSION_MINOR $VERSION_MINOR)
7430 CF_VERBOSE(VERSION_PATCH $VERSION_PATCH)
7431
7432 AC_SUBST(VERSION)
7433 AC_SUBST(VERSION_MAJOR)
7434 AC_SUBST(VERSION_MINOR)
7435 AC_SUBST(VERSION_PATCH)
7436
7437 dnl if a package name is given, define its corresponding version info.  We
7438 dnl need the package name to ensure that the defined symbols are unique.
7439 ifelse($1,,,[
7440         cf_PACKAGE=$1
7441         PACKAGE=ifelse($2,,$1,$2)
7442         AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",[Define to the package-name])
7443         AC_SUBST(PACKAGE)
7444         CF_UPPER(cf_PACKAGE,$cf_PACKAGE)
7445         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_VERSION,"${VERSION_MAJOR}.${VERSION_MINOR}")
7446         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_PATCHDATE,${VERSION_PATCH})
7447 ])
7448 ])dnl
7449 dnl ---------------------------------------------------------------------------
7450 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
7451 dnl -------------
7452 dnl Check if type wide-character type $1 is declared, and if so, which header
7453 dnl file is needed.  The second parameter is used to set a shell variable when
7454 dnl the type is not found.  The first parameter sets a shell variable for the
7455 dnl opposite sense.
7456 AC_DEFUN([CF_WCHAR_TYPE],
7457 [
7458 # This is needed on Tru64 5.0 to declare $1
7459 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
7460 AC_TRY_COMPILE([
7461 #include <stdlib.h>
7462 #include <stdarg.h>
7463 #include <stdio.h>
7464 #ifdef HAVE_LIBUTF8_H
7465 #include <libutf8.h>
7466 #endif],
7467         [$1 state],
7468         [cf_cv_$1=no],
7469         [AC_TRY_COMPILE([
7470 #include <stdlib.h>
7471 #include <stdarg.h>
7472 #include <stdio.h>
7473 #include <wchar.h>
7474 #ifdef HAVE_LIBUTF8_H
7475 #include <libutf8.h>
7476 #endif],
7477         [$1 value],
7478         [cf_cv_$1=yes],
7479         [cf_cv_$1=unknown])])])
7480
7481 if test "$cf_cv_$1" = yes ; then
7482         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
7483         NEED_WCHAR_H=1
7484 fi
7485
7486 ifelse([$2],,,[
7487 # if we do not find $1 in either place, use substitution to provide a fallback.
7488 if test "$cf_cv_$1" = unknown ; then
7489         $2=1
7490 fi
7491 ])
7492 ifelse($3,,,[
7493 # if we find $1 in either place, use substitution to provide a fallback.
7494 if test "$cf_cv_$1" != unknown ; then
7495         $3=1
7496 fi
7497 ])
7498 ])dnl
7499 dnl ---------------------------------------------------------------------------
7500 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
7501 dnl ---------------
7502 dnl Check for compiler-support for weak symbols.
7503 dnl This works with "recent" gcc.
7504 AC_DEFUN([CF_WEAK_SYMBOLS],[
7505 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
7506
7507 AC_TRY_COMPILE([
7508 #include <stdio.h>],
7509 [
7510 #if defined(__GNUC__)
7511 #  if defined __USE_ISOC99
7512 #    define _cat_pragma(exp)    _Pragma(#exp)
7513 #    define _weak_pragma(exp)   _cat_pragma(weak name)
7514 #  else
7515 #    define _weak_pragma(exp)
7516 #  endif
7517 #  define _declare(name)        __extension__ extern __typeof__(name) name
7518 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
7519 #endif
7520
7521 weak_symbol(fopen);
7522 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
7523 ])
7524 ])dnl
7525 dnl ---------------------------------------------------------------------------
7526 dnl CF_WITH_ABI_VERSION version: 3 updated: 2015/06/06 16:10:11
7527 dnl -------------------
7528 dnl Allow library's ABI to be overridden.  Generally this happens when a
7529 dnl packager has incremented the ABI past that used in the original package,
7530 dnl and wishes to keep doing this.
7531 dnl
7532 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
7533 dnl symbol.
7534 AC_DEFUN([CF_WITH_ABI_VERSION],[
7535 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
7536 AC_ARG_WITH(abi-version,
7537 [  --with-abi-version=XXX  override derived ABI version],[
7538         if test "x$cf_cv_abi_version" != "x$withval"
7539         then
7540                 AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
7541                 case $cf_cv_rel_version in
7542                 (5.*)
7543                         cf_cv_rel_version=$withval.0
7544                         ;;
7545                 (6.*)
7546                         cf_cv_rel_version=$withval.9    # FIXME: should be 10 as of 6.0 release
7547                         ;;
7548                 esac
7549         fi
7550         cf_cv_abi_version=$withval])
7551         CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
7552 ifelse($1,,,[
7553 $1_ABI=$cf_cv_abi_version
7554 ])
7555 ])dnl
7556 dnl ---------------------------------------------------------------------------
7557 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
7558 dnl --------------------
7559 dnl Command-line option to specify the Ada95 compiler.
7560 AC_DEFUN([CF_WITH_ADA_COMPILER],[
7561 AC_MSG_CHECKING(for ada-compiler)
7562 AC_ARG_WITH(ada-compiler,
7563         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
7564         [cf_ada_compiler=$withval],
7565         [cf_ada_compiler=gnatmake])
7566 AC_SUBST(cf_ada_compiler)
7567 AC_MSG_RESULT($cf_ada_compiler)
7568 ])dnl
7569 dnl ---------------------------------------------------------------------------
7570 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
7571 dnl -------------------
7572 dnl Command-line option to specify where Ada includes will install.
7573 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
7574 AC_MSG_CHECKING(for ada-include)
7575 CF_WITH_PATH(ada-include,
7576    [  --with-ada-include=DIR  Ada includes are in DIR],
7577    ADA_INCLUDE,
7578    PREFIX/share/ada/adainclude,
7579    [$]prefix/share/ada/adainclude)
7580 AC_SUBST(ADA_INCLUDE)
7581 AC_MSG_RESULT($ADA_INCLUDE)
7582 ])dnl
7583 dnl ---------------------------------------------------------------------------
7584 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
7585 dnl -------------------
7586 dnl Command-line option to specify where Ada objects will install.
7587 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
7588 AC_MSG_CHECKING(for ada-objects)
7589 CF_WITH_PATH(ada-objects,
7590    [  --with-ada-objects=DIR  Ada objects are in DIR],
7591    ADA_OBJECTS,
7592    PREFIX/lib/ada/adalib,
7593    [$]prefix/lib/ada/adalib)
7594 AC_SUBST(ADA_OBJECTS)
7595 AC_MSG_RESULT($ADA_OBJECTS)
7596 ])dnl
7597 dnl ---------------------------------------------------------------------------
7598 dnl CF_WITH_ADA_SHAREDLIB version: 5 updated: 2018/07/21 19:10:35
7599 dnl ---------------------
7600 dnl Command-line option to specify if an Ada95 shared-library should be built,
7601 dnl and optionally what its soname should be.
7602 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
7603 AC_REQUIRE([CF_GNAT_PROJECTS])
7604 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
7605 AC_ARG_WITH(ada-sharedlib,
7606         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
7607         [with_ada_sharedlib=$withval],
7608         [with_ada_sharedlib=no])
7609 AC_MSG_RESULT($with_ada_sharedlib)
7610
7611 if test "x$with_ada_sharedlib" != xno
7612 then
7613         if test "x$cf_gnat_projects" != xyes
7614         then
7615                 AC_MSG_WARN(disabling shared-library since GNAT projects are not supported)
7616                 with_ada_sharedlib=no
7617         fi
7618 fi
7619
7620 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
7621 MAKE_ADA_SHAREDLIB="#"
7622
7623 if test "x$with_ada_sharedlib" != xno
7624 then
7625         MAKE_ADA_SHAREDLIB=
7626         if test "x$with_ada_sharedlib" != xyes
7627         then
7628                 ADA_SHAREDLIB="$with_ada_sharedlib"
7629         fi
7630 fi
7631
7632 AC_SUBST(ADA_SHAREDLIB)
7633 AC_SUBST(MAKE_ADA_SHAREDLIB)
7634 ])dnl
7635 dnl ---------------------------------------------------------------------------
7636 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
7637 dnl ----------------
7638 dnl Configure-option for dbmalloc.  The optional parameter is used to override
7639 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
7640 AC_DEFUN([CF_WITH_DBMALLOC],[
7641 CF_NO_LEAKS_OPTION(dbmalloc,
7642         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
7643         [USE_DBMALLOC])
7644
7645 if test "$with_dbmalloc" = yes ; then
7646         AC_CHECK_HEADER(dbmalloc.h,
7647                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
7648 fi
7649 ])dnl
7650 dnl ---------------------------------------------------------------------------
7651 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
7652 dnl ---------------
7653 dnl Configure-option for dmalloc.  The optional parameter is used to override
7654 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
7655 AC_DEFUN([CF_WITH_DMALLOC],[
7656 CF_NO_LEAKS_OPTION(dmalloc,
7657         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
7658         [USE_DMALLOC])
7659
7660 if test "$with_dmalloc" = yes ; then
7661         AC_CHECK_HEADER(dmalloc.h,
7662                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
7663 fi
7664 ])dnl
7665 dnl ---------------------------------------------------------------------------
7666 dnl CF_WITH_EXPORT_SYMS version: 3 updated: 2014/12/20 19:16:08
7667 dnl -------------------
7668 dnl Use this with libtool to specify the list of symbols that may be exported.
7669 dnl The input file contains one symbol per line; comments work with "#".
7670 dnl
7671 dnl $1 = basename of the ".sym" file (default $PACKAGE)
7672 AC_DEFUN([CF_WITH_EXPORT_SYMS],
7673 [
7674 AC_MSG_CHECKING(if exported-symbols file should be used)
7675 AC_ARG_WITH(export-syms,
7676         [  --with-export-syms=XXX  limit exported symbols using libtool],
7677         [with_export_syms=$withval],
7678         [with_export_syms=no])
7679 if test "x$with_export_syms" = xyes
7680 then
7681         with_export_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).sym'
7682         AC_SUBST(PACKAGE)
7683 fi
7684 AC_MSG_RESULT($with_export_syms)
7685 if test "x$with_export_syms" != xno
7686 then
7687         EXPORT_SYMS="-export-symbols $with_export_syms"
7688         AC_SUBST(EXPORT_SYMS)
7689 fi
7690 ])dnl
7691 dnl ---------------------------------------------------------------------------
7692 dnl CF_WITH_GPM version: 10 updated: 2017/04/29 18:32:18
7693 dnl -----------
7694 dnl
7695 dnl The option parameter (if neither yes/no) is assumed to be the name of
7696 dnl the gpm library, e.g., for dynamic loading.
7697 AC_DEFUN([CF_WITH_GPM],
7698 [
7699 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
7700 AC_ARG_WITH(gpm,
7701         [  --with-gpm              use Alessandro Rubini's GPM library],
7702         [with_gpm=$withval],
7703         [with_gpm=maybe])
7704 AC_MSG_RESULT($with_gpm)
7705
7706 if test "$with_gpm" != no ; then
7707         AC_CHECK_HEADER(gpm.h,[
7708                 AC_DEFINE(HAVE_GPM_H,1,[Define to 1 if we have gpm.h header])
7709                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
7710                         CF_VERBOSE(assuming we really have GPM library)
7711                         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
7712                         with_gpm=yes
7713                 else
7714                         AC_CHECK_LIB(gpm,Gpm_Open,[with_gpm=yes],[
7715                                 if test "$with_gpm" = maybe; then
7716                                         AC_MSG_WARN(Cannot link with GPM library)
7717                                         with_gpm=no
7718                                 else
7719                                         AC_MSG_ERROR(Cannot link with GPM library)
7720                                 fi
7721                         ])
7722                 fi
7723         ],[
7724                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
7725                 with_gpm=no
7726         ])
7727 fi
7728 ])
7729 dnl ---------------------------------------------------------------------------
7730 dnl CF_WITH_LIBTOOL version: 35 updated: 2017/08/12 07:58:51
7731 dnl ---------------
7732 dnl Provide a configure option to incorporate libtool.  Define several useful
7733 dnl symbols for the makefile rules.
7734 dnl
7735 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
7736 dnl macros from libtool.m4 which is in the aclocal directory of automake.
7737 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
7738 dnl But that still does not work properly since the macro is expanded outside
7739 dnl the CF_WITH_LIBTOOL macro:
7740 dnl
7741 dnl     #!/bin/sh
7742 dnl     ACLOCAL=`aclocal --print-ac-dir`
7743 dnl     if test -z "$ACLOCAL" ; then
7744 dnl             echo cannot find aclocal directory
7745 dnl             exit 1
7746 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
7747 dnl             echo cannot find libtool.m4 file
7748 dnl             exit 1
7749 dnl     fi
7750 dnl
7751 dnl     LOCAL=aclocal.m4
7752 dnl     ORIG=aclocal.m4.orig
7753 dnl
7754 dnl     trap "mv $ORIG $LOCAL" 0 1 2 3 15
7755 dnl     rm -f $ORIG
7756 dnl     mv $LOCAL $ORIG
7757 dnl
7758 dnl     # sed the LIBTOOL= assignment to omit the current directory?
7759 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
7760 dnl     cat $ORIG >>$LOCAL
7761 dnl
7762 dnl     autoconf-257 $*
7763 dnl
7764 AC_DEFUN([CF_WITH_LIBTOOL],
7765 [
7766 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
7767 ifdef([AC_PROG_LIBTOOL],,[
7768 LIBTOOL=
7769 ])
7770 # common library maintenance symbols that are convenient for libtool scripts:
7771 LIB_CREATE='${AR} -cr'
7772 LIB_OBJECT='${OBJECTS}'
7773 LIB_SUFFIX=.a
7774 LIB_PREP="$RANLIB"
7775
7776 # symbols used to prop libtool up to enable it to determine what it should be
7777 # doing:
7778 LIB_CLEAN=
7779 LIB_COMPILE=
7780 LIB_LINK='${CC}'
7781 LIB_INSTALL=
7782 LIB_UNINSTALL=
7783
7784 AC_MSG_CHECKING(if you want to build libraries with libtool)
7785 AC_ARG_WITH(libtool,
7786         [  --with-libtool          generate libraries with libtool],
7787         [with_libtool=$withval],
7788         [with_libtool=no])
7789 AC_MSG_RESULT($with_libtool)
7790 if test "$with_libtool" != "no"; then
7791 ifdef([AC_PROG_LIBTOOL],[
7792         # missing_content_AC_PROG_LIBTOOL{{
7793         AC_PROG_LIBTOOL
7794         # missing_content_AC_PROG_LIBTOOL}}
7795 ],[
7796         if test "$with_libtool" != "yes" ; then
7797                 CF_PATH_SYNTAX(with_libtool)
7798                 LIBTOOL=$with_libtool
7799         else
7800                 AC_CHECK_TOOLS(LIBTOOL,[libtool glibtool],none)
7801                 CF_LIBTOOL_VERSION
7802                 if test -z "$cf_cv_libtool_version" && test "$LIBTOOL" = libtool
7803                 then
7804                         CF_FORGET_TOOL(LIBTOOL)
7805                         AC_CHECK_TOOLS(LIBTOOL,[glibtool],none)
7806                         CF_LIBTOOL_VERSION
7807                 fi
7808         fi
7809         if test -z "$LIBTOOL" ; then
7810                 AC_MSG_ERROR(Cannot find libtool)
7811         fi
7812 ])dnl
7813         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${libdir} ${LIBTOOL_VERSION} `cut -f1 ${top_srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
7814         LIB_OBJECT='${OBJECTS:.o=.lo}'
7815         LIB_SUFFIX=.la
7816         LIB_CLEAN='${LIBTOOL} --mode=clean'
7817         LIB_COMPILE='${LIBTOOL} --mode=compile'
7818         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
7819         LIB_INSTALL='${LIBTOOL} --mode=install'
7820         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
7821         LIB_PREP=:
7822
7823         CF_CHECK_LIBTOOL_VERSION
7824
7825         # special hack to add -no-undefined (which libtool should do for itself)
7826         LT_UNDEF=
7827         case "$cf_cv_system_name" in
7828         (cygwin*|msys*|mingw32*|os2*|uwin*|aix[[4-7]])
7829                 LT_UNDEF=-no-undefined
7830                 ;;
7831         esac
7832         AC_SUBST([LT_UNDEF])
7833
7834         # special hack to add --tag option for C++ compiler
7835         case $cf_cv_libtool_version in
7836         (1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*)
7837                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
7838                 LIBTOOL="$LIBTOOL --tag=CC"
7839                 ;;
7840         (*)
7841                 LIBTOOL_CXX="$LIBTOOL"
7842                 ;;
7843         esac
7844 else
7845         LIBTOOL=""
7846         LIBTOOL_CXX=""
7847 fi
7848
7849 test -z "$LIBTOOL" && ECHO_LT=
7850
7851 AC_SUBST(LIBTOOL)
7852 AC_SUBST(LIBTOOL_CXX)
7853 AC_SUBST(LIBTOOL_OPTS)
7854
7855 AC_SUBST(LIB_CREATE)
7856 AC_SUBST(LIB_OBJECT)
7857 AC_SUBST(LIB_SUFFIX)
7858 AC_SUBST(LIB_PREP)
7859
7860 AC_SUBST(LIB_CLEAN)
7861 AC_SUBST(LIB_COMPILE)
7862 AC_SUBST(LIB_LINK)
7863 AC_SUBST(LIB_INSTALL)
7864 AC_SUBST(LIB_UNINSTALL)
7865
7866 ])dnl
7867 dnl ---------------------------------------------------------------------------
7868 dnl CF_WITH_LIBTOOL_OPTS version: 4 updated: 2015/04/17 21:13:04
7869 dnl --------------------
7870 dnl Allow user to pass additional libtool options into the library creation
7871 dnl and link steps.  The main use for this is to do something like
7872 dnl     ./configure --with-libtool-opts=-static
7873 dnl to get the same behavior as automake-flavored
7874 dnl     ./configure --enable-static
7875 AC_DEFUN([CF_WITH_LIBTOOL_OPTS],[
7876 AC_MSG_CHECKING(for additional libtool options)
7877 AC_ARG_WITH(libtool-opts,
7878         [  --with-libtool-opts=XXX specify additional libtool options],
7879         [with_libtool_opts=$withval],
7880         [with_libtool_opts=no])
7881 AC_MSG_RESULT($with_libtool_opts)
7882
7883 case .$with_libtool_opts in
7884 (.yes|.no|.)
7885         ;;
7886 (*)
7887         LIBTOOL_OPTS="$LIBTOOL_OPTS $with_libtool_opts"
7888         ;;
7889 esac
7890
7891 AC_SUBST(LIBTOOL_OPTS)
7892 ])dnl
7893 dnl ---------------------------------------------------------------------------
7894 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
7895 dnl ------------------
7896 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
7897 dnl "lib" prefix, e.g., because it used the dll naming convention.
7898 dnl
7899 dnl $1 = variable to set
7900 AC_DEFUN([CF_WITH_LIB_PREFIX],
7901 [
7902 AC_MSG_CHECKING(if you want to have a library-prefix)
7903 AC_ARG_WITH(lib-prefix,
7904         [  --with-lib-prefix       override library-prefix],
7905         [with_lib_prefix=$withval],
7906         [with_lib_prefix=auto])
7907 AC_MSG_RESULT($with_lib_prefix)
7908
7909 if test $with_lib_prefix = auto
7910 then
7911         CF_LIB_PREFIX($1)
7912 elif test $with_lib_prefix = no
7913 then
7914         LIB_PREFIX=
7915 else
7916         LIB_PREFIX=$with_lib_prefix
7917 fi
7918 ])dnl
7919 dnl ---------------------------------------------------------------------------
7920 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
7921 dnl ------------
7922 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
7923 dnl defaulting to yes/no.
7924 dnl
7925 dnl $1 = option name
7926 dnl $2 = help-text
7927 dnl $3 = environment variable to set
7928 dnl $4 = default value, shown in the help-message, must be a constant
7929 dnl $5 = default value, if it's an expression & cannot be in the help-message
7930 dnl
7931 AC_DEFUN([CF_WITH_PATH],
7932 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
7933 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
7934 if ifelse([$5],,true,[test -n "$5"]) ; then
7935 CF_PATH_SYNTAX(withval)
7936 fi
7937 eval $3="$withval"
7938 AC_SUBST($3)dnl
7939 ])dnl
7940 dnl ---------------------------------------------------------------------------
7941 dnl CF_WITH_PATHLIST version: 10 updated: 2015/04/17 21:13:04
7942 dnl ----------------
7943 dnl Process an option specifying a list of colon-separated paths.
7944 dnl
7945 dnl $1 = option name
7946 dnl $2 = help-text
7947 dnl $3 = environment variable to set
7948 dnl $4 = default value, shown in the help-message, must be a constant
7949 dnl $5 = default value, if it's an expression & cannot be in the help-message
7950 dnl $6 = flag to tell if we want to define or substitute
7951 dnl
7952 AC_DEFUN([CF_WITH_PATHLIST],[
7953 AC_REQUIRE([CF_PATHSEP])
7954 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
7955 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
7956
7957 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
7958 cf_dst_path=
7959 for cf_src_path in $withval
7960 do
7961   CF_PATH_SYNTAX(cf_src_path)
7962   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}$PATH_SEPARATOR"
7963   cf_dst_path="${cf_dst_path}${cf_src_path}"
7964 done
7965 IFS="$ac_save_ifs"
7966
7967 ifelse($6,define,[
7968 # Strip single quotes from the value, e.g., when it was supplied as a literal
7969 # for $4 or $5.
7970 case $cf_dst_path in
7971 (\'*)
7972   cf_dst_path=`echo $cf_dst_path |sed -e s/\'// -e s/\'\$//`
7973   ;;
7974 esac
7975 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
7976 ])
7977
7978 # This may use the prefix/exec_prefix symbols which will only yield "NONE"
7979 # so we have to check/work around.  We do prefer the result of "eval"...
7980 eval cf_dst_eval="$cf_dst_path"
7981 case "x$cf_dst_eval" in
7982 (xNONE*)
7983         $3=$cf_dst_path
7984         ;;
7985 (*)
7986         $3="$cf_dst_eval"
7987         ;;
7988 esac
7989 AC_SUBST($3)dnl
7990
7991 ])dnl
7992 dnl ---------------------------------------------------------------------------
7993 dnl CF_WITH_PCRE2 version: 2 updated: 2018/07/14 16:47:56
7994 dnl -------------
7995 dnl Add PCRE2 (Perl-compatible regular expressions v2) to the build if it is
7996 dnl available and the user requests it.  Assume the application will otherwise
7997 dnl use the POSIX interface.
7998 dnl
7999 dnl TODO allow $withval to specify package location
8000 AC_DEFUN([CF_WITH_PCRE2],
8001 [
8002 AC_REQUIRE([CF_PKG_CONFIG])
8003
8004 AC_MSG_CHECKING(if you want to use PCRE2 for regular-expressions)
8005 AC_ARG_WITH(pcre2,
8006         [  --with-pcre2            use PCRE2 for regular-expressions])
8007 test -z "$with_pcre2" && with_pcre2=no
8008 AC_MSG_RESULT($with_pcre2)
8009
8010 if test "x$with_pcre2" != xno ; then
8011         CF_TRY_PKG_CONFIG(libpcre2,,[
8012         CF_TRY_PKG_CONFIG(libpcre,,[
8013                         AC_MSG_ERROR(Cannot find PCRE2 library)])])
8014
8015         AC_DEFINE(HAVE_LIB_PCRE2,1,[Define to 1 if we can/should compile with the PCRE2 library])
8016
8017         # if pkgconfig gave no results, look for the libraries directly
8018         case $LIBS in
8019         (*pcre2-posix*|*pcreposix*)
8020                 ;;
8021         (*)
8022                 AC_CHECK_LIB(pcre2-posix,regcomp,[
8023                         CF_ADD_LIB(pcre2-posix)],
8024                         [AC_CHECK_LIB(pcreposix,regcomp,[
8025                          CF_ADD_LIB(pcreposix)
8026                         ],[AC_MSG_ERROR(Cannot find PCRE2 POSIX library)])])
8027                 ;;
8028         esac
8029
8030         # either way, check for the library header files
8031         AC_CHECK_HEADERS(pcre2-posix.h pcreposix.h)
8032 fi
8033 ])dnl
8034 dnl ---------------------------------------------------------------------------
8035 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 10 updated: 2015/08/22 17:10:56
8036 dnl -------------------------
8037 dnl Allow the choice of the pkg-config library directory to be overridden.
8038 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
8039
8040 case $PKG_CONFIG in
8041 (no|none|yes)
8042         AC_MSG_CHECKING(for pkg-config library directory)
8043         ;;
8044 (*)
8045         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
8046         ;;
8047 esac
8048
8049 PKG_CONFIG_LIBDIR=no
8050 AC_ARG_WITH(pkg-config-libdir,
8051         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
8052         [PKG_CONFIG_LIBDIR=$withval],
8053         [test "x$PKG_CONFIG" != xnone && PKG_CONFIG_LIBDIR=yes])
8054
8055 case x$PKG_CONFIG_LIBDIR in
8056 (x/*)
8057         ;;
8058 (xyes)
8059         # Look for the library directory using the same prefix as the executable
8060         if test "x$PKG_CONFIG" = xnone
8061         then
8062                 cf_path=$prefix
8063         else
8064                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
8065         fi
8066
8067         # If you don't like using the default architecture, you have to specify the
8068         # intended library directory and corresponding compiler/linker options.
8069         #
8070         # This case allows for Debian's 2014-flavor of multiarch, along with the
8071         # most common variations before that point.  Some other variants spell the
8072         # directory differently, e.g., "pkg-config", and put it in unusual places.
8073         # pkg-config has always been poorly standardized, which is ironic...
8074         case x`(arch) 2>/dev/null` in
8075         (*64)
8076                 cf_search_path="\
8077                         $cf_path/lib/*64-linux-gnu \
8078                         $cf_path/share \
8079                         $cf_path/lib64 \
8080                         $cf_path/lib32 \
8081                         $cf_path/lib"
8082                 ;;
8083         (*)
8084                 cf_search_path="\
8085                         $cf_path/lib/*-linux-gnu \
8086                         $cf_path/share \
8087                         $cf_path/lib32 \
8088                         $cf_path/lib \
8089                         $cf_path/libdata"
8090                 ;;
8091         esac
8092
8093         CF_VERBOSE(list...)
8094         for cf_config in $cf_search_path
8095         do
8096                 CF_VERBOSE(checking $cf_config/pkgconfig)
8097                 if test -d $cf_config/pkgconfig
8098                 then
8099                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
8100                         AC_MSG_CHECKING(done)
8101                         break
8102                 fi
8103         done
8104         ;;
8105 (*)
8106         ;;
8107 esac
8108
8109 if test "x$PKG_CONFIG_LIBDIR" != xno ; then
8110         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
8111 fi
8112
8113 AC_SUBST(PKG_CONFIG_LIBDIR)
8114 ])dnl
8115 dnl ---------------------------------------------------------------------------
8116 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
8117 dnl ---------------
8118 dnl Check for POSIX thread library.
8119 AC_DEFUN([CF_WITH_PTHREAD],
8120 [
8121 AC_MSG_CHECKING(if you want to link with the pthread library)
8122 AC_ARG_WITH(pthread,
8123         [  --with-pthread          use POSIX thread library],
8124         [with_pthread=$withval],
8125         [with_pthread=no])
8126 AC_MSG_RESULT($with_pthread)
8127
8128 if test "$with_pthread" != no ; then
8129         AC_CHECK_HEADER(pthread.h,[
8130         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
8131
8132         for cf_lib_pthread in pthread c_r
8133         do
8134             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
8135             cf_save_LIBS="$LIBS"
8136             CF_ADD_LIB($cf_lib_pthread)
8137             AC_TRY_LINK([
8138 #include <pthread.h>
8139 ],[
8140                 int rc = pthread_create(0,0,0,0);
8141                 int r2 = pthread_mutexattr_settype(0, 0);
8142 ],[with_pthread=yes],[with_pthread=no])
8143             LIBS="$cf_save_LIBS"
8144             AC_MSG_RESULT($with_pthread)
8145             test "$with_pthread" = yes && break
8146         done
8147
8148         if test "$with_pthread" = yes ; then
8149             CF_ADD_LIB($cf_lib_pthread)
8150             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
8151         else
8152             AC_MSG_ERROR(Cannot link with pthread library)
8153         fi
8154         ])
8155 fi
8156 ])
8157 dnl ---------------------------------------------------------------------------
8158 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
8159 dnl -------------------
8160 dnl Allow library's release-version to be overridden.  Generally this happens when a
8161 dnl packager has incremented the release-version past that used in the original package,
8162 dnl and wishes to keep doing this.
8163 dnl
8164 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
8165 dnl and {package}_MINOR symbols
8166 dnl symbol.
8167 AC_DEFUN([CF_WITH_REL_VERSION],[
8168 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
8169 AC_ARG_WITH(rel-version,
8170 [  --with-rel-version=XXX  override derived release version],
8171 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
8172  cf_cv_rel_version=$withval])
8173 ifelse($1,,[
8174  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
8175 ],[
8176  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
8177  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
8178  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
8179  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
8180 ])
8181 ])dnl
8182 dnl ---------------------------------------------------------------------------
8183 dnl CF_WITH_SYSMOUSE version: 3 updated: 2012/10/06 17:56:13
8184 dnl ----------------
8185 dnl If we can compile with sysmouse, make it available unless it is not wanted.
8186 AC_DEFUN([CF_WITH_SYSMOUSE],[
8187 # not everyone has "test -c"
8188 if test -c /dev/sysmouse 2>/dev/null ; then
8189 AC_MSG_CHECKING(if you want to use sysmouse)
8190 AC_ARG_WITH(sysmouse,
8191         [  --with-sysmouse         use sysmouse (FreeBSD console)],
8192         [cf_with_sysmouse=$withval],
8193         [cf_with_sysmouse=maybe])
8194         if test "$cf_with_sysmouse" != no ; then
8195         AC_TRY_COMPILE([
8196 #include <osreldate.h>
8197 #if (__FreeBSD_version >= 400017)
8198 #include <sys/consio.h>
8199 #include <sys/fbio.h>
8200 #else
8201 #include <machine/console.h>
8202 #endif
8203 ],[
8204         struct mouse_info the_mouse;
8205         ioctl(0, CONS_MOUSECTL, &the_mouse);
8206 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
8207         fi
8208 AC_MSG_RESULT($cf_with_sysmouse)
8209 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE,1,[Define to 1 if we can/should use the sysmouse interface])
8210 fi
8211 ])dnl
8212 dnl ---------------------------------------------------------------------------
8213 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
8214 dnl ---------------
8215 dnl For testing, override the derived host system-type which is used to decide
8216 dnl things such as the linker commands used to build shared libraries.  This is
8217 dnl normally chosen automatically based on the type of system which you are
8218 dnl building on.  We use it for testing the configure script.
8219 dnl
8220 dnl This is different from the --host option: it is used only for testing parts
8221 dnl of the configure script which would not be reachable with --host since that
8222 dnl relies on the build environment being real, rather than mocked up.
8223 AC_DEFUN([CF_WITH_SYSTYPE],[
8224 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
8225 AC_ARG_WITH(system-type,
8226         [  --with-system-type=XXX  test: override derived host system-type],
8227 [AC_MSG_WARN(overriding system type to $withval)
8228         cf_cv_system_name=$withval
8229         host_os=$withval
8230 ])
8231 ])dnl
8232 dnl ---------------------------------------------------------------------------
8233 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
8234 dnl ----------------
8235 AC_DEFUN([CF_WITH_VALGRIND],[
8236 CF_NO_LEAKS_OPTION(valgrind,
8237         [  --with-valgrind         test: use valgrind],
8238         [USE_VALGRIND])
8239 ])dnl
8240 dnl ---------------------------------------------------------------------------
8241 dnl CF_WITH_VERSIONED_SYMS version: 8 updated: 2018/10/20 20:24:34
8242 dnl ----------------------
8243 dnl Use this when building shared library with ELF, to markup symbols with the
8244 dnl version identifier from the given input file.  Generally that identifier is
8245 dnl the same as the SONAME at which the symbol was first introduced.
8246 dnl
8247 dnl $1 = basename of the ".map" file (default $PACKAGE)
8248 AC_DEFUN([CF_WITH_VERSIONED_SYMS],
8249 [
8250 AC_MSG_CHECKING(if versioned-symbols file should be used)
8251 AC_ARG_WITH(versioned-syms,
8252         [  --with-versioned-syms=X markup versioned symbols using ld],
8253         [with_versioned_syms=$withval],
8254         [with_versioned_syms=no])
8255 case "x$with_versioned_syms" in
8256 (xyes)
8257         with_versioned_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).map'
8258         AC_SUBST(PACKAGE)
8259         ;;
8260 (xno)
8261         ;;
8262 (x/*)
8263         test -f "$with_versioned_syms" || AC_MSG_ERROR(expected a filename: $with_versioned_syms)
8264         ;;
8265 (*)
8266         test -f "$with_versioned_syms" || AC_MSG_ERROR(expected a filename: $with_versioned_syms)
8267         with_versioned_syms=`pwd`/"$with_versioned_syms"
8268         ;;
8269 esac
8270 AC_MSG_RESULT($with_versioned_syms)
8271
8272 RESULTING_SYMS=
8273 VERSIONED_SYMS=
8274 WILDCARD_SYMS=
8275
8276 if test "x$with_versioned_syms" != xno
8277 then
8278         RESULTING_SYMS=$with_versioned_syms
8279         case "x$MK_SHARED_LIB" in
8280         (*-Wl,*)
8281                 VERSIONED_SYMS="-Wl,--version-script,\${RESULTING_SYMS}"
8282                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-Wl,%\\[$]{VERSIONED_SYMS} -Wl,%"`
8283                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
8284                 ;;
8285         (*-dy\ *)
8286                 VERSIONED_SYMS="-Wl,-M,\${RESULTING_SYMS}"
8287                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-dy%\\[$]{VERSIONED_SYMS} -dy%"`
8288                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
8289                 ;;
8290         (*)
8291                 AC_MSG_WARN(this system does not support versioned-symbols)
8292                 ;;
8293         esac
8294
8295         # Linux ld can selectively override scope, e.g., of symbols beginning with
8296         # "_" by first declaring some as global, and then using a wildcard to
8297         # declare the others as local.  Some other loaders cannot do this.  Check
8298         # by constructing a (very) simple shared library and inspecting its
8299         # symbols.
8300         if test "x$VERSIONED_SYMS" != "x"
8301         then
8302                 AC_MSG_CHECKING(if wildcards can be used to selectively omit symbols)
8303                 WILDCARD_SYMS=no
8304
8305                 # make sources
8306                 rm -f conftest.*
8307
8308                 cat >conftest.ver <<EOF
8309 module_1.0 {
8310 global:
8311         globalf1;
8312 local:
8313         localf1;
8314 };
8315 module_2.0 {
8316 global:
8317         globalf2;
8318 local:
8319         localf2;
8320         _*;
8321 } module_1.0;
8322 submodule_1.0 {
8323 global:
8324         subglobalf1;
8325         _ismissing;
8326 local:
8327         sublocalf1;
8328 };
8329 submodule_2.0 {
8330 global:
8331         subglobalf2;
8332 local:
8333         sublocalf2;
8334         _*;
8335 } submodule_1.0;
8336 EOF
8337                 cat >conftest.$ac_ext <<EOF
8338 #line __oline__ "configure"
8339 int     _ismissing(void) { return 1; }
8340 int     _localf1(void) { return 1; }
8341 int     _localf2(void) { return 2; }
8342 int     globalf1(void) { return 1; }
8343 int     globalf2(void) { return 2; }
8344 int     _sublocalf1(void) { return 1; }
8345 int     _sublocalf2(void) { return 2; }
8346 int     subglobalf1(void) { return 1; }
8347 int     subglobalf2(void) { return 2; }
8348 EOF
8349                 cat >conftest.mk <<EOF
8350 CC=${CC}
8351 CFLAGS=${CFLAGS}
8352 CPPFLAGS=${CPPFLAGS}
8353 LDFLAGS=${LDFLAGS}
8354 LIBS=${LIBS}
8355 VERSIONED_SYMS=${VERSIONED_SYMS}
8356 RESULTING_SYMS=conftest.ver
8357 MK_SHARED_LIB=${MK_SHARED_LIB}
8358 conftest.so: conftest.$ac_cv_objext
8359                 \$(MK_SHARED_LIB) conftest.$ac_cv_objext
8360 EOF
8361
8362                 # compile source, make library
8363                 if make -f conftest.mk 2>&AC_FD_CC >/dev/null
8364                 then
8365                         # test for missing symbol in either Data or Text section
8366                         cf_missing=`nm -P conftest.so 2>&AC_FD_CC |fgrep _ismissing | egrep '[[         ]][[DT]][[      ]]'`
8367                         test -n "$cf_missing" && WILDCARD_SYMS=yes
8368                 fi
8369                 AC_MSG_RESULT($WILDCARD_SYMS)
8370                 rm -f conftest.*
8371         fi
8372 fi
8373 AC_SUBST(RESULTING_SYMS)
8374 AC_SUBST(VERSIONED_SYMS)
8375 AC_SUBST(WILDCARD_SYMS)
8376 ])dnl
8377 dnl ---------------------------------------------------------------------------
8378 dnl CF_WITH_X11_RGB version: 1 updated: 2017/11/25 17:32:16
8379 dnl ---------------
8380 dnl Handle configure option "--with-x11-rgb", setting these shell
8381 dnl variables:
8382 dnl
8383 dnl $RGB_PATH is the option value, used for finding the X11 rgb file.
8384 dnl $no_x11_rgb is a "#" (comment) if "--without-x11-rgb" is given.
8385 dnl
8386 dnl Most Linux's use this:
8387 dnl     /usr/share/X11/rgb.txt
8388 dnl Debian uses this:
8389 dnl     /etc/X11/rgb.txt
8390 dnl DragonFlyBSD ports uses this:
8391 dnl     /usr/pkg/lib/X11/rgb.txt
8392 dnl FreeBSD ports use these:
8393 dnl     /usr/local/lib/X11/rgb.txt
8394 dnl     /usr/local/share/X11/rgb.txt
8395 dnl Mandriva has these:
8396 dnl     /usr/lib/X11/rgb.txt
8397 dnl     /usr/lib64/X11/rgb.txt
8398 dnl NetBSD has these
8399 dnl     /usr/X11R7/lib/X11/rgb.txt
8400 dnl OpenSolaris uses
8401 dnl     32-bit:
8402 dnl     /usr/X11/etc/X11/rgb.txt
8403 dnl     /usr/X11/share/X11/rgb.txt
8404 dnl     /usr/X11/lib/X11/rgb.txt
8405 dnl OSX uses
8406 dnl             /opt/local/share/X11/rgb.txt (MacPorts)
8407 dnl             /opt/X11/share/X11/rgb.txt (non-ports)
8408 dnl     64-bit:
8409 dnl     /usr/X11/etc/X11/rgb.txt
8410 dnl     /usr/X11/share/X11/rgb.txt (perhaps)
8411 dnl     /usr/X11/lib/amd64/X11/rgb.txt
8412 dnl Solaris10 uses (in this order):
8413 dnl     /usr/openwin/lib/X11/rgb.txt
8414 dnl     /usr/X11/lib/X11/rgb.txt
8415 AC_DEFUN([CF_WITH_X11_RGB],[
8416 AC_MSG_CHECKING(for X11 rgb file)
8417 AC_ARG_WITH(x11-rgb,
8418         [  --with-x11-rgb=FILE   file containing X11 rgb information (EPREFIX/lib/X11/rgb.txt)],
8419         [RGB_PATH=$withval],
8420         [RGB_PATH=auto])
8421
8422 if test "x[$]RGB_PATH" = xauto
8423 then
8424         RGB_PATH='${exec_prefix}/lib/X11/rgb.txt'
8425         for cf_path in \
8426                 /opt/local/share/X11/rgb.txt \
8427                 /opt/X11/share/X11/rgb.txt \
8428                 /usr/share/X11/rgb.txt \
8429                 /usr/X11/share/X11/rgb.txt \
8430                 /usr/X11/lib/X11/rgb.txt \
8431                 /usr/lib/X11/rgb.txt \
8432                 /etc/X11/rgb.txt \
8433                 /usr/pkg/lib/X11/rgb.txt \
8434                 /usr/X11R7/lib/X11/rgb.txt \
8435                 /usr/X11R6/lib/X11/rgb.txt \
8436                 /usr/X11R5/lib/X11/rgb.txt \
8437                 /usr/X11R4/lib/X11/rgb.txt \
8438                 /usr/local/lib/X11/rgb.txt \
8439                 /usr/local/share/X11/rgb.txt \
8440                 /usr/lib64/X11/rgb.txt
8441         do
8442                 if test -f "$cf_path" ; then
8443                         RGB_PATH="$cf_path"
8444                         break
8445                 fi
8446         done
8447 else
8448         cf_path=$RGB_PATH
8449         CF_PATH_SYNTAX(cf_path)
8450 fi
8451
8452 AC_MSG_RESULT($RGB_PATH)
8453 AC_SUBST(RGB_PATH)
8454 AC_DEFINE_UNQUOTED(RGB_PATH,"$cf_path")
8455
8456 no_x11_rgb=
8457 if test "$RGB_PATH" = no
8458 then
8459         no_x11_rgb="#"
8460 fi
8461 AC_SUBST(no_x11_rgb)
8462 ])dnl
8463 dnl ---------------------------------------------------------------------------
8464 dnl CF_XOPEN_SOURCE version: 55 updated: 2018/12/31 20:46:17
8465 dnl ---------------
8466 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
8467 dnl or adapt to the vendor's definitions to get equivalent functionality,
8468 dnl without losing the common non-POSIX features.
8469 dnl
8470 dnl Parameters:
8471 dnl     $1 is the nominal value for _XOPEN_SOURCE
8472 dnl     $2 is the nominal value for _POSIX_C_SOURCE
8473 AC_DEFUN([CF_XOPEN_SOURCE],[
8474 AC_REQUIRE([AC_CANONICAL_HOST])
8475 AC_REQUIRE([CF_POSIX_VISIBLE])
8476
8477 if test "$cf_cv_posix_visible" = no; then
8478
8479 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
8480 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
8481 cf_xopen_source=
8482
8483 case $host_os in
8484 (aix[[4-7]]*)
8485         cf_xopen_source="-D_ALL_SOURCE"
8486         ;;
8487 (msys)
8488         cf_XOPEN_SOURCE=600
8489         ;;
8490 (darwin[[0-8]].*)
8491         cf_xopen_source="-D_APPLE_C_SOURCE"
8492         ;;
8493 (darwin*)
8494         cf_xopen_source="-D_DARWIN_C_SOURCE"
8495         cf_XOPEN_SOURCE=
8496         ;;
8497 (freebsd*|dragonfly*|midnightbsd*)
8498         # 5.x headers associate
8499         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
8500         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
8501         cf_POSIX_C_SOURCE=200112L
8502         cf_XOPEN_SOURCE=600
8503         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
8504         ;;
8505 (hpux11*)
8506         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
8507         ;;
8508 (hpux*)
8509         cf_xopen_source="-D_HPUX_SOURCE"
8510         ;;
8511 (irix[[56]].*)
8512         cf_xopen_source="-D_SGI_SOURCE"
8513         cf_XOPEN_SOURCE=
8514         ;;
8515 (linux*|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin)
8516         CF_GNU_SOURCE($cf_XOPEN_SOURCE)
8517         ;;
8518 (minix*)
8519         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
8520         ;;
8521 (mirbsd*)
8522         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
8523         cf_XOPEN_SOURCE=
8524         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
8525         ;;
8526 (netbsd*)
8527         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
8528         ;;
8529 (openbsd[[4-9]]*)
8530         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
8531         cf_xopen_source="-D_BSD_SOURCE"
8532         cf_XOPEN_SOURCE=600
8533         ;;
8534 (openbsd*)
8535         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
8536         ;;
8537 (osf[[45]]*)
8538         cf_xopen_source="-D_OSF_SOURCE"
8539         ;;
8540 (nto-qnx*)
8541         cf_xopen_source="-D_QNX_SOURCE"
8542         ;;
8543 (sco*)
8544         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
8545         ;;
8546 (solaris2.*)
8547         cf_xopen_source="-D__EXTENSIONS__"
8548         cf_cv_xopen_source=broken
8549         ;;
8550 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
8551         cf_XOPEN_SOURCE=
8552         cf_POSIX_C_SOURCE=
8553         ;;
8554 (*)
8555         CF_TRY_XOPEN_SOURCE
8556         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
8557         ;;
8558 esac
8559
8560 if test -n "$cf_xopen_source" ; then
8561         CF_ADD_CFLAGS($cf_xopen_source,true)
8562 fi
8563
8564 dnl In anything but the default case, we may have system-specific setting
8565 dnl which is still not guaranteed to provide all of the entrypoints that
8566 dnl _XOPEN_SOURCE would yield.
8567 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
8568         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
8569         AC_TRY_COMPILE([#include <stdlib.h>],[
8570 #ifndef _XOPEN_SOURCE
8571 make an error
8572 #endif],
8573         [cf_XOPEN_SOURCE_set=yes],
8574         [cf_XOPEN_SOURCE_set=no])
8575         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
8576         if test $cf_XOPEN_SOURCE_set = yes
8577         then
8578                 AC_TRY_COMPILE([#include <stdlib.h>],[
8579 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
8580 make an error
8581 #endif],
8582                 [cf_XOPEN_SOURCE_set_ok=yes],
8583                 [cf_XOPEN_SOURCE_set_ok=no])
8584                 if test $cf_XOPEN_SOURCE_set_ok = no
8585                 then
8586                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
8587                 fi
8588         else
8589                 CF_TRY_XOPEN_SOURCE
8590         fi
8591 fi
8592 fi # cf_cv_posix_visible
8593 ])