configure.in

   1 dnl***************************************************************************
   2 dnl Copyright (c) 1998-2012,2013 Free Software Foundation, Inc.              *
   3 dnl                                                                          *
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a  *
   5 dnl copy of this software and associated documentation files (the            *
   6 dnl "Software"), to deal in the Software without restriction, including      *
   7 dnl without limitation the rights to use, copy, modify, merge, publish,      *
   8 dnl distribute, distribute with modifications, sublicense, and/or sell       *
   9 dnl copies of the Software, and to permit persons to whom the Software is    *
  10 dnl furnished to do so, subject to the following conditions:                 *
  11 dnl                                                                          *
  12 dnl The above copyright notice and this permission notice shall be included  *
  13 dnl in all copies or substantial portions of the Software.                   *
  14 dnl                                                                          *
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS  *
  16 dnl OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF               *
  17 dnl MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.   *
  18 dnl IN NO EVENT SHALL THE ABOVE COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,   *
  19 dnl DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR    *
  20 dnl OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR    *
  21 dnl THE USE OR OTHER DEALINGS IN THE SOFTWARE.                               *
  22 dnl                                                                          *
  23 dnl Except as contained in this notice, the name(s) of the above copyright   *
  24 dnl holders shall not be used in advertising or otherwise to promote the     *
  25 dnl sale, use or other dealings in this Software without prior written       *
  26 dnl authorization.                                                           *
  27 dnl***************************************************************************
  28 dnl
  29 dnl Author: Thomas E. Dickey 1995-on
  30 dnl
  31 dnl $Id: configure.in,v 1.572 2013/07/27 22:19:11 tom Exp $
  32 dnl Process this file with autoconf to produce a configure script.
  33 dnl
  34 dnl See http://invisible-island.net/autoconf/ for additional information.
  35 dnl
  36 dnl ---------------------------------------------------------------------------
  37 AC_PREREQ(2.52.20030208)
  38 AC_REVISION($Revision: 1.572 $)
  39 AC_INIT(ncurses/base/lib_initscr.c)
  40 AC_CONFIG_HEADER(include/ncurses_cfg.h:include/ncurses_cfg.hin)
  41
  42 CF_TOP_BUILDDIR
  43 CF_SUBST_NCURSES_VERSION
  44
  45 CF_WITH_REL_VERSION(NCURSES)
  46 CF_WITH_ABI_VERSION
  47
  48 CF_WITH_SYSTYPE
  49
  50 ###     Save the given $CFLAGS to allow user-override.
  51 cf_user_CFLAGS="$CFLAGS"
  52
  53 ###     Default install-location
  54 CF_CFG_DEFAULTS
  55
  56 ###     Checks for programs.
  57 AC_ARG_WITH(ada,
  58         [  --without-ada           suppress check for Ada95, don't build demo],
  59         [cf_with_ada=$withval],
  60         [cf_with_ada=yes])
  61 if test "x$cf_with_ada" = xyes
  62 then
  63         cf_PROG_CC="gnatgcc gcc cc"
  64 else
  65         cf_PROG_CC="gcc cc"
  66 fi
  67
  68 CF_PROG_CC($cf_PROG_CC)
  69
  70 AC_PROG_CPP
  71 AC_PROG_GCC_TRADITIONAL
  72 CF_PROG_CC_C_O(CC)
  73 CF_PROG_LDCONFIG
  74
  75 dnl DEFECT in autoconf 2.12:    an attempt to set policy, this breaks the
  76 dnl                             configure script by not letting us test if C++
  77 dnl                             is present, making this option necessary.
  78 AC_MSG_CHECKING(if you want to ensure bool is consistent with C++)
  79 AC_ARG_WITH(cxx,
  80         [  --without-cxx           do not adjust ncurses bool to match C++],
  81         [cf_with_cxx=$withval],
  82         [cf_with_cxx=yes])
  83 AC_MSG_RESULT($cf_with_cxx)
  84 if test "X$cf_with_cxx" = Xno ; then
  85         CXX=""
  86         GXX=""
  87 else
  88         # with autoconf 2.13, we can change the error to a warning:
  89         pushdef([AC_MSG_ERROR],
  90                 [AC_MSG_RESULT(no)
  91                  AC_MSG_WARN([You don't have any C++ compiler, too bad])
  92                 cf_with_cxx=no; CXX=""; GXX="";])dnl
  93         AC_PROG_CXX
  94         popdef([AC_MSG_ERROR])dnl
  95         # autoconf 2.5x removed the error (hardcoding it to g++, or just blank)
  96         if test "$CXX" = "g++" ; then
  97                 AC_PATH_PROG(CXX,g++)
  98         fi
  99         case "x$CXX" in #(vi
 100         x|xg++)
 101                 AC_MSG_WARN([You don't have any C++ compiler, too bad])
 102                 cf_with_cxx=no; CXX=""; GXX="";
 103                 ;;
 104         esac
 105 fi
 106
 107 CF_GXX_VERSION
 108 case $GXX_VERSION in
 109 1*|2.[[0-6]]*)
 110         # GXX=""; CXX=""; ac_cv_prog_gxx=no
 111         # cf_cxx_library=no
 112         AC_MSG_WARN(templates do not work)
 113         ;;
 114 esac
 115
 116 AC_MSG_CHECKING(if you want to build C++ binding and demo)
 117 AC_ARG_WITH(cxx-binding,
 118         [  --without-cxx-binding   do not build C++ binding and demo],
 119         [cf_with_cxx_binding=$withval],
 120         [cf_with_cxx_binding=$cf_with_cxx])
 121 AC_MSG_RESULT($cf_with_cxx_binding)
 122
 123 AC_MSG_CHECKING(if you want to build with Ada95)
 124 AC_MSG_RESULT($cf_with_ada)
 125
 126 AC_MSG_CHECKING(if you want to install manpages)
 127 AC_ARG_WITH(manpages,
 128         [  --without-manpages      suppress install of manpages],
 129         [cf_with_manpages=$withval],
 130         [cf_with_manpages=yes])
 131 AC_MSG_RESULT($cf_with_manpages)
 132
 133 AC_MSG_CHECKING(if you want to build programs such as tic)
 134 AC_ARG_WITH(progs,
 135         [  --without-progs         suppress build with programs (e.g., tic)],
 136         [cf_with_progs=$withval],
 137         [cf_with_progs=yes])
 138 AC_MSG_RESULT($cf_with_progs)
 139
 140 AC_MSG_CHECKING(if you want to build test-programs)
 141 AC_ARG_WITH(tests,
 142         [  --without-tests         suppress build with test-programs],
 143         [cf_with_tests=$withval],
 144         [cf_with_tests=yes])
 145 AC_MSG_RESULT($cf_with_tests)
 146
 147 AC_MSG_CHECKING(if you wish to install curses.h)
 148 AC_ARG_WITH(curses-h,
 149         [  --without-curses-h      install curses.h as ncurses.h only],
 150         [with_curses_h=$withval],
 151         [with_curses_h=yes])
 152 AC_MSG_RESULT($with_curses_h)
 153
 154 modules_to_build="ncurses"
 155 if test "X$cf_with_progs" != Xno ; then
 156 modules_to_build="$modules_to_build progs tack"
 157 fi
 158 modules_to_build="$modules_to_build panel menu form"
 159
 160 AC_ARG_PROGRAM
 161
 162 CF_PROG_AWK
 163 CF_PROG_EGREP
 164 CF_PROG_INSTALL
 165 CF_PROG_LINT
 166 CF_PROG_LN_S
 167
 168 AC_SYS_LONG_FILE_NAMES
 169
 170 # if we find pkg-config, check if we should install the ".pc" files.
 171 CF_PKG_CONFIG
 172 CF_WITH_PKG_CONFIG_LIBDIR
 173 CF_ENABLE_PC_FILES
 174
 175 AC_MSG_CHECKING(if we should assume mixed-case filenames)
 176 AC_ARG_ENABLE(mixed-case,
 177         [  --enable-mixed-case     tic should assume mixed-case filenames],
 178         [enable_mixedcase=$enableval],
 179         [enable_mixedcase=auto])
 180 AC_MSG_RESULT($enable_mixedcase)
 181 if test "$enable_mixedcase" = "auto" ; then
 182     CF_MIXEDCASE_FILENAMES
 183 else
 184     cf_cv_mixedcase=$enable_mixedcase
 185     if test "x$enable_mixedcase" = "xyes" ; then
 186         AC_DEFINE(MIXEDCASE_FILENAMES,1,[Define to 1 if tic should assume mixed-case filenames])
 187     fi
 188 fi
 189
 190 # do this after mixed-case option (tags/TAGS is not as important as tic).
 191 AC_PROG_MAKE_SET
 192 CF_MAKE_TAGS
 193 CF_MAKEFLAGS
 194
 195 dnl These are standard among *NIX systems, but not when cross-compiling
 196 AC_CHECK_TOOL(RANLIB, ranlib, ':')
 197 AC_CHECK_TOOL(LD, ld, ld)
 198 AC_CHECK_TOOL(AR, ar, ar)
 199 AC_CHECK_TOOL(NM, nm, nm)
 200 CF_AR_FLAGS
 201
 202 dnl Special option for use by system-builders: the install-prefix is used to
 203 dnl adjust the location into which the actual install is done, so that an
 204 dnl archive can be built without modifying the host system's configuration.
 205 AC_MSG_CHECKING(if you have specified an install-prefix)
 206 AC_ARG_WITH(install-prefix,
 207         [  --with-install-prefix   prefixes actual install-location ($DESTDIR)],
 208         [case "x$withval" in #(vi
 209         xyes|xno) #(vi
 210                 ;;
 211         *)      DESTDIR="$withval"
 212                 ;;
 213         esac])
 214 AC_MSG_RESULT($DESTDIR)
 215 AC_SUBST(DESTDIR)
 216
 217 ###############################################################################
 218 CF_HELP_MESSAGE(Build-Tools Needed to Compile Temporary Applications for Cross-compiling:)
 219 # If we're cross-compiling, allow the user to override the tools and their
 220 # options.  The configure script is oriented toward identifying the host
 221 # compiler, etc., but we need a build compiler to generate parts of the source.
 222 CF_BUILD_CC
 223
 224 ###############################################################################
 225 CF_HELP_MESSAGE(Options to Specify the Libraries Built/Used:)
 226
 227 ### Options to allow the user to specify the set of libraries which are used.
 228 ### Use "--without-normal --with-shared" to allow the default model to be
 229 ### shared, for example.
 230 cf_list_models=""
 231 AC_SUBST(cf_list_models)dnl     the complete list of models ("normal debug")
 232
 233 CF_WITH_LIBTOOL
 234 if test "$with_libtool" != "no" ; then
 235
 236 cf_list_models="$cf_list_models libtool"
 237
 238 else
 239
 240 AC_MSG_CHECKING(if you want to build shared libraries)
 241 AC_ARG_WITH(shared,
 242         [  --with-shared           generate shared-libraries],
 243         [with_shared=$withval],
 244         [with_shared=no])
 245 AC_MSG_RESULT($with_shared)
 246 test "x$with_shared" = "xyes" && cf_list_models="$cf_list_models shared"
 247
 248 AC_MSG_CHECKING(if you want to build static libraries)
 249 AC_ARG_WITH(normal,
 250         [  --with-normal           generate normal-libraries (default)],
 251         [with_normal=$withval],
 252         [with_normal=yes])
 253 AC_MSG_RESULT($with_normal)
 254 test "x$with_normal" = "xyes" && cf_list_models="$cf_list_models normal"
 255
 256 AC_MSG_CHECKING(if you want to build debug libraries)
 257 AC_ARG_WITH(debug,
 258         [  --with-debug            generate debug-libraries (default)],
 259         [with_debug=$withval],
 260         [with_debug=yes])
 261 AC_MSG_RESULT($with_debug)
 262 test "x$with_debug" = "xyes" && cf_list_models="$cf_list_models debug"
 263
 264 AC_MSG_CHECKING(if you want to build profiling libraries)
 265 AC_ARG_WITH(profile,
 266         [  --with-profile          generate profile-libraries],
 267         [with_profile=$withval],
 268         [with_profile=no])
 269 AC_MSG_RESULT($with_profile)
 270 test "x$with_profile" = "xyes" && cf_list_models="$cf_list_models profile"
 271
 272 fi
 273
 274 if test "X$cf_with_cxx_binding" != Xno; then
 275 if test "x$with_shared" = "xyes"; then
 276 AC_MSG_CHECKING(if you want to build C++ shared libraries)
 277 AC_ARG_WITH(cxx-shared,
 278         [  --with-cxx-shared       generate C++ shared-libraries],
 279         [with_shared_cxx=$withval],
 280         [with_shared_cxx=no])
 281 AC_MSG_RESULT($with_shared_cxx)
 282 fi
 283 fi
 284
 285 ###############################################################################
 286
 287 AC_MSG_CHECKING(for specified models)
 288 test -z "$cf_list_models" && cf_list_models=normal
 289 dnl If we use libtool to generate libraries, then it must be the only
 290 dnl specified model.
 291 test "$with_libtool" != "no" && cf_list_models=libtool
 292 AC_MSG_RESULT($cf_list_models)
 293
 294 ### Use the first model as the default, and save its suffix for use in building
 295 ### up test-applications.
 296 AC_MSG_CHECKING(for default model)
 297 DFT_LWR_MODEL=`echo "$cf_list_models" | $AWK '{print $1}'`
 298 AC_MSG_RESULT($DFT_LWR_MODEL)
 299
 300 CF_UPPER(DFT_UPR_MODEL,$DFT_LWR_MODEL)dnl
 301
 302 AC_SUBST(DFT_LWR_MODEL)dnl      the default model ("normal")
 303 AC_SUBST(DFT_UPR_MODEL)dnl      the default model ("NORMAL")
 304
 305 TICS_NAME=tic
 306 AC_SUBST(TICS_NAME)
 307
 308 TINFO_NAME=tinfo
 309 AC_SUBST(TINFO_NAME)
 310
 311 LIB_NAME=ncurses
 312 AC_SUBST(LIB_NAME)
 313
 314 LIB_DIR=../lib
 315 LIB_2ND=../../lib
 316
 317 CF_WITH_LIB_PREFIX(cf_prefix)
 318
 319 LIB_SUFFIX=
 320 AC_SUBST(LIB_SUFFIX)
 321 CF_PATHSEP
 322
 323 ###############################################################################
 324
 325 AC_MSG_CHECKING(if you want to build a separate terminfo library)
 326 AC_ARG_WITH(termlib,
 327         [  --with-termlib          generate separate terminfo library],
 328         [with_termlib=$withval],
 329         [with_termlib=no])
 330 AC_MSG_RESULT($with_termlib)
 331
 332 AC_MSG_CHECKING(if you want to build a separate tic library)
 333 AC_ARG_WITH(ticlib,
 334         [  --with-ticlib           generate separate tic library],
 335         [with_ticlib=$withval],
 336         [with_ticlib=no])
 337 AC_MSG_RESULT($with_ticlib)
 338
 339 ### Checks for special libraries, must be done up-front.
 340 SHLIB_LIST=""
 341 CF_WITH_GPM
 342 if test "$with_gpm" != no ; then
 343         AC_MSG_CHECKING(if you want to load GPM dynamically)
 344         AC_ARG_WITH(dlsym,
 345                 [  --without-dlsym         do not use dlsym() to load GPM dynamically],
 346                 [with_dlsym=$withval],
 347                 [with_dlsym=yes])
 348         AC_MSG_RESULT($with_dlsym)
 349         if test "x$with_dlsym" = xyes ; then
 350                 CF_FUNC_DLSYM
 351                 if test "x$with_gpm" != xyes ; then
 352                         CF_VERBOSE(assuming soname for gpm is $with_gpm)
 353                         cf_cv_gpm_soname="$with_gpm"
 354                 else
 355                         CF_LIB_SONAME([#include <gpm.h>],[if (Gpm_Open(0,0)) Gpm_Close();],gpm)
 356                 fi
 357                 test "$cf_cv_gpm_soname" != "unknown" && AC_DEFINE_UNQUOTED(LIBGPM_SONAME,"$cf_cv_gpm_soname",[Define as needed to set the gpm share library soname])
 358                 SHLIB_LIST="-ldl $SHLIB_LIST"
 359         else
 360                 SHLIB_LIST="-lgpm $SHLIB_LIST"
 361                 CF_ADD_LIB(gpm,TEST_LIBS)
 362         fi
 363         AC_DEFINE(HAVE_LIBGPM,1,[Define to 1 if we have the gpm library])
 364         CF_CHECK_GPM_WGETCH
 365 fi
 366
 367 CF_WITH_SYSMOUSE
 368
 369 dnl Not all ports of gcc support the -g option
 370
 371 if test X"$CC_G_OPT" = X"" ; then
 372         CC_G_OPT='-g'
 373         test -n "$GCC" && test "x${ac_cv_prog_cc_g}" != xyes && CC_G_OPT=''
 374 fi
 375 AC_SUBST(CC_G_OPT)
 376
 377 if test X"$CXX_G_OPT" = X"" ; then
 378         CXX_G_OPT='-g'
 379         test -n "$GXX" && test "x${ac_cv_prog_cxx_g}" != xyes && CXX_G_OPT=''
 380 fi
 381 AC_SUBST(CXX_G_OPT)
 382
 383 AC_MSG_CHECKING(for default loader flags)
 384 case $DFT_LWR_MODEL in
 385 libtool) LD_MODEL=''   ;;
 386 normal)  LD_MODEL=''   ;;
 387 debug)   LD_MODEL=$CC_G_OPT ;;
 388 profile) LD_MODEL='-pg';;
 389 shared)  LD_MODEL=''   ;;
 390 esac
 391 AC_SUBST(LD_MODEL)dnl           the type of link (e.g., -g or -pg)
 392 AC_MSG_RESULT($LD_MODEL)
 393
 394 case $DFT_LWR_MODEL in
 395 shared)
 396 CF_ENABLE_RPATH
 397 AC_MSG_CHECKING(if shared libraries should be relinked during install)
 398 AC_ARG_ENABLE(relink,
 399 [  --disable-relink        relink shared libraries during install],
 400 [cf_cv_do_relink=$enableval],
 401 [cf_cv_do_relink=yes])
 402 AC_MSG_RESULT($cf_cv_do_relink)
 403         ;;
 404 esac
 405
 406 # we will build libraries one-level down.
 407 rel_builddir=..
 408 CF_SHARED_OPTS
 409 if test "$CC_SHARED_OPTS" = "unknown"; then
 410         for model in $cf_list_models; do
 411                 if test "$model" = "shared"; then
 412                         AC_ERROR(Shared libraries are not supported in this version)
 413                 fi
 414         done
 415 fi
 416
 417 ### If we're building with rpath, try to link non-standard libs that way too.
 418 if test "$DFT_LWR_MODEL" = "shared"; then
 419         CF_DISABLE_RPATH_HACK
 420 fi
 421
 422 ###############################################################################
 423 CF_HELP_MESSAGE(Fine-Tuning Your Configuration:)
 424
 425 ###     use option --disable-overwrite to leave out the link to -lcurses
 426 AC_MSG_CHECKING(if you wish to install ncurses overwriting curses)
 427 AC_ARG_ENABLE(overwrite,
 428         [  --disable-overwrite     leave out the link to -lcurses],
 429         [with_overwrite=$enableval],
 430         [if test "$prefix" = "/usr" ; then with_overwrite=yes; else with_overwrite=no; fi])
 431 AC_MSG_RESULT($with_overwrite)
 432
 433 AC_MSG_CHECKING(if external terminfo-database is used)
 434 AC_ARG_ENABLE(database,
 435         [  --disable-database      do not use terminfo, only fallbacks/termcap],
 436         [use_database=$enableval],
 437         [use_database=yes])
 438 AC_MSG_RESULT($use_database)
 439
 440 case $host_os in #(vi
 441 os2*) #(vi
 442         TERMINFO_SRC='${top_srcdir}/misc/emx.src'
 443         ;;
 444 *) #(vi
 445         TERMINFO_SRC='${top_srcdir}/misc/terminfo.src'
 446         ;;
 447 esac
 448 AC_SUBST(TERMINFO_SRC)
 449
 450 NCURSES_USE_DATABASE=0
 451 if test "$use_database" != no ; then
 452         NCURSES_USE_DATABASE=1
 453
 454         AC_MSG_CHECKING(which terminfo source-file will be installed)
 455         AC_ARG_WITH(database,
 456                 [  --with-database=XXX     specify terminfo source to install],
 457                 [TERMINFO_SRC=$withval])
 458         AC_MSG_RESULT($TERMINFO_SRC)
 459
 460         AC_MSG_CHECKING(whether to use hashed database instead of directory/tree)
 461         AC_ARG_WITH(hashed-db,
 462                 [  --with-hashed-db        specify hashed-database library],,
 463                 [with_hashed_db=no])
 464         AC_MSG_RESULT($with_hashed_db)
 465 else
 466         with_hashed_db=no
 467 fi
 468 AC_SUBST(NCURSES_USE_DATABASE)
 469
 470 AC_MSG_CHECKING(for list of fallback descriptions)
 471 AC_ARG_WITH(fallbacks,
 472         [  --with-fallbacks=XXX    specify list of fallback terminal descriptions],
 473         [with_fallback=$withval],
 474         [with_fallback=])
 475 AC_MSG_RESULT($with_fallback)
 476 FALLBACK_LIST=`echo "$with_fallback" | sed -e 's/,/ /g'`
 477 AC_SUBST(FALLBACK_LIST)
 478
 479 AC_MSG_CHECKING(if you want modern xterm or antique)
 480 AC_ARG_WITH(xterm-new,
 481         [  --without-xterm-new     specify if xterm terminfo should be old version],
 482         [with_xterm_new=$withval],
 483         [with_xterm_new=yes])
 484 case $with_xterm_new in
 485 no)     with_xterm_new=xterm-old;;
 486 *)      with_xterm_new=xterm-new;;
 487 esac
 488 AC_MSG_RESULT($with_xterm_new)
 489 WHICH_XTERM=$with_xterm_new
 490 AC_SUBST(WHICH_XTERM)
 491
 492 AC_MSG_CHECKING(if xterm backspace sends BS or DEL)
 493 AC_ARG_WITH(xterm-kbs,
 494         [  --with-xterm-kbs=XXX    specify if xterm backspace sends BS or DEL],
 495         [with_xterm_kbs=$withval],
 496         [with_xterm_kbs=BS])
 497 case x$with_xterm_kbs in
 498 xyes|xno|xBS|xbs|x8)
 499         with_xterm_kbs=BS
 500         ;;
 501 xDEL|xdel|x127)
 502         with_xterm_kbs=DEL
 503         ;;
 504 *)
 505         with_xterm_kbs=$withval
 506         ;;
 507 esac
 508 AC_MSG_RESULT($with_xterm_kbs)
 509 XTERM_KBS=$with_xterm_kbs
 510 AC_SUBST(XTERM_KBS)
 511
 512 MAKE_TERMINFO=
 513 if test "$use_database" = no ; then
 514         TERMINFO="${datadir}/terminfo"
 515         MAKE_TERMINFO="#"
 516 else
 517
 518 AC_MSG_CHECKING(for list of terminfo directories)
 519 CF_WITH_PATHLIST(terminfo-dirs,
 520         [  --with-terminfo-dirs=XXX specify list of terminfo directories],
 521         TERMINFO_DIRS,
 522         DATADIR/terminfo,
 523         ${datadir}/terminfo)
 524 AC_MSG_RESULT($TERMINFO_DIRS)
 525 test -n "$TERMINFO_DIRS" && AC_DEFINE_UNQUOTED(TERMINFO_DIRS,"$TERMINFO_DIRS",[Define as needed to predefine the TERMINFO_DIR searchlist])
 526
 527 AC_MSG_CHECKING(for default terminfo directory)
 528 CF_WITH_PATH(default-terminfo-dir,
 529         [  --with-default-terminfo-dir=DIR default terminfo directory],
 530         TERMINFO,
 531         DATADIR/terminfo,
 532         ${datadir}/terminfo)
 533 AC_MSG_RESULT($TERMINFO)
 534 AC_DEFINE_UNQUOTED(TERMINFO,"$TERMINFO",[Define to set the default terminal database path])
 535
 536 fi
 537
 538 AC_SUBST(TERMINFO)
 539 AC_SUBST(MAKE_TERMINFO)
 540
 541 ###     use option --disable-big-core to make tic run on small machines
 542 ###     We need 4Mb, check if we can allocate 50% more than that.
 543 AC_MSG_CHECKING(if big-core option selected)
 544 AC_ARG_ENABLE(big-core,
 545         [  --disable-big-core      assume machine has little memory],
 546         [with_big_core=$enableval],
 547         [AC_TRY_RUN([
 548 #include <stdlib.h>
 549 #include <string.h>
 550 int main() {
 551         unsigned long n = 6000000L;
 552         char *s = malloc(n);
 553         if (s != 0)
 554                 s[0] = s[n-1] = 0;
 555         ${cf_cv_main_return:-return}(s == 0);
 556 }],
 557         [with_big_core=yes],
 558         [with_big_core=no],
 559         [with_big_core=no])])
 560 AC_MSG_RESULT($with_big_core)
 561 test "x$with_big_core" = "xyes" && AC_DEFINE(HAVE_BIG_CORE,1,[Define to 1 if machine has ample memory for tic])
 562
 563 ### ISO C only guarantees 512-char strings, we have tables which load faster
 564 ### when constructed using "big" strings.  More than the C compiler, the awk
 565 ### program is a limit on most vendor UNIX systems.  Check that we can build.
 566 AC_MSG_CHECKING(if big-strings option selected)
 567 AC_ARG_ENABLE(big-strings,
 568         [  --disable-big-strings   assume compiler has only standard-size strings],
 569         [with_big_strings=$enableval],
 570         [CF_AWK_BIG_PRINTF(12000,with_big_strings)])
 571 AC_MSG_RESULT($with_big_strings)
 572
 573 USE_BIG_STRINGS=0
 574 test "x$with_big_strings" = "xyes" && USE_BIG_STRINGS=1
 575 AC_SUBST(USE_BIG_STRINGS)
 576
 577 ###     use option --enable-termcap to compile in the termcap fallback support
 578 AC_MSG_CHECKING(if you want termcap-fallback support)
 579 AC_ARG_ENABLE(termcap,
 580         [  --enable-termcap        compile in termcap fallback support],
 581         [with_termcap=$enableval],
 582         [with_termcap=no])
 583 AC_MSG_RESULT($with_termcap)
 584
 585 NCURSES_USE_TERMCAP=0
 586 if test "x$with_termcap" != "xyes" ; then
 587         if test "$use_database" = no ; then
 588                 if test -z "$with_fallback" ; then
 589                         AC_ERROR(You have disabled the database w/o specifying fallbacks)
 590                 fi
 591         fi
 592         AC_DEFINE(PURE_TERMINFO,1,[Define to 1 if we should support only terminfo])
 593 else
 594
 595         if test "$with_ticlib" != no ; then
 596                 AC_ERROR(Options --with-ticlib and --enable-termcap cannot be combined)
 597         fi
 598
 599         NCURSES_USE_TERMCAP=1
 600         AC_MSG_CHECKING(for list of termcap files)
 601         CF_WITH_PATHLIST(termpath,
 602                 [  --with-termpath=XXX     specify list of termcap files],
 603                 TERMPATH,
 604                 /etc/termcap:/usr/share/misc/termcap)
 605         AC_MSG_RESULT($TERMPATH)
 606         test -n "$TERMPATH" && AC_DEFINE_UNQUOTED(TERMPATH,"$TERMPATH",[Define to set the termcap searchlist])
 607
 608         ###     use option --enable-getcap to use a hacked getcap for reading termcaps
 609         AC_MSG_CHECKING(if fast termcap-loader is needed)
 610         AC_ARG_ENABLE(getcap,
 611                 [  --enable-getcap         fast termcap load, no xrefs to terminfo],
 612                 [with_getcap=$enableval],
 613                 [with_getcap=no])
 614         AC_MSG_RESULT($with_getcap)
 615         test "x$with_getcap" = "xyes" && AC_DEFINE(USE_GETCAP,1,[Define to 1 to use fast termcap-loader])
 616
 617         AC_MSG_CHECKING(if translated termcaps will be cached in ~/.terminfo)
 618         AC_ARG_ENABLE(getcap-cache,
 619                 [  --enable-getcap-cache   cache translated termcaps in ~/.terminfo],
 620                 [with_getcap_cache=$enableval],
 621                 [with_getcap_cache=no])
 622         AC_MSG_RESULT($with_getcap_cache)
 623         test "x$with_getcap_cache" = "xyes" && AC_DEFINE(USE_GETCAP_CACHE,1,[Define to 1 if translated termcap should be stored in $HOME/.terminfo])
 624
 625 fi
 626 AC_SUBST(NCURSES_USE_TERMCAP)
 627
 628 ###   Use option --disable-home-terminfo to completely remove ~/.terminfo
 629 AC_MSG_CHECKING(if ~/.terminfo is wanted)
 630 AC_ARG_ENABLE(home-terminfo,
 631         [  --disable-home-terminfo drop ~/.terminfo from terminfo search-path],
 632         [with_home_terminfo=$enableval],
 633         [with_home_terminfo=yes])
 634 AC_MSG_RESULT($with_home_terminfo)
 635 test "x$with_home_terminfo" = "xyes" && AC_DEFINE(USE_HOME_TERMINFO,1,[Define to 1 if $HOME/.terminfo feature is wanted])
 636
 637 AC_MSG_CHECKING(if you want to use restricted environment when running as root)
 638 AC_ARG_ENABLE(root-environ,
 639         [  --disable-root-environ  restrict environment when running as root],
 640         [with_root_environ=$enableval],
 641         [with_root_environ=yes])
 642 AC_MSG_RESULT($with_root_environ)
 643 test "x$with_root_environ" = xyes && AC_DEFINE(USE_ROOT_ENVIRON,1,[Define to 1 if environment should be restricted for root user])
 644
 645 ###   Use option --enable-symlinks to make tic use symlinks, not hard links
 646 ###   to reduce storage requirements for the terminfo database.
 647 CF_LINK_FUNCS
 648
 649 with_links=no
 650 with_symlinks=no
 651
 652 # soft links (symbolic links) are useful for some systems where hard links do
 653 # not work, or to make it simpler to copy terminfo trees around.
 654 if test "x$ac_cv_func_symlink" = xyes ; then
 655     AC_MSG_CHECKING(if tic should use symbolic links)
 656     AC_ARG_ENABLE(symlinks,
 657         [  --enable-symlinks       make tic use symbolic links not hard links],
 658         [with_symlinks=$enableval],
 659         [with_symlinks=no])
 660     AC_MSG_RESULT($with_symlinks)
 661 fi
 662
 663 # If we have hard links and did not choose to use soft links instead, there is
 664 # no reason to make this choice optional - use the hard links.
 665 if test "$with_symlinks" = no ; then
 666     AC_MSG_CHECKING(if tic should use hard links)
 667     if test "x$ac_cv_func_link" = xyes ; then
 668         with_links=yes
 669     else
 670         with_links=no
 671     fi
 672     AC_MSG_RESULT($with_links)
 673 fi
 674
 675 test "x$with_links" = xyes && AC_DEFINE(USE_LINKS,1,[Define to 1 if hardlinks should be used in terminfo database])
 676 test "x$with_symlinks" = xyes && AC_DEFINE(USE_SYMLINKS,1,[Define to 1 if symbolic links should be used in terminfo database])
 677
 678 ###   use option --enable-broken-linker to force on use of broken-linker support
 679 AC_MSG_CHECKING(if you want broken-linker support code)
 680 AC_ARG_ENABLE(broken_linker,
 681         [  --enable-broken_linker  compile with broken-linker support code],
 682         [with_broken_linker=$enableval],
 683         [with_broken_linker=${BROKEN_LINKER:-no}])
 684 AC_MSG_RESULT($with_broken_linker)
 685
 686 BROKEN_LINKER=0
 687 if test "x$with_broken_linker" = xyes ; then
 688         AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
 689         BROKEN_LINKER=1
 690 elif test "$DFT_LWR_MODEL" = shared ; then
 691         case $cf_cv_system_name in #(vi
 692         cygwin*)
 693                 AC_DEFINE(BROKEN_LINKER,1,[Define to 1 to work around linkers which cannot link data-only modules])
 694                 BROKEN_LINKER=1
 695                 CF_VERBOSE(cygwin linker is broken anyway)
 696                 ;;
 697         esac
 698 fi
 699 AC_SUBST(BROKEN_LINKER)
 700
 701 ###   use option --enable-bsdpad to have tputs process BSD-style prefix padding
 702 AC_MSG_CHECKING(if tputs should process BSD-style prefix padding)
 703 AC_ARG_ENABLE(bsdpad,
 704         [  --enable-bsdpad         recognize BSD-style prefix padding],
 705         [with_bsdpad=$enableval],
 706         [with_bsdpad=no])
 707 AC_MSG_RESULT($with_bsdpad)
 708 test "x$with_bsdpad" = xyes && AC_DEFINE(BSD_TPUTS,1,[Define to 1 to recognize BSD-style prefix padding])
 709
 710 ###   use option --enable-widec to turn on use of wide-character support
 711 NCURSES_CH_T=chtype
 712 NCURSES_LIBUTF8=0
 713
 714 NEED_WCHAR_H=0
 715 NCURSES_MBSTATE_T=0
 716 NCURSES_WCHAR_T=0
 717 NCURSES_WINT_T=0
 718
 719 # Check to define _XOPEN_SOURCE "automatically"
 720 CF_XOPEN_SOURCE(500)
 721
 722 # Work around breakage on OS X
 723 CF_SIGWINCH
 724
 725 # Checks for CODESET support.
 726 AM_LANGINFO_CODESET
 727
 728 # use these variables to work around a defect in gcc's fixincludes.
 729 NCURSES_OK_WCHAR_T=
 730 NCURSES_OK_WINT_T=
 731
 732 AC_MSG_CHECKING(if you want wide-character code)
 733 AC_ARG_ENABLE(widec,
 734         [  --enable-widec          compile with wide-char/UTF-8 code],
 735         [with_widec=$enableval],
 736         [with_widec=no])
 737 AC_MSG_RESULT($with_widec)
 738 if test "x$with_widec" = xyes ; then
 739         LIB_SUFFIX="w${LIB_SUFFIX}"
 740         AC_DEFINE(USE_WIDEC_SUPPORT,1,[Define to 1 to compile with wide-char/UTF-8 code])
 741         AC_DEFINE(NCURSES_WIDECHAR,1,[Define to 1 to compile with wide-char/UTF-8 code])
 742
 743         CF_CHECK_WCHAR_H
 744
 745         # with_overwrite=no
 746         NCURSES_CH_T=cchar_t
 747         AC_CHECK_FUNCS(putwc btowc wctob mbtowc wctomb mblen mbrlen mbrtowc wcsrtombs mbsrtowcs wcstombs mbstowcs)
 748         if test "x$ac_cv_func_putwc" != xyes ; then
 749                 CF_UTF8_LIB
 750                 if test "$cf_cv_utf8_lib" != no ; then
 751                         NCURSES_LIBUTF8=1
 752                 fi
 753         fi
 754         CF_WCHAR_TYPE(mbstate_t, NCURSES_MBSTATE_T)
 755         CF_WCHAR_TYPE(wchar_t,   NCURSES_WCHAR_T,   NCURSES_OK_WCHAR_T)
 756         CF_WCHAR_TYPE(wint_t,    NCURSES_WINT_T,    NCURSES_OK_WINT_T)
 757
 758         if test "$NCURSES_MBSTATE_T" != 0; then
 759                 AC_DEFINE(NEED_MBSTATE_T_DEF,1,[Define to 1 if we must declare mbstate_t])
 760         fi
 761 fi
 762 AC_SUBST(NCURSES_CH_T)
 763 AC_SUBST(NCURSES_LIBUTF8)
 764
 765 AC_SUBST(NEED_WCHAR_H)
 766 AC_SUBST(NCURSES_MBSTATE_T)
 767 AC_SUBST(NCURSES_WCHAR_T)
 768 AC_SUBST(NCURSES_WINT_T)
 769
 770 AC_SUBST(NCURSES_OK_WCHAR_T)
 771 AC_SUBST(NCURSES_OK_WINT_T)
 772
 773 ###   use option --disable-lp64 to allow long chtype
 774 case $cf_cv_abi_version in
 775 [[345]]*)
 776         default_with_lp64=no
 777         ;;
 778 *)
 779         default_with_lp64=yes
 780         ;;
 781 esac
 782
 783 AC_MSG_CHECKING(whether to enable _LP64 definition in curses.h)
 784 AC_ARG_ENABLE(lp64,
 785         [  --disable-lp64          allow chtype to be long (ignore _LP64)],
 786         [with_lp64=$enableval],
 787         [with_lp64=$default_with_lp64])
 788 AC_MSG_RESULT($with_lp64)
 789
 790 if test "x$with_lp64" = xyes ; then
 791         cf_cv_enable_lp64=1
 792 else
 793         cf_cv_enable_lp64=0
 794 fi
 795 AC_SUBST(cf_cv_enable_lp64)
 796
 797 CF_LARGEFILE
 798
 799 ###   use option --disable-tparm-varargs to make tparm() conform to X/Open
 800 AC_MSG_CHECKING(if you want tparm not to use X/Open fixed-parameter list)
 801 AC_ARG_ENABLE(tparm-varargs,
 802         [  --disable-tparm-varargs compile tparm() without varargs interface],
 803         [with_tparm_varargs=$enableval],
 804         [with_tparm_varargs=yes])
 805 AC_MSG_RESULT($with_tparm_varargs)
 806 NCURSES_TPARM_VARARGS=0
 807 test "x$with_tparm_varargs" = xyes && NCURSES_TPARM_VARARGS=1
 808 AC_SUBST(NCURSES_TPARM_VARARGS)
 809
 810 ###   use option --disable-tic-depends to make libtic not explicitly depend on ncurses/ncursesw
 811 if test "$with_ticlib" != no ; then
 812 AC_MSG_CHECKING(if you want tic library to use explicit dependency on ncurses$LIB_SUFFIX library)
 813 AC_ARG_ENABLE(tic-depends,
 814         [  --disable-tic-depends   link tic library without explicit dependency on ncurses library],
 815         [with_tic_depends=$enableval],
 816         [with_tic_depends=yes])
 817 AC_MSG_RESULT($with_tic_depends)
 818 else
 819         with_tic_depends=no
 820 fi
 821
 822 ###   use option --with-bool to override bool's type
 823 AC_MSG_CHECKING(for type of bool)
 824 AC_ARG_WITH(bool,
 825         [  --with-bool=TYPE        override fallback type of bool variable],
 826         [NCURSES_BOOL="$withval"],
 827         [NCURSES_BOOL=auto])
 828 AC_MSG_RESULT($NCURSES_BOOL)
 829 AC_SUBST(NCURSES_BOOL)
 830
 831 AC_MSG_CHECKING(for alternate terminal capabilities file)
 832 AC_ARG_WITH(caps,
 833         [  --with-caps=alt         compile with alternate Caps file],
 834         [TERMINFO_CAPS=Caps.$withval],
 835         [TERMINFO_CAPS=Caps])
 836 test -f "${srcdir}/include/${TERMINFO_CAPS}" || TERMINFO_CAPS=Caps
 837 AC_MSG_RESULT($TERMINFO_CAPS)
 838 AC_SUBST(TERMINFO_CAPS)
 839
 840 ###   use option --with-chtype to override chtype's type
 841 AC_MSG_CHECKING(for type of chtype)
 842 AC_ARG_WITH(chtype,
 843         [  --with-chtype=TYPE      override type of chtype],
 844         [NCURSES_CHTYPE="$withval"],
 845         [NCURSES_CHTYPE=auto])
 846 AC_MSG_RESULT($NCURSES_CHTYPE)
 847
 848 ###   use option --with-ospeed to override ospeed's type
 849 AC_MSG_CHECKING(for type of ospeed)
 850 AC_ARG_WITH(ospeed,
 851         [  --with-ospeed=TYPE      override type of ospeed variable],
 852         [NCURSES_OSPEED="$withval"],
 853         [NCURSES_OSPEED=short])
 854 AC_MSG_RESULT($NCURSES_OSPEED)
 855 AC_SUBST(NCURSES_OSPEED)
 856
 857 ###   use option --with-mmask-t to override mmask_t's type
 858 AC_MSG_CHECKING(for type of mmask_t)
 859 AC_ARG_WITH(mmask-t,
 860         [  --with-mmask-t=TYPE     override type of mmask_t],
 861         [NCURSES_MMASK_T="$withval"],
 862         [NCURSES_MMASK_T=auto])
 863 AC_MSG_RESULT($NCURSES_MMASK_T)
 864
 865 ###   use option --with-ccharw-max to override CCHARW_MAX size
 866 AC_MSG_CHECKING(for size CCHARW_MAX)
 867 AC_ARG_WITH(ccharw-max,
 868         [  --with-ccharw-max=XXX   override size CCHARW_MAX],
 869         [NCURSES_CCHARW_MAX="$withval"],
 870         [NCURSES_CCHARW_MAX=5])
 871 AC_MSG_RESULT($NCURSES_CCHARW_MAX)
 872 AC_SUBST(NCURSES_CCHARW_MAX)
 873
 874 ###   use option --with-tparm-arg to override tparm's argument type
 875 AC_MSG_CHECKING(for type of tparm args)
 876 AC_ARG_WITH(tparm-arg,
 877         [  --with-tparm-arg=TYPE   override parameter type of tparm],
 878         [NCURSES_TPARM_ARG="$withval"],
 879         [NCURSES_TPARM_ARG=long])
 880 AC_MSG_RESULT($NCURSES_TPARM_ARG)
 881 AC_SUBST(NCURSES_TPARM_ARG)
 882
 883 ### Enable compiling-in rcs id's
 884 AC_MSG_CHECKING(if RCS identifiers should be compiled-in)
 885 AC_ARG_WITH(rcs-ids,
 886         [  --with-rcs-ids          compile-in RCS identifiers],
 887         [with_rcs_ids=$withval],
 888         [with_rcs_ids=no])
 889 AC_MSG_RESULT($with_rcs_ids)
 890 test "x$with_rcs_ids" = xyes && AC_DEFINE(USE_RCS_IDS,1,[Define to 1 to compile-in RCS identifiers])
 891
 892 ###############################################################################
 893 CF_MAN_PAGES([ captoinfo clear infocmp infotocap tabs tic toe tput tset ])
 894
 895 ###############################################################################
 896 CF_HELP_MESSAGE(Extensions:)
 897
 898 ### Note that some functions (such as const) are normally disabled anyway.
 899 AC_MSG_CHECKING(if you want to build with function extensions)
 900 AC_ARG_ENABLE(ext-funcs,
 901         [  --disable-ext-funcs     disable function-extensions],
 902         [with_ext_funcs=$enableval],
 903         [with_ext_funcs=yes])
 904 AC_MSG_RESULT($with_ext_funcs)
 905 if test "x$with_ext_funcs" = xyes ; then
 906         NCURSES_EXT_FUNCS=1
 907         AC_DEFINE(HAVE_ASSUME_DEFAULT_COLORS,1,[Define to 1 to enable assume_default_colors() function])
 908         AC_DEFINE(HAVE_CURSES_VERSION,1,[Define to 1 to enable curses_version() function])
 909         AC_DEFINE(HAVE_HAS_KEY,1,[Define to 1 to enable has_key() function])
 910         AC_DEFINE(HAVE_RESIZETERM,1,[Define to 1 to enable resizeterm() function])
 911         AC_DEFINE(HAVE_RESIZE_TERM,1,[Define to 1 to enable resize_term() function])
 912         AC_DEFINE(HAVE_TERM_ENTRY_H,1,[Define to 1 to enable term_entry() function])
 913         AC_DEFINE(HAVE_USE_DEFAULT_COLORS,1,[Define to 1 to enable use_default_colors() function])
 914         AC_DEFINE(HAVE_USE_SCREEN,1,[Define to 1 to enable use_screen() function])
 915         AC_DEFINE(HAVE_USE_WINDOW,1,[Define to 1 to enable use_window() function])
 916         AC_DEFINE(HAVE_WRESIZE,1,[Define to 1 to enable wresize() function])
 917         AC_DEFINE(NCURSES_EXT_FUNCS,1,[Define to 1 to enable ncurses extended functions])
 918         GENERATED_EXT_FUNCS=generated
 919 else
 920         NCURSES_EXT_FUNCS=0
 921         GENERATED_EXT_FUNCS=
 922 fi
 923 AC_SUBST(NCURSES_EXT_FUNCS)
 924 AC_SUBST(GENERATED_EXT_FUNCS)
 925
 926 AC_MSG_CHECKING(if you want to build with experimental SCREEN extensions)
 927 AC_ARG_ENABLE(sp-funcs,
 928         [  --enable-sp-funcs       enable experimental SCREEN-extensions],
 929         [with_sp_funcs=$enableval],
 930         [with_sp_funcs=no])
 931 AC_MSG_RESULT($with_sp_funcs)
 932 if test "x$with_sp_funcs" = xyes ; then
 933         NCURSES_SP_FUNCS=1
 934         AC_DEFINE(NCURSES_SP_FUNCS,1,[Define to 1 to enable experimental SCREEN-extensions])
 935         GENERATED_SP_FUNCS=generated
 936 else
 937         NCURSES_SP_FUNCS=0
 938         GENERATED_SP_FUNCS=
 939 fi
 940 AC_SUBST(NCURSES_SP_FUNCS)
 941 AC_SUBST(GENERATED_SP_FUNCS)
 942
 943 AC_MSG_CHECKING(if you want to build with experimental terminal-driver)
 944 AC_ARG_ENABLE(term-driver,
 945         [  --enable-term-driver    enable experimental terminal-driver],
 946         [with_term_driver=$enableval],
 947         [with_term_driver=no])
 948 AC_MSG_RESULT($with_term_driver)
 949 if test "x$with_term_driver" = xyes ; then
 950         AC_DEFINE(USE_TERM_DRIVER,1,[Define to 1 to enable experimental terminal-driver])
 951         if test "x$with_sp_funcs" != xyes ; then
 952                 AC_MSG_ERROR(The term-driver option relies upon sp-funcs)
 953         fi
 954 fi
 955
 956 ###   use option --enable-const to turn on use of const beyond that in XSI.
 957 AC_MSG_CHECKING(for extended use of const keyword)
 958 AC_ARG_ENABLE(const,
 959         [  --enable-const          compile with extra/non-standard const],
 960         [with_ext_const=$enableval],
 961         [with_ext_const=no])
 962 AC_MSG_RESULT($with_ext_const)
 963 NCURSES_CONST='/*nothing*/'
 964 if test "x$with_ext_const" = xyes ; then
 965         NCURSES_CONST=const
 966 fi
 967 AC_SUBST(NCURSES_CONST)
 968
 969 ###   use option --enable-ext-colors to turn on use of colors beyond 16.
 970 AC_MSG_CHECKING(if you want to use extended colors)
 971 AC_ARG_ENABLE(ext-colors,
 972         [  --enable-ext-colors     compile for 256-color support],
 973         [with_ext_colors=$enableval],
 974         [with_ext_colors=no])
 975 AC_MSG_RESULT($with_ext_colors)
 976 NCURSES_EXT_COLORS=0
 977 if test "x$with_ext_colors" = xyes ; then
 978         if test "x$with_widec" != xyes ; then
 979                 AC_MSG_ERROR(This option applies only to wide-character library)
 980         else
 981                 # cannot be ABI 5 since it changes sizeof(cchar_t)
 982                 CF_NCURSES_ABI_6
 983         fi
 984         NCURSES_EXT_COLORS=1
 985         AC_DEFINE(NCURSES_EXT_COLORS,1,[Define to 1 to compile for 256-color support])
 986 fi
 987 AC_SUBST(NCURSES_EXT_COLORS)
 988
 989 ###   use option --enable-ext-mouse to modify coding to support 5-button mice
 990 AC_MSG_CHECKING(if you want to use extended mouse encoding)
 991 AC_ARG_ENABLE(ext-mouse,
 992         [  --enable-ext-mouse      compile for extended mouse-encoding],
 993         [with_ext_mouse=$enableval],
 994         [with_ext_mouse=no])
 995 AC_MSG_RESULT($with_ext_mouse)
 996 NCURSES_MOUSE_VERSION=1
 997 if test "x$with_ext_mouse" = xyes ; then
 998         NCURSES_MOUSE_VERSION=2
 999         CF_NCURSES_ABI_6
