configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2013,2014 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: configure.in,v 1.584 2014/09/14 00:21:22 tom Exp $
  32 dnl Process this file with autoconf to produce a configure script.
  33 dnl
  34 dnl See http://invisible-island.net/autoconf/ for additional information.
  35 dnl
  36 dnl ---------------------------------------------------------------------------
  37 AC_PREREQ(2.52.20030208)
  38 AC_REVISION($Revision: 1.584 $)
  39 AC_INIT(ncurses/base/lib_initscr.c)
  40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  41
  42 CF_TOP_BUILDDIR
  43 CF_SUBST_NCURSES_VERSION
  44
  45 CF_WITH_REL_VERSION(NCURSES)
  46 CF_WITH_ABI_VERSION
  47
  48 CF_WITH_SYSTYPE
  49
  50 ###     Save the given $CFLAGS to allow user-override.
  51 cf_user_CFLAGS="$CFLAGS"
  52
  53 ###     Default install-location
  54 CF_CFG_DEFAULTS
  55
  56 ###     Checks for programs.
  57 AC_ARG_WITH(ada,
  58         [  --without-ada           suppress check for Ada95, don't build demo],
  59         [cf_with_ada=$withval],
  60         [cf_with_ada=yes])
  61 if test "x$cf_with_ada" = xyes
  62 then
  63         cf_PROG_CC="gnatgcc gcc cc"
  64 else
  65         cf_PROG_CC="gcc cc"
  66 fi
  67
  68 CF_PROG_CC($cf_PROG_CC)
  69
  70 AC_PROG_CPP
  71 AC_PROG_GCC_TRADITIONAL
  72 CF_PROG_CC_C_O(CC)
  73 CF_PROG_LDCONFIG
  74
  75 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  76 dnl                             configure script by not letting us test if C++
  77 dnl                             is present, making this option necessary.
  78 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  79 AC_ARG_WITH(cxx,
  80         [  --without-cxx           do not adjust ncurses bool to match C++],
  81         [cf_with_cxx=$withval],
  82         [cf_with_cxx=yes])
  83 AC_MSG_RESULT($cf_with_cxx)
  84 if test "X$cf_with_cxx" = Xno ; then
  85         CXX=""
  86         GXX=""
  87 else
  88         # with autoconf 2.13, we can change the error to a warning:
  89         pushdef([AC_MSG_ERROR],
  90                 [AC_MSG_RESULT(no)
  91                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
  92                 cf_with_cxx=no; CXX=""; GXX="";])dnl
  93         AC_PROG_CXX
  94         popdef([AC_MSG_ERROR])dnl
  95
  96         AC_LANG_PUSH(C++)
  97         if test "x$cf_with_cxx" != xno
  98         then
  99                 # Several of the C++ configurations do not work, particularly when
 100                 # cross-compiling (20140913 -TD)
 101                 AC_MSG_CHECKING(if $CXX works)
 102
 103                 save_CPPFLAGS="$CPPFLAGS"
 104                 eval cf_includedir=${includedir}
 105                 CPPFLAGS="$CPPFLAGS -I${cf_includedir}"
 106                 AC_TRY_COMPILE([
 107 #include <stdlib.h>
 108 #include <stdio.h>
 109 ],
 110                 [
 111                 printf("Hello world!\n")
 112                 ],
 113                 [cf_cxx_works=yes],
 114                 [cf_cxx_works=no])
 115                 CPPFLAGS="$save_CPPFLAGS"
 116
 117                 AC_MSG_RESULT($cf_cxx_works)
 118                 if test "x$cf_cxx_works" = xno
 119                 then
 120                         AC_MSG_WARN([Ignore $CXX, since it cannot compile hello-world.])
 121                         cf_with_cxx=no; CXX=""; GXX="";
 122                 fi
 123         fi
 124         AC_LANG_POP
 125
 126         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
 127         if test "$CXX" = "g++" ; then
 128                 AC_PATH_PROG(CXX,g++)
 129         fi
 130         case "x$CXX" in #(vi
 131         x|xg++)
 132                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
 133                 cf_with_cxx=no; CXX=""; GXX="";
 134                 ;;
 135         esac
 136 fi
 137
 138 CF_GXX_VERSION
 139 case $GXX_VERSION in
 140 1*|2.[[0-6]]*)
 141         # GXX=""; CXX=""; ac_cv_prog_gxx=no
 142         # cf_cxx_library=no
 143         AC_MSG_WARN(templates do not work)
 144         ;;
 145 esac
 146
 147 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 148 AC_ARG_WITH(cxx-binding,
 149         [  --without-cxx-binding   do not build C++ binding and demo],
 150         [cf_with_cxx_binding=$withval],
 151         [cf_with_cxx_binding=$cf_with_cxx])
 152 AC_MSG_RESULT($cf_with_cxx_binding)
 153
 154 AC_MSG_CHECKING(if you want to build with Ada95)
 155 AC_MSG_RESULT($cf_with_ada)
 156
 157 AC_MSG_CHECKING(if you want to install terminal database)
 158 AC_ARG_ENABLE(db-install,
 159         [  --disable-db-install    suppress install of terminal database],
 160         [cf_with_db_install=$enableval],
 161         [cf_with_db_install=yes])
 162 AC_MSG_RESULT($cf_with_db_install)
 163
 164 AC_MSG_CHECKING(if you want to install manpages)
 165 AC_ARG_WITH(manpages,
 166         [  --without-manpages      suppress install of manpages],
 167         [cf_with_manpages=$withval],
 168         [cf_with_manpages=yes])
 169 AC_MSG_RESULT($cf_with_manpages)
 170
 171 AC_MSG_CHECKING(if you want to build programs such as tic)
 172 AC_ARG_WITH(progs,
 173         [  --without-progs         suppress build/install with programs (e.g., tic)],
 174         [cf_with_progs=$withval],
 175         [cf_with_progs=yes])
 176 AC_MSG_RESULT($cf_with_progs)
 177
 178 AC_MSG_CHECKING(if you want to build test-programs)
 179 AC_ARG_WITH(tests,
 180         [  --without-tests         suppress build/install with test-programs],
 181         [cf_with_tests=$withval],
 182         [cf_with_tests=yes])
 183 AC_MSG_RESULT($cf_with_tests)
 184
 185 AC_MSG_CHECKING(if you wish to install curses.h)
 186 AC_ARG_WITH(curses-h,
 187         [  --without-curses-h      install curses.h as ncurses.h only],
 188         [with_curses_h=$withval],
 189         [with_curses_h=yes])
 190 AC_MSG_RESULT($with_curses_h)
 191
 192 modules_to_build="ncurses"
 193 if test "X$cf_with_progs" != Xno ; then
 194 modules_to_build="$modules_to_build progs tack"
 195 fi
 196 modules_to_build="$modules_to_build panel menu form"
 197
 198 AC_ARG_PROGRAM
 199
 200 CF_PROG_AWK
 201 CF_PROG_EGREP
 202 CF_PROG_INSTALL
 203 CF_PROG_LINT
 204 CF_PROG_LN_S
 205
 206 AC_SYS_LONG_FILE_NAMES
 207
 208 # if we find pkg-config, check if we should install the ".pc" files.
 209 CF_PKG_CONFIG
 210 CF_WITH_PKG_CONFIG_LIBDIR
 211 CF_ENABLE_PC_FILES
 212
 213 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 214 AC_ARG_ENABLE(mixed-case,
 215         [  --enable-mixed-case     tic should assume mixed-case filenames],
 216         [enable_mixedcase=$enableval],
 217         [enable_mixedcase=auto])
 218 AC_MSG_RESULT($enable_mixedcase)
 219 if test "$enable_mixedcase" = "auto" ; then
 220     CF_MIXEDCASE_FILENAMES
 221 else
 222     cf_cv_mixedcase=$enable_mixedcase
 223     if test "x$enable_mixedcase" = "xyes" ; then
 224         AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
 225     fi
 226 fi
 227
 228 # do this after mixed-case option (tags/TAGS is not as important as tic).
 229 AC_PROG_MAKE_SET
 230 CF_MAKE_TAGS
 231 CF_MAKEFLAGS
 232
 233 dnl These are standard among *NIX systems, but not when cross-compiling
 234 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 235 AC_CHECK_TOOL(LD, ld, ld)
 236 AC_CHECK_TOOL(AR, ar, ar)
 237 AC_CHECK_TOOL(NM, nm, nm)
 238 CF_AR_FLAGS
 239
 240 dnl Special option for use by system-builders: the install-prefix is used to
 241 dnl adjust the location into which the actual install is done, so that an
 242 dnl archive can be built without modifying the host system's configuration.
 243 AC_MSG_CHECKING(if you have specified an install-prefix)
 244 AC_ARG_WITH(install-prefix,
 245         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 246         [case "x$withval" in #(vi
 247         xyes|xno) #(vi
 248                 ;;
 249         *)      DESTDIR="$withval"
 250                 ;;
 251         esac])
 252 AC_MSG_RESULT($DESTDIR)
 253 AC_SUBST(DESTDIR)
 254
 255 ###############################################################################
 256 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 257 # If we're cross-compiling, allow the user to override the tools and their
 258 # options.  The configure script is oriented toward identifying the host
 259 # compiler, etc., but we need a build compiler to generate parts of the source.
 260 CF_BUILD_CC
 261
 262 ###############################################################################
 263 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 264
 265 ### Options to allow the user to specify the set of libraries which are used.
 266 ### Use "--without-normal --with-shared" to allow the default model to be
 267 ### shared, for example.
 268 cf_list_models=""
 269 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 270
 271 CF_WITH_LIBTOOL
 272 if test "$with_libtool" != "no" ; then
 273
 274 cf_list_models="$cf_list_models libtool"
 275
 276 else
 277
 278 AC_MSG_CHECKING(if you want to build shared libraries)
 279 AC_ARG_WITH(shared,
 280         [  --with-shared           generate shared-libraries],
 281         [with_shared=$withval],
 282         [with_shared=no])
 283 AC_MSG_RESULT($with_shared)
 284 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
 285
 286 AC_MSG_CHECKING(if you want to build static libraries)
 287 AC_ARG_WITH(normal,
 288         [  --with-normal           generate normal-libraries (default)],
 289         [with_normal=$withval],
 290         [with_normal=yes])
 291 AC_MSG_RESULT($with_normal)
 292 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
 293
 294 AC_MSG_CHECKING(if you want to build debug libraries)
 295 AC_ARG_WITH(debug,
 296         [  --with-debug            generate debug-libraries (default)],
 297         [with_debug=$withval],
 298         [with_debug=yes])
 299 AC_MSG_RESULT($with_debug)
 300 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
 301
 302 AC_MSG_CHECKING(if you want to build profiling libraries)
 303 AC_ARG_WITH(profile,
 304         [  --with-profile          generate profile-libraries],
 305         [with_profile=$withval],
 306         [with_profile=no])
 307 AC_MSG_RESULT($with_profile)
 308 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
 309
 310 fi
 311
 312 if test "X$cf_with_cxx_binding" != Xno; then
 313 if test "x$with_shared" = "xyes"; then
 314 AC_MSG_CHECKING(if you want to build C++ shared libraries)
 315 AC_ARG_WITH(cxx-shared,
 316         [  --with-cxx-shared       generate C++ shared-libraries],
 317         [with_shared_cxx=$withval],
 318         [with_shared_cxx=no])
 319 AC_MSG_RESULT($with_shared_cxx)
 320 fi
 321 fi
 322
 323 ###############################################################################
 324
 325 AC_MSG_CHECKING(for specified models)
 326 test -z "$cf_list_models" && cf_list_models=normal
 327 dnl If we use libtool to generate libraries, then it must be the only
 328 dnl specified model.
 329 test "$with_libtool" != "no" && cf_list_models=libtool
 330 AC_MSG_RESULT($cf_list_models)
 331
 332 ### Use the first model as the default, and save its suffix for use in building
 333 ### up test-applications.
 334 AC_MSG_CHECKING(for default model)
 335 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 336 AC_MSG_RESULT($DFT_LWR_MODEL)
 337
 338 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 339
 340 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 341 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 342
 343 TICS_NAME=tic
 344 AC_SUBST(TICS_NAME)
 345
 346 TINFO_NAME=tinfo
 347 AC_SUBST(TINFO_NAME)
 348
 349 LIB_NAME=ncurses
 350 AC_SUBST(LIB_NAME)
 351
 352 LIB_DIR=../lib
 353 LIB_2ND=../../lib
 354
 355 CF_WITH_LIB_PREFIX(cf_prefix)
 356
 357 LIB_SUFFIX=
 358 AC_SUBST(LIB_SUFFIX)
 359 CF_PATHSEP
 360
 361 ###############################################################################
 362
 363 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 364 AC_ARG_WITH(termlib,
 365         [  --with-termlib          generate separate terminfo library],
 366         [with_termlib=$withval],
 367         [with_termlib=no])
 368 AC_MSG_RESULT($with_termlib)
 369
 370 AC_MSG_CHECKING(if you want to build a separate tic library)
 371 AC_ARG_WITH(ticlib,
 372         [  --with-ticlib           generate separate tic library],
 373         [with_ticlib=$withval],
 374         [with_ticlib=no])
 375 AC_MSG_RESULT($with_ticlib)
 376
 377 ### Checks for special libraries, must be done up-front.
 378 SHLIB_LIST=""
 379 CF_WITH_GPM
 380 if test "$with_gpm" != no ; then
 381         AC_MSG_CHECKING(if you want to load GPM dynamically)
 382         AC_ARG_WITH(dlsym,
 383                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 384                 [with_dlsym=$withval],
 385                 [with_dlsym=yes])
 386         AC_MSG_RESULT($with_dlsym)
 387         if test "x$with_dlsym" = xyes ; then
 388                 CF_FUNC_DLSYM
 389                 if test "x$with_gpm" != xyes ; then
 390                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 391                         cf_cv_gpm_soname="$with_gpm"
 392                 else
 393                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 394                 fi
 395                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
 396                 SHLIB_LIST="-ldl $SHLIB_LIST"
 397         else
 398                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 399                 CF_ADD_LIB(gpm,TEST_LIBS)
 400         fi
 401         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
 402         CF_CHECK_GPM_WGETCH
 403 fi
 404
 405 CF_WITH_SYSMOUSE
 406
 407 dnl Not all ports of gcc support the -g option
 408
 409 if test X"$CC_G_OPT" = X"" ; then
 410         CC_G_OPT='-g'
 411         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
 412 fi
 413 AC_SUBST(CC_G_OPT)
 414
 415 if test X"$CXX_G_OPT" = X"" ; then
 416         CXX_G_OPT='-g'
 417         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
 418 fi
 419 AC_SUBST(CXX_G_OPT)
 420
 421 AC_MSG_CHECKING(for default loader flags)
 422 case $DFT_LWR_MODEL in
 423 libtool) LD_MODEL=''   ;;
 424 normal)  LD_MODEL=''   ;;
 425 debug)   LD_MODEL=$CC_G_OPT ;;
 426 profile) LD_MODEL='-pg';;
 427 shared)  LD_MODEL=''   ;;
 428 esac
 429 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 430 AC_MSG_RESULT($LD_MODEL)
 431
 432 case $DFT_LWR_MODEL in
 433 shared)
 434 CF_ENABLE_RPATH
 435 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 436 AC_ARG_ENABLE(relink,
 437 [  --disable-relink        relink shared libraries during install],
 438 [cf_cv_do_relink=$enableval],
 439 [cf_cv_do_relink=yes])
 440 AC_MSG_RESULT($cf_cv_do_relink)
 441         ;;
 442 esac
 443
 444 # we will build libraries one-level down.
 445 rel_builddir=..
 446 CF_SHARED_OPTS
 447 if test "$CC_SHARED_OPTS" = "unknown"; then
 448         for model in $cf_list_models; do
 449                 if test "$model" = "shared"; then
 450                         AC_ERROR(Shared libraries are not supported in this version)
 451                 fi
 452         done
 453 fi
 454
 455 # pretend that ncurses==ncursesw==ncursest
 456 AC_MSG_CHECKING(if you want to disable library suffixes)
 457 AC_ARG_ENABLE(lib-suffixes,
 458         [  --disable-lib-suffixes  disable library suffixes],
 459         [disable_lib_suffixes=$enableval],
 460         [disable_lib_suffixes=no])
 461 AC_MSG_RESULT($disable_lib_suffixes)
 462
 463 ### If we're building with rpath, try to link non-standard libs that way too.
 464 if test "$DFT_LWR_MODEL" = "shared"; then
 465         CF_DISABLE_RPATH_HACK
 466 fi
 467
 468 ###############################################################################
 469 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 470
 471 ###     use option --disable-overwrite to leave out the link to -lcurses
 472 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 473 AC_ARG_ENABLE(overwrite,
 474         [  --disable-overwrite     leave out the link to -lcurses],
 475         [with_overwrite=$enableval],
 476         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 477 AC_MSG_RESULT($with_overwrite)
 478
 479 AC_MSG_CHECKING(if external terminfo-database is used)
 480 AC_ARG_ENABLE(database,
 481         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 482         [use_database=$enableval],
 483         [use_database=yes])
 484 AC_MSG_RESULT($use_database)
 485
 486 case $host_os in #(vi
 487 os2*) #(vi
 488         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 489         ;;
 490 *) #(vi
 491         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 492         ;;
 493 esac
 494 AC_SUBST(TERMINFO_SRC)
 495
 496 NCURSES_USE_DATABASE=0
 497 if test "$use_database" != no ; then
 498         NCURSES_USE_DATABASE=1
 499
 500         AC_MSG_CHECKING(which terminfo source-file will be installed)
 501         AC_ARG_WITH(database,
 502                 [  --with-database=XXX     specify terminfo source to install],
 503                 [TERMINFO_SRC=$withval])
 504         AC_MSG_RESULT($TERMINFO_SRC)
 505
 506         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 507         AC_ARG_WITH(hashed-db,
 508                 [  --with-hashed-db        specify hashed-database library],,
 509                 [with_hashed_db=no])
 510         AC_MSG_RESULT($with_hashed_db)
 511 else
 512         with_hashed_db=no
 513 fi
 514 AC_SUBST(NCURSES_USE_DATABASE)
 515
 516 AC_MSG_CHECKING(for list of fallback descriptions)
 517 AC_ARG_WITH(fallbacks,
 518         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 519         [with_fallback=$withval],
 520         [with_fallback=])
 521 AC_MSG_RESULT($with_fallback)
 522 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 523 AC_SUBST(FALLBACK_LIST)
 524
 525 AC_MSG_CHECKING(if you want modern xterm or antique)
 526 AC_ARG_WITH(xterm-new,
 527         [  --without-xterm-new     specify if xterm terminfo should be old version],
 528         [with_xterm_new=$withval],
 529         [with_xterm_new=yes])
 530 case $with_xterm_new in
 531 no)     with_xterm_new=xterm-old;;
 532 *)      with_xterm_new=xterm-new;;
 533 esac
 534 AC_MSG_RESULT($with_xterm_new)
 535 WHICH_XTERM=$with_xterm_new
 536 AC_SUBST(WHICH_XTERM)
 537
 538 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
 539 AC_ARG_WITH(xterm-kbs,
 540         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
 541         [with_xterm_kbs=$withval],
 542         [with_xterm_kbs=BS])
 543 case x$with_xterm_kbs in
 544 xyes|xno|xBS|xbs|x8)
 545         with_xterm_kbs=BS
 546         ;;
 547 xDEL|xdel|x127)
 548         with_xterm_kbs=DEL
 549         ;;
 550 *)
 551         with_xterm_kbs=$withval
 552         ;;
 553 esac
 554 AC_MSG_RESULT($with_xterm_kbs)
 555 XTERM_KBS=$with_xterm_kbs
 556 AC_SUBST(XTERM_KBS)
 557
 558 MAKE_TERMINFO=
 559 if test "$use_database" = no ; then
 560         TERMINFO="${datadir}/terminfo"
 561         MAKE_TERMINFO="#"
 562 else
 563
 564 AC_MSG_CHECKING(for list of terminfo directories)
 565 CF_WITH_PATHLIST(terminfo-dirs,
 566         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 567         TERMINFO_DIRS,
 568         DATADIR/terminfo,
 569         ${datadir}/terminfo)
 570 AC_MSG_RESULT($TERMINFO_DIRS)
 571 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
 572
 573 AC_MSG_CHECKING(for default terminfo directory)
 574 CF_WITH_PATH(default-terminfo-dir,
 575         [  --with-default-terminfo-dir=DIR default terminfo directory],
 576         TERMINFO,
 577         DATADIR/terminfo,
 578         ${datadir}/terminfo)
 579 AC_MSG_RESULT($TERMINFO)
 580 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
 581
 582 fi
 583
 584 AC_SUBST(TERMINFO)
 585 AC_SUBST(MAKE_TERMINFO)
 586
 587 ###     use option --disable-big-core to make tic run on small machines
 588 ###     We need 4Mb, check if we can allocate 50% more than that.
 589 AC_MSG_CHECKING(if big-core option selected)
 590 AC_ARG_ENABLE(big-core,
 591         [  --disable-big-core      assume machine has little memory],
 592         [with_big_core=$enableval],
 593         [AC_TRY_RUN([
 594 #include <stdlib.h>
 595 #include <string.h>
 596 int main() {
 597         unsigned long n = 6000000L;
 598         char *s = malloc(n);
 599         if (s != 0)
 600                 s[0] = s[n-1] = 0;
 601         ${cf_cv_main_return:-return}(s == 0);
 602 }],
 603         [with_big_core=yes],
 604         [with_big_core=no],
 605         [with_big_core=no])])
 606 AC_MSG_RESULT($with_big_core)
 607 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
 608
 609 ### ISO C only guarantees 512-char strings, we have tables which load faster
 610 ### when constructed using "big" strings.  More than the C compiler, the awk
 611 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 612 AC_MSG_CHECKING(if big-strings option selected)
 613 AC_ARG_ENABLE(big-strings,
 614         [  --disable-big-strings   assume compiler has only standard-size strings],
 615         [with_big_strings=$enableval],
 616         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 617 AC_MSG_RESULT($with_big_strings)
 618
 619 USE_BIG_STRINGS=0
 620 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
 621 AC_SUBST(USE_BIG_STRINGS)
 622
 623 ###     use option --enable-termcap to compile in the termcap fallback support
 624 AC_MSG_CHECKING(if you want termcap-fallback support)
 625 AC_ARG_ENABLE(termcap,
 626         [  --enable-termcap        compile in termcap fallback support],
 627         [with_termcap=$enableval],
 628         [with_termcap=no])
 629 AC_MSG_RESULT($with_termcap)
 630
 631 NCURSES_USE_TERMCAP=0
 632 if test "x$with_termcap" != "xyes" ; then
 633         if test "$use_database" = no ; then
 634                 if test -z "$with_fallback" ; then
 635                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 636                 fi
 637         fi
 638         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
 639 else
 640
 641         if test "$with_ticlib" != no ; then
 642                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 643         fi
 644
 645         NCURSES_USE_TERMCAP=1
 646         AC_MSG_CHECKING(for list of termcap files)
 647         CF_WITH_PATHLIST(termpath,
 648                 [  --with-termpath=XXX     specify list of termcap files],
 649                 TERMPATH,
 650                 /etc/termcap:/usr/share/misc/termcap)
 651         AC_MSG_RESULT($TERMPATH)
 652         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
 653
 654         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 655         AC_MSG_CHECKING(if fast termcap-loader is needed)
 656         AC_ARG_ENABLE(getcap,
 657                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 658                 [with_getcap=$enableval],
 659                 [with_getcap=no])
 660         AC_MSG_RESULT($with_getcap)
 661         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
 662
 663         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 664         AC_ARG_ENABLE(getcap-cache,
 665                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 666                 [with_getcap_cache=$enableval],
 667                 [with_getcap_cache=no])
 668         AC_MSG_RESULT($with_getcap_cache)
 669         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
 670
 671 fi
 672 AC_SUBST(NCURSES_USE_TERMCAP)
 673
 674 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 675 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 676 AC_ARG_ENABLE(home-terminfo,
 677         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 678         [with_home_terminfo=$enableval],
 679         [with_home_terminfo=yes])
 680 AC_MSG_RESULT($with_home_terminfo)
 681 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
 682
 683 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 684 AC_ARG_ENABLE(root-environ,
 685         [  --disable-root-environ  restrict environment when running as root],
 686         [with_root_environ=$enableval],
 687         [with_root_environ=yes])
 688 AC_MSG_RESULT($with_root_environ)
 689 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if environment should be restricted for root user])
 690
 691 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 692 ###   to reduce storage requirements for the terminfo database.
 693 CF_LINK_FUNCS
 694
 695 with_links=no
 696 with_symlinks=no
 697
 698 # soft links (symbolic links) are useful for some systems where hard links do
 699 # not work, or to make it simpler to copy terminfo trees around.
 700 if test "x$ac_cv_func_symlink" = xyes ; then
 701     AC_MSG_CHECKING(if tic should use symbolic links)
 702     AC_ARG_ENABLE(symlinks,
 703         [  --enable-symlinks       make tic use symbolic links not hard links],
 704         [with_symlinks=$enableval],
 705         [with_symlinks=no])
 706     AC_MSG_RESULT($with_symlinks)
 707 fi
 708
 709 # If we have hard links and did not choose to use soft links instead, there is
 710 # no reason to make this choice optional - use the hard links.
 711 if test "$with_symlinks" = no ; then
 712     AC_MSG_CHECKING(if tic should use hard links)
 713     if test "x$ac_cv_func_link" = xyes ; then
 714         with_links=yes
 715     else
 716         with_links=no
 717     fi
 718     AC_MSG_RESULT($with_links)
 719 fi
 720
 721 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
 722 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
 723
 724 ###   use option --enable-broken-linker to force on use of broken-linker support
 725 AC_MSG_CHECKING(if you want broken-linker support code)
 726 AC_ARG_ENABLE(broken_linker,
 727         [  --enable-broken_linker  compile with broken-linker support code],
 728         [with_broken_linker=$enableval],
 729         [with_broken_linker=${BROKEN_LINKER:-no}])
 730 AC_MSG_RESULT($with_broken_linker)
 731
 732 BROKEN_LINKER=0
 733 if test "x$with_broken_linker" = xyes ; then
 734         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
 735         BROKEN_LINKER=1
 736 elif test "$DFT_LWR_MODEL" = shared ; then
 737         case $cf_cv_system_name in #(vi
 738         cygwin*)
 739                 AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
 740                 BROKEN_LINKER=1
 741                 CF_VERBOSE(cygwin linker is broken anyway)
 742                 ;;
 743         esac
 744 fi
 745 AC_SUBST(BROKEN_LINKER)
 746
 747 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 748 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 749 AC_ARG_ENABLE(bsdpad,
 750         [  --enable-bsdpad         recognize BSD-style prefix padding],
 751         [with_bsdpad=$enableval],
 752         [with_bsdpad=no])
 753 AC_MSG_RESULT($with_bsdpad)
 754 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
 755
 756 ###   use option --enable-widec to turn on use of wide-character support
 757 NCURSES_CH_T=chtype
 758 NCURSES_LIBUTF8=0
 759
 760 NEED_WCHAR_H=0
 761 NCURSES_MBSTATE_T=0
 762 NCURSES_WCHAR_T=0
 763 NCURSES_WINT_T=0
 764
 765 # Check to define _XOPEN_SOURCE "automatically"
 766 CF_XOPEN_SOURCE(500)
 767
 768 # Work around breakage on OS X
 769 CF_SIGWINCH
 770
 771 # Checks for CODESET support.
 772 AM_LANGINFO_CODESET
 773
 774 # use these variables to work around a defect in gcc's fixincludes.
 775 NCURSES_OK_WCHAR_T=
 776 NCURSES_OK_WINT_T=
 777
 778 AC_MSG_CHECKING(if you want wide-character code)
 779 AC_ARG_ENABLE(widec,
 780         [  --enable-widec          compile with wide-char/UTF-8 code],
 781         [with_widec=$enableval],
 782         [with_widec=no])
 783 AC_MSG_RESULT($with_widec)
 784 if test "x$with_widec" = xyes ; then
 785         if test "x$disable_lib_suffixes" = xno ; then
 786                 LIB_SUFFIX="w${LIB_SUFFIX}"
 787         fi
 788         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
 789         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
 790
 791         CF_CHECK_WCHAR_H
 792
 793         # with_overwrite=no
 794         NCURSES_CH_T=cchar_t
 795         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 796         if test "x$ac_cv_func_putwc" != xyes ; then
 797                 CF_UTF8_LIB
 798                 if test "$cf_cv_utf8_lib" != no ; then
 799                         NCURSES_LIBUTF8=1
 800                 fi
 801         fi
 802         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 803         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 804         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 805
 806         if test "$NCURSES_MBSTATE_T" != 0; then
 807                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
 808         fi
 809 fi
 810 AC_SUBST(NCURSES_CH_T)
 811 AC_SUBST(NCURSES_LIBUTF8)
 812
 813 AC_SUBST(NEED_WCHAR_H)
 814 AC_SUBST(NCURSES_MBSTATE_T)
 815 AC_SUBST(NCURSES_WCHAR_T)
 816 AC_SUBST(NCURSES_WINT_T)
 817
 818 AC_SUBST(NCURSES_OK_WCHAR_T)
 819 AC_SUBST(NCURSES_OK_WINT_T)
 820
 821 ###   use option --disable-lp64 to allow long chtype
 822 case $cf_cv_abi_version in
 823 [[345]]*)
 824         default_with_lp64=no
 825         ;;
 826 *)
 827         default_with_lp64=yes
 828         ;;
 829 esac
 830
 831 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 832 AC_ARG_ENABLE(lp64,
 833         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 834         [with_lp64=$enableval],
 835         [with_lp64=$default_with_lp64])
 836 AC_MSG_RESULT($with_lp64)
 837
 838 if test "x$with_lp64" = xyes ; then
 839         cf_cv_enable_lp64=1
 840 else
 841         cf_cv_enable_lp64=0
 842 fi
 843 AC_SUBST(cf_cv_enable_lp64)
 844
 845 CF_LARGEFILE
 846
 847 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 848 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 849 AC_ARG_ENABLE(tparm-varargs,
 850         [  --disable-tparm-varargs compile tparm() without varargs interface],
 851         [with_tparm_varargs=$enableval],
 852         [with_tparm_varargs=yes])
 853 AC_MSG_RESULT($with_tparm_varargs)
 854 NCURSES_TPARM_VARARGS=0
 855 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
 856 AC_SUBST(NCURSES_TPARM_VARARGS)
 857
 858 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
 859 if test "$with_ticlib" != no ; then
 860 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
 861 AC_ARG_ENABLE(tic-depends,
 862         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
 863         [with_tic_depends=$enableval],
 864         [with_tic_depends=yes])
 865 AC_MSG_RESULT($with_tic_depends)
 866 else
 867         with_tic_depends=no
 868 fi
 869
 870 ###   use option --with-bool to override bool's type
 871 AC_MSG_CHECKING(for type of bool)
 872 AC_ARG_WITH(bool,
 873         [  --with-bool=TYPE        override fallback type of bool variable],
 874         [NCURSES_BOOL="$withval"],
 875         [NCURSES_BOOL=auto])
 876 AC_MSG_RESULT($NCURSES_BOOL)
 877 AC_SUBST(NCURSES_BOOL)
 878
 879 AC_MSG_CHECKING(for alternate terminal capabilities file)
 880 AC_ARG_WITH(caps,
 881         [  --with-caps=alt         compile with alternate Caps file],
 882         [TERMINFO_CAPS=Caps.$withval],
 883         [TERMINFO_CAPS=Caps])
 884 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
 885 AC_MSG_RESULT($TERMINFO_CAPS)
 886 AC_SUBST(TERMINFO_CAPS)
 887
 888 ###   use option --with-chtype to override chtype's type
 889 AC_MSG_CHECKING(for type of chtype)
 890 AC_ARG_WITH(chtype,
 891         [  --with-chtype=TYPE      override type of chtype],
 892         [NCURSES_CHTYPE="$withval"],
 893         [NCURSES_CHTYPE=auto])
 894 AC_MSG_RESULT($NCURSES_CHTYPE)
 895
 896 ###   use option --with-ospeed to override ospeed's type
 897 AC_MSG_CHECKING(for type of ospeed)
 898 AC_ARG_WITH(ospeed,
 899         [  --with-ospeed=TYPE      override type of ospeed variable],
 900         [NCURSES_OSPEED="$withval"],
 901         [NCURSES_OSPEED=short])
 902 AC_MSG_RESULT($NCURSES_OSPEED)
 903 AC_SUBST(NCURSES_OSPEED)
 904
 905 ###   use option --with-mmask-t to override mmask_t's type
 906 AC_MSG_CHECKING(for type of mmask_t)
 907 AC_ARG_WITH(mmask-t,
 908         [  --with-mmask-t=TYPE     override type of mmask_t],
 909         [NCURSES_MMASK_T="$withval"],
 910         [NCURSES_MMASK_T=auto])
 911 AC_MSG_RESULT($NCURSES_MMASK_T)
 912
 913 ###   use option --with-ccharw-max to override CCHARW_MAX size
 914 AC_MSG_CHECKING(for size CCHARW_MAX)
 915 AC_ARG_WITH(ccharw-max,
 916         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
 917         [NCURSES_CCHARW_MAX="$withval"],
 918         [NCURSES_CCHARW_MAX=5])
 919 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
 920 AC_SUBST(NCURSES_CCHARW_MAX)
 921
 922 ###   use option --with-tparm-arg to override tparm's argument type
 923 AC_MSG_CHECKING(for type of tparm args)
 924 AC_ARG_WITH(tparm-arg,
 925         [  --with-tparm-arg=TYPE   override parameter type of tparm],
 926         [NCURSES_TPARM_ARG="$withval"],
 927         [NCURSES_TPARM_ARG=long])
 928 AC_MSG_RESULT($NCURSES_TPARM_ARG)
 929 AC_SUBST(NCURSES_TPARM_ARG)
 930
 931 ### Enable compiling-in rcs id's
 932 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
 933 AC_ARG_WITH(rcs-ids,
 934         [  --with-rcs-ids          compile-in RCS identifiers],
 935         [with_rcs_ids=$withval],
 936         [with_rcs_ids=no])
 937 AC_MSG_RESULT($with_rcs_ids)
 938 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
 939
 940 ###############################################################################
 941 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tabs tic toe tput tset ])
 942
 943 ###############################################################################
 944 CF_HELP_MESSAGE(Extensions:)
 945
 946 ### Note that some functions (such as const) are normally disabled anyway.
 947 AC_MSG_CHECKING(if you want to build with function extensions)
 948 AC_ARG_ENABLE(ext-funcs,
 949         [  --disable-ext-funcs     disable function-extensions],
 950         [with_ext_funcs=$enableval],
 951         [with_ext_funcs=yes])
 952 AC_MSG_RESULT($with_ext_funcs)
 953 if test "x$with_ext_funcs" = xyes ; then
 954         NCURSES_EXT_FUNCS=1
 955         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function])
 956         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function])
 957         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function])
 958         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function])
 959         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function])
 960         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function])
 961         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function])
 962         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function])
 963         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function])
 964         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function])
 965         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
 966         GENERATED_EXT_FUNCS=generated
 967 else
 968         NCURSES_EXT_FUNCS=0
 969         GENERATED_EXT_FUNCS=
 970 fi
 971 AC_SUBST(NCURSES_EXT_FUNCS)
 972 AC_SUBST(GENERATED_EXT_FUNCS)
 973
 974 AC_MSG_CHECKING(if you want to build with experimental SCREEN extensions)
 975 AC_ARG_ENABLE(sp-funcs,
 976         [  --enable-sp-funcs       enable experimental SCREEN-extensions],
 977         [with_sp_funcs=$enableval],
 978         [with_sp_funcs=no])
 979 AC_MSG_RESULT($with_sp_funcs)
 980 if test "x$with_sp_funcs" = xyes ; then
 981         NCURSES_SP_FUNCS=1
 982         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable experimental SCREEN-extensions])
 983         GENERATED_SP_FUNCS=generated
 984 else
 985         NCURSES_SP_FUNCS=0
 986         GENERATED_SP_FUNCS=
 987 fi
 988 AC_SUBST(NCURSES_SP_FUNCS)
 989 AC_SUBST(GENERATED_SP_FUNCS)
 990
 991 AC_MSG_CHECKING(if you want to build with experimental terminal-driver)
 992 AC_ARG_ENABLE(term-driver,
 993         [  --enable-term-driver    enable experimental terminal-driver],
 994         [with_term_driver=$enableval],
 995         [with_term_driver=no])
 996 AC_MSG_RESULT($with_term_driver)
 997 if test "x$with_term_driver" = xyes ; then
 998         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable experimental terminal-driver])
 999         if test "x$with_sp_funcs" != xyes ; then
