aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2016,2017 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.816 2017/11/25 22:33:41 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 4 updated: 2015/04/18 08:56:57
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54         [AC_TRY_LINK([#include <langinfo.h>],
  55         [char* cs = nl_langinfo(CODESET);],
  56         am_cv_langinfo_codeset=yes,
  57         am_cv_langinfo_codeset=no)
  58         ])
  59         if test $am_cv_langinfo_codeset = yes; then
  60                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62         fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ABI_DEFAULTS version: 2 updated: 2015/06/06 13:49:58
  66 dnl ---------------
  67 dnl Provide configure-script defaults for different ncurses ABIs.
  68 AC_DEFUN([CF_ABI_DEFAULTS],[
  69 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
  70 case x$cf_cv_abi_version in
  71 (x[[6789]])
  72         cf_dft_ext_colors=yes
  73         cf_dft_ext_const=yes
  74         cf_dft_ext_mouse=yes
  75         cf_dft_ext_putwin=yes
  76         cf_dft_ext_spfuncs=yes
  77         cf_dft_filter_syms=yes
  78         cf_dft_chtype=uint32_t
  79         cf_dft_mmask_t=uint32_t
  80         cf_dft_interop=yes
  81         cf_dft_tparm_arg=intptr_t
  82         cf_dft_with_lp64=yes
  83         ;;
  84 (*)
  85         cf_dft_ext_colors=no
  86         cf_dft_ext_const=no
  87         cf_dft_ext_mouse=no
  88         cf_dft_ext_putwin=no
  89         cf_dft_ext_spfuncs=no
  90         cf_dft_filter_syms=no
  91         cf_dft_chtype=auto
  92         cf_dft_mmask_t=auto
  93         cf_dft_interop=no
  94         cf_dft_tparm_arg=long
  95         cf_dft_with_lp64=no
  96         ;;
  97 esac
  98 ])dnl
  99 dnl ---------------------------------------------------------------------------
 100 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
 101 dnl ------------------
 102 dnl Conditionally generate script according to whether we're using a given autoconf.
 103 dnl
 104 dnl $1 = version to compare against
 105 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
 106 dnl $3 = code to use if AC_ACVERSION is older than $1.
 107 define([CF_ACVERSION_CHECK],
 108 [
 109 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
 110 ifdef([m4_version_compare],
 111 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
 112 [CF_ACVERSION_COMPARE(
 113 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
 114 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
 115 dnl ---------------------------------------------------------------------------
 116 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
 117 dnl --------------------
 118 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
 119 dnl                      MAJOR2, MINOR2, TERNARY2,
 120 dnl                      PRINTABLE2, not FOUND, FOUND)
 121 define([CF_ACVERSION_COMPARE],
 122 [ifelse(builtin([eval], [$2 < $5]), 1,
 123 [ifelse([$8], , ,[$8])],
 124 [ifelse([$9], , ,[$9])])])dnl
 125 dnl ---------------------------------------------------------------------------
 126 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
 127 dnl -------------------
 128 dnl Construct the list of include-options for the C programs in the Ada95
 129 dnl binding.
 130 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
 131 [
 132 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
 133 if test "$srcdir" != "."; then
 134         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 135 fi
 136 if test "$GCC" != yes; then
 137         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 138 elif test "$includedir" != "/usr/include"; then
 139         if test "$includedir" = '${prefix}/include' ; then
 140                 if test x$prefix != x/usr ; then
 141                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 142                 fi
 143         else
 144                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 145         fi
 146 fi
 147 AC_SUBST(ACPPFLAGS)
 148 ])dnl
 149 dnl ---------------------------------------------------------------------------
 150 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 151 dnl ---------------
 152 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 153 AC_DEFUN([CF_ADD_ADAFLAGS],[
 154         ADAFLAGS="$ADAFLAGS $1"
 155         AC_SUBST(ADAFLAGS)
 156 ])dnl
 157 dnl ---------------------------------------------------------------------------
 158 dnl CF_ADD_CFLAGS version: 13 updated: 2017/02/25 18:57:40
 159 dnl -------------
 160 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 161 dnl The second parameter if given makes this macro verbose.
 162 dnl
 163 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 164 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 165 dnl confused by the quotes (which require backslashes to keep them usable).
 166 AC_DEFUN([CF_ADD_CFLAGS],
 167 [
 168 cf_fix_cppflags=no
 169 cf_new_cflags=
 170 cf_new_cppflags=
 171 cf_new_extra_cppflags=
 172
 173 for cf_add_cflags in $1
 174 do
 175 case $cf_fix_cppflags in
 176 (no)
 177         case $cf_add_cflags in
 178         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 179                 case $cf_add_cflags in
 180                 (-D*)
 181                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 182
 183                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 184                                 && test -z "${cf_tst_cflags}" \
 185                                 && cf_fix_cppflags=yes
 186
 187                         if test $cf_fix_cppflags = yes ; then
 188                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 189                                 continue
 190                         elif test "${cf_tst_cflags}" = "\"'" ; then
 191                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 192                                 continue
 193                         fi
 194                         ;;
 195                 esac
 196                 case "$CPPFLAGS" in
 197                 (*$cf_add_cflags)
 198                         ;;
 199                 (*)
 200                         case $cf_add_cflags in
 201                         (-D*)
 202                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 203                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 204                                 ;;
 205                         esac
 206                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 207                         ;;
 208                 esac
 209                 ;;
 210         (*)
 211                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 212                 ;;
 213         esac
 214         ;;
 215 (yes)
 216         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 217
 218         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 219
 220         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 221                 && test -z "${cf_tst_cflags}" \
 222                 && cf_fix_cppflags=no
 223         ;;
 224 esac
 225 done
 226
 227 if test -n "$cf_new_cflags" ; then
 228         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 229         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 230 fi
 231
 232 if test -n "$cf_new_cppflags" ; then
 233         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 234         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 235 fi
 236
 237 if test -n "$cf_new_extra_cppflags" ; then
 238         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 239         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 240 fi
 241
 242 AC_SUBST(EXTRA_CPPFLAGS)
 243
 244 ])dnl
 245 dnl ---------------------------------------------------------------------------
 246 dnl CF_ADD_INCDIR version: 14 updated: 2015/05/25 20:53:04
 247 dnl -------------
 248 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 249 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 250 dnl but old versions (and some misinstalled ones) need that.  To make things
 251 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 252 dnl the include-path).
 253 AC_DEFUN([CF_ADD_INCDIR],
 254 [
 255 if test -n "$1" ; then
 256   for cf_add_incdir in $1
 257   do
 258         while test $cf_add_incdir != /usr/include
 259         do
 260           if test -d $cf_add_incdir
 261           then
 262                 cf_have_incdir=no
 263                 if test -n "$CFLAGS$CPPFLAGS" ; then
 264                   # a loop is needed to ensure we can add subdirs of existing dirs
 265                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 266                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 267                           cf_have_incdir=yes; break
 268                         fi
 269                   done
 270                 fi
 271
 272                 if test "$cf_have_incdir" = no ; then
 273                   if test "$cf_add_incdir" = /usr/local/include ; then
 274                         if test "$GCC" = yes
 275                         then
 276                           cf_save_CPPFLAGS=$CPPFLAGS
 277                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 278                           AC_TRY_COMPILE([#include <stdio.h>],
 279                                   [printf("Hello")],
 280                                   [],
 281                                   [cf_have_incdir=yes])
 282                           CPPFLAGS=$cf_save_CPPFLAGS
 283                         fi
 284                   fi
 285                 fi
 286
 287                 if test "$cf_have_incdir" = no ; then
 288                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 289                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 290
 291                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 292                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 293                   cf_add_incdir="$cf_top_incdir"
 294                 else
 295                   break
 296                 fi
 297           else
 298                 break
 299           fi
 300         done
 301   done
 302 fi
 303 ])dnl
 304 dnl ---------------------------------------------------------------------------
 305 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 306 dnl ----------
 307 dnl Add a library, used to enforce consistency.
 308 dnl
 309 dnl $1 = library to add, without the "-l"
 310 dnl $2 = variable to update (default $LIBS)
 311 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 312 dnl ---------------------------------------------------------------------------
 313 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 314 dnl -------------
 315 dnl     Adds to the library-path
 316 dnl
 317 dnl     Some machines have trouble with multiple -L options.
 318 dnl
 319 dnl $1 is the (list of) directory(s) to add
 320 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 321 dnl
 322 AC_DEFUN([CF_ADD_LIBDIR],
 323 [
 324 if test -n "$1" ; then
 325         for cf_add_libdir in $1
 326         do
 327                 if test $cf_add_libdir = /usr/lib ; then
 328                         :
 329                 elif test -d $cf_add_libdir
 330                 then
 331                         cf_have_libdir=no
 332                         if test -n "$LDFLAGS$LIBS" ; then
 333                                 # a loop is needed to ensure we can add subdirs of existing dirs
 334                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 335                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 336                                                 cf_have_libdir=yes; break
 337                                         fi
 338                                 done
 339                         fi
 340                         if test "$cf_have_libdir" = no ; then
 341                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 342                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 343                         fi
 344                 fi
 345         done
 346 fi
 347 ])dnl
 348 dnl ---------------------------------------------------------------------------
 349 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
 350 dnl -----------
 351 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 352 dnl prepended to an existing list, since their dependencies are assumed to
 353 dnl already exist in the list.
 354 dnl
 355 dnl $1 = libraries to add, with the "-l", etc.
 356 dnl $2 = variable to update (default $LIBS)
 357 AC_DEFUN([CF_ADD_LIBS],[
 358 cf_add_libs="$1"
 359 # Filter out duplicates - this happens with badly-designed ".pc" files...
 360 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
 361 do
 362         for cf_add_2lib in $cf_add_libs
 363         do
 364                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
 365                 then
 366                         cf_add_1lib=
 367                         break
 368                 fi
 369         done
 370         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
 371 done
 372 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 373 ])dnl
 374 dnl ---------------------------------------------------------------------------
 375 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 376 dnl ------------------
 377 dnl Append to a search-list for a nonstandard header/lib-file
 378 dnl     $1 = the variable to return as result
 379 dnl     $2 = the package name
 380 dnl     $3 = the subdirectory, e.g., bin, include or lib
 381 dnl $4 = the directory under which we will test for subdirectories
 382 dnl $5 = a directory that we do not want $4 to match
 383 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 384 [
 385 test "x$4" != "x$5" && \
 386 test -d "$4" && \
 387 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 388         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 389         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 390         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 391         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 392         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 393         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 394 }
 395 ])dnl
 396 dnl ---------------------------------------------------------------------------
 397 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 398 dnl --------------
 399 dnl use this macro for appending text without introducing an extra blank at
 400 dnl the beginning
 401 define([CF_APPEND_TEXT],
 402 [
 403         test -n "[$]$1" && $1="[$]$1 "
 404         $1="[$]{$1}$2"
 405 ])dnl
 406 dnl ---------------------------------------------------------------------------
 407 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 408 dnl --------------
 409 dnl Allow user to disable a normally-on option.
 410 AC_DEFUN([CF_ARG_DISABLE],
 411 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 412 dnl ---------------------------------------------------------------------------
 413 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 414 dnl -------------
 415 dnl Allow user to enable a normally-off option.
 416 AC_DEFUN([CF_ARG_ENABLE],
 417 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 418 dnl ---------------------------------------------------------------------------
 419 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 420 dnl -------------
 421 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 422 dnl values.
 423 dnl
 424 dnl Parameters:
 425 dnl $1 = option name
 426 dnl $2 = help-string
 427 dnl $3 = action to perform if option is not default
 428 dnl $4 = action if perform if option is default
 429 dnl $5 = default option value (either 'yes' or 'no')
 430 AC_DEFUN([CF_ARG_OPTION],
 431 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 432         if test "$enableval" != "$5" ; then
 433 ifelse([$3],,[    :]dnl
 434 ,[    $3]) ifelse([$4],,,[
 435         else
 436                 $4])
 437         fi],[enableval=$5 ifelse([$4],,,[
 438         $4
 439 ])dnl
 440 ])])dnl
 441 dnl ---------------------------------------------------------------------------
 442 dnl CF_AR_FLAGS version: 6 updated: 2015/10/10 15:25:05
 443 dnl -----------
 444 dnl Check for suitable "ar" (archiver) options for updating an archive.
 445 dnl
 446 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 447 dnl as well as a workaround for breakage of make's archive rules by the GNU
 448 dnl binutils "ar" program.
 449 AC_DEFUN([CF_AR_FLAGS],[
 450 AC_REQUIRE([CF_PROG_AR])
 451
 452 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 453         cf_cv_ar_flags=unknown
 454         for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 455         do
 456
 457                 # check if $ARFLAGS already contains this choice
 458                 if test "x$ARFLAGS" != "x" ; then
 459                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 460                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 461                                 cf_cv_ar_flags=
 462                                 break
 463                         fi
 464                 fi
 465
 466                 rm -f conftest.$ac_cv_objext
 467                 rm -f conftest.a
 468
 469                 cat >conftest.$ac_ext <<EOF
 470 #line __oline__ "configure"
 471 int     testdata[[3]] = { 123, 456, 789 };
 472 EOF
 473                 if AC_TRY_EVAL(ac_compile) ; then
 474                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 475                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 476                         if test -f conftest.a ; then
 477                                 cf_cv_ar_flags=$cf_ar_flags
 478                                 break
 479                         fi
 480                 else
 481                         CF_VERBOSE(cannot compile test-program)
 482                         break
 483                 fi
 484         done
 485         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 486 ])
 487
 488 if test -n "$ARFLAGS" ; then
 489         if test -n "$cf_cv_ar_flags" ; then
 490                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 491         fi
 492 else
 493         ARFLAGS=$cf_cv_ar_flags
 494 fi
 495
 496 AC_SUBST(ARFLAGS)
 497 ])
 498 dnl ---------------------------------------------------------------------------
 499 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
 500 dnl -----------------
 501 dnl Check if awk can handle big strings using printf.  Some older versions of
 502 dnl awk choke on large strings passed via "%s".
 503 dnl
 504 dnl $1 = desired string size
 505 dnl $2 = variable to set with result
 506 AC_DEFUN([CF_AWK_BIG_PRINTF],
 507 [
 508         case x$AWK in
 509         (x)
 510                 eval $2=no
 511                 ;;
 512         (*)
 513                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 514                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 515                         eval $2=yes
 516                 else
 517                         eval $2=no
 518                 fi
 519                 ;;
 520         esac
 521 ])dnl
 522 dnl ---------------------------------------------------------------------------
 523 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 524 dnl ------------
 525 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 526 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 527 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 528 dnl
 529 dnl Treat the configuration-variable specially here, since we're directly
 530 dnl substituting its value (i.e., 1/0).
 531 dnl
 532 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 533 AC_DEFUN([CF_BOOL_DECL],
 534 [
 535 AC_MSG_CHECKING(if we should include stdbool.h)
 536
 537 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 538         AC_TRY_COMPILE([],[bool foo = false],
 539                 [cf_cv_header_stdbool_h=0],
 540                 [AC_TRY_COMPILE([
 541 #ifndef __BEOS__
 542 #include <stdbool.h>
 543 #endif
 544 ],[bool foo = false],
 545                         [cf_cv_header_stdbool_h=1],
 546                         [cf_cv_header_stdbool_h=0])])])
 547
 548 if test "$cf_cv_header_stdbool_h" = 1
 549 then    AC_MSG_RESULT(yes)
 550 else    AC_MSG_RESULT(no)
 551 fi
 552
 553 AC_MSG_CHECKING([for builtin bool type])
 554
 555 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 556         AC_TRY_COMPILE([
 557 #include <stdio.h>
 558 #include <sys/types.h>
 559 ],[bool x = false],
 560                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 561                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 562         ])
 563
 564 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 565 then    AC_MSG_RESULT(yes)
 566 else    AC_MSG_RESULT(no)
 567 fi
 568 ])dnl
 569 dnl ---------------------------------------------------------------------------
 570 dnl CF_BOOL_SIZE version: 15 updated: 2017/01/21 11:06:25
 571 dnl ------------
 572 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 573 dnl Don't bother looking for bool.h, since it's been deprecated.
 574 dnl
 575 dnl If the current compiler is C rather than C++, we get the bool definition
 576 dnl from <stdbool.h>.
 577 AC_DEFUN([CF_BOOL_SIZE],
 578 [
 579 AC_MSG_CHECKING([for size of bool])
 580 AC_CACHE_VAL(cf_cv_type_of_bool,[
 581         rm -f cf_test.out
 582         AC_TRY_RUN([
 583 #include <stdlib.h>
 584 #include <stdio.h>
 585
 586 #if defined(__cplusplus)
 587
 588 #ifdef HAVE_GXX_BUILTIN_H
 589 #include <g++/builtin.h>
 590 #elif HAVE_GPP_BUILTIN_H
 591 #include <gpp/builtin.h>
 592 #elif HAVE_BUILTIN_H
 593 #include <builtin.h>
 594 #endif
 595
 596 #else
 597
 598 #if $cf_cv_header_stdbool_h
 599 #include <stdbool.h>
 600 #endif
 601
 602 #endif
 603
 604 int main(void)
 605 {
 606         FILE *fp = fopen("cf_test.out", "w");
 607         if (fp != 0) {
 608                 bool x = true;
 609                 if ((bool)(-x) >= 0)
 610                         fputs("unsigned ", fp);
 611                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 612                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 613                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 614                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 615                 fclose(fp);
 616         }
 617         ${cf_cv_main_return:-return}(0);
 618 }
 619                 ],
 620                 [cf_cv_type_of_bool=`cat cf_test.out`
 621                  if test -z "$cf_cv_type_of_bool"; then
 622                    cf_cv_type_of_bool=unknown
 623                  fi],
 624                 [cf_cv_type_of_bool=unknown],
 625                 [cf_cv_type_of_bool=unknown])
 626         ])
 627         rm -f cf_test.out
 628 AC_MSG_RESULT($cf_cv_type_of_bool)
 629 if test "$cf_cv_type_of_bool" = unknown ; then
 630         case .$NCURSES_BOOL in
 631         (.auto|.) NCURSES_BOOL=unsigned;;
 632         esac
 633         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 634         cf_cv_type_of_bool=$NCURSES_BOOL
 635 fi
 636 ])dnl
 637 dnl ---------------------------------------------------------------------------
 638 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
 639 dnl -----------
 640 dnl If we're cross-compiling, allow the user to override the tools and their
 641 dnl options.  The configure script is oriented toward identifying the host
 642 dnl compiler, etc., but we need a build compiler to generate parts of the
 643 dnl source.
 644 dnl
 645 dnl $1 = default for $CPPFLAGS
 646 dnl $2 = default for $LIBS
 647 AC_DEFUN([CF_BUILD_CC],[
 648 CF_ACVERSION_CHECK(2.52,,
 649         [AC_REQUIRE([CF_PROG_EXT])])
 650 if test "$cross_compiling" = yes ; then
 651
 652         # defaults that we might want to override
 653         : ${BUILD_CFLAGS:=''}
 654         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 655         : ${BUILD_LDFLAGS:=''}
 656         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 657         : ${BUILD_EXEEXT:='$x'}
 658         : ${BUILD_OBJEXT:='o'}
 659
 660         AC_ARG_WITH(build-cc,
 661                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 662                 [BUILD_CC="$withval"],
 663                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 664         AC_MSG_CHECKING(for native build C compiler)
 665         AC_MSG_RESULT($BUILD_CC)
 666
 667         AC_MSG_CHECKING(for native build C preprocessor)
 668         AC_ARG_WITH(build-cpp,
 669                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 670                 [BUILD_CPP="$withval"],
 671                 [BUILD_CPP='${BUILD_CC} -E'])
 672         AC_MSG_RESULT($BUILD_CPP)
 673
 674         AC_MSG_CHECKING(for native build C flags)
 675         AC_ARG_WITH(build-cflags,
 676                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 677                 [BUILD_CFLAGS="$withval"])
 678         AC_MSG_RESULT($BUILD_CFLAGS)
 679
 680         AC_MSG_CHECKING(for native build C preprocessor-flags)
 681         AC_ARG_WITH(build-cppflags,
 682                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 683                 [BUILD_CPPFLAGS="$withval"])
 684         AC_MSG_RESULT($BUILD_CPPFLAGS)
 685
 686         AC_MSG_CHECKING(for native build linker-flags)
 687         AC_ARG_WITH(build-ldflags,
 688                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 689                 [BUILD_LDFLAGS="$withval"])
 690         AC_MSG_RESULT($BUILD_LDFLAGS)
 691
 692         AC_MSG_CHECKING(for native build linker-libraries)
 693         AC_ARG_WITH(build-libs,
 694                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 695                 [BUILD_LIBS="$withval"])
 696         AC_MSG_RESULT($BUILD_LIBS)
 697
 698         # this assumes we're on Unix.
 699         BUILD_EXEEXT=
 700         BUILD_OBJEXT=o
 701
 702         : ${BUILD_CC:='${CC}'}
 703
 704         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 705                 AC_MSG_ERROR([Cross-build requires two compilers.
 706 Use --with-build-cc to specify the native compiler.])
 707         fi
 708
 709 else
 710         : ${BUILD_CC:='${CC}'}
 711         : ${BUILD_CPP:='${CPP}'}
 712         : ${BUILD_CFLAGS:='${CFLAGS}'}
 713         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 714         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 715         : ${BUILD_LIBS:='${LIBS}'}
 716         : ${BUILD_EXEEXT:='$x'}
 717         : ${BUILD_OBJEXT:='o'}
 718 fi
 719
 720 AC_SUBST(BUILD_CC)
 721 AC_SUBST(BUILD_CPP)
 722 AC_SUBST(BUILD_CFLAGS)
 723 AC_SUBST(BUILD_CPPFLAGS)
 724 AC_SUBST(BUILD_LDFLAGS)
 725 AC_SUBST(BUILD_LIBS)
 726 AC_SUBST(BUILD_EXEEXT)
 727 AC_SUBST(BUILD_OBJEXT)
 728 ])dnl
 729 dnl ---------------------------------------------------------------------------
 730 dnl CF_CC_ENV_FLAGS version: 8 updated: 2017/09/23 08:50:24
 731 dnl ---------------
 732 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 733 dnl into CC.  This will not help with broken scripts that wrap the compiler
 734 dnl with options, but eliminates a more common category of user confusion.
 735 dnl
 736 dnl In particular, it addresses the problem of being able to run the C
 737 dnl preprocessor in a consistent manner.
 738 dnl
 739 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 740 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 741 dnl outweighs that limitation.
 742 AC_DEFUN([CF_CC_ENV_FLAGS],
 743 [
 744 # This should have been defined by AC_PROG_CC
 745 : ${CC:=cc}
 746
 747 AC_MSG_CHECKING(\$CC variable)
 748 case "$CC" in
 749 (*[[\ \ ]]-*)
 750         AC_MSG_RESULT(broken)
 751         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 752         # humor him...
 753         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 754         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
 755         CC="$cf_prog"
 756         for cf_arg in $cf_flags
 757         do
 758                 case "x$cf_arg" in
 759                 (x-[[IUDfgOW]]*)
 760                         CF_ADD_CFLAGS($cf_arg)
 761                         ;;
 762                 (*)
 763                         CC="$CC $cf_arg"
 764                         ;;
 765                 esac
 766         done
 767         CF_VERBOSE(resulting CC: '$CC')
 768         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 769         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 770         ;;
 771 (*)
 772         AC_MSG_RESULT(ok)
 773         ;;
 774 esac
 775 ])dnl
 776 dnl ---------------------------------------------------------------------------
 777 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
 778 dnl ---------------
 779 dnl Determine the default configuration into which we'll install ncurses.  This
 780 dnl can be overridden by the user's command-line options.  There's two items to
 781 dnl look for:
 782 dnl     1. the prefix (e.g., /usr)
 783 dnl     2. the header files (e.g., /usr/include/ncurses)
 784 dnl We'll look for a previous installation of ncurses and use the same defaults.
 785 dnl
 786 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 787 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 788 dnl programs from a vendor's.
 789 AC_DEFUN([CF_CFG_DEFAULTS],
 790 [
 791 AC_MSG_CHECKING(for prefix)
 792 if test "x$prefix" = "xNONE" ; then
 793         case "$cf_cv_system_name" in
 794                 # non-vendor systems don't have a conflict
 795         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 796                 prefix=/usr
 797                 ;;
 798         (*)     prefix=$ac_default_prefix
 799                 ;;
 800         esac
 801 fi
 802 AC_MSG_RESULT($prefix)
 803
 804 if test "x$prefix" = "xNONE" ; then
 805 AC_MSG_CHECKING(for default include-directory)
 806 test -n "$verbose" && echo 1>&AC_FD_MSG
 807 for cf_symbol in \
 808         $includedir \
 809         $includedir/ncurses \
 810         $prefix/include \
 811         $prefix/include/ncurses \
 812         /usr/local/include \
 813         /usr/local/include/ncurses \
 814         /usr/include \
 815         /usr/include/ncurses
 816 do
 817         cf_dir=`eval echo $cf_symbol`
 818         if test -f $cf_dir/curses.h ; then
 819         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 820                 includedir="$cf_symbol"
 821                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 822                 break
 823         fi
 824         fi
 825         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 826 done
 827 AC_MSG_RESULT($includedir)
 828 fi
 829 ])dnl
 830 dnl ---------------------------------------------------------------------------
 831 dnl CF_CGETENT version: 6 updated: 2017/01/21 11:06:25
 832 dnl ----------
 833 dnl Check if the terminal-capability database functions are available.  If not,
 834 dnl ncurses has a much-reduced version.
 835 AC_DEFUN([CF_CGETENT],[
 836 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 837 AC_TRY_LINK([
 838 #include <stdlib.h>],[
 839         char temp[128];
 840         char *buf = temp;
 841         char *db_array = temp;
 842         cgetent(&buf, &db_array, "vt100");
 843         cgetcap(buf, "tc", '=');
 844         cgetmatch(buf, "tc");
 845         ],
 846         [cf_cv_cgetent=yes],
 847         [cf_cv_cgetent=no])
 848 ])
 849
 850 if test "$cf_cv_cgetent" = yes
 851 then
 852         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 853 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 854 AC_TRY_LINK([
 855 #pragma GCC diagnostic error "-Wincompatible-pointer-types-discards-qualifiers"
 856 #include <stdlib.h>],[
 857         char temp[128];
 858         char *buf = temp;
 859 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 860         const char *db_array = temp;
 861         cgetent(&buf, &db_array, "vt100");
 862 #endif
 863         cgetcap(buf, "tc", '=');
 864         cgetmatch(buf, "tc");
 865         ],
 866         [cf_cv_cgetent_const=yes],
 867         [cf_cv_cgetent_const=no])
 868 ])
 869         if test "$cf_cv_cgetent_const" = yes
 870         then
 871                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 872         fi
 873 fi
 874 ])dnl
 875 dnl ---------------------------------------------------------------------------
 876 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 877 dnl --------------
 878 dnl Check if we're accidentally using a cache from a different machine.
 879 dnl Derive the system name, as a check for reusing the autoconf cache.
 880 dnl
 881 dnl If we've packaged config.guess and config.sub, run that (since it does a
 882 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 883 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 884 dnl which is useful in cross-compiles.
 885 dnl
 886 dnl Note: we would use $ac_config_sub, but that is one of the places where
 887 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 888 AC_DEFUN([CF_CHECK_CACHE],
 889 [
 890 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 891         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 892         system_name="$host_os"
 893 else
 894         system_name="`(uname -s -r) 2>/dev/null`"
 895         if test -z "$system_name" ; then
 896                 system_name="`(hostname) 2>/dev/null`"
 897         fi
 898 fi
 899 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 900 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 901
 902 test -z "$system_name" && system_name="$cf_cv_system_name"
 903 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 904
 905 if test ".$system_name" != ".$cf_cv_system_name" ; then
 906         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 907         AC_MSG_ERROR("Please remove config.cache and try again.")
 908 fi
 909 ])dnl
 910 dnl ---------------------------------------------------------------------------
 911 dnl CF_CHECK_ERRNO version: 12 updated: 2015/04/18 08:56:57
 912 dnl --------------
 913 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 914 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 915 dnl ourselves.
 916 dnl
 917 dnl $1 = the name to check
 918 dnl $2 = the assumed type
 919 AC_DEFUN([CF_CHECK_ERRNO],
 920 [
 921 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 922         AC_TRY_COMPILE([
 923 #ifdef HAVE_STDLIB_H
 924 #include <stdlib.h>
 925 #endif
 926 #include <stdio.h>
 927 #include <sys/types.h>
 928 #include <errno.h> ],
 929         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 930         [cf_cv_dcl_$1=yes],
 931         [cf_cv_dcl_$1=no])
 932 ])
 933
 934 if test "$cf_cv_dcl_$1" = no ; then
 935         CF_UPPER(cf_result,decl_$1)
 936         AC_DEFINE_UNQUOTED($cf_result)
 937 fi
 938
 939 # It's possible (for near-UNIX clones) that the data doesn't exist
 940 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 941 ])dnl
 942 dnl ---------------------------------------------------------------------------
 943 dnl CF_CHECK_EXTERN_DATA version: 4 updated: 2015/04/18 08:56:57
 944 dnl --------------------
 945 dnl Check for existence of external data in the current set of libraries.  If
 946 dnl we can modify it, it's real enough.
 947 dnl $1 = the name to check
 948 dnl $2 = its type
 949 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 950 [
 951 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 952         AC_TRY_LINK([
 953 #undef $1
 954 extern $2 $1;
 955 ],
 956         [$1 = 2],
 957         [cf_cv_have_$1=yes],
 958         [cf_cv_have_$1=no])
 959 ])
 960
 961 if test "$cf_cv_have_$1" = yes ; then
 962         CF_UPPER(cf_result,have_$1)
 963         AC_DEFINE_UNQUOTED($cf_result)
 964 fi
 965
 966 ])dnl
 967 dnl ---------------------------------------------------------------------------
 968 dnl CF_CHECK_GPM_WGETCH version: 3 updated: 2017/01/21 11:06:25
 969 dnl -------------------
 970 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 971 dnl is not "weak" - warn about this because it can create problems linking
 972 dnl applications with ncurses.
 973 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 974 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 975
 976 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 977 cf_cv_check_gpm_wgetch=unknown
 978 if test "$cross_compiling" != yes ; then
 979
 980 cat >conftest.$ac_ext <<CF_EOF
 981 #include <gpm.h>
 982 int main(void)
 983 {
 984         Gpm_Wgetch();
 985         ${cf_cv_main_return:-return}(0);
 986 }
 987 CF_EOF
 988
 989         cf_save_LIBS="$LIBS"
 990         # This only works if we can look at the symbol table.  If a shared
 991         # library is stripped for install, we cannot use that.  So we're forced
 992         # to rely on the static library, noting that some packagers may not
 993         # include it.
 994         LIBS="-static -lgpm -dynamic $LIBS"
 995         if AC_TRY_EVAL(ac_compile) ; then
 996                 if AC_TRY_EVAL(ac_link) ; then
 997                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
 998                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
 999                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
