aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2020,2021 Thomas E. Dickey                                *
   3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey 1995-on
  31 dnl
  32 dnl $Id: aclocal.m4,v 1.961 2021/05/19 23:35:25 tom Exp $
  33 dnl Macros used in NCURSES auto-configuration script.
  34 dnl
  35 dnl These macros are maintained separately from NCURSES.  The copyright on
  36 dnl this file applies to the aggregation of macros and does not affect use of
  37 dnl these macros in other applications.
  38 dnl
  39 dnl See these pages for additional information:
  40 dnl             https://invisible-island.net/autoconf/
  41 dnl             https://invisible-island.net/autoconf/my-autoconf.html
  42 dnl
  43 dnl ---------------------------------------------------------------------------
  44 dnl ---------------------------------------------------------------------------
  45 dnl AM_LANGINFO_CODESET version: 6 updated: 2021/01/01 16:53:59
  46 dnl -------------------
  47 dnl Inserted as requested by gettext 0.10.40
  48 dnl File from /usr/share/aclocal
  49 dnl codeset.m4
  50 dnl ====================
  51 dnl serial AM1
  52 dnl
  53 dnl From Bruno Haible.
  54 AC_DEFUN([AM_LANGINFO_CODESET],
  55 [
  56 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  57         [AC_TRY_LINK([#include <langinfo.h>],
  58         [char* cs = nl_langinfo(CODESET); (void)cs],
  59         am_cv_langinfo_codeset=yes,
  60         am_cv_langinfo_codeset=no)
  61         ])
  62         if test "$am_cv_langinfo_codeset" = yes; then
  63                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  64                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  65         fi
  66 ])dnl
  67 dnl ---------------------------------------------------------------------------
  68 dnl CF_ABI_DEFAULTS version: 2 updated: 2015/06/06 13:49:58
  69 dnl ---------------
  70 dnl Provide configure-script defaults for different ncurses ABIs.
  71 AC_DEFUN([CF_ABI_DEFAULTS],[
  72 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
  73 case x$cf_cv_abi_version in
  74 (x[[6789]])
  75         cf_dft_ext_colors=yes
  76         cf_dft_ext_const=yes
  77         cf_dft_ext_mouse=yes
  78         cf_dft_ext_putwin=yes
  79         cf_dft_ext_spfuncs=yes
  80         cf_dft_filter_syms=yes
  81         cf_dft_chtype=uint32_t
  82         cf_dft_mmask_t=uint32_t
  83         cf_dft_interop=yes
  84         cf_dft_tparm_arg=intptr_t
  85         cf_dft_with_lp64=yes
  86         ;;
  87 (*)
  88         cf_dft_ext_colors=no
  89         cf_dft_ext_const=no
  90         cf_dft_ext_mouse=no
  91         cf_dft_ext_putwin=no
  92         cf_dft_ext_spfuncs=no
  93         cf_dft_filter_syms=no
  94         cf_dft_chtype=auto
  95         cf_dft_mmask_t=auto
  96         cf_dft_interop=no
  97         cf_dft_tparm_arg=long
  98         cf_dft_with_lp64=no
  99         ;;
 100 esac
 101 ])dnl
 102 dnl ---------------------------------------------------------------------------
 103 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
 104 dnl ------------------
 105 dnl Conditionally generate script according to whether we're using a given autoconf.
 106 dnl
 107 dnl $1 = version to compare against
 108 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
 109 dnl $3 = code to use if AC_ACVERSION is older than $1.
 110 define([CF_ACVERSION_CHECK],
 111 [
 112 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
 113 ifdef([m4_version_compare],
 114 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
 115 [CF_ACVERSION_COMPARE(
 116 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
 117 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
 118 dnl ---------------------------------------------------------------------------
 119 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
 120 dnl --------------------
 121 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
 122 dnl                      MAJOR2, MINOR2, TERNARY2,
 123 dnl                      PRINTABLE2, not FOUND, FOUND)
 124 define([CF_ACVERSION_COMPARE],
 125 [ifelse(builtin([eval], [$2 < $5]), 1,
 126 [ifelse([$8], , ,[$8])],
 127 [ifelse([$9], , ,[$9])])])dnl
 128 dnl ---------------------------------------------------------------------------
 129 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
 130 dnl -------------------
 131 dnl Construct the list of include-options for the C programs in the Ada95
 132 dnl binding.
 133 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
 134 [
 135 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
 136 if test "$srcdir" != "."; then
 137         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 138 fi
 139 if test "$GCC" != yes; then
 140         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 141 elif test "$includedir" != "/usr/include"; then
 142         if test "$includedir" = '${prefix}/include' ; then
 143                 if test x$prefix != x/usr ; then
 144                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 145                 fi
 146         else
 147                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 148         fi
 149 fi
 150 AC_SUBST(ACPPFLAGS)
 151 ])dnl
 152 dnl ---------------------------------------------------------------------------
 153 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 154 dnl ---------------
 155 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 156 AC_DEFUN([CF_ADD_ADAFLAGS],[
 157         ADAFLAGS="$ADAFLAGS $1"
 158         AC_SUBST(ADAFLAGS)
 159 ])dnl
 160 dnl ---------------------------------------------------------------------------
 161 dnl CF_ADD_CFLAGS version: 15 updated: 2020/12/31 10:54:15
 162 dnl -------------
 163 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 164 dnl $1 = flags to add
 165 dnl $2 = if given makes this macro verbose.
 166 dnl
 167 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 168 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 169 dnl confused by the quotes (which require backslashes to keep them usable).
 170 AC_DEFUN([CF_ADD_CFLAGS],
 171 [
 172 cf_fix_cppflags=no
 173 cf_new_cflags=
 174 cf_new_cppflags=
 175 cf_new_extra_cppflags=
 176
 177 for cf_add_cflags in $1
 178 do
 179 case "$cf_fix_cppflags" in
 180 (no)
 181         case "$cf_add_cflags" in
 182         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 183                 case "$cf_add_cflags" in
 184                 (-D*)
 185                         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 186
 187                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 188                                 && test -z "${cf_tst_cflags}" \
 189                                 && cf_fix_cppflags=yes
 190
 191                         if test "$cf_fix_cppflags" = yes ; then
 192                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 193                                 continue
 194                         elif test "${cf_tst_cflags}" = "\"'" ; then
 195                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 196                                 continue
 197                         fi
 198                         ;;
 199                 esac
 200                 case "$CPPFLAGS" in
 201                 (*$cf_add_cflags)
 202                         ;;
 203                 (*)
 204                         case "$cf_add_cflags" in
 205                         (-D*)
 206                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 207                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 208                                 ;;
 209                         esac
 210                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 211                         ;;
 212                 esac
 213                 ;;
 214         (*)
 215                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 216                 ;;
 217         esac
 218         ;;
 219 (yes)
 220         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 221
 222         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^[[^"]]*"'\''//'`
 223
 224         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 225                 && test -z "${cf_tst_cflags}" \
 226                 && cf_fix_cppflags=no
 227         ;;
 228 esac
 229 done
 230
 231 if test -n "$cf_new_cflags" ; then
 232         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 233         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 234 fi
 235
 236 if test -n "$cf_new_cppflags" ; then
 237         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 238         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 239 fi
 240
 241 if test -n "$cf_new_extra_cppflags" ; then
 242         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 243         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 244 fi
 245
 246 AC_SUBST(EXTRA_CPPFLAGS)
 247
 248 ])dnl
 249 dnl ---------------------------------------------------------------------------
 250 dnl CF_ADD_CXXFLAGS version: 1 updated: 2020/04/04 16:16:13
 251 dnl ---------------
 252 dnl Copy non-preprocessor flags to $CXXFLAGS, preprocessor flags to $CPPFLAGS
 253 dnl The second parameter if given makes this macro verbose.
 254 dnl
 255 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 256 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 257 dnl confused by the quotes (which require backslashes to keep them usable).
 258 AC_DEFUN([CF_ADD_CXXFLAGS],
 259 [
 260 cf_save_CXXFLAGS="$CFLAGS"
 261 CFLAGS="$CXXFLAGS"
 262 CF_ADD_CFLAGS($1 ifelse($2,,,[,$2]))
 263 CXXFLAGS="$CFLAGS"
 264 CFLAGS="$cf_save_CXXFLAGS"
 265 ])dnl
 266 dnl ---------------------------------------------------------------------------
 267 dnl CF_ADD_INCDIR version: 16 updated: 2020/12/31 20:19:42
 268 dnl -------------
 269 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 270 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 271 dnl but old versions (and some misinstalled ones) need that.  To make things
 272 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 273 dnl the include-path).
 274 AC_DEFUN([CF_ADD_INCDIR],
 275 [
 276 if test -n "$1" ; then
 277   for cf_add_incdir in $1
 278   do
 279         while test "$cf_add_incdir" != /usr/include
 280         do
 281           if test -d "$cf_add_incdir"
 282           then
 283                 cf_have_incdir=no
 284                 if test -n "$CFLAGS$CPPFLAGS" ; then
 285                   # a loop is needed to ensure we can add subdirs of existing dirs
 286                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 287                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 288                           cf_have_incdir=yes; break
 289                         fi
 290                   done
 291                 fi
 292
 293                 if test "$cf_have_incdir" = no ; then
 294                   if test "$cf_add_incdir" = /usr/local/include ; then
 295                         if test "$GCC" = yes
 296                         then
 297                           cf_save_CPPFLAGS=$CPPFLAGS
 298                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
 299                           AC_TRY_COMPILE([#include <stdio.h>],
 300                                   [printf("Hello")],
 301                                   [],
 302                                   [cf_have_incdir=yes])
 303                           CPPFLAGS=$cf_save_CPPFLAGS
 304                         fi
 305                   fi
 306                 fi
 307
 308                 if test "$cf_have_incdir" = no ; then
 309                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 310                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 311
 312                   cf_top_incdir=`echo "$cf_add_incdir" | sed -e 's%/include/.*$%/include%'`
 313                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 314                   cf_add_incdir="$cf_top_incdir"
 315                 else
 316                   break
 317                 fi
 318           else
 319                 break
 320           fi
 321         done
 322   done
 323 fi
 324 ])dnl
 325 dnl ---------------------------------------------------------------------------
 326 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 327 dnl ----------
 328 dnl Add a library, used to enforce consistency.
 329 dnl
 330 dnl $1 = library to add, without the "-l"
 331 dnl $2 = variable to update (default $LIBS)
 332 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 333 dnl ---------------------------------------------------------------------------
 334 dnl CF_ADD_LIBDIR version: 11 updated: 2020/12/31 20:19:42
 335 dnl -------------
 336 dnl     Adds to the library-path
 337 dnl
 338 dnl     Some machines have trouble with multiple -L options.
 339 dnl
 340 dnl $1 is the (list of) directory(s) to add
 341 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 342 dnl
 343 AC_DEFUN([CF_ADD_LIBDIR],
 344 [
 345 if test -n "$1" ; then
 346         for cf_add_libdir in $1
 347         do
 348                 if test "$cf_add_libdir" = /usr/lib ; then
 349                         :
 350                 elif test -d "$cf_add_libdir"
 351                 then
 352                         cf_have_libdir=no
 353                         if test -n "$LDFLAGS$LIBS" ; then
 354                                 # a loop is needed to ensure we can add subdirs of existing dirs
 355                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 356                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 357                                                 cf_have_libdir=yes; break
 358                                         fi
 359                                 done
 360                         fi
 361                         if test "$cf_have_libdir" = no ; then
 362                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 363                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 364                         fi
 365                 fi
 366         done
 367 fi
 368 ])dnl
 369 dnl ---------------------------------------------------------------------------
 370 dnl CF_ADD_LIBS version: 3 updated: 2019/11/02 16:47:33
 371 dnl -----------
 372 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 373 dnl prepended to an existing list, since their dependencies are assumed to
 374 dnl already exist in the list.
 375 dnl
 376 dnl $1 = libraries to add, with the "-l", etc.
 377 dnl $2 = variable to update (default $LIBS)
 378 AC_DEFUN([CF_ADD_LIBS],[
 379 cf_add_libs="[$]ifelse($2,,LIBS,[$2])"
 380 # reverse order
 381 cf_add_0lib=
 382 for cf_add_1lib in $1; do cf_add_0lib="$cf_add_1lib $cf_add_0lib"; done
 383 # filter duplicates
 384 for cf_add_1lib in $cf_add_0lib; do
 385         for cf_add_2lib in $cf_add_libs; do
 386                 if test "x$cf_add_1lib" = "x$cf_add_2lib"; then
 387                         cf_add_1lib=
 388                         break
 389                 fi
 390         done
 391         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_1lib $cf_add_libs"
 392 done
 393 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 394 ])dnl
 395 dnl ---------------------------------------------------------------------------
 396 dnl CF_ADD_SUBDIR_PATH version: 5 updated: 2020/12/31 20:19:42
 397 dnl ------------------
 398 dnl Append to a search-list for a nonstandard header/lib-file
 399 dnl     $1 = the variable to return as result
 400 dnl     $2 = the package name
 401 dnl     $3 = the subdirectory, e.g., bin, include or lib
 402 dnl $4 = the directory under which we will test for subdirectories
 403 dnl $5 = a directory that we do not want $4 to match
 404 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 405 [
 406 test "x$4" != "x$5" && \
 407 test -d "$4" && \
 408 ifelse([$5],NONE,,[{ test -z "$5" || test "x$5" = xNONE || test "x$4" != "x$5"; } &&]) {
 409         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 410         test -d "$4/$3" &&          $1="[$]$1 $4/$3"
 411         test -d "$4/$3/$2" &&       $1="[$]$1 $4/$3/$2"
 412         test -d "$4/$3/$2/$3" &&    $1="[$]$1 $4/$3/$2/$3"
 413         test -d "$4/$2/$3" &&       $1="[$]$1 $4/$2/$3"
 414         test -d "$4/$2/$3/$2" &&    $1="[$]$1 $4/$2/$3/$2"
 415 }
 416 ])dnl
 417 dnl ---------------------------------------------------------------------------
 418 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 419 dnl --------------
 420 dnl use this macro for appending text without introducing an extra blank at
 421 dnl the beginning
 422 define([CF_APPEND_TEXT],
 423 [
 424         test -n "[$]$1" && $1="[$]$1 "
 425         $1="[$]{$1}$2"
 426 ])dnl
 427 dnl ---------------------------------------------------------------------------
 428 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 429 dnl --------------
 430 dnl Allow user to disable a normally-on option.
 431 AC_DEFUN([CF_ARG_DISABLE],
 432 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 433 dnl ---------------------------------------------------------------------------
 434 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 435 dnl -------------
 436 dnl Allow user to enable a normally-off option.
 437 AC_DEFUN([CF_ARG_ENABLE],
 438 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 439 dnl ---------------------------------------------------------------------------
 440 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 441 dnl -------------
 442 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 443 dnl values.
 444 dnl
 445 dnl Parameters:
 446 dnl $1 = option name
 447 dnl $2 = help-string
 448 dnl $3 = action to perform if option is not default
 449 dnl $4 = action if perform if option is default
 450 dnl $5 = default option value (either 'yes' or 'no')
 451 AC_DEFUN([CF_ARG_OPTION],
 452 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 453         if test "$enableval" != "$5" ; then
 454 ifelse([$3],,[    :]dnl
 455 ,[    $3]) ifelse([$4],,,[
 456         else
 457                 $4])
 458         fi],[enableval=$5 ifelse([$4],,,[
 459         $4
 460 ])dnl
 461 ])])dnl
 462 dnl ---------------------------------------------------------------------------
 463 dnl CF_AR_FLAGS version: 9 updated: 2021/01/01 13:31:04
 464 dnl -----------
 465 dnl Check for suitable "ar" (archiver) options for updating an archive.
 466 dnl
 467 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 468 dnl as well as a workaround for breakage of make's archive rules by the GNU
 469 dnl binutils "ar" program.
 470 AC_DEFUN([CF_AR_FLAGS],[
 471 AC_REQUIRE([CF_PROG_AR])
 472
 473 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 474         case "$cf_cv_system_name" in
 475         (*-msvc*)
 476                 cf_cv_ar_flags=''
 477                 cat >mk_static_lib.sh <<-EOF
 478                 #!$SHELL
 479                 MSVC_BIN="[$]AR"
 480                 out="\[$]1"
 481                 shift
 482                 exec \[$]MSVC_BIN -out:"\[$]out" \[$]@
 483                 EOF
 484                 chmod +x mk_static_lib.sh
 485                 AR=`pwd`/mk_static_lib.sh
 486                 ;;
 487         (*)
 488                 cf_cv_ar_flags=unknown
 489                 for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 490                 do
 491
 492                         # check if $ARFLAGS already contains this choice
 493                         if test "x$ARFLAGS" != "x" ; then
 494                                 cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 495                                 if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 496                                         cf_cv_ar_flags=
 497                                         break
 498                                 fi
 499                         fi
 500
 501                         rm -f "conftest.$ac_cv_objext"
 502                         rm -f conftest.a
 503
 504                         cat >"conftest.$ac_ext" <<EOF
 505 #line __oline__ "configure"
 506 int     testdata[[3]] = { 123, 456, 789 };
 507 EOF
 508                         if AC_TRY_EVAL(ac_compile) ; then
 509                                 echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 510                                 $AR $ARFLAGS "$cf_ar_flags" conftest.a "conftest.$ac_cv_objext" 2>&AC_FD_CC 1>/dev/null
 511                                 if test -f conftest.a ; then
 512                                         cf_cv_ar_flags="$cf_ar_flags"
 513                                         break
 514                                 fi
 515                         else
 516                                 CF_VERBOSE(cannot compile test-program)
 517                                 break
 518                         fi
 519                 done
 520                 rm -f conftest.a "conftest.$ac_ext" "conftest.$ac_cv_objext"
 521                 ;;
 522         esac
 523 ])
 524
 525 if test -n "$ARFLAGS" ; then
 526         if test -n "$cf_cv_ar_flags" ; then
 527                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 528         fi
 529 else
 530         ARFLAGS=$cf_cv_ar_flags
 531 fi
 532
 533 AC_SUBST(ARFLAGS)
 534 ])
 535 dnl ---------------------------------------------------------------------------
 536 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
 537 dnl -----------------
 538 dnl Check if awk can handle big strings using printf.  Some older versions of
 539 dnl awk choke on large strings passed via "%s".
 540 dnl
 541 dnl $1 = desired string size
 542 dnl $2 = variable to set with result
 543 AC_DEFUN([CF_AWK_BIG_PRINTF],
 544 [
 545         case x$AWK in
 546         (x)
 547                 eval $2=no
 548                 ;;
 549         (*)
 550                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 551                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 552                         eval $2=yes
 553                 else
 554                         eval $2=no
 555                 fi
 556                 ;;
 557         esac
 558 ])dnl
 559 dnl ---------------------------------------------------------------------------
 560 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 561 dnl ------------
 562 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 563 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 564 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 565 dnl
 566 dnl Treat the configuration-variable specially here, since we're directly
 567 dnl substituting its value (i.e., 1/0).
 568 dnl
 569 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 570 AC_DEFUN([CF_BOOL_DECL],
 571 [
 572 AC_MSG_CHECKING(if we should include stdbool.h)
 573
 574 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 575         AC_TRY_COMPILE([],[bool foo = false],
 576                 [cf_cv_header_stdbool_h=0],
 577                 [AC_TRY_COMPILE([
 578 #ifndef __BEOS__
 579 #include <stdbool.h>
 580 #endif
 581 ],[bool foo = false],
 582                         [cf_cv_header_stdbool_h=1],
 583                         [cf_cv_header_stdbool_h=0])])])
 584
 585 if test "$cf_cv_header_stdbool_h" = 1
 586 then    AC_MSG_RESULT(yes)
 587 else    AC_MSG_RESULT(no)
 588 fi
 589
 590 AC_MSG_CHECKING([for builtin bool type])
 591
 592 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 593         AC_TRY_COMPILE([
 594 #include <stdio.h>
 595 #include <sys/types.h>
 596 ],[bool x = false],
 597                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 598                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 599         ])
 600
 601 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 602 then    AC_MSG_RESULT(yes)
 603 else    AC_MSG_RESULT(no)
 604 fi
 605 ])dnl
 606 dnl ---------------------------------------------------------------------------
 607 dnl CF_BOOL_SIZE version: 17 updated: 2020/10/24 19:48:55
 608 dnl ------------
 609 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 610 dnl Don't bother looking for bool.h, since it's been deprecated.
 611 dnl
 612 dnl If the current compiler is C rather than C++, we get the bool definition
 613 dnl from <stdbool.h>.
 614 AC_DEFUN([CF_BOOL_SIZE],
 615 [
 616 AC_CHECK_SIZEOF(bool,,[
 617 #include <stdlib.h>
 618 #include <stdio.h>
 619
 620 #if defined(__cplusplus)
 621
 622 #ifdef HAVE_GXX_BUILTIN_H
 623 #include <g++/builtin.h>
 624 #elif HAVE_GPP_BUILTIN_H
 625 #include <gpp/builtin.h>
 626 #elif HAVE_BUILTIN_H
 627 #include <builtin.h>
 628 #endif
 629
 630 #else
 631
 632 #if $cf_cv_header_stdbool_h
 633 #include <stdbool.h>
 634 #endif
 635
 636 #endif
 637 ])
 638
 639 AC_CACHE_CHECK(for type of bool, cf_cv_type_of_bool,[
 640         rm -f cf_test.out
 641         AC_TRY_RUN([
 642 #include <stdlib.h>
 643 #include <stdio.h>
 644
 645 #if defined(__cplusplus)
 646
 647 #ifdef HAVE_GXX_BUILTIN_H
 648 #include <g++/builtin.h>
 649 #elif HAVE_GPP_BUILTIN_H
 650 #include <gpp/builtin.h>
 651 #elif HAVE_BUILTIN_H
 652 #include <builtin.h>
 653 #endif
 654
 655 #else
 656
 657 #if $cf_cv_header_stdbool_h
 658 #include <stdbool.h>
 659 #endif
 660
 661 #endif
 662
 663 int main(void)
 664 {
 665         FILE *fp = fopen("cf_test.out", "w");
 666         if (fp != 0) {
 667                 bool x = true;
 668                 if ((bool)(-x) >= 0)
 669                         fputs("unsigned ", fp);
 670                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 671                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 672                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 673                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 674                 fclose(fp);
 675         }
 676         ${cf_cv_main_return:-return}(0);
 677 }
 678                 ],
 679                 [cf_cv_type_of_bool=`cat cf_test.out`
 680                  if test -z "$cf_cv_type_of_bool"; then
 681                    cf_cv_type_of_bool=unknown
 682                  fi],
 683                 [cf_cv_type_of_bool=unknown],
 684                 [
 685                 case x$ac_cv_sizeof_bool in
 686                 (x1) cf_cv_type_of_bool="unsigned char";;
 687                 (x2) cf_cv_type_of_bool="unsigned short";;
 688                 (x4) cf_cv_type_of_bool="unsigned int";;
 689                 (x8) cf_cv_type_of_bool="unsigned long";;
 690                 (*)  cf_cv_type_of_bool=unknown;;
 691                 esac
 692                 ])
 693         rm -f cf_test.out
 694 ])
 695
 696 if test "$cf_cv_type_of_bool" = unknown ; then
 697         case .$NCURSES_BOOL in
 698         (.auto|.) NCURSES_BOOL=unsigned;;
 699         esac
 700         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 701         cf_cv_type_of_bool=$NCURSES_BOOL
 702 fi
 703 ])dnl
 704 dnl ---------------------------------------------------------------------------
 705 dnl CF_BUILD_CC version: 9 updated: 2021/01/02 09:31:20
 706 dnl -----------
 707 dnl If we're cross-compiling, allow the user to override the tools and their
 708 dnl options.  The configure script is oriented toward identifying the host
 709 dnl compiler, etc., but we need a build compiler to generate parts of the
 710 dnl source.
 711 dnl
 712 dnl $1 = default for $CPPFLAGS
 713 dnl $2 = default for $LIBS
 714 AC_DEFUN([CF_BUILD_CC],[
 715 CF_ACVERSION_CHECK(2.52,,
 716         [AC_REQUIRE([CF_PROG_EXT])])
 717 if test "$cross_compiling" = yes ; then
 718
 719         # defaults that we might want to override
 720         : ${BUILD_CFLAGS:=''}
 721         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 722         : ${BUILD_LDFLAGS:=''}
 723         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 724         : ${BUILD_EXEEXT:='$x'}
 725         : ${BUILD_OBJEXT:='o'}
 726
 727         AC_ARG_WITH(build-cc,
 728                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 729                 [BUILD_CC="$withval"],
 730                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
 731         AC_MSG_CHECKING(for native build C compiler)
 732         AC_MSG_RESULT($BUILD_CC)
 733
 734         AC_MSG_CHECKING(for native build C preprocessor)
 735         AC_ARG_WITH(build-cpp,
 736                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 737                 [BUILD_CPP="$withval"],
 738                 [BUILD_CPP='${BUILD_CC} -E'])
 739         AC_MSG_RESULT($BUILD_CPP)
 740
 741         AC_MSG_CHECKING(for native build C flags)
 742         AC_ARG_WITH(build-cflags,
 743                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 744                 [BUILD_CFLAGS="$withval"])
 745         AC_MSG_RESULT($BUILD_CFLAGS)
 746
 747         AC_MSG_CHECKING(for native build C preprocessor-flags)
 748         AC_ARG_WITH(build-cppflags,
 749                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 750                 [BUILD_CPPFLAGS="$withval"])
 751         AC_MSG_RESULT($BUILD_CPPFLAGS)
 752
 753         AC_MSG_CHECKING(for native build linker-flags)
 754         AC_ARG_WITH(build-ldflags,
 755                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 756                 [BUILD_LDFLAGS="$withval"])
 757         AC_MSG_RESULT($BUILD_LDFLAGS)
 758
 759         AC_MSG_CHECKING(for native build linker-libraries)
 760         AC_ARG_WITH(build-libs,
 761                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 762                 [BUILD_LIBS="$withval"])
 763         AC_MSG_RESULT($BUILD_LIBS)
 764
 765         # this assumes we're on Unix.
 766         BUILD_EXEEXT=
 767         BUILD_OBJEXT=o
 768
 769         : ${BUILD_CC:='${CC}'}
 770
 771         if { test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}'; } ; then
 772                 AC_MSG_ERROR([Cross-build requires two compilers.
 773 Use --with-build-cc to specify the native compiler.])
 774         fi
 775
 776 else
 777         : ${BUILD_CC:='${CC}'}
 778         : ${BUILD_CPP:='${CPP}'}
 779         : ${BUILD_CFLAGS:='${CFLAGS}'}
 780         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 781         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 782         : ${BUILD_LIBS:='${LIBS}'}
 783         : ${BUILD_EXEEXT:='$x'}
 784         : ${BUILD_OBJEXT:='o'}
 785 fi
 786
 787 AC_SUBST(BUILD_CC)
 788 AC_SUBST(BUILD_CPP)
 789 AC_SUBST(BUILD_CFLAGS)
 790 AC_SUBST(BUILD_CPPFLAGS)
 791 AC_SUBST(BUILD_LDFLAGS)
 792 AC_SUBST(BUILD_LIBS)
 793 AC_SUBST(BUILD_EXEEXT)
 794 AC_SUBST(BUILD_OBJEXT)
 795 ])dnl
 796 dnl ---------------------------------------------------------------------------
 797 dnl CF_C11_NORETURN version: 3 updated: 2021/03/28 11:36:23
 798 dnl ---------------
 799 AC_DEFUN([CF_C11_NORETURN],
 800 [
 801 AC_MSG_CHECKING(if you want to use C11 _Noreturn feature)
 802 CF_ARG_ENABLE(stdnoreturn,
 803         [  --enable-stdnoreturn    enable C11 _Noreturn feature for diagnostics],
 804         [enable_stdnoreturn=yes],
 805         [enable_stdnoreturn=no])
 806 AC_MSG_RESULT($enable_stdnoreturn)
 807
 808 if test $enable_stdnoreturn = yes; then
 809 AC_CACHE_CHECK([for C11 _Noreturn feature], cf_cv_c11_noreturn,
 810         [AC_TRY_COMPILE([
 811 #include <stdio.h>
 812 #include <stdlib.h>
 813 #include <stdnoreturn.h>
 814 static _Noreturn void giveup(void) { exit(0); }
 815         ],
 816         [if (feof(stdin)) giveup()],
 817         cf_cv_c11_noreturn=yes,
 818         cf_cv_c11_noreturn=no)
 819         ])
 820 else
 821         cf_cv_c11_noreturn=no,
 822 fi
 823
 824 if test "$cf_cv_c11_noreturn" = yes; then
 825         AC_DEFINE(HAVE_STDNORETURN_H, 1,[Define if <stdnoreturn.h> header is available and working])
 826         AC_DEFINE_UNQUOTED(STDC_NORETURN,_Noreturn,[Define if C11 _Noreturn keyword is supported])
 827         HAVE_STDNORETURN_H=1
 828 else
 829         HAVE_STDNORETURN_H=0
 830 fi
 831
 832 AC_SUBST(HAVE_STDNORETURN_H)
 833 AC_SUBST(STDC_NORETURN)
 834 ])dnl
 835 dnl ---------------------------------------------------------------------------
 836 dnl CF_CC_ENV_FLAGS version: 10 updated: 2020/12/31 18:40:20
 837 dnl ---------------
 838 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 839 dnl into CC.  This will not help with broken scripts that wrap the compiler
 840 dnl with options, but eliminates a more common category of user confusion.
 841 dnl
 842 dnl In particular, it addresses the problem of being able to run the C
 843 dnl preprocessor in a consistent manner.
 844 dnl
 845 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 846 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 847 dnl outweighs that limitation.
 848 AC_DEFUN([CF_CC_ENV_FLAGS],
 849 [
 850 # This should have been defined by AC_PROG_CC
 851 : "${CC:=cc}"
 852
 853 AC_MSG_CHECKING(\$CFLAGS variable)
 854 case "x$CFLAGS" in
 855 (*-[[IUD]]*)
 856         AC_MSG_RESULT(broken)
 857         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
 858         cf_flags="$CFLAGS"
 859         CFLAGS=
 860         for cf_arg in $cf_flags
 861         do
 862                 CF_ADD_CFLAGS($cf_arg)
 863         done
 864         ;;
 865 (*)
 866         AC_MSG_RESULT(ok)
 867         ;;
 868 esac
 869
 870 AC_MSG_CHECKING(\$CC variable)
 871 case "$CC" in
 872 (*[[\ \ ]]-*)
 873         AC_MSG_RESULT(broken)
 874         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
 875         # humor him...
 876         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 877         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
 878         CC="$cf_prog"
 879         for cf_arg in $cf_flags
 880         do
 881                 case "x$cf_arg" in
 882                 (x-[[IUDfgOW]]*)
 883                         CF_ADD_CFLAGS($cf_arg)
 884                         ;;
 885                 (*)
 886                         CC="$CC $cf_arg"
 887                         ;;
 888                 esac
 889         done
 890         CF_VERBOSE(resulting CC: '$CC')
 891         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 892         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 893         ;;
 894 (*)
 895         AC_MSG_RESULT(ok)
 896         ;;
 897 esac
 898 ])dnl
 899 dnl ---------------------------------------------------------------------------
 900 dnl CF_CFG_DEFAULTS version: 16 updated: 2021/01/04 19:33:05
 901 dnl ---------------
 902 dnl Determine the default configuration into which we'll install ncurses.  This
 903 dnl can be overridden by the user's command-line options.  There's two items to
 904 dnl look for:
 905 dnl     1. the prefix (e.g., /usr)
 906 dnl     2. the header files (e.g., /usr/include/ncurses)
 907 dnl We'll look for a previous installation of ncurses and use the same defaults.
 908 dnl
 909 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 910 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 911 dnl programs from a vendor's.
 912 AC_DEFUN([CF_CFG_DEFAULTS],
 913 [AC_REQUIRE([AC_PROG_FGREP])dnl
 914
 915 AC_MSG_CHECKING(for prefix)
 916 if test "x$prefix" = "xNONE" ; then
 917         case "$cf_cv_system_name" in
 918                 # non-vendor systems don't have a conflict
 919         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 920                 prefix=/usr
 921                 ;;
 922         (*)     prefix=$ac_default_prefix
 923                 ;;
 924         esac
 925 fi
 926 AC_MSG_RESULT($prefix)
 927
 928 if test "x$prefix" = "xNONE" ; then
 929 AC_MSG_CHECKING(for default include-directory)
 930 test -n "$verbose" && echo 1>&AC_FD_MSG
 931 for cf_symbol in \
 932         "$includedir" \
 933         "$includedir/ncurses" \
 934         "$prefix/include" \
 935         "$prefix/include/ncurses" \
 936         /usr/local/include \
 937         /usr/local/include/ncurses \
 938         /usr/include \
 939         /usr/include/ncurses
 940 do
 941         cf_dir=`eval echo "$cf_symbol"`
 942         if test -f "$cf_dir/curses.h" ; then
 943         if ( ${FGREP-fgrep} NCURSES_VERSION "$cf_dir/curses.h" >/dev/null 2>&1 ) ; then
 944                 includedir="$cf_symbol"
 945                 test -n "$verbose"  && echo $ECHO_N "   found " 1>&AC_FD_MSG
 946                 break
 947         fi
 948         fi
 949         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 950 done
 951 AC_MSG_RESULT($includedir)
 952 fi
 953 ])dnl
 954 dnl ---------------------------------------------------------------------------
 955 dnl CF_CGETENT version: 6 updated: 2017/01/21 11:06:25
 956 dnl ----------
 957 dnl Check if the terminal-capability database functions are available.  If not,
 958 dnl ncurses has a much-reduced version.
 959 AC_DEFUN([CF_CGETENT],[
 960 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 961 AC_TRY_LINK([
 962 #include <stdlib.h>],[
 963         char temp[128];
 964         char *buf = temp;
 965         char *db_array = temp;
 966         cgetent(&buf, &db_array, "vt100");
 967         cgetcap(buf, "tc", '=');
 968         cgetmatch(buf, "tc");
 969         ],
 970         [cf_cv_cgetent=yes],
 971         [cf_cv_cgetent=no])
 972 ])
 973
 974 if test "$cf_cv_cgetent" = yes
 975 then
 976         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 977 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 978 AC_TRY_LINK([
 979 #pragma GCC diagnostic error "-Wincompatible-pointer-types-discards-qualifiers"
 980 #include <stdlib.h>],[
 981         char temp[128];
 982         char *buf = temp;
 983 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 984         const char *db_array = temp;
 985         cgetent(&buf, &db_array, "vt100");
 986 #endif
 987         cgetcap(buf, "tc", '=');
 988         cgetmatch(buf, "tc");
 989         ],
 990         [cf_cv_cgetent_const=yes],
 991         [cf_cv_cgetent_const=no])
 992 ])
 993         if test "$cf_cv_cgetent_const" = yes
 994         then
 995                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 996         fi
 997 fi
 998 ])dnl
 999 dnl ---------------------------------------------------------------------------
1000 dnl CF_CHECK_CACHE version: 13 updated: 2020/12/31 10:54:15
1001 dnl --------------
1002 dnl Check if we're accidentally using a cache from a different machine.
1003 dnl Derive the system name, as a check for reusing the autoconf cache.
1004 dnl
1005 dnl If we've packaged config.guess and config.sub, run that (since it does a
1006 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
1007 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
1008 dnl which is useful in cross-compiles.
1009 dnl
1010 dnl Note: we would use $ac_config_sub, but that is one of the places where
1011 dnl autoconf 2.5x broke compatibility with autoconf 2.13
1012 AC_DEFUN([CF_CHECK_CACHE],
1013 [
1014 if test -f "$srcdir/config.guess" || test -f "$ac_aux_dir/config.guess" ; then
1015         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
1016         system_name="$host_os"
1017 else
1018         system_name="`(uname -s -r) 2>/dev/null`"
1019         if test -z "$system_name" ; then
1020                 system_name="`(hostname) 2>/dev/null`"
1021         fi
1022 fi
1023 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
1024 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
1025
1026 test -z "$system_name" && system_name="$cf_cv_system_name"
1027 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
1028
1029 if test ".$system_name" != ".$cf_cv_system_name" ; then
1030         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
1031         AC_MSG_ERROR("Please remove config.cache and try again.")
1032 fi
1033 ])dnl
1034 dnl ---------------------------------------------------------------------------
1035 dnl CF_CHECK_ENVIRON version: 3 updated: 2010/05/26 16:44:57
1036 dnl ----------------
1037 dnl Check for data that is usually declared in <unistd.h>, e.g., the 'environ'
1038 dnl variable.  Define a DECL_xxx symbol if we must declare it ourselves.
1039 dnl
1040 dnl $1 = the name to check
1041 dnl $2 = the assumed type
1042 AC_DEFUN([CF_CHECK_ENVIRON],
1043 [
1044 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
1045     AC_TRY_COMPILE([
1046 #ifdef HAVE_STDLIB_H
1047 #include <stdlib.h>
1048 #endif
1049 #include <unistd.h> ],
1050     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
1051     [cf_cv_dcl_$1=yes],
1052     [cf_cv_dcl_$1=no])
1053 ])
1054
1055 if test "$cf_cv_dcl_$1" = no ; then
1056     CF_UPPER(cf_result,decl_$1)
1057     AC_DEFINE_UNQUOTED($cf_result)
1058 fi
1059
1060 # It's possible (for near-UNIX clones) that the data doesn't exist
1061 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
1062 ])dnl
1063 dnl ---------------------------------------------------------------------------
1064 dnl CF_CHECK_ERRNO version: 13 updated: 2020/03/10 18:53:47
1065 dnl --------------
1066 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
1067 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
1068 dnl ourselves.
1069 dnl
1070 dnl $1 = the name to check
1071 dnl $2 = the assumed type
1072 AC_DEFUN([CF_CHECK_ERRNO],
1073 [
1074 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
1075         AC_TRY_COMPILE([
1076 #ifdef HAVE_STDLIB_H
1077 #include <stdlib.h>
1078 #endif
1079 #include <stdio.h>
1080 #include <sys/types.h>
1081 #include <errno.h> ],
1082         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1; (void)x,
1083         [cf_cv_dcl_$1=yes],
1084         [cf_cv_dcl_$1=no])
1085 ])
1086
1087 if test "$cf_cv_dcl_$1" = no ; then
1088         CF_UPPER(cf_result,decl_$1)
1089         AC_DEFINE_UNQUOTED($cf_result)
1090 fi
1091
1092 # It's possible (for near-UNIX clones) that the data doesn't exist
1093 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
1094 ])dnl
1095 dnl ---------------------------------------------------------------------------
1096 dnl CF_CHECK_EXTERN_DATA version: 4 updated: 2015/04/18 08:56:57
1097 dnl --------------------
1098 dnl Check for existence of external data in the current set of libraries.  If
1099 dnl we can modify it, it's real enough.
1100 dnl $1 = the name to check
1101 dnl $2 = its type
1102 AC_DEFUN([CF_CHECK_EXTERN_DATA],
1103 [
1104 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
1105         AC_TRY_LINK([
1106 #undef $1
1107 extern $2 $1;
1108 ],
1109         [$1 = 2],
1110         [cf_cv_have_$1=yes],
1111         [cf_cv_have_$1=no])
1112 ])
1113
1114 if test "$cf_cv_have_$1" = yes ; then
1115         CF_UPPER(cf_result,have_$1)
1116         AC_DEFINE_UNQUOTED($cf_result)
1117 fi
1118
1119 ])dnl
1120 dnl ---------------------------------------------------------------------------
1121 dnl CF_CHECK_FVISIBILITY version: 2 updated: 2020/04/04 16:16:13
1122 dnl --------------------
1123 dnl Check whether the compiler understands -fvisibility=hidden
1124 dnl
1125 dnl $1 = compiler
1126 dnl $2 = compiler-flags variable name
1127 dnl $3 = cache variable to set
1128 AC_DEFUN([CF_CHECK_FVISIBILITY],[
1129 AC_CACHE_CHECK(if $1 -fvisibility=hidden option works,$3,[
1130     cf_save_cflags="[$]$2"
1131     $2="[$]$2 -fvisibility=hidden"
1132     AC_TRY_LINK([
1133 __attribute__ ((visibility("default"))) int somefunc() {return 42;}
1134         ],[
1135         if (somefunc()) return 1;
1136 ],
1137     [$3=yes],
1138     [$3=no])
1139     $2=$cf_save_cflags
1140 ])
1141 ])dnl
1142 dnl ---------------------------------------------------------------------------
1143 dnl CF_CHECK_GETENV version: 2 updated: 2021/01/02 17:09:14
1144 dnl ---------------
1145 dnl Check if repeated getenv calls return the same pointer, e.g., it does not
1146 dnl discard the previous pointer when returning a new one.
1147 AC_DEFUN([CF_CHECK_GETENV],
1148 [
1149 AC_REQUIRE([CF_CHECK_ENVIRON])
1150 AC_CHECK_FUNC( getenv, ,, AC_MSG_ERROR(getenv not found) )
1151 AC_CHECK_FUNCS( putenv setenv strdup )
1152 AC_CACHE_CHECK(if getenv returns consistent values,cf_cv_consistent_getenv,[
1153 AC_TRY_RUN([
1154 #include <stdlib.h>
1155 #include <unistd.h>
1156 #include <stdio.h>
1157 #include <string.h>
1158 #include <sys/types.h>
1159
1160 #if defined(HAVE_ENVIRON) && defined(DECL_ENVIRON) && !defined(environ)
1161 extern char **environ;  /* POSIX, but some systems are not... */
1162 #endif
1163
1164 #if defined(HAVE_STRDUP)
1165 #define str_alloc(s) strdup(s)
1166 #else
1167 #define str_alloc(s) strcpy(malloc(strlen(s) + 1, s))
1168 #endif
1169
1170 static void set_value(const char *name, const char *value)
1171 {
1172 #if defined(HAVE_SETENV)
1173         setenv(name, value, 1);
1174 #elif defined(HAVE_PUTENV)
1175         char buffer[1024];
1176         sprintf(buffer, "%s=%s", name, value);
1177         putenv(str_alloc(buffer));
1178 #else
1179 #error neither putenv/setenv found
1180 #endif
1181 }
1182 int main(void)
1183 {
1184         int pass;
1185         size_t numenv, limit, j;
1186         char **mynames;
1187         char **myvalues;
1188         char **mypointer;
1189         char *equals;
1190         for (numenv = 0; environ[numenv]; ++numenv) ;
1191         limit = numenv + 10;
1192         mynames = (char **) calloc(limit + 1, sizeof(char *));
1193         myvalues = (char **) calloc(limit + 1, sizeof(char *));
1194         mypointer = (char **) calloc(limit + 1, sizeof(char *));
1195 #if defined(HAVE_ENVIRON)
1196         for (j = 0; environ[j]; ++j) {
1197                 mynames[j] = str_alloc(environ[j]);
1198                 equals = strchr(mynames[j], '=');
1199                 if (equals != 0) {
1200                         *equals++ = '\\0';
1201                         myvalues[j] = str_alloc(equals);
1202                 } else {
1203                         myvalues[j] = str_alloc("");
1204                 }
1205         }
1206 #endif
1207         for (j = numenv; j < limit; ++j) {
1208                 char name[80];
1209                 char value[80];
1210                 size_t found;
1211                 size_t k = 0;
1212                 do {
1213                         size_t jk;
1214                         found = 0;
1215                         sprintf(name, "TERM%lu", (unsigned long) k);
1216                         for (jk = 0; jk < j; ++jk) {
1217                                 if (!strcmp(name, mynames[jk])) {
1218                                         found = 1;
1219                                         ++k;
1220                                         break;
1221                                 }
1222                         }
1223                 } while (found);
1224                 sprintf(value, "%lu:%p", (unsigned long) k, &mynames[j]);
1225                 set_value(name, value);
1226                 mynames[j] = str_alloc(name);
1227                 myvalues[j] = str_alloc(value);
1228         }
1229         for (pass = 0; pass < 3; ++pass) {
1230                 for (j = 0; j < limit; ++j) {
1231                         char *value = getenv(mynames[j]);
1232                         if (pass) {
1233                                 if (value == 0) {
1234                                         fprintf(stderr, "getenv returned null for %s\\n", mynames[j]);
1235                                         ${cf_cv_main_return:-return}(1);
1236                                 } else if (value != mypointer[j]) {
1237                                         fprintf(stderr, "getenv returned different pointer for %s\\n", mynames[j]);
1238                                         ${cf_cv_main_return:-return}(1);
1239                                 } else if (strcmp(value, myvalues[j])) {
1240                                         fprintf(stderr, "getenv returned different value for %s\\n", mynames[j]);
1241                                         ${cf_cv_main_return:-return}(1);
1242                                 }
1243                         } else {
1244                                 size_t k;
1245                                 mypointer[j] = value;
1246                                 for (k = 0; k < j; ++k) {
1247                                         if (mypointer[j] == mypointer[k]) {
1248                                                 fprintf(stderr, "getenv returned same pointer for %s and %s\\n", mynames[j], mynames[k]);
1249                                                 ${cf_cv_main_return:-return}(1);
1250                                         }
1251                                 }
1252                         }
1253                 }
1254         }
1255         ${cf_cv_main_return:-return}(0);
1256 }
1257 ],
1258 [cf_cv_consistent_getenv=yes],
1259 [cf_cv_consistent_getenv=no],
1260 [cf_cv_consistent_getenv=unknown])
1261 ])
1262
1263 if test "x$cf_cv_consistent_getenv" = xno
1264 then
1265         AC_DEFINE(HAVE_CONSISTENT_GETENV,1,[Define to 1 if getenv repeatably returns the same value for a given name])
1266 fi
1267 ])dnl
1268 dnl ---------------------------------------------------------------------------
1269 dnl CF_CHECK_GNAT_VERSION version: 4 updated: 2021/01/01 13:31:04
1270 dnl ---------------------
1271 AC_DEFUN([CF_CHECK_GNAT_VERSION],
1272 [
1273 AC_REQUIRE([CF_GNAT_VERSION])
1274 case "$cf_cv_gnat_version" in
1275 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
1276         cf_cv_prog_gnat_correct=yes
1277         ;;
1278 (*)
1279         AC_MSG_WARN(Unsupported GNAT version $cf_cv_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1280         cf_cv_prog_gnat_correct=no
1281         ;;
1282 esac
1283 ])
1284 dnl ---------------------------------------------------------------------------
1285 dnl CF_CHECK_GPM_WGETCH version: 6 updated: 2021/01/04 18:48:01
1286 dnl -------------------
1287 dnl Check if GPM is already linked with curses.  If so - and if the linkage
1288 dnl is not "weak" - warn about this because it can create problems linking
1289 dnl applications with ncurses.
1290 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
1291 AC_REQUIRE([AC_PROG_EGREP])dnl
1292
1293 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
1294
1295 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
1296 cf_cv_check_gpm_wgetch=unknown
1297 if test "$cross_compiling" != yes ; then
1298
1299 cat >conftest.$ac_ext <<CF_EOF
1300 #include <gpm.h>
1301 int main(void)
1302 {
1303         Gpm_Wgetch();
1304         ${cf_cv_main_return:-return}(0);
1305 }
1306 CF_EOF
1307
1308         cf_save_LIBS="$LIBS"
1309         # This only works if we can look at the symbol table.  If a shared
1310         # library is stripped for install, we cannot use that.  So we're forced
1311         # to rely on the static library, noting that some packagers may not
1312         # include it.
1313         LIBS="-static -lgpm -dynamic $LIBS"
1314         if AC_TRY_EVAL(ac_compile) ; then
1315                 if AC_TRY_EVAL(ac_link) ; then
1316                         cf_cv_check_gpm_wgetch="`nm \"conftest$ac_exeext\" | ${EGREP-egrep} '\<wgetch\>' | ${EGREP-egrep} '\<[[vVwW]]\>'`"
1317                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
1318                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
1319                 fi
1320         fi
1321         rm -rf ./conftest*
1322         LIBS="$cf_save_LIBS"
1323 fi
1324 ])
1325
1326 if test "$cf_cv_check_gpm_wgetch" != yes ; then
1327         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
1328 fi
1329 ])])dnl
1330 dnl ---------------------------------------------------------------------------
1331 dnl CF_CHECK_LIBTOOL_VERSION version: 2 updated: 2021/05/01 16:24:34
1332 dnl ------------------------
1333 dnl Show the version of libtool
1334 dnl
1335 dnl Save the version in a cache variable - this is not entirely a good thing,
1336 dnl but the version string from libtool is very ugly, and for bug reports it
1337 dnl might be useful to have the original string.
1338 dnl
1339 dnl There is an imitation in OpenBSD, which has no apparent use other than to
1340 dnl deny that it is GNU libtool.  Just ignore it.
1341 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
1342 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
1343 then
1344         AC_MSG_CHECKING(version of $LIBTOOL)
1345         CF_LIBTOOL_VERSION
1346         AC_MSG_RESULT($cf_cv_libtool_version)
1347         if test -n "$cf_cv_libtool_version"
1348         then
1349                 cf_check_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' -e 's,[[()]],...,g' -e 's,[[ ]],-,g' -e '2,$d'`
1350                 case "x$cf_check_libtool_version" in
1351                 (*...GNU-libtool...*)
1352                         ;;
1353                 (*)
1354                         AC_MSG_ERROR(This is not GNU libtool)
1355                         ;;
1356                 esac
1357         else
1358                 AC_MSG_ERROR(No version found for $LIBTOOL)
1359         fi
1360 else
1361         AC_MSG_ERROR(GNU libtool has not been found)
1362 fi
1363 ])dnl
1364 dnl ---------------------------------------------------------------------------
1365 dnl CF_CHECK_WCHAR_H version: 3 updated: 2021/01/01 13:31:04
1366 dnl ----------------
1367 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
1368 AC_DEFUN([CF_CHECK_WCHAR_H],[
1369 AC_CHECK_HEADERS( \
1370 wchar.h \
1371 wctype.h \
1372 )
1373 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1374 AC_TRY_COMPILE(
1375 [
1376 #include <stdlib.h>
1377 #ifdef HAVE_WCHAR_H
1378 #include <wchar.h>
1379 #endif
1380 #ifdef HAVE_WCTYPE_H
1381 #include <wctype.h>
1382 #endif
1383 ],[
1384         wint_t foo = 0;
1385         int bar = iswpunct(foo)],
1386         [cf_cv_wchar_h_okay=yes],
1387         [cf_cv_wchar_h_okay=no])])
1388
1389 if test "$cf_cv_wchar_h_okay" = no
1390 then
1391         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1392 fi
1393 ])dnl
1394 dnl ---------------------------------------------------------------------------
1395 dnl CF_CHECK_WCWIDTH_GRAPHICS version: 2 updated: 2021/01/02 17:09:14
1396 dnl -------------------------
1397 dnl Most "modern" terminal emulators are based to some degree on VT100, and
1398 dnl should support line-drawing.  Even with Unicode.  There is a problem.
1399 dnl
1400 dnl While most of the VT100 graphics characters were incorporated into Unicode,
1401 dnl all of those were combined into a page of useful graphics characters.
1402 dnl
1403 dnl So far, so good.
1404 dnl
1405 dnl However, while they are useful, there are other considerations.  CJK
1406 dnl is (because of poor device resolution) often rendered as double-width
1407 dnl characters.  So... for these generally-useful characters, what should
1408 dnl be the width (to make them consistent with adjacent characters)?
1409 dnl
1410 dnl The obvious choice would have been to make this locale-dependent, and use
1411 dnl wcwidth() to tell applications what the actual width is.  That was too
1412 dnl obvious.  Instead, we have a slew of "ambiguous-width" characters.
1413 dnl See for example
1414 dnl             http://www.unicode.org/reports/tr11/tr11-29.html
1415 dnl             http://www.cl.cam.ac.uk/~mgk25/ucs/scw-proposal.html
1416 dnl
1417 dnl The EastAsianWidth-6.2.0.txt file from the Unicode organization lists
1418 dnl more than 22,000 characters, with 1281 of those as ambiguous-width.  For
1419 dnl instance, it lists half (44/96) of the Latin-1 characters as
1420 dnl ambiguous-width.  Also, all of the box-characters at 0x2500 are ambiguous.
1421 dnl
1422 dnl What this means for the implementor is that on some systems wcwidth() can
1423 dnl give bad advice.  On Solaris, some of the ambiguous widths are returned as
1424 dnl 1 (the Latin-1 characters), while others are returned as 2 (line-drawing
1425 dnl characters).  These do not necessarily match the behavior of the terminal
1426 dnl emulator.  xterm, for instance, does an optional startup check to find if
1427 dnl this problem (or similar) exists with the system's locale tables, rejecting
1428 dnl them if they are too unreliable.
1429 AC_DEFUN([CF_CHECK_WCWIDTH_GRAPHICS],[
1430 AC_CACHE_CHECK(if wcwidth agrees graphics are single-width, cf_cv_wcwidth_graphics,[
1431 cat >conftest.in <<CF_EOF
1432 -       VT100 symbols
1433 0x250c  upper left corner
1434 0x2514  lower left corner
1435 0x2510  upper right corner
1436 0x2518  lower right corner
1437 0x251c  tee pointing left
1438 0x2524  tee pointing right
1439 0x2534  tee pointing up
1440 0x252c  tee pointing down
1441 0x2500  horizontal line
1442 0x2502  vertical line
1443 0x253c  large plus or crossover
1444 0x23ba  scan line 1
1445 0x23bd  scan line 9
1446 0x25c6  diamond
1447 0x2592  checker board (stipple)
1448 0x00b0  degree symbol
1449 0x00b1  plus/minus
1450 0x00b7  bullet
1451 -       Teletype 5410v1 symbols
1452 0x2190  arrow pointing left
1453 0x2192  arrow pointing right
1454 0x2193  arrow pointing down
1455 0x2191  arrow pointing up
1456 0x2592  board of squares
1457 0x2603  lantern symbol
1458 0x25ae  solid square block
1459 -       these defaults were invented for ncurses
1460 0x23bb  scan line 3
1461 0x23bc  scan line 7
1462 0x2264  less-than-or-equal-to
1463 0x2265  greater-than-or-equal-to
1464 0x03c0  greek pi
1465 0x2260  not-equal
1466 0x00a3  pound-sterling symbol
1467 -       thick-line-drawing
1468 0x250f  upper left corner
1469 0x2517  lower left corner
1470 0x2513  upper right corner
1471 0x251b  lower right corner
1472 0x2523  tee pointing left
1473 0x252b  tee pointing right
1474 0x253b  tee pointing up
1475 0x2533  tee pointing down
1476 0x2501  horizontal line
1477 0x2503  vertical line
1478 0x254b  large plus or crossover
1479 -       double-line-drawing
1480 0x2554  upper left corner
1481 0x255a  lower left corner
1482 0x2557  upper right corner
1483 0x255d  lower right corner
1484 0x2563  tee pointing left
1485 0x2560  tee pointing right
1486 0x2569  tee pointing up
1487 0x2566  tee pointing down
1488 0x2550  horizontal line
1489 0x2551  vertical line
1490 0x256c  large plus or crossover
1491 CF_EOF
1492 AC_TRY_RUN([
1493 #include <locale.h>
1494 #include <stdio.h>
1495 #include <wchar.h>
1496
1497 #define MY_LEN 80
1498
1499 int
1500 main(void)
1501 {
1502         FILE *fp;
1503         int value;
1504         char buffer[MY_LEN + 1];
1505         char notes[MY_LEN + 1];
1506         int totals = 0;
1507         int passed = 0;
1508
1509         if (setlocale(LC_ALL, "en_US.UTF8") ||
1510                 setlocale(LC_ALL, "en_US.UTF-8") ||
1511                 setlocale(LC_ALL, "en_US.utf8") ||
1512                 setlocale(LC_ALL, "en_US.utf-8")) {
1513                 if ((fp = fopen("conftest.in", "r")) != 0) {
1514                         while (fgets(buffer, MY_LEN, fp) != 0) {
1515                                 if (*buffer == '-') {
1516                                         fprintf(stderr, "\\t%s", buffer);
1517                                 } else if (sscanf(buffer, "%x %s", &value, notes) == 2) {
1518                                         ++totals;
1519                                         if (wcwidth(value) == 1)
1520                                                 ++passed;
1521                                         fprintf(stderr, "%d\\t%s", wcwidth(value), buffer);
1522                                 } else {
1523                                         fprintf(stderr, "?\\t%s", buffer);
1524                                 }
1525                         }
1526                 }
1527         }
1528         fprintf(stderr, "%d/%d passed wcwidth/graphics check\\n", passed, totals);
1529         return (totals == passed) ? 0 : 1;
1530 }
1531 ],
1532 [cf_cv_wcwidth_graphics=yes],
1533 [cf_cv_wcwidth_graphics=no],
1534 [cf_cv_wcwidth_graphics=unknown])
1535 ])
1536 ])dnl
1537 dnl ---------------------------------------------------------------------------
1538 dnl CF_CLANG_COMPILER version: 8 updated: 2021/01/01 13:31:04
1539 dnl -----------------
1540 dnl Check if the given compiler is really clang.  clang's C driver defines
1541 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1542 dnl not ignore some gcc options.
1543 dnl
1544 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1545 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1546 dnl the wrappers for gcc and g++ warnings.
1547 dnl
1548 dnl $1 = GCC (default) or GXX
1549 dnl $2 = CLANG_COMPILER (default)
1550 dnl $3 = CFLAGS (default) or CXXFLAGS
1551 AC_DEFUN([CF_CLANG_COMPILER],[
1552 ifelse([$2],,CLANG_COMPILER,[$2])=no
1553
1554 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1555         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1556         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1557         AC_TRY_COMPILE([],[
1558 #ifdef __clang__
1559 #else
1560 make an error
1561 #endif
1562 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1563 ],[])
1564         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1565         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1566 fi
1567
1568 CLANG_VERSION=none
1569
1570 if test "x$ifelse([$2],,CLANG_COMPILER,[$2])" = "xyes" ; then
1571         case "$CC" in
1572         (c[[1-9]][[0-9]]|*/c[[1-9]][[0-9]])
1573                 AC_MSG_WARN(replacing broken compiler alias $CC)
1574                 CFLAGS="$CFLAGS -std=`echo "$CC" | sed -e 's%.*/%%'`"
1575                 CC=clang
1576                 ;;
1577         esac
1578
1579         AC_MSG_CHECKING(version of $CC)
1580         CLANG_VERSION="`$CC --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(CLANG[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1581         test -z "$CLANG_VERSION" && CLANG_VERSION=unknown
1582         AC_MSG_RESULT($CLANG_VERSION)
1583
1584         for cf_clang_opt in \
1585                 -Qunused-arguments \
1586                 -Wno-error=implicit-function-declaration
1587         do
1588                 AC_MSG_CHECKING(if option $cf_clang_opt works)
1589                 cf_save_CFLAGS="$CFLAGS"
1590                 CFLAGS="$CFLAGS $cf_clang_opt"
1591                 AC_TRY_LINK([
1592                         #include <stdio.h>],[
1593                         printf("hello!\\n");],[
1594                         cf_clang_optok=yes],[
1595                         cf_clang_optok=no])
1596                 AC_MSG_RESULT($cf_clang_optok)
1597                 CFLAGS="$cf_save_CFLAGS"
1598                 if test "$cf_clang_optok" = yes; then
1599                         CF_VERBOSE(adding option $cf_clang_opt)
1600                         CF_APPEND_TEXT(CFLAGS,$cf_clang_opt)
1601                 fi
1602         done
1603 fi
1604 ])
1605 dnl ---------------------------------------------------------------------------
1606 dnl CF_CONST_X_STRING version: 6 updated: 2021/01/01 13:31:04
1607 dnl -----------------
1608 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
1609 dnl character-strings.
1610 dnl
1611 dnl It is ambiguous because the specification accommodated the pre-ANSI
1612 dnl compilers bundled by more than one vendor in lieu of providing a standard C
1613 dnl compiler other than by costly add-ons.  Because of this, the specification
1614 dnl did not take into account the use of const for telling the compiler that
1615 dnl string literals would be in readonly memory.
1616 dnl
1617 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
1618 dnl let the compiler decide how to represent Xt's strings which were #define'd.
1619 dnl That does not solve the problem of using the block of Xt's strings which
1620 dnl are compiled into the library (and is less efficient than one might want).
1621 dnl
1622 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
1623 dnl when compiling the library and compiling using the library, to tell the
1624 dnl compiler that String is const.
1625 AC_DEFUN([CF_CONST_X_STRING],
1626 [
1627 AC_REQUIRE([AC_PATH_XTRA])
1628
1629 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
1630
1631 AC_TRY_COMPILE(
1632 [
1633 #include <stdlib.h>
1634 #include <X11/Intrinsic.h>
1635 ],
1636 [String foo = malloc(1); (void)foo],[
1637
1638 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
1639         AC_TRY_COMPILE(
1640                 [
1641 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
1642 #undef  XTSTRINGDEFINES /* X11R5 and later */
1643 #include <stdlib.h>
1644 #include <X11/Intrinsic.h>
1645                 ],[String foo = malloc(1); *foo = 0],[
1646                         cf_cv_const_x_string=no
1647                 ],[
1648                         cf_cv_const_x_string=yes
1649                 ])
1650 ])
1651
1652 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
1653
1654 case "$cf_cv_const_x_string" in
1655 (no)
1656         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
1657         ;;
1658 (*)
1659         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
1660         ;;
1661 esac
1662
1663 ])
1664 ])dnl
1665 dnl ---------------------------------------------------------------------------
1666 dnl CF_CPP_PARAM_INIT version: 7 updated: 2017/01/21 11:06:25
1667 dnl -----------------
1668 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1669 dnl is a late feature for the standard and is not in some recent compilers
1670 dnl (1999/9/11).
1671 AC_DEFUN([CF_CPP_PARAM_INIT],
1672 [
1673 if test -n "$CXX"; then
1674 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1675         AC_LANG_SAVE
1676         AC_LANG_CPLUSPLUS
1677         AC_TRY_RUN([
1678 class TEST {
1679 private:
1680         int value;
1681 public:
1682         TEST(int x = 1);
1683         ~TEST();
1684 };
1685
1686 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1687 {
1688         value = x;
1689 }
1690 int main(void) { }
1691 ],
1692         [cf_cv_cpp_param_init=yes],
1693         [cf_cv_cpp_param_init=no],
1694         [cf_cv_cpp_param_init=unknown])
1695         AC_LANG_RESTORE
1696 ])
1697 fi
1698 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1699 ])dnl
1700 dnl ---------------------------------------------------------------------------
1701 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1702 dnl ------------------
1703 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1704 dnl not be supported in g++ before 3.0
1705 AC_DEFUN([CF_CPP_STATIC_CAST],
1706 [
1707 if test -n "$CXX"; then
1708
1709 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1710         AC_LANG_SAVE
1711         AC_LANG_CPLUSPLUS
1712
1713         AC_TRY_COMPILE([
1714 class NCursesPanel
1715 {
1716 public:
1717   NCursesPanel(int nlines,
1718                int ncols,
1719                int begin_y = 0,
1720                int begin_x = 0)
1721   {
1722   }
1723   NCursesPanel();
1724   ~NCursesPanel();
1725 };
1726
1727 template<class T> class NCursesUserPanel : public NCursesPanel
1728 {
1729 public:
1730   NCursesUserPanel (int nlines,
1731                     int ncols,
1732                     int begin_y = 0,
1733                     int begin_x = 0,
1734                     const T* p_UserData = static_cast<T*>(0))
1735     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1736   {
1737   };
1738   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1739   {
1740   };
1741
1742   virtual ~NCursesUserPanel() {};
1743 };
1744 ],[
1745         const char* p_UserData = static_cast<char*>(0)],
1746         [cf_cv_cpp_static_cast=yes],
1747         [cf_cv_cpp_static_cast=no])
1748
1749         AC_LANG_RESTORE
1750 ])
1751
1752 fi
1753
1754 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1755 ])dnl
1756 dnl ---------------------------------------------------------------------------
1757 dnl CF_CXX_AR_FLAGS version: 3 updated: 2021/01/01 13:31:04
1758 dnl ---------------
1759 dnl Setup special archiver flags for given compilers.
1760 AC_DEFUN([CF_CXX_AR_FLAGS],[
1761         CXX_AR='$(AR)'
1762         CXX_ARFLAGS='$(ARFLAGS)'
1763         case "$cf_cv_system_name" in
1764         (irix*)
1765             if test "$GXX" != yes ; then
1766                 CXX_AR='$(CXX)'
1767                 CXX_ARFLAGS='-ar -o'
1768             fi
1769             ;;
1770         (sco3.2v5*)
1771             CXXLDFLAGS="-u main"
1772             ;;
1773         (solaris2*)
1774             if test "$GXX" != yes ; then
1775                 CXX_AR='$(CXX)'
1776                 CXX_ARFLAGS='-xar -o'
1777             fi
1778             ;;
1779         esac
1780         AC_SUBST(CXXLDFLAGS)
1781         AC_SUBST(CXX_AR)
1782         AC_SUBST(CXX_ARFLAGS)
1783 ])dnl
1784 dnl ---------------------------------------------------------------------------
1785 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1786 dnl -------------------------
1787 dnl For c++, check if iostream uses "std::" namespace.
1788 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1789 AC_CHECK_HEADERS(iostream)
1790 if test x"$ac_cv_header_iostream" = xyes ; then
1791         AC_MSG_CHECKING(if iostream uses std-namespace)
1792         AC_TRY_COMPILE([
1793 #include <iostream>
1794 using std::endl;
1795 using std::cerr;],[
1796 cerr << "testing" << endl;
1797 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1798         AC_MSG_RESULT($cf_iostream_namespace)
1799         if test "$cf_iostream_namespace" = yes ; then
1800                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1801         fi
1802 fi
1803 ])dnl
1804 dnl ---------------------------------------------------------------------------
1805 dnl CF_C_INLINE version: 6 updated: 2019/09/07 13:38:36
1806 dnl -----------
1807 dnl Check if the C compiler supports "inline".
1808 dnl $1 is the name of a shell variable to set if inline is supported
1809 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1810 AC_DEFUN([CF_C_INLINE],[
1811 AC_REQUIRE([CF_GCC_VERSION])
1812 AC_C_INLINE
1813 $1=
1814 if test "$ac_cv_c_inline" != no ; then
1815         $1=inline
1816         if test "$INTEL_COMPILER" = yes
1817         then
1818                 :
1819         elif test "$CLANG_COMPILER" = yes
1820         then
1821                 :
1822         elif test "$GCC" = yes
1823         then
1824                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1825                 cf_save_CFLAGS=$CFLAGS
1826                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1827                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1828                 [${cf_cv_main_return:-return} foo()],
1829                 [cf_cv_gcc_inline=yes],
1830                 [cf_cv_gcc_inline=no])
1831                 CFLAGS=$cf_save_CFLAGS
1832                 ])
1833                 if test "$cf_cv_gcc_inline" = yes ; then
1834                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1835                 fi
1836         fi
1837 fi
1838 AC_SUBST($1)
1839 ])dnl
1840 dnl ---------------------------------------------------------------------------
1841 dnl CF_DIRNAME version: 5 updated: 2020/12/31 20:19:42
1842 dnl ----------
1843 dnl "dirname" is not portable, so we fake it with a shell script.
1844 AC_DEFUN([CF_DIRNAME],[$1=`echo "$2" | sed -e 's%/[[^/]]*$%%'`])dnl
1845 dnl ---------------------------------------------------------------------------
1846 dnl CF_DIRS_TO_MAKE version: 4 updated: 2021/01/01 13:31:04
1847 dnl ---------------
1848 AC_DEFUN([CF_DIRS_TO_MAKE],
1849 [
1850 DIRS_TO_MAKE="lib"
1851 for cf_item in $cf_list_models
1852 do
1853         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1854         for cf_item2 in $DIRS_TO_MAKE
1855         do
1856                 test "$cf_item2" = "$cf_subdir" && break
1857         done
1858         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1859 done
1860 for cf_dir in $DIRS_TO_MAKE
1861 do
1862         test ! -d "$cf_dir" && mkdir "$cf_dir"
1863 done
1864 AC_SUBST(DIRS_TO_MAKE)
1865 ])dnl
1866 dnl ---------------------------------------------------------------------------
1867 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1868 dnl ---------------
1869 dnl You can always use "make -n" to see the actual options, but it's hard to
1870 dnl pick out/analyze warning messages when the compile-line is long.
1871 dnl
1872 dnl Sets:
1873 dnl     ECHO_LT - symbol to control if libtool is verbose
1874 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1875 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1876 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1877 dnl     ECHO_CC - symbol to put before any "cc" line
1878 dnl
1879 AC_DEFUN([CF_DISABLE_ECHO],[
1880 AC_MSG_CHECKING(if you want to see long compiling messages)
1881 CF_ARG_DISABLE(echo,
1882         [  --disable-echo          do not display "compiling" commands],
1883         [
1884         ECHO_LT='--silent'
1885         ECHO_LD='@echo linking [$]@;'
1886         RULE_CC='@echo compiling [$]<'
1887         SHOW_CC='@echo compiling [$]@'
1888         ECHO_CC='@'
1889 ],[
1890         ECHO_LT=''
1891         ECHO_LD=''
1892         RULE_CC=''
1893         SHOW_CC=''
1894         ECHO_CC=''
1895 ])
1896 AC_MSG_RESULT($enableval)
1897 AC_SUBST(ECHO_LT)
1898 AC_SUBST(ECHO_LD)
1899 AC_SUBST(RULE_CC)
1900 AC_SUBST(SHOW_CC)
1901 AC_SUBST(ECHO_CC)
1902 ])dnl
1903 dnl ---------------------------------------------------------------------------
1904 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1905 dnl ------------------------
1906 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1907 AC_MSG_CHECKING(if we want to use GNAT projects)
1908 CF_ARG_DISABLE(gnat-projects,
1909         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1910         [enable_gnat_projects=no],
1911         [enable_gnat_projects=yes])
1912 AC_MSG_RESULT($enable_gnat_projects)
1913 ])dnl
1914 dnl ---------------------------------------------------------------------------
1915 dnl CF_DISABLE_LEAKS version: 9 updated: 2021/04/03 16:41:50
1916 dnl ----------------
1917 dnl Combine no-leak checks with the libraries or tools that are used for the
1918 dnl checks.
1919 AC_DEFUN([CF_DISABLE_LEAKS],[
1920
1921 AC_REQUIRE([CF_WITH_DMALLOC])
1922 AC_REQUIRE([CF_WITH_DBMALLOC])
1923 AC_REQUIRE([CF_WITH_VALGRIND])
1924
1925 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1926 AC_ARG_ENABLE(leaks,
1927         [  --disable-leaks         test: free permanent memory, analyze leaks],
1928         [enable_leaks=$enableval],
1929         [enable_leaks=yes])
1930 dnl with_no_leaks is more readable...
1931 if test "x$enable_leaks" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi
1932 AC_MSG_RESULT($with_no_leaks)
1933
1934 if test "$enable_leaks" = no ; then
1935         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1936         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1937 fi
1938 ])dnl
1939 dnl ---------------------------------------------------------------------------
1940 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
1941 dnl --------------------------
1942 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1943 dnl the older "-version-info" feature.  The newer feature allows us to use
1944 dnl version numbering on shared libraries which make them compatible with
1945 dnl various systems.
1946 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1947 [
1948 AC_MSG_CHECKING(if libtool -version-number should be used)
1949 CF_ARG_DISABLE(libtool-version,
1950         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1951         [cf_libtool_version=no],
1952         [cf_libtool_version=yes])
1953 AC_MSG_RESULT($cf_libtool_version)
1954
1955 if test "$cf_libtool_version" = yes ; then
1956         LIBTOOL_VERSION="-version-number"
1957 else
1958         LIBTOOL_VERSION="-version-info"
1959         case "x$VERSION" in
1960         (x)
1961                 AC_MSG_WARN(VERSION was not set)
1962                 ;;
1963         (x*.*.*)
1964                 ABI_VERSION="$VERSION"
1965                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1966                 ;;
1967         (x*:*:*)
1968                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
1969                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1970                 ;;
1971         (*)
1972                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
1973                 ;;
1974         esac
1975 fi
1976
1977 AC_SUBST(ABI_VERSION)
1978 AC_SUBST(LIBTOOL_VERSION)
1979 ])dnl
1980 dnl ---------------------------------------------------------------------------
1981 dnl CF_DISABLE_RPATH_HACK version: 3 updated: 2021/01/05 20:14:44
1982 dnl ---------------------
1983 dnl The rpath-hack makes it simpler to build programs, particularly with the
1984 dnl *BSD ports which may have essential libraries in unusual places.  But it
1985 dnl can interfere with building an executable for the base system.  Use this
1986 dnl option in that case.
1987 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1988 [
1989 AC_MSG_CHECKING(if rpath-hack should be disabled)
1990 CF_ARG_DISABLE(rpath-hack,
1991         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1992         [enable_rpath_hack=no],
1993         [enable_rpath_hack=yes])
1994 dnl TODO - drop cf_disable_rpath_hack
1995 if test "x$enable_rpath_hack" = xno; then cf_disable_rpath_hack=yes; else cf_disable_rpath_hack=no; fi
1996 AC_MSG_RESULT($cf_disable_rpath_hack)
1997
1998 if test "$enable_rpath_hack" = yes ; then
1999         CF_RPATH_HACK
2000 fi
2001 ])
2002 dnl ---------------------------------------------------------------------------
2003 dnl CF_ENABLE_BROKEN_LINKER version: 2 updated: 2021/01/02 17:09:14
2004 dnl -----------------------
2005 dnl Some linkers cannot reference a data-only object.  Cygwin used to be one.
2006 dnl This usually follows CF_LINK_DATAONLY, but is not required in case we need
2007 dnl an unconditional feature.
2008 AC_DEFUN([CF_ENABLE_BROKEN_LINKER],[
2009
2010 AC_MSG_CHECKING(if you want broken-linker support code)
2011 AC_ARG_ENABLE(broken_linker,
2012         [  --enable-broken_linker  compile with broken-linker support code],
2013         [with_broken_linker=$enableval],
2014         [with_broken_linker=no])
2015 AC_MSG_RESULT($with_broken_linker)
2016
2017 : "${BROKEN_LINKER:=0}"
2018 if test "x$with_broken_linker" = xyes ; then
2019         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
2020         BROKEN_LINKER=1
2021 fi
2022 AC_SUBST(BROKEN_LINKER)
2023 ])dnl
2024 dnl ---------------------------------------------------------------------------
2025 dnl CF_ENABLE_PC_FILES version: 13 updated: 2015/11/01 05:27:39
2026 dnl ------------------
2027 dnl This is the "--enable-pc-files" option, which is available if there is a
2028 dnl pkg-config configuration on the local machine.
2029 AC_DEFUN([CF_ENABLE_PC_FILES],[
2030 AC_REQUIRE([CF_PKG_CONFIG])
2031 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
2032
2033 if test "x$PKG_CONFIG" != xnone
2034 then
2035         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
2036 else
2037         AC_MSG_CHECKING(if we should install .pc files)
2038 fi
2039
2040 AC_ARG_ENABLE(pc-files,
2041         [  --enable-pc-files       generate and install .pc files for pkg-config],
2042         [enable_pc_files=$enableval],
2043         [enable_pc_files=no])
2044 AC_MSG_RESULT($enable_pc_files)
2045
2046 if test "x$enable_pc_files" != xno
2047 then
2048         MAKE_PC_FILES=
2049         case "x$PKG_CONFIG_LIBDIR" in
2050         (xno|xyes)
2051                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
2052                 ;;
2053         (*)
2054                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
2055                 ;;
2056         esac
2057 else
2058         MAKE_PC_FILES="#"
2059 fi
2060 AC_SUBST(MAKE_PC_FILES)
2061 ])dnl
2062 dnl ---------------------------------------------------------------------------
2063 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
2064 dnl ---------------
2065 dnl Check if the rpath option should be used, setting cache variable
2066 dnl cf_cv_enable_rpath if so.
2067 AC_DEFUN([CF_ENABLE_RPATH],
2068 [
2069 AC_MSG_CHECKING(if rpath option should be used)
2070 AC_ARG_ENABLE(rpath,
2071 [  --enable-rpath          use rpath option when generating shared libraries],
2072 [cf_cv_enable_rpath=$enableval],
2073 [cf_cv_enable_rpath=no])
2074 AC_MSG_RESULT($cf_cv_enable_rpath)
2075 ])dnl
2076 dnl ---------------------------------------------------------------------------
2077 dnl CF_ENABLE_STRING_HACKS version: 6 updated: 2021/01/05 19:23:48
2078 dnl ----------------------
2079 dnl On a few platforms, the compiler and/or loader nags with untruthful
2080 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
2081 dnl and implying that most uses of the recommended alternatives are correct.
2082 dnl
2083 dnl Factually speaking, no one has actually counted the number of uses of these
2084 dnl functions versus the total of incorrect uses.  Samples of a few thousand
2085 dnl instances are meaningless compared to the hundreds of millions of lines of
2086 dnl existing C code.
2087 dnl
2088 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
2089 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
2090 dnl standard - but evolved through phases, and older implementations are likely
2091 dnl to yield surprising results, as documented in manpages on various systems.
2092 AC_DEFUN([CF_ENABLE_STRING_HACKS],
2093 [
2094 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
2095 AC_ARG_ENABLE(string-hacks,
2096         [  --enable-string-hacks   work around bogus compiler/loader warnings],
2097         [enable_string_hacks=$enableval],
2098         [enable_string_hacks=no])
2099 AC_MSG_RESULT($enable_string_hacks)
2100
2101 if test "x$enable_string_hacks" = "xyes"; then
2102         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
2103         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
2104         AC_CHECK_FUNC(strlcat,[
2105                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
2106                 ],[
2107                 AC_CHECK_LIB(bsd,strlcat,[
2108                         CF_ADD_LIB(bsd)
2109                         AC_CHECK_HEADERS(bsd/string.h)
2110                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
2111                         ])
2112                 ])
2113         AC_CHECK_FUNCS( strlcpy snprintf )
2114 fi
2115 ])dnl
2116 dnl ---------------------------------------------------------------------------
2117 dnl CF_ENABLE_WARNINGS version: 9 updated: 2021/01/05 19:40:50
2118 dnl ------------------
2119 dnl Configure-option to enable gcc warnings
2120 dnl
2121 dnl $1 = extra options to add, if supported
2122 dnl $2 = option for checking attributes.  By default, this is done when
2123 dnl      warnings are enabled.  For other values:
2124 dnl      yes: always do this, e.g., to use in generated library-headers
2125 dnl      no: never do this
2126 AC_DEFUN([CF_ENABLE_WARNINGS],[
2127 if test "$GCC" = yes || test "$GXX" = yes
2128 then
2129 CF_FIX_WARNINGS(CFLAGS)
2130 CF_FIX_WARNINGS(CPPFLAGS)
2131 CF_FIX_WARNINGS(LDFLAGS)
2132 AC_MSG_CHECKING(if you want to turn on gcc warnings)
2133 CF_ARG_ENABLE(warnings,
2134         [  --enable-warnings       test: turn on gcc compiler warnings],
2135         [enable_warnings=yes],
2136         [enable_warnings=no])
2137 AC_MSG_RESULT($enable_warnings)
2138 if test "$enable_warnings" = "yes"
2139 then
2140         ifelse($2,,[CF_GCC_ATTRIBUTES])
2141         CF_GCC_WARNINGS($1)
2142 fi
2143 ifelse($2,yes,[CF_GCC_ATTRIBUTES])
2144 fi
2145 ])dnl
2146 dnl ---------------------------------------------------------------------------
2147 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
2148 dnl --------
2149 dnl Check if 'errno' is declared in <errno.h>
2150 AC_DEFUN([CF_ERRNO],
2151 [
2152 CF_CHECK_ERRNO(errno)
2153 ])dnl
2154 dnl ---------------------------------------------------------------------------
2155 dnl CF_ETIP_DEFINES version: 6 updated: 2021/01/02 17:09:14
2156 dnl ---------------
2157 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
2158 dnl math.h and builtin.h, only for ncurses
2159 AC_DEFUN([CF_ETIP_DEFINES],
2160 [
2161 AC_MSG_CHECKING(for special defines needed for etip.h)
2162 cf_save_CXXFLAGS="$CXXFLAGS"
2163 cf_result="none"
2164
2165 # etip.h includes ncurses.h which includes ncurses_dll.h
2166 # But ncurses_dll.h is generated - fix here.
2167 test -d include || mkdir include
2168 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' "${srcdir}/include/ncurses_dll.h.in" >include/ncurses_dll.h
2169
2170 for cf_math in "" MATH_H
2171 do
2172 for cf_excp in "" MATH_EXCEPTION
2173 do
2174         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
2175         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
2176         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
2177 AC_TRY_COMPILE([
2178 #include <etip.h.in>
2179 ],[],[
2180         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
2181         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
2182         cf_result="$cf_math $cf_excp"
2183         break 2
2184 ],[])
2185 done
2186 done
2187 AC_MSG_RESULT($cf_result)
2188 CXXFLAGS="$cf_save_CXXFLAGS"
2189 ])
2190 dnl ---------------------------------------------------------------------------
2191 dnl CF_FIND_LINKAGE version: 22 updated: 2020/12/31 20:19:42
2192 dnl ---------------
2193 dnl Find a library (specifically the linkage used in the code fragment),
2194 dnl searching for it if it is not already in the library path.
2195 dnl See also CF_ADD_SEARCHPATH.
2196 dnl
2197 dnl Parameters (4-on are optional):
2198 dnl     $1 = headers for library entrypoint
2199 dnl     $2 = code fragment for library entrypoint
2200 dnl     $3 = the library name without the "-l" option or ".so" suffix.
2201 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
2202 dnl     $5 = action to perform if not successful
2203 dnl     $6 = module name, if not the same as the library name
2204 dnl     $7 = extra libraries
2205 dnl
2206 dnl Sets these variables:
2207 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
2208 dnl     $cf_cv_header_path_$3 - include-directory if needed
2209 dnl     $cf_cv_library_path_$3 - library-directory if needed
2210 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
2211 AC_DEFUN([CF_FIND_LINKAGE],[
2212
2213 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
2214 # will be set on completion of the AC_TRY_LINK below.
2215 cf_cv_header_path_$3=
2216 cf_cv_library_path_$3=
2217
2218 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
2219
2220 cf_save_LIBS="$LIBS"
2221
2222 AC_TRY_LINK([$1],[$2],[
2223         cf_cv_find_linkage_$3=yes
2224         cf_cv_header_path_$3=/usr/include
2225         cf_cv_library_path_$3=/usr/lib
2226 ],[
2227
2228 LIBS="-l$3 $7 $cf_save_LIBS"
2229
2230 AC_TRY_LINK([$1],[$2],[
2231         cf_cv_find_linkage_$3=yes
2232         cf_cv_header_path_$3=/usr/include
2233         cf_cv_library_path_$3=/usr/lib
2234         cf_cv_library_file_$3="-l$3"
2235 ],[
2236         cf_cv_find_linkage_$3=no
2237         LIBS="$cf_save_LIBS"
2238
2239         CF_VERBOSE(find linkage for $3 library)
2240         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
2241
2242         cf_save_CPPFLAGS="$CPPFLAGS"
2243         cf_test_CPPFLAGS="$CPPFLAGS"
2244
2245         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
2246         for cf_cv_header_path_$3 in $cf_search
2247         do
2248                 if test -d "$cf_cv_header_path_$3" ; then
2249                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
2250                         CPPFLAGS="$cf_save_CPPFLAGS"
2251                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
2252                         AC_TRY_COMPILE([$1],[$2],[
2253                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
2254                                 cf_cv_find_linkage_$3=maybe
2255                                 cf_test_CPPFLAGS="$CPPFLAGS"
2256                                 break],[
2257                                 CPPFLAGS="$cf_save_CPPFLAGS"
2258                                 ])
2259                 fi
2260         done
2261
2262         if test "$cf_cv_find_linkage_$3" = maybe ; then
2263
2264                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
2265
2266                 cf_save_LIBS="$LIBS"
2267                 cf_save_LDFLAGS="$LDFLAGS"
2268
2269                 ifelse([$6],,,[
2270                 CPPFLAGS="$cf_test_CPPFLAGS"
2271                 LIBS="-l$3 $7 $cf_save_LIBS"
2272                 AC_TRY_LINK([$1],[$2],[
2273                         CF_VERBOSE(... found $3 library in system)
2274                         cf_cv_find_linkage_$3=yes])
2275                         CPPFLAGS="$cf_save_CPPFLAGS"
2276                         LIBS="$cf_save_LIBS"
2277                         ])
2278
2279                 if test "$cf_cv_find_linkage_$3" != yes ; then
2280                         CF_LIBRARY_PATH(cf_search,$3)
2281                         for cf_cv_library_path_$3 in $cf_search
2282                         do
2283                                 if test -d "$cf_cv_library_path_$3" ; then
2284                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
2285                                         CPPFLAGS="$cf_test_CPPFLAGS"
2286                                         LIBS="-l$3 $7 $cf_save_LIBS"
2287                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
2288                                         AC_TRY_LINK([$1],[$2],[
2289                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
2290                                         cf_cv_find_linkage_$3=yes
2291                                         cf_cv_library_file_$3="-l$3"
2292                                         break],[
2293                                         CPPFLAGS="$cf_save_CPPFLAGS"
2294                                         LIBS="$cf_save_LIBS"
2295                                         LDFLAGS="$cf_save_LDFLAGS"
2296                                         ])
2297                                 fi
2298                         done
2299                         CPPFLAGS="$cf_save_CPPFLAGS"
2300                         LDFLAGS="$cf_save_LDFLAGS"
2301                 fi
2302
2303         else
2304                 cf_cv_find_linkage_$3=no
2305         fi
2306         ],$7)
2307 ])
2308
2309 LIBS="$cf_save_LIBS"
2310
2311 if test "$cf_cv_find_linkage_$3" = yes ; then
2312 ifelse([$4],,[
2313         CF_ADD_INCDIR($cf_cv_header_path_$3)
2314         CF_ADD_LIBDIR($cf_cv_library_path_$3)
2315         CF_ADD_LIB($3)
2316 ],[$4])
2317 else
2318 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
2319 fi
2320 ])dnl
2321 dnl ---------------------------------------------------------------------------
2322 dnl CF_FIND_SUB_INCDIR version: 3 updated: 2021/01/01 13:31:04
2323 dnl ------------------
2324 dnl Find an include-directory with the given leaf-name.  This is useful for
2325 dnl example with FreeBSD ports, which use this convention to distinguish
2326 dnl different versions of the same port.
2327 AC_DEFUN([CF_FIND_SUB_INCDIR],[
2328         CF_SUBDIR_PATH(cf_search,$1,include)
2329         for cf_item in $cf_search
2330         do
2331                 case "$cf_item" in
2332                 (*/$1)
2333                         CF_ADD_INCDIR($cf_item)
2334                         ;;
2335                 esac
2336         done
2337 ])dnl
2338 dnl ---------------------------------------------------------------------------
2339 dnl CF_FIND_SUB_LIBDIR version: 3 updated: 2021/01/01 13:31:04
2340 dnl ------------------
2341 dnl Find a library-directory with the given leaf-name.  This is useful for
2342 dnl example with FreeBSD ports, which use this convention to distinguish
2343 dnl different versions of the same port.
2344 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
2345         CF_SUBDIR_PATH(cf_search,$1,lib)
2346         for cf_item in $cf_search
2347         do
2348                 case "$cf_item" in
2349                 (*/$1)
2350                         CF_ADD_LIBDIR($cf_item)
2351                         ;;
2352                 esac
2353         done
2354 ])dnl
2355 dnl ---------------------------------------------------------------------------
2356 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
2357 dnl -----------------
2358 dnl make ADAFLAGS consistent with CFLAGS
2359 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
2360         AC_MSG_CHECKING(optimization options for ADAFLAGS)
2361         case "$CFLAGS" in
2362         (*-g*)
2363                 CF_ADD_ADAFLAGS(-g)
2364                 ;;
2365         esac
2366         case "$CFLAGS" in
2367         (*-O*)
2368                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
2369                 CF_ADD_ADAFLAGS($cf_O_flag)
2370                 ;;
2371         esac
2372         AC_MSG_RESULT($ADAFLAGS)
2373 ])dnl
2374 dnl ---------------------------------------------------------------------------
2375 dnl CF_FIX_WARNINGS version: 3 updated: 2020/12/31 18:40:20
2376 dnl ---------------
2377 dnl Warning flags do not belong in CFLAGS, CPPFLAGS, etc.  Any of gcc's
2378 dnl "-Werror" flags can interfere with configure-checks.  Those go into
2379 dnl EXTRA_CFLAGS.
2380 dnl
2381 dnl $1 = variable name to repair
2382 define([CF_FIX_WARNINGS],[
2383 if test "$GCC" = yes || test "$GXX" = yes
2384 then
2385         case [$]$1 in
2386         (*-Werror=*)
2387                 CF_VERBOSE(repairing $1: [$]$1)
2388                 cf_temp_flags=
2389                 for cf_temp_scan in [$]$1
2390                 do
2391                         case "x$cf_temp_scan" in
2392                         (x-Werror=*)
2393                                 CF_APPEND_TEXT(EXTRA_CFLAGS,$cf_temp_scan)
2394                                 ;;
2395                         (*)
2396                                 CF_APPEND_TEXT(cf_temp_flags,$cf_temp_scan)
2397                                 ;;
2398                         esac
2399                 done
2400                 $1="$cf_temp_flags"
2401                 CF_VERBOSE(... fixed [$]$1)
2402                 CF_VERBOSE(... extra $EXTRA_CFLAGS)
2403                 ;;
2404         esac
2405 fi
2406 AC_SUBST(EXTRA_CFLAGS)
2407 ])dnl
2408 dnl ---------------------------------------------------------------------------
2409 dnl CF_FOPEN_BIN_R version: 2 updated: 2019/12/31 08:53:54
2410 dnl --------------
2411 dnl Check if fopen works when the "b" (binary) flag is added to the mode
2412 dnl parameter.  POSIX ignores the "b", which c89 specified.  Some very old
2413 dnl systems do not accept it.
2414 AC_DEFUN([CF_FOPEN_BIN_R],[
2415 AC_CACHE_CHECK(if fopen accepts explicit binary mode,cf_cv_fopen_bin_r,[
2416         AC_TRY_RUN([
2417 #include <stdio.h>
2418 int main(void) {
2419         FILE *fp = fopen("conftest.tmp", "wb");
2420         int rc = 0;
2421         if (fp != 0) {
2422                 int p, q;
2423                 for (p = 0; p < 256; ++p) {
2424                         fputc(p, fp);
2425                 }
2426                 fclose(fp);
2427                 fp = fopen("conftest.tmp", "rb");
2428                 if (fp != 0) {
2429                         for (p = 0; p < 256; ++p) {
2430                                 q = fgetc(fp);
2431                                 if (q != p) {
2432                                         rc = 1;
2433                                         break;
2434                                 }
2435                         }
2436                 } else {
2437                         rc = 1;
2438                 }
2439         } else {
2440                 rc = 1;
2441         }
2442         ${cf_cv_main_return:-return} (rc);
2443 }
2444 ],
2445                 [cf_cv_fopen_bin_r=yes],
2446                 [cf_cv_fopen_bin_r=no],
2447                 [cf_cv_fopen_bin_r=unknown])
2448 ])
2449 test "x$cf_cv_fopen_bin_r" != xno && AC_DEFINE(USE_FOPEN_BIN_R,1,[Define to 1 if fopen accepts explicit binary mode])
2450 ])dnl
2451 dnl ---------------------------------------------------------------------------
2452 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
2453 dnl --------------
2454 dnl Forget that we saw the given tool.
2455 AC_DEFUN([CF_FORGET_TOOL],[
2456 unset ac_cv_prog_ac_ct_$1
2457 unset ac_ct_$1
2458 unset $1
2459 ])dnl
2460 dnl ---------------------------------------------------------------------------
2461 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
2462 dnl -------------
2463 dnl Test for dlsym() and related functions, as well as libdl.
2464 dnl
2465 dnl Sets
2466 dnl     $cf_have_dlsym
2467 dnl     $cf_have_libdl
2468 AC_DEFUN([CF_FUNC_DLSYM],[
2469 cf_have_dlsym=no
2470 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
2471
2472 cf_have_libdl=no
2473 AC_CHECK_LIB(dl,dlsym,[
2474         cf_have_dlsym=yes
2475         cf_have_libdl=yes])])
2476
2477 if test "$cf_have_dlsym" = yes ; then
2478         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
2479
2480         AC_MSG_CHECKING(whether able to link to dl*() functions)
2481         AC_TRY_LINK([#include <dlfcn.h>],[
2482                 void *obj;
2483                 if ((obj = dlopen("filename", 0)) != 0) {
2484                         if (dlsym(obj, "symbolname") == 0) {
2485                         dlclose(obj);
2486                         }
2487                 }],[
2488                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
2489                 AC_MSG_ERROR(Cannot link test program for libdl)])
2490         AC_MSG_RESULT(ok)
2491 else
2492         AC_MSG_ERROR(Cannot find dlsym function)
2493 fi
2494 ])
2495 dnl ---------------------------------------------------------------------------
2496 dnl CF_FUNC_MEMMOVE version: 9 updated: 2017/01/21 11:06:25
2497 dnl ---------------
2498 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
2499 dnl is found, add our own version of memmove to the list of objects.
2500 AC_DEFUN([CF_FUNC_MEMMOVE],
2501 [
2502 AC_CHECK_FUNC(memmove,,[
2503 AC_CHECK_FUNC(bcopy,[
2504         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
2505                 AC_TRY_RUN([
2506 int main(void) {
2507         static char data[] = "abcdefghijklmnopqrstuwwxyz";
2508         char temp[40];
2509         bcopy(data, temp, sizeof(data));
2510         bcopy(temp+10, temp, 15);
2511         bcopy(temp+5, temp+15, 10);
2512         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
2513 }
2514                 ],
2515                 [cf_cv_good_bcopy=yes],
2516                 [cf_cv_good_bcopy=no],
2517                 [cf_cv_good_bcopy=unknown])
2518                 ])
2519         ],[cf_cv_good_bcopy=no])
2520         if test "$cf_cv_good_bcopy" = yes ; then
2521                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
2522         else
2523                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
2524         fi
2525 ])])dnl
2526 dnl ---------------------------------------------------------------------------
2527 dnl CF_FUNC_NANOSLEEP version: 5 updated: 2017/01/21 11:06:25
2528 dnl -----------------
2529 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
2530 dnl AIX 4.x, provide a non-working version.
2531 AC_DEFUN([CF_FUNC_NANOSLEEP],[
2532 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
2533 AC_TRY_RUN([
2534 #include <stdio.h>
2535 #include <errno.h>
2536 #include <time.h>
2537
2538 #ifdef HAVE_SYS_TIME_H
2539 #include <sys/time.h>
2540 #endif
2541
2542 int main(void) {
2543         struct timespec ts1, ts2;
2544         int code;
2545         ts1.tv_sec  = 0;
2546         ts1.tv_nsec = 750000000;
2547         ts2.tv_sec  = 0;
2548         ts2.tv_nsec = 0;
2549         errno = 0;
2550         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
2551         ${cf_cv_main_return:-return}(code != 0);
2552 }
2553 ],
2554         [cf_cv_func_nanosleep=yes],
2555         [cf_cv_func_nanosleep=no],
2556         [cf_cv_func_nanosleep=unknown])])
2557
2558 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
2559 ])
2560 dnl ---------------------------------------------------------------------------
2561 dnl CF_FUNC_OPENPTY version: 6 updated: 2021/01/01 13:31:04
2562 dnl ---------------
2563 dnl Check for openpty() function, along with <pty.h> header.  It may need the
2564 dnl "util" library as well.
2565 AC_DEFUN([CF_FUNC_OPENPTY],
2566 [
2567 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
2568 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
2569         cf_save_LIBS="$LIBS"
2570         test "$cf_cv_lib_util" = yes && { CF_ADD_LIB(util) }
2571         for cf_header in pty.h libutil.h util.h
2572         do
2573         AC_TRY_LINK([
2574 #include <$cf_header>
2575 ],[
2576         int x = openpty((int *)0, (int *)0, (char *)0,
2577                                    (struct termios *)0, (struct winsize *)0);
2578 ],[
2579                 cf_cv_func_openpty=$cf_header
2580                 break
2581 ],[
2582                 cf_cv_func_openpty=no
2583 ])
2584         done
2585         LIBS="$cf_save_LIBS"
2586 ])
2587 ])dnl
2588 dnl ---------------------------------------------------------------------------
2589 dnl CF_FUNC_POLL version: 10 updated: 2021/01/04 19:13:57
2590 dnl ------------
2591 dnl See if the poll function really works.  Some platforms have poll(), but
2592 dnl it does not work for terminals or files.
2593 AC_DEFUN([CF_FUNC_POLL],[
2594 tty >/dev/null 2>&1 || { AC_CHECK_FUNCS(posix_openpt) }
2595 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
2596 AC_TRY_RUN([
2597 #include <stdlib.h>
2598 #include <stdio.h>
2599 #include <unistd.h>
2600 #include <fcntl.h>
2601 #ifdef HAVE_POLL_H
2602 #include <poll.h>
2603 #else
2604 #include <sys/poll.h>
2605 #endif
2606 int main(void) {
2607         struct pollfd myfds;
2608         int ret;
2609
2610         /* check for Darwin bug with respect to "devices" */
2611         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
2612         if (myfds.fd < 0)
2613                 myfds.fd = 0;
2614         myfds.events = POLLIN;
2615         myfds.revents = 0;
2616
2617         ret = poll(&myfds, 1, 100);
2618
2619         if (ret < 0 || (myfds.revents & POLLNVAL)) {
2620                 ret = -1;
2621         } else {
2622                 int fd = 0;
2623                 if (!isatty(fd)) {
2624                         fd = open("/dev/tty", 2);       /* O_RDWR */
2625                 }
2626 #ifdef HAVE_POSIX_OPENPT
2627                 if (fd < 0) {
2628                         fd = posix_openpt(O_RDWR);
2629                 }
2630 #endif
2631
2632                 if (fd >= 0) {
2633                         /* also check with standard input */
2634                         myfds.fd = fd;
2635                         myfds.events = POLLIN;
2636                         myfds.revents = 0;
2637                         ret = poll(&myfds, 1, 100);
2638                 } else {
2639                         ret = -1;
2640                 }
2641         }
2642         ${cf_cv_main_return:-return}(ret < 0);
2643 }],
2644         [cf_cv_working_poll=yes],
2645         [cf_cv_working_poll=no],
2646         [cf_cv_working_poll=unknown])])
2647 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
2648 ])dnl
2649 dnl ---------------------------------------------------------------------------
2650 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
2651 dnl ---------------
2652 dnl Some old/broken variations define tcgetattr() only as a macro in
2653 dnl termio(s).h
2654 AC_DEFUN([CF_FUNC_TERMIOS],[
2655 AC_REQUIRE([CF_STRUCT_TERMIOS])
2656 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
2657 AC_TRY_LINK([
2658 #include <sys/types.h>
2659 #ifdef HAVE_UNISTD_H
2660 #include <unistd.h>
2661 #endif
2662 #ifdef HAVE_TERMIOS_H
2663 #include <termios.h>
2664 #define TTY struct termios
2665 #else
2666 #ifdef HAVE_TERMIO_H
2667 #include <termio.h>
2668 #define TTY struct termio
2669 #endif
2670 #endif
2671 ],[
2672 TTY foo;
2673 tcgetattr(1, &foo);],
2674 [cf_cv_have_tcgetattr=yes],
2675 [cf_cv_have_tcgetattr=no])])
2676 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
2677 ])dnl
2678 dnl ---------------------------------------------------------------------------
2679 dnl CF_FUNC_VSSCANF version: 7 updated: 2021/01/01 13:31:04
2680 dnl ---------------
2681 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
2682 dnl versions of C.  It is in the GNU C library, and can often be simulated by
2683 dnl other functions.
2684 AC_DEFUN([CF_FUNC_VSSCANF],
2685 [
2686 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
2687 AC_TRY_LINK([
2688 #include <stdarg.h>
2689 #include <stdio.h>],[
2690         va_list ap;
2691         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
2692 AC_TRY_LINK([
2693 #include <stdarg.h>
2694 #include <stdio.h>],[
2695         FILE strbuf;
2696         char *str = "from";
2697
2698         strbuf._flag = _IOREAD;
2699         strbuf._ptr = strbuf._base = (unsigned char *) str;
2700         strbuf._cnt = strlen(str);
2701         strbuf._file = _NFILE;
2702         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
2703 AC_TRY_LINK([
2704 #include <stdarg.h>
2705 #include <stdio.h>],[
2706         FILE strbuf;
2707         char *str = "from";
2708
2709         strbuf._flag = _IOREAD;
2710         strbuf._ptr = strbuf._base = (unsigned char *) str;
2711         strbuf._cnt = strlen(str);
2712         strbuf._file = _NFILE;
2713         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
2714 cf_cv_func_vsscanf=no])])])])
2715
2716 case "$cf_cv_func_vsscanf" in
2717 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
2718 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
2719 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
2720 esac
2721
2722 ])dnl
2723 dnl ---------------------------------------------------------------------------
2724 dnl CF_GCC_ATTRIBUTES version: 24 updated: 2021/03/20 12:00:25
2725 dnl -----------------
2726 dnl Test for availability of useful gcc __attribute__ directives to quiet
2727 dnl compiler warnings.  Though useful, not all are supported -- and contrary
2728 dnl to documentation, unrecognized directives cause older compilers to barf.
2729 AC_DEFUN([CF_GCC_ATTRIBUTES],
2730 [AC_REQUIRE([AC_PROG_FGREP])dnl
2731 AC_REQUIRE([CF_C11_NORETURN])dnl
2732
2733 if test "$GCC" = yes || test "$GXX" = yes
2734 then
2735 cat > conftest.i <<EOF
2736 #ifndef GCC_PRINTF
2737 #define GCC_PRINTF 0
2738 #endif
2739 #ifndef GCC_SCANF
2740 #define GCC_SCANF 0
2741 #endif
2742 #ifndef GCC_NORETURN
2743 #define GCC_NORETURN /* nothing */
2744 #endif
2745 #ifndef GCC_UNUSED
2746 #define GCC_UNUSED /* nothing */
2747 #endif
2748 EOF
2749 if test "$GCC" = yes
2750 then
2751         AC_CHECKING([for $CC __attribute__ directives])
2752 cat > "conftest.$ac_ext" <<EOF
2753 #line __oline__ "${as_me:-configure}"
2754 #include "confdefs.h"
2755 #include "conftest.h"
2756 #include "conftest.i"
2757 #if     GCC_PRINTF
2758 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
2759 #else
2760 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
2761 #endif
2762 #if     GCC_SCANF
2763 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2764 #else
2765 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2766 #endif
2767 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2768 extern GCC_NORETURN void oops(char *,...) GCC_PRINTFLIKE(1,2);
2769 extern GCC_NORETURN void foo(void);
2770 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { (void)argc; (void)argv; return 0; }
2771 EOF
2772         cf_printf_attribute=no
2773         cf_scanf_attribute=no
2774         for cf_attribute in scanf printf unused noreturn
2775         do
2776                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2777                 cf_directive="__attribute__(($cf_attribute))"
2778                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2779
2780                 case "$cf_attribute" in
2781                 (printf)
2782                         cf_printf_attribute=yes
2783                         cat >conftest.h <<EOF
2784 #define GCC_$cf_ATTRIBUTE 1
2785 EOF
2786                         ;;
2787                 (scanf)
2788                         cf_scanf_attribute=yes
2789                         cat >conftest.h <<EOF
2790 #define GCC_$cf_ATTRIBUTE 1
2791 EOF
2792                         ;;
2793                 (*)
2794                         cat >conftest.h <<EOF
2795 #define GCC_$cf_ATTRIBUTE $cf_directive
2796 EOF
2797                         ;;
2798                 esac
2799
2800                 if AC_TRY_EVAL(ac_compile); then
2801                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
2802                         cat conftest.h >>confdefs.h
2803                         case "$cf_attribute" in
2804                         (noreturn)
2805                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
2806                                 ;;
2807                         (printf)
2808                                 cf_value='/* nothing */'
2809                                 if test "$cf_printf_attribute" != no ; then
2810                                         cf_value='__attribute__((format(printf,fmt,var)))'
2811                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
2812                                 fi
2813                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
2814                                 ;;
2815                         (scanf)
2816                                 cf_value='/* nothing */'
2817                                 if test "$cf_scanf_attribute" != no ; then
2818                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2819                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2820                                 fi
2821                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2822                                 ;;
2823                         (unused)
2824                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2825                                 ;;
2826                         esac
2827                 fi
2828         done
2829 else
2830         ${FGREP-fgrep} define conftest.i >>confdefs.h
2831 fi
2832 rm -rf ./conftest*
2833 fi
2834 ])dnl
2835 dnl ---------------------------------------------------------------------------
2836 dnl CF_GCC_VERSION version: 8 updated: 2019/09/07 13:38:36
2837 dnl --------------
2838 dnl Find version of gcc, and (because icc/clang pretend to be gcc without being
2839 dnl compatible), attempt to determine if icc/clang is actually used.
2840 AC_DEFUN([CF_GCC_VERSION],[
2841 AC_REQUIRE([AC_PROG_CC])
2842 GCC_VERSION=none
2843 if test "$GCC" = yes ; then
2844         AC_MSG_CHECKING(version of $CC)
2845         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2846         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2847         AC_MSG_RESULT($GCC_VERSION)
2848 fi
2849 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2850 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2851 ])dnl
2852 dnl ---------------------------------------------------------------------------
2853 dnl CF_GCC_WARNINGS version: 41 updated: 2021/01/01 16:53:59
2854 dnl ---------------
2855 dnl Check if the compiler supports useful warning options.  There's a few that
2856 dnl we don't use, simply because they're too noisy:
2857 dnl
2858 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2859 dnl     -Winline (usually not worthwhile)
2860 dnl     -Wredundant-decls (system headers make this too noisy)
2861 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2862 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2863 dnl             is enabled for ncurses using "--enable-const".
2864 dnl     -pedantic
2865 dnl
2866 dnl Parameter:
2867 dnl     $1 is an optional list of gcc warning flags that a particular
2868 dnl             application might want to use, e.g., "no-unused" for
2869 dnl             -Wno-unused
2870 dnl Special:
2871 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2872 dnl
2873 AC_DEFUN([CF_GCC_WARNINGS],
2874 [
2875 AC_REQUIRE([CF_GCC_VERSION])
2876 if test "x$have_x" = xyes; then CF_CONST_X_STRING fi
2877 cat > "conftest.$ac_ext" <<EOF
2878 #line __oline__ "${as_me:-configure}"
2879 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2880 EOF
2881 if test "$INTEL_COMPILER" = yes
2882 then
2883 # The "-wdXXX" options suppress warnings:
2884 # remark #1419: external declaration in primary source file
2885 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2886 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2887 # remark #193: zero used for undefined preprocessing identifier
2888 # remark #593: variable "curs_sb_left_arrow" was set but never used
2889 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2890 # remark #869: parameter "tw" was never referenced
2891 # remark #981: operands are evaluated in unspecified order
2892 # warning #279: controlling expression is constant
2893
2894         AC_CHECKING([for $CC warning options])
2895         cf_save_CFLAGS="$CFLAGS"
2896         EXTRA_CFLAGS="$EXTRA_CFLAGS -Wall"
2897         for cf_opt in \
2898                 wd1419 \
2899                 wd1683 \
2900                 wd1684 \
2901                 wd193 \
2902                 wd593 \
2903                 wd279 \
2904                 wd810 \
2905                 wd869 \
2906                 wd981
2907         do
2908                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2909                 if AC_TRY_EVAL(ac_compile); then
2910                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2911                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2912                 fi
2913         done
2914         CFLAGS="$cf_save_CFLAGS"
2915 elif test "$GCC" = yes && test "$GCC_VERSION" != "unknown"
2916 then
2917         AC_CHECKING([for $CC warning options])
2918         cf_save_CFLAGS="$CFLAGS"
2919         cf_warn_CONST=""
2920         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2921         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2922         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2923         for cf_opt in W Wall \
2924                 Wbad-function-cast \
2925                 Wcast-align \
2926                 Wcast-qual \
2927                 Wdeclaration-after-statement \
2928                 Wextra \
2929                 Winline \
2930                 Wmissing-declarations \
2931                 Wmissing-prototypes \
2932                 Wnested-externs \
2933                 Wpointer-arith \
2934                 Wshadow \
2935                 Wstrict-prototypes \
2936                 Wundef Wno-inline $cf_gcc_warnings $cf_warn_CONST $1
2937         do
2938                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2939                 if AC_TRY_EVAL(ac_compile); then
2940                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2941                         case "$cf_opt" in
2942                         (Winline)
2943                                 case "$GCC_VERSION" in
2944                                 ([[34]].*)
2945                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2946                                         continue;;
2947                                 esac
2948                                 ;;
2949                         (Wpointer-arith)
2950                                 case "$GCC_VERSION" in
2951                                 ([[12]].*)
2952                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2953                                         continue;;
2954                                 esac
2955                                 ;;
2956                         esac
2957                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2958                 fi
2959         done
2960         CFLAGS="$cf_save_CFLAGS"
2961 fi
2962 rm -rf ./conftest*
2963
2964 AC_SUBST(EXTRA_CFLAGS)
2965 ])dnl
2966 dnl ---------------------------------------------------------------------------
2967 dnl CF_GETOPT_HEADER version: 7 updated: 2021/01/01 13:31:04
2968 dnl ----------------
2969 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2970 dnl unistd.h or (nonstandard) in getopt.h
2971 AC_DEFUN([CF_GETOPT_HEADER],
2972 [
2973 AC_HAVE_HEADERS(unistd.h getopt.h)
2974 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2975 cf_cv_getopt_header=none
2976 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2977 do
2978 AC_TRY_COMPILE([
2979 #include <$cf_header>],
2980 [int x = optind; char *y = optarg],
2981 [cf_cv_getopt_header=$cf_header
2982  break])
2983 done
2984 ])
2985 if test "$cf_cv_getopt_header" != none ; then
2986         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2987 fi
2988 if test "$cf_cv_getopt_header" = getopt.h ; then
2989         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2990 fi
2991 ])dnl
2992 dnl ---------------------------------------------------------------------------
2993 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2994 dnl -----------------
2995 AC_DEFUN([CF_GNATPREP_OPT_T],[
2996 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2997 cf_cv_gnatprep_opt_t=no
2998 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2999 ])
3000 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
3001 AC_SUBST(GNATPREP_OPTS)
3002 ])dnl
3003 dnl ---------------------------------------------------------------------------
3004 dnl CF_GNAT_GENERICS version: 7 updated: 2021/01/01 13:31:04
3005 dnl ----------------
3006 AC_DEFUN([CF_GNAT_GENERICS],
3007 [
3008 AC_REQUIRE([CF_GNAT_VERSION])
3009
3010 AC_MSG_CHECKING(if GNAT supports generics)
3011 case "$cf_cv_gnat_version" in
3012 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
3013         cf_gnat_generics=yes
3014         ;;
3015 (*)
3016         cf_gnat_generics=no
3017         ;;
3018 esac
3019 AC_MSG_RESULT($cf_gnat_generics)
3020
3021 if test "$cf_gnat_generics" = yes
3022 then
3023         cf_compile_generics=generics
3024         cf_generic_objects="\${GENOBJS}"
3025 else
3026         cf_compile_generics=
3027         cf_generic_objects=
3028 fi
3029
3030 AC_SUBST(cf_compile_generics)
3031 AC_SUBST(cf_generic_objects)
3032 ])dnl
3033 dnl ---------------------------------------------------------------------------
3034 dnl CF_GNAT_PROJECTS version: 13 updated: 2021/01/02 17:09:14
3035 dnl ----------------
3036 dnl GNAT projects are configured with ".gpr" project files.
3037 dnl GNAT libraries are a further development, using the project feature.
3038 AC_DEFUN([CF_GNAT_PROJECTS],
3039 [
3040 AC_REQUIRE([CF_GNAT_VERSION])
3041 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
3042
3043 cf_gnat_libraries=no
3044 cf_gnat_projects=no
3045
3046 if test "$enable_gnat_projects" != no ; then
3047 AC_MSG_CHECKING(if GNAT supports project files)
3048 case "$cf_cv_gnat_version" in
3049 (3.[[0-9]]*)
3050         ;;
3051 (*)
3052         case "$cf_cv_system_name" in
3053         (cygwin*|msys*)
3054                 ;;
3055         (*)
3056                 rm -rf ./conftest* ./*~conftest*
3057                 if mkdir conftest.src conftest.bin conftest.lib
3058                 then
3059                         cd conftest.src
3060                         rm -rf ./conftest* ./*~conftest*
3061                         cat >>library.gpr <<CF_EOF
3062 project Library is
3063   Kind := External ("LIB_KIND");
3064   for Library_Name use "ConfTest";
3065   for Object_Dir use ".";
3066   for Library_ALI_Dir use External("LIBRARY_DIR");
3067   for Library_Version use External ("SONAME");
3068   for Library_Kind use Kind;
3069   for Library_Dir use External("BUILD_DIR");
3070   Source_Dir := External ("SOURCE_DIR");
3071   for Source_Dirs use (Source_Dir);
3072 end Library;
3073 CF_EOF
3074                         cat >>confpackage.ads <<CF_EOF
3075 package ConfPackage is
3076    procedure conftest;
3077 end ConfPackage;
3078 CF_EOF
3079                         cat >>confpackage.adb <<CF_EOF
3080 with Text_IO;
3081 package body ConfPackage is
3082    procedure conftest is
3083    begin
3084       Text_IO.Put ("Hello World");
3085       Text_IO.New_Line;
3086    end conftest;
3087 end ConfPackage;
3088 CF_EOF
3089                         if ( "$cf_ada_make" $ADAFLAGS \
3090                                         -Plibrary.gpr \
3091                                         -XBUILD_DIR="`cd ../conftest.bin;pwd`" \
3092                                         -XLIBRARY_DIR="`cd ../conftest.lib;pwd`" \
3093                                         -XSOURCE_DIR="`pwd`" \
3094                                         -XSONAME=libConfTest.so.1 \
3095                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
3096                                 cf_gnat_projects=yes
3097                         fi
3098                         cd ..
3099                 fi
3100                 if test -f conftest.lib/confpackage.ali
3101                 then
3102                         cf_gnat_libraries=yes
3103                 fi
3104                 rm -rf ./conftest* ./*~conftest*
3105                 ;;
3106         esac
3107         ;;
3108 esac
3109 AC_MSG_RESULT($cf_gnat_projects)
3110 fi # enable_gnat_projects
3111
3112 if test "$cf_gnat_projects" = yes
3113 then
3114         AC_MSG_CHECKING(if GNAT supports libraries)
3115         AC_MSG_RESULT($cf_gnat_libraries)
3116 fi
3117
3118 USE_OLD_MAKERULES=""
3119 USE_GNAT_PROJECTS="#"
3120 USE_GNAT_MAKE_GPR="#"
3121 USE_GNAT_GPRBUILD="#"
3122
3123 if test "$cf_gnat_projects" = yes
3124 then
3125         USE_OLD_MAKERULES="#"
3126         USE_GNAT_PROJECTS=""
3127         if test "$cf_cv_VERSION_GPRBUILD" != no
3128         then
3129                 USE_GNAT_GPRBUILD=""
3130         elif test "$cf_cv_VERSION_GNATMAKE" != no
3131         then
3132                 USE_GNAT_MAKE_GPR=""
3133         else
3134                 AC_MSG_WARN(use old makefile rules since tools are missing)
3135         fi
3136 fi
3137
3138 if test "$cf_gnat_libraries" = yes
3139 then
3140         USE_GNAT_LIBRARIES=""
3141 else
3142         USE_GNAT_LIBRARIES="#"
3143 fi
3144
3145 AC_SUBST(USE_OLD_MAKERULES)
3146 AC_SUBST(USE_GNAT_PROJECTS)
3147 AC_SUBST(USE_GNAT_LIBRARIES)
3148 AC_SUBST(USE_GNAT_MAKE_GPR)
3149 AC_SUBST(USE_GNAT_GPRBUILD)
3150 ])dnl
3151 dnl ---------------------------------------------------------------------------
3152 dnl CF_GNAT_SIGINT version: 2 updated: 2021/01/01 13:31:04
3153 dnl --------------
3154 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
3155 dnl is noted that gnat may compile a tasking unit even for configurations which
3156 dnl fail at runtime.
3157 AC_DEFUN([CF_GNAT_SIGINT],[
3158 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
3159 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
3160
3161 package ConfTest is
3162
3163    pragma Warnings (Off);  --  the next pragma exists since 3.11p
3164    pragma Unreserve_All_Interrupts;
3165    pragma Warnings (On);
3166
3167    protected Process is
3168       procedure Stop;
3169       function Continue return Boolean;
3170       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
3171    private
3172       Done : Boolean := False;
3173    end Process;
3174
3175 end ConfTest;],
3176 [package body ConfTest is
3177    protected body Process is
3178       procedure Stop is
3179       begin
3180          Done := True;
3181       end Stop;
3182       function Continue return Boolean is
3183       begin
3184          return not Done;
3185       end Continue;
3186    end Process;
3187 end ConfTest;],
3188         [cf_cv_gnat_sigint=yes],
3189         [cf_cv_gnat_sigint=no])])
3190
3191 if test "$cf_cv_gnat_sigint" = yes ; then
3192         USE_GNAT_SIGINT=""
3193 else
3194         USE_GNAT_SIGINT="#"
3195 fi
3196 AC_SUBST(USE_GNAT_SIGINT)
3197 ])dnl
3198 dnl ---------------------------------------------------------------------------
3199 dnl CF_GNAT_TRY_LINK version: 4 updated: 2021/01/01 13:31:04
3200 dnl ----------------
3201 dnl Verify that a test program compiles/links with GNAT.
3202 dnl $cf_ada_make is set to the program that compiles/links
3203 dnl $ADAFLAGS may be set to the GNAT flags.
3204 dnl
3205 dnl $1 is the text of the spec
3206 dnl $2 is the text of the body
3207 dnl $3 is the shell command to execute if successful
3208 dnl $4 is the shell command to execute if not successful
3209 AC_DEFUN([CF_GNAT_TRY_LINK],
3210 [
3211 rm -rf ./conftest* ./*~conftest*
3212 cat >>conftest.ads <<CF_EOF
3213 $1
3214 CF_EOF
3215 cat >>conftest.adb <<CF_EOF
3216 $2
3217 CF_EOF
3218 if ( "$cf_ada_make" $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
3219 ifelse($3,,      :,[      $3])
3220 ifelse($4,,,[else
3221    $4])
3222 fi
3223 rm -rf ./conftest* ./*~conftest*
3224 ])dnl
3225 dnl ---------------------------------------------------------------------------
3226 dnl CF_GNAT_TRY_RUN version: 6 updated: 2021/01/01 13:31:04
3227 dnl ---------------
3228 dnl Verify that a test program compiles and runs with GNAT
3229 dnl $cf_ada_make is set to the program that compiles/links
3230 dnl $ADAFLAGS may be set to the GNAT flags.
3231 dnl
3232 dnl $1 is the text of the spec
3233 dnl $2 is the text of the body
3234 dnl $3 is the shell command to execute if successful
3235 dnl $4 is the shell command to execute if not successful
3236 AC_DEFUN([CF_GNAT_TRY_RUN],
3237 [
3238 rm -rf ./conftest* ./*~conftest*
3239 cat >>conftest.ads <<CF_EOF
3240 $1
3241 CF_EOF
3242 cat >>conftest.adb <<CF_EOF
3243 $2
3244 CF_EOF
3245 if ( "$cf_ada_make" $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
3246    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
3247 ifelse($3,,      :,[      $3])
3248 ifelse($4,,,[   else
3249       $4])
3250    fi
3251 ifelse($4,,,[else
3252    $4])
3253 fi
3254 rm -rf ./conftest* ./*~conftest*
3255 ])dnl
3256 dnl ---------------------------------------------------------------------------
3257 dnl CF_GNAT_VERSION version: 22 updated: 2019/12/31 08:53:54
3258 dnl ---------------
3259 dnl $1 = cache variable to update
3260 dnl $2 = program name
3261 dnl Verify version of GNAT or related tool
3262 AC_DEFUN([CF_GNAT_VERSION],
3263 [
3264 AC_CACHE_CHECK(for ifelse($2,,gnat,$2) version, cf_cv_gnat_version,[
3265 cf_cv_gnat_version=`ifelse($2,,${cf_ada_make:-gnatmake},$2) --version 2>&1 | \
3266         grep '[[0-9]].[[0-9]][[0-9]]*' |\
3267         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
3268 ])
3269 test -z "$cf_cv_gnat_version" && cf_cv_gnat_version=no
3270 ifelse($1,,,[eval $1=$cf_cv_gnat_version; unset cf_cv_gnat_version])
3271 ])dnl
3272 dnl ---------------------------------------------------------------------------
3273 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
3274 dnl -------------
3275 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
3276 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
3277 dnl (or misfeature) of glibc2, which breaks portability of many applications,
3278 dnl since it is interwoven with GNU extensions.
3279 dnl
3280 dnl Well, yes we could work around it...
3281 dnl
3282 dnl Parameters:
3283 dnl     $1 is the nominal value for _XOPEN_SOURCE
3284 AC_DEFUN([CF_GNU_SOURCE],
3285 [
3286 cf_gnu_xopen_source=ifelse($1,,500,$1)
3287
3288 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
3289 AC_TRY_COMPILE([#include <sys/types.h>],[
3290         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
3291                 return 0;
3292         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
3293                 return 0;
3294         #else
3295         #       error not GNU C library
3296         #endif],
3297         [cf_cv_gnu_library=yes],
3298         [cf_cv_gnu_library=no])
3299 ])
3300
3301 if test x$cf_cv_gnu_library = xyes; then
3302
3303         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
3304         # was changed to help a little.  newlib incorporated the change about 4
3305         # years later.
3306         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
3307                 cf_save="$CPPFLAGS"
3308                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3309                 AC_TRY_COMPILE([#include <sys/types.h>],[
3310                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
3311                                 return 0;
3312                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
3313                                 return 0;
3314                         #else
3315                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
3316                         #endif],
3317                         [cf_cv_gnu_library_219=yes],
3318                         [cf_cv_gnu_library_219=no])
3319                 CPPFLAGS="$cf_save"
3320         ])
3321
3322         if test "x$cf_cv_gnu_library_219" = xyes; then
3323                 cf_save="$CPPFLAGS"
3324                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
3325                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
3326                         AC_TRY_COMPILE([
3327                                 #include <limits.h>
3328                                 #include <sys/types.h>
3329                                 ],[
3330                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
3331                                         return 0;
3332                                 #else
3333                                 #       error GNU C library is too old
3334                                 #endif],
3335                                 [cf_cv_gnu_dftsrc_219=yes],
3336                                 [cf_cv_gnu_dftsrc_219=no])
3337                         ])
3338                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
3339         else
3340                 cf_cv_gnu_dftsrc_219=maybe
3341         fi
3342
3343         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
3344
3345                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
3346                 AC_TRY_COMPILE([#include <sys/types.h>],[
3347                         #ifndef _XOPEN_SOURCE
3348                         #error  expected _XOPEN_SOURCE to be defined
3349                         #endif],
3350                         [cf_cv_gnu_source=no],
3351                         [cf_save="$CPPFLAGS"
3352                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
3353                          AC_TRY_COMPILE([#include <sys/types.h>],[
3354                                 #ifdef _XOPEN_SOURCE
3355                                 #error  expected _XOPEN_SOURCE to be undefined
3356                                 #endif],
3357                                 [cf_cv_gnu_source=no],
3358                                 [cf_cv_gnu_source=yes])
3359                         CPPFLAGS="$cf_save"
3360                         ])
3361                 ])
3362
3363                 if test "$cf_cv_gnu_source" = yes
3364                 then
3365                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
3366                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
3367                         AC_TRY_COMPILE([#include <sys/types.h>],[
3368                                 #ifdef _DEFAULT_SOURCE
3369                                 #error  expected _DEFAULT_SOURCE to be undefined
3370                                 #endif],
3371                                 [cf_cv_default_source=no],
3372                                 [cf_cv_default_source=yes])
3373                         ])
3374                         if test "$cf_cv_default_source" = yes
3375                         then
3376                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3377                         fi
3378                 fi
3379         fi
3380
3381 fi
3382 ])dnl
3383 dnl ---------------------------------------------------------------------------
3384 dnl CF_GPP_LIBRARY version: 13 updated: 2021/01/01 13:31:04
3385 dnl --------------
3386 dnl If we're trying to use g++, test if libg++ is installed (a rather common
3387 dnl problem :-).  If we have the compiler but no library, we'll be able to
3388 dnl configure, but won't be able to build the c++ demo program.
3389 AC_DEFUN([CF_GPP_LIBRARY],
3390 [
3391 cf_cxx_library=unknown
3392 case "$cf_cv_system_name" in
3393 (os2*)
3394         cf_gpp_libname=gpp
3395         ;;
3396 (*)
3397         cf_gpp_libname=g++
3398         ;;
3399 esac
3400 if test "$GXX" = yes; then
3401         AC_MSG_CHECKING([for lib$cf_gpp_libname])
3402         cf_save="$LIBS"
3403         CF_ADD_LIB($cf_gpp_libname)
3404         AC_TRY_LINK([
3405 #include <$cf_gpp_libname/builtin.h>
3406         ],
3407         [two_arg_error_handler_t foo2 = lib_error_handler],
3408         [cf_cxx_library=yes
3409          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3410          if test "$cf_gpp_libname" = cpp ; then
3411             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
3412          else
3413             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
3414          fi],
3415         [AC_TRY_LINK([
3416 #include <builtin.h>
3417         ],
3418         [two_arg_error_handler_t foo2 = lib_error_handler],
3419         [cf_cxx_library=yes
3420          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3421          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
3422         [cf_cxx_library=no])])
3423         LIBS="$cf_save"
3424         AC_MSG_RESULT($cf_cxx_library)
3425 fi
3426 ])dnl
3427 dnl ---------------------------------------------------------------------------
3428 dnl CF_GXX_VERSION version: 8 updated: 2017/02/11 14:48:57
3429 dnl --------------
3430 dnl Check for version of g++
3431 AC_DEFUN([CF_GXX_VERSION],[
3432 AC_REQUIRE([AC_PROG_CPP])
3433 GXX_VERSION=none
3434 if test "$GXX" = yes; then
3435         AC_MSG_CHECKING(version of ${CXX:-g++})
3436         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
3437         if test -z "$GXX_VERSION"
3438         then
3439                 GXX_VERSION=unknown
3440                 GXX=no
3441         fi
3442         AC_MSG_RESULT($GXX_VERSION)
3443 fi
3444 ])dnl
3445 dnl ---------------------------------------------------------------------------
3446 dnl CF_GXX_WARNINGS version: 11 updated: 2021/01/08 16:50:55
3447 dnl ---------------
3448 dnl Check if the compiler supports useful warning options.
3449 dnl
3450 dnl Most of gcc's options apply to g++, except:
3451 dnl     -Wbad-function-cast
3452 dnl     -Wmissing-declarations
3453 dnl     -Wnested-externs
3454 dnl
3455 dnl Omit a few (for now):
3456 dnl     -Winline
3457 dnl
3458 dnl Parameter:
3459 dnl     $1 is an optional list of g++ warning flags that a particular
3460 dnl             application might want to use, e.g., "no-unused" for
3461 dnl             -Wno-unused
3462 dnl Special:
3463 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
3464 dnl
3465 AC_DEFUN([CF_GXX_WARNINGS],
3466 [
3467
3468 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
3469 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
3470
3471 AC_REQUIRE([CF_GXX_VERSION])
3472
3473 AC_LANG_SAVE
3474 AC_LANG_CPLUSPLUS
3475
3476 cat > conftest.$ac_ext <<EOF
3477 #line __oline__ "configure"
3478 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
3479 EOF
3480
3481 if test "$INTEL_CPLUSPLUS" = yes
3482 then
3483 # The "-wdXXX" options suppress warnings:
3484 # remark #1419: external declaration in primary source file
3485 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3486 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3487 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
3488 # remark #193: zero used for undefined preprocessing identifier
3489 # remark #593: variable "curs_sb_left_arrow" was set but never used
3490 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
3491 # remark #869: parameter "tw" was never referenced
3492 # remark #981: operands are evaluated in unspecified order
3493 # warning #269: invalid format string conversion
3494
3495         AC_CHECKING([for $CC warning options])
3496         cf_save_CXXFLAGS="$CXXFLAGS"
3497         EXTRA_CXXFLAGS="-Wall"
3498         for cf_opt in \
3499                 wd1419 \
3500                 wd1682 \
3501                 wd1683 \
3502                 wd1684 \
3503                 wd193 \
3504                 wd279 \
3505                 wd593 \
3506                 wd810 \
3507                 wd869 \
3508                 wd981
3509         do
3510                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
3511                 if AC_TRY_EVAL(ac_compile); then
3512                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3513                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3514                 fi
3515         done
3516         CXXFLAGS="$cf_save_CXXFLAGS"
3517
3518 elif test "$GXX" = yes
3519 then
3520         AC_CHECKING([for $CXX warning options])
3521         cf_save_CXXFLAGS="$CXXFLAGS"
3522         EXTRA_CXXFLAGS="-W -Wall"
3523         cf_gxx_extra_warnings=""
3524         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
3525         case "$GXX_VERSION" in
3526         ([[1-2]].*)
3527                 ;;
3528         (*)
3529                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
3530                 ;;
3531         esac
3532         for cf_opt in \
3533                 Wabi \
3534                 fabi-version=0 \
3535                 Wextra \
3536                 Wignored-qualifiers \
3537                 Wlogical-op \
3538                 Woverloaded-virtual \
3539                 Wsign-promo \
3540                 Wsynth \
3541                 Wold-style-cast \
3542                 Wcast-align \
3543                 Wcast-qual \
3544                 Wpointer-arith \
3545                 Wshadow \
3546                 Wundef $cf_gxx_extra_warnings $1
3547         do
3548                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
3549                 if AC_TRY_EVAL(ac_compile); then
3550                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3551                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3552                 else
3553                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
3554                 fi
3555         done
3556         CXXFLAGS="$cf_save_CXXFLAGS"
3557 fi
3558
3559 rm -rf ./conftest*
3560 AC_LANG_RESTORE
3561 AC_SUBST(EXTRA_CXXFLAGS)
3562 ])dnl
3563 dnl ---------------------------------------------------------------------------
3564 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
3565 dnl ------------
3566 dnl Look for an instance of the Berkeley hashed database.
3567 dnl
3568 dnl $1 = optional parameter, to specify install-prefix for the database.
3569 AC_DEFUN([CF_HASHED_DB],
3570 [
3571 ifelse([$1],,,[
3572 case $1 in
3573 (yes|*able*)
3574         ;;
3575 (*)
3576         if test -d "$1" ; then
3577                 CF_ADD_INCDIR($1/include)
3578                 CF_ADD_LIBDIR($1/lib)
3579         else
3580                 case "$1" in
3581                 (./*|../*|/*)
3582                         AC_MSG_WARN(no such directory $1)
3583                         ;;
3584                 (*)
3585                         CF_FIND_SUB_INCDIR($1)
3586                         CF_FIND_SUB_LIBDIR($1)
3587                         ;;
3588                 esac
3589         fi
3590 esac
3591 ])
3592 AC_CHECK_HEADER(db.h,[
3593 CF_HASHED_DB_VERSION
3594 if test "$cf_cv_hashed_db_version" = unknown ; then
3595         AC_MSG_ERROR(Cannot determine version of db)
3596 else
3597         CF_HASHED_DB_LIBS
3598         if test "$cf_cv_hashed_db_libs" = unknown ; then
3599                 AC_MSG_ERROR(Cannot determine library for db)
3600         elif test "$cf_cv_hashed_db_libs" != default ; then
3601                 CF_ADD_LIB($cf_cv_hashed_db_libs)
3602         fi
3603 fi
3604 ],[
3605         AC_MSG_ERROR(Cannot find db.h)
3606 ])
3607 ])dnl
3608 dnl ---------------------------------------------------------------------------
3609 dnl CF_HASHED_DB_LIBS version: 10 updated: 2021/01/02 17:09:14
3610 dnl -----------------
3611 dnl Given that we have the header and version for hashed database, find the
3612 dnl library information.
3613 AC_DEFUN([CF_HASHED_DB_LIBS],
3614 [
3615 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
3616 cf_cv_hashed_db_libs=unknown
3617 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
3618 do
3619         cf_save_libs="$LIBS"
3620         if test -n "$cf_db_libs"; then
3621                 CF_ADD_LIB($cf_db_libs)
3622         fi
3623         CF_MSG_LOG(checking for library $cf_db_libs)
3624         AC_TRY_LINK([
3625 $ac_includes_default
3626 #include <db.h>
3627 ],[
3628         char *path = "/tmp/foo";
3629 #ifdef DB_VERSION_MAJOR
3630 #if DB_VERSION_MAJOR >= 4
3631         DB *result = 0;
3632         db_create(&result, NULL, 0);
3633         result->open(result,
3634                 NULL,
3635                 path,
3636                 path,
3637                 DB_HASH,
3638                 DB_CREATE,
3639                 0644);
3640 #elif DB_VERSION_MAJOR >= 3
3641         DB *result = 0;
3642         db_create(&result, NULL, 0);
3643         result->open(result,
3644                 path,
3645                 path,
3646                 DB_HASH,
3647                 DB_CREATE,
3648                 0644);
3649 #elif DB_VERSION_MAJOR >= 2
3650         DB *result = 0;
3651         db_open(path,
3652                 DB_HASH,
3653                 DB_CREATE,
3654                 0644,
3655                 (DB_ENV *) 0,
3656                 (DB_INFO *) 0,
3657                 &result);
3658 #endif /* DB_VERSION_MAJOR */
3659 #else
3660         DB *result = dbopen(path,
3661                      2,
3662                      0644,
3663                      DB_HASH,
3664                      0);
3665 #endif
3666         ${cf_cv_main_return:-return}(result != 0)
3667 ],[
3668         if test -n "$cf_db_libs" ; then
3669                 cf_cv_hashed_db_libs=$cf_db_libs
3670         else
3671                 cf_cv_hashed_db_libs=default
3672         fi
3673         LIBS="$cf_save_libs"
3674         break
3675 ])
3676         LIBS="$cf_save_libs"
3677 done
3678 ])
3679 ])dnl
3680 dnl ---------------------------------------------------------------------------
3681 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
3682 dnl --------------------
3683 dnl Given that we have the header file for hashed database, find the version
3684 dnl information.
3685 AC_DEFUN([CF_HASHED_DB_VERSION],
3686 [
3687 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
3688 cf_cv_hashed_db_version=unknown
3689
3690 for cf_db_version in 1 2 3 4 5 6
3691 do
3692         CF_MSG_LOG(checking for db version $cf_db_version)
3693         AC_TRY_COMPILE([
3694 $ac_includes_default
3695 #include <db.h>
3696
3697 #ifdef DB_VERSION_MAJOR
3698         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
3699 #if $cf_db_version == DB_VERSION_MAJOR
3700         /* ok */
3701 #else
3702         make an error
3703 #endif
3704 #else
3705 #if $cf_db_version == 1
3706         /* ok: assuming this is DB 1.8.5 */
3707 #else
3708         make an error
3709 #endif
3710 #endif
3711 ],[DBT *foo = 0],[
3712         cf_cv_hashed_db_version=$cf_db_version
3713         break
3714         ])
3715 done
3716 ])
3717 ])dnl
3718 dnl ---------------------------------------------------------------------------
3719 dnl CF_HEADER_PATH version: 15 updated: 2021/01/01 13:31:04
3720 dnl --------------
3721 dnl Construct a search-list of directories for a nonstandard header-file
3722 dnl
3723 dnl Parameters
3724 dnl     $1 = the variable to return as result
3725 dnl     $2 = the package name
3726 AC_DEFUN([CF_HEADER_PATH],
3727 [
3728 $1=
3729
3730 # collect the current set of include-directories from compiler flags
3731 cf_header_path_list=""
3732 if test -n "${CFLAGS}${CPPFLAGS}" ; then
3733         for cf_header_path in $CPPFLAGS $CFLAGS
3734         do
3735                 case "$cf_header_path" in
3736                 (-I*)
3737                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
3738                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
3739                         cf_header_path_list="$cf_header_path_list [$]$1"
3740                         ;;
3741                 esac
3742         done
3743 fi
3744
3745 # add the variations for the package we are looking for
3746 CF_SUBDIR_PATH($1,$2,include)
3747
3748 test "$includedir" != NONE && \
3749 test "$includedir" != "/usr/include" && \
3750 test -d "$includedir" && {
3751         test -d "$includedir" &&    $1="[$]$1 $includedir"
3752         test -d "$includedir/$2" && $1="[$]$1 $includedir/$2"
3753 }
3754
3755 test "$oldincludedir" != NONE && \
3756 test "$oldincludedir" != "/usr/include" && \
3757 test -d "$oldincludedir" && {
3758         test -d "$oldincludedir"    && $1="[$]$1 $oldincludedir"
3759         test -d "$oldincludedir/$2" && $1="[$]$1 $oldincludedir/$2"
3760 }
3761
3762 $1="[$]$1 $cf_header_path_list"
3763 ])dnl
3764 dnl ---------------------------------------------------------------------------
3765 dnl CF_HELP_MESSAGE version: 4 updated: 2019/12/31 08:53:54
3766 dnl ---------------
3767 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
3768 AC_DEFUN([CF_HELP_MESSAGE],
3769 [CF_ACVERSION_CHECK(2.53,[],[
3770 AC_DIVERT_HELP($1)])dnl
3771 ])dnl
3772 dnl ---------------------------------------------------------------------------
3773 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
3774 dnl ---------------
3775 dnl Construct the list of include-options according to whether we're building
3776 dnl in the source directory or using '--srcdir=DIR' option.
3777 AC_DEFUN([CF_INCLUDE_DIRS],
3778 [
3779 if test "$srcdir" != "."; then
3780         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
3781 fi
3782 CPPFLAGS="-I../include $CPPFLAGS"
3783 if test "$srcdir" != "."; then
3784         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
3785 fi
3786 CPPFLAGS="-I. $CPPFLAGS"
3787 AC_SUBST(CPPFLAGS)
3788 ])dnl
3789 dnl ---------------------------------------------------------------------------
3790 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
3791 dnl ---------------
3792 dnl prompt for/fill-in useful install-program options
3793 AC_DEFUN([CF_INSTALL_OPTS],
3794 [
3795 CF_INSTALL_OPT_S
3796 CF_INSTALL_OPT_P
3797 CF_INSTALL_OPT_O
3798 ])dnl
3799 dnl ---------------------------------------------------------------------------
3800 dnl CF_INSTALL_OPT_O version: 3 updated: 2020/12/31 20:19:42
3801 dnl ----------------
3802 dnl Almost all "install" programs default to the current user's ownership.
3803 dnl Almost - MINIX is an exception.
3804 AC_DEFUN([CF_INSTALL_OPT_O],
3805 [
3806 AC_MSG_CHECKING(if install needs to be told about ownership)
3807 case `$ac_config_guess` in
3808 (*minix)
3809         with_install_o=yes
3810         ;;
3811 (*)
3812         with_install_o=no
3813         ;;
3814 esac
3815
3816 AC_MSG_RESULT($with_install_o)
3817 if test "x$with_install_o" = xyes
3818 then
3819         INSTALL_OPT_O="`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`"
3820 else
3821         INSTALL_OPT_O=
3822 fi
3823
3824 AC_SUBST(INSTALL_OPT_O)
3825 ])dnl
3826 dnl ---------------------------------------------------------------------------
3827 dnl CF_INSTALL_OPT_P version: 3 updated: 2021/01/01 13:31:04
3828 dnl ----------------
3829 dnl Some install-programs accept a "-p" option to preserve file modification
3830 dnl timestamps.  That can be useful as an install option, as well as a way to
3831 dnl avoid the need for ranlib after copying a static archive.
3832 AC_DEFUN([CF_INSTALL_OPT_P],
3833 [
3834 : "${INSTALL:=install}"
3835 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
3836         rm -rf ./conftest*
3837         date >conftest.in
3838         mkdir conftest.out
3839         sleep 3
3840         if $INSTALL -p conftest.in conftest.out 2>/dev/null
3841         then
3842                 if test -f conftest.out/conftest.in
3843                 then
3844                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
3845                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
3846                         if test -s conftest.err
3847                         then
3848                                 cf_cv_install_p=no
3849                         else
3850                                 cf_cv_install_p=yes
3851                         fi
3852                 else
3853                         cf_cv_install_p=no
3854                 fi
3855         else
3856                 cf_cv_install_p=no
3857         fi
3858         rm -rf ./conftest*
3859 ])
3860 ])dnl
3861 dnl ---------------------------------------------------------------------------
3862 dnl CF_INSTALL_OPT_S version: 3 updated: 2021/01/05 19:23:48
3863 dnl ----------------
3864 dnl By default, we should strip executables which are installed, but leave the
3865 dnl ability to suppress that for unit-testing.
3866 AC_DEFUN([CF_INSTALL_OPT_S],
3867 [
3868 AC_MSG_CHECKING(if you want to install stripped executables)
3869 CF_ARG_DISABLE(stripping,
3870         [  --disable-stripping     do not strip (debug info) installed executables],
3871         [enable_stripping=no],
3872         [enable_stripping=yes])
3873 AC_MSG_RESULT($enable_stripping)
3874
3875 if test "$enable_stripping" = yes
3876 then
3877         INSTALL_OPT_S="-s"
3878 else
3879         INSTALL_OPT_S=
3880 fi
3881 AC_SUBST(INSTALL_OPT_S)
3882 ])dnl
3883 dnl ---------------------------------------------------------------------------
3884 dnl CF_INTEL_COMPILER version: 8 updated: 2021/01/01 16:53:59
3885 dnl -----------------
3886 dnl Check if the given compiler is really the Intel compiler for Linux.  It
3887 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
3888 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
3889 dnl
3890 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
3891 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
3892 dnl the wrappers for gcc and g++ warnings.
3893 dnl
3894 dnl $1 = GCC (default) or GXX
3895 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
3896 dnl $3 = CFLAGS (default) or CXXFLAGS
3897 AC_DEFUN([CF_INTEL_COMPILER],[
3898 AC_REQUIRE([AC_CANONICAL_HOST])
3899 ifelse([$2],,INTEL_COMPILER,[$2])=no
3900
3901 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
3902         case "$host_os" in
3903         (linux*|gnu*)
3904                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
3905                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
3906                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
3907                 AC_TRY_COMPILE([],[
3908 #ifdef __INTEL_COMPILER
3909 #else
3910 make an error
3911 #endif
3912 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
3913 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
3914 ],[])
3915                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
3916                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
3917                 ;;
3918         esac
3919 fi
3920 ])dnl
3921 dnl ---------------------------------------------------------------------------
3922 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
3923 dnl ----------
3924 dnl Check if we have either a function or macro for 'isascii()'.
3925 AC_DEFUN([CF_ISASCII],
3926 [
3927 AC_MSG_CHECKING(for isascii)
3928 AC_CACHE_VAL(cf_cv_have_isascii,[
3929         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
3930         [cf_cv_have_isascii=yes],
3931         [cf_cv_have_isascii=no])
3932 ])dnl
3933 AC_MSG_RESULT($cf_cv_have_isascii)
3934 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
3935 ])dnl
3936 dnl ---------------------------------------------------------------------------
3937 dnl CF_LARGEFILE version: 12 updated: 2020/03/19 20:23:48
3938 dnl ------------
3939 dnl Add checks for large file support.
3940 AC_DEFUN([CF_LARGEFILE],[
3941 ifdef([AC_FUNC_FSEEKO],[
3942         AC_SYS_LARGEFILE
3943         if test "$enable_largefile" != no ; then
3944         AC_FUNC_FSEEKO
3945
3946         # Normally we would collect these definitions in the config.h,
3947         # but (like _XOPEN_SOURCE), some environments rely on having these
3948         # defined before any of the system headers are included.  Another
3949         # case comes up with C++, e.g., on AIX the compiler compiles the
3950         # header files by themselves before looking at the body files it is
3951         # told to compile.  For ncurses, those header files do not include
3952         # the config.h
3953         if test "$ac_cv_sys_large_files" != no
3954         then
3955                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
3956         fi
3957         if test "$ac_cv_sys_largefile_source" != no
3958         then
3959                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
3960         fi
3961         if test "$ac_cv_sys_file_offset_bits" != no
3962         then
3963                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
3964         fi
3965
3966         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
3967                 AC_TRY_COMPILE([
3968 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
3969 #include <sys/types.h>
3970 #include <dirent.h>
3971                 ],[
3972                 /* if transitional largefile support is setup, this is true */
3973                 extern struct dirent64 * readdir(DIR *);
3974                 struct dirent64 *x = readdir((DIR *)0);
3975                 struct dirent *y = readdir((DIR *)0);
3976                 int z = x - y;
3977                 (void)z;
3978                 ],
3979                 [cf_cv_struct_dirent64=yes],
3980                 [cf_cv_struct_dirent64=no])
3981         ])
3982         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
3983         fi
3984 ])
3985 ])
3986 dnl ---------------------------------------------------------------------------
3987 dnl CF_LDFLAGS_STATIC version: 14 updated: 2021/01/02 17:09:14
3988 dnl -----------------
3989 dnl Check for compiler/linker flags used to temporarily force usage of static
3990 dnl libraries.  This depends on the compiler and platform.  Use this to help
3991 dnl ensure that the linker picks up a given library based on its position in
3992 dnl the list of linker options and libraries.
3993 AC_DEFUN([CF_LDFLAGS_STATIC],[
3994
3995 if test "$GCC" = yes ; then
3996         case "$cf_cv_system_name" in
3997         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
3998                 LDFLAGS_STATIC=
3999                 LDFLAGS_SHARED=
4000                 ;;
4001         (*)     # normally, except when broken
4002                 LDFLAGS_STATIC=-static
4003                 LDFLAGS_SHARED=-dynamic
4004                 ;;
4005         esac
4006 else
4007         case "$cf_cv_system_name" in
4008         (aix[[4-7]]*)   # from ld manpage
4009                 LDFLAGS_STATIC=-bstatic
4010                 LDFLAGS_SHARED=-bdynamic
4011                 ;;
4012         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
4013                 # We could also use just "archive" and "shared".
4014                 LDFLAGS_STATIC=-Wl,-a,archive_shared
4015                 LDFLAGS_SHARED=-Wl,-a,shared_archive
4016                 ;;
4017         (irix*)         # from ld manpage IRIX64
4018                 LDFLAGS_STATIC=-Bstatic
4019                 LDFLAGS_SHARED=-Bdynamic
4020                 ;;
4021         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
4022                 # alternative "-oldstyle_liblookup" (not in cc manpage)
4023                 LDFLAGS_STATIC=-noso
4024                 LDFLAGS_SHARED=-so_archive
4025                 ;;
4026         (solaris2*)
4027                 LDFLAGS_STATIC=-Bstatic
4028                 LDFLAGS_SHARED=-Bdynamic
4029                 ;;
4030         esac
4031 fi
4032
4033 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
4034 then
4035         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
4036
4037         rm -f libconftest.a
4038         cat >conftest.$ac_ext <<EOF
4039 #line __oline__ "configure"
4040 #include <stdio.h>
4041 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
4042 EOF
4043         if AC_TRY_EVAL(ac_compile) ; then
4044                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
4045                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
4046         fi
4047         rm -f conftest.*
4048
4049         cf_save_LIBS="$LIBS"
4050
4051         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
4052         AC_TRY_LINK([
4053 #line __oline__ "configure"
4054 #include <stdio.h>
4055 int cf_ldflags_static(FILE *fp);
4056 ],[
4057         return cf_ldflags_static(stdin);
4058 ],[
4059         # some linkers simply ignore the -dynamic
4060         case x`file "conftest$ac_exeext" 2>/dev/null` in
4061         (*static*)
4062                 cf_ldflags_static=no
4063                 ;;
4064         (*)
4065                 cf_ldflags_static=yes
4066                 ;;
4067         esac
4068 ],[cf_ldflags_static=no])
4069
4070         rm -f libconftest.*
4071         LIBS="$cf_save_LIBS"
4072
4073         AC_MSG_RESULT($cf_ldflags_static)
4074
4075         if test "$cf_ldflags_static" != yes
4076         then
4077                 LDFLAGS_STATIC=
4078                 LDFLAGS_SHARED=
4079         fi
4080 else
4081         LDFLAGS_STATIC=
4082         LDFLAGS_SHARED=
4083 fi
4084
4085 AC_SUBST(LDFLAGS_STATIC)
4086 AC_SUBST(LDFLAGS_SHARED)
4087 ])
4088 dnl ---------------------------------------------------------------------------
4089 dnl CF_LD_RPATH_OPT version: 9 updated: 2021/01/01 13:31:04
4090 dnl ---------------
4091 dnl For the given system and compiler, find the compiler flags to pass to the
4092 dnl loader to use the "rpath" feature.
4093 AC_DEFUN([CF_LD_RPATH_OPT],
4094 [
4095 AC_REQUIRE([CF_CHECK_CACHE])
4096
4097 LD_RPATH_OPT=
4098 if test "x$cf_cv_enable_rpath" != xno
4099 then
4100         AC_MSG_CHECKING(for an rpath option)
4101         case "$cf_cv_system_name" in
4102         (irix*)
4103                 if test "$GCC" = yes; then
4104                         LD_RPATH_OPT="-Wl,-rpath,"
4105                 else
4106                         LD_RPATH_OPT="-rpath "
4107                 fi
4108                 ;;
4109         (linux*|gnu*|k*bsd*-gnu|freebsd*)
4110                 LD_RPATH_OPT="-Wl,-rpath,"
4111                 ;;
4112         (openbsd[[2-9]].*|mirbsd*)
4113                 LD_RPATH_OPT="-Wl,-rpath,"
4114                 ;;
4115         (dragonfly*)
4116                 LD_RPATH_OPT="-rpath "
4117                 ;;
4118         (netbsd*)
4119                 LD_RPATH_OPT="-Wl,-rpath,"
4120                 ;;
4121         (osf*|mls+*)
4122                 LD_RPATH_OPT="-rpath "
4123                 ;;
4124         (solaris2*)
4125                 LD_RPATH_OPT="-R"
4126                 ;;
4127         (*)
4128                 ;;
4129         esac
4130         AC_MSG_RESULT($LD_RPATH_OPT)
4131
4132         case "x$LD_RPATH_OPT" in
4133         (x-R*)
4134                 AC_MSG_CHECKING(if we need a space after rpath option)
4135                 cf_save_LIBS="$LIBS"
4136                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
4137                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
4138                 LIBS="$cf_save_LIBS"
4139                 AC_MSG_RESULT($cf_rpath_space)
4140                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
4141                 ;;
4142         esac
4143 fi
4144 ])dnl
4145 dnl ---------------------------------------------------------------------------
4146 dnl CF_LD_SEARCHPATH version: 3 updated: 2021/03/05 19:13:35
4147 dnl ----------------
4148 dnl Try to obtain the linker's search-path, for use in scripts.
4149 dnl
4150 dnl Ignore LD_LIBRARY_PATH, etc.
4151 AC_DEFUN([CF_LD_SEARCHPATH],[
4152 AC_CACHE_CHECK(for linker search path,cf_cv_ld_searchpath,[
4153
4154 if test "$cross_compiling" != yes ; then
4155
4156 # GNU binutils' ld does not involve permissions which may stop ldconfig.
4157 cf_pathlist=`ld --verbose 2>/dev/null | grep SEARCH_DIR | sed -e 's,SEARCH_DIR[[("=]][[("=]]*,,g' -e 's/"[[)]];//gp' | sort -u`
4158
4159 # The -NX options tell newer versions of Linux ldconfig to not attempt to
4160 # update the cache, which makes it run faster.
4161 test -z "$cf_pathlist" && \
4162         cf_pathlist=`(ldconfig -NX -v) 2>/dev/null | sed -e '/^[[       ]]/d' -e 's/:$//' | sort -u`
4163
4164 test -z "$cf_pathlist" &&
4165         cf_pathlist=`(ldconfig -v) 2>/dev/null | sed -n -e '/^[[        ]]/d' -e 's/:$//p' | sort -u`
4166
4167 # This works with OpenBSD 6.5, which lists only filenames
4168 test -z "$cf_pathlist" &&
4169         cf_pathlist=`(ldconfig -v) 2>/dev/null | sed -n -e 's,^Adding \(.*\)/.*[$],\1,p' | sort -u`
4170
4171 if test -z "$cf_pathlist"
4172 then
4173         # dyld default path with MacOS
4174         if test -f /usr/bin/otool && test "x`uname -s`" = xDarwin
4175         then
4176                 # do this to bypass check
4177                 cf_cv_ld_searchpath='$HOME/lib'
4178                 cf_pathlist="/usr/local/lib /lib /usr/lib"
4179         fi
4180 fi
4181
4182 if test -z "$cf_pathlist"
4183 then
4184         # Solaris is "SunOS"
4185         if test -f /usr/bin/isainfo && test "x`uname -s`" = xSunOS
4186         then
4187                 case x`(isainfo -b)` in
4188                 (x64)
4189                         cf_pathlist="$cf_pathlist /lib/64 /usr/lib/64"
4190                         ;;
4191                 (x32)
4192                         test -d /usr/ccs/lib && cf_pathlist="$cf_pathlist /usr/ccs/lib"
4193                         cf_pathlist="$cf_pathlist /lib /usr/lib"
4194                         ;;
4195                 (*)
4196                         AC_MSG_WARN(problem with Solaris architecture)
4197                         ;;
4198                 esac
4199         fi
4200 fi
4201
4202 if test -z "$cf_pathlist"
4203 then
4204         # HP-UX
4205         if test x"`uname -s`" = xHP-UX
4206         then
4207                 case x`getconf LONG_BIT` in
4208                 (x64)
4209                         cf_pathlist="/usr/lib/hpux64"
4210                         ;;
4211                 (x*)
4212                         cf_pathlist="/usr/lib/hpux32"
4213                         ;;
4214                 esac
4215         fi
4216 fi
4217
4218 fi
4219
4220 # If nothing else, assume it is conventional
4221 test -z "$cf_pathlist" && cf_pathlist="/usr/lib /lib"
4222
4223 # Finally, check that this is only directories
4224 for cf_path in [$]0 $cf_pathlist
4225 do
4226         if test -d "$cf_path"; then
4227                 test -n "$cf_cv_ld_searchpath" && cf_cv_ld_searchpath="${cf_cv_ld_searchpath} "
4228                 cf_cv_ld_searchpath="${cf_cv_ld_searchpath}${cf_path}"
4229         fi
4230 done
4231
4232 # Ensure that it is nonempty
4233 test -z "$cf_cv_ld_searchpath" && cf_cv_ld_searchpath=/usr/lib
4234 ])
4235
4236 LD_SEARCHPATH=`echo "$cf_cv_ld_searchpath"|sed -e 's/ /|/g'`
4237 AC_SUBST(LD_SEARCHPATH)
4238 ])dnl
4239 dnl ---------------------------------------------------------------------------
4240 dnl CF_LIBRARY_PATH version: 11 updated: 2021/01/01 13:31:04
4241 dnl ---------------
4242 dnl Construct a search-list of directories for a nonstandard library-file
4243 dnl
4244 dnl Parameters
4245 dnl     $1 = the variable to return as result
4246 dnl     $2 = the package name
4247 AC_DEFUN([CF_LIBRARY_PATH],
4248 [
4249 $1=
4250 cf_library_path_list=""
4251 if test -n "${LDFLAGS}${LIBS}" ; then
4252         for cf_library_path in $LDFLAGS $LIBS
4253         do
4254                 case "$cf_library_path" in
4255                 (-L*)
4256                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
4257                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
4258                         cf_library_path_list="$cf_library_path_list [$]$1"
4259                         ;;
4260                 esac
4261         done
4262 fi
4263
4264 CF_SUBDIR_PATH($1,$2,lib)
4265
4266 $1="$cf_library_path_list [$]$1"
4267 ])dnl
4268 dnl ---------------------------------------------------------------------------
4269 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
4270 dnl ------------------
4271 AC_DEFUN([CF_LIBTOOL_VERSION],[
4272 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
4273 then
4274         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
4275 else
4276         cf_cv_libtool_version=
4277 fi
4278 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
4279 ])dnl
4280 dnl ---------------------------------------------------------------------------
4281 dnl CF_LIB_PREFIX version: 14 updated: 2021/01/01 13:31:04
4282 dnl -------------
4283 dnl Compute the library-prefix for the given host system
4284 dnl $1 = variable to set
4285 define([CF_LIB_PREFIX],
4286 [
4287         case "$cf_cv_system_name" in
4288         (OS/2*|os2*)
4289                 if test "$DFT_LWR_MODEL" = libtool; then
4290                         LIB_PREFIX='lib'
4291                 else
4292                         LIB_PREFIX=''
4293                 fi
4294                 ;;
4295         (*-msvc*)
4296                 LIB_PREFIX=''
4297                 ;;
4298         (*)     LIB_PREFIX='lib'
4299                 ;;
4300         esac
4301 ifelse($1,,,[$1=$LIB_PREFIX])
4302         AC_SUBST(LIB_PREFIX)
4303 ])dnl
4304 dnl ---------------------------------------------------------------------------
4305 dnl CF_LIB_RULES version: 95 updated: 2021/03/20 12:00:25
4306 dnl ------------
4307 dnl Append definitions and rules for the given models to the subdirectory
4308 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
4309 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
4310 dnl the corresponding makefile to list the models that we'll generate.
4311 dnl
4312 dnl For shared libraries, make a list of symbolic links to construct when
4313 dnl generating each library.  The convention used for Linux is the simplest
4314 dnl one:
4315 dnl     lib<name>.so    ->
4316 dnl     lib<name>.so.<major>    ->
4317 dnl     lib<name>.so.<maj>.<minor>
4318 dnl
4319 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
4320 AC_DEFUN([CF_LIB_RULES],
4321 [AC_REQUIRE([AC_PROG_FGREP])dnl
4322
4323 cf_prefix=$LIB_PREFIX
4324 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
4325
4326 case "$cf_cv_shlib_version" in
4327 (cygdll|msysdll|mingw|msvcdll)
4328         TINFO_NAME=$TINFO_ARG_SUFFIX
4329         TINFO_SUFFIX=.dll
4330         ;;
4331 esac
4332
4333 if test -n "$TINFO_SUFFIX" ; then
4334         case "$TINFO_SUFFIX" in
4335         (tw*)
4336                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
4337                 TINFO_SUFFIX=`echo "$TINFO_SUFFIX" | sed 's/^tw'$EXTRA_SUFFIX'//'`
4338                 ;;
4339         (t*)
4340                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
4341                 TINFO_SUFFIX=`echo "$TINFO_SUFFIX" | sed 's/^t'$EXTRA_SUFFIX'//'`
4342                 ;;
4343         (w*)
4344                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
4345                 TINFO_SUFFIX=`echo "$TINFO_SUFFIX" | sed 's/^w'$EXTRA_SUFFIX'//'`
4346                 ;;
4347         esac
4348 fi
4349
4350 for cf_dir in $SRC_SUBDIRS
4351 do
4352         if test ! -d "$srcdir/$cf_dir" ; then
4353                 continue
4354         elif test -f "$srcdir/$cf_dir/modules" ; then
4355
4356                 SHARED_LIB=
4357                 Libs_To_Make=
4358                 cf_awk_program=
4359                 if test -n "${cf_cv_abi_version}" && test "x${cf_cv_abi_version}" != "x5"
4360                 then
4361                         cf_awk_program="$cf_awk_program\
4362 /deprecated in ABI${cf_cv_abi_version}/ { next; }\
4363 { sub(\"NCURSES([[WT]]+)?\", \"&${cf_cv_abi_version}\"); }\
4364 "
4365                 fi
4366
4367                 if test "x$WILDCARD_SYMS" = xno
4368                 then
4369                         cf_awk_program="$cf_awk_program\
4370 /[[     ]]_\\*;/ { skip=1; next; }\
4371 "
4372                 fi
4373
4374                 if test "x$cf_awk_program" != "x"
4375                 then
4376                         cat >>$cf_dir/Makefile <<CF_EOF
4377
4378 # Generated by CF_LIB_RULES
4379 resulting.map: $UNALTERED_SYMS
4380         $AWK 'BEGIN { skip = 1; last=""; } \
4381 $cf_awk_program \
4382 { if ( last != "" && ( skip == 0 || \[$]\[$]0 !~ /}/ ) ) { print last; }\
4383  skip = 0; last = \[$]\[$]0; } \
4384 END { print last; }' < "$UNALTERED_SYMS" >\[$]@
4385
4386 distclean::
4387         rm -f resulting.map
4388 CF_EOF
4389                 fi
4390
4391                 for cf_item in $cf_LIST_MODELS
4392                 do
4393                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
4394                         if test "$cf_dir" = "c++"
4395                         then
4396                                 CF_MAP_LIB_BASENAME(cf_libname,cxx)
4397                         else
4398                                 CF_MAP_LIB_BASENAME(cf_libname,$cf_dir)
4399                         fi
4400                         test -z "$cf_libname" && cf_libname="$cf_dir"
4401                         if test "$cf_item" = shared ; then
4402                                 if test -n "${LIB_SUFFIX}"
4403                                 then
4404                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
4405                                 else
4406                                         cf_shared_suffix="$cf_suffix"
4407                                 fi
4408                                 if test "$cf_cv_do_symlinks" = yes ; then
4409                                         cf_version_name=
4410
4411                                         case "$cf_cv_shlib_version" in
4412                                         (rel)
4413                                                 cf_version_name=REL_VERSION
4414                                                 ;;
4415                                         (abi)
4416                                                 cf_version_name=ABI_VERSION
4417                                                 ;;
4418                                         esac
4419
4420                                         if test -n "$cf_version_name"
4421                                         then
4422                                                 case "$cf_cv_system_name" in
4423                                                 (darwin*)
4424                                                         # "w", etc?
4425                                                         cf_suffix="${USE_LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
4426                                                         ;;
4427                                                 (*)
4428                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
4429                                                         ;;
4430                                                 esac
4431                                         fi
4432                                         if test -n "${USE_LIB_SUFFIX}"
4433                                         then
4434                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
4435                                         else
4436                                                 cf_shared_suffix="$cf_suffix"
4437                                         fi
4438                                 fi
4439                                 # cygwin needs import library, and has unique naming convention
4440                                 # use autodetected ${cf_prefix} for import lib and static lib, but
4441                                 # use 'cyg' prefix for shared lib.
4442                                 case "$cf_cv_shlib_version" in
4443                                 (cygdll)
4444                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4445                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
4446                                         ;;
4447                                 (msysdll)
4448                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4449                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
4450                                         ;;
4451                                 (mingw)
4452                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4453                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
4454                                         ;;
4455                                 (msvcdll)
4456                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4457                                         cf_add_lib="../lib/${cf_libname}${cf_cygsuf}"
4458                                         ;;
4459                                 (*)
4460                                         cf_add_lib=
4461                                         ;;
4462                                 esac
4463                                 if test -n "$cf_add_lib"
4464                                 then
4465                                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
4466                                         continue
4467                                 fi
4468                         fi
4469                         cf_add_lib="../lib/${cf_prefix}${cf_libname}${cf_suffix}"
4470                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
4471                 done
4472
4473                 if test "$cf_dir" = ncurses ; then
4474                         cf_subsets="$LIB_SUBSETS"
4475                         cf_r_parts="$cf_subsets"
4476                         cf_liblist="$Libs_To_Make"
4477
4478                         while test -n "$cf_r_parts"
4479                         do
4480                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
4481                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
4482                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
4483                                         cf_add_lib=
4484                                         case "$cf_l_parts" in
4485                                         (*termlib*)
4486                                                 cf_add_lib=`echo "$cf_liblist" |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
4487                                                 ;;
4488                                         (*ticlib*)
4489                                                 cf_add_lib=`echo "$cf_liblist" |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
4490                                                 ;;
4491                                         (*)
4492                                                 break
4493                                                 ;;
4494                                         esac
4495                                         if test -n "$cf_add_lib"; then
4496                                                 Libs_To_Make="$cf_add_lib $Libs_To_Make"
4497                                         fi
4498                                 else
4499                                         break
4500                                 fi
4501                         done
4502                 else
4503                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
4504                 fi
4505
4506                 if test "$cf_dir" = c++; then
4507                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
4508                                 cf_list=
4509                                 for cf_item in $Libs_To_Make
4510                                 do
4511                                         case "$cf_item" in
4512                                         (*.a)
4513                                                 ;;
4514                                         (*)
4515                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
4516                                                 ;;
4517                                         esac
4518                                         for cf_test in $cf_list
4519                                         do
4520                                                 if test "$cf_test" = "$cf_item"
4521                                                 then
4522                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
4523                                                         cf_item=
4524                                                         break
4525                                                 fi
4526                                         done
4527                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
4528                                 done
4529                                 Libs_To_Make="$cf_list"
4530                         fi
4531                 fi
4532
4533                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
4534                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
4535                         "$cf_dir/Makefile" >$cf_dir/Makefile.out
4536                 mv "$cf_dir/Makefile.out" "$cf_dir/Makefile"
4537
4538                 $AWK -f "$srcdir/mk-0th.awk" \
4539                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
4540                         "$srcdir/$cf_dir/modules" >>$cf_dir/Makefile
4541
4542                 for cf_subset in $cf_subsets
4543                 do
4544                         cf_subdirs=
4545                         for cf_item in $cf_LIST_MODELS
4546                         do
4547
4548                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
4549                         CF_UPPER(cf_ITEM,$cf_item)
4550
4551                         CXX_MODEL=$cf_ITEM
4552                         if test "$CXX_MODEL" = SHARED; then
4553                                 case "$cf_cv_shlib_version" in
4554                                 (cygdll|msysdll|mingw|msvcdll)
4555                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
4556                                         with_shared_cxx=yes
4557                                         ;;
4558                                 (*)
4559                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
4560                                         ;;
4561                                 esac
4562                         fi
4563
4564                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
4565                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
4566
4567                         # Test for case where we build libtinfo with a different name.
4568                         cf_libname=$cf_dir
4569                         if test "$cf_dir" = ncurses ; then
4570                                 case "$cf_subset" in
4571                                 (*base*)
4572                                         cf_libname=${cf_libname}$USE_LIB_SUFFIX
4573                                         ;;
4574                                 (*termlib*)
4575                                         cf_libname=$TINFO_LIB_SUFFIX
4576                                         ;;
4577                                 (ticlib*)
4578                                         cf_libname=$TICS_LIB_SUFFIX
4579                                         ;;
4580                                 esac
4581                         elif test "$cf_dir" = c++ ; then
4582                                 CF_MAP_LIB_BASENAME(cf_libname,cxx)
4583                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
4584                         else
4585                                 CF_MAP_LIB_BASENAME(cf_libname,$cf_dir)
4586                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
4587                         fi
4588                         if test -n "${USE_ARG_SUFFIX}" ; then
4589                                 # undo $USE_LIB_SUFFIX add-on in CF_LIB_SUFFIX
4590                                 cf_suffix=`echo "$cf_suffix" |sed -e "s%^${USE_LIB_SUFFIX}%%"`
4591                         fi
4592
4593                         # These dependencies really are for development, not
4594                         # builds, but they are useful in porting, too.
4595                         cf_depend="../include/ncurses_cfg.h"
4596                         if test "$srcdir" = "."; then
4597                                 cf_reldir="."
4598                         else
4599                                 cf_reldir="\${srcdir}"
4600                         fi
4601
4602                         if test -f "$srcdir/$cf_dir/$cf_dir.priv.h" ; then
4603                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
4604                         elif test -f "$srcdir/$cf_dir/curses.priv.h" ; then
4605                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
4606                         fi
4607
4608                         cf_dir_suffix=
4609                         old_cf_suffix="$cf_suffix"
4610                         if test "$cf_cv_shlib_version_infix" = yes ; then
4611                         if test -n "$USE_LIB_SUFFIX" ; then
4612                                 case "$USE_LIB_SUFFIX" in
4613                                 (tw*)
4614                                         cf_libname=`echo "$cf_libname" | sed 's/tw'$EXTRA_SUFFIX'$//'`
4615                                         cf_suffix=`echo "$cf_suffix" | sed 's/^tw'$EXTRA_SUFFIX'//'`
4616                                         cf_dir_suffix=tw$EXTRA_SUFFIX
4617                                         ;;
4618                                 (t*)
4619                                         cf_libname=`echo "$cf_libname" | sed 's/t'$EXTRA_SUFFIX'$//'`
4620                                         cf_suffix=`echo "$cf_suffix" | sed 's/^t'$EXTRA_SUFFIX'//'`
4621                                         cf_dir_suffix=t$EXTRA_SUFFIX
4622                                         ;;
4623                                 (w*)
4624                                         cf_libname=`echo "$cf_libname" | sed 's/w'$EXTRA_SUFFIX'$//'`
4625                                         cf_suffix=`echo "$cf_suffix" | sed 's/^w'$EXTRA_SUFFIX'//'`
4626                                         cf_dir_suffix=w$EXTRA_SUFFIX
4627                                         ;;
4628                                 (*)
4629                                         cf_libname=`echo "$cf_libname" | sed 's/'$EXTRA_SUFFIX'$//'`
4630                                         cf_suffix=`echo "$cf_suffix" | sed 's/^'$EXTRA_SUFFIX'//'`
4631                                         cf_dir_suffix=$EXTRA_SUFFIX
4632                                         ;;
4633                                 esac
4634                         fi
4635                         fi
4636
4637                         $AWK -f "$srcdir/mk-1st.awk" \
4638                                 name=${cf_libname}${cf_dir_suffix} \
4639                                 traces=$LIB_TRACING \
4640                                 MODEL=$cf_ITEM \
4641                                 CXX_MODEL=$CXX_MODEL \
4642                                 model=$cf_subdir \
4643                                 prefix=$cf_prefix \
4644                                 suffix=$cf_suffix \
4645                                 subset=$cf_subset \
4646                                 driver=$cf_cv_term_driver \
4647                                 SymLink="$LN_S" \
4648                                 TermlibRoot=$TINFO_NAME \
4649                                 TermlibSuffix=$TINFO_SUFFIX \
4650                                 ShlibVer=$cf_cv_shlib_version \
4651                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
4652                                 ReLink=${cf_cv_do_relink:-no} \
4653                                 ReRanlib=${cf_cv_do_reranlib:-yes} \
4654                                 DoLinks=$cf_cv_do_symlinks \
4655                                 rmSoLocs=$cf_cv_rm_so_locs \
4656                                 ldconfig="$LDCONFIG" \
4657                                 overwrite=$WITH_OVERWRITE \
4658                                 depend="$cf_depend" \
4659                                 host="$host" \
4660                                 libtool_version="$LIBTOOL_VERSION" \
4661                                 "$srcdir/$cf_dir/modules" >>$cf_dir/Makefile
4662
4663                         cf_suffix="$old_cf_suffix"
4664
4665                         for cf_subdir2 in $cf_subdirs lib
4666                         do
4667                                 test "$cf_subdir" = "$cf_subdir2" && break
4668                         done
4669                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
4670                         $AWK -f "$srcdir/mk-2nd.awk" \
4671                                 name=$cf_dir \
4672                                 traces=$LIB_TRACING \
4673                                 MODEL=$cf_ITEM \
4674                                 model=$cf_subdir \
4675                                 subset=$cf_subset \
4676                                 srcdir=$srcdir \
4677                                 echo=$WITH_ECHO \
4678                                 crenames=$cf_cv_prog_CC_c_o \
4679                                 cxxrenames=$cf_cv_prog_CXX_c_o \
4680                                 "$srcdir/$cf_dir/modules" >>$cf_dir/Makefile
4681                         cf_subdirs="$cf_subdirs $cf_subdir"
4682                         done
4683                 done
4684         fi
4685
4686         echo '  ( cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@ )' >>Makefile
4687 done
4688
4689 for cf_dir in $SRC_SUBDIRS
4690 do
4691         if test ! -d "$srcdir/$cf_dir" ; then
4692                 continue
4693         fi
4694
4695         if test -f "$cf_dir/Makefile" ; then
4696                 case "$cf_dir" in
4697                 (Ada95)
4698                         echo 'libs \' >> Makefile
4699                         echo 'install.libs \' >> Makefile
4700                         echo 'uninstall.libs ::' >> Makefile
4701                         echo '  ( cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@ )' >> Makefile
4702                         ;;
4703                 esac
4704         fi
4705
4706         if test -f "$srcdir/$cf_dir/modules" ; then
4707                 echo >> Makefile
4708                 if test -f "$srcdir/$cf_dir/headers" ; then
4709 cat >> Makefile <<CF_EOF
4710 install.includes \\
4711 uninstall.includes \\
4712 CF_EOF
4713                 fi
4714
4715 echo 'lint \' >> Makefile
4716
4717 cat >> Makefile <<CF_EOF
4718 libs \\
4719 lintlib \\
4720 install.libs \\
4721 uninstall.libs \\
4722 install.$cf_dir \\
4723 uninstall.$cf_dir ::
4724         ( cd "$cf_dir" && \${MAKE} \${TOP_MFLAGS} \[$]@ )
4725 CF_EOF
4726         elif test -f "$srcdir/$cf_dir/headers" ; then
4727 cat >> Makefile <<CF_EOF
4728
4729 libs \\
4730 install.libs \\
4731 uninstall.libs \\
4732 install.includes \\
4733 uninstall.includes ::
4734         ( cd "$cf_dir" && \${MAKE} \${TOP_MFLAGS} \[$]@ )
4735 CF_EOF
4736 fi
4737 done
4738
4739 if test "x$cf_with_db_install" = xyes; then
4740 cat >> Makefile <<CF_EOF
4741
4742 install.libs uninstall.libs \\
4743 install.data uninstall.data ::
4744 $MAKE_TERMINFO  ( cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@ )
4745 CF_EOF
4746 else
4747 cat >> Makefile <<CF_EOF
4748
4749 install.libs uninstall.libs ::
4750         ( cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@ )
4751 CF_EOF
4752 fi
4753
4754 if test "x$cf_with_manpages" = xyes; then
4755 cat >> Makefile <<CF_EOF
4756
4757 install.man \\
4758 uninstall.man ::
4759         ( cd man && \${MAKE} \${TOP_MFLAGS} \[$]@ )
4760 CF_EOF
4761 fi
4762
4763 cat >> Makefile <<CF_EOF
4764
4765 distclean ::
4766         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
4767         rm -f headers.sh headers.sed mk_shared_lib.sh
4768         rm -f edit_man.* man_alias.*
4769         rm -rf \${DIRS_TO_MAKE}
4770 CF_EOF
4771
4772 # Special case: tack's manpage lives in its own directory.
4773 if test "x$cf_with_manpages" = xyes; then
4774 if test "x$cf_with_tack" = "xyes"; then
4775 cat >> Makefile <<CF_EOF
4776
4777 install.man \\
4778 uninstall.man ::
4779         ( cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@ )
4780 CF_EOF
4781 fi
4782 fi
4783
4784 dnl If we're installing into a subdirectory of /usr/include, etc., we should
4785 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
4786 dnl anything, and will make it more standardized.  It's awkward to decide this
4787 dnl at configuration because of quoting, so we'll simply make all headers
4788 dnl installed via a script that can do the right thing.
4789
4790 rm -f headers.sed headers.sh
4791
4792 dnl ( generating this script makes the makefiles a little tidier :-)
4793 echo creating headers.sh
4794 cat >headers.sh <<CF_EOF
4795 #! $SHELL
4796 # This shell script is generated by the 'configure' script.  It is invoked in a
4797 # subdirectory of the build tree.  It generates a sed-script in the parent
4798 # directory that is used to adjust includes for header files that reside in a
4799 # subdirectory of /usr/include, etc.
4800 PRG=""
4801 while test \[$]# != 3
4802 do
4803 PRG="\$PRG \[$]1"; shift
4804 done
4805 DST=\[$]1
4806 REF=\[$]2
4807 SRC=\[$]3
4808 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
4809 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
4810 echo installing \$SRC in \$DST
4811 CF_EOF
4812
4813 if test "$WITH_CURSES_H" = yes; then
4814         cat >>headers.sh <<CF_EOF
4815 case \$DST in
4816 (/*/include/*)
4817         END=\`basename \$DST\`
4818         for i in \`cat \$REF/../*/headers |${FGREP-fgrep} -v "#"\`
4819         do
4820                 NAME=\`basename \$i\`
4821                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
4822         done
4823         ;;
4824 (*)
4825         echo "" >> \$TMPSED
4826         ;;
4827 esac
4828 CF_EOF
4829
4830 else
4831         cat >>headers.sh <<CF_EOF
4832 case \$DST in
4833 (/*/include/*)
4834         END=\`basename \$DST\`
4835         for i in \`cat \$REF/../*/headers |${FGREP-fgrep} -v "#"\`
4836         do
4837                 NAME=\`basename \$i\`
4838                 if test "\$NAME" = "curses.h"
4839                 then
4840                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
4841                         NAME=ncurses.h
4842                 fi
4843                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
4844         done
4845         ;;
4846 (*)
4847         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
4848         ;;
4849 esac
4850 CF_EOF
4851 fi
4852 cat >>headers.sh <<CF_EOF
4853 rm -f \$TMPSRC
4854 sed -f \$TMPSED \$SRC > \$TMPSRC
4855 NAME=\`basename \$SRC\`
4856 CF_EOF
4857 if test "$WITH_CURSES_H" != yes; then
4858         cat >>headers.sh <<CF_EOF
4859 test "\$NAME" = "curses.h" && NAME=ncurses.h
4860 CF_EOF
4861 fi
4862 cat >>headers.sh <<CF_EOF
4863 # Just in case someone gzip'd manpages, remove the conflicting copy.
4864 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
4865
4866 eval \$PRG \$TMPSRC \$DST/\$NAME
4867 rm -f \$TMPSRC \$TMPSED
4868 CF_EOF
4869
4870 chmod 0755 headers.sh
4871
4872 for cf_dir in $SRC_SUBDIRS
4873 do
4874         if test ! -d "$srcdir/$cf_dir" ; then
4875                 continue
4876         fi
4877
4878         if test -f "$srcdir/$cf_dir/headers" ; then
4879                 $AWK -f "$srcdir/mk-hdr.awk" \
4880                         subset="$LIB_SUBSETS" \
4881                         compat="$WITH_CURSES_H" \
4882                         "$srcdir/$cf_dir/headers" >>$cf_dir/Makefile
4883         fi
4884
4885         if test -f "$srcdir/$cf_dir/modules" ; then
4886                 if test "$cf_dir" != "c++" ; then
4887                         cat >>$cf_dir/Makefile <<"CF_EOF"
4888 depend : ${AUTO_SRC}
4889         makedepend -- ${CPPFLAGS} -- ${C_SRC}
4890
4891 # DO NOT DELETE THIS LINE -- make depend depends on it.
4892 CF_EOF
4893                 fi
4894         fi
4895 done
4896 AC_SUBST(Libs_To_Make)
4897 ])dnl
4898 dnl ---------------------------------------------------------------------------
4899 dnl CF_LIB_SONAME version: 9 updated: 2021/01/04 18:48:01
4900 dnl -------------
4901 dnl Find the and soname for the given shared library.  Set the cache variable
4902 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
4903 dnl variable to "unknown".
4904 dnl
4905 dnl $1 = headers
4906 dnl $2 = code
4907 dnl $3 = library name
4908 AC_DEFUN([CF_LIB_SONAME],
4909 [AC_REQUIRE([AC_PROG_FGREP])dnl
4910
4911 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
4912
4913 cf_cv_$3_soname=unknown
4914 if test "$cross_compiling" != yes ; then
4915 cat >conftest.$ac_ext <<CF_EOF
4916 $1
4917 int main(void)
4918 {
4919 $2
4920         ${cf_cv_main_return:-return}(0);
4921 }
4922 CF_EOF
4923 cf_save_LIBS="$LIBS"
4924         CF_ADD_LIB($3)
4925         if AC_TRY_EVAL(ac_compile) ; then
4926                 if AC_TRY_EVAL(ac_link) ; then
4927                         cf_cv_$3_soname="`ldd \"conftest$ac_exeext\" 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | ${FGREP-fgrep} lib$3.`"
4928                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
4929                 fi
4930         fi
4931 rm -rf ./conftest*
4932 LIBS="$cf_save_LIBS"
4933 fi
4934 ])
4935 ])
4936 dnl ---------------------------------------------------------------------------
4937 dnl CF_LIB_SUFFIX version: 28 updated: 2021/01/01 16:53:59
4938 dnl -------------
4939 dnl Compute the library file-suffix from the given model name
4940 dnl $1 = model name
4941 dnl $2 = variable to set (the nominal library suffix)
4942 dnl $3 = dependency variable to set (actual filename)
4943 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4944 AC_DEFUN([CF_LIB_SUFFIX],
4945 [
4946         case X$1 in
4947         (Xlibtool)
4948                 $2='.la'
4949                 $3=[$]$2
4950                 ;;
4951         (Xdebug)
4952                 case "$cf_cv_system_name" in
4953                 (*-msvc*)
4954                         $2='_g.lib'
4955                         ;;
4956                 (*)
4957                         $2='_g.a'
4958                         ;;
4959                 esac
4960                 $3=[$]$2
4961                 ;;
4962         (Xprofile)
4963                 case "$cf_cv_system_name" in
4964                 (*-msvc*)
4965                         $2='_p.lib'
4966                         ;;
4967                 (*)
4968                         $2='_p.a'
4969                         ;;
4970                 esac
4971                 $3=[$]$2
4972                 ;;
4973         (Xshared)
4974                 case "$cf_cv_system_name" in
4975                 (aix[[5-7]]*)
4976                         $2='.so'
4977                         $3=[$]$2
4978                         ;;
4979                 (*-msvc*)
4980                         $2='.dll'
4981                         $3='.dll.lib'
4982                         ;;
4983                 (cygwin*|msys*|mingw*)
4984                         $2='.dll'
4985                         $3='.dll.a'
4986                         ;;
4987                 (darwin*)
4988                         $2='.dylib'
4989                         $3=[$]$2
4990                         ;;
4991                 (hpux*)
4992                         case "$target" in
4993                         (ia64*)
4994                                 $2='.so'
4995                                 $3=[$]$2
4996                                 ;;
4997                         (*)
4998                                 $2='.sl'
4999                                 $3=[$]$2
5000                                 ;;
5001                         esac
5002                         ;;
5003                 (*)
5004                         $2='.so'
5005                         $3=[$]$2
5006                         ;;
5007                 esac
5008                 ;;
5009         (*)
5010                 case "$target" in
5011                 (*-msvc*)
5012                         $2='.lib'
5013                         ;;
5014                 (*)
5015                         $2='.a'
5016                         ;;
5017                 esac
5018                 $3=[$]$2
5019                 ;;
5020         esac
5021         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
5022         then
5023                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
5024                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
5025         fi
5026 ])dnl
5027 dnl ---------------------------------------------------------------------------
5028 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
5029 dnl -----------
5030 dnl Compute the string to append to -library from the given model name
5031 dnl $1 = model name
5032 dnl $2 = variable to set
5033 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
5034 AC_DEFUN([CF_LIB_TYPE],
5035 [
5036         case $1 in
5037         (libtool) $2=''   ;;
5038         (normal)  $2=''   ;;
5039         (debug)   $2='_g' ;;
5040         (profile) $2='_p' ;;
5041         (shared)  $2=''   ;;
5042         esac
5043         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
5044 ])dnl
5045 dnl ---------------------------------------------------------------------------
5046 dnl CF_LINK_DATAONLY version: 13 updated: 2020/02/08 15:59:30
5047 dnl ----------------
5048 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
5049 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
5050 dnl have to provide wrappers for global tables to ensure they're linked
5051 dnl properly.
5052 AC_DEFUN([CF_LINK_DATAONLY],
5053 [
5054 AC_MSG_CHECKING([if data-only library module links])
5055 AC_CACHE_VAL(cf_cv_link_dataonly,[
5056         rm -f conftest.a
5057         cat >conftest.$ac_ext <<EOF
5058 #line __oline__ "configure"
5059 int     testdata[[3]] = { 123, 456, 789 };
5060 EOF
5061         if AC_TRY_EVAL(ac_compile) ; then
5062                 mv conftest.o data.o && \
5063                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
5064         fi
5065         rm -f conftest.$ac_ext data.o
5066         cat >conftest.$ac_ext <<EOF
5067 #line __oline__ "configure"
5068 int     testfunc(void)
5069 {
5070 #if defined(NeXT)
5071         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
5072 #else
5073         extern int testdata[[3]];
5074         return testdata[[0]] == 123
5075            &&  testdata[[1]] == 456
5076            &&  testdata[[2]] == 789;
5077 #endif
5078 }
5079 EOF
5080         if AC_TRY_EVAL(ac_compile); then
5081                 mv conftest.o func.o && \
5082                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
5083         fi
5084         rm -f conftest.$ac_ext func.o
5085         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
5086         cf_saveLIBS="$LIBS"
5087         LIBS="conftest.a $LIBS"
5088         AC_TRY_RUN([
5089         int main(void)
5090         {
5091                 extern int testfunc();
5092                 ${cf_cv_main_return:-return} (!testfunc());
5093         }
5094         ],
5095         [cf_cv_link_dataonly=yes],
5096         [cf_cv_link_dataonly=no],
5097         [cf_cv_link_dataonly=unknown])
5098         LIBS="$cf_saveLIBS"
5099         ])
5100 AC_MSG_RESULT($cf_cv_link_dataonly)
5101
5102 if test "$cf_cv_link_dataonly" = no ; then
5103         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
5104         BROKEN_LINKER=1
5105 fi
5106 AC_SUBST(BROKEN_LINKER)
5107
5108 ])dnl
5109 dnl ---------------------------------------------------------------------------
5110 dnl CF_LINK_FUNCS version: 11 updated: 2021/04/18 14:08:47
5111 dnl -------------
5112 dnl Most Unix systems have both link and symlink, a few don't have symlink.
5113 dnl A few non-Unix systems implement symlink, but not link.
5114 dnl A few non-systems implement neither (or have nonfunctional versions).
5115 dnl
5116 dnl This allows for a 2-second difference in modification times to allow for
5117 dnl some marginal NFS implementations.
5118 AC_DEFUN([CF_LINK_FUNCS],
5119 [
5120 AC_CHECK_HEADERS( \
5121 unistd.h \
5122 )
5123 AC_CHECK_FUNCS( \
5124         remove \
5125         unlink )
5126
5127 if test "$cross_compiling" = yes ; then
5128         AC_CHECK_FUNCS( \
5129                 link \
5130                 symlink )
5131 else
5132         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
5133                 cf_cv_link_funcs=
5134                 for cf_func in link symlink ; do
5135                         AC_TRY_RUN([
5136 #include <stdio.h>
5137 #include <sys/types.h>
5138 #include <sys/stat.h>
5139 #ifdef HAVE_UNISTD_H
5140 #include <unistd.h>
5141 #endif
5142 int main(void)
5143 {
5144         int fail = 0;
5145         char *src = "conftest.tmp";
5146         char *dst = "conftest.chk";
5147         struct stat src_sb, dst_sb;
5148         FILE *fp = fopen(src, "w");
5149         if (fp == 0) { fail = 3; } else {
5150                 fclose(fp); stat(src, &src_sb);
5151                 if ($cf_func(src, dst) < 0) {
5152                         fail = 1;
5153                 } else if (stat(dst, &dst_sb) < 0) {
5154                         fail = 2;
5155                 } else {
5156                         long diff = (dst_sb.st_mtime - src_sb.st_mtime);
5157                         if (diff < 0) diff = -diff;
5158                         if (diff > 2) fail = 3;
5159                 }
5160         }
5161 #ifdef HAVE_UNLINK
5162         unlink(dst); unlink(src);
5163 #else
5164         remove(dst); remove(src);
5165 #endif
5166         ${cf_cv_main_return:-return} (fail);
5167 }
5168                         ],[
5169                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
5170                         eval 'ac_cv_func_'$cf_func'=yes'],[
5171                         eval 'ac_cv_func_'$cf_func'=no'],[
5172                         eval 'ac_cv_func_'$cf_func'=error'])
5173                 done
5174                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
5175         ])
5176         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
5177         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
5178 fi
5179 ])dnl
5180 dnl ---------------------------------------------------------------------------
5181 dnl CF_MAKEFLAGS version: 20 updated: 2021/01/03 19:29:49
5182 dnl ------------
5183 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
5184 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
5185 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
5186 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
5187 AC_DEFUN([CF_MAKEFLAGS],
5188 [AC_REQUIRE([AC_PROG_FGREP])dnl
5189
5190 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
5191         cf_cv_makeflags=''
5192         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
5193         do
5194                 cat >cf_makeflags.tmp <<CF_EOF
5195 SHELL = $SHELL
5196 all :
5197         @ echo '.$cf_option'
5198 CF_EOF
5199                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | ${FGREP-fgrep} -v "ing directory" | sed -e 's,[[  ]]*$,,'`
5200                 case "$cf_result" in
5201                 (.*k|.*kw)
5202                         cf_result="`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`"
5203                         case "$cf_result" in
5204                         (.*CC=*)        cf_cv_makeflags=
5205                                 ;;
5206                         (*)     cf_cv_makeflags=$cf_option
5207                                 ;;
5208                         esac
5209                         break
5210                         ;;
5211                 (.-)
5212                         ;;
5213                 (*)
5214                         CF_MSG_LOG(given option \"$cf_option\", no match \"$cf_result\")
5215                         ;;
5216                 esac
5217         done
5218         rm -f cf_makeflags.tmp
5219 ])
5220
5221 AC_SUBST(cf_cv_makeflags)
5222 ])dnl
5223 dnl ---------------------------------------------------------------------------
5224 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
5225 dnl ------------
5226 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
5227 dnl a monocase filesystem.
5228 AC_DEFUN([CF_MAKE_TAGS],[
5229 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
5230
5231 AC_CHECK_PROGS(CTAGS, exctags ctags)
5232 AC_CHECK_PROGS(ETAGS, exetags etags)
5233
5234 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
5235
5236 if test "$cf_cv_mixedcase" = yes ; then
5237         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
5238 else
5239         MAKE_UPPER_TAGS=no
5240 fi
5241
5242 if test "$MAKE_UPPER_TAGS" = yes ; then
5243         MAKE_UPPER_TAGS=
5244 else
5245         MAKE_UPPER_TAGS="#"
5246 fi
5247
5248 if test "$MAKE_LOWER_TAGS" = yes ; then
5249         MAKE_LOWER_TAGS=
5250 else
5251         MAKE_LOWER_TAGS="#"
5252 fi
5253
5254 AC_SUBST(CTAGS)
5255 AC_SUBST(ETAGS)
5256
5257 AC_SUBST(MAKE_UPPER_TAGS)
5258 AC_SUBST(MAKE_LOWER_TAGS)
5259 ])dnl
5260 dnl ---------------------------------------------------------------------------
5261 dnl CF_MANPAGE_FORMAT version: 14 updated: 2021/01/02 17:09:14
5262 dnl -----------------
5263 dnl Option to allow user to override automatic configuration of manpage format.
5264 dnl There are several special cases:
5265 dnl
5266 dnl     gzip - man checks for, can display gzip'd files
5267 dnl     compress - man checks for, can display compressed files
5268 dnl     BSDI - files in the cat-directories are suffixed ".0"
5269 dnl     formatted - installer should format (put files in cat-directory)
5270 dnl     catonly - installer should only format, e.g., for a turnkey system.
5271 dnl
5272 dnl There are other configurations which this macro does not test, e.g., HPUX's
5273 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
5274 dnl convention would not match our use).
5275 AC_DEFUN([CF_MANPAGE_FORMAT],
5276 [
5277 AC_REQUIRE([CF_PATHSEP])
5278 AC_MSG_CHECKING(format of man-pages)
5279
5280 AC_ARG_WITH(manpage-format,
5281         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
5282                           optionally formatted/catonly, e.g., gzip,formatted],
5283         [MANPAGE_FORMAT=$withval],
5284         [MANPAGE_FORMAT=unknown])
5285
5286 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
5287 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
5288
5289 cf_unknown=
5290
5291 case "$MANPAGE_FORMAT" in
5292 (unknown)
5293         if test -z "$MANPATH" ; then
5294                 MANPATH="/usr/man:/usr/share/man"
5295         fi
5296
5297         # look for the 'date' man-page (it's most likely to be installed!)
5298         MANPAGE_FORMAT=
5299         cf_preform="no"
5300         cf_catonly="yes"
5301         cf_example="date"
5302
5303         IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
5304         for cf_dir in $MANPATH; do
5305                 test -z "$cf_dir" && cf_dir=/usr/man
5306                 for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
5307                 do
5308                         cf_test=`echo "$cf_name" | sed -e 's/*//'`
5309                         if test "x$cf_test" = "x$cf_name" ; then
5310
5311                                 case "$cf_name" in
5312                                 (*.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
5313                                 (*.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
5314                                 (*.0)  MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
5315                                 (*)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
5316                                 esac
5317
5318                                 case "$cf_name" in
5319                                 ($cf_dir/man*)
5320                                         cf_catonly=no
5321                                         ;;
5322                                 ($cf_dir/cat*)
5323                                         cf_preform=yes
5324                                         ;;
5325                                 esac
5326                                 break
5327                         fi
5328
5329                         # if we found a match in either man* or cat*, stop looking
5330                         if test -n "$MANPAGE_FORMAT" ; then
5331                                 cf_found=no
5332                                 test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
5333                                 test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
5334                                 case "$cf_name" in
5335                                 ($cf_dir/cat*)
5336                                         cf_found=yes
5337                                         ;;
5338                                 esac
5339                                 test "$cf_found" = yes && break
5340                         fi
5341                 done
5342                 # only check the first directory in $MANPATH where we find manpages
5343                 if test -n "$MANPAGE_FORMAT" ; then
5344                         break
5345                 fi
5346         done
5347         # if we did not find the example, just assume it is normal
5348         test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
5349         IFS="$ac_save_ifs"
5350         ;;
5351 (*)
5352         for cf_option in $MANPAGE_FORMAT; do
5353         case "$cf_option" in
5354         (gzip|compress|BSDI|normal|formatted|catonly)
5355                 ;;
5356         (*)
5357                 cf_unknown="$cf_unknown $cf_option"
5358                 ;;
5359         esac
5360         done
5361         ;;
5362 esac
5363
5364 AC_MSG_RESULT($MANPAGE_FORMAT)
5365 if test -n "$cf_unknown" ; then
5366         AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
5367 fi
5368 ])dnl
5369 dnl ---------------------------------------------------------------------------
5370 dnl CF_MANPAGE_RENAMES version: 12 updated: 2021/01/01 16:53:59
5371 dnl ------------------
5372 dnl The Debian people have their own naming convention for manpages.  This
5373 dnl option lets us override the name of the file containing renaming, or
5374 dnl disable it altogether.
5375 AC_DEFUN([CF_MANPAGE_RENAMES],
5376 [
5377 AC_MSG_CHECKING(for manpage renaming)
5378
5379 AC_ARG_WITH(manpage-renames,
5380         [  --with-manpage-renames  specify manpage-renaming],
5381         [MANPAGE_RENAMES=$withval],
5382         [MANPAGE_RENAMES=yes])
5383
5384 case ".$MANPAGE_RENAMES" in
5385 (.no)
5386         ;;
5387 (.|.yes)
5388         # Debian 'man' program?
5389         if test -f /etc/debian_version ; then
5390                 MANPAGE_RENAMES=`cd "$srcdir" && pwd`/man/man_db.renames
5391         else
5392                 MANPAGE_RENAMES=no
5393         fi
5394         ;;
5395 esac
5396
5397 if test "$MANPAGE_RENAMES" != no ; then
5398         if test -f "$srcdir/man/$MANPAGE_RENAMES" ; then
5399                 MANPAGE_RENAMES=`cd "$srcdir/man" && pwd`/$MANPAGE_RENAMES
5400         elif test ! -f "$MANPAGE_RENAMES" ; then
5401                 AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
5402         fi
5403
5404         test ! -d man && mkdir man
5405
5406         # Construct a sed-script to perform renaming within man-pages
5407         if test -n "$MANPAGE_RENAMES" ; then
5408                 test ! -d man && mkdir man
5409                 $SHELL "$srcdir/man/make_sed.sh" "$MANPAGE_RENAMES" >./edit_man.sed
5410         fi
5411 fi
5412
5413 AC_MSG_RESULT($MANPAGE_RENAMES)
5414 AC_SUBST(MANPAGE_RENAMES)
5415 ])dnl
5416 dnl ---------------------------------------------------------------------------
5417 dnl CF_MANPAGE_SYMLINKS version: 6 updated: 2015/04/17 21:13:04
5418 dnl -------------------
5419 dnl Some people expect each tool to make all aliases for manpages in the
5420 dnl man-directory.  This accommodates the older, less-capable implementations
5421 dnl of 'man', and is optional.
5422 AC_DEFUN([CF_MANPAGE_SYMLINKS],
5423 [
5424 AC_MSG_CHECKING(if manpage aliases will be installed)
5425
5426 AC_ARG_WITH(manpage-aliases,
5427         [  --with-manpage-aliases  specify manpage-aliases using .so],
5428         [MANPAGE_ALIASES=$withval],
5429         [MANPAGE_ALIASES=yes])
5430
5431 AC_MSG_RESULT($MANPAGE_ALIASES)
5432
5433 case "x$LN_S" in
5434 (xln*)
5435         cf_use_symlinks=yes
5436         ;;
5437 (*)
5438         cf_use_symlinks=no
5439         ;;
5440 esac
5441
5442 MANPAGE_SYMLINKS=no
5443 if test "$MANPAGE_ALIASES" = yes ; then
5444 AC_MSG_CHECKING(if manpage symlinks should be used)
5445
5446 AC_ARG_WITH(manpage-symlinks,
5447         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
5448         [MANPAGE_SYMLINKS=$withval],
5449         [MANPAGE_SYMLINKS=$cf_use_symlinks])
5450
5451 if test "$$cf_use_symlinks" = no; then
5452 if test "$MANPAGE_SYMLINKS" = yes ; then
5453         AC_MSG_WARN(cannot make symlinks, will use .so files)
5454         MANPAGE_SYMLINKS=no
5455 fi
5456 fi
5457
5458 AC_MSG_RESULT($MANPAGE_SYMLINKS)
5459 fi
5460
5461 ])dnl
5462 dnl ---------------------------------------------------------------------------
5463 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
5464 dnl --------------
5465 dnl This option causes manpages to be run through tbl(1) to generate tables
5466 dnl correctly.
5467 AC_DEFUN([CF_MANPAGE_TBL],
5468 [
5469 AC_MSG_CHECKING(for manpage tbl)
5470
5471 AC_ARG_WITH(manpage-tbl,
5472         [  --with-manpage-tbl      specify manpage processing with tbl],
5473         [MANPAGE_TBL=$withval],
5474         [MANPAGE_TBL=no])
5475
5476 AC_MSG_RESULT($MANPAGE_TBL)
5477 ])dnl
5478 dnl ---------------------------------------------------------------------------
5479 dnl CF_MAN_PAGES version: 51 updated: 2021/01/05 16:29:19
5480 dnl ------------
5481 dnl Try to determine if the man-pages on the system are compressed, and if
5482 dnl so, what format is used.  Use this information to construct a script that
5483 dnl will install man-pages.
5484 AC_DEFUN([CF_MAN_PAGES],
5485 [
5486 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
5487 CF_MANPAGE_FORMAT
5488 CF_MANPAGE_RENAMES
5489 CF_MANPAGE_SYMLINKS
5490 CF_MANPAGE_TBL
5491
5492 if test "$prefix" = "NONE" ; then
5493         cf_prefix="$ac_default_prefix"
5494 else
5495         cf_prefix="$prefix"
5496 fi
5497
5498 case "$MANPAGE_FORMAT" in
5499 (*catonly*)
5500         cf_format=yes
5501         cf_inboth=no
5502         ;;
5503 (*formatted*)
5504         cf_format=yes
5505         cf_inboth=yes
5506         ;;
5507 (*)
5508         cf_format=no
5509         cf_inboth=no
5510         ;;
5511 esac
5512
5513 test ! -d man && mkdir man
5514
5515 cf_so_strip=
5516 cf_compress=
5517 case "$MANPAGE_FORMAT" in
5518 (*compress*)
5519         cf_so_strip="Z"
5520         cf_compress=compress
5521         ;;
5522 (*gzip*)
5523         cf_so_strip="gz"
5524         cf_compress=gzip
5525         ;;
5526 esac
5527
5528 cf_edit_man=./edit_man.sh
5529 cf_man_alias=`pwd`/man_alias.sed
5530
5531 cat >$cf_edit_man <<CF_EOF
5532 #! $SHELL
5533 # this script is generated by the configure-script CF_MAN_PAGES macro.
5534
5535 prefix="$cf_prefix"
5536 datarootdir="$datarootdir"
5537 datadir="$datadir"
5538
5539 NCURSES_MAJOR="$NCURSES_MAJOR"
5540 NCURSES_MINOR="$NCURSES_MINOR"
5541 NCURSES_PATCH="$NCURSES_PATCH"
5542
5543 NCURSES_OSPEED="$NCURSES_OSPEED"
5544 TERMINFO="$TERMINFO"
5545
5546 INSTALL="$INSTALL"
5547 INSTALL_DATA="$INSTALL_DATA"
5548
5549 transform="$program_transform_name"
5550
5551 TMP=\${TMPDIR:=/tmp}/man\$\$
5552 trap "rm -f \$TMP" 0 1 2 3 15
5553
5554 form=\[$]1
5555 shift || exit 1
5556
5557 verb=\[$]1
5558 shift || exit 1
5559
5560 mandir=\[$]1
5561 shift || exit 1
5562
5563 srcdir=\[$]1
5564 top_srcdir=\[$]srcdir/..
5565 shift || exit 1
5566
5567 if test "\$form" = normal ; then
5568         if test "$cf_format" = yes ; then
5569         if test "$cf_inboth" = no ; then
5570                 $SHELL "\[$]0" format "\$verb" "\$mandir" "\$srcdir" "\[$]@"
5571                 exit $?
5572         fi
5573         fi
5574         cf_subdir=\$mandir/man
5575         cf_tables=$MANPAGE_TBL
5576 else
5577         cf_subdir=\$mandir/cat
5578         cf_tables=yes
5579 fi
5580
5581 # process the list of source-files
5582 for i in "\[$]@" ; do
5583 case \$i in
5584 (*.orig|*.rej) ;;
5585 (*.[[0-9]]*)
5586         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
5587         if test "\$verb" = installing ; then
5588         if test ! -d "\$cf_subdir\${section}" ; then
5589                 mkdir -p "\$cf_subdir\$section"
5590         fi
5591         fi
5592
5593         # replace variables in man page
5594         if test ! -f "$cf_man_alias" ; then
5595 cat >>$cf_man_alias <<-CF_EOF2
5596                 s,@DATADIR@,\$datadir,g
5597                 s,@TERMINFO@,\${TERMINFO:="no default value"},g
5598                 s,@TERMINFO_DIRS@,\${TERMINFO_DIRS:="no default value"},g
5599                 s,@NCURSES_MAJOR@,\${NCURSES_MAJOR:="no default value"},g
5600                 s,@NCURSES_MINOR@,\${NCURSES_MINOR:="no default value"},g
5601                 s,@NCURSES_PATCH@,\${NCURSES_PATCH:="no default value"},g
5602                 s,@NCURSES_OSPEED@,\${NCURSES_OSPEED:="no default value"},g
5603 CF_EOF
5604         ifelse($1,,,[
5605         for cf_name in $1
5606         do
5607                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
5608                 cf_name=`echo "$cf_name" | sed "$program_transform_name"`
5609 cat >>$cf_edit_man <<-CF_EOF
5610                 s,@$cf_NAME@,$cf_name,g
5611 CF_EOF
5612         done
5613         ])
5614 cat >>$cf_edit_man <<CF_EOF
5615 CF_EOF2
5616                 echo "...made $cf_man_alias"
5617         fi
5618
5619         aliases=
5620         cf_source=\`basename "\$i"\`
5621         inalias=\$cf_source
5622         test ! -f "\$inalias" && inalias="\$srcdir/\$inalias"
5623         if test ! -f "\$inalias" ; then
5624                 echo ".. skipped \$cf_source"
5625                 continue
5626         fi
5627 CF_EOF
5628
5629 if test "$MANPAGE_ALIASES" != no ; then
5630 cat >>$cf_edit_man <<CF_EOF
5631         nCurses=ignore.3x
5632         test "$with_curses_h" = yes && nCurses=ncurses.3x
5633         aliases=\`sed -f "\$top_srcdir/man/manlinks.sed" "\$inalias" |sed -f "$cf_man_alias" | sort -u; test "\$inalias" = "\$nCurses" && echo curses\`
5634 CF_EOF
5635 fi
5636
5637 if test "$MANPAGE_RENAMES" = no ; then
5638 cat >>$cf_edit_man <<CF_EOF
5639         # perform program transformations for section 1 man pages
5640         if test \$section = 1 ; then
5641                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
5642         else
5643                 cf_target=\$cf_subdir\${section}/\$cf_source
5644         fi
5645 CF_EOF
5646 else
5647 cat >>$cf_edit_man <<CF_EOF
5648         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
5649         if test -z "\$cf_target" ; then
5650                 echo "? missing rename for \$cf_source"
5651                 cf_target="\$cf_source"
5652         fi
5653         cf_target="\$cf_subdir\${section}/\${cf_target}"
5654
5655 CF_EOF
5656 fi
5657
5658 cat >>$cf_edit_man <<CF_EOF
5659         sed     -f "$cf_man_alias" \\
5660 CF_EOF
5661
5662 if test -f "$MANPAGE_RENAMES" ; then
5663 cat >>$cf_edit_man <<CF_EOF
5664                 < "\$i" | sed -f `pwd`/edit_man.sed >\$TMP
5665 CF_EOF
5666 else
5667 cat >>$cf_edit_man <<CF_EOF
5668                 < "\$i" >\$TMP
5669 CF_EOF
5670 fi
5671
5672 cat >>$cf_edit_man <<CF_EOF
5673 if test \$cf_tables = yes ; then
5674         tbl \$TMP >\$TMP.out
5675         mv \$TMP.out \$TMP
5676 fi
5677 CF_EOF
5678
5679 if test "$with_overwrite" != yes ; then
5680 cat >>$cf_edit_man <<CF_EOF
5681         sed -e "/\\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
5682         mv \$TMP.out \$TMP
5683 CF_EOF
5684 fi
5685
5686 if test "$with_curses_h" != yes ; then
5687 cat >>$cf_edit_man <<CF_EOF
5688         sed -e "/\\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
5689         mv \$TMP.out \$TMP
5690 CF_EOF
5691 fi
5692
5693 cat >>$cf_edit_man <<CF_EOF
5694         if test "\$form" = format ; then
5695                 nroff -man \$TMP >\$TMP.out
5696                 mv \$TMP.out \$TMP
5697         fi
5698 CF_EOF
5699
5700 if test -n "$cf_compress" ; then
5701 cat >>$cf_edit_man <<CF_EOF
5702         if test "\$verb" = installing ; then
5703         if ( "$cf_compress" -f \$TMP )
5704         then
5705                 mv \$TMP.$cf_so_strip \$TMP
5706         fi
5707         fi
5708         cf_target="\$cf_target.$cf_so_strip"
5709 CF_EOF
5710 fi
5711
5712 case "$MANPAGE_FORMAT" in
5713 (*BSDI*)
5714 cat >>$cf_edit_man <<CF_EOF
5715         if test "\$form" = format ; then
5716                 # BSDI installs only .0 suffixes in the cat directories
5717                 cf_target="\`echo \$cf_target|sed -e 's/\\.[[1-9]]\\+[[a-z]]*/.0/'\`"
5718         fi
5719 CF_EOF
5720   ;;
5721 esac
5722
5723 cat >>$cf_edit_man <<CF_EOF
5724         suffix=\`basename "\$cf_target" | sed -e 's%^[[^.]]*%%'\`
5725         if test "\$verb" = installing ; then
5726                 echo "\$verb \$cf_target"
5727                 \$INSTALL_DATA \$TMP "\$cf_target"
5728                 test -d "\$cf_subdir\${section}" &&
5729                 test -n "\$aliases" && (
5730                         cd "\$cf_subdir\${section}" && (
5731                                 cf_source=\`echo "\$cf_target" |sed -e 's%^.*/\\([[^/]][[^/]]*/[[^/]][[^/]]*$\\)%\\1%'\`
5732                                 test -n "$cf_so_strip" && cf_source=\`echo "\$cf_source" |sed -e 's%\\.$cf_so_strip\$%%'\`
5733                                 cf_target=\`basename "\$cf_target"\`
5734                                 for cf_alias in \$aliases
5735                                 do
5736                                         if test "\$section" = 1 ; then
5737                                                 cf_alias=\`echo "\$cf_alias" |sed "\${transform}"\`
5738                                         fi
5739
5740                                         if test "$MANPAGE_SYMLINKS" = yes ; then
5741                                                 if test -f "\$cf_alias\${suffix}" ; then
5742                                                         if ( cmp -s "\$cf_target" "\$cf_alias\${suffix}" )
5743                                                         then
5744                                                                 continue
5745                                                         fi
5746                                                 fi
5747                                                 echo ".. \$verb alias \$cf_alias\${suffix}"
5748 CF_EOF
5749 case "x$LN_S" in
5750 (*-f)
5751 cat >>$cf_edit_man <<CF_EOF
5752                                                 $LN_S "\$cf_target" "\$cf_alias\${suffix}"
5753 CF_EOF
5754         ;;
5755 (*)
5756 cat >>$cf_edit_man <<CF_EOF
5757                                                 rm -f "\$cf_alias\${suffix}"
5758                                                 $LN_S "\$cf_target" "\$cf_alias\${suffix}"
5759 CF_EOF
5760         ;;
5761 esac
5762 cat >>$cf_edit_man <<CF_EOF
5763                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
5764                                                 echo ".so \$cf_source" >\$TMP
5765 CF_EOF
5766 if test -n "$cf_compress" ; then
5767 cat >>$cf_edit_man <<CF_EOF
5768                                                 if test -n "$cf_so_strip" ; then
5769                                                         "$cf_compress" -f \$TMP
5770                                                         mv \$TMP.$cf_so_strip \$TMP
5771                                                 fi
5772 CF_EOF
5773 fi
5774 cat >>$cf_edit_man <<CF_EOF
5775                                                 echo ".. \$verb alias \$cf_alias\${suffix}"
5776                                                 rm -f "\$cf_alias\${suffix}"
5777                                                 \$INSTALL_DATA \$TMP "\$cf_alias\${suffix}"
5778                                         fi
5779                                 done
5780                         )
5781                 )
5782         elif test "\$verb" = removing ; then
5783                 test -f "\$cf_target" && (
5784                         echo "\$verb \$cf_target"
5785                         rm -f "\$cf_target"
5786                 )
5787                 test -d "\$cf_subdir\${section}" &&
5788                 test -n "\$aliases" && (
5789                         cd "\$cf_subdir\${section}" && (
5790                                 for cf_alias in \$aliases
5791                                 do
5792                                         if test "\$section" = 1 ; then
5793                                                 cf_alias=\`echo "\$cf_alias" |sed "\${transform}"\`
5794                                         fi
5795
5796                                         echo ".. \$verb alias \$cf_alias\${suffix}"
5797                                         rm -f "\$cf_alias\${suffix}"
5798                                 done
5799                         )
5800                 )
5801         else
5802 #               echo ".hy 0"
5803                 cat \$TMP
5804         fi
5805         ;;
5806 esac
5807 done
5808
5809 if test "$cf_inboth" = yes ; then
5810 if test "\$form" != format ; then
5811         $SHELL "\[$]0" format "\$verb" "\$mandir" "\$srcdir" "\[$]@"
5812 fi
5813 fi
5814
5815 exit 0
5816 CF_EOF
5817 chmod 755 "$cf_edit_man"
5818
5819 ])dnl
5820 dnl ---------------------------------------------------------------------------
5821 dnl CF_MAP_LIB_BASENAME version: 2 updated: 2021/01/02 17:09:14
5822 dnl -------------------
5823 dnl Convert a default-libname to the actual one used via CF_WITH_LIB_BASENAME.
5824 dnl
5825 dnl $1 = variable to set
5826 dnl $2 = default-libname
5827 AC_DEFUN([CF_MAP_LIB_BASENAME],[
5828 CF_UPPER(cf_map_lib_basename,$2)
5829 eval $1="\$${cf_map_lib_basename}_NAME"
5830 ])dnl
5831 dnl ---------------------------------------------------------------------------
5832 dnl CF_MATH_LIB version: 10 updated: 2020/12/31 18:40:20
5833 dnl -----------
5834 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
5835 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
5836 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
5837 AC_DEFUN([CF_MATH_LIB],
5838 [
5839 AC_CACHE_CHECK(if -lm needed for math functions,
5840         cf_cv_need_libm,[
5841         AC_TRY_LINK([
5842         #include <stdio.h>
5843         #include <stdlib.h>
5844         #include <math.h>
5845         ],
5846         [double x = rand(); printf("result = %g\\n", ]ifelse([$2],,sin(x),$2)[)],
5847         [cf_cv_need_libm=no],
5848         [cf_cv_need_libm=yes])])
5849 if test "$cf_cv_need_libm" = yes
5850 then
5851 ifelse($1,,[
5852         CF_ADD_LIB(m)
5853 ],[$1=-lm])
5854 fi
5855 ])
5856 dnl ---------------------------------------------------------------------------
5857 dnl CF_MIXEDCASE_FILENAMES version: 9 updated: 2021/01/01 16:53:59
5858 dnl ----------------------
5859 dnl Check if the file-system supports mixed-case filenames.  If we're able to
5860 dnl create a lowercase name and see it as uppercase, it doesn't support that.
5861 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
5862 [
5863 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
5864 if test "$cross_compiling" = yes ; then
5865         case "$target_alias" in
5866         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*|darwin*)
5867                 cf_cv_mixedcase=no
5868                 ;;
5869         (*)
5870                 cf_cv_mixedcase=yes
5871                 ;;
5872         esac
5873 else
5874         rm -f conftest CONFTEST
5875         echo test >conftest
5876         if test -f CONFTEST ; then
5877                 cf_cv_mixedcase=no
5878         else
5879                 cf_cv_mixedcase=yes
5880         fi
5881         rm -f conftest CONFTEST
5882 fi
5883 ])
5884 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
5885 ])dnl
5886 dnl ---------------------------------------------------------------------------
5887 dnl CF_MKSTEMP version: 11 updated: 2021/01/01 13:31:04
5888 dnl ----------
5889 dnl Check for a working mkstemp.  This creates two files, checks that they are
5890 dnl successfully created and distinct (AmigaOS apparently fails on the last).
5891 AC_DEFUN([CF_MKSTEMP],[
5892 AC_CHECK_HEADERS( \
5893 unistd.h \
5894 )
5895 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
5896 rm -rf ./conftest*
5897 AC_TRY_RUN([
5898 #include <sys/types.h>
5899 #ifdef HAVE_UNISTD_H
5900 #include <unistd.h>
5901 #endif
5902 #include <stdlib.h>
5903 #include <stdio.h>
5904 #include <string.h>
5905 #include <sys/stat.h>
5906 int main(void)
5907 {
5908         char *tmpl = "conftestXXXXXX";
5909         char name[2][80];
5910         int n;
5911         int result = 0;
5912         int fd;
5913         struct stat sb;
5914
5915         umask(077);
5916         for (n = 0; n < 2; ++n) {
5917                 strcpy(name[n], tmpl);
5918                 if ((fd = mkstemp(name[n])) >= 0) {
5919                         if (!strcmp(name[n], tmpl)
5920                          || stat(name[n], &sb) != 0
5921                          || (sb.st_mode & S_IFMT) != S_IFREG
5922                          || (sb.st_mode & 077) != 0) {
5923                                 result = 1;
5924                         }
5925                         close(fd);
5926                 }
5927         }
5928         if (result == 0
5929          && !strcmp(name[0], name[1]))
5930                 result = 1;
5931         ${cf_cv_main_return:-return}(result);
5932 }
5933 ],[cf_cv_func_mkstemp=yes
5934 ],[cf_cv_func_mkstemp=no
5935 ],[cf_cv_func_mkstemp=maybe])
5936 ])
5937 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
5938         AC_CHECK_FUNC(mkstemp)
5939 fi
5940 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
5941         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
5942 fi
5943 ])dnl
5944 dnl ---------------------------------------------------------------------------
5945 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
5946 dnl ----------
5947 dnl Write a debug message to config.log, along with the line number in the
5948 dnl configure script.
5949 AC_DEFUN([CF_MSG_LOG],[
5950 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
5951 ])dnl
5952 dnl ---------------------------------------------------------------------------
5953 dnl CF_NCURSES_ABI_6 version: 4 updated: 2021/01/01 13:31:04
5954 dnl ----------------
5955 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
5956 dnl warn about this.
5957 AC_DEFUN([CF_NCURSES_ABI_6],[
5958 if test "${with_abi_version+set}" != set; then
5959         case "$cf_cv_rel_version" in
5960         (5.*)
5961                 cf_cv_rel_version=6.0
5962                 cf_cv_abi_version=6
5963                 AC_MSG_WARN(overriding ABI version to $cf_cv_abi_version)
5964                 ;;
5965         esac
5966 fi
5967 ])dnl
5968 dnl ---------------------------------------------------------------------------
5969 dnl CF_NCURSES_WITH_ABI_VERSION version: 3 updated: 2021/01/01 13:31:04
5970 dnl ---------------------------
5971 dnl Allow ncurses's ABI to be overridden.  Generally this happens when a
5972 dnl packager has incremented the ABI past that used in the original package,
5973 dnl and wishes to keep doing this.
5974 dnl
5975 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
5976 dnl symbol.
5977 AC_DEFUN([CF_NCURSES_WITH_ABI_VERSION],[
5978 CF_WITH_ABI_VERSION($1)
5979 if test "x$cf_cv_abi_version" != "x$with_abi_version"
5980 then
5981         case "$cf_cv_rel_version" in
5982         (5.*)
5983                 cf_cv_rel_version=$with_abi_version.0
5984                 ;;
5985         esac
5986 fi
5987 ])dnl
5988 dnl ---------------------------------------------------------------------------
5989 dnl CF_NO_LEAKS_OPTION version: 8 updated: 2021/01/05 20:05:09
5990 dnl ------------------
5991 dnl see CF_WITH_NO_LEAKS
5992 AC_DEFUN([CF_NO_LEAKS_OPTION],[
5993 AC_MSG_CHECKING(if you want to use $1 for testing)
5994 AC_ARG_WITH($1,
5995         [$2],
5996         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
5997          $4
5998 ])
5999         : "${with_cflags:=-g}"
6000         : "${enable_leaks:=no}"
6001          with_$1=yes],
6002         [with_$1=])
6003 AC_MSG_RESULT(${with_$1:-no})
6004
6005 case ".$with_cflags" in
6006 (.*-g*)
6007         case .$CFLAGS in
6008         (.*-g*)
6009                 ;;
6010         (*)
6011                 CF_ADD_CFLAGS([-g])
6012                 ;;
6013         esac
6014         ;;
6015 esac
6016 ])dnl
6017 dnl ---------------------------------------------------------------------------
6018 dnl CF_NUMBER_SYNTAX version: 2 updated: 2015/04/17 21:13:04
6019 dnl ----------------
6020 dnl Check if the given variable is a number.  If not, report an error.
6021 dnl $1 is the variable
6022 dnl $2 is the message
6023 AC_DEFUN([CF_NUMBER_SYNTAX],[
6024 if test -n "$1" ; then
6025   case $1 in
6026   ([[0-9]]*)
6027         ;;
6028   (*)
6029         AC_MSG_ERROR($2 is not a number: $1)
6030         ;;
6031   esac
6032 else
6033   AC_MSG_ERROR($2 value is empty)
6034 fi
6035 ])dnl
6036 dnl ---------------------------------------------------------------------------
6037 dnl CF_OBJ_SUBDIR version: 8 updated: 2021/01/01 13:31:04
6038 dnl -------------
6039 dnl Compute the object-directory name from the given model name
6040 AC_DEFUN([CF_OBJ_SUBDIR],
6041 [
6042         case $1 in
6043         (libtool) $2='obj_lo'  ;;
6044         (normal)  $2='objects' ;;
6045         (debug)   $2='obj_g' ;;
6046         (profile) $2='obj_p' ;;
6047         (shared)
6048                 case "$cf_cv_system_name" in
6049                 (cygwin|msys)
6050                         $2='objects' ;;
6051                 (*)
6052                         $2='obj_s' ;;
6053                 esac
6054         esac
6055 ])dnl
6056 dnl ---------------------------------------------------------------------------
6057 dnl CF_PATHSEP version: 8 updated: 2021/01/01 13:31:04
6058 dnl ----------
6059 dnl Provide a value for the $PATH and similar separator (or amend the value
6060 dnl as provided in autoconf 2.5x).
6061 AC_DEFUN([CF_PATHSEP],
6062 [
6063         AC_MSG_CHECKING(for PATH separator)
6064         case "$cf_cv_system_name" in
6065         (os2*)  PATH_SEPARATOR=';'  ;;
6066         (*)     ${PATH_SEPARATOR:=':'}  ;;
6067         esac
6068 ifelse([$1],,,[$1=$PATH_SEPARATOR])
6069         AC_SUBST(PATH_SEPARATOR)
6070         AC_MSG_RESULT($PATH_SEPARATOR)
6071 ])dnl
6072 dnl ---------------------------------------------------------------------------
6073 dnl CF_PATH_PROG version: 12 updated: 2021/01/02 09:31:20
6074 dnl ------------
6075 dnl Check for a given program, defining corresponding symbol.
6076 dnl     $1 = environment variable, which is suffixed by "_PATH" in the #define.
6077 dnl     $2 = program name to find.
6078 dnl     $3 = optional list of additional program names to test.
6079 dnl $4 = $PATH
6080 dnl
6081 dnl If there is more than one token in the result, #define the remaining tokens
6082 dnl to $1_ARGS.  We need this for 'install' in particular.
6083 dnl
6084 dnl FIXME: we should allow this to be overridden by environment variables
6085 dnl
6086 AC_DEFUN([CF_PATH_PROG],[
6087 AC_REQUIRE([CF_PATHSEP])
6088 test -z "[$]$1" && $1="$2"
6089 AC_PATH_PROGS($1,[$]$1 $2 ifelse($3,,,$3),[$]$1, ifelse($4,,,$4))
6090
6091 cf_path_prog=""
6092 cf_path_args=""
6093 IFS="${IFS:-    }"; cf_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR"
6094 for cf_temp in $ac_cv_path_$1
6095 do
6096         if test -z "$cf_path_prog" ; then
6097                 if test "$with_full_paths" = yes ; then
6098                         CF_PATH_SYNTAX(cf_temp,break)
6099                         cf_path_prog="$cf_temp"
6100                 else
6101                         cf_path_prog="`basename "$cf_temp"`"
6102                 fi
6103         elif test -z "$cf_path_args" ; then
6104                 cf_path_args="$cf_temp"
6105         else
6106                 cf_path_args="$cf_path_args $cf_temp"
6107         fi
6108 done
6109 IFS="$cf_save_ifs"
6110
6111 if test -n "$cf_path_prog" ; then
6112         CF_MSG_LOG(defining path for ${cf_path_prog})
6113         AC_DEFINE_UNQUOTED($1_PATH,"$cf_path_prog",Define to pathname $1)
6114         test -n "$cf_path_args" && AC_DEFINE_UNQUOTED($1_ARGS,"$cf_path_args",Define to provide args for $1)
6115 fi
6116 ])dnl
6117 dnl ---------------------------------------------------------------------------
6118 dnl CF_PATH_SYNTAX version: 18 updated: 2020/12/31 18:40:20
6119 dnl --------------
6120 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
6121 dnl begins with one of the prefix/exec_prefix variables, and then again if the
6122 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
6123 dnl delayed evaluation of those symbols.
6124 AC_DEFUN([CF_PATH_SYNTAX],[
6125 if test "x$prefix" != xNONE; then
6126         cf_path_syntax="$prefix"
6127 else
6128         cf_path_syntax="$ac_default_prefix"
6129 fi
6130
6131 case ".[$]$1" in
6132 (.\[$]\(*\)*|.\'*\'*)
6133         ;;
6134 (..|./*|.\\*)
6135         ;;
6136 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
6137         ;;
6138 (.\[$]\{*prefix\}*|.\[$]\{*dir\}*)
6139         eval $1="[$]$1"
6140         case ".[$]$1" in
6141         (.NONE/*)
6142                 $1=`echo "[$]$1" | sed -e s%NONE%$cf_path_syntax%`
6143                 ;;
6144         esac
6145         ;;
6146 (.no|.NONE/*)
6147         $1=`echo "[$]$1" | sed -e s%NONE%$cf_path_syntax%`
6148         ;;
6149 (*)
6150         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
6151         ;;
6152 esac
6153 ])dnl
6154 dnl ---------------------------------------------------------------------------
6155 dnl CF_PKG_CONFIG version: 11 updated: 2021/01/01 13:31:04
6156 dnl -------------
6157 dnl Check for the package-config program, unless disabled by command-line.
6158 AC_DEFUN([CF_PKG_CONFIG],
6159 [
6160 AC_MSG_CHECKING(if you want to use pkg-config)
6161 AC_ARG_WITH(pkg-config,
6162         [  --with-pkg-config{=path} enable/disable use of pkg-config],
6163         [cf_pkg_config=$withval],
6164         [cf_pkg_config=yes])
6165 AC_MSG_RESULT($cf_pkg_config)
6166
6167 case "$cf_pkg_config" in
6168 (no)
6169         PKG_CONFIG=none
6170         ;;
6171 (yes)
6172         CF_ACVERSION_CHECK(2.52,
6173                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
6174                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
6175         ;;
6176 (*)
6177         PKG_CONFIG=$withval
6178         ;;
6179 esac
6180
6181 test -z "$PKG_CONFIG" && PKG_CONFIG=none
6182 if test "$PKG_CONFIG" != none ; then
6183         CF_PATH_SYNTAX(PKG_CONFIG)
6184 elif test "x$cf_pkg_config" != xno ; then
6185         AC_MSG_WARN(pkg-config is not installed)
6186 fi
6187
6188 AC_SUBST(PKG_CONFIG)
6189 ])dnl
6190 dnl ---------------------------------------------------------------------------
6191 dnl CF_POSIX_C_SOURCE version: 11 updated: 2018/12/31 20:46:17
6192 dnl -----------------
6193 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
6194 dnl
6195 dnl     POSIX.1-1990                            _POSIX_SOURCE
6196 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
6197 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
6198 dnl             Bindings Option
6199 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
6200 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
6201 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
6202 dnl
6203 dnl Parameters:
6204 dnl     $1 is the nominal value for _POSIX_C_SOURCE
6205 AC_DEFUN([CF_POSIX_C_SOURCE],
6206 [AC_REQUIRE([CF_POSIX_VISIBLE])dnl
6207
6208 if test "$cf_cv_posix_visible" = no; then
6209
6210 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
6211
6212 cf_save_CFLAGS="$CFLAGS"
6213 cf_save_CPPFLAGS="$CPPFLAGS"
6214
6215 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
6216 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
6217
6218 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
6219         CF_MSG_LOG(if the symbol is already defined go no further)
6220         AC_TRY_COMPILE([#include <sys/types.h>],[
6221 #ifndef _POSIX_C_SOURCE
6222 make an error
6223 #endif],
6224         [cf_cv_posix_c_source=no],
6225         [cf_want_posix_source=no
6226          case .$cf_POSIX_C_SOURCE in
6227          (.[[12]]??*)
6228                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
6229                 ;;
6230          (.2)
6231                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
6232                 cf_want_posix_source=yes
6233                 ;;
6234          (.*)
6235                 cf_want_posix_source=yes
6236                 ;;
6237          esac
6238          if test "$cf_want_posix_source" = yes ; then
6239                 AC_TRY_COMPILE([#include <sys/types.h>],[
6240 #ifdef _POSIX_SOURCE
6241 make an error
6242 #endif],[],
6243                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
6244          fi
6245          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
6246          CFLAGS="$cf_trim_CFLAGS"
6247          CPPFLAGS="$cf_trim_CPPFLAGS"
6248          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
6249          CF_MSG_LOG(if the second compile does not leave our definition intact error)
6250          AC_TRY_COMPILE([#include <sys/types.h>],[
6251 #ifndef _POSIX_C_SOURCE
6252 make an error
6253 #endif],,
6254          [cf_cv_posix_c_source=no])
6255          CFLAGS="$cf_save_CFLAGS"
6256          CPPFLAGS="$cf_save_CPPFLAGS"
6257         ])
6258 ])
6259
6260 if test "$cf_cv_posix_c_source" != no ; then
6261         CFLAGS="$cf_trim_CFLAGS"
6262         CPPFLAGS="$cf_trim_CPPFLAGS"
6263         CF_ADD_CFLAGS($cf_cv_posix_c_source)
6264 fi
6265
6266 fi # cf_cv_posix_visible
6267
6268 ])dnl
6269 dnl ---------------------------------------------------------------------------
6270 dnl CF_POSIX_VISIBLE version: 1 updated: 2018/12/31 20:46:17
6271 dnl ----------------
6272 dnl POSIX documents test-macros which an application may set before any system
6273 dnl headers are included to make features available.
6274 dnl
6275 dnl Some BSD platforms (originally FreeBSD, but copied by a few others)
6276 dnl diverged from POSIX in 2002 by setting symbols which make all of the most
6277 dnl recent features visible in the system header files unless the application
6278 dnl overrides the corresponding test-macros.  Doing that introduces portability
6279 dnl problems.
6280 dnl
6281 dnl This macro makes a special check for the symbols used for this, to avoid a
6282 dnl conflicting definition.
6283 AC_DEFUN([CF_POSIX_VISIBLE],
6284 [
6285 AC_CACHE_CHECK(if the POSIX test-macros are already defined,cf_cv_posix_visible,[
6286 AC_TRY_COMPILE([#include <stdio.h>],[
6287 #if defined(__POSIX_VISIBLE) && ((__POSIX_VISIBLE - 0L) > 0) \
6288         && defined(__XSI_VISIBLE) && ((__XSI_VISIBLE - 0L) > 0) \
6289         && defined(__BSD_VISIBLE) && ((__BSD_VISIBLE - 0L) > 0) \
6290         && defined(__ISO_C_VISIBLE) && ((__ISO_C_VISIBLE - 0L) > 0)
6291 #error conflicting symbols found
6292 #endif
6293 ],[cf_cv_posix_visible=no],[cf_cv_posix_visible=yes])
6294 ])
6295 ])dnl
6296 dnl ---------------------------------------------------------------------------
6297 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
6298 dnl ------------
6299 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
6300 dnl
6301 dnl $1 = symbol to test
6302 dnl $2 = value (if any) to use for a predefinition
6303 AC_DEFUN([CF_PREDEFINE],
6304 [
6305 AC_MSG_CHECKING(if we must define $1)
6306 AC_TRY_COMPILE([#include <sys/types.h>
6307 ],[
6308 #ifndef $1
6309 make an error
6310 #endif],[cf_result=no],[cf_result=yes])
6311 AC_MSG_RESULT($cf_result)
6312
6313 if test "$cf_result" = yes ; then
6314         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
6315 elif test "x$2" != "x" ; then
6316         AC_MSG_CHECKING(checking for compatible value versus $2)
6317         AC_TRY_COMPILE([#include <sys/types.h>
6318 ],[
6319 #if $1-$2 < 0
6320 make an error
6321 #endif],[cf_result=yes],[cf_result=no])
6322         AC_MSG_RESULT($cf_result)
6323         if test "$cf_result" = no ; then
6324                 # perhaps we can override it - try...
6325                 CPPFLAGS="$CPPFLAGS -D$1=$2"
6326         fi
6327 fi
6328 ])dnl
6329 dnl ---------------------------------------------------------------------------
6330 dnl CF_PRG_RULES version: 2 updated: 2021/01/01 13:31:04
6331 dnl ------------
6332 dnl Append definitions and rules for the given programs to the subdirectory
6333 dnl Makefiles, and the recursion rule for the top-level Makefile.
6334 dnl
6335 dnl parameters
6336 dnl     $1 = script to run
6337 dnl     $2 = list of subdirectories
6338 dnl
6339 dnl variables
6340 dnl     $AWK
6341 AC_DEFUN([CF_PRG_RULES],
6342 [
6343 for cf_dir in $2
6344 do
6345         if test ! -d "$srcdir/$cf_dir" ; then
6346                 continue
6347         elif test -f "$srcdir/$cf_dir/programs" ; then
6348                 $AWK -f $1 "$srcdir/$cf_dir/programs" >>$cf_dir/Makefile
6349         fi
6350 done
6351
6352 ])dnl
6353 dnl ---------------------------------------------------------------------------
6354 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
6355 dnl ----------
6356 dnl Check for archiver "ar".
6357 AC_DEFUN([CF_PROG_AR],[
6358 AC_CHECK_TOOL(AR, ar, ar)
6359 ])
6360 dnl ---------------------------------------------------------------------------
6361 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
6362 dnl -----------
6363 dnl Check for awk, ensure that the check found something.
6364 AC_DEFUN([CF_PROG_AWK],
6365 [
6366 AC_PROG_AWK
6367 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
6368 ])dnl
6369 dnl ---------------------------------------------------------------------------
6370 dnl CF_PROG_CC version: 5 updated: 2019/12/31 08:53:54
6371 dnl ----------
6372 dnl standard check for CC, plus followup sanity checks
6373 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
6374 AC_DEFUN([CF_PROG_CC],[
6375 CF_ACVERSION_CHECK(2.53,
6376         [AC_MSG_WARN(this will incorrectly handle gnatgcc choice)
6377          AC_REQUIRE([AC_PROG_CC])],
6378         [])
6379 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
6380 CF_GCC_VERSION
6381 CF_ACVERSION_CHECK(2.52,
6382         [AC_PROG_CC_STDC],
6383         [CF_ANSI_CC_REQD])
6384 CF_CC_ENV_FLAGS
6385 ])dnl
6386 dnl ---------------------------------------------------------------------------
6387 dnl CF_PROG_CC_C_O version: 6 updated: 2021/01/01 13:31:04
6388 dnl --------------
6389 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
6390 dnl the output file can be renamed, and allows for a shell variable that can
6391 dnl be used later.  The parameter is either CC or CXX.  The result is the
6392 dnl cache variable:
6393 dnl     $cf_cv_prog_CC_c_o
6394 dnl     $cf_cv_prog_CXX_c_o
6395 dnl
6396 dnl $1 = compiler
6397 dnl $2 = compiler options, if any
6398 AC_DEFUN([CF_PROG_CC_C_O],
6399 [AC_REQUIRE([AC_PROG_CC])dnl
6400 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
6401 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
6402 [
6403 cat > conftest.$ac_ext <<CF_EOF
6404 int main(void)
6405 {
6406         ${cf_cv_main_return:-return}(0);
6407 }
6408 CF_EOF
6409 # We do the test twice because some compilers refuse to overwrite an
6410 # existing .o file with -o, though they will create one.
6411 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
6412 if AC_TRY_EVAL(ac_try) &&
6413   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
6414 then
6415   eval cf_cv_prog_$1_c_o=yes
6416 else
6417   eval cf_cv_prog_$1_c_o=no
6418 fi
6419 rm -rf ./conftest*
6420 ])dnl
6421 if test "$cf_cv_prog_$1_c_o" = yes; then
6422   AC_MSG_RESULT([yes])
6423 else
6424   AC_MSG_RESULT([no])
6425 fi
6426 ])dnl
6427 dnl ---------------------------------------------------------------------------
6428 dnl CF_PROG_GNAT version: 12 updated: 2021/01/02 17:09:14
6429 dnl ------------
6430 dnl Check for gnat/gnatmake/etc, ensure that the toolset is complete.
6431 AC_DEFUN([CF_PROG_GNAT],[
6432 for cf_prog_gnat in gnat gnatmake gprconfig gprbuild
6433 do
6434         CF_UPPER(cf_upper_prog_gnat,${cf_prog_gnat})
6435
6436         unset ac_cv_path_cf_TEMP_gnat
6437         unset cf_TEMP_gnat
6438         AC_PATH_PROG(cf_TEMP_gnat,$cf_prog_gnat,no)
6439         eval "cf_cv_PATH_$cf_upper_prog_gnat=[$]ac_cv_path_cf_TEMP_gnat"
6440
6441         if test "x$cf_TEMP_gnat" != xno; then
6442                 unset cf_cv_gnat_version
6443                 unset cf_TEMP_gnat
6444                 CF_GNAT_VERSION(cf_TEMP_gnat,$cf_prog_gnat)
6445         fi
6446         eval "cf_cv_VERSION_$cf_upper_prog_gnat=[$]cf_TEMP_gnat"
6447
6448         unset cf_TEMP_gnat
6449         unset cf_cv_gnat_version
6450         unset ac_cv_path_cf_TEMP_gnat
6451 done
6452
6453 if test "x$cf_cv_VERSION_GNATMAKE" = "xno"; then
6454         cf_ada_make=
6455         cf_cv_prog_gnat_correct=no
6456 else
6457         cf_ada_make=gnatmake
6458         if test "x$cf_cv_VERSION_GPRCONFIG" = "xno"; then
6459                 # gprconfig is newer than gnatmake; we can continue...
6460                 cf_ada_config="##"
6461         else
6462                 rm -rf ./conftest* ./*~conftest*
6463                 if mkdir conftest.src
6464                 then
6465                         cf_ada_config=""
6466                         cd conftest.src
6467                         for cf_gprconfig in Ada C
6468                         do
6469                                 AC_MSG_CHECKING(for gprconfig name for $cf_gprconfig)
6470                                 if test "$cf_gprconfig" = C
6471                                 then
6472                                         for cf_gprconfig_param in \
6473                                                 "$cf_gprconfig,,,,GNATGCC" \
6474                                                 "$cf_gprconfig,,,,GCC" \
6475                                                 "$cf_gprconfig"
6476                                         do
6477                                                 cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
6478                                                 test -n "$cf_gprconfig_value" && break
6479                                         done
6480                                 else
6481                                         cf_gprconfig_param=$cf_gprconfig
6482                                         cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
6483                                 fi
6484                                 if test -n "$cf_gprconfig_value"
6485                                 then
6486                                         eval "cf_ada_config_[$]cf_gprconfig=[$]cf_gprconfig_value"
6487                                         AC_MSG_RESULT($cf_gprconfig_value)
6488                                 else
6489                                         AC_MSG_RESULT(missing)
6490                                         cf_ada_config="#"
6491                                         break
6492                                 fi
6493                         done
6494                         cd ..
6495                         rm -rf ./conftest* ./*~conftest*
6496                 fi
6497         fi
6498         if test "x$cf_ada_config" != "x#"
6499         then
6500                 CF_GNAT_VERSION
6501                 CF_CHECK_GNAT_VERSION
6502                 AC_CHECK_PROG(M4_exists, m4, yes, no)
6503                 if test "$ac_cv_prog_M4_exists" = no; then
6504                         cf_cv_prog_gnat_correct=no
6505                         AC_MSG_WARN(Ada95 binding required program m4 not found. Ada95 binding disabled)
6506                 fi
6507                 if test "$cf_cv_prog_gnat_correct" = yes; then
6508                         AC_MSG_CHECKING(if GNAT works)
6509                         CF_GNAT_TRY_RUN([procedure conftest;],
6510 [with Text_IO;
6511 with GNAT.OS_Lib;
6512 procedure conftest is
6513 begin
6514    Text_IO.Put ("Hello World");
6515    Text_IO.New_Line;
6516    GNAT.OS_Lib.OS_Exit (0);
6517 end conftest;],
6518 [cf_cv_prog_gnat_correct=yes],
6519 [cf_cv_prog_gnat_correct=no])
6520                         AC_MSG_RESULT($cf_cv_prog_gnat_correct)
6521                 fi
6522         else
6523                 cf_cv_prog_gnat_correct=no
6524         fi
6525 fi
6526
6527 AC_SUBST(cf_ada_make)
6528 AC_SUBST(cf_ada_config)
6529 AC_SUBST(cf_ada_config_Ada)
6530 AC_SUBST(cf_ada_config_C)
6531 ])dnl
6532 dnl ---------------------------------------------------------------------------
6533 dnl CF_PROG_INSTALL version: 10 updated: 2021/01/04 19:33:05
6534 dnl ---------------
6535 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
6536 dnl misc/tabset install won't work properly.  Usually this happens only when
6537 dnl using the fallback mkinstalldirs script
6538 AC_DEFUN([CF_PROG_INSTALL],
6539 [AC_PROG_INSTALL
6540 case $INSTALL in
6541 (/*)
6542         ;;
6543 (*)
6544         CF_DIRNAME(cf_dir,$INSTALL)
6545         test -z "$cf_dir" && cf_dir=.
6546         INSTALL="`cd \"$cf_dir\" && pwd`"/"`echo "$INSTALL" | sed -e 's%^.*/%%'`"
6547         ;;
6548 esac
6549 ])dnl
6550 dnl ---------------------------------------------------------------------------
6551 dnl CF_PROG_LDCONFIG version: 5 updated: 2015/04/18 08:56:57
6552 dnl ----------------
6553 dnl Check for ldconfig, needed to fixup shared libraries that would be built
6554 dnl and then used in the install.
6555 AC_DEFUN([CF_PROG_LDCONFIG],[
6556 if test "$cross_compiling" = yes ; then
6557         LDCONFIG=:
6558 else
6559         case "$cf_cv_system_name" in
6560         (dragonfly*|mirbsd*|freebsd*)
6561                 test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
6562                 ;;
6563         (*) LDPATH=$PATH:/sbin:/usr/sbin
6564                 AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
6565                 ;;
6566         esac
6567 fi
6568 AC_SUBST(LDCONFIG)
6569 ])dnl
6570 dnl ---------------------------------------------------------------------------
6571 dnl CF_PROG_LINT version: 4 updated: 2019/11/20 18:55:37
6572 dnl ------------
6573 AC_DEFUN([CF_PROG_LINT],
6574 [
6575 AC_CHECK_PROGS(LINT, lint cppcheck splint)
6576 case "x$LINT" in
6577 (xcppcheck|x*/cppcheck)
6578         test -z "$LINT_OPTS" && LINT_OPTS="--enable=all"
6579         ;;
6580 esac
6581 AC_SUBST(LINT_OPTS)
6582 ])dnl
6583 dnl ---------------------------------------------------------------------------
6584 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
6585 dnl ------------
6586 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
6587 dnl option if it is supported.
6588 AC_DEFUN([CF_PROG_LN_S],[
6589 AC_PROG_LN_S
6590 AC_MSG_CHECKING(if $LN_S -f options work)
6591
6592 rm -f conf$$.src conf$$dst
6593 echo >conf$$.dst
6594 echo first >conf$$.src
6595 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
6596         cf_prog_ln_sf=yes
6597 else
6598         cf_prog_ln_sf=no
6599 fi
6600 rm -f conf$$.dst conf$$src
6601 AC_MSG_RESULT($cf_prog_ln_sf)
6602
6603 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
6604 ])dnl
6605 dnl ---------------------------------------------------------------------------
6606 dnl CF_REGEX version: 18 updated: 2021/01/01 16:53:59
6607 dnl --------
6608 dnl Attempt to determine if we've got one of the flavors of regular-expression
6609 dnl code that we can support.
6610 AC_DEFUN([CF_REGEX],
6611 [
6612
6613 cf_regex_func=no
6614 cf_regex_libs=
6615 case "$host_os" in
6616 (mingw*)
6617         # -lsystre -ltre -lintl -liconv
6618         AC_CHECK_LIB(systre,regcomp,[
6619                 AC_CHECK_LIB(iconv,libiconv_open,[CF_ADD_LIB(iconv)])
6620                 AC_CHECK_LIB(intl,libintl_gettext,[CF_ADD_LIB(intl)])
6621                 AC_CHECK_LIB(tre,tre_regcomp,[CF_ADD_LIB(tre)])
6622                 CF_ADD_LIB(systre)
6623                 cf_regex_func=regcomp
6624         ],[
6625                 AC_CHECK_LIB(gnurx,regcomp,[
6626                         CF_ADD_LIB(gnurx)
6627                         cf_regex_func=regcomp])
6628         ])
6629         ;;
6630 (*)
6631         cf_regex_libs="regex re"
6632         AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
6633                 for cf_regex_lib in $cf_regex_libs
6634                 do
6635                         AC_CHECK_LIB($cf_regex_lib,regcomp,[
6636                                         CF_ADD_LIB($cf_regex_lib)
6637                                         cf_regex_func=regcomp
6638                                         break])
6639                 done
6640         ])
6641         ;;
6642 esac
6643
6644 if test "$cf_regex_func" = no ; then
6645         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
6646                 AC_CHECK_LIB(gen,compile,[
6647                                 CF_ADD_LIB(gen)
6648                                 cf_regex_func=compile])])
6649 fi
6650
6651 if test "$cf_regex_func" = no ; then
6652         AC_MSG_WARN(cannot find regular expression library)
6653 fi
6654
6655 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
6656
6657 cf_cv_regex_hdrs=no
6658 case "$cf_regex_func" in
6659 (compile)
6660         for cf_regex_hdr in regexp.h regexpr.h
6661         do
6662                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
6663                         char *p = compile("", "", "", 0);
6664                         int x = step("", "");
6665                         (void)p;
6666                         (void)x;
6667                 ],[
6668                         cf_cv_regex_hdrs=$cf_regex_hdr
6669                         break
6670                 ])
6671         done
6672         ;;
6673 (*)
6674         for cf_regex_hdr in regex.h
6675         do
6676                 AC_TRY_LINK([#include <sys/types.h>
6677 #include <$cf_regex_hdr>],[
6678                         regex_t *p = 0;
6679                         int x = regcomp(p, "", 0);
6680                         int y = regexec(p, "", 0, 0, 0);
6681                         (void)x;
6682                         (void)y;
6683                         regfree(p);
6684                 ],[
6685                         cf_cv_regex_hdrs=$cf_regex_hdr
6686                         break
6687                 ])
6688         done
6689         ;;
6690 esac
6691
6692 ])
6693
6694 case "$cf_cv_regex_hdrs" in
6695         (no)            AC_MSG_WARN(no regular expression header found) ;;
6696         (regex.h)       AC_DEFINE(HAVE_REGEX_H_FUNCS,1,[Define to 1 to include regex.h for regular expressions]) ;;
6697         (regexp.h)      AC_DEFINE(HAVE_REGEXP_H_FUNCS,1,[Define to 1 to include regexp.h for regular expressions]) ;;
6698         (regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS,1,[Define to 1 to include regexpr.h for regular expressions]) ;;
6699 esac
6700 ])dnl
6701 dnl ---------------------------------------------------------------------------
6702 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
6703 dnl ----------------
6704 dnl Remove all -U and -D options that refer to the given symbol from a list
6705 dnl of C compiler options.  This works around the problem that not all
6706 dnl compilers process -U and -D options from left-to-right, so a -U option
6707 dnl cannot be used to cancel the effect of a preceding -D option.
6708 dnl
6709 dnl $1 = target (which could be the same as the source variable)
6710 dnl $2 = source (including '$')
6711 dnl $3 = symbol to remove
6712 define([CF_REMOVE_DEFINE],
6713 [
6714 $1=`echo "$2" | \
6715         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
6716                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
6717 ])dnl
6718 dnl ---------------------------------------------------------------------------
6719 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
6720 dnl -------------
6721 dnl Remove the given library from the symbol
6722 dnl
6723 dnl $1 = target (which could be the same as the source variable)
6724 dnl $2 = source (including '$')
6725 dnl $3 = library to remove
6726 define([CF_REMOVE_LIB],
6727 [
6728 # remove $3 library from $2
6729 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
6730 ])dnl
6731 dnl ---------------------------------------------------------------------------
6732 dnl CF_RESTORE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:47:45
6733 dnl ---------------------
6734 dnl Restore flags saved in CF_SAVE_XTRA_FLAGS
6735 dnl $1 = name of current macro
6736 define([CF_RESTORE_XTRA_FLAGS],
6737 [
6738 LIBS="$cf_save_LIBS_$1"
6739 CFLAGS="$cf_save_CFLAGS_$1"
6740 CPPFLAGS="$cf_save_CPPFLAGS_$1"
6741 ])dnl
6742 dnl ---------------------------------------------------------------------------
6743 dnl CF_RPATH_HACK version: 13 updated: 2021/01/03 18:30:50
6744 dnl -------------
6745 AC_DEFUN([CF_RPATH_HACK],
6746 [AC_REQUIRE([AC_PROG_FGREP])dnl
6747 AC_REQUIRE([CF_LD_RPATH_OPT])dnl
6748
6749 AC_MSG_CHECKING(for updated LDFLAGS)
6750 if test -n "$LD_RPATH_OPT" ; then
6751         AC_MSG_RESULT(maybe)
6752
6753         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
6754         cf_rpath_list="/usr/lib /lib"
6755         if test "$cf_ldd_prog" != no
6756         then
6757                 cf_rpath_oops=
6758
6759 AC_TRY_LINK([#include <stdio.h>],
6760                 [printf("Hello");],
6761                 [cf_rpath_oops=`"$cf_ldd_prog" "conftest$ac_exeext" | ${FGREP-fgrep} ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
6762                  cf_rpath_list=`"$cf_ldd_prog" "conftest$ac_exeext" | ${FGREP-fgrep} / | sed -e 's%^.*[[        ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
6763
6764                 # If we passed the link-test, but get a "not found" on a given library,
6765                 # this could be due to inept reconfiguration of gcc to make it only
6766                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
6767                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
6768                 # /usr/local libraries.
6769                 if test -n "$cf_rpath_oops"
6770                 then
6771                         for cf_rpath_src in $cf_rpath_oops
6772                         do
6773                                 for cf_rpath_dir in \
6774                                         /usr/local \
6775                                         /usr/pkg \
6776                                         /opt/sfw
6777                                 do
6778                                         if test -f "$cf_rpath_dir/lib/$cf_rpath_src"
6779                                         then
6780                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
6781                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
6782                                                 break
6783                                         fi
6784                                 done
6785                         done
6786                 fi
6787         fi
6788
6789         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
6790
6791         CF_RPATH_HACK_2(LDFLAGS)
6792         CF_RPATH_HACK_2(LIBS)
6793
6794         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
6795 else
6796         AC_MSG_RESULT(no)
6797 fi
6798 AC_SUBST(EXTRA_LDFLAGS)
6799 ])dnl
6800 dnl ---------------------------------------------------------------------------
6801 dnl CF_RPATH_HACK_2 version: 8 updated: 2021/01/01 13:31:04
6802 dnl ---------------
6803 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
6804 dnl EXTRA_LDFLAGS for each -L option found.
6805 dnl
6806 dnl $cf_rpath_list contains a list of directories to ignore.
6807 dnl
6808 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
6809 dnl      but LIBS often has misplaced -L options.
6810 AC_DEFUN([CF_RPATH_HACK_2],
6811 [
6812 CF_VERBOSE(...checking $1 [$]$1)
6813
6814 cf_rpath_dst=
6815 for cf_rpath_src in [$]$1
6816 do
6817         case "$cf_rpath_src" in
6818         (-L*)
6819
6820                 # check if this refers to a directory which we will ignore
6821                 cf_rpath_skip=no
6822                 if test -n "$cf_rpath_list"
6823                 then
6824                         for cf_rpath_item in $cf_rpath_list
6825                         do
6826                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
6827                                 then
6828                                         cf_rpath_skip=yes
6829                                         break
6830                                 fi
6831                         done
6832                 fi
6833
6834                 if test "$cf_rpath_skip" = no
6835                 then
6836                         # transform the option
6837                         if test "$LD_RPATH_OPT" = "-R " ; then
6838                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
6839                         else
6840                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
6841                         fi
6842
6843                         # if we have not already added this, add it now
6844                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
6845                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
6846                         then
6847                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
6848                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
6849                         fi
6850                 fi
6851                 ;;
6852         esac
6853         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
6854 done
6855 $1=$cf_rpath_dst
6856
6857 CF_VERBOSE(...checked $1 [$]$1)
6858 AC_SUBST(EXTRA_LDFLAGS)
6859 ])dnl
6860 dnl ---------------------------------------------------------------------------
6861 dnl CF_SAVE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:46:44
6862 dnl ------------------
6863 dnl Use this macro to save CFLAGS/CPPFLAGS/LIBS before checks against X headers
6864 dnl and libraries which do not update those variables.
6865 dnl
6866 dnl $1 = name of current macro
6867 define([CF_SAVE_XTRA_FLAGS],
6868 [
6869 cf_save_LIBS_$1="$LIBS"
6870 cf_save_CFLAGS_$1="$CFLAGS"
6871 cf_save_CPPFLAGS_$1="$CPPFLAGS"
6872 LIBS="$LIBS ${X_PRE_LIBS} ${X_LIBS} ${X_EXTRA_LIBS}"
6873 for cf_X_CFLAGS in $X_CFLAGS
6874 do
6875         case "x$cf_X_CFLAGS" in
6876         x-[[IUD]]*)
6877                 CPPFLAGS="$CPPFLAGS $cf_X_CFLAGS"
6878                 ;;
6879         *)
6880                 CFLAGS="$CFLAGS $cf_X_CFLAGS"
6881                 ;;
6882         esac
6883 done
6884 ])dnl
6885 dnl ---------------------------------------------------------------------------
6886 dnl CF_SHARED_OPTS version: 105 updated: 2021/01/02 17:09:14
6887 dnl --------------
6888 dnl --------------
6889 dnl Attempt to determine the appropriate CC/LD options for creating a shared
6890 dnl library.
6891 dnl
6892 dnl Notes:
6893 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
6894 dnl the build-tree, i.e., by making use of the libraries that are compiled in
6895 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
6896 dnl shared library since that can lead to unexpected results at runtime.
6897 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
6898 dnl libraries are compiled in ../../lib
6899 dnl
6900 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
6901 dnl to install symbolic links to the rel/abi versions of shared libraries.
6902 dnl
6903 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
6904 dnl version when making symbolic links.
6905 dnl
6906 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
6907 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
6908 dnl (ex: libncurses.so.<ver>).
6909 dnl
6910 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
6911 AC_DEFUN([CF_SHARED_OPTS],
6912 [
6913         AC_REQUIRE([CF_LD_RPATH_OPT])
6914
6915         RM_SHARED_OPTS=
6916         LOCAL_LDFLAGS=
6917         LOCAL_LDFLAGS2=
6918         LD_SHARED_OPTS=
6919         INSTALL_LIB="-m 644"
6920         : ${rel_builddir:=.}
6921
6922         shlibdir=$libdir
6923         AC_SUBST(shlibdir)
6924
6925         MAKE_DLLS="#"
6926         AC_SUBST(MAKE_DLLS)
6927
6928         cf_cv_do_symlinks=no
6929         cf_ld_rpath_opt=
6930         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
6931
6932         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
6933         AC_ARG_WITH(shlib-version,
6934         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
6935         [test -z "$withval" && withval=auto
6936         case "$withval" in
6937         (yes)
6938                 cf_cv_shlib_version=auto
6939                 ;;
6940         (rel|abi|auto)
6941                 cf_cv_shlib_version=$withval
6942                 ;;
6943         (*)
6944                 AC_MSG_RESULT($withval)
6945                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
6946                 ;;
6947         esac
6948         ],[cf_cv_shlib_version=auto])
6949         AC_MSG_RESULT($cf_cv_shlib_version)
6950
6951         cf_cv_rm_so_locs=no
6952         cf_try_cflags=
6953
6954         # Some less-capable ports of gcc support only -fpic
6955         CC_SHARED_OPTS=
6956
6957         cf_try_fPIC=no
6958         if test "$GCC" = yes
6959         then
6960                 cf_try_fPIC=yes
6961         else
6962                 case "$cf_cv_system_name" in
6963                 (*linux*)       # e.g., PGI compiler
6964                         cf_try_fPIC=yes
6965                         ;;
6966                 esac
6967         fi
6968
6969         if test "$cf_try_fPIC" = yes
6970         then
6971                 AC_MSG_CHECKING(which $CC option to use)
6972                 cf_save_CFLAGS="$CFLAGS"
6973                 for CC_SHARED_OPTS in -fPIC -fpic ''
6974                 do
6975                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
6976                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
6977                 done
6978                 AC_MSG_RESULT($CC_SHARED_OPTS)
6979                 CFLAGS="$cf_save_CFLAGS"
6980         fi
6981
6982         cf_cv_shlib_version_infix=no
6983
6984         case "$cf_cv_system_name" in
6985         (aix4.[3-9]*|aix[[5-7]]*)
6986                 if test "$GCC" = yes; then
6987                         CC_SHARED_OPTS='-Wl,-brtl'
6988                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
6989                 else
6990                         CC_SHARED_OPTS='-brtl'
6991                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
6992                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
6993                 fi
6994                 ;;
6995         (beos*)
6996                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
6997                 ;;
6998         (cygwin*)
6999                 CC_SHARED_OPTS=
7000                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
7001                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
7002                 cf_cv_shlib_version=cygdll
7003                 cf_cv_shlib_version_infix=cygdll
7004                 shlibdir=$bindir
7005                 MAKE_DLLS=
7006                 cat >mk_shared_lib.sh <<-CF_EOF
7007                 #!$SHELL
7008                 SHARED_LIB=\[$]1
7009                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
7010                 shift
7011                 cat <<-EOF
7012                 Linking shared library
7013                 ** SHARED_LIB \[$]SHARED_LIB
7014                 ** IMPORT_LIB \[$]IMPORT_LIB
7015 EOF
7016                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
7017 CF_EOF
7018                 chmod +x mk_shared_lib.sh
7019                 ;;
7020         (msys*)
7021                 CC_SHARED_OPTS=
7022                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
7023                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
7024                 cf_cv_shlib_version=msysdll
7025                 cf_cv_shlib_version_infix=msysdll
7026                 shlibdir=$bindir
7027                 MAKE_DLLS=
7028                 cat >mk_shared_lib.sh <<-CF_EOF
7029                 #!$SHELL
7030                 SHARED_LIB=\[$]1
7031                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
7032                 shift
7033                 cat <<-EOF
7034                 Linking shared library
7035                 ** SHARED_LIB \[$]SHARED_LIB
7036                 ** IMPORT_LIB \[$]IMPORT_LIB
7037 EOF
7038                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
7039 CF_EOF
7040                 chmod +x mk_shared_lib.sh
7041                 ;;
7042         (darwin*)
7043                 cf_try_cflags="no-cpp-precomp"
7044                 CC_SHARED_OPTS="-dynamic"
7045                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
7046                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
7047                 cf_cv_shlib_version_infix=yes
7048                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
7049                         cf_save_LDFLAGS=$LDFLAGS
7050                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
7051                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
7052                                 LDFLAGS=$cf_save_LDFLAGS])
7053                 if test "$cf_cv_ldflags_search_paths_first" = yes; then
7054                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
7055                 fi
7056                 ;;
7057         (hpux[[7-8]]*)
7058                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
7059                 if test "$GCC" != yes; then
7060                         CC_SHARED_OPTS='+Z'
7061                 fi
7062                 MK_SHARED_LIB='${LD} ${LDFLAGS} -b -o $[@]'
7063                 INSTALL_LIB="-m 555"
7064                 ;;
7065         (hpux*)
7066                 # (tested with gcc 2.7.2 -- I don't have c89)
7067                 if test "$GCC" = yes; then
7068                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
7069                 else
7070                         CC_SHARED_OPTS='+Z'
7071                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
7072                 fi
7073                 MK_SHARED_LIB='${LD} ${LDFLAGS} +b ${libdir} -b -o $[@]'
7074                 # HP-UX shared libraries must be executable, and should be
7075                 # readonly to exploit a quirk in the memory manager.
7076                 INSTALL_LIB="-m 555"
7077                 ;;
7078         (interix*)
7079                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7080                 if test "$cf_cv_shlib_version" = rel; then
7081                         cf_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
7082                 else
7083                         cf_shared_soname='`basename $[@]`'
7084                 fi
7085                 CC_SHARED_OPTS=
7086                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $[@]'
7087                 ;;
7088         (irix*)
7089                 if test "$cf_cv_enable_rpath" = yes ; then
7090                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7091                 fi
7092                 # tested with IRIX 5.2 and 'cc'.
7093                 if test "$GCC" != yes; then
7094                         CC_SHARED_OPTS='-KPIC'
7095                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
7096                 else
7097                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,`basename $[@]` -o $[@]'
7098                 fi
7099                 cf_cv_rm_so_locs=yes
7100                 ;;
7101         (linux*|gnu*|k*bsd*-gnu)
7102                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
7103                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
7104                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7105                 fi
7106                 if test "$cf_cv_enable_rpath" = yes ; then
7107                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7108                 fi
7109                 CF_SHARED_SONAME
7110                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7111                 ;;
7112         (mingw*msvc*)
7113                 cf_cv_shlib_version=msvcdll
7114                 cf_cv_shlib_version_infix=msvcdll
7115                 shlibdir=$bindir
7116                 MAKE_DLLS=
7117                 if test "$DFT_LWR_MODEL" = "shared" ; then
7118                         LOCAL_LDFLAGS="-link -dll"
7119                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7120                         EXTRA_LDFLAGS="-link -dll $EXTRA_LDFLAGS"
7121                 fi
7122                 CC_SHARED_OPTS=
7123                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ ${LD} [$]{CFLAGS}'
7124                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.lib"
7125                 cat >mk_shared_lib.sh <<-CF_EOF
7126                 #!$SHELL
7127                 SHARED_LIB=\[$]1
7128                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.lib/'\`
7129                 shift
7130                 my_ld=\[$]1
7131                 shift
7132                 cat <<-EOF
7133                 Linking shared library
7134                 ** SHARED LIB \$SHARED_LIB
7135                 ** IMPORT_LIB \$IMPORT_LIB
7136 EOF
7137                 args=\$(echo \[$]* | sed -E "s#-l(\w*)#\1.dll.lib#g" | sed -E "s#-L(\w*)#-LIBPATH:\1#g")
7138                 exec \$my_ld -DLL -IMPLIB:"\${IMPORT_LIB}" -OUT:"\${SHARED_LIB}" ${LDFLAGS} \$args
7139                 mv "\${IMPORT_LIB}" "\${IMPORT_LIB}"
7140 CF_EOF
7141                 chmod +x mk_shared_lib.sh
7142                 cat >mk_prog.sh <<-CF_EOF
7143                 #!$SHELL
7144                 shift
7145                 # Ignore first argument (compiler) and use LD (link.exe) unconditionally
7146                 LD="[$]LD"
7147                 clopts=()
7148                 ldopts=("/subsystem:console")
7149                 libs=()
7150                 isdll=0
7151                 while test \[$]# -gt 0; do
7152                         case "\[$]1" in
7153                                 -link)
7154                                         # ignore -link argument
7155                                         ;;
7156                                 -M[[TD]] | -M[[TD]]d)
7157                                         # ignore runtime-library option
7158                                         ;;
7159                                 -dll)
7160                                         isdll=1
7161                                         ;;
7162                                 -W* | -w*)
7163                                         # ignore warnings
7164                                         ;;
7165                                 -D*)
7166                                         clopts+=("\[$]1")
7167                                         ;;
7168                                 -I*)
7169                                         clopts+=("\[$]1")
7170                                         ;;
7171                                 -l*)
7172                                         libs+=("\`echo \"\[$]1\" | sed \"s/^-l//\"\`")
7173                                         ;;
7174                                 -L*)
7175                                         ldopts+=("\`echo \"\[$]1\" | sed \"s/^-L/-LIBPATH:/\"\`")
7176                                         ;;
7177                                 *.obj | *.o)
7178                                         ldopts+=("\[$]1")
7179                                         ;;
7180                                 -Wl,*)
7181                                         for linkarg in \`echo '\[$]1' | sed -e 's/-Wl,//' -e 's/,/ /'\`; do
7182                                                 ldopts+=("\[$]{linkarg}")
7183                                         done
7184                                         ;;
7185                                 *.lib)
7186                                         ldopts+=("\[$]1")
7187                                         ;;
7188                                 -o)
7189                                         shift
7190                                         ldopts+=("-out:\[$]1")
7191                                         ;;
7192                                 *)
7193                                         clopts+=("\[$]1")
7194                                         ldopts+=("\[$]1")
7195                                         ;;
7196                         esac
7197                         shift
7198                 done
7199                 if [[ "\$isdll" -ne 0 ]]; then
7200                         for lib in \[$]{libs[[*]]}; do
7201                                 ldopts+=("\[$]lib.dll.lib")
7202                         done
7203                 else
7204                         for lib in \[$]{libs[[*]]}; do
7205                                 ldopts+=("\[$]lib.lib")
7206                         done
7207                 fi
7208                 cat <<-EOF
7209                 Creating program
7210                 ** ld options:   "\[$]{ldopts[[@]]}"
7211 EOF
7212                 exec \[$]LD \[$]{ldopts[[@]]}
7213 CF_EOF
7214                 chmod +x mk_prog.sh
7215                 LINK_PROGS="$SHELL ${rel_builddir}/mk_prog.sh"
7216                 LINK_TESTS="$SHELL ${rel_builddir}/mk_prog.sh"
7217                 ;;
7218         (mingw*)
7219                 cf_cv_shlib_version=mingw
7220                 cf_cv_shlib_version_infix=mingw
7221                 shlibdir=$bindir
7222                 MAKE_DLLS=
7223                 if test "$DFT_LWR_MODEL" = "shared" ; then
7224                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
7225                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7226                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
7227                 fi
7228                 CC_SHARED_OPTS=
7229                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
7230                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
7231                 cat >mk_shared_lib.sh <<-CF_EOF
7232                 #!$SHELL
7233                 SHARED_LIB=\[$]1
7234                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
7235                 shift
7236                 cat <<-EOF
7237                 Linking shared library
7238                 ** SHARED_LIB \[$]SHARED_LIB
7239                 ** IMPORT_LIB \[$]IMPORT_LIB
7240 EOF
7241                 exec \[$]* ${LDFLAGS} -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
7242 CF_EOF
7243                 chmod +x mk_shared_lib.sh
7244                 ;;
7245         (openbsd[[2-9]].*|mirbsd*)
7246                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
7247                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
7248                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7249                 fi
7250                 if test "$cf_cv_enable_rpath" = yes ; then
7251                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7252                 fi
7253                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7254                 CF_SHARED_SONAME
7255                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7256                 ;;
7257         (nskJ*)
7258                 CC_SHARED_OPTS=
7259                 MK_SHARED_LIB='${LD} -Wshared -Weld=-export_all -o $[@]'
7260                 ;;
7261         (nskL*)
7262                 CC_SHARED_OPTS=
7263                 MK_SHARED_LIB='${LD} -Wshared -Wxld=-export_all -o $[@]'
7264                 ;;
7265         (nto-qnx*|openbsd*|freebsd[[12]].*)
7266                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7267                 MK_SHARED_LIB='${LD} ${LDFLAGS} -Bshareable -o $[@]'
7268                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7269                 ;;
7270         (dragonfly*|freebsd*)
7271                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7272                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
7273                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
7274                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
7275                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7276                 fi
7277                 CF_SHARED_SONAME
7278                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7279                 ;;
7280         (netbsd*)
7281                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7282                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
7283                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
7284                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7285                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7286                         if test "$cf_cv_shlib_version" = auto; then
7287                         if test -f /usr/libexec/ld.elf_so; then
7288                                 cf_cv_shlib_version=abi
7289                         else
7290                                 cf_cv_shlib_version=rel
7291                         fi
7292                         fi
7293                         CF_SHARED_SONAME
7294                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
7295                 else
7296                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -o $[@]'
7297                 fi
7298                 ;;
7299         (osf*|mls+*)
7300                 # tested with OSF/1 V3.2 and 'cc'
7301                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
7302                 # link with shared libs).
7303                 MK_SHARED_LIB='${LD} ${LDFLAGS} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
7304                 case "$host_os" in
7305                 (osf4*)
7306                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
7307                         ;;
7308                 esac
7309                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
7310                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
7311                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
7312                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7313                 fi
7314                 cf_cv_rm_so_locs=yes
7315                 ;;
7316         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
7317                 # tested with osr5.0.5
7318                 if test "$GCC" != yes; then
7319                         CC_SHARED_OPTS='-belf -KPIC'
7320                 fi
7321                 MK_SHARED_LIB='${LD} ${LDFLAGS} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
7322                 if test "$cf_cv_enable_rpath" = yes ; then
7323                         # only way is to set LD_RUN_PATH but no switch for it
7324                         RUN_PATH=$libdir
7325                 fi
7326                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7327                 LINK_PROGS='LD_RUN_PATH=${libdir}'
7328                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
7329                 ;;
7330         (sunos4*)
7331                 # tested with SunOS 4.1.1 and gcc 2.7.0
7332                 if test "$GCC" != yes; then
7333                         CC_SHARED_OPTS='-KPIC'
7334                 fi
7335                 MK_SHARED_LIB='${LD} ${LDFLAGS} -assert pure-text -o $[@]'
7336                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7337                 ;;
7338         (solaris2*)
7339                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
7340                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
7341                 if test "$DFT_LWR_MODEL" = "shared" ; then
7342                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
7343                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7344                 fi
7345                 if test "$cf_cv_enable_rpath" = yes ; then
7346                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
7347                 fi
7348                 CF_SHARED_SONAME
7349                 if test "$GCC" != yes; then
7350                         cf_save_CFLAGS="$CFLAGS"
7351                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
7352                         do
7353                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
7354                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\\n");],[break])
7355                         done
7356                         CFLAGS="$cf_save_CFLAGS"
7357                         CC_SHARED_OPTS=$cf_shared_opts
7358                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
7359                 else
7360                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
7361                 fi
7362                 ;;
7363         (sysv5uw7*|unix_sv*)
7364                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
7365                 if test "$GCC" != yes; then
7366                         CC_SHARED_OPTS='-KPIC'
7367                 fi
7368                 MK_SHARED_LIB='${LD} ${LDFLAGS} -d y -G -o [$]@'
7369                 ;;
7370         (*)
7371                 CC_SHARED_OPTS='unknown'
7372                 MK_SHARED_LIB='echo unknown'
7373                 ;;
7374         esac
7375
7376         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
7377         case "$cf_cv_shlib_version" in
7378         (rel|abi)
7379                 case "$MK_SHARED_LIB" in
7380                 (*'-o $[@]')
7381                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
7382                         ;;
7383                 (*)
7384                         AC_MSG_WARN(ignored --with-shlib-version)
7385                         ;;
7386                 esac
7387                 ;;
7388         esac
7389
7390         if test -n "$cf_try_cflags"
7391         then
7392 cat > conftest.$ac_ext <<EOF
7393 #line __oline__ "${as_me:-configure}"
7394 #include <stdio.h>
7395 int main(int argc, char *argv[[]])
7396 {
7397         printf("hello\\n");
7398         return (argv[[argc-1]] == 0) ;
7399 }
7400 EOF
7401                 cf_save_CFLAGS="$CFLAGS"
7402                 for cf_opt in $cf_try_cflags
7403                 do
7404                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
7405                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
7406                         if AC_TRY_EVAL(ac_compile); then
7407                                 AC_MSG_RESULT(yes)
7408                                 cf_save_CFLAGS="$CFLAGS"
7409                         else
7410                                 AC_MSG_RESULT(no)
7411                         fi
7412                 done
7413                 CFLAGS="$cf_save_CFLAGS"
7414         fi
7415
7416
7417         # RPATH_LIST is a colon-separated list of directories
7418         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
7419         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
7420
7421         test "$cf_cv_rm_so_locs" = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
7422
7423         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
7424         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
7425
7426         AC_SUBST(CC_SHARED_OPTS)
7427         AC_SUBST(LD_RPATH_OPT)
7428         AC_SUBST(LD_SHARED_OPTS)
7429         AC_SUBST(MK_SHARED_LIB)
7430         AC_SUBST(RM_SHARED_OPTS)
7431
7432         AC_SUBST(LINK_PROGS)
7433         AC_SUBST(LINK_TESTS)
7434
7435         AC_SUBST(EXTRA_LDFLAGS)
7436         AC_SUBST(LOCAL_LDFLAGS)
7437         AC_SUBST(LOCAL_LDFLAGS2)
7438
7439         AC_SUBST(INSTALL_LIB)
7440         AC_SUBST(RPATH_LIST)
7441 ])dnl
7442 dnl ---------------------------------------------------------------------------
7443 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
7444 dnl ----------------
7445 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
7446 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
7447 dnl option.
7448 dnl
7449 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
7450 dnl If missing, use "rel".
7451 define([CF_SHARED_SONAME],
7452 [
7453         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
7454         if test "$cf_cv_shlib_version" = rel; then
7455                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
7456         else
7457                 cf_cv_shared_soname='`basename $[@]`'
7458         fi
7459 ])
7460 dnl ---------------------------------------------------------------------------
7461 dnl CF_SIGWINCH version: 6 updated: 2021/01/01 13:31:04
7462 dnl -----------
7463 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
7464 dnl programs need this test).
7465 dnl
7466 dnl This is really a Mac OS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
7467 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
7468 dnl winsize declaration is left alone - we may revisit this if Apple choose to
7469 dnl break that part of the interface as well.
7470 AC_DEFUN([CF_SIGWINCH],
7471 [
7472 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
7473         AC_TRY_COMPILE([
7474 #include <sys/types.h>
7475 #include <sys/signal.h>
7476 ],[int x = SIGWINCH; (void)x],
7477         [cf_cv_define_sigwinch=yes],
7478         [AC_TRY_COMPILE([
7479 #undef _XOPEN_SOURCE
7480 #undef _POSIX_SOURCE
7481 #undef _POSIX_C_SOURCE
7482 #include <sys/types.h>
7483 #include <sys/signal.h>
7484 ],[int x = SIGWINCH; (void)x],
7485         [cf_cv_define_sigwinch=maybe],
7486         [cf_cv_define_sigwinch=no])
7487 ])
7488 ])
7489
7490 if test "$cf_cv_define_sigwinch" = maybe ; then
7491 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
7492 cf_cv_fixup_sigwinch=unknown
7493 cf_sigwinch=32
7494 while test "$cf_sigwinch" != 1
7495 do
7496         AC_TRY_COMPILE([
7497 #undef _XOPEN_SOURCE
7498 #undef _POSIX_SOURCE
7499 #undef _POSIX_C_SOURCE
7500 #include <sys/types.h>
7501 #include <sys/signal.h>
7502 ],[
7503 #if SIGWINCH != $cf_sigwinch
7504 make an error
7505 #endif
7506 int x = SIGWINCH; (void)x],
7507         [cf_cv_fixup_sigwinch=$cf_sigwinch
7508          break])
7509
7510 cf_sigwinch="`expr "$cf_sigwinch" - 1`"
7511 done
7512 ])
7513
7514         if test "$cf_cv_fixup_sigwinch" != unknown ; then
7515                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
7516         fi
7517 fi
7518 ])dnl
7519 dnl ---------------------------------------------------------------------------
7520 dnl CF_SIG_ATOMIC_T version: 5 updated: 2020/03/10 18:53:47
7521 dnl ---------------
7522 dnl signal handler, but there are some gcc dependencies in that recommendation.
7523 dnl Try anyway.
7524 AC_DEFUN([CF_SIG_ATOMIC_T],
7525 [
7526 AC_MSG_CHECKING(for signal global datatype)
7527 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
7528         for cf_type in \
7529                 "volatile sig_atomic_t" \
7530                 "sig_atomic_t" \
7531                 "int"
7532         do
7533         AC_TRY_COMPILE([
7534 #include <sys/types.h>
7535 #include <signal.h>
7536 #include <stdio.h>
7537
7538 extern $cf_type x;
7539 $cf_type x;
7540 static void handler(int sig)
7541 {
7542         (void)sig;
7543         x = 5;
7544 }],
7545                 [signal(SIGINT, handler);
7546                  x = 1],
7547                 [cf_cv_sig_atomic_t=$cf_type],
7548                 [cf_cv_sig_atomic_t=no])
7549                 test "$cf_cv_sig_atomic_t" != no && break
7550         done
7551         ])
7552 AC_MSG_RESULT($cf_cv_sig_atomic_t)
7553 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
7554 ])dnl
7555 dnl ---------------------------------------------------------------------------
7556 dnl CF_SIZECHANGE version: 17 updated: 2021/01/01 13:31:04
7557 dnl -------------
7558 dnl Check for definitions & structures needed for window size-changing
7559 dnl
7560 dnl https://stackoverflow.com/questions/18878141/difference-between-structures-ttysize-and-winsize/50769952#50769952
7561 AC_DEFUN([CF_SIZECHANGE],
7562 [
7563 AC_REQUIRE([CF_STRUCT_TERMIOS])
7564 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
7565         cf_cv_sizechange=unknown
7566         cf_save_CPPFLAGS="$CPPFLAGS"
7567
7568 for cf_opts in "" "NEED_PTEM_H"
7569 do
7570
7571         CPPFLAGS="$cf_save_CPPFLAGS"
7572         if test -n "$cf_opts"
7573         then
7574                 CF_APPEND_TEXT(CPPFLAGS,-D$cf_opts)
7575         fi
7576         AC_TRY_COMPILE([#include <sys/types.h>
7577 #ifdef HAVE_TERMIOS_H
7578 #include <termios.h>
7579 #else
7580 #ifdef HAVE_TERMIO_H
7581 #include <termio.h>
7582 #endif
7583 #endif
7584
7585 #ifdef NEED_PTEM_H
7586 /* This is a workaround for SCO:  they neglected to define struct winsize in
7587  * termios.h -- it's only in termio.h and ptem.h
7588  */
7589 #include <sys/stream.h>
7590 #include <sys/ptem.h>
7591 #endif
7592
7593 #ifdef HAVE_SYS_IOCTL_H
7594 #include <sys/ioctl.h>
7595 #endif
7596 ],[
7597 #ifdef TIOCGSIZE
7598         struct ttysize win;     /* SunOS 3.0... */
7599         int y = win.ts_lines = 2;
7600         int x = win.ts_cols = 1;
7601         (void)y;
7602         (void)x;
7603 #else
7604 #ifdef TIOCGWINSZ
7605         struct winsize win;     /* everything else */
7606         int y = win.ws_row = 2;
7607         int x = win.ws_col = 1;
7608         (void)y;
7609         (void)x;
7610 #else
7611         no TIOCGSIZE or TIOCGWINSZ
7612 #endif /* TIOCGWINSZ */
7613 #endif /* TIOCGSIZE */
7614         ],
7615         [cf_cv_sizechange=yes],
7616         [cf_cv_sizechange=no])
7617
7618         CPPFLAGS="$cf_save_CPPFLAGS"
7619         if test "$cf_cv_sizechange" = yes ; then
7620                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
7621                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
7622                 break
7623         fi
7624 done
7625 ])
7626 if test "$cf_cv_sizechange" != no ; then
7627         AC_DEFINE(HAVE_SIZECHANGE,1,[Define to 1 if sizechange declarations are provided])
7628         case "$cf_cv_sizechange" in
7629         (NEED*)
7630                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
7631                 ;;
7632         esac
7633 fi
7634 ])dnl
7635 dnl ---------------------------------------------------------------------------
7636 dnl CF_SRC_MODULES version: 33 updated: 2021/01/01 13:31:04
7637 dnl --------------
7638 dnl For each parameter, test if the source-directory exists, and if it contains
7639 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
7640 dnl use in CF_LIB_RULES.
7641 dnl
7642 dnl This uses the configured value to make the lists SRC_SUBDIRS and
7643 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
7644 AC_DEFUN([CF_SRC_MODULES],
7645 [
7646 AC_REQUIRE([CF_CHECK_GNAT_VERSION])
7647 AC_MSG_CHECKING(for src modules)
7648
7649 # dependencies and linker-arguments for test-programs
7650 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
7651 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
7652 if test "$DFT_LWR_MODEL" = "libtool"; then
7653         TEST_ARGS="${TEST_DEPS}"
7654         TEST_ARG2="${TEST_DEP2}"
7655 else
7656         TEST_ARGS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
7657         TEST_ARG2="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARG2"
7658 fi
7659
7660 PC_MODULES_TO_MAKE="ncurses${USE_ARG_SUFFIX}"
7661 cf_cv_src_modules=
7662 for cf_dir in $1
7663 do
7664         if test -f "$srcdir/$cf_dir/modules" ; then
7665
7666                 # We may/may not have tack in the distribution, though the
7667                 # makefile is.
7668                 if test "$cf_dir" = tack ; then
7669                         if test "x$cf_with_tack" != "xyes"; then
7670                                 continue
7671                         fi
7672                 fi
7673
7674                 if test -z "$cf_cv_src_modules"; then
7675                         cf_cv_src_modules=$cf_dir
7676                 else
7677                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
7678                 fi
7679
7680                 # Make the ncurses_cfg.h file record the library interface files as
7681                 # well.  These are header files that are the same name as their
7682                 # directory.  Ncurses is the only library that does not follow
7683                 # that pattern.
7684                 if test "$cf_dir" = tack ; then
7685                         continue
7686                 elif test -f "$srcdir/${cf_dir}/${cf_dir}.h" ; then
7687                         CF_UPPER(cf_have_include,$cf_dir)
7688                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
7689                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
7690                         CF_MAP_LIB_BASENAME(TEST_ROOT,$cf_dir)
7691                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TEST_ROOT}${DFT_DEP_SUFFIX} $TEST_DEPS"
7692                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TEST_ROOT}${DFT_DEP_SUFFIX} $TEST_DEP2"
7693                         if test "$DFT_LWR_MODEL" = "libtool"; then
7694                                 TEST_ARGS="${TEST_DEPS}"
7695                                 TEST_ARG2="${TEST_DEP2}"
7696                         else
7697                                 TEST_ARGS="-l${TEST_ROOT}${USE_ARG_SUFFIX} $TEST_ARGS"
7698                                 TEST_ARG2="-l${TEST_ROOT}${USE_ARG_SUFFIX} $TEST_ARG2"
7699                         fi
7700                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${USE_ARG_SUFFIX}"
7701                 fi
7702         fi
7703 done
7704 AC_MSG_RESULT($cf_cv_src_modules)
7705
7706 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
7707 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
7708
7709 AC_SUBST(TEST_ARGS)
7710 AC_SUBST(TEST_DEPS)
7711
7712 AC_SUBST(TEST_ARG2)
7713 AC_SUBST(TEST_DEP2)
7714
7715 SRC_SUBDIRS=
7716 if test "x$cf_with_manpages" != xno ; then
7717         SRC_SUBDIRS="$SRC_SUBDIRS man"
7718 fi
7719 SRC_SUBDIRS="$SRC_SUBDIRS include"
7720 for cf_dir in $cf_cv_src_modules
7721 do
7722         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
7723 done
7724 if test "x$cf_with_tests" != "xno" ; then
7725         SRC_SUBDIRS="$SRC_SUBDIRS test"
7726 fi
7727 # always make this, to install the ncurses-config script
7728 SRC_SUBDIRS="$SRC_SUBDIRS misc"
7729 if test "$cf_with_cxx_binding" != no; then
7730         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${USE_ARG_SUFFIX}"
7731         SRC_SUBDIRS="$SRC_SUBDIRS c++"
7732 fi
7733
7734 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
7735 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
7736
7737 AC_SUBST(PC_MODULES_TO_MAKE)
7738
7739 ADA_SUBDIRS=
7740 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f "$srcdir/Ada95/Makefile.in" ; then
7741         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
7742         ADA_SUBDIRS="gen src"
7743         if test "x$cf_with_tests" != "xno" ; then
7744                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
7745         fi
7746 fi
7747
7748 SUB_MAKEFILES=
7749 for cf_dir in $SRC_SUBDIRS
7750 do
7751         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
7752 done
7753
7754 if test -n "$ADA_SUBDIRS"; then
7755         for cf_dir in $ADA_SUBDIRS
7756         do
7757                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
7758         done
7759         AC_SUBST(ADA_SUBDIRS)
7760 fi
7761 ])dnl
7762 dnl ---------------------------------------------------------------------------
7763 dnl CF_STDCPP_LIBRARY version: 12 updated: 2021/01/01 13:31:04
7764 dnl -----------------
7765 dnl Check for -lstdc++, which is GNU's standard C++ library.
7766 dnl If $CXXLIBS is set, add that to the libraries used for test-linking.
7767 dnl If -lstdc++ was not already added to $LIBS or $CXXLIBS, and is needed,
7768 dnl add it to $CXXLIBS.
7769 AC_DEFUN([CF_STDCPP_LIBRARY],
7770 [
7771 if test -n "$GXX" ; then
7772
7773         cf_save="$LIBS"
7774         LIBS="$LIBS $CXXLIBS"
7775         AC_MSG_CHECKING(if we already have C++ library)
7776         AC_TRY_LINK([
7777                         #include <iostream>],[
7778                         std::cout << "Hello World!" << std::endl;],
7779                 [cf_have_libstdcpp=yes],
7780                 [cf_have_libstdcpp=no])
7781         AC_MSG_RESULT($cf_have_libstdcpp)
7782         LIBS="$cf_save"
7783
7784         if test "$cf_have_libstdcpp" != yes
7785         then
7786                 case "$cf_cv_system_name" in
7787                 (os2*)
7788                         if test -z "`g++ -dM -E - < /dev/null | grep __KLIBC__`"; then
7789                                 cf_stdcpp_libname=stdcpp
7790                         else
7791                                 cf_stdcpp_libname=stdc++
7792                         fi
7793                         ;;
7794                 (*)
7795                         cf_stdcpp_libname=stdc++
7796                         ;;
7797                 esac
7798
7799                 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
7800                         cf_save="$LIBS"
7801                         LIBS="$LIBS $CXXLIBS"
7802                         CF_ADD_LIB($cf_stdcpp_libname)
7803                 AC_TRY_LINK([
7804                                 #include <iostream>],[
7805                                 std::cout << "Hello World!" << std::endl;],
7806                         [cf_cv_libstdcpp=yes],
7807                         [cf_cv_libstdcpp=no])
7808                         LIBS="$cf_save"
7809                 ])
7810                 test "$cf_cv_libstdcpp" = yes && { CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS) }
7811         fi
7812 fi
7813 ])dnl
7814 dnl ---------------------------------------------------------------------------
7815 dnl CF_STRIP_G_OPT version: 4 updated: 2021/01/02 09:31:20
7816 dnl --------------
7817 dnl     Remove "-g" option from the compiler options
7818 AC_DEFUN([CF_STRIP_G_OPT],
7819 [$1=`echo "${$1}" | CF__SED_TRIMBLANKS(-e 's%-g %%' -e 's%-g$%%')`])dnl
7820 dnl ---------------------------------------------------------------------------
7821 dnl CF_STRUCT_SIGACTION version: 5 updated: 2012/10/06 17:56:13
7822 dnl -------------------
7823 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
7824 dnl do this if we've found the sigaction function.
7825 AC_DEFUN([CF_STRUCT_SIGACTION],[
7826 AC_REQUIRE([CF_XOPEN_SOURCE])
7827
7828 if test "$ac_cv_func_sigaction" = yes; then
7829 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
7830 AC_TRY_COMPILE([
7831 #include <sys/types.h>
7832 #include <signal.h>],
7833         [struct sigaction act],
7834         [sigact_bad=no],
7835         [
7836 AC_TRY_COMPILE([
7837 #define _POSIX_SOURCE
7838 #include <sys/types.h>
7839 #include <signal.h>],
7840         [struct sigaction act],
7841         [sigact_bad=yes
7842          AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE])],
7843          [sigact_bad=unknown])])
7844 AC_MSG_RESULT($sigact_bad)
7845 fi
7846 ])dnl
7847 dnl ---------------------------------------------------------------------------
7848 dnl CF_STRUCT_TERMIOS version: 11 updated: 2020/03/19 20:46:13
7849 dnl -----------------
7850 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
7851 AC_DEFUN([CF_STRUCT_TERMIOS],[
7852 AC_REQUIRE([CF_XOPEN_SOURCE])
7853
7854 AC_CHECK_HEADERS( \
7855 termio.h \
7856 termios.h \
7857 unistd.h \
7858 sys/ioctl.h \
7859 sys/termio.h \
7860 )
7861
7862 if test "$ac_cv_header_termios_h" = yes ; then
7863         case "$CFLAGS $CPPFLAGS" in
7864         (*-D_POSIX_SOURCE*)
7865                 termios_bad=dunno ;;
7866         (*)     termios_bad=maybe ;;
7867         esac
7868         if test "$termios_bad" = maybe ; then
7869         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
7870         AC_TRY_COMPILE([#include <termios.h>],
7871                 [struct termios foo; int x = foo.c_iflag = 1; (void)x],
7872                 termios_bad=no, [
7873                 AC_TRY_COMPILE([
7874 #define _POSIX_SOURCE
7875 #include <termios.h>],
7876                         [struct termios foo; int x = foo.c_iflag = 2; (void)x],
7877                         termios_bad=unknown,
7878                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE]))
7879                         ])
7880         AC_MSG_RESULT($termios_bad)
7881         fi
7882 fi
7883 ])dnl
7884 dnl ---------------------------------------------------------------------------
7885 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
7886 dnl --------------
7887 dnl Construct a search-list for a nonstandard header/lib-file
7888 dnl     $1 = the variable to return as result
7889 dnl     $2 = the package name
7890 dnl     $3 = the subdirectory, e.g., bin, include or lib
7891 AC_DEFUN([CF_SUBDIR_PATH],
7892 [
7893 $1=
7894
7895 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
7896
7897 for cf_subdir_prefix in \
7898         /usr \
7899         /usr/local \
7900         /usr/pkg \
7901         /opt \
7902         /opt/local \
7903         [$]HOME
7904 do
7905         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
7906 done
7907 ])dnl
7908 dnl ---------------------------------------------------------------------------
7909 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
7910 dnl -----------
7911 dnl     Shorthand macro for substituting things that the user may override
7912 dnl     with an environment variable.
7913 dnl
7914 dnl     $1 = condition to pass to "test"
7915 dnl     $2 = environment variable
7916 dnl     $3 = value if the test succeeds
7917 dnl     $4 = value if the test fails
7918 AC_DEFUN([CF_SUBST_IF],
7919 [
7920 if test $1 ; then
7921         $2=$3
7922 ifelse($4,,,[else
7923         $2=$4])
7924 fi
7925 AC_SUBST($2)
7926 ])dnl
7927 dnl ---------------------------------------------------------------------------
7928 dnl CF_SUBST_NCURSES_VERSION version: 10 updated: 2021/01/04 18:48:01
7929 dnl ------------------------
7930 dnl Get the version-number for use in shared-library naming, etc.
7931 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
7932 [AC_REQUIRE([AC_PROG_EGREP])dnl
7933
7934 NCURSES_MAJOR="`${EGREP-egrep} '^NCURSES_MAJOR[[        ]]*=' "$srcdir/dist.mk" | sed -e 's/^[[^0-9]]*//'`"
7935 NCURSES_MINOR="`${EGREP-egrep} '^NCURSES_MINOR[[        ]]*=' "$srcdir/dist.mk" | sed -e 's/^[[^0-9]]*//'`"
7936 NCURSES_PATCH="`${EGREP-egrep} '^NCURSES_PATCH[[        ]]*=' "$srcdir/dist.mk" | sed -e 's/^[[^0-9]]*//'`"
7937 cf_cv_abi_version=${NCURSES_MAJOR}
7938 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
7939 dnl Show the computed version, for logging
7940 cf_cv_timestamp=`date`
7941 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
7942 dnl We need these values in the generated headers
7943 AC_SUBST(NCURSES_MAJOR)
7944 AC_SUBST(NCURSES_MINOR)
7945 AC_SUBST(NCURSES_PATCH)
7946 dnl We need these values in the generated makefiles
7947 AC_SUBST(cf_cv_rel_version)
7948 AC_SUBST(cf_cv_abi_version)
7949 AC_SUBST(cf_cv_builtin_bool)
7950 AC_SUBST(cf_cv_header_stdbool_h)
7951 AC_SUBST(cf_cv_type_of_bool)dnl
7952 ])dnl
7953 dnl ---------------------------------------------------------------------------
7954 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
7955 dnl ------------------
7956 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
7957 dnl older SCO configurations.
7958 AC_DEFUN([CF_SYS_TIME_SELECT],
7959 [
7960 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
7961 AC_CACHE_VAL(cf_cv_sys_time_select,[
7962 AC_TRY_COMPILE([
7963 #include <sys/types.h>
7964 #ifdef HAVE_SYS_TIME_H
7965 #include <sys/time.h>
7966 #endif
7967 #ifdef HAVE_SYS_SELECT_H
7968 #include <sys/select.h>
7969 #endif
7970 ],[],[cf_cv_sys_time_select=yes],
7971          [cf_cv_sys_time_select=no])
7972          ])
7973 AC_MSG_RESULT($cf_cv_sys_time_select)
7974 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
7975 ])dnl
7976 dnl ---------------------------------------------------------------------------
7977 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
7978 dnl ---------------
7979 dnl Define a top_builddir symbol, for applications that need an absolute path.
7980 AC_DEFUN([CF_TOP_BUILDDIR],
7981 [
7982 top_builddir=ifelse($1,,`pwd`,$1)
7983 AC_SUBST(top_builddir)
7984 ])dnl
7985 dnl ---------------------------------------------------------------------------
7986 dnl CF_TRY_PKG_CONFIG version: 6 updated: 2020/12/31 10:54:15
7987 dnl -----------------
7988 dnl This is a simple wrapper to use for pkg-config, for libraries which may be
7989 dnl available in that form.
7990 dnl
7991 dnl $1 = package name, which may be a shell variable
7992 dnl $2 = extra logic to use, if any, after updating CFLAGS and LIBS
7993 dnl $3 = logic to use if pkg-config does not have the package
7994 AC_DEFUN([CF_TRY_PKG_CONFIG],[
7995 AC_REQUIRE([CF_PKG_CONFIG])
7996
7997 if test "$PKG_CONFIG" != none && "$PKG_CONFIG" --exists "$1"; then
7998         CF_VERBOSE(found package $1)
7999         cf_pkgconfig_incs="`$PKG_CONFIG --cflags "$1" 2>/dev/null`"
8000         cf_pkgconfig_libs="`$PKG_CONFIG --libs   "$1" 2>/dev/null`"
8001         CF_VERBOSE(package $1 CFLAGS: $cf_pkgconfig_incs)
8002         CF_VERBOSE(package $1 LIBS: $cf_pkgconfig_libs)
8003         CF_ADD_CFLAGS($cf_pkgconfig_incs)
8004         CF_ADD_LIBS($cf_pkgconfig_libs)
8005         ifelse([$2],,:,[$2])
8006 else
8007         cf_pkgconfig_incs=
8008         cf_pkgconfig_libs=
8009         ifelse([$3],,:,[$3])
8010 fi
8011 ])
8012 dnl ---------------------------------------------------------------------------
8013 dnl CF_TRY_XOPEN_SOURCE version: 2 updated: 2018/06/20 20:23:13
8014 dnl -------------------
8015 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
8016 dnl can define it successfully.
8017 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
8018 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
8019         AC_TRY_COMPILE([
8020 #include <stdlib.h>
8021 #include <string.h>
8022 #include <sys/types.h>
8023 ],[
8024 #ifndef _XOPEN_SOURCE
8025 make an error
8026 #endif],
8027         [cf_cv_xopen_source=no],
8028         [cf_save="$CPPFLAGS"
8029          CF_APPEND_TEXT(CPPFLAGS,-D_XOPEN_SOURCE=$cf_XOPEN_SOURCE)
8030          AC_TRY_COMPILE([
8031 #include <stdlib.h>
8032 #include <string.h>
8033 #include <sys/types.h>
8034 ],[
8035 #ifdef _XOPEN_SOURCE
8036 make an error
8037 #endif],
8038         [cf_cv_xopen_source=no],
8039         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
8040         CPPFLAGS="$cf_save"
8041         ])
8042 ])
8043
8044 if test "$cf_cv_xopen_source" != no ; then
8045         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
8046         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
8047         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
8048         CF_ADD_CFLAGS($cf_temp_xopen_source)
8049 fi
8050 ])
8051 dnl ---------------------------------------------------------------------------
8052 dnl CF_TYPEOF_CHTYPE version: 10 updated: 2017/01/21 11:06:25
8053 dnl ----------------
8054 dnl Determine the type we should use for chtype (and attr_t, which is treated
8055 dnl as the same thing).  We want around 32 bits, so on most machines want a
8056 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
8057 dnl wide characters, we have to have a type compatible with that, as well.
8058 AC_DEFUN([CF_TYPEOF_CHTYPE],
8059 [
8060 AC_MSG_CHECKING([for type of chtype])
8061 AC_CACHE_VAL(cf_cv_typeof_chtype,[
8062                 AC_TRY_RUN([
8063 #define WANT_BITS 31
8064 #include <stdio.h>
8065 int main(void)
8066 {
8067         FILE *fp = fopen("cf_test.out", "w");
8068         if (fp != 0) {
8069                 char *result = "long";
8070                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
8071                         int n;
8072                         unsigned int x, y;
8073                         for (n = 0; n < WANT_BITS; n++) {
8074                                 x = (1 << n);
8075                                 y = (x >> n);
8076                                 if (y != 1 || x == 0) {
8077                                         x = 0;
8078                                         break;
8079                                 }
8080                         }
8081                         /*
8082                          * If x is nonzero, an int is big enough for the bits
8083                          * that we want.
8084                          */
8085                         result = (x != 0) ? "int" : "long";
8086                 }
8087                 fputs(result, fp);
8088                 fclose(fp);
8089         }
8090         ${cf_cv_main_return:-return}(0);
8091 }
8092                 ],
8093                 [cf_cv_typeof_chtype=`cat cf_test.out`],
8094                 [cf_cv_typeof_chtype=long],
8095                 [cf_cv_typeof_chtype=long])
8096                 rm -f cf_test.out
8097         ])
8098 AC_MSG_RESULT($cf_cv_typeof_chtype)
8099
8100 AC_SUBST(cf_cv_typeof_chtype)
8101 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype,[Define to actual type if needed for chtype])
8102 ])dnl
8103 dnl ---------------------------------------------------------------------------
8104 dnl CF_TYPE_SIGACTION version: 4 updated: 2012/10/06 17:56:13
8105 dnl -----------------
8106 dnl
8107 AC_DEFUN([CF_TYPE_SIGACTION],
8108 [
8109 AC_MSG_CHECKING([for type sigaction_t])
8110 AC_CACHE_VAL(cf_cv_type_sigaction,[
8111         AC_TRY_COMPILE([
8112 #include <signal.h>],
8113                 [sigaction_t x],
8114                 [cf_cv_type_sigaction=yes],
8115                 [cf_cv_type_sigaction=no])])
8116 AC_MSG_RESULT($cf_cv_type_sigaction)
8117 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION,1,[Define to 1 if we have the sigaction_t type])
8118 ])dnl
8119 dnl ---------------------------------------------------------------------------
8120 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
8121 dnl --------------------
8122 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
8123 dnl won't, but they're still there.
8124 AC_DEFUN([CF_UNSIGNED_LITERALS],
8125 [
8126 AC_MSG_CHECKING([if unsigned literals are legal])
8127 AC_CACHE_VAL(cf_cv_unsigned_literals,[
8128         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
8129                 [cf_cv_unsigned_literals=yes],
8130                 [cf_cv_unsigned_literals=no])
8131         ])
8132 AC_MSG_RESULT($cf_cv_unsigned_literals)
8133 ])dnl
8134 dnl ---------------------------------------------------------------------------
8135 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
8136 dnl --------
8137 dnl Make an uppercase version of a variable
8138 dnl $1=uppercase($2)
8139 AC_DEFUN([CF_UPPER],
8140 [
8141 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
8142 ])dnl
8143 dnl ---------------------------------------------------------------------------
8144 dnl CF_UTF8_LIB version: 9 updated: 2021/05/19 19:35:25
8145 dnl -----------
8146 dnl Check for multibyte support, and if not found, utf8 compatibility library
8147 AC_DEFUN([CF_UTF8_LIB],
8148 [
8149 AC_HAVE_HEADERS(wchar.h)
8150 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
8151         cf_save_LIBS="$LIBS"
8152         AC_TRY_LINK([
8153 #include <stdlib.h>
8154 #include <stdio.h>
8155 #ifdef HAVE_WCHAR_H
8156 #include <wchar.h>
8157 #endif
8158 ],[putwc(0,0);],
8159         [cf_cv_utf8_lib=yes],
8160         [CF_FIND_LINKAGE([
8161 #include <libutf8.h>],[putwc(0,0);],utf8,
8162                 [cf_cv_utf8_lib=add-on],
8163                 [cf_cv_utf8_lib=no])
8164 ])])
8165
8166 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
8167 # ncurses/ncursesw:
8168 if test "$cf_cv_utf8_lib" = "add-on" ; then
8169         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
8170         CF_ADD_INCDIR($cf_cv_header_path_utf8)
8171         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
8172         CF_ADD_LIBS($cf_cv_library_file_utf8)
8173 fi
8174 ])dnl
8175 dnl ---------------------------------------------------------------------------
8176 dnl CF_VA_COPY version: 6 updated: 2018/12/04 18:14:25
8177 dnl ----------
8178 dnl check for va_copy, part of stdarg.h starting with ISO C 1999.
8179 dnl Also, workaround for glibc's __va_copy, by checking for both.
8180 dnl Finally, try to accommodate pre-ISO C 1999 headers.
8181 AC_DEFUN([CF_VA_COPY],[
8182 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
8183 AC_TRY_LINK([
8184 #include <stdarg.h>
8185 ],[
8186         static va_list dst;
8187         static va_list src;
8188         va_copy(dst, src)],
8189         cf_cv_have_va_copy=yes,
8190         cf_cv_have_va_copy=no)])
8191
8192 if test "$cf_cv_have_va_copy" = yes;
8193 then
8194         AC_DEFINE(HAVE_VA_COPY,1,[Define to 1 if we have va_copy])
8195 else # !cf_cv_have_va_copy
8196
8197 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
8198 AC_TRY_LINK([
8199 #include <stdarg.h>
8200 ],[
8201         static va_list dst;
8202         static va_list src;
8203         __va_copy(dst, src)],
8204         cf_cv_have___va_copy=yes,
8205         cf_cv_have___va_copy=no)])
8206
8207 if test "$cf_cv_have___va_copy" = yes
8208 then
8209         AC_DEFINE(HAVE___VA_COPY,1,[Define to 1 if we have __va_copy])
8210 else # !cf_cv_have___va_copy
8211
8212 AC_CACHE_CHECK(for __builtin_va_copy, cf_cv_have___builtin_va_copy,[
8213 AC_TRY_LINK([
8214 #include <stdarg.h>
8215 ],[
8216         static va_list dst;
8217         static va_list src;
8218         __builtin_va_copy(dst, src)],
8219         cf_cv_have___builtin_va_copy=yes,
8220         cf_cv_have___builtin_va_copy=no)])
8221
8222 test "$cf_cv_have___builtin_va_copy" = yes &&
8223         AC_DEFINE(HAVE___BUILTIN_VA_COPY,1,[Define to 1 if we have __builtin_va_copy])
8224
8225 fi # cf_cv_have___va_copy
8226
8227 fi # cf_cv_have_va_copy
8228
8229 case "${cf_cv_have_va_copy}${cf_cv_have___va_copy}${cf_cv_have___builtin_va_copy}" in
8230 (*yes*)
8231         ;;
8232
8233 (*)
8234         AC_CACHE_CHECK(if we can simply copy va_list, cf_cv_pointer_va_list,[
8235 AC_TRY_LINK([
8236 #include <stdarg.h>
8237 ],[
8238         va_list dst;
8239         va_list src;
8240         dst = src],
8241         cf_cv_pointer_va_list=yes,
8242         cf_cv_pointer_va_list=no)])
8243
8244         if test "$cf_cv_pointer_va_list" = no
8245         then
8246                 AC_CACHE_CHECK(if we can copy va_list indirectly, cf_cv_array_va_list,[
8247 AC_TRY_LINK([
8248 #include <stdarg.h>
8249 ],[
8250         va_list dst;
8251         va_list src;
8252         *dst = *src],
8253                         cf_cv_array_va_list=yes,
8254                         cf_cv_array_va_list=no)])
8255                 test "$cf_cv_array_va_list" = yes && AC_DEFINE(ARRAY_VA_LIST,1,[Define to 1 if we can copy va_list indirectly])
8256         fi
8257         ;;
8258 esac
8259 ])
8260 dnl ---------------------------------------------------------------------------
8261 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
8262 dnl ----------
8263 dnl Use AC_VERBOSE w/o the warnings
8264 AC_DEFUN([CF_VERBOSE],
8265 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
8266 CF_MSG_LOG([$1])
8267 ])dnl
8268 dnl ---------------------------------------------------------------------------
8269 dnl CF_VERSION_INFO version: 8 updated: 2021/01/01 13:31:04
8270 dnl ---------------
8271 dnl Define several useful symbols derived from the VERSION file.  A separate
8272 dnl file is preferred to embedding the version numbers in various scripts.
8273 dnl (automake is a textbook-example of why the latter is a bad idea, but there
8274 dnl are others).
8275 dnl
8276 dnl The file contents are:
8277 dnl     libtool-version release-version patch-version
8278 dnl or
8279 dnl     release-version
8280 dnl where
8281 dnl     libtool-version (see ?) consists of 3 integers separated by '.'
8282 dnl     release-version consists of a major version and minor version
8283 dnl             separated by '.', optionally followed by a patch-version
8284 dnl             separated by '-'.  The minor version need not be an
8285 dnl             integer (but it is preferred).
8286 dnl     patch-version is an integer in the form yyyymmdd, so ifdef's and
8287 dnl             scripts can easily compare versions.
8288 dnl
8289 dnl If libtool is used, the first form is required, since CF_WITH_LIBTOOL
8290 dnl simply extracts the first field using 'cut -f1'.
8291 dnl
8292 dnl Optional parameters:
8293 dnl $1 = internal name for package
8294 dnl $2 = external name for package
8295 AC_DEFUN([CF_VERSION_INFO],
8296 [
8297 if test -f "$srcdir/VERSION" ; then
8298         AC_MSG_CHECKING(for package version)
8299
8300         # if there are not enough fields, cut returns the last one...
8301         cf_field1=`sed -e '2,$d' "$srcdir/VERSION" |cut -f1`
8302         cf_field2=`sed -e '2,$d' "$srcdir/VERSION" |cut -f2`
8303         cf_field3=`sed -e '2,$d' "$srcdir/VERSION" |cut -f3`
8304
8305         # this is how CF_BUNDLED_INTL uses $VERSION:
8306         VERSION="$cf_field1"
8307
8308         VERSION_MAJOR=`echo "$cf_field2" | sed -e 's/\..*//'`
8309         test -z "$VERSION_MAJOR" && AC_MSG_ERROR(missing major-version)
8310
8311         VERSION_MINOR=`echo "$cf_field2" | sed -e 's/^[[^.]]*\.//' -e 's/-.*//'`
8312         test -z "$VERSION_MINOR" && AC_MSG_ERROR(missing minor-version)
8313
8314         AC_MSG_RESULT(${VERSION_MAJOR}.${VERSION_MINOR})
8315
8316         AC_MSG_CHECKING(for package patch date)
8317         VERSION_PATCH=`echo "$cf_field3" | sed -e 's/^[[^-]]*-//'`
8318         case .$VERSION_PATCH in
8319         (.)
8320                 AC_MSG_ERROR(missing patch-date $VERSION_PATCH)
8321                 ;;
8322         (.[[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]])
8323                 ;;
8324         (*)
8325                 AC_MSG_ERROR(illegal patch-date $VERSION_PATCH)
8326                 ;;
8327         esac
8328         AC_MSG_RESULT($VERSION_PATCH)
8329 else
8330         AC_MSG_ERROR(did not find $srcdir/VERSION)
8331 fi
8332
8333 # show the actual data that we have for versions:
8334 CF_VERBOSE(ABI VERSION $VERSION)
8335 CF_VERBOSE(VERSION_MAJOR $VERSION_MAJOR)
8336 CF_VERBOSE(VERSION_MINOR $VERSION_MINOR)
8337 CF_VERBOSE(VERSION_PATCH $VERSION_PATCH)
8338
8339 AC_SUBST(VERSION)
8340 AC_SUBST(VERSION_MAJOR)
8341 AC_SUBST(VERSION_MINOR)
8342 AC_SUBST(VERSION_PATCH)
8343
8344 dnl if a package name is given, define its corresponding version info.  We
8345 dnl need the package name to ensure that the defined symbols are unique.
8346 ifelse($1,,,[
8347         cf_PACKAGE=$1
8348         PACKAGE=ifelse($2,,$1,$2)
8349         AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",[Define to the package-name])
8350         AC_SUBST(PACKAGE)
8351         CF_UPPER(cf_PACKAGE,$cf_PACKAGE)
8352         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_VERSION,"${VERSION_MAJOR}.${VERSION_MINOR}")
8353         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_PATCHDATE,${VERSION_PATCH})
8354 ])
8355 ])dnl
8356 dnl ---------------------------------------------------------------------------
8357 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
8358 dnl -------------
8359 dnl Check if type wide-character type $1 is declared, and if so, which header
8360 dnl file is needed.  The second parameter is used to set a shell variable when
8361 dnl the type is not found.  The first parameter sets a shell variable for the
8362 dnl opposite sense.
8363 AC_DEFUN([CF_WCHAR_TYPE],
8364 [
8365 # This is needed on Tru64 5.0 to declare $1
8366 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
8367 AC_TRY_COMPILE([
8368 #include <stdlib.h>
8369 #include <stdarg.h>
8370 #include <stdio.h>
8371 #ifdef HAVE_LIBUTF8_H
8372 #include <libutf8.h>
8373 #endif],
8374         [$1 state],
8375         [cf_cv_$1=no],
8376         [AC_TRY_COMPILE([
8377 #include <stdlib.h>
8378 #include <stdarg.h>
8379 #include <stdio.h>
8380 #include <wchar.h>
8381 #ifdef HAVE_LIBUTF8_H
8382 #include <libutf8.h>
8383 #endif],
8384         [$1 value],
8385         [cf_cv_$1=yes],
8386         [cf_cv_$1=unknown])])])
8387
8388 if test "$cf_cv_$1" = yes ; then
8389         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
8390         NEED_WCHAR_H=1
8391 fi
8392
8393 ifelse([$2],,,[
8394 # if we do not find $1 in either place, use substitution to provide a fallback.
8395 if test "$cf_cv_$1" = unknown ; then
8396         $2=1
8397 fi
8398 ])
8399 ifelse($3,,,[
8400 # if we find $1 in either place, use substitution to provide a fallback.
8401 if test "$cf_cv_$1" != unknown ; then
8402         $3=1
8403 fi
8404 ])
8405 ])dnl
8406 dnl ---------------------------------------------------------------------------
8407 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
8408 dnl ---------------
8409 dnl Check for compiler-support for weak symbols.
8410 dnl This works with "recent" gcc.
8411 AC_DEFUN([CF_WEAK_SYMBOLS],[
8412 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
8413
8414 AC_TRY_COMPILE([
8415 #include <stdio.h>],
8416 [
8417 #if defined(__GNUC__)
8418 #  if defined __USE_ISOC99
8419 #    define _cat_pragma(exp)    _Pragma(#exp)
8420 #    define _weak_pragma(exp)   _cat_pragma(weak name)
8421 #  else
8422 #    define _weak_pragma(exp)
8423 #  endif
8424 #  define _declare(name)        __extension__ extern __typeof__(name) name
8425 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
8426 #endif
8427
8428 weak_symbol(fopen);
8429 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
8430 ])
8431 ])dnl
8432 dnl ---------------------------------------------------------------------------
8433 dnl CF_WITH_ABI_VERSION version: 4 updated: 2021/01/01 13:31:04
8434 dnl -------------------
8435 dnl Allow library's ABI to be overridden.  Generally this happens when a
8436 dnl packager has incremented the ABI past that used in the original package,
8437 dnl and wishes to keep doing this.
8438 dnl
8439 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
8440 dnl symbol.
8441 AC_DEFUN([CF_WITH_ABI_VERSION],[
8442 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
8443 AC_ARG_WITH(abi-version,
8444 [  --with-abi-version=XXX  override derived ABI version],[
8445         if test "x$cf_cv_abi_version" != "x$withval"
8446         then
8447                 AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
8448                 case "$cf_cv_rel_version" in
8449                 (5.*)
8450                         cf_cv_rel_version=$withval.0
8451                         ;;
8452                 (6.*)
8453                         cf_cv_rel_version=$withval.9    # FIXME: should be 10 as of 6.0 release
8454                         ;;
8455                 esac
8456         fi
8457         cf_cv_abi_version=$withval])
8458         CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
8459 ifelse($1,,,[
8460 $1_ABI=$cf_cv_abi_version
8461 ])
8462 ])dnl
8463 dnl ---------------------------------------------------------------------------
8464 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
8465 dnl --------------------
8466 dnl Command-line option to specify the Ada95 compiler.
8467 AC_DEFUN([CF_WITH_ADA_COMPILER],[
8468 AC_MSG_CHECKING(for ada-compiler)
8469 AC_ARG_WITH(ada-compiler,
8470         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
8471         [cf_ada_compiler=$withval],
8472         [cf_ada_compiler=gnatmake])
8473 AC_SUBST(cf_ada_compiler)
8474 AC_MSG_RESULT($cf_ada_compiler)
8475 ])dnl
8476 dnl ---------------------------------------------------------------------------
8477 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
8478 dnl -------------------
8479 dnl Command-line option to specify where Ada includes will install.
8480 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
8481 AC_MSG_CHECKING(for ada-include)
8482 CF_WITH_PATH(ada-include,
8483    [  --with-ada-include=DIR  Ada includes are in DIR],
8484    ADA_INCLUDE,
8485    PREFIX/share/ada/adainclude,
8486    [$]prefix/share/ada/adainclude)
8487 AC_SUBST(ADA_INCLUDE)
8488 AC_MSG_RESULT($ADA_INCLUDE)
8489 ])dnl
8490 dnl ---------------------------------------------------------------------------
8491 dnl CF_WITH_ADA_LIBNAME version: 1 updated: 2019/09/07 18:59:41
8492 dnl -------------------
8493 dnl CF_WITH_ADA_LIBNAME
8494 dnl -------------------
8495 dnl Command-line option to specify how to name the resulting Ada library.
8496 dnl $1 = default value
8497 AC_DEFUN([CF_WITH_ADA_LIBNAME],[
8498 AC_MSG_CHECKING(for ada-libname)
8499 AC_ARG_WITH(ada-libname,
8500    [  --with-ada-libname=XXX  override default Ada library-name],
8501    ADA_LIBNAME=[$]withval,
8502    ADA_LIBNAME=$1)
8503 case "x$ADA_LIBNAME" in
8504 (x|xyes|xno)
8505         ADA_LIBNAME=$1
8506         ;;
8507 esac
8508 AC_SUBST(ADA_LIBNAME)
8509 AC_MSG_RESULT($ADA_LIBNAME)
8510 ])dnl
8511 dnl ---------------------------------------------------------------------------
8512 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
8513 dnl -------------------
8514 dnl Command-line option to specify where Ada objects will install.
8515 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
8516 AC_MSG_CHECKING(for ada-objects)
8517 CF_WITH_PATH(ada-objects,
8518    [  --with-ada-objects=DIR  Ada objects are in DIR],
8519    ADA_OBJECTS,
8520    PREFIX/lib/ada/adalib,
8521    [$]prefix/lib/ada/adalib)
8522 AC_SUBST(ADA_OBJECTS)
8523 AC_MSG_RESULT($ADA_OBJECTS)
8524 ])dnl
8525 dnl ---------------------------------------------------------------------------
8526 dnl CF_WITH_ADA_SHAREDLIB version: 5 updated: 2018/07/21 19:10:35
8527 dnl ---------------------
8528 dnl Command-line option to specify if an Ada95 shared-library should be built,
8529 dnl and optionally what its soname should be.
8530 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
8531 AC_REQUIRE([CF_GNAT_PROJECTS])
8532 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
8533 AC_ARG_WITH(ada-sharedlib,
8534         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
8535         [with_ada_sharedlib=$withval],
8536         [with_ada_sharedlib=no])
8537 AC_MSG_RESULT($with_ada_sharedlib)
8538
8539 if test "x$with_ada_sharedlib" != xno
8540 then
8541         if test "x$cf_gnat_projects" != xyes
8542         then
8543                 AC_MSG_WARN(disabling shared-library since GNAT projects are not supported)
8544                 with_ada_sharedlib=no
8545         fi
8546 fi
8547
8548 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
8549 MAKE_ADA_SHAREDLIB="#"
8550
8551 if test "x$with_ada_sharedlib" != xno
8552 then
8553         MAKE_ADA_SHAREDLIB=
8554         if test "x$with_ada_sharedlib" != xyes
8555         then
8556                 ADA_SHAREDLIB="$with_ada_sharedlib"
8557         fi
8558 fi
8559
8560 AC_SUBST(ADA_SHAREDLIB)
8561 AC_SUBST(MAKE_ADA_SHAREDLIB)
8562 ])dnl
8563 dnl ---------------------------------------------------------------------------
8564 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
8565 dnl ----------------
8566 dnl Configure-option for dbmalloc.  The optional parameter is used to override
8567 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
8568 AC_DEFUN([CF_WITH_DBMALLOC],[
8569 CF_NO_LEAKS_OPTION(dbmalloc,
8570         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
8571         [USE_DBMALLOC])
8572
8573 if test "$with_dbmalloc" = yes ; then
8574         AC_CHECK_HEADER(dbmalloc.h,
8575                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
8576 fi
8577 ])dnl
8578 dnl ---------------------------------------------------------------------------
8579 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
8580 dnl ---------------
8581 dnl Configure-option for dmalloc.  The optional parameter is used to override
8582 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
8583 AC_DEFUN([CF_WITH_DMALLOC],[
8584 CF_NO_LEAKS_OPTION(dmalloc,
8585         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
8586         [USE_DMALLOC])
8587
8588 if test "$with_dmalloc" = yes ; then
8589         AC_CHECK_HEADER(dmalloc.h,
8590                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
8591 fi
8592 ])dnl
8593 dnl ---------------------------------------------------------------------------
8594 dnl CF_WITH_EXPORT_SYMS version: 3 updated: 2014/12/20 19:16:08
8595 dnl -------------------
8596 dnl Use this with libtool to specify the list of symbols that may be exported.
8597 dnl The input file contains one symbol per line; comments work with "#".
8598 dnl
8599 dnl $1 = basename of the ".sym" file (default $PACKAGE)
8600 AC_DEFUN([CF_WITH_EXPORT_SYMS],
8601 [
8602 AC_MSG_CHECKING(if exported-symbols file should be used)
8603 AC_ARG_WITH(export-syms,
8604         [  --with-export-syms=XXX  limit exported symbols using libtool],
8605         [with_export_syms=$withval],
8606         [with_export_syms=no])
8607 if test "x$with_export_syms" = xyes
8608 then
8609         with_export_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).sym'
8610         AC_SUBST(PACKAGE)
8611 fi
8612 AC_MSG_RESULT($with_export_syms)
8613 if test "x$with_export_syms" != xno
8614 then
8615         EXPORT_SYMS="-export-symbols $with_export_syms"
8616         AC_SUBST(EXPORT_SYMS)
8617 fi
8618 ])dnl
8619 dnl ---------------------------------------------------------------------------
8620 dnl CF_WITH_GPM version: 10 updated: 2017/04/29 18:32:18
8621 dnl -----------
8622 dnl
8623 dnl The option parameter (if neither yes/no) is assumed to be the name of
8624 dnl the gpm library, e.g., for dynamic loading.
8625 AC_DEFUN([CF_WITH_GPM],
8626 [
8627 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
8628 AC_ARG_WITH(gpm,
8629         [  --with-gpm              use Alessandro Rubini's GPM library],
8630         [with_gpm=$withval],
8631         [with_gpm=maybe])
8632 AC_MSG_RESULT($with_gpm)
8633
8634 if test "$with_gpm" != no ; then
8635         AC_CHECK_HEADER(gpm.h,[
8636                 AC_DEFINE(HAVE_GPM_H,1,[Define to 1 if we have gpm.h header])
8637                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
8638                         CF_VERBOSE(assuming we really have GPM library)
8639                         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
8640                         with_gpm=yes
8641                 else
8642                         AC_CHECK_LIB(gpm,Gpm_Open,[with_gpm=yes],[
8643                                 if test "$with_gpm" = maybe; then
8644                                         AC_MSG_WARN(Cannot link with GPM library)
8645                                         with_gpm=no
8646                                 else
8647                                         AC_MSG_ERROR(Cannot link with GPM library)
8648                                 fi
8649                         ])
8650                 fi
8651         ],[
8652                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
8653                 with_gpm=no
8654         ])
8655 fi
8656 ])
8657 dnl ---------------------------------------------------------------------------
8658 dnl CF_WITH_LIBTOOL version: 36 updated: 2021/01/01 13:31:04
8659 dnl ---------------
8660 dnl Provide a configure option to incorporate libtool.  Define several useful
8661 dnl symbols for the makefile rules.
8662 dnl
8663 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
8664 dnl macros from libtool.m4 which is in the aclocal directory of automake.
8665 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
8666 dnl But that still does not work properly since the macro is expanded outside
8667 dnl the CF_WITH_LIBTOOL macro:
8668 dnl
8669 dnl     #!/bin/sh
8670 dnl     ACLOCAL=`aclocal --print-ac-dir`
8671 dnl     if test -z "$ACLOCAL" ; then
8672 dnl             echo cannot find aclocal directory
8673 dnl             exit 1
8674 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
8675 dnl             echo cannot find libtool.m4 file
8676 dnl             exit 1
8677 dnl     fi
8678 dnl
8679 dnl     LOCAL=aclocal.m4
8680 dnl     ORIG=aclocal.m4.orig
8681 dnl
8682 dnl     trap "mv $ORIG $LOCAL" 0 1 2 3 15
8683 dnl     rm -f $ORIG
8684 dnl     mv $LOCAL $ORIG
8685 dnl
8686 dnl     # sed the LIBTOOL= assignment to omit the current directory?
8687 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
8688 dnl     cat $ORIG >>$LOCAL
8689 dnl
8690 dnl     autoconf-257 $*
8691 dnl
8692 AC_DEFUN([CF_WITH_LIBTOOL],
8693 [
8694 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
8695 ifdef([AC_PROG_LIBTOOL],,[
8696 LIBTOOL=
8697 ])
8698 # common library maintenance symbols that are convenient for libtool scripts:
8699 LIB_CREATE='${AR} -cr'
8700 LIB_OBJECT='${OBJECTS}'
8701 LIB_SUFFIX=.a
8702 LIB_PREP="$RANLIB"
8703
8704 # symbols used to prop libtool up to enable it to determine what it should be
8705 # doing:
8706 LIB_CLEAN=
8707 LIB_COMPILE=
8708 LIB_LINK='${CC}'
8709 LIB_INSTALL=
8710 LIB_UNINSTALL=
8711
8712 AC_MSG_CHECKING(if you want to build libraries with libtool)
8713 AC_ARG_WITH(libtool,
8714         [  --with-libtool          generate libraries with libtool],
8715         [with_libtool=$withval],
8716         [with_libtool=no])
8717 AC_MSG_RESULT($with_libtool)
8718 if test "$with_libtool" != "no"; then
8719 ifdef([AC_PROG_LIBTOOL],[
8720         # missing_content_AC_PROG_LIBTOOL{{
8721         AC_PROG_LIBTOOL
8722         # missing_content_AC_PROG_LIBTOOL}}
8723 ],[
8724         if test "$with_libtool" != "yes" ; then
8725                 CF_PATH_SYNTAX(with_libtool)
8726                 LIBTOOL=$with_libtool
8727         else
8728                 AC_CHECK_TOOLS(LIBTOOL,[libtool glibtool],none)
8729                 CF_LIBTOOL_VERSION
8730                 if test -z "$cf_cv_libtool_version" && test "$LIBTOOL" = libtool
8731                 then
8732                         CF_FORGET_TOOL(LIBTOOL)
8733                         AC_CHECK_TOOLS(LIBTOOL,[glibtool],none)
8734                         CF_LIBTOOL_VERSION
8735                 fi
8736         fi
8737         if test -z "$LIBTOOL" ; then
8738                 AC_MSG_ERROR(Cannot find libtool)
8739         fi
8740 ])dnl
8741         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${libdir} ${LIBTOOL_VERSION} `cut -f1 ${top_srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
8742         LIB_OBJECT='${OBJECTS:.o=.lo}'
8743         LIB_SUFFIX=.la
8744         LIB_CLEAN='${LIBTOOL} --mode=clean'
8745         LIB_COMPILE='${LIBTOOL} --mode=compile'
8746         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
8747         LIB_INSTALL='${LIBTOOL} --mode=install'
8748         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
8749         LIB_PREP=:
8750
8751         CF_CHECK_LIBTOOL_VERSION
8752
8753         # special hack to add -no-undefined (which libtool should do for itself)
8754         LT_UNDEF=
8755         case "$cf_cv_system_name" in
8756         (cygwin*|msys*|mingw32*|os2*|uwin*|aix[[4-7]])
8757                 LT_UNDEF=-no-undefined
8758                 ;;
8759         esac
8760         AC_SUBST([LT_UNDEF])
8761
8762         # special hack to add --tag option for C++ compiler
8763         case "$cf_cv_libtool_version" in
8764         (1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*)
8765                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
8766                 LIBTOOL="$LIBTOOL --tag=CC"
8767                 ;;
8768         (*)
8769                 LIBTOOL_CXX="$LIBTOOL"
8770                 ;;
8771         esac
8772 else
8773         LIBTOOL=""
8774         LIBTOOL_CXX=""
8775 fi
8776
8777 test -z "$LIBTOOL" && ECHO_LT=
8778
8779 AC_SUBST(LIBTOOL)
8780 AC_SUBST(LIBTOOL_CXX)
8781 AC_SUBST(LIBTOOL_OPTS)
8782
8783 AC_SUBST(LIB_CREATE)
8784 AC_SUBST(LIB_OBJECT)
8785 AC_SUBST(LIB_SUFFIX)
8786 AC_SUBST(LIB_PREP)
8787
8788 AC_SUBST(LIB_CLEAN)
8789 AC_SUBST(LIB_COMPILE)
8790 AC_SUBST(LIB_LINK)
8791 AC_SUBST(LIB_INSTALL)
8792 AC_SUBST(LIB_UNINSTALL)
8793
8794 ])dnl
8795 dnl ---------------------------------------------------------------------------
8796 dnl CF_WITH_LIBTOOL_OPTS version: 4 updated: 2015/04/17 21:13:04
8797 dnl --------------------
8798 dnl Allow user to pass additional libtool options into the library creation
8799 dnl and link steps.  The main use for this is to do something like
8800 dnl     ./configure --with-libtool-opts=-static
8801 dnl to get the same behavior as automake-flavored
8802 dnl     ./configure --enable-static
8803 AC_DEFUN([CF_WITH_LIBTOOL_OPTS],[
8804 AC_MSG_CHECKING(for additional libtool options)
8805 AC_ARG_WITH(libtool-opts,
8806         [  --with-libtool-opts=XXX specify additional libtool options],
8807         [with_libtool_opts=$withval],
8808         [with_libtool_opts=no])
8809 AC_MSG_RESULT($with_libtool_opts)
8810
8811 case .$with_libtool_opts in
8812 (.yes|.no|.)
8813         ;;
8814 (*)
8815         LIBTOOL_OPTS="$LIBTOOL_OPTS $with_libtool_opts"
8816         ;;
8817 esac
8818
8819 AC_SUBST(LIBTOOL_OPTS)
8820 ])dnl
8821 dnl ---------------------------------------------------------------------------
8822 dnl CF_WITH_LIB_BASENAME version: 1 updated: 2020/03/07 20:05:14
8823 dnl --------------------
8824 dnl Allow for overriding the basename of a library, i.e., the part to which
8825 dnl prefixes/suffixes are attached.
8826 dnl
8827 dnl $1 = variable to set
8828 dnl $2 = option name
8829 dnl $3 = default basename for library, if omitted use $2
8830 AC_DEFUN([CF_WITH_LIB_BASENAME],
8831 [
8832 AC_MSG_CHECKING(for desired basename for $2 library)
8833 AC_ARG_WITH($2-libname,
8834         [  --with-$2-libname=XXX override ifelse($3,,$2,$3) basename of library],
8835         [with_lib_basename=$withval],
8836         [with_lib_basename=ifelse($3,,$2,$3)])
8837 $1="$with_lib_basename"
8838
8839 case "x[$]$1" in
8840 (x|xno|xnone|xyes)
8841         $1=ifelse($3,,$2,$3)
8842         ;;
8843 (*)
8844         ;;
8845 esac
8846
8847 AC_MSG_RESULT([$]$1)
8848 AC_SUBST($1)
8849 ])dnl
8850 dnl ---------------------------------------------------------------------------
8851 dnl CF_WITH_LIB_PREFIX version: 2 updated: 2021/01/01 16:53:59
8852 dnl ------------------
8853 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
8854 dnl "lib" prefix, e.g., because it used the dll naming convention.
8855 dnl
8856 dnl $1 = variable to set
8857 AC_DEFUN([CF_WITH_LIB_PREFIX],
8858 [
8859 AC_MSG_CHECKING(if you want to have a library-prefix)
8860 AC_ARG_WITH(lib-prefix,
8861         [  --with-lib-prefix       override library-prefix],
8862         [with_lib_prefix=$withval],
8863         [with_lib_prefix=auto])
8864 AC_MSG_RESULT($with_lib_prefix)
8865
8866 if test "$with_lib_prefix" = auto
8867 then
8868         CF_LIB_PREFIX($1)
8869 elif test "$with_lib_prefix" = no
8870 then
8871         LIB_PREFIX=
8872 else
8873         LIB_PREFIX=$with_lib_prefix
8874 fi
8875 ])dnl
8876 dnl ---------------------------------------------------------------------------
8877 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
8878 dnl ------------
8879 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
8880 dnl defaulting to yes/no.
8881 dnl
8882 dnl $1 = option name
8883 dnl $2 = help-text
8884 dnl $3 = environment variable to set
8885 dnl $4 = default value, shown in the help-message, must be a constant
8886 dnl $5 = default value, if it's an expression & cannot be in the help-message
8887 dnl
8888 AC_DEFUN([CF_WITH_PATH],
8889 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
8890 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
8891 if ifelse([$5],,true,[test -n "$5"]) ; then
8892 CF_PATH_SYNTAX(withval)
8893 fi
8894 eval $3="$withval"
8895 AC_SUBST($3)dnl
8896 ])dnl
8897 dnl ---------------------------------------------------------------------------
8898 dnl CF_WITH_PATHLIST version: 12 updated: 2021/01/01 13:31:04
8899 dnl ----------------
8900 dnl Process an option specifying a list of colon-separated paths.
8901 dnl
8902 dnl $1 = option name
8903 dnl $2 = help-text
8904 dnl $3 = environment variable to set
8905 dnl $4 = default value, shown in the help-message, must be a constant
8906 dnl $5 = default value, if it's an expression & cannot be in the help-message
8907 dnl $6 = flag to tell if we want to define or substitute
8908 dnl
8909 AC_DEFUN([CF_WITH_PATHLIST],[
8910 AC_REQUIRE([CF_PATHSEP])
8911 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
8912 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
8913
8914 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
8915 cf_dst_path=
8916 for cf_src_path in $withval
8917 do
8918   CF_PATH_SYNTAX(cf_src_path)
8919   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}$PATH_SEPARATOR"
8920   cf_dst_path="${cf_dst_path}${cf_src_path}"
8921 done
8922 IFS="$ac_save_ifs"
8923
8924 ifelse($6,define,[
8925 # Strip single quotes from the value, e.g., when it was supplied as a literal
8926 # for $4 or $5.
8927 case "$cf_dst_path" in
8928 (\'*)
8929   cf_dst_path="`echo "$cf_dst_path" |sed -e s/\'// -e s/\'\$//`"
8930   ;;
8931 esac
8932 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
8933 ])
8934
8935 # This may use the prefix/exec_prefix symbols which will only yield "NONE"
8936 # so we have to check/work around.  We do prefer the result of "eval"...
8937 eval cf_dst_eval="$cf_dst_path"
8938 case "x$cf_dst_eval" in
8939 (xNONE*)
8940         $3=$cf_dst_path
8941         ;;
8942 (*)
8943         $3="$cf_dst_eval"
8944         ;;
8945 esac
8946 AC_SUBST($3)dnl
8947
8948 ])dnl
8949 dnl ---------------------------------------------------------------------------
8950 dnl CF_WITH_PATH_PROG version: 1 updated: 2019/06/30 19:44:43
8951 dnl -----------------
8952 dnl Check for a given program, like CF_PATH_PROG, but allow override using a
8953 dnl "--with-xxx" option.
8954 dnl
8955 dnl Parameters:
8956 dnl             $1 = environment variable to set/update
8957 dnl             $2 = program name
8958 dnl             $3 = help-text
8959 dnl             $4 = $PATH
8960 AC_DEFUN([CF_WITH_PATH_PROG],[
8961 AC_ARG_WITH($2-path,
8962         [  --with-$2-path=XXX     specify path of $2 ifelse($3,,,$3)],
8963         [AC_MSG_CHECKING(for $2 program ifelse($3,,,$3))
8964                 $1=$withval
8965                 AC_MSG_RESULT([$]$1)
8966                 CF_PATH_SYNTAX($1)
8967         ],
8968         [CF_PATH_PROG($1,$2,,ifelse($4,,,$4))
8969                 if test -z "[$]$1"
8970                 then
8971                         AC_MSG_WARN(no $2 program found ifelse($3,,,$3))
8972                 fi
8973         ])
8974 ])
8975 dnl ---------------------------------------------------------------------------
8976 dnl CF_WITH_PCRE2 version: 5 updated: 2021/01/26 18:45:12
8977 dnl -------------
8978 dnl Add PCRE2 (Perl-compatible regular expressions v2) to the build if it is
8979 dnl available and the user requests it.  Assume the application will otherwise
8980 dnl use the POSIX interface.
8981 dnl
8982 dnl TODO allow $withval to specify package location
8983 AC_DEFUN([CF_WITH_PCRE2],
8984 [
8985 AC_REQUIRE([CF_PKG_CONFIG])
8986
8987 AC_MSG_CHECKING(if you want to use PCRE2 for regular-expressions)
8988 AC_ARG_WITH(pcre2,
8989         [  --with-pcre2            use PCRE2 for regular-expressions])
8990 test -z "$with_pcre2" && with_pcre2=no
8991 AC_MSG_RESULT($with_pcre2)
8992
8993 if test "x$with_pcre2" != xno ; then
8994         cf_with_pcre2_ok=no
8995         for cf_with_pcre2 in libpcre2 libpcre2-posix libpcre
8996         do
8997                 CF_TRY_PKG_CONFIG($cf_with_pcre2,[cf_with_pcre2_ok=yes; break])
8998         done
8999         cf_with_pcre2_ok=yes || AC_MSG_ERROR(Cannot find PCRE2 library)
9000
9001         AC_DEFINE(HAVE_LIB_PCRE2,1,[Define to 1 if we can/should compile with the PCRE2 library])
9002
9003         # if pkgconfig gave no results, look for the libraries directly
9004         case "$LIBS" in
9005         (*pcre2-posix*|*pcreposix*)
9006                 ;;
9007         (*)
9008                 AC_CHECK_LIB(pcre2-posix,regcomp,[
9009                         CF_ADD_LIB(pcre2-posix)],
9010                         [AC_CHECK_LIB(pcreposix,regcomp,[
9011                          CF_ADD_LIB(pcreposix)
9012                         ],[AC_MSG_ERROR(Cannot find PCRE2 POSIX library)])])
9013                 ;;
9014         esac
9015
9016         # either way, check for the library header files
9017         AC_CHECK_HEADERS(pcre2posix.h pcreposix.h)
9018 fi
9019 ])dnl
9020 dnl ---------------------------------------------------------------------------
9021 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 11 updated: 2021/01/01 16:16:30
9022 dnl -------------------------
9023 dnl Allow the choice of the pkg-config library directory to be overridden.
9024 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
9025
9026 case "$PKG_CONFIG" in
9027 (no|none|yes)
9028         AC_MSG_CHECKING(for pkg-config library directory)
9029         ;;
9030 (*)
9031         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
9032         ;;
9033 esac
9034
9035 PKG_CONFIG_LIBDIR=no
9036 AC_ARG_WITH(pkg-config-libdir,
9037         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
9038         [PKG_CONFIG_LIBDIR=$withval],
9039         [test "x$PKG_CONFIG" != xnone && PKG_CONFIG_LIBDIR=yes])
9040
9041 case x$PKG_CONFIG_LIBDIR in
9042 (x/*)
9043         ;;
9044 (xyes)
9045         # Look for the library directory using the same prefix as the executable
9046         if test "x$PKG_CONFIG" = xnone
9047         then
9048                 cf_path=$prefix
9049         else
9050                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
9051         fi
9052
9053         # If you don't like using the default architecture, you have to specify the
9054         # intended library directory and corresponding compiler/linker options.
9055         #
9056         # This case allows for Debian's 2014-flavor of multiarch, along with the
9057         # most common variations before that point.  Some other variants spell the
9058         # directory differently, e.g., "pkg-config", and put it in unusual places.
9059         # pkg-config has always been poorly standardized, which is ironic...
9060         case x`(arch) 2>/dev/null` in
9061         (*64)
9062                 cf_search_path="\
9063                         $cf_path/lib/*64-linux-gnu \
9064                         $cf_path/share \
9065                         $cf_path/lib64 \
9066                         $cf_path/lib32 \
9067                         $cf_path/lib"
9068                 ;;
9069         (*)
9070                 cf_search_path="\
9071                         $cf_path/lib/*-linux-gnu \
9072                         $cf_path/share \
9073                         $cf_path/lib32 \
9074                         $cf_path/lib \
9075                         $cf_path/libdata"
9076                 ;;
9077         esac
9078
9079         CF_VERBOSE(list...)
9080         for cf_config in $cf_search_path
9081         do
9082                 CF_VERBOSE(checking $cf_config/pkgconfig)
9083                 if test -d "$cf_config/pkgconfig"
9084                 then
9085                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
9086                         AC_MSG_CHECKING(done)
9087                         break
9088                 fi
9089         done
9090         ;;
9091 (*)
9092         ;;
9093 esac
9094
9095 if test "x$PKG_CONFIG_LIBDIR" != xno ; then
9096         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
9097 fi
9098
9099 AC_SUBST(PKG_CONFIG_LIBDIR)
9100 ])dnl
9101 dnl ---------------------------------------------------------------------------
9102 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
9103 dnl ---------------
9104 dnl Check for POSIX thread library.
9105 AC_DEFUN([CF_WITH_PTHREAD],
9106 [
9107 AC_MSG_CHECKING(if you want to link with the pthread library)
9108 AC_ARG_WITH(pthread,
9109         [  --with-pthread          use POSIX thread library],
9110         [with_pthread=$withval],
9111         [with_pthread=no])
9112 AC_MSG_RESULT($with_pthread)
9113
9114 if test "$with_pthread" != no ; then
9115         AC_CHECK_HEADER(pthread.h,[
9116         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
9117
9118         for cf_lib_pthread in pthread c_r
9119         do
9120             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
9121             cf_save_LIBS="$LIBS"
9122             CF_ADD_LIB($cf_lib_pthread)
9123             AC_TRY_LINK([
9124 #include <pthread.h>
9125 ],[
9126                 int rc = pthread_create(0,0,0,0);
9127                 int r2 = pthread_mutexattr_settype(0, 0);
9128 ],[with_pthread=yes],[with_pthread=no])
9129             LIBS="$cf_save_LIBS"
9130             AC_MSG_RESULT($with_pthread)
9131             test "$with_pthread" = yes && break
9132         done
9133
9134         if test "$with_pthread" = yes ; then
9135             CF_ADD_LIB($cf_lib_pthread)
9136             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
9137         else
9138             AC_MSG_ERROR(Cannot link with pthread library)
9139         fi
9140         ])
9141 fi
9142 ])
9143 dnl ---------------------------------------------------------------------------
9144 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
9145 dnl -------------------
9146 dnl Allow library's release-version to be overridden.  Generally this happens when a
9147 dnl packager has incremented the release-version past that used in the original package,
9148 dnl and wishes to keep doing this.
9149 dnl
9150 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
9151 dnl and {package}_MINOR symbols
9152 dnl symbol.
9153 AC_DEFUN([CF_WITH_REL_VERSION],[
9154 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
9155 AC_ARG_WITH(rel-version,
9156 [  --with-rel-version=XXX  override derived release version],
9157 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
9158  cf_cv_rel_version=$withval])
9159 ifelse($1,,[
9160  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
9161 ],[
9162  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
9163  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
9164  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
9165  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
9166 ])
9167 ])dnl
9168 dnl ---------------------------------------------------------------------------
9169 dnl CF_WITH_SYSMOUSE version: 3 updated: 2012/10/06 17:56:13
9170 dnl ----------------
9171 dnl If we can compile with sysmouse, make it available unless it is not wanted.
9172 AC_DEFUN([CF_WITH_SYSMOUSE],[
9173 # not everyone has "test -c"
9174 if test -c /dev/sysmouse 2>/dev/null ; then
9175 AC_MSG_CHECKING(if you want to use sysmouse)
9176 AC_ARG_WITH(sysmouse,
9177         [  --with-sysmouse         use sysmouse (FreeBSD console)],
9178         [cf_with_sysmouse=$withval],
9179         [cf_with_sysmouse=maybe])
9180         if test "$cf_with_sysmouse" != no ; then
9181         AC_TRY_COMPILE([
9182 #include <osreldate.h>
9183 #if (__FreeBSD_version >= 400017)
9184 #include <sys/consio.h>
9185 #include <sys/fbio.h>
9186 #else
9187 #include <machine/console.h>
9188 #endif
9189 ],[
9190         struct mouse_info the_mouse;
9191         ioctl(0, CONS_MOUSECTL, &the_mouse);
9192 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
9193         fi
9194 AC_MSG_RESULT($cf_with_sysmouse)
9195 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE,1,[Define to 1 if we can/should use the sysmouse interface])
9196 fi
9197 ])dnl
9198 dnl ---------------------------------------------------------------------------
9199 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
9200 dnl ---------------
9201 dnl For testing, override the derived host system-type which is used to decide
9202 dnl things such as the linker commands used to build shared libraries.  This is
9203 dnl normally chosen automatically based on the type of system which you are
9204 dnl building on.  We use it for testing the configure script.
9205 dnl
9206 dnl This is different from the --host option: it is used only for testing parts
9207 dnl of the configure script which would not be reachable with --host since that
9208 dnl relies on the build environment being real, rather than mocked up.
9209 AC_DEFUN([CF_WITH_SYSTYPE],[
9210 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
9211 AC_ARG_WITH(system-type,
9212         [  --with-system-type=XXX  test: override derived host system-type],
9213 [AC_MSG_WARN(overriding system type to $withval)
9214         cf_cv_system_name=$withval
9215         host_os=$withval
9216 ])
9217 ])dnl
9218 dnl ---------------------------------------------------------------------------
9219 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
9220 dnl ----------------
9221 AC_DEFUN([CF_WITH_VALGRIND],[
9222 CF_NO_LEAKS_OPTION(valgrind,
9223         [  --with-valgrind         test: use valgrind],
9224         [USE_VALGRIND])
9225 ])dnl
9226 dnl ---------------------------------------------------------------------------
9227 dnl CF_WITH_VERSIONED_SYMS version: 10 updated: 2021/01/04 18:48:01
9228 dnl ----------------------
9229 dnl Use this when building shared library with ELF, to markup symbols with the
9230 dnl version identifier from the given input file.  Generally that identifier is
9231 dnl the same as the SONAME at which the symbol was first introduced.
9232 dnl
9233 dnl $1 = basename of the ".map" file (default $PACKAGE)
9234 AC_DEFUN([CF_WITH_VERSIONED_SYMS],
9235 [AC_REQUIRE([AC_PROG_FGREP])dnl
9236 AC_REQUIRE([AC_PROG_EGREP])dnl
9237
9238 AC_MSG_CHECKING(if versioned-symbols file should be used)
9239 AC_ARG_WITH(versioned-syms,
9240         [  --with-versioned-syms=X markup versioned symbols using ld],
9241         [with_versioned_syms=$withval],
9242         [with_versioned_syms=no])
9243 case "x$with_versioned_syms" in
9244 (xyes)
9245         with_versioned_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).map'
9246         AC_SUBST(PACKAGE)
9247         ;;
9248 (xno)
9249         ;;
9250 (x/*)
9251         test -f "$with_versioned_syms" || AC_MSG_ERROR(expected a filename: $with_versioned_syms)
9252         ;;
9253 (*)
9254         test -f "$with_versioned_syms" || AC_MSG_ERROR(expected a filename: $with_versioned_syms)
9255         with_versioned_syms=`pwd`/"$with_versioned_syms"
9256         ;;
9257 esac
9258 AC_MSG_RESULT($with_versioned_syms)
9259
9260 RESULTING_SYMS=
9261 VERSIONED_SYMS=
9262 WILDCARD_SYMS=
9263
9264 if test "x$with_versioned_syms" != xno
9265 then
9266         RESULTING_SYMS=$with_versioned_syms
9267         case "x$MK_SHARED_LIB" in
9268         (*-Wl,*)
9269                 VERSIONED_SYMS="-Wl,--version-script,\${RESULTING_SYMS}"
9270                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-Wl,%\\[$]{VERSIONED_SYMS} -Wl,%"`
9271                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
9272                 ;;
9273         (*-dy\ *)
9274                 VERSIONED_SYMS="-Wl,-M,\${RESULTING_SYMS}"
9275                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-dy%\\[$]{VERSIONED_SYMS} -dy%"`
9276                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
9277                 ;;
9278         (*)
9279                 AC_MSG_WARN(this system does not support versioned-symbols)
9280                 ;;
9281         esac
9282
9283         # Linux ld can selectively override scope, e.g., of symbols beginning with
9284         # "_" by first declaring some as global, and then using a wildcard to
9285         # declare the others as local.  Some other loaders cannot do this.  Check
9286         # by constructing a (very) simple shared library and inspecting its
9287         # symbols.
9288         if test "x$VERSIONED_SYMS" != "x"
9289         then
9290                 AC_MSG_CHECKING(if wildcards can be used to selectively omit symbols)
9291                 WILDCARD_SYMS=no
9292
9293                 # make sources
9294                 rm -f conftest.*
9295
9296                 cat >conftest.ver <<EOF
9297 module_1.0 {
9298 global:
9299         globalf1;
9300 local:
9301         localf1;
9302 };
9303 module_2.0 {
9304 global:
9305         globalf2;
9306 local:
9307         localf2;
9308         _*;
9309 } module_1.0;
9310 submodule_1.0 {
9311 global:
9312         subglobalf1;
9313         _ismissing;
9314 local:
9315         sublocalf1;
9316 };
9317 submodule_2.0 {
9318 global:
9319         subglobalf2;
9320 local:
9321         sublocalf2;
9322         _*;
9323 } submodule_1.0;
9324 EOF
9325                 cat >conftest.$ac_ext <<EOF
9326 #line __oline__ "configure"
9327 int     _ismissing(void) { return 1; }
9328 int     _localf1(void) { return 1; }
9329 int     _localf2(void) { return 2; }
9330 int     globalf1(void) { return 1; }
9331 int     globalf2(void) { return 2; }
9332 int     _sublocalf1(void) { return 1; }
9333 int     _sublocalf2(void) { return 2; }
9334 int     subglobalf1(void) { return 1; }
9335 int     subglobalf2(void) { return 2; }
9336 EOF
9337                 cat >conftest.mk <<EOF
9338 CC=${CC}
9339 CFLAGS=${CFLAGS}
9340 CPPFLAGS=${CPPFLAGS}
9341 LDFLAGS=${LDFLAGS}
9342 LIBS=${LIBS}
9343 VERSIONED_SYMS=${VERSIONED_SYMS}
9344 RESULTING_SYMS=conftest.ver
9345 MK_SHARED_LIB=${MK_SHARED_LIB}
9346 conftest.so: conftest.$ac_cv_objext
9347                 \$(MK_SHARED_LIB) conftest.$ac_cv_objext
9348 EOF
9349
9350                 # compile source, make library
9351                 if make -f conftest.mk 2>&AC_FD_CC >/dev/null
9352                 then
9353                         # test for missing symbol in either Data or Text section
9354                         cf_missing="`nm -P conftest.so 2>&AC_FD_CC |${FGREP-fgrep} _ismissing | ${EGREP-egrep} '[[      ]][[DT]][[      ]]'`"
9355                         test -n "$cf_missing" && WILDCARD_SYMS=yes
9356                 fi
9357                 AC_MSG_RESULT($WILDCARD_SYMS)
9358                 rm -f conftest.*
9359         fi
9360 fi
9361 AC_SUBST(RESULTING_SYMS)
9362 AC_SUBST(VERSIONED_SYMS)
9363 AC_SUBST(WILDCARD_SYMS)
9364 ])dnl
9365 dnl ---------------------------------------------------------------------------
9366 dnl CF_WITH_X11_RGB version: 2 updated: 2019/12/31 08:53:54
9367 dnl ---------------
9368 dnl Handle configure option "--with-x11-rgb", setting these shell
9369 dnl variables:
9370 dnl
9371 dnl $RGB_PATH is the option value, used for finding the X11 rgb file.
9372 dnl $no_x11_rgb is a "#" (comment) if "--without-x11-rgb" is given.
9373 dnl
9374 dnl Most Linux's use this:
9375 dnl     /usr/share/X11/rgb.txt
9376 dnl Debian uses this:
9377 dnl     /etc/X11/rgb.txt
9378 dnl DragonFlyBSD ports uses this:
9379 dnl     /usr/pkg/lib/X11/rgb.txt
9380 dnl FreeBSD ports use these:
9381 dnl     /usr/local/lib/X11/rgb.txt
9382 dnl     /usr/local/share/X11/rgb.txt
9383 dnl Mandriva has these:
9384 dnl     /usr/lib/X11/rgb.txt
9385 dnl     /usr/lib64/X11/rgb.txt
9386 dnl NetBSD has these
9387 dnl     /usr/X11R7/lib/X11/rgb.txt
9388 dnl OpenSolaris uses
9389 dnl     32-bit:
9390 dnl     /usr/X11/etc/X11/rgb.txt
9391 dnl     /usr/X11/share/X11/rgb.txt
9392 dnl     /usr/X11/lib/X11/rgb.txt
9393 dnl OSX uses
9394 dnl             /opt/local/share/X11/rgb.txt (MacPorts)
9395 dnl             /opt/X11/share/X11/rgb.txt (non-ports)
9396 dnl     64-bit:
9397 dnl     /usr/X11/etc/X11/rgb.txt
9398 dnl     /usr/X11/share/X11/rgb.txt (perhaps)
9399 dnl     /usr/X11/lib/amd64/X11/rgb.txt
9400 dnl Solaris10 uses (in this order):
9401 dnl     /usr/openwin/lib/X11/rgb.txt
9402 dnl     /usr/X11/lib/X11/rgb.txt
9403 AC_DEFUN([CF_WITH_X11_RGB],[
9404 AC_MSG_CHECKING(for X11 rgb file)
9405 AC_ARG_WITH(x11-rgb,
9406         [  --with-x11-rgb=FILE   file containing X11 rgb information (EPREFIX/lib/X11/rgb.txt)],
9407         [RGB_PATH=$withval],
9408         [RGB_PATH=auto])
9409
9410 if test "x[$]RGB_PATH" = xauto
9411 then
9412         RGB_PATH='${exec_prefix}/lib/X11/rgb.txt'
9413         for cf_path in \
9414                 /opt/local/share/X11/rgb.txt \
9415                 /opt/X11/share/X11/rgb.txt \
9416                 /usr/share/X11/rgb.txt \
9417                 /usr/X11/share/X11/rgb.txt \
9418                 /usr/X11/lib/X11/rgb.txt \
9419                 /usr/lib/X11/rgb.txt \
9420                 /etc/X11/rgb.txt \
9421                 /usr/pkg/lib/X11/rgb.txt \
9422                 /usr/X11R7/lib/X11/rgb.txt \
9423                 /usr/X11R6/lib/X11/rgb.txt \
9424                 /usr/X11R5/lib/X11/rgb.txt \
9425                 /usr/X11R4/lib/X11/rgb.txt \
9426                 /usr/local/lib/X11/rgb.txt \
9427                 /usr/local/share/X11/rgb.txt \
9428                 /usr/lib64/X11/rgb.txt
9429         do
9430                 if test -f "$cf_path" ; then
9431                         RGB_PATH="$cf_path"
9432                         break
9433                 fi
9434         done
9435 else
9436         cf_path=$RGB_PATH
9437         CF_PATH_SYNTAX(cf_path)
9438 fi
9439
9440 AC_MSG_RESULT($RGB_PATH)
9441 AC_SUBST(RGB_PATH)
9442 AC_DEFINE_UNQUOTED(RGB_PATH,"$cf_path",[Define to the full pathname of rgb.txt])
9443
9444 no_x11_rgb=
9445 if test "$RGB_PATH" = no
9446 then
9447         no_x11_rgb="#"
9448 fi
9449 AC_SUBST(no_x11_rgb)
9450 ])dnl
9451 dnl ---------------------------------------------------------------------------
9452 dnl CF_XOPEN_SOURCE version: 58 updated: 2021/05/01 17:49:36
9453 dnl ---------------
9454 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
9455 dnl or adapt to the vendor's definitions to get equivalent functionality,
9456 dnl without losing the common non-POSIX features.
9457 dnl
9458 dnl Parameters:
9459 dnl     $1 is the nominal value for _XOPEN_SOURCE
9460 dnl     $2 is the nominal value for _POSIX_C_SOURCE
9461 AC_DEFUN([CF_XOPEN_SOURCE],[
9462 AC_REQUIRE([AC_CANONICAL_HOST])
9463 AC_REQUIRE([CF_POSIX_VISIBLE])
9464
9465 if test "$cf_cv_posix_visible" = no; then
9466
9467 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
9468 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
9469 cf_xopen_source=
9470
9471 case "$host_os" in
9472 (aix[[4-7]]*)
9473         cf_xopen_source="-D_ALL_SOURCE"
9474         ;;
9475 (msys)
9476         cf_XOPEN_SOURCE=600
9477         ;;
9478 (darwin[[0-8]].*)
9479         cf_xopen_source="-D_APPLE_C_SOURCE"
9480         ;;
9481 (darwin*)
9482         cf_xopen_source="-D_DARWIN_C_SOURCE"
9483         cf_XOPEN_SOURCE=
9484         ;;
9485 (freebsd*|dragonfly*|midnightbsd*)
9486         # 5.x headers associate
9487         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
9488         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
9489         cf_POSIX_C_SOURCE=200112L
9490         cf_XOPEN_SOURCE=600
9491         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
9492         ;;
9493 (hpux11*)
9494         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
9495         ;;
9496 (hpux*)
9497         cf_xopen_source="-D_HPUX_SOURCE"
9498         ;;
9499 (irix[[56]].*)
9500         cf_xopen_source="-D_SGI_SOURCE"
9501         cf_XOPEN_SOURCE=
9502         ;;
9503 (linux*|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin)
9504         CF_GNU_SOURCE($cf_XOPEN_SOURCE)
9505         ;;
9506 (minix*)
9507         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
9508         ;;
9509 (mirbsd*)
9510         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
9511         cf_XOPEN_SOURCE=
9512         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
9513         ;;
9514 (netbsd*)
9515         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
9516         ;;
9517 (openbsd[[6-9]]*)
9518         # OpenBSD 6.x has broken locale support, both compile-time and runtime.
9519         # see https://www.mail-archive.com/bugs@openbsd.org/msg13200.html
9520         # Abusing the conformance level is a workaround.
9521         AC_MSG_WARN(this system does not provide usable locale support)
9522         cf_xopen_source="-D_BSD_SOURCE"
9523         cf_XOPEN_SOURCE=700
9524         ;;
9525 (openbsd[[4-5]]*)
9526         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
9527         cf_xopen_source="-D_BSD_SOURCE"
9528         cf_XOPEN_SOURCE=600
9529         ;;
9530 (openbsd*)
9531         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
9532         ;;
9533 (osf[[45]]*)
9534         cf_xopen_source="-D_OSF_SOURCE"
9535         ;;
9536 (nto-qnx*)
9537         cf_xopen_source="-D_QNX_SOURCE"
9538         ;;
9539 (sco*)
9540         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
9541         ;;
9542 (solaris2.*)
9543         cf_xopen_source="-D__EXTENSIONS__"
9544         cf_cv_xopen_source=broken
9545         ;;
9546 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
9547         cf_XOPEN_SOURCE=
9548         cf_POSIX_C_SOURCE=
9549         ;;
9550 (*)
9551         CF_TRY_XOPEN_SOURCE
9552         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
9553         ;;
9554 esac
9555
9556 if test -n "$cf_xopen_source" ; then
9557         CF_ADD_CFLAGS($cf_xopen_source,true)
9558 fi
9559
9560 dnl In anything but the default case, we may have system-specific setting
9561 dnl which is still not guaranteed to provide all of the entrypoints that
9562 dnl _XOPEN_SOURCE would yield.
9563 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
9564         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
9565         AC_TRY_COMPILE([#include <stdlib.h>],[
9566 #ifndef _XOPEN_SOURCE
9567 make an error
9568 #endif],
9569         [cf_XOPEN_SOURCE_set=yes],
9570         [cf_XOPEN_SOURCE_set=no])
9571         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
9572         if test "$cf_XOPEN_SOURCE_set" = yes
9573         then
9574                 AC_TRY_COMPILE([#include <stdlib.h>],[
9575 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
9576 make an error
9577 #endif],
9578                 [cf_XOPEN_SOURCE_set_ok=yes],
9579                 [cf_XOPEN_SOURCE_set_ok=no])
9580                 if test "$cf_XOPEN_SOURCE_set_ok" = no
9581                 then
9582                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
9583                 fi
9584         else
9585                 CF_TRY_XOPEN_SOURCE
9586         fi
9587 fi
9588 fi # cf_cv_posix_visible
9589 ])
9590 dnl ---------------------------------------------------------------------------
9591 dnl CF__SED_TRIMBLANKS version: 1 updated: 2021/01/02 09:31:20
9592 dnl ------------------
9593 dnl Trim something using sed, then trim extra whitespace
9594 dnl $1 = extra parameters, e.g., in CF_STRIP_G_OPT
9595 define([CF__SED_TRIMBLANKS],[sed ifelse($1,,,[$1] )-e 's%[[     ]]% %g' -e 's% [[ ]]*% %g' -e 's%^ %%' -e 's% [$]%%'])dnl