configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2008,2009 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: configure.in,v 1.466 2009/02/15 00:19:01 tom Exp $
  32 dnl Process this file with autoconf to produce a configure script.
  33 dnl
  34 dnl See http://invisible-island.net/autoconf/ for additional information.
  35 dnl
  36 dnl ---------------------------------------------------------------------------
  37 AC_PREREQ(2.13.20020210)
  38 AC_REVISION($Revision: 1.466 $)
  39 AC_INIT(ncurses/base/lib_initscr.c)
  40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  41
  42 CF_TOP_BUILDDIR
  43 CF_SUBST_NCURSES_VERSION
  44
  45 CF_WITH_REL_VERSION(NCURSES)
  46 CF_WITH_ABI_VERSION
  47
  48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
  49 AC_ARG_WITH(system-type,
  50 [  --with-system-type=XXX  test: override derived host system-type],
  51 [AC_MSG_WARN(overriding system type to $withval)
  52  cf_cv_system_name=$withval])
  53
  54 ###     Save the given $CFLAGS to allow user-override.
  55 cf_user_CFLAGS="$CFLAGS"
  56
  57 ###     Default install-location
  58 CF_CFG_DEFAULTS
  59
  60 ###     Checks for programs.
  61 AC_PROG_CC
  62 CF_GCC_VERSION
  63
  64 AC_PROG_CPP
  65 AC_PROG_GCC_TRADITIONAL
  66 CF_PROG_CC_C_O(CC)
  67 AC_ISC_POSIX
  68 CF_ANSI_CC_REQD
  69 CF_PROG_EXT
  70 CF_PROG_LDCONFIG
  71
  72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  73 dnl                             configure script by not letting us test if C++
  74 dnl                             is present, making this option necessary.
  75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  76 AC_ARG_WITH(cxx,
  77         [  --without-cxx           do not adjust ncurses bool to match C++],
  78         [cf_with_cxx=$withval],
  79         [cf_with_cxx=yes])
  80 AC_MSG_RESULT($cf_with_cxx)
  81 if test "X$cf_with_cxx" = Xno ; then
  82         CXX=""
  83         GXX=""
  84 else
  85         # with autoconf 2.13, we can change the error to a warning:
  86         pushdef([AC_MSG_ERROR],
  87                 [AC_MSG_RESULT(no)
  88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
  89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
  90         AC_PROG_CXX
  91         popdef([AC_MSG_ERROR])dnl
  92         # autoconf 2.5x removed the error - by hardcoding it to g++.
  93         if test "$CXX" = "g++" ; then
  94                 AC_PATH_PROG(CXX,g++)
  95         fi
  96         if test "$CXX" = "g++" ; then
  97                 AC_MSG_WARN(ignoring hardcoded g++)
  98                 cf_with_cxx=no; CXX=""; GXX="";
  99         fi
 100 fi
 101
 102 CF_GXX_VERSION
 103 case $GXX_VERSION in
 104 1*|2.[[0-6]]*)
 105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
 106         # cf_cxx_library=no
 107         AC_MSG_WARN(templates do not work)
 108         ;;
 109 esac
 110
 111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 112 AC_ARG_WITH(cxx-binding,
 113         [  --without-cxx-binding   do not build C++ binding and demo],
 114         [cf_with_cxx_binding=$withval],
 115         [cf_with_cxx_binding=$cf_with_cxx])
 116 AC_MSG_RESULT($cf_with_cxx_binding)
 117
 118 AC_MSG_CHECKING(if you want to build with Ada95)
 119 AC_ARG_WITH(ada,
 120         [  --without-ada           suppress check for Ada95, don't build demo],
 121         [cf_with_ada=$withval],
 122         [cf_with_ada=yes])
 123 AC_MSG_RESULT($cf_with_ada)
 124
 125 AC_MSG_CHECKING(if you want to install manpages)
 126 AC_ARG_WITH(manpages,
 127         [  --without-manpages      suppress install of manpages],
 128         [cf_with_manpages=$withval],
 129         [cf_with_manpages=yes])
 130 AC_MSG_RESULT($cf_with_manpages)
 131
 132 AC_MSG_CHECKING(if you want to build programs such as tic)
 133 AC_ARG_WITH(progs,
 134         [  --without-progs         suppress build with programs (e.g., tic)],
 135         [cf_with_progs=$withval],
 136         [cf_with_progs=yes])
 137 AC_MSG_RESULT($cf_with_progs)
 138
 139 AC_MSG_CHECKING(if you wish to install curses.h)
 140 AC_ARG_WITH(curses-h,
 141         [  --without-curses-h      install curses.h as ncurses.h only],
 142         [with_curses_h=$withval],
 143         [with_curses_h=yes])
 144 AC_MSG_RESULT($with_curses_h)
 145
 146 modules_to_build="ncurses"
 147 if test "X$cf_with_progs" != Xno ; then
 148 modules_to_build="$modules_to_build progs tack"
 149 fi
 150 modules_to_build="$modules_to_build panel menu form"
 151
 152 AC_ARG_PROGRAM
 153
 154 CF_PROG_AWK
 155 CF_PROG_EGREP
 156 CF_PROG_INSTALL
 157 CF_PROG_LINT
 158 AC_PROG_LN_S
 159
 160 AC_SYS_LONG_FILE_NAMES
 161
 162 # if we find pkg-config, check if we should install the ".pc" files.
 163 CF_PKG_CONFIG
 164
 165 if test "$PKG_CONFIG" != no ; then
 166         AC_MSG_CHECKING(if we should install .pc files for $PKG_CONFIG)
 167
 168         # Leave this as something that can be overridden in the environment.
 169         if test -z "$PKG_CONFIG_LIBDIR" ; then
 170                 PKG_CONFIG_LIBDIR=`echo "$PKG_CONFIG" | sed -e 's,/[[^/]]*/[[^/]]*$,,'`/lib/pkgconfig
 171         fi
 172
 173         if test -d "$PKG_CONFIG_LIBDIR" ; then
 174                 AC_ARG_ENABLE(pc-files,
 175                         [  --enable-pc-files       generate and install .pc files for pkg-config],
 176                         [enable_pc_files=$enableval],
 177                         [enable_pc_files=no])
 178                 AC_MSG_RESULT($enable_pc_files)
 179         else
 180                 AC_MSG_RESULT(no)
 181                 AC_MSG_WARN(did not find library $PKG_CONFIG_LIBDIR)
 182                 enable_pc_files=no
 183         fi
 184 fi
 185 AC_SUBST(PKG_CONFIG_LIBDIR)
 186
 187 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 188 AC_ARG_ENABLE(mixed-case,
 189         [  --enable-mixed-case     tic should assume mixed-case filenames],
 190         [enable_mixedcase=$enableval],
 191         [enable_mixedcase=auto])
 192 AC_MSG_RESULT($enable_mixedcase)
 193 if test "$enable_mixedcase" = "auto" ; then
 194     CF_MIXEDCASE_FILENAMES
 195 else
 196     cf_cv_mixedcase=$enable_mixedcase
 197     if test "$enable_mixedcase" = "yes" ; then
 198         AC_DEFINE(MIXEDCASE_FILENAMES)
 199     fi
 200 fi
 201
 202 # do this after mixed-case option (tags/TAGS is not as important as tic).
 203 AC_PROG_MAKE_SET
 204 CF_MAKE_TAGS
 205 CF_MAKEFLAGS
 206
 207 dnl These are standard among *NIX systems, but not when cross-compiling
 208 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 209 AC_CHECK_TOOL(LD, ld, ld)
 210 AC_CHECK_TOOL(AR, ar, ar)
 211 CF_AR_FLAGS
 212
 213 dnl Special option for use by system-builders: the install-prefix is used to
 214 dnl adjust the location into which the actual install is done, so that an
 215 dnl archive can be built without modifying the host system's configuration.
 216 AC_MSG_CHECKING(if you have specified an install-prefix)
 217 AC_ARG_WITH(install-prefix,
 218         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 219         [case "$withval" in #(vi
 220         yes|no) #(vi
 221                 ;;
 222         *)      DESTDIR="$withval"
 223                 ;;
 224         esac])
 225 AC_MSG_RESULT($DESTDIR)
 226 AC_SUBST(DESTDIR)
 227
 228 ###############################################################################
 229 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 230 # If we're cross-compiling, allow the user to override the tools and their
 231 # options.  The configure script is oriented toward identifying the host
 232 # compiler, etc., but we need a build compiler to generate parts of the source.
 233 CF_BUILD_CC
 234
 235 ###############################################################################
 236 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 237
 238 ### Options to allow the user to specify the set of libraries which are used.
 239 ### Use "--without-normal --with-shared" to allow the default model to be
 240 ### shared, for example.
 241 cf_list_models=""
 242 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 243
 244 CF_WITH_LIBTOOL
 245 if test "$with_libtool" != "no" ; then
 246
 247 cf_list_models="$cf_list_models libtool"
 248
 249 else
 250
 251 AC_MSG_CHECKING(if you want to build shared libraries)
 252 AC_ARG_WITH(shared,
 253         [  --with-shared           generate shared-libraries],
 254         [with_shared=$withval],
 255         [with_shared=no])
 256 AC_MSG_RESULT($with_shared)
 257 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
 258
 259 AC_MSG_CHECKING(if you want to build static libraries)
 260 AC_ARG_WITH(normal,
 261         [  --with-normal           generate normal-libraries (default)],
 262         [with_normal=$withval],
 263         [with_normal=yes])
 264 AC_MSG_RESULT($with_normal)
 265 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
 266
 267 AC_MSG_CHECKING(if you want to build debug libraries)
 268 AC_ARG_WITH(debug,
 269         [  --with-debug            generate debug-libraries (default)],
 270         [with_debug=$withval],
 271         [with_debug=yes])
 272 AC_MSG_RESULT($with_debug)
 273 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
 274
 275 AC_MSG_CHECKING(if you want to build profiling libraries)
 276 AC_ARG_WITH(profile,
 277         [  --with-profile          generate profile-libraries],
 278         [with_profile=$withval],
 279         [with_profile=no])
 280 AC_MSG_RESULT($with_profile)
 281 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
 282
 283 fi
 284
 285 ###############################################################################
 286
 287 AC_MSG_CHECKING(for specified models)
 288 test -z "$cf_list_models" && cf_list_models=normal
 289 dnl If we use libtool to generate libraries, then it must be the only
 290 dnl specified model.
 291 test "$with_libtool" != "no" && cf_list_models=libtool
 292 AC_MSG_RESULT($cf_list_models)
 293
 294 ### Use the first model as the default, and save its suffix for use in building
 295 ### up test-applications.
 296 AC_MSG_CHECKING(for default model)
 297 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 298 AC_MSG_RESULT($DFT_LWR_MODEL)
 299
 300 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 301
 302 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 303 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 304
 305 TICS_NAME=tic
 306 AC_SUBST(TICS_NAME)
 307
 308 TINFO_NAME=tinfo
 309 AC_SUBST(TINFO_NAME)
 310
 311 LIB_NAME=ncurses
 312 AC_SUBST(LIB_NAME)
 313
 314 LIB_DIR=../lib
 315 LIB_2ND=../../lib
 316
 317 CF_LIB_PREFIX(cf_prefix)
 318 LIB_PREFIX=$cf_prefix
 319 AC_SUBST(LIB_PREFIX)
 320
 321 LIB_SUFFIX=
 322 AC_SUBST(LIB_SUFFIX)
 323
 324 ###############################################################################
 325
 326 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 327 AC_ARG_WITH(termlib,
 328         [  --with-termlib          generate separate terminfo library],
 329         [with_termlib=$withval],
 330         [with_termlib=no])
 331 AC_MSG_RESULT($with_termlib)
 332
 333 AC_MSG_CHECKING(if you want to build a separate tic library)
 334 AC_ARG_WITH(ticlib,
 335         [  --with-ticlib           generate separate tic library],
 336         [with_ticlib=$withval],
 337         [with_ticlib=no])
 338 AC_MSG_RESULT($with_ticlib)
 339
 340 ### Checks for special libraries, must be done up-front.
 341 SHLIB_LIST=""
 342 CF_WITH_GPM
 343 if test "$with_gpm" != no ; then
 344         AC_MSG_CHECKING(if you want to load GPM dynamically)
 345         AC_ARG_WITH(dlsym,
 346                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 347                 [with_dlsym=$withval],
 348                 [with_dlsym=yes])
 349         AC_MSG_RESULT($with_dlsym)
 350         if test "$with_dlsym" = yes ; then
 351                 CF_FUNC_DLSYM
 352                 if test "$with_gpm" != yes ; then
 353                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 354                         cf_cv_gpm_soname="$with_gpm"
 355                 else
 356                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 357                 fi
 358                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
 359                 SHLIB_LIST="-ldl $SHLIB_LIST"
 360         else
 361                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 362         fi
 363         AC_DEFINE(HAVE_LIBGPM)
 364         CF_CHECK_GPM_WGETCH
 365 fi
 366
 367 CF_WITH_SYSMOUSE
 368
 369 dnl Not all ports of gcc support the -g option
 370
 371 if test X"$CC_G_OPT" = X"" ; then
 372         CC_G_OPT='-g'
 373         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
 374 fi
 375 AC_SUBST(CC_G_OPT)
 376
 377 if test X"$CXX_G_OPT" = X"" ; then
 378         CXX_G_OPT='-g'
 379         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
 380 fi
 381 AC_SUBST(CXX_G_OPT)
 382
 383 AC_MSG_CHECKING(for default loader flags)
 384 case $DFT_LWR_MODEL in
 385 libtool) LD_MODEL=''   ;;
 386 normal)  LD_MODEL=''   ;;
 387 debug)   LD_MODEL=$CC_G_OPT ;;
 388 profile) LD_MODEL='-pg';;
 389 shared)  LD_MODEL=''   ;;
 390 esac
 391 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 392 AC_MSG_RESULT($LD_MODEL)
 393
 394 case $DFT_LWR_MODEL in
 395 shared)
 396 CF_ENABLE_RPATH
 397 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 398 AC_ARG_ENABLE(relink,
 399 [  --disable-relink        relink shared libraries during install],
 400 [cf_cv_do_relink=$enableval],
 401 [cf_cv_do_relink=yes])
 402 AC_MSG_RESULT($cf_cv_do_relink)
 403         ;;
 404 esac
 405
 406 CF_SHARED_OPTS
 407 if test "$CC_SHARED_OPTS" = "unknown"; then
 408         for model in $cf_list_models; do
 409                 if test "$model" = "shared"; then
 410                         AC_ERROR(Shared libraries are not supported in this version)
 411                 fi
 412         done
 413 fi
 414
 415 ###############################################################################
 416 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 417
 418 ###     use option --disable-overwrite to leave out the link to -lcurses
 419 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 420 AC_ARG_ENABLE(overwrite,
 421         [  --disable-overwrite     leave out the link to -lcurses],
 422         [with_overwrite=$enableval],
 423         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 424 AC_MSG_RESULT($with_overwrite)
 425
 426 AC_MSG_CHECKING(if external terminfo-database is used)
 427 AC_ARG_ENABLE(database,
 428         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 429         [use_database=$enableval],
 430         [use_database=yes])
 431 AC_MSG_RESULT($use_database)
 432
 433 case $host_os in #(vi
 434 os2*) #(vi
 435         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 436         ;;
 437 *) #(vi
 438         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 439         ;;
 440 esac
 441 AC_SUBST(TERMINFO_SRC)
 442
 443 CF_PATHSEP
 444 if test "$use_database" != no ; then
 445         AC_DEFINE(USE_DATABASE)
 446
 447         AC_MSG_CHECKING(which terminfo source-file will be installed)
 448         AC_ARG_ENABLE(database,
 449                 [  --with-database=XXX     specify terminfo source to install],
 450                 [TERMINFO_SRC=$withval])
 451         AC_MSG_RESULT($TERMINFO_SRC)
 452
 453         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 454         AC_ARG_WITH(hashed-db,
 455                 [  --with-hashed-db        specify hashed-database library],,
 456                 [with_hashed_db=no])
 457         AC_MSG_RESULT($with_hashed_db)
 458 else
 459         with_hashed_db=no
 460 fi
 461
 462 AC_MSG_CHECKING(for list of fallback descriptions)
 463 AC_ARG_WITH(fallbacks,
 464         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 465         [with_fallback=$withval],
 466         [with_fallback=])
 467 AC_MSG_RESULT($with_fallback)
 468 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 469 AC_SUBST(FALLBACK_LIST)
 470
 471 AC_MSG_CHECKING(if you want modern xterm or antique)
 472 AC_ARG_WITH(xterm-new,
 473         [  --without-xterm-new     specify if xterm terminfo should be old version],
 474         [with_xterm_new=$withval],
 475         [with_xterm_new=yes])
 476 case $with_xterm_new in
 477 no)     with_xterm_new=xterm-old;;
 478 *)      with_xterm_new=xterm-new;;
 479 esac
 480 AC_MSG_RESULT($with_xterm_new)
 481 WHICH_XTERM=$with_xterm_new
 482 AC_SUBST(WHICH_XTERM)
 483
 484 MAKE_TERMINFO=
 485 if test "$use_database" = no ; then
 486         TERMINFO="${datadir}/terminfo"
 487         MAKE_TERMINFO="#"
 488 else
 489
 490 AC_MSG_CHECKING(for list of terminfo directories)
 491 CF_WITH_PATHLIST(terminfo-dirs,
 492         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 493         TERMINFO_DIRS,
 494         DATADIR/terminfo,
 495         ${datadir}/terminfo)
 496 AC_MSG_RESULT($TERMINFO_DIRS)
 497 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
 498
 499 AC_MSG_CHECKING(for default terminfo directory)
 500 CF_WITH_PATH(default-terminfo-dir,
 501         [  --with-default-terminfo-dir=DIR default terminfo directory],
 502         TERMINFO,
 503         DATADIR/terminfo,
 504         ${datadir}/terminfo)
 505 AC_MSG_RESULT($TERMINFO)
 506 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
 507
 508 fi
 509
 510 AC_SUBST(TERMINFO)
 511 AC_SUBST(MAKE_TERMINFO)
 512
 513 ###     use option --disable-big-core to make tic run on small machines
 514 ###     We need 4Mb, check if we can allocate 50% more than that.
 515 AC_MSG_CHECKING(if big-core option selected)
 516 AC_ARG_ENABLE(big-core,
 517         [  --disable-big-core      assume machine has little memory],
 518         [with_big_core=$enableval],
 519         [AC_TRY_RUN([
 520 #include <stdlib.h>
 521 #include <string.h>
 522 int main() {
 523         unsigned long n = 6000000L;
 524         char *s = malloc(n);
 525         if (s != 0)
 526                 s[0] = s[n-1] = 0;
 527         ${cf_cv_main_return:-return}(s == 0);
 528 }],
 529         [with_big_core=yes],
 530         [with_big_core=no],
 531         [with_big_core=no])])
 532 AC_MSG_RESULT($with_big_core)
 533 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
 534
 535 ### ISO C only guarantees 512-char strings, we have tables which load faster
 536 ### when constructed using "big" strings.  More than the C compiler, the awk
 537 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 538 AC_MSG_CHECKING(if big-strings option selected)
 539 AC_ARG_ENABLE(big-strings,
 540         [  --disable-big-strings   assume compiler has only standard-size strings],
 541         [with_big_strings=$enableval],
 542         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 543 AC_MSG_RESULT($with_big_strings)
 544
 545 USE_BIG_STRINGS=0
 546 test "$with_big_strings" = "yes" && USE_BIG_STRINGS=1
 547 AC_SUBST(USE_BIG_STRINGS)
 548
 549 ###     use option --enable-termcap to compile in the termcap fallback support
 550 AC_MSG_CHECKING(if you want termcap-fallback support)
 551 AC_ARG_ENABLE(termcap,
 552         [  --enable-termcap        compile in termcap fallback support],
 553         [with_termcap=$enableval],
 554         [with_termcap=no])
 555 AC_MSG_RESULT($with_termcap)
 556
 557 if test "$with_termcap" != "yes" ; then
 558         if test "$use_database" = no ; then
 559                 if test -z "$with_fallback" ; then
 560                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 561                 fi
 562         fi
 563         AC_DEFINE(PURE_TERMINFO)
 564 else
 565
 566 if test "$with_ticlib" != no ; then
 567         AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 568 fi
 569
 570 AC_DEFINE(USE_TERMCAP)
 571 AC_MSG_CHECKING(for list of termcap files)
 572 CF_WITH_PATHLIST(termpath,
 573         [  --with-termpath=XXX     specify list of termcap files],
 574         TERMPATH,
 575         /etc/termcap:/usr/share/misc/termcap)
 576 AC_MSG_RESULT($TERMPATH)
 577 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
 578
 579 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 580 AC_MSG_CHECKING(if fast termcap-loader is needed)
 581 AC_ARG_ENABLE(getcap,
 582         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 583         [with_getcap=$enableval],
 584         [with_getcap=no])
 585 AC_MSG_RESULT($with_getcap)
 586 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
 587
 588 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 589 AC_ARG_ENABLE(getcap-cache,
 590         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 591         [with_getcap_cache=$enableval],
 592         [with_getcap_cache=no])
 593 AC_MSG_RESULT($with_getcap_cache)
 594 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
 595
 596 fi
 597
 598 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 599 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 600 AC_ARG_ENABLE(home-terminfo,
 601         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 602         [with_home_terminfo=$enableval],
 603         [with_home_terminfo=yes])
 604 AC_MSG_RESULT($with_home_terminfo)
 605 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
 606
 607 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 608 AC_ARG_ENABLE(root-environ,
 609         [  --disable-root-environ  restrict environment when running as root],
 610         [with_root_environ=$enableval],
 611         [with_root_environ=yes])
 612 AC_MSG_RESULT($with_root_environ)
 613 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
 614
 615 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 616 ###   to reduce storage requirements for the terminfo database.
 617 CF_LINK_FUNCS
 618
 619 with_links=no
 620 with_symlinks=no
 621
 622 # soft links (symbolic links) are useful for some systems where hard links do
 623 # not work, or to make it simpler to copy terminfo trees around.
 624 if test "$ac_cv_func_symlink" = yes ; then
 625     AC_MSG_CHECKING(if tic should use symbolic links)
 626     AC_ARG_ENABLE(symlinks,
 627         [  --enable-symlinks       make tic use symbolic links not hard links],
 628         [with_symlinks=$enableval],
 629         [with_symlinks=no])
 630     AC_MSG_RESULT($with_symlinks)
 631 fi
 632
 633 # If we have hard links and did not choose to use soft links instead, there is
 634 # no reason to make this choice optional - use the hard links.
 635 if test "$with_symlinks" = no ; then
 636     AC_MSG_CHECKING(if tic should use hard links)
 637     if test "$ac_cv_func_link" = yes ; then
 638         with_links=yes
 639     else
 640         with_links=no
 641     fi
 642     AC_MSG_RESULT($with_links)
 643 fi
 644
 645 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
 646 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
 647
 648 ###   use option --enable-broken-linker to force on use of broken-linker support
 649 AC_MSG_CHECKING(if you want broken-linker support code)
 650 AC_ARG_ENABLE(broken_linker,
 651         [  --enable-broken_linker  compile with broken-linker support code],
 652         [with_broken_linker=$enableval],
 653         [with_broken_linker=${BROKEN_LINKER-no}])
 654 AC_MSG_RESULT($with_broken_linker)
 655
 656 BROKEN_LINKER=0
 657 if test "$with_broken_linker" = yes ; then
 658         AC_DEFINE(BROKEN_LINKER)
 659         BROKEN_LINKER=1
 660 elif test "$DFT_LWR_MODEL" = shared ; then
 661         case $cf_cv_system_name in #(vi
 662         cygwin*)
 663                 AC_DEFINE(BROKEN_LINKER)
 664                 BROKEN_LINKER=1
 665                 CF_VERBOSE(cygwin linker is broken anyway)
 666                 ;;
 667         esac
 668 fi
 669 AC_SUBST(BROKEN_LINKER)
 670
 671 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 672 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 673 AC_ARG_ENABLE(bsdpad,
 674         [  --enable-bsdpad         recognize BSD-style prefix padding],
 675         [with_bsdpad=$enableval],
 676         [with_bsdpad=no])
 677 AC_MSG_RESULT($with_bsdpad)
 678 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
 679
 680 ###   use option --enable-widec to turn on use of wide-character support
 681 NCURSES_CH_T=chtype
 682 NCURSES_LIBUTF8=0
 683
 684 NEED_WCHAR_H=0
 685 NCURSES_MBSTATE_T=0
 686 NCURSES_WCHAR_T=0
 687 NCURSES_WINT_T=0
 688
 689 # Check to define _XOPEN_SOURCE "automatically"
 690 CF_XOPEN_SOURCE
 691
 692 # Work around breakage on OS X
 693 CF_SIGWINCH
 694
 695 # Checks for CODESET support.
 696 AM_LANGINFO_CODESET
 697
 698 # use these variables to work around a defect in gcc's fixincludes.
 699 NCURSES_OK_WCHAR_T=
 700 NCURSES_OK_WINT_T=
 701
 702 AC_MSG_CHECKING(if you want wide-character code)
 703 AC_ARG_ENABLE(widec,
 704         [  --enable-widec          compile with wide-char/UTF-8 code],
 705         [with_widec=$enableval],
 706         [with_widec=no])
 707 AC_MSG_RESULT($with_widec)
 708 if test "$with_widec" = yes ; then
 709         LIB_SUFFIX="w${LIB_SUFFIX}"
 710         AC_DEFINE(USE_WIDEC_SUPPORT)
 711         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 712         # with_overwrite=no
 713         NCURSES_CH_T=cchar_t
 714         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 715         if test "$ac_cv_func_putwc" != yes ; then
 716                 CF_UTF8_LIB
 717                 if test "$cf_cv_utf8_lib" != no ; then
 718                         NCURSES_LIBUTF8=1
 719                 fi
 720         fi
 721         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 722         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 723         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 724
 725         if test "$NCURSES_MBSTATE_T" != 0; then
 726                 AC_DEFINE(NEED_MBSTATE_T_DEF)
 727         fi
 728 fi
 729 AC_SUBST(NCURSES_CH_T)
 730 AC_SUBST(NCURSES_LIBUTF8)
 731
 732 AC_SUBST(NEED_WCHAR_H)
 733 AC_SUBST(NCURSES_MBSTATE_T)
 734 AC_SUBST(NCURSES_WCHAR_T)
 735 AC_SUBST(NCURSES_WINT_T)
 736
 737 AC_SUBST(NCURSES_OK_WCHAR_T)
 738 AC_SUBST(NCURSES_OK_WINT_T)
 739
 740 ###   use option --disable-lp64 to allow long chtype
 741 case $cf_cv_abi_version in
 742 [[345]]*)
 743         default_with_lp64=no
 744         ;;
 745 *)
 746         default_with_lp64=yes
 747         ;;
 748 esac
 749
 750 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 751 AC_ARG_ENABLE(lp64,
 752         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 753         [with_lp64=$enableval],
 754         [with_lp64=$default_with_lp64])
 755 AC_MSG_RESULT($with_lp64)
 756
 757 if test "$with_lp64" = yes ; then
 758         cf_cv_enable_lp64=1
 759 else
 760         cf_cv_enable_lp64=0
 761 fi
 762 AC_SUBST(cf_cv_enable_lp64)
 763
 764 CF_LARGEFILE
 765
 766 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 767 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 768 AC_ARG_ENABLE(tparm-varargs,
 769         [  --disable-tparm-varargs compile tparm() without varargs interface],
 770         [with_tparm_varargs=$enableval],
 771         [with_tparm_varargs=yes])
 772 AC_MSG_RESULT($with_tparm_varargs)
 773 NCURSES_TPARM_VARARGS=0
 774 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
 775 AC_SUBST(NCURSES_TPARM_VARARGS)
 776
 777 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
 778 if test "$with_ticlib" != no ; then
 779 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
 780 AC_ARG_ENABLE(tic-depends,
 781         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
 782         [with_tic_depends=$enableval],
 783         [with_tic_depends=yes])
 784 AC_MSG_RESULT($with_tic_depends)
 785 else
 786         with_tic_depends=no
 787 fi
 788
 789 ###   use option --with-bool to override bool's type
 790 AC_MSG_CHECKING(for type of bool)
 791 AC_ARG_WITH(bool,
 792         [  --with-bool=TYPE        override fallback type of bool variable],
 793         [NCURSES_BOOL="$withval"],
 794         [NCURSES_BOOL=auto])
 795 AC_MSG_RESULT($NCURSES_BOOL)
 796 AC_SUBST(NCURSES_BOOL)
 797
 798 AC_MSG_CHECKING(for alternate terminal capabilities file)
 799 AC_ARG_WITH(caps,
 800         [  --with-caps=alt         compile with alternate Caps file],
 801         [TERMINFO_CAPS=Caps.$withval],
 802         [TERMINFO_CAPS=Caps])
 803 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
 804 AC_MSG_RESULT($TERMINFO_CAPS)
 805 AC_SUBST(TERMINFO_CAPS)
 806
 807 ###   use option --with-chtype to override chtype's type
 808 AC_MSG_CHECKING(for type of chtype)
 809 AC_ARG_WITH(chtype,
 810         [  --with-chtype=TYPE      override type of chtype],
 811         [NCURSES_CHTYPE="$withval"],
 812         [NCURSES_CHTYPE=auto])
 813 AC_MSG_RESULT($NCURSES_CHTYPE)
 814
 815 ###   use option --with-ospeed to override ospeed's type
 816 AC_MSG_CHECKING(for type of ospeed)
 817 AC_ARG_WITH(ospeed,
 818         [  --with-ospeed=TYPE      override type of ospeed variable],
 819         [NCURSES_OSPEED="$withval"],
 820         [NCURSES_OSPEED=short])
 821 AC_MSG_RESULT($NCURSES_OSPEED)
 822 AC_SUBST(NCURSES_OSPEED)
 823
 824 ###   use option --with-mmask-t to override mmask_t's type
 825 AC_MSG_CHECKING(for type of mmask_t)
 826 AC_ARG_WITH(mmask-t,
 827         [  --with-mmask-t=TYPE     override type of mmask_t],
 828         [NCURSES_MMASK_T="$withval"],
 829         [NCURSES_MMASK_T=auto])
 830 AC_MSG_RESULT($NCURSES_MMASK_T)
 831
 832 ### Enable compiling-in rcs id's
 833 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
 834 AC_ARG_WITH(rcs-ids,
 835         [  --with-rcs-ids          compile-in RCS identifiers],
 836         [with_rcs_ids=$withval],
 837         [with_rcs_ids=no])
 838 AC_MSG_RESULT($with_rcs_ids)
 839 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
 840
 841 ###############################################################################
 842 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tabs tic toe tput tset ])
 843
 844 ###############################################################################
 845 CF_HELP_MESSAGE(Extensions:)
 846
 847 ### Note that some functions (such as const) are normally disabled anyway.
 848 AC_MSG_CHECKING(if you want to build with function extensions)
 849 AC_ARG_ENABLE(ext-funcs,
 850         [  --disable-ext-funcs     disable function-extensions],
 851         [with_ext_funcs=$enableval],
 852         [with_ext_funcs=yes])
 853 AC_MSG_RESULT($with_ext_funcs)
 854 if test "$with_ext_funcs" = yes ; then
 855         NCURSES_EXT_FUNCS=1
 856         AC_DEFINE(HAVE_CURSES_VERSION)
 857         AC_DEFINE(HAVE_HAS_KEY)
 858         AC_DEFINE(HAVE_RESIZETERM)
 859         AC_DEFINE(HAVE_RESIZE_TERM)
 860         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
 861         AC_DEFINE(HAVE_WRESIZE)
 862         AC_DEFINE(NCURSES_EXT_FUNCS)
 863         GENERATED_EXT_FUNCS=generated
 864 else
 865         NCURSES_EXT_FUNCS=0
 866         GENERATED_EXT_FUNCS=
 867 fi
 868 AC_SUBST(NCURSES_EXT_FUNCS)
 869 AC_SUBST(GENERATED_EXT_FUNCS)
 870
 871 AC_MSG_CHECKING(if you want to build with experimental SCREEN extensions)
 872 AC_ARG_ENABLE(sp-funcs,
 873         [  --enable-sp-funcs       disable experimental SCREEN-extensions],
 874         [with_sp_funcs=$enableval],
 875         [with_sp_funcs=no])
 876 AC_MSG_RESULT($with_sp_funcs)
 877 if test "$with_sp_funcs" = yes ; then
 878         NCURSES_SP_FUNCS=1
 879         AC_DEFINE(NCURSES_SP_FUNCS)
 880         GENERATED_SP_FUNCS=generated
 881 else
 882         NCURSES_SP_FUNCS=0
 883         GENERATED_SP_FUNCS=
 884 fi
 885 AC_SUBST(NCURSES_SP_FUNCS)
 886 AC_SUBST(GENERATED_SP_FUNCS)
 887
 888 ###   use option --enable-const to turn on use of const beyond that in XSI.
 889 AC_MSG_CHECKING(for extended use of const keyword)
 890 AC_ARG_ENABLE(const,
 891         [  --enable-const          compile with extra/non-standard const],
 892         [with_ext_const=$enableval],
 893         [with_ext_const=no])
 894 AC_MSG_RESULT($with_ext_const)
 895 NCURSES_CONST='/*nothing*/'
 896 if test "$with_ext_const" = yes ; then
 897         NCURSES_CONST=const
 898 fi
 899 AC_SUBST(NCURSES_CONST)
 900
 901 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
 902 AC_MSG_CHECKING(if you want to use extended colors)
 903 AC_ARG_ENABLE(ext-colors,
 904         [  --enable-ext-colors     compile for 256-color support],
 905         [with_ext_colors=$enableval],
 906         [with_ext_colors=no])
 907 AC_MSG_RESULT($with_ext_colors)
 908 NCURSES_EXT_COLORS=0
 909 if test "$with_ext_colors" = yes ; then
 910         if test "$with_widec" != yes ; then
 911                 AC_MSG_ERROR(This option applies only to wide-character library)
 912         else
 913                 # cannot be ABI 5 since it changes sizeof(cchar_t)
 914                 CF_NCURSES_ABI_6
 915         fi
 916         NCURSES_EXT_COLORS=1
 917         AC_DEFINE(NCURSES_EXT_COLORS)
 918 fi
 919 AC_SUBST(NCURSES_EXT_COLORS)
 920
 921 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
 922 AC_MSG_CHECKING(if you want to use extended mouse encoding)
 923 AC_ARG_ENABLE(ext-mouse,
 924         [  --enable-ext-mouse      compile for extended mouse-encoding],
 925         [with_ext_mouse=$enableval],
 926         [with_ext_mouse=no])
 927 AC_MSG_RESULT($with_ext_mouse)
 928 NCURSES_MOUSE_VERSION=1
 929 if test "$with_ext_mouse" = yes ; then
 930         NCURSES_MOUSE_VERSION=2
 931         CF_NCURSES_ABI_6
 932 fi
 933 AC_SUBST(NCURSES_MOUSE_VERSION)
 934
 935 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
 936 AC_ARG_ENABLE(no-padding,
 937         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
 938         [with_no_padding=$enableval],
 939         [with_no_padding=$with_ext_funcs])
 940 AC_MSG_RESULT($with_no_padding)
 941 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
 942
 943 AC_CHECK_SIZEOF([signed char], 0)
 944 if test "$ac_cv_sizeof_signed_char" = 1 ; then
 945         NCURSES_SBOOL="signed char"
 946 else
 947         NCURSES_SBOOL="char"
 948 fi
 949 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
 950 AC_ARG_ENABLE(signed-char,
 951         [  --enable-signed-char    compile using signed Boolean's in term.h],
 952         [with_signed_char=$enableval],
 953         [with_signed_char=no])
 954 AC_MSG_RESULT($with_signed_char)
 955 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
 956 AC_SUBST(NCURSES_SBOOL)
 957
 958 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
 959 AC_MSG_CHECKING(if you want SIGWINCH handler)
 960 AC_ARG_ENABLE(sigwinch,
 961         [  --enable-sigwinch       compile with SIGWINCH handler],
 962         [with_sigwinch=$enableval],
 963         [with_sigwinch=$with_ext_funcs])
 964 AC_MSG_RESULT($with_sigwinch)
 965 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
 966
 967 ###   use option --enable-tcap-names to allow user to define new capabilities
 968 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
 969 AC_ARG_ENABLE(tcap-names,
 970         [  --enable-tcap-names     compile with user-definable terminal capabilities],
 971         [with_tcap_names=$enableval],
 972         [with_tcap_names=$with_ext_funcs])
 973 AC_MSG_RESULT($with_tcap_names)
 974 NCURSES_XNAMES=0
 975 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
 976 AC_SUBST(NCURSES_XNAMES)
 977
 978 ###############################################################################
 979 # These options are relatively safe to experiment with.
 980 CF_HELP_MESSAGE(Development Code:)
 981 AC_MSG_CHECKING(if you want all development code)
 982 AC_ARG_WITH(develop,
 983         [  --without-develop       disable development options],
 984         [with_develop=$withval],
 985         [with_develop=no])
 986 AC_MSG_RESULT($with_develop)
 987
 988 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
 989 AC_MSG_CHECKING(if you want hard-tabs code)
 990 AC_ARG_ENABLE(hard-tabs,
 991         [  --enable-hard-tabs      compile with hard-tabs code],,
 992         [enable_hard_tabs=$with_develop])
 993 AC_MSG_RESULT($enable_hard_tabs)
 994 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
 995
 996 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
 997 AC_MSG_CHECKING(if you want limited support for xmc)
 998 AC_ARG_ENABLE(xmc-glitch,
 999         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1000         [enable_xmc_glitch=$with_develop])
1001 AC_MSG_RESULT($enable_xmc_glitch)
1002 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
1003
1004 ###############################################################################
1005 # These are just experimental, probably should not be in a package:
1006 CF_HELP_MESSAGE(Experimental Code:)
1007
1008 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1009 AC_ARG_ENABLE(assumed-color,
1010         [  --disable-assumed-color do not assume anything about default-colors],
1011         [with_assumed_color=$enableval],
1012         [with_assumed_color=yes])
1013 AC_MSG_RESULT($with_assumed_color)
1014 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
1015
1016 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1017 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1018 AC_ARG_ENABLE(hashmap,
1019         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1020         [with_hashmap=$enableval],
1021         [with_hashmap=yes])
1022 AC_MSG_RESULT($with_hashmap)
1023 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
1024
1025 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1026 AC_MSG_CHECKING(if you want colorfgbg code)
1027 AC_ARG_ENABLE(colorfgbg,
1028         [  --enable-colorfgbg      compile with $COLORFGBG code],
1029         [with_colorfgbg=$enableval],
1030         [with_colorfgbg=no])
1031 AC_MSG_RESULT($with_colorfgbg)
1032 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
1033
1034 # This is still experimental (20080329), but should ultimately be moved to
1035 # the script-block --with-normal, etc.
1036 CF_WITH_PTHREAD
1037
1038 AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1039 AC_ARG_ENABLE(weak-symbols,
1040     [  --enable-weak-symbols   enable weak-symbols for pthreads],
1041     [use_weak_symbols=$withval],
1042     [use_weak_symbols=no])
1043 AC_MSG_RESULT($use_weak_symbols)
1044 if test "$use_weak_symbols" = yes ; then
1045     CF_WEAK_SYMBOLS
1046 else
1047     cf_cv_weak_symbols=no
1048 fi
1049
1050 if test $cf_cv_weak_symbols = yes ; then
1051     AC_DEFINE(USE_WEAK_SYMBOLS)
1052 fi
1053
1054 PTHREAD=
1055 if test "$with_pthread" = "yes" ; then
1056     AC_DEFINE(USE_PTHREADS)
1057     enable_reentrant=yes
1058     if test $cf_cv_weak_symbols = yes ; then
1059         PTHREAD=-lpthread
1060     fi
1061 fi
1062 AC_SUBST(PTHREAD)
1063
1064 # Reentrant code has to be opaque; there's little advantage to making ncurses
1065 # opaque outside of that, so there is no --enable-opaque option.  We can use
1066 # this option without --with-pthreads, but this will be always set for
1067 # pthreads.
1068 AC_MSG_CHECKING(if you want experimental reentrant code)
1069 AC_ARG_ENABLE(reentrant,
1070         [  --enable-reentrant      compile with experimental reentrant code],
1071         [with_reentrant=$enableval],
1072         [with_reentrant=no])
1073 AC_MSG_RESULT($with_reentrant)
1074 if test "$with_reentrant" = yes ; then
1075         cf_cv_enable_reentrant=1
1076         cf_cv_enable_opaque="NCURSES_INTERNALS"
1077         NCURSES_OPAQUE=1
1078         NCURSES_SIZE_T=int
1079     if test $cf_cv_weak_symbols = yes ; then
1080         CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1081     else
1082         LIB_SUFFIX="t${LIB_SUFFIX}"
1083     fi
1084         AC_DEFINE(USE_REENTRANT)
1085         CF_NCURSES_ABI_6
1086 else
1087         cf_cv_enable_reentrant=0
1088         cf_cv_enable_opaque="NCURSES_OPAQUE"
1089         NCURSES_OPAQUE=0
1090         NCURSES_SIZE_T=short
1091 fi
1092 AC_SUBST(cf_cv_enable_reentrant)
1093 AC_SUBST(cf_cv_enable_opaque)
1094 AC_SUBST(NCURSES_OPAQUE)
1095 AC_SUBST(NCURSES_SIZE_T)
1096
1097 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1098 AC_ARG_ENABLE(safe-sprintf,
1099         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1100         [with_safe_sprintf=$enableval],
1101         [with_safe_sprintf=no])
1102 AC_MSG_RESULT($with_safe_sprintf)
1103 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
1104
1105 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1106 # when hashmap is used scroll hints are useless
1107 if test "$with_hashmap" = no ; then
1108 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1109 AC_ARG_ENABLE(scroll-hints,
1110         [  --disable-scroll-hints  compile without scroll-hints code],
1111         [with_scroll_hints=$enableval],
1112         [with_scroll_hints=yes])
1113 AC_MSG_RESULT($with_scroll_hints)
1114 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
1115 fi
1116
1117 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1118 AC_ARG_ENABLE(wgetch-events,
1119         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1120         [with_wgetch_events=$enableval],
1121         [with_wgetch_events=no])
1122 AC_MSG_RESULT($with_wgetch_events)
1123 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
1124
1125 ###############################################################################
1126 CF_HELP_MESSAGE(Testing/development Options:)
1127
1128 ###     use option --disable-echo to suppress full display compiling commands
1129 AC_MSG_CHECKING(if you want to display full commands during build)
1130 AC_ARG_ENABLE(echo,
1131         [  --enable-echo           build: display "compiling" commands (default)],
1132         [with_echo=$enableval],
1133         [with_echo=yes])
1134 if test "$with_echo" = yes; then
1135         ECHO_LINK=
1136 else
1137         ECHO_LINK='@ echo linking $@ ... ;'
1138         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1139         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1140 fi
1141 AC_MSG_RESULT($with_echo)
1142 AC_SUBST(ECHO_LINK)
1143
1144 ###     use option --enable-warnings to turn on all gcc warnings
1145 AC_MSG_CHECKING(if you want to see compiler warnings)
1146 AC_ARG_ENABLE(warnings,
1147         [  --enable-warnings       build: turn on GCC compiler warnings],
1148         [with_warnings=$enableval])
1149 AC_MSG_RESULT($with_warnings)
1150
1151 if test "x$with_warnings" = "xyes"; then
1152         ADAFLAGS="$ADAFLAGS -gnatg"
1153         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
1154         if test "$cf_with_cxx" = yes ; then
1155                 CF_GXX_WARNINGS(Wno-unused)
1156         fi
1157 fi
1158 CF_GCC_ATTRIBUTES
1159
1160 ###     use option --enable-assertions to turn on generation of assertion code
1161 AC_MSG_CHECKING(if you want to enable runtime assertions)
1162 AC_ARG_ENABLE(assertions,
1163         [  --enable-assertions     test: turn on generation of assertion code],
1164         [with_assertions=$enableval],
1165         [with_assertions=no])
1166 AC_MSG_RESULT($with_assertions)
1167 if test -n "$GCC"
1168 then
1169         if test "$with_assertions" = no
1170         then
1171                 AC_DEFINE(NDEBUG)
1172                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1173         else
1174                 ADAFLAGS="$ADAFLAGS -gnata"
1175         fi
1176 fi
1177
1178 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1179 CF_DISABLE_LEAKS
1180 AC_DEFINE(HAVE_NC_ALLOC_H)
1181
1182 ###     use option --enable-expanded to generate certain macros as functions
1183 AC_ARG_ENABLE(expanded,
1184         [  --enable-expanded       test: generate functions for certain macros],
1185         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1186
1187 ###     use option --disable-macros to suppress macros in favor of functions
1188 AC_ARG_ENABLE(macros,
1189         [  --disable-macros        test: use functions rather than macros],
1190         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1191
1192 # Normally we only add trace() to the debug-library.  Allow this to be
1193 # extended to all models of the ncurses library:
1194 cf_all_traces=no
1195 case "$CFLAGS $CPPFLAGS" in
1196 *-DTRACE*)
1197         cf_all_traces=yes
1198         ;;
1199 esac
1200
1201 AC_MSG_CHECKING(whether to add trace feature to all models)
1202 AC_ARG_WITH(trace,
1203 [  --with-trace            test: add trace() function to all models of ncurses],
1204 [cf_with_trace=$withval],
1205 [cf_with_trace=$cf_all_traces])
1206 AC_MSG_RESULT($cf_with_trace)
1207
1208 if test "$cf_with_trace" = yes ; then
1209         LIB_TRACING=all
1210         ADA_TRACE=TRUE
1211         CF_ADD_CFLAGS(-DTRACE)
1212 else
1213         LIB_TRACING=DEBUG
1214         ADA_TRACE=FALSE
1215 fi
1216
1217 AC_SUBST(ADA_TRACE)
1218
1219 ###     Checks for libraries.
1220 case $cf_cv_system_name in #(vi
1221 *mingw32*) #(vi
1222         ;;
1223 *)
1224 AC_CHECK_FUNC(gettimeofday,
1225         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1226
1227 AC_CHECK_LIB(bsd, gettimeofday,
1228         AC_DEFINE(HAVE_GETTIMEOFDAY)
1229         LIBS="$LIBS -lbsd")])dnl CLIX: bzero, select, gettimeofday
1230         ;;
1231 esac
1232
1233 CF_MATH_LIB(MATH_LIB,sin(x))
1234 AC_SUBST(MATH_LIB)
1235
1236 ###     Checks for header files.
1237 AC_STDC_HEADERS
1238 AC_HEADER_DIRENT
1239 AC_HEADER_TIME
1240 CF_REGEX
1241
1242 dnl These are some other potentially nonportable headers.
1243 AC_CHECK_HEADERS( \
1244 fcntl.h \
1245 getopt.h \
1246 limits.h \
1247 locale.h \
1248 poll.h \
1249 sys/bsdtypes.h \
1250 sys/ioctl.h \
1251 sys/param.h \
1252 sys/poll.h \
1253 sys/select.h \
1254 sys/time.h \
1255 sys/times.h \
1256 ttyent.h \
1257 unistd.h \
1258 wctype.h \
1259 )
1260
1261 # check for ISC (this may also define _POSIX_SOURCE)
1262 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1263 if test "$ISC" = yes ; then
1264         AC_CHECK_LIB(cposix,main)
1265         AC_CHECK_LIB(inet,bzero,LIBS="$LIBS -linet")dnl also 'select()'
1266 fi
1267
1268 CF_SYS_TIME_SELECT
1269
1270 ###     checks for compiler characteristics
1271 AC_LANG_C
1272 AC_C_CONST
1273 CF_C_INLINE(NCURSES_INLINE,1200)
1274 CF_SIG_ATOMIC_T
1275
1276 if test $NCURSES_CHTYPE = auto ; then
1277         CF_TYPEOF_CHTYPE
1278 else
1279         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1280 fi
1281 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1282 AC_SUBST(cf_cv_typeof_chtype)
1283
1284 CF_UNSIGNED_LITERALS
1285 cf_cv_1UL="1"
1286 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1287 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1288 AC_SUBST(cf_cv_1UL)
1289
1290 if test $NCURSES_MMASK_T = auto ; then
1291         cf_cv_typeof_mmask_t=long
1292 else
1293         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1294 fi
1295 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1296 AC_SUBST(cf_cv_typeof_mmask_t)
1297
1298 ###     Checks for external-data
1299 CF_ERRNO
1300 CF_LINK_DATAONLY
1301
1302 ###     Checks for library functions.
1303 AC_CHECK_FUNCS( \
1304 getcwd \
1305 getegid \
1306 geteuid \
1307 getttynam \
1308 issetugid \
1309 poll \
1310 remove \
1311 select \
1312 setbuf \
1313 setbuffer \
1314 setvbuf \
1315 sigaction \
1316 sigvec \
1317 strdup \
1318 strstr \
1319 tcgetpgrp \
1320 times \
1321 vsnprintf \
1322 )
1323 if test "$with_getcap" = "yes" ; then
1324         CF_CGETENT
1325 fi
1326
1327 CF_ISASCII
1328 CF_STRUCT_SIGACTION
1329 CF_FUNC_NANOSLEEP
1330 CF_FUNC_TERMIOS
1331 CF_FUNC_VSSCANF
1332 CF_MKSTEMP
1333
1334 # setup for prototype of fallback for vsscanf()
1335 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1336
1337 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1338 if test "$cross_compiling" = yes ; then
1339         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1340 else
1341         AC_FUNC_SETVBUF_REVERSED
1342 fi
1343 AC_TYPE_SIGNAL
1344 CF_TYPE_SIGACTION
1345 CF_SIZECHANGE
1346 CF_FUNC_MEMMOVE
1347 CF_FUNC_POLL
1348
1349 # special check for test/ditto.c
1350 CF_FUNC_OPENPTY
1351 if test "$cf_cv_func_openpty" != no ; then
1352     AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>)
1353     AC_DEFINE(USE_XTERM_PTY)
1354     if test "$cf_cv_lib_util" = yes ; then
1355         TEST_LIBS="-lutil $TEST_LIBS"
1356     fi
1357 fi
1358 AC_SUBST(TEST_LIBS)
1359
1360 if test "$with_hashed_db" != no ; then
1361         AC_DEFINE(USE_HASHED_DB)
1362         CF_HASHED_DB($with_hashed_db)
1363 fi
1364
1365 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1366 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1367         CF_STRIP_G_OPT(CFLAGS)
1368         CF_STRIP_G_OPT(CXXFLAGS)
1369 fi
1370
1371 # Just in case, check if the C compiler has a bool type.
1372 CF_BOOL_DECL(cf_cv_cc_bool_type)
1373
1374 # Check for C++ compiler characteristics (and ensure that it's there!)
1375 if test -n "$CXX" ; then
1376         AC_LANG_CPLUSPLUS
1377         CF_STDCPP_LIBRARY
1378         CF_PROG_CC_C_O(CXX)
1379
1380         case $GXX_VERSION in
1381         1*|2.[0-6]*)
1382                 cf_cxx_library=yes
1383                 ;;
1384         *-2.7*|2.7*)
1385                 CF_GPP_LIBRARY
1386                 ;;
1387         *)
1388                 cf_cxx_library=no
1389                 ;;
1390         esac
1391
1392         AC_CHECK_HEADERS(iostream typeinfo)
1393
1394     if test x"$ac_cv_header_iostream" = xyes ; then
1395         AC_MSG_CHECKING(if iostream uses std-namespace)
1396         AC_TRY_COMPILE([
1397 #include <iostream>
1398 using std::endl;
1399 using std::cerr;],[
1400 cerr << "testing" << endl;
1401 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1402         AC_MSG_RESULT($cf_iostream_namespace)
1403         if test "$cf_iostream_namespace" = yes ; then
1404             AC_DEFINE(IOSTREAM_NAMESPACE)
1405         fi
1406     fi
1407
1408         CF_BOOL_DECL
1409         CF_BOOL_SIZE
1410         CF_ETIP_DEFINES
1411         CF_CPP_PARAM_INIT
1412         CF_CPP_STATIC_CAST
1413
1414         CXX_AR='$(AR)'
1415         CXX_ARFLAGS='$(ARFLAGS)'
1416         case $cf_cv_system_name in #(vi
1417         irix*) #(vi
1418             if test "$GXX" != yes ; then
1419                 CXX_AR='$(CXX)'
1420                 CXX_ARFLAGS='-ar -o'
1421             fi
1422             ;;
1423         sco3.2v5*) #(vi
1424             CXXLDFLAGS="-u main"
1425             ;;
1426         solaris2*)
1427             if test "$GXX" != yes ; then
1428                 CXX_AR='$(CXX)'
1429                 CXX_ARFLAGS='-xar -o'
1430             fi
1431             ;;
1432         esac
1433         AC_SUBST(CXXLDFLAGS)
1434         AC_SUBST(CXX_AR)
1435         AC_SUBST(CXX_ARFLAGS)
1436 else
1437         cf_cxx_library=no
1438         cf_cv_builtin_bool=1
1439
1440         # Just because we are not configuring against C++ right now does not
1441         # mean that a user will not want to use C++.  Some distributors disable
1442         # the C++ portion of this configuration as a shortcut (or just to avoid
1443         # compiling the demo in the c++ directory).  So we need a reasonable
1444         # default for the 'bool' type.
1445         #
1446         # Caveat: since the storage of the bool type is not standardized, it
1447         # may change.
1448
1449         if test "$NCURSES_BOOL" != auto ; then
1450                 cf_cv_type_of_bool=$NCURSES_BOOL
1451                 cf_cv_header_stdbool_h=0
1452         else
1453                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1454                         CF_BOOL_SIZE
1455                 else
1456                         AC_MSG_CHECKING(for fallback type of bool)
1457                         case "$host_cpu" in #(vi
1458                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1459                         *)      cf_cv_type_of_bool=int  ;;
1460                         esac
1461                         AC_MSG_RESULT($cf_cv_type_of_bool)
1462                 fi
1463         fi
1464 fi
1465 AC_SUBST(CXXLIBS)
1466
1467 # If the C compiler did not declare bool, and we did not determine that the C++
1468 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1469 # ncurses library use the same type as C++ bool.  Note that this allows one to
1470 # specify the type of bool in a configure-script option and postpone
1471 # integration with the C++ compiler provided that the types are compatible.
1472 USE_CXX_BOOL=1
1473 if test $cf_cv_cc_bool_type = 1
1474 then
1475         # oops: C has a bool.  Unlikely, but C++ could differ.
1476         USE_CXX_BOOL=0
1477 elif test $cf_cv_builtin_bool = 0
1478 then
1479         # C++ has no bool
1480         USE_CXX_BOOL=0
1481 else
1482         # this is the normal case
1483         USE_CXX_BOOL='defined(__cplusplus)'
1484 fi
1485 AC_SUBST(USE_CXX_BOOL)
1486
1487 CF_HELP_MESSAGE(Ada95 Binding Options:)
1488
1489 dnl If the Ada95 source-tree is present, add that to the build unless it will
1490 dnl not work, or was not requested.
1491 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1492
1493 dnl libtool does not know anything about GNAT, though a change made in 1998
1494 dnl provided for it "someday".  Disable the ada subtree if we are using
1495 dnl libtool -TD 20070714
1496 if test "$cf_with_ada" != "no" ; then
1497     if test "$with_libtool" != "no"; then
1498         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1499         cf_with_ada=no
1500     fi
1501 fi
1502
1503 dnl Check for availability of GNU Ada Translator (GNAT).
1504 dnl At the moment we support no other Ada95 compiler.
1505 if test "$cf_with_ada" != "no" ; then
1506 cf_ada_make=gnatmake
1507 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
1508 if test "$ac_cv_prog_gnat_exists" = no; then
1509    cf_ada_make=
1510 else
1511    CF_GNAT_VERSION
1512    AC_CHECK_PROG(M4_exists, m4, yes, no)
1513    if test "$ac_cv_prog_M4_exists" = no; then
1514       cf_cv_prog_gnat_correct=no
1515       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
1516    fi
1517    if test "$cf_cv_prog_gnat_correct" = yes; then
1518       AC_MSG_CHECKING(if GNAT works)
1519       CF_GNAT_TRY_RUN([procedure conftest;],
1520 [with Text_IO;
1521 with GNAT.OS_Lib;
1522 procedure conftest is
1523 begin
1524    Text_IO.Put ("Hello World");
1525    Text_IO.New_Line;
1526    GNAT.OS_Lib.OS_Exit (0);
1527 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
1528       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
1529    fi
1530 fi
1531 if test "$cf_cv_prog_gnat_correct" = yes; then
1532    ADAFLAGS="-O3 -gnatpn $ADAFLAGS"
1533
1534    AC_MSG_CHECKING(if GNAT pragma Unreferenced works)
1535    CF_GNAT_TRY_LINK([procedure conftest;],
1536 [with Text_IO;
1537 with GNAT.OS_Lib;
1538 procedure conftest is
1539    test : Integer;
1540    pragma Unreferenced (test);
1541 begin
1542    test := 1;
1543    Text_IO.Put ("Hello World");
1544    Text_IO.New_Line;
1545    GNAT.OS_Lib.OS_Exit (0);
1546 end conftest;],[cf_cv_pragma_unreferenced=yes],[cf_cv_pragma_unreferenced=no])
1547    AC_MSG_RESULT($cf_cv_pragma_unreferenced)
1548
1549    # if the pragma is supported, use it (needed in the Trace code).
1550    if test $cf_cv_pragma_unreferenced = yes ; then
1551       PRAGMA_UNREF=TRUE
1552    else
1553       PRAGMA_UNREF=FALSE
1554    fi
1555
1556    AC_ARG_WITH(ada-compiler,
1557         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
1558         [cf_ada_compiler=$withval],
1559         [cf_ada_compiler=gnatmake])
1560
1561    cf_ada_package=terminal_interface
1562
1563    AC_SUBST(cf_ada_make)
1564    AC_SUBST(cf_ada_compiler)
1565    AC_SUBST(cf_ada_package)
1566    AC_SUBST(ADAFLAGS)
1567    AC_SUBST(cf_compile_generics)
1568    AC_SUBST(cf_generic_objects)
1569    AC_SUBST(PRAGMA_UNREF)
1570
1571    CF_WITH_PATH(ada-include,
1572        [  --with-ada-include=DIR  Ada includes are in DIR],
1573        ADA_INCLUDE,
1574        PREFIX/lib/ada/adainclude,
1575        [$]prefix/lib/ada/adainclude)
1576    AC_SUBST(ADA_INCLUDE)
1577
1578    CF_WITH_PATH(ada-objects,
1579        [  --with-ada-objects=DIR  Ada objects are in DIR],
1580        ADA_OBJECTS,
1581        PREFIX/lib/ada/adalib,
1582        [$]prefix/lib/ada/adalib)
1583    AC_SUBST(ADA_OBJECTS)
1584
1585 fi
1586 fi
1587 else
1588    cf_with_ada=no
1589 fi
1590
1591 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1592 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1593 ###
1594 ### ticlib modules may be a separate library, otherwise contained in termlib.
1595 ### termlib modules may be a separate library, otherwise contained in ncurses.
1596 ###
1597 ### The of "+" or " " between the tokens controls the way the script
1598 ### chooses to split module lists into libraries.
1599 ###
1600 ### (see CF_LIB_RULES).
1601 AC_MSG_CHECKING(for library subsets)
1602 LIB_SUBSETS=
1603
1604 if test "$cf_with_progs" = yes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1605         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1606         if test "$with_ticlib" != no ; then
1607                 LIB_SUBSETS="${LIB_SUBSETS} "
1608         else
1609                 LIB_SUBSETS="${LIB_SUBSETS}+"
1610         fi
1611 fi
1612
1613 LIB_SUBSETS="${LIB_SUBSETS}termlib+port_drivers"
1614
1615 case $cf_cv_system_name in #(vi
1616 *mingw32*) #(vi
1617         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1618         ;;
1619 *) #(vi
1620         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1621         ;;
1622 esac
1623
1624 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1625 if test "$with_termlib" != no ; then
1626         LIB_SUBSETS="${LIB_SUBSETS} "
1627 else
1628         LIB_SUBSETS="${LIB_SUBSETS}+"
1629 fi
1630
1631 LIB_SUBSETS="${LIB_SUBSETS}base"
1632
1633 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1634 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1635
1636 AC_MSG_RESULT($LIB_SUBSETS)
1637
1638 ### Construct the list of include-directories to be generated
1639 CF_INCLUDE_DIRS
1640 CF_ADA_INCLUDE_DIRS
1641
1642 ### Build up pieces for makefile rules
1643 AC_MSG_CHECKING(default library suffix)
1644 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1645 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1646 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1647
1648 AC_MSG_CHECKING(default library-dependency suffix)
1649 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1650 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1651 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1652
1653 AC_MSG_CHECKING(default object directory)
1654 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1655 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1656 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1657
1658 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1659 if test "$cf_with_cxx" = yes ; then
1660 AC_MSG_CHECKING(c++ library-dependency suffix)
1661 if test "$with_libtool" != "no"; then
1662         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1663 else
1664         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)dnl we normally make a static library
1665 fi
1666 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1667 AC_SUBST(CXX_LIB_SUFFIX)
1668 fi
1669
1670 # do not want -ldl in build except as needed for -lncurses dependency
1671 if test "$with_dlsym" = yes ; then
1672 if test $DFT_LWR_MODEL = shared || \
1673    test $DFT_LWR_MODEL = libtool ; then
1674         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1675 fi
1676 fi
1677 ### Set up low-level terminfo dependencies for makefiles.
1678
1679 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1680 # do not need libdl
1681 TICS_LIST=
1682 if test "$with_dlsym" = yes ; then
1683         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1684 fi
1685
1686 if test "$with_ticlib" != no ; then
1687
1688         if test "$with_ticlib" != yes ; then
1689                 TICS_NAME=$with_ticlib
1690                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1691                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1692                 TICS_LIB_SUFFIX="${with_ticlib}"
1693         else
1694                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1695                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1696                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1697         fi
1698         TICS_ARGS="-L${LIB_DIR} -l${TICS_LIB_SUFFIX}"
1699 else
1700         TICS_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1701 fi
1702 AC_SUBST(TICS_ARG_SUFFIX)
1703 AC_SUBST(TICS_DEP_SUFFIX)
1704 AC_SUBST(TICS_LIB_SUFFIX)
1705 AC_SUBST(TICS_ARGS)
1706
1707 if test "$with_termlib" != no ; then
1708
1709         if test "$with_termlib" != yes ; then
1710                 TINFO_NAME=$with_termlib
1711                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1712                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1713                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1714                 TINFO_LIB_SUFFIX="${with_termlib}"
1715         else
1716                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1717                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1718                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1719                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1720         fi
1721
1722         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1723         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1724         if test "$DFT_LWR_MODEL" = "libtool"; then
1725                 TEST_ARGS="${TEST_DEPS}"
1726                 TEST_ARG2="${TEST_DEP2}"
1727                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1728         else
1729                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1730                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1731                 TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1732                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1733                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1734         fi
1735 else
1736         # the next lines are needed for linking libtic over libncurses
1737         TINFO_NAME=${LIB_NAME}
1738         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1739         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1740         if test "$with_tic_depends" = yes ; then
1741                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1742         else
1743                 TICS_LIST="$SHLIB_LIST"
1744         fi
1745
1746         TINFO_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1747 fi
1748
1749 if test "$DFT_LWR_MODEL" = shared ; then
1750         case $cf_cv_system_name in #(vi
1751         cygwin*)
1752                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
1753                 TINFO_SUFFIX=.dll
1754                 ;;
1755         esac
1756 fi
1757
1758 AC_SUBST(TINFO_ARG_SUFFIX)
1759 AC_SUBST(TINFO_DEP_SUFFIX)
1760 AC_SUBST(TINFO_LIB_SUFFIX)
1761 AC_SUBST(TINFO_ARGS)
1762
1763 if test "$with_dlsym" = yes ; then
1764         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1765 fi
1766
1767 if test "$DFT_LWR_MODEL" = "libtool"; then
1768     OBJEXT=lo
1769 fi
1770
1771 # needed for Ada95
1772 TINFO_ARGS2=`echo "$TINFO_ARGS" | sed -e 's,-L\.\./,-L../../,'`
1773 AC_SUBST(TINFO_ARGS2)
1774
1775 case $DFT_LWR_MODEL in
1776 normal|debug|profile)
1777         CF_LDFLAGS_STATIC
1778         ;;
1779 esac
1780
1781 AC_MSG_CHECKING(where we will install curses.h)
1782 test "$with_overwrite" = no && \
1783 test "x$includedir" = 'x${prefix}/include' && \
1784         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1785 AC_MSG_RESULT($includedir)
1786
1787 ### Resolve a conflict between normal and wide-curses by forcing applications
1788 ### that will need libutf8 to add it to their configure script.
1789 if test "$with_overwrite" != no ; then
1790 if test "$NCURSES_LIBUTF8" = 1 ; then
1791         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1792         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1793 fi
1794 fi
1795 WITH_OVERWRITE=$with_overwrite
1796
1797 AC_SUBST(WITH_OVERWRITE)
1798 AC_SUBST(TICS_LIST)
1799 AC_SUBST(TINFO_LIST)
1800 AC_SUBST(SHLIB_LIST)
1801
1802 # used to separate tack out of the tree
1803 NCURSES_TREE=
1804 AC_SUBST(NCURSES_TREE)
1805
1806 ### predefined stuff for the test programs
1807 AC_DEFINE(HAVE_SLK_COLOR)
1808
1809 ### Construct the list of subdirectories for which we'll customize makefiles
1810 ### with the appropriate compile-rules.
1811
1812 CF_SRC_MODULES($modules_to_build)
1813
1814 if test "$cf_with_ada" != "no" && test "$cf_cv_prog_gnat_correct" != "no"; then
1815    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${DFT_ARG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
1816 fi
1817
1818 CF_DIRS_TO_MAKE
1819
1820 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR')
1821
1822 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1823
1824 ### Now that we're done running tests, add the compiler-warnings, if any
1825 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1826
1827 ### If we're building with rpath, try to link non-standard libs that way too.
1828 if test "$DFT_LWR_MODEL" = "shared"; then
1829   CF_RPATH_HACK
1830 fi
1831
1832 ### Define substitutions for header files to avoid name-pollution
1833 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1834 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1835 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1836
1837 ################################################################################
1838 test "$use_database" = yes && \
1839 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1840
1841 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1842
1843 if test x"$enable_pc_files" = xyes ; then \
1844 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
1845 MAKE_PC_FILES=
1846 else
1847 MAKE_PC_FILES="#"
1848 fi
1849 AC_SUBST(MAKE_PC_FILES)
1850
1851 AC_OUTPUT( \
1852         include/MKterm.h.awk \
1853         include/curses.head:include/curses.h.in \
1854         include/termcap.h \
1855         include/unctrl.h \
1856         $SUB_MAKEFILES \
1857         Makefile,[
1858 CF_PRG_RULES([$srcdir/test/mk-test.awk ECHO_LINK="$ECHO_LINK"], test)
1859 CF_LIB_RULES($SRC_SUBDIRS)
1860 ],[
1861 ### Special initialization commands, used to pass information from the
1862 ### configuration-run into config.status
1863
1864 AWK="$AWK"
1865 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1866 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1867 ECHO_LINK="$ECHO_LINK"
1868 LDCONFIG="$LDCONFIG"
1869 LIB_NAME="$LIB_NAME"
1870 LIB_SUBSETS="$LIB_SUBSETS"
1871 LIB_SUFFIX="$LIB_SUFFIX"
1872 LIB_TRACING="$LIB_TRACING"
1873 MAKE_TERMINFO="$MAKE_TERMINFO"
1874 NCURSES_MAJOR="$NCURSES_MAJOR"
1875 NCURSES_MINOR="$NCURSES_MINOR"
1876 NCURSES_OSPEED="$NCURSES_OSPEED"
1877 NCURSES_PATCH="$NCURSES_PATCH"
1878 SRC_SUBDIRS="$SRC_SUBDIRS"
1879 TERMINFO="$TERMINFO"
1880 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1881 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1882 TICS_NAME="$TICS_NAME"
1883 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1884 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1885 TINFO_NAME="$TINFO_NAME"
1886 TINFO_SUFFIX="$TINFO_SUFFIX"
1887 WITH_CURSES_H="$with_curses_h"
1888 WITH_ECHO="$with_echo"
1889 WITH_OVERWRITE="$with_overwrite"
1890 cf_LIST_MODELS="$cf_list_models"
1891 cf_cv_abi_version="$cf_cv_abi_version"
1892 cf_cv_do_relink="$cf_cv_do_relink"
1893 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1894 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1895 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1896 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1897 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1898 cf_cv_rel_version="$cf_cv_rel_version"
1899 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1900 cf_cv_shared_soname='$cf_cv_shared_soname'
1901 cf_cv_shlib_version="$cf_cv_shlib_version"
1902 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1903 cf_cv_system_name="$cf_cv_system_name"
1904 cf_with_cxx_binding="$cf_with_cxx_binding"
1905 cf_with_manpages="$cf_with_manpages"
1906 host="$host"
1907 target="$target"
1908
1909 ],cat)dnl
1910 ${MAKE-make} preinstall