aclocal.m4

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2020,2021 Thomas E. Dickey                                *
   3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey 1995-on
  31 dnl
  32 dnl $Id: aclocal.m4,v 1.954 2021/03/20 16:02:03 tom Exp $
  33 dnl Macros used in NCURSES auto-configuration script.
  34 dnl
  35 dnl These macros are maintained separately from NCURSES.  The copyright on
  36 dnl this file applies to the aggregation of macros and does not affect use of
  37 dnl these macros in other applications.
  38 dnl
  39 dnl See these pages for additional information:
  40 dnl             https://invisible-island.net/autoconf/
  41 dnl             https://invisible-island.net/autoconf/my-autoconf.html
  42 dnl
  43 dnl ---------------------------------------------------------------------------
  44 dnl ---------------------------------------------------------------------------
  45 dnl AM_LANGINFO_CODESET version: 6 updated: 2021/01/01 16:53:59
  46 dnl -------------------
  47 dnl Inserted as requested by gettext 0.10.40
  48 dnl File from /usr/share/aclocal
  49 dnl codeset.m4
  50 dnl ====================
  51 dnl serial AM1
  52 dnl
  53 dnl From Bruno Haible.
  54 AC_DEFUN([AM_LANGINFO_CODESET],
  55 [
  56 AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
  57         [AC_TRY_LINK([#include <langinfo.h>],
  58         [char* cs = nl_langinfo(CODESET); (void)cs],
  59         am_cv_langinfo_codeset=yes,
  60         am_cv_langinfo_codeset=no)
  61         ])
  62         if test "$am_cv_langinfo_codeset" = yes; then
  63                 AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  64                 [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  65         fi
  66 ])dnl
  67 dnl ---------------------------------------------------------------------------
  68 dnl CF_ABI_DEFAULTS version: 2 updated: 2015/06/06 13:49:58
  69 dnl ---------------
  70 dnl Provide configure-script defaults for different ncurses ABIs.
  71 AC_DEFUN([CF_ABI_DEFAULTS],[
  72 AC_REQUIRE([CF_NCURSES_WITH_ABI_VERSION])
  73 case x$cf_cv_abi_version in
  74 (x[[6789]])
  75         cf_dft_ext_colors=yes
  76         cf_dft_ext_const=yes
  77         cf_dft_ext_mouse=yes
  78         cf_dft_ext_putwin=yes
  79         cf_dft_ext_spfuncs=yes
  80         cf_dft_filter_syms=yes
  81         cf_dft_chtype=uint32_t
  82         cf_dft_mmask_t=uint32_t
  83         cf_dft_interop=yes
  84         cf_dft_tparm_arg=intptr_t
  85         cf_dft_with_lp64=yes
  86         ;;
  87 (*)
  88         cf_dft_ext_colors=no
  89         cf_dft_ext_const=no
  90         cf_dft_ext_mouse=no
  91         cf_dft_ext_putwin=no
  92         cf_dft_ext_spfuncs=no
  93         cf_dft_filter_syms=no
  94         cf_dft_chtype=auto
  95         cf_dft_mmask_t=auto
  96         cf_dft_interop=no
  97         cf_dft_tparm_arg=long
  98         cf_dft_with_lp64=no
  99         ;;
 100 esac
 101 ])dnl
 102 dnl ---------------------------------------------------------------------------
 103 dnl CF_ACVERSION_CHECK version: 5 updated: 2014/06/04 19:11:49
 104 dnl ------------------
 105 dnl Conditionally generate script according to whether we're using a given autoconf.
 106 dnl
 107 dnl $1 = version to compare against
 108 dnl $2 = code to use if AC_ACVERSION is at least as high as $1.
 109 dnl $3 = code to use if AC_ACVERSION is older than $1.
 110 define([CF_ACVERSION_CHECK],
 111 [
 112 ifdef([AC_ACVERSION], ,[ifdef([AC_AUTOCONF_VERSION],[m4_copy([AC_AUTOCONF_VERSION],[AC_ACVERSION])],[m4_copy([m4_PACKAGE_VERSION],[AC_ACVERSION])])])dnl
 113 ifdef([m4_version_compare],
 114 [m4_if(m4_version_compare(m4_defn([AC_ACVERSION]), [$1]), -1, [$3], [$2])],
 115 [CF_ACVERSION_COMPARE(
 116 AC_PREREQ_CANON(AC_PREREQ_SPLIT([$1])),
 117 AC_PREREQ_CANON(AC_PREREQ_SPLIT(AC_ACVERSION)), AC_ACVERSION, [$2], [$3])])])dnl
 118 dnl ---------------------------------------------------------------------------
 119 dnl CF_ACVERSION_COMPARE version: 3 updated: 2012/10/03 18:39:53
 120 dnl --------------------
 121 dnl CF_ACVERSION_COMPARE(MAJOR1, MINOR1, TERNARY1,
 122 dnl                      MAJOR2, MINOR2, TERNARY2,
 123 dnl                      PRINTABLE2, not FOUND, FOUND)
 124 define([CF_ACVERSION_COMPARE],
 125 [ifelse(builtin([eval], [$2 < $5]), 1,
 126 [ifelse([$8], , ,[$8])],
 127 [ifelse([$9], , ,[$9])])])dnl
 128 dnl ---------------------------------------------------------------------------
 129 dnl CF_ADA_INCLUDE_DIRS version: 8 updated: 2013/10/14 04:24:07
 130 dnl -------------------
 131 dnl Construct the list of include-options for the C programs in the Ada95
 132 dnl binding.
 133 AC_DEFUN([CF_ADA_INCLUDE_DIRS],
 134 [
 135 ACPPFLAGS="-I. -I../include -I../../include $ACPPFLAGS"
 136 if test "$srcdir" != "."; then
 137         ACPPFLAGS="-I\${srcdir}/../../include $ACPPFLAGS"
 138 fi
 139 if test "$GCC" != yes; then
 140         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 141 elif test "$includedir" != "/usr/include"; then
 142         if test "$includedir" = '${prefix}/include' ; then
 143                 if test x$prefix != x/usr ; then
 144                         ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 145                 fi
 146         else
 147                 ACPPFLAGS="$ACPPFLAGS -I\${includedir}"
 148         fi
 149 fi
 150 AC_SUBST(ACPPFLAGS)
 151 ])dnl
 152 dnl ---------------------------------------------------------------------------
 153 dnl CF_ADD_ADAFLAGS version: 1 updated: 2010/06/19 15:22:18
 154 dnl ---------------
 155 dnl Add to $ADAFLAGS, which is substituted into makefile and scripts.
 156 AC_DEFUN([CF_ADD_ADAFLAGS],[
 157         ADAFLAGS="$ADAFLAGS $1"
 158         AC_SUBST(ADAFLAGS)
 159 ])dnl
 160 dnl ---------------------------------------------------------------------------
 161 dnl CF_ADD_CFLAGS version: 15 updated: 2020/12/31 10:54:15
 162 dnl -------------
 163 dnl Copy non-preprocessor flags to $CFLAGS, preprocessor flags to $CPPFLAGS
 164 dnl $1 = flags to add
 165 dnl $2 = if given makes this macro verbose.
 166 dnl
 167 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 168 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 169 dnl confused by the quotes (which require backslashes to keep them usable).
 170 AC_DEFUN([CF_ADD_CFLAGS],
 171 [
 172 cf_fix_cppflags=no
 173 cf_new_cflags=
 174 cf_new_cppflags=
 175 cf_new_extra_cppflags=
 176
 177 for cf_add_cflags in $1
 178 do
 179 case "$cf_fix_cppflags" in
 180 (no)
 181         case "$cf_add_cflags" in
 182         (-undef|-nostdinc*|-I*|-D*|-U*|-E|-P|-C)
 183                 case "$cf_add_cflags" in
 184                 (-D*)
 185                         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^-D[[^=]]*='\''\"[[^"]]*//'`
 186
 187                         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 188                                 && test -z "${cf_tst_cflags}" \
 189                                 && cf_fix_cppflags=yes
 190
 191                         if test "$cf_fix_cppflags" = yes ; then
 192                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 193                                 continue
 194                         elif test "${cf_tst_cflags}" = "\"'" ; then
 195                                 CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 196                                 continue
 197                         fi
 198                         ;;
 199                 esac
 200                 case "$CPPFLAGS" in
 201                 (*$cf_add_cflags)
 202                         ;;
 203                 (*)
 204                         case "$cf_add_cflags" in
 205                         (-D*)
 206                                 cf_tst_cppflags=`echo "x$cf_add_cflags" | sed -e 's/^...//' -e 's/=.*//'`
 207                                 CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,$cf_tst_cppflags)
 208                                 ;;
 209                         esac
 210                         CF_APPEND_TEXT(cf_new_cppflags,$cf_add_cflags)
 211                         ;;
 212                 esac
 213                 ;;
 214         (*)
 215                 CF_APPEND_TEXT(cf_new_cflags,$cf_add_cflags)
 216                 ;;
 217         esac
 218         ;;
 219 (yes)
 220         CF_APPEND_TEXT(cf_new_extra_cppflags,$cf_add_cflags)
 221
 222         cf_tst_cflags=`echo "${cf_add_cflags}" |sed -e 's/^[[^"]]*"'\''//'`
 223
 224         test "x${cf_add_cflags}" != "x${cf_tst_cflags}" \
 225                 && test -z "${cf_tst_cflags}" \
 226                 && cf_fix_cppflags=no
 227         ;;
 228 esac
 229 done
 230
 231 if test -n "$cf_new_cflags" ; then
 232         ifelse([$2],,,[CF_VERBOSE(add to \$CFLAGS $cf_new_cflags)])
 233         CF_APPEND_TEXT(CFLAGS,$cf_new_cflags)
 234 fi
 235
 236 if test -n "$cf_new_cppflags" ; then
 237         ifelse([$2],,,[CF_VERBOSE(add to \$CPPFLAGS $cf_new_cppflags)])
 238         CF_APPEND_TEXT(CPPFLAGS,$cf_new_cppflags)
 239 fi
 240
 241 if test -n "$cf_new_extra_cppflags" ; then
 242         ifelse([$2],,,[CF_VERBOSE(add to \$EXTRA_CPPFLAGS $cf_new_extra_cppflags)])
 243         CF_APPEND_TEXT(EXTRA_CPPFLAGS,$cf_new_extra_cppflags)
 244 fi
 245
 246 AC_SUBST(EXTRA_CPPFLAGS)
 247
 248 ])dnl
 249 dnl ---------------------------------------------------------------------------
 250 dnl CF_ADD_CXXFLAGS version: 1 updated: 2020/04/04 16:16:13
 251 dnl ---------------
 252 dnl Copy non-preprocessor flags to $CXXFLAGS, preprocessor flags to $CPPFLAGS
 253 dnl The second parameter if given makes this macro verbose.
 254 dnl
 255 dnl Put any preprocessor definitions that use quoted strings in $EXTRA_CPPFLAGS,
 256 dnl to simplify use of $CPPFLAGS in compiler checks, etc., that are easily
 257 dnl confused by the quotes (which require backslashes to keep them usable).
 258 AC_DEFUN([CF_ADD_CXXFLAGS],
 259 [
 260 cf_save_CXXFLAGS="$CFLAGS"
 261 CFLAGS="$CXXFLAGS"
 262 CF_ADD_CFLAGS($1 ifelse($2,,,[,$2]))
 263 CXXFLAGS="$CFLAGS"
 264 CFLAGS="$cf_save_CXXFLAGS"
 265 ])dnl
 266 dnl ---------------------------------------------------------------------------
 267 dnl CF_ADD_INCDIR version: 16 updated: 2020/12/31 20:19:42
 268 dnl -------------
 269 dnl Add an include-directory to $CPPFLAGS.  Don't add /usr/include, since it's
 270 dnl redundant.  We don't normally need to add -I/usr/local/include for gcc,
 271 dnl but old versions (and some misinstalled ones) need that.  To make things
 272 dnl worse, gcc 3.x may give error messages if -I/usr/local/include is added to
 273 dnl the include-path).
 274 AC_DEFUN([CF_ADD_INCDIR],
 275 [
 276 if test -n "$1" ; then
 277   for cf_add_incdir in $1
 278   do
 279         while test "$cf_add_incdir" != /usr/include
 280         do
 281           if test -d "$cf_add_incdir"
 282           then
 283                 cf_have_incdir=no
 284                 if test -n "$CFLAGS$CPPFLAGS" ; then
 285                   # a loop is needed to ensure we can add subdirs of existing dirs
 286                   for cf_test_incdir in $CFLAGS $CPPFLAGS ; do
 287                         if test ".$cf_test_incdir" = ".-I$cf_add_incdir" ; then
 288                           cf_have_incdir=yes; break
 289                         fi
 290                   done
 291                 fi
 292
 293                 if test "$cf_have_incdir" = no ; then
 294                   if test "$cf_add_incdir" = /usr/local/include ; then
 295                         if test "$GCC" = yes
 296                         then
 297                           cf_save_CPPFLAGS=$CPPFLAGS
 298                           CF_APPEND_TEXT(CPPFLAGS,-I$cf_add_incdir)
 299                           AC_TRY_COMPILE([#include <stdio.h>],
 300                                   [printf("Hello")],
 301                                   [],
 302                                   [cf_have_incdir=yes])
 303                           CPPFLAGS=$cf_save_CPPFLAGS
 304                         fi
 305                   fi
 306                 fi
 307
 308                 if test "$cf_have_incdir" = no ; then
 309                   CF_VERBOSE(adding $cf_add_incdir to include-path)
 310                   ifelse([$2],,CPPFLAGS,[$2])="$ifelse([$2],,CPPFLAGS,[$2]) -I$cf_add_incdir"
 311
 312                   cf_top_incdir=`echo "$cf_add_incdir" | sed -e 's%/include/.*$%/include%'`
 313                   test "$cf_top_incdir" = "$cf_add_incdir" && break
 314                   cf_add_incdir="$cf_top_incdir"
 315                 else
 316                   break
 317                 fi
 318           else
 319                 break
 320           fi
 321         done
 322   done
 323 fi
 324 ])dnl
 325 dnl ---------------------------------------------------------------------------
 326 dnl CF_ADD_LIB version: 2 updated: 2010/06/02 05:03:05
 327 dnl ----------
 328 dnl Add a library, used to enforce consistency.
 329 dnl
 330 dnl $1 = library to add, without the "-l"
 331 dnl $2 = variable to update (default $LIBS)
 332 AC_DEFUN([CF_ADD_LIB],[CF_ADD_LIBS(-l$1,ifelse($2,,LIBS,[$2]))])dnl
 333 dnl ---------------------------------------------------------------------------
 334 dnl CF_ADD_LIBDIR version: 11 updated: 2020/12/31 20:19:42
 335 dnl -------------
 336 dnl     Adds to the library-path
 337 dnl
 338 dnl     Some machines have trouble with multiple -L options.
 339 dnl
 340 dnl $1 is the (list of) directory(s) to add
 341 dnl $2 is the optional name of the variable to update (default LDFLAGS)
 342 dnl
 343 AC_DEFUN([CF_ADD_LIBDIR],
 344 [
 345 if test -n "$1" ; then
 346         for cf_add_libdir in $1
 347         do
 348                 if test "$cf_add_libdir" = /usr/lib ; then
 349                         :
 350                 elif test -d "$cf_add_libdir"
 351                 then
 352                         cf_have_libdir=no
 353                         if test -n "$LDFLAGS$LIBS" ; then
 354                                 # a loop is needed to ensure we can add subdirs of existing dirs
 355                                 for cf_test_libdir in $LDFLAGS $LIBS ; do
 356                                         if test ".$cf_test_libdir" = ".-L$cf_add_libdir" ; then
 357                                                 cf_have_libdir=yes; break
 358                                         fi
 359                                 done
 360                         fi
 361                         if test "$cf_have_libdir" = no ; then
 362                                 CF_VERBOSE(adding $cf_add_libdir to library-path)
 363                                 ifelse([$2],,LDFLAGS,[$2])="-L$cf_add_libdir $ifelse([$2],,LDFLAGS,[$2])"
 364                         fi
 365                 fi
 366         done
 367 fi
 368 ])dnl
 369 dnl ---------------------------------------------------------------------------
 370 dnl CF_ADD_LIBS version: 3 updated: 2019/11/02 16:47:33
 371 dnl -----------
 372 dnl Add one or more libraries, used to enforce consistency.  Libraries are
 373 dnl prepended to an existing list, since their dependencies are assumed to
 374 dnl already exist in the list.
 375 dnl
 376 dnl $1 = libraries to add, with the "-l", etc.
 377 dnl $2 = variable to update (default $LIBS)
 378 AC_DEFUN([CF_ADD_LIBS],[
 379 cf_add_libs="[$]ifelse($2,,LIBS,[$2])"
 380 # reverse order
 381 cf_add_0lib=
 382 for cf_add_1lib in $1; do cf_add_0lib="$cf_add_1lib $cf_add_0lib"; done
 383 # filter duplicates
 384 for cf_add_1lib in $cf_add_0lib; do
 385         for cf_add_2lib in $cf_add_libs; do
 386                 if test "x$cf_add_1lib" = "x$cf_add_2lib"; then
 387                         cf_add_1lib=
 388                         break
 389                 fi
 390         done
 391         test -n "$cf_add_1lib" && cf_add_libs="$cf_add_1lib $cf_add_libs"
 392 done
 393 ifelse($2,,LIBS,[$2])="$cf_add_libs"
 394 ])dnl
 395 dnl ---------------------------------------------------------------------------
 396 dnl CF_ADD_SUBDIR_PATH version: 5 updated: 2020/12/31 20:19:42
 397 dnl ------------------
 398 dnl Append to a search-list for a nonstandard header/lib-file
 399 dnl     $1 = the variable to return as result
 400 dnl     $2 = the package name
 401 dnl     $3 = the subdirectory, e.g., bin, include or lib
 402 dnl $4 = the directory under which we will test for subdirectories
 403 dnl $5 = a directory that we do not want $4 to match
 404 AC_DEFUN([CF_ADD_SUBDIR_PATH],
 405 [
 406 test "x$4" != "x$5" && \
 407 test -d "$4" && \
 408 ifelse([$5],NONE,,[{ test -z "$5" || test "x$5" = xNONE || test "x$4" != "x$5"; } &&]) {
 409         test -n "$verbose" && echo "    ... testing for $3-directories under $4"
 410         test -d "$4/$3" &&          $1="[$]$1 $4/$3"
 411         test -d "$4/$3/$2" &&       $1="[$]$1 $4/$3/$2"
 412         test -d "$4/$3/$2/$3" &&    $1="[$]$1 $4/$3/$2/$3"
 413         test -d "$4/$2/$3" &&       $1="[$]$1 $4/$2/$3"
 414         test -d "$4/$2/$3/$2" &&    $1="[$]$1 $4/$2/$3/$2"
 415 }
 416 ])dnl
 417 dnl ---------------------------------------------------------------------------
 418 dnl CF_APPEND_TEXT version: 1 updated: 2017/02/25 18:58:55
 419 dnl --------------
 420 dnl use this macro for appending text without introducing an extra blank at
 421 dnl the beginning
 422 define([CF_APPEND_TEXT],
 423 [
 424         test -n "[$]$1" && $1="[$]$1 "
 425         $1="[$]{$1}$2"
 426 ])dnl
 427 dnl ---------------------------------------------------------------------------
 428 dnl CF_ARG_DISABLE version: 3 updated: 1999/03/30 17:24:31
 429 dnl --------------
 430 dnl Allow user to disable a normally-on option.
 431 AC_DEFUN([CF_ARG_DISABLE],
 432 [CF_ARG_OPTION($1,[$2],[$3],[$4],yes)])dnl
 433 dnl ---------------------------------------------------------------------------
 434 dnl CF_ARG_ENABLE version: 3 updated: 1999/03/30 17:24:31
 435 dnl -------------
 436 dnl Allow user to enable a normally-off option.
 437 AC_DEFUN([CF_ARG_ENABLE],
 438 [CF_ARG_OPTION($1,[$2],[$3],[$4],no)])dnl
 439 dnl ---------------------------------------------------------------------------
 440 dnl CF_ARG_OPTION version: 5 updated: 2015/05/10 19:52:14
 441 dnl -------------
 442 dnl Restricted form of AC_ARG_ENABLE that ensures user doesn't give bogus
 443 dnl values.
 444 dnl
 445 dnl Parameters:
 446 dnl $1 = option name
 447 dnl $2 = help-string
 448 dnl $3 = action to perform if option is not default
 449 dnl $4 = action if perform if option is default
 450 dnl $5 = default option value (either 'yes' or 'no')
 451 AC_DEFUN([CF_ARG_OPTION],
 452 [AC_ARG_ENABLE([$1],[$2],[test "$enableval" != ifelse([$5],no,yes,no) && enableval=ifelse([$5],no,no,yes)
 453         if test "$enableval" != "$5" ; then
 454 ifelse([$3],,[    :]dnl
 455 ,[    $3]) ifelse([$4],,,[
 456         else
 457                 $4])
 458         fi],[enableval=$5 ifelse([$4],,,[
 459         $4
 460 ])dnl
 461 ])])dnl
 462 dnl ---------------------------------------------------------------------------
 463 dnl CF_AR_FLAGS version: 9 updated: 2021/01/01 13:31:04
 464 dnl -----------
 465 dnl Check for suitable "ar" (archiver) options for updating an archive.
 466 dnl
 467 dnl In particular, handle some obsolete cases where the "-" might be omitted,
 468 dnl as well as a workaround for breakage of make's archive rules by the GNU
 469 dnl binutils "ar" program.
 470 AC_DEFUN([CF_AR_FLAGS],[
 471 AC_REQUIRE([CF_PROG_AR])
 472
 473 AC_CACHE_CHECK(for options to update archives, cf_cv_ar_flags,[
 474         case "$cf_cv_system_name" in
 475         (*-msvc*)
 476                 cf_cv_ar_flags=''
 477                 cat >mk_static_lib.sh <<-EOF
 478                 #!$SHELL
 479                 MSVC_BIN="[$]AR"
 480                 out="\[$]1"
 481                 shift
 482                 exec \[$]MSVC_BIN -out:"\[$]out" \[$]@
 483                 EOF
 484                 chmod +x mk_static_lib.sh
 485                 AR=`pwd`/mk_static_lib.sh
 486                 ;;
 487         (*)
 488                 cf_cv_ar_flags=unknown
 489                 for cf_ar_flags in -curvU -curv curv -crv crv -cqv cqv -rv rv
 490                 do
 491
 492                         # check if $ARFLAGS already contains this choice
 493                         if test "x$ARFLAGS" != "x" ; then
 494                                 cf_check_ar_flags=`echo "x$ARFLAGS" | sed -e "s/$cf_ar_flags\$//" -e "s/$cf_ar_flags / /"`
 495                                 if test "x$ARFLAGS" != "$cf_check_ar_flags" ; then
 496                                         cf_cv_ar_flags=
 497                                         break
 498                                 fi
 499                         fi
 500
 501                         rm -f "conftest.$ac_cv_objext"
 502                         rm -f conftest.a
 503
 504                         cat >"conftest.$ac_ext" <<EOF
 505 #line __oline__ "configure"
 506 int     testdata[[3]] = { 123, 456, 789 };
 507 EOF
 508                         if AC_TRY_EVAL(ac_compile) ; then
 509                                 echo "$AR $ARFLAGS $cf_ar_flags conftest.a conftest.$ac_cv_objext" >&AC_FD_CC
 510                                 $AR $ARFLAGS "$cf_ar_flags" conftest.a "conftest.$ac_cv_objext" 2>&AC_FD_CC 1>/dev/null
 511                                 if test -f conftest.a ; then
 512                                         cf_cv_ar_flags="$cf_ar_flags"
 513                                         break
 514                                 fi
 515                         else
 516                                 CF_VERBOSE(cannot compile test-program)
 517                                 break
 518                         fi
 519                 done
 520                 rm -f conftest.a "conftest.$ac_ext" "conftest.$ac_cv_objext"
 521                 ;;
 522         esac
 523 ])
 524
 525 if test -n "$ARFLAGS" ; then
 526         if test -n "$cf_cv_ar_flags" ; then
 527                 ARFLAGS="$ARFLAGS $cf_cv_ar_flags"
 528         fi
 529 else
 530         ARFLAGS=$cf_cv_ar_flags
 531 fi
 532
 533 AC_SUBST(ARFLAGS)
 534 ])
 535 dnl ---------------------------------------------------------------------------
 536 dnl CF_AWK_BIG_PRINTF version: 5 updated: 2015/04/17 21:13:04
 537 dnl -----------------
 538 dnl Check if awk can handle big strings using printf.  Some older versions of
 539 dnl awk choke on large strings passed via "%s".
 540 dnl
 541 dnl $1 = desired string size
 542 dnl $2 = variable to set with result
 543 AC_DEFUN([CF_AWK_BIG_PRINTF],
 544 [
 545         case x$AWK in
 546         (x)
 547                 eval $2=no
 548                 ;;
 549         (*)
 550                 if ( ${AWK} 'BEGIN { xx = "x"; while (length(xx) < $1) { xx = xx "x"; }; printf("%s\n", xx); }' 2>/dev/null \
 551                         | $AWK '{ printf "%d\n", length([$]0); }' 2>/dev/null | $AWK 'BEGIN { eqls=0; recs=0; } { recs++; if ([$]0 == 12000) eqls++; } END { if (recs != 1 || eqls != 1) exit 1; }' 2>/dev/null >/dev/null ) ; then
 552                         eval $2=yes
 553                 else
 554                         eval $2=no
 555                 fi
 556                 ;;
 557         esac
 558 ])dnl
 559 dnl ---------------------------------------------------------------------------
 560 dnl CF_BOOL_DECL version: 8 updated: 2004/01/30 15:51:18
 561 dnl ------------
 562 dnl Test if 'bool' is a builtin type in the configured C++ compiler.  Some
 563 dnl older compilers (e.g., gcc 2.5.8) don't support 'bool' directly; gcc
 564 dnl 2.6.3 does, in anticipation of the ANSI C++ standard.
 565 dnl
 566 dnl Treat the configuration-variable specially here, since we're directly
 567 dnl substituting its value (i.e., 1/0).
 568 dnl
 569 dnl $1 is the shell variable to store the result in, if not $cv_cv_builtin_bool
 570 AC_DEFUN([CF_BOOL_DECL],
 571 [
 572 AC_MSG_CHECKING(if we should include stdbool.h)
 573
 574 AC_CACHE_VAL(cf_cv_header_stdbool_h,[
 575         AC_TRY_COMPILE([],[bool foo = false],
 576                 [cf_cv_header_stdbool_h=0],
 577                 [AC_TRY_COMPILE([
 578 #ifndef __BEOS__
 579 #include <stdbool.h>
 580 #endif
 581 ],[bool foo = false],
 582                         [cf_cv_header_stdbool_h=1],
 583                         [cf_cv_header_stdbool_h=0])])])
 584
 585 if test "$cf_cv_header_stdbool_h" = 1
 586 then    AC_MSG_RESULT(yes)
 587 else    AC_MSG_RESULT(no)
 588 fi
 589
 590 AC_MSG_CHECKING([for builtin bool type])
 591
 592 AC_CACHE_VAL(ifelse($1,,cf_cv_builtin_bool,[$1]),[
 593         AC_TRY_COMPILE([
 594 #include <stdio.h>
 595 #include <sys/types.h>
 596 ],[bool x = false],
 597                 [ifelse($1,,cf_cv_builtin_bool,[$1])=1],
 598                 [ifelse($1,,cf_cv_builtin_bool,[$1])=0])
 599         ])
 600
 601 if test "$ifelse($1,,cf_cv_builtin_bool,[$1])" = 1
 602 then    AC_MSG_RESULT(yes)
 603 else    AC_MSG_RESULT(no)
 604 fi
 605 ])dnl
 606 dnl ---------------------------------------------------------------------------
 607 dnl CF_BOOL_SIZE version: 17 updated: 2020/10/24 19:48:55
 608 dnl ------------
 609 dnl Test for the size of 'bool' in the configured C++ compiler (e.g., a type).
 610 dnl Don't bother looking for bool.h, since it's been deprecated.
 611 dnl
 612 dnl If the current compiler is C rather than C++, we get the bool definition
 613 dnl from <stdbool.h>.
 614 AC_DEFUN([CF_BOOL_SIZE],
 615 [
 616 AC_CHECK_SIZEOF(bool,,[
 617 #include <stdlib.h>
 618 #include <stdio.h>
 619
 620 #if defined(__cplusplus)
 621
 622 #ifdef HAVE_GXX_BUILTIN_H
 623 #include <g++/builtin.h>
 624 #elif HAVE_GPP_BUILTIN_H
 625 #include <gpp/builtin.h>
 626 #elif HAVE_BUILTIN_H
 627 #include <builtin.h>
 628 #endif
 629
 630 #else
 631
 632 #if $cf_cv_header_stdbool_h
 633 #include <stdbool.h>
 634 #endif
 635
 636 #endif
 637 ])
 638
 639 AC_CACHE_CHECK(for type of bool, cf_cv_type_of_bool,[
 640         rm -f cf_test.out
 641         AC_TRY_RUN([
 642 #include <stdlib.h>
 643 #include <stdio.h>
 644
 645 #if defined(__cplusplus)
 646
 647 #ifdef HAVE_GXX_BUILTIN_H
 648 #include <g++/builtin.h>
 649 #elif HAVE_GPP_BUILTIN_H
 650 #include <gpp/builtin.h>
 651 #elif HAVE_BUILTIN_H
 652 #include <builtin.h>
 653 #endif
 654
 655 #else
 656
 657 #if $cf_cv_header_stdbool_h
 658 #include <stdbool.h>
 659 #endif
 660
 661 #endif
 662
 663 int main(void)
 664 {
 665         FILE *fp = fopen("cf_test.out", "w");
 666         if (fp != 0) {
 667                 bool x = true;
 668                 if ((bool)(-x) >= 0)
 669                         fputs("unsigned ", fp);
 670                 if (sizeof(x) == sizeof(int))       fputs("int",  fp);
 671                 else if (sizeof(x) == sizeof(char)) fputs("char", fp);
 672                 else if (sizeof(x) == sizeof(short))fputs("short",fp);
 673                 else if (sizeof(x) == sizeof(long)) fputs("long", fp);
 674                 fclose(fp);
 675         }
 676         ${cf_cv_main_return:-return}(0);
 677 }
 678                 ],
 679                 [cf_cv_type_of_bool=`cat cf_test.out`
 680                  if test -z "$cf_cv_type_of_bool"; then
 681                    cf_cv_type_of_bool=unknown
 682                  fi],
 683                 [cf_cv_type_of_bool=unknown],
 684                 [
 685                 case x$ac_cv_sizeof_bool in
 686                 (x1) cf_cv_type_of_bool="unsigned char";;
 687                 (x2) cf_cv_type_of_bool="unsigned short";;
 688                 (x4) cf_cv_type_of_bool="unsigned int";;
 689                 (x8) cf_cv_type_of_bool="unsigned long";;
 690                 (*)  cf_cv_type_of_bool=unknown;;
 691                 esac
 692                 ])
 693         rm -f cf_test.out
 694 ])
 695
 696 if test "$cf_cv_type_of_bool" = unknown ; then
 697         case .$NCURSES_BOOL in
 698         (.auto|.) NCURSES_BOOL=unsigned;;
 699         esac
 700         AC_MSG_WARN(Assuming $NCURSES_BOOL for type of bool)
 701         cf_cv_type_of_bool=$NCURSES_BOOL
 702 fi
 703 ])dnl
 704 dnl ---------------------------------------------------------------------------
 705 dnl CF_BUILD_CC version: 9 updated: 2021/01/02 09:31:20
 706 dnl -----------
 707 dnl If we're cross-compiling, allow the user to override the tools and their
 708 dnl options.  The configure script is oriented toward identifying the host
 709 dnl compiler, etc., but we need a build compiler to generate parts of the
 710 dnl source.
 711 dnl
 712 dnl $1 = default for $CPPFLAGS
 713 dnl $2 = default for $LIBS
 714 AC_DEFUN([CF_BUILD_CC],[
 715 CF_ACVERSION_CHECK(2.52,,
 716         [AC_REQUIRE([CF_PROG_EXT])])
 717 if test "$cross_compiling" = yes ; then
 718
 719         # defaults that we might want to override
 720         : ${BUILD_CFLAGS:=''}
 721         : ${BUILD_CPPFLAGS:='ifelse([$1],,,[$1])'}
 722         : ${BUILD_LDFLAGS:=''}
 723         : ${BUILD_LIBS:='ifelse([$2],,,[$2])'}
 724         : ${BUILD_EXEEXT:='$x'}
 725         : ${BUILD_OBJEXT:='o'}
 726
 727         AC_ARG_WITH(build-cc,
 728                 [  --with-build-cc=XXX     the build C compiler ($BUILD_CC)],
 729                 [BUILD_CC="$withval"],
 730                 [AC_CHECK_PROGS(BUILD_CC, [gcc clang c99 c89 cc cl],none)])
 731         AC_MSG_CHECKING(for native build C compiler)
 732         AC_MSG_RESULT($BUILD_CC)
 733
 734         AC_MSG_CHECKING(for native build C preprocessor)
 735         AC_ARG_WITH(build-cpp,
 736                 [  --with-build-cpp=XXX    the build C preprocessor ($BUILD_CPP)],
 737                 [BUILD_CPP="$withval"],
 738                 [BUILD_CPP='${BUILD_CC} -E'])
 739         AC_MSG_RESULT($BUILD_CPP)
 740
 741         AC_MSG_CHECKING(for native build C flags)
 742         AC_ARG_WITH(build-cflags,
 743                 [  --with-build-cflags=XXX the build C compiler-flags ($BUILD_CFLAGS)],
 744                 [BUILD_CFLAGS="$withval"])
 745         AC_MSG_RESULT($BUILD_CFLAGS)
 746
 747         AC_MSG_CHECKING(for native build C preprocessor-flags)
 748         AC_ARG_WITH(build-cppflags,
 749                 [  --with-build-cppflags=XXX the build C preprocessor-flags ($BUILD_CPPFLAGS)],
 750                 [BUILD_CPPFLAGS="$withval"])
 751         AC_MSG_RESULT($BUILD_CPPFLAGS)
 752
 753         AC_MSG_CHECKING(for native build linker-flags)
 754         AC_ARG_WITH(build-ldflags,
 755                 [  --with-build-ldflags=XXX the build linker-flags ($BUILD_LDFLAGS)],
 756                 [BUILD_LDFLAGS="$withval"])
 757         AC_MSG_RESULT($BUILD_LDFLAGS)
 758
 759         AC_MSG_CHECKING(for native build linker-libraries)
 760         AC_ARG_WITH(build-libs,
 761                 [  --with-build-libs=XXX   the build libraries (${BUILD_LIBS})],
 762                 [BUILD_LIBS="$withval"])
 763         AC_MSG_RESULT($BUILD_LIBS)
 764
 765         # this assumes we're on Unix.
 766         BUILD_EXEEXT=
 767         BUILD_OBJEXT=o
 768
 769         : ${BUILD_CC:='${CC}'}
 770
 771         if { test "$BUILD_CC" = "$CC" || test "$BUILD_CC" = '${CC}'; } ; then
 772                 AC_MSG_ERROR([Cross-build requires two compilers.
 773 Use --with-build-cc to specify the native compiler.])
 774         fi
 775
 776 else
 777         : ${BUILD_CC:='${CC}'}
 778         : ${BUILD_CPP:='${CPP}'}
 779         : ${BUILD_CFLAGS:='${CFLAGS}'}
 780         : ${BUILD_CPPFLAGS:='${CPPFLAGS}'}
 781         : ${BUILD_LDFLAGS:='${LDFLAGS}'}
 782         : ${BUILD_LIBS:='${LIBS}'}
 783         : ${BUILD_EXEEXT:='$x'}
 784         : ${BUILD_OBJEXT:='o'}
 785 fi
 786
 787 AC_SUBST(BUILD_CC)
 788 AC_SUBST(BUILD_CPP)
 789 AC_SUBST(BUILD_CFLAGS)
 790 AC_SUBST(BUILD_CPPFLAGS)
 791 AC_SUBST(BUILD_LDFLAGS)
 792 AC_SUBST(BUILD_LIBS)
 793 AC_SUBST(BUILD_EXEEXT)
 794 AC_SUBST(BUILD_OBJEXT)
 795 ])dnl
 796 dnl ---------------------------------------------------------------------------
 797 dnl CF_C11_NORETURN version: 1 updated: 2021/03/20 12:00:25
 798 dnl ---------------
 799 AC_DEFUN([CF_C11_NORETURN],
 800 [
 801 AC_CACHE_CHECK([for C11 _Noreturn feature], cf_cv_c11_noreturn,
 802         [AC_TRY_COMPILE([
 803 #include <stdio.h>
 804 #include <stdlib.h>
 805 #include <stdnoreturn.h>
 806 static void giveup(void) { exit(0); }
 807         ],
 808         [if (feof(stdin)) giveup()],
 809         cf_cv_c11_noreturn=yes,
 810         cf_cv_c11_noreturn=no)
 811         ])
 812
 813 if test "$cf_cv_c11_noreturn" = yes; then
 814         AC_DEFINE(HAVE_STDNORETURN_H, 1)
 815         AC_DEFINE_UNQUOTED(STDC_NORETURN,_Noreturn,[Define if C11 _Noreturn keyword is supported])
 816         HAVE_STDNORETURN_H=1
 817 else
 818         HAVE_STDNORETURN_H=0
 819 fi
 820
 821 AC_SUBST(HAVE_STDNORETURN_H)
 822 ])dnl
 823 dnl ---------------------------------------------------------------------------
 824 dnl CF_CC_ENV_FLAGS version: 10 updated: 2020/12/31 18:40:20
 825 dnl ---------------
 826 dnl Check for user's environment-breakage by stuffing CFLAGS/CPPFLAGS content
 827 dnl into CC.  This will not help with broken scripts that wrap the compiler
 828 dnl with options, but eliminates a more common category of user confusion.
 829 dnl
 830 dnl In particular, it addresses the problem of being able to run the C
 831 dnl preprocessor in a consistent manner.
 832 dnl
 833 dnl Caveat: this also disallows blanks in the pathname for the compiler, but
 834 dnl the nuisance of having inconsistent settings for compiler and preprocessor
 835 dnl outweighs that limitation.
 836 AC_DEFUN([CF_CC_ENV_FLAGS],
 837 [
 838 # This should have been defined by AC_PROG_CC
 839 : "${CC:=cc}"
 840
 841 AC_MSG_CHECKING(\$CFLAGS variable)
 842 case "x$CFLAGS" in
 843 (*-[[IUD]]*)
 844         AC_MSG_RESULT(broken)
 845         AC_MSG_WARN(your environment uses the CFLAGS variable to hold CPPFLAGS options)
 846         cf_flags="$CFLAGS"
 847         CFLAGS=
 848         for cf_arg in $cf_flags
 849         do
 850                 CF_ADD_CFLAGS($cf_arg)
 851         done
 852         ;;
 853 (*)
 854         AC_MSG_RESULT(ok)
 855         ;;
 856 esac
 857
 858 AC_MSG_CHECKING(\$CC variable)
 859 case "$CC" in
 860 (*[[\ \ ]]-*)
 861         AC_MSG_RESULT(broken)
 862         AC_MSG_WARN(your environment uses the CC variable to hold CFLAGS/CPPFLAGS options)
 863         # humor him...
 864         cf_prog=`echo "$CC" | sed -e 's/        / /g' -e 's/[[ ]]* / /g' -e 's/[[ ]]*[[ ]]-[[^ ]].*//'`
 865         cf_flags=`echo "$CC" | ${AWK:-awk} -v prog="$cf_prog" '{ printf("%s", [substr]([$]0,1+length(prog))); }'`
 866         CC="$cf_prog"
 867         for cf_arg in $cf_flags
 868         do
 869                 case "x$cf_arg" in
 870                 (x-[[IUDfgOW]]*)
 871                         CF_ADD_CFLAGS($cf_arg)
 872                         ;;
 873                 (*)
 874                         CC="$CC $cf_arg"
 875                         ;;
 876                 esac
 877         done
 878         CF_VERBOSE(resulting CC: '$CC')
 879         CF_VERBOSE(resulting CFLAGS: '$CFLAGS')
 880         CF_VERBOSE(resulting CPPFLAGS: '$CPPFLAGS')
 881         ;;
 882 (*)
 883         AC_MSG_RESULT(ok)
 884         ;;
 885 esac
 886 ])dnl
 887 dnl ---------------------------------------------------------------------------
 888 dnl CF_CFG_DEFAULTS version: 16 updated: 2021/01/04 19:33:05
 889 dnl ---------------
 890 dnl Determine the default configuration into which we'll install ncurses.  This
 891 dnl can be overridden by the user's command-line options.  There's two items to
 892 dnl look for:
 893 dnl     1. the prefix (e.g., /usr)
 894 dnl     2. the header files (e.g., /usr/include/ncurses)
 895 dnl We'll look for a previous installation of ncurses and use the same defaults.
 896 dnl
 897 dnl We don't use AC_PREFIX_DEFAULT, because it gets evaluated too soon, and
 898 dnl we don't use AC_PREFIX_PROGRAM, because we cannot distinguish ncurses's
 899 dnl programs from a vendor's.
 900 AC_DEFUN([CF_CFG_DEFAULTS],
 901 [AC_REQUIRE([AC_PROG_FGREP])dnl
 902
 903 AC_MSG_CHECKING(for prefix)
 904 if test "x$prefix" = "xNONE" ; then
 905         case "$cf_cv_system_name" in
 906                 # non-vendor systems don't have a conflict
 907         (openbsd*|freebsd*|mirbsd*|linux*|cygwin*|msys*|k*bsd*-gnu|mingw*)
 908                 prefix=/usr
 909                 ;;
 910         (*)     prefix=$ac_default_prefix
 911                 ;;
 912         esac
 913 fi
 914 AC_MSG_RESULT($prefix)
 915
 916 if test "x$prefix" = "xNONE" ; then
 917 AC_MSG_CHECKING(for default include-directory)
 918 test -n "$verbose" && echo 1>&AC_FD_MSG
 919 for cf_symbol in \
 920         "$includedir" \
 921         "$includedir/ncurses" \
 922         "$prefix/include" \
 923         "$prefix/include/ncurses" \
 924         /usr/local/include \
 925         /usr/local/include/ncurses \
 926         /usr/include \
 927         /usr/include/ncurses
 928 do
 929         cf_dir=`eval echo "$cf_symbol"`
 930         if test -f "$cf_dir/curses.h" ; then
 931         if ( ${FGREP-fgrep} NCURSES_VERSION "$cf_dir/curses.h" >/dev/null 2>&1 ) ; then
 932                 includedir="$cf_symbol"
 933                 test -n "$verbose"  && echo $ECHO_N "   found " 1>&AC_FD_MSG
 934                 break
 935         fi
 936         fi
 937         test -n "$verbose"  && echo "   tested $cf_dir" 1>&AC_FD_MSG
 938 done
 939 AC_MSG_RESULT($includedir)
 940 fi
 941 ])dnl
 942 dnl ---------------------------------------------------------------------------
 943 dnl CF_CGETENT version: 6 updated: 2017/01/21 11:06:25
 944 dnl ----------
 945 dnl Check if the terminal-capability database functions are available.  If not,
 946 dnl ncurses has a much-reduced version.
 947 AC_DEFUN([CF_CGETENT],[
 948 AC_CACHE_CHECK(for terminal-capability database functions,cf_cv_cgetent,[
 949 AC_TRY_LINK([
 950 #include <stdlib.h>],[
 951         char temp[128];
 952         char *buf = temp;
 953         char *db_array = temp;
 954         cgetent(&buf, &db_array, "vt100");
 955         cgetcap(buf, "tc", '=');
 956         cgetmatch(buf, "tc");
 957         ],
 958         [cf_cv_cgetent=yes],
 959         [cf_cv_cgetent=no])
 960 ])
 961
 962 if test "$cf_cv_cgetent" = yes
 963 then
 964         AC_DEFINE(HAVE_BSD_CGETENT,1,[Define to 1 if we have BSD cgetent])
 965 AC_CACHE_CHECK(if cgetent uses const parameter,cf_cv_cgetent_const,[
 966 AC_TRY_LINK([
 967 #pragma GCC diagnostic error "-Wincompatible-pointer-types-discards-qualifiers"
 968 #include <stdlib.h>],[
 969         char temp[128];
 970         char *buf = temp;
 971 #ifndef _NETBSD_SOURCE                  /* given, since April 2004 in stdlib.h */
 972         const char *db_array = temp;
 973         cgetent(&buf, &db_array, "vt100");
 974 #endif
 975         cgetcap(buf, "tc", '=');
 976         cgetmatch(buf, "tc");
 977         ],
 978         [cf_cv_cgetent_const=yes],
 979         [cf_cv_cgetent_const=no])
 980 ])
 981         if test "$cf_cv_cgetent_const" = yes
 982         then
 983                 AC_DEFINE_UNQUOTED(CGETENT_CONST,const,[Define to const if needed for some BSD cgetent variations])
 984         fi
 985 fi
 986 ])dnl
 987 dnl ---------------------------------------------------------------------------
 988 dnl CF_CHECK_CACHE version: 13 updated: 2020/12/31 10:54:15
 989 dnl --------------
 990 dnl Check if we're accidentally using a cache from a different machine.
 991 dnl Derive the system name, as a check for reusing the autoconf cache.
 992 dnl
 993 dnl If we've packaged config.guess and config.sub, run that (since it does a
 994 dnl better job than uname).  Normally we'll use AC_CANONICAL_HOST, but allow
 995 dnl an extra parameter that we may override, e.g., for AC_CANONICAL_SYSTEM
 996 dnl which is useful in cross-compiles.
 997 dnl
 998 dnl Note: we would use $ac_config_sub, but that is one of the places where
 999 dnl autoconf 2.5x broke compatibility with autoconf 2.13
1000 AC_DEFUN([CF_CHECK_CACHE],
1001 [
1002 if test -f "$srcdir/config.guess" || test -f "$ac_aux_dir/config.guess" ; then
1003         ifelse([$1],,[AC_CANONICAL_HOST],[$1])
1004         system_name="$host_os"
1005 else
1006         system_name="`(uname -s -r) 2>/dev/null`"
1007         if test -z "$system_name" ; then
1008                 system_name="`(hostname) 2>/dev/null`"
1009         fi
1010 fi
1011 test -n "$system_name" && AC_DEFINE_UNQUOTED(SYSTEM_NAME,"$system_name",[Define to the system name.])
1012 AC_CACHE_VAL(cf_cv_system_name,[cf_cv_system_name="$system_name"])
1013
1014 test -z "$system_name" && system_name="$cf_cv_system_name"
1015 test -n "$cf_cv_system_name" && AC_MSG_RESULT(Configuring for $cf_cv_system_name)
1016
1017 if test ".$system_name" != ".$cf_cv_system_name" ; then
1018         AC_MSG_RESULT(Cached system name ($system_name) does not agree with actual ($cf_cv_system_name))
1019         AC_MSG_ERROR("Please remove config.cache and try again.")
1020 fi
1021 ])dnl
1022 dnl ---------------------------------------------------------------------------
1023 dnl CF_CHECK_ENVIRON version: 3 updated: 2010/05/26 16:44:57
1024 dnl ----------------
1025 dnl Check for data that is usually declared in <unistd.h>, e.g., the 'environ'
1026 dnl variable.  Define a DECL_xxx symbol if we must declare it ourselves.
1027 dnl
1028 dnl $1 = the name to check
1029 dnl $2 = the assumed type
1030 AC_DEFUN([CF_CHECK_ENVIRON],
1031 [
1032 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
1033     AC_TRY_COMPILE([
1034 #ifdef HAVE_STDLIB_H
1035 #include <stdlib.h>
1036 #endif
1037 #include <unistd.h> ],
1038     ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1,
1039     [cf_cv_dcl_$1=yes],
1040     [cf_cv_dcl_$1=no])
1041 ])
1042
1043 if test "$cf_cv_dcl_$1" = no ; then
1044     CF_UPPER(cf_result,decl_$1)
1045     AC_DEFINE_UNQUOTED($cf_result)
1046 fi
1047
1048 # It's possible (for near-UNIX clones) that the data doesn't exist
1049 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
1050 ])dnl
1051 dnl ---------------------------------------------------------------------------
1052 dnl CF_CHECK_ERRNO version: 13 updated: 2020/03/10 18:53:47
1053 dnl --------------
1054 dnl Check for data that is usually declared in <stdio.h> or <errno.h>, e.g.,
1055 dnl the 'errno' variable.  Define a DECL_xxx symbol if we must declare it
1056 dnl ourselves.
1057 dnl
1058 dnl $1 = the name to check
1059 dnl $2 = the assumed type
1060 AC_DEFUN([CF_CHECK_ERRNO],
1061 [
1062 AC_CACHE_CHECK(if external $1 is declared, cf_cv_dcl_$1,[
1063         AC_TRY_COMPILE([
1064 #ifdef HAVE_STDLIB_H
1065 #include <stdlib.h>
1066 #endif
1067 #include <stdio.h>
1068 #include <sys/types.h>
1069 #include <errno.h> ],
1070         ifelse([$2],,int,[$2]) x = (ifelse([$2],,int,[$2])) $1; (void)x,
1071         [cf_cv_dcl_$1=yes],
1072         [cf_cv_dcl_$1=no])
1073 ])
1074
1075 if test "$cf_cv_dcl_$1" = no ; then
1076         CF_UPPER(cf_result,decl_$1)
1077         AC_DEFINE_UNQUOTED($cf_result)
1078 fi
1079
1080 # It's possible (for near-UNIX clones) that the data doesn't exist
1081 CF_CHECK_EXTERN_DATA($1,ifelse([$2],,int,[$2]))
1082 ])dnl
1083 dnl ---------------------------------------------------------------------------
1084 dnl CF_CHECK_EXTERN_DATA version: 4 updated: 2015/04/18 08:56:57
1085 dnl --------------------
1086 dnl Check for existence of external data in the current set of libraries.  If
1087 dnl we can modify it, it's real enough.
1088 dnl $1 = the name to check
1089 dnl $2 = its type
1090 AC_DEFUN([CF_CHECK_EXTERN_DATA],
1091 [
1092 AC_CACHE_CHECK(if external $1 exists, cf_cv_have_$1,[
1093         AC_TRY_LINK([
1094 #undef $1
1095 extern $2 $1;
1096 ],
1097         [$1 = 2],
1098         [cf_cv_have_$1=yes],
1099         [cf_cv_have_$1=no])
1100 ])
1101
1102 if test "$cf_cv_have_$1" = yes ; then
1103         CF_UPPER(cf_result,have_$1)
1104         AC_DEFINE_UNQUOTED($cf_result)
1105 fi
1106
1107 ])dnl
1108 dnl ---------------------------------------------------------------------------
1109 dnl CF_CHECK_FVISIBILITY version: 2 updated: 2020/04/04 16:16:13
1110 dnl --------------------
1111 dnl Check whether the compiler understands -fvisibility=hidden
1112 dnl
1113 dnl $1 = compiler
1114 dnl $2 = compiler-flags variable name
1115 dnl $3 = cache variable to set
1116 AC_DEFUN([CF_CHECK_FVISIBILITY],[
1117 AC_CACHE_CHECK(if $1 -fvisibility=hidden option works,$3,[
1118     cf_save_cflags="[$]$2"
1119     $2="[$]$2 -fvisibility=hidden"
1120     AC_TRY_LINK([
1121 __attribute__ ((visibility("default"))) int somefunc() {return 42;}
1122         ],[
1123         if (somefunc()) return 1;
1124 ],
1125     [$3=yes],
1126     [$3=no])
1127     $2=$cf_save_cflags
1128 ])
1129 ])dnl
1130 dnl ---------------------------------------------------------------------------
1131 dnl CF_CHECK_GETENV version: 2 updated: 2021/01/02 17:09:14
1132 dnl ---------------
1133 dnl Check if repeated getenv calls return the same pointer, e.g., it does not
1134 dnl discard the previous pointer when returning a new one.
1135 AC_DEFUN([CF_CHECK_GETENV],
1136 [
1137 AC_REQUIRE([CF_CHECK_ENVIRON])
1138 AC_CHECK_FUNC( getenv, ,, AC_MSG_ERROR(getenv not found) )
1139 AC_CHECK_FUNCS( putenv setenv strdup )
1140 AC_CACHE_CHECK(if getenv returns consistent values,cf_cv_consistent_getenv,[
1141 AC_TRY_RUN([
1142 #include <stdlib.h>
1143 #include <unistd.h>
1144 #include <stdio.h>
1145 #include <string.h>
1146 #include <sys/types.h>
1147
1148 #if defined(HAVE_ENVIRON) && defined(DECL_ENVIRON) && !defined(environ)
1149 extern char **environ;  /* POSIX, but some systems are not... */
1150 #endif
1151
1152 #if defined(HAVE_STRDUP)
1153 #define str_alloc(s) strdup(s)
1154 #else
1155 #define str_alloc(s) strcpy(malloc(strlen(s) + 1, s))
1156 #endif
1157
1158 static void set_value(const char *name, const char *value)
1159 {
1160 #if defined(HAVE_SETENV)
1161         setenv(name, value, 1);
1162 #elif defined(HAVE_PUTENV)
1163         char buffer[1024];
1164         sprintf(buffer, "%s=%s", name, value);
1165         putenv(str_alloc(buffer));
1166 #else
1167 #error neither putenv/setenv found
1168 #endif
1169 }
1170 int main(void)
1171 {
1172         int pass;
1173         size_t numenv, limit, j;
1174         char **mynames;
1175         char **myvalues;
1176         char **mypointer;
1177         char *equals;
1178         for (numenv = 0; environ[numenv]; ++numenv) ;
1179         limit = numenv + 10;
1180         mynames = (char **) calloc(limit + 1, sizeof(char *));
1181         myvalues = (char **) calloc(limit + 1, sizeof(char *));
1182         mypointer = (char **) calloc(limit + 1, sizeof(char *));
1183 #if defined(HAVE_ENVIRON)
1184         for (j = 0; environ[j]; ++j) {
1185                 mynames[j] = str_alloc(environ[j]);
1186                 equals = strchr(mynames[j], '=');
1187                 if (equals != 0) {
1188                         *equals++ = '\\0';
1189                         myvalues[j] = str_alloc(equals);
1190                 } else {
1191                         myvalues[j] = str_alloc("");
1192                 }
1193         }
1194 #endif
1195         for (j = numenv; j < limit; ++j) {
1196                 char name[80];
1197                 char value[80];
1198                 size_t found;
1199                 size_t k = 0;
1200                 do {
1201                         size_t jk;
1202                         found = 0;
1203                         sprintf(name, "TERM%lu", (unsigned long) k);
1204                         for (jk = 0; jk < j; ++jk) {
1205                                 if (!strcmp(name, mynames[jk])) {
1206                                         found = 1;
1207                                         ++k;
1208                                         break;
1209                                 }
1210                         }
1211                 } while (found);
1212                 sprintf(value, "%lu:%p", (unsigned long) k, &mynames[j]);
1213                 set_value(name, value);
1214                 mynames[j] = str_alloc(name);
1215                 myvalues[j] = str_alloc(value);
1216         }
1217         for (pass = 0; pass < 3; ++pass) {
1218                 for (j = 0; j < limit; ++j) {
1219                         char *value = getenv(mynames[j]);
1220                         if (pass) {
1221                                 if (value == 0) {
1222                                         fprintf(stderr, "getenv returned null for %s\\n", mynames[j]);
1223                                         ${cf_cv_main_return:-return}(1);
1224                                 } else if (value != mypointer[j]) {
1225                                         fprintf(stderr, "getenv returned different pointer for %s\\n", mynames[j]);
1226                                         ${cf_cv_main_return:-return}(1);
1227                                 } else if (strcmp(value, myvalues[j])) {
1228                                         fprintf(stderr, "getenv returned different value for %s\\n", mynames[j]);
1229                                         ${cf_cv_main_return:-return}(1);
1230                                 }
1231                         } else {
1232                                 size_t k;
1233                                 mypointer[j] = value;
1234                                 for (k = 0; k < j; ++k) {
1235                                         if (mypointer[j] == mypointer[k]) {
1236                                                 fprintf(stderr, "getenv returned same pointer for %s and %s\\n", mynames[j], mynames[k]);
1237                                                 ${cf_cv_main_return:-return}(1);
1238                                         }
1239                                 }
1240                         }
1241                 }
1242         }
1243         ${cf_cv_main_return:-return}(0);
1244 }
1245 ],
1246 [cf_cv_consistent_getenv=yes],
1247 [cf_cv_consistent_getenv=no],
1248 [cf_cv_consistent_getenv=unknown])
1249 ])
1250
1251 if test "x$cf_cv_consistent_getenv" = xno
1252 then
1253         AC_DEFINE(HAVE_CONSISTENT_GETENV,1,[Define to 1 if getenv repeatably returns the same value for a given name])
1254 fi
1255 ])dnl
1256 dnl ---------------------------------------------------------------------------
1257 dnl CF_CHECK_GNAT_VERSION version: 4 updated: 2021/01/01 13:31:04
1258 dnl ---------------------
1259 AC_DEFUN([CF_CHECK_GNAT_VERSION],
1260 [
1261 AC_REQUIRE([CF_GNAT_VERSION])
1262 case "$cf_cv_gnat_version" in
1263 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
1264         cf_cv_prog_gnat_correct=yes
1265         ;;
1266 (*)
1267         AC_MSG_WARN(Unsupported GNAT version $cf_cv_gnat_version. We require 3.11 or better. Disabling Ada95 binding.)
1268         cf_cv_prog_gnat_correct=no
1269         ;;
1270 esac
1271 ])
1272 dnl ---------------------------------------------------------------------------
1273 dnl CF_CHECK_GPM_WGETCH version: 6 updated: 2021/01/04 18:48:01
1274 dnl -------------------
1275 dnl Check if GPM is already linked with curses.  If so - and if the linkage
1276 dnl is not "weak" - warn about this because it can create problems linking
1277 dnl applications with ncurses.
1278 AC_DEFUN([CF_CHECK_GPM_WGETCH],[
1279 AC_REQUIRE([AC_PROG_EGREP])dnl
1280
1281 AC_CHECK_LIB(gpm,Gpm_Wgetch,[
1282
1283 AC_CACHE_CHECK(if GPM is weakly bound to curses library, cf_cv_check_gpm_wgetch,[
1284 cf_cv_check_gpm_wgetch=unknown
1285 if test "$cross_compiling" != yes ; then
1286
1287 cat >conftest.$ac_ext <<CF_EOF
1288 #include <gpm.h>
1289 int main(void)
1290 {
1291         Gpm_Wgetch();
1292         ${cf_cv_main_return:-return}(0);
1293 }
1294 CF_EOF
1295
1296         cf_save_LIBS="$LIBS"
1297         # This only works if we can look at the symbol table.  If a shared
1298         # library is stripped for install, we cannot use that.  So we're forced
1299         # to rely on the static library, noting that some packagers may not
1300         # include it.
1301         LIBS="-static -lgpm -dynamic $LIBS"
1302         if AC_TRY_EVAL(ac_compile) ; then
1303                 if AC_TRY_EVAL(ac_link) ; then
1304                         cf_cv_check_gpm_wgetch="`nm \"conftest$ac_exeext\" | ${EGREP-egrep} '\<wgetch\>' | ${EGREP-egrep} '\<[[vVwW]]\>'`"
1305                         test -n "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=yes
1306                         test -z "$cf_cv_check_gpm_wgetch" && cf_cv_check_gpm_wgetch=no
1307                 fi
1308         fi
1309         rm -rf ./conftest*
1310         LIBS="$cf_save_LIBS"
1311 fi
1312 ])
1313
1314 if test "$cf_cv_check_gpm_wgetch" != yes ; then
1315         AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
1316 fi
1317 ])])dnl
1318 dnl ---------------------------------------------------------------------------
1319 dnl CF_CHECK_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
1320 dnl ------------------------
1321 dnl Show the version of libtool
1322 dnl
1323 dnl Save the version in a cache variable - this is not entirely a good thing,
1324 dnl but the version string from libtool is very ugly, and for bug reports it
1325 dnl might be useful to have the original string.
1326 AC_DEFUN([CF_CHECK_LIBTOOL_VERSION],[
1327 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
1328 then
1329         AC_MSG_CHECKING(version of $LIBTOOL)
1330         CF_LIBTOOL_VERSION
1331         AC_MSG_RESULT($cf_cv_libtool_version)
1332         if test -z "$cf_cv_libtool_version" ; then
1333                 AC_MSG_ERROR(This is not GNU libtool)
1334         fi
1335 else
1336         AC_MSG_ERROR(GNU libtool has not been found)
1337 fi
1338 ])dnl
1339 dnl ---------------------------------------------------------------------------
1340 dnl CF_CHECK_WCHAR_H version: 3 updated: 2021/01/01 13:31:04
1341 dnl ----------------
1342 dnl Check if wchar.h can be used, i.e., without defining _XOPEN_SOURCE_EXTENDED
1343 AC_DEFUN([CF_CHECK_WCHAR_H],[
1344 AC_CHECK_HEADERS( \
1345 wchar.h \
1346 wctype.h \
1347 )
1348 AC_CACHE_CHECK(if wchar.h can be used as is,cf_cv_wchar_h_okay,[
1349 AC_TRY_COMPILE(
1350 [
1351 #include <stdlib.h>
1352 #ifdef HAVE_WCHAR_H
1353 #include <wchar.h>
1354 #endif
1355 #ifdef HAVE_WCTYPE_H
1356 #include <wctype.h>
1357 #endif
1358 ],[
1359         wint_t foo = 0;
1360         int bar = iswpunct(foo)],
1361         [cf_cv_wchar_h_okay=yes],
1362         [cf_cv_wchar_h_okay=no])])
1363
1364 if test "$cf_cv_wchar_h_okay" = no
1365 then
1366         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
1367 fi
1368 ])dnl
1369 dnl ---------------------------------------------------------------------------
1370 dnl CF_CHECK_WCWIDTH_GRAPHICS version: 2 updated: 2021/01/02 17:09:14
1371 dnl -------------------------
1372 dnl Most "modern" terminal emulators are based to some degree on VT100, and
1373 dnl should support line-drawing.  Even with Unicode.  There is a problem.
1374 dnl
1375 dnl While most of the VT100 graphics characters were incorporated into Unicode,
1376 dnl all of those were combined into a page of useful graphics characters.
1377 dnl
1378 dnl So far, so good.
1379 dnl
1380 dnl However, while they are useful, there are other considerations.  CJK
1381 dnl is (because of poor device resolution) often rendered as double-width
1382 dnl characters.  So... for these generally-useful characters, what should
1383 dnl be the width (to make them consistent with adjacent characters)?
1384 dnl
1385 dnl The obvious choice would have been to make this locale-dependent, and use
1386 dnl wcwidth() to tell applications what the actual width is.  That was too
1387 dnl obvious.  Instead, we have a slew of "ambiguous-width" characters.
1388 dnl See for example
1389 dnl             http://www.unicode.org/reports/tr11/tr11-29.html
1390 dnl             http://www.cl.cam.ac.uk/~mgk25/ucs/scw-proposal.html
1391 dnl
1392 dnl The EastAsianWidth-6.2.0.txt file from the Unicode organization lists
1393 dnl more than 22,000 characters, with 1281 of those as ambiguous-width.  For
1394 dnl instance, it lists half (44/96) of the Latin-1 characters as
1395 dnl ambiguous-width.  Also, all of the box-characters at 0x2500 are ambiguous.
1396 dnl
1397 dnl What this means for the implementor is that on some systems wcwidth() can
1398 dnl give bad advice.  On Solaris, some of the ambiguous widths are returned as
1399 dnl 1 (the Latin-1 characters), while others are returned as 2 (line-drawing
1400 dnl characters).  These do not necessarily match the behavior of the terminal
1401 dnl emulator.  xterm, for instance, does an optional startup check to find if
1402 dnl this problem (or similar) exists with the system's locale tables, rejecting
1403 dnl them if they are too unreliable.
1404 AC_DEFUN([CF_CHECK_WCWIDTH_GRAPHICS],[
1405 AC_CACHE_CHECK(if wcwidth agrees graphics are single-width, cf_cv_wcwidth_graphics,[
1406 cat >conftest.in <<CF_EOF
1407 -       VT100 symbols
1408 0x250c  upper left corner
1409 0x2514  lower left corner
1410 0x2510  upper right corner
1411 0x2518  lower right corner
1412 0x251c  tee pointing left
1413 0x2524  tee pointing right
1414 0x2534  tee pointing up
1415 0x252c  tee pointing down
1416 0x2500  horizontal line
1417 0x2502  vertical line
1418 0x253c  large plus or crossover
1419 0x23ba  scan line 1
1420 0x23bd  scan line 9
1421 0x25c6  diamond
1422 0x2592  checker board (stipple)
1423 0x00b0  degree symbol
1424 0x00b1  plus/minus
1425 0x00b7  bullet
1426 -       Teletype 5410v1 symbols
1427 0x2190  arrow pointing left
1428 0x2192  arrow pointing right
1429 0x2193  arrow pointing down
1430 0x2191  arrow pointing up
1431 0x2592  board of squares
1432 0x2603  lantern symbol
1433 0x25ae  solid square block
1434 -       these defaults were invented for ncurses
1435 0x23bb  scan line 3
1436 0x23bc  scan line 7
1437 0x2264  less-than-or-equal-to
1438 0x2265  greater-than-or-equal-to
1439 0x03c0  greek pi
1440 0x2260  not-equal
1441 0x00a3  pound-sterling symbol
1442 -       thick-line-drawing
1443 0x250f  upper left corner
1444 0x2517  lower left corner
1445 0x2513  upper right corner
1446 0x251b  lower right corner
1447 0x2523  tee pointing left
1448 0x252b  tee pointing right
1449 0x253b  tee pointing up
1450 0x2533  tee pointing down
1451 0x2501  horizontal line
1452 0x2503  vertical line
1453 0x254b  large plus or crossover
1454 -       double-line-drawing
1455 0x2554  upper left corner
1456 0x255a  lower left corner
1457 0x2557  upper right corner
1458 0x255d  lower right corner
1459 0x2563  tee pointing left
1460 0x2560  tee pointing right
1461 0x2569  tee pointing up
1462 0x2566  tee pointing down
1463 0x2550  horizontal line
1464 0x2551  vertical line
1465 0x256c  large plus or crossover
1466 CF_EOF
1467 AC_TRY_RUN([
1468 #include <locale.h>
1469 #include <stdio.h>
1470 #include <wchar.h>
1471
1472 #define MY_LEN 80
1473
1474 int
1475 main(void)
1476 {
1477         FILE *fp;
1478         int value;
1479         char buffer[MY_LEN + 1];
1480         char notes[MY_LEN + 1];
1481         int totals = 0;
1482         int passed = 0;
1483
1484         if (setlocale(LC_ALL, "en_US.UTF8") ||
1485                 setlocale(LC_ALL, "en_US.UTF-8") ||
1486                 setlocale(LC_ALL, "en_US.utf8") ||
1487                 setlocale(LC_ALL, "en_US.utf-8")) {
1488                 if ((fp = fopen("conftest.in", "r")) != 0) {
1489                         while (fgets(buffer, MY_LEN, fp) != 0) {
1490                                 if (*buffer == '-') {
1491                                         fprintf(stderr, "\\t%s", buffer);
1492                                 } else if (sscanf(buffer, "%x %s", &value, notes) == 2) {
1493                                         ++totals;
1494                                         if (wcwidth(value) == 1)
1495                                                 ++passed;
1496                                         fprintf(stderr, "%d\\t%s", wcwidth(value), buffer);
1497                                 } else {
1498                                         fprintf(stderr, "?\\t%s", buffer);
1499                                 }
1500                         }
1501                 }
1502         }
1503         fprintf(stderr, "%d/%d passed wcwidth/graphics check\\n", passed, totals);
1504         return (totals == passed) ? 0 : 1;
1505 }
1506 ],
1507 [cf_cv_wcwidth_graphics=yes],
1508 [cf_cv_wcwidth_graphics=no],
1509 [cf_cv_wcwidth_graphics=unknown])
1510 ])
1511 ])dnl
1512 dnl ---------------------------------------------------------------------------
1513 dnl CF_CLANG_COMPILER version: 8 updated: 2021/01/01 13:31:04
1514 dnl -----------------
1515 dnl Check if the given compiler is really clang.  clang's C driver defines
1516 dnl __GNUC__ (fooling the configure script into setting $GCC to yes) but does
1517 dnl not ignore some gcc options.
1518 dnl
1519 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
1520 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
1521 dnl the wrappers for gcc and g++ warnings.
1522 dnl
1523 dnl $1 = GCC (default) or GXX
1524 dnl $2 = CLANG_COMPILER (default)
1525 dnl $3 = CFLAGS (default) or CXXFLAGS
1526 AC_DEFUN([CF_CLANG_COMPILER],[
1527 ifelse([$2],,CLANG_COMPILER,[$2])=no
1528
1529 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
1530         AC_MSG_CHECKING(if this is really Clang ifelse([$1],GXX,C++,C) compiler)
1531         cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
1532         AC_TRY_COMPILE([],[
1533 #ifdef __clang__
1534 #else
1535 make an error
1536 #endif
1537 ],[ifelse([$2],,CLANG_COMPILER,[$2])=yes
1538 ],[])
1539         ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
1540         AC_MSG_RESULT($ifelse([$2],,CLANG_COMPILER,[$2]))
1541 fi
1542
1543 CLANG_VERSION=none
1544
1545 if test "x$ifelse([$2],,CLANG_COMPILER,[$2])" = "xyes" ; then
1546         case "$CC" in
1547         (c[[1-9]][[0-9]]|*/c[[1-9]][[0-9]])
1548                 AC_MSG_WARN(replacing broken compiler alias $CC)
1549                 CFLAGS="$CFLAGS -std=`echo "$CC" | sed -e 's%.*/%%'`"
1550                 CC=clang
1551                 ;;
1552         esac
1553
1554         AC_MSG_CHECKING(version of $CC)
1555         CLANG_VERSION="`$CC --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(CLANG[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
1556         test -z "$CLANG_VERSION" && CLANG_VERSION=unknown
1557         AC_MSG_RESULT($CLANG_VERSION)
1558
1559         for cf_clang_opt in \
1560                 -Qunused-arguments \
1561                 -Wno-error=implicit-function-declaration
1562         do
1563                 AC_MSG_CHECKING(if option $cf_clang_opt works)
1564                 cf_save_CFLAGS="$CFLAGS"
1565                 CFLAGS="$CFLAGS $cf_clang_opt"
1566                 AC_TRY_LINK([
1567                         #include <stdio.h>],[
1568                         printf("hello!\\n");],[
1569                         cf_clang_optok=yes],[
1570                         cf_clang_optok=no])
1571                 AC_MSG_RESULT($cf_clang_optok)
1572                 CFLAGS="$cf_save_CFLAGS"
1573                 if test "$cf_clang_optok" = yes; then
1574                         CF_VERBOSE(adding option $cf_clang_opt)
1575                         CF_APPEND_TEXT(CFLAGS,$cf_clang_opt)
1576                 fi
1577         done
1578 fi
1579 ])
1580 dnl ---------------------------------------------------------------------------
1581 dnl CF_CONST_X_STRING version: 6 updated: 2021/01/01 13:31:04
1582 dnl -----------------
1583 dnl The X11R4-X11R6 Xt specification uses an ambiguous String type for most
1584 dnl character-strings.
1585 dnl
1586 dnl It is ambiguous because the specification accommodated the pre-ANSI
1587 dnl compilers bundled by more than one vendor in lieu of providing a standard C
1588 dnl compiler other than by costly add-ons.  Because of this, the specification
1589 dnl did not take into account the use of const for telling the compiler that
1590 dnl string literals would be in readonly memory.
1591 dnl
1592 dnl As a workaround, one could (starting with X11R5) define XTSTRINGDEFINES, to
1593 dnl let the compiler decide how to represent Xt's strings which were #define'd.
1594 dnl That does not solve the problem of using the block of Xt's strings which
1595 dnl are compiled into the library (and is less efficient than one might want).
1596 dnl
1597 dnl Xt specification 7 introduces the _CONST_X_STRING symbol which is used both
1598 dnl when compiling the library and compiling using the library, to tell the
1599 dnl compiler that String is const.
1600 AC_DEFUN([CF_CONST_X_STRING],
1601 [
1602 AC_REQUIRE([AC_PATH_XTRA])
1603
1604 CF_SAVE_XTRA_FLAGS([CF_CONST_X_STRING])
1605
1606 AC_TRY_COMPILE(
1607 [
1608 #include <stdlib.h>
1609 #include <X11/Intrinsic.h>
1610 ],
1611 [String foo = malloc(1); (void)foo],[
1612
1613 AC_CACHE_CHECK(for X11/Xt const-feature,cf_cv_const_x_string,[
1614         AC_TRY_COMPILE(
1615                 [
1616 #define _CONST_X_STRING /* X11R7.8 (perhaps) */
1617 #undef  XTSTRINGDEFINES /* X11R5 and later */
1618 #include <stdlib.h>
1619 #include <X11/Intrinsic.h>
1620                 ],[String foo = malloc(1); *foo = 0],[
1621                         cf_cv_const_x_string=no
1622                 ],[
1623                         cf_cv_const_x_string=yes
1624                 ])
1625 ])
1626
1627 CF_RESTORE_XTRA_FLAGS([CF_CONST_X_STRING])
1628
1629 case "$cf_cv_const_x_string" in
1630 (no)
1631         CF_APPEND_TEXT(CPPFLAGS,-DXTSTRINGDEFINES)
1632         ;;
1633 (*)
1634         CF_APPEND_TEXT(CPPFLAGS,-D_CONST_X_STRING)
1635         ;;
1636 esac
1637
1638 ])
1639 ])dnl
1640 dnl ---------------------------------------------------------------------------
1641 dnl CF_CPP_PARAM_INIT version: 7 updated: 2017/01/21 11:06:25
1642 dnl -----------------
1643 dnl Check if the C++ compiler accepts duplicate parameter initialization.  This
1644 dnl is a late feature for the standard and is not in some recent compilers
1645 dnl (1999/9/11).
1646 AC_DEFUN([CF_CPP_PARAM_INIT],
1647 [
1648 if test -n "$CXX"; then
1649 AC_CACHE_CHECK(if $CXX accepts parameter initialization,cf_cv_cpp_param_init,[
1650         AC_LANG_SAVE
1651         AC_LANG_CPLUSPLUS
1652         AC_TRY_RUN([
1653 class TEST {
1654 private:
1655         int value;
1656 public:
1657         TEST(int x = 1);
1658         ~TEST();
1659 };
1660
1661 TEST::TEST(int x = 1)   // some compilers do not like second initializer
1662 {
1663         value = x;
1664 }
1665 int main(void) { }
1666 ],
1667         [cf_cv_cpp_param_init=yes],
1668         [cf_cv_cpp_param_init=no],
1669         [cf_cv_cpp_param_init=unknown])
1670         AC_LANG_RESTORE
1671 ])
1672 fi
1673 test "$cf_cv_cpp_param_init" = yes && AC_DEFINE(CPP_HAS_PARAM_INIT,1,[Define to 1 if C++ has parameter initialization])
1674 ])dnl
1675 dnl ---------------------------------------------------------------------------
1676 dnl CF_CPP_STATIC_CAST version: 3 updated: 2013/04/13 18:03:21
1677 dnl ------------------
1678 dnl Check if the C++ compiler accepts static_cast in generics.  This appears to
1679 dnl not be supported in g++ before 3.0
1680 AC_DEFUN([CF_CPP_STATIC_CAST],
1681 [
1682 if test -n "$CXX"; then
1683
1684 AC_CACHE_CHECK(if $CXX accepts static_cast,cf_cv_cpp_static_cast,[
1685         AC_LANG_SAVE
1686         AC_LANG_CPLUSPLUS
1687
1688         AC_TRY_COMPILE([
1689 class NCursesPanel
1690 {
1691 public:
1692   NCursesPanel(int nlines,
1693                int ncols,
1694                int begin_y = 0,
1695                int begin_x = 0)
1696   {
1697   }
1698   NCursesPanel();
1699   ~NCursesPanel();
1700 };
1701
1702 template<class T> class NCursesUserPanel : public NCursesPanel
1703 {
1704 public:
1705   NCursesUserPanel (int nlines,
1706                     int ncols,
1707                     int begin_y = 0,
1708                     int begin_x = 0,
1709                     const T* p_UserData = static_cast<T*>(0))
1710     : NCursesPanel (nlines, ncols, begin_y, begin_x)
1711   {
1712   };
1713   NCursesUserPanel(const T* p_UserData = static_cast<T*>(0)) : NCursesPanel()
1714   {
1715   };
1716
1717   virtual ~NCursesUserPanel() {};
1718 };
1719 ],[
1720         const char* p_UserData = static_cast<char*>(0)],
1721         [cf_cv_cpp_static_cast=yes],
1722         [cf_cv_cpp_static_cast=no])
1723
1724         AC_LANG_RESTORE
1725 ])
1726
1727 fi
1728
1729 test "$cf_cv_cpp_static_cast" = yes && AC_DEFINE(CPP_HAS_STATIC_CAST,1,[Define to 1 if C++ has static_cast])
1730 ])dnl
1731 dnl ---------------------------------------------------------------------------
1732 dnl CF_CXX_AR_FLAGS version: 3 updated: 2021/01/01 13:31:04
1733 dnl ---------------
1734 dnl Setup special archiver flags for given compilers.
1735 AC_DEFUN([CF_CXX_AR_FLAGS],[
1736         CXX_AR='$(AR)'
1737         CXX_ARFLAGS='$(ARFLAGS)'
1738         case "$cf_cv_system_name" in
1739         (irix*)
1740             if test "$GXX" != yes ; then
1741                 CXX_AR='$(CXX)'
1742                 CXX_ARFLAGS='-ar -o'
1743             fi
1744             ;;
1745         (sco3.2v5*)
1746             CXXLDFLAGS="-u main"
1747             ;;
1748         (solaris2*)
1749             if test "$GXX" != yes ; then
1750                 CXX_AR='$(CXX)'
1751                 CXX_ARFLAGS='-xar -o'
1752             fi
1753             ;;
1754         esac
1755         AC_SUBST(CXXLDFLAGS)
1756         AC_SUBST(CXX_AR)
1757         AC_SUBST(CXX_ARFLAGS)
1758 ])dnl
1759 dnl ---------------------------------------------------------------------------
1760 dnl CF_CXX_IOSTREAM_NAMESPACE version: 2 updated: 2012/10/06 17:56:13
1761 dnl -------------------------
1762 dnl For c++, check if iostream uses "std::" namespace.
1763 AC_DEFUN([CF_CXX_IOSTREAM_NAMESPACE],[
1764 AC_CHECK_HEADERS(iostream)
1765 if test x"$ac_cv_header_iostream" = xyes ; then
1766         AC_MSG_CHECKING(if iostream uses std-namespace)
1767         AC_TRY_COMPILE([
1768 #include <iostream>
1769 using std::endl;
1770 using std::cerr;],[
1771 cerr << "testing" << endl;
1772 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1773         AC_MSG_RESULT($cf_iostream_namespace)
1774         if test "$cf_iostream_namespace" = yes ; then
1775                 AC_DEFINE(IOSTREAM_NAMESPACE,1,[Define to 1 if C++ has namespace iostream])
1776         fi
1777 fi
1778 ])dnl
1779 dnl ---------------------------------------------------------------------------
1780 dnl CF_C_INLINE version: 6 updated: 2019/09/07 13:38:36
1781 dnl -----------
1782 dnl Check if the C compiler supports "inline".
1783 dnl $1 is the name of a shell variable to set if inline is supported
1784 dnl $2 is the threshold for gcc 4.x's option controlling maximum inline size
1785 AC_DEFUN([CF_C_INLINE],[
1786 AC_REQUIRE([CF_GCC_VERSION])
1787 AC_C_INLINE
1788 $1=
1789 if test "$ac_cv_c_inline" != no ; then
1790         $1=inline
1791         if test "$INTEL_COMPILER" = yes
1792         then
1793                 :
1794         elif test "$CLANG_COMPILER" = yes
1795         then
1796                 :
1797         elif test "$GCC" = yes
1798         then
1799                 AC_CACHE_CHECK(if $CC supports options to tune inlining,cf_cv_gcc_inline,[
1800                 cf_save_CFLAGS=$CFLAGS
1801                 CFLAGS="$CFLAGS --param max-inline-insns-single=$2"
1802                 AC_TRY_COMPILE([inline int foo(void) { return 1; }],
1803                 [${cf_cv_main_return:-return} foo()],
1804                 [cf_cv_gcc_inline=yes],
1805                 [cf_cv_gcc_inline=no])
1806                 CFLAGS=$cf_save_CFLAGS
1807                 ])
1808                 if test "$cf_cv_gcc_inline" = yes ; then
1809                         CF_ADD_CFLAGS([--param max-inline-insns-single=$2])
1810                 fi
1811         fi
1812 fi
1813 AC_SUBST($1)
1814 ])dnl
1815 dnl ---------------------------------------------------------------------------
1816 dnl CF_DIRNAME version: 5 updated: 2020/12/31 20:19:42
1817 dnl ----------
1818 dnl "dirname" is not portable, so we fake it with a shell script.
1819 AC_DEFUN([CF_DIRNAME],[$1=`echo "$2" | sed -e 's%/[[^/]]*$%%'`])dnl
1820 dnl ---------------------------------------------------------------------------
1821 dnl CF_DIRS_TO_MAKE version: 4 updated: 2021/01/01 13:31:04
1822 dnl ---------------
1823 AC_DEFUN([CF_DIRS_TO_MAKE],
1824 [
1825 DIRS_TO_MAKE="lib"
1826 for cf_item in $cf_list_models
1827 do
1828         CF_OBJ_SUBDIR($cf_item,cf_subdir)
1829         for cf_item2 in $DIRS_TO_MAKE
1830         do
1831                 test "$cf_item2" = "$cf_subdir" && break
1832         done
1833         test ".$cf_item2" != ".$cf_subdir" && DIRS_TO_MAKE="$DIRS_TO_MAKE $cf_subdir"
1834 done
1835 for cf_dir in $DIRS_TO_MAKE
1836 do
1837         test ! -d "$cf_dir" && mkdir "$cf_dir"
1838 done
1839 AC_SUBST(DIRS_TO_MAKE)
1840 ])dnl
1841 dnl ---------------------------------------------------------------------------
1842 dnl CF_DISABLE_ECHO version: 13 updated: 2015/04/18 08:56:57
1843 dnl ---------------
1844 dnl You can always use "make -n" to see the actual options, but it's hard to
1845 dnl pick out/analyze warning messages when the compile-line is long.
1846 dnl
1847 dnl Sets:
1848 dnl     ECHO_LT - symbol to control if libtool is verbose
1849 dnl     ECHO_LD - symbol to prefix "cc -o" lines
1850 dnl     RULE_CC - symbol to put before implicit "cc -c" lines (e.g., .c.o)
1851 dnl     SHOW_CC - symbol to put before explicit "cc -c" lines
1852 dnl     ECHO_CC - symbol to put before any "cc" line
1853 dnl
1854 AC_DEFUN([CF_DISABLE_ECHO],[
1855 AC_MSG_CHECKING(if you want to see long compiling messages)
1856 CF_ARG_DISABLE(echo,
1857         [  --disable-echo          do not display "compiling" commands],
1858         [
1859         ECHO_LT='--silent'
1860         ECHO_LD='@echo linking [$]@;'
1861         RULE_CC='@echo compiling [$]<'
1862         SHOW_CC='@echo compiling [$]@'
1863         ECHO_CC='@'
1864 ],[
1865         ECHO_LT=''
1866         ECHO_LD=''
1867         RULE_CC=''
1868         SHOW_CC=''
1869         ECHO_CC=''
1870 ])
1871 AC_MSG_RESULT($enableval)
1872 AC_SUBST(ECHO_LT)
1873 AC_SUBST(ECHO_LD)
1874 AC_SUBST(RULE_CC)
1875 AC_SUBST(SHOW_CC)
1876 AC_SUBST(ECHO_CC)
1877 ])dnl
1878 dnl ---------------------------------------------------------------------------
1879 dnl CF_DISABLE_GNAT_PROJECTS version: 1 updated: 2014/06/01 11:34:00
1880 dnl ------------------------
1881 AC_DEFUN([CF_DISABLE_GNAT_PROJECTS],[
1882 AC_MSG_CHECKING(if we want to use GNAT projects)
1883 CF_ARG_DISABLE(gnat-projects,
1884         [  --disable-gnat-projects test: disable GNAT projects even if usable],
1885         [enable_gnat_projects=no],
1886         [enable_gnat_projects=yes])
1887 AC_MSG_RESULT($enable_gnat_projects)
1888 ])dnl
1889 dnl ---------------------------------------------------------------------------
1890 dnl CF_DISABLE_LEAKS version: 8 updated: 2021/01/05 20:05:09
1891 dnl ----------------
1892 dnl Combine no-leak checks with the libraries or tools that are used for the
1893 dnl checks.
1894 AC_DEFUN([CF_DISABLE_LEAKS],[
1895
1896 AC_REQUIRE([CF_WITH_DMALLOC])
1897 AC_REQUIRE([CF_WITH_DBMALLOC])
1898 AC_REQUIRE([CF_WITH_VALGRIND])
1899
1900 AC_MSG_CHECKING(if you want to perform memory-leak testing)
1901 AC_ARG_ENABLE(leaks,
1902         [  --disable-leaks         test: free permanent memory, analyze leaks],
1903         [enable_leaks=no],
1904         [enable_leaks=yes])
1905 dnl TODO - drop with_no_leaks
1906 if test "x$enable_leaks" = xno; then with_no_leaks=yes; else with_no_leaks=no; fi
1907 AC_MSG_RESULT($with_no_leaks)
1908
1909 if test "$enable_leaks" = no ; then
1910         AC_DEFINE(NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1911         AC_DEFINE(YY_NO_LEAKS,1,[Define to 1 if you want to perform memory-leak testing.])
1912 fi
1913 ])dnl
1914 dnl ---------------------------------------------------------------------------
1915 dnl CF_DISABLE_LIBTOOL_VERSION version: 3 updated: 2015/04/17 21:13:04
1916 dnl --------------------------
1917 dnl Check if we should use the libtool 1.5 feature "-version-number" instead of
1918 dnl the older "-version-info" feature.  The newer feature allows us to use
1919 dnl version numbering on shared libraries which make them compatible with
1920 dnl various systems.
1921 AC_DEFUN([CF_DISABLE_LIBTOOL_VERSION],
1922 [
1923 AC_MSG_CHECKING(if libtool -version-number should be used)
1924 CF_ARG_DISABLE(libtool-version,
1925         [  --disable-libtool-version  enable to use libtool's incompatible naming scheme],
1926         [cf_libtool_version=no],
1927         [cf_libtool_version=yes])
1928 AC_MSG_RESULT($cf_libtool_version)
1929
1930 if test "$cf_libtool_version" = yes ; then
1931         LIBTOOL_VERSION="-version-number"
1932 else
1933         LIBTOOL_VERSION="-version-info"
1934         case "x$VERSION" in
1935         (x)
1936                 AC_MSG_WARN(VERSION was not set)
1937                 ;;
1938         (x*.*.*)
1939                 ABI_VERSION="$VERSION"
1940                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1941                 ;;
1942         (x*:*:*)
1943                 ABI_VERSION=`echo "$VERSION" | sed -e 's/:/./g'`
1944                 CF_VERBOSE(ABI_VERSION: $ABI_VERSION)
1945                 ;;
1946         (*)
1947                 AC_MSG_WARN(unexpected VERSION value: $VERSION)
1948                 ;;
1949         esac
1950 fi
1951
1952 AC_SUBST(ABI_VERSION)
1953 AC_SUBST(LIBTOOL_VERSION)
1954 ])dnl
1955 dnl ---------------------------------------------------------------------------
1956 dnl CF_DISABLE_RPATH_HACK version: 3 updated: 2021/01/05 20:14:44
1957 dnl ---------------------
1958 dnl The rpath-hack makes it simpler to build programs, particularly with the
1959 dnl *BSD ports which may have essential libraries in unusual places.  But it
1960 dnl can interfere with building an executable for the base system.  Use this
1961 dnl option in that case.
1962 AC_DEFUN([CF_DISABLE_RPATH_HACK],
1963 [
1964 AC_MSG_CHECKING(if rpath-hack should be disabled)
1965 CF_ARG_DISABLE(rpath-hack,
1966         [  --disable-rpath-hack    don't add rpath options for additional libraries],
1967         [enable_rpath_hack=no],
1968         [enable_rpath_hack=yes])
1969 dnl TODO - drop cf_disable_rpath_hack
1970 if test "x$enable_rpath_hack" = xno; then cf_disable_rpath_hack=yes; else cf_disable_rpath_hack=no; fi
1971 AC_MSG_RESULT($cf_disable_rpath_hack)
1972
1973 if test "$enable_rpath_hack" = yes ; then
1974         CF_RPATH_HACK
1975 fi
1976 ])
1977 dnl ---------------------------------------------------------------------------
1978 dnl CF_ENABLE_BROKEN_LINKER version: 2 updated: 2021/01/02 17:09:14
1979 dnl -----------------------
1980 dnl Some linkers cannot reference a data-only object.  Cygwin used to be one.
1981 dnl This usually follows CF_LINK_DATAONLY, but is not required in case we need
1982 dnl an unconditional feature.
1983 AC_DEFUN([CF_ENABLE_BROKEN_LINKER],[
1984
1985 AC_MSG_CHECKING(if you want broken-linker support code)
1986 AC_ARG_ENABLE(broken_linker,
1987         [  --enable-broken_linker  compile with broken-linker support code],
1988         [with_broken_linker=$enableval],
1989         [with_broken_linker=no])
1990 AC_MSG_RESULT($with_broken_linker)
1991
1992 : "${BROKEN_LINKER:=0}"
1993 if test "x$with_broken_linker" = xyes ; then
1994         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
1995         BROKEN_LINKER=1
1996 fi
1997 AC_SUBST(BROKEN_LINKER)
1998 ])dnl
1999 dnl ---------------------------------------------------------------------------
2000 dnl CF_ENABLE_PC_FILES version: 13 updated: 2015/11/01 05:27:39
2001 dnl ------------------
2002 dnl This is the "--enable-pc-files" option, which is available if there is a
2003 dnl pkg-config configuration on the local machine.
2004 AC_DEFUN([CF_ENABLE_PC_FILES],[
2005 AC_REQUIRE([CF_PKG_CONFIG])
2006 AC_REQUIRE([CF_WITH_PKG_CONFIG_LIBDIR])
2007
2008 if test "x$PKG_CONFIG" != xnone
2009 then
2010         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
2011 else
2012         AC_MSG_CHECKING(if we should install .pc files)
2013 fi
2014
2015 AC_ARG_ENABLE(pc-files,
2016         [  --enable-pc-files       generate and install .pc files for pkg-config],
2017         [enable_pc_files=$enableval],
2018         [enable_pc_files=no])
2019 AC_MSG_RESULT($enable_pc_files)
2020
2021 if test "x$enable_pc_files" != xno
2022 then
2023         MAKE_PC_FILES=
2024         case "x$PKG_CONFIG_LIBDIR" in
2025         (xno|xyes)
2026                 AC_MSG_WARN(no PKG_CONFIG_LIBDIR was found)
2027                 ;;
2028         (*)
2029                 CF_PATH_SYNTAX(PKG_CONFIG_LIBDIR)
2030                 ;;
2031         esac
2032 else
2033         MAKE_PC_FILES="#"
2034 fi
2035 AC_SUBST(MAKE_PC_FILES)
2036 ])dnl
2037 dnl ---------------------------------------------------------------------------
2038 dnl CF_ENABLE_RPATH version: 2 updated: 2010/03/27 18:39:42
2039 dnl ---------------
2040 dnl Check if the rpath option should be used, setting cache variable
2041 dnl cf_cv_enable_rpath if so.
2042 AC_DEFUN([CF_ENABLE_RPATH],
2043 [
2044 AC_MSG_CHECKING(if rpath option should be used)
2045 AC_ARG_ENABLE(rpath,
2046 [  --enable-rpath          use rpath option when generating shared libraries],
2047 [cf_cv_enable_rpath=$enableval],
2048 [cf_cv_enable_rpath=no])
2049 AC_MSG_RESULT($cf_cv_enable_rpath)
2050 ])dnl
2051 dnl ---------------------------------------------------------------------------
2052 dnl CF_ENABLE_STRING_HACKS version: 6 updated: 2021/01/05 19:23:48
2053 dnl ----------------------
2054 dnl On a few platforms, the compiler and/or loader nags with untruthful
2055 dnl comments stating that "most" uses of strcat/strcpy/sprintf are incorrect,
2056 dnl and implying that most uses of the recommended alternatives are correct.
2057 dnl
2058 dnl Factually speaking, no one has actually counted the number of uses of these
2059 dnl functions versus the total of incorrect uses.  Samples of a few thousand
2060 dnl instances are meaningless compared to the hundreds of millions of lines of
2061 dnl existing C code.
2062 dnl
2063 dnl strlcat/strlcpy are (as of 2012) non-standard, and are available on some
2064 dnl platforms, in implementations of varying quality.  Likewise, snprintf is
2065 dnl standard - but evolved through phases, and older implementations are likely
2066 dnl to yield surprising results, as documented in manpages on various systems.
2067 AC_DEFUN([CF_ENABLE_STRING_HACKS],
2068 [
2069 AC_MSG_CHECKING(if you want to work around bogus compiler/loader warnings)
2070 AC_ARG_ENABLE(string-hacks,
2071         [  --enable-string-hacks   work around bogus compiler/loader warnings],
2072         [enable_string_hacks=$enableval],
2073         [enable_string_hacks=no])
2074 AC_MSG_RESULT($enable_string_hacks)
2075
2076 if test "x$enable_string_hacks" = "xyes"; then
2077         AC_DEFINE(USE_STRING_HACKS,1,[Define to 1 to work around bogus compiler/loader warnings])
2078         AC_MSG_WARN(enabling string-hacks to work around bogus compiler/loader warnings)
2079         AC_CHECK_FUNC(strlcat,[
2080                 AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
2081                 ],[
2082                 AC_CHECK_LIB(bsd,strlcat,[
2083                         CF_ADD_LIB(bsd)
2084                         AC_CHECK_HEADERS(bsd/string.h)
2085                         AC_DEFINE(HAVE_STRLCAT,1,[Define to 1 if we have strlcat function])
2086                         ])
2087                 ])
2088         AC_CHECK_FUNCS( strlcpy snprintf )
2089 fi
2090 ])dnl
2091 dnl ---------------------------------------------------------------------------
2092 dnl CF_ENABLE_WARNINGS version: 9 updated: 2021/01/05 19:40:50
2093 dnl ------------------
2094 dnl Configure-option to enable gcc warnings
2095 dnl
2096 dnl $1 = extra options to add, if supported
2097 dnl $2 = option for checking attributes.  By default, this is done when
2098 dnl      warnings are enabled.  For other values:
2099 dnl      yes: always do this, e.g., to use in generated library-headers
2100 dnl      no: never do this
2101 AC_DEFUN([CF_ENABLE_WARNINGS],[
2102 if test "$GCC" = yes || test "$GXX" = yes
2103 then
2104 CF_FIX_WARNINGS(CFLAGS)
2105 CF_FIX_WARNINGS(CPPFLAGS)
2106 CF_FIX_WARNINGS(LDFLAGS)
2107 AC_MSG_CHECKING(if you want to turn on gcc warnings)
2108 CF_ARG_ENABLE(warnings,
2109         [  --enable-warnings       test: turn on gcc compiler warnings],
2110         [enable_warnings=yes],
2111         [enable_warnings=no])
2112 AC_MSG_RESULT($enable_warnings)
2113 if test "$enable_warnings" = "yes"
2114 then
2115         ifelse($2,,[CF_GCC_ATTRIBUTES])
2116         CF_GCC_WARNINGS($1)
2117 fi
2118 ifelse($2,yes,[CF_GCC_ATTRIBUTES])
2119 fi
2120 ])dnl
2121 dnl ---------------------------------------------------------------------------
2122 dnl CF_ERRNO version: 5 updated: 1997/11/30 12:44:39
2123 dnl --------
2124 dnl Check if 'errno' is declared in <errno.h>
2125 AC_DEFUN([CF_ERRNO],
2126 [
2127 CF_CHECK_ERRNO(errno)
2128 ])dnl
2129 dnl ---------------------------------------------------------------------------
2130 dnl CF_ETIP_DEFINES version: 6 updated: 2021/01/02 17:09:14
2131 dnl ---------------
2132 dnl Test for conflicting definitions of exception in gcc 2.8.0, etc., between
2133 dnl math.h and builtin.h, only for ncurses
2134 AC_DEFUN([CF_ETIP_DEFINES],
2135 [
2136 AC_MSG_CHECKING(for special defines needed for etip.h)
2137 cf_save_CXXFLAGS="$CXXFLAGS"
2138 cf_result="none"
2139
2140 # etip.h includes ncurses.h which includes ncurses_dll.h
2141 # But ncurses_dll.h is generated - fix here.
2142 test -d include || mkdir include
2143 test -f include/ncurses_dll.h || sed -e 's/@NCURSES_WRAP_PREFIX@/'$NCURSES_WRAP_PREFIX'/g' "${srcdir}/include/ncurses_dll.h.in" >include/ncurses_dll.h
2144
2145 for cf_math in "" MATH_H
2146 do
2147 for cf_excp in "" MATH_EXCEPTION
2148 do
2149         CXXFLAGS="$cf_save_CXXFLAGS -I${srcdir}/c++ -I${srcdir}/menu -Iinclude -I${srcdir}/include"
2150         test -n "$cf_math" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_math}"
2151         test -n "$cf_excp" && CXXFLAGS="$CXXFLAGS -DETIP_NEEDS_${cf_excp}"
2152 AC_TRY_COMPILE([
2153 #include <etip.h.in>
2154 ],[],[
2155         test -n "$cf_math" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_math})
2156         test -n "$cf_excp" && AC_DEFINE_UNQUOTED(ETIP_NEEDS_${cf_excp})
2157         cf_result="$cf_math $cf_excp"
2158         break 2
2159 ],[])
2160 done
2161 done
2162 AC_MSG_RESULT($cf_result)
2163 CXXFLAGS="$cf_save_CXXFLAGS"
2164 ])
2165 dnl ---------------------------------------------------------------------------
2166 dnl CF_FIND_LINKAGE version: 22 updated: 2020/12/31 20:19:42
2167 dnl ---------------
2168 dnl Find a library (specifically the linkage used in the code fragment),
2169 dnl searching for it if it is not already in the library path.
2170 dnl See also CF_ADD_SEARCHPATH.
2171 dnl
2172 dnl Parameters (4-on are optional):
2173 dnl     $1 = headers for library entrypoint
2174 dnl     $2 = code fragment for library entrypoint
2175 dnl     $3 = the library name without the "-l" option or ".so" suffix.
2176 dnl     $4 = action to perform if successful (default: update CPPFLAGS, etc)
2177 dnl     $5 = action to perform if not successful
2178 dnl     $6 = module name, if not the same as the library name
2179 dnl     $7 = extra libraries
2180 dnl
2181 dnl Sets these variables:
2182 dnl     $cf_cv_find_linkage_$3 - yes/no according to whether linkage is found
2183 dnl     $cf_cv_header_path_$3 - include-directory if needed
2184 dnl     $cf_cv_library_path_$3 - library-directory if needed
2185 dnl     $cf_cv_library_file_$3 - library-file if needed, e.g., -l$3
2186 AC_DEFUN([CF_FIND_LINKAGE],[
2187
2188 # If the linkage is not already in the $CPPFLAGS/$LDFLAGS configuration, these
2189 # will be set on completion of the AC_TRY_LINK below.
2190 cf_cv_header_path_$3=
2191 cf_cv_library_path_$3=
2192
2193 CF_MSG_LOG([Starting [FIND_LINKAGE]($3,$6)])
2194
2195 cf_save_LIBS="$LIBS"
2196
2197 AC_TRY_LINK([$1],[$2],[
2198         cf_cv_find_linkage_$3=yes
2199         cf_cv_header_path_$3=/usr/include
2200         cf_cv_library_path_$3=/usr/lib
2201 ],[
2202
2203 LIBS="-l$3 $7 $cf_save_LIBS"
2204
2205 AC_TRY_LINK([$1],[$2],[
2206         cf_cv_find_linkage_$3=yes
2207         cf_cv_header_path_$3=/usr/include
2208         cf_cv_library_path_$3=/usr/lib
2209         cf_cv_library_file_$3="-l$3"
2210 ],[
2211         cf_cv_find_linkage_$3=no
2212         LIBS="$cf_save_LIBS"
2213
2214         CF_VERBOSE(find linkage for $3 library)
2215         CF_MSG_LOG([Searching for headers in [FIND_LINKAGE]($3,$6)])
2216
2217         cf_save_CPPFLAGS="$CPPFLAGS"
2218         cf_test_CPPFLAGS="$CPPFLAGS"
2219
2220         CF_HEADER_PATH(cf_search,ifelse([$6],,[$3],[$6]))
2221         for cf_cv_header_path_$3 in $cf_search
2222         do
2223                 if test -d "$cf_cv_header_path_$3" ; then
2224                         CF_VERBOSE(... testing $cf_cv_header_path_$3)
2225                         CPPFLAGS="$cf_save_CPPFLAGS"
2226                         CF_APPEND_TEXT(CPPFLAGS,-I$cf_cv_header_path_$3)
2227                         AC_TRY_COMPILE([$1],[$2],[
2228                                 CF_VERBOSE(... found $3 headers in $cf_cv_header_path_$3)
2229                                 cf_cv_find_linkage_$3=maybe
2230                                 cf_test_CPPFLAGS="$CPPFLAGS"
2231                                 break],[
2232                                 CPPFLAGS="$cf_save_CPPFLAGS"
2233                                 ])
2234                 fi
2235         done
2236
2237         if test "$cf_cv_find_linkage_$3" = maybe ; then
2238
2239                 CF_MSG_LOG([Searching for $3 library in [FIND_LINKAGE]($3,$6)])
2240
2241                 cf_save_LIBS="$LIBS"
2242                 cf_save_LDFLAGS="$LDFLAGS"
2243
2244                 ifelse([$6],,,[
2245                 CPPFLAGS="$cf_test_CPPFLAGS"
2246                 LIBS="-l$3 $7 $cf_save_LIBS"
2247                 AC_TRY_LINK([$1],[$2],[
2248                         CF_VERBOSE(... found $3 library in system)
2249                         cf_cv_find_linkage_$3=yes])
2250                         CPPFLAGS="$cf_save_CPPFLAGS"
2251                         LIBS="$cf_save_LIBS"
2252                         ])
2253
2254                 if test "$cf_cv_find_linkage_$3" != yes ; then
2255                         CF_LIBRARY_PATH(cf_search,$3)
2256                         for cf_cv_library_path_$3 in $cf_search
2257                         do
2258                                 if test -d "$cf_cv_library_path_$3" ; then
2259                                         CF_VERBOSE(... testing $cf_cv_library_path_$3)
2260                                         CPPFLAGS="$cf_test_CPPFLAGS"
2261                                         LIBS="-l$3 $7 $cf_save_LIBS"
2262                                         LDFLAGS="$cf_save_LDFLAGS -L$cf_cv_library_path_$3"
2263                                         AC_TRY_LINK([$1],[$2],[
2264                                         CF_VERBOSE(... found $3 library in $cf_cv_library_path_$3)
2265                                         cf_cv_find_linkage_$3=yes
2266                                         cf_cv_library_file_$3="-l$3"
2267                                         break],[
2268                                         CPPFLAGS="$cf_save_CPPFLAGS"
2269                                         LIBS="$cf_save_LIBS"
2270                                         LDFLAGS="$cf_save_LDFLAGS"
2271                                         ])
2272                                 fi
2273                         done
2274                         CPPFLAGS="$cf_save_CPPFLAGS"
2275                         LDFLAGS="$cf_save_LDFLAGS"
2276                 fi
2277
2278         else
2279                 cf_cv_find_linkage_$3=no
2280         fi
2281         ],$7)
2282 ])
2283
2284 LIBS="$cf_save_LIBS"
2285
2286 if test "$cf_cv_find_linkage_$3" = yes ; then
2287 ifelse([$4],,[
2288         CF_ADD_INCDIR($cf_cv_header_path_$3)
2289         CF_ADD_LIBDIR($cf_cv_library_path_$3)
2290         CF_ADD_LIB($3)
2291 ],[$4])
2292 else
2293 ifelse([$5],,AC_MSG_WARN(Cannot find $3 library),[$5])
2294 fi
2295 ])dnl
2296 dnl ---------------------------------------------------------------------------
2297 dnl CF_FIND_SUB_INCDIR version: 3 updated: 2021/01/01 13:31:04
2298 dnl ------------------
2299 dnl Find an include-directory with the given leaf-name.  This is useful for
2300 dnl example with FreeBSD ports, which use this convention to distinguish
2301 dnl different versions of the same port.
2302 AC_DEFUN([CF_FIND_SUB_INCDIR],[
2303         CF_SUBDIR_PATH(cf_search,$1,include)
2304         for cf_item in $cf_search
2305         do
2306                 case "$cf_item" in
2307                 (*/$1)
2308                         CF_ADD_INCDIR($cf_item)
2309                         ;;
2310                 esac
2311         done
2312 ])dnl
2313 dnl ---------------------------------------------------------------------------
2314 dnl CF_FIND_SUB_LIBDIR version: 3 updated: 2021/01/01 13:31:04
2315 dnl ------------------
2316 dnl Find a library-directory with the given leaf-name.  This is useful for
2317 dnl example with FreeBSD ports, which use this convention to distinguish
2318 dnl different versions of the same port.
2319 AC_DEFUN([CF_FIND_SUB_LIBDIR],[
2320         CF_SUBDIR_PATH(cf_search,$1,lib)
2321         for cf_item in $cf_search
2322         do
2323                 case "$cf_item" in
2324                 (*/$1)
2325                         CF_ADD_LIBDIR($cf_item)
2326                         ;;
2327                 esac
2328         done
2329 ])dnl
2330 dnl ---------------------------------------------------------------------------
2331 dnl CF_FIXUP_ADAFLAGS version: 2 updated: 2015/04/17 21:13:04
2332 dnl -----------------
2333 dnl make ADAFLAGS consistent with CFLAGS
2334 AC_DEFUN([CF_FIXUP_ADAFLAGS],[
2335         AC_MSG_CHECKING(optimization options for ADAFLAGS)
2336         case "$CFLAGS" in
2337         (*-g*)
2338                 CF_ADD_ADAFLAGS(-g)
2339                 ;;
2340         esac
2341         case "$CFLAGS" in
2342         (*-O*)
2343                 cf_O_flag=`echo "$CFLAGS" |sed -e 's/^.*-O/-O/' -e 's/[[        ]].*//'`
2344                 CF_ADD_ADAFLAGS($cf_O_flag)
2345                 ;;
2346         esac
2347         AC_MSG_RESULT($ADAFLAGS)
2348 ])dnl
2349 dnl ---------------------------------------------------------------------------
2350 dnl CF_FIX_WARNINGS version: 3 updated: 2020/12/31 18:40:20
2351 dnl ---------------
2352 dnl Warning flags do not belong in CFLAGS, CPPFLAGS, etc.  Any of gcc's
2353 dnl "-Werror" flags can interfere with configure-checks.  Those go into
2354 dnl EXTRA_CFLAGS.
2355 dnl
2356 dnl $1 = variable name to repair
2357 define([CF_FIX_WARNINGS],[
2358 if test "$GCC" = yes || test "$GXX" = yes
2359 then
2360         case [$]$1 in
2361         (*-Werror=*)
2362                 CF_VERBOSE(repairing $1: [$]$1)
2363                 cf_temp_flags=
2364                 for cf_temp_scan in [$]$1
2365                 do
2366                         case "x$cf_temp_scan" in
2367                         (x-Werror=*)
2368                                 CF_APPEND_TEXT(EXTRA_CFLAGS,$cf_temp_scan)
2369                                 ;;
2370                         (*)
2371                                 CF_APPEND_TEXT(cf_temp_flags,$cf_temp_scan)
2372                                 ;;
2373                         esac
2374                 done
2375                 $1="$cf_temp_flags"
2376                 CF_VERBOSE(... fixed [$]$1)
2377                 CF_VERBOSE(... extra $EXTRA_CFLAGS)
2378                 ;;
2379         esac
2380 fi
2381 AC_SUBST(EXTRA_CFLAGS)
2382 ])dnl
2383 dnl ---------------------------------------------------------------------------
2384 dnl CF_FOPEN_BIN_R version: 2 updated: 2019/12/31 08:53:54
2385 dnl --------------
2386 dnl Check if fopen works when the "b" (binary) flag is added to the mode
2387 dnl parameter.  POSIX ignores the "b", which c89 specified.  Some very old
2388 dnl systems do not accept it.
2389 AC_DEFUN([CF_FOPEN_BIN_R],[
2390 AC_CACHE_CHECK(if fopen accepts explicit binary mode,cf_cv_fopen_bin_r,[
2391         AC_TRY_RUN([
2392 #include <stdio.h>
2393 int main(void) {
2394         FILE *fp = fopen("conftest.tmp", "wb");
2395         int rc = 0;
2396         if (fp != 0) {
2397                 int p, q;
2398                 for (p = 0; p < 256; ++p) {
2399                         fputc(p, fp);
2400                 }
2401                 fclose(fp);
2402                 fp = fopen("conftest.tmp", "rb");
2403                 if (fp != 0) {
2404                         for (p = 0; p < 256; ++p) {
2405                                 q = fgetc(fp);
2406                                 if (q != p) {
2407                                         rc = 1;
2408                                         break;
2409                                 }
2410                         }
2411                 } else {
2412                         rc = 1;
2413                 }
2414         } else {
2415                 rc = 1;
2416         }
2417         ${cf_cv_main_return:-return} (rc);
2418 }
2419 ],
2420                 [cf_cv_fopen_bin_r=yes],
2421                 [cf_cv_fopen_bin_r=no],
2422                 [cf_cv_fopen_bin_r=unknown])
2423 ])
2424 test "x$cf_cv_fopen_bin_r" != xno && AC_DEFINE(USE_FOPEN_BIN_R,1,[Define to 1 if fopen accepts explicit binary mode])
2425 ])dnl
2426 dnl ---------------------------------------------------------------------------
2427 dnl CF_FORGET_TOOL version: 1 updated: 2013/04/06 18:03:09
2428 dnl --------------
2429 dnl Forget that we saw the given tool.
2430 AC_DEFUN([CF_FORGET_TOOL],[
2431 unset ac_cv_prog_ac_ct_$1
2432 unset ac_ct_$1
2433 unset $1
2434 ])dnl
2435 dnl ---------------------------------------------------------------------------
2436 dnl CF_FUNC_DLSYM version: 4 updated: 2015/09/12 14:46:44
2437 dnl -------------
2438 dnl Test for dlsym() and related functions, as well as libdl.
2439 dnl
2440 dnl Sets
2441 dnl     $cf_have_dlsym
2442 dnl     $cf_have_libdl
2443 AC_DEFUN([CF_FUNC_DLSYM],[
2444 cf_have_dlsym=no
2445 AC_CHECK_FUNC(dlsym,cf_have_dlsym=yes,[
2446
2447 cf_have_libdl=no
2448 AC_CHECK_LIB(dl,dlsym,[
2449         cf_have_dlsym=yes
2450         cf_have_libdl=yes])])
2451
2452 if test "$cf_have_dlsym" = yes ; then
2453         test "$cf_have_libdl" = yes && { CF_ADD_LIB(dl) }
2454
2455         AC_MSG_CHECKING(whether able to link to dl*() functions)
2456         AC_TRY_LINK([#include <dlfcn.h>],[
2457                 void *obj;
2458                 if ((obj = dlopen("filename", 0)) != 0) {
2459                         if (dlsym(obj, "symbolname") == 0) {
2460                         dlclose(obj);
2461                         }
2462                 }],[
2463                 AC_DEFINE(HAVE_LIBDL,1,[Define to 1 if we have dl library])],[
2464                 AC_MSG_ERROR(Cannot link test program for libdl)])
2465         AC_MSG_RESULT(ok)
2466 else
2467         AC_MSG_ERROR(Cannot find dlsym function)
2468 fi
2469 ])
2470 dnl ---------------------------------------------------------------------------
2471 dnl CF_FUNC_MEMMOVE version: 9 updated: 2017/01/21 11:06:25
2472 dnl ---------------
2473 dnl Check for memmove, or a bcopy that can handle overlapping copy.  If neither
2474 dnl is found, add our own version of memmove to the list of objects.
2475 AC_DEFUN([CF_FUNC_MEMMOVE],
2476 [
2477 AC_CHECK_FUNC(memmove,,[
2478 AC_CHECK_FUNC(bcopy,[
2479         AC_CACHE_CHECK(if bcopy does overlapping moves,cf_cv_good_bcopy,[
2480                 AC_TRY_RUN([
2481 int main(void) {
2482         static char data[] = "abcdefghijklmnopqrstuwwxyz";
2483         char temp[40];
2484         bcopy(data, temp, sizeof(data));
2485         bcopy(temp+10, temp, 15);
2486         bcopy(temp+5, temp+15, 10);
2487         ${cf_cv_main_return:-return} (strcmp(temp, "klmnopqrstuwwxypqrstuwwxyz"));
2488 }
2489                 ],
2490                 [cf_cv_good_bcopy=yes],
2491                 [cf_cv_good_bcopy=no],
2492                 [cf_cv_good_bcopy=unknown])
2493                 ])
2494         ],[cf_cv_good_bcopy=no])
2495         if test "$cf_cv_good_bcopy" = yes ; then
2496                 AC_DEFINE(USE_OK_BCOPY,1,[Define to 1 to use bcopy when memmove is unavailable])
2497         else
2498                 AC_DEFINE(USE_MY_MEMMOVE,1,[Define to 1 to use replacement function when memmove is unavailable])
2499         fi
2500 ])])dnl
2501 dnl ---------------------------------------------------------------------------
2502 dnl CF_FUNC_NANOSLEEP version: 5 updated: 2017/01/21 11:06:25
2503 dnl -----------------
2504 dnl Check for existence of workable nanosleep() function.  Some systems, e.g.,
2505 dnl AIX 4.x, provide a non-working version.
2506 AC_DEFUN([CF_FUNC_NANOSLEEP],[
2507 AC_CACHE_CHECK(if nanosleep really works,cf_cv_func_nanosleep,[
2508 AC_TRY_RUN([
2509 #include <stdio.h>
2510 #include <errno.h>
2511 #include <time.h>
2512
2513 #ifdef HAVE_SYS_TIME_H
2514 #include <sys/time.h>
2515 #endif
2516
2517 int main(void) {
2518         struct timespec ts1, ts2;
2519         int code;
2520         ts1.tv_sec  = 0;
2521         ts1.tv_nsec = 750000000;
2522         ts2.tv_sec  = 0;
2523         ts2.tv_nsec = 0;
2524         errno = 0;
2525         code = nanosleep(&ts1, &ts2); /* on failure errno is ENOSYS. */
2526         ${cf_cv_main_return:-return}(code != 0);
2527 }
2528 ],
2529         [cf_cv_func_nanosleep=yes],
2530         [cf_cv_func_nanosleep=no],
2531         [cf_cv_func_nanosleep=unknown])])
2532
2533 test "$cf_cv_func_nanosleep" = "yes" && AC_DEFINE(HAVE_NANOSLEEP,1,[Define to 1 if we have nanosleep()])
2534 ])
2535 dnl ---------------------------------------------------------------------------
2536 dnl CF_FUNC_OPENPTY version: 6 updated: 2021/01/01 13:31:04
2537 dnl ---------------
2538 dnl Check for openpty() function, along with <pty.h> header.  It may need the
2539 dnl "util" library as well.
2540 AC_DEFUN([CF_FUNC_OPENPTY],
2541 [
2542 AC_CHECK_LIB(util,openpty,cf_cv_lib_util=yes,cf_cv_lib_util=no)
2543 AC_CACHE_CHECK(for openpty header,cf_cv_func_openpty,[
2544         cf_save_LIBS="$LIBS"
2545         test "$cf_cv_lib_util" = yes && { CF_ADD_LIB(util) }
2546         for cf_header in pty.h libutil.h util.h
2547         do
2548         AC_TRY_LINK([
2549 #include <$cf_header>
2550 ],[
2551         int x = openpty((int *)0, (int *)0, (char *)0,
2552                                    (struct termios *)0, (struct winsize *)0);
2553 ],[
2554                 cf_cv_func_openpty=$cf_header
2555                 break
2556 ],[
2557                 cf_cv_func_openpty=no
2558 ])
2559         done
2560         LIBS="$cf_save_LIBS"
2561 ])
2562 ])dnl
2563 dnl ---------------------------------------------------------------------------
2564 dnl CF_FUNC_POLL version: 10 updated: 2021/01/04 19:13:57
2565 dnl ------------
2566 dnl See if the poll function really works.  Some platforms have poll(), but
2567 dnl it does not work for terminals or files.
2568 AC_DEFUN([CF_FUNC_POLL],[
2569 tty >/dev/null 2>&1 || { AC_CHECK_FUNCS(posix_openpt) }
2570 AC_CACHE_CHECK(if poll really works,cf_cv_working_poll,[
2571 AC_TRY_RUN([
2572 #include <stdlib.h>
2573 #include <stdio.h>
2574 #include <unistd.h>
2575 #include <fcntl.h>
2576 #ifdef HAVE_POLL_H
2577 #include <poll.h>
2578 #else
2579 #include <sys/poll.h>
2580 #endif
2581 int main(void) {
2582         struct pollfd myfds;
2583         int ret;
2584
2585         /* check for Darwin bug with respect to "devices" */
2586         myfds.fd = open("/dev/null", 1);        /* O_WRONLY */
2587         if (myfds.fd < 0)
2588                 myfds.fd = 0;
2589         myfds.events = POLLIN;
2590         myfds.revents = 0;
2591
2592         ret = poll(&myfds, 1, 100);
2593
2594         if (ret < 0 || (myfds.revents & POLLNVAL)) {
2595                 ret = -1;
2596         } else {
2597                 int fd = 0;
2598                 if (!isatty(fd)) {
2599                         fd = open("/dev/tty", 2);       /* O_RDWR */
2600                 }
2601 #ifdef HAVE_POSIX_OPENPT
2602                 if (fd < 0) {
2603                         fd = posix_openpt(O_RDWR);
2604                 }
2605 #endif
2606
2607                 if (fd >= 0) {
2608                         /* also check with standard input */
2609                         myfds.fd = fd;
2610                         myfds.events = POLLIN;
2611                         myfds.revents = 0;
2612                         ret = poll(&myfds, 1, 100);
2613                 } else {
2614                         ret = -1;
2615                 }
2616         }
2617         ${cf_cv_main_return:-return}(ret < 0);
2618 }],
2619         [cf_cv_working_poll=yes],
2620         [cf_cv_working_poll=no],
2621         [cf_cv_working_poll=unknown])])
2622 test "$cf_cv_working_poll" = "yes" && AC_DEFINE(HAVE_WORKING_POLL,1,[Define to 1 if the poll function seems to work])
2623 ])dnl
2624 dnl ---------------------------------------------------------------------------
2625 dnl CF_FUNC_TERMIOS version: 3 updated: 2012/10/06 17:56:13
2626 dnl ---------------
2627 dnl Some old/broken variations define tcgetattr() only as a macro in
2628 dnl termio(s).h
2629 AC_DEFUN([CF_FUNC_TERMIOS],[
2630 AC_REQUIRE([CF_STRUCT_TERMIOS])
2631 AC_CACHE_CHECK(for tcgetattr, cf_cv_have_tcgetattr,[
2632 AC_TRY_LINK([
2633 #include <sys/types.h>
2634 #ifdef HAVE_UNISTD_H
2635 #include <unistd.h>
2636 #endif
2637 #ifdef HAVE_TERMIOS_H
2638 #include <termios.h>
2639 #define TTY struct termios
2640 #else
2641 #ifdef HAVE_TERMIO_H
2642 #include <termio.h>
2643 #define TTY struct termio
2644 #endif
2645 #endif
2646 ],[
2647 TTY foo;
2648 tcgetattr(1, &foo);],
2649 [cf_cv_have_tcgetattr=yes],
2650 [cf_cv_have_tcgetattr=no])])
2651 test "$cf_cv_have_tcgetattr" = yes && AC_DEFINE(HAVE_TCGETATTR,1,[Define to 1 if we have tcgetattr])
2652 ])dnl
2653 dnl ---------------------------------------------------------------------------
2654 dnl CF_FUNC_VSSCANF version: 7 updated: 2021/01/01 13:31:04
2655 dnl ---------------
2656 dnl Check for vsscanf() function, which is in c9x but generally not in earlier
2657 dnl versions of C.  It is in the GNU C library, and can often be simulated by
2658 dnl other functions.
2659 AC_DEFUN([CF_FUNC_VSSCANF],
2660 [
2661 AC_CACHE_CHECK(for vsscanf function or workaround,cf_cv_func_vsscanf,[
2662 AC_TRY_LINK([
2663 #include <stdarg.h>
2664 #include <stdio.h>],[
2665         va_list ap;
2666         vsscanf("from", "%d", ap)],[cf_cv_func_vsscanf=vsscanf],[
2667 AC_TRY_LINK([
2668 #include <stdarg.h>
2669 #include <stdio.h>],[
2670         FILE strbuf;
2671         char *str = "from";
2672
2673         strbuf._flag = _IOREAD;
2674         strbuf._ptr = strbuf._base = (unsigned char *) str;
2675         strbuf._cnt = strlen(str);
2676         strbuf._file = _NFILE;
2677         return (vfscanf(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=vfscanf],[
2678 AC_TRY_LINK([
2679 #include <stdarg.h>
2680 #include <stdio.h>],[
2681         FILE strbuf;
2682         char *str = "from";
2683
2684         strbuf._flag = _IOREAD;
2685         strbuf._ptr = strbuf._base = (unsigned char *) str;
2686         strbuf._cnt = strlen(str);
2687         strbuf._file = _NFILE;
2688         return (_doscan(&strbuf, "%d", ap))],[cf_cv_func_vsscanf=_doscan],[
2689 cf_cv_func_vsscanf=no])])])])
2690
2691 case "$cf_cv_func_vsscanf" in
2692 (vsscanf) AC_DEFINE(HAVE_VSSCANF,1,[Define to 1 if we have vsscanf]);;
2693 (vfscanf) AC_DEFINE(HAVE_VFSCANF,1,[Define to 1 if we have vfscanf]);;
2694 (_doscan) AC_DEFINE(HAVE__DOSCAN,1,[Define to 1 if we have _doscan]);;
2695 esac
2696
2697 ])dnl
2698 dnl ---------------------------------------------------------------------------
2699 dnl CF_GCC_ATTRIBUTES version: 24 updated: 2021/03/20 12:00:25
2700 dnl -----------------
2701 dnl Test for availability of useful gcc __attribute__ directives to quiet
2702 dnl compiler warnings.  Though useful, not all are supported -- and contrary
2703 dnl to documentation, unrecognized directives cause older compilers to barf.
2704 AC_DEFUN([CF_GCC_ATTRIBUTES],
2705 [AC_REQUIRE([AC_PROG_FGREP])dnl
2706 AC_REQUIRE([CF_C11_NORETURN])dnl
2707
2708 if test "$GCC" = yes || test "$GXX" = yes
2709 then
2710 cat > conftest.i <<EOF
2711 #ifndef GCC_PRINTF
2712 #define GCC_PRINTF 0
2713 #endif
2714 #ifndef GCC_SCANF
2715 #define GCC_SCANF 0
2716 #endif
2717 #ifndef GCC_NORETURN
2718 #define GCC_NORETURN /* nothing */
2719 #endif
2720 #ifndef GCC_UNUSED
2721 #define GCC_UNUSED /* nothing */
2722 #endif
2723 EOF
2724 if test "$GCC" = yes
2725 then
2726         AC_CHECKING([for $CC __attribute__ directives])
2727 cat > "conftest.$ac_ext" <<EOF
2728 #line __oline__ "${as_me:-configure}"
2729 #include "confdefs.h"
2730 #include "conftest.h"
2731 #include "conftest.i"
2732 #if     GCC_PRINTF
2733 #define GCC_PRINTFLIKE(fmt,var) __attribute__((format(printf,fmt,var)))
2734 #else
2735 #define GCC_PRINTFLIKE(fmt,var) /*nothing*/
2736 #endif
2737 #if     GCC_SCANF
2738 #define GCC_SCANFLIKE(fmt,var)  __attribute__((format(scanf,fmt,var)))
2739 #else
2740 #define GCC_SCANFLIKE(fmt,var)  /*nothing*/
2741 #endif
2742 extern void wow(char *,...) GCC_SCANFLIKE(1,2);
2743 extern GCC_NORETURN void oops(char *,...) GCC_PRINTFLIKE(1,2);
2744 extern GCC_NORETURN void foo(void);
2745 int main(int argc GCC_UNUSED, char *argv[[]] GCC_UNUSED) { (void)argc; (void)argv; return 0; }
2746 EOF
2747         cf_printf_attribute=no
2748         cf_scanf_attribute=no
2749         for cf_attribute in scanf printf unused noreturn
2750         do
2751                 CF_UPPER(cf_ATTRIBUTE,$cf_attribute)
2752                 cf_directive="__attribute__(($cf_attribute))"
2753                 echo "checking for $CC $cf_directive" 1>&AC_FD_CC
2754
2755                 case "$cf_attribute" in
2756                 (printf)
2757                         cf_printf_attribute=yes
2758                         cat >conftest.h <<EOF
2759 #define GCC_$cf_ATTRIBUTE 1
2760 EOF
2761                         ;;
2762                 (scanf)
2763                         cf_scanf_attribute=yes
2764                         cat >conftest.h <<EOF
2765 #define GCC_$cf_ATTRIBUTE 1
2766 EOF
2767                         ;;
2768                 (*)
2769                         cat >conftest.h <<EOF
2770 #define GCC_$cf_ATTRIBUTE $cf_directive
2771 EOF
2772                         ;;
2773                 esac
2774
2775                 if AC_TRY_EVAL(ac_compile); then
2776                         test -n "$verbose" && AC_MSG_RESULT(... $cf_attribute)
2777                         cat conftest.h >>confdefs.h
2778                         case "$cf_attribute" in
2779                         (noreturn)
2780                                 AC_DEFINE_UNQUOTED(GCC_NORETURN,$cf_directive,[Define to noreturn-attribute for gcc])
2781                                 ;;
2782                         (printf)
2783                                 cf_value='/* nothing */'
2784                                 if test "$cf_printf_attribute" != no ; then
2785                                         cf_value='__attribute__((format(printf,fmt,var)))'
2786                                         AC_DEFINE(GCC_PRINTF,1,[Define to 1 if the compiler supports gcc-like printf attribute.])
2787                                 fi
2788                                 AC_DEFINE_UNQUOTED(GCC_PRINTFLIKE(fmt,var),$cf_value,[Define to printf-attribute for gcc])
2789                                 ;;
2790                         (scanf)
2791                                 cf_value='/* nothing */'
2792                                 if test "$cf_scanf_attribute" != no ; then
2793                                         cf_value='__attribute__((format(scanf,fmt,var)))'
2794                                         AC_DEFINE(GCC_SCANF,1,[Define to 1 if the compiler supports gcc-like scanf attribute.])
2795                                 fi
2796                                 AC_DEFINE_UNQUOTED(GCC_SCANFLIKE(fmt,var),$cf_value,[Define to sscanf-attribute for gcc])
2797                                 ;;
2798                         (unused)
2799                                 AC_DEFINE_UNQUOTED(GCC_UNUSED,$cf_directive,[Define to unused-attribute for gcc])
2800                                 ;;
2801                         esac
2802                 fi
2803         done
2804 else
2805         ${FGREP-fgrep} define conftest.i >>confdefs.h
2806 fi
2807 rm -rf ./conftest*
2808 fi
2809 ])dnl
2810 dnl ---------------------------------------------------------------------------
2811 dnl CF_GCC_VERSION version: 8 updated: 2019/09/07 13:38:36
2812 dnl --------------
2813 dnl Find version of gcc, and (because icc/clang pretend to be gcc without being
2814 dnl compatible), attempt to determine if icc/clang is actually used.
2815 AC_DEFUN([CF_GCC_VERSION],[
2816 AC_REQUIRE([AC_PROG_CC])
2817 GCC_VERSION=none
2818 if test "$GCC" = yes ; then
2819         AC_MSG_CHECKING(version of $CC)
2820         GCC_VERSION="`${CC} --version 2>/dev/null | sed -e '2,$d' -e 's/^.*(GCC[[^)]]*) //' -e 's/^.*(Debian[[^)]]*) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
2821         test -z "$GCC_VERSION" && GCC_VERSION=unknown
2822         AC_MSG_RESULT($GCC_VERSION)
2823 fi
2824 CF_INTEL_COMPILER(GCC,INTEL_COMPILER,CFLAGS)
2825 CF_CLANG_COMPILER(GCC,CLANG_COMPILER,CFLAGS)
2826 ])dnl
2827 dnl ---------------------------------------------------------------------------
2828 dnl CF_GCC_WARNINGS version: 41 updated: 2021/01/01 16:53:59
2829 dnl ---------------
2830 dnl Check if the compiler supports useful warning options.  There's a few that
2831 dnl we don't use, simply because they're too noisy:
2832 dnl
2833 dnl     -Wconversion (useful in older versions of gcc, but not in gcc 2.7.x)
2834 dnl     -Winline (usually not worthwhile)
2835 dnl     -Wredundant-decls (system headers make this too noisy)
2836 dnl     -Wtraditional (combines too many unrelated messages, only a few useful)
2837 dnl     -Wwrite-strings (too noisy, but should review occasionally).  This
2838 dnl             is enabled for ncurses using "--enable-const".
2839 dnl     -pedantic
2840 dnl
2841 dnl Parameter:
2842 dnl     $1 is an optional list of gcc warning flags that a particular
2843 dnl             application might want to use, e.g., "no-unused" for
2844 dnl             -Wno-unused
2845 dnl Special:
2846 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
2847 dnl
2848 AC_DEFUN([CF_GCC_WARNINGS],
2849 [
2850 AC_REQUIRE([CF_GCC_VERSION])
2851 if test "x$have_x" = xyes; then CF_CONST_X_STRING fi
2852 cat > "conftest.$ac_ext" <<EOF
2853 #line __oline__ "${as_me:-configure}"
2854 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
2855 EOF
2856 if test "$INTEL_COMPILER" = yes
2857 then
2858 # The "-wdXXX" options suppress warnings:
2859 # remark #1419: external declaration in primary source file
2860 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
2861 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
2862 # remark #193: zero used for undefined preprocessing identifier
2863 # remark #593: variable "curs_sb_left_arrow" was set but never used
2864 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
2865 # remark #869: parameter "tw" was never referenced
2866 # remark #981: operands are evaluated in unspecified order
2867 # warning #279: controlling expression is constant
2868
2869         AC_CHECKING([for $CC warning options])
2870         cf_save_CFLAGS="$CFLAGS"
2871         EXTRA_CFLAGS="$EXTRA_CFLAGS -Wall"
2872         for cf_opt in \
2873                 wd1419 \
2874                 wd1683 \
2875                 wd1684 \
2876                 wd193 \
2877                 wd593 \
2878                 wd279 \
2879                 wd810 \
2880                 wd869 \
2881                 wd981
2882         do
2883                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2884                 if AC_TRY_EVAL(ac_compile); then
2885                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2886                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2887                 fi
2888         done
2889         CFLAGS="$cf_save_CFLAGS"
2890 elif test "$GCC" = yes && test "$GCC_VERSION" != "unknown"
2891 then
2892         AC_CHECKING([for $CC warning options])
2893         cf_save_CFLAGS="$CFLAGS"
2894         cf_warn_CONST=""
2895         test "$with_ext_const" = yes && cf_warn_CONST="Wwrite-strings"
2896         cf_gcc_warnings="Wignored-qualifiers Wlogical-op Wvarargs"
2897         test "x$CLANG_COMPILER" = xyes && cf_gcc_warnings=
2898         for cf_opt in W Wall \
2899                 Wbad-function-cast \
2900                 Wcast-align \
2901                 Wcast-qual \
2902                 Wdeclaration-after-statement \
2903                 Wextra \
2904                 Winline \
2905                 Wmissing-declarations \
2906                 Wmissing-prototypes \
2907                 Wnested-externs \
2908                 Wpointer-arith \
2909                 Wshadow \
2910                 Wstrict-prototypes \
2911                 Wundef Wno-inline $cf_gcc_warnings $cf_warn_CONST $1
2912         do
2913                 CFLAGS="$cf_save_CFLAGS $EXTRA_CFLAGS -$cf_opt"
2914                 if AC_TRY_EVAL(ac_compile); then
2915                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
2916                         case "$cf_opt" in
2917                         (Winline)
2918                                 case "$GCC_VERSION" in
2919                                 ([[34]].*)
2920                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2921                                         continue;;
2922                                 esac
2923                                 ;;
2924                         (Wpointer-arith)
2925                                 case "$GCC_VERSION" in
2926                                 ([[12]].*)
2927                                         CF_VERBOSE(feature is broken in gcc $GCC_VERSION)
2928                                         continue;;
2929                                 esac
2930                                 ;;
2931                         esac
2932                         EXTRA_CFLAGS="$EXTRA_CFLAGS -$cf_opt"
2933                 fi
2934         done
2935         CFLAGS="$cf_save_CFLAGS"
2936 fi
2937 rm -rf ./conftest*
2938
2939 AC_SUBST(EXTRA_CFLAGS)
2940 ])dnl
2941 dnl ---------------------------------------------------------------------------
2942 dnl CF_GETOPT_HEADER version: 7 updated: 2021/01/01 13:31:04
2943 dnl ----------------
2944 dnl Check for getopt's variables which are commonly defined in stdlib.h,
2945 dnl unistd.h or (nonstandard) in getopt.h
2946 AC_DEFUN([CF_GETOPT_HEADER],
2947 [
2948 AC_HAVE_HEADERS(unistd.h getopt.h)
2949 AC_CACHE_CHECK(for header declaring getopt variables,cf_cv_getopt_header,[
2950 cf_cv_getopt_header=none
2951 for cf_header in stdio.h stdlib.h unistd.h getopt.h
2952 do
2953 AC_TRY_COMPILE([
2954 #include <$cf_header>],
2955 [int x = optind; char *y = optarg],
2956 [cf_cv_getopt_header=$cf_header
2957  break])
2958 done
2959 ])
2960 if test "$cf_cv_getopt_header" != none ; then
2961         AC_DEFINE(HAVE_GETOPT_HEADER,1,[Define to 1 if getopt variables are declared in header])
2962 fi
2963 if test "$cf_cv_getopt_header" = getopt.h ; then
2964         AC_DEFINE(NEED_GETOPT_H,1,[Define to 1 if we must include getopt.h])
2965 fi
2966 ])dnl
2967 dnl ---------------------------------------------------------------------------
2968 dnl CF_GNATPREP_OPT_T version: 1 updated: 2014/08/02 18:37:25
2969 dnl -----------------
2970 AC_DEFUN([CF_GNATPREP_OPT_T],[
2971 AC_CACHE_CHECK(if GNATPREP supports -T option,cf_cv_gnatprep_opt_t,[
2972 cf_cv_gnatprep_opt_t=no
2973 gnatprep -T 2>/dev/null >/dev/null && cf_cv_gnatprep_opt_t=yes
2974 ])
2975 test "$cf_cv_gnatprep_opt_t" = yes && GNATPREP_OPTS="-T $GNATPREP_OPTS"
2976 AC_SUBST(GNATPREP_OPTS)
2977 ])dnl
2978 dnl ---------------------------------------------------------------------------
2979 dnl CF_GNAT_GENERICS version: 7 updated: 2021/01/01 13:31:04
2980 dnl ----------------
2981 AC_DEFUN([CF_GNAT_GENERICS],
2982 [
2983 AC_REQUIRE([CF_GNAT_VERSION])
2984
2985 AC_MSG_CHECKING(if GNAT supports generics)
2986 case "$cf_cv_gnat_version" in
2987 (3.1[[1-9]]*|3.[[2-9]]*|[[4-9]].*|[[1-9]][[0-9]].[[0-9]]*|20[[0-9]][[0-9]])
2988         cf_gnat_generics=yes
2989         ;;
2990 (*)
2991         cf_gnat_generics=no
2992         ;;
2993 esac
2994 AC_MSG_RESULT($cf_gnat_generics)
2995
2996 if test "$cf_gnat_generics" = yes
2997 then
2998         cf_compile_generics=generics
2999         cf_generic_objects="\${GENOBJS}"
3000 else
3001         cf_compile_generics=
3002         cf_generic_objects=
3003 fi
3004
3005 AC_SUBST(cf_compile_generics)
3006 AC_SUBST(cf_generic_objects)
3007 ])dnl
3008 dnl ---------------------------------------------------------------------------
3009 dnl CF_GNAT_PROJECTS version: 13 updated: 2021/01/02 17:09:14
3010 dnl ----------------
3011 dnl GNAT projects are configured with ".gpr" project files.
3012 dnl GNAT libraries are a further development, using the project feature.
3013 AC_DEFUN([CF_GNAT_PROJECTS],
3014 [
3015 AC_REQUIRE([CF_GNAT_VERSION])
3016 AC_REQUIRE([CF_DISABLE_GNAT_PROJECTS])
3017
3018 cf_gnat_libraries=no
3019 cf_gnat_projects=no
3020
3021 if test "$enable_gnat_projects" != no ; then
3022 AC_MSG_CHECKING(if GNAT supports project files)
3023 case "$cf_cv_gnat_version" in
3024 (3.[[0-9]]*)
3025         ;;
3026 (*)
3027         case "$cf_cv_system_name" in
3028         (cygwin*|msys*)
3029                 ;;
3030         (*)
3031                 rm -rf ./conftest* ./*~conftest*
3032                 if mkdir conftest.src conftest.bin conftest.lib
3033                 then
3034                         cd conftest.src
3035                         rm -rf ./conftest* ./*~conftest*
3036                         cat >>library.gpr <<CF_EOF
3037 project Library is
3038   Kind := External ("LIB_KIND");
3039   for Library_Name use "ConfTest";
3040   for Object_Dir use ".";
3041   for Library_ALI_Dir use External("LIBRARY_DIR");
3042   for Library_Version use External ("SONAME");
3043   for Library_Kind use Kind;
3044   for Library_Dir use External("BUILD_DIR");
3045   Source_Dir := External ("SOURCE_DIR");
3046   for Source_Dirs use (Source_Dir);
3047 end Library;
3048 CF_EOF
3049                         cat >>confpackage.ads <<CF_EOF
3050 package ConfPackage is
3051    procedure conftest;
3052 end ConfPackage;
3053 CF_EOF
3054                         cat >>confpackage.adb <<CF_EOF
3055 with Text_IO;
3056 package body ConfPackage is
3057    procedure conftest is
3058    begin
3059       Text_IO.Put ("Hello World");
3060       Text_IO.New_Line;
3061    end conftest;
3062 end ConfPackage;
3063 CF_EOF
3064                         if ( "$cf_ada_make" $ADAFLAGS \
3065                                         -Plibrary.gpr \
3066                                         -XBUILD_DIR="`cd ../conftest.bin;pwd`" \
3067                                         -XLIBRARY_DIR="`cd ../conftest.lib;pwd`" \
3068                                         -XSOURCE_DIR="`pwd`" \
3069                                         -XSONAME=libConfTest.so.1 \
3070                                         -XLIB_KIND=static 1>&AC_FD_CC 2>&1 ) ; then
3071                                 cf_gnat_projects=yes
3072                         fi
3073                         cd ..
3074                 fi
3075                 if test -f conftest.lib/confpackage.ali
3076                 then
3077                         cf_gnat_libraries=yes
3078                 fi
3079                 rm -rf ./conftest* ./*~conftest*
3080                 ;;
3081         esac
3082         ;;
3083 esac
3084 AC_MSG_RESULT($cf_gnat_projects)
3085 fi # enable_gnat_projects
3086
3087 if test "$cf_gnat_projects" = yes
3088 then
3089         AC_MSG_CHECKING(if GNAT supports libraries)
3090         AC_MSG_RESULT($cf_gnat_libraries)
3091 fi
3092
3093 USE_OLD_MAKERULES=""
3094 USE_GNAT_PROJECTS="#"
3095 USE_GNAT_MAKE_GPR="#"
3096 USE_GNAT_GPRBUILD="#"
3097
3098 if test "$cf_gnat_projects" = yes
3099 then
3100         USE_OLD_MAKERULES="#"
3101         USE_GNAT_PROJECTS=""
3102         if test "$cf_cv_VERSION_GPRBUILD" != no
3103         then
3104                 USE_GNAT_GPRBUILD=""
3105         elif test "$cf_cv_VERSION_GNATMAKE" != no
3106         then
3107                 USE_GNAT_MAKE_GPR=""
3108         else
3109                 AC_MSG_WARN(use old makefile rules since tools are missing)
3110         fi
3111 fi
3112
3113 if test "$cf_gnat_libraries" = yes
3114 then
3115         USE_GNAT_LIBRARIES=""
3116 else
3117         USE_GNAT_LIBRARIES="#"
3118 fi
3119
3120 AC_SUBST(USE_OLD_MAKERULES)
3121 AC_SUBST(USE_GNAT_PROJECTS)
3122 AC_SUBST(USE_GNAT_LIBRARIES)
3123 AC_SUBST(USE_GNAT_MAKE_GPR)
3124 AC_SUBST(USE_GNAT_GPRBUILD)
3125 ])dnl
3126 dnl ---------------------------------------------------------------------------
3127 dnl CF_GNAT_SIGINT version: 2 updated: 2021/01/01 13:31:04
3128 dnl --------------
3129 dnl Check if gnat supports SIGINT, and presumably tasking.  For the latter, it
3130 dnl is noted that gnat may compile a tasking unit even for configurations which
3131 dnl fail at runtime.
3132 AC_DEFUN([CF_GNAT_SIGINT],[
3133 AC_CACHE_CHECK(if GNAT supports SIGINT,cf_cv_gnat_sigint,[
3134 CF_GNAT_TRY_LINK([with Ada.Interrupts.Names;
3135
3136 package ConfTest is
3137
3138    pragma Warnings (Off);  --  the next pragma exists since 3.11p
3139    pragma Unreserve_All_Interrupts;
3140    pragma Warnings (On);
3141
3142    protected Process is
3143       procedure Stop;
3144       function Continue return Boolean;
3145       pragma Attach_Handler (Stop, Ada.Interrupts.Names.SIGINT);
3146    private
3147       Done : Boolean := False;
3148    end Process;
3149
3150 end ConfTest;],
3151 [package body ConfTest is
3152    protected body Process is
3153       procedure Stop is
3154       begin
3155          Done := True;
3156       end Stop;
3157       function Continue return Boolean is
3158       begin
3159          return not Done;
3160       end Continue;
3161    end Process;
3162 end ConfTest;],
3163         [cf_cv_gnat_sigint=yes],
3164         [cf_cv_gnat_sigint=no])])
3165
3166 if test "$cf_cv_gnat_sigint" = yes ; then
3167         USE_GNAT_SIGINT=""
3168 else
3169         USE_GNAT_SIGINT="#"
3170 fi
3171 AC_SUBST(USE_GNAT_SIGINT)
3172 ])dnl
3173 dnl ---------------------------------------------------------------------------
3174 dnl CF_GNAT_TRY_LINK version: 4 updated: 2021/01/01 13:31:04
3175 dnl ----------------
3176 dnl Verify that a test program compiles/links with GNAT.
3177 dnl $cf_ada_make is set to the program that compiles/links
3178 dnl $ADAFLAGS may be set to the GNAT flags.
3179 dnl
3180 dnl $1 is the text of the spec
3181 dnl $2 is the text of the body
3182 dnl $3 is the shell command to execute if successful
3183 dnl $4 is the shell command to execute if not successful
3184 AC_DEFUN([CF_GNAT_TRY_LINK],
3185 [
3186 rm -rf ./conftest* ./*~conftest*
3187 cat >>conftest.ads <<CF_EOF
3188 $1
3189 CF_EOF
3190 cat >>conftest.adb <<CF_EOF
3191 $2
3192 CF_EOF
3193 if ( "$cf_ada_make" $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
3194 ifelse($3,,      :,[      $3])
3195 ifelse($4,,,[else
3196    $4])
3197 fi
3198 rm -rf ./conftest* ./*~conftest*
3199 ])dnl
3200 dnl ---------------------------------------------------------------------------
3201 dnl CF_GNAT_TRY_RUN version: 6 updated: 2021/01/01 13:31:04
3202 dnl ---------------
3203 dnl Verify that a test program compiles and runs with GNAT
3204 dnl $cf_ada_make is set to the program that compiles/links
3205 dnl $ADAFLAGS may be set to the GNAT flags.
3206 dnl
3207 dnl $1 is the text of the spec
3208 dnl $2 is the text of the body
3209 dnl $3 is the shell command to execute if successful
3210 dnl $4 is the shell command to execute if not successful
3211 AC_DEFUN([CF_GNAT_TRY_RUN],
3212 [
3213 rm -rf ./conftest* ./*~conftest*
3214 cat >>conftest.ads <<CF_EOF
3215 $1
3216 CF_EOF
3217 cat >>conftest.adb <<CF_EOF
3218 $2
3219 CF_EOF
3220 if ( "$cf_ada_make" $ADAFLAGS conftest 1>&AC_FD_CC 2>&1 ) ; then
3221    if ( ./conftest 1>&AC_FD_CC 2>&1 ) ; then
3222 ifelse($3,,      :,[      $3])
3223 ifelse($4,,,[   else
3224       $4])
3225    fi
3226 ifelse($4,,,[else
3227    $4])
3228 fi
3229 rm -rf ./conftest* ./*~conftest*
3230 ])dnl
3231 dnl ---------------------------------------------------------------------------
3232 dnl CF_GNAT_VERSION version: 22 updated: 2019/12/31 08:53:54
3233 dnl ---------------
3234 dnl $1 = cache variable to update
3235 dnl $2 = program name
3236 dnl Verify version of GNAT or related tool
3237 AC_DEFUN([CF_GNAT_VERSION],
3238 [
3239 AC_CACHE_CHECK(for ifelse($2,,gnat,$2) version, cf_cv_gnat_version,[
3240 cf_cv_gnat_version=`ifelse($2,,${cf_ada_make:-gnatmake},$2) --version 2>&1 | \
3241         grep '[[0-9]].[[0-9]][[0-9]]*' |\
3242         sed -e '2,$d' -e 's/[[^0-9 \.]]//g' -e 's/^[[ ]]*//' -e 's/ .*//'`
3243 ])
3244 test -z "$cf_cv_gnat_version" && cf_cv_gnat_version=no
3245 ifelse($1,,,[eval $1=$cf_cv_gnat_version; unset cf_cv_gnat_version])
3246 ])dnl
3247 dnl ---------------------------------------------------------------------------
3248 dnl CF_GNU_SOURCE version: 10 updated: 2018/12/10 20:09:41
3249 dnl -------------
3250 dnl Check if we must define _GNU_SOURCE to get a reasonable value for
3251 dnl _XOPEN_SOURCE, upon which many POSIX definitions depend.  This is a defect
3252 dnl (or misfeature) of glibc2, which breaks portability of many applications,
3253 dnl since it is interwoven with GNU extensions.
3254 dnl
3255 dnl Well, yes we could work around it...
3256 dnl
3257 dnl Parameters:
3258 dnl     $1 is the nominal value for _XOPEN_SOURCE
3259 AC_DEFUN([CF_GNU_SOURCE],
3260 [
3261 cf_gnu_xopen_source=ifelse($1,,500,$1)
3262
3263 AC_CACHE_CHECK(if this is the GNU C library,cf_cv_gnu_library,[
3264 AC_TRY_COMPILE([#include <sys/types.h>],[
3265         #if __GLIBC__ > 0 && __GLIBC_MINOR__ >= 0
3266                 return 0;
3267         #elif __NEWLIB__ > 0 && __NEWLIB_MINOR__ >= 0
3268                 return 0;
3269         #else
3270         #       error not GNU C library
3271         #endif],
3272         [cf_cv_gnu_library=yes],
3273         [cf_cv_gnu_library=no])
3274 ])
3275
3276 if test x$cf_cv_gnu_library = xyes; then
3277
3278         # With glibc 2.19 (13 years after this check was begun), _DEFAULT_SOURCE
3279         # was changed to help a little.  newlib incorporated the change about 4
3280         # years later.
3281         AC_CACHE_CHECK(if _DEFAULT_SOURCE can be used as a basis,cf_cv_gnu_library_219,[
3282                 cf_save="$CPPFLAGS"
3283                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3284                 AC_TRY_COMPILE([#include <sys/types.h>],[
3285                         #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 19) || (__GLIBC__ > 2)
3286                                 return 0;
3287                         #elif (__NEWLIB__ == 2 && __NEWLIB_MINOR__ >= 4) || (__GLIBC__ > 3)
3288                                 return 0;
3289                         #else
3290                         #       error GNU C library __GLIBC__.__GLIBC_MINOR__ is too old
3291                         #endif],
3292                         [cf_cv_gnu_library_219=yes],
3293                         [cf_cv_gnu_library_219=no])
3294                 CPPFLAGS="$cf_save"
3295         ])
3296
3297         if test "x$cf_cv_gnu_library_219" = xyes; then
3298                 cf_save="$CPPFLAGS"
3299                 AC_CACHE_CHECK(if _XOPEN_SOURCE=$cf_gnu_xopen_source works with _DEFAULT_SOURCE,cf_cv_gnu_dftsrc_219,[
3300                         CF_ADD_CFLAGS(-D_DEFAULT_SOURCE -D_XOPEN_SOURCE=$cf_gnu_xopen_source)
3301                         AC_TRY_COMPILE([
3302                                 #include <limits.h>
3303                                 #include <sys/types.h>
3304                                 ],[
3305                                 #if (_XOPEN_SOURCE >= $cf_gnu_xopen_source) && (MB_LEN_MAX > 1)
3306                                         return 0;
3307                                 #else
3308                                 #       error GNU C library is too old
3309                                 #endif],
3310                                 [cf_cv_gnu_dftsrc_219=yes],
3311                                 [cf_cv_gnu_dftsrc_219=no])
3312                         ])
3313                 test "x$cf_cv_gnu_dftsrc_219" = "xyes" || CPPFLAGS="$cf_save"
3314         else
3315                 cf_cv_gnu_dftsrc_219=maybe
3316         fi
3317
3318         if test "x$cf_cv_gnu_dftsrc_219" != xyes; then
3319
3320                 AC_CACHE_CHECK(if we must define _GNU_SOURCE,cf_cv_gnu_source,[
3321                 AC_TRY_COMPILE([#include <sys/types.h>],[
3322                         #ifndef _XOPEN_SOURCE
3323                         #error  expected _XOPEN_SOURCE to be defined
3324                         #endif],
3325                         [cf_cv_gnu_source=no],
3326                         [cf_save="$CPPFLAGS"
3327                          CF_ADD_CFLAGS(-D_GNU_SOURCE)
3328                          AC_TRY_COMPILE([#include <sys/types.h>],[
3329                                 #ifdef _XOPEN_SOURCE
3330                                 #error  expected _XOPEN_SOURCE to be undefined
3331                                 #endif],
3332                                 [cf_cv_gnu_source=no],
3333                                 [cf_cv_gnu_source=yes])
3334                         CPPFLAGS="$cf_save"
3335                         ])
3336                 ])
3337
3338                 if test "$cf_cv_gnu_source" = yes
3339                 then
3340                 AC_CACHE_CHECK(if we should also define _DEFAULT_SOURCE,cf_cv_default_source,[
3341                         CF_APPEND_TEXT(CPPFLAGS,-D_GNU_SOURCE)
3342                         AC_TRY_COMPILE([#include <sys/types.h>],[
3343                                 #ifdef _DEFAULT_SOURCE
3344                                 #error  expected _DEFAULT_SOURCE to be undefined
3345                                 #endif],
3346                                 [cf_cv_default_source=no],
3347                                 [cf_cv_default_source=yes])
3348                         ])
3349                         if test "$cf_cv_default_source" = yes
3350                         then
3351                                 CF_APPEND_TEXT(CPPFLAGS,-D_DEFAULT_SOURCE)
3352                         fi
3353                 fi
3354         fi
3355
3356 fi
3357 ])dnl
3358 dnl ---------------------------------------------------------------------------
3359 dnl CF_GPP_LIBRARY version: 13 updated: 2021/01/01 13:31:04
3360 dnl --------------
3361 dnl If we're trying to use g++, test if libg++ is installed (a rather common
3362 dnl problem :-).  If we have the compiler but no library, we'll be able to
3363 dnl configure, but won't be able to build the c++ demo program.
3364 AC_DEFUN([CF_GPP_LIBRARY],
3365 [
3366 cf_cxx_library=unknown
3367 case "$cf_cv_system_name" in
3368 (os2*)
3369         cf_gpp_libname=gpp
3370         ;;
3371 (*)
3372         cf_gpp_libname=g++
3373         ;;
3374 esac
3375 if test "$GXX" = yes; then
3376         AC_MSG_CHECKING([for lib$cf_gpp_libname])
3377         cf_save="$LIBS"
3378         CF_ADD_LIB($cf_gpp_libname)
3379         AC_TRY_LINK([
3380 #include <$cf_gpp_libname/builtin.h>
3381         ],
3382         [two_arg_error_handler_t foo2 = lib_error_handler],
3383         [cf_cxx_library=yes
3384          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3385          if test "$cf_gpp_libname" = cpp ; then
3386             AC_DEFINE(HAVE_GPP_BUILTIN_H,1,[Define to 1 if we have gpp builtin.h])
3387          else
3388             AC_DEFINE(HAVE_GXX_BUILTIN_H,1,[Define to 1 if we have g++ builtin.h])
3389          fi],
3390         [AC_TRY_LINK([
3391 #include <builtin.h>
3392         ],
3393         [two_arg_error_handler_t foo2 = lib_error_handler],
3394         [cf_cxx_library=yes
3395          CF_ADD_LIB($cf_gpp_libname,CXXLIBS)
3396          AC_DEFINE(HAVE_BUILTIN_H,1,[Define to 1 if we have builtin.h])],
3397         [cf_cxx_library=no])])
3398         LIBS="$cf_save"
3399         AC_MSG_RESULT($cf_cxx_library)
3400 fi
3401 ])dnl
3402 dnl ---------------------------------------------------------------------------
3403 dnl CF_GXX_VERSION version: 8 updated: 2017/02/11 14:48:57
3404 dnl --------------
3405 dnl Check for version of g++
3406 AC_DEFUN([CF_GXX_VERSION],[
3407 AC_REQUIRE([AC_PROG_CPP])
3408 GXX_VERSION=none
3409 if test "$GXX" = yes; then
3410         AC_MSG_CHECKING(version of ${CXX:-g++})
3411         GXX_VERSION="`${CXX:-g++} --version| sed -e '2,$d' -e 's/^.*(GCC) //' -e 's/^[[^0-9.]]*//' -e 's/[[^0-9.]].*//'`"
3412         if test -z "$GXX_VERSION"
3413         then
3414                 GXX_VERSION=unknown
3415                 GXX=no
3416         fi
3417         AC_MSG_RESULT($GXX_VERSION)
3418 fi
3419 ])dnl
3420 dnl ---------------------------------------------------------------------------
3421 dnl CF_GXX_WARNINGS version: 11 updated: 2021/01/08 16:50:55
3422 dnl ---------------
3423 dnl Check if the compiler supports useful warning options.
3424 dnl
3425 dnl Most of gcc's options apply to g++, except:
3426 dnl     -Wbad-function-cast
3427 dnl     -Wmissing-declarations
3428 dnl     -Wnested-externs
3429 dnl
3430 dnl Omit a few (for now):
3431 dnl     -Winline
3432 dnl
3433 dnl Parameter:
3434 dnl     $1 is an optional list of g++ warning flags that a particular
3435 dnl             application might want to use, e.g., "no-unused" for
3436 dnl             -Wno-unused
3437 dnl Special:
3438 dnl     If $with_ext_const is "yes", add a check for -Wwrite-strings
3439 dnl
3440 AC_DEFUN([CF_GXX_WARNINGS],
3441 [
3442
3443 CF_INTEL_COMPILER(GXX,INTEL_CPLUSPLUS,CXXFLAGS)
3444 CF_CLANG_COMPILER(GXX,CLANG_CPLUSPLUS,CXXFLAGS)
3445
3446 AC_REQUIRE([CF_GXX_VERSION])
3447
3448 AC_LANG_SAVE
3449 AC_LANG_CPLUSPLUS
3450
3451 cat > conftest.$ac_ext <<EOF
3452 #line __oline__ "configure"
3453 int main(int argc, char *argv[[]]) { return (argv[[argc-1]] == 0) ; }
3454 EOF
3455
3456 if test "$INTEL_CPLUSPLUS" = yes
3457 then
3458 # The "-wdXXX" options suppress warnings:
3459 # remark #1419: external declaration in primary source file
3460 # remark #1682: implicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3461 # remark #1683: explicit conversion of a 64-bit integral type to a smaller integral type (potential portability problem)
3462 # remark #1684: conversion from pointer to same-sized integral type (potential portability problem)
3463 # remark #193: zero used for undefined preprocessing identifier
3464 # remark #593: variable "curs_sb_left_arrow" was set but never used
3465 # remark #810: conversion from "int" to "Dimension={unsigned short}" may lose significant bits
3466 # remark #869: parameter "tw" was never referenced
3467 # remark #981: operands are evaluated in unspecified order
3468 # warning #269: invalid format string conversion
3469
3470         AC_CHECKING([for $CC warning options])
3471         cf_save_CXXFLAGS="$CXXFLAGS"
3472         EXTRA_CXXFLAGS="-Wall"
3473         for cf_opt in \
3474                 wd1419 \
3475                 wd1682 \
3476                 wd1683 \
3477                 wd1684 \
3478                 wd193 \
3479                 wd279 \
3480                 wd593 \
3481                 wd810 \
3482                 wd869 \
3483                 wd981
3484         do
3485                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -$cf_opt"
3486                 if AC_TRY_EVAL(ac_compile); then
3487                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3488                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3489                 fi
3490         done
3491         CXXFLAGS="$cf_save_CXXFLAGS"
3492
3493 elif test "$GXX" = yes
3494 then
3495         AC_CHECKING([for $CXX warning options])
3496         cf_save_CXXFLAGS="$CXXFLAGS"
3497         EXTRA_CXXFLAGS="-W -Wall"
3498         cf_gxx_extra_warnings=""
3499         test "$with_ext_const" = yes && cf_gxx_extra_warnings="Wwrite-strings"
3500         case "$GXX_VERSION" in
3501         ([[1-2]].*)
3502                 ;;
3503         (*)
3504                 cf_gxx_extra_warnings="$cf_gxx_extra_warnings Weffc++"
3505                 ;;
3506         esac
3507         for cf_opt in \
3508                 Wabi \
3509                 fabi-version=0 \
3510                 Wextra \
3511                 Wignored-qualifiers \
3512                 Wlogical-op \
3513                 Woverloaded-virtual \
3514                 Wsign-promo \
3515                 Wsynth \
3516                 Wold-style-cast \
3517                 Wcast-align \
3518                 Wcast-qual \
3519                 Wpointer-arith \
3520                 Wshadow \
3521                 Wundef $cf_gxx_extra_warnings $1
3522         do
3523                 CXXFLAGS="$cf_save_CXXFLAGS $EXTRA_CXXFLAGS -Werror -$cf_opt"
3524                 if AC_TRY_EVAL(ac_compile); then
3525                         test -n "$verbose" && AC_MSG_RESULT(... -$cf_opt)
3526                         EXTRA_CXXFLAGS="$EXTRA_CXXFLAGS -$cf_opt"
3527                 else
3528                         test -n "$verbose" && AC_MSG_RESULT(... no -$cf_opt)
3529                 fi
3530         done
3531         CXXFLAGS="$cf_save_CXXFLAGS"
3532 fi
3533
3534 rm -rf ./conftest*
3535 AC_LANG_RESTORE
3536 AC_SUBST(EXTRA_CXXFLAGS)
3537 ])dnl
3538 dnl ---------------------------------------------------------------------------
3539 dnl CF_HASHED_DB version: 7 updated: 2015/04/18 08:56:57
3540 dnl ------------
3541 dnl Look for an instance of the Berkeley hashed database.
3542 dnl
3543 dnl $1 = optional parameter, to specify install-prefix for the database.
3544 AC_DEFUN([CF_HASHED_DB],
3545 [
3546 ifelse([$1],,,[
3547 case $1 in
3548 (yes|*able*)
3549         ;;
3550 (*)
3551         if test -d "$1" ; then
3552                 CF_ADD_INCDIR($1/include)
3553                 CF_ADD_LIBDIR($1/lib)
3554         else
3555                 case "$1" in
3556                 (./*|../*|/*)
3557                         AC_MSG_WARN(no such directory $1)
3558                         ;;
3559                 (*)
3560                         CF_FIND_SUB_INCDIR($1)
3561                         CF_FIND_SUB_LIBDIR($1)
3562                         ;;
3563                 esac
3564         fi
3565 esac
3566 ])
3567 AC_CHECK_HEADER(db.h,[
3568 CF_HASHED_DB_VERSION
3569 if test "$cf_cv_hashed_db_version" = unknown ; then
3570         AC_MSG_ERROR(Cannot determine version of db)
3571 else
3572         CF_HASHED_DB_LIBS
3573         if test "$cf_cv_hashed_db_libs" = unknown ; then
3574                 AC_MSG_ERROR(Cannot determine library for db)
3575         elif test "$cf_cv_hashed_db_libs" != default ; then
3576                 CF_ADD_LIB($cf_cv_hashed_db_libs)
3577         fi
3578 fi
3579 ],[
3580         AC_MSG_ERROR(Cannot find db.h)
3581 ])
3582 ])dnl
3583 dnl ---------------------------------------------------------------------------
3584 dnl CF_HASHED_DB_LIBS version: 10 updated: 2021/01/02 17:09:14
3585 dnl -----------------
3586 dnl Given that we have the header and version for hashed database, find the
3587 dnl library information.
3588 AC_DEFUN([CF_HASHED_DB_LIBS],
3589 [
3590 AC_CACHE_CHECK(for db libraries, cf_cv_hashed_db_libs,[
3591 cf_cv_hashed_db_libs=unknown
3592 for cf_db_libs in "" db$cf_cv_hashed_db_version db-$cf_cv_hashed_db_version db ''
3593 do
3594         cf_save_libs="$LIBS"
3595         if test -n "$cf_db_libs"; then
3596                 CF_ADD_LIB($cf_db_libs)
3597         fi
3598         CF_MSG_LOG(checking for library $cf_db_libs)
3599         AC_TRY_LINK([
3600 $ac_includes_default
3601 #include <db.h>
3602 ],[
3603         char *path = "/tmp/foo";
3604 #ifdef DB_VERSION_MAJOR
3605 #if DB_VERSION_MAJOR >= 4
3606         DB *result = 0;
3607         db_create(&result, NULL, 0);
3608         result->open(result,
3609                 NULL,
3610                 path,
3611                 path,
3612                 DB_HASH,
3613                 DB_CREATE,
3614                 0644);
3615 #elif DB_VERSION_MAJOR >= 3
3616         DB *result = 0;
3617         db_create(&result, NULL, 0);
3618         result->open(result,
3619                 path,
3620                 path,
3621                 DB_HASH,
3622                 DB_CREATE,
3623                 0644);
3624 #elif DB_VERSION_MAJOR >= 2
3625         DB *result = 0;
3626         db_open(path,
3627                 DB_HASH,
3628                 DB_CREATE,
3629                 0644,
3630                 (DB_ENV *) 0,
3631                 (DB_INFO *) 0,
3632                 &result);
3633 #endif /* DB_VERSION_MAJOR */
3634 #else
3635         DB *result = dbopen(path,
3636                      2,
3637                      0644,
3638                      DB_HASH,
3639                      0);
3640 #endif
3641         ${cf_cv_main_return:-return}(result != 0)
3642 ],[
3643         if test -n "$cf_db_libs" ; then
3644                 cf_cv_hashed_db_libs=$cf_db_libs
3645         else
3646                 cf_cv_hashed_db_libs=default
3647         fi
3648         LIBS="$cf_save_libs"
3649         break
3650 ])
3651         LIBS="$cf_save_libs"
3652 done
3653 ])
3654 ])dnl
3655 dnl ---------------------------------------------------------------------------
3656 dnl CF_HASHED_DB_VERSION version: 4 updated: 2014/04/12 16:47:01
3657 dnl --------------------
3658 dnl Given that we have the header file for hashed database, find the version
3659 dnl information.
3660 AC_DEFUN([CF_HASHED_DB_VERSION],
3661 [
3662 AC_CACHE_CHECK(for version of db, cf_cv_hashed_db_version,[
3663 cf_cv_hashed_db_version=unknown
3664
3665 for cf_db_version in 1 2 3 4 5 6
3666 do
3667         CF_MSG_LOG(checking for db version $cf_db_version)
3668         AC_TRY_COMPILE([
3669 $ac_includes_default
3670 #include <db.h>
3671
3672 #ifdef DB_VERSION_MAJOR
3673         /* db2 (DB_VERSION_MAJOR=2) has also DB_VERSION_MINOR, tested with 7 */
3674 #if $cf_db_version == DB_VERSION_MAJOR
3675         /* ok */
3676 #else
3677         make an error
3678 #endif
3679 #else
3680 #if $cf_db_version == 1
3681         /* ok: assuming this is DB 1.8.5 */
3682 #else
3683         make an error
3684 #endif
3685 #endif
3686 ],[DBT *foo = 0],[
3687         cf_cv_hashed_db_version=$cf_db_version
3688         break
3689         ])
3690 done
3691 ])
3692 ])dnl
3693 dnl ---------------------------------------------------------------------------
3694 dnl CF_HEADER_PATH version: 15 updated: 2021/01/01 13:31:04
3695 dnl --------------
3696 dnl Construct a search-list of directories for a nonstandard header-file
3697 dnl
3698 dnl Parameters
3699 dnl     $1 = the variable to return as result
3700 dnl     $2 = the package name
3701 AC_DEFUN([CF_HEADER_PATH],
3702 [
3703 $1=
3704
3705 # collect the current set of include-directories from compiler flags
3706 cf_header_path_list=""
3707 if test -n "${CFLAGS}${CPPFLAGS}" ; then
3708         for cf_header_path in $CPPFLAGS $CFLAGS
3709         do
3710                 case "$cf_header_path" in
3711                 (-I*)
3712                         cf_header_path=`echo ".$cf_header_path" |sed -e 's/^...//' -e 's,/include$,,'`
3713                         CF_ADD_SUBDIR_PATH($1,$2,include,$cf_header_path,NONE)
3714                         cf_header_path_list="$cf_header_path_list [$]$1"
3715                         ;;
3716                 esac
3717         done
3718 fi
3719
3720 # add the variations for the package we are looking for
3721 CF_SUBDIR_PATH($1,$2,include)
3722
3723 test "$includedir" != NONE && \
3724 test "$includedir" != "/usr/include" && \
3725 test -d "$includedir" && {
3726         test -d "$includedir" &&    $1="[$]$1 $includedir"
3727         test -d "$includedir/$2" && $1="[$]$1 $includedir/$2"
3728 }
3729
3730 test "$oldincludedir" != NONE && \
3731 test "$oldincludedir" != "/usr/include" && \
3732 test -d "$oldincludedir" && {
3733         test -d "$oldincludedir"    && $1="[$]$1 $oldincludedir"
3734         test -d "$oldincludedir/$2" && $1="[$]$1 $oldincludedir/$2"
3735 }
3736
3737 $1="[$]$1 $cf_header_path_list"
3738 ])dnl
3739 dnl ---------------------------------------------------------------------------
3740 dnl CF_HELP_MESSAGE version: 4 updated: 2019/12/31 08:53:54
3741 dnl ---------------
3742 dnl Insert text into the help-message, for readability, from AC_ARG_WITH.
3743 AC_DEFUN([CF_HELP_MESSAGE],
3744 [CF_ACVERSION_CHECK(2.53,[],[
3745 AC_DIVERT_HELP($1)])dnl
3746 ])dnl
3747 dnl ---------------------------------------------------------------------------
3748 dnl CF_INCLUDE_DIRS version: 10 updated: 2014/09/19 20:58:42
3749 dnl ---------------
3750 dnl Construct the list of include-options according to whether we're building
3751 dnl in the source directory or using '--srcdir=DIR' option.
3752 AC_DEFUN([CF_INCLUDE_DIRS],
3753 [
3754 if test "$srcdir" != "."; then
3755         CPPFLAGS="-I\${srcdir}/../include $CPPFLAGS"
3756 fi
3757 CPPFLAGS="-I../include $CPPFLAGS"
3758 if test "$srcdir" != "."; then
3759         CPPFLAGS="-I\${srcdir} $CPPFLAGS"
3760 fi
3761 CPPFLAGS="-I. $CPPFLAGS"
3762 AC_SUBST(CPPFLAGS)
3763 ])dnl
3764 dnl ---------------------------------------------------------------------------
3765 dnl CF_INSTALL_OPTS version: 2 updated: 2018/08/18 12:19:21
3766 dnl ---------------
3767 dnl prompt for/fill-in useful install-program options
3768 AC_DEFUN([CF_INSTALL_OPTS],
3769 [
3770 CF_INSTALL_OPT_S
3771 CF_INSTALL_OPT_P
3772 CF_INSTALL_OPT_O
3773 ])dnl
3774 dnl ---------------------------------------------------------------------------
3775 dnl CF_INSTALL_OPT_O version: 3 updated: 2020/12/31 20:19:42
3776 dnl ----------------
3777 dnl Almost all "install" programs default to the current user's ownership.
3778 dnl Almost - MINIX is an exception.
3779 AC_DEFUN([CF_INSTALL_OPT_O],
3780 [
3781 AC_MSG_CHECKING(if install needs to be told about ownership)
3782 case `$ac_config_guess` in
3783 (*minix)
3784         with_install_o=yes
3785         ;;
3786 (*)
3787         with_install_o=no
3788         ;;
3789 esac
3790
3791 AC_MSG_RESULT($with_install_o)
3792 if test "x$with_install_o" = xyes
3793 then
3794         INSTALL_OPT_O="`id root|sed -e 's/uid=[[0-9]]*(/ -o /' -e 's/gid=[[0-9]]*(/ -g /' -e 's/ [[^=[:space:]]][[^=[:space:]]]*=.*/ /' -e 's/)//g'`"
3795 else
3796         INSTALL_OPT_O=
3797 fi
3798
3799 AC_SUBST(INSTALL_OPT_O)
3800 ])dnl
3801 dnl ---------------------------------------------------------------------------
3802 dnl CF_INSTALL_OPT_P version: 3 updated: 2021/01/01 13:31:04
3803 dnl ----------------
3804 dnl Some install-programs accept a "-p" option to preserve file modification
3805 dnl timestamps.  That can be useful as an install option, as well as a way to
3806 dnl avoid the need for ranlib after copying a static archive.
3807 AC_DEFUN([CF_INSTALL_OPT_P],
3808 [
3809 : "${INSTALL:=install}"
3810 AC_CACHE_CHECK(if install accepts -p option, cf_cv_install_p,[
3811         rm -rf ./conftest*
3812         date >conftest.in
3813         mkdir conftest.out
3814         sleep 3
3815         if $INSTALL -p conftest.in conftest.out 2>/dev/null
3816         then
3817                 if test -f conftest.out/conftest.in
3818                 then
3819                         test conftest.in -nt conftest.out/conftest.in 2>conftest.err && \
3820                         test conftest.out/conftest.in -nt conftest.in 2>conftest.err
3821                         if test -s conftest.err
3822                         then
3823                                 cf_cv_install_p=no
3824                         else
3825                                 cf_cv_install_p=yes
3826                         fi
3827                 else
3828                         cf_cv_install_p=no
3829                 fi
3830         else
3831                 cf_cv_install_p=no
3832         fi
3833         rm -rf ./conftest*
3834 ])
3835 ])dnl
3836 dnl ---------------------------------------------------------------------------
3837 dnl CF_INSTALL_OPT_S version: 3 updated: 2021/01/05 19:23:48
3838 dnl ----------------
3839 dnl By default, we should strip executables which are installed, but leave the
3840 dnl ability to suppress that for unit-testing.
3841 AC_DEFUN([CF_INSTALL_OPT_S],
3842 [
3843 AC_MSG_CHECKING(if you want to install stripped executables)
3844 CF_ARG_DISABLE(stripping,
3845         [  --disable-stripping     do not strip (debug info) installed executables],
3846         [enable_stripping=no],
3847         [enable_stripping=yes])
3848 AC_MSG_RESULT($enable_stripping)
3849
3850 if test "$enable_stripping" = yes
3851 then
3852         INSTALL_OPT_S="-s"
3853 else
3854         INSTALL_OPT_S=
3855 fi
3856 AC_SUBST(INSTALL_OPT_S)
3857 ])dnl
3858 dnl ---------------------------------------------------------------------------
3859 dnl CF_INTEL_COMPILER version: 8 updated: 2021/01/01 16:53:59
3860 dnl -----------------
3861 dnl Check if the given compiler is really the Intel compiler for Linux.  It
3862 dnl tries to imitate gcc, but does not return an error when it finds a mismatch
3863 dnl between prototypes, e.g., as exercised by CF_MISSING_CHECK.
3864 dnl
3865 dnl This macro should be run "soon" after AC_PROG_CC or AC_PROG_CPLUSPLUS, to
3866 dnl ensure that it is not mistaken for gcc/g++.  It is normally invoked from
3867 dnl the wrappers for gcc and g++ warnings.
3868 dnl
3869 dnl $1 = GCC (default) or GXX
3870 dnl $2 = INTEL_COMPILER (default) or INTEL_CPLUSPLUS
3871 dnl $3 = CFLAGS (default) or CXXFLAGS
3872 AC_DEFUN([CF_INTEL_COMPILER],[
3873 AC_REQUIRE([AC_CANONICAL_HOST])
3874 ifelse([$2],,INTEL_COMPILER,[$2])=no
3875
3876 if test "$ifelse([$1],,[$1],GCC)" = yes ; then
3877         case "$host_os" in
3878         (linux*|gnu*)
3879                 AC_MSG_CHECKING(if this is really Intel ifelse([$1],GXX,C++,C) compiler)
3880                 cf_save_CFLAGS="$ifelse([$3],,CFLAGS,[$3])"
3881                 ifelse([$3],,CFLAGS,[$3])="$ifelse([$3],,CFLAGS,[$3]) -no-gcc"
3882                 AC_TRY_COMPILE([],[
3883 #ifdef __INTEL_COMPILER
3884 #else
3885 make an error
3886 #endif
3887 ],[ifelse([$2],,INTEL_COMPILER,[$2])=yes
3888 cf_save_CFLAGS="$cf_save_CFLAGS -we147"
3889 ],[])
3890                 ifelse([$3],,CFLAGS,[$3])="$cf_save_CFLAGS"
3891                 AC_MSG_RESULT($ifelse([$2],,INTEL_COMPILER,[$2]))
3892                 ;;
3893         esac
3894 fi
3895 ])dnl
3896 dnl ---------------------------------------------------------------------------
3897 dnl CF_ISASCII version: 4 updated: 2012/10/06 17:56:13
3898 dnl ----------
3899 dnl Check if we have either a function or macro for 'isascii()'.
3900 AC_DEFUN([CF_ISASCII],
3901 [
3902 AC_MSG_CHECKING(for isascii)
3903 AC_CACHE_VAL(cf_cv_have_isascii,[
3904         AC_TRY_LINK([#include <ctype.h>],[int x = isascii(' ')],
3905         [cf_cv_have_isascii=yes],
3906         [cf_cv_have_isascii=no])
3907 ])dnl
3908 AC_MSG_RESULT($cf_cv_have_isascii)
3909 test "$cf_cv_have_isascii" = yes && AC_DEFINE(HAVE_ISASCII,1,[Define to 1 if we have isascii()])
3910 ])dnl
3911 dnl ---------------------------------------------------------------------------
3912 dnl CF_LARGEFILE version: 12 updated: 2020/03/19 20:23:48
3913 dnl ------------
3914 dnl Add checks for large file support.
3915 AC_DEFUN([CF_LARGEFILE],[
3916 ifdef([AC_FUNC_FSEEKO],[
3917         AC_SYS_LARGEFILE
3918         if test "$enable_largefile" != no ; then
3919         AC_FUNC_FSEEKO
3920
3921         # Normally we would collect these definitions in the config.h,
3922         # but (like _XOPEN_SOURCE), some environments rely on having these
3923         # defined before any of the system headers are included.  Another
3924         # case comes up with C++, e.g., on AIX the compiler compiles the
3925         # header files by themselves before looking at the body files it is
3926         # told to compile.  For ncurses, those header files do not include
3927         # the config.h
3928         if test "$ac_cv_sys_large_files" != no
3929         then
3930                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGE_FILES)
3931         fi
3932         if test "$ac_cv_sys_largefile_source" != no
3933         then
3934                 CF_APPEND_TEXT(CPPFLAGS,-D_LARGEFILE_SOURCE)
3935         fi
3936         if test "$ac_cv_sys_file_offset_bits" != no
3937         then
3938                 CF_APPEND_TEXT(CPPFLAGS,-D_FILE_OFFSET_BITS=$ac_cv_sys_file_offset_bits)
3939         fi
3940
3941         AC_CACHE_CHECK(whether to use struct dirent64, cf_cv_struct_dirent64,[
3942                 AC_TRY_COMPILE([
3943 #pragma GCC diagnostic error "-Wincompatible-pointer-types"
3944 #include <sys/types.h>
3945 #include <dirent.h>
3946                 ],[
3947                 /* if transitional largefile support is setup, this is true */
3948                 extern struct dirent64 * readdir(DIR *);
3949                 struct dirent64 *x = readdir((DIR *)0);
3950                 struct dirent *y = readdir((DIR *)0);
3951                 int z = x - y;
3952                 (void)z;
3953                 ],
3954                 [cf_cv_struct_dirent64=yes],
3955                 [cf_cv_struct_dirent64=no])
3956         ])
3957         test "$cf_cv_struct_dirent64" = yes && AC_DEFINE(HAVE_STRUCT_DIRENT64,1,[Define to 1 if we have struct dirent64])
3958         fi
3959 ])
3960 ])
3961 dnl ---------------------------------------------------------------------------
3962 dnl CF_LDFLAGS_STATIC version: 14 updated: 2021/01/02 17:09:14
3963 dnl -----------------
3964 dnl Check for compiler/linker flags used to temporarily force usage of static
3965 dnl libraries.  This depends on the compiler and platform.  Use this to help
3966 dnl ensure that the linker picks up a given library based on its position in
3967 dnl the list of linker options and libraries.
3968 AC_DEFUN([CF_LDFLAGS_STATIC],[
3969
3970 if test "$GCC" = yes ; then
3971         case "$cf_cv_system_name" in
3972         (OS/2*|os2*|aix[[4]]*|solaris2.1[[0-9]]|darwin*)
3973                 LDFLAGS_STATIC=
3974                 LDFLAGS_SHARED=
3975                 ;;
3976         (*)     # normally, except when broken
3977                 LDFLAGS_STATIC=-static
3978                 LDFLAGS_SHARED=-dynamic
3979                 ;;
3980         esac
3981 else
3982         case "$cf_cv_system_name" in
3983         (aix[[4-7]]*)   # from ld manpage
3984                 LDFLAGS_STATIC=-bstatic
3985                 LDFLAGS_SHARED=-bdynamic
3986                 ;;
3987         (hpux*)         # from ld manpage for hpux10.20, hpux11.11
3988                 # We could also use just "archive" and "shared".
3989                 LDFLAGS_STATIC=-Wl,-a,archive_shared
3990                 LDFLAGS_SHARED=-Wl,-a,shared_archive
3991                 ;;
3992         (irix*)         # from ld manpage IRIX64
3993                 LDFLAGS_STATIC=-Bstatic
3994                 LDFLAGS_SHARED=-Bdynamic
3995                 ;;
3996         (osf[[45]]*)    # from ld manpage osf4.0d, osf5.1
3997                 # alternative "-oldstyle_liblookup" (not in cc manpage)
3998                 LDFLAGS_STATIC=-noso
3999                 LDFLAGS_SHARED=-so_archive
4000                 ;;
4001         (solaris2*)
4002                 LDFLAGS_STATIC=-Bstatic
4003                 LDFLAGS_SHARED=-Bdynamic
4004                 ;;
4005         esac
4006 fi
4007
4008 if test -n "$LDFLAGS_STATIC" && test -n "$LDFLAGS_SHARED"
4009 then
4010         AC_MSG_CHECKING(if linker supports switching between static/dynamic)
4011
4012         rm -f libconftest.a
4013         cat >conftest.$ac_ext <<EOF
4014 #line __oline__ "configure"
4015 #include <stdio.h>
4016 int cf_ldflags_static(FILE *fp) { return fflush(fp); }
4017 EOF
4018         if AC_TRY_EVAL(ac_compile) ; then
4019                 ( $AR $ARFLAGS libconftest.a conftest.o ) 2>&AC_FD_CC 1>/dev/null
4020                 ( eval $RANLIB libconftest.a ) 2>&AC_FD_CC >/dev/null
4021         fi
4022         rm -f conftest.*
4023
4024         cf_save_LIBS="$LIBS"
4025
4026         LIBS="$LDFLAGS_STATIC -L`pwd` -lconftest $LDFLAGS_DYNAMIC $LIBS"
4027         AC_TRY_LINK([
4028 #line __oline__ "configure"
4029 #include <stdio.h>
4030 int cf_ldflags_static(FILE *fp);
4031 ],[
4032         return cf_ldflags_static(stdin);
4033 ],[
4034         # some linkers simply ignore the -dynamic
4035         case x`file "conftest$ac_exeext" 2>/dev/null` in
4036         (*static*)
4037                 cf_ldflags_static=no
4038                 ;;
4039         (*)
4040                 cf_ldflags_static=yes
4041                 ;;
4042         esac
4043 ],[cf_ldflags_static=no])
4044
4045         rm -f libconftest.*
4046         LIBS="$cf_save_LIBS"
4047
4048         AC_MSG_RESULT($cf_ldflags_static)
4049
4050         if test "$cf_ldflags_static" != yes
4051         then
4052                 LDFLAGS_STATIC=
4053                 LDFLAGS_SHARED=
4054         fi
4055 else
4056         LDFLAGS_STATIC=
4057         LDFLAGS_SHARED=
4058 fi
4059
4060 AC_SUBST(LDFLAGS_STATIC)
4061 AC_SUBST(LDFLAGS_SHARED)
4062 ])
4063 dnl ---------------------------------------------------------------------------
4064 dnl CF_LD_RPATH_OPT version: 9 updated: 2021/01/01 13:31:04
4065 dnl ---------------
4066 dnl For the given system and compiler, find the compiler flags to pass to the
4067 dnl loader to use the "rpath" feature.
4068 AC_DEFUN([CF_LD_RPATH_OPT],
4069 [
4070 AC_REQUIRE([CF_CHECK_CACHE])
4071
4072 LD_RPATH_OPT=
4073 if test "x$cf_cv_enable_rpath" != xno
4074 then
4075         AC_MSG_CHECKING(for an rpath option)
4076         case "$cf_cv_system_name" in
4077         (irix*)
4078                 if test "$GCC" = yes; then
4079                         LD_RPATH_OPT="-Wl,-rpath,"
4080                 else
4081                         LD_RPATH_OPT="-rpath "
4082                 fi
4083                 ;;
4084         (linux*|gnu*|k*bsd*-gnu|freebsd*)
4085                 LD_RPATH_OPT="-Wl,-rpath,"
4086                 ;;
4087         (openbsd[[2-9]].*|mirbsd*)
4088                 LD_RPATH_OPT="-Wl,-rpath,"
4089                 ;;
4090         (dragonfly*)
4091                 LD_RPATH_OPT="-rpath "
4092                 ;;
4093         (netbsd*)
4094                 LD_RPATH_OPT="-Wl,-rpath,"
4095                 ;;
4096         (osf*|mls+*)
4097                 LD_RPATH_OPT="-rpath "
4098                 ;;
4099         (solaris2*)
4100                 LD_RPATH_OPT="-R"
4101                 ;;
4102         (*)
4103                 ;;
4104         esac
4105         AC_MSG_RESULT($LD_RPATH_OPT)
4106
4107         case "x$LD_RPATH_OPT" in
4108         (x-R*)
4109                 AC_MSG_CHECKING(if we need a space after rpath option)
4110                 cf_save_LIBS="$LIBS"
4111                 CF_ADD_LIBS(${LD_RPATH_OPT}$libdir)
4112                 AC_TRY_LINK(, , cf_rpath_space=no, cf_rpath_space=yes)
4113                 LIBS="$cf_save_LIBS"
4114                 AC_MSG_RESULT($cf_rpath_space)
4115                 test "$cf_rpath_space" = yes && LD_RPATH_OPT="$LD_RPATH_OPT "
4116                 ;;
4117         esac
4118 fi
4119 ])dnl
4120 dnl ---------------------------------------------------------------------------
4121 dnl CF_LD_SEARCHPATH version: 3 updated: 2021/03/05 19:13:35
4122 dnl ----------------
4123 dnl Try to obtain the linker's search-path, for use in scripts.
4124 dnl
4125 dnl Ignore LD_LIBRARY_PATH, etc.
4126 AC_DEFUN([CF_LD_SEARCHPATH],[
4127 AC_CACHE_CHECK(for linker search path,cf_cv_ld_searchpath,[
4128
4129 if test "$cross_compiling" != yes ; then
4130
4131 # GNU binutils' ld does not involve permissions which may stop ldconfig.
4132 cf_pathlist=`ld --verbose 2>/dev/null | grep SEARCH_DIR | sed -e 's,SEARCH_DIR[[("=]][[("=]]*,,g' -e 's/"[[)]];//gp' | sort -u`
4133
4134 # The -NX options tell newer versions of Linux ldconfig to not attempt to
4135 # update the cache, which makes it run faster.
4136 test -z "$cf_pathlist" && \
4137         cf_pathlist=`(ldconfig -NX -v) 2>/dev/null | sed -e '/^[[       ]]/d' -e 's/:$//' | sort -u`
4138
4139 test -z "$cf_pathlist" &&
4140         cf_pathlist=`(ldconfig -v) 2>/dev/null | sed -n -e '/^[[        ]]/d' -e 's/:$//p' | sort -u`
4141
4142 # This works with OpenBSD 6.5, which lists only filenames
4143 test -z "$cf_pathlist" &&
4144         cf_pathlist=`(ldconfig -v) 2>/dev/null | sed -n -e 's,^Adding \(.*\)/.*[$],\1,p' | sort -u`
4145
4146 if test -z "$cf_pathlist"
4147 then
4148         # dyld default path with MacOS
4149         if test -f /usr/bin/otool && test "x`uname -s`" = xDarwin
4150         then
4151                 # do this to bypass check
4152                 cf_cv_ld_searchpath='$HOME/lib'
4153                 cf_pathlist="/usr/local/lib /lib /usr/lib"
4154         fi
4155 fi
4156
4157 if test -z "$cf_pathlist"
4158 then
4159         # Solaris is "SunOS"
4160         if test -f /usr/bin/isainfo && test "x`uname -s`" = xSunOS
4161         then
4162                 case x`(isainfo -b)` in
4163                 (x64)
4164                         cf_pathlist="$cf_pathlist /lib/64 /usr/lib/64"
4165                         ;;
4166                 (x32)
4167                         test -d /usr/ccs/lib && cf_pathlist="$cf_pathlist /usr/ccs/lib"
4168                         cf_pathlist="$cf_pathlist /lib /usr/lib"
4169                         ;;
4170                 (*)
4171                         AC_MSG_WARN(problem with Solaris architecture)
4172                         ;;
4173                 esac
4174         fi
4175 fi
4176
4177 if test -z "$cf_pathlist"
4178 then
4179         # HP-UX
4180         if test x"`uname -s`" = xHP-UX
4181         then
4182                 case x`getconf LONG_BIT` in
4183                 (x64)
4184                         cf_pathlist="/usr/lib/hpux64"
4185                         ;;
4186                 (x*)
4187                         cf_pathlist="/usr/lib/hpux32"
4188                         ;;
4189                 esac
4190         fi
4191 fi
4192
4193 fi
4194
4195 # If nothing else, assume it is conventional
4196 test -z "$cf_pathlist" && cf_pathlist="/usr/lib /lib"
4197
4198 # Finally, check that this is only directories
4199 for cf_path in [$]0 $cf_pathlist
4200 do
4201         if test -d "$cf_path"; then
4202                 test -n "$cf_cv_ld_searchpath" && cf_cv_ld_searchpath="${cf_cv_ld_searchpath} "
4203                 cf_cv_ld_searchpath="${cf_cv_ld_searchpath}${cf_path}"
4204         fi
4205 done
4206
4207 # Ensure that it is nonempty
4208 test -z "$cf_cv_ld_searchpath" && cf_cv_ld_searchpath=/usr/lib
4209 ])
4210
4211 LD_SEARCHPATH=`echo "$cf_cv_ld_searchpath"|sed -e 's/ /|/g'`
4212 AC_SUBST(LD_SEARCHPATH)
4213 ])dnl
4214 dnl ---------------------------------------------------------------------------
4215 dnl CF_LIBRARY_PATH version: 11 updated: 2021/01/01 13:31:04
4216 dnl ---------------
4217 dnl Construct a search-list of directories for a nonstandard library-file
4218 dnl
4219 dnl Parameters
4220 dnl     $1 = the variable to return as result
4221 dnl     $2 = the package name
4222 AC_DEFUN([CF_LIBRARY_PATH],
4223 [
4224 $1=
4225 cf_library_path_list=""
4226 if test -n "${LDFLAGS}${LIBS}" ; then
4227         for cf_library_path in $LDFLAGS $LIBS
4228         do
4229                 case "$cf_library_path" in
4230                 (-L*)
4231                         cf_library_path=`echo ".$cf_library_path" |sed -e 's/^...//' -e 's,/lib$,,'`
4232                         CF_ADD_SUBDIR_PATH($1,$2,lib,$cf_library_path,NONE)
4233                         cf_library_path_list="$cf_library_path_list [$]$1"
4234                         ;;
4235                 esac
4236         done
4237 fi
4238
4239 CF_SUBDIR_PATH($1,$2,lib)
4240
4241 $1="$cf_library_path_list [$]$1"
4242 ])dnl
4243 dnl ---------------------------------------------------------------------------
4244 dnl CF_LIBTOOL_VERSION version: 1 updated: 2013/04/06 18:03:09
4245 dnl ------------------
4246 AC_DEFUN([CF_LIBTOOL_VERSION],[
4247 if test -n "$LIBTOOL" && test "$LIBTOOL" != none
4248 then
4249         cf_cv_libtool_version=`$LIBTOOL --version 2>&1 | sed -e '/^$/d' |sed -e '2,$d' -e 's/([[^)]]*)//g' -e 's/^[[^1-9]]*//' -e 's/[[^0-9.]].*//'`
4250 else
4251         cf_cv_libtool_version=
4252 fi
4253 test -z "$cf_cv_libtool_version" && unset cf_cv_libtool_version
4254 ])dnl
4255 dnl ---------------------------------------------------------------------------
4256 dnl CF_LIB_PREFIX version: 14 updated: 2021/01/01 13:31:04
4257 dnl -------------
4258 dnl Compute the library-prefix for the given host system
4259 dnl $1 = variable to set
4260 define([CF_LIB_PREFIX],
4261 [
4262         case "$cf_cv_system_name" in
4263         (OS/2*|os2*)
4264                 if test "$DFT_LWR_MODEL" = libtool; then
4265                         LIB_PREFIX='lib'
4266                 else
4267                         LIB_PREFIX=''
4268                 fi
4269                 ;;
4270         (*-msvc*)
4271                 LIB_PREFIX=''
4272                 ;;
4273         (*)     LIB_PREFIX='lib'
4274                 ;;
4275         esac
4276 ifelse($1,,,[$1=$LIB_PREFIX])
4277         AC_SUBST(LIB_PREFIX)
4278 ])dnl
4279 dnl ---------------------------------------------------------------------------
4280 dnl CF_LIB_RULES version: 95 updated: 2021/03/20 12:00:25
4281 dnl ------------
4282 dnl Append definitions and rules for the given models to the subdirectory
4283 dnl Makefiles, and the recursion rule for the top-level Makefile.  If the
4284 dnl subdirectory is a library-source directory, modify the Libs_To_Make list in
4285 dnl the corresponding makefile to list the models that we'll generate.
4286 dnl
4287 dnl For shared libraries, make a list of symbolic links to construct when
4288 dnl generating each library.  The convention used for Linux is the simplest
4289 dnl one:
4290 dnl     lib<name>.so    ->
4291 dnl     lib<name>.so.<major>    ->
4292 dnl     lib<name>.so.<maj>.<minor>
4293 dnl
4294 dnl Note: Libs_To_Make is mixed case, since it is not a pure autoconf variable.
4295 AC_DEFUN([CF_LIB_RULES],
4296 [AC_REQUIRE([AC_PROG_FGREP])dnl
4297
4298 cf_prefix=$LIB_PREFIX
4299 AC_REQUIRE([CF_SUBST_NCURSES_VERSION])
4300
4301 case "$cf_cv_shlib_version" in
4302 (cygdll|msysdll|mingw|msvcdll)
4303         TINFO_NAME=$TINFO_ARG_SUFFIX
4304         TINFO_SUFFIX=.dll
4305         ;;
4306 esac
4307
4308 if test -n "$TINFO_SUFFIX" ; then
4309         case "$TINFO_SUFFIX" in
4310         (tw*)
4311                 TINFO_NAME="${TINFO_NAME}tw${EXTRA_SUFFIX}"
4312                 TINFO_SUFFIX=`echo "$TINFO_SUFFIX" | sed 's/^tw'$EXTRA_SUFFIX'//'`
4313                 ;;
4314         (t*)
4315                 TINFO_NAME="${TINFO_NAME}t${EXTRA_SUFFIX}"
4316                 TINFO_SUFFIX=`echo "$TINFO_SUFFIX" | sed 's/^t'$EXTRA_SUFFIX'//'`
4317                 ;;
4318         (w*)
4319                 TINFO_NAME="${TINFO_NAME}w${EXTRA_SUFFIX}"
4320                 TINFO_SUFFIX=`echo "$TINFO_SUFFIX" | sed 's/^w'$EXTRA_SUFFIX'//'`
4321                 ;;
4322         esac
4323 fi
4324
4325 for cf_dir in $SRC_SUBDIRS
4326 do
4327         if test ! -d "$srcdir/$cf_dir" ; then
4328                 continue
4329         elif test -f "$srcdir/$cf_dir/modules" ; then
4330
4331                 SHARED_LIB=
4332                 Libs_To_Make=
4333                 cf_awk_program=
4334                 if test -n "${cf_cv_abi_version}" && test "x${cf_cv_abi_version}" != "x5"
4335                 then
4336                         cf_awk_program="$cf_awk_program\
4337 /deprecated in ABI${cf_cv_abi_version}/ { next; }\
4338 { sub(\"NCURSES([[WT]]+)?\", \"&${cf_cv_abi_version}\"); }\
4339 "
4340                 fi
4341
4342                 if test "x$WILDCARD_SYMS" = xno
4343                 then
4344                         cf_awk_program="$cf_awk_program\
4345 /[[     ]]_\\*;/ { skip=1; next; }\
4346 "
4347                 fi
4348
4349                 if test "x$cf_awk_program" != "x"
4350                 then
4351                         cat >>$cf_dir/Makefile <<CF_EOF
4352
4353 # Generated by CF_LIB_RULES
4354 resulting.map: $UNALTERED_SYMS
4355         $AWK 'BEGIN { skip = 1; last=""; } \
4356 $cf_awk_program \
4357 { if ( last != "" && ( skip == 0 || \[$]\[$]0 !~ /}/ ) ) { print last; }\
4358  skip = 0; last = \[$]\[$]0; } \
4359 END { print last; }' < "$UNALTERED_SYMS" >\[$]@
4360
4361 distclean::
4362         rm -f resulting.map
4363 CF_EOF
4364                 fi
4365
4366                 for cf_item in $cf_LIST_MODELS
4367                 do
4368                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
4369                         if test "$cf_dir" = "c++"
4370                         then
4371                                 CF_MAP_LIB_BASENAME(cf_libname,cxx)
4372                         else
4373                                 CF_MAP_LIB_BASENAME(cf_libname,$cf_dir)
4374                         fi
4375                         test -z "$cf_libname" && cf_libname="$cf_dir"
4376                         if test "$cf_item" = shared ; then
4377                                 if test -n "${LIB_SUFFIX}"
4378                                 then
4379                                         cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
4380                                 else
4381                                         cf_shared_suffix="$cf_suffix"
4382                                 fi
4383                                 if test "$cf_cv_do_symlinks" = yes ; then
4384                                         cf_version_name=
4385
4386                                         case "$cf_cv_shlib_version" in
4387                                         (rel)
4388                                                 cf_version_name=REL_VERSION
4389                                                 ;;
4390                                         (abi)
4391                                                 cf_version_name=ABI_VERSION
4392                                                 ;;
4393                                         esac
4394
4395                                         if test -n "$cf_version_name"
4396                                         then
4397                                                 case "$cf_cv_system_name" in
4398                                                 (darwin*)
4399                                                         # "w", etc?
4400                                                         cf_suffix="${USE_LIB_SUFFIX}"'.${'$cf_version_name'}'"$cf_shared_suffix"
4401                                                         ;;
4402                                                 (*)
4403                                                         cf_suffix="$cf_suffix"'.${'$cf_version_name'}'
4404                                                         ;;
4405                                                 esac
4406                                         fi
4407                                         if test -n "${USE_LIB_SUFFIX}"
4408                                         then
4409                                                 cf_shared_suffix=`echo "$cf_suffix" | sed 's/^'"${USE_LIB_SUFFIX}"'//'`
4410                                         else
4411                                                 cf_shared_suffix="$cf_suffix"
4412                                         fi
4413                                 fi
4414                                 # cygwin needs import library, and has unique naming convention
4415                                 # use autodetected ${cf_prefix} for import lib and static lib, but
4416                                 # use 'cyg' prefix for shared lib.
4417                                 case "$cf_cv_shlib_version" in
4418                                 (cygdll)
4419                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4420                                         cf_add_lib="../lib/cyg${cf_libname}${cf_cygsuf}"
4421                                         ;;
4422                                 (msysdll)
4423                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4424                                         cf_add_lib="../lib/msys-${cf_libname}${cf_cygsuf}"
4425                                         ;;
4426                                 (mingw)
4427                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4428                                         cf_add_lib="../lib/lib${cf_libname}${cf_cygsuf}"
4429                                         ;;
4430                                 (msvcdll)
4431                                         cf_cygsuf=`echo "$cf_suffix" | sed -e 's/\.dll/\${ABI_VERSION}.dll/'`
4432                                         cf_add_lib="../lib/${cf_libname}${cf_cygsuf}"
4433                                         ;;
4434                                 (*)
4435                                         cf_add_lib=
4436                                         ;;
4437                                 esac
4438                                 if test -n "$cf_add_lib"
4439                                 then
4440                                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
4441                                         continue
4442                                 fi
4443                         fi
4444                         cf_add_lib="../lib/${cf_prefix}${cf_libname}${cf_suffix}"
4445                         Libs_To_Make="$Libs_To_Make $cf_add_lib"
4446                 done
4447
4448                 if test "$cf_dir" = ncurses ; then
4449                         cf_subsets="$LIB_SUBSETS"
4450                         cf_r_parts="$cf_subsets"
4451                         cf_liblist="$Libs_To_Make"
4452
4453                         while test -n "$cf_r_parts"
4454                         do
4455                                 cf_l_parts=`echo "$cf_r_parts" |sed -e 's/ .*$//'`
4456                                 cf_r_parts=`echo "$cf_r_parts" |sed -e 's/^[[^ ]]* //'`
4457                                 if test "$cf_l_parts" != "$cf_r_parts" ; then
4458                                         cf_add_lib=
4459                                         case "$cf_l_parts" in
4460                                         (*termlib*)
4461                                                 cf_add_lib=`echo "$cf_liblist" |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TINFO_LIB_SUFFIX}%g`
4462                                                 ;;
4463                                         (*ticlib*)
4464                                                 cf_add_lib=`echo "$cf_liblist" |sed -e s%${LIB_NAME}${USE_LIB_SUFFIX}%${TICS_LIB_SUFFIX}%g`
4465                                                 ;;
4466                                         (*)
4467                                                 break
4468                                                 ;;
4469                                         esac
4470                                         if test -n "$cf_add_lib"; then
4471                                                 Libs_To_Make="$cf_add_lib $Libs_To_Make"
4472                                         fi
4473                                 else
4474                                         break
4475                                 fi
4476                         done
4477                 else
4478                         cf_subsets=`echo "$LIB_SUBSETS" | sed -e 's/^termlib.* //'`
4479                 fi
4480
4481                 if test "$cf_dir" = c++; then
4482                         if test "x$with_shared_cxx" != xyes && test -n "$cf_shared_suffix"; then
4483                                 cf_list=
4484                                 for cf_item in $Libs_To_Make
4485                                 do
4486                                         case "$cf_item" in
4487                                         (*.a)
4488                                                 ;;
4489                                         (*)
4490                                                 cf_item=`echo "$cf_item" | sed -e "s,"$cf_shared_suffix",.a,"`
4491                                                 ;;
4492                                         esac
4493                                         for cf_test in $cf_list
4494                                         do
4495                                                 if test "$cf_test" = "$cf_item"
4496                                                 then
4497                                                         cf_LIST_MODELS=`echo "$cf_LIST_MODELS" | sed -e 's/normal//'`
4498                                                         cf_item=
4499                                                         break
4500                                                 fi
4501                                         done
4502                                         test -n "$cf_item" && cf_list="$cf_list $cf_item"
4503                                 done
4504                                 Libs_To_Make="$cf_list"
4505                         fi
4506                 fi
4507
4508                 sed -e "s%@Libs_To_Make@%$Libs_To_Make%" \
4509                     -e "s%@SHARED_LIB@%$SHARED_LIB%" \
4510                         "$cf_dir/Makefile" >$cf_dir/Makefile.out
4511                 mv "$cf_dir/Makefile.out" "$cf_dir/Makefile"
4512
4513                 $AWK -f "$srcdir/mk-0th.awk" \
4514                         libname="${cf_dir}${LIB_SUFFIX}" subsets="$LIB_SUBSETS" ticlib="$TICS_LIB_SUFFIX" termlib="$TINFO_LIB_SUFFIX" \
4515                         "$srcdir/$cf_dir/modules" >>$cf_dir/Makefile
4516
4517                 for cf_subset in $cf_subsets
4518                 do
4519                         cf_subdirs=
4520                         for cf_item in $cf_LIST_MODELS
4521                         do
4522
4523                         echo "Appending rules for ${cf_item} model (${cf_dir}: ${cf_subset})"
4524                         CF_UPPER(cf_ITEM,$cf_item)
4525
4526                         CXX_MODEL=$cf_ITEM
4527                         if test "$CXX_MODEL" = SHARED; then
4528                                 case "$cf_cv_shlib_version" in
4529                                 (cygdll|msysdll|mingw|msvcdll)
4530                                         test "x$with_shared_cxx" = xno && CF_VERBOSE(overriding CXX_MODEL to SHARED)
4531                                         with_shared_cxx=yes
4532                                         ;;
4533                                 (*)
4534                                         test "x$with_shared_cxx" = xno && CXX_MODEL=NORMAL
4535                                         ;;
4536                                 esac
4537                         fi
4538
4539                         CF_LIB_SUFFIX($cf_item,cf_suffix,cf_depsuf)
4540                         CF_OBJ_SUBDIR($cf_item,cf_subdir)
4541
4542                         # Test for case where we build libtinfo with a different name.
4543                         cf_libname=$cf_dir
4544                         if test "$cf_dir" = ncurses ; then
4545                                 case "$cf_subset" in
4546                                 (*base*)
4547                                         cf_libname=${cf_libname}$USE_LIB_SUFFIX
4548                                         ;;
4549                                 (*termlib*)
4550                                         cf_libname=$TINFO_LIB_SUFFIX
4551                                         ;;
4552                                 (ticlib*)
4553                                         cf_libname=$TICS_LIB_SUFFIX
4554                                         ;;
4555                                 esac
4556                         elif test "$cf_dir" = c++ ; then
4557                                 CF_MAP_LIB_BASENAME(cf_libname,cxx)
4558                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
4559                         else
4560                                 CF_MAP_LIB_BASENAME(cf_libname,$cf_dir)
4561                                 cf_libname=${cf_libname}$USE_LIB_SUFFIX
4562                         fi
4563                         if test -n "${USE_ARG_SUFFIX}" ; then
4564                                 # undo $USE_LIB_SUFFIX add-on in CF_LIB_SUFFIX
4565                                 cf_suffix=`echo "$cf_suffix" |sed -e "s%^${USE_LIB_SUFFIX}%%"`
4566                         fi
4567
4568                         # These dependencies really are for development, not
4569                         # builds, but they are useful in porting, too.
4570                         cf_depend="../include/ncurses_cfg.h"
4571                         if test "$srcdir" = "."; then
4572                                 cf_reldir="."
4573                         else
4574                                 cf_reldir="\${srcdir}"
4575                         fi
4576
4577                         if test -f "$srcdir/$cf_dir/$cf_dir.priv.h" ; then
4578                                 cf_depend="$cf_depend $cf_reldir/$cf_dir.priv.h"
4579                         elif test -f "$srcdir/$cf_dir/curses.priv.h" ; then
4580                                 cf_depend="$cf_depend $cf_reldir/curses.priv.h"
4581                         fi
4582
4583                         cf_dir_suffix=
4584                         old_cf_suffix="$cf_suffix"
4585                         if test "$cf_cv_shlib_version_infix" = yes ; then
4586                         if test -n "$USE_LIB_SUFFIX" ; then
4587                                 case "$USE_LIB_SUFFIX" in
4588                                 (tw*)
4589                                         cf_libname=`echo "$cf_libname" | sed 's/tw'$EXTRA_SUFFIX'$//'`
4590                                         cf_suffix=`echo "$cf_suffix" | sed 's/^tw'$EXTRA_SUFFIX'//'`
4591                                         cf_dir_suffix=tw$EXTRA_SUFFIX
4592                                         ;;
4593                                 (t*)
4594                                         cf_libname=`echo "$cf_libname" | sed 's/t'$EXTRA_SUFFIX'$//'`
4595                                         cf_suffix=`echo "$cf_suffix" | sed 's/^t'$EXTRA_SUFFIX'//'`
4596                                         cf_dir_suffix=t$EXTRA_SUFFIX
4597                                         ;;
4598                                 (w*)
4599                                         cf_libname=`echo "$cf_libname" | sed 's/w'$EXTRA_SUFFIX'$//'`
4600                                         cf_suffix=`echo "$cf_suffix" | sed 's/^w'$EXTRA_SUFFIX'//'`
4601                                         cf_dir_suffix=w$EXTRA_SUFFIX
4602                                         ;;
4603                                 (*)
4604                                         cf_libname=`echo "$cf_libname" | sed 's/'$EXTRA_SUFFIX'$//'`
4605                                         cf_suffix=`echo "$cf_suffix" | sed 's/^'$EXTRA_SUFFIX'//'`
4606                                         cf_dir_suffix=$EXTRA_SUFFIX
4607                                         ;;
4608                                 esac
4609                         fi
4610                         fi
4611
4612                         $AWK -f "$srcdir/mk-1st.awk" \
4613                                 name=${cf_libname}${cf_dir_suffix} \
4614                                 traces=$LIB_TRACING \
4615                                 MODEL=$cf_ITEM \
4616                                 CXX_MODEL=$CXX_MODEL \
4617                                 model=$cf_subdir \
4618                                 prefix=$cf_prefix \
4619                                 suffix=$cf_suffix \
4620                                 subset=$cf_subset \
4621                                 driver=$cf_cv_term_driver \
4622                                 SymLink="$LN_S" \
4623                                 TermlibRoot=$TINFO_NAME \
4624                                 TermlibSuffix=$TINFO_SUFFIX \
4625                                 ShlibVer=$cf_cv_shlib_version \
4626                                 ShlibVerInfix=$cf_cv_shlib_version_infix \
4627                                 ReLink=${cf_cv_do_relink:-no} \
4628                                 ReRanlib=${cf_cv_do_reranlib:-yes} \
4629                                 DoLinks=$cf_cv_do_symlinks \
4630                                 rmSoLocs=$cf_cv_rm_so_locs \
4631                                 ldconfig="$LDCONFIG" \
4632                                 overwrite=$WITH_OVERWRITE \
4633                                 depend="$cf_depend" \
4634                                 host="$host" \
4635                                 libtool_version="$LIBTOOL_VERSION" \
4636                                 "$srcdir/$cf_dir/modules" >>$cf_dir/Makefile
4637
4638                         cf_suffix="$old_cf_suffix"
4639
4640                         for cf_subdir2 in $cf_subdirs lib
4641                         do
4642                                 test "$cf_subdir" = "$cf_subdir2" && break
4643                         done
4644                         test "${cf_subset}.${cf_subdir2}" != "${cf_subset}.${cf_subdir}" && \
4645                         $AWK -f "$srcdir/mk-2nd.awk" \
4646                                 name=$cf_dir \
4647                                 traces=$LIB_TRACING \
4648                                 MODEL=$cf_ITEM \
4649                                 model=$cf_subdir \
4650                                 subset=$cf_subset \
4651                                 srcdir=$srcdir \
4652                                 echo=$WITH_ECHO \
4653                                 crenames=$cf_cv_prog_CC_c_o \
4654                                 cxxrenames=$cf_cv_prog_CXX_c_o \
4655                                 "$srcdir/$cf_dir/modules" >>$cf_dir/Makefile
4656                         cf_subdirs="$cf_subdirs $cf_subdir"
4657                         done
4658                 done
4659         fi
4660
4661         echo '  ( cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@ )' >>Makefile
4662 done
4663
4664 for cf_dir in $SRC_SUBDIRS
4665 do
4666         if test ! -d "$srcdir/$cf_dir" ; then
4667                 continue
4668         fi
4669
4670         if test -f "$cf_dir/Makefile" ; then
4671                 case "$cf_dir" in
4672                 (Ada95)
4673                         echo 'libs \' >> Makefile
4674                         echo 'install.libs \' >> Makefile
4675                         echo 'uninstall.libs ::' >> Makefile
4676                         echo '  ( cd '$cf_dir' && ${MAKE} ${TOP_MFLAGS} [$]@ )' >> Makefile
4677                         ;;
4678                 esac
4679         fi
4680
4681         if test -f "$srcdir/$cf_dir/modules" ; then
4682                 echo >> Makefile
4683                 if test -f "$srcdir/$cf_dir/headers" ; then
4684 cat >> Makefile <<CF_EOF
4685 install.includes \\
4686 uninstall.includes \\
4687 CF_EOF
4688                 fi
4689
4690 echo 'lint \' >> Makefile
4691
4692 cat >> Makefile <<CF_EOF
4693 libs \\
4694 lintlib \\
4695 install.libs \\
4696 uninstall.libs \\
4697 install.$cf_dir \\
4698 uninstall.$cf_dir ::
4699         ( cd "$cf_dir" && \${MAKE} \${TOP_MFLAGS} \[$]@ )
4700 CF_EOF
4701         elif test -f "$srcdir/$cf_dir/headers" ; then
4702 cat >> Makefile <<CF_EOF
4703
4704 libs \\
4705 install.libs \\
4706 uninstall.libs \\
4707 install.includes \\
4708 uninstall.includes ::
4709         ( cd "$cf_dir" && \${MAKE} \${TOP_MFLAGS} \[$]@ )
4710 CF_EOF
4711 fi
4712 done
4713
4714 if test "x$cf_with_db_install" = xyes; then
4715 cat >> Makefile <<CF_EOF
4716
4717 install.libs uninstall.libs \\
4718 install.data uninstall.data ::
4719 $MAKE_TERMINFO  ( cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@ )
4720 CF_EOF
4721 else
4722 cat >> Makefile <<CF_EOF
4723
4724 install.libs uninstall.libs ::
4725         ( cd misc && \${MAKE} \${TOP_MFLAGS} \[$]@ )
4726 CF_EOF
4727 fi
4728
4729 if test "x$cf_with_manpages" = xyes; then
4730 cat >> Makefile <<CF_EOF
4731
4732 install.man \\
4733 uninstall.man ::
4734         ( cd man && \${MAKE} \${TOP_MFLAGS} \[$]@ )
4735 CF_EOF
4736 fi
4737
4738 cat >> Makefile <<CF_EOF
4739
4740 distclean ::
4741         rm -f config.cache config.log config.status Makefile include/ncurses_cfg.h
4742         rm -f headers.sh headers.sed mk_shared_lib.sh
4743         rm -f edit_man.* man_alias.*
4744         rm -rf \${DIRS_TO_MAKE}
4745 CF_EOF
4746
4747 # Special case: tack's manpage lives in its own directory.
4748 if test "x$cf_with_manpages" = xyes; then
4749 if test "x$cf_with_tack" = "xyes"; then
4750 cat >> Makefile <<CF_EOF
4751
4752 install.man \\
4753 uninstall.man ::
4754         ( cd tack && \${MAKE} \${TOP_MFLAGS} \[$]@ )
4755 CF_EOF
4756 fi
4757 fi
4758
4759 dnl If we're installing into a subdirectory of /usr/include, etc., we should
4760 dnl prepend the subdirectory's name to the "#include" paths.  It won't hurt
4761 dnl anything, and will make it more standardized.  It's awkward to decide this
4762 dnl at configuration because of quoting, so we'll simply make all headers
4763 dnl installed via a script that can do the right thing.
4764
4765 rm -f headers.sed headers.sh
4766
4767 dnl ( generating this script makes the makefiles a little tidier :-)
4768 echo creating headers.sh
4769 cat >headers.sh <<CF_EOF
4770 #! $SHELL
4771 # This shell script is generated by the 'configure' script.  It is invoked in a
4772 # subdirectory of the build tree.  It generates a sed-script in the parent
4773 # directory that is used to adjust includes for header files that reside in a
4774 # subdirectory of /usr/include, etc.
4775 PRG=""
4776 while test \[$]# != 3
4777 do
4778 PRG="\$PRG \[$]1"; shift
4779 done
4780 DST=\[$]1
4781 REF=\[$]2
4782 SRC=\[$]3
4783 TMPSRC=\${TMPDIR:-/tmp}/\`basename \$SRC\`\$\$
4784 TMPSED=\${TMPDIR:-/tmp}/headers.sed\$\$
4785 echo installing \$SRC in \$DST
4786 CF_EOF
4787
4788 if test "$WITH_CURSES_H" = yes; then
4789         cat >>headers.sh <<CF_EOF
4790 case \$DST in
4791 (/*/include/*)
4792         END=\`basename \$DST\`
4793         for i in \`cat \$REF/../*/headers |${FGREP-fgrep} -v "#"\`
4794         do
4795                 NAME=\`basename \$i\`
4796                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
4797         done
4798         ;;
4799 (*)
4800         echo "" >> \$TMPSED
4801         ;;
4802 esac
4803 CF_EOF
4804
4805 else
4806         cat >>headers.sh <<CF_EOF
4807 case \$DST in
4808 (/*/include/*)
4809         END=\`basename \$DST\`
4810         for i in \`cat \$REF/../*/headers |${FGREP-fgrep} -v "#"\`
4811         do
4812                 NAME=\`basename \$i\`
4813                 if test "\$NAME" = "curses.h"
4814                 then
4815                         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
4816                         NAME=ncurses.h
4817                 fi
4818                 echo "s/<\$NAME>/<\$END\/\$NAME>/" >> \$TMPSED
4819         done
4820         ;;
4821 (*)
4822         echo "s/<curses.h>/<ncurses.h>/" >> \$TMPSED
4823         ;;
4824 esac
4825 CF_EOF
4826 fi
4827 cat >>headers.sh <<CF_EOF
4828 rm -f \$TMPSRC
4829 sed -f \$TMPSED \$SRC > \$TMPSRC
4830 NAME=\`basename \$SRC\`
4831 CF_EOF
4832 if test "$WITH_CURSES_H" != yes; then
4833         cat >>headers.sh <<CF_EOF
4834 test "\$NAME" = "curses.h" && NAME=ncurses.h
4835 CF_EOF
4836 fi
4837 cat >>headers.sh <<CF_EOF
4838 # Just in case someone gzip'd manpages, remove the conflicting copy.
4839 test -f \$DST/\$NAME.gz && rm -f \$DST/\$NAME.gz
4840
4841 eval \$PRG \$TMPSRC \$DST/\$NAME
4842 rm -f \$TMPSRC \$TMPSED
4843 CF_EOF
4844
4845 chmod 0755 headers.sh
4846
4847 for cf_dir in $SRC_SUBDIRS
4848 do
4849         if test ! -d "$srcdir/$cf_dir" ; then
4850                 continue
4851         fi
4852
4853         if test -f "$srcdir/$cf_dir/headers" ; then
4854                 $AWK -f "$srcdir/mk-hdr.awk" \
4855                         subset="$LIB_SUBSETS" \
4856                         compat="$WITH_CURSES_H" \
4857                         "$srcdir/$cf_dir/headers" >>$cf_dir/Makefile
4858         fi
4859
4860         if test -f "$srcdir/$cf_dir/modules" ; then
4861                 if test "$cf_dir" != "c++" ; then
4862                         cat >>$cf_dir/Makefile <<"CF_EOF"
4863 depend : ${AUTO_SRC}
4864         makedepend -- ${CPPFLAGS} -- ${C_SRC}
4865
4866 # DO NOT DELETE THIS LINE -- make depend depends on it.
4867 CF_EOF
4868                 fi
4869         fi
4870 done
4871 AC_SUBST(Libs_To_Make)
4872 ])dnl
4873 dnl ---------------------------------------------------------------------------
4874 dnl CF_LIB_SONAME version: 9 updated: 2021/01/04 18:48:01
4875 dnl -------------
4876 dnl Find the and soname for the given shared library.  Set the cache variable
4877 dnl cf_cv_$3_soname to this, unless it is not found.  Then set the cache
4878 dnl variable to "unknown".
4879 dnl
4880 dnl $1 = headers
4881 dnl $2 = code
4882 dnl $3 = library name
4883 AC_DEFUN([CF_LIB_SONAME],
4884 [AC_REQUIRE([AC_PROG_FGREP])dnl
4885
4886 AC_CACHE_CHECK(for soname of $3 library,cf_cv_$3_soname,[
4887
4888 cf_cv_$3_soname=unknown
4889 if test "$cross_compiling" != yes ; then
4890 cat >conftest.$ac_ext <<CF_EOF
4891 $1
4892 int main(void)
4893 {
4894 $2
4895         ${cf_cv_main_return:-return}(0);
4896 }
4897 CF_EOF
4898 cf_save_LIBS="$LIBS"
4899         CF_ADD_LIB($3)
4900         if AC_TRY_EVAL(ac_compile) ; then
4901                 if AC_TRY_EVAL(ac_link) ; then
4902                         cf_cv_$3_soname="`ldd \"conftest$ac_exeext\" 2>/dev/null | sed -e 's,^.*/,,' -e 's, .*$,,' | ${FGREP-fgrep} lib$3.`"
4903                         test -z "$cf_cv_$3_soname" && cf_cv_$3_soname=unknown
4904                 fi
4905         fi
4906 rm -rf ./conftest*
4907 LIBS="$cf_save_LIBS"
4908 fi
4909 ])
4910 ])
4911 dnl ---------------------------------------------------------------------------
4912 dnl CF_LIB_SUFFIX version: 28 updated: 2021/01/01 16:53:59
4913 dnl -------------
4914 dnl Compute the library file-suffix from the given model name
4915 dnl $1 = model name
4916 dnl $2 = variable to set (the nominal library suffix)
4917 dnl $3 = dependency variable to set (actual filename)
4918 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
4919 AC_DEFUN([CF_LIB_SUFFIX],
4920 [
4921         case X$1 in
4922         (Xlibtool)
4923                 $2='.la'
4924                 $3=[$]$2
4925                 ;;
4926         (Xdebug)
4927                 case "$cf_cv_system_name" in
4928                 (*-msvc*)
4929                         $2='_g.lib'
4930                         ;;
4931                 (*)
4932                         $2='_g.a'
4933                         ;;
4934                 esac
4935                 $3=[$]$2
4936                 ;;
4937         (Xprofile)
4938                 case "$cf_cv_system_name" in
4939                 (*-msvc*)
4940                         $2='_p.lib'
4941                         ;;
4942                 (*)
4943                         $2='_p.a'
4944                         ;;
4945                 esac
4946                 $3=[$]$2
4947                 ;;
4948         (Xshared)
4949                 case "$cf_cv_system_name" in
4950                 (aix[[5-7]]*)
4951                         $2='.so'
4952                         $3=[$]$2
4953                         ;;
4954                 (*-msvc*)
4955                         $2='.dll'
4956                         $3='.dll.lib'
4957                         ;;
4958                 (cygwin*|msys*|mingw*)
4959                         $2='.dll'
4960                         $3='.dll.a'
4961                         ;;
4962                 (darwin*)
4963                         $2='.dylib'
4964                         $3=[$]$2
4965                         ;;
4966                 (hpux*)
4967                         case "$target" in
4968                         (ia64*)
4969                                 $2='.so'
4970                                 $3=[$]$2
4971                                 ;;
4972                         (*)
4973                                 $2='.sl'
4974                                 $3=[$]$2
4975                                 ;;
4976                         esac
4977                         ;;
4978                 (*)
4979                         $2='.so'
4980                         $3=[$]$2
4981                         ;;
4982                 esac
4983                 ;;
4984         (*)
4985                 case "$target" in
4986                 (*-msvc*)
4987                         $2='.lib'
4988                         ;;
4989                 (*)
4990                         $2='.a'
4991                         ;;
4992                 esac
4993                 $3=[$]$2
4994                 ;;
4995         esac
4996         if test -n "${LIB_SUFFIX}${EXTRA_SUFFIX}"
4997         then
4998                 $2="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$2}"
4999                 $3="${LIB_SUFFIX}${EXTRA_SUFFIX}[$]{$3}"
5000         fi
5001 ])dnl
5002 dnl ---------------------------------------------------------------------------
5003 dnl CF_LIB_TYPE version: 5 updated: 2015/04/17 21:13:04
5004 dnl -----------
5005 dnl Compute the string to append to -library from the given model name
5006 dnl $1 = model name
5007 dnl $2 = variable to set
5008 dnl The variable $LIB_SUFFIX, if set, prepends the variable to set.
5009 AC_DEFUN([CF_LIB_TYPE],
5010 [
5011         case $1 in
5012         (libtool) $2=''   ;;
5013         (normal)  $2=''   ;;
5014         (debug)   $2='_g' ;;
5015         (profile) $2='_p' ;;
5016         (shared)  $2=''   ;;
5017         esac
5018         test -n "$LIB_SUFFIX" && $2="${LIB_SUFFIX}[$]{$2}"
5019 ])dnl
5020 dnl ---------------------------------------------------------------------------
5021 dnl CF_LINK_DATAONLY version: 13 updated: 2020/02/08 15:59:30
5022 dnl ----------------
5023 dnl Some systems have a non-ANSI linker that doesn't pull in modules that have
5024 dnl only data (i.e., no functions), for example NeXT.  On those systems we'll
5025 dnl have to provide wrappers for global tables to ensure they're linked
5026 dnl properly.
5027 AC_DEFUN([CF_LINK_DATAONLY],
5028 [
5029 AC_MSG_CHECKING([if data-only library module links])
5030 AC_CACHE_VAL(cf_cv_link_dataonly,[
5031         rm -f conftest.a
5032         cat >conftest.$ac_ext <<EOF
5033 #line __oline__ "configure"
5034 int     testdata[[3]] = { 123, 456, 789 };
5035 EOF
5036         if AC_TRY_EVAL(ac_compile) ; then
5037                 mv conftest.o data.o && \
5038                 ( $AR $ARFLAGS conftest.a data.o ) 2>&AC_FD_CC 1>/dev/null
5039         fi
5040         rm -f conftest.$ac_ext data.o
5041         cat >conftest.$ac_ext <<EOF
5042 #line __oline__ "configure"
5043 int     testfunc(void)
5044 {
5045 #if defined(NeXT)
5046         ${cf_cv_main_return:-return}(1);        /* I'm told this linker is broken */
5047 #else
5048         extern int testdata[[3]];
5049         return testdata[[0]] == 123
5050            &&  testdata[[1]] == 456
5051            &&  testdata[[2]] == 789;
5052 #endif
5053 }
5054 EOF
5055         if AC_TRY_EVAL(ac_compile); then
5056                 mv conftest.o func.o && \
5057                 ( $AR $ARFLAGS conftest.a func.o ) 2>&AC_FD_CC 1>/dev/null
5058         fi
5059         rm -f conftest.$ac_ext func.o
5060         ( eval $RANLIB conftest.a ) 2>&AC_FD_CC >/dev/null
5061         cf_saveLIBS="$LIBS"
5062         LIBS="conftest.a $LIBS"
5063         AC_TRY_RUN([
5064         int main(void)
5065         {
5066                 extern int testfunc();
5067                 ${cf_cv_main_return:-return} (!testfunc());
5068         }
5069         ],
5070         [cf_cv_link_dataonly=yes],
5071         [cf_cv_link_dataonly=no],
5072         [cf_cv_link_dataonly=unknown])
5073         LIBS="$cf_saveLIBS"
5074         ])
5075 AC_MSG_RESULT($cf_cv_link_dataonly)
5076
5077 if test "$cf_cv_link_dataonly" = no ; then
5078         AC_DEFINE(BROKEN_LINKER,1,[if data-only library module does not link])
5079         BROKEN_LINKER=1
5080 fi
5081 AC_SUBST(BROKEN_LINKER)
5082
5083 ])dnl
5084 dnl ---------------------------------------------------------------------------
5085 dnl CF_LINK_FUNCS version: 9 updated: 2017/01/21 11:11:02
5086 dnl -------------
5087 dnl Most Unix systems have both link and symlink, a few don't have symlink.
5088 dnl A few non-Unix systems implement symlink, but not link.
5089 dnl A few non-systems implement neither (or have nonfunctional versions).
5090 AC_DEFUN([CF_LINK_FUNCS],
5091 [
5092 AC_CHECK_HEADERS( \
5093 unistd.h \
5094 )
5095 AC_CHECK_FUNCS( \
5096         remove \
5097         unlink )
5098
5099 if test "$cross_compiling" = yes ; then
5100         AC_CHECK_FUNCS( \
5101                 link \
5102                 symlink )
5103 else
5104         AC_CACHE_CHECK(if link/symlink functions work,cf_cv_link_funcs,[
5105                 cf_cv_link_funcs=
5106                 for cf_func in link symlink ; do
5107                         AC_TRY_RUN([
5108 #include <sys/types.h>
5109 #include <sys/stat.h>
5110 #ifdef HAVE_UNISTD_H
5111 #include <unistd.h>
5112 #endif
5113 int main(void)
5114 {
5115         int fail = 0;
5116         char *src = "config.log";
5117         char *dst = "conftest.chk";
5118         struct stat src_sb;
5119         struct stat dst_sb;
5120
5121         stat(src, &src_sb);
5122         fail = ($cf_func("config.log", "conftest.chk") < 0)
5123             || (stat(dst, &dst_sb) < 0)
5124             || (dst_sb.st_mtime != src_sb.st_mtime);
5125 #ifdef HAVE_UNLINK
5126         unlink(dst);
5127 #else
5128         remove(dst);
5129 #endif
5130         ${cf_cv_main_return:-return} (fail);
5131 }
5132                         ],[
5133                         cf_cv_link_funcs="$cf_cv_link_funcs $cf_func"
5134                         eval 'ac_cv_func_'$cf_func'=yes'],[
5135                         eval 'ac_cv_func_'$cf_func'=no'],[
5136                         eval 'ac_cv_func_'$cf_func'=error'])
5137                 done
5138                 test -z "$cf_cv_link_funcs" && cf_cv_link_funcs=no
5139         ])
5140         test "$ac_cv_func_link"    = yes && AC_DEFINE(HAVE_LINK,1,[Define to 1 if we have link() function])
5141         test "$ac_cv_func_symlink" = yes && AC_DEFINE(HAVE_SYMLINK,1,[Define to 1 if we have symlink() function])
5142 fi
5143 ])dnl
5144 dnl ---------------------------------------------------------------------------
5145 dnl CF_MAKEFLAGS version: 20 updated: 2021/01/03 19:29:49
5146 dnl ------------
5147 dnl Some 'make' programs support ${MAKEFLAGS}, some ${MFLAGS}, to pass 'make'
5148 dnl options to lower-levels.  It's very useful for "make -n" -- if we have it.
5149 dnl (GNU 'make' does both, something POSIX 'make', which happens to make the
5150 dnl ${MAKEFLAGS} variable incompatible because it adds the assignments :-)
5151 AC_DEFUN([CF_MAKEFLAGS],
5152 [AC_REQUIRE([AC_PROG_FGREP])dnl
5153
5154 AC_CACHE_CHECK(for makeflags variable, cf_cv_makeflags,[
5155         cf_cv_makeflags=''
5156         for cf_option in '-${MAKEFLAGS}' '${MFLAGS}'
5157         do
5158                 cat >cf_makeflags.tmp <<CF_EOF
5159 SHELL = $SHELL
5160 all :
5161         @ echo '.$cf_option'
5162 CF_EOF
5163                 cf_result=`${MAKE:-make} -k -f cf_makeflags.tmp 2>/dev/null | ${FGREP-fgrep} -v "ing directory" | sed -e 's,[[  ]]*$,,'`
5164                 case "$cf_result" in
5165                 (.*k|.*kw)
5166                         cf_result="`${MAKE:-make} -k -f cf_makeflags.tmp CC=cc 2>/dev/null`"
5167                         case "$cf_result" in
5168                         (.*CC=*)        cf_cv_makeflags=
5169                                 ;;
5170                         (*)     cf_cv_makeflags=$cf_option
5171                                 ;;
5172                         esac
5173                         break
5174                         ;;
5175                 (.-)
5176                         ;;
5177                 (*)
5178                         CF_MSG_LOG(given option \"$cf_option\", no match \"$cf_result\")
5179                         ;;
5180                 esac
5181         done
5182         rm -f cf_makeflags.tmp
5183 ])
5184
5185 AC_SUBST(cf_cv_makeflags)
5186 ])dnl
5187 dnl ---------------------------------------------------------------------------
5188 dnl CF_MAKE_TAGS version: 6 updated: 2010/10/23 15:52:32
5189 dnl ------------
5190 dnl Generate tags/TAGS targets for makefiles.  Do not generate TAGS if we have
5191 dnl a monocase filesystem.
5192 AC_DEFUN([CF_MAKE_TAGS],[
5193 AC_REQUIRE([CF_MIXEDCASE_FILENAMES])
5194
5195 AC_CHECK_PROGS(CTAGS, exctags ctags)
5196 AC_CHECK_PROGS(ETAGS, exetags etags)
5197
5198 AC_CHECK_PROG(MAKE_LOWER_TAGS, ${CTAGS:-ctags}, yes, no)
5199
5200 if test "$cf_cv_mixedcase" = yes ; then
5201         AC_CHECK_PROG(MAKE_UPPER_TAGS, ${ETAGS:-etags}, yes, no)
5202 else
5203         MAKE_UPPER_TAGS=no
5204 fi
5205
5206 if test "$MAKE_UPPER_TAGS" = yes ; then
5207         MAKE_UPPER_TAGS=
5208 else
5209         MAKE_UPPER_TAGS="#"
5210 fi
5211
5212 if test "$MAKE_LOWER_TAGS" = yes ; then
5213         MAKE_LOWER_TAGS=
5214 else
5215         MAKE_LOWER_TAGS="#"
5216 fi
5217
5218 AC_SUBST(CTAGS)
5219 AC_SUBST(ETAGS)
5220
5221 AC_SUBST(MAKE_UPPER_TAGS)
5222 AC_SUBST(MAKE_LOWER_TAGS)
5223 ])dnl
5224 dnl ---------------------------------------------------------------------------
5225 dnl CF_MANPAGE_FORMAT version: 14 updated: 2021/01/02 17:09:14
5226 dnl -----------------
5227 dnl Option to allow user to override automatic configuration of manpage format.
5228 dnl There are several special cases:
5229 dnl
5230 dnl     gzip - man checks for, can display gzip'd files
5231 dnl     compress - man checks for, can display compressed files
5232 dnl     BSDI - files in the cat-directories are suffixed ".0"
5233 dnl     formatted - installer should format (put files in cat-directory)
5234 dnl     catonly - installer should only format, e.g., for a turnkey system.
5235 dnl
5236 dnl There are other configurations which this macro does not test, e.g., HPUX's
5237 dnl compressed manpages (but uncompressed manpages are fine, and HPUX's naming
5238 dnl convention would not match our use).
5239 AC_DEFUN([CF_MANPAGE_FORMAT],
5240 [
5241 AC_REQUIRE([CF_PATHSEP])
5242 AC_MSG_CHECKING(format of man-pages)
5243
5244 AC_ARG_WITH(manpage-format,
5245         [  --with-manpage-format   specify manpage-format: gzip/compress/BSDI/normal and
5246                           optionally formatted/catonly, e.g., gzip,formatted],
5247         [MANPAGE_FORMAT=$withval],
5248         [MANPAGE_FORMAT=unknown])
5249
5250 test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=unknown
5251 MANPAGE_FORMAT=`echo "$MANPAGE_FORMAT" | sed -e 's/,/ /g'`
5252
5253 cf_unknown=
5254
5255 case "$MANPAGE_FORMAT" in
5256 (unknown)
5257         if test -z "$MANPATH" ; then
5258                 MANPATH="/usr/man:/usr/share/man"
5259         fi
5260
5261         # look for the 'date' man-page (it's most likely to be installed!)
5262         MANPAGE_FORMAT=
5263         cf_preform="no"
5264         cf_catonly="yes"
5265         cf_example="date"
5266
5267         IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${IFS}${PATH_SEPARATOR}"
5268         for cf_dir in $MANPATH; do
5269                 test -z "$cf_dir" && cf_dir=/usr/man
5270                 for cf_name in $cf_dir/man*/$cf_example.[[01]]* $cf_dir/cat*/$cf_example.[[01]]* $cf_dir/man*/$cf_example $cf_dir/cat*/$cf_example
5271                 do
5272                         cf_test=`echo "$cf_name" | sed -e 's/*//'`
5273                         if test "x$cf_test" = "x$cf_name" ; then
5274
5275                                 case "$cf_name" in
5276                                 (*.gz) MANPAGE_FORMAT="$MANPAGE_FORMAT gzip";;
5277                                 (*.Z)  MANPAGE_FORMAT="$MANPAGE_FORMAT compress";;
5278                                 (*.0)  MANPAGE_FORMAT="$MANPAGE_FORMAT BSDI";;
5279                                 (*)    MANPAGE_FORMAT="$MANPAGE_FORMAT normal";;
5280                                 esac
5281
5282                                 case "$cf_name" in
5283                                 ($cf_dir/man*)
5284                                         cf_catonly=no
5285                                         ;;
5286                                 ($cf_dir/cat*)
5287                                         cf_preform=yes
5288                                         ;;
5289                                 esac
5290                                 break
5291                         fi
5292
5293                         # if we found a match in either man* or cat*, stop looking
5294                         if test -n "$MANPAGE_FORMAT" ; then
5295                                 cf_found=no
5296                                 test "$cf_preform" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT formatted"
5297                                 test "$cf_catonly" = yes && MANPAGE_FORMAT="$MANPAGE_FORMAT catonly"
5298                                 case "$cf_name" in
5299                                 ($cf_dir/cat*)
5300                                         cf_found=yes
5301                                         ;;
5302                                 esac
5303                                 test "$cf_found" = yes && break
5304                         fi
5305                 done
5306                 # only check the first directory in $MANPATH where we find manpages
5307                 if test -n "$MANPAGE_FORMAT" ; then
5308                         break
5309                 fi
5310         done
5311         # if we did not find the example, just assume it is normal
5312         test -z "$MANPAGE_FORMAT" && MANPAGE_FORMAT=normal
5313         IFS="$ac_save_ifs"
5314         ;;
5315 (*)
5316         for cf_option in $MANPAGE_FORMAT; do
5317         case "$cf_option" in
5318         (gzip|compress|BSDI|normal|formatted|catonly)
5319                 ;;
5320         (*)
5321                 cf_unknown="$cf_unknown $cf_option"
5322                 ;;
5323         esac
5324         done
5325         ;;
5326 esac
5327
5328 AC_MSG_RESULT($MANPAGE_FORMAT)
5329 if test -n "$cf_unknown" ; then
5330         AC_MSG_WARN(Unexpected manpage-format $cf_unknown)
5331 fi
5332 ])dnl
5333 dnl ---------------------------------------------------------------------------
5334 dnl CF_MANPAGE_RENAMES version: 12 updated: 2021/01/01 16:53:59
5335 dnl ------------------
5336 dnl The Debian people have their own naming convention for manpages.  This
5337 dnl option lets us override the name of the file containing renaming, or
5338 dnl disable it altogether.
5339 AC_DEFUN([CF_MANPAGE_RENAMES],
5340 [
5341 AC_MSG_CHECKING(for manpage renaming)
5342
5343 AC_ARG_WITH(manpage-renames,
5344         [  --with-manpage-renames  specify manpage-renaming],
5345         [MANPAGE_RENAMES=$withval],
5346         [MANPAGE_RENAMES=yes])
5347
5348 case ".$MANPAGE_RENAMES" in
5349 (.no)
5350         ;;
5351 (.|.yes)
5352         # Debian 'man' program?
5353         if test -f /etc/debian_version ; then
5354                 MANPAGE_RENAMES=`cd "$srcdir" && pwd`/man/man_db.renames
5355         else
5356                 MANPAGE_RENAMES=no
5357         fi
5358         ;;
5359 esac
5360
5361 if test "$MANPAGE_RENAMES" != no ; then
5362         if test -f "$srcdir/man/$MANPAGE_RENAMES" ; then
5363                 MANPAGE_RENAMES=`cd "$srcdir/man" && pwd`/$MANPAGE_RENAMES
5364         elif test ! -f "$MANPAGE_RENAMES" ; then
5365                 AC_MSG_ERROR(not a filename: $MANPAGE_RENAMES)
5366         fi
5367
5368         test ! -d man && mkdir man
5369
5370         # Construct a sed-script to perform renaming within man-pages
5371         if test -n "$MANPAGE_RENAMES" ; then
5372                 test ! -d man && mkdir man
5373                 $SHELL "$srcdir/man/make_sed.sh" "$MANPAGE_RENAMES" >./edit_man.sed
5374         fi
5375 fi
5376
5377 AC_MSG_RESULT($MANPAGE_RENAMES)
5378 AC_SUBST(MANPAGE_RENAMES)
5379 ])dnl
5380 dnl ---------------------------------------------------------------------------
5381 dnl CF_MANPAGE_SYMLINKS version: 6 updated: 2015/04/17 21:13:04
5382 dnl -------------------
5383 dnl Some people expect each tool to make all aliases for manpages in the
5384 dnl man-directory.  This accommodates the older, less-capable implementations
5385 dnl of 'man', and is optional.
5386 AC_DEFUN([CF_MANPAGE_SYMLINKS],
5387 [
5388 AC_MSG_CHECKING(if manpage aliases will be installed)
5389
5390 AC_ARG_WITH(manpage-aliases,
5391         [  --with-manpage-aliases  specify manpage-aliases using .so],
5392         [MANPAGE_ALIASES=$withval],
5393         [MANPAGE_ALIASES=yes])
5394
5395 AC_MSG_RESULT($MANPAGE_ALIASES)
5396
5397 case "x$LN_S" in
5398 (xln*)
5399         cf_use_symlinks=yes
5400         ;;
5401 (*)
5402         cf_use_symlinks=no
5403         ;;
5404 esac
5405
5406 MANPAGE_SYMLINKS=no
5407 if test "$MANPAGE_ALIASES" = yes ; then
5408 AC_MSG_CHECKING(if manpage symlinks should be used)
5409
5410 AC_ARG_WITH(manpage-symlinks,
5411         [  --with-manpage-symlinks specify manpage-aliases using symlinks],
5412         [MANPAGE_SYMLINKS=$withval],
5413         [MANPAGE_SYMLINKS=$cf_use_symlinks])
5414
5415 if test "$$cf_use_symlinks" = no; then
5416 if test "$MANPAGE_SYMLINKS" = yes ; then
5417         AC_MSG_WARN(cannot make symlinks, will use .so files)
5418         MANPAGE_SYMLINKS=no
5419 fi
5420 fi
5421
5422 AC_MSG_RESULT($MANPAGE_SYMLINKS)
5423 fi
5424
5425 ])dnl
5426 dnl ---------------------------------------------------------------------------
5427 dnl CF_MANPAGE_TBL version: 3 updated: 2002/01/19 22:51:32
5428 dnl --------------
5429 dnl This option causes manpages to be run through tbl(1) to generate tables
5430 dnl correctly.
5431 AC_DEFUN([CF_MANPAGE_TBL],
5432 [
5433 AC_MSG_CHECKING(for manpage tbl)
5434
5435 AC_ARG_WITH(manpage-tbl,
5436         [  --with-manpage-tbl      specify manpage processing with tbl],
5437         [MANPAGE_TBL=$withval],
5438         [MANPAGE_TBL=no])
5439
5440 AC_MSG_RESULT($MANPAGE_TBL)
5441 ])dnl
5442 dnl ---------------------------------------------------------------------------
5443 dnl CF_MAN_PAGES version: 51 updated: 2021/01/05 16:29:19
5444 dnl ------------
5445 dnl Try to determine if the man-pages on the system are compressed, and if
5446 dnl so, what format is used.  Use this information to construct a script that
5447 dnl will install man-pages.
5448 AC_DEFUN([CF_MAN_PAGES],
5449 [
5450 CF_HELP_MESSAGE(Options to Specify How Manpages are Installed:)
5451 CF_MANPAGE_FORMAT
5452 CF_MANPAGE_RENAMES
5453 CF_MANPAGE_SYMLINKS
5454 CF_MANPAGE_TBL
5455
5456 if test "$prefix" = "NONE" ; then
5457         cf_prefix="$ac_default_prefix"
5458 else
5459         cf_prefix="$prefix"
5460 fi
5461
5462 case "$MANPAGE_FORMAT" in
5463 (*catonly*)
5464         cf_format=yes
5465         cf_inboth=no
5466         ;;
5467 (*formatted*)
5468         cf_format=yes
5469         cf_inboth=yes
5470         ;;
5471 (*)
5472         cf_format=no
5473         cf_inboth=no
5474         ;;
5475 esac
5476
5477 test ! -d man && mkdir man
5478
5479 cf_so_strip=
5480 cf_compress=
5481 case "$MANPAGE_FORMAT" in
5482 (*compress*)
5483         cf_so_strip="Z"
5484         cf_compress=compress
5485         ;;
5486 (*gzip*)
5487         cf_so_strip="gz"
5488         cf_compress=gzip
5489         ;;
5490 esac
5491
5492 cf_edit_man=./edit_man.sh
5493 cf_man_alias=`pwd`/man_alias.sed
5494
5495 cat >$cf_edit_man <<CF_EOF
5496 #! $SHELL
5497 # this script is generated by the configure-script CF_MAN_PAGES macro.
5498
5499 prefix="$cf_prefix"
5500 datarootdir="$datarootdir"
5501 datadir="$datadir"
5502
5503 NCURSES_MAJOR="$NCURSES_MAJOR"
5504 NCURSES_MINOR="$NCURSES_MINOR"
5505 NCURSES_PATCH="$NCURSES_PATCH"
5506
5507 NCURSES_OSPEED="$NCURSES_OSPEED"
5508 TERMINFO="$TERMINFO"
5509
5510 INSTALL="$INSTALL"
5511 INSTALL_DATA="$INSTALL_DATA"
5512
5513 transform="$program_transform_name"
5514
5515 TMP=\${TMPDIR:=/tmp}/man\$\$
5516 trap "rm -f \$TMP" 0 1 2 3 15
5517
5518 form=\[$]1
5519 shift || exit 1
5520
5521 verb=\[$]1
5522 shift || exit 1
5523
5524 mandir=\[$]1
5525 shift || exit 1
5526
5527 srcdir=\[$]1
5528 top_srcdir=\[$]srcdir/..
5529 shift || exit 1
5530
5531 if test "\$form" = normal ; then
5532         if test "$cf_format" = yes ; then
5533         if test "$cf_inboth" = no ; then
5534                 $SHELL "\[$]0" format "\$verb" "\$mandir" "\$srcdir" "\[$]@"
5535                 exit $?
5536         fi
5537         fi
5538         cf_subdir=\$mandir/man
5539         cf_tables=$MANPAGE_TBL
5540 else
5541         cf_subdir=\$mandir/cat
5542         cf_tables=yes
5543 fi
5544
5545 # process the list of source-files
5546 for i in "\[$]@" ; do
5547 case \$i in
5548 (*.orig|*.rej) ;;
5549 (*.[[0-9]]*)
5550         section=\`expr "\$i" : '.*\\.\\([[0-9]]\\)[[xm]]*'\`;
5551         if test "\$verb" = installing ; then
5552         if test ! -d "\$cf_subdir\${section}" ; then
5553                 mkdir -p "\$cf_subdir\$section"
5554         fi
5555         fi
5556
5557         # replace variables in man page
5558         if test ! -f "$cf_man_alias" ; then
5559 cat >>$cf_man_alias <<-CF_EOF2
5560                 s,@DATADIR@,\$datadir,g
5561                 s,@TERMINFO@,\${TERMINFO:="no default value"},g
5562                 s,@TERMINFO_DIRS@,\${TERMINFO_DIRS:="no default value"},g
5563                 s,@NCURSES_MAJOR@,\${NCURSES_MAJOR:="no default value"},g
5564                 s,@NCURSES_MINOR@,\${NCURSES_MINOR:="no default value"},g
5565                 s,@NCURSES_PATCH@,\${NCURSES_PATCH:="no default value"},g
5566                 s,@NCURSES_OSPEED@,\${NCURSES_OSPEED:="no default value"},g
5567 CF_EOF
5568         ifelse($1,,,[
5569         for cf_name in $1
5570         do
5571                 cf_NAME=`echo "$cf_name" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
5572                 cf_name=`echo "$cf_name" | sed "$program_transform_name"`
5573 cat >>$cf_edit_man <<-CF_EOF
5574                 s,@$cf_NAME@,$cf_name,g
5575 CF_EOF
5576         done
5577         ])
5578 cat >>$cf_edit_man <<CF_EOF
5579 CF_EOF2
5580                 echo "...made $cf_man_alias"
5581         fi
5582
5583         aliases=
5584         cf_source=\`basename "\$i"\`
5585         inalias=\$cf_source
5586         test ! -f "\$inalias" && inalias="\$srcdir/\$inalias"
5587         if test ! -f "\$inalias" ; then
5588                 echo ".. skipped \$cf_source"
5589                 continue
5590         fi
5591 CF_EOF
5592
5593 if test "$MANPAGE_ALIASES" != no ; then
5594 cat >>$cf_edit_man <<CF_EOF
5595         nCurses=ignore.3x
5596         test "$with_curses_h" = yes && nCurses=ncurses.3x
5597         aliases=\`sed -f "\$top_srcdir/man/manlinks.sed" "\$inalias" |sed -f "$cf_man_alias" | sort -u; test "\$inalias" = "\$nCurses" && echo curses\`
5598 CF_EOF
5599 fi
5600
5601 if test "$MANPAGE_RENAMES" = no ; then
5602 cat >>$cf_edit_man <<CF_EOF
5603         # perform program transformations for section 1 man pages
5604         if test \$section = 1 ; then
5605                 cf_target=\$cf_subdir\${section}/\`echo \$cf_source|sed "\${transform}"\`
5606         else
5607                 cf_target=\$cf_subdir\${section}/\$cf_source
5608         fi
5609 CF_EOF
5610 else
5611 cat >>$cf_edit_man <<CF_EOF
5612         cf_target=\`grep "^\$cf_source" $MANPAGE_RENAMES | $AWK '{print \[$]2}'\`
5613         if test -z "\$cf_target" ; then
5614                 echo "? missing rename for \$cf_source"
5615                 cf_target="\$cf_source"
5616         fi
5617         cf_target="\$cf_subdir\${section}/\${cf_target}"
5618
5619 CF_EOF
5620 fi
5621
5622 cat >>$cf_edit_man <<CF_EOF
5623         sed     -f "$cf_man_alias" \\
5624 CF_EOF
5625
5626 if test -f "$MANPAGE_RENAMES" ; then
5627 cat >>$cf_edit_man <<CF_EOF
5628                 < "\$i" | sed -f `pwd`/edit_man.sed >\$TMP
5629 CF_EOF
5630 else
5631 cat >>$cf_edit_man <<CF_EOF
5632                 < "\$i" >\$TMP
5633 CF_EOF
5634 fi
5635
5636 cat >>$cf_edit_man <<CF_EOF
5637 if test \$cf_tables = yes ; then
5638         tbl \$TMP >\$TMP.out
5639         mv \$TMP.out \$TMP
5640 fi
5641 CF_EOF
5642
5643 if test "$with_overwrite" != yes ; then
5644 cat >>$cf_edit_man <<CF_EOF
5645         sed -e "/\\#[    ]*include/s,<curses.h,<ncurses$LIB_SUFFIX/curses.h," < \$TMP >\$TMP.out
5646         mv \$TMP.out \$TMP
5647 CF_EOF
5648 fi
5649
5650 if test "$with_curses_h" != yes ; then
5651 cat >>$cf_edit_man <<CF_EOF
5652         sed -e "/\\#[    ]*include/s,curses.h,ncurses.h," < \$TMP >\$TMP.out
5653         mv \$TMP.out \$TMP
5654 CF_EOF
5655 fi
5656
5657 cat >>$cf_edit_man <<CF_EOF
5658         if test "\$form" = format ; then
5659                 nroff -man \$TMP >\$TMP.out
5660                 mv \$TMP.out \$TMP
5661         fi
5662 CF_EOF
5663
5664 if test -n "$cf_compress" ; then
5665 cat >>$cf_edit_man <<CF_EOF
5666         if test "\$verb" = installing ; then
5667         if ( "$cf_compress" -f \$TMP )
5668         then
5669                 mv \$TMP.$cf_so_strip \$TMP
5670         fi
5671         fi
5672         cf_target="\$cf_target.$cf_so_strip"
5673 CF_EOF
5674 fi
5675
5676 case "$MANPAGE_FORMAT" in
5677 (*BSDI*)
5678 cat >>$cf_edit_man <<CF_EOF
5679         if test "\$form" = format ; then
5680                 # BSDI installs only .0 suffixes in the cat directories
5681                 cf_target="\`echo \$cf_target|sed -e 's/\\.[[1-9]]\\+[[a-z]]*/.0/'\`"
5682         fi
5683 CF_EOF
5684   ;;
5685 esac
5686
5687 cat >>$cf_edit_man <<CF_EOF
5688         suffix=\`basename "\$cf_target" | sed -e 's%^[[^.]]*%%'\`
5689         if test "\$verb" = installing ; then
5690                 echo "\$verb \$cf_target"
5691                 \$INSTALL_DATA \$TMP "\$cf_target"
5692                 test -d "\$cf_subdir\${section}" &&
5693                 test -n "\$aliases" && (
5694                         cd "\$cf_subdir\${section}" && (
5695                                 cf_source=\`echo "\$cf_target" |sed -e 's%^.*/\\([[^/]][[^/]]*/[[^/]][[^/]]*$\\)%\\1%'\`
5696                                 test -n "$cf_so_strip" && cf_source=\`echo "\$cf_source" |sed -e 's%\\.$cf_so_strip\$%%'\`
5697                                 cf_target=\`basename "\$cf_target"\`
5698                                 for cf_alias in \$aliases
5699                                 do
5700                                         if test "\$section" = 1 ; then
5701                                                 cf_alias=\`echo "\$cf_alias" |sed "\${transform}"\`
5702                                         fi
5703
5704                                         if test "$MANPAGE_SYMLINKS" = yes ; then
5705                                                 if test -f "\$cf_alias\${suffix}" ; then
5706                                                         if ( cmp -s "\$cf_target" "\$cf_alias\${suffix}" )
5707                                                         then
5708                                                                 continue
5709                                                         fi
5710                                                 fi
5711                                                 echo ".. \$verb alias \$cf_alias\${suffix}"
5712 CF_EOF
5713 case "x$LN_S" in
5714 (*-f)
5715 cat >>$cf_edit_man <<CF_EOF
5716                                                 $LN_S "\$cf_target" "\$cf_alias\${suffix}"
5717 CF_EOF
5718         ;;
5719 (*)
5720 cat >>$cf_edit_man <<CF_EOF
5721                                                 rm -f "\$cf_alias\${suffix}"
5722                                                 $LN_S "\$cf_target" "\$cf_alias\${suffix}"
5723 CF_EOF
5724         ;;
5725 esac
5726 cat >>$cf_edit_man <<CF_EOF
5727                                         elif test "\$cf_target" != "\$cf_alias\${suffix}" ; then
5728                                                 echo ".so \$cf_source" >\$TMP
5729 CF_EOF
5730 if test -n "$cf_compress" ; then
5731 cat >>$cf_edit_man <<CF_EOF
5732                                                 if test -n "$cf_so_strip" ; then
5733                                                         "$cf_compress" -f \$TMP
5734                                                         mv \$TMP.$cf_so_strip \$TMP
5735                                                 fi
5736 CF_EOF
5737 fi
5738 cat >>$cf_edit_man <<CF_EOF
5739                                                 echo ".. \$verb alias \$cf_alias\${suffix}"
5740                                                 rm -f "\$cf_alias\${suffix}"
5741                                                 \$INSTALL_DATA \$TMP "\$cf_alias\${suffix}"
5742                                         fi
5743                                 done
5744                         )
5745                 )
5746         elif test "\$verb" = removing ; then
5747                 test -f "\$cf_target" && (
5748                         echo "\$verb \$cf_target"
5749                         rm -f "\$cf_target"
5750                 )
5751                 test -d "\$cf_subdir\${section}" &&
5752                 test -n "\$aliases" && (
5753                         cd "\$cf_subdir\${section}" && (
5754                                 for cf_alias in \$aliases
5755                                 do
5756                                         if test "\$section" = 1 ; then
5757                                                 cf_alias=\`echo "\$cf_alias" |sed "\${transform}"\`
5758                                         fi
5759
5760                                         echo ".. \$verb alias \$cf_alias\${suffix}"
5761                                         rm -f "\$cf_alias\${suffix}"
5762                                 done
5763                         )
5764                 )
5765         else
5766 #               echo ".hy 0"
5767                 cat \$TMP
5768         fi
5769         ;;
5770 esac
5771 done
5772
5773 if test "$cf_inboth" = yes ; then
5774 if test "\$form" != format ; then
5775         $SHELL "\[$]0" format "\$verb" "\$mandir" "\$srcdir" "\[$]@"
5776 fi
5777 fi
5778
5779 exit 0
5780 CF_EOF
5781 chmod 755 "$cf_edit_man"
5782
5783 ])dnl
5784 dnl ---------------------------------------------------------------------------
5785 dnl CF_MAP_LIB_BASENAME version: 2 updated: 2021/01/02 17:09:14
5786 dnl -------------------
5787 dnl Convert a default-libname to the actual one used via CF_WITH_LIB_BASENAME.
5788 dnl
5789 dnl $1 = variable to set
5790 dnl $2 = default-libname
5791 AC_DEFUN([CF_MAP_LIB_BASENAME],[
5792 CF_UPPER(cf_map_lib_basename,$2)
5793 eval $1="\$${cf_map_lib_basename}_NAME"
5794 ])dnl
5795 dnl ---------------------------------------------------------------------------
5796 dnl CF_MATH_LIB version: 10 updated: 2020/12/31 18:40:20
5797 dnl -----------
5798 dnl Checks for libraries.  At least one UNIX system, Apple Macintosh
5799 dnl Rhapsody 5.5, does not have -lm.  We cannot use the simpler
5800 dnl AC_CHECK_LIB(m,sin), because that fails for C++.
5801 AC_DEFUN([CF_MATH_LIB],
5802 [
5803 AC_CACHE_CHECK(if -lm needed for math functions,
5804         cf_cv_need_libm,[
5805         AC_TRY_LINK([
5806         #include <stdio.h>
5807         #include <stdlib.h>
5808         #include <math.h>
5809         ],
5810         [double x = rand(); printf("result = %g\\n", ]ifelse([$2],,sin(x),$2)[)],
5811         [cf_cv_need_libm=no],
5812         [cf_cv_need_libm=yes])])
5813 if test "$cf_cv_need_libm" = yes
5814 then
5815 ifelse($1,,[
5816         CF_ADD_LIB(m)
5817 ],[$1=-lm])
5818 fi
5819 ])
5820 dnl ---------------------------------------------------------------------------
5821 dnl CF_MIXEDCASE_FILENAMES version: 9 updated: 2021/01/01 16:53:59
5822 dnl ----------------------
5823 dnl Check if the file-system supports mixed-case filenames.  If we're able to
5824 dnl create a lowercase name and see it as uppercase, it doesn't support that.
5825 AC_DEFUN([CF_MIXEDCASE_FILENAMES],
5826 [
5827 AC_CACHE_CHECK(if filesystem supports mixed-case filenames,cf_cv_mixedcase,[
5828 if test "$cross_compiling" = yes ; then
5829         case "$target_alias" in
5830         (*-os2-emx*|*-msdosdjgpp*|*-cygwin*|*-msys*|*-mingw*|*-uwin*|darwin*)
5831                 cf_cv_mixedcase=no
5832                 ;;
5833         (*)
5834                 cf_cv_mixedcase=yes
5835                 ;;
5836         esac
5837 else
5838         rm -f conftest CONFTEST
5839         echo test >conftest
5840         if test -f CONFTEST ; then
5841                 cf_cv_mixedcase=no
5842         else
5843                 cf_cv_mixedcase=yes
5844         fi
5845         rm -f conftest CONFTEST
5846 fi
5847 ])
5848 test "$cf_cv_mixedcase" = yes && AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if filesystem supports mixed-case filenames.])
5849 ])dnl
5850 dnl ---------------------------------------------------------------------------
5851 dnl CF_MKSTEMP version: 11 updated: 2021/01/01 13:31:04
5852 dnl ----------
5853 dnl Check for a working mkstemp.  This creates two files, checks that they are
5854 dnl successfully created and distinct (AmigaOS apparently fails on the last).
5855 AC_DEFUN([CF_MKSTEMP],[
5856 AC_CHECK_HEADERS( \
5857 unistd.h \
5858 )
5859 AC_CACHE_CHECK(for working mkstemp, cf_cv_func_mkstemp,[
5860 rm -rf ./conftest*
5861 AC_TRY_RUN([
5862 #include <sys/types.h>
5863 #ifdef HAVE_UNISTD_H
5864 #include <unistd.h>
5865 #endif
5866 #include <stdlib.h>
5867 #include <stdio.h>
5868 #include <string.h>
5869 #include <sys/stat.h>
5870 int main(void)
5871 {
5872         char *tmpl = "conftestXXXXXX";
5873         char name[2][80];
5874         int n;
5875         int result = 0;
5876         int fd;
5877         struct stat sb;
5878
5879         umask(077);
5880         for (n = 0; n < 2; ++n) {
5881                 strcpy(name[n], tmpl);
5882                 if ((fd = mkstemp(name[n])) >= 0) {
5883                         if (!strcmp(name[n], tmpl)
5884                          || stat(name[n], &sb) != 0
5885                          || (sb.st_mode & S_IFMT) != S_IFREG
5886                          || (sb.st_mode & 077) != 0) {
5887                                 result = 1;
5888                         }
5889                         close(fd);
5890                 }
5891         }
5892         if (result == 0
5893          && !strcmp(name[0], name[1]))
5894                 result = 1;
5895         ${cf_cv_main_return:-return}(result);
5896 }
5897 ],[cf_cv_func_mkstemp=yes
5898 ],[cf_cv_func_mkstemp=no
5899 ],[cf_cv_func_mkstemp=maybe])
5900 ])
5901 if test "x$cf_cv_func_mkstemp" = xmaybe ; then
5902         AC_CHECK_FUNC(mkstemp)
5903 fi
5904 if test "x$cf_cv_func_mkstemp" = xyes || test "x$ac_cv_func_mkstemp" = xyes ; then
5905         AC_DEFINE(HAVE_MKSTEMP,1,[Define to 1 if mkstemp() is available and working.])
5906 fi
5907 ])dnl
5908 dnl ---------------------------------------------------------------------------
5909 dnl CF_MSG_LOG version: 5 updated: 2010/10/23 15:52:32
5910 dnl ----------
5911 dnl Write a debug message to config.log, along with the line number in the
5912 dnl configure script.
5913 AC_DEFUN([CF_MSG_LOG],[
5914 echo "${as_me:-configure}:__oline__: testing $* ..." 1>&AC_FD_CC
5915 ])dnl
5916 dnl ---------------------------------------------------------------------------
5917 dnl CF_NCURSES_ABI_6 version: 4 updated: 2021/01/01 13:31:04
5918 dnl ----------------
5919 dnl Set ncurses' ABI to 6 unless overridden by explicit configure option, and
5920 dnl warn about this.
5921 AC_DEFUN([CF_NCURSES_ABI_6],[
5922 if test "${with_abi_version+set}" != set; then
5923         case "$cf_cv_rel_version" in
5924         (5.*)
5925                 cf_cv_rel_version=6.0
5926                 cf_cv_abi_version=6
5927                 AC_MSG_WARN(overriding ABI version to $cf_cv_abi_version)
5928                 ;;
5929         esac
5930 fi
5931 ])dnl
5932 dnl ---------------------------------------------------------------------------
5933 dnl CF_NCURSES_WITH_ABI_VERSION version: 3 updated: 2021/01/01 13:31:04
5934 dnl ---------------------------
5935 dnl Allow ncurses's ABI to be overridden.  Generally this happens when a
5936 dnl packager has incremented the ABI past that used in the original package,
5937 dnl and wishes to keep doing this.
5938 dnl
5939 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
5940 dnl symbol.
5941 AC_DEFUN([CF_NCURSES_WITH_ABI_VERSION],[
5942 CF_WITH_ABI_VERSION($1)
5943 if test "x$cf_cv_abi_version" != "x$with_abi_version"
5944 then
5945         case "$cf_cv_rel_version" in
5946         (5.*)
5947                 cf_cv_rel_version=$with_abi_version.0
5948                 ;;
5949         esac
5950 fi
5951 ])dnl
5952 dnl ---------------------------------------------------------------------------
5953 dnl CF_NO_LEAKS_OPTION version: 8 updated: 2021/01/05 20:05:09
5954 dnl ------------------
5955 dnl see CF_WITH_NO_LEAKS
5956 AC_DEFUN([CF_NO_LEAKS_OPTION],[
5957 AC_MSG_CHECKING(if you want to use $1 for testing)
5958 AC_ARG_WITH($1,
5959         [$2],
5960         [AC_DEFINE_UNQUOTED($3,1,"Define to 1 if you want to use $1 for testing.")ifelse([$4],,[
5961          $4
5962 ])
5963         : "${with_cflags:=-g}"
5964         : "${enable_leaks:=no}"
5965          with_$1=yes],
5966         [with_$1=])
5967 AC_MSG_RESULT(${with_$1:-no})
5968
5969 case ".$with_cflags" in
5970 (.*-g*)
5971         case .$CFLAGS in
5972         (.*-g*)
5973                 ;;
5974         (*)
5975                 CF_ADD_CFLAGS([-g])
5976                 ;;
5977         esac
5978         ;;
5979 esac
5980 ])dnl
5981 dnl ---------------------------------------------------------------------------
5982 dnl CF_NUMBER_SYNTAX version: 2 updated: 2015/04/17 21:13:04
5983 dnl ----------------
5984 dnl Check if the given variable is a number.  If not, report an error.
5985 dnl $1 is the variable
5986 dnl $2 is the message
5987 AC_DEFUN([CF_NUMBER_SYNTAX],[
5988 if test -n "$1" ; then
5989   case $1 in
5990   ([[0-9]]*)
5991         ;;
5992   (*)
5993         AC_MSG_ERROR($2 is not a number: $1)
5994         ;;
5995   esac
5996 else
5997   AC_MSG_ERROR($2 value is empty)
5998 fi
5999 ])dnl
6000 dnl ---------------------------------------------------------------------------
6001 dnl CF_OBJ_SUBDIR version: 8 updated: 2021/01/01 13:31:04
6002 dnl -------------
6003 dnl Compute the object-directory name from the given model name
6004 AC_DEFUN([CF_OBJ_SUBDIR],
6005 [
6006         case $1 in
6007         (libtool) $2='obj_lo'  ;;
6008         (normal)  $2='objects' ;;
6009         (debug)   $2='obj_g' ;;
6010         (profile) $2='obj_p' ;;
6011         (shared)
6012                 case "$cf_cv_system_name" in
6013                 (cygwin|msys)
6014                         $2='objects' ;;
6015                 (*)
6016                         $2='obj_s' ;;
6017                 esac
6018         esac
6019 ])dnl
6020 dnl ---------------------------------------------------------------------------
6021 dnl CF_PATHSEP version: 8 updated: 2021/01/01 13:31:04
6022 dnl ----------
6023 dnl Provide a value for the $PATH and similar separator (or amend the value
6024 dnl as provided in autoconf 2.5x).
6025 AC_DEFUN([CF_PATHSEP],
6026 [
6027         AC_MSG_CHECKING(for PATH separator)
6028         case "$cf_cv_system_name" in
6029         (os2*)  PATH_SEPARATOR=';'  ;;
6030         (*)     ${PATH_SEPARATOR:=':'}  ;;
6031         esac
6032 ifelse([$1],,,[$1=$PATH_SEPARATOR])
6033         AC_SUBST(PATH_SEPARATOR)
6034         AC_MSG_RESULT($PATH_SEPARATOR)
6035 ])dnl
6036 dnl ---------------------------------------------------------------------------
6037 dnl CF_PATH_PROG version: 12 updated: 2021/01/02 09:31:20
6038 dnl ------------
6039 dnl Check for a given program, defining corresponding symbol.
6040 dnl     $1 = environment variable, which is suffixed by "_PATH" in the #define.
6041 dnl     $2 = program name to find.
6042 dnl     $3 = optional list of additional program names to test.
6043 dnl $4 = $PATH
6044 dnl
6045 dnl If there is more than one token in the result, #define the remaining tokens
6046 dnl to $1_ARGS.  We need this for 'install' in particular.
6047 dnl
6048 dnl FIXME: we should allow this to be overridden by environment variables
6049 dnl
6050 AC_DEFUN([CF_PATH_PROG],[
6051 AC_REQUIRE([CF_PATHSEP])
6052 test -z "[$]$1" && $1="$2"
6053 AC_PATH_PROGS($1,[$]$1 $2 ifelse($3,,,$3),[$]$1, ifelse($4,,,$4))
6054
6055 cf_path_prog=""
6056 cf_path_args=""
6057 IFS="${IFS:-    }"; cf_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR"
6058 for cf_temp in $ac_cv_path_$1
6059 do
6060         if test -z "$cf_path_prog" ; then
6061                 if test "$with_full_paths" = yes ; then
6062                         CF_PATH_SYNTAX(cf_temp,break)
6063                         cf_path_prog="$cf_temp"
6064                 else
6065                         cf_path_prog="`basename "$cf_temp"`"
6066                 fi
6067         elif test -z "$cf_path_args" ; then
6068                 cf_path_args="$cf_temp"
6069         else
6070                 cf_path_args="$cf_path_args $cf_temp"
6071         fi
6072 done
6073 IFS="$cf_save_ifs"
6074
6075 if test -n "$cf_path_prog" ; then
6076         CF_MSG_LOG(defining path for ${cf_path_prog})
6077         AC_DEFINE_UNQUOTED($1_PATH,"$cf_path_prog",Define to pathname $1)
6078         test -n "$cf_path_args" && AC_DEFINE_UNQUOTED($1_ARGS,"$cf_path_args",Define to provide args for $1)
6079 fi
6080 ])dnl
6081 dnl ---------------------------------------------------------------------------
6082 dnl CF_PATH_SYNTAX version: 18 updated: 2020/12/31 18:40:20
6083 dnl --------------
6084 dnl Check the argument to see that it looks like a pathname.  Rewrite it if it
6085 dnl begins with one of the prefix/exec_prefix variables, and then again if the
6086 dnl result begins with 'NONE'.  This is necessary to work around autoconf's
6087 dnl delayed evaluation of those symbols.
6088 AC_DEFUN([CF_PATH_SYNTAX],[
6089 if test "x$prefix" != xNONE; then
6090         cf_path_syntax="$prefix"
6091 else
6092         cf_path_syntax="$ac_default_prefix"
6093 fi
6094
6095 case ".[$]$1" in
6096 (.\[$]\(*\)*|.\'*\'*)
6097         ;;
6098 (..|./*|.\\*)
6099         ;;
6100 (.[[a-zA-Z]]:[[\\/]]*) # OS/2 EMX
6101         ;;
6102 (.\[$]\{*prefix\}*|.\[$]\{*dir\}*)
6103         eval $1="[$]$1"
6104         case ".[$]$1" in
6105         (.NONE/*)
6106                 $1=`echo "[$]$1" | sed -e s%NONE%$cf_path_syntax%`
6107                 ;;
6108         esac
6109         ;;
6110 (.no|.NONE/*)
6111         $1=`echo "[$]$1" | sed -e s%NONE%$cf_path_syntax%`
6112         ;;
6113 (*)
6114         ifelse([$2],,[AC_MSG_ERROR([expected a pathname, not \"[$]$1\"])],$2)
6115         ;;
6116 esac
6117 ])dnl
6118 dnl ---------------------------------------------------------------------------
6119 dnl CF_PKG_CONFIG version: 11 updated: 2021/01/01 13:31:04
6120 dnl -------------
6121 dnl Check for the package-config program, unless disabled by command-line.
6122 AC_DEFUN([CF_PKG_CONFIG],
6123 [
6124 AC_MSG_CHECKING(if you want to use pkg-config)
6125 AC_ARG_WITH(pkg-config,
6126         [  --with-pkg-config{=path} enable/disable use of pkg-config],
6127         [cf_pkg_config=$withval],
6128         [cf_pkg_config=yes])
6129 AC_MSG_RESULT($cf_pkg_config)
6130
6131 case "$cf_pkg_config" in
6132 (no)
6133         PKG_CONFIG=none
6134         ;;
6135 (yes)
6136         CF_ACVERSION_CHECK(2.52,
6137                 [AC_PATH_TOOL(PKG_CONFIG, pkg-config, none)],
6138                 [AC_PATH_PROG(PKG_CONFIG, pkg-config, none)])
6139         ;;
6140 (*)
6141         PKG_CONFIG=$withval
6142         ;;
6143 esac
6144
6145 test -z "$PKG_CONFIG" && PKG_CONFIG=none
6146 if test "$PKG_CONFIG" != none ; then
6147         CF_PATH_SYNTAX(PKG_CONFIG)
6148 elif test "x$cf_pkg_config" != xno ; then
6149         AC_MSG_WARN(pkg-config is not installed)
6150 fi
6151
6152 AC_SUBST(PKG_CONFIG)
6153 ])dnl
6154 dnl ---------------------------------------------------------------------------
6155 dnl CF_POSIX_C_SOURCE version: 11 updated: 2018/12/31 20:46:17
6156 dnl -----------------
6157 dnl Define _POSIX_C_SOURCE to the given level, and _POSIX_SOURCE if needed.
6158 dnl
6159 dnl     POSIX.1-1990                            _POSIX_SOURCE
6160 dnl     POSIX.1-1990 and                        _POSIX_SOURCE and
6161 dnl             POSIX.2-1992 C-Language                 _POSIX_C_SOURCE=2
6162 dnl             Bindings Option
6163 dnl     POSIX.1b-1993                           _POSIX_C_SOURCE=199309L
6164 dnl     POSIX.1c-1996                           _POSIX_C_SOURCE=199506L
6165 dnl     X/Open 2000                             _POSIX_C_SOURCE=200112L
6166 dnl
6167 dnl Parameters:
6168 dnl     $1 is the nominal value for _POSIX_C_SOURCE
6169 AC_DEFUN([CF_POSIX_C_SOURCE],
6170 [AC_REQUIRE([CF_POSIX_VISIBLE])dnl
6171
6172 if test "$cf_cv_posix_visible" = no; then
6173
6174 cf_POSIX_C_SOURCE=ifelse([$1],,199506L,[$1])
6175
6176 cf_save_CFLAGS="$CFLAGS"
6177 cf_save_CPPFLAGS="$CPPFLAGS"
6178
6179 CF_REMOVE_DEFINE(cf_trim_CFLAGS,$cf_save_CFLAGS,_POSIX_C_SOURCE)
6180 CF_REMOVE_DEFINE(cf_trim_CPPFLAGS,$cf_save_CPPFLAGS,_POSIX_C_SOURCE)
6181
6182 AC_CACHE_CHECK(if we should define _POSIX_C_SOURCE,cf_cv_posix_c_source,[
6183         CF_MSG_LOG(if the symbol is already defined go no further)
6184         AC_TRY_COMPILE([#include <sys/types.h>],[
6185 #ifndef _POSIX_C_SOURCE
6186 make an error
6187 #endif],
6188         [cf_cv_posix_c_source=no],
6189         [cf_want_posix_source=no
6190          case .$cf_POSIX_C_SOURCE in
6191          (.[[12]]??*)
6192                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
6193                 ;;
6194          (.2)
6195                 cf_cv_posix_c_source="-D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE"
6196                 cf_want_posix_source=yes
6197                 ;;
6198          (.*)
6199                 cf_want_posix_source=yes
6200                 ;;
6201          esac
6202          if test "$cf_want_posix_source" = yes ; then
6203                 AC_TRY_COMPILE([#include <sys/types.h>],[
6204 #ifdef _POSIX_SOURCE
6205 make an error
6206 #endif],[],
6207                 cf_cv_posix_c_source="$cf_cv_posix_c_source -D_POSIX_SOURCE")
6208          fi
6209          CF_MSG_LOG(ifdef from value $cf_POSIX_C_SOURCE)
6210          CFLAGS="$cf_trim_CFLAGS"
6211          CPPFLAGS="$cf_trim_CPPFLAGS"
6212          CF_APPEND_TEXT(CPPFLAGS,$cf_cv_posix_c_source)
6213          CF_MSG_LOG(if the second compile does not leave our definition intact error)
6214          AC_TRY_COMPILE([#include <sys/types.h>],[
6215 #ifndef _POSIX_C_SOURCE
6216 make an error
6217 #endif],,
6218          [cf_cv_posix_c_source=no])
6219          CFLAGS="$cf_save_CFLAGS"
6220          CPPFLAGS="$cf_save_CPPFLAGS"
6221         ])
6222 ])
6223
6224 if test "$cf_cv_posix_c_source" != no ; then
6225         CFLAGS="$cf_trim_CFLAGS"
6226         CPPFLAGS="$cf_trim_CPPFLAGS"
6227         CF_ADD_CFLAGS($cf_cv_posix_c_source)
6228 fi
6229
6230 fi # cf_cv_posix_visible
6231
6232 ])dnl
6233 dnl ---------------------------------------------------------------------------
6234 dnl CF_POSIX_VISIBLE version: 1 updated: 2018/12/31 20:46:17
6235 dnl ----------------
6236 dnl POSIX documents test-macros which an application may set before any system
6237 dnl headers are included to make features available.
6238 dnl
6239 dnl Some BSD platforms (originally FreeBSD, but copied by a few others)
6240 dnl diverged from POSIX in 2002 by setting symbols which make all of the most
6241 dnl recent features visible in the system header files unless the application
6242 dnl overrides the corresponding test-macros.  Doing that introduces portability
6243 dnl problems.
6244 dnl
6245 dnl This macro makes a special check for the symbols used for this, to avoid a
6246 dnl conflicting definition.
6247 AC_DEFUN([CF_POSIX_VISIBLE],
6248 [
6249 AC_CACHE_CHECK(if the POSIX test-macros are already defined,cf_cv_posix_visible,[
6250 AC_TRY_COMPILE([#include <stdio.h>],[
6251 #if defined(__POSIX_VISIBLE) && ((__POSIX_VISIBLE - 0L) > 0) \
6252         && defined(__XSI_VISIBLE) && ((__XSI_VISIBLE - 0L) > 0) \
6253         && defined(__BSD_VISIBLE) && ((__BSD_VISIBLE - 0L) > 0) \
6254         && defined(__ISO_C_VISIBLE) && ((__ISO_C_VISIBLE - 0L) > 0)
6255 #error conflicting symbols found
6256 #endif
6257 ],[cf_cv_posix_visible=no],[cf_cv_posix_visible=yes])
6258 ])
6259 ])dnl
6260 dnl ---------------------------------------------------------------------------
6261 dnl CF_PREDEFINE version: 2 updated: 2010/05/26 16:44:57
6262 dnl ------------
6263 dnl Add definitions to CPPFLAGS to ensure they're predefined for all compiles.
6264 dnl
6265 dnl $1 = symbol to test
6266 dnl $2 = value (if any) to use for a predefinition
6267 AC_DEFUN([CF_PREDEFINE],
6268 [
6269 AC_MSG_CHECKING(if we must define $1)
6270 AC_TRY_COMPILE([#include <sys/types.h>
6271 ],[
6272 #ifndef $1
6273 make an error
6274 #endif],[cf_result=no],[cf_result=yes])
6275 AC_MSG_RESULT($cf_result)
6276
6277 if test "$cf_result" = yes ; then
6278         CPPFLAGS="$CPPFLAGS ifelse([$2],,-D$1,[-D$1=$2])"
6279 elif test "x$2" != "x" ; then
6280         AC_MSG_CHECKING(checking for compatible value versus $2)
6281         AC_TRY_COMPILE([#include <sys/types.h>
6282 ],[
6283 #if $1-$2 < 0
6284 make an error
6285 #endif],[cf_result=yes],[cf_result=no])
6286         AC_MSG_RESULT($cf_result)
6287         if test "$cf_result" = no ; then
6288                 # perhaps we can override it - try...
6289                 CPPFLAGS="$CPPFLAGS -D$1=$2"
6290         fi
6291 fi
6292 ])dnl
6293 dnl ---------------------------------------------------------------------------
6294 dnl CF_PRG_RULES version: 2 updated: 2021/01/01 13:31:04
6295 dnl ------------
6296 dnl Append definitions and rules for the given programs to the subdirectory
6297 dnl Makefiles, and the recursion rule for the top-level Makefile.
6298 dnl
6299 dnl parameters
6300 dnl     $1 = script to run
6301 dnl     $2 = list of subdirectories
6302 dnl
6303 dnl variables
6304 dnl     $AWK
6305 AC_DEFUN([CF_PRG_RULES],
6306 [
6307 for cf_dir in $2
6308 do
6309         if test ! -d "$srcdir/$cf_dir" ; then
6310                 continue
6311         elif test -f "$srcdir/$cf_dir/programs" ; then
6312                 $AWK -f $1 "$srcdir/$cf_dir/programs" >>$cf_dir/Makefile
6313         fi
6314 done
6315
6316 ])dnl
6317 dnl ---------------------------------------------------------------------------
6318 dnl CF_PROG_AR version: 1 updated: 2009/01/01 20:15:22
6319 dnl ----------
6320 dnl Check for archiver "ar".
6321 AC_DEFUN([CF_PROG_AR],[
6322 AC_CHECK_TOOL(AR, ar, ar)
6323 ])
6324 dnl ---------------------------------------------------------------------------
6325 dnl CF_PROG_AWK version: 1 updated: 2006/09/16 11:40:59
6326 dnl -----------
6327 dnl Check for awk, ensure that the check found something.
6328 AC_DEFUN([CF_PROG_AWK],
6329 [
6330 AC_PROG_AWK
6331 test -z "$AWK" && AC_MSG_ERROR(No awk program found)
6332 ])dnl
6333 dnl ---------------------------------------------------------------------------
6334 dnl CF_PROG_CC version: 5 updated: 2019/12/31 08:53:54
6335 dnl ----------
6336 dnl standard check for CC, plus followup sanity checks
6337 dnl $1 = optional parameter to pass to AC_PROG_CC to specify compiler name
6338 AC_DEFUN([CF_PROG_CC],[
6339 CF_ACVERSION_CHECK(2.53,
6340         [AC_MSG_WARN(this will incorrectly handle gnatgcc choice)
6341          AC_REQUIRE([AC_PROG_CC])],
6342         [])
6343 ifelse($1,,[AC_PROG_CC],[AC_PROG_CC($1)])
6344 CF_GCC_VERSION
6345 CF_ACVERSION_CHECK(2.52,
6346         [AC_PROG_CC_STDC],
6347         [CF_ANSI_CC_REQD])
6348 CF_CC_ENV_FLAGS
6349 ])dnl
6350 dnl ---------------------------------------------------------------------------
6351 dnl CF_PROG_CC_C_O version: 6 updated: 2021/01/01 13:31:04
6352 dnl --------------
6353 dnl Analogous to AC_PROG_CC_C_O, but more useful: tests only $CC, ensures that
6354 dnl the output file can be renamed, and allows for a shell variable that can
6355 dnl be used later.  The parameter is either CC or CXX.  The result is the
6356 dnl cache variable:
6357 dnl     $cf_cv_prog_CC_c_o
6358 dnl     $cf_cv_prog_CXX_c_o
6359 dnl
6360 dnl $1 = compiler
6361 dnl $2 = compiler options, if any
6362 AC_DEFUN([CF_PROG_CC_C_O],
6363 [AC_REQUIRE([AC_PROG_CC])dnl
6364 AC_MSG_CHECKING([whether [$]$1 understands -c and -o together])
6365 AC_CACHE_VAL(cf_cv_prog_$1_c_o,
6366 [
6367 cat > conftest.$ac_ext <<CF_EOF
6368 int main(void)
6369 {
6370         ${cf_cv_main_return:-return}(0);
6371 }
6372 CF_EOF
6373 # We do the test twice because some compilers refuse to overwrite an
6374 # existing .o file with -o, though they will create one.
6375 ac_try='[$]$1 $2 -c conftest.$ac_ext -o conftest2.$ac_objext >&AC_FD_CC'
6376 if AC_TRY_EVAL(ac_try) &&
6377   test -f conftest2.$ac_objext && AC_TRY_EVAL(ac_try);
6378 then
6379   eval cf_cv_prog_$1_c_o=yes
6380 else
6381   eval cf_cv_prog_$1_c_o=no
6382 fi
6383 rm -rf ./conftest*
6384 ])dnl
6385 if test "$cf_cv_prog_$1_c_o" = yes; then
6386   AC_MSG_RESULT([yes])
6387 else
6388   AC_MSG_RESULT([no])
6389 fi
6390 ])dnl
6391 dnl ---------------------------------------------------------------------------
6392 dnl CF_PROG_GNAT version: 12 updated: 2021/01/02 17:09:14
6393 dnl ------------
6394 dnl Check for gnat/gnatmake/etc, ensure that the toolset is complete.
6395 AC_DEFUN([CF_PROG_GNAT],[
6396 for cf_prog_gnat in gnat gnatmake gprconfig gprbuild
6397 do
6398         CF_UPPER(cf_upper_prog_gnat,${cf_prog_gnat})
6399
6400         unset ac_cv_path_cf_TEMP_gnat
6401         unset cf_TEMP_gnat
6402         AC_PATH_PROG(cf_TEMP_gnat,$cf_prog_gnat,no)
6403         eval "cf_cv_PATH_$cf_upper_prog_gnat=[$]ac_cv_path_cf_TEMP_gnat"
6404
6405         if test "x$cf_TEMP_gnat" != xno; then
6406                 unset cf_cv_gnat_version
6407                 unset cf_TEMP_gnat
6408                 CF_GNAT_VERSION(cf_TEMP_gnat,$cf_prog_gnat)
6409         fi
6410         eval "cf_cv_VERSION_$cf_upper_prog_gnat=[$]cf_TEMP_gnat"
6411
6412         unset cf_TEMP_gnat
6413         unset cf_cv_gnat_version
6414         unset ac_cv_path_cf_TEMP_gnat
6415 done
6416
6417 if test "x$cf_cv_VERSION_GNATMAKE" = "xno"; then
6418         cf_ada_make=
6419         cf_cv_prog_gnat_correct=no
6420 else
6421         cf_ada_make=gnatmake
6422         if test "x$cf_cv_VERSION_GPRCONFIG" = "xno"; then
6423                 # gprconfig is newer than gnatmake; we can continue...
6424                 cf_ada_config="##"
6425         else
6426                 rm -rf ./conftest* ./*~conftest*
6427                 if mkdir conftest.src
6428                 then
6429                         cf_ada_config=""
6430                         cd conftest.src
6431                         for cf_gprconfig in Ada C
6432                         do
6433                                 AC_MSG_CHECKING(for gprconfig name for $cf_gprconfig)
6434                                 if test "$cf_gprconfig" = C
6435                                 then
6436                                         for cf_gprconfig_param in \
6437                                                 "$cf_gprconfig,,,,GNATGCC" \
6438                                                 "$cf_gprconfig,,,,GCC" \
6439                                                 "$cf_gprconfig"
6440                                         do
6441                                                 cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
6442                                                 test -n "$cf_gprconfig_value" && break
6443                                         done
6444                                 else
6445                                         cf_gprconfig_param=$cf_gprconfig
6446                                         cf_gprconfig_value=`echo s| gprconfig --config=$cf_gprconfig_param 2>&AC_FD_CC | ${AWK:-awk} '/^\*/{print [$]3;}' | head -n 1`
6447                                 fi
6448                                 if test -n "$cf_gprconfig_value"
6449                                 then
6450                                         eval "cf_ada_config_[$]cf_gprconfig=[$]cf_gprconfig_value"
6451                                         AC_MSG_RESULT($cf_gprconfig_value)
6452                                 else
6453                                         AC_MSG_RESULT(missing)
6454                                         cf_ada_config="#"
6455                                         break
6456                                 fi
6457                         done
6458                         cd ..
6459                         rm -rf ./conftest* ./*~conftest*
6460                 fi
6461         fi
6462         if test "x$cf_ada_config" != "x#"
6463         then
6464                 CF_GNAT_VERSION
6465                 CF_CHECK_GNAT_VERSION
6466                 AC_CHECK_PROG(M4_exists, m4, yes, no)
6467                 if test "$ac_cv_prog_M4_exists" = no; then
6468                         cf_cv_prog_gnat_correct=no
6469                         AC_MSG_WARN(Ada95 binding required program m4 not found. Ada95 binding disabled)
6470                 fi
6471                 if test "$cf_cv_prog_gnat_correct" = yes; then
6472                         AC_MSG_CHECKING(if GNAT works)
6473                         CF_GNAT_TRY_RUN([procedure conftest;],
6474 [with Text_IO;
6475 with GNAT.OS_Lib;
6476 procedure conftest is
6477 begin
6478    Text_IO.Put ("Hello World");
6479    Text_IO.New_Line;
6480    GNAT.OS_Lib.OS_Exit (0);
6481 end conftest;],
6482 [cf_cv_prog_gnat_correct=yes],
6483 [cf_cv_prog_gnat_correct=no])
6484                         AC_MSG_RESULT($cf_cv_prog_gnat_correct)
6485                 fi
6486         else
6487                 cf_cv_prog_gnat_correct=no
6488         fi
6489 fi
6490
6491 AC_SUBST(cf_ada_make)
6492 AC_SUBST(cf_ada_config)
6493 AC_SUBST(cf_ada_config_Ada)
6494 AC_SUBST(cf_ada_config_C)
6495 ])dnl
6496 dnl ---------------------------------------------------------------------------
6497 dnl CF_PROG_INSTALL version: 10 updated: 2021/01/04 19:33:05
6498 dnl ---------------
6499 dnl Force $INSTALL to be an absolute-path.  Otherwise, edit_man.sh and the
6500 dnl misc/tabset install won't work properly.  Usually this happens only when
6501 dnl using the fallback mkinstalldirs script
6502 AC_DEFUN([CF_PROG_INSTALL],
6503 [AC_PROG_INSTALL
6504 case $INSTALL in
6505 (/*)
6506         ;;
6507 (*)
6508         CF_DIRNAME(cf_dir,$INSTALL)
6509         test -z "$cf_dir" && cf_dir=.
6510         INSTALL="`cd \"$cf_dir\" && pwd`"/"`echo "$INSTALL" | sed -e 's%^.*/%%'`"
6511         ;;
6512 esac
6513 ])dnl
6514 dnl ---------------------------------------------------------------------------
6515 dnl CF_PROG_LDCONFIG version: 5 updated: 2015/04/18 08:56:57
6516 dnl ----------------
6517 dnl Check for ldconfig, needed to fixup shared libraries that would be built
6518 dnl and then used in the install.
6519 AC_DEFUN([CF_PROG_LDCONFIG],[
6520 if test "$cross_compiling" = yes ; then
6521         LDCONFIG=:
6522 else
6523         case "$cf_cv_system_name" in
6524         (dragonfly*|mirbsd*|freebsd*)
6525                 test -z "$LDCONFIG" && LDCONFIG="/sbin/ldconfig -R"
6526                 ;;
6527         (*) LDPATH=$PATH:/sbin:/usr/sbin
6528                 AC_PATH_PROG(LDCONFIG,ldconfig,,$LDPATH)
6529                 ;;
6530         esac
6531 fi
6532 AC_SUBST(LDCONFIG)
6533 ])dnl
6534 dnl ---------------------------------------------------------------------------
6535 dnl CF_PROG_LINT version: 4 updated: 2019/11/20 18:55:37
6536 dnl ------------
6537 AC_DEFUN([CF_PROG_LINT],
6538 [
6539 AC_CHECK_PROGS(LINT, lint cppcheck splint)
6540 case "x$LINT" in
6541 (xcppcheck|x*/cppcheck)
6542         test -z "$LINT_OPTS" && LINT_OPTS="--enable=all"
6543         ;;
6544 esac
6545 AC_SUBST(LINT_OPTS)
6546 ])dnl
6547 dnl ---------------------------------------------------------------------------
6548 dnl CF_PROG_LN_S version: 2 updated: 2010/08/14 18:25:37
6549 dnl ------------
6550 dnl Combine checks for "ln -s" and "ln -sf", updating $LN_S to include "-f"
6551 dnl option if it is supported.
6552 AC_DEFUN([CF_PROG_LN_S],[
6553 AC_PROG_LN_S
6554 AC_MSG_CHECKING(if $LN_S -f options work)
6555
6556 rm -f conf$$.src conf$$dst
6557 echo >conf$$.dst
6558 echo first >conf$$.src
6559 if $LN_S -f conf$$.src conf$$.dst 2>/dev/null; then
6560         cf_prog_ln_sf=yes
6561 else
6562         cf_prog_ln_sf=no
6563 fi
6564 rm -f conf$$.dst conf$$src
6565 AC_MSG_RESULT($cf_prog_ln_sf)
6566
6567 test "$cf_prog_ln_sf" = yes && LN_S="$LN_S -f"
6568 ])dnl
6569 dnl ---------------------------------------------------------------------------
6570 dnl CF_REGEX version: 18 updated: 2021/01/01 16:53:59
6571 dnl --------
6572 dnl Attempt to determine if we've got one of the flavors of regular-expression
6573 dnl code that we can support.
6574 AC_DEFUN([CF_REGEX],
6575 [
6576
6577 cf_regex_func=no
6578 cf_regex_libs=
6579 case "$host_os" in
6580 (mingw*)
6581         # -lsystre -ltre -lintl -liconv
6582         AC_CHECK_LIB(systre,regcomp,[
6583                 AC_CHECK_LIB(iconv,libiconv_open,[CF_ADD_LIB(iconv)])
6584                 AC_CHECK_LIB(intl,libintl_gettext,[CF_ADD_LIB(intl)])
6585                 AC_CHECK_LIB(tre,tre_regcomp,[CF_ADD_LIB(tre)])
6586                 CF_ADD_LIB(systre)
6587                 cf_regex_func=regcomp
6588         ],[
6589                 AC_CHECK_LIB(gnurx,regcomp,[
6590                         CF_ADD_LIB(gnurx)
6591                         cf_regex_func=regcomp])
6592         ])
6593         ;;
6594 (*)
6595         cf_regex_libs="regex re"
6596         AC_CHECK_FUNC(regcomp,[cf_regex_func=regcomp],[
6597                 for cf_regex_lib in $cf_regex_libs
6598                 do
6599                         AC_CHECK_LIB($cf_regex_lib,regcomp,[
6600                                         CF_ADD_LIB($cf_regex_lib)
6601                                         cf_regex_func=regcomp
6602                                         break])
6603                 done
6604         ])
6605         ;;
6606 esac
6607
6608 if test "$cf_regex_func" = no ; then
6609         AC_CHECK_FUNC(compile,[cf_regex_func=compile],[
6610                 AC_CHECK_LIB(gen,compile,[
6611                                 CF_ADD_LIB(gen)
6612                                 cf_regex_func=compile])])
6613 fi
6614
6615 if test "$cf_regex_func" = no ; then
6616         AC_MSG_WARN(cannot find regular expression library)
6617 fi
6618
6619 AC_CACHE_CHECK(for regular-expression headers,cf_cv_regex_hdrs,[
6620
6621 cf_cv_regex_hdrs=no
6622 case "$cf_regex_func" in
6623 (compile)
6624         for cf_regex_hdr in regexp.h regexpr.h
6625         do
6626                 AC_TRY_LINK([#include <$cf_regex_hdr>],[
6627                         char *p = compile("", "", "", 0);
6628                         int x = step("", "");
6629                         (void)p;
6630                         (void)x;
6631                 ],[
6632                         cf_cv_regex_hdrs=$cf_regex_hdr
6633                         break
6634                 ])
6635         done
6636         ;;
6637 (*)
6638         for cf_regex_hdr in regex.h
6639         do
6640                 AC_TRY_LINK([#include <sys/types.h>
6641 #include <$cf_regex_hdr>],[
6642                         regex_t *p = 0;
6643                         int x = regcomp(p, "", 0);
6644                         int y = regexec(p, "", 0, 0, 0);
6645                         (void)x;
6646                         (void)y;
6647                         regfree(p);
6648                 ],[
6649                         cf_cv_regex_hdrs=$cf_regex_hdr
6650                         break
6651                 ])
6652         done
6653         ;;
6654 esac
6655
6656 ])
6657
6658 case "$cf_cv_regex_hdrs" in
6659         (no)            AC_MSG_WARN(no regular expression header found) ;;
6660         (regex.h)       AC_DEFINE(HAVE_REGEX_H_FUNCS,1,[Define to 1 to include regex.h for regular expressions]) ;;
6661         (regexp.h)      AC_DEFINE(HAVE_REGEXP_H_FUNCS,1,[Define to 1 to include regexp.h for regular expressions]) ;;
6662         (regexpr.h) AC_DEFINE(HAVE_REGEXPR_H_FUNCS,1,[Define to 1 to include regexpr.h for regular expressions]) ;;
6663 esac
6664 ])dnl
6665 dnl ---------------------------------------------------------------------------
6666 dnl CF_REMOVE_DEFINE version: 3 updated: 2010/01/09 11:05:50
6667 dnl ----------------
6668 dnl Remove all -U and -D options that refer to the given symbol from a list
6669 dnl of C compiler options.  This works around the problem that not all
6670 dnl compilers process -U and -D options from left-to-right, so a -U option
6671 dnl cannot be used to cancel the effect of a preceding -D option.
6672 dnl
6673 dnl $1 = target (which could be the same as the source variable)
6674 dnl $2 = source (including '$')
6675 dnl $3 = symbol to remove
6676 define([CF_REMOVE_DEFINE],
6677 [
6678 $1=`echo "$2" | \
6679         sed     -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[[       ]]/ /g' \
6680                 -e 's/-[[UD]]'"$3"'\(=[[^       ]]*\)\?[$]//g'`
6681 ])dnl
6682 dnl ---------------------------------------------------------------------------
6683 dnl CF_REMOVE_LIB version: 1 updated: 2007/02/17 14:11:52
6684 dnl -------------
6685 dnl Remove the given library from the symbol
6686 dnl
6687 dnl $1 = target (which could be the same as the source variable)
6688 dnl $2 = source (including '$')
6689 dnl $3 = library to remove
6690 define([CF_REMOVE_LIB],
6691 [
6692 # remove $3 library from $2
6693 $1=`echo "$2" | sed -e 's/-l$3[[        ]]//g' -e 's/-l$3[$]//'`
6694 ])dnl
6695 dnl ---------------------------------------------------------------------------
6696 dnl CF_RESTORE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:47:45
6697 dnl ---------------------
6698 dnl Restore flags saved in CF_SAVE_XTRA_FLAGS
6699 dnl $1 = name of current macro
6700 define([CF_RESTORE_XTRA_FLAGS],
6701 [
6702 LIBS="$cf_save_LIBS_$1"
6703 CFLAGS="$cf_save_CFLAGS_$1"
6704 CPPFLAGS="$cf_save_CPPFLAGS_$1"
6705 ])dnl
6706 dnl ---------------------------------------------------------------------------
6707 dnl CF_RPATH_HACK version: 13 updated: 2021/01/03 18:30:50
6708 dnl -------------
6709 AC_DEFUN([CF_RPATH_HACK],
6710 [AC_REQUIRE([AC_PROG_FGREP])dnl
6711 AC_REQUIRE([CF_LD_RPATH_OPT])dnl
6712
6713 AC_MSG_CHECKING(for updated LDFLAGS)
6714 if test -n "$LD_RPATH_OPT" ; then
6715         AC_MSG_RESULT(maybe)
6716
6717         AC_CHECK_PROGS(cf_ldd_prog,ldd,no)
6718         cf_rpath_list="/usr/lib /lib"
6719         if test "$cf_ldd_prog" != no
6720         then
6721                 cf_rpath_oops=
6722
6723 AC_TRY_LINK([#include <stdio.h>],
6724                 [printf("Hello");],
6725                 [cf_rpath_oops=`"$cf_ldd_prog" "conftest$ac_exeext" | ${FGREP-fgrep} ' not found' | sed -e 's% =>.*$%%' |sort | uniq`
6726                  cf_rpath_list=`"$cf_ldd_prog" "conftest$ac_exeext" | ${FGREP-fgrep} / | sed -e 's%^.*[[        ]]/%/%' -e 's%/[[^/]][[^/]]*$%%' |sort | uniq`])
6727
6728                 # If we passed the link-test, but get a "not found" on a given library,
6729                 # this could be due to inept reconfiguration of gcc to make it only
6730                 # partly honor /usr/local/lib (or whatever).  Sometimes this behavior
6731                 # is intentional, e.g., installing gcc in /usr/bin and suppressing the
6732                 # /usr/local libraries.
6733                 if test -n "$cf_rpath_oops"
6734                 then
6735                         for cf_rpath_src in $cf_rpath_oops
6736                         do
6737                                 for cf_rpath_dir in \
6738                                         /usr/local \
6739                                         /usr/pkg \
6740                                         /opt/sfw
6741                                 do
6742                                         if test -f "$cf_rpath_dir/lib/$cf_rpath_src"
6743                                         then
6744                                                 CF_VERBOSE(...adding -L$cf_rpath_dir/lib to LDFLAGS for $cf_rpath_src)
6745                                                 LDFLAGS="$LDFLAGS -L$cf_rpath_dir/lib"
6746                                                 break
6747                                         fi
6748                                 done
6749                         done
6750                 fi
6751         fi
6752
6753         CF_VERBOSE(...checking EXTRA_LDFLAGS $EXTRA_LDFLAGS)
6754
6755         CF_RPATH_HACK_2(LDFLAGS)
6756         CF_RPATH_HACK_2(LIBS)
6757
6758         CF_VERBOSE(...checked EXTRA_LDFLAGS $EXTRA_LDFLAGS)
6759 else
6760         AC_MSG_RESULT(no)
6761 fi
6762 AC_SUBST(EXTRA_LDFLAGS)
6763 ])dnl
6764 dnl ---------------------------------------------------------------------------
6765 dnl CF_RPATH_HACK_2 version: 8 updated: 2021/01/01 13:31:04
6766 dnl ---------------
6767 dnl Do one set of substitutions for CF_RPATH_HACK, adding an rpath option to
6768 dnl EXTRA_LDFLAGS for each -L option found.
6769 dnl
6770 dnl $cf_rpath_list contains a list of directories to ignore.
6771 dnl
6772 dnl $1 = variable name to update.  The LDFLAGS variable should be the only one,
6773 dnl      but LIBS often has misplaced -L options.
6774 AC_DEFUN([CF_RPATH_HACK_2],
6775 [
6776 CF_VERBOSE(...checking $1 [$]$1)
6777
6778 cf_rpath_dst=
6779 for cf_rpath_src in [$]$1
6780 do
6781         case "$cf_rpath_src" in
6782         (-L*)
6783
6784                 # check if this refers to a directory which we will ignore
6785                 cf_rpath_skip=no
6786                 if test -n "$cf_rpath_list"
6787                 then
6788                         for cf_rpath_item in $cf_rpath_list
6789                         do
6790                                 if test "x$cf_rpath_src" = "x-L$cf_rpath_item"
6791                                 then
6792                                         cf_rpath_skip=yes
6793                                         break
6794                                 fi
6795                         done
6796                 fi
6797
6798                 if test "$cf_rpath_skip" = no
6799                 then
6800                         # transform the option
6801                         if test "$LD_RPATH_OPT" = "-R " ; then
6802                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%-R %"`
6803                         else
6804                                 cf_rpath_tmp=`echo "$cf_rpath_src" |sed -e "s%-L%$LD_RPATH_OPT%"`
6805                         fi
6806
6807                         # if we have not already added this, add it now
6808                         cf_rpath_tst=`echo "$EXTRA_LDFLAGS" | sed -e "s%$cf_rpath_tmp %%"`
6809                         if test "x$cf_rpath_tst" = "x$EXTRA_LDFLAGS"
6810                         then
6811                                 CF_VERBOSE(...Filter $cf_rpath_src ->$cf_rpath_tmp)
6812                                 EXTRA_LDFLAGS="$cf_rpath_tmp $EXTRA_LDFLAGS"
6813                         fi
6814                 fi
6815                 ;;
6816         esac
6817         cf_rpath_dst="$cf_rpath_dst $cf_rpath_src"
6818 done
6819 $1=$cf_rpath_dst
6820
6821 CF_VERBOSE(...checked $1 [$]$1)
6822 AC_SUBST(EXTRA_LDFLAGS)
6823 ])dnl
6824 dnl ---------------------------------------------------------------------------
6825 dnl CF_SAVE_XTRA_FLAGS version: 1 updated: 2020/01/11 16:46:44
6826 dnl ------------------
6827 dnl Use this macro to save CFLAGS/CPPFLAGS/LIBS before checks against X headers
6828 dnl and libraries which do not update those variables.
6829 dnl
6830 dnl $1 = name of current macro
6831 define([CF_SAVE_XTRA_FLAGS],
6832 [
6833 cf_save_LIBS_$1="$LIBS"
6834 cf_save_CFLAGS_$1="$CFLAGS"
6835 cf_save_CPPFLAGS_$1="$CPPFLAGS"
6836 LIBS="$LIBS ${X_PRE_LIBS} ${X_LIBS} ${X_EXTRA_LIBS}"
6837 for cf_X_CFLAGS in $X_CFLAGS
6838 do
6839         case "x$cf_X_CFLAGS" in
6840         x-[[IUD]]*)
6841                 CPPFLAGS="$CPPFLAGS $cf_X_CFLAGS"
6842                 ;;
6843         *)
6844                 CFLAGS="$CFLAGS $cf_X_CFLAGS"
6845                 ;;
6846         esac
6847 done
6848 ])dnl
6849 dnl ---------------------------------------------------------------------------
6850 dnl CF_SHARED_OPTS version: 105 updated: 2021/01/02 17:09:14
6851 dnl --------------
6852 dnl --------------
6853 dnl Attempt to determine the appropriate CC/LD options for creating a shared
6854 dnl library.
6855 dnl
6856 dnl Notes:
6857 dnl a) ${LOCAL_LDFLAGS} is used to link executables that will run within
6858 dnl the build-tree, i.e., by making use of the libraries that are compiled in
6859 dnl $rel_builddir/lib We avoid compiling-in a $rel_builddir/lib path for the
6860 dnl shared library since that can lead to unexpected results at runtime.
6861 dnl b) ${LOCAL_LDFLAGS2} has the same intention but assumes that the shared
6862 dnl libraries are compiled in ../../lib
6863 dnl
6864 dnl The variable 'cf_cv_do_symlinks' is used to control whether we configure
6865 dnl to install symbolic links to the rel/abi versions of shared libraries.
6866 dnl
6867 dnl The variable 'cf_cv_shlib_version' controls whether we use the rel or abi
6868 dnl version when making symbolic links.
6869 dnl
6870 dnl The variable 'cf_cv_shlib_version_infix' controls whether shared library
6871 dnl version numbers are infix (ex: libncurses.<ver>.dylib) or postfix
6872 dnl (ex: libncurses.so.<ver>).
6873 dnl
6874 dnl Some loaders leave 'so_locations' lying around.  It's nice to clean up.
6875 AC_DEFUN([CF_SHARED_OPTS],
6876 [
6877         AC_REQUIRE([CF_LD_RPATH_OPT])
6878
6879         RM_SHARED_OPTS=
6880         LOCAL_LDFLAGS=
6881         LOCAL_LDFLAGS2=
6882         LD_SHARED_OPTS=
6883         INSTALL_LIB="-m 644"
6884         : ${rel_builddir:=.}
6885
6886         shlibdir=$libdir
6887         AC_SUBST(shlibdir)
6888
6889         MAKE_DLLS="#"
6890         AC_SUBST(MAKE_DLLS)
6891
6892         cf_cv_do_symlinks=no
6893         cf_ld_rpath_opt=
6894         test "$cf_cv_enable_rpath" = yes && cf_ld_rpath_opt="$LD_RPATH_OPT"
6895
6896         AC_MSG_CHECKING(if release/abi version should be used for shared libs)
6897         AC_ARG_WITH(shlib-version,
6898         [  --with-shlib-version=X  Specify rel or abi version for shared libs],
6899         [test -z "$withval" && withval=auto
6900         case "$withval" in
6901         (yes)
6902                 cf_cv_shlib_version=auto
6903                 ;;
6904         (rel|abi|auto)
6905                 cf_cv_shlib_version=$withval
6906                 ;;
6907         (*)
6908                 AC_MSG_RESULT($withval)
6909                 AC_MSG_ERROR([option value must be one of: rel, abi, or auto])
6910                 ;;
6911         esac
6912         ],[cf_cv_shlib_version=auto])
6913         AC_MSG_RESULT($cf_cv_shlib_version)
6914
6915         cf_cv_rm_so_locs=no
6916         cf_try_cflags=
6917
6918         # Some less-capable ports of gcc support only -fpic
6919         CC_SHARED_OPTS=
6920
6921         cf_try_fPIC=no
6922         if test "$GCC" = yes
6923         then
6924                 cf_try_fPIC=yes
6925         else
6926                 case "$cf_cv_system_name" in
6927                 (*linux*)       # e.g., PGI compiler
6928                         cf_try_fPIC=yes
6929                         ;;
6930                 esac
6931         fi
6932
6933         if test "$cf_try_fPIC" = yes
6934         then
6935                 AC_MSG_CHECKING(which $CC option to use)
6936                 cf_save_CFLAGS="$CFLAGS"
6937                 for CC_SHARED_OPTS in -fPIC -fpic ''
6938                 do
6939                         CFLAGS="$cf_save_CFLAGS $CC_SHARED_OPTS"
6940                         AC_TRY_COMPILE([#include <stdio.h>],[int x = 1],[break],[])
6941                 done
6942                 AC_MSG_RESULT($CC_SHARED_OPTS)
6943                 CFLAGS="$cf_save_CFLAGS"
6944         fi
6945
6946         cf_cv_shlib_version_infix=no
6947
6948         case "$cf_cv_system_name" in
6949         (aix4.[3-9]*|aix[[5-7]]*)
6950                 if test "$GCC" = yes; then
6951                         CC_SHARED_OPTS='-Wl,-brtl'
6952                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
6953                 else
6954                         CC_SHARED_OPTS='-brtl'
6955                         # as well as '-qpic=large -G' or perhaps "-bM:SRE -bnoentry -bexpall"
6956                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -G -Wl,-brtl -Wl,-blibpath:${RPATH_LIST}:/usr/lib -o [$]@'
6957                 fi
6958                 ;;
6959         (beos*)
6960                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -o $[@] -Xlinker -soname=`basename $[@]` -nostart -e 0'
6961                 ;;
6962         (cygwin*)
6963                 CC_SHARED_OPTS=
6964                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
6965                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
6966                 cf_cv_shlib_version=cygdll
6967                 cf_cv_shlib_version_infix=cygdll
6968                 shlibdir=$bindir
6969                 MAKE_DLLS=
6970                 cat >mk_shared_lib.sh <<-CF_EOF
6971                 #!$SHELL
6972                 SHARED_LIB=\[$]1
6973                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/cyg/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
6974                 shift
6975                 cat <<-EOF
6976                 Linking shared library
6977                 ** SHARED_LIB \[$]SHARED_LIB
6978                 ** IMPORT_LIB \[$]IMPORT_LIB
6979 EOF
6980                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
6981 CF_EOF
6982                 chmod +x mk_shared_lib.sh
6983                 ;;
6984         (msys*)
6985                 CC_SHARED_OPTS=
6986                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
6987                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
6988                 cf_cv_shlib_version=msysdll
6989                 cf_cv_shlib_version_infix=msysdll
6990                 shlibdir=$bindir
6991                 MAKE_DLLS=
6992                 cat >mk_shared_lib.sh <<-CF_EOF
6993                 #!$SHELL
6994                 SHARED_LIB=\[$]1
6995                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/msys-/lib/' -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
6996                 shift
6997                 cat <<-EOF
6998                 Linking shared library
6999                 ** SHARED_LIB \[$]SHARED_LIB
7000                 ** IMPORT_LIB \[$]IMPORT_LIB
7001 EOF
7002                 exec \[$]* ${LDFLAGS} -shared -Wl,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
7003 CF_EOF
7004                 chmod +x mk_shared_lib.sh
7005                 ;;
7006         (darwin*)
7007                 cf_try_cflags="no-cpp-precomp"
7008                 CC_SHARED_OPTS="-dynamic"
7009                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dynamiclib -install_name ${libdir}/`basename $[@]` -compatibility_version ${ABI_VERSION} -current_version ${ABI_VERSION} -o $[@]'
7010                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=abi
7011                 cf_cv_shlib_version_infix=yes
7012                 AC_CACHE_CHECK([if ld -search_paths_first works], cf_cv_ldflags_search_paths_first, [
7013                         cf_save_LDFLAGS=$LDFLAGS
7014                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
7015                         AC_TRY_LINK(, [int i;], cf_cv_ldflags_search_paths_first=yes, cf_cv_ldflags_search_paths_first=no)
7016                                 LDFLAGS=$cf_save_LDFLAGS])
7017                 if test "$cf_cv_ldflags_search_paths_first" = yes; then
7018                         LDFLAGS="$LDFLAGS -Wl,-search_paths_first"
7019                 fi
7020                 ;;
7021         (hpux[[7-8]]*)
7022                 # HP-UX 8.07 ld lacks "+b" option used for libdir search-list
7023                 if test "$GCC" != yes; then
7024                         CC_SHARED_OPTS='+Z'
7025                 fi
7026                 MK_SHARED_LIB='${LD} ${LDFLAGS} -b -o $[@]'
7027                 INSTALL_LIB="-m 555"
7028                 ;;
7029         (hpux*)
7030                 # (tested with gcc 2.7.2 -- I don't have c89)
7031                 if test "$GCC" = yes; then
7032                         LD_SHARED_OPTS='-Xlinker +b -Xlinker ${libdir}'
7033                 else
7034                         CC_SHARED_OPTS='+Z'
7035                         LD_SHARED_OPTS='-Wl,+b,${libdir}'
7036                 fi
7037                 MK_SHARED_LIB='${LD} ${LDFLAGS} +b ${libdir} -b -o $[@]'
7038                 # HP-UX shared libraries must be executable, and should be
7039                 # readonly to exploit a quirk in the memory manager.
7040                 INSTALL_LIB="-m 555"
7041                 ;;
7042         (interix*)
7043                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7044                 if test "$cf_cv_shlib_version" = rel; then
7045                         cf_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
7046                 else
7047                         cf_shared_soname='`basename $[@]`'
7048                 fi
7049                 CC_SHARED_OPTS=
7050                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-rpath,${RPATH_LIST} -Wl,-h,'$cf_shared_soname' -o $[@]'
7051                 ;;
7052         (irix*)
7053                 if test "$cf_cv_enable_rpath" = yes ; then
7054                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7055                 fi
7056                 # tested with IRIX 5.2 and 'cc'.
7057                 if test "$GCC" != yes; then
7058                         CC_SHARED_OPTS='-KPIC'
7059                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -rdata_shared -soname `basename $[@]` -o $[@]'
7060                 else
7061                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,`basename $[@]` -o $[@]'
7062                 fi
7063                 cf_cv_rm_so_locs=yes
7064                 ;;
7065         (linux*|gnu*|k*bsd*-gnu)
7066                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
7067                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
7068                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7069                 fi
7070                 if test "$cf_cv_enable_rpath" = yes ; then
7071                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7072                 fi
7073                 CF_SHARED_SONAME
7074                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7075                 ;;
7076         (mingw*msvc*)
7077                 cf_cv_shlib_version=msvcdll
7078                 cf_cv_shlib_version_infix=msvcdll
7079                 shlibdir=$bindir
7080                 MAKE_DLLS=
7081                 if test "$DFT_LWR_MODEL" = "shared" ; then
7082                         LOCAL_LDFLAGS="-link -dll"
7083                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7084                         EXTRA_LDFLAGS="-link -dll $EXTRA_LDFLAGS"
7085                 fi
7086                 CC_SHARED_OPTS=
7087                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ ${LD} [$]{CFLAGS}'
7088                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.lib"
7089                 cat >mk_shared_lib.sh <<-CF_EOF
7090                 #!$SHELL
7091                 SHARED_LIB=\[$]1
7092                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.lib/'\`
7093                 shift
7094                 my_ld=\[$]1
7095                 shift
7096                 cat <<-EOF
7097                 Linking shared library
7098                 ** SHARED LIB \$SHARED_LIB
7099                 ** IMPORT_LIB \$IMPORT_LIB
7100 EOF
7101                 args=\$(echo \[$]* | sed -E "s#-l(\w*)#\1.dll.lib#g" | sed -E "s#-L(\w*)#-LIBPATH:\1#g")
7102                 exec \$my_ld -DLL -IMPLIB:"\${IMPORT_LIB}" -OUT:"\${SHARED_LIB}" ${LDFLAGS} \$args
7103                 mv "\${IMPORT_LIB}" "\${IMPORT_LIB}"
7104 CF_EOF
7105                 chmod +x mk_shared_lib.sh
7106                 cat >mk_prog.sh <<-CF_EOF
7107                 #!$SHELL
7108                 shift
7109                 # Ignore first argument (compiler) and use LD (link.exe) unconditionally
7110                 LD="[$]LD"
7111                 clopts=()
7112                 ldopts=("/subsystem:console")
7113                 libs=()
7114                 isdll=0
7115                 while test \[$]# -gt 0; do
7116                         case "\[$]1" in
7117                                 -link)
7118                                         # ignore -link argument
7119                                         ;;
7120                                 -M[[TD]] | -M[[TD]]d)
7121                                         # ignore runtime-library option
7122                                         ;;
7123                                 -dll)
7124                                         isdll=1
7125                                         ;;
7126                                 -W* | -w*)
7127                                         # ignore warnings
7128                                         ;;
7129                                 -D*)
7130                                         clopts+=("\[$]1")
7131                                         ;;
7132                                 -I*)
7133                                         clopts+=("\[$]1")
7134                                         ;;
7135                                 -l*)
7136                                         libs+=("\`echo \"\[$]1\" | sed \"s/^-l//\"\`")
7137                                         ;;
7138                                 -L*)
7139                                         ldopts+=("\`echo \"\[$]1\" | sed \"s/^-L/-LIBPATH:/\"\`")
7140                                         ;;
7141                                 *.obj | *.o)
7142                                         ldopts+=("\[$]1")
7143                                         ;;
7144                                 -Wl,*)
7145                                         for linkarg in \`echo '\[$]1' | sed -e 's/-Wl,//' -e 's/,/ /'\`; do
7146                                                 ldopts+=("\[$]{linkarg}")
7147                                         done
7148                                         ;;
7149                                 *.lib)
7150                                         ldopts+=("\[$]1")
7151                                         ;;
7152                                 -o)
7153                                         shift
7154                                         ldopts+=("-out:\[$]1")
7155                                         ;;
7156                                 *)
7157                                         clopts+=("\[$]1")
7158                                         ldopts+=("\[$]1")
7159                                         ;;
7160                         esac
7161                         shift
7162                 done
7163                 if [[ "\$isdll" -ne 0 ]]; then
7164                         for lib in \[$]{libs[[*]]}; do
7165                                 ldopts+=("\[$]lib.dll.lib")
7166                         done
7167                 else
7168                         for lib in \[$]{libs[[*]]}; do
7169                                 ldopts+=("\[$]lib.lib")
7170                         done
7171                 fi
7172                 cat <<-EOF
7173                 Creating program
7174                 ** ld options:   "\[$]{ldopts[[@]]}"
7175 EOF
7176                 exec \[$]LD \[$]{ldopts[[@]]}
7177 CF_EOF
7178                 chmod +x mk_prog.sh
7179                 LINK_PROGS="$SHELL ${rel_builddir}/mk_prog.sh"
7180                 LINK_TESTS="$SHELL ${rel_builddir}/mk_prog.sh"
7181                 ;;
7182         (mingw*)
7183                 cf_cv_shlib_version=mingw
7184                 cf_cv_shlib_version_infix=mingw
7185                 shlibdir=$bindir
7186                 MAKE_DLLS=
7187                 if test "$DFT_LWR_MODEL" = "shared" ; then
7188                         LOCAL_LDFLAGS="-Wl,--enable-auto-import"
7189                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7190                         EXTRA_LDFLAGS="-Wl,--enable-auto-import $EXTRA_LDFLAGS"
7191                 fi
7192                 CC_SHARED_OPTS=
7193                 MK_SHARED_LIB=$SHELL' '$rel_builddir'/mk_shared_lib.sh [$]@ [$]{CC} [$]{CFLAGS}'
7194                 RM_SHARED_OPTS="$RM_SHARED_OPTS $rel_builddir/mk_shared_lib.sh *.dll.a"
7195                 cat >mk_shared_lib.sh <<-CF_EOF
7196                 #!$SHELL
7197                 SHARED_LIB=\[$]1
7198                 IMPORT_LIB=\`echo "\[$]1" | sed -e 's/[[0-9]]*\.dll[$]/.dll.a/'\`
7199                 shift
7200                 cat <<-EOF
7201                 Linking shared library
7202                 ** SHARED_LIB \[$]SHARED_LIB
7203                 ** IMPORT_LIB \[$]IMPORT_LIB
7204 EOF
7205                 exec \[$]* ${LDFLAGS} -shared -Wl,--enable-auto-import,--out-implib=\[$]{IMPORT_LIB} -Wl,--export-all-symbols -o \[$]{SHARED_LIB}
7206 CF_EOF
7207                 chmod +x mk_shared_lib.sh
7208                 ;;
7209         (openbsd[[2-9]].*|mirbsd*)
7210                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
7211                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
7212                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7213                 fi
7214                 if test "$cf_cv_enable_rpath" = yes ; then
7215                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7216                 fi
7217                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7218                 CF_SHARED_SONAME
7219                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-Bshareable,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7220                 ;;
7221         (nskJ*)
7222                 CC_SHARED_OPTS=
7223                 MK_SHARED_LIB='${LD} -Wshared -Weld=-export_all -o $[@]'
7224                 ;;
7225         (nskL*)
7226                 CC_SHARED_OPTS=
7227                 MK_SHARED_LIB='${LD} -Wshared -Wxld=-export_all -o $[@]'
7228                 ;;
7229         (nto-qnx*|openbsd*|freebsd[[12]].*)
7230                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7231                 MK_SHARED_LIB='${LD} ${LDFLAGS} -Bshareable -o $[@]'
7232                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7233                 ;;
7234         (dragonfly*|freebsd*)
7235                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7236                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
7237                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
7238                         LOCAL_LDFLAGS2="${cf_ld_rpath_opt}\${RPATH_LIST} $LOCAL_LDFLAGS"
7239                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7240                 fi
7241                 CF_SHARED_SONAME
7242                 MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname',-stats,-lc -o $[@]'
7243                 ;;
7244         (netbsd*)
7245                 CC_SHARED_OPTS="$CC_SHARED_OPTS -DPIC"
7246                 if test "$DFT_LWR_MODEL" = "shared" && test "$cf_cv_enable_rpath" = yes ; then
7247                         LOCAL_LDFLAGS="${cf_ld_rpath_opt}\$(LOCAL_LIBDIR)"
7248                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7249                         EXTRA_LDFLAGS="${cf_ld_rpath_opt}\${RPATH_LIST} $EXTRA_LDFLAGS"
7250                         if test "$cf_cv_shlib_version" = auto; then
7251                         if test -f /usr/libexec/ld.elf_so; then
7252                                 cf_cv_shlib_version=abi
7253                         else
7254                                 cf_cv_shlib_version=rel
7255                         fi
7256                         fi
7257                         CF_SHARED_SONAME
7258                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -Wl,-soname,'$cf_cv_shared_soname' -o $[@]'
7259                 else
7260                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -o $[@]'
7261                 fi
7262                 ;;
7263         (osf*|mls+*)
7264                 # tested with OSF/1 V3.2 and 'cc'
7265                 # tested with OSF/1 V3.2 and gcc 2.6.3 (but the c++ demo didn't
7266                 # link with shared libs).
7267                 MK_SHARED_LIB='${LD} ${LDFLAGS} -set_version ${REL_VERSION}:${ABI_VERSION} -expect_unresolved "*" -shared -soname `basename $[@]`'
7268                 case "$host_os" in
7269                 (osf4*)
7270                         MK_SHARED_LIB="${MK_SHARED_LIB} -msym"
7271                         ;;
7272                 esac
7273                 MK_SHARED_LIB="${MK_SHARED_LIB}"' -o $[@]'
7274                 if test "$DFT_LWR_MODEL" = "shared" && test -n "$LD_RPATH_OPT" ; then
7275                         LOCAL_LDFLAGS="${LD_RPATH_OPT}\$(LOCAL_LIBDIR)"
7276                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7277                 fi
7278                 cf_cv_rm_so_locs=yes
7279                 ;;
7280         (sco3.2v5*)  # also uw2* and UW7: hops 13-Apr-98
7281                 # tested with osr5.0.5
7282                 if test "$GCC" != yes; then
7283                         CC_SHARED_OPTS='-belf -KPIC'
7284                 fi
7285                 MK_SHARED_LIB='${LD} ${LDFLAGS} -dy -G -h `basename $[@] .${REL_VERSION}`.${ABI_VERSION} -o [$]@'
7286                 if test "$cf_cv_enable_rpath" = yes ; then
7287                         # only way is to set LD_RUN_PATH but no switch for it
7288                         RUN_PATH=$libdir
7289                 fi
7290                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7291                 LINK_PROGS='LD_RUN_PATH=${libdir}'
7292                 LINK_TESTS='Pwd=`pwd`;LD_RUN_PATH=`dirname $${Pwd}`/lib'
7293                 ;;
7294         (sunos4*)
7295                 # tested with SunOS 4.1.1 and gcc 2.7.0
7296                 if test "$GCC" != yes; then
7297                         CC_SHARED_OPTS='-KPIC'
7298                 fi
7299                 MK_SHARED_LIB='${LD} ${LDFLAGS} -assert pure-text -o $[@]'
7300                 test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=rel
7301                 ;;
7302         (solaris2*)
7303                 # tested with SunOS 5.5.1 (solaris 2.5.1) and gcc 2.7.2
7304                 # tested with SunOS 5.10 (solaris 10) and gcc 3.4.3
7305                 if test "$DFT_LWR_MODEL" = "shared" ; then
7306                         LOCAL_LDFLAGS="-R \$(LOCAL_LIBDIR):\${libdir}"
7307                         LOCAL_LDFLAGS2="$LOCAL_LDFLAGS"
7308                 fi
7309                 if test "$cf_cv_enable_rpath" = yes ; then
7310                         EXTRA_LDFLAGS="-R \${libdir} $EXTRA_LDFLAGS"
7311                 fi
7312                 CF_SHARED_SONAME
7313                 if test "$GCC" != yes; then
7314                         cf_save_CFLAGS="$CFLAGS"
7315                         for cf_shared_opts in -xcode=pic32 -xcode=pic13 -KPIC -Kpic -O
7316                         do
7317                                 CFLAGS="$cf_shared_opts $cf_save_CFLAGS"
7318                                 AC_TRY_COMPILE([#include <stdio.h>],[printf("Hello\\n");],[break])
7319                         done
7320                         CFLAGS="$cf_save_CFLAGS"
7321                         CC_SHARED_OPTS=$cf_shared_opts
7322                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -dy -G -h '$cf_cv_shared_soname' -o $[@]'
7323                 else
7324                         MK_SHARED_LIB='${CC} ${LDFLAGS} ${CFLAGS} -shared -dy -G -h '$cf_cv_shared_soname' -o $[@]'
7325                 fi
7326                 ;;
7327         (sysv5uw7*|unix_sv*)
7328                 # tested with UnixWare 7.1.0 (gcc 2.95.2 and cc)
7329                 if test "$GCC" != yes; then
7330                         CC_SHARED_OPTS='-KPIC'
7331                 fi
7332                 MK_SHARED_LIB='${LD} ${LDFLAGS} -d y -G -o [$]@'
7333                 ;;
7334         (*)
7335                 CC_SHARED_OPTS='unknown'
7336                 MK_SHARED_LIB='echo unknown'
7337                 ;;
7338         esac
7339
7340         # This works if the last tokens in $MK_SHARED_LIB are the -o target.
7341         case "$cf_cv_shlib_version" in
7342         (rel|abi)
7343                 case "$MK_SHARED_LIB" in
7344                 (*'-o $[@]')
7345                         test "$cf_cv_do_symlinks" = no && cf_cv_do_symlinks=yes
7346                         ;;
7347                 (*)
7348                         AC_MSG_WARN(ignored --with-shlib-version)
7349                         ;;
7350                 esac
7351                 ;;
7352         esac
7353
7354         if test -n "$cf_try_cflags"
7355         then
7356 cat > conftest.$ac_ext <<EOF
7357 #line __oline__ "${as_me:-configure}"
7358 #include <stdio.h>
7359 int main(int argc, char *argv[[]])
7360 {
7361         printf("hello\\n");
7362         return (argv[[argc-1]] == 0) ;
7363 }
7364 EOF
7365                 cf_save_CFLAGS="$CFLAGS"
7366                 for cf_opt in $cf_try_cflags
7367                 do
7368                         CFLAGS="$cf_save_CFLAGS -$cf_opt"
7369                         AC_MSG_CHECKING(if CFLAGS option -$cf_opt works)
7370                         if AC_TRY_EVAL(ac_compile); then
7371                                 AC_MSG_RESULT(yes)
7372                                 cf_save_CFLAGS="$CFLAGS"
7373                         else
7374                                 AC_MSG_RESULT(no)
7375                         fi
7376                 done
7377                 CFLAGS="$cf_save_CFLAGS"
7378         fi
7379
7380
7381         # RPATH_LIST is a colon-separated list of directories
7382         test -n "$cf_ld_rpath_opt" && MK_SHARED_LIB="$MK_SHARED_LIB $cf_ld_rpath_opt\${RPATH_LIST}"
7383         test -z "$RPATH_LIST" && RPATH_LIST="\${libdir}"
7384
7385         test "$cf_cv_rm_so_locs" = yes && RM_SHARED_OPTS="$RM_SHARED_OPTS so_locations"
7386
7387         CF_VERBOSE(CC_SHARED_OPTS: $CC_SHARED_OPTS)
7388         CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
7389
7390         AC_SUBST(CC_SHARED_OPTS)
7391         AC_SUBST(LD_RPATH_OPT)
7392         AC_SUBST(LD_SHARED_OPTS)
7393         AC_SUBST(MK_SHARED_LIB)
7394         AC_SUBST(RM_SHARED_OPTS)
7395
7396         AC_SUBST(LINK_PROGS)
7397         AC_SUBST(LINK_TESTS)
7398
7399         AC_SUBST(EXTRA_LDFLAGS)
7400         AC_SUBST(LOCAL_LDFLAGS)
7401         AC_SUBST(LOCAL_LDFLAGS2)
7402
7403         AC_SUBST(INSTALL_LIB)
7404         AC_SUBST(RPATH_LIST)
7405 ])dnl
7406 dnl ---------------------------------------------------------------------------
7407 dnl CF_SHARED_SONAME version: 3 updated: 2008/09/08 18:34:43
7408 dnl ----------------
7409 dnl utility macro for CF_SHARED_OPTS, constructs "$cf_cv_shared_soname" for
7410 dnl substitution into MK_SHARED_LIB string for the "-soname" (or similar)
7411 dnl option.
7412 dnl
7413 dnl $1 is the default that should be used for "$cf_cv_shlib_version".
7414 dnl If missing, use "rel".
7415 define([CF_SHARED_SONAME],
7416 [
7417         test "$cf_cv_shlib_version" = auto && cf_cv_shlib_version=ifelse($1,,rel,$1)
7418         if test "$cf_cv_shlib_version" = rel; then
7419                 cf_cv_shared_soname='`basename $[@] .${REL_VERSION}`.${ABI_VERSION}'
7420         else
7421                 cf_cv_shared_soname='`basename $[@]`'
7422         fi
7423 ])
7424 dnl ---------------------------------------------------------------------------
7425 dnl CF_SIGWINCH version: 6 updated: 2021/01/01 13:31:04
7426 dnl -----------
7427 dnl Use this macro after CF_XOPEN_SOURCE, but do not require it (not all
7428 dnl programs need this test).
7429 dnl
7430 dnl This is really a Mac OS X 10.4.3 workaround.  Defining _POSIX_C_SOURCE
7431 dnl forces SIGWINCH to be undefined (breaks xterm, ncurses).  Oddly, the struct
7432 dnl winsize declaration is left alone - we may revisit this if Apple choose to
7433 dnl break that part of the interface as well.
7434 AC_DEFUN([CF_SIGWINCH],
7435 [
7436 AC_CACHE_CHECK(if SIGWINCH is defined,cf_cv_define_sigwinch,[
7437         AC_TRY_COMPILE([
7438 #include <sys/types.h>
7439 #include <sys/signal.h>
7440 ],[int x = SIGWINCH; (void)x],
7441         [cf_cv_define_sigwinch=yes],
7442         [AC_TRY_COMPILE([
7443 #undef _XOPEN_SOURCE
7444 #undef _POSIX_SOURCE
7445 #undef _POSIX_C_SOURCE
7446 #include <sys/types.h>
7447 #include <sys/signal.h>
7448 ],[int x = SIGWINCH; (void)x],
7449         [cf_cv_define_sigwinch=maybe],
7450         [cf_cv_define_sigwinch=no])
7451 ])
7452 ])
7453
7454 if test "$cf_cv_define_sigwinch" = maybe ; then
7455 AC_CACHE_CHECK(for actual SIGWINCH definition,cf_cv_fixup_sigwinch,[
7456 cf_cv_fixup_sigwinch=unknown
7457 cf_sigwinch=32
7458 while test "$cf_sigwinch" != 1
7459 do
7460         AC_TRY_COMPILE([
7461 #undef _XOPEN_SOURCE
7462 #undef _POSIX_SOURCE
7463 #undef _POSIX_C_SOURCE
7464 #include <sys/types.h>
7465 #include <sys/signal.h>
7466 ],[
7467 #if SIGWINCH != $cf_sigwinch
7468 make an error
7469 #endif
7470 int x = SIGWINCH; (void)x],
7471         [cf_cv_fixup_sigwinch=$cf_sigwinch
7472          break])
7473
7474 cf_sigwinch="`expr "$cf_sigwinch" - 1`"
7475 done
7476 ])
7477
7478         if test "$cf_cv_fixup_sigwinch" != unknown ; then
7479                 CPPFLAGS="$CPPFLAGS -DSIGWINCH=$cf_cv_fixup_sigwinch"
7480         fi
7481 fi
7482 ])dnl
7483 dnl ---------------------------------------------------------------------------
7484 dnl CF_SIG_ATOMIC_T version: 5 updated: 2020/03/10 18:53:47
7485 dnl ---------------
7486 dnl signal handler, but there are some gcc dependencies in that recommendation.
7487 dnl Try anyway.
7488 AC_DEFUN([CF_SIG_ATOMIC_T],
7489 [
7490 AC_MSG_CHECKING(for signal global datatype)
7491 AC_CACHE_VAL(cf_cv_sig_atomic_t,[
7492         for cf_type in \
7493                 "volatile sig_atomic_t" \
7494                 "sig_atomic_t" \
7495                 "int"
7496         do
7497         AC_TRY_COMPILE([
7498 #include <sys/types.h>
7499 #include <signal.h>
7500 #include <stdio.h>
7501
7502 extern $cf_type x;
7503 $cf_type x;
7504 static void handler(int sig)
7505 {
7506         (void)sig;
7507         x = 5;
7508 }],
7509                 [signal(SIGINT, handler);
7510                  x = 1],
7511                 [cf_cv_sig_atomic_t=$cf_type],
7512                 [cf_cv_sig_atomic_t=no])
7513                 test "$cf_cv_sig_atomic_t" != no && break
7514         done
7515         ])
7516 AC_MSG_RESULT($cf_cv_sig_atomic_t)
7517 test "$cf_cv_sig_atomic_t" != no && AC_DEFINE_UNQUOTED(SIG_ATOMIC_T, $cf_cv_sig_atomic_t,[Define to signal global datatype])
7518 ])dnl
7519 dnl ---------------------------------------------------------------------------
7520 dnl CF_SIZECHANGE version: 17 updated: 2021/01/01 13:31:04
7521 dnl -------------
7522 dnl Check for definitions & structures needed for window size-changing
7523 dnl
7524 dnl https://stackoverflow.com/questions/18878141/difference-between-structures-ttysize-and-winsize/50769952#50769952
7525 AC_DEFUN([CF_SIZECHANGE],
7526 [
7527 AC_REQUIRE([CF_STRUCT_TERMIOS])
7528 AC_CACHE_CHECK(declaration of size-change, cf_cv_sizechange,[
7529         cf_cv_sizechange=unknown
7530         cf_save_CPPFLAGS="$CPPFLAGS"
7531
7532 for cf_opts in "" "NEED_PTEM_H"
7533 do
7534
7535         CPPFLAGS="$cf_save_CPPFLAGS"
7536         if test -n "$cf_opts"
7537         then
7538                 CF_APPEND_TEXT(CPPFLAGS,-D$cf_opts)
7539         fi
7540         AC_TRY_COMPILE([#include <sys/types.h>
7541 #ifdef HAVE_TERMIOS_H
7542 #include <termios.h>
7543 #else
7544 #ifdef HAVE_TERMIO_H
7545 #include <termio.h>
7546 #endif
7547 #endif
7548
7549 #ifdef NEED_PTEM_H
7550 /* This is a workaround for SCO:  they neglected to define struct winsize in
7551  * termios.h -- it's only in termio.h and ptem.h
7552  */
7553 #include <sys/stream.h>
7554 #include <sys/ptem.h>
7555 #endif
7556
7557 #ifdef HAVE_SYS_IOCTL_H
7558 #include <sys/ioctl.h>
7559 #endif
7560 ],[
7561 #ifdef TIOCGSIZE
7562         struct ttysize win;     /* SunOS 3.0... */
7563         int y = win.ts_lines = 2;
7564         int x = win.ts_cols = 1;
7565         (void)y;
7566         (void)x;
7567 #else
7568 #ifdef TIOCGWINSZ
7569         struct winsize win;     /* everything else */
7570         int y = win.ws_row = 2;
7571         int x = win.ws_col = 1;
7572         (void)y;
7573         (void)x;
7574 #else
7575         no TIOCGSIZE or TIOCGWINSZ
7576 #endif /* TIOCGWINSZ */
7577 #endif /* TIOCGSIZE */
7578         ],
7579         [cf_cv_sizechange=yes],
7580         [cf_cv_sizechange=no])
7581
7582         CPPFLAGS="$cf_save_CPPFLAGS"
7583         if test "$cf_cv_sizechange" = yes ; then
7584                 echo "size-change succeeded ($cf_opts)" >&AC_FD_CC
7585                 test -n "$cf_opts" && cf_cv_sizechange="$cf_opts"
7586                 break
7587         fi
7588 done
7589 ])
7590 if test "$cf_cv_sizechange" != no ; then
7591         AC_DEFINE(HAVE_SIZECHANGE,1,[Define to 1 if sizechange declarations are provided])
7592         case "$cf_cv_sizechange" in
7593         (NEED*)
7594                 AC_DEFINE_UNQUOTED($cf_cv_sizechange )
7595                 ;;
7596         esac
7597 fi
7598 ])dnl
7599 dnl ---------------------------------------------------------------------------
7600 dnl CF_SRC_MODULES version: 33 updated: 2021/01/01 13:31:04
7601 dnl --------------
7602 dnl For each parameter, test if the source-directory exists, and if it contains
7603 dnl a 'modules' file.  If so, add to the list $cf_cv_src_modules which we'll
7604 dnl use in CF_LIB_RULES.
7605 dnl
7606 dnl This uses the configured value to make the lists SRC_SUBDIRS and
7607 dnl SUB_MAKEFILES which are used in the makefile-generation scheme.
7608 AC_DEFUN([CF_SRC_MODULES],
7609 [
7610 AC_REQUIRE([CF_CHECK_GNAT_VERSION])
7611 AC_MSG_CHECKING(for src modules)
7612
7613 # dependencies and linker-arguments for test-programs
7614 TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEPS"
7615 TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${LIB_NAME}${DFT_DEP_SUFFIX} $TEST_DEP2"
7616 if test "$DFT_LWR_MODEL" = "libtool"; then
7617         TEST_ARGS="${TEST_DEPS}"
7618         TEST_ARG2="${TEST_DEP2}"
7619 else
7620         TEST_ARGS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
7621         TEST_ARG2="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARG2"
7622 fi
7623
7624 PC_MODULES_TO_MAKE="ncurses${USE_ARG_SUFFIX}"
7625 cf_cv_src_modules=
7626 for cf_dir in $1
7627 do
7628         if test -f "$srcdir/$cf_dir/modules" ; then
7629
7630                 # We may/may not have tack in the distribution, though the
7631                 # makefile is.
7632                 if test "$cf_dir" = tack ; then
7633                         if test "x$cf_with_tack" != "xyes"; then
7634                                 continue
7635                         fi
7636                 fi
7637
7638                 if test -z "$cf_cv_src_modules"; then
7639                         cf_cv_src_modules=$cf_dir
7640                 else
7641                         cf_cv_src_modules="$cf_cv_src_modules $cf_dir"
7642                 fi
7643
7644                 # Make the ncurses_cfg.h file record the library interface files as
7645                 # well.  These are header files that are the same name as their
7646                 # directory.  Ncurses is the only library that does not follow
7647                 # that pattern.
7648                 if test "$cf_dir" = tack ; then
7649                         continue
7650                 elif test -f "$srcdir/${cf_dir}/${cf_dir}.h" ; then
7651                         CF_UPPER(cf_have_include,$cf_dir)
7652                         AC_DEFINE_UNQUOTED(HAVE_${cf_have_include}_H)
7653                         AC_DEFINE_UNQUOTED(HAVE_LIB${cf_have_include})
7654                         CF_MAP_LIB_BASENAME(TEST_ROOT,$cf_dir)
7655                         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TEST_ROOT}${DFT_DEP_SUFFIX} $TEST_DEPS"
7656                         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TEST_ROOT}${DFT_DEP_SUFFIX} $TEST_DEP2"
7657                         if test "$DFT_LWR_MODEL" = "libtool"; then
7658                                 TEST_ARGS="${TEST_DEPS}"
7659                                 TEST_ARG2="${TEST_DEP2}"
7660                         else
7661                                 TEST_ARGS="-l${TEST_ROOT}${USE_ARG_SUFFIX} $TEST_ARGS"
7662                                 TEST_ARG2="-l${TEST_ROOT}${USE_ARG_SUFFIX} $TEST_ARG2"
7663                         fi
7664                         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ${cf_dir}${USE_ARG_SUFFIX}"
7665                 fi
7666         fi
7667 done
7668 AC_MSG_RESULT($cf_cv_src_modules)
7669
7670 TEST_ARGS="-L${LIB_DIR} $TEST_ARGS"
7671 TEST_ARG2="-L${LIB_2ND} $TEST_ARG2"
7672
7673 AC_SUBST(TEST_ARGS)
7674 AC_SUBST(TEST_DEPS)
7675
7676 AC_SUBST(TEST_ARG2)
7677 AC_SUBST(TEST_DEP2)
7678
7679 SRC_SUBDIRS=
7680 if test "x$cf_with_manpages" != xno ; then
7681         SRC_SUBDIRS="$SRC_SUBDIRS man"
7682 fi
7683 SRC_SUBDIRS="$SRC_SUBDIRS include"
7684 for cf_dir in $cf_cv_src_modules
7685 do
7686         SRC_SUBDIRS="$SRC_SUBDIRS $cf_dir"
7687 done
7688 if test "x$cf_with_tests" != "xno" ; then
7689         SRC_SUBDIRS="$SRC_SUBDIRS test"
7690 fi
7691 # always make this, to install the ncurses-config script
7692 SRC_SUBDIRS="$SRC_SUBDIRS misc"
7693 if test "$cf_with_cxx_binding" != no; then
7694         PC_MODULES_TO_MAKE="${PC_MODULES_TO_MAKE} ncurses++${USE_ARG_SUFFIX}"
7695         SRC_SUBDIRS="$SRC_SUBDIRS c++"
7696 fi
7697
7698 test "x$with_termlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TINFO_ARG_SUFFIX"
7699 test "x$with_ticlib" != xno && PC_MODULES_TO_MAKE="$PC_MODULES_TO_MAKE $TICS_ARG_SUFFIX"
7700
7701 AC_SUBST(PC_MODULES_TO_MAKE)
7702
7703 ADA_SUBDIRS=
7704 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = xyes && test -f "$srcdir/Ada95/Makefile.in" ; then
7705         SRC_SUBDIRS="$SRC_SUBDIRS Ada95"
7706         ADA_SUBDIRS="gen src"
7707         if test "x$cf_with_tests" != "xno" ; then
7708                 ADA_SUBDIRS="$ADA_SUBDIRS samples"
7709         fi
7710 fi
7711
7712 SUB_MAKEFILES=
7713 for cf_dir in $SRC_SUBDIRS
7714 do
7715         SUB_MAKEFILES="$SUB_MAKEFILES $cf_dir/Makefile"
7716 done
7717
7718 if test -n "$ADA_SUBDIRS"; then
7719         for cf_dir in $ADA_SUBDIRS
7720         do
7721                 SUB_MAKEFILES="$SUB_MAKEFILES Ada95/$cf_dir/Makefile"
7722         done
7723         AC_SUBST(ADA_SUBDIRS)
7724 fi
7725 ])dnl
7726 dnl ---------------------------------------------------------------------------
7727 dnl CF_STDCPP_LIBRARY version: 12 updated: 2021/01/01 13:31:04
7728 dnl -----------------
7729 dnl Check for -lstdc++, which is GNU's standard C++ library.
7730 dnl If $CXXLIBS is set, add that to the libraries used for test-linking.
7731 dnl If -lstdc++ was not already added to $LIBS or $CXXLIBS, and is needed,
7732 dnl add it to $CXXLIBS.
7733 AC_DEFUN([CF_STDCPP_LIBRARY],
7734 [
7735 if test -n "$GXX" ; then
7736
7737         cf_save="$LIBS"
7738         LIBS="$LIBS $CXXLIBS"
7739         AC_MSG_CHECKING(if we already have C++ library)
7740         AC_TRY_LINK([
7741                         #include <iostream>],[
7742                         std::cout << "Hello World!" << std::endl;],
7743                 [cf_have_libstdcpp=yes],
7744                 [cf_have_libstdcpp=no])
7745         AC_MSG_RESULT($cf_have_libstdcpp)
7746         LIBS="$cf_save"
7747
7748         if test "$cf_have_libstdcpp" != yes
7749         then
7750                 case "$cf_cv_system_name" in
7751                 (os2*)
7752                         if test -z "`g++ -dM -E - < /dev/null | grep __KLIBC__`"; then
7753                                 cf_stdcpp_libname=stdcpp
7754                         else
7755                                 cf_stdcpp_libname=stdc++
7756                         fi
7757                         ;;
7758                 (*)
7759                         cf_stdcpp_libname=stdc++
7760                         ;;
7761                 esac
7762
7763                 AC_CACHE_CHECK(for library $cf_stdcpp_libname,cf_cv_libstdcpp,[
7764                         cf_save="$LIBS"
7765                         LIBS="$LIBS $CXXLIBS"
7766                         CF_ADD_LIB($cf_stdcpp_libname)
7767                 AC_TRY_LINK([
7768                                 #include <iostream>],[
7769                                 std::cout << "Hello World!" << std::endl;],
7770                         [cf_cv_libstdcpp=yes],
7771                         [cf_cv_libstdcpp=no])
7772                         LIBS="$cf_save"
7773                 ])
7774                 test "$cf_cv_libstdcpp" = yes && { CF_ADD_LIB($cf_stdcpp_libname,CXXLIBS) }
7775         fi
7776 fi
7777 ])dnl
7778 dnl ---------------------------------------------------------------------------
7779 dnl CF_STRIP_G_OPT version: 4 updated: 2021/01/02 09:31:20
7780 dnl --------------
7781 dnl     Remove "-g" option from the compiler options
7782 AC_DEFUN([CF_STRIP_G_OPT],
7783 [$1=`echo "${$1}" | CF__SED_TRIMBLANKS(-e 's%-g %%' -e 's%-g$%%')`])dnl
7784 dnl ---------------------------------------------------------------------------
7785 dnl CF_STRUCT_SIGACTION version: 5 updated: 2012/10/06 17:56:13
7786 dnl -------------------
7787 dnl Check if we need _POSIX_SOURCE defined to use struct sigaction.  We'll only
7788 dnl do this if we've found the sigaction function.
7789 AC_DEFUN([CF_STRUCT_SIGACTION],[
7790 AC_REQUIRE([CF_XOPEN_SOURCE])
7791
7792 if test "$ac_cv_func_sigaction" = yes; then
7793 AC_MSG_CHECKING(whether sigaction needs _POSIX_SOURCE)
7794 AC_TRY_COMPILE([
7795 #include <sys/types.h>
7796 #include <signal.h>],
7797         [struct sigaction act],
7798         [sigact_bad=no],
7799         [
7800 AC_TRY_COMPILE([
7801 #define _POSIX_SOURCE
7802 #include <sys/types.h>
7803 #include <signal.h>],
7804         [struct sigaction act],
7805         [sigact_bad=yes
7806          AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE])],
7807          [sigact_bad=unknown])])
7808 AC_MSG_RESULT($sigact_bad)
7809 fi
7810 ])dnl
7811 dnl ---------------------------------------------------------------------------
7812 dnl CF_STRUCT_TERMIOS version: 11 updated: 2020/03/19 20:46:13
7813 dnl -----------------
7814 dnl Some machines require _POSIX_SOURCE to completely define struct termios.
7815 AC_DEFUN([CF_STRUCT_TERMIOS],[
7816 AC_REQUIRE([CF_XOPEN_SOURCE])
7817
7818 AC_CHECK_HEADERS( \
7819 termio.h \
7820 termios.h \
7821 unistd.h \
7822 sys/ioctl.h \
7823 sys/termio.h \
7824 )
7825
7826 if test "$ac_cv_header_termios_h" = yes ; then
7827         case "$CFLAGS $CPPFLAGS" in
7828         (*-D_POSIX_SOURCE*)
7829                 termios_bad=dunno ;;
7830         (*)     termios_bad=maybe ;;
7831         esac
7832         if test "$termios_bad" = maybe ; then
7833         AC_MSG_CHECKING(whether termios.h needs _POSIX_SOURCE)
7834         AC_TRY_COMPILE([#include <termios.h>],
7835                 [struct termios foo; int x = foo.c_iflag = 1; (void)x],
7836                 termios_bad=no, [
7837                 AC_TRY_COMPILE([
7838 #define _POSIX_SOURCE
7839 #include <termios.h>],
7840                         [struct termios foo; int x = foo.c_iflag = 2; (void)x],
7841                         termios_bad=unknown,
7842                         termios_bad=yes AC_DEFINE(_POSIX_SOURCE,1,[Define to 1 if we must define _POSIX_SOURCE]))
7843                         ])
7844         AC_MSG_RESULT($termios_bad)
7845         fi
7846 fi
7847 ])dnl
7848 dnl ---------------------------------------------------------------------------
7849 dnl CF_SUBDIR_PATH version: 7 updated: 2014/12/04 04:33:06
7850 dnl --------------
7851 dnl Construct a search-list for a nonstandard header/lib-file
7852 dnl     $1 = the variable to return as result
7853 dnl     $2 = the package name
7854 dnl     $3 = the subdirectory, e.g., bin, include or lib
7855 AC_DEFUN([CF_SUBDIR_PATH],
7856 [
7857 $1=
7858
7859 CF_ADD_SUBDIR_PATH($1,$2,$3,$prefix,NONE)
7860
7861 for cf_subdir_prefix in \
7862         /usr \
7863         /usr/local \
7864         /usr/pkg \
7865         /opt \
7866         /opt/local \
7867         [$]HOME
7868 do
7869         CF_ADD_SUBDIR_PATH($1,$2,$3,$cf_subdir_prefix,$prefix)
7870 done
7871 ])dnl
7872 dnl ---------------------------------------------------------------------------
7873 dnl CF_SUBST_IF version: 2 updated: 2006/06/17 12:33:03
7874 dnl -----------
7875 dnl     Shorthand macro for substituting things that the user may override
7876 dnl     with an environment variable.
7877 dnl
7878 dnl     $1 = condition to pass to "test"
7879 dnl     $2 = environment variable
7880 dnl     $3 = value if the test succeeds
7881 dnl     $4 = value if the test fails
7882 AC_DEFUN([CF_SUBST_IF],
7883 [
7884 if test $1 ; then
7885         $2=$3
7886 ifelse($4,,,[else
7887         $2=$4])
7888 fi
7889 AC_SUBST($2)
7890 ])dnl
7891 dnl ---------------------------------------------------------------------------
7892 dnl CF_SUBST_NCURSES_VERSION version: 10 updated: 2021/01/04 18:48:01
7893 dnl ------------------------
7894 dnl Get the version-number for use in shared-library naming, etc.
7895 AC_DEFUN([CF_SUBST_NCURSES_VERSION],
7896 [AC_REQUIRE([AC_PROG_EGREP])dnl
7897
7898 NCURSES_MAJOR="`${EGREP-egrep} '^NCURSES_MAJOR[[        ]]*=' "$srcdir/dist.mk" | sed -e 's/^[[^0-9]]*//'`"
7899 NCURSES_MINOR="`${EGREP-egrep} '^NCURSES_MINOR[[        ]]*=' "$srcdir/dist.mk" | sed -e 's/^[[^0-9]]*//'`"
7900 NCURSES_PATCH="`${EGREP-egrep} '^NCURSES_PATCH[[        ]]*=' "$srcdir/dist.mk" | sed -e 's/^[[^0-9]]*//'`"
7901 cf_cv_abi_version=${NCURSES_MAJOR}
7902 cf_cv_rel_version=${NCURSES_MAJOR}.${NCURSES_MINOR}
7903 dnl Show the computed version, for logging
7904 cf_cv_timestamp=`date`
7905 AC_MSG_RESULT(Configuring NCURSES $cf_cv_rel_version ABI $cf_cv_abi_version ($cf_cv_timestamp))
7906 dnl We need these values in the generated headers
7907 AC_SUBST(NCURSES_MAJOR)
7908 AC_SUBST(NCURSES_MINOR)
7909 AC_SUBST(NCURSES_PATCH)
7910 dnl We need these values in the generated makefiles
7911 AC_SUBST(cf_cv_rel_version)
7912 AC_SUBST(cf_cv_abi_version)
7913 AC_SUBST(cf_cv_builtin_bool)
7914 AC_SUBST(cf_cv_header_stdbool_h)
7915 AC_SUBST(cf_cv_type_of_bool)dnl
7916 ])dnl
7917 dnl ---------------------------------------------------------------------------
7918 dnl CF_SYS_TIME_SELECT version: 6 updated: 2015/04/18 08:56:57
7919 dnl ------------------
7920 dnl Check if we can include <sys/time.h> with <sys/select.h>; this breaks on
7921 dnl older SCO configurations.
7922 AC_DEFUN([CF_SYS_TIME_SELECT],
7923 [
7924 AC_MSG_CHECKING(if sys/time.h works with sys/select.h)
7925 AC_CACHE_VAL(cf_cv_sys_time_select,[
7926 AC_TRY_COMPILE([
7927 #include <sys/types.h>
7928 #ifdef HAVE_SYS_TIME_H
7929 #include <sys/time.h>
7930 #endif
7931 #ifdef HAVE_SYS_SELECT_H
7932 #include <sys/select.h>
7933 #endif
7934 ],[],[cf_cv_sys_time_select=yes],
7935          [cf_cv_sys_time_select=no])
7936          ])
7937 AC_MSG_RESULT($cf_cv_sys_time_select)
7938 test "$cf_cv_sys_time_select" = yes && AC_DEFINE(HAVE_SYS_TIME_SELECT,1,[Define to 1 if we can include <sys/time.h> with <sys/select.h>])
7939 ])dnl
7940 dnl ---------------------------------------------------------------------------
7941 dnl CF_TOP_BUILDDIR version: 2 updated: 2013/07/27 17:38:32
7942 dnl ---------------
7943 dnl Define a top_builddir symbol, for applications that need an absolute path.
7944 AC_DEFUN([CF_TOP_BUILDDIR],
7945 [
7946 top_builddir=ifelse($1,,`pwd`,$1)
7947 AC_SUBST(top_builddir)
7948 ])dnl
7949 dnl ---------------------------------------------------------------------------
7950 dnl CF_TRY_PKG_CONFIG version: 6 updated: 2020/12/31 10:54:15
7951 dnl -----------------
7952 dnl This is a simple wrapper to use for pkg-config, for libraries which may be
7953 dnl available in that form.
7954 dnl
7955 dnl $1 = package name, which may be a shell variable
7956 dnl $2 = extra logic to use, if any, after updating CFLAGS and LIBS
7957 dnl $3 = logic to use if pkg-config does not have the package
7958 AC_DEFUN([CF_TRY_PKG_CONFIG],[
7959 AC_REQUIRE([CF_PKG_CONFIG])
7960
7961 if test "$PKG_CONFIG" != none && "$PKG_CONFIG" --exists "$1"; then
7962         CF_VERBOSE(found package $1)
7963         cf_pkgconfig_incs="`$PKG_CONFIG --cflags "$1" 2>/dev/null`"
7964         cf_pkgconfig_libs="`$PKG_CONFIG --libs   "$1" 2>/dev/null`"
7965         CF_VERBOSE(package $1 CFLAGS: $cf_pkgconfig_incs)
7966         CF_VERBOSE(package $1 LIBS: $cf_pkgconfig_libs)
7967         CF_ADD_CFLAGS($cf_pkgconfig_incs)
7968         CF_ADD_LIBS($cf_pkgconfig_libs)
7969         ifelse([$2],,:,[$2])
7970 else
7971         cf_pkgconfig_incs=
7972         cf_pkgconfig_libs=
7973         ifelse([$3],,:,[$3])
7974 fi
7975 ])
7976 dnl ---------------------------------------------------------------------------
7977 dnl CF_TRY_XOPEN_SOURCE version: 2 updated: 2018/06/20 20:23:13
7978 dnl -------------------
7979 dnl If _XOPEN_SOURCE is not defined in the compile environment, check if we
7980 dnl can define it successfully.
7981 AC_DEFUN([CF_TRY_XOPEN_SOURCE],[
7982 AC_CACHE_CHECK(if we should define _XOPEN_SOURCE,cf_cv_xopen_source,[
7983         AC_TRY_COMPILE([
7984 #include <stdlib.h>
7985 #include <string.h>
7986 #include <sys/types.h>
7987 ],[
7988 #ifndef _XOPEN_SOURCE
7989 make an error
7990 #endif],
7991         [cf_cv_xopen_source=no],
7992         [cf_save="$CPPFLAGS"
7993          CF_APPEND_TEXT(CPPFLAGS,-D_XOPEN_SOURCE=$cf_XOPEN_SOURCE)
7994          AC_TRY_COMPILE([
7995 #include <stdlib.h>
7996 #include <string.h>
7997 #include <sys/types.h>
7998 ],[
7999 #ifdef _XOPEN_SOURCE
8000 make an error
8001 #endif],
8002         [cf_cv_xopen_source=no],
8003         [cf_cv_xopen_source=$cf_XOPEN_SOURCE])
8004         CPPFLAGS="$cf_save"
8005         ])
8006 ])
8007
8008 if test "$cf_cv_xopen_source" != no ; then
8009         CF_REMOVE_DEFINE(CFLAGS,$CFLAGS,_XOPEN_SOURCE)
8010         CF_REMOVE_DEFINE(CPPFLAGS,$CPPFLAGS,_XOPEN_SOURCE)
8011         cf_temp_xopen_source="-D_XOPEN_SOURCE=$cf_cv_xopen_source"
8012         CF_ADD_CFLAGS($cf_temp_xopen_source)
8013 fi
8014 ])
8015 dnl ---------------------------------------------------------------------------
8016 dnl CF_TYPEOF_CHTYPE version: 10 updated: 2017/01/21 11:06:25
8017 dnl ----------------
8018 dnl Determine the type we should use for chtype (and attr_t, which is treated
8019 dnl as the same thing).  We want around 32 bits, so on most machines want a
8020 dnl long, but on newer 64-bit machines, probably want an int.  If we're using
8021 dnl wide characters, we have to have a type compatible with that, as well.
8022 AC_DEFUN([CF_TYPEOF_CHTYPE],
8023 [
8024 AC_MSG_CHECKING([for type of chtype])
8025 AC_CACHE_VAL(cf_cv_typeof_chtype,[
8026                 AC_TRY_RUN([
8027 #define WANT_BITS 31
8028 #include <stdio.h>
8029 int main(void)
8030 {
8031         FILE *fp = fopen("cf_test.out", "w");
8032         if (fp != 0) {
8033                 char *result = "long";
8034                 if (sizeof(unsigned long) > sizeof(unsigned int)) {
8035                         int n;
8036                         unsigned int x, y;
8037                         for (n = 0; n < WANT_BITS; n++) {
8038                                 x = (1 << n);
8039                                 y = (x >> n);
8040                                 if (y != 1 || x == 0) {
8041                                         x = 0;
8042                                         break;
8043                                 }
8044                         }
8045                         /*
8046                          * If x is nonzero, an int is big enough for the bits
8047                          * that we want.
8048                          */
8049                         result = (x != 0) ? "int" : "long";
8050                 }
8051                 fputs(result, fp);
8052                 fclose(fp);
8053         }
8054         ${cf_cv_main_return:-return}(0);
8055 }
8056                 ],
8057                 [cf_cv_typeof_chtype=`cat cf_test.out`],
8058                 [cf_cv_typeof_chtype=long],
8059                 [cf_cv_typeof_chtype=long])
8060                 rm -f cf_test.out
8061         ])
8062 AC_MSG_RESULT($cf_cv_typeof_chtype)
8063
8064 AC_SUBST(cf_cv_typeof_chtype)
8065 AC_DEFINE_UNQUOTED(TYPEOF_CHTYPE,$cf_cv_typeof_chtype,[Define to actual type if needed for chtype])
8066 ])dnl
8067 dnl ---------------------------------------------------------------------------
8068 dnl CF_TYPE_SIGACTION version: 4 updated: 2012/10/06 17:56:13
8069 dnl -----------------
8070 dnl
8071 AC_DEFUN([CF_TYPE_SIGACTION],
8072 [
8073 AC_MSG_CHECKING([for type sigaction_t])
8074 AC_CACHE_VAL(cf_cv_type_sigaction,[
8075         AC_TRY_COMPILE([
8076 #include <signal.h>],
8077                 [sigaction_t x],
8078                 [cf_cv_type_sigaction=yes],
8079                 [cf_cv_type_sigaction=no])])
8080 AC_MSG_RESULT($cf_cv_type_sigaction)
8081 test "$cf_cv_type_sigaction" = yes && AC_DEFINE(HAVE_TYPE_SIGACTION,1,[Define to 1 if we have the sigaction_t type])
8082 ])dnl
8083 dnl ---------------------------------------------------------------------------
8084 dnl CF_UNSIGNED_LITERALS version: 2 updated: 1998/02/07 22:10:16
8085 dnl --------------------
8086 dnl Test if the compiler supports 'U' and 'L' suffixes.  Only old compilers
8087 dnl won't, but they're still there.
8088 AC_DEFUN([CF_UNSIGNED_LITERALS],
8089 [
8090 AC_MSG_CHECKING([if unsigned literals are legal])
8091 AC_CACHE_VAL(cf_cv_unsigned_literals,[
8092         AC_TRY_COMPILE([],[long x = 1L + 1UL + 1U + 1],
8093                 [cf_cv_unsigned_literals=yes],
8094                 [cf_cv_unsigned_literals=no])
8095         ])
8096 AC_MSG_RESULT($cf_cv_unsigned_literals)
8097 ])dnl
8098 dnl ---------------------------------------------------------------------------
8099 dnl CF_UPPER version: 5 updated: 2001/01/29 23:40:59
8100 dnl --------
8101 dnl Make an uppercase version of a variable
8102 dnl $1=uppercase($2)
8103 AC_DEFUN([CF_UPPER],
8104 [
8105 $1=`echo "$2" | sed y%abcdefghijklmnopqrstuvwxyz./-%ABCDEFGHIJKLMNOPQRSTUVWXYZ___%`
8106 ])dnl
8107 dnl ---------------------------------------------------------------------------
8108 dnl CF_UTF8_LIB version: 8 updated: 2012/10/06 08:57:51
8109 dnl -----------
8110 dnl Check for multibyte support, and if not found, utf8 compatibility library
8111 AC_DEFUN([CF_UTF8_LIB],
8112 [
8113 AC_CACHE_CHECK(for multibyte character support,cf_cv_utf8_lib,[
8114         cf_save_LIBS="$LIBS"
8115         AC_TRY_LINK([
8116 #include <stdlib.h>],[putwc(0,0);],
8117         [cf_cv_utf8_lib=yes],
8118         [CF_FIND_LINKAGE([
8119 #include <libutf8.h>],[putwc(0,0);],utf8,
8120                 [cf_cv_utf8_lib=add-on],
8121                 [cf_cv_utf8_lib=no])
8122 ])])
8123
8124 # HAVE_LIBUTF8_H is used by ncurses if curses.h is shared between
8125 # ncurses/ncursesw:
8126 if test "$cf_cv_utf8_lib" = "add-on" ; then
8127         AC_DEFINE(HAVE_LIBUTF8_H,1,[Define to 1 if we should include libutf8.h])
8128         CF_ADD_INCDIR($cf_cv_header_path_utf8)
8129         CF_ADD_LIBDIR($cf_cv_library_path_utf8)
8130         CF_ADD_LIBS($cf_cv_library_file_utf8)
8131 fi
8132 ])dnl
8133 dnl ---------------------------------------------------------------------------
8134 dnl CF_VA_COPY version: 6 updated: 2018/12/04 18:14:25
8135 dnl ----------
8136 dnl check for va_copy, part of stdarg.h starting with ISO C 1999.
8137 dnl Also, workaround for glibc's __va_copy, by checking for both.
8138 dnl Finally, try to accommodate pre-ISO C 1999 headers.
8139 AC_DEFUN([CF_VA_COPY],[
8140 AC_CACHE_CHECK(for va_copy, cf_cv_have_va_copy,[
8141 AC_TRY_LINK([
8142 #include <stdarg.h>
8143 ],[
8144         static va_list dst;
8145         static va_list src;
8146         va_copy(dst, src)],
8147         cf_cv_have_va_copy=yes,
8148         cf_cv_have_va_copy=no)])
8149
8150 if test "$cf_cv_have_va_copy" = yes;
8151 then
8152         AC_DEFINE(HAVE_VA_COPY,1,[Define to 1 if we have va_copy])
8153 else # !cf_cv_have_va_copy
8154
8155 AC_CACHE_CHECK(for __va_copy, cf_cv_have___va_copy,[
8156 AC_TRY_LINK([
8157 #include <stdarg.h>
8158 ],[
8159         static va_list dst;
8160         static va_list src;
8161         __va_copy(dst, src)],
8162         cf_cv_have___va_copy=yes,
8163         cf_cv_have___va_copy=no)])
8164
8165 if test "$cf_cv_have___va_copy" = yes
8166 then
8167         AC_DEFINE(HAVE___VA_COPY,1,[Define to 1 if we have __va_copy])
8168 else # !cf_cv_have___va_copy
8169
8170 AC_CACHE_CHECK(for __builtin_va_copy, cf_cv_have___builtin_va_copy,[
8171 AC_TRY_LINK([
8172 #include <stdarg.h>
8173 ],[
8174         static va_list dst;
8175         static va_list src;
8176         __builtin_va_copy(dst, src)],
8177         cf_cv_have___builtin_va_copy=yes,
8178         cf_cv_have___builtin_va_copy=no)])
8179
8180 test "$cf_cv_have___builtin_va_copy" = yes &&
8181         AC_DEFINE(HAVE___BUILTIN_VA_COPY,1,[Define to 1 if we have __builtin_va_copy])
8182
8183 fi # cf_cv_have___va_copy
8184
8185 fi # cf_cv_have_va_copy
8186
8187 case "${cf_cv_have_va_copy}${cf_cv_have___va_copy}${cf_cv_have___builtin_va_copy}" in
8188 (*yes*)
8189         ;;
8190
8191 (*)
8192         AC_CACHE_CHECK(if we can simply copy va_list, cf_cv_pointer_va_list,[
8193 AC_TRY_LINK([
8194 #include <stdarg.h>
8195 ],[
8196         va_list dst;
8197         va_list src;
8198         dst = src],
8199         cf_cv_pointer_va_list=yes,
8200         cf_cv_pointer_va_list=no)])
8201
8202         if test "$cf_cv_pointer_va_list" = no
8203         then
8204                 AC_CACHE_CHECK(if we can copy va_list indirectly, cf_cv_array_va_list,[
8205 AC_TRY_LINK([
8206 #include <stdarg.h>
8207 ],[
8208         va_list dst;
8209         va_list src;
8210         *dst = *src],
8211                         cf_cv_array_va_list=yes,
8212                         cf_cv_array_va_list=no)])
8213                 test "$cf_cv_array_va_list" = yes && AC_DEFINE(ARRAY_VA_LIST,1,[Define to 1 if we can copy va_list indirectly])
8214         fi
8215         ;;
8216 esac
8217 ])
8218 dnl ---------------------------------------------------------------------------
8219 dnl CF_VERBOSE version: 3 updated: 2007/07/29 09:55:12
8220 dnl ----------
8221 dnl Use AC_VERBOSE w/o the warnings
8222 AC_DEFUN([CF_VERBOSE],
8223 [test -n "$verbose" && echo "   $1" 1>&AC_FD_MSG
8224 CF_MSG_LOG([$1])
8225 ])dnl
8226 dnl ---------------------------------------------------------------------------
8227 dnl CF_VERSION_INFO version: 8 updated: 2021/01/01 13:31:04
8228 dnl ---------------
8229 dnl Define several useful symbols derived from the VERSION file.  A separate
8230 dnl file is preferred to embedding the version numbers in various scripts.
8231 dnl (automake is a textbook-example of why the latter is a bad idea, but there
8232 dnl are others).
8233 dnl
8234 dnl The file contents are:
8235 dnl     libtool-version release-version patch-version
8236 dnl or
8237 dnl     release-version
8238 dnl where
8239 dnl     libtool-version (see ?) consists of 3 integers separated by '.'
8240 dnl     release-version consists of a major version and minor version
8241 dnl             separated by '.', optionally followed by a patch-version
8242 dnl             separated by '-'.  The minor version need not be an
8243 dnl             integer (but it is preferred).
8244 dnl     patch-version is an integer in the form yyyymmdd, so ifdef's and
8245 dnl             scripts can easily compare versions.
8246 dnl
8247 dnl If libtool is used, the first form is required, since CF_WITH_LIBTOOL
8248 dnl simply extracts the first field using 'cut -f1'.
8249 dnl
8250 dnl Optional parameters:
8251 dnl $1 = internal name for package
8252 dnl $2 = external name for package
8253 AC_DEFUN([CF_VERSION_INFO],
8254 [
8255 if test -f "$srcdir/VERSION" ; then
8256         AC_MSG_CHECKING(for package version)
8257
8258         # if there are not enough fields, cut returns the last one...
8259         cf_field1=`sed -e '2,$d' "$srcdir/VERSION" |cut -f1`
8260         cf_field2=`sed -e '2,$d' "$srcdir/VERSION" |cut -f2`
8261         cf_field3=`sed -e '2,$d' "$srcdir/VERSION" |cut -f3`
8262
8263         # this is how CF_BUNDLED_INTL uses $VERSION:
8264         VERSION="$cf_field1"
8265
8266         VERSION_MAJOR=`echo "$cf_field2" | sed -e 's/\..*//'`
8267         test -z "$VERSION_MAJOR" && AC_MSG_ERROR(missing major-version)
8268
8269         VERSION_MINOR=`echo "$cf_field2" | sed -e 's/^[[^.]]*\.//' -e 's/-.*//'`
8270         test -z "$VERSION_MINOR" && AC_MSG_ERROR(missing minor-version)
8271
8272         AC_MSG_RESULT(${VERSION_MAJOR}.${VERSION_MINOR})
8273
8274         AC_MSG_CHECKING(for package patch date)
8275         VERSION_PATCH=`echo "$cf_field3" | sed -e 's/^[[^-]]*-//'`
8276         case .$VERSION_PATCH in
8277         (.)
8278                 AC_MSG_ERROR(missing patch-date $VERSION_PATCH)
8279                 ;;
8280         (.[[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]][[0-9]])
8281                 ;;
8282         (*)
8283                 AC_MSG_ERROR(illegal patch-date $VERSION_PATCH)
8284                 ;;
8285         esac
8286         AC_MSG_RESULT($VERSION_PATCH)
8287 else
8288         AC_MSG_ERROR(did not find $srcdir/VERSION)
8289 fi
8290
8291 # show the actual data that we have for versions:
8292 CF_VERBOSE(ABI VERSION $VERSION)
8293 CF_VERBOSE(VERSION_MAJOR $VERSION_MAJOR)
8294 CF_VERBOSE(VERSION_MINOR $VERSION_MINOR)
8295 CF_VERBOSE(VERSION_PATCH $VERSION_PATCH)
8296
8297 AC_SUBST(VERSION)
8298 AC_SUBST(VERSION_MAJOR)
8299 AC_SUBST(VERSION_MINOR)
8300 AC_SUBST(VERSION_PATCH)
8301
8302 dnl if a package name is given, define its corresponding version info.  We
8303 dnl need the package name to ensure that the defined symbols are unique.
8304 ifelse($1,,,[
8305         cf_PACKAGE=$1
8306         PACKAGE=ifelse($2,,$1,$2)
8307         AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",[Define to the package-name])
8308         AC_SUBST(PACKAGE)
8309         CF_UPPER(cf_PACKAGE,$cf_PACKAGE)
8310         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_VERSION,"${VERSION_MAJOR}.${VERSION_MINOR}")
8311         AC_DEFINE_UNQUOTED(${cf_PACKAGE}_PATCHDATE,${VERSION_PATCH})
8312 ])
8313 ])dnl
8314 dnl ---------------------------------------------------------------------------
8315 dnl CF_WCHAR_TYPE version: 4 updated: 2012/10/06 16:39:58
8316 dnl -------------
8317 dnl Check if type wide-character type $1 is declared, and if so, which header
8318 dnl file is needed.  The second parameter is used to set a shell variable when
8319 dnl the type is not found.  The first parameter sets a shell variable for the
8320 dnl opposite sense.
8321 AC_DEFUN([CF_WCHAR_TYPE],
8322 [
8323 # This is needed on Tru64 5.0 to declare $1
8324 AC_CACHE_CHECK(if we must include wchar.h to declare $1,cf_cv_$1,[
8325 AC_TRY_COMPILE([
8326 #include <stdlib.h>
8327 #include <stdarg.h>
8328 #include <stdio.h>
8329 #ifdef HAVE_LIBUTF8_H
8330 #include <libutf8.h>
8331 #endif],
8332         [$1 state],
8333         [cf_cv_$1=no],
8334         [AC_TRY_COMPILE([
8335 #include <stdlib.h>
8336 #include <stdarg.h>
8337 #include <stdio.h>
8338 #include <wchar.h>
8339 #ifdef HAVE_LIBUTF8_H
8340 #include <libutf8.h>
8341 #endif],
8342         [$1 value],
8343         [cf_cv_$1=yes],
8344         [cf_cv_$1=unknown])])])
8345
8346 if test "$cf_cv_$1" = yes ; then
8347         AC_DEFINE(NEED_WCHAR_H,1,[Define to 1 if we must include wchar.h])
8348         NEED_WCHAR_H=1
8349 fi
8350
8351 ifelse([$2],,,[
8352 # if we do not find $1 in either place, use substitution to provide a fallback.
8353 if test "$cf_cv_$1" = unknown ; then
8354         $2=1
8355 fi
8356 ])
8357 ifelse($3,,,[
8358 # if we find $1 in either place, use substitution to provide a fallback.
8359 if test "$cf_cv_$1" != unknown ; then
8360         $3=1
8361 fi
8362 ])
8363 ])dnl
8364 dnl ---------------------------------------------------------------------------
8365 dnl CF_WEAK_SYMBOLS version: 1 updated: 2008/08/16 19:18:06
8366 dnl ---------------
8367 dnl Check for compiler-support for weak symbols.
8368 dnl This works with "recent" gcc.
8369 AC_DEFUN([CF_WEAK_SYMBOLS],[
8370 AC_CACHE_CHECK(if $CC supports weak symbols,cf_cv_weak_symbols,[
8371
8372 AC_TRY_COMPILE([
8373 #include <stdio.h>],
8374 [
8375 #if defined(__GNUC__)
8376 #  if defined __USE_ISOC99
8377 #    define _cat_pragma(exp)    _Pragma(#exp)
8378 #    define _weak_pragma(exp)   _cat_pragma(weak name)
8379 #  else
8380 #    define _weak_pragma(exp)
8381 #  endif
8382 #  define _declare(name)        __extension__ extern __typeof__(name) name
8383 #  define weak_symbol(name)     _weak_pragma(name) _declare(name) __attribute__((weak))
8384 #endif
8385
8386 weak_symbol(fopen);
8387 ],[cf_cv_weak_symbols=yes],[cf_cv_weak_symbols=no])
8388 ])
8389 ])dnl
8390 dnl ---------------------------------------------------------------------------
8391 dnl CF_WITH_ABI_VERSION version: 4 updated: 2021/01/01 13:31:04
8392 dnl -------------------
8393 dnl Allow library's ABI to be overridden.  Generally this happens when a
8394 dnl packager has incremented the ABI past that used in the original package,
8395 dnl and wishes to keep doing this.
8396 dnl
8397 dnl $1 is the package name, if any, to derive a corresponding {package}_ABI
8398 dnl symbol.
8399 AC_DEFUN([CF_WITH_ABI_VERSION],[
8400 test -z "$cf_cv_abi_version" && cf_cv_abi_version=0
8401 AC_ARG_WITH(abi-version,
8402 [  --with-abi-version=XXX  override derived ABI version],[
8403         if test "x$cf_cv_abi_version" != "x$withval"
8404         then
8405                 AC_MSG_WARN(overriding ABI version $cf_cv_abi_version to $withval)
8406                 case "$cf_cv_rel_version" in
8407                 (5.*)
8408                         cf_cv_rel_version=$withval.0
8409                         ;;
8410                 (6.*)
8411                         cf_cv_rel_version=$withval.9    # FIXME: should be 10 as of 6.0 release
8412                         ;;
8413                 esac
8414         fi
8415         cf_cv_abi_version=$withval])
8416         CF_NUMBER_SYNTAX($cf_cv_abi_version,ABI version)
8417 ifelse($1,,,[
8418 $1_ABI=$cf_cv_abi_version
8419 ])
8420 ])dnl
8421 dnl ---------------------------------------------------------------------------
8422 dnl CF_WITH_ADA_COMPILER version: 2 updated: 2010/06/26 17:35:58
8423 dnl --------------------
8424 dnl Command-line option to specify the Ada95 compiler.
8425 AC_DEFUN([CF_WITH_ADA_COMPILER],[
8426 AC_MSG_CHECKING(for ada-compiler)
8427 AC_ARG_WITH(ada-compiler,
8428         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
8429         [cf_ada_compiler=$withval],
8430         [cf_ada_compiler=gnatmake])
8431 AC_SUBST(cf_ada_compiler)
8432 AC_MSG_RESULT($cf_ada_compiler)
8433 ])dnl
8434 dnl ---------------------------------------------------------------------------
8435 dnl CF_WITH_ADA_INCLUDE version: 2 updated: 2010/06/26 17:35:58
8436 dnl -------------------
8437 dnl Command-line option to specify where Ada includes will install.
8438 AC_DEFUN([CF_WITH_ADA_INCLUDE],[
8439 AC_MSG_CHECKING(for ada-include)
8440 CF_WITH_PATH(ada-include,
8441    [  --with-ada-include=DIR  Ada includes are in DIR],
8442    ADA_INCLUDE,
8443    PREFIX/share/ada/adainclude,
8444    [$]prefix/share/ada/adainclude)
8445 AC_SUBST(ADA_INCLUDE)
8446 AC_MSG_RESULT($ADA_INCLUDE)
8447 ])dnl
8448 dnl ---------------------------------------------------------------------------
8449 dnl CF_WITH_ADA_LIBNAME version: 1 updated: 2019/09/07 18:59:41
8450 dnl -------------------
8451 dnl CF_WITH_ADA_LIBNAME
8452 dnl -------------------
8453 dnl Command-line option to specify how to name the resulting Ada library.
8454 dnl $1 = default value
8455 AC_DEFUN([CF_WITH_ADA_LIBNAME],[
8456 AC_MSG_CHECKING(for ada-libname)
8457 AC_ARG_WITH(ada-libname,
8458    [  --with-ada-libname=XXX  override default Ada library-name],
8459    ADA_LIBNAME=[$]withval,
8460    ADA_LIBNAME=$1)
8461 case "x$ADA_LIBNAME" in
8462 (x|xyes|xno)
8463         ADA_LIBNAME=$1
8464         ;;
8465 esac
8466 AC_SUBST(ADA_LIBNAME)
8467 AC_MSG_RESULT($ADA_LIBNAME)
8468 ])dnl
8469 dnl ---------------------------------------------------------------------------
8470 dnl CF_WITH_ADA_OBJECTS version: 2 updated: 2010/06/26 17:35:58
8471 dnl -------------------
8472 dnl Command-line option to specify where Ada objects will install.
8473 AC_DEFUN([CF_WITH_ADA_OBJECTS],[
8474 AC_MSG_CHECKING(for ada-objects)
8475 CF_WITH_PATH(ada-objects,
8476    [  --with-ada-objects=DIR  Ada objects are in DIR],
8477    ADA_OBJECTS,
8478    PREFIX/lib/ada/adalib,
8479    [$]prefix/lib/ada/adalib)
8480 AC_SUBST(ADA_OBJECTS)
8481 AC_MSG_RESULT($ADA_OBJECTS)
8482 ])dnl
8483 dnl ---------------------------------------------------------------------------
8484 dnl CF_WITH_ADA_SHAREDLIB version: 5 updated: 2018/07/21 19:10:35
8485 dnl ---------------------
8486 dnl Command-line option to specify if an Ada95 shared-library should be built,
8487 dnl and optionally what its soname should be.
8488 AC_DEFUN([CF_WITH_ADA_SHAREDLIB],[
8489 AC_REQUIRE([CF_GNAT_PROJECTS])
8490 AC_MSG_CHECKING(if an Ada95 shared-library should be built)
8491 AC_ARG_WITH(ada-sharedlib,
8492         [  --with-ada-sharedlib=soname build shared-library (requires GNAT projects)],
8493         [with_ada_sharedlib=$withval],
8494         [with_ada_sharedlib=no])
8495 AC_MSG_RESULT($with_ada_sharedlib)
8496
8497 if test "x$with_ada_sharedlib" != xno
8498 then
8499         if test "x$cf_gnat_projects" != xyes
8500         then
8501                 AC_MSG_WARN(disabling shared-library since GNAT projects are not supported)
8502                 with_ada_sharedlib=no
8503         fi
8504 fi
8505
8506 ADA_SHAREDLIB='lib$(LIB_NAME).so.1'
8507 MAKE_ADA_SHAREDLIB="#"
8508
8509 if test "x$with_ada_sharedlib" != xno
8510 then
8511         MAKE_ADA_SHAREDLIB=
8512         if test "x$with_ada_sharedlib" != xyes
8513         then
8514                 ADA_SHAREDLIB="$with_ada_sharedlib"
8515         fi
8516 fi
8517
8518 AC_SUBST(ADA_SHAREDLIB)
8519 AC_SUBST(MAKE_ADA_SHAREDLIB)
8520 ])dnl
8521 dnl ---------------------------------------------------------------------------
8522 dnl CF_WITH_DBMALLOC version: 7 updated: 2010/06/21 17:26:47
8523 dnl ----------------
8524 dnl Configure-option for dbmalloc.  The optional parameter is used to override
8525 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
8526 AC_DEFUN([CF_WITH_DBMALLOC],[
8527 CF_NO_LEAKS_OPTION(dbmalloc,
8528         [  --with-dbmalloc         test: use Conor Cahill's dbmalloc library],
8529         [USE_DBMALLOC])
8530
8531 if test "$with_dbmalloc" = yes ; then
8532         AC_CHECK_HEADER(dbmalloc.h,
8533                 [AC_CHECK_LIB(dbmalloc,[debug_malloc]ifelse([$1],,[],[,$1]))])
8534 fi
8535 ])dnl
8536 dnl ---------------------------------------------------------------------------
8537 dnl CF_WITH_DMALLOC version: 7 updated: 2010/06/21 17:26:47
8538 dnl ---------------
8539 dnl Configure-option for dmalloc.  The optional parameter is used to override
8540 dnl the updating of $LIBS, e.g., to avoid conflict with subsequent tests.
8541 AC_DEFUN([CF_WITH_DMALLOC],[
8542 CF_NO_LEAKS_OPTION(dmalloc,
8543         [  --with-dmalloc          test: use Gray Watson's dmalloc library],
8544         [USE_DMALLOC])
8545
8546 if test "$with_dmalloc" = yes ; then
8547         AC_CHECK_HEADER(dmalloc.h,
8548                 [AC_CHECK_LIB(dmalloc,[dmalloc_debug]ifelse([$1],,[],[,$1]))])
8549 fi
8550 ])dnl
8551 dnl ---------------------------------------------------------------------------
8552 dnl CF_WITH_EXPORT_SYMS version: 3 updated: 2014/12/20 19:16:08
8553 dnl -------------------
8554 dnl Use this with libtool to specify the list of symbols that may be exported.
8555 dnl The input file contains one symbol per line; comments work with "#".
8556 dnl
8557 dnl $1 = basename of the ".sym" file (default $PACKAGE)
8558 AC_DEFUN([CF_WITH_EXPORT_SYMS],
8559 [
8560 AC_MSG_CHECKING(if exported-symbols file should be used)
8561 AC_ARG_WITH(export-syms,
8562         [  --with-export-syms=XXX  limit exported symbols using libtool],
8563         [with_export_syms=$withval],
8564         [with_export_syms=no])
8565 if test "x$with_export_syms" = xyes
8566 then
8567         with_export_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).sym'
8568         AC_SUBST(PACKAGE)
8569 fi
8570 AC_MSG_RESULT($with_export_syms)
8571 if test "x$with_export_syms" != xno
8572 then
8573         EXPORT_SYMS="-export-symbols $with_export_syms"
8574         AC_SUBST(EXPORT_SYMS)
8575 fi
8576 ])dnl
8577 dnl ---------------------------------------------------------------------------
8578 dnl CF_WITH_GPM version: 10 updated: 2017/04/29 18:32:18
8579 dnl -----------
8580 dnl
8581 dnl The option parameter (if neither yes/no) is assumed to be the name of
8582 dnl the gpm library, e.g., for dynamic loading.
8583 AC_DEFUN([CF_WITH_GPM],
8584 [
8585 AC_MSG_CHECKING(if you want to link with the GPM mouse library)
8586 AC_ARG_WITH(gpm,
8587         [  --with-gpm              use Alessandro Rubini's GPM library],
8588         [with_gpm=$withval],
8589         [with_gpm=maybe])
8590 AC_MSG_RESULT($with_gpm)
8591
8592 if test "$with_gpm" != no ; then
8593         AC_CHECK_HEADER(gpm.h,[
8594                 AC_DEFINE(HAVE_GPM_H,1,[Define to 1 if we have gpm.h header])
8595                 if test "$with_gpm" != yes && test "$with_gpm" != maybe ; then
8596                         CF_VERBOSE(assuming we really have GPM library)
8597                         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
8598                         with_gpm=yes
8599                 else
8600                         AC_CHECK_LIB(gpm,Gpm_Open,[with_gpm=yes],[
8601                                 if test "$with_gpm" = maybe; then
8602                                         AC_MSG_WARN(Cannot link with GPM library)
8603                                         with_gpm=no
8604                                 else
8605                                         AC_MSG_ERROR(Cannot link with GPM library)
8606                                 fi
8607                         ])
8608                 fi
8609         ],[
8610                 test "$with_gpm" != maybe && AC_MSG_WARN(Cannot find GPM header)
8611                 with_gpm=no
8612         ])
8613 fi
8614 ])
8615 dnl ---------------------------------------------------------------------------
8616 dnl CF_WITH_LIBTOOL version: 36 updated: 2021/01/01 13:31:04
8617 dnl ---------------
8618 dnl Provide a configure option to incorporate libtool.  Define several useful
8619 dnl symbols for the makefile rules.
8620 dnl
8621 dnl The reference to AC_PROG_LIBTOOL does not normally work, since it uses
8622 dnl macros from libtool.m4 which is in the aclocal directory of automake.
8623 dnl Following is a simple script which turns on the AC_PROG_LIBTOOL macro.
8624 dnl But that still does not work properly since the macro is expanded outside
8625 dnl the CF_WITH_LIBTOOL macro:
8626 dnl
8627 dnl     #!/bin/sh
8628 dnl     ACLOCAL=`aclocal --print-ac-dir`
8629 dnl     if test -z "$ACLOCAL" ; then
8630 dnl             echo cannot find aclocal directory
8631 dnl             exit 1
8632 dnl     elif test ! -f $ACLOCAL/libtool.m4 ; then
8633 dnl             echo cannot find libtool.m4 file
8634 dnl             exit 1
8635 dnl     fi
8636 dnl
8637 dnl     LOCAL=aclocal.m4
8638 dnl     ORIG=aclocal.m4.orig
8639 dnl
8640 dnl     trap "mv $ORIG $LOCAL" 0 1 2 3 15
8641 dnl     rm -f $ORIG
8642 dnl     mv $LOCAL $ORIG
8643 dnl
8644 dnl     # sed the LIBTOOL= assignment to omit the current directory?
8645 dnl     sed -e 's/^LIBTOOL=.*/LIBTOOL=${LIBTOOL:-libtool}/' $ACLOCAL/libtool.m4 >>$LOCAL
8646 dnl     cat $ORIG >>$LOCAL
8647 dnl
8648 dnl     autoconf-257 $*
8649 dnl
8650 AC_DEFUN([CF_WITH_LIBTOOL],
8651 [
8652 AC_REQUIRE([CF_DISABLE_LIBTOOL_VERSION])
8653 ifdef([AC_PROG_LIBTOOL],,[
8654 LIBTOOL=
8655 ])
8656 # common library maintenance symbols that are convenient for libtool scripts:
8657 LIB_CREATE='${AR} -cr'
8658 LIB_OBJECT='${OBJECTS}'
8659 LIB_SUFFIX=.a
8660 LIB_PREP="$RANLIB"
8661
8662 # symbols used to prop libtool up to enable it to determine what it should be
8663 # doing:
8664 LIB_CLEAN=
8665 LIB_COMPILE=
8666 LIB_LINK='${CC}'
8667 LIB_INSTALL=
8668 LIB_UNINSTALL=
8669
8670 AC_MSG_CHECKING(if you want to build libraries with libtool)
8671 AC_ARG_WITH(libtool,
8672         [  --with-libtool          generate libraries with libtool],
8673         [with_libtool=$withval],
8674         [with_libtool=no])
8675 AC_MSG_RESULT($with_libtool)
8676 if test "$with_libtool" != "no"; then
8677 ifdef([AC_PROG_LIBTOOL],[
8678         # missing_content_AC_PROG_LIBTOOL{{
8679         AC_PROG_LIBTOOL
8680         # missing_content_AC_PROG_LIBTOOL}}
8681 ],[
8682         if test "$with_libtool" != "yes" ; then
8683                 CF_PATH_SYNTAX(with_libtool)
8684                 LIBTOOL=$with_libtool
8685         else
8686                 AC_CHECK_TOOLS(LIBTOOL,[libtool glibtool],none)
8687                 CF_LIBTOOL_VERSION
8688                 if test -z "$cf_cv_libtool_version" && test "$LIBTOOL" = libtool
8689                 then
8690                         CF_FORGET_TOOL(LIBTOOL)
8691                         AC_CHECK_TOOLS(LIBTOOL,[glibtool],none)
8692                         CF_LIBTOOL_VERSION
8693                 fi
8694         fi
8695         if test -z "$LIBTOOL" ; then
8696                 AC_MSG_ERROR(Cannot find libtool)
8697         fi
8698 ])dnl
8699         LIB_CREATE='${LIBTOOL} --mode=link ${CC} -rpath ${libdir} ${LIBTOOL_VERSION} `cut -f1 ${top_srcdir}/VERSION` ${LIBTOOL_OPTS} ${LT_UNDEF} $(LIBS) -o'
8700         LIB_OBJECT='${OBJECTS:.o=.lo}'
8701         LIB_SUFFIX=.la
8702         LIB_CLEAN='${LIBTOOL} --mode=clean'
8703         LIB_COMPILE='${LIBTOOL} --mode=compile'
8704         LIB_LINK='${LIBTOOL} --mode=link ${CC} ${LIBTOOL_OPTS}'
8705         LIB_INSTALL='${LIBTOOL} --mode=install'
8706         LIB_UNINSTALL='${LIBTOOL} --mode=uninstall'
8707         LIB_PREP=:
8708
8709         CF_CHECK_LIBTOOL_VERSION
8710
8711         # special hack to add -no-undefined (which libtool should do for itself)
8712         LT_UNDEF=
8713         case "$cf_cv_system_name" in
8714         (cygwin*|msys*|mingw32*|os2*|uwin*|aix[[4-7]])
8715                 LT_UNDEF=-no-undefined
8716                 ;;
8717         esac
8718         AC_SUBST([LT_UNDEF])
8719
8720         # special hack to add --tag option for C++ compiler
8721         case "$cf_cv_libtool_version" in
8722         (1.[[5-9]]*|[[2-9]].[[0-9.a-z]]*)
8723                 LIBTOOL_CXX="$LIBTOOL --tag=CXX"
8724                 LIBTOOL="$LIBTOOL --tag=CC"
8725                 ;;
8726         (*)
8727                 LIBTOOL_CXX="$LIBTOOL"
8728                 ;;
8729         esac
8730 else
8731         LIBTOOL=""
8732         LIBTOOL_CXX=""
8733 fi
8734
8735 test -z "$LIBTOOL" && ECHO_LT=
8736
8737 AC_SUBST(LIBTOOL)
8738 AC_SUBST(LIBTOOL_CXX)
8739 AC_SUBST(LIBTOOL_OPTS)
8740
8741 AC_SUBST(LIB_CREATE)
8742 AC_SUBST(LIB_OBJECT)
8743 AC_SUBST(LIB_SUFFIX)
8744 AC_SUBST(LIB_PREP)
8745
8746 AC_SUBST(LIB_CLEAN)
8747 AC_SUBST(LIB_COMPILE)
8748 AC_SUBST(LIB_LINK)
8749 AC_SUBST(LIB_INSTALL)
8750 AC_SUBST(LIB_UNINSTALL)
8751
8752 ])dnl
8753 dnl ---------------------------------------------------------------------------
8754 dnl CF_WITH_LIBTOOL_OPTS version: 4 updated: 2015/04/17 21:13:04
8755 dnl --------------------
8756 dnl Allow user to pass additional libtool options into the library creation
8757 dnl and link steps.  The main use for this is to do something like
8758 dnl     ./configure --with-libtool-opts=-static
8759 dnl to get the same behavior as automake-flavored
8760 dnl     ./configure --enable-static
8761 AC_DEFUN([CF_WITH_LIBTOOL_OPTS],[
8762 AC_MSG_CHECKING(for additional libtool options)
8763 AC_ARG_WITH(libtool-opts,
8764         [  --with-libtool-opts=XXX specify additional libtool options],
8765         [with_libtool_opts=$withval],
8766         [with_libtool_opts=no])
8767 AC_MSG_RESULT($with_libtool_opts)
8768
8769 case .$with_libtool_opts in
8770 (.yes|.no|.)
8771         ;;
8772 (*)
8773         LIBTOOL_OPTS="$LIBTOOL_OPTS $with_libtool_opts"
8774         ;;
8775 esac
8776
8777 AC_SUBST(LIBTOOL_OPTS)
8778 ])dnl
8779 dnl ---------------------------------------------------------------------------
8780 dnl CF_WITH_LIB_BASENAME version: 1 updated: 2020/03/07 20:05:14
8781 dnl --------------------
8782 dnl Allow for overriding the basename of a library, i.e., the part to which
8783 dnl prefixes/suffixes are attached.
8784 dnl
8785 dnl $1 = variable to set
8786 dnl $2 = option name
8787 dnl $3 = default basename for library, if omitted use $2
8788 AC_DEFUN([CF_WITH_LIB_BASENAME],
8789 [
8790 AC_MSG_CHECKING(for desired basename for $2 library)
8791 AC_ARG_WITH($2-libname,
8792         [  --with-$2-libname=XXX override ifelse($3,,$2,$3) basename of library],
8793         [with_lib_basename=$withval],
8794         [with_lib_basename=ifelse($3,,$2,$3)])
8795 $1="$with_lib_basename"
8796
8797 case "x[$]$1" in
8798 (x|xno|xnone|xyes)
8799         $1=ifelse($3,,$2,$3)
8800         ;;
8801 (*)
8802         ;;
8803 esac
8804
8805 AC_MSG_RESULT([$]$1)
8806 AC_SUBST($1)
8807 ])dnl
8808 dnl ---------------------------------------------------------------------------
8809 dnl CF_WITH_LIB_PREFIX version: 2 updated: 2021/01/01 16:53:59
8810 dnl ------------------
8811 dnl Allow the library-prefix to be overridden.  OS/2 EMX originally had no
8812 dnl "lib" prefix, e.g., because it used the dll naming convention.
8813 dnl
8814 dnl $1 = variable to set
8815 AC_DEFUN([CF_WITH_LIB_PREFIX],
8816 [
8817 AC_MSG_CHECKING(if you want to have a library-prefix)
8818 AC_ARG_WITH(lib-prefix,
8819         [  --with-lib-prefix       override library-prefix],
8820         [with_lib_prefix=$withval],
8821         [with_lib_prefix=auto])
8822 AC_MSG_RESULT($with_lib_prefix)
8823
8824 if test "$with_lib_prefix" = auto
8825 then
8826         CF_LIB_PREFIX($1)
8827 elif test "$with_lib_prefix" = no
8828 then
8829         LIB_PREFIX=
8830 else
8831         LIB_PREFIX=$with_lib_prefix
8832 fi
8833 ])dnl
8834 dnl ---------------------------------------------------------------------------
8835 dnl CF_WITH_PATH version: 11 updated: 2012/09/29 15:04:19
8836 dnl ------------
8837 dnl Wrapper for AC_ARG_WITH to ensure that user supplies a pathname, not just
8838 dnl defaulting to yes/no.
8839 dnl
8840 dnl $1 = option name
8841 dnl $2 = help-text
8842 dnl $3 = environment variable to set
8843 dnl $4 = default value, shown in the help-message, must be a constant
8844 dnl $5 = default value, if it's an expression & cannot be in the help-message
8845 dnl
8846 AC_DEFUN([CF_WITH_PATH],
8847 [AC_ARG_WITH($1,[$2 ](default: ifelse([$4],,empty,[$4])),,
8848 ifelse([$4],,[withval="${$3}"],[withval="${$3:-ifelse([$5],,[$4],[$5])}"]))dnl
8849 if ifelse([$5],,true,[test -n "$5"]) ; then
8850 CF_PATH_SYNTAX(withval)
8851 fi
8852 eval $3="$withval"
8853 AC_SUBST($3)dnl
8854 ])dnl
8855 dnl ---------------------------------------------------------------------------
8856 dnl CF_WITH_PATHLIST version: 12 updated: 2021/01/01 13:31:04
8857 dnl ----------------
8858 dnl Process an option specifying a list of colon-separated paths.
8859 dnl
8860 dnl $1 = option name
8861 dnl $2 = help-text
8862 dnl $3 = environment variable to set
8863 dnl $4 = default value, shown in the help-message, must be a constant
8864 dnl $5 = default value, if it's an expression & cannot be in the help-message
8865 dnl $6 = flag to tell if we want to define or substitute
8866 dnl
8867 AC_DEFUN([CF_WITH_PATHLIST],[
8868 AC_REQUIRE([CF_PATHSEP])
8869 AC_ARG_WITH($1,[$2 ](default: ifelse($4,,empty,$4)),,
8870 ifelse($4,,[withval=${$3}],[withval=${$3:-ifelse($5,,$4,$5)}]))dnl
8871
8872 IFS="${IFS:-    }"; ac_save_ifs="$IFS"; IFS="${PATH_SEPARATOR}"
8873 cf_dst_path=
8874 for cf_src_path in $withval
8875 do
8876   CF_PATH_SYNTAX(cf_src_path)
8877   test -n "$cf_dst_path" && cf_dst_path="${cf_dst_path}$PATH_SEPARATOR"
8878   cf_dst_path="${cf_dst_path}${cf_src_path}"
8879 done
8880 IFS="$ac_save_ifs"
8881
8882 ifelse($6,define,[
8883 # Strip single quotes from the value, e.g., when it was supplied as a literal
8884 # for $4 or $5.
8885 case "$cf_dst_path" in
8886 (\'*)
8887   cf_dst_path="`echo "$cf_dst_path" |sed -e s/\'// -e s/\'\$//`"
8888   ;;
8889 esac
8890 cf_dst_path=`echo "$cf_dst_path" | sed -e 's/\\\\/\\\\\\\\/g'`
8891 ])
8892
8893 # This may use the prefix/exec_prefix symbols which will only yield "NONE"
8894 # so we have to check/work around.  We do prefer the result of "eval"...
8895 eval cf_dst_eval="$cf_dst_path"
8896 case "x$cf_dst_eval" in
8897 (xNONE*)
8898         $3=$cf_dst_path
8899         ;;
8900 (*)
8901         $3="$cf_dst_eval"
8902         ;;
8903 esac
8904 AC_SUBST($3)dnl
8905
8906 ])dnl
8907 dnl ---------------------------------------------------------------------------
8908 dnl CF_WITH_PATH_PROG version: 1 updated: 2019/06/30 19:44:43
8909 dnl -----------------
8910 dnl Check for a given program, like CF_PATH_PROG, but allow override using a
8911 dnl "--with-xxx" option.
8912 dnl
8913 dnl Parameters:
8914 dnl             $1 = environment variable to set/update
8915 dnl             $2 = program name
8916 dnl             $3 = help-text
8917 dnl             $4 = $PATH
8918 AC_DEFUN([CF_WITH_PATH_PROG],[
8919 AC_ARG_WITH($2-path,
8920         [  --with-$2-path=XXX     specify path of $2 ifelse($3,,,$3)],
8921         [AC_MSG_CHECKING(for $2 program ifelse($3,,,$3))
8922                 $1=$withval
8923                 AC_MSG_RESULT([$]$1)
8924                 CF_PATH_SYNTAX($1)
8925         ],
8926         [CF_PATH_PROG($1,$2,,ifelse($4,,,$4))
8927                 if test -z "[$]$1"
8928                 then
8929                         AC_MSG_WARN(no $2 program found ifelse($3,,,$3))
8930                 fi
8931         ])
8932 ])
8933 dnl ---------------------------------------------------------------------------
8934 dnl CF_WITH_PCRE2 version: 5 updated: 2021/01/26 18:45:12
8935 dnl -------------
8936 dnl Add PCRE2 (Perl-compatible regular expressions v2) to the build if it is
8937 dnl available and the user requests it.  Assume the application will otherwise
8938 dnl use the POSIX interface.
8939 dnl
8940 dnl TODO allow $withval to specify package location
8941 AC_DEFUN([CF_WITH_PCRE2],
8942 [
8943 AC_REQUIRE([CF_PKG_CONFIG])
8944
8945 AC_MSG_CHECKING(if you want to use PCRE2 for regular-expressions)
8946 AC_ARG_WITH(pcre2,
8947         [  --with-pcre2            use PCRE2 for regular-expressions])
8948 test -z "$with_pcre2" && with_pcre2=no
8949 AC_MSG_RESULT($with_pcre2)
8950
8951 if test "x$with_pcre2" != xno ; then
8952         cf_with_pcre2_ok=no
8953         for cf_with_pcre2 in libpcre2 libpcre2-posix libpcre
8954         do
8955                 CF_TRY_PKG_CONFIG($cf_with_pcre2,[cf_with_pcre2_ok=yes; break])
8956         done
8957         cf_with_pcre2_ok=yes || AC_MSG_ERROR(Cannot find PCRE2 library)
8958
8959         AC_DEFINE(HAVE_LIB_PCRE2,1,[Define to 1 if we can/should compile with the PCRE2 library])
8960
8961         # if pkgconfig gave no results, look for the libraries directly
8962         case "$LIBS" in
8963         (*pcre2-posix*|*pcreposix*)
8964                 ;;
8965         (*)
8966                 AC_CHECK_LIB(pcre2-posix,regcomp,[
8967                         CF_ADD_LIB(pcre2-posix)],
8968                         [AC_CHECK_LIB(pcreposix,regcomp,[
8969                          CF_ADD_LIB(pcreposix)
8970                         ],[AC_MSG_ERROR(Cannot find PCRE2 POSIX library)])])
8971                 ;;
8972         esac
8973
8974         # either way, check for the library header files
8975         AC_CHECK_HEADERS(pcre2posix.h pcreposix.h)
8976 fi
8977 ])dnl
8978 dnl ---------------------------------------------------------------------------
8979 dnl CF_WITH_PKG_CONFIG_LIBDIR version: 11 updated: 2021/01/01 16:16:30
8980 dnl -------------------------
8981 dnl Allow the choice of the pkg-config library directory to be overridden.
8982 AC_DEFUN([CF_WITH_PKG_CONFIG_LIBDIR],[
8983
8984 case "$PKG_CONFIG" in
8985 (no|none|yes)
8986         AC_MSG_CHECKING(for pkg-config library directory)
8987         ;;
8988 (*)
8989         AC_MSG_CHECKING(for $PKG_CONFIG library directory)
8990         ;;
8991 esac
8992
8993 PKG_CONFIG_LIBDIR=no
8994 AC_ARG_WITH(pkg-config-libdir,
8995         [  --with-pkg-config-libdir=XXX use given directory for installing pc-files],
8996         [PKG_CONFIG_LIBDIR=$withval],
8997         [test "x$PKG_CONFIG" != xnone && PKG_CONFIG_LIBDIR=yes])
8998
8999 case x$PKG_CONFIG_LIBDIR in
9000 (x/*)
9001         ;;
9002 (xyes)
9003         # Look for the library directory using the same prefix as the executable
9004         if test "x$PKG_CONFIG" = xnone
9005         then
9006                 cf_path=$prefix
9007         else
9008                 cf_path=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`
9009         fi
9010
9011         # If you don't like using the default architecture, you have to specify the
9012         # intended library directory and corresponding compiler/linker options.
9013         #
9014         # This case allows for Debian's 2014-flavor of multiarch, along with the
9015         # most common variations before that point.  Some other variants spell the
9016         # directory differently, e.g., "pkg-config", and put it in unusual places.
9017         # pkg-config has always been poorly standardized, which is ironic...
9018         case x`(arch) 2>/dev/null` in
9019         (*64)
9020                 cf_search_path="\
9021                         $cf_path/lib/*64-linux-gnu \
9022                         $cf_path/share \
9023                         $cf_path/lib64 \
9024                         $cf_path/lib32 \
9025                         $cf_path/lib"
9026                 ;;
9027         (*)
9028                 cf_search_path="\
9029                         $cf_path/lib/*-linux-gnu \
9030                         $cf_path/share \
9031                         $cf_path/lib32 \
9032                         $cf_path/lib \
9033                         $cf_path/libdata"
9034                 ;;
9035         esac
9036
9037         CF_VERBOSE(list...)
9038         for cf_config in $cf_search_path
9039         do
9040                 CF_VERBOSE(checking $cf_config/pkgconfig)
9041                 if test -d "$cf_config/pkgconfig"
9042                 then
9043                         PKG_CONFIG_LIBDIR=$cf_config/pkgconfig
9044                         AC_MSG_CHECKING(done)
9045                         break
9046                 fi
9047         done
9048         ;;
9049 (*)
9050         ;;
9051 esac
9052
9053 if test "x$PKG_CONFIG_LIBDIR" != xno ; then
9054         AC_MSG_RESULT($PKG_CONFIG_LIBDIR)
9055 fi
9056
9057 AC_SUBST(PKG_CONFIG_LIBDIR)
9058 ])dnl
9059 dnl ---------------------------------------------------------------------------
9060 dnl CF_WITH_PTHREAD version: 7 updated: 2015/04/18 08:56:57
9061 dnl ---------------
9062 dnl Check for POSIX thread library.
9063 AC_DEFUN([CF_WITH_PTHREAD],
9064 [
9065 AC_MSG_CHECKING(if you want to link with the pthread library)
9066 AC_ARG_WITH(pthread,
9067         [  --with-pthread          use POSIX thread library],
9068         [with_pthread=$withval],
9069         [with_pthread=no])
9070 AC_MSG_RESULT($with_pthread)
9071
9072 if test "$with_pthread" != no ; then
9073         AC_CHECK_HEADER(pthread.h,[
9074         AC_DEFINE(HAVE_PTHREADS_H,1,[Define to 1 if we have pthreads.h header])
9075
9076         for cf_lib_pthread in pthread c_r
9077         do
9078             AC_MSG_CHECKING(if we can link with the $cf_lib_pthread library)
9079             cf_save_LIBS="$LIBS"
9080             CF_ADD_LIB($cf_lib_pthread)
9081             AC_TRY_LINK([
9082 #include <pthread.h>
9083 ],[
9084                 int rc = pthread_create(0,0,0,0);
9085                 int r2 = pthread_mutexattr_settype(0, 0);
9086 ],[with_pthread=yes],[with_pthread=no])
9087             LIBS="$cf_save_LIBS"
9088             AC_MSG_RESULT($with_pthread)
9089             test "$with_pthread" = yes && break
9090         done
9091
9092         if test "$with_pthread" = yes ; then
9093             CF_ADD_LIB($cf_lib_pthread)
9094             AC_DEFINE(HAVE_LIBPTHREADS,1,[Define to 1 if we have pthreads library])
9095         else
9096             AC_MSG_ERROR(Cannot link with pthread library)
9097         fi
9098         ])
9099 fi
9100 ])
9101 dnl ---------------------------------------------------------------------------
9102 dnl CF_WITH_REL_VERSION version: 1 updated: 2003/09/20 18:12:49
9103 dnl -------------------
9104 dnl Allow library's release-version to be overridden.  Generally this happens when a
9105 dnl packager has incremented the release-version past that used in the original package,
9106 dnl and wishes to keep doing this.
9107 dnl
9108 dnl $1 is the package name, if any, to derive corresponding {package}_MAJOR
9109 dnl and {package}_MINOR symbols
9110 dnl symbol.
9111 AC_DEFUN([CF_WITH_REL_VERSION],[
9112 test -z "$cf_cv_rel_version" && cf_cv_rel_version=0.0
9113 AC_ARG_WITH(rel-version,
9114 [  --with-rel-version=XXX  override derived release version],
9115 [AC_MSG_WARN(overriding release version $cf_cv_rel_version to $withval)
9116  cf_cv_rel_version=$withval])
9117 ifelse($1,,[
9118  CF_NUMBER_SYNTAX($cf_cv_rel_version,Release version)
9119 ],[
9120  $1_MAJOR=`echo "$cf_cv_rel_version" | sed -e 's/\..*//'`
9121  $1_MINOR=`echo "$cf_cv_rel_version" | sed -e 's/^[[^.]]*//' -e 's/^\.//' -e 's/\..*//'`
9122  CF_NUMBER_SYNTAX([$]$1_MAJOR,Release major-version)
9123  CF_NUMBER_SYNTAX([$]$1_MINOR,Release minor-version)
9124 ])
9125 ])dnl
9126 dnl ---------------------------------------------------------------------------
9127 dnl CF_WITH_SYSMOUSE version: 3 updated: 2012/10/06 17:56:13
9128 dnl ----------------
9129 dnl If we can compile with sysmouse, make it available unless it is not wanted.
9130 AC_DEFUN([CF_WITH_SYSMOUSE],[
9131 # not everyone has "test -c"
9132 if test -c /dev/sysmouse 2>/dev/null ; then
9133 AC_MSG_CHECKING(if you want to use sysmouse)
9134 AC_ARG_WITH(sysmouse,
9135         [  --with-sysmouse         use sysmouse (FreeBSD console)],
9136         [cf_with_sysmouse=$withval],
9137         [cf_with_sysmouse=maybe])
9138         if test "$cf_with_sysmouse" != no ; then
9139         AC_TRY_COMPILE([
9140 #include <osreldate.h>
9141 #if (__FreeBSD_version >= 400017)
9142 #include <sys/consio.h>
9143 #include <sys/fbio.h>
9144 #else
9145 #include <machine/console.h>
9146 #endif
9147 ],[
9148         struct mouse_info the_mouse;
9149         ioctl(0, CONS_MOUSECTL, &the_mouse);
9150 ],[cf_with_sysmouse=yes],[cf_with_sysmouse=no])
9151         fi
9152 AC_MSG_RESULT($cf_with_sysmouse)
9153 test "$cf_with_sysmouse" = yes && AC_DEFINE(USE_SYSMOUSE,1,[Define to 1 if we can/should use the sysmouse interface])
9154 fi
9155 ])dnl
9156 dnl ---------------------------------------------------------------------------
9157 dnl CF_WITH_SYSTYPE version: 1 updated: 2013/01/26 16:26:12
9158 dnl ---------------
9159 dnl For testing, override the derived host system-type which is used to decide
9160 dnl things such as the linker commands used to build shared libraries.  This is
9161 dnl normally chosen automatically based on the type of system which you are
9162 dnl building on.  We use it for testing the configure script.
9163 dnl
9164 dnl This is different from the --host option: it is used only for testing parts
9165 dnl of the configure script which would not be reachable with --host since that
9166 dnl relies on the build environment being real, rather than mocked up.
9167 AC_DEFUN([CF_WITH_SYSTYPE],[
9168 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
9169 AC_ARG_WITH(system-type,
9170         [  --with-system-type=XXX  test: override derived host system-type],
9171 [AC_MSG_WARN(overriding system type to $withval)
9172         cf_cv_system_name=$withval
9173         host_os=$withval
9174 ])
9175 ])dnl
9176 dnl ---------------------------------------------------------------------------
9177 dnl CF_WITH_VALGRIND version: 1 updated: 2006/12/14 18:00:21
9178 dnl ----------------
9179 AC_DEFUN([CF_WITH_VALGRIND],[
9180 CF_NO_LEAKS_OPTION(valgrind,
9181         [  --with-valgrind         test: use valgrind],
9182         [USE_VALGRIND])
9183 ])dnl
9184 dnl ---------------------------------------------------------------------------
9185 dnl CF_WITH_VERSIONED_SYMS version: 10 updated: 2021/01/04 18:48:01
9186 dnl ----------------------
9187 dnl Use this when building shared library with ELF, to markup symbols with the
9188 dnl version identifier from the given input file.  Generally that identifier is
9189 dnl the same as the SONAME at which the symbol was first introduced.
9190 dnl
9191 dnl $1 = basename of the ".map" file (default $PACKAGE)
9192 AC_DEFUN([CF_WITH_VERSIONED_SYMS],
9193 [AC_REQUIRE([AC_PROG_FGREP])dnl
9194 AC_REQUIRE([AC_PROG_EGREP])dnl
9195
9196 AC_MSG_CHECKING(if versioned-symbols file should be used)
9197 AC_ARG_WITH(versioned-syms,
9198         [  --with-versioned-syms=X markup versioned symbols using ld],
9199         [with_versioned_syms=$withval],
9200         [with_versioned_syms=no])
9201 case "x$with_versioned_syms" in
9202 (xyes)
9203         with_versioned_syms='${top_srcdir}/package/ifelse($1,,${PACKAGE},[$1]).map'
9204         AC_SUBST(PACKAGE)
9205         ;;
9206 (xno)
9207         ;;
9208 (x/*)
9209         test -f "$with_versioned_syms" || AC_MSG_ERROR(expected a filename: $with_versioned_syms)
9210         ;;
9211 (*)
9212         test -f "$with_versioned_syms" || AC_MSG_ERROR(expected a filename: $with_versioned_syms)
9213         with_versioned_syms=`pwd`/"$with_versioned_syms"
9214         ;;
9215 esac
9216 AC_MSG_RESULT($with_versioned_syms)
9217
9218 RESULTING_SYMS=
9219 VERSIONED_SYMS=
9220 WILDCARD_SYMS=
9221
9222 if test "x$with_versioned_syms" != xno
9223 then
9224         RESULTING_SYMS=$with_versioned_syms
9225         case "x$MK_SHARED_LIB" in
9226         (*-Wl,*)
9227                 VERSIONED_SYMS="-Wl,--version-script,\${RESULTING_SYMS}"
9228                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-Wl,%\\[$]{VERSIONED_SYMS} -Wl,%"`
9229                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
9230                 ;;
9231         (*-dy\ *)
9232                 VERSIONED_SYMS="-Wl,-M,\${RESULTING_SYMS}"
9233                 MK_SHARED_LIB=`echo "$MK_SHARED_LIB" | sed -e "s%-dy%\\[$]{VERSIONED_SYMS} -dy%"`
9234                 CF_VERBOSE(MK_SHARED_LIB:  $MK_SHARED_LIB)
9235                 ;;
9236         (*)
9237                 AC_MSG_WARN(this system does not support versioned-symbols)
9238                 ;;
9239         esac
9240
9241         # Linux ld can selectively override scope, e.g., of symbols beginning with
9242         # "_" by first declaring some as global, and then using a wildcard to
9243         # declare the others as local.  Some other loaders cannot do this.  Check
9244         # by constructing a (very) simple shared library and inspecting its
9245         # symbols.
9246         if test "x$VERSIONED_SYMS" != "x"
9247         then
9248                 AC_MSG_CHECKING(if wildcards can be used to selectively omit symbols)
9249                 WILDCARD_SYMS=no
9250
9251                 # make sources
9252                 rm -f conftest.*
9253
9254                 cat >conftest.ver <<EOF
9255 module_1.0 {
9256 global:
9257         globalf1;
9258 local:
9259         localf1;
9260 };
9261 module_2.0 {
9262 global:
9263         globalf2;
9264 local:
9265         localf2;
9266         _*;
9267 } module_1.0;
9268 submodule_1.0 {
9269 global:
9270         subglobalf1;
9271         _ismissing;
9272 local:
9273         sublocalf1;
9274 };
9275 submodule_2.0 {
9276 global:
9277         subglobalf2;
9278 local:
9279         sublocalf2;
9280         _*;
9281 } submodule_1.0;
9282 EOF
9283                 cat >conftest.$ac_ext <<EOF
9284 #line __oline__ "configure"
9285 int     _ismissing(void) { return 1; }
9286 int     _localf1(void) { return 1; }
9287 int     _localf2(void) { return 2; }
9288 int     globalf1(void) { return 1; }
9289 int     globalf2(void) { return 2; }
9290 int     _sublocalf1(void) { return 1; }
9291 int     _sublocalf2(void) { return 2; }
9292 int     subglobalf1(void) { return 1; }
9293 int     subglobalf2(void) { return 2; }
9294 EOF
9295                 cat >conftest.mk <<EOF
9296 CC=${CC}
9297 CFLAGS=${CFLAGS}
9298 CPPFLAGS=${CPPFLAGS}
9299 LDFLAGS=${LDFLAGS}
9300 LIBS=${LIBS}
9301 VERSIONED_SYMS=${VERSIONED_SYMS}
9302 RESULTING_SYMS=conftest.ver
9303 MK_SHARED_LIB=${MK_SHARED_LIB}
9304 conftest.so: conftest.$ac_cv_objext
9305                 \$(MK_SHARED_LIB) conftest.$ac_cv_objext
9306 EOF
9307
9308                 # compile source, make library
9309                 if make -f conftest.mk 2>&AC_FD_CC >/dev/null
9310                 then
9311                         # test for missing symbol in either Data or Text section
9312                         cf_missing="`nm -P conftest.so 2>&AC_FD_CC |${FGREP-fgrep} _ismissing | ${EGREP-egrep} '[[      ]][[DT]][[      ]]'`"
9313                         test -n "$cf_missing" && WILDCARD_SYMS=yes
9314                 fi
9315                 AC_MSG_RESULT($WILDCARD_SYMS)
9316                 rm -f conftest.*
9317         fi
9318 fi
9319 AC_SUBST(RESULTING_SYMS)
9320 AC_SUBST(VERSIONED_SYMS)
9321 AC_SUBST(WILDCARD_SYMS)
9322 ])dnl
9323 dnl ---------------------------------------------------------------------------
9324 dnl CF_WITH_X11_RGB version: 2 updated: 2019/12/31 08:53:54
9325 dnl ---------------
9326 dnl Handle configure option "--with-x11-rgb", setting these shell
9327 dnl variables:
9328 dnl
9329 dnl $RGB_PATH is the option value, used for finding the X11 rgb file.
9330 dnl $no_x11_rgb is a "#" (comment) if "--without-x11-rgb" is given.
9331 dnl
9332 dnl Most Linux's use this:
9333 dnl     /usr/share/X11/rgb.txt
9334 dnl Debian uses this:
9335 dnl     /etc/X11/rgb.txt
9336 dnl DragonFlyBSD ports uses this:
9337 dnl     /usr/pkg/lib/X11/rgb.txt
9338 dnl FreeBSD ports use these:
9339 dnl     /usr/local/lib/X11/rgb.txt
9340 dnl     /usr/local/share/X11/rgb.txt
9341 dnl Mandriva has these:
9342 dnl     /usr/lib/X11/rgb.txt
9343 dnl     /usr/lib64/X11/rgb.txt
9344 dnl NetBSD has these
9345 dnl     /usr/X11R7/lib/X11/rgb.txt
9346 dnl OpenSolaris uses
9347 dnl     32-bit:
9348 dnl     /usr/X11/etc/X11/rgb.txt
9349 dnl     /usr/X11/share/X11/rgb.txt
9350 dnl     /usr/X11/lib/X11/rgb.txt
9351 dnl OSX uses
9352 dnl             /opt/local/share/X11/rgb.txt (MacPorts)
9353 dnl             /opt/X11/share/X11/rgb.txt (non-ports)
9354 dnl     64-bit:
9355 dnl     /usr/X11/etc/X11/rgb.txt
9356 dnl     /usr/X11/share/X11/rgb.txt (perhaps)
9357 dnl     /usr/X11/lib/amd64/X11/rgb.txt
9358 dnl Solaris10 uses (in this order):
9359 dnl     /usr/openwin/lib/X11/rgb.txt
9360 dnl     /usr/X11/lib/X11/rgb.txt
9361 AC_DEFUN([CF_WITH_X11_RGB],[
9362 AC_MSG_CHECKING(for X11 rgb file)
9363 AC_ARG_WITH(x11-rgb,
9364         [  --with-x11-rgb=FILE   file containing X11 rgb information (EPREFIX/lib/X11/rgb.txt)],
9365         [RGB_PATH=$withval],
9366         [RGB_PATH=auto])
9367
9368 if test "x[$]RGB_PATH" = xauto
9369 then
9370         RGB_PATH='${exec_prefix}/lib/X11/rgb.txt'
9371         for cf_path in \
9372                 /opt/local/share/X11/rgb.txt \
9373                 /opt/X11/share/X11/rgb.txt \
9374                 /usr/share/X11/rgb.txt \
9375                 /usr/X11/share/X11/rgb.txt \
9376                 /usr/X11/lib/X11/rgb.txt \
9377                 /usr/lib/X11/rgb.txt \
9378                 /etc/X11/rgb.txt \
9379                 /usr/pkg/lib/X11/rgb.txt \
9380                 /usr/X11R7/lib/X11/rgb.txt \
9381                 /usr/X11R6/lib/X11/rgb.txt \
9382                 /usr/X11R5/lib/X11/rgb.txt \
9383                 /usr/X11R4/lib/X11/rgb.txt \
9384                 /usr/local/lib/X11/rgb.txt \
9385                 /usr/local/share/X11/rgb.txt \
9386                 /usr/lib64/X11/rgb.txt
9387         do
9388                 if test -f "$cf_path" ; then
9389                         RGB_PATH="$cf_path"
9390                         break
9391                 fi
9392         done
9393 else
9394         cf_path=$RGB_PATH
9395         CF_PATH_SYNTAX(cf_path)
9396 fi
9397
9398 AC_MSG_RESULT($RGB_PATH)
9399 AC_SUBST(RGB_PATH)
9400 AC_DEFINE_UNQUOTED(RGB_PATH,"$cf_path",[Define to the full pathname of rgb.txt])
9401
9402 no_x11_rgb=
9403 if test "$RGB_PATH" = no
9404 then
9405         no_x11_rgb="#"
9406 fi
9407 AC_SUBST(no_x11_rgb)
9408 ])dnl
9409 dnl ---------------------------------------------------------------------------
9410 dnl CF_XOPEN_SOURCE version: 57 updated: 2021/01/01 16:53:59
9411 dnl ---------------
9412 dnl Try to get _XOPEN_SOURCE defined properly that we can use POSIX functions,
9413 dnl or adapt to the vendor's definitions to get equivalent functionality,
9414 dnl without losing the common non-POSIX features.
9415 dnl
9416 dnl Parameters:
9417 dnl     $1 is the nominal value for _XOPEN_SOURCE
9418 dnl     $2 is the nominal value for _POSIX_C_SOURCE
9419 AC_DEFUN([CF_XOPEN_SOURCE],[
9420 AC_REQUIRE([AC_CANONICAL_HOST])
9421 AC_REQUIRE([CF_POSIX_VISIBLE])
9422
9423 if test "$cf_cv_posix_visible" = no; then
9424
9425 cf_XOPEN_SOURCE=ifelse([$1],,500,[$1])
9426 cf_POSIX_C_SOURCE=ifelse([$2],,199506L,[$2])
9427 cf_xopen_source=
9428
9429 case "$host_os" in
9430 (aix[[4-7]]*)
9431         cf_xopen_source="-D_ALL_SOURCE"
9432         ;;
9433 (msys)
9434         cf_XOPEN_SOURCE=600
9435         ;;
9436 (darwin[[0-8]].*)
9437         cf_xopen_source="-D_APPLE_C_SOURCE"
9438         ;;
9439 (darwin*)
9440         cf_xopen_source="-D_DARWIN_C_SOURCE"
9441         cf_XOPEN_SOURCE=
9442         ;;
9443 (freebsd*|dragonfly*|midnightbsd*)
9444         # 5.x headers associate
9445         #       _XOPEN_SOURCE=600 with _POSIX_C_SOURCE=200112L
9446         #       _XOPEN_SOURCE=500 with _POSIX_C_SOURCE=199506L
9447         cf_POSIX_C_SOURCE=200112L
9448         cf_XOPEN_SOURCE=600
9449         cf_xopen_source="-D_BSD_TYPES -D__BSD_VISIBLE -D_POSIX_C_SOURCE=$cf_POSIX_C_SOURCE -D_XOPEN_SOURCE=$cf_XOPEN_SOURCE"
9450         ;;
9451 (hpux11*)
9452         cf_xopen_source="-D_HPUX_SOURCE -D_XOPEN_SOURCE=500"
9453         ;;
9454 (hpux*)
9455         cf_xopen_source="-D_HPUX_SOURCE"
9456         ;;
9457 (irix[[56]].*)
9458         cf_xopen_source="-D_SGI_SOURCE"
9459         cf_XOPEN_SOURCE=
9460         ;;
9461 (linux*|uclinux*|gnu*|mint*|k*bsd*-gnu|cygwin)
9462         CF_GNU_SOURCE($cf_XOPEN_SOURCE)
9463         ;;
9464 (minix*)
9465         cf_xopen_source="-D_NETBSD_SOURCE" # POSIX.1-2001 features are ifdef'd with this...
9466         ;;
9467 (mirbsd*)
9468         # setting _XOPEN_SOURCE or _POSIX_SOURCE breaks <sys/select.h> and other headers which use u_int / u_short types
9469         cf_XOPEN_SOURCE=
9470         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
9471         ;;
9472 (netbsd*)
9473         cf_xopen_source="-D_NETBSD_SOURCE" # setting _XOPEN_SOURCE breaks IPv6 for lynx on NetBSD 1.6, breaks xterm, is not needed for ncursesw
9474         ;;
9475 (openbsd[[4-9]]*)
9476         # setting _XOPEN_SOURCE lower than 500 breaks g++ compile with wchar.h, needed for ncursesw
9477         cf_xopen_source="-D_BSD_SOURCE"
9478         cf_XOPEN_SOURCE=600
9479         ;;
9480 (openbsd*)
9481         # setting _XOPEN_SOURCE breaks xterm on OpenBSD 2.8, is not needed for ncursesw
9482         ;;
9483 (osf[[45]]*)
9484         cf_xopen_source="-D_OSF_SOURCE"
9485         ;;
9486 (nto-qnx*)
9487         cf_xopen_source="-D_QNX_SOURCE"
9488         ;;
9489 (sco*)
9490         # setting _XOPEN_SOURCE breaks Lynx on SCO Unix / OpenServer
9491         ;;
9492 (solaris2.*)
9493         cf_xopen_source="-D__EXTENSIONS__"
9494         cf_cv_xopen_source=broken
9495         ;;
9496 (sysv4.2uw2.*) # Novell/SCO UnixWare 2.x (tested on 2.1.2)
9497         cf_XOPEN_SOURCE=
9498         cf_POSIX_C_SOURCE=
9499         ;;
9500 (*)
9501         CF_TRY_XOPEN_SOURCE
9502         CF_POSIX_C_SOURCE($cf_POSIX_C_SOURCE)
9503         ;;
9504 esac
9505
9506 if test -n "$cf_xopen_source" ; then
9507         CF_ADD_CFLAGS($cf_xopen_source,true)
9508 fi
9509
9510 dnl In anything but the default case, we may have system-specific setting
9511 dnl which is still not guaranteed to provide all of the entrypoints that
9512 dnl _XOPEN_SOURCE would yield.
9513 if test -n "$cf_XOPEN_SOURCE" && test -z "$cf_cv_xopen_source" ; then
9514         AC_MSG_CHECKING(if _XOPEN_SOURCE really is set)
9515         AC_TRY_COMPILE([#include <stdlib.h>],[
9516 #ifndef _XOPEN_SOURCE
9517 make an error
9518 #endif],
9519         [cf_XOPEN_SOURCE_set=yes],
9520         [cf_XOPEN_SOURCE_set=no])
9521         AC_MSG_RESULT($cf_XOPEN_SOURCE_set)
9522         if test "$cf_XOPEN_SOURCE_set" = yes
9523         then
9524                 AC_TRY_COMPILE([#include <stdlib.h>],[
9525 #if (_XOPEN_SOURCE - 0) < $cf_XOPEN_SOURCE
9526 make an error
9527 #endif],
9528                 [cf_XOPEN_SOURCE_set_ok=yes],
9529                 [cf_XOPEN_SOURCE_set_ok=no])
9530                 if test "$cf_XOPEN_SOURCE_set_ok" = no
9531                 then
9532                         AC_MSG_WARN(_XOPEN_SOURCE is lower than requested)
9533                 fi
9534         else
9535                 CF_TRY_XOPEN_SOURCE
9536         fi
9537 fi
9538 fi # cf_cv_posix_visible
9539 ])
9540 dnl ---------------------------------------------------------------------------
9541 dnl CF__SED_TRIMBLANKS version: 1 updated: 2021/01/02 09:31:20
9542 dnl ------------------
9543 dnl Trim something using sed, then trim extra whitespace
9544 dnl $1 = extra parameters, e.g., in CF_STRIP_G_OPT
9545 define([CF__SED_TRIMBLANKS],[sed ifelse($1,,,[$1] )-e 's%[[     ]]% %g' -e 's% [[ ]]*% %g' -e 's%^ %%' -e 's% [$]%%'])dnl