1000 fi
1001 AC_SUBST(NCURSES_MOUSE_VERSION)
1002
1003 AC_MSG_CHECKING(if you want \$NCURSES_NO_PADDING code)
1004 AC_ARG_ENABLE(no-padding,
1005         [  --enable-no-padding     compile with $NCURSES_NO_PADDING code],
1006         [with_no_padding=$enableval],
1007         [with_no_padding=$with_ext_funcs])
1008 AC_MSG_RESULT($with_no_padding)
1009 test "x$with_no_padding" = xyes && AC_DEFINE(NCURSES_NO_PADDING,1,[Define to 1 to compile with $NCURSES_NO_PADDING code])
1010
1011 AC_CHECK_SIZEOF([signed char], 0)
1012 if test "$ac_cv_sizeof_signed_char" = 1 ; then
1013         NCURSES_SBOOL="signed char"
1014 else
1015         NCURSES_SBOOL="char"
1016 fi
1017 AC_MSG_CHECKING(if you want to use signed Boolean array in term.h)
1018 AC_ARG_ENABLE(signed-char,
1019         [  --enable-signed-char    compile using signed Boolean's in term.h],
1020         [with_signed_char=$enableval],
1021         [with_signed_char=no])
1022 AC_MSG_RESULT($with_signed_char)
1023 test "x$with_signed_char" != xyes && NCURSES_SBOOL="char"
1024 AC_SUBST(NCURSES_SBOOL)
1025
1026 ###   use option --enable-sigwinch to turn on use of SIGWINCH logic
1027 AC_MSG_CHECKING(if you want SIGWINCH handler)
1028 AC_ARG_ENABLE(sigwinch,
1029         [  --enable-sigwinch       compile with SIGWINCH handler],
1030         [with_sigwinch=$enableval],
1031         [with_sigwinch=$with_ext_funcs])
1032 AC_MSG_RESULT($with_sigwinch)
1033 test "x$with_sigwinch" = xyes && AC_DEFINE(USE_SIGWINCH,1,[Define to 1 to compile with SIGWINCH handler])
1034
1035 ###   use option --enable-tcap-names to allow user to define new capabilities
1036 AC_MSG_CHECKING(if you want user-definable terminal capabilities like termcap)
1037 AC_ARG_ENABLE(tcap-names,
1038         [  --enable-tcap-names     compile with user-definable terminal capabilities],
1039         [with_tcap_names=$enableval],
1040         [with_tcap_names=$with_ext_funcs])
1041 AC_MSG_RESULT($with_tcap_names)
1042 NCURSES_XNAMES=0
1043 test "x$with_tcap_names" = xyes && NCURSES_XNAMES=1
1044 AC_SUBST(NCURSES_XNAMES)
1045
1046 ###############################################################################
1047 # These options are relatively safe to experiment with.
1048 CF_HELP_MESSAGE(Development Code:)
1049 AC_MSG_CHECKING(if you want all development code)
1050 AC_ARG_WITH(develop,
1051         [  --without-develop       disable development options],
1052         [with_develop=$withval],
1053         [with_develop=no])
1054 AC_MSG_RESULT($with_develop)
1055
1056 ###   use option --enable-hard-tabs to turn on use of hard-tabs optimize
1057 AC_MSG_CHECKING(if you want hard-tabs code)
1058 AC_ARG_ENABLE(hard-tabs,
1059         [  --enable-hard-tabs      compile with hard-tabs code],,
1060         [enable_hard_tabs=$with_develop])
1061 AC_MSG_RESULT($enable_hard_tabs)
1062 test "x$enable_hard_tabs" = xyes && AC_DEFINE(USE_HARD_TABS,1,[Define to 1 to compile with hard-tabs code])
1063
1064 ###   use option --enable-xmc-glitch to turn on use of magic-cookie optimize
1065 AC_MSG_CHECKING(if you want limited support for xmc)
1066 AC_ARG_ENABLE(xmc-glitch,
1067         [  --enable-xmc-glitch     compile with support for xmc (magic-cookie)],,
1068         [enable_xmc_glitch=$with_develop])
1069 AC_MSG_RESULT($enable_xmc_glitch)
1070 test "x$enable_xmc_glitch" = xyes && AC_DEFINE(USE_XMC_SUPPORT,1,[Define to 1 to compile with support for xmc (magic-cookie)])
1071
1072 ###############################################################################
1073 # These are just experimental, probably should not be in a package:
1074 CF_HELP_MESSAGE(Experimental Code:)
1075
1076 AC_MSG_CHECKING(if you do not want to assume colors are white-on-black)
1077 AC_ARG_ENABLE(assumed-color,
1078         [  --disable-assumed-color do not assume anything about default-colors],
1079         [with_assumed_color=$enableval],
1080         [with_assumed_color=yes])
1081 AC_MSG_RESULT($with_assumed_color)
1082 test "x$with_assumed_color" = xyes && AC_DEFINE(USE_ASSUMED_COLOR,1,[Define to 1 to assume things about default-colors])
1083
1084 ###   use option --enable-hashmap to turn on use of hashmap scrolling logic
1085 AC_MSG_CHECKING(if you want hashmap scrolling-optimization code)
1086 AC_ARG_ENABLE(hashmap,
1087         [  --disable-hashmap       compile without hashmap scrolling-optimization],
1088         [with_hashmap=$enableval],
1089         [with_hashmap=yes])
1090 AC_MSG_RESULT($with_hashmap)
1091 test "x$with_hashmap" = xyes && AC_DEFINE(USE_HASHMAP,1,[Define to 1 to compile with hashmap scrolling-optimization])
1092
1093 ###   use option --enable-colorfgbg to turn on use of $COLORFGBG environment
1094 AC_MSG_CHECKING(if you want colorfgbg code)
1095 AC_ARG_ENABLE(colorfgbg,
1096         [  --enable-colorfgbg      compile-in experimental $COLORFGBG code],
1097         [with_colorfgbg=$enableval],
1098         [with_colorfgbg=no])
1099 AC_MSG_RESULT($with_colorfgbg)
1100 test "x$with_colorfgbg" = xyes && AC_DEFINE(USE_COLORFGBG,1,[Define to 1 to compile-in experimental $COLORFGBG code])
1101
1102 ###   use option --enable-interop to turn on use of bindings used for interop
1103 AC_MSG_CHECKING(if you want interop bindings)
1104 AC_ARG_ENABLE(interop,
1105         [  --enable-interop        compile-in experimental interop bindings],
1106         [with_exp_interop=$enableval],
1107         [with_exp_interop=no])
1108 AC_MSG_RESULT($with_exp_interop)
1109
1110 NCURSES_INTEROP_FUNCS=0
1111 test "x$with_exp_interop" = xyes && NCURSES_INTEROP_FUNCS=1
1112 AC_SUBST(NCURSES_INTEROP_FUNCS)
1113
1114 # This is still experimental (20080329), but should ultimately be moved to
1115 # the script-block --with-normal, etc.
1116 CF_WITH_PTHREAD
1117
1118 if test "x$with_pthread" != xno; then
1119         AC_CHECK_FUNC(pthread_kill,[
1120                 AC_MSG_CHECKING(if you want to allow EINTR in wgetch with pthreads)
1121                 AC_ARG_ENABLE(pthreads-eintr,
1122                         [  --enable-pthreads-eintr enable EINTR in wgetch with pthreads],
1123                         [use_pthreads_eintr=$enableval],
1124                         [use_pthreads_eintr=no])
1125                 AC_MSG_RESULT($use_pthreads_eintr)
1126                 if test "x$use_pthreads_eintr" = xyes ; then
1127                         AC_DEFINE(USE_PTHREADS_EINTR,1,[Define to 1 to enable EINTR in wgetch with pthreads])
1128                 fi])
1129
1130         AC_MSG_CHECKING(if you want to use weak-symbols for pthreads)
1131         AC_ARG_ENABLE(weak-symbols,
1132                 [  --enable-weak-symbols   enable weak-symbols for pthreads],
1133                 [use_weak_symbols=$enableval],
1134                 [use_weak_symbols=no])
1135         AC_MSG_RESULT($use_weak_symbols)
1136         if test "x$use_weak_symbols" = xyes ; then
1137                 CF_WEAK_SYMBOLS
1138         else
1139                 cf_cv_weak_symbols=no
1140         fi
1141
1142         if test "x$cf_cv_weak_symbols" = xyes ; then
1143                 AC_DEFINE(USE_WEAK_SYMBOLS,1,[Define to 1 to enable weak-symbols for pthreads])
1144         fi
1145 fi
1146
1147 PTHREAD=
1148 if test "x$with_pthread" = "xyes" ; then
1149     AC_DEFINE(USE_PTHREADS,1,[Define to 1 to use pthreads feature])
1150     enable_reentrant=yes
1151     if test "x$cf_cv_weak_symbols" = xyes ; then
1152         PTHREAD=-lpthread
1153     fi
1154 fi
1155 AC_SUBST(PTHREAD)
1156
1157 # Reentrant code has to be opaque; there's little advantage to making ncurses
1158 # opaque outside of that, so there is no --enable-opaque option.  We can use
1159 # this option without --with-pthreads, but this will be always set for
1160 # pthreads.
1161 AC_MSG_CHECKING(if you want experimental reentrant code)
1162 AC_ARG_ENABLE(reentrant,
1163         [  --enable-reentrant      compile with experimental reentrant code],
1164         [with_reentrant=$enableval],
1165         [with_reentrant=no])
1166 AC_MSG_RESULT($with_reentrant)
1167 if test "x$with_reentrant" = xyes ; then
1168         cf_cv_enable_reentrant=1
1169         cf_cv_enable_opaque="NCURSES_INTERNALS"
1170         NCURSES_OPAQUE=1
1171         NCURSES_SIZE_T=int
1172         if test "x$cf_cv_weak_symbols" = xyes ; then
1173                 CF_REMOVE_LIB(LIBS,$LIBS,pthread)
1174                 CF_ADD_LIB(pthread,TEST_LIBS)
1175                 CF_ADD_LIB(pthread,TEST_LIBS2)
1176         else
1177                 LIB_SUFFIX="t${LIB_SUFFIX}"
1178         fi
1179         AC_DEFINE(USE_REENTRANT,1,[Define to 1 to use experimental reentrant feature])
1180         CF_NCURSES_ABI_6
1181 else
1182         cf_cv_enable_reentrant=0
1183         cf_cv_enable_opaque="NCURSES_OPAQUE"
1184         NCURSES_OPAQUE=0
1185         NCURSES_SIZE_T=short
1186 fi
1187 AC_SUBST(cf_cv_enable_reentrant)
1188 AC_SUBST(cf_cv_enable_opaque)
1189 AC_SUBST(NCURSES_OPAQUE)
1190 AC_SUBST(NCURSES_SIZE_T)
1191
1192 ### Allow using a different wrap-prefix
1193 if test "$cf_cv_enable_reentrant" != 0 || test "$BROKEN_LINKER" = 1 ; then
1194         AC_MSG_CHECKING(for prefix used to wrap public variables)
1195         AC_ARG_WITH(wrap-prefix,
1196                 [  --with-wrap-prefix=XXX  override prefix used for public variables],
1197                 [NCURSES_WRAP_PREFIX=$withval],
1198                 [NCURSES_WRAP_PREFIX=_nc_])
1199         AC_MSG_RESULT($NCURSES_WRAP_PREFIX)
1200 else
1201         NCURSES_WRAP_PREFIX=_nc_
1202 fi
1203 AC_SUBST(NCURSES_WRAP_PREFIX)
1204 AC_DEFINE_UNQUOTED(NCURSES_WRAP_PREFIX,"$NCURSES_WRAP_PREFIX",[Define to override _nc_ prefix])
1205
1206 AC_MSG_CHECKING(if you want experimental safe-sprintf code)
1207 AC_ARG_ENABLE(safe-sprintf,
1208         [  --enable-safe-sprintf   compile with experimental safe-sprintf code],
1209         [with_safe_sprintf=$enableval],
1210         [with_safe_sprintf=no])
1211 AC_MSG_RESULT($with_safe_sprintf)
1212 test "x$with_safe_sprintf" = xyes && AC_DEFINE(USE_SAFE_SPRINTF,1,[Define to 1 to compile with experimental safe-sprintf code])
1213
1214 ###   use option --disable-scroll-hints to turn off use of scroll-hints scrolling logic
1215 # when hashmap is used scroll hints are useless
1216 if test "$with_hashmap" = no ; then
1217 AC_MSG_CHECKING(if you want to experiment without scrolling-hints code)
1218 AC_ARG_ENABLE(scroll-hints,
1219         [  --disable-scroll-hints  compile without scroll-hints code],
1220         [with_scroll_hints=$enableval],
1221         [with_scroll_hints=yes])
1222 AC_MSG_RESULT($with_scroll_hints)
1223 test "x$with_scroll_hints" = xyes && AC_DEFINE(USE_SCROLL_HINTS,1,[Define to 1 to compile without scroll-hints code])
1224 fi
1225
1226 AC_MSG_CHECKING(if you want experimental wgetch-events code)
1227 AC_ARG_ENABLE(wgetch-events,
1228         [  --enable-wgetch-events  compile with experimental wgetch-events code],
1229         [with_wgetch_events=$enableval],
1230         [with_wgetch_events=no])
1231 AC_MSG_RESULT($with_wgetch_events)
1232 test "x$with_wgetch_events" = xyes && AC_DEFINE(NCURSES_WGETCH_EVENTS,1,[Define to 1 to compile with experimental wgetch-events code])
1233
1234 ###############################################################################
1235 CF_HELP_MESSAGE(Testing/development Options:)
1236
1237 ###     use option --disable-echo to suppress full display compiling commands
1238 CF_DISABLE_ECHO
1239 if test "x$enable_echo" = xyes; then
1240         ECHO_LINK=
1241 else
1242         ECHO_LINK='@ echo linking $@ ... ;'
1243         test -n "$LIBTOOL" && LIBTOOL="$LIBTOOL --silent"
1244         test -n "$LIBTOOL_CXX" && LIBTOOL_CXX="$LIBTOOL_CXX --silent"
1245 fi
1246 AC_SUBST(ECHO_LINK)
1247
1248 ###     use option --enable-warnings to turn on all gcc warnings
1249 AC_MSG_CHECKING(if you want to see compiler warnings)
1250 AC_ARG_ENABLE(warnings,
1251         [  --enable-warnings       build: turn on GCC compiler warnings],
1252         [with_warnings=$enableval])
1253 AC_MSG_RESULT($with_warnings)
1254
1255 if test "x$with_warnings" = "xyes"; then
1256         CF_ADD_ADAFLAGS(-gnatg)
1257         CF_GCC_WARNINGS(Wdeclaration-after-statement Wextra Wno-unknown-pragmas Wswitch-enum)
1258         if test "x$cf_with_cxx" = xyes ; then
1259                 CF_GXX_WARNINGS(Wno-unused)
1260         fi
1261 fi
1262 CF_GCC_ATTRIBUTES
1263 CF_ENABLE_STRING_HACKS
1264
1265 ###     use option --enable-assertions to turn on generation of assertion code
1266 AC_MSG_CHECKING(if you want to enable runtime assertions)
1267 AC_ARG_ENABLE(assertions,
1268         [  --enable-assertions     test: turn on generation of assertion code],
1269         [with_assertions=$enableval],
1270         [with_assertions=no])
1271 AC_MSG_RESULT($with_assertions)
1272 if test -n "$GCC"
1273 then
1274         if test "$with_assertions" = no
1275         then
1276                 CPPFLAGS="$CPPFLAGS -DNDEBUG"
1277         else
1278                 CF_ADD_ADAFLAGS(-gnata)
1279         fi
1280 fi
1281
1282 ###     use option --disable-leaks to suppress "permanent" leaks, for testing
1283 CF_DISABLE_LEAKS
1284 AC_DEFINE(HAVE_NC_ALLOC_H,1,[Define to 1 if we have nc_alloc.h header])
1285
1286 ###     use option --enable-expanded to generate certain macros as functions
1287 AC_ARG_ENABLE(expanded,
1288         [  --enable-expanded       test: generate functions for certain macros],
1289         [test "x$enableval" = xyes && AC_DEFINE(NCURSES_EXPANDED,1,[Define to 1 to generate functions for certain macros])])
1290
1291 ###     use option --disable-macros to suppress macros in favor of functions
1292 AC_ARG_ENABLE(macros,
1293         [  --disable-macros        test: use functions rather than macros],
1294         [test "$enableval" = no && AC_DEFINE(NCURSES_NOMACROS,1,[Define to 1 to use functions rather than macros])])
1295
1296 # Normally we only add trace() to the debug-library.  Allow this to be
1297 # extended to all models of the ncurses library:
1298 cf_all_traces=no
1299 case "$CFLAGS $CPPFLAGS" in
1300 *-DTRACE*)
1301         cf_all_traces=yes
1302         ;;
1303 esac
1304
1305 AC_MSG_CHECKING(whether to add trace feature to all models)
1306 AC_ARG_WITH(trace,
1307 [  --with-trace            test: add trace() function to all models of ncurses],
1308 [cf_with_trace=$withval],
1309 [cf_with_trace=$cf_all_traces])
1310 AC_MSG_RESULT($cf_with_trace)
1311
1312 if test "x$cf_with_trace" = xyes ; then
1313         LIB_TRACING=all
1314         ADA_TRACE=TRUE
1315         CF_ADD_CFLAGS(-DTRACE)
1316 else
1317         LIB_TRACING=DEBUG
1318         ADA_TRACE=FALSE
1319 fi
1320
1321 AC_SUBST(ADA_TRACE)
1322
1323 ###     Checks for libraries.
1324 case $cf_cv_system_name in #(vi
1325 *mingw32*) #(vi
1326         ;;
1327 *)
1328 AC_CHECK_FUNC(gettimeofday,
1329         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function]),[
1330
1331 AC_CHECK_LIB(bsd, gettimeofday,
1332         AC_DEFINE(HAVE_GETTIMEOFDAY,1,[Define to 1 if we have gettimeofday function])
1333         CF_ADD_LIB(bsd))])dnl CLIX: bzero, select, gettimeofday
1334         ;;
1335 esac
1336
1337 CF_MATH_LIB(MATH_LIB,pow(sin(x),x))
1338 AC_SUBST(MATH_LIB)
1339
1340 ###     Checks for header files.
1341 AC_STDC_HEADERS
1342 AC_HEADER_DIRENT
1343 AC_HEADER_TIME
1344 CF_REGEX
1345
1346 dnl These are some other potentially nonportable headers.
1347 AC_CHECK_HEADERS( \
1348 fcntl.h \
1349 getopt.h \
1350 limits.h \
1351 locale.h \
1352 math.h \
1353 poll.h \
1354 sys/bsdtypes.h \
1355 sys/ioctl.h \
1356 sys/param.h \
1357 sys/poll.h \
1358 sys/select.h \
1359 sys/time.h \
1360 sys/times.h \
1361 ttyent.h \
1362 unistd.h \
1363 wctype.h \
1364 )
1365
1366 CF_GETOPT_HEADER
1367
1368 # check for ISC (this may also define _POSIX_SOURCE)
1369 # Note: even non-Posix ISC needs <sys/bsdtypes.h> to declare fd_set
1370 if test "x$ISC" = xyes ; then
1371         AC_CHECK_LIB(cposix,main)
1372         AC_CHECK_LIB(inet,bzero,CF_ADD_LIB(inet))dnl also 'select()'
1373 fi
1374
1375 CF_SYS_TIME_SELECT
1376
1377 ###     checks for compiler characteristics
1378 AC_LANG_C
1379 AC_C_CONST
1380 CF_C_INLINE(NCURSES_INLINE,1200)
1381 CF_SIG_ATOMIC_T
1382
1383 if test $NCURSES_CHTYPE = auto ; then
1384         CF_TYPEOF_CHTYPE
1385 else
1386         cf_cv_typeof_chtype=$NCURSES_CHTYPE
1387 fi
1388 test "$cf_cv_typeof_chtype" = unsigned && cf_cv_typeof_chtype=""
1389 AC_SUBST(cf_cv_typeof_chtype)
1390
1391 CF_UNSIGNED_LITERALS
1392 cf_cv_1UL="1"
1393 test ".$cf_cv_unsigned_literals" = .yes && cf_cv_1UL="${cf_cv_1UL}U"
1394 test ".$cf_cv_typeof_chtype"    = .long && cf_cv_1UL="${cf_cv_1UL}L"
1395 AC_SUBST(cf_cv_1UL)
1396
1397 if test $NCURSES_MMASK_T = auto ; then
1398         cf_cv_typeof_mmask_t=long
1399 else
1400         cf_cv_typeof_mmask_t=$NCURSES_MMASK_T
1401 fi
1402 test "$cf_cv_typeof_mmask_t" = unsigned && cf_cv_typeof_mmask_t=""
1403 AC_SUBST(cf_cv_typeof_mmask_t)
1404
1405 ###     Checks for external-data
1406 CF_ERRNO
1407 CF_LINK_DATAONLY
1408
1409 ###     Checks for library functions.
1410 AC_CHECK_FUNCS( \
1411 getcwd \
1412 getegid \
1413 geteuid \
1414 getttynam \
1415 issetugid \
1416 poll \
1417 putenv \
1418 remove \
1419 select \
1420 setbuf \
1421 setbuffer \
1422 setenv \
1423 setvbuf \
1424 sigaction \
1425 sigvec \
1426 strdup \
1427 strstr \
1428 tcgetpgrp \
1429 times \
1430 vsnprintf \
1431 )
1432 if test "x$with_getcap" = "xyes" ; then
1433         CF_CGETENT
1434 fi
1435
1436 CF_ISASCII
1437 CF_STRUCT_SIGACTION
1438 CF_FUNC_NANOSLEEP
1439 CF_FUNC_TERMIOS
1440 CF_FUNC_VSSCANF
1441 CF_MKSTEMP
1442
1443 # setup for prototype of fallback for vsscanf()
1444 CF_SUBST_IF(["$cf_cv_func_vsscanf" = vsscanf], HAVE_VSSCANF, 1, 0)
1445
1446 dnl FIXME (may need this) AC_SYS_RESTARTABLE_SYSCALLS
1447 if test "x$cross_compiling" = xyes ; then
1448         AC_MSG_WARN(cross compiling: assume setvbuf params not reversed)
1449 else
1450         AC_FUNC_SETVBUF_REVERSED
1451 fi
1452 AC_CHECK_TYPE(intptr_t, long)
1453 CF_TYPE_SIGACTION
1454 CF_SIZECHANGE
1455 CF_FUNC_MEMMOVE
1456 CF_FUNC_POLL
1457 CF_VA_COPY
1458 AC_FUNC_VFORK
1459
1460 # special check for test/ditto.c
1461 CF_FUNC_OPENPTY
1462 if test "$cf_cv_func_openpty" != no ; then
1463     AC_DEFINE_UNQUOTED(USE_OPENPTY_HEADER,<$cf_cv_func_openpty>,[Define to actual header for openpty function])
1464     AC_DEFINE(USE_XTERM_PTY,1,[Define to 1 if we should assume xterm pseudoterminal interface])
1465     if test "x$cf_cv_lib_util" = xyes ; then
1466         CF_ADD_LIB(util,TEST_LIBS)
1467     fi
1468 fi
1469 AC_SUBST(TEST_LIBS)
1470 AC_SUBST(TEST_LIBS2)
1471
1472 if test "$with_hashed_db" != no ; then
1473         AC_DEFINE(USE_HASHED_DB,1,[Define to 1 if we should build terminfo in hashed database])
1474         CF_HASHED_DB($with_hashed_db)
1475 fi
1476
1477 dnl We'll do our own -g libraries, unless the user's overridden via $CFLAGS
1478 if test -z "$cf_user_CFLAGS" && test "$with_no_leaks" = no ; then
1479         CF_STRIP_G_OPT(CFLAGS)
1480         CF_STRIP_G_OPT(CXXFLAGS)
1481 fi
1482
1483 # Just in case, check if the C compiler has a bool type.
1484 CF_BOOL_DECL(cf_cv_cc_bool_type)
1485
1486 # Check for C++ compiler characteristics (and ensure that it's there!)
1487 if test -n "$CXX" ; then
1488         AC_LANG_CPLUSPLUS
1489         CF_STDCPP_LIBRARY
1490         CF_PROG_CC_C_O(CXX)
1491
1492         case $GXX_VERSION in
1493         1*|2.[0-6]*)
1494                 cf_cxx_library=yes
1495                 ;;
1496         *-2.7*|2.7*)
1497                 CF_GPP_LIBRARY
1498                 ;;
1499         *)
1500                 cf_cxx_library=no
1501                 ;;
1502         esac
1503
1504         AC_CHECK_HEADERS(typeinfo)
1505         CF_CXX_IOSTREAM_NAMESPACE
1506         CF_BOOL_DECL
1507         CF_BOOL_SIZE
1508         CF_ETIP_DEFINES
1509         CF_CPP_PARAM_INIT
1510         CF_CPP_STATIC_CAST
1511         CF_CXX_AR_FLAGS
1512 else
1513         cf_cxx_library=no
1514         cf_cv_builtin_bool=1
1515
1516         # Just because we are not configuring against C++ right now does not
1517         # mean that a user will not want to use C++.  Some distributors disable
1518         # the C++ portion of this configuration as a shortcut (or just to avoid
1519         # compiling the demo in the c++ directory).  So we need a reasonable
1520         # default for the 'bool' type.
1521         #
1522         # Caveat: since the storage of the bool type is not standardized, it
1523         # may change.
1524
1525         if test "$NCURSES_BOOL" != auto ; then
1526                 cf_cv_type_of_bool=$NCURSES_BOOL
1527                 cf_cv_header_stdbool_h=0
1528         else
1529                 if test "$cf_cv_header_stdbool_h" = 1 ; then
1530                         CF_BOOL_SIZE
1531                 else
1532                         AC_MSG_CHECKING(for fallback type of bool)
1533                         case "$host_cpu" in #(vi
1534                         i?86)   cf_cv_type_of_bool=char ;; #(vi
1535                         *)      cf_cv_type_of_bool=int  ;;
1536                         esac
1537                         AC_MSG_RESULT($cf_cv_type_of_bool)
1538                 fi
1539         fi
1540 fi
1541 AC_SUBST(CXXLIBS)
1542
1543 # If the C compiler did not declare bool, and we did not determine that the C++
1544 # compiler does not declare bool, turn on an ifdef in curses.h that makes the
1545 # ncurses library use the same type as C++ bool.  Note that this allows one to
1546 # specify the type of bool in a configure-script option and postpone
1547 # integration with the C++ compiler provided that the types are compatible.
1548 USE_CXX_BOOL=1
1549 if test $cf_cv_cc_bool_type = 1
1550 then
1551         # oops: C has a bool.  Unlikely, but C++ could differ.
1552         USE_CXX_BOOL=0
1553 elif test $cf_cv_builtin_bool = 0
1554 then
1555         # C++ has no bool
1556         USE_CXX_BOOL=0
1557 else
1558         # this is the normal case
1559         USE_CXX_BOOL='defined(__cplusplus)'
1560 fi
1561 AC_SUBST(USE_CXX_BOOL)
1562
1563 CF_HELP_MESSAGE(Ada95 Binding Options:)
1564
1565 dnl If the Ada95 source-tree is present, add that to the build unless it will
1566 dnl not work, or was not requested.
1567 if test -f "${srcdir}/Ada95/Makefile.in" ; then
1568
1569 dnl libtool does not know anything about GNAT, though a change made in 1998
1570 dnl provided for it "someday".  Disable the ada subtree if we are using
1571 dnl libtool -TD 20070714
1572         if test "$cf_with_ada" != "no" ; then
1573                 if test "$with_libtool" != "no"; then
1574                         AC_MSG_WARN(libtool does not support Ada - disabling feature)
1575                         cf_with_ada=no
1576                 fi
1577         fi
1578
1579 dnl Check for availability of GNU Ada Translator (GNAT).
1580 dnl At the moment we support no other Ada95 compiler.
1581         if test "$cf_with_ada" != "no" ; then
1582                 CF_PROG_GNAT
1583                 if test "x$cf_cv_prog_gnat_correct" = xyes; then
1584                         CF_ADD_ADAFLAGS(-gnatpn)
1585                         CF_FIXUP_ADAFLAGS
1586
1587                         CF_GNAT_GENERICS
1588                         CF_GNAT_SIGINT
1589                         CF_GNAT_PRAGMA_UNREF
1590                         CF_GNAT_PROJECTS
1591
1592                         CF_WITH_ADA_COMPILER
1593
1594                         cf_ada_package=terminal_interface
1595                         AC_SUBST(cf_ada_package)
1596
1597                         CF_WITH_ADA_INCLUDE
1598                         CF_WITH_ADA_OBJECTS
1599                         CF_WITH_ADA_SHAREDLIB
1600                 fi
1601         fi
1602 else
1603         cf_with_ada=no
1604 fi
1605
1606 # do this "late" to avoid conflict with header-checks
1607 if test "x$with_widec" = xyes ; then
1608         AC_CHECK_SIZEOF(wchar_t)
1609 fi
1610
1611 ### Construct the ncurses library-subsets, if any, from this set of keywords:
1612 ###     none, base, ext_funcs, ext_tinfo, ticlib, termlib, widechar
1613 ###
1614 ### ticlib modules may be a separate library, otherwise contained in termlib.
1615 ### termlib modules may be a separate library, otherwise contained in ncurses.
1616 ###
1617 ### The of "+" or " " between the tokens controls the way the script
1618 ### chooses to split module lists into libraries.
1619 ###
1620 ### (see CF_LIB_RULES).
1621 AC_MSG_CHECKING(for library subsets)
1622 LIB_SUBSETS=
1623
1624 if test "x$cf_with_progs" = xyes || test "$with_ticlib" != no || test "$with_termcap" != no; then
1625         LIB_SUBSETS="${LIB_SUBSETS}ticlib"
1626         if test "$with_ticlib" != no ; then
1627                 LIB_SUBSETS="${LIB_SUBSETS} "
1628         else
1629                 LIB_SUBSETS="${LIB_SUBSETS}+"
1630         fi
1631 fi
1632
1633 LIB_SUBSETS="${LIB_SUBSETS}termlib"
1634 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_tinfo"
1635
1636 if test "$with_termlib" != no ; then
1637         LIB_SUBSETS="${LIB_SUBSETS} "
1638 else
1639         LIB_SUBSETS="${LIB_SUBSETS}+"
1640 fi
1641
1642 LIB_SUBSETS="${LIB_SUBSETS}base"
1643
1644 # Most term-driver calls are to tinfo, but some like init_pair are to the
1645 # base library (so it resides in base).
1646 if test "$with_term_driver" != no ; then
1647         LIB_SUBSETS="${LIB_SUBSETS}+port_drivers"
1648         case $cf_cv_system_name in #(vi
1649         *mingw32*) #(vi
1650                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo+port_win32con"
1651                 ;;
1652         *) #(vi
1653                 LIB_SUBSETS="${LIB_SUBSETS}+port_tinfo"
1654                 ;;
1655         esac
1656 fi
1657
1658 test "x$with_widec"     = xyes && LIB_SUBSETS="${LIB_SUBSETS}+widechar"
1659 test "x$with_ext_funcs" = xyes && LIB_SUBSETS="${LIB_SUBSETS}+ext_funcs"
1660
1661 AC_MSG_RESULT($LIB_SUBSETS)
1662
1663 ### Construct the list of include-directories to be generated
1664 CF_INCLUDE_DIRS
1665 CF_ADA_INCLUDE_DIRS
1666
1667 ### Build up pieces for makefile rules
1668 AC_MSG_CHECKING(default library suffix)
1669 CF_LIB_TYPE($DFT_LWR_MODEL,DFT_ARG_SUFFIX)dnl
1670 AC_SUBST(DFT_ARG_SUFFIX)dnl the string to append to "-lncurses" ("")
1671 AC_MSG_RESULT($DFT_ARG_SUFFIX)
1672
1673 AC_MSG_CHECKING(default library-dependency suffix)
1674 CF_LIB_SUFFIX($DFT_LWR_MODEL,DFT_LIB_SUFFIX,DFT_DEP_SUFFIX)dnl
1675 AC_SUBST(DFT_DEP_SUFFIX)dnl the corresponding library-suffix (".a")
1676 AC_MSG_RESULT($DFT_DEP_SUFFIX)
1677
1678 AC_MSG_CHECKING(default object directory)
1679 CF_OBJ_SUBDIR($DFT_LWR_MODEL,DFT_OBJ_SUBDIR)dnl
1680 AC_SUBST(DFT_OBJ_SUBDIR)dnl the default object-directory ("obj")
1681 AC_MSG_RESULT($DFT_OBJ_SUBDIR)
1682
1683 if test "x$cf_with_cxx" = xyes ; then
1684 AC_MSG_CHECKING(c++ library-dependency suffix)
1685 if test "$with_libtool" != "no"; then
1686         # libtool thinks it can make c++ shared libraries (perhaps only g++)
1687         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1688 elif test "$with_shared_cxx" != "no"; then
1689         # also for g++ users...
1690         CXX_LIB_SUFFIX=$DFT_DEP_SUFFIX
1691 else
1692         # we normally make a static library because C/C++ library rules differ
1693         CF_LIB_SUFFIX(normal,CXX_LIB_SUFFIX,CXX_DEP_SUFFIX)
1694 fi
1695 AC_MSG_RESULT($CXX_LIB_SUFFIX)
1696 AC_SUBST(CXX_LIB_SUFFIX)
1697 fi
1698
1699 # do not want -ldl in build except as needed for -lncurses dependency
1700 if test "x$with_dlsym" = xyes ; then
1701 if test $DFT_LWR_MODEL = shared || \
1702    test $DFT_LWR_MODEL = libtool ; then
1703         CF_REMOVE_LIB(LIBS,$LIBS,dl)
1704 fi
1705 fi
1706 ### Set up low-level terminfo dependencies for makefiles.
1707
1708 # TICS_LIST and TINFO_LIST are needed to build libtic.so and libterm.so, but
1709 # do not need libdl
1710 TICS_LIST=
1711 if test "x$with_dlsym" = xyes ; then
1712         CF_REMOVE_LIB(TINFO_LIST,$SHLIB_LIST,dl)
1713 fi
1714
1715 if test "$with_ticlib" != no ; then
1716
1717         if test "x$with_ticlib" != xyes ; then
1718                 TICS_NAME=$with_ticlib
1719                 TICS_ARG_SUFFIX="${with_ticlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1720                 TICS_DEP_SUFFIX="${with_ticlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1721                 TICS_LIB_SUFFIX="${with_ticlib}"
1722         else
1723                 TICS_ARG_SUFFIX="${TICS_NAME}${DFT_ARG_SUFFIX}"
1724                 TICS_DEP_SUFFIX="${TICS_NAME}${DFT_DEP_SUFFIX}"
1725                 TICS_LIB_SUFFIX="${TICS_NAME}${LIB_SUFFIX}"
1726         fi
1727         TICS_LDFLAGS="-L${LIB_DIR}"
1728         TICS_LIBS="-l${TICS_LIB_SUFFIX}"
1729 else
1730         TICS_LDFLAGS="-L${LIB_DIR}"
1731         TICS_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX}"
1732 fi
1733 AC_SUBST(TICS_ARG_SUFFIX)
1734 AC_SUBST(TICS_DEP_SUFFIX)
1735 AC_SUBST(TICS_LIB_SUFFIX)
1736 AC_SUBST(TICS_LDFLAGS)
1737 AC_SUBST(TICS_LIBS)
1738
1739 if test "$with_termlib" != no ; then
1740
1741         if test "x$with_termlib" != xyes ; then
1742                 TINFO_NAME=$with_termlib
1743                 TINFO_SUFFIX="`echo ${DFT_LIB_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1744                 TINFO_ARG_SUFFIX="${with_termlib}`echo ${DFT_ARG_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1745                 TINFO_DEP_SUFFIX="${with_termlib}`echo ${DFT_DEP_SUFFIX}|sed -e "s/^${LIB_SUFFIX}//"`"
1746                 TINFO_LIB_SUFFIX="${with_termlib}"
1747         else
1748                 TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1749                 TINFO_ARG_SUFFIX="${TINFO_NAME}${DFT_ARG_SUFFIX}"
1750                 TINFO_DEP_SUFFIX="${TINFO_NAME}${DFT_DEP_SUFFIX}"
1751                 TINFO_LIB_SUFFIX="${TINFO_NAME}${LIB_SUFFIX}"
1752         fi
1753
1754         TEST_DEPS="${LIB_DIR}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1755         TEST_DEP2="${LIB_2ND}/${LIB_PREFIX}${TINFO_DEP_SUFFIX}"
1756         if test "$DFT_LWR_MODEL" = "libtool"; then
1757                 TEST_ARGS="${TEST_DEPS}"
1758                 TEST_ARG2="${TEST_DEP2}"
1759                 TINFO_LDFLAGS="-L${LIB_DIR}"
1760                 TINFO_LIBS="$TEST_ARGS"
1761                 TICS_LIST="$SHLIB_LIST $TEST_ARGS"
1762                 SHLIB_LIST="${SHLIB_LIST} $TEST_ARGS"
1763         else
1764                 TEST_ARGS="-l${TINFO_ARG_SUFFIX}"
1765                 TEST_ARG2="-l${TINFO_ARG_SUFFIX}"
1766                 if test "x$with_term_driver" != xno ; then
1767                         TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1768                         TICS_LIBS="$TICS_LIBS -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1769                         TINFO_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX} $TEST_ARGS"
1770                 else
1771                         TICS_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1772                         TINFO_LIBS="$TEST_ARGS"
1773                 fi
1774                 TINFO_LDFLAGS="-L${LIB_DIR}"
1775                 SHLIB_LIST="$SHLIB_LIST -l${TINFO_LIB_SUFFIX}"
1776         fi
1777 else
1778         # the next lines are needed for linking libtic over libncurses
1779         TINFO_NAME=${LIB_NAME}
1780         TINFO_SUFFIX=${DFT_LIB_SUFFIX}
1781         TINFO_ARG_SUFFIX=${LIB_NAME}${DFT_ARG_SUFFIX}
1782         if test "x$with_tic_depends" = xyes ; then
1783                 TICS_LIST="$SHLIB_LIST -l${LIB_NAME}${DFT_ARG_SUFFIX}"
1784         else
1785                 TICS_LIST="$SHLIB_LIST"
1786         fi
1787
1788         TINFO_LDFLAGS="-L${LIB_DIR}"
1789         TINFO_LIBS="-l${LIB_NAME}${DFT_ARG_SUFFIX}"
1790 fi
1791
1792 if test "$DFT_LWR_MODEL" = shared ; then
1793         case $cf_cv_system_name in #(vi
1794         cygwin*)
1795                 # "lib" files have ".dll.a" suffix, "cyg" files have ".dll"
1796                 TINFO_SUFFIX=.dll
1797                 ;;
1798         esac
1799 fi
1800
1801 AC_SUBST(TINFO_ARG_SUFFIX)
1802 AC_SUBST(TINFO_DEP_SUFFIX)
1803 AC_SUBST(TINFO_LIB_SUFFIX)
1804 AC_SUBST(TINFO_LDFLAGS)
1805 AC_SUBST(TINFO_LIBS)
1806
1807 if test "x$with_dlsym" = xyes ; then
1808         CF_REMOVE_LIB(TICS_LIST,$TICS_LIST,dl)
1809 fi
1810
1811 if test "$DFT_LWR_MODEL" = "libtool"; then
1812     OBJEXT=lo
1813 fi
1814
1815 # needed for Ada95
1816 TINFO_LDFLAGS2=`echo "$TINFO_LDFLAGS" | sed -e 's,-L\.\./,-L../../,'`
1817 AC_SUBST(TINFO_LDFLAGS2)
1818
1819 case $DFT_LWR_MODEL in
1820 normal|debug|profile)
1821         CF_LDFLAGS_STATIC
1822         ;;
1823 esac
1824
1825 AC_MSG_CHECKING(where we will install curses.h)
1826 test "$with_overwrite" = no && \
1827 test "x$includedir" = 'x${prefix}/include' && \
1828         includedir='${prefix}/include/ncurses'${LIB_SUFFIX}
1829 AC_MSG_RESULT($includedir)
1830
1831 ### Resolve a conflict between normal and wide-curses by forcing applications
1832 ### that will need libutf8 to add it to their configure script.
1833 if test "$with_overwrite" != no ; then
1834 if test "$NCURSES_LIBUTF8" = 1 ; then
1835         NCURSES_LIBUTF8='defined(HAVE_LIBUTF8_H)'
1836         AC_MSG_WARN(Wide-character applications must define HAVE_LIBUTF8_H to include curses.h)
1837 fi
1838 fi
1839 WITH_OVERWRITE=$with_overwrite
1840
1841 AC_SUBST(WITH_OVERWRITE)
1842 AC_SUBST(TICS_LIST)
1843 AC_SUBST(TINFO_LIST)
1844 AC_SUBST(SHLIB_LIST)
1845
1846 # used to separate tack out of the tree
1847 NCURSES_TREE=
1848 AC_SUBST(NCURSES_TREE)
1849
1850 ### predefined stuff for the test programs
1851 AC_DEFINE(HAVE_SLK_COLOR,1,[Define to 1 if we have slk_color for test-programs])
1852
1853 ### Construct the list of subdirectories for which we'll customize makefiles
1854 ### with the appropriate compile-rules.
1855
1856 CF_SRC_MODULES($modules_to_build)
1857
1858 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
1859    SUB_MAKEFILES="$SUB_MAKEFILES Ada95/gen/adacurses${DFT_ARG_SUFFIX}-config:Ada95/gen/adacurses-config.in"
1860    SUB_MAKEFILES="$SUB_MAKEFILES man/adacurses${DFT_ARG_SUFFIX}-config.1:man/MKada_config.in"
1861 fi
1862
1863 CF_DIRS_TO_MAKE
1864
1865 # symbols that differ when compiling Ada95 by itself.
1866 NCURSES_SHLIB2='sh $(top_srcdir)/misc/shlib'
1867 AC_SUBST(NCURSES_SHLIB2)
1868
1869 # values to use as strings
1870 AC_DEFINE_UNQUOTED(NCURSES_PATHSEP,'$PATH_SEPARATOR',[Define to override ':' as library path-separator])
1871
1872 AC_DEFINE_UNQUOTED(NCURSES_VERSION_STRING, "${NCURSES_MAJOR}.${NCURSES_MINOR}.${NCURSES_PATCH}",[Define to 1 if machine has ample memory for tic])
1873
1874 ### Now that we're done running tests, add the compiler-warnings, if any
1875 CF_ADD_CFLAGS($EXTRA_CFLAGS)
1876
1877 ### Define substitutions for header files to avoid name-pollution
1878 CF_SUBST_IF(["x$cf_cv_have_tcgetattr" = xyes], HAVE_TCGETATTR, 1, 0)
1879 CF_SUBST_IF(["x$ac_cv_header_termio_h" = xyes], HAVE_TERMIO_H, 1, 0)
1880 CF_SUBST_IF(["x$ac_cv_header_termios_h" = xyes], HAVE_TERMIOS_H, 1, 0)
1881
1882 ################################################################################
1883 test "x$use_database" = xyes && \
1884 SUB_MAKEFILES="$SUB_MAKEFILES misc/run_tic.sh:misc/run_tic.in"
1885
1886 SUB_MAKEFILES="$SUB_MAKEFILES misc/ncurses-config:misc/ncurses-config.in"
1887 SUB_MAKEFILES="$SUB_MAKEFILES man/ncurses${DFT_ARG_SUFFIX}${cf_cv_abi_version}-config.1:man/MKncu_config.in"
1888
1889 if test "x$enable_pc_files" = xyes ; then \
1890 SUB_MAKEFILES="$SUB_MAKEFILES misc/gen-pkgconfig:misc/gen-pkgconfig.in"
1891 MAKE_PC_FILES=
1892 else
1893 MAKE_PC_FILES="#"
1894 fi
1895 AC_SUBST(MAKE_PC_FILES)
1896 AC_SUBST(cross_compiling)
1897
1898 AC_PATH_PROG(TIC_PATH,tic,unknown,$PATH:/usr/local/ncurses/bin)
1899 if test -n "$FALLBACK_LIST"
1900 then
1901         if test "$TIC_PATH" = unknown
1902         then
1903                 AC_MSG_WARN(no tic program found for fallbacks)
1904         fi
1905 fi
1906 AC_SUBST(TIC_PATH)
1907
1908 if test "x$cf_with_tests" != xno ; then
1909         MAKE_TESTS=
1910 else
1911         MAKE_TESTS="#"
1912 fi
1913 AC_SUBST(MAKE_TESTS)
1914
1915 ADAHTML_DIR=../../doc/html/ada
1916 AC_SUBST(ADAHTML_DIR)
1917
1918 # these could be configurable, but are not currently
1919 PANEL_NAME=panel
1920 MENU_NAME=menu
1921 FORM_NAME=form
1922 CXX_NAME=ncurses++
1923
1924 AC_SUBST(PANEL_NAME)
1925 AC_SUBST(MENU_NAME)
1926 AC_SUBST(FORM_NAME)
1927 AC_SUBST(CXX_NAME)
1928
1929 SUB_SCRIPTS=
1930
1931 AC_OUTPUT( \
1932         include/MKterm.h.awk \
1933         include/curses.head:include/curses.h.in \
1934         include/ncurses_dll.h \
1935         include/termcap.h \
1936         include/unctrl.h \
1937         $SUB_SCRIPTS \
1938         $SUB_MAKEFILES \
1939         Makefile,[
1940 if test "x$cf_with_tests" != xno ; then
1941         CF_PRG_RULES([$srcdir/test/mk-test.awk INSTALL=no ECHO_LINK="$ECHO_LD"], test)
1942 fi
1943 CF_LIB_RULES($SRC_SUBDIRS)
1944
1945 if test "x$cf_with_ada" = "xyes" && test "x$cf_cv_prog_gnat_correct" = "xyes"; then
1946 if test -z "$USE_OLD_MAKERULES" ; then
1947         $AWK -f $srcdir/Ada95/mk-1st.awk <$srcdir/Ada95/src/modules >>Ada95/src/Makefile
1948 fi
1949 fi
1950 ],[
1951 ### Special initialization commands, used to pass information from the
1952 ### configuration-run into config.status
1953
1954 AWK="$AWK"
1955 DFT_ARG_SUFFIX="$DFT_ARG_SUFFIX"
1956 DFT_LWR_MODEL="$DFT_LWR_MODEL"
1957 ECHO_LD="$ECHO_LD"
1958 LDCONFIG="$LDCONFIG"
1959 LIBTOOL_VERSION="$LIBTOOL_VERSION"
1960 LIB_NAME="$LIB_NAME"
1961 LIB_PREFIX="$LIB_PREFIX"
1962 LIB_SUBSETS="$LIB_SUBSETS"
1963 LIB_SUFFIX="$LIB_SUFFIX"
1964 LIB_TRACING="$LIB_TRACING"
1965 LN_S="$LN_S"
1966 MAKE_TERMINFO="$MAKE_TERMINFO"
1967 NCURSES_MAJOR="$NCURSES_MAJOR"
1968 NCURSES_MINOR="$NCURSES_MINOR"
1969 NCURSES_OSPEED="$NCURSES_OSPEED"
1970 NCURSES_PATCH="$NCURSES_PATCH"
1971 SRC_SUBDIRS="$SRC_SUBDIRS"
1972 TERMINFO="$TERMINFO"
1973 TICS_ARG_SUFFIX="$TICS_ARG_SUFFIX"
1974 TICS_LIB_SUFFIX="$TICS_LIB_SUFFIX"
1975 TICS_NAME="$TICS_NAME"
1976 TIC_PATH="$TIC_PATH"
1977 TINFO_ARG_SUFFIX="$TINFO_ARG_SUFFIX"
1978 TINFO_LIB_SUFFIX="$TINFO_LIB_SUFFIX"
1979 TINFO_NAME="$TINFO_NAME"
1980 TINFO_SUFFIX="$TINFO_SUFFIX"
1981 USE_OLD_MAKERULES="$USE_OLD_MAKERULES"
1982 WITH_CURSES_H="$with_curses_h"
1983 WITH_ECHO="${enable_echo:=yes}"
1984 WITH_OVERWRITE="$with_overwrite"
1985 cf_LIST_MODELS="$cf_list_models"
1986 cf_cv_abi_version="$cf_cv_abi_version"
1987 cf_cv_do_relink="$cf_cv_do_relink"
1988 cf_cv_do_symlinks="$cf_cv_do_symlinks"
1989 cf_cv_enable_lp64="$cf_cv_enable_lp64"
1990 cf_cv_enable_opaque="$cf_cv_enable_opaque"
1991 cf_cv_prog_CC_c_o=$cf_cv_prog_CC_c_o
1992 cf_cv_prog_CXX_c_o=$cf_cv_prog_CXX_c_o
1993 cf_cv_prog_gnat_correct=$cf_cv_prog_gnat_correct
1994 cf_cv_rel_version="$cf_cv_rel_version"
1995 cf_cv_rm_so_locs="$cf_cv_rm_so_locs"
1996 cf_cv_shared_soname='$cf_cv_shared_soname'
1997 cf_cv_shlib_version="$cf_cv_shlib_version"
1998 cf_cv_shlib_version_infix="$cf_cv_shlib_version_infix"
1999 cf_cv_system_name="$cf_cv_system_name"
2000 cf_cv_term_driver="$with_term_driver"
2001 cf_with_ada="$cf_with_ada"
2002 cf_with_cxx_binding="$cf_with_cxx_binding"
2003 cf_with_manpages="$cf_with_manpages"
2004 cf_with_tests="$cf_with_tests"
2005 with_shared_cxx="$with_shared_cxx"
2006 host="$host"
2007 target="$target"
2008
2009 ],cat)dnl
2010 ${MAKE:-make} preinstall