aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2016,2017 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: aclocal.m4,v 1.804 2017/01/21 16:13:56 tom Exp $
  32 dnl Macros used in NCURSES auto-configuration script.
  33 dnl
  34 dnl These macros are maintained separately from NCURSES.  The copyright on
  35 dnl this file applies to the aggregation of macros and does not affect use of
  36 dnl these macros in other applications.
  37 dnl
  38 dnl See http://invisible-island.net/autoconf/ for additional information.
  39 dnl
  40 dnl ---------------------------------------------------------------------------
  41 dnl ---------------------------------------------------------------------------
  42 dnl AM_LANGINFO_CODESET version: 4 updated: 2015/04/18 08:56:57
  43 dnl -------------------
  44 dnl Inserted as requested by gettext 0.10.40
  45 dnl File from /usr/share/aclocal
  46 dnl codeset.m4
  47 dnl ====================
  48 dnl serial AM1
  49 dnl
  50 dnl From Bruno Haible.
  51 AC_DEFUN([AM_LANGINFO_CODESET],
  52 [
  53 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  54         [AC_TRY_LINK([#include <langinfo.h>],
  55         [char* cs = nl_langinfo(CODESET);],
  56         am_cv_langinfo_codeset=yes,
  57         am_cv_langinfo_codeset=no)
  58         ])
  59         if test $am_cv_langinfo_codeset = yes; then
  60                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  61                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  62         fi
  63 ])dnl
  64 dnl ---------------------------------------------------------------------------
  65 dnl CF_ABI_DEFAULTS version: 2 updated: 2015/06/06 13:49:58
  66 dnl ---------------
  67 dnl Provide configure-script defaults for different ncurses ABIs.
  68 AC_DEFUN([CF_ABI_DEFAULTS],[
  69 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
  70 case x$cf_cv_abi_version in
  71 (x[[6789]])
  72         cf_dft_ext_colors=yes
  73         cf_dft_ext_const=yes
  74         cf_dft_ext_mouse=yes
  75         cf_dft_ext_putwin=yes
  76         cf_dft_ext_spfuncs=yes
  77         cf_dft_filter_syms=yes
  78         cf_dft_chtype=uint32_t
  79         cf_dft_mmask_t=uint32_t
  80         cf_dft_interop=yes
  81         cf_dft_tparm_arg=intptr_t
  82         cf_dft_with_lp64=yes
  83         ;;
  84 (*)
  85         cf_dft_ext_colors=no
  86         cf_dft_ext_const=no
  87         cf_dft_ext_mouse=no
  88         cf_dft_ext_putwin=no
  89         cf_dft_ext_spfuncs=no
  90         cf_dft_filter_syms=no
  91         cf_dft_chtype=auto
  92         cf_dft_mmask_t=auto
  93         cf_dft_interop=no
  94         cf_dft_tparm_arg=long
  95         cf_dft_with_lp64=no
  96         ;;
  97 esac
  98 ])dnl
  99 dnl ---------------------------------------------------------------------------
 100 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
 101 dnl ------------------
 102 dnl Conditionally generate script according to whether we're using a given autoconf.
 103 dnl
 104 dnl $1 = version to compare against
 105 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
 106 dnl $3 = code to use if AC_ACVERSION is older than $1.
 107 define([CF_ACVERSION_CHECK],
 108 [
 109 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
 110 ifdef([m4_version_compare],
 111 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
 112 [CF_ACVERSION_COMPARE(
 113 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
 114 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
 115 dnl ---------------------------------------------------------------------------
 116 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
 117 dnl --------------------
 118 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
 119 dnl                      MAJOR2, MINOR2, TERNARY2,
 120 dnl                      PRINTABLE2, not FOUND, FOUND)
 121 define([CF_ACVERSION_COMPARE],
 122 [ifelse(builtin([eval], [$2 < $5]), 1,
 123 [ifelse([$8], , ,[$8])],
 124 [ifelse([$9], , ,[$9])])])dnl
 125 dnl ---------------------------------------------------------------------------
 126 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
 127 dnl -------------------
 128 dnl Construct the list of include-options for the C programs in the Ada95
 129 dnl binding.
 130 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
 131 [
 132 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
 133 if test "$srcdir" != "."; then
 134         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 135 fi
 136 if test "$GCC" != yes; then
 137         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 138 elif test "$includedir" != "/usr/include"; then
 139         if test "$includedir" = '${prefix}/include' ; then
 140                 if test x$prefix != x/usr ; then
 141                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 142                 fi
 143         else
 144                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 145         fi
 146 fi
 147 AC_SUBST(ACPPFLAGS)
 148 ])dnl
 149 dnl ---------------------------------------------------------------------------
 150 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 151 dnl ---------------
 152 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 153 AC_DEFUN([CF_ADD_ADAFLAGS],[
 154         ADAFLAGS="$ADAFLAGS $1"
 155         AC_SUBST(ADAFLAGS)
 156 ])dnl
 157 dnl ---------------------------------------------------------------------------
 158 dnl CF_ADD_CFLAGS version: 12 updated: 2015/04/12 15:39:00
 159 dnl -------------
 160 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 161 dnl The second parameter if given makes this macro verbose.
 162 dnl
 163 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 164 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 165 dnl confused by the quotes (which require backslashes to keep them usable).
 166 AC_DEFUN([CF_ADD_CFLAGS],
 167 [
 168 cf_fix_cppflags=no
 169 cf_new_cflags=
 170 cf_new_cppflags=
 171 cf_new_extra_cppflags=
 172
 173 for cf_add_cflags in $1
 174 do
 175 case $cf_fix_cppflags in
 176 (no)
 177         case $cf_add_cflags in
 178         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 179                 case $cf_add_cflags in
 180                 (-D*)
 181                         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 182
 183                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 184                                 && test -z "${cf_tst_cflags}" \
 185                                 && cf_fix_cppflags=yes
 186
 187                         if test $cf_fix_cppflags = yes ; then
 188                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 189                                 continue
 190                         elif test "${cf_tst_cflags}" = "\"'" ; then
 191                                 cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 192                                 continue
 193                         fi
 194                         ;;
 195                 esac
 196                 case "$CPPFLAGS" in
 197                 (*$cf_add_cflags)
 198                         ;;
 199                 (*)
 200                         case $cf_add_cflags in
 201                         (-D*)
 202                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 203                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 204                                 ;;
 205                         esac
 206                         cf_new_cppflags="$cf_new_cppflags $cf_add_cflags"
 207                         ;;
 208                 esac
 209                 ;;
 210         (*)
 211                 cf_new_cflags="$cf_new_cflags $cf_add_cflags"
 212                 ;;
 213         esac
 214         ;;
 215 (yes)
 216         cf_new_extra_cppflags="$cf_new_extra_cppflags $cf_add_cflags"
 217
 218         cf_tst_cflags=`echo ${cf_add_cflags} |sed -e 's/^[[^"]]*"'\''//'`
 219
 220         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 221                 && test -z "${cf_tst_cflags}" \
 222                 && cf_fix_cppflags=no
 223         ;;
 224 esac
 225 done
 226
 227 if test -n "$cf_new_cflags" ; then
 228         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 229         CFLAGS="$CFLAGS $cf_new_cflags"
 230 fi
 231
 232 if test -n "$cf_new_cppflags" ; then
 233         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 234         CPPFLAGS="$CPPFLAGS $cf_new_cppflags"
 235 fi
 236
 237 if test -n "$cf_new_extra_cppflags" ; then
 238         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 239         EXTRA_CPPFLAGS="$cf_new_extra_cppflags $EXTRA_CPPFLAGS"
 240 fi
 241
 242 AC_SUBST(EXTRA_CPPFLAGS)
 243
 244 ])dnl
 245 dnl ---------------------------------------------------------------------------
 246 dnl CF_ADD_INCDIR version: 14 updated: 2015/05/25 20:53:04
 247 dnl -------------
 248 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 249 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 250 dnl but old versions (and some misinstalled ones) need that.  To make things
 251 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 252 dnl the include-path).
 253 AC_DEFUN([CF_ADD_INCDIR],
 254 [
 255 if test -n "$1" ; then
 256   for cf_add_incdir in $1
 257   do
 258         while test $cf_add_incdir != /usr/include
 259         do
 260           if test -d $cf_add_incdir
 261           then
 262                 cf_have_incdir=no
 263                 if test -n "$CFLAGS$CPPFLAGS" ; then
 264                   # a loop is needed to ensure we can add subdirs of existing dirs
 265                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 266                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 267                           cf_have_incdir=yes; break
 268                         fi
 269                   done
 270                 fi
 271
 272                 if test "$cf_have_incdir" = no ; then
 273                   if test "$cf_add_incdir" = /usr/local/include ; then
 274                         if test "$GCC" = yes
 275                         then
 276                           cf_save_CPPFLAGS=$CPPFLAGS
 277                           CPPFLAGS="$CPPFLAGS -I$cf_add_incdir"
 278                           AC_TRY_COMPILE([#include <stdio.h>],
 279                                   [printf("Hello")],
 280                                   [],
 281                                   [cf_have_incdir=yes])
 282                           CPPFLAGS=$cf_save_CPPFLAGS
 283                         fi
 284                   fi
 285                 fi
 286
 287                 if test "$cf_have_incdir" = no ; then
 288                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 289                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 290
 291                   cf_top_incdir=`echo $cf_add_incdir | sed -e 's%/include/.*$%/include%'`
 292                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 293                   cf_add_incdir="$cf_top_incdir"
 294                 else
 295                   break
 296                 fi
 297           else
 298                 break
 299           fi
 300         done
 301   done
 302 fi
 303 ])dnl
 304 dnl ---------------------------------------------------------------------------
 305 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 306 dnl ----------
 307 dnl Add a library, used to enforce consistency.
 308 dnl
 309 dnl $1 = library to add, without the "-l"
 310 dnl $2 = variable to update (default $LIBS)
 311 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 312 dnl ---------------------------------------------------------------------------
 313 dnl CF_ADD_LIBDIR version: 10 updated: 2015/04/18 08:56:57
 314 dnl -------------
 315 dnl     Adds to the library-path
 316 dnl
 317 dnl     Some machines have trouble with multiple -L options.
 318 dnl
 319 dnl $1 is the (list of) directory(s) to add
 320 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 321 dnl
 322 AC_DEFUN([CF_ADD_LIBDIR],
 323 [
 324 if test -n "$1" ; then
 325         for cf_add_libdir in $1
 326         do
 327                 if test $cf_add_libdir = /usr/lib ; then
 328                         :
 329                 elif test -d $cf_add_libdir
 330                 then
 331                         cf_have_libdir=no
 332                         if test -n "$LDFLAGS$LIBS" ; then
 333                                 # a loop is needed to ensure we can add subdirs of existing dirs
 334                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 335                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 336                                                 cf_have_libdir=yes; break
 337                                         fi
 338                                 done
 339                         fi
 340                         if test "$cf_have_libdir" = no ; then
 341                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 342                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 343                         fi
 344                 fi
 345         done
 346 fi
 347 ])dnl
 348 dnl ---------------------------------------------------------------------------
 349 dnl CF_ADD_LIBS version: 2 updated: 2014/07/13 14:33:27
 350 dnl -----------
 351 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 352 dnl prepended to an existing list, since their dependencies are assumed to
 353 dnl already exist in the list.
 354 dnl
 355 dnl $1 = libraries to add, with the "-l", etc.
 356 dnl $2 = variable to update (default $LIBS)
 357 AC_DEFUN([CF_ADD_LIBS],[
 358 cf_add_libs="$1"
 359 # Filter out duplicates - this happens with badly-designed ".pc" files...
 360 for cf_add_1lib in [$]ifelse($2,,LIBS,[$2])
 361 do
 362         for cf_add_2lib in $cf_add_libs
 363         do
 364                 if test "x$cf_add_1lib" = "x$cf_add_2lib"
 365                 then
 366                         cf_add_1lib=
 367                         break
 368                 fi
 369         done
 370         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_libs $cf_add_1lib"
 371 done
 372 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 373 ])dnl
 374 dnl ---------------------------------------------------------------------------
 375 dnl CF_ADD_SUBDIR_PATH version: 4 updated: 2013/10/08 17:47:05
 376 dnl ------------------
 377 dnl Append to a search-list for a nonstandard header/lib-file
 378 dnl     $1 = the variable to return as result
 379 dnl     $2 = the package name
 380 dnl     $3 = the subdirectory, e.g., bin, include or lib
 381 dnl $4 = the directory under which we will test for subdirectories
 382 dnl $5 = a directory that we do not want $4 to match
 383 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 384 [
 385 test "x$4" != "x$5" && \
 386 test -d "$4" && \
 387 ifelse([$5],NONE,,[(test -z "$5" || test x$5 = xNONE || test "x$4" != "x$5") &&]) {
 388         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 389         test -d $4/$3 &&          $1="[$]$1 $4/$3"
 390         test -d $4/$3/$2 &&       $1="[$]$1 $4/$3/$2"
 391         test -d $4/$3/$2/$3 &&    $1="[$]$1 $4/$3/$2/$3"
 392         test -d $4/$2/$3 &&       $1="[$]$1 $4/$2/$3"
 393         test -d $4/$2/$3/$2 &&    $1="[$]$1 $4/$2/$3/$2"
 394 }
 395 ])dnl
 396 dnl ---------------------------------------------------------------------------
 397 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 398 dnl --------------
 399 dnl Allow user to disable a normally-on option.
 400 AC_DEFUN([CF_ARG_DISABLE],
 401 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 402 dnl ---------------------------------------------------------------------------
 403 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 404 dnl -------------
 405 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 406 dnl values.
 407 dnl
 408 dnl Parameters:
 409 dnl $1 = option name
 410 dnl $2 = help-string
 411 dnl $3 = action to perform if option is not default
 412 dnl $4 = action if perform if option is default
 413 dnl $5 = default option value (either 'yes' or 'no')
 414 AC_DEFUN([CF_ARG_OPTION],
 415 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 416         if test "$enableval" != "$5" ; then
 417 ifelse([$3],,[    :]dnl
 418 ,[    $3]) ifelse([$4],,,[
 419         else
 420                 $4])
 421         fi],[enableval=$5 ifelse([$4],,,[
 422         $4
 423 ])dnl
 424 ])])dnl
 425 dnl ---------------------------------------------------------------------------
 426 dnl CF_AR_FLAGS version: 6 updated: 2015/10/10 15:25:05
 427 dnl -----------
 428 dnl Check for suitable "ar" (archiver) options for updating an archive.
 429 dnl
 430 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 431 dnl as well as a workaround for breakage of make's archive rules by the GNU
 432 dnl binutils "ar" program.
 433 AC_DEFUN([CF_AR_FLAGS],[
 434 AC_REQUIRE([CF_PROG_AR])
 435
 436 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 437         cf_cv_ar_flags=unknown
 438         for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 439         do
 440
 441                 # check if $ARFLAGS already contains this choice
 442                 if test "x$ARFLAGS" != "x" ; then
 443                         cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 444                         if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 445                                 cf_cv_ar_flags=
 446                                 break
 447                         fi
 448                 fi
 449
 450                 rm -f conftest.$ac_cv_objext
 451                 rm -f conftest.a
 452
 453                 cat >conftest.$ac_ext <<EOF
 454 #line __oline__ "configure"
 455 int     testdata[[3]] = { 123, 456, 789 };
 456 EOF
 457                 if AC_TRY_EVAL(ac_compile) ; then
 458                         echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 459                         $AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext 2>&AC_FD_CC 1>/dev/null
 460                         if test -f conftest.a ; then
 461                                 cf_cv_ar_flags=$cf_ar_flags
 462                                 break
 463                         fi
 464                 else
 465                         CF_VERBOSE(cannot compile test-program)
 466                         break
 467                 fi
 468         done
 469         rm -f conftest.a conftest.$ac_ext conftest.$ac_cv_objext
 470 ])
 471
 472 if test -n "$ARFLAGS" ; then
 473         if test -n "$cf_cv_ar_flags" ; then
 474                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 475         fi
 476 else
 477         ARFLAGS=$cf_cv_ar_flags
 478 fi
 479
 480 AC_SUBST(ARFLAGS)
 481 ])
 482 dnl ---------------------------------------------------------------------------
 483 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
 484 dnl -----------------
 485 dnl Check if awk can handle big strings using printf.  Some older versions of
 486 dnl awk choke on large strings passed via "%s".
 487 dnl
 488 dnl $1 = desired string size
 489 dnl $2 = variable to set with result
 490 AC_DEFUN([CF_AWK_BIG_PRINTF],
 491 [
 492         case x$AWK in
 493         (x)
 494                 eval $2=no
 495                 ;;
 496         (*)
 497                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 498                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 499                         eval $2=yes
 500                 else
 501                         eval $2=no
 502                 fi
 503                 ;;
 504         esac
 505 ])dnl
 506 dnl ---------------------------------------------------------------------------
 507 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 508 dnl ------------
 509 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 510 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 511 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 512 dnl
 513 dnl Treat the configuration-variable specially here, since we're directly
 514 dnl substituting its value (i.e., 1/0).
 515 dnl
 516 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 517 AC_DEFUN([CF_BOOL_DECL],
 518 [
 519 AC_MSG_CHECKING(if we should include stdbool.h)
 520
 521 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 522         AC_TRY_COMPILE([],[bool foo = false],
 523                 [cf_cv_header_stdbool_h=0],
 524                 [AC_TRY_COMPILE([
 525 #ifndef __BEOS__
 526 #include <stdbool.h>
 527 #endif
 528 ],[bool foo = false],
 529                         [cf_cv_header_stdbool_h=1],
 530                         [cf_cv_header_stdbool_h=0])])])
 531
 532 if test "$cf_cv_header_stdbool_h" = 1
 533 then    AC_MSG_RESULT(yes)
 534 else    AC_MSG_RESULT(no)
 535 fi
 536
 537 AC_MSG_CHECKING([for builtin bool type])
 538
 539 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 540         AC_TRY_COMPILE([
 541 #include <stdio.h>
 542 #include <sys/types.h>
 543 ],[bool x = false],
 544                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 545                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 546         ])
 547
 548 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 549 then    AC_MSG_RESULT(yes)
 550 else    AC_MSG_RESULT(no)
 551 fi
 552 ])dnl
 553 dnl ---------------------------------------------------------------------------
 554 dnl CF_BOOL_SIZE version: 15 updated: 2017/01/21 11:06:25
 555 dnl ------------
 556 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 557 dnl Don't bother looking for bool.h, since it's been deprecated.
 558 dnl
 559 dnl If the current compiler is C rather than C++, we get the bool definition
 560 dnl from <stdbool.h>.
 561 AC_DEFUN([CF_BOOL_SIZE],
 562 [
 563 AC_MSG_CHECKING([for size of bool])
 564 AC_CACHE_VAL(cf_cv_type_of_bool,[
 565         rm -f cf_test.out
 566         AC_TRY_RUN([
 567 #include <stdlib.h>
 568 #include <stdio.h>
 569
 570 #if defined(__cplusplus)
 571
 572 #ifdef HAVE_GXX_BUILTIN_H
 573 #include <g++/builtin.h>
 574 #elif HAVE_GPP_BUILTIN_H
 575 #include <gpp/builtin.h>
 576 #elif HAVE_BUILTIN_H
 577 #include <builtin.h>
 578 #endif
 579
 580 #else
 581
 582 #if $cf_cv_header_stdbool_h
 583 #include <stdbool.h>
 584 #endif
 585
 586 #endif
 587
 588 int main(void)
 589 {
 590         FILE *fp = fopen("cf_test.out", "w");
 591         if (fp != 0) {
 592                 bool x = true;
 593                 if ((bool)(-x) >= 0)
 594                         fputs("unsigned ", fp);
 595                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 596                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 597                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 598                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 599                 fclose(fp);
 600         }
 601         ${cf_cv_main_return:-return}(0);
 602 }
 603                 ],
 604                 [cf_cv_type_of_bool=`cat cf_test.out`
 605                  if test -z "$cf_cv_type_of_bool"; then
 606                    cf_cv_type_of_bool=unknown
 607                  fi],
 608                 [cf_cv_type_of_bool=unknown],
 609                 [cf_cv_type_of_bool=unknown])
 610         ])
 611         rm -f cf_test.out
 612 AC_MSG_RESULT($cf_cv_type_of_bool)
 613 if test "$cf_cv_type_of_bool" = unknown ; then
 614         case .$NCURSES_BOOL in
 615         (.auto|.) NCURSES_BOOL=unsigned;;
 616         esac
 617         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 618         cf_cv_type_of_bool=$NCURSES_BOOL
 619 fi
 620 ])dnl
 621 dnl ---------------------------------------------------------------------------
 622 dnl CF_BUILD_CC version: 7 updated: 2012/10/06 15:31:55
 623 dnl -----------
 624 dnl If we're cross-compiling, allow the user to override the tools and their
 625 dnl options.  The configure script is oriented toward identifying the host
 626 dnl compiler, etc., but we need a build compiler to generate parts of the
 627 dnl source.
 628 dnl
 629 dnl $1 = default for $CPPFLAGS
 630 dnl $2 = default for $LIBS
 631 AC_DEFUN([CF_BUILD_CC],[
 632 CF_ACVERSION_CHECK(2.52,,
 633         [AC_REQUIRE([CF_PROG_EXT])])
 634 if test "$cross_compiling" = yes ; then
 635
 636         # defaults that we might want to override
 637         : ${BUILD_CFLAGS:=''}
 638         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 639         : ${BUILD_LDFLAGS:=''}
 640         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 641         : ${BUILD_EXEEXT:='$x'}
 642         : ${BUILD_OBJEXT:='o'}
 643
 644         AC_ARG_WITH(build-cc,
 645                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 646                 [BUILD_CC="$withval"],
 647                 [AC_CHECK_PROGS(BUILD_CC, gcc cc cl)])
 648         AC_MSG_CHECKING(for native build C compiler)
 649         AC_MSG_RESULT($BUILD_CC)
 650
 651         AC_MSG_CHECKING(for native build C preprocessor)
 652         AC_ARG_WITH(build-cpp,
 653                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 654                 [BUILD_CPP="$withval"],
 655                 [BUILD_CPP='${BUILD_CC} -E'])
 656         AC_MSG_RESULT($BUILD_CPP)
 657
 658         AC_MSG_CHECKING(for native build C flags)
 659         AC_ARG_WITH(build-cflags,
 660                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 661                 [BUILD_CFLAGS="$withval"])
 662         AC_MSG_RESULT($BUILD_CFLAGS)
 663
 664         AC_MSG_CHECKING(for native build C preprocessor-flags)
 665         AC_ARG_WITH(build-cppflags,
 666                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 667                 [BUILD_CPPFLAGS="$withval"])
 668         AC_MSG_RESULT($BUILD_CPPFLAGS)
 669
 670         AC_MSG_CHECKING(for native build linker-flags)
 671         AC_ARG_WITH(build-ldflags,
 672                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 673                 [BUILD_LDFLAGS="$withval"])
 674         AC_MSG_RESULT($BUILD_LDFLAGS)
 675
 676         AC_MSG_CHECKING(for native build linker-libraries)
 677         AC_ARG_WITH(build-libs,
 678                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 679                 [BUILD_LIBS="$withval"])
 680         AC_MSG_RESULT($BUILD_LIBS)
 681
 682         # this assumes we're on Unix.
 683         BUILD_EXEEXT=
 684         BUILD_OBJEXT=o
 685
 686         : ${BUILD_CC:='${CC}'}
 687
 688         if ( test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}' ) ; then
 689                 AC_MSG_ERROR([Cross-build requires two compilers.
 690 Use --with-build-cc to specify the native compiler.])
 691         fi
 692
 693 else
 694         : ${BUILD_CC:='${CC}'}
 695         : ${BUILD_CPP:='${CPP}'}
 696         : ${BUILD_CFLAGS:='${CFLAGS}'}
 697         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 698         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 699         : ${BUILD_LIBS:='${LIBS}'}
 700         : ${BUILD_EXEEXT:='$x'}
 701         : ${BUILD_OBJEXT:='o'}
 702 fi
 703
 704 AC_SUBST(BUILD_CC)
 705 AC_SUBST(BUILD_CPP)
 706 AC_SUBST(BUILD_CFLAGS)
 707 AC_SUBST(BUILD_CPPFLAGS)
 708 AC_SUBST(BUILD_LDFLAGS)
 709 AC_SUBST(BUILD_LIBS)
 710 AC_SUBST(BUILD_EXEEXT)
 711 AC_SUBST(BUILD_OBJEXT)
 712 ])dnl
 713 dnl ---------------------------------------------------------------------------
 714 dnl CF_CC_ENV_FLAGS version: 6 updated: 2016/08/29 20:57:00
 715 dnl ---------------
 716 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 717 dnl into CC.  This will not help with broken scripts that wrap the compiler
 718 dnl with options, but eliminates a more common category of user confusion.
 719 dnl
 720 dnl In particular, it addresses the problem of being able to run the C
 721 dnl preprocessor in a consistent manner.
 722 dnl
 723 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 724 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 725 dnl outweighs that limitation.
 726 AC_DEFUN([CF_CC_ENV_FLAGS],
 727 [
 728 # This should have been defined by AC_PROG_CC
 729 : ${CC:=cc}
 730
 731 AC_MSG_CHECKING(\$CC variable)
 732 case "$CC" in
 733 (*[[\ \ ]]-*)
 734         AC_MSG_RESULT(broken)
 735         AC_MSG_WARN(your environment misuses the CC variable to hold CFLAGS/CPPFLAGS options)
 736         # humor him...
 737         cf_flags=`echo "$CC" | sed -e 's/^.*[[  ]]\(-[[^        ]]\)/\1/'`
 738         CC=`echo "$CC " | sed -e 's/[[  ]]-[[^  ]].*$//' -e 's/[[       ]]*$//'`
 739         for cf_arg in $cf_flags
 740         do
 741                 case "x$cf_arg" in
 742                 (x-[[IUDfgOW]]*)
 743                         CF_ADD_CFLAGS($cf_flags)
 744                         ;;
 745                 (*)
 746                         CC="$CC $cf_arg"
 747                         ;;
 748                 esac
 749         done
 750         CF_VERBOSE(resulting CC: '$CC')
 751         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 752         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 753         ;;
 754 (*)
 755         AC_MSG_RESULT(ok)
 756         ;;
 757 esac
 758 ])dnl
 759 dnl ---------------------------------------------------------------------------
 760 dnl CF_CFG_DEFAULTS version: 11 updated: 2015/04/17 21:13:04
 761 dnl ---------------
 762 dnl Determine the default configuration into which we'll install ncurses.  This
 763 dnl can be overridden by the user's command-line options.  There's two items to
 764 dnl look for:
 765 dnl     1. the prefix (e.g., /usr)
 766 dnl     2. the header files (e.g., /usr/include/ncurses)
 767 dnl We'll look for a previous installation of ncurses and use the same defaults.
 768 dnl
 769 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 770 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 771 dnl programs from a vendor's.
 772 AC_DEFUN([CF_CFG_DEFAULTS],
 773 [
 774 AC_MSG_CHECKING(for prefix)
 775 if test "x$prefix" = "xNONE" ; then
 776         case "$cf_cv_system_name" in
 777                 # non-vendor systems don't have a conflict
 778         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 779                 prefix=/usr
 780                 ;;
 781         (*)     prefix=$ac_default_prefix
 782                 ;;
 783         esac
 784 fi
 785 AC_MSG_RESULT($prefix)
 786
 787 if test "x$prefix" = "xNONE" ; then
 788 AC_MSG_CHECKING(for default include-directory)
 789 test -n "$verbose" && echo 1>&AC_FD_MSG
 790 for cf_symbol in \
 791         $includedir \
 792         $includedir/ncurses \
 793         $prefix/include \
 794         $prefix/include/ncurses \
 795         /usr/local/include \
 796         /usr/local/include/ncurses \
 797         /usr/include \
 798         /usr/include/ncurses
 799 do
 800         cf_dir=`eval echo $cf_symbol`
 801         if test -f $cf_dir/curses.h ; then
 802         if ( fgrep NCURSES_VERSION $cf_dir/curses.h 2>&1 >/dev/null ) ; then
 803                 includedir="$cf_symbol"
 804                 test -n "$verbose"  && echo $ac_n "     found " 1>&AC_FD_MSG
 805                 break
 806         fi
 807         fi
 808         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 809 done
 810 AC_MSG_RESULT($includedir)
 811 fi
 812 ])dnl
 813 dnl ---------------------------------------------------------------------------
 814 dnl CF_CGETENT version: 6 updated: 2017/01/21 11:06:25
 815 dnl ----------
 816 dnl Check if the terminal-capability database functions are available.  If not,
 817 dnl ncurses has a much-reduced version.
 818 AC_DEFUN([CF_CGETENT],[
 819 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 820 AC_TRY_LINK([
 821 #include <stdlib.h>],[
 822         char temp[128];
 823         char *buf = temp;
 824         char *db_array = temp;
 825         cgetent(&buf, &db_array, "vt100");
 826         cgetcap(buf, "tc", '=');
 827         cgetmatch(buf, "tc");
 828         ],
 829         [cf_cv_cgetent=yes],
 830         [cf_cv_cgetent=no])
 831 ])
 832
 833 if test "$cf_cv_cgetent" = yes
 834 then
 835         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 836 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 837 AC_TRY_LINK([
 838 #pragma GCC diagnostic error "-Wincompatible-pointer-types-discards-qualifiers"
 839 #include <stdlib.h>],[
 840         char temp[128];
 841         char *buf = temp;
 842 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 843         const char *db_array = temp;
 844         cgetent(&buf, &db_array, "vt100");
 845 #endif
 846         cgetcap(buf, "tc", '=');
 847         cgetmatch(buf, "tc");
 848         ],
 849         [cf_cv_cgetent_const=yes],
 850         [cf_cv_cgetent_const=no])
 851 ])
 852         if test "$cf_cv_cgetent_const" = yes
 853         then
 854                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 855         fi
 856 fi
 857 ])dnl
 858 dnl ---------------------------------------------------------------------------
 859 dnl CF_CHECK_CACHE version: 12 updated: 2012/10/02 20:55:03
 860 dnl --------------
 861 dnl Check if we're accidentally using a cache from a different machine.
 862 dnl Derive the system name, as a check for reusing the autoconf cache.
 863 dnl
 864 dnl If we've packaged config.guess and config.sub, run that (since it does a
 865 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 866 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 867 dnl which is useful in cross-compiles.
 868 dnl
 869 dnl Note: we would use $ac_config_sub, but that is one of the places where
 870 dnl autoconf 2.5x broke compatibility with autoconf 2.13
 871 AC_DEFUN([CF_CHECK_CACHE],
 872 [
 873 if test -f $srcdir/config.guess || test -f $ac_aux_dir/config.guess ; then
 874         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
 875         system_name="$host_os"
 876 else
 877         system_name="`(uname -s -r) 2>/dev/null`"
 878         if test -z "$system_name" ; then
 879                 system_name="`(hostname) 2>/dev/null`"
 880         fi
 881 fi
 882 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
 883 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
 884
 885 test -z "$system_name" && system_name="$cf_cv_system_name"
 886 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
 887
 888 if test ".$system_name" != ".$cf_cv_system_name" ; then
 889         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
 890         AC_MSG_ERROR("Please remove config.cache and try again.")
 891 fi
 892 ])dnl
 893 dnl ---------------------------------------------------------------------------
 894 dnl CF_CHECK_ERRNO version: 12 updated: 2015/04/18 08:56:57
 895 dnl --------------
 896 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
 897 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
 898 dnl ourselves.
 899 dnl
 900 dnl $1 = the name to check
 901 dnl $2 = the assumed type
 902 AC_DEFUN([CF_CHECK_ERRNO],
 903 [
 904 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
 905         AC_TRY_COMPILE([
 906 #ifdef HAVE_STDLIB_H
 907 #include <stdlib.h>
 908 #endif
 909 #include <stdio.h>
 910 #include <sys/types.h>
 911 #include <errno.h> ],
 912         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
 913         [cf_cv_dcl_$1=yes],
 914         [cf_cv_dcl_$1=no])
 915 ])
 916
 917 if test "$cf_cv_dcl_$1" = no ; then
 918         CF_UPPER(cf_result,decl_$1)
 919         AC_DEFINE_UNQUOTED($cf_result)
 920 fi
 921
 922 # It's possible (for near-UNIX clones) that the data doesn't exist
 923 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
 924 ])dnl
 925 dnl ---------------------------------------------------------------------------
 926 dnl CF_CHECK_EXTERN_DATA version: 4 updated: 2015/04/18 08:56:57
 927 dnl --------------------
 928 dnl Check for existence of external data in the current set of libraries.  If
 929 dnl we can modify it, it's real enough.
 930 dnl $1 = the name to check
 931 dnl $2 = its type
 932 AC_DEFUN([CF_CHECK_EXTERN_DATA],
 933 [
 934 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
 935         AC_TRY_LINK([
 936 #undef $1
 937 extern $2 $1;
 938 ],
 939         [$1 = 2],
 940         [cf_cv_have_$1=yes],
 941         [cf_cv_have_$1=no])
 942 ])
 943
 944 if test "$cf_cv_have_$1" = yes ; then
 945         CF_UPPER(cf_result,have_$1)
 946         AC_DEFINE_UNQUOTED($cf_result)
 947 fi
 948
 949 ])dnl
 950 dnl ---------------------------------------------------------------------------
 951 dnl CF_CHECK_GPM_WGETCH version: 3 updated: 2017/01/21 11:06:25
 952 dnl -------------------
 953 dnl Check if GPM is already linked with curses.  If so - and if the linkage
 954 dnl is not "weak" - warn about this because it can create problems linking
 955 dnl applications with ncurses.
 956 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
 957 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
 958
 959 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
 960 cf_cv_check_gpm_wgetch=unknown
 961 if test "$cross_compiling" != yes ; then
 962
 963 cat >conftest.$ac_ext <<CF_EOF
 964 #include <gpm.h>
 965 int main(void)
 966 {
 967         Gpm_Wgetch();
 968         ${cf_cv_main_return:-return}(0);
 969 }
 970 CF_EOF
 971
 972         cf_save_LIBS="$LIBS"
 973         # This only works if we can look at the symbol table.  If a shared
 974         # library is stripped for install, we cannot use that.  So we're forced
 975         # to rely on the static library, noting that some packagers may not
 976         # include it.
 977         LIBS="-static -lgpm -dynamic $LIBS"
 978         if AC_TRY_EVAL(ac_compile) ; then
 979                 if AC_TRY_EVAL(ac_link) ; then
 980                         cf_cv_check_gpm_wgetch=`nm conftest$ac_exeext | egrep '\<wgetch\>' | egrep '\<[[vVwW]]\>'`
 981                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
 982                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
 983                 fi
 984         fi
 985         rm -rf conftest*
 986         LIBS="$cf_save_LIBS"
 987 fi
 988 ])
 989
 990 if test "$cf_cv_check_gpm_wgetch" != yes ; then
 991         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
 992 fi
 993 ])])dnl
 994 dnl ---------------------------------------------------------------------------
 995 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
 996 dnl ------------------------
 997 dnl Show the version of libtool
 998 dnl
 999 dnl Save the version in a cache variable - this is not entirely a good thing,
