configure.in

   1 dnl***************************************************************************
   2 dnl Copyright 2018-2019,2020 Thomas E. Dickey                                *
   3 dnl Copyright 1998-2017,2018 Free Software Foundation, Inc.                  *
   4 dnl                                                                          *
   5 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   6 dnl copy of this software and associated documentation files (the            *
   7 dnl "Software"), to deal in the Software without restriction, including      *
   8 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   9 dnl distribute, distribute with modifications, sublicense, and/or sell       *
  10 dnl copies of the Software, and to permit persons to whom the Software is    *
  11 dnl furnished to do so, subject to the following conditions:                 *
  12 dnl                                                                          *
  13 dnl The above copyright notice and this permission notice shall be included  *
  14 dnl in all copies or substantial portions of the Software.                   *
  15 dnl                                                                          *
  16 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  17 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  18 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  19 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  20 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  21 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  22 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  23 dnl                                                                          *
  24 dnl Except as contained in this notice, the name(s) of the above copyright   *
  25 dnl holders shall not be used in advertising or otherwise to promote the     *
  26 dnl sale, use or other dealings in this Software without prior written       *
  27 dnl authorization.                                                           *
  28 dnl***************************************************************************
  29 dnl
  30 dnl Author: Thomas E. Dickey 1995-on
  31 dnl
  32 dnl $Id: configure.in,v 1.713 2020/08/01 21:07:44 tom Exp $
  33 dnl Process this file with autoconf to produce a configure script.
  34 dnl
  35 dnl For additional information, see
  36 dnl     https://invisible-island.net/autoconf/
  37 dnl     https://invisible-island.net/autoconf/my-autoconf.html
  38 dnl
  39 dnl ---------------------------------------------------------------------------
  40 AC_PREREQ(2.52.20200111)
  41 AC_REVISION($Revision: 1.713 $)
  42 AC_INIT(ncurses/base/lib_initscr.c)
  43 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  44
  45 AC_DEFUN([AC_PATH_XTRA],[])dnl ignore dependencies on this
  46
  47 CF_TOP_BUILDDIR
  48 CF_SUBST_NCURSES_VERSION
  49 CF_VERSION_INFO(NCURSES,ncurses)
  50
  51 CF_WITH_REL_VERSION(NCURSES)
  52 CF_NCURSES_WITH_ABI_VERSION
  53
  54 CF_WITH_SYSTYPE
  55
  56 ###     Save the given $CFLAGS to allow user-override.
  57 cf_user_CFLAGS="$CFLAGS"
  58
  59 ###     Default install-location
  60 CF_CFG_DEFAULTS
  61 ### Defaults for ncurses ABI
  62 CF_ABI_DEFAULTS
  63
  64 ###     Checks for programs.
  65 AC_ARG_WITH(ada,
  66         [  --without-ada           suppress check for Ada compiler, don't build demo],
  67         [cf_with_ada=$withval],
  68         [cf_with_ada=yes])
  69
  70 if test "x$cf_with_ada" = xyes
  71 then
  72         cf_prog_cc="gnatgcc gcc cc"
  73 else
  74         cf_prog_cc="gcc cc"
  75 fi
  76 CF_PROG_CC($cf_prog_cc)
  77
  78 AC_PROG_CPP
  79 AC_PROG_GCC_TRADITIONAL
  80 CF_PROG_CC_C_O(CC,[$CFLAGS $CPPFLAGS])
  81 CF_PROG_LDCONFIG
  82
  83 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  84 dnl                             configure script by not letting us test if C++
  85 dnl                             is present, making this option necessary.
  86 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  87 AC_ARG_WITH(cxx,
  88         [  --without-cxx           do not adjust ncurses bool to match C++],
  89         [cf_with_cxx=$withval],
  90         [cf_with_cxx=yes])
  91 AC_MSG_RESULT($cf_with_cxx)
  92 if test "X$cf_with_cxx" = Xno ; then
  93         CXX=""
  94         GXX=""
  95 else
  96         # with autoconf 2.13, we can change the error to a warning:
  97         pushdef([AC_MSG_ERROR],
  98                 [AC_MSG_RESULT(no)
  99                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
 100                 cf_with_cxx=no; CXX=""; GXX="";])dnl
 101         AC_PROG_CXX
 102         popdef([AC_MSG_ERROR])dnl
 103
 104         AC_LANG_PUSH(C++)
 105         if test "x$cf_with_cxx" != xno
 106         then
 107                 # Several of the C++ configurations do not work, particularly when
 108                 # cross-compiling (20140913 -TD)
 109                 AC_MSG_CHECKING(if $CXX works)
 110
 111                 save_CPPFLAGS="$CPPFLAGS"
 112                 eval cf_includedir=${includedir}
 113                 CPPFLAGS="$CPPFLAGS -I${cf_includedir}"
 114                 AC_TRY_COMPILE([
 115 #include <stdlib.h>
 116 #include <stdio.h>
 117 ],
 118                 [
 119                 printf("Hello world!\n")
 120                 ],
 121                 [cf_cxx_works=yes],
 122                 [cf_cxx_works=no])
 123                 CPPFLAGS="$save_CPPFLAGS"
 124
 125                 AC_MSG_RESULT($cf_cxx_works)
 126                 if test "x$cf_cxx_works" = xno
 127                 then
 128                         AC_MSG_WARN([Ignore $CXX, since it cannot compile hello-world.])
 129                         cf_with_cxx=no; CXX=""; GXX="";
 130                 fi
 131         fi
 132         AC_LANG_POP
 133
 134         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
 135         if test "$CXX" = "g++" ; then
 136                 AC_PATH_PROG(CXX,g++)
 137         fi
 138         case "x$CXX" in
 139         (x|xg++)
 140                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
 141                 cf_with_cxx=no; CXX=""; GXX="";
 142                 ;;
 143         esac
 144 fi
 145
 146 CF_GXX_VERSION
 147 case $GXX_VERSION in
 148 ([[1-9]][[0-9]].*)
 149         ;;
 150 (1.*|2.[[0-6]]*)
 151         AC_MSG_WARN(templates do not work)
 152         ;;
 153 esac
 154
 155 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 156 AC_ARG_WITH(cxx-binding,
 157         [  --without-cxx-binding   do not build C++ binding and demo],
 158         [cf_with_cxx_binding=$withval],
 159         [cf_with_cxx_binding=$cf_with_cxx])
 160 AC_MSG_RESULT($cf_with_cxx_binding)
 161
 162 AC_MSG_CHECKING(if you want to build with Ada)
 163 AC_MSG_RESULT($cf_with_ada)
 164
 165 AC_MSG_CHECKING(if you want to install terminal database)
 166 AC_ARG_ENABLE(db-install,
 167         [  --disable-db-install    suppress install of terminal database],
 168         [cf_with_db_install=$enableval],
 169         [cf_with_db_install=yes])
 170 AC_MSG_RESULT($cf_with_db_install)
 171
 172 AC_MSG_CHECKING(if you want to install manpages)
 173 AC_ARG_WITH(manpages,
 174         [  --without-manpages      suppress install of manpages],
 175         [cf_with_manpages=$withval],
 176         [cf_with_manpages=yes])
 177 AC_MSG_RESULT($cf_with_manpages)
 178
 179 AC_MSG_CHECKING(if you want to build programs such as tic)
 180 AC_ARG_WITH(progs,
 181         [  --without-progs         suppress build/install with programs (e.g., tic)],
 182         [cf_with_progs=$withval],
 183         [cf_with_progs=yes])
 184 AC_MSG_RESULT($cf_with_progs)
 185
 186 if test -f $srcdir/tack/tack.h; then
 187         if test "x$cross_compiling" = xyes ; then
 188                 CF_VERBOSE(ignoring tack because we are cross-compiling)
 189                 cf_with_tack=no
 190         else
 191                 AC_MSG_CHECKING(if you want to build the tack program)
 192                 AC_ARG_WITH(tack,
 193                         [  --without-tack          suppress build/install with tack program],
 194                         [cf_with_tack=$withval],
 195                         [cf_with_tack=$cf_with_progs])
 196                 AC_MSG_RESULT($cf_with_tack)
 197         fi
 198 else
 199         cf_with_tack=no
 200 fi
 201
 202 AC_MSG_CHECKING(if you want to build test-programs)
 203 AC_ARG_WITH(tests,
 204         [  --without-tests         suppress build/install with test-programs],
 205         [cf_with_tests=$withval],
 206         [cf_with_tests=yes])
 207 AC_MSG_RESULT($cf_with_tests)
 208
 209 AC_MSG_CHECKING(if you wish to install curses.h)
 210 AC_ARG_WITH(curses-h,
 211         [  --without-curses-h      install curses.h as ncurses.h only],
 212         [with_curses_h=$withval],
 213         [with_curses_h=yes])
 214 AC_MSG_RESULT($with_curses_h)
 215
 216 modules_to_build="ncurses"
 217 test "X$cf_with_progs" != Xno && modules_to_build="$modules_to_build progs"
 218 test "X$cf_with_tack"  != Xno && modules_to_build="$modules_to_build tack"
 219 modules_to_build="$modules_to_build panel menu form"
 220
 221 AC_ARG_PROGRAM
 222
 223 CF_PROG_AWK
 224 CF_PROG_EGREP
 225 CF_PROG_INSTALL
 226 CF_PROG_LINT
 227 CF_PROG_LN_S
 228
 229 AC_SYS_LONG_FILE_NAMES
 230
 231 # Provide for renaming "ncurses5-config" to "ncurses5X-config", etc., in case
 232 # of package conflict.
 233 cf_config_suffix=
 234 AC_ARG_WITH(config-suffix,
 235         [  --with-config-suffix=X  suffixes ncursesXX-config file],
 236         [case "x$withval" in
 237         (xyes|xno)
 238                 AC_MSG_WARN(expected a value for config-suffix option)
 239                 ;;
 240         (*)     cf_config_suffix="$withval"
 241                 ;;
 242         esac])
 243 AC_SUBST(cf_config_suffix)
 244
 245 # If we find pkg-config, check if we should install the ".pc" files.
 246 CF_PKG_CONFIG
 247 CF_WITH_PKG_CONFIG_LIBDIR
 248 CF_ENABLE_PC_FILES
 249 if test -z "$MAKE_PC_FILES"
 250 then
 251         AC_MSG_CHECKING(for suffix to add to pc-files)
 252 AC_ARG_WITH(pc-suffix,
 253         [  --with-pc-suffix        suffixes pc-files],
 254         [case "x$withval" in
 255         (xyes|xno)
 256                 PC_MODULE_SUFFIX=
 257                 ;;
 258         (*)     PC_MODULE_SUFFIX="$withval"
 259                 ;;
 260         esac])
 261         test -z "$PC_MODULE_SUFFIX" && PC_MODULE_SUFFIX=none
 262         AC_MSG_RESULT($PC_MODULE_SUFFIX)
 263         test "$PC_MODULE_SUFFIX" = none && PC_MODULE_SUFFIX=
 264         AC_SUBST(PC_MODULE_SUFFIX)
 265 fi
 266
 267 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 268 AC_ARG_ENABLE(mixed-case,
 269         [  --enable-mixed-case     tic should assume mixed-case filenames],
 270         [enable_mixedcase=$enableval],
 271         [enable_mixedcase=auto])
 272 AC_MSG_RESULT($enable_mixedcase)
 273 if test "$enable_mixedcase" = "auto" ; then
 274         CF_MIXEDCASE_FILENAMES
 275 else
 276         cf_cv_mixedcase=$enable_mixedcase
 277         if test "x$enable_mixedcase" = "xyes" ; then
 278                 AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
 279         fi
 280 fi
 281
 282 # do this after mixed-case option (tags/TAGS is not as important as tic).
 283 AC_PROG_MAKE_SET
 284 CF_MAKE_TAGS
 285 CF_MAKEFLAGS
 286
 287 dnl These are standard among *NIX systems, but not when cross-compiling
 288 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 289 AC_CHECK_TOOL(LD, ld, ld)
 290 AC_CHECK_TOOL(AR, ar, ar)
 291 AC_CHECK_TOOL(NM, nm, nm)
 292 CF_AR_FLAGS
 293
 294 dnl Special option for use by system-builders: the install-prefix is used to
 295 dnl adjust the location into which the actual install is done, so that an
 296 dnl archive can be built without modifying the host system's configuration.
 297 AC_MSG_CHECKING(if you have specified an install-prefix)
 298 AC_ARG_WITH(install-prefix,
 299         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 300         [case "x$withval" in
 301         (xyes|xno)
 302                 ;;
 303         (*)     DESTDIR="$withval"
 304                 ;;
 305         esac])
 306 AC_MSG_RESULT($DESTDIR)
 307 AC_SUBST(DESTDIR)
 308
 309 ###############################################################################
 310 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 311 # If we're cross-compiling, allow the user to override the tools and their
 312 # options.  The configure script is oriented toward identifying the host
 313 # compiler, etc., but we need a build compiler to generate parts of the source.
 314
 315 case $cf_cv_system_name in
 316 (*-msvc*)
 317         LDFLAGS="$LDFLAGS user32.lib"
 318         export LDFLAGS
 319         ;;
 320 esac
 321
 322 CF_BUILD_CC
 323
 324 ###############################################################################
 325 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 326
 327 ### Options to allow the user to specify the set of libraries which are used.
 328 ### Use "--without-normal --with-shared" to allow the default model to be
 329 ### shared, for example.
 330 cf_list_models=""
 331 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 332
 333 CF_WITH_LIBTOOL
 334 if test "$with_libtool" != "no" ; then
 335
 336 cf_list_models="$cf_list_models libtool"
 337
 338 else
 339
 340 AC_MSG_CHECKING(if you want to build shared libraries)
 341 AC_ARG_WITH(shared,
 342         [  --with-shared           generate shared-libraries],
 343         [with_shared=$withval],
 344         [with_shared=no])
 345 AC_MSG_RESULT($with_shared)
 346 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
 347
 348 AC_MSG_CHECKING(if you want to build static libraries)
 349 AC_ARG_WITH(normal,
 350         [  --with-normal           generate normal-libraries (default)],
 351         [with_normal=$withval],
 352         [with_normal=yes])
 353 AC_MSG_RESULT($with_normal)
 354 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
 355
 356 AC_MSG_CHECKING(if you want to build debug libraries)
 357 AC_ARG_WITH(debug,
 358         [  --with-debug            generate debug-libraries (default)],
 359         [with_debug=$withval],
 360         [with_debug=yes])
 361 AC_MSG_RESULT($with_debug)
 362 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
 363
 364 AC_MSG_CHECKING(if you want to build profiling libraries)
 365 AC_ARG_WITH(profile,
 366         [  --with-profile          generate profile-libraries],
 367         [with_profile=$withval],
 368         [with_profile=no])
 369 AC_MSG_RESULT($with_profile)
 370 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
 371
 372 fi
 373
 374 if test "X$cf_with_cxx_binding" != Xno; then
 375 if test "x$with_shared" = "xyes"; then
 376 AC_MSG_CHECKING(if you want to build C++ shared libraries)
 377 AC_ARG_WITH(cxx-shared,
 378         [  --with-cxx-shared       generate C++ shared-libraries],
 379         [with_shared_cxx=$withval],
 380         [with_shared_cxx=no])
 381 AC_MSG_RESULT($with_shared_cxx)
 382 fi
 383 fi
 384
 385 ###############################################################################
 386
 387 AC_MSG_CHECKING(for specified models)
 388 test -z "$cf_list_models" && cf_list_models=normal
 389 dnl If we use libtool to generate libraries, then it must be the only
 390 dnl specified model.
 391 test "$with_libtool" != "no" && cf_list_models=libtool
 392 AC_MSG_RESULT($cf_list_models)
 393
 394 ### Use the first model as the default, and save its suffix for use in building
 395 ### up test-applications.
 396 AC_MSG_CHECKING(for default model)
 397 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 398 AC_MSG_RESULT($DFT_LWR_MODEL)
 399
 400 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 401
 402 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 403 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 404
 405 TICS_NAME=tic
 406 AC_SUBST(TICS_NAME)
 407
 408 TINFO_NAME=tinfo
 409 AC_SUBST(TINFO_NAME)
 410
 411 LIB_NAME=ncurses
 412 AC_SUBST(LIB_NAME)
 413
 414 LIB_DIR=../lib
 415 LIB_2ND=../../lib
 416
 417 CF_WITH_LIB_PREFIX(cf_prefix)
 418
 419 LIB_SUFFIX=
 420 AC_SUBST(LIB_SUFFIX)
 421 CF_PATHSEP
 422
 423 ###############################################################################
 424
 425 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 426 AC_ARG_WITH(termlib,
 427         [  --with-termlib          generate separate terminfo library],
 428         [with_termlib=$withval],
 429         [with_termlib=no])
 430 AC_MSG_RESULT($with_termlib)
 431
 432 AC_MSG_CHECKING(if you want to build a separate tic library)
 433 AC_ARG_WITH(ticlib,
 434         [  --with-ticlib           generate separate tic library],
 435         [with_ticlib=$withval],
 436         [with_ticlib=no])
 437 AC_MSG_RESULT($with_ticlib)
 438
 439 dnl Not all ports of gcc support the -g option
 440
 441 if test X"$CC_G_OPT" = X"" ; then
 442         CC_G_OPT='-g'
 443         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
 444 fi
 445 AC_SUBST(CC_G_OPT)
 446
 447 if test X"$CXX_G_OPT" = X"" ; then
 448         CXX_G_OPT='-g'
 449         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
 450 fi
 451 AC_SUBST(CXX_G_OPT)
 452
 453 AC_MSG_CHECKING(for default loader flags)
 454 case $DFT_LWR_MODEL in
 455 (libtool) LD_MODEL=''   ;;
 456 (normal)  LD_MODEL=''   ;;
 457 (debug)   LD_MODEL=$CC_G_OPT ;;
 458 (profile) LD_MODEL='-pg';;
 459 (shared)  LD_MODEL=''   ;;
 460 esac
 461 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 462 AC_MSG_RESULT($LD_MODEL)
 463
 464 case $DFT_LWR_MODEL in
 465 (shared)
 466 CF_ENABLE_RPATH
 467 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 468 AC_ARG_ENABLE(relink,
 469 [  --disable-relink        relink shared libraries during install],
 470 [cf_cv_do_relink=$enableval],
 471 [cf_cv_do_relink=yes])
 472 AC_MSG_RESULT($cf_cv_do_relink)
 473         ;;
 474 esac
 475
 476 # we will build libraries one-level down.
 477 rel_builddir=..
 478 CF_SHARED_OPTS
 479 for model in $cf_list_models; do
 480         case $model in
 481         (libtool)
 482                 CF_WITH_LIBTOOL_OPTS
 483                 CF_WITH_EXPORT_SYMS
 484                 ;;
 485         (shared)
 486                 if test "$CC_SHARED_OPTS" = "unknown"; then
 487                         AC_ERROR(Shared libraries are not supported in this version)
 488                 fi
 489                 # workaround for inept transition to PIE vs PIC...
 490                 AC_MSG_CHECKING(if current CFLAGS link properly)
 491                 AC_TRY_LINK(
 492                         [#include <stdio.h>],
 493                         [printf("Hello work\n");],
 494                         [cf_cflags_work=yes],
 495                         [cf_cflags_work=no])
 496                 AC_MSG_RESULT($cf_cflags_work)
 497                 if test "$cf_cflags_work" = no
 498                 then
 499                         CF_VERBOSE(try to work around by appending shared-options)
 500                         CFLAGS="$CFLAGS $CC_SHARED_OPTS"
 501                 fi
 502                 CF_WITH_VERSIONED_SYMS
 503                 ;;
 504         esac
 505 done
 506
 507 ### Checks for special libraries, must be done up-front.
 508 SHLIB_LIST=""
 509 CF_WITH_GPM
 510 if test "$with_gpm" != no ; then
 511         AC_MSG_CHECKING(if you want to load GPM dynamically)
 512         AC_ARG_WITH(dlsym,
 513                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 514                 [with_dlsym=$withval],
 515                 [with_dlsym=yes])
 516         AC_MSG_RESULT($with_dlsym)
 517         if test "x$with_dlsym" = xyes ; then
 518                 CF_FUNC_DLSYM
 519                 if test "x$with_gpm" != xyes ; then
 520                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 521                         cf_cv_gpm_soname="$with_gpm"
 522                 else
 523                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 524                 fi
 525                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
 526                 SHLIB_LIST="-ldl $SHLIB_LIST"
 527                 CF_ADD_LIB(dl,PRIVATE_LIBS)
 528         else
 529                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 530                 CF_ADD_LIB(gpm,TEST_LIBS)
 531                 CF_ADD_LIB(gpm,PRIVATE_LIBS)
 532         fi
 533         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
 534         CF_CHECK_GPM_WGETCH
 535 fi
 536
 537 CF_WITH_PCRE2
 538 CF_WITH_SYSMOUSE
 539
 540 # pretend that ncurses==ncursesw==ncursest
 541 AC_MSG_CHECKING(if you want to disable library suffixes)
 542 CF_ARG_DISABLE(lib-suffixes,
 543         [  --disable-lib-suffixes  disable library suffixes],
 544         [disable_lib_suffixes=yes],
 545         [disable_lib_suffixes=no],
 546         no)
 547 AC_MSG_RESULT($disable_lib_suffixes)
 548
 549 ### If we're building with rpath, try to link non-standard libs that way too.
 550 if test "$DFT_LWR_MODEL" = "shared" && test "x$cf_cv_enable_rpath" != xno; then
 551         CF_DISABLE_RPATH_HACK
 552 fi
 553
 554 ### Depending on the system, someone may use rpath to build ncurses but not
 555 # want users of the package to rely upon that feature.  Give those people an
 556 # option to suppress that detail from EXTRA_LDFLAGS.
 557 EXTRA_PKG_LDFLAGS="$EXTRA_LDFLAGS"
 558 if test -n "$EXTRA_PKG_LDFLAGS"
 559 then
 560         AC_MSG_CHECKING(if you want to disable extra LDFLAGS for package-scripts)
 561         CF_ARG_DISABLE(pkg-ldflags,
 562                 [  --disable-pkg-ldflags   disable extra LDFLAGS for package-scripts],
 563                 [disable_pkg_ldflags=yes],
 564                 [disable_pkg_ldflags=no],
 565                 no)
 566         AC_MSG_RESULT($disable_pkg_ldflags)
 567         test "$disable_pkg_ldflags" = yes && EXTRA_PKG_LDFLAGS=
 568 fi
 569 AC_SUBST(EXTRA_PKG_LDFLAGS)
 570
 571 ###############################################################################
 572 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 573
 574 ###     use option --with-extra-suffix to append suffix to headers and libraries
 575 AC_MSG_CHECKING(if you wish to append extra suffix to header/library paths)
 576 EXTRA_SUFFIX=
 577 AC_ARG_WITH(extra-suffix,
 578         [  --with-extra-suffix=X   append extra suffix to header/library paths],
 579         [case x$withval in
 580         (no)
 581                 ;;
 582         (xyes|x)
 583                 EXTRA_SUFFIX=$cf_cv_abi_version
 584                 ;;
 585         (*)
 586                 EXTRA_SUFFIX=$withval
 587                 ;;
 588         esac
 589         ])
 590 AC_MSG_RESULT($EXTRA_SUFFIX)
 591 AC_SUBST(EXTRA_SUFFIX)
 592
 593 ###     use option --disable-overwrite to leave out the link to -lcurses
 594 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 595 AC_ARG_ENABLE(overwrite,
 596         [  --disable-overwrite     put headers in subdir, omit link to -lcurses],
 597         [with_overwrite=$enableval],
 598         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 599 AC_MSG_RESULT($with_overwrite)
 600
 601 AC_MSG_CHECKING(if external terminfo-database is used)
 602 AC_ARG_ENABLE(database,
 603         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 604         [use_database=$enableval],
 605         [use_database=yes])
 606 AC_MSG_RESULT($use_database)
 607
 608 case $host_os in
 609 (os2*)
 610         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 611         ;;
 612 (*)
 613         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 614         ;;
 615 esac
 616 AC_SUBST(TERMINFO_SRC)
 617
 618 NCURSES_USE_DATABASE=0
 619 if test "$use_database" != no ; then
 620         NCURSES_USE_DATABASE=1
 621
 622         AC_MSG_CHECKING(which terminfo source-file will be installed)
 623         AC_ARG_WITH(database,
 624                 [  --with-database=XXX     specify terminfo source to install],
 625                 [TERMINFO_SRC=$withval])
 626         AC_MSG_RESULT($TERMINFO_SRC)
 627
 628         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 629         AC_ARG_WITH(hashed-db,
 630                 [  --with-hashed-db        specify hashed-database library],,
 631                 [with_hashed_db=no])
 632         AC_MSG_RESULT($with_hashed_db)
 633 else
 634         with_hashed_db=no
 635 fi
 636 AC_SUBST(NCURSES_USE_DATABASE)
 637
 638 AC_MSG_CHECKING(for list of fallback descriptions)
 639 AC_ARG_WITH(fallbacks,
 640         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 641         [with_fallback=$withval],
 642         [with_fallback=])
 643 AC_MSG_RESULT($with_fallback)
 644
 645 case ".$with_fallback" in
 646 (.|.no)
 647         FALLBACK_LIST=
 648         ;;
 649 (.yes)
 650         AC_MSG_WARN(expected a list of terminal descriptions)
 651         ;;
 652 (*)
 653         FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 654         ;;
 655 esac
 656
 657 USE_FALLBACKS=
 658 test -z "$FALLBACK_LIST" && USE_FALLBACKS="#"
 659 AC_SUBST(FALLBACK_LIST)
 660 AC_SUBST(USE_FALLBACKS)
 661
 662 # The fallback feature in ncurses relies upon tic/infocmp outside the build
 663 # tree for generating the terminal descriptions that will be compiled into the
 664 # library.  If your toolchain is old, it may not handle current terminal
 665 # databases.  Use configure-options to point to the tools which will be used,
 666 # rather than the first ones found on the $PATH.
 667 if test -n "$FALLBACK_LIST"
 668 then
 669         CF_WITH_PATH_PROG(TIC,     tic,     [for fallbacks], $PATH:/usr/local/ncurses/bin)
 670         CF_WITH_PATH_PROG(INFOCMP, infocmp, [for fallbacks], $PATH:/usr/local/ncurses/bin)
 671 else
 672         : ${TIC:=tic}
 673         : ${INFOCMP:=infocmp}
 674 fi
 675 AC_SUBST(TIC)
 676 AC_SUBST(INFOCMP)
 677
 678 AC_MSG_CHECKING(if you want modern xterm or antique)
 679 AC_ARG_WITH(xterm-new,
 680         [  --without-xterm-new     specify if xterm terminfo should be old version],
 681         [with_xterm_new=$withval],
 682         [with_xterm_new=yes])
 683 case $with_xterm_new in
 684 (no) with_xterm_new=xterm-old;;
 685 (*)      with_xterm_new=xterm-new;;
 686 esac
 687 AC_MSG_RESULT($with_xterm_new)
 688 WHICH_XTERM=$with_xterm_new
 689 AC_SUBST(WHICH_XTERM)
 690
 691 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
 692 AC_ARG_WITH(xterm-kbs,
 693         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
 694         [with_xterm_kbs=$withval],
 695         [with_xterm_kbs=BS])
 696 case x$with_xterm_kbs in
 697 (xyes|xno|xBS|xbs|x8)
 698         with_xterm_kbs=BS
 699         ;;
 700 (xDEL|xdel|x127)
 701         with_xterm_kbs=DEL
 702         ;;
 703 (*)
 704         with_xterm_kbs=$withval
 705         ;;
 706 esac
 707 AC_MSG_RESULT($with_xterm_kbs)
 708 XTERM_KBS=$with_xterm_kbs
 709 AC_SUBST(XTERM_KBS)
 710
 711 MAKE_TERMINFO=
 712 if test "$use_database" = no ; then
 713         TERMINFO="${datadir}/terminfo"
 714         MAKE_TERMINFO="#"
 715 else
 716
 717 AC_MSG_CHECKING(for list of terminfo directories)
 718 CF_WITH_PATHLIST(terminfo-dirs,
 719         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 720         TERMINFO_DIRS,
 721         DATADIR/terminfo,
 722         ${datadir}/terminfo)
 723 AC_MSG_RESULT($TERMINFO_DIRS)
 724 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
 725
 726 case "x$TERMINFO" in
 727 x???:*)
 728         AC_MSG_WARN(ignoring non-directory/file TERMINFO value)
 729         unset TERMINFO
 730         ;;
 731 esac
 732
 733 AC_MSG_CHECKING(for default terminfo directory)
 734 CF_WITH_PATH(default-terminfo-dir,
 735         [  --with-default-terminfo-dir=DIR default terminfo directory],
 736         TERMINFO,
 737         DATADIR/terminfo,
 738         ${datadir}/terminfo)
 739 AC_MSG_RESULT($TERMINFO)
 740 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
 741
 742 fi
 743
 744 AC_SUBST(TERMINFO)
 745 AC_SUBST(MAKE_TERMINFO)
 746
 747 ###     use option --disable-big-core to make tic run on small machines
 748 ###     We need 4Mb, check if we can allocate 50% more than that.
 749 AC_MSG_CHECKING(if big-core option selected)
 750 AC_ARG_ENABLE(big-core,
 751         [  --disable-big-core      assume machine has little memory],
 752         [with_big_core=$enableval],
 753         [AC_TRY_RUN([
 754 #include <stdlib.h>
 755 #include <string.h>
 756 int main() {
 757         unsigned long n = 6000000L;
 758         char *s = malloc(n);
 759         if (s != 0)
 760                 s[0] = s[n-1] = 0;
 761         ${cf_cv_main_return:-return}(s == 0);
 762 }],
 763         [with_big_core=yes],
 764         [with_big_core=no],
 765         [with_big_core=no])])
 766 AC_MSG_RESULT($with_big_core)
 767 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
 768
 769 ### ISO C only guarantees 512-char strings, we have tables which load faster
 770 ### when constructed using "big" strings.  More than the C compiler, the awk
 771 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 772 AC_MSG_CHECKING(if big-strings option selected)
 773 AC_ARG_ENABLE(big-strings,
 774         [  --disable-big-strings   assume compiler has only standard-size strings],
 775         [with_big_strings=$enableval],
 776         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 777 AC_MSG_RESULT($with_big_strings)
 778
 779 USE_BIG_STRINGS=0
 780 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
 781 AC_SUBST(USE_BIG_STRINGS)
 782
 783 ###     use option --enable-termcap to compile in the termcap fallback support
 784 AC_MSG_CHECKING(if you want termcap-fallback support)
 785 AC_ARG_ENABLE(termcap,
 786         [  --enable-termcap        compile in termcap fallback support],
 787         [with_termcap=$enableval],
 788         [with_termcap=no])
 789 AC_MSG_RESULT($with_termcap)
 790
 791 NCURSES_USE_TERMCAP=0
 792 if test "x$with_termcap" != "xyes" ; then
 793         if test "$use_database" = no ; then
 794                 if test -z "$with_fallback" ; then
 795                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 796                 fi
 797         fi
 798         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
 799 else
 800
 801         if test "$with_ticlib" != no ; then
 802                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 803         fi
 804
 805         NCURSES_USE_TERMCAP=1
 806         AC_MSG_CHECKING(for list of termcap files)
 807         CF_WITH_PATHLIST(termpath,
 808                 [  --with-termpath=XXX     specify list of termcap files],
 809                 TERMPATH,
 810                 /etc/termcap:/usr/share/misc/termcap)
 811         AC_MSG_RESULT($TERMPATH)
 812         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
 813
 814         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 815         AC_MSG_CHECKING(if fast termcap-loader is needed)
 816         AC_ARG_ENABLE(getcap,
 817                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 818                 [with_getcap=$enableval],
 819                 [with_getcap=no])
 820         AC_MSG_RESULT($with_getcap)
 821         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
 822
 823         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 824         AC_ARG_ENABLE(getcap-cache,
 825                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 826                 [with_getcap_cache=$enableval],
 827                 [with_getcap_cache=no])
 828         AC_MSG_RESULT($with_getcap_cache)
 829         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
 830
 831 fi
 832 AC_SUBST(NCURSES_USE_TERMCAP)
 833
 834 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 835 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 836 AC_ARG_ENABLE(home-terminfo,
 837         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 838         [with_home_terminfo=$enableval],
 839         [with_home_terminfo=yes])
 840 AC_MSG_RESULT($with_home_terminfo)
 841 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
 842
 843 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 844 AC_ARG_ENABLE(root-environ,
 845         [  --disable-root-environ  restrict environment when running as root],
 846         [with_root_environ=$enableval],
 847         [with_root_environ=yes])
 848 AC_MSG_RESULT($with_root_environ)
 849 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if environment should be restricted for root user])
 850
 851 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 852 ###   to reduce storage requirements for the terminfo database.
 853 CF_LINK_FUNCS
 854
 855 with_links=no
 856 with_symlinks=no
 857
 858 # soft links (symbolic links) are useful for some systems where hard links do
 859 # not work, or to make it simpler to copy terminfo trees around.
 860 if test "x$ac_cv_func_symlink" = xyes ; then
 861         AC_MSG_CHECKING(if tic should use symbolic links)
 862         AC_ARG_ENABLE(symlinks,
 863         [  --enable-symlinks       make tic use symbolic links not hard links],
 864         [with_symlinks=$enableval],
 865         [with_symlinks=no])
 866         AC_MSG_RESULT($with_symlinks)
 867 fi
 868
 869 # If we have hard links and did not choose to use soft links instead, there is
 870 # no reason to make this choice optional - use the hard links.
 871 if test "$with_symlinks" = no ; then
 872         AC_MSG_CHECKING(if tic should use hard links)
 873         if test "x$ac_cv_func_link" = xyes ; then
 874                 with_links=yes
 875         else
 876                 with_links=no
 877         fi
 878         AC_MSG_RESULT($with_links)
 879 fi
 880
 881 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
 882 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
 883
 884 ###   use option --enable-broken-linker to force on use of broken-linker support
 885 CF_ENABLE_BROKEN_LINKER
 886
 887 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 888 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 889 AC_ARG_ENABLE(bsdpad,
 890         [  --enable-bsdpad         recognize BSD-style prefix padding],
 891         [with_bsdpad=$enableval],
 892         [with_bsdpad=no])
 893 AC_MSG_RESULT($with_bsdpad)
 894 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
 895
 896 ###   use option --enable-widec to turn on use of wide-character support
 897 NCURSES_CH_T=chtype
 898 NCURSES_LIBUTF8=0
 899
 900 NEED_WCHAR_H=0
 901 NCURSES_MBSTATE_T=0
 902 NCURSES_WCHAR_T=0
 903 NCURSES_WINT_T=0
 904
 905 # Check to define _XOPEN_SOURCE "automatically"
 906 CPPFLAGS_before_XOPEN="$CPPFLAGS"
 907 CF_XOPEN_SOURCE(600)
 908 CPPFLAGS_after_XOPEN="$CPPFLAGS"
 909
 910 # Work around breakage on OS X
 911 CF_SIGWINCH
 912
 913 # Checks for CODESET support.
 914 AM_LANGINFO_CODESET
 915
 916 # use these variables to work around a defect in gcc's fixincludes.
 917 NCURSES_OK_WCHAR_T=
 918 NCURSES_OK_WINT_T=
 919
 920 AC_MSG_CHECKING(if you want wide-character code)
 921 AC_ARG_ENABLE(widec,
 922         [  --enable-widec          compile with wide-char/UTF-8 code],
 923         [with_widec=$enableval],
 924         [with_widec=no])
 925 AC_MSG_RESULT($with_widec)
 926
 927 NCURSES_WCWIDTH_GRAPHICS=1
 928 AC_SUBST(NCURSES_WCWIDTH_GRAPHICS)
 929
 930 if test "x$with_widec" = xyes ; then
 931         if test "x$disable_lib_suffixes" = xno ; then
 932                 LIB_SUFFIX="w${LIB_SUFFIX}"
 933         fi
 934         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
 935         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
 936
 937         CF_CHECK_WCHAR_H
 938         CF_CHECK_WCWIDTH_GRAPHICS
 939         test "$cf_cv_wcwidth_graphics" = no && NCURSES_WCWIDTH_GRAPHICS=0
 940
 941         # with_overwrite=no
 942         NCURSES_CH_T=cchar_t
 943         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 944         if test "x$ac_cv_func_putwc" != xyes ; then
 945                 CF_UTF8_LIB
 946                 if test "$cf_cv_utf8_lib" != no ; then
 947                         NCURSES_LIBUTF8=1
 948                 fi
 949         fi
 950         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 951         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 952         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 953
 954         if test "$NCURSES_MBSTATE_T" != 0; then
 955                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
 956         fi
 957 fi
 958 AC_SUBST(NCURSES_CH_T)
 959 AC_SUBST(NCURSES_LIBUTF8)
 960
 961 AC_SUBST(NEED_WCHAR_H)
 962 AC_SUBST(NCURSES_MBSTATE_T)
 963 AC_SUBST(NCURSES_WCHAR_T)
 964 AC_SUBST(NCURSES_WINT_T)
 965
 966 AC_SUBST(NCURSES_OK_WCHAR_T)
 967 AC_SUBST(NCURSES_OK_WINT_T)
 968
 969 ###   use option --disable-lp64 to allow long chtype
 970 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 971 AC_ARG_ENABLE(lp64,
 972         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 973         [with_lp64=$enableval],
 974         [with_lp64=$cf_dft_with_lp64])
 975 AC_MSG_RESULT($with_lp64)
 976
 977 if test "x$with_lp64" = xyes ; then
 978         cf_cv_enable_lp64=1
 979 else
 980         cf_cv_enable_lp64=0
 981 fi
 982 AC_SUBST(cf_cv_enable_lp64)
 983
 984 CF_LARGEFILE
 985
 986 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 987 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 988 AC_ARG_ENABLE(tparm-varargs,
 989         [  --disable-tparm-varargs compile tparm() without varargs interface],
 990         [with_tparm_varargs=$enableval],
 991         [with_tparm_varargs=yes])
 992 AC_MSG_RESULT($with_tparm_varargs)
 993 NCURSES_TPARM_VARARGS=0
 994 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
 995 AC_SUBST(NCURSES_TPARM_VARARGS)
 996
 997 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
 998 if test "$with_ticlib" != no ; then
 999 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
1000 AC_ARG_ENABLE(tic-depends,
1001         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
1002         [with_tic_depends=$enableval],
1003         [with_tic_depends=yes])
1004 AC_MSG_RESULT($with_tic_depends)
1005 else
1006         with_tic_depends=no
1007 fi
1008
1009 ###   use option --disable-wattr-macros to suppress wattr* macros from curses.h
1010 AC_MSG_CHECKING(if you want to suppress wattr* macros to help with ncurses5/ncurses6 transition)
1011 AC_ARG_ENABLE(wattr-macros,
1012         [  --disable-wattr-macros  suppress wattr* macros to help with ncurses5/ncurses6 transition],
1013         [with_wattr_macros=$enableval],
1014         [with_wattr_macros=yes])
1015 if [[ "x$with_wattr_macros" != xyes ]]; then
1016         NCURSES_WATTR_MACROS=0
1017         AC_MSG_RESULT(yes)
1018 else
1019         NCURSES_WATTR_MACROS=1
1020         AC_MSG_RESULT(no)
1021 fi
1022 AC_SUBST(NCURSES_WATTR_MACROS)
1023
1024 CF_WITH_X11_RGB
1025
1026 ###   use option --with-bool to override bool's type
1027 AC_MSG_CHECKING(for type of bool)
1028 AC_ARG_WITH(bool,
1029         [  --with-bool=TYPE        override fallback type of bool variable],
1030         [NCURSES_BOOL="$withval"],
1031         [NCURSES_BOOL=auto])
1032 AC_MSG_RESULT($NCURSES_BOOL)
1033 AC_SUBST(NCURSES_BOOL)
1034
1035 AC_MSG_CHECKING(for alternate terminal capabilities file)
1036 AC_ARG_WITH(caps,
1037         [  --with-caps=alt         compile with alternate Caps file],
1038         [TERMINFO_CAPS=Caps.$withval],
1039         [TERMINFO_CAPS=Caps])
1040 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
1041 AC_MSG_RESULT($TERMINFO_CAPS)
1042 AC_SUBST(TERMINFO_CAPS)
1043
1044 ###   use option --with-chtype to override chtype's type
1045 AC_MSG_CHECKING(for type of chtype)
1046 AC_ARG_WITH(chtype,
1047         [  --with-chtype=TYPE      override type of chtype],
1048         [NCURSES_CHTYPE="$withval"],
1049         [NCURSES_CHTYPE=$cf_dft_chtype])
1050 AC_MSG_RESULT($NCURSES_CHTYPE)
1051
1052 ###   use option --with-ospeed to override ospeed's type
1053 AC_MSG_CHECKING(for type of ospeed)
1054 AC_ARG_WITH(ospeed,
1055         [  --with-ospeed=TYPE      override type of ospeed variable],
1056         [NCURSES_OSPEED="$withval"],
1057         [NCURSES_OSPEED=short])
1058 AC_MSG_RESULT($NCURSES_OSPEED)
1059 AC_SUBST(NCURSES_OSPEED)
1060
1061 ###   use option --with-mmask-t to override mmask_t's type
1062 AC_MSG_CHECKING(for type of mmask_t)
1063 AC_ARG_WITH(mmask-t,
1064         [  --with-mmask-t=TYPE     override type of mmask_t],
1065         [NCURSES_MMASK_T="$withval"],
1066         [NCURSES_MMASK_T=$cf_dft_mmask_t])
1067 AC_MSG_RESULT($NCURSES_MMASK_T)
1068
1069 ###   use option --with-ccharw-max to override CCHARW_MAX size
1070 AC_MSG_CHECKING(for size CCHARW_MAX)
1071 AC_ARG_WITH(ccharw-max,
1072         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
1073         [NCURSES_CCHARW_MAX="$withval"],
1074         [NCURSES_CCHARW_MAX=5])
1075 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
1076 AC_SUBST(NCURSES_CCHARW_MAX)
1077
1078 AC_CHECK_SIZEOF([signed char])
1079 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1080         NCURSES_SBOOL="signed char"
1081 else
1082         NCURSES_SBOOL="char"
1083 fi
1084 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1085 AC_ARG_ENABLE(signed-char,
1086         [  --enable-signed-char    compile using signed Boolean's in term.h],
1087         [with_signed_char=$enableval],
1088         [with_signed_char=no])
1089 AC_MSG_RESULT($with_signed_char)
1090 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1091 AC_SUBST(NCURSES_SBOOL)
1092
1093 ###   use option --with-tparm-arg to override tparm's argument type
1094 AC_MSG_CHECKING(for type of tparm args)
1095 AC_ARG_WITH(tparm-arg,
1096         [  --with-tparm-arg=TYPE   override parameter type of tparm],
1097         [NCURSES_TPARM_ARG="$withval"],
1098         [NCURSES_TPARM_ARG=$cf_dft_tparm_arg])
1099 AC_MSG_RESULT($NCURSES_TPARM_ARG)
1100 AC_SUBST(NCURSES_TPARM_ARG)
1101
1102 ### Enable compiling-in rcs id's
1103 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
1104 AC_ARG_WITH(rcs-ids,
1105         [  --with-rcs-ids          compile-in RCS identifiers],
1106         [with_rcs_ids=$withval],
1107         [with_rcs_ids=no])
1108 AC_MSG_RESULT($with_rcs_ids)
1109 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
1110
1111 ###############################################################################
1112 CF_MAN_PAGES([ captoinfo clear infocmp infotocap reset tabs tic toe tput tset ])
1113
1114 ###############################################################################
1115 CF_HELP_MESSAGE(Extensions:)
1116
1117 ### Note that some functions (such as const) are normally disabled anyway.
1118 AC_MSG_CHECKING(if you want to build with function extensions)
1119 AC_ARG_ENABLE(ext-funcs,
1120         [  --disable-ext-funcs     disable function-extensions],
1121         [with_ext_funcs=$enableval],
1122         [with_ext_funcs=yes])
1123 AC_MSG_RESULT($with_ext_funcs)
1124 if test "x$with_ext_funcs" = xyes ; then
1125         NCURSES_EXT_FUNCS=1
1126         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
1127         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function in test-programs])
1128         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function in test-programs])
1129         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function in test-programs])
1130         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function in test-programs])
1131         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function in test-programs])
1132         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function in test-programs])
1133         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function in test-programs])
1134         AC_DEFINE(HAVE_USE_EXTENDED_NAMES,1,[Define to 1 to enable use_extended_names() function in test-programs])
1135         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function in test-programs])
1136         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function in test-programs])
1137         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function in test-programs])
1138         GENERATED_EXT_FUNCS=generated
1139         test "x$with_ext_funcs" = xyes || cf_dft_ext_spfuncs=no
1140 else
1141         NCURSES_EXT_FUNCS=0
1142         GENERATED_EXT_FUNCS=
1143 fi
1144 AC_SUBST(NCURSES_EXT_FUNCS)
1145 AC_SUBST(GENERATED_EXT_FUNCS)
1146
1147 AC_MSG_CHECKING(if you want to build with SCREEN extensions)
1148 AC_ARG_ENABLE(sp-funcs,
1149         [  --enable-sp-funcs       enable SCREEN-extensions],
1150         [with_sp_funcs=$enableval],
1151         [with_sp_funcs=$cf_dft_ext_spfuncs])
1152 AC_MSG_RESULT($with_sp_funcs)
1153 if test "x$with_sp_funcs" = xyes ; then
1154         NCURSES_SP_FUNCS=1
1155         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable SCREEN-extensions])
1156         AC_DEFINE(HAVE_TPUTS_SP,1,[Define to 1 to enable tputs_sp() function in test-programs])
1157         GENERATED_SP_FUNCS=generated
1158 else
1159         NCURSES_SP_FUNCS=0
1160         GENERATED_SP_FUNCS=
1161 fi
1162 AC_SUBST(NCURSES_SP_FUNCS)
1163 AC_SUBST(GENERATED_SP_FUNCS)
1164
1165 AC_MSG_CHECKING(if you want to build with terminal-driver)
1166 AC_ARG_ENABLE(term-driver,
1167         [  --enable-term-driver    enable terminal-driver],
1168         [with_term_driver=$enableval],
1169         [with_term_driver=no])
1170 AC_MSG_RESULT($with_term_driver)
1171 if test "x$with_term_driver" = xyes ; then
1172         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable terminal-driver])
1173         if test "x$with_termlib" != xno ; then
1174                 AC_MSG_ERROR(The term-driver option conflicts with the termlib option)
1175         fi
1176         if test "x$with_sp_funcs" != xyes ; then
1177                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
1178         fi
1179 fi
1180
1181 ###   use option --enable-const to turn on use of const beyond that in XSI.
1182 AC_MSG_CHECKING(for extended use of const keyword)
1183 AC_ARG_ENABLE(const,
1184         [  --enable-const          compile with extra/non-standard const],
1185         [with_ext_const=$enableval],
1186         [with_ext_const=$cf_dft_ext_const])
1187 AC_MSG_RESULT($with_ext_const)
1188 NCURSES_CONST='/*nothing*/'
1189 if test "x$with_ext_const" = xyes ; then
1190         NCURSES_CONST=const
1191 fi
1192 AC_SUBST(NCURSES_CONST)
1193
1194 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
1195 AC_MSG_CHECKING(if you want to use extended colors)
1196 AC_ARG_ENABLE(ext-colors,
1197         [  --enable-ext-colors     compile for 256-color support],
1198         [with_ext_colors=$enableval],
1199         [with_ext_colors=$cf_dft_ext_colors])
1200 AC_MSG_RESULT($with_ext_colors)
1201 NCURSES_EXT_COLORS=0
1202 if test "x$with_ext_colors" = xyes ; then
1203         if test "x$with_widec" != xyes ; then
1204                 AC_MSG_WARN(This option applies only to wide-character library)
1205         else
1206                 # cannot be ABI 5 since it changes sizeof(cchar_t)
1207                 CF_NCURSES_ABI_6
1208                 NCURSES_EXT_COLORS=1
1209                 AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
1210                 AC_DEFINE(HAVE_ALLOC_PAIR,1,[Define to 1 to enable alloc_pair() function])
1211                 AC_DEFINE(HAVE_INIT_EXTENDED_COLOR,1,[Define to 1 to enable init_extended_color() function in test-programs])
1212                 AC_DEFINE(HAVE_RESET_COLOR_PAIRS,1,[Define to 1 to enable reset_color_pairs() function in test-programs])
1213         fi
1214 fi
1215 AC_SUBST(NCURSES_EXT_COLORS)
1216
1217 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
1218 AC_MSG_CHECKING(if you want to use extended mouse encoding)
1219 AC_ARG_ENABLE(ext-mouse,
1220         [  --enable-ext-mouse      compile for extended mouse-encoding],
1221         [with_ext_mouse=$enableval],
1222         [with_ext_mouse=$cf_dft_ext_mouse])
1223 AC_MSG_RESULT($with_ext_mouse)
1224 NCURSES_MOUSE_VERSION=1
1225 if test "x$with_ext_mouse" = xyes ; then
1226         NCURSES_MOUSE_VERSION=2
1227         CF_NCURSES_ABI_6
1228 fi
1229 AC_SUBST(NCURSES_MOUSE_VERSION)
1230
1231 ###   use option --enable-ext-putwin to turn on extended screendumps
1232 AC_MSG_CHECKING(if you want to use extended putwin/screendump)
1233 AC_ARG_ENABLE(ext-putwin,
1234         [  --enable-ext-putwin     compile with extended putwin/screendump],
1235         [with_ext_putwin=$enableval],
1236         [with_ext_putwin=$cf_dft_ext_putwin])
1237 AC_MSG_RESULT($with_ext_putwin)
1238 if test "x$with_ext_putwin" = xyes ; then
1239         AC_DEFINE(NCURSES_EXT_PUTWIN,1,[Define to 1 to compile with extended putwin/screendump])
1240 fi
1241
1242 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1243 AC_ARG_ENABLE(no-padding,
1244         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1245         [with_no_padding=$enableval],
1246         [with_no_padding=$with_ext_funcs])
1247 AC_MSG_RESULT($with_no_padding)
1248 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1249
1250 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1251 AC_MSG_CHECKING(if you want SIGWINCH handler)
1252 AC_ARG_ENABLE(sigwinch,
1253         [  --enable-sigwinch       compile with SIGWINCH handler],
1254         [with_sigwinch=$enableval],
1255         [with_sigwinch=$with_ext_funcs])
1256 AC_MSG_RESULT($with_sigwinch)
1257 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1258
1259 ###   use option --enable-tcap-names to allow user to define new capabilities
1260 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1261 AC_ARG_ENABLE(tcap-names,
1262         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1263         [with_tcap_names=$enableval],
1264         [with_tcap_names=$with_ext_funcs])
1265 AC_MSG_RESULT($with_tcap_names)
1266 NCURSES_XNAMES=0
1267 test "x$with_tcap_names" = xyes && NCURSES_XNAMES=1
1268 AC_SUBST(NCURSES_XNAMES)
1269
1270 ##############################################################################
1271 CF_HELP_MESSAGE(Reentrant Code:)
1272 CF_WITH_PTHREAD
1273
1274 if test "x$with_pthread" != xno; then
1275         AC_CHECK_FUNC(pthread_kill,[
1276                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1277                 AC_ARG_ENABLE(pthreads-eintr,
1278                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1279                         [use_pthreads_eintr=$enableval],
1280                         [use_pthreads_eintr=no])
1281                 AC_MSG_RESULT($use_pthreads_eintr)
1282                 if test "x$use_pthreads_eintr" = xyes ; then
1283                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1284                 fi])
1285
1286         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1287         AC_ARG_ENABLE(weak-symbols,
1288                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1289                 [use_weak_symbols=$enableval],
1290                 [use_weak_symbols=no])
1291         AC_MSG_RESULT($use_weak_symbols)
1292         if test "x$use_weak_symbols" = xyes ; then
1293                 CF_WEAK_SYMBOLS
1294         else
1295                 cf_cv_weak_symbols=no
1296         fi
1297
1298         if test "x$cf_cv_weak_symbols" = xyes ; then
1299                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1300         fi
1301 fi
1302
1303 PTHREAD=
1304 if test "x$with_pthread" = "xyes" ; then
1305         AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1306         enable_reentrant=yes
1307         if test "x$cf_cv_weak_symbols" = xyes ; then
1308                 PTHREAD=-lpthread
1309                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1310         fi
1311 fi
1312 AC_SUBST(PTHREAD)
1313
1314 # Reentrant code has to be opaque; there's little advantage to making ncurses
1315 # opaque outside of that, so there is no --enable-opaque option.  We can use
1316 # this option without --with-pthreads, but this will be always set for
1317 # pthreads.
1318 AC_MSG_CHECKING(if you want reentrant code)
1319 AC_ARG_ENABLE(reentrant,
1320         [  --enable-reentrant      compile with reentrant code],
1321         [with_reentrant=$enableval],
1322         [with_reentrant=no])
1323 AC_MSG_RESULT($with_reentrant)
1324 if test "x$with_reentrant" = xyes ; then
1325         cf_cv_enable_reentrant=1
1326         cf_cv_enable_opaque="NCURSES_INTERNALS"
1327         NCURSES_SIZE_T=int
1328         if test "x$cf_cv_weak_symbols" = xyes ; then
1329                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1330                 CF_ADD_LIB(pthread,TEST_LIBS)
1331                 CF_ADD_LIB(pthread,TEST_LIBS2)
1332                 CF_ADD_LIB(pthread,PRIVATE_LIBS)
1333         else
1334                 # when not using weak symbols but with_reentrant,
1335                 # add 't' to the library suffix on all platforms
1336                 # except cygwin, where we only do that if ALSO
1337                 # compiling with full thread support.
1338                 case "$host" in
1339                 (*cygwin* | *msys*)
1340                         if test "$with_pthread" = "yes" ; then
1341                                 if test "x$disable_lib_suffixes" = "xno" ; then
1342                                         LIB_SUFFIX="t${LIB_SUFFIX}"
1343                                 fi
1344                         fi ;;
1345                 (*)
1346                         if test "x$disable_lib_suffixes" = "xno" ; then
1347                                 LIB_SUFFIX="t${LIB_SUFFIX}"
1348                         fi
1349                         ;;
1350                 esac
1351         fi
1352         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use reentrant feature])
1353         CF_NCURSES_ABI_6
1354 else
1355         cf_cv_enable_reentrant=0
1356         cf_cv_enable_opaque="NCURSES_OPAQUE"
1357         NCURSES_SIZE_T=short
1358 fi
1359 AC_SUBST(cf_cv_enable_reentrant)
1360 AC_SUBST(cf_cv_enable_opaque)
1361
1362 AC_SUBST(NCURSES_SIZE_T)
1363
1364 AC_MSG_CHECKING(if you want opaque curses-library structures)
1365 CF_ARG_ENABLE(opaque-curses,
1366         [  --enable-opaque-curses  make curses WINDOW, etc., "opaque"],
1367         [enable_opaque_curses=yes],[
1368          test "$cf_cv_enable_reentrant" = 1 && enable_opaque_curses=yes
1369          test "$cf_cv_enable_reentrant" = 1 || enable_opaque_curses=no
1370         ])
1371 AC_MSG_RESULT($enable_opaque_curses)
1372
1373 test "$cf_cv_enable_reentrant" = 1 && \
1374 test "$enable_opaque_curses" = no && \
1375 AC_MSG_ERROR(reentrant configuration requires opaque library)
1376
1377 AC_MSG_CHECKING(if you want opaque form-library structures)
1378 AC_ARG_ENABLE(opaque-form,
1379         [  --enable-opaque-form    make form-library structures "opaque"],
1380         [enable_opaque_form=yes],[enable_opaque_form=no])
1381 AC_MSG_RESULT($enable_opaque_form)
1382
1383 AC_MSG_CHECKING(if you want opaque menu-library structures)
1384 AC_ARG_ENABLE(opaque-menu,
1385         [  --enable-opaque-menu    make menu-library structures "opaque"],
1386         [enable_opaque_menu=yes],[enable_opaque_menu=no])
1387 AC_MSG_RESULT($enable_opaque_menu)
1388
1389 AC_MSG_CHECKING(if you want opaque panel-library structures)
1390 AC_ARG_ENABLE(opaque-panel,
1391         [  --enable-opaque-panel   make panel-library structures "opaque"],
1392         [enable_opaque_panel=yes],[enable_opaque_panel=no])
1393 AC_MSG_RESULT($enable_opaque_panel)
1394
1395 NCURSES_OPAQUE=0;               test "$enable_opaque_curses" = yes && NCURSES_OPAQUE=1
1396 NCURSES_OPAQUE_FORM=0;  test "$enable_opaque_form"   = yes && NCURSES_OPAQUE_FORM=1
1397 NCURSES_OPAQUE_MENU=0;  test "$enable_opaque_menu"   = yes && NCURSES_OPAQUE_MENU=1
1398 NCURSES_OPAQUE_PANEL=0; test "$enable_opaque_panel"  = yes && NCURSES_OPAQUE_PANEL=1
1399
1400 AC_SUBST(NCURSES_OPAQUE)
1401 AC_SUBST(NCURSES_OPAQUE_FORM)
1402 AC_SUBST(NCURSES_OPAQUE_MENU)
1403 AC_SUBST(NCURSES_OPAQUE_PANEL)
1404
1405 ### Allow using a different wrap-prefix
1406 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1407         AC_MSG_CHECKING(for prefix used to wrap public variables)
1408         AC_ARG_WITH(wrap-prefix,
1409                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1410                 [NCURSES_WRAP_PREFIX=$withval],
1411                 [NCURSES_WRAP_PREFIX=_nc_])
1412         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1413 else
1414         NCURSES_WRAP_PREFIX=_nc_
1415 fi
1416 AC_SUBST(NCURSES_WRAP_PREFIX)
1417 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1418
1419 ###############################################################################
1420 # These options are relatively safe to experiment with.
1421 CF_HELP_MESSAGE(Development Code:)
1422 AC_MSG_CHECKING(if you want all development code)
1423 AC_ARG_WITH(develop,
1424         [  --without-develop       disable development options],
1425         [with_develop=$withval],
1426         [with_develop=no])
1427 AC_MSG_RESULT($with_develop)
1428
1429 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1430 AC_MSG_CHECKING(if you want hard-tabs code)
1431 AC_ARG_ENABLE(hard-tabs,
1432         [  --enable-hard-tabs      compile with hard-tabs code],,
1433         [enable_hard_tabs=$with_develop])
1434 AC_MSG_RESULT($enable_hard_tabs)
1435 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1436
1437 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1438 AC_MSG_CHECKING(if you want limited support for xmc)
1439 AC_ARG_ENABLE(xmc-glitch,
1440         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1441         [enable_xmc_glitch=$with_develop])
1442 AC_MSG_RESULT($enable_xmc_glitch)
1443 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1444
1445 ###############################################################################
1446 # These are just experimental, probably should not be in a package:
1447 CF_HELP_MESSAGE(Experimental Code:)
1448
1449 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1450 AC_ARG_ENABLE(assumed-color,
1451         [  --disable-assumed-color do not assume anything about default-colors],
1452         [with_assumed_color=$enableval],
1453         [with_assumed_color=yes])
1454 AC_MSG_RESULT($with_assumed_color)
1455 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1456
1457 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1458 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1459 AC_ARG_ENABLE(hashmap,
1460         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1461         [with_hashmap=$enableval],
1462         [with_hashmap=yes])
1463 AC_MSG_RESULT($with_hashmap)
1464 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1465
1466 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1467 AC_MSG_CHECKING(if you want colorfgbg code)
1468 AC_ARG_ENABLE(colorfgbg,
1469         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1470         [with_colorfgbg=$enableval],
1471         [with_colorfgbg=no])
1472 AC_MSG_RESULT($with_colorfgbg)
1473 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1474
1475 ###   use option --enable-fvisibility to turn on use of gcc-specific feature
1476 AC_MSG_CHECKING(if you want to use gcc -fvisibility option)
1477 AC_ARG_ENABLE(fvisibility,
1478         [  --enable-fvisibility    compile with -fvisibility=hidden],
1479         [cf_with_fvisibility=$enableval],
1480         [cf_with_fvisibility=no])
1481 AC_MSG_RESULT($cf_with_fvisibility)
1482
1483 NCURSES_IMPEXP=
1484 NCURSES_CXX_IMPEXP=
1485 if test "x$cf_with_fvisibility" = xyes; then
1486         CF_CHECK_FVISIBILITY($CC,CFLAGS,cf_cv_fvisibility_hidden)
1487         if test "x$cf_cv_fvisibility_hidden" = xyes
1488         then
1489                 CF_ADD_CFLAGS([-fvisibility=hidden])
1490                 NCURSES_IMPEXP="__attribute__ ((visibility(\"default\")))"
1491         fi
1492         if test -n "$CXX"
1493         then
1494                 AC_LANG_PUSH(C++)
1495                 CF_CHECK_FVISIBILITY($CXX,CXXFLAGS,cf_cv_fvisibility_hidden2)
1496                 if test "x$cf_cv_fvisibility_hidden2" = xyes
1497                 then
1498                         CF_ADD_CXXFLAGS([-fvisibility=hidden])
1499                         NCURSES_CXX_IMPEXP="__attribute__ ((visibility(\"default\")))"
1500                 fi
1501                 AC_LANG_POP
1502         fi
1503 fi
1504 AC_SUBST(NCURSES_IMPEXP)
1505 AC_SUBST(NCURSES_CXX_IMPEXP)
1506
1507 ###   use option --enable-interop to turn on use of bindings used for interop
1508 AC_MSG_CHECKING(if you want interop bindings)
1509 AC_ARG_ENABLE(interop,
1510         [  --enable-interop        compile-in interop bindings],
1511         [with_exp_interop=$enableval],
1512         [with_exp_interop=$cf_dft_interop])
1513 AC_MSG_RESULT($with_exp_interop)
1514
1515 NCURSES_INTEROP_FUNCS=0
1516 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1517 AC_SUBST(NCURSES_INTEROP_FUNCS)
1518
1519
1520 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1521 AC_ARG_ENABLE(safe-sprintf,
1522         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1523         [with_safe_sprintf=$enableval],
1524         [with_safe_sprintf=no])
1525 AC_MSG_RESULT($with_safe_sprintf)
1526
1527 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1528 # when hashmap is used scroll hints are useless
1529 if test "$with_hashmap" = no ; then
1530 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1531 AC_ARG_ENABLE(scroll-hints,
1532         [  --disable-scroll-hints  compile without scroll-hints code],
1533         [with_scroll_hints=$enableval],
1534         [with_scroll_hints=yes])
1535 AC_MSG_RESULT($with_scroll_hints)
1536 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1537 fi
1538
1539 AC_MSG_CHECKING(if you want wgetch-events code)
1540 AC_ARG_ENABLE(wgetch-events,
1541         [  --enable-wgetch-events  compile with wgetch-events code],
1542         [with_wgetch_events=$enableval],
1543         [with_wgetch_events=no])
1544 AC_MSG_RESULT($with_wgetch_events)
1545 test "x$with_wgetch_events" = xyes && AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with wgetch-events code])
1546
1547 ###############################################################################
1548 CF_HELP_MESSAGE(Testing/development Options:)
1549
1550 ###     use option --disable-echo to suppress full display compiling commands
1551 CF_DISABLE_ECHO
1552 if test "x$enable_echo" = xyes; then
1553         ECHO_LINK=
1554 else
1555         ECHO_LINK='@ echo linking $@ ... ;'
1556         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1557         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1558 fi
1559 AC_SUBST(ECHO_LINK)
1560
1561 # --disable-stripping is used for debugging
1562 CF_INSTALL_OPTS
1563
1564 # If we're avoiding relinking of shared libraries during install, that is to
1565 # avoid modifying the build-tree.  For the same reason, avoid doing ranlib if
1566 # the install program has "-p" (for preserving timestamps).
1567 cf_cv_do_reranlib=yes
1568 if test "x$cf_cv_install_p" = xyes
1569 then
1570         if test "x$cf_cv_do_relink" != xyes
1571         then
1572                 cf_cv_do_reranlib=no
1573                 INSTALL_OPT_P="-p"
1574                 INSTALL_LIB="$INSTALL_LIB $INSTALL_OPT_P"
1575         fi
1576 fi
1577 AC_SUBST(INSTALL_OPT_P)
1578
1579 ###     use option --enable-warnings to turn on all gcc warnings
1580 AC_MSG_CHECKING(if you want to see compiler warnings)
1581 AC_ARG_ENABLE(warnings,
1582         [  --enable-warnings       build: turn on GCC compiler warnings],
1583         [with_warnings=$enableval])
1584 AC_MSG_RESULT($with_warnings)
1585
1586 if test "x$with_warnings" = "xyes"; then
1587         CF_ADD_ADAFLAGS(-gnatg)
1588         CF_GCC_WARNINGS(Wno-unknown-pragmas Wswitch-enum)
1589         if test "x$cf_with_cxx" = xyes ; then
1590                 CF_GXX_WARNINGS(Wno-unused)
1591         fi
1592 fi
1593 CF_GCC_ATTRIBUTES
1594 CF_ENABLE_STRING_HACKS
1595
1596 ###     use option --enable-assertions to turn on generation of assertion code
1597 AC_MSG_CHECKING(if you want to enable runtime assertions)
1598 AC_ARG_ENABLE(assertions,
1599         [  --enable-assertions     test: turn on generation of assertion code],
1600         [with_assertions=$enableval],
1601         [with_assertions=no])
1602 AC_MSG_RESULT($with_assertions)
1603 if test -n "$GCC"
1604 then
1605         if test "$with_assertions" = no
1606         then
1607                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1608         else
1609                 CF_ADD_ADAFLAGS(-gnata)
1610         fi
1611 fi
1612
1613 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1614 CF_DISABLE_LEAKS
1615 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1616
1617 ###     use option --enable-expanded to generate certain macros as functions
1618 AC_ARG_ENABLE(expanded,
1619         [  --enable-expanded       test: generate functions for certain macros],
1620         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1621
1622 ###     use option --disable-macros to suppress macros in favor of functions
1623 AC_ARG_ENABLE(macros,
1624         [  --disable-macros        test: use functions rather than macros],
1625         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1626
1627 # Normally we only add trace() to the debug-library.  Allow this to be
1628 # extended to all models of the ncurses library:
1629 cf_all_traces=no
1630 case "$CFLAGS $CPPFLAGS" in
1631 (*-DTRACE*)
1632         cf_all_traces=yes
1633         ;;
1634 esac
1635
1636 AC_MSG_CHECKING(whether to add trace feature to all models)
1637 AC_ARG_WITH(trace,
1638 [  --with-trace            test: add trace() function to all models of ncurses],
1639 [cf_with_trace=$withval],
1640 [cf_with_trace=$cf_all_traces])
1641 AC_MSG_RESULT($cf_with_trace)
1642
1643 if test "x$cf_with_trace" = xyes ; then
1644         LIB_TRACING=all
1645         ADA_TRACE=TRUE
1646         CF_ADD_CFLAGS(-DTRACE)
1647         AC_DEFINE(HAVE__TRACEF,1,[Define to 1 if we have _tracef function])
1648 else
1649         LIB_TRACING=DEBUG
1650         ADA_TRACE=FALSE
1651 fi
1652
1653 AC_SUBST(ADA_TRACE)
1654
1655 CF_DISABLE_GNAT_PROJECTS
1656
1657 ###     Checks for libraries.
1658 case $cf_cv_system_name in
1659 (*mingw32*|*mingw64*)
1660         CPPFLAGS="$CPPFLAGS -DWINVER=0x0501 -DWIN32_LEAN_AND_MEAN"
1661         # Note: WINVER may be a problem with Windows 10
1662         ;;
1663 (*)
1664 AC_CHECK_FUNC(gettimeofday,
1665         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1666
1667 AC_CHECK_LIB(bsd, gettimeofday,
1668         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1669         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1670         ;;
1671 esac
1672
1673 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1674 AC_SUBST(MATH_LIB)
1675
1676 ###     Checks for header files.
1677 AC_STDC_HEADERS
1678 AC_HEADER_DIRENT
1679 AC_HEADER_TIME
1680 CF_REGEX
1681
1682 dnl These are some other potentially nonportable headers.
1683 AC_CHECK_HEADERS( \
1684 fcntl.h \
1685 getopt.h \
1686 limits.h \
1687 locale.h \
1688 math.h \
1689 poll.h \
1690 sys/ioctl.h \
1691 sys/param.h \
1692 sys/poll.h \
1693 sys/select.h \
1694 sys/time.h \
1695 sys/times.h \
1696 ttyent.h \
1697 unistd.h \
1698 wctype.h \
1699 )
1700
1701 CF_GETOPT_HEADER
1702
1703 CF_CHECK_ENVIRON(environ)
1704 CF_CHECK_GETENV
1705 if test "x$cf_cv_consistent_getenv" = xno && \
1706         test "x$cf_with_trace" = xyes
1707 then
1708         AC_MSG_WARN(The NCURSES_TRACE environment variable is not supported with this configuration)
1709 fi
1710
1711 CF_SYS_TIME_SELECT
1712
1713 ###     checks for compiler characteristics
1714 AC_LANG_C
1715 AC_C_CONST
1716 CF_C_INLINE(NCURSES_INLINE,1200)
1717 CF_SIG_ATOMIC_T
1718
1719 if test $NCURSES_CHTYPE = auto ; then
1720         CF_TYPEOF_CHTYPE
1721 else
1722         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1723 fi
1724 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1725 AC_SUBST(cf_cv_typeof_chtype)
1726
1727 CF_UNSIGNED_LITERALS
1728 cf_cv_1UL="1"
1729 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1730 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1731 AC_SUBST(cf_cv_1UL)
1732
1733 if test $NCURSES_MMASK_T = auto ; then
1734         cf_cv_typeof_mmask_t=long
1735 else
1736         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1737 fi
1738 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1739 AC_SUBST(cf_cv_typeof_mmask_t)
1740
1741 ###     Checks for external-data
1742 CF_ERRNO
1743 CF_LINK_DATAONLY
1744
1745 ###     Checks for library functions.
1746 AC_CHECK_FUNCS( \
1747 getcwd \
1748 getegid \
1749 geteuid \
1750 getopt \
1751 getttynam \
1752 issetugid \
1753 localeconv \
1754 poll \
1755 putenv \
1756 remove \
1757 select \
1758 setbuf \
1759 setbuffer \
1760 setenv \
1761 setvbuf \
1762 sigaction \
1763 sigvec \
1764 snprintf \
1765 strdup \
1766 strstr \
1767 sysconf \
1768 tcgetpgrp \
1769 times \
1770 tsearch \
1771 vsnprintf \
1772 )
1773
1774 if test "x$ac_cv_func_getopt" = xno && \
1775    test "x$cf_with_progs$cf_with_tests" != xnono; then
1776         AC_MSG_ERROR(getopt is required for building programs)
1777 fi
1778
1779 if test "x$with_safe_sprintf" = xyes
1780 then
1781         if test "x$ac_cv_func_vsnprintf" = xyes
1782         then
1783                 AC_MSG_WARN(will use vsnprintf instead of safe-sprintf option)
1784         else
1785                 AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1786         fi
1787 fi
1788
1789 if test "x$with_getcap" = "xyes" ; then
1790         CF_CGETENT
1791 fi
1792
1793 CF_ISASCII
1794 CF_STRUCT_SIGACTION
1795 CF_FUNC_NANOSLEEP
1796 CF_FUNC_TERMIOS
1797 CF_FUNC_VSSCANF
1798 CF_MKSTEMP
1799
1800 # setup for prototype of fallback for vsscanf()
1801 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1802
1803 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1804 if test "x$cross_compiling" = xyes ; then
1805         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1806 else
1807         AC_FUNC_SETVBUF_REVERSED
1808 fi
1809 AC_CHECK_TYPE(intptr_t, long)
1810 AC_CHECK_TYPE(ssize_t, int)
1811 CF_TYPE_SIGACTION
1812 CF_SIZECHANGE
1813 CF_FUNC_MEMMOVE
1814 CF_FUNC_POLL
1815 CF_VA_COPY
1816 AC_FUNC_VFORK
1817 CF_FOPEN_BIN_R
1818
1819 # special check for test/ditto.c
1820 CF_FUNC_OPENPTY
1821 if test "$cf_cv_func_openpty" != no ; then
1822         AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1823         AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1824         if test "x$cf_cv_lib_util" = xyes ; then
1825                 CF_ADD_LIB(util,TEST_LIBS)
1826         fi
1827 fi
1828 AC_SUBST(TEST_LIBS)
1829 AC_SUBST(TEST_LIBS2)
1830
1831 if test "$with_hashed_db" != no ; then
1832         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1833         CF_HASHED_DB($with_hashed_db)
1834 fi
1835
1836 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1837 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1838         CF_STRIP_G_OPT(CFLAGS)
1839         CF_STRIP_G_OPT(CXXFLAGS)
1840 fi
1841
1842 # Just in case, check if the C compiler has a bool type.
1843 CF_BOOL_DECL(cf_cv_cc_bool_type)
1844
1845 # Check for C++ compiler characteristics (and ensure that it's there!)
1846 if test -n "$CXX" ; then
1847         AC_LANG_CPLUSPLUS
1848         CF_STDCPP_LIBRARY
1849         CF_PROG_CC_C_O(CXX,[$CXXFLAGS $CPPFLAGS])
1850
1851         case $GXX_VERSION in
1852         (1.*|2.[[0-6]]*|[[1-9]][[0-9]].*)
1853                 cf_cxx_library=yes
1854                 ;;
1855         (*-2.7*|2.7*)
1856                 CF_GPP_LIBRARY
1857                 ;;
1858         (*)
1859                 cf_cxx_library=no
1860                 ;;
1861         esac
1862
1863         AC_CHECK_HEADERS(typeinfo)
1864         CF_CXX_IOSTREAM_NAMESPACE
1865         CF_BOOL_DECL
1866         CF_BOOL_SIZE
1867         CF_ETIP_DEFINES
1868         CF_CPP_PARAM_INIT
1869         CF_CPP_STATIC_CAST
1870         CF_CXX_AR_FLAGS
1871 else
1872         cf_cxx_library=no
1873         cf_cv_builtin_bool=1
1874
1875         # Just because we are not configuring against C++ right now does not
1876         # mean that a user will not want to use C++.  Some distributors disable
1877         # the C++ portion of this configuration as a shortcut (or just to avoid
1878         # compiling the demo in the c++ directory).  So we need a reasonable
1879         # default for the 'bool' type.
1880         #
1881         # Caveat: since the storage of the bool type is not standardized, it
1882         # may change.
1883
1884         if test "$NCURSES_BOOL" != auto ; then
1885                 cf_cv_type_of_bool=$NCURSES_BOOL
1886                 cf_cv_header_stdbool_h=0
1887         else
1888                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1889                         CF_BOOL_SIZE
1890                 else
1891                         AC_MSG_CHECKING(for fallback type of bool)
1892                         case "$host_cpu" in
1893                         (i?86)  cf_cv_type_of_bool=char ;;
1894                         (*)     cf_cv_type_of_bool=int  ;;
1895                         esac
1896                         AC_MSG_RESULT($cf_cv_type_of_bool)
1897                 fi
1898         fi
1899 fi
1900 AC_SUBST(CXXLIBS)
1901
1902 # If the C compiler did not declare bool, and we did not determine that the C++
1903 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1904 # ncurses library use the same type as C++ bool.  Note that this allows one to
1905 # specify the type of bool in a configure-script option and postpone
1906 # integration with the C++ compiler provided that the types are compatible.
1907 USE_CXX_BOOL=1
1908 if test $cf_cv_cc_bool_type = 1
1909 then
1910         # oops: C has a bool.  Unlikely, but C++ could differ.
1911         USE_CXX_BOOL=0
1912 elif test $cf_cv_builtin_bool = 0
1913 then
1914         # C++ has no bool
1915         USE_CXX_BOOL=0
1916 else
1917         # this is the normal case
1918         USE_CXX_BOOL='defined(__cplusplus)'
1919 fi
1920 AC_SUBST(USE_CXX_BOOL)
1921
1922 CF_HELP_MESSAGE(Ada Binding Options:)
1923
1924 dnl If the Ada95 source-tree is present, add that to the build unless it will
1925 dnl not work, or was not requested.
1926 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1927
1928 dnl libtool does not know anything about GNAT, though a change made in 1998
1929 dnl provided for it "someday".  Disable the ada subtree if we are using
1930 dnl libtool -TD 20070714
1931         if test "$cf_with_ada" != "no" ; then
1932                 if test "$with_libtool" != "no"; then
1933                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1934                         cf_with_ada=no
1935                 fi
1936         fi
1937
1938 dnl Check for availability of GNU Ada Translator (GNAT).
1939 dnl At the moment we support no other Ada compiler.
1940         if test "$cf_with_ada" != "no" ; then
1941                 CF_PROG_GNAT
1942                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
1943                         CF_ADD_ADAFLAGS(-gnatpn)
1944                         CF_FIXUP_ADAFLAGS
1945
1946                         CF_GNATPREP_OPT_T
1947
1948                         CF_GNAT_GENERICS
1949                         CF_GNAT_SIGINT
1950                         CF_GNAT_PROJECTS
1951
1952                         CF_WITH_ADA_COMPILER
1953
1954                         cf_ada_package=terminal_interface
1955                         AC_SUBST(cf_ada_package)
1956
1957                         CF_WITH_ADA_INCLUDE
1958                         CF_WITH_ADA_OBJECTS
1959                         CF_WITH_ADA_SHAREDLIB
1960
1961                         # allow the Ada binding to be renamed
1962                         CF_WITH_ADA_LIBNAME(AdaCurses)
1963                 fi
1964         fi
1965 else
1966         cf_with_ada=no
1967 fi
1968
1969 # do this "late" to avoid conflict with header-checks
1970 if test "x$with_widec" = xyes ; then
1971         AC_CHECK_SIZEOF(wchar_t)
1972         # cross-compiling to mingw can run into the problem that attempting to
1973         # link with the regex library fails, causing the test to not set this to
1974         # a number.  "recent" autoconf does not address this problem either -TD
1975         if test -z "$ac_cv_sizeof_wchar_t"
1976         then
1977                 CF_VERBOSE(test failed (assume 2))
1978                 sed /SIZEOF_WCHAR_T/d confdefs.h >confdefs.tmp
1979                 mv confdefs.tmp confdefs.h
1980                 echo "#define SIZEOF_WCHAR_T 2" >>confdefs.h
1981         fi
1982 fi
1983
1984 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1985 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1986 ###
1987 ### ticlib modules may be a separate library, otherwise contained in termlib.
1988 ### termlib modules may be a separate library, otherwise contained in ncurses.
1989 ###
1990 ### The of "+" or " " between the tokens controls the way the script
1991 ### chooses to split module lists into libraries.
1992 ###
1993 ### (see CF_LIB_RULES).
1994 AC_MSG_CHECKING(for library subsets)
1995 LIB_SUBSETS=
1996
1997 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1998         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1999         if test "$with_ticlib" != no ; then
2000                 LIB_SUBSETS="${LIB_SUBSETS} "
2001         else
2002                 LIB_SUBSETS="${LIB_SUBSETS}+"
2003         fi
2004 fi
2005
2006 LIB_SUBSETS="${LIB_SUBSETS}termlib"
2007 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
2008
2009 if test "$with_termlib" != no ; then
2010         LIB_SUBSETS="${LIB_SUBSETS} "
2011 else
2012         LIB_SUBSETS="${LIB_SUBSETS}+"
2013 fi
2014
2015 LIB_SUBSETS="${LIB_SUBSETS}base"
2016
2017 # Most term-driver calls are to tinfo, but some like init_pair are to the
2018 # base library (so it resides in base).
2019 if test "$with_term_driver" != no ; then
2020         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
2021         case $cf_cv_system_name in
2022         (*mingw32*|*mingw64*)
2023                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
2024                 CPPFLAGS="$CPPFLAGS -DUSE_WIN32CON_DRIVER"
2025                 ;;
2026         (*)
2027                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
2028                 ;;
2029         esac
2030 fi
2031
2032 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
2033 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
2034
2035 AC_MSG_RESULT($LIB_SUBSETS)
2036
2037 ### Construct the list of include-directories to be generated
2038 CF_INCLUDE_DIRS
2039 CF_ADA_INCLUDE_DIRS
2040
2041 ### Build up pieces for makefile rules
2042 AC_MSG_CHECKING(default library suffix)
2043 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
2044 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
2045 AC_MSG_RESULT($DFT_ARG_SUFFIX)
2046
2047 AC_MSG_CHECKING(default library-dependency suffix)
2048 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
2049 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
2050 AC_MSG_RESULT($DFT_DEP_SUFFIX)
2051
2052 AC_MSG_CHECKING(default object directory)
2053 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
2054 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
2055 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
2056
2057 if test "x$cf_with_cxx" = xyes ; then
2058 AC_MSG_CHECKING(c++ library-dependency suffix)
2059 if test "$with_libtool" != "no"; then
2060         # libtool thinks it can make c++ shared libraries (perhaps only g++)
2061         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2062 elif test "$with_shared_cxx" != "no"; then
2063         # also for g++ users...
2064         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
2065 else
2066         # we normally make a static library because C/C++ library rules differ
2067         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
2068 fi
2069 AC_MSG_RESULT($CXX_LIB_SUFFIX)
2070 AC_SUBST(CXX_LIB_SUFFIX)
2071 fi
2072
2073 # do not want -ldl in build except as needed for -lncurses dependency
2074 if test "x$with_dlsym" = xyes ; then
2075 if test $DFT_LWR_MODEL = shared || \
2076    test $DFT_LWR_MODEL = libtool ; then
2077         CF_REMOVE_LIB(LIBS,$LIBS,dl)
2078 fi
2079 fi
2080 ### Set up low-level terminfo dependencies for makefiles.
2081
2082 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
2083 # do not need libdl
2084 TICS_LIST=
2085 if test "x$with_dlsym" = xyes ; then
2086         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
2087 fi
2088
2089 USE_ARG_SUFFIX="${DFT_ARG_SUFFIX}${EXTRA_SUFFIX}"
2090 USE_LIB_SUFFIX="${LIB_SUFFIX}${EXTRA_SUFFIX}"
2091 USE_CFG_SUFFIX=${DFT_ARG_SUFFIX}${cf_cv_abi_version}
2092 if test -n "$EXTRA_SUFFIX" && test "x$EXTRA_SUFFIX" != "x${cf_cv_abi_version}"
2093 then
2094         USE_CFG_SUFFIX="${USE_CFG_SUFFIX}${EXTRA_SUFFIX}"
2095 fi
2096 AC_SUBST(USE_ARG_SUFFIX)
2097 AC_SUBST(USE_CFG_SUFFIX)
2098 AC_SUBST(USE_LIB_SUFFIX)
2099
2100 if test "$with_ticlib" != no ; then
2101
2102         if test "x$with_ticlib" != xyes ; then
2103                 TICS_NAME=$with_ticlib
2104                 TICS_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
2105                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2106                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2107                 TICS_LIB_SUFFIX="${with_ticlib}"
2108         else
2109                 TICS_SUFFIX=${DFT_LIB_SUFFIX}
2110                 TICS_ARG_SUFFIX="${TICS_NAME}${USE_ARG_SUFFIX}"
2111                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
2112                 TICS_LIB_SUFFIX="${TICS_NAME}${USE_LIB_SUFFIX}"
2113         fi
2114         TICS_LDFLAGS="-L${LIB_DIR}"
2115         TICS_LIBS="-l${TICS_ARG_SUFFIX}"
2116 else
2117         TICS_SUFFIX=${DFT_LIB_SUFFIX}
2118         TICS_LDFLAGS="-L${LIB_DIR}"
2119         TICS_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2120 fi
2121 AC_SUBST(TICS_ARG_SUFFIX)
2122 AC_SUBST(TICS_DEP_SUFFIX)
2123 AC_SUBST(TICS_LIB_SUFFIX)
2124 AC_SUBST(TICS_LDFLAGS)
2125 AC_SUBST(TICS_LIBS)
2126
2127 if test "$with_termlib" != no ; then
2128
2129         if test "x$with_termlib" != xyes ; then
2130                 TINFO_NAME=$with_termlib
2131                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${USE_LIB_SUFFIX}//"`"
2132                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${USE_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2133                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
2134                 TINFO_LIB_SUFFIX="${with_termlib}"
2135         else
2136                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2137                 TINFO_ARG_SUFFIX="${TINFO_NAME}${USE_ARG_SUFFIX}"
2138                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
2139                 TINFO_LIB_SUFFIX="${TINFO_NAME}${USE_LIB_SUFFIX}"
2140         fi
2141
2142         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2143         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
2144         if test "$DFT_LWR_MODEL" = "libtool"; then
2145                 TEST_ARGS="${TEST_DEPS}"
2146                 TEST_ARG2="${TEST_DEP2}"
2147                 TINFO_LDFLAGS="-L${LIB_DIR}"
2148                 TINFO_LIBS="$TEST_ARGS"
2149                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
2150                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
2151         else
2152                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
2153                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
2154                 if test "x$with_term_driver" != xno ; then
2155                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2156                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${USE_ARG_SUFFIX}"
2157                         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX} $TEST_ARGS"
2158                 else
2159                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2160                         TINFO_LIBS="$TEST_ARGS"
2161                 fi
2162                 TINFO_LDFLAGS="-L${LIB_DIR}"
2163                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
2164         fi
2165 else
2166         # the next lines are needed for linking libtic over libncurses
2167         TINFO_NAME=${LIB_NAME}
2168         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
2169         TINFO_ARG_SUFFIX=${LIB_NAME}${USE_ARG_SUFFIX}
2170         if test "x$with_tic_depends" = xyes ; then
2171                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${USE_ARG_SUFFIX}"
2172         else
2173                 TICS_LIST="$SHLIB_LIST"
2174         fi
2175
2176         TINFO_LDFLAGS="-L${LIB_DIR}"
2177         TINFO_LIBS="-l${LIB_NAME}${USE_ARG_SUFFIX}"
2178 fi
2179
2180 if test "$DFT_LWR_MODEL" = shared ; then
2181         case $cf_cv_system_name in
2182         (cygwin*|msys*)
2183                 # "lib" files have ".dll.a" suffix, "cyg"or "msys-" files have ".dll"
2184                 TINFO_SUFFIX=.dll
2185                 ;;
2186         esac
2187 fi
2188
2189 AC_SUBST(TINFO_ARG_SUFFIX)
2190 AC_SUBST(TINFO_DEP_SUFFIX)
2191 AC_SUBST(TINFO_LIB_SUFFIX)
2192 AC_SUBST(TINFO_LDFLAGS)
2193 AC_SUBST(TINFO_LIBS)
2194
2195 if test "x$with_dlsym" = xyes ; then
2196         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
2197 fi
2198
2199 if test "$DFT_LWR_MODEL" = "libtool"; then
2200         OBJEXT=lo
2201 fi
2202
2203 # needed for Ada95
2204 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
2205 AC_SUBST(TINFO_LDFLAGS2)
2206
2207 case $DFT_LWR_MODEL in
2208 (normal|debug|profile)
2209         CF_LDFLAGS_STATIC
2210         ;;
2211 esac
2212
2213 AC_MSG_CHECKING(where we will install curses.h)
2214 AC_SUBST(includesubdir)
2215 includesubdir=
2216 if test "$with_overwrite" = no && \
2217  ( test "x$includedir" = 'x${prefix}/include' || \
2218    test "x$includedir" = "x${prefix}/include" )
2219 then
2220         includesubdir="/ncurses${USE_LIB_SUFFIX}"
2221 fi
2222 AC_MSG_RESULT(${includedir}${includesubdir})
2223
2224 ### Resolve a conflict between normal and wide-curses by forcing applications
2225 ### that will need libutf8 to add it to their configure script.
2226 if test "$with_overwrite" != no ; then
2227 if test "$NCURSES_LIBUTF8" = 1 ; then
2228         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
2229         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
2230 fi
2231 fi
2232 WITH_OVERWRITE=$with_overwrite
2233
2234 ### At least on MinGW a shared library build without libtool
2235 ### requires adding the additional libs to the link list.
2236 case $cf_cv_system_name in
2237 (*mingw32*|*mingw64*)
2238         if test "$DFT_LWR_MODEL" != "libtool"; then
2239            SHLIB_LIST="$SHLIB_LIST ${LIBS}"
2240         fi
2241         ;;
2242 *)      ;;
2243 esac
2244
2245 AC_SUBST(WITH_OVERWRITE)
2246 AC_SUBST(TICS_LIST)
2247 AC_SUBST(TINFO_LIST)
2248 AC_SUBST(SHLIB_LIST)
2249
2250 # used to separate tack out of the tree
2251 NCURSES_TREE=
2252 AC_SUBST(NCURSES_TREE)
2253
2254 ### predefined stuff for the test programs
2255 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
2256
2257 # pkgsrc uses these
2258 CF_WITH_LIB_BASENAME(FORM_NAME,form)
2259 CF_WITH_LIB_BASENAME(MENU_NAME,menu)
2260 CF_WITH_LIB_BASENAME(PANEL_NAME,panel)
2261 CF_WITH_LIB_BASENAME(CXX_NAME,cxx,ncurses++)
2262
2263 ### Construct the list of subdirectories for which we'll customize makefiles
2264 ### with the appropriate compile-rules.
2265
2266 CF_SRC_MODULES($modules_to_build)
2267
2268 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2269    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/src/library.gpr:Ada95/src/library.gpr.in"
2270    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${USE_CFG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
2271    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${USE_CFG_SUFFIX}-config.1:man/MKada_config.in"
2272 fi
2273
2274 CF_DIRS_TO_MAKE
2275
2276 # symbols that differ when compiling Ada95 by itself.
2277 NCURSES_SHLIB2=$SHELL' $(top_srcdir)/misc/shlib'
2278 AC_SUBST(NCURSES_SHLIB2)
2279
2280 # values to use as strings
2281 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
2282
2283 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
2284
2285 ### Now that we're done running tests, add the compiler-warnings, if any
2286 CF_ADD_CFLAGS($EXTRA_CFLAGS)
2287
2288 ### Define substitutions for header files to avoid name-pollution
2289 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
2290 CF_SUBST_IF(["x$ac_cv_header_stdint_h" = xyes], HAVE_STDINT_H, 1, 0)
2291 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
2292 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
2293
2294 ################################################################################
2295 test "x$use_database" = xyes && \
2296 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
2297
2298 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
2299 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${USE_CFG_SUFFIX}-config.1:man/MKncu_config.in"
2300
2301 if test "x$enable_pc_files" = xyes && test -z "$MAKE_PC_FILES" ; then
2302 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
2303 fi
2304 AC_SUBST(cross_compiling)
2305
2306 if test "x$cf_with_tests" != xno ; then
2307         MAKE_TESTS=
2308 else
2309         MAKE_TESTS="#"
2310 fi
2311 AC_SUBST(MAKE_TESTS)
2312
2313 ADAHTML_DIR=../../doc/html/ada
2314 AC_SUBST(ADAHTML_DIR)
2315
2316 # workaround for OS/2 (20151017)
2317 case $cf_cv_system_name in
2318 (os2*)
2319         LIBTOOL_OPTS_CXX="-os2dllname ncurs++"
2320         ;;
2321 (*)
2322         LIBTOOL_OPTS_CXX=
2323         ;;
2324 esac
2325 AC_SUBST(LIBTOOL_OPTS_CXX)
2326
2327 # workaround for g++ versus Solaris (20131116)
2328 case $cf_cv_system_name in
2329 (solaris2*)
2330         case "x$CPPFLAGS" in
2331         (*-D_XOPEN_SOURCE_EXTENDED*)
2332                 CF_VERBOSE(moving _XOPEN_SOURCE_EXTENDED to work around g++ problem)
2333                 CFLAGS="$CFLAGS -D_XOPEN_SOURCE_EXTENDED"
2334                 CPPFLAGS=`echo "x$CPPFLAGS" | sed -e  's/^.//' -e 's/-D_XOPEN_SOURCE_EXTENDED//'`
2335                 ;;
2336         esac
2337         ;;
2338 esac
2339
2340 # Help to automatically enable the extended curses features when using either
2341 # the *-config or the ".pc" files by adding defines.
2342 AC_MSG_CHECKING(for defines to add to ncurses${USE_CFG_SUFFIX}-config script)
2343 PKG_CFLAGS=
2344 for cf_loop1 in $CPPFLAGS_after_XOPEN
2345 do
2346         cf_found=no
2347         for cf_loop2 in $CPPFLAGS_before_XOPEN
2348         do
2349                 if test "x$cf_loop1" = "x$cf_loop2"
2350                 then
2351                         cf_found=yes
2352                         break
2353                 fi
2354         done
2355         test "$cf_found" = no && PKG_CFLAGS="$PKG_CFLAGS $cf_loop1"
2356 done
2357 AC_MSG_RESULT($PKG_CFLAGS)
2358 AC_SUBST(PKG_CFLAGS)
2359
2360 # AC_CHECK_SIZEOF demands a literal parameter, no variables.  So we do this.
2361 case "x$NCURSES_OSPEED" in
2362 (*short*)
2363         cf_compatible=1
2364         ;;
2365 (*)
2366         cf_compatible=0
2367         ;;
2368 esac
2369 AC_DEFINE_UNQUOTED(NCURSES_OSPEED_COMPAT,$cf_compatible,[Define to 1 if termcap variable ospeed is short])
2370
2371 case "x$cf_cv_typeof_chtype" in
2372 (xshort|xint|xlong)
2373         cf_cv_typeof_chtype="unsigned $cf_cv_typeof_chtype"
2374         ;;
2375 esac
2376
2377 case "x$cf_cv_typeof_mmask_t" in
2378 (xshort|xint|xlong)
2379         cf_cv_typeof_mmask_t="unsigned $cf_cv_typeof_mmask_t"
2380         ;;
2381 esac
2382
2383 # substitute into misc/Makefile to suppress
2384 # (un)install.data from the
2385 # (un)install rules.
2386 if test "x$cf_with_db_install" = "xno"; then
2387         MISC_INSTALL_DATA=
2388         MISC_UNINSTALL_DATA=
2389 else
2390         MISC_INSTALL_DATA=install.data
2391         MISC_UNINSTALL_DATA=uninstall.data
2392 fi
2393 AC_SUBST(MISC_INSTALL_DATA)
2394 AC_SUBST(MISC_UNINSTALL_DATA)
2395
2396 if test "x$cf_with_db_install" = "xno" || test "x$TERMINFO_SRC" = "xno"; then
2397         MAKE_DATABASE="#"
2398 else
2399         MAKE_DATABASE="$MAKE_TERMINFO"
2400 fi
2401 AC_SUBST(MAKE_DATABASE)
2402
2403 dnl Override the package used for exported symbols
2404 if test -n "$PACKAGE"
2405 then
2406         PACKAGE="${PACKAGE}${DFT_ARG_SUFFIX}"
2407         export PACKAGE
2408         echo "package: $PACKAGE"
2409 fi
2410
2411 UNALTERED_SYMS=
2412 cf_filter_syms=no
2413
2414 if test -n "$RESULTING_SYMS"
2415 then
2416         cf_filter_syms=$cf_dft_filter_syms
2417         CF_VERBOSE(will map symbols to ABI=$cf_cv_abi_version)
2418 fi
2419
2420 if test "x$WILDCARD_SYMS" = xno
2421 then
2422         cf_filter_syms=yes
2423 fi
2424
2425 test "x$cf_with_trace" = xyes && NCURSES_INLINE=
2426
2427 UNALTERED_SYMS=`echo "$RESULTING_SYMS" | sed -e 's/\\$/\\\\$/g'`
2428 if test $cf_filter_syms = yes
2429 then
2430         RESULTING_SYMS=resulting.map
2431 fi
2432 AC_SUBST(UNALTERED_SYMS)
2433
2434 if test "x$cross_compiling" = xyes ; then
2435         ADAGEN_LDFLAGS='$(CROSS_LDFLAGS)'
2436         CHECK_BUILD="#"
2437 else
2438         ADAGEN_LDFLAGS='$(NATIVE_LDFLAGS)'
2439         CHECK_BUILD=
2440 fi
2441 AC_SUBST(ADAGEN_LDFLAGS)
2442 AC_SUBST(CHECK_BUILD)
2443 AC_SUBST(PRIVATE_LIBS)
2444
2445 # This is used for the *-config script and *.pc data files.
2446 CF_LD_SEARCHPATH
2447
2448 AC_DEFINE(HAVE_CURSES_DATA_BOOLNAMES,1,[definition needed for in-tree build of tack])
2449
2450 AC_OUTPUT( \
2451         include/MKterm.h.awk \
2452         include/curses.head:include/curses.h.in \
2453         include/ncurses_dll.h \
2454         include/termcap.h \
2455         include/unctrl.h \
2456         $SUB_MAKEFILES \
2457         Makefile,[
2458 if test "x$cf_with_tests" != xno ; then
2459         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LD"], test)
2460 fi
2461 CF_LIB_RULES($SRC_SUBDIRS)
2462
2463 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
2464 if test -z "$USE_OLD_MAKERULES" ; then
2465         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
2466 fi
2467 fi
2468 ],[
2469 ### Special initialization commands, used to pass information from the
2470 ### configuration-run into config.status
2471
2472 ALTERNATE_SYMS="$ALTERNATE_SYMS"
2473 AWK="$AWK"
2474 CXX_NAME="$CXX_NAME"
2475 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
2476 DFT_LWR_MODEL="$DFT_LWR_MODEL"
2477 ECHO_LD="$ECHO_LD"
2478 EXTRA_SUFFIX="$EXTRA_SUFFIX"
2479 FORM_NAME="$FORM_NAME"
2480 LDCONFIG="$LDCONFIG"
2481 LIBTOOL_VERSION="$LIBTOOL_VERSION"
2482 LIB_NAME="$LIB_NAME"
2483 LIB_PREFIX="$LIB_PREFIX"
2484 LIB_SUBSETS="$LIB_SUBSETS"
2485 LIB_SUFFIX="$LIB_SUFFIX"
2486 LIB_TRACING="$LIB_TRACING"
2487 LN_S="$LN_S"
2488 MAKE_TERMINFO="$MAKE_TERMINFO"
2489 MENU_NAME="$MENU_NAME"
2490 NCURSES_MAJOR="$NCURSES_MAJOR"
2491 NCURSES_MINOR="$NCURSES_MINOR"
2492 NCURSES_OSPEED="$NCURSES_OSPEED"
2493 NCURSES_PATCH="$NCURSES_PATCH"
2494 PANEL_NAME="$PANEL_NAME"
2495 SRC_SUBDIRS="$SRC_SUBDIRS"
2496 TERMINFO="$TERMINFO"
2497 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
2498 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
2499 TICS_NAME="$TICS_NAME"
2500 TICS_SUFFIX="$TICS_SUFFIX"
2501 TIC_PATH="$TIC_PATH"
2502 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
2503 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
2504 TINFO_NAME="$TINFO_NAME"
2505 TINFO_SUFFIX="$TINFO_SUFFIX"
2506 UNALTERED_SYMS="$UNALTERED_SYMS"
2507 USE_ARG_SUFFIX="$USE_ARG_SUFFIX"
2508 USE_CFG_SUFFIX="$USE_CFG_SUFFIX"
2509 USE_LIB_SUFFIX="$USE_LIB_SUFFIX"
2510 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
2511 WILDCARD_SYMS="$WILDCARD_SYMS"
2512 WITH_CURSES_H="$with_curses_h"
2513 WITH_ECHO="${enable_echo:=yes}"
2514 WITH_OVERWRITE="$with_overwrite"
2515 cf_LIST_MODELS="$cf_list_models"
2516 cf_cv_abi_version="$cf_cv_abi_version"
2517 cf_cv_do_relink="$cf_cv_do_relink"
2518 cf_cv_do_reranlib="$cf_cv_do_reranlib"
2519 cf_cv_do_symlinks="$cf_cv_do_symlinks"
2520 cf_cv_enable_lp64="$cf_cv_enable_lp64"
2521 cf_cv_enable_opaque="$cf_cv_enable_opaque"
2522 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
2523 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
2524 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
2525 cf_cv_rel_version="$cf_cv_rel_version"
2526 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
2527 cf_cv_shared_soname='$cf_cv_shared_soname'
2528 cf_cv_shlib_version="$cf_cv_shlib_version"
2529 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
2530 cf_cv_system_name="$cf_cv_system_name"
2531 cf_cv_term_driver="$with_term_driver"
2532 cf_with_ada="$cf_with_ada"
2533 cf_with_cxx_binding="$cf_with_cxx_binding"
2534 cf_with_db_install="$cf_with_db_install"
2535 cf_with_manpages="$cf_with_manpages"
2536 cf_with_tests="$cf_with_tests"
2537 host="$host"
2538 target="$target"
2539 with_shared_cxx="$with_shared_cxx"
2540
2541 ],cat)dnl
2542 ${MAKE:-make} preinstall