configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2011,2012 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: configure.in,v 1.545 2012/02/25 11:32:40 tom Exp $
  32 dnl Process this file with autoconf to produce a configure script.
  33 dnl
  34 dnl See http://invisible-island.net/autoconf/ for additional information.
  35 dnl
  36 dnl ---------------------------------------------------------------------------
  37 AC_PREREQ(2.13.20020210)
  38 AC_REVISION($Revision: 1.545 $)
  39 AC_INIT(ncurses/base/lib_initscr.c)
  40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  41
  42 CF_TOP_BUILDDIR
  43 CF_SUBST_NCURSES_VERSION
  44
  45 CF_WITH_REL_VERSION(NCURSES)
  46 CF_WITH_ABI_VERSION
  47
  48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
  49 AC_ARG_WITH(system-type,
  50 [  --with-system-type=XXX  test: override derived host system-type],
  51 [AC_MSG_WARN(overriding system type to $withval)
  52  cf_cv_system_name=$withval])
  53
  54 ###     Save the given $CFLAGS to allow user-override.
  55 cf_user_CFLAGS="$CFLAGS"
  56
  57 ###     Default install-location
  58 CF_CFG_DEFAULTS
  59
  60 ###     Checks for programs.
  61 AC_PROG_CC
  62 CF_GCC_VERSION
  63
  64 AC_PROG_CPP
  65 AC_PROG_GCC_TRADITIONAL
  66 CF_PROG_CC_C_O(CC)
  67 AC_ISC_POSIX
  68 CF_ANSI_CC_REQD
  69 CF_PROG_EXT
  70 CF_PROG_LDCONFIG
  71
  72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  73 dnl                             configure script by not letting us test if C++
  74 dnl                             is present, making this option necessary.
  75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  76 AC_ARG_WITH(cxx,
  77         [  --without-cxx           do not adjust ncurses bool to match C++],
  78         [cf_with_cxx=$withval],
  79         [cf_with_cxx=yes])
  80 AC_MSG_RESULT($cf_with_cxx)
  81 if test "X$cf_with_cxx" = Xno ; then
  82         CXX=""
  83         GXX=""
  84 else
  85         # with autoconf 2.13, we can change the error to a warning:
  86         pushdef([AC_MSG_ERROR],
  87                 [AC_MSG_RESULT(no)
  88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
  89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
  90         AC_PROG_CXX
  91         popdef([AC_MSG_ERROR])dnl
  92         # autoconf 2.5x removed the error - by hardcoding it to g++.
  93         if test "$CXX" = "g++" ; then
  94                 AC_PATH_PROG(CXX,g++)
  95         fi
  96         if test "$CXX" = "g++" ; then
  97                 AC_MSG_WARN(ignoring hardcoded g++)
  98                 cf_with_cxx=no; CXX=""; GXX="";
  99         fi
 100 fi
 101
 102 CF_GXX_VERSION
 103 case $GXX_VERSION in
 104 1*|2.[[0-6]]*)
 105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
 106         # cf_cxx_library=no
 107         AC_MSG_WARN(templates do not work)
 108         ;;
 109 esac
 110
 111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 112 AC_ARG_WITH(cxx-binding,
 113         [  --without-cxx-binding   do not build C++ binding and demo],
 114         [cf_with_cxx_binding=$withval],
 115         [cf_with_cxx_binding=$cf_with_cxx])
 116 AC_MSG_RESULT($cf_with_cxx_binding)
 117
 118 AC_MSG_CHECKING(if you want to build with Ada95)
 119 AC_ARG_WITH(ada,
 120         [  --without-ada           suppress check for Ada95, don't build demo],
 121         [cf_with_ada=$withval],
 122         [cf_with_ada=yes])
 123 AC_MSG_RESULT($cf_with_ada)
 124
 125 AC_MSG_CHECKING(if you want to install manpages)
 126 AC_ARG_WITH(manpages,
 127         [  --without-manpages      suppress install of manpages],
 128         [cf_with_manpages=$withval],
 129         [cf_with_manpages=yes])
 130 AC_MSG_RESULT($cf_with_manpages)
 131
 132 AC_MSG_CHECKING(if you want to build programs such as tic)
 133 AC_ARG_WITH(progs,
 134         [  --without-progs         suppress build with programs (e.g., tic)],
 135         [cf_with_progs=$withval],
 136         [cf_with_progs=yes])
 137 AC_MSG_RESULT($cf_with_progs)
 138
 139 AC_MSG_CHECKING(if you want to build test-programs)
 140 AC_ARG_WITH(tests,
 141         [  --without-tests         suppress build with test-programs],
 142         [cf_with_tests=$withval],
 143         [cf_with_tests=yes])
 144 AC_MSG_RESULT($cf_with_tests)
 145
 146 AC_MSG_CHECKING(if you wish to install curses.h)
 147 AC_ARG_WITH(curses-h,
 148         [  --without-curses-h      install curses.h as ncurses.h only],
 149         [with_curses_h=$withval],
 150         [with_curses_h=yes])
 151 AC_MSG_RESULT($with_curses_h)
 152
 153 modules_to_build="ncurses"
 154 if test "X$cf_with_progs" != Xno ; then
 155 modules_to_build="$modules_to_build progs tack"
 156 fi
 157 modules_to_build="$modules_to_build panel menu form"
 158
 159 AC_ARG_PROGRAM
 160
 161 CF_PROG_AWK
 162 CF_PROG_EGREP
 163 CF_PROG_INSTALL
 164 CF_PROG_LINT
 165 CF_PROG_LN_S
 166
 167 AC_SYS_LONG_FILE_NAMES
 168
 169 # if we find pkg-config, check if we should install the ".pc" files.
 170 CF_PKG_CONFIG
 171 CF_WITH_PKG_CONFIG_LIBDIR
 172 CF_ENABLE_PC_FILES
 173
 174 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 175 AC_ARG_ENABLE(mixed-case,
 176         [  --enable-mixed-case     tic should assume mixed-case filenames],
 177         [enable_mixedcase=$enableval],
 178         [enable_mixedcase=auto])
 179 AC_MSG_RESULT($enable_mixedcase)
 180 if test "$enable_mixedcase" = "auto" ; then
 181     CF_MIXEDCASE_FILENAMES
 182 else
 183     cf_cv_mixedcase=$enable_mixedcase
 184     if test "$enable_mixedcase" = "yes" ; then
 185         AC_DEFINE(MIXEDCASE_FILENAMES)
 186     fi
 187 fi
 188
 189 # do this after mixed-case option (tags/TAGS is not as important as tic).
 190 AC_PROG_MAKE_SET
 191 CF_MAKE_TAGS
 192 CF_MAKEFLAGS
 193
 194 dnl These are standard among *NIX systems, but not when cross-compiling
 195 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 196 AC_CHECK_TOOL(LD, ld, ld)
 197 AC_CHECK_TOOL(AR, ar, ar)
 198 CF_AR_FLAGS
 199
 200 dnl Special option for use by system-builders: the install-prefix is used to
 201 dnl adjust the location into which the actual install is done, so that an
 202 dnl archive can be built without modifying the host system's configuration.
 203 AC_MSG_CHECKING(if you have specified an install-prefix)
 204 AC_ARG_WITH(install-prefix,
 205         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 206         [case "$withval" in #(vi
 207         yes|no) #(vi
 208                 ;;
 209         *)      DESTDIR="$withval"
 210                 ;;
 211         esac])
 212 AC_MSG_RESULT($DESTDIR)
 213 AC_SUBST(DESTDIR)
 214
 215 ###############################################################################
 216 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 217 # If we're cross-compiling, allow the user to override the tools and their
 218 # options.  The configure script is oriented toward identifying the host
 219 # compiler, etc., but we need a build compiler to generate parts of the source.
 220 CF_BUILD_CC
 221
 222 ###############################################################################
 223 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 224
 225 ### Options to allow the user to specify the set of libraries which are used.
 226 ### Use "--without-normal --with-shared" to allow the default model to be
 227 ### shared, for example.
 228 cf_list_models=""
 229 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 230
 231 CF_WITH_LIBTOOL
 232 if test "$with_libtool" != "no" ; then
 233
 234 cf_list_models="$cf_list_models libtool"
 235
 236 else
 237
 238 AC_MSG_CHECKING(if you want to build shared libraries)
 239 AC_ARG_WITH(shared,
 240         [  --with-shared           generate shared-libraries],
 241         [with_shared=$withval],
 242         [with_shared=no])
 243 AC_MSG_RESULT($with_shared)
 244 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
 245
 246 AC_MSG_CHECKING(if you want to build static libraries)
 247 AC_ARG_WITH(normal,
 248         [  --with-normal           generate normal-libraries (default)],
 249         [with_normal=$withval],
 250         [with_normal=yes])
 251 AC_MSG_RESULT($with_normal)
 252 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
 253
 254 AC_MSG_CHECKING(if you want to build debug libraries)
 255 AC_ARG_WITH(debug,
 256         [  --with-debug            generate debug-libraries (default)],
 257         [with_debug=$withval],
 258         [with_debug=yes])
 259 AC_MSG_RESULT($with_debug)
 260 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
 261
 262 AC_MSG_CHECKING(if you want to build profiling libraries)
 263 AC_ARG_WITH(profile,
 264         [  --with-profile          generate profile-libraries],
 265         [with_profile=$withval],
 266         [with_profile=no])
 267 AC_MSG_RESULT($with_profile)
 268 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
 269
 270 fi
 271
 272 ###############################################################################
 273
 274 AC_MSG_CHECKING(for specified models)
 275 test -z "$cf_list_models" && cf_list_models=normal
 276 dnl If we use libtool to generate libraries, then it must be the only
 277 dnl specified model.
 278 test "$with_libtool" != "no" && cf_list_models=libtool
 279 AC_MSG_RESULT($cf_list_models)
 280
 281 ### Use the first model as the default, and save its suffix for use in building
 282 ### up test-applications.
 283 AC_MSG_CHECKING(for default model)
 284 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 285 AC_MSG_RESULT($DFT_LWR_MODEL)
 286
 287 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 288
 289 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 290 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 291
 292 TICS_NAME=tic
 293 AC_SUBST(TICS_NAME)
 294
 295 TINFO_NAME=tinfo
 296 AC_SUBST(TINFO_NAME)
 297
 298 LIB_NAME=ncurses
 299 AC_SUBST(LIB_NAME)
 300
 301 LIB_DIR=../lib
 302 LIB_2ND=../../lib
 303
 304 CF_WITH_LIB_PREFIX(cf_prefix)
 305
 306 LIB_SUFFIX=
 307 AC_SUBST(LIB_SUFFIX)
 308
 309 ###############################################################################
 310
 311 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 312 AC_ARG_WITH(termlib,
 313         [  --with-termlib          generate separate terminfo library],
 314         [with_termlib=$withval],
 315         [with_termlib=no])
 316 AC_MSG_RESULT($with_termlib)
 317
 318 AC_MSG_CHECKING(if you want to build a separate tic library)
 319 AC_ARG_WITH(ticlib,
 320         [  --with-ticlib           generate separate tic library],
 321         [with_ticlib=$withval],
 322         [with_ticlib=no])
 323 AC_MSG_RESULT($with_ticlib)
 324
 325 ### Checks for special libraries, must be done up-front.
 326 SHLIB_LIST=""
 327 CF_WITH_GPM
 328 if test "$with_gpm" != no ; then
 329         AC_MSG_CHECKING(if you want to load GPM dynamically)
 330         AC_ARG_WITH(dlsym,
 331                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 332                 [with_dlsym=$withval],
 333                 [with_dlsym=yes])
 334         AC_MSG_RESULT($with_dlsym)
 335         if test "$with_dlsym" = yes ; then
 336                 CF_FUNC_DLSYM
 337                 if test "$with_gpm" != yes ; then
 338                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 339                         cf_cv_gpm_soname="$with_gpm"
 340                 else
 341                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 342                 fi
 343                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
 344                 SHLIB_LIST="-ldl $SHLIB_LIST"
 345         else
 346                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 347                 CF_ADD_LIB(gpm,TEST_LIBS)
 348         fi
 349         AC_DEFINE(HAVE_LIBGPM)
 350         CF_CHECK_GPM_WGETCH
 351 fi
 352
 353 CF_WITH_SYSMOUSE
 354
 355 dnl Not all ports of gcc support the -g option
 356
 357 if test X"$CC_G_OPT" = X"" ; then
 358         CC_G_OPT='-g'
 359         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
 360 fi
 361 AC_SUBST(CC_G_OPT)
 362
 363 if test X"$CXX_G_OPT" = X"" ; then
 364         CXX_G_OPT='-g'
 365         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
 366 fi
 367 AC_SUBST(CXX_G_OPT)
 368
 369 AC_MSG_CHECKING(for default loader flags)
 370 case $DFT_LWR_MODEL in
 371 libtool) LD_MODEL=''   ;;
 372 normal)  LD_MODEL=''   ;;
 373 debug)   LD_MODEL=$CC_G_OPT ;;
 374 profile) LD_MODEL='-pg';;
 375 shared)  LD_MODEL=''   ;;
 376 esac
 377 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 378 AC_MSG_RESULT($LD_MODEL)
 379
 380 case $DFT_LWR_MODEL in
 381 shared)
 382 CF_ENABLE_RPATH
 383 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 384 AC_ARG_ENABLE(relink,
 385 [  --disable-relink        relink shared libraries during install],
 386 [cf_cv_do_relink=$enableval],
 387 [cf_cv_do_relink=yes])
 388 AC_MSG_RESULT($cf_cv_do_relink)
 389         ;;
 390 esac
 391
 392 CF_SHARED_OPTS
 393 if test "$CC_SHARED_OPTS" = "unknown"; then
 394         for model in $cf_list_models; do
 395                 if test "$model" = "shared"; then
 396                         AC_ERROR(Shared libraries are not supported in this version)
 397                 fi
 398         done
 399 fi
 400
 401 ### If we're building with rpath, try to link non-standard libs that way too.
 402 if test "$DFT_LWR_MODEL" = "shared"; then
 403         CF_DISABLE_RPATH_HACK
 404 fi
 405
 406 ###############################################################################
 407 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 408
 409 ###     use option --disable-overwrite to leave out the link to -lcurses
 410 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 411 AC_ARG_ENABLE(overwrite,
 412         [  --disable-overwrite     leave out the link to -lcurses],
 413         [with_overwrite=$enableval],
 414         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 415 AC_MSG_RESULT($with_overwrite)
 416
 417 AC_MSG_CHECKING(if external terminfo-database is used)
 418 AC_ARG_ENABLE(database,
 419         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 420         [use_database=$enableval],
 421         [use_database=yes])
 422 AC_MSG_RESULT($use_database)
 423
 424 case $host_os in #(vi
 425 os2*) #(vi
 426         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 427         ;;
 428 *) #(vi
 429         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 430         ;;
 431 esac
 432 AC_SUBST(TERMINFO_SRC)
 433
 434 if test "$use_database" != no ; then
 435         AC_DEFINE(USE_DATABASE)
 436
 437         AC_MSG_CHECKING(which terminfo source-file will be installed)
 438         AC_ARG_WITH(database,
 439                 [  --with-database=XXX     specify terminfo source to install],
 440                 [TERMINFO_SRC=$withval])
 441         AC_MSG_RESULT($TERMINFO_SRC)
 442
 443         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 444         AC_ARG_WITH(hashed-db,
 445                 [  --with-hashed-db        specify hashed-database library],,
 446                 [with_hashed_db=no])
 447         AC_MSG_RESULT($with_hashed_db)
 448 else
 449         with_hashed_db=no
 450 fi
 451
 452 AC_MSG_CHECKING(for list of fallback descriptions)
 453 AC_ARG_WITH(fallbacks,
 454         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 455         [with_fallback=$withval],
 456         [with_fallback=])
 457 AC_MSG_RESULT($with_fallback)
 458 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 459 AC_SUBST(FALLBACK_LIST)
 460
 461 AC_MSG_CHECKING(if you want modern xterm or antique)
 462 AC_ARG_WITH(xterm-new,
 463         [  --without-xterm-new     specify if xterm terminfo should be old version],
 464         [with_xterm_new=$withval],
 465         [with_xterm_new=yes])
 466 case $with_xterm_new in
 467 no)     with_xterm_new=xterm-old;;
 468 *)      with_xterm_new=xterm-new;;
 469 esac
 470 AC_MSG_RESULT($with_xterm_new)
 471 WHICH_XTERM=$with_xterm_new
 472 AC_SUBST(WHICH_XTERM)
 473
 474 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
 475 AC_ARG_WITH(xterm-kbs,
 476         [  --with-xterm-kbs=XXX     specify if xterm backspace sends BS or DEL],
 477         [with_xterm_kbs=$withval],
 478         [with_xterm_kbs=BS])
 479 case x$with_xterm_kbs in
 480 xyes|xno|xBS|xbs|x8)
 481         with_xterm_kbs=BS
 482         ;;
 483 xDEL|xdel|x127)
 484         with_xterm_kbs=DEL
 485         ;;
 486 *)
 487         with_xterm_kbs=$withval
 488         ;;
 489 esac
 490 AC_MSG_RESULT($with_xterm_kbs)
 491 XTERM_KBS=$with_xterm_kbs
 492 AC_SUBST(XTERM_KBS)
 493
 494 MAKE_TERMINFO=
 495 if test "$use_database" = no ; then
 496         TERMINFO="${datadir}/terminfo"
 497         MAKE_TERMINFO="#"
 498 else
 499
 500 AC_MSG_CHECKING(for list of terminfo directories)
 501 CF_WITH_PATHLIST(terminfo-dirs,
 502         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 503         TERMINFO_DIRS,
 504         DATADIR/terminfo,
 505         ${datadir}/terminfo)
 506 AC_MSG_RESULT($TERMINFO_DIRS)
 507 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
 508
 509 AC_MSG_CHECKING(for default terminfo directory)
 510 CF_WITH_PATH(default-terminfo-dir,
 511         [  --with-default-terminfo-dir=DIR default terminfo directory],
 512         TERMINFO,
 513         DATADIR/terminfo,
 514         ${datadir}/terminfo)
 515 AC_MSG_RESULT($TERMINFO)
 516 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
 517
 518 fi
 519
 520 AC_SUBST(TERMINFO)
 521 AC_SUBST(MAKE_TERMINFO)
 522
 523 ###     use option --disable-big-core to make tic run on small machines
 524 ###     We need 4Mb, check if we can allocate 50% more than that.
 525 AC_MSG_CHECKING(if big-core option selected)
 526 AC_ARG_ENABLE(big-core,
 527         [  --disable-big-core      assume machine has little memory],
 528         [with_big_core=$enableval],
 529         [AC_TRY_RUN([
 530 #include <stdlib.h>
 531 #include <string.h>
 532 int main() {
 533         unsigned long n = 6000000L;
 534         char *s = malloc(n);
 535         if (s != 0)
 536                 s[0] = s[n-1] = 0;
 537         ${cf_cv_main_return:-return}(s == 0);
 538 }],
 539         [with_big_core=yes],
 540         [with_big_core=no],
 541         [with_big_core=no])])
 542 AC_MSG_RESULT($with_big_core)
 543 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
 544
 545 ### ISO C only guarantees 512-char strings, we have tables which load faster
 546 ### when constructed using "big" strings.  More than the C compiler, the awk
 547 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 548 AC_MSG_CHECKING(if big-strings option selected)
 549 AC_ARG_ENABLE(big-strings,
 550         [  --disable-big-strings   assume compiler has only standard-size strings],
 551         [with_big_strings=$enableval],
 552         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 553 AC_MSG_RESULT($with_big_strings)
 554
 555 USE_BIG_STRINGS=0
 556 test "$with_big_strings" = "yes" && USE_BIG_STRINGS=1
 557 AC_SUBST(USE_BIG_STRINGS)
 558
 559 ###     use option --enable-termcap to compile in the termcap fallback support
 560 AC_MSG_CHECKING(if you want termcap-fallback support)
 561 AC_ARG_ENABLE(termcap,
 562         [  --enable-termcap        compile in termcap fallback support],
 563         [with_termcap=$enableval],
 564         [with_termcap=no])
 565 AC_MSG_RESULT($with_termcap)
 566
 567 if test "$with_termcap" != "yes" ; then
 568         if test "$use_database" = no ; then
 569                 if test -z "$with_fallback" ; then
 570                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 571                 fi
 572         fi
 573         AC_DEFINE(PURE_TERMINFO)
 574 else
 575
 576 if test "$with_ticlib" != no ; then
 577         AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 578 fi
 579
 580 AC_DEFINE(USE_TERMCAP)
 581 AC_MSG_CHECKING(for list of termcap files)
 582 CF_WITH_PATHLIST(termpath,
 583         [  --with-termpath=XXX     specify list of termcap files],
 584         TERMPATH,
 585         /etc/termcap:/usr/share/misc/termcap)
 586 AC_MSG_RESULT($TERMPATH)
 587 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
 588
 589 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 590 AC_MSG_CHECKING(if fast termcap-loader is needed)
 591 AC_ARG_ENABLE(getcap,
 592         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 593         [with_getcap=$enableval],
 594         [with_getcap=no])
 595 AC_MSG_RESULT($with_getcap)
 596 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
 597
 598 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 599 AC_ARG_ENABLE(getcap-cache,
 600         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 601         [with_getcap_cache=$enableval],
 602         [with_getcap_cache=no])
 603 AC_MSG_RESULT($with_getcap_cache)
 604 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
 605
 606 fi
 607
 608 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 609 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 610 AC_ARG_ENABLE(home-terminfo,
 611         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 612         [with_home_terminfo=$enableval],
 613         [with_home_terminfo=yes])
 614 AC_MSG_RESULT($with_home_terminfo)
 615 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
 616
 617 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 618 AC_ARG_ENABLE(root-environ,
 619         [  --disable-root-environ  restrict environment when running as root],
 620         [with_root_environ=$enableval],
 621         [with_root_environ=yes])
 622 AC_MSG_RESULT($with_root_environ)
 623 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
 624
 625 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 626 ###   to reduce storage requirements for the terminfo database.
 627 CF_LINK_FUNCS
 628
 629 with_links=no
 630 with_symlinks=no
 631
 632 # soft links (symbolic links) are useful for some systems where hard links do
 633 # not work, or to make it simpler to copy terminfo trees around.
 634 if test "$ac_cv_func_symlink" = yes ; then
 635     AC_MSG_CHECKING(if tic should use symbolic links)
 636     AC_ARG_ENABLE(symlinks,
 637         [  --enable-symlinks       make tic use symbolic links not hard links],
 638         [with_symlinks=$enableval],
 639         [with_symlinks=no])
 640     AC_MSG_RESULT($with_symlinks)
 641 fi
 642
 643 # If we have hard links and did not choose to use soft links instead, there is
 644 # no reason to make this choice optional - use the hard links.
 645 if test "$with_symlinks" = no ; then
 646     AC_MSG_CHECKING(if tic should use hard links)
 647     if test "$ac_cv_func_link" = yes ; then
 648         with_links=yes
 649     else
 650         with_links=no
 651     fi
 652     AC_MSG_RESULT($with_links)
 653 fi
 654
 655 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
 656 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
 657
 658 ###   use option --enable-broken-linker to force on use of broken-linker support
 659 AC_MSG_CHECKING(if you want broken-linker support code)
 660 AC_ARG_ENABLE(broken_linker,
 661         [  --enable-broken_linker  compile with broken-linker support code],
 662         [with_broken_linker=$enableval],
 663         [with_broken_linker=${BROKEN_LINKER:-no}])
 664 AC_MSG_RESULT($with_broken_linker)
 665
 666 BROKEN_LINKER=0
 667 if test "$with_broken_linker" = yes ; then
 668         AC_DEFINE(BROKEN_LINKER)
 669         BROKEN_LINKER=1
 670 elif test "$DFT_LWR_MODEL" = shared ; then
 671         case $cf_cv_system_name in #(vi
 672         cygwin*)
 673                 AC_DEFINE(BROKEN_LINKER)
 674                 BROKEN_LINKER=1
 675                 CF_VERBOSE(cygwin linker is broken anyway)
 676                 ;;
 677         esac
 678 fi
 679 AC_SUBST(BROKEN_LINKER)
 680
 681 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 682 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 683 AC_ARG_ENABLE(bsdpad,
 684         [  --enable-bsdpad         recognize BSD-style prefix padding],
 685         [with_bsdpad=$enableval],
 686         [with_bsdpad=no])
 687 AC_MSG_RESULT($with_bsdpad)
 688 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
 689
 690 ###   use option --enable-widec to turn on use of wide-character support
 691 NCURSES_CH_T=chtype
 692 NCURSES_LIBUTF8=0
 693
 694 NEED_WCHAR_H=0
 695 NCURSES_MBSTATE_T=0
 696 NCURSES_WCHAR_T=0
 697 NCURSES_WINT_T=0
 698
 699 # Check to define _XOPEN_SOURCE "automatically"
 700 CF_XOPEN_SOURCE(500)
 701
 702 # Work around breakage on OS X
 703 CF_SIGWINCH
 704
 705 # Checks for CODESET support.
 706 AM_LANGINFO_CODESET
 707
 708 # use these variables to work around a defect in gcc's fixincludes.
 709 NCURSES_OK_WCHAR_T=
 710 NCURSES_OK_WINT_T=
 711
 712 AC_MSG_CHECKING(if you want wide-character code)
 713 AC_ARG_ENABLE(widec,
 714         [  --enable-widec          compile with wide-char/UTF-8 code],
 715         [with_widec=$enableval],
 716         [with_widec=no])
 717 AC_MSG_RESULT($with_widec)
 718 if test "$with_widec" = yes ; then
 719         LIB_SUFFIX="w${LIB_SUFFIX}"
 720         AC_DEFINE(USE_WIDEC_SUPPORT)
 721         AC_DEFINE(NCURSES_WIDECHAR)
 722
 723         CF_CHECK_WCHAR_H
 724
 725         # with_overwrite=no
 726         NCURSES_CH_T=cchar_t
 727         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 728         if test "$ac_cv_func_putwc" != yes ; then
 729                 CF_UTF8_LIB
 730                 if test "$cf_cv_utf8_lib" != no ; then
 731                         NCURSES_LIBUTF8=1
 732                 fi
 733         fi
 734         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 735         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 736         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 737
 738         if test "$NCURSES_MBSTATE_T" != 0; then
 739                 AC_DEFINE(NEED_MBSTATE_T_DEF)
 740         fi
 741 fi
 742 AC_SUBST(NCURSES_CH_T)
 743 AC_SUBST(NCURSES_LIBUTF8)
 744
 745 AC_SUBST(NEED_WCHAR_H)
 746 AC_SUBST(NCURSES_MBSTATE_T)
 747 AC_SUBST(NCURSES_WCHAR_T)
 748 AC_SUBST(NCURSES_WINT_T)
 749
 750 AC_SUBST(NCURSES_OK_WCHAR_T)
 751 AC_SUBST(NCURSES_OK_WINT_T)
 752
 753 ###   use option --disable-lp64 to allow long chtype
 754 case $cf_cv_abi_version in
 755 [[345]]*)
 756         default_with_lp64=no
 757         ;;
 758 *)
 759         default_with_lp64=yes
 760         ;;
 761 esac
 762
 763 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 764 AC_ARG_ENABLE(lp64,
 765         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 766         [with_lp64=$enableval],
 767         [with_lp64=$default_with_lp64])
 768 AC_MSG_RESULT($with_lp64)
 769
 770 if test "$with_lp64" = yes ; then
 771         cf_cv_enable_lp64=1
 772 else
 773         cf_cv_enable_lp64=0
 774 fi
 775 AC_SUBST(cf_cv_enable_lp64)
 776
 777 CF_LARGEFILE
 778
 779 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 780 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 781 AC_ARG_ENABLE(tparm-varargs,
 782         [  --disable-tparm-varargs compile tparm() without varargs interface],
 783         [with_tparm_varargs=$enableval],
 784         [with_tparm_varargs=yes])
 785 AC_MSG_RESULT($with_tparm_varargs)
 786 NCURSES_TPARM_VARARGS=0
 787 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
 788 AC_SUBST(NCURSES_TPARM_VARARGS)
 789
 790 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
 791 if test "$with_ticlib" != no ; then
 792 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
 793 AC_ARG_ENABLE(tic-depends,
 794         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
 795         [with_tic_depends=$enableval],
 796         [with_tic_depends=yes])
 797 AC_MSG_RESULT($with_tic_depends)
 798 else
 799         with_tic_depends=no
 800 fi
 801
 802 ###   use option --with-bool to override bool's type
 803 AC_MSG_CHECKING(for type of bool)
 804 AC_ARG_WITH(bool,
 805         [  --with-bool=TYPE        override fallback type of bool variable],
 806         [NCURSES_BOOL="$withval"],
 807         [NCURSES_BOOL=auto])
 808 AC_MSG_RESULT($NCURSES_BOOL)
 809 AC_SUBST(NCURSES_BOOL)
 810
 811 AC_MSG_CHECKING(for alternate terminal capabilities file)
 812 AC_ARG_WITH(caps,
 813         [  --with-caps=alt         compile with alternate Caps file],
 814         [TERMINFO_CAPS=Caps.$withval],
 815         [TERMINFO_CAPS=Caps])
 816 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
 817 AC_MSG_RESULT($TERMINFO_CAPS)
 818 AC_SUBST(TERMINFO_CAPS)
 819
 820 ###   use option --with-chtype to override chtype's type
 821 AC_MSG_CHECKING(for type of chtype)
 822 AC_ARG_WITH(chtype,
 823         [  --with-chtype=TYPE      override type of chtype],
 824         [NCURSES_CHTYPE="$withval"],
 825         [NCURSES_CHTYPE=auto])
 826 AC_MSG_RESULT($NCURSES_CHTYPE)
 827
 828 ###   use option --with-ospeed to override ospeed's type
 829 AC_MSG_CHECKING(for type of ospeed)
 830 AC_ARG_WITH(ospeed,
 831         [  --with-ospeed=TYPE      override type of ospeed variable],
 832         [NCURSES_OSPEED="$withval"],
 833         [NCURSES_OSPEED=short])
 834 AC_MSG_RESULT($NCURSES_OSPEED)
 835 AC_SUBST(NCURSES_OSPEED)
 836
 837 ###   use option --with-mmask-t to override mmask_t's type
 838 AC_MSG_CHECKING(for type of mmask_t)
 839 AC_ARG_WITH(mmask-t,
 840         [  --with-mmask-t=TYPE     override type of mmask_t],
 841         [NCURSES_MMASK_T="$withval"],
 842         [NCURSES_MMASK_T=auto])
 843 AC_MSG_RESULT($NCURSES_MMASK_T)
 844
 845 ###   use option --with-ccharw-max to override CCHARW_MAX size
 846 AC_MSG_CHECKING(for size CCHARW_MAX)
 847 AC_ARG_WITH(ccharw-max,
 848         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
 849         [NCURSES_CCHARW_MAX="$withval"],
 850         [NCURSES_CCHARW_MAX=5])
 851 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
 852 AC_SUBST(NCURSES_CCHARW_MAX)
 853
 854 ###   use option --with-tparm-arg to override tparm's argument type
 855 AC_MSG_CHECKING(for type of tparm args)
 856 AC_ARG_WITH(tparm-arg,
 857         [  --with-tparm-arg=TYPE   override parameter type of tparm],
 858         [NCURSES_TPARM_ARG="$withval"],
 859         [NCURSES_TPARM_ARG=long])
 860 AC_MSG_RESULT($NCURSES_TPARM_ARG)
 861 AC_SUBST(NCURSES_TPARM_ARG)
 862
 863 ### Enable compiling-in rcs id's
 864 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
 865 AC_ARG_WITH(rcs-ids,
 866         [  --with-rcs-ids          compile-in RCS identifiers],
 867         [with_rcs_ids=$withval],
 868         [with_rcs_ids=no])
 869 AC_MSG_RESULT($with_rcs_ids)
 870 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
 871
 872 ###############################################################################
 873 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tabs tic toe tput tset ])
 874
 875 ###############################################################################
 876 CF_HELP_MESSAGE(Extensions:)
 877
 878 ### Note that some functions (such as const) are normally disabled anyway.
 879 AC_MSG_CHECKING(if you want to build with function extensions)
 880 AC_ARG_ENABLE(ext-funcs,
 881         [  --disable-ext-funcs     disable function-extensions],
 882         [with_ext_funcs=$enableval],
 883         [with_ext_funcs=yes])
 884 AC_MSG_RESULT($with_ext_funcs)
 885 if test "$with_ext_funcs" = yes ; then
 886         NCURSES_EXT_FUNCS=1
 887         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS)
 888         AC_DEFINE(HAVE_CURSES_VERSION)
 889         AC_DEFINE(HAVE_HAS_KEY)
 890         AC_DEFINE(HAVE_RESIZETERM)
 891         AC_DEFINE(HAVE_RESIZE_TERM)
 892         AC_DEFINE(HAVE_TERM_ENTRY_H)
 893         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
 894         AC_DEFINE(HAVE_USE_SCREEN)
 895         AC_DEFINE(HAVE_USE_WINDOW)
 896         AC_DEFINE(HAVE_WRESIZE)
 897         AC_DEFINE(NCURSES_EXT_FUNCS)
 898         GENERATED_EXT_FUNCS=generated
 899 else
 900         NCURSES_EXT_FUNCS=0
 901         GENERATED_EXT_FUNCS=
 902 fi
 903 AC_SUBST(NCURSES_EXT_FUNCS)
 904 AC_SUBST(GENERATED_EXT_FUNCS)
 905
 906 AC_MSG_CHECKING(if you want to build with experimental SCREEN extensions)
 907 AC_ARG_ENABLE(sp-funcs,
 908         [  --enable-sp-funcs       enable experimental SCREEN-extensions],
 909         [with_sp_funcs=$enableval],
 910         [with_sp_funcs=no])
 911 AC_MSG_RESULT($with_sp_funcs)
 912 if test "$with_sp_funcs" = yes ; then
 913         NCURSES_SP_FUNCS=1
 914         AC_DEFINE(NCURSES_SP_FUNCS)
 915         GENERATED_SP_FUNCS=generated
 916 else
 917         NCURSES_SP_FUNCS=0
 918         GENERATED_SP_FUNCS=
 919 fi
 920 AC_SUBST(NCURSES_SP_FUNCS)
 921 AC_SUBST(GENERATED_SP_FUNCS)
 922
 923 AC_MSG_CHECKING(if you want to build with experimental terminal-driver)
 924 AC_ARG_ENABLE(term-driver,
 925         [  --enable-term-driver    enable experimental terminal-driver],
 926         [with_term_driver=$enableval],
 927         [with_term_driver=no])
 928 AC_MSG_RESULT($with_term_driver)
 929 if test "$with_term_driver" = yes ; then
 930         AC_DEFINE(USE_TERM_DRIVER)
 931         if test "$with_sp_funcs" != yes ; then
 932                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
 933         fi
 934 fi
 935
 936 ###   use option --enable-const to turn on use of const beyond that in XSI.
 937 AC_MSG_CHECKING(for extended use of const keyword)
 938 AC_ARG_ENABLE(const,
 939         [  --enable-const          compile with extra/non-standard const],
 940         [with_ext_const=$enableval],
 941         [with_ext_const=no])
 942 AC_MSG_RESULT($with_ext_const)
 943 NCURSES_CONST='/*nothing*/'
 944 if test "$with_ext_const" = yes ; then
 945         NCURSES_CONST=const
 946 fi
 947 AC_SUBST(NCURSES_CONST)
 948
 949 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
 950 AC_MSG_CHECKING(if you want to use extended colors)
 951 AC_ARG_ENABLE(ext-colors,
 952         [  --enable-ext-colors     compile for 256-color support],
 953         [with_ext_colors=$enableval],
 954         [with_ext_colors=no])
 955 AC_MSG_RESULT($with_ext_colors)
 956 NCURSES_EXT_COLORS=0
 957 if test "$with_ext_colors" = yes ; then
 958         if test "$with_widec" != yes ; then
 959                 AC_MSG_ERROR(This option applies only to wide-character library)
 960         else
 961                 # cannot be ABI 5 since it changes sizeof(cchar_t)
 962                 CF_NCURSES_ABI_6
 963         fi
 964         NCURSES_EXT_COLORS=1
 965         AC_DEFINE(NCURSES_EXT_COLORS)
 966 fi
 967 AC_SUBST(NCURSES_EXT_COLORS)
 968
 969 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
 970 AC_MSG_CHECKING(if you want to use extended mouse encoding)
 971 AC_ARG_ENABLE(ext-mouse,
 972         [  --enable-ext-mouse      compile for extended mouse-encoding],
 973         [with_ext_mouse=$enableval],
 974         [with_ext_mouse=no])
 975 AC_MSG_RESULT($with_ext_mouse)
 976 NCURSES_MOUSE_VERSION=1
 977 if test "$with_ext_mouse" = yes ; then
 978         NCURSES_MOUSE_VERSION=2
 979         CF_NCURSES_ABI_6
 980 fi
 981 AC_SUBST(NCURSES_MOUSE_VERSION)
 982
 983 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
 984 AC_ARG_ENABLE(no-padding,
 985         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
 986         [with_no_padding=$enableval],
 987         [with_no_padding=$with_ext_funcs])
 988 AC_MSG_RESULT($with_no_padding)
 989 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
 990
 991 AC_CHECK_SIZEOF([signed char], 0)
 992 if test "$ac_cv_sizeof_signed_char" = 1 ; then
 993         NCURSES_SBOOL="signed char"
 994 else
 995         NCURSES_SBOOL="char"
 996 fi
 997 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
 998 AC_ARG_ENABLE(signed-char,
 999         [  --enable-signed-char    compile using signed Boolean's in term.h],
1000         [with_signed_char=$enableval],
1001         [with_signed_char=no])
1002 AC_MSG_RESULT($with_signed_char)
1003 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
1004 AC_SUBST(NCURSES_SBOOL)
1005
1006 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1007 AC_MSG_CHECKING(if you want SIGWINCH handler)
1008 AC_ARG_ENABLE(sigwinch,
1009         [  --enable-sigwinch       compile with SIGWINCH handler],
1010         [with_sigwinch=$enableval],
1011         [with_sigwinch=$with_ext_funcs])
1012 AC_MSG_RESULT($with_sigwinch)
1013 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
1014
1015 ###   use option --enable-tcap-names to allow user to define new capabilities
1016 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1017 AC_ARG_ENABLE(tcap-names,
1018         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1019         [with_tcap_names=$enableval],
1020         [with_tcap_names=$with_ext_funcs])
1021 AC_MSG_RESULT($with_tcap_names)
1022 NCURSES_XNAMES=0
1023 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
1024 AC_SUBST(NCURSES_XNAMES)
1025
1026 ###############################################################################
1027 # These options are relatively safe to experiment with.
1028 CF_HELP_MESSAGE(Development Code:)
1029 AC_MSG_CHECKING(if you want all development code)
1030 AC_ARG_WITH(develop,
1031         [  --without-develop       disable development options],
1032         [with_develop=$withval],
1033         [with_develop=no])
1034 AC_MSG_RESULT($with_develop)
1035
1036 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1037 AC_MSG_CHECKING(if you want hard-tabs code)
1038 AC_ARG_ENABLE(hard-tabs,
1039         [  --enable-hard-tabs      compile with hard-tabs code],,
1040         [enable_hard_tabs=$with_develop])
1041 AC_MSG_RESULT($enable_hard_tabs)
1042 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
1043
1044 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1045 AC_MSG_CHECKING(if you want limited support for xmc)
1046 AC_ARG_ENABLE(xmc-glitch,
1047         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1048         [enable_xmc_glitch=$with_develop])
1049 AC_MSG_RESULT($enable_xmc_glitch)
1050 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
1051
1052 ###############################################################################
1053 # These are just experimental, probably should not be in a package:
1054 CF_HELP_MESSAGE(Experimental Code:)
1055
1056 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1057 AC_ARG_ENABLE(assumed-color,
1058         [  --disable-assumed-color do not assume anything about default-colors],
1059         [with_assumed_color=$enableval],
1060         [with_assumed_color=yes])
1061 AC_MSG_RESULT($with_assumed_color)
1062 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
1063
1064 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1065 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1066 AC_ARG_ENABLE(hashmap,
1067         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1068         [with_hashmap=$enableval],
1069         [with_hashmap=yes])
1070 AC_MSG_RESULT($with_hashmap)
1071 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
1072
1073 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1074 AC_MSG_CHECKING(if you want colorfgbg code)
1075 AC_ARG_ENABLE(colorfgbg,
1076         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1077         [with_colorfgbg=$enableval],
1078         [with_colorfgbg=no])
1079 AC_MSG_RESULT($with_colorfgbg)
1080 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
1081
1082 ###   use option --enable-interop to turn on use of bindings used for interop
1083 AC_MSG_CHECKING(if you want interop bindings)
1084 AC_ARG_ENABLE(interop,
1085         [  --enable-interop        compile-in experimental interop bindings],
1086         [with_exp_interop=$enableval],
1087         [with_exp_interop=no])
1088 AC_MSG_RESULT($with_exp_interop)
1089
1090 NCURSES_INTEROP_FUNCS=0
1091 test "$with_exp_interop" = yes && NCURSES_INTEROP_FUNCS=1
1092 AC_SUBST(NCURSES_INTEROP_FUNCS)
1093
1094 # This is still experimental (20080329), but should ultimately be moved to
1095 # the script-block --with-normal, etc.
1096 CF_WITH_PTHREAD
1097
1098 if test "x$with_pthread" != xno; then
1099         AC_CHECK_FUNC(pthread_kill,[
1100                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1101                 AC_ARG_ENABLE(pthreads-eintr,
1102                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1103                         [use_pthreads_eintr=$enableval],
1104                         [use_pthreads_eintr=no])
1105                 AC_MSG_RESULT($use_pthreads_eintr)
1106                 if test $use_pthreads_eintr = yes ; then
1107                         AC_DEFINE(USE_PTHREADS_EINTR)
1108                 fi])
1109
1110         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1111         AC_ARG_ENABLE(weak-symbols,
1112                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1113                 [use_weak_symbols=$enableval],
1114                 [use_weak_symbols=no])
1115         AC_MSG_RESULT($use_weak_symbols)
1116         if test "$use_weak_symbols" = yes ; then
1117                 CF_WEAK_SYMBOLS
1118         else
1119                 cf_cv_weak_symbols=no
1120         fi
1121
1122         if test $cf_cv_weak_symbols = yes ; then
1123                 AC_DEFINE(USE_WEAK_SYMBOLS)
1124         fi
1125 fi
1126
1127 PTHREAD=
1128 if test "$with_pthread" = "yes" ; then
1129     AC_DEFINE(USE_PTHREADS)
1130     enable_reentrant=yes
1131     if test $cf_cv_weak_symbols = yes ; then
1132         PTHREAD=-lpthread
1133     fi
1134 fi
1135 AC_SUBST(PTHREAD)
1136
1137 # Reentrant code has to be opaque; there's little advantage to making ncurses
1138 # opaque outside of that, so there is no --enable-opaque option.  We can use
1139 # this option without --with-pthreads, but this will be always set for
1140 # pthreads.
1141 AC_MSG_CHECKING(if you want experimental reentrant code)
1142 AC_ARG_ENABLE(reentrant,
1143         [  --enable-reentrant      compile with experimental reentrant code],
1144         [with_reentrant=$enableval],
1145         [with_reentrant=no])
1146 AC_MSG_RESULT($with_reentrant)
1147 if test "$with_reentrant" = yes ; then
1148         cf_cv_enable_reentrant=1
1149         cf_cv_enable_opaque="NCURSES_INTERNALS"
1150         NCURSES_OPAQUE=1
1151         NCURSES_SIZE_T=int
1152         if test $cf_cv_weak_symbols = yes ; then
1153                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1154                 CF_ADD_LIB(pthread,TEST_LIBS)
1155                 CF_ADD_LIB(pthread,TEST_LIBS2)
1156         else
1157                 LIB_SUFFIX="t${LIB_SUFFIX}"
1158         fi
1159         AC_DEFINE(USE_REENTRANT)
1160         CF_NCURSES_ABI_6
1161 else
1162         cf_cv_enable_reentrant=0
1163         cf_cv_enable_opaque="NCURSES_OPAQUE"
1164         NCURSES_OPAQUE=0
1165         NCURSES_SIZE_T=short
1166 fi
1167 AC_SUBST(cf_cv_enable_reentrant)
1168 AC_SUBST(cf_cv_enable_opaque)
1169 AC_SUBST(NCURSES_OPAQUE)
1170 AC_SUBST(NCURSES_SIZE_T)
1171
1172 ### Allow using a different wrap-prefix
1173 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1174         AC_MSG_CHECKING(for prefix used to wrap public variables)
1175         AC_ARG_WITH(wrap-prefix,
1176                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1177                 [NCURSES_WRAP_PREFIX=$withval],
1178                 [NCURSES_WRAP_PREFIX=_nc_])
1179         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1180 else
1181         NCURSES_WRAP_PREFIX=_nc_
1182 fi
1183 AC_SUBST(NCURSES_WRAP_PREFIX)
1184 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX")
1185
1186 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1187 AC_ARG_ENABLE(safe-sprintf,
1188         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1189         [with_safe_sprintf=$enableval],
1190         [with_safe_sprintf=no])
1191 AC_MSG_RESULT($with_safe_sprintf)
1192 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
1193
1194 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1195 # when hashmap is used scroll hints are useless
1196 if test "$with_hashmap" = no ; then
1197 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1198 AC_ARG_ENABLE(scroll-hints,
1199         [  --disable-scroll-hints  compile without scroll-hints code],
1200         [with_scroll_hints=$enableval],
1201         [with_scroll_hints=yes])
1202 AC_MSG_RESULT($with_scroll_hints)
1203 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
1204 fi
1205
1206 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1207 AC_ARG_ENABLE(wgetch-events,
1208         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1209         [with_wgetch_events=$enableval],
1210         [with_wgetch_events=no])
1211 AC_MSG_RESULT($with_wgetch_events)
1212 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
1213
1214 ###############################################################################
1215 CF_HELP_MESSAGE(Testing/development Options:)
1216
1217 ###     use option --disable-echo to suppress full display compiling commands
1218 AC_MSG_CHECKING(if you want to display full commands during build)
1219 AC_ARG_ENABLE(echo,
1220         [  --enable-echo           build: display "compiling" commands (default)],
1221         [with_echo=$enableval],
1222         [with_echo=yes])
1223 if test "$with_echo" = yes; then
1224         ECHO_LINK=
1225 else
1226         ECHO_LINK='@ echo linking $@ ... ;'
1227         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1228         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1229 fi
1230 AC_MSG_RESULT($with_echo)
1231 AC_SUBST(ECHO_LINK)
1232
1233 ###     use option --enable-warnings to turn on all gcc warnings
1234 AC_MSG_CHECKING(if you want to see compiler warnings)
1235 AC_ARG_ENABLE(warnings,
1236         [  --enable-warnings       build: turn on GCC compiler warnings],
1237         [with_warnings=$enableval])
1238 AC_MSG_RESULT($with_warnings)
1239
1240 if test "x$with_warnings" = "xyes"; then
1241         CF_ADD_ADAFLAGS(-gnatg)
1242         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
1243         if test "$cf_with_cxx" = yes ; then
1244                 CF_GXX_WARNINGS(Wno-unused)
1245         fi
1246 fi
1247 CF_GCC_ATTRIBUTES
1248 CF_ENABLE_STRING_HACKS
1249
1250 ###     use option --enable-assertions to turn on generation of assertion code
1251 AC_MSG_CHECKING(if you want to enable runtime assertions)
1252 AC_ARG_ENABLE(assertions,
1253         [  --enable-assertions     test: turn on generation of assertion code],
1254         [with_assertions=$enableval],
1255         [with_assertions=no])
1256 AC_MSG_RESULT($with_assertions)
1257 if test -n "$GCC"
1258 then
1259         if test "$with_assertions" = no
1260         then
1261                 AC_DEFINE(NDEBUG)
1262                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1263         else
1264                 CF_ADD_ADAFLAGS(-gnata)
1265         fi
1266 fi
1267
1268 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1269 CF_DISABLE_LEAKS
1270 AC_DEFINE(HAVE_NC_ALLOC_H)
1271
1272 ###     use option --enable-expanded to generate certain macros as functions
1273 AC_ARG_ENABLE(expanded,
1274         [  --enable-expanded       test: generate functions for certain macros],
1275         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1276
1277 ###     use option --disable-macros to suppress macros in favor of functions
1278 AC_ARG_ENABLE(macros,
1279         [  --disable-macros        test: use functions rather than macros],
1280         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1281
1282 # Normally we only add trace() to the debug-library.  Allow this to be
1283 # extended to all models of the ncurses library:
1284 cf_all_traces=no
1285 case "$CFLAGS $CPPFLAGS" in
1286 *-DTRACE*)
1287         cf_all_traces=yes
1288         ;;
1289 esac
1290
1291 AC_MSG_CHECKING(whether to add trace feature to all models)
1292 AC_ARG_WITH(trace,
1293 [  --with-trace            test: add trace() function to all models of ncurses],
1294 [cf_with_trace=$withval],
1295 [cf_with_trace=$cf_all_traces])
1296 AC_MSG_RESULT($cf_with_trace)
1297
1298 if test "$cf_with_trace" = yes ; then
1299         LIB_TRACING=all
1300         ADA_TRACE=TRUE
1301         CF_ADD_CFLAGS(-DTRACE)
1302 else
1303         LIB_TRACING=DEBUG
1304         ADA_TRACE=FALSE
1305 fi
1306
1307 AC_SUBST(ADA_TRACE)
1308
1309 ###     Checks for libraries.
1310 case $cf_cv_system_name in #(vi
1311 *mingw32*) #(vi
1312         ;;
1313 *)
1314 AC_CHECK_FUNC(gettimeofday,
1315         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1316
1317 AC_CHECK_LIB(bsd, gettimeofday,
1318         AC_DEFINE(HAVE_GETTIMEOFDAY)
1319         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1320         ;;
1321 esac
1322
1323 CF_MATH_LIB(MATH_LIB,sin(x))
1324 AC_SUBST(MATH_LIB)
1325
1326 ###     Checks for header files.
1327 AC_STDC_HEADERS
1328 AC_HEADER_DIRENT
1329 AC_HEADER_TIME
1330 CF_REGEX
1331
1332 dnl These are some other potentially nonportable headers.
1333 AC_CHECK_HEADERS( \
1334 fcntl.h \
1335 getopt.h \
1336 limits.h \
1337 locale.h \
1338 math.h \
1339 poll.h \
1340 sys/bsdtypes.h \
1341 sys/ioctl.h \
1342 sys/param.h \
1343 sys/poll.h \
1344 sys/select.h \
1345 sys/time.h \
1346 sys/times.h \
1347 ttyent.h \
1348 unistd.h \
1349 wctype.h \
1350 )
1351
1352 CF_GETOPT_HEADER
1353
1354 # check for ISC (this may also define _POSIX_SOURCE)
1355 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1356 if test "$ISC" = yes ; then
1357         AC_CHECK_LIB(cposix,main)
1358         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1359 fi
1360
1361 CF_SYS_TIME_SELECT
1362
1363 ###     checks for compiler characteristics
1364 AC_LANG_C
1365 AC_C_CONST
1366 CF_C_INLINE(NCURSES_INLINE,1200)
1367 CF_SIG_ATOMIC_T
1368
1369 if test $NCURSES_CHTYPE = auto ; then
1370         CF_TYPEOF_CHTYPE
1371 else
1372         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1373 fi
1374 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1375 AC_SUBST(cf_cv_typeof_chtype)
1376
1377 CF_UNSIGNED_LITERALS
1378 cf_cv_1UL="1"
1379 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1380 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1381 AC_SUBST(cf_cv_1UL)
1382
1383 if test $NCURSES_MMASK_T = auto ; then
1384         cf_cv_typeof_mmask_t=long
1385 else
1386         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1387 fi
1388 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1389 AC_SUBST(cf_cv_typeof_mmask_t)
1390
1391 ###     Checks for external-data
1392 CF_ERRNO
1393 CF_LINK_DATAONLY
1394
1395 ###     Checks for library functions.
1396 AC_CHECK_FUNCS( \
1397 getcwd \
1398 getegid \
1399 geteuid \
1400 getttynam \
1401 issetugid \
1402 poll \
1403 remove \
1404 select \
1405 setbuf \
1406 setbuffer \
1407 setvbuf \
1408 sigaction \
1409 sigvec \
1410 strdup \
1411 strstr \
1412 tcgetpgrp \
1413 times \
1414 vsnprintf \
1415 )
1416 if test "$with_getcap" = "yes" ; then
1417         CF_CGETENT
1418 fi
1419
1420 CF_ISASCII
1421 CF_STRUCT_SIGACTION
1422 CF_FUNC_NANOSLEEP
1423 CF_FUNC_TERMIOS
1424 CF_FUNC_VSSCANF
1425 CF_MKSTEMP
1426
1427 # setup for prototype of fallback for vsscanf()
1428 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1429
1430 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1431 if test "$cross_compiling" = yes ; then
1432         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1433 else
1434         AC_FUNC_SETVBUF_REVERSED
1435 fi
1436 AC_TYPE_SIGNAL
1437 AC_CHECK_TYPE(intptr_t, long)
1438 CF_TYPE_SIGACTION
1439 CF_SIZECHANGE
1440 CF_FUNC_MEMMOVE
1441 CF_FUNC_POLL
1442 CF_VA_COPY
1443 AC_FUNC_VFORK
1444
1445 # special check for test/ditto.c
1446 CF_FUNC_OPENPTY
1447 if test "$cf_cv_func_openpty" != no ; then
1448     AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>)
1449     AC_DEFINE(USE_XTERM_PTY)
1450     if test "$cf_cv_lib_util" = yes ; then
1451         CF_ADD_LIB(util,TEST_LIBS)
1452     fi
1453 fi
1454 AC_SUBST(TEST_LIBS)
1455 AC_SUBST(TEST_LIBS2)
1456
1457 if test "$with_hashed_db" != no ; then
1458         AC_DEFINE(USE_HASHED_DB)
1459         CF_HASHED_DB($with_hashed_db)
1460 fi
1461
1462 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1463 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1464         CF_STRIP_G_OPT(CFLAGS)
1465         CF_STRIP_G_OPT(CXXFLAGS)
1466 fi
1467
1468 # Just in case, check if the C compiler has a bool type.
1469 CF_BOOL_DECL(cf_cv_cc_bool_type)
1470
1471 # Check for C++ compiler characteristics (and ensure that it's there!)
1472 if test -n "$CXX" ; then
1473         AC_LANG_CPLUSPLUS
1474         CF_STDCPP_LIBRARY
1475         CF_PROG_CC_C_O(CXX)
1476
1477         case $GXX_VERSION in
1478         1*|2.[0-6]*)
1479                 cf_cxx_library=yes
1480                 ;;
1481         *-2.7*|2.7*)
1482                 CF_GPP_LIBRARY
1483                 ;;
1484         *)
1485                 cf_cxx_library=no
1486                 ;;
1487         esac
1488
1489         AC_CHECK_HEADERS(typeinfo)
1490         CF_CXX_IOSTREAM_NAMESPACE
1491         CF_BOOL_DECL
1492         CF_BOOL_SIZE
1493         CF_ETIP_DEFINES
1494         CF_CPP_PARAM_INIT
1495         CF_CPP_STATIC_CAST
1496         CF_CXX_AR_FLAGS
1497 else
1498         cf_cxx_library=no
1499         cf_cv_builtin_bool=1
1500
1501         # Just because we are not configuring against C++ right now does not
1502         # mean that a user will not want to use C++.  Some distributors disable
1503         # the C++ portion of this configuration as a shortcut (or just to avoid
1504         # compiling the demo in the c++ directory).  So we need a reasonable
1505         # default for the 'bool' type.
1506         #
1507         # Caveat: since the storage of the bool type is not standardized, it
1508         # may change.
1509
1510         if test "$NCURSES_BOOL" != auto ; then
1511                 cf_cv_type_of_bool=$NCURSES_BOOL
1512                 cf_cv_header_stdbool_h=0
1513         else
1514                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1515                         CF_BOOL_SIZE
1516                 else
1517                         AC_MSG_CHECKING(for fallback type of bool)
1518                         case "$host_cpu" in #(vi
1519                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1520                         *)      cf_cv_type_of_bool=int  ;;
1521                         esac
1522                         AC_MSG_RESULT($cf_cv_type_of_bool)
1523                 fi
1524         fi
1525 fi
1526 AC_SUBST(CXXLIBS)
1527
1528 # If the C compiler did not declare bool, and we did not determine that the C++
1529 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1530 # ncurses library use the same type as C++ bool.  Note that this allows one to
1531 # specify the type of bool in a configure-script option and postpone
1532 # integration with the C++ compiler provided that the types are compatible.
1533 USE_CXX_BOOL=1
1534 if test $cf_cv_cc_bool_type = 1
1535 then
1536         # oops: C has a bool.  Unlikely, but C++ could differ.
1537         USE_CXX_BOOL=0
1538 elif test $cf_cv_builtin_bool = 0
1539 then
1540         # C++ has no bool
1541         USE_CXX_BOOL=0
1542 else
1543         # this is the normal case
1544         USE_CXX_BOOL='defined(__cplusplus)'
1545 fi
1546 AC_SUBST(USE_CXX_BOOL)
1547
1548 CF_HELP_MESSAGE(Ada95 Binding Options:)
1549
1550 dnl If the Ada95 source-tree is present, add that to the build unless it will
1551 dnl not work, or was not requested.
1552 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1553
1554 dnl libtool does not know anything about GNAT, though a change made in 1998
1555 dnl provided for it "someday".  Disable the ada subtree if we are using
1556 dnl libtool -TD 20070714
1557         if test "$cf_with_ada" != "no" ; then
1558                 if test "$with_libtool" != "no"; then
1559                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1560                         cf_with_ada=no
1561                 fi
1562         fi
1563
1564 dnl Check for availability of GNU Ada Translator (GNAT).
1565 dnl At the moment we support no other Ada95 compiler.
1566         if test "$cf_with_ada" != "no" ; then
1567                 CF_PROG_GNAT
1568                 if test "$cf_cv_prog_gnat_correct" = yes; then
1569                         CF_ADD_ADAFLAGS(-gnatpn)
1570
1571                         # make ADAFLAGS consistent with CFLAGS
1572                         case "$CFLAGS" in
1573                         *-g*)
1574                                 CF_ADD_ADAFLAGS(-g)
1575                                 ;;
1576                         esac
1577                         case "$CFLAGS" in
1578                         *-O*)
1579                                 CF_ADD_ADAFLAGS(-O3)
1580                                 ;;
1581                         esac
1582
1583                         CF_GNAT_GENERICS
1584                         CF_GNAT_SIGINT
1585                         CF_GNAT_PRAGMA_UNREF
1586                         CF_GNAT_PROJECTS
1587
1588                         CF_WITH_ADA_COMPILER
1589
1590                         cf_ada_package=terminal_interface
1591                         AC_SUBST(cf_ada_package)
1592
1593                         CF_WITH_ADA_INCLUDE
1594                         CF_WITH_ADA_OBJECTS
1595                         CF_WITH_ADA_SHAREDLIB
1596                 fi
1597         fi
1598 else
1599         cf_with_ada=no
1600 fi
1601
1602 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1603 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1604 ###
1605 ### ticlib modules may be a separate library, otherwise contained in termlib.
1606 ### termlib modules may be a separate library, otherwise contained in ncurses.
1607 ###
1608 ### The of "+" or " " between the tokens controls the way the script
1609 ### chooses to split module lists into libraries.
1610 ###
1611 ### (see CF_LIB_RULES).
1612 AC_MSG_CHECKING(for library subsets)
1613 LIB_SUBSETS=
1614
1615 if test "$cf_with_progs" = yes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1616         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1617         if test "$with_ticlib" != no ; then
1618                 LIB_SUBSETS="${LIB_SUBSETS} "
1619         else
1620                 LIB_SUBSETS="${LIB_SUBSETS}+"
1621         fi
1622 fi
1623
1624 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1625 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1626
1627 if test "$with_termlib" != no ; then
1628         LIB_SUBSETS="${LIB_SUBSETS} "
1629 else
1630         LIB_SUBSETS="${LIB_SUBSETS}+"
1631 fi
1632
1633 LIB_SUBSETS="${LIB_SUBSETS}base"
1634
1635 # Most term-driver calls are to tinfo, but some like init_pair are to the
1636 # base library (so it resides in base).
1637 if test "$with_term_driver" != no ; then
1638         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1639         case $cf_cv_system_name in #(vi
1640         *mingw32*) #(vi
1641                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1642                 ;;
1643         *) #(vi
1644                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1645                 ;;
1646         esac
1647 fi
1648
1649 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1650 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1651
1652 AC_MSG_RESULT($LIB_SUBSETS)
1653
1654 ### Construct the list of include-directories to be generated
1655 CF_INCLUDE_DIRS
1656 CF_ADA_INCLUDE_DIRS
1657
1658 ### Build up pieces for makefile rules
1659 AC_MSG_CHECKING(default library suffix)
1660 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1661 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1662 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1663
1664 AC_MSG_CHECKING(default library-dependency suffix)
1665 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1666 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1667 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1668
1669 AC_MSG_CHECKING(default object directory)
1670 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1671 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1672 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1673
1674 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1675 if test "$cf_with_cxx" = yes ; then
1676 AC_MSG_CHECKING(c++ library-dependency suffix)
1677 if test "$with_libtool" != "no"; then
1678         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1679 else
1680         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)dnl we normally make a static library
1681 fi
1682 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1683 AC_SUBST(CXX_LIB_SUFFIX)
1684 fi
1685
1686 # do not want -ldl in build except as needed for -lncurses dependency
1687 if test "$with_dlsym" = yes ; then
1688 if test $DFT_LWR_MODEL = shared || \
1689    test $DFT_LWR_MODEL = libtool ; then
1690         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1691 fi
1692 fi
1693 ### Set up low-level terminfo dependencies for makefiles.
1694
1695 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1696 # do not need libdl
1697 TICS_LIST=
1698 if test "$with_dlsym" = yes ; then
1699         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1700 fi
1701
1702 if test "$with_ticlib" != no ; then
1703
1704         if test "$with_ticlib" != yes ; then
1705                 TICS_NAME=$with_ticlib
1706                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1707                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1708                 TICS_LIB_SUFFIX="${with_ticlib}"
1709         else
1710                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1711                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1712                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1713         fi
1714         TICS_LDFLAGS="-L${LIB_DIR}"
1715         TICS_LIBS="-l${TICS_LIB_SUFFIX}"
1716 else
1717         TICS_LDFLAGS="-L${LIB_DIR}"
1718         TICS_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX}"
1719 fi
1720 AC_SUBST(TICS_ARG_SUFFIX)
1721 AC_SUBST(TICS_DEP_SUFFIX)
1722 AC_SUBST(TICS_LIB_SUFFIX)
1723 AC_SUBST(TICS_LDFLAGS)
1724 AC_SUBST(TICS_LIBS)
1725
1726 if test "$with_termlib" != no ; then
1727
1728         if test "$with_termlib" != yes ; then
1729                 TINFO_NAME=$with_termlib
1730                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1731                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1732                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1733                 TINFO_LIB_SUFFIX="${with_termlib}"
1734         else
1735                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1736                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1737                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1738                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1739         fi
1740
1741         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1742         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1743         if test "$DFT_LWR_MODEL" = "libtool"; then
1744                 TEST_ARGS="${TEST_DEPS}"
1745                 TEST_ARG2="${TEST_DEP2}"
1746                 TINFO_LDFLAGS="-L${LIB_DIR}"
1747                 TINFO_LIBS="$TEST_ARGS"
1748                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
1749                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
1750         else
1751                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1752                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1753                 if test "x$with_term_driver" != xno ; then
1754                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1755                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1756                         TINFO_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARGS"
1757                 else
1758                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1759                         TINFO_LIBS="$TEST_ARGS"
1760                 fi
1761                 TINFO_LDFLAGS="-L${LIB_DIR}"
1762                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1763         fi
1764 else
1765         # the next lines are needed for linking libtic over libncurses
1766         TINFO_NAME=${LIB_NAME}
1767         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1768         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1769         if test "$with_tic_depends" = yes ; then
1770                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1771         else
1772                 TICS_LIST="$SHLIB_LIST"
1773         fi
1774
1775         TINFO_LDFLAGS="-L${LIB_DIR}"
1776         TINFO_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX}"
1777 fi
1778
1779 if test "$DFT_LWR_MODEL" = shared ; then
1780         case $cf_cv_system_name in #(vi
1781         cygwin*)
1782                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
1783                 TINFO_SUFFIX=.dll
1784                 ;;
1785         esac
1786 fi
1787
1788 AC_SUBST(TINFO_ARG_SUFFIX)
1789 AC_SUBST(TINFO_DEP_SUFFIX)
1790 AC_SUBST(TINFO_LIB_SUFFIX)
1791 AC_SUBST(TINFO_LDFLAGS)
1792 AC_SUBST(TINFO_LIBS)
1793
1794 if test "$with_dlsym" = yes ; then
1795         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1796 fi
1797
1798 if test "$DFT_LWR_MODEL" = "libtool"; then
1799     OBJEXT=lo
1800 fi
1801
1802 # needed for Ada95
1803 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
1804 AC_SUBST(TINFO_LDFLAGS2)
1805
1806 case $DFT_LWR_MODEL in
1807 normal|debug|profile)
1808         CF_LDFLAGS_STATIC
1809         ;;
1810 esac
1811
1812 AC_MSG_CHECKING(where we will install curses.h)
1813 test "$with_overwrite" = no && \
1814 test "x$includedir" = 'x${prefix}/include' && \
1815         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1816 AC_MSG_RESULT($includedir)
1817
1818 ### Resolve a conflict between normal and wide-curses by forcing applications
1819 ### that will need libutf8 to add it to their configure script.
1820 if test "$with_overwrite" != no ; then
1821 if test "$NCURSES_LIBUTF8" = 1 ; then
1822         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1823         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1824 fi
1825 fi
1826 WITH_OVERWRITE=$with_overwrite
1827
1828 AC_SUBST(WITH_OVERWRITE)
1829 AC_SUBST(TICS_LIST)
1830 AC_SUBST(TINFO_LIST)
1831 AC_SUBST(SHLIB_LIST)
1832
1833 # used to separate tack out of the tree
1834 NCURSES_TREE=
1835 AC_SUBST(NCURSES_TREE)
1836
1837 ### predefined stuff for the test programs
1838 AC_DEFINE(HAVE_SLK_COLOR)
1839
1840 ### Construct the list of subdirectories for which we'll customize makefiles
1841 ### with the appropriate compile-rules.
1842
1843 CF_SRC_MODULES($modules_to_build)
1844
1845 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
1846    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${DFT_ARG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
1847    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${DFT_ARG_SUFFIX}-config.1:man/MKada_config.in"
1848 fi
1849
1850 CF_DIRS_TO_MAKE
1851
1852 # symbols that differ when compiling Ada95 by itself.
1853 NCURSES_SHLIB2='sh $(top_srcdir)/misc/shlib'
1854 AC_SUBST(NCURSES_SHLIB2)
1855
1856 # values to use as strings
1857 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR')
1858
1859 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1860
1861 ### Now that we're done running tests, add the compiler-warnings, if any
1862 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1863
1864 ### Define substitutions for header files to avoid name-pollution
1865 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1866 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1867 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1868
1869 ################################################################################
1870 test "$use_database" = yes && \
1871 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1872
1873 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1874 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${DFT_ARG_SUFFIX}${cf_cv_abi_version}-config.1:man/MKncu_config.in"
1875
1876 if test x"$enable_pc_files" = xyes ; then \
1877 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
1878 MAKE_PC_FILES=
1879 else
1880 MAKE_PC_FILES="#"
1881 fi
1882 AC_SUBST(MAKE_PC_FILES)
1883 AC_SUBST(cross_compiling)
1884
1885 AC_PATH_PROG(TIC_PATH,tic,unknown,$PATH:/usr/local/ncurses/bin)
1886 if test -n "$FALLBACK_LIST"
1887 then
1888         if test "$TIC_PATH" = unknown
1889         then
1890                 AC_MSG_WARN(no tic program found for fallbacks)
1891         fi
1892 fi
1893 AC_SUBST(TIC_PATH)
1894
1895 if test "x$cf_with_tests" != xno ; then
1896         MAKE_TESTS=
1897 else
1898         MAKE_TESTS="#"
1899 fi
1900 AC_SUBST(MAKE_TESTS)
1901
1902 ADAHTML_DIR=../../doc/html/ada
1903 AC_SUBST(ADAHTML_DIR)
1904
1905 SUB_SCRIPTS=
1906
1907 AC_OUTPUT( \
1908         include/MKterm.h.awk \
1909         include/curses.head:include/curses.h.in \
1910         include/ncurses_dll.h \
1911         include/termcap.h \
1912         include/unctrl.h \
1913         $SUB_SCRIPTS \
1914         $SUB_MAKEFILES \
1915         Makefile,[
1916 if test "x$cf_with_tests" != xno ; then
1917         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LINK"], test)
1918 fi
1919 CF_LIB_RULES($SRC_SUBDIRS)
1920
1921 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
1922 if test -z "$USE_OLD_MAKERULES" ; then
1923         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
1924 fi
1925 fi
1926 ],[
1927 ### Special initialization commands, used to pass information from the
1928 ### configuration-run into config.status
1929
1930 AWK="$AWK"
1931 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1932 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1933 ECHO_LINK="$ECHO_LINK"
1934 LDCONFIG="$LDCONFIG"
1935 LIBTOOL_VERSION="$LIBTOOL_VERSION"
1936 LIB_NAME="$LIB_NAME"
1937 LIB_PREFIX="$LIB_PREFIX"
1938 LIB_SUBSETS="$LIB_SUBSETS"
1939 LIB_SUFFIX="$LIB_SUFFIX"
1940 LIB_TRACING="$LIB_TRACING"
1941 LN_S="$LN_S"
1942 MAKE_TERMINFO="$MAKE_TERMINFO"
1943 NCURSES_MAJOR="$NCURSES_MAJOR"
1944 NCURSES_MINOR="$NCURSES_MINOR"
1945 NCURSES_OSPEED="$NCURSES_OSPEED"
1946 NCURSES_PATCH="$NCURSES_PATCH"
1947 SRC_SUBDIRS="$SRC_SUBDIRS"
1948 TERMINFO="$TERMINFO"
1949 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1950 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1951 TICS_NAME="$TICS_NAME"
1952 TIC_PATH="$TIC_PATH"
1953 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1954 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1955 TINFO_NAME="$TINFO_NAME"
1956 TINFO_SUFFIX="$TINFO_SUFFIX"
1957 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
1958 WITH_CURSES_H="$with_curses_h"
1959 WITH_ECHO="$with_echo"
1960 WITH_OVERWRITE="$with_overwrite"
1961 cf_LIST_MODELS="$cf_list_models"
1962 cf_cv_abi_version="$cf_cv_abi_version"
1963 cf_cv_do_relink="$cf_cv_do_relink"
1964 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1965 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1966 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1967 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1968 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1969 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
1970 cf_cv_rel_version="$cf_cv_rel_version"
1971 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1972 cf_cv_shared_soname='$cf_cv_shared_soname'
1973 cf_cv_shlib_version="$cf_cv_shlib_version"
1974 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1975 cf_cv_system_name="$cf_cv_system_name"
1976 cf_cv_term_driver="$with_term_driver"
1977 cf_with_ada="$cf_with_ada"
1978 cf_with_cxx_binding="$cf_with_cxx_binding"
1979 cf_with_manpages="$cf_with_manpages"
1980 cf_with_tests="$cf_with_tests"
1981 host="$host"
1982 target="$target"
1983
1984 ],cat)dnl
1985 ${MAKE:-make} preinstall