1000 dnl but the version string from libtool is very ugly, and for bug reports it
1001 dnl might be useful to have the original string.
1002 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
1003 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
1004 then
1005         AC_MSG_CHECKING(version of $LIBTOOL)
1006         CF_LIBTOOL_VERSION
1007         AC_MSG_RESULT($cf_cv_libtool_version)
1008         if test -z "$cf_cv_libtool_version" ; then
1009                 AC_MSG_ERROR(This is not GNU libtool)
1010         fi
1011 else
1012         AC_MSG_ERROR(GNU libtool has not been found)
1013 fi
1014 ])dnl
1015 dnl ---------------------------------------------------------------------------
1016 dnl CF_CHECK_WCHAR_H version: 2 updated: 2017/01/21 11:06:25
1017 dnl ----------------
1018 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
1019 AC_DEFUN([CF_CHECK_WCHAR_H],[
1020 AC_CHECK_HEADERS( \
1021 wchar.h \
1022 wctype.h \
1023 )
1024 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1025 AC_TRY_COMPILE(
1026 [
1027 #include <stdlib.h>
1028 #ifdef HAVE_WCHAR_H
1029 #include <wchar.h>
1030 #endif
1031 #ifdef HAVE_WCTYPE_H
1032 #include <wctype.h>
1033 #endif
1034 ],[
1035         wint_t foo = 0;
1036         int bar = iswpunct(foo)],
1037         [cf_cv_wchar_h_okay=yes],
1038         [cf_cv_wchar_h_okay=no])])
1039
1040 if test $cf_cv_wchar_h_okay = no
1041 then
1042         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1043 fi
1044 ])dnl
1045 dnl ---------------------------------------------------------------------------
1046 dnl CF_CHECK_WCWIDTH_GRAPHICS version: 1 updated: 2015/12/19 17:47:56
1047 dnl -------------------------
1048 dnl Most "modern" terminal emulators are based to some degree on VT100, and
1049 dnl should support line-drawing.  Even with Unicode.  There is a problem.
1050 dnl
1051 dnl While most of the VT100 graphics characters were incorporated into Unicode,
1052 dnl all of those were combined into a page of useful graphics characters.
1053 dnl
1054 dnl So far, so good.
1055 dnl
1056 dnl However, while they are useful, there are other considerations.  CJK
1057 dnl is (because of poor device resolution) often rendered as double-width
1058 dnl characters.  So... for these generally-useful characters, what should
1059 dnl be the width (to make them consistent with adjacent characters)?
1060 dnl
1061 dnl The obvious choice would have been to make this locale-dependent, and use
1062 dnl wcwidth() to tell applications what the actual width is.  That was too
1063 dnl obvious.  Instead, we have a slew of "ambiguous-width" characters.
1064 dnl See for example
1065 dnl             http://www.unicode.org/reports/tr11/tr11-29.html
1066 dnl             http://www.cl.cam.ac.uk/~mgk25/ucs/scw-proposal.html
1067 dnl
1068 dnl The EastAsianWidth-6.2.0.txt file from the Unicode organization lists
1069 dnl more than 22,000 characters, with 1281 of those as ambiguous-width.  For
1070 dnl instance, it lists half (44/96) of the Latin-1 characters as
1071 dnl ambiguous-width.  Also, all of the box-characters at 0x2500 are ambiguous.
1072 dnl
1073 dnl What this means for the implementor is that on some systems wcwidth() can
1074 dnl give bad advice.  On Solaris, some of the ambiguous widths are returned as
1075 dnl 1 (the Latin-1 characters), while others are returned as 2 (line-drawing
1076 dnl characters).  These do not necessarily match the behavior of the terminal
1077 dnl emulator.  xterm, for instance, does an optional startup check to find if
1078 dnl this problem (or similar) exists with the system's locale tables, rejecting
1079 dnl them if they are too unreliable.
1080 AC_DEFUN([CF_CHECK_WCWIDTH_GRAPHICS],[
1081 AC_CACHE_CHECK(if wcwidth agrees graphics are single-width, cf_cv_wcwidth_graphics,[
1082 cat >conftest.in <<CF_EOF
1083 -       VT100 symbols
1084 0x250c  upper left corner
1085 0x2514  lower left corner
1086 0x2510  upper right corner
1087 0x2518  lower right corner
1088 0x251c  tee pointing left
1089 0x2524  tee pointing right
1090 0x2534  tee pointing up
1091 0x252c  tee pointing down
1092 0x2500  horizontal line
1093 0x2502  vertical line
1094 0x253c  large plus or crossover
1095 0x23ba  scan line 1
1096 0x23bd  scan line 9
1097 0x25c6  diamond
1098 0x2592  checker board (stipple)
1099 0x00b0  degree symbol
1100 0x00b1  plus/minus
1101 0x00b7  bullet
1102 -       Teletype 5410v1 symbols
1103 0x2190  arrow pointing left
1104 0x2192  arrow pointing right
1105 0x2193  arrow pointing down
1106 0x2191  arrow pointing up
1107 0x2592  board of squares
1108 0x2603  lantern symbol
1109 0x25ae  solid square block
1110 -       these defaults were invented for ncurses
1111 0x23bb  scan line 3
1112 0x23bc  scan line 7
1113 0x2264  less-than-or-equal-to
1114 0x2265  greater-than-or-equal-to
1115 0x03c0  greek pi
1116 0x2260  not-equal
1117 0x00a3  pound-sterling symbol
1118 -       thick-line-drawing
1119 0x250f  upper left corner
1120 0x2517  lower left corner
1121 0x2513  upper right corner
1122 0x251b  lower right corner
1123 0x2523  tee pointing left
1124 0x252b  tee pointing right
1125 0x253b  tee pointing up
1126 0x2533  tee pointing down
1127 0x2501  horizontal line
1128 0x2503  vertical line
1129 0x254b  large plus or crossover
1130 -       double-line-drawing
1131 0x2554  upper left corner
1132 0x255a  lower left corner
1133 0x2557  upper right corner
1134 0x255d  lower right corner
1135 0x2563  tee pointing left
1136 0x2560  tee pointing right
1137 0x2569  tee pointing up
1138 0x2566  tee pointing down
1139 0x2550  horizontal line
1140 0x2551  vertical line
1141 0x256c  large plus or crossover
1142 CF_EOF
1143 AC_TRY_RUN([
1144 #include <locale.h>
1145 #include <stdio.h>
1146 #include <wchar.h>
1147
1148 #define MY_LEN 80
1149
1150 int
1151 main(void)
1152 {
1153         FILE *fp;
1154         int value;
1155         char buffer[MY_LEN + 1];
1156         char notes[MY_LEN + 1];
1157         int totals = 0;
1158         int passed = 0;
1159
1160         if (setlocale(LC_ALL, "en_US.UTF8") ||
1161                 setlocale(LC_ALL, "en_US.UTF-8") ||
1162                 setlocale(LC_ALL, "en_US.utf8") ||
1163                 setlocale(LC_ALL, "en_US.utf-8")) {
1164                 if ((fp = fopen("conftest.in", "r")) != 0) {
1165                         while (fgets(buffer, MY_LEN, fp) != 0) {
1166                                 if (*buffer == '-') {
1167                                         fprintf(stderr, "\t%s", buffer);
1168                                 } else if (sscanf(buffer, "%x %s", &value, notes) == 2) {
1169                                         ++totals;
1170                                         if (wcwidth(value) == 1)
1171                                                 ++passed;
1172                                         fprintf(stderr, "%d\t%s", wcwidth(value), buffer);
1173                                 } else {
1174                                         fprintf(stderr, "?\t%s", buffer);
1175                                 }
1176                         }
1177                 }
1178         }
1179         fprintf(stderr, "%d/%d passed wcwidth/graphics check\n", passed, totals);
1180         return (totals == passed) ? 0 : 1;
1181 }
1182 ],
1183 [cf_cv_wcwidth_graphics=yes],
1184 [cf_cv_wcwidth_graphics=no],
1185 [cf_cv_wcwidth_graphics=unknown])
1186 ])
1187 ])dnl
1188 dnl ---------------------------------------------------------------------------
1189 dnl CF_CLANG_COMPILER version: 2 updated: 2013/11/19 19:23:35
1190 dnl -----------------
1191 dnl Check if the given compiler is really clang.  clang's C driver defines
1192 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1193 dnl not ignore some gcc options.
1194 dnl
1195 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1196 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1197 dnl the wrappers for gcc and g++ warnings.
1198 dnl
1199 dnl $1 = GCC (default) or GXX
1200 dnl $2 = CLANG_COMPILER (default)
1201 dnl $3 = CFLAGS (default) or CXXFLAGS
1202 AC_DEFUN([CF_CLANG_COMPILER],[
1203 ifelse([$2],,CLANG_COMPILER,[$2])=no
1204
1205 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1206         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1207         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1208         ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -Qunused-arguments"
1209         AC_TRY_COMPILE([],[
1210 #ifdef __clang__
1211 #else
1212 make an error
1213 #endif
1214 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1215 cf_save_CFLAGS="$cf_save_CFLAGS -Qunused-arguments"
1216 ],[])
1217         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1218         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1219 fi
1220 ])
1221 dnl ---------------------------------------------------------------------------
1222 dnl CF_CPP_PARAM_INIT version: 7 updated: 2017/01/21 11:06:25
1223 dnl -----------------
1224 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1225 dnl is a late feature for the standard and is not in some recent compilers
1226 dnl (1999/9/11).
1227 AC_DEFUN([CF_CPP_PARAM_INIT],
1228 [
1229 if test -n "$CXX"; then
1230 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1231         AC_LANG_SAVE
1232         AC_LANG_CPLUSPLUS
1233         AC_TRY_RUN([
1234 class TEST {
1235 private:
1236         int value;
1237 public:
1238         TEST(int x = 1);
1239         ~TEST();
1240 };
1241
1242 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1243 {
1244         value = x;
1245 }
1246 int main(void) { }
1247 ],
1248         [cf_cv_cpp_param_init=yes],
1249         [cf_cv_cpp_param_init=no],
1250         [cf_cv_cpp_param_init=unknown])
1251         AC_LANG_RESTORE
1252 ])
1253 fi
1254 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1255 ])dnl
1256 dnl ---------------------------------------------------------------------------
1257 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1258 dnl ------------------
1259 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1260 dnl not be supported in g++ before 3.0
1261 AC_DEFUN([CF_CPP_STATIC_CAST],
1262 [
1263 if test -n "$CXX"; then
1264
1265 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1266         AC_LANG_SAVE
1267         AC_LANG_CPLUSPLUS
1268
1269         AC_TRY_COMPILE([
1270 class NCursesPanel
1271 {
1272 public:
1273   NCursesPanel(int nlines,
1274                int ncols,
1275                int begin_y = 0,
1276                int begin_x = 0)
1277   {
1278   }
1279   NCursesPanel();
1280   ~NCursesPanel();
1281 };
1282
1283 template<class T> class NCursesUserPanel : public NCursesPanel
1284 {
1285 public:
1286   NCursesUserPanel (int nlines,
1287                     int ncols,
1288                     int begin_y = 0,
1289                     int begin_x = 0,
1290                     const T* p_UserData = static_cast<T*>(0))
1291     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1292   {
1293   };
1294   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1295   {
1296   };
1297
1298   virtual ~NCursesUserPanel() {};
1299 };
1300 ],[
1301         const char* p_UserData = static_cast<char*>(0)],
1302         [cf_cv_cpp_static_cast=yes],
1303         [cf_cv_cpp_static_cast=no])
1304
1305         AC_LANG_RESTORE
1306 ])
1307
1308 fi
1309
1310 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1311 ])dnl
1312 dnl ---------------------------------------------------------------------------
1313 dnl CF_CXX_AR_FLAGS version: 2 updated: 2015/04/17 21:13:04
1314 dnl ---------------
1315 dnl Setup special archiver flags for given compilers.
1316 AC_DEFUN([CF_CXX_AR_FLAGS],[
1317         CXX_AR='$(AR)'
1318         CXX_ARFLAGS='$(ARFLAGS)'
1319         case $cf_cv_system_name in
1320         (irix*)
1321             if test "$GXX" != yes ; then
1322                 CXX_AR='$(CXX)'
1323                 CXX_ARFLAGS='-ar -o'
1324             fi
1325             ;;
1326         (sco3.2v5*)
1327             CXXLDFLAGS="-u main"
1328             ;;
1329         (solaris2*)
1330             if test "$GXX" != yes ; then
1331                 CXX_AR='$(CXX)'
1332                 CXX_ARFLAGS='-xar -o'
1333             fi
1334             ;;
1335         esac
1336         AC_SUBST(CXXLDFLAGS)
1337         AC_SUBST(CXX_AR)
1338         AC_SUBST(CXX_ARFLAGS)
1339 ])dnl
1340 dnl ---------------------------------------------------------------------------
1341 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1342 dnl -------------------------
1343 dnl For c++, check if iostream uses "std::" namespace.
1344 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1345 AC_CHECK_HEADERS(iostream)
1346 if test x"$ac_cv_header_iostream" = xyes ; then
1347         AC_MSG_CHECKING(if iostream uses std-namespace)
1348         AC_TRY_COMPILE([
1349 #include <iostream>
1350 using std::endl;
1351 using std::cerr;],[
1352 cerr << "testing" << endl;
1353 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1354         AC_MSG_RESULT($cf_iostream_namespace)
1355         if test "$cf_iostream_namespace" = yes ; then
1356                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1357         fi
1358 fi
1359 ])dnl
1360 dnl ---------------------------------------------------------------------------
1361 dnl CF_C_INLINE version: 5 updated: 2015/04/18 08:56:57
1362 dnl -----------
1363 dnl Check if the C compiler supports "inline".
1364 dnl $1 is the name of a shell variable to set if inline is supported
1365 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1366 AC_DEFUN([CF_C_INLINE],[
1367 AC_C_INLINE
1368 $1=
1369 if test "$ac_cv_c_inline" != no ; then
1370         $1=inline
1371         if test "$INTEL_COMPILER" = yes
1372         then
1373                 :
1374         elif test "$CLANG_COMPILER" = yes
1375         then
1376                 :
1377         elif test "$GCC" = yes
1378         then
1379                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1380                 cf_save_CFLAGS=$CFLAGS
1381                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1382                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1383                 [${cf_cv_main_return:-return} foo()],
1384                 [cf_cv_gcc_inline=yes],
1385                 [cf_cv_gcc_inline=no])
1386                 CFLAGS=$cf_save_CFLAGS
1387                 ])
1388                 if test "$cf_cv_gcc_inline" = yes ; then
1389                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1390                 fi
1391         fi
1392 fi
1393 AC_SUBST($1)
1394 ])dnl
1395 dnl ---------------------------------------------------------------------------
1396 dnl CF_DIRNAME version: 4 updated: 2002/12/21 19:25:52
1397 dnl ----------
1398 dnl "dirname" is not portable, so we fake it with a shell script.
1399 AC_DEFUN([CF_DIRNAME],[$1=`echo $2 | sed -e 's%/[[^/]]*$%%'`])dnl
1400 dnl ---------------------------------------------------------------------------
1401 dnl CF_DIRS_TO_MAKE version: 3 updated: 2002/02/23 20:38:31
1402 dnl ---------------
1403 AC_DEFUN([CF_DIRS_TO_MAKE],
1404 [
1405 DIRS_TO_MAKE="lib"
1406 for cf_item in $cf_list_models
1407 do
1408         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1409         for cf_item2 in $DIRS_TO_MAKE
1410         do
1411                 test $cf_item2 = $cf_subdir && break
1412         done
1413         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1414 done
1415 for cf_dir in $DIRS_TO_MAKE
1416 do
1417         test ! -d $cf_dir && mkdir $cf_dir
1418 done
1419 AC_SUBST(DIRS_TO_MAKE)
1420 ])dnl
1421 dnl ---------------------------------------------------------------------------
1422 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1423 dnl ---------------
1424 dnl You can always use "make -n" to see the actual options, but it's hard to
1425 dnl pick out/analyze warning messages when the compile-line is long.
1426 dnl
1427 dnl Sets:
1428 dnl     ECHO_LT - symbol to control if libtool is verbose
1429 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1430 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1431 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1432 dnl     ECHO_CC - symbol to put before any "cc" line
1433 dnl
1434 AC_DEFUN([CF_DISABLE_ECHO],[
1435 AC_MSG_CHECKING(if you want to see long compiling messages)
1436 CF_ARG_DISABLE(echo,
1437         [  --disable-echo          do not display "compiling" commands],
1438         [
1439         ECHO_LT='--silent'
1440         ECHO_LD='@echo linking [$]@;'
1441         RULE_CC='@echo compiling [$]<'
1442         SHOW_CC='@echo compiling [$]@'
1443         ECHO_CC='@'
1444 ],[
1445         ECHO_LT=''
1446         ECHO_LD=''
1447         RULE_CC=''
1448         SHOW_CC=''
1449         ECHO_CC=''
1450 ])
1451 AC_MSG_RESULT($enableval)
1452 AC_SUBST(ECHO_LT)
1453 AC_SUBST(ECHO_LD)
1454 AC_SUBST(RULE_CC)
1455 AC_SUBST(SHOW_CC)
1456 AC_SUBST(ECHO_CC)
1457 ])dnl
1458 dnl ---------------------------------------------------------------------------
1459 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1460 dnl ------------------------
1461 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1462 AC_MSG_CHECKING(if we want to use GNAT projects)
1463 CF_ARG_DISABLE(gnat-projects,
1464         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1465         [enable_gnat_projects=no],
1466         [enable_gnat_projects=yes])
1467 AC_MSG_RESULT($enable_gnat_projects)
1468 ])dnl
1469 dnl ---------------------------------------------------------------------------
1470 dnl CF_DISABLE_LEAKS version: 7 updated: 2012/10/02 20:55:03
1471 dnl ----------------
1472 dnl Combine no-leak checks with the libraries or tools that are used for the
1473 dnl checks.
1474 AC_DEFUN([CF_DISABLE_LEAKS],[
1475
1476 AC_REQUIRE([CF_WITH_DMALLOC])
1477 AC_REQUIRE([CF_WITH_DBMALLOC])
1478 AC_REQUIRE([CF_WITH_VALGRIND])
1479
1480 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1481 AC_ARG_ENABLE(leaks,
1482         [  --disable-leaks         test: free permanent memory, analyze leaks],
1483         [if test "x$enableval" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi],
1484         : ${with_no_leaks:=no})
1485 AC_MSG_RESULT($with_no_leaks)
1486
1487 if test "$with_no_leaks" = yes ; then
1488         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1489         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1490 fi
1491 ])dnl
1492 dnl ---------------------------------------------------------------------------
1493 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
1494 dnl --------------------------
1495 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1496 dnl the older "-version-info" feature.  The newer feature allows us to use
1497 dnl version numbering on shared libraries which make them compatible with
1498 dnl various systems.
1499 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1500 [
1501 AC_MSG_CHECKING(if libtool -version-number should be used)
1502 CF_ARG_DISABLE(libtool-version,
1503         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1504         [cf_libtool_version=no],
1505         [cf_libtool_version=yes])
1506 AC_MSG_RESULT($cf_libtool_version)
1507
1508 if test "$cf_libtool_version" = yes ; then
1509         LIBTOOL_VERSION="-version-number"
1510 else
1511         LIBTOOL_VERSION="-version-info"
1512         case "x$VERSION" in
1513         (x)
1514                 AC_MSG_WARN(VERSION was not set)
1515                 ;;
1516         (x*.*.*)
1517                 ABI_VERSION="$VERSION"
1518                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1519                 ;;
1520         (x*:*:*)
1521                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
1522                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1523                 ;;
1524         (*)
1525                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
1526                 ;;
1527         esac
1528 fi
1529
1530 AC_SUBST(ABI_VERSION)
1531 AC_SUBST(LIBTOOL_VERSION)
1532 ])dnl
1533 dnl ---------------------------------------------------------------------------
1534 dnl CF_DISABLE_RPATH_HACK version: 2 updated: 2011/02/13 13:31:33
1535 dnl ---------------------
1536 dnl The rpath-hack makes it simpler to build programs, particularly with the
1537 dnl *BSD ports which may have essential libraries in unusual places.  But it
1538 dnl can interfere with building an executable for the base system.  Use this
1539 dnl option in that case.
1540 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1541 [
1542 AC_MSG_CHECKING(if rpath-hack should be disabled)
1543 CF_ARG_DISABLE(rpath-hack,
1544         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1545         [cf_disable_rpath_hack=yes],
1546         [cf_disable_rpath_hack=no])
1547 AC_MSG_RESULT($cf_disable_rpath_hack)
1548 if test "$cf_disable_rpath_hack" = no ; then
1549         CF_RPATH_HACK
1550 fi
1551 ])
1552 dnl ---------------------------------------------------------------------------
1553 dnl CF_ENABLE_PC_FILES version: 13 updated: 2015/11/01 05:27:39
1554 dnl ------------------
1555 dnl This is the "--enable-pc-files" option, which is available if there is a
1556 dnl pkg-config configuration on the local machine.
1557 AC_DEFUN([CF_ENABLE_PC_FILES],[
1558 AC_REQUIRE([CF_PKG_CONFIG])
1559 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
1560
1561 if test "x$PKG_CONFIG" != xnone
1562 then
1563         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
1564 else
1565         AC_MSG_CHECKING(if we should install .pc files)
1566 fi
1567
1568 AC_ARG_ENABLE(pc-files,
1569         [  --enable-pc-files       generate and install .pc files for pkg-config],
1570         [enable_pc_files=$enableval],
1571         [enable_pc_files=no])
1572 AC_MSG_RESULT($enable_pc_files)
1573
1574 if test "x$enable_pc_files" != xno
1575 then
1576         MAKE_PC_FILES=
1577         case "x$PKG_CONFIG_LIBDIR" in
1578         (xno|xyes)
1579                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
1580                 ;;
1581         (*)
1582                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
1583                 ;;
1584         esac
1585 else
1586         MAKE_PC_FILES="#"
1587 fi
1588 AC_SUBST(MAKE_PC_FILES)
1589 ])dnl
1590 dnl ---------------------------------------------------------------------------
1591 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
1592 dnl ---------------
1593 dnl Check if the rpath option should be used, setting cache variable
1594 dnl cf_cv_enable_rpath if so.
1595 AC_DEFUN([CF_ENABLE_RPATH],
1596 [
1597 AC_MSG_CHECKING(if rpath option should be used)
1598 AC_ARG_ENABLE(rpath,
1599 [  --enable-rpath          use rpath option when generating shared libraries],
1600 [cf_cv_enable_rpath=$enableval],
1601 [cf_cv_enable_rpath=no])
1602 AC_MSG_RESULT($cf_cv_enable_rpath)
1603 ])dnl
1604 dnl ---------------------------------------------------------------------------
1605 dnl CF_ENABLE_STRING_HACKS version: 5 updated: 2016/10/08 17:34:11
1606 dnl ----------------------
1607 dnl On a few platforms, the compiler and/or loader nags with untruthful
1608 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
1609 dnl and implying that most uses of the recommended alternatives are correct.
1610 dnl
1611 dnl Factually speaking, no one has actually counted the number of uses of these
1612 dnl functions versus the total of incorrect uses.  Samples of a few thousand
1613 dnl instances are meaningless compared to the hundreds of millions of lines of
1614 dnl existing C code.
1615 dnl
1616 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
1617 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
1618 dnl standard - but evolved through phases, and older implementations are likely
1619 dnl to yield surprising results, as documented in manpages on various systems.
1620 AC_DEFUN([CF_ENABLE_STRING_HACKS],
1621 [
1622 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
1623 AC_ARG_ENABLE(string-hacks,
1624         [  --enable-string-hacks   work around bogus compiler/loader warnings],
1625         [with_string_hacks=$enableval],
1626         [with_string_hacks=no])
1627 AC_MSG_RESULT($with_string_hacks)
1628
1629 if test "x$with_string_hacks" = "xyes"; then
1630         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
1631         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
1632         AC_CHECK_FUNC(strlcat,[
1633                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1634                 ],[
1635                 AC_CHECK_LIB(bsd,strlcat,[
1636                         CF_ADD_LIB(bsd)
1637                         AC_CHECK_HEADERS(bsd/string.h)
1638                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
1639                         ])
1640                 ])
1641         AC_CHECK_FUNCS( strlcpy snprintf )
1642 fi
1643 ])dnl
1644 dnl ---------------------------------------------------------------------------
1645 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
1646 dnl --------
1647 dnl Check if 'errno' is declared in <errno.h>
1648 AC_DEFUN([CF_ERRNO],
1649 [
1650 CF_CHECK_ERRNO(errno)
1651 ])dnl
1652 dnl ---------------------------------------------------------------------------
1653 dnl CF_ETIP_DEFINES version: 5 updated: 2012/02/18 17:51:07
1654 dnl ---------------
1655 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
1656 dnl math.h and builtin.h, only for ncurses
1657 AC_DEFUN([CF_ETIP_DEFINES],
1658 [
1659 AC_MSG_CHECKING(for special defines needed for etip.h)
1660 cf_save_CXXFLAGS="$CXXFLAGS"
1661 cf_result="none"
1662
1663 # etip.h includes ncurses.h which includes ncurses_dll.h
1664 # But ncurses_dll.h is generated - fix here.
1665 test -d include || mkdir include
1666 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' ${srcdir}/include/ncurses_dll.h.in >include/ncurses_dll.h
1667
1668 for cf_math in "" MATH_H
1669 do
1670 for cf_excp in "" MATH_EXCEPTION
1671 do
1672         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
1673         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
1674         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
1675 AC_TRY_COMPILE([
1676 #include <etip.h.in>
1677 ],[],[
1678         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
1679         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
1680         cf_result="$cf_math $cf_excp"
1681         break 2
1682 ],[])
1683 done
1684 done
1685 AC_MSG_RESULT($cf_result)
1686 CXXFLAGS="$cf_save_CXXFLAGS"
1687 ])
1688 dnl ---------------------------------------------------------------------------
1689 dnl CF_FIND_LINKAGE version: 20 updated: 2015/04/18 08:56:57
1690 dnl ---------------
1691 dnl Find a library (specifically the linkage used in the code fragment),
1692 dnl searching for it if it is not already in the library path.
1693 dnl See also CF_ADD_SEARCHPATH.
1694 dnl
1695 dnl Parameters (4-on are optional):
1696 dnl     $1 = headers for library entrypoint
1697 dnl     $2 = code fragment for library entrypoint
1698 dnl     $3 = the library name without the "-l" option or ".so" suffix.
1699 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
1700 dnl     $5 = action to perform if not successful
1701 dnl     $6 = module name, if not the same as the library name
1702 dnl     $7 = extra libraries
1703 dnl
1704 dnl Sets these variables:
1705 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
1706 dnl     $cf_cv_header_path_$3 - include-directory if needed
1707 dnl     $cf_cv_library_path_$3 - library-directory if needed
1708 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
1709 AC_DEFUN([CF_FIND_LINKAGE],[
1710
1711 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
1712 # will be set on completion of the AC_TRY_LINK below.
1713 cf_cv_header_path_$3=
1714 cf_cv_library_path_$3=
1715
1716 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
1717
1718 cf_save_LIBS="$LIBS"
1719
1720 AC_TRY_LINK([$1],[$2],[
1721         cf_cv_find_linkage_$3=yes
1722         cf_cv_header_path_$3=/usr/include
1723         cf_cv_library_path_$3=/usr/lib
1724 ],[
1725
1726 LIBS="-l$3 $7 $cf_save_LIBS"
1727
1728 AC_TRY_LINK([$1],[$2],[
1729         cf_cv_find_linkage_$3=yes
1730         cf_cv_header_path_$3=/usr/include
1731         cf_cv_library_path_$3=/usr/lib
1732         cf_cv_library_file_$3="-l$3"
1733 ],[
1734         cf_cv_find_linkage_$3=no
1735         LIBS="$cf_save_LIBS"
1736
1737         CF_VERBOSE(find linkage for $3 library)
1738         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
1739
1740         cf_save_CPPFLAGS="$CPPFLAGS"
1741         cf_test_CPPFLAGS="$CPPFLAGS"
1742
1743         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
1744         for cf_cv_header_path_$3 in $cf_search
1745         do
1746                 if test -d $cf_cv_header_path_$3 ; then
1747                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
1748                         CPPFLAGS="$cf_save_CPPFLAGS -I$cf_cv_header_path_$3"
1749                         AC_TRY_COMPILE([$1],[$2],[
1750                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
1751                                 cf_cv_find_linkage_$3=maybe
1752                                 cf_test_CPPFLAGS="$CPPFLAGS"
1753                                 break],[
1754                                 CPPFLAGS="$cf_save_CPPFLAGS"
1755                                 ])
1756                 fi
1757         done
1758
1759         if test "$cf_cv_find_linkage_$3" = maybe ; then
1760
1761                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
1762
1763                 cf_save_LIBS="$LIBS"
1764                 cf_save_LDFLAGS="$LDFLAGS"
1765
1766                 ifelse([$6],,,[
1767                 CPPFLAGS="$cf_test_CPPFLAGS"
1768                 LIBS="-l$3 $7 $cf_save_LIBS"
1769                 AC_TRY_LINK([$1],[$2],[
1770                         CF_VERBOSE(... found $3 library in system)
1771                         cf_cv_find_linkage_$3=yes])
1772                         CPPFLAGS="$cf_save_CPPFLAGS"
1773                         LIBS="$cf_save_LIBS"
1774                         ])
1775
1776                 if test "$cf_cv_find_linkage_$3" != yes ; then
1777                         CF_LIBRARY_PATH(cf_search,$3)
1778                         for cf_cv_library_path_$3 in $cf_search
1779                         do
1780                                 if test -d $cf_cv_library_path_$3 ; then
1781                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
1782                                         CPPFLAGS="$cf_test_CPPFLAGS"
1783                                         LIBS="-l$3 $7 $cf_save_LIBS"
1784                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
1785                                         AC_TRY_LINK([$1],[$2],[
1786                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
1787                                         cf_cv_find_linkage_$3=yes
1788                                         cf_cv_library_file_$3="-l$3"
1789                                         break],[
1790                                         CPPFLAGS="$cf_save_CPPFLAGS"
1791                                         LIBS="$cf_save_LIBS"
1792                                         LDFLAGS="$cf_save_LDFLAGS"
1793                                         ])
1794                                 fi
1795                         done
1796                         CPPFLAGS="$cf_save_CPPFLAGS"
1797                         LDFLAGS="$cf_save_LDFLAGS"
1798                 fi
1799
1800         else
1801                 cf_cv_find_linkage_$3=no
1802         fi
1803         ],$7)
1804 ])
1805
1806 LIBS="$cf_save_LIBS"
1807
1808 if test "$cf_cv_find_linkage_$3" = yes ; then
1809 ifelse([$4],,[
1810         CF_ADD_INCDIR($cf_cv_header_path_$3)
1811         CF_ADD_LIBDIR($cf_cv_library_path_$3)
1812         CF_ADD_LIB($3)
1813 ],[$4])
1814 else
1815 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
1816 fi
1817 ])dnl
1818 dnl ---------------------------------------------------------------------------
1819 dnl CF_FIND_SUB_INCDIR version: 2 updated: 2015/04/17 21:13:04
1820 dnl ------------------
1821 dnl Find an include-directory with the given leaf-name.  This is useful for
1822 dnl example with FreeBSD ports, which use this convention to distinguish
1823 dnl different versions of the same port.
1824 AC_DEFUN([CF_FIND_SUB_INCDIR],[
1825         CF_SUBDIR_PATH(cf_search,$1,include)
1826         for cf_item in $cf_search
1827         do
1828                 case $cf_item in
1829                 (*/$1)
1830                         CF_ADD_INCDIR($cf_item)
1831                         ;;
1832                 esac
1833         done
1834 ])dnl
1835 dnl ---------------------------------------------------------------------------
1836 dnl CF_FIND_SUB_LIBDIR version: 2 updated: 2015/04/17 21:13:04
1837 dnl ------------------
1838 dnl Find a library-directory with the given leaf-name.  This is useful for
1839 dnl example with FreeBSD ports, which use this convention to distinguish
1840 dnl different versions of the same port.
1841 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
1842         CF_SUBDIR_PATH(cf_search,$1,lib)
1843         for cf_item in $cf_search
1844         do
1845                 case $cf_item in
1846                 (*/$1)
1847                         CF_ADD_LIBDIR($cf_item)
1848                         ;;
1849                 esac
1850         done
1851 ])dnl
1852 dnl ---------------------------------------------------------------------------
1853 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
1854 dnl -----------------
1855 dnl make ADAFLAGS consistent with CFLAGS
1856 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
1857         AC_MSG_CHECKING(optimization options for ADAFLAGS)
1858         case "$CFLAGS" in
1859         (*-g*)
1860                 CF_ADD_ADAFLAGS(-g)
1861                 ;;
1862         esac
1863         case "$CFLAGS" in
1864         (*-O*)
1865                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
1866                 CF_ADD_ADAFLAGS($cf_O_flag)
1867                 ;;
1868         esac
1869         AC_MSG_RESULT($ADAFLAGS)
1870 ])dnl
1871 dnl ---------------------------------------------------------------------------
1872 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
1873 dnl --------------
1874 dnl Forget that we saw the given tool.
1875 AC_DEFUN([CF_FORGET_TOOL],[
1876 unset ac_cv_prog_ac_ct_$1
1877 unset ac_ct_$1
1878 unset $1
1879 ])dnl
1880 dnl ---------------------------------------------------------------------------
1881 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
1882 dnl -------------
1883 dnl Test for dlsym() and related functions, as well as libdl.
1884 dnl
1885 dnl Sets
1886 dnl     $cf_have_dlsym
1887 dnl     $cf_have_libdl
1888 AC_DEFUN([CF_FUNC_DLSYM],[
1889 cf_have_dlsym=no
1890 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
1891
1892 cf_have_libdl=no
1893 AC_CHECK_LIB(dl,dlsym,[
1894         cf_have_dlsym=yes
1895         cf_have_libdl=yes])])
1896
1897 if test "$cf_have_dlsym" = yes ; then
1898         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
1899
1900         AC_MSG_CHECKING(whether able to link to dl*() functions)
1901         AC_TRY_LINK([#include <dlfcn.h>],[
1902                 void *obj;
1903                 if ((obj = dlopen("filename", 0)) != 0) {
1904                         if (dlsym(obj, "symbolname") == 0) {
1905                         dlclose(obj);
1906                         }
1907                 }],[
1908                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
1909                 AC_MSG_ERROR(Cannot link test program for libdl)])
1910         AC_MSG_RESULT(ok)
1911 else
1912         AC_MSG_ERROR(Cannot find dlsym function)
1913 fi
1914 ])
1915 dnl ---------------------------------------------------------------------------
1916 dnl CF_FUNC_MEMMOVE version: 9 updated: 2017/01/21 11:06:25
1917 dnl ---------------
1918 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
1919 dnl is found, add our own version of memmove to the list of objects.
1920 AC_DEFUN([CF_FUNC_MEMMOVE],
1921 [
1922 AC_CHECK_FUNC(memmove,,[
1923 AC_CHECK_FUNC(bcopy,[
1924         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
1925                 AC_TRY_RUN([
1926 int main(void) {
1927         static char data[] = "abcdefghijklmnopqrstuwwxyz";
1928         char temp[40];
1929         bcopy(data, temp, sizeof(data));
1930         bcopy(temp+10, temp, 15);
1931         bcopy(temp+5, temp+15, 10);
1932         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
1933 }
1934                 ],
1935                 [cf_cv_good_bcopy=yes],
1936                 [cf_cv_good_bcopy=no],
1937                 [cf_cv_good_bcopy=unknown])
1938                 ])
1939         ],[cf_cv_good_bcopy=no])
1940         if test "$cf_cv_good_bcopy" = yes ; then
1941                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
1942         else
1943                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
1944         fi
1945 ])])dnl
1946 dnl ---------------------------------------------------------------------------
1947 dnl CF_FUNC_NANOSLEEP version: 5 updated: 2017/01/21 11:06:25
1948 dnl -----------------
1949 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
1950 dnl AIX 4.x, provide a non-working version.
1951 AC_DEFUN([CF_FUNC_NANOSLEEP],[
1952 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
1953 AC_TRY_RUN([
1954 #include <stdio.h>
1955 #include <errno.h>
1956 #include <time.h>
1957
1958 #ifdef HAVE_SYS_TIME_H
1959 #include <sys/time.h>
1960 #endif
1961
1962 int main(void) {
1963         struct timespec ts1, ts2;
1964         int code;
1965         ts1.tv_sec  = 0;
1966         ts1.tv_nsec = 750000000;
1967         ts2.tv_sec  = 0;
1968         ts2.tv_nsec = 0;
1969         errno = 0;
1970         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
1971         ${cf_cv_main_return:-return}(code != 0);
1972 }
1973 ],
1974         [cf_cv_func_nanosleep=yes],
1975         [cf_cv_func_nanosleep=no],
1976         [cf_cv_func_nanosleep=unknown])])
1977
1978 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
1979 ])
1980 dnl ---------------------------------------------------------------------------
1981 dnl CF_FUNC_OPENPTY version: 5 updated: 2015/09/12 14:46:50
1982 dnl ---------------
1983 dnl Check for openpty() function, along with <pty.h> header.  It may need the
1984 dnl "util" library as well.
1985 AC_DEFUN([CF_FUNC_OPENPTY],
1986 [
1987 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
1988 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
1989         cf_save_LIBS="$LIBS"
1990         test $cf_cv_lib_util = yes && { CF_ADD_LIB(util) }
1991         for cf_header in pty.h libutil.h util.h
1992         do
1993         AC_TRY_LINK([
1994 #include <$cf_header>
1995 ],[
1996         int x = openpty((int *)0, (int *)0, (char *)0,
1997                                    (struct termios *)0, (struct winsize *)0);
1998 ],[
1999                 cf_cv_func_openpty=$cf_header
2000                 break
2001 ],[
2002                 cf_cv_func_openpty=no
2003 ])
2004         done
2005         LIBS="$cf_save_LIBS"
2006 ])
2007 ])dnl
2008 dnl ---------------------------------------------------------------------------
2009 dnl CF_FUNC_POLL version: 9 updated: 2015/10/10 13:27:32
2010 dnl ------------
2011 dnl See if the poll function really works.  Some platforms have poll(), but
2012 dnl it does not work for terminals or files.
2013 AC_DEFUN([CF_FUNC_POLL],[
2014 tty 2>&1 >/dev/null || { AC_CHECK_FUNCS(posix_openpt) }
2015 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
2016 AC_TRY_RUN([
2017 #include <stdlib.h>
2018 #include <stdio.h>
2019 #include <unistd.h>
2020 #include <fcntl.h>
2021 #ifdef HAVE_POLL_H
2022 #include <poll.h>
2023 #else
2024 #include <sys/poll.h>
2025 #endif
2026 int main(void) {
2027         struct pollfd myfds;
2028         int ret;
2029
2030         /* check for Darwin bug with respect to "devices" */
2031         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
2032         if (myfds.fd < 0)
2033                 myfds.fd = 0;
2034         myfds.events = POLLIN;
2035         myfds.revents = 0;
2036
2037         ret = poll(&myfds, 1, 100);
2038
2039         if (ret < 0 || (myfds.revents & POLLNVAL)) {
2040                 ret = -1;
2041         } else {
2042                 int fd = 0;
2043                 if (!isatty(fd)) {
2044                         fd = open("/dev/tty", 2);       /* O_RDWR */
2045                 }
2046 #ifdef HAVE_POSIX_OPENPT
2047                 if (fd < 0) {
2048                         fd = posix_openpt(O_RDWR);
2049                 }
2050 #endif
2051
2052                 if (fd >= 0) {
2053                         /* also check with standard input */
2054                         myfds.fd = fd;
2055                         myfds.events = POLLIN;
2056                         myfds.revents = 0;
2057                         ret = poll(&myfds, 1, 100);
2058                 } else {
2059                         ret = -1;
2060                 }
2061         }
2062         ${cf_cv_main_return:-return}(ret < 0);
2063 }],
2064         [cf_cv_working_poll=yes],
2065         [cf_cv_working_poll=no],
2066         [cf_cv_working_poll=unknown])])
2067 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
2068 ])dnl
2069 dnl ---------------------------------------------------------------------------
2070 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
2071 dnl ---------------
2072 dnl Some old/broken variations define tcgetattr() only as a macro in
2073 dnl termio(s).h
2074 AC_DEFUN([CF_FUNC_TERMIOS],[
2075 AC_REQUIRE([CF_STRUCT_TERMIOS])
2076 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
2077 AC_TRY_LINK([
2078 #include <sys/types.h>
2079 #ifdef HAVE_UNISTD_H
2080 #include <unistd.h>
2081 #endif
2082 #ifdef HAVE_TERMIOS_H
2083 #include <termios.h>
2084 #define TTY struct termios
2085 #else
2086 #ifdef HAVE_TERMIO_H
2087 #include <termio.h>
2088 #define TTY struct termio
2089 #endif
2090 #endif
2091 ],[
2092 TTY foo;
2093 tcgetattr(1, &foo);],
2094 [cf_cv_have_tcgetattr=yes],
2095 [cf_cv_have_tcgetattr=no])])
2096 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
2097 ])dnl
2098 dnl ---------------------------------------------------------------------------
2099 dnl CF_FUNC_VSSCANF version: 6 updated: 2015/04/18 08:56:57
2100 dnl ---------------
2101 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
2102 dnl versions of C.  It is in the GNU C library, and can often be simulated by
2103 dnl other functions.
2104 AC_DEFUN([CF_FUNC_VSSCANF],
2105 [
2106 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
2107 AC_TRY_LINK([
2108 #include <stdarg.h>
2109 #include <stdio.h>],[
2110         va_list ap;
2111         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
2112 AC_TRY_LINK([
2113 #include <stdarg.h>
2114 #include <stdio.h>],[
2115         FILE strbuf;
2116         char *str = "from";
2117
2118         strbuf._flag = _IOREAD;
2119         strbuf._ptr = strbuf._base = (unsigned char *) str;
2120         strbuf._cnt = strlen(str);
2121         strbuf._file = _NFILE;
2122         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
2123 AC_TRY_LINK([
2124 #include <stdarg.h>
2125 #include <stdio.h>],[
2126         FILE strbuf;
2127         char *str = "from";
2128
2129         strbuf._flag = _IOREAD;
2130         strbuf._ptr = strbuf._base = (unsigned char *) str;
2131         strbuf._cnt = strlen(str);
2132         strbuf._file = _NFILE;
2133         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
2134 cf_cv_func_vsscanf=no])])])])
2135
2136 case $cf_cv_func_vsscanf in
2137 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
2138 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
2139 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
2140 esac
2141
2142 ])dnl
2143 dnl ---------------------------------------------------------------------------
2144 dnl CF_GCC_ATTRIBUTES version: 17 updated: 2015/04/12 15:39:00
2145 dnl -----------------
2146 dnl Test for availability of useful gcc __attribute__ directives to quiet
2147 dnl compiler warnings.  Though useful, not all are supported -- and contrary
2148 dnl to documentation, unrecognized directives cause older compilers to barf.
2149 AC_DEFUN([CF_GCC_ATTRIBUTES],
2150 [
2151 if test "$GCC" = yes
2152 then
2153 cat > conftest.i <<EOF
2154 #ifndef GCC_PRINTF
2155 #define GCC_PRINTF 0
2156 #endif
2157 #ifndef GCC_SCANF
2158 #define GCC_SCANF 0
2159 #endif
2160 #ifndef GCC_NORETURN
2161 #define GCC_NORETURN /* nothing */
2162 #endif
2163 #ifndef GCC_UNUSED
2164 #define GCC_UNUSED /* nothing */
2165 #endif
2166 EOF
2167 if test "$GCC" = yes
2168 then
2169         AC_CHECKING([for $CC __attribute__ directives])
2170 cat > conftest.$ac_ext <<EOF
2171 #line __oline__ "${as_me:-configure}"
2172 #include "confdefs.h"
2173 #include "conftest.h"
2174 #include "conftest.i"
2175 #if     GCC_PRINTF
2176 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
2177 #else
2178 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
2179 #endif
2180 #if     GCC_SCANF
2181 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2182 #else
2183 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2184 #endif
2185 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2186 extern void oops(char *,...) GCC_PRINTFLIKE(1,2) GCC_NORETURN;
2187 extern void foo(void) GCC_NORETURN;
2188 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { return 0; }
2189 EOF
2190         cf_printf_attribute=no
2191         cf_scanf_attribute=no
2192         for cf_attribute in scanf printf unused noreturn
2193         do
2194                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2195                 cf_directive="__attribute__(($cf_attribute))"
2196                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2197
2198                 case $cf_attribute in
2199                 (printf)
2200                         cf_printf_attribute=yes
2201                         cat >conftest.h <<EOF
2202 #define GCC_$cf_ATTRIBUTE 1
2203 EOF
2204                         ;;
2205                 (scanf)
2206                         cf_scanf_attribute=yes
2207                         cat >conftest.h <<EOF
2208 #define GCC_$cf_ATTRIBUTE 1
2209 EOF
2210                         ;;
2211                 (*)
2212                         cat >conftest.h <<EOF
2213 #define GCC_$cf_ATTRIBUTE $cf_directive
2214 EOF
2215                         ;;
2216                 esac
2217
2218                 if AC_TRY_EVAL(ac_compile); then
2219                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
2220                         cat conftest.h >>confdefs.h
2221                         case $cf_attribute in
2222                         (noreturn)
2223                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
2224                                 ;;
2225                         (printf)
2226                                 cf_value='/* nothing */'
2227                                 if test "$cf_printf_attribute" != no ; then
2228                                         cf_value='__attribute__((format(printf,fmt,var)))'
2229                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
2230                                 fi
2231                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
2232                                 ;;
2233                         (scanf)
2234                                 cf_value='/* nothing */'
2235                                 if test "$cf_scanf_attribute" != no ; then
2236                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2237                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2238                                 fi
2239                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2240                                 ;;
2241                         (unused)
2242                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2243                                 ;;
2244                         esac
2245                 fi
2246         done
2247 else
2248         fgrep define conftest.i >>confdefs.h
2249 fi
2250 rm -rf conftest*
2251 fi
2252 ])dnl
2253 dnl ---------------------------------------------------------------------------
2254 dnl CF_GCC_VERSION version: 7 updated: 2012/10/18 06:46:33
2255 dnl --------------
2256 dnl Find version of gcc
2257 AC_DEFUN([CF_GCC_VERSION],[
2258 AC_REQUIRE([AC_PROG_CC])
2259 GCC_VERSION=none
2260 if test "$GCC" = yes ; then
2261         AC_MSG_CHECKING(version of $CC)
2262         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2263         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2264         AC_MSG_RESULT($GCC_VERSION)
2265 fi
2266 ])dnl
2267 dnl ---------------------------------------------------------------------------
2268 dnl CF_GCC_WARNINGS version: 32 updated: 2015/04/12 15:39:00
2269 dnl ---------------
2270 dnl Check if the compiler supports useful warning options.  There's a few that
2271 dnl we don't use, simply because they're too noisy:
2272 dnl
2273 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2274 dnl     -Wredundant-decls (system headers make this too noisy)
2275 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2276 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2277 dnl             is enabled for ncurses using "--enable-const".
2278 dnl     -pedantic
2279 dnl
2280 dnl Parameter:
2281 dnl     $1 is an optional list of gcc warning flags that a particular
2282 dnl             application might want to use, e.g., "no-unused" for
2283 dnl             -Wno-unused
2284 dnl Special:
2285 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2286 dnl
2287 AC_DEFUN([CF_GCC_WARNINGS],
2288 [
2289 AC_REQUIRE([CF_GCC_VERSION])
2290 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2291 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2292
2293 cat > conftest.$ac_ext <<EOF
2294 #line __oline__ "${as_me:-configure}"
2295 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2296 EOF
2297
2298 if test "$INTEL_COMPILER" = yes
2299 then
2300 # The "-wdXXX" options suppress warnings:
2301 # remark #1419: external declaration in primary source file
2302 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2303 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2304 # remark #193: zero used for undefined preprocessing identifier
2305 # remark #593: variable "curs_sb_left_arrow" was set but never used
2306 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2307 # remark #869: parameter "tw" was never referenced
2308 # remark #981: operands are evaluated in unspecified order
2309 # warning #279: controlling expression is constant
2310
2311         AC_CHECKING([for $CC warning options])
2312         cf_save_CFLAGS="$CFLAGS"
2313         EXTRA_CFLAGS="-Wall"
2314         for cf_opt in \
2315                 wd1419 \
2316                 wd1683 \
2317                 wd1684 \
2318                 wd193 \
2319                 wd593 \
2320                 wd279 \
2321                 wd810 \
2322                 wd869 \
2323                 wd981
2324         do
2325                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2326                 if AC_TRY_EVAL(ac_compile); then
2327                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2328                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2329                 fi
2330         done
2331         CFLAGS="$cf_save_CFLAGS"
2332
2333 elif test "$GCC" = yes
2334 then
2335         AC_CHECKING([for $CC warning options])
2336         cf_save_CFLAGS="$CFLAGS"
2337         EXTRA_CFLAGS=
2338         cf_warn_CONST=""
2339         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2340         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2341         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2342         for cf_opt in W Wall \
2343                 Wbad-function-cast \
2344                 Wcast-align \
2345                 Wcast-qual \
2346                 Wdeclaration-after-statement \
2347                 Wextra \
2348                 Winline \
2349                 Wmissing-declarations \
2350                 Wmissing-prototypes \
2351                 Wnested-externs \
2352                 Wpointer-arith \
2353                 Wshadow \
2354                 Wstrict-prototypes \
2355                 Wundef $cf_gcc_warnings $cf_warn_CONST $1
2356         do
2357                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2358                 if AC_TRY_EVAL(ac_compile); then
2359                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2360                         case $cf_opt in
2361                         (Wcast-qual)
2362                                 CPPFLAGS="$CPPFLAGS -DXTSTRINGDEFINES"
2363                                 ;;
2364                         (Winline)
2365                                 case $GCC_VERSION in
2366                                 ([[34]].*)
2367                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2368                                         continue;;
2369                                 esac
2370                                 ;;
2371                         (Wpointer-arith)
2372                                 case $GCC_VERSION in
2373                                 ([[12]].*)
2374                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2375                                         continue;;
2376                                 esac
2377                                 ;;
2378                         esac
2379                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2380                 fi
2381         done
2382         CFLAGS="$cf_save_CFLAGS"
2383 fi
2384 rm -rf conftest*
2385
2386 AC_SUBST(EXTRA_CFLAGS)
2387 ])dnl
2388 dnl ---------------------------------------------------------------------------
2389 dnl CF_GETOPT_HEADER version: 6 updated: 2014/07/22 14:45:54
2390 dnl ----------------
2391 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2392 dnl unistd.h or (nonstandard) in getopt.h
2393 AC_DEFUN([CF_GETOPT_HEADER],
2394 [
2395 AC_HAVE_HEADERS(unistd.h getopt.h)
2396 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2397 cf_cv_getopt_header=none
2398 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2399 do
2400 AC_TRY_COMPILE([
2401 #include <$cf_header>],
2402 [int x = optind; char *y = optarg],
2403 [cf_cv_getopt_header=$cf_header
2404  break])
2405 done
2406 ])
2407 if test $cf_cv_getopt_header != none ; then
2408         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2409 fi
2410 if test $cf_cv_getopt_header = getopt.h ; then
2411         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2412 fi
2413 ])dnl
2414 dnl ---------------------------------------------------------------------------
2415 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2416 dnl -----------------
2417 AC_DEFUN([CF_GNATPREP_OPT_T],[
2418 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2419 cf_cv_gnatprep_opt_t=no
2420 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2421 ])
2422 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
2423 AC_SUBST(GNATPREP_OPTS)
2424 ])dnl
2425 dnl ---------------------------------------------------------------------------
2426 dnl CF_GNAT_GENERICS version: 3 updated: 2015/04/17 21:13:04
2427 dnl ----------------
2428 AC_DEFUN([CF_GNAT_GENERICS],
2429 [
2430 AC_REQUIRE([CF_GNAT_VERSION])
2431
2432 AC_MSG_CHECKING(if GNAT supports generics)
2433 case $cf_gnat_version in
2434 (3.[[1-9]]*|[[4-9]].*)
2435         cf_gnat_generics=yes
2436         ;;
2437 (*)
2438         cf_gnat_generics=no
2439         ;;
2440 esac
2441 AC_MSG_RESULT($cf_gnat_generics)
2442
2443 if test "$cf_gnat_generics" = yes
2444 then
2445         cf_compile_generics=generics
2446         cf_generic_objects="\${GENOBJS}"
2447 else
2448         cf_compile_generics=
2449         cf_generic_objects=
2450 fi
2451
2452 AC_SUBST(cf_compile_generics)
2453 AC_SUBST(cf_generic_objects)
2454 ])dnl
2455 dnl ---------------------------------------------------------------------------
2456 dnl CF_GNAT_PROJECTS version: 8 updated: 2015/04/17 21:13:04
2457 dnl ----------------
2458 dnl GNAT projects are configured with ".gpr" project files.
2459 dnl GNAT libraries are a further development, using the project feature.
2460 AC_DEFUN([CF_GNAT_PROJECTS],
2461 [
2462 AC_REQUIRE([CF_GNAT_VERSION])
2463 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
2464
2465 cf_gnat_libraries=no
2466 cf_gnat_projects=no
2467
2468 if test "$enable_gnat_projects" != no ; then
2469 AC_MSG_CHECKING(if GNAT supports project files)
2470 case $cf_gnat_version in
2471 (3.[[0-9]]*)
2472         ;;
2473 (*)
2474         case $cf_cv_system_name in
2475         (cygwin*|msys*)
2476                 ;;
2477         (*)
2478                 mkdir conftest.src conftest.bin conftest.lib
2479                 cd conftest.src
2480                 rm -rf conftest* *~conftest*
2481                 cat >>library.gpr <<CF_EOF
2482 project Library is
2483   Kind := External ("LIB_KIND");
2484   for Library_Name use "ConfTest";
2485   for Object_Dir use ".";
2486   for Library_ALI_Dir use External("LIBRARY_DIR");
2487   for Library_Version use External ("SONAME");
2488   for Library_Kind use Kind;
2489   for Library_Dir use External("BUILD_DIR");
2490   Source_Dir := External ("SOURCE_DIR");
2491   for Source_Dirs use (Source_Dir);
2492 end Library;
2493 CF_EOF
2494                 cat >>confpackage.ads <<CF_EOF
2495 package ConfPackage is
2496    procedure conftest;
2497 end ConfPackage;
2498 CF_EOF
2499                 cat >>confpackage.adb <<CF_EOF
2500 with Text_IO;
2501 package body ConfPackage is
2502    procedure conftest is
2503    begin
2504       Text_IO.Put ("Hello World");
2505       Text_IO.New_Line;
2506    end conftest;
2507 end ConfPackage;
2508 CF_EOF
2509                 if ( $cf_ada_make $ADAFLAGS \
2510                                 -Plibrary.gpr \
2511                                 -XBUILD_DIR=`cd ../conftest.bin;pwd` \
2512                                 -XLIBRARY_DIR=`cd ../conftest.lib;pwd` \
2513                                 -XSOURCE_DIR=`pwd` \
2514                                 -XSONAME=libConfTest.so.1 \
2515                                 -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
2516                         cf_gnat_projects=yes
2517                 fi
2518                 cd ..
2519                 if test -f conftest.lib/confpackage.ali
2520                 then
2521                         cf_gnat_libraries=yes
2522                 fi
2523                 rm -rf conftest* *~conftest*
2524                 ;;
2525         esac
2526         ;;
2527 esac
2528 AC_MSG_RESULT($cf_gnat_projects)
2529 fi # enable_gnat_projects
2530
2531 if test $cf_gnat_projects = yes
2532 then
2533         AC_MSG_CHECKING(if GNAT supports libraries)
2534         AC_MSG_RESULT($cf_gnat_libraries)
2535 fi
2536
2537 if test "$cf_gnat_projects" = yes
2538 then
2539         USE_OLD_MAKERULES="#"
2540         USE_GNAT_PROJECTS=""
2541 else
2542         USE_OLD_MAKERULES=""
2543         USE_GNAT_PROJECTS="#"
2544 fi
2545
2546 if test "$cf_gnat_libraries" = yes
2547 then
2548         USE_GNAT_LIBRARIES=""
2549 else
2550         USE_GNAT_LIBRARIES="#"
2551 fi
2552
2553 AC_SUBST(USE_OLD_MAKERULES)
2554 AC_SUBST(USE_GNAT_PROJECTS)
2555 AC_SUBST(USE_GNAT_LIBRARIES)
2556 ])dnl
2557 dnl ---------------------------------------------------------------------------
2558 dnl CF_GNAT_SIGINT version: 1 updated: 2011/03/27 20:07:59
2559 dnl --------------
2560 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
2561 dnl is noted that gnat may compile a tasking unit even for configurations which
2562 dnl fail at runtime.
2563 AC_DEFUN([CF_GNAT_SIGINT],[
2564 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
2565 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
2566
2567 package ConfTest is
2568
2569    pragma Warnings (Off);  --  the next pragma exists since 3.11p
2570    pragma Unreserve_All_Interrupts;
2571    pragma Warnings (On);
2572
2573    protected Process is
2574       procedure Stop;
2575       function Continue return Boolean;
2576       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
2577    private
2578       Done : Boolean := False;
2579    end Process;
2580
2581 end ConfTest;],
2582 [package body ConfTest is
2583    protected body Process is
2584       procedure Stop is
2585       begin
2586          Done := True;
2587       end Stop;
2588       function Continue return Boolean is
2589       begin
2590          return not Done;
2591       end Continue;
2592    end Process;
2593 end ConfTest;],
2594         [cf_cv_gnat_sigint=yes],
2595         [cf_cv_gnat_sigint=no])])
2596
2597 if test $cf_cv_gnat_sigint = yes ; then
2598         USE_GNAT_SIGINT=""
2599 else
2600         USE_GNAT_SIGINT="#"
2601 fi
2602 AC_SUBST(USE_GNAT_SIGINT)
2603 ])dnl
2604 dnl ---------------------------------------------------------------------------
2605 dnl CF_GNAT_TRY_LINK version: 3 updated: 2011/03/19 14:47:45
2606 dnl ----------------
2607 dnl Verify that a test program compiles/links with GNAT.
2608 dnl $cf_ada_make is set to the program that compiles/links
2609 dnl $ADAFLAGS may be set to the GNAT flags.
2610 dnl
2611 dnl $1 is the text of the spec
2612 dnl $2 is the text of the body
2613 dnl $3 is the shell command to execute if successful
2614 dnl $4 is the shell command to execute if not successful
2615 AC_DEFUN([CF_GNAT_TRY_LINK],
2616 [
2617 rm -rf conftest* *~conftest*
2618 cat >>conftest.ads <<CF_EOF
2619 $1
2620 CF_EOF
2621 cat >>conftest.adb <<CF_EOF
2622 $2
2623 CF_EOF
2624 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2625 ifelse($3,,      :,[      $3])
2626 ifelse($4,,,[else
2627    $4])
2628 fi
2629 rm -rf conftest* *~conftest*
2630 ])dnl
2631 dnl ---------------------------------------------------------------------------
2632 dnl CF_GNAT_TRY_RUN version: 5 updated: 2011/03/19 14:47:45
2633 dnl ---------------
2634 dnl Verify that a test program compiles and runs with GNAT
2635 dnl $cf_ada_make is set to the program that compiles/links
2636 dnl $ADAFLAGS may be set to the GNAT flags.
2637 dnl
2638 dnl $1 is the text of the spec
2639 dnl $2 is the text of the body
2640 dnl $3 is the shell command to execute if successful
2641 dnl $4 is the shell command to execute if not successful
2642 AC_DEFUN([CF_GNAT_TRY_RUN],
2643 [
2644 rm -rf conftest* *~conftest*
2645 cat >>conftest.ads <<CF_EOF
2646 $1
2647 CF_EOF
2648 cat >>conftest.adb <<CF_EOF
2649 $2
2650 CF_EOF
2651 if ( $cf_ada_make $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
2652    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
2653 ifelse($3,,      :,[      $3])
2654 ifelse($4,,,[   else
2655       $4])
2656    fi
2657 ifelse($4,,,[else
2658    $4])
2659 fi
2660 rm -rf conftest* *~conftest*
2661 ])dnl
2662 dnl ---------------------------------------------------------------------------
2663 dnl CF_GNAT_VERSION version: 20 updated: 2015/04/18 08:56:57
2664 dnl ---------------
2665 dnl Verify version of GNAT.
2666 AC_DEFUN([CF_GNAT_VERSION],
2667 [
2668 AC_MSG_CHECKING(for gnat version)
2669 cf_gnat_version=`${cf_ada_make:-gnatmake} -v 2>&1 | \
2670         grep '[[0-9]].[[0-9]][[0-9]]*' |\
2671         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
2672 AC_MSG_RESULT($cf_gnat_version)
2673
2674 case $cf_gnat_version in
2675 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|20[[0-9]][[0-9]])
2676         cf_cv_prog_gnat_correct=yes
2677         ;;
2678 (*)
2679         AC_MSG_WARN(Unsupported GNAT version $cf_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
2680         cf_cv_prog_gnat_correct=no
2681         ;;
2682 esac
2683 ])
2684 dnl ---------------------------------------------------------------------------
2685 dnl CF_GNU_SOURCE version: 7 updated: 2016/08/05 05:15:37
2686 dnl -------------
2687 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
2688 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
2689 dnl (or misfeature) of glibc2, which breaks portability of many applications,
2690 dnl since it is interwoven with GNU extensions.
2691 dnl
2692 dnl Well, yes we could work around it...
2693 AC_DEFUN([CF_GNU_SOURCE],
2694 [
2695 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
2696 AC_TRY_COMPILE([#include <sys/types.h>],[
2697 #ifndef _XOPEN_SOURCE
2698 make an error
2699 #endif],
2700         [cf_cv_gnu_source=no],
2701         [cf_save="$CPPFLAGS"
2702          CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2703          AC_TRY_COMPILE([#include <sys/types.h>],[
2704 #ifdef _XOPEN_SOURCE
2705 make an error
2706 #endif],
2707         [cf_cv_gnu_source=no],
2708         [cf_cv_gnu_source=yes])
2709         CPPFLAGS="$cf_save"
2710         ])
2711 ])
2712
2713 if test "$cf_cv_gnu_source" = yes
2714 then
2715 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
2716 CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
2717         AC_TRY_COMPILE([#include <sys/types.h>],[
2718 #ifdef _DEFAULT_SOURCE
2719 make an error
2720 #endif],
2721                 [cf_cv_default_source=no],
2722                 [cf_cv_default_source=yes])
2723         ])
2724 test "$cf_cv_default_source" = yes && CPPFLAGS="$CPPFLAGS -D_DEFAULT_SOURCE"
2725 fi
2726 ])dnl
2727 dnl ---------------------------------------------------------------------------
2728 dnl CF_GPP_LIBRARY version: 12 updated: 2015/04/17 21:13:04
2729 dnl --------------
2730 dnl If we're trying to use g++, test if libg++ is installed (a rather common
2731 dnl problem :-).  If we have the compiler but no library, we'll be able to
2732 dnl configure, but won't be able to build the c++ demo program.
2733 AC_DEFUN([CF_GPP_LIBRARY],
2734 [
2735 cf_cxx_library=unknown
2736 case $cf_cv_system_name in
2737 (os2*)
2738         cf_gpp_libname=gpp
2739         ;;
2740 (*)
2741         cf_gpp_libname=g++
2742         ;;
2743 esac
2744 if test "$GXX" = yes; then
2745         AC_MSG_CHECKING([for lib$cf_gpp_libname])
2746         cf_save="$LIBS"
2747         CF_ADD_LIB($cf_gpp_libname)
2748         AC_TRY_LINK([
2749 #include <$cf_gpp_libname/builtin.h>
2750         ],
2751         [two_arg_error_handler_t foo2 = lib_error_handler],
2752         [cf_cxx_library=yes
2753          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2754          if test "$cf_gpp_libname" = cpp ; then
2755             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
2756          else
2757             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
2758          fi],
2759         [AC_TRY_LINK([
2760 #include <builtin.h>
2761         ],
2762         [two_arg_error_handler_t foo2 = lib_error_handler],
2763         [cf_cxx_library=yes
2764          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
2765          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
2766         [cf_cxx_library=no])])
2767         LIBS="$cf_save"
2768         AC_MSG_RESULT($cf_cxx_library)
2769 fi
2770 ])dnl
2771 dnl ---------------------------------------------------------------------------
2772 dnl CF_GXX_VERSION version: 7 updated: 2012/06/16 14:55:39
2773 dnl --------------
2774 dnl Check for version of g++
2775 AC_DEFUN([CF_GXX_VERSION],[
2776 AC_REQUIRE([AC_PROG_CPP])
2777 GXX_VERSION=none
2778 if test "$GXX" = yes; then
2779         AC_MSG_CHECKING(version of ${CXX:-g++})
2780         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2781         test -z "$GXX_VERSION" && GXX_VERSION=unknown
2782         AC_MSG_RESULT($GXX_VERSION)
2783 fi
2784 ])dnl
2785 dnl ---------------------------------------------------------------------------
2786 dnl CF_GXX_WARNINGS version: 9 updated: 2015/04/17 21:13:04
2787 dnl ---------------
2788 dnl Check if the compiler supports useful warning options.
2789 dnl
2790 dnl Most of gcc's options apply to g++, except:
2791 dnl     -Wbad-function-cast
2792 dnl     -Wmissing-declarations
2793 dnl     -Wnested-externs
2794 dnl
2795 dnl Omit a few (for now):
2796 dnl     -Winline
2797 dnl
2798 dnl Parameter:
2799 dnl     $1 is an optional list of g++ warning flags that a particular
2800 dnl             application might want to use, e.g., "no-unused" for
2801 dnl             -Wno-unused
2802 dnl Special:
2803 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2804 dnl
2805 AC_DEFUN([CF_GXX_WARNINGS],
2806 [
2807
2808 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
2809 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
2810
2811 AC_REQUIRE([CF_GXX_VERSION])
2812
2813 AC_LANG_SAVE
2814 AC_LANG_CPLUSPLUS
2815
2816 cat > conftest.$ac_ext <<EOF
2817 #line __oline__ "configure"
2818 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2819 EOF
2820
2821 if test "$INTEL_CPLUSPLUS" = yes
2822 then
2823 # The "-wdXXX" options suppress warnings:
2824 # remark #1419: external declaration in primary source file
2825 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2826 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2827 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2828 # remark #193: zero used for undefined preprocessing identifier
2829 # remark #593: variable "curs_sb_left_arrow" was set but never used
2830 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2831 # remark #869: parameter "tw" was never referenced
2832 # remark #981: operands are evaluated in unspecified order
2833 # warning #269: invalid format string conversion
2834
2835         AC_CHECKING([for $CC warning options])
2836         cf_save_CXXFLAGS="$CXXFLAGS"
2837         EXTRA_CXXFLAGS="-Wall"
2838         for cf_opt in \
2839                 wd1419 \
2840                 wd1682 \
2841                 wd1683 \
2842                 wd1684 \
2843                 wd193 \
2844                 wd279 \
2845                 wd593 \
2846                 wd810 \
2847                 wd869 \
2848                 wd981
2849         do
2850                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
2851                 if AC_TRY_EVAL(ac_compile); then
2852                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2853                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2854                 fi
2855         done
2856         CXXFLAGS="$cf_save_CXXFLAGS"
2857
2858 elif test "$GXX" = yes
2859 then
2860         AC_CHECKING([for $CXX warning options])
2861         cf_save_CXXFLAGS="$CXXFLAGS"
2862         EXTRA_CXXFLAGS="-W -Wall"
2863         cf_gxx_extra_warnings=""
2864         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
2865         case "$GCC_VERSION" in
2866         ([[1-2]].*)
2867                 ;;
2868         (*)
2869                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
2870                 ;;
2871         esac
2872         for cf_opt in \
2873                 Wabi \
2874                 fabi-version=0 \
2875                 Wextra \
2876                 Wignored-qualifiers \
2877                 Wlogical-op \
2878                 Woverloaded-virtual \
2879                 Wsign-promo \
2880                 Wsynth \
2881                 Wold-style-cast \
2882                 Wcast-align \
2883                 Wcast-qual \
2884                 Wpointer-arith \
2885                 Wshadow \
2886                 Wundef $cf_gxx_extra_warnings $1
2887         do
2888                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
2889                 if AC_TRY_EVAL(ac_compile); then
2890                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2891                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
2892                 else
2893                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
2894                 fi
2895         done
2896         CXXFLAGS="$cf_save_CXXFLAGS"
2897 fi
2898
2899 rm -rf conftest*
2900 AC_LANG_RESTORE
2901 AC_SUBST(EXTRA_CXXFLAGS)
2902 ])dnl
2903 dnl ---------------------------------------------------------------------------
2904 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
2905 dnl ------------
2906 dnl Look for an instance of the Berkeley hashed database.
2907 dnl
2908 dnl $1 = optional parameter, to specify install-prefix for the database.
2909 AC_DEFUN([CF_HASHED_DB],
2910 [
2911 ifelse([$1],,,[
2912 case $1 in
2913 (yes|*able*)
2914         ;;
2915 (*)
2916         if test -d "$1" ; then
2917                 CF_ADD_INCDIR($1/include)
2918                 CF_ADD_LIBDIR($1/lib)
2919         else
2920                 case "$1" in
2921                 (./*|../*|/*)
2922                         AC_MSG_WARN(no such directory $1)
2923                         ;;
2924                 (*)
2925                         CF_FIND_SUB_INCDIR($1)
2926                         CF_FIND_SUB_LIBDIR($1)
2927                         ;;
2928                 esac
2929         fi
2930 esac
2931 ])
2932 AC_CHECK_HEADER(db.h,[
2933 CF_HASHED_DB_VERSION
2934 if test "$cf_cv_hashed_db_version" = unknown ; then
2935         AC_MSG_ERROR(Cannot determine version of db)
2936 else
2937         CF_HASHED_DB_LIBS
2938         if test "$cf_cv_hashed_db_libs" = unknown ; then
2939                 AC_MSG_ERROR(Cannot determine library for db)
2940         elif test "$cf_cv_hashed_db_libs" != default ; then
2941                 CF_ADD_LIB($cf_cv_hashed_db_libs)
2942         fi
2943 fi
2944 ],[
2945         AC_MSG_ERROR(Cannot find db.h)
2946 ])
2947 ])dnl
2948 dnl ---------------------------------------------------------------------------
2949 dnl CF_HASHED_DB_LIBS version: 9 updated: 2010/05/29 16:31:02
2950 dnl -----------------
2951 dnl Given that we have the header and version for hashed database, find the
2952 dnl library information.
2953 AC_DEFUN([CF_HASHED_DB_LIBS],
2954 [
2955 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
2956 cf_cv_hashed_db_libs=unknown
2957 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
2958 do
2959         cf_save_libs="$LIBS"
2960         if test -n "$cf_db_libs"; then
2961                 CF_ADD_LIB($cf_db_libs)
2962         fi
2963         CF_MSG_LOG(checking for library "$cf_db_libs")
2964         AC_TRY_LINK([
2965 $ac_includes_default
2966 #include <db.h>
2967 ],[
2968         char *path = "/tmp/foo";
2969 #ifdef DB_VERSION_MAJOR
2970 #if DB_VERSION_MAJOR >= 4
2971         DB *result = 0;
2972         db_create(&result, NULL, 0);
2973         result->open(result,
2974                 NULL,
2975                 path,
2976                 path,
2977                 DB_HASH,
2978                 DB_CREATE,
2979                 0644);
2980 #elif DB_VERSION_MAJOR >= 3
2981         DB *result = 0;
2982         db_create(&result, NULL, 0);
2983         result->open(result,
2984                 path,
2985                 path,
2986                 DB_HASH,
2987                 DB_CREATE,
2988                 0644);
2989 #elif DB_VERSION_MAJOR >= 2
2990         DB *result = 0;
2991         db_open(path,
2992                 DB_HASH,
2993                 DB_CREATE,
2994                 0644,
2995                 (DB_ENV *) 0,
2996                 (DB_INFO *) 0,
2997                 &result);
2998 #endif /* DB_VERSION_MAJOR */
2999 #else
3000         DB *result = dbopen(path,
3001                      2,
3002                      0644,
3003                      DB_HASH,
3004                      0);
3005 #endif
3006         ${cf_cv_main_return:-return}(result != 0)
3007 ],[
3008         if test -n "$cf_db_libs" ; then
3009                 cf_cv_hashed_db_libs=$cf_db_libs
3010         else
3011                 cf_cv_hashed_db_libs=default
3012         fi
3013         LIBS="$cf_save_libs"
3014         break
3015 ])
3016         LIBS="$cf_save_libs"
3017 done
3018 ])
3019 ])dnl
3020 dnl ---------------------------------------------------------------------------
3021 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
3022 dnl --------------------
3023 dnl Given that we have the header file for hashed database, find the version
3024 dnl information.
3025 AC_DEFUN([CF_HASHED_DB_VERSION],
3026 [
3027 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
3028 cf_cv_hashed_db_version=unknown
3029
3030 for cf_db_version in 1 2 3 4 5 6
3031 do
3032         CF_MSG_LOG(checking for db version $cf_db_version)
3033         AC_TRY_COMPILE([
3034 $ac_includes_default
3035 #include <db.h>
3036
3037 #ifdef DB_VERSION_MAJOR
3038         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
3039 #if $cf_db_version == DB_VERSION_MAJOR
3040         /* ok */
3041 #else
3042         make an error
3043 #endif
3044 #else
3045 #if $cf_db_version == 1
3046         /* ok: assuming this is DB 1.8.5 */
3047 #else
3048         make an error
3049 #endif
3050 #endif
3051 ],[DBT *foo = 0],[
3052         cf_cv_hashed_db_version=$cf_db_version
3053         break
3054         ])
3055 done
3056 ])
3057 ])dnl
3058 dnl ---------------------------------------------------------------------------
3059 dnl CF_HEADER_PATH version: 13 updated: 2015/04/15 19:08:48
3060 dnl --------------
3061 dnl Construct a search-list of directories for a nonstandard header-file
3062 dnl
3063 dnl Parameters
3064 dnl     $1 = the variable to return as result
3065 dnl     $2 = the package name
3066 AC_DEFUN([CF_HEADER_PATH],
3067 [
3068 $1=
3069
3070 # collect the current set of include-directories from compiler flags
3071 cf_header_path_list=""
3072 if test -n "${CFLAGS}${CPPFLAGS}" ; then
3073         for cf_header_path in $CPPFLAGS $CFLAGS
3074         do
3075                 case $cf_header_path in
3076                 (-I*)
3077                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
3078                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
3079                         cf_header_path_list="$cf_header_path_list [$]$1"
3080                         ;;
3081                 esac
3082         done
3083 fi
3084
3085 # add the variations for the package we are looking for
3086 CF_SUBDIR_PATH($1,$2,include)
3087
3088 test "$includedir" != NONE && \
3089 test "$includedir" != "/usr/include" && \
3090 test -d "$includedir" && {
3091         test -d $includedir &&    $1="[$]$1 $includedir"
3092         test -d $includedir/$2 && $1="[$]$1 $includedir/$2"
3093 }
3094
3095 test "$oldincludedir" != NONE && \
3096 test "$oldincludedir" != "/usr/include" && \
3097 test -d "$oldincludedir" && {
3098         test -d $oldincludedir    && $1="[$]$1 $oldincludedir"
3099         test -d $oldincludedir/$2 && $1="[$]$1 $oldincludedir/$2"
3100 }
3101
3102 $1="[$]$1 $cf_header_path_list"
3103 ])dnl
3104 dnl ---------------------------------------------------------------------------
3105 dnl CF_HELP_MESSAGE version: 3 updated: 1998/01/14 10:56:23
3106 dnl ---------------
3107 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
3108 AC_DEFUN([CF_HELP_MESSAGE],
3109 [AC_DIVERT_HELP([$1])dnl
3110 ])dnl
3111 dnl ---------------------------------------------------------------------------
3112 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
3113 dnl ---------------
3114 dnl Construct the list of include-options according to whether we're building
3115 dnl in the source directory or using '--srcdir=DIR' option.
3116 AC_DEFUN([CF_INCLUDE_DIRS],
3117 [
3118 if test "$srcdir" != "."; then
3119         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
3120 fi
3121 CPPFLAGS="-I../include $CPPFLAGS"
3122 if test "$srcdir" != "."; then
3123         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
3124 fi
3125 CPPFLAGS="-I. $CPPFLAGS"
3126 AC_SUBST(CPPFLAGS)
3127 ])dnl
3128 dnl ---------------------------------------------------------------------------
3129 dnl CF_INTEL_COMPILER version: 7 updated: 2015/04/12 15:39:00
3130 dnl -----------------
3131 dnl Check if the given compiler is really the Intel compiler for Linux.  It
3132 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
3133 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
3134 dnl
3135 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
3136 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
3137 dnl the wrappers for gcc and g++ warnings.
3138 dnl
3139 dnl $1 = GCC (default) or GXX
3140 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
3141 dnl $3 = CFLAGS (default) or CXXFLAGS
3142 AC_DEFUN([CF_INTEL_COMPILER],[
3143 AC_REQUIRE([AC_CANONICAL_HOST])
3144 ifelse([$2],,INTEL_COMPILER,[$2])=no
3145
3146 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
3147         case $host_os in
3148         (linux*|gnu*)
3149                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
3150                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
3151                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
3152                 AC_TRY_COMPILE([],[
3153 #ifdef __INTEL_COMPILER
3154 #else
3155 make an error
3156 #endif
3157 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
3158 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
3159 ],[])
3160                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
3161                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
3162                 ;;
3163         esac
3164 fi
3165 ])dnl
3166 dnl ---------------------------------------------------------------------------
3167 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
3168 dnl ----------
3169 dnl Check if we have either a function or macro for 'isascii()'.
3170 AC_DEFUN([CF_ISASCII],
3171 [
3172 AC_MSG_CHECKING(for isascii)
3173 AC_CACHE_VAL(cf_cv_have_isascii,[
3174         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
3175         [cf_cv_have_isascii=yes],
3176         [cf_cv_have_isascii=no])
3177 ])dnl
3178 AC_MSG_RESULT($cf_cv_have_isascii)
3179 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
3180 ])dnl
3181 dnl ---------------------------------------------------------------------------
3182 dnl CF_LARGEFILE version: 10 updated: 2017/01/21 11:06:25
3183 dnl ------------
3184 dnl Add checks for large file support.
3185 AC_DEFUN([CF_LARGEFILE],[
3186 ifdef([AC_FUNC_FSEEKO],[
3187         AC_SYS_LARGEFILE
3188         if test "$enable_largefile" != no ; then
3189         AC_FUNC_FSEEKO
3190
3191         # Normally we would collect these definitions in the config.h,
3192         # but (like _XOPEN_SOURCE), some environments rely on having these
3193         # defined before any of the system headers are included.  Another
3194         # case comes up with C++, e.g., on AIX the compiler compiles the
3195         # header files by themselves before looking at the body files it is
3196         # told to compile.  For ncurses, those header files do not include
3197         # the config.h
3198         test "$ac_cv_sys_large_files"      != no && CPPFLAGS="$CPPFLAGS -D_LARGE_FILES "
3199         test "$ac_cv_sys_largefile_source" != no && CPPFLAGS="$CPPFLAGS -D_LARGEFILE_SOURCE "
3200         test "$ac_cv_sys_file_offset_bits" != no && CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits "
3201
3202         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
3203                 AC_TRY_COMPILE([
3204 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
3205 #include <sys/types.h>
3206 #include <dirent.h>
3207                 ],[
3208                 /* if transitional largefile support is setup, this is true */
3209                 extern struct dirent64 * readdir(DIR *);
3210                 struct dirent64 *x = readdir((DIR *)0);
3211                 struct dirent *y = readdir((DIR *)0);
3212                 int z = x - y;
3213                 ],
3214                 [cf_cv_struct_dirent64=yes],
3215                 [cf_cv_struct_dirent64=no])
3216         ])
3217         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
3218         fi
3219 ])
3220 ])
3221 dnl ---------------------------------------------------------------------------
3222 dnl CF_LDFLAGS_STATIC version: 12 updated: 2015/04/18 08:56:57
3223 dnl -----------------
3224 dnl Check for compiler/linker flags used to temporarily force usage of static
3225 dnl libraries.  This depends on the compiler and platform.  Use this to help
3226 dnl ensure that the linker picks up a given library based on its position in
3227 dnl the list of linker options and libraries.
3228 AC_DEFUN([CF_LDFLAGS_STATIC],[
3229
3230 if test "$GCC" = yes ; then
3231         case $cf_cv_system_name in
3232         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
3233                 LDFLAGS_STATIC=
3234                 LDFLAGS_SHARED=
3235                 ;;
3236         (*)     # normally, except when broken
3237                 LDFLAGS_STATIC=-static
3238                 LDFLAGS_SHARED=-dynamic
3239                 ;;
3240         esac
3241 else
3242         case $cf_cv_system_name in
3243         (aix[[4-7]]*)   # from ld manpage
3244                 LDFLAGS_STATIC=-bstatic
3245                 LDFLAGS_SHARED=-bdynamic
3246                 ;;
3247         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
3248                 # We could also use just "archive" and "shared".
3249                 LDFLAGS_STATIC=-Wl,-a,archive_shared
3250                 LDFLAGS_SHARED=-Wl,-a,shared_archive
3251                 ;;
3252         (irix*)         # from ld manpage IRIX64
3253                 LDFLAGS_STATIC=-Bstatic
3254                 LDFLAGS_SHARED=-Bdynamic
3255                 ;;
3256         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
3257                 # alternative "-oldstyle_liblookup" (not in cc manpage)
3258                 LDFLAGS_STATIC=-noso
3259                 LDFLAGS_SHARED=-so_archive
3260                 ;;
3261         (solaris2*)
3262                 LDFLAGS_STATIC=-Bstatic
3263                 LDFLAGS_SHARED=-Bdynamic
3264                 ;;
3265         esac
3266 fi
3267
3268 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
3269 then
3270         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
3271
3272         rm -f libconftest.a
3273         cat >conftest.$ac_ext <<EOF
3274 #line __oline__ "configure"
3275 #include <stdio.h>
3276 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
3277 EOF
3278         if AC_TRY_EVAL(ac_compile) ; then
3279                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
3280                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
3281         fi
3282         rm -f conftest.*
3283
3284         cf_save_LIBS="$LIBS"
3285
3286         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
3287         AC_TRY_LINK([
3288 #line __oline__ "configure"
3289 #include <stdio.h>
3290 int cf_ldflags_static(FILE *fp);
3291 ],[
3292         return cf_ldflags_static(stdin);
3293 ],[
3294         # some linkers simply ignore the -dynamic
3295         case x`file conftest$ac_exeext 2>/dev/null` in
3296         (*static*)
3297                 cf_ldflags_static=no
3298                 ;;
3299         (*)
3300                 cf_ldflags_static=yes
3301                 ;;
3302         esac
3303 ],[cf_ldflags_static=no])
3304
3305         rm -f libconftest.*
3306         LIBS="$cf_save_LIBS"
3307
3308         AC_MSG_RESULT($cf_ldflags_static)
3309
3310         if test $cf_ldflags_static != yes
3311         then
3312                 LDFLAGS_STATIC=
3313                 LDFLAGS_SHARED=
3314         fi
3315 else
3316         LDFLAGS_STATIC=
3317         LDFLAGS_SHARED=
3318 fi
3319
3320 AC_SUBST(LDFLAGS_STATIC)
3321 AC_SUBST(LDFLAGS_SHARED)
3322 ])
3323 dnl ---------------------------------------------------------------------------
3324 dnl CF_LD_RPATH_OPT version: 7 updated: 2016/02/20 18:01:19
3325 dnl ---------------
3326 dnl For the given system and compiler, find the compiler flags to pass to the
3327 dnl loader to use the "rpath" feature.
3328 AC_DEFUN([CF_LD_RPATH_OPT],
3329 [
3330 AC_REQUIRE([CF_CHECK_CACHE])
3331
3332 LD_RPATH_OPT=
3333 AC_MSG_CHECKING(for an rpath option)
3334 case $cf_cv_system_name in
3335 (irix*)
3336         if test "$GCC" = yes; then
3337                 LD_RPATH_OPT="-Wl,-rpath,"
3338         else
3339                 LD_RPATH_OPT="-rpath "
3340         fi
3341         ;;
3342 (linux*|gnu*|k*bsd*-gnu|freebsd*)
3343         LD_RPATH_OPT="-Wl,-rpath,"
3344         ;;
3345 (openbsd[[2-9]].*|mirbsd*)
3346         LD_RPATH_OPT="-Wl,-rpath,"
3347         ;;
3348 (dragonfly*)
3349         LD_RPATH_OPT="-rpath "
3350         ;;
3351 (netbsd*)
3352         LD_RPATH_OPT="-Wl,-rpath,"
3353         ;;
3354 (osf*|mls+*)
3355         LD_RPATH_OPT="-rpath "
3356         ;;
3357 (solaris2*)
3358         LD_RPATH_OPT="-R"
3359         ;;
3360 (*)
3361         ;;
3362 esac
3363 AC_MSG_RESULT($LD_RPATH_OPT)
3364
3365 case "x$LD_RPATH_OPT" in
3366 (x-R*)
3367         AC_MSG_CHECKING(if we need a space after rpath option)
3368         cf_save_LIBS="$LIBS"
3369         CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
3370         AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
3371         LIBS="$cf_save_LIBS"
3372         AC_MSG_RESULT($cf_rpath_space)
3373         test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
3374         ;;
3375 esac
3376 ])dnl
3377 dnl ---------------------------------------------------------------------------
3378 dnl CF_LIBRARY_PATH version: 10 updated: 2015/04/15 19:08:48
3379 dnl ---------------
3380 dnl Construct a search-list of directories for a nonstandard library-file
3381 dnl
3382 dnl Parameters
3383 dnl     $1 = the variable to return as result
3384 dnl     $2 = the package name
3385 AC_DEFUN([CF_LIBRARY_PATH],
3386 [
3387 $1=
3388 cf_library_path_list=""
3389 if test -n "${LDFLAGS}${LIBS}" ; then
3390         for cf_library_path in $LDFLAGS $LIBS
3391         do
3392                 case $cf_library_path in
3393                 (-L*)
3394                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
3395                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
3396                         cf_library_path_list="$cf_library_path_list [$]$1"
3397                         ;;
3398                 esac
3399         done
3400 fi
3401
3402 CF_SUBDIR_PATH($1,$2,lib)
3403
3404 $1="$cf_library_path_list [$]$1"
3405 ])dnl
3406 dnl ---------------------------------------------------------------------------
3407 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
3408 dnl ------------------
3409 AC_DEFUN([CF_LIBTOOL_VERSION],[
3410 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
3411 then
3412         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
3413 else
3414         cf_cv_libtool_version=
3415 fi
3416 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
3417 ])dnl
3418 dnl ---------------------------------------------------------------------------
3419 dnl CF_LIB_PREFIX version: 12 updated: 2015/10/17 19:03:33
3420 dnl -------------
3421 dnl Compute the library-prefix for the given host system
3422 dnl $1 = variable to set
3423 define([CF_LIB_PREFIX],
3424 [
3425         case $cf_cv_system_name in
3426         (OS/2*|os2*)
3427                 if test "$DFT_LWR_MODEL" = libtool; then
3428                         LIB_PREFIX='lib'
3429                 else
3430                         LIB_PREFIX=''
3431                 fi
3432                 ;;
3433         (*)     LIB_PREFIX='lib'
3434                 ;;
3435         esac
3436 ifelse($1,,,[$1=$LIB_PREFIX])
3437         AC_SUBST(LIB_PREFIX)
3438 ])dnl
3439 dnl ---------------------------------------------------------------------------
3440 dnl CF_LIB_RULES version: 86 updated: 2015/11/07 20:01:34
3441 dnl ------------
3442 dnl Append definitions and rules for the given models to the subdirectory
3443 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
3444 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
3445 dnl the corresponding makefile to list the models that we'll generate.
3446 dnl
3447 dnl For shared libraries, make a list of symbolic links to construct when
3448 dnl generating each library.  The convention used for Linux is the simplest
3449 dnl one:
3450 dnl     lib<name>.so    ->
3451 dnl     lib<name>.so.<major>    ->
3452 dnl     lib<name>.so.<maj>.<minor>
3453 dnl
3454 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
3455 AC_DEFUN([CF_LIB_RULES],
3456 [
3457 cf_prefix=$LIB_PREFIX
3458 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
3459
3460 case $cf_cv_shlib_version in
3461 (cygdll|msysdll|mingw)
3462         TINFO_NAME=$TINFO_ARG_SUFFIX
3463         TINFO_SUFFIX=.dll
3464         ;;
3465 esac
3466
3467 if test -n "$TINFO_SUFFIX" ; then
3468         case $TINFO_SUFFIX in
3469         (tw*)
3470                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
3471                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^tw'$EXTRA_SUFFIX'//'`
3472                 ;;
3473         (t*)
3474                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
3475                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^t'$EXTRA_SUFFIX'//'`
3476                 ;;
3477         (w*)
3478                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
3479                 TINFO_SUFFIX=`echo $TINFO_SUFFIX | sed 's/^w'$EXTRA_SUFFIX'//'`
3480                 ;;
3481         esac
3482 fi
3483
3484 for cf_dir in $SRC_SUBDIRS
3485 do
3486         if test ! -d $srcdir/$cf_dir ; then
3487                 continue
3488         elif test -f $srcdir/$cf_dir/modules; then
3489
3490                 SHARED_LIB=
3491                 Libs_To_Make=
3492                 cf_awk_program=
3493                 if test -n "${cf_cv_abi_version}" && test "x${cf_cv_abi_version}" != "x5"
3494                 then
3495                         cf_awk_program="$cf_awk_program\
3496 /deprecated in ABI${cf_cv_abi_version}/ { next; }\
3497 { sub(\"NCURSES([[WT]]+)?\", \"&${cf_cv_abi_version}\"); }\
3498 "
3499                 fi
3500
3501                 if test "x$WILDCARD_SYMS" = xno
3502                 then
3503                         cf_awk_program="$cf_awk_program\
3504 /[[     ]]_\\*;/ { skip=1; next; }\
3505 "
3506                 fi
3507
3508                 if test "x$cf_awk_program" != "x"
3509                 then
3510                         cat >>$cf_dir/Makefile <<CF_EOF
3511
3512 # Generated by CF_LIB_RULES
3513 resulting.map: $UNALTERED_SYMS
3514         $AWK 'BEGIN { skip = 1; last=""; } \
3515 $cf_awk_program \
3516 { if ( last != "" && ( skip == 0 || \[$]\[$]0 !~ /}/ ) ) { print last; }\
3517  skip = 0; last = \[$]\[$]0; } \
3518 END { print last; }' < $UNALTERED_SYMS >\[$]@
3519
3520 distclean::
3521         rm -f resulting.map
3522 CF_EOF
3523                 fi
3524
3525                 for cf_item in $cf_LIST_MODELS
3526                 do
3527                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3528                         cf_libname=$cf_dir
3529                         test "$cf_dir" = c++ && cf_libname=ncurses++
3530                         if test $cf_item = shared ; then
3531                                 if test -n "${LIB_SUFFIX}"
3532                                 then
3533                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3534                                 else
3535                                         cf_shared_suffix="$cf_suffix"
3536                                 fi
3537                                 if test "$cf_cv_do_symlinks" = yes ; then
3538                                         cf_version_name=
3539
3540                                         case "$cf_cv_shlib_version" in
3541                                         (rel)
3542                                                 cf_version_name=REL_VERSION
3543                                                 ;;
3544                                         (abi)
3545                                                 cf_version_name=ABI_VERSION
3546                                                 ;;
3547                                         esac
3548
3549                                         if test -n "$cf_version_name"
3550                                         then
3551                                                 case "$cf_cv_system_name" in
3552                                                 (darwin*)
3553                                                         # "w", etc?
3554                                                         cf_suffix="${USE_LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
3555                                                         ;;
3556                                                 (*)
3557                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
3558                                                         ;;
3559                                                 esac
3560                                         fi
3561                                         if test -n "${USE_LIB_SUFFIX}"
3562                                         then
3563                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
3564                                         else
3565                                                 cf_shared_suffix="$cf_suffix"
3566                                         fi
3567                                 fi
3568                                 # cygwin needs import library, and has unique naming convention
3569                                 # use autodetected ${cf_prefix} for import lib and static lib, but
3570                                 # use 'cyg' prefix for shared lib.
3571                                 case $cf_cv_shlib_version in
3572                                 (cygdll)
3573                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3574                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
3575                                         ;;
3576                                 (msysdll)
3577                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3578                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
3579                                         ;;
3580                                 (mingw)
3581                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
3582                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
3583                                         ;;
3584                                 (*)
3585                                         cf_add_lib=
3586                                         ;;
3587                                 esac
3588                                 if test -n "$cf_add_lib"
3589                                 then
3590                                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3591                                         continue
3592                                 fi
3593                         fi
3594                         cf_add_lib="../lib/${cf_prefix}${cf_libname}${cf_suffix}"
3595                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
3596                 done
3597
3598                 if test $cf_dir = ncurses ; then
3599                         cf_subsets="$LIB_SUBSETS"
3600                         cf_r_parts="$cf_subsets"
3601                         cf_liblist="$Libs_To_Make"
3602
3603                         while test -n "$cf_r_parts"
3604                         do
3605                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
3606                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
3607                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
3608                                         cf_add_lib=
3609                                         case $cf_l_parts in
3610                                         (*termlib*)
3611                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
3612                                                 ;;
3613                                         (*ticlib*)
3614                                                 cf_add_lib=`echo $cf_liblist |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
3615                                                 ;;
3616                                         (*)
3617                                                 break
3618                                                 ;;
3619                                         esac
3620                                         if test -n "$cf_add_lib"; then
3621                                                 Libs_To_Make="$cf_add_lib $Libs_To_Make"
3622                                         fi
3623                                 else
3624                                         break
3625                                 fi
3626                         done
3627                 else
3628                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
3629                 fi
3630
3631                 if test $cf_dir = c++; then
3632                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
3633                                 cf_list=
3634                                 for cf_item in $Libs_To_Make
3635                                 do
3636                                         case $cf_item in
3637                                         (*.a)
3638                                                 ;;
3639                                         (*)
3640                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
3641                                                 ;;
3642                                         esac
3643                                         for cf_test in $cf_list
3644                                         do
3645                                                 if test "$cf_test" = "$cf_item"
3646                                                 then
3647                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
3648                                                         cf_item=
3649                                                         break
3650                                                 fi
3651                                         done
3652                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
3653                                 done
3654                                 Libs_To_Make="$cf_list"
3655                         fi
3656                 fi
3657
3658                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
3659                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
3660                         $cf_dir/Makefile >$cf_dir/Makefile.out
3661                 mv $cf_dir/Makefile.out $cf_dir/Makefile
3662
3663                 $AWK -f $srcdir/mk-0th.awk \
3664                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
3665                         $srcdir/$cf_dir/modules >>$cf_dir/Makefile
3666
3667                 for cf_subset in $cf_subsets
3668                 do
3669                         cf_subdirs=
3670                         for cf_item in $cf_LIST_MODELS
3671                         do
3672
3673                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
3674                         CF_UPPER(cf_ITEM,$cf_item)
3675
3676                         CXX_MODEL=$cf_ITEM
3677                         if test "$CXX_MODEL" = SHARED; then
3678                                 case $cf_cv_shlib_version in
3679                                 (cygdll|msysdll|mingw)
3680                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
3681                                         with_shared_cxx=yes
3682                                         ;;
3683                                 (*)
3684                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
3685                                         ;;
3686                                 esac
3687                         fi
3688
3689                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
3690                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
3691
3692                         # Test for case where we build libtinfo with a different name.
3693                         cf_libname=$cf_dir
3694                         if test $cf_dir = ncurses ; then
3695                                 case $cf_subset in
3696                                 (*base*)
3697                                         cf_libname=${cf_libname}$USE_LIB_SUFFIX
3698                                         ;;
3699                                 (*termlib*)
3700                                         cf_libname=$TINFO_LIB_SUFFIX
3701                                         ;;
3702                                 (ticlib*)
3703                                         cf_libname=$TICS_LIB_SUFFIX
3704                                         ;;
3705                                 esac
3706                         elif test $cf_dir = c++ ; then
3707                                 cf_libname=ncurses++$USE_LIB_SUFFIX
3708                         else
3709    &n