1000                 fi
1001         fi
1002         rm -rf conftest*
1003         LIBS="$cf_save_LIBS"
1004 fi
1005 ])
1006
1007 if test "$cf_cv_check_gpm_wgetch" != yes ; then
1008         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
1009 fi
1010 ])])dnl
1011 dnl ---------------------------------------------------------------------------
1012 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
1013 dnl ------------------------
1014 dnl Show the version of libtool
1015 dnl
1016 dnl Save the version in a cache variable - this is not entirely a good thing,
1017 dnl but the version string from libtool is very ugly, and for bug reports it
1018 dnl might be useful to have the original string.
1019 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
1020 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
1021 then
1022         AC_MSG_CHECKING(version of $LIBTOOL)
1023         CF_LIBTOOL_VERSION
1024         AC_MSG_RESULT($cf_cv_libtool_version)
1025         if test -z "$cf_cv_libtool_version" ; then
1026                 AC_MSG_ERROR(This is not GNU libtool)
1027         fi
1028 else
1029         AC_MSG_ERROR(GNU libtool has not been found)
1030 fi
1031 ])dnl
1032 dnl ---------------------------------------------------------------------------
1033 dnl CF_CHECK_WCHAR_H version: 2 updated: 2017/01/21 11:06:25
1034 dnl ----------------
1035 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
1036 AC_DEFUN([CF_CHECK_WCHAR_H],[
1037 AC_CHECK_HEADERS( \
1038 wchar.h \
1039 wctype.h \
1040 )
1041 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1042 AC_TRY_COMPILE(
1043 [
1044 #include <stdlib.h>
1045 #ifdef HAVE_WCHAR_H
1046 #include <wchar.h>
1047 #endif
1048 #ifdef HAVE_WCTYPE_H
1049 #include <wctype.h>
1050 #endif
1051 ],[
1052         wint_t foo = 0;
1053         int bar = iswpunct(foo)],
1054         [cf_cv_wchar_h_okay=yes],
1055         [cf_cv_wchar_h_okay=no])])
1056
1057 if test $cf_cv_wchar_h_okay = no
1058 then
1059         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1060 fi
1061 ])dnl
1062 dnl ---------------------------------------------------------------------------
1063 dnl CF_CHECK_WCWIDTH_GRAPHICS version: 1 updated: 2015/12/19 17:47:56
1064 dnl -------------------------
1065 dnl Most "modern" terminal emulators are based to some degree on VT100, and
1066 dnl should support line-drawing.  Even with Unicode.  There is a problem.
1067 dnl
1068 dnl While most of the VT100 graphics characters were incorporated into Unicode,
1069 dnl all of those were combined into a page of useful graphics characters.
1070 dnl
1071 dnl So far, so good.
1072 dnl
1073 dnl However, while they are useful, there are other considerations.  CJK
1074 dnl is (because of poor device resolution) often rendered as double-width
1075 dnl characters.  So... for these generally-useful characters, what should
1076 dnl be the width (to make them consistent with adjacent characters)?
1077 dnl
1078 dnl The obvious choice would have been to make this locale-dependent, and use
1079 dnl wcwidth() to tell applications what the actual width is.  That was too
1080 dnl obvious.  Instead, we have a slew of "ambiguous-width" characters.
1081 dnl See for example
1082 dnl             http://www.unicode.org/reports/tr11/tr11-29.html
1083 dnl             http://www.cl.cam.ac.uk/~mgk25/ucs/scw-proposal.html
1084 dnl
1085 dnl The EastAsianWidth-6.2.0.txt file from the Unicode organization lists
1086 dnl more than 22,000 characters, with 1281 of those as ambiguous-width.  For
1087 dnl instance, it lists half (44/96) of the Latin-1 characters as
1088 dnl ambiguous-width.  Also, all of the box-characters at 0x2500 are ambiguous.
1089 dnl
1090 dnl What this means for the implementor is that on some systems wcwidth() can
1091 dnl give bad advice.  On Solaris, some of the ambiguous widths are returned as
1092 dnl 1 (the Latin-1 characters), while others are returned as 2 (line-drawing
1093 dnl characters).  These do not necessarily match the behavior of the terminal
1094 dnl emulator.  xterm, for instance, does an optional startup check to find if
1095 dnl this problem (or similar) exists with the system's locale tables, rejecting
1096 dnl them if they are too unreliable.
1097 AC_DEFUN([CF_CHECK_WCWIDTH_GRAPHICS],[
1098 AC_CACHE_CHECK(if wcwidth agrees graphics are single-width, cf_cv_wcwidth_graphics,[
1099 cat >conftest.in <<CF_EOF
1100 -       VT100 symbols
1101 0x250c  upper left corner
1102 0x2514  lower left corner
1103 0x2510  upper right corner
1104 0x2518  lower right corner
1105 0x251c  tee pointing left
1106 0x2524  tee pointing right
1107 0x2534  tee pointing up
1108 0x252c  tee pointing down
1109 0x2500  horizontal line
1110 0x2502  vertical line
1111 0x253c  large plus or crossover
1112 0x23ba  scan line 1
1113 0x23bd  scan line 9
1114 0x25c6  diamond
1115 0x2592  checker board (stipple)
1116 0x00b0  degree symbol
1117 0x00b1  plus/minus
1118 0x00b7  bullet
1119 -       Teletype 5410v1 symbols
1120 0x2190  arrow pointing left
1121 0x2192  arrow pointing right
1122 0x2193  arrow pointing down
1123 0x2191  arrow pointing up
1124 0x2592  board of squares
1125 0x2603  lantern symbol
1126 0x25ae  solid square block
1127 -       these defaults were invented for ncurses
1128 0x23bb  scan line 3
1129 0x23bc  scan line 7
1130 0x2264  less-than-or-equal-to
1131 0x2265  greater-than-or-equal-to
1132 0x03c0  greek pi
1133 0x2260  not-equal
1134 0x00a3  pound-sterling symbol
1135 -       thick-line-drawing
1136 0x250f  upper left corner
1137 0x2517  lower left corner
1138 0x2513  upper right corner
1139 0x251b  lower right corner
1140 0x2523  tee pointing left
1141 0x252b  tee pointing right
1142 0x253b  tee pointing up
1143 0x2533  tee pointing down
1144 0x2501  horizontal line
1145 0x2503  vertical line
1146 0x254b  large plus or crossover
1147 -       double-line-drawing
1148 0x2554  upper left corner
1149 0x255a  lower left corner
1150 0x2557  upper right corner
1151 0x255d  lower right corner
1152 0x2563  tee pointing left
1153 0x2560  tee pointing right
1154 0x2569  tee pointing up
1155 0x2566  tee pointing down
1156 0x2550  horizontal line
1157 0x2551  vertical line
1158 0x256c  large plus or crossover
1159 CF_EOF
1160 AC_TRY_RUN([
1161 #include <locale.h>
1162 #include <stdio.h>
1163 #include <wchar.h>
1164
1165 #define MY_LEN 80
1166
1167 int
1168 main(void)
1169 {
1170         FILE *fp;
1171         int value;
1172         char buffer[MY_LEN + 1];
1173         char notes[MY_LEN + 1];
1174         int totals = 0;
1175         int passed = 0;
1176
1177         if (setlocale(LC_ALL, "en_US.UTF8") ||
1178                 setlocale(LC_ALL, "en_US.UTF-8") ||
1179                 setlocale(LC_ALL, "en_US.utf8") ||
1180                 setlocale(LC_ALL, "en_US.utf-8")) {
1181                 if ((fp = fopen("conftest.in", "r")) != 0) {
1182                         while (fgets(buffer, MY_LEN, fp) != 0) {
1183                                 if (*buffer == '-') {
1184                                         fprintf(stderr, "\t%s", buffer);
1185                                 } else if (sscanf(buffer, "%x %s", &value, notes) == 2) {
1186                                         ++totals;
1187                                         if (wcwidth(value) == 1)
1188                                                 ++passed;
1189                                         fprintf(stderr, "%d\t%s", wcwidth(value), buffer);
1190                                 } else {
1191                                         fprintf(stderr, "?\t%s", buffer);
1192                                 }
1193                         }
1194                 }
1195         }
1196         fprintf(stderr, "%d/%d passed wcwidth/graphics check\n", passed, totals);
1197         return (totals == passed) ? 0 : 1;
1198 }
1199 ],
1200 [cf_cv_wcwidth_graphics=yes],
1201 [cf_cv_wcwidth_graphics=no],
1202 [cf_cv_wcwidth_graphics=unknown])
1203 ])
1204 ])dnl
1205 dnl ---------------------------------------------------------------------------
1206 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
1207 dnl -----------------
1208 dnl Check if the given compiler is really clang.  clang's C driver defines
1209 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1210 dnl not ignore some gcc options.
1211 dnl
1212 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1213 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1214 dnl the wrappers for gcc and g++ warnings.
1215 dnl
1216 dnl $1 = GCC (default) or GXX
1217 dnl $2 = CLANG_COMPILER (default)
1218 dnl $3 = CFLAGS (default) or CXXFLAGS
1219 AC_DEFUN([CF_CLANG_COMPILER],[
1220 ifelse([$2],,CLANG_COMPILER,[$2])=no
1221
1222 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1223         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1224         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1225         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
1226         AC_TRY_COMPILE([],[
1227 #ifdef __clang__
1228 #else
1229 make an error
1230 #endif
1231 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1232 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
1233 ],[])
1234         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1235         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1236 fi
1237 ])
1238 dnl ---------------------------------------------------------------------------
1239 dnl CF_CPP_PARAM_INIT version: 7 updated: 2017/01/21 11:06:25
1240 dnl -----------------
1241 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1242 dnl is a late feature for the standard and is not in some recent compilers
1243 dnl (1999/9/11).
1244 AC_DEFUN([CF_CPP_PARAM_INIT],
1245 [
1246 if test -n "$CXX"; then
1247 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1248         AC_LANG_SAVE
1249         AC_LANG_CPLUSPLUS
1250         AC_TRY_RUN([
1251 class TEST {
1252 private:
1253         int value;
1254 public:
1255         TEST(int x = 1);
1256         ~TEST();
1257 };
1258
1259 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1260 {
1261         value = x;
1262 }
1263 int main(void) { }
1264 ],
1265         [cf_cv_cpp_param_init=yes],
1266         [cf_cv_cpp_param_init=no],
1267         [cf_cv_cpp_param_init=unknown])
1268         AC_LANG_RESTORE
1269 ])
1270 fi
1271 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1272 ])dnl
1273 dnl ---------------------------------------------------------------------------
1274 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1275 dnl ------------------
1276 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1277 dnl not be supported in g++ before 3.0
1278 AC_DEFUN([CF_CPP_STATIC_CAST],
1279 [
1280 if test -n "$CXX"; then
1281
1282 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1283         AC_LANG_SAVE
1284         AC_LANG_CPLUSPLUS
1285
1286         AC_TRY_COMPILE([
1287 class NCursesPanel
1288 {
1289 public:
1290   NCursesPanel(int nlines,
1291                int ncols,
1292                int begin_y = 0,
1293                int begin_x = 0)
1294   {
1295   }
1296   NCursesPanel();
1297   ~NCursesPanel();
1298 };
1299
1300 template<class T> class NCursesUserPanel : public NCursesPanel
1301 {
1302 public:
1303   NCursesUserPanel (int nlines,
1304                     int ncols,
1305                     int begin_y = 0,
1306                     int begin_x = 0,
1307                     const T* p_UserData = static_cast<T*>(0))
1308     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1309   {
1310   };
1311   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1312   {
1313   };
1314
1315   virtual ~NCursesUserPanel() {};
1316 };
1317 ],[
1318         const char* p_UserData = static_cast<char*>(0)],
1319         [cf_cv_cpp_static_cast=yes],
1320         [cf_cv_cpp_static_cast=no])
1321
1322         AC_LANG_RESTORE
1323 ])
1324
1325 fi
1326
1327 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1328 ])dnl
1329 dnl ---------------------------------------------------------------------------
1330 dnl CF_CXX_AR_FLAGS version: 2 updated: 2015/04/17 21:13:04
1331 dnl ---------------
1332 dnl Setup special archiver flags for given compilers.
1333 AC_DEFUN([CF_CXX_AR_FLAGS],[
1334         CXX_AR='$(AR)'
1335         CXX_ARFLAGS='$(ARFLAGS)'
1336         case $cf_cv_system_name in
1337         (irix*)
1338             if test "$GXX" != yes ; then
1339                 CXX_AR='$(CXX)'
1340                 CXX_ARFLAGS='-ar -o'
1341             fi
1342             ;;
1343         (sco3.2v5*)
1344             CXXLDFLAGS="-u main"
1345             ;;
1346         (solaris2*)
1347             if test "$GXX" != yes ; then
1348                 CXX_AR='$(CXX)'
1349                 CXX_ARFLAGS='-xar -o'
1350             fi
1351             ;;
1352         esac
1353         AC_SUBST(CXXLDFLAGS)
1354         AC_SUBST(CXX_AR)
1355         AC_SUBST(CXX_ARFLAGS)
1356 ])dnl
1357 dnl ---------------------------------------------------------------------------
1358 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1359 dnl -------------------------
1360 dnl For c++, check if iostream uses "std::" namespace.
1361 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1362 AC_CHECK_HEADERS(iostream)
1363 if test x"$ac_cv_header_iostream" = xyes ; then
1364         AC_MSG_CHECKING(if iostream uses std-namespace)
1365         AC_TRY_COMPILE([
1366 #include <iostream>
1367 using std::endl;
1368 using std::cerr;],[
1369 cerr << "testing" << endl;
1370 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1371         AC_MSG_RESULT($cf_iostream_namespace)
1372         if test "$cf_iostream_namespace" = yes ; then
1373                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1374         fi
1375 fi
1376 ])dnl
1377 dnl ---------------------------------------------------------------------------
1378 dnl CF_C_INLINE version: 5 updated: 2015/04/18 08:56:57
1379 dnl -----------
1380 dnl Check if the C compiler supports "inline".
1381 dnl $1 is the name of a shell variable to set if inline is supported
1382 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1383 AC_DEFUN([CF_C_INLINE],[
1384 AC_C_INLINE
1385 $1=
1386 if test "$ac_cv_c_inline" != no ; then
1387         $1=inline
1388         if test "$INTEL_COMPILER" = yes
1389         then
1390                 :
1391         elif test "$CLANG_COMPILER" = yes
1392         then
1393                 :
1394         elif test "$GCC" = yes
1395         then
1396                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1397                 cf_save_CFLAGS=$CFLAGS
1398                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1399                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1400                 [${cf_cv_main_return:-return} foo()],
1401                 [cf_cv_gcc_inline=yes],
1402                 [cf_cv_gcc_inline=no])
1403                 CFLAGS=$cf_save_CFLAGS
1404                 ])
1405                 if test "$cf_cv_gcc_inline" = yes ; then
1406                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1407                 fi
1408         fi
1409 fi
1410 AC_SUBST($1)
1411 ])dnl
1412 dnl ---------------------------------------------------------------------------
1413 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1414 dnl ----------
1415 dnl "dirname" is not portable, so we fake it with a shell script.
1416 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1417 dnl ---------------------------------------------------------------------------
1418 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1419 dnl ---------------
1420 AC_DEFUN([CF_DIRS_TO_MAKE],
1421 [
1422 DIRS_TO_MAKE="lib"
1423 for cf_item in $cf_list_models
1424 do
1425         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1426         for cf_item2 in $DIRS_TO_MAKE
1427         do
1428                 test $cf_item2 = $cf_subdir && break
1429         done
1430         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1431 done
1432 for cf_dir in $DIRS_TO_MAKE
1433 do
1434         test ! -d $cf_dir && mkdir $cf_dir
1435 done
1436 AC_SUBST(DIRS_TO_MAKE)
1437 ])dnl
1438 dnl ---------------------------------------------------------------------------
1439 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1440 dnl ---------------
1441 dnl You can always use "make -n" to see the actual options, but it's hard to
1442 dnl pick out/analyze warning messages when the compile-line is long.
1443 dnl
1444 dnl Sets:
1445 dnl     ECHO_LT - symbol to control if libtool is verbose
1446 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1447 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1448 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1449 dnl     ECHO_CC - symbol to put before any "cc" line
1450 dnl
1451 AC_DEFUN([CF_DISABLE_ECHO],[
1452 AC_MSG_CHECKING(if you want to see long compiling messages)
1453 CF_ARG_DISABLE(echo,
1454         [  --disable-echo          do not display "compiling" commands],
1455         [
1456         ECHO_LT='--silent'
1457         ECHO_LD='@echo linking [$]@;'
1458         RULE_CC='@echo compiling [$]<'
1459         SHOW_CC='@echo compiling [$]@'
1460         ECHO_CC='@'
1461 ],[
1462         ECHO_LT=''
1463         ECHO_LD=''
1464         RULE_CC=''
1465         SHOW_CC=''
1466         ECHO_CC=''
1467 ])
1468 AC_MSG_RESULT($enableval)
1469 AC_SUBST(ECHO_LT)
1470 AC_SUBST(ECHO_LD)
1471 AC_SUBST(RULE_CC)
1472 AC_SUBST(SHOW_CC)
1473 AC_SUBST(ECHO_CC)
1474 ])dnl
1475 dnl ---------------------------------------------------------------------------
1476 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1477 dnl ------------------------
1478 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1479 AC_MSG_CHECKING(if we want to use GNAT projects)
1480 CF_ARG_DISABLE(gnat-projects,
1481         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1482         [enable_gnat_projects=no],
1483         [enable_gnat_projects=yes])
1484 AC_MSG_RESULT($enable_gnat_projects)
1485 ])dnl
1486 dnl ---------------------------------------------------------------------------
1487 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1488 dnl ----------------
1489 dnl Combine no-leak checks with the libraries or tools that are used for the
1490 dnl checks.
1491 AC_DEFUN([CF_DISABLE_LEAKS],[
1492
1493 AC_REQUIRE([CF_WITH_DMALLOC])
1494 AC_REQUIRE([CF_WITH_DBMALLOC])
1495 AC_REQUIRE([CF_WITH_VALGRIND])
1496
1497 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1498 AC_ARG_ENABLE(leaks,
1499         [  --disable-leaks         test: free permanent memory, analyze leaks],
1500         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1501         : ${with_no_leaks:=no})
1502 AC_MSG_RESULT($with_no_leaks)
1503
1504 if test "$with_no_leaks" = yes ; then
1505         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1506         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1507 fi
1508 ])dnl
1509 dnl ---------------------------------------------------------------------------
1510 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
1511 dnl --------------------------
1512 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1513 dnl the older "-version-info" feature.  The newer feature allows us to use
1514 dnl version numbering on shared libraries which make them compatible with
1515 dnl various systems.
1516 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1517 [
1518 AC_MSG_CHECKING(if libtool -version-number should be used)
1519 CF_ARG_DISABLE(libtool-version,
1520         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1521         [cf_libtool_version=no],
1522         [cf_libtool_version=yes])
1523 AC_MSG_RESULT($cf_libtool_version)
1524
1525 if test "$cf_libtool_version" = yes ; then
1526         LIBTOOL_VERSION="-version-number"
1527 else
1528         LIBTOOL_VERSION="-version-info"
1529         case "x$VERSION" in
1530         (x)
1531                 AC_MSG_WARN(VERSION was not set)
1532                 ;;
1533         (x*.*.*)
1534                 ABI_VERSION="$VERSION"
1535                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1536                 ;;
1537         (x*:*:*)
1538                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
1539                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1540                 ;;
1541         (*)
1542                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
1543                 ;;
1544         esac
1545 fi
1546
1547 AC_SUBST(ABI_VERSION)
1548 AC_SUBST(LIBTOOL_VERSION)
1549 ])dnl
1550 dnl ---------------------------------------------------------------------------
1551 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1552 dnl ---------------------
1553 dnl The rpath-hack makes it simpler to build programs, particularly with the
1554 dnl *BSD ports which may have essential libraries in unusual places.  But it
1555 dnl can interfere with building an executable for the base system.  Use this
1556 dnl option in that case.
1557 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1558 [
1559 AC_MSG_CHECKING(if rpath-hack should be disabled)
1560 CF_ARG_DISABLE(rpath-hack,
1561         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1562         [cf_disable_rpath_hack=yes],
1563         [cf_disable_rpath_hack=no])
1564 AC_MSG_RESULT($cf_disable_rpath_hack)
1565 if test "$cf_disable_rpath_hack" = no ; then
1566         CF_RPATH_HACK
1567 fi
1568 ])
1569 dnl ---------------------------------------------------------------------------
1570 dnl CF_ENABLE_PC_FILES version: 13 updated: 2015/11/01 05:27:39
1571 dnl ------------------
1572 dnl This is the "--enable-pc-files" option, which is available if there is a
1573 dnl pkg-config configuration on the local machine.
1574 AC_DEFUN([CF_ENABLE_PC_FILES],[
1575 AC_REQUIRE([CF_PKG_CONFIG])
1576 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1577
1578 if test "x$PKG_CONFIG" != xnone
1579 then
1580         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1581 else
1582         AC_MSG_CHECKING(if we should install .pc files)
1583 fi
1584
1585 AC_ARG_ENABLE(pc-files,
1586         [  --enable-pc-files       generate and install .pc files for pkg-config],
1587         [enable_pc_files=$enableval],
1588         [enable_pc_files=no])
1589 AC_MSG_RESULT($enable_pc_files)
1590
1591 if test "x$enable_pc_files" != xno
1592 then
1593         MAKE_PC_FILES=
1594         case "x$PKG_CONFIG_LIBDIR" in
1595         (xno|xyes)
1596                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
1597                 ;;
1598         (*)
1599                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1600                 ;;
1601         esac
1602 else
1603         MAKE_PC_FILES="#"
1604 fi
1605 AC_SUBST(MAKE_PC_FILES)
1606 ])dnl
1607 dnl ---------------------------------------------------------------------------
1608 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1609 dnl ---------------
1610 dnl Check if the rpath option should be used, setting cache variable
1611 dnl cf_cv_enable_rpath if so.
1612 AC_DEFUN([CF_ENABLE_RPATH],
1613 [
1614 AC_MSG_CHECKING(if rpath option should be used)
1615 AC_ARG_ENABLE(rpath,
1616 [  --enable-rpath          use rpath option when generating shared libraries],
1617 [cf_cv_enable_rpath=$enableval],
1618 [cf_cv_enable_rpath=no])
1619 AC_MSG_RESULT($cf_cv_enable_rpath)
1620 ])dnl
1621 dnl ---------------------------------------------------------------------------
1622 dnl CF_ENABLE_STRING_HACKS version: 5 updated: 2016/10/08 17:34:11
1623 dnl ----------------------
1624 dnl On a few platforms, the compiler and/or loader nags with untruthful
1625 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1626 dnl and implying that most uses of the recommended alternatives are correct.
1627 dnl
1628 dnl Factually speaking, no one has actually counted the number of uses of these
1629 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1630 dnl instances are meaningless compared to the hundreds of millions of lines of
1631 dnl existing C code.
1632 dnl
1633 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1634 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1635 dnl standard - but evolved through phases, and older implementations are likely
1636 dnl to yield surprising results, as documented in manpages on various systems.
1637 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1638 [
1639 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1640 AC_ARG_ENABLE(string-hacks,
1641         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1642         [with_string_hacks=$enableval],
1643         [with_string_hacks=no])
1644 AC_MSG_RESULT($with_string_hacks)
1645
1646 if test "x$with_string_hacks" = "xyes"; then
1647         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1648         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1649         AC_CHECK_FUNC(strlcat,[
1650                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1651                 ],[
1652                 AC_CHECK_LIB(bsd,strlcat,[
1653                         CF_ADD_LIB(bsd)
1654                         AC_CHECK_HEADERS(bsd/string.h)
1655                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1656                         ])
1657                 ])
1658         AC_CHECK_FUNCS( strlcpy snprintf )
1659 fi
1660 ])dnl
1661 dnl ---------------------------------------------------------------------------
1662 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1663 dnl --------
1664 dnl Check if 'errno' is declared in <errno.h>
1665 AC_DEFUN([CF_ERRNO],
1666 [
1667 CF_CHECK_ERRNO(errno)
1668 ])dnl
1669 dnl ---------------------------------------------------------------------------
1670 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1671 dnl ---------------
1672 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1673 dnl math.h and builtin.h, only for ncurses
1674 AC_DEFUN([CF_ETIP_DEFINES],
1675 [
1676 AC_MSG_CHECKING(for special defines needed for etip.h)
1677 cf_save_CXXFLAGS="$CXXFLAGS"
1678 cf_result="none"
1679
1680 # etip.h includes ncurses.h which includes ncurses_dll.h
1681 # But ncurses_dll.h is generated - fix here.
1682 test -d include || mkdir include
1683 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1684
1685 for cf_math in "" MATH_H
1686 do
1687 for cf_excp in "" MATH_EXCEPTION
1688 do
1689         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1690         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1691         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1692 AC_TRY_COMPILE([
1693 #include <etip.h.in>
1694 ],[],[
1695         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1696         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1697         cf_result="$cf_math $cf_excp"
1698         break 2
1699 ],[])
1700 done
1701 done
1702 AC_MSG_RESULT($cf_result)
1703 CXXFLAGS="$cf_save_CXXFLAGS"
1704 ])
1705 dnl ---------------------------------------------------------------------------
1706 dnl CF_FIND_LINKAGE version: 20 updated: 2015/04/18 08:56:57
1707 dnl ---------------
1708 dnl Find a library (specifically the linkage used in the code fragment),
1709 dnl searching for it if it is not already in the library path.
1710 dnl See also CF_ADD_SEARCHPATH.
1711 dnl
1712 dnl Parameters (4-on are optional):
1713 dnl     $1 = headers for library entrypoint
1714 dnl     $2 = code fragment for library entrypoint
1715 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1716 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1717 dnl     $5 = action to perform if not successful
1718 dnl     $6 = module name, if not the same as the library name
1719 dnl     $7 = extra libraries
1720 dnl
1721 dnl Sets these variables:
1722 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1723 dnl     $cf_cv_header_path_$3 - include-directory if needed
1724 dnl     $cf_cv_library_path_$3 - library-directory if needed
1725 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1726 AC_DEFUN([CF_FIND_LINKAGE],[
1727
1728 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1729 # will be set on completion of the AC_TRY_LINK below.
1730 cf_cv_header_path_$3=
1731 cf_cv_library_path_$3=
1732
1733 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1734
1735 cf_save_LIBS="$LIBS"
1736
1737 AC_TRY_LINK([$1],[$2],[
1738         cf_cv_find_linkage_$3=yes
1739         cf_cv_header_path_$3=/usr/include
1740         cf_cv_library_path_$3=/usr/lib
1741 ],[
1742
1743 LIBS="-l$3 $7 $cf_save_LIBS"
1744
1745 AC_TRY_LINK([$1],[$2],[
1746         cf_cv_find_linkage_$3=yes
1747         cf_cv_header_path_$3=/usr/include
1748         cf_cv_library_path_$3=/usr/lib
1749         cf_cv_library_file_$3="-l$3"
1750 ],[
1751         cf_cv_find_linkage_$3=no
1752         LIBS="$cf_save_LIBS"
1753
1754         CF_VERBOSE(find linkage for $3 library)
1755         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1756
1757         cf_save_CPPFLAGS="$CPPFLAGS"
1758         cf_test_CPPFLAGS="$CPPFLAGS"
1759
1760         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1761         for cf_cv_header_path_$3 in $cf_search
1762         do
1763                 if test -d $cf_cv_header_path_$3 ; then
1764                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1765                         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1766                         AC_TRY_COMPILE([$1],[$2],[
1767                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1768                                 cf_cv_find_linkage_$3=maybe
1769                                 cf_test_CPPFLAGS="$CPPFLAGS"
1770                                 break],[
1771                                 CPPFLAGS="$cf_save_CPPFLAGS"
1772                                 ])
1773                 fi
1774         done
1775
1776         if test "$cf_cv_find_linkage_$3" = maybe ; then
1777
1778                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1779
1780                 cf_save_LIBS="$LIBS"
1781                 cf_save_LDFLAGS="$LDFLAGS"
1782
1783                 ifelse([$6],,,[
1784                 CPPFLAGS="$cf_test_CPPFLAGS"
1785                 LIBS="-l$3 $7 $cf_save_LIBS"
1786                 AC_TRY_LINK([$1],[$2],[
1787                         CF_VERBOSE(... found $3 library in system)
1788                         cf_cv_find_linkage_$3=yes])
1789                         CPPFLAGS="$cf_save_CPPFLAGS"
1790                         LIBS="$cf_save_LIBS"
1791                         ])
1792
1793                 if test "$cf_cv_find_linkage_$3" != yes ; then
1794                         CF_LIBRARY_PATH(cf_search,$3)
1795                         for cf_cv_library_path_$3 in $cf_search
1796                         do
1797                                 if test -d $cf_cv_library_path_$3 ; then
1798                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1799                                         CPPFLAGS="$cf_test_CPPFLAGS"
1800                                         LIBS="-l$3 $7 $cf_save_LIBS"
1801                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1802                                         AC_TRY_LINK([$1],[$2],[
1803                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1804                                         cf_cv_find_linkage_$3=yes
1805                                         cf_cv_library_file_$3="-l$3"
1806                                         break],[
1807                                         CPPFLAGS="$cf_save_CPPFLAGS"
1808                                         LIBS="$cf_save_LIBS"
1809                                         LDFLAGS="$cf_save_LDFLAGS"
1810                                         ])
1811                                 fi
1812                         done
1813                         CPPFLAGS="$cf_save_CPPFLAGS"
1814                         LDFLAGS="$cf_save_LDFLAGS"
1815                 fi
1816
1817         else
1818                 cf_cv_find_linkage_$3=no
1819         fi
1820         ],$7)
1821 ])
1822
1823 LIBS="$cf_save_LIBS"
1824
1825 if test "$cf_cv_find_linkage_$3" = yes ; then
1826 ifelse([$4],,[
1827         CF_ADD_INCDIR($cf_cv_header_path_$3)
1828         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1829         CF_ADD_LIB($3)
1830 ],[$4])
1831 else
1832 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1833 fi
1834 ])dnl
1835 dnl ---------------------------------------------------------------------------
1836 dnl CF_FIND_SUB_INCDIR version: 2 updated: 2015/04/17 21:13:04
1837 dnl ------------------
1838 dnl Find an include-directory with the given leaf-name.  This is useful for
1839 dnl example with FreeBSD ports, which use this convention to distinguish
1840 dnl different versions of the same port.
1841 AC_DEFUN([CF_FIND_SUB_INCDIR],[
1842         CF_SUBDIR_PATH(cf_search,$1,include)
1843         for cf_item in $cf_search
1844         do
1845                 case $cf_item in
1846                 (*/$1)
1847                         CF_ADD_INCDIR($cf_item)
1848                         ;;
1849                 esac
1850         done
1851 ])dnl
1852 dnl ---------------------------------------------------------------------------
1853 dnl CF_FIND_SUB_LIBDIR version: 2 updated: 2015/04/17 21:13:04
1854 dnl ------------------
1855 dnl Find a library-directory with the given leaf-name.  This is useful for
1856 dnl example with FreeBSD ports, which use this convention to distinguish
1857 dnl different versions of the same port.
1858 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
1859         CF_SUBDIR_PATH(cf_search,$1,lib)
1860         for cf_item in $cf_search
1861         do
1862                 case $cf_item in
1863                 (*/$1)
1864                         CF_ADD_LIBDIR($cf_item)
1865                         ;;
1866                 esac
1867         done
1868 ])dnl
1869 dnl ---------------------------------------------------------------------------
1870 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
1871 dnl -----------------
1872 dnl make ADAFLAGS consistent with CFLAGS
1873 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1874         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1875         case "$CFLAGS" in
1876         (*-g*)
1877                 CF_ADD_ADAFLAGS(-g)
1878                 ;;
1879         esac
1880         case "$CFLAGS" in
1881         (*-O*)
1882                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1883                 CF_ADD_ADAFLAGS($cf_O_flag)
1884                 ;;
1885         esac
1886         AC_MSG_RESULT($ADAFLAGS)
1887 ])dnl
1888 dnl ---------------------------------------------------------------------------
1889 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
1890 dnl --------------
1891 dnl Forget that we saw the given tool.
1892 AC_DEFUN([CF_FORGET_TOOL],[
1893 unset ac_cv_prog_ac_ct_$1
1894 unset ac_ct_$1
1895 unset $1
1896 ])dnl
1897 dnl ---------------------------------------------------------------------------
1898 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
1899 dnl -------------
1900 dnl Test for dlsym() and related functions, as well as libdl.
1901 dnl
1902 dnl Sets
1903 dnl     $cf_have_dlsym
1904 dnl     $cf_have_libdl
1905 AC_DEFUN([CF_FUNC_DLSYM],[
1906 cf_have_dlsym=no
1907 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1908
1909 cf_have_libdl=no
1910 AC_CHECK_LIB(dl,dlsym,[
1911         cf_have_dlsym=yes
1912         cf_have_libdl=yes])])
1913
1914 if test "$cf_have_dlsym" = yes ; then
1915         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
1916
1917         AC_MSG_CHECKING(whether able to link to dl*() functions)
1918         AC_TRY_LINK([#include <dlfcn.h>],[
1919                 void *obj;
1920                 if ((obj = dlopen("filename", 0)) != 0) {
1921                         if (dlsym(obj, "symbolname") == 0) {
1922                         dlclose(obj);
1923                         }
1924                 }],[
1925                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
1926                 AC_MSG_ERROR(Cannot link test program for libdl)])
1927         AC_MSG_RESULT(ok)
1928 else
1929         AC_MSG_ERROR(Cannot find dlsym function)
1930 fi
1931 ])
1932 dnl ---------------------------------------------------------------------------
1933 dnl CF_FUNC_MEMMOVE version: 9 updated: 2017/01/21 11:06:25
1934 dnl ---------------
1935 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1936 dnl is found, add our own version of memmove to the list of objects.
1937 AC_DEFUN([CF_FUNC_MEMMOVE],
1938 [
1939 AC_CHECK_FUNC(memmove,,[
1940 AC_CHECK_FUNC(bcopy,[
1941         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1942                 AC_TRY_RUN([
1943 int main(void) {
1944         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1945         char temp[40];
1946         bcopy(data, temp, sizeof(data));
1947         bcopy(temp+10, temp, 15);
1948         bcopy(temp+5, temp+15, 10);
1949         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1950 }
1951                 ],
1952                 [cf_cv_good_bcopy=yes],
1953                 [cf_cv_good_bcopy=no],
1954                 [cf_cv_good_bcopy=unknown])
1955                 ])
1956         ],[cf_cv_good_bcopy=no])
1957         if test "$cf_cv_good_bcopy" = yes ; then
1958                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
1959         else
1960                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
1961         fi
1962 ])])dnl
1963 dnl ---------------------------------------------------------------------------
1964 dnl CF_FUNC_NANOSLEEP version: 5 updated: 2017/01/21 11:06:25
1965 dnl -----------------
1966 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1967 dnl AIX 4.x, provide a non-working version.
1968 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1969 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1970 AC_TRY_RUN([
1971 #include <stdio.h>
1972 #include <errno.h>
1973 #include <time.h>
1974
1975 #ifdef HAVE_SYS_TIME_H
1976 #include <sys/time.h>
1977 #endif
1978
1979 int main(void) {
1980         struct timespec ts1, ts2;
1981         int code;
1982         ts1.tv_sec  = 0;
1983         ts1.tv_nsec = 750000000;
1984         ts2.tv_sec  = 0;
1985         ts2.tv_nsec = 0;
1986         errno = 0;
1987         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1988         ${cf_cv_main_return:-return}(code != 0);
1989 }
1990 ],
1991         [cf_cv_func_nanosleep=yes],
1992         [cf_cv_func_nanosleep=no],
1993         [cf_cv_func_nanosleep=unknown])])
1994
1995 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
1996 ])
1997 dnl ---------------------------------------------------------------------------
1998 dnl CF_FUNC_OPENPTY version: 5 updated: 2015/09/12 14:46:50
1999 dnl ---------------
2000 dnl Check for openpty() function, along with <pty.h> header.  It may need the
2001 dnl "util" library as well.
2002 AC_DEFUN([CF_FUNC_OPENPTY],
2003 [
2004 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
2005 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
2006         cf_save_LIBS="$LIBS"
2007         test $cf_cv_lib_util = yes && { CF_ADD_LIB(util) }
2008         for cf_header in pty.h libutil.h util.h
2009         do
2010         AC_TRY_LINK([
2011 #include <$cf_header>
2012 ],[
2013         int x = openpty((int *)0, (int *)0, (char *)0,
2014                                    (struct termios *)0, (struct winsize *)0);
2015 ],[
2016                 cf_cv_func_openpty=$cf_header
2017                 break
2018 ],[
2019                 cf_cv_func_openpty=no
2020 ])
2021         done
2022         LIBS="$cf_save_LIBS"
2023 ])
2024 ])dnl
2025 dnl ---------------------------------------------------------------------------
2026 dnl CF_FUNC_POLL version: 9 updated: 2015/10/10 13:27:32
2027 dnl ------------
2028 dnl See if the poll function really works.  Some platforms have poll(), but
2029 dnl it does not work for terminals or files.
2030 AC_DEFUN([CF_FUNC_POLL],[
2031 tty 2>&1 >/dev/null || { AC_CHECK_FUNCS(posix_openpt) }
2032 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
2033 AC_TRY_RUN([
2034 #include <stdlib.h>
2035 #include <stdio.h>
2036 #include <unistd.h>
2037 #include <fcntl.h>
2038 #ifdef HAVE_POLL_H
2039 #include <poll.h>
2040 #else
2041 #include <sys/poll.h>
2042 #endif
2043 int main(void) {
2044         struct pollfd myfds;
2045         int ret;
2046
2047         /* check for Darwin bug with respect to "devices" */
2048         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
2049         if (myfds.fd < 0)
2050                 myfds.fd = 0;
2051         myfds.events = POLLIN;
2052         myfds.revents = 0;
2053
2054         ret = poll(&myfds, 1, 100);
2055
2056         if (ret < 0 || (myfds.revents & POLLNVAL)) {
2057                 ret = -1;
2058         } else {
2059                 int fd = 0;
2060                 if (!isatty(fd)) {
2061                         fd = open("/dev/tty", 2);       /* O_RDWR */
2062                 }
2063 #ifdef HAVE_POSIX_OPENPT
2064                 if (fd < 0) {
2065                         fd = posix_openpt(O_RDWR);
2066                 }
2067 #endif
2068
2069                 if (fd >= 0) {
2070                         /* also check with standard input */
2071                         myfds.fd = fd;
2072                         myfds.events = POLLIN;
2073                         myfds.revents = 0;
2074                         ret = poll(&myfds, 1, 100);
2075                 } else {
2076                         ret = -1;
2077                 }
2078         }
2079         ${cf_cv_main_return:-return}(ret < 0);
2080 }],
2081         [cf_cv_working_poll=yes],
2082         [cf_cv_working_poll=no],
2083         [cf_cv_working_poll=unknown])])
2084 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
2085 ])dnl
2086 dnl ---------------------------------------------------------------------------
2087 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
2088 dnl ---------------
2089 dnl Some old/broken variations define tcgetattr() only as a macro in
2090 dnl termio(s).h
2091 AC_DEFUN([CF_FUNC_TERMIOS],[
2092 AC_REQUIRE([CF_STRUCT_TERMIOS])
2093 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
2094 AC_TRY_LINK([
2095 #include <sys/types.h>
2096 #ifdef HAVE_UNISTD_H
2097 #include <unistd.h>
2098 #endif
2099 #ifdef HAVE_TERMIOS_H
2100 #include <termios.h>
2101 #define TTY struct termios
2102 #else
2103 #ifdef HAVE_TERMIO_H
2104 #include <termio.h>
2105 #define TTY struct termio
2106 #endif
2107 #endif
2108 ],[
2109 TTY foo;
2110 tcgetattr(1, &foo);],
2111 [cf_cv_have_tcgetattr=yes],
2112 [cf_cv_have_tcgetattr=no])])
2113 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
2114 ])dnl
2115 dnl ---------------------------------------------------------------------------
2116 dnl CF_FUNC_VSSCANF version: 6 updated: 2015/04/18 08:56:57
2117 dnl ---------------
2118 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
2119 dnl versions of C.  It is in the GNU C library, and can often be simulated by
2120 dnl other functions.
2121 AC_DEFUN([CF_FUNC_VSSCANF],
2122 [
2123 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
2124 AC_TRY_LINK([
2125 #include <stdarg.h>
2126 #include <stdio.h>],[
2127         va_list ap;
2128         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
2129 AC_TRY_LINK([
2130 #include <stdarg.h>
2131 #include <stdio.h>],[
2132         FILE strbuf;
2133         char *str = "from";
2134
2135         strbuf._flag = _IOREAD;
2136         strbuf._ptr = strbuf._base = (unsigned char *) str;
2137         strbuf._cnt = strlen(str);
2138         strbuf._file = _NFILE;
2139         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
2140 AC_TRY_LINK([
2141 #include <stdarg.h>
2142 #include <stdio.h>],[
2143         FILE strbuf;
2144         char *str = "from";
2145
2146         strbuf._flag = _IOREAD;
2147         strbuf._ptr = strbuf._base = (unsigned char *) str;
2148         strbuf._cnt = strlen(str);
2149         strbuf._file = _NFILE;
2150         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
2151 cf_cv_func_vsscanf=no])])])])
2152
2153 case $cf_cv_func_vsscanf in
2154 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
2155 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
2156 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
2157 esac
2158
2159 ])dnl
2160 dnl ---------------------------------------------------------------------------
2161 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
2162 dnl -----------------
2163 dnl Test for availability of useful gcc __attribute__ directives to quiet
2164 dnl compiler warnings.  Though useful, not all are supported -- and contrary
2165 dnl to documentation, unrecognized directives cause older compilers to barf.
2166 AC_DEFUN([CF_GCC_ATTRIBUTES],
2167 [
2168 if test "$GCC" = yes
2169 then
2170 cat > conftest.i <<EOF
2171 #ifndef GCC_PRINTF
2172 #define GCC_PRINTF 0
2173 #endif
2174 #ifndef GCC_SCANF
2175 #define GCC_SCANF 0
2176 #endif
2177 #ifndef GCC_NORETURN
2178 #define GCC_NORETURN /* nothing */
2179 #endif
2180 #ifndef GCC_UNUSED
2181 #define GCC_UNUSED /* nothing */
2182 #endif
2183 EOF
2184 if test "$GCC" = yes
2185 then
2186         AC_CHECKING([for $CC __attribute__ directives])
2187 cat > conftest.$ac_ext <<EOF
2188 #line __oline__ "${as_me:-configure}"
2189 #include "confdefs.h"
2190 #include "conftest.h"
2191 #include "conftest.i"
2192 #if     GCC_PRINTF
2193 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
2194 #else
2195 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
2196 #endif
2197 #if     GCC_SCANF
2198 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2199 #else
2200 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2201 #endif
2202 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2203 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
2204 extern void foo(void) GCC_NORETURN;
2205 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
2206 EOF
2207         cf_printf_attribute=no
2208         cf_scanf_attribute=no
2209         for cf_attribute in scanf printf unused noreturn
2210         do
2211                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2212                 cf_directive="__attribute__(($cf_attribute))"
2213                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2214
2215                 case $cf_attribute in
2216                 (printf)
2217                         cf_printf_attribute=yes
2218                         cat >conftest.h <<EOF
2219 #define GCC_$cf_ATTRIBUTE 1
2220 EOF
2221                         ;;
2222                 (scanf)
2223                         cf_scanf_attribute=yes
2224                         cat >conftest.h <<EOF
2225 #define GCC_$cf_ATTRIBUTE 1
2226 EOF
2227                         ;;
2228                 (*)
2229                         cat >conftest.h <<EOF
2230 #define GCC_$cf_ATTRIBUTE $cf_directive
2231 EOF
2232                         ;;
2233                 esac
2234
2235                 if AC_TRY_EVAL(ac_compile); then
2236                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
2237                         cat conftest.h >>confdefs.h
2238                         case $cf_attribute in
2239                         (noreturn)
2240                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
2241                                 ;;
2242                         (printf)
2243                                 cf_value='/* nothing */'
2244                                 if test "$cf_printf_attribute" != no ; then
2245                                         cf_value='__attribute__((format(printf,fmt,var)))'
2246                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
2247                                 fi
2248                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
2249                                 ;;
2250                         (scanf)
2251                                 cf_value='/* nothing */'
2252                                 if test "$cf_scanf_attribute" != no ; then
2253                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2254                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2255                                 fi
2256                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2257                                 ;;
2258                         (unused)
2259                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2260                                 ;;
2261                         esac
2262                 fi
2263         done
2264 else
2265         fgrep define conftest.i >>confdefs.h
2266 fi
2267 rm -rf conftest*
2268 fi
2269 ])dnl
2270 dnl ---------------------------------------------------------------------------
2271 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
2272 dnl --------------
2273 dnl Find version of gcc
2274 AC_DEFUN([CF_GCC_VERSION],[
2275 AC_REQUIRE([AC_PROG_CC])
2276 GCC_VERSION=none
2277 if test "$GCC" = yes ; then
2278         AC_MSG_CHECKING(version of $CC)
2279         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2280         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2281         AC_MSG_RESULT($GCC_VERSION)
2282 fi
2283 ])dnl
2284 dnl ---------------------------------------------------------------------------
2285 dnl CF_GCC_WARNINGS version: 32 updated: 2015/04/12 15:39:00
2286 dnl ---------------
2287 dnl Check if the compiler supports useful warning options.  There's a few that
2288 dnl we don't use, simply because they're too noisy:
2289 dnl
2290 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2291 dnl     -Wredundant-decls (system headers make this too noisy)
2292 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2293 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2294 dnl             is enabled for ncurses using "--enable-const".
2295 dnl     -pedantic
2296 dnl
2297 dnl Parameter:
2298 dnl     $1 is an optional list of gcc warning flags that a particular
2299 dnl             application might want to use, e.g., "no-unused" for
2300 dnl             -Wno-unused
2301 dnl Special:
2302 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2303 dnl
2304 AC_DEFUN([CF_GCC_WARNINGS],
2305 [
2306 AC_REQUIRE([CF_GCC_VERSION])
2307 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2308 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2309
2310 cat > conftest.$ac_ext <<EOF
2311 #line __oline__ "${as_me:-configure}"
2312 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2313 EOF
2314
2315 if test "$INTEL_COMPILER" = yes
2316 then
2317 # The "-wdXXX" options suppress warnings:
2318 # remark #1419: external declaration in primary source file
2319 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2320 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2321 # remark #193: zero used for undefined preprocessing identifier
2322 # remark #593: variable "curs_sb_left_arrow" was set but never used
2323 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2324 # remark #869: parameter "tw" was never referenced
2325 # remark #981: operands are evaluated in unspecified order
2326 # warning #279: controlling expression is constant
2327
2328         AC_CHECKING([for $CC warning options])
2329         cf_save_CFLAGS="$CFLAGS"
2330         EXTRA_CFLAGS="-Wall"
2331         for cf_opt in \
2332                 wd1419 \
2333                 wd1683 \
2334                 wd1684 \
2335                 wd193 \
2336                 wd593 \
2337                 wd279 \
2338                 wd810 \
2339                 wd869 \
2340                 wd981
2341         do
2342                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2343                 if AC_TRY_EVAL(ac_compile); then
2344                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2345                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2346                 fi
2347         done
2348         CFLAGS="$cf_save_CFLAGS"
2349
2350 elif test "$GCC" = yes
2351 then
2352         AC_CHECKING([for $CC warning options])
2353         cf_save_CFLAGS="$CFLAGS"
2354         EXTRA_CFLAGS=
2355         cf_warn_CONST=""
2356         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2357         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2358         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2359         for cf_opt in W Wall \
2360                 Wbad-function-cast \
2361                 Wcast-align \
2362                 Wcast-qual \
2363                 Wdeclaration-after-statement \
2364                 Wextra \
2365                 Winline \
2366                 Wmissing-declarations \
2367                 Wmissing-prototypes \
2368                 Wnested-externs \
2369                 Wpointer-arith \
2370                 Wshadow \
2371                 Wstrict-prototypes \
2372                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
2373         do
2374                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2375                 if AC_TRY_EVAL(ac_compile); then
2376                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2377                         case $cf_opt in
2378                         (Wcast-qual)
2379                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
2380                                 ;;
2381                         (Winline)
2382                                 case $GCC_VERSION in
2383                                 ([[34]].*)
2384                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2385                                         continue;;
2386                                 esac
2387                                 ;;
2388                         (Wpointer-arith)
2389                                 case $GCC_VERSION in
2390                                 ([[12]].*)
2391                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2392                                         continue;;
2393                                 esac
2394                                 ;;
2395                         esac
2396                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2397                 fi
2398         done
2399         CFLAGS="$cf_save_CFLAGS"
2400 fi
2401 rm -rf conftest*
2402
2403 AC_SUBST(EXTRA_CFLAGS)
2404 ])dnl
2405 dnl ---------------------------------------------------------------------------
2406 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
2407 dnl ----------------
2408 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2409 dnl unistd.h or (nonstandard) in getopt.h
2410 AC_DEFUN([CF_GETOPT_HEADER],
2411 [
2412 AC_HAVE_HEADERS(unistd.h getopt.h)
2413 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2414 cf_cv_getopt_header=none
2415 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2416 do
2417 AC_TRY_COMPILE([
2418 #include <$cf_header>],
2419 [int x = optind; char *y = optarg],
2420 [cf_cv_getopt_header=$cf_header
2421  break])
2422 done
2423 ])
2424 if test $cf_cv_getopt_header != none ; then
2425         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2426 fi
2427 if test $cf_cv_getopt_header = getopt.h ; then
2428         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2429 fi
2430 ])dnl
2431 dnl ---------------------------------------------------------------------------
2432 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2433 dnl -----------------
2434 AC_DEFUN([CF_GNATPREP_OPT_T],[
2435 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2436 cf_cv_gnatprep_opt_t=no
2437 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2438 ])
2439 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
2440 AC_SUBST(GNATPREP_OPTS)
2441 ])dnl
2442 dnl ---------------------------------------------------------------------------
2443 dnl CF_GNAT_GENERICS version: 3 updated: 2015/04/17 21:13:04
2444 dnl ----------------
2445 AC_DEFUN([CF_GNAT_GENERICS],
2446 [
2447 AC_REQUIRE([CF_GNAT_VERSION])
2448
2449 AC_MSG_CHECKING(if GNAT supports generics)
2450 case $cf_gnat_version in
2451 (3.[[1-9]]*|[[4-9]].*)
2452         cf_gnat_generics=yes
2453         ;;
2454 (*)
2455         cf_gnat_generics=no
2456         ;;
2457 esac
2458 AC_MSG_RESULT($cf_gnat_generics)
2459
2460 if test "$cf_gnat_generics" = yes
2461 then
2462         cf_compile_generics=generics
2463         cf_generic_objects="\${GENOBJS}"
2464 else
2465         cf_compile_generics=
2466         cf_generic_objects=
2467 fi
2468
2469 AC_SUBST(cf_compile_generics)
2470 AC_SUBST(cf_generic_objects)
2471 ])dnl
2472 dnl ---------------------------------------------------------------------------
2473 dnl CF_GNAT_PROJECTS version: 8 updated: 2015/04/17 21:13:04
2474 dnl ----------------
2475 dnl GNAT projects are configured with ".gpr" project files.
2476 dnl GNAT libraries are a further development, using the project feature.
2477 AC_DEFUN([CF_GNAT_PROJECTS],
2478 [
2479 AC_REQUIRE([CF_GNAT_VERSION])
2480 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
2481
2482 cf_gnat_libraries=no
2483 cf_gnat_projects=no
2484
2485 if test "$enable_gnat_projects" != no ; then
2486 AC_MSG_CHECKING(if GNAT supports project files)
2487 case $cf_gnat_version in
2488 (3.[[0-9]]*)
2489         ;;
2490 (*)
2491         case $cf_cv_system_name in
2492         (cygwin*|msys*)
2493                 ;;
2494         (*)
2495                 mkdir conftest.src conftest.bin conftest.lib
2496                 cd conftest.src
2497                 rm -rf conftest* *~conftest*
2498                 cat >>library.gpr <<CF_EOF
2499 project Library is
2500   Kind := External ("LIB_KIND");
2501   for Library_Name use "ConfTest";
2502   for Object_Dir use ".";
2503   for Library_ALI_Dir use External("LIBRARY_DIR");
2504   for Library_Version use External ("SONAME");
2505   for Library_Kind use Kind;
2506   for Library_Dir use External("BUILD_DIR");
2507   Source_Dir := External ("SOURCE_DIR");
2508   for Source_Dirs use (Source_Dir);
2509 end Library;
2510 CF_EOF
2511                 cat >>confpackage.ads <<CF_EOF
2512 package ConfPackage is
2513    procedure conftest;
2514 end ConfPackage;
2515 CF_EOF
2516                 cat >>confpackage.adb <<CF_EOF
2517 with Text_IO;
2518 package body ConfPackage is
2519    procedure conftest is
2520    begin
2521       Text_IO.Put ("Hello World");
2522       Text_IO.New_Line;
2523    end conftest;
2524 end ConfPackage;
2525 CF_EOF
2526                 if ( $cf_ada_make $ADAFLAGS \
2527                                 -Plibrary.gpr \
2528                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2529                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2530                                 -XSOURCE_DIR=`pwd` \
2531                                 -XSONAME=libConfTest.so.1 \
2532                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2533                         cf_gnat_projects=yes
2534                 fi
2535                 cd ..
2536                 if test -f conftest.lib/confpackage.ali
2537                 then
2538                         cf_gnat_libraries=yes
2539                 fi
2540                 rm -rf conftest* *~conftest*
2541                 ;;
2542         esac
2543         ;;
2544 esac
2545 AC_MSG_RESULT($cf_gnat_projects)
2546 fi # enable_gnat_projects
2547
2548 if test $cf_gnat_projects = yes
2549 then
2550         AC_MSG_CHECKING(if GNAT supports libraries)
2551         AC_MSG_RESULT($cf_gnat_libraries)
2552 fi
2553
2554 if test "$cf_gnat_projects" = yes
2555 then
2556         USE_OLD_MAKERULES="#"
2557         USE_GNAT_PROJECTS=""
2558 else
2559         USE_OLD_MAKERULES=""
2560         USE_GNAT_PROJECTS="#"
2561 fi
2562
2563 if test "$cf_gnat_libraries" = yes
2564 then
2565         USE_GNAT_LIBRARIES=""
2566 else
2567         USE_GNAT_LIBRARIES="#"
2568 fi
2569
2570 AC_SUBST(USE_OLD_MAKERULES)
2571 AC_SUBST(USE_GNAT_PROJECTS)
2572 AC_SUBST(USE_GNAT_LIBRARIES)
2573 ])dnl
2574 dnl ---------------------------------------------------------------------------
2575 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2576 dnl --------------
2577 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2578 dnl is noted that gnat may compile a tasking unit even for configurations which
2579 dnl fail at runtime.
2580 AC_DEFUN([CF_GNAT_SIGINT],[
2581 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2582 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2583
2584 package ConfTest is
2585
2586    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2587    pragma Unreserve_All_Interrupts;
2588    pragma Warnings (On);
2589
2590    protected Process is
2591       procedure Stop;
2592       function Continue return Boolean;
2593       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2594    private
2595       Done : Boolean := False;
2596    end Process;
2597
2598 end ConfTest;],
2599 [package body ConfTest is
2600    protected body Process is
2601       procedure Stop is
2602       begin
2603          Done := True;
2604       end Stop;
2605       function Continue return Boolean is
2606       begin
2607          return not Done;
2608       end Continue;
2609    end Process;
2610 end ConfTest;],
2611         [cf_cv_gnat_sigint=yes],
2612         [cf_cv_gnat_sigint=no])])
2613
2614 if test $cf_cv_gnat_sigint = yes ; then
2615         USE_GNAT_SIGINT=""
2616 else
2617         USE_GNAT_SIGINT="#"
2618 fi
2619 AC_SUBST(USE_GNAT_SIGINT)
2620 ])dnl
2621 dnl ---------------------------------------------------------------------------
2622 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2623 dnl ----------------
2624 dnl Verify that a test program compiles/links with GNAT.
2625 dnl $cf_ada_make is set to the program that compiles/links
2626 dnl $ADAFLAGS may be set to the GNAT flags.
2627 dnl
2628 dnl $1 is the text of the spec
2629 dnl $2 is the text of the body
2630 dnl $3 is the shell command to execute if successful
2631 dnl $4 is the shell command to execute if not successful
2632 AC_DEFUN([CF_GNAT_TRY_LINK],
2633 [
2634 rm -rf conftest* *~conftest*
2635 cat >>conftest.ads <<CF_EOF
2636 $1
2637 CF_EOF
2638 cat >>conftest.adb <<CF_EOF
2639 $2
2640 CF_EOF
2641 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2642 ifelse($3,,      :,[      $3])
2643 ifelse($4,,,[else
2644    $4])
2645 fi
2646 rm -rf conftest* *~conftest*
2647 ])dnl
2648 dnl ---------------------------------------------------------------------------
2649 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2650 dnl ---------------
2651 dnl Verify that a test program compiles and runs with GNAT
2652 dnl $cf_ada_make is set to the program that compiles/links
2653 dnl $ADAFLAGS may be set to the GNAT flags.
2654 dnl
2655 dnl $1 is the text of the spec
2656 dnl $2 is the text of the body
2657 dnl $3 is the shell command to execute if successful
2658 dnl $4 is the shell command to execute if not successful
2659 AC_DEFUN([CF_GNAT_TRY_RUN],
2660 [
2661 rm -rf conftest* *~conftest*
2662 cat >>conftest.ads <<CF_EOF
2663 $1
2664 CF_EOF
2665 cat >>conftest.adb <<CF_EOF
2666 $2
2667 CF_EOF
2668 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2669    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2670 ifelse($3,,      :,[      $3])
2671 ifelse($4,,,[   else
2672       $4])
2673    fi
2674 ifelse($4,,,[else
2675    $4])
2676 fi
2677 rm -rf conftest* *~conftest*
2678 ])dnl
2679 dnl ---------------------------------------------------------------------------
2680 dnl CF_GNAT_VERSION version: 20 updated: 2015/04/18 08:56:57
2681 dnl ---------------
2682 dnl Verify version of GNAT.
2683 AC_DEFUN([CF_GNAT_VERSION],
2684 [
2685 AC_MSG_CHECKING(for gnat version)
2686 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2687         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2688         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2689 AC_MSG_RESULT($cf_gnat_version)
2690
2691 case $cf_gnat_version in
2692 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
2693         cf_cv_prog_gnat_correct=yes
2694         ;;
2695 (*)
2696         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2697         cf_cv_prog_gnat_correct=no
2698         ;;
2699 esac
2700 ])
2701 dnl ---------------------------------------------------------------------------
2702 dnl CF_GNU_SOURCE version: 7 updated: 2016/08/05 05:15:37
2703 dnl -------------
2704 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2705 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2706 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2707 dnl since it is interwoven with GNU extensions.
2708 dnl
2709 dnl Well, yes we could work around it...
2710 AC_DEFUN([CF_GNU_SOURCE],
2711 [
2712 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2713 AC_TRY_COMPILE([#include <sys/types.h>],[
2714 #ifndef _XOPEN_SOURCE
2715 make an error
2716 #endif],
2717         [cf_cv_gnu_source=no],
2718         [cf_save="$CPPFLAGS"
2719          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2720          AC_TRY_COMPILE([#include <sys/types.h>],[
2721 #ifdef _XOPEN_SOURCE
2722 make an error
2723 #endif],
2724         [cf_cv_gnu_source=no],
2725         [cf_cv_gnu_source=yes])
2726         CPPFLAGS="$cf_save"
2727         ])
2728 ])
2729
2730 if test "$cf_cv_gnu_source" = yes
2731 then
2732 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
2733 CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2734         AC_TRY_COMPILE([#include <sys/types.h>],[
2735 #ifdef _DEFAULT_SOURCE
2736 make an error
2737 #endif],
2738                 [cf_cv_default_source=no],
2739                 [cf_cv_default_source=yes])
2740         ])
2741 test "$cf_cv_default_source" = yes && CPPFLAGS="$CPPFLAGS -D_DEFAULT_SOURCE"
2742 fi
2743 ])dnl
2744 dnl ---------------------------------------------------------------------------
2745 dnl CF_GPP_LIBRARY version: 12 updated: 2015/04/17 21:13:04
2746 dnl --------------
2747 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2748 dnl problem :-).  If we have the compiler but no library, we'll be able to
2749 dnl configure, but won't be able to build the c++ demo program.
2750 AC_DEFUN([CF_GPP_LIBRARY],
2751 [
2752 cf_cxx_library=unknown
2753 case $cf_cv_system_name in
2754 (os2*)
2755         cf_gpp_libname=gpp
2756         ;;
2757 (*)
2758         cf_gpp_libname=g++
2759         ;;
2760 esac
2761 if test "$GXX" = yes; then
2762         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2763         cf_save="$LIBS"
2764         CF_ADD_LIB($cf_gpp_libname)
2765         AC_TRY_LINK([
2766 #include <$cf_gpp_libname/builtin.h>
2767         ],
2768         [two_arg_error_handler_t foo2 = lib_error_handler],
2769         [cf_cxx_library=yes
2770          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2771          if test "$cf_gpp_libname" = cpp ; then
2772             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
2773          else
2774             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
2775          fi],
2776         [AC_TRY_LINK([
2777 #include <builtin.h>
2778         ],
2779         [two_arg_error_handler_t foo2 = lib_error_handler],
2780         [cf_cxx_library=yes
2781          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2782          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
2783         [cf_cxx_library=no])])
2784         LIBS="$cf_save"
2785         AC_MSG_RESULT($cf_cxx_library)
2786 fi
2787 ])dnl
2788 dnl ---------------------------------------------------------------------------
2789 dnl CF_GXX_VERSION version: 8 updated: 2017/02/11 14:48:57
2790 dnl --------------
2791 dnl Check for version of g++
2792 AC_DEFUN([CF_GXX_VERSION],[
2793 AC_REQUIRE([AC_PROG_CPP])
2794 GXX_VERSION=none
2795 if test "$GXX" = yes; then
2796         AC_MSG_CHECKING(version of ${CXX:-g++})
2797         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2798         if test -z "$GXX_VERSION"
2799         then
2800                 GXX_VERSION=unknown
2801                 GXX=no
2802         fi
2803         AC_MSG_RESULT($GXX_VERSION)
2804 fi
2805 ])dnl
2806 dnl ---------------------------------------------------------------------------
2807 dnl CF_GXX_WARNINGS version: 9 updated: 2015/04/17 21:13:04
2808 dnl ---------------
2809 dnl Check if the compiler supports useful warning options.
2810 dnl
2811 dnl Most of gcc's options apply to g++, except:
2812 dnl     -Wbad-function-cast
2813 dnl     -Wmissing-declarations
2814 dnl     -Wnested-externs
2815 dnl
2816 dnl Omit a few (for now):
2817 dnl     -Winline
2818 dnl
2819 dnl Parameter:
2820 dnl     $1 is an optional list of g++ warning flags that a particular
2821 dnl             application might want to use, e.g., "no-unused" for
2822 dnl             -Wno-unused
2823 dnl Special:
2824 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2825 dnl
2826 AC_DEFUN([CF_GXX_WARNINGS],
2827 [
2828
2829 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2830 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
2831
2832 AC_REQUIRE([CF_GXX_VERSION])
2833
2834 AC_LANG_SAVE
2835 AC_LANG_CPLUSPLUS
2836
2837 cat > conftest.$ac_ext <<EOF
2838 #line __oline__ "configure"
2839 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2840 EOF
2841
2842 if test "$INTEL_CPLUSPLUS" = yes
2843 then
2844 # The "-wdXXX" options suppress warnings:
2845 # remark #1419: external declaration in primary source file
2846 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2847 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2848 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2849 # remark #193: zero used for undefined preprocessing identifier
2850 # remark #593: variable "curs_sb_left_arrow" was set but never used
2851 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2852 # remark #869: parameter "tw" was never referenced
2853 # remark #981: operands are evaluated in unspecified order
2854 # warning #269: invalid format string conversion
2855
2856         AC_CHECKING([for $CC warning options])
2857         cf_save_CXXFLAGS="$CXXFLAGS"
2858         EXTRA_CXXFLAGS="-Wall"
2859         for cf_opt in \
2860                 wd1419 \
2861                 wd1682 \
2862                 wd1683 \
2863                 wd1684 \
2864                 wd193 \
2865                 wd279 \
2866                 wd593 \
2867                 wd810 \
2868                 wd869 \
2869                 wd981
2870         do
2871                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2872                 if AC_TRY_EVAL(ac_compile); then
2873                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2874                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2875                 fi
2876         done
2877         CXXFLAGS="$cf_save_CXXFLAGS"
2878
2879 elif test "$GXX" = yes
2880 then
2881         AC_CHECKING([for $CXX warning options])
2882         cf_save_CXXFLAGS="$CXXFLAGS"
2883         EXTRA_CXXFLAGS="-W -Wall"
2884         cf_gxx_extra_warnings=""
2885         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2886         case "$GCC_VERSION" in
2887         ([[1-2]].*)
2888                 ;;
2889         (*)
2890                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2891                 ;;
2892         esac
2893         for cf_opt in \
2894                 Wabi \
2895                 fabi-version=0 \
2896                 Wextra \
2897                 Wignored-qualifiers \
2898                 Wlogical-op \
2899                 Woverloaded-virtual \
2900                 Wsign-promo \
2901                 Wsynth \
2902                 Wold-style-cast \
2903                 Wcast-align \
2904                 Wcast-qual \
2905                 Wpointer-arith \
2906                 Wshadow \
2907                 Wundef $cf_gxx_extra_warnings $1
2908         do
2909                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2910                 if AC_TRY_EVAL(ac_compile); then
2911                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2912                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2913                 else
2914                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2915                 fi
2916         done
2917         CXXFLAGS="$cf_save_CXXFLAGS"
2918 fi
2919
2920 rm -rf conftest*
2921 AC_LANG_RESTORE
2922 AC_SUBST(EXTRA_CXXFLAGS)
2923 ])dnl
2924 dnl ---------------------------------------------------------------------------
2925 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
2926 dnl ------------
2927 dnl Look for an instance of the Berkeley hashed database.
2928 dnl
2929 dnl $1 = optional parameter, to specify install-prefix for the database.
2930 AC_DEFUN([CF_HASHED_DB],
2931 [
2932 ifelse([$1],,,[
2933 case $1 in
2934 (yes|*able*)
2935         ;;
2936 (*)
2937         if test -d "$1" ; then
2938                 CF_ADD_INCDIR($1/include)
2939                 CF_ADD_LIBDIR($1/lib)
2940         else
2941                 case "$1" in
2942                 (./*|../*|/*)
2943                         AC_MSG_WARN(no such directory $1)
2944                         ;;
2945                 (*)
2946                         CF_FIND_SUB_INCDIR($1)
2947                         CF_FIND_SUB_LIBDIR($1)
2948                         ;;
2949                 esac
2950         fi
2951 esac
2952 ])
2953 AC_CHECK_HEADER(db.h,[
2954 CF_HASHED_DB_VERSION
2955 if test "$cf_cv_hashed_db_version" = unknown ; then
2956         AC_MSG_ERROR(Cannot determine version of db)
2957 else
2958         CF_HASHED_DB_LIBS
2959         if test "$cf_cv_hashed_db_libs" = unknown ; then
2960                 AC_MSG_ERROR(Cannot determine library for db)
2961         elif test "$cf_cv_hashed_db_libs" != default ; then
2962                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2963         fi
2964 fi
2965 ],[
2966         AC_MSG_ERROR(Cannot find db.h)
2967 ])
2968 ])dnl
2969 dnl ---------------------------------------------------------------------------
2970 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2971 dnl -----------------
2972 dnl Given that we have the header and version for hashed database, find the
2973 dnl library information.
2974 AC_DEFUN([CF_HASHED_DB_LIBS],
2975 [
2976 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2977 cf_cv_hashed_db_libs=unknown
2978 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2979 do
2980         cf_save_libs="$LIBS"
2981         if test -n "$cf_db_libs"; then
2982                 CF_ADD_LIB($cf_db_libs)
2983         fi
2984         CF_MSG_LOG(checking for library "$cf_db_libs")
2985         AC_TRY_LINK([
2986 $ac_includes_default
2987 #include <db.h>
2988 ],[
2989         char *path = "/tmp/foo";
2990 #ifdef DB_VERSION_MAJOR
2991 #if DB_VERSION_MAJOR >= 4
2992         DB *result = 0;
2993         db_create(&result, NULL, 0);
2994         result->open(result,
2995                 NULL,
2996                 path,
2997                 path,
2998                 DB_HASH,
2999                 DB_CREATE,
3000                 0644);
3001 #elif DB_VERSION_MAJOR >= 3
3002         DB *result = 0;
3003         db_create(&result, NULL, 0);
3004         result->open(result,
3005                 path,
3006                 path,
3007                 DB_HASH,
3008                 DB_CREATE,
3009                 0644);
3010 #elif DB_VERSION_MAJOR >= 2
3011         DB *result = 0;
3012         db_open(path,
3013                 DB_HASH,
3014                 DB_CREATE,
3015                 0644,
3016                 (DB_ENV *) 0,
3017                 (DB_INFO *) 0,
3018                 &result);
3019 #endif /* DB_VERSION_MAJOR */
3020 #else
3021         DB *result = dbopen(path,
3022                      2,
3023                      0644,
3024                      DB_HASH,
3025                      0);
3026 #endif
3027         ${cf_cv_main_return:-return}(result != 0)
3028 ],[
3029         if test -n "$cf_db_libs" ; then
3030                 cf_cv_hashed_db_libs=$cf_db_libs
3031         else
3032                 cf_cv_hashed_db_libs=default
3033         fi
3034         LIBS="$cf_save_libs"
3035         break
3036 ])
3037         LIBS="$cf_save_libs"
3038 done
3039 ])
3040 ])dnl
3041 dnl ---------------------------------------------------------------------------
3042 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
3043 dnl --------------------
3044 dnl Given that we have the header file for hashed database, find the version
3045 dnl information.
3046 AC_DEFUN([CF_HASHED_DB_VERSION],
3047 [
3048 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
3049 cf_cv_hashed_db_version=unknown
3050
3051 for cf_db_version in 1 2 3 4 5 6
3052 do
3053         CF_MSG_LOG(checking for db version $cf_db_version)
3054         AC_TRY_COMPILE([
3055 $ac_includes_default
3056 #include <db.h>
3057
3058 #ifdef DB_VERSION_MAJOR
3059         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
3060 #if $cf_db_version == DB_VERSION_MAJOR
3061         /* ok */
3062 #else
3063         make an error
3064 #endif
3065 #else
3066 #if $cf_db_version == 1
3067         /* ok: assuming this is DB 1.8.5 */
3068 #else
3069         make an error
3070 #endif
3071 #endif
3072 ],[DBT *foo = 0],[
3073         cf_cv_hashed_db_version=$cf_db_version
3074         break
3075         ])
3076 done
3077 ])
3078 ])dnl
3079 dnl ---------------------------------------------------------------------------
3080 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
3081 dnl --------------
3082 dnl Construct a search-list of directories for a nonstandard header-file
3083 dnl
3084 dnl Parameters
3085 dnl     $1 = the variable to return as result
3086 dnl     $2 = the package name
3087 AC_DEFUN([CF_HEADER_PATH],
3088 [
3089 $1=
3090
3091 # collect the current set of include-directories from compiler flags
3092 cf_header_path_list=""
3093 if test -n "${CFLAGS}${CPPFLAGS}" ; then
3094         for cf_header_path in $CPPFLAGS $CFLAGS
3095         do
3096                 case $cf_header_path in
3097                 (-I*)
3098                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
3099                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
3100                         cf_header_path_list="$cf_header_path_list [$]$1"
3101                         ;;
3102                 esac
3103         done
3104 fi
3105
3106 # add the variations for the package we are looking for
3107 CF_SUBDIR_PATH($1,$2,include)
3108
3109 test "$includedir" != NONE && \
3110 test "$includedir" != "/usr/include" && \
3111 test -d "$includedir" && {
3112         test -d $includedir &&    $1="[$]$1 $includedir"
3113         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
3114 }
3115
3116 test "$oldincludedir" != NONE && \
3117 test "$oldincludedir" != "/usr/include" && \
3118 test -d "$oldincludedir" && {
3119         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
3120         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
3121 }
3122
3123 $1="[$]$1 $cf_header_path_list"
3124 ])dnl
3125 dnl ---------------------------------------------------------------------------
3126 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
3127 dnl ---------------
3128 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
3129 AC_DEFUN([CF_HELP_MESSAGE],
3130 [AC_DIVERT_HELP([$1])dnl
3131 ])dnl
3132 dnl ---------------------------------------------------------------------------
3133 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
3134 dnl ---------------
3135 dnl Construct the list of include-options according to whether we're building
3136 dnl in the source directory or using '--srcdir=DIR' option.
3137 AC_DEFUN([CF_INCLUDE_DIRS],
3138 [
3139 if test "$srcdir" != "."; then
3140         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
3141 fi
3142 CPPFLAGS="-I../include $CPPFLAGS"
3143 if test "$srcdir" != "."; then
3144         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
3145 fi
3146 CPPFLAGS="-I. $CPPFLAGS"
3147 AC_SUBST(CPPFLAGS)
3148 ])dnl
3149 dnl ---------------------------------------------------------------------------
3150 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
3151 dnl -----------------
3152 dnl Check if the given compiler is really the Intel compiler for Linux.  It
3153 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
3154 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
3155 dnl
3156 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
3157 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
3158 dnl the wrappers for gcc and g++ warnings.
3159 dnl
3160 dnl $1 = GCC (default) or GXX
3161 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
3162 dnl $3 = CFLAGS (default) or CXXFLAGS
3163 AC_DEFUN([CF_INTEL_COMPILER],[
3164 AC_REQUIRE([AC_CANONICAL_HOST])
3165 ifelse([$2],,INTEL_COMPILER,[$2])=no
3166
3167 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
3168         case $host_os in
3169         (linux*|gnu*)
3170                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
3171                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
3172                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
3173                 AC_TRY_COMPILE([],[
3174 #ifdef __INTEL_COMPILER
3175 #else
3176 make an error
3177 #endif
3178 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
3179 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
3180 ],[])
3181                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
3182                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
3183                 ;;
3184         esac
3185 fi
3186 ])dnl
3187 dnl ---------------------------------------------------------------------------
3188 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
3189 dnl ----------
3190 dnl Check if we have either a function or macro for 'isascii()'.
3191 AC_DEFUN([CF_ISASCII],
3192 [
3193 AC_MSG_CHECKING(for isascii)
3194 AC_CACHE_VAL(cf_cv_have_isascii,[
3195         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
3196         [cf_cv_have_isascii=yes],
3197         [cf_cv_have_isascii=no])
3198 ])dnl
3199 AC_MSG_RESULT($cf_cv_have_isascii)
3200 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
3201 ])dnl
3202 dnl ---------------------------------------------------------------------------
3203 dnl CF_LARGEFILE version: 10 updated: 2017/01/21 11:06:25
3204 dnl ------------
3205 dnl Add checks for large file support.
3206 AC_DEFUN([CF_LARGEFILE],[
3207 ifdef([AC_FUNC_FSEEKO],[
3208         AC_SYS_LARGEFILE
3209         if test "$enable_largefile" != no ; then
3210         AC_FUNC_FSEEKO
3211
3212         # Normally we would collect these definitions in the config.h,
3213         # but (like _XOPEN_SOURCE), some environments rely on having these
3214         # defined before any of the system headers are included.  Another
3215         # case comes up with C++, e.g., on AIX the compiler compiles the
3216         # header files by themselves before looking at the body files it is
3217         # told to compile.  For ncurses, those header files do not include
3218         # the config.h
3219         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
3220         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
3221         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
3222
3223         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
3224                 AC_TRY_COMPILE([
3225 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
3226 #include <sys/types.h>
3227 #include <dirent.h>
3228                 ],[
3229                 /* if transitional largefile support is setup, this is true */
3230                 extern struct dirent64 * readdir(DIR *);
3231                 struct dirent64 *x = readdir((DIR *)0);
3232                 struct dirent *y = readdir((DIR *)0);
3233                 int z = x - y;
3234                 ],
3235                 [cf_cv_struct_dirent64=yes],
3236                 [cf_cv_struct_dirent64=no])
3237         ])
3238         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
3239         fi
3240 ])
3241 ])
3242 dnl ---------------------------------------------------------------------------
3243 dnl CF_LDFLAGS_STATIC version: 12 updated: 2015/04/18 08:56:57
3244 dnl -----------------
3245 dnl Check for compiler/linker flags used to temporarily force usage of static
3246 dnl libraries.  This depends on the compiler and platform.  Use this to help
3247 dnl ensure that the linker picks up a given library based on its position in
3248 dnl the list of linker options and libraries.
3249 AC_DEFUN([CF_LDFLAGS_STATIC],[
3250
3251 if test "$GCC" = yes ; then
3252         case $cf_cv_system_name in
3253         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
3254                 LDFLAGS_STATIC=
3255                 LDFLAGS_SHARED=
3256                 ;;
3257         (*)     # normally, except when broken
3258                 LDFLAGS_STATIC=-static
3259                 LDFLAGS_SHARED=-dynamic
3260                 ;;
3261         esac
3262 else
3263         case $cf_cv_system_name in
3264         (aix[[4-7]]*)   # from ld manpage
3265                 LDFLAGS_STATIC=-bstatic
3266                 LDFLAGS_SHARED=-bdynamic
3267                 ;;
3268         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
3269                 # We could also use just "archive" and "shared".
3270                 LDFLAGS_STATIC=-Wl,-a,archive_shared
3271                 LDFLAGS_SHARED=-Wl,-a,shared_archive
3272                 ;;
3273         (irix*)         # from ld manpage IRIX64
3274                 LDFLAGS_STATIC=-Bstatic
3275                 LDFLAGS_SHARED=-Bdynamic
3276                 ;;
3277         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
3278                 # alternative "-oldstyle_liblookup" (not in cc manpage)
3279                 LDFLAGS_STATIC=-noso
3280                 LDFLAGS_SHARED=-so_archive
3281                 ;;
3282         (solaris2*)
3283                 LDFLAGS_STATIC=-Bstatic
3284                 LDFLAGS_SHARED=-Bdynamic
3285                 ;;
3286         esac
3287 fi
3288
3289 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
3290 then
3291         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
3292
3293         rm -f libconftest.a
3294         cat >conftest.$ac_ext <<EOF
3295 #line __oline__ "configure"
3296 #include <stdio.h>
3297 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
3298 EOF
3299         if AC_TRY_EVAL(ac_compile) ; then
3300                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
3301                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
3302         fi
3303         rm -f conftest.*
3304
3305         cf_save_LIBS="$LIBS"
3306
3307         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
3308         AC_TRY_LINK([
3309 #line __oline__ "configure"
3310 #include <stdio.h>
3311 int cf_ldflags_static(FILE *fp);
3312 ],[
3313         return cf_ldflags_static(stdin);
3314 ],[
3315         # some linkers simply ignore the -dynamic
3316         case x`file conftest$ac_exeext 2>/dev/null` in
3317         (*static*)
3318                 cf_ldflags_static=no
3319                 ;;
3320         (*)
3321                 cf_ldflags_static=yes
3322                 ;;
3323         esac
3324 ],[cf_ldflags_static=no])
3325
3326         rm -f libconftest.*
3327         LIBS="$cf_save_LIBS"
3328
3329         AC_MSG_RESULT($cf_ldflags_static)
3330
3331         if test $cf_ldflags_static != yes
3332         then
3333                 LDFLAGS_STATIC=
3334                 LDFLAGS_SHARED=
3335         fi
3336 else
3337         LDFLAGS_STATIC=
3338         LDFLAGS_SHARED=
3339 fi
3340
3341 AC_SUBST(LDFLAGS_STATIC)
3342 AC_SUBST(LDFLAGS_SHARED)
3343 ])
3344 dnl ---------------------------------------------------------------------------
3345 dnl CF_LD_RPATH_OPT version: 7 updated: 2016/02/20 18:01:19
3346 dnl ---------------
3347 dnl For the given system and compiler, find the compiler flags to pass to the
3348 dnl loader to use the "rpath" feature.
3349 AC_DEFUN([CF_LD_RPATH_OPT],
3350 [
3351 AC_REQUIRE([CF_CHECK_CACHE])
3352
3353 LD_RPATH_OPT=
3354 AC_MSG_CHECKING(for an rpath option)
3355 case $cf_cv_system_name in
3356 (irix*)
3357         if test "$GCC" = yes; then
3358                 LD_RPATH_OPT="-Wl,-rpath,"
3359         else
3360                 LD_RPATH_OPT="-rpath "
3361         fi
3362         ;;
3363 (linux*|gnu*|k*bsd*-gnu|freebsd*)
3364         LD_RPATH_OPT="-Wl,-rpath,"
3365         ;;
3366 (openbsd[[2-9]].*|mirbsd*)
3367         LD_RPATH_OPT="-Wl,-rpath,"
3368         ;;
3369 (dragonfly*)
3370         LD_RPATH_OPT="-rpath "
3371         ;;
3372 (netbsd*)
3373         LD_RPATH_OPT="-Wl,-rpath,"
3374         ;;
3375 (osf*|mls+*)
3376         LD_RPATH_OPT="-rpath "
3377         ;;
3378 (solaris2*)
3379         LD_RPATH_OPT="-R"
3380         ;;
3381 (*)
3382         ;;
3383 esac
3384 AC_MSG_RESULT($LD_RPATH_OPT)
3385
3386 case "x$LD_RPATH_OPT" in
3387 (x-R*)
3388         AC_MSG_CHECKING(if we need a space after rpath option)
3389         cf_save_LIBS="$LIBS"
3390         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3391         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3392         LIBS="$cf_save_LIBS"
3393         AC_MSG_RESULT($cf_rpath_space)
3394         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3395         ;;
3396 esac
3397 ])dnl
3398 dnl ---------------------------------------------------------------------------
3399 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
3400 dnl ---------------
3401 dnl Construct a search-list of directories for a nonstandard library-file
3402 dnl
3403 dnl Parameters
3404 dnl     $1 = the variable to return as result
3405 dnl     $2 = the package name
3406 AC_DEFUN([CF_LIBRARY_PATH],
3407 [
3408 $1=
3409 cf_library_path_list=""
3410 if test -n "${LDFLAGS}${LIBS}" ; then
3411         for cf_library_path in $LDFLAGS $LIBS
3412         do
3413                 case $cf_library_path in
3414                 (-L*)
3415                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3416                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3417                         cf_library_path_list="$cf_library_path_list [$]$1"
3418                         ;;
3419                 esac
3420         done
3421 fi
3422
3423 CF_SUBDIR_PATH($1,$2,lib)
3424
3425 $1="$cf_library_path_list [$]$1"
3426 ])dnl
3427 dnl ---------------------------------------------------------------------------
3428 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
3429 dnl ------------------
3430 AC_DEFUN([CF_LIBTOOL_VERSION],[
3431 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
3432 then
3433         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
3434 else
3435         cf_cv_libtool_version=
3436 fi
3437 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
3438 ])dnl
3439 dnl ---------------------------------------------------------------------------
3440 dnl CF_LIB_PREFIX version: 12 updated: 2015/10/17 19:03:33
3441 dnl -------------
3442 dnl Compute the library-prefix for the given host system
3443 dnl $1 = variable to set
3444 define([CF_LIB_PREFIX],
3445 [
3446         case $cf_cv_system_name in
3447         (OS/2*|os2*)
3448                 if test "$DFT_LWR_MODEL" = libtool; then
3449                         LIB_PREFIX='lib'
3450                 else
3451                         LIB_PREFIX=''
3452                 fi
3453                 ;;
3454         (*)     LIB_PREFIX='lib'
3455                 ;;
3456         esac
3457 ifelse($1,,,[$1=$LIB_PREFIX])
3458         AC_SUBST(LIB_PREFIX)
3459 ])dnl
3460 dnl ---------------------------------------------------------------------------
3461 dnl CF_LIB_RULES version: 87 updated: 2017/07/26 17:08:35
3462 dnl ------------
3463 dnl Append definitions and rules for the given models to the subdirectory
3464 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3465 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
3466 dnl the corresponding makefile to list the models that we'll generate.
3467 dnl
3468 dnl For shared libraries, make a list of symbolic links to construct when
3469 dnl generating each library.  The convention used for Linux is the simplest
3470 dnl one:
3471 dnl     lib<name>.so    ->
3472 dnl     lib<name>.so.<major>    ->
3473 dnl     lib<name>.so.<maj>.<minor>
3474 dnl
3475 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
3476 AC_DEFUN([CF_LIB_RULES],
3477 [
3478 cf_prefix=$LIB_PREFIX
3479 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3480
3481 case $cf_cv_shlib_version in
3482 (cygdll|msysdll|mingw)
3483         TINFO_NAME=$TINFO_ARG_SUFFIX
3484         TINFO_SUFFIX=.dll
3485         ;;
3486 esac
3487
3488 if test -n "$TINFO_SUFFIX" ; then
3489         case $TINFO_SUFFIX in
3490         (tw*)
3491                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
3492                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw'$EXTRA_SUFFIX'//'`
3493                 ;;
3494         (t*)
3495                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
3496                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t'$EXTRA_SUFFIX'//'`
3497                 ;;
3498         (w*)
3499                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
3500                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w'$EXTRA_SUFFIX'//'`
3501                 ;;
3502         esac
3503 fi
3504
3505 for cf_dir in $SRC_SUBDIRS
3506 do
3507         if test ! -d $srcdir/$cf_dir ; then
3508                 continue
3509         elif test -f $srcdir/$cf_dir/modules; then
3510
3511                 SHARED_LIB=
3512                 Libs_To_Make=
3513                 cf_awk_program=
3514                 if test -n "${cf_cv_abi_version}" && test "x${cf_cv_abi_version}" != "x5"
3515                 then
3516                         cf_awk_program="$cf_awk_program\
3517 /deprecated in ABI${cf_cv_abi_version}/ { next; }\
3518 { sub(\"NCURSES([[WT]]+)?\", \"&${cf_cv_abi_version}\"); }\
3519 "
3520                 fi
3521
3522                 if test "x$WILDCARD_SYMS" = xno
3523                 then
3524                         cf_awk_program="$cf_awk_program\
3525 /[[     ]]_\\*;/ { skip=1; next; }\
3526 "
3527                 fi
3528
3529                 if test "x$cf_awk_program" != "x"
3530                 then
3531                         cat >>$cf_dir/Makefile <<CF_EOF
3532
3533 # Generated by CF_LIB_RULES
3534 resulting.map: $UNALTERED_SYMS
3535         $AWK 'BEGIN { skip = 1; last=""; } \
3536 $cf_awk_program \
3537 { if ( last != "" && ( skip == 0 || \[$]\[$]0 !~ /}/ ) ) { print last; }\
3538  skip = 0; last = \[$]\[$]0; } \
3539 END { print last; }' < $UNALTERED_SYMS >\[$]@
3540
3541 distclean::
3542         rm -f resulting.map
3543 CF_EOF
3544                 fi
3545
3546                 for cf_item in $cf_LIST_MODELS
3547                 do
3548                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3549                         cf_libname=$cf_dir
3550                         test "$cf_dir" = c++ && cf_libname=ncurses++
3551                         if test $cf_item = shared ; then
3552                                 if test -n "${LIB_SUFFIX}"
3553                                 then
3554                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3555                                 else
3556                                         cf_shared_suffix="$cf_suffix"
3557                                 fi
3558                                 if test "$cf_cv_do_symlinks" = yes ; then
3559                                         cf_version_name=
3560
3561                                         case "$cf_cv_shlib_version" in
3562                                         (rel)
3563                                                 cf_version_name=REL_VERSION
3564                                                 ;;
3565                                         (abi)
3566                                                 cf_version_name=ABI_VERSION
3567                                                 ;;
3568                                         esac
3569
3570                                         if test -n "$cf_version_name"
3571                                         then
3572                                                 case "$cf_cv_system_name" in
3573                                                 (darwin*)
3574                                                         # "w", etc?
3575                                                         cf_suffix="${USE_LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
3576                                                         ;;
3577                                                 (*)
3578                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
3579                                                         ;;
3580                                                 esac
3581                                         fi
3582                                         if test -n "${USE_LIB_SUFFIX}"
3583                                         then
3584                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3585                                         else
3586                                                 cf_shared_suffix="$cf_suffix"
3587                                         fi
3588                                 fi
3589                                 # cygwin needs import library, and has unique naming convention
3590                                 # use autodetected ${cf_prefix} for import lib and static lib, but
3591                                 # use 'cyg' prefix for shared lib.
3592                                 case $cf_cv_shlib_version in
3593                                 (cygdll)
3594                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3595                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
3596                                         ;;
3597                                 (msysdll)
3598                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3599                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
3600                                         ;;
3601                                 (mingw)
3602                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3603                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
3604                                         ;;
3605                                 (*)
3606                                         cf_add_lib=
3607                                         ;;
3608                                 esac
3609                                 if test -n "$cf_add_lib"
3610                                 then
3611                                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3612                                         continue
3613                                 fi
3614                         fi
3615                         cf_add_lib="../lib/${cf_prefix}${cf_libname}${cf_suffix}"
3616                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3617                 done
3618
3619                 if test $cf_dir = ncurses ; then
3620                         cf_subsets="$LIB_SUBSETS"
3621                         cf_r_parts="$cf_subsets"
3622                         cf_liblist="$Libs_To_Make"
3623
3624                         while test -n "$cf_r_parts"
3625                         do
3626                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3627                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3628                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3629                                         cf_add_lib=
3630                                         case $cf_l_parts in
3631                                         (*termlib*)
3632                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3633                                                 ;;
3634                                         (*ticlib*)
3635                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3636                                                 ;;
3637                                         (*)
3638                                                 break
3639                                                 ;;
3640                                         esac
3641                                         if test -n "$cf_add_lib"; then
3642                                                 Libs_To_Make="$cf_add_lib $Libs_To_Make"
3643                                         fi
3644                                 else
3645                                         break
3646                                 fi
3647                         done
3648                 else
3649                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3650                 fi
3651
3652                 if test $cf_dir = c++; then
3653                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
3654                                 cf_list=
3655                                 for cf_item in $Libs_To_Make
3656                                 do
3657                                         case $cf_item in
3658                                         (*.a)
3659                                                 ;;
3660                                         (*)
3661                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
3662                                                 ;;
3663                                         esac
3664                                         for cf_test in $cf_list
3665                                         do
3666                                                 if test "$cf_test" = "$cf_item"
3667                                                 then
3668                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
3669                                                         cf_item=
3670                                                         break
3671                                                 fi
3672                                         done
3673                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
3674                                 done
3675                                 Libs_To_Make="$cf_list"
3676                         fi
3677                 fi
3678
3679                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
3680                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3681                         $cf_dir/Makefile >$cf_dir/Makefile.out
3682                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3683
3684                 $AWK -f $srcdir/mk-0th.awk \
3685                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
3686                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3687
3688                 for cf_subset in $cf_subsets
3689                 do
3690                         cf_subdirs=
3691                         for cf_item in $cf_LIST_MODELS
3692                         do
3693
3694                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3695                         CF_UPPER(cf_ITEM,$cf_item)
3696
3697                         CXX_MODEL=$cf_ITEM
3698                         if test "$CXX_MODEL" = SHARED; then
3699                                 case $cf_cv_shlib_version in
3700                                 (cygdll|msysdll|mingw)
3701                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
3702                                         with_shared_cxx=yes
3703                                         ;;
3704                                 (*)
3705                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
3706                                         ;;
3707                                 esac
3708                         fi
3709
3710                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3711                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3712
3713                         # Test for case where we build libtinfo with a different name.
3714                         cf_libname=$cf_dir
3715                         if test $cf_dir = ncurses ; then
3716                                 case $cf_subset in
3717                                 (*base*)
3718                                         cf_libname=${cf_libname}$USE_LIB_SUFFIX
3719                                         ;;
3720                                 (*termlib*)
3721                                         cf_libname=$TINFO_LIB_SUFFIX
3722                                         ;;
3723                                 (ticlib*)
3724                                         cf_libname=$TICS_LIB_SUFFIX
3725                                         ;;
3726                                 esac
3727                         elif test $cf_dir = c++ ; then
3728                                 cf_libname=ncurses++$USE_LIB_SUFFIX
3729                         else
3730                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
3731                         fi
3732                         if test -n "${USE_ARG_SUFFIX}" ; then
3733                                 # undo $USE_LIB_SUFFIX add-on in CF_LIB_SUFFIX
3734                                 cf_suffix=`echo $cf_suffix |sed -e "s%^${USE_LIB_SUFFIX}%%"`
3735                         fi
3736
3737                         # These dependencies really are for development, not
3738                         # builds, but they are useful in porting, too.
3739                         cf_depend="../include/ncurses_cfg.h"
3740                         if test "$srcdir" = "."; then
3741                                 cf_reldir="."
3742                         else
3743                                 cf_reldir="\${srcdir}"
3744                         fi
3745
3746                         if test -f $srcdir/$cf_dir/$cf_dir.priv.h; then
3747                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
3748                         elif test -f $srcdir/$cf_dir/curses.priv.h; then
3749                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
3750                         fi
3751
3752                         cf_dir_suffix=
3753                         old_cf_suffix="$cf_suffix"
3754                         if test "$cf_cv_shlib_version_infix" = yes ; then
3755                         if test -n "$USE_LIB_SUFFIX" ; then
3756                                 case $USE_LIB_SUFFIX in
3757                                 (tw*)
3758                                         cf_libname=`echo $cf_libname | sed 's/tw'$EXTRA_SUFFIX'$//'`
3759                                         cf_suffix=`echo $cf_suffix | sed 's/^tw'$EXTRA_SUFFIX'//'`
3760                                         cf_dir_suffix=tw$EXTRA_SUFFIX
3761                                         ;;
3762                                 (t*)
3763                                         cf_libname=`echo $cf_libname | sed 's/t'$EXTRA_SUFFIX'$//'`
3764                                         cf_suffix=`echo $cf_suffix | sed 's/^t'$EXTRA_SUFFIX'//'`
3765                                         cf_dir_suffix=t$EXTRA_SUFFIX
3766                                         ;;
3767                                 (w*)
3768                                         cf_libname=`echo $cf_libname | sed 's/w'$EXTRA_SUFFIX'$//'`
3769                                         cf_suffix=`echo $cf_suffix | sed 's/^w'$EXTRA_SUFFIX'//'`
3770                                         cf_dir_suffix=w$EXTRA_SUFFIX
3771                                         ;;
3772                                 (*)
3773                                         cf_libname=`echo $cf_libname | sed 's/'$EXTRA_SUFFIX'$//'`
3774                                         cf_suffix=`echo $cf_suffix | sed 's/^'$EXTRA_SUFFIX'//'`
3775                                         cf_dir_suffix=$EXTRA_SUFFIX
3776                                         ;;
3777                                 esac
3778                         fi
3779                         fi
3780
3781                         $AWK -f $srcdir/mk-1st.awk \
3782                                 name=${cf_libname}${cf_dir_suffix} \
3783                                 traces=$LIB_TRACING \
3784                                 MODEL=$cf_ITEM \
3785                                 CXX_MODEL=$CXX_MODEL \
3786                                 model=$cf_subdir \
3787                                 prefix=$cf_prefix \
3788                                 suffix=$cf_suffix \
3789                                 subset=$cf_subset \
3790                                 driver=$cf_cv_term_driver \
3791                                 SymLink="$LN_S" \
3792                                 TermlibRoot=$TINFO_NAME \
3793                                 TermlibSuffix=$TINFO_SUFFIX \
3794                                 ShlibVer=$cf_cv_shlib_version \
3795                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
3796                                 ReLink=${cf_cv_do_relink:-no} \
3797                                 DoLinks=$cf_cv_do_symlinks \
3798                                 rmSoLocs=$cf_cv_rm_so_locs \
3799                                 ldconfig="$LDCONFIG" \
3800                                 overwrite=$WITH_OVERWRITE \
3801                                 depend="$cf_depend" \
3802                                 host="$host" \
3803                                 libtool_version="$LIBTOOL_VERSION" \
3804                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3805
3806                         cf_suffix="$old_cf_suffix"
3807
3808                         for cf_subdir2 in $cf_subdirs lib
3809                         do
3810                                 test $cf_subdir = $cf_subdir2 && break
3811                         done
3812                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
3813                         $AWK -f $srcdir/mk-2nd.awk \
3814                                 name=$cf_dir \
3815                                 traces=$LIB_TRACING \
3816                                 MODEL=$cf_ITEM \
3817                                 model=$cf_subdir \
3818                                 subset=$cf_subset \
3819                                 srcdir=$srcdir \
3820                                 echo=$WITH_ECHO \
3821                                 crenames=$cf_cv_prog_CC_c_o \
3822                                 cxxrenames=$cf_cv_prog_CXX_c_o \
3823                                 $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3824                         cf_subdirs="$cf_subdirs $cf_subdir"
3825                         done
3826                 done
3827         fi
3828
3829         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >>Makefile
3830 done
3831
3832 for cf_dir in $SRC_SUBDIRS
3833 do
3834         if test ! -d $srcdir/$cf_dir ; then
3835                 continue
3836         fi
3837
3838         if test -f $cf_dir/Makefile ; then
3839                 case "$cf_dir" in
3840                 (Ada95)
3841                         echo 'libs \' >> Makefile
3842                         echo 'install.libs \' >> Makefile
3843                         echo 'uninstall.libs ::' >> Makefile
3844                         echo '  cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@' >> Makefile
3845                         ;;
3846                 esac
3847         fi
3848
3849         if test -f $srcdir/$cf_dir/modules; then
3850                 echo >> Makefile
3851                 if test -f $srcdir/$cf_dir/headers; then
3852 cat >> Makefile <<CF_EOF
3853 install.includes \\
3854 uninstall.includes \\
3855 CF_EOF
3856                 fi
3857 if test "$cf_dir" != "c++" ; then
3858 echo 'lint \' >> Makefile
3859 fi
3860 cat >> Makefile <<CF_EOF
3861 libs \\
3862 lintlib \\
3863 install.libs \\
3864 uninstall.libs \\
3865 install.$cf_dir \\
3866 uninstall.$cf_dir ::
3867         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3868 CF_EOF
3869         elif test -f $srcdir/$cf_dir/headers; then
3870 cat >> Makefile <<CF_EOF
3871
3872 libs \\
3873 install.libs \\
3874 uninstall.libs \\
3875 install.includes \\
3876 uninstall.includes ::
3877         cd $cf_dir && \${MAKE} \${TOP_MFLAGS} \[$]@
3878 CF_EOF
3879 fi
3880 done
3881
3882 if test "x$cf_with_db_install" = xyes; then
3883 cat >> Makefile <<CF_EOF
3884
3885 install.libs uninstall.libs \\
3886 install.data uninstall.data ::
3887 $MAKE_TERMINFO  cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3888 CF_EOF
3889 else
3890 cat >> Makefile <<CF_EOF
3891
3892 install.libs uninstall.libs ::
3893         cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@
3894 CF_EOF
3895 fi
3896
3897 if test "x$cf_with_manpages" = xyes; then
3898 cat >> Makefile <<CF_EOF
3899
3900 install.man \\
3901 uninstall.man ::
3902         cd man && \${MAKE} \${TOP_MFLAGS} \[$]@
3903 CF_EOF
3904 fi
3905
3906 cat >> Makefile <<CF_EOF
3907
3908 distclean ::
3909         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
3910         rm -f headers.sh headers.sed mk_shared_lib.sh
3911         rm -f edit_man.* man_alias.*
3912         rm -rf \${DIRS_TO_MAKE}
3913 CF_EOF
3914
3915 # Special case: tack's manpage lives in its own directory.
3916 if test "x$cf_with_manpages" = xyes; then
3917 if test "x$cf_with_tack" = "xyes"; then
3918 cat >> Makefile <<CF_EOF
3919
3920 install.man \\
3921 uninstall.man ::
3922         cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@
3923 CF_EOF
3924 fi
3925 fi
3926
3927 dnl If we're installing into a subdirectory of /usr/include, etc., we should
3928 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
3929 dnl anything, and will make it more standardized.  It's awkward to decide this
3930 dnl at configuration because of quoting, so we'll simply make all headers
3931 dnl installed via a script that can do the right thing.
3932
3933 rm -f headers.sed headers.sh
3934
3935 dnl ( generating this script makes the makefiles a little tidier :-)
3936 echo creating headers.sh
3937 cat >headers.sh <<CF_EOF
3938 #! $SHELL
3939 # This shell script is generated by the 'configure' script.  It is invoked in a
3940 # subdirectory of the build tree.  It generates a sed-script in the parent
3941 # directory that is used to adjust includes for header files that reside in a
3942 # subdirectory of /usr/include, etc.
3943 PRG=""
3944 while test \[$]# != 3
3945 do
3946 PRG="\$PRG \[$]1"; shift
3947 done
3948 DST=\[$]1
3949 REF=\[$]2
3950 SRC=\[$]3
3951 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
3952 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
3953 echo installing \$SRC in \$DST
3954 CF_EOF
3955
3956 if test $WITH_CURSES_H = yes; then
3957         cat >>headers.sh <<CF_EOF
3958 case \$DST in
3959 (/*/include/*)
3960         END=\`basename \$DST\`
3961         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3962         do
3963                 NAME=\`basename \$i\`
3964                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3965         done
3966         ;;
3967 (*)
3968         echo "" >> \$TMPSED
3969         ;;
3970 esac
3971 CF_EOF
3972
3973 else
3974         cat >>headers.sh <<CF_EOF
3975 case \$DST in
3976 (/*/include/*)
3977         END=\`basename \$DST\`
3978         for i in \`cat \$REF/../*/headers |fgrep -v "#"\`
3979         do
3980                 NAME=\`basename \$i\`
3981                 if test "\$NAME" = "curses.h"
3982                 then
3983                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3984                         NAME=ncurses.h
3985                 fi
3986                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
3987         done
3988         ;;
3989 (*)
3990         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
3991         ;;
3992 esac
3993 CF_EOF
3994 fi
3995 cat >>headers.sh <<CF_EOF
3996 rm -f \$TMPSRC
3997 sed -f \$TMPSED \$SRC > \$TMPSRC
3998 NAME=\`basename \$SRC\`
3999 CF_EOF
4000 if test $WITH_CURSES_H != yes; then
4001         cat >>headers.sh <<CF_EOF
4002 test "\$NAME" = "curses.h" && NAME=ncurses.h
4003 CF_EOF
4004 fi
4005 cat >>headers.sh <<CF_EOF
4006 # Just in case someone gzip'd manpages, remove the conflicting copy.
4007 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
4008
4009 eval \$PRG \$TMPSRC \$DST/\$NAME
4010 rm -f \$TMPSRC \$TMPSED
4011 CF_EOF
4012
4013 chmod 0755 headers.sh
4014
4015 for cf_dir in $SRC_SUBDIRS
4016 do
4017         if test ! -d $srcdir/$cf_dir ; then
4018                 continue
4019         fi
4020
4021         if test -f $srcdir/$cf_dir/headers; then
4022                 $AWK -f $srcdir/mk-hdr.awk \
4023                         subset="$LIB_SUBSETS" \
4024                         compat="$WITH_CURSES_H" \
4025                         $srcdir/$cf_dir/headers >>$cf_dir/Makefile
4026         fi
4027
4028         if test -f $srcdir/$cf_dir/modules; then
4029                 if test "$cf_dir" != "c++" ; then
4030                         cat >>$cf_dir/Makefile <<"CF_EOF"
4031 depend : ${AUTO_SRC}
4032         makedepend -- ${CPPFLAGS} -- ${C_SRC}
4033
4034 # DO NOT DELETE THIS LINE -- make depend depends on it.
4035 CF_EOF
4036                 fi
4037         fi
4038 done
4039 AC_SUBST(Libs_To_Make)
4040 ])dnl
4041 dnl ---------------------------------------------------------------------------
4042 dnl CF_LIB_SONAME version: 6 updated: 2017/01/21 11:06:25
4043 dnl -------------
4044 dnl Find the and soname for the given shared library.  Set the cache variable
4045 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
4046 dnl variable to "unknown".
4047 dnl
4048 dnl $1 = headers
4049 dnl $2 = code
4050 dnl $3 = library name
4051 AC_DEFUN([CF_LIB_SONAME],
4052 [
4053 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
4054
4055 cf_cv_$3_soname=unknown
4056 if test "$cross_compiling" != yes ; then
4057 cat >conftest.$ac_ext <<CF_EOF
4058 $1
4059 int main(void)
4060 {
4061 $2
4062         ${cf_cv_main_return:-return}(0);
4063 }
4064 CF_EOF
4065 cf_save_LIBS="$LIBS"
4066         CF_ADD_LIB($3)
4067         if AC_TRY_EVAL(ac_compile) ; then
4068                 if AC_TRY_EVAL(ac_link) ; then
4069                         cf_cv_$3_soname=`ldd conftest$ac_exeext 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | fgrep lib$3.`
4070                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
4071                 fi
4072         fi
4073 rm -rf conftest*
4074 LIBS="$cf_save_LIBS"
4075 fi
4076 ])
4077 ])
4078 dnl ---------------------------------------------------------------------------
4079 dnl CF_LIB_SUFFIX version: 25 updated: 2015/04/17 21:13:04
4080 dnl -------------
4081 dnl Compute the library file-suffix from the given model name
4082 dnl $1 = model name
4083 dnl $2 = variable to set (the nominal library suffix)
4084 dnl $3 = dependency variable to set (actual filename)
4085 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4086 AC_DEFUN([CF_LIB_SUFFIX],
4087 [
4088         case X$1 in
4089         (Xlibtool)
4090                 $2='.la'
4091                 $3=[$]$2
4092                 ;;
4093         (Xdebug)
4094                 $2='_g.a'
4095                 $3=[$]$2
4096                 ;;
4097         (Xprofile)
4098                 $2='_p.a'
4099                 $3=[$]$2
4100                 ;;
4101         (Xshared)
4102                 case $cf_cv_system_name in
4103                 (aix[[5-7]]*)
4104                         $2='.so'
4105                         $3=[$]$2
4106                         ;;
4107                 (cygwin*|msys*|mingw*)
4108                         $2='.dll'
4109                         $3='.dll.a'
4110                         ;;
4111                 (darwin*)
4112                         $2='.dylib'
4113                         $3=[$]$2
4114                         ;;
4115                 (hpux*)
4116                         case $target in
4117                         (ia64*)
4118                                 $2='.so'
4119                                 $3=[$]$2
4120                                 ;;
4121                         (*)
4122                                 $2='.sl'
4123                                 $3=[$]$2
4124                                 ;;
4125                         esac
4126                         ;;
4127                 (*)
4128                         $2='.so'
4129                         $3=[$]$2
4130                         ;;
4131                 esac
4132                 ;;
4133         (*)
4134                 $2='.a'
4135                 $3=[$]$2
4136                 ;;
4137         esac
4138         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
4139         then
4140                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
4141                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
4142         fi
4143 ])dnl
4144 dnl ---------------------------------------------------------------------------
4145 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
4146 dnl -----------
4147 dnl Compute the string to append to -library from the given model name
4148 dnl $1 = model name
4149 dnl $2 = variable to set
4150 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4151 AC_DEFUN([CF_LIB_TYPE],
4152 [
4153         case $1 in
4154         (libtool) $2=''   ;;
4155         (normal)  $2=''   ;;
4156         (debug)   $2='_g' ;;
4157         (profile) $2='_p' ;;
4158         (shared)  $2=''   ;;
4159         esac
4160         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
4161 ])dnl
4162 dnl ---------------------------------------------------------------------------
4163 dnl CF_LINK_DATAONLY version: 12 updated: 2017/07/23 17:46:07
4164 dnl ----------------
4165 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
4166 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
4167 dnl have to provide wrappers for global tables to ensure they're linked
4168 dnl properly.
4169 AC_DEFUN([CF_LINK_DATAONLY],
4170 [
4171 AC_MSG_CHECKING([if data-only library module links])
4172 AC_CACHE_VAL(cf_cv_link_dataonly,[
4173         rm -f conftest.a
4174         cat >conftest.$ac_ext <<EOF
4175 #line __oline__ "configure"
4176 int     testdata[[3]] = { 123, 456, 789 };
4177 EOF
4178         if AC_TRY_EVAL(ac_compile) ; then
4179                 mv conftest.o data.o && \
4180                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
4181         fi
4182         rm -f conftest.$ac_ext data.o
4183         cat >conftest.$ac_ext <<EOF
4184 #line __oline__ "configure"
4185 int     testfunc(void)
4186 {
4187 #if defined(NeXT)
4188         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
4189 #else
4190         extern int testdata[[3]];
4191         return testdata[[0]] == 123
4192            &&  testdata[[1]] == 456
4193            &&  testdata[[2]] == 789;
4194 #endif
4195 }
4196 EOF
4197         if AC_TRY_EVAL(ac_compile); then
4198                 mv conftest.o func.o && \
4199                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
4200         fi
4201         rm -f conftest.$ac_ext func.o
4202         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
4203         cf_saveLIBS="$LIBS"
4204         LIBS="conftest.a $LIBS"
4205         AC_TRY_RUN([
4206         int main(void)
4207         {
4208                 extern int testfunc();
4209                 ${cf_cv_main_return:-return} (!testfunc());
4210         }
4211         ],
4212         [cf_cv_link_dataonly=yes],
4213         [cf_cv_link_dataonly=no],
4214         [cf_cv_link_dataonly=unknown])
4215         LIBS="$cf_saveLIBS"
4216         ])
4217 AC_MSG_RESULT($cf_cv_link_dataonly)
4218
4219 if test "$cf_cv_link_dataonly" = no ; then
4220         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
4221         BROKEN_LINKER=1
4222 fi
4223
4224 ])dnl
4225 dnl ---------------------------------------------------------------------------
4226 dnl CF_LINK_FUNCS version: 9 updated: 2017/01/21 11:11:02
4227 dnl -------------
4228 dnl Most Unix systems have both link and symlink, a few don't have symlink.
4229 dnl A few non-Unix systems implement symlink, but not link.
4230 dnl A few non-systems implement neither (or have nonfunctional versions).
4231 AC_DEFUN([CF_LINK_FUNCS],
4232 [
4233 AC_CHECK_HEADERS( \
4234 unistd.h \
4235 )
4236 AC_CHECK_FUNCS( \
4237         remove \
4238         unlink )
4239
4240 if test "$cross_compiling" = yes ; then
4241         AC_CHECK_FUNCS( \
4242                 link \
4243                 symlink )
4244 else
4245         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
4246                 cf_cv_link_funcs=
4247                 for cf_func in link symlink ; do
4248                         AC_TRY_RUN([
4249 #include <sys/types.h>
4250 #include <sys/stat.h>
4251 #ifdef HAVE_UNISTD_H
4252 #include <unistd.h>
4253 #endif
4254 int main(void)
4255 {
4256         int fail = 0;
4257         char *src = "config.log";
4258         char *dst = "conftest.chk";
4259         struct stat src_sb;
4260         struct stat dst_sb;
4261
4262         stat(src, &src_sb);
4263         fail = ($cf_func("config.log", "conftest.chk") < 0)
4264             || (stat(dst, &dst_sb) < 0)
4265             || (dst_sb.st_mtime != src_sb.st_mtime);
4266 #ifdef HAVE_UNLINK
4267         unlink(dst);
4268 #else
4269         remove(dst);
4270 #endif
4271         ${cf_cv_main_return:-return} (fail);
4272 }
4273                         ],[
4274                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
4275                         eval 'ac_cv_func_'$cf_func'=yes'],[
4276                         eval 'ac_cv_func_'$cf_func'=no'],[
4277                         eval 'ac_cv_func_'$cf_func'=error'])
4278                 done
4279                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
4280         ])
4281         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
4282         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
4283 fi
4284 ])dnl
4285 dnl ---------------------------------------------------------------------------
4286 dnl CF_MAKEFLAGS version: 17 updated: 2015/08/05 20:44:28
4287 dnl ------------
4288 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
4289 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
4290 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
4291 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
4292 AC_DEFUN([CF_MAKEFLAGS],
4293 [
4294 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
4295         cf_cv_makeflags=''
4296         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
4297         do
4298                 cat >cf_makeflags.tmp <<CF_EOF
4299 SHELL = $SHELL
4300 all :
4301         @ echo '.$cf_option'
4302 CF_EOF
4303                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | fgrep -v "ing directory" | sed -e 's,[[   ]]*$,,'`
4304                 case "$cf_result" in
4305                 (.*k|.*kw)
4306                         cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`
4307                         case "$cf_result" in
4308                         (.*CC=*)        cf_cv_makeflags=
4309                                 ;;
4310                         (*)     cf_cv_makeflags=$cf_option
4311                                 ;;
4312                         esac
4313                         break
4314                         ;;
4315                 (.-)    ;;
4316                 (*)     echo "given option \"$cf_option\", no match \"$cf_result\""
4317                         ;;
4318                 esac
4319         done
4320         rm -f cf_makeflags.tmp
4321 ])
4322
4323 AC_SUBST(cf_cv_makeflags)
4324 ])dnl
4325 dnl ---------------------------------------------------------------------------
4326 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
4327 dnl ------------
4328 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
4329 dnl a monocase filesystem.
4330 AC_DEFUN([CF_MAKE_TAGS],[
4331 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
4332
4333 AC_CHECK_PROGS(CTAGS, exctags ctags)
4334 AC_CHECK_PROGS(ETAGS, exetags etags)
4335
4336 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
4337
4338 if test "$cf_cv_mixedcase" = yes ; then
4339         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
4340 else
4341         MAKE_UPPER_TAGS=no
4342 fi
4343
4344 if test "$MAKE_UPPER_TAGS" = yes ; then
4345         MAKE_UPPER_TAGS=
4346 else
4347         MAKE_UPPER_TAGS="#"
4348 fi
4349
4350 if test "$MAKE_LOWER_TAGS" = yes ; then
4351         MAKE_LOWER_TAGS=
4352 else
4353         MAKE_LOWER_TAGS="#"
4354 fi
4355
4356 AC_SUBST(CTAGS)
4357 AC_SUBST(ETAGS)
4358
4359 AC_SUBST(MAKE_UPPER_TAGS)
4360 AC_SUBST(MAKE_LOWER_TAGS)
4361 ])dnl
4362 dnl ---------------------------------------------------------------------------
4363 dnl CF_MANPAGE_FORMAT version: 11 updated: 2015/04/18 08:56:57
4364 dnl -----------------
4365 dnl Option to allow user to override automatic configuration of manpage format.
4366 dnl There are several special cases:
4367 dnl
4368 dnl     gzip - man checks for, can display gzip'd files
4369 dnl     compress - man checks for, can display compressed files
4370 dnl     BSDI - files in the cat-directories are suffixed ".0"
4371 dnl     formatted - installer should format (put files in cat-directory)
4372 dnl     catonly - installer should only format, e.g., for a turnkey system.
4373 dnl
4374 dnl There are other configurations which this macro does not test, e.g., HPUX's
4375 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
4376 dnl convention would not match our use).
4377 AC_DEFUN([CF_MANPAGE_FORMAT],
4378 [
4379 AC_REQUIRE([CF_PATHSEP])
4380 AC_MSG_CHECKING(format of man-pages)
4381
4382 AC_ARG_WITH(manpage-format,
4383         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
4384                           optionally formatted/catonly, e.g., gzip,formatted],
4385         [MANPAGE_FORMAT=$withval],
4386         [MANPAGE_FORMAT=unknown])
4387
4388 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
4389 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
4390
4391 cf_unknown=
4392
4393 case $MANPAGE_FORMAT in
4394 (unknown)
4395         if test -z "$MANPATH" ; then
4396                 MANPATH="/usr/man:/usr/share/man"
4397         fi
4398
4399         # look for the 'date' man-page (it's most likely to be installed!)
4400         MANPAGE_FORMAT=
4401         cf_preform=no
4402         cf_catonly=yes
4403         cf_example=date
4404
4405         IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
4406         for cf_dir in $MANPATH; do
4407                 test -z "$cf_dir" && cf_dir=/usr/man
4408                 for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
4409                 do
4410                         cf_test=`echo $cf_name | sed -e 's/*//'`
4411                         if test "x$cf_test" = "x$cf_name" ; then
4412
4413                                 case "$cf_name" in
4414                                 (*.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
4415                                 (*.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
4416                                 (*.0)  MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
4417                                 (*)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
4418                                 esac
4419
4420                                 case "$cf_name" in
4421                                 ($cf_dir/man*)
4422                                         cf_catonly=no
4423                                         ;;
4424                                 ($cf_dir/cat*)
4425                                         cf_preform=yes
4426                                         ;;
4427                                 esac
4428                                 break
4429                         fi
4430
4431                         # if we found a match in either man* or cat*, stop looking
4432                         if test -n "$MANPAGE_FORMAT" ; then
4433                                 cf_found=no
4434                                 test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
4435                                 test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
4436                                 case "$cf_name" in
4437                                 ($cf_dir/cat*)
4438                                         cf_found=yes
4439                                         ;;
4440                                 esac
4441                                 test $cf_found=yes && break
4442                         fi
4443                 done
4444                 # only check the first directory in $MANPATH where we find manpages
4445                 if test -n "$MANPAGE_FORMAT" ; then
4446                         break
4447                 fi
4448         done
4449         # if we did not find the example, just assume it is normal
4450         test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
4451         IFS="$ac_save_ifs"
4452         ;;
4453 (*)
4454         for cf_option in $MANPAGE_FORMAT; do
4455         case $cf_option in
4456         (gzip|compress|BSDI|normal|formatted|catonly)
4457                 ;;
4458         (*)
4459                 cf_unknown="$cf_unknown $cf_option"
4460                 ;;
4461         esac
4462         done
4463         ;;
4464 esac
4465
4466 AC_MSG_RESULT($MANPAGE_FORMAT)
4467 if test -n "$cf_unknown" ; then
4468         AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
4469 fi
4470 ])dnl
4471 dnl ---------------------------------------------------------------------------
4472 dnl CF_MANPAGE_RENAMES version: 10 updated: 2015/08/05 20:44:28
4473 dnl ------------------
4474 dnl The Debian people have their own naming convention for manpages.  This
4475 dnl option lets us override the name of the file containing renaming, or
4476 dnl disable it altogether.
4477 AC_DEFUN([CF_MANPAGE_RENAMES],
4478 [
4479 AC_MSG_CHECKING(for manpage renaming)
4480
4481 AC_ARG_WITH(manpage-renames,
4482         [  --with-manpage-renames  specify manpage-renaming],
4483         [MANPAGE_RENAMES=$withval],
4484         [MANPAGE_RENAMES=yes])
4485
4486 case ".$MANPAGE_RENAMES" in
4487 (.no)
4488         ;;
4489 (.|.yes)
4490         # Debian 'man' program?
4491         if test -f /etc/debian_version ; then
4492                 MANPAGE_RENAMES=`cd $srcdir && pwd`/man/man_db.renames
4493         else
4494                 MANPAGE_RENAMES=no
4495         fi
4496         ;;
4497 esac
4498
4499 if test "$MANPAGE_RENAMES" != no ; then
4500         if test -f $srcdir/man/$MANPAGE_RENAMES ; then
4501                 MANPAGE_RENAMES=`cd $srcdir/man && pwd`/$MANPAGE_RENAMES
4502         elif test ! -f $MANPAGE_RENAMES ; then
4503                 AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
4504         fi
4505
4506         test ! -d man && mkdir man
4507
4508         # Construct a sed-script to perform renaming within man-pages
4509         if test -n "$MANPAGE_RENAMES" ; then
4510                 test ! -d man && mkdir man
4511                 $SHELL $srcdir/man/make_sed.sh $MANPAGE_RENAMES >./edit_man.sed
4512         fi
4513 fi
4514
4515 AC_MSG_RESULT($MANPAGE_RENAMES)
4516 AC_SUBST(MANPAGE_RENAMES)
4517 ])dnl
4518 dnl ---------------------------------------------------------------------------
4519 dnl CF_MANPAGE_SYMLINKS version: 6 updated: 2015/04/17 21:13:04
4520 dnl -------------------
4521 dnl Some people expect each tool to make all aliases for manpages in the
4522 dnl man-directory.  This accommodates the older, less-capable implementations
4523 dnl of 'man', and is optional.
4524 AC_DEFUN([CF_MANPAGE_SYMLINKS],
4525 [
4526 AC_MSG_CHECKING(if manpage aliases will be installed)
4527
4528 AC_ARG_WITH(manpage-aliases,
4529         [  --with-manpage-aliases  specify manpage-aliases using .so],
4530         [MANPAGE_ALIASES=$withval],
4531         [MANPAGE_ALIASES=yes])
4532
4533 AC_MSG_RESULT($MANPAGE_ALIASES)
4534
4535 case "x$LN_S" in
4536 (xln*)
4537         cf_use_symlinks=yes
4538         ;;
4539 (*)
4540         cf_use_symlinks=no
4541         ;;
4542 esac
4543
4544 MANPAGE_SYMLINKS=no
4545 if test "$MANPAGE_ALIASES" = yes ; then
4546 AC_MSG_CHECKING(if manpage symlinks should be used)
4547
4548 AC_ARG_WITH(manpage-symlinks,
4549         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
4550         [MANPAGE_SYMLINKS=$withval],
4551         [MANPAGE_SYMLINKS=$cf_use_symlinks])
4552
4553 if test "$$cf_use_symlinks" = no; then
4554 if test "$MANPAGE_SYMLINKS" = yes ; then
4555         AC_MSG_WARN(cannot make symlinks, will use .so files)
4556         MANPAGE_SYMLINKS=no
4557 fi
4558 fi
4559
4560 AC_MSG_RESULT($MANPAGE_SYMLINKS)
4561 fi
4562
4563 ])dnl
4564 dnl ---------------------------------------------------------------------------
4565 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
4566 dnl --------------
4567 dnl This option causes manpages to be run through tbl(1) to generate tables
4568 dnl correctly.
4569 AC_DEFUN([CF_MANPAGE_TBL],
4570 [
4571 AC_MSG_CHECKING(for manpage tbl)
4572
4573 AC_ARG_WITH(manpage-tbl,
4574         [  --with-manpage-tbl      specify manpage processing with tbl],
4575         [MANPAGE_TBL=$withval],
4576         [MANPAGE_TBL=no])
4577
4578 AC_MSG_RESULT($MANPAGE_TBL)
4579 ])dnl
4580 dnl ---------------------------------------------------------------------------
4581 dnl CF_MAN_PAGES version: 47 updated: 2017/08/12 07:58:51
4582 dnl ------------
4583 dnl Try to determine if the man-pages on the system are compressed, and if
4584 dnl so, what format is used.  Use this information to construct a script that
4585 dnl will install man-pages.
4586 AC_DEFUN([CF_MAN_PAGES],
4587 [
4588 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
4589 CF_MANPAGE_FORMAT
4590 CF_MANPAGE_RENAMES
4591 CF_MANPAGE_SYMLINKS
4592 CF_MANPAGE_TBL
4593
4594 if test "$prefix" = "NONE" ; then
4595         cf_prefix="$ac_default_prefix"
4596 else
4597         cf_prefix="$prefix"
4598 fi
4599
4600 case "$MANPAGE_FORMAT" in
4601 (*catonly*)
4602         cf_format=yes
4603         cf_inboth=no
4604         ;;
4605 (*formatted*)
4606         cf_format=yes
4607         cf_inboth=yes
4608         ;;
4609 (*)
4610         cf_format=no
4611         cf_inboth=no
4612         ;;
4613 esac
4614
4615 test ! -d man && mkdir man
4616
4617 cf_so_strip=
4618 cf_compress=
4619 case "$MANPAGE_FORMAT" in
4620 (*compress*)
4621         cf_so_strip="Z"
4622         cf_compress=compress
4623         ;;
4624 (*gzip*)
4625         cf_so_strip="gz"
4626         cf_compress=gzip
4627         ;;
4628 esac
4629
4630 cf_edit_man=./edit_man.sh
4631 cf_man_alias=`pwd`/man_alias.sed
4632
4633 cat >$cf_edit_man <<CF_EOF
4634 #! $SHELL
4635 # this script is generated by the configure-script CF_MAN_PAGES macro.
4636
4637 prefix="$cf_prefix"
4638 datarootdir="$datarootdir"
4639 datadir="$datadir"
4640
4641 NCURSES_MAJOR="$NCURSES_MAJOR"
4642 NCURSES_MINOR="$NCURSES_MINOR"
4643 NCURSES_PATCH="$NCURSES_PATCH"
4644
4645 NCURSES_OSPEED="$NCURSES_OSPEED"
4646 TERMINFO="$TERMINFO"
4647
4648 INSTALL="$INSTALL"
4649 INSTALL_DATA="$INSTALL_DATA"
4650
4651 transform="$program_transform_name"
4652
4653 TMP=\${TMPDIR:=/tmp}/man\$\$
4654 trap "rm -f \$TMP" 0 1 2 3 15
4655
4656 form=\[$]1
4657 shift || exit 1
4658
4659 verb=\[$]1
4660 shift || exit 1
4661
4662 mandir=\[$]1
4663 shift || exit 1
4664
4665 srcdir=\[$]1
4666 top_srcdir=\[$]srcdir/..
4667 shift || exit 1
4668
4669 if test "\$form" = normal ; then
4670         if test "$cf_format" = yes ; then
4671         if test "$cf_inboth" = no ; then
4672                 $SHELL \[$]0 format \$verb \$mandir \$srcdir \[$]*
4673                 exit $?
4674         fi
4675         fi
4676         cf_subdir=\$mandir/man
4677         cf_tables=$MANPAGE_TBL
4678 else
4679         cf_subdir=\$mandir/cat
4680         cf_tables=yes
4681 fi
4682
4683 # process the list of source-files
4684 for i in \[$]* ; do
4685 case \$i in
4686 (*.orig|*.rej) ;;
4687 (*.[[0-9]]*)
4688         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
4689         if test \$verb = installing ; then
4690         if test ! -d \$cf_subdir\${section} ; then
4691                 mkdir -p \$cf_subdir\$section
4692         fi
4693         fi
4694
4695         # replace variables in man page
4696         if test ! -f $cf_man_alias ; then
4697 cat >>$cf_man_alias <<-CF_EOF2
4698                 s,@DATADIR@,\$datadir,g
4699                 s,@TERMINFO@,\${TERMINFO:="no default value"},g
4700                 s,@TERMINFO_DIRS@,\${TERMINFO_DIRS:="no default value"},g
4701                 s,@NCURSES_MAJOR@,\${NCURSES_MAJOR:="no default value"},g
4702                 s,@NCURSES_MINOR@,\${NCURSES_MINOR:="no default value"},g
4703                 s,@NCURSES_PATCH@,\${NCURSES_PATCH:="no default value"},g
4704                 s,@NCURSES_OSPEED@,\${NCURSES_OSPEED:="no default value"},g
4705 CF_EOF
4706         ifelse($1,,,[
4707         for cf_name in $1
4708         do
4709                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
4710                 cf_name=`echo $cf_name|sed "$program_transform_name"`
4711 cat >>$cf_edit_man <<-CF_EOF
4712                 s,@$cf_NAME@,$cf_name,g
4713 CF_EOF
4714         done
4715         ])
4716 cat >>$cf_edit_man <<CF_EOF
4717 CF_EOF2
4718                 echo "...made $cf_man_alias"
4719         fi
4720
4721         aliases=
4722         cf_source=\`basename \$i\`
4723         inalias=\$cf_source
4724         test ! -f \$inalias && inalias="\$srcdir/\$inalias"
4725         if test ! -f \$inalias ; then
4726                 echo .. skipped \$cf_source
4727                 continue
4728         fi
4729 CF_EOF
4730
4731 if test "$MANPAGE_ALIASES" != no ; then
4732 cat >>$cf_edit_man <<CF_EOF
4733         nCurses=ignore.3x
4734         test $with_curses_h = yes && nCurses=ncurses.3x
4735         aliases=\`sed -f \$top_srcdir/man/manlinks.sed \$inalias |sed -f $cf_man_alias | sort -u; test \$inalias = \$nCurses && echo curses\`
4736 CF_EOF
4737 fi
4738
4739 if test "$MANPAGE_RENAMES" = no ; then
4740 cat >>$cf_edit_man <<CF_EOF
4741         # perform program transformations for section 1 man pages
4742         if test \$section = 1 ; then
4743                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
4744         else
4745                 cf_target=\$cf_subdir\${section}/\$cf_source
4746         fi
4747 CF_EOF
4748 else
4749 cat >>$cf_edit_man <<CF_EOF
4750         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
4751         if test -z "\$cf_target" ; then
4752                 echo '? missing rename for '\$cf_source
4753                 cf_target="\$cf_source"
4754         fi
4755         cf_target="\$cf_subdir\${section}/\${cf_target}"
4756
4757 CF_EOF
4758 fi
4759
4760 cat >>$cf_edit_man <<CF_EOF
4761         sed     -f $cf_man_alias \\
4762 CF_EOF
4763
4764 if test -f $MANPAGE_RENAMES ; then
4765 cat >>$cf_edit_man <<CF_EOF
4766                 < \$i | sed -f `pwd`/edit_man.sed >\$TMP
4767 CF_EOF
4768 else
4769 cat >>$cf_edit_man <<CF_EOF
4770                 < \$i >\$TMP
4771 CF_EOF
4772 fi
4773
4774 cat >>$cf_edit_man <<CF_EOF
4775 if test \$cf_tables = yes ; then
4776         tbl \$TMP >\$TMP.out
4777         mv \$TMP.out \$TMP
4778 fi
4779 CF_EOF
4780
4781 if test $with_overwrite != yes ; then
4782 cat >>$cf_edit_man <<CF_EOF
4783         sed -e "/\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
4784         mv \$TMP.out \$TMP
4785 CF_EOF
4786 fi
4787
4788 if test $with_curses_h != yes ; then
4789 cat >>$cf_edit_man <<CF_EOF
4790         sed -e "/\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
4791         mv \$TMP.out \$TMP
4792 CF_EOF
4793 fi
4794
4795 cat >>$cf_edit_man <<CF_EOF
4796         if test \$form = format ; then
4797                 nroff -man \$TMP >\$TMP.out
4798                 mv \$TMP.out \$TMP
4799         fi
4800 CF_EOF
4801
4802 if test -n "$cf_compress" ; then
4803 cat >>$cf_edit_man <<CF_EOF
4804         if test \$verb = installing ; then
4805         if ( $cf_compress -f \$TMP )
4806         then
4807                 mv \$TMP.$cf_so_strip \$TMP
4808         fi
4809         fi
4810         cf_target="\$cf_target.$cf_so_strip"
4811 CF_EOF
4812 fi
4813
4814 case "$MANPAGE_FORMAT" in
4815 (*BSDI*)
4816 cat >>$cf_edit_man <<CF_EOF
4817         if test \$form = format ; then
4818                 # BSDI installs only .0 suffixes in the cat directories
4819                 cf_target="\`echo \$cf_target|sed -e 's/\.[[1-9]]\+[[a-z]]*/.0/'\`"
4820         fi
4821 CF_EOF
4822   ;;
4823 esac
4824
4825 cat >>$cf_edit_man <<CF_EOF
4826         suffix=\`basename \$cf_target | sed -e 's%^[[^.]]*%%'\`
4827         if test \$verb = installing ; then
4828                 echo \$verb \$cf_target
4829                 \$INSTALL_DATA \$TMP \$cf_target
4830                 test -d \$cf_subdir\${section} &&
4831                 test -n "\$aliases" && (
4832                         cd \$cf_subdir\${section} && (
4833                                 cf_source=\`echo \$cf_target |sed -e 's%^.*/\([[^/]][[^/]]*/[[^/]][[^/]]*$\)%\1%'\`
4834                                 test -n "$cf_so_strip" && cf_source=\`echo \$cf_source |sed -e 's%\.$cf_so_strip\$%%'\`
4835                                 cf_target=\`basename \$cf_target\`
4836                                 for cf_alias in \$aliases
4837                                 do
4838                                         if test \$section = 1 ; then
4839                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4840                                         fi
4841
4842                                         if test "$MANPAGE_SYMLINKS" = yes ; then
4843                                                 if test -f \$cf_alias\${suffix} ; then
4844                                                         if ( cmp -s \$cf_target \$cf_alias\${suffix} )
4845                                                         then
4846                                                                 continue
4847                                                         fi
4848                                                 fi
4849                                                 echo .. \$verb alias \$cf_alias\${suffix}
4850 CF_EOF
4851 case "x$LN_S" in
4852 (*-f)
4853 cat >>$cf_edit_man <<CF_EOF
4854                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4855 CF_EOF
4856         ;;
4857 (*)
4858 cat >>$cf_edit_man <<CF_EOF
4859                                                 rm -f \$cf_alias\${suffix}
4860                                                 $LN_S \$cf_target \$cf_alias\${suffix}
4861 CF_EOF
4862         ;;
4863 esac
4864 cat >>$cf_edit_man <<CF_EOF
4865                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
4866                                                 echo ".so \$cf_source" >\$TMP
4867 CF_EOF
4868 if test -n "$cf_compress" ; then
4869 cat >>$cf_edit_man <<CF_EOF
4870                                                 if test -n "$cf_so_strip" ; then
4871                                                         $cf_compress -f \$TMP
4872                                                         mv \$TMP.$cf_so_strip \$TMP
4873                                                 fi
4874 CF_EOF
4875 fi
4876 cat >>$cf_edit_man <<CF_EOF
4877                                                 echo .. \$verb alias \$cf_alias\${suffix}
4878                                                 rm -f \$cf_alias\${suffix}
4879                                                 \$INSTALL_DATA \$TMP \$cf_alias\${suffix}
4880                                         fi
4881                                 done
4882                         )
4883                 )
4884         elif test \$verb = removing ; then
4885                 test -f \$cf_target && (
4886                         echo \$verb \$cf_target
4887                         rm -f \$cf_target
4888                 )
4889                 test -d \$cf_subdir\${section} &&
4890                 test -n "\$aliases" && (
4891                         cd \$cf_subdir\${section} && (
4892                                 for cf_alias in \$aliases
4893                                 do
4894                                         if test \$section = 1 ; then
4895                                                 cf_alias=\`echo \$cf_alias|sed "\${transform}"\`
4896                                         fi
4897
4898                                         echo .. \$verb alias \$cf_alias\${suffix}
4899                                         rm -f \$cf_alias\${suffix}
4900                                 done
4901                         )
4902                 )
4903         else
4904 #               echo ".hy 0"
4905                 cat \$TMP
4906         fi
4907         ;;
4908 esac
4909 done
4910
4911 if test $cf_inboth = yes ; then
4912 if test \$form != format ; then
4913         $SHELL \[$]0 format \$verb \$mandir \$srcdir \[$]*
4914 fi
4915 fi
4916
4917 exit 0
4918 CF_EOF
4919 chmod 755 $cf_edit_man
4920
4921 ])dnl
4922 dnl ---------------------------------------------------------------------------
4923 dnl CF_MATH_LIB version: 9 updated: 2017/01/21 11:06:25
4924 dnl -----------
4925 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
4926 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
4927 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
4928 AC_DEFUN([CF_MATH_LIB],
4929 [
4930 AC_CACHE_CHECK(if -lm needed for math functions,
4931         cf_cv_need_libm,[
4932         AC_TRY_LINK([
4933         #include <stdio.h>
4934         #include <stdlib.h>
4935         #include <math.h>
4936         ],
4937         [double x = rand(); printf("result = %g\n", ]ifelse([$2],,sin(x),$2)[)],
4938         [cf_cv_need_libm=no],
4939         [cf_cv_need_libm=yes])])
4940 if test "$cf_cv_need_libm" = yes
4941 then
4942 ifelse($1,,[
4943         CF_ADD_LIB(m)
4944 ],[$1=-lm])
4945 fi
4946 ])
4947 dnl ---------------------------------------------------------------------------
4948 dnl CF_MIXEDCASE_FILENAMES version: 7 updated: 2015/04/12 15:39:00
4949 dnl ----------------------
4950 dnl Check if the file-system supports mixed-case filenames.  If we're able to
4951 dnl create a lowercase name and see it as uppercase, it doesn't support that.
4952 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
4953 [
4954 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
4955 if test "$cross_compiling" = yes ; then
4956         case $target_alias in
4957         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*)
4958                 cf_cv_mixedcase=no
4959                 ;;
4960         (*)
4961                 cf_cv_mixedcase=yes
4962                 ;;
4963         esac
4964 else
4965         rm -f conftest CONFTEST
4966         echo test >conftest
4967         if test -f CONFTEST ; then
4968                 cf_cv_mixedcase=no
4969         else
4970                 cf_cv_mixedcase=yes
4971         fi
4972         rm -f conftest CONFTEST
4973 fi
4974 ])
4975 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
4976 ])dnl
4977 dnl ---------------------------------------------------------------------------
4978 dnl CF_MKSTEMP version: 10 updated: 2017/01/21 11:12:16
4979 dnl ----------
4980 dnl Check for a working mkstemp.  This creates two files, checks that they are
4981 dnl successfully created and distinct (AmigaOS apparently fails on the last).
4982 AC_DEFUN([CF_MKSTEMP],[
4983 AC_CHECK_HEADERS( \
4984 unistd.h \
4985 )
4986 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
4987 rm -rf conftest*
4988 AC_TRY_RUN([
4989 #include <sys/types.h>
4990 #ifdef HAVE_UNISTD_H
4991 #include <unistd.h>
4992 #endif
4993 #include <stdlib.h>
4994 #include <stdio.h>
4995 #include <string.h>
4996 #include <sys/stat.h>
4997 int main(void)
4998 {
4999         char *tmpl = "conftestXXXXXX";
5000         char name[2][80];
5001         int n;
5002         int result = 0;
5003         int fd;
5004         struct stat sb;
5005
5006         umask(077);
5007         for (n = 0; n < 2; ++n) {
5008                 strcpy(name[n], tmpl);
5009                 if ((fd = mkstemp(name[n])) >= 0) {
5010                         if (!strcmp(name[n], tmpl)
5011                          || stat(name[n], &sb) != 0
5012                          || (sb.st_mode & S_IFMT) != S_IFREG
5013                          || (sb.st_mode & 077) != 0) {
5014                                 result = 1;
5015                         }
5016                         close(fd);
5017                 }
5018         }
5019         if (result == 0
5020          && !strcmp(name[0], name[1]))
5021                 result = 1;
5022         ${cf_cv_main_return:-return}(result);
5023 }
5024 ],[cf_cv_func_mkstemp=yes
5025 ],[cf_cv_func_mkstemp=no
5026 ],[cf_cv_func_mkstemp=maybe])
5027 ])
5028 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
5029         AC_CHECK_FUNC(mkstemp)
5030 fi
5031 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
5032         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
5033 fi
5034 ])dnl
5035 dnl ---------------------------------------------------------------------------
5036 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
5037 dnl ----------
5038 dnl Write a debug message to config.log, along with the line number in the
5039 dnl configure script.
5040 AC_DEFUN([CF_MSG_LOG],[
5041 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
5042 ])dnl
5043 dnl ---------------------------------------------------------------------------
5044 dnl CF_NCURSES_ABI_6 version: 3 updated: 2015/06/06 16:10:11
5045 dnl ----------------
5046 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
5047 dnl warn about this.
5048 AC_DEFUN([CF_NCURSES_ABI_6],[
5049 if test "${with_abi_version+set}" != set; then
5050         case $cf_cv_rel_version in
5051         (5.*)
5052                 cf_cv_rel_version=6.0
5053                 cf_cv_abi_version=6
5054                 AC_MSG_WARN(overriding ABI version to $cf_cv_abi_version)
5055                 ;;
5056         esac
5057 fi
5058 ])dnl
5059 dnl ---------------------------------------------------------------------------
5060 dnl CF_NCURSES_WITH_ABI_VERSION version: 2 updated: 2015/12/19 17:51:52
5061 dnl ---------------------------
5062 dnl Allow ncurses's ABI to be overridden.  Generally this happens when a
5063 dnl packager has incremented the ABI past that used in the original package,
5064 dnl and wishes to keep doing this.
5065 dnl
5066 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
5067 dnl symbol.
5068 AC_DEFUN([CF_NCURSES_WITH_ABI_VERSION],[
5069 CF_WITH_ABI_VERSION($1)
5070 if test "x$cf_cv_abi_version" != "x$with_abi_version"
5071 then
5072         case $cf_cv_rel_version in
5073         (5.*)
5074                 cf_cv_rel_version=$with_abi_version.0
5075                 ;;
5076         esac
5077 fi
5078 ])dnl
5079 dnl ---------------------------------------------------------------------------
5080 dnl CF_NO_LEAKS_OPTION version: 6 updated: 2015/04/12 15:39:00
5081 dnl ------------------
5082 dnl see CF_WITH_NO_LEAKS
5083 AC_DEFUN([CF_NO_LEAKS_OPTION],[
5084 AC_MSG_CHECKING(if you want to use $1 for testing)
5085 AC_ARG_WITH($1,
5086         [$2],
5087         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
5088          $4
5089 ])
5090         : ${with_cflags:=-g}
5091         : ${with_no_leaks:=yes}
5092          with_$1=yes],
5093         [with_$1=])
5094 AC_MSG_RESULT(${with_$1:-no})
5095
5096 case .$with_cflags in
5097 (.*-g*)
5098         case .$CFLAGS in
5099         (.*-g*)
5100                 ;;
5101         (*)
5102                 CF_ADD_CFLAGS([-g])
5103                 ;;
5104         esac
5105         ;;
5106 esac
5107 ])dnl
5108 dnl ---------------------------------------------------------------------------
5109 dnl CF_NUMBER_SYNTAX version: 2 updated: 2015/04/17 21:13:04
5110 dnl ----------------
5111 dnl Check if the given variable is a number.  If not, report an error.
5112 dnl $1 is the variable
5113 dnl $2 is the message
5114 AC_DEFUN([CF_NUMBER_SYNTAX],[
5115 if test -n "$1" ; then
5116   case $1 in
5117   ([[0-9]]*)
5118         ;;
5119   (*)
5120         AC_MSG_ERROR($2 is not a number: $1)
5121         ;;
5122   esac
5123 else
5124   AC_MSG_ERROR($2 value is empty)
5125 fi
5126 ])dnl
5127 dnl ---------------------------------------------------------------------------
5128 dnl CF_OBJ_SUBDIR version: 7 updated: 2015/04/17 21:13:04
5129 dnl -------------
5130 dnl Compute the object-directory name from the given model name
5131 AC_DEFUN([CF_OBJ_SUBDIR],
5132 [
5133         case $1 in
5134         (libtool) $2='obj_lo'  ;;
5135         (normal)  $2='objects' ;;
5136         (debug)   $2='obj_g' ;;
5137         (profile) $2='obj_p' ;;
5138         (shared)
5139                 case $cf_cv_system_name in
5140                 (cygwin|msys)
5141                         $2='objects' ;;
5142                 (*)
5143                         $2='obj_s' ;;
5144                 esac
5145         esac
5146 ])dnl
5147 dnl ---------------------------------------------------------------------------
5148 dnl CF_PATHSEP version: 7 updated: 2015/04/12 15:39:00
5149 dnl ----------
5150 dnl Provide a value for the $PATH and similar separator (or amend the value
5151 dnl as provided in autoconf 2.5x).
5152 AC_DEFUN([CF_PATHSEP],
5153 [
5154         AC_MSG_CHECKING(for PATH separator)
5155         case $cf_cv_system_name in
5156         (os2*)  PATH_SEPARATOR=';'  ;;
5157         (*)     ${PATH_SEPARATOR:=':'}  ;;
5158         esac
5159 ifelse([$1],,,[$1=$PATH_SEPARATOR])
5160         AC_SUBST(PATH_SEPARATOR)
5161         AC_MSG_RESULT($PATH_SEPARATOR)
5162 ])dnl
5163 dnl ---------------------------------------------------------------------------
5164 dnl CF_PATH_SYNTAX version: 16 updated: 2015/04/18 08:56:57
5165 dnl --------------
5166 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
5167 dnl begins with one of the prefix/exec_prefix variables, and then again if the
5168 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
5169 dnl delayed evaluation of those symbols.
5170 AC_DEFUN([CF_PATH_SYNTAX],[
5171 if test "x$prefix" != xNONE; then
5172         cf_path_syntax="$prefix"
5173 else
5174         cf_path_syntax="$ac_default_prefix"
5175 fi
5176
5177 case ".[$]$1" in
5178 (.\[$]\(*\)*|.\'*\'*)
5179         ;;
5180 (..|./*|.\\*)
5181         ;;
5182 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
5183         ;;
5184 (.\[$]{*prefix}*|.\[$]{*dir}*)
5185         eval $1="[$]$1"
5186         case ".[$]$1" in
5187         (.NONE/*)
5188                 $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
5189                 ;;
5190         esac
5191         ;;
5192 (.no|.NONE/*)
5193         $1=`echo [$]$1 | sed -e s%NONE%$cf_path_syntax%`
5194         ;;
5195 (*)
5196         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
5197         ;;
5198 esac
5199 ])dnl
5200 dnl ---------------------------------------------------------------------------
5201 dnl CF_PKG_CONFIG version: 10 updated: 2015/04/26 18:06:58
5202 dnl -------------
5203 dnl Check for the package-config program, unless disabled by command-line.
5204 AC_DEFUN([CF_PKG_CONFIG],
5205 [
5206 AC_MSG_CHECKING(if you want to use pkg-config)
5207 AC_ARG_WITH(pkg-config,
5208         [  --with-pkg-config{=path} enable/disable use of pkg-config],
5209         [cf_pkg_config=$withval],
5210         [cf_pkg_config=yes])
5211 AC_MSG_RESULT($cf_pkg_config)
5212
5213 case $cf_pkg_config in
5214 (no)
5215         PKG_CONFIG=none
5216         ;;
5217 (yes)
5218         CF_ACVERSION_CHECK(2.52,
5219                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
5220                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
5221         ;;
5222 (*)
5223         PKG_CONFIG=$withval
5224         ;;
5225 esac
5226
5227 test -z "$PKG_CONFIG" && PKG_CONFIG=none
5228 if test "$PKG_CONFIG" != none ; then
5229         CF_PATH_SYNTAX(PKG_CONFIG)
5230 elif test "x$cf_pkg_config" != xno ; then
5231         AC_MSG_WARN(pkg-config is not installed)
5232 fi
5233
5234 AC_SUBST(PKG_CONFIG)
5235 ])dnl
5236 dnl ---------------------------------------------------------------------------
5237 dnl CF_POSIX_C_SOURCE version: 9 updated: 2015/04/12 15:39:00
5238 dnl -----------------
5239 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
5240 dnl
5241 dnl     POSIX.1-1990                            _POSIX_SOURCE
5242 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
5243 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
5244 dnl             Bindings Option
5245 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
5246 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
5247 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
5248 dnl
5249 dnl Parameters:
5250 dnl     $1 is the nominal value for _POSIX_C_SOURCE
5251 AC_DEFUN([CF_POSIX_C_SOURCE],
5252 [
5253 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
5254
5255 cf_save_CFLAGS="$CFLAGS"
5256 cf_save_CPPFLAGS="$CPPFLAGS"
5257
5258 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
5259 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
5260
5261 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
5262         CF_MSG_LOG(if the symbol is already defined go no further)
5263         AC_TRY_COMPILE([#include <sys/types.h>],[
5264 #ifndef _POSIX_C_SOURCE
5265 make an error
5266 #endif],
5267         [cf_cv_posix_c_source=no],
5268         [cf_want_posix_source=no
5269          case .$cf_POSIX_C_SOURCE in
5270          (.[[12]]??*)
5271                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
5272                 ;;
5273          (.2)
5274                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
5275                 cf_want_posix_source=yes
5276                 ;;
5277          (.*)
5278                 cf_want_posix_source=yes
5279                 ;;
5280          esac
5281          if test "$cf_want_posix_source" = yes ; then
5282                 AC_TRY_COMPILE([#include <sys/types.h>],[
5283 #ifdef _POSIX_SOURCE
5284 make an error
5285 #endif],[],
5286                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
5287          fi
5288          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
5289          CFLAGS="$cf_trim_CFLAGS"
5290          CPPFLAGS="$cf_trim_CPPFLAGS $cf_cv_posix_c_source"
5291          CF_MSG_LOG(if the second compile does not leave our definition intact error)
5292          AC_TRY_COMPILE([#include <sys/types.h>],[
5293 #ifndef _POSIX_C_SOURCE
5294 make an error
5295 #endif],,
5296          [cf_cv_posix_c_source=no])
5297          CFLAGS="$cf_save_CFLAGS"
5298          CPPFLAGS="$cf_save_CPPFLAGS"
5299         ])
5300 ])
5301
5302 if test "$cf_cv_posix_c_source" != no ; then
5303         CFLAGS="$cf_trim_CFLAGS"
5304         CPPFLAGS="$cf_trim_CPPFLAGS"
5305         CF_ADD_CFLAGS($cf_cv_posix_c_source)
5306 fi
5307
5308 ])dnl
5309 dnl ---------------------------------------------------------------------------
5310 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
5311 dnl ------------
5312 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
5313 dnl
5314 dnl $1 = symbol to test
5315 dnl $2 = value (if any) to use for a predefinition
5316 AC_DEFUN([CF_PREDEFINE],
5317 [
5318 AC_MSG_CHECKING(if we must define $1)
5319 AC_TRY_COMPILE([#include <sys/types.h>
5320 ],[
5321 #ifndef $1
5322 make an error
5323 #endif],[cf_result=no],[cf_result=yes])
5324 AC_MSG_RESULT($cf_result)
5325
5326 if test "$cf_result" = yes ; then
5327         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
5328 elif test "x$2" != "x" ; then
5329         AC_MSG_CHECKING(checking for compatible value versus $2)
5330         AC_TRY_COMPILE([#include <sys/types.h>
5331 ],[
5332 #if $1-$2 < 0
5333 make an error
5334 #endif],[cf_result=yes],[cf_result=no])
5335         AC_MSG_RESULT($cf_result)
5336         if test "$cf_result" = no ; then
5337                 # perhaps we can override it - try...
5338                 CPPFLAGS="$CPPFLAGS -D$1=$2"
5339         fi
5340 fi
5341 ])dnl
5342 dnl ---------------------------------------------------------------------------
5343 dnl CF_PRG_RULES version: 1 updated: 2006/06/03 11:45:08
5344 dnl ------------
5345 dnl Append definitions and rules for the given programs to the subdirectory
5346 dnl Makefiles, and the recursion rule for the top-level Makefile.
5347 dnl
5348 dnl parameters
5349 dnl     $1 = script to run
5350 dnl     $2 = list of subdirectories
5351 dnl
5352 dnl variables
5353 dnl     $AWK
5354 AC_DEFUN([CF_PRG_RULES],
5355 [
5356 for cf_dir in $2
5357 do
5358         if test ! -d $srcdir/$cf_dir; then
5359                 continue
5360         elif test -f $srcdir/$cf_dir/programs; then
5361                 $AWK -f $1 $srcdir/$cf_dir/programs >>$cf_dir/Makefile
5362         fi
5363 done
5364
5365 ])dnl
5366 dnl ---------------------------------------------------------------------------
5367 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
5368 dnl ----------
5369 dnl Check for archiver "ar".
5370 AC_DEFUN([CF_PROG_AR],[
5371 AC_CHECK_TOOL(AR, ar, ar)
5372 ])
5373 dnl ---------------------------------------------------------------------------
5374 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
5375 dnl -----------
5376 dnl Check for awk, ensure that the check found something.
5377 AC_DEFUN([CF_PROG_AWK],
5378 [
5379 AC_PROG_AWK
5380 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
5381 ])dnl
5382 dnl ---------------------------------------------------------------------------
5383 dnl CF_PROG_CC version: 4 updated: 2014/07/12 18:57:58
5384 dnl ----------
5385 dnl standard check for CC, plus followup sanity checks
5386 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
5387 AC_DEFUN([CF_PROG_CC],[
5388 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
5389 CF_GCC_VERSION
5390 CF_ACVERSION_CHECK(2.52,
5391         [AC_PROG_CC_STDC],
5392         [CF_ANSI_CC_REQD])
5393 CF_CC_ENV_FLAGS
5394 ])dnl
5395 dnl ---------------------------------------------------------------------------
5396 dnl CF_PROG_CC_C_O version: 5 updated: 2017/01/21 11:06:25
5397 dnl --------------
5398 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
5399 dnl the output file can be renamed, and allows for a shell variable that can
5400 dnl be used later.  The parameter is either CC or CXX.  The result is the
5401 dnl cache variable:
5402 dnl     $cf_cv_prog_CC_c_o
5403 dnl     $cf_cv_prog_CXX_c_o
5404 dnl
5405 dnl $1 = compiler
5406 dnl $2 = compiler options, if any
5407 AC_DEFUN([CF_PROG_CC_C_O],
5408 [AC_REQUIRE([AC_PROG_CC])dnl
5409 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
5410 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
5411 [
5412 cat > conftest.$ac_ext <<CF_EOF
5413 int main(void)
5414 {
5415         ${cf_cv_main_return:-return}(0);
5416 }
5417 CF_EOF
5418 # We do the test twice because some compilers refuse to overwrite an
5419 # existing .o file with -o, though they will create one.
5420 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
5421 if AC_TRY_EVAL(ac_try) &&
5422   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
5423 then
5424   eval cf_cv_prog_$1_c_o=yes
5425 else
5426   eval cf_cv_prog_$1_c_o=no
5427 fi
5428 rm -rf conftest*
5429 ])dnl
5430 if test $cf_cv_prog_$1_c_o = yes; then
5431   AC_MSG_RESULT([yes])
5432 else
5433   AC_MSG_RESULT([no])
5434 fi
5435 ])dnl
5436 dnl ---------------------------------------------------------------------------
5437 dnl CF_PROG_EGREP version: 2 updated: 2015/04/18 08:56:57
5438 dnl -------------
5439 dnl AC_PROG_EGREP was introduced in autoconf 2.53.
5440 dnl This macro adds a check to ensure the script found something.
5441 AC_DEFUN([CF_PROG_EGREP],
5442 [AC_CACHE_CHECK([for egrep], [ac_cv_prog_egrep],
5443         [if echo a | (grep -E '(a|b)') >/dev/null 2>&1
5444                 then ac_cv_prog_egrep='grep -E'
5445                 else ac_cv_prog_egrep='egrep'
5446         fi])
5447         EGREP=$ac_cv_prog_egrep
5448         AC_SUBST([EGREP])
5449         test -z "$EGREP" && AC_MSG_ERROR(No egrep program found)
5450 ])dnl
5451 dnl ---------------------------------------------------------------------------
5452 dnl CF_PROG_GNAT version: 3 updated: 2015/04/18 08:56:57
5453 dnl ------------
5454 dnl Check for gnatmake, ensure that it is complete.
5455 AC_DEFUN([CF_PROG_GNAT],[
5456 cf_ada_make=gnatmake
5457 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
5458 if test "$ac_cv_prog_gnat_exists" = no; then
5459         cf_ada_make=
5460         cf_cv_prog_gnat_correct=no
5461 else
5462         CF_GNAT_VERSION
5463         AC_CHECK_PROG(M4_exists, m4, yes, no)
5464         if test "$ac_cv_prog_M4_exists" = no; then
5465                 cf_cv_prog_gnat_correct=no
5466                 echo Ada95 binding required program m4 not found. Ada95 binding disabled.
5467         fi
5468         if test "$cf_cv_prog_gnat_correct" = yes; then
5469                 AC_MSG_CHECKING(if GNAT works)
5470                 CF_GNAT_TRY_RUN([procedure conftest;],
5471 [with Text_IO;
5472 with GNAT.OS_Lib;
5473 procedure conftest is
5474 begin
5475    Text_IO.Put ("Hello World");
5476    Text_IO.New_Line;
5477    GNAT.OS_Lib.OS_Exit (0);
5478 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
5479                 AC_MSG_RESULT($cf_cv_prog_gnat_correct)
5480         fi
5481 fi
5482
5483 AC_SUBST(cf_ada_make)
5484 ])dnl
5485 dnl ---------------------------------------------------------------------------
5486 dnl CF_PROG_INSTALL version: 7 updated: 2015/04/18 08:56:57
5487 dnl ---------------
5488 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
5489 dnl misc/tabset install won't work properly.  Usually this happens only when
5490 dnl using the fallback mkinstalldirs script
5491 AC_DEFUN([CF_PROG_INSTALL],
5492 [AC_PROG_INSTALL
5493 case $INSTALL in
5494 (/*)
5495         ;;
5496 (*)
5497         CF_DIRNAME(cf_dir,$INSTALL)
5498         test -z "$cf_dir" && cf_dir=.
5499         INSTALL=`cd $cf_dir && pwd`/`echo $INSTALL | sed -e 's%^.*/%%'`
5500         ;;
5501 esac
5502 ])dnl
5503 dnl ---------------------------------------------------------------------------
5504 dnl CF_PROG_LDCONFIG version: 5 updated: 2015/04/18 08:56:57
5505 dnl ----------------
5506 dnl Check for ldconfig, needed to fixup shared libraries that would be built
5507 dnl and then used in the install.
5508 AC_DEFUN([CF_PROG_LDCONFIG],[
5509 if test "$cross_compiling" = yes ; then
5510         LDCONFIG=:
5511 else
5512         case "$cf_cv_system_name" in
5513         (dragonfly*|mirbsd*|freebsd*)
5514                 test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
5515                 ;;
5516         (*) LDPATH=$PATH:/sbin:/usr/sbin
5517                 AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
5518                 ;;
5519         esac
5520 fi
5521 AC_SUBST(LDCONFIG)
5522 ])dnl
5523 dnl ---------------------------------------------------------------------------
5524 dnl CF_PROG_LINT version: 3 updated: 2016/05/22 15:25:54
5525 dnl ------------
5526 AC_DEFUN([CF_PROG_LINT],
5527 [
5528 AC_CHECK_PROGS(LINT, lint cppcheck splint)
5529 AC_SUBST(LINT_OPTS)
5530 ])dnl
5531 dnl ---------------------------------------------------------------------------
5532 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
5533 dnl ------------
5534 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
5535 dnl option if it is supported.
5536 AC_DEFUN([CF_PROG_LN_S],[
5537 AC_PROG_LN_S
5538 AC_MSG_CHECKING(if $LN_S -f options work)
5539
5540 rm -f conf$$.src conf$$dst
5541 echo >conf$$.dst
5542 echo first >conf$$.src
5543 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
5544         cf_prog_ln_sf=yes
5545 else
5546         cf_prog_ln_sf=no
5547 fi
5548 rm -f conf$$.dst conf$$src
5549 AC_MSG_RESULT($cf_prog_ln_sf)
5550
5551 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
5552 ])dnl
5553 dnl ---------------------------------------------------------------------------
5554 dnl CF_REGEX version: 12 updated: 2015/04/18 08:56:57
5555 dnl --------
5556 dnl Attempt to determine if we've got one of the flavors of regular-expression
5557 dnl code that we can support.
5558 AC_DEFUN([CF_REGEX],
5559 [
5560
5561 cf_regex_func=no
5562
5563 cf_regex_libs="regex re"
5564 case $host_os in
5565 (mingw*)
5566         cf_regex_libs="gnurx $cf_regex_libs"
5567         ;;
5568 esac
5569
5570 AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
5571         for cf_regex_lib in $cf_regex_libs
5572         do
5573                 AC_CHECK_LIB($cf_regex_lib,regcomp,[
5574                                 CF_ADD_LIB($cf_regex_lib)
5575                                 cf_regex_func=regcomp
5576                                 break])
5577         done
5578 ])
5579
5580 if test "$cf_regex_func" = no ; then
5581         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
5582                 AC_CHECK_LIB(gen,compile,[
5583                                 CF_ADD_LIB(gen)
5584                                 cf_regex_func=compile])])
5585 fi
5586
5587 if test "$cf_regex_func" = no ; then
5588         AC_MSG_WARN(cannot find regular expression library)
5589 fi
5590
5591 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
5592
5593 cf_cv_regex_hdrs=no
5594 case $cf_regex_func in
5595 (compile)
5596         for cf_regex_hdr in regexp.h regexpr.h
5597         do
5598                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
5599                         char *p = compile("", "", "", 0);
5600                         int x = step("", "");
5601                 ],[
5602                         cf_cv_regex_hdrs=$cf_regex_hdr
5603                         break
5604                 ])
5605         done
5606         ;;
5607 (*)
5608         for cf_regex_hdr in regex.h
5609         do
5610                 AC_TRY_LINK([#include <sys/types.h>
5611 #include <$cf_regex_hdr>],[
5612                         regex_t *p;
5613                         int x = regcomp(p, "", 0);
5614                         int y = regexec(p, "", 0, 0, 0);
5615                         regfree(p);
5616                 ],[
5617                         cf_cv_regex_hdrs=$cf_regex_hdr
5618                         break
5619                 ])
5620         done
5621         ;;
5622 esac
5623
5624 ])
5625
5626 case $cf_cv_regex_hdrs in
5627         (no)            AC_MSG_WARN(no regular expression header found) ;;
5628         (regex.h)       AC_DEFINE(HAVE_REGEX_H_FUNCS,1,[Define to 1 to include regex.h for regular expressions]) ;;
5629         (regexp.h)      AC_DEFINE(HAVE_REGEXP_H_FUNCS,1,[Define to 1 to include regexp.h for regular expressions]) ;;
5630         (regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS,1,[Define to 1 to include regexpr.h for regular expressions]) ;;
5631 esac
5632 ])dnl
5633 dnl ---------------------------------------------------------------------------
5634 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
5635 dnl ----------------
5636 dnl Remove all -U and -D options that refer to the given symbol from a list
5637 dnl of C compiler options.  This works around the problem that not all
5638 dnl compilers process -U and -D options from left-to-right, so a -U option
5639 dnl cannot be used to cancel the effect of a preceding -D option.
5640 dnl
5641 dnl $1 = target (which could be the same as the source variable)
5642 dnl $2 = source (including '$')
5643 dnl $3 = symbol to remove
5644 define([CF_REMOVE_DEFINE],
5645 [
5646 $1=`echo "$2" | \
5647         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
5648                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
5649 ])dnl
5650 dnl ---------------------------------------------------------------------------
5651 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
5652 dnl -------------
5653 dnl Remove the given library from the symbol
5654 dnl
5655 dnl $1 = target (which could be the same as the source variable)
5656 dnl $2 = source (including '$')
5657 dnl $3 = library to remove
5658 define([CF_REMOVE_LIB],
5659 [
5660 # remove $3 library from $2
5661 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
5662 ])dnl
5663 dnl ---------------------------------------------------------------------------
5664 dnl CF_RPATH_HACK version: 11 updated: 2013/09/01 13:02:00
5665 dnl -------------
5666 AC_DEFUN([CF_RPATH_HACK],
5667 [
5668 AC_REQUIRE([CF_LD_RPATH_OPT])
5669 AC_MSG_CHECKING(for updated LDFLAGS)
5670 if test -n "$LD_RPATH_OPT" ; then
5671         AC_MSG_RESULT(maybe)
5672
5673         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
5674         cf_rpath_list="/usr/lib /lib"
5675         if test "$cf_ldd_prog" != no
5676         then
5677                 cf_rpath_oops=
5678
5679 AC_TRY_LINK([#include <stdio.h>],
5680                 [printf("Hello");],
5681                 [cf_rpath_oops=`$cf_ldd_prog conftest$ac_exeext | fgrep ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
5682                  cf_rpath_list=`$cf_ldd_prog conftest$ac_exeext | fgrep / | sed -e 's%^.*[[     ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
5683
5684                 # If we passed the link-test, but get a "not found" on a given library,
5685                 # this could be due to inept reconfiguration of gcc to make it only
5686                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
5687                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
5688                 # /usr/local libraries.
5689                 if test -n "$cf_rpath_oops"
5690                 then
5691                         for cf_rpath_src in $cf_rpath_oops
5692                         do
5693                                 for cf_rpath_dir in \
5694                                         /usr/local \
5695                                         /usr/pkg \
5696                                         /opt/sfw
5697                                 do
5698                                         if test -f $cf_rpath_dir/lib/$cf_rpath_src
5699                                         then
5700                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
5701                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
5702                                                 break
5703                                         fi
5704                                 done
5705                         done
5706                 fi
5707         fi
5708
5709         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5710
5711         CF_RPATH_HACK_2(LDFLAGS)
5712         CF_RPATH_HACK_2(LIBS)
5713
5714         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
5715 else
5716         AC_MSG_RESULT(no)
5717 fi
5718 AC_SUBST(EXTRA_LDFLAGS)
5719 ])dnl
5720 dnl ---------------------------------------------------------------------------
5721 dnl CF_RPATH_HACK_2 version: 7 updated: 2015/04/12 15:39:00
5722 dnl ---------------
5723 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
5724 dnl EXTRA_LDFLAGS for each -L option found.
5725 dnl
5726 dnl $cf_rpath_list contains a list of directories to ignore.
5727 dnl
5728 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
5729 dnl      but LIBS often has misplaced -L options.
5730 AC_DEFUN([CF_RPATH_HACK_2],
5731 [
5732 CF_VERBOSE(...checking $1 [$]$1)
5733
5734 cf_rpath_dst=
5735 for cf_rpath_src in [$]$1
5736 do
5737         case $cf_rpath_src in
5738         (-L*)
5739
5740                 # check if this refers to a directory which we will ignore
5741                 cf_rpath_skip=no
5742                 if test -n "$cf_rpath_list"
5743                 then
5744                         for cf_rpath_item in $cf_rpath_list
5745                         do
5746                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
5747                                 then
5748                                         cf_rpath_skip=yes
5749                                         break
5750                                 fi
5751                         done
5752                 fi
5753
5754                 if test "$cf_rpath_skip" = no
5755                 then
5756                         # transform the option
5757                         if test "$LD_RPATH_OPT" = "-R " ; then
5758                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
5759                         else
5760                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
5761                         fi
5762
5763                         # if we have not already added this, add it now
5764                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
5765                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
5766                         then
5767                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
5768                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
5769                         fi
5770                 fi
5771                 ;;
5772         esac
5773         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
5774 done
5775 $1=$cf_rpath_dst
5776
5777 CF_VERBOSE(...checked $1 [$]$1)
5778 AC_SUBST(EXTRA_LDFLAGS)
5779 ])dnl
5780 dnl ---------------------------------------------------------------------------
5781 dnl CF_SHARED_OPTS version: 90 updated: 2017/02/11 14:48:57
5782 dnl --------------
5783 dnl --------------
5784 dnl Attempt to determine the appropriate CC/LD options for creating a shared
5785 dnl library.
5786 dnl
5787 dnl Notes:
5788 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
5789 dnl the build-tree, i.e., by making use of the libraries that are compiled in
5790 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
5791 dnl shared library since that can lead to unexpected results at runtime.
5792 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
5793 dnl libraries are compiled in ../../lib
5794 dnl
5795 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
5796 dnl to install symbolic links to the rel/abi versions of shared libraries.
5797 dnl
5798 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
5799 dnl version when making symbolic links.
5800 dnl
5801 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
5802 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
5803 dnl (ex: libncurses.so.<ver>).
5804 dnl
5805 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
5806 AC_DEFUN([CF_SHARED_OPTS],
5807 [
5808         AC_REQUIRE([CF_LD_RPATH_OPT])
5809         RM_SHARED_OPTS=
5810         LOCAL_LDFLAGS=
5811         LOCAL_LDFLAGS2=
5812         LD_SHARED_OPTS=
5813         INSTALL_LIB="-m 644"
5814         : ${rel_builddir:=.}
5815
5816         shlibdir=$libdir
5817         AC_SUBST(shlibdir)
5818
5819         MAKE_DLLS="#"
5820         AC_SUBST(MAKE_DLLS)
5821
5822         cf_cv_do_symlinks=no
5823         cf_ld_rpath_opt=
5824         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
5825
5826         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
5827         AC_ARG_WITH(shlib-version,
5828         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
5829         [test -z "$withval" && withval=auto
5830         case $withval in
5831         (yes)
5832                 cf_cv_shlib_version=auto
5833                 ;;
5834         (rel|abi|auto)
5835                 cf_cv_shlib_version=$withval
5836                 ;;
5837         (*)
5838                 AC_MSG_RESULT($withval)
5839                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
5840                 ;;
5841         esac
5842         ],[cf_cv_shlib_version=auto])
5843         AC_MSG_RESULT($cf_cv_shlib_version)
5844
5845         cf_cv_rm_so_locs=no
5846         cf_try_cflags=
5847
5848         # Some less-capable ports of gcc support only -fpic
5849         CC_SHARED_OPTS=
5850
5851         cf_try_fPIC=no
5852         if test "$GCC" = yes
5853         then
5854                 cf_try_fPIC=yes
5855         else
5856                 case $cf_cv_system_name in
5857                 (*linux*)       # e.g., PGI compiler
5858                         cf_try_fPIC=yes
5859                         ;;
5860                 esac
5861         fi
5862
5863         if test "$cf_try_fPIC" = yes
5864         then
5865                 AC_MSG_CHECKING(which $CC option to use)
5866                 cf_save_CFLAGS="$CFLAGS"
5867                 for CC_SHARED_OPTS in -fPIC -fpic ''
5868                 do
5869                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
5870                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
5871                 done
5872                 AC_MSG_RESULT($CC_SHARED_OPTS)
5873                 CFLAGS="$cf_save_CFLAGS"
5874         fi
5875
5876         cf_cv_shlib_version_infix=no
5877
5878         case $cf_cv_system_name in
5879         (aix4.[3-9]*|aix[[5-7]]*)
5880                 if test "$GCC" = yes; then
5881                         CC_SHARED_OPTS='-Wl,-brtl'
5882                         MK_SHARED_LIB='${CC} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5883                 else
5884                         CC_SHARED_OPTS='-brtl'
5885                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
5886                         MK_SHARED_LIB='${CC} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
5887                 fi
5888                 ;;
5889         (beos*)
5890                 MK_SHARED_LIB='${CC} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
5891                 ;;
5892         (cygwin*)
5893                 CC_SHARED_OPTS=
5894                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5895                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5896                 cf_cv_shlib_version=cygdll
5897                 cf_cv_shlib_version_infix=cygdll
5898                 shlibdir=$bindir
5899                 MAKE_DLLS=
5900                 cat >mk_shared_lib.sh <<-CF_EOF
5901                 #!$SHELL
5902                 SHARED_LIB=\[$]1
5903                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5904                 shift
5905                 cat <<-EOF
5906                 Linking shared library
5907                 ** SHARED_LIB \[$]SHARED_LIB
5908                 ** IMPORT_LIB \[$]IMPORT_LIB
5909 EOF
5910                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5911 CF_EOF
5912                 chmod +x mk_shared_lib.sh
5913                 ;;
5914         (msys*)
5915                 CC_SHARED_OPTS=
5916                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
5917                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
5918                 cf_cv_shlib_version=msysdll
5919                 cf_cv_shlib_version_infix=msysdll
5920                 shlibdir=$bindir
5921                 MAKE_DLLS=
5922                 cat >mk_shared_lib.sh <<-CF_EOF
5923                 #!$SHELL
5924                 SHARED_LIB=\[$]1
5925                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
5926                 shift
5927                 cat <<-EOF
5928                 Linking shared library
5929                 ** SHARED_LIB \[$]SHARED_LIB
5930                 ** IMPORT_LIB \[$]IMPORT_LIB
5931 EOF
5932                 exec \[$]* -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
5933 CF_EOF
5934                 chmod +x mk_shared_lib.sh
5935                 ;;
5936         (darwin*)
5937                 cf_try_cflags="no-cpp-precomp"
5938                 CC_SHARED_OPTS="-dynamic"
5939                 MK_SHARED_LIB='${CC} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
5940                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
5941                 cf_cv_shlib_version_infix=yes
5942                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
5943                         cf_save_LDFLAGS=$LDFLAGS
5944                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5945                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
5946                                 LDFLAGS=$cf_save_LDFLAGS])
5947                 if test $cf_cv_ldflags_search_paths_first = yes; then
5948                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
5949                 fi
5950                 ;;
5951         (hpux[[7-8]]*)
5952                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
5953                 if test "$GCC" != yes; then
5954                         CC_SHARED_OPTS='+Z'
5955                 fi
5956                 MK_SHARED_LIB='${LD} -b -o $[@]'
5957                 INSTALL_LIB="-m 555"
5958                 ;;
5959         (hpux*)
5960                 # (tested with gcc 2.7.2 -- I don't have c89)
5961                 if test "$GCC" = yes; then
5962                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
5963                 else
5964                         CC_SHARED_OPTS='+Z'
5965                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
5966                 fi
5967                 MK_SHARED_LIB='${LD} +b ${libdir} -b -o $[@]'
5968                 # HP-UX shared libraries must be executable, and should be
5969                 # readonly to exploit a quirk in the memory manager.
5970                 INSTALL_LIB="-m 555"
5971                 ;;
5972         (interix*)
5973                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
5974                 if test "$cf_cv_shlib_version" = rel; then
5975                         cf_shared_soname='`basename $@ .${REL_VERSION}`.${ABI_VERSION}'
5976                 else
5977                         cf_shared_soname='`basename $@`'
5978                 fi
5979                 CC_SHARED_OPTS=
5980                 MK_SHARED_LIB='${CC} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $@'
5981                 ;;
5982         (irix*)
5983                 if test "$cf_cv_enable_rpath" = yes ; then
5984                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
5985                 fi
5986                 # tested with IRIX 5.2 and 'cc'.
5987                 if test "$GCC" != yes; then
5988                         CC_SHARED_OPTS='-KPIC'
5989                         MK_SHARED_LIB='${CC} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
5990                 else
5991                         MK_SHARED_LIB='${CC} -shared -Wl,-soname,`basename $[@]` -o $[@]'
5992                 fi
5993                 cf_cv_rm_so_locs=yes
5994                 ;;
5995         (linux*|gnu*|k*bsd*-gnu)
5996                 if test "$DFT_LWR_MODEL" = "shared" ; then
5997                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
5998                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
5999                 fi
6000                 if test "$cf_cv_enable_rpath" = yes ; then
6001                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6002                 fi
6003                 CF_SHARED_SONAME
6004                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
6005                 ;;
6006         (mingw*)
6007                 cf_cv_shlib_version=mingw
6008                 cf_cv_shlib_version_infix=mingw
6009                 shlibdir=$bindir
6010                 MAKE_DLLS=
6011                 if test "$DFT_LWR_MODEL" = "shared" ; then
6012                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
6013                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6014                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
6015                 fi
6016                 CC_SHARED_OPTS=
6017                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
6018                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
6019                 cat >mk_shared_lib.sh <<-CF_EOF
6020                 #!$SHELL
6021                 SHARED_LIB=\[$]1
6022                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
6023                 shift
6024                 cat <<-EOF
6025                 Linking shared library
6026                 ** SHARED_LIB \[$]SHARED_LIB
6027                 ** IMPORT_LIB \[$]IMPORT_LIB
6028 EOF
6029                 exec \[$]* -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
6030 CF_EOF
6031                 chmod +x mk_shared_lib.sh
6032                 ;;
6033         (openbsd[[2-9]].*|mirbsd*)
6034                 if test "$DFT_LWR_MODEL" = "shared" ; then
6035                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
6036                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6037                 fi
6038                 if test "$cf_cv_enable_rpath" = yes ; then
6039                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6040                 fi
6041                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
6042                 CF_SHARED_SONAME
6043                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
6044                 ;;
6045         (nto-qnx*|openbsd*|freebsd[[12]].*)
6046                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
6047                 MK_SHARED_LIB='${LD} -Bshareable -o $[@]'
6048                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6049                 ;;
6050         (dragonfly*|freebsd*)
6051                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
6052                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
6053                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
6054                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
6055                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6056                 fi
6057                 CF_SHARED_SONAME
6058                 MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
6059                 ;;
6060         (netbsd*)
6061                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
6062                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
6063                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
6064                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6065                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
6066                         if test "$cf_cv_shlib_version" = auto; then
6067                         if test -f /usr/libexec/ld.elf_so; then
6068                                 cf_cv_shlib_version=abi
6069                         else
6070                                 cf_cv_shlib_version=rel
6071                         fi
6072                         fi
6073                         CF_SHARED_SONAME
6074                         MK_SHARED_LIB='${CC} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
6075                 else
6076                         MK_SHARED_LIB='${CC} -Wl,-shared -Wl,-Bshareable -o $[@]'
6077                 fi
6078                 ;;
6079         (osf*|mls+*)
6080                 # tested with OSF/1 V3.2 and 'cc'
6081                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
6082                 # link with shared libs).
6083                 MK_SHARED_LIB='${LD} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
6084                 case $host_os in
6085                 (osf4*)
6086                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
6087                         ;;
6088                 esac
6089                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
6090                 if test "$DFT_LWR_MODEL" = "shared" ; then
6091                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
6092                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6093                 fi
6094                 cf_cv_rm_so_locs=yes
6095                 ;;
6096         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
6097                 # tested with osr5.0.5
6098                 if test "$GCC" != yes; then
6099                         CC_SHARED_OPTS='-belf -KPIC'
6100                 fi
6101                 MK_SHARED_LIB='${LD} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
6102                 if test "$cf_cv_enable_rpath" = yes ; then
6103                         # only way is to set LD_RUN_PATH but no switch for it
6104                         RUN_PATH=$libdir
6105                 fi
6106                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6107                 LINK_PROGS='LD_RUN_PATH=${libdir}'
6108                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
6109                 ;;
6110         (sunos4*)
6111                 # tested with SunOS 4.1.1 and gcc 2.7.0
6112                 if test "$GCC" != yes; then
6113                         CC_SHARED_OPTS='-KPIC'
6114                 fi
6115                 MK_SHARED_LIB='${LD} -assert pure-text -o $[@]'
6116                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
6117                 ;;
6118         (solaris2*)
6119                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
6120                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
6121                 if test "$DFT_LWR_MODEL" = "shared" ; then
6122                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
6123                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
6124                 fi
6125                 if test "$cf_cv_enable_rpath" = yes ; then
6126                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
6127                 fi
6128                 CF_SHARED_SONAME
6129                 if test "$GCC" != yes; then
6130                         cf_save_CFLAGS="$CFLAGS"
6131                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
6132                         do
6133                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
6134                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\n");],[break])
6135                         done
6136                         CFLAGS="$cf_save_CFLAGS"
6137                         CC_SHARED_OPTS=$cf_shared_opts
6138                         MK_SHARED_LIB='${CC} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
6139                 else
6140                         MK_SHARED_LIB='${CC} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
6141                 fi
6142                 ;;
6143         (sysv5uw7*|unix_sv*)
6144                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
6145                 if test "$GCC" != yes; then
6146                         CC_SHARED_OPTS='-KPIC'
6147                 fi
6148                 MK_SHARED_LIB='${LD} -d y -G -o [$]@'
6149                 ;;
6150         (*)
6151                 CC_SHARED_OPTS='unknown'
6152                 MK_SHARED_LIB='echo unknown'
6153                 ;;
6154         esac
6155
6156         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
6157         case "$cf_cv_shlib_version" in
6158         (rel|abi)
6159                 case "$MK_SHARED_LIB" in
6160                 (*'-o $[@]')
6161                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
6162                         ;;
6163                 (*)
6164                         AC_MSG_WARN(ignored --with-shlib-version)
6165                         ;;
6166                 esac
6167                 ;;
6168         esac
6169
6170         if test -n "$cf_try_cflags"
6171         then
6172 cat > conftest.$ac_ext <<EOF
6173 #line __oline__ "${as_me:-configure}"
6174 #include <stdio.h>
6175 int main(int argc, char *argv[[]])
6176 {
6177         printf("hello\n");
6178         return (argv[[argc-1]] == 0) ;
6179 }
6180 EOF
6181                 cf_save_CFLAGS="$CFLAGS"
6182                 for cf_opt in $cf_try_cflags
6183                 do
6184                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
6185                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
6186                         if AC_TRY_EVAL(ac_compile); then
6187                                 AC_MSG_RESULT(yes)
6188                                 cf_save_CFLAGS="$CFLAGS"
6189                         else
6190                                 AC_MSG_RESULT(no)
6191                         fi
6192                 done
6193                 CFLAGS="$cf_save_CFLAGS"
6194         fi
6195
6196
6197         # RPATH_LIST is a colon-separated list of directories
6198         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
6199         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
6200
6201         test $cf_cv_rm_so_locs = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
6202
6203         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
6204         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
6205
6206         AC_SUBST(CC_SHARED_OPTS)
6207         AC_SUBST(LD_RPATH_OPT)
6208         AC_SUBST(LD_SHARED_OPTS)
6209         AC_SUBST(MK_SHARED_LIB)
6210         AC_SUBST(RM_SHARED_OPTS)
6211
6212         AC_SUBST(LINK_PROGS)
6213         AC_SUBST(LINK_TESTS)
6214
6215         AC_SUBST(EXTRA_LDFLAGS)
6216         AC_SUBST(LOCAL_LDFLAGS)
6217         AC_SUBST(LOCAL_LDFLAGS2)
6218
6219         AC_SUBST(INSTALL_LIB)
6220         AC_SUBST(RPATH_LIST)
6221 ])dnl
6222 dnl ---------------------------------------------------------------------------
6223 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
6224 dnl ----------------
6225 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
6226 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
6227 dnl option.
6228 dnl
6229 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
6230 dnl If missing, use "rel".
6231 define([CF_SHARED_SONAME],
6232 [
6233         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
6234         if test "$cf_cv_shlib_version" = rel; then
6235                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
6236         else
6237                 cf_cv_shared_soname='`basename $[@]`'
6238         fi
6239 ])
6240 dnl ---------------------------------------------------------------------------
6241 dnl CF_SIGWINCH version: 1 updated: 2006/04/02 16:41:09
6242 dnl -----------
6243 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
6244 dnl programs need this test).
6245 dnl
6246 dnl This is really a MacOS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
6247 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
6248 dnl winsize declaration is left alone - we may revisit this if Apple choose to
6249 dnl break that part of the interface as well.
6250 AC_DEFUN([CF_SIGWINCH],
6251 [
6252 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
6253         AC_TRY_COMPILE([
6254 #include <sys/types.h>
6255 #include <sys/signal.h>
6256 ],[int x = SIGWINCH],
6257         [cf_cv_define_sigwinch=yes],
6258         [AC_TRY_COMPILE([
6259 #undef _XOPEN_SOURCE
6260 #undef _POSIX_SOURCE
6261 #undef _POSIX_C_SOURCE
6262 #include <sys/types.h>
6263 #include <sys/signal.h>
6264 ],[int x = SIGWINCH],
6265         [cf_cv_define_sigwinch=maybe],
6266         [cf_cv_define_sigwinch=no])
6267 ])
6268 ])
6269
6270 if test "$cf_cv_define_sigwinch" = maybe ; then
6271 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
6272 cf_cv_fixup_sigwinch=unknown
6273 cf_sigwinch=32
6274 while test $cf_sigwinch != 1
6275 do
6276         AC_TRY_COMPILE([
6277 #undef _XOPEN_SOURCE
6278 #undef _POSIX_SOURCE
6279 #undef _POSIX_C_SOURCE
6280 #include <sys/types.h>
6281 #include <sys/signal.h>
6282 ],[
6283 #if SIGWINCH != $cf_sigwinch
6284 make an error
6285 #endif
6286 int x = SIGWINCH],
6287         [cf_cv_fixup_sigwinch=$cf_sigwinch
6288          break])
6289
6290 cf_sigwinch=`expr $cf_sigwinch - 1`
6291 done
6292 ])
6293
6294         if test "$cf_cv_fixup_sigwinch" != unknown ; then
6295                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
6296         fi
6297 fi
6298 ])dnl
6299 dnl ---------------------------------------------------------------------------
6300 dnl CF_SIG_ATOMIC_T version: 3 updated: 2012/10/04 20:12:20
6301 dnl ---------------
6302 dnl signal handler, but there are some gcc depedencies in that recommendation.
6303 dnl Try anyway.
6304 AC_DEFUN([CF_SIG_ATOMIC_T],
6305 [
6306 AC_MSG_CHECKING(for signal global datatype)
6307 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
6308         for cf_type in \
6309                 "volatile sig_atomic_t" \
6310                 "sig_atomic_t" \
6311                 "int"
6312         do
6313         AC_TRY_COMPILE([
6314 #include <sys/types.h>
6315 #include <signal.h>
6316 #include <stdio.h>
6317
6318 extern $cf_type x;
6319 $cf_type x;
6320 static void handler(int sig)
6321 {
6322         x = 5;
6323 }],
6324                 [signal(SIGINT, handler);
6325                  x = 1],
6326                 [cf_cv_sig_atomic_t=$cf_type],
6327                 [cf_cv_sig_atomic_t=no])
6328                 test "$cf_cv_sig_atomic_t" != no && break
6329         done
6330         ])
6331 AC_MSG_RESULT($cf_cv_sig_atomic_t)
6332 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
6333 ])dnl
6334 dnl ---------------------------------------------------------------------------
6335 dnl CF_SIZECHANGE version: 11 updated: 2015/04/18 08:56:57
6336 dnl -------------
6337 dnl Check for definitions & structures needed for window size-changing
6338 dnl FIXME: check that this works with "snake" (HP-UX 10.x)
6339 AC_DEFUN([CF_SIZECHANGE],
6340 [
6341 AC_REQUIRE([CF_STRUCT_TERMIOS])
6342 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
6343         cf_cv_sizechange=unknown
6344         cf_save_CPPFLAGS="$CPPFLAGS"
6345
6346 for cf_opts in "" "NEED_PTEM_H"
6347 do
6348
6349         CPPFLAGS="$cf_save_CPPFLAGS"
6350         test -n "$cf_opts" && CPPFLAGS="$CPPFLAGS -D$cf_opts"
6351         AC_TRY_COMPILE([#include <sys/types.h>
6352 #ifdef HAVE_TERMIOS_H
6353 #include <termios.h>
6354 #else
6355 #ifdef HAVE_TERMIO_H
6356 #include <termio.h>
6357 #endif
6358 #endif
6359 #ifdef NEED_PTEM_H
6360 /* This is a workaround for SCO:  they neglected to define struct winsize in
6361  * termios.h -- it's only in termio.h and ptem.h
6362  */
6363 #include        <sys/stream.h>
6364 #include        <sys/ptem.h>
6365 #endif
6366 #if !defined(sun) || !defined(HAVE_TERMIOS_H)
6367 #include <sys/ioctl.h>
6368 #endif
6369 ],[
6370 #ifdef TIOCGSIZE
6371         struct ttysize win;     /* FIXME: what system is this? */
6372         int y = win.ts_lines;
6373         int x = win.ts_cols;
6374 #else
6375 #ifdef TIOCGWINSZ
6376         struct winsize win;
6377         int y = win.ws_row;
6378         int x = win.ws_col;
6379 #else
6380         no TIOCGSIZE or TIOCGWINSZ
6381 #endif /* TIOCGWINSZ */
6382 #endif /* TIOCGSIZE */
6383         ],
6384         [cf_cv_sizechange=yes],
6385         [cf_cv_sizechange=no])
6386
6387         CPPFLAGS="$cf_save_CPPFLAGS"
6388         if test "$cf_cv_sizechange" = yes ; then
6389                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
6390                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
6391                 break
6392         fi
6393 done
6394 ])
6395 if test "$cf_cv_sizechange" != no ; then
6396         AC_DEFINE(HAVE_SIZECHANGE,1,[Define to 1 if sizechar declarations are provided])
6397         case $cf_cv_sizechange in
6398         (NEED*)
6399                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
6400                 ;;
6401         esac
6402 fi
6403 ])dnl
6404 dnl ---------------------------------------------------------------------------
6405 dnl CF_SRC_MODULES version: 30 updated: 2017/07/26 17:08:35
6406 dnl --------------
6407 dnl For each parameter, test if the source-directory exists, and if it contains
6408 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
6409 dnl use in CF_LIB_RULES.
6410 dnl
6411 dnl This uses the configured value to make the lists SRC_SUBDIRS and
6412 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
6413 AC_DEFUN([CF_SRC_MODULES],
6414 [
6415 AC_MSG_CHECKING(for src modules)
6416
6417 # dependencies and linker-arguments for test-programs
6418 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
6419 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
6420 if test "$DFT_LWR_MODEL" = "libtool"; then
6421         TEST_ARGS="${TEST_DEPS}"
6422         TEST_ARG2="${TEST_DEP2}"
6423 else
6424         TEST_ARGS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
6425         TEST_ARG2="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARG2"
6426 fi
6427
6428 PC_MODULES_TO_MAKE="ncurses${USE_ARG_SUFFIX}"
6429 cf_cv_src_modules=
6430 for cf_dir in $1
6431 do
6432         if test -f $srcdir/$cf_dir/modules; then
6433
6434                 # We may/may not have tack in the distribution, though the
6435                 # makefile is.
6436                 if test $cf_dir = tack ; then
6437                         if test "x$cf_with_tack" != "xyes"; then
6438                                 continue
6439                         fi
6440                 fi
6441
6442                 if test -z "$cf_cv_src_modules"; then
6443                         cf_cv_src_modules=$cf_dir
6444                 else
6445                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
6446                 fi
6447
6448                 # Make the ncurses_cfg.h file record the library interface files as
6449                 # well.  These are header files that are the same name as their
6450                 # directory.  Ncurses is the only library that does not follow
6451                 # that pattern.
6452                 if test $cf_dir = tack ; then
6453                         continue
6454                 elif test -f $srcdir/${cf_dir}/${cf_dir}.h; then
6455                         CF_UPPER(cf_have_include,$cf_dir)
6456                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
6457                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
6458                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEPS"
6459                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${cf_dir}${DFT_DEP_SUFFIX} $TEST_DEP2"
6460                         if test "$DFT_LWR_MODEL" = "libtool"; then
6461                                 TEST_ARGS="${TEST_DEPS}"
6462                                 TEST_ARG2="${TEST_DEP2}"
6463                         else
6464                                 TEST_ARGS="-l${cf_dir}${USE_ARG_SUFFIX} $TEST_ARGS"
6465                                 TEST_ARG2="-l${cf_dir}${USE_ARG_SUFFIX} $TEST_ARG2"
6466                         fi
6467                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${USE_ARG_SUFFIX}"
6468                 fi
6469         fi
6470 done
6471 AC_MSG_RESULT($cf_cv_src_modules)
6472
6473 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
6474 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
6475
6476 AC_SUBST(TEST_ARGS)
6477 AC_SUBST(TEST_DEPS)
6478
6479 AC_SUBST(TEST_ARG2)
6480 AC_SUBST(TEST_DEP2)
6481
6482 SRC_SUBDIRS=
6483 if test "x$cf_with_manpages" != xno ; then
6484         SRC_SUBDIRS="$SRC_SUBDIRS man"
6485 fi
6486 SRC_SUBDIRS="$SRC_SUBDIRS include"
6487 for cf_dir in $cf_cv_src_modules
6488 do
6489         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
6490 done
6491 if test "x$cf_with_tests" != "xno" ; then
6492         SRC_SUBDIRS="$SRC_SUBDIRS test"
6493 fi
6494 # always make this, to install the ncurses-config script
6495 SRC_SUBDIRS="$SRC_SUBDIRS misc"
6496 if test "$cf_with_cxx_binding" != no; then
6497         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${USE_ARG_SUFFIX}"
6498         SRC_SUBDIRS="$SRC_SUBDIRS c++"
6499 fi
6500
6501 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
6502 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
6503
6504 AC_SUBST(PC_MODULES_TO_MAKE)
6505
6506 ADA_SUBDIRS=
6507 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f $srcdir/Ada95/Makefile.in; then
6508         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
6509         ADA_SUBDIRS="gen src"
6510         if test "x$cf_with_tests" != "xno" ; then
6511                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
6512         fi
6513 fi
6514
6515 SUB_MAKEFILES=
6516 for cf_dir in $SRC_SUBDIRS
6517 do
6518         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
6519 done
6520
6521 if test -n "$ADA_SUBDIRS"; then
6522         for cf_dir in $ADA_SUBDIRS
6523         do
6524                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
6525         done
6526         AC_SUBST(ADA_SUBDIRS)
6527 fi
6528 ])dnl
6529 dnl ---------------------------------------------------------------------------
6530 dnl CF_STDCPP_LIBRARY version: 11 updated: 2015/10/17 19:03:33
6531 dnl -----------------
6532 dnl Check for -lstdc++, which is GNU's standard C++ library.
6533 dnl If $CXXLIBS is set, add that to the libraries used for test-linking.
6534 dnl If -lstdc++ was not already added to $LIBS or $CXXLIBS, and is needed,
6535 dnl add it to $CXXLIBS.
6536 AC_DEFUN([CF_STDCPP_LIBRARY],
6537 [
6538 if test -n "$GXX" ; then
6539
6540         cf_save="$LIBS"
6541         LIBS="$LIBS $CXXLIBS"
6542         AC_MSG_CHECKING(if we already have C++ library)
6543         AC_TRY_LINK([
6544                         #include <iostream>],[
6545                         std::cout << "Hello World!" << std::endl;],
6546                 [cf_have_libstdcpp=yes],
6547                 [cf_have_libstdcpp=no])
6548         AC_MSG_RESULT($cf_have_libstdcpp)
6549         LIBS="$cf_save"
6550
6551         if test $cf_have_libstdcpp != yes
6552         then
6553                 case $cf_cv_system_name in
6554                 (os2*)
6555                         if test -z "`g++ -dM -E - < /dev/null | grep __KLIBC__`"; then
6556                                 cf_stdcpp_libname=stdcpp
6557                         else
6558                                 cf_stdcpp_libname=stdc++
6559                         fi
6560                         ;;
6561                 (*)
6562                         cf_stdcpp_libname=stdc++
6563                         ;;
6564                 esac
6565
6566                 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
6567                         cf_save="$LIBS"
6568                         LIBS="$LIBS $CXXLIBS"
6569                         CF_ADD_LIB($cf_stdcpp_libname)
6570                 AC_TRY_LINK([
6571                                 #include <iostream>],[
6572                                 std::cout << "Hello World!" << std::endl;],
6573                         [cf_cv_libstdcpp=yes],
6574                         [cf_cv_libstdcpp=no])
6575                         LIBS="$cf_save"
6576                 ])
6577                 test "$cf_cv_libstdcpp" = yes && { CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS) }
6578         fi
6579 fi
6580 ])dnl
6581 dnl ---------------------------------------------------------------------------
6582 dnl CF_STRIP_G_OPT version: 3 updated: 2002/12/21 19:25:52
6583 dnl --------------
6584 dnl     Remove "-g" option from the compiler options
6585 AC_DEFUN([CF_STRIP_G_OPT],
6586 [$1=`echo ${$1} | sed -e 's%-g %%' -e 's%-g$%%'`])dnl
6587 dnl ---------------------------------------------------------------------------
6588 dnl CF_STRUCT_SIGACTION version: 5 updated: 2012/10/06 17:56:13
6589 dnl -------------------
6590 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
6591 dnl do this if we've found the sigaction function.
6592 AC_DEFUN([CF_STRUCT_SIGACTION],[
6593 AC_REQUIRE([CF_XOPEN_SOURCE])
6594
6595 if test "$ac_cv_func_sigaction" = yes; then
6596 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
6597 AC_TRY_COMPILE([
6598 #include <sys/types.h>
6599 #include <signal.h>],
6600         [struct sigaction act],
6601         [sigact_bad=no],
6602         [
6603 AC_TRY_COMPILE([
6604 #define _POSIX_SOURCE
6605 #include <sys/types.h>
6606 #include <signal.h>],
6607         [struct sigaction act],
6608         [sigact_bad=yes
6609          AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE])],
6610          [sigact_bad=unknown])])
6611 AC_MSG_RESULT($sigact_bad)
6612 fi
6613 ])dnl
6614 dnl ---------------------------------------------------------------------------
6615 dnl CF_STRUCT_TERMIOS version: 8 updated: 2015/04/15 19:08:48
6616 dnl -----------------
6617 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
6618 AC_DEFUN([CF_STRUCT_TERMIOS],[
6619 AC_REQUIRE([CF_XOPEN_SOURCE])
6620
6621 AC_CHECK_HEADERS( \
6622 termio.h \
6623 termios.h \
6624 unistd.h \
6625 )
6626
6627 if test "$ISC" = yes ; then
6628         AC_CHECK_HEADERS( sys/termio.h )
6629 fi
6630 if test "$ac_cv_header_termios_h" = yes ; then
6631         case "$CFLAGS $CPPFLAGS" in
6632         (*-D_POSIX_SOURCE*)
6633                 termios_bad=dunno ;;
6634         (*)     termios_bad=maybe ;;
6635         esac
6636         if test "$termios_bad" = maybe ; then
6637         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
6638         AC_TRY_COMPILE([#include <termios.h>],
6639                 [struct termios foo; int x = foo.c_iflag],
6640                 termios_bad=no, [
6641                 AC_TRY_COMPILE([
6642 #define _POSIX_SOURCE
6643 #include <termios.h>],
6644                         [struct termios foo; int x = foo.c_iflag],
6645                         termios_bad=unknown,
6646                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE]))
6647                         ])
6648         AC_MSG_RESULT($termios_bad)
6649         fi
6650 fi
6651 ])dnl
6652 dnl ---------------------------------------------------------------------------
6653 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
6654 dnl --------------
6655 dnl Construct a search-list for a nonstandard header/lib-file
6656 dnl     $1 = the variable to return as result
6657 dnl     $2 = the package name
6658 dnl     $3 = the subdirectory, e.g., bin, include or lib
6659 AC_DEFUN([CF_SUBDIR_PATH],
6660 [
6661 $1=
6662
6663 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
6664
6665 for cf_subdir_prefix in \
6666         /usr \
6667         /usr/local \
6668         /usr/pkg \
6669         /opt \
6670         /opt/local \
6671         [$]HOME
6672 do
6673         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
6674 done
6675 ])dnl
6676 dnl ---------------------------------------------------------------------------
6677 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
6678 dnl -----------
6679 dnl     Shorthand macro for substituting things that the user may override
6680 dnl     with an environment variable.
6681 dnl
6682 dnl     $1 = condition to pass to "test"
6683 dnl     $2 = environment variable
6684 dnl     $3 = value if the test succeeds
6685 dnl     $4 = value if the test fails
6686 AC_DEFUN([CF_SUBST_IF],
6687 [
6688 if test $1 ; then
6689         $2=$3
6690 ifelse($4,,,[else
6691         $2=$4])
6692 fi
6693 AC_SUBST($2)
6694 ])dnl
6695 dnl ---------------------------------------------------------------------------
6696 dnl CF_SUBST_NCURSES_VERSION version: 8 updated: 2006/09/16 11:40:59
6697 dnl ------------------------
6698 dnl Get the version-number for use in shared-library naming, etc.
6699 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
6700 [
6701 AC_REQUIRE([CF_PROG_EGREP])
6702 NCURSES_MAJOR="`$ac_cv_prog_egrep '^NCURSES_MAJOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6703 NCURSES_MINOR="`$ac_cv_prog_egrep '^NCURSES_MINOR[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6704 NCURSES_PATCH="`$ac_cv_prog_egrep '^NCURSES_PATCH[[     ]]*=' $srcdir/dist.mk | sed -e 's/^[[^0-9]]*//'`"
6705 cf_cv_abi_version=${NCURSES_MAJOR}
6706 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
6707 dnl Show the computed version, for logging
6708 cf_cv_timestamp=`date`
6709 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
6710 dnl We need these values in the generated headers
6711 AC_SUBST(NCURSES_MAJOR)
6712 AC_SUBST(NCURSES_MINOR)
6713 AC_SUBST(NCURSES_PATCH)
6714 dnl We need these values in the generated makefiles
6715 AC_SUBST(cf_cv_rel_version)
6716 AC_SUBST(cf_cv_abi_version)
6717 AC_SUBST(cf_cv_builtin_bool)
6718 AC_SUBST(cf_cv_header_stdbool_h)
6719 AC_SUBST(cf_cv_type_of_bool)dnl
6720 ])dnl
6721 dnl ---------------------------------------------------------------------------
6722 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
6723 dnl ------------------
6724 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
6725 dnl older SCO configurations.
6726 AC_DEFUN([CF_SYS_TIME_SELECT],
6727 [
6728 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
6729 AC_CACHE_VAL(cf_cv_sys_time_select,[
6730 AC_TRY_COMPILE([
6731 #include <sys/types.h>
6732 #ifdef HAVE_SYS_TIME_H
6733 #include <sys/time.h>
6734 #endif
6735 #ifdef HAVE_SYS_SELECT_H
6736 #include <sys/select.h>
6737 #endif
6738 ],[],[cf_cv_sys_time_select=yes],
6739          [cf_cv_sys_time_select=no])
6740          ])
6741 AC_MSG_RESULT($cf_cv_sys_time_select)
6742 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
6743 ])dnl
6744 dnl ---------------------------------------------------------------------------
6745 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
6746 dnl ---------------
6747 dnl Define a top_builddir symbol, for applications that need an absolute path.
6748 AC_DEFUN([CF_TOP_BUILDDIR],
6749 [
6750 top_builddir=ifelse($1,,`pwd`,$1)
6751 AC_SUBST(top_builddir)
6752 ])dnl
6753 dnl ---------------------------------------------------------------------------
6754 dnl CF_TRY_XOPEN_SOURCE version: 1 updated: 2011/10/30 17:09:50
6755 dnl -------------------
6756 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
6757 dnl can define it successfully.
6758 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
6759 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
6760         AC_TRY_COMPILE([
6761 #include <stdlib.h>
6762 #include <string.h>
6763 #include <sys/types.h>
6764 ],[
6765 #ifndef _XOPEN_SOURCE
6766 make an error
6767 #endif],
6768         [cf_cv_xopen_source=no],
6769         [cf_save="$CPPFLAGS"
6770          CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
6771          AC_TRY_COMPILE([
6772 #include <stdlib.h>
6773 #include <string.h>
6774 #include <sys/types.h>
6775 ],[
6776 #ifdef _XOPEN_SOURCE
6777 make an error
6778 #endif],
6779         [cf_cv_xopen_source=no],
6780         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
6781         CPPFLAGS="$cf_save"
6782         ])
6783 ])
6784
6785 if test "$cf_cv_xopen_source" != no ; then
6786         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
6787         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
6788         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
6789         CF_ADD_CFLAGS($cf_temp_xopen_source)
6790 fi
6791 ])
6792 dnl ---------------------------------------------------------------------------
6793 dnl CF_TYPEOF_CHTYPE version: 10 updated: 2017/01/21 11:06:25
6794 dnl ----------------
6795 dnl Determine the type we should use for chtype (and attr_t, which is treated
6796 dnl as the same thing).  We want around 32 bits, so on most machines want a
6797 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
6798 dnl wide characters, we have to have a type compatible with that, as well.
6799 AC_DEFUN([CF_TYPEOF_CHTYPE],
6800 [
6801 AC_MSG_CHECKING([for type of chtype])
6802 AC_CACHE_VAL(cf_cv_typeof_chtype,[
6803                 AC_TRY_RUN([
6804 #define WANT_BITS 31
6805 #include <stdio.h>
6806 int main(void)
6807 {
6808         FILE *fp = fopen("cf_test.out", "w");
6809         if (fp != 0) {
6810                 char *result = "long";
6811                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
6812                         int n;
6813                         unsigned int x, y;
6814                         for (n = 0; n < WANT_BITS; n++) {
6815                                 x = (1 << n);
6816                                 y = (x >> n);
6817                                 if (y != 1 || x == 0) {
6818                                         x = 0;
6819                                         break;
6820                                 }
6821                         }
6822                         /*
6823                          * If x is nonzero, an int is big enough for the bits
6824                          * that we want.
6825                          */
6826                         result = (x != 0) ? "int" : "long";
6827                 }
6828                 fputs(result, fp);
6829                 fclose(fp);
6830         }
6831         ${cf_cv_main_return:-return}(0);
6832 }
6833                 ],
6834                 [cf_cv_typeof_chtype=`cat cf_test.out`],
6835                 [cf_cv_typeof_chtype=long],
6836                 [cf_cv_typeof_chtype=long])
6837                 rm -f cf_test.out
6838         ])
6839 AC_MSG_RESULT($cf_cv_typeof_chtype)
6840
6841 AC_SUBST(cf_cv_typeof_chtype)
6842 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype,[Define to actual type if needed for chtype])
6843 ])dnl
6844 dnl ---------------------------------------------------------------------------
6845 dnl CF_TYPE_SIGACTION version: 4 updated: 2012/10/06 17:56:13
6846 dnl -----------------
6847 dnl
6848 AC_DEFUN([CF_TYPE_SIGACTION],
6849 [
6850 AC_MSG_CHECKING([for type sigaction_t])
6851 AC_CACHE_VAL(cf_cv_type_sigaction,[
6852         AC_TRY_COMPILE([
6853 #include <signal.h>],
6854                 [sigaction_t x],
6855                 [cf_cv_type_sigaction=yes],
6856                 [cf_cv_type_sigaction=no])])
6857 AC_MSG_RESULT($cf_cv_type_sigaction)
6858 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION,1,[Define to 1 if we have the sigaction_t type])
6859 ])dnl
6860 dnl ---------------------------------------------------------------------------
6861 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
6862 dnl --------------------
6863 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
6864 dnl won't, but they're still there.
6865 AC_DEFUN([CF_UNSIGNED_LITERALS],
6866 [
6867 AC_MSG_CHECKING([if unsigned literals are legal])
6868 AC_CACHE_VAL(cf_cv_unsigned_literals,[
6869         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
6870                 [cf_cv_unsigned_literals=yes],
6871                 [cf_cv_unsigned_literals=no])
6872         ])
6873 AC_MSG_RESULT($cf_cv_unsigned_literals)
6874 ])dnl
6875 dnl ---------------------------------------------------------------------------
6876 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
6877 dnl --------
6878 dnl Make an uppercase version of a variable
6879 dnl $1=uppercase($2)
6880 AC_DEFUN([CF_UPPER],
6881 [
6882 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
6883 ])dnl
6884 dnl ---------------------------------------------------------------------------
6885 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
6886 dnl -----------
6887 dnl Check for multibyte support, and if not found, utf8 compatibility library
6888 AC_DEFUN([CF_UTF8_LIB],
6889 [
6890 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
6891         cf_save_LIBS="$LIBS"
6892         AC_TRY_LINK([
6893 #include <stdlib.h>],[putwc(0,0);],
6894         [cf_cv_utf8_lib=yes],
6895         [CF_FIND_LINKAGE([
6896 #include <libutf8.h>],[putwc(0,0);],utf8,
6897                 [cf_cv_utf8_lib=add-on],
6898                 [cf_cv_utf8_lib=no])
6899 ])])
6900
6901 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
6902 # ncurses/ncursesw:
6903 if test "$cf_cv_utf8_lib" = "add-on" ; then
6904         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
6905         CF_ADD_INCDIR($cf_cv_header_path_utf8)
6906         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
6907         CF_ADD_LIBS($cf_cv_library_file_utf8)
6908 fi
6909 ])dnl
6910 dnl ---------------------------------------------------------------------------
6911 dnl CF_VA_COPY version: 3 updated: 2012/10/06 11:17:15
6912 dnl ----------
6913 dnl check for va_copy, part of stdarg.h
6914 dnl Also, workaround for glibc's __va_copy, by checking for both.
6915 AC_DEFUN([CF_VA_COPY],[
6916 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
6917 AC_TRY_LINK([
6918 #include <stdarg.h>
6919 ],[
6920         static va_list dst;
6921         static va_list src;
6922         va_copy(dst, src)],
6923         cf_cv_have_va_copy=yes,
6924         cf_cv_have_va_copy=no)])
6925
6926 test "$cf_cv_have_va_copy" = yes && AC_DEFINE(HAVE_VA_COPY,1,[Define to 1 if we have va_copy])
6927
6928 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
6929 AC_TRY_LINK([
6930 #include <stdarg.h>
6931 ],[
6932         static va_list dst;
6933         static va_list src;
6934         __va_copy(dst, src)],
6935         cf_cv_have___va_copy=yes,
6936         cf_cv_have___va_copy=no)])
6937
6938 test "$cf_cv_have___va_copy" = yes && AC_DEFINE(HAVE___VA_COPY,1,[Define to 1 if we have __va_copy])
6939 ])
6940 dnl ---------------------------------------------------------------------------
6941 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
6942 dnl ----------
6943 dnl Use AC_VERBOSE w/o the warnings
6944 AC_DEFUN([CF_VERBOSE],
6945 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
6946 CF_MSG_LOG([$1])
6947 ])dnl
6948 dnl ---------------------------------------------------------------------------
6949 dnl CF_VERSION_INFO version: 7 updated: 2015/04/17 21:13:04
6950 dnl ---------------
6951 dnl Define several useful symbols derived from the VERSION file.  A separate
6952 dnl file is preferred to embedding the version numbers in various scripts.
6953 dnl (automake is a textbook-example of why the latter is a bad idea, but there
6954 dnl are others).
6955 dnl
6956 dnl The file contents are:
6957 dnl     libtool-version release-version patch-version
6958 dnl or
6959 dnl     release-version
6960 dnl where
6961 dnl     libtool-version (see ?) consists of 3 integers separated by '.'
6962 dnl     release-version consists of a major version and minor version
6963 dnl             separated by '.', optionally followed by a patch-version
6964 dnl             separated by '-'.  The minor version need not be an
6965 dnl             integer (but it is preferred).
6966 dnl     patch-version is an integer in the form yyyymmdd, so ifdef's and
6967 dnl             scripts can easily compare versions.
6968 dnl
6969 dnl If libtool is used, the first form is required, since CF_WITH_LIBTOOL
6970 dnl simply extracts the first field using 'cut -f1'.
6971 dnl
6972 dnl Optional parameters:
6973 dnl $1 = internal name for package
6974 dnl $2 = external name for package
6975 AC_DEFUN([CF_VERSION_INFO],
6976 [
6977 if test -f $srcdir/VERSION ; then
6978         AC_MSG_CHECKING(for package version)
6979
6980         # if there are not enough fields, cut returns the last one...
6981         cf_field1=`sed -e '2,$d' $srcdir/VERSION|cut -f1`
6982         cf_field2=`sed -e '2,$d' $srcdir/VERSION|cut -f2`
6983         cf_field3=`sed -e '2,$d' $srcdir/VERSION|cut -f3`
6984
6985         # this is how CF_BUNDLED_INTL uses $VERSION:
6986         VERSION="$cf_field1"
6987
6988         VERSION_MAJOR=`echo "$cf_field2" | sed -e 's/\..*//'`
6989         test -z "$VERSION_MAJOR" && AC_MSG_ERROR(missing major-version)
6990
6991         VERSION_MINOR=`echo "$cf_field2" | sed -e 's/^[[^.]]*\.//' -e 's/-.*//'`
6992         test -z "$VERSION_MINOR" && AC_MSG_ERROR(missing minor-version)
6993
6994         AC_MSG_RESULT(${VERSION_MAJOR}.${VERSION_MINOR})
6995
6996         AC_MSG_CHECKING(for package patch date)
6997         VERSION_PATCH=`echo "$cf_field3" | sed -e 's/^[[^-]]*-//'`
6998         case .$VERSION_PATCH in
6999         (.)
7000                 AC_MSG_ERROR(missing patch-date $VERSION_PATCH)
7001                 ;;
7002         (.[[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]])
7003                 ;;
7004         (*)
7005                 AC_MSG_ERROR(illegal patch-date $VERSION_PATCH)
7006                 ;;
7007         esac
7008         AC_MSG_RESULT($VERSION_PATCH)
7009 else
7010         AC_MSG_ERROR(did not find $srcdir/VERSION)
7011 fi
7012
7013 # show the actual data that we have for versions:
7014 CF_VERBOSE(ABI VERSION $VERSION)
7015 CF_VERBOSE(VERSION_MAJOR $VERSION_MAJOR)
7016 CF_VERBOSE(VERSION_MINOR $VERSION_MINOR)
7017 CF_VERBOSE(VERSION_PATCH $VERSION_PATCH)
7018
7019 AC_SUBST(VERSION)
7020 AC_SUBST(VERSION_MAJOR)
7021 AC_SUBST(VERSION_MINOR)
7022 AC_SUBST(VERSION_PATCH)
7023
7024 dnl if a package name is given, define its corresponding version info.  We
7025 dnl need the package name to ensure that the defined symbols are unique.
7026 ifelse($1,,,[
7027         cf_PACKAGE=$1
7028         PACKAGE=ifelse($2,,$1,$2)
7029         AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",[Define to the package-name])
7030         AC_SUBST(PACKAGE)
7031         CF_UPPER(cf_PACKAGE,$cf_PACKAGE)
7032         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_VERSION,"${VERSION_MAJOR}.${VERSION_MINOR}")
7033         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_PATCHDATE,${VERSION_PATCH})
7034 ])
7035 ])dnl
7036 dnl ---------------------------------------------------------------------------
7037 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
7038 dnl -------------
7039 dnl Check if type wide-character type $1 is declared, and if so, which header
7040 dnl file is needed.  The second parameter is used to set a shell variable when
7041 dnl the type is not found.  The first parameter sets a shell variable for the
7042 dnl opposite sense.
7043 AC_DEFUN([CF_WCHAR_TYPE],
7044 [
7045 # This is needed on Tru64 5.0 to declare $1
7046 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
7047 AC_TRY_COMPILE([
7048 #include <stdlib.h>
7049 #include <stdarg.h>
7050 #include <stdio.h>
7051 #ifdef HAVE_LIBUTF8_H
7052 #include <libutf8.h>
7053 #endif],
7054         [$1 state],
7055         [cf_cv_$1=no],
7056         [AC_TRY_COMPILE([
7057 #include <stdlib.h>
7058 #include <stdarg.h>
7059 #include <stdio.h>
7060 #include <wchar.h>
7061 #ifdef HAVE_LIBUTF8_H
7062 #include <libutf8.h>
7063 #endif],
7064         [$1 value],
7065         [cf_cv_$1=yes],
7066         [cf_cv_$1=unknown])])])
7067
7068 if test "$cf_cv_$1" = yes ; then
7069         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
7070         NEED_WCHAR_H=1
7071 fi
7072
7073 ifelse([$2],,,[
7074 # if we do not find $1 in either place, use substitution to provide a fallback.
7075 if test "$cf_cv_$1" = unknown ; then
7076         $2=1
7077 fi
7078 ])
7079 ifelse($3,,,[
7080 # if we find $1 in either place, use substitution to provide a fallback.
7081 if test "$cf_cv_$1" != unknown ; then
7082         $3=1
7083 fi
7084 ])
7085 ])dnl
7086 dnl ---------------------------------------------------------------------------
7087 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
7088 dnl ---------------
7089 dnl Check for compiler-support for weak symbols.
7090 dnl This works with "recent" gcc.
7091 AC_DEFUN([CF_WEAK_SYMBOLS],[
7092 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
7093
7094 AC_TRY_COMPILE([
7095 #include <stdio.h>],
7096 [
7097 #if defined(__GNUC__)
7098 #  if defined __USE_ISOC99
7099 #    define _cat_pragma(exp)    _Pragma(#exp)
7100 #    define _weak_pragma(exp)   _cat_pragma(weak name)
7101 #  else
7102 #    define _weak_pragma(exp)
7103 #  endif
7104 #  define _declare(name)        __extension__ extern __typeof__(name) name
7105 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
7106 #endif
7107
7108 weak_symbol(fopen);
7109 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
7110 ])
7111 ])dnl
7112 dnl ---------------------------------------------------------------------------
7113 dnl CF_WITH_ABI_VERSION version: 3 updated: 2015/06/06 16:10:11
7114 dnl -------------------
7115 dnl Allow library's ABI to be overridden.  Generally this happens when a
7116 dnl packager has incremented the ABI past that used in the original package,
7117 dnl and wishes to keep doing this.
7118 dnl
7119 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
7120 dnl symbol.
7121 AC_DEFUN([CF_WITH_ABI_VERSION],[
7122 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
7123 AC_ARG_WITH(abi-version,
7124 [  --with-abi-version=XXX  override derived ABI version],[
7125         if test "x$cf_cv_abi_version" != "x$withval"
7126         then
7127                 AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
7128                 case $cf_cv_rel_version in
7129                 (5.*)
7130                         cf_cv_rel_version=$withval.0
7131                         ;;
7132                 (6.*)
7133                         cf_cv_rel_version=$withval.9    # FIXME: should be 10 as of 6.0 release
7134                         ;;
7135                 esac
7136         fi
7137         cf_cv_abi_version=$withval])
7138         CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
7139 ifelse($1,,,[
7140 $1_ABI=$cf_cv_abi_version
7141 ])
7142 ])dnl
7143 dnl ---------------------------------------------------------------------------
7144 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
7145 dnl --------------------
7146 dnl Command-line option to specify the Ada95 compiler.
7147 AC_DEFUN([CF_WITH_ADA_COMPILER],[
7148 AC_MSG_CHECKING(for ada-compiler)
7149 AC_ARG_WITH(ada-compiler,
7150         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
7151         [cf_ada_compiler=$withval],
7152         [cf_ada_compiler=gnatmake])
7153 AC_SUBST(cf_ada_compiler)
7154 AC_MSG_RESULT($cf_ada_compiler)
7155 ])dnl
7156 dnl ---------------------------------------------------------------------------
7157 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
7158 dnl -------------------
7159 dnl Command-line option to specify where Ada includes will install.
7160 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
7161 AC_MSG_CHECKING(for ada-include)
7162 CF_WITH_PATH(ada-include,
7163    [  --with-ada-include=DIR  Ada includes are in DIR],
7164    ADA_INCLUDE,
7165    PREFIX/share/ada/adainclude,
7166    [$]prefix/share/ada/adainclude)
7167 AC_SUBST(ADA_INCLUDE)
7168 AC_MSG_RESULT($ADA_INCLUDE)
7169 ])dnl
7170 dnl ---------------------------------------------------------------------------
7171 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
7172 dnl -------------------
7173 dnl Command-line option to specify where Ada objects will install.
7174 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
7175 AC_MSG_CHECKING(for ada-objects)
7176 CF_WITH_PATH(ada-objects,
7177    [  --with-ada-objects=DIR  Ada objects are in DIR],
7178    ADA_OBJECTS,
7179    PREFIX/lib/ada/adalib,
7180    [$]prefix/lib/ada/adalib)
7181 AC_SUBST(ADA_OBJECTS)
7182 AC_MSG_RESULT($ADA_OBJECTS)
7183 ])dnl
7184 dnl ---------------------------------------------------------------------------
7185 dnl CF_WITH_ADA_SHAREDLIB version: 4 updated: 2014/05/31 21:08:37
7186 dnl ---------------------
7187 dnl Command-line option to specify if an Ada95 shared-library should be built,
7188 dnl and optionally what its soname should be.
7189 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
7190 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
7191 AC_ARG_WITH(ada-sharedlib,
7192         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
7193         [with_ada_sharedlib=$withval],
7194         [with_ada_sharedlib=no])
7195 AC_MSG_RESULT($with_ada_sharedlib)
7196
7197 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
7198 MAKE_ADA_SHAREDLIB="#"
7199
7200 if test "x$with_ada_sharedlib" != xno
7201 then
7202         MAKE_ADA_SHAREDLIB=
7203         if test "x$with_ada_sharedlib" != xyes
7204         then
7205                 ADA_SHAREDLIB="$with_ada_sharedlib"
7206         fi
7207 fi
7208
7209 AC_SUBST(ADA_SHAREDLIB)
7210 AC_SUBST(MAKE_ADA_SHAREDLIB)
7211 ])dnl
7212 dnl ---------------------------------------------------------------------------
7213 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
7214 dnl ----------------
7215 dnl Configure-option for dbmalloc.  The optional parameter is used to override
7216 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
7217 AC_DEFUN([CF_WITH_DBMALLOC],[
7218 CF_NO_LEAKS_OPTION(dbmalloc,
7219         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
7220         [USE_DBMALLOC])
7221
7222 if test "$with_dbmalloc" = yes ; then
7223         AC_CHECK_HEADER(dbmalloc.h,
7224                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
7225 fi
7226 ])dnl
7227 dnl ---------------------------------------------------------------------------
7228 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
7229 dnl ---------------
7230 dnl Configure-option for dmalloc.  The optional parameter is used to override
7231 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
7232 AC_DEFUN([CF_WITH_DMALLOC],[
7233 CF_NO_LEAKS_OPTION(dmalloc,
7234         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
7235         [USE_DMALLOC])
7236
7237 if test "$with_dmalloc" = yes ; then
7238         AC_CHECK_HEADER(dmalloc.h,
7239                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
7240 fi
7241 ])dnl
7242 dnl ---------------------------------------------------------------------------
7243 dnl CF_WITH_EXPORT_SYMS version: 3 updated: 2014/12/20 19:16:08
7244 dnl -------------------
7245 dnl Use this with libtool to specify the list of symbols that may be exported.
7246 dnl The input file contains one symbol per line; comments work with "#".
7247 dnl
7248 dnl $1 = basename of the ".sym" file (default $PACKAGE)
7249 AC_DEFUN([CF_WITH_EXPORT_SYMS],
7250 [
7251 AC_MSG_CHECKING(if exported-symbols file should be used)
7252 AC_ARG_WITH(export-syms,
7253         [  --with-export-syms=XXX  limit exported symbols using libtool],
7254         [with_export_syms=$withval],
7255         [with_export_syms=no])
7256 if test "x$with_export_syms" = xyes
7257 then
7258         with_export_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).sym'
7259         AC_SUBST(PACKAGE)
7260 fi
7261 AC_MSG_RESULT($with_export_syms)
7262 if test "x$with_export_syms" != xno
7263 then
7264         EXPORT_SYMS="-export-symbols $with_export_syms"
7265         AC_SUBST(EXPORT_SYMS)
7266 fi
7267 ])dnl
7268 dnl ---------------------------------------------------------------------------
7269 dnl CF_WITH_GPM version: 10 updated: 2017/04/29 18:32:18
7270 dnl -----------
7271 dnl
7272 dnl The option parameter (if neither yes/no) is assumed to be the name of
7273 dnl the gpm library, e.g., for dynamic loading.
7274 AC_DEFUN([CF_WITH_GPM],
7275 [
7276 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
7277 AC_ARG_WITH(gpm,
7278         [  --with-gpm              use Alessandro Rubini's GPM library],
7279         [with_gpm=$withval],
7280         [with_gpm=maybe])
7281 AC_MSG_RESULT($with_gpm)
7282
7283 if test "$with_gpm" != no ; then
7284         AC_CHECK_HEADER(gpm.h,[
7285                 AC_DEFINE(HAVE_GPM_H,1,[Define to 1 if we have gpm.h header])
7286                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
7287                         CF_VERBOSE(assuming we really have GPM library)
7288                         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
7289                         with_gpm=yes
7290                 else
7291                         AC_CHECK_LIB(gpm,Gpm_Open,[with_gpm=yes],[
7292                                 if test "$with_gpm" = maybe; then
7293                                         AC_MSG_WARN(Cannot link with GPM library)
7294                                         with_gpm=no
7295                                 else
7296                                         AC_MSG_ERROR(Cannot link with GPM library)
7297                                 fi
7298                         ])
7299                 fi
7300         ],[
7301                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
7302                 with_gpm=no
7303         ])
7304 fi
7305 ])
7306 dnl ---------------------------------------------------------------------------
7307 dnl CF_WITH_LIBTOOL version: 35 updated: 2017/08/12 07:58:51
7308 dnl ---------------
7309 dnl Provide a configure option to incorporate libtool.  Define several useful
7310 dnl symbols for the makefile rules.
7311 dnl
7312 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
7313 dnl macros from libtool.m4 which is in the aclocal directory of automake.
7314 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
7315 dnl But that still does not work properly since the macro is expanded outside
7316 dnl the CF_WITH_LIBTOOL macro:
7317 dnl
7318 dnl     #!/bin/sh
7319 dnl     ACLOCAL=`aclocal --print-ac-dir`
7320 dnl     if test -z "$ACLOCAL" ; then
7321 dnl             echo cannot find aclocal directory
7322 dnl             exit 1
7323 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
7324 dnl             echo cannot find libtool.m4 file
7325 dnl             exit 1
7326 dnl     fi
7327 dnl
7328 dnl     LOCAL=aclocal.m4
7329 dnl     ORIG=aclocal.m4.orig
7330 dnl
7331 dnl     trap "mv $ORIG $LOCAL" 0 1 2 3 15
7332 dnl     rm -f $ORIG
7333 dnl     mv $LOCAL $ORIG
7334 dnl
7335 dnl     # sed the LIBTOOL= assignment to omit the current directory?
7336 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
7337 dnl     cat $ORIG >>$LOCAL
7338 dnl
7339 dnl     autoconf-257 $*
7340 dnl
7341 AC_DEFUN([CF_WITH_LIBTOOL],
7342 [
7343 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
7344 ifdef([AC_PROG_LIBTOOL],,[
7345 LIBTOOL=
7346 ])
7347 # common library maintenance symbols that are convenient for libtool scripts:
7348 LIB_CREATE='${AR} -cr'
7349 LIB_OBJECT='${OBJECTS}'
7350 LIB_SUFFIX=.a
7351 LIB_PREP="$RANLIB"
7352
7353 # symbols used to prop libtool up to enable it to determine what it should be
7354 # doing:
7355 LIB_CLEAN=
7356 LIB_COMPILE=
7357 LIB_LINK='${CC}'
7358 LIB_INSTALL=
7359 LIB_UNINSTALL=
7360
7361 AC_MSG_CHECKING(if you want to build libraries with libtool)
7362 AC_ARG_WITH(libtool,
7363         [  --with-libtool          generate libraries with libtool],
7364         [with_libtool=$withval],
7365         [with_libtool=no])
7366 AC_MSG_RESULT($with_libtool)
7367 if test "$with_libtool" != "no"; then
7368 ifdef([AC_PROG_LIBTOOL],[
7369         # missing_content_AC_PROG_LIBTOOL{{
7370         AC_PROG_LIBTOOL
7371         # missing_content_AC_PROG_LIBTOOL}}
7372 ],[
7373         if test "$with_libtool" != "yes" ; then
7374                 CF_PATH_SYNTAX(with_libtool)
7375                 LIBTOOL=$with_libtool
7376         else
7377                 AC_CHECK_TOOLS(LIBTOOL,[libtool glibtool],none)
7378                 CF_LIBTOOL_VERSION
7379                 if test -z "$cf_cv_libtool_version" && test "$LIBTOOL" = libtool
7380                 then
7381                         CF_FORGET_TOOL(LIBTOOL)
7382                         AC_CHECK_TOOLS(LIBTOOL,[glibtool],none)
7383                         CF_LIBTOOL_VERSION
7384                 fi
7385         fi
7386         if test -z "$LIBTOOL" ; then
7387                 AC_MSG_ERROR(Cannot find libtool)
7388         fi
7389 ])dnl
7390         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${libdir} ${LIBTOOL_VERSION} `cut -f1 ${top_srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
7391         LIB_OBJECT='${OBJECTS:.o=.lo}'
7392         LIB_SUFFIX=.la
7393         LIB_CLEAN='${LIBTOOL} --mode=clean'
7394         LIB_COMPILE='${LIBTOOL} --mode=compile'
7395         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
7396         LIB_INSTALL='${LIBTOOL} --mode=install'
7397         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
7398         LIB_PREP=:
7399
7400         CF_CHECK_LIBTOOL_VERSION
7401
7402         # special hack to add -no-undefined (which libtool should do for itself)
7403         LT_UNDEF=
7404         case "$cf_cv_system_name" in
7405         (cygwin*|msys*|mingw32*|os2*|uwin*|aix[[4-7]])
7406                 LT_UNDEF=-no-undefined
7407                 ;;
7408         esac
7409         AC_SUBST([LT_UNDEF])
7410
7411         # special hack to add --tag option for C++ compiler
7412         case $cf_cv_libtool_version in
7413         (1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*)
7414                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
7415                 LIBTOOL="$LIBTOOL --tag=CC"
7416                 ;;
7417         (*)
7418                 LIBTOOL_CXX="$LIBTOOL"
7419                 ;;
7420         esac
7421 else
7422         LIBTOOL=""
7423         LIBTOOL_CXX=""
7424 fi
7425
7426 test -z "$LIBTOOL" && ECHO_LT=
7427
7428 AC_SUBST(LIBTOOL)
7429 AC_SUBST(LIBTOOL_CXX)
7430 AC_SUBST(LIBTOOL_OPTS)
7431
7432 AC_SUBST(LIB_CREATE)
7433 AC_SUBST(LIB_OBJECT)
7434 AC_SUBST(LIB_SUFFIX)
7435 AC_SUBST(LIB_PREP)
7436
7437 AC_SUBST(LIB_CLEAN)
7438 AC_SUBST(LIB_COMPILE)
7439 AC_SUBST(LIB_LINK)
7440 AC_SUBST(LIB_INSTALL)
7441 AC_SUBST(LIB_UNINSTALL)
7442
7443 ])dnl
7444 dnl ---------------------------------------------------------------------------
7445 dnl CF_WITH_LIBTOOL_OPTS version: 4 updated: 2015/04/17 21:13:04
7446 dnl --------------------
7447 dnl Allow user to pass additional libtool options into the library creation
7448 dnl and link steps.  The main use for this is to do something like
7449 dnl     ./configure --with-libtool-opts=-static
7450 dnl to get the same behavior as automake-flavored
7451 dnl     ./configure --enable-static
7452 AC_DEFUN([CF_WITH_LIBTOOL_OPTS],[
7453 AC_MSG_CHECKING(for additional libtool options)
7454 AC_ARG_WITH(libtool-opts,
7455         [  --with-libtool-opts=XXX specify additional libtool options],
7456         [with_libtool_opts=$withval],
7457         [with_libtool_opts=no])
7458 AC_MSG_RESULT($with_libtool_opts)
7459
7460 case .$with_libtool_opts in
7461 (.yes|.no|.)
7462         ;;
7463 (*)
7464         LIBTOOL_OPTS="$LIBTOOL_OPTS $with_libtool_opts"
7465         ;;
7466 esac
7467
7468 AC_SUBST(LIBTOOL_OPTS)
7469 ])dnl
7470 dnl ---------------------------------------------------------------------------
7471 dnl CF_WITH_LIB_PREFIX version: 1 updated: 2012/01/21 19:28:10
7472 dnl ------------------
7473 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
7474 dnl "lib" prefix, e.g., because it used the dll naming convention.
7475 dnl
7476 dnl $1 = variable to set
7477 AC_DEFUN([CF_WITH_LIB_PREFIX],
7478 [
7479 AC_MSG_CHECKING(if you want to have a library-prefix)
7480 AC_ARG_WITH(lib-prefix,
7481         [  --with-lib-prefix       override library-prefix],
7482         [with_lib_prefix=$withval],
7483         [with_lib_prefix=auto])
7484 AC_MSG_RESULT($with_lib_prefix)
7485
7486 if test $with_lib_prefix = auto
7487 then
7488         CF_LIB_PREFIX($1)
7489 elif test $with_lib_prefix = no
7490 then
7491         LIB_PREFIX=
7492 else
7493         LIB_PREFIX=$with_lib_prefix
7494 fi
7495 ])dnl
7496 dnl ---------------------------------------------------------------------------
7497 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
7498 dnl ------------
7499 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
7500 dnl defaulting to yes/no.
7501 dnl
7502 dnl $1 = option name
7503 dnl $2 = help-text
7504 dnl $3 = environment variable to set
7505 dnl $4 = default value, shown in the help-message, must be a constant
7506 dnl $5 = default value, if it's an expression & cannot be in the help-message
7507 dnl
7508 AC_DEFUN([CF_WITH_PATH],
7509 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
7510 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
7511 if ifelse([$5],,true,[test -n "$5"]) ; then
7512 CF_PATH_SYNTAX(withval)
7513 fi
7514 eval $3="$withval"
7515 AC_SUBST($3)dnl
7516 ])dnl
7517 dnl ---------------------------------------------------------------------------
7518 dnl CF_WITH_PATHLIST version: 10 updated: 2015/04/17 21:13:04
7519 dnl ----------------
7520 dnl Process an option specifying a list of colon-separated paths.
7521 dnl
7522 dnl $1 = option name
7523 dnl $2 = help-text
7524 dnl $3 = environment variable to set
7525 dnl $4 = default value, shown in the help-message, must be a constant
7526 dnl $5 = default value, if it's an expression & cannot be in the help-message
7527 dnl $6 = flag to tell if we want to define or substitute
7528 dnl
7529 AC_DEFUN([CF_WITH_PATHLIST],[
7530 AC_REQUIRE([CF_PATHSEP])
7531 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
7532 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
7533
7534 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
7535 cf_dst_path=
7536 for cf_src_path in $withval
7537 do
7538   CF_PATH_SYNTAX(cf_src_path)
7539   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}$PATH_SEPARATOR"
7540   cf_dst_path="${cf_dst_path}${cf_src_path}"
7541 done
7542 IFS="$ac_save_ifs"
7543
7544 ifelse($6,define,[
7545 # Strip single quotes from the value, e.g., when it was supplied as a literal
7546 # for $4 or $5.
7547 case $cf_dst_path in
7548 (\'*)
7549   cf_dst_path=`echo $cf_dst_path |sed -e s/\'// -e s/\'\$//`
7550   ;;
7551 esac
7552 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
7553 ])
7554
7555 # This may use the prefix/exec_prefix symbols which will only yield "NONE"
7556 # so we have to check/work around.  We do prefer the result of "eval"...
7557 eval cf_dst_eval="$cf_dst_path"
7558 case "x$cf_dst_eval" in
7559 (xNONE*)
7560         $3=$cf_dst_path
7561         ;;
7562 (*)
7563         $3="$cf_dst_eval"
7564         ;;
7565 esac
7566 AC_SUBST($3)dnl
7567
7568 ])dnl
7569 dnl ---------------------------------------------------------------------------
7570 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 10 updated: 2015/08/22 17:10:56
7571 dnl -------------------------
7572 dnl Allow the choice of the pkg-config library directory to be overridden.
7573 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
7574
7575 case $PKG_CONFIG in
7576 (no|none|yes)
7577         AC_MSG_CHECKING(for pkg-config library directory)
7578         ;;
7579 (*)
7580         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
7581         ;;
7582 esac
7583
7584 PKG_CONFIG_LIBDIR=no
7585 AC_ARG_WITH(pkg-config-libdir,
7586         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
7587         [PKG_CONFIG_LIBDIR=$withval],
7588         [test "x$PKG_CONFIG" != xnone && PKG_CONFIG_LIBDIR=yes])
7589
7590 case x$PKG_CONFIG_LIBDIR in
7591 (x/*)
7592         ;;
7593 (xyes)
7594         # Look for the library directory using the same prefix as the executable
7595         if test "x$PKG_CONFIG" = xnone
7596         then
7597                 cf_path=$prefix
7598         else
7599                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
7600         fi
7601
7602         # If you don't like using the default architecture, you have to specify the
7603         # intended library directory and corresponding compiler/linker options.
7604         #
7605         # This case allows for Debian's 2014-flavor of multiarch, along with the
7606         # most common variations before that point.  Some other variants spell the
7607         # directory differently, e.g., "pkg-config", and put it in unusual places.
7608         # pkg-config has always been poorly standardized, which is ironic...
7609         case x`(arch) 2>/dev/null` in
7610         (*64)
7611                 cf_search_path="\
7612                         $cf_path/lib/*64-linux-gnu \
7613                         $cf_path/share \
7614                         $cf_path/lib64 \
7615                         $cf_path/lib32 \
7616                         $cf_path/lib"
7617                 ;;
7618         (*)
7619                 cf_search_path="\
7620                         $cf_path/lib/*-linux-gnu \
7621                         $cf_path/share \
7622                         $cf_path/lib32 \
7623                         $cf_path/lib \
7624                         $cf_path/libdata"
7625                 ;;
7626         esac
7627
7628         CF_VERBOSE(list...)
7629         for cf_config in $cf_search_path
7630         do
7631                 CF_VERBOSE(checking $cf_config/pkgconfig)
7632                 if test -d $cf_config/pkgconfig
7633                 then
7634                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
7635                         AC_MSG_CHECKING(done)
7636                         break
7637                 fi
7638         done
7639         ;;
7640 (*)
7641         ;;
7642 esac
7643
7644 if test "x$PKG_CONFIG_LIBDIR" != xno ; then
7645         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
7646 fi
7647
7648 AC_SUBST(PKG_CONFIG_LIBDIR)
7649 ])dnl
7650 dnl ---------------------------------------------------------------------------
7651 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
7652 dnl ---------------
7653 dnl Check for POSIX thread library.
7654 AC_DEFUN([CF_WITH_PTHREAD],
7655 [
7656 AC_MSG_CHECKING(if you want to link with the pthread library)
7657 AC_ARG_WITH(pthread,
7658         [  --with-pthread          use POSIX thread library],
7659         [with_pthread=$withval],
7660         [with_pthread=no])
7661 AC_MSG_RESULT($with_pthread)
7662
7663 if test "$with_pthread" != no ; then
7664         AC_CHECK_HEADER(pthread.h,[
7665         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
7666
7667         for cf_lib_pthread in pthread c_r
7668         do
7669             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
7670             cf_save_LIBS="$LIBS"
7671             CF_ADD_LIB($cf_lib_pthread)
7672             AC_TRY_LINK([
7673 #include <pthread.h>
7674 ],[
7675                 int rc = pthread_create(0,0,0,0);
7676                 int r2 = pthread_mutexattr_settype(0, 0);
7677 ],[with_pthread=yes],[with_pthread=no])
7678             LIBS="$cf_save_LIBS"
7679             AC_MSG_RESULT($with_pthread)
7680             test "$with_pthread" = yes && break
7681         done
7682
7683         if test "$with_pthread" = yes ; then
7684             CF_ADD_LIB($cf_lib_pthread)
7685             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
7686         else
7687             AC_MSG_ERROR(Cannot link with pthread library)
7688         fi
7689         ])
7690 fi
7691 ])
7692 dnl ---------------------------------------------------------------------------
7693 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
7694 dnl -------------------
7695 dnl Allow library's release-version to be overridden.  Generally this happens when a
7696 dnl packager has incremented the release-version past that used in the original package,
7697 dnl and wishes to keep doing this.
7698 dnl
7699 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
7700 dnl and {package}_MINOR symbols
7701 dnl symbol.
7702 AC_DEFUN([CF_WITH_REL_VERSION],[
7703 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
7704 AC_ARG_WITH(rel-version,
7705 [  --with-rel-version=XXX  override derived release version],
7706 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
7707  cf_cv_rel_version=$withval])
7708 ifelse($1,,[
7709  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
7710 ],[
7711  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
7712  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
7713  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
7714  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
7715 ])
7716 ])dnl
7717 dnl ---------------------------------------------------------------------------
7718 dnl CF_WITH_SYSMOUSE version: 3 updated: 2012/10/06 17:56:13
7719 dnl ----------------
7720 dnl If we can compile with sysmouse, make it available unless it is not wanted.
7721 AC_DEFUN([CF_WITH_SYSMOUSE],[
7722 # not everyone has "test -c"
7723 if test -c /dev/sysmouse 2>/dev/null ; then
7724 AC_MSG_CHECKING(if you want to use sysmouse)
7725 AC_ARG_WITH(sysmouse,
7726         [  --with-sysmouse         use sysmouse (FreeBSD console)],
7727         [cf_with_sysmouse=$withval],
7728         [cf_with_sysmouse=maybe])
7729         if test "$cf_with_sysmouse" != no ; then
7730         AC_TRY_COMPILE([
7731 #include <osreldate.h>
7732 #if (__FreeBSD_version >= 400017)
7733 #include <sys/consio.h>
7734 #include <sys/fbio.h>
7735 #else
7736 #include <machine/console.h>
7737 #endif
7738 ],[
7739         struct mouse_info the_mouse;
7740         ioctl(0, CONS_MOUSECTL, &the_mouse);
7741 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
7742         fi
7743 AC_MSG_RESULT($cf_with_sysmouse)
7744 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE,1,[Define to 1 if we can/should use the sysmouse interface])
7745 fi
7746 ])dnl
7747 dnl ---------------------------------------------------------------------------
7748 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
7749 dnl ---------------
7750 dnl For testing, override the derived host system-type which is used to decide
7751 dnl things such as the linker commands used to build shared libraries.  This is
7752 dnl normally chosen automatically based on the type of system which you are
7753 dnl building on.  We use it for testing the configure script.
7754 dnl
7755 dnl This is different from the --host option: it is used only for testing parts
7756 dnl of the configure script which would not be reachable with --host since that
7757 dnl relies on the build environment being real, rather than mocked up.
7758 AC_DEFUN([CF_WITH_SYSTYPE],[
7759 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
7760 AC_ARG_WITH(system-type,
7761         [  --with-system-type=XXX  test: override derived host system-type],
7762 [AC_MSG_WARN(overriding system type to $withval)
7763         cf_cv_system_name=$withval
7764         host_os=$withval
7765 ])
7766 ])dnl
7767 dnl ---------------------------------------------------------------------------
7768 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
7769 dnl ----------------
7770 AC_DEFUN([CF_WITH_VALGRIND],[
7771 CF_NO_LEAKS_OPTION(valgrind,
7772         [  --with-valgrind         test: use valgrind],
7773         [USE_VALGRIND])
7774 ])dnl
7775 dnl ---------------------------------------------------------------------------
7776 dnl CF_WITH_VERSIONED_SYMS version: 7 updated: 2015/10/24 20:50:26
7777 dnl ----------------------
7778 dnl Use this when building shared library with ELF, to markup symbols with the
7779 dnl version identifier from the given input file.  Generally that identifier is
7780 dnl the same as the SONAME at which the symbol was first introduced.
7781 dnl
7782 dnl $1 = basename of the ".map" file (default $PACKAGE)
7783 AC_DEFUN([CF_WITH_VERSIONED_SYMS],
7784 [
7785 AC_MSG_CHECKING(if versioned-symbols file should be used)
7786 AC_ARG_WITH(versioned-syms,
7787         [  --with-versioned-syms=X markup versioned symbols using ld],
7788         [with_versioned_syms=$withval],
7789         [with_versioned_syms=no])
7790 if test "x$with_versioned_syms" = xyes
7791 then
7792         with_versioned_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).map'
7793         AC_SUBST(PACKAGE)
7794 fi
7795 AC_MSG_RESULT($with_versioned_syms)
7796
7797 RESULTING_SYMS=
7798 VERSIONED_SYMS=
7799 WILDCARD_SYMS=
7800
7801 if test "x$with_versioned_syms" != xno
7802 then
7803         RESULTING_SYMS=$with_versioned_syms
7804         case "x$MK_SHARED_LIB" in
7805         (*-Wl,*)
7806                 VERSIONED_SYMS="-Wl,--version-script,\${RESULTING_SYMS}"
7807                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-Wl,%\\[$]{VERSIONED_SYMS} -Wl,%"`
7808                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
7809                 ;;
7810         (*-dy\ *)
7811                 VERSIONED_SYMS="-Wl,-M,\${RESULTING_SYMS}"
7812                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-dy%\\[$]{VERSIONED_SYMS} -dy%"`
7813                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
7814                 ;;
7815         (*)
7816                 AC_MSG_WARN(this system does not support versioned-symbols)
7817                 ;;
7818         esac
7819
7820         # Linux ld can selectively override scope, e.g., of symbols beginning with
7821         # "_" by first declaring some as global, and then using a wildcard to
7822         # declare the others as local.  Some other loaders cannot do this.  Check
7823         # by constructing a (very) simple shared library and inspecting its
7824         # symbols.
7825         if test "x$VERSIONED_SYMS" != "x"
7826         then
7827                 AC_MSG_CHECKING(if wildcards can be used to selectively omit symbols)
7828                 WILDCARD_SYMS=no
7829
7830                 # make sources
7831                 rm -f conftest.*
7832
7833                 cat >conftest.ver <<EOF
7834 module_1.0 {
7835 global:
7836         globalf1;
7837 local:
7838         localf1;
7839 };
7840 module_2.0 {
7841 global:
7842         globalf2;
7843 local:
7844         localf2;
7845         _*;
7846 } module_1.0;
7847 submodule_1.0 {
7848 global:
7849         subglobalf1;
7850         _ismissing;
7851 local:
7852         sublocalf1;
7853 };
7854 submodule_2.0 {
7855 global:
7856         subglobalf2;
7857 local:
7858         sublocalf2;
7859         _*;
7860 } submodule_1.0;
7861 EOF
7862                 cat >conftest.$ac_ext <<EOF
7863 #line __oline__ "configure"
7864 int     _ismissing(void) { return 1; }
7865 int     _localf1(void) { return 1; }
7866 int     _localf2(void) { return 2; }
7867 int     globalf1(void) { return 1; }
7868 int     globalf2(void) { return 2; }
7869 int     _sublocalf1(void) { return 1; }
7870 int     _sublocalf2(void) { return 2; }
7871 int     subglobalf1(void) { return 1; }
7872 int     subglobalf2(void) { return 2; }
7873 EOF
7874                 cat >conftest.mk <<EOF
7875 CC=${CC}
7876 CFLAGS=${CFLAGS}
7877 CPPFLAGS=${CPPFLAGS}
7878 LDFLAGS=${LDFLAGS}
7879 LIBS=${LIBS}
7880 VERSIONED_SYMS=${VERSIONED_SYMS}
7881 RESULTING_SYMS=conftest.ver
7882 MK_SHARED_LIB=${MK_SHARED_LIB}
7883 conftest.so: conftest.$ac_cv_objext
7884                 \$(MK_SHARED_LIB) conftest.$ac_cv_objext
7885 EOF
7886
7887                 # compile source, make library
7888                 if make -f conftest.mk 2>&AC_FD_CC >/dev/null
7889                 then
7890                         # test for missing symbol in either Data or Text section
7891                         cf_missing=`nm -P conftest.so 2>&AC_FD_CC |fgrep _ismissing | egrep '[[         ]][[DT]][[      ]]'`
7892                         test -n "$cf_missing" && WILDCARD_SYMS=yes
7893                 fi
7894                 AC_MSG_RESULT($WILDCARD_SYMS)
7895                 rm -f conftest.*
7896         fi
7897 fi
7898 AC_SUBST(RESULTING_SYMS)
7899 AC_SUBST(VERSIONED_SYMS)
7900 AC_SUBST(WILDCARD_SYMS)
7901 ])dnl
7902 dnl ---------------------------------------------------------------------------
7903 dnl CF_WITH_X11_RGB version: 1 updated: 2017/11/25 17:32:16
7904 dnl ---------------
7905 dnl Handle configure option "--with-x11-rgb", setting these shell
7906 dnl variables:
7907 dnl
7908 dnl $RGB_PATH is the option value, used for finding the X11 rgb file.
7909 dnl $no_x11_rgb is a "#" (comment) if "--without-x11-rgb" is given.
7910 dnl
7911 dnl Most Linux's use this:
7912 dnl     /usr/share/X11/rgb.txt
7913 dnl Debian uses this:
7914 dnl     /etc/X11/rgb.txt
7915 dnl DragonFlyBSD ports uses this:
7916 dnl     /usr/pkg/lib/X11/rgb.txt
7917 dnl FreeBSD ports use these:
7918 dnl     /usr/local/lib/X11/rgb.txt
7919 dnl     /usr/local/share/X11/rgb.txt
7920 dnl Mandriva has these:
7921 dnl     /usr/lib/X11/rgb.txt
7922 dnl     /usr/lib64/X11/rgb.txt
7923 dnl NetBSD has these
7924 dnl     /usr/X11R7/lib/X11/rgb.txt
7925 dnl OpenSolaris uses
7926 dnl     32-bit:
7927 dnl     /usr/X11/etc/X11/rgb.txt
7928 dnl     /usr/X11/share/X11/rgb.txt
7929 dnl     /usr/X11/lib/X11/rgb.txt
7930 dnl OSX uses
7931 dnl             /opt/local/share/X11/rgb.txt (MacPorts)
7932 dnl             /opt/X11/share/X11/rgb.txt (non-ports)
7933 dnl     64-bit:
7934 dnl     /usr/X11/etc/X11/rgb.txt
7935 dnl     /usr/X11/share/X11/rgb.txt (perhaps)
7936 dnl     /usr/X11/lib/amd64/X11/rgb.txt
7937 dnl Solaris10 uses (in this order):
7938 dnl     /usr/openwin/lib/X11/rgb.txt
7939 dnl     /usr/X11/lib/X11/rgb.txt
7940 AC_DEFUN([CF_WITH_X11_RGB],[
7941 AC_MSG_CHECKING(for X11 rgb file)
7942 AC_ARG_WITH(x11-rgb,
7943         [  --with-x11-rgb=FILE   file containing X11 rgb information (EPREFIX/lib/X11/rgb.txt)],
7944         [RGB_PATH=$withval],
7945         [RGB_PATH=auto])
7946
7947 if test "x[$]RGB_PATH" = xauto
7948 then
7949         RGB_PATH='${exec_prefix}/lib/X11/rgb.txt'
7950         for cf_path in \
7951                 /opt/local/share/X11/rgb.txt \
7952                 /opt/X11/share/X11/rgb.txt \
7953                 /usr/share/X11/rgb.txt \
7954                 /usr/X11/share/X11/rgb.txt \
7955                 /usr/X11/lib/X11/rgb.txt \
7956                 /usr/lib/X11/rgb.txt \
7957                 /etc/X11/rgb.txt \
7958                 /usr/pkg/lib/X11/rgb.txt \
7959                 /usr/X11R7/lib/X11/rgb.txt \
7960                 /usr/X11R6/lib/X11/rgb.txt \
7961                 /usr/X11R5/lib/X11/rgb.txt \
7962                 /usr/X11R4/lib/X11/rgb.txt \
7963                 /usr/local/lib/X11/rgb.txt \
7964                 /usr/local/share/X11/rgb.txt \
7965                 /usr/lib64/X11/rgb.txt
7966         do
7967                 if test -f "$cf_path" ; then
7968                         RGB_PATH="$cf_path"
7969                         break
7970                 fi
7971         done
7972 else
7973         cf_path=$RGB_PATH
7974         CF_PATH_SYNTAX(cf_path)
7975 fi
7976
7977 AC_MSG_RESULT($RGB_PATH)
7978 AC_SUBST(RGB_PATH)
7979 AC_DEFINE_UNQUOTED(RGB_PATH,"$cf_path")
7980
7981 no_x11_rgb=
7982 if test "$RGB_PATH" = no
7983 then
7984         no_x11_rgb="#"
7985 fi
7986 AC_SUBST(no_x11_rgb)
7987 ])dnl
7988 dnl ---------------------------------------------------------------------------
7989 dnl CF_XOPEN_SOURCE version: 52 updated: 2016/08/27 12:21:42
7990 dnl ---------------
7991 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
7992 dnl or adapt to the vendor's definitions to get equivalent functionality,
7993 dnl without losing the common non-POSIX features.
7994 dnl
7995 dnl Parameters:
7996 dnl     $1 is the nominal value for _XOPEN_SOURCE
7997 dnl     $2 is the nominal value for _POSIX_C_SOURCE
7998 AC_DEFUN([CF_XOPEN_SOURCE],[
7999 AC_REQUIRE([AC_CANONICAL_HOST])
8000
8001 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
8002 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
8003 cf_xopen_source=
8004
8005 case $host_os in
8006 (aix[[4-7]]*)
8007         cf_xopen_source="-D_ALL_SOURCE"
8008         ;;
8009 (msys)
8010         cf_XOPEN_SOURCE=600
8011         ;;
8012 (darwin[[0-8]].*)
8013         cf_xopen_source="-D_APPLE_C_SOURCE"
8014         ;;
8015 (darwin*)
8016         cf_xopen_source="-D_DARWIN_C_SOURCE"
8017         cf_XOPEN_SOURCE=
8018         ;;
8019 (freebsd*|dragonfly*)
8020         # 5.x headers associate
8021         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
8022         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
8023         cf_POSIX_C_SOURCE=200112L
8024         cf_XOPEN_SOURCE=600
8025         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
8026         ;;
8027 (hpux11*)
8028         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
8029         ;;
8030 (hpux*)
8031         cf_xopen_source="-D_HPUX_SOURCE"
8032         ;;
8033 (irix[[56]].*)
8034         cf_xopen_source="-D_SGI_SOURCE"
8035         cf_XOPEN_SOURCE=
8036         ;;
8037 (linux*|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin)
8038         CF_GNU_SOURCE
8039         ;;
8040 (minix*)
8041         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
8042         ;;
8043 (mirbsd*)
8044         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
8045         cf_XOPEN_SOURCE=
8046         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
8047         ;;
8048 (netbsd*)
8049         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
8050         ;;
8051 (openbsd[[4-9]]*)
8052         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
8053         cf_xopen_source="-D_BSD_SOURCE"
8054         cf_XOPEN_SOURCE=600
8055         ;;
8056 (openbsd*)
8057         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
8058         ;;
8059 (osf[[45]]*)
8060         cf_xopen_source="-D_OSF_SOURCE"
8061         ;;
8062 (nto-qnx*)
8063         cf_xopen_source="-D_QNX_SOURCE"
8064         ;;
8065 (sco*)
8066         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
8067         ;;
8068 (solaris2.*)
8069         cf_xopen_source="-D__EXTENSIONS__"
8070         cf_cv_xopen_source=broken
8071         ;;
8072 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
8073         cf_XOPEN_SOURCE=
8074         cf_POSIX_C_SOURCE=
8075         ;;
8076 (*)
8077         CF_TRY_XOPEN_SOURCE
8078         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
8079         ;;
8080 esac
8081
8082 if test -n "$cf_xopen_source" ; then
8083         CF_ADD_CFLAGS($cf_xopen_source,true)
8084 fi
8085
8086 dnl In anything but the default case, we may have system-specific setting
8087 dnl which is still not guaranteed to provide all of the entrypoints that
8088 dnl _XOPEN_SOURCE would yield.
8089 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
8090         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
8091         AC_TRY_COMPILE([#include <stdlib.h>],[
8092 #ifndef _XOPEN_SOURCE
8093 make an error
8094 #endif],
8095         [cf_XOPEN_SOURCE_set=yes],
8096         [cf_XOPEN_SOURCE_set=no])
8097         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
8098         if test $cf_XOPEN_SOURCE_set = yes
8099         then
8100                 AC_TRY_COMPILE([#include <stdlib.h>],[
8101 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
8102 make an error
8103 #endif],
8104                 [cf_XOPEN_SOURCE_set_ok=yes],
8105                 [cf_XOPEN_SOURCE_set_ok=no])
8106                 if test $cf_XOPEN_SOURCE_set_ok = no
8107                 then
8108                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
8109                 fi
8110         else
8111                 CF_TRY_XOPEN_SOURCE
8112         fi
8113 fi
8114 ])