93542d236ff6656674146c2c973a3afd4031f75e
[ncurses.git] / configure.in
1 dnl***************************************************************************
2 dnl Copyright (c) 1998-2006,2007 Free Software Foundation, Inc.              *
3 dnl                                                                          *
4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
5 dnl copy of this software and associated documentation files (the            *
6 dnl "Software"), to deal in the Software without restriction, including      *
7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
9 dnl copies of the Software, and to permit persons to whom the Software is    *
10 dnl furnished to do so, subject to the following conditions:                 *
11 dnl                                                                          *
12 dnl The above copyright notice and this permission notice shall be included  *
13 dnl in all copies or substantial portions of the Software.                   *
14 dnl                                                                          *
15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
22 dnl                                                                          *
23 dnl Except as contained in this notice, the name(s) of the above copyright   *
24 dnl holders shall not be used in advertising or otherwise to promote the     *
25 dnl sale, use or other dealings in this Software without prior written       *
26 dnl authorization.                                                           *
27 dnl***************************************************************************
28 dnl
29 dnl Author: Thomas E. Dickey 1995-on
30 dnl
31 dnl $Id: configure.in,v 1.389 2007/01/21 00:30:30 tom Exp $
32 dnl Process this file with autoconf to produce a configure script.
33 dnl
34 dnl See http://invisible-island.net/autoconf/ for additional information.
35 dnl
36 dnl ---------------------------------------------------------------------------
37 AC_PREREQ(2.13.20020210)
38 AC_REVISION($Revision: 1.389 $)
39 AC_INIT(ncurses/base/lib_initscr.c)
40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
41
42 CF_TOP_BUILDDIR
43 CF_SUBST_NCURSES_VERSION
44
45 CF_WITH_REL_VERSION(NCURSES)
46 CF_WITH_ABI_VERSION
47
48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
49 AC_ARG_WITH(system-type,
50 [  --with-system-type=XXX  test: override derived host system-type],
51 [AC_MSG_WARN(overriding system type to $withval)
52  cf_cv_system_name=$withval])
53
54 ###     Save the given $CFLAGS to allow user-override.
55 cf_user_CFLAGS="$CFLAGS"
56
57 ###     Default install-location
58 CF_CFG_DEFAULTS
59
60 ###     Checks for programs.
61 AC_PROG_CC
62 CF_GCC_VERSION
63
64 AC_PROG_CPP
65 AC_PROG_GCC_TRADITIONAL
66 CF_PROG_CC_C_O(CC)
67 AC_ISC_POSIX
68 CF_ANSI_CC_REQD
69 CF_PROG_EXT
70 CF_PROG_LDCONFIG
71
72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
73 dnl                             configure script by not letting us test if C++
74 dnl                             is present, making this option necessary.
75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
76 AC_ARG_WITH(cxx,
77         [  --without-cxx           do not adjust ncurses bool to match C++],
78         [cf_with_cxx=$withval],
79         [cf_with_cxx=yes])
80 AC_MSG_RESULT($cf_with_cxx)
81 if test "X$cf_with_cxx" = Xno ; then
82         CXX=""
83         GXX=""
84 else
85         # with autoconf 2.13, we can change the error to a warning:
86         pushdef([AC_MSG_ERROR],
87                 [AC_MSG_RESULT(no)
88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
90         AC_PROG_CXX
91         popdef([AC_MSG_ERROR])dnl
92         # autoconf 2.5x removed the error - by hardcoding it to g++.
93         if test "$CXX" = "g++" ; then
94                 AC_PATH_PROG(CXX,g++)
95         fi
96         if test "$CXX" = "g++" ; then
97                 AC_MSG_WARN(ignoring hardcoded g++)
98                 cf_with_cxx=no; CXX=""; GXX="";
99         fi
100 fi
101
102 CF_GXX_VERSION
103 case $GXX_VERSION in
104 1*|2.[[0-6]]*)
105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
106         # cf_cxx_library=no
107         AC_MSG_WARN(templates do not work)
108         ;;
109 esac
110
111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
112 AC_ARG_WITH(cxx-binding,
113         [  --without-cxx-binding   do not build C++ binding and demo],
114         [cf_with_cxx_binding=$withval],
115         [cf_with_cxx_binding=$cf_with_cxx])
116 AC_MSG_RESULT($cf_with_cxx_binding)
117
118 AC_MSG_CHECKING(if you want to build with Ada95)
119 AC_ARG_WITH(ada,
120         [  --without-ada           suppress check for Ada95, don't build demo],
121         [cf_with_ada=$withval],
122         [cf_with_ada=yes])
123 AC_MSG_RESULT($cf_with_ada)
124
125 AC_MSG_CHECKING(if you want to build programs such as tic)
126 AC_ARG_WITH(progs,
127         [  --without-progs         suppress build with programs (e.g., tic)],
128         [cf_with_progs=$withval],
129         [cf_with_progs=yes])
130 AC_MSG_RESULT($cf_with_progs)
131
132 AC_MSG_CHECKING(if you wish to install curses.h)
133 AC_ARG_WITH(curses-h,
134         [  --without-curses-h      install curses.h as ncurses.h only],
135         [with_curses_h=$withval],
136         [with_curses_h=yes])
137 AC_MSG_RESULT($with_curses_h)
138
139 modules_to_build="ncurses"
140 if test "X$cf_with_progs" != Xno ; then
141 modules_to_build="$modules_to_build progs tack"
142 fi
143 modules_to_build="$modules_to_build panel menu form"
144
145 AC_ARG_PROGRAM
146
147 CF_PROG_AWK
148 CF_PROG_EGREP
149 CF_PROG_INSTALL
150 CF_PROG_LINT
151 AC_PROG_LN_S
152
153 AC_PROG_MAKE_SET
154 CF_MAKE_TAGS
155 CF_MAKEFLAGS
156
157 AC_SYS_LONG_FILE_NAMES
158 CF_MIXEDCASE_FILENAMES
159
160 dnl These are standard among *NIX systems, but not when cross-compiling
161 AC_CHECK_TOOL(RANLIB, ranlib, ':')
162 AC_CHECK_TOOL(LD, ld, ld)
163 AC_CHECK_TOOL(AR, ar, ar)
164 CF_SUBST(archiver options,AR_OPTS,rv)
165
166 dnl Special option for use by system-builders: the install-prefix is used to
167 dnl adjust the location into which the actual install is done, so that an
168 dnl archive can be built without modifying the host system's configuration.
169 AC_MSG_CHECKING(if you have specified an install-prefix)
170 AC_ARG_WITH(install-prefix,
171         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
172         [case "$withval" in #(vi
173         yes|no) #(vi
174                 ;;
175         *)      DESTDIR="$withval"
176                 ;;
177         esac])
178 AC_MSG_RESULT($DESTDIR)
179 AC_SUBST(DESTDIR)
180
181 ###############################################################################
182 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
183 # If we're cross-compiling, allow the user to override the tools and their
184 # options.  The configure script is oriented toward identifying the host
185 # compiler, etc., but we need a build compiler to generate parts of the source.
186 CF_BUILD_CC
187
188 ###############################################################################
189 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
190
191 ### Options to allow the user to specify the set of libraries which are used.
192 ### Use "--without-normal --with-shared" to allow the default model to be
193 ### shared, for example.
194 cf_list_models=""
195 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
196
197 CF_WITH_LIBTOOL
198 if test "$with_libtool" != "no" ; then
199
200 cf_list_models="$cf_list_models libtool"
201
202 else
203
204 AC_MSG_CHECKING(if you want to build shared libraries)
205 AC_ARG_WITH(shared,
206         [  --with-shared           generate shared-libraries],
207         [with_shared=$withval],
208         [with_shared=no])
209 AC_MSG_RESULT($with_shared)
210 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
211
212 AC_MSG_CHECKING(if you want to build static libraries)
213 AC_ARG_WITH(normal,
214         [  --with-normal           generate normal-libraries (default)],
215         [with_normal=$withval],
216         [with_normal=yes])
217 AC_MSG_RESULT($with_normal)
218 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
219
220 AC_MSG_CHECKING(if you want to build debug libraries)
221 AC_ARG_WITH(debug,
222         [  --with-debug            generate debug-libraries (default)],
223         [with_debug=$withval],
224         [with_debug=yes])
225 AC_MSG_RESULT($with_debug)
226 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
227
228 AC_MSG_CHECKING(if you want to build profiling libraries)
229 AC_ARG_WITH(profile,
230         [  --with-profile          generate profile-libraries],
231         [with_profile=$withval],
232         [with_profile=no])
233 AC_MSG_RESULT($with_profile)
234 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
235
236 fi
237
238 ###############################################################################
239
240 AC_MSG_CHECKING(for specified models)
241 test -z "$cf_list_models" && cf_list_models=normal
242 dnl If we use libtool to generate libraries, then it must be the only
243 dnl specified model.
244 test "$with_libtool" != "no" && cf_list_models=libtool
245 AC_MSG_RESULT($cf_list_models)
246
247 ### Use the first model as the default, and save its suffix for use in building
248 ### up test-applications.
249 AC_MSG_CHECKING(for default model)
250 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
251 AC_MSG_RESULT($DFT_LWR_MODEL)
252
253 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
254
255 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
256 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
257
258 TICS_NAME=tic
259 AC_SUBST(TICS_NAME)
260
261 TINFO_NAME=tinfo
262 AC_SUBST(TINFO_NAME)
263
264 LIB_NAME=ncurses
265 AC_SUBST(LIB_NAME)
266
267 LIB_DIR=../lib
268 LIB_2ND=../../lib
269
270 CF_LIB_PREFIX(cf_prefix)
271 LIB_PREFIX=$cf_prefix
272 AC_SUBST(LIB_PREFIX)
273
274 LIB_SUFFIX=
275 AC_SUBST(LIB_SUFFIX)
276
277 ###############################################################################
278
279 AC_MSG_CHECKING(if you want to build a separate terminfo library)
280 AC_ARG_WITH(termlib,
281         [  --with-termlib          generate separate terminfo library],
282         [with_termlib=$withval],
283         [with_termlib=no])
284 AC_MSG_RESULT($with_termlib)
285
286 AC_MSG_CHECKING(if you want to build a separate tic library)
287 AC_ARG_WITH(ticlib,
288         [  --with-ticlib           generate separate tic library],
289         [with_ticlib=$withval],
290         [with_ticlib=no])
291 AC_MSG_RESULT($with_ticlib)
292
293 ### Checks for special libraries, must be done up-front.
294 SHLIB_LIST=""
295 CF_WITH_GPM
296 if test "$with_gpm" != no ; then
297         AC_MSG_CHECKING(if you want to load GPM dynamically)
298         AC_ARG_WITH(dlsym,
299                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
300                 [with_dlsym=$withval],
301                 [with_dlsym=yes])
302         AC_MSG_RESULT($with_dlsym)
303         if test "$with_dlsym" = yes ; then
304                 CF_FUNC_DLSYM
305                 if test "$with_gpm" != yes ; then
306                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
307                         cf_cv_gpm_soname="$with_gpm"
308                 else
309                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
310                 fi
311                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
312                 SHLIB_LIST="-ldl $SHLIB_LIST"
313         else
314                 SHLIB_LIST="-lgpm $SHLIB_LIST"
315         fi
316         AC_DEFINE(HAVE_LIBGPM)
317         AC_CHECK_LIB(gpm,Gpm_Wgetch,[
318                 AC_MSG_WARN(GPM library is already linked with curses - read the FAQ)
319         ])
320 fi
321
322 CF_WITH_SYSMOUSE
323
324 dnl Not all ports of gcc support the -g option
325
326 if test X"$CC_G_OPT" = X"" ; then
327         CC_G_OPT='-g'
328         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
329 fi
330 AC_SUBST(CC_G_OPT)
331
332 if test X"$CXX_G_OPT" = X"" ; then
333         CXX_G_OPT='-g'
334         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
335 fi
336 AC_SUBST(CXX_G_OPT)
337
338 AC_MSG_CHECKING(for default loader flags)
339 case $DFT_LWR_MODEL in
340 libtool) LD_MODEL=''   ;;
341 normal)  LD_MODEL=''   ;;
342 debug)   LD_MODEL=$CC_G_OPT ;;
343 profile) LD_MODEL='-pg';;
344 shared)  LD_MODEL=''   ;;
345 esac
346 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
347 AC_MSG_RESULT($LD_MODEL)
348
349 AC_MSG_CHECKING(if rpath option should be used)
350 AC_ARG_ENABLE(rpath,
351 [  --enable-rpath          use rpath option when generating shared libraries],
352 [cf_cv_ld_rpath=$enableval],
353 [cf_cv_ld_rpath=no])
354 AC_MSG_RESULT($cf_cv_ld_rpath)
355
356 CF_SHARED_OPTS
357 if test "$CC_SHARED_OPTS" = "unknown"; then
358         for model in $cf_list_models; do
359                 if test "$model" = "shared"; then
360                         AC_ERROR(Shared libraries are not supported in this version)
361                 fi
362         done
363 fi
364
365 ###############################################################################
366 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
367
368 ###     use option --disable-overwrite to leave out the link to -lcurses
369 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
370 AC_ARG_ENABLE(overwrite,
371         [  --disable-overwrite     leave out the link to -lcurses],
372         [with_overwrite=$enableval],
373         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
374 AC_MSG_RESULT($with_overwrite)
375
376 AC_MSG_CHECKING(if external terminfo-database is used)
377 AC_ARG_ENABLE(database,
378         [  --disable-database      do not use terminfo, only fallbacks/termcap],
379         [use_database=$enableval],
380         [use_database=yes])
381 AC_MSG_RESULT($use_database)
382
383 case $host_os in #(vi
384 os2*) #(vi
385         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
386         ;;
387 *) #(vi
388         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
389         ;;
390 esac
391 AC_SUBST(TERMINFO_SRC)
392
393 CF_PATHSEP
394 if test "$use_database" != no ; then
395         AC_DEFINE(USE_DATABASE)
396
397         AC_MSG_CHECKING(which terminfo source-file will be installed)
398         AC_ARG_ENABLE(database,
399                 [  --with-database=XXX     specify terminfo source to install],
400                 [TERMINFO_SRC=$withval])
401         AC_MSG_RESULT($TERMINFO_SRC)
402
403         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
404         AC_ARG_WITH(hashed-db,
405                 [  --with-hashed-db        specify hashed-database library],,
406                 [with_hashed_db=no])
407         AC_MSG_RESULT($with_hashed_db)
408 fi
409
410 AC_MSG_CHECKING(for list of fallback descriptions)
411 AC_ARG_WITH(fallbacks,
412         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
413         [with_fallback=$withval],
414         [with_fallback=])
415 AC_MSG_RESULT($with_fallback)
416 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
417 AC_SUBST(FALLBACK_LIST)
418
419 AC_MSG_CHECKING(if you want modern xterm or antique)
420 AC_ARG_WITH(xterm-new,
421         [  --without-xterm-new     specify if xterm terminfo should be old version],
422         [with_xterm_new=$withval],
423         [with_xterm_new=yes])
424 case $with_xterm_new in
425 no)     with_xterm_new=xterm-old;;
426 *)      with_xterm_new=xterm-new;;
427 esac
428 AC_MSG_RESULT($with_xterm_new)
429 WHICH_XTERM=$with_xterm_new
430 AC_SUBST(WHICH_XTERM)
431
432 MAKE_TERMINFO=
433 if test "$use_database" = no ; then
434         TERMINFO="${datadir}/terminfo"
435         MAKE_TERMINFO="#"
436 else
437
438 AC_MSG_CHECKING(for list of terminfo directories)
439 CF_WITH_PATHLIST(terminfo-dirs,
440         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
441         TERMINFO_DIRS,
442         DATADIR/terminfo,
443         ${datadir}/terminfo)
444 AC_MSG_RESULT($TERMINFO_DIRS)
445 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
446
447 AC_MSG_CHECKING(for default terminfo directory)
448 CF_WITH_PATH(default-terminfo-dir,
449         [  --with-default-terminfo-dir=DIR default terminfo directory],
450         TERMINFO,
451         DATADIR/terminfo,
452         ${datadir}/terminfo)
453 AC_MSG_RESULT($TERMINFO)
454 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
455
456 fi
457
458 AC_SUBST(TERMINFO)
459 AC_SUBST(MAKE_TERMINFO)
460
461 ###     use option --disable-big-core to make tic run on small machines
462 ###     We need 4Mb, check if we can allocate 50% more than that.
463 AC_MSG_CHECKING(if big-core option selected)
464 AC_ARG_ENABLE(big-core,
465         [  --disable-big-core      assume machine has little memory],
466         [with_big_core=$enableval],
467         [AC_TRY_RUN([
468 #include <stdlib.h>
469 #include <string.h>
470 int main() {
471         unsigned long n = 6000000L;
472         char *s = malloc(n);
473         if (s != 0)
474                 s[0] = s[n-1] = 0;
475         ${cf_cv_main_return:-return}(s == 0);
476 }],
477         [with_big_core=yes],
478         [with_big_core=no],
479         [with_big_core=no])])
480 AC_MSG_RESULT($with_big_core)
481 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
482
483 ###     use option --enable-termcap to compile in the termcap fallback support
484 AC_MSG_CHECKING(if you want termcap-fallback support)
485 AC_ARG_ENABLE(termcap,
486         [  --enable-termcap        compile in termcap fallback support],
487         [with_termcap=$enableval],
488         [with_termcap=no])
489 AC_MSG_RESULT($with_termcap)
490
491 if test "$with_termcap" != "yes" ; then
492         if test "$use_database" = no ; then
493                 if test -z "$with_fallback" ; then
494                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
495                 fi
496         fi
497         AC_DEFINE(PURE_TERMINFO)
498 else
499
500 AC_DEFINE(USE_TERMCAP)
501 AC_MSG_CHECKING(for list of termcap files)
502 CF_WITH_PATHLIST(termpath,
503         [  --with-termpath=XXX     specify list of termcap files],
504         TERMPATH,
505         /etc/termcap:/usr/share/misc/termcap)
506 AC_MSG_RESULT($TERMPATH)
507 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
508
509 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
510 AC_MSG_CHECKING(if fast termcap-loader is needed)
511 AC_ARG_ENABLE(getcap,
512         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
513         [with_getcap=$enableval],
514         [with_getcap=no])
515 AC_MSG_RESULT($with_getcap)
516 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
517
518 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
519 AC_ARG_ENABLE(getcap-cache,
520         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
521         [with_getcap_cache=$enableval],
522         [with_getcap_cache=no])
523 AC_MSG_RESULT($with_getcap_cache)
524 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
525
526 fi
527
528 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
529 AC_MSG_CHECKING(if ~/.terminfo is wanted)
530 AC_ARG_ENABLE(home-terminfo,
531         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
532         [with_home_terminfo=$enableval],
533         [with_home_terminfo=yes])
534 AC_MSG_RESULT($with_home_terminfo)
535 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
536
537 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
538 AC_ARG_ENABLE(root-environ,
539         [  --disable-root-environ  restrict environment when running as root],
540         [with_root_environ=$enableval],
541         [with_root_environ=yes])
542 AC_MSG_RESULT($with_root_environ)
543 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
544
545 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
546 ###   to reduce storage requirements for the terminfo database.
547 CF_LINK_FUNCS
548
549 with_links=no
550 with_symlinks=no
551
552 # soft links (symbolic links) are useful for some systems where hard links do
553 # not work, or to make it simpler to copy terminfo trees around.
554 if test "$ac_cv_func_symlink" = yes ; then
555     AC_MSG_CHECKING(if tic should use symbolic links)
556     AC_ARG_ENABLE(symlinks,
557         [  --enable-symlinks       make tic use symbolic links not hard links],
558         [with_symlinks=$enableval],
559         [with_symlinks=no])
560     AC_MSG_RESULT($with_symlinks)
561 fi
562
563 # If we have hard links and did not choose to use soft links instead, there is
564 # no reason to make this choice optional - use the hard links.
565 if test "$with_symlinks" = no ; then
566     AC_MSG_CHECKING(if tic should use hard links)
567     if test "$ac_cv_func_link" = yes ; then
568         with_links=yes
569     else
570         with_links=no
571     fi
572     AC_MSG_RESULT($with_links)
573 fi
574
575 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
576 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
577
578 ###   use option --enable-broken-linker to force on use of broken-linker support
579 AC_MSG_CHECKING(if you want broken-linker support code)
580 AC_ARG_ENABLE(broken_linker,
581         [  --enable-broken_linker  compile with broken-linker support code],
582         [with_broken_linker=$enableval],
583         [with_broken_linker=${BROKEN_LINKER-no}])
584 AC_MSG_RESULT($with_broken_linker)
585
586 BROKEN_LINKER=0
587 if test "$with_broken_linker" = yes ; then
588         AC_DEFINE(BROKEN_LINKER)
589         BROKEN_LINKER=1
590 elif test "$DFT_LWR_MODEL" = shared ; then
591         case $cf_cv_system_name in #(vi
592         cygwin*)
593                 AC_DEFINE(BROKEN_LINKER)
594                 BROKEN_LINKER=1
595                 CF_VERBOSE(cygwin linker is broken anyway)
596                 ;;
597         esac
598 fi
599 AC_SUBST(BROKEN_LINKER)
600
601 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
602 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
603 AC_ARG_ENABLE(bsdpad,
604         [  --enable-bsdpad         recognize BSD-style prefix padding],
605         [with_bsdpad=$enableval],
606         [with_bsdpad=no])
607 AC_MSG_RESULT($with_bsdpad)
608 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
609
610 ###   use option --enable-widec to turn on use of wide-character support
611 NCURSES_CH_T=chtype
612 NCURSES_LIBUTF8=0
613
614 NEED_WCHAR_H=0
615 NCURSES_MBSTATE_T=0
616 NCURSES_WCHAR_T=0
617 NCURSES_WINT_T=0
618
619 # Check to define _XOPEN_SOURCE "automatically"
620 CF_XOPEN_SOURCE
621
622 # Work around breakage on OS X
623 CF_SIGWINCH
624
625 # Checks for CODESET support.
626 AM_LANGINFO_CODESET
627
628 # use these variables to work around a defect in gcc's fixincludes.
629 NCURSES_OK_WCHAR_T=
630 NCURSES_OK_WINT_T=
631
632 AC_MSG_CHECKING(if you want wide-character code)
633 AC_ARG_ENABLE(widec,
634         [  --enable-widec          compile with wide-char/UTF-8 code],
635         [with_widec=$enableval],
636         [with_widec=no])
637 AC_MSG_RESULT($with_widec)
638 if test "$with_widec" = yes ; then
639         LIB_SUFFIX="w${LIB_SUFFIX}"
640         AC_DEFINE(USE_WIDEC_SUPPORT)
641         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
642         # with_overwrite=no
643         NCURSES_CH_T=cchar_t
644         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc)
645         if test "$ac_cv_func_putwc" != yes ; then
646                 CF_LIBUTF8
647                 if test "$cf_cv_libutf8" = yes ; then
648                         NCURSES_LIBUTF8=1
649                 fi
650         fi
651         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
652         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
653         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
654
655         if test "$NCURSES_MBSTATE_T" != 0; then
656                 AC_DEFINE(NEED_MBSTATE_T_DEF)
657         fi
658 fi
659 AC_SUBST(NCURSES_CH_T)
660 AC_SUBST(NCURSES_LIBUTF8)
661
662 AC_SUBST(NEED_WCHAR_H)
663 AC_SUBST(NCURSES_MBSTATE_T)
664 AC_SUBST(NCURSES_WCHAR_T)
665 AC_SUBST(NCURSES_WINT_T)
666
667 AC_SUBST(NCURSES_OK_WCHAR_T)
668 AC_SUBST(NCURSES_OK_WINT_T)
669
670 ###   use option --disable-lp64 to allow long chtype
671 case $cf_cv_abi_version in
672 [[345]]*)
673         default_with_lp64=no
674         ;;
675 *)
676         default_with_lp64=yes
677         ;;
678 esac
679
680 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
681 AC_ARG_ENABLE(lp64,
682         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
683         [with_lp64=$enableval],
684         [with_lp64=$default_with_lp64])
685 AC_MSG_RESULT($with_lp64)
686
687 if test "$with_lp64" = yes ; then
688         cf_cv_enable_lp64=1
689 else
690         cf_cv_enable_lp64=0
691 fi
692 AC_SUBST(cf_cv_enable_lp64)
693
694 CF_LARGEFILE
695
696 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
697 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
698 AC_ARG_ENABLE(tparm-varargs,
699         [  --disable-tparm-varargs compile tparm() without varargs interface],
700         [with_tparm_varargs=$enableval],
701         [with_tparm_varargs=yes])
702 AC_MSG_RESULT($with_tparm_varargs)
703 NCURSES_TPARM_VARARGS=0
704 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
705 AC_SUBST(NCURSES_TPARM_VARARGS)
706
707 ###   use option --with-bool to override bool's type
708 AC_MSG_CHECKING(for type of bool)
709 AC_ARG_WITH(bool,
710         [  --with-bool=TYPE        override fallback type of bool variable],
711         [NCURSES_BOOL="$withval"],
712         [NCURSES_BOOL=auto])
713 AC_MSG_RESULT($NCURSES_BOOL)
714 AC_SUBST(NCURSES_BOOL)
715
716 AC_MSG_CHECKING(for alternate terminal capabilities file)
717 AC_ARG_WITH(caps,
718         [  --with-caps=alt         compile with alternate Caps file],
719         [TERMINFO_CAPS=Caps.$withval],
720         [TERMINFO_CAPS=Caps])
721 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
722 AC_MSG_RESULT($TERMINFO_CAPS)
723 AC_SUBST(TERMINFO_CAPS)
724
725 ###   use option --with-chtype to override chtype's type
726 AC_MSG_CHECKING(for type of chtype)
727 AC_ARG_WITH(chtype,
728         [  --with-chtype=TYPE      override type of chtype],
729         [NCURSES_CHTYPE="$withval"],
730         [NCURSES_CHTYPE=auto])
731 AC_MSG_RESULT($NCURSES_CHTYPE)
732
733 ###   use option --with-ospeed to override ospeed's type
734 AC_MSG_CHECKING(for type of ospeed)
735 AC_ARG_WITH(ospeed,
736         [  --with-ospeed=TYPE      override type of ospeed variable],
737         [NCURSES_OSPEED="$withval"],
738         [NCURSES_OSPEED=short])
739 AC_MSG_RESULT($NCURSES_OSPEED)
740 AC_SUBST(NCURSES_OSPEED)
741
742 ###   use option --with-mmask-t to override mmask_t's type
743 AC_MSG_CHECKING(for type of mmask_t)
744 AC_ARG_WITH(mmask-t,
745         [  --with-mmask-t=TYPE     override type of mmask_t],
746         [NCURSES_MMASK_T="$withval"],
747         [NCURSES_MMASK_T=auto])
748 AC_MSG_RESULT($NCURSES_MMASK_T)
749
750 ### Enable compiling-in rcs id's
751 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
752 AC_ARG_WITH(rcs-ids,
753         [  --with-rcs-ids          compile-in RCS identifiers],
754         [with_rcs_ids=$withval],
755         [with_rcs_ids=no])
756 AC_MSG_RESULT($with_rcs_ids)
757 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
758
759 ###############################################################################
760 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tic toe tput ])
761
762 ###############################################################################
763 CF_HELP_MESSAGE(Extensions:)
764
765 ### Note that some functions (such as const) are normally disabled anyway.
766 AC_MSG_CHECKING(if you want to build with function extensions)
767 AC_ARG_ENABLE(ext-funcs,
768         [  --disable-ext-funcs     disable function-extensions],
769         [with_ext_funcs=$enableval],
770         [with_ext_funcs=yes])
771 AC_MSG_RESULT($with_ext_funcs)
772 if test "$with_ext_funcs" = yes ; then
773         NCURSES_EXT_FUNCS=1
774         AC_DEFINE(HAVE_CURSES_VERSION)
775         AC_DEFINE(HAVE_HAS_KEY)
776         AC_DEFINE(HAVE_RESIZETERM)
777         AC_DEFINE(HAVE_RESIZE_TERM)
778         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
779         AC_DEFINE(HAVE_WRESIZE)
780         AC_DEFINE(NCURSES_EXT_FUNCS)
781 else
782         NCURSES_EXT_FUNCS=0
783 fi
784 AC_SUBST(NCURSES_EXT_FUNCS)
785
786 ###   use option --enable-const to turn on use of const beyond that in XSI.
787 AC_MSG_CHECKING(for extended use of const keyword)
788 AC_ARG_ENABLE(const,
789         [  --enable-const          compile with extra/non-standard const],
790         [with_ext_const=$enableval],
791         [with_ext_const=no])
792 AC_MSG_RESULT($with_ext_const)
793 NCURSES_CONST='/*nothing*/'
794 if test "$with_ext_const" = yes ; then
795         NCURSES_CONST=const
796 fi
797 AC_SUBST(NCURSES_CONST)
798
799 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
800 AC_ARG_ENABLE(no-padding,
801         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
802         [with_no_padding=$enableval],
803         [with_no_padding=$with_ext_funcs])
804 AC_MSG_RESULT($with_no_padding)
805 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
806
807 AC_CHECK_SIZEOF([signed char], 0)
808 if test "$ac_cv_sizeof_signed_char" = 1 ; then
809         NCURSES_SBOOL="signed char"
810 else
811         NCURSES_SBOOL="char"
812 fi
813 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
814 AC_ARG_ENABLE(signed-char,
815         [  --enable-signed-char    compile with SIGWINCH handler],
816         [with_signed_char=$enableval],
817         [with_signed_char=no])
818 AC_MSG_RESULT($with_signed_char)
819 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
820 AC_SUBST(NCURSES_SBOOL)
821
822 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
823 AC_MSG_CHECKING(if you want SIGWINCH handler)
824 AC_ARG_ENABLE(sigwinch,
825         [  --enable-sigwinch       compile with SIGWINCH handler],
826         [with_sigwinch=$enableval],
827         [with_sigwinch=$with_ext_funcs])
828 AC_MSG_RESULT($with_sigwinch)
829 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
830
831 ###   use option --enable-tcap-names to allow user to define new capabilities
832 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
833 AC_ARG_ENABLE(tcap-names,
834         [  --enable-tcap-names     compile with user-definable terminal capabilities],
835         [with_tcap_names=$enableval],
836         [with_tcap_names=$with_ext_funcs])
837 AC_MSG_RESULT($with_tcap_names)
838 NCURSES_XNAMES=0
839 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
840 AC_SUBST(NCURSES_XNAMES)
841
842 ###############################################################################
843 # These options are relatively safe to experiment with.
844 CF_HELP_MESSAGE(Development Code:)
845 AC_MSG_CHECKING(if you want all development code)
846 AC_ARG_WITH(develop,
847         [  --without-develop       disable development options],
848         [with_develop=$withval],
849         [with_develop=no])
850 AC_MSG_RESULT($with_develop)
851
852 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
853 AC_MSG_CHECKING(if you want hard-tabs code)
854 AC_ARG_ENABLE(hard-tabs,
855         [  --enable-hard-tabs      compile with hard-tabs code],,
856         [enable_hard_tabs=$with_develop])
857 AC_MSG_RESULT($enable_hard_tabs)
858 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
859
860 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
861 AC_MSG_CHECKING(if you want limited support for xmc)
862 AC_ARG_ENABLE(xmc-glitch,
863         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
864         [enable_xmc_glitch=$with_develop])
865 AC_MSG_RESULT($enable_xmc_glitch)
866 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
867
868 ###############################################################################
869 # These are just experimental, probably should not be in a package:
870 CF_HELP_MESSAGE(Experimental Code:)
871
872 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
873 AC_ARG_ENABLE(assumed-color,
874         [  --disable-assumed-color do not assume anything about default-colors],
875         [with_assumed_color=$enableval],
876         [with_assumed_color=yes])
877 AC_MSG_RESULT($with_assumed_color)
878 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
879
880 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
881 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
882 AC_ARG_ENABLE(hashmap,
883         [  --disable-hashmap       compile without hashmap scrolling-optimization],
884         [with_hashmap=$enableval],
885         [with_hashmap=yes])
886 AC_MSG_RESULT($with_hashmap)
887 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
888
889 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
890 AC_MSG_CHECKING(if you want colorfgbg code)
891 AC_ARG_ENABLE(colorfgbg,
892         [  --enable-colorfgbg      compile with $COLORFGBG code],
893         [with_colorfgbg=$enableval],
894         [with_colorfgbg=no])
895 AC_MSG_RESULT($with_colorfgbg)
896 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
897
898 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
899 AC_MSG_CHECKING(if you want to use experimental extended colors)
900 AC_ARG_ENABLE(ext-colors,
901         [  --enable-ext-colors     compile for experimental 256-color support],
902         [with_ext_colors=$enableval],
903         [with_ext_colors=no])
904 AC_MSG_RESULT($with_ext_colors)
905 NCURSES_EXT_COLORS=0
906 if test "$with_ext_colors" = yes ; then
907         if test "$with_widec" != yes ; then
908                 AC_MSG_WARN(This option applies only to wide-character library)
909         else
910                 # cannot be ABI 5 since it changes sizeof(cchar_t)
911                 CF_NCURSES_ABI_6
912         fi
913         NCURSES_EXT_COLORS=1
914         AC_DEFINE(NCURSES_EXT_COLORS)
915 fi
916 AC_SUBST(NCURSES_EXT_COLORS)
917
918 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
919 AC_MSG_CHECKING(if you want to use experimental extended mouse encoding)
920 AC_ARG_ENABLE(ext-mouse,
921         [  --enable-ext-mouse      compile for experimental mouse-encoding],
922         [with_ext_mouse=$enableval],
923         [with_ext_mouse=no])
924 AC_MSG_RESULT($with_ext_mouse)
925 NCURSES_MOUSE_VERSION=1
926 if test "$with_ext_mouse" = yes ; then
927         NCURSES_MOUSE_VERSION=2
928         CF_NCURSES_ABI_6
929 fi
930 AC_SUBST(NCURSES_MOUSE_VERSION)
931
932 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
933 AC_ARG_ENABLE(safe-sprintf,
934         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
935         [with_safe_sprintf=$enableval],
936         [with_safe_sprintf=no])
937 AC_MSG_RESULT($with_safe_sprintf)
938 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
939
940 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
941 # when hashmap is used scroll hints are useless
942 if test "$with_hashmap" = no ; then
943 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
944 AC_ARG_ENABLE(scroll-hints,
945         [  --disable-scroll-hints  compile without scroll-hints code],
946         [with_scroll_hints=$enableval],
947         [with_scroll_hints=yes])
948 AC_MSG_RESULT($with_scroll_hints)
949 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
950 fi
951
952 AC_MSG_CHECKING(if you want experimental wgetch-events code)
953 AC_ARG_ENABLE(wgetch-events,
954         [  --enable-wgetch-events  compile with experimental wgetch-events code],
955         [with_wgetch_events=$enableval],
956         [with_wgetch_events=no])
957 AC_MSG_RESULT($with_wgetch_events)
958 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
959
960 ###############################################################################
961 CF_HELP_MESSAGE(Testing/development Options:)
962
963 ###     use option --disable-echo to suppress full display compiling commands
964 AC_MSG_CHECKING(if you want to display full commands during build)
965 AC_ARG_ENABLE(echo,
966         [  --enable-echo           build: display "compiling" commands (default)],
967         [with_echo=$enableval],
968         [with_echo=yes])
969 if test "$with_echo" = yes; then
970         ECHO_LINK=
971 else
972         ECHO_LINK='@ echo linking $@ ... ;'
973         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
974 fi
975 AC_MSG_RESULT($with_echo)
976 AC_SUBST(ECHO_LINK)
977
978 ###     use option --enable-warnings to turn on all gcc warnings
979 AC_MSG_CHECKING(if you want to see compiler warnings)
980 AC_ARG_ENABLE(warnings,
981         [  --enable-warnings       build: turn on GCC compiler warnings],
982         [with_warnings=$enableval])
983 AC_MSG_RESULT($with_warnings)
984
985 if test -n "$with_warnings"; then
986         ADAFLAGS="$ADAFLAGS -gnatg"
987         CF_GCC_WARNINGS
988         if test "$cf_with_cxx" = yes ; then
989                 CF_GXX_WARNINGS(Wno-unused)
990         fi
991 fi
992 CF_GCC_ATTRIBUTES
993
994 ###     use option --enable-assertions to turn on generation of assertion code
995 AC_MSG_CHECKING(if you want to enable runtime assertions)
996 AC_ARG_ENABLE(assertions,
997         [  --enable-assertions     test: turn on generation of assertion code],
998         [with_assertions=$enableval],
999         [with_assertions=no])
1000 AC_MSG_RESULT($with_assertions)
1001 if test -n "$GCC"
1002 then
1003         if test "$with_assertions" = no
1004         then
1005                 AC_DEFINE(NDEBUG)
1006                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1007         else
1008                 ADAFLAGS="$ADAFLAGS -gnata"
1009         fi
1010 fi
1011
1012 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1013 CF_DISABLE_LEAKS
1014 AC_DEFINE(HAVE_NC_ALLOC_H)
1015
1016 ###     use option --enable-expanded to generate certain macros as functions
1017 AC_ARG_ENABLE(expanded,
1018         [  --enable-expanded       test: generate functions for certain macros],
1019         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1020
1021 ###     use option --disable-macros to suppress macros in favor of functions
1022 AC_ARG_ENABLE(macros,
1023         [  --disable-macros        test: use functions rather than macros],
1024         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1025
1026 # Normally we only add trace() to the debug-library.  Allow this to be
1027 # extended to all models of the ncurses library:
1028 cf_all_traces=no
1029 case "$CFLAGS $CPPFLAGS" in
1030 *-DTRACE*)
1031         cf_all_traces=yes
1032         ;;
1033 esac
1034
1035 AC_MSG_CHECKING(whether to add trace feature to all models)
1036 AC_ARG_WITH(trace,
1037 [  --with-trace            test: add trace() function to all models of ncurses],
1038 [cf_with_trace=$withval],
1039 [cf_with_trace=$cf_all_traces])
1040 AC_MSG_RESULT($cf_with_trace)
1041
1042 if test "$cf_with_trace" = yes ; then
1043         LIB_TRACING=all
1044         ADA_TRACE=TRUE
1045         CF_ADD_CFLAGS(-DTRACE)
1046 else
1047         LIB_TRACING=DEBUG
1048         ADA_TRACE=FALSE
1049 fi
1050
1051 AC_SUBST(ADA_TRACE)
1052
1053 ###     Checks for libraries.
1054 AC_CHECK_FUNC(gettimeofday,
1055         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1056
1057 AC_CHECK_LIB(bsd, gettimeofday,
1058         AC_DEFINE(HAVE_GETTIMEOFDAY)
1059         LIBS="$LIBS -lbsd")])dnl CLIX: bzero, select, gettimeofday
1060
1061 CF_MATH_LIB(MATH_LIB,sin(x))
1062 AC_SUBST(MATH_LIB)
1063
1064 ###     Checks for header files.
1065 AC_STDC_HEADERS
1066 AC_HEADER_DIRENT
1067 AC_HEADER_TIME
1068 CF_REGEX
1069
1070 dnl These are some other potentially nonportable headers.
1071 AC_CHECK_HEADERS( \
1072 fcntl.h \
1073 getopt.h \
1074 limits.h \
1075 locale.h \
1076 poll.h \
1077 sys/bsdtypes.h \
1078 sys/ioctl.h \
1079 sys/param.h \
1080 sys/poll.h \
1081 sys/select.h \
1082 sys/time.h \
1083 sys/times.h \
1084 ttyent.h \
1085 unistd.h \
1086 wctype.h \
1087 )
1088
1089 # check for ISC (this may also define _POSIX_SOURCE)
1090 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1091 if test "$ISC" = yes ; then
1092         AC_CHECK_LIB(cposix,main)
1093         AC_CHECK_LIB(inet,bzero,LIBS="$LIBS -linet")dnl also 'select()'
1094 fi
1095
1096 CF_SYS_TIME_SELECT
1097
1098 ###     checks for compiler characteristics
1099 AC_LANG_C
1100 AC_C_CONST
1101 AC_C_INLINE
1102
1103 NCURSES_INLINE=
1104 if test "$ac_cv_c_inline" != no ; then
1105         AC_DEFINE(CC_HAS_INLINE_FUNCS)
1106         NCURSES_INLINE=inline
1107 fi
1108 AC_SUBST(NCURSES_INLINE)
1109
1110 if test $NCURSES_CHTYPE = auto ; then
1111         CF_TYPEOF_CHTYPE
1112 else
1113         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1114 fi
1115 AC_SUBST(cf_cv_typeof_chtype)
1116
1117 CF_UNSIGNED_LITERALS
1118 cf_cv_1UL="1"
1119 test "$cf_cv_unsigned_literals" = yes && cf_cv_1UL="${cf_cv_1UL}U"
1120 test "$cf_cv_typeof_chtype"    = long && cf_cv_1UL="${cf_cv_1UL}L"
1121 AC_SUBST(cf_cv_1UL)
1122
1123 if test $NCURSES_MMASK_T = auto ; then
1124         cf_cv_typeof_mmask_t=long
1125 else
1126         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1127 fi
1128 AC_SUBST(cf_cv_typeof_mmask_t)
1129
1130 ###     Checks for external-data
1131 CF_ERRNO
1132 CF_LINK_DATAONLY
1133
1134 ###     Checks for library functions.
1135 AC_CHECK_FUNCS( \
1136 getcwd \
1137 getegid \
1138 geteuid \
1139 getttynam \
1140 issetugid \
1141 poll \
1142 remove \
1143 select \
1144 setbuf \
1145 setbuffer \
1146 setvbuf \
1147 sigaction \
1148 sigvec \
1149 strdup \
1150 strstr \
1151 tcgetpgrp \
1152 times \
1153 vsnprintf \
1154 )
1155 if test "$with_getcap" = "yes" ; then
1156         CF_CGETENT
1157 fi
1158
1159 CF_ISASCII
1160 CF_STRUCT_SIGACTION
1161 CF_FUNC_NANOSLEEP
1162 CF_FUNC_TERMIOS
1163 CF_FUNC_VSSCANF
1164 CF_MKSTEMP
1165
1166 # setup for prototype of fallback for vsscanf()
1167 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1168
1169 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1170 if test "$cross_compiling" = yes ; then
1171         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1172 else
1173         AC_FUNC_SETVBUF_REVERSED
1174 fi
1175 AC_TYPE_SIGNAL
1176 CF_TYPE_SIGACTION
1177 CF_SIZECHANGE
1178 CF_FUNC_MEMMOVE
1179 CF_FUNC_POLL
1180
1181 if test "$with_hashed_db" != no ; then
1182         AC_DEFINE(USE_HASHED_DB)
1183         CF_HASHED_DB
1184 fi
1185
1186 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1187 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1188         CF_STRIP_G_OPT(CFLAGS)
1189         CF_STRIP_G_OPT(CXXFLAGS)
1190 fi
1191
1192 # Just in case, check if the C compiler has a bool type.
1193 CF_BOOL_DECL(cf_cv_cc_bool_type)
1194
1195 # Check for C++ compiler characteristics (and ensure that it's there!)
1196 if test -n "$CXX" ; then
1197         AC_LANG_CPLUSPLUS
1198         CF_STDCPP_LIBRARY
1199         CF_PROG_CC_C_O(CXX)
1200
1201         case $GXX_VERSION in
1202         1*|2.[0-6]*)
1203                 cf_cxx_library=yes
1204                 ;;
1205         *-2.7*|2.7*)
1206                 CF_GPP_LIBRARY
1207                 ;;
1208         *)
1209                 cf_cxx_library=no
1210                 ;;
1211         esac
1212
1213         AC_CHECK_HEADERS(typeinfo)
1214
1215         CF_BOOL_DECL
1216         CF_BOOL_SIZE
1217         CF_ETIP_DEFINES
1218         CF_CPP_PARAM_INIT
1219         CF_CPP_STATIC_CAST
1220         CF_CPP_VSCAN_FUNC
1221
1222         CXX_AR='$(AR)'
1223         CXX_AR_OPTS='$(AR_OPTS)'
1224         case $cf_cv_system_name in #(vi
1225         irix*) #(vi
1226             if test "$GXX" != yes ; then
1227                 CXX_AR='$(CXX)'
1228                 CXX_AR_OPTS='-ar -o'
1229             fi
1230             ;;
1231         sco3.2v5*) #(vi
1232             CXXLDFLAGS="-u main"
1233             ;;
1234         solaris2*)
1235             if test "$GXX" != yes ; then
1236                 CXX_AR='$(CXX)'
1237                 CXX_AR_OPTS='-xar -o'
1238             fi
1239             ;;
1240         esac
1241         AC_SUBST(CXXLDFLAGS)
1242         AC_SUBST(CXX_AR)
1243         AC_SUBST(CXX_AR_OPTS)
1244 else
1245         cf_cxx_library=no
1246         cf_cv_builtin_bool=1
1247
1248         # Just because we are not configuring against C++ right now does not
1249         # mean that a user will not want to use C++.  Some distributors disable
1250         # the C++ portion of this configuration as a shortcut (or just to avoid
1251         # compiling the demo in the c++ directory).  So we need a reasonable
1252         # default for the 'bool' type.
1253         #
1254         # Caveat: since the storage of the bool type is not standardized, it
1255         # may change.
1256
1257         if test "$NCURSES_BOOL" != auto ; then
1258                 cf_cv_type_of_bool=$NCURSES_BOOL
1259                 cf_cv_header_stdbool_h=0
1260         else
1261                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1262                         CF_BOOL_SIZE
1263                 else
1264                         AC_MSG_CHECKING(for fallback type of bool)
1265                         case "$host_cpu" in #(vi
1266                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1267                         *)      cf_cv_type_of_bool=int  ;;
1268                         esac
1269                         AC_MSG_RESULT($cf_cv_type_of_bool)
1270                 fi
1271         fi
1272 fi
1273 AC_SUBST(CXXLIBS)
1274
1275 # If the C compiler did not declare bool, and we did not determine that the C++
1276 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1277 # ncurses library use the same type as C++ bool.  Note that this allows one to
1278 # specify the type of bool in a configure-script option and postpone
1279 # integration with the C++ compiler provided that the types are compatible.
1280 USE_CXX_BOOL=1
1281 if test $cf_cv_cc_bool_type = 1
1282 then
1283         # oops: C has a bool.  Unlikely, but C++ could differ.
1284         USE_CXX_BOOL=0
1285 elif test $cf_cv_builtin_bool = 0
1286 then
1287         # C++ has no bool
1288         USE_CXX_BOOL=0
1289 else
1290         # this is the normal case
1291         USE_CXX_BOOL='defined(__cplusplus)'
1292 fi
1293 AC_SUBST(USE_CXX_BOOL)
1294
1295 CF_HELP_MESSAGE(Ada95 Binding Options:)
1296
1297 dnl Check for availability of GNU Ada Translator (GNAT).
1298 dnl At the moment we support no other Ada95 compiler.
1299 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1300 if test "$cf_with_ada" != "no" ; then
1301 cf_ada_make=gnatmake
1302 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
1303 if test "$ac_cv_prog_gnat_exists" = no; then
1304    cf_ada_make=
1305 else
1306    CF_GNAT_VERSION
1307    AC_CHECK_PROG(M4_exists, m4, yes, no)
1308    if test "$ac_cv_prog_M4_exists" = no; then
1309       cf_cv_prog_gnat_correct=no
1310       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
1311    fi
1312    if test "$cf_cv_prog_gnat_correct" = yes; then
1313       AC_MSG_CHECKING(if GNAT works)
1314       CF_GNAT_TRY_RUN([procedure conftest;],
1315 [with Text_IO;
1316 with GNAT.OS_Lib;
1317 procedure conftest is
1318 begin
1319    Text_IO.Put ("Hello World");
1320    Text_IO.New_Line;
1321    GNAT.OS_Lib.OS_Exit (0);
1322 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
1323       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
1324    fi
1325 fi
1326 if test "$cf_cv_prog_gnat_correct" = yes; then
1327    ADAFLAGS="-O3 -gnatpn $ADAFLAGS"
1328
1329    AC_MSG_CHECKING(if GNAT pragma Unreferenced works)
1330    CF_GNAT_TRY_LINK([procedure conftest;],
1331 [with Text_IO;
1332 with GNAT.OS_Lib;
1333 procedure conftest is
1334    test : Integer;
1335    pragma Unreferenced (test);
1336 begin
1337    test := 1;
1338    Text_IO.Put ("Hello World");
1339    Text_IO.New_Line;
1340    GNAT.OS_Lib.OS_Exit (0);
1341 end conftest;],[cf_cv_pragma_unreferenced=yes],[cf_cv_pragma_unreferenced=no])
1342    AC_MSG_RESULT($cf_cv_pragma_unreferenced)
1343
1344    # if the pragma is supported, use it (needed in the Trace code).
1345    if test $cf_cv_pragma_unreferenced = yes ; then
1346       PRAGMA_UNREF=TRUE
1347    else
1348       PRAGMA_UNREF=FALSE
1349    fi
1350
1351    AC_ARG_WITH(ada-compiler,
1352         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
1353         [cf_ada_compiler=$withval],
1354         [cf_ada_compiler=gnatmake])
1355
1356    cf_ada_package=terminal_interface
1357
1358    AC_SUBST(cf_ada_make)
1359    AC_SUBST(cf_ada_compiler)
1360    AC_SUBST(cf_ada_package)
1361    AC_SUBST(ADAFLAGS)
1362    AC_SUBST(cf_compile_generics)
1363    AC_SUBST(cf_generic_objects)
1364    AC_SUBST(PRAGMA_UNREF)
1365
1366    CF_WITH_PATH(ada-include,
1367        [  --with-ada-include=DIR  Ada includes are in DIR],
1368        ADA_INCLUDE,
1369        PREFIX/lib/ada/adainclude,
1370        [$]prefix/lib/ada/adainclude)
1371    AC_SUBST(ADA_INCLUDE)
1372
1373    CF_WITH_PATH(ada-objects,
1374        [  --with-ada-objects=DIR  Ada objects are in DIR],
1375        ADA_OBJECTS,
1376        PREFIX/lib/ada/adalib,
1377        [$]prefix/lib/ada/adalib)
1378    AC_SUBST(ADA_OBJECTS)
1379
1380 fi
1381 fi
1382 fi
1383
1384 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1385 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1386 ###
1387 ### ticlib modules may be a separate library, otherwise contained in termlib.
1388 ### termlib modules may be a separate library, otherwise contained in ncurses.
1389 ###
1390 ### The of "+" or " " between the tokens controls the way the script
1391 ### chooses to split module lists into libraries.
1392 ###
1393 ### (see CF_LIB_RULES).
1394 AC_MSG_CHECKING(for library subsets)
1395 LIB_SUBSETS=
1396
1397 test "$cf_with_progs"  = yes && LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1398 if test "$with_ticlib" != no ; then
1399         LIB_SUBSETS="${LIB_SUBSETS} "
1400 else
1401         LIB_SUBSETS="${LIB_SUBSETS}+"
1402 fi
1403
1404 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1405 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1406 if test "$with_termlib" != no ; then
1407         LIB_SUBSETS="${LIB_SUBSETS} "
1408 else
1409         LIB_SUBSETS="${LIB_SUBSETS}+"
1410 fi
1411
1412 LIB_SUBSETS="${LIB_SUBSETS}base"
1413 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1414 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1415
1416 AC_MSG_RESULT($LIB_SUBSETS)
1417
1418 ### Construct the list of include-directories to be generated
1419 CF_INCLUDE_DIRS
1420 CF_ADA_INCLUDE_DIRS
1421
1422 ### Build up pieces for makefile rules
1423 AC_MSG_CHECKING(default library suffix)
1424 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1425 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1426 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1427
1428 AC_MSG_CHECKING(default library-dependency suffix)
1429 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_DEP_SUFFIX)dnl
1430 if test $DFT_LWR_MODEL = shared ; then
1431         case $cf_cv_system_name in #(vi
1432         cygwin*)
1433                 DFT_DEP_SUFFIX=".dll.a"
1434                 ;;
1435         esac
1436 fi
1437 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1438 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1439
1440 AC_MSG_CHECKING(default object directory)
1441 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1442 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1443 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1444
1445 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1446 if test "$cf_with_cxx" = yes ; then
1447 AC_MSG_CHECKING(c++ library-dependency suffix)
1448 if test "$with_libtool" != "no"; then
1449         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1450 else
1451         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX)dnl we normally make a static library
1452 fi
1453 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1454 AC_SUBST(CXX_LIB_SUFFIX)
1455 fi
1456
1457 ### Set up low-level terminfo dependencies for makefiles.
1458
1459 # TICS_LIST and TINFO_LIST are needed to build the libtic.so and libterm.so
1460 TICS_LIST="$SHLIB_LIST"
1461 TINFO_LIST="$SHLIB_LIST"
1462
1463 TICS_LEAKS=
1464
1465 if test "$with_ticlib" != no ; then
1466
1467         if test "$with_ticlib" != yes ; then
1468                 TICS_NAME=$with_ticlib
1469                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1470                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1471                 TICS_LIB_SUFFIX="${with_ticlib}"
1472         else
1473                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1474                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1475                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1476         fi
1477         TICS_ARGS="-L${LIB_DIR} -l${TICS_LIB_SUFFIX}"
1478 else
1479         TICS_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1480 fi
1481 AC_SUBST(TICS_ARG_SUFFIX)
1482 AC_SUBST(TICS_DEP_SUFFIX)
1483 AC_SUBST(TICS_LIB_SUFFIX)
1484 AC_SUBST(TICS_ARGS)
1485
1486 AC_SUBST(TICS_LEAKS)
1487
1488 if test "$with_termlib" != no ; then
1489
1490         if test "$with_termlib" != yes ; then
1491                 TINFO_NAME=$with_termlib
1492                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1493                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1494                 TINFO_LIB_SUFFIX="${with_termlib}"
1495         else
1496                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1497                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1498                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1499         fi
1500
1501         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1502         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1503         if test "$DFT_LWR_MODEL" = "libtool"; then
1504                 TEST_ARGS="${TEST_DEPS}"
1505                 TEST_ARG2="${TEST_DEP2}"
1506                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1507         else
1508                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1509                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1510                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1511                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1512         fi
1513 else
1514         TINFO_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1515 fi
1516 AC_SUBST(TINFO_ARG_SUFFIX)
1517 AC_SUBST(TINFO_DEP_SUFFIX)
1518 AC_SUBST(TINFO_LIB_SUFFIX)
1519 AC_SUBST(TINFO_ARGS)
1520
1521 # needed for Ada95
1522 TINFO_ARGS2=`echo "$TINFO_ARGS" | sed -e 's,-L\.\./,-L../../,'`
1523 AC_SUBST(TINFO_ARGS2)
1524
1525 AC_MSG_CHECKING(where we will install curses.h)
1526 test "$with_overwrite" = no && \
1527 test "x$includedir" = 'x${prefix}/include' && \
1528         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1529 AC_MSG_RESULT($includedir)
1530
1531 ### Resolve a conflict between normal and wide-curses by forcing applications
1532 ### that will need libutf8 to add it to their configure script.
1533 if test "$with_overwrite" != no ; then
1534 if test "$NCURSES_LIBUTF8" = 1 ; then
1535         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1536         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1537 fi
1538 fi
1539
1540 AC_SUBST(WITH_OVERWRITE)
1541 AC_SUBST(TINFO_LIST)
1542 AC_SUBST(SHLIB_LIST)
1543
1544 # used to separate tack out of the tree
1545 NCURSES_TREE=
1546 AC_SUBST(NCURSES_TREE)
1547
1548 ### predefined stuff for the test programs
1549 AC_DEFINE(HAVE_SLK_COLOR)
1550
1551 ### Construct the list of subdirectories for which we'll customize makefiles
1552 ### with the appropriate compile-rules.
1553
1554 CF_SRC_MODULES($modules_to_build)
1555 CF_DIRS_TO_MAKE
1556
1557 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATHSEP')
1558
1559 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1560
1561 ### Now that we're done running tests, add the compiler-warnings, if any
1562 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1563
1564 ### Define substitutions for header files to avoid name-pollution
1565 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1566 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1567 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1568
1569 ################################################################################
1570 test "$use_database" = yes && SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1571 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1572 AC_OUTPUT( \
1573         include/MKterm.h.awk \
1574         include/curses.head:include/curses.h.in \
1575         include/termcap.h \
1576         include/unctrl.h \
1577         $SUB_MAKEFILES \
1578         Makefile,[
1579 CF_PRG_RULES([$srcdir/test/mk-test.awk ECHO_LINK="$ECHO_LINK"], test)
1580 CF_LIB_RULES($SRC_SUBDIRS)
1581 ],[
1582 ### Special initialization commands, used to pass information from the
1583 ### configuration-run into config.status
1584
1585 AWK="$AWK"
1586 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1587 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1588 ECHO_LINK="$ECHO_LINK"
1589 LDCONFIG="$LDCONFIG"
1590 LIB_NAME="$LIB_NAME"
1591 LIB_SUBSETS="$LIB_SUBSETS"
1592 LIB_SUFFIX="$LIB_SUFFIX"
1593 LIB_TRACING="$LIB_TRACING"
1594 MAKE_TERMINFO="$MAKE_TERMINFO"
1595 NCURSES_MAJOR="$NCURSES_MAJOR"
1596 NCURSES_MINOR="$NCURSES_MINOR"
1597 NCURSES_OSPEED="$NCURSES_OSPEED"
1598 NCURSES_PATCH="$NCURSES_PATCH"
1599 SRC_SUBDIRS="$SRC_SUBDIRS"
1600 TERMINFO="$TERMINFO"
1601 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1602 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1603 TINFO_NAME="$TINFO_NAME"
1604 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1605 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1606 TICS_NAME="$TICS_NAME"
1607 WITH_CURSES_H="$with_curses_h"
1608 WITH_ECHO="$with_echo"
1609 WITH_OVERWRITE="$with_overwrite"
1610 cf_LIST_MODELS="$cf_list_models"
1611 cf_cv_abi_version="$cf_cv_abi_version"
1612 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1613 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1614 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1615 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1616 cf_cv_rel_version="$cf_cv_rel_version"
1617 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1618 cf_cv_shlib_version="$cf_cv_shlib_version"
1619 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1620 cf_cv_system_name="$cf_cv_system_name"
1621 cf_with_cxx_binding="$cf_with_cxx_binding"
1622 host="$host"
1623 target="$target"
1624
1625 ],cat)dnl
1626 ${MAKE-make} preinstall