configure.in

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2020,2021 Thomas E. Dickey                                *
   3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey 1995-on
  31 dnl
  32 dnl $Id: configure.in,v 1.738 2021/12/04 23:10:01 tom Exp $
  33 dnl Process this file with autoconf to produce a configure script.
  34 dnl
  35 dnl For additional information, see
  36 dnl     https://invisible-island.net/autoconf/
  37 dnl     https://invisible-island.net/autoconf/my-autoconf.html
  38 dnl
  39 dnl ---------------------------------------------------------------------------
  40 AC_PREREQ(2.52.20210101)
  41 AC_REVISION($Revision: 1.738 $)
  42 AC_INIT(ncurses/base/lib_initscr.c)
  43 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  44
  45 AC_DEFUN([AC_PATH_XTRA],[])dnl ignore dependencies on this
  46
  47 CF_TOP_BUILDDIR
  48 CF_SUBST_NCURSES_VERSION
  49 CF_VERSION_INFO(NCURSES,ncurses)
  50
  51 CF_WITH_REL_VERSION(NCURSES)
  52 CF_NCURSES_WITH_ABI_VERSION
  53
  54 CF_WITH_SYSTYPE
  55
  56 ###     Save the given $CFLAGS to allow user-override.
  57 cf_user_CFLAGS="$CFLAGS"
  58
  59 ###     Default install-location
  60 CF_CFG_DEFAULTS
  61 ### Defaults for ncurses ABI
  62 CF_ABI_DEFAULTS
  63
  64 ###     Checks for programs.
  65 AC_ARG_WITH(ada,
  66         [  --without-ada           suppress check for Ada compiler, don't build demo],
  67         [cf_with_ada=$withval],
  68         [cf_with_ada=yes])
  69
  70 if test "x$cf_with_ada" = xyes
  71 then
  72         cf_prog_cc="gnatgcc gcc cc"
  73 else
  74         cf_prog_cc="gcc cc"
  75 fi
  76 CF_PROG_CC($cf_prog_cc)
  77
  78 AC_PROG_CPP
  79 AC_PROG_GCC_TRADITIONAL
  80 CF_PROG_CC_C_O(CC,[$CFLAGS $CPPFLAGS])
  81 CF_PROG_LDCONFIG
  82
  83 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  84 dnl                             configure script by not letting us test if C++
  85 dnl                             is present, making this option necessary.
  86 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  87 AC_ARG_WITH(cxx,
  88         [  --without-cxx           do not adjust ncurses bool to match C++],
  89         [cf_with_cxx=$withval],
  90         [cf_with_cxx=yes])
  91 AC_MSG_RESULT($cf_with_cxx)
  92 if test "X$cf_with_cxx" = Xno ; then
  93         CXX=""
  94         GXX=""
  95 else
  96         # with autoconf 2.13, we can change the error to a warning:
  97         pushdef([AC_MSG_ERROR],
  98                 [AC_MSG_RESULT(no)
  99                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
 100                 cf_with_cxx=no; CXX=""; GXX="";])dnl
 101         AC_PROG_CXX
 102         popdef([AC_MSG_ERROR])dnl
 103
 104         AC_LANG_PUSH(C++)
 105         if test "x$cf_with_cxx" != xno
 106         then
 107                 # Several of the C++ configurations do not work, particularly when
 108                 # cross-compiling (20140913 -TD)
 109                 AC_MSG_CHECKING(if $CXX works)
 110
 111                 save_CPPFLAGS="$CPPFLAGS"
 112                 eval cf_includedir=${includedir}
 113                 CPPFLAGS="$CPPFLAGS -I${cf_includedir}"
 114                 AC_TRY_COMPILE([
 115 #include <stdlib.h>
 116 #include <stdio.h>
 117 ],
 118                 [
 119                 printf("Hello world!\n")
 120                 ],
 121                 [cf_cxx_works=yes],
 122                 [cf_cxx_works=no])
 123                 CPPFLAGS="$save_CPPFLAGS"
 124
 125                 AC_MSG_RESULT($cf_cxx_works)
 126                 if test "x$cf_cxx_works" = xno
 127                 then
 128                         AC_MSG_WARN([Ignore $CXX, since it cannot compile hello-world.])
 129                         cf_with_cxx=no; CXX=""; GXX="";
 130                 fi
 131         fi
 132         AC_LANG_POP
 133
 134         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
 135         if test "$CXX" = "g++" ; then
 136                 AC_PATH_PROG(CXX,g++)
 137         fi
 138         case "x$CXX" in
 139         (x|xg++)
 140                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
 141                 cf_with_cxx=no; CXX=""; GXX="";
 142                 ;;
 143         esac
 144 fi
 145
 146 CF_GXX_VERSION
 147 case "$GXX_VERSION" in
 148 ([[1-9]][[0-9]].*)
 149         ;;
 150 (1.*|2.[[0-6]]*)
 151         AC_MSG_WARN(templates do not work)
 152         ;;
 153 esac
 154
 155 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 156 AC_ARG_WITH(cxx-binding,
 157         [  --without-cxx-binding   do not build C++ binding and demo],
 158         [cf_with_cxx_binding=$withval],
 159         [cf_with_cxx_binding=$cf_with_cxx])
 160 AC_MSG_RESULT($cf_with_cxx_binding)
 161
 162 AC_MSG_CHECKING(if you want to build with Ada)
 163 AC_MSG_RESULT($cf_with_ada)
 164
 165 AC_MSG_CHECKING(if you want to install terminal database)
 166 AC_ARG_ENABLE(db-install,
 167         [  --disable-db-install    suppress install of terminal database],
 168         [cf_with_db_install=$enableval],
 169         [cf_with_db_install=yes])
 170 AC_MSG_RESULT($cf_with_db_install)
 171
 172 AC_MSG_CHECKING(if you want to install manpages)
 173 AC_ARG_WITH(manpages,
 174         [  --without-manpages      suppress install of manpages],
 175         [cf_with_manpages=$withval],
 176         [cf_with_manpages=yes])
 177 AC_MSG_RESULT($cf_with_manpages)
 178
 179 AC_MSG_CHECKING(if you want to build programs such as tic)
 180 AC_ARG_WITH(progs,
 181         [  --without-progs         suppress build/install with programs (e.g., tic)],
 182         [cf_with_progs=$withval],
 183         [cf_with_progs=yes])
 184 AC_MSG_RESULT($cf_with_progs)
 185
 186 if test -f "$srcdir/tack/tack.h" ; then
 187         if test "x$cross_compiling" = xyes ; then
 188                 CF_VERBOSE(ignoring tack because we are cross-compiling)
 189                 cf_with_tack=no
 190         else
 191                 AC_MSG_CHECKING(if you want to build the tack program)
 192                 AC_ARG_WITH(tack,
 193                         [  --without-tack          suppress build/install with tack program],
 194                         [cf_with_tack=$withval],
 195                         [cf_with_tack=$cf_with_progs])
 196                 AC_MSG_RESULT($cf_with_tack)
 197         fi
 198 else
 199         cf_with_tack=no
 200 fi
 201
 202 AC_MSG_CHECKING(if you want to build test-programs)
 203 AC_ARG_WITH(tests,
 204         [  --without-tests         suppress build/install with test-programs],
 205         [cf_with_tests=$withval],
 206         [cf_with_tests=yes])
 207 AC_MSG_RESULT($cf_with_tests)
 208
 209 AC_MSG_CHECKING(if you wish to install curses.h)
 210 AC_ARG_WITH(curses-h,
 211         [  --without-curses-h      install curses.h as ncurses.h only],
 212         [with_curses_h=$withval],
 213         [with_curses_h=yes])
 214 AC_MSG_RESULT($with_curses_h)
 215
 216 modules_to_build="ncurses"
 217 test "X$cf_with_progs" != Xno && modules_to_build="$modules_to_build progs"
 218 test "X$cf_with_tack"  != Xno && modules_to_build="$modules_to_build tack"
 219 modules_to_build="$modules_to_build panel menu form"
 220
 221 AC_ARG_PROGRAM
 222
 223 CF_PROG_AWK
 224 CF_PROG_INSTALL
 225 CF_PROG_LINT
 226 CF_PROG_LN_S
 227
 228 AC_SYS_LONG_FILE_NAMES
 229
 230 # Provide for renaming "ncurses5-config" to "ncurses5X-config", etc., in case
 231 # of package conflict.
 232 cf_config_suffix=
 233 AC_ARG_WITH(config-suffix,
 234         [  --with-config-suffix=X  suffixes ncursesXX-config file],
 235         [case "x$withval" in
 236         (xyes|xno)
 237                 AC_MSG_WARN(expected a value for config-suffix option)
 238                 ;;
 239         (*)     cf_config_suffix="$withval"
 240                 ;;
 241         esac])
 242 AC_SUBST(cf_config_suffix)
 243
 244 # If we find pkg-config, check if we should install the ".pc" files.
 245 CF_PKG_CONFIG
 246 CF_WITH_PKG_CONFIG_LIBDIR
 247 CF_ENABLE_PC_FILES
 248 if test -z "$MAKE_PC_FILES"
 249 then
 250         AC_MSG_CHECKING(for suffix to add to pc-files)
 251 AC_ARG_WITH(pc-suffix,
 252         [  --with-pc-suffix        suffixes pc-files],
 253         [case "x$withval" in
 254         (xyes|xno)
 255                 PC_MODULE_SUFFIX=
 256                 ;;
 257         (*)     PC_MODULE_SUFFIX="$withval"
 258                 ;;
 259         esac])
 260         test -z "$PC_MODULE_SUFFIX" && PC_MODULE_SUFFIX=none
 261         AC_MSG_RESULT($PC_MODULE_SUFFIX)
 262         test "$PC_MODULE_SUFFIX" = none && PC_MODULE_SUFFIX=
 263         AC_SUBST(PC_MODULE_SUFFIX)
 264 fi
 265
 266 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 267 AC_ARG_ENABLE(mixed-case,
 268         [  --enable-mixed-case     tic should assume mixed-case filenames],
 269         [enable_mixedcase=$enableval],
 270         [enable_mixedcase=auto])
 271 AC_MSG_RESULT($enable_mixedcase)
 272 if test "$enable_mixedcase" = "auto" ; then
 273         CF_MIXEDCASE_FILENAMES
 274 else
 275         cf_cv_mixedcase=$enable_mixedcase
 276         if test "x$enable_mixedcase" = "xyes" ; then
 277                 AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
 278         fi
 279 fi
 280
 281 # do this after mixed-case option (tags/TAGS is not as important as tic).
 282 AC_PROG_MAKE_SET
 283 CF_MAKE_PHONY
 284 CF_MAKE_TAGS
 285 CF_MAKEFLAGS
 286
 287 dnl These are standard among *NIX systems, but not when cross-compiling
 288 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 289 AC_CHECK_TOOL(LD, ld, ld)
 290 AC_CHECK_TOOL(AR, ar, ar)
 291 AC_CHECK_TOOL(NM, nm, nm)
 292 CF_AR_FLAGS
 293
 294 dnl Special option for use by system-builders: the install-prefix is used to
 295 dnl adjust the location into which the actual install is done, so that an
 296 dnl archive can be built without modifying the host system's configuration.
 297 AC_MSG_CHECKING(if you have specified an install-prefix)
 298 AC_ARG_WITH(install-prefix,
 299         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 300         [case "x$withval" in
 301         (xyes|xno)
 302                 ;;
 303         (*)     DESTDIR="$withval"
 304                 ;;
 305         esac])
 306 AC_MSG_RESULT($DESTDIR)
 307 AC_SUBST(DESTDIR)
 308
 309 ###############################################################################
 310 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 311 # If we're cross-compiling, allow the user to override the tools and their
 312 # options.  The configure script is oriented toward identifying the host
 313 # compiler, etc., but we need a build compiler to generate parts of the source.
 314
 315 case "$cf_cv_system_name" in
 316 (*-msvc*)
 317         LDFLAGS="$LDFLAGS user32.lib"
 318         export LDFLAGS
 319         ;;
 320 esac
 321
 322 CF_BUILD_CC
 323
 324 ###############################################################################
 325 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 326
 327 ### Options to allow the user to specify the set of libraries which are used.
 328 ### Use "--without-normal --with-shared" to allow the default model to be
 329 ### shared, for example.
 330 cf_list_models=""
 331 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 332
 333 CF_WITH_LIBTOOL
 334 if test "$with_libtool" != "no" ; then
 335
 336 cf_list_models="$cf_list_models libtool"
 337
 338 else
 339
 340 AC_MSG_CHECKING(if you want to build shared libraries)
 341 AC_ARG_WITH(shared,
 342         [  --with-shared           generate shared-libraries],
 343         [with_shared=$withval],
 344         [with_shared=no])
 345 AC_MSG_RESULT($with_shared)
 346 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
 347
 348 AC_MSG_CHECKING(if you want to build static libraries)
 349 AC_ARG_WITH(normal,
 350         [  --with-normal           generate normal-libraries (default)],
 351         [with_normal=$withval],
 352         [with_normal=yes])
 353 AC_MSG_RESULT($with_normal)
 354 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
 355
 356 AC_MSG_CHECKING(if you want to build debug libraries)
 357 AC_ARG_WITH(debug,
 358         [  --with-debug            generate debug-libraries (default)],
 359         [with_debug=$withval],
 360         [with_debug=yes])
 361 AC_MSG_RESULT($with_debug)
 362 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
 363
 364 AC_MSG_CHECKING(if you want to build profiling libraries)
 365 AC_ARG_WITH(profile,
 366         [  --with-profile          generate profile-libraries],
 367         [with_profile=$withval],
 368         [with_profile=no])
 369 AC_MSG_RESULT($with_profile)
 370 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
 371
 372 fi
 373
 374 if test "X$cf_with_cxx_binding" != Xno; then
 375 if test "x$with_shared" = "xyes"; then
 376 AC_MSG_CHECKING(if you want to build C++ shared libraries)
 377 AC_ARG_WITH(cxx-shared,
 378         [  --with-cxx-shared       generate C++ shared-libraries],
 379         [with_shared_cxx=$withval],
 380         [with_shared_cxx=no])
 381 AC_MSG_RESULT($with_shared_cxx)
 382 fi
 383 fi
 384
 385 ###############################################################################
 386
 387 AC_MSG_CHECKING(for specified models)
 388 test -z "$cf_list_models" && cf_list_models=normal
 389 dnl If we use libtool to generate libraries, then it must be the only
 390 dnl specified model.
 391 test "$with_libtool" != "no" && cf_list_models=libtool
 392 AC_MSG_RESULT($cf_list_models)
 393
 394 ### Use the first model as the default, and save its suffix for use in building
 395 ### up test-applications.
 396 AC_MSG_CHECKING(for default model)
 397 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 398 AC_MSG_RESULT($DFT_LWR_MODEL)
 399
 400 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 401
 402 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 403 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 404
 405 TICS_NAME=tic
 406 AC_SUBST(TICS_NAME)
 407
 408 TINFO_NAME=tinfo
 409 AC_SUBST(TINFO_NAME)
 410
 411 LIB_NAME=ncurses
 412 AC_SUBST(LIB_NAME)
 413
 414 LIB_DIR=../lib
 415 LIB_2ND=../../lib
 416
 417 CF_WITH_LIB_PREFIX(cf_prefix)
 418
 419 LIB_SUFFIX=
 420 AC_SUBST(LIB_SUFFIX)
 421 CF_PATHSEP
 422
 423 ###############################################################################
 424
 425 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 426 AC_ARG_WITH(termlib,
 427         [  --with-termlib          generate separate terminfo library],
 428         [with_termlib=$withval],
 429         [with_termlib=no])
 430 AC_MSG_RESULT($with_termlib)
 431
 432 AC_MSG_CHECKING(if you want to build a separate tic library)
 433 AC_ARG_WITH(ticlib,
 434         [  --with-ticlib           generate separate tic library],
 435         [with_ticlib=$withval],
 436         [with_ticlib=no])
 437 AC_MSG_RESULT($with_ticlib)
 438
 439 dnl Not all ports of gcc support the -g option
 440
 441 if test X"$CC_G_OPT" = X"" ; then
 442         CC_G_OPT='-g'
 443         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
 444 fi
 445 AC_SUBST(CC_G_OPT)
 446
 447 if test X"$CXX_G_OPT" = X"" ; then
 448         CXX_G_OPT='-g'
 449         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
 450 fi
 451 AC_SUBST(CXX_G_OPT)
 452
 453 AC_MSG_CHECKING(for default loader flags)
 454 case "$DFT_LWR_MODEL" in
 455 (libtool) LD_MODEL=''   ;;
 456 (normal)  LD_MODEL=''   ;;
 457 (debug)   LD_MODEL=$CC_G_OPT ;;
 458 (profile) LD_MODEL='-pg';;
 459 (shared)  LD_MODEL=''   ;;
 460 esac
 461 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 462 AC_MSG_RESULT($LD_MODEL)
 463
 464 case "$DFT_LWR_MODEL" in
 465 (shared)
 466 CF_ENABLE_RPATH
 467 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 468 AC_ARG_ENABLE(relink,
 469 [  --disable-relink        relink shared libraries during install],
 470 [cf_cv_do_relink=$enableval],
 471 [cf_cv_do_relink=yes])
 472 AC_MSG_RESULT($cf_cv_do_relink)
 473         ;;
 474 esac
 475
 476 # we will build libraries one-level down.
 477 rel_builddir=..
 478 CF_SHARED_OPTS
 479 for model in $cf_list_models ; do
 480         case "$model" in
 481         (libtool)
 482                 CF_WITH_LIBTOOL_OPTS
 483                 CF_WITH_EXPORT_SYMS
 484                 ;;
 485         (shared)
 486                 if test "$CC_SHARED_OPTS" = "unknown"; then
 487                         AC_ERROR(Shared libraries are not supported in this version)
 488                 fi
 489                 # workaround for inept transition to PIE vs PIC...
 490                 AC_MSG_CHECKING(if current CFLAGS link properly)
 491                 AC_TRY_LINK(
 492                         [#include <stdio.h>],
 493                         [printf("Hello work\\n");],
 494                         [cf_cflags_work=yes],
 495                         [cf_cflags_work=no])
 496                 AC_MSG_RESULT($cf_cflags_work)
 497                 if test "$cf_cflags_work" = no
 498                 then
 499                         CF_VERBOSE(try to work around by appending shared-options)
 500                         CFLAGS="$CFLAGS $CC_SHARED_OPTS"
 501                 fi
 502                 CF_WITH_VERSIONED_SYMS
 503                 ;;
 504         esac
 505 done
 506
 507 ### Checks for special libraries, must be done up-front.
 508 SHLIB_LIST=""
 509 CF_WITH_GPM
 510 if test "$with_gpm" != no ; then
 511         AC_MSG_CHECKING(if you want to load GPM dynamically)
 512         AC_ARG_WITH(dlsym,
 513                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 514                 [with_dlsym=$withval],
 515                 [with_dlsym=yes])
 516         AC_MSG_RESULT($with_dlsym)
 517         if test "x$with_dlsym" = xyes ; then
 518                 CF_FUNC_DLSYM
 519                 if test "x$with_gpm" != xyes ; then
 520                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 521                         cf_cv_gpm_soname="$with_gpm"
 522                 else
 523                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 524                 fi
 525                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
 526                 SHLIB_LIST="-ldl $SHLIB_LIST"
 527                 CF_ADD_LIB(dl,PRIVATE_LIBS)
 528         else
 529                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 530                 CF_ADD_LIB(gpm,TEST_LIBS)
 531                 CF_ADD_LIB(gpm,PRIVATE_LIBS)
 532         fi
 533         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
 534         CF_CHECK_GPM_WGETCH
 535 fi
 536
 537 CF_WITH_PCRE2
 538 CF_WITH_SYSMOUSE
 539
 540 # pretend that ncurses==ncursesw==ncursest
 541 AC_MSG_CHECKING(if you want to disable library suffixes)
 542 CF_ARG_DISABLE(lib-suffixes,
 543         [  --disable-lib-suffixes  disable library suffixes],
 544         [disable_lib_suffixes=yes],
 545         [disable_lib_suffixes=no],
 546         no)
 547 AC_MSG_RESULT($disable_lib_suffixes)
 548
 549 ### If we're building with rpath, try to link non-standard libs that way too.
 550 if test "$DFT_LWR_MODEL" = "shared" && test "x$cf_cv_enable_rpath" != xno; then
 551         CF_DISABLE_RPATH_HACK
 552 fi
 553
 554 ### Depending on the system, someone may use rpath to build ncurses but not
 555 # want users of the package to rely upon that feature.  Give those people an
 556 # option to suppress that detail from EXTRA_LDFLAGS.
 557 EXTRA_PKG_LDFLAGS="$LDFLAGS $EXTRA_LDFLAGS"
 558 if test -n "$EXTRA_PKG_LDFLAGS"
 559 then
 560         AC_MSG_CHECKING(if you want to disable extra LDFLAGS for package-scripts)
 561         CF_ARG_DISABLE(pkg-ldflags,
 562                 [  --disable-pkg-ldflags   disable extra LDFLAGS for package-scripts],
 563                 [disable_pkg_ldflags=yes],
 564                 [disable_pkg_ldflags=no],
 565                 no)
 566         AC_MSG_RESULT($disable_pkg_ldflags)
 567         test "$disable_pkg_ldflags" = yes && EXTRA_PKG_LDFLAGS=
 568 fi
 569 AC_SUBST(EXTRA_PKG_LDFLAGS)
 570
 571 ###############################################################################
 572 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 573
 574 ###     use option --with-extra-suffix to append suffix to headers and libraries
 575 AC_MSG_CHECKING(if you wish to append extra suffix to header/library paths)
 576 EXTRA_SUFFIX=
 577 AC_ARG_WITH(extra-suffix,
 578         [  --with-extra-suffix=X   append extra suffix to header/library paths],
 579         [case x$withval in
 580         (xno)
 581                 ;;
 582         (xyes|x)
 583                 EXTRA_SUFFIX=$cf_cv_abi_version
 584                 ;;
 585         (*)
 586                 EXTRA_SUFFIX=$withval
 587                 ;;
 588         esac
 589         ])
 590 AC_MSG_RESULT($EXTRA_SUFFIX)
 591 AC_SUBST(EXTRA_SUFFIX)
 592
 593 ###     use option --disable-overwrite to leave out the link to -lcurses
 594 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 595 AC_ARG_ENABLE(overwrite,
 596         [  --disable-overwrite     put headers in subdir, omit link to -lcurses],
 597         [with_overwrite=$enableval],
 598         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 599 AC_MSG_RESULT($with_overwrite)
 600
 601 AC_MSG_CHECKING(if external terminfo-database is used)
 602 AC_ARG_ENABLE(database,
 603         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 604         [use_database=$enableval],
 605         [use_database=yes])
 606 AC_MSG_RESULT($use_database)
 607
 608 case "$host_os" in
 609 (os2*)
 610         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 611         ;;
 612 (*)
 613         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 614         ;;
 615 esac
 616 AC_SUBST(TERMINFO_SRC)
 617
 618 NCURSES_USE_DATABASE=0
 619 if test "$use_database" != no ; then
 620         NCURSES_USE_DATABASE=1
 621
 622         AC_MSG_CHECKING(which terminfo source-file will be installed)
 623         AC_ARG_WITH(database,
 624                 [  --with-database=XXX     specify terminfo source to install],
 625                 [TERMINFO_SRC=$withval])
 626         AC_MSG_RESULT($TERMINFO_SRC)
 627
 628         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 629         AC_ARG_WITH(hashed-db,
 630                 [  --with-hashed-db        specify hashed-database library],,
 631                 [with_hashed_db=no])
 632         AC_MSG_RESULT($with_hashed_db)
 633 else
 634         with_hashed_db=no
 635 fi
 636 AC_SUBST(NCURSES_USE_DATABASE)
 637
 638 AC_MSG_CHECKING(for list of fallback descriptions)
 639 AC_ARG_WITH(fallbacks,
 640         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 641         [with_fallback=$withval],
 642         [with_fallback=])
 643 AC_MSG_RESULT($with_fallback)
 644
 645 case ".$with_fallback" in
 646 (.|.no)
 647         FALLBACK_LIST=
 648         ;;
 649 (.yes)
 650         AC_MSG_WARN(expected a list of terminal descriptions)
 651         ;;
 652 (*)
 653         FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 654         ;;
 655 esac
 656
 657 # The fallback feature in ncurses relies upon tic/infocmp outside the build
 658 # tree for generating the terminal descriptions that will be compiled into the
 659 # library.  If your toolchain is old, it may not handle current terminal
 660 # databases.  Use configure-options to point to the tools which will be used,
 661 # rather than the first ones found on the $PATH.
 662 AC_CHECK_TOOL(TIC, tic)
 663 AC_CHECK_TOOL(INFOCMP, infocmp)
 664 if test -n "$FALLBACK_LIST"
 665 then
 666         CF_WITH_PATH_PROG(TIC,     tic,     [for fallbacks], $PATH:/usr/local/ncurses/bin)
 667         CF_WITH_PATH_PROG(INFOCMP, infocmp, [for fallbacks], $PATH:/usr/local/ncurses/bin)
 668         test -z "$TIC" && FALLBACK_LIST=
 669         test -z "$INFOCMP" && FALLBACK_LIST=
 670         if test -z "$FALLBACK_LIST"
 671         then
 672                 AC_MSG_WARN(ignoring fallback option because tic/infocmp are not available)
 673         fi
 674 fi
 675 AC_SUBST(TIC)
 676 AC_SUBST(INFOCMP)
 677
 678 USE_FALLBACKS=
 679 test -z "$FALLBACK_LIST" && USE_FALLBACKS="#"
 680 AC_SUBST(FALLBACK_LIST)
 681 AC_SUBST(USE_FALLBACKS)
 682
 683 AC_MSG_CHECKING(if you want modern xterm or antique)
 684 AC_ARG_WITH(xterm-new,
 685         [  --without-xterm-new     specify if xterm terminfo should be old version],
 686         [with_xterm_new=$withval],
 687         [with_xterm_new=yes])
 688 case "$with_xterm_new" in
 689 (no) with_xterm_new=xterm-old;;
 690 (*)      with_xterm_new=xterm-new;;
 691 esac
 692 AC_MSG_RESULT($with_xterm_new)
 693 WHICH_XTERM=$with_xterm_new
 694 AC_SUBST(WHICH_XTERM)
 695
 696 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
 697 AC_ARG_WITH(xterm-kbs,
 698         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
 699         [with_xterm_kbs=$withval],
 700         [with_xterm_kbs=BS])
 701 case x$with_xterm_kbs in
 702 (xyes|xno|xBS|xbs|x8)
 703         with_xterm_kbs=BS
 704         ;;
 705 (xDEL|xdel|x127)
 706         with_xterm_kbs=DEL
 707         ;;
 708 (*)
 709         with_xterm_kbs=$withval
 710         ;;
 711 esac
 712 AC_MSG_RESULT($with_xterm_kbs)
 713 XTERM_KBS=$with_xterm_kbs
 714 AC_SUBST(XTERM_KBS)
 715
 716 MAKE_TERMINFO=
 717 if test "$use_database" = no ; then
 718         TERMINFO="${datadir}/terminfo"
 719         MAKE_TERMINFO="#"
 720 else
 721
 722 AC_MSG_CHECKING(for list of terminfo directories)
 723 CF_WITH_PATHLIST(terminfo-dirs,
 724         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 725         TERMINFO_DIRS,
 726         DATADIR/terminfo,
 727         ${datadir}/terminfo)
 728 AC_MSG_RESULT($TERMINFO_DIRS)
 729 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
 730
 731 case "x$TERMINFO" in
 732 x???:*)
 733         AC_MSG_WARN(ignoring non-directory/file TERMINFO value)
 734         unset TERMINFO
 735         ;;
 736 esac
 737
 738 AC_MSG_CHECKING(for default terminfo directory)
 739 CF_WITH_PATH(default-terminfo-dir,
 740         [  --with-default-terminfo-dir=DIR default terminfo directory],
 741         TERMINFO,
 742         DATADIR/terminfo,
 743         ${datadir}/terminfo)
 744 AC_MSG_RESULT($TERMINFO)
 745 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
 746
 747 fi
 748
 749 AC_SUBST(TERMINFO)
 750 AC_SUBST(MAKE_TERMINFO)
 751
 752 ###     use option --disable-big-core to make tic run on small machines
 753 ###     We need 4Mb, check if we can allocate 50% more than that.
 754 AC_MSG_CHECKING(if big-core option selected)
 755 AC_ARG_ENABLE(big-core,
 756         [  --disable-big-core      assume machine has little memory],
 757         [with_big_core=$enableval],
 758         [AC_TRY_RUN([
 759 #include <stdlib.h>
 760 #include <string.h>
 761 int main() {
 762         unsigned long n = 6000000L;
 763         char *s = malloc(n);
 764         if (s != 0)
 765                 s[0] = s[n-1] = 0;
 766         ${cf_cv_main_return:-return}(s == 0);
 767 }],
 768         [with_big_core=yes],
 769         [with_big_core=no],
 770         [with_big_core=no])])
 771 AC_MSG_RESULT($with_big_core)
 772 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
 773
 774 ### ISO C only guarantees 512-char strings, we have tables which load faster
 775 ### when constructed using "big" strings.  More than the C compiler, the awk
 776 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 777 AC_MSG_CHECKING(if big-strings option selected)
 778 AC_ARG_ENABLE(big-strings,
 779         [  --disable-big-strings   assume compiler has only standard-size strings],
 780         [with_big_strings=$enableval],
 781         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 782 AC_MSG_RESULT($with_big_strings)
 783
 784 USE_BIG_STRINGS=0
 785 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
 786 AC_SUBST(USE_BIG_STRINGS)
 787
 788 ###     use option --enable-termcap to compile in the termcap fallback support
 789 AC_MSG_CHECKING(if you want termcap-fallback support)
 790 AC_ARG_ENABLE(termcap,
 791         [  --enable-termcap        compile in termcap fallback support],
 792         [with_termcap=$enableval],
 793         [with_termcap=no])
 794 AC_MSG_RESULT($with_termcap)
 795
 796 NCURSES_USE_TERMCAP=0
 797 if test "x$with_termcap" != "xyes" ; then
 798         if test "$use_database" = no ; then
 799                 if test -z "$with_fallback" ; then
 800                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 801                 fi
 802         fi
 803         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
 804 else
 805
 806         if test "$with_ticlib" != no ; then
 807                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 808         fi
 809
 810         NCURSES_USE_TERMCAP=1
 811         AC_MSG_CHECKING(for list of termcap files)
 812         CF_WITH_PATHLIST(termpath,
 813                 [  --with-termpath=XXX     specify list of termcap files],
 814                 TERMPATH,
 815                 /etc/termcap:/usr/share/misc/termcap)
 816         AC_MSG_RESULT($TERMPATH)
 817         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
 818
 819         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 820         AC_MSG_CHECKING(if fast termcap-loader is needed)
 821         AC_ARG_ENABLE(getcap,
 822                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 823                 [with_getcap=$enableval],
 824                 [with_getcap=no])
 825         AC_MSG_RESULT($with_getcap)
 826         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
 827
 828         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 829         AC_ARG_ENABLE(getcap-cache,
 830                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 831                 [with_getcap_cache=$enableval],
 832                 [with_getcap_cache=no])
 833         AC_MSG_RESULT($with_getcap_cache)
 834         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
 835
 836 fi
 837 AC_SUBST(NCURSES_USE_TERMCAP)
 838
 839 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 840 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 841 AC_ARG_ENABLE(home-terminfo,
 842         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 843         [with_home_terminfo=$enableval],
 844         [with_home_terminfo=yes])
 845 AC_MSG_RESULT($with_home_terminfo)
 846 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
 847
 848 AC_MSG_CHECKING(if you want to permit root to use ncurses environment variables)
 849 AC_ARG_ENABLE(root-environ,
 850         [  --disable-root-environ  restrict root use of ncurses environment variables],
 851         [with_root_environ=$enableval],
 852         [with_root_environ=yes])
 853 AC_MSG_RESULT($with_root_environ)
 854 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if root is allowed to use ncurses environment])
 855
 856 AC_MSG_CHECKING(if you want to permit setuid programs to access all files)
 857 AC_ARG_ENABLE(root-environ,
 858         [  --disable-root-access   restrict file-access when running setuid],
 859         [with_root_access=$enableval],
 860         [with_root_access=yes])
 861 AC_MSG_RESULT($with_root_access)
 862 test "x$with_root_access" = xyes && AC_DEFINE(USE_ROOT_ACCESS,1,[Define to 1 if setuid is allowed all file-access])
 863
 864 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 865 ###   to reduce storage requirements for the terminfo database.
 866 CF_LINK_FUNCS
 867
 868 with_links=no
 869 with_symlinks=no
 870
 871 # soft links (symbolic links) are useful for some systems where hard links do
 872 # not work, or to make it simpler to copy terminfo trees around.
 873 if test "x$ac_cv_func_symlink" = xyes ; then
 874         AC_MSG_CHECKING(if tic should use symbolic links)
 875         AC_ARG_ENABLE(symlinks,
 876         [  --enable-symlinks       make tic use symbolic links not hard links],
 877         [with_symlinks=$enableval],
 878         [with_symlinks=no])
 879         AC_MSG_RESULT($with_symlinks)
 880 fi
 881
 882 # If we have hard links and did not choose to use soft links instead, there is
 883 # no reason to make this choice optional - use the hard links.
 884 if test "$with_symlinks" = no ; then
 885         AC_MSG_CHECKING(if tic should use hard links)
 886         if test "x$ac_cv_func_link" = xyes ; then
 887                 with_links=yes
 888         else
 889                 with_links=no
 890         fi
 891         AC_MSG_RESULT($with_links)
 892 fi
 893
 894 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
 895 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
 896
 897 ###   use option --enable-broken-linker to force on use of broken-linker support
 898 CF_ENABLE_BROKEN_LINKER
 899
 900 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 901 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 902 AC_ARG_ENABLE(bsdpad,
 903         [  --enable-bsdpad         recognize BSD-style prefix padding],
 904         [with_bsdpad=$enableval],
 905         [with_bsdpad=no])
 906 AC_MSG_RESULT($with_bsdpad)
 907 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
 908
 909 ###   use option --enable-widec to turn on use of wide-character support
 910 NCURSES_CH_T=chtype
 911 NCURSES_LIBUTF8=0
 912
 913 NEED_WCHAR_H=0
 914 NCURSES_MBSTATE_T=0
 915 NCURSES_WCHAR_T=0
 916 NCURSES_WINT_T=0
 917
 918 # Check to define _XOPEN_SOURCE "automatically"
 919 CPPFLAGS_before_XOPEN="$CPPFLAGS"
 920 CF_XOPEN_SOURCE(600)
 921 CPPFLAGS_after_XOPEN="$CPPFLAGS"
 922
 923 # Work around breakage on OS X
 924 CF_SIGWINCH
 925
 926 # Checks for CODESET support.
 927 AM_LANGINFO_CODESET
 928
 929 # use these variables to work around a defect in gcc's fixincludes.
 930 NCURSES_OK_WCHAR_T=
 931 NCURSES_OK_WINT_T=
 932
 933 AC_MSG_CHECKING(if you want wide-character code)
 934 AC_ARG_ENABLE(widec,
 935         [  --enable-widec          compile with wide-char/UTF-8 code],
 936         [with_widec=$enableval],
 937         [with_widec=no])
 938 AC_MSG_RESULT($with_widec)
 939
 940 NCURSES_WCWIDTH_GRAPHICS=1
 941 AC_SUBST(NCURSES_WCWIDTH_GRAPHICS)
 942
 943 if test "x$with_widec" = xyes ; then
 944         if test "x$disable_lib_suffixes" = xno ; then
 945                 LIB_SUFFIX="w${LIB_SUFFIX}"
 946         fi
 947         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
 948         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
 949
 950         CF_CHECK_WCHAR_H
 951         CF_CHECK_WCWIDTH_GRAPHICS
 952         test "$cf_cv_wcwidth_graphics" = no && NCURSES_WCWIDTH_GRAPHICS=0
 953
 954         # with_overwrite=no
 955         NCURSES_CH_T=cchar_t
 956         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 957         if test "x$ac_cv_func_putwc" != xyes ; then
 958                 CF_UTF8_LIB
 959                 if test "$cf_cv_utf8_lib" != no ; then
 960                         NCURSES_LIBUTF8=1
 961                 fi
 962         fi
 963         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 964         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 965         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 966
 967         if test "$NCURSES_MBSTATE_T" != 0; then
 968                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
 969         fi
 970 fi
 971 AC_SUBST(NCURSES_CH_T)
 972 AC_SUBST(NCURSES_LIBUTF8)
 973
 974 AC_SUBST(NEED_WCHAR_H)
 975 AC_SUBST(NCURSES_MBSTATE_T)
 976 AC_SUBST(NCURSES_WCHAR_T)
 977 AC_SUBST(NCURSES_WINT_T)
 978
 979 AC_SUBST(NCURSES_OK_WCHAR_T)
 980 AC_SUBST(NCURSES_OK_WINT_T)
 981
 982 ###   use option --disable-lp64 to allow long chtype
 983 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 984 AC_ARG_ENABLE(lp64,
 985         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 986         [with_lp64=$enableval],
 987         [with_lp64=$cf_dft_with_lp64])
 988 AC_MSG_RESULT($with_lp64)
 989
 990 if test "x$with_lp64" = xyes ; then
 991         cf_cv_enable_lp64=1
 992 else
 993         cf_cv_enable_lp64=0
 994 fi
 995 AC_SUBST(cf_cv_enable_lp64)
 996
 997 CF_LARGEFILE
 998
 999 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
1000 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
1001 AC_ARG_ENABLE(tparm-varargs,
1002         [  --disable-tparm-varargs compile tparm() without varargs interface],
1003         [with_tparm_varargs=$enableval],
1004         [with_tparm_varargs=yes])
1005 AC_MSG_RESULT($with_tparm_varargs)
1006 NCURSES_TPARM_VARARGS=0
1007 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
1008 AC_SUBST(NCURSES_TPARM_VARARGS)
1009
1010 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
1011 if test "$with_ticlib" != no ; then
1012 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
1013 AC_ARG_ENABLE(tic-depends,
1014         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
1015         [with_tic_depends=$enableval],
1016         [with_tic_depends=yes])
1017 AC_MSG_RESULT($with_tic_depends)
1018 else
1019         with_tic_depends=no
1020 fi
1021
1022 ###   use option --enable-wattr-macros to enable wattr* macros in curses.h
1023 AC_MSG_CHECKING(if you want to enable wattr* macros)
1024 AC_ARG_ENABLE(wattr-macros,
1025         [  --enable-wattr-macros   enable wattr* macros],
1026         [with_wattr_macros=$enableval],
1027         [with_wattr_macros=no])
1028 if [[ "x$with_wattr_macros" != xyes ]]; then
1029         NCURSES_WATTR_MACROS=0
1030         AC_MSG_RESULT(no)
1031 else
1032         NCURSES_WATTR_MACROS=1
1033         AC_MSG_RESULT(yes)
1034 fi
1035 AC_SUBST(NCURSES_WATTR_MACROS)
1036
1037 CF_WITH_X11_RGB
1038
1039 ###   use option --with-bool to override bool's type
1040 AC_MSG_CHECKING(for type of bool)
1041 AC_ARG_WITH(bool,
1042         [  --with-bool=TYPE        override fallback type of bool variable],
1043         [NCURSES_BOOL="$withval"],
1044         [NCURSES_BOOL=auto])
1045 AC_MSG_RESULT($NCURSES_BOOL)
1046 AC_SUBST(NCURSES_BOOL)
1047
1048 AC_MSG_CHECKING(for alternate terminal capabilities file)
1049 AC_ARG_WITH(caps,
1050         [  --with-caps=alt         compile with alternate Caps file],
1051         [TERMINFO_CAPS=Caps.$withval],
1052         [TERMINFO_CAPS=Caps])
1053 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
1054 AC_MSG_RESULT($TERMINFO_CAPS)
1055 AC_SUBST(TERMINFO_CAPS)
1056
1057 ###   use option --with-chtype to override chtype's type
1058 AC_MSG_CHECKING(for type of chtype)
1059 AC_ARG_WITH(chtype,
1060         [  --with-chtype=TYPE      override type of chtype],
1061         [NCURSES_CHTYPE="$withval"],
1062         [NCURSES_CHTYPE=$cf_dft_chtype])
1063 AC_MSG_RESULT($NCURSES_CHTYPE)
1064
1065 ###   use option --with-ospeed to override ospeed's type
1066 AC_MSG_CHECKING(for type of ospeed)
1067 AC_ARG_WITH(ospeed,
1068         [  --with-ospeed=TYPE      override type of ospeed variable],
1069         [NCURSES_OSPEED="$withval"],
1070         [NCURSES_OSPEED=short])
1071 AC_MSG_RESULT($NCURSES_OSPEED)
1072 AC_SUBST(NCURSES_OSPEED)
1073
1074 ###   use option --with-mmask-t to override mmask_t's type
1075 AC_MSG_CHECKING(for type of mmask_t)
1076 AC_ARG_WITH(mmask-t,
1077         [  --with-mmask-t=TYPE     override type of mmask_t],
1078         [NCURSES_MMASK_T="$withval"],
1079         [NCURSES_MMASK_T=$cf_dft_mmask_t])
1080 AC_MSG_RESULT($NCURSES_MMASK_T)
1081
1082 ###   use option --with-ccharw-max to override CCHARW_MAX size
1083 AC_MSG_CHECKING(for size CCHARW_MAX)
1084 AC_ARG_WITH(ccharw-max,
1085         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
1086         [NCURSES_CCHARW_MAX="$withval"],
1087         [NCURSES_CCHARW_MAX=5])
1088 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
1089 AC_SUBST(NCURSES_CCHARW_MAX)
1090
1091 AC_CHECK_SIZEOF([signed char])
1092 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1093         NCURSES_SBOOL="signed char"
1094 else
1095         NCURSES_SBOOL="char"
1096 fi
1097 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1098 AC_ARG_ENABLE(signed-char,
1099         [  --enable-signed-char    compile using signed Boolean's in term.h],
1100         [with_signed_char=$enableval],
1101         [with_signed_char=no])
1102 AC_MSG_RESULT($with_signed_char)
1103 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1104 AC_SUBST(NCURSES_SBOOL)
1105
1106 ###   use option --with-tparm-arg to override tparm's argument type
1107 AC_MSG_CHECKING(for type of tparm args)
1108 AC_ARG_WITH(tparm-arg,
1109         [  --with-tparm-arg=TYPE   override parameter type of tparm],
1110         [NCURSES_TPARM_ARG="$withval"],
1111         [NCURSES_TPARM_ARG=$cf_dft_tparm_arg])
1112 AC_MSG_RESULT($NCURSES_TPARM_ARG)
1113 AC_SUBST(NCURSES_TPARM_ARG)
1114
1115 ### Enable compiling-in rcs id's
1116 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
1117 AC_ARG_WITH(rcs-ids,
1118         [  --with-rcs-ids          compile-in RCS identifiers],
1119         [with_rcs_ids=$withval],
1120         [with_rcs_ids=no])
1121 AC_MSG_RESULT($with_rcs_ids)
1122 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
1123
1124 ###############################################################################
1125 CF_MAN_PAGES([ captoinfo clear infocmp infotocap reset tabs tic toe tput tset ])
1126
1127 ###############################################################################
1128 CF_HELP_MESSAGE(Extensions:)
1129
1130 ### Note that some functions (such as const) are normally disabled anyway.
1131 AC_MSG_CHECKING(if you want to build with function extensions)
1132 AC_ARG_ENABLE(ext-funcs,
1133         [  --disable-ext-funcs     disable function-extensions],
1134         [with_ext_funcs=$enableval],
1135         [with_ext_funcs=yes])
1136 AC_MSG_RESULT($with_ext_funcs)
1137 if test "x$with_ext_funcs" = xyes ; then
1138         NCURSES_EXT_FUNCS=1
1139         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
1140         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function in test-programs])
1141         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function in test-programs])
1142         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function in test-programs])
1143         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function in test-programs])
1144         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function in test-programs])
1145         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function in test-programs])
1146         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function in test-programs])
1147         AC_DEFINE(HAVE_USE_EXTENDED_NAMES,1,[Define to 1 to enable use_extended_names() function in test-programs])
1148         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function in test-programs])
1149         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function in test-programs])
1150         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function in test-programs])
1151         GENERATED_EXT_FUNCS=generated
1152         test "x$with_ext_funcs" = xyes || cf_dft_ext_spfuncs=no
1153 else
1154         NCURSES_EXT_FUNCS=0
1155         GENERATED_EXT_FUNCS=
1156 fi
1157 AC_SUBST(NCURSES_EXT_FUNCS)
1158 AC_SUBST(GENERATED_EXT_FUNCS)
1159
1160 AC_MSG_CHECKING(if you want to build with SCREEN extensions)
1161 AC_ARG_ENABLE(sp-funcs,
1162         [  --enable-sp-funcs       enable SCREEN-extensions],
1163         [with_sp_funcs=$enableval],
1164         [with_sp_funcs=$cf_dft_ext_spfuncs])
1165 AC_MSG_RESULT($with_sp_funcs)
1166 if test "x$with_sp_funcs" = xyes ; then
1167         NCURSES_SP_FUNCS=1
1168         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable SCREEN-extensions])
1169         AC_DEFINE(HAVE_TPUTS_SP,1,[Define to 1 to enable tputs_sp() function in test-programs])
1170         GENERATED_SP_FUNCS=generated
1171 else
1172         NCURSES_SP_FUNCS=0
1173         GENERATED_SP_FUNCS=
1174 fi
1175 AC_SUBST(NCURSES_SP_FUNCS)
1176 AC_SUBST(GENERATED_SP_FUNCS)
1177
1178 AC_MSG_CHECKING(if you want to build with terminal-driver)
1179 AC_ARG_ENABLE(term-driver,
1180         [  --enable-term-driver    enable terminal-driver],
1181         [with_term_driver=$enableval],
1182         [with_term_driver=no])
1183 AC_MSG_RESULT($with_term_driver)
1184 if test "x$with_term_driver" = xyes ; then
1185         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable terminal-driver])
1186         if test "x$with_termlib" != xno ; then
1187                 AC_MSG_ERROR(The term-driver option conflicts with the termlib option)
1188         fi
1189         if test "x$with_sp_funcs" != xyes ; then
1190                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
1191         fi
1192 fi
1193
1194 ###   use option --enable-const to turn on use of const beyond that in XSI.
1195 AC_MSG_CHECKING(for extended use of const keyword)
1196 AC_ARG_ENABLE(const,
1197         [  --enable-const          compile with extra/non-standard const],
1198         [with_ext_const=$enableval],
1199         [with_ext_const=$cf_dft_ext_const])
1200 AC_MSG_RESULT($with_ext_const)
1201 NCURSES_CONST='/*nothing*/'
1202 if test "x$with_ext_const" = xyes ; then
1203         NCURSES_CONST=const
1204 fi
1205 AC_SUBST(NCURSES_CONST)
1206
1207 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
1208 AC_MSG_CHECKING(if you want to use extended colors)
1209 AC_ARG_ENABLE(ext-colors,
1210         [  --enable-ext-colors     compile for 256-color support],
1211         [with_ext_colors=$enableval],
1212         [with_ext_colors=$cf_dft_ext_colors])
1213 AC_MSG_RESULT($with_ext_colors)
1214 NCURSES_EXT_COLORS=0
1215 if test "x$with_ext_colors" = xyes ; then
1216         if test "x$with_widec" != xyes ; then
1217                 AC_MSG_WARN(This option applies only to wide-character library)
1218         else
1219                 # cannot be ABI 5 since it changes sizeof(cchar_t)
1220                 CF_NCURSES_ABI_6
1221                 NCURSES_EXT_COLORS=1
1222                 AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1223                 AC_DEFINE(HAVE_ALLOC_PAIR,1,[Define to 1 to enable alloc_pair() function])
1224                 AC_DEFINE(HAVE_INIT_EXTENDED_COLOR,1,[Define to 1 to enable init_extended_color() function in test-programs])
1225                 AC_DEFINE(HAVE_RESET_COLOR_PAIRS,1,[Define to 1 to enable reset_color_pairs() function in test-programs])
1226         fi
1227 fi
1228 AC_SUBST(NCURSES_EXT_COLORS)
1229
1230 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1231 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1232 AC_ARG_ENABLE(ext-mouse,
1233         [  --enable-ext-mouse      compile for extended mouse-encoding],
1234         [with_ext_mouse=$enableval],
1235         [with_ext_mouse=$cf_dft_ext_mouse])
1236 AC_MSG_RESULT($with_ext_mouse)
1237 NCURSES_MOUSE_VERSION=1
1238 if test "x$with_ext_mouse" = xyes ; then
1239         NCURSES_MOUSE_VERSION=2
1240         CF_NCURSES_ABI_6
1241 fi
1242 AC_SUBST(NCURSES_MOUSE_VERSION)
1243
1244 ###   use option --enable-ext-putwin to turn on extended screendumps
1245 AC_MSG_CHECKING(if you want to use extended putwin/screendump)
1246 AC_ARG_ENABLE(ext-putwin,
1247         [  --enable-ext-putwin     compile with extended putwin/screendump],
1248         [with_ext_putwin=$enableval],
1249         [with_ext_putwin=$cf_dft_ext_putwin])
1250 AC_MSG_RESULT($with_ext_putwin)
1251 if test "x$with_ext_putwin" = xyes ; then
1252         AC_DEFINE(NCURSES_EXT_PUTWIN,1,[Define to 1 to compile with extended putwin/screendump])
1253 fi
1254
1255 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1256 AC_ARG_ENABLE(no-padding,
1257         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1258         [with_no_padding=$enableval],
1259         [with_no_padding=$with_ext_funcs])
1260 AC_MSG_RESULT($with_no_padding)
1261 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1262
1263 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1264 AC_MSG_CHECKING(if you want SIGWINCH handler)
1265 AC_ARG_ENABLE(sigwinch,
1266         [  --enable-sigwinch       compile with SIGWINCH handler],
1267         [with_sigwinch=$enableval],
1268         [with_sigwinch=$with_ext_funcs])
1269 AC_MSG_RESULT($with_sigwinch)
1270 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1271
1272 ###   use option --enable-tcap-names to allow user to define new capabilities
1273 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1274 AC_ARG_ENABLE(tcap-names,
1275         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1276         [with_tcap_names=$enableval],
1277         [with_tcap_names=$with_ext_funcs])
1278 AC_MSG_RESULT($with_tcap_names)
1279 NCURSES_XNAMES=0
1280 test "x$with_tcap_names" = xyes && NCURSES_XNAMES=1
1281 AC_SUBST(NCURSES_XNAMES)
1282
1283 ##############################################################################
1284 CF_HELP_MESSAGE(Reentrant Code:)
1285 CF_WITH_PTHREAD
1286
1287 if test "x$with_pthread" != xno; then
1288         AC_CHECK_FUNC(pthread_kill,[
1289                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1290                 AC_ARG_ENABLE(pthreads-eintr,
1291                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1292                         [use_pthreads_eintr=$enableval],
1293                         [use_pthreads_eintr=no])
1294                 AC_MSG_RESULT($use_pthreads_eintr)
1295                 if test "x$use_pthreads_eintr" = xyes ; then
1296                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1297                 fi])
1298
1299         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1300         AC_ARG_ENABLE(weak-symbols,
1301                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1302                 [use_weak_symbols=$enableval],
1303                 [use_weak_symbols=no])
1304         AC_MSG_RESULT($use_weak_symbols)
1305         if test "x$use_weak_symbols" = xyes ; then
1306                 CF_WEAK_SYMBOLS
1307         else
1308                 cf_cv_weak_symbols=no
1309         fi
1310
1311         if test "x$cf_cv_weak_symbols" = xyes ; then
1312                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1313         fi
1314 fi
1315
1316 PTHREAD=
1317 if test "x$with_pthread" = "xyes" ; then
1318         AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1319         enable_reentrant=yes
1320         if test "x$cf_cv_weak_symbols" = xyes ; then
1321                 PTHREAD=-lpthread
1322                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1323         fi
1324 fi
1325 AC_SUBST(PTHREAD)
1326
1327 # Reentrant code has to be opaque; there's little advantage to making ncurses
1328 # opaque outside of that, so there is no --enable-opaque option.  We can use
1329 # this option without --with-pthreads, but this will be always set for
1330 # pthreads.
1331 AC_MSG_CHECKING(if you want reentrant code)
1332 AC_ARG_ENABLE(reentrant,
1333         [  --enable-reentrant      compile with reentrant code],
1334         [with_reentrant=$enableval],
1335         [with_reentrant=no])
1336 AC_MSG_RESULT($with_reentrant)
1337 if test "x$with_reentrant" = xyes ; then
1338         cf_cv_enable_reentrant=1
1339         cf_cv_enable_opaque="NCURSES_INTERNALS"
1340         NCURSES_SIZE_T=int
1341         if test "x$cf_cv_weak_symbols" = xyes ; then
1342                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1343                 CF_ADD_LIB(pthread,TEST_LIBS)
1344                 CF_ADD_LIB(pthread,TEST_LIBS2)
1345                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1346         else
1347                 # when not using weak symbols but with_reentrant,
1348                 # add 't' to the library suffix on all platforms
1349                 # except cygwin, where we only do that if ALSO
1350                 # compiling with full thread support.
1351                 case "$host" in
1352                 (*cygwin* | *msys*)
1353                         if test "$with_pthread" = "yes" ; then
1354                                 if test "x$disable_lib_suffixes" = "xno" ; then
1355                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1356                                 fi
1357                         fi ;;
1358                 (*)
1359                         if test "x$disable_lib_suffixes" = "xno" ; then
1360                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1361                         fi
1362                         ;;
1363                 esac
1364         fi
1365         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use reentrant feature])
1366         CF_NCURSES_ABI_6
1367 else
1368         cf_cv_enable_reentrant=0
1369         cf_cv_enable_opaque="NCURSES_OPAQUE"
1370         NCURSES_SIZE_T=short
1371 fi
1372 AC_SUBST(cf_cv_enable_reentrant)
1373 AC_SUBST(cf_cv_enable_opaque)
1374
1375 AC_SUBST(NCURSES_SIZE_T)
1376
1377 AC_MSG_CHECKING(if you want opaque curses-library structures)
1378 CF_ARG_ENABLE(opaque-curses,
1379         [  --enable-opaque-curses  make curses WINDOW, etc., "opaque"],
1380         [enable_opaque_curses=yes],[
1381          test "$cf_cv_enable_reentrant" = 1 && enable_opaque_curses=yes
1382          test "$cf_cv_enable_reentrant" = 1 || enable_opaque_curses=no
1383         ])
1384 AC_MSG_RESULT($enable_opaque_curses)
1385
1386 test "$cf_cv_enable_reentrant" = 1 && \
1387 test "$enable_opaque_curses" = no && \
1388 AC_MSG_ERROR(reentrant configuration requires opaque library)
1389
1390 AC_MSG_CHECKING(if you want opaque form-library structures)
1391 AC_ARG_ENABLE(opaque-form,
1392         [  --enable-opaque-form    make form-library structures "opaque"],
1393         [enable_opaque_form=yes],[enable_opaque_form=no])
1394 AC_MSG_RESULT($enable_opaque_form)
1395
1396 AC_MSG_CHECKING(if you want opaque menu-library structures)
1397 AC_ARG_ENABLE(opaque-menu,
1398         [  --enable-opaque-menu    make menu-library structures "opaque"],
1399         [enable_opaque_menu=yes],[enable_opaque_menu=no])
1400 AC_MSG_RESULT($enable_opaque_menu)
1401
1402 AC_MSG_CHECKING(if you want opaque panel-library structures)
1403 AC_ARG_ENABLE(opaque-panel,
1404         [  --enable-opaque-panel   make panel-library structures "opaque"],
1405         [enable_opaque_panel=yes],[enable_opaque_panel=no])
1406 AC_MSG_RESULT($enable_opaque_panel)
1407
1408 NCURSES_OPAQUE=0;               test "$enable_opaque_curses" = yes && NCURSES_OPAQUE=1
1409 NCURSES_OPAQUE_FORM=0;  test "$enable_opaque_form"   = yes && NCURSES_OPAQUE_FORM=1
1410 NCURSES_OPAQUE_MENU=0;  test "$enable_opaque_menu"   = yes && NCURSES_OPAQUE_MENU=1
1411 NCURSES_OPAQUE_PANEL=0; test "$enable_opaque_panel"  = yes && NCURSES_OPAQUE_PANEL=1
1412
1413 AC_SUBST(NCURSES_OPAQUE)
1414 AC_SUBST(NCURSES_OPAQUE_FORM)
1415 AC_SUBST(NCURSES_OPAQUE_MENU)
1416 AC_SUBST(NCURSES_OPAQUE_PANEL)
1417
1418 ### Allow using a different wrap-prefix
1419 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1420         AC_MSG_CHECKING(for prefix used to wrap public variables)
1421         AC_ARG_WITH(wrap-prefix,
1422                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1423                 [NCURSES_WRAP_PREFIX=$withval],
1424                 [NCURSES_WRAP_PREFIX=_nc_])
1425         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1426 else
1427         NCURSES_WRAP_PREFIX=_nc_
1428 fi
1429 AC_SUBST(NCURSES_WRAP_PREFIX)
1430 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1431
1432 ###############################################################################
1433 # These options are relatively safe to experiment with.
1434 CF_HELP_MESSAGE(Development Code:)
1435 AC_MSG_CHECKING(if you want all development code)
1436 AC_ARG_WITH(develop,
1437         [  --without-develop       disable development options],
1438         [with_develop=$withval],
1439         [with_develop=no])
1440 AC_MSG_RESULT($with_develop)
1441
1442 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1443 AC_MSG_CHECKING(if you want hard-tabs code)
1444 AC_ARG_ENABLE(hard-tabs,
1445         [  --enable-hard-tabs      compile with hard-tabs code],,
1446         [enable_hard_tabs=$with_develop])
1447 AC_MSG_RESULT($enable_hard_tabs)
1448 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1449
1450 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1451 AC_MSG_CHECKING(if you want limited support for xmc)
1452 AC_ARG_ENABLE(xmc-glitch,
1453         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1454         [enable_xmc_glitch=$with_develop])
1455 AC_MSG_RESULT($enable_xmc_glitch)
1456 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1457
1458 ###############################################################################
1459 # These are just experimental, probably should not be in a package:
1460 CF_HELP_MESSAGE(Experimental Code:)
1461
1462 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1463 AC_ARG_ENABLE(assumed-color,
1464         [  --disable-assumed-color do not assume anything about default-colors],
1465         [with_assumed_color=$enableval],
1466         [with_assumed_color=yes])
1467 AC_MSG_RESULT($with_assumed_color)
1468 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1469
1470 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1471 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1472 AC_ARG_ENABLE(hashmap,
1473         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1474         [with_hashmap=$enableval],
1475         [with_hashmap=yes])
1476 AC_MSG_RESULT($with_hashmap)
1477 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1478
1479 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1480 AC_MSG_CHECKING(if you want colorfgbg code)
1481 AC_ARG_ENABLE(colorfgbg,
1482         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1483         [with_colorfgbg=$enableval],
1484         [with_colorfgbg=no])
1485 AC_MSG_RESULT($with_colorfgbg)
1486 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1487
1488 ###   use option --enable-fvisibility to turn on use of gcc-specific feature
1489 AC_MSG_CHECKING(if you want to use gcc -fvisibility option)
1490 AC_ARG_ENABLE(fvisibility,
1491         [  --enable-fvisibility    compile with -fvisibility=hidden],
1492         [cf_with_fvisibility=$enableval],
1493         [cf_with_fvisibility=no])
1494 AC_MSG_RESULT($cf_with_fvisibility)
1495
1496 NCURSES_IMPEXP=
1497 NCURSES_CXX_IMPEXP=
1498 if test "x$cf_with_fvisibility" = xyes; then
1499         CF_CHECK_FVISIBILITY($CC,CFLAGS,cf_cv_fvisibility_hidden)
1500         if test "x$cf_cv_fvisibility_hidden" = xyes
1501         then
1502                 CF_ADD_CFLAGS([-fvisibility=hidden])
1503                 NCURSES_IMPEXP="__attribute__ ((visibility(\"default\")))"
1504         fi
1505         if test -n "$CXX"
1506         then
1507                 AC_LANG_PUSH(C++)
1508                 CF_CHECK_FVISIBILITY($CXX,CXXFLAGS,cf_cv_fvisibility_hidden2)
1509                 if test "x$cf_cv_fvisibility_hidden2" = xyes
1510                 then
1511                         CF_ADD_CXXFLAGS([-fvisibility=hidden])
1512                         NCURSES_CXX_IMPEXP="__attribute__ ((visibility(\"default\")))"
1513                 fi
1514                 AC_LANG_POP
1515         fi
1516 fi
1517 AC_SUBST(NCURSES_IMPEXP)
1518 AC_SUBST(NCURSES_CXX_IMPEXP)
1519
1520 ###   use option --enable-interop to turn on use of bindings used for interop
1521 AC_MSG_CHECKING(if you want interop bindings)
1522 AC_ARG_ENABLE(interop,
1523         [  --enable-interop        compile-in interop bindings],
1524         [with_exp_interop=$enableval],
1525         [with_exp_interop=$cf_dft_interop])
1526 AC_MSG_RESULT($with_exp_interop)
1527
1528 NCURSES_INTEROP_FUNCS=0
1529 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1530 AC_SUBST(NCURSES_INTEROP_FUNCS)
1531
1532
1533 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1534 AC_ARG_ENABLE(safe-sprintf,
1535         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1536         [with_safe_sprintf=$enableval],
1537         [with_safe_sprintf=no])
1538 AC_MSG_RESULT($with_safe_sprintf)
1539
1540 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1541 # when hashmap is used scroll hints are useless
1542 if test "$with_hashmap" = no ; then
1543 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1544 AC_ARG_ENABLE(scroll-hints,
1545         [  --disable-scroll-hints  compile without scroll-hints code],
1546         [with_scroll_hints=$enableval],
1547         [with_scroll_hints=yes])
1548 AC_MSG_RESULT($with_scroll_hints)
1549 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1550 fi
1551
1552 AC_MSG_CHECKING(if you want wgetch-events code)
1553 AC_ARG_ENABLE(wgetch-events,
1554         [  --enable-wgetch-events  compile with wgetch-events code],
1555         [with_wgetch_events=$enableval],
1556         [with_wgetch_events=no])
1557 AC_MSG_RESULT($with_wgetch_events)
1558 if test "x$with_wgetch_events" = xyes ; then
1559         AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with wgetch-events code])
1560         NCURSES_WGETCH_EVENTS=1
1561 else
1562         NCURSES_WGETCH_EVENTS=0
1563 fi
1564 AC_SUBST(NCURSES_WGETCH_EVENTS)
1565
1566 case "$cf_cv_system_name" in
1567 (*mingw32*|*mingw64*|*-msvc*)
1568         AC_MSG_CHECKING(if you want experimental-Windows driver)
1569         AC_ARG_ENABLE(exp-win32,
1570                 [  --enable-exp-win32      compile with experimental-Windows driver],
1571                 [with_exp_win32=$enableval],
1572                 [with_exp_win32=no])
1573         AC_MSG_RESULT($with_exp_win32)
1574         if test "x$with_exp_win32" = xyes
1575         then
1576                 AC_DEFINE(EXP_WIN32_DRIVER,1,[Define to 1 to compile with experimental win32 driver])
1577                 EXP_WIN32_DRIVER=1
1578                 INTERNALS_HDR='[$](INCDIR)/nc_win32.h'
1579         else
1580                 INTERNALS_HDR='[$](INCDIR)/nc_mingw.h'
1581                 EXP_WIN32_DRIVER=0
1582         fi
1583         ;;
1584 (*)
1585         EXP_WIN32_DRIVER=0
1586         INTERNALS_HDR=
1587         ;;
1588 esac
1589 AC_SUBST(EXP_WIN32_DRIVER)
1590 AC_SUBST(INTERNALS_HDR)
1591
1592 ###############################################################################
1593 CF_HELP_MESSAGE(Testing/development Options:)
1594
1595 ###     use option --disable-echo to suppress full display compiling commands
1596 CF_DISABLE_ECHO
1597 if test "x$enable_echo" = xyes; then
1598         ECHO_LINK=
1599 else
1600         ECHO_LINK='@ echo linking $@ ... ;'
1601         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1602         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1603 fi
1604 AC_SUBST(ECHO_LINK)
1605
1606 # --disable-stripping is used for debugging
1607 CF_INSTALL_OPTS
1608
1609 # If we're avoiding relinking of shared libraries during install, that is to
1610 # avoid modifying the build-tree.  For the same reason, avoid doing ranlib if
1611 # the install program has "-p" (for preserving timestamps).
1612 cf_cv_do_reranlib=yes
1613 if test "x$cf_cv_install_p" = xyes
1614 then
1615         if test "x$cf_cv_do_relink" != xyes
1616         then
1617                 cf_cv_do_reranlib=no
1618                 INSTALL_OPT_P="-p"
1619                 INSTALL_LIB="$INSTALL_LIB $INSTALL_OPT_P"
1620         fi
1621 fi
1622 AC_SUBST(INSTALL_OPT_P)
1623
1624 ###     use option --enable-warnings to turn on all gcc warnings
1625 CF_ENABLE_WARNINGS(Wno-unknown-pragmas Wswitch-enum,yes)
1626
1627 if test "x$enable_warnings" = "xyes"; then
1628         CF_ADD_ADAFLAGS(-gnatg)
1629         if test "x$cf_with_cxx" = xyes ; then
1630                 CF_GXX_WARNINGS(Wno-unused)
1631         fi
1632 fi
1633 CF_ENABLE_STRING_HACKS
1634
1635 ###     use option --enable-assertions to turn on generation of assertion code
1636 AC_MSG_CHECKING(if you want to enable runtime assertions)
1637 AC_ARG_ENABLE(assertions,
1638         [  --enable-assertions     test: turn on generation of assertion code],
1639         [with_assertions=$enableval],
1640         [with_assertions=no])
1641 AC_MSG_RESULT($with_assertions)
1642 if test -n "$GCC"
1643 then
1644         if test "$with_assertions" = no
1645         then
1646                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1647         else
1648                 CF_ADD_ADAFLAGS(-gnata)
1649         fi
1650 fi
1651
1652 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1653 CF_DISABLE_LEAKS
1654 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1655
1656 ###     use option --enable-expanded to generate certain macros as functions
1657 AC_ARG_ENABLE(expanded,
1658         [  --enable-expanded       test: generate functions for certain macros],
1659         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1660
1661 ###     use option --disable-macros to suppress macros in favor of functions
1662 AC_ARG_ENABLE(macros,
1663         [  --disable-macros        test: use functions rather than macros],
1664         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1665
1666 # Normally we only add trace() to the debug-library.  Allow this to be
1667 # extended to all models of the ncurses library:
1668 cf_all_traces=no
1669 case "$CFLAGS $CPPFLAGS" in
1670 (*-DTRACE*)
1671         cf_all_traces=yes
1672         ;;
1673 esac
1674
1675 AC_MSG_CHECKING(whether to add trace feature to all models)
1676 AC_ARG_WITH(trace,
1677 [  --with-trace            test: add trace() function to all models of ncurses],
1678 [cf_with_trace=$withval],
1679 [cf_with_trace=$cf_all_traces])
1680 AC_MSG_RESULT($cf_with_trace)
1681
1682 if test "x$cf_with_trace" = xyes ; then
1683         LIB_TRACING=all
1684         ADA_TRACE=TRUE
1685         CF_ADD_CFLAGS(-DTRACE)
1686         AC_DEFINE(HAVE__TRACEF,1,[Define to 1 if we have _tracef function])
1687 else
1688         LIB_TRACING=DEBUG
1689         ADA_TRACE=FALSE
1690 fi
1691
1692 AC_SUBST(ADA_TRACE)
1693
1694 CF_DISABLE_GNAT_PROJECTS
1695
1696 ###     Checks for libraries.
1697 case "$cf_cv_system_name" in
1698 (*mingw32*|*mingw64*)
1699         # Note: WINVER may be a problem with Windows 10
1700         if test "x$with_exp_win32" = xyes ; then
1701                 CPPFLAGS="$CPPFLAGS -DWINVER=0x0600 -DWIN32_LEAN_AND_MEAN"
1702         else
1703                 CPPFLAGS="$CPPFLAGS -DWINVER=0x0501 -DWIN32_LEAN_AND_MEAN"
1704         fi
1705         CF_CHECK_LIBSSP
1706         ;;
1707 (*)
1708 AC_CHECK_FUNC(gettimeofday,
1709         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1710
1711 AC_CHECK_LIB(bsd, gettimeofday,
1712         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1713         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1714         ;;
1715 esac
1716
1717 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1718 AC_SUBST(MATH_LIB)
1719
1720 ###     Checks for header files.
1721 AC_STDC_HEADERS
1722 AC_HEADER_DIRENT
1723 AC_HEADER_TIME
1724 CF_REGEX
1725
1726 dnl These are some other potentially nonportable headers.
1727 AC_CHECK_HEADERS( \
1728 fcntl.h \
1729 getopt.h \
1730 limits.h \
1731 locale.h \
1732 math.h \
1733 poll.h \
1734 sys/ioctl.h \
1735 sys/param.h \
1736 sys/poll.h \
1737 sys/select.h \
1738 sys/time.h \
1739 sys/times.h \
1740 unistd.h \
1741 wctype.h \
1742 )
1743
1744 CF_GETOPT_HEADER
1745
1746 CF_CHECK_ENVIRON(environ)
1747 CF_CHECK_GETENV
1748 if test "x$cf_cv_consistent_getenv" = xno && \
1749         test "x$cf_with_trace" = xyes
1750 then
1751         AC_MSG_WARN(The NCURSES_TRACE environment variable is not supported with this configuration)
1752 fi
1753
1754 CF_SYS_TIME_SELECT
1755
1756 ###     checks for compiler characteristics
1757 AC_LANG_C
1758 AC_C_CONST
1759 CF_C_INLINE(NCURSES_INLINE,1200)
1760 CF_SIG_ATOMIC_T
1761
1762 if test "$NCURSES_CHTYPE" = auto ; then
1763         CF_TYPEOF_CHTYPE
1764 else
1765         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1766 fi
1767 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1768 AC_SUBST(cf_cv_typeof_chtype)
1769
1770 CF_UNSIGNED_LITERALS
1771 cf_cv_1UL="1"
1772 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1773 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1774 AC_SUBST(cf_cv_1UL)
1775
1776 if test "$NCURSES_MMASK_T" = auto ; then
1777         cf_cv_typeof_mmask_t=long
1778 else
1779         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1780 fi
1781 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1782 AC_SUBST(cf_cv_typeof_mmask_t)
1783
1784 ###     Checks for external-data
1785 CF_ERRNO
1786 CF_LINK_DATAONLY
1787
1788 ###     Checks for library functions.
1789 AC_CHECK_FUNCS( \
1790 getcwd \
1791 getegid \
1792 geteuid \
1793 getopt \
1794 issetugid \
1795 localeconv \
1796 poll \
1797 putenv \
1798 remove \
1799 select \
1800 setbuf \
1801 setbuffer \
1802 setenv \
1803 setfsuid \
1804 setvbuf \
1805 sigaction \
1806 sigvec \
1807 snprintf \
1808 strdup \
1809 strstr \
1810 sysconf \
1811 tcgetpgrp \
1812 times \
1813 tsearch \
1814 vsnprintf \
1815 )
1816
1817 CF_FUNC_GETTTYNAM
1818
1819 if test "x$ac_cv_func_getopt" = xno && \
1820    test "x$cf_with_progs$cf_with_tests" != xnono; then
1821         AC_MSG_ERROR(getopt is required for building programs)
1822 fi
1823
1824 if test "x$with_safe_sprintf" = xyes
1825 then
1826         if test "x$ac_cv_func_vsnprintf" = xyes
1827         then
1828                 AC_MSG_WARN(will use vsnprintf instead of safe-sprintf option)
1829         else
1830                 AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1831         fi
1832 fi
1833
1834 if test "x$with_getcap" = "xyes" ; then
1835         CF_CGETENT
1836 fi
1837
1838 CF_ISASCII
1839 CF_STRUCT_SIGACTION
1840 CF_FUNC_NANOSLEEP
1841 CF_FUNC_TERMIOS
1842 CF_FUNC_VSSCANF
1843 CF_MKSTEMP
1844
1845 # setup for prototype of fallback for vsscanf()
1846 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1847
1848 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1849 if test "x$cross_compiling" = xyes ; then
1850         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1851 else
1852         AC_FUNC_SETVBUF_REVERSED
1853 fi
1854 AC_CHECK_TYPE(intptr_t, long)
1855 AC_CHECK_TYPE(ssize_t, int)
1856 CF_TYPE_SIGACTION
1857 CF_SIZECHANGE
1858 CF_FUNC_MEMMOVE
1859 CF_FUNC_POLL
1860 CF_VA_COPY
1861 AC_FUNC_VFORK
1862 CF_FOPEN_BIN_R
1863
1864 # special check for test/ditto.c
1865 CF_FUNC_OPENPTY
1866 if test "$cf_cv_func_openpty" != no ; then
1867         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1868         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1869         if test "x$cf_cv_lib_util" = xyes ; then
1870                 CF_ADD_LIB(util,TEST_LIBS)
1871         fi
1872 fi
1873 AC_SUBST(TEST_LIBS)
1874 AC_SUBST(TEST_LIBS2)
1875
1876 if test "$with_hashed_db" != no ; then
1877         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1878         CF_HASHED_DB($with_hashed_db)
1879 fi
1880
1881 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1882 if test -z "$cf_user_CFLAGS" && test "$enable_leaks" = yes ; then
1883         CF_STRIP_G_OPT(CFLAGS)
1884         CF_STRIP_G_OPT(CXXFLAGS)
1885 fi
1886
1887 # Just in case, check if the C compiler has a bool type.
1888 CF_BOOL_DECL(cf_cv_cc_bool_type)
1889
1890 # Check for C++ compiler characteristics (and ensure that it's there!)
1891 if test -n "$CXX" ; then
1892         AC_LANG_CPLUSPLUS
1893         CF_STDCPP_LIBRARY
1894         CF_PROG_CC_C_O(CXX,[$CXXFLAGS $CPPFLAGS])
1895
1896         case "$GXX_VERSION" in
1897         (1.*|2.[[0-6]]*|[[1-9]][[0-9]].*)
1898                 cf_cxx_library=yes
1899                 ;;
1900         (*-2.7*|2.7*)
1901                 CF_GPP_LIBRARY
1902                 ;;
1903         (*)
1904                 cf_cxx_library=no
1905                 ;;
1906         esac
1907
1908         AC_CHECK_HEADERS(typeinfo)
1909         CF_CXX_IOSTREAM_NAMESPACE
1910         CF_BOOL_DECL
1911         CF_BOOL_SIZE
1912         CF_ETIP_DEFINES
1913         CF_CPP_PARAM_INIT
1914         CF_CPP_STATIC_CAST
1915         CF_CXX_AR_FLAGS
1916 else
1917         cf_cxx_library=no
1918         cf_cv_builtin_bool=1
1919
1920         # Just because we are not configuring against C++ right now does not
1921         # mean that a user will not want to use C++.  Some distributors disable
1922         # the C++ portion of this configuration as a shortcut (or just to avoid
1923         # compiling the demo in the c++ directory).  So we need a reasonable
1924         # default for the 'bool' type.
1925         #
1926         # Caveat: since the storage of the bool type is not standardized, it
1927         # may change.
1928
1929         if test "$NCURSES_BOOL" != auto ; then
1930                 cf_cv_type_of_bool=$NCURSES_BOOL
1931                 cf_cv_header_stdbool_h=0
1932         else
1933                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1934                         CF_BOOL_SIZE
1935                 else
1936                         AC_MSG_CHECKING(for fallback type of bool)
1937                         case "$host_cpu" in
1938                         (i?86)  cf_cv_type_of_bool=char ;;
1939                         (*)     cf_cv_type_of_bool=int  ;;
1940                         esac
1941                         AC_MSG_RESULT($cf_cv_type_of_bool)
1942                 fi
1943         fi
1944 fi
1945 AC_SUBST(CXXLIBS)
1946
1947 # If the C compiler did not declare bool, and we did not determine that the C++
1948 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1949 # ncurses library use the same type as C++ bool.  Note that this allows one to
1950 # specify the type of bool in a configure-script option and postpone
1951 # integration with the C++ compiler provided that the types are compatible.
1952 USE_CXX_BOOL=1
1953 if test "$cf_cv_cc_bool_type" = 1
1954 then
1955         # oops: C has a bool.  Unlikely, but C++ could differ.
1956         USE_CXX_BOOL=0
1957 elif test "$cf_cv_builtin_bool" = 0
1958 then
1959         # C++ has no bool
1960         USE_CXX_BOOL=0
1961 else
1962         # this is the normal case
1963         USE_CXX_BOOL='defined(__cplusplus)'
1964 fi
1965 AC_SUBST(USE_CXX_BOOL)
1966
1967 CF_HELP_MESSAGE(Ada Binding Options:)
1968
1969 dnl If the Ada95 source-tree is present, add that to the build unless it will
1970 dnl not work, or was not requested.
1971 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1972
1973 dnl libtool does not know anything about GNAT, though a change made in 1998
1974 dnl provided for it "someday".  Disable the ada subtree if we are using
1975 dnl libtool -TD 20070714
1976         if test "$cf_with_ada" != "no" ; then
1977                 if test "$with_libtool" != "no"; then
1978                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1979                         cf_with_ada=no
1980                 fi
1981         fi
1982
1983 dnl Check for availability of GNU Ada Translator (GNAT).
1984 dnl At the moment we support no other Ada compiler.
1985         if test "$cf_with_ada" != "no" ; then
1986                 CF_PROG_GNAT
1987                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
1988                         CF_ADD_ADAFLAGS(-gnatpn)
1989                         CF_FIXUP_ADAFLAGS
1990
1991                         CF_GNATPREP_OPT_T
1992
1993                         CF_GNAT_GENERICS
1994                         CF_GNAT_SIGINT
1995                         CF_GNAT_PROJECTS
1996
1997                         CF_WITH_ADA_COMPILER
1998
1999                         cf_ada_package=terminal_interface
2000                         AC_SUBST(cf_ada_package)
2001
2002                         CF_WITH_ADA_INCLUDE
2003                         CF_WITH_ADA_OBJECTS
2004                         CF_WITH_ADA_SHAREDLIB
2005
2006                         # allow the Ada binding to be renamed
2007                         CF_WITH_ADA_LIBNAME(AdaCurses)
2008                 fi
2009         fi
2010 else
2011         cf_with_ada=no
2012 fi
2013
2014 # do this "late" to avoid conflict with header-checks
2015 if test "x$with_widec" = xyes ; then
2016         AC_CHECK_SIZEOF(wchar_t)
2017         # cross-compiling to mingw can run into the problem that attempting to
2018         # link with the regex library fails, causing the test to not set this to
2019         # a number.  "recent" autoconf does not address this problem either -TD
2020         if test -z "$ac_cv_sizeof_wchar_t"
2021         then
2022                 CF_VERBOSE(test failed (assume 2))
2023                 sed /SIZEOF_WCHAR_T/d confdefs.h >confdefs.tmp
2024                 mv confdefs.tmp confdefs.h
2025                 echo "#define SIZEOF_WCHAR_T 2" >>confdefs.h
2026         fi
2027 fi
2028
2029 ### Construct the ncurses library-subsets, if any, from this set of keywords:
2030 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
2031 ###
2032 ### ticlib modules may be a separate library, otherwise contained in termlib.
2033 ### termlib modules may be a separate library, otherwise contained in ncurses.
2034 ###
2035 ### The of "+" or " " between the tokens controls the way the script
2036 ### chooses to split module lists into libraries.
2037 ###
2038 ### (see CF_LIB_RULES).
2039 AC_MSG_CHECKING(for library subsets)
2040 LIB_SUBSETS=
2041
2042 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
2043         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
2044         if test "$with_ticlib" != no ; then
2045                 LIB_SUBSETS="${LIB_SUBSETS} "
2046         else
2047                 LIB_SUBSETS="${LIB_SUBSETS}+"
2048         fi
2049 fi
2050
2051 LIB_SUBSETS="${LIB_SUBSETS}termlib"
2052 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
2053
2054 if test "$with_termlib" != no ; then
2055         LIB_SUBSETS="${LIB_SUBSETS} "
2056 else
2057         LIB_SUBSETS="${LIB_SUBSETS}+"
2058 fi
2059
2060 LIB_SUBSETS="${LIB_SUBSETS}base"
2061
2062 # Most term-driver calls are to tinfo, but some like init_pair are to the
2063 # base library (so it resides in base).
2064 if test "$with_term_driver" != no ; then
2065         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
2066         case "$cf_cv_system_name" in
2067         (*mingw32*|*mingw64*)
2068                 if test "x$with_exp_win32" = xyes ; then
2069                         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32"
2070                 else
2071                         LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
2072                 fi
2073                 CPPFLAGS="$CPPFLAGS -DUSE_WIN32CON_DRIVER"
2074                 ;;
2075         (*)
2076                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
2077                 ;;
2078         esac
2079 elif test "x$with_exp_win32" = xyes ; then
2080         case "$cf_cv_system_name" in
2081         (*mingw32*|*mingw64*)
2082                 LIB_SUBSETS="${LIB_SUBSETS}+port_win32"
2083                 ;;
2084         (*)
2085                 ;;
2086         esac
2087 fi
2088
2089 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
2090 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
2091
2092 AC_MSG_RESULT($LIB_SUBSETS)
2093
2094 ### Construct the list of include-directories to be generated
2095 CF_INCLUDE_DIRS
2096 CF_ADA_INCLUDE_DIRS
2097
2098 ### Build up pieces for makefile rules
2099 AC_MSG_CHECKING(default library suffix)
2100 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
2101 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
2102 AC_MSG_RESULT($DFT_ARG_SUFFIX)
2103
2104 AC_MSG_CHECKING(default library-dependency suffix)
2105 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
2106 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
2107 AC_MSG_RESULT($DFT_DEP_SUFFIX)
2108
2109 AC_MSG_CHECKING(default object directory)
2110 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
2111 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
2112 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
2113
2114 if test "x$cf_with_cxx" = xyes ; then
2115 AC_MSG_CHECKING(c++ library-dependency suffix)
2116 if test "$with_libtool" != "no"; then
2117         # libtool thinks it can make c++ shared libraries (perhaps only g++)
2118         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2119 elif test "$with_shared_cxx" != "no"; then
2120         # also for g++ users...
2121         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2122 else
2123         # we normally make a static library because C/C++ library rules differ
2124         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
2125 fi
2126 AC_MSG_RESULT($CXX_LIB_SUFFIX)
2127 AC_SUBST(CXX_LIB_SUFFIX)
2128 fi
2129
2130 # do not want -ldl in build except as needed for -lncurses dependency
2131 if test "x$with_dlsym" = xyes ; then
2132 if test "$DFT_LWR_MODEL" = shared || \
2133    test "$DFT_LWR_MODEL" = libtool ; then
2134         CF_REMOVE_LIB(LIBS,$LIBS,dl)
2135 fi
2136 fi
2137 ### Set up low-level terminfo dependencies for makefiles.
2138
2139 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
2140 # do not need libdl
2141 TICS_LIST=
2142 if test "x$with_dlsym" = xyes ; then
2143         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
2144 fi
2145
2146 USE_ARG_SUFFIX="${DFT_ARG_SUFFIX}${EXTRA_SUFFIX}"
2147 USE_LIB_SUFFIX="${LIB_SUFFIX}${EXTRA_SUFFIX}"
2148 USE_CFG_SUFFIX=${DFT_ARG_SUFFIX}${cf_cv_abi_version}
2149 if test -n "$EXTRA_SUFFIX" && test "x$EXTRA_SUFFIX" != "x${cf_cv_abi_version}"
2150 then
2151         USE_CFG_SUFFIX="${USE_CFG_SUFFIX}${EXTRA_SUFFIX}"
2152 fi
2153 AC_SUBST(USE_ARG_SUFFIX)
2154 AC_SUBST(USE_CFG_SUFFIX)
2155 AC_SUBST(USE_LIB_SUFFIX)
2156
2157 if test "$with_ticlib" != no ; then
2158
2159         if test "x$with_ticlib" != xyes ; then
2160                 TICS_NAME=$with_ticlib
2161                 TICS_SUFFIX="`echo "${DFT_LIB_SUFFIX}" |sed -e "s/^${USE_LIB_SUFFIX}//"`"
2162                 TICS_ARG_SUFFIX="${with_ticlib}`echo "${USE_ARG_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2163                 TICS_DEP_SUFFIX="${with_ticlib}`echo "${DFT_DEP_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2164                 TICS_LIB_SUFFIX="${with_ticlib}"
2165         else
2166                 TICS_SUFFIX=${DFT_LIB_SUFFIX}
2167                 TICS_ARG_SUFFIX="${TICS_NAME}${USE_ARG_SUFFIX}"
2168                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
2169                 TICS_LIB_SUFFIX="${TICS_NAME}${USE_LIB_SUFFIX}"
2170         fi
2171         TICS_LDFLAGS="-L${LIB_DIR}"
2172         TICS_LIBS="-l${TICS_ARG_SUFFIX}"
2173 else
2174         TICS_SUFFIX=${DFT_LIB_SUFFIX}
2175         TICS_LDFLAGS="-L${LIB_DIR}"
2176         TICS_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2177 fi
2178 AC_SUBST(TICS_ARG_SUFFIX)
2179 AC_SUBST(TICS_DEP_SUFFIX)
2180 AC_SUBST(TICS_LIB_SUFFIX)
2181 AC_SUBST(TICS_LDFLAGS)
2182 AC_SUBST(TICS_LIBS)
2183
2184 if test "$with_termlib" != no ; then
2185
2186         if test "x$with_termlib" != xyes ; then
2187                 TINFO_NAME=$with_termlib
2188                 TINFO_SUFFIX="`echo "${DFT_LIB_SUFFIX}" |sed -e "s/^${USE_LIB_SUFFIX}//"`"
2189                 TINFO_ARG_SUFFIX="${with_termlib}`echo "${USE_ARG_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2190                 TINFO_DEP_SUFFIX="${with_termlib}`echo "${DFT_DEP_SUFFIX}" |sed -e "s/^${LIB_SUFFIX}//"`"
2191                 TINFO_LIB_SUFFIX="${with_termlib}"
2192         else
2193                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2194                 TINFO_ARG_SUFFIX="${TINFO_NAME}${USE_ARG_SUFFIX}"
2195                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
2196                 TINFO_LIB_SUFFIX="${TINFO_NAME}${USE_LIB_SUFFIX}"
2197         fi
2198
2199         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2200         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2201         if test "$DFT_LWR_MODEL" = "libtool"; then
2202                 TEST_ARGS="${TEST_DEPS}"
2203                 TEST_ARG2="${TEST_DEP2}"
2204                 TINFO_LDFLAGS="-L${LIB_DIR}"
2205                 TINFO_LIBS="$TEST_ARGS"
2206                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
2207                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
2208         else
2209                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
2210                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
2211                 if test "x$with_term_driver" != xno ; then
2212                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2213                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${USE_ARG_SUFFIX}"
2214                         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
2215                 else
2216                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2217                         TINFO_LIBS="$TEST_ARGS"
2218                 fi
2219                 TINFO_LDFLAGS="-L${LIB_DIR}"
2220                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2221         fi
2222 else
2223         # the next lines are needed for linking libtic over libncurses
2224         TINFO_NAME=${LIB_NAME}
2225         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2226         TINFO_ARG_SUFFIX=${LIB_NAME}${USE_ARG_SUFFIX}
2227         if test "x$with_tic_depends" = xyes ; then
2228                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2229         else
2230                 TICS_LIST="$SHLIB_LIST"
2231         fi
2232
2233         TINFO_LDFLAGS="-L${LIB_DIR}"
2234         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2235 fi
2236
2237 if test "$DFT_LWR_MODEL" = shared ; then
2238         case "$cf_cv_system_name" in
2239         (cygwin*|msys*)
2240                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
2241                 TINFO_SUFFIX=.dll
2242                 ;;
2243         esac
2244 fi
2245
2246 AC_SUBST(TINFO_ARG_SUFFIX)
2247 AC_SUBST(TINFO_DEP_SUFFIX)
2248 AC_SUBST(TINFO_LIB_SUFFIX)
2249 AC_SUBST(TINFO_LDFLAGS)
2250 AC_SUBST(TINFO_LIBS)
2251
2252 if test "x$with_dlsym" = xyes ; then
2253         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
2254 fi
2255
2256 if test "$DFT_LWR_MODEL" = "libtool"; then
2257         OBJEXT=lo
2258 fi
2259
2260 # needed for Ada95
2261 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
2262 AC_SUBST(TINFO_LDFLAGS2)
2263
2264 case "$DFT_LWR_MODEL" in
2265 (normal|debug|profile)
2266         CF_LDFLAGS_STATIC
2267         ;;
2268 esac
2269
2270 AC_MSG_CHECKING(where we will install curses.h)
2271 AC_SUBST(includesubdir)
2272 includesubdir=
2273 if test "$with_overwrite" = no && \
2274  { test "x$includedir" = 'x${prefix}/include' || \
2275    test "x$includedir" = "x${prefix}/include"; }
2276 then
2277         includesubdir="/ncurses${USE_LIB_SUFFIX}"
2278 fi
2279 AC_MSG_RESULT(${includedir}${includesubdir})
2280
2281 ### Resolve a conflict between normal and wide-curses by forcing applications
2282 ### that will need libutf8 to add it to their configure script.
2283 if test "$with_overwrite" != no ; then
2284 if test "$NCURSES_LIBUTF8" = 1 ; then
2285         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
2286         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
2287 fi
2288 fi
2289 WITH_OVERWRITE=$with_overwrite
2290
2291 ### At least on MinGW a shared library build without libtool
2292 ### requires adding the additional libs to the link list.
2293 case "$cf_cv_system_name" in
2294 (*mingw32*|*mingw64*)
2295         if test "$DFT_LWR_MODEL" != "libtool"; then
2296            SHLIB_LIST="$SHLIB_LIST ${LIBS}"
2297         fi
2298         ;;
2299 *)      ;;
2300 esac
2301
2302 AC_SUBST(WITH_OVERWRITE)
2303 AC_SUBST(TICS_LIST)
2304 AC_SUBST(TINFO_LIST)
2305 AC_SUBST(SHLIB_LIST)
2306
2307 # used to separate tack out of the tree
2308 NCURSES_TREE=
2309 AC_SUBST(NCURSES_TREE)
2310
2311 ### predefined stuff for the test programs
2312 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
2313
2314 # pkgsrc uses these
2315 CF_WITH_LIB_BASENAME(FORM_NAME,form)
2316 CF_WITH_LIB_BASENAME(MENU_NAME,menu)
2317 CF_WITH_LIB_BASENAME(PANEL_NAME,panel)
2318 CF_WITH_LIB_BASENAME(CXX_NAME,cxx,ncurses++)
2319
2320 ### Construct the list of subdirectories for which we'll customize makefiles
2321 ### with the appropriate compile-rules.
2322
2323 CF_SRC_MODULES($modules_to_build)
2324
2325 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2326    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/src/library.gpr:Ada95/src/library.gpr.in"
2327    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${USE_CFG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
2328    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${USE_CFG_SUFFIX}-config.1:man/MKada_config.in"
2329 fi
2330
2331 CF_DIRS_TO_MAKE
2332
2333 # symbols that differ when compiling Ada95 by itself.
2334 NCURSES_SHLIB2=$SHELL' $(top_srcdir)/misc/shlib'
2335 AC_SUBST(NCURSES_SHLIB2)
2336
2337 # values to use as strings
2338 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
2339
2340 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
2341
2342 ### Define substitutions for header files to avoid name-pollution
2343 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
2344 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
2345 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
2346 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
2347
2348 ################################################################################
2349 test "x$use_database" = xyes && \
2350 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
2351
2352 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
2353 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${USE_CFG_SUFFIX}-config.1:man/MKncu_config.in"
2354
2355 if test "x$enable_pc_files" = xyes && test -z "$MAKE_PC_FILES" ; then
2356 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
2357 fi
2358 AC_SUBST(cross_compiling)
2359
2360 if test "x$cf_with_tests" != xno ; then
2361         MAKE_TESTS=
2362 else
2363         MAKE_TESTS="#"
2364 fi
2365 AC_SUBST(MAKE_TESTS)
2366
2367 ADAHTML_DIR=../../doc/html/ada
2368 AC_SUBST(ADAHTML_DIR)
2369
2370 # workaround for OS/2 (20151017)
2371 case "$cf_cv_system_name" in
2372 (os2*)
2373         LIBTOOL_OPTS_CXX="-os2dllname ncurs++"
2374         ;;
2375 (*)
2376         LIBTOOL_OPTS_CXX=
2377         ;;
2378 esac
2379 AC_SUBST(LIBTOOL_OPTS_CXX)
2380
2381 # workaround for g++ versus Solaris (20131116)
2382 case "$cf_cv_system_name" in
2383 (solaris2*)
2384         case "x$CPPFLAGS" in
2385         (*-D_XOPEN_SOURCE_EXTENDED*)
2386                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
2387                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
2388                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
2389                 ;;
2390         esac
2391         ;;
2392 esac
2393
2394 # Help to automatically enable the extended curses features when using either
2395 # the *-config or the ".pc" files by adding defines.
2396 AC_MSG_CHECKING(for defines to add to ncurses${USE_CFG_SUFFIX}-config script)
2397 PKG_CFLAGS=
2398 for cf_loop1 in $CPPFLAGS_after_XOPEN
2399 do
2400         cf_found=no
2401         for cf_loop2 in $CPPFLAGS_before_XOPEN
2402         do
2403                 if test "x$cf_loop1" = "x$cf_loop2"
2404                 then
2405                         cf_found=yes
2406                         break
2407                 fi
2408         done
2409         test "$cf_found" = no && PKG_CFLAGS="$PKG_CFLAGS $cf_loop1"
2410 done
2411 AC_MSG_RESULT($PKG_CFLAGS)
2412 AC_SUBST(PKG_CFLAGS)
2413
2414 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
2415 case "x$NCURSES_OSPEED" in
2416 (*short*)
2417         cf_compatible=1
2418         ;;
2419 (*)
2420         cf_compatible=0
2421         ;;
2422 esac
2423 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
2424
2425 case "x$cf_cv_typeof_chtype" in
2426 (xshort|xint|xlong)
2427         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
2428         ;;
2429 esac
2430
2431 case "x$cf_cv_typeof_mmask_t" in
2432 (xshort|xint|xlong)
2433         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2434         ;;
2435 esac
2436
2437 # substitute into misc/Makefile to suppress
2438 # (un)install.data from the
2439 # (un)install rules.
2440 if test "x$cf_with_db_install" = "xno"; then
2441         MISC_INSTALL_DATA=
2442         MISC_UNINSTALL_DATA=
2443 else
2444         MISC_INSTALL_DATA=install.data
2445         MISC_UNINSTALL_DATA=uninstall.data
2446 fi
2447 AC_SUBST(MISC_INSTALL_DATA)
2448 AC_SUBST(MISC_UNINSTALL_DATA)
2449
2450 if test "x$cf_with_db_install" = "xno" || test "x$TERMINFO_SRC" = "xno"; then
2451         MAKE_DATABASE="#"
2452 else
2453         MAKE_DATABASE="$MAKE_TERMINFO"
2454 fi
2455 AC_SUBST(MAKE_DATABASE)
2456
2457 dnl Override the package used for exported symbols
2458 if test -n "$PACKAGE"
2459 then
2460         PACKAGE="${PACKAGE}${DFT_ARG_SUFFIX}"
2461         export PACKAGE
2462         echo "package: $PACKAGE"
2463 fi
2464
2465 UNALTERED_SYMS=
2466 cf_filter_syms=no
2467
2468 if test -n "$RESULTING_SYMS"
2469 then
2470         cf_filter_syms=$cf_dft_filter_syms
2471         CF_VERBOSE(will map symbols to ABI=$cf_cv_abi_version)
2472 fi
2473
2474 if test "x$WILDCARD_SYMS" = xno
2475 then
2476         cf_filter_syms=yes
2477 fi
2478
2479 test "x$cf_with_trace" = xyes && NCURSES_INLINE=
2480
2481 UNALTERED_SYMS=`echo "$RESULTING_SYMS" | sed -e 's/\\$/\\\\$/g'`
2482 if test "$cf_filter_syms" = yes
2483 then
2484         RESULTING_SYMS=resulting.map
2485 fi
2486 AC_SUBST(UNALTERED_SYMS)
2487
2488 if test "x$cross_compiling" = xyes ; then
2489         ADAGEN_LDFLAGS='$(CROSS_LDFLAGS)'
2490         CHECK_BUILD="#"
2491 else
2492         ADAGEN_LDFLAGS='$(NATIVE_LDFLAGS)'
2493         CHECK_BUILD=
2494 fi
2495 AC_SUBST(ADAGEN_LDFLAGS)
2496 AC_SUBST(CHECK_BUILD)
2497 AC_SUBST(PRIVATE_LIBS)
2498
2499 # This is used for the *-config script and *.pc data files.
2500 CF_LD_SEARCHPATH
2501
2502 AC_DEFINE(HAVE_CURSES_DATA_BOOLNAMES,1,[definition needed for in-tree build of tack])
2503
2504 AC_OUTPUT( \
2505         include/MKterm.h.awk \
2506         include/curses.head:include/curses.h.in \
2507         include/ncurses_dll.h \
2508         include/termcap.h \
2509         include/unctrl.h \
2510         $SUB_MAKEFILES \
2511         Makefile,[
2512 if test "x$cf_with_tests" != xno ; then
2513         CF_PRG_RULES(["$srcdir/test/mk-test.awk" INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2514 fi
2515 CF_LIB_RULES($SRC_SUBDIRS)
2516
2517 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2518 if test -z "$USE_OLD_MAKERULES" ; then
2519         $AWK -f "$srcdir/Ada95/mk-1st.awk" <"$srcdir/Ada95/src/modules" >>Ada95/src/Makefile
2520 fi
2521 fi
2522 ],[
2523 ### Special initialization commands, used to pass information from the
2524 ### configuration-run into config.status
2525
2526 ALTERNATE_SYMS="$ALTERNATE_SYMS"
2527 AWK="$AWK"
2528 CXX_NAME="$CXX_NAME"
2529 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2530 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2531 ECHO_LD="$ECHO_LD"
2532 EXTRA_SUFFIX="$EXTRA_SUFFIX"
2533 FORM_NAME="$FORM_NAME"
2534 LDCONFIG="$LDCONFIG"
2535 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2536 LIB_NAME="$LIB_NAME"
2537 LIB_PREFIX="$LIB_PREFIX"
2538 LIB_SUBSETS="$LIB_SUBSETS"
2539 LIB_SUFFIX="$LIB_SUFFIX"
2540 LIB_TRACING="$LIB_TRACING"
2541 LN_S="$LN_S"
2542 MAKE_TERMINFO="$MAKE_TERMINFO"
2543 MENU_NAME="$MENU_NAME"
2544 NCURSES_MAJOR="$NCURSES_MAJOR"
2545 NCURSES_MINOR="$NCURSES_MINOR"
2546 NCURSES_OSPEED="$NCURSES_OSPEED"
2547 NCURSES_PATCH="$NCURSES_PATCH"
2548 PANEL_NAME="$PANEL_NAME"
2549 SRC_SUBDIRS="$SRC_SUBDIRS"
2550 TERMINFO="$TERMINFO"
2551 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2552 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2553 TICS_NAME="$TICS_NAME"
2554 TICS_SUFFIX="$TICS_SUFFIX"
2555 TIC_PATH="$TIC_PATH"
2556 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2557 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2558 TINFO_NAME="$TINFO_NAME"
2559 TINFO_SUFFIX="$TINFO_SUFFIX"
2560 UNALTERED_SYMS="$UNALTERED_SYMS"
2561 USE_ARG_SUFFIX="$USE_ARG_SUFFIX"
2562 USE_CFG_SUFFIX="$USE_CFG_SUFFIX"
2563 USE_LIB_SUFFIX="$USE_LIB_SUFFIX"
2564 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2565 WILDCARD_SYMS="$WILDCARD_SYMS"
2566 WITH_CURSES_H="$with_curses_h"
2567 WITH_ECHO="${enable_echo:=yes}"
2568 WITH_OVERWRITE="$with_overwrite"
2569 cf_LIST_MODELS="$cf_list_models"
2570 cf_cv_VERSION_GNATMAKE=$cf_cv_VERSION_GNATMAKE
2571 cf_cv_VERSION_GPRBUILD=$cf_cv_VERSION_GPRBUILD
2572 cf_cv_abi_version="$cf_cv_abi_version"
2573 cf_cv_do_relink="$cf_cv_do_relink"
2574 cf_cv_do_reranlib="$cf_cv_do_reranlib"
2575 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2576 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2577 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2578 cf_cv_make_PHONY="$cf_cv_make_PHONY"
2579 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2580 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2581 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2582 cf_cv_rel_version="$cf_cv_rel_version"
2583 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2584 cf_cv_shared_soname='$cf_cv_shared_soname'
2585 cf_cv_shlib_version="$cf_cv_shlib_version"
2586 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2587 cf_cv_system_name="$cf_cv_system_name"
2588 cf_cv_term_driver="$with_term_driver"
2589 cf_with_ada="$cf_with_ada"
2590 cf_with_cxx_binding="$cf_with_cxx_binding"
2591 cf_with_db_install="$cf_with_db_install"
2592 cf_with_manpages="$cf_with_manpages"
2593 cf_with_tests="$cf_with_tests"
2594 host="$host"
2595 target="$target"
2596 with_shared_cxx="$with_shared_cxx"
2597
2598 ],cat)dnl
2599 ${MAKE:-make} preinstall