1000                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
1001         fi
1002 fi
1003
1004 ###   use option --enable-const to turn on use of const beyond that in XSI.
1005 AC_MSG_CHECKING(for extended use of const keyword)
1006 AC_ARG_ENABLE(const,
1007         [  --enable-const          compile with extra/non-standard const],
1008         [with_ext_const=$enableval],
1009         [with_ext_const=no])
1010 AC_MSG_RESULT($with_ext_const)
1011 NCURSES_CONST='/*nothing*/'
1012 if test "x$with_ext_const" = xyes ; then
1013         NCURSES_CONST=const
1014 fi
1015 AC_SUBST(NCURSES_CONST)
1016
1017 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
1018 AC_MSG_CHECKING(if you want to use extended colors)
1019 AC_ARG_ENABLE(ext-colors,
1020         [  --enable-ext-colors     compile for 256-color support],
1021         [with_ext_colors=$enableval],
1022         [with_ext_colors=no])
1023 AC_MSG_RESULT($with_ext_colors)
1024 NCURSES_EXT_COLORS=0
1025 if test "x$with_ext_colors" = xyes ; then
1026         if test "x$with_widec" != xyes ; then
1027                 AC_MSG_ERROR(This option applies only to wide-character library)
1028         else
1029                 # cannot be ABI 5 since it changes sizeof(cchar_t)
1030                 CF_NCURSES_ABI_6
1031         fi
1032         NCURSES_EXT_COLORS=1
1033         AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1034 fi
1035 AC_SUBST(NCURSES_EXT_COLORS)
1036
1037 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1038 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1039 AC_ARG_ENABLE(ext-mouse,
1040         [  --enable-ext-mouse      compile for extended mouse-encoding],
1041         [with_ext_mouse=$enableval],
1042         [with_ext_mouse=no])
1043 AC_MSG_RESULT($with_ext_mouse)
1044 NCURSES_MOUSE_VERSION=1
1045 if test "x$with_ext_mouse" = xyes ; then
1046         NCURSES_MOUSE_VERSION=2
1047         CF_NCURSES_ABI_6
1048 fi
1049 AC_SUBST(NCURSES_MOUSE_VERSION)
1050
1051 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1052 AC_ARG_ENABLE(no-padding,
1053         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1054         [with_no_padding=$enableval],
1055         [with_no_padding=$with_ext_funcs])
1056 AC_MSG_RESULT($with_no_padding)
1057 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1058
1059 AC_CHECK_SIZEOF([signed char], 0)
1060 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1061         NCURSES_SBOOL="signed char"
1062 else
1063         NCURSES_SBOOL="char"
1064 fi
1065 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1066 AC_ARG_ENABLE(signed-char,
1067         [  --enable-signed-char    compile using signed Boolean's in term.h],
1068         [with_signed_char=$enableval],
1069         [with_signed_char=no])
1070 AC_MSG_RESULT($with_signed_char)
1071 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1072 AC_SUBST(NCURSES_SBOOL)
1073
1074 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1075 AC_MSG_CHECKING(if you want SIGWINCH handler)
1076 AC_ARG_ENABLE(sigwinch,
1077         [  --enable-sigwinch       compile with SIGWINCH handler],
1078         [with_sigwinch=$enableval],
1079         [with_sigwinch=$with_ext_funcs])
1080 AC_MSG_RESULT($with_sigwinch)
1081 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1082
1083 ###   use option --enable-tcap-names to allow user to define new capabilities
1084 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1085 AC_ARG_ENABLE(tcap-names,
1086         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1087         [with_tcap_names=$enableval],
1088         [with_tcap_names=$with_ext_funcs])
1089 AC_MSG_RESULT($with_tcap_names)
1090 NCURSES_XNAMES=0
1091 test "x$with_tcap_names" = xyes && NCURSES_XNAMES=1
1092 AC_SUBST(NCURSES_XNAMES)
1093
1094 ###############################################################################
1095 # These options are relatively safe to experiment with.
1096 CF_HELP_MESSAGE(Development Code:)
1097 AC_MSG_CHECKING(if you want all development code)
1098 AC_ARG_WITH(develop,
1099         [  --without-develop       disable development options],
1100         [with_develop=$withval],
1101         [with_develop=no])
1102 AC_MSG_RESULT($with_develop)
1103
1104 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1105 AC_MSG_CHECKING(if you want hard-tabs code)
1106 AC_ARG_ENABLE(hard-tabs,
1107         [  --enable-hard-tabs      compile with hard-tabs code],,
1108         [enable_hard_tabs=$with_develop])
1109 AC_MSG_RESULT($enable_hard_tabs)
1110 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1111
1112 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1113 AC_MSG_CHECKING(if you want limited support for xmc)
1114 AC_ARG_ENABLE(xmc-glitch,
1115         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1116         [enable_xmc_glitch=$with_develop])
1117 AC_MSG_RESULT($enable_xmc_glitch)
1118 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1119
1120 ###############################################################################
1121 # These are just experimental, probably should not be in a package:
1122 CF_HELP_MESSAGE(Experimental Code:)
1123
1124 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1125 AC_ARG_ENABLE(assumed-color,
1126         [  --disable-assumed-color do not assume anything about default-colors],
1127         [with_assumed_color=$enableval],
1128         [with_assumed_color=yes])
1129 AC_MSG_RESULT($with_assumed_color)
1130 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1131
1132 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1133 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1134 AC_ARG_ENABLE(hashmap,
1135         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1136         [with_hashmap=$enableval],
1137         [with_hashmap=yes])
1138 AC_MSG_RESULT($with_hashmap)
1139 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1140
1141 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1142 AC_MSG_CHECKING(if you want colorfgbg code)
1143 AC_ARG_ENABLE(colorfgbg,
1144         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1145         [with_colorfgbg=$enableval],
1146         [with_colorfgbg=no])
1147 AC_MSG_RESULT($with_colorfgbg)
1148 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1149
1150 ###   use option --enable-interop to turn on use of bindings used for interop
1151 AC_MSG_CHECKING(if you want interop bindings)
1152 AC_ARG_ENABLE(interop,
1153         [  --enable-interop        compile-in experimental interop bindings],
1154         [with_exp_interop=$enableval],
1155         [with_exp_interop=no])
1156 AC_MSG_RESULT($with_exp_interop)
1157
1158 NCURSES_INTEROP_FUNCS=0
1159 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1160 AC_SUBST(NCURSES_INTEROP_FUNCS)
1161
1162 # This is still experimental (20080329), but should ultimately be moved to
1163 # the script-block --with-normal, etc.
1164 CF_WITH_PTHREAD
1165
1166 if test "x$with_pthread" != xno; then
1167         AC_CHECK_FUNC(pthread_kill,[
1168                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1169                 AC_ARG_ENABLE(pthreads-eintr,
1170                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1171                         [use_pthreads_eintr=$enableval],
1172                         [use_pthreads_eintr=no])
1173                 AC_MSG_RESULT($use_pthreads_eintr)
1174                 if test "x$use_pthreads_eintr" = xyes ; then
1175                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1176                 fi])
1177
1178         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1179         AC_ARG_ENABLE(weak-symbols,
1180                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1181                 [use_weak_symbols=$enableval],
1182                 [use_weak_symbols=no])
1183         AC_MSG_RESULT($use_weak_symbols)
1184         if test "x$use_weak_symbols" = xyes ; then
1185                 CF_WEAK_SYMBOLS
1186         else
1187                 cf_cv_weak_symbols=no
1188         fi
1189
1190         if test "x$cf_cv_weak_symbols" = xyes ; then
1191                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1192         fi
1193 fi
1194
1195 PTHREAD=
1196 if test "x$with_pthread" = "xyes" ; then
1197     AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1198     enable_reentrant=yes
1199     if test "x$cf_cv_weak_symbols" = xyes ; then
1200         PTHREAD=-lpthread
1201     fi
1202 fi
1203 AC_SUBST(PTHREAD)
1204
1205 # Reentrant code has to be opaque; there's little advantage to making ncurses
1206 # opaque outside of that, so there is no --enable-opaque option.  We can use
1207 # this option without --with-pthreads, but this will be always set for
1208 # pthreads.
1209 AC_MSG_CHECKING(if you want experimental reentrant code)
1210 AC_ARG_ENABLE(reentrant,
1211         [  --enable-reentrant      compile with experimental reentrant code],
1212         [with_reentrant=$enableval],
1213         [with_reentrant=no])
1214 AC_MSG_RESULT($with_reentrant)
1215 if test "x$with_reentrant" = xyes ; then
1216         cf_cv_enable_reentrant=1
1217         cf_cv_enable_opaque="NCURSES_INTERNALS"
1218         NCURSES_OPAQUE=1
1219         NCURSES_SIZE_T=int
1220         if test "x$cf_cv_weak_symbols" = xyes ; then
1221                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1222                 CF_ADD_LIB(pthread,TEST_LIBS)
1223                 CF_ADD_LIB(pthread,TEST_LIBS2)
1224         else
1225                 # when not using weak symbols but with_reentrant,
1226                 # add 't' to the library suffix on all platforms
1227                 # except cygwin, where we only do that if ALSO
1228                 # compiling with full thread support.
1229                 case "$host" in
1230                 *cygwin* | *msys*) #(vi
1231                         if test "$with_pthread" = "yes" ; then
1232                                 if test "x$disable_lib_suffixes" = "xno" ; then
1233                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1234                                 fi
1235                         fi ;;
1236                 *)
1237                         if test "x$disable_lib_suffixes" = "xno" ; then
1238                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1239                         fi
1240                         ;;
1241                 esac
1242         fi
1243         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use experimental reentrant feature])
1244         CF_NCURSES_ABI_6
1245 else
1246         cf_cv_enable_reentrant=0
1247         cf_cv_enable_opaque="NCURSES_OPAQUE"
1248         NCURSES_OPAQUE=0
1249         NCURSES_SIZE_T=short
1250 fi
1251 AC_SUBST(cf_cv_enable_reentrant)
1252 AC_SUBST(cf_cv_enable_opaque)
1253 AC_SUBST(NCURSES_OPAQUE)
1254 AC_SUBST(NCURSES_SIZE_T)
1255
1256 ### Allow using a different wrap-prefix
1257 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1258         AC_MSG_CHECKING(for prefix used to wrap public variables)
1259         AC_ARG_WITH(wrap-prefix,
1260                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1261                 [NCURSES_WRAP_PREFIX=$withval],
1262                 [NCURSES_WRAP_PREFIX=_nc_])
1263         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1264 else
1265         NCURSES_WRAP_PREFIX=_nc_
1266 fi
1267 AC_SUBST(NCURSES_WRAP_PREFIX)
1268 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1269
1270 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1271 AC_ARG_ENABLE(safe-sprintf,
1272         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1273         [with_safe_sprintf=$enableval],
1274         [with_safe_sprintf=no])
1275 AC_MSG_RESULT($with_safe_sprintf)
1276 test "x$with_safe_sprintf" = xyes && AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1277
1278 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1279 # when hashmap is used scroll hints are useless
1280 if test "$with_hashmap" = no ; then
1281 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1282 AC_ARG_ENABLE(scroll-hints,
1283         [  --disable-scroll-hints  compile without scroll-hints code],
1284         [with_scroll_hints=$enableval],
1285         [with_scroll_hints=yes])
1286 AC_MSG_RESULT($with_scroll_hints)
1287 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1288 fi
1289
1290 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1291 AC_ARG_ENABLE(wgetch-events,
1292         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1293         [with_wgetch_events=$enableval],
1294         [with_wgetch_events=no])
1295 AC_MSG_RESULT($with_wgetch_events)
1296 test "x$with_wgetch_events" = xyes && AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with experimental wgetch-events code])
1297
1298 ###############################################################################
1299 CF_HELP_MESSAGE(Testing/development Options:)
1300
1301 ###     use option --disable-echo to suppress full display compiling commands
1302 CF_DISABLE_ECHO
1303 if test "x$enable_echo" = xyes; then
1304         ECHO_LINK=
1305 else
1306         ECHO_LINK='@ echo linking $@ ... ;'
1307         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1308         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1309 fi
1310 AC_SUBST(ECHO_LINK)
1311
1312 ###     use option --enable-warnings to turn on all gcc warnings
1313 AC_MSG_CHECKING(if you want to see compiler warnings)
1314 AC_ARG_ENABLE(warnings,
1315         [  --enable-warnings       build: turn on GCC compiler warnings],
1316         [with_warnings=$enableval])
1317 AC_MSG_RESULT($with_warnings)
1318
1319 if test "x$with_warnings" = "xyes"; then
1320         CF_ADD_ADAFLAGS(-gnatg)
1321         CF_GCC_WARNINGS(Wno-unknown-pragmas Wswitch-enum)
1322         if test "x$cf_with_cxx" = xyes ; then
1323                 CF_GXX_WARNINGS(Wno-unused)
1324         fi
1325 fi
1326 CF_GCC_ATTRIBUTES
1327 CF_ENABLE_STRING_HACKS
1328
1329 ###     use option --enable-assertions to turn on generation of assertion code
1330 AC_MSG_CHECKING(if you want to enable runtime assertions)
1331 AC_ARG_ENABLE(assertions,
1332         [  --enable-assertions     test: turn on generation of assertion code],
1333         [with_assertions=$enableval],
1334         [with_assertions=no])
1335 AC_MSG_RESULT($with_assertions)
1336 if test -n "$GCC"
1337 then
1338         if test "$with_assertions" = no
1339         then
1340                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1341         else
1342                 CF_ADD_ADAFLAGS(-gnata)
1343         fi
1344 fi
1345
1346 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1347 CF_DISABLE_LEAKS
1348 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1349
1350 ###     use option --enable-expanded to generate certain macros as functions
1351 AC_ARG_ENABLE(expanded,
1352         [  --enable-expanded       test: generate functions for certain macros],
1353         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1354
1355 ###     use option --disable-macros to suppress macros in favor of functions
1356 AC_ARG_ENABLE(macros,
1357         [  --disable-macros        test: use functions rather than macros],
1358         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1359
1360 # Normally we only add trace() to the debug-library.  Allow this to be
1361 # extended to all models of the ncurses library:
1362 cf_all_traces=no
1363 case "$CFLAGS $CPPFLAGS" in
1364 *-DTRACE*)
1365         cf_all_traces=yes
1366         ;;
1367 esac
1368
1369 AC_MSG_CHECKING(whether to add trace feature to all models)
1370 AC_ARG_WITH(trace,
1371 [  --with-trace            test: add trace() function to all models of ncurses],
1372 [cf_with_trace=$withval],
1373 [cf_with_trace=$cf_all_traces])
1374 AC_MSG_RESULT($cf_with_trace)
1375
1376 if test "x$cf_with_trace" = xyes ; then
1377         LIB_TRACING=all
1378         ADA_TRACE=TRUE
1379         CF_ADD_CFLAGS(-DTRACE)
1380 else
1381         LIB_TRACING=DEBUG
1382         ADA_TRACE=FALSE
1383 fi
1384
1385 AC_SUBST(ADA_TRACE)
1386
1387 CF_DISABLE_GNAT_PROJECTS
1388
1389 ###     Checks for libraries.
1390 case $cf_cv_system_name in #(vi
1391 *mingw32*) #(vi
1392         CPPFLAGS="$CPPFLAGS -DWINVER=0x0501"
1393         LIBS=" -lpsapi $LIBS"
1394         ;;
1395 *)
1396 AC_CHECK_FUNC(gettimeofday,
1397         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1398
1399 AC_CHECK_LIB(bsd, gettimeofday,
1400         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1401         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1402         ;;
1403 esac
1404
1405 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1406 AC_SUBST(MATH_LIB)
1407
1408 ###     Checks for header files.
1409 AC_STDC_HEADERS
1410 AC_HEADER_DIRENT
1411 AC_HEADER_TIME
1412 CF_REGEX
1413
1414 dnl These are some other potentially nonportable headers.
1415 AC_CHECK_HEADERS( \
1416 fcntl.h \
1417 getopt.h \
1418 limits.h \
1419 locale.h \
1420 math.h \
1421 poll.h \
1422 sys/bsdtypes.h \
1423 sys/ioctl.h \
1424 sys/param.h \
1425 sys/poll.h \
1426 sys/select.h \
1427 sys/time.h \
1428 sys/times.h \
1429 ttyent.h \
1430 unistd.h \
1431 wctype.h \
1432 )
1433
1434 CF_GETOPT_HEADER
1435
1436 # check for ISC (this may also define _POSIX_SOURCE)
1437 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1438 if test "x$ISC" = xyes ; then
1439         AC_CHECK_LIB(cposix,main)
1440         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1441 fi
1442
1443 CF_SYS_TIME_SELECT
1444
1445 ###     checks for compiler characteristics
1446 AC_LANG_C
1447 AC_C_CONST
1448 CF_C_INLINE(NCURSES_INLINE,1200)
1449 CF_SIG_ATOMIC_T
1450
1451 if test $NCURSES_CHTYPE = auto ; then
1452         CF_TYPEOF_CHTYPE
1453 else
1454         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1455 fi
1456 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1457 AC_SUBST(cf_cv_typeof_chtype)
1458
1459 CF_UNSIGNED_LITERALS
1460 cf_cv_1UL="1"
1461 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1462 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1463 AC_SUBST(cf_cv_1UL)
1464
1465 if test $NCURSES_MMASK_T = auto ; then
1466         cf_cv_typeof_mmask_t=long
1467 else
1468         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1469 fi
1470 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1471 AC_SUBST(cf_cv_typeof_mmask_t)
1472
1473 ###     Checks for external-data
1474 CF_ERRNO
1475 CF_LINK_DATAONLY
1476
1477 ###     Checks for library functions.
1478 AC_CHECK_FUNCS( \
1479 getcwd \
1480 getegid \
1481 geteuid \
1482 getttynam \
1483 issetugid \
1484 poll \
1485 putenv \
1486 remove \
1487 select \
1488 setbuf \
1489 setbuffer \
1490 setenv \
1491 setvbuf \
1492 sigaction \
1493 sigvec \
1494 strdup \
1495 strstr \
1496 tcgetpgrp \
1497 times \
1498 vsnprintf \
1499 )
1500 if test "x$with_getcap" = "xyes" ; then
1501         CF_CGETENT
1502 fi
1503
1504 CF_ISASCII
1505 CF_STRUCT_SIGACTION
1506 CF_FUNC_NANOSLEEP
1507 CF_FUNC_TERMIOS
1508 CF_FUNC_VSSCANF
1509 CF_MKSTEMP
1510
1511 # setup for prototype of fallback for vsscanf()
1512 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1513
1514 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1515 if test "x$cross_compiling" = xyes ; then
1516         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1517 else
1518         AC_FUNC_SETVBUF_REVERSED
1519 fi
1520 AC_CHECK_TYPE(intptr_t, long)
1521 CF_TYPE_SIGACTION
1522 CF_SIZECHANGE
1523 CF_FUNC_MEMMOVE
1524 CF_FUNC_POLL
1525 CF_VA_COPY
1526 AC_FUNC_VFORK
1527
1528 # special check for test/ditto.c
1529 CF_FUNC_OPENPTY
1530 if test "$cf_cv_func_openpty" != no ; then
1531     AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1532     AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1533     if test "x$cf_cv_lib_util" = xyes ; then
1534         CF_ADD_LIB(util,TEST_LIBS)
1535     fi
1536 fi
1537 AC_SUBST(TEST_LIBS)
1538 AC_SUBST(TEST_LIBS2)
1539
1540 if test "$with_hashed_db" != no ; then
1541         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1542         CF_HASHED_DB($with_hashed_db)
1543 fi
1544
1545 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1546 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1547         CF_STRIP_G_OPT(CFLAGS)
1548         CF_STRIP_G_OPT(CXXFLAGS)
1549 fi
1550
1551 # Just in case, check if the C compiler has a bool type.
1552 CF_BOOL_DECL(cf_cv_cc_bool_type)
1553
1554 # Check for C++ compiler characteristics (and ensure that it's there!)
1555 if test -n "$CXX" ; then
1556         AC_LANG_CPLUSPLUS
1557         CF_STDCPP_LIBRARY
1558         CF_PROG_CC_C_O(CXX)
1559
1560         case $GXX_VERSION in
1561         1*|2.[0-6]*)
1562                 cf_cxx_library=yes
1563                 ;;
1564         *-2.7*|2.7*)
1565                 CF_GPP_LIBRARY
1566                 ;;
1567         *)
1568                 cf_cxx_library=no
1569                 ;;
1570         esac
1571
1572         AC_CHECK_HEADERS(typeinfo)
1573         CF_CXX_IOSTREAM_NAMESPACE
1574         CF_BOOL_DECL
1575         CF_BOOL_SIZE
1576         CF_ETIP_DEFINES
1577         CF_CPP_PARAM_INIT
1578         CF_CPP_STATIC_CAST
1579         CF_CXX_AR_FLAGS
1580 else
1581         cf_cxx_library=no
1582         cf_cv_builtin_bool=1
1583
1584         # Just because we are not configuring against C++ right now does not
1585         # mean that a user will not want to use C++.  Some distributors disable
1586         # the C++ portion of this configuration as a shortcut (or just to avoid
1587         # compiling the demo in the c++ directory).  So we need a reasonable
1588         # default for the 'bool' type.
1589         #
1590         # Caveat: since the storage of the bool type is not standardized, it
1591         # may change.
1592
1593         if test "$NCURSES_BOOL" != auto ; then
1594                 cf_cv_type_of_bool=$NCURSES_BOOL
1595                 cf_cv_header_stdbool_h=0
1596         else
1597                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1598                         CF_BOOL_SIZE
1599                 else
1600                         AC_MSG_CHECKING(for fallback type of bool)
1601                         case "$host_cpu" in #(vi
1602                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1603                         *)      cf_cv_type_of_bool=int  ;;
1604                         esac
1605                         AC_MSG_RESULT($cf_cv_type_of_bool)
1606                 fi
1607         fi
1608 fi
1609 AC_SUBST(CXXLIBS)
1610
1611 # If the C compiler did not declare bool, and we did not determine that the C++
1612 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1613 # ncurses library use the same type as C++ bool.  Note that this allows one to
1614 # specify the type of bool in a configure-script option and postpone
1615 # integration with the C++ compiler provided that the types are compatible.
1616 USE_CXX_BOOL=1
1617 if test $cf_cv_cc_bool_type = 1
1618 then
1619         # oops: C has a bool.  Unlikely, but C++ could differ.
1620         USE_CXX_BOOL=0
1621 elif test $cf_cv_builtin_bool = 0
1622 then
1623         # C++ has no bool
1624         USE_CXX_BOOL=0
1625 else
1626         # this is the normal case
1627         USE_CXX_BOOL='defined(__cplusplus)'
1628 fi
1629 AC_SUBST(USE_CXX_BOOL)
1630
1631 CF_HELP_MESSAGE(Ada95 Binding Options:)
1632
1633 dnl If the Ada95 source-tree is present, add that to the build unless it will
1634 dnl not work, or was not requested.
1635 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1636
1637 dnl libtool does not know anything about GNAT, though a change made in 1998
1638 dnl provided for it "someday".  Disable the ada subtree if we are using
1639 dnl libtool -TD 20070714
1640         if test "$cf_with_ada" != "no" ; then
1641                 if test "$with_libtool" != "no"; then
1642                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1643                         cf_with_ada=no
1644                 fi
1645         fi
1646
1647 dnl Check for availability of GNU Ada Translator (GNAT).
1648 dnl At the moment we support no other Ada95 compiler.
1649         if test "$cf_with_ada" != "no" ; then
1650                 CF_PROG_GNAT
1651                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
1652                         CF_ADD_ADAFLAGS(-gnatpn)
1653                         CF_FIXUP_ADAFLAGS
1654
1655                         CF_GNATPREP_OPT_T
1656
1657                         CF_GNAT_GENERICS
1658                         CF_GNAT_SIGINT
1659                         CF_GNAT_PROJECTS
1660
1661                         CF_WITH_ADA_COMPILER
1662
1663                         cf_ada_package=terminal_interface
1664                         AC_SUBST(cf_ada_package)
1665
1666                         CF_WITH_ADA_INCLUDE
1667                         CF_WITH_ADA_OBJECTS
1668                         CF_WITH_ADA_SHAREDLIB
1669                 fi
1670         fi
1671 else
1672         cf_with_ada=no
1673 fi
1674
1675 # do this "late" to avoid conflict with header-checks
1676 if test "x$with_widec" = xyes ; then
1677         AC_CHECK_SIZEOF(wchar_t)
1678 fi
1679
1680 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1681 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1682 ###
1683 ### ticlib modules may be a separate library, otherwise contained in termlib.
1684 ### termlib modules may be a separate library, otherwise contained in ncurses.
1685 ###
1686 ### The of "+" or " " between the tokens controls the way the script
1687 ### chooses to split module lists into libraries.
1688 ###
1689 ### (see CF_LIB_RULES).
1690 AC_MSG_CHECKING(for library subsets)
1691 LIB_SUBSETS=
1692
1693 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1694         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1695         if test "$with_ticlib" != no ; then
1696                 LIB_SUBSETS="${LIB_SUBSETS} "
1697         else
1698                 LIB_SUBSETS="${LIB_SUBSETS}+"
1699         fi
1700 fi
1701
1702 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1703 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1704
1705 if test "$with_termlib" != no ; then
1706         LIB_SUBSETS="${LIB_SUBSETS} "
1707 else
1708         LIB_SUBSETS="${LIB_SUBSETS}+"
1709 fi
1710
1711 LIB_SUBSETS="${LIB_SUBSETS}base"
1712
1713 # Most term-driver calls are to tinfo, but some like init_pair are to the
1714 # base library (so it resides in base).
1715 if test "$with_term_driver" != no ; then
1716         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1717         case $cf_cv_system_name in #(vi
1718         *mingw32*) #(vi
1719                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1720                 ;;
1721         *) #(vi
1722                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1723                 ;;
1724         esac
1725 fi
1726
1727 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1728 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1729
1730 AC_MSG_RESULT($LIB_SUBSETS)
1731
1732 ### Construct the list of include-directories to be generated
1733 CF_INCLUDE_DIRS
1734 CF_ADA_INCLUDE_DIRS
1735
1736 ### Build up pieces for makefile rules
1737 AC_MSG_CHECKING(default library suffix)
1738 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1739 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1740 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1741
1742 AC_MSG_CHECKING(default library-dependency suffix)
1743 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1744 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1745 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1746
1747 AC_MSG_CHECKING(default object directory)
1748 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1749 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1750 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1751
1752 if test "x$cf_with_cxx" = xyes ; then
1753 AC_MSG_CHECKING(c++ library-dependency suffix)
1754 if test "$with_libtool" != "no"; then
1755         # libtool thinks it can make c++ shared libraries (perhaps only g++)
1756         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1757 elif test "$with_shared_cxx" != "no"; then
1758         # also for g++ users...
1759         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1760 else
1761         # we normally make a static library because C/C++ library rules differ
1762         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
1763 fi
1764 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1765 AC_SUBST(CXX_LIB_SUFFIX)
1766 fi
1767
1768 # do not want -ldl in build except as needed for -lncurses dependency
1769 if test "x$with_dlsym" = xyes ; then
1770 if test $DFT_LWR_MODEL = shared || \
1771    test $DFT_LWR_MODEL = libtool ; then
1772         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1773 fi
1774 fi
1775 ### Set up low-level terminfo dependencies for makefiles.
1776
1777 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1778 # do not need libdl
1779 TICS_LIST=
1780 if test "x$with_dlsym" = xyes ; then
1781         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1782 fi
1783
1784 if test "$with_ticlib" != no ; then
1785
1786         if test "x$with_ticlib" != xyes ; then
1787                 TICS_NAME=$with_ticlib
1788                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1789                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1790                 TICS_LIB_SUFFIX="${with_ticlib}"
1791         else
1792                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1793                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1794                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1795         fi
1796         TICS_LDFLAGS="-L${LIB_DIR}"
1797         TICS_LIBS="-l${TICS_LIB_SUFFIX}"
1798 else
1799         TICS_LDFLAGS="-L${LIB_DIR}"
1800         TICS_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX}"
1801 fi
1802 AC_SUBST(TICS_ARG_SUFFIX)
1803 AC_SUBST(TICS_DEP_SUFFIX)
1804 AC_SUBST(TICS_LIB_SUFFIX)
1805 AC_SUBST(TICS_LDFLAGS)
1806 AC_SUBST(TICS_LIBS)
1807
1808 if test "$with_termlib" != no ; then
1809
1810         if test "x$with_termlib" != xyes ; then
1811                 TINFO_NAME=$with_termlib
1812                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1813                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1814                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1815                 TINFO_LIB_SUFFIX="${with_termlib}"
1816         else
1817                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1818                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1819                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1820                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1821         fi
1822
1823         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1824         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1825         if test "$DFT_LWR_MODEL" = "libtool"; then
1826                 TEST_ARGS="${TEST_DEPS}"
1827                 TEST_ARG2="${TEST_DEP2}"
1828                 TINFO_LDFLAGS="-L${LIB_DIR}"
1829                 TINFO_LIBS="$TEST_ARGS"
1830                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
1831                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
1832         else
1833                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1834                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1835                 if test "x$with_term_driver" != xno ; then
1836                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1837                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1838                         TINFO_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARGS"
1839                 else
1840                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1841                         TINFO_LIBS="$TEST_ARGS"
1842                 fi
1843                 TINFO_LDFLAGS="-L${LIB_DIR}"
1844                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1845         fi
1846 else
1847         # the next lines are needed for linking libtic over libncurses
1848         TINFO_NAME=${LIB_NAME}
1849         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1850         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1851         if test "x$with_tic_depends" = xyes ; then
1852                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1853         else
1854                 TICS_LIST="$SHLIB_LIST"
1855         fi
1856
1857         TINFO_LDFLAGS="-L${LIB_DIR}"
1858         TINFO_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX}"
1859 fi
1860
1861 if test "$DFT_LWR_MODEL" = shared ; then
1862         case $cf_cv_system_name in #(vi
1863         cygwin*|msys*)
1864                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
1865                 TINFO_SUFFIX=.dll
1866                 ;;
1867         esac
1868 fi
1869
1870 AC_SUBST(TINFO_ARG_SUFFIX)
1871 AC_SUBST(TINFO_DEP_SUFFIX)
1872 AC_SUBST(TINFO_LIB_SUFFIX)
1873 AC_SUBST(TINFO_LDFLAGS)
1874 AC_SUBST(TINFO_LIBS)
1875
1876 if test "x$with_dlsym" = xyes ; then
1877         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1878 fi
1879
1880 if test "$DFT_LWR_MODEL" = "libtool"; then
1881     OBJEXT=lo
1882 fi
1883
1884 # needed for Ada95
1885 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
1886 AC_SUBST(TINFO_LDFLAGS2)
1887
1888 case $DFT_LWR_MODEL in
1889 normal|debug|profile)
1890         CF_LDFLAGS_STATIC
1891         ;;
1892 esac
1893
1894 AC_MSG_CHECKING(where we will install curses.h)
1895 AC_SUBST(includesubdir)
1896 includesubdir=
1897 if test "$with_overwrite" = no && \
1898  ( test "x$includedir" = 'x${prefix}/include' || \
1899    test "x$includedir" = "x${prefix}/include" )
1900 then
1901         includesubdir="/ncurses${LIB_SUFFIX}"
1902 fi
1903 AC_MSG_RESULT(${includedir}${includesubdir})
1904
1905 ### Resolve a conflict between normal and wide-curses by forcing applications
1906 ### that will need libutf8 to add it to their configure script.
1907 if test "$with_overwrite" != no ; then
1908 if test "$NCURSES_LIBUTF8" = 1 ; then
1909         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1910         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1911 fi
1912 fi
1913 WITH_OVERWRITE=$with_overwrite
1914
1915 AC_SUBST(WITH_OVERWRITE)
1916 AC_SUBST(TICS_LIST)
1917 AC_SUBST(TINFO_LIST)
1918 AC_SUBST(SHLIB_LIST)
1919
1920 # used to separate tack out of the tree
1921 NCURSES_TREE=
1922 AC_SUBST(NCURSES_TREE)
1923
1924 ### predefined stuff for the test programs
1925 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
1926
1927 ### Construct the list of subdirectories for which we'll customize makefiles
1928 ### with the appropriate compile-rules.
1929
1930 CF_SRC_MODULES($modules_to_build)
1931
1932 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
1933    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${DFT_ARG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
1934    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${DFT_ARG_SUFFIX}-config.1:man/MKada_config.in"
1935 fi
1936
1937 CF_DIRS_TO_MAKE
1938
1939 # symbols that differ when compiling Ada95 by itself.
1940 NCURSES_SHLIB2='sh $(top_srcdir)/misc/shlib'
1941 AC_SUBST(NCURSES_SHLIB2)
1942
1943 # values to use as strings
1944 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
1945
1946 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
1947
1948 ### Now that we're done running tests, add the compiler-warnings, if any
1949 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1950
1951 ### Define substitutions for header files to avoid name-pollution
1952 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
1953 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
1954 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
1955 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
1956
1957 ################################################################################
1958 test "x$use_database" = xyes && \
1959 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1960
1961 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1962 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${DFT_ARG_SUFFIX}${cf_cv_abi_version}-config.1:man/MKncu_config.in"
1963
1964 if test "x$enable_pc_files" = xyes ; then \
1965 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
1966 MAKE_PC_FILES=
1967 else
1968 MAKE_PC_FILES="#"
1969 fi
1970 AC_SUBST(MAKE_PC_FILES)
1971 AC_SUBST(cross_compiling)
1972
1973 AC_PATH_PROG(TIC_PATH,tic,unknown,$PATH:/usr/local/ncurses/bin)
1974 if test -n "$FALLBACK_LIST"
1975 then
1976         if test "$TIC_PATH" = unknown
1977         then
1978                 AC_MSG_WARN(no tic program found for fallbacks)
1979         fi
1980 fi
1981 AC_SUBST(TIC_PATH)
1982
1983 if test "x$cf_with_tests" != xno ; then
1984         MAKE_TESTS=
1985 else
1986         MAKE_TESTS="#"
1987 fi
1988 AC_SUBST(MAKE_TESTS)
1989
1990 ADAHTML_DIR=../../doc/html/ada
1991 AC_SUBST(ADAHTML_DIR)
1992
1993 # these could be configurable, but are not currently
1994 PANEL_NAME=panel
1995 MENU_NAME=menu
1996 FORM_NAME=form
1997 CXX_NAME=ncurses++
1998
1999 AC_SUBST(PANEL_NAME)
2000 AC_SUBST(MENU_NAME)
2001 AC_SUBST(FORM_NAME)
2002 AC_SUBST(CXX_NAME)
2003
2004 # workaround for g++ versus Solaris (20131116)
2005 case $cf_cv_system_name in #(vi
2006 solaris2*) #(vi
2007         case "x$CPPFLAGS" in #(vi
2008         *-D_XOPEN_SOURCE_EXTENDED*)
2009                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
2010                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
2011                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
2012                 ;;
2013         esac
2014         ;;
2015 esac
2016
2017 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
2018 case "x$NCURSES_OSPEED" in #(vi
2019 *short*) #(vi
2020         cf_compatible=1
2021         ;;
2022 *)
2023         cf_compatible=0
2024         ;;
2025 esac
2026 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
2027
2028 case "x$cf_cv_typeof_chtype" in
2029 xshort|xint|xlong)
2030         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
2031         ;;
2032 esac
2033
2034 case "x$cf_cv_typeof_mmask_t" in
2035 xshort|xint|xlong)
2036         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2037         ;;
2038 esac
2039
2040 SUB_SCRIPTS=
2041
2042 AC_OUTPUT( \
2043         include/MKterm.h.awk \
2044         include/curses.head:include/curses.h.in \
2045         include/ncurses_dll.h \
2046         include/termcap.h \
2047         include/unctrl.h \
2048         $SUB_SCRIPTS \
2049         $SUB_MAKEFILES \
2050         Makefile,[
2051 if test "x$cf_with_tests" != xno ; then
2052         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2053 fi
2054 CF_LIB_RULES($SRC_SUBDIRS)
2055
2056 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2057 if test -z "$USE_OLD_MAKERULES" ; then
2058         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
2059 fi
2060 fi
2061 ],[
2062 ### Special initialization commands, used to pass information from the
2063 ### configuration-run into config.status
2064
2065 AWK="$AWK"
2066 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2067 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2068 ECHO_LD="$ECHO_LD"
2069 LDCONFIG="$LDCONFIG"
2070 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2071 LIB_NAME="$LIB_NAME"
2072 LIB_PREFIX="$LIB_PREFIX"
2073 LIB_SUBSETS="$LIB_SUBSETS"
2074 LIB_SUFFIX="$LIB_SUFFIX"
2075 LIB_TRACING="$LIB_TRACING"
2076 LN_S="$LN_S"
2077 MAKE_TERMINFO="$MAKE_TERMINFO"
2078 NCURSES_MAJOR="$NCURSES_MAJOR"
2079 NCURSES_MINOR="$NCURSES_MINOR"
2080 NCURSES_OSPEED="$NCURSES_OSPEED"
2081 NCURSES_PATCH="$NCURSES_PATCH"
2082 SRC_SUBDIRS="$SRC_SUBDIRS"
2083 TERMINFO="$TERMINFO"
2084 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2085 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2086 TICS_NAME="$TICS_NAME"
2087 TIC_PATH="$TIC_PATH"
2088 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2089 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2090 TINFO_NAME="$TINFO_NAME"
2091 TINFO_SUFFIX="$TINFO_SUFFIX"
2092 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2093 WITH_CURSES_H="$with_curses_h"
2094 WITH_ECHO="${enable_echo:=yes}"
2095 WITH_OVERWRITE="$with_overwrite"
2096 cf_LIST_MODELS="$cf_list_models"
2097 cf_cv_abi_version="$cf_cv_abi_version"
2098 cf_cv_do_relink="$cf_cv_do_relink"
2099 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2100 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2101 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2102 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2103 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2104 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2105 cf_cv_rel_version="$cf_cv_rel_version"
2106 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2107 cf_cv_shared_soname='$cf_cv_shared_soname'
2108 cf_cv_shlib_version="$cf_cv_shlib_version"
2109 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2110 cf_cv_system_name="$cf_cv_system_name"
2111 cf_cv_term_driver="$with_term_driver"
2112 cf_with_ada="$cf_with_ada"
2113 cf_with_cxx_binding="$cf_with_cxx_binding"
2114 cf_with_db_install="$cf_with_db_install"
2115 cf_with_manpages="$cf_with_manpages"
2116 cf_with_tests="$cf_with_tests"
2117 with_shared_cxx="$with_shared_cxx"
2118 host="$host"
2119 target="$target"
2120
2121 ],cat)dnl
2122 ${MAKE:-make} preinstall