configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2007,2008 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: configure.in,v 1.452 2008/10/11 16:02:56 tom Exp $
  32 dnl Process this file with autoconf to produce a configure script.
  33 dnl
  34 dnl See http://invisible-island.net/autoconf/ for additional information.
  35 dnl
  36 dnl ---------------------------------------------------------------------------
  37 AC_PREREQ(2.13.20020210)
  38 AC_REVISION($Revision: 1.452 $)
  39 AC_INIT(ncurses/base/lib_initscr.c)
  40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  41
  42 CF_TOP_BUILDDIR
  43 CF_SUBST_NCURSES_VERSION
  44
  45 CF_WITH_REL_VERSION(NCURSES)
  46 CF_WITH_ABI_VERSION
  47
  48 CF_CHECK_CACHE([AC_CANONICAL_SYSTEM])
  49 AC_ARG_WITH(system-type,
  50 [  --with-system-type=XXX  test: override derived host system-type],
  51 [AC_MSG_WARN(overriding system type to $withval)
  52  cf_cv_system_name=$withval])
  53
  54 ###     Save the given $CFLAGS to allow user-override.
  55 cf_user_CFLAGS="$CFLAGS"
  56
  57 ###     Default install-location
  58 CF_CFG_DEFAULTS
  59
  60 ###     Checks for programs.
  61 AC_PROG_CC
  62 CF_GCC_VERSION
  63
  64 AC_PROG_CPP
  65 AC_PROG_GCC_TRADITIONAL
  66 CF_PROG_CC_C_O(CC)
  67 AC_ISC_POSIX
  68 CF_ANSI_CC_REQD
  69 CF_PROG_EXT
  70 CF_PROG_LDCONFIG
  71
  72 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  73 dnl                             configure script by not letting us test if C++
  74 dnl                             is present, making this option necessary.
  75 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  76 AC_ARG_WITH(cxx,
  77         [  --without-cxx           do not adjust ncurses bool to match C++],
  78         [cf_with_cxx=$withval],
  79         [cf_with_cxx=yes])
  80 AC_MSG_RESULT($cf_with_cxx)
  81 if test "X$cf_with_cxx" = Xno ; then
  82         CXX=""
  83         GXX=""
  84 else
  85         # with autoconf 2.13, we can change the error to a warning:
  86         pushdef([AC_MSG_ERROR],
  87                 [AC_MSG_RESULT(no)
  88                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
  89                 cf_with_cxx=no; CXX=""; GXX="";])dnl
  90         AC_PROG_CXX
  91         popdef([AC_MSG_ERROR])dnl
  92         # autoconf 2.5x removed the error - by hardcoding it to g++.
  93         if test "$CXX" = "g++" ; then
  94                 AC_PATH_PROG(CXX,g++)
  95         fi
  96         if test "$CXX" = "g++" ; then
  97                 AC_MSG_WARN(ignoring hardcoded g++)
  98                 cf_with_cxx=no; CXX=""; GXX="";
  99         fi
 100 fi
 101
 102 CF_GXX_VERSION
 103 case $GXX_VERSION in
 104 1*|2.[[0-6]]*)
 105         # GXX=""; CXX=""; ac_cv_prog_gxx=no
 106         # cf_cxx_library=no
 107         AC_MSG_WARN(templates do not work)
 108         ;;
 109 esac
 110
 111 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 112 AC_ARG_WITH(cxx-binding,
 113         [  --without-cxx-binding   do not build C++ binding and demo],
 114         [cf_with_cxx_binding=$withval],
 115         [cf_with_cxx_binding=$cf_with_cxx])
 116 AC_MSG_RESULT($cf_with_cxx_binding)
 117
 118 AC_MSG_CHECKING(if you want to build with Ada95)
 119 AC_ARG_WITH(ada,
 120         [  --without-ada           suppress check for Ada95, don't build demo],
 121         [cf_with_ada=$withval],
 122         [cf_with_ada=yes])
 123 AC_MSG_RESULT($cf_with_ada)
 124
 125 AC_MSG_CHECKING(if you want to build programs such as tic)
 126 AC_ARG_WITH(progs,
 127         [  --without-progs         suppress build with programs (e.g., tic)],
 128         [cf_with_progs=$withval],
 129         [cf_with_progs=yes])
 130 AC_MSG_RESULT($cf_with_progs)
 131
 132 AC_MSG_CHECKING(if you wish to install curses.h)
 133 AC_ARG_WITH(curses-h,
 134         [  --without-curses-h      install curses.h as ncurses.h only],
 135         [with_curses_h=$withval],
 136         [with_curses_h=yes])
 137 AC_MSG_RESULT($with_curses_h)
 138
 139 modules_to_build="ncurses"
 140 if test "X$cf_with_progs" != Xno ; then
 141 modules_to_build="$modules_to_build progs tack"
 142 fi
 143 modules_to_build="$modules_to_build panel menu form"
 144
 145 AC_ARG_PROGRAM
 146
 147 CF_PROG_AWK
 148 CF_PROG_EGREP
 149 CF_PROG_INSTALL
 150 CF_PROG_LINT
 151 AC_PROG_LN_S
 152
 153 AC_SYS_LONG_FILE_NAMES
 154
 155 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 156 AC_ARG_ENABLE(mixed-case,
 157         [  --enable-mixed-case     tic should assume mixed-case filenames],
 158         [enable_mixedcase=$enableval],
 159         [enable_mixedcase=auto])
 160 AC_MSG_RESULT($enable_mixedcase)
 161 if test "$enable_mixedcase" = "auto" ; then
 162     CF_MIXEDCASE_FILENAMES
 163 else
 164     cf_cv_mixedcase=$enable_mixedcase
 165     if test "$enable_mixedcase" = "yes" ; then
 166         AC_DEFINE(MIXEDCASE_FILENAMES)
 167     fi
 168 fi
 169
 170 # do this after mixed-case option (tags/TAGS is not as important as tic).
 171 AC_PROG_MAKE_SET
 172 CF_MAKE_TAGS
 173 CF_MAKEFLAGS
 174
 175 dnl These are standard among *NIX systems, but not when cross-compiling
 176 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 177 AC_CHECK_TOOL(LD, ld, ld)
 178 AC_CHECK_TOOL(AR, ar, ar)
 179 CF_SUBST(archiver options,AR_OPTS,rv)
 180
 181 dnl Special option for use by system-builders: the install-prefix is used to
 182 dnl adjust the location into which the actual install is done, so that an
 183 dnl archive can be built without modifying the host system's configuration.
 184 AC_MSG_CHECKING(if you have specified an install-prefix)
 185 AC_ARG_WITH(install-prefix,
 186         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 187         [case "$withval" in #(vi
 188         yes|no) #(vi
 189                 ;;
 190         *)      DESTDIR="$withval"
 191                 ;;
 192         esac])
 193 AC_MSG_RESULT($DESTDIR)
 194 AC_SUBST(DESTDIR)
 195
 196 ###############################################################################
 197 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 198 # If we're cross-compiling, allow the user to override the tools and their
 199 # options.  The configure script is oriented toward identifying the host
 200 # compiler, etc., but we need a build compiler to generate parts of the source.
 201 CF_BUILD_CC
 202
 203 ###############################################################################
 204 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 205
 206 ### Options to allow the user to specify the set of libraries which are used.
 207 ### Use "--without-normal --with-shared" to allow the default model to be
 208 ### shared, for example.
 209 cf_list_models=""
 210 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 211
 212 CF_WITH_LIBTOOL
 213 if test "$with_libtool" != "no" ; then
 214
 215 cf_list_models="$cf_list_models libtool"
 216
 217 else
 218
 219 AC_MSG_CHECKING(if you want to build shared libraries)
 220 AC_ARG_WITH(shared,
 221         [  --with-shared           generate shared-libraries],
 222         [with_shared=$withval],
 223         [with_shared=no])
 224 AC_MSG_RESULT($with_shared)
 225 test "$with_shared" = "yes" && cf_list_models="$cf_list_models shared"
 226
 227 AC_MSG_CHECKING(if you want to build static libraries)
 228 AC_ARG_WITH(normal,
 229         [  --with-normal           generate normal-libraries (default)],
 230         [with_normal=$withval],
 231         [with_normal=yes])
 232 AC_MSG_RESULT($with_normal)
 233 test "$with_normal" = "yes" && cf_list_models="$cf_list_models normal"
 234
 235 AC_MSG_CHECKING(if you want to build debug libraries)
 236 AC_ARG_WITH(debug,
 237         [  --with-debug            generate debug-libraries (default)],
 238         [with_debug=$withval],
 239         [with_debug=yes])
 240 AC_MSG_RESULT($with_debug)
 241 test "$with_debug" = "yes" && cf_list_models="$cf_list_models debug"
 242
 243 AC_MSG_CHECKING(if you want to build profiling libraries)
 244 AC_ARG_WITH(profile,
 245         [  --with-profile          generate profile-libraries],
 246         [with_profile=$withval],
 247         [with_profile=no])
 248 AC_MSG_RESULT($with_profile)
 249 test "$with_profile" = "yes" && cf_list_models="$cf_list_models profile"
 250
 251 fi
 252
 253 ###############################################################################
 254
 255 AC_MSG_CHECKING(for specified models)
 256 test -z "$cf_list_models" && cf_list_models=normal
 257 dnl If we use libtool to generate libraries, then it must be the only
 258 dnl specified model.
 259 test "$with_libtool" != "no" && cf_list_models=libtool
 260 AC_MSG_RESULT($cf_list_models)
 261
 262 ### Use the first model as the default, and save its suffix for use in building
 263 ### up test-applications.
 264 AC_MSG_CHECKING(for default model)
 265 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 266 AC_MSG_RESULT($DFT_LWR_MODEL)
 267
 268 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 269
 270 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 271 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 272
 273 TICS_NAME=tic
 274 AC_SUBST(TICS_NAME)
 275
 276 TINFO_NAME=tinfo
 277 AC_SUBST(TINFO_NAME)
 278
 279 LIB_NAME=ncurses
 280 AC_SUBST(LIB_NAME)
 281
 282 LIB_DIR=../lib
 283 LIB_2ND=../../lib
 284
 285 CF_LIB_PREFIX(cf_prefix)
 286 LIB_PREFIX=$cf_prefix
 287 AC_SUBST(LIB_PREFIX)
 288
 289 LIB_SUFFIX=
 290 AC_SUBST(LIB_SUFFIX)
 291
 292 ###############################################################################
 293
 294 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 295 AC_ARG_WITH(termlib,
 296         [  --with-termlib          generate separate terminfo library],
 297         [with_termlib=$withval],
 298         [with_termlib=no])
 299 AC_MSG_RESULT($with_termlib)
 300
 301 AC_MSG_CHECKING(if you want to build a separate tic library)
 302 AC_ARG_WITH(ticlib,
 303         [  --with-ticlib           generate separate tic library],
 304         [with_ticlib=$withval],
 305         [with_ticlib=no])
 306 AC_MSG_RESULT($with_ticlib)
 307
 308 ### Checks for special libraries, must be done up-front.
 309 SHLIB_LIST=""
 310 CF_WITH_GPM
 311 if test "$with_gpm" != no ; then
 312         AC_MSG_CHECKING(if you want to load GPM dynamically)
 313         AC_ARG_WITH(dlsym,
 314                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 315                 [with_dlsym=$withval],
 316                 [with_dlsym=yes])
 317         AC_MSG_RESULT($with_dlsym)
 318         if test "$with_dlsym" = yes ; then
 319                 CF_FUNC_DLSYM
 320                 if test "$with_gpm" != yes ; then
 321                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 322                         cf_cv_gpm_soname="$with_gpm"
 323                 else
 324                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 325                 fi
 326                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname")
 327                 SHLIB_LIST="-ldl $SHLIB_LIST"
 328         else
 329                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 330         fi
 331         AC_DEFINE(HAVE_LIBGPM)
 332         CF_CHECK_GPM_WGETCH
 333 fi
 334
 335 CF_WITH_SYSMOUSE
 336
 337 dnl Not all ports of gcc support the -g option
 338
 339 if test X"$CC_G_OPT" = X"" ; then
 340         CC_G_OPT='-g'
 341         test -n "$GCC" && test "${ac_cv_prog_cc_g}" != yes && CC_G_OPT=''
 342 fi
 343 AC_SUBST(CC_G_OPT)
 344
 345 if test X"$CXX_G_OPT" = X"" ; then
 346         CXX_G_OPT='-g'
 347         test -n "$GXX" && test "${ac_cv_prog_cxx_g}" != yes && CXX_G_OPT=''
 348 fi
 349 AC_SUBST(CXX_G_OPT)
 350
 351 AC_MSG_CHECKING(for default loader flags)
 352 case $DFT_LWR_MODEL in
 353 libtool) LD_MODEL=''   ;;
 354 normal)  LD_MODEL=''   ;;
 355 debug)   LD_MODEL=$CC_G_OPT ;;
 356 profile) LD_MODEL='-pg';;
 357 shared)  LD_MODEL=''   ;;
 358 esac
 359 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 360 AC_MSG_RESULT($LD_MODEL)
 361
 362 case $DFT_LWR_MODEL in
 363 shared)
 364 CF_ENABLE_RPATH
 365 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 366 AC_ARG_ENABLE(relink,
 367 [  --disable-relink        relink shared libraries during install],
 368 [cf_cv_do_relink=$enableval],
 369 [cf_cv_do_relink=yes])
 370 AC_MSG_RESULT($cf_cv_do_relink)
 371         ;;
 372 esac
 373
 374 CF_SHARED_OPTS
 375 if test "$CC_SHARED_OPTS" = "unknown"; then
 376         for model in $cf_list_models; do
 377                 if test "$model" = "shared"; then
 378                         AC_ERROR(Shared libraries are not supported in this version)
 379                 fi
 380         done
 381 fi
 382
 383 ###############################################################################
 384 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 385
 386 ###     use option --disable-overwrite to leave out the link to -lcurses
 387 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 388 AC_ARG_ENABLE(overwrite,
 389         [  --disable-overwrite     leave out the link to -lcurses],
 390         [with_overwrite=$enableval],
 391         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 392 AC_MSG_RESULT($with_overwrite)
 393
 394 AC_MSG_CHECKING(if external terminfo-database is used)
 395 AC_ARG_ENABLE(database,
 396         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 397         [use_database=$enableval],
 398         [use_database=yes])
 399 AC_MSG_RESULT($use_database)
 400
 401 case $host_os in #(vi
 402 os2*) #(vi
 403         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 404         ;;
 405 *) #(vi
 406         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 407         ;;
 408 esac
 409 AC_SUBST(TERMINFO_SRC)
 410
 411 CF_PATHSEP
 412 if test "$use_database" != no ; then
 413         AC_DEFINE(USE_DATABASE)
 414
 415         AC_MSG_CHECKING(which terminfo source-file will be installed)
 416         AC_ARG_ENABLE(database,
 417                 [  --with-database=XXX     specify terminfo source to install],
 418                 [TERMINFO_SRC=$withval])
 419         AC_MSG_RESULT($TERMINFO_SRC)
 420
 421         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 422         AC_ARG_WITH(hashed-db,
 423                 [  --with-hashed-db        specify hashed-database library],,
 424                 [with_hashed_db=no])
 425         AC_MSG_RESULT($with_hashed_db)
 426 fi
 427
 428 AC_MSG_CHECKING(for list of fallback descriptions)
 429 AC_ARG_WITH(fallbacks,
 430         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 431         [with_fallback=$withval],
 432         [with_fallback=])
 433 AC_MSG_RESULT($with_fallback)
 434 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 435 AC_SUBST(FALLBACK_LIST)
 436
 437 AC_MSG_CHECKING(if you want modern xterm or antique)
 438 AC_ARG_WITH(xterm-new,
 439         [  --without-xterm-new     specify if xterm terminfo should be old version],
 440         [with_xterm_new=$withval],
 441         [with_xterm_new=yes])
 442 case $with_xterm_new in
 443 no)     with_xterm_new=xterm-old;;
 444 *)      with_xterm_new=xterm-new;;
 445 esac
 446 AC_MSG_RESULT($with_xterm_new)
 447 WHICH_XTERM=$with_xterm_new
 448 AC_SUBST(WHICH_XTERM)
 449
 450 MAKE_TERMINFO=
 451 if test "$use_database" = no ; then
 452         TERMINFO="${datadir}/terminfo"
 453         MAKE_TERMINFO="#"
 454 else
 455
 456 AC_MSG_CHECKING(for list of terminfo directories)
 457 CF_WITH_PATHLIST(terminfo-dirs,
 458         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 459         TERMINFO_DIRS,
 460         DATADIR/terminfo,
 461         ${datadir}/terminfo)
 462 AC_MSG_RESULT($TERMINFO_DIRS)
 463 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS")
 464
 465 AC_MSG_CHECKING(for default terminfo directory)
 466 CF_WITH_PATH(default-terminfo-dir,
 467         [  --with-default-terminfo-dir=DIR default terminfo directory],
 468         TERMINFO,
 469         DATADIR/terminfo,
 470         ${datadir}/terminfo)
 471 AC_MSG_RESULT($TERMINFO)
 472 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO")
 473
 474 fi
 475
 476 AC_SUBST(TERMINFO)
 477 AC_SUBST(MAKE_TERMINFO)
 478
 479 ###     use option --disable-big-core to make tic run on small machines
 480 ###     We need 4Mb, check if we can allocate 50% more than that.
 481 AC_MSG_CHECKING(if big-core option selected)
 482 AC_ARG_ENABLE(big-core,
 483         [  --disable-big-core      assume machine has little memory],
 484         [with_big_core=$enableval],
 485         [AC_TRY_RUN([
 486 #include <stdlib.h>
 487 #include <string.h>
 488 int main() {
 489         unsigned long n = 6000000L;
 490         char *s = malloc(n);
 491         if (s != 0)
 492                 s[0] = s[n-1] = 0;
 493         ${cf_cv_main_return:-return}(s == 0);
 494 }],
 495         [with_big_core=yes],
 496         [with_big_core=no],
 497         [with_big_core=no])])
 498 AC_MSG_RESULT($with_big_core)
 499 test "$with_big_core" = "yes" && AC_DEFINE(HAVE_BIG_CORE)
 500
 501 ### ISO C only guarantees 512-char strings, we have tables which load faster
 502 ### when constructed using "big" strings.  More than the C compiler, the awk
 503 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 504 AC_MSG_CHECKING(if big-strings option selected)
 505 AC_ARG_ENABLE(big-strings,
 506         [  --disable-big-strings   assume compiler has only standard-size strings],
 507         [with_big_strings=$enableval],
 508         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 509 AC_MSG_RESULT($with_big_strings)
 510
 511 USE_BIG_STRINGS=0
 512 test "$with_big_strings" = "yes" && USE_BIG_STRINGS=1
 513 AC_SUBST(USE_BIG_STRINGS)
 514
 515 ###     use option --enable-termcap to compile in the termcap fallback support
 516 AC_MSG_CHECKING(if you want termcap-fallback support)
 517 AC_ARG_ENABLE(termcap,
 518         [  --enable-termcap        compile in termcap fallback support],
 519         [with_termcap=$enableval],
 520         [with_termcap=no])
 521 AC_MSG_RESULT($with_termcap)
 522
 523 if test "$with_termcap" != "yes" ; then
 524         if test "$use_database" = no ; then
 525                 if test -z "$with_fallback" ; then
 526                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 527                 fi
 528         fi
 529         AC_DEFINE(PURE_TERMINFO)
 530 else
 531
 532 if test "$with_ticlib" != no ; then
 533         AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 534 fi
 535
 536 AC_DEFINE(USE_TERMCAP)
 537 AC_MSG_CHECKING(for list of termcap files)
 538 CF_WITH_PATHLIST(termpath,
 539         [  --with-termpath=XXX     specify list of termcap files],
 540         TERMPATH,
 541         /etc/termcap:/usr/share/misc/termcap)
 542 AC_MSG_RESULT($TERMPATH)
 543 test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH")
 544
 545 ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 546 AC_MSG_CHECKING(if fast termcap-loader is needed)
 547 AC_ARG_ENABLE(getcap,
 548         [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 549         [with_getcap=$enableval],
 550         [with_getcap=no])
 551 AC_MSG_RESULT($with_getcap)
 552 test "$with_getcap" = "yes" && AC_DEFINE(USE_GETCAP)
 553
 554 AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 555 AC_ARG_ENABLE(getcap-cache,
 556         [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 557         [with_getcap_cache=$enableval],
 558         [with_getcap_cache=no])
 559 AC_MSG_RESULT($with_getcap_cache)
 560 test "$with_getcap_cache" = "yes" && AC_DEFINE(USE_GETCAP_CACHE)
 561
 562 fi
 563
 564 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 565 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 566 AC_ARG_ENABLE(home-terminfo,
 567         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 568         [with_home_terminfo=$enableval],
 569         [with_home_terminfo=yes])
 570 AC_MSG_RESULT($with_home_terminfo)
 571 test "$with_home_terminfo" = "yes" && AC_DEFINE(USE_HOME_TERMINFO)
 572
 573 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 574 AC_ARG_ENABLE(root-environ,
 575         [  --disable-root-environ  restrict environment when running as root],
 576         [with_root_environ=$enableval],
 577         [with_root_environ=yes])
 578 AC_MSG_RESULT($with_root_environ)
 579 test "$with_root_environ" = yes && AC_DEFINE(USE_ROOT_ENVIRON)
 580
 581 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 582 ###   to reduce storage requirements for the terminfo database.
 583 CF_LINK_FUNCS
 584
 585 with_links=no
 586 with_symlinks=no
 587
 588 # soft links (symbolic links) are useful for some systems where hard links do
 589 # not work, or to make it simpler to copy terminfo trees around.
 590 if test "$ac_cv_func_symlink" = yes ; then
 591     AC_MSG_CHECKING(if tic should use symbolic links)
 592     AC_ARG_ENABLE(symlinks,
 593         [  --enable-symlinks       make tic use symbolic links not hard links],
 594         [with_symlinks=$enableval],
 595         [with_symlinks=no])
 596     AC_MSG_RESULT($with_symlinks)
 597 fi
 598
 599 # If we have hard links and did not choose to use soft links instead, there is
 600 # no reason to make this choice optional - use the hard links.
 601 if test "$with_symlinks" = no ; then
 602     AC_MSG_CHECKING(if tic should use hard links)
 603     if test "$ac_cv_func_link" = yes ; then
 604         with_links=yes
 605     else
 606         with_links=no
 607     fi
 608     AC_MSG_RESULT($with_links)
 609 fi
 610
 611 test "$with_links" = yes && AC_DEFINE(USE_LINKS)
 612 test "$with_symlinks" = yes && AC_DEFINE(USE_SYMLINKS)
 613
 614 ###   use option --enable-broken-linker to force on use of broken-linker support
 615 AC_MSG_CHECKING(if you want broken-linker support code)
 616 AC_ARG_ENABLE(broken_linker,
 617         [  --enable-broken_linker  compile with broken-linker support code],
 618         [with_broken_linker=$enableval],
 619         [with_broken_linker=${BROKEN_LINKER-no}])
 620 AC_MSG_RESULT($with_broken_linker)
 621
 622 BROKEN_LINKER=0
 623 if test "$with_broken_linker" = yes ; then
 624         AC_DEFINE(BROKEN_LINKER)
 625         BROKEN_LINKER=1
 626 elif test "$DFT_LWR_MODEL" = shared ; then
 627         case $cf_cv_system_name in #(vi
 628         cygwin*)
 629                 AC_DEFINE(BROKEN_LINKER)
 630                 BROKEN_LINKER=1
 631                 CF_VERBOSE(cygwin linker is broken anyway)
 632                 ;;
 633         esac
 634 fi
 635 AC_SUBST(BROKEN_LINKER)
 636
 637 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 638 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 639 AC_ARG_ENABLE(bsdpad,
 640         [  --enable-bsdpad         recognize BSD-style prefix padding],
 641         [with_bsdpad=$enableval],
 642         [with_bsdpad=no])
 643 AC_MSG_RESULT($with_bsdpad)
 644 test "$with_bsdpad" = yes && AC_DEFINE(BSD_TPUTS)
 645
 646 ###   use option --enable-widec to turn on use of wide-character support
 647 NCURSES_CH_T=chtype
 648 NCURSES_LIBUTF8=0
 649
 650 NEED_WCHAR_H=0
 651 NCURSES_MBSTATE_T=0
 652 NCURSES_WCHAR_T=0
 653 NCURSES_WINT_T=0
 654
 655 # Check to define _XOPEN_SOURCE "automatically"
 656 CF_XOPEN_SOURCE
 657
 658 # Work around breakage on OS X
 659 CF_SIGWINCH
 660
 661 # Checks for CODESET support.
 662 AM_LANGINFO_CODESET
 663
 664 # use these variables to work around a defect in gcc's fixincludes.
 665 NCURSES_OK_WCHAR_T=
 666 NCURSES_OK_WINT_T=
 667
 668 AC_MSG_CHECKING(if you want wide-character code)
 669 AC_ARG_ENABLE(widec,
 670         [  --enable-widec          compile with wide-char/UTF-8 code],
 671         [with_widec=$enableval],
 672         [with_widec=no])
 673 AC_MSG_RESULT($with_widec)
 674 if test "$with_widec" = yes ; then
 675         LIB_SUFFIX="w${LIB_SUFFIX}"
 676         AC_DEFINE(USE_WIDEC_SUPPORT)
 677         CF_PREDEFINE(_XOPEN_SOURCE_EXTENDED)
 678         # with_overwrite=no
 679         NCURSES_CH_T=cchar_t
 680         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 681         if test "$ac_cv_func_putwc" != yes ; then
 682                 CF_LIBUTF8
 683                 if test "$cf_cv_libutf8" = yes ; then
 684                         NCURSES_LIBUTF8=1
 685                 fi
 686         fi
 687         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 688         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 689         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 690
 691         if test "$NCURSES_MBSTATE_T" != 0; then
 692                 AC_DEFINE(NEED_MBSTATE_T_DEF)
 693         fi
 694 fi
 695 AC_SUBST(NCURSES_CH_T)
 696 AC_SUBST(NCURSES_LIBUTF8)
 697
 698 AC_SUBST(NEED_WCHAR_H)
 699 AC_SUBST(NCURSES_MBSTATE_T)
 700 AC_SUBST(NCURSES_WCHAR_T)
 701 AC_SUBST(NCURSES_WINT_T)
 702
 703 AC_SUBST(NCURSES_OK_WCHAR_T)
 704 AC_SUBST(NCURSES_OK_WINT_T)
 705
 706 ###   use option --disable-lp64 to allow long chtype
 707 case $cf_cv_abi_version in
 708 [[345]]*)
 709         default_with_lp64=no
 710         ;;
 711 *)
 712         default_with_lp64=yes
 713         ;;
 714 esac
 715
 716 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 717 AC_ARG_ENABLE(lp64,
 718         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 719         [with_lp64=$enableval],
 720         [with_lp64=$default_with_lp64])
 721 AC_MSG_RESULT($with_lp64)
 722
 723 if test "$with_lp64" = yes ; then
 724         cf_cv_enable_lp64=1
 725 else
 726         cf_cv_enable_lp64=0
 727 fi
 728 AC_SUBST(cf_cv_enable_lp64)
 729
 730 CF_LARGEFILE
 731
 732 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 733 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 734 AC_ARG_ENABLE(tparm-varargs,
 735         [  --disable-tparm-varargs compile tparm() without varargs interface],
 736         [with_tparm_varargs=$enableval],
 737         [with_tparm_varargs=yes])
 738 AC_MSG_RESULT($with_tparm_varargs)
 739 NCURSES_TPARM_VARARGS=0
 740 test "$with_tparm_varargs" = yes && NCURSES_TPARM_VARARGS=1
 741 AC_SUBST(NCURSES_TPARM_VARARGS)
 742
 743 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
 744 if test "$with_ticlib" != no ; then
 745 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
 746 AC_ARG_ENABLE(tic-depends,
 747         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
 748         [with_tic_depends=$enableval],
 749         [with_tic_depends=yes])
 750 AC_MSG_RESULT($with_tic_depends)
 751 else
 752         with_tic_depends=no
 753 fi
 754
 755 ###   use option --with-bool to override bool's type
 756 AC_MSG_CHECKING(for type of bool)
 757 AC_ARG_WITH(bool,
 758         [  --with-bool=TYPE        override fallback type of bool variable],
 759         [NCURSES_BOOL="$withval"],
 760         [NCURSES_BOOL=auto])
 761 AC_MSG_RESULT($NCURSES_BOOL)
 762 AC_SUBST(NCURSES_BOOL)
 763
 764 AC_MSG_CHECKING(for alternate terminal capabilities file)
 765 AC_ARG_WITH(caps,
 766         [  --with-caps=alt         compile with alternate Caps file],
 767         [TERMINFO_CAPS=Caps.$withval],
 768         [TERMINFO_CAPS=Caps])
 769 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
 770 AC_MSG_RESULT($TERMINFO_CAPS)
 771 AC_SUBST(TERMINFO_CAPS)
 772
 773 ###   use option --with-chtype to override chtype's type
 774 AC_MSG_CHECKING(for type of chtype)
 775 AC_ARG_WITH(chtype,
 776         [  --with-chtype=TYPE      override type of chtype],
 777         [NCURSES_CHTYPE="$withval"],
 778         [NCURSES_CHTYPE=auto])
 779 AC_MSG_RESULT($NCURSES_CHTYPE)
 780
 781 ###   use option --with-ospeed to override ospeed's type
 782 AC_MSG_CHECKING(for type of ospeed)
 783 AC_ARG_WITH(ospeed,
 784         [  --with-ospeed=TYPE      override type of ospeed variable],
 785         [NCURSES_OSPEED="$withval"],
 786         [NCURSES_OSPEED=short])
 787 AC_MSG_RESULT($NCURSES_OSPEED)
 788 AC_SUBST(NCURSES_OSPEED)
 789
 790 ###   use option --with-mmask-t to override mmask_t's type
 791 AC_MSG_CHECKING(for type of mmask_t)
 792 AC_ARG_WITH(mmask-t,
 793         [  --with-mmask-t=TYPE     override type of mmask_t],
 794         [NCURSES_MMASK_T="$withval"],
 795         [NCURSES_MMASK_T=auto])
 796 AC_MSG_RESULT($NCURSES_MMASK_T)
 797
 798 ### Enable compiling-in rcs id's
 799 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
 800 AC_ARG_WITH(rcs-ids,
 801         [  --with-rcs-ids          compile-in RCS identifiers],
 802         [with_rcs_ids=$withval],
 803         [with_rcs_ids=no])
 804 AC_MSG_RESULT($with_rcs_ids)
 805 test "$with_rcs_ids" = yes && AC_DEFINE(USE_RCS_IDS)
 806
 807 ###############################################################################
 808 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tic toe tput ])
 809
 810 ###############################################################################
 811 CF_HELP_MESSAGE(Extensions:)
 812
 813 ### Note that some functions (such as const) are normally disabled anyway.
 814 AC_MSG_CHECKING(if you want to build with function extensions)
 815 AC_ARG_ENABLE(ext-funcs,
 816         [  --disable-ext-funcs     disable function-extensions],
 817         [with_ext_funcs=$enableval],
 818         [with_ext_funcs=yes])
 819 AC_MSG_RESULT($with_ext_funcs)
 820 if test "$with_ext_funcs" = yes ; then
 821         NCURSES_EXT_FUNCS=1
 822         AC_DEFINE(HAVE_CURSES_VERSION)
 823         AC_DEFINE(HAVE_HAS_KEY)
 824         AC_DEFINE(HAVE_RESIZETERM)
 825         AC_DEFINE(HAVE_RESIZE_TERM)
 826         AC_DEFINE(HAVE_USE_DEFAULT_COLORS)
 827         AC_DEFINE(HAVE_WRESIZE)
 828         AC_DEFINE(NCURSES_EXT_FUNCS)
 829 else
 830         NCURSES_EXT_FUNCS=0
 831 fi
 832 AC_SUBST(NCURSES_EXT_FUNCS)
 833
 834 ###   use option --enable-const to turn on use of const beyond that in XSI.
 835 AC_MSG_CHECKING(for extended use of const keyword)
 836 AC_ARG_ENABLE(const,
 837         [  --enable-const          compile with extra/non-standard const],
 838         [with_ext_const=$enableval],
 839         [with_ext_const=no])
 840 AC_MSG_RESULT($with_ext_const)
 841 NCURSES_CONST='/*nothing*/'
 842 if test "$with_ext_const" = yes ; then
 843         NCURSES_CONST=const
 844 fi
 845 AC_SUBST(NCURSES_CONST)
 846
 847 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
 848 AC_MSG_CHECKING(if you want to use extended colors)
 849 AC_ARG_ENABLE(ext-colors,
 850         [  --enable-ext-colors     compile for 256-color support],
 851         [with_ext_colors=$enableval],
 852         [with_ext_colors=no])
 853 AC_MSG_RESULT($with_ext_colors)
 854 NCURSES_EXT_COLORS=0
 855 if test "$with_ext_colors" = yes ; then
 856         if test "$with_widec" != yes ; then
 857                 AC_MSG_ERROR(This option applies only to wide-character library)
 858         else
 859                 # cannot be ABI 5 since it changes sizeof(cchar_t)
 860                 CF_NCURSES_ABI_6
 861         fi
 862         NCURSES_EXT_COLORS=1
 863         AC_DEFINE(NCURSES_EXT_COLORS)
 864 fi
 865 AC_SUBST(NCURSES_EXT_COLORS)
 866
 867 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
 868 AC_MSG_CHECKING(if you want to use extended mouse encoding)
 869 AC_ARG_ENABLE(ext-mouse,
 870         [  --enable-ext-mouse      compile for extended mouse-encoding],
 871         [with_ext_mouse=$enableval],
 872         [with_ext_mouse=no])
 873 AC_MSG_RESULT($with_ext_mouse)
 874 NCURSES_MOUSE_VERSION=1
 875 if test "$with_ext_mouse" = yes ; then
 876         NCURSES_MOUSE_VERSION=2
 877         CF_NCURSES_ABI_6
 878 fi
 879 AC_SUBST(NCURSES_MOUSE_VERSION)
 880
 881 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
 882 AC_ARG_ENABLE(no-padding,
 883         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
 884         [with_no_padding=$enableval],
 885         [with_no_padding=$with_ext_funcs])
 886 AC_MSG_RESULT($with_no_padding)
 887 test "$with_no_padding" = yes && AC_DEFINE(NCURSES_NO_PADDING)
 888
 889 AC_CHECK_SIZEOF([signed char], 0)
 890 if test "$ac_cv_sizeof_signed_char" = 1 ; then
 891         NCURSES_SBOOL="signed char"
 892 else
 893         NCURSES_SBOOL="char"
 894 fi
 895 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
 896 AC_ARG_ENABLE(signed-char,
 897         [  --enable-signed-char    compile using signed Boolean's in term.h],
 898         [with_signed_char=$enableval],
 899         [with_signed_char=no])
 900 AC_MSG_RESULT($with_signed_char)
 901 test "$with_signed_char" != yes && NCURSES_SBOOL="char"
 902 AC_SUBST(NCURSES_SBOOL)
 903
 904 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
 905 AC_MSG_CHECKING(if you want SIGWINCH handler)
 906 AC_ARG_ENABLE(sigwinch,
 907         [  --enable-sigwinch       compile with SIGWINCH handler],
 908         [with_sigwinch=$enableval],
 909         [with_sigwinch=$with_ext_funcs])
 910 AC_MSG_RESULT($with_sigwinch)
 911 test "$with_sigwinch" = yes && AC_DEFINE(USE_SIGWINCH)
 912
 913 ###   use option --enable-tcap-names to allow user to define new capabilities
 914 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
 915 AC_ARG_ENABLE(tcap-names,
 916         [  --enable-tcap-names     compile with user-definable terminal capabilities],
 917         [with_tcap_names=$enableval],
 918         [with_tcap_names=$with_ext_funcs])
 919 AC_MSG_RESULT($with_tcap_names)
 920 NCURSES_XNAMES=0
 921 test "$with_tcap_names" = yes && NCURSES_XNAMES=1
 922 AC_SUBST(NCURSES_XNAMES)
 923
 924 ###############################################################################
 925 # These options are relatively safe to experiment with.
 926 CF_HELP_MESSAGE(Development Code:)
 927 AC_MSG_CHECKING(if you want all development code)
 928 AC_ARG_WITH(develop,
 929         [  --without-develop       disable development options],
 930         [with_develop=$withval],
 931         [with_develop=no])
 932 AC_MSG_RESULT($with_develop)
 933
 934 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
 935 AC_MSG_CHECKING(if you want hard-tabs code)
 936 AC_ARG_ENABLE(hard-tabs,
 937         [  --enable-hard-tabs      compile with hard-tabs code],,
 938         [enable_hard_tabs=$with_develop])
 939 AC_MSG_RESULT($enable_hard_tabs)
 940 test "$enable_hard_tabs" = yes && AC_DEFINE(USE_HARD_TABS)
 941
 942 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
 943 AC_MSG_CHECKING(if you want limited support for xmc)
 944 AC_ARG_ENABLE(xmc-glitch,
 945         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
 946         [enable_xmc_glitch=$with_develop])
 947 AC_MSG_RESULT($enable_xmc_glitch)
 948 test "$enable_xmc_glitch" = yes && AC_DEFINE(USE_XMC_SUPPORT)
 949
 950 ###############################################################################
 951 # These are just experimental, probably should not be in a package:
 952 CF_HELP_MESSAGE(Experimental Code:)
 953
 954 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
 955 AC_ARG_ENABLE(assumed-color,
 956         [  --disable-assumed-color do not assume anything about default-colors],
 957         [with_assumed_color=$enableval],
 958         [with_assumed_color=yes])
 959 AC_MSG_RESULT($with_assumed_color)
 960 test "$with_assumed_color" = yes && AC_DEFINE(USE_ASSUMED_COLOR)
 961
 962 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
 963 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
 964 AC_ARG_ENABLE(hashmap,
 965         [  --disable-hashmap       compile without hashmap scrolling-optimization],
 966         [with_hashmap=$enableval],
 967         [with_hashmap=yes])
 968 AC_MSG_RESULT($with_hashmap)
 969 test "$with_hashmap" = yes && AC_DEFINE(USE_HASHMAP)
 970
 971 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
 972 AC_MSG_CHECKING(if you want colorfgbg code)
 973 AC_ARG_ENABLE(colorfgbg,
 974         [  --enable-colorfgbg      compile with $COLORFGBG code],
 975         [with_colorfgbg=$enableval],
 976         [with_colorfgbg=no])
 977 AC_MSG_RESULT($with_colorfgbg)
 978 test "$with_colorfgbg" = yes && AC_DEFINE(USE_COLORFGBG)
 979
 980 # This is still experimental (20080329), but should ultimately be moved to
 981 # the script-block --with-normal, etc.
 982 CF_WITH_PTHREAD
 983
 984 AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
 985 AC_ARG_ENABLE(weak-symbols,
 986     [  --enable-weak-symbols   enable weak-symbols for pthreads],
 987     [use_weak_symbols=$withval],
 988     [use_weak_symbols=no])
 989 AC_MSG_RESULT($use_weak_symbols)
 990 if test "$use_weak_symbols" = yes ; then
 991     CF_WEAK_SYMBOLS
 992 else
 993     cf_cv_weak_symbols=no
 994 fi
 995
 996 if test $cf_cv_weak_symbols = yes ; then
 997     AC_DEFINE(USE_WEAK_SYMBOLS)
 998 fi
 999
1000 PTHREAD=
1001 if test "$with_pthread" = "yes" ; then
1002     AC_DEFINE(USE_PTHREADS)
1003     enable_reentrant=yes
1004     if test $cf_cv_weak_symbols = yes ; then
1005         PTHREAD=-lpthread
1006     fi
1007 fi
1008 AC_SUBST(PTHREAD)
1009
1010 # Reentrant code has to be opaque; there's little advantage to making ncurses
1011 # opaque outside of that, so there is no --enable-opaque option.  We can use
1012 # this option without --with-pthreads, but this will be always set for
1013 # pthreads.
1014 AC_MSG_CHECKING(if you want experimental reentrant code)
1015 AC_ARG_ENABLE(reentrant,
1016         [  --enable-reentrant      compile with experimental reentrant code],
1017         [with_reentrant=$enableval],
1018         [with_reentrant=no])
1019 AC_MSG_RESULT($with_reentrant)
1020 if test "$with_reentrant" = yes ; then
1021         cf_cv_enable_reentrant=1
1022         cf_cv_enable_opaque="NCURSES_INTERNALS"
1023         NCURSES_OPAQUE=1
1024         NCURSES_SIZE_T=int
1025     if test $cf_cv_weak_symbols = yes ; then
1026         CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1027     else
1028         LIB_SUFFIX="t${LIB_SUFFIX}"
1029     fi
1030         AC_DEFINE(USE_REENTRANT)
1031         CF_NCURSES_ABI_6
1032 else
1033         cf_cv_enable_reentrant=0
1034         cf_cv_enable_opaque="NCURSES_OPAQUE"
1035         NCURSES_OPAQUE=0
1036         NCURSES_SIZE_T=short
1037 fi
1038 AC_SUBST(cf_cv_enable_reentrant)
1039 AC_SUBST(cf_cv_enable_opaque)
1040 AC_SUBST(NCURSES_OPAQUE)
1041 AC_SUBST(NCURSES_SIZE_T)
1042
1043 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1044 AC_ARG_ENABLE(safe-sprintf,
1045         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1046         [with_safe_sprintf=$enableval],
1047         [with_safe_sprintf=no])
1048 AC_MSG_RESULT($with_safe_sprintf)
1049 test "$with_safe_sprintf" = yes && AC_DEFINE(USE_SAFE_SPRINTF)
1050
1051 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1052 # when hashmap is used scroll hints are useless
1053 if test "$with_hashmap" = no ; then
1054 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1055 AC_ARG_ENABLE(scroll-hints,
1056         [  --disable-scroll-hints  compile without scroll-hints code],
1057         [with_scroll_hints=$enableval],
1058         [with_scroll_hints=yes])
1059 AC_MSG_RESULT($with_scroll_hints)
1060 test "$with_scroll_hints" = yes && AC_DEFINE(USE_SCROLL_HINTS)
1061 fi
1062
1063 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1064 AC_ARG_ENABLE(wgetch-events,
1065         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1066         [with_wgetch_events=$enableval],
1067         [with_wgetch_events=no])
1068 AC_MSG_RESULT($with_wgetch_events)
1069 test "$with_wgetch_events" = yes && AC_DEFINE(NCURSES_WGETCH_EVENTS)
1070
1071 ###############################################################################
1072 CF_HELP_MESSAGE(Testing/development Options:)
1073
1074 ###     use option --disable-echo to suppress full display compiling commands
1075 AC_MSG_CHECKING(if you want to display full commands during build)
1076 AC_ARG_ENABLE(echo,
1077         [  --enable-echo           build: display "compiling" commands (default)],
1078         [with_echo=$enableval],
1079         [with_echo=yes])
1080 if test "$with_echo" = yes; then
1081         ECHO_LINK=
1082 else
1083         ECHO_LINK='@ echo linking $@ ... ;'
1084         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1085         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1086 fi
1087 AC_MSG_RESULT($with_echo)
1088 AC_SUBST(ECHO_LINK)
1089
1090 ###     use option --enable-warnings to turn on all gcc warnings
1091 AC_MSG_CHECKING(if you want to see compiler warnings)
1092 AC_ARG_ENABLE(warnings,
1093         [  --enable-warnings       build: turn on GCC compiler warnings],
1094         [with_warnings=$enableval])
1095 AC_MSG_RESULT($with_warnings)
1096
1097 if test "x$with_warnings" = "xyes"; then
1098         ADAFLAGS="$ADAFLAGS -gnatg"
1099         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
1100         if test "$cf_with_cxx" = yes ; then
1101                 CF_GXX_WARNINGS(Wno-unused)
1102         fi
1103 fi
1104 CF_GCC_ATTRIBUTES
1105
1106 ###     use option --enable-assertions to turn on generation of assertion code
1107 AC_MSG_CHECKING(if you want to enable runtime assertions)
1108 AC_ARG_ENABLE(assertions,
1109         [  --enable-assertions     test: turn on generation of assertion code],
1110         [with_assertions=$enableval],
1111         [with_assertions=no])
1112 AC_MSG_RESULT($with_assertions)
1113 if test -n "$GCC"
1114 then
1115         if test "$with_assertions" = no
1116         then
1117                 AC_DEFINE(NDEBUG)
1118                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1119         else
1120                 ADAFLAGS="$ADAFLAGS -gnata"
1121         fi
1122 fi
1123
1124 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1125 CF_DISABLE_LEAKS
1126 AC_DEFINE(HAVE_NC_ALLOC_H)
1127
1128 ###     use option --enable-expanded to generate certain macros as functions
1129 AC_ARG_ENABLE(expanded,
1130         [  --enable-expanded       test: generate functions for certain macros],
1131         [test "$enableval" = yes && AC_DEFINE(NCURSES_EXPANDED)])
1132
1133 ###     use option --disable-macros to suppress macros in favor of functions
1134 AC_ARG_ENABLE(macros,
1135         [  --disable-macros        test: use functions rather than macros],
1136         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS)])
1137
1138 # Normally we only add trace() to the debug-library.  Allow this to be
1139 # extended to all models of the ncurses library:
1140 cf_all_traces=no
1141 case "$CFLAGS $CPPFLAGS" in
1142 *-DTRACE*)
1143         cf_all_traces=yes
1144         ;;
1145 esac
1146
1147 AC_MSG_CHECKING(whether to add trace feature to all models)
1148 AC_ARG_WITH(trace,
1149 [  --with-trace            test: add trace() function to all models of ncurses],
1150 [cf_with_trace=$withval],
1151 [cf_with_trace=$cf_all_traces])
1152 AC_MSG_RESULT($cf_with_trace)
1153
1154 if test "$cf_with_trace" = yes ; then
1155         LIB_TRACING=all
1156         ADA_TRACE=TRUE
1157         CF_ADD_CFLAGS(-DTRACE)
1158 else
1159         LIB_TRACING=DEBUG
1160         ADA_TRACE=FALSE
1161 fi
1162
1163 AC_SUBST(ADA_TRACE)
1164
1165 ###     Checks for libraries.
1166 AC_CHECK_FUNC(gettimeofday,
1167         AC_DEFINE(HAVE_GETTIMEOFDAY),[
1168
1169 AC_CHECK_LIB(bsd, gettimeofday,
1170         AC_DEFINE(HAVE_GETTIMEOFDAY)
1171         LIBS="$LIBS -lbsd")])dnl CLIX: bzero, select, gettimeofday
1172
1173 CF_MATH_LIB(MATH_LIB,sin(x))
1174 AC_SUBST(MATH_LIB)
1175
1176 ###     Checks for header files.
1177 AC_STDC_HEADERS
1178 AC_HEADER_DIRENT
1179 AC_HEADER_TIME
1180 CF_REGEX
1181
1182 dnl These are some other potentially nonportable headers.
1183 AC_CHECK_HEADERS( \
1184 fcntl.h \
1185 getopt.h \
1186 limits.h \
1187 locale.h \
1188 poll.h \
1189 sys/bsdtypes.h \
1190 sys/ioctl.h \
1191 sys/param.h \
1192 sys/poll.h \
1193 sys/select.h \
1194 sys/time.h \
1195 sys/times.h \
1196 ttyent.h \
1197 unistd.h \
1198 wctype.h \
1199 )
1200
1201 # check for ISC (this may also define _POSIX_SOURCE)
1202 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1203 if test "$ISC" = yes ; then
1204         AC_CHECK_LIB(cposix,main)
1205         AC_CHECK_LIB(inet,bzero,LIBS="$LIBS -linet")dnl also 'select()'
1206 fi
1207
1208 CF_SYS_TIME_SELECT
1209
1210 ###     checks for compiler characteristics
1211 AC_LANG_C
1212 AC_C_CONST
1213 CF_C_INLINE(NCURSES_INLINE,1200)
1214 CF_SIG_ATOMIC_T
1215
1216 if test $NCURSES_CHTYPE = auto ; then
1217         CF_TYPEOF_CHTYPE
1218 else
1219         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1220 fi
1221 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1222 AC_SUBST(cf_cv_typeof_chtype)
1223
1224 CF_UNSIGNED_LITERALS
1225 cf_cv_1UL="1"
1226 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1227 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1228 AC_SUBST(cf_cv_1UL)
1229
1230 if test $NCURSES_MMASK_T = auto ; then
1231         cf_cv_typeof_mmask_t=long
1232 else
1233         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1234 fi
1235 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1236 AC_SUBST(cf_cv_typeof_mmask_t)
1237
1238 ###     Checks for external-data
1239 CF_ERRNO
1240 CF_LINK_DATAONLY
1241
1242 ###     Checks for library functions.
1243 AC_CHECK_FUNCS( \
1244 getcwd \
1245 getegid \
1246 geteuid \
1247 getttynam \
1248 issetugid \
1249 poll \
1250 remove \
1251 select \
1252 setbuf \
1253 setbuffer \
1254 setvbuf \
1255 sigaction \
1256 sigvec \
1257 strdup \
1258 strstr \
1259 tcgetpgrp \
1260 times \
1261 vsnprintf \
1262 )
1263 if test "$with_getcap" = "yes" ; then
1264         CF_CGETENT
1265 fi
1266
1267 CF_ISASCII
1268 CF_STRUCT_SIGACTION
1269 CF_FUNC_NANOSLEEP
1270 CF_FUNC_TERMIOS
1271 CF_FUNC_VSSCANF
1272 CF_MKSTEMP
1273
1274 # setup for prototype of fallback for vsscanf()
1275 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1276
1277 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1278 if test "$cross_compiling" = yes ; then
1279         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1280 else
1281         AC_FUNC_SETVBUF_REVERSED
1282 fi
1283 AC_TYPE_SIGNAL
1284 CF_TYPE_SIGACTION
1285 CF_SIZECHANGE
1286 CF_FUNC_MEMMOVE
1287 CF_FUNC_POLL
1288
1289 # special check for test/ditto.c
1290 CF_FUNC_OPENPTY
1291 if test "$cf_cv_func_openpty" != no ; then
1292     AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>)
1293     AC_DEFINE(USE_XTERM_PTY)
1294     if test "$cf_cv_lib_util" = yes ; then
1295         TEST_LIBS="-lutil $TEST_LIBS"
1296     fi
1297 fi
1298 AC_SUBST(TEST_LIBS)
1299
1300 if test "$with_hashed_db" != no ; then
1301         AC_DEFINE(USE_HASHED_DB)
1302         CF_HASHED_DB($with_hashed_db)
1303 fi
1304
1305 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1306 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1307         CF_STRIP_G_OPT(CFLAGS)
1308         CF_STRIP_G_OPT(CXXFLAGS)
1309 fi
1310
1311 # Just in case, check if the C compiler has a bool type.
1312 CF_BOOL_DECL(cf_cv_cc_bool_type)
1313
1314 # Check for C++ compiler characteristics (and ensure that it's there!)
1315 if test -n "$CXX" ; then
1316         AC_LANG_CPLUSPLUS
1317         CF_STDCPP_LIBRARY
1318         CF_PROG_CC_C_O(CXX)
1319
1320         case $GXX_VERSION in
1321         1*|2.[0-6]*)
1322                 cf_cxx_library=yes
1323                 ;;
1324         *-2.7*|2.7*)
1325                 CF_GPP_LIBRARY
1326                 ;;
1327         *)
1328                 cf_cxx_library=no
1329                 ;;
1330         esac
1331
1332         AC_CHECK_HEADERS(iostream typeinfo)
1333
1334     if test x"$ac_cv_header_iostream" = xyes ; then
1335         AC_MSG_CHECKING(if iostream uses std-namespace)
1336         AC_TRY_COMPILE([
1337 #include <iostream>
1338 using std::endl;
1339 using std::cerr;],[
1340 cerr << "testing" << endl;
1341 ],[cf_iostream_namespace=yes],[cf_iostream_namespace=no])
1342         AC_MSG_RESULT($cf_iostream_namespace)
1343         if test "$cf_iostream_namespace" = yes ; then
1344             AC_DEFINE(IOSTREAM_NAMESPACE)
1345         fi
1346     fi
1347
1348         CF_BOOL_DECL
1349         CF_BOOL_SIZE
1350         CF_ETIP_DEFINES
1351         CF_CPP_PARAM_INIT
1352         CF_CPP_STATIC_CAST
1353
1354         CXX_AR='$(AR)'
1355         CXX_AR_OPTS='$(AR_OPTS)'
1356         case $cf_cv_system_name in #(vi
1357         irix*) #(vi
1358             if test "$GXX" != yes ; then
1359                 CXX_AR='$(CXX)'
1360                 CXX_AR_OPTS='-ar -o'
1361             fi
1362             ;;
1363         sco3.2v5*) #(vi
1364             CXXLDFLAGS="-u main"
1365             ;;
1366         solaris2*)
1367             if test "$GXX" != yes ; then
1368                 CXX_AR='$(CXX)'
1369                 CXX_AR_OPTS='-xar -o'
1370             fi
1371             ;;
1372         esac
1373         AC_SUBST(CXXLDFLAGS)
1374         AC_SUBST(CXX_AR)
1375         AC_SUBST(CXX_AR_OPTS)
1376 else
1377         cf_cxx_library=no
1378         cf_cv_builtin_bool=1
1379
1380         # Just because we are not configuring against C++ right now does not
1381         # mean that a user will not want to use C++.  Some distributors disable
1382         # the C++ portion of this configuration as a shortcut (or just to avoid
1383         # compiling the demo in the c++ directory).  So we need a reasonable
1384         # default for the 'bool' type.
1385         #
1386         # Caveat: since the storage of the bool type is not standardized, it
1387         # may change.
1388
1389         if test "$NCURSES_BOOL" != auto ; then
1390                 cf_cv_type_of_bool=$NCURSES_BOOL
1391                 cf_cv_header_stdbool_h=0
1392         else
1393                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1394                         CF_BOOL_SIZE
1395                 else
1396                         AC_MSG_CHECKING(for fallback type of bool)
1397                         case "$host_cpu" in #(vi
1398                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1399                         *)      cf_cv_type_of_bool=int  ;;
1400                         esac
1401                         AC_MSG_RESULT($cf_cv_type_of_bool)
1402                 fi
1403         fi
1404 fi
1405 AC_SUBST(CXXLIBS)
1406
1407 # If the C compiler did not declare bool, and we did not determine that the C++
1408 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1409 # ncurses library use the same type as C++ bool.  Note that this allows one to
1410 # specify the type of bool in a configure-script option and postpone
1411 # integration with the C++ compiler provided that the types are compatible.
1412 USE_CXX_BOOL=1
1413 if test $cf_cv_cc_bool_type = 1
1414 then
1415         # oops: C has a bool.  Unlikely, but C++ could differ.
1416         USE_CXX_BOOL=0
1417 elif test $cf_cv_builtin_bool = 0
1418 then
1419         # C++ has no bool
1420         USE_CXX_BOOL=0
1421 else
1422         # this is the normal case
1423         USE_CXX_BOOL='defined(__cplusplus)'
1424 fi
1425 AC_SUBST(USE_CXX_BOOL)
1426
1427 CF_HELP_MESSAGE(Ada95 Binding Options:)
1428
1429 dnl If the Ada95 source-tree is present, add that to the build unless it will
1430 dnl not work, or was not requested.
1431 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1432
1433 dnl libtool does not know anything about GNAT, though a change made in 1998
1434 dnl provided for it "someday".  Disable the ada subtree if we are using
1435 dnl libtool -TD 20070714
1436 if test "$cf_with_ada" != "no" ; then
1437     if test "$with_libtool" != "no"; then
1438         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1439         cf_with_ada=no
1440     fi
1441 fi
1442
1443 dnl Check for availability of GNU Ada Translator (GNAT).
1444 dnl At the moment we support no other Ada95 compiler.
1445 if test "$cf_with_ada" != "no" ; then
1446 cf_ada_make=gnatmake
1447 AC_CHECK_PROG(gnat_exists, $cf_ada_make, yes, no)
1448 if test "$ac_cv_prog_gnat_exists" = no; then
1449    cf_ada_make=
1450 else
1451    CF_GNAT_VERSION
1452    AC_CHECK_PROG(M4_exists, m4, yes, no)
1453    if test "$ac_cv_prog_M4_exists" = no; then
1454       cf_cv_prog_gnat_correct=no
1455       echo Ada95 binding required program m4 not found. Ada95 binding disabled.
1456    fi
1457    if test "$cf_cv_prog_gnat_correct" = yes; then
1458       AC_MSG_CHECKING(if GNAT works)
1459       CF_GNAT_TRY_RUN([procedure conftest;],
1460 [with Text_IO;
1461 with GNAT.OS_Lib;
1462 procedure conftest is
1463 begin
1464    Text_IO.Put ("Hello World");
1465    Text_IO.New_Line;
1466    GNAT.OS_Lib.OS_Exit (0);
1467 end conftest;],[cf_cv_prog_gnat_correct=yes],[cf_cv_prog_gnat_correct=no])
1468       AC_MSG_RESULT($cf_cv_prog_gnat_correct)
1469    fi
1470 fi
1471 if test "$cf_cv_prog_gnat_correct" = yes; then
1472    ADAFLAGS="-O3 -gnatpn $ADAFLAGS"
1473
1474    AC_MSG_CHECKING(if GNAT pragma Unreferenced works)
1475    CF_GNAT_TRY_LINK([procedure conftest;],
1476 [with Text_IO;
1477 with GNAT.OS_Lib;
1478 procedure conftest is
1479    test : Integer;
1480    pragma Unreferenced (test);
1481 begin
1482    test := 1;
1483    Text_IO.Put ("Hello World");
1484    Text_IO.New_Line;
1485    GNAT.OS_Lib.OS_Exit (0);
1486 end conftest;],[cf_cv_pragma_unreferenced=yes],[cf_cv_pragma_unreferenced=no])
1487    AC_MSG_RESULT($cf_cv_pragma_unreferenced)
1488
1489    # if the pragma is supported, use it (needed in the Trace code).
1490    if test $cf_cv_pragma_unreferenced = yes ; then
1491       PRAGMA_UNREF=TRUE
1492    else
1493       PRAGMA_UNREF=FALSE
1494    fi
1495
1496    AC_ARG_WITH(ada-compiler,
1497         [  --with-ada-compiler=CMD specify Ada95 compiler command (default gnatmake)],
1498         [cf_ada_compiler=$withval],
1499         [cf_ada_compiler=gnatmake])
1500
1501    cf_ada_package=terminal_interface
1502
1503    AC_SUBST(cf_ada_make)
1504    AC_SUBST(cf_ada_compiler)
1505    AC_SUBST(cf_ada_package)
1506    AC_SUBST(ADAFLAGS)
1507    AC_SUBST(cf_compile_generics)
1508    AC_SUBST(cf_generic_objects)
1509    AC_SUBST(PRAGMA_UNREF)
1510
1511    CF_WITH_PATH(ada-include,
1512        [  --with-ada-include=DIR  Ada includes are in DIR],
1513        ADA_INCLUDE,
1514        PREFIX/lib/ada/adainclude,
1515        [$]prefix/lib/ada/adainclude)
1516    AC_SUBST(ADA_INCLUDE)
1517
1518    CF_WITH_PATH(ada-objects,
1519        [  --with-ada-objects=DIR  Ada objects are in DIR],
1520        ADA_OBJECTS,
1521        PREFIX/lib/ada/adalib,
1522        [$]prefix/lib/ada/adalib)
1523    AC_SUBST(ADA_OBJECTS)
1524
1525 fi
1526 fi
1527 else
1528    cf_with_ada=no
1529 fi
1530
1531 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1532 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1533 ###
1534 ### ticlib modules may be a separate library, otherwise contained in termlib.
1535 ### termlib modules may be a separate library, otherwise contained in ncurses.
1536 ###
1537 ### The of "+" or " " between the tokens controls the way the script
1538 ### chooses to split module lists into libraries.
1539 ###
1540 ### (see CF_LIB_RULES).
1541 AC_MSG_CHECKING(for library subsets)
1542 LIB_SUBSETS=
1543
1544 if test "$cf_with_progs" = yes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1545         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1546         if test "$with_ticlib" != no ; then
1547                 LIB_SUBSETS="${LIB_SUBSETS} "
1548         else
1549                 LIB_SUBSETS="${LIB_SUBSETS}+"
1550         fi
1551 fi
1552
1553 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1554 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1555 if test "$with_termlib" != no ; then
1556         LIB_SUBSETS="${LIB_SUBSETS} "
1557 else
1558         LIB_SUBSETS="${LIB_SUBSETS}+"
1559 fi
1560
1561 LIB_SUBSETS="${LIB_SUBSETS}base"
1562 test "$with_widec"     = yes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1563 test "$with_ext_funcs" = yes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1564
1565 AC_MSG_RESULT($LIB_SUBSETS)
1566
1567 ### Construct the list of include-directories to be generated
1568 CF_INCLUDE_DIRS
1569 CF_ADA_INCLUDE_DIRS
1570
1571 ### Build up pieces for makefile rules
1572 AC_MSG_CHECKING(default library suffix)
1573 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1574 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1575 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1576
1577 AC_MSG_CHECKING(default library-dependency suffix)
1578 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1579 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1580 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1581
1582 AC_MSG_CHECKING(default object directory)
1583 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1584 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1585 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1586
1587 # libtool thinks it can make c++ shared libraries (perhaps only g++)
1588 if test "$cf_with_cxx" = yes ; then
1589 AC_MSG_CHECKING(c++ library-dependency suffix)
1590 if test "$with_libtool" != "no"; then
1591         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1592 else
1593         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)dnl we normally make a static library
1594 fi
1595 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1596 AC_SUBST(CXX_LIB_SUFFIX)
1597 fi
1598
1599 # do not want -ldl in build except as needed for -lncurses dependency
1600 if test "$with_dlsym" = yes ; then
1601 if test $DFT_LWR_MODEL = shared || \
1602    test $DFT_LWR_MODEL = libtool ; then
1603         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1604 fi
1605 fi
1606 ### Set up low-level terminfo dependencies for makefiles.
1607
1608 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1609 # do not need libdl
1610 TICS_LIST=
1611 if test "$with_dlsym" = yes ; then
1612         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1613 fi
1614
1615 if test "$with_ticlib" != no ; then
1616
1617         if test "$with_ticlib" != yes ; then
1618                 TICS_NAME=$with_ticlib
1619                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1620                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1621                 TICS_LIB_SUFFIX="${with_ticlib}"
1622         else
1623                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1624                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1625                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1626         fi
1627         TICS_ARGS="-L${LIB_DIR} -l${TICS_LIB_SUFFIX}"
1628 else
1629         TICS_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1630 fi
1631 AC_SUBST(TICS_ARG_SUFFIX)
1632 AC_SUBST(TICS_DEP_SUFFIX)
1633 AC_SUBST(TICS_LIB_SUFFIX)
1634 AC_SUBST(TICS_ARGS)
1635
1636 if test "$with_termlib" != no ; then
1637
1638         if test "$with_termlib" != yes ; then
1639                 TINFO_NAME=$with_termlib
1640                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1641                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1642                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1643                 TINFO_LIB_SUFFIX="${with_termlib}"
1644         else
1645                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1646                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1647                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1648                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1649         fi
1650
1651         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1652         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1653         if test "$DFT_LWR_MODEL" = "libtool"; then
1654                 TEST_ARGS="${TEST_DEPS}"
1655                 TEST_ARG2="${TEST_DEP2}"
1656                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1657         else
1658                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1659                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1660                 TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1661                 TINFO_ARGS="-L${LIB_DIR} $TEST_ARGS"
1662                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1663         fi
1664 else
1665         # the next lines are needed for linking libtic over libncurses
1666         TINFO_NAME=${LIB_NAME}
1667         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1668         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1669         if test "$with_tic_depends" = yes ; then
1670                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1671         else
1672                 TICS_LIST="$SHLIB_LIST"
1673         fi
1674
1675         TINFO_ARGS="-L${LIB_DIR} -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1676 fi
1677
1678 if test "$DFT_LWR_MODEL" = shared ; then
1679         case $cf_cv_system_name in #(vi
1680         cygwin*)
1681                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
1682                 TINFO_SUFFIX=.dll
1683                 ;;
1684         esac
1685 fi
1686
1687 AC_SUBST(TINFO_ARG_SUFFIX)
1688 AC_SUBST(TINFO_DEP_SUFFIX)
1689 AC_SUBST(TINFO_LIB_SUFFIX)
1690 AC_SUBST(TINFO_ARGS)
1691
1692 if test "$with_dlsym" = yes ; then
1693         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1694 fi
1695
1696 if test "$DFT_LWR_MODEL" = "libtool"; then
1697     OBJEXT=lo
1698 fi
1699
1700 # needed for Ada95
1701 TINFO_ARGS2=`echo "$TINFO_ARGS" | sed -e 's,-L\.\./,-L../../,'`
1702 AC_SUBST(TINFO_ARGS2)
1703
1704 case $DFT_LWR_MODEL in
1705 normal|debug|profile)
1706         CF_LDFLAGS_STATIC
1707         ;;
1708 esac
1709
1710 AC_MSG_CHECKING(where we will install curses.h)
1711 test "$with_overwrite" = no && \
1712 test "x$includedir" = 'x${prefix}/include' && \
1713         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1714 AC_MSG_RESULT($includedir)
1715
1716 ### Resolve a conflict between normal and wide-curses by forcing applications
1717 ### that will need libutf8 to add it to their configure script.
1718 if test "$with_overwrite" != no ; then
1719 if test "$NCURSES_LIBUTF8" = 1 ; then
1720         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1721         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1722 fi
1723 fi
1724
1725 AC_SUBST(WITH_OVERWRITE)
1726 AC_SUBST(TICS_LIST)
1727 AC_SUBST(TINFO_LIST)
1728 AC_SUBST(SHLIB_LIST)
1729
1730 # used to separate tack out of the tree
1731 NCURSES_TREE=
1732 AC_SUBST(NCURSES_TREE)
1733
1734 ### predefined stuff for the test programs
1735 AC_DEFINE(HAVE_SLK_COLOR)
1736
1737 ### Construct the list of subdirectories for which we'll customize makefiles
1738 ### with the appropriate compile-rules.
1739
1740 CF_SRC_MODULES($modules_to_build)
1741
1742 if test "$cf_with_ada" != "no" && test "$cf_cv_prog_gnat_correct" != "no"; then
1743    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses-config"
1744 fi
1745
1746 CF_DIRS_TO_MAKE
1747
1748 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATHSEP')
1749
1750 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}")
1751
1752 ### Now that we're done running tests, add the compiler-warnings, if any
1753 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1754
1755 ### If we're building with rpath, try to link non-standard libs that way too.
1756 if test "$DFT_LWR_MODEL" = "shared"; then
1757   CF_RPATH_HACK
1758 fi
1759
1760 ### Define substitutions for header files to avoid name-pollution
1761 CF_SUBST_IF(["$cf_cv_have_tcgetattr" = yes], HAVE_TCGETATTR, 1, 0)
1762 CF_SUBST_IF(["$ac_cv_header_termio_h" = yes], HAVE_TERMIO_H, 1, 0)
1763 CF_SUBST_IF(["$ac_cv_header_termios_h" = yes], HAVE_TERMIOS_H, 1, 0)
1764
1765 ################################################################################
1766 test "$use_database" = yes && SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1767 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1768 AC_OUTPUT( \
1769         include/MKterm.h.awk \
1770         include/curses.head:include/curses.h.in \
1771         include/termcap.h \
1772         include/unctrl.h \
1773         $SUB_MAKEFILES \
1774         Makefile,[
1775 CF_PRG_RULES([$srcdir/test/mk-test.awk ECHO_LINK="$ECHO_LINK"], test)
1776 CF_LIB_RULES($SRC_SUBDIRS)
1777 ],[
1778 ### Special initialization commands, used to pass information from the
1779 ### configuration-run into config.status
1780
1781 AWK="$AWK"
1782 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1783 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1784 ECHO_LINK="$ECHO_LINK"
1785 LDCONFIG="$LDCONFIG"
1786 LIB_NAME="$LIB_NAME"
1787 LIB_SUBSETS="$LIB_SUBSETS"
1788 LIB_SUFFIX="$LIB_SUFFIX"
1789 LIB_TRACING="$LIB_TRACING"
1790 MAKE_TERMINFO="$MAKE_TERMINFO"
1791 NCURSES_MAJOR="$NCURSES_MAJOR"
1792 NCURSES_MINOR="$NCURSES_MINOR"
1793 NCURSES_OSPEED="$NCURSES_OSPEED"
1794 NCURSES_PATCH="$NCURSES_PATCH"
1795 SRC_SUBDIRS="$SRC_SUBDIRS"
1796 TERMINFO="$TERMINFO"
1797 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1798 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1799 TINFO_NAME="$TINFO_NAME"
1800 TINFO_SUFFIX="$TINFO_SUFFIX"
1801 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1802 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1803 TICS_NAME="$TICS_NAME"
1804 WITH_CURSES_H="$with_curses_h"
1805 WITH_ECHO="$with_echo"
1806 WITH_OVERWRITE="$with_overwrite"
1807 cf_LIST_MODELS="$cf_list_models"
1808 cf_cv_abi_version="$cf_cv_abi_version"
1809 cf_cv_do_relink="$cf_cv_do_relink"
1810 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1811 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1812 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1813 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1814 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1815 cf_cv_rel_version="$cf_cv_rel_version"
1816 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1817 cf_cv_shared_soname='$cf_cv_shared_soname'
1818 cf_cv_shlib_version="$cf_cv_shlib_version"
1819 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1820 cf_cv_system_name="$cf_cv_system_name"
1821 cf_with_cxx_binding="$cf_with_cxx_binding"
1822 host="$host"
1823 target="$target"
1824
1825 ],cat)dnl
1826 ${MAKE-make} preinstall