71362382c3da0597b5ef7a8374a73c68cc2e3df1
[ncurses.git] / configure.in
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2014,2015 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1995-on
30 dnl
31 dnl $Id: configure.in,v 1.611 2015/04/18 17:26:15 tom Exp $
32 dnl Process this file with autoconf to produce a configure script.
33 dnl
34 dnl See http://invisible-island.net/autoconf/ for additional information.
35 dnl
36 dnl ---------------------------------------------------------------------------
37 AC_PREREQ(2.52.20030208)
38 AC_REVISION($Revision: 1.611 $)
39 AC_INIT(ncurses/base/lib_initscr.c)
40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
41
42 CF_TOP_BUILDDIR
43 CF_SUBST_NCURSES_VERSION
44 CF_VERSION_INFO(NCURSES,ncurses)
45
46 CF_WITH_REL_VERSION(NCURSES)
47 CF_WITH_ABI_VERSION
48
49 CF_WITH_SYSTYPE
50
51 ###     Save the given $CFLAGS to allow user-override.
52 cf_user_CFLAGS="$CFLAGS"
53
54 ###     Default install-location
55 CF_CFG_DEFAULTS
56
57 ###     Checks for programs.
58 AC_ARG_WITH(ada,
59         [  --without-ada           suppress check for Ada95, don't build demo],
60         [cf_with_ada=$withval],
61         [cf_with_ada=yes])
62 if test "x$cf_with_ada" = xyes
63 then
64         cf_PROG_CC="gnatgcc gcc cc"
65 else
66         cf_PROG_CC="gcc cc"
67 fi
68
69 CF_PROG_CC($cf_PROG_CC)
70
71 AC_PROG_CPP
72 AC_PROG_GCC_TRADITIONAL
73 CF_PROG_CC_C_O(CC)
74 CF_PROG_LDCONFIG
75
76 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
77 dnl                             configure script by not letting us test if C++
78 dnl                             is present, making this option necessary.
79 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
80 AC_ARG_WITH(cxx,
81         [  --without-cxx           do not adjust ncurses bool to match C++],
82         [cf_with_cxx=$withval],
83         [cf_with_cxx=yes])
84 AC_MSG_RESULT($cf_with_cxx)
85 if test "X$cf_with_cxx" = Xno ; then
86         CXX=""
87         GXX=""
88 else
89         # with autoconf 2.13, we can change the error to a warning:
90         pushdef([AC_MSG_ERROR],
91                 [AC_MSG_RESULT(no)
92                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
93                 cf_with_cxx=no; CXX=""; GXX="";])dnl
94         AC_PROG_CXX
95         popdef([AC_MSG_ERROR])dnl
96
97         AC_LANG_PUSH(C++)
98         if test "x$cf_with_cxx" != xno
99         then
100                 # Several of the C++ configurations do not work, particularly when
101                 # cross-compiling (20140913 -TD)
102                 AC_MSG_CHECKING(if $CXX works)
103
104                 save_CPPFLAGS="$CPPFLAGS"
105                 eval cf_includedir=${includedir}
106                 CPPFLAGS="$CPPFLAGS -I${cf_includedir}"
107                 AC_TRY_COMPILE([
108 #include <stdlib.h>
109 #include <stdio.h>
110 ],
111                 [
112                 printf("Hello world!\n")
113                 ],
114                 [cf_cxx_works=yes],
115                 [cf_cxx_works=no])
116                 CPPFLAGS="$save_CPPFLAGS"
117
118                 AC_MSG_RESULT($cf_cxx_works)
119                 if test "x$cf_cxx_works" = xno
120                 then
121                         AC_MSG_WARN([Ignore $CXX, since it cannot compile hello-world.])
122                         cf_with_cxx=no; CXX=""; GXX="";
123                 fi
124         fi
125         AC_LANG_POP
126
127         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
128         if test "$CXX" = "g++" ; then
129                 AC_PATH_PROG(CXX,g++)
130         fi
131         case "x$CXX" in
132         (x|xg++)
133                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
134                 cf_with_cxx=no; CXX=""; GXX="";
135                 ;;
136         esac
137 fi
138
139 CF_GXX_VERSION
140 case $GXX_VERSION in
141 (1*|2.[[0-6]]*)
142         # GXX=""; CXX=""; ac_cv_prog_gxx=no
143         # cf_cxx_library=no
144         AC_MSG_WARN(templates do not work)
145         ;;
146 esac
147
148 AC_MSG_CHECKING(if you want to build C++ binding and demo)
149 AC_ARG_WITH(cxx-binding,
150         [  --without-cxx-binding   do not build C++ binding and demo],
151         [cf_with_cxx_binding=$withval],
152         [cf_with_cxx_binding=$cf_with_cxx])
153 AC_MSG_RESULT($cf_with_cxx_binding)
154
155 AC_MSG_CHECKING(if you want to build with Ada95)
156 AC_MSG_RESULT($cf_with_ada)
157
158 AC_MSG_CHECKING(if you want to install terminal database)
159 AC_ARG_ENABLE(db-install,
160         [  --disable-db-install    suppress install of terminal database],
161         [cf_with_db_install=$enableval],
162         [cf_with_db_install=yes])
163 AC_MSG_RESULT($cf_with_db_install)
164
165 AC_MSG_CHECKING(if you want to install manpages)
166 AC_ARG_WITH(manpages,
167         [  --without-manpages      suppress install of manpages],
168         [cf_with_manpages=$withval],
169         [cf_with_manpages=yes])
170 AC_MSG_RESULT($cf_with_manpages)
171
172 AC_MSG_CHECKING(if you want to build programs such as tic)
173 AC_ARG_WITH(progs,
174         [  --without-progs         suppress build/install with programs (e.g., tic)],
175         [cf_with_progs=$withval],
176         [cf_with_progs=yes])
177 AC_MSG_RESULT($cf_with_progs)
178
179 AC_MSG_CHECKING(if you want to build test-programs)
180 AC_ARG_WITH(tests,
181         [  --without-tests         suppress build/install with test-programs],
182         [cf_with_tests=$withval],
183         [cf_with_tests=yes])
184 AC_MSG_RESULT($cf_with_tests)
185
186 AC_MSG_CHECKING(if you wish to install curses.h)
187 AC_ARG_WITH(curses-h,
188         [  --without-curses-h      install curses.h as ncurses.h only],
189         [with_curses_h=$withval],
190         [with_curses_h=yes])
191 AC_MSG_RESULT($with_curses_h)
192
193 modules_to_build="ncurses"
194 if test "X$cf_with_progs" != Xno ; then
195 modules_to_build="$modules_to_build progs tack"
196 fi
197 modules_to_build="$modules_to_build panel menu form"
198
199 AC_ARG_PROGRAM
200
201 CF_PROG_AWK
202 CF_PROG_EGREP
203 CF_PROG_INSTALL
204 CF_PROG_LINT
205 CF_PROG_LN_S
206
207 AC_SYS_LONG_FILE_NAMES
208
209 # if we find pkg-config, check if we should install the ".pc" files.
210 CF_PKG_CONFIG
211 CF_WITH_PKG_CONFIG_LIBDIR
212 CF_ENABLE_PC_FILES
213 if test -z "$MAKE_PC_FILES"
214 then
215         AC_MSG_CHECKING(for suffix to add to pc-files)
216 AC_ARG_WITH(pc-suffix,
217         [  --with-pc-suffix        suffixes pc-files],
218         [case "x$withval" in
219         (xyes|xno)
220                 PC_MODULE_SUFFIX=
221                 ;;
222         (*)     PC_MODULE_SUFFIX="$withval"
223                 ;;
224         esac])
225         test -z "$PC_MODULE_SUFFIX" && PC_MODULE_SUFFIX=none
226         AC_MSG_RESULT($PC_MODULE_SUFFIX)
227         test "$PC_MODULE_SUFFIX" = none && PC_MODULE_SUFFIX=
228         AC_SUBST(PC_MODULE_SUFFIX)
229 fi
230
231 AC_MSG_CHECKING(if we should assume mixed-case filenames)
232 AC_ARG_ENABLE(mixed-case,
233         [  --enable-mixed-case     tic should assume mixed-case filenames],
234         [enable_mixedcase=$enableval],
235         [enable_mixedcase=auto])
236 AC_MSG_RESULT($enable_mixedcase)
237 if test "$enable_mixedcase" = "auto" ; then
238         CF_MIXEDCASE_FILENAMES
239 else
240         cf_cv_mixedcase=$enable_mixedcase
241         if test "x$enable_mixedcase" = "xyes" ; then
242                 AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
243         fi
244 fi
245
246 # do this after mixed-case option (tags/TAGS is not as important as tic).
247 AC_PROG_MAKE_SET
248 CF_MAKE_TAGS
249 CF_MAKEFLAGS
250
251 dnl These are standard among *NIX systems, but not when cross-compiling
252 AC_CHECK_TOOL(RANLIB, ranlib, ':')
253 AC_CHECK_TOOL(LD, ld, ld)
254 AC_CHECK_TOOL(AR, ar, ar)
255 AC_CHECK_TOOL(NM, nm, nm)
256 CF_AR_FLAGS
257
258 dnl Special option for use by system-builders: the install-prefix is used to
259 dnl adjust the location into which the actual install is done, so that an
260 dnl archive can be built without modifying the host system's configuration.
261 AC_MSG_CHECKING(if you have specified an install-prefix)
262 AC_ARG_WITH(install-prefix,
263         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
264         [case "x$withval" in
265         (xyes|xno)
266                 ;;
267         (*)     DESTDIR="$withval"
268                 ;;
269         esac])
270 AC_MSG_RESULT($DESTDIR)
271 AC_SUBST(DESTDIR)
272
273 ###############################################################################
274 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
275 # If we're cross-compiling, allow the user to override the tools and their
276 # options.  The configure script is oriented toward identifying the host
277 # compiler, etc., but we need a build compiler to generate parts of the source.
278 CF_BUILD_CC
279
280 ###############################################################################
281 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
282
283 ### Options to allow the user to specify the set of libraries which are used.
284 ### Use "--without-normal --with-shared" to allow the default model to be
285 ### shared, for example.
286 cf_list_models=""
287 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
288
289 CF_WITH_LIBTOOL
290 if test "$with_libtool" != "no" ; then
291
292 cf_list_models="$cf_list_models libtool"
293
294 else
295
296 AC_MSG_CHECKING(if you want to build shared libraries)
297 AC_ARG_WITH(shared,
298         [  --with-shared           generate shared-libraries],
299         [with_shared=$withval],
300         [with_shared=no])
301 AC_MSG_RESULT($with_shared)
302 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
303
304 AC_MSG_CHECKING(if you want to build static libraries)
305 AC_ARG_WITH(normal,
306         [  --with-normal           generate normal-libraries (default)],
307         [with_normal=$withval],
308         [with_normal=yes])
309 AC_MSG_RESULT($with_normal)
310 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
311
312 AC_MSG_CHECKING(if you want to build debug libraries)
313 AC_ARG_WITH(debug,
314         [  --with-debug            generate debug-libraries (default)],
315         [with_debug=$withval],
316         [with_debug=yes])
317 AC_MSG_RESULT($with_debug)
318 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
319
320 AC_MSG_CHECKING(if you want to build profiling libraries)
321 AC_ARG_WITH(profile,
322         [  --with-profile          generate profile-libraries],
323         [with_profile=$withval],
324         [with_profile=no])
325 AC_MSG_RESULT($with_profile)
326 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
327
328 fi
329
330 if test "X$cf_with_cxx_binding" != Xno; then
331 if test "x$with_shared" = "xyes"; then
332 AC_MSG_CHECKING(if you want to build C++ shared libraries)
333 AC_ARG_WITH(cxx-shared,
334         [  --with-cxx-shared       generate C++ shared-libraries],
335         [with_shared_cxx=$withval],
336         [with_shared_cxx=no])
337 AC_MSG_RESULT($with_shared_cxx)
338 fi
339 fi
340
341 ###############################################################################
342
343 AC_MSG_CHECKING(for specified models)
344 test -z "$cf_list_models" && cf_list_models=normal
345 dnl If we use libtool to generate libraries, then it must be the only
346 dnl specified model.
347 test "$with_libtool" != "no" && cf_list_models=libtool
348 AC_MSG_RESULT($cf_list_models)
349
350 ### Use the first model as the default, and save its suffix for use in building
351 ### up test-applications.
352 AC_MSG_CHECKING(for default model)
353 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
354 AC_MSG_RESULT($DFT_LWR_MODEL)
355
356 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
357
358 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
359 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
360
361 TICS_NAME=tic
362 AC_SUBST(TICS_NAME)
363
364 TINFO_NAME=tinfo
365 AC_SUBST(TINFO_NAME)
366
367 LIB_NAME=ncurses
368 AC_SUBST(LIB_NAME)
369
370 LIB_DIR=../lib
371 LIB_2ND=../../lib
372
373 CF_WITH_LIB_PREFIX(cf_prefix)
374
375 LIB_SUFFIX=
376 AC_SUBST(LIB_SUFFIX)
377 CF_PATHSEP
378
379 ###############################################################################
380
381 AC_MSG_CHECKING(if you want to build a separate terminfo library)
382 AC_ARG_WITH(termlib,
383         [  --with-termlib          generate separate terminfo library],
384         [with_termlib=$withval],
385         [with_termlib=no])
386 AC_MSG_RESULT($with_termlib)
387
388 AC_MSG_CHECKING(if you want to build a separate tic library)
389 AC_ARG_WITH(ticlib,
390         [  --with-ticlib           generate separate tic library],
391         [with_ticlib=$withval],
392         [with_ticlib=no])
393 AC_MSG_RESULT($with_ticlib)
394
395 ### Checks for special libraries, must be done up-front.
396 SHLIB_LIST=""
397 CF_WITH_GPM
398 if test "$with_gpm" != no ; then
399         AC_MSG_CHECKING(if you want to load GPM dynamically)
400         AC_ARG_WITH(dlsym,
401                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
402                 [with_dlsym=$withval],
403                 [with_dlsym=yes])
404         AC_MSG_RESULT($with_dlsym)
405         if test "x$with_dlsym" = xyes ; then
406                 CF_FUNC_DLSYM
407                 if test "x$with_gpm" != xyes ; then
408                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
409                         cf_cv_gpm_soname="$with_gpm"
410                 else
411                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
412                 fi
413                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
414                 SHLIB_LIST="-ldl $SHLIB_LIST"
415         else
416                 SHLIB_LIST="-lgpm $SHLIB_LIST"
417                 CF_ADD_LIB(gpm,TEST_LIBS)
418         fi
419         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
420         CF_CHECK_GPM_WGETCH
421 fi
422
423 CF_WITH_SYSMOUSE
424
425 dnl Not all ports of gcc support the -g option
426
427 if test X"$CC_G_OPT" = X"" ; then
428         CC_G_OPT='-g'
429         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
430 fi
431 AC_SUBST(CC_G_OPT)
432
433 if test X"$CXX_G_OPT" = X"" ; then
434         CXX_G_OPT='-g'
435         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
436 fi
437 AC_SUBST(CXX_G_OPT)
438
439 AC_MSG_CHECKING(for default loader flags)
440 case $DFT_LWR_MODEL in
441 (libtool) LD_MODEL=''   ;;
442 (normal)  LD_MODEL=''   ;;
443 (debug)   LD_MODEL=$CC_G_OPT ;;
444 (profile) LD_MODEL='-pg';;
445 (shared)  LD_MODEL=''   ;;
446 esac
447 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
448 AC_MSG_RESULT($LD_MODEL)
449
450 case $DFT_LWR_MODEL in
451 (shared)
452 CF_ENABLE_RPATH
453 AC_MSG_CHECKING(if shared libraries should be relinked during install)
454 AC_ARG_ENABLE(relink,
455 [  --disable-relink        relink shared libraries during install],
456 [cf_cv_do_relink=$enableval],
457 [cf_cv_do_relink=yes])
458 AC_MSG_RESULT($cf_cv_do_relink)
459         ;;
460 esac
461
462 # we will build libraries one-level down.
463 rel_builddir=..
464 CF_SHARED_OPTS
465 for model in $cf_list_models; do
466         case $model in
467         (libtool)
468                 CF_WITH_LIBTOOL_OPTS
469                 CF_WITH_EXPORT_SYMS
470                 ;;
471         (shared)
472                 if test "$CC_SHARED_OPTS" = "unknown"; then
473                         AC_ERROR(Shared libraries are not supported in this version)
474                 fi
475                 CF_WITH_VERSIONED_SYMS
476                 ;;
477         esac
478 done
479
480 # pretend that ncurses==ncursesw==ncursest
481 AC_MSG_CHECKING(if you want to disable library suffixes)
482 CF_ARG_DISABLE(lib-suffixes,
483         [  --disable-lib-suffixes  disable library suffixes],
484         [disable_lib_suffixes=yes],
485         [disable_lib_suffixes=no],
486         no)
487 AC_MSG_RESULT($disable_lib_suffixes)
488
489 ### If we're building with rpath, try to link non-standard libs that way too.
490 if test "$DFT_LWR_MODEL" = "shared"; then
491         CF_DISABLE_RPATH_HACK
492 fi
493
494 ###############################################################################
495 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
496
497 ###     use option --with-extra-suffix to append suffix to headers and libraries
498 AC_MSG_CHECKING(if you wish to append extra suffix to header/library paths)
499 EXTRA_SUFFIX=
500 AC_ARG_WITH(extra-suffix,
501         [  --with-extra-suffix=X   append extra suffix to header/library paths],
502         [case x$withval in
503         (no)
504                 ;;
505         (xyes|x)
506                 EXTRA_SUFFIX=$cf_cv_abi_version
507                 ;;
508         (*)
509                 EXTRA_SUFFIX=$withval
510                 ;;
511         esac
512         ])
513 AC_MSG_RESULT($EXTRA_SUFFIX)
514 AC_SUBST(EXTRA_SUFFIX)
515
516 ###     use option --disable-overwrite to leave out the link to -lcurses
517 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
518 AC_ARG_ENABLE(overwrite,
519         [  --disable-overwrite     put headers in subdir, omit link to -lcurses],
520         [with_overwrite=$enableval],
521         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
522 AC_MSG_RESULT($with_overwrite)
523
524 AC_MSG_CHECKING(if external terminfo-database is used)
525 AC_ARG_ENABLE(database,
526         [  --disable-database      do not use terminfo, only fallbacks/termcap],
527         [use_database=$enableval],
528         [use_database=yes])
529 AC_MSG_RESULT($use_database)
530
531 case $host_os in
532 (os2*)
533         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
534         ;;
535 (*)
536         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
537         ;;
538 esac
539 AC_SUBST(TERMINFO_SRC)
540
541 NCURSES_USE_DATABASE=0
542 if test "$use_database" != no ; then
543         NCURSES_USE_DATABASE=1
544
545         AC_MSG_CHECKING(which terminfo source-file will be installed)
546         AC_ARG_WITH(database,
547                 [  --with-database=XXX     specify terminfo source to install],
548                 [TERMINFO_SRC=$withval])
549         AC_MSG_RESULT($TERMINFO_SRC)
550
551         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
552         AC_ARG_WITH(hashed-db,
553                 [  --with-hashed-db        specify hashed-database library],,
554                 [with_hashed_db=no])
555         AC_MSG_RESULT($with_hashed_db)
556 else
557         with_hashed_db=no
558 fi
559 AC_SUBST(NCURSES_USE_DATABASE)
560
561 AC_MSG_CHECKING(for list of fallback descriptions)
562 AC_ARG_WITH(fallbacks,
563         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
564         [with_fallback=$withval],
565         [with_fallback=])
566 AC_MSG_RESULT($with_fallback)
567 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
568 AC_SUBST(FALLBACK_LIST)
569
570 AC_MSG_CHECKING(if you want modern xterm or antique)
571 AC_ARG_WITH(xterm-new,
572         [  --without-xterm-new     specify if xterm terminfo should be old version],
573         [with_xterm_new=$withval],
574         [with_xterm_new=yes])
575 case $with_xterm_new in
576 (no) with_xterm_new=xterm-old;;
577 (*)      with_xterm_new=xterm-new;;
578 esac
579 AC_MSG_RESULT($with_xterm_new)
580 WHICH_XTERM=$with_xterm_new
581 AC_SUBST(WHICH_XTERM)
582
583 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
584 AC_ARG_WITH(xterm-kbs,
585         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
586         [with_xterm_kbs=$withval],
587         [with_xterm_kbs=BS])
588 case x$with_xterm_kbs in
589 (xyes|xno|xBS|xbs|x8)
590         with_xterm_kbs=BS
591         ;;
592 (xDEL|xdel|x127)
593         with_xterm_kbs=DEL
594         ;;
595 (*)
596         with_xterm_kbs=$withval
597         ;;
598 esac
599 AC_MSG_RESULT($with_xterm_kbs)
600 XTERM_KBS=$with_xterm_kbs
601 AC_SUBST(XTERM_KBS)
602
603 MAKE_TERMINFO=
604 if test "$use_database" = no ; then
605         TERMINFO="${datadir}/terminfo"
606         MAKE_TERMINFO="#"
607 else
608
609 AC_MSG_CHECKING(for list of terminfo directories)
610 CF_WITH_PATHLIST(terminfo-dirs,
611         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
612         TERMINFO_DIRS,
613         DATADIR/terminfo,
614         ${datadir}/terminfo)
615 AC_MSG_RESULT($TERMINFO_DIRS)
616 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
617
618 AC_MSG_CHECKING(for default terminfo directory)
619 CF_WITH_PATH(default-terminfo-dir,
620         [  --with-default-terminfo-dir=DIR default terminfo directory],
621         TERMINFO,
622         DATADIR/terminfo,
623         ${datadir}/terminfo)
624 AC_MSG_RESULT($TERMINFO)
625 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
626
627 fi
628
629 AC_SUBST(TERMINFO)
630 AC_SUBST(MAKE_TERMINFO)
631
632 ###     use option --disable-big-core to make tic run on small machines
633 ###     We need 4Mb, check if we can allocate 50% more than that.
634 AC_MSG_CHECKING(if big-core option selected)
635 AC_ARG_ENABLE(big-core,
636         [  --disable-big-core      assume machine has little memory],
637         [with_big_core=$enableval],
638         [AC_TRY_RUN([
639 #include <stdlib.h>
640 #include <string.h>
641 int main() {
642         unsigned long n = 6000000L;
643         char *s = malloc(n);
644         if (s != 0)
645                 s[0] = s[n-1] = 0;
646         ${cf_cv_main_return:-return}(s == 0);
647 }],
648         [with_big_core=yes],
649         [with_big_core=no],
650         [with_big_core=no])])
651 AC_MSG_RESULT($with_big_core)
652 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
653
654 ### ISO C only guarantees 512-char strings, we have tables which load faster
655 ### when constructed using "big" strings.  More than the C compiler, the awk
656 ### program is a limit on most vendor UNIX systems.  Check that we can build.
657 AC_MSG_CHECKING(if big-strings option selected)
658 AC_ARG_ENABLE(big-strings,
659         [  --disable-big-strings   assume compiler has only standard-size strings],
660         [with_big_strings=$enableval],
661         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
662 AC_MSG_RESULT($with_big_strings)
663
664 USE_BIG_STRINGS=0
665 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
666 AC_SUBST(USE_BIG_STRINGS)
667
668 ###     use option --enable-termcap to compile in the termcap fallback support
669 AC_MSG_CHECKING(if you want termcap-fallback support)
670 AC_ARG_ENABLE(termcap,
671         [  --enable-termcap        compile in termcap fallback support],
672         [with_termcap=$enableval],
673         [with_termcap=no])
674 AC_MSG_RESULT($with_termcap)
675
676 NCURSES_USE_TERMCAP=0
677 if test "x$with_termcap" != "xyes" ; then
678         if test "$use_database" = no ; then
679                 if test -z "$with_fallback" ; then
680                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
681                 fi
682         fi
683         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
684 else
685
686         if test "$with_ticlib" != no ; then
687                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
688         fi
689
690         NCURSES_USE_TERMCAP=1
691         AC_MSG_CHECKING(for list of termcap files)
692         CF_WITH_PATHLIST(termpath,
693                 [  --with-termpath=XXX     specify list of termcap files],
694                 TERMPATH,
695                 /etc/termcap:/usr/share/misc/termcap)
696         AC_MSG_RESULT($TERMPATH)
697         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
698
699         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
700         AC_MSG_CHECKING(if fast termcap-loader is needed)
701         AC_ARG_ENABLE(getcap,
702                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
703                 [with_getcap=$enableval],
704                 [with_getcap=no])
705         AC_MSG_RESULT($with_getcap)
706         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
707
708         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
709         AC_ARG_ENABLE(getcap-cache,
710                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
711                 [with_getcap_cache=$enableval],
712                 [with_getcap_cache=no])
713         AC_MSG_RESULT($with_getcap_cache)
714         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
715
716 fi
717 AC_SUBST(NCURSES_USE_TERMCAP)
718
719 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
720 AC_MSG_CHECKING(if ~/.terminfo is wanted)
721 AC_ARG_ENABLE(home-terminfo,
722         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
723         [with_home_terminfo=$enableval],
724         [with_home_terminfo=yes])
725 AC_MSG_RESULT($with_home_terminfo)
726 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
727
728 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
729 AC_ARG_ENABLE(root-environ,
730         [  --disable-root-environ  restrict environment when running as root],
731         [with_root_environ=$enableval],
732         [with_root_environ=yes])
733 AC_MSG_RESULT($with_root_environ)
734 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if environment should be restricted for root user])
735
736 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
737 ###   to reduce storage requirements for the terminfo database.
738 CF_LINK_FUNCS
739
740 with_links=no
741 with_symlinks=no
742
743 # soft links (symbolic links) are useful for some systems where hard links do
744 # not work, or to make it simpler to copy terminfo trees around.
745 if test "x$ac_cv_func_symlink" = xyes ; then
746         AC_MSG_CHECKING(if tic should use symbolic links)
747         AC_ARG_ENABLE(symlinks,
748         [  --enable-symlinks       make tic use symbolic links not hard links],
749         [with_symlinks=$enableval],
750         [with_symlinks=no])
751         AC_MSG_RESULT($with_symlinks)
752 fi
753
754 # If we have hard links and did not choose to use soft links instead, there is
755 # no reason to make this choice optional - use the hard links.
756 if test "$with_symlinks" = no ; then
757         AC_MSG_CHECKING(if tic should use hard links)
758         if test "x$ac_cv_func_link" = xyes ; then
759                 with_links=yes
760         else
761                 with_links=no
762         fi
763         AC_MSG_RESULT($with_links)
764 fi
765
766 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
767 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
768
769 ###   use option --enable-broken-linker to force on use of broken-linker support
770 AC_MSG_CHECKING(if you want broken-linker support code)
771 AC_ARG_ENABLE(broken_linker,
772         [  --enable-broken_linker  compile with broken-linker support code],
773         [with_broken_linker=$enableval],
774         [with_broken_linker=${BROKEN_LINKER:-no}])
775 AC_MSG_RESULT($with_broken_linker)
776
777 BROKEN_LINKER=0
778 if test "x$with_broken_linker" = xyes ; then
779         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
780         BROKEN_LINKER=1
781 elif test "$DFT_LWR_MODEL" = shared ; then
782         case $cf_cv_system_name in
783         (cygwin*)
784                 AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
785                 BROKEN_LINKER=1
786                 CF_VERBOSE(cygwin linker is broken anyway)
787                 ;;
788         esac
789 fi
790 AC_SUBST(BROKEN_LINKER)
791
792 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
793 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
794 AC_ARG_ENABLE(bsdpad,
795         [  --enable-bsdpad         recognize BSD-style prefix padding],
796         [with_bsdpad=$enableval],
797         [with_bsdpad=no])
798 AC_MSG_RESULT($with_bsdpad)
799 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
800
801 ###   use option --enable-widec to turn on use of wide-character support
802 NCURSES_CH_T=chtype
803 NCURSES_LIBUTF8=0
804
805 NEED_WCHAR_H=0
806 NCURSES_MBSTATE_T=0
807 NCURSES_WCHAR_T=0
808 NCURSES_WINT_T=0
809
810 # Check to define _XOPEN_SOURCE "automatically"
811 CPPFLAGS_before_XOPEN="$CPPFLAGS"
812 CF_XOPEN_SOURCE(500)
813 CPPFLAGS_after_XOPEN="$CPPFLAGS"
814
815 # Work around breakage on OS X
816 CF_SIGWINCH
817
818 # Checks for CODESET support.
819 AM_LANGINFO_CODESET
820
821 # use these variables to work around a defect in gcc's fixincludes.
822 NCURSES_OK_WCHAR_T=
823 NCURSES_OK_WINT_T=
824
825 AC_MSG_CHECKING(if you want wide-character code)
826 AC_ARG_ENABLE(widec,
827         [  --enable-widec          compile with wide-char/UTF-8 code],
828         [with_widec=$enableval],
829         [with_widec=no])
830 AC_MSG_RESULT($with_widec)
831 if test "x$with_widec" = xyes ; then
832         if test "x$disable_lib_suffixes" = xno ; then
833                 LIB_SUFFIX="w${LIB_SUFFIX}"
834         fi
835         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
836         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
837
838         CF_CHECK_WCHAR_H
839
840         # with_overwrite=no
841         NCURSES_CH_T=cchar_t
842         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
843         if test "x$ac_cv_func_putwc" != xyes ; then
844                 CF_UTF8_LIB
845                 if test "$cf_cv_utf8_lib" != no ; then
846                         NCURSES_LIBUTF8=1
847                 fi
848         fi
849         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
850         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
851         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
852
853         if test "$NCURSES_MBSTATE_T" != 0; then
854                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
855         fi
856 fi
857 AC_SUBST(NCURSES_CH_T)
858 AC_SUBST(NCURSES_LIBUTF8)
859
860 AC_SUBST(NEED_WCHAR_H)
861 AC_SUBST(NCURSES_MBSTATE_T)
862 AC_SUBST(NCURSES_WCHAR_T)
863 AC_SUBST(NCURSES_WINT_T)
864
865 AC_SUBST(NCURSES_OK_WCHAR_T)
866 AC_SUBST(NCURSES_OK_WINT_T)
867
868 ###   use option --disable-lp64 to allow long chtype
869 case $cf_cv_abi_version in
870 ([[345]]*)
871         default_with_lp64=no
872         ;;
873 (*)
874         default_with_lp64=yes
875         ;;
876 esac
877
878 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
879 AC_ARG_ENABLE(lp64,
880         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
881         [with_lp64=$enableval],
882         [with_lp64=$default_with_lp64])
883 AC_MSG_RESULT($with_lp64)
884
885 if test "x$with_lp64" = xyes ; then
886         cf_cv_enable_lp64=1
887 else
888         cf_cv_enable_lp64=0
889 fi
890 AC_SUBST(cf_cv_enable_lp64)
891
892 CF_LARGEFILE
893
894 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
895 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
896 AC_ARG_ENABLE(tparm-varargs,
897         [  --disable-tparm-varargs compile tparm() without varargs interface],
898         [with_tparm_varargs=$enableval],
899         [with_tparm_varargs=yes])
900 AC_MSG_RESULT($with_tparm_varargs)
901 NCURSES_TPARM_VARARGS=0
902 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
903 AC_SUBST(NCURSES_TPARM_VARARGS)
904
905 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
906 if test "$with_ticlib" != no ; then
907 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
908 AC_ARG_ENABLE(tic-depends,
909         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
910         [with_tic_depends=$enableval],
911         [with_tic_depends=yes])
912 AC_MSG_RESULT($with_tic_depends)
913 else
914         with_tic_depends=no
915 fi
916
917 ###   use option --with-bool to override bool's type
918 AC_MSG_CHECKING(for type of bool)
919 AC_ARG_WITH(bool,
920         [  --with-bool=TYPE        override fallback type of bool variable],
921         [NCURSES_BOOL="$withval"],
922         [NCURSES_BOOL=auto])
923 AC_MSG_RESULT($NCURSES_BOOL)
924 AC_SUBST(NCURSES_BOOL)
925
926 AC_MSG_CHECKING(for alternate terminal capabilities file)
927 AC_ARG_WITH(caps,
928         [  --with-caps=alt         compile with alternate Caps file],
929         [TERMINFO_CAPS=Caps.$withval],
930         [TERMINFO_CAPS=Caps])
931 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
932 AC_MSG_RESULT($TERMINFO_CAPS)
933 AC_SUBST(TERMINFO_CAPS)
934
935 ###   use option --with-chtype to override chtype's type
936 AC_MSG_CHECKING(for type of chtype)
937 AC_ARG_WITH(chtype,
938         [  --with-chtype=TYPE      override type of chtype],
939         [NCURSES_CHTYPE="$withval"],
940         [NCURSES_CHTYPE=auto])
941 AC_MSG_RESULT($NCURSES_CHTYPE)
942
943 ###   use option --with-ospeed to override ospeed's type
944 AC_MSG_CHECKING(for type of ospeed)
945 AC_ARG_WITH(ospeed,
946         [  --with-ospeed=TYPE      override type of ospeed variable],
947         [NCURSES_OSPEED="$withval"],
948         [NCURSES_OSPEED=short])
949 AC_MSG_RESULT($NCURSES_OSPEED)
950 AC_SUBST(NCURSES_OSPEED)
951
952 ###   use option --with-mmask-t to override mmask_t's type
953 AC_MSG_CHECKING(for type of mmask_t)
954 AC_ARG_WITH(mmask-t,
955         [  --with-mmask-t=TYPE     override type of mmask_t],
956         [NCURSES_MMASK_T="$withval"],
957         [NCURSES_MMASK_T=auto])
958 AC_MSG_RESULT($NCURSES_MMASK_T)
959
960 ###   use option --with-ccharw-max to override CCHARW_MAX size
961 AC_MSG_CHECKING(for size CCHARW_MAX)
962 AC_ARG_WITH(ccharw-max,
963         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
964         [NCURSES_CCHARW_MAX="$withval"],
965         [NCURSES_CCHARW_MAX=5])
966 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
967 AC_SUBST(NCURSES_CCHARW_MAX)
968
969 ###   use option --with-tparm-arg to override tparm's argument type
970 AC_MSG_CHECKING(for type of tparm args)
971 AC_ARG_WITH(tparm-arg,
972         [  --with-tparm-arg=TYPE   override parameter type of tparm],
973         [NCURSES_TPARM_ARG="$withval"],
974         [NCURSES_TPARM_ARG=long])
975 AC_MSG_RESULT($NCURSES_TPARM_ARG)
976 AC_SUBST(NCURSES_TPARM_ARG)
977
978 ### Enable compiling-in rcs id's
979 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
980 AC_ARG_WITH(rcs-ids,
981         [  --with-rcs-ids          compile-in RCS identifiers],
982         [with_rcs_ids=$withval],
983         [with_rcs_ids=no])
984 AC_MSG_RESULT($with_rcs_ids)
985 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
986
987 ###############################################################################
988 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tabs tic toe tput tset ])
989
990 ###############################################################################
991 CF_HELP_MESSAGE(Extensions:)
992
993 ### Note that some functions (such as const) are normally disabled anyway.
994 AC_MSG_CHECKING(if you want to build with function extensions)
995 AC_ARG_ENABLE(ext-funcs,
996         [  --disable-ext-funcs     disable function-extensions],
997         [with_ext_funcs=$enableval],
998         [with_ext_funcs=yes])
999 AC_MSG_RESULT($with_ext_funcs)
1000 if test "x$with_ext_funcs" = xyes ; then
1001         NCURSES_EXT_FUNCS=1
1002         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function])
1003         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function])
1004         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function])
1005         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function])
1006         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function])
1007         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function])
1008         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function])
1009         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function])
1010         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function])
1011         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function])
1012         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
1013         GENERATED_EXT_FUNCS=generated
1014 else
1015         NCURSES_EXT_FUNCS=0
1016         GENERATED_EXT_FUNCS=
1017 fi
1018 AC_SUBST(NCURSES_EXT_FUNCS)
1019 AC_SUBST(GENERATED_EXT_FUNCS)
1020
1021 AC_MSG_CHECKING(if you want to build with experimental SCREEN extensions)
1022 AC_ARG_ENABLE(sp-funcs,
1023         [  --enable-sp-funcs       enable experimental SCREEN-extensions],
1024         [with_sp_funcs=$enableval],
1025         [with_sp_funcs=no])
1026 AC_MSG_RESULT($with_sp_funcs)
1027 if test "x$with_sp_funcs" = xyes ; then
1028         NCURSES_SP_FUNCS=1
1029         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable experimental SCREEN-extensions])
1030         GENERATED_SP_FUNCS=generated
1031 else
1032         NCURSES_SP_FUNCS=0
1033         GENERATED_SP_FUNCS=
1034 fi
1035 AC_SUBST(NCURSES_SP_FUNCS)
1036 AC_SUBST(GENERATED_SP_FUNCS)
1037
1038 AC_MSG_CHECKING(if you want to build with experimental terminal-driver)
1039 AC_ARG_ENABLE(term-driver,
1040         [  --enable-term-driver    enable experimental terminal-driver],
1041         [with_term_driver=$enableval],
1042         [with_term_driver=no])
1043 AC_MSG_RESULT($with_term_driver)
1044 if test "x$with_term_driver" = xyes ; then
1045         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable experimental terminal-driver])
1046         if test "x$with_sp_funcs" != xyes ; then
1047                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
1048         fi
1049 fi
1050
1051 ###   use option --enable-const to turn on use of const beyond that in XSI.
1052 AC_MSG_CHECKING(for extended use of const keyword)
1053 AC_ARG_ENABLE(const,
1054         [  --enable-const          compile with extra/non-standard const],
1055         [with_ext_const=$enableval],
1056         [with_ext_const=no])
1057 AC_MSG_RESULT($with_ext_const)
1058 NCURSES_CONST='/*nothing*/'
1059 if test "x$with_ext_const" = xyes ; then
1060         NCURSES_CONST=const
1061 fi
1062 AC_SUBST(NCURSES_CONST)
1063
1064 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
1065 AC_MSG_CHECKING(if you want to use extended colors)
1066 AC_ARG_ENABLE(ext-colors,
1067         [  --enable-ext-colors     compile for 256-color support],
1068         [with_ext_colors=$enableval],
1069         [with_ext_colors=no])
1070 AC_MSG_RESULT($with_ext_colors)
1071 NCURSES_EXT_COLORS=0
1072 if test "x$with_ext_colors" = xyes ; then
1073         if test "x$with_widec" != xyes ; then
1074                 AC_MSG_ERROR(This option applies only to wide-character library)
1075         else
1076                 # cannot be ABI 5 since it changes sizeof(cchar_t)
1077                 CF_NCURSES_ABI_6
1078         fi
1079         NCURSES_EXT_COLORS=1
1080         AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1081 fi
1082 AC_SUBST(NCURSES_EXT_COLORS)
1083
1084 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1085 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1086 AC_ARG_ENABLE(ext-mouse,
1087         [  --enable-ext-mouse      compile for extended mouse-encoding],
1088         [with_ext_mouse=$enableval],
1089         [with_ext_mouse=no])
1090 AC_MSG_RESULT($with_ext_mouse)
1091 NCURSES_MOUSE_VERSION=1
1092 if test "x$with_ext_mouse" = xyes ; then
1093         NCURSES_MOUSE_VERSION=2
1094         CF_NCURSES_ABI_6
1095 fi
1096 AC_SUBST(NCURSES_MOUSE_VERSION)
1097
1098 ###   use option --enable-ext-putwin to turn on extended screendumps
1099 AC_MSG_CHECKING(if you want to use extended putwin/screendump)
1100 AC_ARG_ENABLE(ext-putwin,
1101         [  --enable-ext-putwin     compile with extended putwin/screendump],
1102         [with_ext_putwin=$enableval],
1103         [with_ext_putwin=no])
1104 AC_MSG_RESULT($with_ext_putwin)
1105 if test "x$with_ext_putwin" = xyes ; then
1106         AC_DEFINE(NCURSES_EXT_PUTWIN,1,[Define to 1 to compile with extended putwin/screendump])
1107 fi
1108
1109 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1110 AC_ARG_ENABLE(no-padding,
1111         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1112         [with_no_padding=$enableval],
1113         [with_no_padding=$with_ext_funcs])
1114 AC_MSG_RESULT($with_no_padding)
1115 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1116
1117 AC_CHECK_SIZEOF([signed char], 0)
1118 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1119         NCURSES_SBOOL="signed char"
1120 else
1121         NCURSES_SBOOL="char"
1122 fi
1123 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1124 AC_ARG_ENABLE(signed-char,
1125         [  --enable-signed-char    compile using signed Boolean's in term.h],
1126         [with_signed_char=$enableval],
1127         [with_signed_char=no])
1128 AC_MSG_RESULT($with_signed_char)
1129 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1130 AC_SUBST(NCURSES_SBOOL)
1131
1132 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1133 AC_MSG_CHECKING(if you want SIGWINCH handler)
1134 AC_ARG_ENABLE(sigwinch,
1135         [  --enable-sigwinch       compile with SIGWINCH handler],
1136         [with_sigwinch=$enableval],
1137         [with_sigwinch=$with_ext_funcs])
1138 AC_MSG_RESULT($with_sigwinch)
1139 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1140
1141 ###   use option --enable-tcap-names to allow user to define new capabilities
1142 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1143 AC_ARG_ENABLE(tcap-names,
1144         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1145         [with_tcap_names=$enableval],
1146         [with_tcap_names=$with_ext_funcs])
1147 AC_MSG_RESULT($with_tcap_names)
1148 NCURSES_XNAMES=0
1149 test "x$with_tcap_names" = xyes && NCURSES_XNAMES=1
1150 AC_SUBST(NCURSES_XNAMES)
1151
1152 ###############################################################################
1153 # These options are relatively safe to experiment with.
1154 CF_HELP_MESSAGE(Development Code:)
1155 AC_MSG_CHECKING(if you want all development code)
1156 AC_ARG_WITH(develop,
1157         [  --without-develop       disable development options],
1158         [with_develop=$withval],
1159         [with_develop=no])
1160 AC_MSG_RESULT($with_develop)
1161
1162 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1163 AC_MSG_CHECKING(if you want hard-tabs code)
1164 AC_ARG_ENABLE(hard-tabs,
1165         [  --enable-hard-tabs      compile with hard-tabs code],,
1166         [enable_hard_tabs=$with_develop])
1167 AC_MSG_RESULT($enable_hard_tabs)
1168 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1169
1170 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1171 AC_MSG_CHECKING(if you want limited support for xmc)
1172 AC_ARG_ENABLE(xmc-glitch,
1173         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1174         [enable_xmc_glitch=$with_develop])
1175 AC_MSG_RESULT($enable_xmc_glitch)
1176 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1177
1178 ###############################################################################
1179 # These are just experimental, probably should not be in a package:
1180 CF_HELP_MESSAGE(Experimental Code:)
1181
1182 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1183 AC_ARG_ENABLE(assumed-color,
1184         [  --disable-assumed-color do not assume anything about default-colors],
1185         [with_assumed_color=$enableval],
1186         [with_assumed_color=yes])
1187 AC_MSG_RESULT($with_assumed_color)
1188 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1189
1190 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1191 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1192 AC_ARG_ENABLE(hashmap,
1193         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1194         [with_hashmap=$enableval],
1195         [with_hashmap=yes])
1196 AC_MSG_RESULT($with_hashmap)
1197 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1198
1199 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1200 AC_MSG_CHECKING(if you want colorfgbg code)
1201 AC_ARG_ENABLE(colorfgbg,
1202         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1203         [with_colorfgbg=$enableval],
1204         [with_colorfgbg=no])
1205 AC_MSG_RESULT($with_colorfgbg)
1206 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1207
1208 ###   use option --enable-interop to turn on use of bindings used for interop
1209 AC_MSG_CHECKING(if you want interop bindings)
1210 AC_ARG_ENABLE(interop,
1211         [  --enable-interop        compile-in experimental interop bindings],
1212         [with_exp_interop=$enableval],
1213         [with_exp_interop=no])
1214 AC_MSG_RESULT($with_exp_interop)
1215
1216 NCURSES_INTEROP_FUNCS=0
1217 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1218 AC_SUBST(NCURSES_INTEROP_FUNCS)
1219
1220 # This is still experimental (20080329), but should ultimately be moved to
1221 # the script-block --with-normal, etc.
1222 CF_WITH_PTHREAD
1223
1224 if test "x$with_pthread" != xno; then
1225         AC_CHECK_FUNC(pthread_kill,[
1226                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1227                 AC_ARG_ENABLE(pthreads-eintr,
1228                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1229                         [use_pthreads_eintr=$enableval],
1230                         [use_pthreads_eintr=no])
1231                 AC_MSG_RESULT($use_pthreads_eintr)
1232                 if test "x$use_pthreads_eintr" = xyes ; then
1233                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1234                 fi])
1235
1236         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1237         AC_ARG_ENABLE(weak-symbols,
1238                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1239                 [use_weak_symbols=$enableval],
1240                 [use_weak_symbols=no])
1241         AC_MSG_RESULT($use_weak_symbols)
1242         if test "x$use_weak_symbols" = xyes ; then
1243                 CF_WEAK_SYMBOLS
1244         else
1245                 cf_cv_weak_symbols=no
1246         fi
1247
1248         if test "x$cf_cv_weak_symbols" = xyes ; then
1249                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1250         fi
1251 fi
1252
1253 PTHREAD=
1254 if test "x$with_pthread" = "xyes" ; then
1255         AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1256         enable_reentrant=yes
1257         if test "x$cf_cv_weak_symbols" = xyes ; then
1258                 PTHREAD=-lpthread
1259         fi
1260 fi
1261 AC_SUBST(PTHREAD)
1262
1263 # Reentrant code has to be opaque; there's little advantage to making ncurses
1264 # opaque outside of that, so there is no --enable-opaque option.  We can use
1265 # this option without --with-pthreads, but this will be always set for
1266 # pthreads.
1267 AC_MSG_CHECKING(if you want experimental reentrant code)
1268 AC_ARG_ENABLE(reentrant,
1269         [  --enable-reentrant      compile with experimental reentrant code],
1270         [with_reentrant=$enableval],
1271         [with_reentrant=no])
1272 AC_MSG_RESULT($with_reentrant)
1273 if test "x$with_reentrant" = xyes ; then
1274         cf_cv_enable_reentrant=1
1275         cf_cv_enable_opaque="NCURSES_INTERNALS"
1276         NCURSES_OPAQUE=1
1277         NCURSES_SIZE_T=int
1278         if test "x$cf_cv_weak_symbols" = xyes ; then
1279                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1280                 CF_ADD_LIB(pthread,TEST_LIBS)
1281                 CF_ADD_LIB(pthread,TEST_LIBS2)
1282         else
1283                 # when not using weak symbols but with_reentrant,
1284                 # add 't' to the library suffix on all platforms
1285                 # except cygwin, where we only do that if ALSO
1286                 # compiling with full thread support.
1287                 case "$host" in
1288                 (*cygwin* | *msys*)
1289                         if test "$with_pthread" = "yes" ; then
1290                                 if test "x$disable_lib_suffixes" = "xno" ; then
1291                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1292                                 fi
1293                         fi ;;
1294                 (*)
1295                         if test "x$disable_lib_suffixes" = "xno" ; then
1296                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1297                         fi
1298                         ;;
1299                 esac
1300         fi
1301         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use experimental reentrant feature])
1302         CF_NCURSES_ABI_6
1303 else
1304         cf_cv_enable_reentrant=0
1305         cf_cv_enable_opaque="NCURSES_OPAQUE"
1306         NCURSES_OPAQUE=0
1307         NCURSES_SIZE_T=short
1308 fi
1309 AC_SUBST(cf_cv_enable_reentrant)
1310 AC_SUBST(cf_cv_enable_opaque)
1311 AC_SUBST(NCURSES_OPAQUE)
1312 AC_SUBST(NCURSES_SIZE_T)
1313
1314 ### Allow using a different wrap-prefix
1315 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1316         AC_MSG_CHECKING(for prefix used to wrap public variables)
1317         AC_ARG_WITH(wrap-prefix,
1318                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1319                 [NCURSES_WRAP_PREFIX=$withval],
1320                 [NCURSES_WRAP_PREFIX=_nc_])
1321         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1322 else
1323         NCURSES_WRAP_PREFIX=_nc_
1324 fi
1325 AC_SUBST(NCURSES_WRAP_PREFIX)
1326 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1327
1328 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1329 AC_ARG_ENABLE(safe-sprintf,
1330         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1331         [with_safe_sprintf=$enableval],
1332         [with_safe_sprintf=no])
1333 AC_MSG_RESULT($with_safe_sprintf)
1334 test "x$with_safe_sprintf" = xyes && AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1335
1336 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1337 # when hashmap is used scroll hints are useless
1338 if test "$with_hashmap" = no ; then
1339 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1340 AC_ARG_ENABLE(scroll-hints,
1341         [  --disable-scroll-hints  compile without scroll-hints code],
1342         [with_scroll_hints=$enableval],
1343         [with_scroll_hints=yes])
1344 AC_MSG_RESULT($with_scroll_hints)
1345 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1346 fi
1347
1348 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1349 AC_ARG_ENABLE(wgetch-events,
1350         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1351         [with_wgetch_events=$enableval],
1352         [with_wgetch_events=no])
1353 AC_MSG_RESULT($with_wgetch_events)
1354 test "x$with_wgetch_events" = xyes && AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with experimental wgetch-events code])
1355
1356 ###############################################################################
1357 CF_HELP_MESSAGE(Testing/development Options:)
1358
1359 ###     use option --disable-echo to suppress full display compiling commands
1360 CF_DISABLE_ECHO
1361 if test "x$enable_echo" = xyes; then
1362         ECHO_LINK=
1363 else
1364         ECHO_LINK='@ echo linking $@ ... ;'
1365         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1366         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1367 fi
1368 AC_SUBST(ECHO_LINK)
1369
1370 ###     use option --enable-warnings to turn on all gcc warnings
1371 AC_MSG_CHECKING(if you want to see compiler warnings)
1372 AC_ARG_ENABLE(warnings,
1373         [  --enable-warnings       build: turn on GCC compiler warnings],
1374         [with_warnings=$enableval])
1375 AC_MSG_RESULT($with_warnings)
1376
1377 if test "x$with_warnings" = "xyes"; then
1378         CF_ADD_ADAFLAGS(-gnatg)
1379         CF_GCC_WARNINGS(Wno-unknown-pragmas Wswitch-enum)
1380         if test "x$cf_with_cxx" = xyes ; then
1381                 CF_GXX_WARNINGS(Wno-unused)
1382         fi
1383 fi
1384 CF_GCC_ATTRIBUTES
1385 CF_ENABLE_STRING_HACKS
1386
1387 ###     use option --enable-assertions to turn on generation of assertion code
1388 AC_MSG_CHECKING(if you want to enable runtime assertions)
1389 AC_ARG_ENABLE(assertions,
1390         [  --enable-assertions     test: turn on generation of assertion code],
1391         [with_assertions=$enableval],
1392         [with_assertions=no])
1393 AC_MSG_RESULT($with_assertions)
1394 if test -n "$GCC"
1395 then
1396         if test "$with_assertions" = no
1397         then
1398                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1399         else
1400                 CF_ADD_ADAFLAGS(-gnata)
1401         fi
1402 fi
1403
1404 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1405 CF_DISABLE_LEAKS
1406 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1407
1408 ###     use option --enable-expanded to generate certain macros as functions
1409 AC_ARG_ENABLE(expanded,
1410         [  --enable-expanded       test: generate functions for certain macros],
1411         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1412
1413 ###     use option --disable-macros to suppress macros in favor of functions
1414 AC_ARG_ENABLE(macros,
1415         [  --disable-macros        test: use functions rather than macros],
1416         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1417
1418 # Normally we only add trace() to the debug-library.  Allow this to be
1419 # extended to all models of the ncurses library:
1420 cf_all_traces=no
1421 case "$CFLAGS $CPPFLAGS" in
1422 (*-DTRACE*)
1423         cf_all_traces=yes
1424         ;;
1425 esac
1426
1427 AC_MSG_CHECKING(whether to add trace feature to all models)
1428 AC_ARG_WITH(trace,
1429 [  --with-trace            test: add trace() function to all models of ncurses],
1430 [cf_with_trace=$withval],
1431 [cf_with_trace=$cf_all_traces])
1432 AC_MSG_RESULT($cf_with_trace)
1433
1434 if test "x$cf_with_trace" = xyes ; then
1435         LIB_TRACING=all
1436         ADA_TRACE=TRUE
1437         CF_ADD_CFLAGS(-DTRACE)
1438 else
1439         LIB_TRACING=DEBUG
1440         ADA_TRACE=FALSE
1441 fi
1442
1443 AC_SUBST(ADA_TRACE)
1444
1445 CF_DISABLE_GNAT_PROJECTS
1446
1447 ###     Checks for libraries.
1448 case $cf_cv_system_name in
1449 (*mingw32*|*mingw64*)
1450         CPPFLAGS="$CPPFLAGS -DWINVER=0x0501"
1451         LIBS=" -lpsapi $LIBS"
1452         ;;
1453 (*)
1454 AC_CHECK_FUNC(gettimeofday,
1455         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1456
1457 AC_CHECK_LIB(bsd, gettimeofday,
1458         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1459         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1460         ;;
1461 esac
1462
1463 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1464 AC_SUBST(MATH_LIB)
1465
1466 ###     Checks for header files.
1467 AC_STDC_HEADERS
1468 AC_HEADER_DIRENT
1469 AC_HEADER_TIME
1470 CF_REGEX
1471
1472 dnl These are some other potentially nonportable headers.
1473 AC_CHECK_HEADERS( \
1474 fcntl.h \
1475 getopt.h \
1476 limits.h \
1477 locale.h \
1478 math.h \
1479 poll.h \
1480 sys/bsdtypes.h \
1481 sys/ioctl.h \
1482 sys/param.h \
1483 sys/poll.h \
1484 sys/select.h \
1485 sys/time.h \
1486 sys/times.h \
1487 ttyent.h \
1488 unistd.h \
1489 wctype.h \
1490 )
1491
1492 CF_GETOPT_HEADER
1493
1494 # check for ISC (this may also define _POSIX_SOURCE)
1495 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1496 if test "x$ISC" = xyes ; then
1497         AC_CHECK_LIB(cposix,main)
1498         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1499 fi
1500
1501 CF_SYS_TIME_SELECT
1502
1503 ###     checks for compiler characteristics
1504 AC_LANG_C
1505 AC_C_CONST
1506 CF_C_INLINE(NCURSES_INLINE,1200)
1507 CF_SIG_ATOMIC_T
1508
1509 if test $NCURSES_CHTYPE = auto ; then
1510         CF_TYPEOF_CHTYPE
1511 else
1512         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1513 fi
1514 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1515 AC_SUBST(cf_cv_typeof_chtype)
1516
1517 CF_UNSIGNED_LITERALS
1518 cf_cv_1UL="1"
1519 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1520 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1521 AC_SUBST(cf_cv_1UL)
1522
1523 if test $NCURSES_MMASK_T = auto ; then
1524         cf_cv_typeof_mmask_t=long
1525 else
1526         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1527 fi
1528 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1529 AC_SUBST(cf_cv_typeof_mmask_t)
1530
1531 ###     Checks for external-data
1532 CF_ERRNO
1533 CF_LINK_DATAONLY
1534
1535 ###     Checks for library functions.
1536 AC_CHECK_FUNCS( \
1537 getcwd \
1538 getegid \
1539 geteuid \
1540 getopt \
1541 getttynam \
1542 issetugid \
1543 poll \
1544 putenv \
1545 remove \
1546 select \
1547 setbuf \
1548 setbuffer \
1549 setenv \
1550 setvbuf \
1551 sigaction \
1552 sigvec \
1553 strdup \
1554 strstr \
1555 tcgetpgrp \
1556 times \
1557 vsnprintf \
1558 )
1559
1560 if test "x$ac_cv_func_getopt" = xno &&
1561    test "x$cf_with_progs$cf_with_tests" != xnono; then
1562         AC_MSG_ERROR(getopt is required for building programs)
1563 fi
1564
1565 if test "x$with_getcap" = "xyes" ; then
1566         CF_CGETENT
1567 fi
1568
1569 CF_ISASCII
1570 CF_STRUCT_SIGACTION
1571 CF_FUNC_NANOSLEEP
1572 CF_FUNC_TERMIOS
1573 CF_FUNC_VSSCANF
1574 CF_MKSTEMP
1575
1576 # setup for prototype of fallback for vsscanf()
1577 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1578
1579 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1580 if test "x$cross_compiling" = xyes ; then
1581         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1582 else
1583         AC_FUNC_SETVBUF_REVERSED
1584 fi
1585 AC_CHECK_TYPE(intptr_t, long)
1586 AC_CHECK_TYPE(ssize_t, int)
1587 CF_TYPE_SIGACTION
1588 CF_SIZECHANGE
1589 CF_FUNC_MEMMOVE
1590 CF_FUNC_POLL
1591 CF_VA_COPY
1592 AC_FUNC_VFORK
1593
1594 # special check for test/ditto.c
1595 CF_FUNC_OPENPTY
1596 if test "$cf_cv_func_openpty" != no ; then
1597         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1598         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1599         if test "x$cf_cv_lib_util" = xyes ; then
1600                 CF_ADD_LIB(util,TEST_LIBS)
1601         fi
1602 fi
1603 AC_SUBST(TEST_LIBS)
1604 AC_SUBST(TEST_LIBS2)
1605
1606 if test "$with_hashed_db" != no ; then
1607         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1608         CF_HASHED_DB($with_hashed_db)
1609 fi
1610
1611 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1612 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1613         CF_STRIP_G_OPT(CFLAGS)
1614         CF_STRIP_G_OPT(CXXFLAGS)
1615 fi
1616
1617 # Just in case, check if the C compiler has a bool type.
1618 CF_BOOL_DECL(cf_cv_cc_bool_type)
1619
1620 # Check for C++ compiler characteristics (and ensure that it's there!)
1621 if test -n "$CXX" ; then
1622         AC_LANG_CPLUSPLUS
1623         CF_STDCPP_LIBRARY
1624         CF_PROG_CC_C_O(CXX)
1625
1626         case $GXX_VERSION in
1627         (1*|2.[0-6]*)
1628                 cf_cxx_library=yes
1629                 ;;
1630         (*-2.7*|2.7*)
1631                 CF_GPP_LIBRARY
1632                 ;;
1633         (*)
1634                 cf_cxx_library=no
1635                 ;;
1636         esac
1637
1638         AC_CHECK_HEADERS(typeinfo)
1639         CF_CXX_IOSTREAM_NAMESPACE
1640         CF_BOOL_DECL
1641         CF_BOOL_SIZE
1642         CF_ETIP_DEFINES
1643         CF_CPP_PARAM_INIT
1644         CF_CPP_STATIC_CAST
1645         CF_CXX_AR_FLAGS
1646 else
1647         cf_cxx_library=no
1648         cf_cv_builtin_bool=1
1649
1650         # Just because we are not configuring against C++ right now does not
1651         # mean that a user will not want to use C++.  Some distributors disable
1652         # the C++ portion of this configuration as a shortcut (or just to avoid
1653         # compiling the demo in the c++ directory).  So we need a reasonable
1654         # default for the 'bool' type.
1655         #
1656         # Caveat: since the storage of the bool type is not standardized, it
1657         # may change.
1658
1659         if test "$NCURSES_BOOL" != auto ; then
1660                 cf_cv_type_of_bool=$NCURSES_BOOL
1661                 cf_cv_header_stdbool_h=0
1662         else
1663                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1664                         CF_BOOL_SIZE
1665                 else
1666                         AC_MSG_CHECKING(for fallback type of bool)
1667                         case "$host_cpu" in
1668                         (i?86)  cf_cv_type_of_bool=char ;;
1669                         (*)     cf_cv_type_of_bool=int  ;;
1670                         esac
1671                         AC_MSG_RESULT($cf_cv_type_of_bool)
1672                 fi
1673         fi
1674 fi
1675 AC_SUBST(CXXLIBS)
1676
1677 # If the C compiler did not declare bool, and we did not determine that the C++
1678 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1679 # ncurses library use the same type as C++ bool.  Note that this allows one to
1680 # specify the type of bool in a configure-script option and postpone
1681 # integration with the C++ compiler provided that the types are compatible.
1682 USE_CXX_BOOL=1
1683 if test $cf_cv_cc_bool_type = 1
1684 then
1685         # oops: C has a bool.  Unlikely, but C++ could differ.
1686         USE_CXX_BOOL=0
1687 elif test $cf_cv_builtin_bool = 0
1688 then
1689         # C++ has no bool
1690         USE_CXX_BOOL=0
1691 else
1692         # this is the normal case
1693         USE_CXX_BOOL='defined(__cplusplus)'
1694 fi
1695 AC_SUBST(USE_CXX_BOOL)
1696
1697 CF_HELP_MESSAGE(Ada95 Binding Options:)
1698
1699 dnl If the Ada95 source-tree is present, add that to the build unless it will
1700 dnl not work, or was not requested.
1701 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1702
1703 dnl libtool does not know anything about GNAT, though a change made in 1998
1704 dnl provided for it "someday".  Disable the ada subtree if we are using
1705 dnl libtool -TD 20070714
1706         if test "$cf_with_ada" != "no" ; then
1707                 if test "$with_libtool" != "no"; then
1708                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1709                         cf_with_ada=no
1710                 fi
1711         fi
1712
1713 dnl Check for availability of GNU Ada Translator (GNAT).
1714 dnl At the moment we support no other Ada95 compiler.
1715         if test "$cf_with_ada" != "no" ; then
1716                 CF_PROG_GNAT
1717                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
1718                         CF_ADD_ADAFLAGS(-gnatpn)
1719                         CF_FIXUP_ADAFLAGS
1720
1721                         CF_GNATPREP_OPT_T
1722
1723                         CF_GNAT_GENERICS
1724                         CF_GNAT_SIGINT
1725                         CF_GNAT_PROJECTS
1726
1727                         CF_WITH_ADA_COMPILER
1728
1729                         cf_ada_package=terminal_interface
1730                         AC_SUBST(cf_ada_package)
1731
1732                         CF_WITH_ADA_INCLUDE
1733                         CF_WITH_ADA_OBJECTS
1734                         CF_WITH_ADA_SHAREDLIB
1735                 fi
1736         fi
1737 else
1738         cf_with_ada=no
1739 fi
1740
1741 # do this "late" to avoid conflict with header-checks
1742 if test "x$with_widec" = xyes ; then
1743         AC_CHECK_SIZEOF(wchar_t)
1744 fi
1745
1746 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1747 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1748 ###
1749 ### ticlib modules may be a separate library, otherwise contained in termlib.
1750 ### termlib modules may be a separate library, otherwise contained in ncurses.
1751 ###
1752 ### The of "+" or " " between the tokens controls the way the script
1753 ### chooses to split module lists into libraries.
1754 ###
1755 ### (see CF_LIB_RULES).
1756 AC_MSG_CHECKING(for library subsets)
1757 LIB_SUBSETS=
1758
1759 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1760         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1761         if test "$with_ticlib" != no ; then
1762                 LIB_SUBSETS="${LIB_SUBSETS} "
1763         else
1764                 LIB_SUBSETS="${LIB_SUBSETS}+"
1765         fi
1766 fi
1767
1768 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1769 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1770
1771 if test "$with_termlib" != no ; then
1772         LIB_SUBSETS="${LIB_SUBSETS} "
1773 else
1774         LIB_SUBSETS="${LIB_SUBSETS}+"
1775 fi
1776
1777 LIB_SUBSETS="${LIB_SUBSETS}base"
1778
1779 # Most term-driver calls are to tinfo, but some like init_pair are to the
1780 # base library (so it resides in base).
1781 if test "$with_term_driver" != no ; then
1782         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1783         case $cf_cv_system_name in
1784         (*mingw32*|*mingw64*)
1785                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1786                 CPPFLAGS="$CPPFLAGS -DUSE_WIN32CON_DRIVER"
1787                 ;;
1788         (*)
1789                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1790                 ;;
1791         esac
1792 fi
1793
1794 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1795 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1796
1797 AC_MSG_RESULT($LIB_SUBSETS)
1798
1799 ### Construct the list of include-directories to be generated
1800 CF_INCLUDE_DIRS
1801 CF_ADA_INCLUDE_DIRS
1802
1803 ### Build up pieces for makefile rules
1804 AC_MSG_CHECKING(default library suffix)
1805 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1806 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1807 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1808
1809 AC_MSG_CHECKING(default library-dependency suffix)
1810 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1811 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1812 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1813
1814 AC_MSG_CHECKING(default object directory)
1815 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1816 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1817 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1818
1819 if test "x$cf_with_cxx" = xyes ; then
1820 AC_MSG_CHECKING(c++ library-dependency suffix)
1821 if test "$with_libtool" != "no"; then
1822         # libtool thinks it can make c++ shared libraries (perhaps only g++)
1823         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1824 elif test "$with_shared_cxx" != "no"; then
1825         # also for g++ users...
1826         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1827 else
1828         # we normally make a static library because C/C++ library rules differ
1829         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
1830 fi
1831 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1832 AC_SUBST(CXX_LIB_SUFFIX)
1833 fi
1834
1835 # do not want -ldl in build except as needed for -lncurses dependency
1836 if test "x$with_dlsym" = xyes ; then
1837 if test $DFT_LWR_MODEL = shared || \
1838    test $DFT_LWR_MODEL = libtool ; then
1839         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1840 fi
1841 fi
1842 ### Set up low-level terminfo dependencies for makefiles.
1843
1844 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1845 # do not need libdl
1846 TICS_LIST=
1847 if test "x$with_dlsym" = xyes ; then
1848         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1849 fi
1850
1851 USE_ARG_SUFFIX="${DFT_ARG_SUFFIX}${EXTRA_SUFFIX}"
1852 USE_LIB_SUFFIX="${LIB_SUFFIX}${EXTRA_SUFFIX}"
1853 USE_CFG_SUFFIX=${DFT_ARG_SUFFIX}${cf_cv_abi_version}
1854 if test -n "$EXTRA_SUFFIX" && test "x$EXTRA_SUFFIX" != "x${cf_cv_abi_version}"
1855 then
1856         USE_CFG_SUFFIX="${USE_CFG_SUFFIX}${EXTRA_SUFFIX}"
1857 fi
1858 AC_SUBST(USE_ARG_SUFFIX)
1859 AC_SUBST(USE_CFG_SUFFIX)
1860 AC_SUBST(USE_LIB_SUFFIX)
1861
1862 if test "$with_ticlib" != no ; then
1863
1864         if test "x$with_ticlib" != xyes ; then
1865                 TICS_NAME=$with_ticlib
1866                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1867                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1868                 TICS_LIB_SUFFIX="${with_ticlib}"
1869         else
1870                 TICS_ARG_SUFFIX="${TICS_NAME}${USE_ARG_SUFFIX}"
1871                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1872                 TICS_LIB_SUFFIX="${TICS_NAME}${USE_LIB_SUFFIX}"
1873         fi
1874         TICS_LDFLAGS="-L${LIB_DIR}"
1875         TICS_LIBS="-l${TICS_LIB_SUFFIX}"
1876 else
1877         TICS_LDFLAGS="-L${LIB_DIR}"
1878         TICS_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
1879 fi
1880 AC_SUBST(TICS_ARG_SUFFIX)
1881 AC_SUBST(TICS_DEP_SUFFIX)
1882 AC_SUBST(TICS_LIB_SUFFIX)
1883 AC_SUBST(TICS_LDFLAGS)
1884 AC_SUBST(TICS_LIBS)
1885
1886 if test "$with_termlib" != no ; then
1887
1888         if test "x$with_termlib" != xyes ; then
1889                 TINFO_NAME=$with_termlib
1890                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
1891                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1892                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1893                 TINFO_LIB_SUFFIX="${with_termlib}"
1894         else
1895                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1896                 TINFO_ARG_SUFFIX="${TINFO_NAME}${USE_ARG_SUFFIX}"
1897                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1898                 TINFO_LIB_SUFFIX="${TINFO_NAME}${USE_LIB_SUFFIX}"
1899         fi
1900
1901         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1902         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1903         if test "$DFT_LWR_MODEL" = "libtool"; then
1904                 TEST_ARGS="${TEST_DEPS}"
1905                 TEST_ARG2="${TEST_DEP2}"
1906                 TINFO_LDFLAGS="-L${LIB_DIR}"
1907                 TINFO_LIBS="$TEST_ARGS"
1908                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
1909                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
1910         else
1911                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1912                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1913                 if test "x$with_term_driver" != xno ; then
1914                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
1915                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${USE_ARG_SUFFIX}"
1916                         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
1917                 else
1918                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1919                         TINFO_LIBS="$TEST_ARGS"
1920                 fi
1921                 TINFO_LDFLAGS="-L${LIB_DIR}"
1922                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1923         fi
1924 else
1925         # the next lines are needed for linking libtic over libncurses
1926         TINFO_NAME=${LIB_NAME}
1927         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1928         TINFO_ARG_SUFFIX=${LIB_NAME}${USE_ARG_SUFFIX}
1929         if test "x$with_tic_depends" = xyes ; then
1930                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
1931         else
1932                 TICS_LIST="$SHLIB_LIST"
1933         fi
1934
1935         TINFO_LDFLAGS="-L${LIB_DIR}"
1936         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
1937 fi
1938
1939 if test "$DFT_LWR_MODEL" = shared ; then
1940         case $cf_cv_system_name in
1941         (cygwin*|msys*)
1942                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
1943                 TINFO_SUFFIX=.dll
1944                 ;;
1945         esac
1946 fi
1947
1948 AC_SUBST(TINFO_ARG_SUFFIX)
1949 AC_SUBST(TINFO_DEP_SUFFIX)
1950 AC_SUBST(TINFO_LIB_SUFFIX)
1951 AC_SUBST(TINFO_LDFLAGS)
1952 AC_SUBST(TINFO_LIBS)
1953
1954 if test "x$with_dlsym" = xyes ; then
1955         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1956 fi
1957
1958 if test "$DFT_LWR_MODEL" = "libtool"; then
1959         OBJEXT=lo
1960 fi
1961
1962 # needed for Ada95
1963 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
1964 AC_SUBST(TINFO_LDFLAGS2)
1965
1966 case $DFT_LWR_MODEL in
1967 (normal|debug|profile)
1968         CF_LDFLAGS_STATIC
1969         ;;
1970 esac
1971
1972 AC_MSG_CHECKING(where we will install curses.h)
1973 AC_SUBST(includesubdir)
1974 includesubdir=
1975 if test "$with_overwrite" = no && \
1976  ( test "x$includedir" = 'x${prefix}/include' || \
1977    test "x$includedir" = "x${prefix}/include" )
1978 then
1979         includesubdir="/ncurses${USE_LIB_SUFFIX}"
1980 fi
1981 AC_MSG_RESULT(${includedir}${includesubdir})
1982
1983 ### Resolve a conflict between normal and wide-curses by forcing applications
1984 ### that will need libutf8 to add it to their configure script.
1985 if test "$with_overwrite" != no ; then
1986 if test "$NCURSES_LIBUTF8" = 1 ; then
1987         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1988         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1989 fi
1990 fi
1991 WITH_OVERWRITE=$with_overwrite
1992
1993 AC_SUBST(WITH_OVERWRITE)
1994 AC_SUBST(TICS_LIST)
1995 AC_SUBST(TINFO_LIST)
1996 AC_SUBST(SHLIB_LIST)
1997
1998 # used to separate tack out of the tree
1999 NCURSES_TREE=
2000 AC_SUBST(NCURSES_TREE)
2001
2002 ### predefined stuff for the test programs
2003 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
2004
2005 ### Construct the list of subdirectories for which we'll customize makefiles
2006 ### with the appropriate compile-rules.
2007
2008 CF_SRC_MODULES($modules_to_build)
2009
2010 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2011    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${USE_CFG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
2012    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${USE_CFG_SUFFIX}-config.1:man/MKada_config.in"
2013 fi
2014
2015 CF_DIRS_TO_MAKE
2016
2017 # symbols that differ when compiling Ada95 by itself.
2018 NCURSES_SHLIB2='sh $(top_srcdir)/misc/shlib'
2019 AC_SUBST(NCURSES_SHLIB2)
2020
2021 # values to use as strings
2022 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
2023
2024 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
2025
2026 ### Now that we're done running tests, add the compiler-warnings, if any
2027 CF_ADD_CFLAGS($EXTRA_CFLAGS)
2028
2029 ### Define substitutions for header files to avoid name-pollution
2030 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
2031 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
2032 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
2033 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
2034
2035 ################################################################################
2036 test "x$use_database" = xyes && \
2037 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
2038
2039 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
2040 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${USE_CFG_SUFFIX}-config.1:man/MKncu_config.in"
2041
2042 if test "x$enable_pc_files" = xyes ; then \
2043 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
2044 MAKE_PC_FILES=
2045 else
2046 MAKE_PC_FILES="#"
2047 fi
2048 AC_SUBST(MAKE_PC_FILES)
2049 AC_SUBST(cross_compiling)
2050
2051 AC_PATH_PROG(TIC_PATH,tic,unknown,$PATH:/usr/local/ncurses/bin)
2052 if test -n "$FALLBACK_LIST"
2053 then
2054         if test "$TIC_PATH" = unknown
2055         then
2056                 AC_MSG_WARN(no tic program found for fallbacks)
2057         fi
2058 fi
2059 AC_SUBST(TIC_PATH)
2060
2061 if test "x$cf_with_tests" != xno ; then
2062         MAKE_TESTS=
2063 else
2064         MAKE_TESTS="#"
2065 fi
2066 AC_SUBST(MAKE_TESTS)
2067
2068 ADAHTML_DIR=../../doc/html/ada
2069 AC_SUBST(ADAHTML_DIR)
2070
2071 # these could be configurable, but are not currently
2072 PANEL_NAME=panel
2073 MENU_NAME=menu
2074 FORM_NAME=form
2075 CXX_NAME=ncurses++
2076
2077 AC_SUBST(PANEL_NAME)
2078 AC_SUBST(MENU_NAME)
2079 AC_SUBST(FORM_NAME)
2080 AC_SUBST(CXX_NAME)
2081
2082 # workaround for g++ versus Solaris (20131116)
2083 case $cf_cv_system_name in
2084 (solaris2*)
2085         case "x$CPPFLAGS" in
2086         (*-D_XOPEN_SOURCE_EXTENDED*)
2087                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
2088                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
2089                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
2090                 ;;
2091         esac
2092         ;;
2093 esac
2094
2095 # Help to automatically enable the extended curses features when using either
2096 # the *-config or the ".pc" files by adding defines.
2097 AC_MSG_CHECKING(for defines to add to ncurses${USE_CFG_SUFFIX}-config script)
2098 PKG_CFLAGS=
2099 for cf_loop1 in $CPPFLAGS_after_XOPEN
2100 do
2101         cf_found=no
2102         for cf_loop2 in $CPPFLAGS_before_XOPEN
2103         do
2104                 if test "x$cf_loop1" = "x$cf_loop2"
2105                 then
2106                         cf_found=yes
2107                         break
2108                 fi
2109         done
2110         test "$cf_found" = no && PKG_CFLAGS="$PKG_CFLAGS $cf_loop1"
2111 done
2112 AC_MSG_RESULT($PKG_CFLAGS)
2113 AC_SUBST(PKG_CFLAGS)
2114
2115 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
2116 case "x$NCURSES_OSPEED" in
2117 (*short*)
2118         cf_compatible=1
2119         ;;
2120 (*)
2121         cf_compatible=0
2122         ;;
2123 esac
2124 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
2125
2126 case "x$cf_cv_typeof_chtype" in
2127 (xshort|xint|xlong)
2128         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
2129         ;;
2130 esac
2131
2132 case "x$cf_cv_typeof_mmask_t" in
2133 (xshort|xint|xlong)
2134         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2135         ;;
2136 esac
2137
2138 # substitute into misc/Makefile to suppress
2139 # (un)install.data from the
2140 # (un)install rules.
2141 if test "x$cf_with_db_install" = "xno"; then
2142         MISC_INSTALL_DATA=
2143         MISC_UNINSTALL_DATA=
2144 else
2145         MISC_INSTALL_DATA=install.data
2146         MISC_UNINSTALL_DATA=uninstall.data
2147 fi
2148 AC_SUBST(MISC_INSTALL_DATA)
2149 AC_SUBST(MISC_UNINSTALL_DATA)
2150
2151 SUB_SCRIPTS=
2152
2153 dnl Override the package used for exported symbols
2154 if test -n "$PACKAGE"
2155 then
2156         PACKAGE="${PACKAGE}${DFT_ARG_SUFFIX}"
2157         export PACKAGE
2158         echo "package: $PACKAGE"
2159 fi
2160
2161 UNALTERED_SYMS=
2162 cf_filter_syms=no
2163
2164 if test -n "$RESULTING_SYMS"
2165 then
2166         case $cf_cv_abi_version in
2167         ([[6789]])
2168                 CF_VERBOSE(will map symbols to ABI=$cf_cv_abi_version)
2169                 cf_filter_syms=yes
2170                 ;;
2171         (*)
2172                 CF_VERBOSE(will map symbols to default ABI)
2173                 ;;
2174         esac
2175 fi
2176
2177 if test "x$WILDCARD_SYMS" = xno
2178 then
2179         cf_filter_syms=yes
2180 fi
2181
2182 UNALTERED_SYMS=`echo "$RESULTING_SYMS" | sed -e 's/\\$/\\\\$/g'`
2183 if test $cf_filter_syms = yes
2184 then
2185         RESULTING_SYMS=resulting.map
2186 fi
2187 AC_SUBST(UNALTERED_SYMS)
2188
2189 AC_OUTPUT( \
2190         include/MKterm.h.awk \
2191         include/curses.head:include/curses.h.in \
2192         include/ncurses_dll.h \
2193         include/termcap.h \
2194         include/unctrl.h \
2195         $SUB_SCRIPTS \
2196         $SUB_MAKEFILES \
2197         Makefile,[
2198 if test "x$cf_with_tests" != xno ; then
2199         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2200 fi
2201 CF_LIB_RULES($SRC_SUBDIRS)
2202
2203 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2204 if test -z "$USE_OLD_MAKERULES" ; then
2205         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
2206 fi
2207 fi
2208 ],[
2209 ### Special initialization commands, used to pass information from the
2210 ### configuration-run into config.status
2211
2212 AWK="$AWK"
2213 ALTERNATE_SYMS="$ALTERNATE_SYMS"
2214 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2215 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2216 ECHO_LD="$ECHO_LD"
2217 EXTRA_SUFFIX="$EXTRA_SUFFIX"
2218 LDCONFIG="$LDCONFIG"
2219 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2220 LIB_NAME="$LIB_NAME"
2221 LIB_PREFIX="$LIB_PREFIX"
2222 LIB_SUBSETS="$LIB_SUBSETS"
2223 LIB_SUFFIX="$LIB_SUFFIX"
2224 LIB_TRACING="$LIB_TRACING"
2225 LN_S="$LN_S"
2226 MAKE_TERMINFO="$MAKE_TERMINFO"
2227 NCURSES_MAJOR="$NCURSES_MAJOR"
2228 NCURSES_MINOR="$NCURSES_MINOR"
2229 NCURSES_OSPEED="$NCURSES_OSPEED"
2230 NCURSES_PATCH="$NCURSES_PATCH"
2231 SRC_SUBDIRS="$SRC_SUBDIRS"
2232 TERMINFO="$TERMINFO"
2233 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2234 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2235 TICS_NAME="$TICS_NAME"
2236 TIC_PATH="$TIC_PATH"
2237 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2238 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2239 TINFO_NAME="$TINFO_NAME"
2240 TINFO_SUFFIX="$TINFO_SUFFIX"
2241 UNALTERED_SYMS="$UNALTERED_SYMS"
2242 USE_ARG_SUFFIX="$USE_ARG_SUFFIX"
2243 USE_CFG_SUFFIX="$USE_CFG_SUFFIX"
2244 USE_LIB_SUFFIX="$USE_LIB_SUFFIX"
2245 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2246 WILDCARD_SYMS="$WILDCARD_SYMS"
2247 WITH_CURSES_H="$with_curses_h"
2248 WITH_ECHO="${enable_echo:=yes}"
2249 WITH_OVERWRITE="$with_overwrite"
2250 cf_LIST_MODELS="$cf_list_models"
2251 cf_cv_abi_version="$cf_cv_abi_version"
2252 cf_cv_do_relink="$cf_cv_do_relink"
2253 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2254 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2255 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2256 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2257 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2258 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2259 cf_cv_rel_version="$cf_cv_rel_version"
2260 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2261 cf_cv_shared_soname='$cf_cv_shared_soname'
2262 cf_cv_shlib_version="$cf_cv_shlib_version"
2263 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2264 cf_cv_system_name="$cf_cv_system_name"
2265 cf_cv_term_driver="$with_term_driver"
2266 cf_with_ada="$cf_with_ada"
2267 cf_with_cxx_binding="$cf_with_cxx_binding"
2268 cf_with_db_install="$cf_with_db_install"
2269 cf_with_manpages="$cf_with_manpages"
2270 cf_with_tests="$cf_with_tests"
2271 host="$host"
2272 target="$target"
2273 with_shared_cxx="$with_shared_cxx"
2274
2275 ],cat)dnl
2276 ${MAKE:-make} preinstall