configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2010,2011 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: configure.in,v 1.534 2011/12/17 21:12:37 tom Exp $
  32 dnl Process this file with autoconf to produce a configure script.
  33 dnl
  34 dnl See http://invisible-island.net/autoconf/ for additional information.
  35 dnl
  36 dnl ---------------------------------------------------------------------------
  37 AC_PREREQ(2.13.20020210)
  38 AC_REVISION($Revision: 1.534 $)
  39 AC_INIT(ncurses/base/lib_initscr.c)
  40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  41
  42 CF_TOP_BUILDDIR
  43 CF_SUBST_NCURSES_VERSION
  44
  45 CF_WITH_REL_VERSION(NCURSES)
  46 CF_WITH_ABI_VERSION
  47
  48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
  49 AC_ARG_WITH(system-type,
  50 [  --with-system-type=XXX  test: override derived host system-type],
  51 [AC_MSG_WARN(overriding system type to $withval)
  52  cf_cv_system_name=$withval])
  53
  54 ###     Save the given $CFLAGS to allow user-override.
  55 cf_user_CFLAGS="$CFLAGS"
  56
  57 ###     Default install-location
  58 CF_CFG_DEFAULTS
  59
  60 ###     Checks for programs.
  61 AC_PROG_CC
  62 CF_GCC_VERSION
  63
  64 AC_PROG_CPP
  65 AC_PROG_GCC_TRADITIONAL
  66 CF_PROG_CC_C_O(CC)
  67 AC_ISC_POSIX
  68 CF_ANSI_CC_REQD
  69 CF_PROG_EXT
  70 CF_PROG_LDCONFIG
  71
  72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  73 dnl                             configure script by not letting us test if C++
  74 dnl                             is present, making this option necessary.
  75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  76 AC_ARG_WITH(cxx,
  77         [  --without-cxx           do not adjust ncurses bool to match C++],
  78         [cf_with_cxx=$withval],
  79         [cf_with_cxx=yes])
  80 AC_MSG_RESULT($cf_with_cxx)
  81 if test "X$cf_with_cxx" = Xno ; then
  82         CXX=""
  83         GXX=""
  84 else
  85         # with autoconf 2.13, we can change the error to a warning:
  86         pushdef([AC_MSG_ERROR],
  87                 [AC_MSG_RESULT(no)
  88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
  89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
  90         AC_PROG_CXX
  91         popdef([AC_MSG_ERROR])dnl
  92         # autoconf 2.5x removed the error - by hardcoding it to g++.
  93         if test "$CXX" = "g++" ; then
  94                 AC_PATH_PROG(CXX,g++)
  95         fi
  96         if test "$CXX" = "g++" ; then
  97                 AC_MSG_WARN(ignoring hardcoded g++)
  98                 cf_with_cxx=no; CXX=""; GXX="";
  99         fi
 100 fi
 101
 102 CF_GXX_VERSION
 103 case $GXX_VERSION in
 104 1*|2.[[0-6]]*)
 105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
 106         # cf_cxx_library=no
 107         AC_MSG_WARN(templates do not work)
 108         ;;
 109 esac
 110
 111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 112 AC_ARG_WITH(cxx-binding,
 113         [  --without-cxx-binding   do not build C++ binding and demo],
 114         [cf_with_cxx_binding=$withval],
 115         [cf_with_cxx_binding=$cf_with_cxx])
 116 AC_MSG_RESULT($cf_with_cxx_binding)
 117
 118 AC_MSG_CHECKING(if you want to build with Ada95)
 119 AC_ARG_WITH(ada,
 120         [  --without-ada           suppress check for Ada95, don't build demo],
 121         [cf_with_ada=$withval],
 122         [cf_with_ada=yes])
 123 AC_MSG_RESULT($cf_with_ada)
 124
 125 AC_MSG_CHECKING(if you want to install manpages)
 126 AC_ARG_WITH(manpages,
 127         [  --without-manpages      suppress install of manpages],
 128         [cf_with_manpages=$withval],
 129         [cf_with_manpages=yes])
 130 AC_MSG_RESULT($cf_with_manpages)
 131
 132 AC_MSG_CHECKING(if you want to build programs such as tic)
 133 AC_ARG_WITH(progs,
 134         [  --without-progs         suppress build with programs (e.g., tic)],
 135         [cf_with_progs=$withval],
 136         [cf_with_progs=yes])
 137 AC_MSG_RESULT($cf_with_progs)
 138
 139 AC_MSG_CHECKING(if you want to build test-programs)
 140 AC_ARG_WITH(tests,
 141         [  --without-tests         suppress build with test-programs],
 142         [cf_with_tests=$withval],
 143         [cf_with_tests=yes])
 144 AC_MSG_RESULT($cf_with_tests)
 145
 146 AC_MSG_CHECKING(if you wish to install curses.h)
 147 AC_ARG_WITH(curses-h,
 148         [  --without-curses-h      install curses.h as ncurses.h only],
 149         [with_curses_h=$withval],
 150         [with_curses_h=yes])
 151 AC_MSG_RESULT($with_curses_h)
 152
 153 modules_to_build="ncurses"
 154 if test "X$cf_with_progs" != Xno ; then
 155 modules_to_build="$modules_to_build progs tack"
 156 fi
 157 modules_to_build="$modules_to_build panel menu form"
 158
 159 AC_ARG_PROGRAM
 160
 161 CF_PROG_AWK
 162 CF_PROG_EGREP
 163 CF_PROG_INSTALL
 164 CF_PROG_LINT
 165 CF_PROG_LN_S
 166
 167 AC_SYS_LONG_FILE_NAMES
 168
 169 # if we find pkg-config, check if we should install the ".pc" files.
 170 CF_PKG_CONFIG
 171 CF_WITH_PKG_CONFIG_LIBDIR
 172 CF_ENABLE_PC_FILES
 173
 174 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 175 AC_ARG_ENABLE(mixed-case,
 176         [  --enable-mixed-case     tic should assume mixed-case filenames],
 177         [enable_mixedcase=$enableval],
 178         [enable_mixedcase=auto])
 179 AC_MSG_RESULT($enable_mixedcase)
 180 if test "$enable_mixedcase" = "auto" ; then
 181     CF_MIXEDCASE_FILENAMES
 182 else
 183     cf_cv_mixedcase=$enable_mixedcase
 184     if test "$enable_mixedcase" = "yes" ; then
 185         AC_DEFINE(MIXEDCASE_FILENAMES)
 186     fi
 187 fi
 188
 189 # do this after mixed-case option (tags/TAGS is not as important as tic).
 190 AC_PROG_MAKE_SET
 191 CF_MAKE_TAGS
 192 CF_MAKEFLAGS
 193
 194 dnl These are standard among *NIX systems, but not when cross-compiling
 195 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 196 AC_CHECK_TOOL(LD, ld, ld)
 197 AC_CHECK_TOOL(AR, ar, ar)
 198 CF_AR_FLAGS
 199
 200 dnl Special option for use by system-builders: the install-prefix is used to
 201 dnl adjust the location into which the actual install is done, so that an
 202 dnl archive can be built without modifying the host system's configuration.
 203 AC_MSG_CHECKING(if you have specified an install-prefix)
 204 AC_ARG_WITH(install-prefix,
 205         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 206         [case "$withval" in #(vi
 207         yes|no) #(vi
 208                 ;;
 209         *)      DESTDIR="$withval"
 210                 ;;
 211         esac])
 212 AC_MSG_RESULT($DESTDIR)
 213 AC_SUBST(DESTDIR)
 214
 215 ###############################################################################
 216 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 217 # If we're cross-compiling, allow the user to override the tools and their
 218 # options.  The configure script is oriented toward identifying the host
 219 # compiler, etc., but we need a build compiler to generate parts of the source.
 220 CF_BUILD_CC
 221
 222 ###############################################################################
 223 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 224
 225 ### Options to allow the user to specify the set of libraries which are used.
 226 ### Use "--without-normal --with-shared" to allow the default model to be
 227 ### shared, for example.
 228 cf_list_models=""
 229 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 230
 231 CF_WITH_LIBTOOL
 232 if test "$with_libtool" != "no" ; then
 233
 234 cf_list_models="$cf_list_models libtool"
 235
 236 else
 237
 238 AC_MSG_CHECKING(if you want to build shared libraries)
 239 AC_ARG_WITH(shared,
 240         [  --with-shared           generate shared-libraries],
 241         [with_shared=$withval],
 242         [with_shared=no])
 243 AC_MSG_RESULT($with_shared)
 244 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
 245
 246 AC_MSG_CHECKING(if you want to build static libraries)
 247 AC_ARG_WITH(normal,
 248         [  --with-normal           generate normal-libraries (default)],
 249         [with_normal=$withval],
 250         [with_normal=yes])
 251 AC_MSG_RESULT($with_normal)
 252 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
 253
 254 AC_MSG_CHECKING(if you want to build debug libraries)
 255 AC_ARG_WITH(debug,
 256         [  --with-debug            generate debug-libraries (default)],
 257         [with_debug=$withval],
 258         [with_debug=yes])
 259 AC_MSG_RESULT($with_debug)
 260 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
 261
 262 AC_MSG_CHECKING(if you want to build profiling libraries)
 263 AC_ARG_WITH(profile,
 264         [  --with-profile          generate profile-libraries],
 265         [with_profile=$withval],
 266         [with_profile=no])
 267 AC_MSG_RESULT($with_profile)
 268 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
 269
 270 fi
 271
 272 ###############################################################################
 273
 274 AC_MSG_CHECKING(for specified models)
 275 test -z "$cf_list_models" && cf_list_models=normal
 276 dnl If we use libtool to generate libraries, then it must be the only
 277 dnl specified model.
 278 test "$with_libtool" != "no" && cf_list_models=libtool
 279 AC_MSG_RESULT($cf_list_models)
 280
 281 ### Use the first model as the default, and save its suffix for use in building
 282 ### up test-applications.
 283 AC_MSG_CHECKING(for default model)
 284 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 285 AC_MSG_RESULT($DFT_LWR_MODEL)
 286
 287 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 288
 289 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 290 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 291
 292 TICS_NAME=tic
 293 AC_SUBST(TICS_NAME)
 294
 295 TINFO_NAME=tinfo
 296 AC_SUBST(TINFO_NAME)
 297
 298 LIB_NAME=ncurses
 299 AC_SUBST(LIB_NAME)
 300
 301 LIB_DIR=../lib
 302 LIB_2ND=../../lib
 303
 304 CF_LIB_PREFIX(cf_prefix)
 305 LIB_PREFIX=$cf_prefix
 306 AC_SUBST(LIB_PREFIX)
 307
 308 LIB_SUFFIX=
 309 AC_SUBST(LIB_SUFFIX)
 310
 311 ###############################################################################
 312
 313 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 314 AC_ARG_WITH(termlib,
 315         [  --with-termlib          generate separate terminfo library],
 316         [with_termlib=$withval],
 317         [with_termlib=no])
 318 AC_MSG_RESULT($with_termlib)
 319
 320 AC_MSG_CHECKING(if you want to build a separate tic library)
 321 AC_ARG_WITH(ticlib,
 322         [  --with-ticlib           generate separate tic library],
 323         [with_ticlib=$withval],
 324         [with_ticlib=no])
 325 AC_MSG_RESULT($with_ticlib)
 326
 327 ### Checks for special libraries, must be done up-front.
 328 SHLIB_LIST=""
 329 CF_WITH_GPM
 330 if test "$with_gpm" != no ; then
 331         AC_MSG_CHECKING(if you want to load GPM dynamically)
 332         AC_ARG_WITH(dlsym,
 333                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 334                 [with_dlsym=$withval],
 335                 [with_dlsym=yes])
 336         AC_MSG_RESULT($with_dlsym)
 337         if test "$with_dlsym" = yes ; then
 338                 CF_FUNC_DLSYM
 339                 if test "$with_gpm" != yes ; then
 340                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 341                         cf_cv_gpm_soname="$with_gpm"
 342                 else
 343                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 344                 fi
 345                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
 346                 SHLIB_LIST="-ldl $SHLIB_LIST"
 347         else
 348                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 349                 CF_ADD_LIB(gpm,TEST_LIBS)
 350         fi
 351         AC_DEFINE(HAVE_LIBGPM)
 352         CF_CHECK_GPM_WGETCH
 353 fi
 354
 355 CF_WITH_SYSMOUSE
 356
 357 dnl Not all ports of gcc support the -g option
 358
 359 if test X"$CC_G_OPT" = X"" ; then
 360         CC_G_OPT='-g'
 361         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
 362 fi
 363 AC_SUBST(CC_G_OPT)
 364
 365 if test X"$CXX_G_OPT" = X"" ; then
 366         CXX_G_OPT='-g'
 367         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
 368 fi
 369 AC_SUBST(CXX_G_OPT)
 370
 371 AC_MSG_CHECKING(for default loader flags)
 372 case $DFT_LWR_MODEL in
 373 libtool) LD_MODEL=''   ;;
 374 normal)  LD_MODEL=''   ;;
 375 debug)   LD_MODEL=$CC_G_OPT ;;
 376 profile) LD_MODEL='-pg';;
 377 shared)  LD_MODEL=''   ;;
 378 esac
 379 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 380 AC_MSG_RESULT($LD_MODEL)
 381
 382 case $DFT_LWR_MODEL in
 383 shared)
 384 CF_ENABLE_RPATH
 385 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 386 AC_ARG_ENABLE(relink,
 387 [  --disable-relink        relink shared libraries during install],
 388 [cf_cv_do_relink=$enableval],
 389 [cf_cv_do_relink=yes])
 390 AC_MSG_RESULT($cf_cv_do_relink)
 391         ;;
 392 esac
 393
 394 CF_SHARED_OPTS
 395 if test "$CC_SHARED_OPTS" = "unknown"; then
 396         for model in $cf_list_models; do
 397                 if test "$model" = "shared"; then
 398                         AC_ERROR(Shared libraries are not supported in this version)
 399                 fi
 400         done
 401 fi
 402
 403 ### If we're building with rpath, try to link non-standard libs that way too.
 404 if test "$DFT_LWR_MODEL" = "shared"; then
 405         CF_DISABLE_RPATH_HACK
 406 fi
 407
 408 ###############################################################################
 409 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 410
 411 ###     use option --disable-overwrite to leave out the link to -lcurses
 412 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 413 AC_ARG_ENABLE(overwrite,
 414         [  --disable-overwrite     leave out the link to -lcurses],
 415         [with_overwrite=$enableval],
 416         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 417 AC_MSG_RESULT($with_overwrite)
 418
 419 AC_MSG_CHECKING(if external terminfo-database is used)
 420 AC_ARG_ENABLE(database,
 421         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 422         [use_database=$enableval],
 423         [use_database=yes])
 424 AC_MSG_RESULT($use_database)
 425
 426 case $host_os in #(vi
 427 os2*) #(vi
 428         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 429         ;;
 430 *) #(vi
 431         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 432         ;;
 433 esac
 434 AC_SUBST(TERMINFO_SRC)
 435
 436 if test "$use_database" != no ; then
 437         AC_DEFINE(USE_DATABASE)
 438
 439         AC_MSG_CHECKING(which terminfo source-file will be installed)
 440         AC_ARG_WITH(database,
 441                 [  --with-database=XXX     specify terminfo source to install],
 442                 [TERMINFO_SRC=$withval])
 443         AC_MSG_RESULT($TERMINFO_SRC)
 444
 445         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 446         AC_ARG_WITH(hashed-db,
 447                 [  --with-hashed-db        specify hashed-database library],,
 448                 [with_hashed_db=no])
 449         AC_MSG_RESULT($with_hashed_db)
 450 else
 451         with_hashed_db=no
 452 fi
 453
 454 AC_MSG_CHECKING(for list of fallback descriptions)
 455 AC_ARG_WITH(fallbacks,
 456         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 457         [with_fallback=$withval],
 458         [with_fallback=])
 459 AC_MSG_RESULT($with_fallback)
 460 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 461 AC_SUBST(FALLBACK_LIST)
 462
 463 AC_MSG_CHECKING(if you want modern xterm or antique)
 464 AC_ARG_WITH(xterm-new,
 465         [  --without-xterm-new     specify if xterm terminfo should be old version],
 466         [with_xterm_new=$withval],
 467         [with_xterm_new=yes])
 468 case $with_xterm_new in
 469 no)     with_xterm_new=xterm-old;;
 470 *)      with_xterm_new=xterm-new;;
 471 esac
 472 AC_MSG_RESULT($with_xterm_new)
 473 WHICH_XTERM=$with_xterm_new
 474 AC_SUBST(WHICH_XTERM)
 475
 476 MAKE_TERMINFO=
 477 if test "$use_database" = no ; then
 478         TERMINFO="${datadir}/terminfo"
 479         MAKE_TERMINFO="#"
 480 else
 481
 482 AC_MSG_CHECKING(for list of terminfo directories)
 483 CF_WITH_PATHLIST(terminfo-dirs,
 484         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 485         TERMINFO_DIRS,
 486         DATADIR/terminfo,
 487         ${datadir}/terminfo)
 488 AC_MSG_RESULT($TERMINFO_DIRS)
 489 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
 490
 491 AC_MSG_CHECKING(for default terminfo directory)
 492 CF_WITH_PATH(default-terminfo-dir,
 493         [  --with-default-terminfo-dir=DIR default terminfo directory],
 494         TERMINFO,
 495         DATADIR/terminfo,
 496         ${datadir}/terminfo)
 497 AC_MSG_RESULT($TERMINFO)
 498 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
 499
 500 fi
 501
 502 AC_SUBST(TERMINFO)
 503 AC_SUBST(MAKE_TERMINFO)
 504
 505 ###     use option --disable-big-core to make tic run on small machines
 506 ###     We need 4Mb, check if we can allocate 50% more than that.
 507 AC_MSG_CHECKING(if big-core option selected)
 508 AC_ARG_ENABLE(big-core,
 509         [  --disable-big-core      assume machine has little memory],
 510         [with_big_core=$enableval],
 511         [AC_TRY_RUN([
 512 #include <stdlib.h>
 513 #include <string.h>
 514 int main() {
 515         unsigned long n = 6000000L;
 516         char *s = malloc(n);
 517         if (s != 0)
 518                 s[0] = s[n-1] = 0;
 519         ${cf_cv_main_return:-return}(s == 0);
 520 }],
 521         [with_big_core=yes],
 522         [with_big_core=no],
 523         [with_big_core=no])])
 524 AC_MSG_RESULT($with_big_core)
 525 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
 526
 527 ### ISO C only guarantees 512-char strings, we have tables which load faster
 528 ### when constructed using "big" strings.  More than the C compiler, the awk
 529 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 530 AC_MSG_CHECKING(if big-strings option selected)
 531 AC_ARG_ENABLE(big-strings,
 532         [  --disable-big-strings   assume compiler has only standard-size strings],
 533         [with_big_strings=$enableval],
 534         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 535 AC_MSG_RESULT($with_big_strings)
 536
 537 USE_BIG_STRINGS=0
 538 test "$with_big_strings" = "yes" && USE_BIG_STRINGS=1
 539 AC_SUBST(USE_BIG_STRINGS)
 540
 541 ###     use option --enable-termcap to compile in the termcap fallback support
 542 AC_MSG_CHECKING(if you want termcap-fallback support)
 543 AC_ARG_ENABLE(termcap,
 544         [  --enable-termcap        compile in termcap fallback support],
 545         [with_termcap=$enableval],
 546         [with_termcap=no])
 547 AC_MSG_RESULT($with_termcap)
 548
 549 if test "$with_termcap" != "yes" ; then
 550         if test "$use_database" = no ; then
 551                 if test -z "$with_fallback" ; then
 552                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 553                 fi
 554         fi
 555         AC_DEFINE(PURE_TERMINFO)
 556 else
 557
 558 if test "$with_ticlib" != no ; then
 559         AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 560 fi
 561
 562 AC_DEFINE(USE_TERMCAP)
 563 AC_MSG_CHECKING(for list of termcap files)
 564 CF_WITH_PATHLIST(termpath,
 565         [  --with-termpath=XXX     specify list of termcap files],
 566         TERMPATH,
 567         /etc/termcap:/usr/share/misc/termcap)
 568 AC_MSG_RESULT($TERMPATH)
 569 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
 570
 571 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 572 AC_MSG_CHECKING(if fast termcap-loader is needed)
 573 AC_ARG_ENABLE(getcap,
 574         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 575         [with_getcap=$enableval],
 576         [with_getcap=no])
 577 AC_MSG_RESULT($with_getcap)
 578 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
 579
 580 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 581 AC_ARG_ENABLE(getcap-cache,
 582         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 583         [with_getcap_cache=$enableval],
 584         [with_getcap_cache=no])
 585 AC_MSG_RESULT($with_getcap_cache)
 586 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
 587
 588 fi
 589
 590 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 591 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 592 AC_ARG_ENABLE(home-terminfo,
 593         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 594         [with_home_terminfo=$enableval],
 595         [with_home_terminfo=yes])
 596 AC_MSG_RESULT($with_home_terminfo)
 597 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
 598
 599 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 600 AC_ARG_ENABLE(root-environ,
 601         [  --disable-root-environ  restrict environment when running as root],
 602         [with_root_environ=$enableval],
 603         [with_root_environ=yes])
 604 AC_MSG_RESULT($with_root_environ)
 605 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
 606
 607 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 608 ###   to reduce storage requirements for the terminfo database.
 609 CF_LINK_FUNCS
 610
 611 with_links=no
 612 with_symlinks=no
 613
 614 # soft links (symbolic links) are useful for some systems where hard links do
 615 # not work, or to make it simpler to copy terminfo trees around.
 616 if test "$ac_cv_func_symlink" = yes ; then
 617     AC_MSG_CHECKING(if tic should use symbolic links)
 618     AC_ARG_ENABLE(symlinks,
 619         [  --enable-symlinks       make tic use symbolic links not hard links],
 620         [with_symlinks=$enableval],
 621         [with_symlinks=no])
 622     AC_MSG_RESULT($with_symlinks)
 623 fi
 624
 625 # If we have hard links and did not choose to use soft links instead, there is
 626 # no reason to make this choice optional - use the hard links.
 627 if test "$with_symlinks" = no ; then
 628     AC_MSG_CHECKING(if tic should use hard links)
 629     if test "$ac_cv_func_link" = yes ; then
 630         with_links=yes
 631     else
 632         with_links=no
 633     fi
 634     AC_MSG_RESULT($with_links)
 635 fi
 636
 637 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
 638 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
 639
 640 ###   use option --enable-broken-linker to force on use of broken-linker support
 641 AC_MSG_CHECKING(if you want broken-linker support code)
 642 AC_ARG_ENABLE(broken_linker,
 643         [  --enable-broken_linker  compile with broken-linker support code],
 644         [with_broken_linker=$enableval],
 645         [with_broken_linker=${BROKEN_LINKER:-no}])
 646 AC_MSG_RESULT($with_broken_linker)
 647
 648 BROKEN_LINKER=0
 649 if test "$with_broken_linker" = yes ; then
 650         AC_DEFINE(BROKEN_LINKER)
 651         BROKEN_LINKER=1
 652 elif test "$DFT_LWR_MODEL" = shared ; then
 653         case $cf_cv_system_name in #(vi
 654         cygwin*)
 655                 AC_DEFINE(BROKEN_LINKER)
 656                 BROKEN_LINKER=1
 657                 CF_VERBOSE(cygwin linker is broken anyway)
 658                 ;;
 659         esac
 660 fi
 661 AC_SUBST(BROKEN_LINKER)
 662
 663 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 664 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 665 AC_ARG_ENABLE(bsdpad,
 666         [  --enable-bsdpad         recognize BSD-style prefix padding],
 667         [with_bsdpad=$enableval],
 668         [with_bsdpad=no])
 669 AC_MSG_RESULT($with_bsdpad)
 670 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
 671
 672 ###   use option --enable-widec to turn on use of wide-character support
 673 NCURSES_CH_T=chtype
 674 NCURSES_LIBUTF8=0
 675
 676 NEED_WCHAR_H=0
 677 NCURSES_MBSTATE_T=0
 678 NCURSES_WCHAR_T=0
 679 NCURSES_WINT_T=0
 680
 681 # Check to define _XOPEN_SOURCE "automatically"
 682 CF_XOPEN_SOURCE(500)
 683
 684 # Work around breakage on OS X
 685 CF_SIGWINCH
 686
 687 # Checks for CODESET support.
 688 AM_LANGINFO_CODESET
 689
 690 # use these variables to work around a defect in gcc's fixincludes.
 691 NCURSES_OK_WCHAR_T=
 692 NCURSES_OK_WINT_T=
 693
 694 AC_MSG_CHECKING(if you want wide-character code)
 695 AC_ARG_ENABLE(widec,
 696         [  --enable-widec          compile with wide-char/UTF-8 code],
 697         [with_widec=$enableval],
 698         [with_widec=no])
 699 AC_MSG_RESULT($with_widec)
 700 if test "$with_widec" = yes ; then
 701         LIB_SUFFIX="w${LIB_SUFFIX}"
 702         AC_DEFINE(USE_WIDEC_SUPPORT)
 703         AC_DEFINE(NCURSES_WIDECHAR)
 704
 705         CF_CHECK_WCHAR_H
 706
 707         # with_overwrite=no
 708         NCURSES_CH_T=cchar_t
 709         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 710         if test "$ac_cv_func_putwc" != yes ; then
 711                 CF_UTF8_LIB
 712                 if test "$cf_cv_utf8_lib" != no ; then
 713                         NCURSES_LIBUTF8=1
 714                 fi
 715         fi
 716         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 717         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 718         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 719
 720         if test "$NCURSES_MBSTATE_T" != 0; then
 721                 AC_DEFINE(NEED_MBSTATE_T_DEF)
 722         fi
 723 fi
 724 AC_SUBST(NCURSES_CH_T)
 725 AC_SUBST(NCURSES_LIBUTF8)
 726
 727 AC_SUBST(NEED_WCHAR_H)
 728 AC_SUBST(NCURSES_MBSTATE_T)
 729 AC_SUBST(NCURSES_WCHAR_T)
 730 AC_SUBST(NCURSES_WINT_T)
 731
 732 AC_SUBST(NCURSES_OK_WCHAR_T)
 733 AC_SUBST(NCURSES_OK_WINT_T)
 734
 735 ###   use option --disable-lp64 to allow long chtype
 736 case $cf_cv_abi_version in
 737 [[345]]*)
 738         default_with_lp64=no
 739         ;;
 740 *)
 741         default_with_lp64=yes
 742         ;;
 743 esac
 744
 745 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 746 AC_ARG_ENABLE(lp64,
 747         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 748         [with_lp64=$enableval],
 749         [with_lp64=$default_with_lp64])
 750 AC_MSG_RESULT($with_lp64)
 751
 752 if test "$with_lp64" = yes ; then
 753         cf_cv_enable_lp64=1
 754 else
 755         cf_cv_enable_lp64=0
 756 fi
 757 AC_SUBST(cf_cv_enable_lp64)
 758
 759 CF_LARGEFILE
 760
 761 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 762 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 763 AC_ARG_ENABLE(tparm-varargs,
 764         [  --disable-tparm-varargs compile tparm() without varargs interface],
 765         [with_tparm_varargs=$enableval],
 766         [with_tparm_varargs=yes])
 767 AC_MSG_RESULT($with_tparm_varargs)
 768 NCURSES_TPARM_VARARGS=0
 769 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
 770 AC_SUBST(NCURSES_TPARM_VARARGS)
 771
 772 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
 773 if test "$with_ticlib" != no ; then
 774 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
 775 AC_ARG_ENABLE(tic-depends,
 776         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
 777         [with_tic_depends=$enableval],
 778         [with_tic_depends=yes])
 779 AC_MSG_RESULT($with_tic_depends)
 780 else
 781         with_tic_depends=no
 782 fi
 783
 784 ###   use option --with-bool to override bool's type
 785 AC_MSG_CHECKING(for type of bool)
 786 AC_ARG_WITH(bool,
 787         [  --with-bool=TYPE        override fallback type of bool variable],
 788         [NCURSES_BOOL="$withval"],
 789         [NCURSES_BOOL=auto])
 790 AC_MSG_RESULT($NCURSES_BOOL)
 791 AC_SUBST(NCURSES_BOOL)
 792
 793 AC_MSG_CHECKING(for alternate terminal capabilities file)
 794 AC_ARG_WITH(caps,
 795         [  --with-caps=alt         compile with alternate Caps file],
 796         [TERMINFO_CAPS=Caps.$withval],
 797         [TERMINFO_CAPS=Caps])
 798 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
 799 AC_MSG_RESULT($TERMINFO_CAPS)
 800 AC_SUBST(TERMINFO_CAPS)
 801
 802 ###   use option --with-chtype to override chtype's type
 803 AC_MSG_CHECKING(for type of chtype)
 804 AC_ARG_WITH(chtype,
 805         [  --with-chtype=TYPE      override type of chtype],
 806         [NCURSES_CHTYPE="$withval"],
 807         [NCURSES_CHTYPE=auto])
 808 AC_MSG_RESULT($NCURSES_CHTYPE)
 809
 810 ###   use option --with-ospeed to override ospeed's type
 811 AC_MSG_CHECKING(for type of ospeed)
 812 AC_ARG_WITH(ospeed,
 813         [  --with-ospeed=TYPE      override type of ospeed variable],
 814         [NCURSES_OSPEED="$withval"],
 815         [NCURSES_OSPEED=short])
 816 AC_MSG_RESULT($NCURSES_OSPEED)
 817 AC_SUBST(NCURSES_OSPEED)
 818
 819 ###   use option --with-mmask-t to override mmask_t's type
 820 AC_MSG_CHECKING(for type of mmask_t)
 821 AC_ARG_WITH(mmask-t,
 822         [  --with-mmask-t=TYPE     override type of mmask_t],
 823         [NCURSES_MMASK_T="$withval"],
 824         [NCURSES_MMASK_T=auto])
 825 AC_MSG_RESULT($NCURSES_MMASK_T)
 826
 827 ###   use option --with-ccharw-max to override CCHARW_MAX size
 828 AC_MSG_CHECKING(for size CCHARW_MAX)
 829 AC_ARG_WITH(ccharw-max,
 830         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
 831         [NCURSES_CCHARW_MAX="$withval"],
 832         [NCURSES_CCHARW_MAX=5])
 833 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
 834 AC_SUBST(NCURSES_CCHARW_MAX)
 835
 836 ### Enable compiling-in rcs id's
 837 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
 838 AC_ARG_WITH(rcs-ids,
 839         [  --with-rcs-ids          compile-in RCS identifiers],
 840         [with_rcs_ids=$withval],
 841         [with_rcs_ids=no])
 842 AC_MSG_RESULT($with_rcs_ids)
 843 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
 844
 845 ###############################################################################
 846 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tabs tic toe tput tset ])
 847
 848 ###############################################################################
 849 CF_HELP_MESSAGE(Extensions:)
 850
 851 ### Note that some functions (such as const) are normally disabled anyway.
 852 AC_MSG_CHECKING(if you want to build with function extensions)
 853 AC_ARG_ENABLE(ext-funcs,
 854         [  --disable-ext-funcs     disable function-extensions],
 855         [with_ext_funcs=$enableval],
 856         [with_ext_funcs=yes])
 857 AC_MSG_RESULT($with_ext_funcs)
 858 if test "$with_ext_funcs" = yes ; then
 859         NCURSES_EXT_FUNCS=1
 860         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS)
 861         AC_DEFINE(HAVE_CURSES_VERSION)
 862         AC_DEFINE(HAVE_HAS_KEY)
 863         AC_DEFINE(HAVE_RESIZETERM)
 864         AC_DEFINE(HAVE_RESIZE_TERM)
 865         AC_DEFINE(HAVE_TERM_ENTRY_H)
 866         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
 867         AC_DEFINE(HAVE_USE_SCREEN)
 868         AC_DEFINE(HAVE_USE_WINDOW)
 869         AC_DEFINE(HAVE_WRESIZE)
 870         AC_DEFINE(NCURSES_EXT_FUNCS)
 871         GENERATED_EXT_FUNCS=generated
 872 else
 873         NCURSES_EXT_FUNCS=0
 874         GENERATED_EXT_FUNCS=
 875 fi
 876 AC_SUBST(NCURSES_EXT_FUNCS)
 877 AC_SUBST(GENERATED_EXT_FUNCS)
 878
 879 AC_MSG_CHECKING(if you want to build with experimental SCREEN extensions)
 880 AC_ARG_ENABLE(sp-funcs,
 881         [  --enable-sp-funcs       enable experimental SCREEN-extensions],
 882         [with_sp_funcs=$enableval],
 883         [with_sp_funcs=no])
 884 AC_MSG_RESULT($with_sp_funcs)
 885 if test "$with_sp_funcs" = yes ; then
 886         NCURSES_SP_FUNCS=1
 887         AC_DEFINE(NCURSES_SP_FUNCS)
 888         GENERATED_SP_FUNCS=generated
 889 else
 890         NCURSES_SP_FUNCS=0
 891         GENERATED_SP_FUNCS=
 892 fi
 893 AC_SUBST(NCURSES_SP_FUNCS)
 894 AC_SUBST(GENERATED_SP_FUNCS)
 895
 896 AC_MSG_CHECKING(if you want to build with experimental terminal-driver)
 897 AC_ARG_ENABLE(term-driver,
 898         [  --enable-term-driver    enable experimental terminal-driver],
 899         [with_term_driver=$enableval],
 900         [with_term_driver=no])
 901 AC_MSG_RESULT($with_term_driver)
 902 if test "$with_term_driver" = yes ; then
 903         AC_DEFINE(USE_TERM_DRIVER)
 904         if test "$with_sp_funcs" != yes ; then
 905                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
 906         fi
 907 fi
 908
 909 ###   use option --enable-const to turn on use of const beyond that in XSI.
 910 AC_MSG_CHECKING(for extended use of const keyword)
 911 AC_ARG_ENABLE(const,
 912         [  --enable-const          compile with extra/non-standard const],
 913         [with_ext_const=$enableval],
 914         [with_ext_const=no])
 915 AC_MSG_RESULT($with_ext_const)
 916 NCURSES_CONST='/*nothing*/'
 917 if test "$with_ext_const" = yes ; then
 918         NCURSES_CONST=const
 919 fi
 920 AC_SUBST(NCURSES_CONST)
 921
 922 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
 923 AC_MSG_CHECKING(if you want to use extended colors)
 924 AC_ARG_ENABLE(ext-colors,
 925         [  --enable-ext-colors     compile for 256-color support],
 926         [with_ext_colors=$enableval],
 927         [with_ext_colors=no])
 928 AC_MSG_RESULT($with_ext_colors)
 929 NCURSES_EXT_COLORS=0
 930 if test "$with_ext_colors" = yes ; then
 931         if test "$with_widec" != yes ; then
 932                 AC_MSG_ERROR(This option applies only to wide-character library)
 933         else
 934                 # cannot be ABI 5 since it changes sizeof(cchar_t)
 935                 CF_NCURSES_ABI_6
 936         fi
 937         NCURSES_EXT_COLORS=1
 938         AC_DEFINE(NCURSES_EXT_COLORS)
 939 fi
 940 AC_SUBST(NCURSES_EXT_COLORS)
 941
 942 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
 943 AC_MSG_CHECKING(if you want to use extended mouse encoding)
 944 AC_ARG_ENABLE(ext-mouse,
 945         [  --enable-ext-mouse      compile for extended mouse-encoding],
 946         [with_ext_mouse=$enableval],
 947         [with_ext_mouse=no])
 948 AC_MSG_RESULT($with_ext_mouse)
 949 NCURSES_MOUSE_VERSION=1
 950 if test "$with_ext_mouse" = yes ; then
 951         NCURSES_MOUSE_VERSION=2
 952         CF_NCURSES_ABI_6
 953 fi
 954 AC_SUBST(NCURSES_MOUSE_VERSION)
 955
 956 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
 957 AC_ARG_ENABLE(no-padding,
 958         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
 959         [with_no_padding=$enableval],
 960         [with_no_padding=$with_ext_funcs])
 961 AC_MSG_RESULT($with_no_padding)
 962 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
 963
 964 AC_CHECK_SIZEOF([signed char], 0)
 965 if test "$ac_cv_sizeof_signed_char" = 1 ; then
 966         NCURSES_SBOOL="signed char"
 967 else
 968         NCURSES_SBOOL="char"
 969 fi
 970 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
 971 AC_ARG_ENABLE(signed-char,
 972         [  --enable-signed-char    compile using signed Boolean's in term.h],
 973         [with_signed_char=$enableval],
 974         [with_signed_char=no])
 975 AC_MSG_RESULT($with_signed_char)
 976 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
 977 AC_SUBST(NCURSES_SBOOL)
 978
 979 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
 980 AC_MSG_CHECKING(if you want SIGWINCH handler)
 981 AC_ARG_ENABLE(sigwinch,
 982         [  --enable-sigwinch       compile with SIGWINCH handler],
 983         [with_sigwinch=$enableval],
 984         [with_sigwinch=$with_ext_funcs])
 985 AC_MSG_RESULT($with_sigwinch)
 986 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
 987
 988 ###   use option --enable-tcap-names to allow user to define new capabilities
 989 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
 990 AC_ARG_ENABLE(tcap-names,
 991         [  --enable-tcap-names     compile with user-definable terminal capabilities],
 992         [with_tcap_names=$enableval],
 993         [with_tcap_names=$with_ext_funcs])
 994 AC_MSG_RESULT($with_tcap_names)
 995 NCURSES_XNAMES=0
 996 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
 997 AC_SUBST(NCURSES_XNAMES)
 998
 999 ###############################################################################
1000 # These options are relatively safe to experiment with.
1001 CF_HELP_MESSAGE(Development Code:)
1002 AC_MSG_CHECKING(if you want all development code)
1003 AC_ARG_WITH(develop,
1004         [  --without-develop       disable development options],
1005         [with_develop=$withval],
1006         [with_develop=no])
1007 AC_MSG_RESULT($with_develop)
1008
1009 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1010 AC_MSG_CHECKING(if you want hard-tabs code)
1011 AC_ARG_ENABLE(hard-tabs,
1012         [  --enable-hard-tabs      compile with hard-tabs code],,
1013         [enable_hard_tabs=$with_develop])
1014 AC_MSG_RESULT($enable_hard_tabs)
1015 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
1016
1017 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1018 AC_MSG_CHECKING(if you want limited support for xmc)
1019 AC_ARG_ENABLE(xmc-glitch,
1020         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1021         [enable_xmc_glitch=$with_develop])
1022 AC_MSG_RESULT($enable_xmc_glitch)
1023 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
1024
1025 ###############################################################################
1026 # These are just experimental, probably should not be in a package:
1027 CF_HELP_MESSAGE(Experimental Code:)
1028
1029 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1030 AC_ARG_ENABLE(assumed-color,
1031         [  --disable-assumed-color do not assume anything about default-colors],
1032         [with_assumed_color=$enableval],
1033         [with_assumed_color=yes])
1034 AC_MSG_RESULT($with_assumed_color)
1035 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
1036
1037 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1038 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1039 AC_ARG_ENABLE(hashmap,
1040         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1041         [with_hashmap=$enableval],
1042         [with_hashmap=yes])
1043 AC_MSG_RESULT($with_hashmap)
1044 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
1045
1046 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1047 AC_MSG_CHECKING(if you want colorfgbg code)
1048 AC_ARG_ENABLE(colorfgbg,
1049         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1050         [with_colorfgbg=$enableval],
1051         [with_colorfgbg=no])
1052 AC_MSG_RESULT($with_colorfgbg)
1053 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
1054
1055 ###   use option --enable-interop to turn on use of bindings used for interop
1056 AC_MSG_CHECKING(if you want interop bindings)
1057 AC_ARG_ENABLE(interop,
1058         [  --enable-interop        compile-in experimental interop bindings],
1059         [with_exp_interop=$enableval],
1060         [with_exp_interop=no])
1061 AC_MSG_RESULT($with_exp_interop)
1062
1063 NCURSES_INTEROP_FUNCS=0
1064 test "$with_exp_interop" = yes && NCURSES_INTEROP_FUNCS=1
1065 AC_SUBST(NCURSES_INTEROP_FUNCS)
1066
1067 # This is still experimental (20080329), but should ultimately be moved to
1068 # the script-block --with-normal, etc.
1069 CF_WITH_PTHREAD
1070
1071 if test "x$with_pthread" != xno; then
1072         AC_CHECK_FUNC(pthread_kill,[
1073                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1074                 AC_ARG_ENABLE(pthreads-eintr,
1075                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1076                         [use_pthreads_eintr=$enableval],
1077                         [use_pthreads_eintr=no])
1078                 AC_MSG_RESULT($use_pthreads_eintr)
1079                 if test $use_pthreads_eintr = yes ; then
1080                         AC_DEFINE(USE_PTHREADS_EINTR)
1081                 fi])
1082
1083         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1084         AC_ARG_ENABLE(weak-symbols,
1085                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1086                 [use_weak_symbols=$enableval],
1087                 [use_weak_symbols=no])
1088         AC_MSG_RESULT($use_weak_symbols)
1089         if test "$use_weak_symbols" = yes ; then
1090                 CF_WEAK_SYMBOLS
1091         else
1092                 cf_cv_weak_symbols=no
1093         fi
1094
1095         if test $cf_cv_weak_symbols = yes ; then
1096                 AC_DEFINE(USE_WEAK_SYMBOLS)
1097         fi
1098 fi
1099
1100 PTHREAD=
1101 if test "$with_pthread" = "yes" ; then
1102     AC_DEFINE(USE_PTHREADS)
1103     enable_reentrant=yes
1104     if test $cf_cv_weak_symbols = yes ; then
1105         PTHREAD=-lpthread
1106     fi
1107 fi
1108 AC_SUBST(PTHREAD)
1109
1110 # Reentrant code has to be opaque; there's little advantage to making ncurses
1111 # opaque outside of that, so there is no --enable-opaque option.  We can use
1112 # this option without --with-pthreads, but this will be always set for
1113 # pthreads.
1114 AC_MSG_CHECKING(if you want experimental reentrant code)
1115 AC_ARG_ENABLE(reentrant,
1116         [  --enable-reentrant      compile with experimental reentrant code],
1117         [with_reentrant=$enableval],
1118         [with_reentrant=no])
1119 AC_MSG_RESULT($with_reentrant)
1120 if test "$with_reentrant" = yes ; then
1121         cf_cv_enable_reentrant=1
1122         cf_cv_enable_opaque="NCURSES_INTERNALS"
1123         NCURSES_OPAQUE=1
1124         NCURSES_SIZE_T=int
1125         if test $cf_cv_weak_symbols = yes ; then
1126                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1127                 CF_ADD_LIB(pthread,TEST_LIBS)
1128                 CF_ADD_LIB(pthread,TEST_LIBS2)
1129         else
1130                 LIB_SUFFIX="t${LIB_SUFFIX}"
1131         fi
1132         AC_DEFINE(USE_REENTRANT)
1133         CF_NCURSES_ABI_6
1134 else
1135         cf_cv_enable_reentrant=0
1136         cf_cv_enable_opaque="NCURSES_OPAQUE"
1137         NCURSES_OPAQUE=0
1138         NCURSES_SIZE_T=short
1139 fi
1140 AC_SUBST(cf_cv_enable_reentrant)
1141 AC_SUBST(cf_cv_enable_opaque)
1142 AC_SUBST(NCURSES_OPAQUE)
1143 AC_SUBST(NCURSES_SIZE_T)
1144
1145 ### Allow using a different wrap-prefix
1146 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1147         AC_MSG_CHECKING(for prefix used to wrap public variables)
1148         AC_ARG_WITH(wrap-prefix,
1149                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1150                 [NCURSES_WRAP_PREFIX=$withval],
1151                 [NCURSES_WRAP_PREFIX=_nc_])
1152         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1153 else
1154         NCURSES_WRAP_PREFIX=_nc_
1155 fi
1156 AC_SUBST(NCURSES_WRAP_PREFIX)
1157 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX")
1158
1159 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1160 AC_ARG_ENABLE(safe-sprintf,
1161         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1162         [with_safe_sprintf=$enableval],
1163         [with_safe_sprintf=no])
1164 AC_MSG_RESULT($with_safe_sprintf)
1165 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
1166
1167 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1168 # when hashmap is used scroll hints are useless
1169 if test "$with_hashmap" = no ; then
1170 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1171 AC_ARG_ENABLE(scroll-hints,
1172         [  --disable-scroll-hints  compile without scroll-hints code],
1173         [with_scroll_hints=$enableval],
1174         [with_scroll_hints=yes])
1175 AC_MSG_RESULT($with_scroll_hints)
1176 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
1177 fi
1178
1179 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1180 AC_ARG_ENABLE(wgetch-events,
1181         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1182         [with_wgetch_events=$enableval],
1183         [with_wgetch_events=no])
1184 AC_MSG_RESULT($with_wgetch_events)
1185 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
1186
1187 ###############################################################################
1188 CF_HELP_MESSAGE(Testing/development Options:)
1189
1190 ###     use option --disable-echo to suppress full display compiling commands
1191 AC_MSG_CHECKING(if you want to display full commands during build)
1192 AC_ARG_ENABLE(echo,
1193         [  --enable-echo           build: display "compiling" commands (default)],
1194         [with_echo=$enableval],
1195         [with_echo=yes])
1196 if test "$with_echo" = yes; then
1197         ECHO_LINK=
1198 else
1199         ECHO_LINK='@ echo linking $@ ... ;'
1200         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1201         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1202 fi
1203 AC_MSG_RESULT($with_echo)
1204 AC_SUBST(ECHO_LINK)
1205
1206 ###     use option --enable-warnings to turn on all gcc warnings
1207 AC_MSG_CHECKING(if you want to see compiler warnings)
1208 AC_ARG_ENABLE(warnings,
1209         [  --enable-warnings       build: turn on GCC compiler warnings],
1210         [with_warnings=$enableval])
1211 AC_MSG_RESULT($with_warnings)
1212
1213 if test "x$with_warnings" = "xyes"; then
1214         CF_ADD_ADAFLAGS(-gnatg)
1215         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
1216         if test "$cf_with_cxx" = yes ; then
1217                 CF_GXX_WARNINGS(Wno-unused)
1218         fi
1219 fi
1220 CF_GCC_ATTRIBUTES
1221
1222 ###     use option --enable-assertions to turn on generation of assertion code
1223 AC_MSG_CHECKING(if you want to enable runtime assertions)
1224 AC_ARG_ENABLE(assertions,
1225         [  --enable-assertions     test: turn on generation of assertion code],
1226         [with_assertions=$enableval],
1227         [with_assertions=no])
1228 AC_MSG_RESULT($with_assertions)
1229 if test -n "$GCC"
1230 then
1231         if test "$with_assertions" = no
1232         then
1233                 AC_DEFINE(NDEBUG)
1234                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1235         else
1236                 CF_ADD_ADAFLAGS(-gnata)
1237         fi
1238 fi
1239
1240 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1241 CF_DISABLE_LEAKS
1242 AC_DEFINE(HAVE_NC_ALLOC_H)
1243
1244 ###     use option --enable-expanded to generate certain macros as functions
1245 AC_ARG_ENABLE(expanded,
1246         [  --enable-expanded       test: generate functions for certain macros],
1247         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1248
1249 ###     use option --disable-macros to suppress macros in favor of functions
1250 AC_ARG_ENABLE(macros,
1251         [  --disable-macros        test: use functions rather than macros],
1252         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1253
1254 # Normally we only add trace() to the debug-library.  Allow this to be
1255 # extended to all models of the ncurses library:
1256 cf_all_traces=no
1257 case "$CFLAGS $CPPFLAGS" in
1258 *-DTRACE*)
1259         cf_all_traces=yes
1260         ;;
1261 esac
1262
1263 AC_MSG_CHECKING(whether to add trace feature to all models)
1264 AC_ARG_WITH(trace,
1265 [  --with-trace            test: add trace() function to all models of ncurses],
1266 [cf_with_trace=$withval],
1267 [cf_with_trace=$cf_all_traces])
1268 AC_MSG_RESULT($cf_with_trace)
1269
1270 if test "$cf_with_trace" = yes ; then
1271         LIB_TRACING=all
1272         ADA_TRACE=TRUE
1273         CF_ADD_CFLAGS(-DTRACE)
1274 else
1275         LIB_TRACING=DEBUG
1276         ADA_TRACE=FALSE
1277 fi
1278
1279 AC_SUBST(ADA_TRACE)
1280
1281 ###     Checks for libraries.
1282 case $cf_cv_system_name in #(vi
1283 *mingw32*) #(vi
1284         ;;
1285 *)
1286 AC_CHECK_FUNC(gettimeofday,
1287         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1288
1289 AC_CHECK_LIB(bsd, gettimeofday,
1290         AC_DEFINE(HAVE_GETTIMEOFDAY)
1291         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1292         ;;
1293 esac
1294
1295 CF_MATH_LIB(MATH_LIB,sin(x))
1296 AC_SUBST(MATH_LIB)
1297
1298 ###     Checks for header files.
1299 AC_STDC_HEADERS
1300 AC_HEADER_DIRENT
1301 AC_HEADER_TIME
1302 CF_REGEX
1303
1304 dnl These are some other potentially nonportable headers.
1305 AC_CHECK_HEADERS( \
1306 fcntl.h \
1307 getopt.h \
1308 limits.h \
1309 locale.h \
1310 math.h \
1311 poll.h \
1312 sys/bsdtypes.h \
1313 sys/ioctl.h \
1314 sys/param.h \
1315 sys/poll.h \
1316 sys/select.h \
1317 sys/time.h \
1318 sys/times.h \
1319 ttyent.h \
1320 unistd.h \
1321 wctype.h \
1322 )
1323
1324 CF_GETOPT_HEADER
1325
1326 # check for ISC (this may also define _POSIX_SOURCE)
1327 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1328 if test "$ISC" = yes ; then
1329         AC_CHECK_LIB(cposix,main)
1330         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1331 fi
1332
1333 CF_SYS_TIME_SELECT
1334
1335 ###     checks for compiler characteristics
1336 AC_LANG_C
1337 AC_C_CONST
1338 CF_C_INLINE(NCURSES_INLINE,1200)
1339 CF_SIG_ATOMIC_T
1340
1341 if test $NCURSES_CHTYPE = auto ; then
1342         CF_TYPEOF_CHTYPE
1343 else
1344         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1345 fi
1346 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1347 AC_SUBST(cf_cv_typeof_chtype)
1348
1349 CF_UNSIGNED_LITERALS
1350 cf_cv_1UL="1"
1351 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1352 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1353 AC_SUBST(cf_cv_1UL)
1354
1355 if test $NCURSES_MMASK_T = auto ; then
1356         cf_cv_typeof_mmask_t=long
1357 else
1358         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1359 fi
1360 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1361 AC_SUBST(cf_cv_typeof_mmask_t)
1362
1363 ###     Checks for external-data
1364 CF_ERRNO
1365 CF_LINK_DATAONLY
1366
1367 ###     Checks for library functions.
1368 AC_CHECK_FUNCS( \
1369 getcwd \
1370 getegid \
1371 geteuid \
1372 getttynam \
1373 issetugid \
1374 poll \
1375 remove \
1376 select \
1377 setbuf \
1378 setbuffer \
1379 setvbuf \
1380 sigaction \
1381 sigvec \
1382 strdup \
1383 strstr \
1384 tcgetpgrp \
1385 times \
1386 vsnprintf \
1387 )
1388 if test "$with_getcap" = "yes" ; then
1389         CF_CGETENT
1390 fi
1391
1392 CF_ISASCII
1393 CF_STRUCT_SIGACTION
1394 CF_FUNC_NANOSLEEP
1395 CF_FUNC_TERMIOS
1396 CF_FUNC_VSSCANF
1397 CF_MKSTEMP
1398
1399 # setup for prototype of fallback for vsscanf()
1400 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1401
1402 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1403 if test "$cross_compiling" = yes ; then
1404         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1405 else
1406         AC_FUNC_SETVBUF_REVERSED
1407 fi
1408 AC_TYPE_SIGNAL
1409 AC_CHECK_TYPE(intptr_t, long)
1410 CF_TYPE_SIGACTION
1411 CF_SIZECHANGE
1412 CF_FUNC_MEMMOVE
1413 CF_FUNC_POLL
1414 CF_VA_COPY
1415 AC_FUNC_VFORK
1416
1417 # special check for test/ditto.c
1418 CF_FUNC_OPENPTY
1419 if test "$cf_cv_func_openpty" != no ; then
1420     AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>)
1421     AC_DEFINE(USE_XTERM_PTY)
1422     if test "$cf_cv_lib_util" = yes ; then
1423         CF_ADD_LIB(util,TEST_LIBS)
1424     fi
1425 fi
1426 AC_SUBST(TEST_LIBS)
1427 AC_SUBST(TEST_LIBS2)
1428
1429 if test "$with_hashed_db" != no ; then
1430         AC_DEFINE(USE_HASHED_DB)
1431         CF_HASHED_DB($with_hashed_db)
1432 fi
1433
1434 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1435 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1436         CF_STRIP_G_OPT(CFLAGS)
1437         CF_STRIP_G_OPT(CXXFLAGS)
1438 fi
1439
1440 # Just in case, check if the C compiler has a bool type.
1441 CF_BOOL_DECL(cf_cv_cc_bool_type)
1442
1443 # Check for C++ compiler characteristics (and ensure that it's there!)
1444 if test -n "$CXX" ; then
1445         AC_LANG_CPLUSPLUS
1446         CF_STDCPP_LIBRARY
1447         CF_PROG_CC_C_O(CXX)
1448
1449         case $GXX_VERSION in
1450         1*|2.[0-6]*)
1451                 cf_cxx_library=yes
1452                 ;;
1453         *-2.7*|2.7*)
1454                 CF_GPP_LIBRARY
1455                 ;;
1456         *)
1457                 cf_cxx_library=no
1458                 ;;
1459         esac
1460
1461         AC_CHECK_HEADERS(typeinfo)
1462         CF_CXX_IOSTREAM_NAMESPACE
1463         CF_BOOL_DECL
1464         CF_BOOL_SIZE
1465         CF_ETIP_DEFINES
1466         CF_CPP_PARAM_INIT
1467         CF_CPP_STATIC_CAST
1468         CF_CXX_AR_FLAGS
1469 else
1470         cf_cxx_library=no
1471         cf_cv_builtin_bool=1
1472
1473         # Just because we are not configuring against C++ right now does not
1474         # mean that a user will not want to use C++.  Some distributors disable
1475         # the C++ portion of this configuration as a shortcut (or just to avoid
1476         # compiling the demo in the c++ directory).  So we need a reasonable
1477         # default for the 'bool' type.
1478         #
1479         # Caveat: since the storage of the bool type is not standardized, it
1480         # may change.
1481
1482         if test "$NCURSES_BOOL" != auto ; then
1483                 cf_cv_type_of_bool=$NCURSES_BOOL
1484                 cf_cv_header_stdbool_h=0
1485         else
1486                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1487                         CF_BOOL_SIZE
1488                 else
1489                         AC_MSG_CHECKING(for fallback type of bool)
1490                         case "$host_cpu" in #(vi
1491                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1492                         *)      cf_cv_type_of_bool=int  ;;
1493                         esac
1494                         AC_MSG_RESULT($cf_cv_type_of_bool)
1495                 fi
1496         fi
1497 fi
1498 AC_SUBST(CXXLIBS)
1499
1500 # If the C compiler did not declare bool, and we did not determine that the C++
1501 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1502 # ncurses library use the same type as C++ bool.  Note that this allows one to
1503 # specify the type of bool in a configure-script option and postpone
1504 # integration with the C++ compiler provided that the types are compatible.
1505 USE_CXX_BOOL=1
1506 if test $cf_cv_cc_bool_type = 1
1507 then
1508         # oops: C has a bool.  Unlikely, but C++ could differ.
1509         USE_CXX_BOOL=0
1510 elif test $cf_cv_builtin_bool = 0
1511 then
1512         # C++ has no bool
1513         USE_CXX_BOOL=0
1514 else
1515         # this is the normal case
1516         USE_CXX_BOOL='defined(__cplusplus)'
1517 fi
1518 AC_SUBST(USE_CXX_BOOL)
1519
1520 CF_HELP_MESSAGE(Ada95 Binding Options:)
1521
1522 dnl If the Ada95 source-tree is present, add that to the build unless it will
1523 dnl not work, or was not requested.
1524 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1525
1526 dnl libtool does not know anything about GNAT, though a change made in 1998
1527 dnl provided for it "someday".  Disable the ada subtree if we are using
1528 dnl libtool -TD 20070714
1529         if test "$cf_with_ada" != "no" ; then
1530                 if test "$with_libtool" != "no"; then
1531                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1532                         cf_with_ada=no
1533                 fi
1534         fi
1535
1536 dnl Check for availability of GNU Ada Translator (GNAT).
1537 dnl At the moment we support no other Ada95 compiler.
1538         if test "$cf_with_ada" != "no" ; then
1539                 CF_PROG_GNAT
1540                 if test "$cf_cv_prog_gnat_correct" = yes; then
1541                         CF_ADD_ADAFLAGS(-gnatpn)
1542
1543                         # make ADAFLAGS consistent with CFLAGS
1544                         case "$CFLAGS" in
1545                         *-g*)
1546                                 CF_ADD_ADAFLAGS(-g)
1547                                 ;;
1548                         esac
1549                         case "$CFLAGS" in
1550                         *-O*)
1551                                 CF_ADD_ADAFLAGS(-O3)
1552                                 ;;
1553                         esac
1554
1555                         CF_GNAT_GENERICS
1556                         CF_GNAT_SIGINT
1557                         CF_GNAT_PRAGMA_UNREF
1558                         CF_GNAT_PROJECTS
1559
1560                         CF_WITH_ADA_COMPILER
1561
1562                         cf_ada_package=terminal_interface
1563                         AC_SUBST(cf_ada_package)
1564
1565                         CF_WITH_ADA_INCLUDE
1566                         CF_WITH_ADA_OBJECTS
1567                         CF_WITH_ADA_SHAREDLIB
1568                 fi
1569         fi
1570 else
1571         cf_with_ada=no
1572 fi
1573
1574 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1575 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1576 ###
1577 ### ticlib modules may be a separate library, otherwise contained in termlib.
1578 ### termlib modules may be a separate library, otherwise contained in ncurses.
1579 ###
1580 ### The of "+" or " " between the tokens controls the way the script
1581 ### chooses to split module lists into libraries.
1582 ###
1583 ### (see CF_LIB_RULES).
1584 AC_MSG_CHECKING(for library subsets)
1585 LIB_SUBSETS=
1586
1587 if test "$cf_with_progs" = yes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1588         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1589         if test "$with_ticlib" != no ; then
1590                 LIB_SUBSETS="${LIB_SUBSETS} "
1591         else
1592                 LIB_SUBSETS="${LIB_SUBSETS}+"
1593         fi
1594 fi
1595
1596 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1597 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1598
1599 if test "$with_termlib" != no ; then
1600         LIB_SUBSETS="${LIB_SUBSETS} "
1601 else
1602         LIB_SUBSETS="${LIB_SUBSETS}+"
1603 fi
1604
1605 LIB_SUBSETS="${LIB_SUBSETS}base"
1606
1607 # Most term-driver calls are to tinfo, but some like init_pair are to the
1608 # base library (so it resides in base).
1609 if test "$with_term_driver" != no ; then
1610         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1611         case $cf_cv_system_name in #(vi
1612         *mingw32*) #(vi
1613                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1614                 ;;
1615         *) #(vi
1616                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1617                 ;;
1618         esac
1619 fi
1620
1621 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1622 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1623
1624 AC_MSG_RESULT($LIB_SUBSETS)
1625
1626 ### Construct the list of include-directories to be generated
1627 CF_INCLUDE_DIRS
1628 CF_ADA_INCLUDE_DIRS
1629
1630 ### Build up pieces for makefile rules
1631 AC_MSG_CHECKING(default library suffix)
1632 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1633 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1634 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1635
1636 AC_MSG_CHECKING(default library-dependency suffix)
1637 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1638 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1639 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1640
1641 AC_MSG_CHECKING(default object directory)
1642 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1643 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1644 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1645
1646 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1647 if test "$cf_with_cxx" = yes ; then
1648 AC_MSG_CHECKING(c++ library-dependency suffix)
1649 if test "$with_libtool" != "no"; then
1650         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1651 else
1652         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)dnl we normally make a static library
1653 fi
1654 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1655 AC_SUBST(CXX_LIB_SUFFIX)
1656 fi
1657
1658 # do not want -ldl in build except as needed for -lncurses dependency
1659 if test "$with_dlsym" = yes ; then
1660 if test $DFT_LWR_MODEL = shared || \
1661    test $DFT_LWR_MODEL = libtool ; then
1662         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1663 fi
1664 fi
1665 ### Set up low-level terminfo dependencies for makefiles.
1666
1667 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1668 # do not need libdl
1669 TICS_LIST=
1670 if test "$with_dlsym" = yes ; then
1671         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1672 fi
1673
1674 if test "$with_ticlib" != no ; then
1675
1676         if test "$with_ticlib" != yes ; then
1677                 TICS_NAME=$with_ticlib
1678                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1679                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1680                 TICS_LIB_SUFFIX="${with_ticlib}"
1681         else
1682                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1683                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1684                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1685         fi
1686         TICS_LDFLAGS="-L${LIB_DIR}"
1687         TICS_LIBS="-l${TICS_LIB_SUFFIX}"
1688 else
1689         TICS_LDFLAGS="-L${LIB_DIR}"
1690         TICS_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX}"
1691 fi
1692 AC_SUBST(TICS_ARG_SUFFIX)
1693 AC_SUBST(TICS_DEP_SUFFIX)
1694 AC_SUBST(TICS_LIB_SUFFIX)
1695 AC_SUBST(TICS_LDFLAGS)
1696 AC_SUBST(TICS_LIBS)
1697
1698 if test "$with_termlib" != no ; then
1699
1700         if test "$with_termlib" != yes ; then
1701                 TINFO_NAME=$with_termlib
1702                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1703                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1704                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1705                 TINFO_LIB_SUFFIX="${with_termlib}"
1706         else
1707                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1708                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1709                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1710                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1711         fi
1712
1713         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1714         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1715         if test "$DFT_LWR_MODEL" = "libtool"; then
1716                 TEST_ARGS="${TEST_DEPS}"
1717                 TEST_ARG2="${TEST_DEP2}"
1718                 TINFO_LDFLAGS="-L${LIB_DIR}"
1719                 TINFO_LIBS="$TEST_ARGS"
1720                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
1721                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
1722         else
1723                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1724                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1725                 if test "x$with_term_driver" != xno ; then
1726                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1727                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1728                         TINFO_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARGS"
1729                 else
1730                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1731                         TINFO_LIBS="$TEST_ARGS"
1732                 fi
1733                 TINFO_LDFLAGS="-L${LIB_DIR}"
1734                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1735         fi
1736 else
1737         # the next lines are needed for linking libtic over libncurses
1738         TINFO_NAME=${LIB_NAME}
1739         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1740         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1741         if test "$with_tic_depends" = yes ; then
1742                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1743         else
1744                 TICS_LIST="$SHLIB_LIST"
1745         fi
1746
1747         TINFO_LDFLAGS="-L${LIB_DIR}"
1748         TINFO_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX}"
1749 fi
1750
1751 if test "$DFT_LWR_MODEL" = shared ; then
1752         case $cf_cv_system_name in #(vi
1753         cygwin*)
1754                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
1755                 TINFO_SUFFIX=.dll
1756                 ;;
1757         esac
1758 fi
1759
1760 AC_SUBST(TINFO_ARG_SUFFIX)
1761 AC_SUBST(TINFO_DEP_SUFFIX)
1762 AC_SUBST(TINFO_LIB_SUFFIX)
1763 AC_SUBST(TINFO_LDFLAGS)
1764 AC_SUBST(TINFO_LIBS)
1765
1766 if test "$with_dlsym" = yes ; then
1767         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1768 fi
1769
1770 if test "$DFT_LWR_MODEL" = "libtool"; then
1771     OBJEXT=lo
1772 fi
1773
1774 # needed for Ada95
1775 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
1776 AC_SUBST(TINFO_LDFLAGS2)
1777
1778 case $DFT_LWR_MODEL in
1779 normal|debug|profile)
1780         CF_LDFLAGS_STATIC
1781         ;;
1782 esac
1783
1784 AC_MSG_CHECKING(where we will install curses.h)
1785 test "$with_overwrite" = no && \
1786 test "x$includedir" = 'x${prefix}/include' && \
1787         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1788 AC_MSG_RESULT($includedir)
1789
1790 ### Resolve a conflict between normal and wide-curses by forcing applications
1791 ### that will need libutf8 to add it to their configure script.
1792 if test "$with_overwrite" != no ; then
1793 if test "$NCURSES_LIBUTF8" = 1 ; then
1794         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1795         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1796 fi
1797 fi
1798 WITH_OVERWRITE=$with_overwrite
1799
1800 AC_SUBST(WITH_OVERWRITE)
1801 AC_SUBST(TICS_LIST)
1802 AC_SUBST(TINFO_LIST)
1803 AC_SUBST(SHLIB_LIST)
1804
1805 # used to separate tack out of the tree
1806 NCURSES_TREE=
1807 AC_SUBST(NCURSES_TREE)
1808
1809 ### predefined stuff for the test programs
1810 AC_DEFINE(HAVE_SLK_COLOR)
1811
1812 ### Construct the list of subdirectories for which we'll customize makefiles
1813 ### with the appropriate compile-rules.
1814
1815 CF_SRC_MODULES($modules_to_build)
1816
1817 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
1818    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${DFT_ARG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
1819    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${DFT_ARG_SUFFIX}-config.1:man/MKada_config.in"
1820 fi
1821
1822 CF_DIRS_TO_MAKE
1823
1824 # symbols that differ when compiling Ada95 by itself.
1825 NCURSES_SHLIB2='sh $(top_srcdir)/misc/shlib'
1826 AC_SUBST(NCURSES_SHLIB2)
1827
1828 # values to use as strings
1829 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR')
1830
1831 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1832
1833 ### Now that we're done running tests, add the compiler-warnings, if any
1834 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1835
1836 ### Define substitutions for header files to avoid name-pollution
1837 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1838 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1839 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1840
1841 ################################################################################
1842 test "$use_database" = yes && \
1843 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1844
1845 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1846 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${DFT_ARG_SUFFIX}${cf_cv_abi_version}-config.1:man/MKncu_config.in"
1847
1848 if test x"$enable_pc_files" = xyes ; then \
1849 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
1850 MAKE_PC_FILES=
1851 else
1852 MAKE_PC_FILES="#"
1853 fi
1854 AC_SUBST(MAKE_PC_FILES)
1855 AC_SUBST(cross_compiling)
1856
1857 AC_PATH_PROG(TIC_PATH,tic,unknown,$PATH:/usr/local/ncurses/bin)
1858 if test -n "$FALLBACK_LIST"
1859 then
1860         if test "$TIC_PATH" = unknown
1861         then
1862                 AC_MSG_WARN(no tic program found for fallbacks)
1863         fi
1864 fi
1865 AC_SUBST(TIC_PATH)
1866
1867 if test "x$cf_with_tests" != xno ; then
1868         MAKE_TESTS=
1869 else
1870         MAKE_TESTS="#"
1871 fi
1872 AC_SUBST(MAKE_TESTS)
1873
1874 ADAHTML_DIR=../../doc/html/ada
1875 AC_SUBST(ADAHTML_DIR)
1876
1877 SUB_SCRIPTS=
1878 case $cf_cv_system_name in #(vi
1879 *mingw32*) #(vi
1880         SUB_SCRIPTS="mk-dlls.sh"
1881         ;;
1882 esac
1883
1884 AC_OUTPUT( \
1885         include/MKterm.h.awk \
1886         include/curses.head:include/curses.h.in \
1887         include/ncurses_dll.h \
1888         include/termcap.h \
1889         include/unctrl.h \
1890         $SUB_SCRIPTS \
1891         $SUB_MAKEFILES \
1892         Makefile,[
1893 if test "x$cf_with_tests" != xno ; then
1894         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LINK"], test)
1895 fi
1896 CF_LIB_RULES($SRC_SUBDIRS)
1897
1898 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
1899 if test -z "$USE_OLD_MAKERULES" ; then
1900         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
1901 fi
1902 fi
1903 ],[
1904 ### Special initialization commands, used to pass information from the
1905 ### configuration-run into config.status
1906
1907 AWK="$AWK"
1908 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1909 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1910 ECHO_LINK="$ECHO_LINK"
1911 LDCONFIG="$LDCONFIG"
1912 LIBTOOL_VERSION="$LIBTOOL_VERSION"
1913 LIB_NAME="$LIB_NAME"
1914 LIB_SUBSETS="$LIB_SUBSETS"
1915 LIB_SUFFIX="$LIB_SUFFIX"
1916 LIB_TRACING="$LIB_TRACING"
1917 LN_S="$LN_S"
1918 MAKE_TERMINFO="$MAKE_TERMINFO"
1919 NCURSES_MAJOR="$NCURSES_MAJOR"
1920 NCURSES_MINOR="$NCURSES_MINOR"
1921 NCURSES_OSPEED="$NCURSES_OSPEED"
1922 NCURSES_PATCH="$NCURSES_PATCH"
1923 SRC_SUBDIRS="$SRC_SUBDIRS"
1924 TERMINFO="$TERMINFO"
1925 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1926 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1927 TICS_NAME="$TICS_NAME"
1928 TIC_PATH="$TIC_PATH"
1929 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1930 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1931 TINFO_NAME="$TINFO_NAME"
1932 TINFO_SUFFIX="$TINFO_SUFFIX"
1933 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
1934 WITH_CURSES_H="$with_curses_h"
1935 WITH_ECHO="$with_echo"
1936 WITH_OVERWRITE="$with_overwrite"
1937 cf_LIST_MODELS="$cf_list_models"
1938 cf_cv_abi_version="$cf_cv_abi_version"
1939 cf_cv_do_relink="$cf_cv_do_relink"
1940 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1941 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1942 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1943 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1944 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1945 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
1946 cf_cv_rel_version="$cf_cv_rel_version"
1947 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1948 cf_cv_shared_soname='$cf_cv_shared_soname'
1949 cf_cv_shlib_version="$cf_cv_shlib_version"
1950 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1951 cf_cv_system_name="$cf_cv_system_name"
1952 cf_cv_term_driver="$with_term_driver"
1953 cf_with_ada="$cf_with_ada"
1954 cf_with_cxx_binding="$cf_with_cxx_binding"
1955 cf_with_manpages="$cf_with_manpages"
1956 cf_with_tests="$cf_with_tests"
1957 host="$host"
1958 target="$target"
1959
1960 ],cat)dnl
1961 ${MAKE:-make} preinstall